gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99 # URI of GIT logo (72x27 size)
 100 our $logo = "++GITWEB_LOGO++";
 101 # URI of GIT favicon, assumed to be image/png type
 102 our $favicon = "++GITWEB_FAVICON++";
 103 # URI of gitweb.js (JavaScript code for gitweb)
 104 our $javascript = "++GITWEB_JS++";
 105
 106 # URI and label (title) of GIT logo link
 107 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 108 #our $logo_label = "git documentation";
 109 our $logo_url = "http://git-scm.com/";
 110 our $logo_label = "git homepage";
 111
 112 # source of projects list
 113 our $projects_list = "++GITWEB_LIST++";
 114
 115 # the width (in characters) of the projects list "Description" column
 116 our $projects_list_description_width = 25;
 117
 118 # group projects by category on the projects list
 119 # (enabled if this variable evaluates to true)
 120 our $projects_list_group_categories = 0;
 121
 122 # default category if none specified
 123 # (leave the empty string for no category)
 124 our $project_list_default_category = "";
 125
 126 # default order of projects list
 127 # valid values are none, project, descr, owner, and age
 128 our $default_projects_order = "project";
 129
 130 # show repository only if this file exists
 131 # (only effective if this variable evaluates to true)
 132 our $export_ok = "++GITWEB_EXPORT_OK++";
 133
 134 # show repository only if this subroutine returns true
 135 # when given the path to the project, for example:
 136 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 137 our $export_auth_hook = undef;
 138
 139 # only allow viewing of repositories also shown on the overview page
 140 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 141
 142 # list of git base URLs used for URL to where fetch project from,
 143 # i.e. full URL is "$git_base_url/$project"
 144 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 145
 146 # default blob_plain mimetype and default charset for text/plain blob
 147 our $default_blob_plain_mimetype = 'text/plain';
 148 our $default_text_plain_charset  = undef;
 149
 150 # file to use for guessing MIME types before trying /etc/mime.types
 151 # (relative to the current git repository)
 152 our $mimetypes_file = undef;
 153
 154 # assume this charset if line contains non-UTF-8 characters;
 155 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 156 # for which encoding all byte sequences are valid, for example
 157 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 158 # could be even 'utf-8' for the old behavior)
 159 our $fallback_encoding = 'latin1';
 160
 161 # rename detection options for git-diff and git-diff-tree
 162 # - default is '-M', with the cost proportional to
 163 #   (number of removed files) * (number of new files).
 164 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 165 #   (number of changed files + number of removed files) * (number of new files)
 166 # - even more costly is '-C', '--find-copies-harder' with cost
 167 #   (number of files in the original tree) * (number of new files)
 168 # - one might want to include '-B' option, e.g. '-B', '-M'
 169 our @diff_opts = ('-M'); # taken from git_commit
 170
 171 # Disables features that would allow repository owners to inject script into
 172 # the gitweb domain.
 173 our $prevent_xss = 0;
 174
 175 # Path to the highlight executable to use (must be the one from
 176 # http://www.andre-simon.de due to assumptions about parameters and output).
 177 # Useful if highlight is not installed on your webserver's PATH.
 178 # [Default: highlight]
 179 our $highlight_bin = "++HIGHLIGHT_BIN++";
 180
 181 # information about snapshot formats that gitweb is capable of serving
 182 our %known_snapshot_formats = (
 183         # name => {
 184         #       'display' => display name,
 185         #       'type' => mime type,
 186         #       'suffix' => filename suffix,
 187         #       'format' => --format for git-archive,
 188         #       'compressor' => [compressor command and arguments]
 189         #                       (array reference, optional)
 190         #       'disabled' => boolean (optional)}
 191         #
 192         'tgz' => {
 193                 'display' => 'tar.gz',
 194                 'type' => 'application/x-gzip',
 195                 'suffix' => '.tar.gz',
 196                 'format' => 'tar',
 197                 'compressor' => ['gzip', '-n']},
 198
 199         'tbz2' => {
 200                 'display' => 'tar.bz2',
 201                 'type' => 'application/x-bzip2',
 202                 'suffix' => '.tar.bz2',
 203                 'format' => 'tar',
 204                 'compressor' => ['bzip2']},
 205
 206         'txz' => {
 207                 'display' => 'tar.xz',
 208                 'type' => 'application/x-xz',
 209                 'suffix' => '.tar.xz',
 210                 'format' => 'tar',
 211                 'compressor' => ['xz'],
 212                 'disabled' => 1},
 213
 214         'zip' => {
 215                 'display' => 'zip',
 216                 'type' => 'application/x-zip',
 217                 'suffix' => '.zip',
 218                 'format' => 'zip'},
 219 );
 220
 221 # Aliases so we understand old gitweb.snapshot values in repository
 222 # configuration.
 223 our %known_snapshot_format_aliases = (
 224         'gzip'  => 'tgz',
 225         'bzip2' => 'tbz2',
 226         'xz'    => 'txz',
 227
 228         # backward compatibility: legacy gitweb config support
 229         'x-gzip' => undef, 'gz' => undef,
 230         'x-bzip2' => undef, 'bz2' => undef,
 231         'x-zip' => undef, '' => undef,
 232 );
 233
 234 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 235 # are changed, it may be appropriate to change these values too via
 236 # $GITWEB_CONFIG.
 237 our %avatar_size = (
 238         'default' => 16,
 239         'double'  => 32
 240 );
 241
 242 # Used to set the maximum load that we will still respond to gitweb queries.
 243 # If server load exceed this value then return "503 server busy" error.
 244 # If gitweb cannot determined server load, it is taken to be 0.
 245 # Leave it undefined (or set to 'undef') to turn off load checking.
 246 our $maxload = 300;
 247
 248 # configuration for 'highlight' (http://www.andre-simon.de/)
 249 # match by basename
 250 our %highlight_basename = (
 251         #'Program' => 'py',
 252         #'Library' => 'py',
 253         'SConstruct' => 'py', # SCons equivalent of Makefile
 254         'Makefile' => 'make',
 255 );
 256 # match by extension
 257 our %highlight_ext = (
 258         # main extensions, defining name of syntax;
 259         # see files in /usr/share/highlight/langDefs/ directory
 260         map { $_ => $_ }
 261                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 262         # alternate extensions, see /etc/highlight/filetypes.conf
 263         'h' => 'c',
 264         map { $_ => 'sh'  } qw(bash zsh ksh),
 265         map { $_ => 'cpp' } qw(cxx c++ cc),
 266         map { $_ => 'php' } qw(php3 php4 php5 phps),
 267         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 268         map { $_ => 'make'} qw(mak mk),
 269         map { $_ => 'xml' } qw(xhtml html htm),
 270 );
 271
 272 # You define site-wide feature defaults here; override them with
 273 # $GITWEB_CONFIG as necessary.
 274 our %feature = (
 275         # feature => {
 276         #       'sub' => feature-sub (subroutine),
 277         #       'override' => allow-override (boolean),
 278         #       'default' => [ default options...] (array reference)}
 279         #
 280         # if feature is overridable (it means that allow-override has true value),
 281         # then feature-sub will be called with default options as parameters;
 282         # return value of feature-sub indicates if to enable specified feature
 283         #
 284         # if there is no 'sub' key (no feature-sub), then feature cannot be
 285         # overridden
 286         #
 287         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 288         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 289         # is enabled
 290
 291         # Enable the 'blame' blob view, showing the last commit that modified
 292         # each line in the file. This can be very CPU-intensive.
 293
 294         # To enable system wide have in $GITWEB_CONFIG
 295         # $feature{'blame'}{'default'} = [1];
 296         # To have project specific config enable override in $GITWEB_CONFIG
 297         # $feature{'blame'}{'override'} = 1;
 298         # and in project config gitweb.blame = 0|1;
 299         'blame' => {
 300                 'sub' => sub { feature_bool('blame', @_) },
 301                 'override' => 0,
 302                 'default' => [0]},
 303
 304         # Enable the 'snapshot' link, providing a compressed archive of any
 305         # tree. This can potentially generate high traffic if you have large
 306         # project.
 307
 308         # Value is a list of formats defined in %known_snapshot_formats that
 309         # you wish to offer.
 310         # To disable system wide have in $GITWEB_CONFIG
 311         # $feature{'snapshot'}{'default'} = [];
 312         # To have project specific config enable override in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'override'} = 1;
 314         # and in project config, a comma-separated list of formats or "none"
 315         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 316         'snapshot' => {
 317                 'sub' => \&feature_snapshot,
 318                 'override' => 0,
 319                 'default' => ['tgz']},
 320
 321         # Enable text search, which will list the commits which match author,
 322         # committer or commit text to a given string.  Enabled by default.
 323         # Project specific override is not supported.
 324         'search' => {
 325                 'override' => 0,
 326                 'default' => [1]},
 327
 328         # Enable grep search, which will list the files in currently selected
 329         # tree containing the given string. Enabled by default. This can be
 330         # potentially CPU-intensive, of course.
 331         # Note that you need to have 'search' feature enabled too.
 332
 333         # To enable system wide have in $GITWEB_CONFIG
 334         # $feature{'grep'}{'default'} = [1];
 335         # To have project specific config enable override in $GITWEB_CONFIG
 336         # $feature{'grep'}{'override'} = 1;
 337         # and in project config gitweb.grep = 0|1;
 338         'grep' => {
 339                 'sub' => sub { feature_bool('grep', @_) },
 340                 'override' => 0,
 341                 'default' => [1]},
 342
 343         # Enable the pickaxe search, which will list the commits that modified
 344         # a given string in a file. This can be practical and quite faster
 345         # alternative to 'blame', but still potentially CPU-intensive.
 346         # Note that you need to have 'search' feature enabled too.
 347
 348         # To enable system wide have in $GITWEB_CONFIG
 349         # $feature{'pickaxe'}{'default'} = [1];
 350         # To have project specific config enable override in $GITWEB_CONFIG
 351         # $feature{'pickaxe'}{'override'} = 1;
 352         # and in project config gitweb.pickaxe = 0|1;
 353         'pickaxe' => {
 354                 'sub' => sub { feature_bool('pickaxe', @_) },
 355                 'override' => 0,
 356                 'default' => [1]},
 357
 358         # Enable showing size of blobs in a 'tree' view, in a separate
 359         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 360
 361         # To disable system wide have in $GITWEB_CONFIG
 362         # $feature{'show-sizes'}{'default'} = [0];
 363         # To have project specific config enable override in $GITWEB_CONFIG
 364         # $feature{'show-sizes'}{'override'} = 1;
 365         # and in project config gitweb.showsizes = 0|1;
 366         'show-sizes' => {
 367                 'sub' => sub { feature_bool('showsizes', @_) },
 368                 'override' => 0,
 369                 'default' => [1]},
 370
 371         # Make gitweb use an alternative format of the URLs which can be
 372         # more readable and natural-looking: project name is embedded
 373         # directly in the path and the query string contains other
 374         # auxiliary information. All gitweb installations recognize
 375         # URL in either format; this configures in which formats gitweb
 376         # generates links.
 377
 378         # To enable system wide have in $GITWEB_CONFIG
 379         # $feature{'pathinfo'}{'default'} = [1];
 380         # Project specific override is not supported.
 381
 382         # Note that you will need to change the default location of CSS,
 383         # favicon, logo and possibly other files to an absolute URL. Also,
 384         # if gitweb.cgi serves as your indexfile, you will need to force
 385         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 386         'pathinfo' => {
 387                 'override' => 0,
 388                 'default' => [0]},
 389
 390         # Make gitweb consider projects in project root subdirectories
 391         # to be forks of existing projects. Given project $projname.git,
 392         # projects matching $projname/*.git will not be shown in the main
 393         # projects list, instead a '+' mark will be added to $projname
 394         # there and a 'forks' view will be enabled for the project, listing
 395         # all the forks. If project list is taken from a file, forks have
 396         # to be listed after the main project.
 397
 398         # To enable system wide have in $GITWEB_CONFIG
 399         # $feature{'forks'}{'default'} = [1];
 400         # Project specific override is not supported.
 401         'forks' => {
 402                 'override' => 0,
 403                 'default' => [0]},
 404
 405         # Insert custom links to the action bar of all project pages.
 406         # This enables you mainly to link to third-party scripts integrating
 407         # into gitweb; e.g. git-browser for graphical history representation
 408         # or custom web-based repository administration interface.
 409
 410         # The 'default' value consists of a list of triplets in the form
 411         # (label, link, position) where position is the label after which
 412         # to insert the link and link is a format string where %n expands
 413         # to the project name, %f to the project path within the filesystem,
 414         # %h to the current hash (h gitweb parameter) and %b to the current
 415         # hash base (hb gitweb parameter); %% expands to %.
 416
 417         # To enable system wide have in $GITWEB_CONFIG e.g.
 418         # $feature{'actions'}{'default'} = [('graphiclog',
 419         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 420         # Project specific override is not supported.
 421         'actions' => {
 422                 'override' => 0,
 423                 'default' => []},
 424
 425         # Allow gitweb scan project content tags of project repository,
 426         # and display the popular Web 2.0-ish "tag cloud" near the projects
 427         # list.  Note that this is something COMPLETELY different from the
 428         # normal Git tags.
 429
 430         # gitweb by itself can show existing tags, but it does not handle
 431         # tagging itself; you need to do it externally, outside gitweb.
 432         # The format is described in git_get_project_ctags() subroutine.
 433         # You may want to install the HTML::TagCloud Perl module to get
 434         # a pretty tag cloud instead of just a list of tags.
 435
 436         # To enable system wide have in $GITWEB_CONFIG
 437         # $feature{'ctags'}{'default'} = [1];
 438         # Project specific override is not supported.
 439
 440         # In the future whether ctags editing is enabled might depend
 441         # on the value, but using 1 should always mean no editing of ctags.
 442         'ctags' => {
 443                 'override' => 0,
 444                 'default' => [0]},
 445
 446         # The maximum number of patches in a patchset generated in patch
 447         # view. Set this to 0 or undef to disable patch view, or to a
 448         # negative number to remove any limit.
 449
 450         # To disable system wide have in $GITWEB_CONFIG
 451         # $feature{'patches'}{'default'} = [0];
 452         # To have project specific config enable override in $GITWEB_CONFIG
 453         # $feature{'patches'}{'override'} = 1;
 454         # and in project config gitweb.patches = 0|n;
 455         # where n is the maximum number of patches allowed in a patchset.
 456         'patches' => {
 457                 'sub' => \&feature_patches,
 458                 'override' => 0,
 459                 'default' => [16]},
 460
 461         # Avatar support. When this feature is enabled, views such as
 462         # shortlog or commit will display an avatar associated with
 463         # the email of the committer(s) and/or author(s).
 464
 465         # Currently available providers are gravatar and picon.
 466         # If an unknown provider is specified, the feature is disabled.
 467
 468         # Gravatar depends on Digest::MD5.
 469         # Picon currently relies on the indiana.edu database.
 470
 471         # To enable system wide have in $GITWEB_CONFIG
 472         # $feature{'avatar'}{'default'} = ['<provider>'];
 473         # where <provider> is either gravatar or picon.
 474         # To have project specific config enable override in $GITWEB_CONFIG
 475         # $feature{'avatar'}{'override'} = 1;
 476         # and in project config gitweb.avatar = <provider>;
 477         'avatar' => {
 478                 'sub' => \&feature_avatar,
 479                 'override' => 0,
 480                 'default' => ['']},
 481
 482         # Enable displaying how much time and how many git commands
 483         # it took to generate and display page.  Disabled by default.
 484         # Project specific override is not supported.
 485         'timed' => {
 486                 'override' => 0,
 487                 'default' => [0]},
 488
 489         # Enable turning some links into links to actions which require
 490         # JavaScript to run (like 'blame_incremental').  Not enabled by
 491         # default.  Project specific override is currently not supported.
 492         'javascript-actions' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable and configure ability to change common timezone for dates
 497         # in gitweb output via JavaScript.  Enabled by default.
 498         # Project specific override is not supported.
 499         'javascript-timezone' => {
 500                 'override' => 0,
 501                 'default' => [
 502                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 503                                      # or undef to turn off this feature
 504                         'gitweb_tz', # name of cookie where to store selected timezone
 505                         'datetime',  # CSS class used to mark up dates for manipulation
 506                 ]},
 507
 508         # Syntax highlighting support. This is based on Daniel Svensson's
 509         # and Sham Chukoury's work in gitweb-xmms2.git.
 510         # It requires the 'highlight' program present in $PATH,
 511         # and therefore is disabled by default.
 512
 513         # To enable system wide have in $GITWEB_CONFIG
 514         # $feature{'highlight'}{'default'} = [1];
 515
 516         'highlight' => {
 517                 'sub' => sub { feature_bool('highlight', @_) },
 518                 'override' => 0,
 519                 'default' => [0]},
 520
 521         # Enable displaying of remote heads in the heads list
 522
 523         # To enable system wide have in $GITWEB_CONFIG
 524         # $feature{'remote_heads'}{'default'} = [1];
 525         # To have project specific config enable override in $GITWEB_CONFIG
 526         # $feature{'remote_heads'}{'override'} = 1;
 527         # and in project config gitweb.remote_heads = 0|1;
 528         'remote_heads' => {
 529                 'sub' => sub { feature_bool('remote_heads', @_) },
 530                 'override' => 0,
 531                 'default' => [0]},
 532 );
 533
 534 sub gitweb_get_feature {
 535         my ($name) = @_;
 536         return unless exists $feature{$name};
 537         my ($sub, $override, @defaults) = (
 538                 $feature{$name}{'sub'},
 539                 $feature{$name}{'override'},
 540                 @{$feature{$name}{'default'}});
 541         # project specific override is possible only if we have project
 542         our $git_dir; # global variable, declared later
 543         if (!$override || !defined $git_dir) {
 544                 return @defaults;
 545         }
 546         if (!defined $sub) {
 547                 warn "feature $name is not overridable";
 548                 return @defaults;
 549         }
 550         return $sub->(@defaults);
 551 }
 552
 553 # A wrapper to check if a given feature is enabled.
 554 # With this, you can say
 555 #
 556 #   my $bool_feat = gitweb_check_feature('bool_feat');
 557 #   gitweb_check_feature('bool_feat') or somecode;
 558 #
 559 # instead of
 560 #
 561 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 562 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 563 #
 564 sub gitweb_check_feature {
 565         return (gitweb_get_feature(@_))[0];
 566 }
 567
 568
 569 sub feature_bool {
 570         my $key = shift;
 571         my ($val) = git_get_project_config($key, '--bool');
 572
 573         if (!defined $val) {
 574                 return ($_[0]);
 575         } elsif ($val eq 'true') {
 576                 return (1);
 577         } elsif ($val eq 'false') {
 578                 return (0);
 579         }
 580 }
 581
 582 sub feature_snapshot {
 583         my (@fmts) = @_;
 584
 585         my ($val) = git_get_project_config('snapshot');
 586
 587         if ($val) {
 588                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 589         }
 590
 591         return @fmts;
 592 }
 593
 594 sub feature_patches {
 595         my @val = (git_get_project_config('patches', '--int'));
 596
 597         if (@val) {
 598                 return @val;
 599         }
 600
 601         return ($_[0]);
 602 }
 603
 604 sub feature_avatar {
 605         my @val = (git_get_project_config('avatar'));
 606
 607         return @val ? @val : @_;
 608 }
 609
 610 # checking HEAD file with -e is fragile if the repository was
 611 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 612 # and then pruned.
 613 sub check_head_link {
 614         my ($dir) = @_;
 615         my $headfile = "$dir/HEAD";
 616         return ((-e $headfile) ||
 617                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 618 }
 619
 620 sub check_export_ok {
 621         my ($dir) = @_;
 622         return (check_head_link($dir) &&
 623                 (!$export_ok || -e "$dir/$export_ok") &&
 624                 (!$export_auth_hook || $export_auth_hook->($dir)));
 625 }
 626
 627 # process alternate names for backward compatibility
 628 # filter out unsupported (unknown) snapshot formats
 629 sub filter_snapshot_fmts {
 630         my @fmts = @_;
 631
 632         @fmts = map {
 633                 exists $known_snapshot_format_aliases{$_} ?
 634                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 635         @fmts = grep {
 636                 exists $known_snapshot_formats{$_} &&
 637                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 638 }
 639
 640 # If it is set to code reference, it is code that it is to be run once per
 641 # request, allowing updating configurations that change with each request,
 642 # while running other code in config file only once.
 643 #
 644 # Otherwise, if it is false then gitweb would process config file only once;
 645 # if it is true then gitweb config would be run for each request.
 646 our $per_request_config = 1;
 647
 648 # read and parse gitweb config file given by its parameter.
 649 # returns true on success, false on recoverable error, allowing
 650 # to chain this subroutine, using first file that exists.
 651 # dies on errors during parsing config file, as it is unrecoverable.
 652 sub read_config_file {
 653         my $filename = shift;
 654         return unless defined $filename;
 655         # die if there are errors parsing config file
 656         if (-e $filename) {
 657                 do $filename;
 658                 die $@ if $@;
 659                 return 1;
 660         }
 661         return;
 662 }
 663
 664 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 665 sub evaluate_gitweb_config {
 666         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 667         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 668
 669         # use first config file that exists
 670         read_config_file($GITWEB_CONFIG) or
 671         read_config_file($GITWEB_CONFIG_SYSTEM);
 672 }
 673
 674 # Get loadavg of system, to compare against $maxload.
 675 # Currently it requires '/proc/loadavg' present to get loadavg;
 676 # if it is not present it returns 0, which means no load checking.
 677 sub get_loadavg {
 678         if( -e '/proc/loadavg' ){
 679                 open my $fd, '<', '/proc/loadavg'
 680                         or return 0;
 681                 my @load = split(/\s+/, scalar <$fd>);
 682                 close $fd;
 683
 684                 # The first three columns measure CPU and IO utilization of the last one,
 685                 # five, and 10 minute periods.  The fourth column shows the number of
 686                 # currently running processes and the total number of processes in the m/n
 687                 # format.  The last column displays the last process ID used.
 688                 return $load[0] || 0;
 689         }
 690         # additional checks for load average should go here for things that don't export
 691         # /proc/loadavg
 692
 693         return 0;
 694 }
 695
 696 # version of the core git binary
 697 our $git_version;
 698 sub evaluate_git_version {
 699         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 700         $number_of_git_cmds++;
 701 }
 702
 703 sub check_loadavg {
 704         if (defined $maxload && get_loadavg() > $maxload) {
 705                 die_error(503, "The load average on the server is too high");
 706         }
 707 }
 708
 709 # ======================================================================
 710 # input validation and dispatch
 711
 712 # input parameters can be collected from a variety of sources (presently, CGI
 713 # and PATH_INFO), so we define an %input_params hash that collects them all
 714 # together during validation: this allows subsequent uses (e.g. href()) to be
 715 # agnostic of the parameter origin
 716
 717 our %input_params = ();
 718
 719 # input parameters are stored with the long parameter name as key. This will
 720 # also be used in the href subroutine to convert parameters to their CGI
 721 # equivalent, and since the href() usage is the most frequent one, we store
 722 # the name -> CGI key mapping here, instead of the reverse.
 723 #
 724 # XXX: Warning: If you touch this, check the search form for updating,
 725 # too.
 726
 727 our @cgi_param_mapping = (
 728         project => "p",
 729         action => "a",
 730         file_name => "f",
 731         file_parent => "fp",
 732         hash => "h",
 733         hash_parent => "hp",
 734         hash_base => "hb",
 735         hash_parent_base => "hpb",
 736         page => "pg",
 737         order => "o",
 738         searchtext => "s",
 739         searchtype => "st",
 740         snapshot_format => "sf",
 741         extra_options => "opt",
 742         search_use_regexp => "sr",
 743         ctag => "by_tag",
 744         # this must be last entry (for manipulation from JavaScript)
 745         javascript => "js"
 746 );
 747 our %cgi_param_mapping = @cgi_param_mapping;
 748
 749 # we will also need to know the possible actions, for validation
 750 our %actions = (
 751         "blame" => \&git_blame,
 752         "blame_incremental" => \&git_blame_incremental,
 753         "blame_data" => \&git_blame_data,
 754         "blobdiff" => \&git_blobdiff,
 755         "blobdiff_plain" => \&git_blobdiff_plain,
 756         "blob" => \&git_blob,
 757         "blob_plain" => \&git_blob_plain,
 758         "commitdiff" => \&git_commitdiff,
 759         "commitdiff_plain" => \&git_commitdiff_plain,
 760         "commit" => \&git_commit,
 761         "forks" => \&git_forks,
 762         "heads" => \&git_heads,
 763         "history" => \&git_history,
 764         "log" => \&git_log,
 765         "patch" => \&git_patch,
 766         "patches" => \&git_patches,
 767         "remotes" => \&git_remotes,
 768         "rss" => \&git_rss,
 769         "atom" => \&git_atom,
 770         "search" => \&git_search,
 771         "search_help" => \&git_search_help,
 772         "shortlog" => \&git_shortlog,
 773         "summary" => \&git_summary,
 774         "tag" => \&git_tag,
 775         "tags" => \&git_tags,
 776         "tree" => \&git_tree,
 777         "snapshot" => \&git_snapshot,
 778         "object" => \&git_object,
 779         # those below don't need $project
 780         "opml" => \&git_opml,
 781         "project_list" => \&git_project_list,
 782         "project_index" => \&git_project_index,
 783 );
 784
 785 # finally, we have the hash of allowed extra_options for the commands that
 786 # allow them
 787 our %allowed_options = (
 788         "--no-merges" => [ qw(rss atom log shortlog history) ],
 789 );
 790
 791 # fill %input_params with the CGI parameters. All values except for 'opt'
 792 # should be single values, but opt can be an array. We should probably
 793 # build an array of parameters that can be multi-valued, but since for the time
 794 # being it's only this one, we just single it out
 795 sub evaluate_query_params {
 796         our $cgi;
 797
 798         while (my ($name, $symbol) = each %cgi_param_mapping) {
 799                 if ($symbol eq 'opt') {
 800                         $input_params{$name} = [ $cgi->param($symbol) ];
 801                 } else {
 802                         $input_params{$name} = $cgi->param($symbol);
 803                 }
 804         }
 805 }
 806
 807 # now read PATH_INFO and update the parameter list for missing parameters
 808 sub evaluate_path_info {
 809         return if defined $input_params{'project'};
 810         return if !$path_info;
 811         $path_info =~ s,^/+,,;
 812         return if !$path_info;
 813
 814         # find which part of PATH_INFO is project
 815         my $project = $path_info;
 816         $project =~ s,/+$,,;
 817         while ($project && !check_head_link("$projectroot/$project")) {
 818                 $project =~ s,/*[^/]*$,,;
 819         }
 820         return unless $project;
 821         $input_params{'project'} = $project;
 822
 823         # do not change any parameters if an action is given using the query string
 824         return if $input_params{'action'};
 825         $path_info =~ s,^\Q$project\E/*,,;
 826
 827         # next, check if we have an action
 828         my $action = $path_info;
 829         $action =~ s,/.*$,,;
 830         if (exists $actions{$action}) {
 831                 $path_info =~ s,^$action/*,,;
 832                 $input_params{'action'} = $action;
 833         }
 834
 835         # list of actions that want hash_base instead of hash, but can have no
 836         # pathname (f) parameter
 837         my @wants_base = (
 838                 'tree',
 839                 'history',
 840         );
 841
 842         # we want to catch, among others
 843         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 844         my ($parentrefname, $parentpathname, $refname, $pathname) =
 845                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 846
 847         # first, analyze the 'current' part
 848         if (defined $pathname) {
 849                 # we got "branch:filename" or "branch:dir/"
 850                 # we could use git_get_type(branch:pathname), but:
 851                 # - it needs $git_dir
 852                 # - it does a git() call
 853                 # - the convention of terminating directories with a slash
 854                 #   makes it superfluous
 855                 # - embedding the action in the PATH_INFO would make it even
 856                 #   more superfluous
 857                 $pathname =~ s,^/+,,;
 858                 if (!$pathname || substr($pathname, -1) eq "/") {
 859                         $input_params{'action'} ||= "tree";
 860                         $pathname =~ s,/$,,;
 861                 } else {
 862                         # the default action depends on whether we had parent info
 863                         # or not
 864                         if ($parentrefname) {
 865                                 $input_params{'action'} ||= "blobdiff_plain";
 866                         } else {
 867                                 $input_params{'action'} ||= "blob_plain";
 868                         }
 869                 }
 870                 $input_params{'hash_base'} ||= $refname;
 871                 $input_params{'file_name'} ||= $pathname;
 872         } elsif (defined $refname) {
 873                 # we got "branch". In this case we have to choose if we have to
 874                 # set hash or hash_base.
 875                 #
 876                 # Most of the actions without a pathname only want hash to be
 877                 # set, except for the ones specified in @wants_base that want
 878                 # hash_base instead. It should also be noted that hand-crafted
 879                 # links having 'history' as an action and no pathname or hash
 880                 # set will fail, but that happens regardless of PATH_INFO.
 881                 if (defined $parentrefname) {
 882                         # if there is parent let the default be 'shortlog' action
 883                         # (for http://git.example.com/repo.git/A..B links); if there
 884                         # is no parent, dispatch will detect type of object and set
 885                         # action appropriately if required (if action is not set)
 886                         $input_params{'action'} ||= "shortlog";
 887                 }
 888                 if ($input_params{'action'} &&
 889                     grep { $_ eq $input_params{'action'} } @wants_base) {
 890                         $input_params{'hash_base'} ||= $refname;
 891                 } else {
 892                         $input_params{'hash'} ||= $refname;
 893                 }
 894         }
 895
 896         # next, handle the 'parent' part, if present
 897         if (defined $parentrefname) {
 898                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 899                 # someproject/blobdiff/oldrev..newrev:/filename
 900                 if ($parentpathname) {
 901                         $parentpathname =~ s,^/+,,;
 902                         $parentpathname =~ s,/$,,;
 903                         $input_params{'file_parent'} ||= $parentpathname;
 904                 } else {
 905                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 906                 }
 907                 # we assume that hash_parent_base is wanted if a path was specified,
 908                 # or if the action wants hash_base instead of hash
 909                 if (defined $input_params{'file_parent'} ||
 910                         grep { $_ eq $input_params{'action'} } @wants_base) {
 911                         $input_params{'hash_parent_base'} ||= $parentrefname;
 912                 } else {
 913                         $input_params{'hash_parent'} ||= $parentrefname;
 914                 }
 915         }
 916
 917         # for the snapshot action, we allow URLs in the form
 918         # $project/snapshot/$hash.ext
 919         # where .ext determines the snapshot and gets removed from the
 920         # passed $refname to provide the $hash.
 921         #
 922         # To be able to tell that $refname includes the format extension, we
 923         # require the following two conditions to be satisfied:
 924         # - the hash input parameter MUST have been set from the $refname part
 925         #   of the URL (i.e. they must be equal)
 926         # - the snapshot format MUST NOT have been defined already (e.g. from
 927         #   CGI parameter sf)
 928         # It's also useless to try any matching unless $refname has a dot,
 929         # so we check for that too
 930         if (defined $input_params{'action'} &&
 931                 $input_params{'action'} eq 'snapshot' &&
 932                 defined $refname && index($refname, '.') != -1 &&
 933                 $refname eq $input_params{'hash'} &&
 934                 !defined $input_params{'snapshot_format'}) {
 935                 # We loop over the known snapshot formats, checking for
 936                 # extensions. Allowed extensions are both the defined suffix
 937                 # (which includes the initial dot already) and the snapshot
 938                 # format key itself, with a prepended dot
 939                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 940                         my $hash = $refname;
 941                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 942                                 next;
 943                         }
 944                         my $sfx = $1;
 945                         # a valid suffix was found, so set the snapshot format
 946                         # and reset the hash parameter
 947                         $input_params{'snapshot_format'} = $fmt;
 948                         $input_params{'hash'} = $hash;
 949                         # we also set the format suffix to the one requested
 950                         # in the URL: this way a request for e.g. .tgz returns
 951                         # a .tgz instead of a .tar.gz
 952                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 953                         last;
 954                 }
 955         }
 956 }
 957
 958 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 959      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 960      $searchtext, $search_regexp);
 961 sub evaluate_and_validate_params {
 962         our $action = $input_params{'action'};
 963         if (defined $action) {
 964                 if (!validate_action($action)) {
 965                         die_error(400, "Invalid action parameter");
 966                 }
 967         }
 968
 969         # parameters which are pathnames
 970         our $project = $input_params{'project'};
 971         if (defined $project) {
 972                 if (!validate_project($project)) {
 973                         undef $project;
 974                         die_error(404, "No such project");
 975                 }
 976         }
 977
 978         our $file_name = $input_params{'file_name'};
 979         if (defined $file_name) {
 980                 if (!validate_pathname($file_name)) {
 981                         die_error(400, "Invalid file parameter");
 982                 }
 983         }
 984
 985         our $file_parent = $input_params{'file_parent'};
 986         if (defined $file_parent) {
 987                 if (!validate_pathname($file_parent)) {
 988                         die_error(400, "Invalid file parent parameter");
 989                 }
 990         }
 991
 992         # parameters which are refnames
 993         our $hash = $input_params{'hash'};
 994         if (defined $hash) {
 995                 if (!validate_refname($hash)) {
 996                         die_error(400, "Invalid hash parameter");
 997                 }
 998         }
 999
1000         our $hash_parent = $input_params{'hash_parent'};
1001         if (defined $hash_parent) {
1002                 if (!validate_refname($hash_parent)) {
1003                         die_error(400, "Invalid hash parent parameter");
1004                 }
1005         }
1006
1007         our $hash_base = $input_params{'hash_base'};
1008         if (defined $hash_base) {
1009                 if (!validate_refname($hash_base)) {
1010                         die_error(400, "Invalid hash base parameter");
1011                 }
1012         }
1013
1014         our @extra_options = @{$input_params{'extra_options'}};
1015         # @extra_options is always defined, since it can only be (currently) set from
1016         # CGI, and $cgi->param() returns the empty array in array context if the param
1017         # is not set
1018         foreach my $opt (@extra_options) {
1019                 if (not exists $allowed_options{$opt}) {
1020                         die_error(400, "Invalid option parameter");
1021                 }
1022                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1023                         die_error(400, "Invalid option parameter for this action");
1024                 }
1025         }
1026
1027         our $hash_parent_base = $input_params{'hash_parent_base'};
1028         if (defined $hash_parent_base) {
1029                 if (!validate_refname($hash_parent_base)) {
1030                         die_error(400, "Invalid hash parent base parameter");
1031                 }
1032         }
1033
1034         # other parameters
1035         our $page = $input_params{'page'};
1036         if (defined $page) {
1037                 if ($page =~ m/[^0-9]/) {
1038                         die_error(400, "Invalid page parameter");
1039                 }
1040         }
1041
1042         our $searchtype = $input_params{'searchtype'};
1043         if (defined $searchtype) {
1044                 if ($searchtype =~ m/[^a-z]/) {
1045                         die_error(400, "Invalid searchtype parameter");
1046                 }
1047         }
1048
1049         our $search_use_regexp = $input_params{'search_use_regexp'};
1050
1051         our $searchtext = $input_params{'searchtext'};
1052         our $search_regexp;
1053         if (defined $searchtext) {
1054                 if (length($searchtext) < 2) {
1055                         die_error(403, "At least two characters are required for search parameter");
1056                 }
1057                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1058         }
1059 }
1060
1061 # path to the current git repository
1062 our $git_dir;
1063 sub evaluate_git_dir {
1064         our $git_dir = "$projectroot/$project" if $project;
1065 }
1066
1067 our (@snapshot_fmts, $git_avatar);
1068 sub configure_gitweb_features {
1069         # list of supported snapshot formats
1070         our @snapshot_fmts = gitweb_get_feature('snapshot');
1071         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1072
1073         # check that the avatar feature is set to a known provider name,
1074         # and for each provider check if the dependencies are satisfied.
1075         # if the provider name is invalid or the dependencies are not met,
1076         # reset $git_avatar to the empty string.
1077         our ($git_avatar) = gitweb_get_feature('avatar');
1078         if ($git_avatar eq 'gravatar') {
1079                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1080         } elsif ($git_avatar eq 'picon') {
1081                 # no dependencies
1082         } else {
1083                 $git_avatar = '';
1084         }
1085 }
1086
1087 # custom error handler: 'die <message>' is Internal Server Error
1088 sub handle_errors_html {
1089         my $msg = shift; # it is already HTML escaped
1090
1091         # to avoid infinite loop where error occurs in die_error,
1092         # change handler to default handler, disabling handle_errors_html
1093         set_message("Error occured when inside die_error:\n$msg");
1094
1095         # you cannot jump out of die_error when called as error handler;
1096         # the subroutine set via CGI::Carp::set_message is called _after_
1097         # HTTP headers are already written, so it cannot write them itself
1098         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1099 }
1100 set_message(\&handle_errors_html);
1101
1102 # dispatch
1103 sub dispatch {
1104         if (!defined $action) {
1105                 if (defined $hash) {
1106                         $action = git_get_type($hash);
1107                 } elsif (defined $hash_base && defined $file_name) {
1108                         $action = git_get_type("$hash_base:$file_name");
1109                 } elsif (defined $project) {
1110                         $action = 'summary';
1111                 } else {
1112                         $action = 'project_list';
1113                 }
1114         }
1115         if (!defined($actions{$action})) {
1116                 die_error(400, "Unknown action");
1117         }
1118         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1119             !$project) {
1120                 die_error(400, "Project needed");
1121         }
1122         $actions{$action}->();
1123 }
1124
1125 sub reset_timer {
1126         our $t0 = [ gettimeofday() ]
1127                 if defined $t0;
1128         our $number_of_git_cmds = 0;
1129 }
1130
1131 our $first_request = 1;
1132 sub run_request {
1133         reset_timer();
1134
1135         evaluate_uri();
1136         if ($first_request) {
1137                 evaluate_gitweb_config();
1138                 evaluate_git_version();
1139         }
1140         if ($per_request_config) {
1141                 if (ref($per_request_config) eq 'CODE') {
1142                         $per_request_config->();
1143                 } elsif (!$first_request) {
1144                         evaluate_gitweb_config();
1145                 }
1146         }
1147         check_loadavg();
1148
1149         # $projectroot and $projects_list might be set in gitweb config file
1150         $projects_list ||= $projectroot;
1151
1152         evaluate_query_params();
1153         evaluate_path_info();
1154         evaluate_and_validate_params();
1155         evaluate_git_dir();
1156
1157         configure_gitweb_features();
1158
1159         dispatch();
1160 }
1161
1162 our $is_last_request = sub { 1 };
1163 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1164 our $CGI = 'CGI';
1165 our $cgi;
1166 sub configure_as_fcgi {
1167         require CGI::Fast;
1168         our $CGI = 'CGI::Fast';
1169
1170         my $request_number = 0;
1171         # let each child service 100 requests
1172         our $is_last_request = sub { ++$request_number > 100 };
1173 }
1174 sub evaluate_argv {
1175         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1176         configure_as_fcgi()
1177                 if $script_name =~ /\.fcgi$/;
1178
1179         return unless (@ARGV);
1180
1181         require Getopt::Long;
1182         Getopt::Long::GetOptions(
1183                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1184                 'nproc|n=i' => sub {
1185                         my ($arg, $val) = @_;
1186                         return unless eval { require FCGI::ProcManager; 1; };
1187                         my $proc_manager = FCGI::ProcManager->new({
1188                                 n_processes => $val,
1189                         });
1190                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1191                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1192                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1193                 },
1194         );
1195 }
1196
1197 sub run {
1198         evaluate_argv();
1199
1200         $first_request = 1;
1201         $pre_listen_hook->()
1202                 if $pre_listen_hook;
1203
1204  REQUEST:
1205         while ($cgi = $CGI->new()) {
1206                 $pre_dispatch_hook->()
1207                         if $pre_dispatch_hook;
1208
1209                 run_request();
1210
1211                 $post_dispatch_hook->()
1212                         if $post_dispatch_hook;
1213                 $first_request = 0;
1214
1215                 last REQUEST if ($is_last_request->());
1216         }
1217
1218  DONE_GITWEB:
1219         1;
1220 }
1221
1222 run();
1223
1224 if (defined caller) {
1225         # wrapped in a subroutine processing requests,
1226         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1227         return;
1228 } else {
1229         # pure CGI script, serving single request
1230         exit;
1231 }
1232
1233 ## ======================================================================
1234 ## action links
1235
1236 # possible values of extra options
1237 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1238 # -replay => 1      - start from a current view (replay with modifications)
1239 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1240 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1241 sub href {
1242         my %params = @_;
1243         # default is to use -absolute url() i.e. $my_uri
1244         my $href = $params{-full} ? $my_url : $my_uri;
1245
1246         # implicit -replay, must be first of implicit params
1247         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1248
1249         $params{'project'} = $project unless exists $params{'project'};
1250
1251         if ($params{-replay}) {
1252                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1253                         if (!exists $params{$name}) {
1254                                 $params{$name} = $input_params{$name};
1255                         }
1256                 }
1257         }
1258
1259         my $use_pathinfo = gitweb_check_feature('pathinfo');
1260         if (defined $params{'project'} &&
1261             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1262                 # try to put as many parameters as possible in PATH_INFO:
1263                 #   - project name
1264                 #   - action
1265                 #   - hash_parent or hash_parent_base:/file_parent
1266                 #   - hash or hash_base:/filename
1267                 #   - the snapshot_format as an appropriate suffix
1268
1269                 # When the script is the root DirectoryIndex for the domain,
1270                 # $href here would be something like http://gitweb.example.com/
1271                 # Thus, we strip any trailing / from $href, to spare us double
1272                 # slashes in the final URL
1273                 $href =~ s,/$,,;
1274
1275                 # Then add the project name, if present
1276                 $href .= "/".esc_path_info($params{'project'});
1277                 delete $params{'project'};
1278
1279                 # since we destructively absorb parameters, we keep this
1280                 # boolean that remembers if we're handling a snapshot
1281                 my $is_snapshot = $params{'action'} eq 'snapshot';
1282
1283                 # Summary just uses the project path URL, any other action is
1284                 # added to the URL
1285                 if (defined $params{'action'}) {
1286                         $href .= "/".esc_path_info($params{'action'})
1287                                 unless $params{'action'} eq 'summary';
1288                         delete $params{'action'};
1289                 }
1290
1291                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1292                 # stripping nonexistent or useless pieces
1293                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1294                         || $params{'hash_parent'} || $params{'hash'});
1295                 if (defined $params{'hash_base'}) {
1296                         if (defined $params{'hash_parent_base'}) {
1297                                 $href .= esc_path_info($params{'hash_parent_base'});
1298                                 # skip the file_parent if it's the same as the file_name
1299                                 if (defined $params{'file_parent'}) {
1300                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1301                                                 delete $params{'file_parent'};
1302                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1303                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1304                                                 delete $params{'file_parent'};
1305                                         }
1306                                 }
1307                                 $href .= "..";
1308                                 delete $params{'hash_parent'};
1309                                 delete $params{'hash_parent_base'};
1310                         } elsif (defined $params{'hash_parent'}) {
1311                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1312                                 delete $params{'hash_parent'};
1313                         }
1314
1315                         $href .= esc_path_info($params{'hash_base'});
1316                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1317                                 $href .= ":/".esc_path_info($params{'file_name'});
1318                                 delete $params{'file_name'};
1319                         }
1320                         delete $params{'hash'};
1321                         delete $params{'hash_base'};
1322                 } elsif (defined $params{'hash'}) {
1323                         $href .= esc_path_info($params{'hash'});
1324                         delete $params{'hash'};
1325                 }
1326
1327                 # If the action was a snapshot, we can absorb the
1328                 # snapshot_format parameter too
1329                 if ($is_snapshot) {
1330                         my $fmt = $params{'snapshot_format'};
1331                         # snapshot_format should always be defined when href()
1332                         # is called, but just in case some code forgets, we
1333                         # fall back to the default
1334                         $fmt ||= $snapshot_fmts[0];
1335                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1336                         delete $params{'snapshot_format'};
1337                 }
1338         }
1339
1340         # now encode the parameters explicitly
1341         my @result = ();
1342         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1343                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1344                 if (defined $params{$name}) {
1345                         if (ref($params{$name}) eq "ARRAY") {
1346                                 foreach my $par (@{$params{$name}}) {
1347                                         push @result, $symbol . "=" . esc_param($par);
1348                                 }
1349                         } else {
1350                                 push @result, $symbol . "=" . esc_param($params{$name});
1351                         }
1352                 }
1353         }
1354         $href .= "?" . join(';', @result) if scalar @result;
1355
1356         # final transformation: trailing spaces must be escaped (URI-encoded)
1357         $href =~ s/(\s+)$/CGI::escape($1)/e;
1358
1359         if ($params{-anchor}) {
1360                 $href .= "#".esc_param($params{-anchor});
1361         }
1362
1363         return $href;
1364 }
1365
1366
1367 ## ======================================================================
1368 ## validation, quoting/unquoting and escaping
1369
1370 sub validate_action {
1371         my $input = shift || return undef;
1372         return undef unless exists $actions{$input};
1373         return $input;
1374 }
1375
1376 sub validate_project {
1377         my $input = shift || return undef;
1378         if (!validate_pathname($input) ||
1379                 !(-d "$projectroot/$input") ||
1380                 !check_export_ok("$projectroot/$input") ||
1381                 ($strict_export && !project_in_list($input))) {
1382                 return undef;
1383         } else {
1384                 return $input;
1385         }
1386 }
1387
1388 sub validate_pathname {
1389         my $input = shift || return undef;
1390
1391         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1392         # at the beginning, at the end, and between slashes.
1393         # also this catches doubled slashes
1394         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1395                 return undef;
1396         }
1397         # no null characters
1398         if ($input =~ m!\0!) {
1399                 return undef;
1400         }
1401         return $input;
1402 }
1403
1404 sub validate_refname {
1405         my $input = shift || return undef;
1406
1407         # textual hashes are O.K.
1408         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1409                 return $input;
1410         }
1411         # it must be correct pathname
1412         $input = validate_pathname($input)
1413                 or return undef;
1414         # restrictions on ref name according to git-check-ref-format
1415         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1416                 return undef;
1417         }
1418         return $input;
1419 }
1420
1421 # decode sequences of octets in utf8 into Perl's internal form,
1422 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1423 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1424 sub to_utf8 {
1425         my $str = shift;
1426         return undef unless defined $str;
1427         if (utf8::valid($str)) {
1428                 utf8::decode($str);
1429                 return $str;
1430         } else {
1431                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1432         }
1433 }
1434
1435 # quote unsafe chars, but keep the slash, even when it's not
1436 # correct, but quoted slashes look too horrible in bookmarks
1437 sub esc_param {
1438         my $str = shift;
1439         return undef unless defined $str;
1440         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1441         $str =~ s/ /\+/g;
1442         return $str;
1443 }
1444
1445 # the quoting rules for path_info fragment are slightly different
1446 sub esc_path_info {
1447         my $str = shift;
1448         return undef unless defined $str;
1449
1450         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1451         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1452
1453         return $str;
1454 }
1455
1456 # quote unsafe chars in whole URL, so some characters cannot be quoted
1457 sub esc_url {
1458         my $str = shift;
1459         return undef unless defined $str;
1460         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1461         $str =~ s/ /\+/g;
1462         return $str;
1463 }
1464
1465 # quote unsafe characters in HTML attributes
1466 sub esc_attr {
1467
1468         # for XHTML conformance escaping '"' to '&quot;' is not enough
1469         return esc_html(@_);
1470 }
1471
1472 # replace invalid utf8 character with SUBSTITUTION sequence
1473 sub esc_html {
1474         my $str = shift;
1475         my %opts = @_;
1476
1477         return undef unless defined $str;
1478
1479         $str = to_utf8($str);
1480         $str = $cgi->escapeHTML($str);
1481         if ($opts{'-nbsp'}) {
1482                 $str =~ s/ /&nbsp;/g;
1483         }
1484         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1485         return $str;
1486 }
1487
1488 # quote control characters and escape filename to HTML
1489 sub esc_path {
1490         my $str = shift;
1491         my %opts = @_;
1492
1493         return undef unless defined $str;
1494
1495         $str = to_utf8($str);
1496         $str = $cgi->escapeHTML($str);
1497         if ($opts{'-nbsp'}) {
1498                 $str =~ s/ /&nbsp;/g;
1499         }
1500         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1501         return $str;
1502 }
1503
1504 # Make control characters "printable", using character escape codes (CEC)
1505 sub quot_cec {
1506         my $cntrl = shift;
1507         my %opts = @_;
1508         my %es = ( # character escape codes, aka escape sequences
1509                 "\t" => '\t',   # tab            (HT)
1510                 "\n" => '\n',   # line feed      (LF)
1511                 "\r" => '\r',   # carrige return (CR)
1512                 "\f" => '\f',   # form feed      (FF)
1513                 "\b" => '\b',   # backspace      (BS)
1514                 "\a" => '\a',   # alarm (bell)   (BEL)
1515                 "\e" => '\e',   # escape         (ESC)
1516                 "\013" => '\v', # vertical tab   (VT)
1517                 "\000" => '\0', # nul character  (NUL)
1518         );
1519         my $chr = ( (exists $es{$cntrl})
1520                     ? $es{$cntrl}
1521                     : sprintf('\%2x', ord($cntrl)) );
1522         if ($opts{-nohtml}) {
1523                 return $chr;
1524         } else {
1525                 return "<span class=\"cntrl\">$chr</span>";
1526         }
1527 }
1528
1529 # Alternatively use unicode control pictures codepoints,
1530 # Unicode "printable representation" (PR)
1531 sub quot_upr {
1532         my $cntrl = shift;
1533         my %opts = @_;
1534
1535         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1536         if ($opts{-nohtml}) {
1537                 return $chr;
1538         } else {
1539                 return "<span class=\"cntrl\">$chr</span>";
1540         }
1541 }
1542
1543 # git may return quoted and escaped filenames
1544 sub unquote {
1545         my $str = shift;
1546
1547         sub unq {
1548                 my $seq = shift;
1549                 my %es = ( # character escape codes, aka escape sequences
1550                         't' => "\t",   # tab            (HT, TAB)
1551                         'n' => "\n",   # newline        (NL)
1552                         'r' => "\r",   # return         (CR)
1553                         'f' => "\f",   # form feed      (FF)
1554                         'b' => "\b",   # backspace      (BS)
1555                         'a' => "\a",   # alarm (bell)   (BEL)
1556                         'e' => "\e",   # escape         (ESC)
1557                         'v' => "\013", # vertical tab   (VT)
1558                 );
1559
1560                 if ($seq =~ m/^[0-7]{1,3}$/) {
1561                         # octal char sequence
1562                         return chr(oct($seq));
1563                 } elsif (exists $es{$seq}) {
1564                         # C escape sequence, aka character escape code
1565                         return $es{$seq};
1566                 }
1567                 # quoted ordinary character
1568                 return $seq;
1569         }
1570
1571         if ($str =~ m/^"(.*)"$/) {
1572                 # needs unquoting
1573                 $str = $1;
1574                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1575         }
1576         return $str;
1577 }
1578
1579 # escape tabs (convert tabs to spaces)
1580 sub untabify {
1581         my $line = shift;
1582
1583         while ((my $pos = index($line, "\t")) != -1) {
1584                 if (my $count = (8 - ($pos % 8))) {
1585                         my $spaces = ' ' x $count;
1586                         $line =~ s/\t/$spaces/;
1587                 }
1588         }
1589
1590         return $line;
1591 }
1592
1593 sub project_in_list {
1594         my $project = shift;
1595         my @list = git_get_projects_list();
1596         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1597 }
1598
1599 ## ----------------------------------------------------------------------
1600 ## HTML aware string manipulation
1601
1602 # Try to chop given string on a word boundary between position
1603 # $len and $len+$add_len. If there is no word boundary there,
1604 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1605 # (marking chopped part) would be longer than given string.
1606 sub chop_str {
1607         my $str = shift;
1608         my $len = shift;
1609         my $add_len = shift || 10;
1610         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1611
1612         # Make sure perl knows it is utf8 encoded so we don't
1613         # cut in the middle of a utf8 multibyte char.
1614         $str = to_utf8($str);
1615
1616         # allow only $len chars, but don't cut a word if it would fit in $add_len
1617         # if it doesn't fit, cut it if it's still longer than the dots we would add
1618         # remove chopped character entities entirely
1619
1620         # when chopping in the middle, distribute $len into left and right part
1621         # return early if chopping wouldn't make string shorter
1622         if ($where eq 'center') {
1623                 return $str if ($len + 5 >= length($str)); # filler is length 5
1624                 $len = int($len/2);
1625         } else {
1626                 return $str if ($len + 4 >= length($str)); # filler is length 4
1627         }
1628
1629         # regexps: ending and beginning with word part up to $add_len
1630         my $endre = qr/.{$len}\w{0,$add_len}/;
1631         my $begre = qr/\w{0,$add_len}.{$len}/;
1632
1633         if ($where eq 'left') {
1634                 $str =~ m/^(.*?)($begre)$/;
1635                 my ($lead, $body) = ($1, $2);
1636                 if (length($lead) > 4) {
1637                         $lead = " ...";
1638                 }
1639                 return "$lead$body";
1640
1641         } elsif ($where eq 'center') {
1642                 $str =~ m/^($endre)(.*)$/;
1643                 my ($left, $str)  = ($1, $2);
1644                 $str =~ m/^(.*?)($begre)$/;
1645                 my ($mid, $right) = ($1, $2);
1646                 if (length($mid) > 5) {
1647                         $mid = " ... ";
1648                 }
1649                 return "$left$mid$right";
1650
1651         } else {
1652                 $str =~ m/^($endre)(.*)$/;
1653                 my $body = $1;
1654                 my $tail = $2;
1655                 if (length($tail) > 4) {
1656                         $tail = "... ";
1657                 }
1658                 return "$body$tail";
1659         }
1660 }
1661
1662 # takes the same arguments as chop_str, but also wraps a <span> around the
1663 # result with a title attribute if it does get chopped. Additionally, the
1664 # string is HTML-escaped.
1665 sub chop_and_escape_str {
1666         my ($str) = @_;
1667
1668         my $chopped = chop_str(@_);
1669         if ($chopped eq $str) {
1670                 return esc_html($chopped);
1671         } else {
1672                 $str =~ s/[[:cntrl:]]/?/g;
1673                 return $cgi->span({-title=>$str}, esc_html($chopped));
1674         }
1675 }
1676
1677 ## ----------------------------------------------------------------------
1678 ## functions returning short strings
1679
1680 # CSS class for given age value (in seconds)
1681 sub age_class {
1682         my $age = shift;
1683
1684         if (!defined $age) {
1685                 return "noage";
1686         } elsif ($age < 60*60*2) {
1687                 return "age0";
1688         } elsif ($age < 60*60*24*2) {
1689                 return "age1";
1690         } else {
1691                 return "age2";
1692         }
1693 }
1694
1695 # convert age in seconds to "nn units ago" string
1696 sub age_string {
1697         my $age = shift;
1698         my $age_str;
1699
1700         if ($age > 60*60*24*365*2) {
1701                 $age_str = (int $age/60/60/24/365);
1702                 $age_str .= " years ago";
1703         } elsif ($age > 60*60*24*(365/12)*2) {
1704                 $age_str = int $age/60/60/24/(365/12);
1705                 $age_str .= " months ago";
1706         } elsif ($age > 60*60*24*7*2) {
1707                 $age_str = int $age/60/60/24/7;
1708                 $age_str .= " weeks ago";
1709         } elsif ($age > 60*60*24*2) {
1710                 $age_str = int $age/60/60/24;
1711                 $age_str .= " days ago";
1712         } elsif ($age > 60*60*2) {
1713                 $age_str = int $age/60/60;
1714                 $age_str .= " hours ago";
1715         } elsif ($age > 60*2) {
1716                 $age_str = int $age/60;
1717                 $age_str .= " min ago";
1718         } elsif ($age > 2) {
1719                 $age_str = int $age;
1720                 $age_str .= " sec ago";
1721         } else {
1722                 $age_str .= " right now";
1723         }
1724         return $age_str;
1725 }
1726
1727 use constant {
1728         S_IFINVALID => 0030000,
1729         S_IFGITLINK => 0160000,
1730 };
1731
1732 # submodule/subproject, a commit object reference
1733 sub S_ISGITLINK {
1734         my $mode = shift;
1735
1736         return (($mode & S_IFMT) == S_IFGITLINK)
1737 }
1738
1739 # convert file mode in octal to symbolic file mode string
1740 sub mode_str {
1741         my $mode = oct shift;
1742
1743         if (S_ISGITLINK($mode)) {
1744                 return 'm---------';
1745         } elsif (S_ISDIR($mode & S_IFMT)) {
1746                 return 'drwxr-xr-x';
1747         } elsif (S_ISLNK($mode)) {
1748                 return 'lrwxrwxrwx';
1749         } elsif (S_ISREG($mode)) {
1750                 # git cares only about the executable bit
1751                 if ($mode & S_IXUSR) {
1752                         return '-rwxr-xr-x';
1753                 } else {
1754                         return '-rw-r--r--';
1755                 };
1756         } else {
1757                 return '----------';
1758         }
1759 }
1760
1761 # convert file mode in octal to file type string
1762 sub file_type {
1763         my $mode = shift;
1764
1765         if ($mode !~ m/^[0-7]+$/) {
1766                 return $mode;
1767         } else {
1768                 $mode = oct $mode;
1769         }
1770
1771         if (S_ISGITLINK($mode)) {
1772                 return "submodule";
1773         } elsif (S_ISDIR($mode & S_IFMT)) {
1774                 return "directory";
1775         } elsif (S_ISLNK($mode)) {
1776                 return "symlink";
1777         } elsif (S_ISREG($mode)) {
1778                 return "file";
1779         } else {
1780                 return "unknown";
1781         }
1782 }
1783
1784 # convert file mode in octal to file type description string
1785 sub file_type_long {
1786         my $mode = shift;
1787
1788         if ($mode !~ m/^[0-7]+$/) {
1789                 return $mode;
1790         } else {
1791                 $mode = oct $mode;
1792         }
1793
1794         if (S_ISGITLINK($mode)) {
1795                 return "submodule";
1796         } elsif (S_ISDIR($mode & S_IFMT)) {
1797                 return "directory";
1798         } elsif (S_ISLNK($mode)) {
1799                 return "symlink";
1800         } elsif (S_ISREG($mode)) {
1801                 if ($mode & S_IXUSR) {
1802                         return "executable";
1803                 } else {
1804                         return "file";
1805                 };
1806         } else {
1807                 return "unknown";
1808         }
1809 }
1810
1811
1812 ## ----------------------------------------------------------------------
1813 ## functions returning short HTML fragments, or transforming HTML fragments
1814 ## which don't belong to other sections
1815
1816 # format line of commit message.
1817 sub format_log_line_html {
1818         my $line = shift;
1819
1820         $line = esc_html($line, -nbsp=>1);
1821         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1822                 $cgi->a({-href => href(action=>"object", hash=>$1),
1823                                         -class => "text"}, $1);
1824         }eg;
1825
1826         return $line;
1827 }
1828
1829 # format marker of refs pointing to given object
1830
1831 # the destination action is chosen based on object type and current context:
1832 # - for annotated tags, we choose the tag view unless it's the current view
1833 #   already, in which case we go to shortlog view
1834 # - for other refs, we keep the current view if we're in history, shortlog or
1835 #   log view, and select shortlog otherwise
1836 sub format_ref_marker {
1837         my ($refs, $id) = @_;
1838         my $markers = '';
1839
1840         if (defined $refs->{$id}) {
1841                 foreach my $ref (@{$refs->{$id}}) {
1842                         # this code exploits the fact that non-lightweight tags are the
1843                         # only indirect objects, and that they are the only objects for which
1844                         # we want to use tag instead of shortlog as action
1845                         my ($type, $name) = qw();
1846                         my $indirect = ($ref =~ s/\^\{\}$//);
1847                         # e.g. tags/v2.6.11 or heads/next
1848                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1849                                 $type = $1;
1850                                 $name = $2;
1851                         } else {
1852                                 $type = "ref";
1853                                 $name = $ref;
1854                         }
1855
1856                         my $class = $type;
1857                         $class .= " indirect" if $indirect;
1858
1859                         my $dest_action = "shortlog";
1860
1861                         if ($indirect) {
1862                                 $dest_action = "tag" unless $action eq "tag";
1863                         } elsif ($action =~ /^(history|(short)?log)$/) {
1864                                 $dest_action = $action;
1865                         }
1866
1867                         my $dest = "";
1868                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1869                         $dest .= $ref;
1870
1871                         my $link = $cgi->a({
1872                                 -href => href(
1873                                         action=>$dest_action,
1874                                         hash=>$dest
1875                                 )}, $name);
1876
1877                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1878                                 $link . "</span>";
1879                 }
1880         }
1881
1882         if ($markers) {
1883                 return ' <span class="refs">'. $markers . '</span>';
1884         } else {
1885                 return "";
1886         }
1887 }
1888
1889 # format, perhaps shortened and with markers, title line
1890 sub format_subject_html {
1891         my ($long, $short, $href, $extra) = @_;
1892         $extra = '' unless defined($extra);
1893
1894         if (length($short) < length($long)) {
1895                 $long =~ s/[[:cntrl:]]/?/g;
1896                 return $cgi->a({-href => $href, -class => "list subject",
1897                                 -title => to_utf8($long)},
1898                        esc_html($short)) . $extra;
1899         } else {
1900                 return $cgi->a({-href => $href, -class => "list subject"},
1901                        esc_html($long)) . $extra;
1902         }
1903 }
1904
1905 # Rather than recomputing the url for an email multiple times, we cache it
1906 # after the first hit. This gives a visible benefit in views where the avatar
1907 # for the same email is used repeatedly (e.g. shortlog).
1908 # The cache is shared by all avatar engines (currently gravatar only), which
1909 # are free to use it as preferred. Since only one avatar engine is used for any
1910 # given page, there's no risk for cache conflicts.
1911 our %avatar_cache = ();
1912
1913 # Compute the picon url for a given email, by using the picon search service over at
1914 # http://www.cs.indiana.edu/picons/search.html
1915 sub picon_url {
1916         my $email = lc shift;
1917         if (!$avatar_cache{$email}) {
1918                 my ($user, $domain) = split('@', $email);
1919                 $avatar_cache{$email} =
1920                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1921                         "$domain/$user/" .
1922                         "users+domains+unknown/up/single";
1923         }
1924         return $avatar_cache{$email};
1925 }
1926
1927 # Compute the gravatar url for a given email, if it's not in the cache already.
1928 # Gravatar stores only the part of the URL before the size, since that's the
1929 # one computationally more expensive. This also allows reuse of the cache for
1930 # different sizes (for this particular engine).
1931 sub gravatar_url {
1932         my $email = lc shift;
1933         my $size = shift;
1934         $avatar_cache{$email} ||=
1935                 "http://www.gravatar.com/avatar/" .
1936                         Digest::MD5::md5_hex($email) . "?s=";
1937         return $avatar_cache{$email} . $size;
1938 }
1939
1940 # Insert an avatar for the given $email at the given $size if the feature
1941 # is enabled.
1942 sub git_get_avatar {
1943         my ($email, %opts) = @_;
1944         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1945         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1946         $opts{-size} ||= 'default';
1947         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1948         my $url = "";
1949         if ($git_avatar eq 'gravatar') {
1950                 $url = gravatar_url($email, $size);
1951         } elsif ($git_avatar eq 'picon') {
1952                 $url = picon_url($email);
1953         }
1954         # Other providers can be added by extending the if chain, defining $url
1955         # as needed. If no variant puts something in $url, we assume avatars
1956         # are completely disabled/unavailable.
1957         if ($url) {
1958                 return $pre_white .
1959                        "<img width=\"$size\" " .
1960                             "class=\"avatar\" " .
1961                             "src=\"".esc_url($url)."\" " .
1962                             "alt=\"\" " .
1963                        "/>" . $post_white;
1964         } else {
1965                 return "";
1966         }
1967 }
1968
1969 sub format_search_author {
1970         my ($author, $searchtype, $displaytext) = @_;
1971         my $have_search = gitweb_check_feature('search');
1972
1973         if ($have_search) {
1974                 my $performed = "";
1975                 if ($searchtype eq 'author') {
1976                         $performed = "authored";
1977                 } elsif ($searchtype eq 'committer') {
1978                         $performed = "committed";
1979                 }
1980
1981                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1982                                 searchtext=>$author,
1983                                 searchtype=>$searchtype), class=>"list",
1984                                 title=>"Search for commits $performed by $author"},
1985                                 $displaytext);
1986
1987         } else {
1988                 return $displaytext;
1989         }
1990 }
1991
1992 # format the author name of the given commit with the given tag
1993 # the author name is chopped and escaped according to the other
1994 # optional parameters (see chop_str).
1995 sub format_author_html {
1996         my $tag = shift;
1997         my $co = shift;
1998         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1999         return "<$tag class=\"author\">" .
2000                format_search_author($co->{'author_name'}, "author",
2001                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2002                        $author) .
2003                "</$tag>";
2004 }
2005
2006 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2007 sub format_git_diff_header_line {
2008         my $line = shift;
2009         my $diffinfo = shift;
2010         my ($from, $to) = @_;
2011
2012         if ($diffinfo->{'nparents'}) {
2013                 # combined diff
2014                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2015                 if ($to->{'href'}) {
2016                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2017                                          esc_path($to->{'file'}));
2018                 } else { # file was deleted (no href)
2019                         $line .= esc_path($to->{'file'});
2020                 }
2021         } else {
2022                 # "ordinary" diff
2023                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2024                 if ($from->{'href'}) {
2025                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2026                                          'a/' . esc_path($from->{'file'}));
2027                 } else { # file was added (no href)
2028                         $line .= 'a/' . esc_path($from->{'file'});
2029                 }
2030                 $line .= ' ';
2031                 if ($to->{'href'}) {
2032                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2033                                          'b/' . esc_path($to->{'file'}));
2034                 } else { # file was deleted
2035                         $line .= 'b/' . esc_path($to->{'file'});
2036                 }
2037         }
2038
2039         return "<div class=\"diff header\">$line</div>\n";
2040 }
2041
2042 # format extended diff header line, before patch itself
2043 sub format_extended_diff_header_line {
2044         my $line = shift;
2045         my $diffinfo = shift;
2046         my ($from, $to) = @_;
2047
2048         # match <path>
2049         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2050                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2051                                        esc_path($from->{'file'}));
2052         }
2053         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2054                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2055                                  esc_path($to->{'file'}));
2056         }
2057         # match single <mode>
2058         if ($line =~ m/\s(\d{6})$/) {
2059                 $line .= '<span class="info"> (' .
2060                          file_type_long($1) .
2061                          ')</span>';
2062         }
2063         # match <hash>
2064         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2065                 # can match only for combined diff
2066                 $line = 'index ';
2067                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2068                         if ($from->{'href'}[$i]) {
2069                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2070                                                   -class=>"hash"},
2071                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2072                         } else {
2073                                 $line .= '0' x 7;
2074                         }
2075                         # separator
2076                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2077                 }
2078                 $line .= '..';
2079                 if ($to->{'href'}) {
2080                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2081                                          substr($diffinfo->{'to_id'},0,7));
2082                 } else {
2083                         $line .= '0' x 7;
2084                 }
2085
2086         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2087                 # can match only for ordinary diff
2088                 my ($from_link, $to_link);
2089                 if ($from->{'href'}) {
2090                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2091                                              substr($diffinfo->{'from_id'},0,7));
2092                 } else {
2093                         $from_link = '0' x 7;
2094                 }
2095                 if ($to->{'href'}) {
2096                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2097                                            substr($diffinfo->{'to_id'},0,7));
2098                 } else {
2099                         $to_link = '0' x 7;
2100                 }
2101                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2102                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2103         }
2104
2105         return $line . "<br/>\n";
2106 }
2107
2108 # format from-file/to-file diff header
2109 sub format_diff_from_to_header {
2110         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2111         my $line;
2112         my $result = '';
2113
2114         $line = $from_line;
2115         #assert($line =~ m/^---/) if DEBUG;
2116         # no extra formatting for "^--- /dev/null"
2117         if (! $diffinfo->{'nparents'}) {
2118                 # ordinary (single parent) diff
2119                 if ($line =~ m!^--- "?a/!) {
2120                         if ($from->{'href'}) {
2121                                 $line = '--- a/' .
2122                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2123                                                 esc_path($from->{'file'}));
2124                         } else {
2125                                 $line = '--- a/' .
2126                                         esc_path($from->{'file'});
2127                         }
2128                 }
2129                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2130
2131         } else {
2132                 # combined diff (merge commit)
2133                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2134                         if ($from->{'href'}[$i]) {
2135                                 $line = '--- ' .
2136                                         $cgi->a({-href=>href(action=>"blobdiff",
2137                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2138                                                              hash_parent_base=>$parents[$i],
2139                                                              file_parent=>$from->{'file'}[$i],
2140                                                              hash=>$diffinfo->{'to_id'},
2141                                                              hash_base=>$hash,
2142                                                              file_name=>$to->{'file'}),
2143                                                  -class=>"path",
2144                                                  -title=>"diff" . ($i+1)},
2145                                                 $i+1) .
2146                                         '/' .
2147                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2148                                                 esc_path($from->{'file'}[$i]));
2149                         } else {
2150                                 $line = '--- /dev/null';
2151                         }
2152                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2153                 }
2154         }
2155
2156         $line = $to_line;
2157         #assert($line =~ m/^\+\+\+/) if DEBUG;
2158         # no extra formatting for "^+++ /dev/null"
2159         if ($line =~ m!^\+\+\+ "?b/!) {
2160                 if ($to->{'href'}) {
2161                         $line = '+++ b/' .
2162                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2163                                         esc_path($to->{'file'}));
2164                 } else {
2165                         $line = '+++ b/' .
2166                                 esc_path($to->{'file'});
2167                 }
2168         }
2169         $result .= qq!<div class="diff to_file">$line</div>\n!;
2170
2171         return $result;
2172 }
2173
2174 # create note for patch simplified by combined diff
2175 sub format_diff_cc_simplified {
2176         my ($diffinfo, @parents) = @_;
2177         my $result = '';
2178
2179         $result .= "<div class=\"diff header\">" .
2180                    "diff --cc ";
2181         if (!is_deleted($diffinfo)) {
2182                 $result .= $cgi->a({-href => href(action=>"blob",
2183                                                   hash_base=>$hash,
2184                                                   hash=>$diffinfo->{'to_id'},
2185                                                   file_name=>$diffinfo->{'to_file'}),
2186                                     -class => "path"},
2187                                    esc_path($diffinfo->{'to_file'}));
2188         } else {
2189                 $result .= esc_path($diffinfo->{'to_file'});
2190         }
2191         $result .= "</div>\n" . # class="diff header"
2192                    "<div class=\"diff nodifferences\">" .
2193                    "Simple merge" .
2194                    "</div>\n"; # class="diff nodifferences"
2195
2196         return $result;
2197 }
2198
2199 # format patch (diff) line (not to be used for diff headers)
2200 sub format_diff_line {
2201         my $line = shift;
2202         my ($from, $to) = @_;
2203         my $diff_class = "";
2204
2205         chomp $line;
2206
2207         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2208                 # combined diff
2209                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2210                 if ($line =~ m/^\@{3}/) {
2211                         $diff_class = " chunk_header";
2212                 } elsif ($line =~ m/^\\/) {
2213                         $diff_class = " incomplete";
2214                 } elsif ($prefix =~ tr/+/+/) {
2215                         $diff_class = " add";
2216                 } elsif ($prefix =~ tr/-/-/) {
2217                         $diff_class = " rem";
2218                 }
2219         } else {
2220                 # assume ordinary diff
2221                 my $char = substr($line, 0, 1);
2222                 if ($char eq '+') {
2223                         $diff_class = " add";
2224                 } elsif ($char eq '-') {
2225                         $diff_class = " rem";
2226                 } elsif ($char eq '@') {
2227                         $diff_class = " chunk_header";
2228                 } elsif ($char eq "\\") {
2229                         $diff_class = " incomplete";
2230                 }
2231         }
2232         $line = untabify($line);
2233         if ($from && $to && $line =~ m/^\@{2} /) {
2234                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2235                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2236
2237                 $from_lines = 0 unless defined $from_lines;
2238                 $to_lines   = 0 unless defined $to_lines;
2239
2240                 if ($from->{'href'}) {
2241                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2242                                              -class=>"list"}, $from_text);
2243                 }
2244                 if ($to->{'href'}) {
2245                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2246                                              -class=>"list"}, $to_text);
2247                 }
2248                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2249                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2250                 return "<div class=\"diff$diff_class\">$line</div>\n";
2251         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2252                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2253                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2254
2255                 @from_text = split(' ', $ranges);
2256                 for (my $i = 0; $i < @from_text; ++$i) {
2257                         ($from_start[$i], $from_nlines[$i]) =
2258                                 (split(',', substr($from_text[$i], 1)), 0);
2259                 }
2260
2261                 $to_text   = pop @from_text;
2262                 $to_start  = pop @from_start;
2263                 $to_nlines = pop @from_nlines;
2264
2265                 $line = "<span class=\"chunk_info\">$prefix ";
2266                 for (my $i = 0; $i < @from_text; ++$i) {
2267                         if ($from->{'href'}[$i]) {
2268                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2269                                                   -class=>"list"}, $from_text[$i]);
2270                         } else {
2271                                 $line .= $from_text[$i];
2272                         }
2273                         $line .= " ";
2274                 }
2275                 if ($to->{'href'}) {
2276                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2277                                           -class=>"list"}, $to_text);
2278                 } else {
2279                         $line .= $to_text;
2280                 }
2281                 $line .= " $prefix</span>" .
2282                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2283                 return "<div class=\"diff$diff_class\">$line</div>\n";
2284         }
2285         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2286 }
2287
2288 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2289 # linked.  Pass the hash of the tree/commit to snapshot.
2290 sub format_snapshot_links {
2291         my ($hash) = @_;
2292         my $num_fmts = @snapshot_fmts;
2293         if ($num_fmts > 1) {
2294                 # A parenthesized list of links bearing format names.
2295                 # e.g. "snapshot (_tar.gz_ _zip_)"
2296                 return "snapshot (" . join(' ', map
2297                         $cgi->a({
2298                                 -href => href(
2299                                         action=>"snapshot",
2300                                         hash=>$hash,
2301                                         snapshot_format=>$_
2302                                 )
2303                         }, $known_snapshot_formats{$_}{'display'})
2304                 , @snapshot_fmts) . ")";
2305         } elsif ($num_fmts == 1) {
2306                 # A single "snapshot" link whose tooltip bears the format name.
2307                 # i.e. "_snapshot_"
2308                 my ($fmt) = @snapshot_fmts;
2309                 return
2310                         $cgi->a({
2311                                 -href => href(
2312                                         action=>"snapshot",
2313                                         hash=>$hash,
2314                                         snapshot_format=>$fmt
2315                                 ),
2316                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2317                         }, "snapshot");
2318         } else { # $num_fmts == 0
2319                 return undef;
2320         }
2321 }
2322
2323 ## ......................................................................
2324 ## functions returning values to be passed, perhaps after some
2325 ## transformation, to other functions; e.g. returning arguments to href()
2326
2327 # returns hash to be passed to href to generate gitweb URL
2328 # in -title key it returns description of link
2329 sub get_feed_info {
2330         my $format = shift || 'Atom';
2331         my %res = (action => lc($format));
2332
2333         # feed links are possible only for project views
2334         return unless (defined $project);
2335         # some views should link to OPML, or to generic project feed,
2336         # or don't have specific feed yet (so they should use generic)
2337         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2338
2339         my $branch;
2340         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2341         # from tag links; this also makes possible to detect branch links
2342         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2343             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2344                 $branch = $1;
2345         }
2346         # find log type for feed description (title)
2347         my $type = 'log';
2348         if (defined $file_name) {
2349                 $type  = "history of $file_name";
2350                 $type .= "/" if ($action eq 'tree');
2351                 $type .= " on '$branch'" if (defined $branch);
2352         } else {
2353                 $type = "log of $branch" if (defined $branch);
2354         }
2355
2356         $res{-title} = $type;
2357         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2358         $res{'file_name'} = $file_name;
2359
2360         return %res;
2361 }
2362
2363 ## ----------------------------------------------------------------------
2364 ## git utility subroutines, invoking git commands
2365
2366 # returns path to the core git executable and the --git-dir parameter as list
2367 sub git_cmd {
2368         $number_of_git_cmds++;
2369         return $GIT, '--git-dir='.$git_dir;
2370 }
2371
2372 # quote the given arguments for passing them to the shell
2373 # quote_command("command", "arg 1", "arg with ' and ! characters")
2374 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2375 # Try to avoid using this function wherever possible.
2376 sub quote_command {
2377         return join(' ',
2378                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2379 }
2380
2381 # get HEAD ref of given project as hash
2382 sub git_get_head_hash {
2383         return git_get_full_hash(shift, 'HEAD');
2384 }
2385
2386 sub git_get_full_hash {
2387         return git_get_hash(@_);
2388 }
2389
2390 sub git_get_short_hash {
2391         return git_get_hash(@_, '--short=7');
2392 }
2393
2394 sub git_get_hash {
2395         my ($project, $hash, @options) = @_;
2396         my $o_git_dir = $git_dir;
2397         my $retval = undef;
2398         $git_dir = "$projectroot/$project";
2399         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2400             '--verify', '-q', @options, $hash) {
2401                 $retval = <$fd>;
2402                 chomp $retval if defined $retval;
2403                 close $fd;
2404         }
2405         if (defined $o_git_dir) {
2406                 $git_dir = $o_git_dir;
2407         }
2408         return $retval;
2409 }
2410
2411 # get type of given object
2412 sub git_get_type {
2413         my $hash = shift;
2414
2415         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2416         my $type = <$fd>;
2417         close $fd or return;
2418         chomp $type;
2419         return $type;
2420 }
2421
2422 # repository configuration
2423 our $config_file = '';
2424 our %config;
2425
2426 # store multiple values for single key as anonymous array reference
2427 # single values stored directly in the hash, not as [ <value> ]
2428 sub hash_set_multi {
2429         my ($hash, $key, $value) = @_;
2430
2431         if (!exists $hash->{$key}) {
2432                 $hash->{$key} = $value;
2433         } elsif (!ref $hash->{$key}) {
2434                 $hash->{$key} = [ $hash->{$key}, $value ];
2435         } else {
2436                 push @{$hash->{$key}}, $value;
2437         }
2438 }
2439
2440 # return hash of git project configuration
2441 # optionally limited to some section, e.g. 'gitweb'
2442 sub git_parse_project_config {
2443         my $section_regexp = shift;
2444         my %config;
2445
2446         local $/ = "\0";
2447
2448         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2449                 or return;
2450
2451         while (my $keyval = <$fh>) {
2452                 chomp $keyval;
2453                 my ($key, $value) = split(/\n/, $keyval, 2);
2454
2455                 hash_set_multi(\%config, $key, $value)
2456                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2457         }
2458         close $fh;
2459
2460         return %config;
2461 }
2462
2463 # convert config value to boolean: 'true' or 'false'
2464 # no value, number > 0, 'true' and 'yes' values are true
2465 # rest of values are treated as false (never as error)
2466 sub config_to_bool {
2467         my $val = shift;
2468
2469         return 1 if !defined $val;             # section.key
2470
2471         # strip leading and trailing whitespace
2472         $val =~ s/^\s+//;
2473         $val =~ s/\s+$//;
2474
2475         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2476                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2477 }
2478
2479 # convert config value to simple decimal number
2480 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2481 # to be multiplied by 1024, 1048576, or 1073741824
2482 sub config_to_int {
2483         my $val = shift;
2484
2485         # strip leading and trailing whitespace
2486         $val =~ s/^\s+//;
2487         $val =~ s/\s+$//;
2488
2489         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2490                 $unit = lc($unit);
2491                 # unknown unit is treated as 1
2492                 return $num * ($unit eq 'g' ? 1073741824 :
2493                                $unit eq 'm' ?    1048576 :
2494                                $unit eq 'k' ?       1024 : 1);
2495         }
2496         return $val;
2497 }
2498
2499 # convert config value to array reference, if needed
2500 sub config_to_multi {
2501         my $val = shift;
2502
2503         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2504 }
2505
2506 sub git_get_project_config {
2507         my ($key, $type) = @_;
2508
2509         return unless defined $git_dir;
2510
2511         # key sanity check
2512         return unless ($key);
2513         $key =~ s/^gitweb\.//;
2514         return if ($key =~ m/\W/);
2515
2516         # type sanity check
2517         if (defined $type) {
2518                 $type =~ s/^--//;
2519                 $type = undef
2520                         unless ($type eq 'bool' || $type eq 'int');
2521         }
2522
2523         # get config
2524         if (!defined $config_file ||
2525             $config_file ne "$git_dir/config") {
2526                 %config = git_parse_project_config('gitweb');
2527                 $config_file = "$git_dir/config";
2528         }
2529
2530         # check if config variable (key) exists
2531         return unless exists $config{"gitweb.$key"};
2532
2533         # ensure given type
2534         if (!defined $type) {
2535                 return $config{"gitweb.$key"};
2536         } elsif ($type eq 'bool') {
2537                 # backward compatibility: 'git config --bool' returns true/false
2538                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2539         } elsif ($type eq 'int') {
2540                 return config_to_int($config{"gitweb.$key"});
2541         }
2542         return $config{"gitweb.$key"};
2543 }
2544
2545 # get hash of given path at given ref
2546 sub git_get_hash_by_path {
2547         my $base = shift;
2548         my $path = shift || return undef;
2549         my $type = shift;
2550
2551         $path =~ s,/+$,,;
2552
2553         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2554                 or die_error(500, "Open git-ls-tree failed");
2555         my $line = <$fd>;
2556         close $fd or return undef;
2557
2558         if (!defined $line) {
2559                 # there is no tree or hash given by $path at $base
2560                 return undef;
2561         }
2562
2563         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2564         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2565         if (defined $type && $type ne $2) {
2566                 # type doesn't match
2567                 return undef;
2568         }
2569         return $3;
2570 }
2571
2572 # get path of entry with given hash at given tree-ish (ref)
2573 # used to get 'from' filename for combined diff (merge commit) for renames
2574 sub git_get_path_by_hash {
2575         my $base = shift || return;
2576         my $hash = shift || return;
2577
2578         local $/ = "\0";
2579
2580         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2581                 or return undef;
2582         while (my $line = <$fd>) {
2583                 chomp $line;
2584
2585                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2586                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2587                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2588                         close $fd;
2589                         return $1;
2590                 }
2591         }
2592         close $fd;
2593         return undef;
2594 }
2595
2596 ## ......................................................................
2597 ## git utility functions, directly accessing git repository
2598
2599 # get the value of config variable either from file named as the variable
2600 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2601 # configuration variable in the repository config file.
2602 sub git_get_file_or_project_config {
2603         my ($path, $name) = @_;
2604
2605         $git_dir = "$projectroot/$path";
2606         open my $fd, '<', "$git_dir/$name"
2607                 or return git_get_project_config($name);
2608         my $conf = <$fd>;
2609         close $fd;
2610         if (defined $conf) {
2611                 chomp $conf;
2612         }
2613         return $conf;
2614 }
2615
2616 sub git_get_project_description {
2617         my $path = shift;
2618         return git_get_file_or_project_config($path, 'description');
2619 }
2620
2621 sub git_get_project_category {
2622         my $path = shift;
2623         return git_get_file_or_project_config($path, 'category');
2624 }
2625
2626
2627 # supported formats:
2628 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2629 #   - if its contents is a number, use it as tag weight,
2630 #   - otherwise add a tag with weight 1
2631 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2632 #   the same value multiple times increases tag weight
2633 # * `gitweb.ctag' multi-valued repo config variable
2634 sub git_get_project_ctags {
2635         my $project = shift;
2636         my $ctags = {};
2637
2638         $git_dir = "$projectroot/$project";
2639         if (opendir my $dh, "$git_dir/ctags") {
2640                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2641                 foreach my $tagfile (@files) {
2642                         open my $ct, '<', $tagfile
2643                                 or next;
2644                         my $val = <$ct>;
2645                         chomp $val if $val;
2646                         close $ct;
2647
2648                         (my $ctag = $tagfile) =~ s#.*/##;
2649                         if ($val =~ /^\d+$/) {
2650                                 $ctags->{$ctag} = $val;
2651                         } else {
2652                                 $ctags->{$ctag} = 1;
2653                         }
2654                 }
2655                 closedir $dh;
2656
2657         } elsif (open my $fh, '<', "$git_dir/ctags") {
2658                 while (my $line = <$fh>) {
2659                         chomp $line;
2660                         $ctags->{$line}++ if $line;
2661                 }
2662                 close $fh;
2663
2664         } else {
2665                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2666                 foreach my $tag (@$taglist) {
2667                         $ctags->{$tag}++;
2668                 }
2669         }
2670
2671         return $ctags;
2672 }
2673
2674 # return hash, where keys are content tags ('ctags'),
2675 # and values are sum of weights of given tag in every project
2676 sub git_gather_all_ctags {
2677         my $projects = shift;
2678         my $ctags = {};
2679
2680         foreach my $p (@$projects) {
2681                 foreach my $ct (keys %{$p->{'ctags'}}) {
2682                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2683                 }
2684         }
2685
2686         return $ctags;
2687 }
2688
2689 sub git_populate_project_tagcloud {
2690         my $ctags = shift;
2691
2692         # First, merge different-cased tags; tags vote on casing
2693         my %ctags_lc;
2694         foreach (keys %$ctags) {
2695                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2696                 if (not $ctags_lc{lc $_}->{topcount}
2697                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2698                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2699                         $ctags_lc{lc $_}->{topname} = $_;
2700                 }
2701         }
2702
2703         my $cloud;
2704         my $matched = $cgi->param('by_tag');
2705         if (eval { require HTML::TagCloud; 1; }) {
2706                 $cloud = HTML::TagCloud->new;
2707                 foreach my $ctag (sort keys %ctags_lc) {
2708                         # Pad the title with spaces so that the cloud looks
2709                         # less crammed.
2710                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2711                         $title =~ s/ /&nbsp;/g;
2712                         $title =~ s/^/&nbsp;/g;
2713                         $title =~ s/$/&nbsp;/g;
2714                         if (defined $matched && $matched eq $ctag) {
2715                                 $title = qq(<span class="match">$title</span>);
2716                         }
2717                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2718                                     $ctags_lc{$ctag}->{count});
2719                 }
2720         } else {
2721                 $cloud = {};
2722                 foreach my $ctag (keys %ctags_lc) {
2723                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2724                         if (defined $matched && $matched eq $ctag) {
2725                                 $title = qq(<span class="match">$title</span>);
2726                         }
2727                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2728                         $cloud->{$ctag}{ctag} =
2729                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2730                 }
2731         }
2732         return $cloud;
2733 }
2734
2735 sub git_show_project_tagcloud {
2736         my ($cloud, $count) = @_;
2737         if (ref $cloud eq 'HTML::TagCloud') {
2738                 return $cloud->html_and_css($count);
2739         } else {
2740                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2741                 return
2742                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2743                         join (', ', map {
2744                                 $cloud->{$_}->{'ctag'}
2745                         } splice(@tags, 0, $count)) .
2746                         '</div>';
2747         }
2748 }
2749
2750 sub git_get_project_url_list {
2751         my $path = shift;
2752
2753         $git_dir = "$projectroot/$path";
2754         open my $fd, '<', "$git_dir/cloneurl"
2755                 or return wantarray ?
2756                 @{ config_to_multi(git_get_project_config('url')) } :
2757                    config_to_multi(git_get_project_config('url'));
2758         my @git_project_url_list = map { chomp; $_ } <$fd>;
2759         close $fd;
2760
2761         return wantarray ? @git_project_url_list : \@git_project_url_list;
2762 }
2763
2764 sub git_get_projects_list {
2765         my $filter = shift || '';
2766         my @list;
2767
2768         $filter =~ s/\.git$//;
2769
2770         if (-d $projects_list) {
2771                 # search in directory
2772                 my $dir = $projects_list;
2773                 # remove the trailing "/"
2774                 $dir =~ s!/+$!!;
2775                 my $pfxlen = length("$projects_list");
2776                 my $pfxdepth = ($projects_list =~ tr!/!!);
2777                 # when filtering, search only given subdirectory
2778                 if ($filter) {
2779                         $dir .= "/$filter";
2780                         $dir =~ s!/+$!!;
2781                 }
2782
2783                 File::Find::find({
2784                         follow_fast => 1, # follow symbolic links
2785                         follow_skip => 2, # ignore duplicates
2786                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2787                         wanted => sub {
2788                                 # global variables
2789                                 our $project_maxdepth;
2790                                 our $projectroot;
2791                                 # skip project-list toplevel, if we get it.
2792                                 return if (m!^[/.]$!);
2793                                 # only directories can be git repositories
2794                                 return unless (-d $_);
2795                                 # don't traverse too deep (Find is super slow on os x)
2796                                 # $project_maxdepth excludes depth of $projectroot
2797                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2798                                         $File::Find::prune = 1;
2799                                         return;
2800                                 }
2801
2802                                 my $path = substr($File::Find::name, $pfxlen + 1);
2803                                 # we check related file in $projectroot
2804                                 if (check_export_ok("$projectroot/$path")) {
2805                                         push @list, { path => $path };
2806                                         $File::Find::prune = 1;
2807                                 }
2808                         },
2809                 }, "$dir");
2810
2811         } elsif (-f $projects_list) {
2812                 # read from file(url-encoded):
2813                 # 'git%2Fgit.git Linus+Torvalds'
2814                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2815                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2816                 open my $fd, '<', $projects_list or return;
2817         PROJECT:
2818                 while (my $line = <$fd>) {
2819                         chomp $line;
2820                         my ($path, $owner) = split ' ', $line;
2821                         $path = unescape($path);
2822                         $owner = unescape($owner);
2823                         if (!defined $path) {
2824                                 next;
2825                         }
2826                         # if $filter is rpovided, check if $path begins with $filter
2827                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2828                                 next;
2829                         }
2830                         if (check_export_ok("$projectroot/$path")) {
2831                                 my $pr = {
2832                                         path => $path,
2833                                         owner => to_utf8($owner),
2834                                 };
2835                                 push @list, $pr;
2836                         }
2837                 }
2838                 close $fd;
2839         }
2840         return @list;
2841 }
2842
2843 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2844 # as side effects it sets 'forks' field to list of forks for forked projects
2845 sub filter_forks_from_projects_list {
2846         my $projects = shift;
2847
2848         my %trie; # prefix tree of directories (path components)
2849         # generate trie out of those directories that might contain forks
2850         foreach my $pr (@$projects) {
2851                 my $path = $pr->{'path'};
2852                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2853                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2854                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2855                 next unless (-d $path);   # containing directory exists
2856                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2857
2858                 # add to trie
2859                 my @dirs = split('/', $path);
2860                 # walk the trie, until either runs out of components or out of trie
2861                 my $ref = \%trie;
2862                 while (scalar @dirs &&
2863                        exists($ref->{$dirs[0]})) {
2864                         $ref = $ref->{shift @dirs};
2865                 }
2866                 # create rest of trie structure from rest of components
2867                 foreach my $dir (@dirs) {
2868                         $ref = $ref->{$dir} = {};
2869                 }
2870                 # create end marker, store $pr as a data
2871                 $ref->{''} = $pr if (!exists $ref->{''});
2872         }
2873
2874         # filter out forks, by finding shortest prefix match for paths
2875         my @filtered;
2876  PROJECT:
2877         foreach my $pr (@$projects) {
2878                 # trie lookup
2879                 my $ref = \%trie;
2880         DIR:
2881                 foreach my $dir (split('/', $pr->{'path'})) {
2882                         if (exists $ref->{''}) {
2883                                 # found [shortest] prefix, is a fork - skip it
2884                                 push @{$ref->{''}{'forks'}}, $pr;
2885                                 next PROJECT;
2886                         }
2887                         if (!exists $ref->{$dir}) {
2888                                 # not in trie, cannot have prefix, not a fork
2889                                 push @filtered, $pr;
2890                                 next PROJECT;
2891                         }
2892                         # If the dir is there, we just walk one step down the trie.
2893                         $ref = $ref->{$dir};
2894                 }
2895                 # we ran out of trie
2896                 # (shouldn't happen: it's either no match, or end marker)
2897                 push @filtered, $pr;
2898         }
2899
2900         return @filtered;
2901 }
2902
2903 # note: fill_project_list_info must be run first,
2904 # for 'descr_long' and 'ctags' to be filled
2905 sub search_projects_list {
2906         my ($projlist, %opts) = @_;
2907         my $tagfilter  = $opts{'tagfilter'};
2908         my $searchtext = $opts{'searchtext'};
2909
2910         return @$projlist
2911                 unless ($tagfilter || $searchtext);
2912
2913         my @projects;
2914  PROJECT:
2915         foreach my $pr (@$projlist) {
2916
2917                 if ($tagfilter) {
2918                         next unless ref($pr->{'ctags'}) eq 'HASH';
2919                         next unless
2920                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2921                 }
2922
2923                 if ($searchtext) {
2924                         next unless
2925                                 $pr->{'path'} =~ /$searchtext/ ||
2926                                 $pr->{'descr_long'} =~ /$searchtext/;
2927                 }
2928
2929                 push @projects, $pr;
2930         }
2931
2932         return @projects;
2933 }
2934
2935 our $gitweb_project_owner = undef;
2936 sub git_get_project_list_from_file {
2937
2938         return if (defined $gitweb_project_owner);
2939
2940         $gitweb_project_owner = {};
2941         # read from file (url-encoded):
2942         # 'git%2Fgit.git Linus+Torvalds'
2943         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2944         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2945         if (-f $projects_list) {
2946                 open(my $fd, '<', $projects_list);
2947                 while (my $line = <$fd>) {
2948                         chomp $line;
2949                         my ($pr, $ow) = split ' ', $line;
2950                         $pr = unescape($pr);
2951                         $ow = unescape($ow);
2952                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2953                 }
2954                 close $fd;
2955         }
2956 }
2957
2958 sub git_get_project_owner {
2959         my $project = shift;
2960         my $owner;
2961
2962         return undef unless $project;
2963         $git_dir = "$projectroot/$project";
2964
2965         if (!defined $gitweb_project_owner) {
2966                 git_get_project_list_from_file();
2967         }
2968
2969         if (exists $gitweb_project_owner->{$project}) {
2970                 $owner = $gitweb_project_owner->{$project};
2971         }
2972         if (!defined $owner){
2973                 $owner = git_get_project_config('owner');
2974         }
2975         if (!defined $owner) {
2976                 $owner = get_file_owner("$git_dir");
2977         }
2978
2979         return $owner;
2980 }
2981
2982 sub git_get_last_activity {
2983         my ($path) = @_;
2984         my $fd;
2985
2986         $git_dir = "$projectroot/$path";
2987         open($fd, "-|", git_cmd(), 'for-each-ref',
2988              '--format=%(committer)',
2989              '--sort=-committerdate',
2990              '--count=1',
2991              'refs/heads') or return;
2992         my $most_recent = <$fd>;
2993         close $fd or return;
2994         if (defined $most_recent &&
2995             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2996                 my $timestamp = $1;
2997                 my $age = time - $timestamp;
2998                 return ($age, age_string($age));
2999         }
3000         return (undef, undef);
3001 }
3002
3003 # Implementation note: when a single remote is wanted, we cannot use 'git
3004 # remote show -n' because that command always work (assuming it's a remote URL
3005 # if it's not defined), and we cannot use 'git remote show' because that would
3006 # try to make a network roundtrip. So the only way to find if that particular
3007 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3008 # and when we find what we want.
3009 sub git_get_remotes_list {
3010         my $wanted = shift;
3011         my %remotes = ();
3012
3013         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3014         return unless $fd;
3015         while (my $remote = <$fd>) {
3016                 chomp $remote;
3017                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3018                 next if $wanted and not $remote eq $wanted;
3019                 my ($url, $key) = ($1, $2);
3020
3021                 $remotes{$remote} ||= { 'heads' => () };
3022                 $remotes{$remote}{$key} = $url;
3023         }
3024         close $fd or return;
3025         return wantarray ? %remotes : \%remotes;
3026 }
3027
3028 # Takes a hash of remotes as first parameter and fills it by adding the
3029 # available remote heads for each of the indicated remotes.
3030 sub fill_remote_heads {
3031         my $remotes = shift;
3032         my @heads = map { "remotes/$_" } keys %$remotes;
3033         my @remoteheads = git_get_heads_list(undef, @heads);
3034         foreach my $remote (keys %$remotes) {
3035                 $remotes->{$remote}{'heads'} = [ grep {
3036                         $_->{'name'} =~ s!^$remote/!!
3037                         } @remoteheads ];
3038         }
3039 }
3040
3041 sub git_get_references {
3042         my $type = shift || "";
3043         my %refs;
3044         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3045         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3046         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3047                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3048                 or return;
3049
3050         while (my $line = <$fd>) {
3051                 chomp $line;
3052                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3053                         if (defined $refs{$1}) {
3054                                 push @{$refs{$1}}, $2;
3055                         } else {
3056                                 $refs{$1} = [ $2 ];
3057                         }
3058                 }
3059         }
3060         close $fd or return;
3061         return \%refs;
3062 }
3063
3064 sub git_get_rev_name_tags {
3065         my $hash = shift || return undef;
3066
3067         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3068                 or return;
3069         my $name_rev = <$fd>;
3070         close $fd;
3071
3072         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3073                 return $1;
3074         } else {
3075                 # catches also '$hash undefined' output
3076                 return undef;
3077         }
3078 }
3079
3080 ## ----------------------------------------------------------------------
3081 ## parse to hash functions
3082
3083 sub parse_date {
3084         my $epoch = shift;
3085         my $tz = shift || "-0000";
3086
3087         my %date;
3088         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3089         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3090         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3091         $date{'hour'} = $hour;
3092         $date{'minute'} = $min;
3093         $date{'mday'} = $mday;
3094         $date{'day'} = $days[$wday];
3095         $date{'month'} = $months[$mon];
3096         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3097                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3098         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3099                              $mday, $months[$mon], $hour ,$min;
3100         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3101                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3102
3103         my ($tz_sign, $tz_hour, $tz_min) =
3104                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3105         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3106         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3107         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3108         $date{'hour_local'} = $hour;
3109         $date{'minute_local'} = $min;
3110         $date{'tz_local'} = $tz;
3111         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3112                                   1900+$year, $mon+1, $mday,
3113                                   $hour, $min, $sec, $tz);
3114         return %date;
3115 }
3116
3117 sub parse_tag {
3118         my $tag_id = shift;
3119         my %tag;
3120         my @comment;
3121
3122         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3123         $tag{'id'} = $tag_id;
3124         while (my $line = <$fd>) {
3125                 chomp $line;
3126                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3127                         $tag{'object'} = $1;
3128                 } elsif ($line =~ m/^type (.+)$/) {
3129                         $tag{'type'} = $1;
3130                 } elsif ($line =~ m/^tag (.+)$/) {
3131                         $tag{'name'} = $1;
3132                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3133                         $tag{'author'} = $1;
3134                         $tag{'author_epoch'} = $2;
3135                         $tag{'author_tz'} = $3;
3136                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3137                                 $tag{'author_name'}  = $1;
3138                                 $tag{'author_email'} = $2;
3139                         } else {
3140                                 $tag{'author_name'} = $tag{'author'};
3141                         }
3142                 } elsif ($line =~ m/--BEGIN/) {
3143                         push @comment, $line;
3144                         last;
3145                 } elsif ($line eq "") {
3146                         last;
3147                 }
3148         }
3149         push @comment, <$fd>;
3150         $tag{'comment'} = \@comment;
3151         close $fd or return;
3152         if (!defined $tag{'name'}) {
3153                 return
3154         };
3155         return %tag
3156 }
3157
3158 sub parse_commit_text {
3159         my ($commit_text, $withparents) = @_;
3160         my @commit_lines = split '\n', $commit_text;
3161         my %co;
3162
3163         pop @commit_lines; # Remove '\0'
3164
3165         if (! @commit_lines) {
3166                 return;
3167         }
3168
3169         my $header = shift @commit_lines;
3170         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3171                 return;
3172         }
3173         ($co{'id'}, my @parents) = split ' ', $header;
3174         while (my $line = shift @commit_lines) {
3175                 last if $line eq "\n";
3176                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3177                         $co{'tree'} = $1;
3178                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3179                         push @parents, $1;
3180                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3181                         $co{'author'} = to_utf8($1);
3182                         $co{'author_epoch'} = $2;
3183                         $co{'author_tz'} = $3;
3184                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3185                                 $co{'author_name'}  = $1;
3186                                 $co{'author_email'} = $2;
3187                         } else {
3188                                 $co{'author_name'} = $co{'author'};
3189                         }
3190                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3191                         $co{'committer'} = to_utf8($1);
3192                         $co{'committer_epoch'} = $2;
3193                         $co{'committer_tz'} = $3;
3194                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3195                                 $co{'committer_name'}  = $1;
3196                                 $co{'committer_email'} = $2;
3197                         } else {
3198                                 $co{'committer_name'} = $co{'committer'};
3199                         }
3200                 }
3201         }
3202         if (!defined $co{'tree'}) {
3203                 return;
3204         };
3205         $co{'parents'} = \@parents;
3206         $co{'parent'} = $parents[0];
3207
3208         foreach my $title (@commit_lines) {
3209                 $title =~ s/^    //;
3210                 if ($title ne "") {
3211                         $co{'title'} = chop_str($title, 80, 5);
3212                         # remove leading stuff of merges to make the interesting part visible
3213                         if (length($title) > 50) {
3214                                 $title =~ s/^Automatic //;
3215                                 $title =~ s/^merge (of|with) /Merge ... /i;
3216                                 if (length($title) > 50) {
3217                                         $title =~ s/(http|rsync):\/\///;
3218                                 }
3219                                 if (length($title) > 50) {
3220                                         $title =~ s/(master|www|rsync)\.//;
3221                                 }
3222                                 if (length($title) > 50) {
3223                                         $title =~ s/kernel.org:?//;
3224                                 }
3225                                 if (length($title) > 50) {
3226                                         $title =~ s/\/pub\/scm//;
3227                                 }
3228                         }
3229                         $co{'title_short'} = chop_str($title, 50, 5);
3230                         last;
3231                 }
3232         }
3233         if (! defined $co{'title'} || $co{'title'} eq "") {
3234                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3235         }
3236         # remove added spaces
3237         foreach my $line (@commit_lines) {
3238                 $line =~ s/^    //;
3239         }
3240         $co{'comment'} = \@commit_lines;
3241
3242         my $age = time - $co{'committer_epoch'};
3243         $co{'age'} = $age;
3244         $co{'age_string'} = age_string($age);
3245         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3246         if ($age > 60*60*24*7*2) {
3247                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3248                 $co{'age_string_age'} = $co{'age_string'};
3249         } else {
3250                 $co{'age_string_date'} = $co{'age_string'};
3251                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3252         }
3253         return %co;
3254 }
3255
3256 sub parse_commit {
3257         my ($commit_id) = @_;
3258         my %co;
3259
3260         local $/ = "\0";
3261
3262         open my $fd, "-|", git_cmd(), "rev-list",
3263                 "--parents",
3264                 "--header",
3265                 "--max-count=1",
3266                 $commit_id,
3267                 "--",
3268                 or die_error(500, "Open git-rev-list failed");
3269         %co = parse_commit_text(<$fd>, 1);
3270         close $fd;
3271
3272         return %co;
3273 }
3274
3275 sub parse_commits {
3276         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3277         my @cos;
3278
3279         $maxcount ||= 1;
3280         $skip ||= 0;
3281
3282         local $/ = "\0";
3283
3284         open my $fd, "-|", git_cmd(), "rev-list",
3285                 "--header",
3286                 @args,
3287                 ("--max-count=" . $maxcount),
3288                 ("--skip=" . $skip),
3289                 @extra_options,
3290                 $commit_id,
3291                 "--",
3292                 ($filename ? ($filename) : ())
3293                 or die_error(500, "Open git-rev-list failed");
3294         while (my $line = <$fd>) {
3295                 my %co = parse_commit_text($line);
3296                 push @cos, \%co;
3297         }
3298         close $fd;
3299
3300         return wantarray ? @cos : \@cos;
3301 }
3302
3303 # parse line of git-diff-tree "raw" output
3304 sub parse_difftree_raw_line {
3305         my $line = shift;
3306         my %res;
3307
3308         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3309         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3310         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3311                 $res{'from_mode'} = $1;
3312                 $res{'to_mode'} = $2;
3313                 $res{'from_id'} = $3;
3314                 $res{'to_id'} = $4;
3315                 $res{'status'} = $5;
3316                 $res{'similarity'} = $6;
3317                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3318                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3319                 } else {
3320                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3321                 }
3322         }
3323         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3324         # combined diff (for merge commit)
3325         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3326                 $res{'nparents'}  = length($1);
3327                 $res{'from_mode'} = [ split(' ', $2) ];
3328                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3329                 $res{'from_id'} = [ split(' ', $3) ];
3330                 $res{'to_id'} = pop @{$res{'from_id'}};
3331                 $res{'status'} = [ split('', $4) ];
3332                 $res{'to_file'} = unquote($5);
3333         }
3334         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3335         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3336                 $res{'commit'} = $1;
3337         }
3338
3339         return wantarray ? %res : \%res;
3340 }
3341
3342 # wrapper: return parsed line of git-diff-tree "raw" output
3343 # (the argument might be raw line, or parsed info)
3344 sub parsed_difftree_line {
3345         my $line_or_ref = shift;
3346
3347         if (ref($line_or_ref) eq "HASH") {
3348                 # pre-parsed (or generated by hand)
3349                 return $line_or_ref;
3350         } else {
3351                 return parse_difftree_raw_line($line_or_ref);
3352         }
3353 }
3354
3355 # parse line of git-ls-tree output
3356 sub parse_ls_tree_line {
3357         my $line = shift;
3358         my %opts = @_;
3359         my %res;
3360
3361         if ($opts{'-l'}) {
3362                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3363                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3364
3365                 $res{'mode'} = $1;
3366                 $res{'type'} = $2;
3367                 $res{'hash'} = $3;
3368                 $res{'size'} = $4;
3369                 if ($opts{'-z'}) {
3370                         $res{'name'} = $5;
3371                 } else {
3372                         $res{'name'} = unquote($5);
3373                 }
3374         } else {
3375                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3376                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3377
3378                 $res{'mode'} = $1;
3379                 $res{'type'} = $2;
3380                 $res{'hash'} = $3;
3381                 if ($opts{'-z'}) {
3382                         $res{'name'} = $4;
3383                 } else {
3384                         $res{'name'} = unquote($4);
3385                 }
3386         }
3387
3388         return wantarray ? %res : \%res;
3389 }
3390
3391 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3392 sub parse_from_to_diffinfo {
3393         my ($diffinfo, $from, $to, @parents) = @_;
3394
3395         if ($diffinfo->{'nparents'}) {
3396                 # combined diff
3397                 $from->{'file'} = [];
3398                 $from->{'href'} = [];
3399                 fill_from_file_info($diffinfo, @parents)
3400                         unless exists $diffinfo->{'from_file'};
3401                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3402                         $from->{'file'}[$i] =
3403                                 defined $diffinfo->{'from_file'}[$i] ?
3404                                         $diffinfo->{'from_file'}[$i] :
3405                                         $diffinfo->{'to_file'};
3406                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3407                                 $from->{'href'}[$i] = href(action=>"blob",
3408                                                            hash_base=>$parents[$i],
3409                                                            hash=>$diffinfo->{'from_id'}[$i],
3410                                                            file_name=>$from->{'file'}[$i]);
3411                         } else {
3412                                 $from->{'href'}[$i] = undef;
3413                         }
3414                 }
3415         } else {
3416                 # ordinary (not combined) diff
3417                 $from->{'file'} = $diffinfo->{'from_file'};
3418                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3419                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3420                                                hash=>$diffinfo->{'from_id'},
3421                                                file_name=>$from->{'file'});
3422                 } else {
3423                         delete $from->{'href'};
3424                 }
3425         }
3426
3427         $to->{'file'} = $diffinfo->{'to_file'};
3428         if (!is_deleted($diffinfo)) { # file exists in result
3429                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3430                                      hash=>$diffinfo->{'to_id'},
3431                                      file_name=>$to->{'file'});
3432         } else {
3433                 delete $to->{'href'};
3434         }
3435 }
3436
3437 ## ......................................................................
3438 ## parse to array of hashes functions
3439
3440 sub git_get_heads_list {
3441         my ($limit, @classes) = @_;
3442         @classes = ('heads') unless @classes;
3443         my @patterns = map { "refs/$_" } @classes;
3444         my @headslist;
3445
3446         open my $fd, '-|', git_cmd(), 'for-each-ref',
3447                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3448                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3449                 @patterns
3450                 or return;
3451         while (my $line = <$fd>) {
3452                 my %ref_item;
3453
3454                 chomp $line;
3455                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3456                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3457                 my ($committer, $epoch, $tz) =
3458                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3459                 $ref_item{'fullname'}  = $name;
3460                 $name =~ s!^refs/(?:head|remote)s/!!;
3461
3462                 $ref_item{'name'}  = $name;
3463                 $ref_item{'id'}    = $hash;
3464                 $ref_item{'title'} = $title || '(no commit message)';
3465                 $ref_item{'epoch'} = $epoch;
3466                 if ($epoch) {
3467                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3468                 } else {
3469                         $ref_item{'age'} = "unknown";
3470                 }
3471
3472                 push @headslist, \%ref_item;
3473         }
3474         close $fd;
3475
3476         return wantarray ? @headslist : \@headslist;
3477 }
3478
3479 sub git_get_tags_list {
3480         my $limit = shift;
3481         my @tagslist;
3482
3483         open my $fd, '-|', git_cmd(), 'for-each-ref',
3484                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3485                 '--format=%(objectname) %(objecttype) %(refname) '.
3486                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3487                 'refs/tags'
3488                 or return;
3489         while (my $line = <$fd>) {
3490                 my %ref_item;
3491
3492                 chomp $line;
3493                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3494                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3495                 my ($creator, $epoch, $tz) =
3496                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3497                 $ref_item{'fullname'} = $name;
3498                 $name =~ s!^refs/tags/!!;
3499
3500                 $ref_item{'type'} = $type;
3501                 $ref_item{'id'} = $id;
3502                 $ref_item{'name'} = $name;
3503                 if ($type eq "tag") {
3504                         $ref_item{'subject'} = $title;
3505                         $ref_item{'reftype'} = $reftype;
3506                         $ref_item{'refid'}   = $refid;
3507                 } else {
3508                         $ref_item{'reftype'} = $type;
3509                         $ref_item{'refid'}   = $id;
3510                 }
3511
3512                 if ($type eq "tag" || $type eq "commit") {
3513                         $ref_item{'epoch'} = $epoch;
3514                         if ($epoch) {
3515                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3516                         } else {
3517                                 $ref_item{'age'} = "unknown";
3518                         }
3519                 }
3520
3521                 push @tagslist, \%ref_item;
3522         }
3523         close $fd;
3524
3525         return wantarray ? @tagslist : \@tagslist;
3526 }
3527
3528 ## ----------------------------------------------------------------------
3529 ## filesystem-related functions
3530
3531 sub get_file_owner {
3532         my $path = shift;
3533
3534         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3535         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3536         if (!defined $gcos) {
3537                 return undef;
3538         }
3539         my $owner = $gcos;
3540         $owner =~ s/[,;].*$//;
3541         return to_utf8($owner);
3542 }
3543
3544 # assume that file exists
3545 sub insert_file {
3546         my $filename = shift;
3547
3548         open my $fd, '<', $filename;
3549         print map { to_utf8($_) } <$fd>;
3550         close $fd;
3551 }
3552
3553 ## ......................................................................
3554 ## mimetype related functions
3555
3556 sub mimetype_guess_file {
3557         my $filename = shift;
3558         my $mimemap = shift;
3559         -r $mimemap or return undef;
3560
3561         my %mimemap;
3562         open(my $mh, '<', $mimemap) or return undef;
3563         while (<$mh>) {
3564                 next if m/^#/; # skip comments
3565                 my ($mimetype, $exts) = split(/\t+/);
3566                 if (defined $exts) {
3567                         my @exts = split(/\s+/, $exts);
3568                         foreach my $ext (@exts) {
3569                                 $mimemap{$ext} = $mimetype;
3570                         }
3571                 }
3572         }
3573         close($mh);
3574
3575         $filename =~ /\.([^.]*)$/;
3576         return $mimemap{$1};
3577 }
3578
3579 sub mimetype_guess {
3580         my $filename = shift;
3581         my $mime;
3582         $filename =~ /\./ or return undef;
3583
3584         if ($mimetypes_file) {
3585                 my $file = $mimetypes_file;
3586                 if ($file !~ m!^/!) { # if it is relative path
3587                         # it is relative to project
3588                         $file = "$projectroot/$project/$file";
3589                 }
3590                 $mime = mimetype_guess_file($filename, $file);
3591         }
3592         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3593         return $mime;
3594 }
3595
3596 sub blob_mimetype {
3597         my $fd = shift;
3598         my $filename = shift;
3599
3600         if ($filename) {
3601                 my $mime = mimetype_guess($filename);
3602                 $mime and return $mime;
3603         }
3604
3605         # just in case
3606         return $default_blob_plain_mimetype unless $fd;
3607
3608         if (-T $fd) {
3609                 return 'text/plain';
3610         } elsif (! $filename) {
3611                 return 'application/octet-stream';
3612         } elsif ($filename =~ m/\.png$/i) {
3613                 return 'image/png';
3614         } elsif ($filename =~ m/\.gif$/i) {
3615                 return 'image/gif';
3616         } elsif ($filename =~ m/\.jpe?g$/i) {
3617                 return 'image/jpeg';
3618         } else {
3619                 return 'application/octet-stream';
3620         }
3621 }
3622
3623 sub blob_contenttype {
3624         my ($fd, $file_name, $type) = @_;
3625
3626         $type ||= blob_mimetype($fd, $file_name);
3627         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3628                 $type .= "; charset=$default_text_plain_charset";
3629         }
3630
3631         return $type;
3632 }
3633
3634 # guess file syntax for syntax highlighting; return undef if no highlighting
3635 # the name of syntax can (in the future) depend on syntax highlighter used
3636 sub guess_file_syntax {
3637         my ($highlight, $mimetype, $file_name) = @_;
3638         return undef unless ($highlight && defined $file_name);
3639         my $basename = basename($file_name, '.in');
3640         return $highlight_basename{$basename}
3641                 if exists $highlight_basename{$basename};
3642
3643         $basename =~ /\.([^.]*)$/;
3644         my $ext = $1 or return undef;
3645         return $highlight_ext{$ext}
3646                 if exists $highlight_ext{$ext};
3647
3648         return undef;
3649 }
3650
3651 # run highlighter and return FD of its output,
3652 # or return original FD if no highlighting
3653 sub run_highlighter {
3654         my ($fd, $highlight, $syntax) = @_;
3655         return $fd unless ($highlight && defined $syntax);
3656
3657         close $fd;
3658         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3659                   quote_command($highlight_bin).
3660                   " --replace-tabs=8 --fragment --syntax $syntax |"
3661                 or die_error(500, "Couldn't open file or run syntax highlighter");
3662         return $fd;
3663 }
3664
3665 ## ======================================================================
3666 ## functions printing HTML: header, footer, error page
3667
3668 sub get_page_title {
3669         my $title = to_utf8($site_name);
3670
3671         return $title unless (defined $project);
3672         $title .= " - " . to_utf8($project);
3673
3674         return $title unless (defined $action);
3675         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3676
3677         return $title unless (defined $file_name);
3678         $title .= " - " . esc_path($file_name);
3679         if ($action eq "tree" && $file_name !~ m|/$|) {
3680                 $title .= "/";
3681         }
3682
3683         return $title;
3684 }
3685
3686 sub print_feed_meta {
3687         if (defined $project) {
3688                 my %href_params = get_feed_info();
3689                 if (!exists $href_params{'-title'}) {
3690                         $href_params{'-title'} = 'log';
3691                 }
3692
3693                 foreach my $format (qw(RSS Atom)) {
3694                         my $type = lc($format);
3695                         my %link_attr = (
3696                                 '-rel' => 'alternate',
3697                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3698                                 '-type' => "application/$type+xml"
3699                         );
3700
3701                         $href_params{'action'} = $type;
3702                         $link_attr{'-href'} = href(%href_params);
3703                         print "<link ".
3704                               "rel=\"$link_attr{'-rel'}\" ".
3705                               "title=\"$link_attr{'-title'}\" ".
3706                               "href=\"$link_attr{'-href'}\" ".
3707                               "type=\"$link_attr{'-type'}\" ".
3708                               "/>\n";
3709
3710                         $href_params{'extra_options'} = '--no-merges';
3711                         $link_attr{'-href'} = href(%href_params);
3712                         $link_attr{'-title'} .= ' (no merges)';
3713                         print "<link ".
3714                               "rel=\"$link_attr{'-rel'}\" ".
3715                               "title=\"$link_attr{'-title'}\" ".
3716                               "href=\"$link_attr{'-href'}\" ".
3717                               "type=\"$link_attr{'-type'}\" ".
3718                               "/>\n";
3719                 }
3720
3721         } else {
3722                 printf('<link rel="alternate" title="%s projects list" '.
3723                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3724                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3725                 printf('<link rel="alternate" title="%s projects feeds" '.
3726                        'href="%s" type="text/x-opml" />'."\n",
3727                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3728         }
3729 }
3730
3731 sub git_header_html {
3732         my $status = shift || "200 OK";
3733         my $expires = shift;
3734         my %opts = @_;
3735
3736         my $title = get_page_title();
3737         my $content_type;
3738         # require explicit support from the UA if we are to send the page as
3739         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3740         # we have to do this because MSIE sometimes globs '*/*', pretending to
3741         # support xhtml+xml but choking when it gets what it asked for.
3742         if (defined $cgi->http('HTTP_ACCEPT') &&
3743             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3744             $cgi->Accept('application/xhtml+xml') != 0) {
3745                 $content_type = 'application/xhtml+xml';
3746         } else {
3747                 $content_type = 'text/html';
3748         }
3749         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3750                            -status=> $status, -expires => $expires)
3751                 unless ($opts{'-no_http_header'});
3752         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3753         print <<EOF;
3754 <?xml version="1.0" encoding="utf-8"?>
3755 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3756 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3757 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3758 <!-- git core binaries version $git_version -->
3759 <head>
3760 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3761 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3762 <meta name="robots" content="index, nofollow"/>
3763 <title>$title</title>
3764 EOF
3765         # the stylesheet, favicon etc urls won't work correctly with path_info
3766         # unless we set the appropriate base URL
3767         if ($ENV{'PATH_INFO'}) {
3768                 print "<base href=\"".esc_url($base_url)."\" />\n";
3769         }
3770         # print out each stylesheet that exist, providing backwards capability
3771         # for those people who defined $stylesheet in a config file
3772         if (defined $stylesheet) {
3773                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3774         } else {
3775                 foreach my $stylesheet (@stylesheets) {
3776                         next unless $stylesheet;
3777                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3778                 }
3779         }
3780         print_feed_meta()
3781                 if ($status eq '200 OK');
3782         if (defined $favicon) {
3783                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3784         }
3785
3786         print "</head>\n" .
3787               "<body>\n";
3788
3789         if (defined $site_header && -f $site_header) {
3790                 insert_file($site_header);
3791         }
3792
3793         print "<div class=\"page_header\">\n";
3794         if (defined $logo) {
3795                 print $cgi->a({-href => esc_url($logo_url),
3796                                -title => $logo_label},
3797                               $cgi->img({-src => esc_url($logo),
3798                                          -width => 72, -height => 27,
3799                                          -alt => "git",
3800                                          -class => "logo"}));
3801         }
3802         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3803         if (defined $project) {
3804                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3805                 if (defined $action) {
3806                         my $action_print = $action ;
3807                         if (defined $opts{-action_extra}) {
3808                                 $action_print = $cgi->a({-href => href(action=>$action)},
3809                                         $action);
3810                         }
3811                         print " / $action_print";
3812                 }
3813                 if (defined $opts{-action_extra}) {
3814                         print " / $opts{-action_extra}";
3815                 }
3816                 print "\n";
3817         }
3818         print "</div>\n";
3819
3820         my $have_search = gitweb_check_feature('search');
3821         if (defined $project && $have_search) {
3822                 if (!defined $searchtext) {
3823                         $searchtext = "";
3824                 }
3825                 my $search_hash;
3826                 if (defined $hash_base) {
3827                         $search_hash = $hash_base;
3828                 } elsif (defined $hash) {
3829                         $search_hash = $hash;
3830                 } else {
3831                         $search_hash = "HEAD";
3832                 }
3833                 my $action = $my_uri;
3834                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3835                 if ($use_pathinfo) {
3836                         $action .= "/".esc_url($project);
3837                 }
3838                 print $cgi->startform(-method => "get", -action => $action) .
3839                       "<div class=\"search\">\n" .
3840                       (!$use_pathinfo &&
3841                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3842                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3843                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3844                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3845                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3846                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3847                       " search:\n",
3848                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3849                       "<span title=\"Extended regular expression\">" .
3850                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3851                                      -checked => $search_use_regexp) .
3852                       "</span>" .
3853                       "</div>" .
3854                       $cgi->end_form() . "\n";
3855         }
3856 }
3857
3858 sub git_footer_html {
3859         my $feed_class = 'rss_logo';
3860
3861         print "<div class=\"page_footer\">\n";
3862         if (defined $project) {
3863                 my $descr = git_get_project_description($project);
3864                 if (defined $descr) {
3865                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3866                 }
3867
3868                 my %href_params = get_feed_info();
3869                 if (!%href_params) {
3870                         $feed_class .= ' generic';
3871                 }
3872                 $href_params{'-title'} ||= 'log';
3873
3874                 foreach my $format (qw(RSS Atom)) {
3875                         $href_params{'action'} = lc($format);
3876                         print $cgi->a({-href => href(%href_params),
3877                                       -title => "$href_params{'-title'} $format feed",
3878                                       -class => $feed_class}, $format)."\n";
3879                 }
3880
3881         } else {
3882                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3883                               -class => $feed_class}, "OPML") . " ";
3884                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3885                               -class => $feed_class}, "TXT") . "\n";
3886         }
3887         print "</div>\n"; # class="page_footer"
3888
3889         if (defined $t0 && gitweb_check_feature('timed')) {
3890                 print "<div id=\"generating_info\">\n";
3891                 print 'This page took '.
3892                       '<span id="generating_time" class="time_span">'.
3893                       tv_interval($t0, [ gettimeofday() ]).
3894                       ' seconds </span>'.
3895                       ' and '.
3896                       '<span id="generating_cmd">'.
3897                       $number_of_git_cmds.
3898                       '</span> git commands '.
3899                       " to generate.\n";
3900                 print "</div>\n"; # class="page_footer"
3901         }
3902
3903         if (defined $site_footer && -f $site_footer) {
3904                 insert_file($site_footer);
3905         }
3906
3907         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3908         if (defined $action &&
3909             $action eq 'blame_incremental') {
3910                 print qq!<script type="text/javascript">\n!.
3911                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3912                       qq!           "!. href() .qq!");\n!.
3913                       qq!</script>\n!;
3914         } else {
3915                 my ($jstimezone, $tz_cookie, $datetime_class) =
3916                         gitweb_get_feature('javascript-timezone');
3917
3918                 print qq!<script type="text/javascript">\n!.
3919                       qq!window.onload = function () {\n!;
3920                 if (gitweb_check_feature('javascript-actions')) {
3921                         print qq!       fixLinks();\n!;
3922                 }
3923                 if ($jstimezone && $tz_cookie && $datetime_class) {
3924                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
3925                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
3926                 }
3927                 print qq!};\n!.
3928                       qq!</script>\n!;
3929         }
3930
3931         print "</body>\n" .
3932               "</html>";
3933 }
3934
3935 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3936 # Example: die_error(404, 'Hash not found')
3937 # By convention, use the following status codes (as defined in RFC 2616):
3938 # 400: Invalid or missing CGI parameters, or
3939 #      requested object exists but has wrong type.
3940 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3941 #      this server or project.
3942 # 404: Requested object/revision/project doesn't exist.
3943 # 500: The server isn't configured properly, or
3944 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3945 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3946 # 503: The server is currently unavailable (because it is overloaded,
3947 #      or down for maintenance).  Generally, this is a temporary state.
3948 sub die_error {
3949         my $status = shift || 500;
3950         my $error = esc_html(shift) || "Internal Server Error";
3951         my $extra = shift;
3952         my %opts = @_;
3953
3954         my %http_responses = (
3955                 400 => '400 Bad Request',
3956                 403 => '403 Forbidden',
3957                 404 => '404 Not Found',
3958                 500 => '500 Internal Server Error',
3959                 503 => '503 Service Unavailable',
3960         );
3961         git_header_html($http_responses{$status}, undef, %opts);
3962         print <<EOF;
3963 <div class="page_body">
3964 <br /><br />
3965 $status - $error
3966 <br />
3967 EOF
3968         if (defined $extra) {
3969                 print "<hr />\n" .
3970                       "$extra\n";
3971         }
3972         print "</div>\n";
3973
3974         git_footer_html();
3975         goto DONE_GITWEB
3976                 unless ($opts{'-error_handler'});
3977 }
3978
3979 ## ----------------------------------------------------------------------
3980 ## functions printing or outputting HTML: navigation
3981
3982 sub git_print_page_nav {
3983         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3984         $extra = '' if !defined $extra; # pager or formats
3985
3986         my @navs = qw(summary shortlog log commit commitdiff tree);
3987         if ($suppress) {
3988                 @navs = grep { $_ ne $suppress } @navs;
3989         }
3990
3991         my %arg = map { $_ => {action=>$_} } @navs;
3992         if (defined $head) {
3993                 for (qw(commit commitdiff)) {
3994                         $arg{$_}{'hash'} = $head;
3995                 }
3996                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3997                         for (qw(shortlog log)) {
3998                                 $arg{$_}{'hash'} = $head;
3999                         }
4000                 }
4001         }
4002
4003         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4004         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4005
4006         my @actions = gitweb_get_feature('actions');
4007         my %repl = (
4008                 '%' => '%',
4009                 'n' => $project,         # project name
4010                 'f' => $git_dir,         # project path within filesystem
4011                 'h' => $treehead || '',  # current hash ('h' parameter)
4012                 'b' => $treebase || '',  # hash base ('hb' parameter)
4013         );
4014         while (@actions) {
4015                 my ($label, $link, $pos) = splice(@actions,0,3);
4016                 # insert
4017                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4018                 # munch munch
4019                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4020                 $arg{$label}{'_href'} = $link;
4021         }
4022
4023         print "<div class=\"page_nav\">\n" .
4024                 (join " | ",
4025                  map { $_ eq $current ?
4026                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4027                  } @navs);
4028         print "<br/>\n$extra<br/>\n" .
4029               "</div>\n";
4030 }
4031
4032 # returns a submenu for the nagivation of the refs views (tags, heads,
4033 # remotes) with the current view disabled and the remotes view only
4034 # available if the feature is enabled
4035 sub format_ref_views {
4036         my ($current) = @_;
4037         my @ref_views = qw{tags heads};
4038         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4039         return join " | ", map {
4040                 $_ eq $current ? $_ :
4041                 $cgi->a({-href => href(action=>$_)}, $_)
4042         } @ref_views
4043 }
4044
4045 sub format_paging_nav {
4046         my ($action, $page, $has_next_link) = @_;
4047         my $paging_nav;
4048
4049
4050         if ($page > 0) {
4051                 $paging_nav .=
4052                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4053                         " &sdot; " .
4054                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4055                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4056         } else {
4057                 $paging_nav .= "first &sdot; prev";
4058         }
4059
4060         if ($has_next_link) {
4061                 $paging_nav .= " &sdot; " .
4062                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4063                                  -accesskey => "n", -title => "Alt-n"}, "next");
4064         } else {
4065                 $paging_nav .= " &sdot; next";
4066         }
4067
4068         return $paging_nav;
4069 }
4070
4071 ## ......................................................................
4072 ## functions printing or outputting HTML: div
4073
4074 sub git_print_header_div {
4075         my ($action, $title, $hash, $hash_base) = @_;
4076         my %args = ();
4077
4078         $args{'action'} = $action;
4079         $args{'hash'} = $hash if $hash;
4080         $args{'hash_base'} = $hash_base if $hash_base;
4081
4082         print "<div class=\"header\">\n" .
4083               $cgi->a({-href => href(%args), -class => "title"},
4084               $title ? $title : $action) .
4085               "\n</div>\n";
4086 }
4087
4088 sub format_repo_url {
4089         my ($name, $url) = @_;
4090         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4091 }
4092
4093 # Group output by placing it in a DIV element and adding a header.
4094 # Options for start_div() can be provided by passing a hash reference as the
4095 # first parameter to the function.
4096 # Options to git_print_header_div() can be provided by passing an array
4097 # reference. This must follow the options to start_div if they are present.
4098 # The content can be a scalar, which is output as-is, a scalar reference, which
4099 # is output after html escaping, an IO handle passed either as *handle or
4100 # *handle{IO}, or a function reference. In the latter case all following
4101 # parameters will be taken as argument to the content function call.
4102 sub git_print_section {
4103         my ($div_args, $header_args, $content);
4104         my $arg = shift;
4105         if (ref($arg) eq 'HASH') {
4106                 $div_args = $arg;
4107                 $arg = shift;
4108         }
4109         if (ref($arg) eq 'ARRAY') {
4110                 $header_args = $arg;
4111                 $arg = shift;
4112         }
4113         $content = $arg;
4114
4115         print $cgi->start_div($div_args);
4116         git_print_header_div(@$header_args);
4117
4118         if (ref($content) eq 'CODE') {
4119                 $content->(@_);
4120         } elsif (ref($content) eq 'SCALAR') {
4121                 print esc_html($$content);
4122         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4123                 print <$content>;
4124         } elsif (!ref($content) && defined($content)) {
4125                 print $content;
4126         }
4127
4128         print $cgi->end_div;
4129 }
4130
4131 sub format_timestamp_html {
4132         my $date = shift;
4133         my $strtime = $date->{'rfc2822'};
4134
4135         my (undef, undef, $datetime_class) =
4136                 gitweb_get_feature('javascript-timezone');
4137         if ($datetime_class) {
4138                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4139         }
4140
4141         my $localtime_format = '(%02d:%02d %s)';
4142         if ($date->{'hour_local'} < 6) {
4143                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4144         }
4145         $strtime .= ' ' .
4146                     sprintf($localtime_format,
4147                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4148
4149         return $strtime;
4150 }
4151
4152 # Outputs the author name and date in long form
4153 sub git_print_authorship {
4154         my $co = shift;
4155         my %opts = @_;
4156         my $tag = $opts{-tag} || 'div';
4157         my $author = $co->{'author_name'};
4158
4159         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4160         print "<$tag class=\"author_date\">" .
4161               format_search_author($author, "author", esc_html($author)) .
4162               " [".format_timestamp_html(\%ad)."]".
4163               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4164               "</$tag>\n";
4165 }
4166
4167 # Outputs table rows containing the full author or committer information,
4168 # in the format expected for 'commit' view (& similar).
4169 # Parameters are a commit hash reference, followed by the list of people
4170 # to output information for. If the list is empty it defaults to both
4171 # author and committer.
4172 sub git_print_authorship_rows {
4173         my $co = shift;
4174         # too bad we can't use @people = @_ || ('author', 'committer')
4175         my @people = @_;
4176         @people = ('author', 'committer') unless @people;
4177         foreach my $who (@people) {
4178                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4179                 print "<tr><td>$who</td><td>" .
4180                       format_search_author($co->{"${who}_name"}, $who,
4181                                            esc_html($co->{"${who}_name"})) . " " .
4182                       format_search_author($co->{"${who}_email"}, $who,
4183                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4184                       "</td><td rowspan=\"2\">" .
4185                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4186                       "</td></tr>\n" .
4187                       "<tr>" .
4188                       "<td></td><td>" .
4189                       format_timestamp_html(\%wd) .
4190                       "</td>" .
4191                       "</tr>\n";
4192         }
4193 }
4194
4195 sub git_print_page_path {
4196         my $name = shift;
4197         my $type = shift;
4198         my $hb = shift;
4199
4200
4201         print "<div class=\"page_path\">";
4202         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4203                       -title => 'tree root'}, to_utf8("[$project]"));
4204         print " / ";
4205         if (defined $name) {
4206                 my @dirname = split '/', $name;
4207                 my $basename = pop @dirname;
4208                 my $fullname = '';
4209
4210                 foreach my $dir (@dirname) {
4211                         $fullname .= ($fullname ? '/' : '') . $dir;
4212                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4213                                                      hash_base=>$hb),
4214                                       -title => $fullname}, esc_path($dir));
4215                         print " / ";
4216                 }
4217                 if (defined $type && $type eq 'blob') {
4218                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4219                                                      hash_base=>$hb),
4220                                       -title => $name}, esc_path($basename));
4221                 } elsif (defined $type && $type eq 'tree') {
4222                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4223                                                      hash_base=>$hb),
4224                                       -title => $name}, esc_path($basename));
4225                         print " / ";
4226                 } else {
4227                         print esc_path($basename);
4228                 }
4229         }
4230         print "<br/></div>\n";
4231 }
4232
4233 sub git_print_log {
4234         my $log = shift;
4235         my %opts = @_;
4236
4237         if ($opts{'-remove_title'}) {
4238                 # remove title, i.e. first line of log
4239                 shift @$log;
4240         }
4241         # remove leading empty lines
4242         while (defined $log->[0] && $log->[0] eq "") {
4243                 shift @$log;
4244         }
4245
4246         # print log
4247         my $signoff = 0;
4248         my $empty = 0;
4249         foreach my $line (@$log) {
4250                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4251                         $signoff = 1;
4252                         $empty = 0;
4253                         if (! $opts{'-remove_signoff'}) {
4254                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4255                                 next;
4256                         } else {
4257                                 # remove signoff lines
4258                                 next;
4259                         }
4260                 } else {
4261                         $signoff = 0;
4262                 }
4263
4264                 # print only one empty line
4265                 # do not print empty line after signoff
4266                 if ($line eq "") {
4267                         next if ($empty || $signoff);
4268                         $empty = 1;
4269                 } else {
4270                         $empty = 0;
4271                 }
4272
4273                 print format_log_line_html($line) . "<br/>\n";
4274         }
4275
4276         if ($opts{'-final_empty_line'}) {
4277                 # end with single empty line
4278                 print "<br/>\n" unless $empty;
4279         }
4280 }
4281
4282 # return link target (what link points to)
4283 sub git_get_link_target {
4284         my $hash = shift;
4285         my $link_target;
4286
4287         # read link
4288         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4289                 or return;
4290         {
4291                 local $/ = undef;
4292                 $link_target = <$fd>;
4293         }
4294         close $fd
4295                 or return;
4296
4297         return $link_target;
4298 }
4299
4300 # given link target, and the directory (basedir) the link is in,
4301 # return target of link relative to top directory (top tree);
4302 # return undef if it is not possible (including absolute links).
4303 sub normalize_link_target {
4304         my ($link_target, $basedir) = @_;
4305
4306         # absolute symlinks (beginning with '/') cannot be normalized
4307         return if (substr($link_target, 0, 1) eq '/');
4308
4309         # normalize link target to path from top (root) tree (dir)
4310         my $path;
4311         if ($basedir) {
4312                 $path = $basedir . '/' . $link_target;
4313         } else {
4314                 # we are in top (root) tree (dir)
4315                 $path = $link_target;
4316         }
4317
4318         # remove //, /./, and /../
4319         my @path_parts;
4320         foreach my $part (split('/', $path)) {
4321                 # discard '.' and ''
4322                 next if (!$part || $part eq '.');
4323                 # handle '..'
4324                 if ($part eq '..') {
4325                         if (@path_parts) {
4326                                 pop @path_parts;
4327                         } else {
4328                                 # link leads outside repository (outside top dir)
4329                                 return;
4330                         }
4331                 } else {
4332                         push @path_parts, $part;
4333                 }
4334         }
4335         $path = join('/', @path_parts);
4336
4337         return $path;
4338 }
4339
4340 # print tree entry (row of git_tree), but without encompassing <tr> element
4341 sub git_print_tree_entry {
4342         my ($t, $basedir, $hash_base, $have_blame) = @_;
4343
4344         my %base_key = ();
4345         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4346
4347         # The format of a table row is: mode list link.  Where mode is
4348         # the mode of the entry, list is the name of the entry, an href,
4349         # and link is the action links of the entry.
4350
4351         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4352         if (exists $t->{'size'}) {
4353                 print "<td class=\"size\">$t->{'size'}</td>\n";
4354         }
4355         if ($t->{'type'} eq "blob") {
4356                 print "<td class=\"list\">" .
4357                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4358                                                file_name=>"$basedir$t->{'name'}", %base_key),
4359                                 -class => "list"}, esc_path($t->{'name'}));
4360                 if (S_ISLNK(oct $t->{'mode'})) {
4361                         my $link_target = git_get_link_target($t->{'hash'});
4362                         if ($link_target) {
4363                                 my $norm_target = normalize_link_target($link_target, $basedir);
4364                                 if (defined $norm_target) {
4365                                         print " -> " .
4366                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4367                                                                      file_name=>$norm_target),
4368                                                        -title => $norm_target}, esc_path($link_target));
4369                                 } else {
4370                                         print " -> " . esc_path($link_target);
4371                                 }
4372                         }
4373                 }
4374                 print "</td>\n";
4375                 print "<td class=\"link\">";
4376                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4377                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4378                               "blob");
4379                 if ($have_blame) {
4380                         print " | " .
4381                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4382                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4383                                       "blame");
4384                 }
4385                 if (defined $hash_base) {
4386                         print " | " .
4387                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4388                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4389                                       "history");
4390                 }
4391                 print " | " .
4392                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4393                                                file_name=>"$basedir$t->{'name'}")},
4394                                 "raw");
4395                 print "</td>\n";
4396
4397         } elsif ($t->{'type'} eq "tree") {
4398                 print "<td class=\"list\">";
4399                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4400                                              file_name=>"$basedir$t->{'name'}",
4401                                              %base_key)},
4402                               esc_path($t->{'name'}));
4403                 print "</td>\n";
4404                 print "<td class=\"link\">";
4405                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4406                                              file_name=>"$basedir$t->{'name'}",
4407                                              %base_key)},
4408                               "tree");
4409                 if (defined $hash_base) {
4410                         print " | " .
4411                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4412                                                      file_name=>"$basedir$t->{'name'}")},
4413                                       "history");
4414                 }
4415                 print "</td>\n";
4416         } else {
4417                 # unknown object: we can only present history for it
4418                 # (this includes 'commit' object, i.e. submodule support)
4419                 print "<td class=\"list\">" .
4420                       esc_path($t->{'name'}) .
4421                       "</td>\n";
4422                 print "<td class=\"link\">";
4423                 if (defined $hash_base) {
4424                         print $cgi->a({-href => href(action=>"history",
4425                                                      hash_base=>$hash_base,
4426                                                      file_name=>"$basedir$t->{'name'}")},
4427                                       "history");
4428                 }
4429                 print "</td>\n";
4430         }
4431 }
4432
4433 ## ......................................................................
4434 ## functions printing large fragments of HTML
4435
4436 # get pre-image filenames for merge (combined) diff
4437 sub fill_from_file_info {
4438         my ($diff, @parents) = @_;
4439
4440         $diff->{'from_file'} = [ ];
4441         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4442         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4443                 if ($diff->{'status'}[$i] eq 'R' ||
4444                     $diff->{'status'}[$i] eq 'C') {
4445                         $diff->{'from_file'}[$i] =
4446                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4447                 }
4448         }
4449
4450         return $diff;
4451 }
4452
4453 # is current raw difftree line of file deletion
4454 sub is_deleted {
4455         my $diffinfo = shift;
4456
4457         return $diffinfo->{'to_id'} eq ('0' x 40);
4458 }
4459
4460 # does patch correspond to [previous] difftree raw line
4461 # $diffinfo  - hashref of parsed raw diff format
4462 # $patchinfo - hashref of parsed patch diff format
4463 #              (the same keys as in $diffinfo)
4464 sub is_patch_split {
4465         my ($diffinfo, $patchinfo) = @_;
4466
4467         return defined $diffinfo && defined $patchinfo
4468                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4469 }
4470
4471
4472 sub git_difftree_body {
4473         my ($difftree, $hash, @parents) = @_;
4474         my ($parent) = $parents[0];
4475         my $have_blame = gitweb_check_feature('blame');
4476         print "<div class=\"list_head\">\n";
4477         if ($#{$difftree} > 10) {
4478                 print(($#{$difftree} + 1) . " files changed:\n");
4479         }
4480         print "</div>\n";
4481
4482         print "<table class=\"" .
4483               (@parents > 1 ? "combined " : "") .
4484               "diff_tree\">\n";
4485
4486         # header only for combined diff in 'commitdiff' view
4487         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4488         if ($has_header) {
4489                 # table header
4490                 print "<thead><tr>\n" .
4491                        "<th></th><th></th>\n"; # filename, patchN link
4492                 for (my $i = 0; $i < @parents; $i++) {
4493                         my $par = $parents[$i];
4494                         print "<th>" .
4495                               $cgi->a({-href => href(action=>"commitdiff",
4496                                                      hash=>$hash, hash_parent=>$par),
4497                                        -title => 'commitdiff to parent number ' .
4498                                                   ($i+1) . ': ' . substr($par,0,7)},
4499                                       $i+1) .
4500                               "&nbsp;</th>\n";
4501                 }
4502                 print "</tr></thead>\n<tbody>\n";
4503         }
4504
4505         my $alternate = 1;
4506         my $patchno = 0;
4507         foreach my $line (@{$difftree}) {
4508                 my $diff = parsed_difftree_line($line);
4509
4510                 if ($alternate) {
4511                         print "<tr class=\"dark\">\n";
4512                 } else {
4513                         print "<tr class=\"light\">\n";
4514                 }
4515                 $alternate ^= 1;
4516
4517                 if (exists $diff->{'nparents'}) { # combined diff
4518
4519                         fill_from_file_info($diff, @parents)
4520                                 unless exists $diff->{'from_file'};
4521
4522                         if (!is_deleted($diff)) {
4523                                 # file exists in the result (child) commit
4524                                 print "<td>" .
4525                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4526                                                              file_name=>$diff->{'to_file'},
4527                                                              hash_base=>$hash),
4528                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4529                                       "</td>\n";
4530                         } else {
4531                                 print "<td>" .
4532                                       esc_path($diff->{'to_file'}) .
4533                                       "</td>\n";
4534                         }
4535
4536                         if ($action eq 'commitdiff') {
4537                                 # link to patch
4538                                 $patchno++;
4539                                 print "<td class=\"link\">" .
4540                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4541                                               "patch") .
4542                                       " | " .
4543                                       "</td>\n";
4544                         }
4545
4546                         my $has_history = 0;
4547                         my $not_deleted = 0;
4548                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4549                                 my $hash_parent = $parents[$i];
4550                                 my $from_hash = $diff->{'from_id'}[$i];
4551                                 my $from_path = $diff->{'from_file'}[$i];
4552                                 my $status = $diff->{'status'}[$i];
4553
4554                                 $has_history ||= ($status ne 'A');
4555                                 $not_deleted ||= ($status ne 'D');
4556
4557                                 if ($status eq 'A') {
4558                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4559                                 } elsif ($status eq 'D') {
4560                                         print "<td class=\"link\">" .
4561                                               $cgi->a({-href => href(action=>"blob",
4562                                                                      hash_base=>$hash,
4563                                                                      hash=>$from_hash,
4564                                                                      file_name=>$from_path)},
4565                                                       "blob" . ($i+1)) .
4566                                               " | </td>\n";
4567                                 } else {
4568                                         if ($diff->{'to_id'} eq $from_hash) {
4569                                                 print "<td class=\"link nochange\">";
4570                                         } else {
4571                                                 print "<td class=\"link\">";
4572                                         }
4573                                         print $cgi->a({-href => href(action=>"blobdiff",
4574                                                                      hash=>$diff->{'to_id'},
4575                                                                      hash_parent=>$from_hash,
4576                                                                      hash_base=>$hash,
4577                                                                      hash_parent_base=>$hash_parent,
4578                                                                      file_name=>$diff->{'to_file'},
4579                                                                      file_parent=>$from_path)},
4580                                                       "diff" . ($i+1)) .
4581                                               " | </td>\n";
4582                                 }
4583                         }
4584
4585                         print "<td class=\"link\">";
4586                         if ($not_deleted) {
4587                                 print $cgi->a({-href => href(action=>"blob",
4588                                                              hash=>$diff->{'to_id'},
4589                                                              file_name=>$diff->{'to_file'},
4590                                                              hash_base=>$hash)},
4591                                               "blob");
4592                                 print " | " if ($has_history);
4593                         }
4594                         if ($has_history) {
4595                                 print $cgi->a({-href => href(action=>"history",
4596                                                              file_name=>$diff->{'to_file'},
4597                                                              hash_base=>$hash)},
4598                                               "history");
4599                         }
4600                         print "</td>\n";
4601
4602                         print "</tr>\n";
4603                         next; # instead of 'else' clause, to avoid extra indent
4604                 }
4605                 # else ordinary diff
4606
4607                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4608                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4609                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4610                         $to_mode_oct = oct $diff->{'to_mode'};
4611                         if (S_ISREG($to_mode_oct)) { # only for regular file
4612                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4613                         }
4614                         $to_file_type = file_type($diff->{'to_mode'});
4615                 }
4616                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4617                         $from_mode_oct = oct $diff->{'from_mode'};
4618                         if (S_ISREG($from_mode_oct)) { # only for regular file
4619                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4620                         }
4621                         $from_file_type = file_type($diff->{'from_mode'});
4622                 }
4623
4624                 if ($diff->{'status'} eq "A") { # created
4625                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4626                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4627                         $mode_chng   .= "]</span>";
4628                         print "<td>";
4629                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4630                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4631                                       -class => "list"}, esc_path($diff->{'file'}));
4632                         print "</td>\n";
4633                         print "<td>$mode_chng</td>\n";
4634                         print "<td class=\"link\">";
4635                         if ($action eq 'commitdiff') {
4636                                 # link to patch
4637                                 $patchno++;
4638                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4639                                               "patch") .
4640                                       " | ";
4641                         }
4642                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4643                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4644                                       "blob");
4645                         print "</td>\n";
4646
4647                 } elsif ($diff->{'status'} eq "D") { # deleted
4648                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4649                         print "<td>";
4650                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4651                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4652                                        -class => "list"}, esc_path($diff->{'file'}));
4653                         print "</td>\n";
4654                         print "<td>$mode_chng</td>\n";
4655                         print "<td class=\"link\">";
4656                         if ($action eq 'commitdiff') {
4657                                 # link to patch
4658                                 $patchno++;
4659                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4660                                               "patch") .
4661                                       " | ";
4662                         }
4663                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4664                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4665                                       "blob") . " | ";
4666                         if ($have_blame) {
4667                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4668                                                              file_name=>$diff->{'file'})},
4669                                               "blame") . " | ";
4670                         }
4671                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4672                                                      file_name=>$diff->{'file'})},
4673                                       "history");
4674                         print "</td>\n";
4675
4676                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4677                         my $mode_chnge = "";
4678                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4679                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4680                                 if ($from_file_type ne $to_file_type) {
4681                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4682                                 }
4683                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4684                                         if ($from_mode_str && $to_mode_str) {
4685                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4686                                         } elsif ($to_mode_str) {
4687                                                 $mode_chnge .= " mode: $to_mode_str";
4688                                         }
4689                                 }
4690                                 $mode_chnge .= "]</span>\n";
4691                         }
4692                         print "<td>";
4693                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4694                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4695                                       -class => "list"}, esc_path($diff->{'file'}));
4696                         print "</td>\n";
4697                         print "<td>$mode_chnge</td>\n";
4698                         print "<td class=\"link\">";
4699                         if ($action eq 'commitdiff') {
4700                                 # link to patch
4701                                 $patchno++;
4702                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4703                                               "patch") .
4704                                       " | ";
4705                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4706                                 # "commit" view and modified file (not onlu mode changed)
4707                                 print $cgi->a({-href => href(action=>"blobdiff",
4708                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4709                                                              hash_base=>$hash, hash_parent_base=>$parent,
4710                                                              file_name=>$diff->{'file'})},
4711                                               "diff") .
4712                                       " | ";
4713                         }
4714                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4715                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4716                                        "blob") . " | ";
4717                         if ($have_blame) {
4718                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4719                                                              file_name=>$diff->{'file'})},
4720                                               "blame") . " | ";
4721                         }
4722                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4723                                                      file_name=>$diff->{'file'})},
4724                                       "history");
4725                         print "</td>\n";
4726
4727                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4728                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4729                         my $nstatus = $status_name{$diff->{'status'}};
4730                         my $mode_chng = "";
4731                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4732                                 # mode also for directories, so we cannot use $to_mode_str
4733                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4734                         }
4735                         print "<td>" .
4736                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4737                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4738                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4739                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4740                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4741                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4742                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4743                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4744                               "<td class=\"link\">";
4745                         if ($action eq 'commitdiff') {
4746                                 # link to patch
4747                                 $patchno++;
4748                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4749                                               "patch") .
4750                                       " | ";
4751                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4752                                 # "commit" view and modified file (not only pure rename or copy)
4753                                 print $cgi->a({-href => href(action=>"blobdiff",
4754                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4755                                                              hash_base=>$hash, hash_parent_base=>$parent,
4756                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4757                                               "diff") .
4758                                       " | ";
4759                         }
4760                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4761                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4762                                       "blob") . " | ";
4763                         if ($have_blame) {
4764                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4765                                                              file_name=>$diff->{'to_file'})},
4766                                               "blame") . " | ";
4767                         }
4768                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4769                                                     file_name=>$diff->{'to_file'})},
4770                                       "history");
4771                         print "</td>\n";
4772
4773                 } # we should not encounter Unmerged (U) or Unknown (X) status
4774                 print "</tr>\n";
4775         }
4776         print "</tbody>" if $has_header;
4777         print "</table>\n";
4778 }
4779
4780 sub git_patchset_body {
4781         my ($fd, $difftree, $hash, @hash_parents) = @_;
4782         my ($hash_parent) = $hash_parents[0];
4783
4784         my $is_combined = (@hash_parents > 1);
4785         my $patch_idx = 0;
4786         my $patch_number = 0;
4787         my $patch_line;
4788         my $diffinfo;
4789         my $to_name;
4790         my (%from, %to);
4791
4792         print "<div class=\"patchset\">\n";
4793
4794         # skip to first patch
4795         while ($patch_line = <$fd>) {
4796                 chomp $patch_line;
4797
4798                 last if ($patch_line =~ m/^diff /);
4799         }
4800
4801  PATCH:
4802         while ($patch_line) {
4803
4804                 # parse "git diff" header line
4805                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4806                         # $1 is from_name, which we do not use
4807                         $to_name = unquote($2);
4808                         $to_name =~ s!^b/!!;
4809                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4810                         # $1 is 'cc' or 'combined', which we do not use
4811                         $to_name = unquote($2);
4812                 } else {
4813                         $to_name = undef;
4814                 }
4815
4816                 # check if current patch belong to current raw line
4817                 # and parse raw git-diff line if needed
4818                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4819                         # this is continuation of a split patch
4820                         print "<div class=\"patch cont\">\n";
4821                 } else {
4822                         # advance raw git-diff output if needed
4823                         $patch_idx++ if defined $diffinfo;
4824
4825                         # read and prepare patch information
4826                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4827
4828                         # compact combined diff output can have some patches skipped
4829                         # find which patch (using pathname of result) we are at now;
4830                         if ($is_combined) {
4831                                 while ($to_name ne $diffinfo->{'to_file'}) {
4832                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4833                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4834                                               "</div>\n";  # class="patch"
4835
4836                                         $patch_idx++;
4837                                         $patch_number++;
4838
4839                                         last if $patch_idx > $#$difftree;
4840                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4841                                 }
4842                         }
4843
4844                         # modifies %from, %to hashes
4845                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4846
4847                         # this is first patch for raw difftree line with $patch_idx index
4848                         # we index @$difftree array from 0, but number patches from 1
4849                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4850                 }
4851
4852                 # git diff header
4853                 #assert($patch_line =~ m/^diff /) if DEBUG;
4854                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4855                 $patch_number++;
4856                 # print "git diff" header
4857                 print format_git_diff_header_line($patch_line, $diffinfo,
4858                                                   \%from, \%to);
4859
4860                 # print extended diff header
4861                 print "<div class=\"diff extended_header\">\n";
4862         EXTENDED_HEADER:
4863                 while ($patch_line = <$fd>) {
4864                         chomp $patch_line;
4865
4866                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4867
4868                         print format_extended_diff_header_line($patch_line, $diffinfo,
4869                                                                \%from, \%to);
4870                 }
4871                 print "</div>\n"; # class="diff extended_header"
4872
4873                 # from-file/to-file diff header
4874                 if (! $patch_line) {
4875                         print "</div>\n"; # class="patch"
4876                         last PATCH;
4877                 }
4878                 next PATCH if ($patch_line =~ m/^diff /);
4879                 #assert($patch_line =~ m/^---/) if DEBUG;
4880
4881                 my $last_patch_line = $patch_line;
4882                 $patch_line = <$fd>;
4883                 chomp $patch_line;
4884                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4885
4886                 print format_diff_from_to_header($last_patch_line, $patch_line,
4887                                                  $diffinfo, \%from, \%to,
4888                                                  @hash_parents);
4889
4890                 # the patch itself
4891         LINE:
4892                 while ($patch_line = <$fd>) {
4893                         chomp $patch_line;
4894
4895                         next PATCH if ($patch_line =~ m/^diff /);
4896
4897                         print format_diff_line($patch_line, \%from, \%to);
4898                 }
4899
4900         } continue {
4901                 print "</div>\n"; # class="patch"
4902         }
4903
4904         # for compact combined (--cc) format, with chunk and patch simplification
4905         # the patchset might be empty, but there might be unprocessed raw lines
4906         for (++$patch_idx if $patch_number > 0;
4907              $patch_idx < @$difftree;
4908              ++$patch_idx) {
4909                 # read and prepare patch information
4910                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4911
4912                 # generate anchor for "patch" links in difftree / whatchanged part
4913                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4914                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4915                       "</div>\n";  # class="patch"
4916
4917                 $patch_number++;
4918         }
4919
4920         if ($patch_number == 0) {
4921                 if (@hash_parents > 1) {
4922                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4923                 } else {
4924                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4925                 }
4926         }
4927
4928         print "</div>\n"; # class="patchset"
4929 }
4930
4931 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4932
4933 # fills project list info (age, description, owner, category, forks)
4934 # for each project in the list, removing invalid projects from
4935 # returned list
4936 # NOTE: modifies $projlist, but does not remove entries from it
4937 sub fill_project_list_info {
4938         my $projlist = shift;
4939         my @projects;
4940
4941         my $show_ctags = gitweb_check_feature('ctags');
4942  PROJECT:
4943         foreach my $pr (@$projlist) {
4944                 my (@activity) = git_get_last_activity($pr->{'path'});
4945                 unless (@activity) {
4946                         next PROJECT;
4947                 }
4948                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4949                 if (!defined $pr->{'descr'}) {
4950                         my $descr = git_get_project_description($pr->{'path'}) || "";
4951                         $descr = to_utf8($descr);
4952                         $pr->{'descr_long'} = $descr;
4953                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4954                 }
4955                 if (!defined $pr->{'owner'}) {
4956                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4957                 }
4958                 if ($show_ctags) {
4959                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4960                 }
4961                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
4962                         my $cat = git_get_project_category($pr->{'path'}) ||
4963                                                            $project_list_default_category;
4964                         $pr->{'category'} = to_utf8($cat);
4965                 }
4966
4967                 push @projects, $pr;
4968         }
4969
4970         return @projects;
4971 }
4972
4973 sub sort_projects_list {
4974         my ($projlist, $order) = @_;
4975         my @projects;
4976
4977         my %order_info = (
4978                 project => { key => 'path', type => 'str' },
4979                 descr => { key => 'descr_long', type => 'str' },
4980                 owner => { key => 'owner', type => 'str' },
4981                 age => { key => 'age', type => 'num' }
4982         );
4983         my $oi = $order_info{$order};
4984         return @$projlist unless defined $oi;
4985         if ($oi->{'type'} eq 'str') {
4986                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
4987         } else {
4988                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
4989         }
4990
4991         return @projects;
4992 }
4993
4994 # returns a hash of categories, containing the list of project
4995 # belonging to each category
4996 sub build_projlist_by_category {
4997         my ($projlist, $from, $to) = @_;
4998         my %categories;
4999
5000         $from = 0 unless defined $from;
5001         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5002
5003         for (my $i = $from; $i <= $to; $i++) {
5004                 my $pr = $projlist->[$i];
5005                 push @{$categories{ $pr->{'category'} }}, $pr;
5006         }
5007
5008         return wantarray ? %categories : \%categories;
5009 }
5010
5011 # print 'sort by' <th> element, generating 'sort by $name' replay link
5012 # if that order is not selected
5013 sub print_sort_th {
5014         print format_sort_th(@_);
5015 }
5016
5017 sub format_sort_th {
5018         my ($name, $order, $header) = @_;
5019         my $sort_th = "";
5020         $header ||= ucfirst($name);
5021
5022         if ($order eq $name) {
5023                 $sort_th .= "<th>$header</th>\n";
5024         } else {
5025                 $sort_th .= "<th>" .
5026                             $cgi->a({-href => href(-replay=>1, order=>$name),
5027                                      -class => "header"}, $header) .
5028                             "</th>\n";
5029         }
5030
5031         return $sort_th;
5032 }
5033
5034 sub git_project_list_rows {
5035         my ($projlist, $from, $to, $check_forks) = @_;
5036
5037         $from = 0 unless defined $from;
5038         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5039
5040         my $alternate = 1;
5041         for (my $i = $from; $i <= $to; $i++) {
5042                 my $pr = $projlist->[$i];
5043
5044                 if ($alternate) {
5045                         print "<tr class=\"dark\">\n";
5046                 } else {
5047                         print "<tr class=\"light\">\n";
5048                 }
5049                 $alternate ^= 1;
5050
5051                 if ($check_forks) {
5052                         print "<td>";
5053                         if ($pr->{'forks'}) {
5054                                 my $nforks = scalar @{$pr->{'forks'}};
5055                                 if ($nforks > 0) {
5056                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5057                                                        -title => "$nforks forks"}, "+");
5058                                 } else {
5059                                         print $cgi->span({-title => "$nforks forks"}, "+");
5060                                 }
5061                         }
5062                         print "</td>\n";
5063                 }
5064                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5065                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5066                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5067                                         -class => "list", -title => $pr->{'descr_long'}},
5068                                         esc_html($pr->{'descr'})) . "</td>\n" .
5069                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5070                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5071                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5072                       "<td class=\"link\">" .
5073                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5074                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5075                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5076                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5077                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5078                       "</td>\n" .
5079                       "</tr>\n";
5080         }
5081 }
5082
5083 sub git_project_list_body {
5084         # actually uses global variable $project
5085         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5086         my @projects = @$projlist;
5087
5088         my $check_forks = gitweb_check_feature('forks');
5089         my $show_ctags  = gitweb_check_feature('ctags');
5090         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5091         $check_forks = undef
5092                 if ($tagfilter || $searchtext);
5093
5094         # filtering out forks before filling info allows to do less work
5095         @projects = filter_forks_from_projects_list(\@projects)
5096                 if ($check_forks);
5097         @projects = fill_project_list_info(\@projects);
5098         # searching projects require filling to be run before it
5099         @projects = search_projects_list(\@projects,
5100                                          'searchtext' => $searchtext,
5101                                          'tagfilter'  => $tagfilter)
5102                 if ($tagfilter || $searchtext);
5103
5104         $order ||= $default_projects_order;
5105         $from = 0 unless defined $from;
5106         $to = $#projects if (!defined $to || $#projects < $to);
5107
5108         # short circuit
5109         if ($from > $to) {
5110                 print "<center>\n".
5111                       "<b>No such projects found</b><br />\n".
5112                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5113                       "</center>\n<br />\n";
5114                 return;
5115         }
5116
5117         @projects = sort_projects_list(\@projects, $order);
5118
5119         if ($show_ctags) {
5120                 my $ctags = git_gather_all_ctags(\@projects);
5121                 my $cloud = git_populate_project_tagcloud($ctags);
5122                 print git_show_project_tagcloud($cloud, 64);
5123         }
5124
5125         print "<table class=\"project_list\">\n";
5126         unless ($no_header) {
5127                 print "<tr>\n";
5128                 if ($check_forks) {
5129                         print "<th></th>\n";
5130                 }
5131                 print_sort_th('project', $order, 'Project');
5132                 print_sort_th('descr', $order, 'Description');
5133                 print_sort_th('owner', $order, 'Owner');
5134                 print_sort_th('age', $order, 'Last Change');
5135                 print "<th></th>\n" . # for links
5136                       "</tr>\n";
5137         }
5138
5139         if ($projects_list_group_categories) {
5140                 # only display categories with projects in the $from-$to window
5141                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5142                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5143                 foreach my $cat (sort keys %categories) {
5144                         unless ($cat eq "") {
5145                                 print "<tr>\n";
5146                                 if ($check_forks) {
5147                                         print "<td></td>\n";
5148                                 }
5149                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5150                                 print "</tr>\n";
5151                         }
5152
5153                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5154                 }
5155         } else {
5156                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5157         }
5158
5159         if (defined $extra) {
5160                 print "<tr>\n";
5161                 if ($check_forks) {
5162                         print "<td></td>\n";
5163                 }
5164                 print "<td colspan=\"5\">$extra</td>\n" .
5165                       "</tr>\n";
5166         }
5167         print "</table>\n";
5168 }
5169
5170 sub git_log_body {
5171         # uses global variable $project
5172         my ($commitlist, $from, $to, $refs, $extra) = @_;
5173
5174         $from = 0 unless defined $from;
5175         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5176
5177         for (my $i = 0; $i <= $to; $i++) {
5178                 my %co = %{$commitlist->[$i]};
5179                 next if !%co;
5180                 my $commit = $co{'id'};
5181                 my $ref = format_ref_marker($refs, $commit);
5182                 git_print_header_div('commit',
5183                                "<span class=\"age\">$co{'age_string'}</span>" .
5184                                esc_html($co{'title'}) . $ref,
5185                                $commit);
5186                 print "<div class=\"title_text\">\n" .
5187                       "<div class=\"log_link\">\n" .
5188                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5189                       " | " .
5190                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5191                       " | " .
5192                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5193                       "<br/>\n" .
5194                       "</div>\n";
5195                       git_print_authorship(\%co, -tag => 'span');
5196                       print "<br/>\n</div>\n";
5197
5198                 print "<div class=\"log_body\">\n";
5199                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5200                 print "</div>\n";
5201         }
5202         if ($extra) {
5203                 print "<div class=\"page_nav\">\n";
5204                 print "$extra\n";
5205                 print "</div>\n";
5206         }
5207 }
5208
5209 sub git_shortlog_body {
5210         # uses global variable $project
5211         my ($commitlist, $from, $to, $refs, $extra) = @_;
5212
5213         $from = 0 unless defined $from;
5214         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5215
5216         print "<table class=\"shortlog\">\n";
5217         my $alternate = 1;
5218         for (my $i = $from; $i <= $to; $i++) {
5219                 my %co = %{$commitlist->[$i]};
5220                 my $commit = $co{'id'};
5221                 my $ref = format_ref_marker($refs, $commit);
5222                 if ($alternate) {
5223                         print "<tr class=\"dark\">\n";
5224                 } else {
5225                         print "<tr class=\"light\">\n";
5226                 }
5227                 $alternate ^= 1;
5228                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5229                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5230                       format_author_html('td', \%co, 10) . "<td>";
5231                 print format_subject_html($co{'title'}, $co{'title_short'},
5232                                           href(action=>"commit", hash=>$commit), $ref);
5233                 print "</td>\n" .
5234                       "<td class=\"link\">" .
5235                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5236                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5237                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5238                 my $snapshot_links = format_snapshot_links($commit);
5239                 if (defined $snapshot_links) {
5240                         print " | " . $snapshot_links;
5241                 }
5242                 print "</td>\n" .
5243                       "</tr>\n";
5244         }
5245         if (defined $extra) {
5246                 print "<tr>\n" .
5247                       "<td colspan=\"4\">$extra</td>\n" .
5248                       "</tr>\n";
5249         }
5250         print "</table>\n";
5251 }
5252
5253 sub git_history_body {
5254         # Warning: assumes constant type (blob or tree) during history
5255         my ($commitlist, $from, $to, $refs, $extra,
5256             $file_name, $file_hash, $ftype) = @_;
5257
5258         $from = 0 unless defined $from;
5259         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5260
5261         print "<table class=\"history\">\n";
5262         my $alternate = 1;
5263         for (my $i = $from; $i <= $to; $i++) {
5264                 my %co = %{$commitlist->[$i]};
5265                 if (!%co) {
5266                         next;
5267                 }
5268                 my $commit = $co{'id'};
5269
5270                 my $ref = format_ref_marker($refs, $commit);
5271
5272                 if ($alternate) {
5273                         print "<tr class=\"dark\">\n";
5274                 } else {
5275                         print "<tr class=\"light\">\n";
5276                 }
5277                 $alternate ^= 1;
5278                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5279         # shortlog:   format_author_html('td', \%co, 10)
5280                       format_author_html('td', \%co, 15, 3) . "<td>";
5281                 # originally git_history used chop_str($co{'title'}, 50)
5282                 print format_subject_html($co{'title'}, $co{'title_short'},
5283                                           href(action=>"commit", hash=>$commit), $ref);
5284                 print "</td>\n" .
5285                       "<td class=\"link\">" .
5286                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5287                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5288
5289                 if ($ftype eq 'blob') {
5290                         my $blob_current = $file_hash;
5291                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5292                         if (defined $blob_current && defined $blob_parent &&
5293                                         $blob_current ne $blob_parent) {
5294                                 print " | " .
5295                                         $cgi->a({-href => href(action=>"blobdiff",
5296                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5297                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5298                                                                file_name=>$file_name)},
5299                                                 "diff to current");
5300                         }
5301                 }
5302                 print "</td>\n" .
5303                       "</tr>\n";
5304         }
5305         if (defined $extra) {
5306                 print "<tr>\n" .
5307                       "<td colspan=\"4\">$extra</td>\n" .
5308                       "</tr>\n";
5309         }
5310         print "</table>\n";
5311 }
5312
5313 sub git_tags_body {
5314         # uses global variable $project
5315         my ($taglist, $from, $to, $extra) = @_;
5316         $from = 0 unless defined $from;
5317         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5318
5319         print "<table class=\"tags\">\n";
5320         my $alternate = 1;
5321         for (my $i = $from; $i <= $to; $i++) {
5322                 my $entry = $taglist->[$i];
5323                 my %tag = %$entry;
5324                 my $comment = $tag{'subject'};
5325                 my $comment_short;
5326                 if (defined $comment) {
5327                         $comment_short = chop_str($comment, 30, 5);
5328                 }
5329                 if ($alternate) {
5330                         print "<tr class=\"dark\">\n";
5331                 } else {
5332                         print "<tr class=\"light\">\n";
5333                 }
5334                 $alternate ^= 1;
5335                 if (defined $tag{'age'}) {
5336                         print "<td><i>$tag{'age'}</i></td>\n";
5337                 } else {
5338                         print "<td></td>\n";
5339                 }
5340                 print "<td>" .
5341                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5342                                -class => "list name"}, esc_html($tag{'name'})) .
5343                       "</td>\n" .
5344                       "<td>";
5345                 if (defined $comment) {
5346                         print format_subject_html($comment, $comment_short,
5347                                                   href(action=>"tag", hash=>$tag{'id'}));
5348                 }
5349                 print "</td>\n" .
5350                       "<td class=\"selflink\">";
5351                 if ($tag{'type'} eq "tag") {
5352                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5353                 } else {
5354                         print "&nbsp;";
5355                 }
5356                 print "</td>\n" .
5357                       "<td class=\"link\">" . " | " .
5358                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5359                 if ($tag{'reftype'} eq "commit") {
5360                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5361                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5362                 } elsif ($tag{'reftype'} eq "blob") {
5363                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5364                 }
5365                 print "</td>\n" .
5366                       "</tr>";
5367         }
5368         if (defined $extra) {
5369                 print "<tr>\n" .
5370                       "<td colspan=\"5\">$extra</td>\n" .
5371                       "</tr>\n";
5372         }
5373         print "</table>\n";
5374 }
5375
5376 sub git_heads_body {
5377         # uses global variable $project
5378         my ($headlist, $head, $from, $to, $extra) = @_;
5379         $from = 0 unless defined $from;
5380         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5381
5382         print "<table class=\"heads\">\n";
5383         my $alternate = 1;
5384         for (my $i = $from; $i <= $to; $i++) {
5385                 my $entry = $headlist->[$i];
5386                 my %ref = %$entry;
5387                 my $curr = $ref{'id'} eq $head;
5388                 if ($alternate) {
5389                         print "<tr class=\"dark\">\n";
5390                 } else {
5391                         print "<tr class=\"light\">\n";
5392                 }
5393                 $alternate ^= 1;
5394                 print "<td><i>$ref{'age'}</i></td>\n" .
5395                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5396                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5397                                -class => "list name"},esc_html($ref{'name'})) .
5398                       "</td>\n" .
5399                       "<td class=\"link\">" .
5400                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5401                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5402                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5403                       "</td>\n" .
5404                       "</tr>";
5405         }
5406         if (defined $extra) {
5407                 print "<tr>\n" .
5408                       "<td colspan=\"3\">$extra</td>\n" .
5409                       "</tr>\n";
5410         }
5411         print "</table>\n";
5412 }
5413
5414 # Display a single remote block
5415 sub git_remote_block {
5416         my ($remote, $rdata, $limit, $head) = @_;
5417
5418         my $heads = $rdata->{'heads'};
5419         my $fetch = $rdata->{'fetch'};
5420         my $push = $rdata->{'push'};
5421
5422         my $urls_table = "<table class=\"projects_list\">\n" ;
5423
5424         if (defined $fetch) {
5425                 if ($fetch eq $push) {
5426                         $urls_table .= format_repo_url("URL", $fetch);
5427                 } else {
5428                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5429                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5430                 }
5431         } elsif (defined $push) {
5432                 $urls_table .= format_repo_url("Push URL", $push);
5433         } else {
5434                 $urls_table .= format_repo_url("", "No remote URL");
5435         }
5436
5437         $urls_table .= "</table>\n";
5438
5439         my $dots;
5440         if (defined $limit && $limit < @$heads) {
5441                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5442         }
5443
5444         print $urls_table;
5445         git_heads_body($heads, $head, 0, $limit, $dots);
5446 }
5447
5448 # Display a list of remote names with the respective fetch and push URLs
5449 sub git_remotes_list {
5450         my ($remotedata, $limit) = @_;
5451         print "<table class=\"heads\">\n";
5452         my $alternate = 1;
5453         my @remotes = sort keys %$remotedata;
5454
5455         my $limited = $limit && $limit < @remotes;
5456
5457         $#remotes = $limit - 1 if $limited;
5458
5459         while (my $remote = shift @remotes) {
5460                 my $rdata = $remotedata->{$remote};
5461                 my $fetch = $rdata->{'fetch'};
5462                 my $push = $rdata->{'push'};
5463                 if ($alternate) {
5464                         print "<tr class=\"dark\">\n";
5465                 } else {
5466                         print "<tr class=\"light\">\n";
5467                 }
5468                 $alternate ^= 1;
5469                 print "<td>" .
5470                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5471                                -class=> "list name"},esc_html($remote)) .
5472                       "</td>";
5473                 print "<td class=\"link\">" .
5474                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5475                       " | " .
5476                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5477                       "</td>";
5478
5479                 print "</tr>\n";
5480         }
5481
5482         if ($limited) {
5483                 print "<tr>\n" .
5484                       "<td colspan=\"3\">" .
5485                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5486                       "</td>\n" . "</tr>\n";
5487         }
5488
5489         print "</table>";
5490 }
5491
5492 # Display remote heads grouped by remote, unless there are too many
5493 # remotes, in which case we only display the remote names
5494 sub git_remotes_body {
5495         my ($remotedata, $limit, $head) = @_;
5496         if ($limit and $limit < keys %$remotedata) {
5497                 git_remotes_list($remotedata, $limit);
5498         } else {
5499                 fill_remote_heads($remotedata);
5500                 while (my ($remote, $rdata) = each %$remotedata) {
5501                         git_print_section({-class=>"remote", -id=>$remote},
5502                                 ["remotes", $remote, $remote], sub {
5503                                         git_remote_block($remote, $rdata, $limit, $head);
5504                                 });
5505                 }
5506         }
5507 }
5508
5509 sub git_search_grep_body {
5510         my ($commitlist, $from, $to, $extra) = @_;
5511         $from = 0 unless defined $from;
5512         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5513
5514         print "<table class=\"commit_search\">\n";
5515         my $alternate = 1;
5516         for (my $i = $from; $i <= $to; $i++) {
5517                 my %co = %{$commitlist->[$i]};
5518                 if (!%co) {
5519                         next;
5520                 }
5521                 my $commit = $co{'id'};
5522                 if ($alternate) {
5523                         print "<tr class=\"dark\">\n";
5524                 } else {
5525                         print "<tr class=\"light\">\n";
5526                 }
5527                 $alternate ^= 1;
5528                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5529                       format_author_html('td', \%co, 15, 5) .
5530                       "<td>" .
5531                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5532                                -class => "list subject"},
5533                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5534                 my $comment = $co{'comment'};
5535                 foreach my $line (@$comment) {
5536                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5537                                 my ($lead, $match, $trail) = ($1, $2, $3);
5538                                 $match = chop_str($match, 70, 5, 'center');
5539                                 my $contextlen = int((80 - length($match))/2);
5540                                 $contextlen = 30 if ($contextlen > 30);
5541                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5542                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5543
5544                                 $lead  = esc_html($lead);
5545                                 $match = esc_html($match);
5546                                 $trail = esc_html($trail);
5547
5548                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5549                         }
5550                 }
5551                 print "</td>\n" .
5552                       "<td class=\"link\">" .
5553                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5554                       " | " .
5555                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5556                       " | " .
5557                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5558                 print "</td>\n" .
5559                       "</tr>\n";
5560         }
5561         if (defined $extra) {
5562                 print "<tr>\n" .
5563                       "<td colspan=\"3\">$extra</td>\n" .
5564                       "</tr>\n";
5565         }
5566         print "</table>\n";
5567 }
5568
5569 ## ======================================================================
5570 ## ======================================================================
5571 ## actions
5572
5573 sub git_project_list {
5574         my $order = $input_params{'order'};
5575         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5576                 die_error(400, "Unknown order parameter");
5577         }
5578
5579         my @list = git_get_projects_list();
5580         if (!@list) {
5581                 die_error(404, "No projects found");
5582         }
5583
5584         git_header_html();
5585         if (defined $home_text && -f $home_text) {
5586                 print "<div class=\"index_include\">\n";
5587                 insert_file($home_text);
5588                 print "</div>\n";
5589         }
5590         print $cgi->startform(-method => "get") .
5591               "<p class=\"projsearch\">Search:\n" .
5592               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5593               "</p>" .
5594               $cgi->end_form() . "\n";
5595         git_project_list_body(\@list, $order);
5596         git_footer_html();
5597 }
5598
5599 sub git_forks {
5600         my $order = $input_params{'order'};
5601         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5602                 die_error(400, "Unknown order parameter");
5603         }
5604
5605         my @list = git_get_projects_list($project);
5606         if (!@list) {
5607                 die_error(404, "No forks found");
5608         }
5609
5610         git_header_html();
5611         git_print_page_nav('','');
5612         git_print_header_div('summary', "$project forks");
5613         git_project_list_body(\@list, $order);
5614         git_footer_html();
5615 }
5616
5617 sub git_project_index {
5618         my @projects = git_get_projects_list();
5619         if (!@projects) {
5620                 die_error(404, "No projects found");
5621         }
5622
5623         print $cgi->header(
5624                 -type => 'text/plain',
5625                 -charset => 'utf-8',
5626                 -content_disposition => 'inline; filename="index.aux"');
5627
5628         foreach my $pr (@projects) {
5629                 if (!exists $pr->{'owner'}) {
5630                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5631                 }
5632
5633                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5634                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5635                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5636                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5637                 $path  =~ s/ /\+/g;
5638                 $owner =~ s/ /\+/g;
5639
5640                 print "$path $owner\n";
5641         }
5642 }
5643
5644 sub git_summary {
5645         my $descr = git_get_project_description($project) || "none";
5646         my %co = parse_commit("HEAD");
5647         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5648         my $head = $co{'id'};
5649         my $remote_heads = gitweb_check_feature('remote_heads');
5650
5651         my $owner = git_get_project_owner($project);
5652
5653         my $refs = git_get_references();
5654         # These get_*_list functions return one more to allow us to see if
5655         # there are more ...
5656         my @taglist  = git_get_tags_list(16);
5657         my @headlist = git_get_heads_list(16);
5658         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5659         my @forklist;
5660         my $check_forks = gitweb_check_feature('forks');
5661
5662         if ($check_forks) {
5663                 # find forks of a project
5664                 @forklist = git_get_projects_list($project);
5665                 # filter out forks of forks
5666                 @forklist = filter_forks_from_projects_list(\@forklist)
5667                         if (@forklist);
5668         }
5669
5670         git_header_html();
5671         git_print_page_nav('summary','', $head);
5672
5673         print "<div class=\"title\">&nbsp;</div>\n";
5674         print "<table class=\"projects_list\">\n" .
5675               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5676               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5677         if (defined $cd{'rfc2822'}) {
5678                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
5679                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
5680         }
5681
5682         # use per project git URL list in $projectroot/$project/cloneurl
5683         # or make project git URL from git base URL and project name
5684         my $url_tag = "URL";
5685         my @url_list = git_get_project_url_list($project);
5686         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5687         foreach my $git_url (@url_list) {
5688                 next unless $git_url;
5689                 print format_repo_url($url_tag, $git_url);
5690                 $url_tag = "";
5691         }
5692
5693         # Tag cloud
5694         my $show_ctags = gitweb_check_feature('ctags');
5695         if ($show_ctags) {
5696                 my $ctags = git_get_project_ctags($project);
5697                 if (%$ctags) {
5698                         # without ability to add tags, don't show if there are none
5699                         my $cloud = git_populate_project_tagcloud($ctags);
5700                         print "<tr id=\"metadata_ctags\">" .
5701                               "<td>content tags</td>" .
5702                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
5703                               "</tr>\n";
5704                 }
5705         }
5706
5707         print "</table>\n";
5708
5709         # If XSS prevention is on, we don't include README.html.
5710         # TODO: Allow a readme in some safe format.
5711         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5712                 print "<div class=\"title\">readme</div>\n" .
5713                       "<div class=\"readme\">\n";
5714                 insert_file("$projectroot/$project/README.html");
5715                 print "\n</div>\n"; # class="readme"
5716         }
5717
5718         # we need to request one more than 16 (0..15) to check if
5719         # those 16 are all
5720         my @commitlist = $head ? parse_commits($head, 17) : ();
5721         if (@commitlist) {
5722                 git_print_header_div('shortlog');
5723                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5724                                   $#commitlist <=  15 ? undef :
5725                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5726         }
5727
5728         if (@taglist) {
5729                 git_print_header_div('tags');
5730                 git_tags_body(\@taglist, 0, 15,
5731                               $#taglist <=  15 ? undef :
5732                               $cgi->a({-href => href(action=>"tags")}, "..."));
5733         }
5734
5735         if (@headlist) {
5736                 git_print_header_div('heads');
5737                 git_heads_body(\@headlist, $head, 0, 15,
5738                                $#headlist <= 15 ? undef :
5739                                $cgi->a({-href => href(action=>"heads")}, "..."));
5740         }
5741
5742         if (%remotedata) {
5743                 git_print_header_div('remotes');
5744                 git_remotes_body(\%remotedata, 15, $head);
5745         }
5746
5747         if (@forklist) {
5748                 git_print_header_div('forks');
5749                 git_project_list_body(\@forklist, 'age', 0, 15,
5750                                       $#forklist <= 15 ? undef :
5751                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5752                                       'no_header');
5753         }
5754
5755         git_footer_html();
5756 }
5757
5758 sub git_tag {
5759         my %tag = parse_tag($hash);
5760
5761         if (! %tag) {
5762                 die_error(404, "Unknown tag object");
5763         }
5764
5765         my $head = git_get_head_hash($project);
5766         git_header_html();
5767         git_print_page_nav('','', $head,undef,$head);
5768         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5769         print "<div class=\"title_text\">\n" .
5770               "<table class=\"object_header\">\n" .
5771               "<tr>\n" .
5772               "<td>object</td>\n" .
5773               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5774                                $tag{'object'}) . "</td>\n" .
5775               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5776                                               $tag{'type'}) . "</td>\n" .
5777               "</tr>\n";
5778         if (defined($tag{'author'})) {
5779                 git_print_authorship_rows(\%tag, 'author');
5780         }
5781         print "</table>\n\n" .
5782               "</div>\n";
5783         print "<div class=\"page_body\">";
5784         my $comment = $tag{'comment'};
5785         foreach my $line (@$comment) {
5786                 chomp $line;
5787                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5788         }
5789         print "</div>\n";
5790         git_footer_html();
5791 }
5792
5793 sub git_blame_common {
5794         my $format = shift || 'porcelain';
5795         if ($format eq 'porcelain' && $cgi->param('js')) {
5796                 $format = 'incremental';
5797                 $action = 'blame_incremental'; # for page title etc
5798         }
5799
5800         # permissions
5801         gitweb_check_feature('blame')
5802                 or die_error(403, "Blame view not allowed");
5803
5804         # error checking
5805         die_error(400, "No file name given") unless $file_name;
5806         $hash_base ||= git_get_head_hash($project);
5807         die_error(404, "Couldn't find base commit") unless $hash_base;
5808         my %co = parse_commit($hash_base)
5809                 or die_error(404, "Commit not found");
5810         my $ftype = "blob";
5811         if (!defined $hash) {
5812                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5813                         or die_error(404, "Error looking up file");
5814         } else {
5815                 $ftype = git_get_type($hash);
5816                 if ($ftype !~ "blob") {
5817                         die_error(400, "Object is not a blob");
5818                 }
5819         }
5820
5821         my $fd;
5822         if ($format eq 'incremental') {
5823                 # get file contents (as base)
5824                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5825                         or die_error(500, "Open git-cat-file failed");
5826         } elsif ($format eq 'data') {
5827                 # run git-blame --incremental
5828                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5829                         $hash_base, "--", $file_name
5830                         or die_error(500, "Open git-blame --incremental failed");
5831         } else {
5832                 # run git-blame --porcelain
5833                 open $fd, "-|", git_cmd(), "blame", '-p',
5834                         $hash_base, '--', $file_name
5835                         or die_error(500, "Open git-blame --porcelain failed");
5836         }
5837
5838         # incremental blame data returns early
5839         if ($format eq 'data') {
5840                 print $cgi->header(
5841                         -type=>"text/plain", -charset => "utf-8",
5842                         -status=> "200 OK");
5843                 local $| = 1; # output autoflush
5844                 print while <$fd>;
5845                 close $fd
5846                         or print "ERROR $!\n";
5847
5848                 print 'END';
5849                 if (defined $t0 && gitweb_check_feature('timed')) {
5850                         print ' '.
5851                               tv_interval($t0, [ gettimeofday() ]).
5852                               ' '.$number_of_git_cmds;
5853                 }
5854                 print "\n";
5855
5856                 return;
5857         }
5858
5859         # page header
5860         git_header_html();
5861         my $formats_nav =
5862                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5863                         "blob") .
5864                 " | ";
5865         if ($format eq 'incremental') {
5866                 $formats_nav .=
5867                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5868                                 "blame") . " (non-incremental)";
5869         } else {
5870                 $formats_nav .=
5871                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5872                                 "blame") . " (incremental)";
5873         }
5874         $formats_nav .=
5875                 " | " .
5876                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5877                         "history") .
5878                 " | " .
5879                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5880                         "HEAD");
5881         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5882         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5883         git_print_page_path($file_name, $ftype, $hash_base);
5884
5885         # page body
5886         if ($format eq 'incremental') {
5887                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5888                       "This page requires JavaScript to run.\n Use ".
5889                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5890                               'this page').
5891                       " instead.\n".
5892                       "</b></center></div>\n</noscript>\n";
5893
5894                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5895         }
5896
5897         print qq!<div class="page_body">\n!;
5898         print qq!<div id="progress_info">... / ...</div>\n!
5899                 if ($format eq 'incremental');
5900         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5901               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5902               qq!<thead>\n!.
5903               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5904               qq!</thead>\n!.
5905               qq!<tbody>\n!;
5906
5907         my @rev_color = qw(light dark);
5908         my $num_colors = scalar(@rev_color);
5909         my $current_color = 0;
5910
5911         if ($format eq 'incremental') {
5912                 my $color_class = $rev_color[$current_color];
5913
5914                 #contents of a file
5915                 my $linenr = 0;
5916         LINE:
5917                 while (my $line = <$fd>) {
5918                         chomp $line;
5919                         $linenr++;
5920
5921                         print qq!<tr id="l$linenr" class="$color_class">!.
5922                               qq!<td class="sha1"><a href=""> </a></td>!.
5923                               qq!<td class="linenr">!.
5924                               qq!<a class="linenr" href="">$linenr</a></td>!;
5925                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5926                         print qq!</tr>\n!;
5927                 }
5928
5929         } else { # porcelain, i.e. ordinary blame
5930                 my %metainfo = (); # saves information about commits
5931
5932                 # blame data
5933         LINE:
5934                 while (my $line = <$fd>) {
5935                         chomp $line;
5936                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5937                         # no <lines in group> for subsequent lines in group of lines
5938                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5939                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5940                         if (!exists $metainfo{$full_rev}) {
5941                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5942                         }
5943                         my $meta = $metainfo{$full_rev};
5944                         my $data;
5945                         while ($data = <$fd>) {
5946                                 chomp $data;
5947                                 last if ($data =~ s/^\t//); # contents of line
5948                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5949                                         $meta->{$1} = $2 unless exists $meta->{$1};
5950                                 }
5951                                 if ($data =~ /^previous /) {
5952                                         $meta->{'nprevious'}++;
5953                                 }
5954                         }
5955                         my $short_rev = substr($full_rev, 0, 8);
5956                         my $author = $meta->{'author'};
5957                         my %date =
5958                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5959                         my $date = $date{'iso-tz'};
5960                         if ($group_size) {
5961                                 $current_color = ($current_color + 1) % $num_colors;
5962                         }
5963                         my $tr_class = $rev_color[$current_color];
5964                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5965                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5966                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5967                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5968                         if ($group_size) {
5969                                 print "<td class=\"sha1\"";
5970                                 print " title=\"". esc_html($author) . ", $date\"";
5971                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5972                                 print ">";
5973                                 print $cgi->a({-href => href(action=>"commit",
5974                                                              hash=>$full_rev,
5975                                                              file_name=>$file_name)},
5976                                               esc_html($short_rev));
5977                                 if ($group_size >= 2) {
5978                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5979                                         if (@author_initials) {
5980                                                 print "<br />" .
5981                                                       esc_html(join('', @author_initials));
5982                                                 #           or join('.', ...)
5983                                         }
5984                                 }
5985                                 print "</td>\n";
5986                         }
5987                         # 'previous' <sha1 of parent commit> <filename at commit>
5988                         if (exists $meta->{'previous'} &&
5989                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5990                                 $meta->{'parent'} = $1;
5991                                 $meta->{'file_parent'} = unquote($2);
5992                         }
5993                         my $linenr_commit =
5994                                 exists($meta->{'parent'}) ?
5995                                 $meta->{'parent'} : $full_rev;
5996                         my $linenr_filename =
5997                                 exists($meta->{'file_parent'}) ?
5998                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5999                         my $blamed = href(action => 'blame',
6000                                           file_name => $linenr_filename,
6001                                           hash_base => $linenr_commit);
6002                         print "<td class=\"linenr\">";
6003                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6004                                         -class => "linenr" },
6005                                       esc_html($lineno));
6006                         print "</td>";
6007                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6008                         print "</tr>\n";
6009                 } # end while
6010
6011         }
6012
6013         # footer
6014         print "</tbody>\n".
6015               "</table>\n"; # class="blame"
6016         print "</div>\n";   # class="blame_body"
6017         close $fd
6018                 or print "Reading blob failed\n";
6019
6020         git_footer_html();
6021 }
6022
6023 sub git_blame {
6024         git_blame_common();
6025 }
6026
6027 sub git_blame_incremental {
6028         git_blame_common('incremental');
6029 }
6030
6031 sub git_blame_data {
6032         git_blame_common('data');
6033 }
6034
6035 sub git_tags {
6036         my $head = git_get_head_hash($project);
6037         git_header_html();
6038         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6039         git_print_header_div('summary', $project);
6040
6041         my @tagslist = git_get_tags_list();
6042         if (@tagslist) {
6043                 git_tags_body(\@tagslist);
6044         }
6045         git_footer_html();
6046 }
6047
6048 sub git_heads {
6049         my $head = git_get_head_hash($project);
6050         git_header_html();
6051         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6052         git_print_header_div('summary', $project);
6053
6054         my @headslist = git_get_heads_list();
6055         if (@headslist) {
6056                 git_heads_body(\@headslist, $head);
6057         }
6058         git_footer_html();
6059 }
6060
6061 # used both for single remote view and for list of all the remotes
6062 sub git_remotes {
6063         gitweb_check_feature('remote_heads')
6064                 or die_error(403, "Remote heads view is disabled");
6065
6066         my $head = git_get_head_hash($project);
6067         my $remote = $input_params{'hash'};
6068
6069         my $remotedata = git_get_remotes_list($remote);
6070         die_error(500, "Unable to get remote information") unless defined $remotedata;
6071
6072         unless (%$remotedata) {
6073                 die_error(404, defined $remote ?
6074                         "Remote $remote not found" :
6075                         "No remotes found");
6076         }
6077
6078         git_header_html(undef, undef, -action_extra => $remote);
6079         git_print_page_nav('', '',  $head, undef, $head,
6080                 format_ref_views($remote ? '' : 'remotes'));
6081
6082         fill_remote_heads($remotedata);
6083         if (defined $remote) {
6084                 git_print_header_div('remotes', "$remote remote for $project");
6085                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6086         } else {
6087                 git_print_header_div('summary', "$project remotes");
6088                 git_remotes_body($remotedata, undef, $head);
6089         }
6090
6091         git_footer_html();
6092 }
6093
6094 sub git_blob_plain {
6095         my $type = shift;
6096         my $expires;
6097
6098         if (!defined $hash) {
6099                 if (defined $file_name) {
6100                         my $base = $hash_base || git_get_head_hash($project);
6101                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6102                                 or die_error(404, "Cannot find file");
6103                 } else {
6104                         die_error(400, "No file name defined");
6105                 }
6106         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6107                 # blobs defined by non-textual hash id's can be cached
6108                 $expires = "+1d";
6109         }
6110
6111         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6112                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6113
6114         # content-type (can include charset)
6115         $type = blob_contenttype($fd, $file_name, $type);
6116
6117         # "save as" filename, even when no $file_name is given
6118         my $save_as = "$hash";
6119         if (defined $file_name) {
6120                 $save_as = $file_name;
6121         } elsif ($type =~ m/^text\//) {
6122                 $save_as .= '.txt';
6123         }
6124
6125         # With XSS prevention on, blobs of all types except a few known safe
6126         # ones are served with "Content-Disposition: attachment" to make sure
6127         # they don't run in our security domain.  For certain image types,
6128         # blob view writes an <img> tag referring to blob_plain view, and we
6129         # want to be sure not to break that by serving the image as an
6130         # attachment (though Firefox 3 doesn't seem to care).
6131         my $sandbox = $prevent_xss &&
6132                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6133
6134         print $cgi->header(
6135                 -type => $type,
6136                 -expires => $expires,
6137                 -content_disposition =>
6138                         ($sandbox ? 'attachment' : 'inline')
6139                         . '; filename="' . $save_as . '"');
6140         local $/ = undef;
6141         binmode STDOUT, ':raw';
6142         print <$fd>;
6143         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6144         close $fd;
6145 }
6146
6147 sub git_blob {
6148         my $expires;
6149
6150         if (!defined $hash) {
6151                 if (defined $file_name) {
6152                         my $base = $hash_base || git_get_head_hash($project);
6153                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6154                                 or die_error(404, "Cannot find file");
6155                 } else {
6156                         die_error(400, "No file name defined");
6157                 }
6158         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6159                 # blobs defined by non-textual hash id's can be cached
6160                 $expires = "+1d";
6161         }
6162
6163         my $have_blame = gitweb_check_feature('blame');
6164         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6165                 or die_error(500, "Couldn't cat $file_name, $hash");
6166         my $mimetype = blob_mimetype($fd, $file_name);
6167         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6168         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6169                 close $fd;
6170                 return git_blob_plain($mimetype);
6171         }
6172         # we can have blame only for text/* mimetype
6173         $have_blame &&= ($mimetype =~ m!^text/!);
6174
6175         my $highlight = gitweb_check_feature('highlight');
6176         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6177         $fd = run_highlighter($fd, $highlight, $syntax)
6178                 if $syntax;
6179
6180         git_header_html(undef, $expires);
6181         my $formats_nav = '';
6182         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6183                 if (defined $file_name) {
6184                         if ($have_blame) {
6185                                 $formats_nav .=
6186                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6187                                                 "blame") .
6188                                         " | ";
6189                         }
6190                         $formats_nav .=
6191                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6192                                         "history") .
6193                                 " | " .
6194                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6195                                         "raw") .
6196                                 " | " .
6197                                 $cgi->a({-href => href(action=>"blob",
6198                                                        hash_base=>"HEAD", file_name=>$file_name)},
6199                                         "HEAD");
6200                 } else {
6201                         $formats_nav .=
6202                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6203                                         "raw");
6204                 }
6205                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6206                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6207         } else {
6208                 print "<div class=\"page_nav\">\n" .
6209                       "<br/><br/></div>\n" .
6210                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6211         }
6212         git_print_page_path($file_name, "blob", $hash_base);
6213         print "<div class=\"page_body\">\n";
6214         if ($mimetype =~ m!^image/!) {
6215                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6216                 if ($file_name) {
6217                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6218                 }
6219                 print qq! src="! .
6220                       href(action=>"blob_plain", hash=>$hash,
6221                            hash_base=>$hash_base, file_name=>$file_name) .
6222                       qq!" />\n!;
6223         } else {
6224                 my $nr;
6225                 while (my $line = <$fd>) {
6226                         chomp $line;
6227                         $nr++;
6228                         $line = untabify($line);
6229                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6230                                $nr, esc_attr(href(-replay => 1)), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
6231                 }
6232         }
6233         close $fd
6234                 or print "Reading blob failed.\n";
6235         print "</div>";
6236         git_footer_html();
6237 }
6238
6239 sub git_tree {
6240         if (!defined $hash_base) {
6241                 $hash_base = "HEAD";
6242         }
6243         if (!defined $hash) {
6244                 if (defined $file_name) {
6245                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6246                 } else {
6247                         $hash = $hash_base;
6248                 }
6249         }
6250         die_error(404, "No such tree") unless defined($hash);
6251
6252         my $show_sizes = gitweb_check_feature('show-sizes');
6253         my $have_blame = gitweb_check_feature('blame');
6254
6255         my @entries = ();
6256         {
6257                 local $/ = "\0";
6258                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6259                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6260                         or die_error(500, "Open git-ls-tree failed");
6261                 @entries = map { chomp; $_ } <$fd>;
6262                 close $fd
6263                         or die_error(404, "Reading tree failed");
6264         }
6265
6266         my $refs = git_get_references();
6267         my $ref = format_ref_marker($refs, $hash_base);
6268         git_header_html();
6269         my $basedir = '';
6270         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6271                 my @views_nav = ();
6272                 if (defined $file_name) {
6273                         push @views_nav,
6274                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6275                                         "history"),
6276                                 $cgi->a({-href => href(action=>"tree",
6277                                                        hash_base=>"HEAD", file_name=>$file_name)},
6278                                         "HEAD"),
6279                 }
6280                 my $snapshot_links = format_snapshot_links($hash);
6281                 if (defined $snapshot_links) {
6282                         # FIXME: Should be available when we have no hash base as well.
6283                         push @views_nav, $snapshot_links;
6284                 }
6285                 git_print_page_nav('tree','', $hash_base, undef, undef,
6286                                    join(' | ', @views_nav));
6287                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6288         } else {
6289                 undef $hash_base;
6290                 print "<div class=\"page_nav\">\n";
6291                 print "<br/><br/></div>\n";
6292                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6293         }
6294         if (defined $file_name) {
6295                 $basedir = $file_name;
6296                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6297                         $basedir .= '/';
6298                 }
6299                 git_print_page_path($file_name, 'tree', $hash_base);
6300         }
6301         print "<div class=\"page_body\">\n";
6302         print "<table class=\"tree\">\n";
6303         my $alternate = 1;
6304         # '..' (top directory) link if possible
6305         if (defined $hash_base &&
6306             defined $file_name && $file_name =~ m![^/]+$!) {
6307                 if ($alternate) {
6308                         print "<tr class=\"dark\">\n";
6309                 } else {
6310                         print "<tr class=\"light\">\n";
6311                 }
6312                 $alternate ^= 1;
6313
6314                 my $up = $file_name;
6315                 $up =~ s!/?[^/]+$!!;
6316                 undef $up unless $up;
6317                 # based on git_print_tree_entry
6318                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6319                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6320                 print '<td class="list">';
6321                 print $cgi->a({-href => href(action=>"tree",
6322                                              hash_base=>$hash_base,
6323                                              file_name=>$up)},
6324                               "..");
6325                 print "</td>\n";
6326                 print "<td class=\"link\"></td>\n";
6327
6328                 print "</tr>\n";
6329         }
6330         foreach my $line (@entries) {
6331                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6332
6333                 if ($alternate) {
6334                         print "<tr class=\"dark\">\n";
6335                 } else {
6336                         print "<tr class=\"light\">\n";
6337                 }
6338                 $alternate ^= 1;
6339
6340                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6341
6342                 print "</tr>\n";
6343         }
6344         print "</table>\n" .
6345               "</div>";
6346         git_footer_html();
6347 }
6348
6349 sub snapshot_name {
6350         my ($project, $hash) = @_;
6351
6352         # path/to/project.git  -> project
6353         # path/to/project/.git -> project
6354         my $name = to_utf8($project);
6355         $name =~ s,([^/])/*\.git$,$1,;
6356         $name = basename($name);
6357         # sanitize name
6358         $name =~ s/[[:cntrl:]]/?/g;
6359
6360         my $ver = $hash;
6361         if ($hash =~ /^[0-9a-fA-F]+$/) {
6362                 # shorten SHA-1 hash
6363                 my $full_hash = git_get_full_hash($project, $hash);
6364                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6365                         $ver = git_get_short_hash($project, $hash);
6366                 }
6367         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6368                 # tags don't need shortened SHA-1 hash
6369                 $ver = $1;
6370         } else {
6371                 # branches and other need shortened SHA-1 hash
6372                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6373                         $ver = $1;
6374                 }
6375                 $ver .= '-' . git_get_short_hash($project, $hash);
6376         }
6377         # in case of hierarchical branch names
6378         $ver =~ s!/!.!g;
6379
6380         # name = project-version_string
6381         $name = "$name-$ver";
6382
6383         return wantarray ? ($name, $name) : $name;
6384 }
6385
6386 sub git_snapshot {
6387         my $format = $input_params{'snapshot_format'};
6388         if (!@snapshot_fmts) {
6389                 die_error(403, "Snapshots not allowed");
6390         }
6391         # default to first supported snapshot format
6392         $format ||= $snapshot_fmts[0];
6393         if ($format !~ m/^[a-z0-9]+$/) {
6394                 die_error(400, "Invalid snapshot format parameter");
6395         } elsif (!exists($known_snapshot_formats{$format})) {
6396                 die_error(400, "Unknown snapshot format");
6397         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6398                 die_error(403, "Snapshot format not allowed");
6399         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6400                 die_error(403, "Unsupported snapshot format");
6401         }
6402
6403         my $type = git_get_type("$hash^{}");
6404         if (!$type) {
6405                 die_error(404, 'Object does not exist');
6406         }  elsif ($type eq 'blob') {
6407                 die_error(400, 'Object is not a tree-ish');
6408         }
6409
6410         my ($name, $prefix) = snapshot_name($project, $hash);
6411         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6412         my $cmd = quote_command(
6413                 git_cmd(), 'archive',
6414                 "--format=$known_snapshot_formats{$format}{'format'}",
6415                 "--prefix=$prefix/", $hash);
6416         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6417                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6418         }
6419
6420         $filename =~ s/(["\\])/\\$1/g;
6421         print $cgi->header(
6422                 -type => $known_snapshot_formats{$format}{'type'},
6423                 -content_disposition => 'inline; filename="' . $filename . '"',
6424                 -status => '200 OK');
6425
6426         open my $fd, "-|", $cmd
6427                 or die_error(500, "Execute git-archive failed");
6428         binmode STDOUT, ':raw';
6429         print <$fd>;
6430         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6431         close $fd;
6432 }
6433
6434 sub git_log_generic {
6435         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6436
6437         my $head = git_get_head_hash($project);
6438         if (!defined $base) {
6439                 $base = $head;
6440         }
6441         if (!defined $page) {
6442                 $page = 0;
6443         }
6444         my $refs = git_get_references();
6445
6446         my $commit_hash = $base;
6447         if (defined $parent) {
6448                 $commit_hash = "$parent..$base";
6449         }
6450         my @commitlist =
6451                 parse_commits($commit_hash, 101, (100 * $page),
6452                               defined $file_name ? ($file_name, "--full-history") : ());
6453
6454         my $ftype;
6455         if (!defined $file_hash && defined $file_name) {
6456                 # some commits could have deleted file in question,
6457                 # and not have it in tree, but one of them has to have it
6458                 for (my $i = 0; $i < @commitlist; $i++) {
6459                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6460                         last if defined $file_hash;
6461                 }
6462         }
6463         if (defined $file_hash) {
6464                 $ftype = git_get_type($file_hash);
6465         }
6466         if (defined $file_name && !defined $ftype) {
6467                 die_error(500, "Unknown type of object");
6468         }
6469         my %co;
6470         if (defined $file_name) {
6471                 %co = parse_commit($base)
6472                         or die_error(404, "Unknown commit object");
6473         }
6474
6475
6476         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6477         my $next_link = '';
6478         if ($#commitlist >= 100) {
6479                 $next_link =
6480                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6481                                  -accesskey => "n", -title => "Alt-n"}, "next");
6482         }
6483         my $patch_max = gitweb_get_feature('patches');
6484         if ($patch_max && !defined $file_name) {
6485                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6486                         $paging_nav .= " &sdot; " .
6487                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6488                                         "patches");
6489                 }
6490         }
6491
6492         git_header_html();
6493         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6494         if (defined $file_name) {
6495                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6496         } else {
6497                 git_print_header_div('summary', $project)
6498         }
6499         git_print_page_path($file_name, $ftype, $hash_base)
6500                 if (defined $file_name);
6501
6502         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6503                      $file_name, $file_hash, $ftype);
6504
6505         git_footer_html();
6506 }
6507
6508 sub git_log {
6509         git_log_generic('log', \&git_log_body,
6510                         $hash, $hash_parent);
6511 }
6512
6513 sub git_commit {
6514         $hash ||= $hash_base || "HEAD";
6515         my %co = parse_commit($hash)
6516             or die_error(404, "Unknown commit object");
6517
6518         my $parent  = $co{'parent'};
6519         my $parents = $co{'parents'}; # listref
6520
6521         # we need to prepare $formats_nav before any parameter munging
6522         my $formats_nav;
6523         if (!defined $parent) {
6524                 # --root commitdiff
6525                 $formats_nav .= '(initial)';
6526         } elsif (@$parents == 1) {
6527                 # single parent commit
6528                 $formats_nav .=
6529                         '(parent: ' .
6530                         $cgi->a({-href => href(action=>"commit",
6531                                                hash=>$parent)},
6532                                 esc_html(substr($parent, 0, 7))) .
6533                         ')';
6534         } else {
6535                 # merge commit
6536                 $formats_nav .=
6537                         '(merge: ' .
6538                         join(' ', map {
6539                                 $cgi->a({-href => href(action=>"commit",
6540                                                        hash=>$_)},
6541                                         esc_html(substr($_, 0, 7)));
6542                         } @$parents ) .
6543                         ')';
6544         }
6545         if (gitweb_check_feature('patches') && @$parents <= 1) {
6546                 $formats_nav .= " | " .
6547                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6548                                 "patch");
6549         }
6550
6551         if (!defined $parent) {
6552                 $parent = "--root";
6553         }
6554         my @difftree;
6555         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6556                 @diff_opts,
6557                 (@$parents <= 1 ? $parent : '-c'),
6558                 $hash, "--"
6559                 or die_error(500, "Open git-diff-tree failed");
6560         @difftree = map { chomp; $_ } <$fd>;
6561         close $fd or die_error(404, "Reading git-diff-tree failed");
6562
6563         # non-textual hash id's can be cached
6564         my $expires;
6565         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6566                 $expires = "+1d";
6567         }
6568         my $refs = git_get_references();
6569         my $ref = format_ref_marker($refs, $co{'id'});
6570
6571         git_header_html(undef, $expires);
6572         git_print_page_nav('commit', '',
6573                            $hash, $co{'tree'}, $hash,
6574                            $formats_nav);
6575
6576         if (defined $co{'parent'}) {
6577                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6578         } else {
6579                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6580         }
6581         print "<div class=\"title_text\">\n" .
6582               "<table class=\"object_header\">\n";
6583         git_print_authorship_rows(\%co);
6584         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6585         print "<tr>" .
6586               "<td>tree</td>" .
6587               "<td class=\"sha1\">" .
6588               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6589                        class => "list"}, $co{'tree'}) .
6590               "</td>" .
6591               "<td class=\"link\">" .
6592               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6593                       "tree");
6594         my $snapshot_links = format_snapshot_links($hash);
6595         if (defined $snapshot_links) {
6596                 print " | " . $snapshot_links;
6597         }
6598         print "</td>" .
6599               "</tr>\n";
6600
6601         foreach my $par (@$parents) {
6602                 print "<tr>" .
6603                       "<td>parent</td>" .
6604                       "<td class=\"sha1\">" .
6605                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6606                                class => "list"}, $par) .
6607                       "</td>" .
6608                       "<td class=\"link\">" .
6609                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6610                       " | " .
6611                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6612                       "</td>" .
6613                       "</tr>\n";
6614         }
6615         print "</table>".
6616               "</div>\n";
6617
6618         print "<div class=\"page_body\">\n";
6619         git_print_log($co{'comment'});
6620         print "</div>\n";
6621
6622         git_difftree_body(\@difftree, $hash, @$parents);
6623
6624         git_footer_html();
6625 }
6626
6627 sub git_object {
6628         # object is defined by:
6629         # - hash or hash_base alone
6630         # - hash_base and file_name
6631         my $type;
6632
6633         # - hash or hash_base alone
6634         if ($hash || ($hash_base && !defined $file_name)) {
6635                 my $object_id = $hash || $hash_base;
6636
6637                 open my $fd, "-|", quote_command(
6638                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6639                         or die_error(404, "Object does not exist");
6640                 $type = <$fd>;
6641                 chomp $type;
6642                 close $fd
6643                         or die_error(404, "Object does not exist");
6644
6645         # - hash_base and file_name
6646         } elsif ($hash_base && defined $file_name) {
6647                 $file_name =~ s,/+$,,;
6648
6649                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6650                         or die_error(404, "Base object does not exist");
6651
6652                 # here errors should not hapen
6653                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6654                         or die_error(500, "Open git-ls-tree failed");
6655                 my $line = <$fd>;
6656                 close $fd;
6657
6658                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6659                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6660                         die_error(404, "File or directory for given base does not exist");
6661                 }
6662                 $type = $2;
6663                 $hash = $3;
6664         } else {
6665                 die_error(400, "Not enough information to find object");
6666         }
6667
6668         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6669                                           hash=>$hash, hash_base=>$hash_base,
6670                                           file_name=>$file_name),
6671                              -status => '302 Found');
6672 }
6673
6674 sub git_blobdiff {
6675         my $format = shift || 'html';
6676
6677         my $fd;
6678         my @difftree;
6679         my %diffinfo;
6680         my $expires;
6681
6682         # preparing $fd and %diffinfo for git_patchset_body
6683         # new style URI
6684         if (defined $hash_base && defined $hash_parent_base) {
6685                 if (defined $file_name) {
6686                         # read raw output
6687                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6688                                 $hash_parent_base, $hash_base,
6689                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6690                                 or die_error(500, "Open git-diff-tree failed");
6691                         @difftree = map { chomp; $_ } <$fd>;
6692                         close $fd
6693                                 or die_error(404, "Reading git-diff-tree failed");
6694                         @difftree
6695                                 or die_error(404, "Blob diff not found");
6696
6697                 } elsif (defined $hash &&
6698                          $hash =~ /[0-9a-fA-F]{40}/) {
6699                         # try to find filename from $hash
6700
6701                         # read filtered raw output
6702                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6703                                 $hash_parent_base, $hash_base, "--"
6704                                 or die_error(500, "Open git-diff-tree failed");
6705                         @difftree =
6706                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6707                                 # $hash == to_id
6708                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6709                                 map { chomp; $_ } <$fd>;
6710                         close $fd
6711                                 or die_error(404, "Reading git-diff-tree failed");
6712                         @difftree
6713                                 or die_error(404, "Blob diff not found");
6714
6715                 } else {
6716                         die_error(400, "Missing one of the blob diff parameters");
6717                 }
6718
6719                 if (@difftree > 1) {
6720                         die_error(400, "Ambiguous blob diff specification");
6721                 }
6722
6723                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6724                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6725                 $file_name   ||= $diffinfo{'to_file'};
6726
6727                 $hash_parent ||= $diffinfo{'from_id'};
6728                 $hash        ||= $diffinfo{'to_id'};
6729
6730                 # non-textual hash id's can be cached
6731                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6732                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6733                         $expires = '+1d';
6734                 }
6735
6736                 # open patch output
6737                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6738                         '-p', ($format eq 'html' ? "--full-index" : ()),
6739                         $hash_parent_base, $hash_base,
6740                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6741                         or die_error(500, "Open git-diff-tree failed");
6742         }
6743
6744         # old/legacy style URI -- not generated anymore since 1.4.3.
6745         if (!%diffinfo) {
6746                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6747         }
6748
6749         # header
6750         if ($format eq 'html') {
6751                 my $formats_nav =
6752                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6753                                 "raw");
6754                 git_header_html(undef, $expires);
6755                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6756                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6757                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6758                 } else {
6759                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6760                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
6761                 }
6762                 if (defined $file_name) {
6763                         git_print_page_path($file_name, "blob", $hash_base);
6764                 } else {
6765                         print "<div class=\"page_path\"></div>\n";
6766                 }
6767
6768         } elsif ($format eq 'plain') {
6769                 print $cgi->header(
6770                         -type => 'text/plain',
6771                         -charset => 'utf-8',
6772                         -expires => $expires,
6773                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6774
6775                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6776
6777         } else {
6778                 die_error(400, "Unknown blobdiff format");
6779         }
6780
6781         # patch
6782         if ($format eq 'html') {
6783                 print "<div class=\"page_body\">\n";
6784
6785                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6786                 close $fd;
6787
6788                 print "</div>\n"; # class="page_body"
6789                 git_footer_html();
6790
6791         } else {
6792                 while (my $line = <$fd>) {
6793                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6794                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6795
6796                         print $line;
6797
6798                         last if $line =~ m!^\+\+\+!;
6799                 }
6800                 local $/ = undef;
6801                 print <$fd>;
6802                 close $fd;
6803         }
6804 }
6805
6806 sub git_blobdiff_plain {
6807         git_blobdiff('plain');
6808 }
6809
6810 sub git_commitdiff {
6811         my %params = @_;
6812         my $format = $params{-format} || 'html';
6813
6814         my ($patch_max) = gitweb_get_feature('patches');
6815         if ($format eq 'patch') {
6816                 die_error(403, "Patch view not allowed") unless $patch_max;
6817         }
6818
6819         $hash ||= $hash_base || "HEAD";
6820         my %co = parse_commit($hash)
6821             or die_error(404, "Unknown commit object");
6822
6823         # choose format for commitdiff for merge
6824         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6825                 $hash_parent = '--cc';
6826         }
6827         # we need to prepare $formats_nav before almost any parameter munging
6828         my $formats_nav;
6829         if ($format eq 'html') {
6830                 $formats_nav =
6831                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6832                                 "raw");
6833                 if ($patch_max && @{$co{'parents'}} <= 1) {
6834                         $formats_nav .= " | " .
6835                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6836                                         "patch");
6837                 }
6838
6839                 if (defined $hash_parent &&
6840                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6841                         # commitdiff with two commits given
6842                         my $hash_parent_short = $hash_parent;
6843                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6844                                 $hash_parent_short = substr($hash_parent, 0, 7);
6845                         }
6846                         $formats_nav .=
6847                                 ' (from';
6848                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6849                                 if ($co{'parents'}[$i] eq $hash_parent) {
6850                                         $formats_nav .= ' parent ' . ($i+1);
6851                                         last;
6852                                 }
6853                         }
6854                         $formats_nav .= ': ' .
6855                                 $cgi->a({-href => href(action=>"commitdiff",
6856                                                        hash=>$hash_parent)},
6857                                         esc_html($hash_parent_short)) .
6858                                 ')';
6859                 } elsif (!$co{'parent'}) {
6860                         # --root commitdiff
6861                         $formats_nav .= ' (initial)';
6862                 } elsif (scalar @{$co{'parents'}} == 1) {
6863                         # single parent commit
6864                         $formats_nav .=
6865                                 ' (parent: ' .
6866                                 $cgi->a({-href => href(action=>"commitdiff",
6867                                                        hash=>$co{'parent'})},
6868                                         esc_html(substr($co{'parent'}, 0, 7))) .
6869                                 ')';
6870                 } else {
6871                         # merge commit
6872                         if ($hash_parent eq '--cc') {
6873                                 $formats_nav .= ' | ' .
6874                                         $cgi->a({-href => href(action=>"commitdiff",
6875                                                                hash=>$hash, hash_parent=>'-c')},
6876                                                 'combined');
6877                         } else { # $hash_parent eq '-c'
6878                                 $formats_nav .= ' | ' .
6879                                         $cgi->a({-href => href(action=>"commitdiff",
6880                                                                hash=>$hash, hash_parent=>'--cc')},
6881                                                 'compact');
6882                         }
6883                         $formats_nav .=
6884                                 ' (merge: ' .
6885                                 join(' ', map {
6886                                         $cgi->a({-href => href(action=>"commitdiff",
6887                                                                hash=>$_)},
6888                                                 esc_html(substr($_, 0, 7)));
6889                                 } @{$co{'parents'}} ) .
6890                                 ')';
6891                 }
6892         }
6893
6894         my $hash_parent_param = $hash_parent;
6895         if (!defined $hash_parent_param) {
6896                 # --cc for multiple parents, --root for parentless
6897                 $hash_parent_param =
6898                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6899         }
6900
6901         # read commitdiff
6902         my $fd;
6903         my @difftree;
6904         if ($format eq 'html') {
6905                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6906                         "--no-commit-id", "--patch-with-raw", "--full-index",
6907                         $hash_parent_param, $hash, "--"
6908                         or die_error(500, "Open git-diff-tree failed");
6909
6910                 while (my $line = <$fd>) {
6911                         chomp $line;
6912                         # empty line ends raw part of diff-tree output
6913                         last unless $line;
6914                         push @difftree, scalar parse_difftree_raw_line($line);
6915                 }
6916
6917         } elsif ($format eq 'plain') {
6918                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6919                         '-p', $hash_parent_param, $hash, "--"
6920                         or die_error(500, "Open git-diff-tree failed");
6921         } elsif ($format eq 'patch') {
6922                 # For commit ranges, we limit the output to the number of
6923                 # patches specified in the 'patches' feature.
6924                 # For single commits, we limit the output to a single patch,
6925                 # diverging from the git-format-patch default.
6926                 my @commit_spec = ();
6927                 if ($hash_parent) {
6928                         if ($patch_max > 0) {
6929                                 push @commit_spec, "-$patch_max";
6930                         }
6931                         push @commit_spec, '-n', "$hash_parent..$hash";
6932                 } else {
6933                         if ($params{-single}) {
6934                                 push @commit_spec, '-1';
6935                         } else {
6936                                 if ($patch_max > 0) {
6937                                         push @commit_spec, "-$patch_max";
6938                                 }
6939                                 push @commit_spec, "-n";
6940                         }
6941                         push @commit_spec, '--root', $hash;
6942                 }
6943                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6944                         '--encoding=utf8', '--stdout', @commit_spec
6945                         or die_error(500, "Open git-format-patch failed");
6946         } else {
6947                 die_error(400, "Unknown commitdiff format");
6948         }
6949
6950         # non-textual hash id's can be cached
6951         my $expires;
6952         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6953                 $expires = "+1d";
6954         }
6955
6956         # write commit message
6957         if ($format eq 'html') {
6958                 my $refs = git_get_references();
6959                 my $ref = format_ref_marker($refs, $co{'id'});
6960
6961                 git_header_html(undef, $expires);
6962                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6963                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6964                 print "<div class=\"title_text\">\n" .
6965                       "<table class=\"object_header\">\n";
6966                 git_print_authorship_rows(\%co);
6967                 print "</table>".
6968                       "</div>\n";
6969                 print "<div class=\"page_body\">\n";
6970                 if (@{$co{'comment'}} > 1) {
6971                         print "<div class=\"log\">\n";
6972                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6973                         print "</div>\n"; # class="log"
6974                 }
6975
6976         } elsif ($format eq 'plain') {
6977                 my $refs = git_get_references("tags");
6978                 my $tagname = git_get_rev_name_tags($hash);
6979                 my $filename = basename($project) . "-$hash.patch";
6980
6981                 print $cgi->header(
6982                         -type => 'text/plain',
6983                         -charset => 'utf-8',
6984                         -expires => $expires,
6985                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6986                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6987                 print "From: " . to_utf8($co{'author'}) . "\n";
6988                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6989                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6990
6991                 print "X-Git-Tag: $tagname\n" if $tagname;
6992                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6993
6994                 foreach my $line (@{$co{'comment'}}) {
6995                         print to_utf8($line) . "\n";
6996                 }
6997                 print "---\n\n";
6998         } elsif ($format eq 'patch') {
6999                 my $filename = basename($project) . "-$hash.patch";
7000
7001                 print $cgi->header(
7002                         -type => 'text/plain',
7003                         -charset => 'utf-8',
7004                         -expires => $expires,
7005                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7006         }
7007
7008         # write patch
7009         if ($format eq 'html') {
7010                 my $use_parents = !defined $hash_parent ||
7011                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7012                 git_difftree_body(\@difftree, $hash,
7013                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7014                 print "<br/>\n";
7015
7016                 git_patchset_body($fd, \@difftree, $hash,
7017                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7018                 close $fd;
7019                 print "</div>\n"; # class="page_body"
7020                 git_footer_html();
7021
7022         } elsif ($format eq 'plain') {
7023                 local $/ = undef;
7024                 print <$fd>;
7025                 close $fd
7026                         or print "Reading git-diff-tree failed\n";
7027         } elsif ($format eq 'patch') {
7028                 local $/ = undef;
7029                 print <$fd>;
7030                 close $fd
7031                         or print "Reading git-format-patch failed\n";
7032         }
7033 }
7034
7035 sub git_commitdiff_plain {
7036         git_commitdiff(-format => 'plain');
7037 }
7038
7039 # format-patch-style patches
7040 sub git_patch {
7041         git_commitdiff(-format => 'patch', -single => 1);
7042 }
7043
7044 sub git_patches {
7045         git_commitdiff(-format => 'patch');
7046 }
7047
7048 sub git_history {
7049         git_log_generic('history', \&git_history_body,
7050                         $hash_base, $hash_parent_base,
7051                         $file_name, $hash);
7052 }
7053
7054 sub git_search {
7055         gitweb_check_feature('search') or die_error(403, "Search is disabled");
7056         if (!defined $searchtext) {
7057                 die_error(400, "Text field is empty");
7058         }
7059         if (!defined $hash) {
7060                 $hash = git_get_head_hash($project);
7061         }
7062         my %co = parse_commit($hash);
7063         if (!%co) {
7064                 die_error(404, "Unknown commit object");
7065         }
7066         if (!defined $page) {
7067                 $page = 0;
7068         }
7069
7070         $searchtype ||= 'commit';
7071         if ($searchtype eq 'pickaxe') {
7072                 # pickaxe may take all resources of your box and run for several minutes
7073                 # with every query - so decide by yourself how public you make this feature
7074                 gitweb_check_feature('pickaxe')
7075                     or die_error(403, "Pickaxe is disabled");
7076         }
7077         if ($searchtype eq 'grep') {
7078                 gitweb_check_feature('grep')
7079                     or die_error(403, "Grep is disabled");
7080         }
7081
7082         git_header_html();
7083
7084         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
7085                 my $greptype;
7086                 if ($searchtype eq 'commit') {
7087                         $greptype = "--grep=";
7088                 } elsif ($searchtype eq 'author') {
7089                         $greptype = "--author=";
7090                 } elsif ($searchtype eq 'committer') {
7091                         $greptype = "--committer=";
7092                 }
7093                 $greptype .= $searchtext;
7094                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
7095                                                $greptype, '--regexp-ignore-case',
7096                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
7097
7098                 my $paging_nav = '';
7099                 if ($page > 0) {
7100                         $paging_nav .=
7101                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
7102                                                        searchtext=>$searchtext,
7103                                                        searchtype=>$searchtype)},
7104                                         "first");
7105                         $paging_nav .= " &sdot; " .
7106                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
7107                                          -accesskey => "p", -title => "Alt-p"}, "prev");
7108                 } else {
7109                         $paging_nav .= "first";
7110                         $paging_nav .= " &sdot; prev";
7111                 }
7112                 my $next_link = '';
7113                 if ($#commitlist >= 100) {
7114                         $next_link =
7115                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
7116                                          -accesskey => "n", -title => "Alt-n"}, "next");
7117                         $paging_nav .= " &sdot; $next_link";
7118                 } else {
7119                         $paging_nav .= " &sdot; next";
7120                 }
7121
7122                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
7123                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
7124                 if ($page == 0 && !@commitlist) {
7125                         print "<p>No match.</p>\n";
7126                 } else {
7127                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
7128                 }
7129         }
7130
7131         if ($searchtype eq 'pickaxe') {
7132                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
7133                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
7134
7135                 print "<table class=\"pickaxe search\">\n";
7136                 my $alternate = 1;
7137                 local $/ = "\n";
7138                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
7139                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
7140                         ($search_use_regexp ? '--pickaxe-regex' : ());
7141                 undef %co;
7142                 my @files;
7143                 while (my $line = <$fd>) {
7144                         chomp $line;
7145                         next unless $line;
7146
7147                         my %set = parse_difftree_raw_line($line);
7148                         if (defined $set{'commit'}) {
7149                                 # finish previous commit
7150                                 if (%co) {
7151                                         print "</td>\n" .
7152                                               "<td class=\"link\">" .
7153                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
7154                                               " | " .
7155                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
7156                                         print "</td>\n" .
7157                                               "</tr>\n";
7158                                 }
7159
7160                                 if ($alternate) {
7161                                         print "<tr class=\"dark\">\n";
7162                                 } else {
7163                                         print "<tr class=\"light\">\n";
7164                                 }
7165                                 $alternate ^= 1;
7166                                 %co = parse_commit($set{'commit'});
7167                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
7168                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
7169                                       "<td><i>$author</i></td>\n" .
7170                                       "<td>" .
7171                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
7172                                               -class => "list subject"},
7173                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
7174                         } elsif (defined $set{'to_id'}) {
7175                                 next if ($set{'to_id'} =~ m/^0{40}$/);
7176
7177                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
7178                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
7179                                               -class => "list"},
7180                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
7181                                       "<br/>\n";
7182                         }
7183                 }
7184                 close $fd;
7185
7186                 # finish last commit (warning: repetition!)
7187                 if (%co) {
7188                         print "</td>\n" .
7189                               "<td class=\"link\">" .
7190                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
7191                               " | " .
7192                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
7193                         print "</td>\n" .
7194                               "</tr>\n";
7195                 }
7196
7197                 print "</table>\n";
7198         }
7199
7200         if ($searchtype eq 'grep') {
7201                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
7202                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
7203
7204                 print "<table class=\"grep_search\">\n";
7205                 my $alternate = 1;
7206                 my $matches = 0;
7207                 local $/ = "\n";
7208                 open my $fd, "-|", git_cmd(), 'grep', '-n',
7209                         $search_use_regexp ? ('-E', '-i') : '-F',
7210                         $searchtext, $co{'tree'};
7211                 my $lastfile = '';
7212                 while (my $line = <$fd>) {
7213                         chomp $line;
7214                         my ($file, $lno, $ltext, $binary);
7215                         last if ($matches++ > 1000);
7216                         if ($line =~ /^Binary file (.+) matches$/) {
7217                                 $file = $1;
7218                                 $binary = 1;
7219                         } else {
7220                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
7221                         }
7222                         if ($file ne $lastfile) {
7223                                 $lastfile and print "</td></tr>\n";
7224                                 if ($alternate++) {
7225                                         print "<tr class=\"dark\">\n";
7226                                 } else {
7227                                         print "<tr class=\"light\">\n";
7228                                 }
7229                                 print "<td class=\"list\">".
7230                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
7231                                                                file_name=>"$file"),
7232                                                 -class => "list"}, esc_path($file));
7233                                 print "</td><td>\n";
7234                                 $lastfile = $file;
7235                         }
7236                         if ($binary) {
7237                                 print "<div class=\"binary\">Binary file</div>\n";
7238                         } else {
7239                                 $ltext = untabify($ltext);
7240                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
7241                                         $ltext = esc_html($1, -nbsp=>1);
7242                                         $ltext .= '<span class="match">';
7243                                         $ltext .= esc_html($2, -nbsp=>1);
7244                                         $ltext .= '</span>';
7245                                         $ltext .= esc_html($3, -nbsp=>1);
7246                                 } else {
7247                                         $ltext = esc_html($ltext, -nbsp=>1);
7248                                 }
7249                                 print "<div class=\"pre\">" .
7250                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
7251                                                                file_name=>"$file").'#l'.$lno,
7252                                                 -class => "linenr"}, sprintf('%4i', $lno))
7253                                         . ' ' .  $ltext . "</div>\n";
7254                         }
7255                 }
7256                 if ($lastfile) {
7257                         print "</td></tr>\n";
7258                         if ($matches > 1000) {
7259                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
7260                         }
7261                 } else {
7262                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
7263                 }
7264                 close $fd;
7265
7266                 print "</table>\n";
7267         }
7268         git_footer_html();
7269 }
7270
7271 sub git_search_help {
7272         git_header_html();
7273         git_print_page_nav('','', $hash,$hash,$hash);
7274         print <<EOT;
7275 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7276 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7277 the pattern entered is recognized as the POSIX extended
7278 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7279 insensitive).</p>
7280 <dl>
7281 <dt><b>commit</b></dt>
7282 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7283 EOT
7284         my $have_grep = gitweb_check_feature('grep');
7285         if ($have_grep) {
7286                 print <<EOT;
7287 <dt><b>grep</b></dt>
7288 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7289     a different one) are searched for the given pattern. On large trees, this search can take
7290 a while and put some strain on the server, so please use it with some consideration. Note that
7291 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7292 case-sensitive.</dd>
7293 EOT
7294         }
7295         print <<EOT;
7296 <dt><b>author</b></dt>
7297 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7298 <dt><b>committer</b></dt>
7299 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7300 EOT
7301         my $have_pickaxe = gitweb_check_feature('pickaxe');
7302         if ($have_pickaxe) {
7303                 print <<EOT;
7304 <dt><b>pickaxe</b></dt>
7305 <dd>All commits that caused the string to appear or disappear from any file (changes that
7306 added, removed or "modified" the string) will be listed. This search can take a while and
7307 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7308 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7309 EOT
7310         }
7311         print "</dl>\n";
7312         git_footer_html();
7313 }
7314
7315 sub git_shortlog {
7316         git_log_generic('shortlog', \&git_shortlog_body,
7317                         $hash, $hash_parent);
7318 }
7319
7320 ## ......................................................................
7321 ## feeds (RSS, Atom; OPML)
7322
7323 sub git_feed {
7324         my $format = shift || 'atom';
7325         my $have_blame = gitweb_check_feature('blame');
7326
7327         # Atom: http://www.atomenabled.org/developers/syndication/
7328         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7329         if ($format ne 'rss' && $format ne 'atom') {
7330                 die_error(400, "Unknown web feed format");
7331         }
7332
7333         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7334         my $head = $hash || 'HEAD';
7335         my @commitlist = parse_commits($head, 150, 0, $file_name);
7336
7337         my %latest_commit;
7338         my %latest_date;
7339         my $content_type = "application/$format+xml";
7340         if (defined $cgi->http('HTTP_ACCEPT') &&
7341                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7342                 # browser (feed reader) prefers text/xml
7343                 $content_type = 'text/xml';
7344         }
7345         if (defined($commitlist[0])) {
7346                 %latest_commit = %{$commitlist[0]};
7347                 my $latest_epoch = $latest_commit{'committer_epoch'};
7348                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7349                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7350                 if (defined $if_modified) {
7351                         my $since;
7352                         if (eval { require HTTP::Date; 1; }) {
7353                                 $since = HTTP::Date::str2time($if_modified);
7354                         } elsif (eval { require Time::ParseDate; 1; }) {
7355                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7356                         }
7357                         if (defined $since && $latest_epoch <= $since) {
7358                                 print $cgi->header(
7359                                         -type => $content_type,
7360                                         -charset => 'utf-8',
7361                                         -last_modified => $latest_date{'rfc2822'},
7362                                         -status => '304 Not Modified');
7363                                 return;
7364                         }
7365                 }
7366                 print $cgi->header(
7367                         -type => $content_type,
7368                         -charset => 'utf-8',
7369                         -last_modified => $latest_date{'rfc2822'});
7370         } else {
7371                 print $cgi->header(
7372                         -type => $content_type,
7373                         -charset => 'utf-8');
7374         }
7375
7376         # Optimization: skip generating the body if client asks only
7377         # for Last-Modified date.
7378         return if ($cgi->request_method() eq 'HEAD');
7379
7380         # header variables
7381         my $title = "$site_name - $project/$action";
7382         my $feed_type = 'log';
7383         if (defined $hash) {
7384                 $title .= " - '$hash'";
7385                 $feed_type = 'branch log';
7386                 if (defined $file_name) {
7387                         $title .= " :: $file_name";
7388                         $feed_type = 'history';
7389                 }
7390         } elsif (defined $file_name) {
7391                 $title .= " - $file_name";
7392                 $feed_type = 'history';
7393         }
7394         $title .= " $feed_type";
7395         my $descr = git_get_project_description($project);
7396         if (defined $descr) {
7397                 $descr = esc_html($descr);
7398         } else {
7399                 $descr = "$project " .
7400                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7401                          " feed";
7402         }
7403         my $owner = git_get_project_owner($project);
7404         $owner = esc_html($owner);
7405
7406         #header
7407         my $alt_url;
7408         if (defined $file_name) {
7409                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7410         } elsif (defined $hash) {
7411                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7412         } else {
7413                 $alt_url = href(-full=>1, action=>"summary");
7414         }
7415         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7416         if ($format eq 'rss') {
7417                 print <<XML;
7418 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7419 <channel>
7420 XML
7421                 print "<title>$title</title>\n" .
7422                       "<link>$alt_url</link>\n" .
7423                       "<description>$descr</description>\n" .
7424                       "<language>en</language>\n" .
7425                       # project owner is responsible for 'editorial' content
7426                       "<managingEditor>$owner</managingEditor>\n";
7427                 if (defined $logo || defined $favicon) {
7428                         # prefer the logo to the favicon, since RSS
7429                         # doesn't allow both
7430                         my $img = esc_url($logo || $favicon);
7431                         print "<image>\n" .
7432                               "<url>$img</url>\n" .
7433                               "<title>$title</title>\n" .
7434                               "<link>$alt_url</link>\n" .
7435                               "</image>\n";
7436                 }
7437                 if (%latest_date) {
7438                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7439                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7440                 }
7441                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7442         } elsif ($format eq 'atom') {
7443                 print <<XML;
7444 <feed xmlns="http://www.w3.org/2005/Atom">
7445 XML
7446                 print "<title>$title</title>\n" .
7447                       "<subtitle>$descr</subtitle>\n" .
7448                       '<link rel="alternate" type="text/html" href="' .
7449                       $alt_url . '" />' . "\n" .
7450                       '<link rel="self" type="' . $content_type . '" href="' .
7451                       $cgi->self_url() . '" />' . "\n" .
7452                       "<id>" . href(-full=>1) . "</id>\n" .
7453                       # use project owner for feed author
7454                       "<author><name>$owner</name></author>\n";
7455                 if (defined $favicon) {
7456                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7457                 }
7458                 if (defined $logo) {
7459                         # not twice as wide as tall: 72 x 27 pixels
7460                         print "<logo>" . esc_url($logo) . "</logo>\n";
7461                 }
7462                 if (! %latest_date) {
7463                         # dummy date to keep the feed valid until commits trickle in:
7464                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7465                 } else {
7466                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7467                 }
7468                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7469         }
7470
7471         # contents
7472         for (my $i = 0; $i <= $#commitlist; $i++) {
7473                 my %co = %{$commitlist[$i]};
7474                 my $commit = $co{'id'};
7475                 # we read 150, we always show 30 and the ones more recent than 48 hours
7476                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7477                         last;
7478                 }
7479                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7480
7481                 # get list of changed files
7482                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7483                         $co{'parent'} || "--root",
7484                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7485                         or next;
7486                 my @difftree = map { chomp; $_ } <$fd>;
7487                 close $fd
7488                         or next;
7489
7490                 # print element (entry, item)
7491                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7492                 if ($format eq 'rss') {
7493                         print "<item>\n" .
7494                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7495                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7496                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7497                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7498                               "<link>$co_url</link>\n" .
7499                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7500                               "<content:encoded>" .
7501                               "<![CDATA[\n";
7502                 } elsif ($format eq 'atom') {
7503                         print "<entry>\n" .
7504                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7505                               "<updated>$cd{'iso-8601'}</updated>\n" .
7506                               "<author>\n" .
7507                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7508                         if ($co{'author_email'}) {
7509                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7510                         }
7511                         print "</author>\n" .
7512                               # use committer for contributor
7513                               "<contributor>\n" .
7514                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7515                         if ($co{'committer_email'}) {
7516                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7517                         }
7518                         print "</contributor>\n" .
7519                               "<published>$cd{'iso-8601'}</published>\n" .
7520                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7521                               "<id>$co_url</id>\n" .
7522                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7523                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7524                 }
7525                 my $comment = $co{'comment'};
7526                 print "<pre>\n";
7527                 foreach my $line (@$comment) {
7528                         $line = esc_html($line);
7529                         print "$line\n";
7530                 }
7531                 print "</pre><ul>\n";
7532                 foreach my $difftree_line (@difftree) {
7533                         my %difftree = parse_difftree_raw_line($difftree_line);
7534                         next if !$difftree{'from_id'};
7535
7536                         my $file = $difftree{'file'} || $difftree{'to_file'};
7537
7538                         print "<li>" .
7539                               "[" .
7540                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7541                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7542                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7543                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7544                                       -title => "diff"}, 'D');
7545                         if ($have_blame) {
7546                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7547                                                              file_name=>$file, hash_base=>$commit),
7548                                               -title => "blame"}, 'B');
7549                         }
7550                         # if this is not a feed of a file history
7551                         if (!defined $file_name || $file_name ne $file) {
7552                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7553                                                              file_name=>$file, hash=>$commit),
7554                                               -title => "history"}, 'H');
7555                         }
7556                         $file = esc_path($file);
7557                         print "] ".
7558                               "$file</li>\n";
7559                 }
7560                 if ($format eq 'rss') {
7561                         print "</ul>]]>\n" .
7562                               "</content:encoded>\n" .
7563                               "</item>\n";
7564                 } elsif ($format eq 'atom') {
7565                         print "</ul>\n</div>\n" .
7566                               "</content>\n" .
7567                               "</entry>\n";
7568                 }
7569         }
7570
7571         # end of feed
7572         if ($format eq 'rss') {
7573                 print "</channel>\n</rss>\n";
7574         } elsif ($format eq 'atom') {
7575                 print "</feed>\n";
7576         }
7577 }
7578
7579 sub git_rss {
7580         git_feed('rss');
7581 }
7582
7583 sub git_atom {
7584         git_feed('atom');
7585 }
7586
7587 sub git_opml {
7588         my @list = git_get_projects_list();
7589         if (!@list) {
7590                 die_error(404, "No projects found");
7591         }
7592
7593         print $cgi->header(
7594                 -type => 'text/xml',
7595                 -charset => 'utf-8',
7596                 -content_disposition => 'inline; filename="opml.xml"');
7597
7598         print <<XML;
7599 <?xml version="1.0" encoding="utf-8"?>
7600 <opml version="1.0">
7601 <head>
7602   <title>$site_name OPML Export</title>
7603 </head>
7604 <body>
7605 <outline text="git RSS feeds">
7606 XML
7607
7608         foreach my $pr (@list) {
7609                 my %proj = %$pr;
7610                 my $head = git_get_head_hash($proj{'path'});
7611                 if (!defined $head) {
7612                         next;
7613                 }
7614                 $git_dir = "$projectroot/$proj{'path'}";
7615                 my %co = parse_commit($head);
7616                 if (!%co) {
7617                         next;
7618                 }
7619
7620                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7621                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7622                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7623                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7624         }
7625         print <<XML;
7626 </outline>
7627 </body>
7628 </opml>
7629 XML
7630 }