git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself if your address
  92                   appears in a From: line. Defaults to off.
  93
  94    --thread       Specify that the "In-Reply-To:" header should be set on all
  95                   emails. Defaults to on.
  96
  97    --quiet        Make git-send-email less verbose.  One line per email
  98                   should be all that is output.
  99
 100    --dry-run      Do everything except actually send the emails.
 101
 102    --envelope-sender    Specify the envelope sender used to send the emails.
 103
 104 EOT
 105         exit(1);
 106 }
 107
 108 # most mail servers generate the Date: header, but not all...
 109 sub format_2822_time {
 110         my ($time) = @_;
 111         my @localtm = localtime($time);
 112         my @gmttm = gmtime($time);
 113         my $localmin = $localtm[1] + $localtm[2] * 60;
 114         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 115         if ($localtm[0] != $gmttm[0]) {
 116                 die "local zone differs from GMT by a non-minute interval\n";
 117         }
 118         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 119                 $localmin += 1440;
 120         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 121                 $localmin -= 1440;
 122         } elsif ($gmttm[6] != $localtm[6]) {
 123                 die "local time offset greater than or equal to 24 hours\n";
 124         }
 125         my $offset = $localmin - $gmtmin;
 126         my $offhour = $offset / 60;
 127         my $offmin = abs($offset % 60);
 128         if (abs($offhour) >= 24) {
 129                 die ("local time offset greater than or equal to 24 hours\n");
 130         }
 131
 132         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 133                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 134                        $localtm[3],
 135                        qw(Jan Feb Mar Apr May Jun
 136                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 137                        $localtm[5]+1900,
 138                        $localtm[2],
 139                        $localtm[1],
 140                        $localtm[0],
 141                        ($offset >= 0) ? '+' : '-',
 142                        abs($offhour),
 143                        $offmin,
 144                        );
 145 }
 146
 147 my $have_email_valid = eval { require Email::Valid; 1 };
 148 my $smtp;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180
 181 my %config_bool_settings = (
 182     "thread" => [\$thread, 1],
 183     "chainreplyto" => [\$chain_reply_to, 1],
 184     "suppressfrom" => [\$suppress_from, 0],
 185     "signedoffcc" => [\$signed_off_cc, 1],
 186     "smtpssl" => [\$smtp_ssl, 0],
 187 );
 188
 189 my %config_settings = (
 190     "smtpserver" => \$smtp_server,
 191     "smtpserverport" => \$smtp_server_port,
 192     "smtpuser" => \$smtp_authuser,
 193     "smtppass" => \$smtp_authpass,
 194     "to" => \@to,
 195     "cccmd" => \$cc_cmd,
 196     "aliasfiletype" => \$aliasfiletype,
 197     "bcc" => \@bcclist,
 198     "aliasesfile" => \@alias_files,
 199 );
 200
 201 # Begin by accumulating all the variables (defined above), that we will end up
 202 # needing, first, from the command line:
 203
 204 my $rc = GetOptions("sender|from=s" => \$sender,
 205                     "in-reply-to=s" => \$initial_reply_to,
 206                     "subject=s" => \$initial_subject,
 207                     "to=s" => \@to,
 208                     "cc=s" => \@initial_cc,
 209                     "bcc=s" => \@bcclist,
 210                     "chain-reply-to!" => \$chain_reply_to,
 211                     "smtp-server=s" => \$smtp_server,
 212                     "smtp-server-port=s" => \$smtp_server_port,
 213                     "smtp-user=s" => \$smtp_authuser,
 214                     "smtp-pass=s" => \$smtp_authpass,
 215                     "smtp-ssl!" => \$smtp_ssl,
 216                     "identity=s" => \$identity,
 217                     "compose" => \$compose,
 218                     "quiet" => \$quiet,
 219                     "cc-cmd=s" => \$cc_cmd,
 220                     "suppress-from!" => \$suppress_from,
 221                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 222                     "dry-run" => \$dry_run,
 223                     "envelope-sender=s" => \$envelope_sender,
 224                     "thread!" => \$thread,
 225          );
 226
 227 unless ($rc) {
 228     usage();
 229 }
 230
 231 # Now, let's fill any that aren't set in with defaults:
 232
 233 sub read_config {
 234         my ($prefix) = @_;
 235
 236         foreach my $setting (keys %config_bool_settings) {
 237                 my $target = $config_bool_settings{$setting}->[0];
 238                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 239         }
 240
 241         foreach my $setting (keys %config_settings) {
 242                 my $target = $config_settings{$setting};
 243                 if (ref($target) eq "ARRAY") {
 244                         unless (@$target) {
 245                                 my @values = $repo->config("$prefix.$setting");
 246                                 @$target = @values if (@values && defined $values[0]);
 247                         }
 248                 }
 249                 else {
 250                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 251                 }
 252         }
 253 }
 254
 255 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 256 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 257 read_config("sendemail.$identity") if (defined $identity);
 258 read_config("sendemail");
 259
 260 # fall back on builtin bool defaults
 261 foreach my $setting (values %config_bool_settings) {
 262         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 263 }
 264
 265 my ($repoauthor) = $repo->ident_person('author');
 266 my ($repocommitter) = $repo->ident_person('committer');
 267
 268 # Verify the user input
 269
 270 foreach my $entry (@to) {
 271         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 272 }
 273
 274 foreach my $entry (@initial_cc) {
 275         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 276 }
 277
 278 foreach my $entry (@bcclist) {
 279         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 280 }
 281
 282 my %aliases;
 283 my %parse_alias = (
 284         # multiline formats can be supported in the future
 285         mutt => sub { my $fh = shift; while (<$fh>) {
 286                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 287                         my ($alias, $addr) = ($1, $2);
 288                         $addr =~ s/#.*$//; # mutt allows # comments
 289                          # commas delimit multiple addresses
 290                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 291                 }}},
 292         mailrc => sub { my $fh = shift; while (<$fh>) {
 293                 if (/^alias\s+(\S+)\s+(.*)$/) {
 294                         # spaces delimit multiple addresses
 295                         $aliases{$1} = [ split(/\s+/, $2) ];
 296                 }}},
 297         pine => sub { my $fh = shift; while (<$fh>) {
 298                 if (/^(\S+)\t.*\t(.*)$/) {
 299                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 300                 }}},
 301         gnus => sub { my $fh = shift; while (<$fh>) {
 302                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 303                         $aliases{$1} = [ $2 ];
 304                 }}}
 305 );
 306
 307 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 308         foreach my $file (@alias_files) {
 309                 open my $fh, '<', $file or die "opening $file: $!\n";
 310                 $parse_alias{$aliasfiletype}->($fh);
 311                 close $fh;
 312         }
 313 }
 314
 315 ($sender) = expand_aliases($sender) if defined $sender;
 316
 317 my $prompting = 0;
 318 if (!defined $sender) {
 319         $sender = $repoauthor || $repocommitter;
 320         do {
 321                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 322         } while (!defined $_);
 323
 324         $sender = $_ if ($_);
 325         print "Emails will be sent from: ", $sender, "\n";
 326         $prompting++;
 327 }
 328
 329 if (!@to) {
 330         do {
 331                 $_ = $term->readline("Who should the emails be sent to? ",
 332                                 "");
 333         } while (!defined $_);
 334         my $to = $_;
 335         push @to, split /,/, $to;
 336         $prompting++;
 337 }
 338
 339 sub expand_aliases {
 340         my @cur = @_;
 341         my @last;
 342         do {
 343                 @last = @cur;
 344                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 345         } while (join(',',@cur) ne join(',',@last));
 346         return @cur;
 347 }
 348
 349 @to = expand_aliases(@to);
 350 @to = (map { sanitize_address($_) } @to);
 351 @initial_cc = expand_aliases(@initial_cc);
 352 @bcclist = expand_aliases(@bcclist);
 353
 354 if (!defined $initial_subject && $compose) {
 355         do {
 356                 $_ = $term->readline("What subject should the emails start with? ",
 357                         $initial_subject);
 358         } while (!defined $_);
 359         $initial_subject = $_;
 360         $prompting++;
 361 }
 362
 363 if ($thread && !defined $initial_reply_to && $prompting) {
 364         do {
 365                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 366                         $initial_reply_to);
 367         } while (!defined $_);
 368
 369         $initial_reply_to = $_;
 370         $initial_reply_to =~ s/^\s+<?/</;
 371         $initial_reply_to =~ s/>?\s+$/>/;
 372 }
 373
 374 if (!defined $smtp_server) {
 375         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 376                 if (-x $_) {
 377                         $smtp_server = $_;
 378                         last;
 379                 }
 380         }
 381         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 382 }
 383
 384 if ($compose) {
 385         # Note that this does not need to be secure, but we will make a small
 386         # effort to have it be unique
 387         open(C,">",$compose_filename)
 388                 or die "Failed to open for writing $compose_filename: $!";
 389         print C "From $sender # This line is ignored.\n";
 390         printf C "Subject: %s\n\n", $initial_subject;
 391         printf C <<EOT;
 392 GIT: Please enter your email below.
 393 GIT: Lines beginning in "GIT: " will be removed.
 394 GIT: Consider including an overall diffstat or table of contents
 395 GIT: for the patch you are writing.
 396
 397 EOT
 398         close(C);
 399
 400         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 401         system($editor, $compose_filename);
 402
 403         open(C2,">",$compose_filename . ".final")
 404                 or die "Failed to open $compose_filename.final : " . $!;
 405
 406         open(C,"<",$compose_filename)
 407                 or die "Failed to open $compose_filename : " . $!;
 408
 409         while(<C>) {
 410                 next if m/^GIT: /;
 411                 print C2 $_;
 412         }
 413         close(C);
 414         close(C2);
 415
 416         do {
 417                 $_ = $term->readline("Send this email? (y|n) ");
 418         } while (!defined $_);
 419
 420         if (uc substr($_,0,1) ne 'Y') {
 421                 cleanup_compose_files();
 422                 exit(0);
 423         }
 424
 425         @files = ($compose_filename . ".final");
 426 }
 427
 428
 429 # Now that all the defaults are set, process the rest of the command line
 430 # arguments and collect up the files that need to be processed.
 431 for my $f (@ARGV) {
 432         if (-d $f) {
 433                 opendir(DH,$f)
 434                         or die "Failed to opendir $f: $!";
 435
 436                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 437                                 sort readdir(DH);
 438
 439         } elsif (-f $f) {
 440                 push @files, $f;
 441
 442         } else {
 443                 print STDERR "Skipping $f - not found.\n";
 444         }
 445 }
 446
 447 if (@files) {
 448         unless ($quiet) {
 449                 print $_,"\n" for (@files);
 450         }
 451 } else {
 452         print STDERR "\nNo patch files specified!\n\n";
 453         usage();
 454 }
 455
 456 # Variables we set as part of the loop over files
 457 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 458
 459 sub extract_valid_address {
 460         my $address = shift;
 461         my $local_part_regexp = '[^<>"\s@]+';
 462         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 463
 464         # check for a local address:
 465         return $address if ($address =~ /^($local_part_regexp)$/);
 466
 467         $address =~ s/^\s*<(.*)>\s*$/$1/;
 468         if ($have_email_valid) {
 469                 return scalar Email::Valid->address($address);
 470         } else {
 471                 # less robust/correct than the monster regexp in Email::Valid,
 472                 # but still does a 99% job, and one less dependency
 473                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 474                 return $1;
 475         }
 476 }
 477
 478 # Usually don't need to change anything below here.
 479
 480 # we make a "fake" message id by taking the current number
 481 # of seconds since the beginning of Unix time and tacking on
 482 # a random number to the end, in case we are called quicker than
 483 # 1 second since the last time we were called.
 484
 485 # We'll setup a template for the message id, using the "from" address:
 486
 487 my ($message_id_stamp, $message_id_serial);
 488 sub make_message_id
 489 {
 490         my $uniq;
 491         if (!defined $message_id_stamp) {
 492                 $message_id_stamp = sprintf("%s-%s", time, $$);
 493                 $message_id_serial = 0;
 494         }
 495         $message_id_serial++;
 496         $uniq = "$message_id_stamp-$message_id_serial";
 497
 498         my $du_part;
 499         for ($sender, $repocommitter, $repoauthor) {
 500                 $du_part = extract_valid_address(sanitize_address($_));
 501                 last if (defined $du_part and $du_part ne '');
 502         }
 503         if (not defined $du_part or $du_part eq '') {
 504                 use Sys::Hostname qw();
 505                 $du_part = 'user@' . Sys::Hostname::hostname();
 506         }
 507         my $message_id_template = "<%s-git-send-email-%s>";
 508         $message_id = sprintf($message_id_template, $uniq, $du_part);
 509         #print "new message id = $message_id\n"; # Was useful for debugging
 510 }
 511
 512
 513
 514 $time = time - scalar $#files;
 515
 516 sub unquote_rfc2047 {
 517         local ($_) = @_;
 518         if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
 519                 s/_/ /g;
 520                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 521         }
 522         return "$_";
 523 }
 524
 525 # use the simplest quoting being able to handle the recipient
 526 sub sanitize_address
 527 {
 528         my ($recipient) = @_;
 529         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 530
 531         if (not $recipient_name) {
 532                 return "$recipient";
 533         }
 534
 535         # if recipient_name is already quoted, do nothing
 536         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 537                 return $recipient;
 538         }
 539
 540         # rfc2047 is needed if a non-ascii char is included
 541         if ($recipient_name =~ /[^[:ascii:]]/) {
 542                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 543                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 544         }
 545
 546         # double quotes are needed if specials or CTLs are included
 547         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 548                 $recipient_name =~ s/(["\\\r])/\\$1/;
 549                 $recipient_name = "\"$recipient_name\"";
 550         }
 551
 552         return "$recipient_name $recipient_addr";
 553
 554 }
 555
 556 sub send_message
 557 {
 558         my @recipients = unique_email_list(@to);
 559         @cc = (map { sanitize_address($_) } @cc);
 560         my $to = join (",\n\t", @recipients);
 561         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 562         @recipients = (map { extract_valid_address($_) } @recipients);
 563         my $date = format_2822_time($time++);
 564         my $gitversion = '@@GIT_VERSION@@';
 565         if ($gitversion =~ m/..GIT_VERSION../) {
 566             $gitversion = Git::version();
 567         }
 568
 569         my $cc = join(", ", unique_email_list(@cc));
 570         my $ccline = "";
 571         if ($cc ne '') {
 572                 $ccline = "\nCc: $cc";
 573         }
 574         my $sanitized_sender = sanitize_address($sender);
 575         make_message_id();
 576
 577         my $header = "From: $sanitized_sender
 578 To: $to${ccline}
 579 Subject: $subject
 580 Date: $date
 581 Message-Id: $message_id
 582 X-Mailer: git-send-email $gitversion
 583 ";
 584         if ($thread && $reply_to) {
 585
 586                 $header .= "In-Reply-To: $reply_to\n";
 587                 $header .= "References: $references\n";
 588         }
 589         if (@xh) {
 590                 $header .= join("\n", @xh) . "\n";
 591         }
 592
 593         my @sendmail_parameters = ('-i', @recipients);
 594         my $raw_from = $sanitized_sender;
 595         $raw_from = $envelope_sender if (defined $envelope_sender);
 596         $raw_from = extract_valid_address($raw_from);
 597         unshift (@sendmail_parameters,
 598                         '-f', $raw_from) if(defined $envelope_sender);
 599
 600         if ($dry_run) {
 601                 # We don't want to send the email.
 602         } elsif ($smtp_server =~ m#^/#) {
 603                 my $pid = open my $sm, '|-';
 604                 defined $pid or die $!;
 605                 if (!$pid) {
 606                         exec($smtp_server, @sendmail_parameters) or die $!;
 607                 }
 608                 print $sm "$header\n$message";
 609                 close $sm or die $?;
 610         } else {
 611
 612                 if (!defined $smtp_server) {
 613                         die "The required SMTP server is not properly defined."
 614                 }
 615
 616                 if ($smtp_ssl) {
 617                         $smtp_server_port ||= 465; # ssmtp
 618                         require Net::SMTP::SSL;
 619                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 620                 }
 621                 else {
 622                         require Net::SMTP;
 623                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 624                                                  ? "$smtp_server:$smtp_server_port"
 625                                                  : $smtp_server);
 626                 }
 627
 628                 if (!$smtp) {
 629                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 630                 }
 631
 632                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 633                         $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 634                 }
 635                 $smtp->mail( $raw_from ) or die $smtp->message;
 636                 $smtp->to( @recipients ) or die $smtp->message;
 637                 $smtp->data or die $smtp->message;
 638                 $smtp->datasend("$header\n$message") or die $smtp->message;
 639                 $smtp->dataend() or die $smtp->message;
 640                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 641         }
 642         if ($quiet) {
 643                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 644         } else {
 645                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 646                 if ($smtp_server !~ m#^/#) {
 647                         print "Server: $smtp_server\n";
 648                         print "MAIL FROM:<$raw_from>\n";
 649                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 650                 } else {
 651                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 652                 }
 653                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 654                 if ($smtp) {
 655                         print "Result: ", $smtp->code, ' ',
 656                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 657                 } else {
 658                         print "Result: OK\n";
 659                 }
 660         }
 661 }
 662
 663 $reply_to = $initial_reply_to;
 664 $references = $initial_reply_to || '';
 665 $subject = $initial_subject;
 666
 667 foreach my $t (@files) {
 668         open(F,"<",$t) or die "can't open file $t";
 669
 670         my $author = undef;
 671         @cc = @initial_cc;
 672         @xh = ();
 673         my $input_format = undef;
 674         my $header_done = 0;
 675         $message = "";
 676         while(<F>) {
 677                 if (!$header_done) {
 678                         if (/^From /) {
 679                                 $input_format = 'mbox';
 680                                 next;
 681                         }
 682                         chomp;
 683                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 684                                 $input_format = 'mbox';
 685                         }
 686
 687                         if (defined $input_format && $input_format eq 'mbox') {
 688                                 if (/^Subject:\s+(.*)$/) {
 689                                         $subject = $1;
 690
 691                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 692                                         if (unquote_rfc2047($2) eq $sender) {
 693                                                 next if ($suppress_from);
 694                                         }
 695                                         elsif ($1 eq 'From') {
 696                                                 $author = unquote_rfc2047($2);
 697                                         }
 698                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 699                                                 $2, $_) unless $quiet;
 700                                         push @cc, $2;
 701                                 }
 702                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 703                                         push @xh, $_;
 704                                 }
 705
 706                         } else {
 707                                 # In the traditional
 708                                 # "send lots of email" format,
 709                                 # line 1 = cc
 710                                 # line 2 = subject
 711                                 # So let's support that, too.
 712                                 $input_format = 'lots';
 713                                 if (@cc == 0) {
 714                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 715                                                 $_, $_) unless $quiet;
 716
 717                                         push @cc, $_;
 718
 719                                 } elsif (!defined $subject) {
 720                                         $subject = $_;
 721                                 }
 722                         }
 723
 724                         # A whitespace line will terminate the headers
 725                         if (m/^\s*$/) {
 726                                 $header_done = 1;
 727                         }
 728                 } else {
 729                         $message .=  $_;
 730                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 731                                 my $c = $2;
 732                                 chomp $c;
 733                                 push @cc, $c;
 734                                 printf("(sob) Adding cc: %s from line '%s'\n",
 735                                         $c, $_) unless $quiet;
 736                         }
 737                 }
 738         }
 739         close F;
 740
 741         if (defined $cc_cmd) {
 742                 open(F, "$cc_cmd $t |")
 743                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 744                 while(<F>) {
 745                         my $c = $_;
 746                         $c =~ s/^\s*//g;
 747                         $c =~ s/\n$//g;
 748                         push @cc, $c;
 749                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 750                                 $c, $cc_cmd) unless $quiet;
 751                 }
 752                 close F
 753                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 754         }
 755
 756         if (defined $author) {
 757                 $message = "From: $author\n\n$message";
 758         }
 759
 760         send_message();
 761
 762         # set up for the next message
 763         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 764                 $reply_to = $message_id;
 765                 if (length $references > 0) {
 766                         $references .= "\n $message_id";
 767                 } else {
 768                         $references = "$message_id";
 769                 }
 770         }
 771 }
 772
 773 if ($compose) {
 774         cleanup_compose_files();
 775 }
 776
 777 sub cleanup_compose_files() {
 778         unlink($compose_filename, $compose_filename . ".final");
 779
 780 }
 781
 782 $smtp->quit if $smtp;
 783
 784 sub unique_email_list(@) {
 785         my %seen;
 786         my @emails;
 787
 788         foreach my $entry (@_) {
 789                 if (my $clean = extract_valid_address($entry)) {
 790                         $seen{$clean} ||= 0;
 791                         next if $seen{$clean}++;
 792                         push @emails, $entry;
 793                 } else {
 794                         print STDERR "W: unable to extract a valid address",
 795                                         " from: $entry\n";
 796                 }
 797         }
 798         return @emails;
 799 }