?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-gui: Fix use of renamed tag.
[git/mjg.git] / lib / diff.tcl
blob7b1fddf490b22b380bd454e0724b4b03e0082bdf
1 # git-gui diff viewer
2 # Copyright (C) 2006, 2007 Shawn Pearce
3
4 proc clear_diff {} {
5 global ui_diff current_diff_path current_diff_header
6 global ui_index ui_workdir
7
8 $ui_diff conf -state normal
9 $ui_diff delete 0.0 end
10 $ui_diff conf -state disabled
11
12 set current_diff_path {}
13 set current_diff_header {}
14
15 $ui_index tag remove in_diff 0.0 end
16 $ui_workdir tag remove in_diff 0.0 end
17 }
18
19 proc reshow_diff {{after {}}} {
20 global file_states file_lists
21 global current_diff_path current_diff_side
22 global ui_diff
23
24 set p $current_diff_path
25 if {$p eq {}} {
26 # No diff is being shown.
27 } elseif {$current_diff_side eq {}} {
28 clear_diff
29 } elseif {[catch {set s $file_states($p)}]
30 || [lsearch -sorted -exact $file_lists($current_diff_side) $p] == -1} {
31
32 if {[find_next_diff $current_diff_side $p {} {[^O]}]} {
33 next_diff $after
34 } else {
35 clear_diff
36 }
37 } else {
38 set save_pos [lindex [$ui_diff yview] 0]
39 show_diff $p $current_diff_side {} $save_pos $after
40 }
41 }
42
43 proc force_diff_encoding {enc} {
44 global current_diff_path
45
46 if {$current_diff_path ne {}} {
47 force_path_encoding $current_diff_path $enc
48 reshow_diff
49 }
50 }
51
52 proc handle_empty_diff {} {
53 global current_diff_path file_states file_lists
54 global diff_empty_count
55
56 set path $current_diff_path
57 set s $file_states($path)
58 if {[lindex $s 0] ne {_M} || [has_textconv $path]} return
59
60 # Prevent infinite rescan loops
61 incr diff_empty_count
62 if {$diff_empty_count > 1} return
63
64 info_popup [mc "No differences detected.
65
66 %s has no changes.
67
68 The modification date of this file was updated by another application, but the content within the file was not changed.
69
70 A rescan will be automatically started to find other files which may have the same state." [short_path $path]]
71
72 clear_diff
73 display_file $path __
74 rescan ui_ready 0
75 }
76
77 proc show_diff {path w {lno {}} {scroll_pos {}} {callback {}}} {
78 global file_states file_lists
79 global is_3way_diff is_conflict_diff diff_active repo_config
80 global ui_diff ui_index ui_workdir
81 global current_diff_path current_diff_side current_diff_header
82 global current_diff_queue
83
84 if {$diff_active || ![lock_index read]} return
85
86 clear_diff
87 if {$lno == {}} {
88 set lno [lsearch -sorted -exact $file_lists($w) $path]
89 if {$lno >= 0} {
90 incr lno
91 }
92 }
93 if {$lno >= 1} {
94 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
95 $w see $lno.0
96 }
97
98 set s $file_states($path)
99 set m [lindex $s 0]
100 set is_conflict_diff 0
101 set current_diff_path $path
102 set current_diff_side $w
103 set current_diff_queue {}
104 ui_status [mc "Loading diff of %s..." [escape_path $path]]
105
106 set cont_info [list $scroll_pos $callback]
107
108 if {[string first {U} $m] >= 0} {
109 merge_load_stages $path [list show_unmerged_diff $cont_info]
110 } elseif {$m eq {_O}} {
111 show_other_diff $path $w $m $cont_info
112 } else {
113 start_show_diff $cont_info
114 }
115 }
116
117 proc show_unmerged_diff {cont_info} {
118 global current_diff_path current_diff_side
119 global merge_stages ui_diff is_conflict_diff
120 global current_diff_queue
121
122 if {$merge_stages(2) eq {}} {
123 set is_conflict_diff 1
124 lappend current_diff_queue \
125 [list [mc "LOCAL: deleted\nREMOTE:\n"] d= \
126 [list ":1:$current_diff_path" ":3:$current_diff_path"]]
127 } elseif {$merge_stages(3) eq {}} {
128 set is_conflict_diff 1
129 lappend current_diff_queue \
130 [list [mc "REMOTE: deleted\nLOCAL:\n"] d= \
131 [list ":1:$current_diff_path" ":2:$current_diff_path"]]
132 } elseif {[lindex $merge_stages(1) 0] eq {120000}
133 || [lindex $merge_stages(2) 0] eq {120000}
134 || [lindex $merge_stages(3) 0] eq {120000}} {
135 set is_conflict_diff 1
136 lappend current_diff_queue \
137 [list [mc "LOCAL:\n"] d= \
138 [list ":1:$current_diff_path" ":2:$current_diff_path"]]
139 lappend current_diff_queue \
140 [list [mc "REMOTE:\n"] d= \
141 [list ":1:$current_diff_path" ":3:$current_diff_path"]]
142 } else {
143 start_show_diff $cont_info
144 return
145 }
146
147 advance_diff_queue $cont_info
148 }
149
150 proc advance_diff_queue {cont_info} {
151 global current_diff_queue ui_diff
152
153 set item [lindex $current_diff_queue 0]
154 set current_diff_queue [lrange $current_diff_queue 1 end]
155
156 $ui_diff conf -state normal
157 $ui_diff insert end [lindex $item 0] [lindex $item 1]
158 $ui_diff conf -state disabled
159
160 start_show_diff $cont_info [lindex $item 2]
161 }
162
163 proc show_other_diff {path w m cont_info} {
164 global file_states file_lists
165 global is_3way_diff diff_active repo_config
166 global ui_diff ui_index ui_workdir
167 global current_diff_path current_diff_side current_diff_header
168
169 # - Git won't give us the diff, there's nothing to compare to!
170 #
171 if {$m eq {_O}} {
172 set max_sz 100000
173 set type unknown
174 if {[catch {
175 set type [file type $path]
176 switch -- $type {
177 directory {
178 set type submodule
179 set content {}
180 set sz 0
181 }
182 link {
183 set content [file readlink $path]
184 set sz [string length $content]
185 }
186 file {
187 set fd [open $path r]
188 fconfigure $fd \
189 -eofchar {} \
190 -encoding [get_path_encoding $path]
191 set content [read $fd $max_sz]
192 close $fd
193 set sz [file size $path]
194 }
195 default {
196 error "'$type' not supported"
197 }
198 }
199 } err ]} {
200 set diff_active 0
201 unlock_index
202 ui_status [mc "Unable to display %s" [escape_path $path]]
203 error_popup [strcat [mc "Error loading file:"] "\n\n$err"]
204 return
205 }
206 $ui_diff conf -state normal
207 if {$type eq {submodule}} {
208 $ui_diff insert end [append \
209 "* " \
210 [mc "Git Repository (subproject)"] \
211 "\n"] d_@
212 } elseif {![catch {set type [exec file $path]}]} {
213 set n [string length $path]
214 if {[string equal -length $n $path $type]} {
215 set type [string range $type $n end]
216 regsub {^:?\s*} $type {} type
217 }
218 $ui_diff insert end "* $type\n" d_@
219 }
220 if {[string first "\0" $content] != -1} {
221 $ui_diff insert end \
222 [mc "* Binary file (not showing content)."] \
223 d_@
224 } else {
225 if {$sz > $max_sz} {
226 $ui_diff insert end [mc \
227 "* Untracked file is %d bytes.
228 * Showing only first %d bytes.
229 " $sz $max_sz] d_@
230 }
231 $ui_diff insert end $content
232 if {$sz > $max_sz} {
233 $ui_diff insert end [mc "
234 * Untracked file clipped here by %s.
235 * To see the entire file, use an external editor.
236 " [appname]] d_@
237 }
238 }
239 $ui_diff conf -state disabled
240 set diff_active 0
241 unlock_index
242 set scroll_pos [lindex $cont_info 0]
243 if {$scroll_pos ne {}} {
244 update
245 $ui_diff yview moveto $scroll_pos
246 }
247 ui_ready
248 set callback [lindex $cont_info 1]
249 if {$callback ne {}} {
250 eval $callback
251 }
252 return
253 }
254 }
255
256 proc get_conflict_marker_size {path} {
257 set size 7
258 catch {
259 set fd_rc [eval [list git_read check-attr "conflict-marker-size" -- $path]]
260 set ret [gets $fd_rc line]
261 close $fd_rc
262 if {$ret > 0} {
263 regexp {.*: conflict-marker-size: (\d+)$} $line line size
264 }
265 }
266 return $size
267 }
268
269 proc start_show_diff {cont_info {add_opts {}}} {
270 global file_states file_lists
271 global is_3way_diff is_submodule_diff diff_active repo_config
272 global ui_diff ui_index ui_workdir
273 global current_diff_path current_diff_side current_diff_header
274
275 set path $current_diff_path
276 set w $current_diff_side
277
278 set s $file_states($path)
279 set m [lindex $s 0]
280 set is_3way_diff 0
281 set is_submodule_diff 0
282 set diff_active 1
283 set current_diff_header {}
284 set conflict_size [get_conflict_marker_size $path]
285
286 set cmd [list]
287 if {$w eq $ui_index} {
288 lappend cmd diff-index
289 lappend cmd --cached
290 } elseif {$w eq $ui_workdir} {
291 if {[string first {U} $m] >= 0} {
292 lappend cmd diff
293 } else {
294 lappend cmd diff-files
295 }
296 }
297 if {![is_config_false gui.textconv] && [git-version >= 1.6.1]} {
298 lappend cmd --textconv
299 }
300
301 if {[string match {160000 *} [lindex $s 2]]
302 || [string match {160000 *} [lindex $s 3]]} {
303 set is_submodule_diff 1
304
305 if {[git-version >= "1.6.6"]} {
306 lappend cmd --submodule
307 }
308 }
309
310 lappend cmd -p
311 lappend cmd --color
312 if {$repo_config(gui.diffcontext) >= 1} {
313 lappend cmd "-U$repo_config(gui.diffcontext)"
314 }
315 if {$w eq $ui_index} {
316 lappend cmd [PARENT]
317 }
318 if {$add_opts ne {}} {
319 eval lappend cmd $add_opts
320 } else {
321 lappend cmd --
322 lappend cmd $path
323 }
324
325 if {$is_submodule_diff && [git-version < "1.6.6"]} {
326 if {$w eq $ui_index} {
327 set cmd [list submodule summary --cached -- $path]
328 } else {
329 set cmd [list submodule summary --files -- $path]
330 }
331 }
332
333 if {[catch {set fd [eval git_read --nice $cmd]} err]} {
334 set diff_active 0
335 unlock_index
336 ui_status [mc "Unable to display %s" [escape_path $path]]
337 error_popup [strcat [mc "Error loading diff:"] "\n\n$err"]
338 return
339 }
340
341 set ::current_diff_inheader 1
342 fconfigure $fd \
343 -blocking 0 \
344 -encoding [get_path_encoding $path] \
345 -translation lf
346 fileevent $fd readable [list read_diff $fd $conflict_size $cont_info]
347 }
348
349 proc parse_color_line {line} {
350 set start 0
351 set result ""
352 set markup [list]
353 set regexp {\033\[((?:\d+;)*\d+)?m}
354 set need_reset 0
355 while {[regexp -indices -start $start $regexp $line match code]} {
356 foreach {begin end} $match break
357 append result [string range $line $start [expr {$begin - 1}]]
358 set pos [string length $result]
359 set col [eval [linsert $code 0 string range $line]]
360 set start [incr end]
361 if {$col eq "0" || $col eq ""} {
362 if {!$need_reset} continue
363 set need_reset 0
364 } else {
365 set need_reset 1
366 }
367 lappend markup $pos $col
368 }
369 append result [string range $line $start end]
370 if {[llength $markup] < 4} {set markup {}}
371 return [list $result $markup]
372 }
373
374 proc read_diff {fd conflict_size cont_info} {
375 global ui_diff diff_active is_submodule_diff
376 global is_3way_diff is_conflict_diff current_diff_header
377 global current_diff_queue
378 global diff_empty_count
379
380 $ui_diff conf -state normal
381 while {[gets $fd line] >= 0} {
382 foreach {line markup} [parse_color_line $line] break
383 set line [string map {\033 ^} $line]
384
385 # -- Cleanup uninteresting diff header lines.
386 #
387 if {$::current_diff_inheader} {
388 if { [string match {diff --git *} $line]
389 || [string match {diff --cc *} $line]
390 || [string match {diff --combined *} $line]
391 || [string match {--- *} $line]
392 || [string match {+++ *} $line]} {
393 append current_diff_header $line "\n"
394 continue
395 }
396 }
397 if {[string match {index *} $line]} continue
398 if {$line eq {deleted file mode 120000}} {
399 set line "deleted symlink"
400 }
401 set ::current_diff_inheader 0
402
403 # -- Automatically detect if this is a 3 way diff.
404 #
405 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
406
407 if {[string match {mode *} $line]
408 || [string match {new file *} $line]
409 || [regexp {^(old|new) mode *} $line]
410 || [string match {deleted file *} $line]
411 || [string match {deleted symlink} $line]
412 || [string match {Binary files * and * differ} $line]
413 || $line eq {\ No newline at end of file}
414 || [regexp {^\* Unmerged path } $line]} {
415 set tags {}
416 } elseif {$is_3way_diff} {
417 set op [string range $line 0 1]
418 switch -- $op {
419 { } {set tags {}}
420 {@@} {set tags d_@}
421 { +} {set tags d_s+}
422 { -} {set tags d_s-}
423 {+ } {set tags d_+s}
424 {- } {set tags d_-s}
425 {--} {set tags d_--}
426 {++} {
427 set regexp [string map [list %conflict_size $conflict_size]\
428 {^\+\+([<>=]){%conflict_size}(?: |$)}]
429 if {[regexp $regexp $line _g op]} {
430 set is_conflict_diff 1
431 set line [string replace $line 0 1 { }]
432 set tags d$op
433 } else {
434 set tags d_++
435 }
436 }
437 default {
438 puts "error: Unhandled 3 way diff marker: {$op}"
439 set tags {}
440 }
441 }
442 } elseif {$is_submodule_diff} {
443 if {$line == ""} continue
444 if {[regexp {^Submodule } $line]} {
445 set tags d_@
446 } elseif {[regexp {^\* } $line]} {
447 set line [string replace $line 0 1 {Submodule }]
448 set tags d_@
449 } else {
450 set op [string range $line 0 2]
451 switch -- $op {
452 { <} {set tags d_-}
453 { >} {set tags d_+}
454 { W} {set tags {}}
455 default {
456 puts "error: Unhandled submodule diff marker: {$op}"
457 set tags {}
458 }
459 }
460 }
461 } else {
462 set op [string index $line 0]
463 switch -- $op {
464 { } {set tags {}}
465 {@} {set tags d_@}
466 {-} {set tags d_-}
467 {+} {
468 set regexp [string map [list %conflict_size $conflict_size]\
469 {^\+([<>=]){%conflict_size}(?: |$)}]
470 if {[regexp $regexp $line _g op]} {
471 set is_conflict_diff 1
472 set tags d$op
473 } else {
474 set tags d_+
475 }
476 }
477 default {
478 puts "error: Unhandled 2 way diff marker: {$op}"
479 set tags {}
480 }
481 }
482 }
483 set mark [$ui_diff index "end - 1 line linestart"]
484 $ui_diff insert end $line $tags
485 if {[string index $line end] eq "\r"} {
486 $ui_diff tag add d_cr {end - 2c}
487 }
488 $ui_diff insert end "\n" $tags
489
490 foreach {posbegin colbegin posend colend} $markup {
491 set prefix clr
492 foreach style [split $colbegin ";"] {
493 if {$style eq "7"} {append prefix i; continue}
494 if {$style < 30 || $style > 47} {continue}
495 set a "$mark linestart + $posbegin chars"
496 set b "$mark linestart + $posend chars"
497 catch {$ui_diff tag add $prefix$style $a $b}
498 }
499 }
500 }
501 $ui_diff conf -state disabled
502
503 if {[eof $fd]} {
504 close $fd
505
506 if {$current_diff_queue ne {}} {
507 advance_diff_queue $cont_info
508 return
509 }
510
511 set diff_active 0
512 unlock_index
513 set scroll_pos [lindex $cont_info 0]
514 if {$scroll_pos ne {}} {
515 update
516 $ui_diff yview moveto $scroll_pos
517 }
518 ui_ready
519
520 if {[$ui_diff index end] eq {2.0}} {
521 handle_empty_diff
522 } else {
523 set diff_empty_count 0
524 }
525
526 set callback [lindex $cont_info 1]
527 if {$callback ne {}} {
528 eval $callback
529 }
530 }
531 }
532
533 proc apply_hunk {x y} {
534 global current_diff_path current_diff_header current_diff_side
535 global ui_diff ui_index file_states
536
537 if {$current_diff_path eq {} || $current_diff_header eq {}} return
538 if {![lock_index apply_hunk]} return
539
540 set apply_cmd {apply --cached --whitespace=nowarn}
541 set mi [lindex $file_states($current_diff_path) 0]
542 if {$current_diff_side eq $ui_index} {
543 set failed_msg [mc "Failed to unstage selected hunk."]
544 lappend apply_cmd --reverse
545 if {[string index $mi 0] ne {M}} {
546 unlock_index
547 return
548 }
549 } else {
550 set failed_msg [mc "Failed to stage selected hunk."]
551 if {[string index $mi 1] ne {M}} {
552 unlock_index
553 return
554 }
555 }
556
557 set s_lno [lindex [split [$ui_diff index @$x,$y] .] 0]
558 set s_lno [$ui_diff search -backwards -regexp ^@@ $s_lno.0 0.0]
559 if {$s_lno eq {}} {
560 unlock_index
561 return
562 }
563
564 set e_lno [$ui_diff search -forwards -regexp ^@@ "$s_lno + 1 lines" end]
565 if {$e_lno eq {}} {
566 set e_lno end
567 }
568
569 if {[catch {
570 set enc [get_path_encoding $current_diff_path]
571 set p [eval git_write $apply_cmd]
572 fconfigure $p -translation binary -encoding $enc
573 puts -nonewline $p $current_diff_header
574 puts -nonewline $p [$ui_diff get $s_lno $e_lno]
575 close $p} err]} {
576 error_popup [append $failed_msg "\n\n$err"]
577 unlock_index
578 return
579 }
580
581 $ui_diff conf -state normal
582 $ui_diff delete $s_lno $e_lno
583 $ui_diff conf -state disabled
584
585 if {[$ui_diff get 1.0 end] eq "\n"} {
586 set o _
587 } else {
588 set o ?
589 }
590
591 if {$current_diff_side eq $ui_index} {
592 set mi ${o}M
593 } elseif {[string index $mi 0] eq {_}} {
594 set mi M$o
595 } else {
596 set mi ?$o
597 }
598 unlock_index
599 display_file $current_diff_path $mi
600 # This should trigger shift to the next changed file
601 if {$o eq {_}} {
602 reshow_diff
603 }
604 }
605
606 proc apply_range_or_line {x y} {
607 global current_diff_path current_diff_header current_diff_side
608 global ui_diff ui_index file_states
609
610 set selected [$ui_diff tag nextrange sel 0.0]
611
612 if {$selected == {}} {
613 set first [$ui_diff index "@$x,$y"]
614 set last $first
615 } else {
616 set first [lindex $selected 0]
617 set last [lindex $selected 1]
618 }
619
620 set first_l [$ui_diff index "$first linestart"]
621 set last_l [$ui_diff index "$last lineend"]
622
623 if {$current_diff_path eq {} || $current_diff_header eq {}} return
624 if {![lock_index apply_hunk]} return
625
626 set apply_cmd {apply --cached --whitespace=nowarn}
627 set mi [lindex $file_states($current_diff_path) 0]
628 if {$current_diff_side eq $ui_index} {
629 set failed_msg [mc "Failed to unstage selected line."]
630 set to_context {+}
631 lappend apply_cmd --reverse
632 if {[string index $mi 0] ne {M}} {
633 unlock_index
634 return
635 }
636 } else {
637 set failed_msg [mc "Failed to stage selected line."]
638 set to_context {-}
639 if {[string index $mi 1] ne {M}} {
640 unlock_index
641 return
642 }
643 }
644
645 set wholepatch {}
646
647 while {$first_l < $last_l} {
648 set i_l [$ui_diff search -backwards -regexp ^@@ $first_l 0.0]
649 if {$i_l eq {}} {
650 # If there's not a @@ above, then the selected range
651 # must have come before the first_l @@
652 set i_l [$ui_diff search -regexp ^@@ $first_l $last_l]
653 }
654 if {$i_l eq {}} {
655 unlock_index
656 return
657 }
658 # $i_l is now at the beginning of a line
659
660 # pick start line number from hunk header
661 set hh [$ui_diff get $i_l "$i_l + 1 lines"]
662 set hh [lindex [split $hh ,] 0]
663 set hln [lindex [split $hh -] 1]
664
665 # There is a special situation to take care of. Consider this
666 # hunk:
667 #
668 # @@ -10,4 +10,4 @@
669 # context before
670 # -old 1
671 # -old 2
672 # +new 1
673 # +new 2
674 # context after
675 #
676 # We used to keep the context lines in the order they appear in
677 # the hunk. But then it is not possible to correctly stage only
678 # "-old 1" and "+new 1" - it would result in this staged text:
679 #
680 # context before
681 # old 2
682 # new 1
683 # context after
684 #
685 # (By symmetry it is not possible to *un*stage "old 2" and "new
686 # 2".)
687 #
688 # We resolve the problem by introducing an asymmetry, namely,
689 # when a "+" line is *staged*, it is moved in front of the
690 # context lines that are generated from the "-" lines that are
691 # immediately before the "+" block. That is, we construct this
692 # patch:
693 #
694 # @@ -10,4 +10,5 @@
695 # context before
696 # +new 1
697 # old 1
698 # old 2
699 # context after
700 #
701 # But we do *not* treat "-" lines that are *un*staged in a
702 # special way.
703 #
704 # With this asymmetry it is possible to stage the change "old
705 # 1" -> "new 1" directly, and to stage the change "old 2" ->
706 # "new 2" by first staging the entire hunk and then unstaging
707 # the change "old 1" -> "new 1".
708 #
709 # Applying multiple lines adds complexity to the special
710 # situation. The pre_context must be moved after the entire
711 # first block of consecutive staged "+" lines, so that
712 # staging both additions gives the following patch:
713 #
714 # @@ -10,4 +10,6 @@
715 # context before
716 # +new 1
717 # +new 2
718 # old 1
719 # old 2
720 # context after
721
722 # This is non-empty if and only if we are _staging_ changes;
723 # then it accumulates the consecutive "-" lines (after
724 # converting them to context lines) in order to be moved after
725 # "+" change lines.
726 set pre_context {}
727
728 set n 0
729 set m 0
730 set i_l [$ui_diff index "$i_l + 1 lines"]
731 set patch {}
732 while {[$ui_diff compare $i_l < "end - 1 chars"] &&
733 [$ui_diff get $i_l "$i_l + 2 chars"] ne {@@}} {
734 set next_l [$ui_diff index "$i_l + 1 lines"]
735 set c1 [$ui_diff get $i_l]
736 if {[$ui_diff compare $first_l <= $i_l] &&
737 [$ui_diff compare $i_l < $last_l] &&
738 ($c1 eq {-} || $c1 eq {+})} {
739 # a line to stage/unstage
740 set ln [$ui_diff get $i_l $next_l]
741 if {$c1 eq {-}} {
742 set n [expr $n+1]
743 set patch "$patch$pre_context$ln"
744 set pre_context {}
745 } else {
746 set m [expr $m+1]
747 set patch "$patch$ln"
748 }
749 } elseif {$c1 ne {-} && $c1 ne {+}} {
750 # context line
751 set ln [$ui_diff get $i_l $next_l]
752 set patch "$patch$pre_context$ln"
753 set n [expr $n+1]
754 set m [expr $m+1]
755 set pre_context {}
756 } elseif {$c1 eq $to_context} {
757 # turn change line into context line
758 set ln [$ui_diff get "$i_l + 1 chars" $next_l]
759 if {$c1 eq {-}} {
760 set pre_context "$pre_context $ln"
761 } else {
762 set patch "$patch $ln"
763 }
764 set n [expr $n+1]
765 set m [expr $m+1]
766 } else {
767 # a change in the opposite direction of
768 # to_context which is outside the range of
769 # lines to apply.
770 set patch "$patch$pre_context"
771 set pre_context {}
772 }
773 set i_l $next_l
774 }
775 set patch "$patch$pre_context"
776 set wholepatch "$wholepatch@@ -$hln,$n +$hln,$m @@\n$patch"
777 set first_l [$ui_diff index "$next_l + 1 lines"]
778 }
779
780 if {[catch {
781 set enc [get_path_encoding $current_diff_path]
782 set p [eval git_write $apply_cmd]
783 fconfigure $p -translation binary -encoding $enc
784 puts -nonewline $p $current_diff_header
785 puts -nonewline $p $wholepatch
786 close $p} err]} {
787 error_popup [append $failed_msg "\n\n$err"]
788 }
789
790 unlock_index
791 }
Michael J Gruber's git tree