git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42
  43   Composing:
  44     --from                  <str>  * Email From:
  45     --to                    <str>  * Email To:
  46     --cc                    <str>  * Email Cc:
  47     --bcc                   <str>  * Email Bcc:
  48     --subject               <str>  * Email "Subject:"
  49     --in-reply-to           <str>  * Email "In-Reply-To:"
  50     --compose                      * Open an editor for introduction.
  51
  52   Sending:
  53     --envelope-sender       <str>  * Email envelope sender.
  54     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  55                                      is optional. Default 'localhost'.
  56     --smtp-server-port      <int>  * Outgoing SMTP server port.
  57     --smtp-user             <str>  * Username for SMTP-AUTH.
  58     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  59     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  60     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  61
  62   Automating:
  63     --identity              <str>  * Use the sendemail.<id> options.
  64     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  65     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  66     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  67                                      addresses. Default on.
  68     --[no-]suppress-from           * Send to self. Default off.
  69     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  70     --[no-]thread                  * Use In-Reply-To: field. Default on.
  71
  72   Administering:
  73     --quiet                        * Output one line of info per email.
  74     --dry-run                      * Don't actually send the emails.
  75     --[no-]validate                * Perform patch sanity checks. Default on.
  76
  77 EOT
  78         exit(1);
  79 }
  80
  81 # most mail servers generate the Date: header, but not all...
  82 sub format_2822_time {
  83         my ($time) = @_;
  84         my @localtm = localtime($time);
  85         my @gmttm = gmtime($time);
  86         my $localmin = $localtm[1] + $localtm[2] * 60;
  87         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  88         if ($localtm[0] != $gmttm[0]) {
  89                 die "local zone differs from GMT by a non-minute interval\n";
  90         }
  91         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
  92                 $localmin += 1440;
  93         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
  94                 $localmin -= 1440;
  95         } elsif ($gmttm[6] != $localtm[6]) {
  96                 die "local time offset greater than or equal to 24 hours\n";
  97         }
  98         my $offset = $localmin - $gmtmin;
  99         my $offhour = $offset / 60;
 100         my $offmin = abs($offset % 60);
 101         if (abs($offhour) >= 24) {
 102                 die ("local time offset greater than or equal to 24 hours\n");
 103         }
 104
 105         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 106                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 107                        $localtm[3],
 108                        qw(Jan Feb Mar Apr May Jun
 109                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 110                        $localtm[5]+1900,
 111                        $localtm[2],
 112                        $localtm[1],
 113                        $localtm[0],
 114                        ($offset >= 0) ? '+' : '-',
 115                        abs($offhour),
 116                        $offmin,
 117                        );
 118 }
 119
 120 my $have_email_valid = eval { require Email::Valid; 1 };
 121 my $smtp;
 122 my $auth;
 123
 124 sub unique_email_list(@);
 125 sub cleanup_compose_files();
 126
 127 # Constants (essentially)
 128 my $compose_filename = ".msg.$$";
 129
 130 # Variables we fill in automatically, or via prompting:
 131 my (@to,@cc,@initial_cc,@bcclist,@xh,
 132         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 133
 134 my $envelope_sender;
 135
 136 # Example reply to:
 137 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 138
 139 my $repo = eval { Git->repository() };
 140 my @repo = $repo ? ($repo) : ();
 141 my $term = eval {
 142         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 143                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 144                 : new Term::ReadLine 'git-send-email';
 145 };
 146 if ($@) {
 147         $term = new FakeTerm "$@: going non-interactive";
 148 }
 149
 150 # Behavior modification variables
 151 my ($quiet, $dry_run) = (0, 0);
 152
 153 # Variables with corresponding config settings
 154 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 155 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 156 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 157 my ($validate);
 158 my (@suppress_cc);
 159
 160 my %config_bool_settings = (
 161     "thread" => [\$thread, 1],
 162     "chainreplyto" => [\$chain_reply_to, 1],
 163     "suppressfrom" => [\$suppress_from, undef],
 164     "signedoffbycc" => [\$signed_off_by_cc, undef],
 165     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 166     "validate" => [\$validate, 1],
 167 );
 168
 169 my %config_settings = (
 170     "smtpserver" => \$smtp_server,
 171     "smtpserverport" => \$smtp_server_port,
 172     "smtpuser" => \$smtp_authuser,
 173     "smtppass" => \$smtp_authpass,
 174     "to" => \@to,
 175     "cc" => \@initial_cc,
 176     "cccmd" => \$cc_cmd,
 177     "aliasfiletype" => \$aliasfiletype,
 178     "bcc" => \@bcclist,
 179     "aliasesfile" => \@alias_files,
 180     "suppresscc" => \@suppress_cc,
 181     "envelopesender" => \$envelope_sender,
 182 );
 183
 184 # Handle Uncouth Termination
 185 sub signal_handler {
 186
 187         # Make text normal
 188         print color("reset"), "\n";
 189
 190         # SMTP password masked
 191         system "stty echo";
 192
 193         # tmp files from --compose
 194         if (-e $compose_filename) {
 195                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 196         }
 197         if (-e ($compose_filename . ".final")) {
 198                 print "'$compose_filename.final' contains the composed email.\n"
 199         }
 200
 201         exit;
 202 };
 203
 204 $SIG{TERM} = \&signal_handler;
 205 $SIG{INT}  = \&signal_handler;
 206
 207 # Begin by accumulating all the variables (defined above), that we will end up
 208 # needing, first, from the command line:
 209
 210 my $rc = GetOptions("sender|from=s" => \$sender,
 211                     "in-reply-to=s" => \$initial_reply_to,
 212                     "subject=s" => \$initial_subject,
 213                     "to=s" => \@to,
 214                     "cc=s" => \@initial_cc,
 215                     "bcc=s" => \@bcclist,
 216                     "chain-reply-to!" => \$chain_reply_to,
 217                     "smtp-server=s" => \$smtp_server,
 218                     "smtp-server-port=s" => \$smtp_server_port,
 219                     "smtp-user=s" => \$smtp_authuser,
 220                     "smtp-pass:s" => \$smtp_authpass,
 221                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 222                     "smtp-encryption=s" => \$smtp_encryption,
 223                     "identity=s" => \$identity,
 224                     "compose" => \$compose,
 225                     "quiet" => \$quiet,
 226                     "cc-cmd=s" => \$cc_cmd,
 227                     "suppress-from!" => \$suppress_from,
 228                     "suppress-cc=s" => \@suppress_cc,
 229                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 230                     "dry-run" => \$dry_run,
 231                     "envelope-sender=s" => \$envelope_sender,
 232                     "thread!" => \$thread,
 233                     "validate!" => \$validate,
 234          );
 235
 236 unless ($rc) {
 237     usage();
 238 }
 239
 240 # Now, let's fill any that aren't set in with defaults:
 241
 242 sub read_config {
 243         my ($prefix) = @_;
 244
 245         foreach my $setting (keys %config_bool_settings) {
 246                 my $target = $config_bool_settings{$setting}->[0];
 247                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 248         }
 249
 250         foreach my $setting (keys %config_settings) {
 251                 my $target = $config_settings{$setting};
 252                 if (ref($target) eq "ARRAY") {
 253                         unless (@$target) {
 254                                 my @values = Git::config(@repo, "$prefix.$setting");
 255                                 @$target = @values if (@values && defined $values[0]);
 256                         }
 257                 }
 258                 else {
 259                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 260                 }
 261         }
 262
 263         if (!defined $smtp_encryption) {
 264                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 265                 if (defined $enc) {
 266                         $smtp_encryption = $enc;
 267                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 268                         $smtp_encryption = 'ssl';
 269                 }
 270         }
 271 }
 272
 273 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 274 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 275 read_config("sendemail.$identity") if (defined $identity);
 276 read_config("sendemail");
 277
 278 # fall back on builtin bool defaults
 279 foreach my $setting (values %config_bool_settings) {
 280         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 281 }
 282
 283 # 'default' encryption is none -- this only prevents a warning
 284 $smtp_encryption = '' unless (defined $smtp_encryption);
 285
 286 # Set CC suppressions
 287 my(%suppress_cc);
 288 if (@suppress_cc) {
 289         foreach my $entry (@suppress_cc) {
 290                 die "Unknown --suppress-cc field: '$entry'\n"
 291                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 292                 $suppress_cc{$entry} = 1;
 293         }
 294 }
 295
 296 if ($suppress_cc{'all'}) {
 297         foreach my $entry (qw (ccmd cc author self sob)) {
 298                 $suppress_cc{$entry} = 1;
 299         }
 300         delete $suppress_cc{'all'};
 301 }
 302
 303 # If explicit old-style ones are specified, they trump --suppress-cc.
 304 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 305 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 306
 307 # Debugging, print out the suppressions.
 308 if (0) {
 309         print "suppressions:\n";
 310         foreach my $entry (keys %suppress_cc) {
 311                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 312         }
 313 }
 314
 315 my ($repoauthor, $repocommitter);
 316 ($repoauthor) = Git::ident_person(@repo, 'author');
 317 ($repocommitter) = Git::ident_person(@repo, 'committer');
 318
 319 # Verify the user input
 320
 321 foreach my $entry (@to) {
 322         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 323 }
 324
 325 foreach my $entry (@initial_cc) {
 326         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 327 }
 328
 329 foreach my $entry (@bcclist) {
 330         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 331 }
 332
 333 my %aliases;
 334 my %parse_alias = (
 335         # multiline formats can be supported in the future
 336         mutt => sub { my $fh = shift; while (<$fh>) {
 337                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 338                         my ($alias, $addr) = ($1, $2);
 339                         $addr =~ s/#.*$//; # mutt allows # comments
 340                          # commas delimit multiple addresses
 341                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 342                 }}},
 343         mailrc => sub { my $fh = shift; while (<$fh>) {
 344                 if (/^alias\s+(\S+)\s+(.*)$/) {
 345                         # spaces delimit multiple addresses
 346                         $aliases{$1} = [ split(/\s+/, $2) ];
 347                 }}},
 348         pine => sub { my $fh = shift; while (<$fh>) {
 349                 if (/^(\S+)\t.*\t(.*)$/) {
 350                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 351                 }}},
 352         gnus => sub { my $fh = shift; while (<$fh>) {
 353                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 354                         $aliases{$1} = [ $2 ];
 355                 }}}
 356 );
 357
 358 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 359         foreach my $file (@alias_files) {
 360                 open my $fh, '<', $file or die "opening $file: $!\n";
 361                 $parse_alias{$aliasfiletype}->($fh);
 362                 close $fh;
 363         }
 364 }
 365
 366 ($sender) = expand_aliases($sender) if defined $sender;
 367
 368 # Now that all the defaults are set, process the rest of the command line
 369 # arguments and collect up the files that need to be processed.
 370 for my $f (@ARGV) {
 371         if (-d $f) {
 372                 opendir(DH,$f)
 373                         or die "Failed to opendir $f: $!";
 374
 375                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 376                                 sort readdir(DH);
 377
 378         } elsif (-f $f or -p $f) {
 379                 push @files, $f;
 380
 381         } else {
 382                 print STDERR "Skipping $f - not found.\n";
 383         }
 384 }
 385
 386 if ($validate) {
 387         foreach my $f (@files) {
 388                 unless (-p $f) {
 389                         my $error = validate_patch($f);
 390                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 391                 }
 392         }
 393 }
 394
 395 if (@files) {
 396         unless ($quiet) {
 397                 print $_,"\n" for (@files);
 398         }
 399 } else {
 400         print STDERR "\nNo patch files specified!\n\n";
 401         usage();
 402 }
 403
 404 my $prompting = 0;
 405 if (!defined $sender) {
 406         $sender = $repoauthor || $repocommitter || '';
 407
 408         while (1) {
 409                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 410                 last if defined $_;
 411                 print "\n";
 412         }
 413
 414         $sender = $_ if ($_);
 415         print "Emails will be sent from: ", $sender, "\n";
 416         $prompting++;
 417 }
 418
 419 if (!@to) {
 420
 421
 422         while (1) {
 423                 $_ = $term->readline("Who should the emails be sent to? ", "");
 424                 last if defined $_;
 425                 print "\n";
 426         }
 427
 428         my $to = $_;
 429         push @to, split /,\s*/, $to;
 430         $prompting++;
 431 }
 432
 433 sub expand_aliases {
 434         my @cur = @_;
 435         my @last;
 436         do {
 437                 @last = @cur;
 438                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 439         } while (join(',',@cur) ne join(',',@last));
 440         return @cur;
 441 }
 442
 443 @to = expand_aliases(@to);
 444 @to = (map { sanitize_address($_) } @to);
 445 @initial_cc = expand_aliases(@initial_cc);
 446 @bcclist = expand_aliases(@bcclist);
 447
 448 if (!defined $initial_subject && $compose) {
 449         while (1) {
 450                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 451                 last if defined $_;
 452                 print "\n";
 453         }
 454
 455         $initial_subject = $_;
 456         $prompting++;
 457 }
 458
 459 if ($thread && !defined $initial_reply_to && $prompting) {
 460         while (1) {
 461                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 462                 last if defined $_;
 463                 print "\n";
 464         }
 465
 466         $initial_reply_to = $_;
 467 }
 468 if (defined $initial_reply_to) {
 469         $initial_reply_to =~ s/^\s*<?//;
 470         $initial_reply_to =~ s/>?\s*$//;
 471         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 472 }
 473
 474 if (!defined $smtp_server) {
 475         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 476                 if (-x $_) {
 477                         $smtp_server = $_;
 478                         last;
 479                 }
 480         }
 481         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 482 }
 483
 484 if ($compose) {
 485         # Note that this does not need to be secure, but we will make a small
 486         # effort to have it be unique
 487         open(C,">",$compose_filename)
 488                 or die "Failed to open for writing $compose_filename: $!";
 489         print C "From $sender # This line is ignored.\n";
 490         printf C "Subject: %s\n\n", $initial_subject;
 491         printf C <<EOT;
 492 GIT: Please enter your email below.
 493 GIT: Lines beginning in "GIT: " will be removed.
 494 GIT: Consider including an overall diffstat or table of contents
 495 GIT: for the patch you are writing.
 496
 497 EOT
 498         close(C);
 499
 500         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 501         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 502
 503         open(C2,">",$compose_filename . ".final")
 504                 or die "Failed to open $compose_filename.final : " . $!;
 505
 506         open(C,"<",$compose_filename)
 507                 or die "Failed to open $compose_filename : " . $!;
 508
 509         my $need_8bit_cte = file_has_nonascii($compose_filename);
 510         my $in_body = 0;
 511         while(<C>) {
 512                 next if m/^GIT: /;
 513                 if (!$in_body && /^\n$/) {
 514                         $in_body = 1;
 515                         if ($need_8bit_cte) {
 516                                 print C2 "MIME-Version: 1.0\n",
 517                                          "Content-Type: text/plain; ",
 518                                            "charset=utf-8\n",
 519                                          "Content-Transfer-Encoding: 8bit\n";
 520                         }
 521                 }
 522                 if (!$in_body && /^MIME-Version:/i) {
 523                         $need_8bit_cte = 0;
 524                 }
 525                 if (!$in_body && /^Subject: ?(.*)/i) {
 526                         my $subject = $1;
 527                         $_ = "Subject: " .
 528                                 ($subject =~ /[^[:ascii:]]/ ?
 529                                  quote_rfc2047($subject) :
 530                                  $subject) .
 531                                 "\n";
 532                 }
 533                 print C2 $_;
 534         }
 535         close(C);
 536         close(C2);
 537
 538         while (1) {
 539                 $_ = $term->readline("Send this email? (y|n) ");
 540                 last if defined $_;
 541                 print "\n";
 542         }
 543
 544         if (uc substr($_,0,1) ne 'Y') {
 545                 cleanup_compose_files();
 546                 exit(0);
 547         }
 548
 549         @files = ($compose_filename . ".final", @files);
 550 }
 551
 552 # Variables we set as part of the loop over files
 553 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 554
 555 sub extract_valid_address {
 556         my $address = shift;
 557         my $local_part_regexp = '[^<>"\s@]+';
 558         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 559
 560         # check for a local address:
 561         return $address if ($address =~ /^($local_part_regexp)$/);
 562
 563         $address =~ s/^\s*<(.*)>\s*$/$1/;
 564         if ($have_email_valid) {
 565                 return scalar Email::Valid->address($address);
 566         } else {
 567                 # less robust/correct than the monster regexp in Email::Valid,
 568                 # but still does a 99% job, and one less dependency
 569                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 570                 return $1;
 571         }
 572 }
 573
 574 # Usually don't need to change anything below here.
 575
 576 # we make a "fake" message id by taking the current number
 577 # of seconds since the beginning of Unix time and tacking on
 578 # a random number to the end, in case we are called quicker than
 579 # 1 second since the last time we were called.
 580
 581 # We'll setup a template for the message id, using the "from" address:
 582
 583 my ($message_id_stamp, $message_id_serial);
 584 sub make_message_id
 585 {
 586         my $uniq;
 587         if (!defined $message_id_stamp) {
 588                 $message_id_stamp = sprintf("%s-%s", time, $$);
 589                 $message_id_serial = 0;
 590         }
 591         $message_id_serial++;
 592         $uniq = "$message_id_stamp-$message_id_serial";
 593
 594         my $du_part;
 595         for ($sender, $repocommitter, $repoauthor) {
 596                 $du_part = extract_valid_address(sanitize_address($_));
 597                 last if (defined $du_part and $du_part ne '');
 598         }
 599         if (not defined $du_part or $du_part eq '') {
 600                 use Sys::Hostname qw();
 601                 $du_part = 'user@' . Sys::Hostname::hostname();
 602         }
 603         my $message_id_template = "<%s-git-send-email-%s>";
 604         $message_id = sprintf($message_id_template, $uniq, $du_part);
 605         #print "new message id = $message_id\n"; # Was useful for debugging
 606 }
 607
 608
 609
 610 $time = time - scalar $#files;
 611
 612 sub unquote_rfc2047 {
 613         local ($_) = @_;
 614         my $encoding;
 615         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 616                 $encoding = $1;
 617                 s/_/ /g;
 618                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 619         }
 620         return wantarray ? ($_, $encoding) : $_;
 621 }
 622
 623 sub quote_rfc2047 {
 624         local $_ = shift;
 625         my $encoding = shift || 'utf-8';
 626         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 627         s/(.*)/=\?$encoding\?q\?$1\?=/;
 628         return $_;
 629 }
 630
 631 # use the simplest quoting being able to handle the recipient
 632 sub sanitize_address
 633 {
 634         my ($recipient) = @_;
 635         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 636
 637         if (not $recipient_name) {
 638                 return "$recipient";
 639         }
 640
 641         # if recipient_name is already quoted, do nothing
 642         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 643                 return $recipient;
 644         }
 645
 646         # rfc2047 is needed if a non-ascii char is included
 647         if ($recipient_name =~ /[^[:ascii:]]/) {
 648                 $recipient_name = quote_rfc2047($recipient_name);
 649         }
 650
 651         # double quotes are needed if specials or CTLs are included
 652         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 653                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 654                 $recipient_name = "\"$recipient_name\"";
 655         }
 656
 657         return "$recipient_name $recipient_addr";
 658
 659 }
 660
 661 sub send_message
 662 {
 663         my @recipients = unique_email_list(@to);
 664         @cc = (grep { my $cc = extract_valid_address($_);
 665                       not grep { $cc eq $_ } @recipients
 666                     }
 667                map { sanitize_address($_) }
 668                @cc);
 669         my $to = join (",\n\t", @recipients);
 670         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 671         @recipients = (map { extract_valid_address($_) } @recipients);
 672         my $date = format_2822_time($time++);
 673         my $gitversion = '@@GIT_VERSION@@';
 674         if ($gitversion =~ m/..GIT_VERSION../) {
 675             $gitversion = Git::version();
 676         }
 677
 678         my $cc = join(", ", unique_email_list(@cc));
 679         my $ccline = "";
 680         if ($cc ne '') {
 681                 $ccline = "\nCc: $cc";
 682         }
 683         my $sanitized_sender = sanitize_address($sender);
 684         make_message_id() unless defined($message_id);
 685
 686         my $header = "From: $sanitized_sender
 687 To: $to${ccline}
 688 Subject: $subject
 689 Date: $date
 690 Message-Id: $message_id
 691 X-Mailer: git-send-email $gitversion
 692 ";
 693         if ($thread && $reply_to) {
 694
 695                 $header .= "In-Reply-To: $reply_to\n";
 696                 $header .= "References: $references\n";
 697         }
 698         if (@xh) {
 699                 $header .= join("\n", @xh) . "\n";
 700         }
 701
 702         my @sendmail_parameters = ('-i', @recipients);
 703         my $raw_from = $sanitized_sender;
 704         $raw_from = $envelope_sender if (defined $envelope_sender);
 705         $raw_from = extract_valid_address($raw_from);
 706         unshift (@sendmail_parameters,
 707                         '-f', $raw_from) if(defined $envelope_sender);
 708
 709         if ($dry_run) {
 710                 # We don't want to send the email.
 711         } elsif ($smtp_server =~ m#^/#) {
 712                 my $pid = open my $sm, '|-';
 713                 defined $pid or die $!;
 714                 if (!$pid) {
 715                         exec($smtp_server, @sendmail_parameters) or die $!;
 716                 }
 717                 print $sm "$header\n$message";
 718                 close $sm or die $?;
 719         } else {
 720
 721                 if (!defined $smtp_server) {
 722                         die "The required SMTP server is not properly defined."
 723                 }
 724
 725                 if ($smtp_encryption eq 'ssl') {
 726                         $smtp_server_port ||= 465; # ssmtp
 727                         require Net::SMTP::SSL;
 728                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 729                 }
 730                 else {
 731                         require Net::SMTP;
 732                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 733                                                  ? "$smtp_server:$smtp_server_port"
 734                                                  : $smtp_server);
 735                         if ($smtp_encryption eq 'tls') {
 736                                 require Net::SMTP::SSL;
 737                                 $smtp->command('STARTTLS');
 738                                 $smtp->response();
 739                                 if ($smtp->code == 220) {
 740                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 741                                                 or die "STARTTLS failed! ".$smtp->message;
 742                                         $smtp_encryption = '';
 743                                         # Send EHLO again to receive fresh
 744                                         # supported commands
 745                                         $smtp->hello();
 746                                 } else {
 747                                         die "Server does not support STARTTLS! ".$smtp->message;
 748                                 }
 749                         }
 750                 }
 751
 752                 if (!$smtp) {
 753                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 754                 }
 755
 756                 if (defined $smtp_authuser) {
 757
 758                         if (!defined $smtp_authpass) {
 759
 760                                 system "stty -echo";
 761
 762                                 do {
 763                                         print "Password: ";
 764                                         $_ = <STDIN>;
 765                                         print "\n";
 766                                 } while (!defined $_);
 767
 768                                 chomp($smtp_authpass = $_);
 769
 770                                 system "stty echo";
 771                         }
 772
 773                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 774                 }
 775
 776                 $smtp->mail( $raw_from ) or die $smtp->message;
 777                 $smtp->to( @recipients ) or die $smtp->message;
 778                 $smtp->data or die $smtp->message;
 779                 $smtp->datasend("$header\n$message") or die $smtp->message;
 780                 $smtp->dataend() or die $smtp->message;
 781                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 782         }
 783         if ($quiet) {
 784                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 785         } else {
 786                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 787                 if ($smtp_server !~ m#^/#) {
 788                         print "Server: $smtp_server\n";
 789                         print "MAIL FROM:<$raw_from>\n";
 790                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 791                 } else {
 792                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 793                 }
 794                 print $header, "\n";
 795                 if ($smtp) {
 796                         print "Result: ", $smtp->code, ' ',
 797                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 798                 } else {
 799                         print "Result: OK\n";
 800                 }
 801         }
 802 }
 803
 804 $reply_to = $initial_reply_to;
 805 $references = $initial_reply_to || '';
 806 $subject = $initial_subject;
 807
 808 foreach my $t (@files) {
 809         open(F,"<",$t) or die "can't open file $t";
 810
 811         my $author = undef;
 812         my $author_encoding;
 813         my $has_content_type;
 814         my $body_encoding;
 815         @cc = @initial_cc;
 816         @xh = ();
 817         my $input_format = undef;
 818         my $header_done = 0;
 819         $message = "";
 820         while(<F>) {
 821                 if (!$header_done) {
 822                         if (/^From /) {
 823                                 $input_format = 'mbox';
 824                                 next;
 825                         }
 826                         chomp;
 827                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 828                                 $input_format = 'mbox';
 829                         }
 830
 831                         if (defined $input_format && $input_format eq 'mbox') {
 832                                 if (/^Subject:\s+(.*)$/) {
 833                                         $subject = $1;
 834
 835                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 836                                         if (unquote_rfc2047($2) eq $sender) {
 837                                                 next if ($suppress_cc{'self'});
 838                                         }
 839                                         elsif ($1 eq 'From') {
 840                                                 ($author, $author_encoding)
 841                                                   = unquote_rfc2047($2);
 842                                                 next if ($suppress_cc{'author'});
 843                                         } else {
 844                                                 next if ($suppress_cc{'cc'});
 845                                         }
 846                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 847                                                 $2, $_) unless $quiet;
 848                                         push @cc, $2;
 849                                 }
 850                                 elsif (/^Content-type:/i) {
 851                                         $has_content_type = 1;
 852                                         if (/charset="?([^ "]+)/) {
 853                                                 $body_encoding = $1;
 854                                         }
 855                                         push @xh, $_;
 856                                 }
 857                                 elsif (/^Message-Id: (.*)/i) {
 858                                         $message_id = $1;
 859                                 }
 860                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 861                                         push @xh, $_;
 862                                 }
 863
 864                         } else {
 865                                 # In the traditional
 866                                 # "send lots of email" format,
 867                                 # line 1 = cc
 868                                 # line 2 = subject
 869                                 # So let's support that, too.
 870                                 $input_format = 'lots';
 871                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 872                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 873                                                 $_, $_) unless $quiet;
 874
 875                                         push @cc, $_;
 876
 877                                 } elsif (!defined $subject) {
 878                                         $subject = $_;
 879                                 }
 880                         }
 881
 882                         # A whitespace line will terminate the headers
 883                         if (m/^\s*$/) {
 884                                 $header_done = 1;
 885                         }
 886                 } else {
 887                         $message .=  $_;
 888                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 889                                 next if ($suppress_cc{'sob'});
 890                                 chomp;
 891                                 my $c = $2;
 892                                 chomp $c;
 893                                 next if ($c eq $sender and $suppress_cc{'self'});
 894                                 push @cc, $c;
 895                                 printf("(sob) Adding cc: %s from line '%s'\n",
 896                                         $c, $_) unless $quiet;
 897                         }
 898                 }
 899         }
 900         close F;
 901
 902         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 903                 open(F, "$cc_cmd $t |")
 904                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 905                 while(<F>) {
 906                         my $c = $_;
 907                         $c =~ s/^\s*//g;
 908                         $c =~ s/\n$//g;
 909                         next if ($c eq $sender and $suppress_from);
 910                         push @cc, $c;
 911                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 912                                 $c, $cc_cmd) unless $quiet;
 913                 }
 914                 close F
 915                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 916         }
 917
 918         if (defined $author) {
 919                 $message = "From: $author\n\n$message";
 920                 if (defined $author_encoding) {
 921                         if ($has_content_type) {
 922                                 if ($body_encoding eq $author_encoding) {
 923                                         # ok, we already have the right encoding
 924                                 }
 925                                 else {
 926                                         # uh oh, we should re-encode
 927                                 }
 928                         }
 929                         else {
 930                                 push @xh,
 931                                   'MIME-Version: 1.0',
 932                                   "Content-Type: text/plain; charset=$author_encoding",
 933                                   'Content-Transfer-Encoding: 8bit';
 934                         }
 935                 }
 936         }
 937
 938         send_message();
 939
 940         # set up for the next message
 941         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 942                 $reply_to = $message_id;
 943                 if (length $references > 0) {
 944                         $references .= "\n $message_id";
 945                 } else {
 946                         $references = "$message_id";
 947                 }
 948         }
 949         $message_id = undef;
 950 }
 951
 952 if ($compose) {
 953         cleanup_compose_files();
 954 }
 955
 956 sub cleanup_compose_files() {
 957         unlink($compose_filename, $compose_filename . ".final");
 958
 959 }
 960
 961 $smtp->quit if $smtp;
 962
 963 sub unique_email_list(@) {
 964         my %seen;
 965         my @emails;
 966
 967         foreach my $entry (@_) {
 968                 if (my $clean = extract_valid_address($entry)) {
 969                         $seen{$clean} ||= 0;
 970                         next if $seen{$clean}++;
 971                         push @emails, $entry;
 972                 } else {
 973                         print STDERR "W: unable to extract a valid address",
 974                                         " from: $entry\n";
 975                 }
 976         }
 977         return @emails;
 978 }
 979
 980 sub validate_patch {
 981         my $fn = shift;
 982         open(my $fh, '<', $fn)
 983                 or die "unable to open $fn: $!\n";
 984         while (my $line = <$fh>) {
 985                 if (length($line) > 998) {
 986                         return "$.: patch contains a line longer than 998 characters";
 987                 }
 988         }
 989         return undef;
 990 }
 991
 992 sub file_has_nonascii {
 993         my $fn = shift;
 994         open(my $fh, '<', $fn)
 995                 or die "unable to open $fn: $!\n";
 996         while (my $line = <$fh>) {
 997                 return 1 if $line =~ /[^[:ascii:]]/;
 998         }
 999         return 0;
1000 }