cook

   1 #!/usr/bin/perl -w
   2 # Maintain "what's cooking" messages
   3
   4 use strict;
   5
   6 my %reverts = ('next' => {
   7         map { $_ => 1 } qw(
   8             ) });
   9
  10 %reverts = ();
  11
  12 sub phrase_these {
  13         my %uniq = ();
  14         my (@u) = grep { $uniq{$_}++ == 0 } sort @_;
  15         my @d = ();
  16         for (my $i = 0; $i < @u; $i++) {
  17                 push @d, $u[$i];
  18                 if ($i == @u - 2) {
  19                         push @d, " and ";
  20                 } elsif ($i < @u - 2) {
  21                         push @d, ", ";
  22                 }
  23         }
  24         return join('', @d);
  25 }
  26
  27 sub describe_relation {
  28         my ($topic_info) = @_;
  29         my @desc;
  30
  31         if (exists $topic_info->{'used'}) {
  32                 push @desc, ("is used by " .
  33                              phrase_these(@{$topic_info->{'used'}}));
  34         }
  35
  36         if (exists $topic_info->{'uses'}) {
  37                 push @desc, ("uses " .
  38                              phrase_these(@{$topic_info->{'uses'}}));
  39         }
  40
  41         if (exists $topic_info->{'shares'}) {
  42                 push @desc, ("is tangled with " .
  43                              phrase_these(@{$topic_info->{'shares'}}));
  44         }
  45
  46         if (!@desc) {
  47                 return "";
  48         }
  49
  50         return "(this branch " . join("; ", @desc) . ".)";
  51 }
  52
  53 sub forks_from {
  54         my ($topic, $fork, $forkee, @overlap) = @_;
  55         my %ovl = map { $_ => 1 } (@overlap, @{$topic->{$forkee}{'log'}});
  56
  57         push @{$topic->{$fork}{'uses'}}, $forkee;
  58         push @{$topic->{$forkee}{'used'}}, $fork;
  59         @{$topic->{$fork}{'log'}} = (grep { !exists $ovl{$_} }
  60                                      @{$topic->{$fork}{'log'}});
  61 }
  62
  63 sub topic_relation {
  64         my ($topic, $one, $two) = @_;
  65
  66         my $fh;
  67         open($fh, '-|',
  68              qw(git log --abbrev=7), "--format=%m %h",
  69              "$one...$two", "^master")
  70             or die "$!: open log --left-right";
  71         my (@left, @right);
  72         while (<$fh>) {
  73                 my ($sign, $sha1) = /^(.) (.*)/;
  74                 if ($sign eq '<') {
  75                         push @left, $sha1;
  76                 } elsif ($sign eq '>') {
  77                         push @right, $sha1;
  78                 }
  79         }
  80         close($fh) or die "$!: close log --left-right";
  81
  82         if (!@left) {
  83                 if (@right) {
  84                         forks_from($topic, $two, $one);
  85                 }
  86         } elsif (!@right) {
  87                 forks_from($topic, $one, $two);
  88         } else {
  89                 push @{$topic->{$one}{'shares'}}, $two;
  90                 push @{$topic->{$two}{'shares'}}, $one;
  91         }
  92 }
  93
  94 =head1
  95 Inspect the current set of topics
  96
  97 Returns a hash:
  98
  99     $topic = {
 100         $branchname => {
 101             'tipdate' => date of the tip commit,
 102             'desc' => description string,
 103             'log' => [ $commit,... ],
 104         },
 105     }
 106
 107 =cut
 108
 109 sub get_commit {
 110         my (@base) = qw(master next pu);
 111         my $fh;
 112         open($fh, '-|',
 113              qw(git for-each-ref),
 114              "--format=%(refname:short) %(committerdate:iso8601)",
 115              "refs/heads/??/*")
 116             or die "$!: open for-each-ref";
 117         my @topic;
 118         my %topic;
 119
 120         while (<$fh>) {
 121                 chomp;
 122                 my ($branch, $date) = /^(\S+) (.*)$/;
 123                 push @topic, $branch;
 124                 $date =~ s/ .*//;
 125                 $topic{$branch} = +{
 126                         log => [],
 127                         tipdate => $date,
 128                 };
 129         }
 130         close($fh) or die "$!: close for-each-ref";
 131
 132         my %base = map { $_ => undef } @base;
 133         my %commit;
 134         my $show_branch_batch = 20;
 135
 136         while (@topic) {
 137                 my @t = (@base, splice(@topic, 0, $show_branch_batch));
 138                 my $header_delim = '-' x scalar(@t);
 139                 my $contain_pat = '.' x scalar(@t);
 140                 open($fh, '-|', qw(git show-branch --sparse --sha1-name),
 141                      map { "refs/heads/$_" } @t)
 142                     or die "$!: open show-branch";
 143                 while (<$fh>) {
 144                         chomp;
 145                         if ($header_delim) {
 146                                 if (/^$header_delim$/) {
 147                                         $header_delim = undef;
 148                                 }
 149                                 next;
 150                         }
 151                         my ($contain, $sha1, $log) =
 152                             ($_ =~ /^($contain_pat) \[([0-9a-f]+)\] (.*)$/);
 153
 154                         for (my $i = 0; $i < @t; $i++) {
 155                                 my $branch = $t[$i];
 156                                 my $sign = substr($contain, $i, 1);
 157                                 next if ($sign eq ' ');
 158                                 next if (substr($contain, 0, 1) ne ' ');
 159
 160                                 if (!exists $commit{$sha1}) {
 161                                         $commit{$sha1} = +{
 162                                                 branch => {},
 163                                                 log => $log,
 164                                         };
 165                                 }
 166                                 my $co = $commit{$sha1};
 167                                 if (!exists $reverts{$branch}{$sha1}) {
 168                                         $co->{'branch'}{$branch} = 1;
 169                                 }
 170                                 next if (exists $base{$branch});
 171                                 push @{$topic{$branch}{'log'}}, $sha1;
 172                         }
 173                 }
 174                 close($fh) or die "$!: close show-branch";
 175         }
 176
 177         my %shared;
 178         for my $sha1 (keys %commit) {
 179                 my $sign;
 180                 my $co = $commit{$sha1};
 181                 if (exists $co->{'branch'}{'next'}) {
 182                         $sign = '+';
 183                 } elsif (exists $co->{'branch'}{'pu'}) {
 184                         $sign = '-';
 185                 } else {
 186                         $sign = '.';
 187                 }
 188                 $co->{'log'} = $sign . ' ' . $co->{'log'};
 189                 my @t = (sort grep { !exists $base{$_} }
 190                          keys %{$co->{'branch'}});
 191                 next if (@t < 2);
 192                 my $t = "@t";
 193                 $shared{$t} = 1;
 194         }
 195
 196         for my $combo (keys %shared) {
 197                 my @combo = split(' ', $combo);
 198                 for (my $i = 0; $i < @combo - 1; $i++) {
 199                         for (my $j = $i + 1; $j < @combo; $j++) {
 200                                 topic_relation(\%topic, $combo[$i], $combo[$j]);
 201                         }
 202                 }
 203         }
 204
 205         open($fh, '-|',
 206              qw(git log --first-parent --abbrev=7),
 207              "--format=%ci %h %p :%s", "master..next")
 208             or die "$!: open log master..next";
 209         while (<$fh>) {
 210                 my ($date, $commit, $parent, $tips);
 211                 unless (($date, $commit, $parent, $tips) =
 212                         /^([-0-9]+) ..:..:.. .\d{4} (\S+) (\S+) ([^:]*):/) {
 213                         die "Oops: $_";
 214                 }
 215                 for my $tip (split(' ', $tips)) {
 216                         my $co = $commit{$tip};
 217                         next unless ($co->{'branch'}{'next'});
 218                         $co->{'merged'} = " (merged to 'next' on $date at $commit)";
 219                 }
 220         }
 221         close($fh) or die "$!: close log master..next";
 222
 223         for my $branch (keys %topic) {
 224                 my @log = ();
 225                 my $n = scalar(@{$topic{$branch}{'log'}});
 226                 if (!$n) {
 227                         delete $topic{$branch};
 228                         next;
 229                 } elsif ($n == 1) {
 230                         $n = "1 commit";
 231                 } else {
 232                         $n = "$n commits";
 233                 }
 234                 my $d = $topic{$branch}{'tipdate'};
 235                 my $head = "* $branch ($d) $n\n";
 236                 my @desc;
 237                 for (@{$topic{$branch}{'log'}}) {
 238                         my $co = $commit{$_};
 239                         if (exists $co->{'merged'}) {
 240                                 push @desc, $co->{'merged'};
 241                         }
 242                         push @desc, $commit{$_}->{'log'};
 243                 }
 244
 245                 if (80 < @desc) {
 246                         @desc = @desc[0..4];
 247                         push @desc, "- ...";
 248                 }
 249
 250                 my $list = join("\n", map { " " . $_ } @desc);
 251                 my $relation = describe_relation($topic{$branch});
 252                 $topic{$branch}{'desc'} = $head . $list;
 253                 if ($relation) {
 254                         $topic{$branch}{'desc'} .= "\n $relation";
 255                 }
 256         }
 257
 258         return \%topic;
 259 }
 260
 261 sub blurb_text {
 262         my ($mon, $year, $issue, $dow, $date,
 263             $master_at, $next_at, $text) = @_;
 264
 265         my $now_string = localtime;
 266         my ($current_dow, $current_mon, $current_date, $current_year) =
 267             ($now_string =~ /^(\w+) (\w+) (\d+) [\d:]+ (\d+)$/);
 268
 269         $mon ||= $current_mon;
 270         $year ||= $current_year;
 271         $issue ||= "01";
 272         $dow ||= $current_dow;
 273         $date ||= $current_date;
 274         $master_at ||= '0' x 40;
 275         $next_at ||= '0' x 40;
 276         $text ||= <<'EOF';
 277 Here are the topics that have been cooking.  Commits prefixed with '-' are
 278 only in 'pu' (proposed updates) while commits prefixed with '+' are in 'next'.
 279 The ones marked with '.' do not appear in any of the integration branches,
 280 but I am still holding onto them.
 281
 282 You can find the changes described here in the integration branches of the
 283 repositories listed at
 284
 285     http://git-blame.blogspot.com/p/git-public-repositories.html
 286 EOF
 287
 288         $text = <<EOF;
 289 To: git\@vger.kernel.org
 290 Bcc: lwn\@lwn.net
 291 Subject: What's cooking in git.git ($mon $year, #$issue; $dow, $date)
 292 X-master-at: $master_at
 293 X-next-at: $next_at
 294
 295 What's cooking in git.git ($mon $year, #$issue; $dow, $date)
 296 --------------------------------------------------
 297
 298 $text
 299 EOF
 300         $text =~ s/\n+\Z/\n/;
 301         return $text;
 302 }
 303
 304 my $blurb_match = <<'EOF';
 305 (?i:\s*[a-z]+: .*\n)*?Subject: What's cooking in \S+ \((\w+) (\d+), #(\d+); (\w+), (\d+)\)
 306 X-master-at: ([0-9a-f]{40})
 307 X-next-at: ([0-9a-f]{40})
 308
 309 What's cooking in \S+ \(\1 \2, #\3; \4, \5\)
 310 -{30,}
 311 \n*
 312 EOF
 313
 314 my $blurb = "b..l..u..r..b";
 315 sub read_previous {
 316         my ($fn) = @_;
 317         my $fh;
 318         my $section = undef;
 319         my $serial = 1;
 320         my $branch = $blurb;
 321         my $last_empty = undef;
 322         my (@section, %section, @branch, %branch, %description, @leader);
 323         my $in_unedited_olde = 0;
 324
 325         if (!-r $fn) {
 326                 return +{
 327                         'section_list' => [],
 328                         'section_data' => {},
 329                         'topic_description' => {
 330                                 $blurb => {
 331                                         desc => undef,
 332                                         text => blurb_text(),
 333                                 },
 334                         },
 335                 };
 336         }
 337
 338         open ($fh, '<', $fn) or die "$!: open $fn";
 339         while (<$fh>) {
 340                 chomp;
 341                 s/\s+$//;
 342                 if ($in_unedited_olde) {
 343                         if (/^>>$/) {
 344                                 $in_unedited_olde = 0;
 345                                 $_ = " | $_";
 346                         }
 347                 } elsif (/^<<$/) {
 348                         $in_unedited_olde = 1;
 349                 }
 350
 351                 if ($in_unedited_olde) {
 352                         $_ = " | $_";
 353                 }
 354
 355                 if (defined $section && /^-{20,}$/) {
 356                         $_ = "";
 357                 }
 358                 if (/^$/) {
 359                         $last_empty = 1;
 360                         next;
 361                 }
 362                 if (/^\[(.*)\]\s*$/) {
 363                         $section = $1;
 364                         $branch = undef;
 365                         if (!exists $section{$section}) {
 366                                 push @section, $section;
 367                                 $section{$section} = [];
 368                         }
 369                         next;
 370                 }
 371                 if (defined $section && /^\* (\S+) /) {
 372                         $branch = $1;
 373                         $last_empty = 0;
 374                         if (!exists $branch{$branch}) {
 375                                 push @branch, [$branch, $section];
 376                                 $branch{$branch} = 1;
 377                         }
 378                         push @{$section{$section}}, $branch;
 379                 }
 380                 if (defined $branch) {
 381                         my $was_last_empty = $last_empty;
 382                         $last_empty = 0;
 383                         if (!exists $description{$branch}) {
 384                                 $description{$branch} = [];
 385                         }
 386                         if ($was_last_empty) {
 387                                 push @{$description{$branch}}, "";
 388                         }
 389                         push @{$description{$branch}}, $_;
 390                 }
 391         }
 392         close($fh);
 393
 394         my $lead = " ";
 395         for my $branch (keys %description) {
 396                 my $ary = $description{$branch};
 397                 if ($branch eq $blurb) {
 398                         while (@{$ary} && $ary->[-1] =~ /^-{30,}$/) {
 399                                 pop @{$ary};
 400                         }
 401                         $description{$branch} = +{
 402                                 desc => undef,
 403                                 text => join("\n", @{$ary}),
 404                         };
 405                 } else {
 406                         my @desc = ();
 407                         while (@{$ary}) {
 408                                 my $elem = shift @{$ary};
 409                                 last if ($elem eq '');
 410                                 push @desc, $elem;
 411                         }
 412                         my @txt = map {
 413                                 s/^\s+//;
 414                                 $_ = "$lead$_";
 415                                 s/\s+$//;
 416                                 $_;
 417                         } @{$ary};
 418
 419                         $description{$branch} = +{
 420                                 desc => join("\n", @desc),
 421                                 text => join("\n", @txt),
 422                         };
 423                 }
 424         }
 425
 426         return +{
 427                 section_list => \@section,
 428                 section_data => \%section,
 429                 topic_description => \%description,
 430         };
 431 }
 432
 433 sub write_cooking {
 434         my ($fn, $cooking) = @_;
 435         my $fh;
 436
 437         open($fh, '>', $fn) or die "$!: open $fn";
 438         print $fh $cooking->{'topic_description'}{$blurb}{'text'};
 439
 440         for my $section_name (@{$cooking->{'section_list'}}) {
 441                 my $topic_list = $cooking->{'section_data'}{$section_name};
 442                 next if (!@{$topic_list});
 443
 444                 print $fh "\n";
 445                 print $fh '-' x 50, "\n";
 446                 print $fh "[$section_name]\n";
 447                 my $lead = "\n";
 448                 for my $topic (@{$topic_list}) {
 449                         my $d = $cooking->{'topic_description'}{$topic};
 450
 451                         print $fh $lead, $d->{'desc'}, "\n";
 452                         if ($d->{'text'}) {
 453                                 print $fh "\n", $d->{'text'}, "\n";
 454                         }
 455                         $lead = "\n\n";
 456                 }
 457         }
 458         close($fh);
 459 }
 460
 461 my $graduated = 'Graduated to "master"';
 462 my $new_topics = 'New Topics';
 463 my $discarded = 'Discarded';
 464 my $old_new_topics = 'Old New Topics';
 465
 466 sub update_issue {
 467         my ($cooking) = @_;
 468         my ($fh, $master_at, $next_at, $incremental);
 469
 470         open($fh, '-|',
 471              qw(git for-each-ref),
 472              "--format=%(refname:short) %(objectname)",
 473              "refs/heads/master",
 474              "refs/heads/next") or die "$!: open for-each-ref";
 475         while (<$fh>) {
 476                 my ($branch, $at) = /^(\S+) (\S+)$/;
 477                 if ($branch eq 'master') { $master_at = $at; }
 478                 if ($branch eq 'next') { $next_at = $at; }
 479         }
 480         close($fh) or die "$!: close for-each-ref";
 481
 482         $incremental = ((-r "Meta/whats-cooking.txt") &&
 483                         system("cd Meta && " .
 484                                "git diff --quiet --no-ext-diff HEAD -- " .
 485                                "whats-cooking.txt"));
 486
 487         my $now_string = localtime;
 488         my ($current_dow, $current_mon, $current_date, $current_year) =
 489             ($now_string =~ /^(\w+) (\w+) +(\d+) [\d:]+ (\d+)$/);
 490
 491         my $btext = $cooking->{'topic_description'}{$blurb}{'text'};
 492         if ($btext !~ s/\A$blurb_match//) {
 493                 die "match pattern broken?";
 494         }
 495         my ($mon, $year, $issue, $dow, $date) = ($1, $2, $3, $4, $5);
 496
 497         if ($current_mon ne $mon || $current_year ne $year) {
 498                 $issue = "01";
 499         } elsif (!$incremental) {
 500                 $issue =~ s/^0*//;
 501                 $issue = sprintf "%02d", ($issue + 1);
 502         }
 503         $mon = $current_mon;
 504         $year = $current_year;
 505         $dow = $current_dow;
 506         $date = $current_date;
 507
 508         $cooking->{'topic_description'}{$blurb}{'text'} =
 509             blurb_text($mon, $year, $issue, $dow, $date,
 510                        $master_at, $next_at, $btext);
 511
 512         if (!$incremental) {
 513                 my $sd = $cooking->{'section_data'};
 514                 my $sl = $cooking->{'section_list'};
 515                 # Rename "New" to "Old New" and insert "New".
 516                 # Move "New" to "Old New"
 517                 my $i;
 518                 my $doneso;
 519                 for ($i = 0; $i < @{$sl}; $i++) {
 520                         if ($sl->[$i] eq $new_topics) {
 521                                 $sl->[$i] = $old_new_topics;
 522                                 unshift @{$sl}, $new_topics;
 523                                 $doneso = 1;
 524                                 last;
 525                         }
 526                 }
 527                 if ($doneso) {
 528                         $sd->{$old_new_topics} = $sd->{$new_topics};
 529                 }
 530                 $sd->{$new_topics} = [];
 531         }
 532
 533         return $incremental;
 534 }
 535
 536 sub topic_in_pu {
 537         my ($topic_desc) = @_;
 538         for my $line (split(/\n/, $topic_desc)) {
 539                 if ($line =~ /^ [+-] /) {
 540                         return 1;
 541                 }
 542         }
 543         return 0;
 544 }
 545
 546 sub merge_cooking {
 547         my ($cooking, $current) = @_;
 548         my $td = $cooking->{'topic_description'};
 549         my $sd = $cooking->{'section_data'};
 550         my $sl = $cooking->{'section_list'};
 551         my (@new_topic, @gone_topic);
 552
 553         # Make sure "New Topics" and "Graduated" exists
 554         if (!exists $sd->{$new_topics}) {
 555                 $sd->{$new_topics} = [];
 556                 unshift @{$sl}, $new_topics;
 557         }
 558
 559         if (!exists $sd->{$graduated}) {
 560                 $sd->{$graduated} = [];
 561                 unshift @{$sl}, $graduated;
 562         }
 563
 564         my $incremental = update_issue($cooking);
 565
 566         for my $topic (sort keys %{$current}) {
 567                 if (!exists $td->{$topic}) {
 568                         # Ignore new topics without anything merged
 569                         if (topic_in_pu($current->{$topic}{'desc'})) {
 570                                 push @new_topic, $topic;
 571                         }
 572                         next;
 573                 }
 574                 # Annotate if the contents of the topic changed
 575                 my $n = $current->{$topic}{'desc'};
 576                 my $o = $td->{$topic}{'desc'};
 577                 if ($n ne $o) {
 578                         $td->{$topic}{'desc'} = $n . "\n<<\n" . $o ."\n>>";
 579                 }
 580         }
 581
 582         for my $topic (sort keys %{$td}) {
 583                 next if ($topic eq $blurb);
 584                 next if (!$incremental &&
 585                          grep { $topic eq $_ } @{$sd->{$graduated}});
 586                 next if (grep { $topic eq $_ } @{$sd->{$discarded}});
 587                 if (!exists $current->{$topic}) {
 588                         push @gone_topic, $topic;
 589                 }
 590         }
 591
 592         for (@new_topic) {
 593                 push @{$sd->{$new_topics}}, $_;
 594                 $td->{$_}{'desc'} = $current->{$_}{'desc'};
 595         }
 596
 597         if (!$incremental) {
 598                 $sd->{$graduated} = [];
 599         }
 600
 601         if (@gone_topic) {
 602                 for my $topic (@gone_topic) {
 603                         for my $section (@{$sl}) {
 604                                 my $pre = scalar(@{$sd->{$section}});
 605                                 @{$sd->{$section}} = (grep { $_ ne $topic }
 606                                                       @{$sd->{$section}});
 607                                 my $post = scalar(@{$sd->{$section}});
 608                                 next if ($pre == $post);
 609                         }
 610                 }
 611                 for (@gone_topic) {
 612                         push @{$sd->{$graduated}}, $_;
 613                 }
 614         }
 615 }
 616
 617 ################################################################
 618 # WilDo
 619 sub wildo_queue {
 620         my ($what, $action, $topic) = @_;
 621         if (!exists $what->{$action}) {
 622                 $what->{$action} = [];
 623         }
 624         push @{$what->{$action}}, $topic;
 625 }
 626
 627 sub section_action {
 628         my ($section) = @_;
 629         if ($section) {
 630                 for ($section) {
 631                         return if (/^Graduated to/ || /^Discarded$/);
 632                         return $_ if (/^Stalled$/);
 633                 }
 634         }
 635         return "Undecided";
 636 }
 637
 638 sub wildo_flush_topic {
 639         my ($in_section, $what, $topic) = @_;
 640         if (defined $topic) {
 641                 my $action = section_action($in_section);
 642                 if ($action) {
 643                         wildo_queue($what, $action, $topic);
 644                 }
 645         }
 646 }
 647
 648 sub wildo_match {
 649         if (/^Will (?:\S+ ){0,2}(fast-track|keep|merge|drop|discard|cook|kick|defer|be re-?rolled)[,. ]/ ||
 650             /^Not urgent/ || /^Not ready/ || /^Waiting for / ||
 651             /^Needs? / || /^Expecting / || /^May want to /) {
 652                 return 1;
 653         }
 654         return 0;
 655 }
 656
 657 sub wildo {
 658         my (%what, $topic, $last_merge_to_next, $in_section, $in_desc);
 659         my $too_recent = '9999-99-99';
 660         while (<>) {
 661                 chomp;
 662
 663                 if (/^\[(.*)\]$/) {
 664                         my $old_section = $in_section;
 665                         $in_section = $1;
 666                         wildo_flush_topic($old_section, \%what, $topic);
 667                         $topic = $in_desc = undef;
 668                         next;
 669                 }
 670
 671                 if (/^\* (\S+) \(([-0-9]+)\) (\d+) commits?$/) {
 672                         wildo_flush_topic($in_section, \%what, $topic);
 673
 674                         # tip-date, next-date, topic, count, pu-count
 675                         $topic = [$2, $too_recent, $1, $3, 0];
 676                         $in_desc = undef;
 677                         next;
 678                 }
 679
 680                 if (defined $topic &&
 681                     ($topic->[1] eq $too_recent) &&
 682                     ($topic->[4] == 0) &&
 683                     (/^  \(merged to 'next' on ([-0-9]+)/)) {
 684                         $topic->[1] = $1;
 685                 }
 686                 if (defined $topic && /^ - /) {
 687                         $topic->[4]++;
 688                 }
 689
 690                 if (defined $topic && /^$/) {
 691                         $in_desc = 1;
 692                         next;
 693                 }
 694
 695                 next unless defined $topic && $in_desc;
 696
 697                 s/^\s+//;
 698                 if (wildo_match($_)) {
 699                         wildo_queue(\%what, $_, $topic);
 700                         $topic = $in_desc = undef;
 701                 }
 702
 703                 if (/Originally merged to 'next' on ([-0-9]+)/) {
 704                         $topic->[1] = $1;
 705                 }
 706         }
 707         wildo_flush_topic($in_section, \%what, $topic);
 708
 709         my $ipbl = "";
 710         for my $what (sort keys %what) {
 711                 print "$ipbl$what\n";
 712                 for $topic (sort { (($a->[1] cmp $b->[1]) ||
 713                                     ($a->[0] cmp $b->[0])) }
 714                             @{$what{$what}}) {
 715                         my ($tip, $next, $name, $count, $pu) = @$topic;
 716                         my ($sign);
 717                         $tip =~ s/^\d{4}-//;
 718                         if (($next eq $too_recent) || (0 < $pu)) {
 719                                 $sign = "-";
 720                                 $next = " " x 6;
 721                         } else {
 722                                 $sign = "+";
 723                                 $next =~ s|^\d{4}-|/|;
 724                         }
 725                         $count = "#$count";
 726                         printf " %s %-60s %s%s %5s\n", $sign, $name, $tip, $next, $count;
 727                 }
 728                 $ipbl = "\n";
 729         }
 730 }
 731
 732 ################################################################
 733 # HavDone
 734 sub havedone_show {
 735         my $topic = shift;
 736         my $str = shift;
 737         my $prefix = " * ";
 738         $str =~ s/\A\n+//;
 739         $str =~ s/\n+\Z//;
 740
 741         print "($topic)\n";
 742         for $str (split(/\n/, $str)) {
 743                 print "$prefix$str\n";
 744                 $prefix = "   ";
 745         }
 746 }
 747
 748 sub havedone_count {
 749         my @range = @_;
 750         my $cnt = `git rev-list --count @range`;
 751         chomp $cnt;
 752         return $cnt;
 753 }
 754
 755 sub havedone {
 756         my $fh;
 757         my %topic = ();
 758         my @topic = ();
 759         my ($topic, $to_maint, %to_maint, %merged, $in_desc);
 760         if (!@ARGV) {
 761                 open($fh, '-|',
 762                      qw(git rev-list --first-parent -1 master Documentation/RelNotes))
 763                     or die "$!: open rev-list";
 764                 my ($rev) = <$fh>;
 765                 close($fh) or die "$!: close rev-list";
 766                 chomp $rev;
 767                 @ARGV = ("$rev..master");
 768         }
 769         open($fh, '-|',
 770              qw(git log --first-parent --oneline --reverse), @ARGV)
 771             or die "$!: open log --first-parent";
 772         while (<$fh>) {
 773                 my ($sha1, $branch) = /^([0-9a-f]+) Merge branch '(.*)'$/;
 774                 next unless $branch;
 775                 $topic{$branch} = "";
 776                 $merged{$branch} = $sha1;
 777                 push @topic, $branch;
 778         }
 779         close($fh) or die "$!: close log --first-parent";
 780         open($fh, "<", "Meta/whats-cooking.txt")
 781             or die "$!: open whats-cooking";
 782         while (<$fh>) {
 783                 chomp;
 784                 if (/^\[(.*)\]$/) {
 785                         # section header
 786                         $in_desc = $topic = undef;
 787                         next;
 788                 }
 789                 if (/^\* (\S+) \([-0-9]+\) \d+ commits?$/) {
 790                         if (exists $topic{$1}) {
 791                                 $topic = $1;
 792                                 $to_maint = 0;
 793                         } else {
 794                                 $in_desc = $topic = undef;
 795                         }
 796                         next;
 797                 }
 798                 if (defined $topic && /^$/) {
 799                         $in_desc = 1;
 800                         next;
 801                 }
 802
 803                 next unless defined $topic && $in_desc;
 804
 805                 s/^\s+//;
 806                 if (wildo_match($_)) {
 807                         next;
 808                 }
 809                 $topic{$topic} .= "$_\n";
 810         }
 811         close($fh) or die "$!: close whats-cooking";
 812
 813         for $topic (@topic) {
 814                 my $merged = $merged{$topic};
 815                 my $in_master = havedone_count("$merged^1..$merged^2");
 816                 my $not_in_maint = havedone_count("maint..$merged^2");
 817                 if ($in_master == $not_in_maint) {
 818                         $to_maint{$topic} = 1;
 819                 }
 820         }
 821
 822         my $shown = 0;
 823         for $topic (@topic) {
 824                 next if (exists $to_maint{$topic});
 825                 havedone_show($topic, $topic{$topic});
 826                 print "\n";
 827                 $shown++;
 828         }
 829
 830         if ($shown) {
 831                 print "-" x 64, "\n";
 832         }
 833
 834         for $topic (@topic) {
 835                 next unless (exists $to_maint{$topic});
 836                 havedone_show($topic, $topic{$topic});
 837                 my $sha1 = `git rev-parse --short $topic`;
 838                 chomp $sha1;
 839                 print "   (merge $sha1 $topic later to maint).\n";
 840                 print "\n";
 841         }
 842 }
 843
 844 ################################################################
 845 # WhatsCooking
 846
 847 sub doit {
 848         my $topic = get_commit();
 849         my $cooking = read_previous('Meta/whats-cooking.txt');
 850         merge_cooking($cooking, $topic);
 851         write_cooking('Meta/whats-cooking.txt', $cooking);
 852 }
 853
 854 ################################################################
 855 # Main
 856
 857 use Getopt::Long;
 858
 859 my $wildo;
 860 my $havedone;
 861 if (!GetOptions("wildo" => \$wildo, "havedone" => \$havedone)) {
 862         print STDERR "$0 [--wildo|--havedone]\n";
 863         exit 1;
 864 }
 865
 866 if ($wildo) {
 867         if (!@ARGV) {
 868                 push @ARGV, "Meta/whats-cooking.txt";
 869         }
 870         wildo();
 871 } elsif ($havedone) {
 872         havedone();
 873 } else {
 874         doit();
 875 }