lib/merge.tcl

   1 # git-gui branch merge support
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class merge {
   5
   6 field w         ; # top level window
   7 field w_rev     ; # mega-widget to pick the revision to merge
   8
   9 method _can_merge {} {
  10         global HEAD commit_type file_states
  11
  12         if {[string match amend* $commit_type]} {
  13                 info_popup {Cannot merge while amending.
  14
  15 You must finish amending this commit before starting any type of merge.
  16 }
  17                 return 0
  18         }
  19
  20         if {[committer_ident] eq {}} {return 0}
  21         if {![lock_index merge]} {return 0}
  22
  23         # -- Our in memory state should match the repository.
  24         #
  25         repository_state curType curHEAD curMERGE_HEAD
  26         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
  27                 info_popup {Last scanned state does not match repository state.
  28
  29 Another Git program has modified this repository since the last scan.  A rescan must be performed before a merge can be performed.
  30
  31 The rescan will be automatically started now.
  32 }
  33                 unlock_index
  34                 rescan ui_ready
  35                 return 0
  36         }
  37
  38         foreach path [array names file_states] {
  39                 switch -glob -- [lindex $file_states($path) 0] {
  40                 _O {
  41                         continue; # and pray it works!
  42                 }
  43                 U? {
  44                         error_popup "You are in the middle of a conflicted merge.
  45
  46 File [short_path $path] has merge conflicts.
  47
  48 You must resolve them, add the file, and commit to complete the current merge.  Only then can you begin another merge.
  49 "
  50                         unlock_index
  51                         return 0
  52                 }
  53                 ?? {
  54                         error_popup "You are in the middle of a change.
  55
  56 File [short_path $path] is modified.
  57
  58 You should complete the current commit before starting a merge.  Doing so will help you abort a failed merge, should the need arise.
  59 "
  60                         unlock_index
  61                         return 0
  62                 }
  63                 }
  64         }
  65
  66         return 1
  67 }
  68
  69 method _rev {} {
  70         if {[catch {$w_rev commit_or_die}]} {
  71                 return {}
  72         }
  73         return [$w_rev get]
  74 }
  75
  76 method _visualize {} {
  77         set rev [_rev $this]
  78         if {$rev ne {}} {
  79                 do_gitk [list $rev --not HEAD]
  80         }
  81 }
  82
  83 method _start {} {
  84         global HEAD current_branch
  85
  86         set name [_rev $this]
  87         if {$name eq {}} {
  88                 return
  89         }
  90
  91         set cmd [list git merge $name]
  92         set msg "Merging $current_branch and $name"
  93         ui_status "$msg..."
  94         set cons [console::new "Merge" $cmd]
  95         console::exec $cons $cmd [cb _finish $cons]
  96
  97         wm protocol $w WM_DELETE_WINDOW {}
  98         destroy $w
  99 }
 100
 101 method _finish {cons ok} {
 102         console::done $cons $ok
 103         if {$ok} {
 104                 set msg {Merge completed successfully.}
 105         } else {
 106                 set msg {Merge failed.  Conflict resolution is required.}
 107         }
 108         unlock_index
 109         rescan [list ui_status $msg]
 110         delete_this
 111 }
 112
 113 constructor dialog {} {
 114         global current_branch
 115         global M1B
 116
 117         if {![_can_merge $this]} {
 118                 delete_this
 119                 return
 120         }
 121
 122         make_toplevel top w
 123         wm title $top "[appname] ([reponame]): Merge"
 124         if {$top ne {.}} {
 125                 wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
 126         }
 127
 128         set _start [cb _start]
 129
 130         label $w.header \
 131                 -text "Merge Into $current_branch" \
 132                 -font font_uibold
 133         pack $w.header -side top -fill x
 134
 135         frame $w.buttons
 136         button $w.buttons.visualize \
 137                 -text Visualize \
 138                 -command [cb _visualize]
 139         pack $w.buttons.visualize -side left
 140         button $w.buttons.merge \
 141                 -text Merge \
 142                 -command $_start
 143         pack $w.buttons.merge -side right
 144         button $w.buttons.cancel \
 145                 -text {Cancel} \
 146                 -command [cb _cancel]
 147         pack $w.buttons.cancel -side right -padx 5
 148         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
 149
 150         set w_rev [::choose_rev::new_unmerged $w.rev {Revision To Merge}]
 151         pack $w.rev -anchor nw -fill both -expand 1 -pady 5 -padx 5
 152
 153         bind $w <$M1B-Key-Return> $_start
 154         bind $w <Key-Return> $_start
 155         bind $w <Key-Escape> [cb _cancel]
 156         wm protocol $w WM_DELETE_WINDOW [cb _cancel]
 157
 158         bind $w.buttons.merge <Visibility> [cb _visible]
 159         tkwait window $w
 160 }
 161
 162 method _visible {} {
 163         grab $w
 164         if {[is_config_true gui.matchtrackingbranch]} {
 165                 $w_rev pick_tracking_branch
 166         }
 167         $w_rev focus_filter
 168 }
 169
 170 method _cancel {} {
 171         wm protocol $w WM_DELETE_WINDOW {}
 172         unlock_index
 173         destroy $w
 174         delete_this
 175 }
 176
 177 }
 178
 179 namespace eval merge {
 180
 181 proc reset_hard {} {
 182         global HEAD commit_type file_states
 183
 184         if {[string match amend* $commit_type]} {
 185                 info_popup {Cannot abort while amending.
 186
 187 You must finish amending this commit.
 188 }
 189                 return
 190         }
 191
 192         if {![lock_index abort]} return
 193
 194         if {[string match *merge* $commit_type]} {
 195                 set op merge
 196         } else {
 197                 set op commit
 198         }
 199
 200         if {[ask_popup "Abort $op?
 201
 202 Aborting the current $op will cause *ALL* uncommitted changes to be lost.
 203
 204 Continue with aborting the current $op?"] eq {yes}} {
 205                 set fd [git_read read-tree --reset -u HEAD]
 206                 fconfigure $fd -blocking 0 -translation binary
 207                 fileevent $fd readable [namespace code [list _reset_wait $fd]]
 208                 ui_status {Aborting... please wait...}
 209         } else {
 210                 unlock_index
 211         }
 212 }
 213
 214 proc _reset_wait {fd} {
 215         global ui_comm
 216
 217         read $fd
 218         if {[eof $fd]} {
 219                 close $fd
 220                 unlock_index
 221
 222                 $ui_comm delete 0.0 end
 223                 $ui_comm edit modified false
 224
 225                 catch {file delete [gitdir MERGE_HEAD]}
 226                 catch {file delete [gitdir rr-cache MERGE_RR]}
 227                 catch {file delete [gitdir SQUASH_MSG]}
 228                 catch {file delete [gitdir MERGE_MSG]}
 229                 catch {file delete [gitdir GITGUI_MSG]}
 230
 231                 rescan {ui_status {Abort completed.  Ready.}}
 232         }
 233 }
 234
 235 }