?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
fast-import.c::validate_raw_date(): really validate the value
[git/kusma.git] / git-svn.perl
blob24bdbf5b813ddd6c7f242189b9bb22fbe7dfff11
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision $_repository
8 $_q $_authors $_authors_prog %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22 $Git::SVN::_minimize_url = 'unset';
23
24 $Git::SVN::Log::TZ = $ENV{TZ};
25 $ENV{TZ} = 'UTC';
26 $| = 1; # unbuffer STDOUT
27
28 sub fatal (@) { print STDERR "@_\n"; exit 1 }
29 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
30 require SVN::Ra;
31 require SVN::Delta;
32 if ($SVN::Core::VERSION lt '1.1.0') {
33 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
34 }
35 my $can_compress = eval { require Compress::Zlib; 1};
36 push @Git::SVN::Ra::ISA, 'SVN::Ra';
37 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
38 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
39 use Carp qw/croak/;
40 use Digest::MD5;
41 use IO::File qw//;
42 use File::Basename qw/dirname basename/;
43 use File::Path qw/mkpath/;
44 use File::Spec;
45 use File::Find;
46 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
47 use IPC::Open3;
48 use Git;
49
50 BEGIN {
51 # import functions from Git into our packages, en masse
52 no strict 'refs';
53 foreach (qw/command command_oneline command_noisy command_output_pipe
54 command_input_pipe command_close_pipe
55 command_bidi_pipe command_close_bidi_pipe/) {
56 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
57 Git::SVN::Migration Git::SVN::Log Git::SVN),
58 __PACKAGE__) {
59 *{"${package}::$_"} = \&{"Git::$_"};
60 }
61 }
62 }
63
64 my ($SVN);
65
66 $sha1 = qr/[a-f\d]{40}/;
67 $sha1_short = qr/[a-f\d]{4,40}/;
68 my ($_stdin, $_help, $_edit,
69 $_message, $_file, $_branch_dest,
70 $_template, $_shared,
71 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
72 $_merge, $_strategy, $_dry_run, $_local,
73 $_prefix, $_no_checkout, $_url, $_verbose,
74 $_git_format, $_commit_url, $_tag);
75 $Git::SVN::_follow_parent = 1;
76 $_q ||= 0;
77 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
78 'config-dir=s' => \$Git::SVN::Ra::config_dir,
79 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
80 'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
81 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
82 'authors-file|A=s' => \$_authors,
83 'authors-prog=s' => \$_authors_prog,
84 'repack:i' => \$Git::SVN::_repack,
85 'noMetadata' => \$Git::SVN::_no_metadata,
86 'useSvmProps' => \$Git::SVN::_use_svm_props,
87 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
88 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
89 'no-checkout' => \$_no_checkout,
90 'quiet|q+' => \$_q,
91 'repack-flags|repack-args|repack-opts=s' =>
92 \$Git::SVN::_repack_flags,
93 'use-log-author' => \$Git::SVN::_use_log_author,
94 'add-author-from' => \$Git::SVN::_add_author_from,
95 'localtime' => \$Git::SVN::_localtime,
96 %remote_opts );
97
98 my ($_trunk, @_tags, @_branches, $_stdlayout);
99 my %icv;
100 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
101 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
102 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
103 'stdlayout|s' => \$_stdlayout,
104 'minimize-url|m!' => \$Git::SVN::_minimize_url,
105 'no-metadata' => sub { $icv{noMetadata} = 1 },
106 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
107 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
108 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
109 %remote_opts );
110 my %cmt_opts = ( 'edit|e' => \$_edit,
111 'rmdir' => \$SVN::Git::Editor::_rmdir,
112 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
113 'l=i' => \$SVN::Git::Editor::_rename_limit,
114 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
115 );
116
117 my %cmd = (
118 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
119 { 'revision|r=s' => \$_revision,
120 'fetch-all|all' => \$_fetch_all,
121 'parent|p' => \$_fetch_parent,
122 %fc_opts } ],
123 clone => [ \&cmd_clone, "Initialize and fetch revisions",
124 { 'revision|r=s' => \$_revision,
125 %fc_opts, %init_opts } ],
126 init => [ \&cmd_init, "Initialize a repo for tracking" .
127 " (requires URL argument)",
128 \%init_opts ],
129 'multi-init' => [ \&cmd_multi_init,
130 "Deprecated alias for ".
131 "'$0 init -T<trunk> -b<branches> -t<tags>'",
132 \%init_opts ],
133 dcommit => [ \&cmd_dcommit,
134 'Commit several diffs to merge with upstream',
135 { 'merge|m|M' => \$_merge,
136 'strategy|s=s' => \$_strategy,
137 'verbose|v' => \$_verbose,
138 'dry-run|n' => \$_dry_run,
139 'fetch-all|all' => \$_fetch_all,
140 'commit-url=s' => \$_commit_url,
141 'revision|r=i' => \$_revision,
142 'no-rebase' => \$_no_rebase,
143 %cmt_opts, %fc_opts } ],
144 branch => [ \&cmd_branch,
145 'Create a branch in the SVN repository',
146 { 'message|m=s' => \$_message,
147 'destination|d=s' => \$_branch_dest,
148 'dry-run|n' => \$_dry_run,
149 'tag|t' => \$_tag } ],
150 tag => [ sub { $_tag = 1; cmd_branch(@_) },
151 'Create a tag in the SVN repository',
152 { 'message|m=s' => \$_message,
153 'destination|d=s' => \$_branch_dest,
154 'dry-run|n' => \$_dry_run } ],
155 'set-tree' => [ \&cmd_set_tree,
156 "Set an SVN repository to a git tree-ish",
157 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
158 'create-ignore' => [ \&cmd_create_ignore,
159 'Create a .gitignore per svn:ignore',
160 { 'revision|r=i' => \$_revision
161 } ],
162 'propget' => [ \&cmd_propget,
163 'Print the value of a property on a file or directory',
164 { 'revision|r=i' => \$_revision } ],
165 'proplist' => [ \&cmd_proplist,
166 'List all properties of a file or directory',
167 { 'revision|r=i' => \$_revision } ],
168 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
169 { 'revision|r=i' => \$_revision
170 } ],
171 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
172 { 'revision|r=i' => \$_revision
173 } ],
174 'multi-fetch' => [ \&cmd_multi_fetch,
175 "Deprecated alias for $0 fetch --all",
176 { 'revision|r=s' => \$_revision, %fc_opts } ],
177 'migrate' => [ sub { },
178 # no-op, we automatically run this anyways,
179 'Migrate configuration/metadata/layout from
180 previous versions of git-svn',
181 { 'minimize' => \$Git::SVN::Migration::_minimize,
182 %remote_opts } ],
183 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
184 { 'limit=i' => \$Git::SVN::Log::limit,
185 'revision|r=s' => \$_revision,
186 'verbose|v' => \$Git::SVN::Log::verbose,
187 'incremental' => \$Git::SVN::Log::incremental,
188 'oneline' => \$Git::SVN::Log::oneline,
189 'show-commit' => \$Git::SVN::Log::show_commit,
190 'non-recursive' => \$Git::SVN::Log::non_recursive,
191 'authors-file|A=s' => \$_authors,
192 'color' => \$Git::SVN::Log::color,
193 'pager=s' => \$Git::SVN::Log::pager
194 } ],
195 'find-rev' => [ \&cmd_find_rev,
196 "Translate between SVN revision numbers and tree-ish",
197 {} ],
198 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
199 { 'merge|m|M' => \$_merge,
200 'verbose|v' => \$_verbose,
201 'strategy|s=s' => \$_strategy,
202 'local|l' => \$_local,
203 'fetch-all|all' => \$_fetch_all,
204 'dry-run|n' => \$_dry_run,
205 %fc_opts } ],
206 'commit-diff' => [ \&cmd_commit_diff,
207 'Commit a diff between two trees',
208 { 'message|m=s' => \$_message,
209 'file|F=s' => \$_file,
210 'revision|r=s' => \$_revision,
211 %cmt_opts } ],
212 'info' => [ \&cmd_info,
213 "Show info about the latest SVN revision
214 on the current branch",
215 { 'url' => \$_url, } ],
216 'blame' => [ \&Git::SVN::Log::cmd_blame,
217 "Show what revision and author last modified each line of a file",
218 { 'git-format' => \$_git_format } ],
219 'reset' => [ \&cmd_reset,
220 "Undo fetches back to the specified SVN revision",
221 { 'revision|r=s' => \$_revision,
222 'parent|p' => \$_fetch_parent } ],
223 'gc' => [ \&cmd_gc,
224 "Compress unhandled.log files in .git/svn and remove " .
225 "index files in .git/svn",
226 {} ],
227 );
228
229 my $cmd;
230 for (my $i = 0; $i < @ARGV; $i++) {
231 if (defined $cmd{$ARGV[$i]}) {
232 $cmd = $ARGV[$i];
233 splice @ARGV, $i, 1;
234 last;
235 } elsif ($ARGV[$i] eq 'help') {
236 $cmd = $ARGV[$i+1];
237 usage(0);
238 }
239 };
240
241 # make sure we're always running at the top-level working directory
242 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
243 unless (-d $ENV{GIT_DIR}) {
244 if ($git_dir_user_set) {
245 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
246 "but it is not a directory\n";
247 }
248 my $git_dir = delete $ENV{GIT_DIR};
249 my $cdup = undef;
250 git_cmd_try {
251 $cdup = command_oneline(qw/rev-parse --show-cdup/);
252 $git_dir = '.' unless ($cdup);
253 chomp $cdup if ($cdup);
254 $cdup = "." unless ($cdup && length $cdup);
255 } "Already at toplevel, but $git_dir not found\n";
256 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
257 unless (-d $git_dir) {
258 die "$git_dir still not found after going to ",
259 "'$cdup'\n";
260 }
261 $ENV{GIT_DIR} = $git_dir;
262 }
263 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
264 }
265
266 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
267
268 read_repo_config(\%opts);
269 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
270 Getopt::Long::Configure('pass_through');
271 }
272 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
273 'minimize-connections' => \$Git::SVN::Migration::_minimize,
274 'id|i=s' => \$Git::SVN::default_ref_id,
275 'svn-remote|remote|R=s' => sub {
276 $Git::SVN::no_reuse_existing = 1;
277 $Git::SVN::default_repo_id = $_[1] });
278 exit 1 if (!$rv && $cmd && $cmd ne 'log');
279
280 usage(0) if $_help;
281 version() if $_version;
282 usage(1) unless defined $cmd;
283 load_authors() if $_authors;
284 if (defined $_authors_prog) {
285 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
286 }
287
288 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
289 Git::SVN::Migration::migration_check();
290 }
291 Git::SVN::init_vars();
292 eval {
293 Git::SVN::verify_remotes_sanity();
294 $cmd{$cmd}->[0]->(@ARGV);
295 };
296 fatal $@ if $@;
297 post_fetch_checkout();
298 exit 0;
299
300 ####################### primary functions ######################
301 sub usage {
302 my $exit = shift || 0;
303 my $fd = $exit ? \*STDERR : \*STDOUT;
304 print $fd <<"";
305 git-svn - bidirectional operations between a single Subversion tree and git
306 Usage: git svn <command> [options] [arguments]\n
307
308 print $fd "Available commands:\n" unless $cmd;
309
310 foreach (sort keys %cmd) {
311 next if $cmd && $cmd ne $_;
312 next if /^multi-/; # don't show deprecated commands
313 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
314 foreach (sort keys %{$cmd{$_}->[2]}) {
315 # mixed-case options are for .git/config only
316 next if /[A-Z]/ && /^[a-z]+$/i;
317 # prints out arguments as they should be passed:
318 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
319 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
320 "--$_" : "-$_" }
321 split /\|/,$_)," $x\n";
322 }
323 }
324 print $fd <<"";
325 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
326 arbitrary identifier if you're tracking multiple SVN branches/repositories in
327 one git repository and want to keep them separate. See git-svn(1) for more
328 information.
329
330 exit $exit;
331 }
332
333 sub version {
334 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
335 exit 0;
336 }
337
338 sub do_git_init_db {
339 unless (-d $ENV{GIT_DIR}) {
340 my @init_db = ('init');
341 push @init_db, "--template=$_template" if defined $_template;
342 if (defined $_shared) {
343 if ($_shared =~ /[a-z]/) {
344 push @init_db, "--shared=$_shared";
345 } else {
346 push @init_db, "--shared";
347 }
348 }
349 command_noisy(@init_db);
350 $_repository = Git->repository(Repository => ".git");
351 }
352 command_noisy('config', 'core.autocrlf', 'false');
353 my $set;
354 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
355 foreach my $i (keys %icv) {
356 die "'$set' and '$i' cannot both be set\n" if $set;
357 next unless defined $icv{$i};
358 command_noisy('config', "$pfx.$i", $icv{$i});
359 $set = $i;
360 }
361 my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
362 command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
363 if defined $$ignore_regex;
364 }
365
366 sub init_subdir {
367 my $repo_path = shift or return;
368 mkpath([$repo_path]) unless -d $repo_path;
369 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
370 $ENV{GIT_DIR} = '.git';
371 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
372 }
373
374 sub cmd_clone {
375 my ($url, $path) = @_;
376 if (!defined $path &&
377 (defined $_trunk || @_branches || @_tags ||
378 defined $_stdlayout) &&
379 $url !~ m#^[a-z\+]+://#) {
380 $path = $url;
381 }
382 $path = basename($url) if !defined $path || !length $path;
383 cmd_init($url, $path);
384 Git::SVN::fetch_all($Git::SVN::default_repo_id);
385 command_oneline('config', 'svn.authorsfile', $_authors) if $_authors;
386 }
387
388 sub cmd_init {
389 if (defined $_stdlayout) {
390 $_trunk = 'trunk' if (!defined $_trunk);
391 @_tags = 'tags' if (! @_tags);
392 @_branches = 'branches' if (! @_branches);
393 }
394 if (defined $_trunk || @_branches || @_tags) {
395 return cmd_multi_init(@_);
396 }
397 my $url = shift or die "SVN repository location required ",
398 "as a command-line argument\n";
399 $url = canonicalize_url($url);
400 init_subdir(@_);
401 do_git_init_db();
402
403 if ($Git::SVN::_minimize_url eq 'unset') {
404 $Git::SVN::_minimize_url = 0;
405 }
406
407 Git::SVN->init($url);
408 }
409
410 sub cmd_fetch {
411 if (grep /^\d+=./, @_) {
412 die "'<rev>=<commit>' fetch arguments are ",
413 "no longer supported.\n";
414 }
415 my ($remote) = @_;
416 if (@_ > 1) {
417 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
418 }
419 if ($_fetch_parent) {
420 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
421 unless ($gs) {
422 die "Unable to determine upstream SVN information from ",
423 "working tree history\n";
424 }
425 # just fetch, don't checkout.
426 $_no_checkout = 'true';
427 $_fetch_all ? $gs->fetch_all : $gs->fetch;
428 } elsif ($_fetch_all) {
429 cmd_multi_fetch();
430 } else {
431 $remote ||= $Git::SVN::default_repo_id;
432 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
433 }
434 }
435
436 sub cmd_set_tree {
437 my (@commits) = @_;
438 if ($_stdin || !@commits) {
439 print "Reading from stdin...\n";
440 @commits = ();
441 while (<STDIN>) {
442 if (/\b($sha1_short)\b/o) {
443 unshift @commits, $1;
444 }
445 }
446 }
447 my @revs;
448 foreach my $c (@commits) {
449 my @tmp = command('rev-parse',$c);
450 if (scalar @tmp == 1) {
451 push @revs, $tmp[0];
452 } elsif (scalar @tmp > 1) {
453 push @revs, reverse(command('rev-list',@tmp));
454 } else {
455 fatal "Failed to rev-parse $c";
456 }
457 }
458 my $gs = Git::SVN->new;
459 my ($r_last, $cmt_last) = $gs->last_rev_commit;
460 $gs->fetch;
461 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
462 fatal "There are new revisions that were fetched ",
463 "and need to be merged (or acknowledged) ",
464 "before committing.\nlast rev: $r_last\n",
465 " current: $gs->{last_rev}";
466 }
467 $gs->set_tree($_) foreach @revs;
468 print "Done committing ",scalar @revs," revisions to SVN\n";
469 unlink $gs->{index};
470 }
471
472 sub cmd_dcommit {
473 my $head = shift;
474 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
475 'Cannot dcommit with a dirty index. Commit your changes first, '
476 . "or stash them with `git stash'.\n";
477 $head ||= 'HEAD';
478
479 my $old_head;
480 if ($head ne 'HEAD') {
481 $old_head = eval {
482 command_oneline([qw/symbolic-ref -q HEAD/])
483 };
484 if ($old_head) {
485 $old_head =~ s{^refs/heads/}{};
486 } else {
487 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
488 }
489 command(['checkout', $head], STDERR => 0);
490 }
491
492 my @refs;
493 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
494 unless ($gs) {
495 die "Unable to determine upstream SVN information from ",
496 "$head history.\nPerhaps the repository is empty.";
497 }
498
499 if (defined $_commit_url) {
500 $url = $_commit_url;
501 } else {
502 $url = eval { command_oneline('config', '--get',
503 "svn-remote.$gs->{repo_id}.commiturl") };
504 if (!$url) {
505 $url = $gs->full_url
506 }
507 }
508
509 my $last_rev = $_revision if defined $_revision;
510 if ($url) {
511 print "Committing to $url ...\n";
512 }
513 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
514 if ($_no_rebase && scalar(@$linear_refs) > 1) {
515 warn "Attempting to commit more than one change while ",
516 "--no-rebase is enabled.\n",
517 "If these changes depend on each other, re-running ",
518 "without --no-rebase may be required."
519 }
520 my $expect_url = $url;
521 Git::SVN::remove_username($expect_url);
522 while (1) {
523 my $d = shift @$linear_refs or last;
524 unless (defined $last_rev) {
525 (undef, $last_rev, undef) = cmt_metadata("$d~1");
526 unless (defined $last_rev) {
527 fatal "Unable to extract revision information ",
528 "from commit $d~1";
529 }
530 }
531 if ($_dry_run) {
532 print "diff-tree $d~1 $d\n";
533 } else {
534 my $cmt_rev;
535 my %ed_opts = ( r => $last_rev,
536 log => get_commit_entry($d)->{log},
537 ra => Git::SVN::Ra->new($url),
538 config => SVN::Core::config_get_config(
539 $Git::SVN::Ra::config_dir
540 ),
541 tree_a => "$d~1",
542 tree_b => $d,
543 editor_cb => sub {
544 print "Committed r$_[0]\n";
545 $cmt_rev = $_[0];
546 },
547 svn_path => '');
548 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
549 print "No changes\n$d~1 == $d\n";
550 } elsif ($parents->{$d} && @{$parents->{$d}}) {
551 $gs->{inject_parents_dcommit}->{$cmt_rev} =
552 $parents->{$d};
553 }
554 $_fetch_all ? $gs->fetch_all : $gs->fetch;
555 $last_rev = $cmt_rev;
556 next if $_no_rebase;
557
558 # we always want to rebase against the current HEAD,
559 # not any head that was passed to us
560 my @diff = command('diff-tree', $d,
561 $gs->refname, '--');
562 my @finish;
563 if (@diff) {
564 @finish = rebase_cmd();
565 print STDERR "W: $d and ", $gs->refname,
566 " differ, using @finish:\n",
567 join("\n", @diff), "\n";
568 } else {
569 print "No changes between current HEAD and ",
570 $gs->refname,
571 "\nResetting to the latest ",
572 $gs->refname, "\n";
573 @finish = qw/reset --mixed/;
574 }
575 command_noisy(@finish, $gs->refname);
576 if (@diff) {
577 @refs = ();
578 my ($url_, $rev_, $uuid_, $gs_) =
579 working_head_info('HEAD', \@refs);
580 my ($linear_refs_, $parents_) =
581 linearize_history($gs_, \@refs);
582 if (scalar(@$linear_refs) !=
583 scalar(@$linear_refs_)) {
584 fatal "# of revisions changed ",
585 "\nbefore:\n",
586 join("\n", @$linear_refs),
587 "\n\nafter:\n",
588 join("\n", @$linear_refs_), "\n",
589 'If you are attempting to commit ',
590 "merges, try running:\n\t",
591 'git rebase --interactive',
592 '--preserve-merges ',
593 $gs->refname,
594 "\nBefore dcommitting";
595 }
596 if ($url_ ne $expect_url) {
597 fatal "URL mismatch after rebase: ",
598 "$url_ != $expect_url";
599 }
600 if ($uuid_ ne $uuid) {
601 fatal "uuid mismatch after rebase: ",
602 "$uuid_ != $uuid";
603 }
604 # remap parents
605 my (%p, @l, $i);
606 for ($i = 0; $i < scalar @$linear_refs; $i++) {
607 my $new = $linear_refs_->[$i] or next;
608 $p{$new} =
609 $parents->{$linear_refs->[$i]};
610 push @l, $new;
611 }
612 $parents = \%p;
613 $linear_refs = \@l;
614 }
615 }
616 }
617
618 if ($old_head) {
619 my $new_head = command_oneline(qw/rev-parse HEAD/);
620 my $new_is_symbolic = eval {
621 command_oneline(qw/symbolic-ref -q HEAD/);
622 };
623 if ($new_is_symbolic) {
624 print "dcommitted the branch ", $head, "\n";
625 } else {
626 print "dcommitted on a detached HEAD because you gave ",
627 "a revision argument.\n",
628 "The rewritten commit is: ", $new_head, "\n";
629 }
630 command(['checkout', $old_head], STDERR => 0);
631 }
632
633 unlink $gs->{index};
634 }
635
636 sub cmd_branch {
637 my ($branch_name, $head) = @_;
638
639 unless (defined $branch_name && length $branch_name) {
640 die(($_tag ? "tag" : "branch") . " name required\n");
641 }
642 $head ||= 'HEAD';
643
644 my ($src, $rev, undef, $gs) = working_head_info($head);
645
646 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
647 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
648 my $glob;
649 if ($#{$allglobs} == 0) {
650 $glob = $allglobs->[0];
651 } else {
652 unless(defined $_branch_dest) {
653 die "Multiple ",
654 $_tag ? "tag" : "branch",
655 " paths defined for Subversion repository.\n",
656 "You must specify where you want to create the ",
657 $_tag ? "tag" : "branch",
658 " with the --destination argument.\n";
659 }
660 foreach my $g (@{$allglobs}) {
661 # SVN::Git::Editor could probably be moved to Git.pm..
662 my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
663 if ($_branch_dest =~ /$re/) {
664 $glob = $g;
665 last;
666 }
667 }
668 unless (defined $glob) {
669 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
670 foreach my $g (@{$allglobs}) {
671 $g->{path}->{left} =~ /$dest_re/ or next;
672 if (defined $glob) {
673 die "Ambiguous destination: ",
674 $_branch_dest, "\nmatches both '",
675 $glob->{path}->{left}, "' and '",
676 $g->{path}->{left}, "'\n";
677 }
678 $glob = $g;
679 }
680 unless (defined $glob) {
681 die "Unknown ",
682 $_tag ? "tag" : "branch",
683 " destination $_branch_dest\n";
684 }
685 }
686 }
687 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
688 my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
689
690 my $ctx = SVN::Client->new(
691 auth => Git::SVN::Ra::_auth_providers(),
692 log_msg => sub {
693 ${ $_[0] } = defined $_message
694 ? $_message
695 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
696 . $branch_name;
697 },
698 );
699
700 eval {
701 $ctx->ls($dst, 'HEAD', 0);
702 } and die "branch ${branch_name} already exists\n";
703
704 print "Copying ${src} at r${rev} to ${dst}...\n";
705 $ctx->copy($src, $rev, $dst)
706 unless $_dry_run;
707
708 $gs->fetch_all;
709 }
710
711 sub cmd_find_rev {
712 my $revision_or_hash = shift or die "SVN or git revision required ",
713 "as a command-line argument\n";
714 my $result;
715 if ($revision_or_hash =~ /^r\d+$/) {
716 my $head = shift;
717 $head ||= 'HEAD';
718 my @refs;
719 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
720 unless ($gs) {
721 die "Unable to determine upstream SVN information from ",
722 "$head history\n";
723 }
724 my $desired_revision = substr($revision_or_hash, 1);
725 $result = $gs->rev_map_get($desired_revision, $uuid);
726 } else {
727 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
728 $result = $rev;
729 }
730 print "$result\n" if $result;
731 }
732
733 sub cmd_rebase {
734 command_noisy(qw/update-index --refresh/);
735 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
736 unless ($gs) {
737 die "Unable to determine upstream SVN information from ",
738 "working tree history\n";
739 }
740 if ($_dry_run) {
741 print "Remote Branch: " . $gs->refname . "\n";
742 print "SVN URL: " . $url . "\n";
743 return;
744 }
745 if (command(qw/diff-index HEAD --/)) {
746 print STDERR "Cannot rebase with uncommited changes:\n";
747 command_noisy('status');
748 exit 1;
749 }
750 unless ($_local) {
751 # rebase will checkout for us, so no need to do it explicitly
752 $_no_checkout = 'true';
753 $_fetch_all ? $gs->fetch_all : $gs->fetch;
754 }
755 command_noisy(rebase_cmd(), $gs->refname);
756 }
757
758 sub cmd_show_ignore {
759 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
760 $gs ||= Git::SVN->new;
761 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
762 $gs->prop_walk($gs->{path}, $r, sub {
763 my ($gs, $path, $props) = @_;
764 print STDOUT "\n# $path\n";
765 my $s = $props->{'svn:ignore'} or return;
766 $s =~ s/[\r\n]+/\n/g;
767 chomp $s;
768 $s =~ s#^#$path#gm;
769 print STDOUT "$s\n";
770 });
771 }
772
773 sub cmd_show_externals {
774 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
775 $gs ||= Git::SVN->new;
776 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
777 $gs->prop_walk($gs->{path}, $r, sub {
778 my ($gs, $path, $props) = @_;
779 print STDOUT "\n# $path\n";
780 my $s = $props->{'svn:externals'} or return;
781 $s =~ s/[\r\n]+/\n/g;
782 chomp $s;
783 $s =~ s#^#$path#gm;
784 print STDOUT "$s\n";
785 });
786 }
787
788 sub cmd_create_ignore {
789 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
790 $gs ||= Git::SVN->new;
791 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
792 $gs->prop_walk($gs->{path}, $r, sub {
793 my ($gs, $path, $props) = @_;
794 # $path is of the form /path/to/dir/
795 $path = '.' . $path;
796 # SVN can have attributes on empty directories,
797 # which git won't track
798 mkpath([$path]) unless -d $path;
799 my $ignore = $path . '.gitignore';
800 my $s = $props->{'svn:ignore'} or return;
801 open(GITIGNORE, '>', $ignore)
802 or fatal("Failed to open `$ignore' for writing: $!");
803 $s =~ s/[\r\n]+/\n/g;
804 chomp $s;
805 # Prefix all patterns so that the ignore doesn't apply
806 # to sub-directories.
807 $s =~ s#^#/#gm;
808 print GITIGNORE "$s\n";
809 close(GITIGNORE)
810 or fatal("Failed to close `$ignore': $!");
811 command_noisy('add', '-f', $ignore);
812 });
813 }
814
815 sub canonicalize_path {
816 my ($path) = @_;
817 my $dot_slash_added = 0;
818 if (substr($path, 0, 1) ne "/") {
819 $path = "./" . $path;
820 $dot_slash_added = 1;
821 }
822 # File::Spec->canonpath doesn't collapse x/../y into y (for a
823 # good reason), so let's do this manually.
824 $path =~ s#/+#/#g;
825 $path =~ s#/\.(?:/|$)#/#g;
826 $path =~ s#/[^/]+/\.\.##g;
827 $path =~ s#/$##g;
828 $path =~ s#^\./## if $dot_slash_added;
829 $path =~ s#^/##;
830 $path =~ s#^\.$##;
831 return $path;
832 }
833
834 sub canonicalize_url {
835 my ($url) = @_;
836 $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
837 return $url;
838 }
839
840 # get_svnprops(PATH)
841 # ------------------
842 # Helper for cmd_propget and cmd_proplist below.
843 sub get_svnprops {
844 my $path = shift;
845 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
846 $gs ||= Git::SVN->new;
847
848 # prefix THE PATH by the sub-directory from which the user
849 # invoked us.
850 $path = $cmd_dir_prefix . $path;
851 fatal("No such file or directory: $path") unless -e $path;
852 my $is_dir = -d $path ? 1 : 0;
853 $path = $gs->{path} . '/' . $path;
854
855 # canonicalize the path (otherwise libsvn will abort or fail to
856 # find the file)
857 $path = canonicalize_path($path);
858
859 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
860 my $props;
861 if ($is_dir) {
862 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
863 }
864 else {
865 (undef, $props) = $gs->ra->get_file($path, $r, undef);
866 }
867 return $props;
868 }
869
870 # cmd_propget (PROP, PATH)
871 # ------------------------
872 # Print the SVN property PROP for PATH.
873 sub cmd_propget {
874 my ($prop, $path) = @_;
875 $path = '.' if not defined $path;
876 usage(1) if not defined $prop;
877 my $props = get_svnprops($path);
878 if (not defined $props->{$prop}) {
879 fatal("`$path' does not have a `$prop' SVN property.");
880 }
881 print $props->{$prop} . "\n";
882 }
883
884 # cmd_proplist (PATH)
885 # -------------------
886 # Print the list of SVN properties for PATH.
887 sub cmd_proplist {
888 my $path = shift;
889 $path = '.' if not defined $path;
890 my $props = get_svnprops($path);
891 print "Properties on '$path':\n";
892 foreach (sort keys %{$props}) {
893 print " $_\n";
894 }
895 }
896
897 sub cmd_multi_init {
898 my $url = shift;
899 unless (defined $_trunk || @_branches || @_tags) {
900 usage(1);
901 }
902
903 $_prefix = '' unless defined $_prefix;
904 if (defined $url) {
905 $url = canonicalize_url($url);
906 init_subdir(@_);
907 }
908 do_git_init_db();
909 if (defined $_trunk) {
910 my $trunk_ref = $_prefix . 'trunk';
911 # try both old-style and new-style lookups:
912 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
913 unless ($gs_trunk) {
914 my ($trunk_url, $trunk_path) =
915 complete_svn_url($url, $_trunk);
916 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
917 undef, $trunk_ref);
918 }
919 }
920 return unless @_branches || @_tags;
921 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
922 foreach my $path (@_branches) {
923 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
924 }
925 foreach my $path (@_tags) {
926 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
927 }
928 }
929
930 sub cmd_multi_fetch {
931 my $remotes = Git::SVN::read_all_remotes();
932 foreach my $repo_id (sort keys %$remotes) {
933 if ($remotes->{$repo_id}->{url}) {
934 Git::SVN::fetch_all($repo_id, $remotes);
935 }
936 }
937 }
938
939 # this command is special because it requires no metadata
940 sub cmd_commit_diff {
941 my ($ta, $tb, $url) = @_;
942 my $usage = "Usage: $0 commit-diff -r<revision> ".
943 "<tree-ish> <tree-ish> [<URL>]";
944 fatal($usage) if (!defined $ta || !defined $tb);
945 my $svn_path = '';
946 if (!defined $url) {
947 my $gs = eval { Git::SVN->new };
948 if (!$gs) {
949 fatal("Needed URL or usable git-svn --id in ",
950 "the command-line\n", $usage);
951 }
952 $url = $gs->{url};
953 $svn_path = $gs->{path};
954 }
955 unless (defined $_revision) {
956 fatal("-r|--revision is a required argument\n", $usage);
957 }
958 if (defined $_message && defined $_file) {
959 fatal("Both --message/-m and --file/-F specified ",
960 "for the commit message.\n",
961 "I have no idea what you mean");
962 }
963 if (defined $_file) {
964 $_message = file_to_s($_file);
965 } else {
966 $_message ||= get_commit_entry($tb)->{log};
967 }
968 my $ra ||= Git::SVN::Ra->new($url);
969 my $r = $_revision;
970 if ($r eq 'HEAD') {
971 $r = $ra->get_latest_revnum;
972 } elsif ($r !~ /^\d+$/) {
973 die "revision argument: $r not understood by git-svn\n";
974 }
975 my %ed_opts = ( r => $r,
976 log => $_message,
977 ra => $ra,
978 tree_a => $ta,
979 tree_b => $tb,
980 editor_cb => sub { print "Committed r$_[0]\n" },
981 svn_path => $svn_path );
982 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
983 print "No changes\n$ta == $tb\n";
984 }
985 }
986
987 sub escape_uri_only {
988 my ($uri) = @_;
989 my @tmp;
990 foreach (split m{/}, $uri) {
991 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
992 push @tmp, $_;
993 }
994 join('/', @tmp);
995 }
996
997 sub escape_url {
998 my ($url) = @_;
999 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1000 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1001 $url = "$scheme://$domain$uri";
1002 }
1003 $url;
1004 }
1005
1006 sub cmd_info {
1007 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1008 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1009 if (exists $_[1]) {
1010 die "Too many arguments specified\n";
1011 }
1012
1013 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1014
1015 if (!$file_type && !$diff_status) {
1016 print STDERR "svn: '$path' is not under version control\n";
1017 exit 1;
1018 }
1019
1020 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1021 unless ($gs) {
1022 die "Unable to determine upstream SVN information from ",
1023 "working tree history\n";
1024 }
1025
1026 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1027 $path = "." if $path eq "";
1028
1029 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1030
1031 if ($_url) {
1032 print escape_url($full_url), "\n";
1033 return;
1034 }
1035
1036 my $result = "Path: $path\n";
1037 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1038 $result .= "URL: " . escape_url($full_url) . "\n";
1039
1040 eval {
1041 my $repos_root = $gs->repos_root;
1042 Git::SVN::remove_username($repos_root);
1043 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1044 };
1045 if ($@) {
1046 $result .= "Repository Root: (offline)\n";
1047 }
1048 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1049 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1050 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1051
1052 $result .= "Node Kind: " .
1053 ($file_type eq "dir" ? "directory" : "file") . "\n";
1054
1055 my $schedule = $diff_status eq "A"
1056 ? "add"
1057 : ($diff_status eq "D" ? "delete" : "normal");
1058 $result .= "Schedule: $schedule\n";
1059
1060 if ($diff_status eq "A") {
1061 print $result, "\n";
1062 return;
1063 }
1064
1065 my ($lc_author, $lc_rev, $lc_date_utc);
1066 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1067 my $log = command_output_pipe(@args);
1068 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1069 while (<$log>) {
1070 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1071 $lc_author = $1;
1072 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1073 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1074 (undef, $lc_rev, undef) = ::extract_metadata($1);
1075 }
1076 }
1077 close $log;
1078
1079 Git::SVN::Log::set_local_timezone();
1080
1081 $result .= "Last Changed Author: $lc_author\n";
1082 $result .= "Last Changed Rev: $lc_rev\n";
1083 $result .= "Last Changed Date: " .
1084 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1085
1086 if ($file_type ne "dir") {
1087 my $text_last_updated_date =
1088 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1089 $result .=
1090 "Text Last Updated: " .
1091 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1092 "\n";
1093 my $checksum;
1094 if ($diff_status eq "D") {
1095 my ($fh, $ctx) =
1096 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1097 if ($file_type eq "link") {
1098 my $file_name = <$fh>;
1099 $checksum = md5sum("link $file_name");
1100 } else {
1101 $checksum = md5sum($fh);
1102 }
1103 command_close_pipe($fh, $ctx);
1104 } elsif ($file_type eq "link") {
1105 my $file_name =
1106 command(qw(cat-file blob), "HEAD:$path");
1107 $checksum =
1108 md5sum("link " . $file_name);
1109 } else {
1110 open FILE, "<", $path or die $!;
1111 $checksum = md5sum(\*FILE);
1112 close FILE or die $!;
1113 }
1114 $result .= "Checksum: " . $checksum . "\n";
1115 }
1116
1117 print $result, "\n";
1118 }
1119
1120 sub cmd_reset {
1121 my $target = shift || $_revision or die "SVN revision required\n";
1122 $target = $1 if $target =~ /^r(\d+)$/;
1123 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1124 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1125 unless ($gs) {
1126 die "Unable to determine upstream SVN information from ".
1127 "history\n";
1128 }
1129 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1130 $gs->rev_map_set($r, $c, 'reset', $uuid);
1131 print "r$r = $c ($gs->{ref_id})\n";
1132 }
1133
1134 sub cmd_gc {
1135 if (!$can_compress) {
1136 warn "Compress::Zlib could not be found; unhandled.log " .
1137 "files will not be compressed.\n";
1138 }
1139 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1140 }
1141
1142 ########################### utility functions #########################
1143
1144 sub rebase_cmd {
1145 my @cmd = qw/rebase/;
1146 push @cmd, '-v' if $_verbose;
1147 push @cmd, qw/--merge/ if $_merge;
1148 push @cmd, "--strategy=$_strategy" if $_strategy;
1149 @cmd;
1150 }
1151
1152 sub post_fetch_checkout {
1153 return if $_no_checkout;
1154 my $gs = $Git::SVN::_head or return;
1155 return if verify_ref('refs/heads/master^0');
1156
1157 my $valid_head = verify_ref('HEAD^0');
1158 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1159 return if ($valid_head || !verify_ref('HEAD^0'));
1160
1161 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1162 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1163 return if -f $index;
1164
1165 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1166 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1167 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1168 print STDERR "Checked out HEAD:\n ",
1169 $gs->full_url, " r", $gs->last_rev, "\n";
1170 }
1171
1172 sub complete_svn_url {
1173 my ($url, $path) = @_;
1174 $path =~ s#/+$##;
1175 if ($path !~ m#^[a-z\+]+://#) {
1176 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1177 fatal("E: '$path' is not a complete URL ",
1178 "and a separate URL is not specified");
1179 }
1180 return ($url, $path);
1181 }
1182 return ($path, '');
1183 }
1184
1185 sub complete_url_ls_init {
1186 my ($ra, $repo_path, $switch, $pfx) = @_;
1187 unless ($repo_path) {
1188 print STDERR "W: $switch not specified\n";
1189 return;
1190 }
1191 $repo_path =~ s#/+$##;
1192 if ($repo_path =~ m#^[a-z\+]+://#) {
1193 $ra = Git::SVN::Ra->new($repo_path);
1194 $repo_path = '';
1195 } else {
1196 $repo_path =~ s#^/+##;
1197 unless ($ra) {
1198 fatal("E: '$repo_path' is not a complete URL ",
1199 "and a separate URL is not specified");
1200 }
1201 }
1202 my $url = $ra->{url};
1203 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1204 my $k = "svn-remote.$gs->{repo_id}.url";
1205 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1206 if ($orig_url && ($orig_url ne $gs->{url})) {
1207 die "$k already set: $orig_url\n",
1208 "wanted to set to: $gs->{url}\n";
1209 }
1210 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1211 my $remote_path = "$gs->{path}/$repo_path";
1212 $remote_path =~ s#/+#/#g;
1213 $remote_path =~ s#^/##g;
1214 $remote_path .= "/*" if $remote_path !~ /\*/;
1215 my ($n) = ($switch =~ /^--(\w+)/);
1216 if (length $pfx && $pfx !~ m#/$#) {
1217 die "--prefix='$pfx' must have a trailing slash '/'\n";
1218 }
1219 command_noisy('config',
1220 '--add',
1221 "svn-remote.$gs->{repo_id}.$n",
1222 "$remote_path:refs/remotes/$pfx*" .
1223 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1224 }
1225
1226 sub verify_ref {
1227 my ($ref) = @_;
1228 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1229 { STDERR => 0 }); };
1230 }
1231
1232 sub get_tree_from_treeish {
1233 my ($treeish) = @_;
1234 # $treeish can be a symbolic ref, too:
1235 my $type = command_oneline(qw/cat-file -t/, $treeish);
1236 my $expected;
1237 while ($type eq 'tag') {
1238 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1239 }
1240 if ($type eq 'commit') {
1241 $expected = (grep /^tree /, command(qw/cat-file commit/,
1242 $treeish))[0];
1243 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1244 die "Unable to get tree from $treeish\n" unless $expected;
1245 } elsif ($type eq 'tree') {
1246 $expected = $treeish;
1247 } else {
1248 die "$treeish is a $type, expected tree, tag or commit\n";
1249 }
1250 return $expected;
1251 }
1252
1253 sub get_commit_entry {
1254 my ($treeish) = shift;
1255 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1256 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1257 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1258 open my $log_fh, '>', $commit_editmsg or croak $!;
1259
1260 my $type = command_oneline(qw/cat-file -t/, $treeish);
1261 if ($type eq 'commit' || $type eq 'tag') {
1262 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1263 $type, $treeish);
1264 my $in_msg = 0;
1265 my $author;
1266 my $saw_from = 0;
1267 my $msgbuf = "";
1268 while (<$msg_fh>) {
1269 if (!$in_msg) {
1270 $in_msg = 1 if (/^\s*$/);
1271 $author = $1 if (/^author (.*>)/);
1272 } elsif (/^git-svn-id: /) {
1273 # skip this for now, we regenerate the
1274 # correct one on re-fetch anyways
1275 # TODO: set *:merge properties or like...
1276 } else {
1277 if (/^From:/ || /^Signed-off-by:/) {
1278 $saw_from = 1;
1279 }
1280 $msgbuf .= $_;
1281 }
1282 }
1283 $msgbuf =~ s/\s+$//s;
1284 if ($Git::SVN::_add_author_from && defined($author)
1285 && !$saw_from) {
1286 $msgbuf .= "\n\nFrom: $author";
1287 }
1288 print $log_fh $msgbuf or croak $!;
1289 command_close_pipe($msg_fh, $ctx);
1290 }
1291 close $log_fh or croak $!;
1292
1293 if ($_edit || ($type eq 'tree')) {
1294 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1295 # TODO: strip out spaces, comments, like git-commit.sh
1296 system($editor, $commit_editmsg);
1297 }
1298 rename $commit_editmsg, $commit_msg or croak $!;
1299 {
1300 require Encode;
1301 # SVN requires messages to be UTF-8 when entering the repo
1302 local $/;
1303 open $log_fh, '<', $commit_msg or croak $!;
1304 binmode $log_fh;
1305 chomp($log_entry{log} = <$log_fh>);
1306
1307 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1308 my $msg = $log_entry{log};
1309
1310 eval { $msg = Encode::decode($enc, $msg, 1) };
1311 if ($@) {
1312 die "Could not decode as $enc:\n", $msg,
1313 "\nPerhaps you need to set i18n.commitencoding\n";
1314 }
1315
1316 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1317 die "Could not encode as UTF-8:\n$msg\n" if $@;
1318
1319 $log_entry{log} = $msg;
1320
1321 close $log_fh or croak $!;
1322 }
1323 unlink $commit_msg;
1324 \%log_entry;
1325 }
1326
1327 sub s_to_file {
1328 my ($str, $file, $mode) = @_;
1329 open my $fd,'>',$file or croak $!;
1330 print $fd $str,"\n" or croak $!;
1331 close $fd or croak $!;
1332 chmod ($mode &~ umask, $file) if (defined $mode);
1333 }
1334
1335 sub file_to_s {
1336 my $file = shift;
1337 open my $fd,'<',$file or croak "$!: file: $file\n";
1338 local $/;
1339 my $ret = <$fd>;
1340 close $fd or croak $!;
1341 $ret =~ s/\s*$//s;
1342 return $ret;
1343 }
1344
1345 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1346 sub load_authors {
1347 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1348 my $log = $cmd eq 'log';
1349 while (<$authors>) {
1350 chomp;
1351 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1352 my ($user, $name, $email) = ($1, $2, $3);
1353 if ($log) {
1354 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1355 } else {
1356 $users{$user} = [$name, $email];
1357 }
1358 }
1359 close $authors or croak $!;
1360 }
1361
1362 # convert GetOpt::Long specs for use by git-config
1363 sub read_repo_config {
1364 return unless -d $ENV{GIT_DIR};
1365 my $opts = shift;
1366 my @config_only;
1367 foreach my $o (keys %$opts) {
1368 # if we have mixedCase and a long option-only, then
1369 # it's a config-only variable that we don't need for
1370 # the command-line.
1371 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1372 my $v = $opts->{$o};
1373 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1374 $key =~ s/-//g;
1375 my $arg = 'git config';
1376 $arg .= ' --int' if ($o =~ /[:=]i$/);
1377 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1378 if (ref $v eq 'ARRAY') {
1379 chomp(my @tmp = `$arg --get-all svn.$key`);
1380 @$v = @tmp if @tmp;
1381 } else {
1382 chomp(my $tmp = `$arg --get svn.$key`);
1383 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1384 $$v = $tmp;
1385 }
1386 }
1387 }
1388 delete @$opts{@config_only} if @config_only;
1389 }
1390
1391 sub extract_metadata {
1392 my $id = shift or return (undef, undef, undef);
1393 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1394 \s([a-f\d\-]+)$/ix);
1395 if (!defined $rev || !$uuid || !$url) {
1396 # some of the original repositories I made had
1397 # identifiers like this:
1398 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1399 }
1400 return ($url, $rev, $uuid);
1401 }
1402
1403 sub cmt_metadata {
1404 return extract_metadata((grep(/^git-svn-id: /,
1405 command(qw/cat-file commit/, shift)))[-1]);
1406 }
1407
1408 sub cmt_sha2rev_batch {
1409 my %s2r;
1410 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1411 my $list = shift;
1412
1413 foreach my $sha (@{$list}) {
1414 my $first = 1;
1415 my $size = 0;
1416 print $out $sha, "\n";
1417
1418 while (my $line = <$in>) {
1419 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1420 last;
1421 } elsif ($first &&
1422 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1423 $first = 0;
1424 $size = $1;
1425 next;
1426 } elsif ($line =~ /^(git-svn-id: )/) {
1427 my (undef, $rev, undef) =
1428 extract_metadata($line);
1429 $s2r{$sha} = $rev;
1430 }
1431
1432 $size -= length($line);
1433 last if ($size == 0);
1434 }
1435 }
1436
1437 command_close_bidi_pipe($pid, $in, $out, $ctx);
1438
1439 return \%s2r;
1440 }
1441
1442 sub working_head_info {
1443 my ($head, $refs) = @_;
1444 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1445 my ($fh, $ctx) = command_output_pipe(@args, $head);
1446 my $hash;
1447 my %max;
1448 while (<$fh>) {
1449 if ( m{^commit ($::sha1)$} ) {
1450 unshift @$refs, $hash if $hash and $refs;
1451 $hash = $1;
1452 next;
1453 }
1454 next unless s{^\s*(git-svn-id:)}{$1};
1455 my ($url, $rev, $uuid) = extract_metadata($_);
1456 if (defined $url && defined $rev) {
1457 next if $max{$url} and $max{$url} < $rev;
1458 if (my $gs = Git::SVN->find_by_url($url)) {
1459 my $c = $gs->rev_map_get($rev, $uuid);
1460 if ($c && $c eq $hash) {
1461 close $fh; # break the pipe
1462 return ($url, $rev, $uuid, $gs);
1463 } else {
1464 $max{$url} ||= $gs->rev_map_max;
1465 }
1466 }
1467 }
1468 }
1469 command_close_pipe($fh, $ctx);
1470 (undef, undef, undef, undef);
1471 }
1472
1473 sub read_commit_parents {
1474 my ($parents, $c) = @_;
1475 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1476 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1477 @{$parents->{$c}} = split(/ /, $p);
1478 }
1479
1480 sub linearize_history {
1481 my ($gs, $refs) = @_;
1482 my %parents;
1483 foreach my $c (@$refs) {
1484 read_commit_parents(\%parents, $c);
1485 }
1486
1487 my @linear_refs;
1488 my %skip = ();
1489 my $last_svn_commit = $gs->last_commit;
1490 foreach my $c (reverse @$refs) {
1491 next if $c eq $last_svn_commit;
1492 last if $skip{$c};
1493
1494 unshift @linear_refs, $c;
1495 $skip{$c} = 1;
1496
1497 # we only want the first parent to diff against for linear
1498 # history, we save the rest to inject when we finalize the
1499 # svn commit
1500 my $fp_a = verify_ref("$c~1");
1501 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1502 if (!$fp_a || !$fp_b) {
1503 die "Commit $c\n",
1504 "has no parent commit, and therefore ",
1505 "nothing to diff against.\n",
1506 "You should be working from a repository ",
1507 "originally created by git-svn\n";
1508 }
1509 if ($fp_a ne $fp_b) {
1510 die "$c~1 = $fp_a, however parsing commit $c ",
1511 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1512 }
1513
1514 foreach my $p (@{$parents{$c}}) {
1515 $skip{$p} = 1;
1516 }
1517 }
1518 (\@linear_refs, \%parents);
1519 }
1520
1521 sub find_file_type_and_diff_status {
1522 my ($path) = @_;
1523 return ('dir', '') if $path eq '';
1524
1525 my $diff_output =
1526 command_oneline(qw(diff --cached --name-status --), $path) || "";
1527 my $diff_status = (split(' ', $diff_output))[0] || "";
1528
1529 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1530
1531 return (undef, undef) if !$diff_status && !$ls_tree;
1532
1533 if ($diff_status eq "A") {
1534 return ("link", $diff_status) if -l $path;
1535 return ("dir", $diff_status) if -d $path;
1536 return ("file", $diff_status);
1537 }
1538
1539 my $mode = (split(' ', $ls_tree))[0] || "";
1540
1541 return ("link", $diff_status) if $mode eq "120000";
1542 return ("dir", $diff_status) if $mode eq "040000";
1543 return ("file", $diff_status);
1544 }
1545
1546 sub md5sum {
1547 my $arg = shift;
1548 my $ref = ref $arg;
1549 my $md5 = Digest::MD5->new();
1550 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1551 $md5->addfile($arg) or croak $!;
1552 } elsif ($ref eq 'SCALAR') {
1553 $md5->add($$arg) or croak $!;
1554 } elsif (!$ref) {
1555 $md5->add($arg) or croak $!;
1556 } else {
1557 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1558 }
1559 return $md5->hexdigest();
1560 }
1561
1562 sub gc_directory {
1563 if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1564 my $out_filename = $_ . ".gz";
1565 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1566 binmode $in_fh;
1567 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1568 die "Unable to open $out_filename: $!\n";
1569
1570 my $res;
1571 while ($res = sysread($in_fh, my $str, 1024)) {
1572 $gz->gzwrite($str) or
1573 die "Unable to write: ".$gz->gzerror()."!\n";
1574 }
1575 unlink $_ or die "unlink $File::Find::name: $!\n";
1576 } elsif (-f $_ && basename($_) eq "index") {
1577 unlink $_ or die "unlink $_: $!\n";
1578 }
1579 }
1580
1581 package Git::SVN;
1582 use strict;
1583 use warnings;
1584 use Fcntl qw/:DEFAULT :seek/;
1585 use constant rev_map_fmt => 'NH40';
1586 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1587 $_repack $_repack_flags $_use_svm_props $_head
1588 $_use_svnsync_props $no_reuse_existing $_minimize_url
1589 $_use_log_author $_add_author_from $_localtime/;
1590 use Carp qw/croak/;
1591 use File::Path qw/mkpath/;
1592 use File::Copy qw/copy/;
1593 use IPC::Open3;
1594
1595 my ($_gc_nr, $_gc_period);
1596
1597 # properties that we do not log:
1598 my %SKIP_PROP;
1599 BEGIN {
1600 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1601 svn:special svn:executable
1602 svn:entry:committed-rev
1603 svn:entry:last-author
1604 svn:entry:uuid
1605 svn:entry:committed-date/;
1606
1607 # some options are read globally, but can be overridden locally
1608 # per [svn-remote "..."] section. Command-line options will *NOT*
1609 # override options set in an [svn-remote "..."] section
1610 no strict 'refs';
1611 for my $option (qw/follow_parent no_metadata use_svm_props
1612 use_svnsync_props/) {
1613 my $key = $option;
1614 $key =~ tr/_//d;
1615 my $prop = "-$option";
1616 *$option = sub {
1617 my ($self) = @_;
1618 return $self->{$prop} if exists $self->{$prop};
1619 my $k = "svn-remote.$self->{repo_id}.$key";
1620 eval { command_oneline(qw/config --get/, $k) };
1621 if ($@) {
1622 $self->{$prop} = ${"Git::SVN::_$option"};
1623 } else {
1624 my $v = command_oneline(qw/config --bool/,$k);
1625 $self->{$prop} = $v eq 'false' ? 0 : 1;
1626 }
1627 return $self->{$prop};
1628 }
1629 }
1630 }
1631
1632
1633 my (%LOCKFILES, %INDEX_FILES);
1634 END {
1635 unlink keys %LOCKFILES if %LOCKFILES;
1636 unlink keys %INDEX_FILES if %INDEX_FILES;
1637 }
1638
1639 sub resolve_local_globs {
1640 my ($url, $fetch, $glob_spec) = @_;
1641 return unless defined $glob_spec;
1642 my $ref = $glob_spec->{ref};
1643 my $path = $glob_spec->{path};
1644 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1645 next unless m#^refs/remotes/$ref->{regex}$#;
1646 my $p = $1;
1647 my $pathname = desanitize_refname($path->full_path($p));
1648 my $refname = desanitize_refname($ref->full_path($p));
1649 if (my $existing = $fetch->{$pathname}) {
1650 if ($existing ne $refname) {
1651 die "Refspec conflict:\n",
1652 "existing: refs/remotes/$existing\n",
1653 " globbed: refs/remotes/$refname\n";
1654 }
1655 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1656 $u =~ s!^\Q$url\E(/|$)!! or die
1657 "refs/remotes/$refname: '$url' not found in '$u'\n";
1658 if ($pathname ne $u) {
1659 warn "W: Refspec glob conflict ",
1660 "(ref: refs/remotes/$refname):\n",
1661 "expected path: $pathname\n",
1662 " real path: $u\n",
1663 "Continuing ahead with $u\n";
1664 next;
1665 }
1666 } else {
1667 $fetch->{$pathname} = $refname;
1668 }
1669 }
1670 }
1671
1672 sub parse_revision_argument {
1673 my ($base, $head) = @_;
1674 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1675 return ($base, $head);
1676 }
1677 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1678 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1679 return ($head, $head) if ($::_revision eq 'HEAD');
1680 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1681 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1682 die "revision argument: $::_revision not understood by git-svn\n";
1683 }
1684
1685 sub fetch_all {
1686 my ($repo_id, $remotes) = @_;
1687 if (ref $repo_id) {
1688 my $gs = $repo_id;
1689 $repo_id = undef;
1690 $repo_id = $gs->{repo_id};
1691 }
1692 $remotes ||= read_all_remotes();
1693 my $remote = $remotes->{$repo_id} or
1694 die "[svn-remote \"$repo_id\"] unknown\n";
1695 my $fetch = $remote->{fetch};
1696 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1697 my (@gs, @globs);
1698 my $ra = Git::SVN::Ra->new($url);
1699 my $uuid = $ra->get_uuid;
1700 my $head = $ra->get_latest_revnum;
1701 $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1702 my $base = defined $fetch ? $head : 0;
1703
1704 # read the max revs for wildcard expansion (branches/*, tags/*)
1705 foreach my $t (qw/branches tags/) {
1706 defined $remote->{$t} or next;
1707 push @globs, @{$remote->{$t}};
1708
1709 my $max_rev = eval { tmp_config(qw/--int --get/,
1710 "svn-remote.$repo_id.${t}-maxRev") };
1711 if (defined $max_rev && ($max_rev < $base)) {
1712 $base = $max_rev;
1713 } elsif (!defined $max_rev) {
1714 $base = 0;
1715 }
1716 }
1717
1718 if ($fetch) {
1719 foreach my $p (sort keys %$fetch) {
1720 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1721 my $lr = $gs->rev_map_max;
1722 if (defined $lr) {
1723 $base = $lr if ($lr < $base);
1724 }
1725 push @gs, $gs;
1726 }
1727 }
1728
1729 ($base, $head) = parse_revision_argument($base, $head);
1730 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1731 }
1732
1733 sub read_all_remotes {
1734 my $r = {};
1735 my $use_svm_props = eval { command_oneline(qw/config --bool
1736 svn.useSvmProps/) };
1737 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1738 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1739 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1740 my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1741 die("svn-remote.$remote: remote ref '$_remote_ref' "
1742 . "must start with 'refs/remotes/'\n")
1743 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1744 my $remote_ref = $1;
1745 $local_ref =~ s{^/}{};
1746 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1747 $r->{$remote}->{svm} = {} if $use_svm_props;
1748 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1749 $r->{$1}->{svm} = {};
1750 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1751 $r->{$1}->{url} = $2;
1752 } elsif (m!^(.+)\.(branches|tags)=
1753 (.*):refs/remotes/(.+)\s*$/!x) {
1754 my ($p, $g) = ($3, $4);
1755 my $rs = {
1756 t => $2,
1757 remote => $1,
1758 path => Git::SVN::GlobSpec->new($p),
1759 ref => Git::SVN::GlobSpec->new($g) };
1760 if (length($rs->{ref}->{right}) != 0) {
1761 die "The '*' glob character must be the last ",
1762 "character of '$g'\n";
1763 }
1764 push @{ $r->{$1}->{$2} }, $rs;
1765 }
1766 }
1767
1768 map {
1769 if (defined $r->{$_}->{svm}) {
1770 my $svm;
1771 eval {
1772 my $section = "svn-remote.$_";
1773 $svm = {
1774 source => tmp_config('--get',
1775 "$section.svm-source"),
1776 replace => tmp_config('--get',
1777 "$section.svm-replace"),
1778 }
1779 };
1780 $r->{$_}->{svm} = $svm;
1781 }
1782 } keys %$r;
1783
1784 $r;
1785 }
1786
1787 sub init_vars {
1788 $_gc_nr = $_gc_period = 1000;
1789 if (defined $_repack || defined $_repack_flags) {
1790 warn "Repack options are obsolete; they have no effect.\n";
1791 }
1792 }
1793
1794 sub verify_remotes_sanity {
1795 return unless -d $ENV{GIT_DIR};
1796 my %seen;
1797 foreach (command(qw/config -l/)) {
1798 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1799 if ($seen{$1}) {
1800 die "Remote ref refs/remote/$1 is tracked by",
1801 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1802 "Please resolve this ambiguity in ",
1803 "your git configuration file before ",
1804 "continuing\n";
1805 }
1806 $seen{$1} = $_;
1807 }
1808 }
1809 }
1810
1811 sub find_existing_remote {
1812 my ($url, $remotes) = @_;
1813 return undef if $no_reuse_existing;
1814 my $existing;
1815 foreach my $repo_id (keys %$remotes) {
1816 my $u = $remotes->{$repo_id}->{url} or next;
1817 next if $u ne $url;
1818 $existing = $repo_id;
1819 last;
1820 }
1821 $existing;
1822 }
1823
1824 sub init_remote_config {
1825 my ($self, $url, $no_write) = @_;
1826 $url =~ s!/+$!!; # strip trailing slash
1827 my $r = read_all_remotes();
1828 my $existing = find_existing_remote($url, $r);
1829 if ($existing) {
1830 unless ($no_write) {
1831 print STDERR "Using existing ",
1832 "[svn-remote \"$existing\"]\n";
1833 }
1834 $self->{repo_id} = $existing;
1835 } elsif ($_minimize_url) {
1836 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1837 $existing = find_existing_remote($min_url, $r);
1838 if ($existing) {
1839 unless ($no_write) {
1840 print STDERR "Using existing ",
1841 "[svn-remote \"$existing\"]\n";
1842 }
1843 $self->{repo_id} = $existing;
1844 }
1845 if ($min_url ne $url) {
1846 unless ($no_write) {
1847 print STDERR "Using higher level of URL: ",
1848 "$url => $min_url\n";
1849 }
1850 my $old_path = $self->{path};
1851 $self->{path} = $url;
1852 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1853 if (length $old_path) {
1854 $self->{path} .= "/$old_path";
1855 }
1856 $url = $min_url;
1857 }
1858 }
1859 my $orig_url;
1860 if (!$existing) {
1861 # verify that we aren't overwriting anything:
1862 $orig_url = eval {
1863 command_oneline('config', '--get',
1864 "svn-remote.$self->{repo_id}.url")
1865 };
1866 if ($orig_url && ($orig_url ne $url)) {
1867 die "svn-remote.$self->{repo_id}.url already set: ",
1868 "$orig_url\nwanted to set to: $url\n";
1869 }
1870 }
1871 my ($xrepo_id, $xpath) = find_ref($self->refname);
1872 if (defined $xpath) {
1873 die "svn-remote.$xrepo_id.fetch already set to track ",
1874 "$xpath:refs/remotes/", $self->refname, "\n";
1875 }
1876 unless ($no_write) {
1877 command_noisy('config',
1878 "svn-remote.$self->{repo_id}.url", $url);
1879 $self->{path} =~ s{^/}{};
1880 command_noisy('config', '--add',
1881 "svn-remote.$self->{repo_id}.fetch",
1882 "$self->{path}:".$self->refname);
1883 }
1884 $self->{url} = $url;
1885 }
1886
1887 sub find_by_url { # repos_root and, path are optional
1888 my ($class, $full_url, $repos_root, $path) = @_;
1889
1890 return undef unless defined $full_url;
1891 remove_username($full_url);
1892 remove_username($repos_root) if defined $repos_root;
1893 my $remotes = read_all_remotes();
1894 if (defined $full_url && defined $repos_root && !defined $path) {
1895 $path = $full_url;
1896 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1897 }
1898 foreach my $repo_id (keys %$remotes) {
1899 my $u = $remotes->{$repo_id}->{url} or next;
1900 remove_username($u);
1901 next if defined $repos_root && $repos_root ne $u;
1902
1903 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1904 foreach my $t (qw/branches tags/) {
1905 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1906 resolve_local_globs($u, $fetch, $globspec);
1907 }
1908 }
1909 my $p = $path;
1910 my $rwr = rewrite_root({repo_id => $repo_id});
1911 my $svm = $remotes->{$repo_id}->{svm}
1912 if defined $remotes->{$repo_id}->{svm};
1913 unless (defined $p) {
1914 $p = $full_url;
1915 my $z = $u;
1916 my $prefix = '';
1917 if ($rwr) {
1918 $z = $rwr;
1919 remove_username($z);
1920 } elsif (defined $svm) {
1921 $z = $svm->{source};
1922 $prefix = $svm->{replace};
1923 $prefix =~ s#^\Q$u\E(?:/|$)##;
1924 $prefix =~ s#/$##;
1925 }
1926 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1927 }
1928 foreach my $f (keys %$fetch) {
1929 next if $f ne $p;
1930 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1931 }
1932 }
1933 undef;
1934 }
1935
1936 sub init {
1937 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1938 my $self = _new($class, $repo_id, $ref_id, $path);
1939 if (defined $url) {
1940 $self->init_remote_config($url, $no_write);
1941 }
1942 $self;
1943 }
1944
1945 sub find_ref {
1946 my ($ref_id) = @_;
1947 foreach (command(qw/config -l/)) {
1948 next unless m!^svn-remote\.(.+)\.fetch=
1949 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1950 my ($repo_id, $path, $ref) = ($1, $2, $3);
1951 if ($ref eq $ref_id) {
1952 $path = '' if ($path =~ m#^\./?#);
1953 return ($repo_id, $path);
1954 }
1955 }
1956 (undef, undef, undef);
1957 }
1958
1959 sub new {
1960 my ($class, $ref_id, $repo_id, $path) = @_;
1961 if (defined $ref_id && !defined $repo_id && !defined $path) {
1962 ($repo_id, $path) = find_ref($ref_id);
1963 if (!defined $repo_id) {
1964 die "Could not find a \"svn-remote.*.fetch\" key ",
1965 "in the repository configuration matching: ",
1966 "refs/remotes/$ref_id\n";
1967 }
1968 }
1969 my $self = _new($class, $repo_id, $ref_id, $path);
1970 if (!defined $self->{path} || !length $self->{path}) {
1971 my $fetch = command_oneline('config', '--get',
1972 "svn-remote.$repo_id.fetch",
1973 ":refs/remotes/$ref_id\$") or
1974 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1975 "\":refs/remotes/$ref_id\$\" in config\n";
1976 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1977 }
1978 $self->{url} = command_oneline('config', '--get',
1979 "svn-remote.$repo_id.url") or
1980 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1981 $self->rebuild;
1982 $self;
1983 }
1984
1985 sub refname {
1986 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1987
1988 # It cannot end with a slash /, we'll throw up on this because
1989 # SVN can't have directories with a slash in their name, either:
1990 if ($refname =~ m{/$}) {
1991 die "ref: '$refname' ends with a trailing slash, this is ",
1992 "not permitted by git nor Subversion\n";
1993 }
1994
1995 # It cannot have ASCII control character space, tilde ~, caret ^,
1996 # colon :, question-mark ?, asterisk *, space, or open bracket [
1997 # anywhere.
1998 #
1999 # Additionally, % must be escaped because it is used for escaping
2000 # and we want our escaped refname to be reversible
2001 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2002
2003 # no slash-separated component can begin with a dot .
2004 # /.* becomes /%2E*
2005 $refname =~ s{/\.}{/%2E}g;
2006
2007 # It cannot have two consecutive dots .. anywhere
2008 # .. becomes %2E%2E
2009 $refname =~ s{\.\.}{%2E%2E}g;
2010
2011 return $refname;
2012 }
2013
2014 sub desanitize_refname {
2015 my ($refname) = @_;
2016 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2017 return $refname;
2018 }
2019
2020 sub svm_uuid {
2021 my ($self) = @_;
2022 return $self->{svm}->{uuid} if $self->svm;
2023 $self->ra;
2024 unless ($self->{svm}) {
2025 die "SVM UUID not cached, and reading remotely failed\n";
2026 }
2027 $self->{svm}->{uuid};
2028 }
2029
2030 sub svm {
2031 my ($self) = @_;
2032 return $self->{svm} if $self->{svm};
2033 my $svm;
2034 # see if we have it in our config, first:
2035 eval {
2036 my $section = "svn-remote.$self->{repo_id}";
2037 $svm = {
2038 source => tmp_config('--get', "$section.svm-source"),
2039 uuid => tmp_config('--get', "$section.svm-uuid"),
2040 replace => tmp_config('--get', "$section.svm-replace"),
2041 }
2042 };
2043 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2044 $self->{svm} = $svm;
2045 }
2046 $self->{svm};
2047 }
2048
2049 sub _set_svm_vars {
2050 my ($self, $ra) = @_;
2051 return $ra if $self->svm;
2052
2053 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2054 "(svm:source, svm:uuid) ",
2055 "from the following URLs:\n" );
2056 sub read_svm_props {
2057 my ($self, $ra, $path, $r) = @_;
2058 my $props = ($ra->get_dir($path, $r))[2];
2059 my $src = $props->{'svm:source'};
2060 my $uuid = $props->{'svm:uuid'};
2061 return undef if (!$src || !$uuid);
2062
2063 chomp($src, $uuid);
2064
2065 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2066 or die "doesn't look right - svm:uuid is '$uuid'\n";
2067
2068 # the '!' is used to mark the repos_root!/relative/path
2069 $src =~ s{/?!/?}{/};
2070 $src =~ s{/+$}{}; # no trailing slashes please
2071 # username is of no interest
2072 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2073
2074 my $replace = $ra->{url};
2075 $replace .= "/$path" if length $path;
2076
2077 my $section = "svn-remote.$self->{repo_id}";
2078 tmp_config("$section.svm-source", $src);
2079 tmp_config("$section.svm-replace", $replace);
2080 tmp_config("$section.svm-uuid", $uuid);
2081 $self->{svm} = {
2082 source => $src,
2083 uuid => $uuid,
2084 replace => $replace
2085 };
2086 }
2087
2088 my $r = $ra->get_latest_revnum;
2089 my $path = $self->{path};
2090 my %tried;
2091 while (length $path) {
2092 unless ($tried{"$self->{url}/$path"}) {
2093 return $ra if $self->read_svm_props($ra, $path, $r);
2094 $tried{"$self->{url}/$path"} = 1;
2095 }
2096 $path =~ s#/?[^/]+$##;
2097 }
2098 die "Path: '$path' should be ''\n" if $path ne '';
2099 return $ra if $self->read_svm_props($ra, $path, $r);
2100 $tried{"$self->{url}/$path"} = 1;
2101
2102 if ($ra->{repos_root} eq $self->{url}) {
2103 die @err, (map { " $_\n" } keys %tried), "\n";
2104 }
2105
2106 # nope, make sure we're connected to the repository root:
2107 my $ok;
2108 my @tried_b;
2109 $path = $ra->{svn_path};
2110 $ra = Git::SVN::Ra->new($ra->{repos_root});
2111 while (length $path) {
2112 unless ($tried{"$ra->{url}/$path"}) {
2113 $ok = $self->read_svm_props($ra, $path, $r);
2114 last if $ok;
2115 $tried{"$ra->{url}/$path"} = 1;
2116 }
2117 $path =~ s#/?[^/]+$##;
2118 }
2119 die "Path: '$path' should be ''\n" if $path ne '';
2120 $ok ||= $self->read_svm_props($ra, $path, $r);
2121 $tried{"$ra->{url}/$path"} = 1;
2122 if (!$ok) {
2123 die @err, (map { " $_\n" } keys %tried), "\n";
2124 }
2125 Git::SVN::Ra->new($self->{url});
2126 }
2127
2128 sub svnsync {
2129 my ($self) = @_;
2130 return $self->{svnsync} if $self->{svnsync};
2131
2132 if ($self->no_metadata) {
2133 die "Can't have both 'noMetadata' and ",
2134 "'useSvnsyncProps' options set!\n";
2135 }
2136 if ($self->rewrite_root) {
2137 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2138 "options set!\n";
2139 }
2140
2141 my $svnsync;
2142 # see if we have it in our config, first:
2143 eval {
2144 my $section = "svn-remote.$self->{repo_id}";
2145
2146 my $url = tmp_config('--get', "$section.svnsync-url");
2147 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2148 die "doesn't look right - svn:sync-from-url is '$url'\n";
2149
2150 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2151 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2152 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2153
2154 $svnsync = { url => $url, uuid => $uuid }
2155 };
2156 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2157 return $self->{svnsync} = $svnsync;
2158 }
2159
2160 my $err = "useSvnsyncProps set, but failed to read " .
2161 "svnsync property: svn:sync-from-";
2162 my $rp = $self->ra->rev_proplist(0);
2163
2164 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2165 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2166 die "doesn't look right - svn:sync-from-url is '$url'\n";
2167
2168 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2169 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2170 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2171
2172 my $section = "svn-remote.$self->{repo_id}";
2173 tmp_config('--add', "$section.svnsync-uuid", $uuid);
2174 tmp_config('--add', "$section.svnsync-url", $url);
2175 return $self->{svnsync} = { url => $url, uuid => $uuid };
2176 }
2177
2178 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2179 # remote lookup (useful for 'git svn log').
2180 sub ra_uuid {
2181 my ($self) = @_;
2182 unless ($self->{ra_uuid}) {
2183 my $key = "svn-remote.$self->{repo_id}.uuid";
2184 my $uuid = eval { tmp_config('--get', $key) };
2185 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2186 $self->{ra_uuid} = $uuid;
2187 } else {
2188 die "ra_uuid called without URL\n" unless $self->{url};
2189 $self->{ra_uuid} = $self->ra->get_uuid;
2190 tmp_config('--add', $key, $self->{ra_uuid});
2191 }
2192 }
2193 $self->{ra_uuid};
2194 }
2195
2196 sub _set_repos_root {
2197 my ($self, $repos_root) = @_;
2198 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2199 $repos_root ||= $self->ra->{repos_root};
2200 tmp_config($k, $repos_root);
2201 $repos_root;
2202 }
2203
2204 sub repos_root {
2205 my ($self) = @_;
2206 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2207 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2208 }
2209
2210 sub ra {
2211 my ($self) = shift;
2212 my $ra = Git::SVN::Ra->new($self->{url});
2213 $self->_set_repos_root($ra->{repos_root});
2214 if ($self->use_svm_props && !$self->{svm}) {
2215 if ($self->no_metadata) {
2216 die "Can't have both 'noMetadata' and ",
2217 "'useSvmProps' options set!\n";
2218 } elsif ($self->use_svnsync_props) {
2219 die "Can't have both 'useSvnsyncProps' and ",
2220 "'useSvmProps' options set!\n";
2221 }
2222 $ra = $self->_set_svm_vars($ra);
2223 $self->{-want_revprops} = 1;
2224 }
2225 $ra;
2226 }
2227
2228 # prop_walk(PATH, REV, SUB)
2229 # -------------------------
2230 # Recursively traverse PATH at revision REV and invoke SUB for each
2231 # directory that contains a SVN property. SUB will be invoked as
2232 # follows: &SUB(gs, path, props); where `gs' is this instance of
2233 # Git::SVN, `path' the path to the directory where the properties
2234 # `props' were found. The `path' will be relative to point of checkout,
2235 # that is, if url://repo/trunk is the current Git branch, and that
2236 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2237 # as `path' (note the trailing `/').
2238 sub prop_walk {
2239 my ($self, $path, $rev, $sub) = @_;
2240
2241 $path =~ s#^/##;
2242 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2243 $path =~ s#^/*#/#g;
2244 my $p = $path;
2245 # Strip the irrelevant part of the path.
2246 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2247 # Ensure the path is terminated by a `/'.
2248 $p =~ s#/*$#/#;
2249
2250 # The properties contain all the internal SVN stuff nobody
2251 # (usually) cares about.
2252 my $interesting_props = 0;
2253 foreach (keys %{$props}) {
2254 # If it doesn't start with `svn:', it must be a
2255 # user-defined property.
2256 ++$interesting_props and next if $_ !~ /^svn:/;
2257 # FIXME: Fragile, if SVN adds new public properties,
2258 # this needs to be updated.
2259 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2260 |eol-style|mime-type
2261 |externals|needs-lock)$/x;
2262 }
2263 &$sub($self, $p, $props) if $interesting_props;
2264
2265 foreach (sort keys %$dirent) {
2266 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2267 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2268 }
2269 }
2270
2271 sub last_rev { ($_[0]->last_rev_commit)[0] }
2272 sub last_commit { ($_[0]->last_rev_commit)[1] }
2273
2274 # returns the newest SVN revision number and newest commit SHA1
2275 sub last_rev_commit {
2276 my ($self) = @_;
2277 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2278 return ($self->{last_rev}, $self->{last_commit});
2279 }
2280 my $c = ::verify_ref($self->refname.'^0');
2281 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2282 my $rev = (::cmt_metadata($c))[1];
2283 if (defined $rev) {
2284 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2285 return ($rev, $c);
2286 }
2287 }
2288 my $map_path = $self->map_path;
2289 unless (-e $map_path) {
2290 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2291 return (undef, undef);
2292 }
2293 my ($rev, $commit) = $self->rev_map_max(1);
2294 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2295 return ($rev, $commit);
2296 }
2297
2298 sub get_fetch_range {
2299 my ($self, $min, $max) = @_;
2300 $max ||= $self->ra->get_latest_revnum;
2301 $min ||= $self->rev_map_max;
2302 (++$min, $max);
2303 }
2304
2305 sub tmp_config {
2306 my (@args) = @_;
2307 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2308 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2309 if (! -f $config && -f $old_def_config) {
2310 rename $old_def_config, $config or
2311 die "Failed rename $old_def_config => $config: $!\n";
2312 }
2313 my $old_config = $ENV{GIT_CONFIG};
2314 $ENV{GIT_CONFIG} = $config;
2315 $@ = undef;
2316 my @ret = eval {
2317 unless (-f $config) {
2318 mkfile($config);
2319 open my $fh, '>', $config or
2320 die "Can't open $config: $!\n";
2321 print $fh "; This file is used internally by ",
2322 "git-svn\n" or die
2323 "Couldn't write to $config: $!\n";
2324 print $fh "; You should not have to edit it\n" or
2325 die "Couldn't write to $config: $!\n";
2326 close $fh or die "Couldn't close $config: $!\n";
2327 }
2328 command('config', @args);
2329 };
2330 my $err = $@;
2331 if (defined $old_config) {
2332 $ENV{GIT_CONFIG} = $old_config;
2333 } else {
2334 delete $ENV{GIT_CONFIG};
2335 }
2336 die $err if $err;
2337 wantarray ? @ret : $ret[0];
2338 }
2339
2340 sub tmp_index_do {
2341 my ($self, $sub) = @_;
2342 my $old_index = $ENV{GIT_INDEX_FILE};
2343 $ENV{GIT_INDEX_FILE} = $self->{index};
2344 $@ = undef;
2345 my @ret = eval {
2346 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2347 mkpath([$dir]) unless -d $dir;
2348 &$sub;
2349 };
2350 my $err = $@;
2351 if (defined $old_index) {
2352 $ENV{GIT_INDEX_FILE} = $old_index;
2353 } else {
2354 delete $ENV{GIT_INDEX_FILE};
2355 }
2356 die $err if $err;
2357 wantarray ? @ret : $ret[0];
2358 }
2359
2360 sub assert_index_clean {
2361 my ($self, $treeish) = @_;
2362
2363 $self->tmp_index_do(sub {
2364 command_noisy('read-tree', $treeish) unless -e $self->{index};
2365 my $x = command_oneline('write-tree');
2366 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2367 /^tree ($::sha1)/mo);
2368 return if $y eq $x;
2369
2370 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2371 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2372 command_noisy('read-tree', $treeish);
2373 $x = command_oneline('write-tree');
2374 if ($y ne $x) {
2375 ::fatal "trees ($treeish) $y != $x\n",
2376 "Something is seriously wrong...";
2377 }
2378 });
2379 }
2380
2381 sub get_commit_parents {
2382 my ($self, $log_entry) = @_;
2383 my (%seen, @ret, @tmp);
2384 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2385 if (my $ip = $self->{inject_parents}) {
2386 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2387 push @tmp, $commit;
2388 }
2389 }
2390 if (my $cur = ::verify_ref($self->refname.'^0')) {
2391 push @tmp, $cur;
2392 }
2393 if (my $ipd = $self->{inject_parents_dcommit}) {
2394 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2395 push @tmp, @$commit;
2396 }
2397 }
2398 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2399 while (my $p = shift @tmp) {
2400 next if $seen{$p};
2401 $seen{$p} = 1;
2402 push @ret, $p;
2403 # MAXPARENT is defined to 16 in commit-tree.c:
2404 last if @ret >= 16;
2405 }
2406 if (@tmp) {
2407 die "r$log_entry->{revision}: No room for parents:\n\t",
2408 join("\n\t", @tmp), "\n";
2409 }
2410 @ret;
2411 }
2412
2413 sub rewrite_root {
2414 my ($self) = @_;
2415 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2416 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2417 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2418 if ($rwr) {
2419 $rwr =~ s#/+$##;
2420 if ($rwr !~ m#^[a-z\+]+://#) {
2421 die "$rwr is not a valid URL (key: $k)\n";
2422 }
2423 }
2424 $self->{-rewrite_root} = $rwr;
2425 }
2426
2427 sub metadata_url {
2428 my ($self) = @_;
2429 ($self->rewrite_root || $self->{url}) .
2430 (length $self->{path} ? '/' . $self->{path} : '');
2431 }
2432
2433 sub full_url {
2434 my ($self) = @_;
2435 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2436 }
2437
2438
2439 sub set_commit_header_env {
2440 my ($log_entry) = @_;
2441 my %env;
2442 foreach my $ned (qw/NAME EMAIL DATE/) {
2443 foreach my $ac (qw/AUTHOR COMMITTER/) {
2444 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2445 }
2446 }
2447
2448 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2449 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2450 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2451
2452 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2453 ? $log_entry->{commit_name}
2454 : $log_entry->{name};
2455 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2456 ? $log_entry->{commit_email}
2457 : $log_entry->{email};
2458 \%env;
2459 }
2460
2461 sub restore_commit_header_env {
2462 my ($env) = @_;
2463 foreach my $ned (qw/NAME EMAIL DATE/) {
2464 foreach my $ac (qw/AUTHOR COMMITTER/) {
2465 my $k = "GIT_${ac}_${ned}";
2466 if (defined $env->{$k}) {
2467 $ENV{$k} = $env->{$k};
2468 } else {
2469 delete $ENV{$k};
2470 }
2471 }
2472 }
2473 }
2474
2475 sub gc {
2476 command_noisy('gc', '--auto');
2477 };
2478
2479 sub do_git_commit {
2480 my ($self, $log_entry) = @_;
2481 my $lr = $self->last_rev;
2482 if (defined $lr && $lr >= $log_entry->{revision}) {
2483 die "Last fetched revision of ", $self->refname,
2484 " was r$lr, but we are about to fetch: ",
2485 "r$log_entry->{revision}!\n";
2486 }
2487 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2488 croak "$log_entry->{revision} = $c already exists! ",
2489 "Why are we refetching it?\n";
2490 }
2491 my $old_env = set_commit_header_env($log_entry);
2492 my $tree = $log_entry->{tree};
2493 if (!defined $tree) {
2494 $tree = $self->tmp_index_do(sub {
2495 command_oneline('write-tree') });
2496 }
2497 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2498
2499 my @exec = ('git', 'commit-tree', $tree);
2500 foreach ($self->get_commit_parents($log_entry)) {
2501 push @exec, '-p', $_;
2502 }
2503 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2504 or croak $!;
2505 binmode $msg_fh;
2506
2507 # we always get UTF-8 from SVN, but we may want our commits in
2508 # a different encoding.
2509 if (my $enc = Git::config('i18n.commitencoding')) {
2510 require Encode;
2511 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2512 }
2513 print $msg_fh $log_entry->{log} or croak $!;
2514 restore_commit_header_env($old_env);
2515 unless ($self->no_metadata) {
2516 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2517 or croak $!;
2518 }
2519 $msg_fh->flush == 0 or croak $!;
2520 close $msg_fh or croak $!;
2521 chomp(my $commit = do { local $/; <$out_fh> });
2522 close $out_fh or croak $!;
2523 waitpid $pid, 0;
2524 croak $? if $?;
2525 if ($commit !~ /^$::sha1$/o) {
2526 die "Failed to commit, invalid sha1: $commit\n";
2527 }
2528
2529 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2530
2531 $self->{last_rev} = $log_entry->{revision};
2532 $self->{last_commit} = $commit;
2533 print "r$log_entry->{revision}" unless $::_q > 1;
2534 if (defined $log_entry->{svm_revision}) {
2535 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2536 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2537 0, $self->svm_uuid);
2538 }
2539 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2540 if (--$_gc_nr == 0) {
2541 $_gc_nr = $_gc_period;
2542 gc();
2543 }
2544 return $commit;
2545 }
2546
2547 sub match_paths {
2548 my ($self, $paths, $r) = @_;
2549 return 1 if $self->{path} eq '';
2550 if (my $path = $paths->{"/$self->{path}"}) {
2551 return ($path->{action} eq 'D') ? 0 : 1;
2552 }
2553 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2554 if (grep /$self->{path_regex}/, keys %$paths) {
2555 return 1;
2556 }
2557 my $c = '';
2558 foreach (split m#/#, $self->{path}) {
2559 $c .= "/$_";
2560 next unless ($paths->{$c} &&
2561 ($paths->{$c}->{action} =~ /^[AR]$/));
2562 if ($self->ra->check_path($self->{path}, $r) ==
2563 $SVN::Node::dir) {
2564 return 1;
2565 }
2566 }
2567 return 0;
2568 }
2569
2570 sub find_parent_branch {
2571 my ($self, $paths, $rev) = @_;
2572 return undef unless $self->follow_parent;
2573 unless (defined $paths) {
2574 my $err_handler = $SVN::Error::handler;
2575 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2576 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2577 sub { $paths = $_[0] });
2578 $SVN::Error::handler = $err_handler;
2579 }
2580 return undef unless defined $paths;
2581
2582 # look for a parent from another branch:
2583 my @b_path_components = split m#/#, $self->{path};
2584 my @a_path_components;
2585 my $i;
2586 while (@b_path_components) {
2587 $i = $paths->{'/'.join('/', @b_path_components)};
2588 last if $i && defined $i->{copyfrom_path};
2589 unshift(@a_path_components, pop(@b_path_components));
2590 }
2591 return undef unless defined $i && defined $i->{copyfrom_path};
2592 my $branch_from = $i->{copyfrom_path};
2593 if (@a_path_components) {
2594 print STDERR "branch_from: $branch_from => ";
2595 $branch_from .= '/'.join('/', @a_path_components);
2596 print STDERR $branch_from, "\n";
2597 }
2598 my $r = $i->{copyfrom_rev};
2599 my $repos_root = $self->ra->{repos_root};
2600 my $url = $self->ra->{url};
2601 my $new_url = $url . $branch_from;
2602 print STDERR "Found possible branch point: ",
2603 "$new_url => ", $self->full_url, ", $r\n";
2604 $branch_from =~ s#^/##;
2605 my $gs = $self->other_gs($new_url, $url,
2606 $branch_from, $r, $self->{ref_id});
2607 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2608 {
2609 my ($base, $head);
2610 if (!defined $r0 || !defined $parent) {
2611 ($base, $head) = parse_revision_argument(0, $r);
2612 } else {
2613 if ($r0 < $r) {
2614 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2615 0, 1, sub { $base = $_[1] - 1 });
2616 }
2617 }
2618 if (defined $base && $base <= $r) {
2619 $gs->fetch($base, $r);
2620 }
2621 ($r0, $parent) = $gs->find_rev_before($r, 1);
2622 }
2623 if (defined $r0 && defined $parent) {
2624 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2625 my $ed;
2626 if ($self->ra->can_do_switch) {
2627 $self->assert_index_clean($parent);
2628 print STDERR "Following parent with do_switch\n";
2629 # do_switch works with svn/trunk >= r22312, but that
2630 # is not included with SVN 1.4.3 (the latest version
2631 # at the moment), so we can't rely on it
2632 $self->{last_rev} = $r0;
2633 $self->{last_commit} = $parent;
2634 $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2635 $gs->ra->gs_do_switch($r0, $rev, $gs,
2636 $self->full_url, $ed)
2637 or die "SVN connection failed somewhere...\n";
2638 } elsif ($self->ra->trees_match($new_url, $r0,
2639 $self->full_url, $rev)) {
2640 print STDERR "Trees match:\n",
2641 " $new_url\@$r0\n",
2642 " ${\$self->full_url}\@$rev\n",
2643 "Following parent with no changes\n";
2644 $self->tmp_index_do(sub {
2645 command_noisy('read-tree', $parent);
2646 });
2647 $self->{last_commit} = $parent;
2648 } else {
2649 print STDERR "Following parent with do_update\n";
2650 $ed = SVN::Git::Fetcher->new($self);
2651 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2652 or die "SVN connection failed somewhere...\n";
2653 }
2654 print STDERR "Successfully followed parent\n";
2655 return $self->make_log_entry($rev, [$parent], $ed);
2656 }
2657 return undef;
2658 }
2659
2660 sub do_fetch {
2661 my ($self, $paths, $rev) = @_;
2662 my $ed;
2663 my ($last_rev, @parents);
2664 if (my $lc = $self->last_commit) {
2665 # we can have a branch that was deleted, then re-added
2666 # under the same name but copied from another path, in
2667 # which case we'll have multiple parents (we don't
2668 # want to break the original ref, nor lose copypath info):
2669 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2670 push @{$log_entry->{parents}}, $lc;
2671 return $log_entry;
2672 }
2673 $ed = SVN::Git::Fetcher->new($self);
2674 $last_rev = $self->{last_rev};
2675 $ed->{c} = $lc;
2676 @parents = ($lc);
2677 } else {
2678 $last_rev = $rev;
2679 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2680 return $log_entry;
2681 }
2682 $ed = SVN::Git::Fetcher->new($self);
2683 }
2684 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2685 die "SVN connection failed somewhere...\n";
2686 }
2687 $self->make_log_entry($rev, \@parents, $ed);
2688 }
2689
2690 sub get_untracked {
2691 my ($self, $ed) = @_;
2692 my @out;
2693 my $h = $ed->{empty};
2694 foreach (sort keys %$h) {
2695 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2696 push @out, " $act: " . uri_encode($_);
2697 warn "W: $act: $_\n";
2698 }
2699 foreach my $t (qw/dir_prop file_prop/) {
2700 $h = $ed->{$t} or next;
2701 foreach my $path (sort keys %$h) {
2702 my $ppath = $path eq '' ? '.' : $path;
2703 foreach my $prop (sort keys %{$h->{$path}}) {
2704 next if $SKIP_PROP{$prop};
2705 my $v = $h->{$path}->{$prop};
2706 my $t_ppath_prop = "$t: " .
2707 uri_encode($ppath) . ' ' .
2708 uri_encode($prop);
2709 if (defined $v) {
2710 push @out, " +$t_ppath_prop " .
2711 uri_encode($v);
2712 } else {
2713 push @out, " -$t_ppath_prop";
2714 }
2715 }
2716 }
2717 }
2718 foreach my $t (qw/absent_file absent_directory/) {
2719 $h = $ed->{$t} or next;
2720 foreach my $parent (sort keys %$h) {
2721 foreach my $path (sort @{$h->{$parent}}) {
2722 push @out, " $t: " .
2723 uri_encode("$parent/$path");
2724 warn "W: $t: $parent/$path ",
2725 "Insufficient permissions?\n";
2726 }
2727 }
2728 }
2729 \@out;
2730 }
2731
2732 # parse_svn_date(DATE)
2733 # --------------------
2734 # Given a date (in UTC) from Subversion, return a string in the format
2735 # "<TZ Offset> <local date/time>" that Git will use.
2736 #
2737 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2738 # is true we'll convert it to the local timezone instead.
2739 sub parse_svn_date {
2740 my $date = shift || return '+0000 1970-01-01 00:00:00';
2741 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2742 (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2743 croak "Unable to parse date: $date\n";
2744 my $parsed_date; # Set next.
2745
2746 if ($Git::SVN::_localtime) {
2747 # Translate the Subversion datetime to an epoch time.
2748 # Begin by switching ourselves to $date's timezone, UTC.
2749 my $old_env_TZ = $ENV{TZ};
2750 $ENV{TZ} = 'UTC';
2751
2752 my $epoch_in_UTC =
2753 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2754
2755 # Determine our local timezone (including DST) at the
2756 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
2757 # value of TZ, if any, at the time we were run.
2758 if (defined $Git::SVN::Log::TZ) {
2759 $ENV{TZ} = $Git::SVN::Log::TZ;
2760 } else {
2761 delete $ENV{TZ};
2762 }
2763
2764 my $our_TZ =
2765 POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2766
2767 # This converts $epoch_in_UTC into our local timezone.
2768 my ($sec, $min, $hour, $mday, $mon, $year,
2769 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2770
2771 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2772 $our_TZ, $year + 1900, $mon + 1,
2773 $mday, $hour, $min, $sec);
2774
2775 # Reset us to the timezone in effect when we entered
2776 # this routine.
2777 if (defined $old_env_TZ) {
2778 $ENV{TZ} = $old_env_TZ;
2779 } else {
2780 delete $ENV{TZ};
2781 }
2782 } else {
2783 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2784 }
2785
2786 return $parsed_date;
2787 }
2788
2789 sub other_gs {
2790 my ($self, $new_url, $url,
2791 $branch_from, $r, $old_ref_id) = @_;
2792 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2793 unless ($gs) {
2794 my $ref_id = $old_ref_id;
2795 $ref_id =~ s/\@\d+$//;
2796 $ref_id .= "\@$r";
2797 # just grow a tail if we're not unique enough :x
2798 $ref_id .= '-' while find_ref($ref_id);
2799 print STDERR "Initializing parent: $ref_id\n";
2800 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2801 if ($u =~ s#^\Q$url\E(/|$)##) {
2802 $p = $u;
2803 $u = $url;
2804 $repo_id = $self->{repo_id};
2805 }
2806 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2807 }
2808 $gs
2809 }
2810
2811 sub call_authors_prog {
2812 my ($orig_author) = @_;
2813 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2814 my $author = `$::_authors_prog $orig_author`;
2815 if ($? != 0) {
2816 die "$::_authors_prog failed with exit code $?\n"
2817 }
2818 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2819 my ($name, $email) = ($1, $2);
2820 $email = undef if length $2 == 0;
2821 return [$name, $email];
2822 } else {
2823 die "Author: $orig_author: $::_authors_prog returned "
2824 . "invalid author format: $author\n";
2825 }
2826 }
2827
2828 sub check_author {
2829 my ($author) = @_;
2830 if (!defined $author || length $author == 0) {
2831 $author = '(no author)';
2832 }
2833 if (!defined $::users{$author}) {
2834 if (defined $::_authors_prog) {
2835 $::users{$author} = call_authors_prog($author);
2836 } elsif (defined $::_authors) {
2837 die "Author: $author not defined in $::_authors file\n";
2838 }
2839 }
2840 $author;
2841 }
2842
2843 sub make_log_entry {
2844 my ($self, $rev, $parents, $ed) = @_;
2845 my $untracked = $self->get_untracked($ed);
2846
2847 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2848 print $un "r$rev\n" or croak $!;
2849 print $un $_, "\n" foreach @$untracked;
2850 my %log_entry = ( parents => $parents || [], revision => $rev,
2851 log => '');
2852
2853 my $headrev;
2854 my $logged = delete $self->{logged_rev_props};
2855 if (!$logged || $self->{-want_revprops}) {
2856 my $rp = $self->ra->rev_proplist($rev);
2857 foreach (sort keys %$rp) {
2858 my $v = $rp->{$_};
2859 if (/^svn:(author|date|log)$/) {
2860 $log_entry{$1} = $v;
2861 } elsif ($_ eq 'svm:headrev') {
2862 $headrev = $v;
2863 } else {
2864 print $un " rev_prop: ", uri_encode($_), ' ',
2865 uri_encode($v), "\n";
2866 }
2867 }
2868 } else {
2869 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2870 }
2871 close $un or croak $!;
2872
2873 $log_entry{date} = parse_svn_date($log_entry{date});
2874 $log_entry{log} .= "\n";
2875 my $author = $log_entry{author} = check_author($log_entry{author});
2876 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2877 : ($author, undef);
2878
2879 my ($commit_name, $commit_email) = ($name, $email);
2880 if ($_use_log_author) {
2881 my $name_field;
2882 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2883 $name_field = $1;
2884 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2885 $name_field = $1;
2886 }
2887 if (!defined $name_field) {
2888 if (!defined $email) {
2889 $email = $name;
2890 }
2891 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2892 ($name, $email) = ($1, $2);
2893 } elsif ($name_field =~ /(.*)@/) {
2894 ($name, $email) = ($1, $name_field);
2895 } else {
2896 ($name, $email) = ($name_field, $name_field);
2897 }
2898 }
2899 if (defined $headrev && $self->use_svm_props) {
2900 if ($self->rewrite_root) {
2901 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2902 "options set!\n";
2903 }
2904 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2905 # we don't want "SVM: initializing mirror for junk" ...
2906 return undef if $r == 0;
2907 my $svm = $self->svm;
2908 if ($uuid ne $svm->{uuid}) {
2909 die "UUID mismatch on SVM path:\n",
2910 "expected: $svm->{uuid}\n",
2911 " got: $uuid\n";
2912 }
2913 my $full_url = $self->full_url;
2914 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2915 die "Failed to replace '$svm->{replace}' with ",
2916 "'$svm->{source}' in $full_url\n";
2917 # throw away username for storing in records
2918 remove_username($full_url);
2919 $log_entry{metadata} = "$full_url\@$r $uuid";
2920 $log_entry{svm_revision} = $r;
2921 $email ||= "$author\@$uuid";
2922 $commit_email ||= "$author\@$uuid";
2923 } elsif ($self->use_svnsync_props) {
2924 my $full_url = $self->svnsync->{url};
2925 $full_url .= "/$self->{path}" if length $self->{path};
2926 remove_username($full_url);
2927 my $uuid = $self->svnsync->{uuid};
2928 $log_entry{metadata} = "$full_url\@$rev $uuid";
2929 $email ||= "$author\@$uuid";
2930 $commit_email ||= "$author\@$uuid";
2931 } else {
2932 my $url = $self->metadata_url;
2933 remove_username($url);
2934 $log_entry{metadata} = "$url\@$rev " .
2935 $self->ra->get_uuid;
2936 $email ||= "$author\@" . $self->ra->get_uuid;
2937 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2938 }
2939 $log_entry{name} = $name;
2940 $log_entry{email} = $email;
2941 $log_entry{commit_name} = $commit_name;
2942 $log_entry{commit_email} = $commit_email;
2943 \%log_entry;
2944 }
2945
2946 sub fetch {
2947 my ($self, $min_rev, $max_rev, @parents) = @_;
2948 my ($last_rev, $last_commit) = $self->last_rev_commit;
2949 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2950 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2951 }
2952
2953 sub set_tree_cb {
2954 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2955 $self->{inject_parents} = { $rev => $tree };
2956 $self->fetch(undef, undef);
2957 }
2958
2959 sub set_tree {
2960 my ($self, $tree) = (shift, shift);
2961 my $log_entry = ::get_commit_entry($tree);
2962 unless ($self->{last_rev}) {
2963 ::fatal("Must have an existing revision to commit");
2964 }
2965 my %ed_opts = ( r => $self->{last_rev},
2966 log => $log_entry->{log},
2967 ra => $self->ra,
2968 tree_a => $self->{last_commit},
2969 tree_b => $tree,
2970 editor_cb => sub {
2971 $self->set_tree_cb($log_entry, $tree, @_) },
2972 svn_path => $self->{path} );
2973 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2974 print "No changes\nr$self->{last_rev} = $tree\n";
2975 }
2976 }
2977
2978 sub rebuild_from_rev_db {
2979 my ($self, $path) = @_;
2980 my $r = -1;
2981 open my $fh, '<', $path or croak "open: $!";
2982 binmode $fh or croak "binmode: $!";
2983 while (<$fh>) {
2984 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2985 chomp($_);
2986 ++$r;
2987 next if $_ eq ('0' x 40);
2988 $self->rev_map_set($r, $_);
2989 print "r$r = $_\n";
2990 }
2991 close $fh or croak "close: $!";
2992 unlink $path or croak "unlink: $!";
2993 }
2994
2995 sub rebuild {
2996 my ($self) = @_;
2997 my $map_path = $self->map_path;
2998 my $partial = (-e $map_path && ! -z $map_path);
2999 return unless ::verify_ref($self->refname.'^0');
3000 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3001 my $rev_db = $self->rev_db_path;
3002 $self->rebuild_from_rev_db($rev_db);
3003 if ($self->use_svm_props) {
3004 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3005 $self->rebuild_from_rev_db($svm_rev_db);
3006 }
3007 $self->unlink_rev_db_symlink;
3008 return;
3009 }
3010 print "Rebuilding $map_path ...\n" if (!$partial);
3011 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3012 (undef, undef));
3013 my ($log, $ctx) =
3014 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3015 ($head ? "$head.." : "") . $self->refname,
3016 '--');
3017 my $metadata_url = $self->metadata_url;
3018 remove_username($metadata_url);
3019 my $svn_uuid = $self->ra_uuid;
3020 my $c;
3021 while (<$log>) {
3022 if ( m{^commit ($::sha1)$} ) {
3023 $c = $1;
3024 next;
3025 }
3026 next unless s{^\s*(git-svn-id:)}{$1};
3027 my ($url, $rev, $uuid) = ::extract_metadata($_);
3028 remove_username($url);
3029
3030 # ignore merges (from set-tree)
3031 next if (!defined $rev || !$uuid);
3032
3033 # if we merged or otherwise started elsewhere, this is
3034 # how we break out of it
3035 if (($uuid ne $svn_uuid) ||
3036 ($metadata_url && $url && ($url ne $metadata_url))) {
3037 next;
3038 }
3039 if ($partial && $head) {
3040 print "Partial-rebuilding $map_path ...\n";
3041 print "Currently at $base_rev = $head\n";
3042 $head = undef;
3043 }
3044
3045 $self->rev_map_set($rev, $c);
3046 print "r$rev = $c\n";
3047 }
3048 command_close_pipe($log, $ctx);
3049 print "Done rebuilding $map_path\n" if (!$partial || !$head);
3050 my $rev_db_path = $self->rev_db_path;
3051 if (-f $self->rev_db_path) {
3052 unlink $self->rev_db_path or croak "unlink: $!";
3053 }
3054 $self->unlink_rev_db_symlink;
3055 }
3056
3057 # rev_map:
3058 # Tie::File seems to be prone to offset errors if revisions get sparse,
3059 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3060 # one of my favorite modules is out :< Next up would be one of the DBM
3061 # modules, but I'm not sure which is most portable...
3062 #
3063 # This is the replacement for the rev_db format, which was too big
3064 # and inefficient for large repositories with a lot of sparse history
3065 # (mainly tags)
3066 #
3067 # The format is this:
3068 # - 24 bytes for every record,
3069 # * 4 bytes for the integer representing an SVN revision number
3070 # * 20 bytes representing the sha1 of a git commit
3071 # - No empty padding records like the old format
3072 # (except the last record, which can be overwritten)
3073 # - new records are written append-only since SVN revision numbers
3074 # increase monotonically
3075 # - lookups on SVN revision number are done via a binary search
3076 # - Piping the file to xxd -c24 is a good way of dumping it for
3077 # viewing or editing (piped back through xxd -r), should the need
3078 # ever arise.
3079 # - The last record can be padding revision with an all-zero sha1
3080 # This is used to optimize fetch performance when using multiple
3081 # "fetch" directives in .git/config
3082 #
3083 # These files are disposable unless noMetadata or useSvmProps is set
3084
3085 sub _rev_map_set {
3086 my ($fh, $rev, $commit) = @_;
3087
3088 binmode $fh or croak "binmode: $!";
3089 my $size = (stat($fh))[7];
3090 ($size % 24) == 0 or croak "inconsistent size: $size";
3091
3092 my $wr_offset = 0;
3093 if ($size > 0) {
3094 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3095 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3096 $read == 24 or croak "read only $read bytes (!= 24)";
3097 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3098 if ($last_commit eq ('0' x40)) {
3099 if ($size >= 48) {
3100 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3101 $read = sysread($fh, $buf, 24) or
3102 croak "read: $!";
3103 $read == 24 or
3104 croak "read only $read bytes (!= 24)";
3105 ($last_rev, $last_commit) =
3106 unpack(rev_map_fmt, $buf);
3107 if ($last_commit eq ('0' x40)) {
3108 croak "inconsistent .rev_map\n";
3109 }
3110 }
3111 if ($last_rev >= $rev) {
3112 croak "last_rev is higher!: $last_rev >= $rev";
3113 }
3114 $wr_offset = -24;
3115 }
3116 }
3117 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3118 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3119 croak "write: $!";
3120 }
3121
3122 sub _rev_map_reset {
3123 my ($fh, $rev, $commit) = @_;
3124 my $c = _rev_map_get($fh, $rev);
3125 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3126 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3127 truncate $fh, $offset or croak "truncate: $!";
3128 }
3129
3130 sub mkfile {
3131 my ($path) = @_;
3132 unless (-e $path) {
3133 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3134 mkpath([$dir]) unless -d $dir;
3135 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3136 close $fh or die "Couldn't close (create) $path: $!\n";
3137 }
3138 }
3139
3140 sub rev_map_set {
3141 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3142 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3143 my $db = $self->map_path($uuid);
3144 my $db_lock = "$db.lock";
3145 my $sig;
3146 $update_ref ||= 0;
3147 if ($update_ref) {
3148 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3149 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3150 }
3151 mkfile($db);
3152
3153 $LOCKFILES{$db_lock} = 1;
3154 my $sync;
3155 # both of these options make our .rev_db file very, very important
3156 # and we can't afford to lose it because rebuild() won't work
3157 if ($self->use_svm_props || $self->no_metadata) {
3158 $sync = 1;
3159 copy($db, $db_lock) or die "rev_map_set(@_): ",
3160 "Failed to copy: ",
3161 "$db => $db_lock ($!)\n";
3162 } else {
3163 rename $db, $db_lock or die "rev_map_set(@_): ",
3164 "Failed to rename: ",
3165 "$db => $db_lock ($!)\n";
3166 }
3167
3168 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3169 or croak "Couldn't open $db_lock: $!\n";
3170 $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3171 _rev_map_set($fh, $rev, $commit);
3172 if ($sync) {
3173 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3174 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3175 }
3176 close $fh or croak $!;
3177 if ($update_ref) {
3178 $_head = $self;
3179 my $note = "";
3180 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3181 command_noisy('update-ref', '-m', "r$rev$note",
3182 $self->refname, $commit);
3183 }
3184 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3185 "$db_lock => $db ($!)\n";
3186 delete $LOCKFILES{$db_lock};
3187 if ($update_ref) {
3188 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3189 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3190 kill $sig, $$ if defined $sig;
3191 }
3192 }
3193
3194 # If want_commit, this will return an array of (rev, commit) where
3195 # commit _must_ be a valid commit in the archive.
3196 # Otherwise, it'll return the max revision (whether or not the
3197 # commit is valid or just a 0x40 placeholder).
3198 sub rev_map_max {
3199 my ($self, $want_commit) = @_;
3200 $self->rebuild;
3201 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3202 $want_commit ? ($r, $c) : $r;
3203 }
3204
3205 sub rev_map_max_norebuild {
3206 my ($self, $want_commit) = @_;
3207 my $map_path = $self->map_path;
3208 stat $map_path or return $want_commit ? (0, undef) : 0;
3209 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3210 binmode $fh or croak "binmode: $!";
3211 my $size = (stat($fh))[7];
3212 ($size % 24) == 0 or croak "inconsistent size: $size";
3213
3214 if ($size == 0) {
3215 close $fh or croak "close: $!";
3216 return $want_commit ? (0, undef) : 0;
3217 }
3218
3219 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3220 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3221 my ($r, $c) = unpack(rev_map_fmt, $buf);
3222 if ($want_commit && $c eq ('0' x40)) {
3223 if ($size < 48) {
3224 return $want_commit ? (0, undef) : 0;
3225 }
3226 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3227 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3228 ($r, $c) = unpack(rev_map_fmt, $buf);
3229 if ($c eq ('0'x40)) {
3230 croak "Penultimate record is all-zeroes in $map_path";
3231 }
3232 }
3233 close $fh or croak "close: $!";
3234 $want_commit ? ($r, $c) : $r;
3235 }
3236
3237 sub rev_map_get {
3238 my ($self, $rev, $uuid) = @_;
3239 my $map_path = $self->map_path($uuid);
3240 return undef unless -e $map_path;
3241
3242 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3243 my $c = _rev_map_get($fh, $rev);
3244 close($fh) or croak "close: $!";
3245 $c
3246 }
3247
3248 sub _rev_map_get {
3249 my ($fh, $rev) = @_;
3250
3251 binmode $fh or croak "binmode: $!";
3252 my $size = (stat($fh))[7];
3253 ($size % 24) == 0 or croak "inconsistent size: $size";
3254
3255 if ($size == 0) {
3256 return undef;
3257 }
3258
3259 my ($l, $u) = (0, $size - 24);
3260 my ($r, $c, $buf);
3261
3262 while ($l <= $u) {
3263 my $i = int(($l/24 + $u/24) / 2) * 24;
3264 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3265 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3266 my ($r, $c) = unpack('NH40', $buf);
3267
3268 if ($r < $rev) {
3269 $l = $i + 24;
3270 } elsif ($r > $rev) {
3271 $u = $i - 24;
3272 } else { # $r == $rev
3273 return $c eq ('0' x 40) ? undef : $c;
3274 }
3275 }
3276 undef;
3277 }
3278
3279 # Finds the first svn revision that exists on (if $eq_ok is true) or
3280 # before $rev for the current branch. It will not search any lower
3281 # than $min_rev. Returns the git commit hash and svn revision number
3282 # if found, else (undef, undef).
3283 sub find_rev_before {
3284 my ($self, $rev, $eq_ok, $min_rev) = @_;
3285 --$rev unless $eq_ok;
3286 $min_rev ||= 1;
3287 my $max_rev = $self->rev_map_max;
3288 $rev = $max_rev if ($rev > $max_rev);
3289 while ($rev >= $min_rev) {
3290 if (my $c = $self->rev_map_get($rev)) {
3291 return ($rev, $c);
3292 }
3293 --$rev;
3294 }
3295 return (undef, undef);
3296 }
3297
3298 # Finds the first svn revision that exists on (if $eq_ok is true) or
3299 # after $rev for the current branch. It will not search any higher
3300 # than $max_rev. Returns the git commit hash and svn revision number
3301 # if found, else (undef, undef).
3302 sub find_rev_after {
3303 my ($self, $rev, $eq_ok, $max_rev) = @_;
3304 ++$rev unless $eq_ok;
3305 $max_rev ||= $self->rev_map_max;
3306 while ($rev <= $max_rev) {
3307 if (my $c = $self->rev_map_get($rev)) {
3308 return ($rev, $c);
3309 }
3310 ++$rev;
3311 }
3312 return (undef, undef);
3313 }
3314
3315 sub _new {
3316 my ($class, $repo_id, $ref_id, $path) = @_;
3317 unless (defined $repo_id && length $repo_id) {
3318 $repo_id = $Git::SVN::default_repo_id;
3319 }
3320 unless (defined $ref_id && length $ref_id) {
3321 $_[2] = $ref_id = $Git::SVN::default_ref_id;
3322 }
3323 $_[1] = $repo_id;
3324 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3325 $_[3] = $path = '' unless (defined $path);
3326 mkpath(["$ENV{GIT_DIR}/svn"]);
3327 bless {
3328 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3329 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3330 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3331 }
3332
3333 # for read-only access of old .rev_db formats
3334 sub unlink_rev_db_symlink {
3335 my ($self) = @_;
3336 my $link = $self->rev_db_path;
3337 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3338 if (-l $link) {
3339 unlink $link or croak "unlink: $link failed!";
3340 }
3341 }
3342
3343 sub rev_db_path {
3344 my ($self, $uuid) = @_;
3345 my $db_path = $self->map_path($uuid);
3346 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3347 or croak "map_path: $db_path does not contain '/.rev_map.' !";
3348 $db_path;
3349 }
3350
3351 # the new replacement for .rev_db
3352 sub map_path {
3353 my ($self, $uuid) = @_;
3354 $uuid ||= $self->ra_uuid;
3355 "$self->{map_root}.$uuid";
3356 }
3357
3358 sub uri_encode {
3359 my ($f) = @_;
3360 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3361 $f
3362 }
3363
3364 sub remove_username {
3365 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3366 }
3367
3368 package Git::SVN::Prompt;
3369 use strict;
3370 use warnings;
3371 require SVN::Core;
3372 use vars qw/$_no_auth_cache $_username/;
3373
3374 sub simple {
3375 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3376 $may_save = undef if $_no_auth_cache;
3377 $default_username = $_username if defined $_username;
3378 if (defined $default_username && length $default_username) {
3379 if (defined $realm && length $realm) {
3380 print STDERR "Authentication realm: $realm\n";
3381 STDERR->flush;
3382 }
3383 $cred->username($default_username);
3384 } else {
3385 username($cred, $realm, $may_save, $pool);
3386 }
3387 $cred->password(_read_password("Password for '" .
3388 $cred->username . "': ", $realm));
3389 $cred->may_save($may_save);
3390 $SVN::_Core::SVN_NO_ERROR;
3391 }
3392
3393 sub ssl_server_trust {
3394 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3395 $may_save = undef if $_no_auth_cache;
3396 print STDERR "Error validating server certificate for '$realm':\n";
3397 {
3398 no warnings 'once';
3399 # All variables SVN::Auth::SSL::* are used only once,
3400 # so we're shutting up Perl warnings about this.
3401 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3402 print STDERR " - The certificate is not issued ",
3403 "by a trusted authority. Use the\n",
3404 " fingerprint to validate ",
3405 "the certificate manually!\n";
3406 }
3407 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3408 print STDERR " - The certificate hostname ",
3409 "does not match.\n";
3410 }
3411 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3412 print STDERR " - The certificate is not yet valid.\n";
3413 }
3414 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3415 print STDERR " - The certificate has expired.\n";
3416 }
3417 if ($failures & $SVN::Auth::SSL::OTHER) {
3418 print STDERR " - The certificate has ",
3419 "an unknown error.\n";
3420 }
3421 } # no warnings 'once'
3422 printf STDERR
3423 "Certificate information:\n".
3424 " - Hostname: %s\n".
3425 " - Valid: from %s until %s\n".
3426 " - Issuer: %s\n".
3427 " - Fingerprint: %s\n",
3428 map $cert_info->$_, qw(hostname valid_from valid_until
3429 issuer_dname fingerprint);
3430 my $choice;
3431 prompt:
3432 print STDERR $may_save ?
3433 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3434 "(R)eject or accept (t)emporarily? ";
3435 STDERR->flush;
3436 $choice = lc(substr(<STDIN> || 'R', 0, 1));
3437 if ($choice =~ /^t$/i) {
3438 $cred->may_save(undef);
3439 } elsif ($choice =~ /^r$/i) {
3440 return -1;
3441 } elsif ($may_save && $choice =~ /^p$/i) {
3442 $cred->may_save($may_save);
3443 } else {
3444 goto prompt;
3445 }
3446 $cred->accepted_failures($failures);
3447 $SVN::_Core::SVN_NO_ERROR;
3448 }
3449
3450 sub ssl_client_cert {
3451 my ($cred, $realm, $may_save, $pool) = @_;
3452 $may_save = undef if $_no_auth_cache;
3453 print STDERR "Client certificate filename: ";
3454 STDERR->flush;
3455 chomp(my $filename = <STDIN>);
3456 $cred->cert_file($filename);
3457 $cred->may_save($may_save);
3458 $SVN::_Core::SVN_NO_ERROR;
3459 }
3460
3461 sub ssl_client_cert_pw {
3462 my ($cred, $realm, $may_save, $pool) = @_;
3463 $may_save = undef if $_no_auth_cache;
3464 $cred->password(_read_password("Password: ", $realm));
3465 $cred->may_save($may_save);
3466 $SVN::_Core::SVN_NO_ERROR;
3467 }
3468
3469 sub username {
3470 my ($cred, $realm, $may_save, $pool) = @_;
3471 $may_save = undef if $_no_auth_cache;
3472 if (defined $realm && length $realm) {
3473 print STDERR "Authentication realm: $realm\n";
3474 }
3475 my $username;
3476 if (defined $_username) {
3477 $username = $_username;
3478 } else {
3479 print STDERR "Username: ";
3480 STDERR->flush;
3481 chomp($username = <STDIN>);
3482 }
3483 $cred->username($username);
3484 $cred->may_save($may_save);
3485 $SVN::_Core::SVN_NO_ERROR;
3486 }
3487
3488 sub _read_password {
3489 my ($prompt, $realm) = @_;
3490 print STDERR $prompt;
3491 STDERR->flush;
3492 require Term::ReadKey;
3493 Term::ReadKey::ReadMode('noecho');
3494 my $password = '';
3495 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3496 last if $key =~ /[\012\015]/; # \n\r
3497 $password .= $key;
3498 }
3499 Term::ReadKey::ReadMode('restore');
3500 print STDERR "\n";
3501 STDERR->flush;
3502 $password;
3503 }
3504
3505 package SVN::Git::Fetcher;
3506 use vars qw/@ISA/;
3507 use strict;
3508 use warnings;
3509 use Carp qw/croak/;
3510 use File::Temp qw/tempfile/;
3511 use IO::File qw//;
3512 use vars qw/$_ignore_regex/;
3513
3514 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3515 sub new {
3516 my ($class, $git_svn, $switch_path) = @_;
3517 my $self = SVN::Delta::Editor->new;
3518 bless $self, $class;
3519 if (exists $git_svn->{last_commit}) {
3520 $self->{c} = $git_svn->{last_commit};
3521 $self->{empty_symlinks} =
3522 _mark_empty_symlinks($git_svn, $switch_path);
3523 }
3524 $self->{ignore_regex} = eval { command_oneline('config', '--get',
3525 "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3526 $self->{empty} = {};
3527 $self->{dir_prop} = {};
3528 $self->{file_prop} = {};
3529 $self->{absent_dir} = {};
3530 $self->{absent_file} = {};
3531 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3532 $self;
3533 }
3534
3535 # this uses the Ra object, so it must be called before do_{switch,update},
3536 # not inside them (when the Git::SVN::Fetcher object is passed) to
3537 # do_{switch,update}
3538 sub _mark_empty_symlinks {
3539 my ($git_svn, $switch_path) = @_;
3540 my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3541 return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3542
3543 my %ret;
3544 my ($rev, $cmt) = $git_svn->last_rev_commit;
3545 return {} unless ($rev && $cmt);
3546
3547 # allow the warning to be printed for each revision we fetch to
3548 # ensure the user sees it. The user can also disable the workaround
3549 # on the repository even while git svn is running and the next
3550 # revision fetched will skip this expensive function.
3551 my $printed_warning;
3552 chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3553 my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3554 local $/ = "\0";
3555 my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3556 $pfx .= '/' if length($pfx);
3557 while (<$ls>) {
3558 chomp;
3559 s/\A100644 blob $empty_blob\t//o or next;
3560 unless ($printed_warning) {
3561 print STDERR "Scanning for empty symlinks, ",
3562 "this may take a while if you have ",
3563 "many empty files\n",
3564 "You may disable this with `",
3565 "git config svn.brokenSymlinkWorkaround ",
3566 "false'.\n",
3567 "This may be done in a different ",
3568 "terminal without restarting ",
3569 "git svn\n";
3570 $printed_warning = 1;
3571 }
3572 my $path = $_;
3573 my (undef, $props) =
3574 $git_svn->ra->get_file($pfx.$path, $rev, undef);
3575 if ($props->{'svn:special'}) {
3576 $ret{$path} = 1;
3577 }
3578 }
3579 command_close_pipe($ls, $ctx);
3580 \%ret;
3581 }
3582
3583 # returns true if a given path is inside a ".git" directory
3584 sub in_dot_git {
3585 $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3586 }
3587
3588 # return value: 0 -- don't ignore, 1 -- ignore
3589 sub is_path_ignored {
3590 my ($self, $path) = @_;
3591 return 1 if in_dot_git($path);
3592 return 1 if defined($self->{ignore_regex}) &&
3593 $path =~ m!$self->{ignore_regex}!;
3594 return 0 unless defined($_ignore_regex);
3595 return 1 if $path =~ m!$_ignore_regex!o;
3596 return 0;
3597 }
3598
3599 sub set_path_strip {
3600 my ($self, $path) = @_;
3601 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3602 }
3603
3604 sub open_root {
3605 { path => '' };
3606 }
3607
3608 sub open_directory {
3609 my ($self, $path, $pb, $rev) = @_;
3610 { path => $path };
3611 }
3612
3613 sub git_path {
3614 my ($self, $path) = @_;
3615 if ($self->{path_strip}) {
3616 $path =~ s!$self->{path_strip}!! or
3617 die "Failed to strip path '$path' ($self->{path_strip})\n";
3618 }
3619 $path;
3620 }
3621
3622 sub delete_entry {
3623 my ($self, $path, $rev, $pb) = @_;
3624 return undef if $self->is_path_ignored($path);
3625
3626 my $gpath = $self->git_path($path);
3627 return undef if ($gpath eq '');
3628
3629 # remove entire directories.
3630 my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3631 =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3632 if ($tree) {
3633 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3634 -r --name-only -z/,
3635 $tree);
3636 local $/ = "\0";
3637 while (<$ls>) {
3638 chomp;
3639 my $rmpath = "$gpath/$_";
3640 $self->{gii}->remove($rmpath);
3641 print "\tD\t$rmpath\n" unless $::_q;
3642 }
3643 print "\tD\t$gpath/\n" unless $::_q;
3644 command_close_pipe($ls, $ctx);
3645 $self->{empty}->{$path} = 0
3646 } else {
3647 $self->{gii}->remove($gpath);
3648 print "\tD\t$gpath\n" unless $::_q;
3649 }
3650 undef;
3651 }
3652
3653 sub open_file {
3654 my ($self, $path, $pb, $rev) = @_;
3655 my ($mode, $blob);
3656
3657 goto out if $self->is_path_ignored($path);
3658
3659 my $gpath = $self->git_path($path);
3660 ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3661 =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3662 unless (defined $mode && defined $blob) {
3663 die "$path was not found in commit $self->{c} (r$rev)\n";
3664 }
3665 if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3666 $mode = '120000';
3667 }
3668 out:
3669 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3670 pool => SVN::Pool->new, action => 'M' };
3671 }
3672
3673 sub add_file {
3674 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3675 my $mode;
3676
3677 if (!$self->is_path_ignored($path)) {
3678 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3679 delete $self->{empty}->{$dir};
3680 $mode = '100644';
3681 }
3682 { path => $path, mode_a => $mode, mode_b => $mode,
3683 pool => SVN::Pool->new, action => 'A' };
3684 }
3685
3686 sub add_directory {
3687 my ($self, $path, $cp_path, $cp_rev) = @_;
3688 goto out if $self->is_path_ignored($path);
3689 my $gpath = $self->git_path($path);
3690 if ($gpath eq '') {
3691 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3692 -r --name-only -z/,
3693 $self->{c});
3694 local $/ = "\0";
3695 while (<$ls>) {
3696 chomp;
3697 $self->{gii}->remove($_);
3698 print "\tD\t$_\n" unless $::_q;
3699 }
3700 command_close_pipe($ls, $ctx);
3701 $self->{empty}->{$path} = 0;
3702 }
3703 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3704 delete $self->{empty}->{$dir};
3705 $self->{empty}->{$path} = 1;
3706 out:
3707 { path => $path };
3708 }
3709
3710 sub change_dir_prop {
3711 my ($self, $db, $prop, $value) = @_;
3712 return undef if $self->is_path_ignored($db->{path});
3713 $self->{dir_prop}->{$db->{path}} ||= {};
3714 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3715 undef;
3716 }
3717
3718 sub absent_directory {
3719 my ($self, $path, $pb) = @_;
3720 return undef if $self->is_path_ignored($path);
3721 $self->{absent_dir}->{$pb->{path}} ||= [];
3722 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3723 undef;
3724 }
3725
3726 sub absent_file {
3727 my ($self, $path, $pb) = @_;
3728 return undef if $self->is_path_ignored($path);
3729 $self->{absent_file}->{$pb->{path}} ||= [];
3730 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3731 undef;
3732 }
3733
3734 sub change_file_prop {
3735 my ($self, $fb, $prop, $value) = @_;
3736 return undef if $self->is_path_ignored($fb->{path});
3737 if ($prop eq 'svn:executable') {
3738 if ($fb->{mode_b} != 120000) {
3739 $fb->{mode_b} = defined $value ? 100755 : 100644;
3740 }
3741 } elsif ($prop eq 'svn:special') {
3742 $fb->{mode_b} = defined $value ? 120000 : 100644;
3743 } else {
3744 $self->{file_prop}->{$fb->{path}} ||= {};
3745 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3746 }
3747 undef;
3748 }
3749
3750 sub apply_textdelta {
3751 my ($self, $fb, $exp) = @_;
3752 return undef if $self->is_path_ignored($fb->{path});
3753 my $fh = $::_repository->temp_acquire('svn_delta');
3754 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3755 # (but $base does not,) so dup() it for reading in close_file
3756 open my $dup, '<&', $fh or croak $!;
3757 my $base = $::_repository->temp_acquire('git_blob');
3758
3759 if ($fb->{blob}) {
3760 my ($base_is_link, $size);
3761
3762 if ($fb->{mode_a} eq '120000' &&
3763 ! $self->{empty_symlinks}->{$fb->{path}}) {
3764 print $base 'link ' or die "print $!\n";
3765 $base_is_link = 1;
3766 }
3767 retry:
3768 $size = $::_repository->cat_blob($fb->{blob}, $base);
3769 die "Failed to read object $fb->{blob}" if ($size < 0);
3770
3771 if (defined $exp) {
3772 seek $base, 0, 0 or croak $!;
3773 my $got = ::md5sum($base);
3774 if ($got ne $exp) {
3775 my $err = "Checksum mismatch: ".
3776 "$fb->{path} $fb->{blob}\n" .
3777 "expected: $exp\n" .
3778 " got: $got\n";
3779 if ($base_is_link) {
3780 warn $err,
3781 "Retrying... (possibly ",
3782 "a bad symlink from SVN)\n";
3783 $::_repository->temp_reset($base);
3784 $base_is_link = 0;
3785 goto retry;
3786 }
3787 die $err;
3788 }
3789 }
3790 }
3791 seek $base, 0, 0 or croak $!;
3792 $fb->{fh} = $fh;
3793 $fb->{base} = $base;
3794 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3795 }
3796
3797 sub close_file {
3798 my ($self, $fb, $exp) = @_;
3799 return undef if $self->is_path_ignored($fb->{path});
3800
3801 my $hash;
3802 my $path = $self->git_path($fb->{path});
3803 if (my $fh = $fb->{fh}) {
3804 if (defined $exp) {
3805 seek($fh, 0, 0) or croak $!;
3806 my $got = ::md5sum($fh);
3807 if ($got ne $exp) {
3808 die "Checksum mismatch: $path\n",
3809 "expected: $exp\n got: $got\n";
3810 }
3811 }
3812 if ($fb->{mode_b} == 120000) {
3813 sysseek($fh, 0, 0) or croak $!;
3814 my $rd = sysread($fh, my $buf, 5);
3815
3816 if (!defined $rd) {
3817 croak "sysread: $!\n";
3818 } elsif ($rd == 0) {
3819 warn "$path has mode 120000",
3820 " but it points to nothing\n",
3821 "converting to an empty file with mode",
3822 " 100644\n";
3823 $fb->{mode_b} = '100644';
3824 } elsif ($buf ne 'link ') {
3825 warn "$path has mode 120000",
3826 " but is not a link\n";
3827 } else {
3828 my $tmp_fh = $::_repository->temp_acquire(
3829 'svn_hash');
3830 my $res;
3831 while ($res = sysread($fh, my $str, 1024)) {
3832 my $out = syswrite($tmp_fh, $str, $res);
3833 defined($out) && $out == $res
3834 or croak("write ",
3835 Git::temp_path($tmp_fh),
3836 ": $!\n");
3837 }
3838 defined $res or croak $!;
3839
3840 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3841 Git::temp_release($tmp_fh, 1);
3842 }
3843 }
3844
3845 $hash = $::_repository->hash_and_insert_object(
3846 Git::temp_path($fh));
3847 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3848
3849 Git::temp_release($fb->{base}, 1);
3850 Git::temp_release($fh, 1);
3851 } else {
3852 $hash = $fb->{blob} or die "no blob information\n";
3853 }
3854 $fb->{pool}->clear;
3855 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3856 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3857 undef;
3858 }
3859
3860 sub abort_edit {
3861 my $self = shift;
3862 $self->{nr} = $self->{gii}->{nr};
3863 delete $self->{gii};
3864 $self->SUPER::abort_edit(@_);
3865 }
3866
3867 sub close_edit {
3868 my $self = shift;
3869 $self->{git_commit_ok} = 1;
3870 $self->{nr} = $self->{gii}->{nr};
3871 delete $self->{gii};
3872 $self->SUPER::close_edit(@_);
3873 }
3874
3875 package SVN::Git::Editor;
3876 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3877 use strict;
3878 use warnings;
3879 use Carp qw/croak/;
3880 use IO::File;
3881
3882 sub new {
3883 my ($class, $opts) = @_;
3884 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3885 die "$_ required!\n" unless (defined $opts->{$_});
3886 }
3887
3888 my $pool = SVN::Pool->new;
3889 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3890 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3891 $opts->{r}, $mods);
3892
3893 # $opts->{ra} functions should not be used after this:
3894 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3895 $opts->{editor_cb}, $pool);
3896 my $self = SVN::Delta::Editor->new(@ce, $pool);
3897 bless $self, $class;
3898 foreach (qw/svn_path r tree_a tree_b/) {
3899 $self->{$_} = $opts->{$_};
3900 }
3901 $self->{url} = $opts->{ra}->{url};
3902 $self->{mods} = $mods;
3903 $self->{types} = $types;
3904 $self->{pool} = $pool;
3905 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3906 $self->{rm} = { };
3907 $self->{path_prefix} = length $self->{svn_path} ?
3908 "$self->{svn_path}/" : '';
3909 $self->{config} = $opts->{config};
3910 return $self;
3911 }
3912
3913 sub generate_diff {
3914 my ($tree_a, $tree_b) = @_;
3915 my @diff_tree = qw(diff-tree -z -r);
3916 if ($_cp_similarity) {
3917 push @diff_tree, "-C$_cp_similarity";
3918 } else {
3919 push @diff_tree, '-C';
3920 }
3921 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3922 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3923 push @diff_tree, $tree_a, $tree_b;
3924 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3925 local $/ = "\0";
3926 my $state = 'meta';
3927 my @mods;
3928 while (<$diff_fh>) {
3929 chomp $_; # this gets rid of the trailing "\0"
3930 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3931 ($::sha1)\s($::sha1)\s
3932 ([MTCRAD])\d*$/xo) {
3933 push @mods, { mode_a => $1, mode_b => $2,
3934 sha1_a => $3, sha1_b => $4,
3935 chg => $5 };
3936 if ($5 =~ /^(?:C|R)$/) {
3937 $state = 'file_a';
3938 } else {
3939 $state = 'file_b';
3940 }
3941 } elsif ($state eq 'file_a') {
3942 my $x = $mods[$#mods] or croak "Empty array\n";
3943 if ($x->{chg} !~ /^(?:C|R)$/) {
3944 croak "Error parsing $_, $x->{chg}\n";
3945 }
3946 $x->{file_a} = $_;
3947 $state = 'file_b';
3948 } elsif ($state eq 'file_b') {
3949 my $x = $mods[$#mods] or croak "Empty array\n";
3950 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3951 croak "Error parsing $_, $x->{chg}\n";
3952 }
3953 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3954 croak "Error parsing $_, $x->{chg}\n";
3955 }
3956 $x->{file_b} = $_;
3957 $state = 'meta';
3958 } else {
3959 croak "Error parsing $_\n";
3960 }
3961 }
3962 command_close_pipe($diff_fh, $ctx);
3963 \@mods;
3964 }
3965
3966 sub check_diff_paths {
3967 my ($ra, $pfx, $rev, $mods) = @_;
3968 my %types;
3969 $pfx .= '/' if length $pfx;
3970
3971 sub type_diff_paths {
3972 my ($ra, $types, $path, $rev) = @_;
3973 my @p = split m#/+#, $path;
3974 my $c = shift @p;
3975 unless (defined $types->{$c}) {
3976 $types->{$c} = $ra->check_path($c, $rev);
3977 }
3978 while (@p) {
3979 $c .= '/' . shift @p;
3980 next if defined $types->{$c};
3981 $types->{$c} = $ra->check_path($c, $rev);
3982 }
3983 }
3984
3985 foreach my $m (@$mods) {
3986 foreach my $f (qw/file_a file_b/) {
3987 next unless defined $m->{$f};
3988 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3989 if (length $pfx.$dir && ! defined $types{$dir}) {
3990 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3991 }
3992 }
3993 }
3994 \%types;
3995 }
3996
3997 sub split_path {
3998 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3999 }
4000
4001 sub repo_path {
4002 my ($self, $path) = @_;
4003 $self->{path_prefix}.(defined $path ? $path : '');
4004 }
4005
4006 sub url_path {
4007 my ($self, $path) = @_;
4008 if ($self->{url} =~ m#^https?://#) {
4009 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4010 }
4011 $self->{url} . '/' . $self->repo_path($path);
4012 }
4013
4014 sub rmdirs {
4015 my ($self) = @_;
4016 my $rm = $self->{rm};
4017 delete $rm->{''}; # we never delete the url we're tracking
4018 return unless %$rm;
4019
4020 foreach (keys %$rm) {
4021 my @d = split m#/#, $_;
4022 my $c = shift @d;
4023 $rm->{$c} = 1;
4024 while (@d) {
4025 $c .= '/' . shift @d;
4026 $rm->{$c} = 1;
4027 }
4028 }
4029 delete $rm->{$self->{svn_path}};
4030 delete $rm->{''}; # we never delete the url we're tracking
4031 return unless %$rm;
4032
4033 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4034 $self->{tree_b});
4035 local $/ = "\0";
4036 while (<$fh>) {
4037 chomp;
4038 my @dn = split m#/#, $_;
4039 while (pop @dn) {
4040 delete $rm->{join '/', @dn};
4041 }
4042 unless (%$rm) {
4043 close $fh;
4044 return;
4045 }
4046 }
4047 command_close_pipe($fh, $ctx);
4048
4049 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4050 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4051 $self->close_directory($bat->{$d}, $p);
4052 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4053 print "\tD+\t$d/\n" unless $::_q;
4054 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4055 delete $bat->{$d};
4056 }
4057 }
4058
4059 sub open_or_add_dir {
4060 my ($self, $full_path, $baton) = @_;
4061 my $t = $self->{types}->{$full_path};
4062 if (!defined $t) {
4063 die "$full_path not known in r$self->{r} or we have a bug!\n";
4064 }
4065 {
4066 no warnings 'once';
4067 # SVN::Node::none and SVN::Node::file are used only once,
4068 # so we're shutting up Perl's warnings about them.
4069 if ($t == $SVN::Node::none) {
4070 return $self->add_directory($full_path, $baton,
4071 undef, -1, $self->{pool});
4072 } elsif ($t == $SVN::Node::dir) {
4073 return $self->open_directory($full_path, $baton,
4074 $self->{r}, $self->{pool});
4075 } # no warnings 'once'
4076 print STDERR "$full_path already exists in repository at ",
4077 "r$self->{r} and it is not a directory (",
4078 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4079 } # no warnings 'once'
4080 exit 1;
4081 }
4082
4083 sub ensure_path {
4084 my ($self, $path) = @_;
4085 my $bat = $self->{bat};
4086 my $repo_path = $self->repo_path($path);
4087 return $bat->{''} unless (length $repo_path);
4088 my @p = split m#/+#, $repo_path;
4089 my $c = shift @p;
4090 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4091 while (@p) {
4092 my $c0 = $c;
4093 $c .= '/' . shift @p;
4094 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4095 }
4096 return $bat->{$c};
4097 }
4098
4099 # Subroutine to convert a globbing pattern to a regular expression.
4100 # From perl cookbook.
4101 sub glob2pat {
4102 my $globstr = shift;
4103 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4104 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4105 return '^' . $globstr . '$';
4106 }
4107
4108 sub check_autoprop {
4109 my ($self, $pattern, $properties, $file, $fbat) = @_;
4110 # Convert the globbing pattern to a regular expression.
4111 my $regex = glob2pat($pattern);
4112 # Check if the pattern matches the file name.
4113 if($file =~ m/($regex)/) {
4114 # Parse the list of properties to set.
4115 my @props = split(/;/, $properties);
4116 foreach my $prop (@props) {
4117 # Parse 'name=value' syntax and set the property.
4118 if ($prop =~ /([^=]+)=(.*)/) {
4119 my ($n,$v) = ($1,$2);
4120 for ($n, $v) {
4121 s/^\s+//; s/\s+$//;
4122 }
4123 $self->change_file_prop($fbat, $n, $v);
4124 }
4125 }
4126 }
4127 }
4128
4129 sub apply_autoprops {
4130 my ($self, $file, $fbat) = @_;
4131 my $conf_t = ${$self->{config}}{'config'};
4132 no warnings 'once';
4133 # Check [miscellany]/enable-auto-props in svn configuration.
4134 if (SVN::_Core::svn_config_get_bool(
4135 $conf_t,
4136 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4137 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4138 0)) {
4139 # Auto-props are enabled. Enumerate them to look for matches.
4140 my $callback = sub {
4141 $self->check_autoprop($_[0], $_[1], $file, $fbat);
4142 };
4143 SVN::_Core::svn_config_enumerate(
4144 $conf_t,
4145 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4146 $callback);
4147 }
4148 }
4149
4150 sub A {
4151 my ($self, $m) = @_;
4152 my ($dir, $file) = split_path($m->{file_b});
4153 my $pbat = $self->ensure_path($dir);
4154 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4155 undef, -1);
4156 print "\tA\t$m->{file_b}\n" unless $::_q;
4157 $self->apply_autoprops($file, $fbat);
4158 $self->chg_file($fbat, $m);
4159 $self->close_file($fbat,undef,$self->{pool});
4160 }
4161
4162 sub C {
4163 my ($self, $m) = @_;
4164 my ($dir, $file) = split_path($m->{file_b});
4165 my $pbat = $self->ensure_path($dir);
4166 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4167 $self->url_path($m->{file_a}), $self->{r});
4168 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4169 $self->chg_file($fbat, $m);
4170 $self->close_file($fbat,undef,$self->{pool});
4171 }
4172
4173 sub delete_entry {
4174 my ($self, $path, $pbat) = @_;
4175 my $rpath = $self->repo_path($path);
4176 my ($dir, $file) = split_path($rpath);
4177 $self->{rm}->{$dir} = 1;
4178 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4179 }
4180
4181 sub R {
4182 my ($self, $m) = @_;
4183 my ($dir, $file) = split_path($m->{file_b});
4184 my $pbat = $self->ensure_path($dir);
4185 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4186 $self->url_path($m->{file_a}), $self->{r});
4187 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4188 $self->apply_autoprops($file, $fbat);
4189 $self->chg_file($fbat, $m);
4190 $self->close_file($fbat,undef,$self->{pool});
4191
4192 ($dir, $file) = split_path($m->{file_a});
4193 $pbat = $self->ensure_path($dir);
4194 $self->delete_entry($m->{file_a}, $pbat);
4195 }
4196
4197 sub M {
4198 my ($self, $m) = @_;
4199 my ($dir, $file) = split_path($m->{file_b});
4200 my $pbat = $self->ensure_path($dir);
4201 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4202 $pbat,$self->{r},$self->{pool});
4203 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4204 $self->chg_file($fbat, $m);
4205 $self->close_file($fbat,undef,$self->{pool});
4206 }
4207
4208 sub T { shift->M(@_) }
4209
4210 sub change_file_prop {
4211 my ($self, $fbat, $pname, $pval) = @_;
4212 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4213 }
4214
4215 sub _chg_file_get_blob ($$$$) {
4216 my ($self, $fbat, $m, $which) = @_;
4217 my $fh = $::_repository->temp_acquire("git_blob_$which");
4218 if ($m->{"mode_$which"} =~ /^120/) {
4219 print $fh 'link ' or croak $!;
4220 $self->change_file_prop($fbat,'svn:special','*');
4221 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4222 $self->change_file_prop($fbat,'svn:special',undef);
4223 }
4224 my $blob = $m->{"sha1_$which"};
4225 return ($fh,) if ($blob =~ /^0{40}$/);
4226 my $size = $::_repository->cat_blob($blob, $fh);
4227 croak "Failed to read object $blob" if ($size < 0);
4228 $fh->flush == 0 or croak $!;
4229 seek $fh, 0, 0 or croak $!;
4230
4231 my $exp = ::md5sum($fh);
4232 seek $fh, 0, 0 or croak $!;
4233 return ($fh, $exp);
4234 }
4235
4236 sub chg_file {
4237 my ($self, $fbat, $m) = @_;
4238 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4239 $self->change_file_prop($fbat,'svn:executable','*');
4240 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4241 $self->change_file_prop($fbat,'svn:executable',undef);
4242 }
4243 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4244 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4245 my $pool = SVN::Pool->new;
4246 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4247 if (-s $fh_a) {
4248 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4249 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4250 if (defined $res) {
4251 die "Unexpected result from send_txstream: $res\n",
4252 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4253 }
4254 } else {
4255 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4256 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4257 if ($got ne $exp_b);
4258 }
4259 Git::temp_release($fh_b, 1);
4260 Git::temp_release($fh_a, 1);
4261 $pool->clear;
4262 }
4263
4264 sub D {
4265 my ($self, $m) = @_;
4266 my ($dir, $file) = split_path($m->{file_b});
4267 my $pbat = $self->ensure_path($dir);
4268 print "\tD\t$m->{file_b}\n" unless $::_q;
4269 $self->delete_entry($m->{file_b}, $pbat);
4270 }
4271
4272 sub close_edit {
4273 my ($self) = @_;
4274 my ($p,$bat) = ($self->{pool}, $self->{bat});
4275 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4276 next if $_ eq '';
4277 $self->close_directory($bat->{$_}, $p);
4278 }
4279 $self->close_directory($bat->{''}, $p);
4280 $self->SUPER::close_edit($p);
4281 $p->clear;
4282 }
4283
4284 sub abort_edit {
4285 my ($self) = @_;
4286 $self->SUPER::abort_edit($self->{pool});
4287 }
4288
4289 sub DESTROY {
4290 my $self = shift;
4291 $self->SUPER::DESTROY(@_);
4292 $self->{pool}->clear;
4293 }
4294
4295 # this drives the editor
4296 sub apply_diff {
4297 my ($self) = @_;
4298 my $mods = $self->{mods};
4299 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4300 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4301 my $f = $m->{chg};
4302 if (defined $o{$f}) {
4303 $self->$f($m);
4304 } else {
4305 fatal("Invalid change type: $f");
4306 }
4307 }
4308 $self->rmdirs if $_rmdir;
4309 if (@$mods == 0) {
4310 $self->abort_edit;
4311 } else {
4312 $self->close_edit;
4313 }
4314 return scalar @$mods;
4315 }
4316
4317 package Git::SVN::Ra;
4318 use vars qw/@ISA $config_dir $_log_window_size/;
4319 use strict;
4320 use warnings;
4321 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4322
4323 BEGIN {
4324 # enforce temporary pool usage for some simple functions
4325 no strict 'refs';
4326 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4327 get_file/) {
4328 my $SUPER = "SUPER::$f";
4329 *$f = sub {
4330 my $self = shift;
4331 my $pool = SVN::Pool->new;
4332 my @ret = $self->$SUPER(@_,$pool);
4333 $pool->clear;
4334 wantarray ? @ret : $ret[0];
4335 };
4336 }
4337 }
4338
4339 sub _auth_providers () {
4340 [
4341 SVN::Client::get_simple_provider(),
4342 SVN::Client::get_ssl_server_trust_file_provider(),
4343 SVN::Client::get_simple_prompt_provider(
4344 \&Git::SVN::Prompt::simple, 2),
4345 SVN::Client::get_ssl_client_cert_file_provider(),
4346 SVN::Client::get_ssl_client_cert_prompt_provider(
4347 \&Git::SVN::Prompt::ssl_client_cert, 2),
4348 SVN::Client::get_ssl_client_cert_pw_file_provider(),
4349 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4350 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4351 SVN::Client::get_username_provider(),
4352 SVN::Client::get_ssl_server_trust_prompt_provider(
4353 \&Git::SVN::Prompt::ssl_server_trust),
4354 SVN::Client::get_username_prompt_provider(
4355 \&Git::SVN::Prompt::username, 2)
4356 ]
4357 }
4358
4359 sub escape_uri_only {
4360 my ($uri) = @_;
4361 my @tmp;
4362 foreach (split m{/}, $uri) {
4363 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4364 push @tmp, $_;
4365 }
4366 join('/', @tmp);
4367 }
4368
4369 sub escape_url {
4370 my ($url) = @_;
4371 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4372 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4373 $url = "$scheme://$domain$uri";
4374 }
4375 $url;
4376 }
4377
4378 sub new {
4379 my ($class, $url) = @_;
4380 $url =~ s!/+$!!;
4381 return $RA if ($RA && $RA->{url} eq $url);
4382
4383 SVN::_Core::svn_config_ensure($config_dir, undef);
4384 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4385 my $config = SVN::Core::config_get_config($config_dir);
4386 $RA = undef;
4387 my $dont_store_passwords = 1;
4388 my $conf_t = ${$config}{'config'};
4389 {
4390 no warnings 'once';
4391 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4392 # produces warnings that variables are used only once.
4393 # I had not found the better way to shut them up, so
4394 # the warnings of type 'once' are disabled in this block.
4395 if (SVN::_Core::svn_config_get_bool($conf_t,
4396 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4397 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4398 1) == 0) {
4399 SVN::_Core::svn_auth_set_parameter($baton,
4400 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4401 bless (\$dont_store_passwords, "_p_void"));
4402 }
4403 if (SVN::_Core::svn_config_get_bool($conf_t,
4404 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4405 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4406 1) == 0) {
4407 $Git::SVN::Prompt::_no_auth_cache = 1;
4408 }
4409 } # no warnings 'once'
4410 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4411 config => $config,
4412 pool => SVN::Pool->new,
4413 auth_provider_callbacks => $callbacks);
4414 $self->{url} = $url;
4415 $self->{svn_path} = $url;
4416 $self->{repos_root} = $self->get_repos_root;
4417 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4418 $self->{cache} = { check_path => { r => 0, data => {} },
4419 get_dir => { r => 0, data => {} } };
4420 $RA = bless $self, $class;
4421 }
4422
4423 sub check_path {
4424 my ($self, $path, $r) = @_;
4425 my $cache = $self->{cache}->{check_path};
4426 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4427 return $cache->{data}->{$path};
4428 }
4429 my $pool = SVN::Pool->new;
4430 my $t = $self->SUPER::check_path($path, $r, $pool);
4431 $pool->clear;
4432 if ($r != $cache->{r}) {
4433 %{$cache->{data}} = ();
4434 $cache->{r} = $r;
4435 }
4436 $cache->{data}->{$path} = $t;
4437 }
4438
4439 sub get_dir {
4440 my ($self, $dir, $r) = @_;
4441 my $cache = $self->{cache}->{get_dir};
4442 if ($r == $cache->{r}) {
4443 if (my $x = $cache->{data}->{$dir}) {
4444 return wantarray ? @$x : $x->[0];
4445 }
4446 }
4447 my $pool = SVN::Pool->new;
4448 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4449 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4450 $pool->clear;
4451 if ($r != $cache->{r}) {
4452 %{$cache->{data}} = ();
4453 $cache->{r} = $r;
4454 }
4455 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4456 wantarray ? (\%dirents, $r, $props) : \%dirents;
4457 }
4458
4459 sub DESTROY {
4460 # do not call the real DESTROY since we store ourselves in $RA
4461 }
4462
4463 # get_log(paths, start, end, limit,
4464 # discover_changed_paths, strict_node_history, receiver)
4465 sub get_log {
4466 my ($self, @args) = @_;
4467 my $pool = SVN::Pool->new;
4468
4469 # svn_log_changed_path_t objects passed to get_log are likely to be
4470 # overwritten even if only the refs are copied to an external variable,
4471 # so we should dup the structures in their entirety. Using an
4472 # externally passed pool (instead of our temporary and quickly cleared
4473 # pool in Git::SVN::Ra) does not help matters at all...
4474 my $receiver = pop @args;
4475 my $prefix = "/".$self->{svn_path};
4476 $prefix =~ s#/+($)##;
4477 my $prefix_regex = qr#^\Q$prefix\E#;
4478 push(@args, sub {
4479 my ($paths) = $_[0];
4480 return &$receiver(@_) unless $paths;
4481 $_[0] = ();
4482 foreach my $p (keys %$paths) {
4483 my $i = $paths->{$p};
4484 # Make path relative to our url, not repos_root
4485 $p =~ s/$prefix_regex//;
4486 my %s = map { $_ => $i->$_; }
4487 qw/copyfrom_path copyfrom_rev action/;
4488 if ($s{'copyfrom_path'}) {
4489 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4490 }
4491 $_[0]{$p} = \%s;
4492 }
4493 &$receiver(@_);
4494 });
4495
4496
4497 # the limit parameter was not supported in SVN 1.1.x, so we
4498 # drop it. Therefore, the receiver callback passed to it
4499 # is made aware of this limitation by being wrapped if
4500 # the limit passed to is being wrapped.
4501 if ($SVN::Core::VERSION le '1.2.0') {
4502 my $limit = splice(@args, 3, 1);
4503 if ($limit > 0) {
4504 my $receiver = pop @args;
4505 push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4506 }
4507 }
4508 my $ret = $self->SUPER::get_log(@args, $pool);
4509 $pool->clear;
4510 $ret;
4511 }
4512
4513 sub trees_match {
4514 my ($self, $url1, $rev1, $url2, $rev2) = @_;
4515 my $ctx = SVN::Client->new(auth => _auth_providers);
4516 my $out = IO::File->new_tmpfile;
4517
4518 # older SVN (1.1.x) doesn't take $pool as the last parameter for
4519 # $ctx->diff(), so we'll create a default one
4520 my $pool = SVN::Pool->new_default_sub;
4521
4522 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4523 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4524 $out->flush;
4525 my $ret = (($out->stat)[7] == 0);
4526 close $out or croak $!;
4527
4528 $ret;
4529 }
4530
4531 sub get_commit_editor {
4532 my ($self, $log, $cb, $pool) = @_;
4533 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4534 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4535 }
4536
4537 sub gs_do_update {
4538 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4539 my $new = ($rev_a == $rev_b);
4540 my $path = $gs->{path};
4541
4542 if ($new && -e $gs->{index}) {
4543 unlink $gs->{index} or die
4544 "Couldn't unlink index: $gs->{index}: $!\n";
4545 }
4546 my $pool = SVN::Pool->new;
4547 $editor->set_path_strip($path);
4548 my (@pc) = split m#/#, $path;
4549 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4550 1, $editor, $pool);
4551 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4552
4553 # Since we can't rely on svn_ra_reparent being available, we'll
4554 # just have to do some magic with set_path to make it so
4555 # we only want a partial path.
4556 my $sp = '';
4557 my $final = join('/', @pc);
4558 while (@pc) {
4559 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4560 $sp .= '/' if length $sp;
4561 $sp .= shift @pc;
4562 }
4563 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4564
4565 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4566
4567 $reporter->finish_report($pool);
4568 $pool->clear;
4569 $editor->{git_commit_ok};
4570 }
4571
4572 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4573 # svn_ra_reparent didn't work before 1.4)
4574 sub gs_do_switch {
4575 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4576 my $path = $gs->{path};
4577 my $pool = SVN::Pool->new;
4578
4579 my $full_url = $self->{url};
4580 my $old_url = $full_url;
4581 $full_url .= '/' . $path if length $path;
4582 my ($ra, $reparented);
4583
4584 if ($old_url =~ m#^svn(\+ssh)?://# ||
4585 ($full_url =~ m#^https?://# &&
4586 escape_url($full_url) ne $full_url)) {
4587 $_[0] = undef;
4588 $self = undef;
4589 $RA = undef;
4590 $ra = Git::SVN::Ra->new($full_url);
4591 $ra_invalid = 1;
4592 } elsif ($old_url ne $full_url) {
4593 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4594 $self->{url} = $full_url;
4595 $reparented = 1;
4596 }
4597
4598 $ra ||= $self;
4599 $url_b = escape_url($url_b);
4600 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4601 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4602 $reporter->set_path('', $rev_a, 0, @lock, $pool);
4603 $reporter->finish_report($pool);
4604
4605 if ($reparented) {
4606 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4607 $self->{url} = $old_url;
4608 }
4609
4610 $pool->clear;
4611 $editor->{git_commit_ok};
4612 }
4613
4614 sub longest_common_path {
4615 my ($gsv, $globs) = @_;
4616 my %common;
4617 my $common_max = scalar @$gsv;
4618
4619 foreach my $gs (@$gsv) {
4620 my @tmp = split m#/#, $gs->{path};
4621 my $p = '';
4622 foreach (@tmp) {
4623 $p .= length($p) ? "/$_" : $_;
4624 $common{$p} ||= 0;
4625 $common{$p}++;
4626 }
4627 }
4628 $globs ||= [];
4629 $common_max += scalar @$globs;
4630 foreach my $glob (@$globs) {
4631 my @tmp = split m#/#, $glob->{path}->{left};
4632 my $p = '';
4633 foreach (@tmp) {
4634 $p .= length($p) ? "/$_" : $_;
4635 $common{$p} ||= 0;
4636 $common{$p}++;
4637 }
4638 }
4639
4640 my $longest_path = '';
4641 foreach (sort {length $b <=> length $a} keys %common) {
4642 if ($common{$_} == $common_max) {
4643 $longest_path = $_;
4644 last;
4645 }
4646 }
4647 $longest_path;
4648 }
4649
4650 sub gs_fetch_loop_common {
4651 my ($self, $base, $head, $gsv, $globs) = @_;
4652 return if ($base > $head);
4653 my $inc = $_log_window_size;
4654 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4655 my $longest_path = longest_common_path($gsv, $globs);
4656 my $ra_url = $self->{url};
4657 my $find_trailing_edge;
4658 while (1) {
4659 my %revs;
4660 my $err;
4661 my $err_handler = $SVN::Error::handler;
4662 $SVN::Error::handler = sub {
4663 ($err) = @_;
4664 skip_unknown_revs($err);
4665 };
4666 sub _cb {
4667 my ($paths, $r, $author, $date, $log) = @_;
4668 [ $paths,
4669 { author => $author, date => $date, log => $log } ];
4670 }
4671 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4672 sub { $revs{$_[1]} = _cb(@_) });
4673 if ($err) {
4674 print "Checked through r$max\r";
4675 } else {
4676 $find_trailing_edge = 1;
4677 }
4678 if ($err and $find_trailing_edge) {
4679 print STDERR "Path '$longest_path' ",
4680 "was probably deleted:\n",
4681 $err->expanded_message,
4682 "\nWill attempt to follow ",
4683 "revisions r$min .. r$max ",
4684 "committed before the deletion\n";
4685 my $hi = $max;
4686 while (--$hi >= $min) {
4687 my $ok;
4688 $self->get_log([$longest_path], $min, $hi,
4689 0, 1, 1, sub {
4690 $ok = $_[1];
4691 $revs{$_[1]} = _cb(@_) });
4692 if ($ok) {
4693 print STDERR "r$min .. r$ok OK\n";
4694 last;
4695 }
4696 }
4697 $find_trailing_edge = 0;
4698 }
4699 $SVN::Error::handler = $err_handler;
4700
4701 my %exists = map { $_->{path} => $_ } @$gsv;
4702 foreach my $r (sort {$a <=> $b} keys %revs) {
4703 my ($paths, $logged) = @{$revs{$r}};
4704
4705 foreach my $gs ($self->match_globs(\%exists, $paths,
4706 $globs, $r)) {
4707 if ($gs->rev_map_max >= $r) {
4708 next;
4709 }
4710 next unless $gs->match_paths($paths, $r);
4711 $gs->{logged_rev_props} = $logged;
4712 if (my $last_commit = $gs->last_commit) {
4713 $gs->assert_index_clean($last_commit);
4714 }
4715 my $log_entry = $gs->do_fetch($paths, $r);
4716 if ($log_entry) {
4717 $gs->do_git_commit($log_entry);
4718 }
4719 $INDEX_FILES{$gs->{index}} = 1;
4720 }
4721 foreach my $g (@$globs) {
4722 my $k = "svn-remote.$g->{remote}." .
4723 "$g->{t}-maxRev";
4724 Git::SVN::tmp_config($k, $r);
4725 }
4726 if ($ra_invalid) {
4727 $_[0] = undef;
4728 $self = undef;
4729 $RA = undef;
4730 $self = Git::SVN::Ra->new($ra_url);
4731 $ra_invalid = undef;
4732 }
4733 }
4734 # pre-fill the .rev_db since it'll eventually get filled in
4735 # with '0' x40 if something new gets committed
4736 foreach my $gs (@$gsv) {
4737 next if $gs->rev_map_max >= $max;
4738 next if defined $gs->rev_map_get($max);
4739 $gs->rev_map_set($max, 0 x40);
4740 }
4741 foreach my $g (@$globs) {
4742 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4743 Git::SVN::tmp_config($k, $max);
4744 }
4745 last if $max >= $head;
4746 $min = $max + 1;
4747 $max += $inc;
4748 $max = $head if ($max > $head);
4749 }
4750 Git::SVN::gc();
4751 }
4752
4753 sub get_dir_globbed {
4754 my ($self, $left, $depth, $r) = @_;
4755
4756 my @x = eval { $self->get_dir($left, $r) };
4757 return unless scalar @x == 3;
4758 my $dirents = $x[0];
4759 my @finalents;
4760 foreach my $de (keys %$dirents) {
4761 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4762 if ($depth > 1) {
4763 my @args = ("$left/$de", $depth - 1, $r);
4764 foreach my $dir ($self->get_dir_globbed(@args)) {
4765 push @finalents, "$de/$dir";
4766 }
4767 } else {
4768 push @finalents, $de;
4769 }
4770 }
4771 @finalents;
4772 }
4773
4774 sub match_globs {
4775 my ($self, $exists, $paths, $globs, $r) = @_;
4776
4777 sub get_dir_check {
4778 my ($self, $exists, $g, $r) = @_;
4779
4780 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4781 $g->{path}->{depth},
4782 $r);
4783
4784 foreach my $de (@dirs) {
4785 my $p = $g->{path}->full_path($de);
4786 next if $exists->{$p};
4787 next if (length $g->{path}->{right} &&
4788 ($self->check_path($p, $r) !=
4789 $SVN::Node::dir));
4790 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4791 $g->{ref}->full_path($de), 1);
4792 }
4793 }
4794 foreach my $g (@$globs) {
4795 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4796 if ($path->{action} =~ /^[AR]$/) {
4797 get_dir_check($self, $exists, $g, $r);
4798 }
4799 }
4800 foreach (keys %$paths) {
4801 if (/$g->{path}->{left_regex}/ &&
4802 !/$g->{path}->{regex}/) {
4803 next if $paths->{$_}->{action} !~ /^[AR]$/;
4804 get_dir_check($self, $exists, $g, $r);
4805 }
4806 next unless /$g->{path}->{regex}/;
4807 my $p = $1;
4808 my $pathname = $g->{path}->full_path($p);
4809 next if $exists->{$pathname};
4810 next if ($self->check_path($pathname, $r) !=
4811 $SVN::Node::dir);
4812 $exists->{$pathname} = Git::SVN->init(
4813 $self->{url}, $pathname, undef,
4814 $g->{ref}->full_path($p), 1);
4815 }
4816 my $c = '';
4817 foreach (split m#/#, $g->{path}->{left}) {
4818 $c .= "/$_";
4819 next unless ($paths->{$c} &&
4820 ($paths->{$c}->{action} =~ /^[AR]$/));
4821 get_dir_check($self, $exists, $g, $r);
4822 }
4823 }
4824 values %$exists;
4825 }
4826
4827 sub minimize_url {
4828 my ($self) = @_;
4829 return $self->{url} if ($self->{url} eq $self->{repos_root});
4830 my $url = $self->{repos_root};
4831 my @components = split(m!/!, $self->{svn_path});
4832 my $c = '';
4833 do {
4834 $url .= "/$c" if length $c;
4835 eval {
4836 my $ra = (ref $self)->new($url);
4837 my $latest = $ra->get_latest_revnum;
4838 $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
4839 };
4840 } while ($@ && ($c = shift @components));
4841 $url;
4842 }
4843
4844 sub can_do_switch {
4845 my $self = shift;
4846 unless (defined $can_do_switch) {
4847 my $pool = SVN::Pool->new;
4848 my $rep = eval {
4849 $self->do_switch(1, '', 0, $self->{url},
4850 SVN::Delta::Editor->new, $pool);
4851 };
4852 if ($@) {
4853 $can_do_switch = 0;
4854 } else {
4855 $rep->abort_report($pool);
4856 $can_do_switch = 1;
4857 }
4858 $pool->clear;
4859 }
4860 $can_do_switch;
4861 }
4862
4863 sub skip_unknown_revs {
4864 my ($err) = @_;
4865 my $errno = $err->apr_err();
4866 # Maybe the branch we're tracking didn't
4867 # exist when the repo started, so it's
4868 # not an error if it doesn't, just continue
4869 #
4870 # Wonderfully consistent library, eh?
4871 # 160013 - svn:// and file://
4872 # 175002 - http(s)://
4873 # 175007 - http(s):// (this repo required authorization, too...)
4874 # More codes may be discovered later...
4875 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4876 my $err_key = $err->expanded_message;
4877 # revision numbers change every time, filter them out
4878 $err_key =~ s/\d+/\0/g;
4879 $err_key = "$errno\0$err_key";
4880 unless ($ignored_err{$err_key}) {
4881 warn "W: Ignoring error from SVN, path probably ",
4882 "does not exist: ($errno): ",
4883 $err->expanded_message,"\n";
4884 warn "W: Do not be alarmed at the above message ",
4885 "git-svn is just searching aggressively for ",
4886 "old history.\n",
4887 "This may take a while on large repositories\n";
4888 $ignored_err{$err_key} = 1;
4889 }
4890 return;
4891 }
4892 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4893 }
4894
4895 package Git::SVN::Log;
4896 use strict;
4897 use warnings;
4898 use POSIX qw/strftime/;
4899 use Time::Local;
4900 use constant commit_log_separator => ('-' x 72) . "\n";
4901 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4902 %rusers $show_commit $incremental/;
4903 my $l_fmt;
4904
4905 sub cmt_showable {
4906 my ($c) = @_;
4907 return 1 if defined $c->{r};
4908
4909 # big commit message got truncated by the 16k pretty buffer in rev-list
4910 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4911 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4912 @{$c->{l}} = ();
4913 my @log = command(qw/cat-file commit/, $c->{c});
4914
4915 # shift off the headers
4916 shift @log while ($log[0] ne '');
4917 shift @log;
4918
4919 # TODO: make $c->{l} not have a trailing newline in the future
4920 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4921
4922 (undef, $c->{r}, undef) = ::extract_metadata(
4923 (grep(/^git-svn-id: /, @log))[-1]);
4924 }
4925 return defined $c->{r};
4926 }
4927
4928 sub log_use_color {
4929 return $color || Git->repository->get_colorbool('color.diff');
4930 }
4931
4932 sub git_svn_log_cmd {
4933 my ($r_min, $r_max, @args) = @_;
4934 my $head = 'HEAD';
4935 my (@files, @log_opts);
4936 foreach my $x (@args) {
4937 if ($x eq '--' || @files) {
4938 push @files, $x;
4939 } else {
4940 if (::verify_ref("$x^0")) {
4941 $head = $x;
4942 } else {
4943 push @log_opts, $x;
4944 }
4945 }
4946 }
4947
4948 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4949 $gs ||= Git::SVN->_new;
4950 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4951 $gs->refname);
4952 push @cmd, '-r' unless $non_recursive;
4953 push @cmd, qw/--raw --name-status/ if $verbose;
4954 push @cmd, '--color' if log_use_color();
4955 push @cmd, @log_opts;
4956 if (defined $r_max && $r_max == $r_min) {
4957 push @cmd, '--max-count=1';
4958 if (my $c = $gs->rev_map_get($r_max)) {
4959 push @cmd, $c;
4960 }
4961 } elsif (defined $r_max) {
4962 if ($r_max < $r_min) {
4963 ($r_min, $r_max) = ($r_max, $r_min);
4964 }
4965 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4966 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4967 # If there are no commits in the range, both $c_max and $c_min
4968 # will be undefined. If there is at least 1 commit in the
4969 # range, both will be defined.
4970 return () if !defined $c_min || !defined $c_max;
4971 if ($c_min eq $c_max) {
4972 push @cmd, '--max-count=1', $c_min;
4973 } else {
4974 push @cmd, '--boundary', "$c_min..$c_max";
4975 }
4976 }
4977 return (@cmd, @files);
4978 }
4979
4980 # adapted from pager.c
4981 sub config_pager {
4982 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4983 if (!defined $pager) {
4984 $pager = 'less';
4985 } elsif (length $pager == 0 || $pager eq 'cat') {
4986 $pager = undef;
4987 }
4988 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4989 }
4990
4991 sub run_pager {
4992 return unless -t *STDOUT && defined $pager;
4993 pipe my ($rfd, $wfd) or return;
4994 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4995 if (!$pid) {
4996 open STDOUT, '>&', $wfd or
4997 ::fatal "Can't redirect to stdout: $!";
4998 return;
4999 }
5000 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5001 $ENV{LESS} ||= 'FRSX';
5002 exec $pager or ::fatal "Can't run pager: $! ($pager)";
5003 }
5004
5005 sub format_svn_date {
5006 # some systmes don't handle or mishandle %z, so be creative.
5007 my $t = shift || time;
5008 my $gm = timelocal(gmtime($t));
5009 my $sign = qw( + + - )[ $t <=> $gm ];
5010 my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5011 return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5012 }
5013
5014 sub parse_git_date {
5015 my ($t, $tz) = @_;
5016 # Date::Parse isn't in the standard Perl distro :(
5017 if ($tz =~ s/^\+//) {
5018 $t += tz_to_s_offset($tz);
5019 } elsif ($tz =~ s/^\-//) {
5020 $t -= tz_to_s_offset($tz);
5021 }
5022 return $t;
5023 }
5024
5025 sub set_local_timezone {
5026 if (defined $TZ) {
5027 $ENV{TZ} = $TZ;
5028 } else {
5029 delete $ENV{TZ};
5030 }
5031 }
5032
5033 sub tz_to_s_offset {
5034 my ($tz) = @_;
5035 $tz =~ s/(\d\d)$//;
5036 return ($1 * 60) + ($tz * 3600);
5037 }
5038
5039 sub get_author_info {
5040 my ($dest, $author, $t, $tz) = @_;
5041 $author =~ s/(?:^\s*|\s*$)//g;
5042 $dest->{a_raw} = $author;
5043 my $au;
5044 if ($::_authors) {
5045 $au = $rusers{$author} || undef;
5046 }
5047 if (!$au) {
5048 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5049 }
5050 $dest->{t} = $t;
5051 $dest->{tz} = $tz;
5052 $dest->{a} = $au;
5053 $dest->{t_utc} = parse_git_date($t, $tz);
5054 }
5055
5056 sub process_commit {
5057 my ($c, $r_min, $r_max, $defer) = @_;
5058 if (defined $r_min && defined $r_max) {
5059 if ($r_min == $c->{r} && $r_min == $r_max) {
5060 show_commit($c);
5061 return 0;
5062 }
5063 return 1 if $r_min == $r_max;
5064 if ($r_min < $r_max) {
5065 # we need to reverse the print order
5066 return 0 if (defined $limit && --$limit < 0);
5067 push @$defer, $c;
5068 return 1;
5069 }
5070 if ($r_min != $r_max) {
5071 return 1 if ($r_min < $c->{r});
5072 return 1 if ($r_max > $c->{r});
5073 }
5074 }
5075 return 0 if (defined $limit && --$limit < 0);
5076 show_commit($c);
5077 return 1;
5078 }
5079
5080 sub show_commit {
5081 my $c = shift;
5082 if ($oneline) {
5083 my $x = "\n";
5084 if (my $l = $c->{l}) {
5085 while ($l->[0] =~ /^\s*$/) { shift @$l }
5086 $x = $l->[0];
5087 }
5088 $l_fmt ||= 'A' . length($c->{r});
5089 print 'r',pack($l_fmt, $c->{r}),' | ';
5090 print "$c->{c} | " if $show_commit;
5091 print $x;
5092 } else {
5093 show_commit_normal($c);
5094 }
5095 }
5096
5097 sub show_commit_changed_paths {
5098 my ($c) = @_;
5099 return unless $c->{changed};
5100 print "Changed paths:\n", @{$c->{changed}};
5101 }
5102
5103 sub show_commit_normal {
5104 my ($c) = @_;
5105 print commit_log_separator, "r$c->{r} | ";
5106 print "$c->{c} | " if $show_commit;
5107 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5108 my $nr_line = 0;
5109
5110 if (my $l = $c->{l}) {
5111 while ($l->[$#$l] eq "\n" && $#$l > 0
5112 && $l->[($#$l - 1)] eq "\n") {
5113 pop @$l;
5114 }
5115 $nr_line = scalar @$l;
5116 if (!$nr_line) {
5117 print "1 line\n\n\n";
5118 } else {
5119 if ($nr_line == 1) {
5120 $nr_line = '1 line';
5121 } else {
5122 $nr_line .= ' lines';
5123 }
5124 print $nr_line, "\n";
5125 show_commit_changed_paths($c);
5126 print "\n";
5127 print $_ foreach @$l;
5128 }
5129 } else {
5130 print "1 line\n";
5131 show_commit_changed_paths($c);
5132 print "\n";
5133
5134 }
5135 foreach my $x (qw/raw stat diff/) {
5136 if ($c->{$x}) {
5137 print "\n";
5138 print $_ foreach @{$c->{$x}}
5139 }
5140 }
5141 }
5142
5143 sub cmd_show_log {
5144 my (@args) = @_;
5145 my ($r_min, $r_max);
5146 my $r_last = -1; # prevent dupes
5147 set_local_timezone();
5148 if (defined $::_revision) {
5149 if ($::_revision =~ /^(\d+):(\d+)$/) {
5150 ($r_min, $r_max) = ($1, $2);
5151 } elsif ($::_revision =~ /^\d+$/) {
5152 $r_min = $r_max = $::_revision;
5153 } else {
5154 ::fatal "-r$::_revision is not supported, use ",
5155 "standard 'git log' arguments instead";
5156 }
5157 }
5158
5159 config_pager();
5160 @args = git_svn_log_cmd($r_min, $r_max, @args);
5161 if (!@args) {
5162 print commit_log_separator unless $incremental || $oneline;
5163 return;
5164 }
5165 my $log = command_output_pipe(@args);
5166 run_pager();
5167 my (@k, $c, $d, $stat);
5168 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5169 while (<$log>) {
5170 if (/^${esc_color}commit -?($::sha1_short)/o) {
5171 my $cmt = $1;
5172 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5173 $r_last = $c->{r};
5174 process_commit($c, $r_min, $r_max, \@k) or
5175 goto out;
5176 }
5177 $d = undef;
5178 $c = { c => $cmt };
5179 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5180 get_author_info($c, $1, $2, $3);
5181 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5182 # ignore
5183 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5184 push @{$c->{raw}}, $_;
5185 } elsif (/^${esc_color}[ACRMDT]\t/) {
5186 # we could add $SVN->{svn_path} here, but that requires
5187 # remote access at the moment (repo_path_split)...
5188 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
5189 push @{$c->{changed}}, $_;
5190 } elsif (/^${esc_color}diff /o) {
5191 $d = 1;
5192 push @{$c->{diff}}, $_;
5193 } elsif ($d) {
5194 push @{$c->{diff}}, $_;
5195 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5196 $esc_color*[\+\-]*$esc_color$/x) {
5197 $stat = 1;
5198 push @{$c->{stat}}, $_;
5199 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5200 push @{$c->{stat}}, $_;
5201 $stat = undef;
5202 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
5203 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5204 } elsif (s/^${esc_color} //o) {
5205 push @{$c->{l}}, $_;
5206 }
5207 }
5208 if ($c && defined $c->{r} && $c->{r} != $r_last) {
5209 $r_last = $c->{r};
5210 process_commit($c, $r_min, $r_max, \@k);
5211 }
5212 if (@k) {
5213 ($r_min, $r_max) = ($r_max, $r_min);
5214 process_commit($_, $r_min, $r_max) foreach reverse @k;
5215 }
5216 out:
5217 close $log;
5218 print commit_log_separator unless $incremental || $oneline;
5219 }
5220
5221 sub cmd_blame {
5222 my $path = pop;
5223
5224 config_pager();
5225 run_pager();
5226
5227 my ($fh, $ctx, $rev);
5228
5229 if ($_git_format) {
5230 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5231 while (my $line = <$fh>) {
5232 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5233 # Uncommitted edits show up as a rev ID of
5234 # all zeros, which we can't look up with
5235 # cmt_metadata
5236 if ($1 !~ /^0+$/) {
5237 (undef, $rev, undef) =
5238 ::cmt_metadata($1);
5239 $rev = '0' if (!$rev);
5240 } else {
5241 $rev = '0';
5242 }
5243 $rev = sprintf('%-10s', $rev);
5244 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5245 }
5246 print $line;
5247 }
5248 } else {
5249 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5250 '--', $path);
5251 my ($sha1);
5252 my %authors;
5253 my @buffer;
5254 my %dsha; #distinct sha keys
5255
5256 while (my $line = <$fh>) {
5257 push @buffer, $line;
5258 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5259 $dsha{$1} = 1;
5260 }
5261 }
5262
5263 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5264
5265 foreach my $line (@buffer) {
5266 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5267 $rev = $s2r->{$1};
5268 $rev = '0' if (!$rev)
5269 }
5270 elsif ($line =~ /^author (.*)/) {
5271 $authors{$rev} = $1;
5272 $authors{$rev} =~ s/\s/_/g;
5273 }
5274 elsif ($line =~ /^\t(.*)$/) {
5275 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5276 }
5277 }
5278 }
5279 command_close_pipe($fh, $ctx);
5280 }
5281
5282 package Git::SVN::Migration;
5283 # these version numbers do NOT correspond to actual version numbers
5284 # of git nor git-svn. They are just relative.
5285 #
5286 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5287 #
5288 # v1 layout: .git/$id/info/url, refs/remotes/$id
5289 #
5290 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5291 #
5292 # v3 layout: .git/svn/$id, refs/remotes/$id
5293 # - info/url may remain for backwards compatibility
5294 # - this is what we migrate up to this layout automatically,
5295 # - this will be used by git svn init on single branches
5296 # v3.1 layout (auto migrated):
5297 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5298 # for backwards compatibility
5299 #
5300 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5301 # - this is only created for newly multi-init-ed
5302 # repositories. Similar in spirit to the
5303 # --use-separate-remotes option in git-clone (now default)
5304 # - we do not automatically migrate to this (following
5305 # the example set by core git)
5306 #
5307 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5308 # - newer, more-efficient format that uses 24-bytes per record
5309 # with no filler space.
5310 # - use xxd -c24 < .rev_map.$UUID to view and debug
5311 # - This is a one-way migration, repositories updated to the
5312 # new format will not be able to use old git-svn without
5313 # rebuilding the .rev_db. Rebuilding the rev_db is not
5314 # possible if noMetadata or useSvmProps are set; but should
5315 # be no problem for users that use the (sensible) defaults.
5316 use strict;
5317 use warnings;
5318 use Carp qw/croak/;
5319 use File::Path qw/mkpath/;
5320 use File::Basename qw/dirname basename/;
5321 use vars qw/$_minimize/;
5322
5323 sub migrate_from_v0 {
5324 my $git_dir = $ENV{GIT_DIR};
5325 return undef unless -d $git_dir;
5326 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5327 my $migrated = 0;
5328 while (<$fh>) {
5329 chomp;
5330 my ($id, $orig_ref) = ($_, $_);
5331 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5332 next unless -f "$git_dir/$id/info/url";
5333 my $new_ref = "refs/remotes/$id";
5334 if (::verify_ref("$new_ref^0")) {
5335 print STDERR "W: $orig_ref is probably an old ",
5336 "branch used by an ancient version of ",
5337 "git-svn.\n",
5338 "However, $new_ref also exists.\n",
5339 "We will not be able ",
5340 "to use this branch until this ",
5341 "ambiguity is resolved.\n";
5342 next;
5343 }
5344 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5345 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5346 command_noisy('update-ref', $new_ref, $orig_ref);
5347 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5348 $migrated++;
5349 }
5350 command_close_pipe($fh, $ctx);
5351 print STDERR "Done migrating from v0 layout...\n" if $migrated;
5352 $migrated;
5353 }
5354
5355 sub migrate_from_v1 {
5356 my $git_dir = $ENV{GIT_DIR};
5357 my $migrated = 0;
5358 return $migrated unless -d $git_dir;
5359 my $svn_dir = "$git_dir/svn";
5360
5361 # just in case somebody used 'svn' as their $id at some point...
5362 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5363
5364 print STDERR "Migrating from a git-svn v1 layout...\n";
5365 mkpath([$svn_dir]);
5366 print STDERR "Data from a previous version of git-svn exists, but\n\t",
5367 "$svn_dir\n\t(required for this version ",
5368 "($::VERSION) of git-svn) does not exist.\n";
5369 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5370 while (<$fh>) {
5371 my $x = $_;
5372 next unless $x =~ s#^refs/remotes/##;
5373 chomp $x;
5374 next unless -f "$git_dir/$x/info/url";
5375 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5376 next unless $u;
5377 my $dn = dirname("$git_dir/svn/$x");
5378 mkpath([$dn]) unless -d $dn;
5379 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5380 mkpath(["$git_dir/svn/svn"]);
5381 print STDERR " - $git_dir/$x/info => ",
5382 "$git_dir/svn/$x/info\n";
5383 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5384 croak "$!: $x";
5385 # don't worry too much about these, they probably
5386 # don't exist with repos this old (save for index,
5387 # and we can easily regenerate that)
5388 foreach my $f (qw/unhandled.log index .rev_db/) {
5389 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5390 }
5391 } else {
5392 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5393 rename "$git_dir/$x", "$git_dir/svn/$x" or
5394 croak "$!: $x";
5395 }
5396 $migrated++;
5397 }
5398 command_close_pipe($fh, $ctx);
5399 print STDERR "Done migrating from a git-svn v1 layout\n";
5400 $migrated;
5401 }
5402
5403 sub read_old_urls {
5404 my ($l_map, $pfx, $path) = @_;
5405 my @dir;
5406 foreach (<$path/*>) {
5407 if (-r "$_/info/url") {
5408 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5409 my $ref_id = $pfx . basename $_;
5410 my $url = ::file_to_s("$_/info/url");
5411 $l_map->{$ref_id} = $url;
5412 } elsif (-d $_) {
5413 push @dir, $_;
5414 }
5415 }
5416 foreach (@dir) {
5417 my $x = $_;
5418 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5419 read_old_urls($l_map, $x, $_);
5420 }
5421 }
5422
5423 sub migrate_from_v2 {
5424 my @cfg = command(qw/config -l/);
5425 return if grep /^svn-remote\..+\.url=/, @cfg;
5426 my %l_map;
5427 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5428 my $migrated = 0;
5429
5430 foreach my $ref_id (sort keys %l_map) {
5431 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5432 if ($@) {
5433 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5434 }
5435 $migrated++;
5436 }
5437 $migrated;
5438 }
5439
5440 sub minimize_connections {
5441 my $r = Git::SVN::read_all_remotes();
5442 my $new_urls = {};
5443 my $root_repos = {};
5444 foreach my $repo_id (keys %$r) {
5445 my $url = $r->{$repo_id}->{url} or next;
5446 my $fetch = $r->{$repo_id}->{fetch} or next;
5447 my $ra = Git::SVN::Ra->new($url);
5448
5449 # skip existing cases where we already connect to the root
5450 if (($ra->{url} eq $ra->{repos_root}) ||
5451 ($ra->{repos_root} eq $repo_id)) {
5452 $root_repos->{$ra->{url}} = $repo_id;
5453 next;
5454 }
5455
5456 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5457 my $root_path = $ra->{url};
5458 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5459 foreach my $path (keys %$fetch) {
5460 my $ref_id = $fetch->{$path};
5461 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5462
5463 # make sure we can read when connecting to
5464 # a higher level of a repository
5465 my ($last_rev, undef) = $gs->last_rev_commit;
5466 if (!defined $last_rev) {
5467 $last_rev = eval {
5468 $root_ra->get_latest_revnum;
5469 };
5470 next if $@;
5471 }
5472 my $new = $root_path;
5473 $new .= length $path ? "/$path" : '';
5474 eval {
5475 $root_ra->get_log([$new], $last_rev, $last_rev,
5476 0, 0, 1, sub { });
5477 };
5478 next if $@;
5479 $new_urls->{$ra->{repos_root}}->{$new} =
5480 { ref_id => $ref_id,
5481 old_repo_id => $repo_id,
5482 old_path => $path };
5483 }
5484 }
5485
5486 my @emptied;
5487 foreach my $url (keys %$new_urls) {
5488 # see if we can re-use an existing [svn-remote "repo_id"]
5489 # instead of creating a(n ugly) new section:
5490 my $repo_id = $root_repos->{$url} || $url;
5491
5492 my $fetch = $new_urls->{$url};
5493 foreach my $path (keys %$fetch) {
5494 my $x = $fetch->{$path};
5495 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5496 my $pfx = "svn-remote.$x->{old_repo_id}";
5497
5498 my $old_fetch = quotemeta("$x->{old_path}:".
5499 "refs/remotes/$x->{ref_id}");
5500 command_noisy(qw/config --unset/,
5501 "$pfx.fetch", '^'. $old_fetch . '$');
5502 delete $r->{$x->{old_repo_id}}->
5503 {fetch}->{$x->{old_path}};
5504 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5505 command_noisy(qw/config --unset/,
5506 "$pfx.url");
5507 push @emptied, $x->{old_repo_id}
5508 }
5509 }
5510 }
5511 if (@emptied) {
5512 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5513 print STDERR <<EOF;
5514 The following [svn-remote] sections in your config file ($file) are empty
5515 and can be safely removed:
5516 EOF
5517 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5518 }
5519 }
5520
5521 sub migration_check {
5522 migrate_from_v0();
5523 migrate_from_v1();
5524 migrate_from_v2();
5525 minimize_connections() if $_minimize;
5526 }
5527
5528 package Git::IndexInfo;
5529 use strict;
5530 use warnings;
5531 use Git qw/command_input_pipe command_close_pipe/;
5532
5533 sub new {
5534 my ($class) = @_;
5535 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5536 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5537 }
5538
5539 sub remove {
5540 my ($self, $path) = @_;
5541 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5542 return ++$self->{nr};
5543 }
5544 undef;
5545 }
5546
5547 sub update {
5548 my ($self, $mode, $hash, $path) = @_;
5549 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5550 return ++$self->{nr};
5551 }
5552 undef;
5553 }
5554
5555 sub DESTROY {
5556 my ($self) = @_;
5557 command_close_pipe($self->{gui}, $self->{ctx});
5558 }
5559
5560 package Git::SVN::GlobSpec;
5561 use strict;
5562 use warnings;
5563
5564 sub new {
5565 my ($class, $glob) = @_;
5566 my $re = $glob;
5567 $re =~ s!/+$!!g; # no need for trailing slashes
5568 $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5569 my $temp = $re;
5570 my ($left, $right) = ($1, $3);
5571 $re = $2;
5572 my $depth = $re =~ tr/*/*/;
5573 if ($depth != $temp =~ tr/*/*/) {
5574 die "Only one set of wildcard directories " .
5575 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5576 }
5577 if ($depth == 0) {
5578 die "One '*' is needed for glob: '$glob'\n";
5579 }
5580 $re =~ s!\*!\[^/\]*!g;
5581 $re = quotemeta($left) . "($re)" . quotemeta($right);
5582 if (length $left && !($left =~ s!/+$!!g)) {
5583 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5584 }
5585 if (length $right && !($right =~ s!^/+!!g)) {
5586 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5587 }
5588 my $left_re = qr/^\/\Q$left\E(\/|$)/;
5589 bless { left => $left, right => $right, left_regex => $left_re,
5590 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5591 }
5592
5593 sub full_path {
5594 my ($self, $path) = @_;
5595 return (length $self->{left} ? "$self->{left}/" : '') .
5596 $path . (length $self->{right} ? "/$self->{right}" : '');
5597 }
5598
5599 __END__
5600
5601 Data structures:
5602
5603
5604 $remotes = { # returned by read_all_remotes()
5605 'svn' => {
5606 # svn-remote.svn.url=https://svn.musicpd.org
5607 url => 'https://svn.musicpd.org',
5608 # svn-remote.svn.fetch=mpd/trunk:trunk
5609 fetch => {
5610 'mpd/trunk' => 'trunk',
5611 },
5612 # svn-remote.svn.tags=mpd/tags/*:tags/*
5613 tags => {
5614 path => {
5615 left => 'mpd/tags',
5616 right => '',
5617 regex => qr!mpd/tags/([^/]+)$!,
5618 glob => 'tags/*',
5619 },
5620 ref => {
5621 left => 'tags',
5622 right => '',
5623 regex => qr!tags/([^/]+)$!,
5624 glob => 'tags/*',
5625 },
5626 }
5627 }
5628 };
5629
5630 $log_entry hashref as returned by libsvn_log_entry()
5631 {
5632 log => 'whitespace-formatted log entry
5633 ', # trailing newline is preserved
5634 revision => '8', # integer
5635 date => '2004-02-24T17:01:44.108345Z', # commit date
5636 author => 'committer name'
5637 };
5638
5639
5640 # this is generated by generate_diff();
5641 @mods = array of diff-index line hashes, each element represents one line
5642 of diff-index output
5643
5644 diff-index line ($m hash)
5645 {
5646 mode_a => first column of diff-index output, no leading ':',
5647 mode_b => second column of diff-index output,
5648 sha1_b => sha1sum of the final blob,
5649 chg => change type [MCRADT],
5650 file_a => original file name of a file (iff chg is 'C' or 'R')
5651 file_b => new/current file name of a file (any chg)
5652 }
5653 ;
5654
5655 # retval of read_url_paths{,_all}();
5656 $l_map = {
5657 # repository root url
5658 'https://svn.musicpd.org' => {
5659 # repository path # GIT_SVN_ID
5660 'mpd/trunk' => 'trunk',
5661 'mpd/tags/0.11.5' => 'tags/0.11.5',
5662 },
5663 }
5664
5665 Notes:
5666 I don't trust the each() function on unless I created %hash myself
5667 because the internal iterator may not have started at base.
kusma's git playground