configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  79 # Define PYTHON_PATH to provide path to Python.
  80 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
  81 AS_HELP_STRING([--without-python], [don't use python scripts])],
  82  [if test "$withval" = "no"; then \
  83     NO_PYTHON=YesPlease; \
  84   elif test "$withval" = "yes"; then \
  85     NO_PYTHON=; \
  86   else \
  87     NO_PYTHON=; \
  88     PYTHON_PATH=$withval; \
  89   fi; \
  90  ])
  91 AC_SUBST(NO_PYTHON)
  92 AC_SUBST(PYTHON_PATH)
  93
  94
  95 ## Checks for programs.
  96 AC_MSG_NOTICE([CHECKS for programs])
  97 #
  98 AC_PROG_CC
  99 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 100 AC_CHECK_TOOL(AR, ar, :)
 101 AC_CHECK_PROGS(TAR, [gtar tar])
 102 #
 103 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 104 # Define PYTHON_PATH to provide path to Python.
 105 if test -z "$NO_PYTHON"; then
 106         if test -z "$PYTHON_PATH"; then
 107                 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 108         fi
 109         if test -n "$PYTHON_PATH"; then
 110                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 111                 NO_PYTHON=""
 112         fi
 113 fi
 114
 115
 116 ## Checks for libraries.
 117 AC_MSG_NOTICE([CHECKS for libraries])
 118 #
 119 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 120 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 121 AC_CHECK_LIB([crypto], [SHA1_Init],
 122 [NEEDS_SSL_WITH_CRYPTO=],
 123 [AC_CHECK_LIB([ssl], [SHA1_Init],
 124  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 125   NEEDS_SSL_WITH_CRYPTO=],
 126  [NO_OPENSSL=YesPlease])])
 127 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 128 AC_SUBST(NO_OPENSSL)
 129 #
 130 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 131 # git-http-push are not built, and you cannot use http:// and https://
 132 # transports.
 133 AC_CHECK_LIB([curl], [curl_global_init],
 134 [NO_CURL=],
 135 [NO_CURL=YesPlease])
 136 AC_SUBST(NO_CURL)
 137 #
 138 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 139 # not built, and you cannot push using http:// and https:// transports.
 140 AC_CHECK_LIB([expat], [XML_ParserCreate],
 141 [NO_EXPAT=],
 142 [NO_EXPAT=YesPlease])
 143 AC_SUBST(NO_EXPAT)
 144 #
 145 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 146 AC_CHECK_LIB([c], [iconv],
 147 [NEEDS_LIBICONV=],
 148 [NEEDS_LIBICONV=YesPlease])
 149 AC_SUBST(NEEDS_LIBICONV)
 150 #
 151 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 152 # Patrick Mauritz).
 153 AC_CHECK_LIB([c], [socket],
 154 [NEEDS_SOCKET=],
 155 [NEEDS_SOCKET=YesPlease])
 156 AC_SUBST(NEEDS_SOCKET)
 157
 158
 159 ## Checks for header files.
 160
 161
 162 ## Checks for typedefs, structures, and compiler characteristics.
 163 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 164 #
 165 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 166 AC_CHECK_MEMBER(struct dirent.d_ino,
 167 [NO_D_INO_IN_DIRENT=],
 168 [NO_D_INO_IN_DIRENT=YesPlease],
 169 [#include <dirent.h>])
 170 AC_SUBST(NO_D_INO_IN_DIRENT)
 171 #
 172 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 173 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 174 AC_CHECK_MEMBER(struct dirent.d_type,
 175 [NO_D_TYPE_IN_DIRENT=],
 176 [NO_D_TYPE_IN_DIRENT=YesPlease],
 177 [#include <dirent.h>])
 178 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 179 #
 180 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 181 # sockaddr_storage.
 182 AC_CHECK_TYPE(struct sockaddr_storage,
 183 [NO_SOCKADDR_STORAGE=],
 184 [NO_SOCKADDR_STORAGE=YesPlease],
 185 [#include <netinet/in.h>])
 186 AC_SUBST(NO_SOCKADDR_STORAGE)
 187 #
 188 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 189 AC_CHECK_TYPE([struct addrinfo],[
 190  AC_CHECK_FUNC([getaddrinfo],
 191   [NO_IPV6=],
 192   [NO_IPV6=YesPlease])
 193 ],[NO_IPV6=YesPlease],[
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <netdb.h>
 197 ])
 198 AC_SUBST(NO_IPV6)
 199 #
 200 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 201 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 202 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 203 # some C compilers supported these specifiers prior to C99 as an extension.
 204 AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 205  ac_cv_c_c99_format,
 206 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 207 AC_RUN_IFELSE(
 208         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 209                 [[char buf[64];
 210                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 211                   exit(1);
 212                 else if (strcmp(buf, "12345"))
 213                   exit(2);]])],
 214         [ac_cv_c_c99_format=yes],
 215         [ac_cv_c_c99_format=no])
 216 ])
 217 if test $ac_cv_c_c99_format = no; then
 218         NO_C99_FORMAT=YesPlease
 219 else
 220         NO_C99_FORMAT=
 221 fi
 222 AC_SUBST(NO_C99_FORMAT)
 223
 224
 225 ## Checks for library functions.
 226 ## (in default C library and libraries checked by AC_CHECK_LIB)
 227 AC_MSG_NOTICE([CHECKS for library functions])
 228 #
 229 # Define NO_STRCASESTR if you don't have strcasestr.
 230 AC_CHECK_FUNC(strcasestr,
 231 [NO_STRCASESTR=],
 232 [NO_STRCASESTR=YesPlease])
 233 AC_SUBST(NO_STRCASESTR)
 234 #
 235 # Define NO_STRLCPY if you don't have strlcpy.
 236 AC_CHECK_FUNC(strlcpy,
 237 [NO_STRLCPY=],
 238 [NO_STRLCPY=YesPlease])
 239 AC_SUBST(NO_STRLCPY)
 240 #
 241 # Define NO_SETENV if you don't have setenv in the C library.
 242 AC_CHECK_FUNC(setenv,
 243 [NO_SETENV=],
 244 [NO_SETENV=YesPlease])
 245 AC_SUBST(NO_SETENV)
 246 #
 247 # Define NO_MMAP if you want to avoid mmap.
 248 #
 249 # Define NO_ICONV if your libc does not properly support iconv.
 250
 251
 252 ## Other checks.
 253 # Define USE_PIC if you need the main git objects to be built with -fPIC
 254 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 255 #
 256 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 257 # Enable it on Windows.  By default, symrefs are still used.
 258 #
 259 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 260 #
 261 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 262 # a missing newline at the end of the file.
 263
 264
 265 ## Site configuration (override autodetection)
 266 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 267 AC_MSG_NOTICE([CHECKS for site configuration])
 268 #
 269 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 270 # tests.  These tests take up a significant amount of the total test time
 271 # but are not needed unless you plan to talk to SVN repos.
 272 #
 273 # Define MOZILLA_SHA1 environment variable when running make to make use of
 274 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 275 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 276 # choice) has very fast version optimized for i586.
 277 #
 278 # Define PPC_SHA1 environment variable when running make to make use of
 279 # a bundled SHA1 routine optimized for PowerPC.
 280 #
 281 # Define ARM_SHA1 environment variable when running make to make use of
 282 # a bundled SHA1 routine optimized for ARM.
 283 #
 284 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 285 # This also implies MOZILLA_SHA1.
 286 #
 287 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 288 # /foo/bar/include and /foo/bar/lib directories.
 289 AC_ARG_WITH(openssl,
 290 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 291 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 292 GIT_PARSE_WITH(openssl))
 293 #
 294 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 295 # git-http-push are not built, and you cannot use http:// and https://
 296 # transports.
 297 #
 298 # Define CURLDIR=/foo/bar if your curl header and library files are in
 299 # /foo/bar/include and /foo/bar/lib directories.
 300 AC_ARG_WITH(curl,
 301 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 302 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 303 GIT_PARSE_WITH(curl))
 304 #
 305 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 306 # not built, and you cannot push using http:// and https:// transports.
 307 #
 308 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 309 # /foo/bar/include and /foo/bar/lib directories.
 310 AC_ARG_WITH(expat,
 311 AS_HELP_STRING([--with-expat],
 312 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 313 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 314 GIT_PARSE_WITH(expat))
 315 #
 316 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 317 # installed in /sw, but don't want GIT to link against any libraries
 318 # installed there.  If defined you may specify your own (or Fink's)
 319 # include directories and library directories by defining CFLAGS
 320 # and LDFLAGS appropriately.
 321 #
 322 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 323 # have DarwinPorts installed in /opt/local, but don't want GIT to
 324 # link against any libraries installed there.  If defined you may
 325 # specify your own (or DarwinPort's) include directories and
 326 # library directories by defining CFLAGS and LDFLAGS appropriately.
 327 #
 328 # Define NO_MMAP if you want to avoid mmap.
 329
 330 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 331 #
 332 # Define COLLISION_CHECK below if you believe that SHA1's
 333 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 334 # sufficient guarantee that no collisions between objects will ever happen.
 335 #
 336 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 337 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 338 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 339 # randomly break unless your underlying filesystem supports those sub-second
 340 # times (my ext3 doesn't).
 341 #
 342 # Define USE_STDEV below if you want git to care about the underlying device
 343 # change being considered an inode change from the update-cache perspective.
 344
 345
 346 ## Output files
 347 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 348 AC_OUTPUT
 349
 350
 351 ## Cleanup
 352 rm -f "${config_append}"