git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitworktree {}
 125 set _isbare {}
 126 set _gitexec {}
 127 set _githtmldir {}
 128 set _reponame {}
 129 set _iscygwin {}
 130 set _search_path {}
 131
 132 set _trace [lsearch -exact $argv --trace]
 133 if {$_trace >= 0} {
 134         set argv [lreplace $argv $_trace $_trace]
 135         set _trace 1
 136 } else {
 137         set _trace 0
 138 }
 139
 140 proc appname {} {
 141         global _appname
 142         return $_appname
 143 }
 144
 145 proc gitdir {args} {
 146         global _gitdir
 147         if {$args eq {}} {
 148                 return $_gitdir
 149         }
 150         return [eval [list file join $_gitdir] $args]
 151 }
 152
 153 proc gitexec {args} {
 154         global _gitexec
 155         if {$_gitexec eq {}} {
 156                 if {[catch {set _gitexec [git --exec-path]} err]} {
 157                         error "Git not installed?\n\n$err"
 158                 }
 159                 if {[is_Cygwin]} {
 160                         set _gitexec [exec cygpath \
 161                                 --windows \
 162                                 --absolute \
 163                                 $_gitexec]
 164                 } else {
 165                         set _gitexec [file normalize $_gitexec]
 166                 }
 167         }
 168         if {$args eq {}} {
 169                 return $_gitexec
 170         }
 171         return [eval [list file join $_gitexec] $args]
 172 }
 173
 174 proc githtmldir {args} {
 175         global _githtmldir
 176         if {$_githtmldir eq {}} {
 177                 if {[catch {set _githtmldir [git --html-path]}]} {
 178                         # Git not installed or option not yet supported
 179                         return {}
 180                 }
 181                 if {[is_Cygwin]} {
 182                         set _githtmldir [exec cygpath \
 183                                 --windows \
 184                                 --absolute \
 185                                 $_githtmldir]
 186                 } else {
 187                         set _githtmldir [file normalize $_githtmldir]
 188                 }
 189         }
 190         if {$args eq {}} {
 191                 return $_githtmldir
 192         }
 193         return [eval [list file join $_githtmldir] $args]
 194 }
 195
 196 proc reponame {} {
 197         return $::_reponame
 198 }
 199
 200 proc is_MacOSX {} {
 201         if {[tk windowingsystem] eq {aqua}} {
 202                 return 1
 203         }
 204         return 0
 205 }
 206
 207 proc is_Windows {} {
 208         if {$::tcl_platform(platform) eq {windows}} {
 209                 return 1
 210         }
 211         return 0
 212 }
 213
 214 proc is_Cygwin {} {
 215         global _iscygwin
 216         if {$_iscygwin eq {}} {
 217                 if {$::tcl_platform(platform) eq {windows}} {
 218                         if {[catch {set p [exec cygpath --windir]} err]} {
 219                                 set _iscygwin 0
 220                         } else {
 221                                 set _iscygwin 1
 222                         }
 223                 } else {
 224                         set _iscygwin 0
 225                 }
 226         }
 227         return $_iscygwin
 228 }
 229
 230 proc is_enabled {option} {
 231         global enabled_options
 232         if {[catch {set on $enabled_options($option)}]} {return 0}
 233         return $on
 234 }
 235
 236 proc enable_option {option} {
 237         global enabled_options
 238         set enabled_options($option) 1
 239 }
 240
 241 proc disable_option {option} {
 242         global enabled_options
 243         set enabled_options($option) 0
 244 }
 245
 246 ######################################################################
 247 ##
 248 ## config
 249
 250 proc is_many_config {name} {
 251         switch -glob -- $name {
 252         gui.recentrepo -
 253         remote.*.fetch -
 254         remote.*.push
 255                 {return 1}
 256         *
 257                 {return 0}
 258         }
 259 }
 260
 261 proc is_config_true {name} {
 262         global repo_config
 263         if {[catch {set v $repo_config($name)}]} {
 264                 return 0
 265         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 266                 return 1
 267         } else {
 268                 return 0
 269         }
 270 }
 271
 272 proc get_config {name} {
 273         global repo_config
 274         if {[catch {set v $repo_config($name)}]} {
 275                 return {}
 276         } else {
 277                 return $v
 278         }
 279 }
 280
 281 proc is_bare {} {
 282         global _isbare
 283         global _gitdir
 284         global _gitworktree
 285
 286         if {$_isbare eq {}} {
 287                 if {[catch {
 288                         set _bare [git rev-parse --is-bare-repository]
 289                         switch  -- $_bare {
 290                         true { set _isbare 1 }
 291                         false { set _isbare 0}
 292                         default { throw }
 293                         }
 294                 }]} {
 295                         if {[is_config_true core.bare]
 296                                 || ($_gitworktree eq {}
 297                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 298                                 set _isbare 1
 299                         } else {
 300                                 set _isbare 0
 301                         }
 302                 }
 303         }
 304         return $_isbare
 305 }
 306
 307 ######################################################################
 308 ##
 309 ## handy utils
 310
 311 proc _trace_exec {cmd} {
 312         if {!$::_trace} return
 313         set d {}
 314         foreach v $cmd {
 315                 if {$d ne {}} {
 316                         append d { }
 317                 }
 318                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 319                         set v [sq $v]
 320                 }
 321                 append d $v
 322         }
 323         puts stderr $d
 324 }
 325
 326 proc _git_cmd {name} {
 327         global _git_cmd_path
 328
 329         if {[catch {set v $_git_cmd_path($name)}]} {
 330                 switch -- $name {
 331                   version   -
 332                 --version   -
 333                 --exec-path { return [list $::_git $name] }
 334                 }
 335
 336                 set p [gitexec git-$name$::_search_exe]
 337                 if {[file exists $p]} {
 338                         set v [list $p]
 339                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 340                         # Try to determine what sort of magic will make
 341                         # git-$name go and do its thing, because native
 342                         # Tcl on Windows doesn't know it.
 343                         #
 344                         set p [gitexec git-$name]
 345                         set f [open $p r]
 346                         set s [gets $f]
 347                         close $f
 348
 349                         switch -glob -- [lindex $s 0] {
 350                         #!*sh     { set i sh     }
 351                         #!*perl   { set i perl   }
 352                         #!*python { set i python }
 353                         default   { error "git-$name is not supported: $s" }
 354                         }
 355
 356                         upvar #0 _$i interp
 357                         if {![info exists interp]} {
 358                                 set interp [_which $i]
 359                         }
 360                         if {$interp eq {}} {
 361                                 error "git-$name requires $i (not in PATH)"
 362                         }
 363                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 364                 } else {
 365                         # Assume it is builtin to git somehow and we
 366                         # aren't actually able to see a file for it.
 367                         #
 368                         set v [list $::_git $name]
 369                 }
 370                 set _git_cmd_path($name) $v
 371         }
 372         return $v
 373 }
 374
 375 proc _which {what args} {
 376         global env _search_exe _search_path
 377
 378         if {$_search_path eq {}} {
 379                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 380                         set _search_path [split [exec cygpath \
 381                                 --windows \
 382                                 --path \
 383                                 --absolute \
 384                                 $env(PATH)] {;}]
 385                         set _search_exe .exe
 386                 } elseif {[is_Windows]} {
 387                         set gitguidir [file dirname [info script]]
 388                         regsub -all ";" $gitguidir "\\;" gitguidir
 389                         set env(PATH) "$gitguidir;$env(PATH)"
 390                         set _search_path [split $env(PATH) {;}]
 391                         set _search_exe .exe
 392                 } else {
 393                         set _search_path [split $env(PATH) :]
 394                         set _search_exe {}
 395                 }
 396         }
 397
 398         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 399                 set suffix {}
 400         } else {
 401                 set suffix $_search_exe
 402         }
 403
 404         foreach p $_search_path {
 405                 set p [file join $p $what$suffix]
 406                 if {[file exists $p]} {
 407                         return [file normalize $p]
 408                 }
 409         }
 410         return {}
 411 }
 412
 413 proc _lappend_nice {cmd_var} {
 414         global _nice
 415         upvar $cmd_var cmd
 416
 417         if {![info exists _nice]} {
 418                 set _nice [_which nice]
 419         }
 420         if {$_nice ne {}} {
 421                 lappend cmd $_nice
 422         }
 423 }
 424
 425 proc git {args} {
 426         set opt [list]
 427
 428         while {1} {
 429                 switch -- [lindex $args 0] {
 430                 --nice {
 431                         _lappend_nice opt
 432                 }
 433
 434                 default {
 435                         break
 436                 }
 437
 438                 }
 439
 440                 set args [lrange $args 1 end]
 441         }
 442
 443         set cmdp [_git_cmd [lindex $args 0]]
 444         set args [lrange $args 1 end]
 445
 446         _trace_exec [concat $opt $cmdp $args]
 447         set result [eval exec $opt $cmdp $args]
 448         if {$::_trace} {
 449                 puts stderr "< $result"
 450         }
 451         return $result
 452 }
 453
 454 proc _open_stdout_stderr {cmd} {
 455         _trace_exec $cmd
 456         if {[catch {
 457                         set fd [open [concat [list | ] $cmd] r]
 458                 } err]} {
 459                 if {   [lindex $cmd end] eq {2>@1}
 460                     && $err eq {can not find channel named "1"}
 461                         } {
 462                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 463                         # redirect operator.  Fallback to |& cat for those.
 464                         # The command was not actually started, so its safe
 465                         # to try to start it a second time.
 466                         #
 467                         set fd [open [concat \
 468                                 [list | ] \
 469                                 [lrange $cmd 0 end-1] \
 470                                 [list |& cat] \
 471                                 ] r]
 472                 } else {
 473                         error $err
 474                 }
 475         }
 476         fconfigure $fd -eofchar {}
 477         return $fd
 478 }
 479
 480 proc git_read {args} {
 481         set opt [list]
 482
 483         while {1} {
 484                 switch -- [lindex $args 0] {
 485                 --nice {
 486                         _lappend_nice opt
 487                 }
 488
 489                 --stderr {
 490                         lappend args 2>@1
 491                 }
 492
 493                 default {
 494                         break
 495                 }
 496
 497                 }
 498
 499                 set args [lrange $args 1 end]
 500         }
 501
 502         set cmdp [_git_cmd [lindex $args 0]]
 503         set args [lrange $args 1 end]
 504
 505         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 506 }
 507
 508 proc git_write {args} {
 509         set opt [list]
 510
 511         while {1} {
 512                 switch -- [lindex $args 0] {
 513                 --nice {
 514                         _lappend_nice opt
 515                 }
 516
 517                 default {
 518                         break
 519                 }
 520
 521                 }
 522
 523                 set args [lrange $args 1 end]
 524         }
 525
 526         set cmdp [_git_cmd [lindex $args 0]]
 527         set args [lrange $args 1 end]
 528
 529         _trace_exec [concat $opt $cmdp $args]
 530         return [open [concat [list | ] $opt $cmdp $args] w]
 531 }
 532
 533 proc githook_read {hook_name args} {
 534         set pchook [gitdir hooks $hook_name]
 535         lappend args 2>@1
 536
 537         # On Windows [file executable] might lie so we need to ask
 538         # the shell if the hook is executable.  Yes that's annoying.
 539         #
 540         if {[is_Windows]} {
 541                 upvar #0 _sh interp
 542                 if {![info exists interp]} {
 543                         set interp [_which sh]
 544                 }
 545                 if {$interp eq {}} {
 546                         error "hook execution requires sh (not in PATH)"
 547                 }
 548
 549                 set scr {if test -x "$1";then exec "$@";fi}
 550                 set sh_c [list $interp -c $scr $interp $pchook]
 551                 return [_open_stdout_stderr [concat $sh_c $args]]
 552         }
 553
 554         if {[file executable $pchook]} {
 555                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 556         }
 557
 558         return {}
 559 }
 560
 561 proc kill_file_process {fd} {
 562         set process [pid $fd]
 563
 564         catch {
 565                 if {[is_Windows]} {
 566                         # Use a Cygwin-specific flag to allow killing
 567                         # native Windows processes
 568                         exec kill -f $process
 569                 } else {
 570                         exec kill $process
 571                 }
 572         }
 573 }
 574
 575 proc gitattr {path attr default} {
 576         if {[catch {set r [git check-attr $attr -- $path]}]} {
 577                 set r unspecified
 578         } else {
 579                 set r [join [lrange [split $r :] 2 end] :]
 580                 regsub {^ } $r {} r
 581         }
 582         if {$r eq {unspecified}} {
 583                 return $default
 584         }
 585         return $r
 586 }
 587
 588 proc sq {value} {
 589         regsub -all ' $value "'\\''" value
 590         return "'$value'"
 591 }
 592
 593 proc load_current_branch {} {
 594         global current_branch is_detached
 595
 596         set fd [open [gitdir HEAD] r]
 597         if {[gets $fd ref] < 1} {
 598                 set ref {}
 599         }
 600         close $fd
 601
 602         set pfx {ref: refs/heads/}
 603         set len [string length $pfx]
 604         if {[string equal -length $len $pfx $ref]} {
 605                 # We're on a branch.  It might not exist.  But
 606                 # HEAD looks good enough to be a branch.
 607                 #
 608                 set current_branch [string range $ref $len end]
 609                 set is_detached 0
 610         } else {
 611                 # Assume this is a detached head.
 612                 #
 613                 set current_branch HEAD
 614                 set is_detached 1
 615         }
 616 }
 617
 618 auto_load tk_optionMenu
 619 rename tk_optionMenu real__tkOptionMenu
 620 proc tk_optionMenu {w varName args} {
 621         set m [eval real__tkOptionMenu $w $varName $args]
 622         $m configure -font font_ui
 623         $w configure -font font_ui
 624         return $m
 625 }
 626
 627 proc rmsel_tag {text} {
 628         $text tag conf sel \
 629                 -background [$text cget -background] \
 630                 -foreground [$text cget -foreground] \
 631                 -borderwidth 0
 632         $text tag conf in_sel -background lightgray
 633         bind $text <Motion> break
 634         return $text
 635 }
 636
 637 set root_exists 0
 638 bind . <Visibility> {
 639         bind . <Visibility> {}
 640         set root_exists 1
 641 }
 642
 643 if {[is_Windows]} {
 644         wm iconbitmap . -default $oguilib/git-gui.ico
 645         set ::tk::AlwaysShowSelection 1
 646
 647         # Spoof an X11 display for SSH
 648         if {![info exists env(DISPLAY)]} {
 649                 set env(DISPLAY) :9999
 650         }
 651 } else {
 652         catch {
 653                 image create photo gitlogo -width 16 -height 16
 654
 655                 gitlogo put #33CC33 -to  7  0  9  2
 656                 gitlogo put #33CC33 -to  4  2 12  4
 657                 gitlogo put #33CC33 -to  7  4  9  6
 658                 gitlogo put #CC3333 -to  4  6 12  8
 659                 gitlogo put gray26  -to  4  9  6 10
 660                 gitlogo put gray26  -to  3 10  6 12
 661                 gitlogo put gray26  -to  8  9 13 11
 662                 gitlogo put gray26  -to  8 11 10 12
 663                 gitlogo put gray26  -to 11 11 13 14
 664                 gitlogo put gray26  -to  3 12  5 14
 665                 gitlogo put gray26  -to  5 13
 666                 gitlogo put gray26  -to 10 13
 667                 gitlogo put gray26  -to  4 14 12 15
 668                 gitlogo put gray26  -to  5 15 11 16
 669                 gitlogo redither
 670
 671                 wm iconphoto . -default gitlogo
 672         }
 673 }
 674
 675 ######################################################################
 676 ##
 677 ## config defaults
 678
 679 set cursor_ptr arrow
 680 font create font_diff -family Courier -size 10
 681 font create font_ui
 682 catch {
 683         label .dummy
 684         eval font configure font_ui [font actual [.dummy cget -font]]
 685         destroy .dummy
 686 }
 687
 688 font create font_uiitalic
 689 font create font_uibold
 690 font create font_diffbold
 691 font create font_diffitalic
 692
 693 foreach class {Button Checkbutton Entry Label
 694                 Labelframe Listbox Message
 695                 Radiobutton Spinbox Text} {
 696         option add *$class.font font_ui
 697 }
 698 if {![is_MacOSX]} {
 699         option add *Menu.font font_ui
 700 }
 701 unset class
 702
 703 if {[is_Windows] || [is_MacOSX]} {
 704         option add *Menu.tearOff 0
 705 }
 706
 707 if {[is_MacOSX]} {
 708         set M1B M1
 709         set M1T Cmd
 710 } else {
 711         set M1B Control
 712         set M1T Ctrl
 713 }
 714
 715 proc bind_button3 {w cmd} {
 716         bind $w <Any-Button-3> $cmd
 717         if {[is_MacOSX]} {
 718                 # Mac OS X sends Button-2 on right click through three-button mouse,
 719                 # or through trackpad right-clicking (two-finger touch + click).
 720                 bind $w <Any-Button-2> $cmd
 721                 bind $w <Control-Button-1> $cmd
 722         }
 723 }
 724
 725 proc apply_config {} {
 726         global repo_config font_descs
 727
 728         foreach option $font_descs {
 729                 set name [lindex $option 0]
 730                 set font [lindex $option 1]
 731                 if {[catch {
 732                         set need_weight 1
 733                         foreach {cn cv} $repo_config(gui.$name) {
 734                                 if {$cn eq {-weight}} {
 735                                         set need_weight 0
 736                                 }
 737                                 font configure $font $cn $cv
 738                         }
 739                         if {$need_weight} {
 740                                 font configure $font -weight normal
 741                         }
 742                         } err]} {
 743                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 744                 }
 745                 foreach {cn cv} [font configure $font] {
 746                         font configure ${font}bold $cn $cv
 747                         font configure ${font}italic $cn $cv
 748                 }
 749                 font configure ${font}bold -weight bold
 750                 font configure ${font}italic -slant italic
 751         }
 752 }
 753
 754 set default_config(branch.autosetupmerge) true
 755 set default_config(merge.tool) {}
 756 set default_config(mergetool.keepbackup) true
 757 set default_config(merge.diffstat) true
 758 set default_config(merge.summary) false
 759 set default_config(merge.verbosity) 2
 760 set default_config(user.name) {}
 761 set default_config(user.email) {}
 762
 763 set default_config(gui.encoding) [encoding system]
 764 set default_config(gui.matchtrackingbranch) false
 765 set default_config(gui.pruneduringfetch) false
 766 set default_config(gui.trustmtime) false
 767 set default_config(gui.fastcopyblame) false
 768 set default_config(gui.copyblamethreshold) 40
 769 set default_config(gui.blamehistoryctx) 7
 770 set default_config(gui.diffcontext) 5
 771 set default_config(gui.commitmsgwidth) 75
 772 set default_config(gui.newbranchtemplate) {}
 773 set default_config(gui.spellingdictionary) {}
 774 set default_config(gui.fontui) [font configure font_ui]
 775 set default_config(gui.fontdiff) [font configure font_diff]
 776 # TODO: this option should be added to the git-config documentation
 777 set default_config(gui.maxfilesdisplayed) 5000
 778 set font_descs {
 779         {fontui   font_ui   {mc "Main Font"}}
 780         {fontdiff font_diff {mc "Diff/Console Font"}}
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## find git
 786
 787 set _git  [_which git]
 788 if {$_git eq {}} {
 789         catch {wm withdraw .}
 790         tk_messageBox \
 791                 -icon error \
 792                 -type ok \
 793                 -title [mc "git-gui: fatal error"] \
 794                 -message [mc "Cannot find git in PATH."]
 795         exit 1
 796 }
 797
 798 ######################################################################
 799 ##
 800 ## version check
 801
 802 if {[catch {set _git_version [git --version]} err]} {
 803         catch {wm withdraw .}
 804         tk_messageBox \
 805                 -icon error \
 806                 -type ok \
 807                 -title [mc "git-gui: fatal error"] \
 808                 -message "Cannot determine Git version:
 809
 810 $err
 811
 812 [appname] requires Git 1.5.0 or later."
 813         exit 1
 814 }
 815 if {![regsub {^git version } $_git_version {} _git_version]} {
 816         catch {wm withdraw .}
 817         tk_messageBox \
 818                 -icon error \
 819                 -type ok \
 820                 -title [mc "git-gui: fatal error"] \
 821                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 822         exit 1
 823 }
 824
 825 set _real_git_version $_git_version
 826 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 827 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 828 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 829 regsub {\.GIT$} $_git_version {} _git_version
 830 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 831
 832 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 833         catch {wm withdraw .}
 834         if {[tk_messageBox \
 835                 -icon warning \
 836                 -type yesno \
 837                 -default no \
 838                 -title "[appname]: warning" \
 839                  -message [mc "Git version cannot be determined.
 840
 841 %s claims it is version '%s'.
 842
 843 %s requires at least Git 1.5.0 or later.
 844
 845 Assume '%s' is version 1.5.0?
 846 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 847                 set _git_version 1.5.0
 848         } else {
 849                 exit 1
 850         }
 851 }
 852 unset _real_git_version
 853
 854 proc git-version {args} {
 855         global _git_version
 856
 857         switch [llength $args] {
 858         0 {
 859                 return $_git_version
 860         }
 861
 862         2 {
 863                 set op [lindex $args 0]
 864                 set vr [lindex $args 1]
 865                 set cm [package vcompare $_git_version $vr]
 866                 return [expr $cm $op 0]
 867         }
 868
 869         4 {
 870                 set type [lindex $args 0]
 871                 set name [lindex $args 1]
 872                 set parm [lindex $args 2]
 873                 set body [lindex $args 3]
 874
 875                 if {($type ne {proc} && $type ne {method})} {
 876                         error "Invalid arguments to git-version"
 877                 }
 878                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 879                         error "Last arm of $type $name must be default"
 880                 }
 881
 882                 foreach {op vr cb} [lrange $body 0 end-2] {
 883                         if {[git-version $op $vr]} {
 884                                 return [uplevel [list $type $name $parm $cb]]
 885                         }
 886                 }
 887
 888                 return [uplevel [list $type $name $parm [lindex $body end]]]
 889         }
 890
 891         default {
 892                 error "git-version >= x"
 893         }
 894
 895         }
 896 }
 897
 898 if {[git-version < 1.5]} {
 899         catch {wm withdraw .}
 900         tk_messageBox \
 901                 -icon error \
 902                 -type ok \
 903                 -title [mc "git-gui: fatal error"] \
 904                 -message "[appname] requires Git 1.5.0 or later.
 905
 906 You are using [git-version]:
 907
 908 [git --version]"
 909         exit 1
 910 }
 911
 912 ######################################################################
 913 ##
 914 ## configure our library
 915
 916 set idx [file join $oguilib tclIndex]
 917 if {[catch {set fd [open $idx r]} err]} {
 918         catch {wm withdraw .}
 919         tk_messageBox \
 920                 -icon error \
 921                 -type ok \
 922                 -title [mc "git-gui: fatal error"] \
 923                 -message $err
 924         exit 1
 925 }
 926 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 927         set idx [list]
 928         while {[gets $fd n] >= 0} {
 929                 if {$n ne {} && ![string match #* $n]} {
 930                         lappend idx $n
 931                 }
 932         }
 933 } else {
 934         set idx {}
 935 }
 936 close $fd
 937
 938 if {$idx ne {}} {
 939         set loaded [list]
 940         foreach p $idx {
 941                 if {[lsearch -exact $loaded $p] >= 0} continue
 942                 source [file join $oguilib $p]
 943                 lappend loaded $p
 944         }
 945         unset loaded p
 946 } else {
 947         set auto_path [concat [list $oguilib] $auto_path]
 948 }
 949 unset -nocomplain idx fd
 950
 951 ######################################################################
 952 ##
 953 ## config file parsing
 954
 955 git-version proc _parse_config {arr_name args} {
 956         >= 1.5.3 {
 957                 upvar $arr_name arr
 958                 array unset arr
 959                 set buf {}
 960                 catch {
 961                         set fd_rc [eval \
 962                                 [list git_read config] \
 963                                 $args \
 964                                 [list --null --list]]
 965                         fconfigure $fd_rc -translation binary
 966                         set buf [read $fd_rc]
 967                         close $fd_rc
 968                 }
 969                 foreach line [split $buf "\0"] {
 970                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 971                                 if {[is_many_config $name]} {
 972                                         lappend arr($name) $value
 973                                 } else {
 974                                         set arr($name) $value
 975                                 }
 976                         }
 977                 }
 978         }
 979         default {
 980                 upvar $arr_name arr
 981                 array unset arr
 982                 catch {
 983                         set fd_rc [eval [list git_read config --list] $args]
 984                         while {[gets $fd_rc line] >= 0} {
 985                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 986                                         if {[is_many_config $name]} {
 987                                                 lappend arr($name) $value
 988                                         } else {
 989                                                 set arr($name) $value
 990                                         }
 991                                 }
 992                         }
 993                         close $fd_rc
 994                 }
 995         }
 996 }
 997
 998 proc load_config {include_global} {
 999         global repo_config global_config system_config default_config
1000
1001         if {$include_global} {
1002                 _parse_config system_config --system
1003                 _parse_config global_config --global
1004         }
1005         _parse_config repo_config
1006
1007         foreach name [array names default_config] {
1008                 if {[catch {set v $system_config($name)}]} {
1009                         set system_config($name) $default_config($name)
1010                 }
1011         }
1012         foreach name [array names system_config] {
1013                 if {[catch {set v $global_config($name)}]} {
1014                         set global_config($name) $system_config($name)
1015                 }
1016                 if {[catch {set v $repo_config($name)}]} {
1017                         set repo_config($name) $system_config($name)
1018                 }
1019         }
1020 }
1021
1022 ######################################################################
1023 ##
1024 ## feature option selection
1025
1026 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1027         unset _junk
1028 } else {
1029         set subcommand gui
1030 }
1031 if {$subcommand eq {gui.sh}} {
1032         set subcommand gui
1033 }
1034 if {$subcommand eq {gui} && [llength $argv] > 0} {
1035         set subcommand [lindex $argv 0]
1036         set argv [lrange $argv 1 end]
1037 }
1038
1039 enable_option multicommit
1040 enable_option branch
1041 enable_option transport
1042 disable_option bare
1043
1044 switch -- $subcommand {
1045 browser -
1046 blame {
1047         enable_option bare
1048
1049         disable_option multicommit
1050         disable_option branch
1051         disable_option transport
1052 }
1053 citool {
1054         enable_option singlecommit
1055         enable_option retcode
1056
1057         disable_option multicommit
1058         disable_option branch
1059         disable_option transport
1060
1061         while {[llength $argv] > 0} {
1062                 set a [lindex $argv 0]
1063                 switch -- $a {
1064                 --amend {
1065                         enable_option initialamend
1066                 }
1067                 --nocommit {
1068                         enable_option nocommit
1069                         enable_option nocommitmsg
1070                 }
1071                 --commitmsg {
1072                         disable_option nocommitmsg
1073                 }
1074                 default {
1075                         break
1076                 }
1077                 }
1078
1079                 set argv [lrange $argv 1 end]
1080         }
1081 }
1082 }
1083
1084 ######################################################################
1085 ##
1086 ## execution environment
1087
1088 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1089
1090 # Suggest our implementation of askpass, if none is set
1091 if {![info exists env(SSH_ASKPASS)]} {
1092         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1093 }
1094
1095 ######################################################################
1096 ##
1097 ## repository setup
1098
1099 set picked 0
1100 if {[catch {
1101                 set _gitdir $env(GIT_DIR)
1102                 set _prefix {}
1103                 }]
1104         && [catch {
1105                 # beware that from the .git dir this sets _gitdir to .
1106                 # and _prefix to the empty string
1107                 set _gitdir [git rev-parse --git-dir]
1108                 set _prefix [git rev-parse --show-prefix]
1109         } err]} {
1110         load_config 1
1111         apply_config
1112         choose_repository::pick
1113         set picked 1
1114 }
1115
1116 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1117 # run from the .git dir itself) lest the routines to find the worktree
1118 # get confused
1119 if {$_gitdir eq "."} {
1120         set _gitdir [pwd]
1121 }
1122
1123 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1124         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1125 }
1126 if {![file isdirectory $_gitdir]} {
1127         catch {wm withdraw .}
1128         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1129         exit 1
1130 }
1131 # _gitdir exists, so try loading the config
1132 load_config 0
1133 apply_config
1134 # try to set work tree from environment, falling back to core.worktree
1135 if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1136         set _gitworktree [get_config core.worktree]
1137 }
1138 if {$_prefix ne {}} {
1139         if {$_gitworktree eq {}} {
1140                 regsub -all {[^/]+/} $_prefix ../ cdup
1141         } else {
1142                 set cdup $_gitworktree
1143         }
1144         if {[catch {cd $cdup} err]} {
1145                 catch {wm withdraw .}
1146                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1147                 exit 1
1148         }
1149         set _gitworktree [pwd]
1150         unset cdup
1151 } elseif {![is_enabled bare]} {
1152         if {[is_bare]} {
1153                 catch {wm withdraw .}
1154                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1155                 exit 1
1156         }
1157         if {$_gitworktree eq {}} {
1158                 set _gitworktree [file dirname $_gitdir]
1159         }
1160         if {[catch {cd $_gitworktree} err]} {
1161                 catch {wm withdraw .}
1162                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1163                 exit 1
1164         }
1165         set _gitworktree [pwd]
1166 }
1167 set _reponame [file split [file normalize $_gitdir]]
1168 if {[lindex $_reponame end] eq {.git}} {
1169         set _reponame [lindex $_reponame end-1]
1170 } else {
1171         set _reponame [lindex $_reponame end]
1172 }
1173
1174 set env(GIT_DIR) $_gitdir
1175 set env(GIT_WORK_TREE) $_gitworktree
1176
1177 ######################################################################
1178 ##
1179 ## global init
1180
1181 set current_diff_path {}
1182 set current_diff_side {}
1183 set diff_actions [list]
1184
1185 set HEAD {}
1186 set PARENT {}
1187 set MERGE_HEAD [list]
1188 set commit_type {}
1189 set empty_tree {}
1190 set current_branch {}
1191 set is_detached 0
1192 set current_diff_path {}
1193 set is_3way_diff 0
1194 set is_submodule_diff 0
1195 set is_conflict_diff 0
1196 set selected_commit_type new
1197 set diff_empty_count 0
1198
1199 set nullid "0000000000000000000000000000000000000000"
1200 set nullid2 "0000000000000000000000000000000000000001"
1201
1202 ######################################################################
1203 ##
1204 ## task management
1205
1206 set rescan_active 0
1207 set diff_active 0
1208 set last_clicked {}
1209
1210 set disable_on_lock [list]
1211 set index_lock_type none
1212
1213 proc lock_index {type} {
1214         global index_lock_type disable_on_lock
1215
1216         if {$index_lock_type eq {none}} {
1217                 set index_lock_type $type
1218                 foreach w $disable_on_lock {
1219                         uplevel #0 $w disabled
1220                 }
1221                 return 1
1222         } elseif {$index_lock_type eq "begin-$type"} {
1223                 set index_lock_type $type
1224                 return 1
1225         }
1226         return 0
1227 }
1228
1229 proc unlock_index {} {
1230         global index_lock_type disable_on_lock
1231
1232         set index_lock_type none
1233         foreach w $disable_on_lock {
1234                 uplevel #0 $w normal
1235         }
1236 }
1237
1238 ######################################################################
1239 ##
1240 ## status
1241
1242 proc repository_state {ctvar hdvar mhvar} {
1243         global current_branch
1244         upvar $ctvar ct $hdvar hd $mhvar mh
1245
1246         set mh [list]
1247
1248         load_current_branch
1249         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1250                 set hd {}
1251                 set ct initial
1252                 return
1253         }
1254
1255         set merge_head [gitdir MERGE_HEAD]
1256         if {[file exists $merge_head]} {
1257                 set ct merge
1258                 set fd_mh [open $merge_head r]
1259                 while {[gets $fd_mh line] >= 0} {
1260                         lappend mh $line
1261                 }
1262                 close $fd_mh
1263                 return
1264         }
1265
1266         set ct normal
1267 }
1268
1269 proc PARENT {} {
1270         global PARENT empty_tree
1271
1272         set p [lindex $PARENT 0]
1273         if {$p ne {}} {
1274                 return $p
1275         }
1276         if {$empty_tree eq {}} {
1277                 set empty_tree [git mktree << {}]
1278         }
1279         return $empty_tree
1280 }
1281
1282 proc force_amend {} {
1283         global selected_commit_type
1284         global HEAD PARENT MERGE_HEAD commit_type
1285
1286         repository_state newType newHEAD newMERGE_HEAD
1287         set HEAD $newHEAD
1288         set PARENT $newHEAD
1289         set MERGE_HEAD $newMERGE_HEAD
1290         set commit_type $newType
1291
1292         set selected_commit_type amend
1293         do_select_commit_type
1294 }
1295
1296 proc rescan {after {honor_trustmtime 1}} {
1297         global HEAD PARENT MERGE_HEAD commit_type
1298         global ui_index ui_workdir ui_comm
1299         global rescan_active file_states
1300         global repo_config
1301
1302         if {$rescan_active > 0 || ![lock_index read]} return
1303
1304         repository_state newType newHEAD newMERGE_HEAD
1305         if {[string match amend* $commit_type]
1306                 && $newType eq {normal}
1307                 && $newHEAD eq $HEAD} {
1308         } else {
1309                 set HEAD $newHEAD
1310                 set PARENT $newHEAD
1311                 set MERGE_HEAD $newMERGE_HEAD
1312                 set commit_type $newType
1313         }
1314
1315         array unset file_states
1316
1317         if {!$::GITGUI_BCK_exists &&
1318                 (![$ui_comm edit modified]
1319                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1320                 if {[string match amend* $commit_type]} {
1321                 } elseif {[load_message GITGUI_MSG]} {
1322                 } elseif {[run_prepare_commit_msg_hook]} {
1323                 } elseif {[load_message MERGE_MSG]} {
1324                 } elseif {[load_message SQUASH_MSG]} {
1325                 }
1326                 $ui_comm edit reset
1327                 $ui_comm edit modified false
1328         }
1329
1330         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1331                 rescan_stage2 {} $after
1332         } else {
1333                 set rescan_active 1
1334                 ui_status [mc "Refreshing file status..."]
1335                 set fd_rf [git_read update-index \
1336                         -q \
1337                         --unmerged \
1338                         --ignore-missing \
1339                         --refresh \
1340                         ]
1341                 fconfigure $fd_rf -blocking 0 -translation binary
1342                 fileevent $fd_rf readable \
1343                         [list rescan_stage2 $fd_rf $after]
1344         }
1345 }
1346
1347 if {[is_Cygwin]} {
1348         set is_git_info_exclude {}
1349         proc have_info_exclude {} {
1350                 global is_git_info_exclude
1351
1352                 if {$is_git_info_exclude eq {}} {
1353                         if {[catch {exec test -f [gitdir info exclude]}]} {
1354                                 set is_git_info_exclude 0
1355                         } else {
1356                                 set is_git_info_exclude 1
1357                         }
1358                 }
1359                 return $is_git_info_exclude
1360         }
1361 } else {
1362         proc have_info_exclude {} {
1363                 return [file readable [gitdir info exclude]]
1364         }
1365 }
1366
1367 proc rescan_stage2 {fd after} {
1368         global rescan_active buf_rdi buf_rdf buf_rlo
1369
1370         if {$fd ne {}} {
1371                 read $fd
1372                 if {![eof $fd]} return
1373                 close $fd
1374         }
1375
1376         set ls_others [list --exclude-per-directory=.gitignore]
1377         if {[have_info_exclude]} {
1378                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1379         }
1380         set user_exclude [get_config core.excludesfile]
1381         if {$user_exclude ne {} && [file readable $user_exclude]} {
1382                 lappend ls_others "--exclude-from=$user_exclude"
1383         }
1384
1385         set buf_rdi {}
1386         set buf_rdf {}
1387         set buf_rlo {}
1388
1389         set rescan_active 3
1390         ui_status [mc "Scanning for modified files ..."]
1391         set fd_di [git_read diff-index --cached -z [PARENT]]
1392         set fd_df [git_read diff-files -z]
1393         set fd_lo [eval git_read ls-files --others -z $ls_others]
1394
1395         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1396         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1397         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1398         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1399         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1400         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1401 }
1402
1403 proc load_message {file} {
1404         global ui_comm
1405
1406         set f [gitdir $file]
1407         if {[file isfile $f]} {
1408                 if {[catch {set fd [open $f r]}]} {
1409                         return 0
1410                 }
1411                 fconfigure $fd -eofchar {}
1412                 set content [string trim [read $fd]]
1413                 close $fd
1414                 regsub -all -line {[ \r\t]+$} $content {} content
1415                 $ui_comm delete 0.0 end
1416                 $ui_comm insert end $content
1417                 return 1
1418         }
1419         return 0
1420 }
1421
1422 proc run_prepare_commit_msg_hook {} {
1423         global pch_error
1424
1425         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1426         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1427         # empty file but existant file.
1428
1429         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1430
1431         if {[file isfile [gitdir MERGE_MSG]]} {
1432                 set pcm_source "merge"
1433                 set fd_mm [open [gitdir MERGE_MSG] r]
1434                 puts -nonewline $fd_pcm [read $fd_mm]
1435                 close $fd_mm
1436         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1437                 set pcm_source "squash"
1438                 set fd_sm [open [gitdir SQUASH_MSG] r]
1439                 puts -nonewline $fd_pcm [read $fd_sm]
1440                 close $fd_sm
1441         } else {
1442                 set pcm_source ""
1443         }
1444
1445         close $fd_pcm
1446
1447         set fd_ph [githook_read prepare-commit-msg \
1448                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1449         if {$fd_ph eq {}} {
1450                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1451                 return 0;
1452         }
1453
1454         ui_status [mc "Calling prepare-commit-msg hook..."]
1455         set pch_error {}
1456
1457         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1458         fileevent $fd_ph readable \
1459                 [list prepare_commit_msg_hook_wait $fd_ph]
1460
1461         return 1;
1462 }
1463
1464 proc prepare_commit_msg_hook_wait {fd_ph} {
1465         global pch_error
1466
1467         append pch_error [read $fd_ph]
1468         fconfigure $fd_ph -blocking 1
1469         if {[eof $fd_ph]} {
1470                 if {[catch {close $fd_ph}]} {
1471                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1472                         hook_failed_popup prepare-commit-msg $pch_error
1473                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1474                         exit 1
1475                 } else {
1476                         load_message PREPARE_COMMIT_MSG
1477                 }
1478                 set pch_error {}
1479                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1480                 return
1481         }
1482         fconfigure $fd_ph -blocking 0
1483         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1484 }
1485
1486 proc read_diff_index {fd after} {
1487         global buf_rdi
1488
1489         append buf_rdi [read $fd]
1490         set c 0
1491         set n [string length $buf_rdi]
1492         while {$c < $n} {
1493                 set z1 [string first "\0" $buf_rdi $c]
1494                 if {$z1 == -1} break
1495                 incr z1
1496                 set z2 [string first "\0" $buf_rdi $z1]
1497                 if {$z2 == -1} break
1498
1499                 incr c
1500                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1501                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1502                 merge_state \
1503                         [encoding convertfrom $p] \
1504                         [lindex $i 4]? \
1505                         [list [lindex $i 0] [lindex $i 2]] \
1506                         [list]
1507                 set c $z2
1508                 incr c
1509         }
1510         if {$c < $n} {
1511                 set buf_rdi [string range $buf_rdi $c end]
1512         } else {
1513                 set buf_rdi {}
1514         }
1515
1516         rescan_done $fd buf_rdi $after
1517 }
1518
1519 proc read_diff_files {fd after} {
1520         global buf_rdf
1521
1522         append buf_rdf [read $fd]
1523         set c 0
1524         set n [string length $buf_rdf]
1525         while {$c < $n} {
1526                 set z1 [string first "\0" $buf_rdf $c]
1527                 if {$z1 == -1} break
1528                 incr z1
1529                 set z2 [string first "\0" $buf_rdf $z1]
1530                 if {$z2 == -1} break
1531
1532                 incr c
1533                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1534                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1535                 merge_state \
1536                         [encoding convertfrom $p] \
1537                         ?[lindex $i 4] \
1538                         [list] \
1539                         [list [lindex $i 0] [lindex $i 2]]
1540                 set c $z2
1541                 incr c
1542         }
1543         if {$c < $n} {
1544                 set buf_rdf [string range $buf_rdf $c end]
1545         } else {
1546                 set buf_rdf {}
1547         }
1548
1549         rescan_done $fd buf_rdf $after
1550 }
1551
1552 proc read_ls_others {fd after} {
1553         global buf_rlo
1554
1555         append buf_rlo [read $fd]
1556         set pck [split $buf_rlo "\0"]
1557         set buf_rlo [lindex $pck end]
1558         foreach p [lrange $pck 0 end-1] {
1559                 set p [encoding convertfrom $p]
1560                 if {[string index $p end] eq {/}} {
1561                         set p [string range $p 0 end-1]
1562                 }
1563                 merge_state $p ?O
1564         }
1565         rescan_done $fd buf_rlo $after
1566 }
1567
1568 proc rescan_done {fd buf after} {
1569         global rescan_active current_diff_path
1570         global file_states repo_config
1571         upvar $buf to_clear
1572
1573         if {![eof $fd]} return
1574         set to_clear {}
1575         close $fd
1576         if {[incr rescan_active -1] > 0} return
1577
1578         prune_selection
1579         unlock_index
1580         display_all_files
1581         if {$current_diff_path ne {}} { reshow_diff $after }
1582         if {$current_diff_path eq {}} { select_first_diff $after }
1583 }
1584
1585 proc prune_selection {} {
1586         global file_states selected_paths
1587
1588         foreach path [array names selected_paths] {
1589                 if {[catch {set still_here $file_states($path)}]} {
1590                         unset selected_paths($path)
1591                 }
1592         }
1593 }
1594
1595 ######################################################################
1596 ##
1597 ## ui helpers
1598
1599 proc mapicon {w state path} {
1600         global all_icons
1601
1602         if {[catch {set r $all_icons($state$w)}]} {
1603                 puts "error: no icon for $w state={$state} $path"
1604                 return file_plain
1605         }
1606         return $r
1607 }
1608
1609 proc mapdesc {state path} {
1610         global all_descs
1611
1612         if {[catch {set r $all_descs($state)}]} {
1613                 puts "error: no desc for state={$state} $path"
1614                 return $state
1615         }
1616         return $r
1617 }
1618
1619 proc ui_status {msg} {
1620         global main_status
1621         if {[info exists main_status]} {
1622                 $main_status show $msg
1623         }
1624 }
1625
1626 proc ui_ready {{test {}}} {
1627         global main_status
1628         if {[info exists main_status]} {
1629                 $main_status show [mc "Ready."] $test
1630         }
1631 }
1632
1633 proc escape_path {path} {
1634         regsub -all {\\} $path "\\\\" path
1635         regsub -all "\n" $path "\\n" path
1636         return $path
1637 }
1638
1639 proc short_path {path} {
1640         return [escape_path [lindex [file split $path] end]]
1641 }
1642
1643 set next_icon_id 0
1644 set null_sha1 [string repeat 0 40]
1645
1646 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1647         global file_states next_icon_id null_sha1
1648
1649         set s0 [string index $new_state 0]
1650         set s1 [string index $new_state 1]
1651
1652         if {[catch {set info $file_states($path)}]} {
1653                 set state __
1654                 set icon n[incr next_icon_id]
1655         } else {
1656                 set state [lindex $info 0]
1657                 set icon [lindex $info 1]
1658                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1659                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1660         }
1661
1662         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1663         elseif {$s0 eq {_}} {set s0 _}
1664
1665         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1666         elseif {$s1 eq {_}} {set s1 _}
1667
1668         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1669                 set head_info [list 0 $null_sha1]
1670         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1671                 && $head_info eq {}} {
1672                 set head_info $index_info
1673         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1674                 set index_info $head_info
1675                 set head_info {}
1676         }
1677
1678         set file_states($path) [list $s0$s1 $icon \
1679                 $head_info $index_info \
1680                 ]
1681         return $state
1682 }
1683
1684 proc display_file_helper {w path icon_name old_m new_m} {
1685         global file_lists
1686
1687         if {$new_m eq {_}} {
1688                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1689                 if {$lno >= 0} {
1690                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1691                         incr lno
1692                         $w conf -state normal
1693                         $w delete $lno.0 [expr {$lno + 1}].0
1694                         $w conf -state disabled
1695                 }
1696         } elseif {$old_m eq {_} && $new_m ne {_}} {
1697                 lappend file_lists($w) $path
1698                 set file_lists($w) [lsort -unique $file_lists($w)]
1699                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1700                 incr lno
1701                 $w conf -state normal
1702                 $w image create $lno.0 \
1703                         -align center -padx 5 -pady 1 \
1704                         -name $icon_name \
1705                         -image [mapicon $w $new_m $path]
1706                 $w insert $lno.1 "[escape_path $path]\n"
1707                 $w conf -state disabled
1708         } elseif {$old_m ne $new_m} {
1709                 $w conf -state normal
1710                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1711                 $w conf -state disabled
1712         }
1713 }
1714
1715 proc display_file {path state} {
1716         global file_states selected_paths
1717         global ui_index ui_workdir
1718
1719         set old_m [merge_state $path $state]
1720         set s $file_states($path)
1721         set new_m [lindex $s 0]
1722         set icon_name [lindex $s 1]
1723
1724         set o [string index $old_m 0]
1725         set n [string index $new_m 0]
1726         if {$o eq {U}} {
1727                 set o _
1728         }
1729         if {$n eq {U}} {
1730                 set n _
1731         }
1732         display_file_helper     $ui_index $path $icon_name $o $n
1733
1734         if {[string index $old_m 0] eq {U}} {
1735                 set o U
1736         } else {
1737                 set o [string index $old_m 1]
1738         }
1739         if {[string index $new_m 0] eq {U}} {
1740                 set n U
1741         } else {
1742                 set n [string index $new_m 1]
1743         }
1744         display_file_helper     $ui_workdir $path $icon_name $o $n
1745
1746         if {$new_m eq {__}} {
1747                 unset file_states($path)
1748                 catch {unset selected_paths($path)}
1749         }
1750 }
1751
1752 proc display_all_files_helper {w path icon_name m} {
1753         global file_lists
1754
1755         lappend file_lists($w) $path
1756         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1757         $w image create end \
1758                 -align center -padx 5 -pady 1 \
1759                 -name $icon_name \
1760                 -image [mapicon $w $m $path]
1761         $w insert end "[escape_path $path]\n"
1762 }
1763
1764 set files_warning 0
1765 proc display_all_files {} {
1766         global ui_index ui_workdir
1767         global file_states file_lists
1768         global last_clicked
1769         global files_warning
1770
1771         $ui_index conf -state normal
1772         $ui_workdir conf -state normal
1773
1774         $ui_index delete 0.0 end
1775         $ui_workdir delete 0.0 end
1776         set last_clicked {}
1777
1778         set file_lists($ui_index) [list]
1779         set file_lists($ui_workdir) [list]
1780
1781         set to_display [lsort [array names file_states]]
1782         set display_limit [get_config gui.maxfilesdisplayed]
1783         if {[llength $to_display] > $display_limit} {
1784                 if {!$files_warning} {
1785                         # do not repeatedly warn:
1786                         set files_warning 1
1787                         info_popup [mc "Displaying only %s of %s files." \
1788                                 $display_limit [llength $to_display]]
1789                 }
1790                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1791         }
1792         foreach path $to_display {
1793                 set s $file_states($path)
1794                 set m [lindex $s 0]
1795                 set icon_name [lindex $s 1]
1796
1797                 set s [string index $m 0]
1798                 if {$s ne {U} && $s ne {_}} {
1799                         display_all_files_helper $ui_index $path \
1800                                 $icon_name $s
1801                 }
1802
1803                 if {[string index $m 0] eq {U}} {
1804                         set s U
1805                 } else {
1806                         set s [string index $m 1]
1807                 }
1808                 if {$s ne {_}} {
1809                         display_all_files_helper $ui_workdir $path \
1810                                 $icon_name $s
1811                 }
1812         }
1813
1814         $ui_index conf -state disabled
1815         $ui_workdir conf -state disabled
1816 }
1817
1818 ######################################################################
1819 ##
1820 ## icons
1821
1822 set filemask {
1823 #define mask_width 14
1824 #define mask_height 15
1825 static unsigned char mask_bits[] = {
1826    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1827    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1828    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1829 }
1830
1831 image create bitmap file_plain -background white -foreground black -data {
1832 #define plain_width 14
1833 #define plain_height 15
1834 static unsigned char plain_bits[] = {
1835    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1836    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1837    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1838 } -maskdata $filemask
1839
1840 image create bitmap file_mod -background white -foreground blue -data {
1841 #define mod_width 14
1842 #define mod_height 15
1843 static unsigned char mod_bits[] = {
1844    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1845    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1846    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1847 } -maskdata $filemask
1848
1849 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1850 #define file_fulltick_width 14
1851 #define file_fulltick_height 15
1852 static unsigned char file_fulltick_bits[] = {
1853    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1854    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1855    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1856 } -maskdata $filemask
1857
1858 image create bitmap file_question -background white -foreground black -data {
1859 #define file_question_width 14
1860 #define file_question_height 15
1861 static unsigned char file_question_bits[] = {
1862    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1863    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1864    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1865 } -maskdata $filemask
1866
1867 image create bitmap file_removed -background white -foreground red -data {
1868 #define file_removed_width 14
1869 #define file_removed_height 15
1870 static unsigned char file_removed_bits[] = {
1871    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1872    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1873    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1874 } -maskdata $filemask
1875
1876 image create bitmap file_merge -background white -foreground blue -data {
1877 #define file_merge_width 14
1878 #define file_merge_height 15
1879 static unsigned char file_merge_bits[] = {
1880    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1881    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1882    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1883 } -maskdata $filemask
1884
1885 image create bitmap file_statechange -background white -foreground green -data {
1886 #define file_merge_width 14
1887 #define file_merge_height 15
1888 static unsigned char file_statechange_bits[] = {
1889    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1890    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1891    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1892 } -maskdata $filemask
1893
1894 set ui_index .vpane.files.index.list
1895 set ui_workdir .vpane.files.workdir.list
1896
1897 set all_icons(_$ui_index)   file_plain
1898 set all_icons(A$ui_index)   file_plain
1899 set all_icons(M$ui_index)   file_fulltick
1900 set all_icons(D$ui_index)   file_removed
1901 set all_icons(U$ui_index)   file_merge
1902 set all_icons(T$ui_index)   file_statechange
1903
1904 set all_icons(_$ui_workdir) file_plain
1905 set all_icons(M$ui_workdir) file_mod
1906 set all_icons(D$ui_workdir) file_question
1907 set all_icons(U$ui_workdir) file_merge
1908 set all_icons(O$ui_workdir) file_plain
1909 set all_icons(T$ui_workdir) file_statechange
1910
1911 set max_status_desc 0
1912 foreach i {
1913                 {__ {mc "Unmodified"}}
1914
1915                 {_M {mc "Modified, not staged"}}
1916                 {M_ {mc "Staged for commit"}}
1917                 {MM {mc "Portions staged for commit"}}
1918                 {MD {mc "Staged for commit, missing"}}
1919
1920                 {_T {mc "File type changed, not staged"}}
1921                 {T_ {mc "File type changed, staged"}}
1922
1923                 {_O {mc "Untracked, not staged"}}
1924                 {A_ {mc "Staged for commit"}}
1925                 {AM {mc "Portions staged for commit"}}
1926                 {AD {mc "Staged for commit, missing"}}
1927
1928                 {_D {mc "Missing"}}
1929                 {D_ {mc "Staged for removal"}}
1930                 {DO {mc "Staged for removal, still present"}}
1931
1932                 {_U {mc "Requires merge resolution"}}
1933                 {U_ {mc "Requires merge resolution"}}
1934                 {UU {mc "Requires merge resolution"}}
1935                 {UM {mc "Requires merge resolution"}}
1936                 {UD {mc "Requires merge resolution"}}
1937                 {UT {mc "Requires merge resolution"}}
1938         } {
1939         set text [eval [lindex $i 1]]
1940         if {$max_status_desc < [string length $text]} {
1941                 set max_status_desc [string length $text]
1942         }
1943         set all_descs([lindex $i 0]) $text
1944 }
1945 unset i
1946
1947 ######################################################################
1948 ##
1949 ## util
1950
1951 proc scrollbar2many {list mode args} {
1952         foreach w $list {eval $w $mode $args}
1953 }
1954
1955 proc many2scrollbar {list mode sb top bottom} {
1956         $sb set $top $bottom
1957         foreach w $list {$w $mode moveto $top}
1958 }
1959
1960 proc incr_font_size {font {amt 1}} {
1961         set sz [font configure $font -size]
1962         incr sz $amt
1963         font configure $font -size $sz
1964         font configure ${font}bold -size $sz
1965         font configure ${font}italic -size $sz
1966 }
1967
1968 ######################################################################
1969 ##
1970 ## ui commands
1971
1972 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1973
1974 proc do_gitk {revs {is_submodule false}} {
1975         global current_diff_path file_states current_diff_side ui_index
1976         global _gitdir _gitworktree
1977
1978         # -- Always start gitk through whatever we were loaded with.  This
1979         #    lets us bypass using shell process on Windows systems.
1980         #
1981         set exe [_which gitk -script]
1982         set cmd [list [info nameofexecutable] $exe]
1983         if {$exe eq {}} {
1984                 error_popup [mc "Couldn't find gitk in PATH"]
1985         } else {
1986                 global env
1987
1988                 set pwd [pwd]
1989
1990                 if {!$is_submodule} {
1991                         if {![is_bare]} {
1992                                 cd $_gitworktree
1993                         }
1994                 } else {
1995                         cd $current_diff_path
1996                         if {$revs eq {--}} {
1997                                 set s $file_states($current_diff_path)
1998                                 set old_sha1 {}
1999                                 set new_sha1 {}
2000                                 switch -glob -- [lindex $s 0] {
2001                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2002                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2003                                 MM {
2004                                         if {$current_diff_side eq $ui_index} {
2005                                                 set old_sha1 [lindex [lindex $s 2] 1]
2006                                                 set new_sha1 [lindex [lindex $s 3] 1]
2007                                         } else {
2008                                                 set old_sha1 [lindex [lindex $s 3] 1]
2009                                         }
2010                                 }
2011                                 }
2012                                 set revs $old_sha1...$new_sha1
2013                         }
2014                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2015                         # we've been using for the main repository, so unset them.
2016                         # TODO we could make life easier (start up faster?) for gitk
2017                         # by setting these to the appropriate values to allow gitk
2018                         # to skip the heuristics to find their proper value
2019                         unset env(GIT_DIR)
2020                         unset env(GIT_WORK_TREE)
2021                 }
2022                 eval exec $cmd $revs "--" "--" &
2023
2024                 set env(GIT_DIR) $_gitdir
2025                 set env(GIT_WORK_TREE) $_gitworktree
2026                 cd $pwd
2027
2028                 ui_status $::starting_gitk_msg
2029                 after 10000 {
2030                         ui_ready $starting_gitk_msg
2031                 }
2032         }
2033 }
2034
2035 proc do_git_gui {} {
2036         global current_diff_path
2037
2038         # -- Always start git gui through whatever we were loaded with.  This
2039         #    lets us bypass using shell process on Windows systems.
2040         #
2041         set exe [_which git]
2042         if {$exe eq {}} {
2043                 error_popup [mc "Couldn't find git gui in PATH"]
2044         } else {
2045                 global env
2046                 global _gitdir _gitworktree
2047
2048                 # see note in do_gitk about unsetting these vars when
2049                 # running tools in a submodule
2050                 unset env(GIT_DIR)
2051                 unset env(GIT_WORK_TREE)
2052
2053                 set pwd [pwd]
2054                 cd $current_diff_path
2055
2056                 eval exec $exe gui &
2057
2058                 set env(GIT_DIR) $_gitdir
2059                 set env(GIT_WORK_TREE) $_gitworktree
2060                 cd $pwd
2061
2062                 ui_status $::starting_gitk_msg
2063                 after 10000 {
2064                         ui_ready $starting_gitk_msg
2065                 }
2066         }
2067 }
2068
2069 proc do_explore {} {
2070         global _gitworktree
2071         set explorer {}
2072         if {[is_Cygwin] || [is_Windows]} {
2073                 set explorer "explorer.exe"
2074         } elseif {[is_MacOSX]} {
2075                 set explorer "open"
2076         } else {
2077                 # freedesktop.org-conforming system is our best shot
2078                 set explorer "xdg-open"
2079         }
2080         eval exec $explorer $_gitworktree &
2081 }
2082
2083 set is_quitting 0
2084 set ret_code    1
2085
2086 proc terminate_me {win} {
2087         global ret_code
2088         if {$win ne {.}} return
2089         exit $ret_code
2090 }
2091
2092 proc do_quit {{rc {1}}} {
2093         global ui_comm is_quitting repo_config commit_type
2094         global GITGUI_BCK_exists GITGUI_BCK_i
2095         global ui_comm_spell
2096         global ret_code
2097
2098         if {$is_quitting} return
2099         set is_quitting 1
2100
2101         if {[winfo exists $ui_comm]} {
2102                 # -- Stash our current commit buffer.
2103                 #
2104                 set save [gitdir GITGUI_MSG]
2105                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2106                         file rename -force [gitdir GITGUI_BCK] $save
2107                         set GITGUI_BCK_exists 0
2108                 } else {
2109                         set msg [string trim [$ui_comm get 0.0 end]]
2110                         regsub -all -line {[ \r\t]+$} $msg {} msg
2111                         if {(![string match amend* $commit_type]
2112                                 || [$ui_comm edit modified])
2113                                 && $msg ne {}} {
2114                                 catch {
2115                                         set fd [open $save w]
2116                                         puts -nonewline $fd $msg
2117                                         close $fd
2118                                 }
2119                         } else {
2120                                 catch {file delete $save}
2121                         }
2122                 }
2123
2124                 # -- Cancel our spellchecker if its running.
2125                 #
2126                 if {[info exists ui_comm_spell]} {
2127                         $ui_comm_spell stop
2128                 }
2129
2130                 # -- Remove our editor backup, its not needed.
2131                 #
2132                 after cancel $GITGUI_BCK_i
2133                 if {$GITGUI_BCK_exists} {
2134                         catch {file delete [gitdir GITGUI_BCK]}
2135                 }
2136
2137                 # -- Stash our current window geometry into this repository.
2138                 #
2139                 set cfg_wmstate [wm state .]
2140                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2141                         set rc_wmstate {}
2142                 }
2143                 if {$cfg_wmstate ne $rc_wmstate} {
2144                         catch {git config gui.wmstate $cfg_wmstate}
2145                 }
2146                 if {$cfg_wmstate eq {zoomed}} {
2147                         # on Windows wm geometry will lie about window
2148                         # position (but not size) when window is zoomed
2149                         # restore the window before querying wm geometry
2150                         wm state . normal
2151                 }
2152                 set cfg_geometry [list]
2153                 lappend cfg_geometry [wm geometry .]
2154                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2155                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2156                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2157                         set rc_geometry {}
2158                 }
2159                 if {$cfg_geometry ne $rc_geometry} {
2160                         catch {git config gui.geometry $cfg_geometry}
2161                 }
2162         }
2163
2164         set ret_code $rc
2165
2166         # Briefly enable send again, working around Tk bug
2167         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2168         tk appname [appname]
2169
2170         destroy .
2171 }
2172
2173 proc do_rescan {} {
2174         rescan ui_ready
2175 }
2176
2177 proc ui_do_rescan {} {
2178         rescan {force_first_diff ui_ready}
2179 }
2180
2181 proc do_commit {} {
2182         commit_tree
2183 }
2184
2185 proc next_diff {{after {}}} {
2186         global next_diff_p next_diff_w next_diff_i
2187         show_diff $next_diff_p $next_diff_w {} {} $after
2188 }
2189
2190 proc find_anchor_pos {lst name} {
2191         set lid [lsearch -sorted -exact $lst $name]
2192
2193         if {$lid == -1} {
2194                 set lid 0
2195                 foreach lname $lst {
2196                         if {$lname >= $name} break
2197                         incr lid
2198                 }
2199         }
2200
2201         return $lid
2202 }
2203
2204 proc find_file_from {flist idx delta path mmask} {
2205         global file_states
2206
2207         set len [llength $flist]
2208         while {$idx >= 0 && $idx < $len} {
2209                 set name [lindex $flist $idx]
2210
2211                 if {$name ne $path && [info exists file_states($name)]} {
2212                         set state [lindex $file_states($name) 0]
2213
2214                         if {$mmask eq {} || [regexp $mmask $state]} {
2215                                 return $idx
2216                         }
2217                 }
2218
2219                 incr idx $delta
2220         }
2221
2222         return {}
2223 }
2224
2225 proc find_next_diff {w path {lno {}} {mmask {}}} {
2226         global next_diff_p next_diff_w next_diff_i
2227         global file_lists ui_index ui_workdir
2228
2229         set flist $file_lists($w)
2230         if {$lno eq {}} {
2231                 set lno [find_anchor_pos $flist $path]
2232         } else {
2233                 incr lno -1
2234         }
2235
2236         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2237                 if {$w eq $ui_index} {
2238                         set mmask "^$mmask"
2239                 } else {
2240                         set mmask "$mmask\$"
2241                 }
2242         }
2243
2244         set idx [find_file_from $flist $lno 1 $path $mmask]
2245         if {$idx eq {}} {
2246                 incr lno -1
2247                 set idx [find_file_from $flist $lno -1 $path $mmask]
2248         }
2249
2250         if {$idx ne {}} {
2251                 set next_diff_w $w
2252                 set next_diff_p [lindex $flist $idx]
2253                 set next_diff_i [expr {$idx+1}]
2254                 return 1
2255         } else {
2256                 return 0
2257         }
2258 }
2259
2260 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2261         global current_diff_path
2262
2263         if {$path ne $current_diff_path} {
2264                 return {}
2265         } elseif {[find_next_diff $w $path $lno $mmask]} {
2266                 return {next_diff;}
2267         } else {
2268                 return {reshow_diff;}
2269         }
2270 }
2271
2272 proc select_first_diff {after} {
2273         global ui_workdir
2274
2275         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2276             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2277                 next_diff $after
2278         } else {
2279                 uplevel #0 $after
2280         }
2281 }
2282
2283 proc force_first_diff {after} {
2284         global ui_workdir current_diff_path file_states
2285
2286         if {[info exists file_states($current_diff_path)]} {
2287                 set state [lindex $file_states($current_diff_path) 0]
2288         } else {
2289                 set state {OO}
2290         }
2291
2292         set reselect 0
2293         if {[string first {U} $state] >= 0} {
2294                 # Already a conflict, do nothing
2295         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2296                 set reselect 1
2297         } elseif {[string index $state 1] ne {O}} {
2298                 # Already a diff & no conflicts, do nothing
2299         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2300                 set reselect 1
2301         }
2302
2303         if {$reselect} {
2304                 next_diff $after
2305         } else {
2306                 uplevel #0 $after
2307         }
2308 }
2309
2310 proc toggle_or_diff {w x y} {
2311         global file_states file_lists current_diff_path ui_index ui_workdir
2312         global last_clicked selected_paths
2313
2314         set pos [split [$w index @$x,$y] .]
2315         set lno [lindex $pos 0]
2316         set col [lindex $pos 1]
2317         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2318         if {$path eq {}} {
2319                 set last_clicked {}
2320                 return
2321         }
2322
2323         set last_clicked [list $w $lno]
2324         array unset selected_paths
2325         $ui_index tag remove in_sel 0.0 end
2326         $ui_workdir tag remove in_sel 0.0 end
2327
2328         # Determine the state of the file
2329         if {[info exists file_states($path)]} {
2330                 set state [lindex $file_states($path) 0]
2331         } else {
2332                 set state {__}
2333         }
2334
2335         # Restage the file, or simply show the diff
2336         if {$col == 0 && $y > 1} {
2337                 # Conflicts need special handling
2338                 if {[string first {U} $state] >= 0} {
2339                         # $w must always be $ui_workdir, but...
2340                         if {$w ne $ui_workdir} { set lno {} }
2341                         merge_stage_workdir $path $lno
2342                         return
2343                 }
2344
2345                 if {[string index $state 1] eq {O}} {
2346                         set mmask {}
2347                 } else {
2348                         set mmask {[^O]}
2349                 }
2350
2351                 set after [next_diff_after_action $w $path $lno $mmask]
2352
2353                 if {$w eq $ui_index} {
2354                         update_indexinfo \
2355                                 "Unstaging [short_path $path] from commit" \
2356                                 [list $path] \
2357                                 [concat $after [list ui_ready]]
2358                 } elseif {$w eq $ui_workdir} {
2359                         update_index \
2360                                 "Adding [short_path $path]" \
2361                                 [list $path] \
2362                                 [concat $after [list ui_ready]]
2363                 }
2364         } else {
2365                 show_diff $path $w $lno
2366         }
2367 }
2368
2369 proc add_one_to_selection {w x y} {
2370         global file_lists last_clicked selected_paths
2371
2372         set lno [lindex [split [$w index @$x,$y] .] 0]
2373         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2374         if {$path eq {}} {
2375                 set last_clicked {}
2376                 return
2377         }
2378
2379         if {$last_clicked ne {}
2380                 && [lindex $last_clicked 0] ne $w} {
2381                 array unset selected_paths
2382                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2383         }
2384
2385         set last_clicked [list $w $lno]
2386         if {[catch {set in_sel $selected_paths($path)}]} {
2387                 set in_sel 0
2388         }
2389         if {$in_sel} {
2390                 unset selected_paths($path)
2391                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2392         } else {
2393                 set selected_paths($path) 1
2394                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2395         }
2396 }
2397
2398 proc add_range_to_selection {w x y} {
2399         global file_lists last_clicked selected_paths
2400
2401         if {[lindex $last_clicked 0] ne $w} {
2402                 toggle_or_diff $w $x $y
2403                 return
2404         }
2405
2406         set lno [lindex [split [$w index @$x,$y] .] 0]
2407         set lc [lindex $last_clicked 1]
2408         if {$lc < $lno} {
2409                 set begin $lc
2410                 set end $lno
2411         } else {
2412                 set begin $lno
2413                 set end $lc
2414         }
2415
2416         foreach path [lrange $file_lists($w) \
2417                 [expr {$begin - 1}] \
2418                 [expr {$end - 1}]] {
2419                 set selected_paths($path) 1
2420         }
2421         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2422 }
2423
2424 proc show_more_context {} {
2425         global repo_config
2426         if {$repo_config(gui.diffcontext) < 99} {
2427                 incr repo_config(gui.diffcontext)
2428                 reshow_diff
2429         }
2430 }
2431
2432 proc show_less_context {} {
2433         global repo_config
2434         if {$repo_config(gui.diffcontext) > 1} {
2435                 incr repo_config(gui.diffcontext) -1
2436                 reshow_diff
2437         }
2438 }
2439
2440 ######################################################################
2441 ##
2442 ## ui construction
2443
2444 set ui_comm {}
2445
2446 # -- Menu Bar
2447 #
2448 menu .mbar -tearoff 0
2449 if {[is_MacOSX]} {
2450         # -- Apple Menu (Mac OS X only)
2451         #
2452         .mbar add cascade -label Apple -menu .mbar.apple
2453         menu .mbar.apple
2454 }
2455 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2456 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2457 if {[is_enabled branch]} {
2458         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2459 }
2460 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2461         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2462 }
2463 if {[is_enabled transport]} {
2464         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2465         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2466 }
2467 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2468         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2469 }
2470
2471 # -- Repository Menu
2472 #
2473 menu .mbar.repository
2474
2475 if {![is_bare]} {
2476         .mbar.repository add command \
2477                 -label [mc "Explore Working Copy"] \
2478                 -command {do_explore}
2479         .mbar.repository add separator
2480 }
2481
2482 .mbar.repository add command \
2483         -label [mc "Browse Current Branch's Files"] \
2484         -command {browser::new $current_branch}
2485 set ui_browse_current [.mbar.repository index last]
2486 .mbar.repository add command \
2487         -label [mc "Browse Branch Files..."] \
2488         -command browser_open::dialog
2489 .mbar.repository add separator
2490
2491 .mbar.repository add command \
2492         -label [mc "Visualize Current Branch's History"] \
2493         -command {do_gitk $current_branch}
2494 set ui_visualize_current [.mbar.repository index last]
2495 .mbar.repository add command \
2496         -label [mc "Visualize All Branch History"] \
2497         -command {do_gitk --all}
2498 .mbar.repository add separator
2499
2500 proc current_branch_write {args} {
2501         global current_branch
2502         .mbar.repository entryconf $::ui_browse_current \
2503                 -label [mc "Browse %s's Files" $current_branch]
2504         .mbar.repository entryconf $::ui_visualize_current \
2505                 -label [mc "Visualize %s's History" $current_branch]
2506 }
2507 trace add variable current_branch write current_branch_write
2508
2509 if {[is_enabled multicommit]} {
2510         .mbar.repository add command -label [mc "Database Statistics"] \
2511                 -command do_stats
2512
2513         .mbar.repository add command -label [mc "Compress Database"] \
2514                 -command do_gc
2515
2516         .mbar.repository add command -label [mc "Verify Database"] \
2517                 -command do_fsck_objects
2518
2519         .mbar.repository add separator
2520
2521         if {[is_Cygwin]} {
2522                 .mbar.repository add command \
2523                         -label [mc "Create Desktop Icon"] \
2524                         -command do_cygwin_shortcut
2525         } elseif {[is_Windows]} {
2526                 .mbar.repository add command \
2527                         -label [mc "Create Desktop Icon"] \
2528                         -command do_windows_shortcut
2529         } elseif {[is_MacOSX]} {
2530                 .mbar.repository add command \
2531                         -label [mc "Create Desktop Icon"] \
2532                         -command do_macosx_app
2533         }
2534 }
2535
2536 if {[is_MacOSX]} {
2537         proc ::tk::mac::Quit {args} { do_quit }
2538 } else {
2539         .mbar.repository add command -label [mc Quit] \
2540                 -command do_quit \
2541                 -accelerator $M1T-Q
2542 }
2543
2544 # -- Edit Menu
2545 #
2546 menu .mbar.edit
2547 .mbar.edit add command -label [mc Undo] \
2548         -command {catch {[focus] edit undo}} \
2549         -accelerator $M1T-Z
2550 .mbar.edit add command -label [mc Redo] \
2551         -command {catch {[focus] edit redo}} \
2552         -accelerator $M1T-Y
2553 .mbar.edit add separator
2554 .mbar.edit add command -label [mc Cut] \
2555         -command {catch {tk_textCut [focus]}} \
2556         -accelerator $M1T-X
2557 .mbar.edit add command -label [mc Copy] \
2558         -command {catch {tk_textCopy [focus]}} \
2559         -accelerator $M1T-C
2560 .mbar.edit add command -label [mc Paste] \
2561         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2562         -accelerator $M1T-V
2563 .mbar.edit add command -label [mc Delete] \
2564         -command {catch {[focus] delete sel.first sel.last}} \
2565         -accelerator Del
2566 .mbar.edit add separator
2567 .mbar.edit add command -label [mc "Select All"] \
2568         -command {catch {[focus] tag add sel 0.0 end}} \
2569         -accelerator $M1T-A
2570
2571 # -- Branch Menu
2572 #
2573 if {[is_enabled branch]} {
2574         menu .mbar.branch
2575
2576         .mbar.branch add command -label [mc "Create..."] \
2577                 -command branch_create::dialog \
2578                 -accelerator $M1T-N
2579         lappend disable_on_lock [list .mbar.branch entryconf \
2580                 [.mbar.branch index last] -state]
2581
2582         .mbar.branch add command -label [mc "Checkout..."] \
2583                 -command branch_checkout::dialog \
2584                 -accelerator $M1T-O
2585         lappend disable_on_lock [list .mbar.branch entryconf \
2586                 [.mbar.branch index last] -state]
2587
2588         .mbar.branch add command -label [mc "Rename..."] \
2589                 -command branch_rename::dialog
2590         lappend disable_on_lock [list .mbar.branch entryconf \
2591                 [.mbar.branch index last] -state]
2592
2593         .mbar.branch add command -label [mc "Delete..."] \
2594                 -command branch_delete::dialog
2595         lappend disable_on_lock [list .mbar.branch entryconf \
2596                 [.mbar.branch index last] -state]
2597
2598         .mbar.branch add command -label [mc "Reset..."] \
2599                 -command merge::reset_hard
2600         lappend disable_on_lock [list .mbar.branch entryconf \
2601                 [.mbar.branch index last] -state]
2602 }
2603
2604 # -- Commit Menu
2605 #
2606 proc commit_btn_caption {} {
2607         if {[is_enabled nocommit]} {
2608                 return [mc "Done"]
2609         } else {
2610                 return [mc Commit@@verb]
2611         }
2612 }
2613
2614 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2615         menu .mbar.commit
2616
2617         if {![is_enabled nocommit]} {
2618                 .mbar.commit add radiobutton \
2619                         -label [mc "New Commit"] \
2620                         -command do_select_commit_type \
2621                         -variable selected_commit_type \
2622                         -value new
2623                 lappend disable_on_lock \
2624                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2625
2626                 .mbar.commit add radiobutton \
2627                         -label [mc "Amend Last Commit"] \
2628                         -command do_select_commit_type \
2629                         -variable selected_commit_type \
2630                         -value amend
2631                 lappend disable_on_lock \
2632                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2633
2634                 .mbar.commit add separator
2635         }
2636
2637         .mbar.commit add command -label [mc Rescan] \
2638                 -command ui_do_rescan \
2639                 -accelerator F5
2640         lappend disable_on_lock \
2641                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2642
2643         .mbar.commit add command -label [mc "Stage To Commit"] \
2644                 -command do_add_selection \
2645                 -accelerator $M1T-T
2646         lappend disable_on_lock \
2647                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2648
2649         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2650                 -command do_add_all \
2651                 -accelerator $M1T-I
2652         lappend disable_on_lock \
2653                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2654
2655         .mbar.commit add command -label [mc "Unstage From Commit"] \
2656                 -command do_unstage_selection \
2657                 -accelerator $M1T-U
2658         lappend disable_on_lock \
2659                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2660
2661         .mbar.commit add command -label [mc "Revert Changes"] \
2662                 -command do_revert_selection \
2663                 -accelerator $M1T-J
2664         lappend disable_on_lock \
2665                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2666
2667         .mbar.commit add separator
2668
2669         .mbar.commit add command -label [mc "Show Less Context"] \
2670                 -command show_less_context \
2671                 -accelerator $M1T-\-
2672
2673         .mbar.commit add command -label [mc "Show More Context"] \
2674                 -command show_more_context \
2675                 -accelerator $M1T-=
2676
2677         .mbar.commit add separator
2678
2679         if {![is_enabled nocommitmsg]} {
2680                 .mbar.commit add command -label [mc "Sign Off"] \
2681                         -command do_signoff \
2682                         -accelerator $M1T-S
2683         }
2684
2685         .mbar.commit add command -label [commit_btn_caption] \
2686                 -command do_commit \
2687                 -accelerator $M1T-Return
2688         lappend disable_on_lock \
2689                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2690 }
2691
2692 # -- Merge Menu
2693 #
2694 if {[is_enabled branch]} {
2695         menu .mbar.merge
2696         .mbar.merge add command -label [mc "Local Merge..."] \
2697                 -command merge::dialog \
2698                 -accelerator $M1T-M
2699         lappend disable_on_lock \
2700                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2701         .mbar.merge add command -label [mc "Abort Merge..."] \
2702                 -command merge::reset_hard
2703         lappend disable_on_lock \
2704                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2705 }
2706
2707 # -- Transport Menu
2708 #
2709 if {[is_enabled transport]} {
2710         menu .mbar.remote
2711
2712         .mbar.remote add command \
2713                 -label [mc "Add..."] \
2714                 -command remote_add::dialog \
2715                 -accelerator $M1T-A
2716         .mbar.remote add command \
2717                 -label [mc "Push..."] \
2718                 -command do_push_anywhere \
2719                 -accelerator $M1T-P
2720         .mbar.remote add command \
2721                 -label [mc "Delete Branch..."] \
2722                 -command remote_branch_delete::dialog
2723 }
2724
2725 if {[is_MacOSX]} {
2726         proc ::tk::mac::ShowPreferences {} {do_options}
2727 } else {
2728         # -- Edit Menu
2729         #
2730         .mbar.edit add separator
2731         .mbar.edit add command -label [mc "Options..."] \
2732                 -command do_options
2733 }
2734
2735 # -- Tools Menu
2736 #
2737 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2738         set tools_menubar .mbar.tools
2739         menu $tools_menubar
2740         $tools_menubar add separator
2741         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2742         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2743         set tools_tailcnt 3
2744         if {[array names repo_config guitool.*.cmd] ne {}} {
2745                 tools_populate_all
2746         }
2747 }
2748
2749 # -- Help Menu
2750 #
2751 .mbar add cascade -label [mc Help] -menu .mbar.help
2752 menu .mbar.help
2753
2754 if {[is_MacOSX]} {
2755         .mbar.apple add command -label [mc "About %s" [appname]] \
2756                 -command do_about
2757         .mbar.apple add separator
2758 } else {
2759         .mbar.help add command -label [mc "About %s" [appname]] \
2760                 -command do_about
2761 }
2762 . configure -menu .mbar
2763
2764 set doc_path [githtmldir]
2765 if {$doc_path ne {}} {
2766         set doc_path [file join $doc_path index.html]
2767
2768         if {[is_Cygwin]} {
2769                 set doc_path [exec cygpath --mixed $doc_path]
2770         }
2771 }
2772
2773 if {[file isfile $doc_path]} {
2774         set doc_url "file:$doc_path"
2775 } else {
2776         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2777 }
2778
2779 proc start_browser {url} {
2780         git "web--browse" $url
2781 }
2782
2783 .mbar.help add command -label [mc "Online Documentation"] \
2784         -command [list start_browser $doc_url]
2785
2786 .mbar.help add command -label [mc "Show SSH Key"] \
2787         -command do_ssh_key
2788
2789 unset doc_path doc_url
2790
2791 # -- Standard bindings
2792 #
2793 wm protocol . WM_DELETE_WINDOW do_quit
2794 bind all <$M1B-Key-q> do_quit
2795 bind all <$M1B-Key-Q> do_quit
2796 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2797 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2798
2799 set subcommand_args {}
2800 proc usage {} {
2801         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2802         exit 1
2803 }
2804
2805 proc normalize_relpath {path} {
2806         set elements {}
2807         foreach item [file split $path] {
2808                 if {$item eq {.}} continue
2809                 if {$item eq {..} && [llength $elements] > 0
2810                     && [lindex $elements end] ne {..}} {
2811                         set elements [lrange $elements 0 end-1]
2812                         continue
2813                 }
2814                 lappend elements $item
2815         }
2816         return [eval file join $elements]
2817 }
2818
2819 # -- Not a normal commit type invocation?  Do that instead!
2820 #
2821 switch -- $subcommand {
2822 browser -
2823 blame {
2824         if {$subcommand eq "blame"} {
2825                 set subcommand_args {[--line=<num>] rev? path}
2826         } else {
2827                 set subcommand_args {rev? path}
2828         }
2829         if {$argv eq {}} usage
2830         set head {}
2831         set path {}
2832         set jump_spec {}
2833         set is_path 0
2834         foreach a $argv {
2835                 if {$is_path || [file exists $_prefix$a]} {
2836                         if {$path ne {}} usage
2837                         set path [normalize_relpath $_prefix$a]
2838                         break
2839                 } elseif {$a eq {--}} {
2840                         if {$path ne {}} {
2841                                 if {$head ne {}} usage
2842                                 set head $path
2843                                 set path {}
2844                         }
2845                         set is_path 1
2846                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2847                         if {$jump_spec ne {} || $head ne {}} usage
2848                         set jump_spec [list $lnum]
2849                 } elseif {$head eq {}} {
2850                         if {$head ne {}} usage
2851                         set head $a
2852                         set is_path 1
2853                 } else {
2854                         usage
2855                 }
2856         }
2857         unset is_path
2858
2859         if {$head ne {} && $path eq {}} {
2860                 set path [normalize_relpath $_prefix$head]
2861                 set head {}
2862         }
2863
2864         if {$head eq {}} {
2865                 load_current_branch
2866         } else {
2867                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2868                         if {[catch {
2869                                         set head [git rev-parse --verify $head]
2870                                 } err]} {
2871                                 puts stderr $err
2872                                 exit 1
2873                         }
2874                 }
2875                 set current_branch $head
2876         }
2877
2878         switch -- $subcommand {
2879         browser {
2880                 if {$jump_spec ne {}} usage
2881                 if {$head eq {}} {
2882                         if {$path ne {} && [file isdirectory $path]} {
2883                                 set head $current_branch
2884                         } else {
2885                                 set head $path
2886                                 set path {}
2887                         }
2888                 }
2889                 browser::new $head $path
2890         }
2891         blame   {
2892                 if {$head eq {} && ![file exists $path]} {
2893                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2894                         exit 1
2895                 }
2896                 blame::new $head $path $jump_spec
2897         }
2898         }
2899         return
2900 }
2901 citool -
2902 gui {
2903         if {[llength $argv] != 0} {
2904                 puts -nonewline stderr "usage: $argv0"
2905                 if {$subcommand ne {gui}
2906                         && [file tail $argv0] ne "git-$subcommand"} {
2907                         puts -nonewline stderr " $subcommand"
2908                 }
2909                 puts stderr {}
2910                 exit 1
2911         }
2912         # fall through to setup UI for commits
2913 }
2914 default {
2915         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2916         exit 1
2917 }
2918 }
2919
2920 # -- Branch Control
2921 #
2922 frame .branch \
2923         -borderwidth 1 \
2924         -relief sunken
2925 label .branch.l1 \
2926         -text [mc "Current Branch:"] \
2927         -anchor w \
2928         -justify left
2929 label .branch.cb \
2930         -textvariable current_branch \
2931         -anchor w \
2932         -justify left
2933 pack .branch.l1 -side left
2934 pack .branch.cb -side left -fill x
2935 pack .branch -side top -fill x
2936
2937 # -- Main Window Layout
2938 #
2939 panedwindow .vpane -orient horizontal
2940 panedwindow .vpane.files -orient vertical
2941 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2942 pack .vpane -anchor n -side top -fill both -expand 1
2943
2944 # -- Index File List
2945 #
2946 frame .vpane.files.index -height 100 -width 200
2947 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2948         -background lightgreen -foreground black
2949 text $ui_index -background white -foreground black \
2950         -borderwidth 0 \
2951         -width 20 -height 10 \
2952         -wrap none \
2953         -cursor $cursor_ptr \
2954         -xscrollcommand {.vpane.files.index.sx set} \
2955         -yscrollcommand {.vpane.files.index.sy set} \
2956         -state disabled
2957 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2958 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2959 pack .vpane.files.index.title -side top -fill x
2960 pack .vpane.files.index.sx -side bottom -fill x
2961 pack .vpane.files.index.sy -side right -fill y
2962 pack $ui_index -side left -fill both -expand 1
2963
2964 # -- Working Directory File List
2965 #
2966 frame .vpane.files.workdir -height 100 -width 200
2967 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2968         -background lightsalmon -foreground black
2969 text $ui_workdir -background white -foreground black \
2970         -borderwidth 0 \
2971         -width 20 -height 10 \
2972         -wrap none \
2973         -cursor $cursor_ptr \
2974         -xscrollcommand {.vpane.files.workdir.sx set} \
2975         -yscrollcommand {.vpane.files.workdir.sy set} \
2976         -state disabled
2977 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2978 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2979 pack .vpane.files.workdir.title -side top -fill x
2980 pack .vpane.files.workdir.sx -side bottom -fill x
2981 pack .vpane.files.workdir.sy -side right -fill y
2982 pack $ui_workdir -side left -fill both -expand 1
2983
2984 .vpane.files add .vpane.files.workdir -sticky nsew
2985 .vpane.files add .vpane.files.index -sticky nsew
2986
2987 foreach i [list $ui_index $ui_workdir] {
2988         rmsel_tag $i
2989         $i tag conf in_diff -background [$i tag cget in_sel -background]
2990 }
2991 unset i
2992
2993 # -- Diff and Commit Area
2994 #
2995 frame .vpane.lower -height 300 -width 400
2996 frame .vpane.lower.commarea
2997 frame .vpane.lower.diff -relief sunken -borderwidth 1
2998 pack .vpane.lower.diff -fill both -expand 1
2999 pack .vpane.lower.commarea -side bottom -fill x
3000 .vpane add .vpane.lower -sticky nsew
3001
3002 # -- Commit Area Buttons
3003 #
3004 frame .vpane.lower.commarea.buttons
3005 label .vpane.lower.commarea.buttons.l -text {} \
3006         -anchor w \
3007         -justify left
3008 pack .vpane.lower.commarea.buttons.l -side top -fill x
3009 pack .vpane.lower.commarea.buttons -side left -fill y
3010
3011 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3012         -command ui_do_rescan
3013 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3014 lappend disable_on_lock \
3015         {.vpane.lower.commarea.buttons.rescan conf -state}
3016
3017 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3018         -command do_add_all
3019 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3020 lappend disable_on_lock \
3021         {.vpane.lower.commarea.buttons.incall conf -state}
3022
3023 if {![is_enabled nocommitmsg]} {
3024         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3025                 -command do_signoff
3026         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3027 }
3028
3029 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3030         -command do_commit
3031 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3032 lappend disable_on_lock \
3033         {.vpane.lower.commarea.buttons.commit conf -state}
3034
3035 if {![is_enabled nocommit]} {
3036         button .vpane.lower.commarea.buttons.push -text [mc Push] \
3037                 -command do_push_anywhere
3038         pack .vpane.lower.commarea.buttons.push -side top -fill x
3039 }
3040
3041 # -- Commit Message Buffer
3042 #
3043 frame .vpane.lower.commarea.buffer
3044 frame .vpane.lower.commarea.buffer.header
3045 set ui_comm .vpane.lower.commarea.buffer.t
3046 set ui_coml .vpane.lower.commarea.buffer.header.l
3047
3048 if {![is_enabled nocommit]} {
3049         radiobutton .vpane.lower.commarea.buffer.header.new \
3050                 -text [mc "New Commit"] \
3051                 -command do_select_commit_type \
3052                 -variable selected_commit_type \
3053                 -value new
3054         lappend disable_on_lock \
3055                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3056         radiobutton .vpane.lower.commarea.buffer.header.amend \
3057                 -text [mc "Amend Last Commit"] \
3058                 -command do_select_commit_type \
3059                 -variable selected_commit_type \
3060                 -value amend
3061         lappend disable_on_lock \
3062                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3063 }
3064
3065 label $ui_coml \
3066         -anchor w \
3067         -justify left
3068 proc trace_commit_type {varname args} {
3069         global ui_coml commit_type
3070         switch -glob -- $commit_type {
3071         initial       {set txt [mc "Initial Commit Message:"]}
3072         amend         {set txt [mc "Amended Commit Message:"]}
3073         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3074         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3075         merge         {set txt [mc "Merge Commit Message:"]}
3076         *             {set txt [mc "Commit Message:"]}
3077         }
3078         $ui_coml conf -text $txt
3079 }
3080 trace add variable commit_type write trace_commit_type
3081 pack $ui_coml -side left -fill x
3082
3083 if {![is_enabled nocommit]} {
3084         pack .vpane.lower.commarea.buffer.header.amend -side right
3085         pack .vpane.lower.commarea.buffer.header.new -side right
3086 }
3087
3088 text $ui_comm -background white -foreground black \
3089         -borderwidth 1 \
3090         -undo true \
3091         -maxundo 20 \
3092         -autoseparators true \
3093         -relief sunken \
3094         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3095         -font font_diff \
3096         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3097 scrollbar .vpane.lower.commarea.buffer.sby \
3098         -command [list $ui_comm yview]
3099 pack .vpane.lower.commarea.buffer.header -side top -fill x
3100 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3101 pack $ui_comm -side left -fill y
3102 pack .vpane.lower.commarea.buffer -side left -fill y
3103
3104 # -- Commit Message Buffer Context Menu
3105 #
3106 set ctxm .vpane.lower.commarea.buffer.ctxm
3107 menu $ctxm -tearoff 0
3108 $ctxm add command \
3109         -label [mc Cut] \
3110         -command {tk_textCut $ui_comm}
3111 $ctxm add command \
3112         -label [mc Copy] \
3113         -command {tk_textCopy $ui_comm}
3114 $ctxm add command \
3115         -label [mc Paste] \
3116         -command {tk_textPaste $ui_comm}
3117 $ctxm add command \
3118         -label [mc Delete] \
3119         -command {catch {$ui_comm delete sel.first sel.last}}
3120 $ctxm add separator
3121 $ctxm add command \
3122         -label [mc "Select All"] \
3123         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3124 $ctxm add command \
3125         -label [mc "Copy All"] \
3126         -command {
3127                 $ui_comm tag add sel 0.0 end
3128                 tk_textCopy $ui_comm
3129                 $ui_comm tag remove sel 0.0 end
3130         }
3131 $ctxm add separator
3132 $ctxm add command \
3133         -label [mc "Sign Off"] \
3134         -command do_signoff
3135 set ui_comm_ctxm $ctxm
3136
3137 # -- Diff Header
3138 #
3139 proc trace_current_diff_path {varname args} {
3140         global current_diff_path diff_actions file_states
3141         if {$current_diff_path eq {}} {
3142                 set s {}
3143                 set f {}
3144                 set p {}
3145                 set o disabled
3146         } else {
3147                 set p $current_diff_path
3148                 set s [mapdesc [lindex $file_states($p) 0] $p]
3149                 set f [mc "File:"]
3150                 set p [escape_path $p]
3151                 set o normal
3152         }
3153
3154         .vpane.lower.diff.header.status configure -text $s
3155         .vpane.lower.diff.header.file configure -text $f
3156         .vpane.lower.diff.header.path configure -text $p
3157         foreach w $diff_actions {
3158                 uplevel #0 $w $o
3159         }
3160 }
3161 trace add variable current_diff_path write trace_current_diff_path
3162
3163 frame .vpane.lower.diff.header -background gold
3164 label .vpane.lower.diff.header.status \
3165         -background gold \
3166         -foreground black \
3167         -width $max_status_desc \
3168         -anchor w \
3169         -justify left
3170 label .vpane.lower.diff.header.file \
3171         -background gold \
3172         -foreground black \
3173         -anchor w \
3174         -justify left
3175 label .vpane.lower.diff.header.path \
3176         -background gold \
3177         -foreground black \
3178         -anchor w \
3179         -justify left
3180 pack .vpane.lower.diff.header.status -side left
3181 pack .vpane.lower.diff.header.file -side left
3182 pack .vpane.lower.diff.header.path -fill x
3183 set ctxm .vpane.lower.diff.header.ctxm
3184 menu $ctxm -tearoff 0
3185 $ctxm add command \
3186         -label [mc Copy] \
3187         -command {
3188                 clipboard clear
3189                 clipboard append \
3190                         -format STRING \
3191                         -type STRING \
3192                         -- $current_diff_path
3193         }
3194 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3195 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3196
3197 # -- Diff Body
3198 #
3199 frame .vpane.lower.diff.body
3200 set ui_diff .vpane.lower.diff.body.t
3201 text $ui_diff -background white -foreground black \
3202         -borderwidth 0 \
3203         -width 80 -height 5 -wrap none \
3204         -font font_diff \
3205         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3206         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3207         -state disabled
3208 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3209         -command [list $ui_diff xview]
3210 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3211         -command [list $ui_diff yview]
3212 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3213 pack .vpane.lower.diff.body.sby -side right -fill y
3214 pack $ui_diff -side left -fill both -expand 1
3215 pack .vpane.lower.diff.header -side top -fill x
3216 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3217
3218 $ui_diff tag conf d_cr -elide true
3219 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
3220 $ui_diff tag conf d_+ -foreground {#00a000}
3221 $ui_diff tag conf d_- -foreground red
3222
3223 $ui_diff tag conf d_++ -foreground {#00a000}
3224 $ui_diff tag conf d_-- -foreground red
3225 $ui_diff tag conf d_+s \
3226         -foreground {#00a000} \
3227         -background {#e2effa}
3228 $ui_diff tag conf d_-s \
3229         -foreground red \
3230         -background {#e2effa}
3231 $ui_diff tag conf d_s+ \
3232         -foreground {#00a000} \
3233         -background ivory1
3234 $ui_diff tag conf d_s- \
3235         -foreground red \
3236         -background ivory1
3237
3238 $ui_diff tag conf d<<<<<<< \
3239         -foreground orange \
3240         -font font_diffbold
3241 $ui_diff tag conf d======= \
3242         -foreground orange \
3243         -font font_diffbold
3244 $ui_diff tag conf d>>>>>>> \
3245         -foreground orange \
3246         -font font_diffbold
3247
3248 $ui_diff tag raise sel
3249
3250 # -- Diff Body Context Menu
3251 #
3252
3253 proc create_common_diff_popup {ctxm} {
3254         $ctxm add command \
3255                 -label [mc Refresh] \
3256                 -command reshow_diff
3257         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3258         $ctxm add command \
3259                 -label [mc Copy] \
3260                 -command {tk_textCopy $ui_diff}
3261         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3262         $ctxm add command \
3263                 -label [mc "Select All"] \
3264                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3265         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3266         $ctxm add command \
3267                 -label [mc "Copy All"] \
3268                 -command {
3269                         $ui_diff tag add sel 0.0 end
3270                         tk_textCopy $ui_diff
3271                         $ui_diff tag remove sel 0.0 end
3272                 }
3273         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3274         $ctxm add separator
3275         $ctxm add command \
3276                 -label [mc "Decrease Font Size"] \
3277                 -command {incr_font_size font_diff -1}
3278         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3279         $ctxm add command \
3280                 -label [mc "Increase Font Size"] \
3281                 -command {incr_font_size font_diff 1}
3282         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3283         $ctxm add separator
3284         set emenu $ctxm.enc
3285         menu $emenu
3286         build_encoding_menu $emenu [list force_diff_encoding]
3287         $ctxm add cascade \
3288                 -label [mc "Encoding"] \
3289                 -menu $emenu
3290         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3291         $ctxm add separator
3292         $ctxm add command -label [mc "Options..."] \
3293                 -command do_options
3294 }
3295
3296 set ctxm .vpane.lower.diff.body.ctxm
3297 menu $ctxm -tearoff 0
3298 $ctxm add command \
3299         -label [mc "Apply/Reverse Hunk"] \
3300         -command {apply_hunk $cursorX $cursorY}
3301 set ui_diff_applyhunk [$ctxm index last]
3302 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3303 $ctxm add command \
3304         -label [mc "Apply/Reverse Line"] \
3305         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3306 set ui_diff_applyline [$ctxm index last]
3307 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3308 $ctxm add separator
3309 $ctxm add command \
3310         -label [mc "Show Less Context"] \
3311         -command show_less_context
3312 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3313 $ctxm add command \
3314         -label [mc "Show More Context"] \
3315         -command show_more_context
3316 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3317 $ctxm add separator
3318 create_common_diff_popup $ctxm
3319
3320 set ctxmmg .vpane.lower.diff.body.ctxmmg
3321 menu $ctxmmg -tearoff 0
3322 $ctxmmg add command \
3323         -label [mc "Run Merge Tool"] \
3324         -command {merge_resolve_tool}
3325 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3326 $ctxmmg add separator
3327 $ctxmmg add command \
3328         -label [mc "Use Remote Version"] \
3329         -command {merge_resolve_one 3}
3330 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3331 $ctxmmg add command \
3332         -label [mc "Use Local Version"] \
3333         -command {merge_resolve_one 2}
3334 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3335 $ctxmmg add command \
3336         -label [mc "Revert To Base"] \
3337         -command {merge_resolve_one 1}
3338 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3339 $ctxmmg add separator
3340 $ctxmmg add command \
3341         -label [mc "Show Less Context"] \
3342         -command show_less_context
3343 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3344 $ctxmmg add command \
3345         -label [mc "Show More Context"] \
3346         -command show_more_context
3347 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3348 $ctxmmg add separator
3349 create_common_diff_popup $ctxmmg
3350
3351 set ctxmsm .vpane.lower.diff.body.ctxmsm
3352 menu $ctxmsm -tearoff 0
3353 $ctxmsm add command \
3354         -label [mc "Visualize These Changes In The Submodule"] \
3355         -command {do_gitk -- true}
3356 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3357 $ctxmsm add command \
3358         -label [mc "Visualize Current Branch History In The Submodule"] \
3359         -command {do_gitk {} true}
3360 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3361 $ctxmsm add command \
3362         -label [mc "Visualize All Branch History In The Submodule"] \
3363         -command {do_gitk --all true}
3364 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3365 $ctxmsm add separator
3366 $ctxmsm add command \
3367         -label [mc "Start git gui In The Submodule"] \
3368         -command {do_git_gui}
3369 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3370 $ctxmsm add separator
3371 create_common_diff_popup $ctxmsm
3372
3373 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3374         global current_diff_path file_states
3375         set ::cursorX $x
3376         set ::cursorY $y
3377         if {[info exists file_states($current_diff_path)]} {
3378                 set state [lindex $file_states($current_diff_path) 0]
3379         } else {
3380                 set state {__}
3381         }
3382         if {[string first {U} $state] >= 0} {
3383                 tk_popup $ctxmmg $X $Y
3384         } elseif {$::is_submodule_diff} {
3385                 tk_popup $ctxmsm $X $Y
3386         } else {
3387                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3388                 if {$::ui_index eq $::current_diff_side} {
3389                         set l [mc "Unstage Hunk From Commit"]
3390                         if {$has_range} {
3391                                 set t [mc "Unstage Lines From Commit"]
3392                         } else {
3393                                 set t [mc "Unstage Line From Commit"]
3394                         }
3395                 } else {
3396                         set l [mc "Stage Hunk For Commit"]
3397                         if {$has_range} {
3398                                 set t [mc "Stage Lines For Commit"]
3399                         } else {
3400                                 set t [mc "Stage Line For Commit"]
3401                         }
3402                 }
3403                 if {$::is_3way_diff
3404                         || $current_diff_path eq {}
3405                         || {__} eq $state
3406                         || {_O} eq $state
3407                         || {_T} eq $state
3408                         || {T_} eq $state} {
3409                         set s disabled
3410                 } else {
3411                         set s normal
3412                 }
3413                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3414                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3415                 tk_popup $ctxm $X $Y
3416         }
3417 }
3418 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3419
3420 # -- Status Bar
3421 #
3422 set main_status [::status_bar::new .status]
3423 pack .status -anchor w -side bottom -fill x
3424 $main_status show [mc "Initializing..."]
3425
3426 # -- Load geometry
3427 #
3428 catch {
3429 set gm $repo_config(gui.geometry)
3430 wm geometry . [lindex $gm 0]
3431 .vpane sash place 0 \
3432         [lindex $gm 1] \
3433         [lindex [.vpane sash coord 0] 1]
3434 .vpane.files sash place 0 \
3435         [lindex [.vpane.files sash coord 0] 0] \
3436         [lindex $gm 2]
3437 unset gm
3438 }
3439
3440 # -- Load window state
3441 #
3442 catch {
3443 set gws $repo_config(gui.wmstate)
3444 wm state . $gws
3445 unset gws
3446 }
3447
3448 # -- Key Bindings
3449 #
3450 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3451 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3452 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3453 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3454 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3455 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3456 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3457 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3458 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3459 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3460 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3461 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3462 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3463 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3464 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3465 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3466 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3467 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3468 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3469 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3470 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3471 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3472
3473 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3474 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3475 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3476 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3477 bind $ui_diff <$M1B-Key-v> {break}
3478 bind $ui_diff <$M1B-Key-V> {break}
3479 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3480 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3481 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3482 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3483 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3484 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3485 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3486 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3487 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3488 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3489 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3490 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3491 bind $ui_diff <Button-1>   {focus %W}
3492
3493 if {[is_enabled branch]} {
3494         bind . <$M1B-Key-n> branch_create::dialog
3495         bind . <$M1B-Key-N> branch_create::dialog
3496         bind . <$M1B-Key-o> branch_checkout::dialog
3497         bind . <$M1B-Key-O> branch_checkout::dialog
3498         bind . <$M1B-Key-m> merge::dialog
3499         bind . <$M1B-Key-M> merge::dialog
3500 }
3501 if {[is_enabled transport]} {
3502         bind . <$M1B-Key-p> do_push_anywhere
3503         bind . <$M1B-Key-P> do_push_anywhere
3504 }
3505
3506 bind .   <Key-F5>     ui_do_rescan
3507 bind .   <$M1B-Key-r> ui_do_rescan
3508 bind .   <$M1B-Key-R> ui_do_rescan
3509 bind .   <$M1B-Key-s> do_signoff
3510 bind .   <$M1B-Key-S> do_signoff
3511 bind .   <$M1B-Key-t> do_add_selection
3512 bind .   <$M1B-Key-T> do_add_selection
3513 bind .   <$M1B-Key-i> do_add_all
3514 bind .   <$M1B-Key-I> do_add_all
3515 bind .   <$M1B-Key-minus> {show_less_context;break}
3516 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3517 bind .   <$M1B-Key-equal> {show_more_context;break}
3518 bind .   <$M1B-Key-plus> {show_more_context;break}
3519 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3520 bind .   <$M1B-Key-Return> do_commit
3521 foreach i [list $ui_index $ui_workdir] {
3522         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3523         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3524         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3525 }
3526 unset i
3527
3528 set file_lists($ui_index) [list]
3529 set file_lists($ui_workdir) [list]
3530
3531 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3532 focus -force $ui_comm
3533
3534 # -- Warn the user about environmental problems.  Cygwin's Tcl
3535 #    does *not* pass its env array onto any processes it spawns.
3536 #    This means that git processes get none of our environment.
3537 #
3538 if {[is_Cygwin]} {
3539         set ignored_env 0
3540         set suggest_user {}
3541         set msg [mc "Possible environment issues exist.
3542
3543 The following environment variables are probably
3544 going to be ignored by any Git subprocess run
3545 by %s:
3546
3547 " [appname]]
3548         foreach name [array names env] {
3549                 switch -regexp -- $name {
3550                 {^GIT_INDEX_FILE$} -
3551                 {^GIT_OBJECT_DIRECTORY$} -
3552                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3553                 {^GIT_DIFF_OPTS$} -
3554                 {^GIT_EXTERNAL_DIFF$} -
3555                 {^GIT_PAGER$} -
3556                 {^GIT_TRACE$} -
3557                 {^GIT_CONFIG$} -
3558                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3559                         append msg " - $name\n"
3560                         incr ignored_env
3561                 }
3562                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3563                         append msg " - $name\n"
3564                         incr ignored_env
3565                         set suggest_user $name
3566                 }
3567                 }
3568         }
3569         if {$ignored_env > 0} {
3570                 append msg [mc "
3571 This is due to a known issue with the
3572 Tcl binary distributed by Cygwin."]
3573
3574                 if {$suggest_user ne {}} {
3575                         append msg [mc "
3576
3577 A good replacement for %s
3578 is placing values for the user.name and
3579 user.email settings into your personal
3580 ~/.gitconfig file.
3581 " $suggest_user]
3582                 }
3583                 warn_popup $msg
3584         }
3585         unset ignored_env msg suggest_user name
3586 }
3587
3588 # -- Only initialize complex UI if we are going to stay running.
3589 #
3590 if {[is_enabled transport]} {
3591         load_all_remotes
3592
3593         set n [.mbar.remote index end]
3594         populate_remotes_menu
3595         set n [expr {[.mbar.remote index end] - $n}]
3596         if {$n > 0} {
3597                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3598                 .mbar.remote insert $n separator
3599         }
3600         unset n
3601 }
3602
3603 if {[winfo exists $ui_comm]} {
3604         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3605
3606         # -- If both our backup and message files exist use the
3607         #    newer of the two files to initialize the buffer.
3608         #
3609         if {$GITGUI_BCK_exists} {
3610                 set m [gitdir GITGUI_MSG]
3611                 if {[file isfile $m]} {
3612                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3613                                 catch {file delete [gitdir GITGUI_MSG]}
3614                         } else {
3615                                 $ui_comm delete 0.0 end
3616                                 $ui_comm edit reset
3617                                 $ui_comm edit modified false
3618                                 catch {file delete [gitdir GITGUI_BCK]}
3619                                 set GITGUI_BCK_exists 0
3620                         }
3621                 }
3622                 unset m
3623         }
3624
3625         proc backup_commit_buffer {} {
3626                 global ui_comm GITGUI_BCK_exists
3627
3628                 set m [$ui_comm edit modified]
3629                 if {$m || $GITGUI_BCK_exists} {
3630                         set msg [string trim [$ui_comm get 0.0 end]]
3631                         regsub -all -line {[ \r\t]+$} $msg {} msg
3632
3633                         if {$msg eq {}} {
3634                                 if {$GITGUI_BCK_exists} {
3635                                         catch {file delete [gitdir GITGUI_BCK]}
3636                                         set GITGUI_BCK_exists 0
3637                                 }
3638                         } elseif {$m} {
3639                                 catch {
3640                                         set fd [open [gitdir GITGUI_BCK] w]
3641                                         puts -nonewline $fd $msg
3642                                         close $fd
3643                                         set GITGUI_BCK_exists 1
3644                                 }
3645                         }
3646
3647                         $ui_comm edit modified false
3648                 }
3649
3650                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3651         }
3652
3653         backup_commit_buffer
3654
3655         # -- If the user has aspell available we can drive it
3656         #    in pipe mode to spellcheck the commit message.
3657         #
3658         set spell_cmd [list |]
3659         set spell_dict [get_config gui.spellingdictionary]
3660         lappend spell_cmd aspell
3661         if {$spell_dict ne {}} {
3662                 lappend spell_cmd --master=$spell_dict
3663         }
3664         lappend spell_cmd --mode=none
3665         lappend spell_cmd --encoding=utf-8
3666         lappend spell_cmd pipe
3667         if {$spell_dict eq {none}
3668          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3669                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3670         } else {
3671                 set ui_comm_spell [spellcheck::init \
3672                         $spell_fd \
3673                         $ui_comm \
3674                         $ui_comm_ctxm \
3675                 ]
3676         }
3677         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3678 }
3679
3680 lock_index begin-read
3681 if {![winfo ismapped .]} {
3682         wm deiconify .
3683 }
3684 after 1 {
3685         if {[is_enabled initialamend]} {
3686                 force_amend
3687         } else {
3688                 do_rescan
3689         }
3690
3691         if {[is_enabled nocommitmsg]} {
3692                 $ui_comm configure -state disabled -background gray
3693         }
3694 }
3695 if {[is_enabled multicommit]} {
3696         after 1000 hint_gc
3697 }
3698 if {[is_enabled retcode]} {
3699         bind . <Destroy> {+terminate_me %W}
3700 }
3701 if {$picked && [is_config_true gui.autoexplore]} {
3702         do_explore
3703 }