git-remote.perl

   1 #!/usr/bin/perl -w
   2
   3 use Git;
   4 my $git = Git->repository();
   5
   6 sub add_remote_config {
   7         my ($hash, $name, $what, $value) = @_;
   8         if ($what eq 'url') {
   9                 if (exists $hash->{$name}{'URL'}) {
  10                         print STDERR "Warning: more than one remote.$name.url\n";
  11                 }
  12                 $hash->{$name}{'URL'} = $value;
  13         }
  14         elsif ($what eq 'fetch') {
  15                 $hash->{$name}{'FETCH'} ||= [];
  16                 push @{$hash->{$name}{'FETCH'}}, $value;
  17         }
  18         elsif ($what eq 'push') {
  19                 $hash->{$name}{'PUSH'} ||= [];
  20                 push @{$hash->{$name}{'PUSH'}}, $value;
  21         }
  22         if (!exists $hash->{$name}{'SOURCE'}) {
  23                 $hash->{$name}{'SOURCE'} = 'config';
  24         }
  25 }
  26
  27 sub add_remote_remotes {
  28         my ($hash, $file, $name) = @_;
  29
  30         if (exists $hash->{$name}) {
  31                 $hash->{$name}{'WARNING'} = 'ignored due to config';
  32                 return;
  33         }
  34
  35         my $fh;
  36         if (!open($fh, '<', $file)) {
  37                 print STDERR "Warning: cannot open $file\n";
  38                 return;
  39         }
  40         my $it = { 'SOURCE' => 'remotes' };
  41         $hash->{$name} = $it;
  42         while (<$fh>) {
  43                 chomp;
  44                 if (/^URL:\s*(.*)$/) {
  45                         # Having more than one is Ok -- it is used for push.
  46                         if (! exists $it->{'URL'}) {
  47                                 $it->{'URL'} = $1;
  48                         }
  49                 }
  50                 elsif (/^Push:\s*(.*)$/) {
  51                         $it->{'PUSH'} ||= [];
  52                         push @{$it->{'PUSH'}}, $1;
  53                 }
  54                 elsif (/^Pull:\s*(.*)$/) {
  55                         $it->{'FETCH'} ||= [];
  56                         push @{$it->{'FETCH'}}, $1;
  57                 }
  58                 elsif (/^\#/) {
  59                         ; # ignore
  60                 }
  61                 else {
  62                         print STDERR "Warning: funny line in $file: $_\n";
  63                 }
  64         }
  65         close($fh);
  66 }
  67
  68 sub list_remote {
  69         my ($git) = @_;
  70         my %seen = ();
  71         my @remotes = eval {
  72                 $git->command(qw(config --get-regexp), '^remote\.');
  73         };
  74         for (@remotes) {
  75                 if (/^remote\.(\S+?)\.([^.\s]+)\s+(.*)$/) {
  76                         add_remote_config(\%seen, $1, $2, $3);
  77                 }
  78         }
  79
  80         my $dir = $git->repo_path() . "/remotes";
  81         if (opendir(my $dh, $dir)) {
  82                 local $_;
  83                 while ($_ = readdir($dh)) {
  84                         chomp;
  85                         next if (! -f "$dir/$_" || ! -r _);
  86                         add_remote_remotes(\%seen, "$dir/$_", $_);
  87                 }
  88         }
  89
  90         return \%seen;
  91 }
  92
  93 sub add_branch_config {
  94         my ($hash, $name, $what, $value) = @_;
  95         if ($what eq 'remote') {
  96                 if (exists $hash->{$name}{'REMOTE'}) {
  97                         print STDERR "Warning: more than one branch.$name.remote\n";
  98                 }
  99                 $hash->{$name}{'REMOTE'} = $value;
 100         }
 101         elsif ($what eq 'merge') {
 102                 $hash->{$name}{'MERGE'} ||= [];
 103                 push @{$hash->{$name}{'MERGE'}}, $value;
 104         }
 105 }
 106
 107 sub list_branch {
 108         my ($git) = @_;
 109         my %seen = ();
 110         my @branches = eval {
 111                 $git->command(qw(config --get-regexp), '^branch\.');
 112         };
 113         for (@branches) {
 114                 if (/^branch\.([^.]*)\.(\S*)\s+(.*)$/) {
 115                         add_branch_config(\%seen, $1, $2, $3);
 116                 }
 117         }
 118
 119         return \%seen;
 120 }
 121
 122 my $remote = list_remote($git);
 123 my $branch = list_branch($git);
 124
 125 sub update_ls_remote {
 126         my ($harder, $info) = @_;
 127
 128         return if (($harder == 0) ||
 129                    (($harder == 1) && exists $info->{'LS_REMOTE'}));
 130
 131         my @ref = map {
 132                 s|^[0-9a-f]{40}\s+refs/heads/||;
 133                 $_;
 134         } $git->command(qw(ls-remote --heads), $info->{'URL'});
 135         $info->{'LS_REMOTE'} = \@ref;
 136 }
 137
 138 sub list_wildcard_mapping {
 139         my ($forced, $ours, $ls) = @_;
 140         my %refs;
 141         for (@$ls) {
 142                 $refs{$_} = 01; # bit #0 to say "they have"
 143         }
 144         for ($git->command('for-each-ref', "refs/remotes/$ours")) {
 145                 chomp;
 146                 next unless (s|^[0-9a-f]{40}\s[a-z]+\srefs/remotes/$ours/||);
 147                 next if ($_ eq 'HEAD');
 148                 $refs{$_} ||= 0;
 149                 $refs{$_} |= 02; # bit #1 to say "we have"
 150         }
 151         my (@new, @stale, @tracked);
 152         for (sort keys %refs) {
 153                 my $have = $refs{$_};
 154                 if ($have == 1) {
 155                         push @new, $_;
 156                 }
 157                 elsif ($have == 2) {
 158                         push @stale, $_;
 159                 }
 160                 elsif ($have == 3) {
 161                         push @tracked, $_;
 162                 }
 163         }
 164         return \@new, \@stale, \@tracked;
 165 }
 166
 167 sub list_mapping {
 168         my ($name, $info) = @_;
 169         my $fetch = $info->{'FETCH'};
 170         my $ls = $info->{'LS_REMOTE'};
 171         my (@new, @stale, @tracked);
 172
 173         for (@$fetch) {
 174                 next unless (/(\+)?([^:]+):(.*)/);
 175                 my ($forced, $theirs, $ours) = ($1, $2, $3);
 176                 if ($theirs eq 'refs/heads/*' &&
 177                     $ours =~ /^refs\/remotes\/(.*)\/\*$/) {
 178                         # wildcard mapping
 179                         my ($w_new, $w_stale, $w_tracked)
 180                                 = list_wildcard_mapping($forced, $1, $ls);
 181                         push @new, @$w_new;
 182                         push @stale, @$w_stale;
 183                         push @tracked, @$w_tracked;
 184                 }
 185                 elsif ($theirs =~ /\*/ || $ours =~ /\*/) {
 186                         print STDERR "Warning: unrecognized mapping in remotes.$name.fetch: $_\n";
 187                 }
 188                 elsif ($theirs =~ s|^refs/heads/||) {
 189                         if (!grep { $_ eq $theirs } @$ls) {
 190                                 push @stale, $theirs;
 191                         }
 192                         elsif ($ours ne '') {
 193                                 push @tracked, $theirs;
 194                         }
 195                 }
 196         }
 197         return \@new, \@stale, \@tracked;
 198 }
 199
 200 sub show_mapping {
 201         my ($name, $info) = @_;
 202         my ($new, $stale, $tracked) = list_mapping($name, $info);
 203         if (@$new) {
 204                 print "  New remote branches (next fetch will store in remotes/$name)\n";
 205                 print "    @$new\n";
 206         }
 207         if (@$stale) {
 208                 print "  Stale tracking branches in remotes/$name (use 'git remote prune')\n";
 209                 print "    @$stale\n";
 210         }
 211         if (@$tracked) {
 212                 print "  Tracked remote branches\n";
 213                 print "    @$tracked\n";
 214         }
 215 }
 216
 217 sub prune_remote {
 218         my ($name, $ls_remote) = @_;
 219         if (!exists $remote->{$name}) {
 220                 print STDERR "No such remote $name\n";
 221                 return;
 222         }
 223         my $info = $remote->{$name};
 224         update_ls_remote($ls_remote, $info);
 225
 226         my ($new, $stale, $tracked) = list_mapping($name, $info);
 227         my $prefix = "refs/remotes/$name";
 228         foreach my $to_prune (@$stale) {
 229                 my @v = $git->command(qw(rev-parse --verify), "$prefix/$to_prune");
 230                 $git->command(qw(update-ref -d), "$prefix/$to_prune", $v[0]);
 231         }
 232 }
 233
 234 sub show_remote {
 235         my ($name, $ls_remote) = @_;
 236         if (!exists $remote->{$name}) {
 237                 print STDERR "No such remote $name\n";
 238                 return;
 239         }
 240         my $info = $remote->{$name};
 241         update_ls_remote($ls_remote, $info);
 242
 243         print "* remote $name\n";
 244         print "  URL: $info->{'URL'}\n";
 245         for my $branchname (sort keys %$branch) {
 246                 next if ($branch->{$branchname}{'REMOTE'} ne $name);
 247                 my @merged = map {
 248                         s|^refs/heads/||;
 249                         $_;
 250                 } split(' ',"@{$branch->{$branchname}{'MERGE'}}");
 251                 next unless (@merged);
 252                 print "  Remote branch(es) merged with 'git pull' while on branch $branchname\n";
 253                 print "    @merged\n";
 254         }
 255         if ($info->{'LS_REMOTE'}) {
 256                 show_mapping($name, $info);
 257         }
 258         if ($info->{'PUSH'}) {
 259                 my @pushed = map {
 260                         s|^refs/heads/||;
 261                         s|^\+refs/heads/|+|;
 262                         s|:refs/heads/|:|;
 263                         $_;
 264                 } @{$info->{'PUSH'}};
 265                 print "  Local branch(es) pushed with 'git push'\n";
 266                 print "    @pushed\n";
 267         }
 268 }
 269
 270 sub add_remote {
 271         my ($name, $url, $opts) = @_;
 272         if (exists $remote->{$name}) {
 273                 print STDERR "remote $name already exists.\n";
 274                 exit(1);
 275         }
 276         $git->command('config', "remote.$name.url", $url);
 277         my $track = $opts->{'track'} || ["*"];
 278
 279         for (@$track) {
 280                 $git->command('config', '--add', "remote.$name.fetch",
 281                               "+refs/heads/$_:refs/remotes/$name/$_");
 282         }
 283         if ($opts->{'fetch'}) {
 284                 $git->command('fetch', $name);
 285         }
 286         if (exists $opts->{'master'}) {
 287                 $git->command('symbolic-ref', "refs/remotes/$name/HEAD",
 288                               "refs/remotes/$name/$opts->{'master'}");
 289         }
 290 }
 291
 292 sub update_remote {
 293         my ($name) = @_;
 294
 295         my $conf = $git->config("remotes." . $name);
 296         if (defined($conf)) {
 297                 @remotes = split(' ', $conf);
 298         } elsif ($name eq 'default') {
 299                 undef @remotes;
 300                 for (sort keys %$remote) {
 301                         my $do_fetch = $git->config_bool("remote." . $_ .
 302                                                     ".skipDefaultUpdate");
 303                         unless ($do_fetch) {
 304                                 push @remotes, $_;
 305                         }
 306                 }
 307         } else {
 308                 print STDERR "Remote group $name does not exists.\n";
 309                 exit(1);
 310         }
 311         for (@remotes) {
 312                 print "Updating $_\n";
 313                 $git->command('fetch', "$_");
 314         }
 315 }
 316
 317 sub add_usage {
 318         print STDERR "Usage: git remote add [-f] [-t track]* [-m master] <name> <url>\n";
 319         exit(1);
 320 }
 321
 322 local $VERBOSE = 0;
 323 @ARGV = grep {
 324         if ($_ eq '-v' or $_ eq '--verbose') {
 325                 $VERBOSE=1;
 326                 0
 327         } else {
 328                 1
 329         }
 330 } @ARGV;
 331
 332 if (!@ARGV) {
 333         for (sort keys %$remote) {
 334                 print "$_";
 335                 print "\t$remote->{$_}->{URL}" if $VERBOSE;
 336                 print "\n";
 337         }
 338 }
 339 elsif ($ARGV[0] eq 'show') {
 340         my $ls_remote = 1;
 341         my $i;
 342         for ($i = 1; $i < @ARGV; $i++) {
 343                 if ($ARGV[$i] eq '-n') {
 344                         $ls_remote = 0;
 345                 }
 346                 else {
 347                         last;
 348                 }
 349         }
 350         if ($i >= @ARGV) {
 351                 print STDERR "Usage: git remote show <remote>\n";
 352                 exit(1);
 353         }
 354         for (; $i < @ARGV; $i++) {
 355                 show_remote($ARGV[$i], $ls_remote);
 356         }
 357 }
 358 elsif ($ARGV[0] eq 'update') {
 359         if (@ARGV <= 1) {
 360                 update_remote("default");
 361                 exit(1);
 362         }
 363         for ($i = 1; $i < @ARGV; $i++) {
 364                 update_remote($ARGV[$i]);
 365         }
 366 }
 367 elsif ($ARGV[0] eq 'prune') {
 368         my $ls_remote = 1;
 369         my $i;
 370         for ($i = 1; $i < @ARGV; $i++) {
 371                 if ($ARGV[$i] eq '-n') {
 372                         $ls_remote = 0;
 373                 }
 374                 else {
 375                         last;
 376                 }
 377         }
 378         if ($i >= @ARGV) {
 379                 print STDERR "Usage: git remote prune <remote>\n";
 380                 exit(1);
 381         }
 382         for (; $i < @ARGV; $i++) {
 383                 prune_remote($ARGV[$i], $ls_remote);
 384         }
 385 }
 386 elsif ($ARGV[0] eq 'add') {
 387         my %opts = ();
 388         while (1 < @ARGV && $ARGV[1] =~ /^-/) {
 389                 my $opt = $ARGV[1];
 390                 shift @ARGV;
 391                 if ($opt eq '-f' || $opt eq '--fetch') {
 392                         $opts{'fetch'} = 1;
 393                         next;
 394                 }
 395                 if ($opt eq '-t' || $opt eq '--track') {
 396                         if (@ARGV < 1) {
 397                                 add_usage();
 398                         }
 399                         $opts{'track'} ||= [];
 400                         push @{$opts{'track'}}, $ARGV[1];
 401                         shift @ARGV;
 402                         next;
 403                 }
 404                 if ($opt eq '-m' || $opt eq '--master') {
 405                         if ((@ARGV < 1) || exists $opts{'master'}) {
 406                                 add_usage();
 407                         }
 408                         $opts{'master'} = $ARGV[1];
 409                         shift @ARGV;
 410                         next;
 411                 }
 412                 add_usage();
 413         }
 414         if (@ARGV != 3) {
 415                 add_usage();
 416         }
 417         add_remote($ARGV[1], $ARGV[2], \%opts);
 418 }
 419 else {
 420         print STDERR "Usage: git remote\n";
 421         print STDERR "       git remote add <name> <url>\n";
 422         print STDERR "       git remote show <name>\n";
 423         print STDERR "       git remote prune <name>\n";
 424         print STDERR "       git remote update [group]\n";
 425         exit(1);
 426 }