git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --[no-]to               <str>  * Email To:
  51     --[no-]cc               <str>  * Email Cc:
  52     --[no-]bcc              <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  58
  59   Sending:
  60     --envelope-sender       <str>  * Email envelope sender.
  61     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  62                                      is optional. Default 'localhost'.
  63     --smtp-server-port      <int>  * Outgoing SMTP server port.
  64     --smtp-user             <str>  * Username for SMTP-AUTH.
  65     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  66     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  67     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  68     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  69     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  70
  71   Automating:
  72     --identity              <str>  * Use the sendemail.<id> options.
  73     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  74     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  75     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  76     --[no-]suppress-from           * Send to self. Default off.
  77     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  78     --[no-]thread                  * Use In-Reply-To: field. Default on.
  79
  80   Administering:
  81     --confirm               <str>  * Confirm recipients before sending;
  82                                      auto, cc, compose, always, or never.
  83     --quiet                        * Output one line of info per email.
  84     --dry-run                      * Don't actually send the emails.
  85     --[no-]validate                * Perform patch sanity checks. Default on.
  86     --[no-]format-patch            * understand any non optional arguments as
  87                                      `git format-patch` ones.
  88     --force                        * Send even if safety checks would prevent it.
  89
  90 EOT
  91         exit(1);
  92 }
  93
  94 # most mail servers generate the Date: header, but not all...
  95 sub format_2822_time {
  96         my ($time) = @_;
  97         my @localtm = localtime($time);
  98         my @gmttm = gmtime($time);
  99         my $localmin = $localtm[1] + $localtm[2] * 60;
 100         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 101         if ($localtm[0] != $gmttm[0]) {
 102                 die "local zone differs from GMT by a non-minute interval\n";
 103         }
 104         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 105                 $localmin += 1440;
 106         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 107                 $localmin -= 1440;
 108         } elsif ($gmttm[6] != $localtm[6]) {
 109                 die "local time offset greater than or equal to 24 hours\n";
 110         }
 111         my $offset = $localmin - $gmtmin;
 112         my $offhour = $offset / 60;
 113         my $offmin = abs($offset % 60);
 114         if (abs($offhour) >= 24) {
 115                 die ("local time offset greater than or equal to 24 hours\n");
 116         }
 117
 118         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 119                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 120                        $localtm[3],
 121                        qw(Jan Feb Mar Apr May Jun
 122                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 123                        $localtm[5]+1900,
 124                        $localtm[2],
 125                        $localtm[1],
 126                        $localtm[0],
 127                        ($offset >= 0) ? '+' : '-',
 128                        abs($offhour),
 129                        $offmin,
 130                        );
 131 }
 132
 133 my $have_email_valid = eval { require Email::Valid; 1 };
 134 my $have_mail_address = eval { require Mail::Address; 1 };
 135 my $smtp;
 136 my $auth;
 137
 138 sub unique_email_list(@);
 139 sub cleanup_compose_files();
 140
 141 # Variables we fill in automatically, or via prompting:
 142 my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 143         $initial_reply_to,$initial_subject,@files,
 144         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 145
 146 my $envelope_sender;
 147
 148 # Example reply to:
 149 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 150
 151 my $repo = eval { Git->repository() };
 152 my @repo = $repo ? ($repo) : ();
 153 my $term = eval {
 154         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 155                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 156                 : new Term::ReadLine 'git-send-email';
 157 };
 158 if ($@) {
 159         $term = new FakeTerm "$@: going non-interactive";
 160 }
 161
 162 # Behavior modification variables
 163 my ($quiet, $dry_run) = (0, 0);
 164 my $format_patch;
 165 my $compose_filename;
 166 my $force = 0;
 167
 168 # Handle interactive edition of files.
 169 my $multiedit;
 170 my $editor;
 171
 172 sub do_edit {
 173         if (!defined($editor)) {
 174                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 175         }
 176         if (defined($multiedit) && !$multiedit) {
 177                 map {
 178                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 179                         if (($? & 127) || ($? >> 8)) {
 180                                 die("the editor exited uncleanly, aborting everything");
 181                         }
 182                 } @_;
 183         } else {
 184                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 185                 if (($? & 127) || ($? >> 8)) {
 186                         die("the editor exited uncleanly, aborting everything");
 187                 }
 188         }
 189 }
 190
 191 # Variables with corresponding config settings
 192 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 193 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 194 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts, $smtp_domain);
 195 my ($validate, $confirm);
 196 my (@suppress_cc);
 197 my ($auto_8bit_encoding);
 198
 199 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 200
 201 my $not_set_by_user = "true but not set by the user";
 202
 203 my %config_bool_settings = (
 204     "thread" => [\$thread, 1],
 205     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 206     "suppressfrom" => [\$suppress_from, undef],
 207     "signedoffbycc" => [\$signed_off_by_cc, undef],
 208     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 209     "validate" => [\$validate, 1],
 210 );
 211
 212 my %config_settings = (
 213     "smtpserver" => \$smtp_server,
 214     "smtpserverport" => \$smtp_server_port,
 215     "smtpuser" => \$smtp_authuser,
 216     "smtppass" => \$smtp_authpass,
 217         "smtpdomain" => \$smtp_domain,
 218     "to" => \@to,
 219     "cc" => \@initial_cc,
 220     "cccmd" => \$cc_cmd,
 221     "aliasfiletype" => \$aliasfiletype,
 222     "bcc" => \@bcclist,
 223     "aliasesfile" => \@alias_files,
 224     "suppresscc" => \@suppress_cc,
 225     "envelopesender" => \$envelope_sender,
 226     "multiedit" => \$multiedit,
 227     "confirm"   => \$confirm,
 228     "from" => \$sender,
 229     "assume8bitencoding" => \$auto_8bit_encoding,
 230 );
 231
 232 # Help users prepare for 1.7.0
 233 sub chain_reply_to {
 234         if (defined $chain_reply_to &&
 235             $chain_reply_to eq $not_set_by_user) {
 236                 print STDERR
 237                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 238                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 239                     "you want to keep --chain-reply-to as your default.\n";
 240                 $chain_reply_to = 0;
 241         }
 242         return $chain_reply_to;
 243 }
 244
 245 # Handle Uncouth Termination
 246 sub signal_handler {
 247
 248         # Make text normal
 249         print color("reset"), "\n";
 250
 251         # SMTP password masked
 252         system "stty echo";
 253
 254         # tmp files from --compose
 255         if (defined $compose_filename) {
 256                 if (-e $compose_filename) {
 257                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 258                 }
 259                 if (-e ($compose_filename . ".final")) {
 260                         print "'$compose_filename.final' contains the composed email.\n"
 261                 }
 262         }
 263
 264         exit;
 265 };
 266
 267 $SIG{TERM} = \&signal_handler;
 268 $SIG{INT}  = \&signal_handler;
 269
 270 # Begin by accumulating all the variables (defined above), that we will end up
 271 # needing, first, from the command line:
 272
 273 my $rc = GetOptions("sender|from=s" => \$sender,
 274                     "in-reply-to=s" => \$initial_reply_to,
 275                     "subject=s" => \$initial_subject,
 276                     "to=s" => \@to,
 277                     "no-to" => \$no_to,
 278                     "cc=s" => \@initial_cc,
 279                     "no-cc" => \$no_cc,
 280                     "bcc=s" => \@bcclist,
 281                     "no-bcc" => \$no_bcc,
 282                     "chain-reply-to!" => \$chain_reply_to,
 283                     "smtp-server=s" => \$smtp_server,
 284                     "smtp-server-port=s" => \$smtp_server_port,
 285                     "smtp-user=s" => \$smtp_authuser,
 286                     "smtp-pass:s" => \$smtp_authpass,
 287                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 288                     "smtp-encryption=s" => \$smtp_encryption,
 289                     "smtp-debug:i" => \$debug_net_smtp,
 290                     "smtp-domain:s" => \$smtp_domain,
 291                     "identity=s" => \$identity,
 292                     "annotate" => \$annotate,
 293                     "compose" => \$compose,
 294                     "quiet" => \$quiet,
 295                     "cc-cmd=s" => \$cc_cmd,
 296                     "suppress-from!" => \$suppress_from,
 297                     "suppress-cc=s" => \@suppress_cc,
 298                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 299                     "confirm=s" => \$confirm,
 300                     "dry-run" => \$dry_run,
 301                     "envelope-sender=s" => \$envelope_sender,
 302                     "thread!" => \$thread,
 303                     "validate!" => \$validate,
 304                     "format-patch!" => \$format_patch,
 305                     "8bit-encoding=s" => \$auto_8bit_encoding,
 306                     "force" => \$force,
 307          );
 308
 309 unless ($rc) {
 310     usage();
 311 }
 312
 313 die "Cannot run git format-patch from outside a repository\n"
 314         if $format_patch and not $repo;
 315
 316 # Now, let's fill any that aren't set in with defaults:
 317
 318 sub read_config {
 319         my ($prefix) = @_;
 320
 321         foreach my $setting (keys %config_bool_settings) {
 322                 my $target = $config_bool_settings{$setting}->[0];
 323                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 324         }
 325
 326         foreach my $setting (keys %config_settings) {
 327                 my $target = $config_settings{$setting};
 328                 next if $setting eq "to" and defined $no_to;
 329                 next if $setting eq "cc" and defined $no_cc;
 330                 next if $setting eq "bcc" and defined $no_bcc;
 331                 if (ref($target) eq "ARRAY") {
 332                         unless (@$target) {
 333                                 my @values = Git::config(@repo, "$prefix.$setting");
 334                                 @$target = @values if (@values && defined $values[0]);
 335                         }
 336                 }
 337                 else {
 338                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 339                 }
 340         }
 341
 342         if (!defined $smtp_encryption) {
 343                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 344                 if (defined $enc) {
 345                         $smtp_encryption = $enc;
 346                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 347                         $smtp_encryption = 'ssl';
 348                 }
 349         }
 350 }
 351
 352 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 353 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 354 read_config("sendemail.$identity") if (defined $identity);
 355 read_config("sendemail");
 356
 357 # fall back on builtin bool defaults
 358 foreach my $setting (values %config_bool_settings) {
 359         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 360 }
 361
 362 # 'default' encryption is none -- this only prevents a warning
 363 $smtp_encryption = '' unless (defined $smtp_encryption);
 364
 365 # Set CC suppressions
 366 my(%suppress_cc);
 367 if (@suppress_cc) {
 368         foreach my $entry (@suppress_cc) {
 369                 die "Unknown --suppress-cc field: '$entry'\n"
 370                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 371                 $suppress_cc{$entry} = 1;
 372         }
 373 }
 374
 375 if ($suppress_cc{'all'}) {
 376         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 377                 $suppress_cc{$entry} = 1;
 378         }
 379         delete $suppress_cc{'all'};
 380 }
 381
 382 # If explicit old-style ones are specified, they trump --suppress-cc.
 383 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 384 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 385
 386 if ($suppress_cc{'body'}) {
 387         foreach my $entry (qw (sob bodycc)) {
 388                 $suppress_cc{$entry} = 1;
 389         }
 390         delete $suppress_cc{'body'};
 391 }
 392
 393 # Set confirm's default value
 394 my $confirm_unconfigured = !defined $confirm;
 395 if ($confirm_unconfigured) {
 396         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 397 };
 398 die "Unknown --confirm setting: '$confirm'\n"
 399         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 400
 401 # Debugging, print out the suppressions.
 402 if (0) {
 403         print "suppressions:\n";
 404         foreach my $entry (keys %suppress_cc) {
 405                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 406         }
 407 }
 408
 409 my ($repoauthor, $repocommitter);
 410 ($repoauthor) = Git::ident_person(@repo, 'author');
 411 ($repocommitter) = Git::ident_person(@repo, 'committer');
 412
 413 # Verify the user input
 414
 415 foreach my $entry (@to) {
 416         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 417 }
 418
 419 foreach my $entry (@initial_cc) {
 420         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 421 }
 422
 423 foreach my $entry (@bcclist) {
 424         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 425 }
 426
 427 sub parse_address_line {
 428         if ($have_mail_address) {
 429                 return map { $_->format } Mail::Address->parse($_[0]);
 430         } else {
 431                 return split_addrs($_[0]);
 432         }
 433 }
 434
 435 sub split_addrs {
 436         return quotewords('\s*,\s*', 1, @_);
 437 }
 438
 439 my %aliases;
 440 my %parse_alias = (
 441         # multiline formats can be supported in the future
 442         mutt => sub { my $fh = shift; while (<$fh>) {
 443                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 444                         my ($alias, $addr) = ($1, $2);
 445                         $addr =~ s/#.*$//; # mutt allows # comments
 446                          # commas delimit multiple addresses
 447                         $aliases{$alias} = [ split_addrs($addr) ];
 448                 }}},
 449         mailrc => sub { my $fh = shift; while (<$fh>) {
 450                 if (/^alias\s+(\S+)\s+(.*)$/) {
 451                         # spaces delimit multiple addresses
 452                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 453                 }}},
 454         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 455                 for (my $x = ''; defined($x); $x = $_) {
 456                         chomp $x;
 457                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 458                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 459                         $aliases{$1} = [ split_addrs($2) ];
 460                 }},
 461         elm => sub  { my $fh = shift;
 462                       while (<$fh>) {
 463                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 464                               my ($alias, $addr) = ($1, $2);
 465                                $aliases{$alias} = [ split_addrs($addr) ];
 466                           }
 467                       } },
 468
 469         gnus => sub { my $fh = shift; while (<$fh>) {
 470                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 471                         $aliases{$1} = [ $2 ];
 472                 }}}
 473 );
 474
 475 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 476         foreach my $file (@alias_files) {
 477                 open my $fh, '<', $file or die "opening $file: $!\n";
 478                 $parse_alias{$aliasfiletype}->($fh);
 479                 close $fh;
 480         }
 481 }
 482
 483 ($sender) = expand_aliases($sender) if defined $sender;
 484
 485 # returns 1 if the conflict must be solved using it as a format-patch argument
 486 sub check_file_rev_conflict($) {
 487         return unless $repo;
 488         my $f = shift;
 489         try {
 490                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 491                 if (defined($format_patch)) {
 492                         return $format_patch;
 493                 }
 494                 die(<<EOF);
 495 File '$f' exists but it could also be the range of commits
 496 to produce patches for.  Please disambiguate by...
 497
 498     * Saying "./$f" if you mean a file; or
 499     * Giving --format-patch option if you mean a range.
 500 EOF
 501         } catch Git::Error::Command with {
 502                 return 0;
 503         }
 504 }
 505
 506 # Now that all the defaults are set, process the rest of the command line
 507 # arguments and collect up the files that need to be processed.
 508 my @rev_list_opts;
 509 while (defined(my $f = shift @ARGV)) {
 510         if ($f eq "--") {
 511                 push @rev_list_opts, "--", @ARGV;
 512                 @ARGV = ();
 513         } elsif (-d $f and !check_file_rev_conflict($f)) {
 514                 opendir(DH,$f)
 515                         or die "Failed to opendir $f: $!";
 516
 517                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 518                                 sort readdir(DH);
 519                 closedir(DH);
 520         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 521                 push @files, $f;
 522         } else {
 523                 push @rev_list_opts, $f;
 524         }
 525 }
 526
 527 if (@rev_list_opts) {
 528         die "Cannot run git format-patch from outside a repository\n"
 529                 unless $repo;
 530         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 531 }
 532
 533 if ($validate) {
 534         foreach my $f (@files) {
 535                 unless (-p $f) {
 536                         my $error = validate_patch($f);
 537                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 538                 }
 539         }
 540 }
 541
 542 if (@files) {
 543         unless ($quiet) {
 544                 print $_,"\n" for (@files);
 545         }
 546 } else {
 547         print STDERR "\nNo patch files specified!\n\n";
 548         usage();
 549 }
 550
 551 sub get_patch_subject($) {
 552         my $fn = shift;
 553         open (my $fh, '<', $fn);
 554         while (my $line = <$fh>) {
 555                 next unless ($line =~ /^Subject: (.*)$/);
 556                 close $fh;
 557                 return "GIT: $1\n";
 558         }
 559         close $fh;
 560         die "No subject line in $fn ?";
 561 }
 562
 563 if ($compose) {
 564         # Note that this does not need to be secure, but we will make a small
 565         # effort to have it be unique
 566         $compose_filename = ($repo ?
 567                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 568                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 569         open(C,">",$compose_filename)
 570                 or die "Failed to open for writing $compose_filename: $!";
 571
 572
 573         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 574         my $tpl_subject = $initial_subject || '';
 575         my $tpl_reply_to = $initial_reply_to || '';
 576
 577         print C <<EOT;
 578 From $tpl_sender # This line is ignored.
 579 GIT: Lines beginning in "GIT:" will be removed.
 580 GIT: Consider including an overall diffstat or table of contents
 581 GIT: for the patch you are writing.
 582 GIT:
 583 GIT: Clear the body content if you don't wish to send a summary.
 584 From: $tpl_sender
 585 Subject: $tpl_subject
 586 In-Reply-To: $tpl_reply_to
 587
 588 EOT
 589         for my $f (@files) {
 590                 print C get_patch_subject($f);
 591         }
 592         close(C);
 593
 594         if ($annotate) {
 595                 do_edit($compose_filename, @files);
 596         } else {
 597                 do_edit($compose_filename);
 598         }
 599
 600         open(C2,">",$compose_filename . ".final")
 601                 or die "Failed to open $compose_filename.final : " . $!;
 602
 603         open(C,"<",$compose_filename)
 604                 or die "Failed to open $compose_filename : " . $!;
 605
 606         my $need_8bit_cte = file_has_nonascii($compose_filename);
 607         my $in_body = 0;
 608         my $summary_empty = 1;
 609         while(<C>) {
 610                 next if m/^GIT:/;
 611                 if ($in_body) {
 612                         $summary_empty = 0 unless (/^\n$/);
 613                 } elsif (/^\n$/) {
 614                         $in_body = 1;
 615                         if ($need_8bit_cte) {
 616                                 print C2 "MIME-Version: 1.0\n",
 617                                          "Content-Type: text/plain; ",
 618                                            "charset=UTF-8\n",
 619                                          "Content-Transfer-Encoding: 8bit\n";
 620                         }
 621                 } elsif (/^MIME-Version:/i) {
 622                         $need_8bit_cte = 0;
 623                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 624                         $initial_subject = $1;
 625                         my $subject = $initial_subject;
 626                         $_ = "Subject: " .
 627                                 ($subject =~ /[^[:ascii:]]/ ?
 628                                  quote_rfc2047($subject) :
 629                                  $subject) .
 630                                 "\n";
 631                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 632                         $initial_reply_to = $1;
 633                         next;
 634                 } elsif (/^From:\s*(.+)\s*$/i) {
 635                         $sender = $1;
 636                         next;
 637                 } elsif (/^(?:To|Cc|Bcc):/i) {
 638                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 639                         next;
 640                 }
 641                 print C2 $_;
 642         }
 643         close(C);
 644         close(C2);
 645
 646         if ($summary_empty) {
 647                 print "Summary email is empty, skipping it\n";
 648                 $compose = -1;
 649         }
 650 } elsif ($annotate) {
 651         do_edit(@files);
 652 }
 653
 654 sub ask {
 655         my ($prompt, %arg) = @_;
 656         my $valid_re = $arg{valid_re};
 657         my $default = $arg{default};
 658         my $resp;
 659         my $i = 0;
 660         return defined $default ? $default : undef
 661                 unless defined $term->IN and defined fileno($term->IN) and
 662                        defined $term->OUT and defined fileno($term->OUT);
 663         while ($i++ < 10) {
 664                 $resp = $term->readline($prompt);
 665                 if (!defined $resp) { # EOF
 666                         print "\n";
 667                         return defined $default ? $default : undef;
 668                 }
 669                 if ($resp eq '' and defined $default) {
 670                         return $default;
 671                 }
 672                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 673                         return $resp;
 674                 }
 675         }
 676         return undef;
 677 }
 678
 679 my %broken_encoding;
 680
 681 sub file_declares_8bit_cte($) {
 682         my $fn = shift;
 683         open (my $fh, '<', $fn);
 684         while (my $line = <$fh>) {
 685                 last if ($line =~ /^$/);
 686                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 687         }
 688         close $fh;
 689         return 0;
 690 }
 691
 692 foreach my $f (@files) {
 693         next unless (body_or_subject_has_nonascii($f)
 694                      && !file_declares_8bit_cte($f));
 695         $broken_encoding{$f} = 1;
 696 }
 697
 698 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 699         print "The following files are 8bit, but do not declare " .
 700                 "a Content-Transfer-Encoding.\n";
 701         foreach my $f (sort keys %broken_encoding) {
 702                 print "    $f\n";
 703         }
 704         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 705                                   default => "UTF-8");
 706 }
 707
 708 if (!$force) {
 709         for my $f (@files) {
 710                 if (get_patch_subject($f) =~ /\*\*\* SUBJECT HERE \*\*\*/) {
 711                         die "Refusing to send because the patch\n\t$f\n"
 712                                 . "has the template subject '*** SUBJECT HERE ***'. "
 713                                 . "Pass --force if you really want to send.\n";
 714                 }
 715         }
 716 }
 717
 718 my $prompting = 0;
 719 if (!defined $sender) {
 720         $sender = $repoauthor || $repocommitter || '';
 721         $sender = ask("Who should the emails appear to be from? [$sender] ",
 722                       default => $sender);
 723         print "Emails will be sent from: ", $sender, "\n";
 724         $prompting++;
 725 }
 726
 727 if (!@to) {
 728         my $to = ask("Who should the emails be sent to? ");
 729         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 730         $prompting++;
 731 }
 732
 733 sub expand_aliases {
 734         return map { expand_one_alias($_) } @_;
 735 }
 736
 737 my %EXPANDED_ALIASES;
 738 sub expand_one_alias {
 739         my $alias = shift;
 740         if ($EXPANDED_ALIASES{$alias}) {
 741                 die "fatal: alias '$alias' expands to itself\n";
 742         }
 743         local $EXPANDED_ALIASES{$alias} = 1;
 744         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 745 }
 746
 747 @to = expand_aliases(@to);
 748 @to = (map { sanitize_address($_) } @to);
 749 @initial_cc = expand_aliases(@initial_cc);
 750 @bcclist = expand_aliases(@bcclist);
 751
 752 if ($thread && !defined $initial_reply_to && $prompting) {
 753         $initial_reply_to = ask(
 754                 "Message-ID to be used as In-Reply-To for the first email? ");
 755 }
 756 if (defined $initial_reply_to) {
 757         $initial_reply_to =~ s/^\s*<?//;
 758         $initial_reply_to =~ s/>?\s*$//;
 759         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 760 }
 761
 762 if (!defined $smtp_server) {
 763         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 764                 if (-x $_) {
 765                         $smtp_server = $_;
 766                         last;
 767                 }
 768         }
 769         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 770 }
 771
 772 if ($compose && $compose > 0) {
 773         @files = ($compose_filename . ".final", @files);
 774 }
 775
 776 # Variables we set as part of the loop over files
 777 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 778         $needs_confirm, $message_num, $ask_default);
 779
 780 sub extract_valid_address {
 781         my $address = shift;
 782         my $local_part_regexp = '[^<>"\s@]+';
 783         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 784
 785         # check for a local address:
 786         return $address if ($address =~ /^($local_part_regexp)$/);
 787
 788         $address =~ s/^\s*<(.*)>\s*$/$1/;
 789         if ($have_email_valid) {
 790                 return scalar Email::Valid->address($address);
 791         } else {
 792                 # less robust/correct than the monster regexp in Email::Valid,
 793                 # but still does a 99% job, and one less dependency
 794                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 795                 return $1;
 796         }
 797 }
 798
 799 # Usually don't need to change anything below here.
 800
 801 # we make a "fake" message id by taking the current number
 802 # of seconds since the beginning of Unix time and tacking on
 803 # a random number to the end, in case we are called quicker than
 804 # 1 second since the last time we were called.
 805
 806 # We'll setup a template for the message id, using the "from" address:
 807
 808 my ($message_id_stamp, $message_id_serial);
 809 sub make_message_id {
 810         my $uniq;
 811         if (!defined $message_id_stamp) {
 812                 $message_id_stamp = sprintf("%s-%s", time, $$);
 813                 $message_id_serial = 0;
 814         }
 815         $message_id_serial++;
 816         $uniq = "$message_id_stamp-$message_id_serial";
 817
 818         my $du_part;
 819         for ($sender, $repocommitter, $repoauthor) {
 820                 $du_part = extract_valid_address(sanitize_address($_));
 821                 last if (defined $du_part and $du_part ne '');
 822         }
 823         if (not defined $du_part or $du_part eq '') {
 824                 use Sys::Hostname qw();
 825                 $du_part = 'user@' . Sys::Hostname::hostname();
 826         }
 827         my $message_id_template = "<%s-git-send-email-%s>";
 828         $message_id = sprintf($message_id_template, $uniq, $du_part);
 829         #print "new message id = $message_id\n"; # Was useful for debugging
 830 }
 831
 832
 833
 834 $time = time - scalar $#files;
 835
 836 sub unquote_rfc2047 {
 837         local ($_) = @_;
 838         my $encoding;
 839         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 840                 $encoding = $1;
 841                 s/_/ /g;
 842                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 843         }
 844         return wantarray ? ($_, $encoding) : $_;
 845 }
 846
 847 sub quote_rfc2047 {
 848         local $_ = shift;
 849         my $encoding = shift || 'UTF-8';
 850         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 851         s/(.*)/=\?$encoding\?q\?$1\?=/;
 852         return $_;
 853 }
 854
 855 sub is_rfc2047_quoted {
 856         my $s = shift;
 857         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 858         my $encoded_text = '[!->@-~]+';
 859         length($s) <= 75 &&
 860         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 861 }
 862
 863 # use the simplest quoting being able to handle the recipient
 864 sub sanitize_address {
 865         my ($recipient) = @_;
 866         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 867
 868         if (not $recipient_name) {
 869                 return "$recipient";
 870         }
 871
 872         # if recipient_name is already quoted, do nothing
 873         if (is_rfc2047_quoted($recipient_name)) {
 874                 return $recipient;
 875         }
 876
 877         # rfc2047 is needed if a non-ascii char is included
 878         if ($recipient_name =~ /[^[:ascii:]]/) {
 879                 $recipient_name =~ s/^"(.*)"$/$1/;
 880                 $recipient_name = quote_rfc2047($recipient_name);
 881         }
 882
 883         # double quotes are needed if specials or CTLs are included
 884         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 885                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 886                 $recipient_name = "\"$recipient_name\"";
 887         }
 888
 889         return "$recipient_name $recipient_addr";
 890
 891 }
 892
 893 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 894 #
 895 # Tightly configured MTAa require that a caller sends a real DNS
 896 # domain name that corresponds the IP address in the HELO/EHLO
 897 # handshake. This is used to verify the connection and prevent
 898 # spammers from trying to hide their identity. If the DNS and IP don't
 899 # match, the receiveing MTA may deny the connection.
 900 #
 901 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 902 #
 903 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 904 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 905 #
 906 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 907 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 908
 909 sub valid_fqdn {
 910         my $domain = shift;
 911         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 912 }
 913
 914 sub maildomain_net {
 915         my $maildomain;
 916
 917         if (eval { require Net::Domain; 1 }) {
 918                 my $domain = Net::Domain::domainname();
 919                 $maildomain = $domain if valid_fqdn($domain);
 920         }
 921
 922         return $maildomain;
 923 }
 924
 925 sub maildomain_mta {
 926         my $maildomain;
 927
 928         if (eval { require Net::SMTP; 1 }) {
 929                 for my $host (qw(mailhost localhost)) {
 930                         my $smtp = Net::SMTP->new($host);
 931                         if (defined $smtp) {
 932                                 my $domain = $smtp->domain;
 933                                 $smtp->quit;
 934
 935                                 $maildomain = $domain if valid_fqdn($domain);
 936
 937                                 last if $maildomain;
 938                         }
 939                 }
 940         }
 941
 942         return $maildomain;
 943 }
 944
 945 sub maildomain {
 946         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 947 }
 948
 949 # Returns 1 if the message was sent, and 0 otherwise.
 950 # In actuality, the whole program dies when there
 951 # is an error sending a message.
 952
 953 sub send_message {
 954         my @recipients = unique_email_list(@to);
 955         @cc = (grep { my $cc = extract_valid_address($_);
 956                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
 957                     }
 958                map { sanitize_address($_) }
 959                @cc);
 960         my $to = join (",\n\t", @recipients);
 961         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 962         @recipients = (map { extract_valid_address($_) } @recipients);
 963         my $date = format_2822_time($time++);
 964         my $gitversion = '@@GIT_VERSION@@';
 965         if ($gitversion =~ m/..GIT_VERSION../) {
 966             $gitversion = Git::version();
 967         }
 968
 969         my $cc = join(",\n\t", unique_email_list(@cc));
 970         my $ccline = "";
 971         if ($cc ne '') {
 972                 $ccline = "\nCc: $cc";
 973         }
 974         my $sanitized_sender = sanitize_address($sender);
 975         make_message_id() unless defined($message_id);
 976
 977         my $header = "From: $sanitized_sender
 978 To: $to${ccline}
 979 Subject: $subject
 980 Date: $date
 981 Message-Id: $message_id
 982 X-Mailer: git-send-email $gitversion
 983 ";
 984         if ($reply_to) {
 985
 986                 $header .= "In-Reply-To: $reply_to\n";
 987                 $header .= "References: $references\n";
 988         }
 989         if (@xh) {
 990                 $header .= join("\n", @xh) . "\n";
 991         }
 992
 993         my @sendmail_parameters = ('-i', @recipients);
 994         my $raw_from = $sanitized_sender;
 995         if (defined $envelope_sender && $envelope_sender ne "auto") {
 996                 $raw_from = $envelope_sender;
 997         }
 998         $raw_from = extract_valid_address($raw_from);
 999         unshift (@sendmail_parameters,
1000                         '-f', $raw_from) if(defined $envelope_sender);
1001
1002         if ($needs_confirm && !$dry_run) {
1003                 print "\n$header\n";
1004                 if ($needs_confirm eq "inform") {
1005                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1006                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1007                         print "    The Cc list above has been expanded by additional\n";
1008                         print "    addresses found in the patch commit message. By default\n";
1009                         print "    send-email prompts before sending whenever this occurs.\n";
1010                         print "    This behavior is controlled by the sendemail.confirm\n";
1011                         print "    configuration setting.\n";
1012                         print "\n";
1013                         print "    For additional information, run 'git send-email --help'.\n";
1014                         print "    To retain the current behavior, but squelch this message,\n";
1015                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1016                 }
1017                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1018                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1019                          default => $ask_default);
1020                 die "Send this email reply required" unless defined $_;
1021                 if (/^n/i) {
1022                         return 0;
1023                 } elsif (/^q/i) {
1024                         cleanup_compose_files();
1025                         exit(0);
1026                 } elsif (/^a/i) {
1027                         $confirm = 'never';
1028                 }
1029         }
1030
1031         if ($dry_run) {
1032                 # We don't want to send the email.
1033         } elsif ($smtp_server =~ m#^/#) {
1034                 my $pid = open my $sm, '|-';
1035                 defined $pid or die $!;
1036                 if (!$pid) {
1037                         exec($smtp_server, @sendmail_parameters) or die $!;
1038                 }
1039                 print $sm "$header\n$message";
1040                 close $sm or die $?;
1041         } else {
1042
1043                 if (!defined $smtp_server) {
1044                         die "The required SMTP server is not properly defined."
1045                 }
1046
1047                 if ($smtp_encryption eq 'ssl') {
1048                         $smtp_server_port ||= 465; # ssmtp
1049                         require Net::SMTP::SSL;
1050                         $smtp_domain ||= maildomain();
1051                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1052                                                       Hello => $smtp_domain,
1053                                                       Port => $smtp_server_port);
1054                 }
1055                 else {
1056                         require Net::SMTP;
1057                         $smtp_domain ||= maildomain();
1058                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1059                                                  ? "$smtp_server:$smtp_server_port"
1060                                                  : $smtp_server,
1061                                                  Hello => $smtp_domain,
1062                                                  Debug => $debug_net_smtp);
1063                         if ($smtp_encryption eq 'tls' && $smtp) {
1064                                 require Net::SMTP::SSL;
1065                                 $smtp->command('STARTTLS');
1066                                 $smtp->response();
1067                                 if ($smtp->code == 220) {
1068                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1069                                                 or die "STARTTLS failed! ".$smtp->message;
1070                                         $smtp_encryption = '';
1071                                         # Send EHLO again to receive fresh
1072                                         # supported commands
1073                                         $smtp->hello();
1074                                 } else {
1075                                         die "Server does not support STARTTLS! ".$smtp->message;
1076                                 }
1077                         }
1078                 }
1079
1080                 if (!$smtp) {
1081                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1082                             "VALUES: server=$smtp_server ",
1083                             "encryption=$smtp_encryption ",
1084                             "hello=$smtp_domain",
1085                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1086                 }
1087
1088                 if (defined $smtp_authuser) {
1089
1090                         if (!defined $smtp_authpass) {
1091
1092                                 system "stty -echo";
1093
1094                                 do {
1095                                         print "Password: ";
1096                                         $_ = <STDIN>;
1097                                         print "\n";
1098                                 } while (!defined $_);
1099
1100                                 chomp($smtp_authpass = $_);
1101
1102                                 system "stty echo";
1103                         }
1104
1105                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1106                 }
1107
1108                 $smtp->mail( $raw_from ) or die $smtp->message;
1109                 $smtp->to( @recipients ) or die $smtp->message;
1110                 $smtp->data or die $smtp->message;
1111                 $smtp->datasend("$header\n$message") or die $smtp->message;
1112                 $smtp->dataend() or die $smtp->message;
1113                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1114         }
1115         if ($quiet) {
1116                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1117         } else {
1118                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1119                 if ($smtp_server !~ m#^/#) {
1120                         print "Server: $smtp_server\n";
1121                         print "MAIL FROM:<$raw_from>\n";
1122                         foreach my $entry (@recipients) {
1123                             print "RCPT TO:<$entry>\n";
1124                         }
1125                 } else {
1126                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1127                 }
1128                 print $header, "\n";
1129                 if ($smtp) {
1130                         print "Result: ", $smtp->code, ' ',
1131                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1132                 } else {
1133                         print "Result: OK\n";
1134                 }
1135         }
1136
1137         return 1;
1138 }
1139
1140 $reply_to = $initial_reply_to;
1141 $references = $initial_reply_to || '';
1142 $subject = $initial_subject;
1143 $message_num = 0;
1144
1145 foreach my $t (@files) {
1146         open(F,"<",$t) or die "can't open file $t";
1147
1148         my $author = undef;
1149         my $author_encoding;
1150         my $has_content_type;
1151         my $body_encoding;
1152         @cc = ();
1153         @xh = ();
1154         my $input_format = undef;
1155         my @header = ();
1156         $message = "";
1157         $message_num++;
1158         # First unfold multiline header fields
1159         while(<F>) {
1160                 last if /^\s*$/;
1161                 if (/^\s+\S/ and @header) {
1162                         chomp($header[$#header]);
1163                         s/^\s+/ /;
1164                         $header[$#header] .= $_;
1165             } else {
1166                         push(@header, $_);
1167                 }
1168         }
1169         # Now parse the header
1170         foreach(@header) {
1171                 if (/^From /) {
1172                         $input_format = 'mbox';
1173                         next;
1174                 }
1175                 chomp;
1176                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1177                         $input_format = 'mbox';
1178                 }
1179
1180                 if (defined $input_format && $input_format eq 'mbox') {
1181                         if (/^Subject:\s+(.*)$/) {
1182                                 $subject = $1;
1183                         }
1184                         elsif (/^From:\s+(.*)$/) {
1185                                 ($author, $author_encoding) = unquote_rfc2047($1);
1186                                 next if $suppress_cc{'author'};
1187                                 next if $suppress_cc{'self'} and $author eq $sender;
1188                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1189                                         $1, $_) unless $quiet;
1190                                 push @cc, $1;
1191                         }
1192                         elsif (/^Cc:\s+(.*)$/) {
1193                                 foreach my $addr (parse_address_line($1)) {
1194                                         if (unquote_rfc2047($addr) eq $sender) {
1195                                                 next if ($suppress_cc{'self'});
1196                                         } else {
1197                                                 next if ($suppress_cc{'cc'});
1198                                         }
1199                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1200                                                 $addr, $_) unless $quiet;
1201                                         push @cc, $addr;
1202                                 }
1203                         }
1204                         elsif (/^Content-type:/i) {
1205                                 $has_content_type = 1;
1206                                 if (/charset="?([^ "]+)/) {
1207                                         $body_encoding = $1;
1208                                 }
1209                                 push @xh, $_;
1210                         }
1211                         elsif (/^Message-Id: (.*)/i) {
1212                                 $message_id = $1;
1213                         }
1214                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1215                                 push @xh, $_;
1216                         }
1217
1218                 } else {
1219                         # In the traditional
1220                         # "send lots of email" format,
1221                         # line 1 = cc
1222                         # line 2 = subject
1223                         # So let's support that, too.
1224                         $input_format = 'lots';
1225                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1226                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1227                                         $_, $_) unless $quiet;
1228                                 push @cc, $_;
1229                         } elsif (!defined $subject) {
1230                                 $subject = $_;
1231                         }
1232                 }
1233         }
1234         # Now parse the message body
1235         while(<F>) {
1236                 $message .=  $_;
1237                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1238                         chomp;
1239                         my ($what, $c) = ($1, $2);
1240                         chomp $c;
1241                         if ($c eq $sender) {
1242                                 next if ($suppress_cc{'self'});
1243                         } else {
1244                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1245                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1246                         }
1247                         push @cc, $c;
1248                         printf("(body) Adding cc: %s from line '%s'\n",
1249                                 $c, $_) unless $quiet;
1250                 }
1251         }
1252         close F;
1253
1254         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1255                 open(F, "$cc_cmd \Q$t\E |")
1256                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1257                 while(<F>) {
1258                         my $c = $_;
1259                         $c =~ s/^\s*//g;
1260                         $c =~ s/\n$//g;
1261                         next if ($c eq $sender and $suppress_from);
1262                         push @cc, $c;
1263                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1264                                 $c, $cc_cmd) unless $quiet;
1265                 }
1266                 close F
1267                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1268         }
1269
1270         if ($broken_encoding{$t} && !$has_content_type) {
1271                 $has_content_type = 1;
1272                 push @xh, "MIME-Version: 1.0",
1273                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1274                         "Content-Transfer-Encoding: 8bit";
1275                 $body_encoding = $auto_8bit_encoding;
1276         }
1277
1278         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1279                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1280         }
1281
1282         if (defined $author and $author ne $sender) {
1283                 $message = "From: $author\n\n$message";
1284                 if (defined $author_encoding) {
1285                         if ($has_content_type) {
1286                                 if ($body_encoding eq $author_encoding) {
1287                                         # ok, we already have the right encoding
1288                                 }
1289                                 else {
1290                                         # uh oh, we should re-encode
1291                                 }
1292                         }
1293                         else {
1294                                 $has_content_type = 1;
1295                                 push @xh,
1296                                   'MIME-Version: 1.0',
1297                                   "Content-Type: text/plain; charset=$author_encoding",
1298                                   'Content-Transfer-Encoding: 8bit';
1299                         }
1300                 }
1301         }
1302
1303         $needs_confirm = (
1304                 $confirm eq "always" or
1305                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1306                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1307         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1308
1309         @cc = (@initial_cc, @cc);
1310
1311         my $message_was_sent = send_message();
1312
1313         # set up for the next message
1314         if ($thread && $message_was_sent &&
1315                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1316                 $reply_to = $message_id;
1317                 if (length $references > 0) {
1318                         $references .= "\n $message_id";
1319                 } else {
1320                         $references = "$message_id";
1321                 }
1322         }
1323         $message_id = undef;
1324 }
1325
1326 cleanup_compose_files();
1327
1328 sub cleanup_compose_files() {
1329         unlink($compose_filename, $compose_filename . ".final") if $compose;
1330 }
1331
1332 $smtp->quit if $smtp;
1333
1334 sub unique_email_list(@) {
1335         my %seen;
1336         my @emails;
1337
1338         foreach my $entry (@_) {
1339                 if (my $clean = extract_valid_address($entry)) {
1340                         $seen{$clean} ||= 0;
1341                         next if $seen{$clean}++;
1342                         push @emails, $entry;
1343                 } else {
1344                         print STDERR "W: unable to extract a valid address",
1345                                         " from: $entry\n";
1346                 }
1347         }
1348         return @emails;
1349 }
1350
1351 sub validate_patch {
1352         my $fn = shift;
1353         open(my $fh, '<', $fn)
1354                 or die "unable to open $fn: $!\n";
1355         while (my $line = <$fh>) {
1356                 if (length($line) > 998) {
1357                         return "$.: patch contains a line longer than 998 characters";
1358                 }
1359         }
1360         return undef;
1361 }
1362
1363 sub file_has_nonascii {
1364         my $fn = shift;
1365         open(my $fh, '<', $fn)
1366                 or die "unable to open $fn: $!\n";
1367         while (my $line = <$fh>) {
1368                 return 1 if $line =~ /[^[:ascii:]]/;
1369         }
1370         return 0;
1371 }
1372
1373 sub body_or_subject_has_nonascii {
1374         my $fn = shift;
1375         open(my $fh, '<', $fn)
1376                 or die "unable to open $fn: $!\n";
1377         while (my $line = <$fh>) {
1378                 last if $line =~ /^$/;
1379                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1380         }
1381         while (my $line = <$fh>) {
1382                 return 1 if $line =~ /[^[:ascii:]]/;
1383         }
1384         return 0;
1385 }