git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc sq {value} {
 525         regsub -all ' $value "'\\''" value
 526         return "'$value'"
 527 }
 528
 529 proc load_current_branch {} {
 530         global current_branch is_detached
 531
 532         set fd [open [gitdir HEAD] r]
 533         if {[gets $fd ref] < 1} {
 534                 set ref {}
 535         }
 536         close $fd
 537
 538         set pfx {ref: refs/heads/}
 539         set len [string length $pfx]
 540         if {[string equal -length $len $pfx $ref]} {
 541                 # We're on a branch.  It might not exist.  But
 542                 # HEAD looks good enough to be a branch.
 543                 #
 544                 set current_branch [string range $ref $len end]
 545                 set is_detached 0
 546         } else {
 547                 # Assume this is a detached head.
 548                 #
 549                 set current_branch HEAD
 550                 set is_detached 1
 551         }
 552 }
 553
 554 auto_load tk_optionMenu
 555 rename tk_optionMenu real__tkOptionMenu
 556 proc tk_optionMenu {w varName args} {
 557         set m [eval real__tkOptionMenu $w $varName $args]
 558         $m configure -font font_ui
 559         $w configure -font font_ui
 560         return $m
 561 }
 562
 563 proc rmsel_tag {text} {
 564         $text tag conf sel \
 565                 -background [$text cget -background] \
 566                 -foreground [$text cget -foreground] \
 567                 -borderwidth 0
 568         $text tag conf in_sel -background lightgray
 569         bind $text <Motion> break
 570         return $text
 571 }
 572
 573 set root_exists 0
 574 bind . <Visibility> {
 575         bind . <Visibility> {}
 576         set root_exists 1
 577 }
 578
 579 if {[is_Windows]} {
 580         wm iconbitmap . -default $oguilib/git-gui.ico
 581 }
 582
 583 ######################################################################
 584 ##
 585 ## config defaults
 586
 587 set cursor_ptr arrow
 588 font create font_diff -family Courier -size 10
 589 font create font_ui
 590 catch {
 591         label .dummy
 592         eval font configure font_ui [font actual [.dummy cget -font]]
 593         destroy .dummy
 594 }
 595
 596 font create font_uiitalic
 597 font create font_uibold
 598 font create font_diffbold
 599 font create font_diffitalic
 600
 601 foreach class {Button Checkbutton Entry Label
 602                 Labelframe Listbox Menu Message
 603                 Radiobutton Spinbox Text} {
 604         option add *$class.font font_ui
 605 }
 606 unset class
 607
 608 if {[is_Windows] || [is_MacOSX]} {
 609         option add *Menu.tearOff 0
 610 }
 611
 612 if {[is_MacOSX]} {
 613         set M1B M1
 614         set M1T Cmd
 615 } else {
 616         set M1B Control
 617         set M1T Ctrl
 618 }
 619
 620 proc bind_button3 {w cmd} {
 621         bind $w <Any-Button-3> $cmd
 622         if {[is_MacOSX]} {
 623                 # Mac OS X sends Button-2 on right click through three-button mouse,
 624                 # or through trackpad right-clicking (two-finger touch + click).
 625                 bind $w <Any-Button-2> $cmd
 626                 bind $w <Control-Button-1> $cmd
 627         }
 628 }
 629
 630 proc apply_config {} {
 631         global repo_config font_descs
 632
 633         foreach option $font_descs {
 634                 set name [lindex $option 0]
 635                 set font [lindex $option 1]
 636                 if {[catch {
 637                         set need_weight 1
 638                         foreach {cn cv} $repo_config(gui.$name) {
 639                                 if {$cn eq {-weight}} {
 640                                         set need_weight 0
 641                                 }
 642                                 font configure $font $cn $cv
 643                         }
 644                         if {$need_weight} {
 645                                 font configure $font -weight normal
 646                         }
 647                         } err]} {
 648                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                 }
 650                 foreach {cn cv} [font configure $font] {
 651                         font configure ${font}bold $cn $cv
 652                         font configure ${font}italic $cn $cv
 653                 }
 654                 font configure ${font}bold -weight bold
 655                 font configure ${font}italic -slant italic
 656         }
 657 }
 658
 659 set default_config(branch.autosetupmerge) true
 660 set default_config(merge.tool) {}
 661 set default_config(merge.keepbackup) true
 662 set default_config(merge.diffstat) true
 663 set default_config(merge.summary) false
 664 set default_config(merge.verbosity) 2
 665 set default_config(user.name) {}
 666 set default_config(user.email) {}
 667
 668 set default_config(gui.matchtrackingbranch) false
 669 set default_config(gui.pruneduringfetch) false
 670 set default_config(gui.trustmtime) false
 671 set default_config(gui.fastcopyblame) false
 672 set default_config(gui.copyblamethreshold) 40
 673 set default_config(gui.blamehistoryctx) 7
 674 set default_config(gui.diffcontext) 5
 675 set default_config(gui.commitmsgwidth) 75
 676 set default_config(gui.newbranchtemplate) {}
 677 set default_config(gui.spellingdictionary) {}
 678 set default_config(gui.fontui) [font configure font_ui]
 679 set default_config(gui.fontdiff) [font configure font_diff]
 680 set font_descs {
 681         {fontui   font_ui   {mc "Main Font"}}
 682         {fontdiff font_diff {mc "Diff/Console Font"}}
 683 }
 684
 685 ######################################################################
 686 ##
 687 ## find git
 688
 689 set _git  [_which git]
 690 if {$_git eq {}} {
 691         catch {wm withdraw .}
 692         tk_messageBox \
 693                 -icon error \
 694                 -type ok \
 695                 -title [mc "git-gui: fatal error"] \
 696                 -message [mc "Cannot find git in PATH."]
 697         exit 1
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## version check
 703
 704 if {[catch {set _git_version [git --version]} err]} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message "Cannot determine Git version:
 711
 712 $err
 713
 714 [appname] requires Git 1.5.0 or later."
 715         exit 1
 716 }
 717 if {![regsub {^git version } $_git_version {} _git_version]} {
 718         catch {wm withdraw .}
 719         tk_messageBox \
 720                 -icon error \
 721                 -type ok \
 722                 -title [mc "git-gui: fatal error"] \
 723                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724         exit 1
 725 }
 726
 727 set _real_git_version $_git_version
 728 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731 regsub {\.GIT$} $_git_version {} _git_version
 732 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735         catch {wm withdraw .}
 736         if {[tk_messageBox \
 737                 -icon warning \
 738                 -type yesno \
 739                 -default no \
 740                 -title "[appname]: warning" \
 741                  -message [mc "Git version cannot be determined.
 742
 743 %s claims it is version '%s'.
 744
 745 %s requires at least Git 1.5.0 or later.
 746
 747 Assume '%s' is version 1.5.0?
 748 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                 set _git_version 1.5.0
 750         } else {
 751                 exit 1
 752         }
 753 }
 754 unset _real_git_version
 755
 756 proc git-version {args} {
 757         global _git_version
 758
 759         switch [llength $args] {
 760         0 {
 761                 return $_git_version
 762         }
 763
 764         2 {
 765                 set op [lindex $args 0]
 766                 set vr [lindex $args 1]
 767                 set cm [package vcompare $_git_version $vr]
 768                 return [expr $cm $op 0]
 769         }
 770
 771         4 {
 772                 set type [lindex $args 0]
 773                 set name [lindex $args 1]
 774                 set parm [lindex $args 2]
 775                 set body [lindex $args 3]
 776
 777                 if {($type ne {proc} && $type ne {method})} {
 778                         error "Invalid arguments to git-version"
 779                 }
 780                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                         error "Last arm of $type $name must be default"
 782                 }
 783
 784                 foreach {op vr cb} [lrange $body 0 end-2] {
 785                         if {[git-version $op $vr]} {
 786                                 return [uplevel [list $type $name $parm $cb]]
 787                         }
 788                 }
 789
 790                 return [uplevel [list $type $name $parm [lindex $body end]]]
 791         }
 792
 793         default {
 794                 error "git-version >= x"
 795         }
 796
 797         }
 798 }
 799
 800 if {[git-version < 1.5]} {
 801         catch {wm withdraw .}
 802         tk_messageBox \
 803                 -icon error \
 804                 -type ok \
 805                 -title [mc "git-gui: fatal error"] \
 806                 -message "[appname] requires Git 1.5.0 or later.
 807
 808 You are using [git-version]:
 809
 810 [git --version]"
 811         exit 1
 812 }
 813
 814 ######################################################################
 815 ##
 816 ## configure our library
 817
 818 set idx [file join $oguilib tclIndex]
 819 if {[catch {set fd [open $idx r]} err]} {
 820         catch {wm withdraw .}
 821         tk_messageBox \
 822                 -icon error \
 823                 -type ok \
 824                 -title [mc "git-gui: fatal error"] \
 825                 -message $err
 826         exit 1
 827 }
 828 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829         set idx [list]
 830         while {[gets $fd n] >= 0} {
 831                 if {$n ne {} && ![string match #* $n]} {
 832                         lappend idx $n
 833                 }
 834         }
 835 } else {
 836         set idx {}
 837 }
 838 close $fd
 839
 840 if {$idx ne {}} {
 841         set loaded [list]
 842         foreach p $idx {
 843                 if {[lsearch -exact $loaded $p] >= 0} continue
 844                 source [file join $oguilib $p]
 845                 lappend loaded $p
 846         }
 847         unset loaded p
 848 } else {
 849         set auto_path [concat [list $oguilib] $auto_path]
 850 }
 851 unset -nocomplain idx fd
 852
 853 ######################################################################
 854 ##
 855 ## config file parsing
 856
 857 git-version proc _parse_config {arr_name args} {
 858         >= 1.5.3 {
 859                 upvar $arr_name arr
 860                 array unset arr
 861                 set buf {}
 862                 catch {
 863                         set fd_rc [eval \
 864                                 [list git_read config] \
 865                                 $args \
 866                                 [list --null --list]]
 867                         fconfigure $fd_rc -translation binary
 868                         set buf [read $fd_rc]
 869                         close $fd_rc
 870                 }
 871                 foreach line [split $buf "\0"] {
 872                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                 if {[is_many_config $name]} {
 874                                         lappend arr($name) $value
 875                                 } else {
 876                                         set arr($name) $value
 877                                 }
 878                         }
 879                 }
 880         }
 881         default {
 882                 upvar $arr_name arr
 883                 array unset arr
 884                 catch {
 885                         set fd_rc [eval [list git_read config --list] $args]
 886                         while {[gets $fd_rc line] >= 0} {
 887                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                         if {[is_many_config $name]} {
 889                                                 lappend arr($name) $value
 890                                         } else {
 891                                                 set arr($name) $value
 892                                         }
 893                                 }
 894                         }
 895                         close $fd_rc
 896                 }
 897         }
 898 }
 899
 900 proc load_config {include_global} {
 901         global repo_config global_config default_config
 902
 903         if {$include_global} {
 904                 _parse_config global_config --global
 905         }
 906         _parse_config repo_config
 907
 908         foreach name [array names default_config] {
 909                 if {[catch {set v $global_config($name)}]} {
 910                         set global_config($name) $default_config($name)
 911                 }
 912                 if {[catch {set v $repo_config($name)}]} {
 913                         set repo_config($name) $default_config($name)
 914                 }
 915         }
 916 }
 917
 918 ######################################################################
 919 ##
 920 ## feature option selection
 921
 922 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923         unset _junk
 924 } else {
 925         set subcommand gui
 926 }
 927 if {$subcommand eq {gui.sh}} {
 928         set subcommand gui
 929 }
 930 if {$subcommand eq {gui} && [llength $argv] > 0} {
 931         set subcommand [lindex $argv 0]
 932         set argv [lrange $argv 1 end]
 933 }
 934
 935 enable_option multicommit
 936 enable_option branch
 937 enable_option transport
 938 disable_option bare
 939
 940 switch -- $subcommand {
 941 browser -
 942 blame {
 943         enable_option bare
 944
 945         disable_option multicommit
 946         disable_option branch
 947         disable_option transport
 948 }
 949 citool {
 950         enable_option singlecommit
 951         enable_option retcode
 952
 953         disable_option multicommit
 954         disable_option branch
 955         disable_option transport
 956
 957         while {[llength $argv] > 0} {
 958                 set a [lindex $argv 0]
 959                 switch -- $a {
 960                 --amend {
 961                         enable_option initialamend
 962                 }
 963                 --nocommit {
 964                         enable_option nocommit
 965                         enable_option nocommitmsg
 966                 }
 967                 --commitmsg {
 968                         disable_option nocommitmsg
 969                 }
 970                 default {
 971                         break
 972                 }
 973                 }
 974
 975                 set argv [lrange $argv 1 end]
 976         }
 977 }
 978 }
 979
 980 ######################################################################
 981 ##
 982 ## repository setup
 983
 984 if {[catch {
 985                 set _gitdir $env(GIT_DIR)
 986                 set _prefix {}
 987                 }]
 988         && [catch {
 989                 set _gitdir [git rev-parse --git-dir]
 990                 set _prefix [git rev-parse --show-prefix]
 991         } err]} {
 992         load_config 1
 993         apply_config
 994         choose_repository::pick
 995 }
 996 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 997         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 998 }
 999 if {![file isdirectory $_gitdir]} {
1000         catch {wm withdraw .}
1001         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1002         exit 1
1003 }
1004 if {$_prefix ne {}} {
1005         regsub -all {[^/]+/} $_prefix ../ cdup
1006         if {[catch {cd $cdup} err]} {
1007                 catch {wm withdraw .}
1008                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1009                 exit 1
1010         }
1011         unset cdup
1012 } elseif {![is_enabled bare]} {
1013         if {[lindex [file split $_gitdir] end] ne {.git}} {
1014                 catch {wm withdraw .}
1015                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1016                 exit 1
1017         }
1018         if {[catch {cd [file dirname $_gitdir]} err]} {
1019                 catch {wm withdraw .}
1020                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1021                 exit 1
1022         }
1023 }
1024 set _reponame [file split [file normalize $_gitdir]]
1025 if {[lindex $_reponame end] eq {.git}} {
1026         set _reponame [lindex $_reponame end-1]
1027 } else {
1028         set _reponame [lindex $_reponame end]
1029 }
1030
1031 ######################################################################
1032 ##
1033 ## global init
1034
1035 set current_diff_path {}
1036 set current_diff_side {}
1037 set diff_actions [list]
1038
1039 set HEAD {}
1040 set PARENT {}
1041 set MERGE_HEAD [list]
1042 set commit_type {}
1043 set empty_tree {}
1044 set current_branch {}
1045 set is_detached 0
1046 set current_diff_path {}
1047 set is_3way_diff 0
1048 set selected_commit_type new
1049
1050 set nullid "0000000000000000000000000000000000000000"
1051 set nullid2 "0000000000000000000000000000000000000001"
1052
1053 ######################################################################
1054 ##
1055 ## task management
1056
1057 set rescan_active 0
1058 set diff_active 0
1059 set last_clicked {}
1060
1061 set disable_on_lock [list]
1062 set index_lock_type none
1063
1064 proc lock_index {type} {
1065         global index_lock_type disable_on_lock
1066
1067         if {$index_lock_type eq {none}} {
1068                 set index_lock_type $type
1069                 foreach w $disable_on_lock {
1070                         uplevel #0 $w disabled
1071                 }
1072                 return 1
1073         } elseif {$index_lock_type eq "begin-$type"} {
1074                 set index_lock_type $type
1075                 return 1
1076         }
1077         return 0
1078 }
1079
1080 proc unlock_index {} {
1081         global index_lock_type disable_on_lock
1082
1083         set index_lock_type none
1084         foreach w $disable_on_lock {
1085                 uplevel #0 $w normal
1086         }
1087 }
1088
1089 ######################################################################
1090 ##
1091 ## status
1092
1093 proc repository_state {ctvar hdvar mhvar} {
1094         global current_branch
1095         upvar $ctvar ct $hdvar hd $mhvar mh
1096
1097         set mh [list]
1098
1099         load_current_branch
1100         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1101                 set hd {}
1102                 set ct initial
1103                 return
1104         }
1105
1106         set merge_head [gitdir MERGE_HEAD]
1107         if {[file exists $merge_head]} {
1108                 set ct merge
1109                 set fd_mh [open $merge_head r]
1110                 while {[gets $fd_mh line] >= 0} {
1111                         lappend mh $line
1112                 }
1113                 close $fd_mh
1114                 return
1115         }
1116
1117         set ct normal
1118 }
1119
1120 proc PARENT {} {
1121         global PARENT empty_tree
1122
1123         set p [lindex $PARENT 0]
1124         if {$p ne {}} {
1125                 return $p
1126         }
1127         if {$empty_tree eq {}} {
1128                 set empty_tree [git mktree << {}]
1129         }
1130         return $empty_tree
1131 }
1132
1133 proc force_amend {} {
1134         global selected_commit_type
1135         global HEAD PARENT MERGE_HEAD commit_type
1136
1137         repository_state newType newHEAD newMERGE_HEAD
1138         set HEAD $newHEAD
1139         set PARENT $newHEAD
1140         set MERGE_HEAD $newMERGE_HEAD
1141         set commit_type $newType
1142
1143         set selected_commit_type amend
1144         do_select_commit_type
1145 }
1146
1147 proc rescan {after {honor_trustmtime 1}} {
1148         global HEAD PARENT MERGE_HEAD commit_type
1149         global ui_index ui_workdir ui_comm
1150         global rescan_active file_states
1151         global repo_config
1152
1153         if {$rescan_active > 0 || ![lock_index read]} return
1154
1155         repository_state newType newHEAD newMERGE_HEAD
1156         if {[string match amend* $commit_type]
1157                 && $newType eq {normal}
1158                 && $newHEAD eq $HEAD} {
1159         } else {
1160                 set HEAD $newHEAD
1161                 set PARENT $newHEAD
1162                 set MERGE_HEAD $newMERGE_HEAD
1163                 set commit_type $newType
1164         }
1165
1166         array unset file_states
1167
1168         if {!$::GITGUI_BCK_exists &&
1169                 (![$ui_comm edit modified]
1170                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1171                 if {[string match amend* $commit_type]} {
1172                 } elseif {[load_message GITGUI_MSG]} {
1173                 } elseif {[load_message MERGE_MSG]} {
1174                 } elseif {[load_message SQUASH_MSG]} {
1175                 }
1176                 $ui_comm edit reset
1177                 $ui_comm edit modified false
1178         }
1179
1180         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1181                 rescan_stage2 {} $after
1182         } else {
1183                 set rescan_active 1
1184                 ui_status [mc "Refreshing file status..."]
1185                 set fd_rf [git_read update-index \
1186                         -q \
1187                         --unmerged \
1188                         --ignore-missing \
1189                         --refresh \
1190                         ]
1191                 fconfigure $fd_rf -blocking 0 -translation binary
1192                 fileevent $fd_rf readable \
1193                         [list rescan_stage2 $fd_rf $after]
1194         }
1195 }
1196
1197 if {[is_Cygwin]} {
1198         set is_git_info_exclude {}
1199         proc have_info_exclude {} {
1200                 global is_git_info_exclude
1201
1202                 if {$is_git_info_exclude eq {}} {
1203                         if {[catch {exec test -f [gitdir info exclude]}]} {
1204                                 set is_git_info_exclude 0
1205                         } else {
1206                                 set is_git_info_exclude 1
1207                         }
1208                 }
1209                 return $is_git_info_exclude
1210         }
1211 } else {
1212         proc have_info_exclude {} {
1213                 return [file readable [gitdir info exclude]]
1214         }
1215 }
1216
1217 proc rescan_stage2 {fd after} {
1218         global rescan_active buf_rdi buf_rdf buf_rlo
1219
1220         if {$fd ne {}} {
1221                 read $fd
1222                 if {![eof $fd]} return
1223                 close $fd
1224         }
1225
1226         set ls_others [list --exclude-per-directory=.gitignore]
1227         if {[have_info_exclude]} {
1228                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1229         }
1230         set user_exclude [get_config core.excludesfile]
1231         if {$user_exclude ne {} && [file readable $user_exclude]} {
1232                 lappend ls_others "--exclude-from=$user_exclude"
1233         }
1234
1235         set buf_rdi {}
1236         set buf_rdf {}
1237         set buf_rlo {}
1238
1239         set rescan_active 3
1240         ui_status [mc "Scanning for modified files ..."]
1241         set fd_di [git_read diff-index --cached -z [PARENT]]
1242         set fd_df [git_read diff-files -z]
1243         set fd_lo [eval git_read ls-files --others -z $ls_others]
1244
1245         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1246         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1247         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1248         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1249         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1250         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1251 }
1252
1253 proc load_message {file} {
1254         global ui_comm
1255
1256         set f [gitdir $file]
1257         if {[file isfile $f]} {
1258                 if {[catch {set fd [open $f r]}]} {
1259                         return 0
1260                 }
1261                 fconfigure $fd -eofchar {}
1262                 set content [string trim [read $fd]]
1263                 close $fd
1264                 regsub -all -line {[ \r\t]+$} $content {} content
1265                 $ui_comm delete 0.0 end
1266                 $ui_comm insert end $content
1267                 return 1
1268         }
1269         return 0
1270 }
1271
1272 proc read_diff_index {fd after} {
1273         global buf_rdi
1274
1275         append buf_rdi [read $fd]
1276         set c 0
1277         set n [string length $buf_rdi]
1278         while {$c < $n} {
1279                 set z1 [string first "\0" $buf_rdi $c]
1280                 if {$z1 == -1} break
1281                 incr z1
1282                 set z2 [string first "\0" $buf_rdi $z1]
1283                 if {$z2 == -1} break
1284
1285                 incr c
1286                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1287                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1288                 merge_state \
1289                         [encoding convertfrom $p] \
1290                         [lindex $i 4]? \
1291                         [list [lindex $i 0] [lindex $i 2]] \
1292                         [list]
1293                 set c $z2
1294                 incr c
1295         }
1296         if {$c < $n} {
1297                 set buf_rdi [string range $buf_rdi $c end]
1298         } else {
1299                 set buf_rdi {}
1300         }
1301
1302         rescan_done $fd buf_rdi $after
1303 }
1304
1305 proc read_diff_files {fd after} {
1306         global buf_rdf
1307
1308         append buf_rdf [read $fd]
1309         set c 0
1310         set n [string length $buf_rdf]
1311         while {$c < $n} {
1312                 set z1 [string first "\0" $buf_rdf $c]
1313                 if {$z1 == -1} break
1314                 incr z1
1315                 set z2 [string first "\0" $buf_rdf $z1]
1316                 if {$z2 == -1} break
1317
1318                 incr c
1319                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1320                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1321                 merge_state \
1322                         [encoding convertfrom $p] \
1323                         ?[lindex $i 4] \
1324                         [list] \
1325                         [list [lindex $i 0] [lindex $i 2]]
1326                 set c $z2
1327                 incr c
1328         }
1329         if {$c < $n} {
1330                 set buf_rdf [string range $buf_rdf $c end]
1331         } else {
1332                 set buf_rdf {}
1333         }
1334
1335         rescan_done $fd buf_rdf $after
1336 }
1337
1338 proc read_ls_others {fd after} {
1339         global buf_rlo
1340
1341         append buf_rlo [read $fd]
1342         set pck [split $buf_rlo "\0"]
1343         set buf_rlo [lindex $pck end]
1344         foreach p [lrange $pck 0 end-1] {
1345                 set p [encoding convertfrom $p]
1346                 if {[string index $p end] eq {/}} {
1347                         set p [string range $p 0 end-1]
1348                 }
1349                 merge_state $p ?O
1350         }
1351         rescan_done $fd buf_rlo $after
1352 }
1353
1354 proc rescan_done {fd buf after} {
1355         global rescan_active current_diff_path
1356         global file_states repo_config
1357         upvar $buf to_clear
1358
1359         if {![eof $fd]} return
1360         set to_clear {}
1361         close $fd
1362         if {[incr rescan_active -1] > 0} return
1363
1364         prune_selection
1365         unlock_index
1366         display_all_files
1367         if {$current_diff_path ne {}} reshow_diff
1368         if {$current_diff_path eq {}} select_first_diff
1369
1370         uplevel #0 $after
1371 }
1372
1373 proc prune_selection {} {
1374         global file_states selected_paths
1375
1376         foreach path [array names selected_paths] {
1377                 if {[catch {set still_here $file_states($path)}]} {
1378                         unset selected_paths($path)
1379                 }
1380         }
1381 }
1382
1383 ######################################################################
1384 ##
1385 ## ui helpers
1386
1387 proc mapicon {w state path} {
1388         global all_icons
1389
1390         if {[catch {set r $all_icons($state$w)}]} {
1391                 puts "error: no icon for $w state={$state} $path"
1392                 return file_plain
1393         }
1394         return $r
1395 }
1396
1397 proc mapdesc {state path} {
1398         global all_descs
1399
1400         if {[catch {set r $all_descs($state)}]} {
1401                 puts "error: no desc for state={$state} $path"
1402                 return $state
1403         }
1404         return $r
1405 }
1406
1407 proc ui_status {msg} {
1408         global main_status
1409         if {[info exists main_status]} {
1410                 $main_status show $msg
1411         }
1412 }
1413
1414 proc ui_ready {{test {}}} {
1415         global main_status
1416         if {[info exists main_status]} {
1417                 $main_status show [mc "Ready."] $test
1418         }
1419 }
1420
1421 proc escape_path {path} {
1422         regsub -all {\\} $path "\\\\" path
1423         regsub -all "\n" $path "\\n" path
1424         return $path
1425 }
1426
1427 proc short_path {path} {
1428         return [escape_path [lindex [file split $path] end]]
1429 }
1430
1431 set next_icon_id 0
1432 set null_sha1 [string repeat 0 40]
1433
1434 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1435         global file_states next_icon_id null_sha1
1436
1437         set s0 [string index $new_state 0]
1438         set s1 [string index $new_state 1]
1439
1440         if {[catch {set info $file_states($path)}]} {
1441                 set state __
1442                 set icon n[incr next_icon_id]
1443         } else {
1444                 set state [lindex $info 0]
1445                 set icon [lindex $info 1]
1446                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1447                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1448         }
1449
1450         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1451         elseif {$s0 eq {_}} {set s0 _}
1452
1453         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1454         elseif {$s1 eq {_}} {set s1 _}
1455
1456         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1457                 set head_info [list 0 $null_sha1]
1458         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1459                 && $head_info eq {}} {
1460                 set head_info $index_info
1461         }
1462
1463         set file_states($path) [list $s0$s1 $icon \
1464                 $head_info $index_info \
1465                 ]
1466         return $state
1467 }
1468
1469 proc display_file_helper {w path icon_name old_m new_m} {
1470         global file_lists
1471
1472         if {$new_m eq {_}} {
1473                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1474                 if {$lno >= 0} {
1475                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1476                         incr lno
1477                         $w conf -state normal
1478                         $w delete $lno.0 [expr {$lno + 1}].0
1479                         $w conf -state disabled
1480                 }
1481         } elseif {$old_m eq {_} && $new_m ne {_}} {
1482                 lappend file_lists($w) $path
1483                 set file_lists($w) [lsort -unique $file_lists($w)]
1484                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1485                 incr lno
1486                 $w conf -state normal
1487                 $w image create $lno.0 \
1488                         -align center -padx 5 -pady 1 \
1489                         -name $icon_name \
1490                         -image [mapicon $w $new_m $path]
1491                 $w insert $lno.1 "[escape_path $path]\n"
1492                 $w conf -state disabled
1493         } elseif {$old_m ne $new_m} {
1494                 $w conf -state normal
1495                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1496                 $w conf -state disabled
1497         }
1498 }
1499
1500 proc display_file {path state} {
1501         global file_states selected_paths
1502         global ui_index ui_workdir
1503
1504         set old_m [merge_state $path $state]
1505         set s $file_states($path)
1506         set new_m [lindex $s 0]
1507         set icon_name [lindex $s 1]
1508
1509         set o [string index $old_m 0]
1510         set n [string index $new_m 0]
1511         if {$o eq {U}} {
1512                 set o _
1513         }
1514         if {$n eq {U}} {
1515                 set n _
1516         }
1517         display_file_helper     $ui_index $path $icon_name $o $n
1518
1519         if {[string index $old_m 0] eq {U}} {
1520                 set o U
1521         } else {
1522                 set o [string index $old_m 1]
1523         }
1524         if {[string index $new_m 0] eq {U}} {
1525                 set n U
1526         } else {
1527                 set n [string index $new_m 1]
1528         }
1529         display_file_helper     $ui_workdir $path $icon_name $o $n
1530
1531         if {$new_m eq {__}} {
1532                 unset file_states($path)
1533                 catch {unset selected_paths($path)}
1534         }
1535 }
1536
1537 proc display_all_files_helper {w path icon_name m} {
1538         global file_lists
1539
1540         lappend file_lists($w) $path
1541         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1542         $w image create end \
1543                 -align center -padx 5 -pady 1 \
1544                 -name $icon_name \
1545                 -image [mapicon $w $m $path]
1546         $w insert end "[escape_path $path]\n"
1547 }
1548
1549 proc display_all_files {} {
1550         global ui_index ui_workdir
1551         global file_states file_lists
1552         global last_clicked
1553
1554         $ui_index conf -state normal
1555         $ui_workdir conf -state normal
1556
1557         $ui_index delete 0.0 end
1558         $ui_workdir delete 0.0 end
1559         set last_clicked {}
1560
1561         set file_lists($ui_index) [list]
1562         set file_lists($ui_workdir) [list]
1563
1564         foreach path [lsort [array names file_states]] {
1565                 set s $file_states($path)
1566                 set m [lindex $s 0]
1567                 set icon_name [lindex $s 1]
1568
1569                 set s [string index $m 0]
1570                 if {$s ne {U} && $s ne {_}} {
1571                         display_all_files_helper $ui_index $path \
1572                                 $icon_name $s
1573                 }
1574
1575                 if {[string index $m 0] eq {U}} {
1576                         set s U
1577                 } else {
1578                         set s [string index $m 1]
1579                 }
1580                 if {$s ne {_}} {
1581                         display_all_files_helper $ui_workdir $path \
1582                                 $icon_name $s
1583                 }
1584         }
1585
1586         $ui_index conf -state disabled
1587         $ui_workdir conf -state disabled
1588 }
1589
1590 ######################################################################
1591 ##
1592 ## icons
1593
1594 set filemask {
1595 #define mask_width 14
1596 #define mask_height 15
1597 static unsigned char mask_bits[] = {
1598    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1599    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1600    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1601 }
1602
1603 image create bitmap file_plain -background white -foreground black -data {
1604 #define plain_width 14
1605 #define plain_height 15
1606 static unsigned char plain_bits[] = {
1607    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1608    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1609    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1610 } -maskdata $filemask
1611
1612 image create bitmap file_mod -background white -foreground blue -data {
1613 #define mod_width 14
1614 #define mod_height 15
1615 static unsigned char mod_bits[] = {
1616    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1617    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1618    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1619 } -maskdata $filemask
1620
1621 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1622 #define file_fulltick_width 14
1623 #define file_fulltick_height 15
1624 static unsigned char file_fulltick_bits[] = {
1625    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1626    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1627    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1628 } -maskdata $filemask
1629
1630 image create bitmap file_parttick -background white -foreground "#005050" -data {
1631 #define parttick_width 14
1632 #define parttick_height 15
1633 static unsigned char parttick_bits[] = {
1634    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1635    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1636    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1637 } -maskdata $filemask
1638
1639 image create bitmap file_question -background white -foreground black -data {
1640 #define file_question_width 14
1641 #define file_question_height 15
1642 static unsigned char file_question_bits[] = {
1643    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1644    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1645    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1646 } -maskdata $filemask
1647
1648 image create bitmap file_removed -background white -foreground red -data {
1649 #define file_removed_width 14
1650 #define file_removed_height 15
1651 static unsigned char file_removed_bits[] = {
1652    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1653    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1654    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1655 } -maskdata $filemask
1656
1657 image create bitmap file_merge -background white -foreground blue -data {
1658 #define file_merge_width 14
1659 #define file_merge_height 15
1660 static unsigned char file_merge_bits[] = {
1661    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1662    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1663    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1664 } -maskdata $filemask
1665
1666 image create bitmap file_statechange -background white -foreground green -data {
1667 #define file_merge_width 14
1668 #define file_merge_height 15
1669 static unsigned char file_statechange_bits[] = {
1670    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1671    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1672    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1673 } -maskdata $filemask
1674
1675 set ui_index .vpane.files.index.list
1676 set ui_workdir .vpane.files.workdir.list
1677
1678 set all_icons(_$ui_index)   file_plain
1679 set all_icons(A$ui_index)   file_fulltick
1680 set all_icons(M$ui_index)   file_fulltick
1681 set all_icons(D$ui_index)   file_removed
1682 set all_icons(U$ui_index)   file_merge
1683 set all_icons(T$ui_index)   file_statechange
1684
1685 set all_icons(_$ui_workdir) file_plain
1686 set all_icons(M$ui_workdir) file_mod
1687 set all_icons(D$ui_workdir) file_question
1688 set all_icons(U$ui_workdir) file_merge
1689 set all_icons(O$ui_workdir) file_plain
1690 set all_icons(T$ui_workdir) file_statechange
1691
1692 set max_status_desc 0
1693 foreach i {
1694                 {__ {mc "Unmodified"}}
1695
1696                 {_M {mc "Modified, not staged"}}
1697                 {M_ {mc "Staged for commit"}}
1698                 {MM {mc "Portions staged for commit"}}
1699                 {MD {mc "Staged for commit, missing"}}
1700
1701                 {_T {mc "File type changed, not staged"}}
1702                 {T_ {mc "File type changed, staged"}}
1703
1704                 {_O {mc "Untracked, not staged"}}
1705                 {A_ {mc "Staged for commit"}}
1706                 {AM {mc "Portions staged for commit"}}
1707                 {AD {mc "Staged for commit, missing"}}
1708
1709                 {_D {mc "Missing"}}
1710                 {D_ {mc "Staged for removal"}}
1711                 {DO {mc "Staged for removal, still present"}}
1712
1713                 {_U {mc "Requires merge resolution"}}
1714                 {U_ {mc "Requires merge resolution"}}
1715                 {UU {mc "Requires merge resolution"}}
1716                 {UM {mc "Requires merge resolution"}}
1717                 {UD {mc "Requires merge resolution"}}
1718                 {UT {mc "Requires merge resolution"}}
1719         } {
1720         set text [eval [lindex $i 1]]
1721         if {$max_status_desc < [string length $text]} {
1722                 set max_status_desc [string length $text]
1723         }
1724         set all_descs([lindex $i 0]) $text
1725 }
1726 unset i
1727
1728 ######################################################################
1729 ##
1730 ## util
1731
1732 proc scrollbar2many {list mode args} {
1733         foreach w $list {eval $w $mode $args}
1734 }
1735
1736 proc many2scrollbar {list mode sb top bottom} {
1737         $sb set $top $bottom
1738         foreach w $list {$w $mode moveto $top}
1739 }
1740
1741 proc incr_font_size {font {amt 1}} {
1742         set sz [font configure $font -size]
1743         incr sz $amt
1744         font configure $font -size $sz
1745         font configure ${font}bold -size $sz
1746         font configure ${font}italic -size $sz
1747 }
1748
1749 ######################################################################
1750 ##
1751 ## ui commands
1752
1753 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1754
1755 proc do_gitk {revs} {
1756         # -- Always start gitk through whatever we were loaded with.  This
1757         #    lets us bypass using shell process on Windows systems.
1758         #
1759         set exe [_which gitk -script]
1760         set cmd [list [info nameofexecutable] $exe]
1761         if {$exe eq {}} {
1762                 error_popup [mc "Couldn't find gitk in PATH"]
1763         } else {
1764                 global env
1765
1766                 if {[info exists env(GIT_DIR)]} {
1767                         set old_GIT_DIR $env(GIT_DIR)
1768                 } else {
1769                         set old_GIT_DIR {}
1770                 }
1771
1772                 set pwd [pwd]
1773                 cd [file dirname [gitdir]]
1774                 set env(GIT_DIR) [file tail [gitdir]]
1775
1776                 eval exec $cmd $revs &
1777
1778                 if {$old_GIT_DIR eq {}} {
1779                         unset env(GIT_DIR)
1780                 } else {
1781                         set env(GIT_DIR) $old_GIT_DIR
1782                 }
1783                 cd $pwd
1784
1785                 ui_status $::starting_gitk_msg
1786                 after 10000 {
1787                         ui_ready $starting_gitk_msg
1788                 }
1789         }
1790 }
1791
1792 set is_quitting 0
1793 set ret_code    1
1794
1795 proc terminate_me {win} {
1796         global ret_code
1797         if {$win ne {.}} return
1798         exit $ret_code
1799 }
1800
1801 proc do_quit {{rc {1}}} {
1802         global ui_comm is_quitting repo_config commit_type
1803         global GITGUI_BCK_exists GITGUI_BCK_i
1804         global ui_comm_spell
1805         global ret_code
1806
1807         if {$is_quitting} return
1808         set is_quitting 1
1809
1810         if {[winfo exists $ui_comm]} {
1811                 # -- Stash our current commit buffer.
1812                 #
1813                 set save [gitdir GITGUI_MSG]
1814                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1815                         file rename -force [gitdir GITGUI_BCK] $save
1816                         set GITGUI_BCK_exists 0
1817                 } else {
1818                         set msg [string trim [$ui_comm get 0.0 end]]
1819                         regsub -all -line {[ \r\t]+$} $msg {} msg
1820                         if {(![string match amend* $commit_type]
1821                                 || [$ui_comm edit modified])
1822                                 && $msg ne {}} {
1823                                 catch {
1824                                         set fd [open $save w]
1825                                         puts -nonewline $fd $msg
1826                                         close $fd
1827                                 }
1828                         } else {
1829                                 catch {file delete $save}
1830                         }
1831                 }
1832
1833                 # -- Cancel our spellchecker if its running.
1834                 #
1835                 if {[info exists ui_comm_spell]} {
1836                         $ui_comm_spell stop
1837                 }
1838
1839                 # -- Remove our editor backup, its not needed.
1840                 #
1841                 after cancel $GITGUI_BCK_i
1842                 if {$GITGUI_BCK_exists} {
1843                         catch {file delete [gitdir GITGUI_BCK]}
1844                 }
1845
1846                 # -- Stash our current window geometry into this repository.
1847                 #
1848                 set cfg_geometry [list]
1849                 lappend cfg_geometry [wm geometry .]
1850                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1851                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1852                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1853                         set rc_geometry {}
1854                 }
1855                 if {$cfg_geometry ne $rc_geometry} {
1856                         catch {git config gui.geometry $cfg_geometry}
1857                 }
1858         }
1859
1860         set ret_code $rc
1861         destroy .
1862 }
1863
1864 proc do_rescan {} {
1865         rescan ui_ready
1866 }
1867
1868 proc ui_do_rescan {} {
1869         rescan {force_first_diff; ui_ready}
1870 }
1871
1872 proc do_commit {} {
1873         commit_tree
1874 }
1875
1876 proc next_diff {} {
1877         global next_diff_p next_diff_w next_diff_i
1878         show_diff $next_diff_p $next_diff_w {}
1879 }
1880
1881 proc find_anchor_pos {lst name} {
1882         set lid [lsearch -sorted -exact $lst $name]
1883
1884         if {$lid == -1} {
1885                 set lid 0
1886                 foreach lname $lst {
1887                         if {$lname >= $name} break
1888                         incr lid
1889                 }
1890         }
1891
1892         return $lid
1893 }
1894
1895 proc find_file_from {flist idx delta path mmask} {
1896         global file_states
1897
1898         set len [llength $flist]
1899         while {$idx >= 0 && $idx < $len} {
1900                 set name [lindex $flist $idx]
1901
1902                 if {$name ne $path && [info exists file_states($name)]} {
1903                         set state [lindex $file_states($name) 0]
1904
1905                         if {$mmask eq {} || [regexp $mmask $state]} {
1906                                 return $idx
1907                         }
1908                 }
1909
1910                 incr idx $delta
1911         }
1912
1913         return {}
1914 }
1915
1916 proc find_next_diff {w path {lno {}} {mmask {}}} {
1917         global next_diff_p next_diff_w next_diff_i
1918         global file_lists ui_index ui_workdir
1919
1920         set flist $file_lists($w)
1921         if {$lno eq {}} {
1922                 set lno [find_anchor_pos $flist $path]
1923         } else {
1924                 incr lno -1
1925         }
1926
1927         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
1928                 if {$w eq $ui_index} {
1929                         set mmask "^$mmask"
1930                 } else {
1931                         set mmask "$mmask\$"
1932                 }
1933         }
1934
1935         set idx [find_file_from $flist $lno 1 $path $mmask]
1936         if {$idx eq {}} {
1937                 incr lno -1
1938                 set idx [find_file_from $flist $lno -1 $path $mmask]
1939         }
1940
1941         if {$idx ne {}} {
1942                 set next_diff_w $w
1943                 set next_diff_p [lindex $flist $idx]
1944                 set next_diff_i [expr {$idx+1}]
1945                 return 1
1946         } else {
1947                 return 0
1948         }
1949 }
1950
1951 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
1952         global current_diff_path
1953
1954         if {$path ne $current_diff_path} {
1955                 return {}
1956         } elseif {[find_next_diff $w $path $lno $mmask]} {
1957                 return {next_diff;}
1958         } else {
1959                 return {reshow_diff;}
1960         }
1961 }
1962
1963 proc select_first_diff {} {
1964         global ui_workdir
1965
1966         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
1967             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
1968                 next_diff
1969         }
1970 }
1971
1972 proc force_first_diff {} {
1973         global current_diff_path
1974
1975         if {[info exists file_states($current_diff_path)]} {
1976                 set state [lindex $file_states($current_diff_path) 0]
1977
1978                 if {[string index $state 1] ne {O}} return
1979         }
1980
1981         select_first_diff
1982 }
1983
1984 proc toggle_or_diff {w x y} {
1985         global file_states file_lists current_diff_path ui_index ui_workdir
1986         global last_clicked selected_paths
1987
1988         set pos [split [$w index @$x,$y] .]
1989         set lno [lindex $pos 0]
1990         set col [lindex $pos 1]
1991         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1992         if {$path eq {}} {
1993                 set last_clicked {}
1994                 return
1995         }
1996
1997         set last_clicked [list $w $lno]
1998         array unset selected_paths
1999         $ui_index tag remove in_sel 0.0 end
2000         $ui_workdir tag remove in_sel 0.0 end
2001
2002         # Do not stage files with conflicts
2003         if {[info exists file_states($path)]} {
2004                 set state [lindex $file_states($path) 0]
2005         } else {
2006                 set state {__}
2007         }
2008
2009         if {[string first {U} $state] >= 0} {
2010                 set col 1
2011         }
2012
2013         # Restage the file, or simply show the diff
2014         if {$col == 0 && $y > 1} {
2015                 if {[string index $state 1] eq {O}} {
2016                         set mmask {}
2017                 } else {
2018                         set mmask {[^O]}
2019                 }
2020
2021                 set after [next_diff_after_action $w $path $lno $mmask]
2022
2023                 if {$w eq $ui_index} {
2024                         update_indexinfo \
2025                                 "Unstaging [short_path $path] from commit" \
2026                                 [list $path] \
2027                                 [concat $after [list ui_ready]]
2028                 } elseif {$w eq $ui_workdir} {
2029                         update_index \
2030                                 "Adding [short_path $path]" \
2031                                 [list $path] \
2032                                 [concat $after [list ui_ready]]
2033                 }
2034         } else {
2035                 show_diff $path $w $lno
2036         }
2037 }
2038
2039 proc add_one_to_selection {w x y} {
2040         global file_lists last_clicked selected_paths
2041
2042         set lno [lindex [split [$w index @$x,$y] .] 0]
2043         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2044         if {$path eq {}} {
2045                 set last_clicked {}
2046                 return
2047         }
2048
2049         if {$last_clicked ne {}
2050                 && [lindex $last_clicked 0] ne $w} {
2051                 array unset selected_paths
2052                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2053         }
2054
2055         set last_clicked [list $w $lno]
2056         if {[catch {set in_sel $selected_paths($path)}]} {
2057                 set in_sel 0
2058         }
2059         if {$in_sel} {
2060                 unset selected_paths($path)
2061                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2062         } else {
2063                 set selected_paths($path) 1
2064                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2065         }
2066 }
2067
2068 proc add_range_to_selection {w x y} {
2069         global file_lists last_clicked selected_paths
2070
2071         if {[lindex $last_clicked 0] ne $w} {
2072                 toggle_or_diff $w $x $y
2073                 return
2074         }
2075
2076         set lno [lindex [split [$w index @$x,$y] .] 0]
2077         set lc [lindex $last_clicked 1]
2078         if {$lc < $lno} {
2079                 set begin $lc
2080                 set end $lno
2081         } else {
2082                 set begin $lno
2083                 set end $lc
2084         }
2085
2086         foreach path [lrange $file_lists($w) \
2087                 [expr {$begin - 1}] \
2088                 [expr {$end - 1}]] {
2089                 set selected_paths($path) 1
2090         }
2091         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2092 }
2093
2094 proc show_more_context {} {
2095         global repo_config
2096         if {$repo_config(gui.diffcontext) < 99} {
2097                 incr repo_config(gui.diffcontext)
2098                 reshow_diff
2099         }
2100 }
2101
2102 proc show_less_context {} {
2103         global repo_config
2104         if {$repo_config(gui.diffcontext) > 1} {
2105                 incr repo_config(gui.diffcontext) -1
2106                 reshow_diff
2107         }
2108 }
2109
2110 ######################################################################
2111 ##
2112 ## ui construction
2113
2114 load_config 0
2115 apply_config
2116 set ui_comm {}
2117
2118 # -- Menu Bar
2119 #
2120 menu .mbar -tearoff 0
2121 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2122 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2123 if {[is_enabled branch]} {
2124         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2125 }
2126 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2127         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2128 }
2129 if {[is_enabled transport]} {
2130         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2131         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2132 }
2133 . configure -menu .mbar
2134
2135 # -- Repository Menu
2136 #
2137 menu .mbar.repository
2138
2139 .mbar.repository add command \
2140         -label [mc "Browse Current Branch's Files"] \
2141         -command {browser::new $current_branch}
2142 set ui_browse_current [.mbar.repository index last]
2143 .mbar.repository add command \
2144         -label [mc "Browse Branch Files..."] \
2145         -command browser_open::dialog
2146 .mbar.repository add separator
2147
2148 .mbar.repository add command \
2149         -label [mc "Visualize Current Branch's History"] \
2150         -command {do_gitk $current_branch}
2151 set ui_visualize_current [.mbar.repository index last]
2152 .mbar.repository add command \
2153         -label [mc "Visualize All Branch History"] \
2154         -command {do_gitk --all}
2155 .mbar.repository add separator
2156
2157 proc current_branch_write {args} {
2158         global current_branch
2159         .mbar.repository entryconf $::ui_browse_current \
2160                 -label [mc "Browse %s's Files" $current_branch]
2161         .mbar.repository entryconf $::ui_visualize_current \
2162                 -label [mc "Visualize %s's History" $current_branch]
2163 }
2164 trace add variable current_branch write current_branch_write
2165
2166 if {[is_enabled multicommit]} {
2167         .mbar.repository add command -label [mc "Database Statistics"] \
2168                 -command do_stats
2169
2170         .mbar.repository add command -label [mc "Compress Database"] \
2171                 -command do_gc
2172
2173         .mbar.repository add command -label [mc "Verify Database"] \
2174                 -command do_fsck_objects
2175
2176         .mbar.repository add separator
2177
2178         if {[is_Cygwin]} {
2179                 .mbar.repository add command \
2180                         -label [mc "Create Desktop Icon"] \
2181                         -command do_cygwin_shortcut
2182         } elseif {[is_Windows]} {
2183                 .mbar.repository add command \
2184                         -label [mc "Create Desktop Icon"] \
2185                         -command do_windows_shortcut
2186         } elseif {[is_MacOSX]} {
2187                 .mbar.repository add command \
2188                         -label [mc "Create Desktop Icon"] \
2189                         -command do_macosx_app
2190         }
2191 }
2192
2193 if {[is_MacOSX]} {
2194         proc ::tk::mac::Quit {args} { do_quit }
2195 } else {
2196         .mbar.repository add command -label [mc Quit] \
2197                 -command do_quit \
2198                 -accelerator $M1T-Q
2199 }
2200
2201 # -- Edit Menu
2202 #
2203 menu .mbar.edit
2204 .mbar.edit add command -label [mc Undo] \
2205         -command {catch {[focus] edit undo}} \
2206         -accelerator $M1T-Z
2207 .mbar.edit add command -label [mc Redo] \
2208         -command {catch {[focus] edit redo}} \
2209         -accelerator $M1T-Y
2210 .mbar.edit add separator
2211 .mbar.edit add command -label [mc Cut] \
2212         -command {catch {tk_textCut [focus]}} \
2213         -accelerator $M1T-X
2214 .mbar.edit add command -label [mc Copy] \
2215         -command {catch {tk_textCopy [focus]}} \
2216         -accelerator $M1T-C
2217 .mbar.edit add command -label [mc Paste] \
2218         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2219         -accelerator $M1T-V
2220 .mbar.edit add command -label [mc Delete] \
2221         -command {catch {[focus] delete sel.first sel.last}} \
2222         -accelerator Del
2223 .mbar.edit add separator
2224 .mbar.edit add command -label [mc "Select All"] \
2225         -command {catch {[focus] tag add sel 0.0 end}} \
2226         -accelerator $M1T-A
2227
2228 # -- Branch Menu
2229 #
2230 if {[is_enabled branch]} {
2231         menu .mbar.branch
2232
2233         .mbar.branch add command -label [mc "Create..."] \
2234                 -command branch_create::dialog \
2235                 -accelerator $M1T-N
2236         lappend disable_on_lock [list .mbar.branch entryconf \
2237                 [.mbar.branch index last] -state]
2238
2239         .mbar.branch add command -label [mc "Checkout..."] \
2240                 -command branch_checkout::dialog \
2241                 -accelerator $M1T-O
2242         lappend disable_on_lock [list .mbar.branch entryconf \
2243                 [.mbar.branch index last] -state]
2244
2245         .mbar.branch add command -label [mc "Rename..."] \
2246                 -command branch_rename::dialog
2247         lappend disable_on_lock [list .mbar.branch entryconf \
2248                 [.mbar.branch index last] -state]
2249
2250         .mbar.branch add command -label [mc "Delete..."] \
2251                 -command branch_delete::dialog
2252         lappend disable_on_lock [list .mbar.branch entryconf \
2253                 [.mbar.branch index last] -state]
2254
2255         .mbar.branch add command -label [mc "Reset..."] \
2256                 -command merge::reset_hard
2257         lappend disable_on_lock [list .mbar.branch entryconf \
2258                 [.mbar.branch index last] -state]
2259 }
2260
2261 # -- Commit Menu
2262 #
2263 proc commit_btn_caption {} {
2264         if {[is_enabled nocommit]} {
2265                 return [mc "Done"]
2266         } else {
2267                 return [mc Commit@@verb]
2268         }
2269 }
2270
2271 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2272         menu .mbar.commit
2273
2274         if {![is_enabled nocommit]} {
2275                 .mbar.commit add radiobutton \
2276                         -label [mc "New Commit"] \
2277                         -command do_select_commit_type \
2278                         -variable selected_commit_type \
2279                         -value new
2280                 lappend disable_on_lock \
2281                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2282
2283                 .mbar.commit add radiobutton \
2284                         -label [mc "Amend Last Commit"] \
2285                         -command do_select_commit_type \
2286                         -variable selected_commit_type \
2287                         -value amend
2288                 lappend disable_on_lock \
2289                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2290
2291                 .mbar.commit add separator
2292         }
2293
2294         .mbar.commit add command -label [mc Rescan] \
2295                 -command ui_do_rescan \
2296                 -accelerator F5
2297         lappend disable_on_lock \
2298                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2299
2300         .mbar.commit add command -label [mc "Stage To Commit"] \
2301                 -command do_add_selection \
2302                 -accelerator $M1T-T
2303         lappend disable_on_lock \
2304                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2305
2306         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2307                 -command do_add_all \
2308                 -accelerator $M1T-I
2309         lappend disable_on_lock \
2310                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2311
2312         .mbar.commit add command -label [mc "Unstage From Commit"] \
2313                 -command do_unstage_selection
2314         lappend disable_on_lock \
2315                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2316
2317         .mbar.commit add command -label [mc "Revert Changes"] \
2318                 -command do_revert_selection
2319         lappend disable_on_lock \
2320                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2321
2322         .mbar.commit add separator
2323
2324         .mbar.commit add command -label [mc "Show Less Context"] \
2325                 -command show_less_context \
2326                 -accelerator $M1T-\-
2327
2328         .mbar.commit add command -label [mc "Show More Context"] \
2329                 -command show_more_context \
2330                 -accelerator $M1T-=
2331
2332         .mbar.commit add separator
2333
2334         if {![is_enabled nocommit]} {
2335                 .mbar.commit add command -label [mc "Sign Off"] \
2336                         -command do_signoff \
2337                         -accelerator $M1T-S
2338         }
2339
2340         .mbar.commit add command -label [commit_btn_caption] \
2341                 -command do_commit \
2342                 -accelerator $M1T-Return
2343         lappend disable_on_lock \
2344                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2345 }
2346
2347 # -- Merge Menu
2348 #
2349 if {[is_enabled branch]} {
2350         menu .mbar.merge
2351         .mbar.merge add command -label [mc "Local Merge..."] \
2352                 -command merge::dialog \
2353                 -accelerator $M1T-M
2354         lappend disable_on_lock \
2355                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2356         .mbar.merge add command -label [mc "Abort Merge..."] \
2357                 -command merge::reset_hard
2358         lappend disable_on_lock \
2359                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2360 }
2361
2362 # -- Transport Menu
2363 #
2364 if {[is_enabled transport]} {
2365         menu .mbar.remote
2366
2367         .mbar.remote add command \
2368                 -label [mc "Push..."] \
2369                 -command do_push_anywhere \
2370                 -accelerator $M1T-P
2371         .mbar.remote add command \
2372                 -label [mc "Delete..."] \
2373                 -command remote_branch_delete::dialog
2374 }
2375
2376 if {[is_MacOSX]} {
2377         # -- Apple Menu (Mac OS X only)
2378         #
2379         .mbar add cascade -label Apple -menu .mbar.apple
2380         menu .mbar.apple
2381
2382         .mbar.apple add command -label [mc "About %s" [appname]] \
2383                 -command do_about
2384         .mbar.apple add separator
2385         .mbar.apple add command \
2386                 -label [mc "Preferences..."] \
2387                 -command do_options \
2388                 -accelerator $M1T-,
2389         bind . <$M1B-,> do_options
2390 } else {
2391         # -- Edit Menu
2392         #
2393         .mbar.edit add separator
2394         .mbar.edit add command -label [mc "Options..."] \
2395                 -command do_options
2396 }
2397
2398 # -- Help Menu
2399 #
2400 .mbar add cascade -label [mc Help] -menu .mbar.help
2401 menu .mbar.help
2402
2403 if {![is_MacOSX]} {
2404         .mbar.help add command -label [mc "About %s" [appname]] \
2405                 -command do_about
2406 }
2407
2408 set browser {}
2409 catch {set browser $repo_config(instaweb.browser)}
2410 set doc_path [file dirname [gitexec]]
2411 set doc_path [file join $doc_path Documentation index.html]
2412
2413 if {[is_Cygwin]} {
2414         set doc_path [exec cygpath --mixed $doc_path]
2415 }
2416
2417 if {$browser eq {}} {
2418         if {[is_MacOSX]} {
2419                 set browser open
2420         } elseif {[is_Cygwin]} {
2421                 set program_files [file dirname [exec cygpath --windir]]
2422                 set program_files [file join $program_files {Program Files}]
2423                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2424                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2425                 if {[file exists $firefox]} {
2426                         set browser $firefox
2427                 } elseif {[file exists $ie]} {
2428                         set browser $ie
2429                 }
2430                 unset program_files firefox ie
2431         }
2432 }
2433
2434 if {[file isfile $doc_path]} {
2435         set doc_url "file:$doc_path"
2436 } else {
2437         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2438 }
2439
2440 if {$browser ne {}} {
2441         .mbar.help add command -label [mc "Online Documentation"] \
2442                 -command [list exec $browser $doc_url &]
2443 }
2444 unset browser doc_path doc_url
2445
2446 # -- Standard bindings
2447 #
2448 wm protocol . WM_DELETE_WINDOW do_quit
2449 bind all <$M1B-Key-q> do_quit
2450 bind all <$M1B-Key-Q> do_quit
2451 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2452 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2453
2454 set subcommand_args {}
2455 proc usage {} {
2456         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2457         exit 1
2458 }
2459
2460 # -- Not a normal commit type invocation?  Do that instead!
2461 #
2462 switch -- $subcommand {
2463 browser -
2464 blame {
2465         if {$subcommand eq "blame"} {
2466                 set subcommand_args {[--line=<num>] rev? path}
2467         } else {
2468                 set subcommand_args {rev? path}
2469         }
2470         if {$argv eq {}} usage
2471         set head {}
2472         set path {}
2473         set jump_spec {}
2474         set is_path 0
2475         foreach a $argv {
2476                 if {$is_path || [file exists $_prefix$a]} {
2477                         if {$path ne {}} usage
2478                         set path $_prefix$a
2479                         break
2480                 } elseif {$a eq {--}} {
2481                         if {$path ne {}} {
2482                                 if {$head ne {}} usage
2483                                 set head $path
2484                                 set path {}
2485                         }
2486                         set is_path 1
2487                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2488                         if {$jump_spec ne {} || $head ne {}} usage
2489                         set jump_spec [list $lnum]
2490                 } elseif {$head eq {}} {
2491                         if {$head ne {}} usage
2492                         set head $a
2493                         set is_path 1
2494                 } else {
2495                         usage
2496                 }
2497         }
2498         unset is_path
2499
2500         if {$head ne {} && $path eq {}} {
2501                 set path $_prefix$head
2502                 set head {}
2503         }
2504
2505         if {$head eq {}} {
2506                 load_current_branch
2507         } else {
2508                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2509                         if {[catch {
2510                                         set head [git rev-parse --verify $head]
2511                                 } err]} {
2512                                 puts stderr $err
2513                                 exit 1
2514                         }
2515                 }
2516                 set current_branch $head
2517         }
2518
2519         switch -- $subcommand {
2520         browser {
2521                 if {$jump_spec ne {}} usage
2522                 if {$head eq {}} {
2523                         if {$path ne {} && [file isdirectory $path]} {
2524                                 set head $current_branch
2525                         } else {
2526                                 set head $path
2527                                 set path {}
2528                         }
2529                 }
2530                 browser::new $head $path
2531         }
2532         blame   {
2533                 if {$head eq {} && ![file exists $path]} {
2534                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2535                         exit 1
2536                 }
2537                 blame::new $head $path $jump_spec
2538         }
2539         }
2540         return
2541 }
2542 citool -
2543 gui {
2544         if {[llength $argv] != 0} {
2545                 puts -nonewline stderr "usage: $argv0"
2546                 if {$subcommand ne {gui}
2547                         && [file tail $argv0] ne "git-$subcommand"} {
2548                         puts -nonewline stderr " $subcommand"
2549                 }
2550                 puts stderr {}
2551                 exit 1
2552         }
2553         # fall through to setup UI for commits
2554 }
2555 default {
2556         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2557         exit 1
2558 }
2559 }
2560
2561 # -- Branch Control
2562 #
2563 frame .branch \
2564         -borderwidth 1 \
2565         -relief sunken
2566 label .branch.l1 \
2567         -text [mc "Current Branch:"] \
2568         -anchor w \
2569         -justify left
2570 label .branch.cb \
2571         -textvariable current_branch \
2572         -anchor w \
2573         -justify left
2574 pack .branch.l1 -side left
2575 pack .branch.cb -side left -fill x
2576 pack .branch -side top -fill x
2577
2578 # -- Main Window Layout
2579 #
2580 panedwindow .vpane -orient horizontal
2581 panedwindow .vpane.files -orient vertical
2582 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2583 pack .vpane -anchor n -side top -fill both -expand 1
2584
2585 # -- Index File List
2586 #
2587 frame .vpane.files.index -height 100 -width 200
2588 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2589         -background lightgreen -foreground black
2590 text $ui_index -background white -foreground black \
2591         -borderwidth 0 \
2592         -width 20 -height 10 \
2593         -wrap none \
2594         -cursor $cursor_ptr \
2595         -xscrollcommand {.vpane.files.index.sx set} \
2596         -yscrollcommand {.vpane.files.index.sy set} \
2597         -state disabled
2598 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2599 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2600 pack .vpane.files.index.title -side top -fill x
2601 pack .vpane.files.index.sx -side bottom -fill x
2602 pack .vpane.files.index.sy -side right -fill y
2603 pack $ui_index -side left -fill both -expand 1
2604
2605 # -- Working Directory File List
2606 #
2607 frame .vpane.files.workdir -height 100 -width 200
2608 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2609         -background lightsalmon -foreground black
2610 text $ui_workdir -background white -foreground black \
2611         -borderwidth 0 \
2612         -width 20 -height 10 \
2613         -wrap none \
2614         -cursor $cursor_ptr \
2615         -xscrollcommand {.vpane.files.workdir.sx set} \
2616         -yscrollcommand {.vpane.files.workdir.sy set} \
2617         -state disabled
2618 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2619 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2620 pack .vpane.files.workdir.title -side top -fill x
2621 pack .vpane.files.workdir.sx -side bottom -fill x
2622 pack .vpane.files.workdir.sy -side right -fill y
2623 pack $ui_workdir -side left -fill both -expand 1
2624
2625 .vpane.files add .vpane.files.workdir -sticky nsew
2626 .vpane.files add .vpane.files.index -sticky nsew
2627
2628 foreach i [list $ui_index $ui_workdir] {
2629         rmsel_tag $i
2630         $i tag conf in_diff -background [$i tag cget in_sel -background]
2631 }
2632 unset i
2633
2634 # -- Diff and Commit Area
2635 #
2636 frame .vpane.lower -height 300 -width 400
2637 frame .vpane.lower.commarea
2638 frame .vpane.lower.diff -relief sunken -borderwidth 1
2639 pack .vpane.lower.diff -fill both -expand 1
2640 pack .vpane.lower.commarea -side bottom -fill x
2641 .vpane add .vpane.lower -sticky nsew
2642
2643 # -- Commit Area Buttons
2644 #
2645 frame .vpane.lower.commarea.buttons
2646 label .vpane.lower.commarea.buttons.l -text {} \
2647         -anchor w \
2648         -justify left
2649 pack .vpane.lower.commarea.buttons.l -side top -fill x
2650 pack .vpane.lower.commarea.buttons -side left -fill y
2651
2652 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2653         -command ui_do_rescan
2654 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2655 lappend disable_on_lock \
2656         {.vpane.lower.commarea.buttons.rescan conf -state}
2657
2658 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2659         -command do_add_all
2660 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2661 lappend disable_on_lock \
2662         {.vpane.lower.commarea.buttons.incall conf -state}
2663
2664 if {![is_enabled nocommit]} {
2665         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2666                 -command do_signoff
2667         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2668 }
2669
2670 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2671         -command do_commit
2672 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2673 lappend disable_on_lock \
2674         {.vpane.lower.commarea.buttons.commit conf -state}
2675
2676 if {![is_enabled nocommit]} {
2677         button .vpane.lower.commarea.buttons.push -text [mc Push] \
2678                 -command do_push_anywhere
2679         pack .vpane.lower.commarea.buttons.push -side top -fill x
2680 }
2681
2682 # -- Commit Message Buffer
2683 #
2684 frame .vpane.lower.commarea.buffer
2685 frame .vpane.lower.commarea.buffer.header
2686 set ui_comm .vpane.lower.commarea.buffer.t
2687 set ui_coml .vpane.lower.commarea.buffer.header.l
2688
2689 if {![is_enabled nocommit]} {
2690         radiobutton .vpane.lower.commarea.buffer.header.new \
2691                 -text [mc "New Commit"] \
2692                 -command do_select_commit_type \
2693                 -variable selected_commit_type \
2694                 -value new
2695         lappend disable_on_lock \
2696                 [list .vpane.lower.commarea.buffer.header.new conf -state]
2697         radiobutton .vpane.lower.commarea.buffer.header.amend \
2698                 -text [mc "Amend Last Commit"] \
2699                 -command do_select_commit_type \
2700                 -variable selected_commit_type \
2701                 -value amend
2702         lappend disable_on_lock \
2703                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
2704 }
2705
2706 label $ui_coml \
2707         -anchor w \
2708         -justify left
2709 proc trace_commit_type {varname args} {
2710         global ui_coml commit_type
2711         switch -glob -- $commit_type {
2712         initial       {set txt [mc "Initial Commit Message:"]}
2713         amend         {set txt [mc "Amended Commit Message:"]}
2714         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2715         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2716         merge         {set txt [mc "Merge Commit Message:"]}
2717         *             {set txt [mc "Commit Message:"]}
2718         }
2719         $ui_coml conf -text $txt
2720 }
2721 trace add variable commit_type write trace_commit_type
2722 pack $ui_coml -side left -fill x
2723
2724 if {![is_enabled nocommit]} {
2725         pack .vpane.lower.commarea.buffer.header.amend -side right
2726         pack .vpane.lower.commarea.buffer.header.new -side right
2727 }
2728
2729 text $ui_comm -background white -foreground black \
2730         -borderwidth 1 \
2731         -undo true \
2732         -maxundo 20 \
2733         -autoseparators true \
2734         -relief sunken \
2735         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2736         -font font_diff \
2737         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2738 scrollbar .vpane.lower.commarea.buffer.sby \
2739         -command [list $ui_comm yview]
2740 pack .vpane.lower.commarea.buffer.header -side top -fill x
2741 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2742 pack $ui_comm -side left -fill y
2743 pack .vpane.lower.commarea.buffer -side left -fill y
2744
2745 # -- Commit Message Buffer Context Menu
2746 #
2747 set ctxm .vpane.lower.commarea.buffer.ctxm
2748 menu $ctxm -tearoff 0
2749 $ctxm add command \
2750         -label [mc Cut] \
2751         -command {tk_textCut $ui_comm}
2752 $ctxm add command \
2753         -label [mc Copy] \
2754         -command {tk_textCopy $ui_comm}
2755 $ctxm add command \
2756         -label [mc Paste] \
2757         -command {tk_textPaste $ui_comm}
2758 $ctxm add command \
2759         -label [mc Delete] \
2760         -command {$ui_comm delete sel.first sel.last}
2761 $ctxm add separator
2762 $ctxm add command \
2763         -label [mc "Select All"] \
2764         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2765 $ctxm add command \
2766         -label [mc "Copy All"] \
2767         -command {
2768                 $ui_comm tag add sel 0.0 end
2769                 tk_textCopy $ui_comm
2770                 $ui_comm tag remove sel 0.0 end
2771         }
2772 $ctxm add separator
2773 $ctxm add command \
2774         -label [mc "Sign Off"] \
2775         -command do_signoff
2776 set ui_comm_ctxm $ctxm
2777
2778 # -- Diff Header
2779 #
2780 proc trace_current_diff_path {varname args} {
2781         global current_diff_path diff_actions file_states
2782         if {$current_diff_path eq {}} {
2783                 set s {}
2784                 set f {}
2785                 set p {}
2786                 set o disabled
2787         } else {
2788                 set p $current_diff_path
2789                 set s [mapdesc [lindex $file_states($p) 0] $p]
2790                 set f [mc "File:"]
2791                 set p [escape_path $p]
2792                 set o normal
2793         }
2794
2795         .vpane.lower.diff.header.status configure -text $s
2796         .vpane.lower.diff.header.file configure -text $f
2797         .vpane.lower.diff.header.path configure -text $p
2798         foreach w $diff_actions {
2799                 uplevel #0 $w $o
2800         }
2801 }
2802 trace add variable current_diff_path write trace_current_diff_path
2803
2804 frame .vpane.lower.diff.header -background gold
2805 label .vpane.lower.diff.header.status \
2806         -background gold \
2807         -foreground black \
2808         -width $max_status_desc \
2809         -anchor w \
2810         -justify left
2811 label .vpane.lower.diff.header.file \
2812         -background gold \
2813         -foreground black \
2814         -anchor w \
2815         -justify left
2816 label .vpane.lower.diff.header.path \
2817         -background gold \
2818         -foreground black \
2819         -anchor w \
2820         -justify left
2821 pack .vpane.lower.diff.header.status -side left
2822 pack .vpane.lower.diff.header.file -side left
2823 pack .vpane.lower.diff.header.path -fill x
2824 set ctxm .vpane.lower.diff.header.ctxm
2825 menu $ctxm -tearoff 0
2826 $ctxm add command \
2827         -label [mc Copy] \
2828         -command {
2829                 clipboard clear
2830                 clipboard append \
2831                         -format STRING \
2832                         -type STRING \
2833                         -- $current_diff_path
2834         }
2835 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2836 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2837
2838 # -- Diff Body
2839 #
2840 frame .vpane.lower.diff.body
2841 set ui_diff .vpane.lower.diff.body.t
2842 text $ui_diff -background white -foreground black \
2843         -borderwidth 0 \
2844         -width 80 -height 15 -wrap none \
2845         -font font_diff \
2846         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2847         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2848         -state disabled
2849 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2850         -command [list $ui_diff xview]
2851 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2852         -command [list $ui_diff yview]
2853 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2854 pack .vpane.lower.diff.body.sby -side right -fill y
2855 pack $ui_diff -side left -fill both -expand 1
2856 pack .vpane.lower.diff.header -side top -fill x
2857 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2858
2859 $ui_diff tag conf d_cr -elide true
2860 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2861 $ui_diff tag conf d_+ -foreground {#00a000}
2862 $ui_diff tag conf d_- -foreground red
2863
2864 $ui_diff tag conf d_++ -foreground {#00a000}
2865 $ui_diff tag conf d_-- -foreground red
2866 $ui_diff tag conf d_+s \
2867         -foreground {#00a000} \
2868         -background {#e2effa}
2869 $ui_diff tag conf d_-s \
2870         -foreground red \
2871         -background {#e2effa}
2872 $ui_diff tag conf d_s+ \
2873         -foreground {#00a000} \
2874         -background ivory1
2875 $ui_diff tag conf d_s- \
2876         -foreground red \
2877         -background ivory1
2878
2879 $ui_diff tag conf d<<<<<<< \
2880         -foreground orange \
2881         -font font_diffbold
2882 $ui_diff tag conf d======= \
2883         -foreground orange \
2884         -font font_diffbold
2885 $ui_diff tag conf d>>>>>>> \
2886         -foreground orange \
2887         -font font_diffbold
2888
2889 $ui_diff tag raise sel
2890
2891 # -- Diff Body Context Menu
2892 #
2893
2894 proc create_common_diff_popup {ctxm} {
2895         $ctxm add command \
2896                 -label [mc "Show Less Context"] \
2897                 -command show_less_context
2898         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2899         $ctxm add command \
2900                 -label [mc "Show More Context"] \
2901                 -command show_more_context
2902         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2903         $ctxm add separator
2904         $ctxm add command \
2905                 -label [mc Refresh] \
2906                 -command reshow_diff
2907         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2908         $ctxm add command \
2909                 -label [mc Copy] \
2910                 -command {tk_textCopy $ui_diff}
2911         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2912         $ctxm add command \
2913                 -label [mc "Select All"] \
2914                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2915         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2916         $ctxm add command \
2917                 -label [mc "Copy All"] \
2918                 -command {
2919                         $ui_diff tag add sel 0.0 end
2920                         tk_textCopy $ui_diff
2921                         $ui_diff tag remove sel 0.0 end
2922                 }
2923         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2924         $ctxm add separator
2925         $ctxm add command \
2926                 -label [mc "Decrease Font Size"] \
2927                 -command {incr_font_size font_diff -1}
2928         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2929         $ctxm add command \
2930                 -label [mc "Increase Font Size"] \
2931                 -command {incr_font_size font_diff 1}
2932         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2933         $ctxm add separator
2934         $ctxm add command -label [mc "Options..."] \
2935                 -command do_options
2936 }
2937
2938 set ctxm .vpane.lower.diff.body.ctxm
2939 menu $ctxm -tearoff 0
2940 $ctxm add command \
2941         -label [mc "Apply/Reverse Hunk"] \
2942         -command {apply_hunk $cursorX $cursorY}
2943 set ui_diff_applyhunk [$ctxm index last]
2944 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2945 $ctxm add command \
2946         -label [mc "Apply/Reverse Line"] \
2947         -command {apply_line $cursorX $cursorY; do_rescan}
2948 set ui_diff_applyline [$ctxm index last]
2949 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2950 $ctxm add separator
2951 create_common_diff_popup $ctxm
2952
2953 set ctxmmg .vpane.lower.diff.body.ctxmmg
2954 menu $ctxmmg -tearoff 0
2955 $ctxmmg add command \
2956         -label [mc "Run Merge Tool"] \
2957         -command {merge_resolve_tool}
2958 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2959 $ctxmmg add separator
2960 $ctxmmg add command \
2961         -label [mc "Use Remote Version"] \
2962         -command {merge_resolve_one 3}
2963 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2964 $ctxmmg add command \
2965         -label [mc "Use Local Version"] \
2966         -command {merge_resolve_one 2}
2967 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2968 $ctxmmg add command \
2969         -label [mc "Revert To Base"] \
2970         -command {merge_resolve_one 1}
2971 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2972 $ctxmmg add separator
2973 $ctxmmg add command \
2974         -label [mc "Stage Working Copy"] \
2975         -command {merge_resolve_one 0}
2976 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2977 $ctxmmg add separator
2978 create_common_diff_popup $ctxmmg
2979
2980 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2981         global current_diff_path file_states
2982         set ::cursorX $x
2983         set ::cursorY $y
2984         if {[info exists file_states($current_diff_path)]} {
2985                 set state [lindex $file_states($current_diff_path) 0]
2986         } else {
2987                 set state {__}
2988         }
2989         if {[string first {U} $state] >= 0} {
2990                 tk_popup $ctxmmg $X $Y
2991         } else {
2992                 if {$::ui_index eq $::current_diff_side} {
2993                         set l [mc "Unstage Hunk From Commit"]
2994                         set t [mc "Unstage Line From Commit"]
2995                 } else {
2996                         set l [mc "Stage Hunk For Commit"]
2997                         set t [mc "Stage Line For Commit"]
2998                 }
2999                 if {$::is_3way_diff
3000                         || $current_diff_path eq {}
3001                         || {__} eq $state
3002                         || {_O} eq $state
3003                         || {_T} eq $state
3004                         || {T_} eq $state} {
3005                         set s disabled
3006                 } else {
3007                         set s normal
3008                 }
3009                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3010                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3011                 tk_popup $ctxm $X $Y
3012         }
3013 }
3014 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3015
3016 # -- Status Bar
3017 #
3018 set main_status [::status_bar::new .status]
3019 pack .status -anchor w -side bottom -fill x
3020 $main_status show [mc "Initializing..."]
3021
3022 # -- Load geometry
3023 #
3024 catch {
3025 set gm $repo_config(gui.geometry)
3026 wm geometry . [lindex $gm 0]
3027 .vpane sash place 0 \
3028         [lindex $gm 1] \
3029         [lindex [.vpane sash coord 0] 1]
3030 .vpane.files sash place 0 \
3031         [lindex [.vpane.files sash coord 0] 0] \
3032         [lindex $gm 2]
3033 unset gm
3034 }
3035
3036 # -- Key Bindings
3037 #
3038 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3039 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3040 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3041 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3042 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3043 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3044 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3045 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3046 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3047 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3048 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3049 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3050 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3051 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3052 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3053 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3054 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3055 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3056
3057 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3058 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3059 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3060 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3061 bind $ui_diff <$M1B-Key-v> {break}
3062 bind $ui_diff <$M1B-Key-V> {break}
3063 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3064 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3065 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3066 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3067 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3068 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3069 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3070 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3071 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3072 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3073 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3074 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3075 bind $ui_diff <Button-1>   {focus %W}
3076
3077 if {[is_enabled branch]} {
3078         bind . <$M1B-Key-n> branch_create::dialog
3079         bind . <$M1B-Key-N> branch_create::dialog
3080         bind . <$M1B-Key-o> branch_checkout::dialog
3081         bind . <$M1B-Key-O> branch_checkout::dialog
3082         bind . <$M1B-Key-m> merge::dialog
3083         bind . <$M1B-Key-M> merge::dialog
3084 }
3085 if {[is_enabled transport]} {
3086         bind . <$M1B-Key-p> do_push_anywhere
3087         bind . <$M1B-Key-P> do_push_anywhere
3088 }
3089
3090 bind .   <Key-F5>     ui_do_rescan
3091 bind .   <$M1B-Key-r> ui_do_rescan
3092 bind .   <$M1B-Key-R> ui_do_rescan
3093 bind .   <$M1B-Key-s> do_signoff
3094 bind .   <$M1B-Key-S> do_signoff
3095 bind .   <$M1B-Key-t> do_add_selection
3096 bind .   <$M1B-Key-T> do_add_selection
3097 bind .   <$M1B-Key-i> do_add_all
3098 bind .   <$M1B-Key-I> do_add_all
3099 bind .   <$M1B-Key-minus> {show_less_context;break}
3100 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3101 bind .   <$M1B-Key-equal> {show_more_context;break}
3102 bind .   <$M1B-Key-plus> {show_more_context;break}
3103 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3104 bind .   <$M1B-Key-Return> do_commit
3105 foreach i [list $ui_index $ui_workdir] {
3106         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3107         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3108         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3109 }
3110 unset i
3111
3112 set file_lists($ui_index) [list]
3113 set file_lists($ui_workdir) [list]
3114
3115 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3116 focus -force $ui_comm
3117
3118 # -- Warn the user about environmental problems.  Cygwin's Tcl
3119 #    does *not* pass its env array onto any processes it spawns.
3120 #    This means that git processes get none of our environment.
3121 #
3122 if {[is_Cygwin]} {
3123         set ignored_env 0
3124         set suggest_user {}
3125         set msg [mc "Possible environment issues exist.
3126
3127 The following environment variables are probably
3128 going to be ignored by any Git subprocess run
3129 by %s:
3130
3131 " [appname]]
3132         foreach name [array names env] {
3133                 switch -regexp -- $name {
3134                 {^GIT_INDEX_FILE$} -
3135                 {^GIT_OBJECT_DIRECTORY$} -
3136                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3137                 {^GIT_DIFF_OPTS$} -
3138                 {^GIT_EXTERNAL_DIFF$} -
3139                 {^GIT_PAGER$} -
3140                 {^GIT_TRACE$} -
3141                 {^GIT_CONFIG$} -
3142                 {^GIT_CONFIG_LOCAL$} -
3143                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3144                         append msg " - $name\n"
3145                         incr ignored_env
3146                 }
3147                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3148                         append msg " - $name\n"
3149                         incr ignored_env
3150                         set suggest_user $name
3151                 }
3152                 }
3153         }
3154         if {$ignored_env > 0} {
3155                 append msg [mc "
3156 This is due to a known issue with the
3157 Tcl binary distributed by Cygwin."]
3158
3159                 if {$suggest_user ne {}} {
3160                         append msg [mc "
3161
3162 A good replacement for %s
3163 is placing values for the user.name and
3164 user.email settings into your personal
3165 ~/.gitconfig file.
3166 " $suggest_user]
3167                 }
3168                 warn_popup $msg
3169         }
3170         unset ignored_env msg suggest_user name
3171 }
3172
3173 # -- Only initialize complex UI if we are going to stay running.
3174 #
3175 if {[is_enabled transport]} {
3176         load_all_remotes
3177
3178         set n [.mbar.remote index end]
3179         populate_push_menu
3180         populate_fetch_menu
3181         set n [expr {[.mbar.remote index end] - $n}]
3182         if {$n > 0} {
3183                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3184                 .mbar.remote insert $n separator
3185         }
3186         unset n
3187 }
3188
3189 if {[winfo exists $ui_comm]} {
3190         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3191
3192         # -- If both our backup and message files exist use the
3193         #    newer of the two files to initialize the buffer.
3194         #
3195         if {$GITGUI_BCK_exists} {
3196                 set m [gitdir GITGUI_MSG]
3197                 if {[file isfile $m]} {
3198                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3199                                 catch {file delete [gitdir GITGUI_MSG]}
3200                         } else {
3201                                 $ui_comm delete 0.0 end
3202                                 $ui_comm edit reset
3203                                 $ui_comm edit modified false
3204                                 catch {file delete [gitdir GITGUI_BCK]}
3205                                 set GITGUI_BCK_exists 0
3206                         }
3207                 }
3208                 unset m
3209         }
3210
3211         proc backup_commit_buffer {} {
3212                 global ui_comm GITGUI_BCK_exists
3213
3214                 set m [$ui_comm edit modified]
3215                 if {$m || $GITGUI_BCK_exists} {
3216                         set msg [string trim [$ui_comm get 0.0 end]]
3217                         regsub -all -line {[ \r\t]+$} $msg {} msg
3218
3219                         if {$msg eq {}} {
3220                                 if {$GITGUI_BCK_exists} {
3221                                         catch {file delete [gitdir GITGUI_BCK]}
3222                                         set GITGUI_BCK_exists 0
3223                                 }
3224                         } elseif {$m} {
3225                                 catch {
3226                                         set fd [open [gitdir GITGUI_BCK] w]
3227                                         puts -nonewline $fd $msg
3228                                         close $fd
3229                                         set GITGUI_BCK_exists 1
3230                                 }
3231                         }
3232
3233                         $ui_comm edit modified false
3234                 }
3235
3236                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3237         }
3238
3239         backup_commit_buffer
3240
3241         # -- If the user has aspell available we can drive it
3242         #    in pipe mode to spellcheck the commit message.
3243         #
3244         set spell_cmd [list |]
3245         set spell_dict [get_config gui.spellingdictionary]
3246         lappend spell_cmd aspell
3247         if {$spell_dict ne {}} {
3248                 lappend spell_cmd --master=$spell_dict
3249         }
3250         lappend spell_cmd --mode=none
3251         lappend spell_cmd --encoding=utf-8
3252         lappend spell_cmd pipe
3253         if {$spell_dict eq {none}
3254          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3255                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3256         } else {
3257                 set ui_comm_spell [spellcheck::init \
3258                         $spell_fd \
3259                         $ui_comm \
3260                         $ui_comm_ctxm \
3261                 ]
3262         }
3263         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3264 }
3265
3266 lock_index begin-read
3267 if {![winfo ismapped .]} {
3268         wm deiconify .
3269 }
3270 after 1 {
3271         if {[is_enabled initialamend]} {
3272                 force_amend
3273         } else {
3274                 do_rescan
3275         }
3276
3277         if {[is_enabled nocommitmsg]} {
3278                 $ui_comm configure -state disabled -background gray
3279         }
3280 }
3281 if {[is_enabled multicommit]} {
3282         after 1000 hint_gc
3283 }
3284 if {[is_enabled retcode]} {
3285         bind . <Destroy> {+terminate_me %W}
3286 }