?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
add option to find zlib in custom path
[git/jrn.git] / git-svn.perl
blobee7ef693fa9300082ca090ebf97f7e242043fb72
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
13 $ENV{GIT_DIR} ||= '.git';
14 $Git::SVN::default_repo_id = 'svn';
15 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
16 $Git::SVN::Ra::_log_window_size = 100;
17
18 $Git::SVN::Log::TZ = $ENV{TZ};
19 $ENV{TZ} = 'UTC';
20 $| = 1; # unbuffer STDOUT
21
22 sub fatal (@) { print STDERR @_; exit 1 }
23 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
24 require SVN::Ra;
25 require SVN::Delta;
26 if ($SVN::Core::VERSION lt '1.1.0') {
27 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
28 }
29 push @Git::SVN::Ra::ISA, 'SVN::Ra';
30 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
31 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
32 use Carp qw/croak/;
33 use IO::File qw//;
34 use File::Basename qw/dirname basename/;
35 use File::Path qw/mkpath/;
36 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
37 use IPC::Open3;
38 use Git;
39
40 BEGIN {
41 # import functions from Git into our packages, en masse
42 no strict 'refs';
43 foreach (qw/command command_oneline command_noisy command_output_pipe
44 command_input_pipe command_close_pipe/) {
45 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
46 Git::SVN::Migration Git::SVN::Log Git::SVN),
47 __PACKAGE__) {
48 *{"${package}::$_"} = \&{"Git::$_"};
49 }
50 }
51 }
52
53 my ($SVN);
54
55 $sha1 = qr/[a-f\d]{40}/;
56 $sha1_short = qr/[a-f\d]{4,40}/;
57 my ($_stdin, $_help, $_edit,
58 $_message, $_file,
59 $_template, $_shared,
60 $_version, $_fetch_all, $_no_rebase,
61 $_merge, $_strategy, $_dry_run, $_local,
62 $_prefix, $_no_checkout, $_verbose);
63 $Git::SVN::_follow_parent = 1;
64 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
65 'config-dir=s' => \$Git::SVN::Ra::config_dir,
66 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
67 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
68 'authors-file|A=s' => \$_authors,
69 'repack:i' => \$Git::SVN::_repack,
70 'noMetadata' => \$Git::SVN::_no_metadata,
71 'useSvmProps' => \$Git::SVN::_use_svm_props,
72 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
73 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
74 'no-checkout' => \$_no_checkout,
75 'quiet|q' => \$_q,
76 'repack-flags|repack-args|repack-opts=s' =>
77 \$Git::SVN::_repack_flags,
78 %remote_opts );
79
80 my ($_trunk, $_tags, $_branches);
81 my %icv;
82 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
83 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
84 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
85 'minimize-url|m' => \$Git::SVN::_minimize_url,
86 'no-metadata' => sub { $icv{noMetadata} = 1 },
87 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
88 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
89 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
90 %remote_opts );
91 my %cmt_opts = ( 'edit|e' => \$_edit,
92 'rmdir' => \$SVN::Git::Editor::_rmdir,
93 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
94 'l=i' => \$SVN::Git::Editor::_rename_limit,
95 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
96 );
97
98 my %cmd = (
99 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
100 { 'revision|r=s' => \$_revision,
101 'fetch-all|all' => \$_fetch_all,
102 %fc_opts } ],
103 clone => [ \&cmd_clone, "Initialize and fetch revisions",
104 { 'revision|r=s' => \$_revision,
105 %fc_opts, %init_opts } ],
106 init => [ \&cmd_init, "Initialize a repo for tracking" .
107 " (requires URL argument)",
108 \%init_opts ],
109 'multi-init' => [ \&cmd_multi_init,
110 "Deprecated alias for ".
111 "'$0 init -T<trunk> -b<branches> -t<tags>'",
112 \%init_opts ],
113 dcommit => [ \&cmd_dcommit,
114 'Commit several diffs to merge with upstream',
115 { 'merge|m|M' => \$_merge,
116 'strategy|s=s' => \$_strategy,
117 'verbose|v' => \$_verbose,
118 'dry-run|n' => \$_dry_run,
119 'fetch-all|all' => \$_fetch_all,
120 'no-rebase' => \$_no_rebase,
121 %cmt_opts, %fc_opts } ],
122 'set-tree' => [ \&cmd_set_tree,
123 "Set an SVN repository to a git tree-ish",
124 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
125 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
126 { 'revision|r=i' => \$_revision } ],
127 'multi-fetch' => [ \&cmd_multi_fetch,
128 "Deprecated alias for $0 fetch --all",
129 { 'revision|r=s' => \$_revision, %fc_opts } ],
130 'migrate' => [ sub { },
131 # no-op, we automatically run this anyways,
132 'Migrate configuration/metadata/layout from
133 previous versions of git-svn',
134 { 'minimize' => \$Git::SVN::Migration::_minimize,
135 %remote_opts } ],
136 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
137 { 'limit=i' => \$Git::SVN::Log::limit,
138 'revision|r=s' => \$_revision,
139 'verbose|v' => \$Git::SVN::Log::verbose,
140 'incremental' => \$Git::SVN::Log::incremental,
141 'oneline' => \$Git::SVN::Log::oneline,
142 'show-commit' => \$Git::SVN::Log::show_commit,
143 'non-recursive' => \$Git::SVN::Log::non_recursive,
144 'authors-file|A=s' => \$_authors,
145 'color' => \$Git::SVN::Log::color,
146 'pager=s' => \$Git::SVN::Log::pager,
147 } ],
148 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
149 { } ],
150 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
151 { 'merge|m|M' => \$_merge,
152 'verbose|v' => \$_verbose,
153 'strategy|s=s' => \$_strategy,
154 'local|l' => \$_local,
155 'fetch-all|all' => \$_fetch_all,
156 %fc_opts } ],
157 'commit-diff' => [ \&cmd_commit_diff,
158 'Commit a diff between two trees',
159 { 'message|m=s' => \$_message,
160 'file|F=s' => \$_file,
161 'revision|r=s' => \$_revision,
162 %cmt_opts } ],
163 );
164
165 my $cmd;
166 for (my $i = 0; $i < @ARGV; $i++) {
167 if (defined $cmd{$ARGV[$i]}) {
168 $cmd = $ARGV[$i];
169 splice @ARGV, $i, 1;
170 last;
171 }
172 };
173
174 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
175
176 read_repo_config(\%opts);
177 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
178 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
179 'minimize-connections' => \$Git::SVN::Migration::_minimize,
180 'id|i=s' => \$Git::SVN::default_ref_id,
181 'svn-remote|remote|R=s' => sub {
182 $Git::SVN::no_reuse_existing = 1;
183 $Git::SVN::default_repo_id = $_[1] });
184 exit 1 if (!$rv && $cmd && $cmd ne 'log');
185
186 usage(0) if $_help;
187 version() if $_version;
188 usage(1) unless defined $cmd;
189 load_authors() if $_authors;
190
191 # make sure we're always running
192 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
193 unless (-d $ENV{GIT_DIR}) {
194 if ($git_dir_user_set) {
195 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
196 "but it is not a directory\n";
197 }
198 my $git_dir = delete $ENV{GIT_DIR};
199 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
200 unless (length $cdup) {
201 die "Already at toplevel, but $git_dir ",
202 "not found '$cdup'\n";
203 }
204 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
205 unless (-d $git_dir) {
206 die "$git_dir still not found after going to ",
207 "'$cdup'\n";
208 }
209 $ENV{GIT_DIR} = $git_dir;
210 }
211 }
212 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
213 Git::SVN::Migration::migration_check();
214 }
215 Git::SVN::init_vars();
216 eval {
217 Git::SVN::verify_remotes_sanity();
218 $cmd{$cmd}->[0]->(@ARGV);
219 };
220 fatal $@ if $@;
221 post_fetch_checkout();
222 exit 0;
223
224 ####################### primary functions ######################
225 sub usage {
226 my $exit = shift || 0;
227 my $fd = $exit ? \*STDERR : \*STDOUT;
228 print $fd <<"";
229 git-svn - bidirectional operations between a single Subversion tree and git
230 Usage: $0 <command> [options] [arguments]\n
231
232 print $fd "Available commands:\n" unless $cmd;
233
234 foreach (sort keys %cmd) {
235 next if $cmd && $cmd ne $_;
236 next if /^multi-/; # don't show deprecated commands
237 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
238 foreach (keys %{$cmd{$_}->[2]}) {
239 # mixed-case options are for .git/config only
240 next if /[A-Z]/ && /^[a-z]+$/i;
241 # prints out arguments as they should be passed:
242 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
243 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
244 "--$_" : "-$_" }
245 split /\|/,$_)," $x\n";
246 }
247 }
248 print $fd <<"";
249 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
250 arbitrary identifier if you're tracking multiple SVN branches/repositories in
251 one git repository and want to keep them separate. See git-svn(1) for more
252 information.
253
254 exit $exit;
255 }
256
257 sub version {
258 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
259 exit 0;
260 }
261
262 sub do_git_init_db {
263 unless (-d $ENV{GIT_DIR}) {
264 my @init_db = ('init');
265 push @init_db, "--template=$_template" if defined $_template;
266 if (defined $_shared) {
267 if ($_shared =~ /[a-z]/) {
268 push @init_db, "--shared=$_shared";
269 } else {
270 push @init_db, "--shared";
271 }
272 }
273 command_noisy(@init_db);
274 }
275 my $set;
276 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
277 foreach my $i (keys %icv) {
278 die "'$set' and '$i' cannot both be set\n" if $set;
279 next unless defined $icv{$i};
280 command_noisy('config', "$pfx.$i", $icv{$i});
281 $set = $i;
282 }
283 }
284
285 sub init_subdir {
286 my $repo_path = shift or return;
287 mkpath([$repo_path]) unless -d $repo_path;
288 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
289 $ENV{GIT_DIR} = '.git';
290 }
291
292 sub cmd_clone {
293 my ($url, $path) = @_;
294 if (!defined $path &&
295 (defined $_trunk || defined $_branches || defined $_tags) &&
296 $url !~ m#^[a-z\+]+://#) {
297 $path = $url;
298 }
299 $path = basename($url) if !defined $path || !length $path;
300 cmd_init($url, $path);
301 Git::SVN::fetch_all($Git::SVN::default_repo_id);
302 }
303
304 sub cmd_init {
305 if (defined $_trunk || defined $_branches || defined $_tags) {
306 return cmd_multi_init(@_);
307 }
308 my $url = shift or die "SVN repository location required ",
309 "as a command-line argument\n";
310 init_subdir(@_);
311 do_git_init_db();
312
313 Git::SVN->init($url);
314 }
315
316 sub cmd_fetch {
317 if (grep /^\d+=./, @_) {
318 die "'<rev>=<commit>' fetch arguments are ",
319 "no longer supported.\n";
320 }
321 my ($remote) = @_;
322 if (@_ > 1) {
323 die "Usage: $0 fetch [--all] [svn-remote]\n";
324 }
325 $remote ||= $Git::SVN::default_repo_id;
326 if ($_fetch_all) {
327 cmd_multi_fetch();
328 } else {
329 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
330 }
331 }
332
333 sub cmd_set_tree {
334 my (@commits) = @_;
335 if ($_stdin || !@commits) {
336 print "Reading from stdin...\n";
337 @commits = ();
338 while (<STDIN>) {
339 if (/\b($sha1_short)\b/o) {
340 unshift @commits, $1;
341 }
342 }
343 }
344 my @revs;
345 foreach my $c (@commits) {
346 my @tmp = command('rev-parse',$c);
347 if (scalar @tmp == 1) {
348 push @revs, $tmp[0];
349 } elsif (scalar @tmp > 1) {
350 push @revs, reverse(command('rev-list',@tmp));
351 } else {
352 fatal "Failed to rev-parse $c\n";
353 }
354 }
355 my $gs = Git::SVN->new;
356 my ($r_last, $cmt_last) = $gs->last_rev_commit;
357 $gs->fetch;
358 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
359 fatal "There are new revisions that were fetched ",
360 "and need to be merged (or acknowledged) ",
361 "before committing.\nlast rev: $r_last\n",
362 " current: $gs->{last_rev}\n";
363 }
364 $gs->set_tree($_) foreach @revs;
365 print "Done committing ",scalar @revs," revisions to SVN\n";
366 }
367
368 sub cmd_dcommit {
369 my $head = shift;
370 $head ||= 'HEAD';
371 my @refs;
372 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
373 unless ($gs) {
374 die "Unable to determine upstream SVN information from ",
375 "$head history\n";
376 }
377 my $last_rev;
378 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
379 foreach my $d (@$linear_refs) {
380 unless (defined $last_rev) {
381 (undef, $last_rev, undef) = cmt_metadata("$d~1");
382 unless (defined $last_rev) {
383 fatal "Unable to extract revision information ",
384 "from commit $d~1\n";
385 }
386 }
387 if ($_dry_run) {
388 print "diff-tree $d~1 $d\n";
389 } else {
390 my %ed_opts = ( r => $last_rev,
391 log => get_commit_entry($d)->{log},
392 ra => Git::SVN::Ra->new($gs->full_url),
393 tree_a => "$d~1",
394 tree_b => $d,
395 editor_cb => sub {
396 print "Committed r$_[0]\n";
397 $last_rev = $_[0]; },
398 svn_path => '');
399 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
400 print "No changes\n$d~1 == $d\n";
401 } elsif ($parents->{$d} && @{$parents->{$d}}) {
402 $gs->{inject_parents_dcommit}->{$last_rev} =
403 $parents->{$d};
404 }
405 }
406 }
407 return if $_dry_run;
408 unless ($gs) {
409 warn "Could not determine fetch information for $url\n",
410 "Will not attempt to fetch and rebase commits.\n",
411 "This probably means you have useSvmProps and should\n",
412 "now resync your SVN::Mirror repository.\n";
413 return;
414 }
415 $_fetch_all ? $gs->fetch_all : $gs->fetch;
416 unless ($_no_rebase) {
417 # we always want to rebase against the current HEAD, not any
418 # head that was passed to us
419 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
420 my @finish;
421 if (@diff) {
422 @finish = rebase_cmd();
423 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
424 "using @finish:\n", "@diff";
425 } else {
426 print "No changes between current HEAD and ",
427 $gs->refname, "\nResetting to the latest ",
428 $gs->refname, "\n";
429 @finish = qw/reset --mixed/;
430 }
431 command_noisy(@finish, $gs->refname);
432 }
433 }
434
435 sub cmd_find_rev {
436 my $revision_or_hash = shift;
437 my $result;
438 if ($revision_or_hash =~ /^r\d+$/) {
439 my $head = shift;
440 $head ||= 'HEAD';
441 my @refs;
442 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
443 unless ($gs) {
444 die "Unable to determine upstream SVN information from ",
445 "$head history\n";
446 }
447 my $desired_revision = substr($revision_or_hash, 1);
448 $result = $gs->rev_db_get($desired_revision);
449 } else {
450 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
451 $result = $rev;
452 }
453 print "$result\n" if $result;
454 }
455
456 sub cmd_rebase {
457 command_noisy(qw/update-index --refresh/);
458 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
459 unless ($gs) {
460 die "Unable to determine upstream SVN information from ",
461 "working tree history\n";
462 }
463 if (command(qw/diff-index HEAD --/)) {
464 print STDERR "Cannot rebase with uncommited changes:\n";
465 command_noisy('status');
466 exit 1;
467 }
468 unless ($_local) {
469 $_fetch_all ? $gs->fetch_all : $gs->fetch;
470 }
471 command_noisy(rebase_cmd(), $gs->refname);
472 }
473
474 sub cmd_show_ignore {
475 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
476 $gs ||= Git::SVN->new;
477 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
478 $gs->traverse_ignore(\*STDOUT, $gs->{path}, $r);
479 }
480
481 sub cmd_multi_init {
482 my $url = shift;
483 unless (defined $_trunk || defined $_branches || defined $_tags) {
484 usage(1);
485 }
486
487 # there are currently some bugs that prevent multi-init/multi-fetch
488 # setups from working well without this.
489 $Git::SVN::_minimize_url = 1;
490
491 $_prefix = '' unless defined $_prefix;
492 if (defined $url) {
493 $url =~ s#/+$##;
494 init_subdir(@_);
495 }
496 do_git_init_db();
497 if (defined $_trunk) {
498 my $trunk_ref = $_prefix . 'trunk';
499 # try both old-style and new-style lookups:
500 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
501 unless ($gs_trunk) {
502 my ($trunk_url, $trunk_path) =
503 complete_svn_url($url, $_trunk);
504 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
505 undef, $trunk_ref);
506 }
507 }
508 return unless defined $_branches || defined $_tags;
509 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
510 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
511 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
512 }
513
514 sub cmd_multi_fetch {
515 my $remotes = Git::SVN::read_all_remotes();
516 foreach my $repo_id (sort keys %$remotes) {
517 if ($remotes->{$repo_id}->{url}) {
518 Git::SVN::fetch_all($repo_id, $remotes);
519 }
520 }
521 }
522
523 # this command is special because it requires no metadata
524 sub cmd_commit_diff {
525 my ($ta, $tb, $url) = @_;
526 my $usage = "Usage: $0 commit-diff -r<revision> ".
527 "<tree-ish> <tree-ish> [<URL>]\n";
528 fatal($usage) if (!defined $ta || !defined $tb);
529 my $svn_path;
530 if (!defined $url) {
531 my $gs = eval { Git::SVN->new };
532 if (!$gs) {
533 fatal("Needed URL or usable git-svn --id in ",
534 "the command-line\n", $usage);
535 }
536 $url = $gs->{url};
537 $svn_path = $gs->{path};
538 }
539 unless (defined $_revision) {
540 fatal("-r|--revision is a required argument\n", $usage);
541 }
542 if (defined $_message && defined $_file) {
543 fatal("Both --message/-m and --file/-F specified ",
544 "for the commit message.\n",
545 "I have no idea what you mean\n");
546 }
547 if (defined $_file) {
548 $_message = file_to_s($_file);
549 } else {
550 $_message ||= get_commit_entry($tb)->{log};
551 }
552 my $ra ||= Git::SVN::Ra->new($url);
553 $svn_path ||= $ra->{svn_path};
554 my $r = $_revision;
555 if ($r eq 'HEAD') {
556 $r = $ra->get_latest_revnum;
557 } elsif ($r !~ /^\d+$/) {
558 die "revision argument: $r not understood by git-svn\n";
559 }
560 my %ed_opts = ( r => $r,
561 log => $_message,
562 ra => $ra,
563 tree_a => $ta,
564 tree_b => $tb,
565 editor_cb => sub { print "Committed r$_[0]\n" },
566 svn_path => $svn_path );
567 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
568 print "No changes\n$ta == $tb\n";
569 }
570 }
571
572 ########################### utility functions #########################
573
574 sub rebase_cmd {
575 my @cmd = qw/rebase/;
576 push @cmd, '-v' if $_verbose;
577 push @cmd, qw/--merge/ if $_merge;
578 push @cmd, "--strategy=$_strategy" if $_strategy;
579 @cmd;
580 }
581
582 sub post_fetch_checkout {
583 return if $_no_checkout;
584 my $gs = $Git::SVN::_head or return;
585 return if verify_ref('refs/heads/master^0');
586
587 my $valid_head = verify_ref('HEAD^0');
588 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
589 return if ($valid_head || !verify_ref('HEAD^0'));
590
591 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
592 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
593 return if -f $index;
594
595 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
596 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
597 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
598 print STDERR "Checked out HEAD:\n ",
599 $gs->full_url, " r", $gs->last_rev, "\n";
600 }
601
602 sub complete_svn_url {
603 my ($url, $path) = @_;
604 $path =~ s#/+$##;
605 if ($path !~ m#^[a-z\+]+://#) {
606 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
607 fatal("E: '$path' is not a complete URL ",
608 "and a separate URL is not specified\n");
609 }
610 return ($url, $path);
611 }
612 return ($path, '');
613 }
614
615 sub complete_url_ls_init {
616 my ($ra, $repo_path, $switch, $pfx) = @_;
617 unless ($repo_path) {
618 print STDERR "W: $switch not specified\n";
619 return;
620 }
621 $repo_path =~ s#/+$##;
622 if ($repo_path =~ m#^[a-z\+]+://#) {
623 $ra = Git::SVN::Ra->new($repo_path);
624 $repo_path = '';
625 } else {
626 $repo_path =~ s#^/+##;
627 unless ($ra) {
628 fatal("E: '$repo_path' is not a complete URL ",
629 "and a separate URL is not specified\n");
630 }
631 }
632 my $url = $ra->{url};
633 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
634 my $k = "svn-remote.$gs->{repo_id}.url";
635 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
636 if ($orig_url && ($orig_url ne $gs->{url})) {
637 die "$k already set: $orig_url\n",
638 "wanted to set to: $gs->{url}\n";
639 }
640 command_oneline('config', $k, $gs->{url}) unless $orig_url;
641 my $remote_path = "$ra->{svn_path}/$repo_path/*";
642 $remote_path =~ s#/+#/#g;
643 $remote_path =~ s#^/##g;
644 my ($n) = ($switch =~ /^--(\w+)/);
645 if (length $pfx && $pfx !~ m#/$#) {
646 die "--prefix='$pfx' must have a trailing slash '/'\n";
647 }
648 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
649 "$remote_path:refs/remotes/$pfx*");
650 }
651
652 sub verify_ref {
653 my ($ref) = @_;
654 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
655 { STDERR => 0 }); };
656 }
657
658 sub get_tree_from_treeish {
659 my ($treeish) = @_;
660 # $treeish can be a symbolic ref, too:
661 my $type = command_oneline(qw/cat-file -t/, $treeish);
662 my $expected;
663 while ($type eq 'tag') {
664 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
665 }
666 if ($type eq 'commit') {
667 $expected = (grep /^tree /, command(qw/cat-file commit/,
668 $treeish))[0];
669 ($expected) = ($expected =~ /^tree ($sha1)$/o);
670 die "Unable to get tree from $treeish\n" unless $expected;
671 } elsif ($type eq 'tree') {
672 $expected = $treeish;
673 } else {
674 die "$treeish is a $type, expected tree, tag or commit\n";
675 }
676 return $expected;
677 }
678
679 sub get_commit_entry {
680 my ($treeish) = shift;
681 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
682 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
683 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
684 open my $log_fh, '>', $commit_editmsg or croak $!;
685
686 my $type = command_oneline(qw/cat-file -t/, $treeish);
687 if ($type eq 'commit' || $type eq 'tag') {
688 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
689 $type, $treeish);
690 my $in_msg = 0;
691 while (<$msg_fh>) {
692 if (!$in_msg) {
693 $in_msg = 1 if (/^\s*$/);
694 } elsif (/^git-svn-id: /) {
695 # skip this for now, we regenerate the
696 # correct one on re-fetch anyways
697 # TODO: set *:merge properties or like...
698 } else {
699 print $log_fh $_ or croak $!;
700 }
701 }
702 command_close_pipe($msg_fh, $ctx);
703 }
704 close $log_fh or croak $!;
705
706 if ($_edit || ($type eq 'tree')) {
707 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
708 # TODO: strip out spaces, comments, like git-commit.sh
709 system($editor, $commit_editmsg);
710 }
711 rename $commit_editmsg, $commit_msg or croak $!;
712 open $log_fh, '<', $commit_msg or croak $!;
713 { local $/; chomp($log_entry{log} = <$log_fh>); }
714 close $log_fh or croak $!;
715 unlink $commit_msg;
716 \%log_entry;
717 }
718
719 sub s_to_file {
720 my ($str, $file, $mode) = @_;
721 open my $fd,'>',$file or croak $!;
722 print $fd $str,"\n" or croak $!;
723 close $fd or croak $!;
724 chmod ($mode &~ umask, $file) if (defined $mode);
725 }
726
727 sub file_to_s {
728 my $file = shift;
729 open my $fd,'<',$file or croak "$!: file: $file\n";
730 local $/;
731 my $ret = <$fd>;
732 close $fd or croak $!;
733 $ret =~ s/\s*$//s;
734 return $ret;
735 }
736
737 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
738 sub load_authors {
739 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
740 my $log = $cmd eq 'log';
741 while (<$authors>) {
742 chomp;
743 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
744 my ($user, $name, $email) = ($1, $2, $3);
745 if ($log) {
746 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
747 } else {
748 $users{$user} = [$name, $email];
749 }
750 }
751 close $authors or croak $!;
752 }
753
754 # convert GetOpt::Long specs for use by git-config
755 sub read_repo_config {
756 return unless -d $ENV{GIT_DIR};
757 my $opts = shift;
758 my @config_only;
759 foreach my $o (keys %$opts) {
760 # if we have mixedCase and a long option-only, then
761 # it's a config-only variable that we don't need for
762 # the command-line.
763 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
764 my $v = $opts->{$o};
765 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
766 $key =~ s/-//g;
767 my $arg = 'git-config';
768 $arg .= ' --int' if ($o =~ /[:=]i$/);
769 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
770 if (ref $v eq 'ARRAY') {
771 chomp(my @tmp = `$arg --get-all svn.$key`);
772 @$v = @tmp if @tmp;
773 } else {
774 chomp(my $tmp = `$arg --get svn.$key`);
775 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
776 $$v = $tmp;
777 }
778 }
779 }
780 delete @$opts{@config_only} if @config_only;
781 }
782
783 sub extract_metadata {
784 my $id = shift or return (undef, undef, undef);
785 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
786 \s([a-f\d\-]+)$/x);
787 if (!defined $rev || !$uuid || !$url) {
788 # some of the original repositories I made had
789 # identifiers like this:
790 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
791 }
792 return ($url, $rev, $uuid);
793 }
794
795 sub cmt_metadata {
796 return extract_metadata((grep(/^git-svn-id: /,
797 command(qw/cat-file commit/, shift)))[-1]);
798 }
799
800 sub working_head_info {
801 my ($head, $refs) = @_;
802 my ($fh, $ctx) = command_output_pipe('log', $head);
803 my $hash;
804 my %max;
805 while (<$fh>) {
806 if ( m{^commit ($::sha1)$} ) {
807 unshift @$refs, $hash if $hash and $refs;
808 $hash = $1;
809 next;
810 }
811 next unless s{^\s*(git-svn-id:)}{$1};
812 my ($url, $rev, $uuid) = extract_metadata($_);
813 if (defined $url && defined $rev) {
814 next if $max{$url} and $max{$url} < $rev;
815 if (my $gs = Git::SVN->find_by_url($url)) {
816 my $c = $gs->rev_db_get($rev);
817 if ($c && $c eq $hash) {
818 close $fh; # break the pipe
819 return ($url, $rev, $uuid, $gs);
820 } else {
821 $max{$url} ||= $gs->rev_db_max;
822 }
823 }
824 }
825 }
826 command_close_pipe($fh, $ctx);
827 (undef, undef, undef, undef);
828 }
829
830 sub read_commit_parents {
831 my ($parents, $c) = @_;
832 my ($fh, $ctx) = command_output_pipe(qw/cat-file commit/, $c);
833 while (<$fh>) {
834 chomp;
835 last if '';
836 /^parent ($sha1)/ or next;
837 push @{$parents->{$c}}, $1;
838 }
839 close $fh; # break the pipe
840 }
841
842 sub linearize_history {
843 my ($gs, $refs) = @_;
844 my %parents;
845 foreach my $c (@$refs) {
846 read_commit_parents(\%parents, $c);
847 }
848
849 my @linear_refs;
850 my %skip = ();
851 my $last_svn_commit = $gs->last_commit;
852 foreach my $c (reverse @$refs) {
853 next if $c eq $last_svn_commit;
854 last if $skip{$c};
855
856 unshift @linear_refs, $c;
857 $skip{$c} = 1;
858
859 # we only want the first parent to diff against for linear
860 # history, we save the rest to inject when we finalize the
861 # svn commit
862 my $fp_a = verify_ref("$c~1");
863 my $fp_b = shift @{$parents{$c}} if $parents{$c};
864 if (!$fp_a || !$fp_b) {
865 die "Commit $c\n",
866 "has no parent commit, and therefore ",
867 "nothing to diff against.\n",
868 "You should be working from a repository ",
869 "originally created by git-svn\n";
870 }
871 if ($fp_a ne $fp_b) {
872 die "$c~1 = $fp_a, however parsing commit $c ",
873 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
874 }
875
876 foreach my $p (@{$parents{$c}}) {
877 $skip{$p} = 1;
878 }
879 }
880 (\@linear_refs, \%parents);
881 }
882
883 package Git::SVN;
884 use strict;
885 use warnings;
886 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
887 $_repack $_repack_flags $_use_svm_props $_head
888 $_use_svnsync_props $no_reuse_existing $_minimize_url/;
889 use Carp qw/croak/;
890 use File::Path qw/mkpath/;
891 use File::Copy qw/copy/;
892 use IPC::Open3;
893
894 my $_repack_nr;
895 # properties that we do not log:
896 my %SKIP_PROP;
897 BEGIN {
898 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
899 svn:special svn:executable
900 svn:entry:committed-rev
901 svn:entry:last-author
902 svn:entry:uuid
903 svn:entry:committed-date/;
904
905 # some options are read globally, but can be overridden locally
906 # per [svn-remote "..."] section. Command-line options will *NOT*
907 # override options set in an [svn-remote "..."] section
908 no strict 'refs';
909 for my $option (qw/follow_parent no_metadata use_svm_props
910 use_svnsync_props/) {
911 my $key = $option;
912 $key =~ tr/_//d;
913 my $prop = "-$option";
914 *$option = sub {
915 my ($self) = @_;
916 return $self->{$prop} if exists $self->{$prop};
917 my $k = "svn-remote.$self->{repo_id}.$key";
918 eval { command_oneline(qw/config --get/, $k) };
919 if ($@) {
920 $self->{$prop} = ${"Git::SVN::_$option"};
921 } else {
922 my $v = command_oneline(qw/config --bool/,$k);
923 $self->{$prop} = $v eq 'false' ? 0 : 1;
924 }
925 return $self->{$prop};
926 }
927 }
928 }
929
930 my %LOCKFILES;
931 END { unlink keys %LOCKFILES if %LOCKFILES }
932
933 sub resolve_local_globs {
934 my ($url, $fetch, $glob_spec) = @_;
935 return unless defined $glob_spec;
936 my $ref = $glob_spec->{ref};
937 my $path = $glob_spec->{path};
938 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
939 next unless m#^refs/remotes/$ref->{regex}$#;
940 my $p = $1;
941 my $pathname = desanitize_refname($path->full_path($p));
942 my $refname = desanitize_refname($ref->full_path($p));
943 if (my $existing = $fetch->{$pathname}) {
944 if ($existing ne $refname) {
945 die "Refspec conflict:\n",
946 "existing: refs/remotes/$existing\n",
947 " globbed: refs/remotes/$refname\n";
948 }
949 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
950 $u =~ s!^\Q$url\E(/|$)!! or die
951 "refs/remotes/$refname: '$url' not found in '$u'\n";
952 if ($pathname ne $u) {
953 warn "W: Refspec glob conflict ",
954 "(ref: refs/remotes/$refname):\n",
955 "expected path: $pathname\n",
956 " real path: $u\n",
957 "Continuing ahead with $u\n";
958 next;
959 }
960 } else {
961 $fetch->{$pathname} = $refname;
962 }
963 }
964 }
965
966 sub parse_revision_argument {
967 my ($base, $head) = @_;
968 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
969 return ($base, $head);
970 }
971 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
972 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
973 return ($head, $head) if ($::_revision eq 'HEAD');
974 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
975 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
976 die "revision argument: $::_revision not understood by git-svn\n";
977 }
978
979 sub fetch_all {
980 my ($repo_id, $remotes) = @_;
981 if (ref $repo_id) {
982 my $gs = $repo_id;
983 $repo_id = undef;
984 $repo_id = $gs->{repo_id};
985 }
986 $remotes ||= read_all_remotes();
987 my $remote = $remotes->{$repo_id} or
988 die "[svn-remote \"$repo_id\"] unknown\n";
989 my $fetch = $remote->{fetch};
990 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
991 my (@gs, @globs);
992 my $ra = Git::SVN::Ra->new($url);
993 my $uuid = $ra->get_uuid;
994 my $head = $ra->get_latest_revnum;
995 my $base = defined $fetch ? $head : 0;
996
997 # read the max revs for wildcard expansion (branches/*, tags/*)
998 foreach my $t (qw/branches tags/) {
999 defined $remote->{$t} or next;
1000 push @globs, $remote->{$t};
1001 my $max_rev = eval { tmp_config(qw/--int --get/,
1002 "svn-remote.$repo_id.${t}-maxRev") };
1003 if (defined $max_rev && ($max_rev < $base)) {
1004 $base = $max_rev;
1005 } elsif (!defined $max_rev) {
1006 $base = 0;
1007 }
1008 }
1009
1010 if ($fetch) {
1011 foreach my $p (sort keys %$fetch) {
1012 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1013 my $lr = $gs->rev_db_max;
1014 if (defined $lr) {
1015 $base = $lr if ($lr < $base);
1016 }
1017 push @gs, $gs;
1018 }
1019 }
1020
1021 ($base, $head) = parse_revision_argument($base, $head);
1022 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1023 }
1024
1025 sub read_all_remotes {
1026 my $r = {};
1027 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1028 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1029 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1030 $local_ref =~ s{^/}{};
1031 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1032 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1033 $r->{$1}->{url} = $2;
1034 } elsif (m!^(.+)\.(branches|tags)=
1035 (.*):refs/remotes/(.+)\s*$/!x) {
1036 my ($p, $g) = ($3, $4);
1037 my $rs = $r->{$1}->{$2} = {
1038 t => $2,
1039 remote => $1,
1040 path => Git::SVN::GlobSpec->new($p),
1041 ref => Git::SVN::GlobSpec->new($g) };
1042 if (length($rs->{ref}->{right}) != 0) {
1043 die "The '*' glob character must be the last ",
1044 "character of '$g'\n";
1045 }
1046 }
1047 }
1048 $r;
1049 }
1050
1051 sub init_vars {
1052 if (defined $_repack) {
1053 $_repack = 1000 if ($_repack <= 0);
1054 $_repack_nr = $_repack;
1055 $_repack_flags ||= '-d';
1056 }
1057 }
1058
1059 sub verify_remotes_sanity {
1060 return unless -d $ENV{GIT_DIR};
1061 my %seen;
1062 foreach (command(qw/config -l/)) {
1063 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1064 if ($seen{$1}) {
1065 die "Remote ref refs/remote/$1 is tracked by",
1066 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1067 "Please resolve this ambiguity in ",
1068 "your git configuration file before ",
1069 "continuing\n";
1070 }
1071 $seen{$1} = $_;
1072 }
1073 }
1074 }
1075
1076 # we allow more chars than remotes2config.sh...
1077 sub sanitize_remote_name {
1078 my ($name) = @_;
1079 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1080 $name;
1081 }
1082
1083 sub find_existing_remote {
1084 my ($url, $remotes) = @_;
1085 return undef if $no_reuse_existing;
1086 my $existing;
1087 foreach my $repo_id (keys %$remotes) {
1088 my $u = $remotes->{$repo_id}->{url} or next;
1089 next if $u ne $url;
1090 $existing = $repo_id;
1091 last;
1092 }
1093 $existing;
1094 }
1095
1096 sub init_remote_config {
1097 my ($self, $url, $no_write) = @_;
1098 $url =~ s!/+$!!; # strip trailing slash
1099 my $r = read_all_remotes();
1100 my $existing = find_existing_remote($url, $r);
1101 if ($existing) {
1102 unless ($no_write) {
1103 print STDERR "Using existing ",
1104 "[svn-remote \"$existing\"]\n";
1105 }
1106 $self->{repo_id} = $existing;
1107 } elsif ($_minimize_url) {
1108 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1109 $existing = find_existing_remote($min_url, $r);
1110 if ($existing) {
1111 unless ($no_write) {
1112 print STDERR "Using existing ",
1113 "[svn-remote \"$existing\"]\n";
1114 }
1115 $self->{repo_id} = $existing;
1116 }
1117 if ($min_url ne $url) {
1118 unless ($no_write) {
1119 print STDERR "Using higher level of URL: ",
1120 "$url => $min_url\n";
1121 }
1122 my $old_path = $self->{path};
1123 $self->{path} = $url;
1124 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1125 if (length $old_path) {
1126 $self->{path} .= "/$old_path";
1127 }
1128 $url = $min_url;
1129 }
1130 }
1131 my $orig_url;
1132 if (!$existing) {
1133 # verify that we aren't overwriting anything:
1134 $orig_url = eval {
1135 command_oneline('config', '--get',
1136 "svn-remote.$self->{repo_id}.url")
1137 };
1138 if ($orig_url && ($orig_url ne $url)) {
1139 die "svn-remote.$self->{repo_id}.url already set: ",
1140 "$orig_url\nwanted to set to: $url\n";
1141 }
1142 }
1143 my ($xrepo_id, $xpath) = find_ref($self->refname);
1144 if (defined $xpath) {
1145 die "svn-remote.$xrepo_id.fetch already set to track ",
1146 "$xpath:refs/remotes/", $self->refname, "\n";
1147 }
1148 unless ($no_write) {
1149 command_noisy('config',
1150 "svn-remote.$self->{repo_id}.url", $url);
1151 $self->{path} =~ s{^/}{};
1152 command_noisy('config', '--add',
1153 "svn-remote.$self->{repo_id}.fetch",
1154 "$self->{path}:".$self->refname);
1155 }
1156 $self->{url} = $url;
1157 }
1158
1159 sub find_by_url { # repos_root and, path are optional
1160 my ($class, $full_url, $repos_root, $path) = @_;
1161
1162 return undef unless defined $full_url;
1163 remove_username($full_url);
1164 remove_username($repos_root) if defined $repos_root;
1165 my $remotes = read_all_remotes();
1166 if (defined $full_url && defined $repos_root && !defined $path) {
1167 $path = $full_url;
1168 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1169 }
1170 foreach my $repo_id (keys %$remotes) {
1171 my $u = $remotes->{$repo_id}->{url} or next;
1172 remove_username($u);
1173 next if defined $repos_root && $repos_root ne $u;
1174
1175 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1176 foreach (qw/branches tags/) {
1177 resolve_local_globs($u, $fetch,
1178 $remotes->{$repo_id}->{$_});
1179 }
1180 my $p = $path;
1181 unless (defined $p) {
1182 $p = $full_url;
1183 $p =~ s#^\Q$u\E(?:/|$)## or next;
1184 }
1185 foreach my $f (keys %$fetch) {
1186 next if $f ne $p;
1187 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1188 }
1189 }
1190 undef;
1191 }
1192
1193 sub init {
1194 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1195 my $self = _new($class, $repo_id, $ref_id, $path);
1196 if (defined $url) {
1197 $self->init_remote_config($url, $no_write);
1198 }
1199 $self;
1200 }
1201
1202 sub find_ref {
1203 my ($ref_id) = @_;
1204 foreach (command(qw/config -l/)) {
1205 next unless m!^svn-remote\.(.+)\.fetch=
1206 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1207 my ($repo_id, $path, $ref) = ($1, $2, $3);
1208 if ($ref eq $ref_id) {
1209 $path = '' if ($path =~ m#^\./?#);
1210 return ($repo_id, $path);
1211 }
1212 }
1213 (undef, undef, undef);
1214 }
1215
1216 sub new {
1217 my ($class, $ref_id, $repo_id, $path) = @_;
1218 if (defined $ref_id && !defined $repo_id && !defined $path) {
1219 ($repo_id, $path) = find_ref($ref_id);
1220 if (!defined $repo_id) {
1221 die "Could not find a \"svn-remote.*.fetch\" key ",
1222 "in the repository configuration matching: ",
1223 "refs/remotes/$ref_id\n";
1224 }
1225 }
1226 my $self = _new($class, $repo_id, $ref_id, $path);
1227 if (!defined $self->{path} || !length $self->{path}) {
1228 my $fetch = command_oneline('config', '--get',
1229 "svn-remote.$repo_id.fetch",
1230 ":refs/remotes/$ref_id\$") or
1231 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1232 "\":refs/remotes/$ref_id\$\" in config\n";
1233 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1234 }
1235 $self->{url} = command_oneline('config', '--get',
1236 "svn-remote.$repo_id.url") or
1237 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1238 $self->rebuild;
1239 $self;
1240 }
1241
1242 sub refname {
1243 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1244
1245 # It cannot end with a slash /, we'll throw up on this because
1246 # SVN can't have directories with a slash in their name, either:
1247 if ($refname =~ m{/$}) {
1248 die "ref: '$refname' ends with a trailing slash, this is ",
1249 "not permitted by git nor Subversion\n";
1250 }
1251
1252 # It cannot have ASCII control character space, tilde ~, caret ^,
1253 # colon :, question-mark ?, asterisk *, space, or open bracket [
1254 # anywhere.
1255 #
1256 # Additionally, % must be escaped because it is used for escaping
1257 # and we want our escaped refname to be reversible
1258 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1259
1260 # no slash-separated component can begin with a dot .
1261 # /.* becomes /%2E*
1262 $refname =~ s{/\.}{/%2E}g;
1263
1264 # It cannot have two consecutive dots .. anywhere
1265 # .. becomes %2E%2E
1266 $refname =~ s{\.\.}{%2E%2E}g;
1267
1268 return $refname;
1269 }
1270
1271 sub desanitize_refname {
1272 my ($refname) = @_;
1273 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1274 return $refname;
1275 }
1276
1277 sub svm_uuid {
1278 my ($self) = @_;
1279 return $self->{svm}->{uuid} if $self->svm;
1280 $self->ra;
1281 unless ($self->{svm}) {
1282 die "SVM UUID not cached, and reading remotely failed\n";
1283 }
1284 $self->{svm}->{uuid};
1285 }
1286
1287 sub svm {
1288 my ($self) = @_;
1289 return $self->{svm} if $self->{svm};
1290 my $svm;
1291 # see if we have it in our config, first:
1292 eval {
1293 my $section = "svn-remote.$self->{repo_id}";
1294 $svm = {
1295 source => tmp_config('--get', "$section.svm-source"),
1296 uuid => tmp_config('--get', "$section.svm-uuid"),
1297 replace => tmp_config('--get', "$section.svm-replace"),
1298 }
1299 };
1300 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1301 $self->{svm} = $svm;
1302 }
1303 $self->{svm};
1304 }
1305
1306 sub _set_svm_vars {
1307 my ($self, $ra) = @_;
1308 return $ra if $self->svm;
1309
1310 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1311 "(svm:source, svm:uuid) ",
1312 "from the following URLs:\n" );
1313 sub read_svm_props {
1314 my ($self, $ra, $path, $r) = @_;
1315 my $props = ($ra->get_dir($path, $r))[2];
1316 my $src = $props->{'svm:source'};
1317 my $uuid = $props->{'svm:uuid'};
1318 return undef if (!$src || !$uuid);
1319
1320 chomp($src, $uuid);
1321
1322 $uuid =~ m{^[0-9a-f\-]{30,}$}
1323 or die "doesn't look right - svm:uuid is '$uuid'\n";
1324
1325 # the '!' is used to mark the repos_root!/relative/path
1326 $src =~ s{/?!/?}{/};
1327 $src =~ s{/+$}{}; # no trailing slashes please
1328 # username is of no interest
1329 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1330
1331 my $replace = $ra->{url};
1332 $replace .= "/$path" if length $path;
1333
1334 my $section = "svn-remote.$self->{repo_id}";
1335 tmp_config("$section.svm-source", $src);
1336 tmp_config("$section.svm-replace", $replace);
1337 tmp_config("$section.svm-uuid", $uuid);
1338 $self->{svm} = {
1339 source => $src,
1340 uuid => $uuid,
1341 replace => $replace
1342 };
1343 }
1344
1345 my $r = $ra->get_latest_revnum;
1346 my $path = $self->{path};
1347 my %tried;
1348 while (length $path) {
1349 unless ($tried{"$self->{url}/$path"}) {
1350 return $ra if $self->read_svm_props($ra, $path, $r);
1351 $tried{"$self->{url}/$path"} = 1;
1352 }
1353 $path =~ s#/?[^/]+$##;
1354 }
1355 die "Path: '$path' should be ''\n" if $path ne '';
1356 return $ra if $self->read_svm_props($ra, $path, $r);
1357 $tried{"$self->{url}/$path"} = 1;
1358
1359 if ($ra->{repos_root} eq $self->{url}) {
1360 die @err, (map { " $_\n" } keys %tried), "\n";
1361 }
1362
1363 # nope, make sure we're connected to the repository root:
1364 my $ok;
1365 my @tried_b;
1366 $path = $ra->{svn_path};
1367 $ra = Git::SVN::Ra->new($ra->{repos_root});
1368 while (length $path) {
1369 unless ($tried{"$ra->{url}/$path"}) {
1370 $ok = $self->read_svm_props($ra, $path, $r);
1371 last if $ok;
1372 $tried{"$ra->{url}/$path"} = 1;
1373 }
1374 $path =~ s#/?[^/]+$##;
1375 }
1376 die "Path: '$path' should be ''\n" if $path ne '';
1377 $ok ||= $self->read_svm_props($ra, $path, $r);
1378 $tried{"$ra->{url}/$path"} = 1;
1379 if (!$ok) {
1380 die @err, (map { " $_\n" } keys %tried), "\n";
1381 }
1382 Git::SVN::Ra->new($self->{url});
1383 }
1384
1385 sub svnsync {
1386 my ($self) = @_;
1387 return $self->{svnsync} if $self->{svnsync};
1388
1389 if ($self->no_metadata) {
1390 die "Can't have both 'noMetadata' and ",
1391 "'useSvnsyncProps' options set!\n";
1392 }
1393 if ($self->rewrite_root) {
1394 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1395 "options set!\n";
1396 }
1397
1398 my $svnsync;
1399 # see if we have it in our config, first:
1400 eval {
1401 my $section = "svn-remote.$self->{repo_id}";
1402 $svnsync = {
1403 url => tmp_config('--get', "$section.svnsync-url"),
1404 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1405 }
1406 };
1407 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1408 return $self->{svnsync} = $svnsync;
1409 }
1410
1411 my $err = "useSvnsyncProps set, but failed to read " .
1412 "svnsync property: svn:sync-from-";
1413 my $rp = $self->ra->rev_proplist(0);
1414
1415 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1416 $url =~ m{^[a-z\+]+://} or
1417 die "doesn't look right - svn:sync-from-url is '$url'\n";
1418
1419 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1420 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1421 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1422
1423 my $section = "svn-remote.$self->{repo_id}";
1424 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1425 tmp_config('--add', "$section.svnsync-url", $url);
1426 return $self->{svnsync} = { url => $url, uuid => $uuid };
1427 }
1428
1429 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1430 # remote lookup (useful for 'git svn log').
1431 sub ra_uuid {
1432 my ($self) = @_;
1433 unless ($self->{ra_uuid}) {
1434 my $key = "svn-remote.$self->{repo_id}.uuid";
1435 my $uuid = eval { tmp_config('--get', $key) };
1436 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1437 $self->{ra_uuid} = $uuid;
1438 } else {
1439 die "ra_uuid called without URL\n" unless $self->{url};
1440 $self->{ra_uuid} = $self->ra->get_uuid;
1441 tmp_config('--add', $key, $self->{ra_uuid});
1442 }
1443 }
1444 $self->{ra_uuid};
1445 }
1446
1447 sub ra {
1448 my ($self) = shift;
1449 my $ra = Git::SVN::Ra->new($self->{url});
1450 if ($self->use_svm_props && !$self->{svm}) {
1451 if ($self->no_metadata) {
1452 die "Can't have both 'noMetadata' and ",
1453 "'useSvmProps' options set!\n";
1454 } elsif ($self->use_svnsync_props) {
1455 die "Can't have both 'useSvnsyncProps' and ",
1456 "'useSvmProps' options set!\n";
1457 }
1458 $ra = $self->_set_svm_vars($ra);
1459 $self->{-want_revprops} = 1;
1460 }
1461 $ra;
1462 }
1463
1464 sub rel_path {
1465 my ($self) = @_;
1466 my $repos_root = $self->ra->{repos_root};
1467 return $self->{path} if ($self->{url} eq $repos_root);
1468 my $url = $self->{url} .
1469 (length $self->{path} ? "/$self->{path}" : $self->{path});
1470 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1471 $url;
1472 }
1473
1474 sub traverse_ignore {
1475 my ($self, $fh, $path, $r) = @_;
1476 $path =~ s#^/+##g;
1477 my $ra = $self->ra;
1478 my ($dirent, undef, $props) = $ra->get_dir($path, $r);
1479 my $p = $path;
1480 $p =~ s#^\Q$self->{path}\E(/|$)##;
1481 print $fh length $p ? "\n# $p\n" : "\n# /\n";
1482 if (my $s = $props->{'svn:ignore'}) {
1483 $s =~ s/[\r\n]+/\n/g;
1484 chomp $s;
1485 if (length $p == 0) {
1486 $s =~ s#\n#\n/$p#g;
1487 print $fh "/$s\n";
1488 } else {
1489 $s =~ s#\n#\n/$p/#g;
1490 print $fh "/$p/$s\n";
1491 }
1492 }
1493 foreach (sort keys %$dirent) {
1494 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1495 $self->traverse_ignore($fh, "$path/$_", $r);
1496 }
1497 }
1498
1499 sub last_rev { ($_[0]->last_rev_commit)[0] }
1500 sub last_commit { ($_[0]->last_rev_commit)[1] }
1501
1502 # returns the newest SVN revision number and newest commit SHA1
1503 sub last_rev_commit {
1504 my ($self) = @_;
1505 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1506 return ($self->{last_rev}, $self->{last_commit});
1507 }
1508 my $c = ::verify_ref($self->refname.'^0');
1509 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1510 my $rev = (::cmt_metadata($c))[1];
1511 if (defined $rev) {
1512 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1513 return ($rev, $c);
1514 }
1515 }
1516 my $db_path = $self->db_path;
1517 unless (-e $db_path) {
1518 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1519 return (undef, undef);
1520 }
1521 my $offset = -41; # from tail
1522 my $rl;
1523 open my $fh, '<', $db_path or croak "$db_path not readable: $!\n";
1524 sysseek($fh, $offset, 2); # don't care for errors
1525 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1526 chomp $rl;
1527 while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
1528 $offset -= 41;
1529 sysseek($fh, $offset, 2); # don't care for errors
1530 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1531 chomp $rl;
1532 }
1533 if ($c && $c ne $rl) {
1534 die "$db_path and ", $self->refname,
1535 " inconsistent!:\n$c != $rl\n";
1536 }
1537 my $rev = sysseek($fh, 0, 1) or croak $!;
1538 $rev = ($rev - 41) / 41;
1539 close $fh or croak $!;
1540 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1541 return ($rev, $c);
1542 }
1543
1544 sub get_fetch_range {
1545 my ($self, $min, $max) = @_;
1546 $max ||= $self->ra->get_latest_revnum;
1547 $min ||= $self->rev_db_max;
1548 (++$min, $max);
1549 }
1550
1551 sub tmp_config {
1552 my (@args) = @_;
1553 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1554 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1555 if (! -f $config && -f $old_def_config) {
1556 rename $old_def_config, $config or
1557 die "Failed rename $old_def_config => $config: $!\n";
1558 }
1559 my $old_config = $ENV{GIT_CONFIG};
1560 $ENV{GIT_CONFIG} = $config;
1561 $@ = undef;
1562 my @ret = eval {
1563 unless (-f $config) {
1564 mkfile($config);
1565 open my $fh, '>', $config or
1566 die "Can't open $config: $!\n";
1567 print $fh "; This file is used internally by ",
1568 "git-svn\n" or die
1569 "Couldn't write to $config: $!\n";
1570 print $fh "; You should not have to edit it\n" or
1571 die "Couldn't write to $config: $!\n";
1572 close $fh or die "Couldn't close $config: $!\n";
1573 }
1574 command('config', @args);
1575 };
1576 my $err = $@;
1577 if (defined $old_config) {
1578 $ENV{GIT_CONFIG} = $old_config;
1579 } else {
1580 delete $ENV{GIT_CONFIG};
1581 }
1582 die $err if $err;
1583 wantarray ? @ret : $ret[0];
1584 }
1585
1586 sub tmp_index_do {
1587 my ($self, $sub) = @_;
1588 my $old_index = $ENV{GIT_INDEX_FILE};
1589 $ENV{GIT_INDEX_FILE} = $self->{index};
1590 $@ = undef;
1591 my @ret = eval {
1592 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1593 mkpath([$dir]) unless -d $dir;
1594 &$sub;
1595 };
1596 my $err = $@;
1597 if (defined $old_index) {
1598 $ENV{GIT_INDEX_FILE} = $old_index;
1599 } else {
1600 delete $ENV{GIT_INDEX_FILE};
1601 }
1602 die $err if $err;
1603 wantarray ? @ret : $ret[0];
1604 }
1605
1606 sub assert_index_clean {
1607 my ($self, $treeish) = @_;
1608
1609 $self->tmp_index_do(sub {
1610 command_noisy('read-tree', $treeish) unless -e $self->{index};
1611 my $x = command_oneline('write-tree');
1612 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1613 /^tree ($::sha1)/mo);
1614 return if $y eq $x;
1615
1616 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1617 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1618 command_noisy('read-tree', $treeish);
1619 $x = command_oneline('write-tree');
1620 if ($y ne $x) {
1621 ::fatal "trees ($treeish) $y != $x\n",
1622 "Something is seriously wrong...\n";
1623 }
1624 });
1625 }
1626
1627 sub get_commit_parents {
1628 my ($self, $log_entry) = @_;
1629 my (%seen, @ret, @tmp);
1630 # legacy support for 'set-tree'; this is only used by set_tree_cb:
1631 if (my $ip = $self->{inject_parents}) {
1632 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1633 push @tmp, $commit;
1634 }
1635 }
1636 if (my $cur = ::verify_ref($self->refname.'^0')) {
1637 push @tmp, $cur;
1638 }
1639 if (my $ipd = $self->{inject_parents_dcommit}) {
1640 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
1641 push @tmp, @$commit;
1642 }
1643 }
1644 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1645 while (my $p = shift @tmp) {
1646 next if $seen{$p};
1647 $seen{$p} = 1;
1648 push @ret, $p;
1649 # MAXPARENT is defined to 16 in commit-tree.c:
1650 last if @ret >= 16;
1651 }
1652 if (@tmp) {
1653 die "r$log_entry->{revision}: No room for parents:\n\t",
1654 join("\n\t", @tmp), "\n";
1655 }
1656 @ret;
1657 }
1658
1659 sub rewrite_root {
1660 my ($self) = @_;
1661 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
1662 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
1663 my $rwr = eval { command_oneline(qw/config --get/, $k) };
1664 if ($rwr) {
1665 $rwr =~ s#/+$##;
1666 if ($rwr !~ m#^[a-z\+]+://#) {
1667 die "$rwr is not a valid URL (key: $k)\n";
1668 }
1669 }
1670 $self->{-rewrite_root} = $rwr;
1671 }
1672
1673 sub metadata_url {
1674 my ($self) = @_;
1675 ($self->rewrite_root || $self->{url}) .
1676 (length $self->{path} ? '/' . $self->{path} : '');
1677 }
1678
1679 sub full_url {
1680 my ($self) = @_;
1681 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1682 }
1683
1684 sub do_git_commit {
1685 my ($self, $log_entry) = @_;
1686 my $lr = $self->last_rev;
1687 if (defined $lr && $lr >= $log_entry->{revision}) {
1688 die "Last fetched revision of ", $self->refname,
1689 " was r$lr, but we are about to fetch: ",
1690 "r$log_entry->{revision}!\n";
1691 }
1692 if (my $c = $self->rev_db_get($log_entry->{revision})) {
1693 croak "$log_entry->{revision} = $c already exists! ",
1694 "Why are we refetching it?\n";
1695 }
1696 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $log_entry->{name};
1697 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} =
1698 $log_entry->{email};
1699 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1700
1701 my $tree = $log_entry->{tree};
1702 if (!defined $tree) {
1703 $tree = $self->tmp_index_do(sub {
1704 command_oneline('write-tree') });
1705 }
1706 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1707
1708 my @exec = ('git-commit-tree', $tree);
1709 foreach ($self->get_commit_parents($log_entry)) {
1710 push @exec, '-p', $_;
1711 }
1712 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1713 or croak $!;
1714 print $msg_fh $log_entry->{log} or croak $!;
1715 unless ($self->no_metadata) {
1716 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1717 or croak $!;
1718 }
1719 $msg_fh->flush == 0 or croak $!;
1720 close $msg_fh or croak $!;
1721 chomp(my $commit = do { local $/; <$out_fh> });
1722 close $out_fh or croak $!;
1723 waitpid $pid, 0;
1724 croak $? if $?;
1725 if ($commit !~ /^$::sha1$/o) {
1726 die "Failed to commit, invalid sha1: $commit\n";
1727 }
1728
1729 $self->rev_db_set($log_entry->{revision}, $commit, 1);
1730
1731 $self->{last_rev} = $log_entry->{revision};
1732 $self->{last_commit} = $commit;
1733 print "r$log_entry->{revision}";
1734 if (defined $log_entry->{svm_revision}) {
1735 print " (\@$log_entry->{svm_revision})";
1736 $self->rev_db_set($log_entry->{svm_revision}, $commit,
1737 0, $self->svm_uuid);
1738 }
1739 print " = $commit ($self->{ref_id})\n";
1740 if (defined $_repack && (--$_repack_nr == 0)) {
1741 $_repack_nr = $_repack;
1742 # repack doesn't use any arguments with spaces in them, does it?
1743 print "Running git repack $_repack_flags ...\n";
1744 command_noisy('repack', split(/\s+/, $_repack_flags));
1745 print "Done repacking\n";
1746 }
1747 return $commit;
1748 }
1749
1750 sub match_paths {
1751 my ($self, $paths, $r) = @_;
1752 return 1 if $self->{path} eq '';
1753 if (my $path = $paths->{"/$self->{path}"}) {
1754 return ($path->{action} eq 'D') ? 0 : 1;
1755 }
1756 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
1757 if (grep /$self->{path_regex}/, keys %$paths) {
1758 return 1;
1759 }
1760 my $c = '';
1761 foreach (split m#/#, $self->{path}) {
1762 $c .= "/$_";
1763 next unless ($paths->{$c} &&
1764 ($paths->{$c}->{action} =~ /^[AR]$/));
1765 if ($self->ra->check_path($self->{path}, $r) ==
1766 $SVN::Node::dir) {
1767 return 1;
1768 }
1769 }
1770 return 0;
1771 }
1772
1773 sub find_parent_branch {
1774 my ($self, $paths, $rev) = @_;
1775 return undef unless $self->follow_parent;
1776 unless (defined $paths) {
1777 my $err_handler = $SVN::Error::handler;
1778 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1779 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1780 $paths =
1781 Git::SVN::Ra::dup_changed_paths($_[0]) });
1782 $SVN::Error::handler = $err_handler;
1783 }
1784 return undef unless defined $paths;
1785
1786 # look for a parent from another branch:
1787 my @b_path_components = split m#/#, $self->rel_path;
1788 my @a_path_components;
1789 my $i;
1790 while (@b_path_components) {
1791 $i = $paths->{'/'.join('/', @b_path_components)};
1792 last if $i && defined $i->{copyfrom_path};
1793 unshift(@a_path_components, pop(@b_path_components));
1794 }
1795 return undef unless defined $i && defined $i->{copyfrom_path};
1796 my $branch_from = $i->{copyfrom_path};
1797 if (@a_path_components) {
1798 print STDERR "branch_from: $branch_from => ";
1799 $branch_from .= '/'.join('/', @a_path_components);
1800 print STDERR $branch_from, "\n";
1801 }
1802 my $r = $i->{copyfrom_rev};
1803 my $repos_root = $self->ra->{repos_root};
1804 my $url = $self->ra->{url};
1805 my $new_url = $repos_root . $branch_from;
1806 print STDERR "Found possible branch point: ",
1807 "$new_url => ", $self->full_url, ", $r\n";
1808 $branch_from =~ s#^/##;
1809 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
1810 unless ($gs) {
1811 my $ref_id = $self->{ref_id};
1812 $ref_id =~ s/\@\d+$//;
1813 $ref_id .= "\@$r";
1814 # just grow a tail if we're not unique enough :x
1815 $ref_id .= '-' while find_ref($ref_id);
1816 print STDERR "Initializing parent: $ref_id\n";
1817 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1818 }
1819 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1820 if (!defined $r0 || !defined $parent) {
1821 my ($base, $head) = parse_revision_argument(0, $r);
1822 if ($base <= $r) {
1823 $gs->fetch($base, $r);
1824 }
1825 ($r0, $parent) = $gs->last_rev_commit;
1826 }
1827 if (defined $r0 && defined $parent) {
1828 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1829 my $ed;
1830 if ($self->ra->can_do_switch) {
1831 $self->assert_index_clean($parent);
1832 print STDERR "Following parent with do_switch\n";
1833 # do_switch works with svn/trunk >= r22312, but that
1834 # is not included with SVN 1.4.3 (the latest version
1835 # at the moment), so we can't rely on it
1836 $self->{last_commit} = $parent;
1837 $ed = SVN::Git::Fetcher->new($self);
1838 $gs->ra->gs_do_switch($r0, $rev, $gs,
1839 $self->full_url, $ed)
1840 or die "SVN connection failed somewhere...\n";
1841 } else {
1842 print STDERR "Following parent with do_update\n";
1843 $ed = SVN::Git::Fetcher->new($self);
1844 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1845 or die "SVN connection failed somewhere...\n";
1846 }
1847 print STDERR "Successfully followed parent\n";
1848 return $self->make_log_entry($rev, [$parent], $ed);
1849 }
1850 return undef;
1851 }
1852
1853 sub do_fetch {
1854 my ($self, $paths, $rev) = @_;
1855 my $ed;
1856 my ($last_rev, @parents);
1857 if (my $lc = $self->last_commit) {
1858 # we can have a branch that was deleted, then re-added
1859 # under the same name but copied from another path, in
1860 # which case we'll have multiple parents (we don't
1861 # want to break the original ref, nor lose copypath info):
1862 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1863 push @{$log_entry->{parents}}, $lc;
1864 return $log_entry;
1865 }
1866 $ed = SVN::Git::Fetcher->new($self);
1867 $last_rev = $self->{last_rev};
1868 $ed->{c} = $lc;
1869 @parents = ($lc);
1870 } else {
1871 $last_rev = $rev;
1872 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1873 return $log_entry;
1874 }
1875 $ed = SVN::Git::Fetcher->new($self);
1876 }
1877 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1878 die "SVN connection failed somewhere...\n";
1879 }
1880 $self->make_log_entry($rev, \@parents, $ed);
1881 }
1882
1883 sub get_untracked {
1884 my ($self, $ed) = @_;
1885 my @out;
1886 my $h = $ed->{empty};
1887 foreach (sort keys %$h) {
1888 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1889 push @out, " $act: " . uri_encode($_);
1890 warn "W: $act: $_\n";
1891 }
1892 foreach my $t (qw/dir_prop file_prop/) {
1893 $h = $ed->{$t} or next;
1894 foreach my $path (sort keys %$h) {
1895 my $ppath = $path eq '' ? '.' : $path;
1896 foreach my $prop (sort keys %{$h->{$path}}) {
1897 next if $SKIP_PROP{$prop};
1898 my $v = $h->{$path}->{$prop};
1899 my $t_ppath_prop = "$t: " .
1900 uri_encode($ppath) . ' ' .
1901 uri_encode($prop);
1902 if (defined $v) {
1903 push @out, " +$t_ppath_prop " .
1904 uri_encode($v);
1905 } else {
1906 push @out, " -$t_ppath_prop";
1907 }
1908 }
1909 }
1910 }
1911 foreach my $t (qw/absent_file absent_directory/) {
1912 $h = $ed->{$t} or next;
1913 foreach my $parent (sort keys %$h) {
1914 foreach my $path (sort @{$h->{$parent}}) {
1915 push @out, " $t: " .
1916 uri_encode("$parent/$path");
1917 warn "W: $t: $parent/$path ",
1918 "Insufficient permissions?\n";
1919 }
1920 }
1921 }
1922 \@out;
1923 }
1924
1925 sub parse_svn_date {
1926 my $date = shift || return '+0000 1970-01-01 00:00:00';
1927 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1928 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1929 croak "Unable to parse date: $date\n";
1930 "+0000 $Y-$m-$d $H:$M:$S";
1931 }
1932
1933 sub check_author {
1934 my ($author) = @_;
1935 if (!defined $author || length $author == 0) {
1936 $author = '(no author)';
1937 }
1938 if (defined $::_authors && ! defined $::users{$author}) {
1939 die "Author: $author not defined in $::_authors file\n";
1940 }
1941 $author;
1942 }
1943
1944 sub make_log_entry {
1945 my ($self, $rev, $parents, $ed) = @_;
1946 my $untracked = $self->get_untracked($ed);
1947
1948 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1949 print $un "r$rev\n" or croak $!;
1950 print $un $_, "\n" foreach @$untracked;
1951 my %log_entry = ( parents => $parents || [], revision => $rev,
1952 log => '');
1953
1954 my $headrev;
1955 my $logged = delete $self->{logged_rev_props};
1956 if (!$logged || $self->{-want_revprops}) {
1957 my $rp = $self->ra->rev_proplist($rev);
1958 foreach (sort keys %$rp) {
1959 my $v = $rp->{$_};
1960 if (/^svn:(author|date|log)$/) {
1961 $log_entry{$1} = $v;
1962 } elsif ($_ eq 'svm:headrev') {
1963 $headrev = $v;
1964 } else {
1965 print $un " rev_prop: ", uri_encode($_), ' ',
1966 uri_encode($v), "\n";
1967 }
1968 }
1969 } else {
1970 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1971 }
1972 close $un or croak $!;
1973
1974 $log_entry{date} = parse_svn_date($log_entry{date});
1975 $log_entry{log} .= "\n";
1976 my $author = $log_entry{author} = check_author($log_entry{author});
1977 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1978 : ($author, undef);
1979 if (defined $headrev && $self->use_svm_props) {
1980 if ($self->rewrite_root) {
1981 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1982 "options set!\n";
1983 }
1984 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
1985 # we don't want "SVM: initializing mirror for junk" ...
1986 return undef if $r == 0;
1987 my $svm = $self->svm;
1988 if ($uuid ne $svm->{uuid}) {
1989 die "UUID mismatch on SVM path:\n",
1990 "expected: $svm->{uuid}\n",
1991 " got: $uuid\n";
1992 }
1993 my $full_url = $self->full_url;
1994 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1995 die "Failed to replace '$svm->{replace}' with ",
1996 "'$svm->{source}' in $full_url\n";
1997 # throw away username for storing in records
1998 remove_username($full_url);
1999 $log_entry{metadata} = "$full_url\@$r $uuid";
2000 $log_entry{svm_revision} = $r;
2001 $email ||= "$author\@$uuid"
2002 } elsif ($self->use_svnsync_props) {
2003 my $full_url = $self->svnsync->{url};
2004 $full_url .= "/$self->{path}" if length $self->{path};
2005 remove_username($full_url);
2006 my $uuid = $self->svnsync->{uuid};
2007 $log_entry{metadata} = "$full_url\@$rev $uuid";
2008 $email ||= "$author\@$uuid"
2009 } else {
2010 my $url = $self->metadata_url;
2011 remove_username($url);
2012 $log_entry{metadata} = "$url\@$rev " .
2013 $self->ra->get_uuid;
2014 $email ||= "$author\@" . $self->ra->get_uuid;
2015 }
2016 $log_entry{name} = $name;
2017 $log_entry{email} = $email;
2018 \%log_entry;
2019 }
2020
2021 sub fetch {
2022 my ($self, $min_rev, $max_rev, @parents) = @_;
2023 my ($last_rev, $last_commit) = $self->last_rev_commit;
2024 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2025 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2026 }
2027
2028 sub set_tree_cb {
2029 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2030 $self->{inject_parents} = { $rev => $tree };
2031 $self->fetch(undef, undef);
2032 }
2033
2034 sub set_tree {
2035 my ($self, $tree) = (shift, shift);
2036 my $log_entry = ::get_commit_entry($tree);
2037 unless ($self->{last_rev}) {
2038 fatal("Must have an existing revision to commit\n");
2039 }
2040 my %ed_opts = ( r => $self->{last_rev},
2041 log => $log_entry->{log},
2042 ra => $self->ra,
2043 tree_a => $self->{last_commit},
2044 tree_b => $tree,
2045 editor_cb => sub {
2046 $self->set_tree_cb($log_entry, $tree, @_) },
2047 svn_path => $self->{path} );
2048 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2049 print "No changes\nr$self->{last_rev} = $tree\n";
2050 }
2051 }
2052
2053 sub rebuild {
2054 my ($self) = @_;
2055 my $db_path = $self->db_path;
2056 return if (-e $db_path && ! -z $db_path);
2057 return unless ::verify_ref($self->refname.'^0');
2058 if (-f $self->{db_root}) {
2059 rename $self->{db_root}, $db_path or die
2060 "rename $self->{db_root} => $db_path failed: $!\n";
2061 my ($dir, $base) = ($db_path =~ m#^(.*?)/?([^/]+)$#);
2062 symlink $base, $self->{db_root} or die
2063 "symlink $base => $self->{db_root} failed: $!\n";
2064 return;
2065 }
2066 print "Rebuilding $db_path ...\n";
2067 my ($log, $ctx) = command_output_pipe("log", $self->refname);
2068 my $latest;
2069 my $full_url = $self->full_url;
2070 remove_username($full_url);
2071 my $svn_uuid;
2072 my $c;
2073 while (<$log>) {
2074 if ( m{^commit ($::sha1)$} ) {
2075 $c = $1;
2076 next;
2077 }
2078 next unless s{^\s*(git-svn-id:)}{$1};
2079 my ($url, $rev, $uuid) = ::extract_metadata($_);
2080 remove_username($url);
2081
2082 # ignore merges (from set-tree)
2083 next if (!defined $rev || !$uuid);
2084
2085 # if we merged or otherwise started elsewhere, this is
2086 # how we break out of it
2087 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
2088 ($full_url && $url && ($url ne $full_url))) {
2089 next;
2090 }
2091 $latest ||= $rev;
2092 $svn_uuid ||= $uuid;
2093
2094 $self->rev_db_set($rev, $c);
2095 print "r$rev = $c\n";
2096 }
2097 command_close_pipe($log, $ctx);
2098 print "Done rebuilding $db_path\n";
2099 }
2100
2101 # rev_db:
2102 # Tie::File seems to be prone to offset errors if revisions get sparse,
2103 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2104 # one of my favorite modules is out :< Next up would be one of the DBM
2105 # modules, but I'm not sure which is most portable... So I'll just
2106 # go with something that's plain-text, but still capable of
2107 # being randomly accessed. So here's my ultra-simple fixed-width
2108 # database. All records are 40 characters + "\n", so it's easy to seek
2109 # to a revision: (41 * rev) is the byte offset.
2110 # A record of 40 0s denotes an empty revision.
2111 # And yes, it's still pretty fast (faster than Tie::File).
2112 # These files are disposable unless noMetadata or useSvmProps is set
2113
2114 sub _rev_db_set {
2115 my ($fh, $rev, $commit) = @_;
2116 my $offset = $rev * 41;
2117 # assume that append is the common case:
2118 seek $fh, 0, 2 or croak $!;
2119 my $pos = tell $fh;
2120 if ($pos < $offset) {
2121 for (1 .. (($offset - $pos) / 41)) {
2122 print $fh (('0' x 40),"\n") or croak $!;
2123 }
2124 }
2125 seek $fh, $offset, 0 or croak $!;
2126 print $fh $commit,"\n" or croak $!;
2127 }
2128
2129 sub mkfile {
2130 my ($path) = @_;
2131 unless (-e $path) {
2132 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2133 mkpath([$dir]) unless -d $dir;
2134 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2135 close $fh or die "Couldn't close (create) $path: $!\n";
2136 }
2137 }
2138
2139 sub rev_db_set {
2140 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2141 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2142 my $db = $self->db_path($uuid);
2143 my $db_lock = "$db.lock";
2144 my $sig;
2145 if ($update_ref) {
2146 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2147 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2148 }
2149 mkfile($db);
2150
2151 $LOCKFILES{$db_lock} = 1;
2152 my $sync;
2153 # both of these options make our .rev_db file very, very important
2154 # and we can't afford to lose it because rebuild() won't work
2155 if ($self->use_svm_props || $self->no_metadata) {
2156 $sync = 1;
2157 copy($db, $db_lock) or die "rev_db_set(@_): ",
2158 "Failed to copy: ",
2159 "$db => $db_lock ($!)\n";
2160 } else {
2161 rename $db, $db_lock or die "rev_db_set(@_): ",
2162 "Failed to rename: ",
2163 "$db => $db_lock ($!)\n";
2164 }
2165 open my $fh, '+<', $db_lock or die "Couldn't open $db_lock: $!\n";
2166 _rev_db_set($fh, $rev, $commit);
2167 if ($sync) {
2168 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2169 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2170 }
2171 close $fh or croak $!;
2172 if ($update_ref) {
2173 $_head = $self;
2174 command_noisy('update-ref', '-m', "r$rev",
2175 $self->refname, $commit);
2176 }
2177 rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
2178 "$db_lock => $db ($!)\n";
2179 delete $LOCKFILES{$db_lock};
2180 if ($update_ref) {
2181 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2182 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2183 kill $sig, $$ if defined $sig;
2184 }
2185 }
2186
2187 sub rev_db_max {
2188 my ($self) = @_;
2189 $self->rebuild;
2190 my $db_path = $self->db_path;
2191 my @stat = stat $db_path or return 0;
2192 ($stat[7] % 41) == 0 or die "$db_path inconsistent size: $stat[7]\n";
2193 my $max = $stat[7] / 41;
2194 (($max > 0) ? $max - 1 : 0);
2195 }
2196
2197 sub rev_db_get {
2198 my ($self, $rev, $uuid) = @_;
2199 my $ret;
2200 my $offset = $rev * 41;
2201 my $db_path = $self->db_path($uuid);
2202 return undef unless -e $db_path;
2203 open my $fh, '<', $db_path or croak $!;
2204 if (sysseek($fh, $offset, 0) == $offset) {
2205 my $read = sysread($fh, $ret, 40);
2206 $ret = undef if ($read != 40 || $ret eq ('0'x40));
2207 }
2208 close $fh or croak $!;
2209 $ret;
2210 }
2211
2212 sub find_rev_before {
2213 my ($self, $rev, $eq_ok) = @_;
2214 --$rev unless $eq_ok;
2215 while ($rev > 0) {
2216 if (my $c = $self->rev_db_get($rev)) {
2217 return ($rev, $c);
2218 }
2219 --$rev;
2220 }
2221 return (undef, undef);
2222 }
2223
2224 sub _new {
2225 my ($class, $repo_id, $ref_id, $path) = @_;
2226 unless (defined $repo_id && length $repo_id) {
2227 $repo_id = $Git::SVN::default_repo_id;
2228 }
2229 unless (defined $ref_id && length $ref_id) {
2230 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2231 }
2232 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2233 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2234 $_[3] = $path = '' unless (defined $path);
2235 mkpath(["$ENV{GIT_DIR}/svn"]);
2236 bless {
2237 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2238 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2239 db_root => "$dir/.rev_db", repo_id => $repo_id }, $class;
2240 }
2241
2242 sub db_path {
2243 my ($self, $uuid) = @_;
2244 $uuid ||= $self->ra_uuid;
2245 "$self->{db_root}.$uuid";
2246 }
2247
2248 sub uri_encode {
2249 my ($f) = @_;
2250 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2251 $f
2252 }
2253
2254 sub remove_username {
2255 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2256 }
2257
2258 package Git::SVN::Prompt;
2259 use strict;
2260 use warnings;
2261 require SVN::Core;
2262 use vars qw/$_no_auth_cache $_username/;
2263
2264 sub simple {
2265 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2266 $may_save = undef if $_no_auth_cache;
2267 $default_username = $_username if defined $_username;
2268 if (defined $default_username && length $default_username) {
2269 if (defined $realm && length $realm) {
2270 print STDERR "Authentication realm: $realm\n";
2271 STDERR->flush;
2272 }
2273 $cred->username($default_username);
2274 } else {
2275 username($cred, $realm, $may_save, $pool);
2276 }
2277 $cred->password(_read_password("Password for '" .
2278 $cred->username . "': ", $realm));
2279 $cred->may_save($may_save);
2280 $SVN::_Core::SVN_NO_ERROR;
2281 }
2282
2283 sub ssl_server_trust {
2284 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2285 $may_save = undef if $_no_auth_cache;
2286 print STDERR "Error validating server certificate for '$realm':\n";
2287 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2288 print STDERR " - The certificate is not issued by a trusted ",
2289 "authority. Use the\n",
2290 " fingerprint to validate the certificate manually!\n";
2291 }
2292 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2293 print STDERR " - The certificate hostname does not match.\n";
2294 }
2295 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2296 print STDERR " - The certificate is not yet valid.\n";
2297 }
2298 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2299 print STDERR " - The certificate has expired.\n";
2300 }
2301 if ($failures & $SVN::Auth::SSL::OTHER) {
2302 print STDERR " - The certificate has an unknown error.\n";
2303 }
2304 printf STDERR
2305 "Certificate information:\n".
2306 " - Hostname: %s\n".
2307 " - Valid: from %s until %s\n".
2308 " - Issuer: %s\n".
2309 " - Fingerprint: %s\n",
2310 map $cert_info->$_, qw(hostname valid_from valid_until
2311 issuer_dname fingerprint);
2312 my $choice;
2313 prompt:
2314 print STDERR $may_save ?
2315 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2316 "(R)eject or accept (t)emporarily? ";
2317 STDERR->flush;
2318 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2319 if ($choice =~ /^t$/i) {
2320 $cred->may_save(undef);
2321 } elsif ($choice =~ /^r$/i) {
2322 return -1;
2323 } elsif ($may_save && $choice =~ /^p$/i) {
2324 $cred->may_save($may_save);
2325 } else {
2326 goto prompt;
2327 }
2328 $cred->accepted_failures($failures);
2329 $SVN::_Core::SVN_NO_ERROR;
2330 }
2331
2332 sub ssl_client_cert {
2333 my ($cred, $realm, $may_save, $pool) = @_;
2334 $may_save = undef if $_no_auth_cache;
2335 print STDERR "Client certificate filename: ";
2336 STDERR->flush;
2337 chomp(my $filename = <STDIN>);
2338 $cred->cert_file($filename);
2339 $cred->may_save($may_save);
2340 $SVN::_Core::SVN_NO_ERROR;
2341 }
2342
2343 sub ssl_client_cert_pw {
2344 my ($cred, $realm, $may_save, $pool) = @_;
2345 $may_save = undef if $_no_auth_cache;
2346 $cred->password(_read_password("Password: ", $realm));
2347 $cred->may_save($may_save);
2348 $SVN::_Core::SVN_NO_ERROR;
2349 }
2350
2351 sub username {
2352 my ($cred, $realm, $may_save, $pool) = @_;
2353 $may_save = undef if $_no_auth_cache;
2354 if (defined $realm && length $realm) {
2355 print STDERR "Authentication realm: $realm\n";
2356 }
2357 my $username;
2358 if (defined $_username) {
2359 $username = $_username;
2360 } else {
2361 print STDERR "Username: ";
2362 STDERR->flush;
2363 chomp($username = <STDIN>);
2364 }
2365 $cred->username($username);
2366 $cred->may_save($may_save);
2367 $SVN::_Core::SVN_NO_ERROR;
2368 }
2369
2370 sub _read_password {
2371 my ($prompt, $realm) = @_;
2372 print STDERR $prompt;
2373 STDERR->flush;
2374 require Term::ReadKey;
2375 Term::ReadKey::ReadMode('noecho');
2376 my $password = '';
2377 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2378 last if $key =~ /[\012\015]/; # \n\r
2379 $password .= $key;
2380 }
2381 Term::ReadKey::ReadMode('restore');
2382 print STDERR "\n";
2383 STDERR->flush;
2384 $password;
2385 }
2386
2387 package main;
2388
2389 {
2390 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2391 $SVN::Node::dir.$SVN::Node::unknown.
2392 $SVN::Node::none.$SVN::Node::file.
2393 $SVN::Node::dir.$SVN::Node::unknown.
2394 $SVN::Auth::SSL::CNMISMATCH.
2395 $SVN::Auth::SSL::NOTYETVALID.
2396 $SVN::Auth::SSL::EXPIRED.
2397 $SVN::Auth::SSL::UNKNOWNCA.
2398 $SVN::Auth::SSL::OTHER;
2399 }
2400
2401 package SVN::Git::Fetcher;
2402 use vars qw/@ISA/;
2403 use strict;
2404 use warnings;
2405 use Carp qw/croak/;
2406 use IO::File qw//;
2407 use Digest::MD5;
2408
2409 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2410 sub new {
2411 my ($class, $git_svn) = @_;
2412 my $self = SVN::Delta::Editor->new;
2413 bless $self, $class;
2414 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2415 $self->{empty} = {};
2416 $self->{dir_prop} = {};
2417 $self->{file_prop} = {};
2418 $self->{absent_dir} = {};
2419 $self->{absent_file} = {};
2420 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2421 $self;
2422 }
2423
2424 sub set_path_strip {
2425 my ($self, $path) = @_;
2426 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2427 }
2428
2429 sub open_root {
2430 { path => '' };
2431 }
2432
2433 sub open_directory {
2434 my ($self, $path, $pb, $rev) = @_;
2435 { path => $path };
2436 }
2437
2438 sub git_path {
2439 my ($self, $path) = @_;
2440 if ($self->{path_strip}) {
2441 $path =~ s!$self->{path_strip}!! or
2442 die "Failed to strip path '$path' ($self->{path_strip})\n";
2443 }
2444 $path;
2445 }
2446
2447 sub delete_entry {
2448 my ($self, $path, $rev, $pb) = @_;
2449
2450 my $gpath = $self->git_path($path);
2451 return undef if ($gpath eq '');
2452
2453 # remove entire directories.
2454 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2455 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2456 -r --name-only -z/,
2457 $self->{c}, '--', $gpath);
2458 local $/ = "\0";
2459 while (<$ls>) {
2460 chomp;
2461 $self->{gii}->remove($_);
2462 print "\tD\t$_\n" unless $::_q;
2463 }
2464 print "\tD\t$gpath/\n" unless $::_q;
2465 command_close_pipe($ls, $ctx);
2466 $self->{empty}->{$path} = 0
2467 } else {
2468 $self->{gii}->remove($gpath);
2469 print "\tD\t$gpath\n" unless $::_q;
2470 }
2471 undef;
2472 }
2473
2474 sub open_file {
2475 my ($self, $path, $pb, $rev) = @_;
2476 my $gpath = $self->git_path($path);
2477 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
2478 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2479 unless (defined $mode && defined $blob) {
2480 die "$path was not found in commit $self->{c} (r$rev)\n";
2481 }
2482 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2483 pool => SVN::Pool->new, action => 'M' };
2484 }
2485
2486 sub add_file {
2487 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2488 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2489 delete $self->{empty}->{$dir};
2490 { path => $path, mode_a => 100644, mode_b => 100644,
2491 pool => SVN::Pool->new, action => 'A' };
2492 }
2493
2494 sub add_directory {
2495 my ($self, $path, $cp_path, $cp_rev) = @_;
2496 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2497 delete $self->{empty}->{$dir};
2498 $self->{empty}->{$path} = 1;
2499 { path => $path };
2500 }
2501
2502 sub change_dir_prop {
2503 my ($self, $db, $prop, $value) = @_;
2504 $self->{dir_prop}->{$db->{path}} ||= {};
2505 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2506 undef;
2507 }
2508
2509 sub absent_directory {
2510 my ($self, $path, $pb) = @_;
2511 $self->{absent_dir}->{$pb->{path}} ||= [];
2512 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2513 undef;
2514 }
2515
2516 sub absent_file {
2517 my ($self, $path, $pb) = @_;
2518 $self->{absent_file}->{$pb->{path}} ||= [];
2519 push @{$self->{absent_file}->{$pb->{path}}}, $path;
2520 undef;
2521 }
2522
2523 sub change_file_prop {
2524 my ($self, $fb, $prop, $value) = @_;
2525 if ($prop eq 'svn:executable') {
2526 if ($fb->{mode_b} != 120000) {
2527 $fb->{mode_b} = defined $value ? 100755 : 100644;
2528 }
2529 } elsif ($prop eq 'svn:special') {
2530 $fb->{mode_b} = defined $value ? 120000 : 100644;
2531 } else {
2532 $self->{file_prop}->{$fb->{path}} ||= {};
2533 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2534 }
2535 undef;
2536 }
2537
2538 sub apply_textdelta {
2539 my ($self, $fb, $exp) = @_;
2540 my $fh = IO::File->new_tmpfile;
2541 $fh->autoflush(1);
2542 # $fh gets auto-closed() by SVN::TxDelta::apply(),
2543 # (but $base does not,) so dup() it for reading in close_file
2544 open my $dup, '<&', $fh or croak $!;
2545 my $base = IO::File->new_tmpfile;
2546 $base->autoflush(1);
2547 if ($fb->{blob}) {
2548 defined (my $pid = fork) or croak $!;
2549 if (!$pid) {
2550 open STDOUT, '>&', $base or croak $!;
2551 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2552 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2553 }
2554 waitpid $pid, 0;
2555 croak $? if $?;
2556
2557 if (defined $exp) {
2558 seek $base, 0, 0 or croak $!;
2559 my $md5 = Digest::MD5->new;
2560 $md5->addfile($base);
2561 my $got = $md5->hexdigest;
2562 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2563 "expected: $exp\n",
2564 " got: $got\n" if ($got ne $exp);
2565 }
2566 }
2567 seek $base, 0, 0 or croak $!;
2568 $fb->{fh} = $dup;
2569 $fb->{base} = $base;
2570 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2571 }
2572
2573 sub close_file {
2574 my ($self, $fb, $exp) = @_;
2575 my $hash;
2576 my $path = $self->git_path($fb->{path});
2577 if (my $fh = $fb->{fh}) {
2578 if (defined $exp) {
2579 seek($fh, 0, 0) or croak $!;
2580 my $md5 = Digest::MD5->new;
2581 $md5->addfile($fh);
2582 my $got = $md5->hexdigest;
2583 if ($got ne $exp) {
2584 die "Checksum mismatch: $path\n",
2585 "expected: $exp\n got: $got\n";
2586 }
2587 }
2588 sysseek($fh, 0, 0) or croak $!;
2589 if ($fb->{mode_b} == 120000) {
2590 sysread($fh, my $buf, 5) == 5 or croak $!;
2591 $buf eq 'link ' or die "$path has mode 120000",
2592 "but is not a link\n";
2593 }
2594 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2595 if (!$pid) {
2596 open STDIN, '<&', $fh or croak $!;
2597 exec qw/git-hash-object -w --stdin/ or croak $!;
2598 }
2599 chomp($hash = do { local $/; <$out> });
2600 close $out or croak $!;
2601 close $fh or croak $!;
2602 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2603 close $fb->{base} or croak $!;
2604 } else {
2605 $hash = $fb->{blob} or die "no blob information\n";
2606 }
2607 $fb->{pool}->clear;
2608 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
2609 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
2610 undef;
2611 }
2612
2613 sub abort_edit {
2614 my $self = shift;
2615 $self->{nr} = $self->{gii}->{nr};
2616 delete $self->{gii};
2617 $self->SUPER::abort_edit(@_);
2618 }
2619
2620 sub close_edit {
2621 my $self = shift;
2622 $self->{git_commit_ok} = 1;
2623 $self->{nr} = $self->{gii}->{nr};
2624 delete $self->{gii};
2625 $self->SUPER::close_edit(@_);
2626 }
2627
2628 package SVN::Git::Editor;
2629 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
2630 use strict;
2631 use warnings;
2632 use Carp qw/croak/;
2633 use IO::File;
2634 use Digest::MD5;
2635
2636 sub new {
2637 my ($class, $opts) = @_;
2638 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
2639 die "$_ required!\n" unless (defined $opts->{$_});
2640 }
2641
2642 my $pool = SVN::Pool->new;
2643 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
2644 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
2645 $opts->{r}, $mods);
2646
2647 # $opts->{ra} functions should not be used after this:
2648 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
2649 $opts->{editor_cb}, $pool);
2650 my $self = SVN::Delta::Editor->new(@ce, $pool);
2651 bless $self, $class;
2652 foreach (qw/svn_path r tree_a tree_b/) {
2653 $self->{$_} = $opts->{$_};
2654 }
2655 $self->{url} = $opts->{ra}->{url};
2656 $self->{mods} = $mods;
2657 $self->{types} = $types;
2658 $self->{pool} = $pool;
2659 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2660 $self->{rm} = { };
2661 $self->{path_prefix} = length $self->{svn_path} ?
2662 "$self->{svn_path}/" : '';
2663 return $self;
2664 }
2665
2666 sub generate_diff {
2667 my ($tree_a, $tree_b) = @_;
2668 my @diff_tree = qw(diff-tree -z -r);
2669 if ($_cp_similarity) {
2670 push @diff_tree, "-C$_cp_similarity";
2671 } else {
2672 push @diff_tree, '-C';
2673 }
2674 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
2675 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
2676 push @diff_tree, $tree_a, $tree_b;
2677 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2678 local $/ = "\0";
2679 my $state = 'meta';
2680 my @mods;
2681 while (<$diff_fh>) {
2682 chomp $_; # this gets rid of the trailing "\0"
2683 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2684 $::sha1\s($::sha1)\s
2685 ([MTCRAD])\d*$/xo) {
2686 push @mods, { mode_a => $1, mode_b => $2,
2687 sha1_b => $3, chg => $4 };
2688 if ($4 =~ /^(?:C|R)$/) {
2689 $state = 'file_a';
2690 } else {
2691 $state = 'file_b';
2692 }
2693 } elsif ($state eq 'file_a') {
2694 my $x = $mods[$#mods] or croak "Empty array\n";
2695 if ($x->{chg} !~ /^(?:C|R)$/) {
2696 croak "Error parsing $_, $x->{chg}\n";
2697 }
2698 $x->{file_a} = $_;
2699 $state = 'file_b';
2700 } elsif ($state eq 'file_b') {
2701 my $x = $mods[$#mods] or croak "Empty array\n";
2702 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2703 croak "Error parsing $_, $x->{chg}\n";
2704 }
2705 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2706 croak "Error parsing $_, $x->{chg}\n";
2707 }
2708 $x->{file_b} = $_;
2709 $state = 'meta';
2710 } else {
2711 croak "Error parsing $_\n";
2712 }
2713 }
2714 command_close_pipe($diff_fh, $ctx);
2715 \@mods;
2716 }
2717
2718 sub check_diff_paths {
2719 my ($ra, $pfx, $rev, $mods) = @_;
2720 my %types;
2721 $pfx .= '/' if length $pfx;
2722
2723 sub type_diff_paths {
2724 my ($ra, $types, $path, $rev) = @_;
2725 my @p = split m#/+#, $path;
2726 my $c = shift @p;
2727 unless (defined $types->{$c}) {
2728 $types->{$c} = $ra->check_path($c, $rev);
2729 }
2730 while (@p) {
2731 $c .= '/' . shift @p;
2732 next if defined $types->{$c};
2733 $types->{$c} = $ra->check_path($c, $rev);
2734 }
2735 }
2736
2737 foreach my $m (@$mods) {
2738 foreach my $f (qw/file_a file_b/) {
2739 next unless defined $m->{$f};
2740 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
2741 if (length $pfx.$dir && ! defined $types{$dir}) {
2742 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
2743 }
2744 }
2745 }
2746 \%types;
2747 }
2748
2749 sub split_path {
2750 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2751 }
2752
2753 sub repo_path {
2754 my ($self, $path) = @_;
2755 $self->{path_prefix}.(defined $path ? $path : '');
2756 }
2757
2758 sub url_path {
2759 my ($self, $path) = @_;
2760 if ($self->{url} =~ m#^https?://#) {
2761 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
2762 }
2763 $self->{url} . '/' . $self->repo_path($path);
2764 }
2765
2766 sub rmdirs {
2767 my ($self) = @_;
2768 my $rm = $self->{rm};
2769 delete $rm->{''}; # we never delete the url we're tracking
2770 return unless %$rm;
2771
2772 foreach (keys %$rm) {
2773 my @d = split m#/#, $_;
2774 my $c = shift @d;
2775 $rm->{$c} = 1;
2776 while (@d) {
2777 $c .= '/' . shift @d;
2778 $rm->{$c} = 1;
2779 }
2780 }
2781 delete $rm->{$self->{svn_path}};
2782 delete $rm->{''}; # we never delete the url we're tracking
2783 return unless %$rm;
2784
2785 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2786 $self->{tree_b});
2787 local $/ = "\0";
2788 while (<$fh>) {
2789 chomp;
2790 my @dn = split m#/#, $_;
2791 while (pop @dn) {
2792 delete $rm->{join '/', @dn};
2793 }
2794 unless (%$rm) {
2795 close $fh;
2796 return;
2797 }
2798 }
2799 command_close_pipe($fh, $ctx);
2800
2801 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2802 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2803 $self->close_directory($bat->{$d}, $p);
2804 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2805 print "\tD+\t$d/\n" unless $::_q;
2806 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2807 delete $bat->{$d};
2808 }
2809 }
2810
2811 sub open_or_add_dir {
2812 my ($self, $full_path, $baton) = @_;
2813 my $t = $self->{types}->{$full_path};
2814 if (!defined $t) {
2815 die "$full_path not known in r$self->{r} or we have a bug!\n";
2816 }
2817 if ($t == $SVN::Node::none) {
2818 return $self->add_directory($full_path, $baton,
2819 undef, -1, $self->{pool});
2820 } elsif ($t == $SVN::Node::dir) {
2821 return $self->open_directory($full_path, $baton,
2822 $self->{r}, $self->{pool});
2823 }
2824 print STDERR "$full_path already exists in repository at ",
2825 "r$self->{r} and it is not a directory (",
2826 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2827 exit 1;
2828 }
2829
2830 sub ensure_path {
2831 my ($self, $path) = @_;
2832 my $bat = $self->{bat};
2833 my $repo_path = $self->repo_path($path);
2834 return $bat->{''} unless (length $repo_path);
2835 my @p = split m#/+#, $repo_path;
2836 my $c = shift @p;
2837 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2838 while (@p) {
2839 my $c0 = $c;
2840 $c .= '/' . shift @p;
2841 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2842 }
2843 return $bat->{$c};
2844 }
2845
2846 sub A {
2847 my ($self, $m) = @_;
2848 my ($dir, $file) = split_path($m->{file_b});
2849 my $pbat = $self->ensure_path($dir);
2850 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2851 undef, -1);
2852 print "\tA\t$m->{file_b}\n" unless $::_q;
2853 $self->chg_file($fbat, $m);
2854 $self->close_file($fbat,undef,$self->{pool});
2855 }
2856
2857 sub C {
2858 my ($self, $m) = @_;
2859 my ($dir, $file) = split_path($m->{file_b});
2860 my $pbat = $self->ensure_path($dir);
2861 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2862 $self->url_path($m->{file_a}), $self->{r});
2863 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2864 $self->chg_file($fbat, $m);
2865 $self->close_file($fbat,undef,$self->{pool});
2866 }
2867
2868 sub delete_entry {
2869 my ($self, $path, $pbat) = @_;
2870 my $rpath = $self->repo_path($path);
2871 my ($dir, $file) = split_path($rpath);
2872 $self->{rm}->{$dir} = 1;
2873 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2874 }
2875
2876 sub R {
2877 my ($self, $m) = @_;
2878 my ($dir, $file) = split_path($m->{file_b});
2879 my $pbat = $self->ensure_path($dir);
2880 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2881 $self->url_path($m->{file_a}), $self->{r});
2882 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2883 $self->chg_file($fbat, $m);
2884 $self->close_file($fbat,undef,$self->{pool});
2885
2886 ($dir, $file) = split_path($m->{file_a});
2887 $pbat = $self->ensure_path($dir);
2888 $self->delete_entry($m->{file_a}, $pbat);
2889 }
2890
2891 sub M {
2892 my ($self, $m) = @_;
2893 my ($dir, $file) = split_path($m->{file_b});
2894 my $pbat = $self->ensure_path($dir);
2895 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2896 $pbat,$self->{r},$self->{pool});
2897 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2898 $self->chg_file($fbat, $m);
2899 $self->close_file($fbat,undef,$self->{pool});
2900 }
2901
2902 sub T { shift->M(@_) }
2903
2904 sub change_file_prop {
2905 my ($self, $fbat, $pname, $pval) = @_;
2906 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2907 }
2908
2909 sub chg_file {
2910 my ($self, $fbat, $m) = @_;
2911 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2912 $self->change_file_prop($fbat,'svn:executable','*');
2913 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2914 $self->change_file_prop($fbat,'svn:executable',undef);
2915 }
2916 my $fh = IO::File->new_tmpfile or croak $!;
2917 if ($m->{mode_b} =~ /^120/) {
2918 print $fh 'link ' or croak $!;
2919 $self->change_file_prop($fbat,'svn:special','*');
2920 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2921 $self->change_file_prop($fbat,'svn:special',undef);
2922 }
2923 defined(my $pid = fork) or croak $!;
2924 if (!$pid) {
2925 open STDOUT, '>&', $fh or croak $!;
2926 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2927 }
2928 waitpid $pid, 0;
2929 croak $? if $?;
2930 $fh->flush == 0 or croak $!;
2931 seek $fh, 0, 0 or croak $!;
2932
2933 my $md5 = Digest::MD5->new;
2934 $md5->addfile($fh) or croak $!;
2935 seek $fh, 0, 0 or croak $!;
2936
2937 my $exp = $md5->hexdigest;
2938 my $pool = SVN::Pool->new;
2939 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2940 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2941 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2942 $pool->clear;
2943
2944 close $fh or croak $!;
2945 }
2946
2947 sub D {
2948 my ($self, $m) = @_;
2949 my ($dir, $file) = split_path($m->{file_b});
2950 my $pbat = $self->ensure_path($dir);
2951 print "\tD\t$m->{file_b}\n" unless $::_q;
2952 $self->delete_entry($m->{file_b}, $pbat);
2953 }
2954
2955 sub close_edit {
2956 my ($self) = @_;
2957 my ($p,$bat) = ($self->{pool}, $self->{bat});
2958 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2959 next if $_ eq '';
2960 $self->close_directory($bat->{$_}, $p);
2961 }
2962 $self->close_directory($bat->{''}, $p);
2963 $self->SUPER::close_edit($p);
2964 $p->clear;
2965 }
2966
2967 sub abort_edit {
2968 my ($self) = @_;
2969 $self->SUPER::abort_edit($self->{pool});
2970 }
2971
2972 sub DESTROY {
2973 my $self = shift;
2974 $self->SUPER::DESTROY(@_);
2975 $self->{pool}->clear;
2976 }
2977
2978 # this drives the editor
2979 sub apply_diff {
2980 my ($self) = @_;
2981 my $mods = $self->{mods};
2982 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2983 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2984 my $f = $m->{chg};
2985 if (defined $o{$f}) {
2986 $self->$f($m);
2987 } else {
2988 fatal("Invalid change type: $f\n");
2989 }
2990 }
2991 $self->rmdirs if $_rmdir;
2992 if (@$mods == 0) {
2993 $self->abort_edit;
2994 } else {
2995 $self->close_edit;
2996 }
2997 return scalar @$mods;
2998 }
2999
3000 package Git::SVN::Ra;
3001 use vars qw/@ISA $config_dir $_log_window_size/;
3002 use strict;
3003 use warnings;
3004 my ($can_do_switch, %ignored_err, $RA);
3005
3006 BEGIN {
3007 # enforce temporary pool usage for some simple functions
3008 no strict 'refs';
3009 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3010 my $SUPER = "SUPER::$f";
3011 *$f = sub {
3012 my $self = shift;
3013 my $pool = SVN::Pool->new;
3014 my @ret = $self->$SUPER(@_,$pool);
3015 $pool->clear;
3016 wantarray ? @ret : $ret[0];
3017 };
3018 }
3019 }
3020
3021 sub new {
3022 my ($class, $url) = @_;
3023 $url =~ s!/+$!!;
3024 return $RA if ($RA && $RA->{url} eq $url);
3025
3026 SVN::_Core::svn_config_ensure($config_dir, undef);
3027 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
3028 SVN::Client::get_simple_provider(),
3029 SVN::Client::get_ssl_server_trust_file_provider(),
3030 SVN::Client::get_simple_prompt_provider(
3031 \&Git::SVN::Prompt::simple, 2),
3032 SVN::Client::get_ssl_client_cert_file_provider(),
3033 SVN::Client::get_ssl_client_cert_prompt_provider(
3034 \&Git::SVN::Prompt::ssl_client_cert, 2),
3035 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3036 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3037 SVN::Client::get_username_provider(),
3038 SVN::Client::get_ssl_server_trust_prompt_provider(
3039 \&Git::SVN::Prompt::ssl_server_trust),
3040 SVN::Client::get_username_prompt_provider(
3041 \&Git::SVN::Prompt::username, 2),
3042 ]);
3043 my $config = SVN::Core::config_get_config($config_dir);
3044 $RA = undef;
3045 my $self = SVN::Ra->new(url => $url, auth => $baton,
3046 config => $config,
3047 pool => SVN::Pool->new,
3048 auth_provider_callbacks => $callbacks);
3049 $self->{svn_path} = $url;
3050 $self->{repos_root} = $self->get_repos_root;
3051 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3052 $self->{cache} = { check_path => { r => 0, data => {} },
3053 get_dir => { r => 0, data => {} } };
3054 $RA = bless $self, $class;
3055 }
3056
3057 sub check_path {
3058 my ($self, $path, $r) = @_;
3059 my $cache = $self->{cache}->{check_path};
3060 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3061 return $cache->{data}->{$path};
3062 }
3063 my $pool = SVN::Pool->new;
3064 my $t = $self->SUPER::check_path($path, $r, $pool);
3065 $pool->clear;
3066 if ($r != $cache->{r}) {
3067 %{$cache->{data}} = ();
3068 $cache->{r} = $r;
3069 }
3070 $cache->{data}->{$path} = $t;
3071 }
3072
3073 sub get_dir {
3074 my ($self, $dir, $r) = @_;
3075 my $cache = $self->{cache}->{get_dir};
3076 if ($r == $cache->{r}) {
3077 if (my $x = $cache->{data}->{$dir}) {
3078 return wantarray ? @$x : $x->[0];
3079 }
3080 }
3081 my $pool = SVN::Pool->new;
3082 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3083 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3084 $pool->clear;
3085 if ($r != $cache->{r}) {
3086 %{$cache->{data}} = ();
3087 $cache->{r} = $r;
3088 }
3089 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3090 wantarray ? (\%dirents, $r, $props) : \%dirents;
3091 }
3092
3093 sub DESTROY {
3094 # do not call the real DESTROY since we store ourselves in $RA
3095 }
3096
3097 sub get_log {
3098 my ($self, @args) = @_;
3099 my $pool = SVN::Pool->new;
3100 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3101 my $ret = $self->SUPER::get_log(@args, $pool);
3102 $pool->clear;
3103 $ret;
3104 }
3105
3106 sub get_commit_editor {
3107 my ($self, $log, $cb, $pool) = @_;
3108 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3109 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3110 }
3111
3112 sub gs_do_update {
3113 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3114 my $new = ($rev_a == $rev_b);
3115 my $path = $gs->{path};
3116
3117 if ($new && -e $gs->{index}) {
3118 unlink $gs->{index} or die
3119 "Couldn't unlink index: $gs->{index}: $!\n";
3120 }
3121 my $pool = SVN::Pool->new;
3122 $editor->set_path_strip($path);
3123 my (@pc) = split m#/#, $path;
3124 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3125 1, $editor, $pool);
3126 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3127
3128 # Since we can't rely on svn_ra_reparent being available, we'll
3129 # just have to do some magic with set_path to make it so
3130 # we only want a partial path.
3131 my $sp = '';
3132 my $final = join('/', @pc);
3133 while (@pc) {
3134 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3135 $sp .= '/' if length $sp;
3136 $sp .= shift @pc;
3137 }
3138 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3139
3140 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3141
3142 $reporter->finish_report($pool);
3143 $pool->clear;
3144 $editor->{git_commit_ok};
3145 }
3146
3147 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3148 # svn_ra_reparent didn't work before 1.4)
3149 sub gs_do_switch {
3150 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3151 my $path = $gs->{path};
3152 my $pool = SVN::Pool->new;
3153
3154 my $full_url = $self->{url};
3155 my $old_url = $full_url;
3156 $full_url .= "/$path" if length $path;
3157 my ($ra, $reparented);
3158 if ($old_url ne $full_url) {
3159 if ($old_url !~ m#^svn(\+ssh)?://#) {
3160 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3161 $pool);
3162 $self->{url} = $full_url;
3163 $reparented = 1;
3164 } else {
3165 $ra = Git::SVN::Ra->new($full_url);
3166 }
3167 }
3168 $ra ||= $self;
3169 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3170 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3171 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3172 $reporter->finish_report($pool);
3173
3174 if ($reparented) {
3175 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3176 $self->{url} = $old_url;
3177 }
3178
3179 $pool->clear;
3180 $editor->{git_commit_ok};
3181 }
3182
3183 sub longest_common_path {
3184 my ($gsv, $globs) = @_;
3185 my %common;
3186 my $common_max = scalar @$gsv;
3187
3188 foreach my $gs (@$gsv) {
3189 my @tmp = split m#/#, $gs->{path};
3190 my $p = '';
3191 foreach (@tmp) {
3192 $p .= length($p) ? "/$_" : $_;
3193 $common{$p} ||= 0;
3194 $common{$p}++;
3195 }
3196 }
3197 $globs ||= [];
3198 $common_max += scalar @$globs;
3199 foreach my $glob (@$globs) {
3200 my @tmp = split m#/#, $glob->{path}->{left};
3201 my $p = '';
3202 foreach (@tmp) {
3203 $p .= length($p) ? "/$_" : $_;
3204 $common{$p} ||= 0;
3205 $common{$p}++;
3206 }
3207 }
3208
3209 my $longest_path = '';
3210 foreach (sort {length $b <=> length $a} keys %common) {
3211 if ($common{$_} == $common_max) {
3212 $longest_path = $_;
3213 last;
3214 }
3215 }
3216 $longest_path;
3217 }
3218
3219 sub gs_fetch_loop_common {
3220 my ($self, $base, $head, $gsv, $globs) = @_;
3221 return if ($base > $head);
3222 my $inc = $_log_window_size;
3223 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3224 my $longest_path = longest_common_path($gsv, $globs);
3225 while (1) {
3226 my %revs;
3227 my $err;
3228 my $err_handler = $SVN::Error::handler;
3229 $SVN::Error::handler = sub {
3230 ($err) = @_;
3231 skip_unknown_revs($err);
3232 };
3233 sub _cb {
3234 my ($paths, $r, $author, $date, $log) = @_;
3235 [ dup_changed_paths($paths),
3236 { author => $author, date => $date, log => $log } ];
3237 }
3238 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3239 sub { $revs{$_[1]} = _cb(@_) });
3240 if ($err && $max >= $head) {
3241 print STDERR "Path '$longest_path' ",
3242 "was probably deleted:\n",
3243 $err->expanded_message,
3244 "\nWill attempt to follow ",
3245 "revisions r$min .. r$max ",
3246 "committed before the deletion\n";
3247 my $hi = $max;
3248 while (--$hi >= $min) {
3249 my $ok;
3250 $self->get_log([$longest_path], $min, $hi,
3251 0, 1, 1, sub {
3252 $ok ||= $_[1];
3253 $revs{$_[1]} = _cb(@_) });
3254 if ($ok) {
3255 print STDERR "r$min .. r$ok OK\n";
3256 last;
3257 }
3258 }
3259 }
3260 $SVN::Error::handler = $err_handler;
3261
3262 my %exists = map { $_->{path} => $_ } @$gsv;
3263 foreach my $r (sort {$a <=> $b} keys %revs) {
3264 my ($paths, $logged) = @{$revs{$r}};
3265
3266 foreach my $gs ($self->match_globs(\%exists, $paths,
3267 $globs, $r)) {
3268 if ($gs->rev_db_max >= $r) {
3269 next;
3270 }
3271 next unless $gs->match_paths($paths, $r);
3272 $gs->{logged_rev_props} = $logged;
3273 if (my $last_commit = $gs->last_commit) {
3274 $gs->assert_index_clean($last_commit);
3275 }
3276 my $log_entry = $gs->do_fetch($paths, $r);
3277 if ($log_entry) {
3278 $gs->do_git_commit($log_entry);
3279 }
3280 }
3281 foreach my $g (@$globs) {
3282 my $k = "svn-remote.$g->{remote}." .
3283 "$g->{t}-maxRev";
3284 Git::SVN::tmp_config($k, $r);
3285 }
3286 }
3287 # pre-fill the .rev_db since it'll eventually get filled in
3288 # with '0' x40 if something new gets committed
3289 foreach my $gs (@$gsv) {
3290 next if defined $gs->rev_db_get($max);
3291 $gs->rev_db_set($max, 0 x40);
3292 }
3293 foreach my $g (@$globs) {
3294 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3295 Git::SVN::tmp_config($k, $max);
3296 }
3297 last if $max >= $head;
3298 $min = $max + 1;
3299 $max += $inc;
3300 $max = $head if ($max > $head);
3301 }
3302 }
3303
3304 sub match_globs {
3305 my ($self, $exists, $paths, $globs, $r) = @_;
3306
3307 sub get_dir_check {
3308 my ($self, $exists, $g, $r) = @_;
3309 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3310 return unless scalar @x == 3;
3311 my $dirents = $x[0];
3312 foreach my $de (keys %$dirents) {
3313 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3314 my $p = $g->{path}->full_path($de);
3315 next if $exists->{$p};
3316 next if (length $g->{path}->{right} &&
3317 ($self->check_path($p, $r) !=
3318 $SVN::Node::dir));
3319 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3320 $g->{ref}->full_path($de), 1);
3321 }
3322 }
3323 foreach my $g (@$globs) {
3324 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3325 if ($path->{action} =~ /^[AR]$/) {
3326 get_dir_check($self, $exists, $g, $r);
3327 }
3328 }
3329 foreach (keys %$paths) {
3330 if (/$g->{path}->{left_regex}/ &&
3331 !/$g->{path}->{regex}/) {
3332 next if $paths->{$_}->{action} !~ /^[AR]$/;
3333 get_dir_check($self, $exists, $g, $r);
3334 }
3335 next unless /$g->{path}->{regex}/;
3336 my $p = $1;
3337 my $pathname = $g->{path}->full_path($p);
3338 next if $exists->{$pathname};
3339 next if ($self->check_path($pathname, $r) !=
3340 $SVN::Node::dir);
3341 $exists->{$pathname} = Git::SVN->init(
3342 $self->{url}, $pathname, undef,
3343 $g->{ref}->full_path($p), 1);
3344 }
3345 my $c = '';
3346 foreach (split m#/#, $g->{path}->{left}) {
3347 $c .= "/$_";
3348 next unless ($paths->{$c} &&
3349 ($paths->{$c}->{action} =~ /^[AR]$/));
3350 get_dir_check($self, $exists, $g, $r);
3351 }
3352 }
3353 values %$exists;
3354 }
3355
3356 sub minimize_url {
3357 my ($self) = @_;
3358 return $self->{url} if ($self->{url} eq $self->{repos_root});
3359 my $url = $self->{repos_root};
3360 my @components = split(m!/!, $self->{svn_path});
3361 my $c = '';
3362 do {
3363 $url .= "/$c" if length $c;
3364 eval { (ref $self)->new($url)->get_latest_revnum };
3365 } while ($@ && ($c = shift @components));
3366 $url;
3367 }
3368
3369 sub can_do_switch {
3370 my $self = shift;
3371 unless (defined $can_do_switch) {
3372 my $pool = SVN::Pool->new;
3373 my $rep = eval {
3374 $self->do_switch(1, '', 0, $self->{url},
3375 SVN::Delta::Editor->new, $pool);
3376 };
3377 if ($@) {
3378 $can_do_switch = 0;
3379 } else {
3380 $rep->abort_report($pool);
3381 $can_do_switch = 1;
3382 }
3383 $pool->clear;
3384 }
3385 $can_do_switch;
3386 }
3387
3388 sub skip_unknown_revs {
3389 my ($err) = @_;
3390 my $errno = $err->apr_err();
3391 # Maybe the branch we're tracking didn't
3392 # exist when the repo started, so it's
3393 # not an error if it doesn't, just continue
3394 #
3395 # Wonderfully consistent library, eh?
3396 # 160013 - svn:// and file://
3397 # 175002 - http(s)://
3398 # 175007 - http(s):// (this repo required authorization, too...)
3399 # More codes may be discovered later...
3400 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3401 my $err_key = $err->expanded_message;
3402 # revision numbers change every time, filter them out
3403 $err_key =~ s/\d+/\0/g;
3404 $err_key = "$errno\0$err_key";
3405 unless ($ignored_err{$err_key}) {
3406 warn "W: Ignoring error from SVN, path probably ",
3407 "does not exist: ($errno): ",
3408 $err->expanded_message,"\n";
3409 $ignored_err{$err_key} = 1;
3410 }
3411 return;
3412 }
3413 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3414 }
3415
3416 # svn_log_changed_path_t objects passed to get_log are likely to be
3417 # overwritten even if only the refs are copied to an external variable,
3418 # so we should dup the structures in their entirety. Using an externally
3419 # passed pool (instead of our temporary and quickly cleared pool in
3420 # Git::SVN::Ra) does not help matters at all...
3421 sub dup_changed_paths {
3422 my ($paths) = @_;
3423 return undef unless $paths;
3424 my %ret;
3425 foreach my $p (keys %$paths) {
3426 my $i = $paths->{$p};
3427 my %s = map { $_ => $i->$_ }
3428 qw/copyfrom_path copyfrom_rev action/;
3429 $ret{$p} = \%s;
3430 }
3431 \%ret;
3432 }
3433
3434 package Git::SVN::Log;
3435 use strict;
3436 use warnings;
3437 use POSIX qw/strftime/;
3438 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
3439 %rusers $show_commit $incremental/;
3440 my $l_fmt;
3441
3442 sub cmt_showable {
3443 my ($c) = @_;
3444 return 1 if defined $c->{r};
3445
3446 # big commit message got truncated by the 16k pretty buffer in rev-list
3447 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
3448 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
3449 @{$c->{l}} = ();
3450 my @log = command(qw/cat-file commit/, $c->{c});
3451
3452 # shift off the headers
3453 shift @log while ($log[0] ne '');
3454 shift @log;
3455
3456 # TODO: make $c->{l} not have a trailing newline in the future
3457 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
3458
3459 (undef, $c->{r}, undef) = ::extract_metadata(
3460 (grep(/^git-svn-id: /, @log))[-1]);
3461 }
3462 return defined $c->{r};
3463 }
3464
3465 sub log_use_color {
3466 return 1 if $color;
3467 my ($dc, $dcvar);
3468 $dcvar = 'color.diff';
3469 $dc = `git-config --get $dcvar`;
3470 if ($dc eq '') {
3471 # nothing at all; fallback to "diff.color"
3472 $dcvar = 'diff.color';
3473 $dc = `git-config --get $dcvar`;
3474 }
3475 chomp($dc);
3476 if ($dc eq 'auto') {
3477 my $pc;
3478 $pc = `git-config --get color.pager`;
3479 if ($pc eq '') {
3480 # does not have it -- fallback to pager.color
3481 $pc = `git-config --bool --get pager.color`;
3482 }
3483 else {
3484 $pc = `git-config --bool --get color.pager`;
3485 if ($?) {
3486 $pc = 'false';
3487 }
3488 }
3489 chomp($pc);
3490 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
3491 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
3492 }
3493 return 0;
3494 }
3495 return 0 if $dc eq 'never';
3496 return 1 if $dc eq 'always';
3497 chomp($dc = `git-config --bool --get $dcvar`);
3498 return ($dc eq 'true');
3499 }
3500
3501 sub git_svn_log_cmd {
3502 my ($r_min, $r_max, @args) = @_;
3503 my $head = 'HEAD';
3504 foreach my $x (@args) {
3505 last if $x eq '--';
3506 next unless ::verify_ref("$x^0");
3507 $head = $x;
3508 last;
3509 }
3510
3511 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
3512 $gs ||= Git::SVN->_new;
3513 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
3514 $gs->refname);
3515 push @cmd, '-r' unless $non_recursive;
3516 push @cmd, qw/--raw --name-status/ if $verbose;
3517 push @cmd, '--color' if log_use_color();
3518 return @cmd unless defined $r_max;
3519 if ($r_max == $r_min) {
3520 push @cmd, '--max-count=1';
3521 if (my $c = $gs->rev_db_get($r_max)) {
3522 push @cmd, $c;
3523 }
3524 } else {
3525 my ($c_min, $c_max);
3526 $c_max = $gs->rev_db_get($r_max);
3527 $c_min = $gs->rev_db_get($r_min);
3528 if (defined $c_min && defined $c_max) {
3529 if ($r_max > $r_max) {
3530 push @cmd, "$c_min..$c_max";
3531 } else {
3532 push @cmd, "$c_max..$c_min";
3533 }
3534 } elsif ($r_max > $r_min) {
3535 push @cmd, $c_max;
3536 } else {
3537 push @cmd, $c_min;
3538 }
3539 }
3540 return @cmd;
3541 }
3542
3543 # adapted from pager.c
3544 sub config_pager {
3545 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
3546 if (!defined $pager) {
3547 $pager = 'less';
3548 } elsif (length $pager == 0 || $pager eq 'cat') {
3549 $pager = undef;
3550 }
3551 }
3552
3553 sub run_pager {
3554 return unless -t *STDOUT;
3555 pipe my $rfd, my $wfd or return;
3556 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
3557 if (!$pid) {
3558 open STDOUT, '>&', $wfd or
3559 ::fatal "Can't redirect to stdout: $!\n";
3560 return;
3561 }
3562 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
3563 $ENV{LESS} ||= 'FRSX';
3564 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
3565 }
3566
3567 sub tz_to_s_offset {
3568 my ($tz) = @_;
3569 $tz =~ s/(\d\d)$//;
3570 return ($1 * 60) + ($tz * 3600);
3571 }
3572
3573 sub get_author_info {
3574 my ($dest, $author, $t, $tz) = @_;
3575 $author =~ s/(?:^\s*|\s*$)//g;
3576 $dest->{a_raw} = $author;
3577 my $au;
3578 if ($::_authors) {
3579 $au = $rusers{$author} || undef;
3580 }
3581 if (!$au) {
3582 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
3583 }
3584 $dest->{t} = $t;
3585 $dest->{tz} = $tz;
3586 $dest->{a} = $au;
3587 # Date::Parse isn't in the standard Perl distro :(
3588 if ($tz =~ s/^\+//) {
3589 $t += tz_to_s_offset($tz);
3590 } elsif ($tz =~ s/^\-//) {
3591 $t -= tz_to_s_offset($tz);
3592 }
3593 $dest->{t_utc} = $t;
3594 }
3595
3596 sub process_commit {
3597 my ($c, $r_min, $r_max, $defer) = @_;
3598 if (defined $r_min && defined $r_max) {
3599 if ($r_min == $c->{r} && $r_min == $r_max) {
3600 show_commit($c);
3601 return 0;
3602 }
3603 return 1 if $r_min == $r_max;
3604 if ($r_min < $r_max) {
3605 # we need to reverse the print order
3606 return 0 if (defined $limit && --$limit < 0);
3607 push @$defer, $c;
3608 return 1;
3609 }
3610 if ($r_min != $r_max) {
3611 return 1 if ($r_min < $c->{r});
3612 return 1 if ($r_max > $c->{r});
3613 }
3614 }
3615 return 0 if (defined $limit && --$limit < 0);
3616 show_commit($c);
3617 return 1;
3618 }
3619
3620 sub show_commit {
3621 my $c = shift;
3622 if ($oneline) {
3623 my $x = "\n";
3624 if (my $l = $c->{l}) {
3625 while ($l->[0] =~ /^\s*$/) { shift @$l }
3626 $x = $l->[0];
3627 }
3628 $l_fmt ||= 'A' . length($c->{r});
3629 print 'r',pack($l_fmt, $c->{r}),' | ';
3630 print "$c->{c} | " if $show_commit;
3631 print $x;
3632 } else {
3633 show_commit_normal($c);
3634 }
3635 }
3636
3637 sub show_commit_changed_paths {
3638 my ($c) = @_;
3639 return unless $c->{changed};
3640 print "Changed paths:\n", @{$c->{changed}};
3641 }
3642
3643 sub show_commit_normal {
3644 my ($c) = @_;
3645 print '-' x72, "\nr$c->{r} | ";
3646 print "$c->{c} | " if $show_commit;
3647 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
3648 localtime($c->{t_utc})), ' | ';
3649 my $nr_line = 0;
3650
3651 if (my $l = $c->{l}) {
3652 while ($l->[$#$l] eq "\n" && $#$l > 0
3653 && $l->[($#$l - 1)] eq "\n") {
3654 pop @$l;
3655 }
3656 $nr_line = scalar @$l;
3657 if (!$nr_line) {
3658 print "1 line\n\n\n";
3659 } else {
3660 if ($nr_line == 1) {
3661 $nr_line = '1 line';
3662 } else {
3663 $nr_line .= ' lines';
3664 }
3665 print $nr_line, "\n";
3666 show_commit_changed_paths($c);
3667 print "\n";
3668 print $_ foreach @$l;
3669 }
3670 } else {
3671 print "1 line\n";
3672 show_commit_changed_paths($c);
3673 print "\n";
3674
3675 }
3676 foreach my $x (qw/raw stat diff/) {
3677 if ($c->{$x}) {
3678 print "\n";
3679 print $_ foreach @{$c->{$x}}
3680 }
3681 }
3682 }
3683
3684 sub cmd_show_log {
3685 my (@args) = @_;
3686 my ($r_min, $r_max);
3687 my $r_last = -1; # prevent dupes
3688 if (defined $TZ) {
3689 $ENV{TZ} = $TZ;
3690 } else {
3691 delete $ENV{TZ};
3692 }
3693 if (defined $::_revision) {
3694 if ($::_revision =~ /^(\d+):(\d+)$/) {
3695 ($r_min, $r_max) = ($1, $2);
3696 } elsif ($::_revision =~ /^\d+$/) {
3697 $r_min = $r_max = $::_revision;
3698 } else {
3699 ::fatal "-r$::_revision is not supported, use ",
3700 "standard \'git log\' arguments instead\n";
3701 }
3702 }
3703
3704 config_pager();
3705 @args = (git_svn_log_cmd($r_min, $r_max, @args), @args);
3706 my $log = command_output_pipe(@args);
3707 run_pager();
3708 my (@k, $c, $d, $stat);
3709 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
3710 while (<$log>) {
3711 if (/^${esc_color}commit ($::sha1_short)/o) {
3712 my $cmt = $1;
3713 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
3714 $r_last = $c->{r};
3715 process_commit($c, $r_min, $r_max, \@k) or
3716 goto out;
3717 }
3718 $d = undef;
3719 $c = { c => $cmt };
3720 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
3721 get_author_info($c, $1, $2, $3);
3722 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
3723 # ignore
3724 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
3725 push @{$c->{raw}}, $_;
3726 } elsif (/^${esc_color}[ACRMDT]\t/) {
3727 # we could add $SVN->{svn_path} here, but that requires
3728 # remote access at the moment (repo_path_split)...
3729 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
3730 push @{$c->{changed}}, $_;
3731 } elsif (/^${esc_color}diff /o) {
3732 $d = 1;
3733 push @{$c->{diff}}, $_;
3734 } elsif ($d) {
3735 push @{$c->{diff}}, $_;
3736 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
3737 $esc_color*[\+\-]*$esc_color$/x) {
3738 $stat = 1;
3739 push @{$c->{stat}}, $_;
3740 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
3741 push @{$c->{stat}}, $_;
3742 $stat = undef;
3743 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
3744 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
3745 } elsif (s/^${esc_color} //o) {
3746 push @{$c->{l}}, $_;
3747 }
3748 }
3749 if ($c && defined $c->{r} && $c->{r} != $r_last) {
3750 $r_last = $c->{r};
3751 process_commit($c, $r_min, $r_max, \@k);
3752 }
3753 if (@k) {
3754 my $swap = $r_max;
3755 $r_max = $r_min;
3756 $r_min = $swap;
3757 process_commit($_, $r_min, $r_max) foreach reverse @k;
3758 }
3759 out:
3760 close $log;
3761 print '-' x72,"\n" unless $incremental || $oneline;
3762 }
3763
3764 package Git::SVN::Migration;
3765 # these version numbers do NOT correspond to actual version numbers
3766 # of git nor git-svn. They are just relative.
3767 #
3768 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
3769 #
3770 # v1 layout: .git/$id/info/url, refs/remotes/$id
3771 #
3772 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
3773 #
3774 # v3 layout: .git/svn/$id, refs/remotes/$id
3775 # - info/url may remain for backwards compatibility
3776 # - this is what we migrate up to this layout automatically,
3777 # - this will be used by git svn init on single branches
3778 # v3.1 layout (auto migrated):
3779 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
3780 # for backwards compatibility
3781 #
3782 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
3783 # - this is only created for newly multi-init-ed
3784 # repositories. Similar in spirit to the
3785 # --use-separate-remotes option in git-clone (now default)
3786 # - we do not automatically migrate to this (following
3787 # the example set by core git)
3788 use strict;
3789 use warnings;
3790 use Carp qw/croak/;
3791 use File::Path qw/mkpath/;
3792 use File::Basename qw/dirname basename/;
3793 use vars qw/$_minimize/;
3794
3795 sub migrate_from_v0 {
3796 my $git_dir = $ENV{GIT_DIR};
3797 return undef unless -d $git_dir;
3798 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3799 my $migrated = 0;
3800 while (<$fh>) {
3801 chomp;
3802 my ($id, $orig_ref) = ($_, $_);
3803 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
3804 next unless -f "$git_dir/$id/info/url";
3805 my $new_ref = "refs/remotes/$id";
3806 if (::verify_ref("$new_ref^0")) {
3807 print STDERR "W: $orig_ref is probably an old ",
3808 "branch used by an ancient version of ",
3809 "git-svn.\n",
3810 "However, $new_ref also exists.\n",
3811 "We will not be able ",
3812 "to use this branch until this ",
3813 "ambiguity is resolved.\n";
3814 next;
3815 }
3816 print STDERR "Migrating from v0 layout...\n" if !$migrated;
3817 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
3818 command_noisy('update-ref', $new_ref, $orig_ref);
3819 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
3820 $migrated++;
3821 }
3822 command_close_pipe($fh, $ctx);
3823 print STDERR "Done migrating from v0 layout...\n" if $migrated;
3824 $migrated;
3825 }
3826
3827 sub migrate_from_v1 {
3828 my $git_dir = $ENV{GIT_DIR};
3829 my $migrated = 0;
3830 return $migrated unless -d $git_dir;
3831 my $svn_dir = "$git_dir/svn";
3832
3833 # just in case somebody used 'svn' as their $id at some point...
3834 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
3835
3836 print STDERR "Migrating from a git-svn v1 layout...\n";
3837 mkpath([$svn_dir]);
3838 print STDERR "Data from a previous version of git-svn exists, but\n\t",
3839 "$svn_dir\n\t(required for this version ",
3840 "($::VERSION) of git-svn) does not. exist\n";
3841 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3842 while (<$fh>) {
3843 my $x = $_;
3844 next unless $x =~ s#^refs/remotes/##;
3845 chomp $x;
3846 next unless -f "$git_dir/$x/info/url";
3847 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
3848 next unless $u;
3849 my $dn = dirname("$git_dir/svn/$x");
3850 mkpath([$dn]) unless -d $dn;
3851 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
3852 mkpath(["$git_dir/svn/svn"]);
3853 print STDERR " - $git_dir/$x/info => ",
3854 "$git_dir/svn/$x/info\n";
3855 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
3856 croak "$!: $x";
3857 # don't worry too much about these, they probably
3858 # don't exist with repos this old (save for index,
3859 # and we can easily regenerate that)
3860 foreach my $f (qw/unhandled.log index .rev_db/) {
3861 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
3862 }
3863 } else {
3864 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
3865 rename "$git_dir/$x", "$git_dir/svn/$x" or
3866 croak "$!: $x";
3867 }
3868 $migrated++;
3869 }
3870 command_close_pipe($fh, $ctx);
3871 print STDERR "Done migrating from a git-svn v1 layout\n";
3872 $migrated;
3873 }
3874
3875 sub read_old_urls {
3876 my ($l_map, $pfx, $path) = @_;
3877 my @dir;
3878 foreach (<$path/*>) {
3879 if (-r "$_/info/url") {
3880 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
3881 my $ref_id = $pfx . basename $_;
3882 my $url = ::file_to_s("$_/info/url");
3883 $l_map->{$ref_id} = $url;
3884 } elsif (-d $_) {
3885 push @dir, $_;
3886 }
3887 }
3888 foreach (@dir) {
3889 my $x = $_;
3890 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
3891 read_old_urls($l_map, $x, $_);
3892 }
3893 }
3894
3895 sub migrate_from_v2 {
3896 my @cfg = command(qw/config -l/);
3897 return if grep /^svn-remote\..+\.url=/, @cfg;
3898 my %l_map;
3899 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
3900 my $migrated = 0;
3901
3902 foreach my $ref_id (sort keys %l_map) {
3903 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
3904 if ($@) {
3905 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
3906 }
3907 $migrated++;
3908 }
3909 $migrated;
3910 }
3911
3912 sub minimize_connections {
3913 my $r = Git::SVN::read_all_remotes();
3914 my $new_urls = {};
3915 my $root_repos = {};
3916 foreach my $repo_id (keys %$r) {
3917 my $url = $r->{$repo_id}->{url} or next;
3918 my $fetch = $r->{$repo_id}->{fetch} or next;
3919 my $ra = Git::SVN::Ra->new($url);
3920
3921 # skip existing cases where we already connect to the root
3922 if (($ra->{url} eq $ra->{repos_root}) ||
3923 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
3924 $repo_id)) {
3925 $root_repos->{$ra->{url}} = $repo_id;
3926 next;
3927 }
3928
3929 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
3930 my $root_path = $ra->{url};
3931 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
3932 foreach my $path (keys %$fetch) {
3933 my $ref_id = $fetch->{$path};
3934 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
3935
3936 # make sure we can read when connecting to
3937 # a higher level of a repository
3938 my ($last_rev, undef) = $gs->last_rev_commit;
3939 if (!defined $last_rev) {
3940 $last_rev = eval {
3941 $root_ra->get_latest_revnum;
3942 };
3943 next if $@;
3944 }
3945 my $new = $root_path;
3946 $new .= length $path ? "/$path" : '';
3947 eval {
3948 $root_ra->get_log([$new], $last_rev, $last_rev,
3949 0, 0, 1, sub { });
3950 };
3951 next if $@;
3952 $new_urls->{$ra->{repos_root}}->{$new} =
3953 { ref_id => $ref_id,
3954 old_repo_id => $repo_id,
3955 old_path => $path };
3956 }
3957 }
3958
3959 my @emptied;
3960 foreach my $url (keys %$new_urls) {
3961 # see if we can re-use an existing [svn-remote "repo_id"]
3962 # instead of creating a(n ugly) new section:
3963 my $repo_id = $root_repos->{$url} ||
3964 Git::SVN::sanitize_remote_name($url);
3965
3966 my $fetch = $new_urls->{$url};
3967 foreach my $path (keys %$fetch) {
3968 my $x = $fetch->{$path};
3969 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
3970 my $pfx = "svn-remote.$x->{old_repo_id}";
3971
3972 my $old_fetch = quotemeta("$x->{old_path}:".
3973 "refs/remotes/$x->{ref_id}");
3974 command_noisy(qw/config --unset/,
3975 "$pfx.fetch", '^'. $old_fetch . '$');
3976 delete $r->{$x->{old_repo_id}}->
3977 {fetch}->{$x->{old_path}};
3978 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3979 command_noisy(qw/config --unset/,
3980 "$pfx.url");
3981 push @emptied, $x->{old_repo_id}
3982 }
3983 }
3984 }
3985 if (@emptied) {
3986 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3987 "$ENV{GIT_DIR}/config";
3988 print STDERR <<EOF;
3989 The following [svn-remote] sections in your config file ($file) are empty
3990 and can be safely removed:
3991 EOF
3992 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3993 }
3994 }
3995
3996 sub migration_check {
3997 migrate_from_v0();
3998 migrate_from_v1();
3999 migrate_from_v2();
4000 minimize_connections() if $_minimize;
4001 }
4002
4003 package Git::IndexInfo;
4004 use strict;
4005 use warnings;
4006 use Git qw/command_input_pipe command_close_pipe/;
4007
4008 sub new {
4009 my ($class) = @_;
4010 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4011 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4012 }
4013
4014 sub remove {
4015 my ($self, $path) = @_;
4016 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4017 return ++$self->{nr};
4018 }
4019 undef;
4020 }
4021
4022 sub update {
4023 my ($self, $mode, $hash, $path) = @_;
4024 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4025 return ++$self->{nr};
4026 }
4027 undef;
4028 }
4029
4030 sub DESTROY {
4031 my ($self) = @_;
4032 command_close_pipe($self->{gui}, $self->{ctx});
4033 }
4034
4035 package Git::SVN::GlobSpec;
4036 use strict;
4037 use warnings;
4038
4039 sub new {
4040 my ($class, $glob) = @_;
4041 my $re = $glob;
4042 $re =~ s!/+$!!g; # no need for trailing slashes
4043 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4044 my ($left, $right) = ($1, $2);
4045 if ($nr > 1) {
4046 die "Only one '*' wildcard expansion ",
4047 "is supported (got $nr): '$glob'\n";
4048 } elsif ($nr == 0) {
4049 die "One '*' is needed for glob: '$glob'\n";
4050 }
4051 $re = quotemeta($left) . $re . quotemeta($right);
4052 if (length $left && !($left =~ s!/+$!!g)) {
4053 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4054 }
4055 if (length $right && !($right =~ s!^/+!!g)) {
4056 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4057 }
4058 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4059 bless { left => $left, right => $right, left_regex => $left_re,
4060 regex => qr/$re/, glob => $glob }, $class;
4061 }
4062
4063 sub full_path {
4064 my ($self, $path) = @_;
4065 return (length $self->{left} ? "$self->{left}/" : '') .
4066 $path . (length $self->{right} ? "/$self->{right}" : '');
4067 }
4068
4069 __END__
4070
4071 Data structures:
4072
4073
4074 $remotes = { # returned by read_all_remotes()
4075 'svn' => {
4076 # svn-remote.svn.url=https://svn.musicpd.org
4077 url => 'https://svn.musicpd.org',
4078 # svn-remote.svn.fetch=mpd/trunk:trunk
4079 fetch => {
4080 'mpd/trunk' => 'trunk',
4081 },
4082 # svn-remote.svn.tags=mpd/tags/*:tags/*
4083 tags => {
4084 path => {
4085 left => 'mpd/tags',
4086 right => '',
4087 regex => qr!mpd/tags/([^/]+)$!,
4088 glob => 'tags/*',
4089 },
4090 ref => {
4091 left => 'tags',
4092 right => '',
4093 regex => qr!tags/([^/]+)$!,
4094 glob => 'tags/*',
4095 },
4096 }
4097 }
4098 };
4099
4100 $log_entry hashref as returned by libsvn_log_entry()
4101 {
4102 log => 'whitespace-formatted log entry
4103 ', # trailing newline is preserved
4104 revision => '8', # integer
4105 date => '2004-02-24T17:01:44.108345Z', # commit date
4106 author => 'committer name'
4107 };
4108
4109
4110 # this is generated by generate_diff();
4111 @mods = array of diff-index line hashes, each element represents one line
4112 of diff-index output
4113
4114 diff-index line ($m hash)
4115 {
4116 mode_a => first column of diff-index output, no leading ':',
4117 mode_b => second column of diff-index output,
4118 sha1_b => sha1sum of the final blob,
4119 chg => change type [MCRADT],
4120 file_a => original file name of a file (iff chg is 'C' or 'R')
4121 file_b => new/current file name of a file (any chg)
4122 }
4123 ;
4124
4125 # retval of read_url_paths{,_all}();
4126 $l_map = {
4127 # repository root url
4128 'https://svn.musicpd.org' => {
4129 # repository path # GIT_SVN_ID
4130 'mpd/trunk' => 'trunk',
4131 'mpd/tags/0.11.5' => 'tags/0.11.5',
4132 },
4133 }
4134
4135 Notes:
4136 I don't trust the each() function on unless I created %hash myself
4137 because the internal iterator may not have started at base.
Jonathan Nieder’s miscellaneous git branches