?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Merge branch 'jc/maint-fetch-regression-1.5.4' into maint
[git/mingw.git] / git-svn.perl
blobe0434099ce6832871df7901f25a5c9f4ee477dd8
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
458
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift or die "SVN or git revision required ",
523 "as a command-line argument\n";
524 my $result;
525 if ($revision_or_hash =~ /^r\d+$/) {
526 my $head = shift;
527 $head ||= 'HEAD';
528 my @refs;
529 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
530 unless ($gs) {
531 die "Unable to determine upstream SVN information from ",
532 "$head history\n";
533 }
534 my $desired_revision = substr($revision_or_hash, 1);
535 $result = $gs->rev_map_get($desired_revision);
536 } else {
537 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
538 $result = $rev;
539 }
540 print "$result\n" if $result;
541 }
542
543 sub cmd_rebase {
544 command_noisy(qw/update-index --refresh/);
545 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
546 unless ($gs) {
547 die "Unable to determine upstream SVN information from ",
548 "working tree history\n";
549 }
550 if (command(qw/diff-index HEAD --/)) {
551 print STDERR "Cannot rebase with uncommited changes:\n";
552 command_noisy('status');
553 exit 1;
554 }
555 unless ($_local) {
556 # rebase will checkout for us, so no need to do it explicitly
557 $_no_checkout = 'true';
558 $_fetch_all ? $gs->fetch_all : $gs->fetch;
559 }
560 command_noisy(rebase_cmd(), $gs->refname);
561 }
562
563 sub cmd_show_ignore {
564 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
565 $gs ||= Git::SVN->new;
566 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
567 $gs->prop_walk($gs->{path}, $r, sub {
568 my ($gs, $path, $props) = @_;
569 print STDOUT "\n# $path\n";
570 my $s = $props->{'svn:ignore'} or return;
571 $s =~ s/[\r\n]+/\n/g;
572 chomp $s;
573 $s =~ s#^#$path#gm;
574 print STDOUT "$s\n";
575 });
576 }
577
578 sub cmd_show_externals {
579 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
580 $gs ||= Git::SVN->new;
581 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
582 $gs->prop_walk($gs->{path}, $r, sub {
583 my ($gs, $path, $props) = @_;
584 print STDOUT "\n# $path\n";
585 my $s = $props->{'svn:externals'} or return;
586 $s =~ s/[\r\n]+/\n/g;
587 chomp $s;
588 $s =~ s#^#$path#gm;
589 print STDOUT "$s\n";
590 });
591 }
592
593 sub cmd_create_ignore {
594 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
595 $gs ||= Git::SVN->new;
596 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
597 $gs->prop_walk($gs->{path}, $r, sub {
598 my ($gs, $path, $props) = @_;
599 # $path is of the form /path/to/dir/
600 my $ignore = '.' . $path . '.gitignore';
601 my $s = $props->{'svn:ignore'} or return;
602 open(GITIGNORE, '>', $ignore)
603 or fatal("Failed to open `$ignore' for writing: $!");
604 $s =~ s/[\r\n]+/\n/g;
605 chomp $s;
606 # Prefix all patterns so that the ignore doesn't apply
607 # to sub-directories.
608 $s =~ s#^#/#gm;
609 print GITIGNORE "$s\n";
610 close(GITIGNORE)
611 or fatal("Failed to close `$ignore': $!");
612 command_noisy('add', $ignore);
613 });
614 }
615
616 sub canonicalize_path {
617 my ($path) = @_;
618 my $dot_slash_added = 0;
619 if (substr($path, 0, 1) ne "/") {
620 $path = "./" . $path;
621 $dot_slash_added = 1;
622 }
623 # File::Spec->canonpath doesn't collapse x/../y into y (for a
624 # good reason), so let's do this manually.
625 $path =~ s#/+#/#g;
626 $path =~ s#/\.(?:/|$)#/#g;
627 $path =~ s#/[^/]+/\.\.##g;
628 $path =~ s#/$##g;
629 $path =~ s#^\./## if $dot_slash_added;
630 return $path;
631 }
632
633 # get_svnprops(PATH)
634 # ------------------
635 # Helper for cmd_propget and cmd_proplist below.
636 sub get_svnprops {
637 my $path = shift;
638 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
639 $gs ||= Git::SVN->new;
640
641 # prefix THE PATH by the sub-directory from which the user
642 # invoked us.
643 $path = $cmd_dir_prefix . $path;
644 fatal("No such file or directory: $path") unless -e $path;
645 my $is_dir = -d $path ? 1 : 0;
646 $path = $gs->{path} . '/' . $path;
647
648 # canonicalize the path (otherwise libsvn will abort or fail to
649 # find the file)
650 $path = canonicalize_path($path);
651
652 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
653 my $props;
654 if ($is_dir) {
655 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
656 }
657 else {
658 (undef, $props) = $gs->ra->get_file($path, $r, undef);
659 }
660 return $props;
661 }
662
663 # cmd_propget (PROP, PATH)
664 # ------------------------
665 # Print the SVN property PROP for PATH.
666 sub cmd_propget {
667 my ($prop, $path) = @_;
668 $path = '.' if not defined $path;
669 usage(1) if not defined $prop;
670 my $props = get_svnprops($path);
671 if (not defined $props->{$prop}) {
672 fatal("`$path' does not have a `$prop' SVN property.");
673 }
674 print $props->{$prop} . "\n";
675 }
676
677 # cmd_proplist (PATH)
678 # -------------------
679 # Print the list of SVN properties for PATH.
680 sub cmd_proplist {
681 my $path = shift;
682 $path = '.' if not defined $path;
683 my $props = get_svnprops($path);
684 print "Properties on '$path':\n";
685 foreach (sort keys %{$props}) {
686 print " $_\n";
687 }
688 }
689
690 sub cmd_multi_init {
691 my $url = shift;
692 unless (defined $_trunk || defined $_branches || defined $_tags) {
693 usage(1);
694 }
695
696 # there are currently some bugs that prevent multi-init/multi-fetch
697 # setups from working well without this.
698 $Git::SVN::_minimize_url = 1;
699
700 $_prefix = '' unless defined $_prefix;
701 if (defined $url) {
702 $url =~ s#/+$##;
703 init_subdir(@_);
704 }
705 do_git_init_db();
706 if (defined $_trunk) {
707 my $trunk_ref = $_prefix . 'trunk';
708 # try both old-style and new-style lookups:
709 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
710 unless ($gs_trunk) {
711 my ($trunk_url, $trunk_path) =
712 complete_svn_url($url, $_trunk);
713 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
714 undef, $trunk_ref);
715 }
716 }
717 return unless defined $_branches || defined $_tags;
718 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
719 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
720 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
721 }
722
723 sub cmd_multi_fetch {
724 my $remotes = Git::SVN::read_all_remotes();
725 foreach my $repo_id (sort keys %$remotes) {
726 if ($remotes->{$repo_id}->{url}) {
727 Git::SVN::fetch_all($repo_id, $remotes);
728 }
729 }
730 }
731
732 # this command is special because it requires no metadata
733 sub cmd_commit_diff {
734 my ($ta, $tb, $url) = @_;
735 my $usage = "Usage: $0 commit-diff -r<revision> ".
736 "<tree-ish> <tree-ish> [<URL>]";
737 fatal($usage) if (!defined $ta || !defined $tb);
738 my $svn_path;
739 if (!defined $url) {
740 my $gs = eval { Git::SVN->new };
741 if (!$gs) {
742 fatal("Needed URL or usable git-svn --id in ",
743 "the command-line\n", $usage);
744 }
745 $url = $gs->{url};
746 $svn_path = $gs->{path};
747 }
748 unless (defined $_revision) {
749 fatal("-r|--revision is a required argument\n", $usage);
750 }
751 if (defined $_message && defined $_file) {
752 fatal("Both --message/-m and --file/-F specified ",
753 "for the commit message.\n",
754 "I have no idea what you mean");
755 }
756 if (defined $_file) {
757 $_message = file_to_s($_file);
758 } else {
759 $_message ||= get_commit_entry($tb)->{log};
760 }
761 my $ra ||= Git::SVN::Ra->new($url);
762 $svn_path ||= $ra->{svn_path};
763 my $r = $_revision;
764 if ($r eq 'HEAD') {
765 $r = $ra->get_latest_revnum;
766 } elsif ($r !~ /^\d+$/) {
767 die "revision argument: $r not understood by git-svn\n";
768 }
769 my %ed_opts = ( r => $r,
770 log => $_message,
771 ra => $ra,
772 tree_a => $ta,
773 tree_b => $tb,
774 editor_cb => sub { print "Committed r$_[0]\n" },
775 svn_path => $svn_path );
776 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
777 print "No changes\n$ta == $tb\n";
778 }
779 }
780
781 sub cmd_info {
782 my $path = canonicalize_path(shift or ".");
783 unless (scalar(@_) == 0) {
784 die "Too many arguments specified\n";
785 }
786
787 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
788
789 if (!$file_type && !$diff_status) {
790 print STDERR "$path: (Not a versioned resource)\n\n";
791 return;
792 }
793
794 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
795 unless ($gs) {
796 die "Unable to determine upstream SVN information from ",
797 "working tree history\n";
798 }
799 my $full_url = $url . ($path eq "." ? "" : "/$path");
800
801 if ($_url) {
802 print $full_url, "\n";
803 return;
804 }
805
806 my $result = "Path: $path\n";
807 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
808 $result .= "URL: " . $full_url . "\n";
809
810 eval {
811 my $repos_root = $gs->repos_root;
812 Git::SVN::remove_username($repos_root);
813 $result .= "Repository Root: $repos_root\n";
814 };
815 if ($@) {
816 $result .= "Repository Root: (offline)\n";
817 }
818 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
819 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
820
821 $result .= "Node Kind: " .
822 ($file_type eq "dir" ? "directory" : "file") . "\n";
823
824 my $schedule = $diff_status eq "A"
825 ? "add"
826 : ($diff_status eq "D" ? "delete" : "normal");
827 $result .= "Schedule: $schedule\n";
828
829 if ($diff_status eq "A") {
830 print $result, "\n";
831 return;
832 }
833
834 my ($lc_author, $lc_rev, $lc_date_utc);
835 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
836 my $log = command_output_pipe(@args);
837 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
838 while (<$log>) {
839 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
840 $lc_author = $1;
841 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
842 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
843 (undef, $lc_rev, undef) = ::extract_metadata($1);
844 }
845 }
846 close $log;
847
848 Git::SVN::Log::set_local_timezone();
849
850 $result .= "Last Changed Author: $lc_author\n";
851 $result .= "Last Changed Rev: $lc_rev\n";
852 $result .= "Last Changed Date: " .
853 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
854
855 if ($file_type ne "dir") {
856 my $text_last_updated_date =
857 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
858 $result .=
859 "Text Last Updated: " .
860 Git::SVN::Log::format_svn_date($text_last_updated_date) .
861 "\n";
862 my $checksum;
863 if ($diff_status eq "D") {
864 my ($fh, $ctx) =
865 command_output_pipe(qw(cat-file blob), "HEAD:$path");
866 if ($file_type eq "link") {
867 my $file_name = <$fh>;
868 $checksum = md5sum("link $file_name");
869 } else {
870 $checksum = md5sum($fh);
871 }
872 command_close_pipe($fh, $ctx);
873 } elsif ($file_type eq "link") {
874 my $file_name =
875 command(qw(cat-file blob), "HEAD:$path");
876 $checksum =
877 md5sum("link " . $file_name);
878 } else {
879 open FILE, "<", $path or die $!;
880 $checksum = md5sum(\*FILE);
881 close FILE or die $!;
882 }
883 $result .= "Checksum: " . $checksum . "\n";
884 }
885
886 print $result, "\n";
887 }
888
889 ########################### utility functions #########################
890
891 sub rebase_cmd {
892 my @cmd = qw/rebase/;
893 push @cmd, '-v' if $_verbose;
894 push @cmd, qw/--merge/ if $_merge;
895 push @cmd, "--strategy=$_strategy" if $_strategy;
896 @cmd;
897 }
898
899 sub post_fetch_checkout {
900 return if $_no_checkout;
901 my $gs = $Git::SVN::_head or return;
902 return if verify_ref('refs/heads/master^0');
903
904 my $valid_head = verify_ref('HEAD^0');
905 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
906 return if ($valid_head || !verify_ref('HEAD^0'));
907
908 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
909 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
910 return if -f $index;
911
912 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
913 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
914 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
915 print STDERR "Checked out HEAD:\n ",
916 $gs->full_url, " r", $gs->last_rev, "\n";
917 }
918
919 sub complete_svn_url {
920 my ($url, $path) = @_;
921 $path =~ s#/+$##;
922 if ($path !~ m#^[a-z\+]+://#) {
923 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
924 fatal("E: '$path' is not a complete URL ",
925 "and a separate URL is not specified");
926 }
927 return ($url, $path);
928 }
929 return ($path, '');
930 }
931
932 sub complete_url_ls_init {
933 my ($ra, $repo_path, $switch, $pfx) = @_;
934 unless ($repo_path) {
935 print STDERR "W: $switch not specified\n";
936 return;
937 }
938 $repo_path =~ s#/+$##;
939 if ($repo_path =~ m#^[a-z\+]+://#) {
940 $ra = Git::SVN::Ra->new($repo_path);
941 $repo_path = '';
942 } else {
943 $repo_path =~ s#^/+##;
944 unless ($ra) {
945 fatal("E: '$repo_path' is not a complete URL ",
946 "and a separate URL is not specified");
947 }
948 }
949 my $url = $ra->{url};
950 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
951 my $k = "svn-remote.$gs->{repo_id}.url";
952 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
953 if ($orig_url && ($orig_url ne $gs->{url})) {
954 die "$k already set: $orig_url\n",
955 "wanted to set to: $gs->{url}\n";
956 }
957 command_oneline('config', $k, $gs->{url}) unless $orig_url;
958 my $remote_path = "$ra->{svn_path}/$repo_path";
959 $remote_path =~ s#/+#/#g;
960 $remote_path =~ s#^/##g;
961 $remote_path .= "/*" if $remote_path !~ /\*/;
962 my ($n) = ($switch =~ /^--(\w+)/);
963 if (length $pfx && $pfx !~ m#/$#) {
964 die "--prefix='$pfx' must have a trailing slash '/'\n";
965 }
966 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
967 "$remote_path:refs/remotes/$pfx*");
968 }
969
970 sub verify_ref {
971 my ($ref) = @_;
972 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
973 { STDERR => 0 }); };
974 }
975
976 sub get_tree_from_treeish {
977 my ($treeish) = @_;
978 # $treeish can be a symbolic ref, too:
979 my $type = command_oneline(qw/cat-file -t/, $treeish);
980 my $expected;
981 while ($type eq 'tag') {
982 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
983 }
984 if ($type eq 'commit') {
985 $expected = (grep /^tree /, command(qw/cat-file commit/,
986 $treeish))[0];
987 ($expected) = ($expected =~ /^tree ($sha1)$/o);
988 die "Unable to get tree from $treeish\n" unless $expected;
989 } elsif ($type eq 'tree') {
990 $expected = $treeish;
991 } else {
992 die "$treeish is a $type, expected tree, tag or commit\n";
993 }
994 return $expected;
995 }
996
997 sub get_commit_entry {
998 my ($treeish) = shift;
999 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1000 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1001 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1002 open my $log_fh, '>', $commit_editmsg or croak $!;
1003
1004 my $type = command_oneline(qw/cat-file -t/, $treeish);
1005 if ($type eq 'commit' || $type eq 'tag') {
1006 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1007 $type, $treeish);
1008 my $in_msg = 0;
1009 while (<$msg_fh>) {
1010 if (!$in_msg) {
1011 $in_msg = 1 if (/^\s*$/);
1012 } elsif (/^git-svn-id: /) {
1013 # skip this for now, we regenerate the
1014 # correct one on re-fetch anyways
1015 # TODO: set *:merge properties or like...
1016 } else {
1017 print $log_fh $_ or croak $!;
1018 }
1019 }
1020 command_close_pipe($msg_fh, $ctx);
1021 }
1022 close $log_fh or croak $!;
1023
1024 if ($_edit || ($type eq 'tree')) {
1025 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1026 # TODO: strip out spaces, comments, like git-commit.sh
1027 system($editor, $commit_editmsg);
1028 }
1029 rename $commit_editmsg, $commit_msg or croak $!;
1030 open $log_fh, '<', $commit_msg or croak $!;
1031 { local $/; chomp($log_entry{log} = <$log_fh>); }
1032 close $log_fh or croak $!;
1033 unlink $commit_msg;
1034 \%log_entry;
1035 }
1036
1037 sub s_to_file {
1038 my ($str, $file, $mode) = @_;
1039 open my $fd,'>',$file or croak $!;
1040 print $fd $str,"\n" or croak $!;
1041 close $fd or croak $!;
1042 chmod ($mode &~ umask, $file) if (defined $mode);
1043 }
1044
1045 sub file_to_s {
1046 my $file = shift;
1047 open my $fd,'<',$file or croak "$!: file: $file\n";
1048 local $/;
1049 my $ret = <$fd>;
1050 close $fd or croak $!;
1051 $ret =~ s/\s*$//s;
1052 return $ret;
1053 }
1054
1055 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1056 sub load_authors {
1057 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1058 my $log = $cmd eq 'log';
1059 while (<$authors>) {
1060 chomp;
1061 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1062 my ($user, $name, $email) = ($1, $2, $3);
1063 if ($log) {
1064 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1065 } else {
1066 $users{$user} = [$name, $email];
1067 }
1068 }
1069 close $authors or croak $!;
1070 }
1071
1072 # convert GetOpt::Long specs for use by git-config
1073 sub read_repo_config {
1074 return unless -d $ENV{GIT_DIR};
1075 my $opts = shift;
1076 my @config_only;
1077 foreach my $o (keys %$opts) {
1078 # if we have mixedCase and a long option-only, then
1079 # it's a config-only variable that we don't need for
1080 # the command-line.
1081 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1082 my $v = $opts->{$o};
1083 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1084 $key =~ s/-//g;
1085 my $arg = 'git-config';
1086 $arg .= ' --int' if ($o =~ /[:=]i$/);
1087 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1088 if (ref $v eq 'ARRAY') {
1089 chomp(my @tmp = `$arg --get-all svn.$key`);
1090 @$v = @tmp if @tmp;
1091 } else {
1092 chomp(my $tmp = `$arg --get svn.$key`);
1093 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1094 $$v = $tmp;
1095 }
1096 }
1097 }
1098 delete @$opts{@config_only} if @config_only;
1099 }
1100
1101 sub extract_metadata {
1102 my $id = shift or return (undef, undef, undef);
1103 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1104 \s([a-f\d\-]+)$/x);
1105 if (!defined $rev || !$uuid || !$url) {
1106 # some of the original repositories I made had
1107 # identifiers like this:
1108 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1109 }
1110 return ($url, $rev, $uuid);
1111 }
1112
1113 sub cmt_metadata {
1114 return extract_metadata((grep(/^git-svn-id: /,
1115 command(qw/cat-file commit/, shift)))[-1]);
1116 }
1117
1118 sub working_head_info {
1119 my ($head, $refs) = @_;
1120 my @args = ('log', '--no-color', '--first-parent');
1121 my ($fh, $ctx) = command_output_pipe(@args, $head);
1122 my $hash;
1123 my %max;
1124 while (<$fh>) {
1125 if ( m{^commit ($::sha1)$} ) {
1126 unshift @$refs, $hash if $hash and $refs;
1127 $hash = $1;
1128 next;
1129 }
1130 next unless s{^\s*(git-svn-id:)}{$1};
1131 my ($url, $rev, $uuid) = extract_metadata($_);
1132 if (defined $url && defined $rev) {
1133 next if $max{$url} and $max{$url} < $rev;
1134 if (my $gs = Git::SVN->find_by_url($url)) {
1135 my $c = $gs->rev_map_get($rev);
1136 if ($c && $c eq $hash) {
1137 close $fh; # break the pipe
1138 return ($url, $rev, $uuid, $gs);
1139 } else {
1140 $max{$url} ||= $gs->rev_map_max;
1141 }
1142 }
1143 }
1144 }
1145 command_close_pipe($fh, $ctx);
1146 (undef, undef, undef, undef);
1147 }
1148
1149 sub read_commit_parents {
1150 my ($parents, $c) = @_;
1151 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1152 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1153 @{$parents->{$c}} = split(/ /, $p);
1154 }
1155
1156 sub linearize_history {
1157 my ($gs, $refs) = @_;
1158 my %parents;
1159 foreach my $c (@$refs) {
1160 read_commit_parents(\%parents, $c);
1161 }
1162
1163 my @linear_refs;
1164 my %skip = ();
1165 my $last_svn_commit = $gs->last_commit;
1166 foreach my $c (reverse @$refs) {
1167 next if $c eq $last_svn_commit;
1168 last if $skip{$c};
1169
1170 unshift @linear_refs, $c;
1171 $skip{$c} = 1;
1172
1173 # we only want the first parent to diff against for linear
1174 # history, we save the rest to inject when we finalize the
1175 # svn commit
1176 my $fp_a = verify_ref("$c~1");
1177 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1178 if (!$fp_a || !$fp_b) {
1179 die "Commit $c\n",
1180 "has no parent commit, and therefore ",
1181 "nothing to diff against.\n",
1182 "You should be working from a repository ",
1183 "originally created by git-svn\n";
1184 }
1185 if ($fp_a ne $fp_b) {
1186 die "$c~1 = $fp_a, however parsing commit $c ",
1187 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1188 }
1189
1190 foreach my $p (@{$parents{$c}}) {
1191 $skip{$p} = 1;
1192 }
1193 }
1194 (\@linear_refs, \%parents);
1195 }
1196
1197 sub find_file_type_and_diff_status {
1198 my ($path) = @_;
1199 return ('dir', '') if $path eq '.';
1200
1201 my $diff_output =
1202 command_oneline(qw(diff --cached --name-status --), $path) || "";
1203 my $diff_status = (split(' ', $diff_output))[0] || "";
1204
1205 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1206
1207 return (undef, undef) if !$diff_status && !$ls_tree;
1208
1209 if ($diff_status eq "A") {
1210 return ("link", $diff_status) if -l $path;
1211 return ("dir", $diff_status) if -d $path;
1212 return ("file", $diff_status);
1213 }
1214
1215 my $mode = (split(' ', $ls_tree))[0] || "";
1216
1217 return ("link", $diff_status) if $mode eq "120000";
1218 return ("dir", $diff_status) if $mode eq "040000";
1219 return ("file", $diff_status);
1220 }
1221
1222 sub md5sum {
1223 my $arg = shift;
1224 my $ref = ref $arg;
1225 my $md5 = Digest::MD5->new();
1226 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1227 $md5->addfile($arg) or croak $!;
1228 } elsif ($ref eq 'SCALAR') {
1229 $md5->add($$arg) or croak $!;
1230 } elsif (!$ref) {
1231 $md5->add($arg) or croak $!;
1232 } else {
1233 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1234 }
1235 return $md5->hexdigest();
1236 }
1237
1238 package Git::SVN;
1239 use strict;
1240 use warnings;
1241 use Fcntl qw/:DEFAULT :seek/;
1242 use constant rev_map_fmt => 'NH40';
1243 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1244 $_repack $_repack_flags $_use_svm_props $_head
1245 $_use_svnsync_props $no_reuse_existing $_minimize_url
1246 $_use_log_author/;
1247 use Carp qw/croak/;
1248 use File::Path qw/mkpath/;
1249 use File::Copy qw/copy/;
1250 use IPC::Open3;
1251
1252 my $_repack_nr;
1253 # properties that we do not log:
1254 my %SKIP_PROP;
1255 BEGIN {
1256 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1257 svn:special svn:executable
1258 svn:entry:committed-rev
1259 svn:entry:last-author
1260 svn:entry:uuid
1261 svn:entry:committed-date/;
1262
1263 # some options are read globally, but can be overridden locally
1264 # per [svn-remote "..."] section. Command-line options will *NOT*
1265 # override options set in an [svn-remote "..."] section
1266 no strict 'refs';
1267 for my $option (qw/follow_parent no_metadata use_svm_props
1268 use_svnsync_props/) {
1269 my $key = $option;
1270 $key =~ tr/_//d;
1271 my $prop = "-$option";
1272 *$option = sub {
1273 my ($self) = @_;
1274 return $self->{$prop} if exists $self->{$prop};
1275 my $k = "svn-remote.$self->{repo_id}.$key";
1276 eval { command_oneline(qw/config --get/, $k) };
1277 if ($@) {
1278 $self->{$prop} = ${"Git::SVN::_$option"};
1279 } else {
1280 my $v = command_oneline(qw/config --bool/,$k);
1281 $self->{$prop} = $v eq 'false' ? 0 : 1;
1282 }
1283 return $self->{$prop};
1284 }
1285 }
1286 }
1287
1288 my (%LOCKFILES, %INDEX_FILES);
1289 END {
1290 unlink keys %LOCKFILES if %LOCKFILES;
1291 unlink keys %INDEX_FILES if %INDEX_FILES;
1292 }
1293
1294 sub resolve_local_globs {
1295 my ($url, $fetch, $glob_spec) = @_;
1296 return unless defined $glob_spec;
1297 my $ref = $glob_spec->{ref};
1298 my $path = $glob_spec->{path};
1299 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1300 next unless m#^refs/remotes/$ref->{regex}$#;
1301 my $p = $1;
1302 my $pathname = desanitize_refname($path->full_path($p));
1303 my $refname = desanitize_refname($ref->full_path($p));
1304 if (my $existing = $fetch->{$pathname}) {
1305 if ($existing ne $refname) {
1306 die "Refspec conflict:\n",
1307 "existing: refs/remotes/$existing\n",
1308 " globbed: refs/remotes/$refname\n";
1309 }
1310 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1311 $u =~ s!^\Q$url\E(/|$)!! or die
1312 "refs/remotes/$refname: '$url' not found in '$u'\n";
1313 if ($pathname ne $u) {
1314 warn "W: Refspec glob conflict ",
1315 "(ref: refs/remotes/$refname):\n",
1316 "expected path: $pathname\n",
1317 " real path: $u\n",
1318 "Continuing ahead with $u\n";
1319 next;
1320 }
1321 } else {
1322 $fetch->{$pathname} = $refname;
1323 }
1324 }
1325 }
1326
1327 sub parse_revision_argument {
1328 my ($base, $head) = @_;
1329 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1330 return ($base, $head);
1331 }
1332 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1333 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1334 return ($head, $head) if ($::_revision eq 'HEAD');
1335 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1336 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1337 die "revision argument: $::_revision not understood by git-svn\n";
1338 }
1339
1340 sub fetch_all {
1341 my ($repo_id, $remotes) = @_;
1342 if (ref $repo_id) {
1343 my $gs = $repo_id;
1344 $repo_id = undef;
1345 $repo_id = $gs->{repo_id};
1346 }
1347 $remotes ||= read_all_remotes();
1348 my $remote = $remotes->{$repo_id} or
1349 die "[svn-remote \"$repo_id\"] unknown\n";
1350 my $fetch = $remote->{fetch};
1351 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1352 my (@gs, @globs);
1353 my $ra = Git::SVN::Ra->new($url);
1354 my $uuid = $ra->get_uuid;
1355 my $head = $ra->get_latest_revnum;
1356 my $base = defined $fetch ? $head : 0;
1357
1358 # read the max revs for wildcard expansion (branches/*, tags/*)
1359 foreach my $t (qw/branches tags/) {
1360 defined $remote->{$t} or next;
1361 push @globs, $remote->{$t};
1362 my $max_rev = eval { tmp_config(qw/--int --get/,
1363 "svn-remote.$repo_id.${t}-maxRev") };
1364 if (defined $max_rev && ($max_rev < $base)) {
1365 $base = $max_rev;
1366 } elsif (!defined $max_rev) {
1367 $base = 0;
1368 }
1369 }
1370
1371 if ($fetch) {
1372 foreach my $p (sort keys %$fetch) {
1373 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1374 my $lr = $gs->rev_map_max;
1375 if (defined $lr) {
1376 $base = $lr if ($lr < $base);
1377 }
1378 push @gs, $gs;
1379 }
1380 }
1381
1382 ($base, $head) = parse_revision_argument($base, $head);
1383 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1384 }
1385
1386 sub read_all_remotes {
1387 my $r = {};
1388 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1389 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1390 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1391 $local_ref =~ s{^/}{};
1392 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1393 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1394 $r->{$1}->{url} = $2;
1395 } elsif (m!^(.+)\.(branches|tags)=
1396 (.*):refs/remotes/(.+)\s*$/!x) {
1397 my ($p, $g) = ($3, $4);
1398 my $rs = $r->{$1}->{$2} = {
1399 t => $2,
1400 remote => $1,
1401 path => Git::SVN::GlobSpec->new($p),
1402 ref => Git::SVN::GlobSpec->new($g) };
1403 if (length($rs->{ref}->{right}) != 0) {
1404 die "The '*' glob character must be the last ",
1405 "character of '$g'\n";
1406 }
1407 }
1408 }
1409 $r;
1410 }
1411
1412 sub init_vars {
1413 $_repack = 1000 unless (defined $_repack && $_repack > 0);
1414 $_repack_nr = $_repack;
1415 $_repack_flags ||= '-d';
1416 }
1417
1418 sub verify_remotes_sanity {
1419 return unless -d $ENV{GIT_DIR};
1420 my %seen;
1421 foreach (command(qw/config -l/)) {
1422 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1423 if ($seen{$1}) {
1424 die "Remote ref refs/remote/$1 is tracked by",
1425 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1426 "Please resolve this ambiguity in ",
1427 "your git configuration file before ",
1428 "continuing\n";
1429 }
1430 $seen{$1} = $_;
1431 }
1432 }
1433 }
1434
1435 # we allow more chars than remotes2config.sh...
1436 sub sanitize_remote_name {
1437 my ($name) = @_;
1438 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1439 $name;
1440 }
1441
1442 sub find_existing_remote {
1443 my ($url, $remotes) = @_;
1444 return undef if $no_reuse_existing;
1445 my $existing;
1446 foreach my $repo_id (keys %$remotes) {
1447 my $u = $remotes->{$repo_id}->{url} or next;
1448 next if $u ne $url;
1449 $existing = $repo_id;
1450 last;
1451 }
1452 $existing;
1453 }
1454
1455 sub init_remote_config {
1456 my ($self, $url, $no_write) = @_;
1457 $url =~ s!/+$!!; # strip trailing slash
1458 my $r = read_all_remotes();
1459 my $existing = find_existing_remote($url, $r);
1460 if ($existing) {
1461 unless ($no_write) {
1462 print STDERR "Using existing ",
1463 "[svn-remote \"$existing\"]\n";
1464 }
1465 $self->{repo_id} = $existing;
1466 } elsif ($_minimize_url) {
1467 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1468 $existing = find_existing_remote($min_url, $r);
1469 if ($existing) {
1470 unless ($no_write) {
1471 print STDERR "Using existing ",
1472 "[svn-remote \"$existing\"]\n";
1473 }
1474 $self->{repo_id} = $existing;
1475 }
1476 if ($min_url ne $url) {
1477 unless ($no_write) {
1478 print STDERR "Using higher level of URL: ",
1479 "$url => $min_url\n";
1480 }
1481 my $old_path = $self->{path};
1482 $self->{path} = $url;
1483 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1484 if (length $old_path) {
1485 $self->{path} .= "/$old_path";
1486 }
1487 $url = $min_url;
1488 }
1489 }
1490 my $orig_url;
1491 if (!$existing) {
1492 # verify that we aren't overwriting anything:
1493 $orig_url = eval {
1494 command_oneline('config', '--get',
1495 "svn-remote.$self->{repo_id}.url")
1496 };
1497 if ($orig_url && ($orig_url ne $url)) {
1498 die "svn-remote.$self->{repo_id}.url already set: ",
1499 "$orig_url\nwanted to set to: $url\n";
1500 }
1501 }
1502 my ($xrepo_id, $xpath) = find_ref($self->refname);
1503 if (defined $xpath) {
1504 die "svn-remote.$xrepo_id.fetch already set to track ",
1505 "$xpath:refs/remotes/", $self->refname, "\n";
1506 }
1507 unless ($no_write) {
1508 command_noisy('config',
1509 "svn-remote.$self->{repo_id}.url", $url);
1510 $self->{path} =~ s{^/}{};
1511 command_noisy('config', '--add',
1512 "svn-remote.$self->{repo_id}.fetch",
1513 "$self->{path}:".$self->refname);
1514 }
1515 $self->{url} = $url;
1516 }
1517
1518 sub find_by_url { # repos_root and, path are optional
1519 my ($class, $full_url, $repos_root, $path) = @_;
1520
1521 return undef unless defined $full_url;
1522 remove_username($full_url);
1523 remove_username($repos_root) if defined $repos_root;
1524 my $remotes = read_all_remotes();
1525 if (defined $full_url && defined $repos_root && !defined $path) {
1526 $path = $full_url;
1527 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1528 }
1529 foreach my $repo_id (keys %$remotes) {
1530 my $u = $remotes->{$repo_id}->{url} or next;
1531 remove_username($u);
1532 next if defined $repos_root && $repos_root ne $u;
1533
1534 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1535 foreach (qw/branches tags/) {
1536 resolve_local_globs($u, $fetch,
1537 $remotes->{$repo_id}->{$_});
1538 }
1539 my $p = $path;
1540 my $rwr = rewrite_root({repo_id => $repo_id});
1541 unless (defined $p) {
1542 $p = $full_url;
1543 my $z = $u;
1544 if ($rwr) {
1545 $z = $rwr;
1546 }
1547 $p =~ s#^\Q$z\E(?:/|$)## or next;
1548 }
1549 foreach my $f (keys %$fetch) {
1550 next if $f ne $p;
1551 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1552 }
1553 }
1554 undef;
1555 }
1556
1557 sub init {
1558 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1559 my $self = _new($class, $repo_id, $ref_id, $path);
1560 if (defined $url) {
1561 $self->init_remote_config($url, $no_write);
1562 }
1563 $self;
1564 }
1565
1566 sub find_ref {
1567 my ($ref_id) = @_;
1568 foreach (command(qw/config -l/)) {
1569 next unless m!^svn-remote\.(.+)\.fetch=
1570 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1571 my ($repo_id, $path, $ref) = ($1, $2, $3);
1572 if ($ref eq $ref_id) {
1573 $path = '' if ($path =~ m#^\./?#);
1574 return ($repo_id, $path);
1575 }
1576 }
1577 (undef, undef, undef);
1578 }
1579
1580 sub new {
1581 my ($class, $ref_id, $repo_id, $path) = @_;
1582 if (defined $ref_id && !defined $repo_id && !defined $path) {
1583 ($repo_id, $path) = find_ref($ref_id);
1584 if (!defined $repo_id) {
1585 die "Could not find a \"svn-remote.*.fetch\" key ",
1586 "in the repository configuration matching: ",
1587 "refs/remotes/$ref_id\n";
1588 }
1589 }
1590 my $self = _new($class, $repo_id, $ref_id, $path);
1591 if (!defined $self->{path} || !length $self->{path}) {
1592 my $fetch = command_oneline('config', '--get',
1593 "svn-remote.$repo_id.fetch",
1594 ":refs/remotes/$ref_id\$") or
1595 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1596 "\":refs/remotes/$ref_id\$\" in config\n";
1597 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1598 }
1599 $self->{url} = command_oneline('config', '--get',
1600 "svn-remote.$repo_id.url") or
1601 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1602 $self->rebuild;
1603 $self;
1604 }
1605
1606 sub refname {
1607 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1608
1609 # It cannot end with a slash /, we'll throw up on this because
1610 # SVN can't have directories with a slash in their name, either:
1611 if ($refname =~ m{/$}) {
1612 die "ref: '$refname' ends with a trailing slash, this is ",
1613 "not permitted by git nor Subversion\n";
1614 }
1615
1616 # It cannot have ASCII control character space, tilde ~, caret ^,
1617 # colon :, question-mark ?, asterisk *, space, or open bracket [
1618 # anywhere.
1619 #
1620 # Additionally, % must be escaped because it is used for escaping
1621 # and we want our escaped refname to be reversible
1622 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1623
1624 # no slash-separated component can begin with a dot .
1625 # /.* becomes /%2E*
1626 $refname =~ s{/\.}{/%2E}g;
1627
1628 # It cannot have two consecutive dots .. anywhere
1629 # .. becomes %2E%2E
1630 $refname =~ s{\.\.}{%2E%2E}g;
1631
1632 return $refname;
1633 }
1634
1635 sub desanitize_refname {
1636 my ($refname) = @_;
1637 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1638 return $refname;
1639 }
1640
1641 sub svm_uuid {
1642 my ($self) = @_;
1643 return $self->{svm}->{uuid} if $self->svm;
1644 $self->ra;
1645 unless ($self->{svm}) {
1646 die "SVM UUID not cached, and reading remotely failed\n";
1647 }
1648 $self->{svm}->{uuid};
1649 }
1650
1651 sub svm {
1652 my ($self) = @_;
1653 return $self->{svm} if $self->{svm};
1654 my $svm;
1655 # see if we have it in our config, first:
1656 eval {
1657 my $section = "svn-remote.$self->{repo_id}";
1658 $svm = {
1659 source => tmp_config('--get', "$section.svm-source"),
1660 uuid => tmp_config('--get', "$section.svm-uuid"),
1661 replace => tmp_config('--get', "$section.svm-replace"),
1662 }
1663 };
1664 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1665 $self->{svm} = $svm;
1666 }
1667 $self->{svm};
1668 }
1669
1670 sub _set_svm_vars {
1671 my ($self, $ra) = @_;
1672 return $ra if $self->svm;
1673
1674 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1675 "(svm:source, svm:uuid) ",
1676 "from the following URLs:\n" );
1677 sub read_svm_props {
1678 my ($self, $ra, $path, $r) = @_;
1679 my $props = ($ra->get_dir($path, $r))[2];
1680 my $src = $props->{'svm:source'};
1681 my $uuid = $props->{'svm:uuid'};
1682 return undef if (!$src || !$uuid);
1683
1684 chomp($src, $uuid);
1685
1686 $uuid =~ m{^[0-9a-f\-]{30,}$}
1687 or die "doesn't look right - svm:uuid is '$uuid'\n";
1688
1689 # the '!' is used to mark the repos_root!/relative/path
1690 $src =~ s{/?!/?}{/};
1691 $src =~ s{/+$}{}; # no trailing slashes please
1692 # username is of no interest
1693 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1694
1695 my $replace = $ra->{url};
1696 $replace .= "/$path" if length $path;
1697
1698 my $section = "svn-remote.$self->{repo_id}";
1699 tmp_config("$section.svm-source", $src);
1700 tmp_config("$section.svm-replace", $replace);
1701 tmp_config("$section.svm-uuid", $uuid);
1702 $self->{svm} = {
1703 source => $src,
1704 uuid => $uuid,
1705 replace => $replace
1706 };
1707 }
1708
1709 my $r = $ra->get_latest_revnum;
1710 my $path = $self->{path};
1711 my %tried;
1712 while (length $path) {
1713 unless ($tried{"$self->{url}/$path"}) {
1714 return $ra if $self->read_svm_props($ra, $path, $r);
1715 $tried{"$self->{url}/$path"} = 1;
1716 }
1717 $path =~ s#/?[^/]+$##;
1718 }
1719 die "Path: '$path' should be ''\n" if $path ne '';
1720 return $ra if $self->read_svm_props($ra, $path, $r);
1721 $tried{"$self->{url}/$path"} = 1;
1722
1723 if ($ra->{repos_root} eq $self->{url}) {
1724 die @err, (map { " $_\n" } keys %tried), "\n";
1725 }
1726
1727 # nope, make sure we're connected to the repository root:
1728 my $ok;
1729 my @tried_b;
1730 $path = $ra->{svn_path};
1731 $ra = Git::SVN::Ra->new($ra->{repos_root});
1732 while (length $path) {
1733 unless ($tried{"$ra->{url}/$path"}) {
1734 $ok = $self->read_svm_props($ra, $path, $r);
1735 last if $ok;
1736 $tried{"$ra->{url}/$path"} = 1;
1737 }
1738 $path =~ s#/?[^/]+$##;
1739 }
1740 die "Path: '$path' should be ''\n" if $path ne '';
1741 $ok ||= $self->read_svm_props($ra, $path, $r);
1742 $tried{"$ra->{url}/$path"} = 1;
1743 if (!$ok) {
1744 die @err, (map { " $_\n" } keys %tried), "\n";
1745 }
1746 Git::SVN::Ra->new($self->{url});
1747 }
1748
1749 sub svnsync {
1750 my ($self) = @_;
1751 return $self->{svnsync} if $self->{svnsync};
1752
1753 if ($self->no_metadata) {
1754 die "Can't have both 'noMetadata' and ",
1755 "'useSvnsyncProps' options set!\n";
1756 }
1757 if ($self->rewrite_root) {
1758 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1759 "options set!\n";
1760 }
1761
1762 my $svnsync;
1763 # see if we have it in our config, first:
1764 eval {
1765 my $section = "svn-remote.$self->{repo_id}";
1766
1767 my $url = tmp_config('--get', "$section.svnsync-url");
1768 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1769 die "doesn't look right - svn:sync-from-url is '$url'\n";
1770
1771 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1772 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1773 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1774
1775 $svnsync = { url => $url, uuid => $uuid }
1776 };
1777 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1778 return $self->{svnsync} = $svnsync;
1779 }
1780
1781 my $err = "useSvnsyncProps set, but failed to read " .
1782 "svnsync property: svn:sync-from-";
1783 my $rp = $self->ra->rev_proplist(0);
1784
1785 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1786 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1787 die "doesn't look right - svn:sync-from-url is '$url'\n";
1788
1789 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1790 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1791 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1792
1793 my $section = "svn-remote.$self->{repo_id}";
1794 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1795 tmp_config('--add', "$section.svnsync-url", $url);
1796 return $self->{svnsync} = { url => $url, uuid => $uuid };
1797 }
1798
1799 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1800 # remote lookup (useful for 'git svn log').
1801 sub ra_uuid {
1802 my ($self) = @_;
1803 unless ($self->{ra_uuid}) {
1804 my $key = "svn-remote.$self->{repo_id}.uuid";
1805 my $uuid = eval { tmp_config('--get', $key) };
1806 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1807 $self->{ra_uuid} = $uuid;
1808 } else {
1809 die "ra_uuid called without URL\n" unless $self->{url};
1810 $self->{ra_uuid} = $self->ra->get_uuid;
1811 tmp_config('--add', $key, $self->{ra_uuid});
1812 }
1813 }
1814 $self->{ra_uuid};
1815 }
1816
1817 sub _set_repos_root {
1818 my ($self, $repos_root) = @_;
1819 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1820 $repos_root ||= $self->ra->{repos_root};
1821 tmp_config($k, $repos_root);
1822 $repos_root;
1823 }
1824
1825 sub repos_root {
1826 my ($self) = @_;
1827 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1828 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1829 }
1830
1831 sub ra {
1832 my ($self) = shift;
1833 my $ra = Git::SVN::Ra->new($self->{url});
1834 $self->_set_repos_root($ra->{repos_root});
1835 if ($self->use_svm_props && !$self->{svm}) {
1836 if ($self->no_metadata) {
1837 die "Can't have both 'noMetadata' and ",
1838 "'useSvmProps' options set!\n";
1839 } elsif ($self->use_svnsync_props) {
1840 die "Can't have both 'useSvnsyncProps' and ",
1841 "'useSvmProps' options set!\n";
1842 }
1843 $ra = $self->_set_svm_vars($ra);
1844 $self->{-want_revprops} = 1;
1845 }
1846 $ra;
1847 }
1848
1849 sub rel_path {
1850 my ($self) = @_;
1851 my $repos_root = $self->ra->{repos_root};
1852 return $self->{path} if ($self->{url} eq $repos_root);
1853 my $url = $self->{url} .
1854 (length $self->{path} ? "/$self->{path}" : $self->{path});
1855 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1856 $url;
1857 }
1858
1859 # prop_walk(PATH, REV, SUB)
1860 # -------------------------
1861 # Recursively traverse PATH at revision REV and invoke SUB for each
1862 # directory that contains a SVN property. SUB will be invoked as
1863 # follows: &SUB(gs, path, props); where `gs' is this instance of
1864 # Git::SVN, `path' the path to the directory where the properties
1865 # `props' were found. The `path' will be relative to point of checkout,
1866 # that is, if url://repo/trunk is the current Git branch, and that
1867 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1868 # as `path' (note the trailing `/').
1869 sub prop_walk {
1870 my ($self, $path, $rev, $sub) = @_;
1871
1872 $path =~ s#^/##;
1873 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1874 $path =~ s#^/*#/#g;
1875 my $p = $path;
1876 # Strip the irrelevant part of the path.
1877 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1878 # Ensure the path is terminated by a `/'.
1879 $p =~ s#/*$#/#;
1880
1881 # The properties contain all the internal SVN stuff nobody
1882 # (usually) cares about.
1883 my $interesting_props = 0;
1884 foreach (keys %{$props}) {
1885 # If it doesn't start with `svn:', it must be a
1886 # user-defined property.
1887 ++$interesting_props and next if $_ !~ /^svn:/;
1888 # FIXME: Fragile, if SVN adds new public properties,
1889 # this needs to be updated.
1890 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1891 |eol-style|mime-type
1892 |externals|needs-lock)$/x;
1893 }
1894 &$sub($self, $p, $props) if $interesting_props;
1895
1896 foreach (sort keys %$dirent) {
1897 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1898 $self->prop_walk($path . '/' . $_, $rev, $sub);
1899 }
1900 }
1901
1902 sub last_rev { ($_[0]->last_rev_commit)[0] }
1903 sub last_commit { ($_[0]->last_rev_commit)[1] }
1904
1905 # returns the newest SVN revision number and newest commit SHA1
1906 sub last_rev_commit {
1907 my ($self) = @_;
1908 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1909 return ($self->{last_rev}, $self->{last_commit});
1910 }
1911 my $c = ::verify_ref($self->refname.'^0');
1912 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1913 my $rev = (::cmt_metadata($c))[1];
1914 if (defined $rev) {
1915 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1916 return ($rev, $c);
1917 }
1918 }
1919 my $map_path = $self->map_path;
1920 unless (-e $map_path) {
1921 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1922 return (undef, undef);
1923 }
1924 my ($rev, $commit) = $self->rev_map_max(1);
1925 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1926 return ($rev, $commit);
1927 }
1928
1929 sub get_fetch_range {
1930 my ($self, $min, $max) = @_;
1931 $max ||= $self->ra->get_latest_revnum;
1932 $min ||= $self->rev_map_max;
1933 (++$min, $max);
1934 }
1935
1936 sub tmp_config {
1937 my (@args) = @_;
1938 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1939 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1940 if (! -f $config && -f $old_def_config) {
1941 rename $old_def_config, $config or
1942 die "Failed rename $old_def_config => $config: $!\n";
1943 }
1944 my $old_config = $ENV{GIT_CONFIG};
1945 $ENV{GIT_CONFIG} = $config;
1946 $@ = undef;
1947 my @ret = eval {
1948 unless (-f $config) {
1949 mkfile($config);
1950 open my $fh, '>', $config or
1951 die "Can't open $config: $!\n";
1952 print $fh "; This file is used internally by ",
1953 "git-svn\n" or die
1954 "Couldn't write to $config: $!\n";
1955 print $fh "; You should not have to edit it\n" or
1956 die "Couldn't write to $config: $!\n";
1957 close $fh or die "Couldn't close $config: $!\n";
1958 }
1959 command('config', @args);
1960 };
1961 my $err = $@;
1962 if (defined $old_config) {
1963 $ENV{GIT_CONFIG} = $old_config;
1964 } else {
1965 delete $ENV{GIT_CONFIG};
1966 }
1967 die $err if $err;
1968 wantarray ? @ret : $ret[0];
1969 }
1970
1971 sub tmp_index_do {
1972 my ($self, $sub) = @_;
1973 my $old_index = $ENV{GIT_INDEX_FILE};
1974 $ENV{GIT_INDEX_FILE} = $self->{index};
1975 $@ = undef;
1976 my @ret = eval {
1977 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1978 mkpath([$dir]) unless -d $dir;
1979 &$sub;
1980 };
1981 my $err = $@;
1982 if (defined $old_index) {
1983 $ENV{GIT_INDEX_FILE} = $old_index;
1984 } else {
1985 delete $ENV{GIT_INDEX_FILE};
1986 }
1987 die $err if $err;
1988 wantarray ? @ret : $ret[0];
1989 }
1990
1991 sub assert_index_clean {
1992 my ($self, $treeish) = @_;
1993
1994 $self->tmp_index_do(sub {
1995 command_noisy('read-tree', $treeish) unless -e $self->{index};
1996 my $x = command_oneline('write-tree');
1997 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1998 /^tree ($::sha1)/mo);
1999 return if $y eq $x;
2000
2001 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2002 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2003 command_noisy('read-tree', $treeish);
2004 $x = command_oneline('write-tree');
2005 if ($y ne $x) {
2006 ::fatal "trees ($treeish) $y != $x\n",
2007 "Something is seriously wrong...";
2008 }
2009 });
2010 }
2011
2012 sub get_commit_parents {
2013 my ($self, $log_entry) = @_;
2014 my (%seen, @ret, @tmp);
2015 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2016 if (my $ip = $self->{inject_parents}) {
2017 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2018 push @tmp, $commit;
2019 }
2020 }
2021 if (my $cur = ::verify_ref($self->refname.'^0')) {
2022 push @tmp, $cur;
2023 }
2024 if (my $ipd = $self->{inject_parents_dcommit}) {
2025 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2026 push @tmp, @$commit;
2027 }
2028 }
2029 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2030 while (my $p = shift @tmp) {
2031 next if $seen{$p};
2032 $seen{$p} = 1;
2033 push @ret, $p;
2034 # MAXPARENT is defined to 16 in commit-tree.c:
2035 last if @ret >= 16;
2036 }
2037 if (@tmp) {
2038 die "r$log_entry->{revision}: No room for parents:\n\t",
2039 join("\n\t", @tmp), "\n";
2040 }
2041 @ret;
2042 }
2043
2044 sub rewrite_root {
2045 my ($self) = @_;
2046 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2047 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2048 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2049 if ($rwr) {
2050 $rwr =~ s#/+$##;
2051 if ($rwr !~ m#^[a-z\+]+://#) {
2052 die "$rwr is not a valid URL (key: $k)\n";
2053 }
2054 }
2055 $self->{-rewrite_root} = $rwr;
2056 }
2057
2058 sub metadata_url {
2059 my ($self) = @_;
2060 ($self->rewrite_root || $self->{url}) .
2061 (length $self->{path} ? '/' . $self->{path} : '');
2062 }
2063
2064 sub full_url {
2065 my ($self) = @_;
2066 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2067 }
2068
2069
2070 sub set_commit_header_env {
2071 my ($log_entry) = @_;
2072 my %env;
2073 foreach my $ned (qw/NAME EMAIL DATE/) {
2074 foreach my $ac (qw/AUTHOR COMMITTER/) {
2075 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2076 }
2077 }
2078
2079 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2080 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2081 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2082
2083 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2084 ? $log_entry->{commit_name}
2085 : $log_entry->{name};
2086 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2087 ? $log_entry->{commit_email}
2088 : $log_entry->{email};
2089 \%env;
2090 }
2091
2092 sub restore_commit_header_env {
2093 my ($env) = @_;
2094 foreach my $ned (qw/NAME EMAIL DATE/) {
2095 foreach my $ac (qw/AUTHOR COMMITTER/) {
2096 my $k = "GIT_${ac}_${ned}";
2097 if (defined $env->{$k}) {
2098 $ENV{$k} = $env->{$k};
2099 } else {
2100 delete $ENV{$k};
2101 }
2102 }
2103 }
2104 }
2105
2106 sub do_git_commit {
2107 my ($self, $log_entry) = @_;
2108 my $lr = $self->last_rev;
2109 if (defined $lr && $lr >= $log_entry->{revision}) {
2110 die "Last fetched revision of ", $self->refname,
2111 " was r$lr, but we are about to fetch: ",
2112 "r$log_entry->{revision}!\n";
2113 }
2114 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2115 croak "$log_entry->{revision} = $c already exists! ",
2116 "Why are we refetching it?\n";
2117 }
2118 my $old_env = set_commit_header_env($log_entry);
2119 my $tree = $log_entry->{tree};
2120 if (!defined $tree) {
2121 $tree = $self->tmp_index_do(sub {
2122 command_oneline('write-tree') });
2123 }
2124 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2125
2126 my @exec = ('git-commit-tree', $tree);
2127 foreach ($self->get_commit_parents($log_entry)) {
2128 push @exec, '-p', $_;
2129 }
2130 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2131 or croak $!;
2132 print $msg_fh $log_entry->{log} or croak $!;
2133 restore_commit_header_env($old_env);
2134 unless ($self->no_metadata) {
2135 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2136 or croak $!;
2137 }
2138 $msg_fh->flush == 0 or croak $!;
2139 close $msg_fh or croak $!;
2140 chomp(my $commit = do { local $/; <$out_fh> });
2141 close $out_fh or croak $!;
2142 waitpid $pid, 0;
2143 croak $? if $?;
2144 if ($commit !~ /^$::sha1$/o) {
2145 die "Failed to commit, invalid sha1: $commit\n";
2146 }
2147
2148 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2149
2150 $self->{last_rev} = $log_entry->{revision};
2151 $self->{last_commit} = $commit;
2152 print "r$log_entry->{revision}";
2153 if (defined $log_entry->{svm_revision}) {
2154 print " (\@$log_entry->{svm_revision})";
2155 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2156 0, $self->svm_uuid);
2157 }
2158 print " = $commit ($self->{ref_id})\n";
2159 if ($_repack && (--$_repack_nr == 0)) {
2160 $_repack_nr = $_repack;
2161 # repack doesn't use any arguments with spaces in them, does it?
2162 print "Running git repack $_repack_flags ...\n";
2163 command_noisy('repack', split(/\s+/, $_repack_flags));
2164 print "Done repacking\n";
2165 }
2166 return $commit;
2167 }
2168
2169 sub match_paths {
2170 my ($self, $paths, $r) = @_;
2171 return 1 if $self->{path} eq '';
2172 if (my $path = $paths->{"/$self->{path}"}) {
2173 return ($path->{action} eq 'D') ? 0 : 1;
2174 }
2175 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2176 if (grep /$self->{path_regex}/, keys %$paths) {
2177 return 1;
2178 }
2179 my $c = '';
2180 foreach (split m#/#, $self->{path}) {
2181 $c .= "/$_";
2182 next unless ($paths->{$c} &&
2183 ($paths->{$c}->{action} =~ /^[AR]$/));
2184 if ($self->ra->check_path($self->{path}, $r) ==
2185 $SVN::Node::dir) {
2186 return 1;
2187 }
2188 }
2189 return 0;
2190 }
2191
2192 sub find_parent_branch {
2193 my ($self, $paths, $rev) = @_;
2194 return undef unless $self->follow_parent;
2195 unless (defined $paths) {
2196 my $err_handler = $SVN::Error::handler;
2197 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2198 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2199 $paths =
2200 Git::SVN::Ra::dup_changed_paths($_[0]) });
2201 $SVN::Error::handler = $err_handler;
2202 }
2203 return undef unless defined $paths;
2204
2205 # look for a parent from another branch:
2206 my @b_path_components = split m#/#, $self->rel_path;
2207 my @a_path_components;
2208 my $i;
2209 while (@b_path_components) {
2210 $i = $paths->{'/'.join('/', @b_path_components)};
2211 last if $i && defined $i->{copyfrom_path};
2212 unshift(@a_path_components, pop(@b_path_components));
2213 }
2214 return undef unless defined $i && defined $i->{copyfrom_path};
2215 my $branch_from = $i->{copyfrom_path};
2216 if (@a_path_components) {
2217 print STDERR "branch_from: $branch_from => ";
2218 $branch_from .= '/'.join('/', @a_path_components);
2219 print STDERR $branch_from, "\n";
2220 }
2221 my $r = $i->{copyfrom_rev};
2222 my $repos_root = $self->ra->{repos_root};
2223 my $url = $self->ra->{url};
2224 my $new_url = $repos_root . $branch_from;
2225 print STDERR "Found possible branch point: ",
2226 "$new_url => ", $self->full_url, ", $r\n";
2227 $branch_from =~ s#^/##;
2228 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2229 unless ($gs) {
2230 my $ref_id = $self->{ref_id};
2231 $ref_id =~ s/\@\d+$//;
2232 $ref_id .= "\@$r";
2233 # just grow a tail if we're not unique enough :x
2234 $ref_id .= '-' while find_ref($ref_id);
2235 print STDERR "Initializing parent: $ref_id\n";
2236 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2237 }
2238 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2239 if (!defined $r0 || !defined $parent) {
2240 my ($base, $head) = parse_revision_argument(0, $r);
2241 if ($base <= $r) {
2242 $gs->fetch($base, $r);
2243 }
2244 ($r0, $parent) = $gs->last_rev_commit;
2245 }
2246 if (defined $r0 && defined $parent) {
2247 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2248 my $ed;
2249 if ($self->ra->can_do_switch) {
2250 $self->assert_index_clean($parent);
2251 print STDERR "Following parent with do_switch\n";
2252 # do_switch works with svn/trunk >= r22312, but that
2253 # is not included with SVN 1.4.3 (the latest version
2254 # at the moment), so we can't rely on it
2255 $self->{last_commit} = $parent;
2256 $ed = SVN::Git::Fetcher->new($self);
2257 $gs->ra->gs_do_switch($r0, $rev, $gs,
2258 $self->full_url, $ed)
2259 or die "SVN connection failed somewhere...\n";
2260 } elsif ($self->ra->trees_match($new_url, $r0,
2261 $self->full_url, $rev)) {
2262 print STDERR "Trees match:\n",
2263 " $new_url\@$r0\n",
2264 " ${\$self->full_url}\@$rev\n",
2265 "Following parent with no changes\n";
2266 $self->tmp_index_do(sub {
2267 command_noisy('read-tree', $parent);
2268 });
2269 $self->{last_commit} = $parent;
2270 } else {
2271 print STDERR "Following parent with do_update\n";
2272 $ed = SVN::Git::Fetcher->new($self);
2273 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2274 or die "SVN connection failed somewhere...\n";
2275 }
2276 print STDERR "Successfully followed parent\n";
2277 return $self->make_log_entry($rev, [$parent], $ed);
2278 }
2279 return undef;
2280 }
2281
2282 sub do_fetch {
2283 my ($self, $paths, $rev) = @_;
2284 my $ed;
2285 my ($last_rev, @parents);
2286 if (my $lc = $self->last_commit) {
2287 # we can have a branch that was deleted, then re-added
2288 # under the same name but copied from another path, in
2289 # which case we'll have multiple parents (we don't
2290 # want to break the original ref, nor lose copypath info):
2291 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2292 push @{$log_entry->{parents}}, $lc;
2293 return $log_entry;
2294 }
2295 $ed = SVN::Git::Fetcher->new($self);
2296 $last_rev = $self->{last_rev};
2297 $ed->{c} = $lc;
2298 @parents = ($lc);
2299 } else {
2300 $last_rev = $rev;
2301 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2302 return $log_entry;
2303 }
2304 $ed = SVN::Git::Fetcher->new($self);
2305 }
2306 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2307 die "SVN connection failed somewhere...\n";
2308 }
2309 $self->make_log_entry($rev, \@parents, $ed);
2310 }
2311
2312 sub get_untracked {
2313 my ($self, $ed) = @_;
2314 my @out;
2315 my $h = $ed->{empty};
2316 foreach (sort keys %$h) {
2317 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2318 push @out, " $act: " . uri_encode($_);
2319 warn "W: $act: $_\n";
2320 }
2321 foreach my $t (qw/dir_prop file_prop/) {
2322 $h = $ed->{$t} or next;
2323 foreach my $path (sort keys %$h) {
2324 my $ppath = $path eq '' ? '.' : $path;
2325 foreach my $prop (sort keys %{$h->{$path}}) {
2326 next if $SKIP_PROP{$prop};
2327 my $v = $h->{$path}->{$prop};
2328 my $t_ppath_prop = "$t: " .
2329 uri_encode($ppath) . ' ' .
2330 uri_encode($prop);
2331 if (defined $v) {
2332 push @out, " +$t_ppath_prop " .
2333 uri_encode($v);
2334 } else {
2335 push @out, " -$t_ppath_prop";
2336 }
2337 }
2338 }
2339 }
2340 foreach my $t (qw/absent_file absent_directory/) {
2341 $h = $ed->{$t} or next;
2342 foreach my $parent (sort keys %$h) {
2343 foreach my $path (sort @{$h->{$parent}}) {
2344 push @out, " $t: " .
2345 uri_encode("$parent/$path");
2346 warn "W: $t: $parent/$path ",
2347 "Insufficient permissions?\n";
2348 }
2349 }
2350 }
2351 \@out;
2352 }
2353
2354 sub parse_svn_date {
2355 my $date = shift || return '+0000 1970-01-01 00:00:00';
2356 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2357 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2358 croak "Unable to parse date: $date\n";
2359 "+0000 $Y-$m-$d $H:$M:$S";
2360 }
2361
2362 sub check_author {
2363 my ($author) = @_;
2364 if (!defined $author || length $author == 0) {
2365 $author = '(no author)';
2366 }
2367 if (defined $::_authors && ! defined $::users{$author}) {
2368 die "Author: $author not defined in $::_authors file\n";
2369 }
2370 $author;
2371 }
2372
2373 sub make_log_entry {
2374 my ($self, $rev, $parents, $ed) = @_;
2375 my $untracked = $self->get_untracked($ed);
2376
2377 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2378 print $un "r$rev\n" or croak $!;
2379 print $un $_, "\n" foreach @$untracked;
2380 my %log_entry = ( parents => $parents || [], revision => $rev,
2381 log => '');
2382
2383 my $headrev;
2384 my $logged = delete $self->{logged_rev_props};
2385 if (!$logged || $self->{-want_revprops}) {
2386 my $rp = $self->ra->rev_proplist($rev);
2387 foreach (sort keys %$rp) {
2388 my $v = $rp->{$_};
2389 if (/^svn:(author|date|log)$/) {
2390 $log_entry{$1} = $v;
2391 } elsif ($_ eq 'svm:headrev') {
2392 $headrev = $v;
2393 } else {
2394 print $un " rev_prop: ", uri_encode($_), ' ',
2395 uri_encode($v), "\n";
2396 }
2397 }
2398 } else {
2399 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2400 }
2401 close $un or croak $!;
2402
2403 $log_entry{date} = parse_svn_date($log_entry{date});
2404 $log_entry{log} .= "\n";
2405 my $author = $log_entry{author} = check_author($log_entry{author});
2406 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2407 : ($author, undef);
2408
2409 my ($commit_name, $commit_email) = ($name, $email);
2410 if ($_use_log_author) {
2411 my $name_field;
2412 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2413 $name_field = $1;
2414 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2415 $name_field = $1;
2416 }
2417 if (!defined $name_field) {
2418 #
2419 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2420 ($name, $email) = ($1, $2);
2421 } elsif ($name_field =~ /(.*)@/) {
2422 ($name, $email) = ($1, $name_field);
2423 } else {
2424 ($name, $email) = ($name_field, 'unknown');
2425 }
2426 }
2427 if (defined $headrev && $self->use_svm_props) {
2428 if ($self->rewrite_root) {
2429 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2430 "options set!\n";
2431 }
2432 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2433 # we don't want "SVM: initializing mirror for junk" ...
2434 return undef if $r == 0;
2435 my $svm = $self->svm;
2436 if ($uuid ne $svm->{uuid}) {
2437 die "UUID mismatch on SVM path:\n",
2438 "expected: $svm->{uuid}\n",
2439 " got: $uuid\n";
2440 }
2441 my $full_url = $self->full_url;
2442 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2443 die "Failed to replace '$svm->{replace}' with ",
2444 "'$svm->{source}' in $full_url\n";
2445 # throw away username for storing in records
2446 remove_username($full_url);
2447 $log_entry{metadata} = "$full_url\@$r $uuid";
2448 $log_entry{svm_revision} = $r;
2449 $email ||= "$author\@$uuid";
2450 $commit_email ||= "$author\@$uuid";
2451 } elsif ($self->use_svnsync_props) {
2452 my $full_url = $self->svnsync->{url};
2453 $full_url .= "/$self->{path}" if length $self->{path};
2454 remove_username($full_url);
2455 my $uuid = $self->svnsync->{uuid};
2456 $log_entry{metadata} = "$full_url\@$rev $uuid";
2457 $email ||= "$author\@$uuid";
2458 $commit_email ||= "$author\@$uuid";
2459 } else {
2460 my $url = $self->metadata_url;
2461 remove_username($url);
2462 $log_entry{metadata} = "$url\@$rev " .
2463 $self->ra->get_uuid;
2464 $email ||= "$author\@" . $self->ra->get_uuid;
2465 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2466 }
2467 $log_entry{name} = $name;
2468 $log_entry{email} = $email;
2469 $log_entry{commit_name} = $commit_name;
2470 $log_entry{commit_email} = $commit_email;
2471 \%log_entry;
2472 }
2473
2474 sub fetch {
2475 my ($self, $min_rev, $max_rev, @parents) = @_;
2476 my ($last_rev, $last_commit) = $self->last_rev_commit;
2477 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2478 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2479 }
2480
2481 sub set_tree_cb {
2482 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2483 $self->{inject_parents} = { $rev => $tree };
2484 $self->fetch(undef, undef);
2485 }
2486
2487 sub set_tree {
2488 my ($self, $tree) = (shift, shift);
2489 my $log_entry = ::get_commit_entry($tree);
2490 unless ($self->{last_rev}) {
2491 fatal("Must have an existing revision to commit");
2492 }
2493 my %ed_opts = ( r => $self->{last_rev},
2494 log => $log_entry->{log},
2495 ra => $self->ra,
2496 tree_a => $self->{last_commit},
2497 tree_b => $tree,
2498 editor_cb => sub {
2499 $self->set_tree_cb($log_entry, $tree, @_) },
2500 svn_path => $self->{path} );
2501 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2502 print "No changes\nr$self->{last_rev} = $tree\n";
2503 }
2504 }
2505
2506 sub rebuild_from_rev_db {
2507 my ($self, $path) = @_;
2508 my $r = -1;
2509 open my $fh, '<', $path or croak "open: $!";
2510 while (<$fh>) {
2511 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2512 chomp($_);
2513 ++$r;
2514 next if $_ eq ('0' x 40);
2515 $self->rev_map_set($r, $_);
2516 print "r$r = $_\n";
2517 }
2518 close $fh or croak "close: $!";
2519 unlink $path or croak "unlink: $!";
2520 }
2521
2522 sub rebuild {
2523 my ($self) = @_;
2524 my $map_path = $self->map_path;
2525 return if (-e $map_path && ! -z $map_path);
2526 return unless ::verify_ref($self->refname.'^0');
2527 if ($self->use_svm_props || $self->no_metadata) {
2528 my $rev_db = $self->rev_db_path;
2529 $self->rebuild_from_rev_db($rev_db);
2530 if ($self->use_svm_props) {
2531 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2532 $self->rebuild_from_rev_db($svm_rev_db);
2533 }
2534 $self->unlink_rev_db_symlink;
2535 return;
2536 }
2537 print "Rebuilding $map_path ...\n";
2538 my ($log, $ctx) =
2539 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2540 $self->refname, '--');
2541 my $full_url = $self->full_url;
2542 remove_username($full_url);
2543 my $svn_uuid = $self->ra_uuid;
2544 my $c;
2545 while (<$log>) {
2546 if ( m{^commit ($::sha1)$} ) {
2547 $c = $1;
2548 next;
2549 }
2550 next unless s{^\s*(git-svn-id:)}{$1};
2551 my ($url, $rev, $uuid) = ::extract_metadata($_);
2552 remove_username($url);
2553
2554 # ignore merges (from set-tree)
2555 next if (!defined $rev || !$uuid);
2556
2557 # if we merged or otherwise started elsewhere, this is
2558 # how we break out of it
2559 if (($uuid ne $svn_uuid) ||
2560 ($full_url && $url && ($url ne $full_url))) {
2561 next;
2562 }
2563
2564 $self->rev_map_set($rev, $c);
2565 print "r$rev = $c\n";
2566 }
2567 command_close_pipe($log, $ctx);
2568 print "Done rebuilding $map_path\n";
2569 my $rev_db_path = $self->rev_db_path;
2570 if (-f $self->rev_db_path) {
2571 unlink $self->rev_db_path or croak "unlink: $!";
2572 }
2573 $self->unlink_rev_db_symlink;
2574 }
2575
2576 # rev_map:
2577 # Tie::File seems to be prone to offset errors if revisions get sparse,
2578 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2579 # one of my favorite modules is out :< Next up would be one of the DBM
2580 # modules, but I'm not sure which is most portable...
2581 #
2582 # This is the replacement for the rev_db format, which was too big
2583 # and inefficient for large repositories with a lot of sparse history
2584 # (mainly tags)
2585 #
2586 # The format is this:
2587 # - 24 bytes for every record,
2588 # * 4 bytes for the integer representing an SVN revision number
2589 # * 20 bytes representing the sha1 of a git commit
2590 # - No empty padding records like the old format
2591 # (except the last record, which can be overwritten)
2592 # - new records are written append-only since SVN revision numbers
2593 # increase monotonically
2594 # - lookups on SVN revision number are done via a binary search
2595 # - Piping the file to xxd -c24 is a good way of dumping it for
2596 # viewing or editing (piped back through xxd -r), should the need
2597 # ever arise.
2598 # - The last record can be padding revision with an all-zero sha1
2599 # This is used to optimize fetch performance when using multiple
2600 # "fetch" directives in .git/config
2601 #
2602 # These files are disposable unless noMetadata or useSvmProps is set
2603
2604 sub _rev_map_set {
2605 my ($fh, $rev, $commit) = @_;
2606
2607 my $size = (stat($fh))[7];
2608 ($size % 24) == 0 or croak "inconsistent size: $size";
2609
2610 my $wr_offset = 0;
2611 if ($size > 0) {
2612 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2613 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2614 $read == 24 or croak "read only $read bytes (!= 24)";
2615 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2616 if ($last_commit eq ('0' x40)) {
2617 if ($size >= 48) {
2618 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2619 $read = sysread($fh, $buf, 24) or
2620 croak "read: $!";
2621 $read == 24 or
2622 croak "read only $read bytes (!= 24)";
2623 ($last_rev, $last_commit) =
2624 unpack(rev_map_fmt, $buf);
2625 if ($last_commit eq ('0' x40)) {
2626 croak "inconsistent .rev_map\n";
2627 }
2628 }
2629 if ($last_rev >= $rev) {
2630 croak "last_rev is higher!: $last_rev >= $rev";
2631 }
2632 $wr_offset = -24;
2633 }
2634 }
2635 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2636 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2637 croak "write: $!";
2638 }
2639
2640 sub mkfile {
2641 my ($path) = @_;
2642 unless (-e $path) {
2643 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2644 mkpath([$dir]) unless -d $dir;
2645 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2646 close $fh or die "Couldn't close (create) $path: $!\n";
2647 }
2648 }
2649
2650 sub rev_map_set {
2651 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2652 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2653 my $db = $self->map_path($uuid);
2654 my $db_lock = "$db.lock";
2655 my $sig;
2656 if ($update_ref) {
2657 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2658 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2659 }
2660 mkfile($db);
2661
2662 $LOCKFILES{$db_lock} = 1;
2663 my $sync;
2664 # both of these options make our .rev_db file very, very important
2665 # and we can't afford to lose it because rebuild() won't work
2666 if ($self->use_svm_props || $self->no_metadata) {
2667 $sync = 1;
2668 copy($db, $db_lock) or die "rev_map_set(@_): ",
2669 "Failed to copy: ",
2670 "$db => $db_lock ($!)\n";
2671 } else {
2672 rename $db, $db_lock or die "rev_map_set(@_): ",
2673 "Failed to rename: ",
2674 "$db => $db_lock ($!)\n";
2675 }
2676
2677 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2678 or croak "Couldn't open $db_lock: $!\n";
2679 _rev_map_set($fh, $rev, $commit);
2680 if ($sync) {
2681 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2682 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2683 }
2684 close $fh or croak $!;
2685 if ($update_ref) {
2686 $_head = $self;
2687 command_noisy('update-ref', '-m', "r$rev",
2688 $self->refname, $commit);
2689 }
2690 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2691 "$db_lock => $db ($!)\n";
2692 delete $LOCKFILES{$db_lock};
2693 if ($update_ref) {
2694 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2695 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2696 kill $sig, $$ if defined $sig;
2697 }
2698 }
2699
2700 # If want_commit, this will return an array of (rev, commit) where
2701 # commit _must_ be a valid commit in the archive.
2702 # Otherwise, it'll return the max revision (whether or not the
2703 # commit is valid or just a 0x40 placeholder).
2704 sub rev_map_max {
2705 my ($self, $want_commit) = @_;
2706 $self->rebuild;
2707 my $map_path = $self->map_path;
2708 stat $map_path or return $want_commit ? (0, undef) : 0;
2709 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2710 my $size = (stat($fh))[7];
2711 ($size % 24) == 0 or croak "inconsistent size: $size";
2712
2713 if ($size == 0) {
2714 close $fh or croak "close: $!";
2715 return $want_commit ? (0, undef) : 0;
2716 }
2717
2718 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2719 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2720 my ($r, $c) = unpack(rev_map_fmt, $buf);
2721 if ($want_commit && $c eq ('0' x40)) {
2722 if ($size < 48) {
2723 return $want_commit ? (0, undef) : 0;
2724 }
2725 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2726 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2727 ($r, $c) = unpack(rev_map_fmt, $buf);
2728 if ($c eq ('0'x40)) {
2729 croak "Penultimate record is all-zeroes in $map_path";
2730 }
2731 }
2732 close $fh or croak "close: $!";
2733 $want_commit ? ($r, $c) : $r;
2734 }
2735
2736 sub rev_map_get {
2737 my ($self, $rev, $uuid) = @_;
2738 my $map_path = $self->map_path($uuid);
2739 return undef unless -e $map_path;
2740
2741 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2742 my $size = (stat($fh))[7];
2743 ($size % 24) == 0 or croak "inconsistent size: $size";
2744
2745 if ($size == 0) {
2746 close $fh or croak "close: $fh";
2747 return undef;
2748 }
2749
2750 my ($l, $u) = (0, $size - 24);
2751 my ($r, $c, $buf);
2752
2753 while ($l <= $u) {
2754 my $i = int(($l/24 + $u/24) / 2) * 24;
2755 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2756 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2757 my ($r, $c) = unpack('NH40', $buf);
2758
2759 if ($r < $rev) {
2760 $l = $i + 24;
2761 } elsif ($r > $rev) {
2762 $u = $i - 24;
2763 } else { # $r == $rev
2764 close($fh) or croak "close: $!";
2765 return $c eq ('0' x 40) ? undef : $c;
2766 }
2767 }
2768 close($fh) or croak "close: $!";
2769 undef;
2770 }
2771
2772 # Finds the first svn revision that exists on (if $eq_ok is true) or
2773 # before $rev for the current branch. It will not search any lower
2774 # than $min_rev. Returns the git commit hash and svn revision number
2775 # if found, else (undef, undef).
2776 sub find_rev_before {
2777 my ($self, $rev, $eq_ok, $min_rev) = @_;
2778 --$rev unless $eq_ok;
2779 $min_rev ||= 1;
2780 while ($rev >= $min_rev) {
2781 if (my $c = $self->rev_map_get($rev)) {
2782 return ($rev, $c);
2783 }
2784 --$rev;
2785 }
2786 return (undef, undef);
2787 }
2788
2789 # Finds the first svn revision that exists on (if $eq_ok is true) or
2790 # after $rev for the current branch. It will not search any higher
2791 # than $max_rev. Returns the git commit hash and svn revision number
2792 # if found, else (undef, undef).
2793 sub find_rev_after {
2794 my ($self, $rev, $eq_ok, $max_rev) = @_;
2795 ++$rev unless $eq_ok;
2796 $max_rev ||= $self->rev_map_max;
2797 while ($rev <= $max_rev) {
2798 if (my $c = $self->rev_map_get($rev)) {
2799 return ($rev, $c);
2800 }
2801 ++$rev;
2802 }
2803 return (undef, undef);
2804 }
2805
2806 sub _new {
2807 my ($class, $repo_id, $ref_id, $path) = @_;
2808 unless (defined $repo_id && length $repo_id) {
2809 $repo_id = $Git::SVN::default_repo_id;
2810 }
2811 unless (defined $ref_id && length $ref_id) {
2812 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2813 }
2814 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2815 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2816 $_[3] = $path = '' unless (defined $path);
2817 mkpath(["$ENV{GIT_DIR}/svn"]);
2818 bless {
2819 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2820 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2821 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2822 }
2823
2824 # for read-only access of old .rev_db formats
2825 sub unlink_rev_db_symlink {
2826 my ($self) = @_;
2827 my $link = $self->rev_db_path;
2828 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2829 if (-l $link) {
2830 unlink $link or croak "unlink: $link failed!";
2831 }
2832 }
2833
2834 sub rev_db_path {
2835 my ($self, $uuid) = @_;
2836 my $db_path = $self->map_path($uuid);
2837 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2838 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2839 $db_path;
2840 }
2841
2842 # the new replacement for .rev_db
2843 sub map_path {
2844 my ($self, $uuid) = @_;
2845 $uuid ||= $self->ra_uuid;
2846 "$self->{map_root}.$uuid";
2847 }
2848
2849 sub uri_encode {
2850 my ($f) = @_;
2851 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2852 $f
2853 }
2854
2855 sub remove_username {
2856 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2857 }
2858
2859 package Git::SVN::Prompt;
2860 use strict;
2861 use warnings;
2862 require SVN::Core;
2863 use vars qw/$_no_auth_cache $_username/;
2864
2865 sub simple {
2866 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2867 $may_save = undef if $_no_auth_cache;
2868 $default_username = $_username if defined $_username;
2869 if (defined $default_username && length $default_username) {
2870 if (defined $realm && length $realm) {
2871 print STDERR "Authentication realm: $realm\n";
2872 STDERR->flush;
2873 }
2874 $cred->username($default_username);
2875 } else {
2876 username($cred, $realm, $may_save, $pool);
2877 }
2878 $cred->password(_read_password("Password for '" .
2879 $cred->username . "': ", $realm));
2880 $cred->may_save($may_save);
2881 $SVN::_Core::SVN_NO_ERROR;
2882 }
2883
2884 sub ssl_server_trust {
2885 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2886 $may_save = undef if $_no_auth_cache;
2887 print STDERR "Error validating server certificate for '$realm':\n";
2888 {
2889 no warnings 'once';
2890 # All variables SVN::Auth::SSL::* are used only once,
2891 # so we're shutting up Perl warnings about this.
2892 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2893 print STDERR " - The certificate is not issued ",
2894 "by a trusted authority. Use the\n",
2895 " fingerprint to validate ",
2896 "the certificate manually!\n";
2897 }
2898 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2899 print STDERR " - The certificate hostname ",
2900 "does not match.\n";
2901 }
2902 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2903 print STDERR " - The certificate is not yet valid.\n";
2904 }
2905 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2906 print STDERR " - The certificate has expired.\n";
2907 }
2908 if ($failures & $SVN::Auth::SSL::OTHER) {
2909 print STDERR " - The certificate has ",
2910 "an unknown error.\n";
2911 }
2912 } # no warnings 'once'
2913 printf STDERR
2914 "Certificate information:\n".
2915 " - Hostname: %s\n".
2916 " - Valid: from %s until %s\n".
2917 " - Issuer: %s\n".
2918 " - Fingerprint: %s\n",
2919 map $cert_info->$_, qw(hostname valid_from valid_until
2920 issuer_dname fingerprint);
2921 my $choice;
2922 prompt:
2923 print STDERR $may_save ?
2924 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2925 "(R)eject or accept (t)emporarily? ";
2926 STDERR->flush;
2927 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2928 if ($choice =~ /^t$/i) {
2929 $cred->may_save(undef);
2930 } elsif ($choice =~ /^r$/i) {
2931 return -1;
2932 } elsif ($may_save && $choice =~ /^p$/i) {
2933 $cred->may_save($may_save);
2934 } else {
2935 goto prompt;
2936 }
2937 $cred->accepted_failures($failures);
2938 $SVN::_Core::SVN_NO_ERROR;
2939 }
2940
2941 sub ssl_client_cert {
2942 my ($cred, $realm, $may_save, $pool) = @_;
2943 $may_save = undef if $_no_auth_cache;
2944 print STDERR "Client certificate filename: ";
2945 STDERR->flush;
2946 chomp(my $filename = <STDIN>);
2947 $cred->cert_file($filename);
2948 $cred->may_save($may_save);
2949 $SVN::_Core::SVN_NO_ERROR;
2950 }
2951
2952 sub ssl_client_cert_pw {
2953 my ($cred, $realm, $may_save, $pool) = @_;
2954 $may_save = undef if $_no_auth_cache;
2955 $cred->password(_read_password("Password: ", $realm));
2956 $cred->may_save($may_save);
2957 $SVN::_Core::SVN_NO_ERROR;
2958 }
2959
2960 sub username {
2961 my ($cred, $realm, $may_save, $pool) = @_;
2962 $may_save = undef if $_no_auth_cache;
2963 if (defined $realm && length $realm) {
2964 print STDERR "Authentication realm: $realm\n";
2965 }
2966 my $username;
2967 if (defined $_username) {
2968 $username = $_username;
2969 } else {
2970 print STDERR "Username: ";
2971 STDERR->flush;
2972 chomp($username = <STDIN>);
2973 }
2974 $cred->username($username);
2975 $cred->may_save($may_save);
2976 $SVN::_Core::SVN_NO_ERROR;
2977 }
2978
2979 sub _read_password {
2980 my ($prompt, $realm) = @_;
2981 print STDERR $prompt;
2982 STDERR->flush;
2983 require Term::ReadKey;
2984 Term::ReadKey::ReadMode('noecho');
2985 my $password = '';
2986 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2987 last if $key =~ /[\012\015]/; # \n\r
2988 $password .= $key;
2989 }
2990 Term::ReadKey::ReadMode('restore');
2991 print STDERR "\n";
2992 STDERR->flush;
2993 $password;
2994 }
2995
2996 package SVN::Git::Fetcher;
2997 use vars qw/@ISA/;
2998 use strict;
2999 use warnings;
3000 use Carp qw/croak/;
3001 use IO::File qw//;
3002
3003 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3004 sub new {
3005 my ($class, $git_svn) = @_;
3006 my $self = SVN::Delta::Editor->new;
3007 bless $self, $class;
3008 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3009 $self->{empty} = {};
3010 $self->{dir_prop} = {};
3011 $self->{file_prop} = {};
3012 $self->{absent_dir} = {};
3013 $self->{absent_file} = {};
3014 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3015 $self;
3016 }
3017
3018 sub set_path_strip {
3019 my ($self, $path) = @_;
3020 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3021 }
3022
3023 sub open_root {
3024 { path => '' };
3025 }
3026
3027 sub open_directory {
3028 my ($self, $path, $pb, $rev) = @_;
3029 { path => $path };
3030 }
3031
3032 sub git_path {
3033 my ($self, $path) = @_;
3034 if ($self->{path_strip}) {
3035 $path =~ s!$self->{path_strip}!! or
3036 die "Failed to strip path '$path' ($self->{path_strip})\n";
3037 }
3038 $path;
3039 }
3040
3041 sub delete_entry {
3042 my ($self, $path, $rev, $pb) = @_;
3043
3044 my $gpath = $self->git_path($path);
3045 return undef if ($gpath eq '');
3046
3047 # remove entire directories.
3048 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3049 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3050 -r --name-only -z/,
3051 $self->{c}, '--', $gpath);
3052 local $/ = "\0";
3053 while (<$ls>) {
3054 chomp;
3055 $self->{gii}->remove($_);
3056 print "\tD\t$_\n" unless $::_q;
3057 }
3058 print "\tD\t$gpath/\n" unless $::_q;
3059 command_close_pipe($ls, $ctx);
3060 $self->{empty}->{$path} = 0
3061 } else {
3062 $self->{gii}->remove($gpath);
3063 print "\tD\t$gpath\n" unless $::_q;
3064 }
3065 undef;
3066 }
3067
3068 sub open_file {
3069 my ($self, $path, $pb, $rev) = @_;
3070 my $gpath = $self->git_path($path);
3071 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3072 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3073 unless (defined $mode && defined $blob) {
3074 die "$path was not found in commit $self->{c} (r$rev)\n";
3075 }
3076 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3077 pool => SVN::Pool->new, action => 'M' };
3078 }
3079
3080 sub add_file {
3081 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3082 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3083 delete $self->{empty}->{$dir};
3084 { path => $path, mode_a => 100644, mode_b => 100644,
3085 pool => SVN::Pool->new, action => 'A' };
3086 }
3087
3088 sub add_directory {
3089 my ($self, $path, $cp_path, $cp_rev) = @_;
3090 my $gpath = $self->git_path($path);
3091 if ($gpath eq '') {
3092 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3093 -r --name-only -z/,
3094 $self->{c});
3095 local $/ = "\0";
3096 while (<$ls>) {
3097 chomp;
3098 $self->{gii}->remove($_);
3099 print "\tD\t$_\n" unless $::_q;
3100 }
3101 command_close_pipe($ls, $ctx);
3102 $self->{empty}->{$path} = 0;
3103 }
3104 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3105 delete $self->{empty}->{$dir};
3106 $self->{empty}->{$path} = 1;
3107 { path => $path };
3108 }
3109
3110 sub change_dir_prop {
3111 my ($self, $db, $prop, $value) = @_;
3112 $self->{dir_prop}->{$db->{path}} ||= {};
3113 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3114 undef;
3115 }
3116
3117 sub absent_directory {
3118 my ($self, $path, $pb) = @_;
3119 $self->{absent_dir}->{$pb->{path}} ||= [];
3120 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3121 undef;
3122 }
3123
3124 sub absent_file {
3125 my ($self, $path, $pb) = @_;
3126 $self->{absent_file}->{$pb->{path}} ||= [];
3127 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3128 undef;
3129 }
3130
3131 sub change_file_prop {
3132 my ($self, $fb, $prop, $value) = @_;
3133 if ($prop eq 'svn:executable') {
3134 if ($fb->{mode_b} != 120000) {
3135 $fb->{mode_b} = defined $value ? 100755 : 100644;
3136 }
3137 } elsif ($prop eq 'svn:special') {
3138 $fb->{mode_b} = defined $value ? 120000 : 100644;
3139 } else {
3140 $self->{file_prop}->{$fb->{path}} ||= {};
3141 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3142 }
3143 undef;
3144 }
3145
3146 sub apply_textdelta {
3147 my ($self, $fb, $exp) = @_;
3148 my $fh = IO::File->new_tmpfile;
3149 $fh->autoflush(1);
3150 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3151 # (but $base does not,) so dup() it for reading in close_file
3152 open my $dup, '<&', $fh or croak $!;
3153 my $base = IO::File->new_tmpfile;
3154 $base->autoflush(1);
3155 if ($fb->{blob}) {
3156 defined (my $pid = fork) or croak $!;
3157 if (!$pid) {
3158 open STDOUT, '>&', $base or croak $!;
3159 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3160 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3161 }
3162 waitpid $pid, 0;
3163 croak $? if $?;
3164
3165 if (defined $exp) {
3166 seek $base, 0, 0 or croak $!;
3167 my $got = ::md5sum($base);
3168 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3169 "expected: $exp\n",
3170 " got: $got\n" if ($got ne $exp);
3171 }
3172 }
3173 seek $base, 0, 0 or croak $!;
3174 $fb->{fh} = $dup;
3175 $fb->{base} = $base;
3176 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3177 }
3178
3179 sub close_file {
3180 my ($self, $fb, $exp) = @_;
3181 my $hash;
3182 my $path = $self->git_path($fb->{path});
3183 if (my $fh = $fb->{fh}) {
3184 if (defined $exp) {
3185 seek($fh, 0, 0) or croak $!;
3186 my $got = ::md5sum($fh);
3187 if ($got ne $exp) {
3188 die "Checksum mismatch: $path\n",
3189 "expected: $exp\n got: $got\n";
3190 }
3191 }
3192 sysseek($fh, 0, 0) or croak $!;
3193 if ($fb->{mode_b} == 120000) {
3194 eval {
3195 sysread($fh, my $buf, 5) == 5 or croak $!;
3196 $buf eq 'link ' or die "$path has mode 120000",
3197 " but is not a link";
3198 };
3199 if ($@) {
3200 warn "$@\n";
3201 sysseek($fh, 0, 0) or croak $!;
3202 }
3203 }
3204 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3205 if (!$pid) {
3206 open STDIN, '<&', $fh or croak $!;
3207 exec qw/git-hash-object -w --stdin/ or croak $!;
3208 }
3209 chomp($hash = do { local $/; <$out> });
3210 close $out or croak $!;
3211 close $fh or croak $!;
3212 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3213 close $fb->{base} or croak $!;
3214 } else {
3215 $hash = $fb->{blob} or die "no blob information\n";
3216 }
3217 $fb->{pool}->clear;
3218 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3219 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3220 undef;
3221 }
3222
3223 sub abort_edit {
3224 my $self = shift;
3225 $self->{nr} = $self->{gii}->{nr};
3226 delete $self->{gii};
3227 $self->SUPER::abort_edit(@_);
3228 }
3229
3230 sub close_edit {
3231 my $self = shift;
3232 $self->{git_commit_ok} = 1;
3233 $self->{nr} = $self->{gii}->{nr};
3234 delete $self->{gii};
3235 $self->SUPER::close_edit(@_);
3236 }
3237
3238 package SVN::Git::Editor;
3239 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3240 use strict;
3241 use warnings;
3242 use Carp qw/croak/;
3243 use IO::File;
3244
3245 sub new {
3246 my ($class, $opts) = @_;
3247 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3248 die "$_ required!\n" unless (defined $opts->{$_});
3249 }
3250
3251 my $pool = SVN::Pool->new;
3252 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3253 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3254 $opts->{r}, $mods);
3255
3256 # $opts->{ra} functions should not be used after this:
3257 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3258 $opts->{editor_cb}, $pool);
3259 my $self = SVN::Delta::Editor->new(@ce, $pool);
3260 bless $self, $class;
3261 foreach (qw/svn_path r tree_a tree_b/) {
3262 $self->{$_} = $opts->{$_};
3263 }
3264 $self->{url} = $opts->{ra}->{url};
3265 $self->{mods} = $mods;
3266 $self->{types} = $types;
3267 $self->{pool} = $pool;
3268 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3269 $self->{rm} = { };
3270 $self->{path_prefix} = length $self->{svn_path} ?
3271 "$self->{svn_path}/" : '';
3272 return $self;
3273 }
3274
3275 sub generate_diff {
3276 my ($tree_a, $tree_b) = @_;
3277 my @diff_tree = qw(diff-tree -z -r);
3278 if ($_cp_similarity) {
3279 push @diff_tree, "-C$_cp_similarity";
3280 } else {
3281 push @diff_tree, '-C';
3282 }
3283 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3284 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3285 push @diff_tree, $tree_a, $tree_b;
3286 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3287 local $/ = "\0";
3288 my $state = 'meta';
3289 my @mods;
3290 while (<$diff_fh>) {
3291 chomp $_; # this gets rid of the trailing "\0"
3292 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3293 $::sha1\s($::sha1)\s
3294 ([MTCRAD])\d*$/xo) {
3295 push @mods, { mode_a => $1, mode_b => $2,
3296 sha1_b => $3, chg => $4 };
3297 if ($4 =~ /^(?:C|R)$/) {
3298 $state = 'file_a';
3299 } else {
3300 $state = 'file_b';
3301 }
3302 } elsif ($state eq 'file_a') {
3303 my $x = $mods[$#mods] or croak "Empty array\n";
3304 if ($x->{chg} !~ /^(?:C|R)$/) {
3305 croak "Error parsing $_, $x->{chg}\n";
3306 }
3307 $x->{file_a} = $_;
3308 $state = 'file_b';
3309 } elsif ($state eq 'file_b') {
3310 my $x = $mods[$#mods] or croak "Empty array\n";
3311 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3312 croak "Error parsing $_, $x->{chg}\n";
3313 }
3314 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3315 croak "Error parsing $_, $x->{chg}\n";
3316 }
3317 $x->{file_b} = $_;
3318 $state = 'meta';
3319 } else {
3320 croak "Error parsing $_\n";
3321 }
3322 }
3323 command_close_pipe($diff_fh, $ctx);
3324 \@mods;
3325 }
3326
3327 sub check_diff_paths {
3328 my ($ra, $pfx, $rev, $mods) = @_;
3329 my %types;
3330 $pfx .= '/' if length $pfx;
3331
3332 sub type_diff_paths {
3333 my ($ra, $types, $path, $rev) = @_;
3334 my @p = split m#/+#, $path;
3335 my $c = shift @p;
3336 unless (defined $types->{$c}) {
3337 $types->{$c} = $ra->check_path($c, $rev);
3338 }
3339 while (@p) {
3340 $c .= '/' . shift @p;
3341 next if defined $types->{$c};
3342 $types->{$c} = $ra->check_path($c, $rev);
3343 }
3344 }
3345
3346 foreach my $m (@$mods) {
3347 foreach my $f (qw/file_a file_b/) {
3348 next unless defined $m->{$f};
3349 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3350 if (length $pfx.$dir && ! defined $types{$dir}) {
3351 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3352 }
3353 }
3354 }
3355 \%types;
3356 }
3357
3358 sub split_path {
3359 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3360 }
3361
3362 sub repo_path {
3363 my ($self, $path) = @_;
3364 $self->{path_prefix}.(defined $path ? $path : '');
3365 }
3366
3367 sub url_path {
3368 my ($self, $path) = @_;
3369 if ($self->{url} =~ m#^https?://#) {
3370 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3371 }
3372 $self->{url} . '/' . $self->repo_path($path);
3373 }
3374
3375 sub rmdirs {
3376 my ($self) = @_;
3377 my $rm = $self->{rm};
3378 delete $rm->{''}; # we never delete the url we're tracking
3379 return unless %$rm;
3380
3381 foreach (keys %$rm) {
3382 my @d = split m#/#, $_;
3383 my $c = shift @d;
3384 $rm->{$c} = 1;
3385 while (@d) {
3386 $c .= '/' . shift @d;
3387 $rm->{$c} = 1;
3388 }
3389 }
3390 delete $rm->{$self->{svn_path}};
3391 delete $rm->{''}; # we never delete the url we're tracking
3392 return unless %$rm;
3393
3394 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3395 $self->{tree_b});
3396 local $/ = "\0";
3397 while (<$fh>) {
3398 chomp;
3399 my @dn = split m#/#, $_;
3400 while (pop @dn) {
3401 delete $rm->{join '/', @dn};
3402 }
3403 unless (%$rm) {
3404 close $fh;
3405 return;
3406 }
3407 }
3408 command_close_pipe($fh, $ctx);
3409
3410 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3411 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3412 $self->close_directory($bat->{$d}, $p);
3413 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3414 print "\tD+\t$d/\n" unless $::_q;
3415 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3416 delete $bat->{$d};
3417 }
3418 }
3419
3420 sub open_or_add_dir {
3421 my ($self, $full_path, $baton) = @_;
3422 my $t = $self->{types}->{$full_path};
3423 if (!defined $t) {
3424 die "$full_path not known in r$self->{r} or we have a bug!\n";
3425 }
3426 {
3427 no warnings 'once';
3428 # SVN::Node::none and SVN::Node::file are used only once,
3429 # so we're shutting up Perl's warnings about them.
3430 if ($t == $SVN::Node::none) {
3431 return $self->add_directory($full_path, $baton,
3432 undef, -1, $self->{pool});
3433 } elsif ($t == $SVN::Node::dir) {
3434 return $self->open_directory($full_path, $baton,
3435 $self->{r}, $self->{pool});
3436 } # no warnings 'once'
3437 print STDERR "$full_path already exists in repository at ",
3438 "r$self->{r} and it is not a directory (",
3439 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3440 } # no warnings 'once'
3441 exit 1;
3442 }
3443
3444 sub ensure_path {
3445 my ($self, $path) = @_;
3446 my $bat = $self->{bat};
3447 my $repo_path = $self->repo_path($path);
3448 return $bat->{''} unless (length $repo_path);
3449 my @p = split m#/+#, $repo_path;
3450 my $c = shift @p;
3451 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3452 while (@p) {
3453 my $c0 = $c;
3454 $c .= '/' . shift @p;
3455 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3456 }
3457 return $bat->{$c};
3458 }
3459
3460 sub A {
3461 my ($self, $m) = @_;
3462 my ($dir, $file) = split_path($m->{file_b});
3463 my $pbat = $self->ensure_path($dir);
3464 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3465 undef, -1);
3466 print "\tA\t$m->{file_b}\n" unless $::_q;
3467 $self->chg_file($fbat, $m);
3468 $self->close_file($fbat,undef,$self->{pool});
3469 }
3470
3471 sub C {
3472 my ($self, $m) = @_;
3473 my ($dir, $file) = split_path($m->{file_b});
3474 my $pbat = $self->ensure_path($dir);
3475 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3476 $self->url_path($m->{file_a}), $self->{r});
3477 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3478 $self->chg_file($fbat, $m);
3479 $self->close_file($fbat,undef,$self->{pool});
3480 }
3481
3482 sub delete_entry {
3483 my ($self, $path, $pbat) = @_;
3484 my $rpath = $self->repo_path($path);
3485 my ($dir, $file) = split_path($rpath);
3486 $self->{rm}->{$dir} = 1;
3487 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3488 }
3489
3490 sub R {
3491 my ($self, $m) = @_;
3492 my ($dir, $file) = split_path($m->{file_b});
3493 my $pbat = $self->ensure_path($dir);
3494 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3495 $self->url_path($m->{file_a}), $self->{r});
3496 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3497 $self->chg_file($fbat, $m);
3498 $self->close_file($fbat,undef,$self->{pool});
3499
3500 ($dir, $file) = split_path($m->{file_a});
3501 $pbat = $self->ensure_path($dir);
3502 $self->delete_entry($m->{file_a}, $pbat);
3503 }
3504
3505 sub M {
3506 my ($self, $m) = @_;
3507 my ($dir, $file) = split_path($m->{file_b});
3508 my $pbat = $self->ensure_path($dir);
3509 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3510 $pbat,$self->{r},$self->{pool});
3511 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3512 $self->chg_file($fbat, $m);
3513 $self->close_file($fbat,undef,$self->{pool});
3514 }
3515
3516 sub T { shift->M(@_) }
3517
3518 sub change_file_prop {
3519 my ($self, $fbat, $pname, $pval) = @_;
3520 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3521 }
3522
3523 sub chg_file {
3524 my ($self, $fbat, $m) = @_;
3525 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3526 $self->change_file_prop($fbat,'svn:executable','*');
3527 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3528 $self->change_file_prop($fbat,'svn:executable',undef);
3529 }
3530 my $fh = IO::File->new_tmpfile or croak $!;
3531 if ($m->{mode_b} =~ /^120/) {
3532 print $fh 'link ' or croak $!;
3533 $self->change_file_prop($fbat,'svn:special','*');
3534 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3535 $self->change_file_prop($fbat,'svn:special',undef);
3536 }
3537 defined(my $pid = fork) or croak $!;
3538 if (!$pid) {
3539 open STDOUT, '>&', $fh or croak $!;
3540 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3541 }
3542 waitpid $pid, 0;
3543 croak $? if $?;
3544 $fh->flush == 0 or croak $!;
3545 seek $fh, 0, 0 or croak $!;
3546
3547 my $exp = ::md5sum($fh);
3548 seek $fh, 0, 0 or croak $!;
3549
3550 my $pool = SVN::Pool->new;
3551 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3552 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3553 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3554 $pool->clear;
3555
3556 close $fh or croak $!;
3557 }
3558
3559 sub D {
3560 my ($self, $m) = @_;
3561 my ($dir, $file) = split_path($m->{file_b});
3562 my $pbat = $self->ensure_path($dir);
3563 print "\tD\t$m->{file_b}\n" unless $::_q;
3564 $self->delete_entry($m->{file_b}, $pbat);
3565 }
3566
3567 sub close_edit {
3568 my ($self) = @_;
3569 my ($p,$bat) = ($self->{pool}, $self->{bat});
3570 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3571 next if $_ eq '';
3572 $self->close_directory($bat->{$_}, $p);
3573 }
3574 $self->close_directory($bat->{''}, $p);
3575 $self->SUPER::close_edit($p);
3576 $p->clear;
3577 }
3578
3579 sub abort_edit {
3580 my ($self) = @_;
3581 $self->SUPER::abort_edit($self->{pool});
3582 }
3583
3584 sub DESTROY {
3585 my $self = shift;
3586 $self->SUPER::DESTROY(@_);
3587 $self->{pool}->clear;
3588 }
3589
3590 # this drives the editor
3591 sub apply_diff {
3592 my ($self) = @_;
3593 my $mods = $self->{mods};
3594 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3595 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3596 my $f = $m->{chg};
3597 if (defined $o{$f}) {
3598 $self->$f($m);
3599 } else {
3600 fatal("Invalid change type: $f");
3601 }
3602 }
3603 $self->rmdirs if $_rmdir;
3604 if (@$mods == 0) {
3605 $self->abort_edit;
3606 } else {
3607 $self->close_edit;
3608 }
3609 return scalar @$mods;
3610 }
3611
3612 package Git::SVN::Ra;
3613 use vars qw/@ISA $config_dir $_log_window_size/;
3614 use strict;
3615 use warnings;
3616 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3617
3618 BEGIN {
3619 # enforce temporary pool usage for some simple functions
3620 no strict 'refs';
3621 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3622 my $SUPER = "SUPER::$f";
3623 *$f = sub {
3624 my $self = shift;
3625 my $pool = SVN::Pool->new;
3626 my @ret = $self->$SUPER(@_,$pool);
3627 $pool->clear;
3628 wantarray ? @ret : $ret[0];
3629 };
3630 }
3631 }
3632
3633 sub _auth_providers () {
3634 [
3635 SVN::Client::get_simple_provider(),
3636 SVN::Client::get_ssl_server_trust_file_provider(),
3637 SVN::Client::get_simple_prompt_provider(
3638 \&Git::SVN::Prompt::simple, 2),
3639 SVN::Client::get_ssl_client_cert_file_provider(),
3640 SVN::Client::get_ssl_client_cert_prompt_provider(
3641 \&Git::SVN::Prompt::ssl_client_cert, 2),
3642 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3643 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3644 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3645 SVN::Client::get_username_provider(),
3646 SVN::Client::get_ssl_server_trust_prompt_provider(
3647 \&Git::SVN::Prompt::ssl_server_trust),
3648 SVN::Client::get_username_prompt_provider(
3649 \&Git::SVN::Prompt::username, 2)
3650 ]
3651 }
3652
3653 sub escape_uri_only {
3654 my ($uri) = @_;
3655 my @tmp;
3656 foreach (split m{/}, $uri) {
3657 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3658 push @tmp, $_;
3659 }
3660 join('/', @tmp);
3661 }
3662
3663 sub escape_url {
3664 my ($url) = @_;
3665 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3666 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3667 $url = "$scheme://$domain$uri";
3668 }
3669 $url;
3670 }
3671
3672 sub new {
3673 my ($class, $url) = @_;
3674 $url =~ s!/+$!!;
3675 return $RA if ($RA && $RA->{url} eq $url);
3676
3677 SVN::_Core::svn_config_ensure($config_dir, undef);
3678 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3679 my $config = SVN::Core::config_get_config($config_dir);
3680 $RA = undef;
3681 my $dont_store_passwords = 1;
3682 my $conf_t = ${$config}{'config'};
3683 {
3684 no warnings 'once';
3685 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3686 # produces warnings that variables are used only once.
3687 # I had not found the better way to shut them up, so
3688 # the warnings of type 'once' are disabled in this block.
3689 if (SVN::_Core::svn_config_get_bool($conf_t,
3690 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3691 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3692 1) == 0) {
3693 SVN::_Core::svn_auth_set_parameter($baton,
3694 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3695 bless (\$dont_store_passwords, "_p_void"));
3696 }
3697 if (SVN::_Core::svn_config_get_bool($conf_t,
3698 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3699 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3700 1) == 0) {
3701 $Git::SVN::Prompt::_no_auth_cache = 1;
3702 }
3703 } # no warnings 'once'
3704 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3705 config => $config,
3706 pool => SVN::Pool->new,
3707 auth_provider_callbacks => $callbacks);
3708 $self->{url} = $url;
3709 $self->{svn_path} = $url;
3710 $self->{repos_root} = $self->get_repos_root;
3711 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3712 $self->{cache} = { check_path => { r => 0, data => {} },
3713 get_dir => { r => 0, data => {} } };
3714 $RA = bless $self, $class;
3715 }
3716
3717 sub check_path {
3718 my ($self, $path, $r) = @_;
3719 my $cache = $self->{cache}->{check_path};
3720 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3721 return $cache->{data}->{$path};
3722 }
3723 my $pool = SVN::Pool->new;
3724 my $t = $self->SUPER::check_path($path, $r, $pool);
3725 $pool->clear;
3726 if ($r != $cache->{r}) {
3727 %{$cache->{data}} = ();
3728 $cache->{r} = $r;
3729 }
3730 $cache->{data}->{$path} = $t;
3731 }
3732
3733 sub get_dir {
3734 my ($self, $dir, $r) = @_;
3735 my $cache = $self->{cache}->{get_dir};
3736 if ($r == $cache->{r}) {
3737 if (my $x = $cache->{data}->{$dir}) {
3738 return wantarray ? @$x : $x->[0];
3739 }
3740 }
3741 my $pool = SVN::Pool->new;
3742 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3743 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3744 $pool->clear;
3745 if ($r != $cache->{r}) {
3746 %{$cache->{data}} = ();
3747 $cache->{r} = $r;
3748 }
3749 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3750 wantarray ? (\%dirents, $r, $props) : \%dirents;
3751 }
3752
3753 sub DESTROY {
3754 # do not call the real DESTROY since we store ourselves in $RA
3755 }
3756
3757 sub get_log {
3758 my ($self, @args) = @_;
3759 my $pool = SVN::Pool->new;
3760 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3761 my $ret = $self->SUPER::get_log(@args, $pool);
3762 $pool->clear;
3763 $ret;
3764 }
3765
3766 sub trees_match {
3767 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3768 my $ctx = SVN::Client->new(auth => _auth_providers);
3769 my $out = IO::File->new_tmpfile;
3770
3771 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3772 # $ctx->diff(), so we'll create a default one
3773 my $pool = SVN::Pool->new_default_sub;
3774
3775 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3776 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3777 $out->flush;
3778 my $ret = (($out->stat)[7] == 0);
3779 close $out or croak $!;
3780
3781 $ret;
3782 }
3783
3784 sub get_commit_editor {
3785 my ($self, $log, $cb, $pool) = @_;
3786 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3787 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3788 }
3789
3790 sub gs_do_update {
3791 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3792 my $new = ($rev_a == $rev_b);
3793 my $path = $gs->{path};
3794
3795 if ($new && -e $gs->{index}) {
3796 unlink $gs->{index} or die
3797 "Couldn't unlink index: $gs->{index}: $!\n";
3798 }
3799 my $pool = SVN::Pool->new;
3800 $editor->set_path_strip($path);
3801 my (@pc) = split m#/#, $path;
3802 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3803 1, $editor, $pool);
3804 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3805
3806 # Since we can't rely on svn_ra_reparent being available, we'll
3807 # just have to do some magic with set_path to make it so
3808 # we only want a partial path.
3809 my $sp = '';
3810 my $final = join('/', @pc);
3811 while (@pc) {
3812 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3813 $sp .= '/' if length $sp;
3814 $sp .= shift @pc;
3815 }
3816 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3817
3818 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3819
3820 $reporter->finish_report($pool);
3821 $pool->clear;
3822 $editor->{git_commit_ok};
3823 }
3824
3825 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3826 # svn_ra_reparent didn't work before 1.4)
3827 sub gs_do_switch {
3828 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3829 my $path = $gs->{path};
3830 my $pool = SVN::Pool->new;
3831
3832 my $full_url = $self->{url};
3833 my $old_url = $full_url;
3834 $full_url .= '/' . escape_uri_only($path) if length $path;
3835 my ($ra, $reparented);
3836 if ($old_url ne $full_url) {
3837 if ($old_url !~ m#^svn(\+ssh)?://#) {
3838 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3839 $pool);
3840 $self->{url} = $full_url;
3841 $reparented = 1;
3842 } else {
3843 $_[0] = undef;
3844 $self = undef;
3845 $RA = undef;
3846 $ra = Git::SVN::Ra->new($full_url);
3847 $ra_invalid = 1;
3848 }
3849 }
3850 $ra ||= $self;
3851 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3852 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3853 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3854 $reporter->finish_report($pool);
3855
3856 if ($reparented) {
3857 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3858 $self->{url} = $old_url;
3859 }
3860
3861 $pool->clear;
3862 $editor->{git_commit_ok};
3863 }
3864
3865 sub longest_common_path {
3866 my ($gsv, $globs) = @_;
3867 my %common;
3868 my $common_max = scalar @$gsv;
3869
3870 foreach my $gs (@$gsv) {
3871 my @tmp = split m#/#, $gs->{path};
3872 my $p = '';
3873 foreach (@tmp) {
3874 $p .= length($p) ? "/$_" : $_;
3875 $common{$p} ||= 0;
3876 $common{$p}++;
3877 }
3878 }
3879 $globs ||= [];
3880 $common_max += scalar @$globs;
3881 foreach my $glob (@$globs) {
3882 my @tmp = split m#/#, $glob->{path}->{left};
3883 my $p = '';
3884 foreach (@tmp) {
3885 $p .= length($p) ? "/$_" : $_;
3886 $common{$p} ||= 0;
3887 $common{$p}++;
3888 }
3889 }
3890
3891 my $longest_path = '';
3892 foreach (sort {length $b <=> length $a} keys %common) {
3893 if ($common{$_} == $common_max) {
3894 $longest_path = $_;
3895 last;
3896 }
3897 }
3898 $longest_path;
3899 }
3900
3901 sub gs_fetch_loop_common {
3902 my ($self, $base, $head, $gsv, $globs) = @_;
3903 return if ($base > $head);
3904 my $inc = $_log_window_size;
3905 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3906 my $longest_path = longest_common_path($gsv, $globs);
3907 my $ra_url = $self->{url};
3908 while (1) {
3909 my %revs;
3910 my $err;
3911 my $err_handler = $SVN::Error::handler;
3912 $SVN::Error::handler = sub {
3913 ($err) = @_;
3914 skip_unknown_revs($err);
3915 };
3916 sub _cb {
3917 my ($paths, $r, $author, $date, $log) = @_;
3918 [ dup_changed_paths($paths),
3919 { author => $author, date => $date, log => $log } ];
3920 }
3921 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3922 sub { $revs{$_[1]} = _cb(@_) });
3923 if ($err && $max >= $head) {
3924 print STDERR "Path '$longest_path' ",
3925 "was probably deleted:\n",
3926 $err->expanded_message,
3927 "\nWill attempt to follow ",
3928 "revisions r$min .. r$max ",
3929 "committed before the deletion\n";
3930 my $hi = $max;
3931 while (--$hi >= $min) {
3932 my $ok;
3933 $self->get_log([$longest_path], $min, $hi,
3934 0, 1, 1, sub {
3935 $ok ||= $_[1];
3936 $revs{$_[1]} = _cb(@_) });
3937 if ($ok) {
3938 print STDERR "r$min .. r$ok OK\n";
3939 last;
3940 }
3941 }
3942 }
3943 $SVN::Error::handler = $err_handler;
3944
3945 my %exists = map { $_->{path} => $_ } @$gsv;
3946 foreach my $r (sort {$a <=> $b} keys %revs) {
3947 my ($paths, $logged) = @{$revs{$r}};
3948
3949 foreach my $gs ($self->match_globs(\%exists, $paths,
3950 $globs, $r)) {
3951 if ($gs->rev_map_max >= $r) {
3952 next;
3953 }
3954 next unless $gs->match_paths($paths, $r);
3955 $gs->{logged_rev_props} = $logged;
3956 if (my $last_commit = $gs->last_commit) {
3957 $gs->assert_index_clean($last_commit);
3958 }
3959 my $log_entry = $gs->do_fetch($paths, $r);
3960 if ($log_entry) {
3961 $gs->do_git_commit($log_entry);
3962 }
3963 $INDEX_FILES{$gs->{index}} = 1;
3964 }
3965 foreach my $g (@$globs) {
3966 my $k = "svn-remote.$g->{remote}." .
3967 "$g->{t}-maxRev";
3968 Git::SVN::tmp_config($k, $r);
3969 }
3970 if ($ra_invalid) {
3971 $_[0] = undef;
3972 $self = undef;
3973 $RA = undef;
3974 $self = Git::SVN::Ra->new($ra_url);
3975 $ra_invalid = undef;
3976 }
3977 }
3978 # pre-fill the .rev_db since it'll eventually get filled in
3979 # with '0' x40 if something new gets committed
3980 foreach my $gs (@$gsv) {
3981 next if $gs->rev_map_max >= $max;
3982 next if defined $gs->rev_map_get($max);
3983 $gs->rev_map_set($max, 0 x40);
3984 }
3985 foreach my $g (@$globs) {
3986 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3987 Git::SVN::tmp_config($k, $max);
3988 }
3989 last if $max >= $head;
3990 $min = $max + 1;
3991 $max += $inc;
3992 $max = $head if ($max > $head);
3993 }
3994 }
3995
3996 sub match_globs {
3997 my ($self, $exists, $paths, $globs, $r) = @_;
3998
3999 sub get_dir_check {
4000 my ($self, $exists, $g, $r) = @_;
4001 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4002 return unless scalar @x == 3;
4003 my $dirents = $x[0];
4004 foreach my $de (keys %$dirents) {
4005 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4006 my $p = $g->{path}->full_path($de);
4007 next if $exists->{$p};
4008 next if (length $g->{path}->{right} &&
4009 ($self->check_path($p, $r) !=
4010 $SVN::Node::dir));
4011 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4012 $g->{ref}->full_path($de), 1);
4013 }
4014 }
4015 foreach my $g (@$globs) {
4016 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4017 if ($path->{action} =~ /^[AR]$/) {
4018 get_dir_check($self, $exists, $g, $r);
4019 }
4020 }
4021 foreach (keys %$paths) {
4022 if (/$g->{path}->{left_regex}/ &&
4023 !/$g->{path}->{regex}/) {
4024 next if $paths->{$_}->{action} !~ /^[AR]$/;
4025 get_dir_check($self, $exists, $g, $r);
4026 }
4027 next unless /$g->{path}->{regex}/;
4028 my $p = $1;
4029 my $pathname = $g->{path}->full_path($p);
4030 next if $exists->{$pathname};
4031 next if ($self->check_path($pathname, $r) !=
4032 $SVN::Node::dir);
4033 $exists->{$pathname} = Git::SVN->init(
4034 $self->{url}, $pathname, undef,
4035 $g->{ref}->full_path($p), 1);
4036 }
4037 my $c = '';
4038 foreach (split m#/#, $g->{path}->{left}) {
4039 $c .= "/$_";
4040 next unless ($paths->{$c} &&
4041 ($paths->{$c}->{action} =~ /^[AR]$/));
4042 get_dir_check($self, $exists, $g, $r);
4043 }
4044 }
4045 values %$exists;
4046 }
4047
4048 sub minimize_url {
4049 my ($self) = @_;
4050 return $self->{url} if ($self->{url} eq $self->{repos_root});
4051 my $url = $self->{repos_root};
4052 my @components = split(m!/!, $self->{svn_path});
4053 my $c = '';
4054 do {
4055 $url .= "/$c" if length $c;
4056 eval { (ref $self)->new($url)->get_latest_revnum };
4057 } while ($@ && ($c = shift @components));
4058 $url;
4059 }
4060
4061 sub can_do_switch {
4062 my $self = shift;
4063 unless (defined $can_do_switch) {
4064 my $pool = SVN::Pool->new;
4065 my $rep = eval {
4066 $self->do_switch(1, '', 0, $self->{url},
4067 SVN::Delta::Editor->new, $pool);
4068 };
4069 if ($@) {
4070 $can_do_switch = 0;
4071 } else {
4072 $rep->abort_report($pool);
4073 $can_do_switch = 1;
4074 }
4075 $pool->clear;
4076 }
4077 $can_do_switch;
4078 }
4079
4080 sub skip_unknown_revs {
4081 my ($err) = @_;
4082 my $errno = $err->apr_err();
4083 # Maybe the branch we're tracking didn't
4084 # exist when the repo started, so it's
4085 # not an error if it doesn't, just continue
4086 #
4087 # Wonderfully consistent library, eh?
4088 # 160013 - svn:// and file://
4089 # 175002 - http(s)://
4090 # 175007 - http(s):// (this repo required authorization, too...)
4091 # More codes may be discovered later...
4092 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4093 my $err_key = $err->expanded_message;
4094 # revision numbers change every time, filter them out
4095 $err_key =~ s/\d+/\0/g;
4096 $err_key = "$errno\0$err_key";
4097 unless ($ignored_err{$err_key}) {
4098 warn "W: Ignoring error from SVN, path probably ",
4099 "does not exist: ($errno): ",
4100 $err->expanded_message,"\n";
4101 warn "W: Do not be alarmed at the above message ",
4102 "git-svn is just searching aggressively for ",
4103 "old history.\n",
4104 "This may take a while on large repositories\n";
4105 $ignored_err{$err_key} = 1;
4106 }
4107 return;
4108 }
4109 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4110 }
4111
4112 # svn_log_changed_path_t objects passed to get_log are likely to be
4113 # overwritten even if only the refs are copied to an external variable,
4114 # so we should dup the structures in their entirety. Using an externally
4115 # passed pool (instead of our temporary and quickly cleared pool in
4116 # Git::SVN::Ra) does not help matters at all...
4117 sub dup_changed_paths {
4118 my ($paths) = @_;
4119 return undef unless $paths;
4120 my %ret;
4121 foreach my $p (keys %$paths) {
4122 my $i = $paths->{$p};
4123 my %s = map { $_ => $i->$_ }
4124 qw/copyfrom_path copyfrom_rev action/;
4125 $ret{$p} = \%s;
4126 }
4127 \%ret;
4128 }
4129
4130 package Git::SVN::Log;
4131 use strict;
4132 use warnings;
4133 use POSIX qw/strftime/;
4134 use constant commit_log_separator => ('-' x 72) . "\n";
4135 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4136 %rusers $show_commit $incremental/;
4137 my $l_fmt;
4138
4139 sub cmt_showable {
4140 my ($c) = @_;
4141 return 1 if defined $c->{r};
4142
4143 # big commit message got truncated by the 16k pretty buffer in rev-list
4144 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4145 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4146 @{$c->{l}} = ();
4147 my @log = command(qw/cat-file commit/, $c->{c});
4148
4149 # shift off the headers
4150 shift @log while ($log[0] ne '');
4151 shift @log;
4152
4153 # TODO: make $c->{l} not have a trailing newline in the future
4154 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4155
4156 (undef, $c->{r}, undef) = ::extract_metadata(
4157 (grep(/^git-svn-id: /, @log))[-1]);
4158 }
4159 return defined $c->{r};
4160 }
4161
4162 sub log_use_color {
4163 return $color || Git->repository->get_colorbool('color.diff');
4164 }
4165
4166 sub git_svn_log_cmd {
4167 my ($r_min, $r_max, @args) = @_;
4168 my $head = 'HEAD';
4169 my (@files, @log_opts);
4170 foreach my $x (@args) {
4171 if ($x eq '--' || @files) {
4172 push @files, $x;
4173 } else {
4174 if (::verify_ref("$x^0")) {
4175 $head = $x;
4176 } else {
4177 push @log_opts, $x;
4178 }
4179 }
4180 }
4181
4182 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4183 $gs ||= Git::SVN->_new;
4184 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4185 $gs->refname);
4186 push @cmd, '-r' unless $non_recursive;
4187 push @cmd, qw/--raw --name-status/ if $verbose;
4188 push @cmd, '--color' if log_use_color();
4189 push @cmd, @log_opts;
4190 if (defined $r_max && $r_max == $r_min) {
4191 push @cmd, '--max-count=1';
4192 if (my $c = $gs->rev_map_get($r_max)) {
4193 push @cmd, $c;
4194 }
4195 } elsif (defined $r_max) {
4196 if ($r_max < $r_min) {
4197 ($r_min, $r_max) = ($r_max, $r_min);
4198 }
4199 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4200 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4201 # If there are no commits in the range, both $c_max and $c_min
4202 # will be undefined. If there is at least 1 commit in the
4203 # range, both will be defined.
4204 return () if !defined $c_min || !defined $c_max;
4205 if ($c_min eq $c_max) {
4206 push @cmd, '--max-count=1', $c_min;
4207 } else {
4208 push @cmd, '--boundary', "$c_min..$c_max";
4209 }
4210 }
4211 return (@cmd, @files);
4212 }
4213
4214 # adapted from pager.c
4215 sub config_pager {
4216 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4217 if (!defined $pager) {
4218 $pager = 'less';
4219 } elsif (length $pager == 0 || $pager eq 'cat') {
4220 $pager = undef;
4221 }
4222 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4223 }
4224
4225 sub run_pager {
4226 return unless -t *STDOUT && defined $pager;
4227 pipe my $rfd, my $wfd or return;
4228 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4229 if (!$pid) {
4230 open STDOUT, '>&', $wfd or
4231 ::fatal "Can't redirect to stdout: $!";
4232 return;
4233 }
4234 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4235 $ENV{LESS} ||= 'FRSX';
4236 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4237 }
4238
4239 sub format_svn_date {
4240 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4241 }
4242
4243 sub parse_git_date {
4244 my ($t, $tz) = @_;
4245 # Date::Parse isn't in the standard Perl distro :(
4246 if ($tz =~ s/^\+//) {
4247 $t += tz_to_s_offset($tz);
4248 } elsif ($tz =~ s/^\-//) {
4249 $t -= tz_to_s_offset($tz);
4250 }
4251 return $t;
4252 }
4253
4254 sub set_local_timezone {
4255 if (defined $TZ) {
4256 $ENV{TZ} = $TZ;
4257 } else {
4258 delete $ENV{TZ};
4259 }
4260 }
4261
4262 sub tz_to_s_offset {
4263 my ($tz) = @_;
4264 $tz =~ s/(\d\d)$//;
4265 return ($1 * 60) + ($tz * 3600);
4266 }
4267
4268 sub get_author_info {
4269 my ($dest, $author, $t, $tz) = @_;
4270 $author =~ s/(?:^\s*|\s*$)//g;
4271 $dest->{a_raw} = $author;
4272 my $au;
4273 if ($::_authors) {
4274 $au = $rusers{$author} || undef;
4275 }
4276 if (!$au) {
4277 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4278 }
4279 $dest->{t} = $t;
4280 $dest->{tz} = $tz;
4281 $dest->{a} = $au;
4282 $dest->{t_utc} = parse_git_date($t, $tz);
4283 }
4284
4285 sub process_commit {
4286 my ($c, $r_min, $r_max, $defer) = @_;
4287 if (defined $r_min && defined $r_max) {
4288 if ($r_min == $c->{r} && $r_min == $r_max) {
4289 show_commit($c);
4290 return 0;
4291 }
4292 return 1 if $r_min == $r_max;
4293 if ($r_min < $r_max) {
4294 # we need to reverse the print order
4295 return 0 if (defined $limit && --$limit < 0);
4296 push @$defer, $c;
4297 return 1;
4298 }
4299 if ($r_min != $r_max) {
4300 return 1 if ($r_min < $c->{r});
4301 return 1 if ($r_max > $c->{r});
4302 }
4303 }
4304 return 0 if (defined $limit && --$limit < 0);
4305 show_commit($c);
4306 return 1;
4307 }
4308
4309 sub show_commit {
4310 my $c = shift;
4311 if ($oneline) {
4312 my $x = "\n";
4313 if (my $l = $c->{l}) {
4314 while ($l->[0] =~ /^\s*$/) { shift @$l }
4315 $x = $l->[0];
4316 }
4317 $l_fmt ||= 'A' . length($c->{r});
4318 print 'r',pack($l_fmt, $c->{r}),' | ';
4319 print "$c->{c} | " if $show_commit;
4320 print $x;
4321 } else {
4322 show_commit_normal($c);
4323 }
4324 }
4325
4326 sub show_commit_changed_paths {
4327 my ($c) = @_;
4328 return unless $c->{changed};
4329 print "Changed paths:\n", @{$c->{changed}};
4330 }
4331
4332 sub show_commit_normal {
4333 my ($c) = @_;
4334 print commit_log_separator, "r$c->{r} | ";
4335 print "$c->{c} | " if $show_commit;
4336 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4337 my $nr_line = 0;
4338
4339 if (my $l = $c->{l}) {
4340 while ($l->[$#$l] eq "\n" && $#$l > 0
4341 && $l->[($#$l - 1)] eq "\n") {
4342 pop @$l;
4343 }
4344 $nr_line = scalar @$l;
4345 if (!$nr_line) {
4346 print "1 line\n\n\n";
4347 } else {
4348 if ($nr_line == 1) {
4349 $nr_line = '1 line';
4350 } else {
4351 $nr_line .= ' lines';
4352 }
4353 print $nr_line, "\n";
4354 show_commit_changed_paths($c);
4355 print "\n";
4356 print $_ foreach @$l;
4357 }
4358 } else {
4359 print "1 line\n";
4360 show_commit_changed_paths($c);
4361 print "\n";
4362
4363 }
4364 foreach my $x (qw/raw stat diff/) {
4365 if ($c->{$x}) {
4366 print "\n";
4367 print $_ foreach @{$c->{$x}}
4368 }
4369 }
4370 }
4371
4372 sub cmd_show_log {
4373 my (@args) = @_;
4374 my ($r_min, $r_max);
4375 my $r_last = -1; # prevent dupes
4376 set_local_timezone();
4377 if (defined $::_revision) {
4378 if ($::_revision =~ /^(\d+):(\d+)$/) {
4379 ($r_min, $r_max) = ($1, $2);
4380 } elsif ($::_revision =~ /^\d+$/) {
4381 $r_min = $r_max = $::_revision;
4382 } else {
4383 ::fatal "-r$::_revision is not supported, use ",
4384 "standard 'git log' arguments instead";
4385 }
4386 }
4387
4388 config_pager();
4389 @args = git_svn_log_cmd($r_min, $r_max, @args);
4390 if (!@args) {
4391 print commit_log_separator unless $incremental || $oneline;
4392 return;
4393 }
4394 my $log = command_output_pipe(@args);
4395 run_pager();
4396 my (@k, $c, $d, $stat);
4397 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4398 while (<$log>) {
4399 if (/^${esc_color}commit -?($::sha1_short)/o) {
4400 my $cmt = $1;
4401 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4402 $r_last = $c->{r};
4403 process_commit($c, $r_min, $r_max, \@k) or
4404 goto out;
4405 }
4406 $d = undef;
4407 $c = { c => $cmt };
4408 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4409 get_author_info($c, $1, $2, $3);
4410 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4411 # ignore
4412 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4413 push @{$c->{raw}}, $_;
4414 } elsif (/^${esc_color}[ACRMDT]\t/) {
4415 # we could add $SVN->{svn_path} here, but that requires
4416 # remote access at the moment (repo_path_split)...
4417 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4418 push @{$c->{changed}}, $_;
4419 } elsif (/^${esc_color}diff /o) {
4420 $d = 1;
4421 push @{$c->{diff}}, $_;
4422 } elsif ($d) {
4423 push @{$c->{diff}}, $_;
4424 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4425 $esc_color*[\+\-]*$esc_color$/x) {
4426 $stat = 1;
4427 push @{$c->{stat}}, $_;
4428 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4429 push @{$c->{stat}}, $_;
4430 $stat = undef;
4431 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4432 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4433 } elsif (s/^${esc_color} //o) {
4434 push @{$c->{l}}, $_;
4435 }
4436 }
4437 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4438 $r_last = $c->{r};
4439 process_commit($c, $r_min, $r_max, \@k);
4440 }
4441 if (@k) {
4442 ($r_min, $r_max) = ($r_max, $r_min);
4443 process_commit($_, $r_min, $r_max) foreach reverse @k;
4444 }
4445 out:
4446 close $log;
4447 print commit_log_separator unless $incremental || $oneline;
4448 }
4449
4450 package Git::SVN::Migration;
4451 # these version numbers do NOT correspond to actual version numbers
4452 # of git nor git-svn. They are just relative.
4453 #
4454 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4455 #
4456 # v1 layout: .git/$id/info/url, refs/remotes/$id
4457 #
4458 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4459 #
4460 # v3 layout: .git/svn/$id, refs/remotes/$id
4461 # - info/url may remain for backwards compatibility
4462 # - this is what we migrate up to this layout automatically,
4463 # - this will be used by git svn init on single branches
4464 # v3.1 layout (auto migrated):
4465 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4466 # for backwards compatibility
4467 #
4468 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4469 # - this is only created for newly multi-init-ed
4470 # repositories. Similar in spirit to the
4471 # --use-separate-remotes option in git-clone (now default)
4472 # - we do not automatically migrate to this (following
4473 # the example set by core git)
4474 #
4475 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4476 # - newer, more-efficient format that uses 24-bytes per record
4477 # with no filler space.
4478 # - use xxd -c24 < .rev_map.$UUID to view and debug
4479 # - This is a one-way migration, repositories updated to the
4480 # new format will not be able to use old git-svn without
4481 # rebuilding the .rev_db. Rebuilding the rev_db is not
4482 # possible if noMetadata or useSvmProps are set; but should
4483 # be no problem for users that use the (sensible) defaults.
4484 use strict;
4485 use warnings;
4486 use Carp qw/croak/;
4487 use File::Path qw/mkpath/;
4488 use File::Basename qw/dirname basename/;
4489 use vars qw/$_minimize/;
4490
4491 sub migrate_from_v0 {
4492 my $git_dir = $ENV{GIT_DIR};
4493 return undef unless -d $git_dir;
4494 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4495 my $migrated = 0;
4496 while (<$fh>) {
4497 chomp;
4498 my ($id, $orig_ref) = ($_, $_);
4499 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4500 next unless -f "$git_dir/$id/info/url";
4501 my $new_ref = "refs/remotes/$id";
4502 if (::verify_ref("$new_ref^0")) {
4503 print STDERR "W: $orig_ref is probably an old ",
4504 "branch used by an ancient version of ",
4505 "git-svn.\n",
4506 "However, $new_ref also exists.\n",
4507 "We will not be able ",
4508 "to use this branch until this ",
4509 "ambiguity is resolved.\n";
4510 next;
4511 }
4512 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4513 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4514 command_noisy('update-ref', $new_ref, $orig_ref);
4515 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4516 $migrated++;
4517 }
4518 command_close_pipe($fh, $ctx);
4519 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4520 $migrated;
4521 }
4522
4523 sub migrate_from_v1 {
4524 my $git_dir = $ENV{GIT_DIR};
4525 my $migrated = 0;
4526 return $migrated unless -d $git_dir;
4527 my $svn_dir = "$git_dir/svn";
4528
4529 # just in case somebody used 'svn' as their $id at some point...
4530 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4531
4532 print STDERR "Migrating from a git-svn v1 layout...\n";
4533 mkpath([$svn_dir]);
4534 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4535 "$svn_dir\n\t(required for this version ",
4536 "($::VERSION) of git-svn) does not. exist\n";
4537 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4538 while (<$fh>) {
4539 my $x = $_;
4540 next unless $x =~ s#^refs/remotes/##;
4541 chomp $x;
4542 next unless -f "$git_dir/$x/info/url";
4543 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4544 next unless $u;
4545 my $dn = dirname("$git_dir/svn/$x");
4546 mkpath([$dn]) unless -d $dn;
4547 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4548 mkpath(["$git_dir/svn/svn"]);
4549 print STDERR " - $git_dir/$x/info => ",
4550 "$git_dir/svn/$x/info\n";
4551 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4552 croak "$!: $x";
4553 # don't worry too much about these, they probably
4554 # don't exist with repos this old (save for index,
4555 # and we can easily regenerate that)
4556 foreach my $f (qw/unhandled.log index .rev_db/) {
4557 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4558 }
4559 } else {
4560 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4561 rename "$git_dir/$x", "$git_dir/svn/$x" or
4562 croak "$!: $x";
4563 }
4564 $migrated++;
4565 }
4566 command_close_pipe($fh, $ctx);
4567 print STDERR "Done migrating from a git-svn v1 layout\n";
4568 $migrated;
4569 }
4570
4571 sub read_old_urls {
4572 my ($l_map, $pfx, $path) = @_;
4573 my @dir;
4574 foreach (<$path/*>) {
4575 if (-r "$_/info/url") {
4576 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4577 my $ref_id = $pfx . basename $_;
4578 my $url = ::file_to_s("$_/info/url");
4579 $l_map->{$ref_id} = $url;
4580 } elsif (-d $_) {
4581 push @dir, $_;
4582 }
4583 }
4584 foreach (@dir) {
4585 my $x = $_;
4586 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4587 read_old_urls($l_map, $x, $_);
4588 }
4589 }
4590
4591 sub migrate_from_v2 {
4592 my @cfg = command(qw/config -l/);
4593 return if grep /^svn-remote\..+\.url=/, @cfg;
4594 my %l_map;
4595 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4596 my $migrated = 0;
4597
4598 foreach my $ref_id (sort keys %l_map) {
4599 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4600 if ($@) {
4601 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4602 }
4603 $migrated++;
4604 }
4605 $migrated;
4606 }
4607
4608 sub minimize_connections {
4609 my $r = Git::SVN::read_all_remotes();
4610 my $new_urls = {};
4611 my $root_repos = {};
4612 foreach my $repo_id (keys %$r) {
4613 my $url = $r->{$repo_id}->{url} or next;
4614 my $fetch = $r->{$repo_id}->{fetch} or next;
4615 my $ra = Git::SVN::Ra->new($url);
4616
4617 # skip existing cases where we already connect to the root
4618 if (($ra->{url} eq $ra->{repos_root}) ||
4619 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4620 $repo_id)) {
4621 $root_repos->{$ra->{url}} = $repo_id;
4622 next;
4623 }
4624
4625 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4626 my $root_path = $ra->{url};
4627 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4628 foreach my $path (keys %$fetch) {
4629 my $ref_id = $fetch->{$path};
4630 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4631
4632 # make sure we can read when connecting to
4633 # a higher level of a repository
4634 my ($last_rev, undef) = $gs->last_rev_commit;
4635 if (!defined $last_rev) {
4636 $last_rev = eval {
4637 $root_ra->get_latest_revnum;
4638 };
4639 next if $@;
4640 }
4641 my $new = $root_path;
4642 $new .= length $path ? "/$path" : '';
4643 eval {
4644 $root_ra->get_log([$new], $last_rev, $last_rev,
4645 0, 0, 1, sub { });
4646 };
4647 next if $@;
4648 $new_urls->{$ra->{repos_root}}->{$new} =
4649 { ref_id => $ref_id,
4650 old_repo_id => $repo_id,
4651 old_path => $path };
4652 }
4653 }
4654
4655 my @emptied;
4656 foreach my $url (keys %$new_urls) {
4657 # see if we can re-use an existing [svn-remote "repo_id"]
4658 # instead of creating a(n ugly) new section:
4659 my $repo_id = $root_repos->{$url} ||
4660 Git::SVN::sanitize_remote_name($url);
4661
4662 my $fetch = $new_urls->{$url};
4663 foreach my $path (keys %$fetch) {
4664 my $x = $fetch->{$path};
4665 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4666 my $pfx = "svn-remote.$x->{old_repo_id}";
4667
4668 my $old_fetch = quotemeta("$x->{old_path}:".
4669 "refs/remotes/$x->{ref_id}");
4670 command_noisy(qw/config --unset/,
4671 "$pfx.fetch", '^'. $old_fetch . '$');
4672 delete $r->{$x->{old_repo_id}}->
4673 {fetch}->{$x->{old_path}};
4674 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4675 command_noisy(qw/config --unset/,
4676 "$pfx.url");
4677 push @emptied, $x->{old_repo_id}
4678 }
4679 }
4680 }
4681 if (@emptied) {
4682 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4683 "$ENV{GIT_DIR}/config";
4684 print STDERR <<EOF;
4685 The following [svn-remote] sections in your config file ($file) are empty
4686 and can be safely removed:
4687 EOF
4688 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4689 }
4690 }
4691
4692 sub migration_check {
4693 migrate_from_v0();
4694 migrate_from_v1();
4695 migrate_from_v2();
4696 minimize_connections() if $_minimize;
4697 }
4698
4699 package Git::IndexInfo;
4700 use strict;
4701 use warnings;
4702 use Git qw/command_input_pipe command_close_pipe/;
4703
4704 sub new {
4705 my ($class) = @_;
4706 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4707 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4708 }
4709
4710 sub remove {
4711 my ($self, $path) = @_;
4712 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4713 return ++$self->{nr};
4714 }
4715 undef;
4716 }
4717
4718 sub update {
4719 my ($self, $mode, $hash, $path) = @_;
4720 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4721 return ++$self->{nr};
4722 }
4723 undef;
4724 }
4725
4726 sub DESTROY {
4727 my ($self) = @_;
4728 command_close_pipe($self->{gui}, $self->{ctx});
4729 }
4730
4731 package Git::SVN::GlobSpec;
4732 use strict;
4733 use warnings;
4734
4735 sub new {
4736 my ($class, $glob) = @_;
4737 my $re = $glob;
4738 $re =~ s!/+$!!g; # no need for trailing slashes
4739 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4740 my ($left, $right) = ($1, $2);
4741 if ($nr > 1) {
4742 die "Only one '*' wildcard expansion ",
4743 "is supported (got $nr): '$glob'\n";
4744 } elsif ($nr == 0) {
4745 die "One '*' is needed for glob: '$glob'\n";
4746 }
4747 $re = quotemeta($left) . $re . quotemeta($right);
4748 if (length $left && !($left =~ s!/+$!!g)) {
4749 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4750 }
4751 if (length $right && !($right =~ s!^/+!!g)) {
4752 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4753 }
4754 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4755 bless { left => $left, right => $right, left_regex => $left_re,
4756 regex => qr/$re/, glob => $glob }, $class;
4757 }
4758
4759 sub full_path {
4760 my ($self, $path) = @_;
4761 return (length $self->{left} ? "$self->{left}/" : '') .
4762 $path . (length $self->{right} ? "/$self->{right}" : '');
4763 }
4764
4765 __END__
4766
4767 Data structures:
4768
4769
4770 $remotes = { # returned by read_all_remotes()
4771 'svn' => {
4772 # svn-remote.svn.url=https://svn.musicpd.org
4773 url => 'https://svn.musicpd.org',
4774 # svn-remote.svn.fetch=mpd/trunk:trunk
4775 fetch => {
4776 'mpd/trunk' => 'trunk',
4777 },
4778 # svn-remote.svn.tags=mpd/tags/*:tags/*
4779 tags => {
4780 path => {
4781 left => 'mpd/tags',
4782 right => '',
4783 regex => qr!mpd/tags/([^/]+)$!,
4784 glob => 'tags/*',
4785 },
4786 ref => {
4787 left => 'tags',
4788 right => '',
4789 regex => qr!tags/([^/]+)$!,
4790 glob => 'tags/*',
4791 },
4792 }
4793 }
4794 };
4795
4796 $log_entry hashref as returned by libsvn_log_entry()
4797 {
4798 log => 'whitespace-formatted log entry
4799 ', # trailing newline is preserved
4800 revision => '8', # integer
4801 date => '2004-02-24T17:01:44.108345Z', # commit date
4802 author => 'committer name'
4803 };
4804
4805
4806 # this is generated by generate_diff();
4807 @mods = array of diff-index line hashes, each element represents one line
4808 of diff-index output
4809
4810 diff-index line ($m hash)
4811 {
4812 mode_a => first column of diff-index output, no leading ':',
4813 mode_b => second column of diff-index output,
4814 sha1_b => sha1sum of the final blob,
4815 chg => change type [MCRADT],
4816 file_a => original file name of a file (iff chg is 'C' or 'R')
4817 file_b => new/current file name of a file (any chg)
4818 }
4819 ;
4820
4821 # retval of read_url_paths{,_all}();
4822 $l_map = {
4823 # repository root url
4824 'https://svn.musicpd.org' => {
4825 # repository path # GIT_SVN_ID
4826 'mpd/trunk' => 'trunk',
4827 'mpd/tags/0.11.5' => 'tags/0.11.5',
4828 },
4829 }
4830
4831 Notes:
4832 I don't trust the each() function on unless I created %hash myself
4833 because the internal iterator may not have started at base.
MinGW port of GIT