git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = Git::command_oneline('var', 'GIT_EDITOR');
 166
 167 sub do_edit {
 168         if (defined($multiedit) && !$multiedit) {
 169                 map {
 170                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 171                         if (($? & 127) || ($? >> 8)) {
 172                                 die("the editor exited uncleanly, aborting everything");
 173                         }
 174                 } @_;
 175         } else {
 176                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 177                 if (($? & 127) || ($? >> 8)) {
 178                         die("the editor exited uncleanly, aborting everything");
 179                 }
 180         }
 181 }
 182
 183 # Variables with corresponding config settings
 184 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 185 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 186 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 187 my ($validate, $confirm);
 188 my (@suppress_cc);
 189
 190 my %config_bool_settings = (
 191     "thread" => [\$thread, 1],
 192     "chainreplyto" => [\$chain_reply_to, 1],
 193     "suppressfrom" => [\$suppress_from, undef],
 194     "signedoffbycc" => [\$signed_off_by_cc, undef],
 195     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 196     "validate" => [\$validate, 1],
 197 );
 198
 199 my %config_settings = (
 200     "smtpserver" => \$smtp_server,
 201     "smtpserverport" => \$smtp_server_port,
 202     "smtpuser" => \$smtp_authuser,
 203     "smtppass" => \$smtp_authpass,
 204     "to" => \@to,
 205     "cc" => \@initial_cc,
 206     "cccmd" => \$cc_cmd,
 207     "aliasfiletype" => \$aliasfiletype,
 208     "bcc" => \@bcclist,
 209     "aliasesfile" => \@alias_files,
 210     "suppresscc" => \@suppress_cc,
 211     "envelopesender" => \$envelope_sender,
 212     "multiedit" => \$multiedit,
 213     "confirm"   => \$confirm,
 214     "from" => \$sender,
 215 );
 216
 217 # Handle Uncouth Termination
 218 sub signal_handler {
 219
 220         # Make text normal
 221         print color("reset"), "\n";
 222
 223         # SMTP password masked
 224         system "stty echo";
 225
 226         # tmp files from --compose
 227         if (defined $compose_filename) {
 228                 if (-e $compose_filename) {
 229                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 230                 }
 231                 if (-e ($compose_filename . ".final")) {
 232                         print "'$compose_filename.final' contains the composed email.\n"
 233                 }
 234         }
 235
 236         exit;
 237 };
 238
 239 $SIG{TERM} = \&signal_handler;
 240 $SIG{INT}  = \&signal_handler;
 241
 242 # Begin by accumulating all the variables (defined above), that we will end up
 243 # needing, first, from the command line:
 244
 245 my $rc = GetOptions("sender|from=s" => \$sender,
 246                     "in-reply-to=s" => \$initial_reply_to,
 247                     "subject=s" => \$initial_subject,
 248                     "to=s" => \@to,
 249                     "cc=s" => \@initial_cc,
 250                     "bcc=s" => \@bcclist,
 251                     "chain-reply-to!" => \$chain_reply_to,
 252                     "smtp-server=s" => \$smtp_server,
 253                     "smtp-server-port=s" => \$smtp_server_port,
 254                     "smtp-user=s" => \$smtp_authuser,
 255                     "smtp-pass:s" => \$smtp_authpass,
 256                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 257                     "smtp-encryption=s" => \$smtp_encryption,
 258                     "identity=s" => \$identity,
 259                     "annotate" => \$annotate,
 260                     "compose" => \$compose,
 261                     "quiet" => \$quiet,
 262                     "cc-cmd=s" => \$cc_cmd,
 263                     "suppress-from!" => \$suppress_from,
 264                     "suppress-cc=s" => \@suppress_cc,
 265                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 266                     "confirm=s" => \$confirm,
 267                     "dry-run" => \$dry_run,
 268                     "envelope-sender=s" => \$envelope_sender,
 269                     "thread!" => \$thread,
 270                     "validate!" => \$validate,
 271                     "format-patch!" => \$format_patch,
 272          );
 273
 274 unless ($rc) {
 275     usage();
 276 }
 277
 278 die "Cannot run git format-patch from outside a repository\n"
 279         if $format_patch and not $repo;
 280
 281 # Now, let's fill any that aren't set in with defaults:
 282
 283 sub read_config {
 284         my ($prefix) = @_;
 285
 286         foreach my $setting (keys %config_bool_settings) {
 287                 my $target = $config_bool_settings{$setting}->[0];
 288                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 289         }
 290
 291         foreach my $setting (keys %config_settings) {
 292                 my $target = $config_settings{$setting};
 293                 if (ref($target) eq "ARRAY") {
 294                         unless (@$target) {
 295                                 my @values = Git::config(@repo, "$prefix.$setting");
 296                                 @$target = @values if (@values && defined $values[0]);
 297                         }
 298                 }
 299                 else {
 300                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 301                 }
 302         }
 303
 304         if (!defined $smtp_encryption) {
 305                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 306                 if (defined $enc) {
 307                         $smtp_encryption = $enc;
 308                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 309                         $smtp_encryption = 'ssl';
 310                 }
 311         }
 312 }
 313
 314 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 315 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 316 read_config("sendemail.$identity") if (defined $identity);
 317 read_config("sendemail");
 318
 319 # fall back on builtin bool defaults
 320 foreach my $setting (values %config_bool_settings) {
 321         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 322 }
 323
 324 # 'default' encryption is none -- this only prevents a warning
 325 $smtp_encryption = '' unless (defined $smtp_encryption);
 326
 327 # Set CC suppressions
 328 my(%suppress_cc);
 329 if (@suppress_cc) {
 330         foreach my $entry (@suppress_cc) {
 331                 die "Unknown --suppress-cc field: '$entry'\n"
 332                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 333                 $suppress_cc{$entry} = 1;
 334         }
 335 }
 336
 337 if ($suppress_cc{'all'}) {
 338         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 339                 $suppress_cc{$entry} = 1;
 340         }
 341         delete $suppress_cc{'all'};
 342 }
 343
 344 # If explicit old-style ones are specified, they trump --suppress-cc.
 345 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 346 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 347
 348 if ($suppress_cc{'body'}) {
 349         foreach my $entry (qw (sob bodycc)) {
 350                 $suppress_cc{$entry} = 1;
 351         }
 352         delete $suppress_cc{'body'};
 353 }
 354
 355 # Set confirm's default value
 356 my $confirm_unconfigured = !defined $confirm;
 357 if ($confirm_unconfigured) {
 358         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 359 };
 360 die "Unknown --confirm setting: '$confirm'\n"
 361         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 362
 363 # Debugging, print out the suppressions.
 364 if (0) {
 365         print "suppressions:\n";
 366         foreach my $entry (keys %suppress_cc) {
 367                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 368         }
 369 }
 370
 371 my ($repoauthor, $repocommitter);
 372 ($repoauthor) = Git::ident_person(@repo, 'author');
 373 ($repocommitter) = Git::ident_person(@repo, 'committer');
 374
 375 # Verify the user input
 376
 377 foreach my $entry (@to) {
 378         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 379 }
 380
 381 foreach my $entry (@initial_cc) {
 382         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 383 }
 384
 385 foreach my $entry (@bcclist) {
 386         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 387 }
 388
 389 sub parse_address_line {
 390         if ($have_mail_address) {
 391                 return map { $_->format } Mail::Address->parse($_[0]);
 392         } else {
 393                 return split_addrs($_[0]);
 394         }
 395 }
 396
 397 sub split_addrs {
 398         return quotewords('\s*,\s*', 1, @_);
 399 }
 400
 401 my %aliases;
 402 my %parse_alias = (
 403         # multiline formats can be supported in the future
 404         mutt => sub { my $fh = shift; while (<$fh>) {
 405                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 406                         my ($alias, $addr) = ($1, $2);
 407                         $addr =~ s/#.*$//; # mutt allows # comments
 408                          # commas delimit multiple addresses
 409                         $aliases{$alias} = [ split_addrs($addr) ];
 410                 }}},
 411         mailrc => sub { my $fh = shift; while (<$fh>) {
 412                 if (/^alias\s+(\S+)\s+(.*)$/) {
 413                         # spaces delimit multiple addresses
 414                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 415                 }}},
 416         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 417                 for (my $x = ''; defined($x); $x = $_) {
 418                         chomp $x;
 419                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 420                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 421                         $aliases{$1} = [ split_addrs($2) ];
 422                 }},
 423         elm => sub  { my $fh = shift;
 424                       while (<$fh>) {
 425                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 426                               my ($alias, $addr) = ($1, $2);
 427                                $aliases{$alias} = [ split_addrs($addr) ];
 428                           }
 429                       } },
 430
 431         gnus => sub { my $fh = shift; while (<$fh>) {
 432                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 433                         $aliases{$1} = [ $2 ];
 434                 }}}
 435 );
 436
 437 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 438         foreach my $file (@alias_files) {
 439                 open my $fh, '<', $file or die "opening $file: $!\n";
 440                 $parse_alias{$aliasfiletype}->($fh);
 441                 close $fh;
 442         }
 443 }
 444
 445 ($sender) = expand_aliases($sender) if defined $sender;
 446
 447 # returns 1 if the conflict must be solved using it as a format-patch argument
 448 sub check_file_rev_conflict($) {
 449         return unless $repo;
 450         my $f = shift;
 451         try {
 452                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 453                 if (defined($format_patch)) {
 454                         return $format_patch;
 455                 }
 456                 die(<<EOF);
 457 File '$f' exists but it could also be the range of commits
 458 to produce patches for.  Please disambiguate by...
 459
 460     * Saying "./$f" if you mean a file; or
 461     * Giving --format-patch option if you mean a range.
 462 EOF
 463         } catch Git::Error::Command with {
 464                 return 0;
 465         }
 466 }
 467
 468 # Now that all the defaults are set, process the rest of the command line
 469 # arguments and collect up the files that need to be processed.
 470 my @rev_list_opts;
 471 while (defined(my $f = shift @ARGV)) {
 472         if ($f eq "--") {
 473                 push @rev_list_opts, "--", @ARGV;
 474                 @ARGV = ();
 475         } elsif (-d $f and !check_file_rev_conflict($f)) {
 476                 opendir(DH,$f)
 477                         or die "Failed to opendir $f: $!";
 478
 479                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 480                                 sort readdir(DH);
 481                 closedir(DH);
 482         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 483                 push @files, $f;
 484         } else {
 485                 push @rev_list_opts, $f;
 486         }
 487 }
 488
 489 if (@rev_list_opts) {
 490         die "Cannot run git format-patch from outside a repository\n"
 491                 unless $repo;
 492         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 493 }
 494
 495 if ($validate) {
 496         foreach my $f (@files) {
 497                 unless (-p $f) {
 498                         my $error = validate_patch($f);
 499                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 500                 }
 501         }
 502 }
 503
 504 if (@files) {
 505         unless ($quiet) {
 506                 print $_,"\n" for (@files);
 507         }
 508 } else {
 509         print STDERR "\nNo patch files specified!\n\n";
 510         usage();
 511 }
 512
 513 sub get_patch_subject($) {
 514         my $fn = shift;
 515         open (my $fh, '<', $fn);
 516         while (my $line = <$fh>) {
 517                 next unless ($line =~ /^Subject: (.*)$/);
 518                 close $fh;
 519                 return "GIT: $1\n";
 520         }
 521         close $fh;
 522         die "No subject line in $fn ?";
 523 }
 524
 525 if ($compose) {
 526         # Note that this does not need to be secure, but we will make a small
 527         # effort to have it be unique
 528         $compose_filename = ($repo ?
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 530                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 531         open(C,">",$compose_filename)
 532                 or die "Failed to open for writing $compose_filename: $!";
 533
 534
 535         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 536         my $tpl_subject = $initial_subject || '';
 537         my $tpl_reply_to = $initial_reply_to || '';
 538
 539         print C <<EOT;
 540 From $tpl_sender # This line is ignored.
 541 GIT: Lines beginning in "GIT:" will be removed.
 542 GIT: Consider including an overall diffstat or table of contents
 543 GIT: for the patch you are writing.
 544 GIT:
 545 GIT: Clear the body content if you don't wish to send a summary.
 546 From: $tpl_sender
 547 Subject: $tpl_subject
 548 In-Reply-To: $tpl_reply_to
 549
 550 EOT
 551         for my $f (@files) {
 552                 print C get_patch_subject($f);
 553         }
 554         close(C);
 555
 556         if ($annotate) {
 557                 do_edit($compose_filename, @files);
 558         } else {
 559                 do_edit($compose_filename);
 560         }
 561
 562         open(C2,">",$compose_filename . ".final")
 563                 or die "Failed to open $compose_filename.final : " . $!;
 564
 565         open(C,"<",$compose_filename)
 566                 or die "Failed to open $compose_filename : " . $!;
 567
 568         my $need_8bit_cte = file_has_nonascii($compose_filename);
 569         my $in_body = 0;
 570         my $summary_empty = 1;
 571         while(<C>) {
 572                 next if m/^GIT:/;
 573                 if ($in_body) {
 574                         $summary_empty = 0 unless (/^\n$/);
 575                 } elsif (/^\n$/) {
 576                         $in_body = 1;
 577                         if ($need_8bit_cte) {
 578                                 print C2 "MIME-Version: 1.0\n",
 579                                          "Content-Type: text/plain; ",
 580                                            "charset=UTF-8\n",
 581                                          "Content-Transfer-Encoding: 8bit\n";
 582                         }
 583                 } elsif (/^MIME-Version:/i) {
 584                         $need_8bit_cte = 0;
 585                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 586                         $initial_subject = $1;
 587                         my $subject = $initial_subject;
 588                         $_ = "Subject: " .
 589                                 ($subject =~ /[^[:ascii:]]/ ?
 590                                  quote_rfc2047($subject) :
 591                                  $subject) .
 592                                 "\n";
 593                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 594                         $initial_reply_to = $1;
 595                         next;
 596                 } elsif (/^From:\s*(.+)\s*$/i) {
 597                         $sender = $1;
 598                         next;
 599                 } elsif (/^(?:To|Cc|Bcc):/i) {
 600                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 601                         next;
 602                 }
 603                 print C2 $_;
 604         }
 605         close(C);
 606         close(C2);
 607
 608         if ($summary_empty) {
 609                 print "Summary email is empty, skipping it\n";
 610                 $compose = -1;
 611         }
 612 } elsif ($annotate) {
 613         do_edit(@files);
 614 }
 615
 616 sub ask {
 617         my ($prompt, %arg) = @_;
 618         my $valid_re = $arg{valid_re};
 619         my $default = $arg{default};
 620         my $resp;
 621         my $i = 0;
 622         return defined $default ? $default : undef
 623                 unless defined $term->IN and defined fileno($term->IN) and
 624                        defined $term->OUT and defined fileno($term->OUT);
 625         while ($i++ < 10) {
 626                 $resp = $term->readline($prompt);
 627                 if (!defined $resp) { # EOF
 628                         print "\n";
 629                         return defined $default ? $default : undef;
 630                 }
 631                 if ($resp eq '' and defined $default) {
 632                         return $default;
 633                 }
 634                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 635                         return $resp;
 636                 }
 637         }
 638         return undef;
 639 }
 640
 641 my $prompting = 0;
 642 if (!defined $sender) {
 643         $sender = $repoauthor || $repocommitter || '';
 644         $sender = ask("Who should the emails appear to be from? [$sender] ",
 645                       default => $sender);
 646         print "Emails will be sent from: ", $sender, "\n";
 647         $prompting++;
 648 }
 649
 650 if (!@to) {
 651         my $to = ask("Who should the emails be sent to? ");
 652         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 653         $prompting++;
 654 }
 655
 656 sub expand_aliases {
 657         return map { expand_one_alias($_) } @_;
 658 }
 659
 660 my %EXPANDED_ALIASES;
 661 sub expand_one_alias {
 662         my $alias = shift;
 663         if ($EXPANDED_ALIASES{$alias}) {
 664                 die "fatal: alias '$alias' expands to itself\n";
 665         }
 666         local $EXPANDED_ALIASES{$alias} = 1;
 667         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 668 }
 669
 670 @to = expand_aliases(@to);
 671 @to = (map { sanitize_address($_) } @to);
 672 @initial_cc = expand_aliases(@initial_cc);
 673 @bcclist = expand_aliases(@bcclist);
 674
 675 if ($thread && !defined $initial_reply_to && $prompting) {
 676         $initial_reply_to = ask(
 677                 "Message-ID to be used as In-Reply-To for the first email? ");
 678 }
 679 if (defined $initial_reply_to) {
 680         $initial_reply_to =~ s/^\s*<?//;
 681         $initial_reply_to =~ s/>?\s*$//;
 682         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 683 }
 684
 685 if (!defined $smtp_server) {
 686         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 687                 if (-x $_) {
 688                         $smtp_server = $_;
 689                         last;
 690                 }
 691         }
 692         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 693 }
 694
 695 if ($compose && $compose > 0) {
 696         @files = ($compose_filename . ".final", @files);
 697 }
 698
 699 # Variables we set as part of the loop over files
 700 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 701         $needs_confirm, $message_num, $ask_default);
 702
 703 sub extract_valid_address {
 704         my $address = shift;
 705         my $local_part_regexp = '[^<>"\s@]+';
 706         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 707
 708         # check for a local address:
 709         return $address if ($address =~ /^($local_part_regexp)$/);
 710
 711         $address =~ s/^\s*<(.*)>\s*$/$1/;
 712         if ($have_email_valid) {
 713                 return scalar Email::Valid->address($address);
 714         } else {
 715                 # less robust/correct than the monster regexp in Email::Valid,
 716                 # but still does a 99% job, and one less dependency
 717                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 718                 return $1;
 719         }
 720 }
 721
 722 # Usually don't need to change anything below here.
 723
 724 # we make a "fake" message id by taking the current number
 725 # of seconds since the beginning of Unix time and tacking on
 726 # a random number to the end, in case we are called quicker than
 727 # 1 second since the last time we were called.
 728
 729 # We'll setup a template for the message id, using the "from" address:
 730
 731 my ($message_id_stamp, $message_id_serial);
 732 sub make_message_id
 733 {
 734         my $uniq;
 735         if (!defined $message_id_stamp) {
 736                 $message_id_stamp = sprintf("%s-%s", time, $$);
 737                 $message_id_serial = 0;
 738         }
 739         $message_id_serial++;
 740         $uniq = "$message_id_stamp-$message_id_serial";
 741
 742         my $du_part;
 743         for ($sender, $repocommitter, $repoauthor) {
 744                 $du_part = extract_valid_address(sanitize_address($_));
 745                 last if (defined $du_part and $du_part ne '');
 746         }
 747         if (not defined $du_part or $du_part eq '') {
 748                 use Sys::Hostname qw();
 749                 $du_part = 'user@' . Sys::Hostname::hostname();
 750         }
 751         my $message_id_template = "<%s-git-send-email-%s>";
 752         $message_id = sprintf($message_id_template, $uniq, $du_part);
 753         #print "new message id = $message_id\n"; # Was useful for debugging
 754 }
 755
 756
 757
 758 $time = time - scalar $#files;
 759
 760 sub unquote_rfc2047 {
 761         local ($_) = @_;
 762         my $encoding;
 763         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 764                 $encoding = $1;
 765                 s/_/ /g;
 766                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 767         }
 768         return wantarray ? ($_, $encoding) : $_;
 769 }
 770
 771 sub quote_rfc2047 {
 772         local $_ = shift;
 773         my $encoding = shift || 'UTF-8';
 774         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 775         s/(.*)/=\?$encoding\?q\?$1\?=/;
 776         return $_;
 777 }
 778
 779 sub is_rfc2047_quoted {
 780         my $s = shift;
 781         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 782         my $encoded_text = '[!->@-~]+';
 783         length($s) <= 75 &&
 784         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 785 }
 786
 787 # use the simplest quoting being able to handle the recipient
 788 sub sanitize_address
 789 {
 790         my ($recipient) = @_;
 791         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 792
 793         if (not $recipient_name) {
 794                 return "$recipient";
 795         }
 796
 797         # if recipient_name is already quoted, do nothing
 798         if (is_rfc2047_quoted($recipient_name)) {
 799                 return $recipient;
 800         }
 801
 802         # rfc2047 is needed if a non-ascii char is included
 803         if ($recipient_name =~ /[^[:ascii:]]/) {
 804                 $recipient_name =~ s/^"(.*)"$/$1/;
 805                 $recipient_name = quote_rfc2047($recipient_name);
 806         }
 807
 808         # double quotes are needed if specials or CTLs are included
 809         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 810                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 811                 $recipient_name = "\"$recipient_name\"";
 812         }
 813
 814         return "$recipient_name $recipient_addr";
 815
 816 }
 817
 818 # Returns 1 if the message was sent, and 0 otherwise.
 819 # In actuality, the whole program dies when there
 820 # is an error sending a message.
 821
 822 sub send_message
 823 {
 824         my @recipients = unique_email_list(@to);
 825         @cc = (grep { my $cc = extract_valid_address($_);
 826                       not grep { $cc eq $_ } @recipients
 827                     }
 828                map { sanitize_address($_) }
 829                @cc);
 830         my $to = join (",\n\t", @recipients);
 831         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 832         @recipients = (map { extract_valid_address($_) } @recipients);
 833         my $date = format_2822_time($time++);
 834         my $gitversion = '@@GIT_VERSION@@';
 835         if ($gitversion =~ m/..GIT_VERSION../) {
 836             $gitversion = Git::version();
 837         }
 838
 839         my $cc = join(",\n\t", unique_email_list(@cc));
 840         my $ccline = "";
 841         if ($cc ne '') {
 842                 $ccline = "\nCc: $cc";
 843         }
 844         my $sanitized_sender = sanitize_address($sender);
 845         make_message_id() unless defined($message_id);
 846
 847         my $header = "From: $sanitized_sender
 848 To: $to${ccline}
 849 Subject: $subject
 850 Date: $date
 851 Message-Id: $message_id
 852 X-Mailer: git-send-email $gitversion
 853 ";
 854         if ($reply_to) {
 855
 856                 $header .= "In-Reply-To: $reply_to\n";
 857                 $header .= "References: $references\n";
 858         }
 859         if (@xh) {
 860                 $header .= join("\n", @xh) . "\n";
 861         }
 862
 863         my @sendmail_parameters = ('-i', @recipients);
 864         my $raw_from = $sanitized_sender;
 865         $raw_from = $envelope_sender if (defined $envelope_sender);
 866         $raw_from = extract_valid_address($raw_from);
 867         unshift (@sendmail_parameters,
 868                         '-f', $raw_from) if(defined $envelope_sender);
 869
 870         if ($needs_confirm && !$dry_run) {
 871                 print "\n$header\n";
 872                 if ($needs_confirm eq "inform") {
 873                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 874                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 875                         print "    The Cc list above has been expanded by additional\n";
 876                         print "    addresses found in the patch commit message. By default\n";
 877                         print "    send-email prompts before sending whenever this occurs.\n";
 878                         print "    This behavior is controlled by the sendemail.confirm\n";
 879                         print "    configuration setting.\n";
 880                         print "\n";
 881                         print "    For additional information, run 'git send-email --help'.\n";
 882                         print "    To retain the current behavior, but squelch this message,\n";
 883                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 884                 }
 885                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 886                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 887                          default => $ask_default);
 888                 die "Send this email reply required" unless defined $_;
 889                 if (/^n/i) {
 890                         return 0;
 891                 } elsif (/^q/i) {
 892                         cleanup_compose_files();
 893                         exit(0);
 894                 } elsif (/^a/i) {
 895                         $confirm = 'never';
 896                 }
 897         }
 898
 899         if ($dry_run) {
 900                 # We don't want to send the email.
 901         } elsif ($smtp_server =~ m#^/#) {
 902                 my $pid = open my $sm, '|-';
 903                 defined $pid or die $!;
 904                 if (!$pid) {
 905                         exec($smtp_server, @sendmail_parameters) or die $!;
 906                 }
 907                 print $sm "$header\n$message";
 908                 close $sm or die $?;
 909         } else {
 910
 911                 if (!defined $smtp_server) {
 912                         die "The required SMTP server is not properly defined."
 913                 }
 914
 915                 if ($smtp_encryption eq 'ssl') {
 916                         $smtp_server_port ||= 465; # ssmtp
 917                         require Net::SMTP::SSL;
 918                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 919                 }
 920                 else {
 921                         require Net::SMTP;
 922                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 923                                                  ? "$smtp_server:$smtp_server_port"
 924                                                  : $smtp_server);
 925                         if ($smtp_encryption eq 'tls' && $smtp) {
 926                                 require Net::SMTP::SSL;
 927                                 $smtp->command('STARTTLS');
 928                                 $smtp->response();
 929                                 if ($smtp->code == 220) {
 930                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 931                                                 or die "STARTTLS failed! ".$smtp->message;
 932                                         $smtp_encryption = '';
 933                                         # Send EHLO again to receive fresh
 934                                         # supported commands
 935                                         $smtp->hello();
 936                                 } else {
 937                                         die "Server does not support STARTTLS! ".$smtp->message;
 938                                 }
 939                         }
 940                 }
 941
 942                 if (!$smtp) {
 943                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 944                 }
 945
 946                 if (defined $smtp_authuser) {
 947
 948                         if (!defined $smtp_authpass) {
 949
 950                                 system "stty -echo";
 951
 952                                 do {
 953                                         print "Password: ";
 954                                         $_ = <STDIN>;
 955                                         print "\n";
 956                                 } while (!defined $_);
 957
 958                                 chomp($smtp_authpass = $_);
 959
 960                                 system "stty echo";
 961                         }
 962
 963                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 964                 }
 965
 966                 $smtp->mail( $raw_from ) or die $smtp->message;
 967                 $smtp->to( @recipients ) or die $smtp->message;
 968                 $smtp->data or die $smtp->message;
 969                 $smtp->datasend("$header\n$message") or die $smtp->message;
 970                 $smtp->dataend() or die $smtp->message;
 971                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 972         }
 973         if ($quiet) {
 974                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 975         } else {
 976                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 977                 if ($smtp_server !~ m#^/#) {
 978                         print "Server: $smtp_server\n";
 979                         print "MAIL FROM:<$raw_from>\n";
 980                         foreach my $entry (@recipients) {
 981                             print "RCPT TO:<$entry>\n";
 982                         }
 983                 } else {
 984                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 985                 }
 986                 print $header, "\n";
 987                 if ($smtp) {
 988                         print "Result: ", $smtp->code, ' ',
 989                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 990                 } else {
 991                         print "Result: OK\n";
 992                 }
 993         }
 994
 995         return 1;
 996 }
 997
 998 $reply_to = $initial_reply_to;
 999 $references = $initial_reply_to || '';
1000 $subject = $initial_subject;
1001 $message_num = 0;
1002
1003 foreach my $t (@files) {
1004         open(F,"<",$t) or die "can't open file $t";
1005
1006         my $author = undef;
1007         my $author_encoding;
1008         my $has_content_type;
1009         my $body_encoding;
1010         @cc = ();
1011         @xh = ();
1012         my $input_format = undef;
1013         my @header = ();
1014         $message = "";
1015         $message_num++;
1016         # First unfold multiline header fields
1017         while(<F>) {
1018                 last if /^\s*$/;
1019                 if (/^\s+\S/ and @header) {
1020                         chomp($header[$#header]);
1021                         s/^\s+/ /;
1022                         $header[$#header] .= $_;
1023             } else {
1024                         push(@header, $_);
1025                 }
1026         }
1027         # Now parse the header
1028         foreach(@header) {
1029                 if (/^From /) {
1030                         $input_format = 'mbox';
1031                         next;
1032                 }
1033                 chomp;
1034                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1035                         $input_format = 'mbox';
1036                 }
1037
1038                 if (defined $input_format && $input_format eq 'mbox') {
1039                         if (/^Subject:\s+(.*)$/) {
1040                                 $subject = $1;
1041                         }
1042                         elsif (/^From:\s+(.*)$/) {
1043                                 ($author, $author_encoding) = unquote_rfc2047($1);
1044                                 next if $suppress_cc{'author'};
1045                                 next if $suppress_cc{'self'} and $author eq $sender;
1046                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1047                                         $1, $_) unless $quiet;
1048                                 push @cc, $1;
1049                         }
1050                         elsif (/^Cc:\s+(.*)$/) {
1051                                 foreach my $addr (parse_address_line($1)) {
1052                                         if (unquote_rfc2047($addr) eq $sender) {
1053                                                 next if ($suppress_cc{'self'});
1054                                         } else {
1055                                                 next if ($suppress_cc{'cc'});
1056                                         }
1057                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1058                                                 $addr, $_) unless $quiet;
1059                                         push @cc, $addr;
1060                                 }
1061                         }
1062                         elsif (/^Content-type:/i) {
1063                                 $has_content_type = 1;
1064                                 if (/charset="?([^ "]+)/) {
1065                                         $body_encoding = $1;
1066                                 }
1067                                 push @xh, $_;
1068                         }
1069                         elsif (/^Message-Id: (.*)/i) {
1070                                 $message_id = $1;
1071                         }
1072                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1073                                 push @xh, $_;
1074                         }
1075
1076                 } else {
1077                         # In the traditional
1078                         # "send lots of email" format,
1079                         # line 1 = cc
1080                         # line 2 = subject
1081                         # So let's support that, too.
1082                         $input_format = 'lots';
1083                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1084                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1085                                         $_, $_) unless $quiet;
1086                                 push @cc, $_;
1087                         } elsif (!defined $subject) {
1088                                 $subject = $_;
1089                         }
1090                 }
1091         }
1092         # Now parse the message body
1093         while(<F>) {
1094                 $message .=  $_;
1095                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1096                         chomp;
1097                         my ($what, $c) = ($1, $2);
1098                         chomp $c;
1099                         if ($c eq $sender) {
1100                                 next if ($suppress_cc{'self'});
1101                         } else {
1102                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1103                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1104                         }
1105                         push @cc, $c;
1106                         printf("(body) Adding cc: %s from line '%s'\n",
1107                                 $c, $_) unless $quiet;
1108                 }
1109         }
1110         close F;
1111
1112         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1113                 open(F, "$cc_cmd \Q$t\E |")
1114                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1115                 while(<F>) {
1116                         my $c = $_;
1117                         $c =~ s/^\s*//g;
1118                         $c =~ s/\n$//g;
1119                         next if ($c eq $sender and $suppress_from);
1120                         push @cc, $c;
1121                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1122                                 $c, $cc_cmd) unless $quiet;
1123                 }
1124                 close F
1125                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1126         }
1127
1128         if (defined $author and $author ne $sender) {
1129                 $message = "From: $author\n\n$message";
1130                 if (defined $author_encoding) {
1131                         if ($has_content_type) {
1132                                 if ($body_encoding eq $author_encoding) {
1133                                         # ok, we already have the right encoding
1134                                 }
1135                                 else {
1136                                         # uh oh, we should re-encode
1137                                 }
1138                         }
1139                         else {
1140                                 push @xh,
1141                                   'MIME-Version: 1.0',
1142                                   "Content-Type: text/plain; charset=$author_encoding",
1143                                   'Content-Transfer-Encoding: 8bit';
1144                         }
1145                 }
1146         }
1147
1148         $needs_confirm = (
1149                 $confirm eq "always" or
1150                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1151                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1152         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1153
1154         @cc = (@initial_cc, @cc);
1155
1156         my $message_was_sent = send_message();
1157
1158         # set up for the next message
1159         if ($thread && $message_was_sent &&
1160                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0)) {
1161                 $reply_to = $message_id;
1162                 if (length $references > 0) {
1163                         $references .= "\n $message_id";
1164                 } else {
1165                         $references = "$message_id";
1166                 }
1167         }
1168         $message_id = undef;
1169 }
1170
1171 cleanup_compose_files();
1172
1173 sub cleanup_compose_files() {
1174         unlink($compose_filename, $compose_filename . ".final") if $compose;
1175 }
1176
1177 $smtp->quit if $smtp;
1178
1179 sub unique_email_list(@) {
1180         my %seen;
1181         my @emails;
1182
1183         foreach my $entry (@_) {
1184                 if (my $clean = extract_valid_address($entry)) {
1185                         $seen{$clean} ||= 0;
1186                         next if $seen{$clean}++;
1187                         push @emails, $entry;
1188                 } else {
1189                         print STDERR "W: unable to extract a valid address",
1190                                         " from: $entry\n";
1191                 }
1192         }
1193         return @emails;
1194 }
1195
1196 sub validate_patch {
1197         my $fn = shift;
1198         open(my $fh, '<', $fn)
1199                 or die "unable to open $fn: $!\n";
1200         while (my $line = <$fh>) {
1201                 if (length($line) > 998) {
1202                         return "$.: patch contains a line longer than 998 characters";
1203                 }
1204         }
1205         return undef;
1206 }
1207
1208 sub file_has_nonascii {
1209         my $fn = shift;
1210         open(my $fh, '<', $fn)
1211                 or die "unable to open $fn: $!\n";
1212         while (my $line = <$fh>) {
1213                 return 1 if $line =~ /[^[:ascii:]]/;
1214         }
1215         return 0;
1216 }