git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.
  81
  82    --smtp-user    The username for SMTP-AUTH.
  83
  84    --smtp-pass    The password for SMTP-AUTH.
  85
  86    --smtp-ssl     If set, connects to the SMTP server using SSL.
  87
  88    --suppress-from Suppress sending emails to yourself if your address
  89                   appears in a From: line. Defaults to off.
  90
  91    --thread       Specify that the "In-Reply-To:" header should be set on all
  92                   emails. Defaults to on.
  93
  94    --quiet        Make git-send-email less verbose.  One line per email
  95                   should be all that is output.
  96
  97    --dry-run      Do everything except actually send the emails.
  98
  99    --envelope-sender    Specify the envelope sender used to send the emails.
 100
 101 EOT
 102         exit(1);
 103 }
 104
 105 # most mail servers generate the Date: header, but not all...
 106 sub format_2822_time {
 107         my ($time) = @_;
 108         my @localtm = localtime($time);
 109         my @gmttm = gmtime($time);
 110         my $localmin = $localtm[1] + $localtm[2] * 60;
 111         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 112         if ($localtm[0] != $gmttm[0]) {
 113                 die "local zone differs from GMT by a non-minute interval\n";
 114         }
 115         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 116                 $localmin += 1440;
 117         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 118                 $localmin -= 1440;
 119         } elsif ($gmttm[6] != $localtm[6]) {
 120                 die "local time offset greater than or equal to 24 hours\n";
 121         }
 122         my $offset = $localmin - $gmtmin;
 123         my $offhour = $offset / 60;
 124         my $offmin = abs($offset % 60);
 125         if (abs($offhour) >= 24) {
 126                 die ("local time offset greater than or equal to 24 hours\n");
 127         }
 128
 129         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 130                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 131                        $localtm[3],
 132                        qw(Jan Feb Mar Apr May Jun
 133                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 134                        $localtm[5]+1900,
 135                        $localtm[2],
 136                        $localtm[1],
 137                        $localtm[0],
 138                        ($offset >= 0) ? '+' : '-',
 139                        abs($offhour),
 140                        $offmin,
 141                        );
 142 }
 143
 144 my $have_email_valid = eval { require Email::Valid; 1 };
 145 my $smtp;
 146
 147 sub unique_email_list(@);
 148 sub cleanup_compose_files();
 149
 150 # Constants (essentially)
 151 my $compose_filename = ".msg.$$";
 152
 153 # Variables we fill in automatically, or via prompting:
 154 my (@to,@cc,@initial_cc,@bcclist,@xh,
 155         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 156
 157 my $envelope_sender;
 158
 159 # Example reply to:
 160 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 161
 162 my $repo = Git->repository();
 163 my $term = eval {
 164         new Term::ReadLine 'git-send-email';
 165 };
 166 if ($@) {
 167         $term = new FakeTerm "$@: going non-interactive";
 168 }
 169
 170 # Behavior modification variables
 171 my ($quiet, $dry_run) = (0, 0);
 172
 173 # Variables with corresponding config settings
 174 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 175 my ($smtp_server, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 176 my ($identity, $aliasfiletype, @alias_files);
 177
 178 my %config_bool_settings = (
 179     "thread" => [\$thread, 1],
 180     "chainreplyto" => [\$chain_reply_to, 1],
 181     "suppressfrom" => [\$suppress_from, 0],
 182     "signedoffcc" => [\$signed_off_cc, 1],
 183     "smtpssl" => [\$smtp_ssl, 0],
 184 );
 185
 186 my %config_settings = (
 187     "smtpserver" => \$smtp_server,
 188     "smtpuser" => \$smtp_authuser,
 189     "smtppass" => \$smtp_authpass,
 190     "cccmd" => \$cc_cmd,
 191     "aliasfiletype" => \$aliasfiletype,
 192     "bcc" => \@bcclist,
 193     "aliasesfile" => \@alias_files,
 194 );
 195
 196 # Begin by accumulating all the variables (defined above), that we will end up
 197 # needing, first, from the command line:
 198
 199 my $rc = GetOptions("sender|from=s" => \$sender,
 200                     "in-reply-to=s" => \$initial_reply_to,
 201                     "subject=s" => \$initial_subject,
 202                     "to=s" => \@to,
 203                     "cc=s" => \@initial_cc,
 204                     "bcc=s" => \@bcclist,
 205                     "chain-reply-to!" => \$chain_reply_to,
 206                     "smtp-server=s" => \$smtp_server,
 207                     "smtp-user=s" => \$smtp_authuser,
 208                     "smtp-pass=s" => \$smtp_authpass,
 209                     "smtp-ssl!" => \$smtp_ssl,
 210                     "identity=s" => \$identity,
 211                     "compose" => \$compose,
 212                     "quiet" => \$quiet,
 213                     "cc-cmd=s" => \$cc_cmd,
 214                     "suppress-from!" => \$suppress_from,
 215                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 216                     "dry-run" => \$dry_run,
 217                     "envelope-sender=s" => \$envelope_sender,
 218                     "thread!" => \$thread,
 219          );
 220
 221 unless ($rc) {
 222     usage();
 223 }
 224
 225 # Now, let's fill any that aren't set in with defaults:
 226
 227 sub read_config {
 228         my ($prefix) = @_;
 229
 230         foreach my $setting (keys %config_bool_settings) {
 231                 my $target = $config_bool_settings{$setting}->[0];
 232                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 233         }
 234
 235         foreach my $setting (keys %config_settings) {
 236                 my $target = $config_settings{$setting};
 237                 if (ref($target) eq "ARRAY") {
 238                         unless (@$target) {
 239                                 my @values = $repo->config("$prefix.$setting");
 240                                 @$target = @values if (@values && defined $values[0]);
 241                         }
 242                 }
 243                 else {
 244                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 245                 }
 246         }
 247 }
 248
 249 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 250 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 251 read_config("sendemail.$identity") if (defined $identity);
 252 read_config("sendemail");
 253
 254 # fall back on builtin bool defaults
 255 foreach my $setting (values %config_bool_settings) {
 256         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 257 }
 258
 259 my ($repoauthor) = $repo->ident_person('author');
 260 my ($repocommitter) = $repo->ident_person('committer');
 261
 262 # Verify the user input
 263
 264 foreach my $entry (@to) {
 265         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 266 }
 267
 268 foreach my $entry (@initial_cc) {
 269         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 270 }
 271
 272 foreach my $entry (@bcclist) {
 273         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 274 }
 275
 276 my %aliases;
 277 my %parse_alias = (
 278         # multiline formats can be supported in the future
 279         mutt => sub { my $fh = shift; while (<$fh>) {
 280                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 281                         my ($alias, $addr) = ($1, $2);
 282                         $addr =~ s/#.*$//; # mutt allows # comments
 283                          # commas delimit multiple addresses
 284                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 285                 }}},
 286         mailrc => sub { my $fh = shift; while (<$fh>) {
 287                 if (/^alias\s+(\S+)\s+(.*)$/) {
 288                         # spaces delimit multiple addresses
 289                         $aliases{$1} = [ split(/\s+/, $2) ];
 290                 }}},
 291         pine => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^(\S+)\t.*\t(.*)$/) {
 293                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 294                 }}},
 295         gnus => sub { my $fh = shift; while (<$fh>) {
 296                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 297                         $aliases{$1} = [ $2 ];
 298                 }}}
 299 );
 300
 301 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 302         foreach my $file (@alias_files) {
 303                 open my $fh, '<', $file or die "opening $file: $!\n";
 304                 $parse_alias{$aliasfiletype}->($fh);
 305                 close $fh;
 306         }
 307 }
 308
 309 ($sender) = expand_aliases($sender) if defined $sender;
 310
 311 my $prompting = 0;
 312 if (!defined $sender) {
 313         $sender = $repoauthor || $repocommitter;
 314         do {
 315                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 316         } while (!defined $_);
 317
 318         $sender = $_ if ($_);
 319         print "Emails will be sent from: ", $sender, "\n";
 320         $prompting++;
 321 }
 322
 323 if (!@to) {
 324         do {
 325                 $_ = $term->readline("Who should the emails be sent to? ",
 326                                 "");
 327         } while (!defined $_);
 328         my $to = $_;
 329         push @to, split /,/, $to;
 330         $prompting++;
 331 }
 332
 333 sub expand_aliases {
 334         my @cur = @_;
 335         my @last;
 336         do {
 337                 @last = @cur;
 338                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 339         } while (join(',',@cur) ne join(',',@last));
 340         return @cur;
 341 }
 342
 343 @to = expand_aliases(@to);
 344 @to = (map { sanitize_address($_) } @to);
 345 @initial_cc = expand_aliases(@initial_cc);
 346 @bcclist = expand_aliases(@bcclist);
 347
 348 if (!defined $initial_subject && $compose) {
 349         do {
 350                 $_ = $term->readline("What subject should the emails start with? ",
 351                         $initial_subject);
 352         } while (!defined $_);
 353         $initial_subject = $_;
 354         $prompting++;
 355 }
 356
 357 if ($thread && !defined $initial_reply_to && $prompting) {
 358         do {
 359                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 360                         $initial_reply_to);
 361         } while (!defined $_);
 362
 363         $initial_reply_to = $_;
 364         $initial_reply_to =~ s/^\s+<?/</;
 365         $initial_reply_to =~ s/>?\s+$/>/;
 366 }
 367
 368 if (!defined $smtp_server) {
 369         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 370                 if (-x $_) {
 371                         $smtp_server = $_;
 372                         last;
 373                 }
 374         }
 375         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 376 }
 377
 378 if ($compose) {
 379         # Note that this does not need to be secure, but we will make a small
 380         # effort to have it be unique
 381         open(C,">",$compose_filename)
 382                 or die "Failed to open for writing $compose_filename: $!";
 383         print C "From $sender # This line is ignored.\n";
 384         printf C "Subject: %s\n\n", $initial_subject;
 385         printf C <<EOT;
 386 GIT: Please enter your email below.
 387 GIT: Lines beginning in "GIT: " will be removed.
 388 GIT: Consider including an overall diffstat or table of contents
 389 GIT: for the patch you are writing.
 390
 391 EOT
 392         close(C);
 393
 394         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 395         system($editor, $compose_filename);
 396
 397         open(C2,">",$compose_filename . ".final")
 398                 or die "Failed to open $compose_filename.final : " . $!;
 399
 400         open(C,"<",$compose_filename)
 401                 or die "Failed to open $compose_filename : " . $!;
 402
 403         while(<C>) {
 404                 next if m/^GIT: /;
 405                 print C2 $_;
 406         }
 407         close(C);
 408         close(C2);
 409
 410         do {
 411                 $_ = $term->readline("Send this email? (y|n) ");
 412         } while (!defined $_);
 413
 414         if (uc substr($_,0,1) ne 'Y') {
 415                 cleanup_compose_files();
 416                 exit(0);
 417         }
 418
 419         @files = ($compose_filename . ".final");
 420 }
 421
 422
 423 # Now that all the defaults are set, process the rest of the command line
 424 # arguments and collect up the files that need to be processed.
 425 for my $f (@ARGV) {
 426         if (-d $f) {
 427                 opendir(DH,$f)
 428                         or die "Failed to opendir $f: $!";
 429
 430                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 431                                 sort readdir(DH);
 432
 433         } elsif (-f $f) {
 434                 push @files, $f;
 435
 436         } else {
 437                 print STDERR "Skipping $f - not found.\n";
 438         }
 439 }
 440
 441 if (@files) {
 442         unless ($quiet) {
 443                 print $_,"\n" for (@files);
 444         }
 445 } else {
 446         print STDERR "\nNo patch files specified!\n\n";
 447         usage();
 448 }
 449
 450 # Variables we set as part of the loop over files
 451 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 452
 453 sub extract_valid_address {
 454         my $address = shift;
 455         my $local_part_regexp = '[^<>"\s@]+';
 456         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 457
 458         # check for a local address:
 459         return $address if ($address =~ /^($local_part_regexp)$/);
 460
 461         $address =~ s/^\s*<(.*)>\s*$/$1/;
 462         if ($have_email_valid) {
 463                 return scalar Email::Valid->address($address);
 464         } else {
 465                 # less robust/correct than the monster regexp in Email::Valid,
 466                 # but still does a 99% job, and one less dependency
 467                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 468                 return $1;
 469         }
 470 }
 471
 472 # Usually don't need to change anything below here.
 473
 474 # we make a "fake" message id by taking the current number
 475 # of seconds since the beginning of Unix time and tacking on
 476 # a random number to the end, in case we are called quicker than
 477 # 1 second since the last time we were called.
 478
 479 # We'll setup a template for the message id, using the "from" address:
 480
 481 my ($message_id_stamp, $message_id_serial);
 482 sub make_message_id
 483 {
 484         my $uniq;
 485         if (!defined $message_id_stamp) {
 486                 $message_id_stamp = sprintf("%s-%s", time, $$);
 487                 $message_id_serial = 0;
 488         }
 489         $message_id_serial++;
 490         $uniq = "$message_id_stamp-$message_id_serial";
 491
 492         my $du_part;
 493         for ($sender, $repocommitter, $repoauthor) {
 494                 $du_part = extract_valid_address(sanitize_address($_));
 495                 last if (defined $du_part and $du_part ne '');
 496         }
 497         if (not defined $du_part or $du_part eq '') {
 498                 use Sys::Hostname qw();
 499                 $du_part = 'user@' . Sys::Hostname::hostname();
 500         }
 501         my $message_id_template = "<%s-git-send-email-%s>";
 502         $message_id = sprintf($message_id_template, $uniq, $du_part);
 503         #print "new message id = $message_id\n"; # Was useful for debugging
 504 }
 505
 506
 507
 508 $time = time - scalar $#files;
 509
 510 sub unquote_rfc2047 {
 511         local ($_) = @_;
 512         if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
 513                 s/_/ /g;
 514                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 515         }
 516         return "$_";
 517 }
 518
 519 # use the simplest quoting being able to handle the recipient
 520 sub sanitize_address
 521 {
 522         my ($recipient) = @_;
 523         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 524
 525         if (not $recipient_name) {
 526                 return "$recipient";
 527         }
 528
 529         # if recipient_name is already quoted, do nothing
 530         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 531                 return $recipient;
 532         }
 533
 534         # rfc2047 is needed if a non-ascii char is included
 535         if ($recipient_name =~ /[^[:ascii:]]/) {
 536                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 537                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 538         }
 539
 540         # double quotes are needed if specials or CTLs are included
 541         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 542                 $recipient_name =~ s/(["\\\r])/\\$1/;
 543                 $recipient_name = "\"$recipient_name\"";
 544         }
 545
 546         return "$recipient_name $recipient_addr";
 547
 548 }
 549
 550 sub send_message
 551 {
 552         my @recipients = unique_email_list(@to);
 553         @cc = (map { sanitize_address($_) } @cc);
 554         my $to = join (",\n\t", @recipients);
 555         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 556         @recipients = (map { extract_valid_address($_) } @recipients);
 557         my $date = format_2822_time($time++);
 558         my $gitversion = '@@GIT_VERSION@@';
 559         if ($gitversion =~ m/..GIT_VERSION../) {
 560             $gitversion = Git::version();
 561         }
 562
 563         my $cc = join(", ", unique_email_list(@cc));
 564         my $ccline = "";
 565         if ($cc ne '') {
 566                 $ccline = "\nCc: $cc";
 567         }
 568         my $sanitized_sender = sanitize_address($sender);
 569         make_message_id();
 570
 571         my $header = "From: $sanitized_sender
 572 To: $to${ccline}
 573 Subject: $subject
 574 Date: $date
 575 Message-Id: $message_id
 576 X-Mailer: git-send-email $gitversion
 577 ";
 578         if ($thread && $reply_to) {
 579
 580                 $header .= "In-Reply-To: $reply_to\n";
 581                 $header .= "References: $references\n";
 582         }
 583         if (@xh) {
 584                 $header .= join("\n", @xh) . "\n";
 585         }
 586
 587         my @sendmail_parameters = ('-i', @recipients);
 588         my $raw_from = $sanitized_sender;
 589         $raw_from = $envelope_sender if (defined $envelope_sender);
 590         $raw_from = extract_valid_address($raw_from);
 591         unshift (@sendmail_parameters,
 592                         '-f', $raw_from) if(defined $envelope_sender);
 593
 594         if ($dry_run) {
 595                 # We don't want to send the email.
 596         } elsif ($smtp_server =~ m#^/#) {
 597                 my $pid = open my $sm, '|-';
 598                 defined $pid or die $!;
 599                 if (!$pid) {
 600                         exec($smtp_server, @sendmail_parameters) or die $!;
 601                 }
 602                 print $sm "$header\n$message";
 603                 close $sm or die $?;
 604         } else {
 605                 if ($smtp_ssl) {
 606                         require Net::SMTP::SSL;
 607                         $smtp ||= Net::SMTP::SSL->new( $smtp_server, Port => 465 );
 608                 }
 609                 else {
 610                         require Net::SMTP;
 611                         $smtp ||= Net::SMTP->new( $smtp_server );
 612                 }
 613                 $smtp->auth( $smtp_authuser, $smtp_authpass )
 614                         or die $smtp->message if (defined $smtp_authuser);
 615                 $smtp->mail( $raw_from ) or die $smtp->message;
 616                 $smtp->to( @recipients ) or die $smtp->message;
 617                 $smtp->data or die $smtp->message;
 618                 $smtp->datasend("$header\n$message") or die $smtp->message;
 619                 $smtp->dataend() or die $smtp->message;
 620                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 621         }
 622         if ($quiet) {
 623                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 624         } else {
 625                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 626                 if ($smtp_server !~ m#^/#) {
 627                         print "Server: $smtp_server\n";
 628                         print "MAIL FROM:<$raw_from>\n";
 629                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 630                 } else {
 631                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 632                 }
 633                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 634                 if ($smtp) {
 635                         print "Result: ", $smtp->code, ' ',
 636                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 637                 } else {
 638                         print "Result: OK\n";
 639                 }
 640         }
 641 }
 642
 643 $reply_to = $initial_reply_to;
 644 $references = $initial_reply_to || '';
 645 $subject = $initial_subject;
 646
 647 foreach my $t (@files) {
 648         open(F,"<",$t) or die "can't open file $t";
 649
 650         my $author = undef;
 651         @cc = @initial_cc;
 652         @xh = ();
 653         my $input_format = undef;
 654         my $header_done = 0;
 655         $message = "";
 656         while(<F>) {
 657                 if (!$header_done) {
 658                         if (/^From /) {
 659                                 $input_format = 'mbox';
 660                                 next;
 661                         }
 662                         chomp;
 663                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 664                                 $input_format = 'mbox';
 665                         }
 666
 667                         if (defined $input_format && $input_format eq 'mbox') {
 668                                 if (/^Subject:\s+(.*)$/) {
 669                                         $subject = $1;
 670
 671                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 672                                         if (unquote_rfc2047($2) eq $sender) {
 673                                                 next if ($suppress_from);
 674                                         }
 675                                         elsif ($1 eq 'From') {
 676                                                 $author = unquote_rfc2047($2);
 677                                         }
 678                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 679                                                 $2, $_) unless $quiet;
 680                                         push @cc, $2;
 681                                 }
 682                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 683                                         push @xh, $_;
 684                                 }
 685
 686                         } else {
 687                                 # In the traditional
 688                                 # "send lots of email" format,
 689                                 # line 1 = cc
 690                                 # line 2 = subject
 691                                 # So let's support that, too.
 692                                 $input_format = 'lots';
 693                                 if (@cc == 0) {
 694                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 695                                                 $_, $_) unless $quiet;
 696
 697                                         push @cc, $_;
 698
 699                                 } elsif (!defined $subject) {
 700                                         $subject = $_;
 701                                 }
 702                         }
 703
 704                         # A whitespace line will terminate the headers
 705                         if (m/^\s*$/) {
 706                                 $header_done = 1;
 707                         }
 708                 } else {
 709                         $message .=  $_;
 710                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 711                                 my $c = $2;
 712                                 chomp $c;
 713                                 push @cc, $c;
 714                                 printf("(sob) Adding cc: %s from line '%s'\n",
 715                                         $c, $_) unless $quiet;
 716                         }
 717                 }
 718         }
 719         close F;
 720
 721         if (defined $cc_cmd) {
 722                 open(F, "$cc_cmd $t |")
 723                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 724                 while(<F>) {
 725                         my $c = $_;
 726                         $c =~ s/^\s*//g;
 727                         $c =~ s/\n$//g;
 728                         push @cc, $c;
 729                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 730                                 $c, $cc_cmd) unless $quiet;
 731                 }
 732                 close F
 733                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 734         }
 735
 736         if (defined $author) {
 737                 $message = "From: $author\n\n$message";
 738         }
 739
 740         send_message();
 741
 742         # set up for the next message
 743         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 744                 $reply_to = $message_id;
 745                 if (length $references > 0) {
 746                         $references .= "\n $message_id";
 747                 } else {
 748                         $references = "$message_id";
 749                 }
 750         }
 751 }
 752
 753 if ($compose) {
 754         cleanup_compose_files();
 755 }
 756
 757 sub cleanup_compose_files() {
 758         unlink($compose_filename, $compose_filename . ".final");
 759
 760 }
 761
 762 $smtp->quit if $smtp;
 763
 764 sub unique_email_list(@) {
 765         my %seen;
 766         my @emails;
 767
 768         foreach my $entry (@_) {
 769                 if (my $clean = extract_valid_address($entry)) {
 770                         $seen{$clean} ||= 0;
 771                         next if $seen{$clean}++;
 772                         push @emails, $entry;
 773                 } else {
 774                         print STDERR "W: unable to extract a valid address",
 775                                         " from: $entry\n";
 776                 }
 777         }
 778         return @emails;
 779 }