git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]annotate                * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef],
 216     "annotate" => [\$annotate, undef]
 217 );
 218
 219 my %config_settings = (
 220     "smtpserver" => \$smtp_server,
 221     "smtpserverport" => \$smtp_server_port,
 222     "smtpserveroption" => \@smtp_server_options,
 223     "smtpuser" => \$smtp_authuser,
 224     "smtppass" => \$smtp_authpass,
 225     "smtpdomain" => \$smtp_domain,
 226     "to" => \@initial_to,
 227     "tocmd" => \$to_cmd,
 228     "cc" => \@initial_cc,
 229     "cccmd" => \$cc_cmd,
 230     "aliasfiletype" => \$aliasfiletype,
 231     "bcc" => \@bcclist,
 232     "suppresscc" => \@suppress_cc,
 233     "envelopesender" => \$envelope_sender,
 234     "confirm"   => \$confirm,
 235     "from" => \$sender,
 236     "assume8bitencoding" => \$auto_8bit_encoding,
 237     "composeencoding" => \$compose_encoding,
 238 );
 239
 240 my %config_path_settings = (
 241     "aliasesfile" => \@alias_files,
 242 );
 243
 244 # Help users prepare for 1.7.0
 245 sub chain_reply_to {
 246         if (defined $chain_reply_to &&
 247             $chain_reply_to eq $not_set_by_user) {
 248                 print STDERR
 249                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 250                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 251                     "you want to keep --chain-reply-to as your default.\n";
 252                 $chain_reply_to = 0;
 253         }
 254         return $chain_reply_to;
 255 }
 256
 257 # Handle Uncouth Termination
 258 sub signal_handler {
 259
 260         # Make text normal
 261         print color("reset"), "\n";
 262
 263         # SMTP password masked
 264         system "stty echo";
 265
 266         # tmp files from --compose
 267         if (defined $compose_filename) {
 268                 if (-e $compose_filename) {
 269                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 270                 }
 271                 if (-e ($compose_filename . ".final")) {
 272                         print "'$compose_filename.final' contains the composed email.\n"
 273                 }
 274         }
 275
 276         exit;
 277 };
 278
 279 $SIG{TERM} = \&signal_handler;
 280 $SIG{INT}  = \&signal_handler;
 281
 282 # Begin by accumulating all the variables (defined above), that we will end up
 283 # needing, first, from the command line:
 284
 285 my $help;
 286 my $rc = GetOptions("h" => \$help,
 287                     "sender|from=s" => \$sender,
 288                     "in-reply-to=s" => \$initial_reply_to,
 289                     "subject=s" => \$initial_subject,
 290                     "to=s" => \@initial_to,
 291                     "to-cmd=s" => \$to_cmd,
 292                     "no-to" => \$no_to,
 293                     "cc=s" => \@initial_cc,
 294                     "no-cc" => \$no_cc,
 295                     "bcc=s" => \@bcclist,
 296                     "no-bcc" => \$no_bcc,
 297                     "chain-reply-to!" => \$chain_reply_to,
 298                     "smtp-server=s" => \$smtp_server,
 299                     "smtp-server-option=s" => \@smtp_server_options,
 300                     "smtp-server-port=s" => \$smtp_server_port,
 301                     "smtp-user=s" => \$smtp_authuser,
 302                     "smtp-pass:s" => \$smtp_authpass,
 303                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 304                     "smtp-encryption=s" => \$smtp_encryption,
 305                     "smtp-debug:i" => \$debug_net_smtp,
 306                     "smtp-domain:s" => \$smtp_domain,
 307                     "identity=s" => \$identity,
 308                     "annotate!" => \$annotate,
 309                     "compose" => \$compose,
 310                     "quiet" => \$quiet,
 311                     "cc-cmd=s" => \$cc_cmd,
 312                     "suppress-from!" => \$suppress_from,
 313                     "suppress-cc=s" => \@suppress_cc,
 314                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 315                     "confirm=s" => \$confirm,
 316                     "dry-run" => \$dry_run,
 317                     "envelope-sender=s" => \$envelope_sender,
 318                     "thread!" => \$thread,
 319                     "validate!" => \$validate,
 320                     "format-patch!" => \$format_patch,
 321                     "8bit-encoding=s" => \$auto_8bit_encoding,
 322                     "compose-encoding=s" => \$compose_encoding,
 323                     "force" => \$force,
 324          );
 325
 326 usage() if $help;
 327 unless ($rc) {
 328     usage();
 329 }
 330
 331 die "Cannot run git format-patch from outside a repository\n"
 332         if $format_patch and not $repo;
 333
 334 # Now, let's fill any that aren't set in with defaults:
 335
 336 sub read_config {
 337         my ($prefix) = @_;
 338
 339         foreach my $setting (keys %config_bool_settings) {
 340                 my $target = $config_bool_settings{$setting}->[0];
 341                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 342         }
 343
 344         foreach my $setting (keys %config_path_settings) {
 345                 my $target = $config_path_settings{$setting};
 346                 if (ref($target) eq "ARRAY") {
 347                         unless (@$target) {
 348                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 349                                 @$target = @values if (@values && defined $values[0]);
 350                         }
 351                 }
 352                 else {
 353                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 354                 }
 355         }
 356
 357         foreach my $setting (keys %config_settings) {
 358                 my $target = $config_settings{$setting};
 359                 next if $setting eq "to" and defined $no_to;
 360                 next if $setting eq "cc" and defined $no_cc;
 361                 next if $setting eq "bcc" and defined $no_bcc;
 362                 if (ref($target) eq "ARRAY") {
 363                         unless (@$target) {
 364                                 my @values = Git::config(@repo, "$prefix.$setting");
 365                                 @$target = @values if (@values && defined $values[0]);
 366                         }
 367                 }
 368                 else {
 369                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 370                 }
 371         }
 372
 373         if (!defined $smtp_encryption) {
 374                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 375                 if (defined $enc) {
 376                         $smtp_encryption = $enc;
 377                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 378                         $smtp_encryption = 'ssl';
 379                 }
 380         }
 381 }
 382
 383 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 384 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 385 read_config("sendemail.$identity") if (defined $identity);
 386 read_config("sendemail");
 387
 388 # fall back on builtin bool defaults
 389 foreach my $setting (values %config_bool_settings) {
 390         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 391 }
 392
 393 # 'default' encryption is none -- this only prevents a warning
 394 $smtp_encryption = '' unless (defined $smtp_encryption);
 395
 396 # Set CC suppressions
 397 my(%suppress_cc);
 398 if (@suppress_cc) {
 399         foreach my $entry (@suppress_cc) {
 400                 die "Unknown --suppress-cc field: '$entry'\n"
 401                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 402                 $suppress_cc{$entry} = 1;
 403         }
 404 }
 405
 406 if ($suppress_cc{'all'}) {
 407         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 408                 $suppress_cc{$entry} = 1;
 409         }
 410         delete $suppress_cc{'all'};
 411 }
 412
 413 # If explicit old-style ones are specified, they trump --suppress-cc.
 414 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 415 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 416
 417 if ($suppress_cc{'body'}) {
 418         foreach my $entry (qw (sob bodycc)) {
 419                 $suppress_cc{$entry} = 1;
 420         }
 421         delete $suppress_cc{'body'};
 422 }
 423
 424 # Set confirm's default value
 425 my $confirm_unconfigured = !defined $confirm;
 426 if ($confirm_unconfigured) {
 427         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 428 };
 429 die "Unknown --confirm setting: '$confirm'\n"
 430         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 431
 432 # Debugging, print out the suppressions.
 433 if (0) {
 434         print "suppressions:\n";
 435         foreach my $entry (keys %suppress_cc) {
 436                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 437         }
 438 }
 439
 440 my ($repoauthor, $repocommitter);
 441 ($repoauthor) = Git::ident_person(@repo, 'author');
 442 ($repocommitter) = Git::ident_person(@repo, 'committer');
 443
 444 # Verify the user input
 445
 446 foreach my $entry (@initial_to) {
 447         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 448 }
 449
 450 foreach my $entry (@initial_cc) {
 451         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 452 }
 453
 454 foreach my $entry (@bcclist) {
 455         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 456 }
 457
 458 sub parse_address_line {
 459         if ($have_mail_address) {
 460                 return map { $_->format } Mail::Address->parse($_[0]);
 461         } else {
 462                 return split_addrs($_[0]);
 463         }
 464 }
 465
 466 sub split_addrs {
 467         return quotewords('\s*,\s*', 1, @_);
 468 }
 469
 470 my %aliases;
 471 my %parse_alias = (
 472         # multiline formats can be supported in the future
 473         mutt => sub { my $fh = shift; while (<$fh>) {
 474                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 475                         my ($alias, $addr) = ($1, $2);
 476                         $addr =~ s/#.*$//; # mutt allows # comments
 477                          # commas delimit multiple addresses
 478                         $aliases{$alias} = [ split_addrs($addr) ];
 479                 }}},
 480         mailrc => sub { my $fh = shift; while (<$fh>) {
 481                 if (/^alias\s+(\S+)\s+(.*)$/) {
 482                         # spaces delimit multiple addresses
 483                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 484                 }}},
 485         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 486                 for (my $x = ''; defined($x); $x = $_) {
 487                         chomp $x;
 488                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 489                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 490                         $aliases{$1} = [ split_addrs($2) ];
 491                 }},
 492         elm => sub  { my $fh = shift;
 493                       while (<$fh>) {
 494                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 495                               my ($alias, $addr) = ($1, $2);
 496                                $aliases{$alias} = [ split_addrs($addr) ];
 497                           }
 498                       } },
 499
 500         gnus => sub { my $fh = shift; while (<$fh>) {
 501                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 502                         $aliases{$1} = [ $2 ];
 503                 }}}
 504 );
 505
 506 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 507         foreach my $file (@alias_files) {
 508                 open my $fh, '<', $file or die "opening $file: $!\n";
 509                 $parse_alias{$aliasfiletype}->($fh);
 510                 close $fh;
 511         }
 512 }
 513
 514 ($sender) = expand_aliases($sender) if defined $sender;
 515
 516 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 517 # $f is a revision list specification to be passed to format-patch.
 518 sub is_format_patch_arg {
 519         return unless $repo;
 520         my $f = shift;
 521         try {
 522                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 523                 if (defined($format_patch)) {
 524                         return $format_patch;
 525                 }
 526                 die(<<EOF);
 527 File '$f' exists but it could also be the range of commits
 528 to produce patches for.  Please disambiguate by...
 529
 530     * Saying "./$f" if you mean a file; or
 531     * Giving --format-patch option if you mean a range.
 532 EOF
 533         } catch Git::Error::Command with {
 534                 # Not a valid revision.  Treat it as a filename.
 535                 return 0;
 536         }
 537 }
 538
 539 # Now that all the defaults are set, process the rest of the command line
 540 # arguments and collect up the files that need to be processed.
 541 my @rev_list_opts;
 542 while (defined(my $f = shift @ARGV)) {
 543         if ($f eq "--") {
 544                 push @rev_list_opts, "--", @ARGV;
 545                 @ARGV = ();
 546         } elsif (-d $f and !is_format_patch_arg($f)) {
 547                 opendir my $dh, $f
 548                         or die "Failed to opendir $f: $!";
 549
 550                 push @files, grep { -f $_ } map { catfile($f, $_) }
 551                                 sort readdir $dh;
 552                 closedir $dh;
 553         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 554                 push @files, $f;
 555         } else {
 556                 push @rev_list_opts, $f;
 557         }
 558 }
 559
 560 if (@rev_list_opts) {
 561         die "Cannot run git format-patch from outside a repository\n"
 562                 unless $repo;
 563         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 564 }
 565
 566 if ($validate) {
 567         foreach my $f (@files) {
 568                 unless (-p $f) {
 569                         my $error = validate_patch($f);
 570                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 571                 }
 572         }
 573 }
 574
 575 if (@files) {
 576         unless ($quiet) {
 577                 print $_,"\n" for (@files);
 578         }
 579 } else {
 580         print STDERR "\nNo patch files specified!\n\n";
 581         usage();
 582 }
 583
 584 sub get_patch_subject {
 585         my $fn = shift;
 586         open (my $fh, '<', $fn);
 587         while (my $line = <$fh>) {
 588                 next unless ($line =~ /^Subject: (.*)$/);
 589                 close $fh;
 590                 return "GIT: $1\n";
 591         }
 592         close $fh;
 593         die "No subject line in $fn ?";
 594 }
 595
 596 if ($compose) {
 597         # Note that this does not need to be secure, but we will make a small
 598         # effort to have it be unique
 599         $compose_filename = ($repo ?
 600                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 601                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 602         open my $c, ">", $compose_filename
 603                 or die "Failed to open for writing $compose_filename: $!";
 604
 605
 606         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 607         my $tpl_subject = $initial_subject || '';
 608         my $tpl_reply_to = $initial_reply_to || '';
 609
 610         print $c <<EOT;
 611 From $tpl_sender # This line is ignored.
 612 GIT: Lines beginning in "GIT:" will be removed.
 613 GIT: Consider including an overall diffstat or table of contents
 614 GIT: for the patch you are writing.
 615 GIT:
 616 GIT: Clear the body content if you don't wish to send a summary.
 617 From: $tpl_sender
 618 Subject: $tpl_subject
 619 In-Reply-To: $tpl_reply_to
 620
 621 EOT
 622         for my $f (@files) {
 623                 print $c get_patch_subject($f);
 624         }
 625         close $c;
 626
 627         if ($annotate) {
 628                 do_edit($compose_filename, @files);
 629         } else {
 630                 do_edit($compose_filename);
 631         }
 632
 633         open my $c2, ">", $compose_filename . ".final"
 634                 or die "Failed to open $compose_filename.final : " . $!;
 635
 636         open $c, "<", $compose_filename
 637                 or die "Failed to open $compose_filename : " . $!;
 638
 639         my $need_8bit_cte = file_has_nonascii($compose_filename);
 640         my $in_body = 0;
 641         my $summary_empty = 1;
 642         if (!defined $compose_encoding) {
 643                 $compose_encoding = "UTF-8";
 644         }
 645         while(<$c>) {
 646                 next if m/^GIT:/;
 647                 if ($in_body) {
 648                         $summary_empty = 0 unless (/^\n$/);
 649                 } elsif (/^\n$/) {
 650                         $in_body = 1;
 651                         if ($need_8bit_cte) {
 652                                 print $c2 "MIME-Version: 1.0\n",
 653                                          "Content-Type: text/plain; ",
 654                                            "charset=$compose_encoding\n",
 655                                          "Content-Transfer-Encoding: 8bit\n";
 656                         }
 657                 } elsif (/^MIME-Version:/i) {
 658                         $need_8bit_cte = 0;
 659                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 660                         $initial_subject = $1;
 661                         my $subject = $initial_subject;
 662                         $_ = "Subject: " .
 663                                 quote_subject($subject, $compose_encoding) .
 664                                 "\n";
 665                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 666                         $initial_reply_to = $1;
 667                         next;
 668                 } elsif (/^From:\s*(.+)\s*$/i) {
 669                         $sender = $1;
 670                         next;
 671                 } elsif (/^(?:To|Cc|Bcc):/i) {
 672                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 673                         next;
 674                 }
 675                 print $c2 $_;
 676         }
 677         close $c;
 678         close $c2;
 679
 680         if ($summary_empty) {
 681                 print "Summary email is empty, skipping it\n";
 682                 $compose = -1;
 683         }
 684 } elsif ($annotate) {
 685         do_edit(@files);
 686 }
 687
 688 sub ask {
 689         my ($prompt, %arg) = @_;
 690         my $valid_re = $arg{valid_re};
 691         my $default = $arg{default};
 692         my $confirm_only = $arg{confirm_only};
 693         my $resp;
 694         my $i = 0;
 695         return defined $default ? $default : undef
 696                 unless defined $term->IN and defined fileno($term->IN) and
 697                        defined $term->OUT and defined fileno($term->OUT);
 698         while ($i++ < 10) {
 699                 $resp = $term->readline($prompt);
 700                 if (!defined $resp) { # EOF
 701                         print "\n";
 702                         return defined $default ? $default : undef;
 703                 }
 704                 if ($resp eq '' and defined $default) {
 705                         return $default;
 706                 }
 707                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 708                         return $resp;
 709                 }
 710                 if ($confirm_only) {
 711                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 712                         if (defined $yesno && $yesno =~ /y/i) {
 713                                 return $resp;
 714                         }
 715                 }
 716         }
 717         return;
 718 }
 719
 720 my %broken_encoding;
 721
 722 sub file_declares_8bit_cte {
 723         my $fn = shift;
 724         open (my $fh, '<', $fn);
 725         while (my $line = <$fh>) {
 726                 last if ($line =~ /^$/);
 727                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 728         }
 729         close $fh;
 730         return 0;
 731 }
 732
 733 foreach my $f (@files) {
 734         next unless (body_or_subject_has_nonascii($f)
 735                      && !file_declares_8bit_cte($f));
 736         $broken_encoding{$f} = 1;
 737 }
 738
 739 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 740         print "The following files are 8bit, but do not declare " .
 741                 "a Content-Transfer-Encoding.\n";
 742         foreach my $f (sort keys %broken_encoding) {
 743                 print "    $f\n";
 744         }
 745         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 746                                   default => "UTF-8");
 747 }
 748
 749 if (!$force) {
 750         for my $f (@files) {
 751                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 752                         die "Refusing to send because the patch\n\t$f\n"
 753                                 . "has the template subject '*** SUBJECT HERE ***'. "
 754                                 . "Pass --force if you really want to send.\n";
 755                 }
 756         }
 757 }
 758
 759 if (!defined $sender) {
 760         $sender = $repoauthor || $repocommitter || '';
 761 }
 762
 763 # $sender could be an already sanitized address
 764 # (e.g. sendemail.from could be manually sanitized by user).
 765 # But it's a no-op to run sanitize_address on an already sanitized address.
 766 $sender = sanitize_address($sender);
 767
 768 my $prompting = 0;
 769 if (!@initial_to && !defined $to_cmd) {
 770         my $to = ask("Who should the emails be sent to (if any)? ",
 771                      default => "",
 772                      valid_re => qr/\@.*\./, confirm_only => 1);
 773         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 774         $prompting++;
 775 }
 776
 777 sub expand_aliases {
 778         return map { expand_one_alias($_) } @_;
 779 }
 780
 781 my %EXPANDED_ALIASES;
 782 sub expand_one_alias {
 783         my $alias = shift;
 784         if ($EXPANDED_ALIASES{$alias}) {
 785                 die "fatal: alias '$alias' expands to itself\n";
 786         }
 787         local $EXPANDED_ALIASES{$alias} = 1;
 788         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 789 }
 790
 791 @initial_to = expand_aliases(@initial_to);
 792 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 793 @initial_cc = expand_aliases(@initial_cc);
 794 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 795 @bcclist = expand_aliases(@bcclist);
 796 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 797
 798 if ($thread && !defined $initial_reply_to && $prompting) {
 799         $initial_reply_to = ask(
 800                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 801                 default => "",
 802                 valid_re => qr/\@.*\./, confirm_only => 1);
 803 }
 804 if (defined $initial_reply_to) {
 805         $initial_reply_to =~ s/^\s*<?//;
 806         $initial_reply_to =~ s/>?\s*$//;
 807         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 808 }
 809
 810 if (!defined $smtp_server) {
 811         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 812                 if (-x $_) {
 813                         $smtp_server = $_;
 814                         last;
 815                 }
 816         }
 817         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 818 }
 819
 820 if ($compose && $compose > 0) {
 821         @files = ($compose_filename . ".final", @files);
 822 }
 823
 824 # Variables we set as part of the loop over files
 825 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 826         $needs_confirm, $message_num, $ask_default);
 827
 828 sub extract_valid_address {
 829         my $address = shift;
 830         my $local_part_regexp = qr/[^<>"\s@]+/;
 831         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 832
 833         # check for a local address:
 834         return $address if ($address =~ /^($local_part_regexp)$/);
 835
 836         $address =~ s/^\s*<(.*)>\s*$/$1/;
 837         if ($have_email_valid) {
 838                 return scalar Email::Valid->address($address);
 839         }
 840
 841         # less robust/correct than the monster regexp in Email::Valid,
 842         # but still does a 99% job, and one less dependency
 843         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 844         return;
 845 }
 846
 847 sub extract_valid_address_or_die {
 848         my $address = shift;
 849         $address = extract_valid_address($address);
 850         die "error: unable to extract a valid address from: $address\n"
 851                 if !$address;
 852         return $address;
 853 }
 854
 855 sub validate_address {
 856         my $address = shift;
 857         while (!extract_valid_address($address)) {
 858                 print STDERR "error: unable to extract a valid address from: $address\n";
 859                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 860                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 861                         default => 'q');
 862                 if (/^d/i) {
 863                         return undef;
 864                 } elsif (/^q/i) {
 865                         cleanup_compose_files();
 866                         exit(0);
 867                 }
 868                 $address = ask("Who should the email be sent to (if any)? ",
 869                         default => "",
 870                         valid_re => qr/\@.*\./, confirm_only => 1);
 871         }
 872         return $address;
 873 }
 874
 875 sub validate_address_list {
 876         return (grep { defined $_ }
 877                 map { validate_address($_) } @_);
 878 }
 879
 880 # Usually don't need to change anything below here.
 881
 882 # we make a "fake" message id by taking the current number
 883 # of seconds since the beginning of Unix time and tacking on
 884 # a random number to the end, in case we are called quicker than
 885 # 1 second since the last time we were called.
 886
 887 # We'll setup a template for the message id, using the "from" address:
 888
 889 my ($message_id_stamp, $message_id_serial);
 890 sub make_message_id {
 891         my $uniq;
 892         if (!defined $message_id_stamp) {
 893                 $message_id_stamp = sprintf("%s-%s", time, $$);
 894                 $message_id_serial = 0;
 895         }
 896         $message_id_serial++;
 897         $uniq = "$message_id_stamp-$message_id_serial";
 898
 899         my $du_part;
 900         for ($sender, $repocommitter, $repoauthor) {
 901                 $du_part = extract_valid_address(sanitize_address($_));
 902                 last if (defined $du_part and $du_part ne '');
 903         }
 904         if (not defined $du_part or $du_part eq '') {
 905                 require Sys::Hostname;
 906                 $du_part = 'user@' . Sys::Hostname::hostname();
 907         }
 908         my $message_id_template = "<%s-git-send-email-%s>";
 909         $message_id = sprintf($message_id_template, $uniq, $du_part);
 910         #print "new message id = $message_id\n"; # Was useful for debugging
 911 }
 912
 913
 914
 915 $time = time - scalar $#files;
 916
 917 sub unquote_rfc2047 {
 918         local ($_) = @_;
 919         my $encoding;
 920         s{=\?([^?]+)\?q\?(.*?)\?=}{
 921                 $encoding = $1;
 922                 my $e = $2;
 923                 $e =~ s/_/ /g;
 924                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 925                 $e;
 926         }eg;
 927         return wantarray ? ($_, $encoding) : $_;
 928 }
 929
 930 sub quote_rfc2047 {
 931         local $_ = shift;
 932         my $encoding = shift || 'UTF-8';
 933         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 934         s/(.*)/=\?$encoding\?q\?$1\?=/;
 935         return $_;
 936 }
 937
 938 sub is_rfc2047_quoted {
 939         my $s = shift;
 940         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 941         my $encoded_text = qr/[!->@-~]+/;
 942         length($s) <= 75 &&
 943         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 944 }
 945
 946 sub subject_needs_rfc2047_quoting {
 947         my $s = shift;
 948
 949         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 950 }
 951
 952 sub quote_subject {
 953         local $subject = shift;
 954         my $encoding = shift || 'UTF-8';
 955
 956         if (subject_needs_rfc2047_quoting($subject)) {
 957                 return quote_rfc2047($subject, $encoding);
 958         }
 959         return $subject;
 960 }
 961
 962 # use the simplest quoting being able to handle the recipient
 963 sub sanitize_address {
 964         my ($recipient) = @_;
 965
 966         # remove garbage after email address
 967         $recipient =~ s/(.*>).*$/$1/;
 968
 969         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 970
 971         if (not $recipient_name) {
 972                 return $recipient;
 973         }
 974
 975         # if recipient_name is already quoted, do nothing
 976         if (is_rfc2047_quoted($recipient_name)) {
 977                 return $recipient;
 978         }
 979
 980         # rfc2047 is needed if a non-ascii char is included
 981         if ($recipient_name =~ /[^[:ascii:]]/) {
 982                 $recipient_name =~ s/^"(.*)"$/$1/;
 983                 $recipient_name = quote_rfc2047($recipient_name);
 984         }
 985
 986         # double quotes are needed if specials or CTLs are included
 987         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 988                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 989                 $recipient_name = qq["$recipient_name"];
 990         }
 991
 992         return "$recipient_name $recipient_addr";
 993
 994 }
 995
 996 sub sanitize_address_list {
 997         return (map { sanitize_address($_) } @_);
 998 }
 999
1000 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1001 #
1002 # Tightly configured MTAa require that a caller sends a real DNS
1003 # domain name that corresponds the IP address in the HELO/EHLO
1004 # handshake. This is used to verify the connection and prevent
1005 # spammers from trying to hide their identity. If the DNS and IP don't
1006 # match, the receiveing MTA may deny the connection.
1007 #
1008 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1009 #
1010 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1011 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1012 #
1013 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1014 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1015
1016 sub valid_fqdn {
1017         my $domain = shift;
1018         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1019 }
1020
1021 sub maildomain_net {
1022         my $maildomain;
1023
1024         if (eval { require Net::Domain; 1 }) {
1025                 my $domain = Net::Domain::domainname();
1026                 $maildomain = $domain if valid_fqdn($domain);
1027         }
1028
1029         return $maildomain;
1030 }
1031
1032 sub maildomain_mta {
1033         my $maildomain;
1034
1035         if (eval { require Net::SMTP; 1 }) {
1036                 for my $host (qw(mailhost localhost)) {
1037                         my $smtp = Net::SMTP->new($host);
1038                         if (defined $smtp) {
1039                                 my $domain = $smtp->domain;
1040                                 $smtp->quit;
1041
1042                                 $maildomain = $domain if valid_fqdn($domain);
1043
1044                                 last if $maildomain;
1045                         }
1046                 }
1047         }
1048
1049         return $maildomain;
1050 }
1051
1052 sub maildomain {
1053         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1054 }
1055
1056 sub smtp_host_string {
1057         if (defined $smtp_server_port) {
1058                 return "$smtp_server:$smtp_server_port";
1059         } else {
1060                 return $smtp_server;
1061         }
1062 }
1063
1064 # Returns 1 if authentication succeeded or was not necessary
1065 # (smtp_user was not specified), and 0 otherwise.
1066
1067 sub smtp_auth_maybe {
1068         if (!defined $smtp_authuser || $auth) {
1069                 return 1;
1070         }
1071
1072         # Workaround AUTH PLAIN/LOGIN interaction defect
1073         # with Authen::SASL::Cyrus
1074         eval {
1075                 require Authen::SASL;
1076                 Authen::SASL->import(qw(Perl));
1077         };
1078
1079         # TODO: Authentication may fail not because credentials were
1080         # invalid but due to other reasons, in which we should not
1081         # reject credentials.
1082         $auth = Git::credential({
1083                 'protocol' => 'smtp',
1084                 'host' => smtp_host_string(),
1085                 'username' => $smtp_authuser,
1086                 # if there's no password, "git credential fill" will
1087                 # give us one, otherwise it'll just pass this one.
1088                 'password' => $smtp_authpass
1089         }, sub {
1090                 my $cred = shift;
1091                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1092         });
1093
1094         return $auth;
1095 }
1096
1097 # Returns 1 if the message was sent, and 0 otherwise.
1098 # In actuality, the whole program dies when there
1099 # is an error sending a message.
1100
1101 sub send_message {
1102         my @recipients = unique_email_list(@to);
1103         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1104                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1105                     }
1106                @cc);
1107         my $to = join (",\n\t", @recipients);
1108         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1109         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1110         my $date = format_2822_time($time++);
1111         my $gitversion = '@@GIT_VERSION@@';
1112         if ($gitversion =~ m/..GIT_VERSION../) {
1113             $gitversion = Git::version();
1114         }
1115
1116         my $cc = join(",\n\t", unique_email_list(@cc));
1117         my $ccline = "";
1118         if ($cc ne '') {
1119                 $ccline = "\nCc: $cc";
1120         }
1121         make_message_id() unless defined($message_id);
1122
1123         my $header = "From: $sender
1124 To: $to${ccline}
1125 Subject: $subject
1126 Date: $date
1127 Message-Id: $message_id
1128 X-Mailer: git-send-email $gitversion
1129 ";
1130         if ($reply_to) {
1131
1132                 $header .= "In-Reply-To: $reply_to\n";
1133                 $header .= "References: $references\n";
1134         }
1135         if (@xh) {
1136                 $header .= join("\n", @xh) . "\n";
1137         }
1138
1139         my @sendmail_parameters = ('-i', @recipients);
1140         my $raw_from = $sender;
1141         if (defined $envelope_sender && $envelope_sender ne "auto") {
1142                 $raw_from = $envelope_sender;
1143         }
1144         $raw_from = extract_valid_address($raw_from);
1145         unshift (@sendmail_parameters,
1146                         '-f', $raw_from) if(defined $envelope_sender);
1147
1148         if ($needs_confirm && !$dry_run) {
1149                 print "\n$header\n";
1150                 if ($needs_confirm eq "inform") {
1151                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1152                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1153                         print "    The Cc list above has been expanded by additional\n";
1154                         print "    addresses found in the patch commit message. By default\n";
1155                         print "    send-email prompts before sending whenever this occurs.\n";
1156                         print "    This behavior is controlled by the sendemail.confirm\n";
1157                         print "    configuration setting.\n";
1158                         print "\n";
1159                         print "    For additional information, run 'git send-email --help'.\n";
1160                         print "    To retain the current behavior, but squelch this message,\n";
1161                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1162                 }
1163                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1164                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1165                          default => $ask_default);
1166                 die "Send this email reply required" unless defined $_;
1167                 if (/^n/i) {
1168                         return 0;
1169                 } elsif (/^q/i) {
1170                         cleanup_compose_files();
1171                         exit(0);
1172                 } elsif (/^a/i) {
1173                         $confirm = 'never';
1174                 }
1175         }
1176
1177         unshift (@sendmail_parameters, @smtp_server_options);
1178
1179         if ($dry_run) {
1180                 # We don't want to send the email.
1181         } elsif ($smtp_server =~ m#^/#) {
1182                 my $pid = open my $sm, '|-';
1183                 defined $pid or die $!;
1184                 if (!$pid) {
1185                         exec($smtp_server, @sendmail_parameters) or die $!;
1186                 }
1187                 print $sm "$header\n$message";
1188                 close $sm or die $!;
1189         } else {
1190
1191                 if (!defined $smtp_server) {
1192                         die "The required SMTP server is not properly defined."
1193                 }
1194
1195                 if ($smtp_encryption eq 'ssl') {
1196                         $smtp_server_port ||= 465; # ssmtp
1197                         require Net::SMTP::SSL;
1198                         $smtp_domain ||= maildomain();
1199                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1200                                                       Hello => $smtp_domain,
1201                                                       Port => $smtp_server_port);
1202                 }
1203                 else {
1204                         require Net::SMTP;
1205                         $smtp_domain ||= maildomain();
1206                         $smtp ||= Net::SMTP->new(smtp_host_string(),
1207                                                  Hello => $smtp_domain,
1208                                                  Debug => $debug_net_smtp);
1209                         if ($smtp_encryption eq 'tls' && $smtp) {
1210                                 require Net::SMTP::SSL;
1211                                 $smtp->command('STARTTLS');
1212                                 $smtp->response();
1213                                 if ($smtp->code == 220) {
1214                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1215                                                 or die "STARTTLS failed! ".$smtp->message;
1216                                         $smtp_encryption = '';
1217                                         # Send EHLO again to receive fresh
1218                                         # supported commands
1219                                         $smtp->hello($smtp_domain);
1220                                 } else {
1221                                         die "Server does not support STARTTLS! ".$smtp->message;
1222                                 }
1223                         }
1224                 }
1225
1226                 if (!$smtp) {
1227                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1228                             "VALUES: server=$smtp_server ",
1229                             "encryption=$smtp_encryption ",
1230                             "hello=$smtp_domain",
1231                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1232                 }
1233
1234                 smtp_auth_maybe or die $smtp->message;
1235
1236                 $smtp->mail( $raw_from ) or die $smtp->message;
1237                 $smtp->to( @recipients ) or die $smtp->message;
1238                 $smtp->data or die $smtp->message;
1239                 $smtp->datasend("$header\n$message") or die $smtp->message;
1240                 $smtp->dataend() or die $smtp->message;
1241                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1242         }
1243         if ($quiet) {
1244                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1245         } else {
1246                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1247                 if ($smtp_server !~ m#^/#) {
1248                         print "Server: $smtp_server\n";
1249                         print "MAIL FROM:<$raw_from>\n";
1250                         foreach my $entry (@recipients) {
1251                             print "RCPT TO:<$entry>\n";
1252                         }
1253                 } else {
1254                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1255                 }
1256                 print $header, "\n";
1257                 if ($smtp) {
1258                         print "Result: ", $smtp->code, ' ',
1259                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1260                 } else {
1261                         print "Result: OK\n";
1262                 }
1263         }
1264
1265         return 1;
1266 }
1267
1268 $reply_to = $initial_reply_to;
1269 $references = $initial_reply_to || '';
1270 $subject = $initial_subject;
1271 $message_num = 0;
1272
1273 foreach my $t (@files) {
1274         open my $fh, "<", $t or die "can't open file $t";
1275
1276         my $author = undef;
1277         my $sauthor = undef;
1278         my $author_encoding;
1279         my $has_content_type;
1280         my $body_encoding;
1281         @to = ();
1282         @cc = ();
1283         @xh = ();
1284         my $input_format = undef;
1285         my @header = ();
1286         $message = "";
1287         $message_num++;
1288         # First unfold multiline header fields
1289         while(<$fh>) {
1290                 last if /^\s*$/;
1291                 if (/^\s+\S/ and @header) {
1292                         chomp($header[$#header]);
1293                         s/^\s+/ /;
1294                         $header[$#header] .= $_;
1295             } else {
1296                         push(@header, $_);
1297                 }
1298         }
1299         # Now parse the header
1300         foreach(@header) {
1301                 if (/^From /) {
1302                         $input_format = 'mbox';
1303                         next;
1304                 }
1305                 chomp;
1306                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1307                         $input_format = 'mbox';
1308                 }
1309
1310                 if (defined $input_format && $input_format eq 'mbox') {
1311                         if (/^Subject:\s+(.*)$/i) {
1312                                 $subject = $1;
1313                         }
1314                         elsif (/^From:\s+(.*)$/i) {
1315                                 ($author, $author_encoding) = unquote_rfc2047($1);
1316                                 $sauthor = sanitize_address($author);
1317                                 next if $suppress_cc{'author'};
1318                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1319                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1320                                         $1, $_) unless $quiet;
1321                                 push @cc, $1;
1322                         }
1323                         elsif (/^To:\s+(.*)$/i) {
1324                                 foreach my $addr (parse_address_line($1)) {
1325                                         printf("(mbox) Adding to: %s from line '%s'\n",
1326                                                 $addr, $_) unless $quiet;
1327                                         push @to, $addr;
1328                                 }
1329                         }
1330                         elsif (/^Cc:\s+(.*)$/i) {
1331                                 foreach my $addr (parse_address_line($1)) {
1332                                         my $qaddr = unquote_rfc2047($addr);
1333                                         my $saddr = sanitize_address($qaddr);
1334                                         if ($saddr eq $sender) {
1335                                                 next if ($suppress_cc{'self'});
1336                                         } else {
1337                                                 next if ($suppress_cc{'cc'});
1338                                         }
1339                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1340                                                 $addr, $_) unless $quiet;
1341                                         push @cc, $addr;
1342                                 }
1343                         }
1344                         elsif (/^Content-type:/i) {
1345                                 $has_content_type = 1;
1346                                 if (/charset="?([^ "]+)/) {
1347                                         $body_encoding = $1;
1348                                 }
1349                                 push @xh, $_;
1350                         }
1351                         elsif (/^Message-Id: (.*)/i) {
1352                                 $message_id = $1;
1353                         }
1354                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1355                                 push @xh, $_;
1356                         }
1357
1358                 } else {
1359                         # In the traditional
1360                         # "send lots of email" format,
1361                         # line 1 = cc
1362                         # line 2 = subject
1363                         # So let's support that, too.
1364                         $input_format = 'lots';
1365                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1366                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1367                                         $_, $_) unless $quiet;
1368                                 push @cc, $_;
1369                         } elsif (!defined $subject) {
1370                                 $subject = $_;
1371                         }
1372                 }
1373         }
1374         # Now parse the message body
1375         while(<$fh>) {
1376                 $message .=  $_;
1377                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1378                         chomp;
1379                         my ($what, $c) = ($1, $2);
1380                         chomp $c;
1381                         my $sc = sanitize_address($c);
1382                         if ($sc eq $sender) {
1383                                 next if ($suppress_cc{'self'});
1384                         } else {
1385                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1386                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1387                         }
1388                         push @cc, $c;
1389                         printf("(body) Adding cc: %s from line '%s'\n",
1390                                 $c, $_) unless $quiet;
1391                 }
1392         }
1393         close $fh;
1394
1395         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1396                 if defined $to_cmd;
1397         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1398                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1399
1400         if ($broken_encoding{$t} && !$has_content_type) {
1401                 $has_content_type = 1;
1402                 push @xh, "MIME-Version: 1.0",
1403                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1404                         "Content-Transfer-Encoding: 8bit";
1405                 $body_encoding = $auto_8bit_encoding;
1406         }
1407
1408         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1409                 $subject = quote_subject($subject, $auto_8bit_encoding);
1410         }
1411
1412         if (defined $sauthor and $sauthor ne $sender) {
1413                 $message = "From: $author\n\n$message";
1414                 if (defined $author_encoding) {
1415                         if ($has_content_type) {
1416                                 if ($body_encoding eq $author_encoding) {
1417                                         # ok, we already have the right encoding
1418                                 }
1419                                 else {
1420                                         # uh oh, we should re-encode
1421                                 }
1422                         }
1423                         else {
1424                                 $has_content_type = 1;
1425                                 push @xh,
1426                                   'MIME-Version: 1.0',
1427                                   "Content-Type: text/plain; charset=$author_encoding",
1428                                   'Content-Transfer-Encoding: 8bit';
1429                         }
1430                 }
1431         }
1432
1433         $needs_confirm = (
1434                 $confirm eq "always" or
1435                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1436                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1437         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1438
1439         @to = validate_address_list(sanitize_address_list(@to));
1440         @cc = validate_address_list(sanitize_address_list(@cc));
1441
1442         @to = (@initial_to, @to);
1443         @cc = (@initial_cc, @cc);
1444
1445         my $message_was_sent = send_message();
1446
1447         # set up for the next message
1448         if ($thread && $message_was_sent &&
1449                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1450                 $message_num == 1)) {
1451                 $reply_to = $message_id;
1452                 if (length $references > 0) {
1453                         $references .= "\n $message_id";
1454                 } else {
1455                         $references = "$message_id";
1456                 }
1457         }
1458         $message_id = undef;
1459 }
1460
1461 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1462 # and return a results array
1463 sub recipients_cmd {
1464         my ($prefix, $what, $cmd, $file) = @_;
1465
1466         my @addresses = ();
1467         open my $fh, "-|", "$cmd \Q$file\E"
1468             or die "($prefix) Could not execute '$cmd'";
1469         while (my $address = <$fh>) {
1470                 $address =~ s/^\s*//g;
1471                 $address =~ s/\s*$//g;
1472                 $address = sanitize_address($address);
1473                 next if ($address eq $sender and $suppress_cc{'self'});
1474                 push @addresses, $address;
1475                 printf("($prefix) Adding %s: %s from: '%s'\n",
1476                        $what, $address, $cmd) unless $quiet;
1477                 }
1478         close $fh
1479             or die "($prefix) failed to close pipe to '$cmd'";
1480         return @addresses;
1481 }
1482
1483 cleanup_compose_files();
1484
1485 sub cleanup_compose_files {
1486         unlink($compose_filename, $compose_filename . ".final") if $compose;
1487 }
1488
1489 $smtp->quit if $smtp;
1490
1491 sub unique_email_list {
1492         my %seen;
1493         my @emails;
1494
1495         foreach my $entry (@_) {
1496                 my $clean = extract_valid_address_or_die($entry);
1497                 $seen{$clean} ||= 0;
1498                 next if $seen{$clean}++;
1499                 push @emails, $entry;
1500         }
1501         return @emails;
1502 }
1503
1504 sub validate_patch {
1505         my $fn = shift;
1506         open(my $fh, '<', $fn)
1507                 or die "unable to open $fn: $!\n";
1508         while (my $line = <$fh>) {
1509                 if (length($line) > 998) {
1510                         return "$.: patch contains a line longer than 998 characters";
1511                 }
1512         }
1513         return;
1514 }
1515
1516 sub file_has_nonascii {
1517         my $fn = shift;
1518         open(my $fh, '<', $fn)
1519                 or die "unable to open $fn: $!\n";
1520         while (my $line = <$fh>) {
1521                 return 1 if $line =~ /[^[:ascii:]]/;
1522         }
1523         return 0;
1524 }
1525
1526 sub body_or_subject_has_nonascii {
1527         my $fn = shift;
1528         open(my $fh, '<', $fn)
1529                 or die "unable to open $fn: $!\n";
1530         while (my $line = <$fh>) {
1531                 last if $line =~ /^$/;
1532                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1533         }
1534         while (my $line = <$fh>) {
1535                 return 1 if $line =~ /[^[:ascii:]]/;
1536         }
1537         return 0;
1538 }