git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {$::_trace} {
 552                 puts stderr "< $result"
 553         }
 554         return $result
 555 }
 556
 557 proc _open_stdout_stderr {cmd} {
 558         _trace_exec $cmd
 559         if {[catch {
 560                         set fd [open [concat [list | ] $cmd] r]
 561                 } err]} {
 562                 if {   [lindex $cmd end] eq {2>@1}
 563                     && $err eq {can not find channel named "1"}
 564                         } {
 565                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 566                         # redirect operator.  Fallback to |& cat for those.
 567                         # The command was not actually started, so its safe
 568                         # to try to start it a second time.
 569                         #
 570                         set fd [open [concat \
 571                                 [list | ] \
 572                                 [lrange $cmd 0 end-1] \
 573                                 [list |& cat] \
 574                                 ] r]
 575                 } else {
 576                         error $err
 577                 }
 578         }
 579         fconfigure $fd -eofchar {}
 580         return $fd
 581 }
 582
 583 proc git_read {args} {
 584         set opt [list]
 585
 586         while {1} {
 587                 switch -- [lindex $args 0] {
 588                 --nice {
 589                         _lappend_nice opt
 590                 }
 591
 592                 --stderr {
 593                         lappend args 2>@1
 594                 }
 595
 596                 default {
 597                         break
 598                 }
 599
 600                 }
 601
 602                 set args [lrange $args 1 end]
 603         }
 604
 605         set cmdp [_git_cmd [lindex $args 0]]
 606         set args [lrange $args 1 end]
 607
 608         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 609 }
 610
 611 proc git_write {args} {
 612         set opt [list]
 613
 614         while {1} {
 615                 switch -- [lindex $args 0] {
 616                 --nice {
 617                         _lappend_nice opt
 618                 }
 619
 620                 default {
 621                         break
 622                 }
 623
 624                 }
 625
 626                 set args [lrange $args 1 end]
 627         }
 628
 629         set cmdp [_git_cmd [lindex $args 0]]
 630         set args [lrange $args 1 end]
 631
 632         _trace_exec [concat $opt $cmdp $args]
 633         return [open [concat [list | ] $opt $cmdp $args] w]
 634 }
 635
 636 proc githook_read {hook_name args} {
 637         set pchook [gitdir hooks $hook_name]
 638         lappend args 2>@1
 639
 640         # On Windows [file executable] might lie so we need to ask
 641         # the shell if the hook is executable.  Yes that's annoying.
 642         #
 643         if {[is_Windows]} {
 644                 upvar #0 _sh interp
 645                 if {![info exists interp]} {
 646                         set interp [_which sh]
 647                 }
 648                 if {$interp eq {}} {
 649                         error "hook execution requires sh (not in PATH)"
 650                 }
 651
 652                 set scr {if test -x "$1";then exec "$@";fi}
 653                 set sh_c [list $interp -c $scr $interp $pchook]
 654                 return [_open_stdout_stderr [concat $sh_c $args]]
 655         }
 656
 657         if {[file executable $pchook]} {
 658                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 659         }
 660
 661         return {}
 662 }
 663
 664 proc kill_file_process {fd} {
 665         set process [pid $fd]
 666
 667         catch {
 668                 if {[is_Windows]} {
 669                         # Use a Cygwin-specific flag to allow killing
 670                         # native Windows processes
 671                         exec kill -f $process
 672                 } else {
 673                         exec kill $process
 674                 }
 675         }
 676 }
 677
 678 proc gitattr {path attr default} {
 679         if {[catch {set r [git check-attr $attr -- $path]}]} {
 680                 set r unspecified
 681         } else {
 682                 set r [join [lrange [split $r :] 2 end] :]
 683                 regsub {^ } $r {} r
 684         }
 685         if {$r eq {unspecified}} {
 686                 return $default
 687         }
 688         return $r
 689 }
 690
 691 proc sq {value} {
 692         regsub -all ' $value "'\\''" value
 693         return "'$value'"
 694 }
 695
 696 proc load_current_branch {} {
 697         global current_branch is_detached
 698
 699         set fd [open [gitdir HEAD] r]
 700         if {[gets $fd ref] < 1} {
 701                 set ref {}
 702         }
 703         close $fd
 704
 705         set pfx {ref: refs/heads/}
 706         set len [string length $pfx]
 707         if {[string equal -length $len $pfx $ref]} {
 708                 # We're on a branch.  It might not exist.  But
 709                 # HEAD looks good enough to be a branch.
 710                 #
 711                 set current_branch [string range $ref $len end]
 712                 set is_detached 0
 713         } else {
 714                 # Assume this is a detached head.
 715                 #
 716                 set current_branch HEAD
 717                 set is_detached 1
 718         }
 719 }
 720
 721 auto_load tk_optionMenu
 722 rename tk_optionMenu real__tkOptionMenu
 723 proc tk_optionMenu {w varName args} {
 724         set m [eval real__tkOptionMenu $w $varName $args]
 725         $m configure -font font_ui
 726         $w configure -font font_ui
 727         return $m
 728 }
 729
 730 proc rmsel_tag {text} {
 731         $text tag conf sel \
 732                 -background [$text cget -background] \
 733                 -foreground [$text cget -foreground] \
 734                 -borderwidth 0
 735         $text tag conf in_sel -background lightgray
 736         bind $text <Motion> break
 737         return $text
 738 }
 739
 740 wm withdraw .
 741 set root_exists 0
 742 bind . <Visibility> {
 743         bind . <Visibility> {}
 744         set root_exists 1
 745 }
 746
 747 if {[is_Windows]} {
 748         wm iconbitmap . -default $oguilib/git-gui.ico
 749         set ::tk::AlwaysShowSelection 1
 750         bind . <Control-F2> {console show}
 751
 752         # Spoof an X11 display for SSH
 753         if {![info exists env(DISPLAY)]} {
 754                 set env(DISPLAY) :9999
 755         }
 756 } else {
 757         catch {
 758                 image create photo gitlogo -width 16 -height 16
 759
 760                 gitlogo put #33CC33 -to  7  0  9  2
 761                 gitlogo put #33CC33 -to  4  2 12  4
 762                 gitlogo put #33CC33 -to  7  4  9  6
 763                 gitlogo put #CC3333 -to  4  6 12  8
 764                 gitlogo put gray26  -to  4  9  6 10
 765                 gitlogo put gray26  -to  3 10  6 12
 766                 gitlogo put gray26  -to  8  9 13 11
 767                 gitlogo put gray26  -to  8 11 10 12
 768                 gitlogo put gray26  -to 11 11 13 14
 769                 gitlogo put gray26  -to  3 12  5 14
 770                 gitlogo put gray26  -to  5 13
 771                 gitlogo put gray26  -to 10 13
 772                 gitlogo put gray26  -to  4 14 12 15
 773                 gitlogo put gray26  -to  5 15 11 16
 774                 gitlogo redither
 775
 776                 image create photo gitlogo32 -width 32 -height 32
 777                 gitlogo32 copy gitlogo -zoom 2 2
 778
 779                 wm iconphoto . -default gitlogo gitlogo32
 780         }
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## config defaults
 786
 787 set cursor_ptr arrow
 788 font create font_ui
 789 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 790         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 791         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 792 } else {
 793         font create font_diff -family Courier -size 10
 794         catch {
 795                 label .dummy
 796                 eval font configure font_ui [font actual [.dummy cget -font]]
 797                 destroy .dummy
 798         }
 799 }
 800
 801 font create font_uiitalic
 802 font create font_uibold
 803 font create font_diffbold
 804 font create font_diffitalic
 805
 806 foreach class {Button Checkbutton Entry Label
 807                 Labelframe Listbox Message
 808                 Radiobutton Spinbox Text} {
 809         option add *$class.font font_ui
 810 }
 811 if {![is_MacOSX]} {
 812         option add *Menu.font font_ui
 813         option add *Entry.borderWidth 1 startupFile
 814         option add *Entry.relief sunken startupFile
 815         option add *RadioButton.anchor w startupFile
 816 }
 817 unset class
 818
 819 if {[is_Windows] || [is_MacOSX]} {
 820         option add *Menu.tearOff 0
 821 }
 822
 823 if {[is_MacOSX]} {
 824         set M1B M1
 825         set M1T Cmd
 826 } else {
 827         set M1B Control
 828         set M1T Ctrl
 829 }
 830
 831 proc bind_button3 {w cmd} {
 832         bind $w <Any-Button-3> $cmd
 833         if {[is_MacOSX]} {
 834                 # Mac OS X sends Button-2 on right click through three-button mouse,
 835                 # or through trackpad right-clicking (two-finger touch + click).
 836                 bind $w <Any-Button-2> $cmd
 837                 bind $w <Control-Button-1> $cmd
 838         }
 839 }
 840
 841 proc apply_config {} {
 842         global repo_config font_descs
 843
 844         foreach option $font_descs {
 845                 set name [lindex $option 0]
 846                 set font [lindex $option 1]
 847                 if {[catch {
 848                         set need_weight 1
 849                         foreach {cn cv} $repo_config(gui.$name) {
 850                                 if {$cn eq {-weight}} {
 851                                         set need_weight 0
 852                                 }
 853                                 font configure $font $cn $cv
 854                         }
 855                         if {$need_weight} {
 856                                 font configure $font -weight normal
 857                         }
 858                         } err]} {
 859                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 860                 }
 861                 foreach {cn cv} [font configure $font] {
 862                         font configure ${font}bold $cn $cv
 863                         font configure ${font}italic $cn $cv
 864                 }
 865                 font configure ${font}bold -weight bold
 866                 font configure ${font}italic -slant italic
 867         }
 868
 869         global use_ttk NS
 870         set use_ttk 0
 871         set NS {}
 872         if {$repo_config(gui.usettk)} {
 873                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 874                 if {$use_ttk} {
 875                         set NS ttk
 876                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 877                         pave_toplevel .
 878                 }
 879         }
 880 }
 881
 882 set default_config(branch.autosetupmerge) true
 883 set default_config(merge.tool) {}
 884 set default_config(mergetool.keepbackup) true
 885 set default_config(merge.diffstat) true
 886 set default_config(merge.summary) false
 887 set default_config(merge.verbosity) 2
 888 set default_config(user.name) {}
 889 set default_config(user.email) {}
 890
 891 set default_config(gui.encoding) [encoding system]
 892 set default_config(gui.matchtrackingbranch) false
 893 set default_config(gui.textconv) true
 894 set default_config(gui.pruneduringfetch) false
 895 set default_config(gui.trustmtime) false
 896 set default_config(gui.fastcopyblame) false
 897 set default_config(gui.maxrecentrepo) 10
 898 set default_config(gui.copyblamethreshold) 40
 899 set default_config(gui.blamehistoryctx) 7
 900 set default_config(gui.diffcontext) 5
 901 set default_config(gui.diffopts) {}
 902 set default_config(gui.commitmsgwidth) 75
 903 set default_config(gui.newbranchtemplate) {}
 904 set default_config(gui.spellingdictionary) {}
 905 set default_config(gui.fontui) [font configure font_ui]
 906 set default_config(gui.fontdiff) [font configure font_diff]
 907 # TODO: this option should be added to the git-config documentation
 908 set default_config(gui.maxfilesdisplayed) 5000
 909 set default_config(gui.usettk) 1
 910 set default_config(gui.warndetachedcommit) 1
 911 set font_descs {
 912         {fontui   font_ui   {mc "Main Font"}}
 913         {fontdiff font_diff {mc "Diff/Console Font"}}
 914 }
 915 set default_config(gui.stageuntracked) ask
 916 set default_config(gui.displayuntracked) true
 917
 918 ######################################################################
 919 ##
 920 ## find git
 921
 922 set _git  [_which git]
 923 if {$_git eq {}} {
 924         catch {wm withdraw .}
 925         tk_messageBox \
 926                 -icon error \
 927                 -type ok \
 928                 -title [mc "git-gui: fatal error"] \
 929                 -message [mc "Cannot find git in PATH."]
 930         exit 1
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## version check
 936
 937 if {[catch {set _git_version [git --version]} err]} {
 938         catch {wm withdraw .}
 939         tk_messageBox \
 940                 -icon error \
 941                 -type ok \
 942                 -title [mc "git-gui: fatal error"] \
 943                 -message "Cannot determine Git version:
 944
 945 $err
 946
 947 [appname] requires Git 1.5.0 or later."
 948         exit 1
 949 }
 950 if {![regsub {^git version } $_git_version {} _git_version]} {
 951         catch {wm withdraw .}
 952         tk_messageBox \
 953                 -icon error \
 954                 -type ok \
 955                 -title [mc "git-gui: fatal error"] \
 956                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 957         exit 1
 958 }
 959
 960 proc get_trimmed_version {s} {
 961     set r {}
 962     foreach x [split $s -._] {
 963         if {[string is integer -strict $x]} {
 964             lappend r $x
 965         } else {
 966             break
 967         }
 968     }
 969     return [join $r .]
 970 }
 971 set _real_git_version $_git_version
 972 set _git_version [get_trimmed_version $_git_version]
 973
 974 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 975         catch {wm withdraw .}
 976         if {[tk_messageBox \
 977                 -icon warning \
 978                 -type yesno \
 979                 -default no \
 980                 -title "[appname]: warning" \
 981                  -message [mc "Git version cannot be determined.
 982
 983 %s claims it is version '%s'.
 984
 985 %s requires at least Git 1.5.0 or later.
 986
 987 Assume '%s' is version 1.5.0?
 988 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 989                 set _git_version 1.5.0
 990         } else {
 991                 exit 1
 992         }
 993 }
 994 unset _real_git_version
 995
 996 proc git-version {args} {
 997         global _git_version
 998
 999         switch [llength $args] {
1000         0 {
1001                 return $_git_version
1002         }
1003
1004         2 {
1005                 set op [lindex $args 0]
1006                 set vr [lindex $args 1]
1007                 set cm [package vcompare $_git_version $vr]
1008                 return [expr $cm $op 0]
1009         }
1010
1011         4 {
1012                 set type [lindex $args 0]
1013                 set name [lindex $args 1]
1014                 set parm [lindex $args 2]
1015                 set body [lindex $args 3]
1016
1017                 if {($type ne {proc} && $type ne {method})} {
1018                         error "Invalid arguments to git-version"
1019                 }
1020                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1021                         error "Last arm of $type $name must be default"
1022                 }
1023
1024                 foreach {op vr cb} [lrange $body 0 end-2] {
1025                         if {[git-version $op $vr]} {
1026                                 return [uplevel [list $type $name $parm $cb]]
1027                         }
1028                 }
1029
1030                 return [uplevel [list $type $name $parm [lindex $body end]]]
1031         }
1032
1033         default {
1034                 error "git-version >= x"
1035         }
1036
1037         }
1038 }
1039
1040 if {[git-version < 1.5]} {
1041         catch {wm withdraw .}
1042         tk_messageBox \
1043                 -icon error \
1044                 -type ok \
1045                 -title [mc "git-gui: fatal error"] \
1046                 -message "[appname] requires Git 1.5.0 or later.
1047
1048 You are using [git-version]:
1049
1050 [git --version]"
1051         exit 1
1052 }
1053
1054 ######################################################################
1055 ##
1056 ## configure our library
1057
1058 set idx [file join $oguilib tclIndex]
1059 if {[catch {set fd [open $idx r]} err]} {
1060         catch {wm withdraw .}
1061         tk_messageBox \
1062                 -icon error \
1063                 -type ok \
1064                 -title [mc "git-gui: fatal error"] \
1065                 -message $err
1066         exit 1
1067 }
1068 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1069         set idx [list]
1070         while {[gets $fd n] >= 0} {
1071                 if {$n ne {} && ![string match #* $n]} {
1072                         lappend idx $n
1073                 }
1074         }
1075 } else {
1076         set idx {}
1077 }
1078 close $fd
1079
1080 if {$idx ne {}} {
1081         set loaded [list]
1082         foreach p $idx {
1083                 if {[lsearch -exact $loaded $p] >= 0} continue
1084                 source [file join $oguilib $p]
1085                 lappend loaded $p
1086         }
1087         unset loaded p
1088 } else {
1089         set auto_path [concat [list $oguilib] $auto_path]
1090 }
1091 unset -nocomplain idx fd
1092
1093 ######################################################################
1094 ##
1095 ## config file parsing
1096
1097 git-version proc _parse_config {arr_name args} {
1098         >= 1.5.3 {
1099                 upvar $arr_name arr
1100                 array unset arr
1101                 set buf {}
1102                 catch {
1103                         set fd_rc [eval \
1104                                 [list git_read config] \
1105                                 $args \
1106                                 [list --null --list]]
1107                         fconfigure $fd_rc -translation binary
1108                         set buf [read $fd_rc]
1109                         close $fd_rc
1110                 }
1111                 foreach line [split $buf "\0"] {
1112                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1113                                 if {[is_many_config $name]} {
1114                                         lappend arr($name) $value
1115                                 } else {
1116                                         set arr($name) $value
1117                                 }
1118                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1119                                 # no value given, but interpreting them as
1120                                 # boolean will be handled as true
1121                                 set arr($name) {}
1122                         }
1123                 }
1124         }
1125         default {
1126                 upvar $arr_name arr
1127                 array unset arr
1128                 catch {
1129                         set fd_rc [eval [list git_read config --list] $args]
1130                         while {[gets $fd_rc line] >= 0} {
1131                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1132                                         if {[is_many_config $name]} {
1133                                                 lappend arr($name) $value
1134                                         } else {
1135                                                 set arr($name) $value
1136                                         }
1137                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1138                                         # no value given, but interpreting them as
1139                                         # boolean will be handled as true
1140                                         set arr($name) {}
1141                                 }
1142                         }
1143                         close $fd_rc
1144                 }
1145         }
1146 }
1147
1148 proc load_config {include_global} {
1149         global repo_config global_config system_config default_config
1150
1151         if {$include_global} {
1152                 _parse_config system_config --system
1153                 _parse_config global_config --global
1154         }
1155         _parse_config repo_config
1156
1157         foreach name [array names default_config] {
1158                 if {[catch {set v $system_config($name)}]} {
1159                         set system_config($name) $default_config($name)
1160                 }
1161         }
1162         foreach name [array names system_config] {
1163                 if {[catch {set v $global_config($name)}]} {
1164                         set global_config($name) $system_config($name)
1165                 }
1166                 if {[catch {set v $repo_config($name)}]} {
1167                         set repo_config($name) $system_config($name)
1168                 }
1169         }
1170 }
1171
1172 ######################################################################
1173 ##
1174 ## feature option selection
1175
1176 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1177         unset _junk
1178 } else {
1179         set subcommand gui
1180 }
1181 if {$subcommand eq {gui.sh}} {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui} && [llength $argv] > 0} {
1185         set subcommand [lindex $argv 0]
1186         set argv [lrange $argv 1 end]
1187 }
1188
1189 enable_option multicommit
1190 enable_option branch
1191 enable_option transport
1192 disable_option bare
1193
1194 switch -- $subcommand {
1195 browser -
1196 blame {
1197         enable_option bare
1198
1199         disable_option multicommit
1200         disable_option branch
1201         disable_option transport
1202 }
1203 citool {
1204         enable_option singlecommit
1205         enable_option retcode
1206
1207         disable_option multicommit
1208         disable_option branch
1209         disable_option transport
1210
1211         while {[llength $argv] > 0} {
1212                 set a [lindex $argv 0]
1213                 switch -- $a {
1214                 --amend {
1215                         enable_option initialamend
1216                 }
1217                 --nocommit {
1218                         enable_option nocommit
1219                         enable_option nocommitmsg
1220                 }
1221                 --commitmsg {
1222                         disable_option nocommitmsg
1223                 }
1224                 default {
1225                         break
1226                 }
1227                 }
1228
1229                 set argv [lrange $argv 1 end]
1230         }
1231 }
1232 }
1233
1234 ######################################################################
1235 ##
1236 ## execution environment
1237
1238 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1239
1240 # Suggest our implementation of askpass, if none is set
1241 if {![info exists env(SSH_ASKPASS)]} {
1242         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1243 }
1244
1245 ######################################################################
1246 ##
1247 ## repository setup
1248
1249 set picked 0
1250 if {[catch {
1251                 set _gitdir $env(GIT_DIR)
1252                 set _prefix {}
1253                 }]
1254         && [catch {
1255                 # beware that from the .git dir this sets _gitdir to .
1256                 # and _prefix to the empty string
1257                 set _gitdir [git rev-parse --git-dir]
1258                 set _prefix [git rev-parse --show-prefix]
1259         } err]} {
1260         load_config 1
1261         apply_config
1262         choose_repository::pick
1263         set picked 1
1264 }
1265
1266 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1267 # run from the .git dir itself) lest the routines to find the worktree
1268 # get confused
1269 if {$_gitdir eq "."} {
1270         set _gitdir [pwd]
1271 }
1272
1273 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1274         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1275 }
1276 if {![file isdirectory $_gitdir]} {
1277         catch {wm withdraw .}
1278         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1279         exit 1
1280 }
1281 # _gitdir exists, so try loading the config
1282 load_config 0
1283 apply_config
1284
1285 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1286 if {[package vsatisfies $_git_version 1.7.0-]} {
1287         if { [is_Cygwin] } {
1288                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1289         } else {
1290                 set _gitworktree [git rev-parse --show-toplevel]
1291         }
1292 } else {
1293         # try to set work tree from environment, core.worktree or use
1294         # cdup to obtain a relative path to the top of the worktree. If
1295         # run from the top, the ./ prefix ensures normalize expands pwd.
1296         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1297                 set _gitworktree [get_config core.worktree]
1298                 if {$_gitworktree eq ""} {
1299                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1300                 }
1301         }
1302 }
1303
1304 if {$_prefix ne {}} {
1305         if {$_gitworktree eq {}} {
1306                 regsub -all {[^/]+/} $_prefix ../ cdup
1307         } else {
1308                 set cdup $_gitworktree
1309         }
1310         if {[catch {cd $cdup} err]} {
1311                 catch {wm withdraw .}
1312                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1313                 exit 1
1314         }
1315         set _gitworktree [pwd]
1316         unset cdup
1317 } elseif {![is_enabled bare]} {
1318         if {[is_bare]} {
1319                 catch {wm withdraw .}
1320                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1321                 exit 1
1322         }
1323         if {$_gitworktree eq {}} {
1324                 set _gitworktree [file dirname $_gitdir]
1325         }
1326         if {[catch {cd $_gitworktree} err]} {
1327                 catch {wm withdraw .}
1328                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1329                 exit 1
1330         }
1331         set _gitworktree [pwd]
1332 }
1333 set _reponame [file split [file normalize $_gitdir]]
1334 if {[lindex $_reponame end] eq {.git}} {
1335         set _reponame [lindex $_reponame end-1]
1336 } else {
1337         set _reponame [lindex $_reponame end]
1338 }
1339
1340 ######################################################################
1341 ##
1342 ## global init
1343
1344 set current_diff_path {}
1345 set current_diff_side {}
1346 set diff_actions [list]
1347
1348 set HEAD {}
1349 set PARENT {}
1350 set MERGE_HEAD [list]
1351 set commit_type {}
1352 set empty_tree {}
1353 set current_branch {}
1354 set is_detached 0
1355 set current_diff_path {}
1356 set is_3way_diff 0
1357 set is_submodule_diff 0
1358 set is_conflict_diff 0
1359 set selected_commit_type new
1360 set diff_empty_count 0
1361
1362 set nullid "0000000000000000000000000000000000000000"
1363 set nullid2 "0000000000000000000000000000000000000001"
1364
1365 ######################################################################
1366 ##
1367 ## task management
1368
1369 set rescan_active 0
1370 set diff_active 0
1371 set last_clicked {}
1372
1373 set disable_on_lock [list]
1374 set index_lock_type none
1375
1376 proc lock_index {type} {
1377         global index_lock_type disable_on_lock
1378
1379         if {$index_lock_type eq {none}} {
1380                 set index_lock_type $type
1381                 foreach w $disable_on_lock {
1382                         uplevel #0 $w disabled
1383                 }
1384                 return 1
1385         } elseif {$index_lock_type eq "begin-$type"} {
1386                 set index_lock_type $type
1387                 return 1
1388         }
1389         return 0
1390 }
1391
1392 proc unlock_index {} {
1393         global index_lock_type disable_on_lock
1394
1395         set index_lock_type none
1396         foreach w $disable_on_lock {
1397                 uplevel #0 $w normal
1398         }
1399 }
1400
1401 ######################################################################
1402 ##
1403 ## status
1404
1405 proc repository_state {ctvar hdvar mhvar} {
1406         global current_branch
1407         upvar $ctvar ct $hdvar hd $mhvar mh
1408
1409         set mh [list]
1410
1411         load_current_branch
1412         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1413                 set hd {}
1414                 set ct initial
1415                 return
1416         }
1417
1418         set merge_head [gitdir MERGE_HEAD]
1419         if {[file exists $merge_head]} {
1420                 set ct merge
1421                 set fd_mh [open $merge_head r]
1422                 while {[gets $fd_mh line] >= 0} {
1423                         lappend mh $line
1424                 }
1425                 close $fd_mh
1426                 return
1427         }
1428
1429         set ct normal
1430 }
1431
1432 proc PARENT {} {
1433         global PARENT empty_tree
1434
1435         set p [lindex $PARENT 0]
1436         if {$p ne {}} {
1437                 return $p
1438         }
1439         if {$empty_tree eq {}} {
1440                 set empty_tree [git mktree << {}]
1441         }
1442         return $empty_tree
1443 }
1444
1445 proc force_amend {} {
1446         global selected_commit_type
1447         global HEAD PARENT MERGE_HEAD commit_type
1448
1449         repository_state newType newHEAD newMERGE_HEAD
1450         set HEAD $newHEAD
1451         set PARENT $newHEAD
1452         set MERGE_HEAD $newMERGE_HEAD
1453         set commit_type $newType
1454
1455         set selected_commit_type amend
1456         do_select_commit_type
1457 }
1458
1459 proc rescan {after {honor_trustmtime 1}} {
1460         global HEAD PARENT MERGE_HEAD commit_type
1461         global ui_index ui_workdir ui_comm
1462         global rescan_active file_states
1463         global repo_config
1464
1465         if {$rescan_active > 0 || ![lock_index read]} return
1466
1467         repository_state newType newHEAD newMERGE_HEAD
1468         if {[string match amend* $commit_type]
1469                 && $newType eq {normal}
1470                 && $newHEAD eq $HEAD} {
1471         } else {
1472                 set HEAD $newHEAD
1473                 set PARENT $newHEAD
1474                 set MERGE_HEAD $newMERGE_HEAD
1475                 set commit_type $newType
1476         }
1477
1478         array unset file_states
1479
1480         if {!$::GITGUI_BCK_exists &&
1481                 (![$ui_comm edit modified]
1482                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1483                 if {[string match amend* $commit_type]} {
1484                 } elseif {[load_message GITGUI_MSG utf-8]} {
1485                 } elseif {[run_prepare_commit_msg_hook]} {
1486                 } elseif {[load_message MERGE_MSG]} {
1487                 } elseif {[load_message SQUASH_MSG]} {
1488                 }
1489                 $ui_comm edit reset
1490                 $ui_comm edit modified false
1491         }
1492
1493         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1494                 rescan_stage2 {} $after
1495         } else {
1496                 set rescan_active 1
1497                 ui_status [mc "Refreshing file status..."]
1498                 set fd_rf [git_read update-index \
1499                         -q \
1500                         --unmerged \
1501                         --ignore-missing \
1502                         --refresh \
1503                         ]
1504                 fconfigure $fd_rf -blocking 0 -translation binary
1505                 fileevent $fd_rf readable \
1506                         [list rescan_stage2 $fd_rf $after]
1507         }
1508 }
1509
1510 if {[is_Cygwin]} {
1511         set is_git_info_exclude {}
1512         proc have_info_exclude {} {
1513                 global is_git_info_exclude
1514
1515                 if {$is_git_info_exclude eq {}} {
1516                         if {[catch {exec test -f [gitdir info exclude]}]} {
1517                                 set is_git_info_exclude 0
1518                         } else {
1519                                 set is_git_info_exclude 1
1520                         }
1521                 }
1522                 return $is_git_info_exclude
1523         }
1524 } else {
1525         proc have_info_exclude {} {
1526                 return [file readable [gitdir info exclude]]
1527         }
1528 }
1529
1530 proc rescan_stage2 {fd after} {
1531         global rescan_active buf_rdi buf_rdf buf_rlo
1532
1533         if {$fd ne {}} {
1534                 read $fd
1535                 if {![eof $fd]} return
1536                 close $fd
1537         }
1538
1539         if {[package vsatisfies $::_git_version 1.6.3-]} {
1540                 set ls_others [list --exclude-standard]
1541         } else {
1542                 set ls_others [list --exclude-per-directory=.gitignore]
1543                 if {[have_info_exclude]} {
1544                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1545                 }
1546                 set user_exclude [get_config core.excludesfile]
1547                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1548                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1549                 }
1550         }
1551
1552         set buf_rdi {}
1553         set buf_rdf {}
1554         set buf_rlo {}
1555
1556         set rescan_active 2
1557         ui_status [mc "Scanning for modified files ..."]
1558         set fd_di [git_read diff-index --cached -z [PARENT]]
1559         set fd_df [git_read diff-files -z]
1560
1561         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1562         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1563
1564         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1565         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1566
1567         if {[is_config_true gui.displayuntracked]} {
1568                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1569                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1570                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1571                 incr rescan_active
1572         }
1573 }
1574
1575 proc load_message {file {encoding {}}} {
1576         global ui_comm
1577
1578         set f [gitdir $file]
1579         if {[file isfile $f]} {
1580                 if {[catch {set fd [open $f r]}]} {
1581                         return 0
1582                 }
1583                 fconfigure $fd -eofchar {}
1584                 if {$encoding ne {}} {
1585                         fconfigure $fd -encoding $encoding
1586                 }
1587                 set content [string trim [read $fd]]
1588                 close $fd
1589                 regsub -all -line {[ \r\t]+$} $content {} content
1590                 $ui_comm delete 0.0 end
1591                 $ui_comm insert end $content
1592                 return 1
1593         }
1594         return 0
1595 }
1596
1597 proc run_prepare_commit_msg_hook {} {
1598         global pch_error
1599
1600         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1601         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1602         # empty file but existent file.
1603
1604         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1605
1606         if {[file isfile [gitdir MERGE_MSG]]} {
1607                 set pcm_source "merge"
1608                 set fd_mm [open [gitdir MERGE_MSG] r]
1609                 puts -nonewline $fd_pcm [read $fd_mm]
1610                 close $fd_mm
1611         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1612                 set pcm_source "squash"
1613                 set fd_sm [open [gitdir SQUASH_MSG] r]
1614                 puts -nonewline $fd_pcm [read $fd_sm]
1615                 close $fd_sm
1616         } else {
1617                 set pcm_source ""
1618         }
1619
1620         close $fd_pcm
1621
1622         set fd_ph [githook_read prepare-commit-msg \
1623                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1624         if {$fd_ph eq {}} {
1625                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1626                 return 0;
1627         }
1628
1629         ui_status [mc "Calling prepare-commit-msg hook..."]
1630         set pch_error {}
1631
1632         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1633         fileevent $fd_ph readable \
1634                 [list prepare_commit_msg_hook_wait $fd_ph]
1635
1636         return 1;
1637 }
1638
1639 proc prepare_commit_msg_hook_wait {fd_ph} {
1640         global pch_error
1641
1642         append pch_error [read $fd_ph]
1643         fconfigure $fd_ph -blocking 1
1644         if {[eof $fd_ph]} {
1645                 if {[catch {close $fd_ph}]} {
1646                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1647                         hook_failed_popup prepare-commit-msg $pch_error
1648                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1649                         exit 1
1650                 } else {
1651                         load_message PREPARE_COMMIT_MSG
1652                 }
1653                 set pch_error {}
1654                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1655                 return
1656         }
1657         fconfigure $fd_ph -blocking 0
1658         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1659 }
1660
1661 proc read_diff_index {fd after} {
1662         global buf_rdi
1663
1664         append buf_rdi [read $fd]
1665         set c 0
1666         set n [string length $buf_rdi]
1667         while {$c < $n} {
1668                 set z1 [string first "\0" $buf_rdi $c]
1669                 if {$z1 == -1} break
1670                 incr z1
1671                 set z2 [string first "\0" $buf_rdi $z1]
1672                 if {$z2 == -1} break
1673
1674                 incr c
1675                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1676                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1677                 merge_state \
1678                         [encoding convertfrom $p] \
1679                         [lindex $i 4]? \
1680                         [list [lindex $i 0] [lindex $i 2]] \
1681                         [list]
1682                 set c $z2
1683                 incr c
1684         }
1685         if {$c < $n} {
1686                 set buf_rdi [string range $buf_rdi $c end]
1687         } else {
1688                 set buf_rdi {}
1689         }
1690
1691         rescan_done $fd buf_rdi $after
1692 }
1693
1694 proc read_diff_files {fd after} {
1695         global buf_rdf
1696
1697         append buf_rdf [read $fd]
1698         set c 0
1699         set n [string length $buf_rdf]
1700         while {$c < $n} {
1701                 set z1 [string first "\0" $buf_rdf $c]
1702                 if {$z1 == -1} break
1703                 incr z1
1704                 set z2 [string first "\0" $buf_rdf $z1]
1705                 if {$z2 == -1} break
1706
1707                 incr c
1708                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1709                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1710                 merge_state \
1711                         [encoding convertfrom $p] \
1712                         ?[lindex $i 4] \
1713                         [list] \
1714                         [list [lindex $i 0] [lindex $i 2]]
1715                 set c $z2
1716                 incr c
1717         }
1718         if {$c < $n} {
1719                 set buf_rdf [string range $buf_rdf $c end]
1720         } else {
1721                 set buf_rdf {}
1722         }
1723
1724         rescan_done $fd buf_rdf $after
1725 }
1726
1727 proc read_ls_others {fd after} {
1728         global buf_rlo
1729
1730         append buf_rlo [read $fd]
1731         set pck [split $buf_rlo "\0"]
1732         set buf_rlo [lindex $pck end]
1733         foreach p [lrange $pck 0 end-1] {
1734                 set p [encoding convertfrom $p]
1735                 if {[string index $p end] eq {/}} {
1736                         set p [string range $p 0 end-1]
1737                 }
1738                 merge_state $p ?O
1739         }
1740         rescan_done $fd buf_rlo $after
1741 }
1742
1743 proc rescan_done {fd buf after} {
1744         global rescan_active current_diff_path
1745         global file_states repo_config
1746         upvar $buf to_clear
1747
1748         if {![eof $fd]} return
1749         set to_clear {}
1750         close $fd
1751         if {[incr rescan_active -1] > 0} return
1752
1753         prune_selection
1754         unlock_index
1755         display_all_files
1756         if {$current_diff_path ne {}} { reshow_diff $after }
1757         if {$current_diff_path eq {}} { select_first_diff $after }
1758 }
1759
1760 proc prune_selection {} {
1761         global file_states selected_paths
1762
1763         foreach path [array names selected_paths] {
1764                 if {[catch {set still_here $file_states($path)}]} {
1765                         unset selected_paths($path)
1766                 }
1767         }
1768 }
1769
1770 ######################################################################
1771 ##
1772 ## ui helpers
1773
1774 proc mapicon {w state path} {
1775         global all_icons
1776
1777         if {[catch {set r $all_icons($state$w)}]} {
1778                 puts "error: no icon for $w state={$state} $path"
1779                 return file_plain
1780         }
1781         return $r
1782 }
1783
1784 proc mapdesc {state path} {
1785         global all_descs
1786
1787         if {[catch {set r $all_descs($state)}]} {
1788                 puts "error: no desc for state={$state} $path"
1789                 return $state
1790         }
1791         return $r
1792 }
1793
1794 proc ui_status {msg} {
1795         global main_status
1796         if {[info exists main_status]} {
1797                 $main_status show $msg
1798         }
1799 }
1800
1801 proc ui_ready {{test {}}} {
1802         global main_status
1803         if {[info exists main_status]} {
1804                 $main_status show [mc "Ready."] $test
1805         }
1806 }
1807
1808 proc escape_path {path} {
1809         regsub -all {\\} $path "\\\\" path
1810         regsub -all "\n" $path "\\n" path
1811         return $path
1812 }
1813
1814 proc short_path {path} {
1815         return [escape_path [lindex [file split $path] end]]
1816 }
1817
1818 set next_icon_id 0
1819 set null_sha1 [string repeat 0 40]
1820
1821 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1822         global file_states next_icon_id null_sha1
1823
1824         set s0 [string index $new_state 0]
1825         set s1 [string index $new_state 1]
1826
1827         if {[catch {set info $file_states($path)}]} {
1828                 set state __
1829                 set icon n[incr next_icon_id]
1830         } else {
1831                 set state [lindex $info 0]
1832                 set icon [lindex $info 1]
1833                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1834                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1835         }
1836
1837         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1838         elseif {$s0 eq {_}} {set s0 _}
1839
1840         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1841         elseif {$s1 eq {_}} {set s1 _}
1842
1843         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1844                 set head_info [list 0 $null_sha1]
1845         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1846                 && $head_info eq {}} {
1847                 set head_info $index_info
1848         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1849                 set index_info $head_info
1850                 set head_info {}
1851         }
1852
1853         set file_states($path) [list $s0$s1 $icon \
1854                 $head_info $index_info \
1855                 ]
1856         return $state
1857 }
1858
1859 proc display_file_helper {w path icon_name old_m new_m} {
1860         global file_lists
1861
1862         if {$new_m eq {_}} {
1863                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1864                 if {$lno >= 0} {
1865                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1866                         incr lno
1867                         $w conf -state normal
1868                         $w delete $lno.0 [expr {$lno + 1}].0
1869                         $w conf -state disabled
1870                 }
1871         } elseif {$old_m eq {_} && $new_m ne {_}} {
1872                 lappend file_lists($w) $path
1873                 set file_lists($w) [lsort -unique $file_lists($w)]
1874                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1875                 incr lno
1876                 $w conf -state normal
1877                 $w image create $lno.0 \
1878                         -align center -padx 5 -pady 1 \
1879                         -name $icon_name \
1880                         -image [mapicon $w $new_m $path]
1881                 $w insert $lno.1 "[escape_path $path]\n"
1882                 $w conf -state disabled
1883         } elseif {$old_m ne $new_m} {
1884                 $w conf -state normal
1885                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1886                 $w conf -state disabled
1887         }
1888 }
1889
1890 proc display_file {path state} {
1891         global file_states selected_paths
1892         global ui_index ui_workdir
1893
1894         set old_m [merge_state $path $state]
1895         set s $file_states($path)
1896         set new_m [lindex $s 0]
1897         set icon_name [lindex $s 1]
1898
1899         set o [string index $old_m 0]
1900         set n [string index $new_m 0]
1901         if {$o eq {U}} {
1902                 set o _
1903         }
1904         if {$n eq {U}} {
1905                 set n _
1906         }
1907         display_file_helper     $ui_index $path $icon_name $o $n
1908
1909         if {[string index $old_m 0] eq {U}} {
1910                 set o U
1911         } else {
1912                 set o [string index $old_m 1]
1913         }
1914         if {[string index $new_m 0] eq {U}} {
1915                 set n U
1916         } else {
1917                 set n [string index $new_m 1]
1918         }
1919         display_file_helper     $ui_workdir $path $icon_name $o $n
1920
1921         if {$new_m eq {__}} {
1922                 unset file_states($path)
1923                 catch {unset selected_paths($path)}
1924         }
1925 }
1926
1927 proc display_all_files_helper {w path icon_name m} {
1928         global file_lists
1929
1930         lappend file_lists($w) $path
1931         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1932         $w image create end \
1933                 -align center -padx 5 -pady 1 \
1934                 -name $icon_name \
1935                 -image [mapicon $w $m $path]
1936         $w insert end "[escape_path $path]\n"
1937 }
1938
1939 set files_warning 0
1940 proc display_all_files {} {
1941         global ui_index ui_workdir
1942         global file_states file_lists
1943         global last_clicked
1944         global files_warning
1945
1946         $ui_index conf -state normal
1947         $ui_workdir conf -state normal
1948
1949         $ui_index delete 0.0 end
1950         $ui_workdir delete 0.0 end
1951         set last_clicked {}
1952
1953         set file_lists($ui_index) [list]
1954         set file_lists($ui_workdir) [list]
1955
1956         set to_display [lsort [array names file_states]]
1957         set display_limit [get_config gui.maxfilesdisplayed]
1958         if {[llength $to_display] > $display_limit} {
1959                 if {!$files_warning} {
1960                         # do not repeatedly warn:
1961                         set files_warning 1
1962                         info_popup [mc "Displaying only %s of %s files." \
1963                                 $display_limit [llength $to_display]]
1964                 }
1965                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1966         }
1967         foreach path $to_display {
1968                 set s $file_states($path)
1969                 set m [lindex $s 0]
1970                 set icon_name [lindex $s 1]
1971
1972                 set s [string index $m 0]
1973                 if {$s ne {U} && $s ne {_}} {
1974                         display_all_files_helper $ui_index $path \
1975                                 $icon_name $s
1976                 }
1977
1978                 if {[string index $m 0] eq {U}} {
1979                         set s U
1980                 } else {
1981                         set s [string index $m 1]
1982                 }
1983                 if {$s ne {_}} {
1984                         display_all_files_helper $ui_workdir $path \
1985                                 $icon_name $s
1986                 }
1987         }
1988
1989         $ui_index conf -state disabled
1990         $ui_workdir conf -state disabled
1991 }
1992
1993 ######################################################################
1994 ##
1995 ## icons
1996
1997 set filemask {
1998 #define mask_width 14
1999 #define mask_height 15
2000 static unsigned char mask_bits[] = {
2001    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2002    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2003    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2004 }
2005
2006 image create bitmap file_plain -background white -foreground black -data {
2007 #define plain_width 14
2008 #define plain_height 15
2009 static unsigned char plain_bits[] = {
2010    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2011    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2012    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2013 } -maskdata $filemask
2014
2015 image create bitmap file_mod -background white -foreground blue -data {
2016 #define mod_width 14
2017 #define mod_height 15
2018 static unsigned char mod_bits[] = {
2019    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2020    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2021    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2022 } -maskdata $filemask
2023
2024 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2025 #define file_fulltick_width 14
2026 #define file_fulltick_height 15
2027 static unsigned char file_fulltick_bits[] = {
2028    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2029    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2030    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2031 } -maskdata $filemask
2032
2033 image create bitmap file_question -background white -foreground black -data {
2034 #define file_question_width 14
2035 #define file_question_height 15
2036 static unsigned char file_question_bits[] = {
2037    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2038    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2039    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2040 } -maskdata $filemask
2041
2042 image create bitmap file_removed -background white -foreground red -data {
2043 #define file_removed_width 14
2044 #define file_removed_height 15
2045 static unsigned char file_removed_bits[] = {
2046    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2047    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2048    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2049 } -maskdata $filemask
2050
2051 image create bitmap file_merge -background white -foreground blue -data {
2052 #define file_merge_width 14
2053 #define file_merge_height 15
2054 static unsigned char file_merge_bits[] = {
2055    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2056    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2057    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2058 } -maskdata $filemask
2059
2060 image create bitmap file_statechange -background white -foreground green -data {
2061 #define file_statechange_width 14
2062 #define file_statechange_height 15
2063 static unsigned char file_statechange_bits[] = {
2064    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2065    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2066    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2067 } -maskdata $filemask
2068
2069 set ui_index .vpane.files.index.list
2070 set ui_workdir .vpane.files.workdir.list
2071
2072 set all_icons(_$ui_index)   file_plain
2073 set all_icons(A$ui_index)   file_plain
2074 set all_icons(M$ui_index)   file_fulltick
2075 set all_icons(D$ui_index)   file_removed
2076 set all_icons(U$ui_index)   file_merge
2077 set all_icons(T$ui_index)   file_statechange
2078
2079 set all_icons(_$ui_workdir) file_plain
2080 set all_icons(M$ui_workdir) file_mod
2081 set all_icons(D$ui_workdir) file_question
2082 set all_icons(U$ui_workdir) file_merge
2083 set all_icons(O$ui_workdir) file_plain
2084 set all_icons(T$ui_workdir) file_statechange
2085
2086 set max_status_desc 0
2087 foreach i {
2088                 {__ {mc "Unmodified"}}
2089
2090                 {_M {mc "Modified, not staged"}}
2091                 {M_ {mc "Staged for commit"}}
2092                 {MM {mc "Portions staged for commit"}}
2093                 {MD {mc "Staged for commit, missing"}}
2094
2095                 {_T {mc "File type changed, not staged"}}
2096                 {MT {mc "File type changed, old type staged for commit"}}
2097                 {AT {mc "File type changed, old type staged for commit"}}
2098                 {T_ {mc "File type changed, staged"}}
2099                 {TM {mc "File type change staged, modification not staged"}}
2100                 {TD {mc "File type change staged, file missing"}}
2101
2102                 {_O {mc "Untracked, not staged"}}
2103                 {A_ {mc "Staged for commit"}}
2104                 {AM {mc "Portions staged for commit"}}
2105                 {AD {mc "Staged for commit, missing"}}
2106
2107                 {_D {mc "Missing"}}
2108                 {D_ {mc "Staged for removal"}}
2109                 {DO {mc "Staged for removal, still present"}}
2110
2111                 {_U {mc "Requires merge resolution"}}
2112                 {U_ {mc "Requires merge resolution"}}
2113                 {UU {mc "Requires merge resolution"}}
2114                 {UM {mc "Requires merge resolution"}}
2115                 {UD {mc "Requires merge resolution"}}
2116                 {UT {mc "Requires merge resolution"}}
2117         } {
2118         set text [eval [lindex $i 1]]
2119         if {$max_status_desc < [string length $text]} {
2120                 set max_status_desc [string length $text]
2121         }
2122         set all_descs([lindex $i 0]) $text
2123 }
2124 unset i
2125
2126 ######################################################################
2127 ##
2128 ## util
2129
2130 proc scrollbar2many {list mode args} {
2131         foreach w $list {eval $w $mode $args}
2132 }
2133
2134 proc many2scrollbar {list mode sb top bottom} {
2135         $sb set $top $bottom
2136         foreach w $list {$w $mode moveto $top}
2137 }
2138
2139 proc incr_font_size {font {amt 1}} {
2140         set sz [font configure $font -size]
2141         incr sz $amt
2142         font configure $font -size $sz
2143         font configure ${font}bold -size $sz
2144         font configure ${font}italic -size $sz
2145 }
2146
2147 ######################################################################
2148 ##
2149 ## ui commands
2150
2151 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2152
2153 proc do_gitk {revs {is_submodule false}} {
2154         global current_diff_path file_states current_diff_side ui_index
2155         global _gitworktree
2156
2157         # -- Always start gitk through whatever we were loaded with.  This
2158         #    lets us bypass using shell process on Windows systems.
2159         #
2160         set exe [_which gitk -script]
2161         set cmd [list [info nameofexecutable] $exe]
2162         if {$exe eq {}} {
2163                 error_popup [mc "Couldn't find gitk in PATH"]
2164         } else {
2165                 global env
2166
2167                 if {[info exists env(GIT_DIR)]} {
2168                         set old_GIT_DIR $env(GIT_DIR)
2169                 } else {
2170                         set old_GIT_DIR {}
2171                 }
2172
2173                 set pwd [pwd]
2174
2175                 if {!$is_submodule} {
2176                         if {![is_bare]} {
2177                                 cd $_gitworktree
2178                         }
2179                         set env(GIT_DIR) [file normalize [gitdir]]
2180                 } else {
2181                         cd $current_diff_path
2182                         if {$revs eq {--}} {
2183                                 set s $file_states($current_diff_path)
2184                                 set old_sha1 {}
2185                                 set new_sha1 {}
2186                                 switch -glob -- [lindex $s 0] {
2187                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2188                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2189                                 MM {
2190                                         if {$current_diff_side eq $ui_index} {
2191                                                 set old_sha1 [lindex [lindex $s 2] 1]
2192                                                 set new_sha1 [lindex [lindex $s 3] 1]
2193                                         } else {
2194                                                 set old_sha1 [lindex [lindex $s 3] 1]
2195                                         }
2196                                 }
2197                                 }
2198                                 set revs $old_sha1...$new_sha1
2199                         }
2200                         if {[info exists env(GIT_DIR)]} {
2201                                 unset env(GIT_DIR)
2202                         }
2203                 }
2204                 eval exec $cmd $revs "--" "--" &
2205
2206                 if {$old_GIT_DIR ne {}} {
2207                         set env(GIT_DIR) $old_GIT_DIR
2208                 }
2209                 cd $pwd
2210
2211                 ui_status $::starting_gitk_msg
2212                 after 10000 {
2213                         ui_ready $starting_gitk_msg
2214                 }
2215         }
2216 }
2217
2218 proc do_git_gui {} {
2219         global current_diff_path
2220
2221         # -- Always start git gui through whatever we were loaded with.  This
2222         #    lets us bypass using shell process on Windows systems.
2223         #
2224         set exe [list [_which git]]
2225         if {$exe eq {}} {
2226                 error_popup [mc "Couldn't find git gui in PATH"]
2227         } else {
2228                 global env
2229
2230                 if {[info exists env(GIT_DIR)]} {
2231                         set old_GIT_DIR $env(GIT_DIR)
2232                         unset env(GIT_DIR)
2233                 } else {
2234                         set old_GIT_DIR {}
2235                 }
2236
2237                 set pwd [pwd]
2238                 cd $current_diff_path
2239
2240                 eval exec $exe gui &
2241
2242                 if {$old_GIT_DIR ne {}} {
2243                         set env(GIT_DIR) $old_GIT_DIR
2244                 }
2245                 cd $pwd
2246
2247                 ui_status $::starting_gitk_msg
2248                 after 10000 {
2249                         ui_ready $starting_gitk_msg
2250                 }
2251         }
2252 }
2253
2254 proc do_explore {} {
2255         global _gitworktree
2256         set explorer {}
2257         if {[is_Cygwin] || [is_Windows]} {
2258                 set explorer "explorer.exe"
2259         } elseif {[is_MacOSX]} {
2260                 set explorer "open"
2261         } else {
2262                 # freedesktop.org-conforming system is our best shot
2263                 set explorer "xdg-open"
2264         }
2265         eval exec $explorer [list [file nativename $_gitworktree]] &
2266 }
2267
2268 set is_quitting 0
2269 set ret_code    1
2270
2271 proc terminate_me {win} {
2272         global ret_code
2273         if {$win ne {.}} return
2274         exit $ret_code
2275 }
2276
2277 proc do_quit {{rc {1}}} {
2278         global ui_comm is_quitting repo_config commit_type
2279         global GITGUI_BCK_exists GITGUI_BCK_i
2280         global ui_comm_spell
2281         global ret_code use_ttk
2282
2283         if {$is_quitting} return
2284         set is_quitting 1
2285
2286         if {[winfo exists $ui_comm]} {
2287                 # -- Stash our current commit buffer.
2288                 #
2289                 set save [gitdir GITGUI_MSG]
2290                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2291                         file rename -force [gitdir GITGUI_BCK] $save
2292                         set GITGUI_BCK_exists 0
2293                 } else {
2294                         set msg [string trim [$ui_comm get 0.0 end]]
2295                         regsub -all -line {[ \r\t]+$} $msg {} msg
2296                         if {(![string match amend* $commit_type]
2297                                 || [$ui_comm edit modified])
2298                                 && $msg ne {}} {
2299                                 catch {
2300                                         set fd [open $save w]
2301                                         fconfigure $fd -encoding utf-8
2302                                         puts -nonewline $fd $msg
2303                                         close $fd
2304                                 }
2305                         } else {
2306                                 catch {file delete $save}
2307                         }
2308                 }
2309
2310                 # -- Cancel our spellchecker if its running.
2311                 #
2312                 if {[info exists ui_comm_spell]} {
2313                         $ui_comm_spell stop
2314                 }
2315
2316                 # -- Remove our editor backup, its not needed.
2317                 #
2318                 after cancel $GITGUI_BCK_i
2319                 if {$GITGUI_BCK_exists} {
2320                         catch {file delete [gitdir GITGUI_BCK]}
2321                 }
2322
2323                 # -- Stash our current window geometry into this repository.
2324                 #
2325                 set cfg_wmstate [wm state .]
2326                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2327                         set rc_wmstate {}
2328                 }
2329                 if {$cfg_wmstate ne $rc_wmstate} {
2330                         catch {git config gui.wmstate $cfg_wmstate}
2331                 }
2332                 if {$cfg_wmstate eq {zoomed}} {
2333                         # on Windows wm geometry will lie about window
2334                         # position (but not size) when window is zoomed
2335                         # restore the window before querying wm geometry
2336                         wm state . normal
2337                 }
2338                 set cfg_geometry [list]
2339                 lappend cfg_geometry [wm geometry .]
2340                 if {$use_ttk} {
2341                         lappend cfg_geometry [.vpane sashpos 0]
2342                         lappend cfg_geometry [.vpane.files sashpos 0]
2343                 } else {
2344                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2345                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2346                 }
2347                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2348                         set rc_geometry {}
2349                 }
2350                 if {$cfg_geometry ne $rc_geometry} {
2351                         catch {git config gui.geometry $cfg_geometry}
2352                 }
2353         }
2354
2355         set ret_code $rc
2356
2357         # Briefly enable send again, working around Tk bug
2358         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2359         tk appname [appname]
2360
2361         destroy .
2362 }
2363
2364 proc do_rescan {} {
2365         rescan ui_ready
2366 }
2367
2368 proc ui_do_rescan {} {
2369         rescan {force_first_diff ui_ready}
2370 }
2371
2372 proc do_commit {} {
2373         commit_tree
2374 }
2375
2376 proc next_diff {{after {}}} {
2377         global next_diff_p next_diff_w next_diff_i
2378         show_diff $next_diff_p $next_diff_w {} {} $after
2379 }
2380
2381 proc find_anchor_pos {lst name} {
2382         set lid [lsearch -sorted -exact $lst $name]
2383
2384         if {$lid == -1} {
2385                 set lid 0
2386                 foreach lname $lst {
2387                         if {$lname >= $name} break
2388                         incr lid
2389                 }
2390         }
2391
2392         return $lid
2393 }
2394
2395 proc find_file_from {flist idx delta path mmask} {
2396         global file_states
2397
2398         set len [llength $flist]
2399         while {$idx >= 0 && $idx < $len} {
2400                 set name [lindex $flist $idx]
2401
2402                 if {$name ne $path && [info exists file_states($name)]} {
2403                         set state [lindex $file_states($name) 0]
2404
2405                         if {$mmask eq {} || [regexp $mmask $state]} {
2406                                 return $idx
2407                         }
2408                 }
2409
2410                 incr idx $delta
2411         }
2412
2413         return {}
2414 }
2415
2416 proc find_next_diff {w path {lno {}} {mmask {}}} {
2417         global next_diff_p next_diff_w next_diff_i
2418         global file_lists ui_index ui_workdir
2419
2420         set flist $file_lists($w)
2421         if {$lno eq {}} {
2422                 set lno [find_anchor_pos $flist $path]
2423         } else {
2424                 incr lno -1
2425         }
2426
2427         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2428                 if {$w eq $ui_index} {
2429                         set mmask "^$mmask"
2430                 } else {
2431                         set mmask "$mmask\$"
2432                 }
2433         }
2434
2435         set idx [find_file_from $flist $lno 1 $path $mmask]
2436         if {$idx eq {}} {
2437                 incr lno -1
2438                 set idx [find_file_from $flist $lno -1 $path $mmask]
2439         }
2440
2441         if {$idx ne {}} {
2442                 set next_diff_w $w
2443                 set next_diff_p [lindex $flist $idx]
2444                 set next_diff_i [expr {$idx+1}]
2445                 return 1
2446         } else {
2447                 return 0
2448         }
2449 }
2450
2451 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2452         global current_diff_path
2453
2454         if {$path ne $current_diff_path} {
2455                 return {}
2456         } elseif {[find_next_diff $w $path $lno $mmask]} {
2457                 return {next_diff;}
2458         } else {
2459                 return {reshow_diff;}
2460         }
2461 }
2462
2463 proc select_first_diff {after} {
2464         global ui_workdir
2465
2466         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2467             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2468                 next_diff $after
2469         } else {
2470                 uplevel #0 $after
2471         }
2472 }
2473
2474 proc force_first_diff {after} {
2475         global ui_workdir current_diff_path file_states
2476
2477         if {[info exists file_states($current_diff_path)]} {
2478                 set state [lindex $file_states($current_diff_path) 0]
2479         } else {
2480                 set state {OO}
2481         }
2482
2483         set reselect 0
2484         if {[string first {U} $state] >= 0} {
2485                 # Already a conflict, do nothing
2486         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2487                 set reselect 1
2488         } elseif {[string index $state 1] ne {O}} {
2489                 # Already a diff & no conflicts, do nothing
2490         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2491                 set reselect 1
2492         }
2493
2494         if {$reselect} {
2495                 next_diff $after
2496         } else {
2497                 uplevel #0 $after
2498         }
2499 }
2500
2501 proc toggle_or_diff {w x y} {
2502         global file_states file_lists current_diff_path ui_index ui_workdir
2503         global last_clicked selected_paths
2504
2505         set pos [split [$w index @$x,$y] .]
2506         set lno [lindex $pos 0]
2507         set col [lindex $pos 1]
2508         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2509         if {$path eq {}} {
2510                 set last_clicked {}
2511                 return
2512         }
2513
2514         set last_clicked [list $w $lno]
2515         array unset selected_paths
2516         $ui_index tag remove in_sel 0.0 end
2517         $ui_workdir tag remove in_sel 0.0 end
2518
2519         # Determine the state of the file
2520         if {[info exists file_states($path)]} {
2521                 set state [lindex $file_states($path) 0]
2522         } else {
2523                 set state {__}
2524         }
2525
2526         # Restage the file, or simply show the diff
2527         if {$col == 0 && $y > 1} {
2528                 # Conflicts need special handling
2529                 if {[string first {U} $state] >= 0} {
2530                         # $w must always be $ui_workdir, but...
2531                         if {$w ne $ui_workdir} { set lno {} }
2532                         merge_stage_workdir $path $lno
2533                         return
2534                 }
2535
2536                 if {[string index $state 1] eq {O}} {
2537                         set mmask {}
2538                 } else {
2539                         set mmask {[^O]}
2540                 }
2541
2542                 set after [next_diff_after_action $w $path $lno $mmask]
2543
2544                 if {$w eq $ui_index} {
2545                         update_indexinfo \
2546                                 "Unstaging [short_path $path] from commit" \
2547                                 [list $path] \
2548                                 [concat $after [list ui_ready]]
2549                 } elseif {$w eq $ui_workdir} {
2550                         update_index \
2551                                 "Adding [short_path $path]" \
2552                                 [list $path] \
2553                                 [concat $after [list ui_ready]]
2554                 }
2555         } else {
2556                 set selected_paths($path) 1
2557                 show_diff $path $w $lno
2558         }
2559 }
2560
2561 proc add_one_to_selection {w x y} {
2562         global file_lists last_clicked selected_paths
2563
2564         set lno [lindex [split [$w index @$x,$y] .] 0]
2565         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2566         if {$path eq {}} {
2567                 set last_clicked {}
2568                 return
2569         }
2570
2571         if {$last_clicked ne {}
2572                 && [lindex $last_clicked 0] ne $w} {
2573                 array unset selected_paths
2574                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2575         }
2576
2577         set last_clicked [list $w $lno]
2578         if {[catch {set in_sel $selected_paths($path)}]} {
2579                 set in_sel 0
2580         }
2581         if {$in_sel} {
2582                 unset selected_paths($path)
2583                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2584         } else {
2585                 set selected_paths($path) 1
2586                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2587         }
2588 }
2589
2590 proc add_range_to_selection {w x y} {
2591         global file_lists last_clicked selected_paths
2592
2593         if {[lindex $last_clicked 0] ne $w} {
2594                 toggle_or_diff $w $x $y
2595                 return
2596         }
2597
2598         set lno [lindex [split [$w index @$x,$y] .] 0]
2599         set lc [lindex $last_clicked 1]
2600         if {$lc < $lno} {
2601                 set begin $lc
2602                 set end $lno
2603         } else {
2604                 set begin $lno
2605                 set end $lc
2606         }
2607
2608         foreach path [lrange $file_lists($w) \
2609                 [expr {$begin - 1}] \
2610                 [expr {$end - 1}]] {
2611                 set selected_paths($path) 1
2612         }
2613         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2614 }
2615
2616 proc show_more_context {} {
2617         global repo_config
2618         if {$repo_config(gui.diffcontext) < 99} {
2619                 incr repo_config(gui.diffcontext)
2620                 reshow_diff
2621         }
2622 }
2623
2624 proc show_less_context {} {
2625         global repo_config
2626         if {$repo_config(gui.diffcontext) > 1} {
2627                 incr repo_config(gui.diffcontext) -1
2628                 reshow_diff
2629         }
2630 }
2631
2632 ######################################################################
2633 ##
2634 ## ui construction
2635
2636 set ui_comm {}
2637
2638 # -- Menu Bar
2639 #
2640 menu .mbar -tearoff 0
2641 if {[is_MacOSX]} {
2642         # -- Apple Menu (Mac OS X only)
2643         #
2644         .mbar add cascade -label Apple -menu .mbar.apple
2645         menu .mbar.apple
2646 }
2647 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2648 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2649 if {[is_enabled branch]} {
2650         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2651 }
2652 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2653         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2654 }
2655 if {[is_enabled transport]} {
2656         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2657         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2658 }
2659 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2660         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2661 }
2662
2663 # -- Repository Menu
2664 #
2665 menu .mbar.repository
2666
2667 if {![is_bare]} {
2668         .mbar.repository add command \
2669                 -label [mc "Explore Working Copy"] \
2670                 -command {do_explore}
2671 }
2672
2673 if {[is_Windows]} {
2674         .mbar.repository add command \
2675                 -label [mc "Git Bash"] \
2676                 -command {eval exec [auto_execok start] \
2677                                           [list "Git Bash" bash --login -l &]}
2678 }
2679
2680 if {[is_Windows] || ![is_bare]} {
2681         .mbar.repository add separator
2682 }
2683
2684 .mbar.repository add command \
2685         -label [mc "Browse Current Branch's Files"] \
2686         -command {browser::new $current_branch}
2687 set ui_browse_current [.mbar.repository index last]
2688 .mbar.repository add command \
2689         -label [mc "Browse Branch Files..."] \
2690         -command browser_open::dialog
2691 .mbar.repository add separator
2692
2693 .mbar.repository add command \
2694         -label [mc "Visualize Current Branch's History"] \
2695         -command {do_gitk $current_branch}
2696 set ui_visualize_current [.mbar.repository index last]
2697 .mbar.repository add command \
2698         -label [mc "Visualize All Branch History"] \
2699         -command {do_gitk --all}
2700 .mbar.repository add separator
2701
2702 proc current_branch_write {args} {
2703         global current_branch
2704         .mbar.repository entryconf $::ui_browse_current \
2705                 -label [mc "Browse %s's Files" $current_branch]
2706         .mbar.repository entryconf $::ui_visualize_current \
2707                 -label [mc "Visualize %s's History" $current_branch]
2708 }
2709 trace add variable current_branch write current_branch_write
2710
2711 if {[is_enabled multicommit]} {
2712         .mbar.repository add command -label [mc "Database Statistics"] \
2713                 -command do_stats
2714
2715         .mbar.repository add command -label [mc "Compress Database"] \
2716                 -command do_gc
2717
2718         .mbar.repository add command -label [mc "Verify Database"] \
2719                 -command do_fsck_objects
2720
2721         .mbar.repository add separator
2722
2723         if {[is_Cygwin]} {
2724                 .mbar.repository add command \
2725                         -label [mc "Create Desktop Icon"] \
2726                         -command do_cygwin_shortcut
2727         } elseif {[is_Windows]} {
2728                 .mbar.repository add command \
2729                         -label [mc "Create Desktop Icon"] \
2730                         -command do_windows_shortcut
2731         } elseif {[is_MacOSX]} {
2732                 .mbar.repository add command \
2733                         -label [mc "Create Desktop Icon"] \
2734                         -command do_macosx_app
2735         }
2736 }
2737
2738 if {[is_MacOSX]} {
2739         proc ::tk::mac::Quit {args} { do_quit }
2740 } else {
2741         .mbar.repository add command -label [mc Quit] \
2742                 -command do_quit \
2743                 -accelerator $M1T-Q
2744 }
2745
2746 # -- Edit Menu
2747 #
2748 menu .mbar.edit
2749 .mbar.edit add command -label [mc Undo] \
2750         -command {catch {[focus] edit undo}} \
2751         -accelerator $M1T-Z
2752 .mbar.edit add command -label [mc Redo] \
2753         -command {catch {[focus] edit redo}} \
2754         -accelerator $M1T-Y
2755 .mbar.edit add separator
2756 .mbar.edit add command -label [mc Cut] \
2757         -command {catch {tk_textCut [focus]}} \
2758         -accelerator $M1T-X
2759 .mbar.edit add command -label [mc Copy] \
2760         -command {catch {tk_textCopy [focus]}} \
2761         -accelerator $M1T-C
2762 .mbar.edit add command -label [mc Paste] \
2763         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2764         -accelerator $M1T-V
2765 .mbar.edit add command -label [mc Delete] \
2766         -command {catch {[focus] delete sel.first sel.last}} \
2767         -accelerator Del
2768 .mbar.edit add separator
2769 .mbar.edit add command -label [mc "Select All"] \
2770         -command {catch {[focus] tag add sel 0.0 end}} \
2771         -accelerator $M1T-A
2772
2773 # -- Branch Menu
2774 #
2775 if {[is_enabled branch]} {
2776         menu .mbar.branch
2777
2778         .mbar.branch add command -label [mc "Create..."] \
2779                 -command branch_create::dialog \
2780                 -accelerator $M1T-N
2781         lappend disable_on_lock [list .mbar.branch entryconf \
2782                 [.mbar.branch index last] -state]
2783
2784         .mbar.branch add command -label [mc "Checkout..."] \
2785                 -command branch_checkout::dialog \
2786                 -accelerator $M1T-O
2787         lappend disable_on_lock [list .mbar.branch entryconf \
2788                 [.mbar.branch index last] -state]
2789
2790         .mbar.branch add command -label [mc "Rename..."] \
2791                 -command branch_rename::dialog
2792         lappend disable_on_lock [list .mbar.branch entryconf \
2793                 [.mbar.branch index last] -state]
2794
2795         .mbar.branch add command -label [mc "Delete..."] \
2796                 -command branch_delete::dialog
2797         lappend disable_on_lock [list .mbar.branch entryconf \
2798                 [.mbar.branch index last] -state]
2799
2800         .mbar.branch add command -label [mc "Reset..."] \
2801                 -command merge::reset_hard
2802         lappend disable_on_lock [list .mbar.branch entryconf \
2803                 [.mbar.branch index last] -state]
2804 }
2805
2806 # -- Commit Menu
2807 #
2808 proc commit_btn_caption {} {
2809         if {[is_enabled nocommit]} {
2810                 return [mc "Done"]
2811         } else {
2812                 return [mc Commit@@verb]
2813         }
2814 }
2815
2816 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2817         menu .mbar.commit
2818
2819         if {![is_enabled nocommit]} {
2820                 .mbar.commit add radiobutton \
2821                         -label [mc "New Commit"] \
2822                         -command do_select_commit_type \
2823                         -variable selected_commit_type \
2824                         -value new
2825                 lappend disable_on_lock \
2826                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2827
2828                 .mbar.commit add radiobutton \
2829                         -label [mc "Amend Last Commit"] \
2830                         -command do_select_commit_type \
2831                         -variable selected_commit_type \
2832                         -value amend
2833                 lappend disable_on_lock \
2834                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2835
2836                 .mbar.commit add separator
2837         }
2838
2839         .mbar.commit add command -label [mc Rescan] \
2840                 -command ui_do_rescan \
2841                 -accelerator F5
2842         lappend disable_on_lock \
2843                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2844
2845         .mbar.commit add command -label [mc "Stage To Commit"] \
2846                 -command do_add_selection \
2847                 -accelerator $M1T-T
2848         lappend disable_on_lock \
2849                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2850
2851         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2852                 -command do_add_all \
2853                 -accelerator $M1T-I
2854         lappend disable_on_lock \
2855                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2856
2857         .mbar.commit add command -label [mc "Unstage From Commit"] \
2858                 -command do_unstage_selection \
2859                 -accelerator $M1T-U
2860         lappend disable_on_lock \
2861                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2862
2863         .mbar.commit add command -label [mc "Revert Changes"] \
2864                 -command do_revert_selection \
2865                 -accelerator $M1T-J
2866         lappend disable_on_lock \
2867                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2868
2869         .mbar.commit add separator
2870
2871         .mbar.commit add command -label [mc "Show Less Context"] \
2872                 -command show_less_context \
2873                 -accelerator $M1T-\-
2874
2875         .mbar.commit add command -label [mc "Show More Context"] \
2876                 -command show_more_context \
2877                 -accelerator $M1T-=
2878
2879         .mbar.commit add separator
2880
2881         if {![is_enabled nocommitmsg]} {
2882                 .mbar.commit add command -label [mc "Sign Off"] \
2883                         -command do_signoff \
2884                         -accelerator $M1T-S
2885         }
2886
2887         .mbar.commit add command -label [commit_btn_caption] \
2888                 -command do_commit \
2889                 -accelerator $M1T-Return
2890         lappend disable_on_lock \
2891                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2892 }
2893
2894 # -- Merge Menu
2895 #
2896 if {[is_enabled branch]} {
2897         menu .mbar.merge
2898         .mbar.merge add command -label [mc "Local Merge..."] \
2899                 -command merge::dialog \
2900                 -accelerator $M1T-M
2901         lappend disable_on_lock \
2902                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2903         .mbar.merge add command -label [mc "Abort Merge..."] \
2904                 -command merge::reset_hard
2905         lappend disable_on_lock \
2906                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2907 }
2908
2909 # -- Transport Menu
2910 #
2911 if {[is_enabled transport]} {
2912         menu .mbar.remote
2913
2914         .mbar.remote add command \
2915                 -label [mc "Add..."] \
2916                 -command remote_add::dialog \
2917                 -accelerator $M1T-A
2918         .mbar.remote add command \
2919                 -label [mc "Push..."] \
2920                 -command do_push_anywhere \
2921                 -accelerator $M1T-P
2922         .mbar.remote add command \
2923                 -label [mc "Delete Branch..."] \
2924                 -command remote_branch_delete::dialog
2925 }
2926
2927 if {[is_MacOSX]} {
2928         proc ::tk::mac::ShowPreferences {} {do_options}
2929 } else {
2930         # -- Edit Menu
2931         #
2932         .mbar.edit add separator
2933         .mbar.edit add command -label [mc "Options..."] \
2934                 -command do_options
2935 }
2936
2937 # -- Tools Menu
2938 #
2939 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2940         set tools_menubar .mbar.tools
2941         menu $tools_menubar
2942         $tools_menubar add separator
2943         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2944         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2945         set tools_tailcnt 3
2946         if {[array names repo_config guitool.*.cmd] ne {}} {
2947                 tools_populate_all
2948         }
2949 }
2950
2951 # -- Help Menu
2952 #
2953 .mbar add cascade -label [mc Help] -menu .mbar.help
2954 menu .mbar.help
2955
2956 if {[is_MacOSX]} {
2957         .mbar.apple add command -label [mc "About %s" [appname]] \
2958                 -command do_about
2959         .mbar.apple add separator
2960 } else {
2961         .mbar.help add command -label [mc "About %s" [appname]] \
2962                 -command do_about
2963 }
2964 . configure -menu .mbar
2965
2966 set doc_path [githtmldir]
2967 if {$doc_path ne {}} {
2968         set doc_path [file join $doc_path index.html]
2969
2970         if {[is_Cygwin]} {
2971                 set doc_path [exec cygpath --mixed $doc_path]
2972         }
2973 }
2974
2975 if {[file isfile $doc_path]} {
2976         set doc_url "file:$doc_path"
2977 } else {
2978         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2979 }
2980
2981 proc start_browser {url} {
2982         git "web--browse" $url
2983 }
2984
2985 .mbar.help add command -label [mc "Online Documentation"] \
2986         -command [list start_browser $doc_url]
2987
2988 .mbar.help add command -label [mc "Show SSH Key"] \
2989         -command do_ssh_key
2990
2991 unset doc_path doc_url
2992
2993 # -- Standard bindings
2994 #
2995 wm protocol . WM_DELETE_WINDOW do_quit
2996 bind all <$M1B-Key-q> do_quit
2997 bind all <$M1B-Key-Q> do_quit
2998 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2999 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3000
3001 set subcommand_args {}
3002 proc usage {} {
3003         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3004         if {[tk windowingsystem] eq "win32"} {
3005                 wm withdraw .
3006                 tk_messageBox -icon info -message $s \
3007                         -title [mc "Usage"]
3008         } else {
3009                 puts stderr $s
3010         }
3011         exit 1
3012 }
3013
3014 proc normalize_relpath {path} {
3015         set elements {}
3016         foreach item [file split $path] {
3017                 if {$item eq {.}} continue
3018                 if {$item eq {..} && [llength $elements] > 0
3019                     && [lindex $elements end] ne {..}} {
3020                         set elements [lrange $elements 0 end-1]
3021                         continue
3022                 }
3023                 lappend elements $item
3024         }
3025         return [eval file join $elements]
3026 }
3027
3028 # -- Not a normal commit type invocation?  Do that instead!
3029 #
3030 switch -- $subcommand {
3031 browser -
3032 blame {
3033         if {$subcommand eq "blame"} {
3034                 set subcommand_args {[--line=<num>] rev? path}
3035         } else {
3036                 set subcommand_args {rev? path}
3037         }
3038         if {$argv eq {}} usage
3039         set head {}
3040         set path {}
3041         set jump_spec {}
3042         set is_path 0
3043         foreach a $argv {
3044                 set p [file join $_prefix $a]
3045
3046                 if {$is_path || [file exists $p]} {
3047                         if {$path ne {}} usage
3048                         set path [normalize_relpath $p]
3049                         break
3050                 } elseif {$a eq {--}} {
3051                         if {$path ne {}} {
3052                                 if {$head ne {}} usage
3053                                 set head $path
3054                                 set path {}
3055                         }
3056                         set is_path 1
3057                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3058                         if {$jump_spec ne {} || $head ne {}} usage
3059                         set jump_spec [list $lnum]
3060                 } elseif {$head eq {}} {
3061                         if {$head ne {}} usage
3062                         set head $a
3063                         set is_path 1
3064                 } else {
3065                         usage
3066                 }
3067         }
3068         unset is_path
3069
3070         if {$head ne {} && $path eq {}} {
3071                 if {[string index $head 0] eq {/}} {
3072                         set path [normalize_relpath $head]
3073                         set head {}
3074                 } else {
3075                         set path [normalize_relpath $_prefix$head]
3076                         set head {}
3077                 }
3078         }
3079
3080         if {$head eq {}} {
3081                 load_current_branch
3082         } else {
3083                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3084                         if {[catch {
3085                                         set head [git rev-parse --verify $head]
3086                                 } err]} {
3087                                 if {[tk windowingsystem] eq "win32"} {
3088                                         tk_messageBox -icon error -title [mc Error] -message $err
3089                                 } else {
3090                                         puts stderr $err
3091                                 }
3092                                 exit 1
3093                         }
3094                 }
3095                 set current_branch $head
3096         }
3097
3098         wm deiconify .
3099         switch -- $subcommand {
3100         browser {
3101                 if {$jump_spec ne {}} usage
3102                 if {$head eq {}} {
3103                         if {$path ne {} && [file isdirectory $path]} {
3104                                 set head $current_branch
3105                         } else {
3106                                 set head $path
3107                                 set path {}
3108                         }
3109                 }
3110                 browser::new $head $path
3111         }
3112         blame   {
3113                 if {$head eq {} && ![file exists $path]} {
3114                         catch {wm withdraw .}
3115                         tk_messageBox \
3116                                 -icon error \
3117                                 -type ok \
3118                                 -title [mc "git-gui: fatal error"] \
3119                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3120                         exit 1
3121                 }
3122                 blame::new $head $path $jump_spec
3123         }
3124         }
3125         return
3126 }
3127 citool -
3128 gui {
3129         if {[llength $argv] != 0} {
3130                 usage
3131         }
3132         # fall through to setup UI for commits
3133 }
3134 default {
3135         set err "usage: $argv0 \[{blame|browser|citool}\]"
3136         if {[tk windowingsystem] eq "win32"} {
3137                 wm withdraw .
3138                 tk_messageBox -icon error -message $err \
3139                         -title [mc "Usage"]
3140         } else {
3141                 puts stderr $err
3142         }
3143         exit 1
3144 }
3145 }
3146
3147 # -- Branch Control
3148 #
3149 ${NS}::frame .branch
3150 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3151 ${NS}::label .branch.l1 \
3152         -text [mc "Current Branch:"] \
3153         -anchor w \
3154         -justify left
3155 ${NS}::label .branch.cb \
3156         -textvariable current_branch \
3157         -anchor w \
3158         -justify left
3159 pack .branch.l1 -side left
3160 pack .branch.cb -side left -fill x
3161 pack .branch -side top -fill x
3162
3163 # -- Main Window Layout
3164 #
3165 ${NS}::panedwindow .vpane -orient horizontal
3166 ${NS}::panedwindow .vpane.files -orient vertical
3167 if {$use_ttk} {
3168         .vpane add .vpane.files
3169 } else {
3170         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3171 }
3172 pack .vpane -anchor n -side top -fill both -expand 1
3173
3174 # -- Index File List
3175 #
3176 ${NS}::frame .vpane.files.index -height 100 -width 200
3177 tlabel .vpane.files.index.title \
3178         -text [mc "Staged Changes (Will Commit)"] \
3179         -background lightgreen -foreground black
3180 text $ui_index -background white -foreground black \
3181         -borderwidth 0 \
3182         -width 20 -height 10 \
3183         -wrap none \
3184         -cursor $cursor_ptr \
3185         -xscrollcommand {.vpane.files.index.sx set} \
3186         -yscrollcommand {.vpane.files.index.sy set} \
3187         -state disabled
3188 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3189 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3190 pack .vpane.files.index.title -side top -fill x
3191 pack .vpane.files.index.sx -side bottom -fill x
3192 pack .vpane.files.index.sy -side right -fill y
3193 pack $ui_index -side left -fill both -expand 1
3194
3195 # -- Working Directory File List
3196 #
3197 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3198 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3199         -background lightsalmon -foreground black
3200 text $ui_workdir -background white -foreground black \
3201         -borderwidth 0 \
3202         -width 20 -height 10 \
3203         -wrap none \
3204         -cursor $cursor_ptr \
3205         -xscrollcommand {.vpane.files.workdir.sx set} \
3206         -yscrollcommand {.vpane.files.workdir.sy set} \
3207         -state disabled
3208 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3209 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3210 pack .vpane.files.workdir.title -side top -fill x
3211 pack .vpane.files.workdir.sx -side bottom -fill x
3212 pack .vpane.files.workdir.sy -side right -fill y
3213 pack $ui_workdir -side left -fill both -expand 1
3214
3215 .vpane.files add .vpane.files.workdir
3216 .vpane.files add .vpane.files.index
3217 if {!$use_ttk} {
3218         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3219         .vpane.files paneconfigure .vpane.files.index -sticky news
3220 }
3221
3222 foreach i [list $ui_index $ui_workdir] {
3223         rmsel_tag $i
3224         $i tag conf in_diff -background [$i tag cget in_sel -background]
3225 }
3226 unset i
3227
3228 # -- Diff and Commit Area
3229 #
3230 if {$have_tk85} {
3231         ${NS}::panedwindow .vpane.lower -orient vertical
3232         ${NS}::frame .vpane.lower.commarea
3233         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3234         .vpane.lower add .vpane.lower.diff
3235         .vpane.lower add .vpane.lower.commarea
3236         .vpane add .vpane.lower
3237         if {$use_ttk} {
3238                 .vpane.lower pane .vpane.lower.diff -weight 1
3239                 .vpane.lower pane .vpane.lower.commarea -weight 0
3240         } else {
3241                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3242                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3243         }
3244 } else {
3245         frame .vpane.lower -height 300 -width 400
3246         frame .vpane.lower.commarea
3247         frame .vpane.lower.diff -relief sunken -borderwidth 1
3248         pack .vpane.lower.diff -fill both -expand 1
3249         pack .vpane.lower.commarea -side bottom -fill x
3250         .vpane add .vpane.lower
3251         .vpane paneconfigure .vpane.lower -sticky nsew
3252 }
3253
3254 # -- Commit Area Buttons
3255 #
3256 ${NS}::frame .vpane.lower.commarea.buttons
3257 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3258         -anchor w \
3259         -justify left
3260 pack .vpane.lower.commarea.buttons.l -side top -fill x
3261 pack .vpane.lower.commarea.buttons -side left -fill y
3262
3263 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3264         -command ui_do_rescan
3265 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3266 lappend disable_on_lock \
3267         {.vpane.lower.commarea.buttons.rescan conf -state}
3268
3269 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3270         -command do_add_all
3271 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3272 lappend disable_on_lock \
3273         {.vpane.lower.commarea.buttons.incall conf -state}
3274
3275 if {![is_enabled nocommitmsg]} {
3276         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3277                 -command do_signoff
3278         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3279 }
3280
3281 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3282         -command do_commit
3283 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3284 lappend disable_on_lock \
3285         {.vpane.lower.commarea.buttons.commit conf -state}
3286
3287 if {![is_enabled nocommit]} {
3288         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3289                 -command do_push_anywhere
3290         pack .vpane.lower.commarea.buttons.push -side top -fill x
3291 }
3292
3293 # -- Commit Message Buffer
3294 #
3295 ${NS}::frame .vpane.lower.commarea.buffer
3296 ${NS}::frame .vpane.lower.commarea.buffer.header
3297 set ui_comm .vpane.lower.commarea.buffer.t
3298 set ui_coml .vpane.lower.commarea.buffer.header.l
3299
3300 if {![is_enabled nocommit]} {
3301         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3302                 -text [mc "New Commit"] \
3303                 -command do_select_commit_type \
3304                 -variable selected_commit_type \
3305                 -value new
3306         lappend disable_on_lock \
3307                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3308         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3309                 -text [mc "Amend Last Commit"] \
3310                 -command do_select_commit_type \
3311                 -variable selected_commit_type \
3312                 -value amend
3313         lappend disable_on_lock \
3314                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3315 }
3316
3317 ${NS}::label $ui_coml \
3318         -anchor w \
3319         -justify left
3320 proc trace_commit_type {varname args} {
3321         global ui_coml commit_type
3322         switch -glob -- $commit_type {
3323         initial       {set txt [mc "Initial Commit Message:"]}
3324         amend         {set txt [mc "Amended Commit Message:"]}
3325         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3326         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3327         merge         {set txt [mc "Merge Commit Message:"]}
3328         *             {set txt [mc "Commit Message:"]}
3329         }
3330         $ui_coml conf -text $txt
3331 }
3332 trace add variable commit_type write trace_commit_type
3333 pack $ui_coml -side left -fill x
3334
3335 if {![is_enabled nocommit]} {
3336         pack .vpane.lower.commarea.buffer.header.amend -side right
3337         pack .vpane.lower.commarea.buffer.header.new -side right
3338 }
3339
3340 text $ui_comm -background white -foreground black \
3341         -borderwidth 1 \
3342         -undo true \
3343         -maxundo 20 \
3344         -autoseparators true \
3345         -relief sunken \
3346         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3347         -font font_diff \
3348         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3349 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3350         -command [list $ui_comm yview]
3351 pack .vpane.lower.commarea.buffer.header -side top -fill x
3352 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3353 pack $ui_comm -side left -fill y
3354 pack .vpane.lower.commarea.buffer -side left -fill y
3355
3356 # -- Commit Message Buffer Context Menu
3357 #
3358 set ctxm .vpane.lower.commarea.buffer.ctxm
3359 menu $ctxm -tearoff 0
3360 $ctxm add command \
3361         -label [mc Cut] \
3362         -command {tk_textCut $ui_comm}
3363 $ctxm add command \
3364         -label [mc Copy] \
3365         -command {tk_textCopy $ui_comm}
3366 $ctxm add command \
3367         -label [mc Paste] \
3368         -command {tk_textPaste $ui_comm}
3369 $ctxm add command \
3370         -label [mc Delete] \
3371         -command {catch {$ui_comm delete sel.first sel.last}}
3372 $ctxm add separator
3373 $ctxm add command \
3374         -label [mc "Select All"] \
3375         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3376 $ctxm add command \
3377         -label [mc "Copy All"] \
3378         -command {
3379                 $ui_comm tag add sel 0.0 end
3380                 tk_textCopy $ui_comm
3381                 $ui_comm tag remove sel 0.0 end
3382         }
3383 $ctxm add separator
3384 $ctxm add command \
3385         -label [mc "Sign Off"] \
3386         -command do_signoff
3387 set ui_comm_ctxm $ctxm
3388
3389 # -- Diff Header
3390 #
3391 proc trace_current_diff_path {varname args} {
3392         global current_diff_path diff_actions file_states
3393         if {$current_diff_path eq {}} {
3394                 set s {}
3395                 set f {}
3396                 set p {}
3397                 set o disabled
3398         } else {
3399                 set p $current_diff_path
3400                 set s [mapdesc [lindex $file_states($p) 0] $p]
3401                 set f [mc "File:"]
3402                 set p [escape_path $p]
3403                 set o normal
3404         }
3405
3406         .vpane.lower.diff.header.status configure -text $s
3407         .vpane.lower.diff.header.file configure -text $f
3408         .vpane.lower.diff.header.path configure -text $p
3409         foreach w $diff_actions {
3410                 uplevel #0 $w $o
3411         }
3412 }
3413 trace add variable current_diff_path write trace_current_diff_path
3414
3415 gold_frame .vpane.lower.diff.header
3416 tlabel .vpane.lower.diff.header.status \
3417         -background gold \
3418         -foreground black \
3419         -width $max_status_desc \
3420         -anchor w \
3421         -justify left
3422 tlabel .vpane.lower.diff.header.file \
3423         -background gold \
3424         -foreground black \
3425         -anchor w \
3426         -justify left
3427 tlabel .vpane.lower.diff.header.path \
3428         -background gold \
3429         -foreground black \
3430         -anchor w \
3431         -justify left
3432 pack .vpane.lower.diff.header.status -side left
3433 pack .vpane.lower.diff.header.file -side left
3434 pack .vpane.lower.diff.header.path -fill x
3435 set ctxm .vpane.lower.diff.header.ctxm
3436 menu $ctxm -tearoff 0
3437 $ctxm add command \
3438         -label [mc Copy] \
3439         -command {
3440                 clipboard clear
3441                 clipboard append \
3442                         -format STRING \
3443                         -type STRING \
3444                         -- $current_diff_path
3445         }
3446 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3447 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3448
3449 # -- Diff Body
3450 #
3451 ${NS}::frame .vpane.lower.diff.body
3452 set ui_diff .vpane.lower.diff.body.t
3453 text $ui_diff -background white -foreground black \
3454         -borderwidth 0 \
3455         -width 80 -height 5 -wrap none \
3456         -font font_diff \
3457         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3458         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3459         -state disabled
3460 catch {$ui_diff configure -tabstyle wordprocessor}
3461 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3462         -command [list $ui_diff xview]
3463 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3464         -command [list $ui_diff yview]
3465 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3466 pack .vpane.lower.diff.body.sby -side right -fill y
3467 pack $ui_diff -side left -fill both -expand 1
3468 pack .vpane.lower.diff.header -side top -fill x
3469 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3470
3471 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3472         $ui_diff tag configure clr4$n -background $c
3473         $ui_diff tag configure clri4$n -foreground $c
3474         $ui_diff tag configure clr3$n -foreground $c
3475         $ui_diff tag configure clri3$n -background $c
3476 }
3477 $ui_diff tag configure clr1 -font font_diffbold
3478 $ui_diff tag configure clr4 -underline 1
3479
3480 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3481
3482 $ui_diff tag conf d_cr -elide true
3483 $ui_diff tag conf d_@ -font font_diffbold
3484 $ui_diff tag conf d_+ -foreground {#00a000}
3485 $ui_diff tag conf d_- -foreground red
3486
3487 $ui_diff tag conf d_++ -foreground {#00a000}
3488 $ui_diff tag conf d_-- -foreground red
3489 $ui_diff tag conf d_+s \
3490         -foreground {#00a000} \
3491         -background {#e2effa}
3492 $ui_diff tag conf d_-s \
3493         -foreground red \
3494         -background {#e2effa}
3495 $ui_diff tag conf d_s+ \
3496         -foreground {#00a000} \
3497         -background ivory1
3498 $ui_diff tag conf d_s- \
3499         -foreground red \
3500         -background ivory1
3501
3502 $ui_diff tag conf d< \
3503         -foreground orange \
3504         -font font_diffbold
3505 $ui_diff tag conf d= \
3506         -foreground orange \
3507         -font font_diffbold
3508 $ui_diff tag conf d> \
3509         -foreground orange \
3510         -font font_diffbold
3511
3512 $ui_diff tag raise sel
3513
3514 # -- Diff Body Context Menu
3515 #
3516
3517 proc create_common_diff_popup {ctxm} {
3518         $ctxm add command \
3519                 -label [mc Refresh] \
3520                 -command reshow_diff
3521         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3522         $ctxm add command \
3523                 -label [mc Copy] \
3524                 -command {tk_textCopy $ui_diff}
3525         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3526         $ctxm add command \
3527                 -label [mc "Select All"] \
3528                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3529         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3530         $ctxm add command \
3531                 -label [mc "Copy All"] \
3532                 -command {
3533                         $ui_diff tag add sel 0.0 end
3534                         tk_textCopy $ui_diff
3535                         $ui_diff tag remove sel 0.0 end
3536                 }
3537         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3538         $ctxm add separator
3539         $ctxm add command \
3540                 -label [mc "Decrease Font Size"] \
3541                 -command {incr_font_size font_diff -1}
3542         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543         $ctxm add command \
3544                 -label [mc "Increase Font Size"] \
3545                 -command {incr_font_size font_diff 1}
3546         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3547         $ctxm add separator
3548         set emenu $ctxm.enc
3549         menu $emenu
3550         build_encoding_menu $emenu [list force_diff_encoding]
3551         $ctxm add cascade \
3552                 -label [mc "Encoding"] \
3553                 -menu $emenu
3554         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3555         $ctxm add separator
3556         $ctxm add command -label [mc "Options..."] \
3557                 -command do_options
3558 }
3559
3560 set ctxm .vpane.lower.diff.body.ctxm
3561 menu $ctxm -tearoff 0
3562 $ctxm add command \
3563         -label [mc "Apply/Reverse Hunk"] \
3564         -command {apply_hunk $cursorX $cursorY}
3565 set ui_diff_applyhunk [$ctxm index last]
3566 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3567 $ctxm add command \
3568         -label [mc "Apply/Reverse Line"] \
3569         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3570 set ui_diff_applyline [$ctxm index last]
3571 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3572 $ctxm add separator
3573 $ctxm add command \
3574         -label [mc "Show Less Context"] \
3575         -command show_less_context
3576 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3577 $ctxm add command \
3578         -label [mc "Show More Context"] \
3579         -command show_more_context
3580 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3581 $ctxm add separator
3582 create_common_diff_popup $ctxm
3583
3584 set ctxmmg .vpane.lower.diff.body.ctxmmg
3585 menu $ctxmmg -tearoff 0
3586 $ctxmmg add command \
3587         -label [mc "Run Merge Tool"] \
3588         -command {merge_resolve_tool}
3589 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3590 $ctxmmg add separator
3591 $ctxmmg add command \
3592         -label [mc "Use Remote Version"] \
3593         -command {merge_resolve_one 3}
3594 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3595 $ctxmmg add command \
3596         -label [mc "Use Local Version"] \
3597         -command {merge_resolve_one 2}
3598 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3599 $ctxmmg add command \
3600         -label [mc "Revert To Base"] \
3601         -command {merge_resolve_one 1}
3602 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3603 $ctxmmg add separator
3604 $ctxmmg add command \
3605         -label [mc "Show Less Context"] \
3606         -command show_less_context
3607 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3608 $ctxmmg add command \
3609         -label [mc "Show More Context"] \
3610         -command show_more_context
3611 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3612 $ctxmmg add separator
3613 create_common_diff_popup $ctxmmg
3614
3615 set ctxmsm .vpane.lower.diff.body.ctxmsm
3616 menu $ctxmsm -tearoff 0
3617 $ctxmsm add command \
3618         -label [mc "Visualize These Changes In The Submodule"] \
3619         -command {do_gitk -- true}
3620 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3621 $ctxmsm add command \
3622         -label [mc "Visualize Current Branch History In The Submodule"] \
3623         -command {do_gitk {} true}
3624 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3625 $ctxmsm add command \
3626         -label [mc "Visualize All Branch History In The Submodule"] \
3627         -command {do_gitk --all true}
3628 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3629 $ctxmsm add separator
3630 $ctxmsm add command \
3631         -label [mc "Start git gui In The Submodule"] \
3632         -command {do_git_gui}
3633 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3634 $ctxmsm add separator
3635 create_common_diff_popup $ctxmsm
3636
3637 proc has_textconv {path} {
3638         if {[is_config_false gui.textconv]} {
3639                 return 0
3640         }
3641         set filter [gitattr $path diff set]
3642         set textconv [get_config [join [list diff $filter textconv] .]]
3643         if {$filter ne {set} && $textconv ne {}} {
3644                 return 1
3645         } else {
3646                 return 0
3647         }
3648 }
3649
3650 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3651         global current_diff_path file_states
3652         set ::cursorX $x
3653         set ::cursorY $y
3654         if {[info exists file_states($current_diff_path)]} {
3655                 set state [lindex $file_states($current_diff_path) 0]
3656         } else {
3657                 set state {__}
3658         }
3659         if {[string first {U} $state] >= 0} {
3660                 tk_popup $ctxmmg $X $Y
3661         } elseif {$::is_submodule_diff} {
3662                 tk_popup $ctxmsm $X $Y
3663         } else {
3664                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3665                 if {$::ui_index eq $::current_diff_side} {
3666                         set l [mc "Unstage Hunk From Commit"]
3667                         if {$has_range} {
3668                                 set t [mc "Unstage Lines From Commit"]
3669                         } else {
3670                                 set t [mc "Unstage Line From Commit"]
3671                         }
3672                 } else {
3673                         set l [mc "Stage Hunk For Commit"]
3674                         if {$has_range} {
3675                                 set t [mc "Stage Lines For Commit"]
3676                         } else {
3677                                 set t [mc "Stage Line For Commit"]
3678                         }
3679                 }
3680                 if {$::is_3way_diff
3681                         || $current_diff_path eq {}
3682                         || {__} eq $state
3683                         || {_O} eq $state
3684                         || [string match {?T} $state]
3685                         || [string match {T?} $state]
3686                         || [has_textconv $current_diff_path]} {
3687                         set s disabled
3688                 } else {
3689                         set s normal
3690                 }
3691                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3692                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3693                 tk_popup $ctxm $X $Y
3694         }
3695 }
3696 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3697
3698 # -- Status Bar
3699 #
3700 set main_status [::status_bar::new .status]
3701 pack .status -anchor w -side bottom -fill x
3702 $main_status show [mc "Initializing..."]
3703
3704 # -- Load geometry
3705 #
3706 proc on_ttk_pane_mapped {w pane pos} {
3707         bind $w <Map> {}
3708         after 0 [list after idle [list $w sashpos $pane $pos]]
3709 }
3710 proc on_tk_pane_mapped {w pane x y} {
3711         bind $w <Map> {}
3712         after 0 [list after idle [list $w sash place $pane $x $y]]
3713 }
3714 proc on_application_mapped {} {
3715         global repo_config use_ttk
3716         bind . <Map> {}
3717         set gm $repo_config(gui.geometry)
3718         if {$use_ttk} {
3719                 bind .vpane <Map> \
3720                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3721                 bind .vpane.files <Map> \
3722                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3723         } else {
3724                 bind .vpane <Map> \
3725                     [list on_tk_pane_mapped %W 0 \
3726                          [lindex $gm 1] \
3727                          [lindex [.vpane sash coord 0] 1]]
3728                 bind .vpane.files <Map> \
3729                     [list on_tk_pane_mapped %W 0 \
3730                          [lindex [.vpane.files sash coord 0] 0] \
3731                          [lindex $gm 2]]
3732         }
3733         wm geometry . [lindex $gm 0]
3734 }
3735 if {[info exists repo_config(gui.geometry)]} {
3736         bind . <Map> [list on_application_mapped]
3737         wm geometry . [lindex $repo_config(gui.geometry) 0]
3738 }
3739
3740 # -- Load window state
3741 #
3742 if {[info exists repo_config(gui.wmstate)]} {
3743         catch {wm state . $repo_config(gui.wmstate)}
3744 }
3745
3746 # -- Key Bindings
3747 #
3748 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3749 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3750 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3751 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3752 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3753 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3754 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3755 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3756 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3757 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3758 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3759 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3760 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3761 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3762 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3763 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3764 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3765 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3766 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3767 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3768 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3769 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3770
3771 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3772 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3773 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3774 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3775 bind $ui_diff <$M1B-Key-v> {break}
3776 bind $ui_diff <$M1B-Key-V> {break}
3777 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3778 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3779 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3780 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3781 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3782 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3783 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3784 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3785 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3786 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3787 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3788 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3789 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3790 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3791 bind $ui_diff <Button-1>   {focus %W}
3792
3793 if {[is_enabled branch]} {
3794         bind . <$M1B-Key-n> branch_create::dialog
3795         bind . <$M1B-Key-N> branch_create::dialog
3796         bind . <$M1B-Key-o> branch_checkout::dialog
3797         bind . <$M1B-Key-O> branch_checkout::dialog
3798         bind . <$M1B-Key-m> merge::dialog
3799         bind . <$M1B-Key-M> merge::dialog
3800 }
3801 if {[is_enabled transport]} {
3802         bind . <$M1B-Key-p> do_push_anywhere
3803         bind . <$M1B-Key-P> do_push_anywhere
3804 }
3805
3806 bind .   <Key-F5>     ui_do_rescan
3807 bind .   <$M1B-Key-r> ui_do_rescan
3808 bind .   <$M1B-Key-R> ui_do_rescan
3809 bind .   <$M1B-Key-s> do_signoff
3810 bind .   <$M1B-Key-S> do_signoff
3811 bind .   <$M1B-Key-t> do_add_selection
3812 bind .   <$M1B-Key-T> do_add_selection
3813 bind .   <$M1B-Key-u> do_unstage_selection
3814 bind .   <$M1B-Key-U> do_unstage_selection
3815 bind .   <$M1B-Key-j> do_revert_selection
3816 bind .   <$M1B-Key-J> do_revert_selection
3817 bind .   <$M1B-Key-i> do_add_all
3818 bind .   <$M1B-Key-I> do_add_all
3819 bind .   <$M1B-Key-minus> {show_less_context;break}
3820 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3821 bind .   <$M1B-Key-equal> {show_more_context;break}
3822 bind .   <$M1B-Key-plus> {show_more_context;break}
3823 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3824 bind .   <$M1B-Key-Return> do_commit
3825 foreach i [list $ui_index $ui_workdir] {
3826         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3827         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3828         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3829 }
3830 unset i
3831
3832 set file_lists($ui_index) [list]
3833 set file_lists($ui_workdir) [list]
3834
3835 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3836 focus -force $ui_comm
3837
3838 # -- Warn the user about environmental problems.  Cygwin's Tcl
3839 #    does *not* pass its env array onto any processes it spawns.
3840 #    This means that git processes get none of our environment.
3841 #
3842 if {[is_Cygwin]} {
3843         set ignored_env 0
3844         set suggest_user {}
3845         set msg [mc "Possible environment issues exist.
3846
3847 The following environment variables are probably
3848 going to be ignored by any Git subprocess run
3849 by %s:
3850
3851 " [appname]]
3852         foreach name [array names env] {
3853                 switch -regexp -- $name {
3854                 {^GIT_INDEX_FILE$} -
3855                 {^GIT_OBJECT_DIRECTORY$} -
3856                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3857                 {^GIT_DIFF_OPTS$} -
3858                 {^GIT_EXTERNAL_DIFF$} -
3859                 {^GIT_PAGER$} -
3860                 {^GIT_TRACE$} -
3861                 {^GIT_CONFIG$} -
3862                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3863                         append msg " - $name\n"
3864                         incr ignored_env
3865                 }
3866                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3867                         append msg " - $name\n"
3868                         incr ignored_env
3869                         set suggest_user $name
3870                 }
3871                 }
3872         }
3873         if {$ignored_env > 0} {
3874                 append msg [mc "
3875 This is due to a known issue with the
3876 Tcl binary distributed by Cygwin."]
3877
3878                 if {$suggest_user ne {}} {
3879                         append msg [mc "
3880
3881 A good replacement for %s
3882 is placing values for the user.name and
3883 user.email settings into your personal
3884 ~/.gitconfig file.
3885 " $suggest_user]
3886                 }
3887                 warn_popup $msg
3888         }
3889         unset ignored_env msg suggest_user name
3890 }
3891
3892 # -- Only initialize complex UI if we are going to stay running.
3893 #
3894 if {[is_enabled transport]} {
3895         load_all_remotes
3896
3897         set n [.mbar.remote index end]
3898         populate_remotes_menu
3899         set n [expr {[.mbar.remote index end] - $n}]
3900         if {$n > 0} {
3901                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3902                 .mbar.remote insert $n separator
3903         }
3904         unset n
3905 }
3906
3907 if {[winfo exists $ui_comm]} {
3908         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3909
3910         # -- If both our backup and message files exist use the
3911         #    newer of the two files to initialize the buffer.
3912         #
3913         if {$GITGUI_BCK_exists} {
3914                 set m [gitdir GITGUI_MSG]
3915                 if {[file isfile $m]} {
3916                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3917                                 catch {file delete [gitdir GITGUI_MSG]}
3918                         } else {
3919                                 $ui_comm delete 0.0 end
3920                                 $ui_comm edit reset
3921                                 $ui_comm edit modified false
3922                                 catch {file delete [gitdir GITGUI_BCK]}
3923                                 set GITGUI_BCK_exists 0
3924                         }
3925                 }
3926                 unset m
3927         }
3928
3929         proc backup_commit_buffer {} {
3930                 global ui_comm GITGUI_BCK_exists
3931
3932                 set m [$ui_comm edit modified]
3933                 if {$m || $GITGUI_BCK_exists} {
3934                         set msg [string trim [$ui_comm get 0.0 end]]
3935                         regsub -all -line {[ \r\t]+$} $msg {} msg
3936
3937                         if {$msg eq {}} {
3938                                 if {$GITGUI_BCK_exists} {
3939                                         catch {file delete [gitdir GITGUI_BCK]}
3940                                         set GITGUI_BCK_exists 0
3941                                 }
3942                         } elseif {$m} {
3943                                 catch {
3944                                         set fd [open [gitdir GITGUI_BCK] w]
3945                                         fconfigure $fd -encoding utf-8
3946                                         puts -nonewline $fd $msg
3947                                         close $fd
3948                                         set GITGUI_BCK_exists 1
3949                                 }
3950                         }
3951
3952                         $ui_comm edit modified false
3953                 }
3954
3955                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3956         }
3957
3958         backup_commit_buffer
3959
3960         # -- If the user has aspell available we can drive it
3961         #    in pipe mode to spellcheck the commit message.
3962         #
3963         set spell_cmd [list |]
3964         set spell_dict [get_config gui.spellingdictionary]
3965         lappend spell_cmd aspell
3966         if {$spell_dict ne {}} {
3967                 lappend spell_cmd --master=$spell_dict
3968         }
3969         lappend spell_cmd --mode=none
3970         lappend spell_cmd --encoding=utf-8
3971         lappend spell_cmd pipe
3972         if {$spell_dict eq {none}
3973          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3974                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3975         } else {
3976                 set ui_comm_spell [spellcheck::init \
3977                         $spell_fd \
3978                         $ui_comm \
3979                         $ui_comm_ctxm \
3980                 ]
3981         }
3982         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3983 }
3984
3985 lock_index begin-read
3986 if {![winfo ismapped .]} {
3987         wm deiconify .
3988 }
3989 after 1 {
3990         if {[is_enabled initialamend]} {
3991                 force_amend
3992         } else {
3993                 do_rescan
3994         }
3995
3996         if {[is_enabled nocommitmsg]} {
3997                 $ui_comm configure -state disabled -background gray
3998         }
3999 }
4000 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4001         after 1000 hint_gc
4002 }
4003 if {[is_enabled retcode]} {
4004         bind . <Destroy> {+terminate_me %W}
4005 }
4006 if {$picked && [is_config_true gui.autoexplore]} {
4007         do_explore
4008 }
4009
4010 # Local variables:
4011 # mode: tcl
4012 # indent-tabs-mode: t
4013 # tab-width: 4
4014 # End: