git-add--interactive.perl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Git;
   5
   6 binmode(STDOUT, ":raw");
   7
   8 my $repo = Git->repository();
   9
  10 my $menu_use_color = $repo->get_colorbool('color.interactive');
  11 my ($prompt_color, $header_color, $help_color) =
  12         $menu_use_color ? (
  13                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  14                 $repo->get_color('color.interactive.header', 'bold'),
  15                 $repo->get_color('color.interactive.help', 'red bold'),
  16         ) : ();
  17 my $error_color = ();
  18 if ($menu_use_color) {
  19         my $help_color_spec = ($repo->config('color.interactive.help') or
  20                                 'red bold');
  21         $error_color = $repo->get_color('color.interactive.error',
  22                                         $help_color_spec);
  23 }
  24
  25 my $diff_use_color = $repo->get_colorbool('color.diff');
  26 my ($fraginfo_color) =
  27         $diff_use_color ? (
  28                 $repo->get_color('color.diff.frag', 'cyan'),
  29         ) : ();
  30 my ($diff_plain_color) =
  31         $diff_use_color ? (
  32                 $repo->get_color('color.diff.plain', ''),
  33         ) : ();
  34 my ($diff_old_color) =
  35         $diff_use_color ? (
  36                 $repo->get_color('color.diff.old', 'red'),
  37         ) : ();
  38 my ($diff_new_color) =
  39         $diff_use_color ? (
  40                 $repo->get_color('color.diff.new', 'green'),
  41         ) : ();
  42
  43 my $normal_color = $repo->get_color("", "reset");
  44
  45 my $use_readkey = 0;
  46 sub ReadMode;
  47 sub ReadKey;
  48 if ($repo->config_bool("interactive.singlekey")) {
  49         eval {
  50                 require Term::ReadKey;
  51                 Term::ReadKey->import;
  52                 $use_readkey = 1;
  53         };
  54 }
  55
  56 sub colored {
  57         my $color = shift;
  58         my $string = join("", @_);
  59
  60         if (defined $color) {
  61                 # Put a color code at the beginning of each line, a reset at the end
  62                 # color after newlines that are not at the end of the string
  63                 $string =~ s/(\n+)(.)/$1$color$2/g;
  64                 # reset before newlines
  65                 $string =~ s/(\n+)/$normal_color$1/g;
  66                 # codes at beginning and end (if necessary):
  67                 $string =~ s/^/$color/;
  68                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  69         }
  70         return $string;
  71 }
  72
  73 # command line options
  74 my $patch_mode;
  75 my $patch_mode_revision;
  76
  77 sub apply_patch;
  78 sub apply_patch_for_checkout_commit;
  79 sub apply_patch_for_stash;
  80
  81 my %patch_modes = (
  82         'stage' => {
  83                 DIFF => 'diff-files -p',
  84                 APPLY => sub { apply_patch 'apply --cached', @_; },
  85                 APPLY_CHECK => 'apply --cached',
  86                 VERB => 'Stage',
  87                 TARGET => '',
  88                 PARTICIPLE => 'staging',
  89                 FILTER => 'file-only',
  90         },
  91         'stash' => {
  92                 DIFF => 'diff-index -p HEAD',
  93                 APPLY => sub { apply_patch 'apply --cached', @_; },
  94                 APPLY_CHECK => 'apply --cached',
  95                 VERB => 'Stash',
  96                 TARGET => '',
  97                 PARTICIPLE => 'stashing',
  98                 FILTER => undef,
  99         },
 100         'reset_head' => {
 101                 DIFF => 'diff-index -p --cached',
 102                 APPLY => sub { apply_patch 'apply -R --cached', @_; },
 103                 APPLY_CHECK => 'apply -R --cached',
 104                 VERB => 'Unstage',
 105                 TARGET => '',
 106                 PARTICIPLE => 'unstaging',
 107                 FILTER => 'index-only',
 108         },
 109         'reset_nothead' => {
 110                 DIFF => 'diff-index -R -p --cached',
 111                 APPLY => sub { apply_patch 'apply --cached', @_; },
 112                 APPLY_CHECK => 'apply --cached',
 113                 VERB => 'Apply',
 114                 TARGET => ' to index',
 115                 PARTICIPLE => 'applying',
 116                 FILTER => 'index-only',
 117         },
 118         'checkout_index' => {
 119                 DIFF => 'diff-files -p',
 120                 APPLY => sub { apply_patch 'apply -R', @_; },
 121                 APPLY_CHECK => 'apply -R',
 122                 VERB => 'Discard',
 123                 TARGET => ' from worktree',
 124                 PARTICIPLE => 'discarding',
 125                 FILTER => 'file-only',
 126         },
 127         'checkout_head' => {
 128                 DIFF => 'diff-index -p',
 129                 APPLY => sub { apply_patch_for_checkout_commit '-R', @_ },
 130                 APPLY_CHECK => 'apply -R',
 131                 VERB => 'Discard',
 132                 TARGET => ' from index and worktree',
 133                 PARTICIPLE => 'discarding',
 134                 FILTER => undef,
 135         },
 136         'checkout_nothead' => {
 137                 DIFF => 'diff-index -R -p',
 138                 APPLY => sub { apply_patch_for_checkout_commit '', @_ },
 139                 APPLY_CHECK => 'apply',
 140                 VERB => 'Apply',
 141                 TARGET => ' to index and worktree',
 142                 PARTICIPLE => 'applying',
 143                 FILTER => undef,
 144         },
 145 );
 146
 147 my %patch_mode_flavour = %{$patch_modes{stage}};
 148
 149 sub run_cmd_pipe {
 150         if ($^O eq 'MSWin32' || $^O eq 'msys') {
 151                 my @invalid = grep {m/[":*]/} @_;
 152                 die "$^O does not support: @invalid\n" if @invalid;
 153                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
 154                 return qx{@args};
 155         } else {
 156                 my $fh = undef;
 157                 open($fh, '-|', @_) or die;
 158                 return <$fh>;
 159         }
 160 }
 161
 162 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
 163
 164 if (!defined $GIT_DIR) {
 165         exit(1); # rev-parse would have already said "not a git repo"
 166 }
 167 chomp($GIT_DIR);
 168
 169 my %cquote_map = (
 170  "b" => chr(8),
 171  "t" => chr(9),
 172  "n" => chr(10),
 173  "v" => chr(11),
 174  "f" => chr(12),
 175  "r" => chr(13),
 176  "\\" => "\\",
 177  "\042" => "\042",
 178 );
 179
 180 sub unquote_path {
 181         local ($_) = @_;
 182         my ($retval, $remainder);
 183         if (!/^\042(.*)\042$/) {
 184                 return $_;
 185         }
 186         ($_, $retval) = ($1, "");
 187         while (/^([^\\]*)\\(.*)$/) {
 188                 $remainder = $2;
 189                 $retval .= $1;
 190                 for ($remainder) {
 191                         if (/^([0-3][0-7][0-7])(.*)$/) {
 192                                 $retval .= chr(oct($1));
 193                                 $_ = $2;
 194                                 last;
 195                         }
 196                         if (/^([\\\042btnvfr])(.*)$/) {
 197                                 $retval .= $cquote_map{$1};
 198                                 $_ = $2;
 199                                 last;
 200                         }
 201                         # This is malformed -- just return it as-is for now.
 202                         return $_[0];
 203                 }
 204                 $_ = $remainder;
 205         }
 206         $retval .= $_;
 207         return $retval;
 208 }
 209
 210 sub refresh {
 211         my $fh;
 212         open $fh, 'git update-index --refresh |'
 213             or die;
 214         while (<$fh>) {
 215                 ;# ignore 'needs update'
 216         }
 217         close $fh;
 218 }
 219
 220 sub list_untracked {
 221         map {
 222                 chomp $_;
 223                 unquote_path($_);
 224         }
 225         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 226 }
 227
 228 my $status_fmt = '%12s %12s %s';
 229 my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
 230
 231 {
 232         my $initial;
 233         sub is_initial_commit {
 234                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 235                         unless defined $initial;
 236                 return $initial;
 237         }
 238 }
 239
 240 sub get_empty_tree {
 241         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 242 }
 243
 244 # Returns list of hashes, contents of each of which are:
 245 # VALUE:        pathname
 246 # BINARY:       is a binary path
 247 # INDEX:        is index different from HEAD?
 248 # FILE:         is file different from index?
 249 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 250 # FILE_ADDDEL:  is it add/delete between index and file?
 251
 252 sub list_modified {
 253         my ($only) = @_;
 254         my (%data, @return);
 255         my ($add, $del, $adddel, $file);
 256         my @tracked = ();
 257
 258         if (@ARGV) {
 259                 @tracked = map {
 260                         chomp $_;
 261                         unquote_path($_);
 262                 } run_cmd_pipe(qw(git ls-files --exclude-standard --), @ARGV);
 263                 return if (!@tracked);
 264         }
 265
 266         my $reference;
 267         if (defined $patch_mode_revision and $patch_mode_revision ne 'HEAD') {
 268                 $reference = $patch_mode_revision;
 269         } elsif (is_initial_commit()) {
 270                 $reference = get_empty_tree();
 271         } else {
 272                 $reference = 'HEAD';
 273         }
 274         for (run_cmd_pipe(qw(git diff-index --cached
 275                              --numstat --summary), $reference,
 276                              '--', @tracked)) {
 277                 if (($add, $del, $file) =
 278                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 279                         my ($change, $bin);
 280                         $file = unquote_path($file);
 281                         if ($add eq '-' && $del eq '-') {
 282                                 $change = 'binary';
 283                                 $bin = 1;
 284                         }
 285                         else {
 286                                 $change = "+$add/-$del";
 287                         }
 288                         $data{$file} = {
 289                                 INDEX => $change,
 290                                 BINARY => $bin,
 291                                 FILE => 'nothing',
 292                         }
 293                 }
 294                 elsif (($adddel, $file) =
 295                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 296                         $file = unquote_path($file);
 297                         $data{$file}{INDEX_ADDDEL} = $adddel;
 298                 }
 299         }
 300
 301         for (run_cmd_pipe(qw(git diff-files --numstat --summary --), @tracked)) {
 302                 if (($add, $del, $file) =
 303                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 304                         $file = unquote_path($file);
 305                         if (!exists $data{$file}) {
 306                                 $data{$file} = +{
 307                                         INDEX => 'unchanged',
 308                                         BINARY => 0,
 309                                 };
 310                         }
 311                         my ($change, $bin);
 312                         if ($add eq '-' && $del eq '-') {
 313                                 $change = 'binary';
 314                                 $bin = 1;
 315                         }
 316                         else {
 317                                 $change = "+$add/-$del";
 318                         }
 319                         $data{$file}{FILE} = $change;
 320                         if ($bin) {
 321                                 $data{$file}{BINARY} = 1;
 322                         }
 323                 }
 324                 elsif (($adddel, $file) =
 325                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 326                         $file = unquote_path($file);
 327                         $data{$file}{FILE_ADDDEL} = $adddel;
 328                 }
 329         }
 330
 331         for (sort keys %data) {
 332                 my $it = $data{$_};
 333
 334                 if ($only) {
 335                         if ($only eq 'index-only') {
 336                                 next if ($it->{INDEX} eq 'unchanged');
 337                         }
 338                         if ($only eq 'file-only') {
 339                                 next if ($it->{FILE} eq 'nothing');
 340                         }
 341                 }
 342                 push @return, +{
 343                         VALUE => $_,
 344                         %$it,
 345                 };
 346         }
 347         return @return;
 348 }
 349
 350 sub find_unique {
 351         my ($string, @stuff) = @_;
 352         my $found = undef;
 353         for (my $i = 0; $i < @stuff; $i++) {
 354                 my $it = $stuff[$i];
 355                 my $hit = undef;
 356                 if (ref $it) {
 357                         if ((ref $it) eq 'ARRAY') {
 358                                 $it = $it->[0];
 359                         }
 360                         else {
 361                                 $it = $it->{VALUE};
 362                         }
 363                 }
 364                 eval {
 365                         if ($it =~ /^$string/) {
 366                                 $hit = 1;
 367                         };
 368                 };
 369                 if (defined $hit && defined $found) {
 370                         return undef;
 371                 }
 372                 if ($hit) {
 373                         $found = $i + 1;
 374                 }
 375         }
 376         return $found;
 377 }
 378
 379 # inserts string into trie and updates count for each character
 380 sub update_trie {
 381         my ($trie, $string) = @_;
 382         foreach (split //, $string) {
 383                 $trie = $trie->{$_} ||= {COUNT => 0};
 384                 $trie->{COUNT}++;
 385         }
 386 }
 387
 388 # returns an array of tuples (prefix, remainder)
 389 sub find_unique_prefixes {
 390         my @stuff = @_;
 391         my @return = ();
 392
 393         # any single prefix exceeding the soft limit is omitted
 394         # if any prefix exceeds the hard limit all are omitted
 395         # 0 indicates no limit
 396         my $soft_limit = 0;
 397         my $hard_limit = 3;
 398
 399         # build a trie modelling all possible options
 400         my %trie;
 401         foreach my $print (@stuff) {
 402                 if ((ref $print) eq 'ARRAY') {
 403                         $print = $print->[0];
 404                 }
 405                 elsif ((ref $print) eq 'HASH') {
 406                         $print = $print->{VALUE};
 407                 }
 408                 update_trie(\%trie, $print);
 409                 push @return, $print;
 410         }
 411
 412         # use the trie to find the unique prefixes
 413         for (my $i = 0; $i < @return; $i++) {
 414                 my $ret = $return[$i];
 415                 my @letters = split //, $ret;
 416                 my %search = %trie;
 417                 my ($prefix, $remainder);
 418                 my $j;
 419                 for ($j = 0; $j < @letters; $j++) {
 420                         my $letter = $letters[$j];
 421                         if ($search{$letter}{COUNT} == 1) {
 422                                 $prefix = substr $ret, 0, $j + 1;
 423                                 $remainder = substr $ret, $j + 1;
 424                                 last;
 425                         }
 426                         else {
 427                                 my $prefix = substr $ret, 0, $j;
 428                                 return ()
 429                                     if ($hard_limit && $j + 1 > $hard_limit);
 430                         }
 431                         %search = %{$search{$letter}};
 432                 }
 433                 if (ord($letters[0]) > 127 ||
 434                     ($soft_limit && $j + 1 > $soft_limit)) {
 435                         $prefix = undef;
 436                         $remainder = $ret;
 437                 }
 438                 $return[$i] = [$prefix, $remainder];
 439         }
 440         return @return;
 441 }
 442
 443 # filters out prefixes which have special meaning to list_and_choose()
 444 sub is_valid_prefix {
 445         my $prefix = shift;
 446         return (defined $prefix) &&
 447             !($prefix =~ /[\s,]/) && # separators
 448             !($prefix =~ /^-/) &&    # deselection
 449             !($prefix =~ /^\d+/) &&  # selection
 450             ($prefix ne '*') &&      # "all" wildcard
 451             ($prefix ne '?');        # prompt help
 452 }
 453
 454 # given a prefix/remainder tuple return a string with the prefix highlighted
 455 # for now use square brackets; later might use ANSI colors (underline, bold)
 456 sub highlight_prefix {
 457         my $prefix = shift;
 458         my $remainder = shift;
 459
 460         if (!defined $prefix) {
 461                 return $remainder;
 462         }
 463
 464         if (!is_valid_prefix($prefix)) {
 465                 return "$prefix$remainder";
 466         }
 467
 468         if (!$menu_use_color) {
 469                 return "[$prefix]$remainder";
 470         }
 471
 472         return "$prompt_color$prefix$normal_color$remainder";
 473 }
 474
 475 sub error_msg {
 476         print STDERR colored $error_color, @_;
 477 }
 478
 479 sub list_and_choose {
 480         my ($opts, @stuff) = @_;
 481         my (@chosen, @return);
 482         my $i;
 483         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 484
 485       TOPLOOP:
 486         while (1) {
 487                 my $last_lf = 0;
 488
 489                 if ($opts->{HEADER}) {
 490                         if (!$opts->{LIST_FLAT}) {
 491                                 print "     ";
 492                         }
 493                         print colored $header_color, "$opts->{HEADER}\n";
 494                 }
 495                 for ($i = 0; $i < @stuff; $i++) {
 496                         my $chosen = $chosen[$i] ? '*' : ' ';
 497                         my $print = $stuff[$i];
 498                         my $ref = ref $print;
 499                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 500                             if @prefixes;
 501                         if ($ref eq 'ARRAY') {
 502                                 $print = $highlighted || $print->[0];
 503                         }
 504                         elsif ($ref eq 'HASH') {
 505                                 my $value = $highlighted || $print->{VALUE};
 506                                 $print = sprintf($status_fmt,
 507                                     $print->{INDEX},
 508                                     $print->{FILE},
 509                                     $value);
 510                         }
 511                         else {
 512                                 $print = $highlighted || $print;
 513                         }
 514                         printf("%s%2d: %s", $chosen, $i+1, $print);
 515                         if (($opts->{LIST_FLAT}) &&
 516                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 517                                 print "\t";
 518                                 $last_lf = 0;
 519                         }
 520                         else {
 521                                 print "\n";
 522                                 $last_lf = 1;
 523                         }
 524                 }
 525                 if (!$last_lf) {
 526                         print "\n";
 527                 }
 528
 529                 return if ($opts->{LIST_ONLY});
 530
 531                 print colored $prompt_color, $opts->{PROMPT};
 532                 if ($opts->{SINGLETON}) {
 533                         print "> ";
 534                 }
 535                 else {
 536                         print ">> ";
 537                 }
 538                 my $line = <STDIN>;
 539                 if (!$line) {
 540                         print "\n";
 541                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 542                         last;
 543                 }
 544                 chomp $line;
 545                 last if $line eq '';
 546                 if ($line eq '?') {
 547                         $opts->{SINGLETON} ?
 548                             singleton_prompt_help_cmd() :
 549                             prompt_help_cmd();
 550                         next TOPLOOP;
 551                 }
 552                 for my $choice (split(/[\s,]+/, $line)) {
 553                         my $choose = 1;
 554                         my ($bottom, $top);
 555
 556                         # Input that begins with '-'; unchoose
 557                         if ($choice =~ s/^-//) {
 558                                 $choose = 0;
 559                         }
 560                         # A range can be specified like 5-7 or 5-.
 561                         if ($choice =~ /^(\d+)-(\d*)$/) {
 562                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 563                         }
 564                         elsif ($choice =~ /^\d+$/) {
 565                                 $bottom = $top = $choice;
 566                         }
 567                         elsif ($choice eq '*') {
 568                                 $bottom = 1;
 569                                 $top = 1 + @stuff;
 570                         }
 571                         else {
 572                                 $bottom = $top = find_unique($choice, @stuff);
 573                                 if (!defined $bottom) {
 574                                         error_msg "Huh ($choice)?\n";
 575                                         next TOPLOOP;
 576                                 }
 577                         }
 578                         if ($opts->{SINGLETON} && $bottom != $top) {
 579                                 error_msg "Huh ($choice)?\n";
 580                                 next TOPLOOP;
 581                         }
 582                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 583                                 next if (@stuff <= $i || $i < 0);
 584                                 $chosen[$i] = $choose;
 585                         }
 586                 }
 587                 last if ($opts->{IMMEDIATE} || $line eq '*');
 588         }
 589         for ($i = 0; $i < @stuff; $i++) {
 590                 if ($chosen[$i]) {
 591                         push @return, $stuff[$i];
 592                 }
 593         }
 594         return @return;
 595 }
 596
 597 sub singleton_prompt_help_cmd {
 598         print colored $help_color, <<\EOF ;
 599 Prompt help:
 600 1          - select a numbered item
 601 foo        - select item based on unique prefix
 602            - (empty) select nothing
 603 EOF
 604 }
 605
 606 sub prompt_help_cmd {
 607         print colored $help_color, <<\EOF ;
 608 Prompt help:
 609 1          - select a single item
 610 3-5        - select a range of items
 611 2-3,6-9    - select multiple ranges
 612 foo        - select item based on unique prefix
 613 -...       - unselect specified items
 614 *          - choose all items
 615            - (empty) finish selecting
 616 EOF
 617 }
 618
 619 sub status_cmd {
 620         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 621                         list_modified());
 622         print "\n";
 623 }
 624
 625 sub say_n_paths {
 626         my $did = shift @_;
 627         my $cnt = scalar @_;
 628         print "$did ";
 629         if (1 < $cnt) {
 630                 print "$cnt paths\n";
 631         }
 632         else {
 633                 print "one path\n";
 634         }
 635 }
 636
 637 sub update_cmd {
 638         my @mods = list_modified('file-only');
 639         return if (!@mods);
 640
 641         my @update = list_and_choose({ PROMPT => 'Update',
 642                                        HEADER => $status_head, },
 643                                      @mods);
 644         if (@update) {
 645                 system(qw(git update-index --add --remove --),
 646                        map { $_->{VALUE} } @update);
 647                 say_n_paths('updated', @update);
 648         }
 649         print "\n";
 650 }
 651
 652 sub revert_cmd {
 653         my @update = list_and_choose({ PROMPT => 'Revert',
 654                                        HEADER => $status_head, },
 655                                      list_modified());
 656         if (@update) {
 657                 if (is_initial_commit()) {
 658                         system(qw(git rm --cached),
 659                                 map { $_->{VALUE} } @update);
 660                 }
 661                 else {
 662                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 663                                                  map { $_->{VALUE} } @update);
 664                         my $fh;
 665                         open $fh, '| git update-index --index-info'
 666                             or die;
 667                         for (@lines) {
 668                                 print $fh $_;
 669                         }
 670                         close($fh);
 671                         for (@update) {
 672                                 if ($_->{INDEX_ADDDEL} &&
 673                                     $_->{INDEX_ADDDEL} eq 'create') {
 674                                         system(qw(git update-index --force-remove --),
 675                                                $_->{VALUE});
 676                                         print "note: $_->{VALUE} is untracked now.\n";
 677                                 }
 678                         }
 679                 }
 680                 refresh();
 681                 say_n_paths('reverted', @update);
 682         }
 683         print "\n";
 684 }
 685
 686 sub add_untracked_cmd {
 687         my @add = list_and_choose({ PROMPT => 'Add untracked' },
 688                                   list_untracked());
 689         if (@add) {
 690                 system(qw(git update-index --add --), @add);
 691                 say_n_paths('added', @add);
 692         }
 693         print "\n";
 694 }
 695
 696 sub run_git_apply {
 697         my $cmd = shift;
 698         my $fh;
 699         open $fh, '| git ' . $cmd;
 700         print $fh @_;
 701         return close $fh;
 702 }
 703
 704 sub parse_diff {
 705         my ($path) = @_;
 706         my @diff_cmd = split(" ", $patch_mode_flavour{DIFF});
 707         if (defined $patch_mode_revision) {
 708                 push @diff_cmd, $patch_mode_revision;
 709         }
 710         my @diff = run_cmd_pipe("git", @diff_cmd, "--", $path);
 711         my @colored = ();
 712         if ($diff_use_color) {
 713                 @colored = run_cmd_pipe("git", @diff_cmd, qw(--color --), $path);
 714         }
 715         my (@hunk) = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 716
 717         for (my $i = 0; $i < @diff; $i++) {
 718                 if ($diff[$i] =~ /^@@ /) {
 719                         push @hunk, { TEXT => [], DISPLAY => [],
 720                                 TYPE => 'hunk' };
 721                 }
 722                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 723                 push @{$hunk[-1]{DISPLAY}},
 724                         ($diff_use_color ? $colored[$i] : $diff[$i]);
 725         }
 726         return @hunk;
 727 }
 728
 729 sub parse_diff_header {
 730         my $src = shift;
 731
 732         my $head = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 733         my $mode = { TEXT => [], DISPLAY => [], TYPE => 'mode' };
 734
 735         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 736                 my $dest = $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ?
 737                         $mode : $head;
 738                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 739                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 740         }
 741         return ($head, $mode);
 742 }
 743
 744 sub hunk_splittable {
 745         my ($text) = @_;
 746
 747         my @s = split_hunk($text);
 748         return (1 < @s);
 749 }
 750
 751 sub parse_hunk_header {
 752         my ($line) = @_;
 753         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 754             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
 755         $o_cnt = 1 unless defined $o_cnt;
 756         $n_cnt = 1 unless defined $n_cnt;
 757         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 758 }
 759
 760 sub split_hunk {
 761         my ($text, $display) = @_;
 762         my @split = ();
 763         if (!defined $display) {
 764                 $display = $text;
 765         }
 766         # If there are context lines in the middle of a hunk,
 767         # it can be split, but we would need to take care of
 768         # overlaps later.
 769
 770         my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
 771         my $hunk_start = 1;
 772
 773       OUTER:
 774         while (1) {
 775                 my $next_hunk_start = undef;
 776                 my $i = $hunk_start - 1;
 777                 my $this = +{
 778                         TEXT => [],
 779                         DISPLAY => [],
 780                         TYPE => 'hunk',
 781                         OLD => $o_ofs,
 782                         NEW => $n_ofs,
 783                         OCNT => 0,
 784                         NCNT => 0,
 785                         ADDDEL => 0,
 786                         POSTCTX => 0,
 787                         USE => undef,
 788                 };
 789
 790                 while (++$i < @$text) {
 791                         my $line = $text->[$i];
 792                         my $display = $display->[$i];
 793                         if ($line =~ /^ /) {
 794                                 if ($this->{ADDDEL} &&
 795                                     !defined $next_hunk_start) {
 796                                         # We have seen leading context and
 797                                         # adds/dels and then here is another
 798                                         # context, which is trailing for this
 799                                         # split hunk and leading for the next
 800                                         # one.
 801                                         $next_hunk_start = $i;
 802                                 }
 803                                 push @{$this->{TEXT}}, $line;
 804                                 push @{$this->{DISPLAY}}, $display;
 805                                 $this->{OCNT}++;
 806                                 $this->{NCNT}++;
 807                                 if (defined $next_hunk_start) {
 808                                         $this->{POSTCTX}++;
 809                                 }
 810                                 next;
 811                         }
 812
 813                         # add/del
 814                         if (defined $next_hunk_start) {
 815                                 # We are done with the current hunk and
 816                                 # this is the first real change for the
 817                                 # next split one.
 818                                 $hunk_start = $next_hunk_start;
 819                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 820                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 821                                 $o_ofs -= $this->{POSTCTX};
 822                                 $n_ofs -= $this->{POSTCTX};
 823                                 push @split, $this;
 824                                 redo OUTER;
 825                         }
 826                         push @{$this->{TEXT}}, $line;
 827                         push @{$this->{DISPLAY}}, $display;
 828                         $this->{ADDDEL}++;
 829                         if ($line =~ /^-/) {
 830                                 $this->{OCNT}++;
 831                         }
 832                         else {
 833                                 $this->{NCNT}++;
 834                         }
 835                 }
 836
 837                 push @split, $this;
 838                 last;
 839         }
 840
 841         for my $hunk (@split) {
 842                 $o_ofs = $hunk->{OLD};
 843                 $n_ofs = $hunk->{NEW};
 844                 my $o_cnt = $hunk->{OCNT};
 845                 my $n_cnt = $hunk->{NCNT};
 846
 847                 my $head = ("@@ -$o_ofs" .
 848                             (($o_cnt != 1) ? ",$o_cnt" : '') .
 849                             " +$n_ofs" .
 850                             (($n_cnt != 1) ? ",$n_cnt" : '') .
 851                             " @@\n");
 852                 my $display_head = $head;
 853                 unshift @{$hunk->{TEXT}}, $head;
 854                 if ($diff_use_color) {
 855                         $display_head = colored($fraginfo_color, $head);
 856                 }
 857                 unshift @{$hunk->{DISPLAY}}, $display_head;
 858         }
 859         return @split;
 860 }
 861
 862 sub find_last_o_ctx {
 863         my ($it) = @_;
 864         my $text = $it->{TEXT};
 865         my ($o_ofs, $o_cnt) = parse_hunk_header($text->[0]);
 866         my $i = @{$text};
 867         my $last_o_ctx = $o_ofs + $o_cnt;
 868         while (0 < --$i) {
 869                 my $line = $text->[$i];
 870                 if ($line =~ /^ /) {
 871                         $last_o_ctx--;
 872                         next;
 873                 }
 874                 last;
 875         }
 876         return $last_o_ctx;
 877 }
 878
 879 sub merge_hunk {
 880         my ($prev, $this) = @_;
 881         my ($o0_ofs, $o0_cnt, $n0_ofs, $n0_cnt) =
 882             parse_hunk_header($prev->{TEXT}[0]);
 883         my ($o1_ofs, $o1_cnt, $n1_ofs, $n1_cnt) =
 884             parse_hunk_header($this->{TEXT}[0]);
 885
 886         my (@line, $i, $ofs, $o_cnt, $n_cnt);
 887         $ofs = $o0_ofs;
 888         $o_cnt = $n_cnt = 0;
 889         for ($i = 1; $i < @{$prev->{TEXT}}; $i++) {
 890                 my $line = $prev->{TEXT}[$i];
 891                 if ($line =~ /^\+/) {
 892                         $n_cnt++;
 893                         push @line, $line;
 894                         next;
 895                 }
 896
 897                 last if ($o1_ofs <= $ofs);
 898
 899                 $o_cnt++;
 900                 $ofs++;
 901                 if ($line =~ /^ /) {
 902                         $n_cnt++;
 903                 }
 904                 push @line, $line;
 905         }
 906
 907         for ($i = 1; $i < @{$this->{TEXT}}; $i++) {
 908                 my $line = $this->{TEXT}[$i];
 909                 if ($line =~ /^\+/) {
 910                         $n_cnt++;
 911                         push @line, $line;
 912                         next;
 913                 }
 914                 $ofs++;
 915                 $o_cnt++;
 916                 if ($line =~ /^ /) {
 917                         $n_cnt++;
 918                 }
 919                 push @line, $line;
 920         }
 921         my $head = ("@@ -$o0_ofs" .
 922                     (($o_cnt != 1) ? ",$o_cnt" : '') .
 923                     " +$n0_ofs" .
 924                     (($n_cnt != 1) ? ",$n_cnt" : '') .
 925                     " @@\n");
 926         @{$prev->{TEXT}} = ($head, @line);
 927 }
 928
 929 sub coalesce_overlapping_hunks {
 930         my (@in) = @_;
 931         my @out = ();
 932
 933         my ($last_o_ctx, $last_was_dirty);
 934
 935         for (grep { $_->{USE} } @in) {
 936                 my $text = $_->{TEXT};
 937                 my ($o_ofs) = parse_hunk_header($text->[0]);
 938                 if (defined $last_o_ctx &&
 939                     $o_ofs <= $last_o_ctx &&
 940                     !$_->{DIRTY} &&
 941                     !$last_was_dirty) {
 942                         merge_hunk($out[-1], $_);
 943                 }
 944                 else {
 945                         push @out, $_;
 946                 }
 947                 $last_o_ctx = find_last_o_ctx($out[-1]);
 948                 $last_was_dirty = $_->{DIRTY};
 949         }
 950         return @out;
 951 }
 952
 953 sub color_diff {
 954         return map {
 955                 colored((/^@/  ? $fraginfo_color :
 956                          /^\+/ ? $diff_new_color :
 957                          /^-/  ? $diff_old_color :
 958                          $diff_plain_color),
 959                         $_);
 960         } @_;
 961 }
 962
 963 sub edit_hunk_manually {
 964         my ($oldtext) = @_;
 965
 966         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
 967         my $fh;
 968         open $fh, '>', $hunkfile
 969                 or die "failed to open hunk edit file for writing: " . $!;
 970         print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
 971         print $fh @$oldtext;
 972         my $participle = $patch_mode_flavour{PARTICIPLE};
 973         print $fh <<EOF;
 974 # ---
 975 # To remove '-' lines, make them ' ' lines (context).
 976 # To remove '+' lines, delete them.
 977 # Lines starting with # will be removed.
 978 #
 979 # If the patch applies cleanly, the edited hunk will immediately be
 980 # marked for $participle. If it does not apply cleanly, you will be given
 981 # an opportunity to edit again. If all lines of the hunk are removed,
 982 # then the edit is aborted and the hunk is left unchanged.
 983 EOF
 984         close $fh;
 985
 986         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor")
 987                 || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 988         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
 989
 990         if ($? != 0) {
 991                 return undef;
 992         }
 993
 994         open $fh, '<', $hunkfile
 995                 or die "failed to open hunk edit file for reading: " . $!;
 996         my @newtext = grep { !/^#/ } <$fh>;
 997         close $fh;
 998         unlink $hunkfile;
 999
1000         # Abort if nothing remains
1001         if (!grep { /\S/ } @newtext) {
1002                 return undef;
1003         }
1004
1005         # Reinsert the first hunk header if the user accidentally deleted it
1006         if ($newtext[0] !~ /^@/) {
1007                 unshift @newtext, $oldtext->[0];
1008         }
1009         return \@newtext;
1010 }
1011
1012 sub diff_applies {
1013         my $fh;
1014         return run_git_apply($patch_mode_flavour{APPLY_CHECK} . ' --recount --check',
1015                              map { @{$_->{TEXT}} } @_);
1016 }
1017
1018 sub _restore_terminal_and_die {
1019         ReadMode 'restore';
1020         print "\n";
1021         exit 1;
1022 }
1023
1024 sub prompt_single_character {
1025         if ($use_readkey) {
1026                 local $SIG{TERM} = \&_restore_terminal_and_die;
1027                 local $SIG{INT} = \&_restore_terminal_and_die;
1028                 ReadMode 'cbreak';
1029                 my $key = ReadKey 0;
1030                 ReadMode 'restore';
1031                 print "$key" if defined $key;
1032                 print "\n";
1033                 return $key;
1034         } else {
1035                 return <STDIN>;
1036         }
1037 }
1038
1039 sub prompt_yesno {
1040         my ($prompt) = @_;
1041         while (1) {
1042                 print colored $prompt_color, $prompt;
1043                 my $line = prompt_single_character;
1044                 return 0 if $line =~ /^n/i;
1045                 return 1 if $line =~ /^y/i;
1046         }
1047 }
1048
1049 sub edit_hunk_loop {
1050         my ($head, $hunk, $ix) = @_;
1051         my $text = $hunk->[$ix]->{TEXT};
1052
1053         while (1) {
1054                 $text = edit_hunk_manually($text);
1055                 if (!defined $text) {
1056                         return undef;
1057                 }
1058                 my $newhunk = {
1059                         TEXT => $text,
1060                         TYPE => $hunk->[$ix]->{TYPE},
1061                         USE => 1,
1062                         DIRTY => 1,
1063                 };
1064                 if (diff_applies($head,
1065                                  @{$hunk}[0..$ix-1],
1066                                  $newhunk,
1067                                  @{$hunk}[$ix+1..$#{$hunk}])) {
1068                         $newhunk->{DISPLAY} = [color_diff(@{$text})];
1069                         return $newhunk;
1070                 }
1071                 else {
1072                         prompt_yesno(
1073                                 'Your edited hunk does not apply. Edit again '
1074                                 . '(saying "no" discards!) [y/n]? '
1075                                 ) or return undef;
1076                 }
1077         }
1078 }
1079
1080 sub help_patch_cmd {
1081         my $verb = lc $patch_mode_flavour{VERB};
1082         my $target = $patch_mode_flavour{TARGET};
1083         print colored $help_color, <<EOF ;
1084 y - $verb this hunk$target
1085 n - do not $verb this hunk$target
1086 q - quit, do not $verb this hunk nor any of the remaining ones
1087 a - $verb this and all the remaining hunks in the file
1088 d - do not $verb this hunk nor any of the remaining hunks in the file
1089 g - select a hunk to go to
1090 / - search for a hunk matching the given regex
1091 j - leave this hunk undecided, see next undecided hunk
1092 J - leave this hunk undecided, see next hunk
1093 k - leave this hunk undecided, see previous undecided hunk
1094 K - leave this hunk undecided, see previous hunk
1095 s - split the current hunk into smaller hunks
1096 e - manually edit the current hunk
1097 ? - print help
1098 EOF
1099 }
1100
1101 sub apply_patch {
1102         my $cmd = shift;
1103         my $ret = run_git_apply $cmd . ' --recount', @_;
1104         if (!$ret) {
1105                 print STDERR @_;
1106         }
1107         return $ret;
1108 }
1109
1110 sub apply_patch_for_checkout_commit {
1111         my $reverse = shift;
1112         my $applies_index = run_git_apply 'apply '.$reverse.' --cached --recount --check', @_;
1113         my $applies_worktree = run_git_apply 'apply '.$reverse.' --recount --check', @_;
1114
1115         if ($applies_worktree && $applies_index) {
1116                 run_git_apply 'apply '.$reverse.' --cached --recount', @_;
1117                 run_git_apply 'apply '.$reverse.' --recount', @_;
1118                 return 1;
1119         } elsif (!$applies_index) {
1120                 print colored $error_color, "The selected hunks do not apply to the index!\n";
1121                 if (prompt_yesno "Apply them to the worktree anyway? ") {
1122                         return run_git_apply 'apply '.$reverse.' --recount', @_;
1123                 } else {
1124                         print colored $error_color, "Nothing was applied.\n";
1125                         return 0;
1126                 }
1127         } else {
1128                 print STDERR @_;
1129                 return 0;
1130         }
1131 }
1132
1133 sub patch_update_cmd {
1134         my @all_mods = list_modified($patch_mode_flavour{FILTER});
1135         my @mods = grep { !($_->{BINARY}) } @all_mods;
1136         my @them;
1137
1138         if (!@mods) {
1139                 if (@all_mods) {
1140                         print STDERR "Only binary files changed.\n";
1141                 } else {
1142                         print STDERR "No changes.\n";
1143                 }
1144                 return 0;
1145         }
1146         if ($patch_mode) {
1147                 @them = @mods;
1148         }
1149         else {
1150                 @them = list_and_choose({ PROMPT => 'Patch update',
1151                                           HEADER => $status_head, },
1152                                         @mods);
1153         }
1154         for (@them) {
1155                 return 0 if patch_update_file($_->{VALUE});
1156         }
1157 }
1158
1159 # Generate a one line summary of a hunk.
1160 sub summarize_hunk {
1161         my $rhunk = shift;
1162         my $summary = $rhunk->{TEXT}[0];
1163
1164         # Keep the line numbers, discard extra context.
1165         $summary =~ s/@@(.*?)@@.*/$1 /s;
1166         $summary .= " " x (20 - length $summary);
1167
1168         # Add some user context.
1169         for my $line (@{$rhunk->{TEXT}}) {
1170                 if ($line =~ m/^[+-].*\w/) {
1171                         $summary .= $line;
1172                         last;
1173                 }
1174         }
1175
1176         chomp $summary;
1177         return substr($summary, 0, 80) . "\n";
1178 }
1179
1180
1181 # Print a one-line summary of each hunk in the array ref in
1182 # the first argument, starting wih the index in the 2nd.
1183 sub display_hunks {
1184         my ($hunks, $i) = @_;
1185         my $ctr = 0;
1186         $i ||= 0;
1187         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
1188                 my $status = " ";
1189                 if (defined $hunks->[$i]{USE}) {
1190                         $status = $hunks->[$i]{USE} ? "+" : "-";
1191                 }
1192                 printf "%s%2d: %s",
1193                         $status,
1194                         $i + 1,
1195                         summarize_hunk($hunks->[$i]);
1196         }
1197         return $i;
1198 }
1199
1200 sub patch_update_file {
1201         my $quit = 0;
1202         my ($ix, $num);
1203         my $path = shift;
1204         my ($head, @hunk) = parse_diff($path);
1205         ($head, my $mode) = parse_diff_header($head);
1206         for (@{$head->{DISPLAY}}) {
1207                 print;
1208         }
1209
1210         if (@{$mode->{TEXT}}) {
1211                 unshift @hunk, $mode;
1212         }
1213
1214         $num = scalar @hunk;
1215         $ix = 0;
1216
1217         while (1) {
1218                 my ($prev, $next, $other, $undecided, $i);
1219                 $other = '';
1220
1221                 if ($num <= $ix) {
1222                         $ix = 0;
1223                 }
1224                 for ($i = 0; $i < $ix; $i++) {
1225                         if (!defined $hunk[$i]{USE}) {
1226                                 $prev = 1;
1227                                 $other .= ',k';
1228                                 last;
1229                         }
1230                 }
1231                 if ($ix) {
1232                         $other .= ',K';
1233                 }
1234                 for ($i = $ix + 1; $i < $num; $i++) {
1235                         if (!defined $hunk[$i]{USE}) {
1236                                 $next = 1;
1237                                 $other .= ',j';
1238                                 last;
1239                         }
1240                 }
1241                 if ($ix < $num - 1) {
1242                         $other .= ',J';
1243                 }
1244                 if ($num > 1) {
1245                         $other .= ',g';
1246                 }
1247                 for ($i = 0; $i < $num; $i++) {
1248                         if (!defined $hunk[$i]{USE}) {
1249                                 $undecided = 1;
1250                                 last;
1251                         }
1252                 }
1253                 last if (!$undecided);
1254
1255                 if ($hunk[$ix]{TYPE} eq 'hunk' &&
1256                     hunk_splittable($hunk[$ix]{TEXT})) {
1257                         $other .= ',s';
1258                 }
1259                 if ($hunk[$ix]{TYPE} eq 'hunk') {
1260                         $other .= ',e';
1261                 }
1262                 for (@{$hunk[$ix]{DISPLAY}}) {
1263                         print;
1264                 }
1265                 print colored $prompt_color, $patch_mode_flavour{VERB},
1266                   ($hunk[$ix]{TYPE} eq 'mode' ? ' mode change' : ' this hunk'),
1267                   $patch_mode_flavour{TARGET},
1268                   " [y,n,q,a,d,/$other,?]? ";
1269                 my $line = prompt_single_character;
1270                 if ($line) {
1271                         if ($line =~ /^y/i) {
1272                                 $hunk[$ix]{USE} = 1;
1273                         }
1274                         elsif ($line =~ /^n/i) {
1275                                 $hunk[$ix]{USE} = 0;
1276                         }
1277                         elsif ($line =~ /^a/i) {
1278                                 while ($ix < $num) {
1279                                         if (!defined $hunk[$ix]{USE}) {
1280                                                 $hunk[$ix]{USE} = 1;
1281                                         }
1282                                         $ix++;
1283                                 }
1284                                 next;
1285                         }
1286                         elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1287                                 my $response = $1;
1288                                 my $no = $ix > 10 ? $ix - 10 : 0;
1289                                 while ($response eq '') {
1290                                         my $extra = "";
1291                                         $no = display_hunks(\@hunk, $no);
1292                                         if ($no < $num) {
1293                                                 $extra = " (<ret> to see more)";
1294                                         }
1295                                         print "go to which hunk$extra? ";
1296                                         $response = <STDIN>;
1297                                         if (!defined $response) {
1298                                                 $response = '';
1299                                         }
1300                                         chomp $response;
1301                                 }
1302                                 if ($response !~ /^\s*\d+\s*$/) {
1303                                         error_msg "Invalid number: '$response'\n";
1304                                 } elsif (0 < $response && $response <= $num) {
1305                                         $ix = $response - 1;
1306                                 } else {
1307                                         error_msg "Sorry, only $num hunks available.\n";
1308                                 }
1309                                 next;
1310                         }
1311                         elsif ($line =~ /^d/i) {
1312                                 while ($ix < $num) {
1313                                         if (!defined $hunk[$ix]{USE}) {
1314                                                 $hunk[$ix]{USE} = 0;
1315                                         }
1316                                         $ix++;
1317                                 }
1318                                 next;
1319                         }
1320                         elsif ($line =~ /^q/i) {
1321                                 while ($ix < $num) {
1322                                         if (!defined $hunk[$ix]{USE}) {
1323                                                 $hunk[$ix]{USE} = 0;
1324                                         }
1325                                         $ix++;
1326                                 }
1327                                 $quit = 1;
1328                                 next;
1329                         }
1330                         elsif ($line =~ m|^/(.*)|) {
1331                                 my $regex = $1;
1332                                 if ($1 eq "") {
1333                                         print colored $prompt_color, "search for regex? ";
1334                                         $regex = <STDIN>;
1335                                         if (defined $regex) {
1336                                                 chomp $regex;
1337                                         }
1338                                 }
1339                                 my $search_string;
1340                                 eval {
1341                                         $search_string = qr{$regex}m;
1342                                 };
1343                                 if ($@) {
1344                                         my ($err,$exp) = ($@, $1);
1345                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1346                                         error_msg "Malformed search regexp $exp: $err\n";
1347                                         next;
1348                                 }
1349                                 my $iy = $ix;
1350                                 while (1) {
1351                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1352                                         last if ($text =~ $search_string);
1353                                         $iy++;
1354                                         $iy = 0 if ($iy >= $num);
1355                                         if ($ix == $iy) {
1356                                                 error_msg "No hunk matches the given pattern\n";
1357                                                 last;
1358                                         }
1359                                 }
1360                                 $ix = $iy;
1361                                 next;
1362                         }
1363                         elsif ($line =~ /^K/) {
1364                                 if ($other =~ /K/) {
1365                                         $ix--;
1366                                 }
1367                                 else {
1368                                         error_msg "No previous hunk\n";
1369                                 }
1370                                 next;
1371                         }
1372                         elsif ($line =~ /^J/) {
1373                                 if ($other =~ /J/) {
1374                                         $ix++;
1375                                 }
1376                                 else {
1377                                         error_msg "No next hunk\n";
1378                                 }
1379                                 next;
1380                         }
1381                         elsif ($line =~ /^k/) {
1382                                 if ($other =~ /k/) {
1383                                         while (1) {
1384                                                 $ix--;
1385                                                 last if (!$ix ||
1386                                                          !defined $hunk[$ix]{USE});
1387                                         }
1388                                 }
1389                                 else {
1390                                         error_msg "No previous hunk\n";
1391                                 }
1392                                 next;
1393                         }
1394                         elsif ($line =~ /^j/) {
1395                                 if ($other !~ /j/) {
1396                                         error_msg "No next hunk\n";
1397                                         next;
1398                                 }
1399                         }
1400                         elsif ($other =~ /s/ && $line =~ /^s/) {
1401                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1402                                 if (1 < @split) {
1403                                         print colored $header_color, "Split into ",
1404                                         scalar(@split), " hunks.\n";
1405                                 }
1406                                 splice (@hunk, $ix, 1, @split);
1407                                 $num = scalar @hunk;
1408                                 next;
1409                         }
1410                         elsif ($other =~ /e/ && $line =~ /^e/) {
1411                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1412                                 if (defined $newhunk) {
1413                                         splice @hunk, $ix, 1, $newhunk;
1414                                 }
1415                         }
1416                         else {
1417                                 help_patch_cmd($other);
1418                                 next;
1419                         }
1420                         # soft increment
1421                         while (1) {
1422                                 $ix++;
1423                                 last if ($ix >= $num ||
1424                                          !defined $hunk[$ix]{USE});
1425                         }
1426                 }
1427         }
1428
1429         @hunk = coalesce_overlapping_hunks(@hunk);
1430
1431         my $n_lofs = 0;
1432         my @result = ();
1433         for (@hunk) {
1434                 if ($_->{USE}) {
1435                         push @result, @{$_->{TEXT}};
1436                 }
1437         }
1438
1439         if (@result) {
1440                 my $fh;
1441                 my @patch = (@{$head->{TEXT}}, @result);
1442                 my $apply_routine = $patch_mode_flavour{APPLY};
1443                 &$apply_routine(@patch);
1444                 refresh();
1445         }
1446
1447         print "\n";
1448         return $quit;
1449 }
1450
1451 sub diff_cmd {
1452         my @mods = list_modified('index-only');
1453         @mods = grep { !($_->{BINARY}) } @mods;
1454         return if (!@mods);
1455         my (@them) = list_and_choose({ PROMPT => 'Review diff',
1456                                      IMMEDIATE => 1,
1457                                      HEADER => $status_head, },
1458                                    @mods);
1459         return if (!@them);
1460         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1461         system(qw(git diff -p --cached), $reference, '--',
1462                 map { $_->{VALUE} } @them);
1463 }
1464
1465 sub quit_cmd {
1466         print "Bye.\n";
1467         exit(0);
1468 }
1469
1470 sub help_cmd {
1471         print colored $help_color, <<\EOF ;
1472 status        - show paths with changes
1473 update        - add working tree state to the staged set of changes
1474 revert        - revert staged set of changes back to the HEAD version
1475 patch         - pick hunks and update selectively
1476 diff          - view diff between HEAD and index
1477 add untracked - add contents of untracked files to the staged set of changes
1478 EOF
1479 }
1480
1481 sub process_args {
1482         return unless @ARGV;
1483         my $arg = shift @ARGV;
1484         if ($arg =~ /--patch(?:=(.*))?/) {
1485                 if (defined $1) {
1486                         if ($1 eq 'reset') {
1487                                 $patch_mode = 'reset_head';
1488                                 $patch_mode_revision = 'HEAD';
1489                                 $arg = shift @ARGV or die "missing --";
1490                                 if ($arg ne '--') {
1491                                         $patch_mode_revision = $arg;
1492                                         $patch_mode = ($arg eq 'HEAD' ?
1493                                                        'reset_head' : 'reset_nothead');
1494                                         $arg = shift @ARGV or die "missing --";
1495                                 }
1496                         } elsif ($1 eq 'checkout') {
1497                                 $arg = shift @ARGV or die "missing --";
1498                                 if ($arg eq '--') {
1499                                         $patch_mode = 'checkout_index';
1500                                 } else {
1501                                         $patch_mode_revision = $arg;
1502                                         $patch_mode = ($arg eq 'HEAD' ?
1503                                                        'checkout_head' : 'checkout_nothead');
1504                                         $arg = shift @ARGV or die "missing --";
1505                                 }
1506                         } elsif ($1 eq 'stage' or $1 eq 'stash') {
1507                                 $patch_mode = $1;
1508                                 $arg = shift @ARGV or die "missing --";
1509                         } else {
1510                                 die "unknown --patch mode: $1";
1511                         }
1512                 } else {
1513                         $patch_mode = 'stage';
1514                         $arg = shift @ARGV or die "missing --";
1515                 }
1516                 die "invalid argument $arg, expecting --"
1517                     unless $arg eq "--";
1518                 %patch_mode_flavour = %{$patch_modes{$patch_mode}};
1519         }
1520         elsif ($arg ne "--") {
1521                 die "invalid argument $arg, expecting --";
1522         }
1523 }
1524
1525 sub main_loop {
1526         my @cmd = ([ 'status', \&status_cmd, ],
1527                    [ 'update', \&update_cmd, ],
1528                    [ 'revert', \&revert_cmd, ],
1529                    [ 'add untracked', \&add_untracked_cmd, ],
1530                    [ 'patch', \&patch_update_cmd, ],
1531                    [ 'diff', \&diff_cmd, ],
1532                    [ 'quit', \&quit_cmd, ],
1533                    [ 'help', \&help_cmd, ],
1534         );
1535         while (1) {
1536                 my ($it) = list_and_choose({ PROMPT => 'What now',
1537                                              SINGLETON => 1,
1538                                              LIST_FLAT => 4,
1539                                              HEADER => '*** Commands ***',
1540                                              ON_EOF => \&quit_cmd,
1541                                              IMMEDIATE => 1 }, @cmd);
1542                 if ($it) {
1543                         eval {
1544                                 $it->[1]->();
1545                         };
1546                         if ($@) {
1547                                 print "$@";
1548                         }
1549                 }
1550         }
1551 }
1552
1553 process_args();
1554 refresh();
1555 if ($patch_mode) {
1556         patch_update_cmd();
1557 }
1558 else {
1559         status_cmd();
1560         main_loop();
1561 }