?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-svn: reduce check_cherry_pick cache overhead
[git/mingw.git] / perl / Git / SVN.pm
blob171af37f4a66f9be500148720c8f4b7f036338d5
1 package Git::SVN;
2 use strict;
3 use warnings;
4 use Fcntl qw/:DEFAULT :seek/;
5 use constant rev_map_fmt => 'NH40';
6 use vars qw/$_no_metadata
7 $_repack $_repack_flags $_use_svm_props $_head
8 $_use_svnsync_props $no_reuse_existing
9 $_use_log_author $_add_author_from $_localtime/;
10 use Carp qw/croak/;
11 use File::Path qw/mkpath/;
12 use File::Copy qw/copy/;
13 use IPC::Open3;
14 use Memoize; # core since 5.8.0, Jul 2002
15 use Memoize::Storable;
16 use POSIX qw(:signal_h);
17
18 use Git qw(
19 command
20 command_oneline
21 command_noisy
22 command_output_pipe
23 command_close_pipe
24 get_tz_offset
25 );
26 use Git::SVN::Utils qw(
27 fatal
28 can_compress
29 join_paths
30 canonicalize_path
31 canonicalize_url
32 add_path_to_url
33 );
34
35 my $can_use_yaml;
36 BEGIN {
37 $can_use_yaml = eval { require Git::SVN::Memoize::YAML; 1};
38 }
39
40 our $_follow_parent = 1;
41 our $_minimize_url = 'unset';
42 our $default_repo_id = 'svn';
43 our $default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
44
45 my ($_gc_nr, $_gc_period);
46
47 # properties that we do not log:
48 my %SKIP_PROP;
49 BEGIN {
50 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
51 svn:special svn:executable
52 svn:entry:committed-rev
53 svn:entry:last-author
54 svn:entry:uuid
55 svn:entry:committed-date/;
56
57 # some options are read globally, but can be overridden locally
58 # per [svn-remote "..."] section. Command-line options will *NOT*
59 # override options set in an [svn-remote "..."] section
60 no strict 'refs';
61 for my $option (qw/follow_parent no_metadata use_svm_props
62 use_svnsync_props/) {
63 my $key = $option;
64 $key =~ tr/_//d;
65 my $prop = "-$option";
66 *$option = sub {
67 my ($self) = @_;
68 return $self->{$prop} if exists $self->{$prop};
69 my $k = "svn-remote.$self->{repo_id}.$key";
70 eval { command_oneline(qw/config --get/, $k) };
71 if ($@) {
72 $self->{$prop} = ${"Git::SVN::_$option"};
73 } else {
74 my $v = command_oneline(qw/config --bool/,$k);
75 $self->{$prop} = $v eq 'false' ? 0 : 1;
76 }
77 return $self->{$prop};
78 }
79 }
80 }
81
82
83 my (%LOCKFILES, %INDEX_FILES);
84 END {
85 unlink keys %LOCKFILES if %LOCKFILES;
86 unlink keys %INDEX_FILES if %INDEX_FILES;
87 }
88
89 sub resolve_local_globs {
90 my ($url, $fetch, $glob_spec) = @_;
91 return unless defined $glob_spec;
92 my $ref = $glob_spec->{ref};
93 my $path = $glob_spec->{path};
94 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
95 next unless m#^$ref->{regex}$#;
96 my $p = $1;
97 my $pathname = desanitize_refname($path->full_path($p));
98 my $refname = desanitize_refname($ref->full_path($p));
99 if (my $existing = $fetch->{$pathname}) {
100 if ($existing ne $refname) {
101 die "Refspec conflict:\n",
102 "existing: $existing\n",
103 " globbed: $refname\n";
104 }
105 my $u = (::cmt_metadata("$refname"))[0];
106 $u =~ s!^\Q$url\E(/|$)!! or die
107 "$refname: '$url' not found in '$u'\n";
108 if ($pathname ne $u) {
109 warn "W: Refspec glob conflict ",
110 "(ref: $refname):\n",
111 "expected path: $pathname\n",
112 " real path: $u\n",
113 "Continuing ahead with $u\n";
114 next;
115 }
116 } else {
117 $fetch->{$pathname} = $refname;
118 }
119 }
120 }
121
122 sub parse_revision_argument {
123 my ($base, $head) = @_;
124 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
125 return ($base, $head);
126 }
127 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
128 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
129 return ($head, $head) if ($::_revision eq 'HEAD');
130 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
131 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
132 die "revision argument: $::_revision not understood by git-svn\n";
133 }
134
135 sub fetch_all {
136 my ($repo_id, $remotes) = @_;
137 if (ref $repo_id) {
138 my $gs = $repo_id;
139 $repo_id = undef;
140 $repo_id = $gs->{repo_id};
141 }
142 $remotes ||= read_all_remotes();
143 my $remote = $remotes->{$repo_id} or
144 die "[svn-remote \"$repo_id\"] unknown\n";
145 my $fetch = $remote->{fetch};
146 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
147 my (@gs, @globs);
148 my $ra = Git::SVN::Ra->new($url);
149 my $uuid = $ra->get_uuid;
150 my $head = $ra->get_latest_revnum;
151
152 # ignore errors, $head revision may not even exist anymore
153 eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
154 warn "W: $@\n" if $@;
155
156 my $base = defined $fetch ? $head : 0;
157
158 # read the max revs for wildcard expansion (branches/*, tags/*)
159 foreach my $t (qw/branches tags/) {
160 defined $remote->{$t} or next;
161 push @globs, @{$remote->{$t}};
162
163 my $max_rev = eval { tmp_config(qw/--int --get/,
164 "svn-remote.$repo_id.${t}-maxRev") };
165 if (defined $max_rev && ($max_rev < $base)) {
166 $base = $max_rev;
167 } elsif (!defined $max_rev) {
168 $base = 0;
169 }
170 }
171
172 if ($fetch) {
173 foreach my $p (sort keys %$fetch) {
174 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
175 my $lr = $gs->rev_map_max;
176 if (defined $lr) {
177 $base = $lr if ($lr < $base);
178 }
179 push @gs, $gs;
180 }
181 }
182
183 ($base, $head) = parse_revision_argument($base, $head);
184 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
185 }
186
187 sub read_all_remotes {
188 my $r = {};
189 my $use_svm_props = eval { command_oneline(qw/config --bool
190 svn.useSvmProps/) };
191 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
192 my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
193 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
194 if (m!^(.+)\.fetch=$svn_refspec$!) {
195 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
196 die("svn-remote.$remote: remote ref '$remote_ref' "
197 . "must start with 'refs/'\n")
198 unless $remote_ref =~ m{^refs/};
199 $local_ref = uri_decode($local_ref);
200 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
201 $r->{$remote}->{svm} = {} if $use_svm_props;
202 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
203 $r->{$1}->{svm} = {};
204 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
205 $r->{$1}->{url} = canonicalize_url($2);
206 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
207 $r->{$1}->{pushurl} = canonicalize_url($2);
208 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
209 $r->{$1}->{ignore_refs_regex} = $2;
210 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
211 my ($remote, $t, $local_ref, $remote_ref) =
212 ($1, $2, $3, $4);
213 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
214 . "must start with 'refs/'\n")
215 unless $remote_ref =~ m{^refs/};
216 $local_ref = uri_decode($local_ref);
217
218 require Git::SVN::GlobSpec;
219 my $rs = {
220 t => $t,
221 remote => $remote,
222 path => Git::SVN::GlobSpec->new($local_ref, 1),
223 ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
224 if (length($rs->{ref}->{right}) != 0) {
225 die "The '*' glob character must be the last ",
226 "character of '$remote_ref'\n";
227 }
228 push @{ $r->{$remote}->{$t} }, $rs;
229 }
230 }
231
232 map {
233 if (defined $r->{$_}->{svm}) {
234 my $svm;
235 eval {
236 my $section = "svn-remote.$_";
237 $svm = {
238 source => tmp_config('--get',
239 "$section.svm-source"),
240 replace => tmp_config('--get',
241 "$section.svm-replace"),
242 }
243 };
244 $r->{$_}->{svm} = $svm;
245 }
246 } keys %$r;
247
248 foreach my $remote (keys %$r) {
249 foreach ( grep { defined $_ }
250 map { $r->{$remote}->{$_} } qw(branches tags) ) {
251 foreach my $rs ( @$_ ) {
252 $rs->{ignore_refs_regex} =
253 $r->{$remote}->{ignore_refs_regex};
254 }
255 }
256 }
257
258 $r;
259 }
260
261 sub init_vars {
262 $_gc_nr = $_gc_period = 1000;
263 if (defined $_repack || defined $_repack_flags) {
264 warn "Repack options are obsolete; they have no effect.\n";
265 }
266 }
267
268 sub verify_remotes_sanity {
269 return unless -d $ENV{GIT_DIR};
270 my %seen;
271 foreach (command(qw/config -l/)) {
272 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
273 if ($seen{$1}) {
274 die "Remote ref refs/remote/$1 is tracked by",
275 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
276 "Please resolve this ambiguity in ",
277 "your git configuration file before ",
278 "continuing\n";
279 }
280 $seen{$1} = $_;
281 }
282 }
283 }
284
285 sub find_existing_remote {
286 my ($url, $remotes) = @_;
287 return undef if $no_reuse_existing;
288 my $existing;
289 foreach my $repo_id (keys %$remotes) {
290 my $u = $remotes->{$repo_id}->{url} or next;
291 next if $u ne $url;
292 $existing = $repo_id;
293 last;
294 }
295 $existing;
296 }
297
298 sub init_remote_config {
299 my ($self, $url, $no_write) = @_;
300 $url = canonicalize_url($url);
301 my $r = read_all_remotes();
302 my $existing = find_existing_remote($url, $r);
303 if ($existing) {
304 unless ($no_write) {
305 print STDERR "Using existing ",
306 "[svn-remote \"$existing\"]\n";
307 }
308 $self->{repo_id} = $existing;
309 } elsif ($_minimize_url) {
310 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
311 $existing = find_existing_remote($min_url, $r);
312 if ($existing) {
313 unless ($no_write) {
314 print STDERR "Using existing ",
315 "[svn-remote \"$existing\"]\n";
316 }
317 $self->{repo_id} = $existing;
318 }
319 if ($min_url ne $url) {
320 unless ($no_write) {
321 print STDERR "Using higher level of URL: ",
322 "$url => $min_url\n";
323 }
324 my $old_path = $self->path;
325 $url =~ s!^\Q$min_url\E(/|$)!!;
326 $url = join_paths($url, $old_path);
327 $self->path($url);
328 $url = $min_url;
329 }
330 }
331 my $orig_url;
332 if (!$existing) {
333 # verify that we aren't overwriting anything:
334 $orig_url = eval {
335 command_oneline('config', '--get',
336 "svn-remote.$self->{repo_id}.url")
337 };
338 if ($orig_url && ($orig_url ne $url)) {
339 die "svn-remote.$self->{repo_id}.url already set: ",
340 "$orig_url\nwanted to set to: $url\n";
341 }
342 }
343 my ($xrepo_id, $xpath) = find_ref($self->refname);
344 if (!$no_write && defined $xpath) {
345 die "svn-remote.$xrepo_id.fetch already set to track ",
346 "$xpath:", $self->refname, "\n";
347 }
348 unless ($no_write) {
349 command_noisy('config',
350 "svn-remote.$self->{repo_id}.url", $url);
351 my $path = $self->path;
352 $path =~ s{^/}{};
353 $path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
354 $self->path($path);
355 command_noisy('config', '--add',
356 "svn-remote.$self->{repo_id}.fetch",
357 $self->path.":".$self->refname);
358 }
359 $self->url($url);
360 }
361
362 sub find_by_url { # repos_root and, path are optional
363 my ($class, $full_url, $repos_root, $path) = @_;
364
365 $full_url = canonicalize_url($full_url);
366
367 return undef unless defined $full_url;
368 remove_username($full_url);
369 remove_username($repos_root) if defined $repos_root;
370 my $remotes = read_all_remotes();
371 if (defined $full_url && defined $repos_root && !defined $path) {
372 $path = $full_url;
373 $path =~ s#^\Q$repos_root\E(?:/|$)##;
374 }
375 foreach my $repo_id (keys %$remotes) {
376 my $u = $remotes->{$repo_id}->{url} or next;
377 remove_username($u);
378 next if defined $repos_root && $repos_root ne $u;
379
380 my $fetch = $remotes->{$repo_id}->{fetch} || {};
381 foreach my $t (qw/branches tags/) {
382 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
383 resolve_local_globs($u, $fetch, $globspec);
384 }
385 }
386 my $p = $path;
387 my $rwr = rewrite_root({repo_id => $repo_id});
388 my $svm = $remotes->{$repo_id}->{svm}
389 if defined $remotes->{$repo_id}->{svm};
390 unless (defined $p) {
391 $p = $full_url;
392 my $z = $u;
393 my $prefix = '';
394 if ($rwr) {
395 $z = $rwr;
396 remove_username($z);
397 } elsif (defined $svm) {
398 $z = $svm->{source};
399 $prefix = $svm->{replace};
400 $prefix =~ s#^\Q$u\E(?:/|$)##;
401 $prefix =~ s#/$##;
402 }
403 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
404 }
405
406 # remote fetch paths are not URI escaped. Decode ours
407 # so they match
408 $p = uri_decode($p);
409
410 foreach my $f (keys %$fetch) {
411 next if $f ne $p;
412 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
413 }
414 }
415 undef;
416 }
417
418 sub init {
419 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
420 my $self = _new($class, $repo_id, $ref_id, $path);
421 if (defined $url) {
422 $self->init_remote_config($url, $no_write);
423 }
424 $self;
425 }
426
427 sub find_ref {
428 my ($ref_id) = @_;
429 foreach (command(qw/config -l/)) {
430 next unless m!^svn-remote\.(.+)\.fetch=
431 \s*(.*?)\s*:\s*(.+?)\s*$!x;
432 my ($repo_id, $path, $ref) = ($1, $2, $3);
433 if ($ref eq $ref_id) {
434 $path = '' if ($path =~ m#^\./?#);
435 return ($repo_id, $path);
436 }
437 }
438 (undef, undef, undef);
439 }
440
441 sub new {
442 my ($class, $ref_id, $repo_id, $path) = @_;
443 if (defined $ref_id && !defined $repo_id && !defined $path) {
444 ($repo_id, $path) = find_ref($ref_id);
445 if (!defined $repo_id) {
446 die "Could not find a \"svn-remote.*.fetch\" key ",
447 "in the repository configuration matching: ",
448 "$ref_id\n";
449 }
450 }
451 my $self = _new($class, $repo_id, $ref_id, $path);
452 if (!defined $self->path || !length $self->path) {
453 my $fetch = command_oneline('config', '--get',
454 "svn-remote.$repo_id.fetch",
455 ":$ref_id\$") or
456 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
457 "\":$ref_id\$\" in config\n";
458 my($path) = split(/\s*:\s*/, $fetch);
459 $self->path($path);
460 }
461 {
462 my $path = $self->path;
463 $path =~ s{\A/}{};
464 $path =~ s{/\z}{};
465 $self->path($path);
466 }
467 my $url = command_oneline('config', '--get',
468 "svn-remote.$repo_id.url") or
469 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
470 $self->url($url);
471 $self->{pushurl} = eval { command_oneline('config', '--get',
472 "svn-remote.$repo_id.pushurl") };
473 $self->rebuild;
474 $self;
475 }
476
477 sub refname {
478 my ($refname) = $_[0]->{ref_id} ;
479
480 # It cannot end with a slash /, we'll throw up on this because
481 # SVN can't have directories with a slash in their name, either:
482 if ($refname =~ m{/$}) {
483 die "ref: '$refname' ends with a trailing slash; this is ",
484 "not permitted by git or Subversion\n";
485 }
486
487 # It cannot have ASCII control character space, tilde ~, caret ^,
488 # colon :, question-mark ?, asterisk *, space, or open bracket [
489 # anywhere.
490 #
491 # Additionally, % must be escaped because it is used for escaping
492 # and we want our escaped refname to be reversible
493 $refname =~ s{([ \%~\^:\?\*\[\t])}{sprintf('%%%02X',ord($1))}eg;
494
495 # no slash-separated component can begin with a dot .
496 # /.* becomes /%2E*
497 $refname =~ s{/\.}{/%2E}g;
498
499 # It cannot have two consecutive dots .. anywhere
500 # .. becomes %2E%2E
501 $refname =~ s{\.\.}{%2E%2E}g;
502
503 # trailing dots and .lock are not allowed
504 # .$ becomes %2E and .lock becomes %2Elock
505 $refname =~ s{\.(?=$|lock$)}{%2E};
506
507 # the sequence @{ is used to access the reflog
508 # @{ becomes %40{
509 $refname =~ s{\@\{}{%40\{}g;
510
511 return $refname;
512 }
513
514 sub desanitize_refname {
515 my ($refname) = @_;
516 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
517 return $refname;
518 }
519
520 sub svm_uuid {
521 my ($self) = @_;
522 return $self->{svm}->{uuid} if $self->svm;
523 $self->ra;
524 unless ($self->{svm}) {
525 die "SVM UUID not cached, and reading remotely failed\n";
526 }
527 $self->{svm}->{uuid};
528 }
529
530 sub svm {
531 my ($self) = @_;
532 return $self->{svm} if $self->{svm};
533 my $svm;
534 # see if we have it in our config, first:
535 eval {
536 my $section = "svn-remote.$self->{repo_id}";
537 $svm = {
538 source => tmp_config('--get', "$section.svm-source"),
539 uuid => tmp_config('--get', "$section.svm-uuid"),
540 replace => tmp_config('--get', "$section.svm-replace"),
541 }
542 };
543 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
544 $self->{svm} = $svm;
545 }
546 $self->{svm};
547 }
548
549 sub _set_svm_vars {
550 my ($self, $ra) = @_;
551 return $ra if $self->svm;
552
553 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
554 "(svm:source, svm:uuid) ",
555 "from the following URLs:\n" );
556 sub read_svm_props {
557 my ($self, $ra, $path, $r) = @_;
558 my $props = ($ra->get_dir($path, $r))[2];
559 my $src = $props->{'svm:source'};
560 my $uuid = $props->{'svm:uuid'};
561 return undef if (!$src || !$uuid);
562
563 chomp($src, $uuid);
564
565 $uuid =~ m{^[0-9a-f\-]{30,}$}i
566 or die "doesn't look right - svm:uuid is '$uuid'\n";
567
568 # the '!' is used to mark the repos_root!/relative/path
569 $src =~ s{/?!/?}{/};
570 $src =~ s{/+$}{}; # no trailing slashes please
571 # username is of no interest
572 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
573
574 my $replace = add_path_to_url($ra->url, $path);
575
576 my $section = "svn-remote.$self->{repo_id}";
577 tmp_config("$section.svm-source", $src);
578 tmp_config("$section.svm-replace", $replace);
579 tmp_config("$section.svm-uuid", $uuid);
580 $self->{svm} = {
581 source => $src,
582 uuid => $uuid,
583 replace => $replace
584 };
585 }
586
587 my $r = $ra->get_latest_revnum;
588 my $path = $self->path;
589 my %tried;
590 while (length $path) {
591 my $try = add_path_to_url($self->url, $path);
592 unless ($tried{$try}) {
593 return $ra if $self->read_svm_props($ra, $path, $r);
594 $tried{$try} = 1;
595 }
596 $path =~ s#/?[^/]+$##;
597 }
598 die "Path: '$path' should be ''\n" if $path ne '';
599 return $ra if $self->read_svm_props($ra, $path, $r);
600 $tried{ add_path_to_url($self->url, $path) } = 1;
601
602 if ($ra->{repos_root} eq $self->url) {
603 die @err, (map { " $_\n" } keys %tried), "\n";
604 }
605
606 # nope, make sure we're connected to the repository root:
607 my $ok;
608 my @tried_b;
609 $path = $ra->{svn_path};
610 $ra = Git::SVN::Ra->new($ra->{repos_root});
611 while (length $path) {
612 my $try = add_path_to_url($ra->url, $path);
613 unless ($tried{$try}) {
614 $ok = $self->read_svm_props($ra, $path, $r);
615 last if $ok;
616 $tried{$try} = 1;
617 }
618 $path =~ s#/?[^/]+$##;
619 }
620 die "Path: '$path' should be ''\n" if $path ne '';
621 $ok ||= $self->read_svm_props($ra, $path, $r);
622 $tried{ add_path_to_url($ra->url, $path) } = 1;
623 if (!$ok) {
624 die @err, (map { " $_\n" } keys %tried), "\n";
625 }
626 Git::SVN::Ra->new($self->url);
627 }
628
629 sub svnsync {
630 my ($self) = @_;
631 return $self->{svnsync} if $self->{svnsync};
632
633 if ($self->no_metadata) {
634 die "Can't have both 'noMetadata' and ",
635 "'useSvnsyncProps' options set!\n";
636 }
637 if ($self->rewrite_root) {
638 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
639 "options set!\n";
640 }
641 if ($self->rewrite_uuid) {
642 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
643 "options set!\n";
644 }
645
646 my $svnsync;
647 # see if we have it in our config, first:
648 eval {
649 my $section = "svn-remote.$self->{repo_id}";
650
651 my $url = tmp_config('--get', "$section.svnsync-url");
652 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
653 die "doesn't look right - svn:sync-from-url is '$url'\n";
654
655 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
656 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
657 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
658
659 $svnsync = { url => $url, uuid => $uuid }
660 };
661 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
662 return $self->{svnsync} = $svnsync;
663 }
664
665 my $err = "useSvnsyncProps set, but failed to read " .
666 "svnsync property: svn:sync-from-";
667 my $rp = $self->ra->rev_proplist(0);
668
669 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
670 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
671 die "doesn't look right - svn:sync-from-url is '$url'\n";
672
673 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
674 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
675 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
676
677 my $section = "svn-remote.$self->{repo_id}";
678 tmp_config('--add', "$section.svnsync-uuid", $uuid);
679 tmp_config('--add', "$section.svnsync-url", $url);
680 return $self->{svnsync} = { url => $url, uuid => $uuid };
681 }
682
683 # this allows us to memoize our SVN::Ra UUID locally and avoid a
684 # remote lookup (useful for 'git svn log').
685 sub ra_uuid {
686 my ($self) = @_;
687 unless ($self->{ra_uuid}) {
688 my $key = "svn-remote.$self->{repo_id}.uuid";
689 my $uuid = eval { tmp_config('--get', $key) };
690 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
691 $self->{ra_uuid} = $uuid;
692 } else {
693 die "ra_uuid called without URL\n" unless $self->url;
694 $self->{ra_uuid} = $self->ra->get_uuid;
695 tmp_config('--add', $key, $self->{ra_uuid});
696 }
697 }
698 $self->{ra_uuid};
699 }
700
701 sub _set_repos_root {
702 my ($self, $repos_root) = @_;
703 my $k = "svn-remote.$self->{repo_id}.reposRoot";
704 $repos_root ||= $self->ra->{repos_root};
705 tmp_config($k, $repos_root);
706 $repos_root;
707 }
708
709 sub repos_root {
710 my ($self) = @_;
711 my $k = "svn-remote.$self->{repo_id}.reposRoot";
712 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
713 }
714
715 sub ra {
716 my ($self) = shift;
717 my $ra = Git::SVN::Ra->new($self->url);
718 $self->_set_repos_root($ra->{repos_root});
719 if ($self->use_svm_props && !$self->{svm}) {
720 if ($self->no_metadata) {
721 die "Can't have both 'noMetadata' and ",
722 "'useSvmProps' options set!\n";
723 } elsif ($self->use_svnsync_props) {
724 die "Can't have both 'useSvnsyncProps' and ",
725 "'useSvmProps' options set!\n";
726 }
727 $ra = $self->_set_svm_vars($ra);
728 $self->{-want_revprops} = 1;
729 }
730 $ra;
731 }
732
733 # prop_walk(PATH, REV, SUB)
734 # -------------------------
735 # Recursively traverse PATH at revision REV and invoke SUB for each
736 # directory that contains a SVN property. SUB will be invoked as
737 # follows: &SUB(gs, path, props); where `gs' is this instance of
738 # Git::SVN, `path' the path to the directory where the properties
739 # `props' were found. The `path' will be relative to point of checkout,
740 # that is, if url://repo/trunk is the current Git branch, and that
741 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
742 # as `path' (note the trailing `/').
743 sub prop_walk {
744 my ($self, $path, $rev, $sub) = @_;
745
746 $path =~ s#^/##;
747 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
748 $path =~ s#^/*#/#g;
749 my $p = $path;
750 # Strip the irrelevant part of the path.
751 $p =~ s#^/+\Q@{[$self->path]}\E(/|$)#/#;
752 # Ensure the path is terminated by a `/'.
753 $p =~ s#/*$#/#;
754
755 # The properties contain all the internal SVN stuff nobody
756 # (usually) cares about.
757 my $interesting_props = 0;
758 foreach (keys %{$props}) {
759 # If it doesn't start with `svn:', it must be a
760 # user-defined property.
761 ++$interesting_props and next if $_ !~ /^svn:/;
762 # FIXME: Fragile, if SVN adds new public properties,
763 # this needs to be updated.
764 ++$interesting_props if /^svn:(?:ignore|keywords|executable
765 |eol-style|mime-type
766 |externals|needs-lock)$/x;
767 }
768 &$sub($self, $p, $props) if $interesting_props;
769
770 foreach (sort keys %$dirent) {
771 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
772 $self->prop_walk($self->path . $p . $_, $rev, $sub);
773 }
774 }
775
776 sub last_rev { ($_[0]->last_rev_commit)[0] }
777 sub last_commit { ($_[0]->last_rev_commit)[1] }
778
779 # returns the newest SVN revision number and newest commit SHA1
780 sub last_rev_commit {
781 my ($self) = @_;
782 if (defined $self->{last_rev} && defined $self->{last_commit}) {
783 return ($self->{last_rev}, $self->{last_commit});
784 }
785 my $c = ::verify_ref($self->refname.'^0');
786 if ($c && !$self->use_svm_props && !$self->no_metadata) {
787 my $rev = (::cmt_metadata($c))[1];
788 if (defined $rev) {
789 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
790 return ($rev, $c);
791 }
792 }
793 my $map_path = $self->map_path;
794 unless (-e $map_path) {
795 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
796 return (undef, undef);
797 }
798 my ($rev, $commit) = $self->rev_map_max(1);
799 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
800 return ($rev, $commit);
801 }
802
803 sub get_fetch_range {
804 my ($self, $min, $max) = @_;
805 $max ||= $self->ra->get_latest_revnum;
806 $min ||= $self->rev_map_max;
807 (++$min, $max);
808 }
809
810 sub tmp_config {
811 my (@args) = @_;
812 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
813 my $config = "$ENV{GIT_DIR}/svn/.metadata";
814 if (! -f $config && -f $old_def_config) {
815 rename $old_def_config, $config or
816 die "Failed rename $old_def_config => $config: $!\n";
817 }
818 my $old_config = $ENV{GIT_CONFIG};
819 $ENV{GIT_CONFIG} = $config;
820 $@ = undef;
821 my @ret = eval {
822 unless (-f $config) {
823 mkfile($config);
824 open my $fh, '>', $config or
825 die "Can't open $config: $!\n";
826 print $fh "; This file is used internally by ",
827 "git-svn\n" or die
828 "Couldn't write to $config: $!\n";
829 print $fh "; You should not have to edit it\n" or
830 die "Couldn't write to $config: $!\n";
831 close $fh or die "Couldn't close $config: $!\n";
832 }
833 command('config', @args);
834 };
835 my $err = $@;
836 if (defined $old_config) {
837 $ENV{GIT_CONFIG} = $old_config;
838 } else {
839 delete $ENV{GIT_CONFIG};
840 }
841 die $err if $err;
842 wantarray ? @ret : $ret[0];
843 }
844
845 sub tmp_index_do {
846 my ($self, $sub) = @_;
847 my $old_index = $ENV{GIT_INDEX_FILE};
848 $ENV{GIT_INDEX_FILE} = $self->{index};
849 $@ = undef;
850 my @ret = eval {
851 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
852 mkpath([$dir]) unless -d $dir;
853 &$sub;
854 };
855 my $err = $@;
856 if (defined $old_index) {
857 $ENV{GIT_INDEX_FILE} = $old_index;
858 } else {
859 delete $ENV{GIT_INDEX_FILE};
860 }
861 die $err if $err;
862 wantarray ? @ret : $ret[0];
863 }
864
865 sub assert_index_clean {
866 my ($self, $treeish) = @_;
867
868 $self->tmp_index_do(sub {
869 command_noisy('read-tree', $treeish) unless -e $self->{index};
870 my $x = command_oneline('write-tree');
871 my ($y) = (command(qw/cat-file commit/, $treeish) =~
872 /^tree ($::sha1)/mo);
873 return if $y eq $x;
874
875 warn "Index mismatch: $y != $x\nrereading $treeish\n";
876 unlink $self->{index} or die "unlink $self->{index}: $!\n";
877 command_noisy('read-tree', $treeish);
878 $x = command_oneline('write-tree');
879 if ($y ne $x) {
880 fatal "trees ($treeish) $y != $x\n",
881 "Something is seriously wrong...";
882 }
883 });
884 }
885
886 sub get_commit_parents {
887 my ($self, $log_entry) = @_;
888 my (%seen, @ret, @tmp);
889 # legacy support for 'set-tree'; this is only used by set_tree_cb:
890 if (my $ip = $self->{inject_parents}) {
891 if (my $commit = delete $ip->{$log_entry->{revision}}) {
892 push @tmp, $commit;
893 }
894 }
895 if (my $cur = ::verify_ref($self->refname.'^0')) {
896 push @tmp, $cur;
897 }
898 if (my $ipd = $self->{inject_parents_dcommit}) {
899 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
900 push @tmp, @$commit;
901 }
902 }
903 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
904 while (my $p = shift @tmp) {
905 next if $seen{$p};
906 $seen{$p} = 1;
907 push @ret, $p;
908 }
909 @ret;
910 }
911
912 sub rewrite_root {
913 my ($self) = @_;
914 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
915 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
916 my $rwr = eval { command_oneline(qw/config --get/, $k) };
917 if ($rwr) {
918 $rwr =~ s#/+$##;
919 if ($rwr !~ m#^[a-z\+]+://#) {
920 die "$rwr is not a valid URL (key: $k)\n";
921 }
922 }
923 $self->{-rewrite_root} = $rwr;
924 }
925
926 sub rewrite_uuid {
927 my ($self) = @_;
928 return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
929 my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
930 my $rwid = eval { command_oneline(qw/config --get/, $k) };
931 if ($rwid) {
932 $rwid =~ s#/+$##;
933 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
934 die "$rwid is not a valid UUID (key: $k)\n";
935 }
936 }
937 $self->{-rewrite_uuid} = $rwid;
938 }
939
940 sub metadata_url {
941 my ($self) = @_;
942 my $url = $self->rewrite_root || $self->url;
943 return canonicalize_url( add_path_to_url( $url, $self->path ) );
944 }
945
946 sub full_url {
947 my ($self) = @_;
948 return canonicalize_url( add_path_to_url( $self->url, $self->path ) );
949 }
950
951 sub full_pushurl {
952 my ($self) = @_;
953 if ($self->{pushurl}) {
954 return canonicalize_url( add_path_to_url( $self->{pushurl}, $self->path ) );
955 } else {
956 return $self->full_url;
957 }
958 }
959
960 sub set_commit_header_env {
961 my ($log_entry) = @_;
962 my %env;
963 foreach my $ned (qw/NAME EMAIL DATE/) {
964 foreach my $ac (qw/AUTHOR COMMITTER/) {
965 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
966 }
967 }
968
969 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
970 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
971 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
972
973 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
974 ? $log_entry->{commit_name}
975 : $log_entry->{name};
976 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
977 ? $log_entry->{commit_email}
978 : $log_entry->{email};
979 \%env;
980 }
981
982 sub restore_commit_header_env {
983 my ($env) = @_;
984 foreach my $ned (qw/NAME EMAIL DATE/) {
985 foreach my $ac (qw/AUTHOR COMMITTER/) {
986 my $k = "GIT_${ac}_${ned}";
987 if (defined $env->{$k}) {
988 $ENV{$k} = $env->{$k};
989 } else {
990 delete $ENV{$k};
991 }
992 }
993 }
994 }
995
996 sub gc {
997 command_noisy('gc', '--auto');
998 };
999
1000 sub do_git_commit {
1001 my ($self, $log_entry) = @_;
1002 my $lr = $self->last_rev;
1003 if (defined $lr && $lr >= $log_entry->{revision}) {
1004 die "Last fetched revision of ", $self->refname,
1005 " was r$lr, but we are about to fetch: ",
1006 "r$log_entry->{revision}!\n";
1007 }
1008 if (my $c = $self->rev_map_get($log_entry->{revision})) {
1009 croak "$log_entry->{revision} = $c already exists! ",
1010 "Why are we refetching it?\n";
1011 }
1012 my $old_env = set_commit_header_env($log_entry);
1013 my $tree = $log_entry->{tree};
1014 if (!defined $tree) {
1015 $tree = $self->tmp_index_do(sub {
1016 command_oneline('write-tree') });
1017 }
1018 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1019
1020 my @exec = ('git', 'commit-tree', $tree);
1021 foreach ($self->get_commit_parents($log_entry)) {
1022 push @exec, '-p', $_;
1023 }
1024 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1025 or croak $!;
1026 binmode $msg_fh;
1027
1028 # we always get UTF-8 from SVN, but we may want our commits in
1029 # a different encoding.
1030 if (my $enc = Git::config('i18n.commitencoding')) {
1031 require Encode;
1032 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
1033 }
1034 print $msg_fh $log_entry->{log} or croak $!;
1035 restore_commit_header_env($old_env);
1036 unless ($self->no_metadata) {
1037 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1038 or croak $!;
1039 }
1040 $msg_fh->flush == 0 or croak $!;
1041 close $msg_fh or croak $!;
1042 chomp(my $commit = do { local $/; <$out_fh> });
1043 close $out_fh or croak $!;
1044 waitpid $pid, 0;
1045 croak $? if $?;
1046 if ($commit !~ /^$::sha1$/o) {
1047 die "Failed to commit, invalid sha1: $commit\n";
1048 }
1049
1050 $self->rev_map_set($log_entry->{revision}, $commit, 1);
1051
1052 $self->{last_rev} = $log_entry->{revision};
1053 $self->{last_commit} = $commit;
1054 print "r$log_entry->{revision}" unless $::_q > 1;
1055 if (defined $log_entry->{svm_revision}) {
1056 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
1057 $self->rev_map_set($log_entry->{svm_revision}, $commit,
1058 0, $self->svm_uuid);
1059 }
1060 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
1061 if (--$_gc_nr == 0) {
1062 $_gc_nr = $_gc_period;
1063 gc();
1064 }
1065 return $commit;
1066 }
1067
1068 sub match_paths {
1069 my ($self, $paths, $r) = @_;
1070 return 1 if $self->path eq '';
1071 if (my $path = $paths->{"/".$self->path}) {
1072 return ($path->{action} eq 'D') ? 0 : 1;
1073 }
1074 $self->{path_regex} ||= qr{^/\Q@{[$self->path]}\E/};
1075 if (grep /$self->{path_regex}/, keys %$paths) {
1076 return 1;
1077 }
1078 my $c = '';
1079 foreach (split m#/#, $self->path) {
1080 $c .= "/$_";
1081 next unless ($paths->{$c} &&
1082 ($paths->{$c}->{action} =~ /^[AR]$/));
1083 if ($self->ra->check_path($self->path, $r) ==
1084 $SVN::Node::dir) {
1085 return 1;
1086 }
1087 }
1088 return 0;
1089 }
1090
1091 sub find_parent_branch {
1092 my ($self, $paths, $rev) = @_;
1093 return undef unless $self->follow_parent;
1094 unless (defined $paths) {
1095 my $err_handler = $SVN::Error::handler;
1096 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1097 $self->ra->get_log([$self->path], $rev, $rev, 0, 1, 1,
1098 sub { $paths = $_[0] });
1099 $SVN::Error::handler = $err_handler;
1100 }
1101 return undef unless defined $paths;
1102
1103 # look for a parent from another branch:
1104 my @b_path_components = split m#/#, $self->path;
1105 my @a_path_components;
1106 my $i;
1107 while (@b_path_components) {
1108 $i = $paths->{'/'.join('/', @b_path_components)};
1109 last if $i && defined $i->{copyfrom_path};
1110 unshift(@a_path_components, pop(@b_path_components));
1111 }
1112 return undef unless defined $i && defined $i->{copyfrom_path};
1113 my $branch_from = $i->{copyfrom_path};
1114 if (@a_path_components) {
1115 print STDERR "branch_from: $branch_from => ";
1116 $branch_from .= '/'.join('/', @a_path_components);
1117 print STDERR $branch_from, "\n";
1118 }
1119 my $r = $i->{copyfrom_rev};
1120 my $repos_root = $self->ra->{repos_root};
1121 my $url = $self->ra->url;
1122 my $new_url = canonicalize_url( add_path_to_url( $url, $branch_from ) );
1123 print STDERR "Found possible branch point: ",
1124 "$new_url => ", $self->full_url, ", $r\n"
1125 unless $::_q > 1;
1126 $branch_from =~ s#^/##;
1127 my $gs = $self->other_gs($new_url, $url,
1128 $branch_from, $r, $self->{ref_id});
1129 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1130 {
1131 my ($base, $head);
1132 if (!defined $r0 || !defined $parent) {
1133 ($base, $head) = parse_revision_argument(0, $r);
1134 } else {
1135 if ($r0 < $r) {
1136 $gs->ra->get_log([$gs->path], $r0 + 1, $r, 1,
1137 0, 1, sub { $base = $_[1] - 1 });
1138 }
1139 }
1140 if (defined $base && $base <= $r) {
1141 $gs->fetch($base, $r);
1142 }
1143 ($r0, $parent) = $gs->find_rev_before($r, 1);
1144 }
1145 if (defined $r0 && defined $parent) {
1146 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
1147 unless $::_q > 1;
1148 my $ed;
1149 if ($self->ra->can_do_switch) {
1150 $self->assert_index_clean($parent);
1151 print STDERR "Following parent with do_switch\n"
1152 unless $::_q > 1;
1153 # do_switch works with svn/trunk >= r22312, but that
1154 # is not included with SVN 1.4.3 (the latest version
1155 # at the moment), so we can't rely on it
1156 $self->{last_rev} = $r0;
1157 $self->{last_commit} = $parent;
1158 $ed = Git::SVN::Fetcher->new($self, $gs->path);
1159 $gs->ra->gs_do_switch($r0, $rev, $gs,
1160 $self->full_url, $ed)
1161 or die "SVN connection failed somewhere...\n";
1162 } elsif ($self->ra->trees_match($new_url, $r0,
1163 $self->full_url, $rev)) {
1164 print STDERR "Trees match:\n",
1165 " $new_url\@$r0\n",
1166 " ${\$self->full_url}\@$rev\n",
1167 "Following parent with no changes\n"
1168 unless $::_q > 1;
1169 $self->tmp_index_do(sub {
1170 command_noisy('read-tree', $parent);
1171 });
1172 $self->{last_commit} = $parent;
1173 } else {
1174 print STDERR "Following parent with do_update\n"
1175 unless $::_q > 1;
1176 $ed = Git::SVN::Fetcher->new($self);
1177 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1178 or die "SVN connection failed somewhere...\n";
1179 }
1180 print STDERR "Successfully followed parent\n" unless $::_q > 1;
1181 return $self->make_log_entry($rev, [$parent], $ed, $r0, $branch_from);
1182 }
1183 return undef;
1184 }
1185
1186 sub do_fetch {
1187 my ($self, $paths, $rev) = @_;
1188 my $ed;
1189 my ($last_rev, @parents);
1190 if (my $lc = $self->last_commit) {
1191 # we can have a branch that was deleted, then re-added
1192 # under the same name but copied from another path, in
1193 # which case we'll have multiple parents (we don't
1194 # want to break the original ref or lose copypath info):
1195 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1196 push @{$log_entry->{parents}}, $lc;
1197 return $log_entry;
1198 }
1199 $ed = Git::SVN::Fetcher->new($self);
1200 $last_rev = $self->{last_rev};
1201 $ed->{c} = $lc;
1202 @parents = ($lc);
1203 } else {
1204 $last_rev = $rev;
1205 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1206 return $log_entry;
1207 }
1208 $ed = Git::SVN::Fetcher->new($self);
1209 }
1210 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1211 die "SVN connection failed somewhere...\n";
1212 }
1213 $self->make_log_entry($rev, \@parents, $ed, $last_rev, $self->path);
1214 }
1215
1216 sub mkemptydirs {
1217 my ($self, $r) = @_;
1218
1219 sub scan {
1220 my ($r, $empty_dirs, $line) = @_;
1221 if (defined $r && $line =~ /^r(\d+)$/) {
1222 return 0 if $1 > $r;
1223 } elsif ($line =~ /^ \+empty_dir: (.+)$/) {
1224 $empty_dirs->{$1} = 1;
1225 } elsif ($line =~ /^ \-empty_dir: (.+)$/) {
1226 my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
1227 delete @$empty_dirs{@d};
1228 }
1229 1; # continue
1230 };
1231
1232 my %empty_dirs = ();
1233 my $gz_file = "$self->{dir}/unhandled.log.gz";
1234 if (-f $gz_file) {
1235 if (!can_compress()) {
1236 warn "Compress::Zlib could not be found; ",
1237 "empty directories in $gz_file will not be read\n";
1238 } else {
1239 my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
1240 die "Unable to open $gz_file: $!\n";
1241 my $line;
1242 while ($gz->gzreadline($line) > 0) {
1243 scan($r, \%empty_dirs, $line) or last;
1244 }
1245 $gz->gzclose;
1246 }
1247 }
1248
1249 if (open my $fh, '<', "$self->{dir}/unhandled.log") {
1250 binmode $fh or croak "binmode: $!";
1251 while (<$fh>) {
1252 scan($r, \%empty_dirs, $_) or last;
1253 }
1254 close $fh;
1255 }
1256
1257 my $strip = qr/\A\Q@{[$self->path]}\E(?:\/|$)/;
1258 foreach my $d (sort keys %empty_dirs) {
1259 $d = uri_decode($d);
1260 $d =~ s/$strip//;
1261 next unless length($d);
1262 next if -d $d;
1263 if (-e $d) {
1264 warn "$d exists but is not a directory\n";
1265 } else {
1266 print "creating empty directory: $d\n";
1267 mkpath([$d]);
1268 }
1269 }
1270 }
1271
1272 sub get_untracked {
1273 my ($self, $ed) = @_;
1274 my @out;
1275 my $h = $ed->{empty};
1276 foreach (sort keys %$h) {
1277 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1278 push @out, " $act: " . uri_encode($_);
1279 warn "W: $act: $_\n";
1280 }
1281 foreach my $t (qw/dir_prop file_prop/) {
1282 $h = $ed->{$t} or next;
1283 foreach my $path (sort keys %$h) {
1284 my $ppath = $path eq '' ? '.' : $path;
1285 foreach my $prop (sort keys %{$h->{$path}}) {
1286 next if $SKIP_PROP{$prop};
1287 my $v = $h->{$path}->{$prop};
1288 my $t_ppath_prop = "$t: " .
1289 uri_encode($ppath) . ' ' .
1290 uri_encode($prop);
1291 if (defined $v) {
1292 push @out, " +$t_ppath_prop " .
1293 uri_encode($v);
1294 } else {
1295 push @out, " -$t_ppath_prop";
1296 }
1297 }
1298 }
1299 }
1300 foreach my $t (qw/absent_file absent_directory/) {
1301 $h = $ed->{$t} or next;
1302 foreach my $parent (sort keys %$h) {
1303 foreach my $path (sort @{$h->{$parent}}) {
1304 push @out, " $t: " .
1305 uri_encode("$parent/$path");
1306 warn "W: $t: $parent/$path ",
1307 "Insufficient permissions?\n";
1308 }
1309 }
1310 }
1311 \@out;
1312 }
1313
1314 # parse_svn_date(DATE)
1315 # --------------------
1316 # Given a date (in UTC) from Subversion, return a string in the format
1317 # "<TZ Offset> <local date/time>" that Git will use.
1318 #
1319 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
1320 # is true we'll convert it to the local timezone instead.
1321 sub parse_svn_date {
1322 my $date = shift || return '+0000 1970-01-01 00:00:00';
1323 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1324 (\d\d?)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
1325 croak "Unable to parse date: $date\n";
1326 my $parsed_date; # Set next.
1327
1328 if ($Git::SVN::_localtime) {
1329 # Translate the Subversion datetime to an epoch time.
1330 # Begin by switching ourselves to $date's timezone, UTC.
1331 my $old_env_TZ = $ENV{TZ};
1332 $ENV{TZ} = 'UTC';
1333
1334 my $epoch_in_UTC =
1335 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
1336
1337 # Determine our local timezone (including DST) at the
1338 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
1339 # value of TZ, if any, at the time we were run.
1340 if (defined $Git::SVN::Log::TZ) {
1341 $ENV{TZ} = $Git::SVN::Log::TZ;
1342 } else {
1343 delete $ENV{TZ};
1344 }
1345
1346 my $our_TZ = get_tz_offset();
1347
1348 # This converts $epoch_in_UTC into our local timezone.
1349 my ($sec, $min, $hour, $mday, $mon, $year,
1350 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
1351
1352 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
1353 $our_TZ, $year + 1900, $mon + 1,
1354 $mday, $hour, $min, $sec);
1355
1356 # Reset us to the timezone in effect when we entered
1357 # this routine.
1358 if (defined $old_env_TZ) {
1359 $ENV{TZ} = $old_env_TZ;
1360 } else {
1361 delete $ENV{TZ};
1362 }
1363 } else {
1364 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
1365 }
1366
1367 return $parsed_date;
1368 }
1369
1370 sub other_gs {
1371 my ($self, $new_url, $url,
1372 $branch_from, $r, $old_ref_id) = @_;
1373 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
1374 unless ($gs) {
1375 my $ref_id = $old_ref_id;
1376 $ref_id =~ s/\@\d+-*$//;
1377 $ref_id .= "\@$r";
1378 # just grow a tail if we're not unique enough :x
1379 $ref_id .= '-' while find_ref($ref_id);
1380 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
1381 if ($u =~ s#^\Q$url\E(/|$)##) {
1382 $p = $u;
1383 $u = $url;
1384 $repo_id = $self->{repo_id};
1385 }
1386 while (1) {
1387 # It is possible to tag two different subdirectories at
1388 # the same revision. If the url for an existing ref
1389 # does not match, we must either find a ref with a
1390 # matching url or create a new ref by growing a tail.
1391 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
1392 my (undef, $max_commit) = $gs->rev_map_max(1);
1393 last if (!$max_commit);
1394 my ($url) = ::cmt_metadata($max_commit);
1395 last if ($url eq $gs->metadata_url);
1396 $ref_id .= '-';
1397 }
1398 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
1399 }
1400 $gs
1401 }
1402
1403 sub call_authors_prog {
1404 my ($orig_author) = @_;
1405 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
1406 my $author = `$::_authors_prog $orig_author`;
1407 if ($? != 0) {
1408 die "$::_authors_prog failed with exit code $?\n"
1409 }
1410 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
1411 my ($name, $email) = ($1, $2);
1412 $email = undef if length $2 == 0;
1413 return [$name, $email];
1414 } else {
1415 die "Author: $orig_author: $::_authors_prog returned "
1416 . "invalid author format: $author\n";
1417 }
1418 }
1419
1420 sub check_author {
1421 my ($author) = @_;
1422 if (!defined $author || length $author == 0) {
1423 $author = '(no author)';
1424 }
1425 if (!defined $::users{$author}) {
1426 if (defined $::_authors_prog) {
1427 $::users{$author} = call_authors_prog($author);
1428 } elsif (defined $::_authors) {
1429 die "Author: $author not defined in $::_authors file\n";
1430 }
1431 }
1432 $author;
1433 }
1434
1435 sub find_extra_svk_parents {
1436 my ($self, $ed, $tickets, $parents) = @_;
1437 # aha! svk:merge property changed...
1438 my @tickets = split "\n", $tickets;
1439 my @known_parents;
1440 for my $ticket ( @tickets ) {
1441 my ($uuid, $path, $rev) = split /:/, $ticket;
1442 if ( $uuid eq $self->ra_uuid ) {
1443 my $repos_root = $self->url;
1444 my $branch_from = $path;
1445 $branch_from =~ s{^/}{};
1446 my $gs = $self->other_gs(add_path_to_url( $repos_root, $branch_from ),
1447 $repos_root,
1448 $branch_from,
1449 $rev,
1450 $self->{ref_id});
1451 if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
1452 # wahey! we found it, but it might be
1453 # an old one (!)
1454 push @known_parents, [ $rev, $commit ];
1455 }
1456 }
1457 }
1458 # Ordering matters; highest-numbered commit merge tickets
1459 # first, as they may account for later merge ticket additions
1460 # or changes.
1461 @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
1462 for my $parent ( @known_parents ) {
1463 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
1464 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
1465 my $new;
1466 while ( <$msg_fh> ) {
1467 $new=1;last;
1468 }
1469 command_close_pipe($msg_fh, $ctx);
1470 if ( $new ) {
1471 print STDERR
1472 "Found merge parent (svk:merge ticket): $parent\n";
1473 push @$parents, $parent;
1474 }
1475 }
1476 }
1477
1478 sub lookup_svn_merge {
1479 my $uuid = shift;
1480 my $url = shift;
1481 my $source = shift;
1482 my $revs = shift;
1483
1484 my $path = $source;
1485 $path =~ s{^/}{};
1486 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
1487 if ( !$gs ) {
1488 warn "Couldn't find revmap for $url$source\n";
1489 return;
1490 }
1491 my @ranges = split ",", $revs;
1492 my ($tip, $tip_commit);
1493 my @merged_commit_ranges;
1494 # find the tip
1495 for my $range ( @ranges ) {
1496 if ($range =~ /[*]$/) {
1497 warn "W: Ignoring partial merge in svn:mergeinfo "
1498 ."dirprop: $source:$range\n";
1499 next;
1500 }
1501 my ($bottom, $top) = split "-", $range;
1502 $top ||= $bottom;
1503 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
1504 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
1505
1506 unless ($top_commit and $bottom_commit) {
1507 warn "W: unknown path/rev in svn:mergeinfo "
1508 ."dirprop: $source:$range\n";
1509 next;
1510 }
1511
1512 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
1513 push @merged_commit_ranges,
1514 "$bottom_commit^..$top_commit";
1515 } else {
1516 push @merged_commit_ranges, "$top_commit";
1517 }
1518
1519 if ( !defined $tip or $top > $tip ) {
1520 $tip = $top;
1521 $tip_commit = $top_commit;
1522 }
1523 }
1524 return ($tip_commit, @merged_commit_ranges);
1525 }
1526
1527 sub _rev_list {
1528 my ($msg_fh, $ctx) = command_output_pipe(
1529 "rev-list", @_,
1530 );
1531 my @rv;
1532 while ( <$msg_fh> ) {
1533 chomp;
1534 push @rv, $_;
1535 }
1536 command_close_pipe($msg_fh, $ctx);
1537 @rv;
1538 }
1539
1540 sub check_cherry_pick2 {
1541 my $base = shift;
1542 my $tip = shift;
1543 my $parents = shift;
1544 my @ranges = @_;
1545 my %commits = map { $_ => 1 }
1546 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
1547 for my $range ( @ranges ) {
1548 delete @commits{_rev_list($range, "--")};
1549 }
1550 for my $commit (keys %commits) {
1551 if (has_no_changes($commit)) {
1552 delete $commits{$commit};
1553 }
1554 }
1555 my @k = (keys %commits);
1556 return (scalar @k, $k[0]);
1557 }
1558
1559 sub has_no_changes {
1560 my $commit = shift;
1561
1562 my @revs = split / /, command_oneline(
1563 qw(rev-list --parents -1 -m), $commit);
1564
1565 # Commits with no parents, e.g. the start of a partial branch,
1566 # have changes by definition.
1567 return 1 if (@revs < 2);
1568
1569 # Commits with multiple parents, e.g a merge, have no changes
1570 # by definition.
1571 return 0 if (@revs > 2);
1572
1573 return (command_oneline("rev-parse", "$commit^{tree}") eq
1574 command_oneline("rev-parse", "$commit~1^{tree}"));
1575 }
1576
1577 sub tie_for_persistent_memoization {
1578 my $hash = shift;
1579 my $path = shift;
1580
1581 if ($can_use_yaml) {
1582 tie %$hash => 'Git::SVN::Memoize::YAML', "$path.yaml";
1583 } else {
1584 tie %$hash => 'Memoize::Storable', "$path.db", 'nstore';
1585 }
1586 }
1587
1588 # The GIT_DIR environment variable is not always set until after the command
1589 # line arguments are processed, so we can't memoize in a BEGIN block.
1590 {
1591 my $memoized = 0;
1592
1593 sub memoize_svn_mergeinfo_functions {
1594 return if $memoized;
1595 $memoized = 1;
1596
1597 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1598 mkpath([$cache_path]) unless -d $cache_path;
1599
1600 my %lookup_svn_merge_cache;
1601 my %check_cherry_pick2_cache;
1602 my %has_no_changes_cache;
1603 my %_rev_list_cache;
1604
1605 tie_for_persistent_memoization(\%lookup_svn_merge_cache,
1606 "$cache_path/lookup_svn_merge");
1607 memoize 'lookup_svn_merge',
1608 SCALAR_CACHE => 'FAULT',
1609 LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
1610 ;
1611
1612 tie_for_persistent_memoization(\%check_cherry_pick2_cache,
1613 "$cache_path/check_cherry_pick2");
1614 memoize 'check_cherry_pick2',
1615 SCALAR_CACHE => 'FAULT',
1616 LIST_CACHE => ['HASH' => \%check_cherry_pick2_cache],
1617 ;
1618
1619 tie_for_persistent_memoization(\%has_no_changes_cache,
1620 "$cache_path/has_no_changes");
1621 memoize 'has_no_changes',
1622 SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
1623 LIST_CACHE => 'FAULT',
1624 ;
1625
1626 tie_for_persistent_memoization(\%_rev_list_cache,
1627 "$cache_path/_rev_list");
1628 memoize '_rev_list',
1629 SCALAR_CACHE => 'FAULT',
1630 LIST_CACHE => ['HASH' => \%_rev_list_cache],
1631 ;
1632
1633 }
1634
1635 sub unmemoize_svn_mergeinfo_functions {
1636 return if not $memoized;
1637 $memoized = 0;
1638
1639 Memoize::unmemoize 'lookup_svn_merge';
1640 Memoize::unmemoize 'check_cherry_pick2';
1641 Memoize::unmemoize 'has_no_changes';
1642 Memoize::unmemoize '_rev_list';
1643 }
1644
1645 sub clear_memoized_mergeinfo_caches {
1646 die "Only call this method in non-memoized context" if ($memoized);
1647
1648 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1649 return unless -d $cache_path;
1650
1651 for my $cache_file (("$cache_path/lookup_svn_merge",
1652 "$cache_path/check_cherry_pick", # old
1653 "$cache_path/check_cherry_pick2",
1654 "$cache_path/has_no_changes")) {
1655 for my $suffix (qw(yaml db)) {
1656 my $file = "$cache_file.$suffix";
1657 next unless -e $file;
1658 unlink($file) or die "unlink($file) failed: $!\n";
1659 }
1660 }
1661 }
1662
1663
1664 Memoize::memoize 'Git::SVN::repos_root';
1665 }
1666
1667 END {
1668 # Force cache writeout explicitly instead of waiting for
1669 # global destruction to avoid segfault in Storable:
1670 # http://rt.cpan.org/Public/Bug/Display.html?id=36087
1671 unmemoize_svn_mergeinfo_functions();
1672 }
1673
1674 sub parents_exclude {
1675 my $parents = shift;
1676 my @commits = @_;
1677 return unless @commits;
1678
1679 my @excluded;
1680 my $excluded;
1681 do {
1682 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
1683 $excluded = command_oneline(@cmd);
1684 if ( $excluded ) {
1685 my @new;
1686 my $found;
1687 for my $commit ( @commits ) {
1688 if ( $commit eq $excluded ) {
1689 push @excluded, $commit;
1690 $found++;
1691 }
1692 else {
1693 push @new, $commit;
1694 }
1695 }
1696 die "saw commit '$excluded' in rev-list output, "
1697 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
1698 unless $found;
1699 @commits = @new;
1700 }
1701 }
1702 while ($excluded and @commits);
1703
1704 return @excluded;
1705 }
1706
1707 # Compute what's new in svn:mergeinfo.
1708 sub mergeinfo_changes {
1709 my ($self, $old_path, $old_rev, $path, $rev, $mergeinfo_prop) = @_;
1710 my %minfo = map {split ":", $_ } split "\n", $mergeinfo_prop;
1711 my $old_minfo = {};
1712
1713 # Initialize cache on the first call.
1714 unless (defined $self->{cached_mergeinfo_rev}) {
1715 $self->{cached_mergeinfo_rev} = {};
1716 $self->{cached_mergeinfo} = {};
1717 }
1718
1719 my $cached_rev = $self->{cached_mergeinfo_rev}{$old_path};
1720 if (defined $cached_rev && $cached_rev == $old_rev) {
1721 $old_minfo = $self->{cached_mergeinfo}{$old_path};
1722 } else {
1723 my $ra = $self->ra;
1724 # Give up if $old_path isn't in the repo.
1725 # This is probably a merge on a subtree.
1726 if ($ra->check_path($old_path, $old_rev) != $SVN::Node::dir) {
1727 warn "W: ignoring svn:mergeinfo on $old_path, ",
1728 "directory didn't exist in r$old_rev\n";
1729 return {};
1730 }
1731 my (undef, undef, $props) =
1732 $self->ra->get_dir($old_path, $old_rev);
1733 if (defined $props->{"svn:mergeinfo"}) {
1734 my %omi = map {split ":", $_ } split "\n",
1735 $props->{"svn:mergeinfo"};
1736 $old_minfo = \%omi;
1737 }
1738 $self->{cached_mergeinfo}{$old_path} = $old_minfo;
1739 $self->{cached_mergeinfo_rev}{$old_path} = $old_rev;
1740 }
1741
1742 # Cache the new mergeinfo.
1743 $self->{cached_mergeinfo}{$path} = \%minfo;
1744 $self->{cached_mergeinfo_rev}{$path} = $rev;
1745
1746 my %changes = ();
1747 foreach my $p (keys %minfo) {
1748 my $a = $old_minfo->{$p} || "";
1749 my $b = $minfo{$p};
1750 # Omit merged branches whose ranges lists are unchanged.
1751 next if $a eq $b;
1752 # Remove any common range list prefix.
1753 ($a ^ $b) =~ /^[\0]*/;
1754 my $common_prefix = rindex $b, ",", $+[0] - 1;
1755 $changes{$p} = substr $b, $common_prefix + 1;
1756 }
1757 print STDERR "Checking svn:mergeinfo changes since r$old_rev: ",
1758 scalar(keys %minfo), " sources, ",
1759 scalar(keys %changes), " changed\n";
1760
1761 return \%changes;
1762 }
1763
1764 # note: this function should only be called if the various dirprops
1765 # have actually changed
1766 sub find_extra_svn_parents {
1767 my ($self, $ed, $mergeinfo, $parents) = @_;
1768 # aha! svk:merge property changed...
1769
1770 memoize_svn_mergeinfo_functions();
1771
1772 # We first search for merged tips which are not in our
1773 # history. Then, we figure out which git revisions are in
1774 # that tip, but not this revision. If all of those revisions
1775 # are now marked as merge, we can add the tip as a parent.
1776 my @merges = sort keys %$mergeinfo;
1777 my @merge_tips;
1778 my $url = $self->url;
1779 my $uuid = $self->ra_uuid;
1780 my @all_ranges;
1781 for my $merge ( @merges ) {
1782 my ($tip_commit, @ranges) =
1783 lookup_svn_merge( $uuid, $url,
1784 $merge, $mergeinfo->{$merge} );
1785 unless (!$tip_commit or
1786 grep { $_ eq $tip_commit } @$parents ) {
1787 push @merge_tips, $tip_commit;
1788 push @all_ranges, @ranges;
1789 } else {
1790 push @merge_tips, undef;
1791 }
1792 }
1793
1794 my %excluded = map { $_ => 1 }
1795 parents_exclude($parents, grep { defined } @merge_tips);
1796
1797 # check merge tips for new parents
1798 my @new_parents;
1799 for my $merge_tip ( @merge_tips ) {
1800 my $merge = shift @merges;
1801 next unless $merge_tip and $excluded{$merge_tip};
1802 my $spec = "$merge:$mergeinfo->{$merge}";
1803
1804 # check out 'new' tips
1805 my $merge_base;
1806 eval {
1807 $merge_base = command_oneline(
1808 "merge-base",
1809 @$parents, $merge_tip,
1810 );
1811 };
1812 if ($@) {
1813 die "An error occurred during merge-base"
1814 unless $@->isa("Git::Error::Command");
1815
1816 warn "W: Cannot find common ancestor between ".
1817 "@$parents and $merge_tip. Ignoring merge info.\n";
1818 next;
1819 }
1820
1821 # double check that there are no missing non-merge commits
1822 my ($ninc, $ifirst) = check_cherry_pick2(
1823 $merge_base, $merge_tip,
1824 $parents,
1825 @all_ranges,
1826 );
1827
1828 if ($ninc) {
1829 warn "W:svn cherry-pick ignored ($spec) - missing " .
1830 "$ninc commit(s) (eg $ifirst)\n";
1831 } else {
1832 warn
1833 "Found merge parent ($spec): ",
1834 $merge_tip, "\n";
1835 push @new_parents, $merge_tip;
1836 }
1837 }
1838
1839 # cater for merges which merge commits from multiple branches
1840 if ( @new_parents > 1 ) {
1841 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
1842 for ( my $j = 0; $j <= $#new_parents; $j++ ) {
1843 next if $i == $j;
1844 next unless $new_parents[$i];
1845 next unless $new_parents[$j];
1846 my $revs = command_oneline(
1847 "rev-list", "-1",
1848 "$new_parents[$i]..$new_parents[$j]",
1849 );
1850 if ( !$revs ) {
1851 undef($new_parents[$j]);
1852 }
1853 }
1854 }
1855 }
1856 push @$parents, grep { defined } @new_parents;
1857 }
1858
1859 sub make_log_entry {
1860 my ($self, $rev, $parents, $ed, $parent_rev, $parent_path) = @_;
1861 my $untracked = $self->get_untracked($ed);
1862
1863 my @parents = @$parents;
1864 my $props = $ed->{dir_prop}{$self->path};
1865 if ( $props->{"svk:merge"} ) {
1866 $self->find_extra_svk_parents
1867 ($ed, $props->{"svk:merge"}, \@parents);
1868 }
1869 if ( $props->{"svn:mergeinfo"} ) {
1870 my $mi_changes = $self->mergeinfo_changes
1871 ($parent_path, $parent_rev,
1872 $self->path, $rev,
1873 $props->{"svn:mergeinfo"});
1874 $self->find_extra_svn_parents
1875 ($ed, $mi_changes, \@parents);
1876 }
1877
1878 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1879 print $un "r$rev\n" or croak $!;
1880 print $un $_, "\n" foreach @$untracked;
1881 my %log_entry = ( parents => \@parents, revision => $rev,
1882 log => '');
1883
1884 my $headrev;
1885 my $logged = delete $self->{logged_rev_props};
1886 if (!$logged || $self->{-want_revprops}) {
1887 my $rp = $self->ra->rev_proplist($rev);
1888 foreach (sort keys %$rp) {
1889 my $v = $rp->{$_};
1890 if (/^svn:(author|date|log)$/) {
1891 $log_entry{$1} = $v;
1892 } elsif ($_ eq 'svm:headrev') {
1893 $headrev = $v;
1894 } else {
1895 print $un " rev_prop: ", uri_encode($_), ' ',
1896 uri_encode($v), "\n";
1897 }
1898 }
1899 } else {
1900 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1901 }
1902 close $un or croak $!;
1903
1904 $log_entry{date} = parse_svn_date($log_entry{date});
1905 $log_entry{log} .= "\n";
1906 my $author = $log_entry{author} = check_author($log_entry{author});
1907 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1908 : ($author, undef);
1909
1910 my ($commit_name, $commit_email) = ($name, $email);
1911 if ($_use_log_author) {
1912 my $name_field;
1913 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
1914 $name_field = $1;
1915 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
1916 $name_field = $1;
1917 }
1918 if (!defined $name_field) {
1919 if (!defined $email) {
1920 $email = $name;
1921 }
1922 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
1923 ($name, $email) = ($1, $2);
1924 } elsif ($name_field =~ /(.*)@/) {
1925 ($name, $email) = ($1, $name_field);
1926 } else {
1927 ($name, $email) = ($name_field, $name_field);
1928 }
1929 }
1930 if (defined $headrev && $self->use_svm_props) {
1931 if ($self->rewrite_root) {
1932 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1933 "options set!\n";
1934 }
1935 if ($self->rewrite_uuid) {
1936 die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
1937 "options set!\n";
1938 }
1939 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
1940 # we don't want "SVM: initializing mirror for junk" ...
1941 return undef if $r == 0;
1942 my $svm = $self->svm;
1943 if ($uuid ne $svm->{uuid}) {
1944 die "UUID mismatch on SVM path:\n",
1945 "expected: $svm->{uuid}\n",
1946 " got: $uuid\n";
1947 }
1948 my $full_url = $self->full_url;
1949 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1950 die "Failed to replace '$svm->{replace}' with ",
1951 "'$svm->{source}' in $full_url\n";
1952 # throw away username for storing in records
1953 remove_username($full_url);
1954 $log_entry{metadata} = "$full_url\@$r $uuid";
1955 $log_entry{svm_revision} = $r;
1956 $email ||= "$author\@$uuid";
1957 $commit_email ||= "$author\@$uuid";
1958 } elsif ($self->use_svnsync_props) {
1959 my $full_url = canonicalize_url(
1960 add_path_to_url( $self->svnsync->{url}, $self->path )
1961 );
1962 remove_username($full_url);
1963 my $uuid = $self->svnsync->{uuid};
1964 $log_entry{metadata} = "$full_url\@$rev $uuid";
1965 $email ||= "$author\@$uuid";
1966 $commit_email ||= "$author\@$uuid";
1967 } else {
1968 my $url = $self->metadata_url;
1969 remove_username($url);
1970 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
1971 $log_entry{metadata} = "$url\@$rev " . $uuid;
1972 $email ||= "$author\@" . $uuid;
1973 $commit_email ||= "$author\@" . $uuid;
1974 }
1975 $log_entry{name} = $name;
1976 $log_entry{email} = $email;
1977 $log_entry{commit_name} = $commit_name;
1978 $log_entry{commit_email} = $commit_email;
1979 \%log_entry;
1980 }
1981
1982 sub fetch {
1983 my ($self, $min_rev, $max_rev, @parents) = @_;
1984 my ($last_rev, $last_commit) = $self->last_rev_commit;
1985 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1986 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1987 }
1988
1989 sub set_tree_cb {
1990 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1991 $self->{inject_parents} = { $rev => $tree };
1992 $self->fetch(undef, undef);
1993 }
1994
1995 sub set_tree {
1996 my ($self, $tree) = (shift, shift);
1997 my $log_entry = ::get_commit_entry($tree);
1998 unless ($self->{last_rev}) {
1999 fatal("Must have an existing revision to commit");
2000 }
2001 my %ed_opts = ( r => $self->{last_rev},
2002 log => $log_entry->{log},
2003 ra => $self->ra,
2004 tree_a => $self->{last_commit},
2005 tree_b => $tree,
2006 editor_cb => sub {
2007 $self->set_tree_cb($log_entry, $tree, @_) },
2008 svn_path => $self->path );
2009 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
2010 print "No changes\nr$self->{last_rev} = $tree\n";
2011 }
2012 }
2013
2014 sub rebuild_from_rev_db {
2015 my ($self, $path) = @_;
2016 my $r = -1;
2017 open my $fh, '<', $path or croak "open: $!";
2018 binmode $fh or croak "binmode: $!";
2019 while (<$fh>) {
2020 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2021 chomp($_);
2022 ++$r;
2023 next if $_ eq ('0' x 40);
2024 $self->rev_map_set($r, $_);
2025 print "r$r = $_\n";
2026 }
2027 close $fh or croak "close: $!";
2028 unlink $path or croak "unlink: $!";
2029 }
2030
2031 #define a global associate map to record rebuild status
2032 my %rebuild_status;
2033 #define a global associate map to record rebuild verify status
2034 my %rebuild_verify_status;
2035
2036 sub rebuild {
2037 my ($self) = @_;
2038 my $map_path = $self->map_path;
2039 my $partial = (-e $map_path && ! -z $map_path);
2040 my $verify_key = $self->refname.'^0';
2041 if (!$rebuild_verify_status{$verify_key}) {
2042 my $verify_result = ::verify_ref($verify_key);
2043 if ($verify_result) {
2044 $rebuild_verify_status{$verify_key} = 1;
2045 }
2046 }
2047 if (!$rebuild_verify_status{$verify_key}) {
2048 return;
2049 }
2050 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2051 my $rev_db = $self->rev_db_path;
2052 $self->rebuild_from_rev_db($rev_db);
2053 if ($self->use_svm_props) {
2054 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2055 $self->rebuild_from_rev_db($svm_rev_db);
2056 }
2057 $self->unlink_rev_db_symlink;
2058 return;
2059 }
2060 print "Rebuilding $map_path ...\n" if (!$partial);
2061 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2062 (undef, undef));
2063 my $key_value = ($head ? "$head.." : "") . $self->refname;
2064 if (exists $rebuild_status{$key_value}) {
2065 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2066 my $rev_db_path = $self->rev_db_path;
2067 if (-f $self->rev_db_path) {
2068 unlink $self->rev_db_path or croak "unlink: $!";
2069 }
2070 $self->unlink_rev_db_symlink;
2071 return;
2072 }
2073 my ($log, $ctx) =
2074 command_output_pipe(qw/rev-list --pretty=raw --reverse/,
2075 $key_value,
2076 '--');
2077 $rebuild_status{$key_value} = 1;
2078 my $metadata_url = $self->metadata_url;
2079 remove_username($metadata_url);
2080 my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
2081 my $c;
2082 while (<$log>) {
2083 if ( m{^commit ($::sha1)$} ) {
2084 $c = $1;
2085 next;
2086 }
2087 next unless s{^\s*(git-svn-id:)}{$1};
2088 my ($url, $rev, $uuid) = ::extract_metadata($_);
2089 remove_username($url);
2090
2091 # ignore merges (from set-tree)
2092 next if (!defined $rev || !$uuid);
2093
2094 # if we merged or otherwise started elsewhere, this is
2095 # how we break out of it
2096 if (($uuid ne $svn_uuid) ||
2097 ($metadata_url && $url && ($url ne $metadata_url))) {
2098 next;
2099 }
2100 if ($partial && $head) {
2101 print "Partial-rebuilding $map_path ...\n";
2102 print "Currently at $base_rev = $head\n";
2103 $head = undef;
2104 }
2105
2106 $self->rev_map_set($rev, $c);
2107 print "r$rev = $c\n";
2108 }
2109 command_close_pipe($log, $ctx);
2110 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2111 my $rev_db_path = $self->rev_db_path;
2112 if (-f $self->rev_db_path) {
2113 unlink $self->rev_db_path or croak "unlink: $!";
2114 }
2115 $self->unlink_rev_db_symlink;
2116 }
2117
2118 # rev_map:
2119 # Tie::File seems to be prone to offset errors if revisions get sparse,
2120 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2121 # one of my favorite modules is out :< Next up would be one of the DBM
2122 # modules, but I'm not sure which is most portable...
2123 #
2124 # This is the replacement for the rev_db format, which was too big
2125 # and inefficient for large repositories with a lot of sparse history
2126 # (mainly tags)
2127 #
2128 # The format is this:
2129 # - 24 bytes for every record,
2130 # * 4 bytes for the integer representing an SVN revision number
2131 # * 20 bytes representing the sha1 of a git commit
2132 # - No empty padding records like the old format
2133 # (except the last record, which can be overwritten)
2134 # - new records are written append-only since SVN revision numbers
2135 # increase monotonically
2136 # - lookups on SVN revision number are done via a binary search
2137 # - Piping the file to xxd -c24 is a good way of dumping it for
2138 # viewing or editing (piped back through xxd -r), should the need
2139 # ever arise.
2140 # - The last record can be padding revision with an all-zero sha1
2141 # This is used to optimize fetch performance when using multiple
2142 # "fetch" directives in .git/config
2143 #
2144 # These files are disposable unless noMetadata or useSvmProps is set
2145
2146 sub _rev_map_set {
2147 my ($fh, $rev, $commit) = @_;
2148
2149 binmode $fh or croak "binmode: $!";
2150 my $size = (stat($fh))[7];
2151 ($size % 24) == 0 or croak "inconsistent size: $size";
2152
2153 my $wr_offset = 0;
2154 if ($size > 0) {
2155 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2156 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2157 $read == 24 or croak "read only $read bytes (!= 24)";
2158 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2159 if ($last_commit eq ('0' x40)) {
2160 if ($size >= 48) {
2161 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2162 $read = sysread($fh, $buf, 24) or
2163 croak "read: $!";
2164 $read == 24 or
2165 croak "read only $read bytes (!= 24)";
2166 ($last_rev, $last_commit) =
2167 unpack(rev_map_fmt, $buf);
2168 if ($last_commit eq ('0' x40)) {
2169 croak "inconsistent .rev_map\n";
2170 }
2171 }
2172 if ($last_rev >= $rev) {
2173 croak "last_rev is higher!: $last_rev >= $rev";
2174 }
2175 $wr_offset = -24;
2176 }
2177 }
2178 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2179 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2180 croak "write: $!";
2181 }
2182
2183 sub _rev_map_reset {
2184 my ($fh, $rev, $commit) = @_;
2185 my $c = _rev_map_get($fh, $rev);
2186 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
2187 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
2188 truncate $fh, $offset or croak "truncate: $!";
2189 }
2190
2191 sub mkfile {
2192 my ($path) = @_;
2193 unless (-e $path) {
2194 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2195 mkpath([$dir]) unless -d $dir;
2196 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2197 close $fh or die "Couldn't close (create) $path: $!\n";
2198 }
2199 }
2200
2201 sub rev_map_set {
2202 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2203 defined $commit or die "missing arg3\n";
2204 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2205 my $db = $self->map_path($uuid);
2206 my $db_lock = "$db.lock";
2207 my $sigmask;
2208 $update_ref ||= 0;
2209 if ($update_ref) {
2210 $sigmask = POSIX::SigSet->new();
2211 my $signew = POSIX::SigSet->new(SIGINT, SIGHUP, SIGTERM,
2212 SIGALRM, SIGUSR1, SIGUSR2);
2213 sigprocmask(SIG_BLOCK, $signew, $sigmask) or
2214 croak "Can't block signals: $!";
2215 }
2216 mkfile($db);
2217
2218 $LOCKFILES{$db_lock} = 1;
2219 my $sync;
2220 # both of these options make our .rev_db file very, very important
2221 # and we can't afford to lose it because rebuild() won't work
2222 if ($self->use_svm_props || $self->no_metadata) {
2223 $sync = 1;
2224 copy($db, $db_lock) or die "rev_map_set(@_): ",
2225 "Failed to copy: ",
2226 "$db => $db_lock ($!)\n";
2227 } else {
2228 rename $db, $db_lock or die "rev_map_set(@_): ",
2229 "Failed to rename: ",
2230 "$db => $db_lock ($!)\n";
2231 }
2232
2233 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2234 or croak "Couldn't open $db_lock: $!\n";
2235 if ($update_ref eq 'reset') {
2236 clear_memoized_mergeinfo_caches();
2237 _rev_map_reset($fh, $rev, $commit);
2238 } else {
2239 _rev_map_set($fh, $rev, $commit);
2240 }
2241
2242 if ($sync) {
2243 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2244 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2245 }
2246 close $fh or croak $!;
2247 if ($update_ref) {
2248 $_head = $self;
2249 my $note = "";
2250 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
2251 command_noisy('update-ref', '-m', "r$rev$note",
2252 $self->refname, $commit);
2253 }
2254 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2255 "$db_lock => $db ($!)\n";
2256 delete $LOCKFILES{$db_lock};
2257 if ($update_ref) {
2258 sigprocmask(SIG_SETMASK, $sigmask) or
2259 croak "Can't restore signal mask: $!";
2260 }
2261 }
2262
2263 # If want_commit, this will return an array of (rev, commit) where
2264 # commit _must_ be a valid commit in the archive.
2265 # Otherwise, it'll return the max revision (whether or not the
2266 # commit is valid or just a 0x40 placeholder).
2267 sub rev_map_max {
2268 my ($self, $want_commit) = @_;
2269 $self->rebuild;
2270 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2271 $want_commit ? ($r, $c) : $r;
2272 }
2273
2274 sub rev_map_max_norebuild {
2275 my ($self, $want_commit) = @_;
2276 my $map_path = $self->map_path;
2277 stat $map_path or return $want_commit ? (0, undef) : 0;
2278 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2279 binmode $fh or croak "binmode: $!";
2280 my $size = (stat($fh))[7];
2281 ($size % 24) == 0 or croak "inconsistent size: $size";
2282
2283 if ($size == 0) {
2284 close $fh or croak "close: $!";
2285 return $want_commit ? (0, undef) : 0;
2286 }
2287
2288 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2289 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2290 my ($r, $c) = unpack(rev_map_fmt, $buf);
2291 if ($want_commit && $c eq ('0' x40)) {
2292 if ($size < 48) {
2293 return $want_commit ? (0, undef) : 0;
2294 }
2295 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2296 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2297 ($r, $c) = unpack(rev_map_fmt, $buf);
2298 if ($c eq ('0'x40)) {
2299 croak "Penultimate record is all-zeroes in $map_path";
2300 }
2301 }
2302 close $fh or croak "close: $!";
2303 $want_commit ? ($r, $c) : $r;
2304 }
2305
2306 sub rev_map_get {
2307 my ($self, $rev, $uuid) = @_;
2308 my $map_path = $self->map_path($uuid);
2309 return undef unless -e $map_path;
2310
2311 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2312 my $c = _rev_map_get($fh, $rev);
2313 close($fh) or croak "close: $!";
2314 $c
2315 }
2316
2317 sub _rev_map_get {
2318 my ($fh, $rev) = @_;
2319
2320 binmode $fh or croak "binmode: $!";
2321 my $size = (stat($fh))[7];
2322 ($size % 24) == 0 or croak "inconsistent size: $size";
2323
2324 if ($size == 0) {
2325 return undef;
2326 }
2327
2328 my ($l, $u) = (0, $size - 24);
2329 my ($r, $c, $buf);
2330
2331 while ($l <= $u) {
2332 my $i = int(($l/24 + $u/24) / 2) * 24;
2333 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2334 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2335 my ($r, $c) = unpack(rev_map_fmt, $buf);
2336
2337 if ($r < $rev) {
2338 $l = $i + 24;
2339 } elsif ($r > $rev) {
2340 $u = $i - 24;
2341 } else { # $r == $rev
2342 return $c eq ('0' x 40) ? undef : $c;
2343 }
2344 }
2345 undef;
2346 }
2347
2348 # Finds the first svn revision that exists on (if $eq_ok is true) or
2349 # before $rev for the current branch. It will not search any lower
2350 # than $min_rev. Returns the git commit hash and svn revision number
2351 # if found, else (undef, undef).
2352 sub find_rev_before {
2353 my ($self, $rev, $eq_ok, $min_rev) = @_;
2354 --$rev unless $eq_ok;
2355 $min_rev ||= 1;
2356 my $max_rev = $self->rev_map_max;
2357 $rev = $max_rev if ($rev > $max_rev);
2358 while ($rev >= $min_rev) {
2359 if (my $c = $self->rev_map_get($rev)) {
2360 return ($rev, $c);
2361 }
2362 --$rev;
2363 }
2364 return (undef, undef);
2365 }
2366
2367 # Finds the first svn revision that exists on (if $eq_ok is true) or
2368 # after $rev for the current branch. It will not search any higher
2369 # than $max_rev. Returns the git commit hash and svn revision number
2370 # if found, else (undef, undef).
2371 sub find_rev_after {
2372 my ($self, $rev, $eq_ok, $max_rev) = @_;
2373 ++$rev unless $eq_ok;
2374 $max_rev ||= $self->rev_map_max;
2375 while ($rev <= $max_rev) {
2376 if (my $c = $self->rev_map_get($rev)) {
2377 return ($rev, $c);
2378 }
2379 ++$rev;
2380 }
2381 return (undef, undef);
2382 }
2383
2384 sub _new {
2385 my ($class, $repo_id, $ref_id, $path) = @_;
2386 unless (defined $repo_id && length $repo_id) {
2387 $repo_id = $default_repo_id;
2388 }
2389 unless (defined $ref_id && length $ref_id) {
2390 # Access the prefix option from the git-svn main program if it's loaded.
2391 my $prefix = defined &::opt_prefix ? ::opt_prefix() : "";
2392 $_[2] = $ref_id =
2393 "refs/remotes/$prefix$default_ref_id";
2394 }
2395 $_[1] = $repo_id;
2396 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2397
2398 # Older repos imported by us used $GIT_DIR/svn/foo instead of
2399 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
2400 if ($ref_id =~ m{^refs/remotes/(.*)}) {
2401 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
2402 if (-d $old_dir && ! -d $dir) {
2403 $dir = $old_dir;
2404 }
2405 }
2406
2407 $_[3] = $path = '' unless (defined $path);
2408 mkpath([$dir]);
2409 my $obj = bless {
2410 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2411 config => "$ENV{GIT_DIR}/svn/config",
2412 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2413
2414 # Ensure it gets canonicalized
2415 $obj->path($path);
2416
2417 return $obj;
2418 }
2419
2420 sub path {
2421 my $self = shift;
2422
2423 if (@_) {
2424 my $path = shift;
2425 $self->{_path} = canonicalize_path($path);
2426 return;
2427 }
2428
2429 return $self->{_path};
2430 }
2431
2432 sub url {
2433 my $self = shift;
2434
2435 if (@_) {
2436 my $url = shift;
2437 $self->{url} = canonicalize_url($url);
2438 return;
2439 }
2440
2441 return $self->{url};
2442 }
2443
2444 # for read-only access of old .rev_db formats
2445 sub unlink_rev_db_symlink {
2446 my ($self) = @_;
2447 my $link = $self->rev_db_path;
2448 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2449 if (-l $link) {
2450 unlink $link or croak "unlink: $link failed!";
2451 }
2452 }
2453
2454 sub rev_db_path {
2455 my ($self, $uuid) = @_;
2456 my $db_path = $self->map_path($uuid);
2457 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2458 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2459 $db_path;
2460 }
2461
2462 # the new replacement for .rev_db
2463 sub map_path {
2464 my ($self, $uuid) = @_;
2465 $uuid ||= $self->ra_uuid;
2466 "$self->{map_root}.$uuid";
2467 }
2468
2469 sub uri_encode {
2470 my ($f) = @_;
2471 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#sprintf("%%%02X",ord($1))#eg;
2472 $f
2473 }
2474
2475 sub uri_decode {
2476 my ($f) = @_;
2477 $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
2478 $f
2479 }
2480
2481 sub remove_username {
2482 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2483 }
2484
2485 1;
MinGW port of GIT