gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 BEGIN {
  22         CGI->compile() if $ENV{'MOD_PERL'};
  23 }
  24
  25 our $cgi = new CGI;
  26 our $version = "++GIT_VERSION++";
  27 our $my_url = $cgi->url();
  28 our $my_uri = $cgi->url(-absolute => 1);
  29
  30 # if we're called with PATH_INFO, we have to strip that
  31 # from the URL to find our real URL
  32 # we make $path_info global because it's also used later on
  33 our $path_info = $ENV{"PATH_INFO"};
  34 if ($path_info) {
  35         $my_url =~ s,\Q$path_info\E$,,;
  36         $my_uri =~ s,\Q$path_info\E$,,;
  37 }
  38
  39 # core git executable to use
  40 # this can just be "git" if your webserver has a sensible PATH
  41 our $GIT = "++GIT_BINDIR++/git";
  42
  43 # absolute fs-path which will be prepended to the project path
  44 #our $projectroot = "/pub/scm";
  45 our $projectroot = "++GITWEB_PROJECTROOT++";
  46
  47 # fs traversing limit for getting project list
  48 # the number is relative to the projectroot
  49 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  50
  51 # target of the home link on top of all pages
  52 our $home_link = $my_uri || "/";
  53
  54 # string of the home link on top of all pages
  55 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  56
  57 # name of your site or organization to appear in page titles
  58 # replace this with something more descriptive for clearer bookmarks
  59 our $site_name = "++GITWEB_SITENAME++"
  60                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  61
  62 # filename of html text to include at top of each page
  63 our $site_header = "++GITWEB_SITE_HEADER++";
  64 # html text to include at home page
  65 our $home_text = "++GITWEB_HOMETEXT++";
  66 # filename of html text to include at bottom of each page
  67 our $site_footer = "++GITWEB_SITE_FOOTER++";
  68
  69 # URI of stylesheets
  70 our @stylesheets = ("++GITWEB_CSS++");
  71 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  72 our $stylesheet = undef;
  73 # URI of GIT logo (72x27 size)
  74 our $logo = "++GITWEB_LOGO++";
  75 # URI of GIT favicon, assumed to be image/png type
  76 our $favicon = "++GITWEB_FAVICON++";
  77
  78 # URI and label (title) of GIT logo link
  79 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
  80 #our $logo_label = "git documentation";
  81 our $logo_url = "http://git.or.cz/";
  82 our $logo_label = "git homepage";
  83
  84 # source of projects list
  85 our $projects_list = "++GITWEB_LIST++";
  86
  87 # the width (in characters) of the projects list "Description" column
  88 our $projects_list_description_width = 25;
  89
  90 # default order of projects list
  91 # valid values are none, project, descr, owner, and age
  92 our $default_projects_order = "project";
  93
  94 # show repository only if this file exists
  95 # (only effective if this variable evaluates to true)
  96 our $export_ok = "++GITWEB_EXPORT_OK++";
  97
  98 # show repository only if this subroutine returns true
  99 # when given the path to the project, for example:
 100 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 101 our $export_auth_hook = undef;
 102
 103 # only allow viewing of repositories also shown on the overview page
 104 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 105
 106 # list of git base URLs used for URL to where fetch project from,
 107 # i.e. full URL is "$git_base_url/$project"
 108 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 109
 110 # default blob_plain mimetype and default charset for text/plain blob
 111 our $default_blob_plain_mimetype = 'text/plain';
 112 our $default_text_plain_charset  = undef;
 113
 114 # file to use for guessing MIME types before trying /etc/mime.types
 115 # (relative to the current git repository)
 116 our $mimetypes_file = undef;
 117
 118 # assume this charset if line contains non-UTF-8 characters;
 119 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 120 # for which encoding all byte sequences are valid, for example
 121 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 122 # could be even 'utf-8' for the old behavior)
 123 our $fallback_encoding = 'latin1';
 124
 125 # rename detection options for git-diff and git-diff-tree
 126 # - default is '-M', with the cost proportional to
 127 #   (number of removed files) * (number of new files).
 128 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 129 #   (number of changed files + number of removed files) * (number of new files)
 130 # - even more costly is '-C', '--find-copies-harder' with cost
 131 #   (number of files in the original tree) * (number of new files)
 132 # - one might want to include '-B' option, e.g. '-B', '-M'
 133 our @diff_opts = ('-M'); # taken from git_commit
 134
 135 # Disables features that would allow repository owners to inject script into
 136 # the gitweb domain.
 137 our $prevent_xss = 0;
 138
 139 # information about snapshot formats that gitweb is capable of serving
 140 our %known_snapshot_formats = (
 141         # name => {
 142         #       'display' => display name,
 143         #       'type' => mime type,
 144         #       'suffix' => filename suffix,
 145         #       'format' => --format for git-archive,
 146         #       'compressor' => [compressor command and arguments]
 147         #                       (array reference, optional)}
 148         #
 149         'tgz' => {
 150                 'display' => 'tar.gz',
 151                 'type' => 'application/x-gzip',
 152                 'suffix' => '.tar.gz',
 153                 'format' => 'tar',
 154                 'compressor' => ['gzip']},
 155
 156         'tbz2' => {
 157                 'display' => 'tar.bz2',
 158                 'type' => 'application/x-bzip2',
 159                 'suffix' => '.tar.bz2',
 160                 'format' => 'tar',
 161                 'compressor' => ['bzip2']},
 162
 163         'zip' => {
 164                 'display' => 'zip',
 165                 'type' => 'application/x-zip',
 166                 'suffix' => '.zip',
 167                 'format' => 'zip'},
 168 );
 169
 170 # Aliases so we understand old gitweb.snapshot values in repository
 171 # configuration.
 172 our %known_snapshot_format_aliases = (
 173         'gzip'  => 'tgz',
 174         'bzip2' => 'tbz2',
 175
 176         # backward compatibility: legacy gitweb config support
 177         'x-gzip' => undef, 'gz' => undef,
 178         'x-bzip2' => undef, 'bz2' => undef,
 179         'x-zip' => undef, '' => undef,
 180 );
 181
 182 # You define site-wide feature defaults here; override them with
 183 # $GITWEB_CONFIG as necessary.
 184 our %feature = (
 185         # feature => {
 186         #       'sub' => feature-sub (subroutine),
 187         #       'override' => allow-override (boolean),
 188         #       'default' => [ default options...] (array reference)}
 189         #
 190         # if feature is overridable (it means that allow-override has true value),
 191         # then feature-sub will be called with default options as parameters;
 192         # return value of feature-sub indicates if to enable specified feature
 193         #
 194         # if there is no 'sub' key (no feature-sub), then feature cannot be
 195         # overriden
 196         #
 197         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 198         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 199         # is enabled
 200
 201         # Enable the 'blame' blob view, showing the last commit that modified
 202         # each line in the file. This can be very CPU-intensive.
 203
 204         # To enable system wide have in $GITWEB_CONFIG
 205         # $feature{'blame'}{'default'} = [1];
 206         # To have project specific config enable override in $GITWEB_CONFIG
 207         # $feature{'blame'}{'override'} = 1;
 208         # and in project config gitweb.blame = 0|1;
 209         'blame' => {
 210                 'sub' => \&feature_blame,
 211                 'override' => 0,
 212                 'default' => [0]},
 213
 214         # Enable the 'snapshot' link, providing a compressed archive of any
 215         # tree. This can potentially generate high traffic if you have large
 216         # project.
 217
 218         # Value is a list of formats defined in %known_snapshot_formats that
 219         # you wish to offer.
 220         # To disable system wide have in $GITWEB_CONFIG
 221         # $feature{'snapshot'}{'default'} = [];
 222         # To have project specific config enable override in $GITWEB_CONFIG
 223         # $feature{'snapshot'}{'override'} = 1;
 224         # and in project config, a comma-separated list of formats or "none"
 225         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 226         'snapshot' => {
 227                 'sub' => \&feature_snapshot,
 228                 'override' => 0,
 229                 'default' => ['tgz']},
 230
 231         # Enable text search, which will list the commits which match author,
 232         # committer or commit text to a given string.  Enabled by default.
 233         # Project specific override is not supported.
 234         'search' => {
 235                 'override' => 0,
 236                 'default' => [1]},
 237
 238         # Enable grep search, which will list the files in currently selected
 239         # tree containing the given string. Enabled by default. This can be
 240         # potentially CPU-intensive, of course.
 241
 242         # To enable system wide have in $GITWEB_CONFIG
 243         # $feature{'grep'}{'default'} = [1];
 244         # To have project specific config enable override in $GITWEB_CONFIG
 245         # $feature{'grep'}{'override'} = 1;
 246         # and in project config gitweb.grep = 0|1;
 247         'grep' => {
 248                 'sub' => \&feature_grep,
 249                 'override' => 0,
 250                 'default' => [1]},
 251
 252         # Enable the pickaxe search, which will list the commits that modified
 253         # a given string in a file. This can be practical and quite faster
 254         # alternative to 'blame', but still potentially CPU-intensive.
 255
 256         # To enable system wide have in $GITWEB_CONFIG
 257         # $feature{'pickaxe'}{'default'} = [1];
 258         # To have project specific config enable override in $GITWEB_CONFIG
 259         # $feature{'pickaxe'}{'override'} = 1;
 260         # and in project config gitweb.pickaxe = 0|1;
 261         'pickaxe' => {
 262                 'sub' => \&feature_pickaxe,
 263                 'override' => 0,
 264                 'default' => [1]},
 265
 266         # Make gitweb use an alternative format of the URLs which can be
 267         # more readable and natural-looking: project name is embedded
 268         # directly in the path and the query string contains other
 269         # auxiliary information. All gitweb installations recognize
 270         # URL in either format; this configures in which formats gitweb
 271         # generates links.
 272
 273         # To enable system wide have in $GITWEB_CONFIG
 274         # $feature{'pathinfo'}{'default'} = [1];
 275         # Project specific override is not supported.
 276
 277         # Note that you will need to change the default location of CSS,
 278         # favicon, logo and possibly other files to an absolute URL. Also,
 279         # if gitweb.cgi serves as your indexfile, you will need to force
 280         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 281         'pathinfo' => {
 282                 'override' => 0,
 283                 'default' => [0]},
 284
 285         # Make gitweb consider projects in project root subdirectories
 286         # to be forks of existing projects. Given project $projname.git,
 287         # projects matching $projname/*.git will not be shown in the main
 288         # projects list, instead a '+' mark will be added to $projname
 289         # there and a 'forks' view will be enabled for the project, listing
 290         # all the forks. If project list is taken from a file, forks have
 291         # to be listed after the main project.
 292
 293         # To enable system wide have in $GITWEB_CONFIG
 294         # $feature{'forks'}{'default'} = [1];
 295         # Project specific override is not supported.
 296         'forks' => {
 297                 'override' => 0,
 298                 'default' => [0]},
 299
 300         # Insert custom links to the action bar of all project pages.
 301         # This enables you mainly to link to third-party scripts integrating
 302         # into gitweb; e.g. git-browser for graphical history representation
 303         # or custom web-based repository administration interface.
 304
 305         # The 'default' value consists of a list of triplets in the form
 306         # (label, link, position) where position is the label after which
 307         # to insert the link and link is a format string where %n expands
 308         # to the project name, %f to the project path within the filesystem,
 309         # %h to the current hash (h gitweb parameter) and %b to the current
 310         # hash base (hb gitweb parameter); %% expands to %.
 311
 312         # To enable system wide have in $GITWEB_CONFIG e.g.
 313         # $feature{'actions'}{'default'} = [('graphiclog',
 314         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 315         # Project specific override is not supported.
 316         'actions' => {
 317                 'override' => 0,
 318                 'default' => []},
 319
 320         # Allow gitweb scan project content tags described in ctags/
 321         # of project repository, and display the popular Web 2.0-ish
 322         # "tag cloud" near the project list. Note that this is something
 323         # COMPLETELY different from the normal Git tags.
 324
 325         # gitweb by itself can show existing tags, but it does not handle
 326         # tagging itself; you need an external application for that.
 327         # For an example script, check Girocco's cgi/tagproj.cgi.
 328         # You may want to install the HTML::TagCloud Perl module to get
 329         # a pretty tag cloud instead of just a list of tags.
 330
 331         # To enable system wide have in $GITWEB_CONFIG
 332         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 333         # Project specific override is not supported.
 334         'ctags' => {
 335                 'override' => 0,
 336                 'default' => [0]},
 337 );
 338
 339 sub gitweb_get_feature {
 340         my ($name) = @_;
 341         return unless exists $feature{$name};
 342         my ($sub, $override, @defaults) = (
 343                 $feature{$name}{'sub'},
 344                 $feature{$name}{'override'},
 345                 @{$feature{$name}{'default'}});
 346         if (!$override) { return @defaults; }
 347         if (!defined $sub) {
 348                 warn "feature $name is not overrideable";
 349                 return @defaults;
 350         }
 351         return $sub->(@defaults);
 352 }
 353
 354 # A wrapper to check if a given feature is enabled.
 355 # With this, you can say
 356 #
 357 #   my $bool_feat = gitweb_check_feature('bool_feat');
 358 #   gitweb_check_feature('bool_feat') or somecode;
 359 #
 360 # instead of
 361 #
 362 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 363 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 364 #
 365 sub gitweb_check_feature {
 366         return (gitweb_get_feature(@_))[0];
 367 }
 368
 369
 370 sub feature_blame {
 371         my ($val) = git_get_project_config('blame', '--bool');
 372
 373         if ($val eq 'true') {
 374                 return 1;
 375         } elsif ($val eq 'false') {
 376                 return 0;
 377         }
 378
 379         return $_[0];
 380 }
 381
 382 sub feature_snapshot {
 383         my (@fmts) = @_;
 384
 385         my ($val) = git_get_project_config('snapshot');
 386
 387         if ($val) {
 388                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 389         }
 390
 391         return @fmts;
 392 }
 393
 394 sub feature_grep {
 395         my ($val) = git_get_project_config('grep', '--bool');
 396
 397         if ($val eq 'true') {
 398                 return (1);
 399         } elsif ($val eq 'false') {
 400                 return (0);
 401         }
 402
 403         return ($_[0]);
 404 }
 405
 406 sub feature_pickaxe {
 407         my ($val) = git_get_project_config('pickaxe', '--bool');
 408
 409         if ($val eq 'true') {
 410                 return (1);
 411         } elsif ($val eq 'false') {
 412                 return (0);
 413         }
 414
 415         return ($_[0]);
 416 }
 417
 418 # checking HEAD file with -e is fragile if the repository was
 419 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 420 # and then pruned.
 421 sub check_head_link {
 422         my ($dir) = @_;
 423         my $headfile = "$dir/HEAD";
 424         return ((-e $headfile) ||
 425                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 426 }
 427
 428 sub check_export_ok {
 429         my ($dir) = @_;
 430         return (check_head_link($dir) &&
 431                 (!$export_ok || -e "$dir/$export_ok") &&
 432                 (!$export_auth_hook || $export_auth_hook->($dir)));
 433 }
 434
 435 # process alternate names for backward compatibility
 436 # filter out unsupported (unknown) snapshot formats
 437 sub filter_snapshot_fmts {
 438         my @fmts = @_;
 439
 440         @fmts = map {
 441                 exists $known_snapshot_format_aliases{$_} ?
 442                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 443         @fmts = grep(exists $known_snapshot_formats{$_}, @fmts);
 444
 445 }
 446
 447 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 448 if (-e $GITWEB_CONFIG) {
 449         do $GITWEB_CONFIG;
 450 } else {
 451         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 452         do $GITWEB_CONFIG_SYSTEM if -e $GITWEB_CONFIG_SYSTEM;
 453 }
 454
 455 # version of the core git binary
 456 our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 457
 458 $projects_list ||= $projectroot;
 459
 460 # ======================================================================
 461 # input validation and dispatch
 462
 463 # input parameters can be collected from a variety of sources (presently, CGI
 464 # and PATH_INFO), so we define an %input_params hash that collects them all
 465 # together during validation: this allows subsequent uses (e.g. href()) to be
 466 # agnostic of the parameter origin
 467
 468 our %input_params = ();
 469
 470 # input parameters are stored with the long parameter name as key. This will
 471 # also be used in the href subroutine to convert parameters to their CGI
 472 # equivalent, and since the href() usage is the most frequent one, we store
 473 # the name -> CGI key mapping here, instead of the reverse.
 474 #
 475 # XXX: Warning: If you touch this, check the search form for updating,
 476 # too.
 477
 478 our @cgi_param_mapping = (
 479         project => "p",
 480         action => "a",
 481         file_name => "f",
 482         file_parent => "fp",
 483         hash => "h",
 484         hash_parent => "hp",
 485         hash_base => "hb",
 486         hash_parent_base => "hpb",
 487         page => "pg",
 488         order => "o",
 489         searchtext => "s",
 490         searchtype => "st",
 491         snapshot_format => "sf",
 492         extra_options => "opt",
 493         search_use_regexp => "sr",
 494 );
 495 our %cgi_param_mapping = @cgi_param_mapping;
 496
 497 # we will also need to know the possible actions, for validation
 498 our %actions = (
 499         "blame" => \&git_blame,
 500         "blobdiff" => \&git_blobdiff,
 501         "blobdiff_plain" => \&git_blobdiff_plain,
 502         "blob" => \&git_blob,
 503         "blob_plain" => \&git_blob_plain,
 504         "commitdiff" => \&git_commitdiff,
 505         "commitdiff_plain" => \&git_commitdiff_plain,
 506         "commit" => \&git_commit,
 507         "forks" => \&git_forks,
 508         "heads" => \&git_heads,
 509         "history" => \&git_history,
 510         "log" => \&git_log,
 511         "rss" => \&git_rss,
 512         "atom" => \&git_atom,
 513         "search" => \&git_search,
 514         "search_help" => \&git_search_help,
 515         "shortlog" => \&git_shortlog,
 516         "summary" => \&git_summary,
 517         "tag" => \&git_tag,
 518         "tags" => \&git_tags,
 519         "tree" => \&git_tree,
 520         "snapshot" => \&git_snapshot,
 521         "object" => \&git_object,
 522         # those below don't need $project
 523         "opml" => \&git_opml,
 524         "project_list" => \&git_project_list,
 525         "project_index" => \&git_project_index,
 526 );
 527
 528 # finally, we have the hash of allowed extra_options for the commands that
 529 # allow them
 530 our %allowed_options = (
 531         "--no-merges" => [ qw(rss atom log shortlog history) ],
 532 );
 533
 534 # fill %input_params with the CGI parameters. All values except for 'opt'
 535 # should be single values, but opt can be an array. We should probably
 536 # build an array of parameters that can be multi-valued, but since for the time
 537 # being it's only this one, we just single it out
 538 while (my ($name, $symbol) = each %cgi_param_mapping) {
 539         if ($symbol eq 'opt') {
 540                 $input_params{$name} = [ $cgi->param($symbol) ];
 541         } else {
 542                 $input_params{$name} = $cgi->param($symbol);
 543         }
 544 }
 545
 546 # now read PATH_INFO and update the parameter list for missing parameters
 547 sub evaluate_path_info {
 548         return if defined $input_params{'project'};
 549         return if !$path_info;
 550         $path_info =~ s,^/+,,;
 551         return if !$path_info;
 552
 553         # find which part of PATH_INFO is project
 554         my $project = $path_info;
 555         $project =~ s,/+$,,;
 556         while ($project && !check_head_link("$projectroot/$project")) {
 557                 $project =~ s,/*[^/]*$,,;
 558         }
 559         return unless $project;
 560         $input_params{'project'} = $project;
 561
 562         # do not change any parameters if an action is given using the query string
 563         return if $input_params{'action'};
 564         $path_info =~ s,^\Q$project\E/*,,;
 565
 566         # next, check if we have an action
 567         my $action = $path_info;
 568         $action =~ s,/.*$,,;
 569         if (exists $actions{$action}) {
 570                 $path_info =~ s,^$action/*,,;
 571                 $input_params{'action'} = $action;
 572         }
 573
 574         # list of actions that want hash_base instead of hash, but can have no
 575         # pathname (f) parameter
 576         my @wants_base = (
 577                 'tree',
 578                 'history',
 579         );
 580
 581         # we want to catch
 582         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 583         my ($parentrefname, $parentpathname, $refname, $pathname) =
 584                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?(.+?)(?::(.+))?$/);
 585
 586         # first, analyze the 'current' part
 587         if (defined $pathname) {
 588                 # we got "branch:filename" or "branch:dir/"
 589                 # we could use git_get_type(branch:pathname), but:
 590                 # - it needs $git_dir
 591                 # - it does a git() call
 592                 # - the convention of terminating directories with a slash
 593                 #   makes it superfluous
 594                 # - embedding the action in the PATH_INFO would make it even
 595                 #   more superfluous
 596                 $pathname =~ s,^/+,,;
 597                 if (!$pathname || substr($pathname, -1) eq "/") {
 598                         $input_params{'action'} ||= "tree";
 599                         $pathname =~ s,/$,,;
 600                 } else {
 601                         # the default action depends on whether we had parent info
 602                         # or not
 603                         if ($parentrefname) {
 604                                 $input_params{'action'} ||= "blobdiff_plain";
 605                         } else {
 606                                 $input_params{'action'} ||= "blob_plain";
 607                         }
 608                 }
 609                 $input_params{'hash_base'} ||= $refname;
 610                 $input_params{'file_name'} ||= $pathname;
 611         } elsif (defined $refname) {
 612                 # we got "branch". In this case we have to choose if we have to
 613                 # set hash or hash_base.
 614                 #
 615                 # Most of the actions without a pathname only want hash to be
 616                 # set, except for the ones specified in @wants_base that want
 617                 # hash_base instead. It should also be noted that hand-crafted
 618                 # links having 'history' as an action and no pathname or hash
 619                 # set will fail, but that happens regardless of PATH_INFO.
 620                 $input_params{'action'} ||= "shortlog";
 621                 if (grep { $_ eq $input_params{'action'} } @wants_base) {
 622                         $input_params{'hash_base'} ||= $refname;
 623                 } else {
 624                         $input_params{'hash'} ||= $refname;
 625                 }
 626         }
 627
 628         # next, handle the 'parent' part, if present
 629         if (defined $parentrefname) {
 630                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 631                 # someproject/blobdiff/oldrev..newrev:/filename
 632                 if ($parentpathname) {
 633                         $parentpathname =~ s,^/+,,;
 634                         $parentpathname =~ s,/$,,;
 635                         $input_params{'file_parent'} ||= $parentpathname;
 636                 } else {
 637                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 638                 }
 639                 # we assume that hash_parent_base is wanted if a path was specified,
 640                 # or if the action wants hash_base instead of hash
 641                 if (defined $input_params{'file_parent'} ||
 642                         grep { $_ eq $input_params{'action'} } @wants_base) {
 643                         $input_params{'hash_parent_base'} ||= $parentrefname;
 644                 } else {
 645                         $input_params{'hash_parent'} ||= $parentrefname;
 646                 }
 647         }
 648
 649         # for the snapshot action, we allow URLs in the form
 650         # $project/snapshot/$hash.ext
 651         # where .ext determines the snapshot and gets removed from the
 652         # passed $refname to provide the $hash.
 653         #
 654         # To be able to tell that $refname includes the format extension, we
 655         # require the following two conditions to be satisfied:
 656         # - the hash input parameter MUST have been set from the $refname part
 657         #   of the URL (i.e. they must be equal)
 658         # - the snapshot format MUST NOT have been defined already (e.g. from
 659         #   CGI parameter sf)
 660         # It's also useless to try any matching unless $refname has a dot,
 661         # so we check for that too
 662         if (defined $input_params{'action'} &&
 663                 $input_params{'action'} eq 'snapshot' &&
 664                 defined $refname && index($refname, '.') != -1 &&
 665                 $refname eq $input_params{'hash'} &&
 666                 !defined $input_params{'snapshot_format'}) {
 667                 # We loop over the known snapshot formats, checking for
 668                 # extensions. Allowed extensions are both the defined suffix
 669                 # (which includes the initial dot already) and the snapshot
 670                 # format key itself, with a prepended dot
 671                 while (my ($fmt, %opt) = each %known_snapshot_formats) {
 672                         my $hash = $refname;
 673                         my $sfx;
 674                         $hash =~ s/(\Q$opt{'suffix'}\E|\Q.$fmt\E)$//;
 675                         next unless $sfx = $1;
 676                         # a valid suffix was found, so set the snapshot format
 677                         # and reset the hash parameter
 678                         $input_params{'snapshot_format'} = $fmt;
 679                         $input_params{'hash'} = $hash;
 680                         # we also set the format suffix to the one requested
 681                         # in the URL: this way a request for e.g. .tgz returns
 682                         # a .tgz instead of a .tar.gz
 683                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 684                         last;
 685                 }
 686         }
 687 }
 688 evaluate_path_info();
 689
 690 our $action = $input_params{'action'};
 691 if (defined $action) {
 692         if (!validate_action($action)) {
 693                 die_error(400, "Invalid action parameter");
 694         }
 695 }
 696
 697 # parameters which are pathnames
 698 our $project = $input_params{'project'};
 699 if (defined $project) {
 700         if (!validate_project($project)) {
 701                 undef $project;
 702                 die_error(404, "No such project");
 703         }
 704 }
 705
 706 our $file_name = $input_params{'file_name'};
 707 if (defined $file_name) {
 708         if (!validate_pathname($file_name)) {
 709                 die_error(400, "Invalid file parameter");
 710         }
 711 }
 712
 713 our $file_parent = $input_params{'file_parent'};
 714 if (defined $file_parent) {
 715         if (!validate_pathname($file_parent)) {
 716                 die_error(400, "Invalid file parent parameter");
 717         }
 718 }
 719
 720 # parameters which are refnames
 721 our $hash = $input_params{'hash'};
 722 if (defined $hash) {
 723         if (!validate_refname($hash)) {
 724                 die_error(400, "Invalid hash parameter");
 725         }
 726 }
 727
 728 our $hash_parent = $input_params{'hash_parent'};
 729 if (defined $hash_parent) {
 730         if (!validate_refname($hash_parent)) {
 731                 die_error(400, "Invalid hash parent parameter");
 732         }
 733 }
 734
 735 our $hash_base = $input_params{'hash_base'};
 736 if (defined $hash_base) {
 737         if (!validate_refname($hash_base)) {
 738                 die_error(400, "Invalid hash base parameter");
 739         }
 740 }
 741
 742 our @extra_options = @{$input_params{'extra_options'}};
 743 # @extra_options is always defined, since it can only be (currently) set from
 744 # CGI, and $cgi->param() returns the empty array in array context if the param
 745 # is not set
 746 foreach my $opt (@extra_options) {
 747         if (not exists $allowed_options{$opt}) {
 748                 die_error(400, "Invalid option parameter");
 749         }
 750         if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 751                 die_error(400, "Invalid option parameter for this action");
 752         }
 753 }
 754
 755 our $hash_parent_base = $input_params{'hash_parent_base'};
 756 if (defined $hash_parent_base) {
 757         if (!validate_refname($hash_parent_base)) {
 758                 die_error(400, "Invalid hash parent base parameter");
 759         }
 760 }
 761
 762 # other parameters
 763 our $page = $input_params{'page'};
 764 if (defined $page) {
 765         if ($page =~ m/[^0-9]/) {
 766                 die_error(400, "Invalid page parameter");
 767         }
 768 }
 769
 770 our $searchtype = $input_params{'searchtype'};
 771 if (defined $searchtype) {
 772         if ($searchtype =~ m/[^a-z]/) {
 773                 die_error(400, "Invalid searchtype parameter");
 774         }
 775 }
 776
 777 our $search_use_regexp = $input_params{'search_use_regexp'};
 778
 779 our $searchtext = $input_params{'searchtext'};
 780 our $search_regexp;
 781 if (defined $searchtext) {
 782         if (length($searchtext) < 2) {
 783                 die_error(403, "At least two characters are required for search parameter");
 784         }
 785         $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
 786 }
 787
 788 # path to the current git repository
 789 our $git_dir;
 790 $git_dir = "$projectroot/$project" if $project;
 791
 792 # list of supported snapshot formats
 793 our @snapshot_fmts = gitweb_get_feature('snapshot');
 794 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
 795
 796 # dispatch
 797 if (!defined $action) {
 798         if (defined $hash) {
 799                 $action = git_get_type($hash);
 800         } elsif (defined $hash_base && defined $file_name) {
 801                 $action = git_get_type("$hash_base:$file_name");
 802         } elsif (defined $project) {
 803                 $action = 'summary';
 804         } else {
 805                 $action = 'project_list';
 806         }
 807 }
 808 if (!defined($actions{$action})) {
 809         die_error(400, "Unknown action");
 810 }
 811 if ($action !~ m/^(opml|project_list|project_index)$/ &&
 812     !$project) {
 813         die_error(400, "Project needed");
 814 }
 815 $actions{$action}->();
 816 exit;
 817
 818 ## ======================================================================
 819 ## action links
 820
 821 sub href (%) {
 822         my %params = @_;
 823         # default is to use -absolute url() i.e. $my_uri
 824         my $href = $params{-full} ? $my_url : $my_uri;
 825
 826         $params{'project'} = $project unless exists $params{'project'};
 827
 828         if ($params{-replay}) {
 829                 while (my ($name, $symbol) = each %cgi_param_mapping) {
 830                         if (!exists $params{$name}) {
 831                                 $params{$name} = $input_params{$name};
 832                         }
 833                 }
 834         }
 835
 836         my $use_pathinfo = gitweb_check_feature('pathinfo');
 837         if ($use_pathinfo) {
 838                 # try to put as many parameters as possible in PATH_INFO:
 839                 #   - project name
 840                 #   - action
 841                 #   - hash_parent or hash_parent_base:/file_parent
 842                 #   - hash or hash_base:/filename
 843                 #   - the snapshot_format as an appropriate suffix
 844
 845                 # When the script is the root DirectoryIndex for the domain,
 846                 # $href here would be something like http://gitweb.example.com/
 847                 # Thus, we strip any trailing / from $href, to spare us double
 848                 # slashes in the final URL
 849                 $href =~ s,/$,,;
 850
 851                 # Then add the project name, if present
 852                 $href .= "/".esc_url($params{'project'}) if defined $params{'project'};
 853                 delete $params{'project'};
 854
 855                 # since we destructively absorb parameters, we keep this
 856                 # boolean that remembers if we're handling a snapshot
 857                 my $is_snapshot = $params{'action'} eq 'snapshot';
 858
 859                 # Summary just uses the project path URL, any other action is
 860                 # added to the URL
 861                 if (defined $params{'action'}) {
 862                         $href .= "/".esc_url($params{'action'}) unless $params{'action'} eq 'summary';
 863                         delete $params{'action'};
 864                 }
 865
 866                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
 867                 # stripping nonexistent or useless pieces
 868                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
 869                         || $params{'hash_parent'} || $params{'hash'});
 870                 if (defined $params{'hash_base'}) {
 871                         if (defined $params{'hash_parent_base'}) {
 872                                 $href .= esc_url($params{'hash_parent_base'});
 873                                 # skip the file_parent if it's the same as the file_name
 874                                 delete $params{'file_parent'} if $params{'file_parent'} eq $params{'file_name'};
 875                                 if (defined $params{'file_parent'} && $params{'file_parent'} !~ /\.\./) {
 876                                         $href .= ":/".esc_url($params{'file_parent'});
 877                                         delete $params{'file_parent'};
 878                                 }
 879                                 $href .= "..";
 880                                 delete $params{'hash_parent'};
 881                                 delete $params{'hash_parent_base'};
 882                         } elsif (defined $params{'hash_parent'}) {
 883                                 $href .= esc_url($params{'hash_parent'}). "..";
 884                                 delete $params{'hash_parent'};
 885                         }
 886
 887                         $href .= esc_url($params{'hash_base'});
 888                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
 889                                 $href .= ":/".esc_url($params{'file_name'});
 890                                 delete $params{'file_name'};
 891                         }
 892                         delete $params{'hash'};
 893                         delete $params{'hash_base'};
 894                 } elsif (defined $params{'hash'}) {
 895                         $href .= esc_url($params{'hash'});
 896                         delete $params{'hash'};
 897                 }
 898
 899                 # If the action was a snapshot, we can absorb the
 900                 # snapshot_format parameter too
 901                 if ($is_snapshot) {
 902                         my $fmt = $params{'snapshot_format'};
 903                         # snapshot_format should always be defined when href()
 904                         # is called, but just in case some code forgets, we
 905                         # fall back to the default
 906                         $fmt ||= $snapshot_fmts[0];
 907                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
 908                         delete $params{'snapshot_format'};
 909                 }
 910         }
 911
 912         # now encode the parameters explicitly
 913         my @result = ();
 914         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
 915                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
 916                 if (defined $params{$name}) {
 917                         if (ref($params{$name}) eq "ARRAY") {
 918                                 foreach my $par (@{$params{$name}}) {
 919                                         push @result, $symbol . "=" . esc_param($par);
 920                                 }
 921                         } else {
 922                                 push @result, $symbol . "=" . esc_param($params{$name});
 923                         }
 924                 }
 925         }
 926         $href .= "?" . join(';', @result) if scalar @result;
 927
 928         return $href;
 929 }
 930
 931
 932 ## ======================================================================
 933 ## validation, quoting/unquoting and escaping
 934
 935 sub validate_action {
 936         my $input = shift || return undef;
 937         return undef unless exists $actions{$input};
 938         return $input;
 939 }
 940
 941 sub validate_project {
 942         my $input = shift || return undef;
 943         if (!validate_pathname($input) ||
 944                 !(-d "$projectroot/$input") ||
 945                 !check_export_ok("$projectroot/$input") ||
 946                 ($strict_export && !project_in_list($input))) {
 947                 return undef;
 948         } else {
 949                 return $input;
 950         }
 951 }
 952
 953 sub validate_pathname {
 954         my $input = shift || return undef;
 955
 956         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
 957         # at the beginning, at the end, and between slashes.
 958         # also this catches doubled slashes
 959         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
 960                 return undef;
 961         }
 962         # no null characters
 963         if ($input =~ m!\0!) {
 964                 return undef;
 965         }
 966         return $input;
 967 }
 968
 969 sub validate_refname {
 970         my $input = shift || return undef;
 971
 972         # textual hashes are O.K.
 973         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
 974                 return $input;
 975         }
 976         # it must be correct pathname
 977         $input = validate_pathname($input)
 978                 or return undef;
 979         # restrictions on ref name according to git-check-ref-format
 980         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
 981                 return undef;
 982         }
 983         return $input;
 984 }
 985
 986 # decode sequences of octets in utf8 into Perl's internal form,
 987 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
 988 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
 989 sub to_utf8 {
 990         my $str = shift;
 991         if (utf8::valid($str)) {
 992                 utf8::decode($str);
 993                 return $str;
 994         } else {
 995                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
 996         }
 997 }
 998
 999 # quote unsafe chars, but keep the slash, even when it's not
1000 # correct, but quoted slashes look too horrible in bookmarks
1001 sub esc_param {
1002         my $str = shift;
1003         $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
1004         $str =~ s/\+/%2B/g;
1005         $str =~ s/ /\+/g;
1006         return $str;
1007 }
1008
1009 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
1010 sub esc_url {
1011         my $str = shift;
1012         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
1013         $str =~ s/\+/%2B/g;
1014         $str =~ s/ /\+/g;
1015         return $str;
1016 }
1017
1018 # replace invalid utf8 character with SUBSTITUTION sequence
1019 sub esc_html ($;%) {
1020         my $str = shift;
1021         my %opts = @_;
1022
1023         $str = to_utf8($str);
1024         $str = $cgi->escapeHTML($str);
1025         if ($opts{'-nbsp'}) {
1026                 $str =~ s/ /&nbsp;/g;
1027         }
1028         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1029         return $str;
1030 }
1031
1032 # quote control characters and escape filename to HTML
1033 sub esc_path {
1034         my $str = shift;
1035         my %opts = @_;
1036
1037         $str = to_utf8($str);
1038         $str = $cgi->escapeHTML($str);
1039         if ($opts{'-nbsp'}) {
1040                 $str =~ s/ /&nbsp;/g;
1041         }
1042         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1043         return $str;
1044 }
1045
1046 # Make control characters "printable", using character escape codes (CEC)
1047 sub quot_cec {
1048         my $cntrl = shift;
1049         my %opts = @_;
1050         my %es = ( # character escape codes, aka escape sequences
1051                 "\t" => '\t',   # tab            (HT)
1052                 "\n" => '\n',   # line feed      (LF)
1053                 "\r" => '\r',   # carrige return (CR)
1054                 "\f" => '\f',   # form feed      (FF)
1055                 "\b" => '\b',   # backspace      (BS)
1056                 "\a" => '\a',   # alarm (bell)   (BEL)
1057                 "\e" => '\e',   # escape         (ESC)
1058                 "\013" => '\v', # vertical tab   (VT)
1059                 "\000" => '\0', # nul character  (NUL)
1060         );
1061         my $chr = ( (exists $es{$cntrl})
1062                     ? $es{$cntrl}
1063                     : sprintf('\%2x', ord($cntrl)) );
1064         if ($opts{-nohtml}) {
1065                 return $chr;
1066         } else {
1067                 return "<span class=\"cntrl\">$chr</span>";
1068         }
1069 }
1070
1071 # Alternatively use unicode control pictures codepoints,
1072 # Unicode "printable representation" (PR)
1073 sub quot_upr {
1074         my $cntrl = shift;
1075         my %opts = @_;
1076
1077         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1078         if ($opts{-nohtml}) {
1079                 return $chr;
1080         } else {
1081                 return "<span class=\"cntrl\">$chr</span>";
1082         }
1083 }
1084
1085 # git may return quoted and escaped filenames
1086 sub unquote {
1087         my $str = shift;
1088
1089         sub unq {
1090                 my $seq = shift;
1091                 my %es = ( # character escape codes, aka escape sequences
1092                         't' => "\t",   # tab            (HT, TAB)
1093                         'n' => "\n",   # newline        (NL)
1094                         'r' => "\r",   # return         (CR)
1095                         'f' => "\f",   # form feed      (FF)
1096                         'b' => "\b",   # backspace      (BS)
1097                         'a' => "\a",   # alarm (bell)   (BEL)
1098                         'e' => "\e",   # escape         (ESC)
1099                         'v' => "\013", # vertical tab   (VT)
1100                 );
1101
1102                 if ($seq =~ m/^[0-7]{1,3}$/) {
1103                         # octal char sequence
1104                         return chr(oct($seq));
1105                 } elsif (exists $es{$seq}) {
1106                         # C escape sequence, aka character escape code
1107                         return $es{$seq};
1108                 }
1109                 # quoted ordinary character
1110                 return $seq;
1111         }
1112
1113         if ($str =~ m/^"(.*)"$/) {
1114                 # needs unquoting
1115                 $str = $1;
1116                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1117         }
1118         return $str;
1119 }
1120
1121 # escape tabs (convert tabs to spaces)
1122 sub untabify {
1123         my $line = shift;
1124
1125         while ((my $pos = index($line, "\t")) != -1) {
1126                 if (my $count = (8 - ($pos % 8))) {
1127                         my $spaces = ' ' x $count;
1128                         $line =~ s/\t/$spaces/;
1129                 }
1130         }
1131
1132         return $line;
1133 }
1134
1135 sub project_in_list {
1136         my $project = shift;
1137         my @list = git_get_projects_list();
1138         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1139 }
1140
1141 ## ----------------------------------------------------------------------
1142 ## HTML aware string manipulation
1143
1144 # Try to chop given string on a word boundary between position
1145 # $len and $len+$add_len. If there is no word boundary there,
1146 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1147 # (marking chopped part) would be longer than given string.
1148 sub chop_str {
1149         my $str = shift;
1150         my $len = shift;
1151         my $add_len = shift || 10;
1152         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1153
1154         # Make sure perl knows it is utf8 encoded so we don't
1155         # cut in the middle of a utf8 multibyte char.
1156         $str = to_utf8($str);
1157
1158         # allow only $len chars, but don't cut a word if it would fit in $add_len
1159         # if it doesn't fit, cut it if it's still longer than the dots we would add
1160         # remove chopped character entities entirely
1161
1162         # when chopping in the middle, distribute $len into left and right part
1163         # return early if chopping wouldn't make string shorter
1164         if ($where eq 'center') {
1165                 return $str if ($len + 5 >= length($str)); # filler is length 5
1166                 $len = int($len/2);
1167         } else {
1168                 return $str if ($len + 4 >= length($str)); # filler is length 4
1169         }
1170
1171         # regexps: ending and beginning with word part up to $add_len
1172         my $endre = qr/.{$len}\w{0,$add_len}/;
1173         my $begre = qr/\w{0,$add_len}.{$len}/;
1174
1175         if ($where eq 'left') {
1176                 $str =~ m/^(.*?)($begre)$/;
1177                 my ($lead, $body) = ($1, $2);
1178                 if (length($lead) > 4) {
1179                         $body =~ s/^[^;]*;// if ($lead =~ m/&[^;]*$/);
1180                         $lead = " ...";
1181                 }
1182                 return "$lead$body";
1183
1184         } elsif ($where eq 'center') {
1185                 $str =~ m/^($endre)(.*)$/;
1186                 my ($left, $str)  = ($1, $2);
1187                 $str =~ m/^(.*?)($begre)$/;
1188                 my ($mid, $right) = ($1, $2);
1189                 if (length($mid) > 5) {
1190                         $left  =~ s/&[^;]*$//;
1191                         $right =~ s/^[^;]*;// if ($mid =~ m/&[^;]*$/);
1192                         $mid = " ... ";
1193                 }
1194                 return "$left$mid$right";
1195
1196         } else {
1197                 $str =~ m/^($endre)(.*)$/;
1198                 my $body = $1;
1199                 my $tail = $2;
1200                 if (length($tail) > 4) {
1201                         $body =~ s/&[^;]*$//;
1202                         $tail = "... ";
1203                 }
1204                 return "$body$tail";
1205         }
1206 }
1207
1208 # takes the same arguments as chop_str, but also wraps a <span> around the
1209 # result with a title attribute if it does get chopped. Additionally, the
1210 # string is HTML-escaped.
1211 sub chop_and_escape_str {
1212         my ($str) = @_;
1213
1214         my $chopped = chop_str(@_);
1215         if ($chopped eq $str) {
1216                 return esc_html($chopped);
1217         } else {
1218                 $str =~ s/([[:cntrl:]])/?/g;
1219                 return $cgi->span({-title=>$str}, esc_html($chopped));
1220         }
1221 }
1222
1223 ## ----------------------------------------------------------------------
1224 ## functions returning short strings
1225
1226 # CSS class for given age value (in seconds)
1227 sub age_class {
1228         my $age = shift;
1229
1230         if (!defined $age) {
1231                 return "noage";
1232         } elsif ($age < 60*60*2) {
1233                 return "age0";
1234         } elsif ($age < 60*60*24*2) {
1235                 return "age1";
1236         } else {
1237                 return "age2";
1238         }
1239 }
1240
1241 # convert age in seconds to "nn units ago" string
1242 sub age_string {
1243         my $age = shift;
1244         my $age_str;
1245
1246         if ($age > 60*60*24*365*2) {
1247                 $age_str = (int $age/60/60/24/365);
1248                 $age_str .= " years ago";
1249         } elsif ($age > 60*60*24*(365/12)*2) {
1250                 $age_str = int $age/60/60/24/(365/12);
1251                 $age_str .= " months ago";
1252         } elsif ($age > 60*60*24*7*2) {
1253                 $age_str = int $age/60/60/24/7;
1254                 $age_str .= " weeks ago";
1255         } elsif ($age > 60*60*24*2) {
1256                 $age_str = int $age/60/60/24;
1257                 $age_str .= " days ago";
1258         } elsif ($age > 60*60*2) {
1259                 $age_str = int $age/60/60;
1260                 $age_str .= " hours ago";
1261         } elsif ($age > 60*2) {
1262                 $age_str = int $age/60;
1263                 $age_str .= " min ago";
1264         } elsif ($age > 2) {
1265                 $age_str = int $age;
1266                 $age_str .= " sec ago";
1267         } else {
1268                 $age_str .= " right now";
1269         }
1270         return $age_str;
1271 }
1272
1273 use constant {
1274         S_IFINVALID => 0030000,
1275         S_IFGITLINK => 0160000,
1276 };
1277
1278 # submodule/subproject, a commit object reference
1279 sub S_ISGITLINK($) {
1280         my $mode = shift;
1281
1282         return (($mode & S_IFMT) == S_IFGITLINK)
1283 }
1284
1285 # convert file mode in octal to symbolic file mode string
1286 sub mode_str {
1287         my $mode = oct shift;
1288
1289         if (S_ISGITLINK($mode)) {
1290                 return 'm---------';
1291         } elsif (S_ISDIR($mode & S_IFMT)) {
1292                 return 'drwxr-xr-x';
1293         } elsif (S_ISLNK($mode)) {
1294                 return 'lrwxrwxrwx';
1295         } elsif (S_ISREG($mode)) {
1296                 # git cares only about the executable bit
1297                 if ($mode & S_IXUSR) {
1298                         return '-rwxr-xr-x';
1299                 } else {
1300                         return '-rw-r--r--';
1301                 };
1302         } else {
1303                 return '----------';
1304         }
1305 }
1306
1307 # convert file mode in octal to file type string
1308 sub file_type {
1309         my $mode = shift;
1310
1311         if ($mode !~ m/^[0-7]+$/) {
1312                 return $mode;
1313         } else {
1314                 $mode = oct $mode;
1315         }
1316
1317         if (S_ISGITLINK($mode)) {
1318                 return "submodule";
1319         } elsif (S_ISDIR($mode & S_IFMT)) {
1320                 return "directory";
1321         } elsif (S_ISLNK($mode)) {
1322                 return "symlink";
1323         } elsif (S_ISREG($mode)) {
1324                 return "file";
1325         } else {
1326                 return "unknown";
1327         }
1328 }
1329
1330 # convert file mode in octal to file type description string
1331 sub file_type_long {
1332         my $mode = shift;
1333
1334         if ($mode !~ m/^[0-7]+$/) {
1335                 return $mode;
1336         } else {
1337                 $mode = oct $mode;
1338         }
1339
1340         if (S_ISGITLINK($mode)) {
1341                 return "submodule";
1342         } elsif (S_ISDIR($mode & S_IFMT)) {
1343                 return "directory";
1344         } elsif (S_ISLNK($mode)) {
1345                 return "symlink";
1346         } elsif (S_ISREG($mode)) {
1347                 if ($mode & S_IXUSR) {
1348                         return "executable";
1349                 } else {
1350                         return "file";
1351                 };
1352         } else {
1353                 return "unknown";
1354         }
1355 }
1356
1357
1358 ## ----------------------------------------------------------------------
1359 ## functions returning short HTML fragments, or transforming HTML fragments
1360 ## which don't belong to other sections
1361
1362 # format line of commit message.
1363 sub format_log_line_html {
1364         my $line = shift;
1365
1366         $line = esc_html($line, -nbsp=>1);
1367         if ($line =~ m/([0-9a-fA-F]{8,40})/) {
1368                 my $hash_text = $1;
1369                 my $link =
1370                         $cgi->a({-href => href(action=>"object", hash=>$hash_text),
1371                                 -class => "text"}, $hash_text);
1372                 $line =~ s/$hash_text/$link/;
1373         }
1374         return $line;
1375 }
1376
1377 # format marker of refs pointing to given object
1378
1379 # the destination action is chosen based on object type and current context:
1380 # - for annotated tags, we choose the tag view unless it's the current view
1381 #   already, in which case we go to shortlog view
1382 # - for other refs, we keep the current view if we're in history, shortlog or
1383 #   log view, and select shortlog otherwise
1384 sub format_ref_marker {
1385         my ($refs, $id) = @_;
1386         my $markers = '';
1387
1388         if (defined $refs->{$id}) {
1389                 foreach my $ref (@{$refs->{$id}}) {
1390                         # this code exploits the fact that non-lightweight tags are the
1391                         # only indirect objects, and that they are the only objects for which
1392                         # we want to use tag instead of shortlog as action
1393                         my ($type, $name) = qw();
1394                         my $indirect = ($ref =~ s/\^\{\}$//);
1395                         # e.g. tags/v2.6.11 or heads/next
1396                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1397                                 $type = $1;
1398                                 $name = $2;
1399                         } else {
1400                                 $type = "ref";
1401                                 $name = $ref;
1402                         }
1403
1404                         my $class = $type;
1405                         $class .= " indirect" if $indirect;
1406
1407                         my $dest_action = "shortlog";
1408
1409                         if ($indirect) {
1410                                 $dest_action = "tag" unless $action eq "tag";
1411                         } elsif ($action =~ /^(history|(short)?log)$/) {
1412                                 $dest_action = $action;
1413                         }
1414
1415                         my $dest = "";
1416                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1417                         $dest .= $ref;
1418
1419                         my $link = $cgi->a({
1420                                 -href => href(
1421                                         action=>$dest_action,
1422                                         hash=>$dest
1423                                 )}, $name);
1424
1425                         $markers .= " <span class=\"$class\" title=\"$ref\">" .
1426                                 $link . "</span>";
1427                 }
1428         }
1429
1430         if ($markers) {
1431                 return ' <span class="refs">'. $markers . '</span>';
1432         } else {
1433                 return "";
1434         }
1435 }
1436
1437 # format, perhaps shortened and with markers, title line
1438 sub format_subject_html {
1439         my ($long, $short, $href, $extra) = @_;
1440         $extra = '' unless defined($extra);
1441
1442         if (length($short) < length($long)) {
1443                 return $cgi->a({-href => $href, -class => "list subject",
1444                                 -title => to_utf8($long)},
1445                        esc_html($short) . $extra);
1446         } else {
1447                 return $cgi->a({-href => $href, -class => "list subject"},
1448                        esc_html($long)  . $extra);
1449         }
1450 }
1451
1452 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1453 sub format_git_diff_header_line {
1454         my $line = shift;
1455         my $diffinfo = shift;
1456         my ($from, $to) = @_;
1457
1458         if ($diffinfo->{'nparents'}) {
1459                 # combined diff
1460                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1461                 if ($to->{'href'}) {
1462                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1463                                          esc_path($to->{'file'}));
1464                 } else { # file was deleted (no href)
1465                         $line .= esc_path($to->{'file'});
1466                 }
1467         } else {
1468                 # "ordinary" diff
1469                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1470                 if ($from->{'href'}) {
1471                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1472                                          'a/' . esc_path($from->{'file'}));
1473                 } else { # file was added (no href)
1474                         $line .= 'a/' . esc_path($from->{'file'});
1475                 }
1476                 $line .= ' ';
1477                 if ($to->{'href'}) {
1478                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1479                                          'b/' . esc_path($to->{'file'}));
1480                 } else { # file was deleted
1481                         $line .= 'b/' . esc_path($to->{'file'});
1482                 }
1483         }
1484
1485         return "<div class=\"diff header\">$line</div>\n";
1486 }
1487
1488 # format extended diff header line, before patch itself
1489 sub format_extended_diff_header_line {
1490         my $line = shift;
1491         my $diffinfo = shift;
1492         my ($from, $to) = @_;
1493
1494         # match <path>
1495         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1496                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1497                                        esc_path($from->{'file'}));
1498         }
1499         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1500                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1501                                  esc_path($to->{'file'}));
1502         }
1503         # match single <mode>
1504         if ($line =~ m/\s(\d{6})$/) {
1505                 $line .= '<span class="info"> (' .
1506                          file_type_long($1) .
1507                          ')</span>';
1508         }
1509         # match <hash>
1510         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1511                 # can match only for combined diff
1512                 $line = 'index ';
1513                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1514                         if ($from->{'href'}[$i]) {
1515                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1516                                                   -class=>"hash"},
1517                                                  substr($diffinfo->{'from_id'}[$i],0,7));
1518                         } else {
1519                                 $line .= '0' x 7;
1520                         }
1521                         # separator
1522                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1523                 }
1524                 $line .= '..';
1525                 if ($to->{'href'}) {
1526                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1527                                          substr($diffinfo->{'to_id'},0,7));
1528                 } else {
1529                         $line .= '0' x 7;
1530                 }
1531
1532         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1533                 # can match only for ordinary diff
1534                 my ($from_link, $to_link);
1535                 if ($from->{'href'}) {
1536                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
1537                                              substr($diffinfo->{'from_id'},0,7));
1538                 } else {
1539                         $from_link = '0' x 7;
1540                 }
1541                 if ($to->{'href'}) {
1542                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1543                                            substr($diffinfo->{'to_id'},0,7));
1544                 } else {
1545                         $to_link = '0' x 7;
1546                 }
1547                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
1548                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
1549         }
1550
1551         return $line . "<br/>\n";
1552 }
1553
1554 # format from-file/to-file diff header
1555 sub format_diff_from_to_header {
1556         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
1557         my $line;
1558         my $result = '';
1559
1560         $line = $from_line;
1561         #assert($line =~ m/^---/) if DEBUG;
1562         # no extra formatting for "^--- /dev/null"
1563         if (! $diffinfo->{'nparents'}) {
1564                 # ordinary (single parent) diff
1565                 if ($line =~ m!^--- "?a/!) {
1566                         if ($from->{'href'}) {
1567                                 $line = '--- a/' .
1568                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1569                                                 esc_path($from->{'file'}));
1570                         } else {
1571                                 $line = '--- a/' .
1572                                         esc_path($from->{'file'});
1573                         }
1574                 }
1575                 $result .= qq!<div class="diff from_file">$line</div>\n!;
1576
1577         } else {
1578                 # combined diff (merge commit)
1579                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1580                         if ($from->{'href'}[$i]) {
1581                                 $line = '--- ' .
1582                                         $cgi->a({-href=>href(action=>"blobdiff",
1583                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
1584                                                              hash_parent_base=>$parents[$i],
1585                                                              file_parent=>$from->{'file'}[$i],
1586                                                              hash=>$diffinfo->{'to_id'},
1587                                                              hash_base=>$hash,
1588                                                              file_name=>$to->{'file'}),
1589                                                  -class=>"path",
1590                                                  -title=>"diff" . ($i+1)},
1591                                                 $i+1) .
1592                                         '/' .
1593                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
1594                                                 esc_path($from->{'file'}[$i]));
1595                         } else {
1596                                 $line = '--- /dev/null';
1597                         }
1598                         $result .= qq!<div class="diff from_file">$line</div>\n!;
1599                 }
1600         }
1601
1602         $line = $to_line;
1603         #assert($line =~ m/^\+\+\+/) if DEBUG;
1604         # no extra formatting for "^+++ /dev/null"
1605         if ($line =~ m!^\+\+\+ "?b/!) {
1606                 if ($to->{'href'}) {
1607                         $line = '+++ b/' .
1608                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1609                                         esc_path($to->{'file'}));
1610                 } else {
1611                         $line = '+++ b/' .
1612                                 esc_path($to->{'file'});
1613                 }
1614         }
1615         $result .= qq!<div class="diff to_file">$line</div>\n!;
1616
1617         return $result;
1618 }
1619
1620 # create note for patch simplified by combined diff
1621 sub format_diff_cc_simplified {
1622         my ($diffinfo, @parents) = @_;
1623         my $result = '';
1624
1625         $result .= "<div class=\"diff header\">" .
1626                    "diff --cc ";
1627         if (!is_deleted($diffinfo)) {
1628                 $result .= $cgi->a({-href => href(action=>"blob",
1629                                                   hash_base=>$hash,
1630                                                   hash=>$diffinfo->{'to_id'},
1631                                                   file_name=>$diffinfo->{'to_file'}),
1632                                     -class => "path"},
1633                                    esc_path($diffinfo->{'to_file'}));
1634         } else {
1635                 $result .= esc_path($diffinfo->{'to_file'});
1636         }
1637         $result .= "</div>\n" . # class="diff header"
1638                    "<div class=\"diff nodifferences\">" .
1639                    "Simple merge" .
1640                    "</div>\n"; # class="diff nodifferences"
1641
1642         return $result;
1643 }
1644
1645 # format patch (diff) line (not to be used for diff headers)
1646 sub format_diff_line {
1647         my $line = shift;
1648         my ($from, $to) = @_;
1649         my $diff_class = "";
1650
1651         chomp $line;
1652
1653         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
1654                 # combined diff
1655                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
1656                 if ($line =~ m/^\@{3}/) {
1657                         $diff_class = " chunk_header";
1658                 } elsif ($line =~ m/^\\/) {
1659                         $diff_class = " incomplete";
1660                 } elsif ($prefix =~ tr/+/+/) {
1661                         $diff_class = " add";
1662                 } elsif ($prefix =~ tr/-/-/) {
1663                         $diff_class = " rem";
1664                 }
1665         } else {
1666                 # assume ordinary diff
1667                 my $char = substr($line, 0, 1);
1668                 if ($char eq '+') {
1669                         $diff_class = " add";
1670                 } elsif ($char eq '-') {
1671                         $diff_class = " rem";
1672                 } elsif ($char eq '@') {
1673                         $diff_class = " chunk_header";
1674                 } elsif ($char eq "\\") {
1675                         $diff_class = " incomplete";
1676                 }
1677         }
1678         $line = untabify($line);
1679         if ($from && $to && $line =~ m/^\@{2} /) {
1680                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
1681                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
1682
1683                 $from_lines = 0 unless defined $from_lines;
1684                 $to_lines   = 0 unless defined $to_lines;
1685
1686                 if ($from->{'href'}) {
1687                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
1688                                              -class=>"list"}, $from_text);
1689                 }
1690                 if ($to->{'href'}) {
1691                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
1692                                              -class=>"list"}, $to_text);
1693                 }
1694                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
1695                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
1696                 return "<div class=\"diff$diff_class\">$line</div>\n";
1697         } elsif ($from && $to && $line =~ m/^\@{3}/) {
1698                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
1699                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
1700
1701                 @from_text = split(' ', $ranges);
1702                 for (my $i = 0; $i < @from_text; ++$i) {
1703                         ($from_start[$i], $from_nlines[$i]) =
1704                                 (split(',', substr($from_text[$i], 1)), 0);
1705                 }
1706
1707                 $to_text   = pop @from_text;
1708                 $to_start  = pop @from_start;
1709                 $to_nlines = pop @from_nlines;
1710
1711                 $line = "<span class=\"chunk_info\">$prefix ";
1712                 for (my $i = 0; $i < @from_text; ++$i) {
1713                         if ($from->{'href'}[$i]) {
1714                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
1715                                                   -class=>"list"}, $from_text[$i]);
1716                         } else {
1717                                 $line .= $from_text[$i];
1718                         }
1719                         $line .= " ";
1720                 }
1721                 if ($to->{'href'}) {
1722                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
1723                                           -class=>"list"}, $to_text);
1724                 } else {
1725                         $line .= $to_text;
1726                 }
1727                 $line .= " $prefix</span>" .
1728                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
1729                 return "<div class=\"diff$diff_class\">$line</div>\n";
1730         }
1731         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
1732 }
1733
1734 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
1735 # linked.  Pass the hash of the tree/commit to snapshot.
1736 sub format_snapshot_links {
1737         my ($hash) = @_;
1738         my $num_fmts = @snapshot_fmts;
1739         if ($num_fmts > 1) {
1740                 # A parenthesized list of links bearing format names.
1741                 # e.g. "snapshot (_tar.gz_ _zip_)"
1742                 return "snapshot (" . join(' ', map
1743                         $cgi->a({
1744                                 -href => href(
1745                                         action=>"snapshot",
1746                                         hash=>$hash,
1747                                         snapshot_format=>$_
1748                                 )
1749                         }, $known_snapshot_formats{$_}{'display'})
1750                 , @snapshot_fmts) . ")";
1751         } elsif ($num_fmts == 1) {
1752                 # A single "snapshot" link whose tooltip bears the format name.
1753                 # i.e. "_snapshot_"
1754                 my ($fmt) = @snapshot_fmts;
1755                 return
1756                         $cgi->a({
1757                                 -href => href(
1758                                         action=>"snapshot",
1759                                         hash=>$hash,
1760                                         snapshot_format=>$fmt
1761                                 ),
1762                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
1763                         }, "snapshot");
1764         } else { # $num_fmts == 0
1765                 return undef;
1766         }
1767 }
1768
1769 ## ......................................................................
1770 ## functions returning values to be passed, perhaps after some
1771 ## transformation, to other functions; e.g. returning arguments to href()
1772
1773 # returns hash to be passed to href to generate gitweb URL
1774 # in -title key it returns description of link
1775 sub get_feed_info {
1776         my $format = shift || 'Atom';
1777         my %res = (action => lc($format));
1778
1779         # feed links are possible only for project views
1780         return unless (defined $project);
1781         # some views should link to OPML, or to generic project feed,
1782         # or don't have specific feed yet (so they should use generic)
1783         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
1784
1785         my $branch;
1786         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
1787         # from tag links; this also makes possible to detect branch links
1788         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
1789             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
1790                 $branch = $1;
1791         }
1792         # find log type for feed description (title)
1793         my $type = 'log';
1794         if (defined $file_name) {
1795                 $type  = "history of $file_name";
1796                 $type .= "/" if ($action eq 'tree');
1797                 $type .= " on '$branch'" if (defined $branch);
1798         } else {
1799                 $type = "log of $branch" if (defined $branch);
1800         }
1801
1802         $res{-title} = $type;
1803         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
1804         $res{'file_name'} = $file_name;
1805
1806         return %res;
1807 }
1808
1809 ## ----------------------------------------------------------------------
1810 ## git utility subroutines, invoking git commands
1811
1812 # returns path to the core git executable and the --git-dir parameter as list
1813 sub git_cmd {
1814         return $GIT, '--git-dir='.$git_dir;
1815 }
1816
1817 # quote the given arguments for passing them to the shell
1818 # quote_command("command", "arg 1", "arg with ' and ! characters")
1819 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
1820 # Try to avoid using this function wherever possible.
1821 sub quote_command {
1822         return join(' ',
1823                     map( { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ ));
1824 }
1825
1826 # get HEAD ref of given project as hash
1827 sub git_get_head_hash {
1828         my $project = shift;
1829         my $o_git_dir = $git_dir;
1830         my $retval = undef;
1831         $git_dir = "$projectroot/$project";
1832         if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
1833                 my $head = <$fd>;
1834                 close $fd;
1835                 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
1836                         $retval = $1;
1837                 }
1838         }
1839         if (defined $o_git_dir) {
1840                 $git_dir = $o_git_dir;
1841         }
1842         return $retval;
1843 }
1844
1845 # get type of given object
1846 sub git_get_type {
1847         my $hash = shift;
1848
1849         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
1850         my $type = <$fd>;
1851         close $fd or return;
1852         chomp $type;
1853         return $type;
1854 }
1855
1856 # repository configuration
1857 our $config_file = '';
1858 our %config;
1859
1860 # store multiple values for single key as anonymous array reference
1861 # single values stored directly in the hash, not as [ <value> ]
1862 sub hash_set_multi {
1863         my ($hash, $key, $value) = @_;
1864
1865         if (!exists $hash->{$key}) {
1866                 $hash->{$key} = $value;
1867         } elsif (!ref $hash->{$key}) {
1868                 $hash->{$key} = [ $hash->{$key}, $value ];
1869         } else {
1870                 push @{$hash->{$key}}, $value;
1871         }
1872 }
1873
1874 # return hash of git project configuration
1875 # optionally limited to some section, e.g. 'gitweb'
1876 sub git_parse_project_config {
1877         my $section_regexp = shift;
1878         my %config;
1879
1880         local $/ = "\0";
1881
1882         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
1883                 or return;
1884
1885         while (my $keyval = <$fh>) {
1886                 chomp $keyval;
1887                 my ($key, $value) = split(/\n/, $keyval, 2);
1888
1889                 hash_set_multi(\%config, $key, $value)
1890                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
1891         }
1892         close $fh;
1893
1894         return %config;
1895 }
1896
1897 # convert config value to boolean, 'true' or 'false'
1898 # no value, number > 0, 'true' and 'yes' values are true
1899 # rest of values are treated as false (never as error)
1900 sub config_to_bool {
1901         my $val = shift;
1902
1903         # strip leading and trailing whitespace
1904         $val =~ s/^\s+//;
1905         $val =~ s/\s+$//;
1906
1907         return (!defined $val ||               # section.key
1908                 ($val =~ /^\d+$/ && $val) ||   # section.key = 1
1909                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
1910 }
1911
1912 # convert config value to simple decimal number
1913 # an optional value suffix of 'k', 'm', or 'g' will cause the value
1914 # to be multiplied by 1024, 1048576, or 1073741824
1915 sub config_to_int {
1916         my $val = shift;
1917
1918         # strip leading and trailing whitespace
1919         $val =~ s/^\s+//;
1920         $val =~ s/\s+$//;
1921
1922         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
1923                 $unit = lc($unit);
1924                 # unknown unit is treated as 1
1925                 return $num * ($unit eq 'g' ? 1073741824 :
1926                                $unit eq 'm' ?    1048576 :
1927                                $unit eq 'k' ?       1024 : 1);
1928         }
1929         return $val;
1930 }
1931
1932 # convert config value to array reference, if needed
1933 sub config_to_multi {
1934         my $val = shift;
1935
1936         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
1937 }
1938
1939 sub git_get_project_config {
1940         my ($key, $type) = @_;
1941
1942         # key sanity check
1943         return unless ($key);
1944         $key =~ s/^gitweb\.//;
1945         return if ($key =~ m/\W/);
1946
1947         # type sanity check
1948         if (defined $type) {
1949                 $type =~ s/^--//;
1950                 $type = undef
1951                         unless ($type eq 'bool' || $type eq 'int');
1952         }
1953
1954         # get config
1955         if (!defined $config_file ||
1956             $config_file ne "$git_dir/config") {
1957                 %config = git_parse_project_config('gitweb');
1958                 $config_file = "$git_dir/config";
1959         }
1960
1961         # ensure given type
1962         if (!defined $type) {
1963                 return $config{"gitweb.$key"};
1964         } elsif ($type eq 'bool') {
1965                 # backward compatibility: 'git config --bool' returns true/false
1966                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
1967         } elsif ($type eq 'int') {
1968                 return config_to_int($config{"gitweb.$key"});
1969         }
1970         return $config{"gitweb.$key"};
1971 }
1972
1973 # get hash of given path at given ref
1974 sub git_get_hash_by_path {
1975         my $base = shift;
1976         my $path = shift || return undef;
1977         my $type = shift;
1978
1979         $path =~ s,/+$,,;
1980
1981         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
1982                 or die_error(500, "Open git-ls-tree failed");
1983         my $line = <$fd>;
1984         close $fd or return undef;
1985
1986         if (!defined $line) {
1987                 # there is no tree or hash given by $path at $base
1988                 return undef;
1989         }
1990
1991         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1992         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
1993         if (defined $type && $type ne $2) {
1994                 # type doesn't match
1995                 return undef;
1996         }
1997         return $3;
1998 }
1999
2000 # get path of entry with given hash at given tree-ish (ref)
2001 # used to get 'from' filename for combined diff (merge commit) for renames
2002 sub git_get_path_by_hash {
2003         my $base = shift || return;
2004         my $hash = shift || return;
2005
2006         local $/ = "\0";
2007
2008         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2009                 or return undef;
2010         while (my $line = <$fd>) {
2011                 chomp $line;
2012
2013                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2014                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2015                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2016                         close $fd;
2017                         return $1;
2018                 }
2019         }
2020         close $fd;
2021         return undef;
2022 }
2023
2024 ## ......................................................................
2025 ## git utility functions, directly accessing git repository
2026
2027 sub git_get_project_description {
2028         my $path = shift;
2029
2030         $git_dir = "$projectroot/$path";
2031         open my $fd, "$git_dir/description"
2032                 or return git_get_project_config('description');
2033         my $descr = <$fd>;
2034         close $fd;
2035         if (defined $descr) {
2036                 chomp $descr;
2037         }
2038         return $descr;
2039 }
2040
2041 sub git_get_project_ctags {
2042         my $path = shift;
2043         my $ctags = {};
2044
2045         $git_dir = "$projectroot/$path";
2046         unless (opendir D, "$git_dir/ctags") {
2047                 return $ctags;
2048         }
2049         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir(D)) {
2050                 open CT, $_ or next;
2051                 my $val = <CT>;
2052                 chomp $val;
2053                 close CT;
2054                 my $ctag = $_; $ctag =~ s#.*/##;
2055                 $ctags->{$ctag} = $val;
2056         }
2057         closedir D;
2058         $ctags;
2059 }
2060
2061 sub git_populate_project_tagcloud {
2062         my $ctags = shift;
2063
2064         # First, merge different-cased tags; tags vote on casing
2065         my %ctags_lc;
2066         foreach (keys %$ctags) {
2067                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2068                 if (not $ctags_lc{lc $_}->{topcount}
2069                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2070                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2071                         $ctags_lc{lc $_}->{topname} = $_;
2072                 }
2073         }
2074
2075         my $cloud;
2076         if (eval { require HTML::TagCloud; 1; }) {
2077                 $cloud = HTML::TagCloud->new;
2078                 foreach (sort keys %ctags_lc) {
2079                         # Pad the title with spaces so that the cloud looks
2080                         # less crammed.
2081                         my $title = $ctags_lc{$_}->{topname};
2082                         $title =~ s/ /&nbsp;/g;
2083                         $title =~ s/^/&nbsp;/g;
2084                         $title =~ s/$/&nbsp;/g;
2085                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2086                 }
2087         } else {
2088                 $cloud = \%ctags_lc;
2089         }
2090         $cloud;
2091 }
2092
2093 sub git_show_project_tagcloud {
2094         my ($cloud, $count) = @_;
2095         print STDERR ref($cloud)."..\n";
2096         if (ref $cloud eq 'HTML::TagCloud') {
2097                 return $cloud->html_and_css($count);
2098         } else {
2099                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2100                 return '<p align="center">' . join (', ', map {
2101                         "<a href=\"$home_link?by_tag=$_\">$cloud->{$_}->{topname}</a>"
2102                 } splice(@tags, 0, $count)) . '</p>';
2103         }
2104 }
2105
2106 sub git_get_project_url_list {
2107         my $path = shift;
2108
2109         $git_dir = "$projectroot/$path";
2110         open my $fd, "$git_dir/cloneurl"
2111                 or return wantarray ?
2112                 @{ config_to_multi(git_get_project_config('url')) } :
2113                    config_to_multi(git_get_project_config('url'));
2114         my @git_project_url_list = map { chomp; $_ } <$fd>;
2115         close $fd;
2116
2117         return wantarray ? @git_project_url_list : \@git_project_url_list;
2118 }
2119
2120 sub git_get_projects_list {
2121         my ($filter) = @_;
2122         my @list;
2123
2124         $filter ||= '';
2125         $filter =~ s/\.git$//;
2126
2127         my $check_forks = gitweb_check_feature('forks');
2128
2129         if (-d $projects_list) {
2130                 # search in directory
2131                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2132                 # remove the trailing "/"
2133                 $dir =~ s!/+$!!;
2134                 my $pfxlen = length("$dir");
2135                 my $pfxdepth = ($dir =~ tr!/!!);
2136
2137                 File::Find::find({
2138                         follow_fast => 1, # follow symbolic links
2139                         follow_skip => 2, # ignore duplicates
2140                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2141                         wanted => sub {
2142                                 # skip project-list toplevel, if we get it.
2143                                 return if (m!^[/.]$!);
2144                                 # only directories can be git repositories
2145                                 return unless (-d $_);
2146                                 # don't traverse too deep (Find is super slow on os x)
2147                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2148                                         $File::Find::prune = 1;
2149                                         return;
2150                                 }
2151
2152                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2153                                 # we check related file in $projectroot
2154                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2155                                 if (check_export_ok("$projectroot/$path")) {
2156                                         push @list, { path => $path };
2157                                         $File::Find::prune = 1;
2158                                 }
2159                         },
2160                 }, "$dir");
2161
2162         } elsif (-f $projects_list) {
2163                 # read from file(url-encoded):
2164                 # 'git%2Fgit.git Linus+Torvalds'
2165                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2166                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2167                 my %paths;
2168                 open my ($fd), $projects_list or return;
2169         PROJECT:
2170                 while (my $line = <$fd>) {
2171                         chomp $line;
2172                         my ($path, $owner) = split ' ', $line;
2173                         $path = unescape($path);
2174                         $owner = unescape($owner);
2175                         if (!defined $path) {
2176                                 next;
2177                         }
2178                         if ($filter ne '') {
2179                                 # looking for forks;
2180                                 my $pfx = substr($path, 0, length($filter));
2181                                 if ($pfx ne $filter) {
2182                                         next PROJECT;
2183                                 }
2184                                 my $sfx = substr($path, length($filter));
2185                                 if ($sfx !~ /^\/.*\.git$/) {
2186                                         next PROJECT;
2187                                 }
2188                         } elsif ($check_forks) {
2189                         PATH:
2190                                 foreach my $filter (keys %paths) {
2191                                         # looking for forks;
2192                                         my $pfx = substr($path, 0, length($filter));
2193                                         if ($pfx ne $filter) {
2194                                                 next PATH;
2195                                         }
2196                                         my $sfx = substr($path, length($filter));
2197                                         if ($sfx !~ /^\/.*\.git$/) {
2198                                                 next PATH;
2199                                         }
2200                                         # is a fork, don't include it in
2201                                         # the list
2202                                         next PROJECT;
2203                                 }
2204                         }
2205                         if (check_export_ok("$projectroot/$path")) {
2206                                 my $pr = {
2207                                         path => $path,
2208                                         owner => to_utf8($owner),
2209                                 };
2210                                 push @list, $pr;
2211                                 (my $forks_path = $path) =~ s/\.git$//;
2212                                 $paths{$forks_path}++;
2213                         }
2214                 }
2215                 close $fd;
2216         }
2217         return @list;
2218 }
2219
2220 our $gitweb_project_owner = undef;
2221 sub git_get_project_list_from_file {
2222
2223         return if (defined $gitweb_project_owner);
2224
2225         $gitweb_project_owner = {};
2226         # read from file (url-encoded):
2227         # 'git%2Fgit.git Linus+Torvalds'
2228         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2229         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2230         if (-f $projects_list) {
2231                 open (my $fd , $projects_list);
2232                 while (my $line = <$fd>) {
2233                         chomp $line;
2234                         my ($pr, $ow) = split ' ', $line;
2235                         $pr = unescape($pr);
2236                         $ow = unescape($ow);
2237                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2238                 }
2239                 close $fd;
2240         }
2241 }
2242
2243 sub git_get_project_owner {
2244         my $project = shift;
2245         my $owner;
2246
2247         return undef unless $project;
2248         $git_dir = "$projectroot/$project";
2249
2250         if (!defined $gitweb_project_owner) {
2251                 git_get_project_list_from_file();
2252         }
2253
2254         if (exists $gitweb_project_owner->{$project}) {
2255                 $owner = $gitweb_project_owner->{$project};
2256         }
2257         if (!defined $owner){
2258                 $owner = git_get_project_config('owner');
2259         }
2260         if (!defined $owner) {
2261                 $owner = get_file_owner("$git_dir");
2262         }
2263
2264         return $owner;
2265 }
2266
2267 sub git_get_last_activity {
2268         my ($path) = @_;
2269         my $fd;
2270
2271         $git_dir = "$projectroot/$path";
2272         open($fd, "-|", git_cmd(), 'for-each-ref',
2273              '--format=%(committer)',
2274              '--sort=-committerdate',
2275              '--count=1',
2276              'refs/heads') or return;
2277         my $most_recent = <$fd>;
2278         close $fd or return;
2279         if (defined $most_recent &&
2280             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2281                 my $timestamp = $1;
2282                 my $age = time - $timestamp;
2283                 return ($age, age_string($age));
2284         }
2285         return (undef, undef);
2286 }
2287
2288 sub git_get_references {
2289         my $type = shift || "";
2290         my %refs;
2291         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2292         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2293         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2294                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2295                 or return;
2296
2297         while (my $line = <$fd>) {
2298                 chomp $line;
2299                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2300                         if (defined $refs{$1}) {
2301                                 push @{$refs{$1}}, $2;
2302                         } else {
2303                                 $refs{$1} = [ $2 ];
2304                         }
2305                 }
2306         }
2307         close $fd or return;
2308         return \%refs;
2309 }
2310
2311 sub git_get_rev_name_tags {
2312         my $hash = shift || return undef;
2313
2314         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2315                 or return;
2316         my $name_rev = <$fd>;
2317         close $fd;
2318
2319         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2320                 return $1;
2321         } else {
2322                 # catches also '$hash undefined' output
2323                 return undef;
2324         }
2325 }
2326
2327 ## ----------------------------------------------------------------------
2328 ## parse to hash functions
2329
2330 sub parse_date {
2331         my $epoch = shift;
2332         my $tz = shift || "-0000";
2333
2334         my %date;
2335         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2336         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2337         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2338         $date{'hour'} = $hour;
2339         $date{'minute'} = $min;
2340         $date{'mday'} = $mday;
2341         $date{'day'} = $days[$wday];
2342         $date{'month'} = $months[$mon];
2343         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2344                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2345         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2346                              $mday, $months[$mon], $hour ,$min;
2347         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2348                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2349
2350         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2351         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2352         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2353         $date{'hour_local'} = $hour;
2354         $date{'minute_local'} = $min;
2355         $date{'tz_local'} = $tz;
2356         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2357                                   1900+$year, $mon+1, $mday,
2358                                   $hour, $min, $sec, $tz);
2359         return %date;
2360 }
2361
2362 sub parse_tag {
2363         my $tag_id = shift;
2364         my %tag;
2365         my @comment;
2366
2367         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2368         $tag{'id'} = $tag_id;
2369         while (my $line = <$fd>) {
2370                 chomp $line;
2371                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2372                         $tag{'object'} = $1;
2373                 } elsif ($line =~ m/^type (.+)$/) {
2374                         $tag{'type'} = $1;
2375                 } elsif ($line =~ m/^tag (.+)$/) {
2376                         $tag{'name'} = $1;
2377                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2378                         $tag{'author'} = $1;
2379                         $tag{'epoch'} = $2;
2380                         $tag{'tz'} = $3;
2381                 } elsif ($line =~ m/--BEGIN/) {
2382                         push @comment, $line;
2383                         last;
2384                 } elsif ($line eq "") {
2385                         last;
2386                 }
2387         }
2388         push @comment, <$fd>;
2389         $tag{'comment'} = \@comment;
2390         close $fd or return;
2391         if (!defined $tag{'name'}) {
2392                 return
2393         };
2394         return %tag
2395 }
2396
2397 sub parse_commit_text {
2398         my ($commit_text, $withparents) = @_;
2399         my @commit_lines = split '\n', $commit_text;
2400         my %co;
2401
2402         pop @commit_lines; # Remove '\0'
2403
2404         if (! @commit_lines) {
2405                 return;
2406         }
2407
2408         my $header = shift @commit_lines;
2409         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2410                 return;
2411         }
2412         ($co{'id'}, my @parents) = split ' ', $header;
2413         while (my $line = shift @commit_lines) {
2414                 last if $line eq "\n";
2415                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2416                         $co{'tree'} = $1;
2417                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2418                         push @parents, $1;
2419                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2420                         $co{'author'} = $1;
2421                         $co{'author_epoch'} = $2;
2422                         $co{'author_tz'} = $3;
2423                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2424                                 $co{'author_name'}  = $1;
2425                                 $co{'author_email'} = $2;
2426                         } else {
2427                                 $co{'author_name'} = $co{'author'};
2428                         }
2429                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
2430                         $co{'committer'} = $1;
2431                         $co{'committer_epoch'} = $2;
2432                         $co{'committer_tz'} = $3;
2433                         $co{'committer_name'} = $co{'committer'};
2434                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
2435                                 $co{'committer_name'}  = $1;
2436                                 $co{'committer_email'} = $2;
2437                         } else {
2438                                 $co{'committer_name'} = $co{'committer'};
2439                         }
2440                 }
2441         }
2442         if (!defined $co{'tree'}) {
2443                 return;
2444         };
2445         $co{'parents'} = \@parents;
2446         $co{'parent'} = $parents[0];
2447
2448         foreach my $title (@commit_lines) {
2449                 $title =~ s/^    //;
2450                 if ($title ne "") {
2451                         $co{'title'} = chop_str($title, 80, 5);
2452                         # remove leading stuff of merges to make the interesting part visible
2453                         if (length($title) > 50) {
2454                                 $title =~ s/^Automatic //;
2455                                 $title =~ s/^merge (of|with) /Merge ... /i;
2456                                 if (length($title) > 50) {
2457                                         $title =~ s/(http|rsync):\/\///;
2458                                 }
2459                                 if (length($title) > 50) {
2460                                         $title =~ s/(master|www|rsync)\.//;
2461                                 }
2462                                 if (length($title) > 50) {
2463                                         $title =~ s/kernel.org:?//;
2464                                 }
2465                                 if (length($title) > 50) {
2466                                         $title =~ s/\/pub\/scm//;
2467                                 }
2468                         }
2469                         $co{'title_short'} = chop_str($title, 50, 5);
2470                         last;
2471                 }
2472         }
2473         if (! defined $co{'title'} || $co{'title'} eq "") {
2474                 $co{'title'} = $co{'title_short'} = '(no commit message)';
2475         }
2476         # remove added spaces
2477         foreach my $line (@commit_lines) {
2478                 $line =~ s/^    //;
2479         }
2480         $co{'comment'} = \@commit_lines;
2481
2482         my $age = time - $co{'committer_epoch'};
2483         $co{'age'} = $age;
2484         $co{'age_string'} = age_string($age);
2485         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
2486         if ($age > 60*60*24*7*2) {
2487                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2488                 $co{'age_string_age'} = $co{'age_string'};
2489         } else {
2490                 $co{'age_string_date'} = $co{'age_string'};
2491                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2492         }
2493         return %co;
2494 }
2495
2496 sub parse_commit {
2497         my ($commit_id) = @_;
2498         my %co;
2499
2500         local $/ = "\0";
2501
2502         open my $fd, "-|", git_cmd(), "rev-list",
2503                 "--parents",
2504                 "--header",
2505                 "--max-count=1",
2506                 $commit_id,
2507                 "--",
2508                 or die_error(500, "Open git-rev-list failed");
2509         %co = parse_commit_text(<$fd>, 1);
2510         close $fd;
2511
2512         return %co;
2513 }
2514
2515 sub parse_commits {
2516         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
2517         my @cos;
2518
2519         $maxcount ||= 1;
2520         $skip ||= 0;
2521
2522         local $/ = "\0";
2523
2524         open my $fd, "-|", git_cmd(), "rev-list",
2525                 "--header",
2526                 @args,
2527                 ("--max-count=" . $maxcount),
2528                 ("--skip=" . $skip),
2529                 @extra_options,
2530                 $commit_id,
2531                 "--",
2532                 ($filename ? ($filename) : ())
2533                 or die_error(500, "Open git-rev-list failed");
2534         while (my $line = <$fd>) {
2535                 my %co = parse_commit_text($line);
2536                 push @cos, \%co;
2537         }
2538         close $fd;
2539
2540         return wantarray ? @cos : \@cos;
2541 }
2542
2543 # parse line of git-diff-tree "raw" output
2544 sub parse_difftree_raw_line {
2545         my $line = shift;
2546         my %res;
2547
2548         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
2549         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
2550         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
2551                 $res{'from_mode'} = $1;
2552                 $res{'to_mode'} = $2;
2553                 $res{'from_id'} = $3;
2554                 $res{'to_id'} = $4;
2555                 $res{'status'} = $5;
2556                 $res{'similarity'} = $6;
2557                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
2558                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
2559                 } else {
2560                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
2561                 }
2562         }
2563         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
2564         # combined diff (for merge commit)
2565         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
2566                 $res{'nparents'}  = length($1);
2567                 $res{'from_mode'} = [ split(' ', $2) ];
2568                 $res{'to_mode'} = pop @{$res{'from_mode'}};
2569                 $res{'from_id'} = [ split(' ', $3) ];
2570                 $res{'to_id'} = pop @{$res{'from_id'}};
2571                 $res{'status'} = [ split('', $4) ];
2572                 $res{'to_file'} = unquote($5);
2573         }
2574         # 'c512b523472485aef4fff9e57b229d9d243c967f'
2575         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
2576                 $res{'commit'} = $1;
2577         }
2578
2579         return wantarray ? %res : \%res;
2580 }
2581
2582 # wrapper: return parsed line of git-diff-tree "raw" output
2583 # (the argument might be raw line, or parsed info)
2584 sub parsed_difftree_line {
2585         my $line_or_ref = shift;
2586
2587         if (ref($line_or_ref) eq "HASH") {
2588                 # pre-parsed (or generated by hand)
2589                 return $line_or_ref;
2590         } else {
2591                 return parse_difftree_raw_line($line_or_ref);
2592         }
2593 }
2594
2595 # parse line of git-ls-tree output
2596 sub parse_ls_tree_line ($;%) {
2597         my $line = shift;
2598         my %opts = @_;
2599         my %res;
2600
2601         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2602         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
2603
2604         $res{'mode'} = $1;
2605         $res{'type'} = $2;
2606         $res{'hash'} = $3;
2607         if ($opts{'-z'}) {
2608                 $res{'name'} = $4;
2609         } else {
2610                 $res{'name'} = unquote($4);
2611         }
2612
2613         return wantarray ? %res : \%res;
2614 }
2615
2616 # generates _two_ hashes, references to which are passed as 2 and 3 argument
2617 sub parse_from_to_diffinfo {
2618         my ($diffinfo, $from, $to, @parents) = @_;
2619
2620         if ($diffinfo->{'nparents'}) {
2621                 # combined diff
2622                 $from->{'file'} = [];
2623                 $from->{'href'} = [];
2624                 fill_from_file_info($diffinfo, @parents)
2625                         unless exists $diffinfo->{'from_file'};
2626                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2627                         $from->{'file'}[$i] =
2628                                 defined $diffinfo->{'from_file'}[$i] ?
2629                                         $diffinfo->{'from_file'}[$i] :
2630                                         $diffinfo->{'to_file'};
2631                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
2632                                 $from->{'href'}[$i] = href(action=>"blob",
2633                                                            hash_base=>$parents[$i],
2634                                                            hash=>$diffinfo->{'from_id'}[$i],
2635                                                            file_name=>$from->{'file'}[$i]);
2636                         } else {
2637                                 $from->{'href'}[$i] = undef;
2638                         }
2639                 }
2640         } else {
2641                 # ordinary (not combined) diff
2642                 $from->{'file'} = $diffinfo->{'from_file'};
2643                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
2644                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
2645                                                hash=>$diffinfo->{'from_id'},
2646                                                file_name=>$from->{'file'});
2647                 } else {
2648                         delete $from->{'href'};
2649                 }
2650         }
2651
2652         $to->{'file'} = $diffinfo->{'to_file'};
2653         if (!is_deleted($diffinfo)) { # file exists in result
2654                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
2655                                      hash=>$diffinfo->{'to_id'},
2656                                      file_name=>$to->{'file'});
2657         } else {
2658                 delete $to->{'href'};
2659         }
2660 }
2661
2662 ## ......................................................................
2663 ## parse to array of hashes functions
2664
2665 sub git_get_heads_list {
2666         my $limit = shift;
2667         my @headslist;
2668
2669         open my $fd, '-|', git_cmd(), 'for-each-ref',
2670                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
2671                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
2672                 'refs/heads'
2673                 or return;
2674         while (my $line = <$fd>) {
2675                 my %ref_item;
2676
2677                 chomp $line;
2678                 my ($refinfo, $committerinfo) = split(/\0/, $line);
2679                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
2680                 my ($committer, $epoch, $tz) =
2681                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
2682                 $ref_item{'fullname'}  = $name;
2683                 $name =~ s!^refs/heads/!!;
2684
2685                 $ref_item{'name'}  = $name;
2686                 $ref_item{'id'}    = $hash;
2687                 $ref_item{'title'} = $title || '(no commit message)';
2688                 $ref_item{'epoch'} = $epoch;
2689                 if ($epoch) {
2690                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
2691                 } else {
2692                         $ref_item{'age'} = "unknown";
2693                 }
2694
2695                 push @headslist, \%ref_item;
2696         }
2697         close $fd;
2698
2699         return wantarray ? @headslist : \@headslist;
2700 }
2701
2702 sub git_get_tags_list {
2703         my $limit = shift;
2704         my @tagslist;
2705
2706         open my $fd, '-|', git_cmd(), 'for-each-ref',
2707                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
2708                 '--format=%(objectname) %(objecttype) %(refname) '.
2709                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
2710                 'refs/tags'
2711                 or return;
2712         while (my $line = <$fd>) {
2713                 my %ref_item;
2714
2715                 chomp $line;
2716                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
2717                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
2718                 my ($creator, $epoch, $tz) =
2719                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
2720                 $ref_item{'fullname'} = $name;
2721                 $name =~ s!^refs/tags/!!;
2722
2723                 $ref_item{'type'} = $type;
2724                 $ref_item{'id'} = $id;
2725                 $ref_item{'name'} = $name;
2726                 if ($type eq "tag") {
2727                         $ref_item{'subject'} = $title;
2728                         $ref_item{'reftype'} = $reftype;
2729                         $ref_item{'refid'}   = $refid;
2730                 } else {
2731                         $ref_item{'reftype'} = $type;
2732                         $ref_item{'refid'}   = $id;
2733                 }
2734
2735                 if ($type eq "tag" || $type eq "commit") {
2736                         $ref_item{'epoch'} = $epoch;
2737                         if ($epoch) {
2738                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
2739                         } else {
2740                                 $ref_item{'age'} = "unknown";
2741                         }
2742                 }
2743
2744                 push @tagslist, \%ref_item;
2745         }
2746         close $fd;
2747
2748         return wantarray ? @tagslist : \@tagslist;
2749 }
2750
2751 ## ----------------------------------------------------------------------
2752 ## filesystem-related functions
2753
2754 sub get_file_owner {
2755         my $path = shift;
2756
2757         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
2758         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
2759         if (!defined $gcos) {
2760                 return undef;
2761         }
2762         my $owner = $gcos;
2763         $owner =~ s/[,;].*$//;
2764         return to_utf8($owner);
2765 }
2766
2767 # assume that file exists
2768 sub insert_file {
2769         my $filename = shift;
2770
2771         open my $fd, '<', $filename;
2772         print map { to_utf8($_) } <$fd>;
2773         close $fd;
2774 }
2775
2776 ## ......................................................................
2777 ## mimetype related functions
2778
2779 sub mimetype_guess_file {
2780         my $filename = shift;
2781         my $mimemap = shift;
2782         -r $mimemap or return undef;
2783
2784         my %mimemap;
2785         open(MIME, $mimemap) or return undef;
2786         while (<MIME>) {
2787                 next if m/^#/; # skip comments
2788                 my ($mime, $exts) = split(/\t+/);
2789                 if (defined $exts) {
2790                         my @exts = split(/\s+/, $exts);
2791                         foreach my $ext (@exts) {
2792                                 $mimemap{$ext} = $mime;
2793                         }
2794                 }
2795         }
2796         close(MIME);
2797
2798         $filename =~ /\.([^.]*)$/;
2799         return $mimemap{$1};
2800 }
2801
2802 sub mimetype_guess {
2803         my $filename = shift;
2804         my $mime;
2805         $filename =~ /\./ or return undef;
2806
2807         if ($mimetypes_file) {
2808                 my $file = $mimetypes_file;
2809                 if ($file !~ m!^/!) { # if it is relative path
2810                         # it is relative to project
2811                         $file = "$projectroot/$project/$file";
2812                 }
2813                 $mime = mimetype_guess_file($filename, $file);
2814         }
2815         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
2816         return $mime;
2817 }
2818
2819 sub blob_mimetype {
2820         my $fd = shift;
2821         my $filename = shift;
2822
2823         if ($filename) {
2824                 my $mime = mimetype_guess($filename);
2825                 $mime and return $mime;
2826         }
2827
2828         # just in case
2829         return $default_blob_plain_mimetype unless $fd;
2830
2831         if (-T $fd) {
2832                 return 'text/plain';
2833         } elsif (! $filename) {
2834                 return 'application/octet-stream';
2835         } elsif ($filename =~ m/\.png$/i) {
2836                 return 'image/png';
2837         } elsif ($filename =~ m/\.gif$/i) {
2838                 return 'image/gif';
2839         } elsif ($filename =~ m/\.jpe?g$/i) {
2840                 return 'image/jpeg';
2841         } else {
2842                 return 'application/octet-stream';
2843         }
2844 }
2845
2846 sub blob_contenttype {
2847         my ($fd, $file_name, $type) = @_;
2848
2849         $type ||= blob_mimetype($fd, $file_name);
2850         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
2851                 $type .= "; charset=$default_text_plain_charset";
2852         }
2853
2854         return $type;
2855 }
2856
2857 ## ======================================================================
2858 ## functions printing HTML: header, footer, error page
2859
2860 sub git_header_html {
2861         my $status = shift || "200 OK";
2862         my $expires = shift;
2863
2864         my $title = "$site_name";
2865         if (defined $project) {
2866                 $title .= " - " . to_utf8($project);
2867                 if (defined $action) {
2868                         $title .= "/$action";
2869                         if (defined $file_name) {
2870                                 $title .= " - " . esc_path($file_name);
2871                                 if ($action eq "tree" && $file_name !~ m|/$|) {
2872                                         $title .= "/";
2873                                 }
2874                         }
2875                 }
2876         }
2877         my $content_type;
2878         # require explicit support from the UA if we are to send the page as
2879         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
2880         # we have to do this because MSIE sometimes globs '*/*', pretending to
2881         # support xhtml+xml but choking when it gets what it asked for.
2882         if (defined $cgi->http('HTTP_ACCEPT') &&
2883             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
2884             $cgi->Accept('application/xhtml+xml') != 0) {
2885                 $content_type = 'application/xhtml+xml';
2886         } else {
2887                 $content_type = 'text/html';
2888         }
2889         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
2890                            -status=> $status, -expires => $expires);
2891         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
2892         print <<EOF;
2893 <?xml version="1.0" encoding="utf-8"?>
2894 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
2895 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
2896 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
2897 <!-- git core binaries version $git_version -->
2898 <head>
2899 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
2900 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
2901 <meta name="robots" content="index, nofollow"/>
2902 <title>$title</title>
2903 EOF
2904 # print out each stylesheet that exist
2905         if (defined $stylesheet) {
2906 #provides backwards capability for those people who define style sheet in a config file
2907                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
2908         } else {
2909                 foreach my $stylesheet (@stylesheets) {
2910                         next unless $stylesheet;
2911                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
2912                 }
2913         }
2914         if (defined $project) {
2915                 my %href_params = get_feed_info();
2916                 if (!exists $href_params{'-title'}) {
2917                         $href_params{'-title'} = 'log';
2918                 }
2919
2920                 foreach my $format qw(RSS Atom) {
2921                         my $type = lc($format);
2922                         my %link_attr = (
2923                                 '-rel' => 'alternate',
2924                                 '-title' => "$project - $href_params{'-title'} - $format feed",
2925                                 '-type' => "application/$type+xml"
2926                         );
2927
2928                         $href_params{'action'} = $type;
2929                         $link_attr{'-href'} = href(%href_params);
2930                         print "<link ".
2931                               "rel=\"$link_attr{'-rel'}\" ".
2932                               "title=\"$link_attr{'-title'}\" ".
2933                               "href=\"$link_attr{'-href'}\" ".
2934                               "type=\"$link_attr{'-type'}\" ".
2935                               "/>\n";
2936
2937                         $href_params{'extra_options'} = '--no-merges';
2938                         $link_attr{'-href'} = href(%href_params);
2939                         $link_attr{'-title'} .= ' (no merges)';
2940                         print "<link ".
2941                               "rel=\"$link_attr{'-rel'}\" ".
2942                               "title=\"$link_attr{'-title'}\" ".
2943                               "href=\"$link_attr{'-href'}\" ".
2944                               "type=\"$link_attr{'-type'}\" ".
2945                               "/>\n";
2946                 }
2947
2948         } else {
2949                 printf('<link rel="alternate" title="%s projects list" '.
2950                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
2951                        $site_name, href(project=>undef, action=>"project_index"));
2952                 printf('<link rel="alternate" title="%s projects feeds" '.
2953                        'href="%s" type="text/x-opml" />'."\n",
2954                        $site_name, href(project=>undef, action=>"opml"));
2955         }
2956         if (defined $favicon) {
2957                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png" />\n);
2958         }
2959
2960         print "</head>\n" .
2961               "<body>\n";
2962
2963         if (-f $site_header) {
2964                 insert_file($site_header);
2965         }
2966
2967         print "<div class=\"page_header\">\n" .
2968               $cgi->a({-href => esc_url($logo_url),
2969                        -title => $logo_label},
2970                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
2971         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
2972         if (defined $project) {
2973                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
2974                 if (defined $action) {
2975                         print " / $action";
2976                 }
2977                 print "\n";
2978         }
2979         print "</div>\n";
2980
2981         my $have_search = gitweb_check_feature('search');
2982         if (defined $project && $have_search) {
2983                 if (!defined $searchtext) {
2984                         $searchtext = "";
2985                 }
2986                 my $search_hash;
2987                 if (defined $hash_base) {
2988                         $search_hash = $hash_base;
2989                 } elsif (defined $hash) {
2990                         $search_hash = $hash;
2991                 } else {
2992                         $search_hash = "HEAD";
2993                 }
2994                 my $action = $my_uri;
2995                 my $use_pathinfo = gitweb_check_feature('pathinfo');
2996                 if ($use_pathinfo) {
2997                         $action .= "/".esc_url($project);
2998                 }
2999                 print $cgi->startform(-method => "get", -action => $action) .
3000                       "<div class=\"search\">\n" .
3001                       (!$use_pathinfo &&
3002                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3003                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3004                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3005                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3006                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3007                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3008                       " search:\n",
3009                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3010                       "<span title=\"Extended regular expression\">" .
3011                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3012                                      -checked => $search_use_regexp) .
3013                       "</span>" .
3014                       "</div>" .
3015                       $cgi->end_form() . "\n";
3016         }
3017 }
3018
3019 sub git_footer_html {
3020         my $feed_class = 'rss_logo';
3021
3022         print "<div class=\"page_footer\">\n";
3023         if (defined $project) {
3024                 my $descr = git_get_project_description($project);
3025                 if (defined $descr) {
3026                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3027                 }
3028
3029                 my %href_params = get_feed_info();
3030                 if (!%href_params) {
3031                         $feed_class .= ' generic';
3032                 }
3033                 $href_params{'-title'} ||= 'log';
3034
3035                 foreach my $format qw(RSS Atom) {
3036                         $href_params{'action'} = lc($format);
3037                         print $cgi->a({-href => href(%href_params),
3038                                       -title => "$href_params{'-title'} $format feed",
3039                                       -class => $feed_class}, $format)."\n";
3040                 }
3041
3042         } else {
3043                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3044                               -class => $feed_class}, "OPML") . " ";
3045                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3046                               -class => $feed_class}, "TXT") . "\n";
3047         }
3048         print "</div>\n"; # class="page_footer"
3049
3050         if (-f $site_footer) {
3051                 insert_file($site_footer);
3052         }
3053
3054         print "</body>\n" .
3055               "</html>";
3056 }
3057
3058 # die_error(<http_status_code>, <error_message>)
3059 # Example: die_error(404, 'Hash not found')
3060 # By convention, use the following status codes (as defined in RFC 2616):
3061 # 400: Invalid or missing CGI parameters, or
3062 #      requested object exists but has wrong type.
3063 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3064 #      this server or project.
3065 # 404: Requested object/revision/project doesn't exist.
3066 # 500: The server isn't configured properly, or
3067 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3068 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3069 sub die_error {
3070         my $status = shift || 500;
3071         my $error = shift || "Internal server error";
3072
3073         my %http_responses = (400 => '400 Bad Request',
3074                               403 => '403 Forbidden',
3075                               404 => '404 Not Found',
3076                               500 => '500 Internal Server Error');
3077         git_header_html($http_responses{$status});
3078         print <<EOF;
3079 <div class="page_body">
3080 <br /><br />
3081 $status - $error
3082 <br />
3083 </div>
3084 EOF
3085         git_footer_html();
3086         exit;
3087 }
3088
3089 ## ----------------------------------------------------------------------
3090 ## functions printing or outputting HTML: navigation
3091
3092 sub git_print_page_nav {
3093         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3094         $extra = '' if !defined $extra; # pager or formats
3095
3096         my @navs = qw(summary shortlog log commit commitdiff tree);
3097         if ($suppress) {
3098                 @navs = grep { $_ ne $suppress } @navs;
3099         }
3100
3101         my %arg = map { $_ => {action=>$_} } @navs;
3102         if (defined $head) {
3103                 for (qw(commit commitdiff)) {
3104                         $arg{$_}{'hash'} = $head;
3105                 }
3106                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3107                         for (qw(shortlog log)) {
3108                                 $arg{$_}{'hash'} = $head;
3109                         }
3110                 }
3111         }
3112
3113         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3114         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3115
3116         my @actions = gitweb_get_feature('actions');
3117         my %repl = (
3118                 '%' => '%',
3119                 'n' => $project,         # project name
3120                 'f' => $git_dir,         # project path within filesystem
3121                 'h' => $treehead || '',  # current hash ('h' parameter)
3122                 'b' => $treebase || '',  # hash base ('hb' parameter)
3123         );
3124         while (@actions) {
3125                 my ($label, $link, $pos) = splice(@actions,0,3);
3126                 # insert
3127                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3128                 # munch munch
3129                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3130                 $arg{$label}{'_href'} = $link;
3131         }
3132
3133         print "<div class=\"page_nav\">\n" .
3134                 (join " | ",
3135                  map { $_ eq $current ?
3136                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3137                  } @navs);
3138         print "<br/>\n$extra<br/>\n" .
3139               "</div>\n";
3140 }
3141
3142 sub format_paging_nav {
3143         my ($action, $hash, $head, $page, $has_next_link) = @_;
3144         my $paging_nav;
3145
3146
3147         if ($hash ne $head || $page) {
3148                 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
3149         } else {
3150                 $paging_nav .= "HEAD";
3151         }
3152
3153         if ($page > 0) {
3154                 $paging_nav .= " &sdot; " .
3155                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3156                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3157         } else {
3158                 $paging_nav .= " &sdot; prev";
3159         }
3160
3161         if ($has_next_link) {
3162                 $paging_nav .= " &sdot; " .
3163                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3164                                  -accesskey => "n", -title => "Alt-n"}, "next");
3165         } else {
3166                 $paging_nav .= " &sdot; next";
3167         }
3168
3169         return $paging_nav;
3170 }
3171
3172 ## ......................................................................
3173 ## functions printing or outputting HTML: div
3174
3175 sub git_print_header_div {
3176         my ($action, $title, $hash, $hash_base) = @_;
3177         my %args = ();
3178
3179         $args{'action'} = $action;
3180         $args{'hash'} = $hash if $hash;
3181         $args{'hash_base'} = $hash_base if $hash_base;
3182
3183         print "<div class=\"header\">\n" .
3184               $cgi->a({-href => href(%args), -class => "title"},
3185               $title ? $title : $action) .
3186               "\n</div>\n";
3187 }
3188
3189 #sub git_print_authorship (\%) {
3190 sub git_print_authorship {
3191         my $co = shift;
3192
3193         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3194         print "<div class=\"author_date\">" .
3195               esc_html($co->{'author_name'}) .
3196               " [$ad{'rfc2822'}";
3197         if ($ad{'hour_local'} < 6) {
3198                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3199                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3200         } else {
3201                 printf(" (%02d:%02d %s)",
3202                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3203         }
3204         print "]</div>\n";
3205 }
3206
3207 sub git_print_page_path {
3208         my $name = shift;
3209         my $type = shift;
3210         my $hb = shift;
3211
3212
3213         print "<div class=\"page_path\">";
3214         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3215                       -title => 'tree root'}, to_utf8("[$project]"));
3216         print " / ";
3217         if (defined $name) {
3218                 my @dirname = split '/', $name;
3219                 my $basename = pop @dirname;
3220                 my $fullname = '';
3221
3222                 foreach my $dir (@dirname) {
3223                         $fullname .= ($fullname ? '/' : '') . $dir;
3224                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
3225                                                      hash_base=>$hb),
3226                                       -title => $fullname}, esc_path($dir));
3227                         print " / ";
3228                 }
3229                 if (defined $type && $type eq 'blob') {
3230                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
3231                                                      hash_base=>$hb),
3232                                       -title => $name}, esc_path($basename));
3233                 } elsif (defined $type && $type eq 'tree') {
3234                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
3235                                                      hash_base=>$hb),
3236                                       -title => $name}, esc_path($basename));
3237                         print " / ";
3238                 } else {
3239                         print esc_path($basename);
3240                 }
3241         }
3242         print "<br/></div>\n";
3243 }
3244
3245 # sub git_print_log (\@;%) {
3246 sub git_print_log ($;%) {
3247         my $log = shift;
3248         my %opts = @_;
3249
3250         if ($opts{'-remove_title'}) {
3251                 # remove title, i.e. first line of log
3252                 shift @$log;
3253         }
3254         # remove leading empty lines
3255         while (defined $log->[0] && $log->[0] eq "") {
3256                 shift @$log;
3257         }
3258
3259         # print log
3260         my $signoff = 0;
3261         my $empty = 0;
3262         foreach my $line (@$log) {
3263                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
3264                         $signoff = 1;
3265                         $empty = 0;
3266                         if (! $opts{'-remove_signoff'}) {
3267                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
3268                                 next;
3269                         } else {
3270                                 # remove signoff lines
3271                                 next;
3272                         }
3273                 } else {
3274                         $signoff = 0;
3275                 }
3276
3277                 # print only one empty line
3278                 # do not print empty line after signoff
3279                 if ($line eq "") {
3280                         next if ($empty || $signoff);
3281                         $empty = 1;
3282                 } else {
3283                         $empty = 0;
3284                 }
3285
3286                 print format_log_line_html($line) . "<br/>\n";
3287         }
3288
3289         if ($opts{'-final_empty_line'}) {
3290                 # end with single empty line
3291                 print "<br/>\n" unless $empty;
3292         }
3293 }
3294
3295 # return link target (what link points to)
3296 sub git_get_link_target {
3297         my $hash = shift;
3298         my $link_target;
3299
3300         # read link
3301         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3302                 or return;
3303         {
3304                 local $/;
3305                 $link_target = <$fd>;
3306         }
3307         close $fd
3308                 or return;
3309
3310         return $link_target;
3311 }
3312
3313 # given link target, and the directory (basedir) the link is in,
3314 # return target of link relative to top directory (top tree);
3315 # return undef if it is not possible (including absolute links).
3316 sub normalize_link_target {
3317         my ($link_target, $basedir, $hash_base) = @_;
3318
3319         # we can normalize symlink target only if $hash_base is provided
3320         return unless $hash_base;
3321
3322         # absolute symlinks (beginning with '/') cannot be normalized
3323         return if (substr($link_target, 0, 1) eq '/');
3324
3325         # normalize link target to path from top (root) tree (dir)
3326         my $path;
3327         if ($basedir) {
3328                 $path = $basedir . '/' . $link_target;
3329         } else {
3330                 # we are in top (root) tree (dir)
3331                 $path = $link_target;
3332         }
3333
3334         # remove //, /./, and /../
3335         my @path_parts;
3336         foreach my $part (split('/', $path)) {
3337                 # discard '.' and ''
3338                 next if (!$part || $part eq '.');
3339                 # handle '..'
3340                 if ($part eq '..') {
3341                         if (@path_parts) {
3342                                 pop @path_parts;
3343                         } else {
3344                                 # link leads outside repository (outside top dir)
3345                                 return;
3346                         }
3347                 } else {
3348                         push @path_parts, $part;
3349                 }
3350         }
3351         $path = join('/', @path_parts);
3352
3353         return $path;
3354 }
3355
3356 # print tree entry (row of git_tree), but without encompassing <tr> element
3357 sub git_print_tree_entry {
3358         my ($t, $basedir, $hash_base, $have_blame) = @_;
3359
3360         my %base_key = ();
3361         $base_key{'hash_base'} = $hash_base if defined $hash_base;
3362
3363         # The format of a table row is: mode list link.  Where mode is
3364         # the mode of the entry, list is the name of the entry, an href,
3365         # and link is the action links of the entry.
3366
3367         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
3368         if ($t->{'type'} eq "blob") {
3369                 print "<td class=\"list\">" .
3370                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
3371                                                file_name=>"$basedir$t->{'name'}", %base_key),
3372                                 -class => "list"}, esc_path($t->{'name'}));
3373                 if (S_ISLNK(oct $t->{'mode'})) {
3374                         my $link_target = git_get_link_target($t->{'hash'});
3375                         if ($link_target) {
3376                                 my $norm_target = normalize_link_target($link_target, $basedir, $hash_base);
3377                                 if (defined $norm_target) {
3378                                         print " -> " .
3379                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
3380                                                                      file_name=>$norm_target),
3381                                                        -title => $norm_target}, esc_path($link_target));
3382                                 } else {
3383                                         print " -> " . esc_path($link_target);
3384                                 }
3385                         }
3386                 }
3387                 print "</td>\n";
3388                 print "<td class=\"link\">";
3389                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
3390                                              file_name=>"$basedir$t->{'name'}", %base_key)},
3391                               "blob");
3392                 if ($have_blame) {
3393                         print " | " .
3394                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
3395                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
3396                                       "blame");
3397                 }
3398                 if (defined $hash_base) {
3399                         print " | " .
3400                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3401                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
3402                                       "history");
3403                 }
3404                 print " | " .
3405                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
3406                                                file_name=>"$basedir$t->{'name'}")},
3407                                 "raw");
3408                 print "</td>\n";
3409
3410         } elsif ($t->{'type'} eq "tree") {
3411                 print "<td class=\"list\">";
3412                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
3413                                              file_name=>"$basedir$t->{'name'}", %base_key)},
3414                               esc_path($t->{'name'}));
3415                 print "</td>\n";
3416                 print "<td class=\"link\">";
3417                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
3418                                              file_name=>"$basedir$t->{'name'}", %base_key)},
3419                               "tree");
3420                 if (defined $hash_base) {
3421                         print " | " .
3422                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3423                                                      file_name=>"$basedir$t->{'name'}")},
3424                                       "history");
3425                 }
3426                 print "</td>\n";
3427         } else {
3428                 # unknown object: we can only present history for it
3429                 # (this includes 'commit' object, i.e. submodule support)
3430                 print "<td class=\"list\">" .
3431                       esc_path($t->{'name'}) .
3432                       "</td>\n";
3433                 print "<td class=\"link\">";
3434                 if (defined $hash_base) {
3435                         print $cgi->a({-href => href(action=>"history",
3436                                                      hash_base=>$hash_base,
3437                                                      file_name=>"$basedir$t->{'name'}")},
3438                                       "history");
3439                 }
3440                 print "</td>\n";
3441         }
3442 }
3443
3444 ## ......................................................................
3445 ## functions printing large fragments of HTML
3446
3447 # get pre-image filenames for merge (combined) diff
3448 sub fill_from_file_info {
3449         my ($diff, @parents) = @_;
3450
3451         $diff->{'from_file'} = [ ];
3452         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
3453         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
3454                 if ($diff->{'status'}[$i] eq 'R' ||
3455                     $diff->{'status'}[$i] eq 'C') {
3456                         $diff->{'from_file'}[$i] =
3457                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
3458                 }
3459         }
3460
3461         return $diff;
3462 }
3463
3464 # is current raw difftree line of file deletion
3465 sub is_deleted {
3466         my $diffinfo = shift;
3467
3468         return $diffinfo->{'to_id'} eq ('0' x 40);
3469 }
3470
3471 # does patch correspond to [previous] difftree raw line
3472 # $diffinfo  - hashref of parsed raw diff format
3473 # $patchinfo - hashref of parsed patch diff format
3474 #              (the same keys as in $diffinfo)
3475 sub is_patch_split {
3476         my ($diffinfo, $patchinfo) = @_;
3477
3478         return defined $diffinfo && defined $patchinfo
3479                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
3480 }
3481
3482
3483 sub git_difftree_body {
3484         my ($difftree, $hash, @parents) = @_;
3485         my ($parent) = $parents[0];
3486         my $have_blame = gitweb_check_feature('blame');
3487         print "<div class=\"list_head\">\n";
3488         if ($#{$difftree} > 10) {
3489                 print(($#{$difftree} + 1) . " files changed:\n");
3490         }
3491         print "</div>\n";
3492
3493         print "<table class=\"" .
3494               (@parents > 1 ? "combined " : "") .
3495               "diff_tree\">\n";
3496
3497         # header only for combined diff in 'commitdiff' view
3498         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
3499         if ($has_header) {
3500                 # table header
3501                 print "<thead><tr>\n" .
3502                        "<th></th><th></th>\n"; # filename, patchN link
3503                 for (my $i = 0; $i < @parents; $i++) {
3504                         my $par = $parents[$i];
3505                         print "<th>" .
3506                               $cgi->a({-href => href(action=>"commitdiff",
3507                                                      hash=>$hash, hash_parent=>$par),
3508                                        -title => 'commitdiff to parent number ' .
3509                                                   ($i+1) . ': ' . substr($par,0,7)},
3510                                       $i+1) .
3511                               "&nbsp;</th>\n";
3512                 }
3513                 print "</tr></thead>\n<tbody>\n";
3514         }
3515
3516         my $alternate = 1;
3517         my $patchno = 0;
3518         foreach my $line (@{$difftree}) {
3519                 my $diff = parsed_difftree_line($line);
3520
3521                 if ($alternate) {
3522                         print "<tr class=\"dark\">\n";
3523                 } else {
3524                         print "<tr class=\"light\">\n";
3525                 }
3526                 $alternate ^= 1;
3527
3528                 if (exists $diff->{'nparents'}) { # combined diff
3529
3530                         fill_from_file_info($diff, @parents)
3531                                 unless exists $diff->{'from_file'};
3532
3533                         if (!is_deleted($diff)) {
3534                                 # file exists in the result (child) commit
3535                                 print "<td>" .
3536                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3537                                                              file_name=>$diff->{'to_file'},
3538                                                              hash_base=>$hash),
3539                                               -class => "list"}, esc_path($diff->{'to_file'})) .
3540                                       "</td>\n";
3541                         } else {
3542                                 print "<td>" .
3543                                       esc_path($diff->{'to_file'}) .
3544                                       "</td>\n";
3545                         }
3546
3547                         if ($action eq 'commitdiff') {
3548                                 # link to patch
3549                                 $patchno++;
3550                                 print "<td class=\"link\">" .
3551                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
3552                                       " | " .
3553                                       "</td>\n";
3554                         }
3555
3556                         my $has_history = 0;
3557                         my $not_deleted = 0;
3558                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
3559                                 my $hash_parent = $parents[$i];
3560                                 my $from_hash = $diff->{'from_id'}[$i];
3561                                 my $from_path = $diff->{'from_file'}[$i];
3562                                 my $status = $diff->{'status'}[$i];
3563
3564                                 $has_history ||= ($status ne 'A');
3565                                 $not_deleted ||= ($status ne 'D');
3566
3567                                 if ($status eq 'A') {
3568                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
3569                                 } elsif ($status eq 'D') {
3570                                         print "<td class=\"link\">" .
3571                                               $cgi->a({-href => href(action=>"blob",
3572                                                                      hash_base=>$hash,
3573                                                                      hash=>$from_hash,
3574                                                                      file_name=>$from_path)},
3575                                                       "blob" . ($i+1)) .
3576                                               " | </td>\n";
3577                                 } else {
3578                                         if ($diff->{'to_id'} eq $from_hash) {
3579                                                 print "<td class=\"link nochange\">";
3580                                         } else {
3581                                                 print "<td class=\"link\">";
3582                                         }
3583                                         print $cgi->a({-href => href(action=>"blobdiff",
3584                                                                      hash=>$diff->{'to_id'},
3585                                                                      hash_parent=>$from_hash,
3586                                                                      hash_base=>$hash,
3587                                                                      hash_parent_base=>$hash_parent,
3588                                                                      file_name=>$diff->{'to_file'},
3589                                                                      file_parent=>$from_path)},
3590                                                       "diff" . ($i+1)) .
3591                                               " | </td>\n";
3592                                 }
3593                         }
3594
3595                         print "<td class=\"link\">";
3596                         if ($not_deleted) {
3597                                 print $cgi->a({-href => href(action=>"blob",
3598                                                              hash=>$diff->{'to_id'},
3599                                                              file_name=>$diff->{'to_file'},
3600                                                              hash_base=>$hash)},
3601                                               "blob");
3602                                 print " | " if ($has_history);
3603                         }
3604                         if ($has_history) {
3605                                 print $cgi->a({-href => href(action=>"history",
3606                                                              file_name=>$diff->{'to_file'},
3607                                                              hash_base=>$hash)},
3608                                               "history");
3609                         }
3610                         print "</td>\n";
3611
3612                         print "</tr>\n";
3613                         next; # instead of 'else' clause, to avoid extra indent
3614                 }
3615                 # else ordinary diff
3616
3617                 my ($to_mode_oct, $to_mode_str, $to_file_type);
3618                 my ($from_mode_oct, $from_mode_str, $from_file_type);
3619                 if ($diff->{'to_mode'} ne ('0' x 6)) {
3620                         $to_mode_oct = oct $diff->{'to_mode'};
3621                         if (S_ISREG($to_mode_oct)) { # only for regular file
3622                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
3623                         }
3624                         $to_file_type = file_type($diff->{'to_mode'});
3625                 }
3626                 if ($diff->{'from_mode'} ne ('0' x 6)) {
3627                         $from_mode_oct = oct $diff->{'from_mode'};
3628                         if (S_ISREG($to_mode_oct)) { # only for regular file
3629                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
3630                         }
3631                         $from_file_type = file_type($diff->{'from_mode'});
3632                 }
3633
3634                 if ($diff->{'status'} eq "A") { # created
3635                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
3636                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
3637                         $mode_chng   .= "]</span>";
3638                         print "<td>";
3639                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3640                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
3641                                       -class => "list"}, esc_path($diff->{'file'}));
3642                         print "</td>\n";
3643                         print "<td>$mode_chng</td>\n";
3644                         print "<td class=\"link\">";
3645                         if ($action eq 'commitdiff') {
3646                                 # link to patch
3647                                 $patchno++;
3648                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
3649                                 print " | ";
3650                         }
3651                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3652                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
3653                                       "blob");
3654                         print "</td>\n";
3655
3656                 } elsif ($diff->{'status'} eq "D") { # deleted
3657                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
3658                         print "<td>";
3659                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
3660                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
3661                                        -class => "list"}, esc_path($diff->{'file'}));
3662                         print "</td>\n";
3663                         print "<td>$mode_chng</td>\n";
3664                         print "<td class=\"link\">";
3665                         if ($action eq 'commitdiff') {
3666                                 # link to patch
3667                                 $patchno++;
3668                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
3669                                 print " | ";
3670                         }
3671                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
3672                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
3673                                       "blob") . " | ";
3674                         if ($have_blame) {
3675                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
3676                                                              file_name=>$diff->{'file'})},
3677                                               "blame") . " | ";
3678                         }
3679                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
3680                                                      file_name=>$diff->{'file'})},
3681                                       "history");
3682                         print "</td>\n";
3683
3684                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
3685                         my $mode_chnge = "";
3686                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
3687                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
3688                                 if ($from_file_type ne $to_file_type) {
3689                                         $mode_chnge .= " from $from_file_type to $to_file_type";
3690                                 }
3691                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
3692                                         if ($from_mode_str && $to_mode_str) {
3693                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
3694                                         } elsif ($to_mode_str) {
3695                                                 $mode_chnge .= " mode: $to_mode_str";
3696                                         }
3697                                 }
3698                                 $mode_chnge .= "]</span>\n";
3699                         }
3700                         print "<td>";
3701                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3702                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
3703                                       -class => "list"}, esc_path($diff->{'file'}));
3704                         print "</td>\n";
3705                         print "<td>$mode_chnge</td>\n";
3706                         print "<td class=\"link\">";
3707                         if ($action eq 'commitdiff') {
3708                                 # link to patch
3709                                 $patchno++;
3710                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
3711                                       " | ";
3712                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
3713                                 # "commit" view and modified file (not onlu mode changed)
3714                                 print $cgi->a({-href => href(action=>"blobdiff",
3715                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
3716                                                              hash_base=>$hash, hash_parent_base=>$parent,
3717                                                              file_name=>$diff->{'file'})},
3718                                               "diff") .
3719                                       " | ";
3720                         }
3721                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3722                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
3723                                        "blob") . " | ";
3724                         if ($have_blame) {
3725                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
3726                                                              file_name=>$diff->{'file'})},
3727                                               "blame") . " | ";
3728                         }
3729                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
3730                                                      file_name=>$diff->{'file'})},
3731                                       "history");
3732                         print "</td>\n";
3733
3734                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
3735                         my %status_name = ('R' => 'moved', 'C' => 'copied');
3736                         my $nstatus = $status_name{$diff->{'status'}};
3737                         my $mode_chng = "";
3738                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
3739                                 # mode also for directories, so we cannot use $to_mode_str
3740                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
3741                         }
3742                         print "<td>" .
3743                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
3744                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
3745                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
3746                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
3747                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
3748                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
3749                                       -class => "list"}, esc_path($diff->{'from_file'})) .
3750                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
3751                               "<td class=\"link\">";
3752                         if ($action eq 'commitdiff') {
3753                                 # link to patch
3754                                 $patchno++;
3755                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
3756                                       " | ";
3757                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
3758                                 # "commit" view and modified file (not only pure rename or copy)
3759                                 print $cgi->a({-href => href(action=>"blobdiff",
3760                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
3761                                                              hash_base=>$hash, hash_parent_base=>$parent,
3762                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
3763                                               "diff") .
3764                                       " | ";
3765                         }
3766                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3767                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
3768                                       "blob") . " | ";
3769                         if ($have_blame) {
3770                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
3771                                                              file_name=>$diff->{'to_file'})},
3772                                               "blame") . " | ";
3773                         }
3774                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
3775                                                     file_name=>$diff->{'to_file'})},
3776                                       "history");
3777                         print "</td>\n";
3778
3779                 } # we should not encounter Unmerged (U) or Unknown (X) status
3780                 print "</tr>\n";
3781         }
3782         print "</tbody>" if $has_header;
3783         print "</table>\n";
3784 }
3785
3786 sub git_patchset_body {
3787         my ($fd, $difftree, $hash, @hash_parents) = @_;
3788         my ($hash_parent) = $hash_parents[0];
3789
3790         my $is_combined = (@hash_parents > 1);
3791         my $patch_idx = 0;
3792         my $patch_number = 0;
3793         my $patch_line;
3794         my $diffinfo;
3795         my $to_name;
3796         my (%from, %to);
3797
3798         print "<div class=\"patchset\">\n";
3799
3800         # skip to first patch
3801         while ($patch_line = <$fd>) {
3802                 chomp $patch_line;
3803
3804                 last if ($patch_line =~ m/^diff /);
3805         }
3806
3807  PATCH:
3808         while ($patch_line) {
3809
3810                 # parse "git diff" header line
3811                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
3812                         # $1 is from_name, which we do not use
3813                         $to_name = unquote($2);
3814                         $to_name =~ s!^b/!!;
3815                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
3816                         # $1 is 'cc' or 'combined', which we do not use
3817                         $to_name = unquote($2);
3818                 } else {
3819                         $to_name = undef;
3820                 }
3821
3822                 # check if current patch belong to current raw line
3823                 # and parse raw git-diff line if needed
3824                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
3825                         # this is continuation of a split patch
3826                         print "<div class=\"patch cont\">\n";
3827                 } else {
3828                         # advance raw git-diff output if needed
3829                         $patch_idx++ if defined $diffinfo;
3830
3831                         # read and prepare patch information
3832                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
3833
3834                         # compact combined diff output can have some patches skipped
3835                         # find which patch (using pathname of result) we are at now;
3836                         if ($is_combined) {
3837                                 while ($to_name ne $diffinfo->{'to_file'}) {
3838                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
3839                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
3840                                               "</div>\n";  # class="patch"
3841
3842                                         $patch_idx++;
3843                                         $patch_number++;
3844
3845                                         last if $patch_idx > $#$difftree;
3846                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
3847                                 }
3848                         }
3849
3850                         # modifies %from, %to hashes
3851                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
3852
3853                         # this is first patch for raw difftree line with $patch_idx index
3854                         # we index @$difftree array from 0, but number patches from 1
3855                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
3856                 }
3857
3858                 # git diff header
3859                 #assert($patch_line =~ m/^diff /) if DEBUG;
3860                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
3861                 $patch_number++;
3862                 # print "git diff" header
3863                 print format_git_diff_header_line($patch_line, $diffinfo,
3864                                                   \%from, \%to);
3865
3866                 # print extended diff header
3867                 print "<div class=\"diff extended_header\">\n";
3868         EXTENDED_HEADER:
3869                 while ($patch_line = <$fd>) {
3870                         chomp $patch_line;
3871
3872                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
3873
3874                         print format_extended_diff_header_line($patch_line, $diffinfo,
3875                                                                \%from, \%to);
3876                 }
3877                 print "</div>\n"; # class="diff extended_header"
3878
3879                 # from-file/to-file diff header
3880                 if (! $patch_line) {
3881                         print "</div>\n"; # class="patch"
3882                         last PATCH;
3883                 }
3884                 next PATCH if ($patch_line =~ m/^diff /);
3885                 #assert($patch_line =~ m/^---/) if DEBUG;
3886
3887                 my $last_patch_line = $patch_line;
3888                 $patch_line = <$fd>;
3889                 chomp $patch_line;
3890                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
3891
3892                 print format_diff_from_to_header($last_patch_line, $patch_line,
3893                                                  $diffinfo, \%from, \%to,
3894                                                  @hash_parents);
3895
3896                 # the patch itself
3897         LINE:
3898                 while ($patch_line = <$fd>) {
3899                         chomp $patch_line;
3900
3901                         next PATCH if ($patch_line =~ m/^diff /);
3902
3903                         print format_diff_line($patch_line, \%from, \%to);
3904                 }
3905
3906         } continue {
3907                 print "</div>\n"; # class="patch"
3908         }
3909
3910         # for compact combined (--cc) format, with chunk and patch simpliciaction
3911         # patchset might be empty, but there might be unprocessed raw lines
3912         for (++$patch_idx if $patch_number > 0;
3913              $patch_idx < @$difftree;
3914              ++$patch_idx) {
3915                 # read and prepare patch information
3916                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
3917
3918                 # generate anchor for "patch" links in difftree / whatchanged part
3919                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
3920                       format_diff_cc_simplified($diffinfo, @hash_parents) .
3921                       "</div>\n";  # class="patch"
3922
3923                 $patch_number++;
3924         }
3925
3926         if ($patch_number == 0) {
3927                 if (@hash_parents > 1) {
3928                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
3929                 } else {
3930                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
3931                 }
3932         }
3933
3934         print "</div>\n"; # class="patchset"
3935 }
3936
3937 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
3938
3939 # fills project list info (age, description, owner, forks) for each
3940 # project in the list, removing invalid projects from returned list
3941 # NOTE: modifies $projlist, but does not remove entries from it
3942 sub fill_project_list_info {
3943         my ($projlist, $check_forks) = @_;
3944         my @projects;
3945
3946         my $show_ctags = gitweb_check_feature('ctags');
3947  PROJECT:
3948         foreach my $pr (@$projlist) {
3949                 my (@activity) = git_get_last_activity($pr->{'path'});
3950                 unless (@activity) {
3951                         next PROJECT;
3952                 }
3953                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
3954                 if (!defined $pr->{'descr'}) {
3955                         my $descr = git_get_project_description($pr->{'path'}) || "";
3956                         $descr = to_utf8($descr);
3957                         $pr->{'descr_long'} = $descr;
3958                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
3959                 }
3960                 if (!defined $pr->{'owner'}) {
3961                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
3962                 }
3963                 if ($check_forks) {
3964                         my $pname = $pr->{'path'};
3965                         if (($pname =~ s/\.git$//) &&
3966                             ($pname !~ /\/$/) &&
3967                             (-d "$projectroot/$pname")) {
3968                                 $pr->{'forks'} = "-d $projectroot/$pname";
3969                         }       else {
3970                                 $pr->{'forks'} = 0;
3971                         }
3972                 }
3973                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
3974                 push @projects, $pr;
3975         }
3976
3977         return @projects;
3978 }
3979
3980 # print 'sort by' <th> element, generating 'sort by $name' replay link
3981 # if that order is not selected
3982 sub print_sort_th {
3983         my ($name, $order, $header) = @_;
3984         $header ||= ucfirst($name);
3985
3986         if ($order eq $name) {
3987                 print "<th>$header</th>\n";
3988         } else {
3989                 print "<th>" .
3990                       $cgi->a({-href => href(-replay=>1, order=>$name),
3991                                -class => "header"}, $header) .
3992                       "</th>\n";
3993         }
3994 }
3995
3996 sub git_project_list_body {
3997         # actually uses global variable $project
3998         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
3999
4000         my $check_forks = gitweb_check_feature('forks');
4001         my @projects = fill_project_list_info($projlist, $check_forks);
4002
4003         $order ||= $default_projects_order;
4004         $from = 0 unless defined $from;
4005         $to = $#projects if (!defined $to || $#projects < $to);
4006
4007         my %order_info = (
4008                 project => { key => 'path', type => 'str' },
4009                 descr => { key => 'descr_long', type => 'str' },
4010                 owner => { key => 'owner', type => 'str' },
4011                 age => { key => 'age', type => 'num' }
4012         );
4013         my $oi = $order_info{$order};
4014         if ($oi->{'type'} eq 'str') {
4015                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4016         } else {
4017                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4018         }
4019
4020         my $show_ctags = gitweb_check_feature('ctags');
4021         if ($show_ctags) {
4022                 my %ctags;
4023                 foreach my $p (@projects) {
4024                         foreach my $ct (keys %{$p->{'ctags'}}) {
4025                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4026                         }
4027                 }
4028                 my $cloud = git_populate_project_tagcloud(\%ctags);
4029                 print git_show_project_tagcloud($cloud, 64);
4030         }
4031
4032         print "<table class=\"project_list\">\n";
4033         unless ($no_header) {
4034                 print "<tr>\n";
4035                 if ($check_forks) {
4036                         print "<th></th>\n";
4037                 }
4038                 print_sort_th('project', $order, 'Project');
4039                 print_sort_th('descr', $order, 'Description');
4040                 print_sort_th('owner', $order, 'Owner');
4041                 print_sort_th('age', $order, 'Last Change');
4042                 print "<th></th>\n" . # for links
4043                       "</tr>\n";
4044         }
4045         my $alternate = 1;
4046         my $tagfilter = $cgi->param('by_tag');
4047         for (my $i = $from; $i <= $to; $i++) {
4048                 my $pr = $projects[$i];
4049
4050                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4051                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4052                         and not $pr->{'descr_long'} =~ /$searchtext/;
4053                 # Weed out forks or non-matching entries of search
4054                 if ($check_forks) {
4055                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4056                         $forkbase="^$forkbase" if $forkbase;
4057                         next if not $searchtext and not $tagfilter and $show_ctags
4058                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4059                 }
4060
4061                 if ($alternate) {
4062                         print "<tr class=\"dark\">\n";
4063                 } else {
4064                         print "<tr class=\"light\">\n";
4065                 }
4066                 $alternate ^= 1;
4067                 if ($check_forks) {
4068                         print "<td>";
4069                         if ($pr->{'forks'}) {
4070                                 print "<!-- $pr->{'forks'} -->\n";
4071                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4072                         }
4073                         print "</td>\n";
4074                 }
4075                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4076                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4077                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4078                                         -class => "list", -title => $pr->{'descr_long'}},
4079                                         esc_html($pr->{'descr'})) . "</td>\n" .
4080                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4081                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4082                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4083                       "<td class=\"link\">" .
4084                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4085                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4086                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4087                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4088                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4089                       "</td>\n" .
4090                       "</tr>\n";
4091         }
4092         if (defined $extra) {
4093                 print "<tr>\n";
4094                 if ($check_forks) {
4095                         print "<td></td>\n";
4096                 }
4097                 print "<td colspan=\"5\">$extra</td>\n" .
4098                       "</tr>\n";
4099         }
4100         print "</table>\n";
4101 }
4102
4103 sub git_shortlog_body {
4104         # uses global variable $project
4105         my ($commitlist, $from, $to, $refs, $extra) = @_;
4106
4107         $from = 0 unless defined $from;
4108         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4109
4110         print "<table class=\"shortlog\">\n";
4111         my $alternate = 1;
4112         for (my $i = $from; $i <= $to; $i++) {
4113                 my %co = %{$commitlist->[$i]};
4114                 my $commit = $co{'id'};
4115                 my $ref = format_ref_marker($refs, $commit);
4116                 if ($alternate) {
4117                         print "<tr class=\"dark\">\n";
4118                 } else {
4119                         print "<tr class=\"light\">\n";
4120                 }
4121                 $alternate ^= 1;
4122                 my $author = chop_and_escape_str($co{'author_name'}, 10);
4123                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4124                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4125                       "<td><i>" . $author . "</i></td>\n" .
4126                       "<td>";
4127                 print format_subject_html($co{'title'}, $co{'title_short'},
4128                                           href(action=>"commit", hash=>$commit), $ref);
4129                 print "</td>\n" .
4130                       "<td class=\"link\">" .
4131                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4132                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4133                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4134                 my $snapshot_links = format_snapshot_links($commit);
4135                 if (defined $snapshot_links) {
4136                         print " | " . $snapshot_links;
4137                 }
4138                 print "</td>\n" .
4139                       "</tr>\n";
4140         }
4141         if (defined $extra) {
4142                 print "<tr>\n" .
4143                       "<td colspan=\"4\">$extra</td>\n" .
4144                       "</tr>\n";
4145         }
4146         print "</table>\n";
4147 }
4148
4149 sub git_history_body {
4150         # Warning: assumes constant type (blob or tree) during history
4151         my ($commitlist, $from, $to, $refs, $hash_base, $ftype, $extra) = @_;
4152
4153         $from = 0 unless defined $from;
4154         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4155
4156         print "<table class=\"history\">\n";
4157         my $alternate = 1;
4158         for (my $i = $from; $i <= $to; $i++) {
4159                 my %co = %{$commitlist->[$i]};
4160                 if (!%co) {
4161                         next;
4162                 }
4163                 my $commit = $co{'id'};
4164
4165                 my $ref = format_ref_marker($refs, $commit);
4166
4167                 if ($alternate) {
4168                         print "<tr class=\"dark\">\n";
4169                 } else {
4170                         print "<tr class=\"light\">\n";
4171                 }
4172                 $alternate ^= 1;
4173         # shortlog uses      chop_str($co{'author_name'}, 10)
4174                 my $author = chop_and_escape_str($co{'author_name'}, 15, 3);
4175                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4176                       "<td><i>" . $author . "</i></td>\n" .
4177                       "<td>";
4178                 # originally git_history used chop_str($co{'title'}, 50)
4179                 print format_subject_html($co{'title'}, $co{'title_short'},
4180                                           href(action=>"commit", hash=>$commit), $ref);
4181                 print "</td>\n" .
4182                       "<td class=\"link\">" .
4183                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
4184                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
4185
4186                 if ($ftype eq 'blob') {
4187                         my $blob_current = git_get_hash_by_path($hash_base, $file_name);
4188                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
4189                         if (defined $blob_current && defined $blob_parent &&
4190                                         $blob_current ne $blob_parent) {
4191                                 print " | " .
4192                                         $cgi->a({-href => href(action=>"blobdiff",
4193                                                                hash=>$blob_current, hash_parent=>$blob_parent,
4194                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
4195                                                                file_name=>$file_name)},
4196                                                 "diff to current");
4197                         }
4198                 }
4199                 print "</td>\n" .
4200                       "</tr>\n";
4201         }
4202         if (defined $extra) {
4203                 print "<tr>\n" .
4204                       "<td colspan=\"4\">$extra</td>\n" .
4205                       "</tr>\n";
4206         }
4207         print "</table>\n";
4208 }
4209
4210 sub git_tags_body {
4211         # uses global variable $project
4212         my ($taglist, $from, $to, $extra) = @_;
4213         $from = 0 unless defined $from;
4214         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
4215
4216         print "<table class=\"tags\">\n";
4217         my $alternate = 1;
4218         for (my $i = $from; $i <= $to; $i++) {
4219                 my $entry = $taglist->[$i];
4220                 my %tag = %$entry;
4221                 my $comment = $tag{'subject'};
4222                 my $comment_short;
4223                 if (defined $comment) {
4224                         $comment_short = chop_str($comment, 30, 5);
4225                 }
4226                 if ($alternate) {
4227                         print "<tr class=\"dark\">\n";
4228                 } else {
4229                         print "<tr class=\"light\">\n";
4230                 }
4231                 $alternate ^= 1;
4232                 if (defined $tag{'age'}) {
4233                         print "<td><i>$tag{'age'}</i></td>\n";
4234                 } else {
4235                         print "<td></td>\n";
4236                 }
4237                 print "<td>" .
4238                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
4239                                -class => "list name"}, esc_html($tag{'name'})) .
4240                       "</td>\n" .
4241                       "<td>";
4242                 if (defined $comment) {
4243                         print format_subject_html($comment, $comment_short,
4244                                                   href(action=>"tag", hash=>$tag{'id'}));
4245                 }
4246                 print "</td>\n" .
4247                       "<td class=\"selflink\">";
4248                 if ($tag{'type'} eq "tag") {
4249                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
4250                 } else {
4251                         print "&nbsp;";
4252                 }
4253                 print "</td>\n" .
4254                       "<td class=\"link\">" . " | " .
4255                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
4256                 if ($tag{'reftype'} eq "commit") {
4257                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
4258                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
4259                 } elsif ($tag{'reftype'} eq "blob") {
4260                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
4261                 }
4262                 print "</td>\n" .
4263                       "</tr>";
4264         }
4265         if (defined $extra) {
4266                 print "<tr>\n" .
4267                       "<td colspan=\"5\">$extra</td>\n" .
4268                       "</tr>\n";
4269         }
4270         print "</table>\n";
4271 }
4272
4273 sub git_heads_body {
4274         # uses global variable $project
4275         my ($headlist, $head, $from, $to, $extra) = @_;
4276         $from = 0 unless defined $from;
4277         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
4278
4279         print "<table class=\"heads\">\n";
4280         my $alternate = 1;
4281         for (my $i = $from; $i <= $to; $i++) {
4282                 my $entry = $headlist->[$i];
4283                 my %ref = %$entry;
4284                 my $curr = $ref{'id'} eq $head;
4285                 if ($alternate) {
4286                         print "<tr class=\"dark\">\n";
4287                 } else {
4288                         print "<tr class=\"light\">\n";
4289                 }
4290                 $alternate ^= 1;
4291                 print "<td><i>$ref{'age'}</i></td>\n" .
4292                       ($curr ? "<td class=\"current_head\">" : "<td>") .
4293                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
4294                                -class => "list name"},esc_html($ref{'name'})) .
4295                       "</td>\n" .
4296                       "<td class=\"link\">" .
4297                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
4298                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
4299                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'name'})}, "tree") .
4300                       "</td>\n" .
4301                       "</tr>";
4302         }
4303         if (defined $extra) {
4304                 print "<tr>\n" .
4305                       "<td colspan=\"3\">$extra</td>\n" .
4306                       "</tr>\n";
4307         }
4308         print "</table>\n";
4309 }
4310
4311 sub git_search_grep_body {
4312         my ($commitlist, $from, $to, $extra) = @_;
4313         $from = 0 unless defined $from;
4314         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4315
4316         print "<table class=\"commit_search\">\n";
4317         my $alternate = 1;
4318         for (my $i = $from; $i <= $to; $i++) {
4319                 my %co = %{$commitlist->[$i]};
4320                 if (!%co) {
4321                         next;
4322                 }
4323                 my $commit = $co{'id'};
4324                 if ($alternate) {
4325                         print "<tr class=\"dark\">\n";
4326                 } else {
4327                         print "<tr class=\"light\">\n";
4328                 }
4329                 $alternate ^= 1;
4330                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
4331                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4332                       "<td><i>" . $author . "</i></td>\n" .
4333                       "<td>" .
4334                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4335                                -class => "list subject"},
4336                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
4337                 my $comment = $co{'comment'};
4338                 foreach my $line (@$comment) {
4339                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
4340                                 my ($lead, $match, $trail) = ($1, $2, $3);
4341                                 $match = chop_str($match, 70, 5, 'center');
4342                                 my $contextlen = int((80 - length($match))/2);
4343                                 $contextlen = 30 if ($contextlen > 30);
4344                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
4345                                 $trail = chop_str($trail, $contextlen, 10, 'right');
4346
4347                                 $lead  = esc_html($lead);
4348                                 $match = esc_html($match);
4349                                 $trail = esc_html($trail);
4350
4351                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
4352                         }
4353                 }
4354                 print "</td>\n" .
4355                       "<td class=\"link\">" .
4356                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4357                       " | " .
4358                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
4359                       " | " .
4360                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4361                 print "</td>\n" .
4362                       "</tr>\n";
4363         }
4364         if (defined $extra) {
4365                 print "<tr>\n" .
4366                       "<td colspan=\"3\">$extra</td>\n" .
4367                       "</tr>\n";
4368         }
4369         print "</table>\n";
4370 }
4371
4372 ## ======================================================================
4373 ## ======================================================================
4374 ## actions
4375
4376 sub git_project_list {
4377         my $order = $input_params{'order'};
4378         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
4379                 die_error(400, "Unknown order parameter");
4380         }
4381
4382         my @list = git_get_projects_list();
4383         if (!@list) {
4384                 die_error(404, "No projects found");
4385         }
4386
4387         git_header_html();
4388         if (-f $home_text) {
4389                 print "<div class=\"index_include\">\n";
4390                 insert_file($home_text);
4391                 print "</div>\n";
4392         }
4393         print $cgi->startform(-method => "get") .
4394               "<p class=\"projsearch\">Search:\n" .
4395               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
4396               "</p>" .
4397               $cgi->end_form() . "\n";
4398         git_project_list_body(\@list, $order);
4399         git_footer_html();
4400 }
4401
4402 sub git_forks {
4403         my $order = $input_params{'order'};
4404         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
4405                 die_error(400, "Unknown order parameter");
4406         }
4407
4408         my @list = git_get_projects_list($project);
4409         if (!@list) {
4410                 die_error(404, "No forks found");
4411         }
4412
4413         git_header_html();
4414         git_print_page_nav('','');
4415         git_print_header_div('summary', "$project forks");
4416         git_project_list_body(\@list, $order);
4417         git_footer_html();
4418 }
4419
4420 sub git_project_index {
4421         my @projects = git_get_projects_list($project);
4422
4423         print $cgi->header(
4424                 -type => 'text/plain',
4425                 -charset => 'utf-8',
4426                 -content_disposition => 'inline; filename="index.aux"');
4427
4428         foreach my $pr (@projects) {
4429                 if (!exists $pr->{'owner'}) {
4430                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
4431                 }
4432
4433                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
4434                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
4435                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
4436                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
4437                 $path  =~ s/ /\+/g;
4438                 $owner =~ s/ /\+/g;
4439
4440                 print "$path $owner\n";
4441         }
4442 }
4443
4444 sub git_summary {
4445         my $descr = git_get_project_description($project) || "none";
4446         my %co = parse_commit("HEAD");
4447         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
4448         my $head = $co{'id'};
4449
4450         my $owner = git_get_project_owner($project);
4451
4452         my $refs = git_get_references();
4453         # These get_*_list functions return one more to allow us to see if
4454         # there are more ...
4455         my @taglist  = git_get_tags_list(16);
4456         my @headlist = git_get_heads_list(16);
4457         my @forklist;
4458         my $check_forks = gitweb_check_feature('forks');
4459
4460         if ($check_forks) {
4461                 @forklist = git_get_projects_list($project);
4462         }
4463
4464         git_header_html();
4465         git_print_page_nav('summary','', $head);
4466
4467         print "<div class=\"title\">&nbsp;</div>\n";
4468         print "<table class=\"projects_list\">\n" .
4469               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
4470               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
4471         if (defined $cd{'rfc2822'}) {
4472                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
4473         }
4474
4475         # use per project git URL list in $projectroot/$project/cloneurl
4476         # or make project git URL from git base URL and project name
4477         my $url_tag = "URL";
4478         my @url_list = git_get_project_url_list($project);
4479         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
4480         foreach my $git_url (@url_list) {
4481                 next unless $git_url;
4482                 print "<tr class=\"metadata_url\"><td>$url_tag</td><td>$git_url</td></tr>\n";
4483                 $url_tag = "";
4484         }
4485
4486         # Tag cloud
4487         my $show_ctags = gitweb_check_feature('ctags');
4488         if ($show_ctags) {
4489                 my $ctags = git_get_project_ctags($project);
4490                 my $cloud = git_populate_project_tagcloud($ctags);
4491                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
4492                 print "</td>\n<td>" unless %$ctags;
4493                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
4494                 print "</td>\n<td>" if %$ctags;
4495                 print git_show_project_tagcloud($cloud, 48);
4496                 print "</td></tr>";
4497         }
4498
4499         print "</table>\n";
4500
4501         # If XSS prevention is on, we don't include README.html.
4502         # TODO: Allow a readme in some safe format.
4503         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
4504                 print "<div class=\"title\">readme</div>\n" .
4505                       "<div class=\"readme\">\n";
4506                 insert_file("$projectroot/$project/README.html");
4507                 print "\n</div>\n"; # class="readme"
4508         }
4509
4510         # we need to request one more than 16 (0..15) to check if
4511         # those 16 are all
4512         my @commitlist = $head ? parse_commits($head, 17) : ();
4513         if (@commitlist) {
4514                 git_print_header_div('shortlog');
4515                 git_shortlog_body(\@commitlist, 0, 15, $refs,
4516                                   $#commitlist <=  15 ? undef :
4517                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
4518         }
4519
4520         if (@taglist) {
4521                 git_print_header_div('tags');
4522                 git_tags_body(\@taglist, 0, 15,
4523                               $#taglist <=  15 ? undef :
4524                               $cgi->a({-href => href(action=>"tags")}, "..."));
4525         }
4526
4527         if (@headlist) {
4528                 git_print_header_div('heads');
4529                 git_heads_body(\@headlist, $head, 0, 15,
4530                                $#headlist <= 15 ? undef :
4531                                $cgi->a({-href => href(action=>"heads")}, "..."));
4532         }
4533
4534         if (@forklist) {
4535                 git_print_header_div('forks');
4536                 git_project_list_body(\@forklist, 'age', 0, 15,
4537                                       $#forklist <= 15 ? undef :
4538                                       $cgi->a({-href => href(action=>"forks")}, "..."),
4539                                       'no_header');
4540         }
4541
4542         git_footer_html();
4543 }
4544
4545 sub git_tag {
4546         my $head = git_get_head_hash($project);
4547         git_header_html();
4548         git_print_page_nav('','', $head,undef,$head);
4549         my %tag = parse_tag($hash);
4550
4551         if (! %tag) {
4552                 die_error(404, "Unknown tag object");
4553         }
4554
4555         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
4556         print "<div class=\"title_text\">\n" .
4557               "<table class=\"object_header\">\n" .
4558               "<tr>\n" .
4559               "<td>object</td>\n" .
4560               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
4561                                $tag{'object'}) . "</td>\n" .
4562               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
4563                                               $tag{'type'}) . "</td>\n" .
4564               "</tr>\n";
4565         if (defined($tag{'author'})) {
4566                 my %ad = parse_date($tag{'epoch'}, $tag{'tz'});
4567                 print "<tr><td>author</td><td>" . esc_html($tag{'author'}) . "</td></tr>\n";
4568                 print "<tr><td></td><td>" . $ad{'rfc2822'} .
4569                         sprintf(" (%02d:%02d %s)", $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'}) .
4570                         "</td></tr>\n";
4571         }
4572         print "</table>\n\n" .
4573               "</div>\n";
4574         print "<div class=\"page_body\">";
4575         my $comment = $tag{'comment'};
4576         foreach my $line (@$comment) {
4577                 chomp $line;
4578                 print esc_html($line, -nbsp=>1) . "<br/>\n";
4579         }
4580         print "</div>\n";
4581         git_footer_html();
4582 }
4583
4584 sub git_blame {
4585         my $fd;
4586         my $ftype;
4587
4588         gitweb_check_feature('blame')
4589             or die_error(403, "Blame view not allowed");
4590
4591         die_error(400, "No file name given") unless $file_name;
4592         $hash_base ||= git_get_head_hash($project);
4593         die_error(404, "Couldn't find base commit") unless ($hash_base);
4594         my %co = parse_commit($hash_base)
4595                 or die_error(404, "Commit not found");
4596         if (!defined $hash) {
4597                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
4598                         or die_error(404, "Error looking up file");
4599         }
4600         $ftype = git_get_type($hash);
4601         if ($ftype !~ "blob") {
4602                 die_error(400, "Object is not a blob");
4603         }
4604         open ($fd, "-|", git_cmd(), "blame", '-p', '--',
4605               $file_name, $hash_base)
4606                 or die_error(500, "Open git-blame failed");
4607         git_header_html();
4608         my $formats_nav =
4609                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
4610                         "blob") .
4611                 " | " .
4612                 $cgi->a({-href => href(action=>"history", -replay=>1)},
4613                         "history") .
4614                 " | " .
4615                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
4616                         "HEAD");
4617         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
4618         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
4619         git_print_page_path($file_name, $ftype, $hash_base);
4620         my @rev_color = (qw(light2 dark2));
4621         my $num_colors = scalar(@rev_color);
4622         my $current_color = 0;
4623         my $last_rev;
4624         print <<HTML;
4625 <div class="page_body">
4626 <table class="blame">
4627 <tr><th>Commit</th><th>Line</th><th>Data</th></tr>
4628 HTML
4629         my %metainfo = ();
4630         while (1) {
4631                 $_ = <$fd>;
4632                 last unless defined $_;
4633                 my ($full_rev, $orig_lineno, $lineno, $group_size) =
4634                     /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/;
4635                 if (!exists $metainfo{$full_rev}) {
4636                         $metainfo{$full_rev} = {};
4637                 }
4638                 my $meta = $metainfo{$full_rev};
4639                 while (<$fd>) {
4640                         last if (s/^\t//);
4641                         if (/^(\S+) (.*)$/) {
4642                                 $meta->{$1} = $2;
4643                         }
4644                 }
4645                 my $data = $_;
4646                 chomp $data;
4647                 my $rev = substr($full_rev, 0, 8);
4648                 my $author = $meta->{'author'};
4649                 my %date = parse_date($meta->{'author-time'},
4650                                       $meta->{'author-tz'});
4651                 my $date = $date{'iso-tz'};
4652                 if ($group_size) {
4653                         $current_color = ++$current_color % $num_colors;
4654                 }
4655                 print "<tr class=\"$rev_color[$current_color]\">\n";
4656                 if ($group_size) {
4657                         print "<td class=\"sha1\"";
4658                         print " title=\"". esc_html($author) . ", $date\"";
4659                         print " rowspan=\"$group_size\"" if ($group_size > 1);
4660                         print ">";
4661                         print $cgi->a({-href => href(action=>"commit",
4662                                                      hash=>$full_rev,
4663                                                      file_name=>$file_name)},
4664                                       esc_html($rev));
4665                         print "</td>\n";
4666                 }
4667                 open (my $dd, "-|", git_cmd(), "rev-parse", "$full_rev^")
4668                         or die_error(500, "Open git-rev-parse failed");
4669                 my $parent_commit = <$dd>;
4670                 close $dd;
4671                 chomp($parent_commit);
4672                 my $blamed = href(action => 'blame',
4673                                   file_name => $meta->{'filename'},
4674                                   hash_base => $parent_commit);
4675                 print "<td class=\"linenr\">";
4676                 print $cgi->a({ -href => "$blamed#l$orig_lineno",
4677                                 -id => "l$lineno",
4678                                 -class => "linenr" },
4679                               esc_html($lineno));
4680                 print "</td>";
4681                 print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
4682                 print "</tr>\n";
4683         }
4684         print "</table>\n";
4685         print "</div>";
4686         close $fd
4687                 or print "Reading blob failed\n";
4688         git_footer_html();
4689 }
4690
4691 sub git_tags {
4692         my $head = git_get_head_hash($project);
4693         git_header_html();
4694         git_print_page_nav('','', $head,undef,$head);
4695         git_print_header_div('summary', $project);
4696
4697         my @tagslist = git_get_tags_list();
4698         if (@tagslist) {
4699                 git_tags_body(\@tagslist);
4700         }
4701         git_footer_html();
4702 }
4703
4704 sub git_heads {
4705         my $head = git_get_head_hash($project);
4706         git_header_html();
4707         git_print_page_nav('','', $head,undef,$head);
4708         git_print_header_div('summary', $project);
4709
4710         my @headslist = git_get_heads_list();
4711         if (@headslist) {
4712                 git_heads_body(\@headslist, $head);
4713         }
4714         git_footer_html();
4715 }
4716
4717 sub git_blob_plain {
4718         my $type = shift;
4719         my $expires;
4720
4721         if (!defined $hash) {
4722                 if (defined $file_name) {
4723                         my $base = $hash_base || git_get_head_hash($project);
4724                         $hash = git_get_hash_by_path($base, $file_name, "blob")
4725                                 or die_error(404, "Cannot find file");
4726                 } else {
4727                         die_error(400, "No file name defined");
4728                 }
4729         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
4730                 # blobs defined by non-textual hash id's can be cached
4731                 $expires = "+1d";
4732         }
4733
4734         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4735                 or die_error(500, "Open git-cat-file blob '$hash' failed");
4736
4737         # content-type (can include charset)
4738         $type = blob_contenttype($fd, $file_name, $type);
4739
4740         # "save as" filename, even when no $file_name is given
4741         my $save_as = "$hash";
4742         if (defined $file_name) {
4743                 $save_as = $file_name;
4744         } elsif ($type =~ m/^text\//) {
4745                 $save_as .= '.txt';
4746         }
4747
4748         # With XSS prevention on, blobs of all types except a few known safe
4749         # ones are served with "Content-Disposition: attachment" to make sure
4750         # they don't run in our security domain.  For certain image types,
4751         # blob view writes an <img> tag referring to blob_plain view, and we
4752         # want to be sure not to break that by serving the image as an
4753         # attachment (though Firefox 3 doesn't seem to care).
4754         my $sandbox = $prevent_xss &&
4755                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
4756
4757         # serve text/* as text/plain
4758         if ($prevent_xss &&
4759             $type =~ m!^text/[a-z]+\b(.*)$!) {
4760                 my $rest = $1;
4761                 $rest = defined $rest ? $rest : '';
4762                 $type = "text/plain$rest";
4763         }
4764
4765         print $cgi->header(
4766                 -type => $type,
4767                 -expires => $expires,
4768                 -content_disposition =>
4769                         ($sandbox ? 'attachment' : 'inline')
4770                         . '; filename="' . $save_as . '"');
4771         undef $/;
4772         binmode STDOUT, ':raw';
4773         print <$fd>;
4774         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
4775         $/ = "\n";
4776         close $fd;
4777 }
4778
4779 sub git_blob {
4780         my $expires;
4781
4782         if (!defined $hash) {
4783                 if (defined $file_name) {
4784                         my $base = $hash_base || git_get_head_hash($project);
4785                         $hash = git_get_hash_by_path($base, $file_name, "blob")
4786                                 or die_error(404, "Cannot find file");
4787                 } else {
4788                         die_error(400, "No file name defined");
4789                 }
4790         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
4791                 # blobs defined by non-textual hash id's can be cached
4792                 $expires = "+1d";
4793         }
4794
4795         my $have_blame = gitweb_check_feature('blame');
4796         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4797                 or die_error(500, "Couldn't cat $file_name, $hash");
4798         my $mimetype = blob_mimetype($fd, $file_name);
4799         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
4800                 close $fd;
4801                 return git_blob_plain($mimetype);
4802         }
4803         # we can have blame only for text/* mimetype
4804         $have_blame &&= ($mimetype =~ m!^text/!);
4805
4806         git_header_html(undef, $expires);
4807         my $formats_nav = '';
4808         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
4809                 if (defined $file_name) {
4810                         if ($have_blame) {
4811                                 $formats_nav .=
4812                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
4813                                                 "blame") .
4814                                         " | ";
4815                         }
4816                         $formats_nav .=
4817                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
4818                                         "history") .
4819                                 " | " .
4820                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
4821                                         "raw") .
4822                                 " | " .
4823                                 $cgi->a({-href => href(action=>"blob",
4824                                                        hash_base=>"HEAD", file_name=>$file_name)},
4825                                         "HEAD");
4826                 } else {
4827                         $formats_nav .=
4828                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
4829                                         "raw");
4830                 }
4831                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
4832                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
4833         } else {
4834                 print "<div class=\"page_nav\">\n" .
4835                       "<br/><br/></div>\n" .
4836                       "<div class=\"title\">$hash</div>\n";
4837         }
4838         git_print_page_path($file_name, "blob", $hash_base);
4839         print "<div class=\"page_body\">\n";
4840         if ($mimetype =~ m!^image/!) {
4841                 print qq!<img type="$mimetype"!;
4842                 if ($file_name) {
4843                         print qq! alt="$file_name" title="$file_name"!;
4844                 }
4845                 print qq! src="! .
4846                       href(action=>"blob_plain", hash=>$hash,
4847                            hash_base=>$hash_base, file_name=>$file_name) .
4848                       qq!" />\n!;
4849         } else {
4850                 my $nr;
4851                 while (my $line = <$fd>) {
4852                         chomp $line;
4853                         $nr++;
4854                         $line = untabify($line);
4855                         printf "<div class=\"pre\"><a id=\"l%i\" href=\"#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
4856                                $nr, $nr, $nr, esc_html($line, -nbsp=>1);
4857                 }
4858         }
4859         close $fd
4860                 or print "Reading blob failed.\n";
4861         print "</div>";
4862         git_footer_html();
4863 }
4864
4865 sub git_tree {
4866         if (!defined $hash_base) {
4867                 $hash_base = "HEAD";
4868         }
4869         if (!defined $hash) {
4870                 if (defined $file_name) {
4871                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
4872                 } else {
4873                         $hash = $hash_base;
4874                 }
4875         }
4876         die_error(404, "No such tree") unless defined($hash);
4877         $/ = "\0";
4878         open my $fd, "-|", git_cmd(), "ls-tree", '-z', $hash
4879                 or die_error(500, "Open git-ls-tree failed");
4880         my @entries = map { chomp; $_ } <$fd>;
4881         close $fd or die_error(404, "Reading tree failed");
4882         $/ = "\n";
4883
4884         my $refs = git_get_references();
4885         my $ref = format_ref_marker($refs, $hash_base);
4886         git_header_html();
4887         my $basedir = '';
4888         my $have_blame = gitweb_check_feature('blame');
4889         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
4890                 my @views_nav = ();
4891                 if (defined $file_name) {
4892                         push @views_nav,
4893                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
4894                                         "history"),
4895                                 $cgi->a({-href => href(action=>"tree",
4896                                                        hash_base=>"HEAD", file_name=>$file_name)},
4897                                         "HEAD"),
4898                 }
4899                 my $snapshot_links = format_snapshot_links($hash);
4900                 if (defined $snapshot_links) {
4901                         # FIXME: Should be available when we have no hash base as well.
4902                         push @views_nav, $snapshot_links;
4903                 }
4904                 git_print_page_nav('tree','', $hash_base, undef, undef, join(' | ', @views_nav));
4905                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
4906         } else {
4907                 undef $hash_base;
4908                 print "<div class=\"page_nav\">\n";
4909                 print "<br/><br/></div>\n";
4910                 print "<div class=\"title\">$hash</div>\n";
4911         }
4912         if (defined $file_name) {
4913                 $basedir = $file_name;
4914                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
4915                         $basedir .= '/';
4916                 }
4917                 git_print_page_path($file_name, 'tree', $hash_base);
4918         }
4919         print "<div class=\"page_body\">\n";
4920         print "<table class=\"tree\">\n";
4921         my $alternate = 1;
4922         # '..' (top directory) link if possible
4923         if (defined $hash_base &&
4924             defined $file_name && $file_name =~ m![^/]+$!) {
4925                 if ($alternate) {
4926                         print "<tr class=\"dark\">\n";
4927                 } else {
4928                         print "<tr class=\"light\">\n";
4929                 }
4930                 $alternate ^= 1;
4931
4932                 my $up = $file_name;
4933                 $up =~ s!/?[^/]+$!!;
4934                 undef $up unless $up;
4935                 # based on git_print_tree_entry
4936                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
4937                 print '<td class="list">';
4938                 print $cgi->a({-href => href(action=>"tree", hash_base=>$hash_base,
4939                                              file_name=>$up)},
4940                               "..");
4941                 print "</td>\n";
4942                 print "<td class=\"link\"></td>\n";
4943
4944                 print "</tr>\n";
4945         }
4946         foreach my $line (@entries) {
4947                 my %t = parse_ls_tree_line($line, -z => 1);
4948
4949                 if ($alternate) {
4950                         print "<tr class=\"dark\">\n";
4951                 } else {
4952                         print "<tr class=\"light\">\n";
4953                 }
4954                 $alternate ^= 1;
4955
4956                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
4957
4958                 print "</tr>\n";
4959         }
4960         print "</table>\n" .
4961               "</div>";
4962         git_footer_html();
4963 }
4964
4965 sub git_snapshot {
4966         my $format = $input_params{'snapshot_format'};
4967         if (!@snapshot_fmts) {
4968                 die_error(403, "Snapshots not allowed");
4969         }
4970         # default to first supported snapshot format
4971         $format ||= $snapshot_fmts[0];
4972         if ($format !~ m/^[a-z0-9]+$/) {
4973                 die_error(400, "Invalid snapshot format parameter");
4974         } elsif (!exists($known_snapshot_formats{$format})) {
4975                 die_error(400, "Unknown snapshot format");
4976         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
4977                 die_error(403, "Unsupported snapshot format");
4978         }
4979
4980         if (!defined $hash) {
4981                 $hash = git_get_head_hash($project);
4982         }
4983
4984         my $name = $project;
4985         $name =~ s,([^/])/*\.git$,$1,;
4986         $name = basename($name);
4987         my $filename = to_utf8($name);
4988         $name =~ s/\047/\047\\\047\047/g;
4989         my $cmd;
4990         $filename .= "-$hash$known_snapshot_formats{$format}{'suffix'}";
4991         $cmd = quote_command(
4992                 git_cmd(), 'archive',
4993                 "--format=$known_snapshot_formats{$format}{'format'}",
4994                 "--prefix=$name/", $hash);
4995         if (exists $known_snapshot_formats{$format}{'compressor'}) {
4996                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
4997         }
4998
4999         print $cgi->header(
5000                 -type => $known_snapshot_formats{$format}{'type'},
5001                 -content_disposition => 'inline; filename="' . "$filename" . '"',
5002                 -status => '200 OK');
5003
5004         open my $fd, "-|", $cmd
5005                 or die_error(500, "Execute git-archive failed");
5006         binmode STDOUT, ':raw';
5007         print <$fd>;
5008         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5009         close $fd;
5010 }
5011
5012 sub git_log {
5013         my $head = git_get_head_hash($project);
5014         if (!defined $hash) {
5015                 $hash = $head;
5016         }
5017         if (!defined $page) {
5018                 $page = 0;
5019         }
5020         my $refs = git_get_references();
5021
5022         my @commitlist = parse_commits($hash, 101, (100 * $page));
5023
5024         my $paging_nav = format_paging_nav('log', $hash, $head, $page, $#commitlist >= 100);
5025
5026         git_header_html();
5027         git_print_page_nav('log','', $hash,undef,undef, $paging_nav);
5028
5029         if (!@commitlist) {
5030                 my %co = parse_commit($hash);
5031
5032                 git_print_header_div('summary', $project);
5033                 print "<div class=\"page_body\"> Last change $co{'age_string'}.<br/><br/></div>\n";
5034         }
5035         my $to = ($#commitlist >= 99) ? (99) : ($#commitlist);
5036         for (my $i = 0; $i <= $to; $i++) {
5037                 my %co = %{$commitlist[$i]};
5038                 next if !%co;
5039                 my $commit = $co{'id'};
5040                 my $ref = format_ref_marker($refs, $commit);
5041                 my %ad = parse_date($co{'author_epoch'});
5042                 git_print_header_div('commit',
5043                                "<span class=\"age\">$co{'age_string'}</span>" .
5044                                esc_html($co{'title'}) . $ref,
5045                                $commit);
5046                 print "<div class=\"title_text\">\n" .
5047                       "<div class=\"log_link\">\n" .
5048                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5049                       " | " .
5050                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5051                       " | " .
5052                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5053                       "<br/>\n" .
5054                       "</div>\n" .
5055                       "<i>" . esc_html($co{'author_name'}) .  " [$ad{'rfc2822'}]</i><br/>\n" .
5056                       "</div>\n";
5057
5058                 print "<div class=\"log_body\">\n";
5059                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5060                 print "</div>\n";
5061         }
5062         if ($#commitlist >= 100) {
5063                 print "<div class=\"page_nav\">\n";
5064                 print $cgi->a({-href => href(-replay=>1, page=>$page+1),
5065                                -accesskey => "n", -title => "Alt-n"}, "next");
5066                 print "</div>\n";
5067         }
5068         git_footer_html();
5069 }
5070
5071 sub git_commit {
5072         $hash ||= $hash_base || "HEAD";
5073         my %co = parse_commit($hash)
5074             or die_error(404, "Unknown commit object");
5075         my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
5076         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
5077
5078         my $parent  = $co{'parent'};
5079         my $parents = $co{'parents'}; # listref
5080
5081         # we need to prepare $formats_nav before any parameter munging
5082         my $formats_nav;
5083         if (!defined $parent) {
5084                 # --root commitdiff
5085                 $formats_nav .= '(initial)';
5086         } elsif (@$parents == 1) {
5087                 # single parent commit
5088                 $formats_nav .=
5089                         '(parent: ' .
5090                         $cgi->a({-href => href(action=>"commit",
5091                                                hash=>$parent)},
5092                                 esc_html(substr($parent, 0, 7))) .
5093                         ')';
5094         } else {
5095                 # merge commit
5096                 $formats_nav .=
5097                         '(merge: ' .
5098                         join(' ', map {
5099                                 $cgi->a({-href => href(action=>"commit",
5100                                                        hash=>$_)},
5101                                         esc_html(substr($_, 0, 7)));
5102                         } @$parents ) .
5103                         ')';
5104         }
5105
5106         if (!defined $parent) {
5107                 $parent = "--root";
5108         }
5109         my @difftree;
5110         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
5111                 @diff_opts,
5112                 (@$parents <= 1 ? $parent : '-c'),
5113                 $hash, "--"
5114                 or die_error(500, "Open git-diff-tree failed");
5115         @difftree = map { chomp; $_ } <$fd>;
5116         close $fd or die_error(404, "Reading git-diff-tree failed");
5117
5118         # non-textual hash id's can be cached
5119         my $expires;
5120         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5121                 $expires = "+1d";
5122         }
5123         my $refs = git_get_references();
5124         my $ref = format_ref_marker($refs, $co{'id'});
5125
5126         git_header_html(undef, $expires);
5127         git_print_page_nav('commit', '',
5128                            $hash, $co{'tree'}, $hash,
5129                            $formats_nav);
5130
5131         if (defined $co{'parent'}) {
5132                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
5133         } else {
5134                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
5135         }
5136         print "<div class=\"title_text\">\n" .
5137               "<table class=\"object_header\">\n";
5138         print "<tr><td>author</td><td>" . esc_html($co{'author'}) . "</td></tr>\n".
5139               "<tr>" .
5140               "<td></td><td> $ad{'rfc2822'}";
5141         if ($ad{'hour_local'} < 6) {
5142                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
5143                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
5144         } else {
5145                 printf(" (%02d:%02d %s)",
5146                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
5147         }
5148         print "</td>" .
5149               "</tr>\n";
5150         print "<tr><td>committer</td><td>" . esc_html($co{'committer'}) . "</td></tr>\n";
5151         print "<tr><td></td><td> $cd{'rfc2822'}" .
5152               sprintf(" (%02d:%02d %s)", $cd{'hour_local'}, $cd{'minute_local'}, $cd{'tz_local'}) .
5153               "</td></tr>\n";
5154         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
5155         print "<tr>" .
5156               "<td>tree</td>" .
5157               "<td class=\"sha1\">" .
5158               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
5159                        class => "list"}, $co{'tree'}) .
5160               "</td>" .
5161               "<td class=\"link\">" .
5162               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
5163                       "tree");
5164         my $snapshot_links = format_snapshot_links($hash);
5165         if (defined $snapshot_links) {
5166                 print " | " . $snapshot_links;
5167         }
5168         print "</td>" .
5169               "</tr>\n";
5170
5171         foreach my $par (@$parents) {
5172                 print "<tr>" .
5173                       "<td>parent</td>" .
5174                       "<td class=\"sha1\">" .
5175                       $cgi->a({-href => href(action=>"commit", hash=>$par),
5176                                class => "list"}, $par) .
5177                       "</td>" .
5178                       "<td class=\"link\">" .
5179                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
5180                       " | " .
5181                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
5182                       "</td>" .
5183                       "</tr>\n";
5184         }
5185         print "</table>".
5186               "</div>\n";
5187
5188         print "<div class=\"page_body\">\n";
5189         git_print_log($co{'comment'});
5190         print "</div>\n";
5191
5192         git_difftree_body(\@difftree, $hash, @$parents);
5193
5194         git_footer_html();
5195 }
5196
5197 sub git_object {
5198         # object is defined by:
5199         # - hash or hash_base alone
5200         # - hash_base and file_name
5201         my $type;
5202
5203         # - hash or hash_base alone
5204         if ($hash || ($hash_base && !defined $file_name)) {
5205                 my $object_id = $hash || $hash_base;
5206
5207                 open my $fd, "-|", quote_command(
5208                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
5209                         or die_error(404, "Object does not exist");
5210                 $type = <$fd>;
5211                 chomp $type;
5212                 close $fd
5213                         or die_error(404, "Object does not exist");
5214
5215         # - hash_base and file_name
5216         } elsif ($hash_base && defined $file_name) {
5217                 $file_name =~ s,/+$,,;
5218
5219                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
5220                         or die_error(404, "Base object does not exist");
5221
5222                 # here errors should not hapen
5223                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
5224                         or die_error(500, "Open git-ls-tree failed");
5225                 my $line = <$fd>;
5226                 close $fd;
5227
5228                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
5229                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
5230                         die_error(404, "File or directory for given base does not exist");
5231                 }
5232                 $type = $2;
5233                 $hash = $3;
5234         } else {
5235                 die_error(400, "Not enough information to find object");
5236         }
5237
5238         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
5239                                           hash=>$hash, hash_base=>$hash_base,
5240                                           file_name=>$file_name),
5241                              -status => '302 Found');
5242 }
5243
5244 sub git_blobdiff {
5245         my $format = shift || 'html';
5246
5247         my $fd;
5248         my @difftree;
5249         my %diffinfo;
5250         my $expires;
5251
5252         # preparing $fd and %diffinfo for git_patchset_body
5253         # new style URI
5254         if (defined $hash_base && defined $hash_parent_base) {
5255                 if (defined $file_name) {
5256                         # read raw output
5257                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5258                                 $hash_parent_base, $hash_base,
5259                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
5260                                 or die_error(500, "Open git-diff-tree failed");
5261                         @difftree = map { chomp; $_ } <$fd>;
5262                         close $fd
5263                                 or die_error(404, "Reading git-diff-tree failed");
5264                         @difftree
5265                                 or die_error(404, "Blob diff not found");
5266
5267                 } elsif (defined $hash &&
5268                          $hash =~ /[0-9a-fA-F]{40}/) {
5269                         # try to find filename from $hash
5270
5271                         # read filtered raw output
5272                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5273                                 $hash_parent_base, $hash_base, "--"
5274                                 or die_error(500, "Open git-diff-tree failed");
5275                         @difftree =
5276                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
5277                                 # $hash == to_id
5278                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
5279                                 map { chomp; $_ } <$fd>;
5280                         close $fd
5281                                 or die_error(404, "Reading git-diff-tree failed");
5282                         @difftree
5283                                 or die_error(404, "Blob diff not found");
5284
5285                 } else {
5286                         die_error(400, "Missing one of the blob diff parameters");
5287                 }
5288
5289                 if (@difftree > 1) {
5290                         die_error(400, "Ambiguous blob diff specification");
5291                 }
5292
5293                 %diffinfo = parse_difftree_raw_line($difftree[0]);
5294                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
5295                 $file_name   ||= $diffinfo{'to_file'};
5296
5297                 $hash_parent ||= $diffinfo{'from_id'};
5298                 $hash        ||= $diffinfo{'to_id'};
5299
5300                 # non-textual hash id's can be cached
5301                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
5302                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
5303                         $expires = '+1d';
5304                 }
5305
5306                 # open patch output
5307                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5308                         '-p', ($format eq 'html' ? "--full-index" : ()),
5309                         $hash_parent_base, $hash_base,
5310                         "--", (defined $file_parent ? $file_parent : ()), $file_name
5311                         or die_error(500, "Open git-diff-tree failed");
5312         }
5313
5314         # old/legacy style URI -- not generated anymore since 1.4.3.
5315         if (!%diffinfo) {
5316                 die_error('404 Not Found', "Missing one of the blob diff parameters")
5317         }
5318
5319         # header
5320         if ($format eq 'html') {
5321                 my $formats_nav =
5322                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
5323                                 "raw");
5324                 git_header_html(undef, $expires);
5325                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5326                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5327                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5328                 } else {
5329                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
5330                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
5331                 }
5332                 if (defined $file_name) {
5333                         git_print_page_path($file_name, "blob", $hash_base);
5334                 } else {
5335                         print "<div class=\"page_path\"></div>\n";
5336                 }
5337
5338         } elsif ($format eq 'plain') {
5339                 print $cgi->header(
5340                         -type => 'text/plain',
5341                         -charset => 'utf-8',
5342                         -expires => $expires,
5343                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
5344
5345                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
5346
5347         } else {
5348                 die_error(400, "Unknown blobdiff format");
5349         }
5350
5351         # patch
5352         if ($format eq 'html') {
5353                 print "<div class=\"page_body\">\n";
5354
5355                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
5356                 close $fd;
5357
5358                 print "</div>\n"; # class="page_body"
5359                 git_footer_html();
5360
5361         } else {
5362                 while (my $line = <$fd>) {
5363                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
5364                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
5365
5366                         print $line;
5367
5368                         last if $line =~ m!^\+\+\+!;
5369                 }
5370                 local $/ = undef;
5371                 print <$fd>;
5372                 close $fd;
5373         }
5374 }
5375
5376 sub git_blobdiff_plain {
5377         git_blobdiff('plain');
5378 }
5379
5380 sub git_commitdiff {
5381         my $format = shift || 'html';
5382         $hash ||= $hash_base || "HEAD";
5383         my %co = parse_commit($hash)
5384             or die_error(404, "Unknown commit object");
5385
5386         # choose format for commitdiff for merge
5387         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
5388                 $hash_parent = '--cc';
5389         }
5390         # we need to prepare $formats_nav before almost any parameter munging
5391         my $formats_nav;
5392         if ($format eq 'html') {
5393                 $formats_nav =
5394                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
5395                                 "raw");
5396
5397                 if (defined $hash_parent &&
5398                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
5399                         # commitdiff with two commits given
5400                         my $hash_parent_short = $hash_parent;
5401                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
5402                                 $hash_parent_short = substr($hash_parent, 0, 7);
5403                         }
5404                         $formats_nav .=
5405                                 ' (from';
5406                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
5407                                 if ($co{'parents'}[$i] eq $hash_parent) {
5408                                         $formats_nav .= ' parent ' . ($i+1);
5409                                         last;
5410                                 }
5411                         }
5412                         $formats_nav .= ': ' .
5413                                 $cgi->a({-href => href(action=>"commitdiff",
5414                                                        hash=>$hash_parent)},
5415                                         esc_html($hash_parent_short)) .
5416                                 ')';
5417                 } elsif (!$co{'parent'}) {
5418                         # --root commitdiff
5419                         $formats_nav .= ' (initial)';
5420                 } elsif (scalar @{$co{'parents'}} == 1) {
5421                         # single parent commit
5422                         $formats_nav .=
5423                                 ' (parent: ' .
5424                                 $cgi->a({-href => href(action=>"commitdiff",
5425                                                        hash=>$co{'parent'})},
5426                                         esc_html(substr($co{'parent'}, 0, 7))) .
5427                                 ')';
5428                 } else {
5429                         # merge commit
5430                         if ($hash_parent eq '--cc') {
5431                                 $formats_nav .= ' | ' .
5432                                         $cgi->a({-href => href(action=>"commitdiff",
5433                                                                hash=>$hash, hash_parent=>'-c')},
5434                                                 'combined');
5435                         } else { # $hash_parent eq '-c'
5436                                 $formats_nav .= ' | ' .
5437                                         $cgi->a({-href => href(action=>"commitdiff",
5438                                                                hash=>$hash, hash_parent=>'--cc')},
5439                                                 'compact');
5440                         }
5441                         $formats_nav .=
5442                                 ' (merge: ' .
5443                                 join(' ', map {
5444                                         $cgi->a({-href => href(action=>"commitdiff",
5445                                                                hash=>$_)},
5446                                                 esc_html(substr($_, 0, 7)));
5447                                 } @{$co{'parents'}} ) .
5448                                 ')';
5449                 }
5450         }
5451
5452         my $hash_parent_param = $hash_parent;
5453         if (!defined $hash_parent_param) {
5454                 # --cc for multiple parents, --root for parentless
5455                 $hash_parent_param =
5456                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
5457         }
5458
5459         # read commitdiff
5460         my $fd;
5461         my @difftree;
5462         if ($format eq 'html') {
5463                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5464                         "--no-commit-id", "--patch-with-raw", "--full-index",
5465                         $hash_parent_param, $hash, "--"
5466                         or die_error(500, "Open git-diff-tree failed");
5467
5468                 while (my $line = <$fd>) {
5469                         chomp $line;
5470                         # empty line ends raw part of diff-tree output
5471                         last unless $line;
5472                         push @difftree, scalar parse_difftree_raw_line($line);
5473                 }
5474
5475         } elsif ($format eq 'plain') {
5476                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5477                         '-p', $hash_parent_param, $hash, "--"
5478                         or die_error(500, "Open git-diff-tree failed");
5479
5480         } else {
5481                 die_error(400, "Unknown commitdiff format");
5482         }
5483
5484         # non-textual hash id's can be cached
5485         my $expires;
5486         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5487                 $expires = "+1d";
5488         }
5489
5490         # write commit message
5491         if ($format eq 'html') {
5492                 my $refs = git_get_references();
5493                 my $ref = format_ref_marker($refs, $co{'id'});
5494
5495                 git_header_html(undef, $expires);
5496                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
5497                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
5498                 git_print_authorship(\%co);
5499                 print "<div class=\"page_body\">\n";
5500                 if (@{$co{'comment'}} > 1) {
5501                         print "<div class=\"log\">\n";
5502                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
5503                         print "</div>\n"; # class="log"
5504                 }
5505
5506         } elsif ($format eq 'plain') {
5507                 my $refs = git_get_references("tags");
5508                 my $tagname = git_get_rev_name_tags($hash);
5509                 my $filename = basename($project) . "-$hash.patch";
5510
5511                 print $cgi->header(
5512                         -type => 'text/plain',
5513                         -charset => 'utf-8',
5514                         -expires => $expires,
5515                         -content_disposition => 'inline; filename="' . "$filename" . '"');
5516                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
5517                 print "From: " . to_utf8($co{'author'}) . "\n";
5518                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
5519                 print "Subject: " . to_utf8($co{'title'}) . "\n";
5520
5521                 print "X-Git-Tag: $tagname\n" if $tagname;
5522                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
5523
5524                 foreach my $line (@{$co{'comment'}}) {
5525                         print to_utf8($line) . "\n";
5526                 }
5527                 print "---\n\n";
5528         }
5529
5530         # write patch
5531         if ($format eq 'html') {
5532                 my $use_parents = !defined $hash_parent ||
5533                         $hash_parent eq '-c' || $hash_parent eq '--cc';
5534                 git_difftree_body(\@difftree, $hash,
5535                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
5536                 print "<br/>\n";
5537
5538                 git_patchset_body($fd, \@difftree, $hash,
5539                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
5540                 close $fd;
5541                 print "</div>\n"; # class="page_body"
5542                 git_footer_html();
5543
5544         } elsif ($format eq 'plain') {
5545                 local $/ = undef;
5546                 print <$fd>;
5547                 close $fd
5548                         or print "Reading git-diff-tree failed\n";
5549         }
5550 }
5551
5552 sub git_commitdiff_plain {
5553         git_commitdiff('plain');
5554 }
5555
5556 sub git_history {
5557         if (!defined $hash_base) {
5558                 $hash_base = git_get_head_hash($project);
5559         }
5560         if (!defined $page) {
5561                 $page = 0;
5562         }
5563         my $ftype;
5564         my %co = parse_commit($hash_base)
5565             or die_error(404, "Unknown commit object");
5566
5567         my $refs = git_get_references();
5568         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
5569
5570         my @commitlist = parse_commits($hash_base, 101, (100 * $page),
5571                                        $file_name, "--full-history")
5572             or die_error(404, "No such file or directory on given branch");
5573
5574         if (!defined $hash && defined $file_name) {
5575                 # some commits could have deleted file in question,
5576                 # and not have it in tree, but one of them has to have it
5577                 for (my $i = 0; $i <= @commitlist; $i++) {
5578                         $hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
5579                         last if defined $hash;
5580                 }
5581         }
5582         if (defined $hash) {
5583                 $ftype = git_get_type($hash);
5584         }
5585         if (!defined $ftype) {
5586                 die_error(500, "Unknown type of object");
5587         }
5588
5589         my $paging_nav = '';
5590         if ($page > 0) {
5591                 $paging_nav .=
5592                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
5593                                                file_name=>$file_name)},
5594                                 "first");
5595                 $paging_nav .= " &sdot; " .
5596                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5597                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5598         } else {
5599                 $paging_nav .= "first";
5600                 $paging_nav .= " &sdot; prev";
5601         }
5602         my $next_link = '';
5603         if ($#commitlist >= 100) {
5604                 $next_link =
5605                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5606                                  -accesskey => "n", -title => "Alt-n"}, "next");
5607                 $paging_nav .= " &sdot; $next_link";
5608         } else {
5609                 $paging_nav .= " &sdot; next";
5610         }
5611
5612         git_header_html();
5613         git_print_page_nav('history','', $hash_base,$co{'tree'},$hash_base, $paging_nav);
5614         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5615         git_print_page_path($file_name, $ftype, $hash_base);
5616
5617         git_history_body(\@commitlist, 0, 99,
5618                          $refs, $hash_base, $ftype, $next_link);
5619
5620         git_footer_html();
5621 }
5622
5623 sub git_search {
5624         gitweb_check_feature('search') or die_error(403, "Search is disabled");
5625         if (!defined $searchtext) {
5626                 die_error(400, "Text field is empty");
5627         }
5628         if (!defined $hash) {
5629                 $hash = git_get_head_hash($project);
5630         }
5631         my %co = parse_commit($hash);
5632         if (!%co) {
5633                 die_error(404, "Unknown commit object");
5634         }
5635         if (!defined $page) {
5636                 $page = 0;
5637         }
5638
5639         $searchtype ||= 'commit';
5640         if ($searchtype eq 'pickaxe') {
5641                 # pickaxe may take all resources of your box and run for several minutes
5642                 # with every query - so decide by yourself how public you make this feature
5643                 gitweb_check_feature('pickaxe')
5644                     or die_error(403, "Pickaxe is disabled");
5645         }
5646         if ($searchtype eq 'grep') {
5647                 gitweb_check_feature('grep')
5648                     or die_error(403, "Grep is disabled");
5649         }
5650
5651         git_header_html();
5652
5653         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
5654                 my $greptype;
5655                 if ($searchtype eq 'commit') {
5656                         $greptype = "--grep=";
5657                 } elsif ($searchtype eq 'author') {
5658                         $greptype = "--author=";
5659                 } elsif ($searchtype eq 'committer') {
5660                         $greptype = "--committer=";
5661                 }
5662                 $greptype .= $searchtext;
5663                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5664                                                $greptype, '--regexp-ignore-case',
5665                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5666
5667                 my $paging_nav = '';
5668                 if ($page > 0) {
5669                         $paging_nav .=
5670                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
5671                                                        searchtext=>$searchtext,
5672                                                        searchtype=>$searchtype)},
5673                                         "first");
5674                         $paging_nav .= " &sdot; " .
5675                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
5676                                          -accesskey => "p", -title => "Alt-p"}, "prev");
5677                 } else {
5678                         $paging_nav .= "first";
5679                         $paging_nav .= " &sdot; prev";
5680                 }
5681                 my $next_link = '';
5682                 if ($#commitlist >= 100) {
5683                         $next_link =
5684                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
5685                                          -accesskey => "n", -title => "Alt-n"}, "next");
5686                         $paging_nav .= " &sdot; $next_link";
5687                 } else {
5688                         $paging_nav .= " &sdot; next";
5689                 }
5690
5691                 if ($#commitlist >= 100) {
5692                 }
5693
5694                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5695                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
5696                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5697         }
5698
5699         if ($searchtype eq 'pickaxe') {
5700                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
5701                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
5702
5703                 print "<table class=\"pickaxe search\">\n";
5704                 my $alternate = 1;
5705                 $/ = "\n";
5706                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5707                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5708                         ($search_use_regexp ? '--pickaxe-regex' : ());
5709                 undef %co;
5710                 my @files;
5711                 while (my $line = <$fd>) {
5712                         chomp $line;
5713                         next unless $line;
5714
5715                         my %set = parse_difftree_raw_line($line);
5716                         if (defined $set{'commit'}) {
5717                                 # finish previous commit
5718                                 if (%co) {
5719                                         print "</td>\n" .
5720                                               "<td class=\"link\">" .
5721                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5722                                               " | " .
5723                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5724                                         print "</td>\n" .
5725                                               "</tr>\n";
5726                                 }
5727
5728                                 if ($alternate) {
5729                                         print "<tr class=\"dark\">\n";
5730                                 } else {
5731                                         print "<tr class=\"light\">\n";
5732                                 }
5733                                 $alternate ^= 1;
5734                                 %co = parse_commit($set{'commit'});
5735                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5736                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5737                                       "<td><i>$author</i></td>\n" .
5738                                       "<td>" .
5739                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5740                                               -class => "list subject"},
5741                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5742                         } elsif (defined $set{'to_id'}) {
5743                                 next if ($set{'to_id'} =~ m/^0{40}$/);
5744
5745                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5746                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5747                                               -class => "list"},
5748                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5749                                       "<br/>\n";
5750                         }
5751                 }
5752                 close $fd;
5753
5754                 # finish last commit (warning: repetition!)
5755                 if (%co) {
5756                         print "</td>\n" .
5757                               "<td class=\"link\">" .
5758                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5759                               " | " .
5760                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5761                         print "</td>\n" .
5762                               "</tr>\n";
5763                 }
5764
5765                 print "</table>\n";
5766         }
5767
5768         if ($searchtype eq 'grep') {
5769                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
5770                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
5771
5772                 print "<table class=\"grep_search\">\n";
5773                 my $alternate = 1;
5774                 my $matches = 0;
5775                 $/ = "\n";
5776                 open my $fd, "-|", git_cmd(), 'grep', '-n',
5777                         $search_use_regexp ? ('-E', '-i') : '-F',
5778                         $searchtext, $co{'tree'};
5779                 my $lastfile = '';
5780                 while (my $line = <$fd>) {
5781                         chomp $line;
5782                         my ($file, $lno, $ltext, $binary);
5783                         last if ($matches++ > 1000);
5784                         if ($line =~ /^Binary file (.+) matches$/) {
5785                                 $file = $1;
5786                                 $binary = 1;
5787                         } else {
5788                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5789                         }
5790                         if ($file ne $lastfile) {
5791                                 $lastfile and print "</td></tr>\n";
5792                                 if ($alternate++) {
5793                                         print "<tr class=\"dark\">\n";
5794                                 } else {
5795                                         print "<tr class=\"light\">\n";
5796                                 }
5797                                 print "<td class=\"list\">".
5798                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5799                                                                file_name=>"$file"),
5800                                                 -class => "list"}, esc_path($file));
5801                                 print "</td><td>\n";
5802                                 $lastfile = $file;
5803                         }
5804                         if ($binary) {
5805                                 print "<div class=\"binary\">Binary file</div>\n";
5806                         } else {
5807                                 $ltext = untabify($ltext);
5808                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5809                                         $ltext = esc_html($1, -nbsp=>1);
5810                                         $ltext .= '<span class="match">';
5811                                         $ltext .= esc_html($2, -nbsp=>1);
5812                                         $ltext .= '</span>';
5813                                         $ltext .= esc_html($3, -nbsp=>1);
5814                                 } else {
5815                                         $ltext = esc_html($ltext, -nbsp=>1);
5816                                 }
5817                                 print "<div class=\"pre\">" .
5818                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5819                                                                file_name=>"$file").'#l'.$lno,
5820                                                 -class => "linenr"}, sprintf('%4i', $lno))
5821                                         . ' ' .  $ltext . "</div>\n";
5822                         }
5823                 }
5824                 if ($lastfile) {
5825                         print "</td></tr>\n";
5826                         if ($matches > 1000) {
5827                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5828                         }
5829                 } else {
5830                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
5831                 }
5832                 close $fd;
5833
5834                 print "</table>\n";
5835         }
5836         git_footer_html();
5837 }
5838
5839 sub git_search_help {
5840         git_header_html();
5841         git_print_page_nav('','', $hash,$hash,$hash);
5842         print <<EOT;
5843 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
5844 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
5845 the pattern entered is recognized as the POSIX extended
5846 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
5847 insensitive).</p>
5848 <dl>
5849 <dt><b>commit</b></dt>
5850 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
5851 EOT
5852         my $have_grep = gitweb_check_feature('grep');
5853         if ($have_grep) {
5854                 print <<EOT;
5855 <dt><b>grep</b></dt>
5856 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
5857     a different one) are searched for the given pattern. On large trees, this search can take
5858 a while and put some strain on the server, so please use it with some consideration. Note that
5859 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
5860 case-sensitive.</dd>
5861 EOT
5862         }
5863         print <<EOT;
5864 <dt><b>author</b></dt>
5865 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
5866 <dt><b>committer</b></dt>
5867 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
5868 EOT
5869         my $have_pickaxe = gitweb_check_feature('pickaxe');
5870         if ($have_pickaxe) {
5871                 print <<EOT;
5872 <dt><b>pickaxe</b></dt>
5873 <dd>All commits that caused the string to appear or disappear from any file (changes that
5874 added, removed or "modified" the string) will be listed. This search can take a while and
5875 takes a lot of strain on the server, so please use it wisely. Note that since you may be
5876 interested even in changes just changing the case as well, this search is case sensitive.</dd>
5877 EOT
5878         }
5879         print "</dl>\n";
5880         git_footer_html();
5881 }
5882
5883 sub git_shortlog {
5884         my $head = git_get_head_hash($project);
5885         if (!defined $hash) {
5886                 $hash = $head;
5887         }
5888         if (!defined $page) {
5889                 $page = 0;
5890         }
5891         my $refs = git_get_references();
5892
5893         my $commit_hash = $hash;
5894         if (defined $hash_parent) {
5895                 $commit_hash = "$hash_parent..$hash";
5896         }
5897         my @commitlist = parse_commits($commit_hash, 101, (100 * $page));
5898
5899         my $paging_nav = format_paging_nav('shortlog', $hash, $head, $page, $#commitlist >= 100);
5900         my $next_link = '';
5901         if ($#commitlist >= 100) {
5902                 $next_link =
5903                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5904                                  -accesskey => "n", -title => "Alt-n"}, "next");
5905         }
5906
5907         git_header_html();
5908         git_print_page_nav('shortlog','', $hash,$hash,$hash, $paging_nav);
5909         git_print_header_div('summary', $project);
5910
5911         git_shortlog_body(\@commitlist, 0, 99, $refs, $next_link);
5912
5913         git_footer_html();
5914 }
5915
5916 ## ......................................................................
5917 ## feeds (RSS, Atom; OPML)
5918
5919 sub git_feed {
5920         my $format = shift || 'atom';
5921         my $have_blame = gitweb_check_feature('blame');
5922
5923         # Atom: http://www.atomenabled.org/developers/syndication/
5924         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
5925         if ($format ne 'rss' && $format ne 'atom') {
5926                 die_error(400, "Unknown web feed format");
5927         }
5928
5929         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
5930         my $head = $hash || 'HEAD';
5931         my @commitlist = parse_commits($head, 150, 0, $file_name);
5932
5933         my %latest_commit;
5934         my %latest_date;
5935         my $content_type = "application/$format+xml";
5936         if (defined $cgi->http('HTTP_ACCEPT') &&
5937                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
5938                 # browser (feed reader) prefers text/xml
5939                 $content_type = 'text/xml';
5940         }
5941         if (defined($commitlist[0])) {
5942                 %latest_commit = %{$commitlist[0]};
5943                 %latest_date   = parse_date($latest_commit{'author_epoch'});
5944                 print $cgi->header(
5945                         -type => $content_type,
5946                         -charset => 'utf-8',
5947                         -last_modified => $latest_date{'rfc2822'});
5948         } else {
5949                 print $cgi->header(
5950                         -type => $content_type,
5951                         -charset => 'utf-8');
5952         }
5953
5954         # Optimization: skip generating the body if client asks only
5955         # for Last-Modified date.
5956         return if ($cgi->request_method() eq 'HEAD');
5957
5958         # header variables
5959         my $title = "$site_name - $project/$action";
5960         my $feed_type = 'log';
5961         if (defined $hash) {
5962                 $title .= " - '$hash'";
5963                 $feed_type = 'branch log';
5964                 if (defined $file_name) {
5965                         $title .= " :: $file_name";
5966                         $feed_type = 'history';
5967                 }
5968         } elsif (defined $file_name) {
5969                 $title .= " - $file_name";
5970                 $feed_type = 'history';
5971         }
5972         $title .= " $feed_type";
5973         my $descr = git_get_project_description($project);
5974         if (defined $descr) {
5975                 $descr = esc_html($descr);
5976         } else {
5977                 $descr = "$project " .
5978                          ($format eq 'rss' ? 'RSS' : 'Atom') .
5979                          " feed";
5980         }
5981         my $owner = git_get_project_owner($project);
5982         $owner = esc_html($owner);
5983
5984         #header
5985         my $alt_url;
5986         if (defined $file_name) {
5987                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
5988         } elsif (defined $hash) {
5989                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
5990         } else {
5991                 $alt_url = href(-full=>1, action=>"summary");
5992         }
5993         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
5994         if ($format eq 'rss') {
5995                 print <<XML;
5996 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
5997 <channel>
5998 XML
5999                 print "<title>$title</title>\n" .
6000                       "<link>$alt_url</link>\n" .
6001                       "<description>$descr</description>\n" .
6002                       "<language>en</language>\n";
6003         } elsif ($format eq 'atom') {
6004                 print <<XML;
6005 <feed xmlns="http://www.w3.org/2005/Atom">
6006 XML
6007                 print "<title>$title</title>\n" .
6008                       "<subtitle>$descr</subtitle>\n" .
6009                       '<link rel="alternate" type="text/html" href="' .
6010                       $alt_url . '" />' . "\n" .
6011                       '<link rel="self" type="' . $content_type . '" href="' .
6012                       $cgi->self_url() . '" />' . "\n" .
6013                       "<id>" . href(-full=>1) . "</id>\n" .
6014                       # use project owner for feed author
6015                       "<author><name>$owner</name></author>\n";
6016                 if (defined $favicon) {
6017                         print "<icon>" . esc_url($favicon) . "</icon>\n";
6018                 }
6019                 if (defined $logo_url) {
6020                         # not twice as wide as tall: 72 x 27 pixels
6021                         print "<logo>" . esc_url($logo) . "</logo>\n";
6022                 }
6023                 if (! %latest_date) {
6024                         # dummy date to keep the feed valid until commits trickle in:
6025                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
6026                 } else {
6027                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
6028                 }
6029         }
6030
6031         # contents
6032         for (my $i = 0; $i <= $#commitlist; $i++) {
6033                 my %co = %{$commitlist[$i]};
6034                 my $commit = $co{'id'};
6035                 # we read 150, we always show 30 and the ones more recent than 48 hours
6036                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
6037                         last;
6038                 }
6039                 my %cd = parse_date($co{'author_epoch'});
6040
6041                 # get list of changed files
6042                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6043                         $co{'parent'} || "--root",
6044                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
6045                         or next;
6046                 my @difftree = map { chomp; $_ } <$fd>;
6047                 close $fd
6048                         or next;
6049
6050                 # print element (entry, item)
6051                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
6052                 if ($format eq 'rss') {
6053                         print "<item>\n" .
6054                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
6055                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
6056                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
6057                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
6058                               "<link>$co_url</link>\n" .
6059                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
6060                               "<content:encoded>" .
6061                               "<![CDATA[\n";
6062                 } elsif ($format eq 'atom') {
6063                         print "<entry>\n" .
6064                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
6065                               "<updated>$cd{'iso-8601'}</updated>\n" .
6066                               "<author>\n" .
6067                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
6068                         if ($co{'author_email'}) {
6069                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
6070                         }
6071                         print "</author>\n" .
6072                               # use committer for contributor
6073                               "<contributor>\n" .
6074                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
6075                         if ($co{'committer_email'}) {
6076                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
6077                         }
6078                         print "</contributor>\n" .
6079                               "<published>$cd{'iso-8601'}</published>\n" .
6080                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
6081                               "<id>$co_url</id>\n" .
6082                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
6083                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
6084                 }
6085                 my $comment = $co{'comment'};
6086                 print "<pre>\n";
6087                 foreach my $line (@$comment) {
6088                         $line = esc_html($line);
6089                         print "$line\n";
6090                 }
6091                 print "</pre><ul>\n";
6092                 foreach my $difftree_line (@difftree) {
6093                         my %difftree = parse_difftree_raw_line($difftree_line);
6094                         next if !$difftree{'from_id'};
6095
6096                         my $file = $difftree{'file'} || $difftree{'to_file'};
6097
6098                         print "<li>" .
6099                               "[" .
6100                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
6101                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
6102                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
6103                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
6104                                       -title => "diff"}, 'D');
6105                         if ($have_blame) {
6106                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
6107                                                              file_name=>$file, hash_base=>$commit),
6108                                               -title => "blame"}, 'B');
6109                         }
6110                         # if this is not a feed of a file history
6111                         if (!defined $file_name || $file_name ne $file) {
6112                                 print $cgi->a({-href => href(-full=>1, action=>"history",
6113                                                              file_name=>$file, hash=>$commit),
6114                                               -title => "history"}, 'H');
6115                         }
6116                         $file = esc_path($file);
6117                         print "] ".
6118                               "$file</li>\n";
6119                 }
6120                 if ($format eq 'rss') {
6121                         print "</ul>]]>\n" .
6122                               "</content:encoded>\n" .
6123                               "</item>\n";
6124                 } elsif ($format eq 'atom') {
6125                         print "</ul>\n</div>\n" .
6126                               "</content>\n" .
6127                               "</entry>\n";
6128                 }
6129         }
6130
6131         # end of feed
6132         if ($format eq 'rss') {
6133                 print "</channel>\n</rss>\n";
6134         }       elsif ($format eq 'atom') {
6135                 print "</feed>\n";
6136         }
6137 }
6138
6139 sub git_rss {
6140         git_feed('rss');
6141 }
6142
6143 sub git_atom {
6144         git_feed('atom');
6145 }
6146
6147 sub git_opml {
6148         my @list = git_get_projects_list();
6149
6150         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
6151         print <<XML;
6152 <?xml version="1.0" encoding="utf-8"?>
6153 <opml version="1.0">
6154 <head>
6155   <title>$site_name OPML Export</title>
6156 </head>
6157 <body>
6158 <outline text="git RSS feeds">
6159 XML
6160
6161         foreach my $pr (@list) {
6162                 my %proj = %$pr;
6163                 my $head = git_get_head_hash($proj{'path'});
6164                 if (!defined $head) {
6165                         next;
6166                 }
6167                 $git_dir = "$projectroot/$proj{'path'}";
6168                 my %co = parse_commit($head);
6169                 if (!%co) {
6170                         next;
6171                 }
6172
6173                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
6174                 my $rss  = "$my_url?p=$proj{'path'};a=rss";
6175                 my $html = "$my_url?p=$proj{'path'};a=summary";
6176                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
6177         }
6178         print <<XML;
6179 </outline>
6180 </body>
6181 </opml>
6182 XML
6183 }