?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
test GIT_WORK_TREE
[git/jrn.git] / git-svn.perl
blob886b898fccfb37c0473d2d412f97cef6c4a284df
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
13 $ENV{GIT_DIR} ||= '.git';
14 $Git::SVN::default_repo_id = 'svn';
15 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
16 $Git::SVN::Ra::_log_window_size = 100;
17
18 $Git::SVN::Log::TZ = $ENV{TZ};
19 $ENV{TZ} = 'UTC';
20 $| = 1; # unbuffer STDOUT
21
22 sub fatal (@) { print STDERR @_; exit 1 }
23 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
24 require SVN::Ra;
25 require SVN::Delta;
26 if ($SVN::Core::VERSION lt '1.1.0') {
27 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
28 }
29 push @Git::SVN::Ra::ISA, 'SVN::Ra';
30 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
31 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
32 use Carp qw/croak/;
33 use IO::File qw//;
34 use File::Basename qw/dirname basename/;
35 use File::Path qw/mkpath/;
36 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
37 use IPC::Open3;
38 use Git;
39
40 BEGIN {
41 my $s;
42 foreach (qw/command command_oneline command_noisy command_output_pipe
43 command_input_pipe command_close_pipe/) {
44 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
45 "*Git::SVN::Migration::$_ = ".
46 "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
47 }
48 eval $s;
49 }
50
51 my ($SVN);
52
53 $sha1 = qr/[a-f\d]{40}/;
54 $sha1_short = qr/[a-f\d]{4,40}/;
55 my ($_stdin, $_help, $_edit,
56 $_message, $_file,
57 $_template, $_shared,
58 $_version, $_fetch_all, $_no_rebase,
59 $_merge, $_strategy, $_dry_run, $_local,
60 $_prefix, $_no_checkout, $_verbose);
61 $Git::SVN::_follow_parent = 1;
62 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
63 'config-dir=s' => \$Git::SVN::Ra::config_dir,
64 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
65 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
66 'authors-file|A=s' => \$_authors,
67 'repack:i' => \$Git::SVN::_repack,
68 'noMetadata' => \$Git::SVN::_no_metadata,
69 'useSvmProps' => \$Git::SVN::_use_svm_props,
70 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
71 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
72 'no-checkout' => \$_no_checkout,
73 'quiet|q' => \$_q,
74 'repack-flags|repack-args|repack-opts=s' =>
75 \$Git::SVN::_repack_flags,
76 %remote_opts );
77
78 my ($_trunk, $_tags, $_branches);
79 my %icv;
80 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
81 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
82 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
83 'minimize-url|m' => \$Git::SVN::_minimize_url,
84 'no-metadata' => sub { $icv{noMetadata} = 1 },
85 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
86 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
87 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
88 %remote_opts );
89 my %cmt_opts = ( 'edit|e' => \$_edit,
90 'rmdir' => \$SVN::Git::Editor::_rmdir,
91 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
92 'l=i' => \$SVN::Git::Editor::_rename_limit,
93 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
94 );
95
96 my %cmd = (
97 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
98 { 'revision|r=s' => \$_revision,
99 'fetch-all|all' => \$_fetch_all,
100 %fc_opts } ],
101 clone => [ \&cmd_clone, "Initialize and fetch revisions",
102 { 'revision|r=s' => \$_revision,
103 %fc_opts, %init_opts } ],
104 init => [ \&cmd_init, "Initialize a repo for tracking" .
105 " (requires URL argument)",
106 \%init_opts ],
107 'multi-init' => [ \&cmd_multi_init,
108 "Deprecated alias for ".
109 "'$0 init -T<trunk> -b<branches> -t<tags>'",
110 \%init_opts ],
111 dcommit => [ \&cmd_dcommit,
112 'Commit several diffs to merge with upstream',
113 { 'merge|m|M' => \$_merge,
114 'strategy|s=s' => \$_strategy,
115 'verbose|v' => \$_verbose,
116 'dry-run|n' => \$_dry_run,
117 'fetch-all|all' => \$_fetch_all,
118 'no-rebase' => \$_no_rebase,
119 %cmt_opts, %fc_opts } ],
120 'set-tree' => [ \&cmd_set_tree,
121 "Set an SVN repository to a git tree-ish",
122 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
123 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
124 { 'revision|r=i' => \$_revision } ],
125 'multi-fetch' => [ \&cmd_multi_fetch,
126 "Deprecated alias for $0 fetch --all",
127 { 'revision|r=s' => \$_revision, %fc_opts } ],
128 'migrate' => [ sub { },
129 # no-op, we automatically run this anyways,
130 'Migrate configuration/metadata/layout from
131 previous versions of git-svn',
132 { 'minimize' => \$Git::SVN::Migration::_minimize,
133 %remote_opts } ],
134 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
135 { 'limit=i' => \$Git::SVN::Log::limit,
136 'revision|r=s' => \$_revision,
137 'verbose|v' => \$Git::SVN::Log::verbose,
138 'incremental' => \$Git::SVN::Log::incremental,
139 'oneline' => \$Git::SVN::Log::oneline,
140 'show-commit' => \$Git::SVN::Log::show_commit,
141 'non-recursive' => \$Git::SVN::Log::non_recursive,
142 'authors-file|A=s' => \$_authors,
143 'color' => \$Git::SVN::Log::color,
144 'pager=s' => \$Git::SVN::Log::pager,
145 } ],
146 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
147 { } ],
148 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
149 { 'merge|m|M' => \$_merge,
150 'verbose|v' => \$_verbose,
151 'strategy|s=s' => \$_strategy,
152 'local|l' => \$_local,
153 'fetch-all|all' => \$_fetch_all,
154 %fc_opts } ],
155 'commit-diff' => [ \&cmd_commit_diff,
156 'Commit a diff between two trees',
157 { 'message|m=s' => \$_message,
158 'file|F=s' => \$_file,
159 'revision|r=s' => \$_revision,
160 %cmt_opts } ],
161 );
162
163 my $cmd;
164 for (my $i = 0; $i < @ARGV; $i++) {
165 if (defined $cmd{$ARGV[$i]}) {
166 $cmd = $ARGV[$i];
167 splice @ARGV, $i, 1;
168 last;
169 }
170 };
171
172 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
173
174 read_repo_config(\%opts);
175 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
176 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
177 'minimize-connections' => \$Git::SVN::Migration::_minimize,
178 'id|i=s' => \$Git::SVN::default_ref_id,
179 'svn-remote|remote|R=s' => sub {
180 $Git::SVN::no_reuse_existing = 1;
181 $Git::SVN::default_repo_id = $_[1] });
182 exit 1 if (!$rv && $cmd && $cmd ne 'log');
183
184 usage(0) if $_help;
185 version() if $_version;
186 usage(1) unless defined $cmd;
187 load_authors() if $_authors;
188
189 # make sure we're always running
190 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
191 unless (-d $ENV{GIT_DIR}) {
192 if ($git_dir_user_set) {
193 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
194 "but it is not a directory\n";
195 }
196 my $git_dir = delete $ENV{GIT_DIR};
197 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
198 unless (length $cdup) {
199 die "Already at toplevel, but $git_dir ",
200 "not found '$cdup'\n";
201 }
202 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
203 unless (-d $git_dir) {
204 die "$git_dir still not found after going to ",
205 "'$cdup'\n";
206 }
207 $ENV{GIT_DIR} = $git_dir;
208 }
209 }
210 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
211 Git::SVN::Migration::migration_check();
212 }
213 Git::SVN::init_vars();
214 eval {
215 Git::SVN::verify_remotes_sanity();
216 $cmd{$cmd}->[0]->(@ARGV);
217 };
218 fatal $@ if $@;
219 post_fetch_checkout();
220 exit 0;
221
222 ####################### primary functions ######################
223 sub usage {
224 my $exit = shift || 0;
225 my $fd = $exit ? \*STDERR : \*STDOUT;
226 print $fd <<"";
227 git-svn - bidirectional operations between a single Subversion tree and git
228 Usage: $0 <command> [options] [arguments]\n
229
230 print $fd "Available commands:\n" unless $cmd;
231
232 foreach (sort keys %cmd) {
233 next if $cmd && $cmd ne $_;
234 next if /^multi-/; # don't show deprecated commands
235 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
236 foreach (keys %{$cmd{$_}->[2]}) {
237 # mixed-case options are for .git/config only
238 next if /[A-Z]/ && /^[a-z]+$/i;
239 # prints out arguments as they should be passed:
240 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
241 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
242 "--$_" : "-$_" }
243 split /\|/,$_)," $x\n";
244 }
245 }
246 print $fd <<"";
247 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
248 arbitrary identifier if you're tracking multiple SVN branches/repositories in
249 one git repository and want to keep them separate. See git-svn(1) for more
250 information.
251
252 exit $exit;
253 }
254
255 sub version {
256 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
257 exit 0;
258 }
259
260 sub do_git_init_db {
261 unless (-d $ENV{GIT_DIR}) {
262 my @init_db = ('init');
263 push @init_db, "--template=$_template" if defined $_template;
264 if (defined $_shared) {
265 if ($_shared =~ /[a-z]/) {
266 push @init_db, "--shared=$_shared";
267 } else {
268 push @init_db, "--shared";
269 }
270 }
271 command_noisy(@init_db);
272 }
273 my $set;
274 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
275 foreach my $i (keys %icv) {
276 die "'$set' and '$i' cannot both be set\n" if $set;
277 next unless defined $icv{$i};
278 command_noisy('config', "$pfx.$i", $icv{$i});
279 $set = $i;
280 }
281 }
282
283 sub init_subdir {
284 my $repo_path = shift or return;
285 mkpath([$repo_path]) unless -d $repo_path;
286 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
287 $ENV{GIT_DIR} = '.git';
288 }
289
290 sub cmd_clone {
291 my ($url, $path) = @_;
292 if (!defined $path &&
293 (defined $_trunk || defined $_branches || defined $_tags) &&
294 $url !~ m#^[a-z\+]+://#) {
295 $path = $url;
296 }
297 $path = basename($url) if !defined $path || !length $path;
298 cmd_init($url, $path);
299 Git::SVN::fetch_all($Git::SVN::default_repo_id);
300 }
301
302 sub cmd_init {
303 if (defined $_trunk || defined $_branches || defined $_tags) {
304 return cmd_multi_init(@_);
305 }
306 my $url = shift or die "SVN repository location required ",
307 "as a command-line argument\n";
308 init_subdir(@_);
309 do_git_init_db();
310
311 Git::SVN->init($url);
312 }
313
314 sub cmd_fetch {
315 if (grep /^\d+=./, @_) {
316 die "'<rev>=<commit>' fetch arguments are ",
317 "no longer supported.\n";
318 }
319 my ($remote) = @_;
320 if (@_ > 1) {
321 die "Usage: $0 fetch [--all] [svn-remote]\n";
322 }
323 $remote ||= $Git::SVN::default_repo_id;
324 if ($_fetch_all) {
325 cmd_multi_fetch();
326 } else {
327 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
328 }
329 }
330
331 sub cmd_set_tree {
332 my (@commits) = @_;
333 if ($_stdin || !@commits) {
334 print "Reading from stdin...\n";
335 @commits = ();
336 while (<STDIN>) {
337 if (/\b($sha1_short)\b/o) {
338 unshift @commits, $1;
339 }
340 }
341 }
342 my @revs;
343 foreach my $c (@commits) {
344 my @tmp = command('rev-parse',$c);
345 if (scalar @tmp == 1) {
346 push @revs, $tmp[0];
347 } elsif (scalar @tmp > 1) {
348 push @revs, reverse(command('rev-list',@tmp));
349 } else {
350 fatal "Failed to rev-parse $c\n";
351 }
352 }
353 my $gs = Git::SVN->new;
354 my ($r_last, $cmt_last) = $gs->last_rev_commit;
355 $gs->fetch;
356 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
357 fatal "There are new revisions that were fetched ",
358 "and need to be merged (or acknowledged) ",
359 "before committing.\nlast rev: $r_last\n",
360 " current: $gs->{last_rev}\n";
361 }
362 $gs->set_tree($_) foreach @revs;
363 print "Done committing ",scalar @revs," revisions to SVN\n";
364 }
365
366 sub cmd_dcommit {
367 my $head = shift;
368 $head ||= 'HEAD';
369 my @refs;
370 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
371 unless ($gs) {
372 die "Unable to determine upstream SVN information from ",
373 "$head history\n";
374 }
375 my $c = $refs[-1];
376 my $last_rev;
377 foreach my $d (@refs) {
378 if (!verify_ref("$d~1")) {
379 fatal "Commit $d\n",
380 "has no parent commit, and therefore ",
381 "nothing to diff against.\n",
382 "You should be working from a repository ",
383 "originally created by git-svn\n";
384 }
385 unless (defined $last_rev) {
386 (undef, $last_rev, undef) = cmt_metadata("$d~1");
387 unless (defined $last_rev) {
388 fatal "Unable to extract revision information ",
389 "from commit $d~1\n";
390 }
391 }
392 if ($_dry_run) {
393 print "diff-tree $d~1 $d\n";
394 } else {
395 my %ed_opts = ( r => $last_rev,
396 log => get_commit_entry($d)->{log},
397 ra => Git::SVN::Ra->new($gs->full_url),
398 tree_a => "$d~1",
399 tree_b => $d,
400 editor_cb => sub {
401 print "Committed r$_[0]\n";
402 $last_rev = $_[0]; },
403 svn_path => '');
404 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
405 print "No changes\n$d~1 == $d\n";
406 }
407 }
408 }
409 return if $_dry_run;
410 unless ($gs) {
411 warn "Could not determine fetch information for $url\n",
412 "Will not attempt to fetch and rebase commits.\n",
413 "This probably means you have useSvmProps and should\n",
414 "now resync your SVN::Mirror repository.\n";
415 return;
416 }
417 $_fetch_all ? $gs->fetch_all : $gs->fetch;
418 unless ($_no_rebase) {
419 # we always want to rebase against the current HEAD, not any
420 # head that was passed to us
421 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
422 my @finish;
423 if (@diff) {
424 @finish = rebase_cmd();
425 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
426 "using @finish:\n", "@diff";
427 } else {
428 print "No changes between current HEAD and ",
429 $gs->refname, "\nResetting to the latest ",
430 $gs->refname, "\n";
431 @finish = qw/reset --mixed/;
432 }
433 command_noisy(@finish, $gs->refname);
434 }
435 }
436
437 sub cmd_find_rev {
438 my $revision_or_hash = shift;
439 my $result;
440 if ($revision_or_hash =~ /^r\d+$/) {
441 my $head = shift;
442 $head ||= 'HEAD';
443 my @refs;
444 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
445 unless ($gs) {
446 die "Unable to determine upstream SVN information from ",
447 "$head history\n";
448 }
449 my $desired_revision = substr($revision_or_hash, 1);
450 $result = $gs->rev_db_get($desired_revision);
451 } else {
452 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
453 $result = $rev;
454 }
455 print "$result\n" if $result;
456 }
457
458 sub cmd_rebase {
459 command_noisy(qw/update-index --refresh/);
460 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
461 unless ($gs) {
462 die "Unable to determine upstream SVN information from ",
463 "working tree history\n";
464 }
465 if (command(qw/diff-index HEAD --/)) {
466 print STDERR "Cannot rebase with uncommited changes:\n";
467 command_noisy('status');
468 exit 1;
469 }
470 unless ($_local) {
471 $_fetch_all ? $gs->fetch_all : $gs->fetch;
472 }
473 command_noisy(rebase_cmd(), $gs->refname);
474 }
475
476 sub cmd_show_ignore {
477 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
478 $gs ||= Git::SVN->new;
479 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
480 $gs->traverse_ignore(\*STDOUT, $gs->{path}, $r);
481 }
482
483 sub cmd_multi_init {
484 my $url = shift;
485 unless (defined $_trunk || defined $_branches || defined $_tags) {
486 usage(1);
487 }
488
489 # there are currently some bugs that prevent multi-init/multi-fetch
490 # setups from working well without this.
491 $Git::SVN::_minimize_url = 1;
492
493 $_prefix = '' unless defined $_prefix;
494 if (defined $url) {
495 $url =~ s#/+$##;
496 init_subdir(@_);
497 }
498 do_git_init_db();
499 if (defined $_trunk) {
500 my $trunk_ref = $_prefix . 'trunk';
501 # try both old-style and new-style lookups:
502 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
503 unless ($gs_trunk) {
504 my ($trunk_url, $trunk_path) =
505 complete_svn_url($url, $_trunk);
506 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
507 undef, $trunk_ref);
508 }
509 }
510 return unless defined $_branches || defined $_tags;
511 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
512 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
513 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
514 }
515
516 sub cmd_multi_fetch {
517 my $remotes = Git::SVN::read_all_remotes();
518 foreach my $repo_id (sort keys %$remotes) {
519 if ($remotes->{$repo_id}->{url}) {
520 Git::SVN::fetch_all($repo_id, $remotes);
521 }
522 }
523 }
524
525 # this command is special because it requires no metadata
526 sub cmd_commit_diff {
527 my ($ta, $tb, $url) = @_;
528 my $usage = "Usage: $0 commit-diff -r<revision> ".
529 "<tree-ish> <tree-ish> [<URL>]\n";
530 fatal($usage) if (!defined $ta || !defined $tb);
531 my $svn_path;
532 if (!defined $url) {
533 my $gs = eval { Git::SVN->new };
534 if (!$gs) {
535 fatal("Needed URL or usable git-svn --id in ",
536 "the command-line\n", $usage);
537 }
538 $url = $gs->{url};
539 $svn_path = $gs->{path};
540 }
541 unless (defined $_revision) {
542 fatal("-r|--revision is a required argument\n", $usage);
543 }
544 if (defined $_message && defined $_file) {
545 fatal("Both --message/-m and --file/-F specified ",
546 "for the commit message.\n",
547 "I have no idea what you mean\n");
548 }
549 if (defined $_file) {
550 $_message = file_to_s($_file);
551 } else {
552 $_message ||= get_commit_entry($tb)->{log};
553 }
554 my $ra ||= Git::SVN::Ra->new($url);
555 $svn_path ||= $ra->{svn_path};
556 my $r = $_revision;
557 if ($r eq 'HEAD') {
558 $r = $ra->get_latest_revnum;
559 } elsif ($r !~ /^\d+$/) {
560 die "revision argument: $r not understood by git-svn\n";
561 }
562 my %ed_opts = ( r => $r,
563 log => $_message,
564 ra => $ra,
565 tree_a => $ta,
566 tree_b => $tb,
567 editor_cb => sub { print "Committed r$_[0]\n" },
568 svn_path => $svn_path );
569 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
570 print "No changes\n$ta == $tb\n";
571 }
572 }
573
574 ########################### utility functions #########################
575
576 sub rebase_cmd {
577 my @cmd = qw/rebase/;
578 push @cmd, '-v' if $_verbose;
579 push @cmd, qw/--merge/ if $_merge;
580 push @cmd, "--strategy=$_strategy" if $_strategy;
581 @cmd;
582 }
583
584 sub post_fetch_checkout {
585 return if $_no_checkout;
586 my $gs = $Git::SVN::_head or return;
587 return if verify_ref('refs/heads/master^0');
588
589 my $valid_head = verify_ref('HEAD^0');
590 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
591 return if ($valid_head || !verify_ref('HEAD^0'));
592
593 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
594 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
595 return if -f $index;
596
597 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
598 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
599 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
600 print STDERR "Checked out HEAD:\n ",
601 $gs->full_url, " r", $gs->last_rev, "\n";
602 }
603
604 sub complete_svn_url {
605 my ($url, $path) = @_;
606 $path =~ s#/+$##;
607 if ($path !~ m#^[a-z\+]+://#) {
608 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
609 fatal("E: '$path' is not a complete URL ",
610 "and a separate URL is not specified\n");
611 }
612 return ($url, $path);
613 }
614 return ($path, '');
615 }
616
617 sub complete_url_ls_init {
618 my ($ra, $repo_path, $switch, $pfx) = @_;
619 unless ($repo_path) {
620 print STDERR "W: $switch not specified\n";
621 return;
622 }
623 $repo_path =~ s#/+$##;
624 if ($repo_path =~ m#^[a-z\+]+://#) {
625 $ra = Git::SVN::Ra->new($repo_path);
626 $repo_path = '';
627 } else {
628 $repo_path =~ s#^/+##;
629 unless ($ra) {
630 fatal("E: '$repo_path' is not a complete URL ",
631 "and a separate URL is not specified\n");
632 }
633 }
634 my $url = $ra->{url};
635 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
636 my $k = "svn-remote.$gs->{repo_id}.url";
637 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
638 if ($orig_url && ($orig_url ne $gs->{url})) {
639 die "$k already set: $orig_url\n",
640 "wanted to set to: $gs->{url}\n";
641 }
642 command_oneline('config', $k, $gs->{url}) unless $orig_url;
643 my $remote_path = "$ra->{svn_path}/$repo_path/*";
644 $remote_path =~ s#/+#/#g;
645 $remote_path =~ s#^/##g;
646 my ($n) = ($switch =~ /^--(\w+)/);
647 if (length $pfx && $pfx !~ m#/$#) {
648 die "--prefix='$pfx' must have a trailing slash '/'\n";
649 }
650 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
651 "$remote_path:refs/remotes/$pfx*");
652 }
653
654 sub verify_ref {
655 my ($ref) = @_;
656 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
657 { STDERR => 0 }); };
658 }
659
660 sub get_tree_from_treeish {
661 my ($treeish) = @_;
662 # $treeish can be a symbolic ref, too:
663 my $type = command_oneline(qw/cat-file -t/, $treeish);
664 my $expected;
665 while ($type eq 'tag') {
666 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
667 }
668 if ($type eq 'commit') {
669 $expected = (grep /^tree /, command(qw/cat-file commit/,
670 $treeish))[0];
671 ($expected) = ($expected =~ /^tree ($sha1)$/o);
672 die "Unable to get tree from $treeish\n" unless $expected;
673 } elsif ($type eq 'tree') {
674 $expected = $treeish;
675 } else {
676 die "$treeish is a $type, expected tree, tag or commit\n";
677 }
678 return $expected;
679 }
680
681 sub get_commit_entry {
682 my ($treeish) = shift;
683 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
684 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
685 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
686 open my $log_fh, '>', $commit_editmsg or croak $!;
687
688 my $type = command_oneline(qw/cat-file -t/, $treeish);
689 if ($type eq 'commit' || $type eq 'tag') {
690 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
691 $type, $treeish);
692 my $in_msg = 0;
693 while (<$msg_fh>) {
694 if (!$in_msg) {
695 $in_msg = 1 if (/^\s*$/);
696 } elsif (/^git-svn-id: /) {
697 # skip this for now, we regenerate the
698 # correct one on re-fetch anyways
699 # TODO: set *:merge properties or like...
700 } else {
701 print $log_fh $_ or croak $!;
702 }
703 }
704 command_close_pipe($msg_fh, $ctx);
705 }
706 close $log_fh or croak $!;
707
708 if ($_edit || ($type eq 'tree')) {
709 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
710 # TODO: strip out spaces, comments, like git-commit.sh
711 system($editor, $commit_editmsg);
712 }
713 rename $commit_editmsg, $commit_msg or croak $!;
714 open $log_fh, '<', $commit_msg or croak $!;
715 { local $/; chomp($log_entry{log} = <$log_fh>); }
716 close $log_fh or croak $!;
717 unlink $commit_msg;
718 \%log_entry;
719 }
720
721 sub s_to_file {
722 my ($str, $file, $mode) = @_;
723 open my $fd,'>',$file or croak $!;
724 print $fd $str,"\n" or croak $!;
725 close $fd or croak $!;
726 chmod ($mode &~ umask, $file) if (defined $mode);
727 }
728
729 sub file_to_s {
730 my $file = shift;
731 open my $fd,'<',$file or croak "$!: file: $file\n";
732 local $/;
733 my $ret = <$fd>;
734 close $fd or croak $!;
735 $ret =~ s/\s*$//s;
736 return $ret;
737 }
738
739 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
740 sub load_authors {
741 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
742 my $log = $cmd eq 'log';
743 while (<$authors>) {
744 chomp;
745 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
746 my ($user, $name, $email) = ($1, $2, $3);
747 if ($log) {
748 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
749 } else {
750 $users{$user} = [$name, $email];
751 }
752 }
753 close $authors or croak $!;
754 }
755
756 # convert GetOpt::Long specs for use by git-config
757 sub read_repo_config {
758 return unless -d $ENV{GIT_DIR};
759 my $opts = shift;
760 my @config_only;
761 foreach my $o (keys %$opts) {
762 # if we have mixedCase and a long option-only, then
763 # it's a config-only variable that we don't need for
764 # the command-line.
765 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
766 my $v = $opts->{$o};
767 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
768 $key =~ s/-//g;
769 my $arg = 'git-config';
770 $arg .= ' --int' if ($o =~ /[:=]i$/);
771 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
772 if (ref $v eq 'ARRAY') {
773 chomp(my @tmp = `$arg --get-all svn.$key`);
774 @$v = @tmp if @tmp;
775 } else {
776 chomp(my $tmp = `$arg --get svn.$key`);
777 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
778 $$v = $tmp;
779 }
780 }
781 }
782 delete @$opts{@config_only} if @config_only;
783 }
784
785 sub extract_metadata {
786 my $id = shift or return (undef, undef, undef);
787 my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
788 \s([a-f\d\-]+)$/x);
789 if (!defined $rev || !$uuid || !$url) {
790 # some of the original repositories I made had
791 # identifiers like this:
792 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
793 }
794 return ($url, $rev, $uuid);
795 }
796
797 sub cmt_metadata {
798 return extract_metadata((grep(/^git-svn-id: /,
799 command(qw/cat-file commit/, shift)))[-1]);
800 }
801
802 sub working_head_info {
803 my ($head, $refs) = @_;
804 my ($fh, $ctx) = command_output_pipe('rev-list', $head);
805 while (my $hash = <$fh>) {
806 chomp($hash);
807 my ($url, $rev, $uuid) = cmt_metadata($hash);
808 if (defined $url && defined $rev) {
809 if (my $gs = Git::SVN->find_by_url($url)) {
810 my $c = $gs->rev_db_get($rev);
811 if ($c && $c eq $hash) {
812 close $fh; # break the pipe
813 return ($url, $rev, $uuid, $gs);
814 }
815 }
816 }
817 unshift @$refs, $hash if $refs;
818 }
819 command_close_pipe($fh, $ctx);
820 (undef, undef, undef, undef);
821 }
822
823 package Git::SVN;
824 use strict;
825 use warnings;
826 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
827 $_repack $_repack_flags $_use_svm_props $_head
828 $_use_svnsync_props $no_reuse_existing $_minimize_url/;
829 use Carp qw/croak/;
830 use File::Path qw/mkpath/;
831 use File::Copy qw/copy/;
832 use IPC::Open3;
833
834 my $_repack_nr;
835 # properties that we do not log:
836 my %SKIP_PROP;
837 BEGIN {
838 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
839 svn:special svn:executable
840 svn:entry:committed-rev
841 svn:entry:last-author
842 svn:entry:uuid
843 svn:entry:committed-date/;
844
845 # some options are read globally, but can be overridden locally
846 # per [svn-remote "..."] section. Command-line options will *NOT*
847 # override options set in an [svn-remote "..."] section
848 my $e;
849 foreach (qw/follow_parent no_metadata use_svm_props
850 use_svnsync_props/) {
851 my $key = $_;
852 $key =~ tr/_//d;
853 $e .= "sub $_ {
854 my (\$self) = \@_;
855 return \$self->{-$_} if exists \$self->{-$_};
856 my \$k = \"svn-remote.\$self->{repo_id}\.$key\";
857 eval { command_oneline(qw/config --get/, \$k) };
858 if (\$@) {
859 \$self->{-$_} = \$Git::SVN::_$_;
860 } else {
861 my \$v = command_oneline(qw/config --bool/,\$k);
862 \$self->{-$_} = \$v eq 'false' ? 0 : 1;
863 }
864 return \$self->{-$_} }\n";
865 }
866 $e .= "1;\n";
867 eval $e or die $@;
868 }
869
870 my %LOCKFILES;
871 END { unlink keys %LOCKFILES if %LOCKFILES }
872
873 sub resolve_local_globs {
874 my ($url, $fetch, $glob_spec) = @_;
875 return unless defined $glob_spec;
876 my $ref = $glob_spec->{ref};
877 my $path = $glob_spec->{path};
878 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
879 next unless m#^refs/remotes/$ref->{regex}$#;
880 my $p = $1;
881 my $pathname = $path->full_path($p);
882 my $refname = $ref->full_path($p);
883 if (my $existing = $fetch->{$pathname}) {
884 if ($existing ne $refname) {
885 die "Refspec conflict:\n",
886 "existing: refs/remotes/$existing\n",
887 " globbed: refs/remotes/$refname\n";
888 }
889 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
890 $u =~ s!^\Q$url\E(/|$)!! or die
891 "refs/remotes/$refname: '$url' not found in '$u'\n";
892 if ($pathname ne $u) {
893 warn "W: Refspec glob conflict ",
894 "(ref: refs/remotes/$refname):\n",
895 "expected path: $pathname\n",
896 " real path: $u\n",
897 "Continuing ahead with $u\n";
898 next;
899 }
900 } else {
901 $fetch->{$pathname} = $refname;
902 }
903 }
904 }
905
906 sub parse_revision_argument {
907 my ($base, $head) = @_;
908 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
909 return ($base, $head);
910 }
911 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
912 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
913 return ($head, $head) if ($::_revision eq 'HEAD');
914 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
915 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
916 die "revision argument: $::_revision not understood by git-svn\n";
917 }
918
919 sub fetch_all {
920 my ($repo_id, $remotes) = @_;
921 if (ref $repo_id) {
922 my $gs = $repo_id;
923 $repo_id = undef;
924 $repo_id = $gs->{repo_id};
925 }
926 $remotes ||= read_all_remotes();
927 my $remote = $remotes->{$repo_id} or
928 die "[svn-remote \"$repo_id\"] unknown\n";
929 my $fetch = $remote->{fetch};
930 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
931 my (@gs, @globs);
932 my $ra = Git::SVN::Ra->new($url);
933 my $uuid = $ra->get_uuid;
934 my $head = $ra->get_latest_revnum;
935 my $base = defined $fetch ? $head : 0;
936
937 # read the max revs for wildcard expansion (branches/*, tags/*)
938 foreach my $t (qw/branches tags/) {
939 defined $remote->{$t} or next;
940 push @globs, $remote->{$t};
941 my $max_rev = eval { tmp_config(qw/--int --get/,
942 "svn-remote.$repo_id.${t}-maxRev") };
943 if (defined $max_rev && ($max_rev < $base)) {
944 $base = $max_rev;
945 } elsif (!defined $max_rev) {
946 $base = 0;
947 }
948 }
949
950 if ($fetch) {
951 foreach my $p (sort keys %$fetch) {
952 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
953 my $lr = $gs->rev_db_max;
954 if (defined $lr) {
955 $base = $lr if ($lr < $base);
956 }
957 push @gs, $gs;
958 }
959 }
960
961 ($base, $head) = parse_revision_argument($base, $head);
962 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
963 }
964
965 sub read_all_remotes {
966 my $r = {};
967 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
968 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
969 $r->{$1}->{fetch}->{$2} = $3;
970 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
971 $r->{$1}->{url} = $2;
972 } elsif (m!^(.+)\.(branches|tags)=
973 (.*):refs/remotes/(.+)\s*$/!x) {
974 my ($p, $g) = ($3, $4);
975 my $rs = $r->{$1}->{$2} = {
976 t => $2,
977 remote => $1,
978 path => Git::SVN::GlobSpec->new($p),
979 ref => Git::SVN::GlobSpec->new($g) };
980 if (length($rs->{ref}->{right}) != 0) {
981 die "The '*' glob character must be the last ",
982 "character of '$g'\n";
983 }
984 }
985 }
986 $r;
987 }
988
989 sub init_vars {
990 if (defined $_repack) {
991 $_repack = 1000 if ($_repack <= 0);
992 $_repack_nr = $_repack;
993 $_repack_flags ||= '-d';
994 }
995 }
996
997 sub verify_remotes_sanity {
998 return unless -d $ENV{GIT_DIR};
999 my %seen;
1000 foreach (command(qw/config -l/)) {
1001 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1002 if ($seen{$1}) {
1003 die "Remote ref refs/remote/$1 is tracked by",
1004 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1005 "Please resolve this ambiguity in ",
1006 "your git configuration file before ",
1007 "continuing\n";
1008 }
1009 $seen{$1} = $_;
1010 }
1011 }
1012 }
1013
1014 # we allow more chars than remotes2config.sh...
1015 sub sanitize_remote_name {
1016 my ($name) = @_;
1017 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1018 $name;
1019 }
1020
1021 sub find_existing_remote {
1022 my ($url, $remotes) = @_;
1023 return undef if $no_reuse_existing;
1024 my $existing;
1025 foreach my $repo_id (keys %$remotes) {
1026 my $u = $remotes->{$repo_id}->{url} or next;
1027 next if $u ne $url;
1028 $existing = $repo_id;
1029 last;
1030 }
1031 $existing;
1032 }
1033
1034 sub init_remote_config {
1035 my ($self, $url, $no_write) = @_;
1036 $url =~ s!/+$!!; # strip trailing slash
1037 my $r = read_all_remotes();
1038 my $existing = find_existing_remote($url, $r);
1039 if ($existing) {
1040 unless ($no_write) {
1041 print STDERR "Using existing ",
1042 "[svn-remote \"$existing\"]\n";
1043 }
1044 $self->{repo_id} = $existing;
1045 } elsif ($_minimize_url) {
1046 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1047 $existing = find_existing_remote($min_url, $r);
1048 if ($existing) {
1049 unless ($no_write) {
1050 print STDERR "Using existing ",
1051 "[svn-remote \"$existing\"]\n";
1052 }
1053 $self->{repo_id} = $existing;
1054 }
1055 if ($min_url ne $url) {
1056 unless ($no_write) {
1057 print STDERR "Using higher level of URL: ",
1058 "$url => $min_url\n";
1059 }
1060 my $old_path = $self->{path};
1061 $self->{path} = $url;
1062 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1063 if (length $old_path) {
1064 $self->{path} .= "/$old_path";
1065 }
1066 $url = $min_url;
1067 }
1068 }
1069 my $orig_url;
1070 if (!$existing) {
1071 # verify that we aren't overwriting anything:
1072 $orig_url = eval {
1073 command_oneline('config', '--get',
1074 "svn-remote.$self->{repo_id}.url")
1075 };
1076 if ($orig_url && ($orig_url ne $url)) {
1077 die "svn-remote.$self->{repo_id}.url already set: ",
1078 "$orig_url\nwanted to set to: $url\n";
1079 }
1080 }
1081 my ($xrepo_id, $xpath) = find_ref($self->refname);
1082 if (defined $xpath) {
1083 die "svn-remote.$xrepo_id.fetch already set to track ",
1084 "$xpath:refs/remotes/", $self->refname, "\n";
1085 }
1086 unless ($no_write) {
1087 command_noisy('config',
1088 "svn-remote.$self->{repo_id}.url", $url);
1089 command_noisy('config', '--add',
1090 "svn-remote.$self->{repo_id}.fetch",
1091 "$self->{path}:".$self->refname);
1092 }
1093 $self->{url} = $url;
1094 }
1095
1096 sub find_by_url { # repos_root and, path are optional
1097 my ($class, $full_url, $repos_root, $path) = @_;
1098
1099 return undef unless defined $full_url;
1100 remove_username($full_url);
1101 remove_username($repos_root) if defined $repos_root;
1102 my $remotes = read_all_remotes();
1103 if (defined $full_url && defined $repos_root && !defined $path) {
1104 $path = $full_url;
1105 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1106 }
1107 foreach my $repo_id (keys %$remotes) {
1108 my $u = $remotes->{$repo_id}->{url} or next;
1109 remove_username($u);
1110 next if defined $repos_root && $repos_root ne $u;
1111
1112 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1113 foreach (qw/branches tags/) {
1114 resolve_local_globs($u, $fetch,
1115 $remotes->{$repo_id}->{$_});
1116 }
1117 my $p = $path;
1118 unless (defined $p) {
1119 $p = $full_url;
1120 $p =~ s#^\Q$u\E(?:/|$)## or next;
1121 }
1122 foreach my $f (keys %$fetch) {
1123 next if $f ne $p;
1124 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1125 }
1126 }
1127 undef;
1128 }
1129
1130 sub init {
1131 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1132 my $self = _new($class, $repo_id, $ref_id, $path);
1133 if (defined $url) {
1134 $self->init_remote_config($url, $no_write);
1135 }
1136 $self;
1137 }
1138
1139 sub find_ref {
1140 my ($ref_id) = @_;
1141 foreach (command(qw/config -l/)) {
1142 next unless m!^svn-remote\.(.+)\.fetch=
1143 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1144 my ($repo_id, $path, $ref) = ($1, $2, $3);
1145 if ($ref eq $ref_id) {
1146 $path = '' if ($path =~ m#^\./?#);
1147 return ($repo_id, $path);
1148 }
1149 }
1150 (undef, undef, undef);
1151 }
1152
1153 sub new {
1154 my ($class, $ref_id, $repo_id, $path) = @_;
1155 if (defined $ref_id && !defined $repo_id && !defined $path) {
1156 ($repo_id, $path) = find_ref($ref_id);
1157 if (!defined $repo_id) {
1158 die "Could not find a \"svn-remote.*.fetch\" key ",
1159 "in the repository configuration matching: ",
1160 "refs/remotes/$ref_id\n";
1161 }
1162 }
1163 my $self = _new($class, $repo_id, $ref_id, $path);
1164 if (!defined $self->{path} || !length $self->{path}) {
1165 my $fetch = command_oneline('config', '--get',
1166 "svn-remote.$repo_id.fetch",
1167 ":refs/remotes/$ref_id\$") or
1168 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1169 "\":refs/remotes/$ref_id\$\" in config\n";
1170 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1171 }
1172 $self->{url} = command_oneline('config', '--get',
1173 "svn-remote.$repo_id.url") or
1174 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1175 $self->rebuild;
1176 $self;
1177 }
1178
1179 sub refname { "refs/remotes/$_[0]->{ref_id}" }
1180
1181 sub svm_uuid {
1182 my ($self) = @_;
1183 return $self->{svm}->{uuid} if $self->svm;
1184 $self->ra;
1185 unless ($self->{svm}) {
1186 die "SVM UUID not cached, and reading remotely failed\n";
1187 }
1188 $self->{svm}->{uuid};
1189 }
1190
1191 sub svm {
1192 my ($self) = @_;
1193 return $self->{svm} if $self->{svm};
1194 my $svm;
1195 # see if we have it in our config, first:
1196 eval {
1197 my $section = "svn-remote.$self->{repo_id}";
1198 $svm = {
1199 source => tmp_config('--get', "$section.svm-source"),
1200 uuid => tmp_config('--get', "$section.svm-uuid"),
1201 replace => tmp_config('--get', "$section.svm-replace"),
1202 }
1203 };
1204 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1205 $self->{svm} = $svm;
1206 }
1207 $self->{svm};
1208 }
1209
1210 sub _set_svm_vars {
1211 my ($self, $ra) = @_;
1212 return $ra if $self->svm;
1213
1214 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1215 "(svm:source, svm:uuid) ",
1216 "from the following URLs:\n" );
1217 sub read_svm_props {
1218 my ($self, $ra, $path, $r) = @_;
1219 my $props = ($ra->get_dir($path, $r))[2];
1220 my $src = $props->{'svm:source'};
1221 my $uuid = $props->{'svm:uuid'};
1222 return undef if (!$src || !$uuid);
1223
1224 chomp($src, $uuid);
1225
1226 $uuid =~ m{^[0-9a-f\-]{30,}$}
1227 or die "doesn't look right - svm:uuid is '$uuid'\n";
1228
1229 # the '!' is used to mark the repos_root!/relative/path
1230 $src =~ s{/?!/?}{/};
1231 $src =~ s{/+$}{}; # no trailing slashes please
1232 # username is of no interest
1233 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1234
1235 my $replace = $ra->{url};
1236 $replace .= "/$path" if length $path;
1237
1238 my $section = "svn-remote.$self->{repo_id}";
1239 tmp_config("$section.svm-source", $src);
1240 tmp_config("$section.svm-replace", $replace);
1241 tmp_config("$section.svm-uuid", $uuid);
1242 $self->{svm} = {
1243 source => $src,
1244 uuid => $uuid,
1245 replace => $replace
1246 };
1247 }
1248
1249 my $r = $ra->get_latest_revnum;
1250 my $path = $self->{path};
1251 my %tried;
1252 while (length $path) {
1253 unless ($tried{"$self->{url}/$path"}) {
1254 return $ra if $self->read_svm_props($ra, $path, $r);
1255 $tried{"$self->{url}/$path"} = 1;
1256 }
1257 $path =~ s#/?[^/]+$##;
1258 }
1259 die "Path: '$path' should be ''\n" if $path ne '';
1260 return $ra if $self->read_svm_props($ra, $path, $r);
1261 $tried{"$self->{url}/$path"} = 1;
1262
1263 if ($ra->{repos_root} eq $self->{url}) {
1264 die @err, (map { " $_\n" } keys %tried), "\n";
1265 }
1266
1267 # nope, make sure we're connected to the repository root:
1268 my $ok;
1269 my @tried_b;
1270 $path = $ra->{svn_path};
1271 $ra = Git::SVN::Ra->new($ra->{repos_root});
1272 while (length $path) {
1273 unless ($tried{"$ra->{url}/$path"}) {
1274 $ok = $self->read_svm_props($ra, $path, $r);
1275 last if $ok;
1276 $tried{"$ra->{url}/$path"} = 1;
1277 }
1278 $path =~ s#/?[^/]+$##;
1279 }
1280 die "Path: '$path' should be ''\n" if $path ne '';
1281 $ok ||= $self->read_svm_props($ra, $path, $r);
1282 $tried{"$ra->{url}/$path"} = 1;
1283 if (!$ok) {
1284 die @err, (map { " $_\n" } keys %tried), "\n";
1285 }
1286 Git::SVN::Ra->new($self->{url});
1287 }
1288
1289 sub svnsync {
1290 my ($self) = @_;
1291 return $self->{svnsync} if $self->{svnsync};
1292
1293 if ($self->no_metadata) {
1294 die "Can't have both 'noMetadata' and ",
1295 "'useSvnsyncProps' options set!\n";
1296 }
1297 if ($self->rewrite_root) {
1298 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1299 "options set!\n";
1300 }
1301
1302 my $svnsync;
1303 # see if we have it in our config, first:
1304 eval {
1305 my $section = "svn-remote.$self->{repo_id}";
1306 $svnsync = {
1307 url => tmp_config('--get', "$section.svnsync-url"),
1308 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1309 }
1310 };
1311 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1312 return $self->{svnsync} = $svnsync;
1313 }
1314
1315 my $err = "useSvnsyncProps set, but failed to read " .
1316 "svnsync property: svn:sync-from-";
1317 my $rp = $self->ra->rev_proplist(0);
1318
1319 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1320 $url =~ m{^[a-z\+]+://} or
1321 die "doesn't look right - svn:sync-from-url is '$url'\n";
1322
1323 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1324 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1325 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1326
1327 my $section = "svn-remote.$self->{repo_id}";
1328 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1329 tmp_config('--add', "$section.svnsync-url", $url);
1330 return $self->{svnsync} = { url => $url, uuid => $uuid };
1331 }
1332
1333 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1334 # remote lookup (useful for 'git svn log').
1335 sub ra_uuid {
1336 my ($self) = @_;
1337 unless ($self->{ra_uuid}) {
1338 my $key = "svn-remote.$self->{repo_id}.uuid";
1339 my $uuid = eval { tmp_config('--get', $key) };
1340 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1341 $self->{ra_uuid} = $uuid;
1342 } else {
1343 die "ra_uuid called without URL\n" unless $self->{url};
1344 $self->{ra_uuid} = $self->ra->get_uuid;
1345 tmp_config('--add', $key, $self->{ra_uuid});
1346 }
1347 }
1348 $self->{ra_uuid};
1349 }
1350
1351 sub ra {
1352 my ($self) = shift;
1353 my $ra = Git::SVN::Ra->new($self->{url});
1354 if ($self->use_svm_props && !$self->{svm}) {
1355 if ($self->no_metadata) {
1356 die "Can't have both 'noMetadata' and ",
1357 "'useSvmProps' options set!\n";
1358 } elsif ($self->use_svnsync_props) {
1359 die "Can't have both 'useSvnsyncProps' and ",
1360 "'useSvmProps' options set!\n";
1361 }
1362 $ra = $self->_set_svm_vars($ra);
1363 $self->{-want_revprops} = 1;
1364 }
1365 $ra;
1366 }
1367
1368 sub rel_path {
1369 my ($self) = @_;
1370 my $repos_root = $self->ra->{repos_root};
1371 return $self->{path} if ($self->{url} eq $repos_root);
1372 my $url = $self->{url} .
1373 (length $self->{path} ? "/$self->{path}" : $self->{path});
1374 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1375 $url;
1376 }
1377
1378 sub traverse_ignore {
1379 my ($self, $fh, $path, $r) = @_;
1380 $path =~ s#^/+##g;
1381 my $ra = $self->ra;
1382 my ($dirent, undef, $props) = $ra->get_dir($path, $r);
1383 my $p = $path;
1384 $p =~ s#^\Q$self->{path}\E(/|$)##;
1385 print $fh length $p ? "\n# $p\n" : "\n# /\n";
1386 if (my $s = $props->{'svn:ignore'}) {
1387 $s =~ s/[\r\n]+/\n/g;
1388 chomp $s;
1389 if (length $p == 0) {
1390 $s =~ s#\n#\n/$p#g;
1391 print $fh "/$s\n";
1392 } else {
1393 $s =~ s#\n#\n/$p/#g;
1394 print $fh "/$p/$s\n";
1395 }
1396 }
1397 foreach (sort keys %$dirent) {
1398 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1399 $self->traverse_ignore($fh, "$path/$_", $r);
1400 }
1401 }
1402
1403 sub last_rev { ($_[0]->last_rev_commit)[0] }
1404 sub last_commit { ($_[0]->last_rev_commit)[1] }
1405
1406 # returns the newest SVN revision number and newest commit SHA1
1407 sub last_rev_commit {
1408 my ($self) = @_;
1409 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1410 return ($self->{last_rev}, $self->{last_commit});
1411 }
1412 my $c = ::verify_ref($self->refname.'^0');
1413 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1414 my $rev = (::cmt_metadata($c))[1];
1415 if (defined $rev) {
1416 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1417 return ($rev, $c);
1418 }
1419 }
1420 my $db_path = $self->db_path;
1421 unless (-e $db_path) {
1422 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1423 return (undef, undef);
1424 }
1425 my $offset = -41; # from tail
1426 my $rl;
1427 open my $fh, '<', $db_path or croak "$db_path not readable: $!\n";
1428 sysseek($fh, $offset, 2); # don't care for errors
1429 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1430 chomp $rl;
1431 while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
1432 $offset -= 41;
1433 sysseek($fh, $offset, 2); # don't care for errors
1434 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1435 chomp $rl;
1436 }
1437 if ($c && $c ne $rl) {
1438 die "$db_path and ", $self->refname,
1439 " inconsistent!:\n$c != $rl\n";
1440 }
1441 my $rev = sysseek($fh, 0, 1) or croak $!;
1442 $rev = ($rev - 41) / 41;
1443 close $fh or croak $!;
1444 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1445 return ($rev, $c);
1446 }
1447
1448 sub get_fetch_range {
1449 my ($self, $min, $max) = @_;
1450 $max ||= $self->ra->get_latest_revnum;
1451 $min ||= $self->rev_db_max;
1452 (++$min, $max);
1453 }
1454
1455 sub tmp_config {
1456 my (@args) = @_;
1457 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1458 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1459 if (-e $old_def_config && ! -e $config) {
1460 rename $old_def_config, $config or
1461 die "Failed rename $old_def_config => $config: $!\n";
1462 }
1463 my $old_config = $ENV{GIT_CONFIG};
1464 $ENV{GIT_CONFIG} = $config;
1465 $@ = undef;
1466 my @ret = eval {
1467 unless (-f $config) {
1468 mkfile($config);
1469 open my $fh, '>', $config or
1470 die "Can't open $config: $!\n";
1471 print $fh "; This file is used internally by ",
1472 "git-svn\n" or die
1473 "Couldn't write to $config: $!\n";
1474 print $fh "; You should not have to edit it\n" or
1475 die "Couldn't write to $config: $!\n";
1476 close $fh or die "Couldn't close $config: $!\n";
1477 }
1478 command('config', @args);
1479 };
1480 my $err = $@;
1481 if (defined $old_config) {
1482 $ENV{GIT_CONFIG} = $old_config;
1483 } else {
1484 delete $ENV{GIT_CONFIG};
1485 }
1486 die $err if $err;
1487 wantarray ? @ret : $ret[0];
1488 }
1489
1490 sub tmp_index_do {
1491 my ($self, $sub) = @_;
1492 my $old_index = $ENV{GIT_INDEX_FILE};
1493 $ENV{GIT_INDEX_FILE} = $self->{index};
1494 $@ = undef;
1495 my @ret = eval {
1496 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1497 mkpath([$dir]) unless -d $dir;
1498 &$sub;
1499 };
1500 my $err = $@;
1501 if (defined $old_index) {
1502 $ENV{GIT_INDEX_FILE} = $old_index;
1503 } else {
1504 delete $ENV{GIT_INDEX_FILE};
1505 }
1506 die $err if $err;
1507 wantarray ? @ret : $ret[0];
1508 }
1509
1510 sub assert_index_clean {
1511 my ($self, $treeish) = @_;
1512
1513 $self->tmp_index_do(sub {
1514 command_noisy('read-tree', $treeish) unless -e $self->{index};
1515 my $x = command_oneline('write-tree');
1516 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1517 /^tree ($::sha1)/mo);
1518 return if $y eq $x;
1519
1520 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1521 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1522 command_noisy('read-tree', $treeish);
1523 $x = command_oneline('write-tree');
1524 if ($y ne $x) {
1525 ::fatal "trees ($treeish) $y != $x\n",
1526 "Something is seriously wrong...\n";
1527 }
1528 });
1529 }
1530
1531 sub get_commit_parents {
1532 my ($self, $log_entry) = @_;
1533 my (%seen, @ret, @tmp);
1534 # legacy support for 'set-tree'; this is only used by set_tree_cb:
1535 if (my $ip = $self->{inject_parents}) {
1536 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1537 push @tmp, $commit;
1538 }
1539 }
1540 if (my $cur = ::verify_ref($self->refname.'^0')) {
1541 push @tmp, $cur;
1542 }
1543 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1544 while (my $p = shift @tmp) {
1545 next if $seen{$p};
1546 $seen{$p} = 1;
1547 push @ret, $p;
1548 # MAXPARENT is defined to 16 in commit-tree.c:
1549 last if @ret >= 16;
1550 }
1551 if (@tmp) {
1552 die "r$log_entry->{revision}: No room for parents:\n\t",
1553 join("\n\t", @tmp), "\n";
1554 }
1555 @ret;
1556 }
1557
1558 sub rewrite_root {
1559 my ($self) = @_;
1560 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
1561 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
1562 my $rwr = eval { command_oneline(qw/config --get/, $k) };
1563 if ($rwr) {
1564 $rwr =~ s#/+$##;
1565 if ($rwr !~ m#^[a-z\+]+://#) {
1566 die "$rwr is not a valid URL (key: $k)\n";
1567 }
1568 }
1569 $self->{-rewrite_root} = $rwr;
1570 }
1571
1572 sub metadata_url {
1573 my ($self) = @_;
1574 ($self->rewrite_root || $self->{url}) .
1575 (length $self->{path} ? '/' . $self->{path} : '');
1576 }
1577
1578 sub full_url {
1579 my ($self) = @_;
1580 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1581 }
1582
1583 sub do_git_commit {
1584 my ($self, $log_entry) = @_;
1585 my $lr = $self->last_rev;
1586 if (defined $lr && $lr >= $log_entry->{revision}) {
1587 die "Last fetched revision of ", $self->refname,
1588 " was r$lr, but we are about to fetch: ",
1589 "r$log_entry->{revision}!\n";
1590 }
1591 if (my $c = $self->rev_db_get($log_entry->{revision})) {
1592 croak "$log_entry->{revision} = $c already exists! ",
1593 "Why are we refetching it?\n";
1594 }
1595 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $log_entry->{name};
1596 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} =
1597 $log_entry->{email};
1598 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1599
1600 my $tree = $log_entry->{tree};
1601 if (!defined $tree) {
1602 $tree = $self->tmp_index_do(sub {
1603 command_oneline('write-tree') });
1604 }
1605 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1606
1607 my @exec = ('git-commit-tree', $tree);
1608 foreach ($self->get_commit_parents($log_entry)) {
1609 push @exec, '-p', $_;
1610 }
1611 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1612 or croak $!;
1613 print $msg_fh $log_entry->{log} or croak $!;
1614 unless ($self->no_metadata) {
1615 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1616 or croak $!;
1617 }
1618 $msg_fh->flush == 0 or croak $!;
1619 close $msg_fh or croak $!;
1620 chomp(my $commit = do { local $/; <$out_fh> });
1621 close $out_fh or croak $!;
1622 waitpid $pid, 0;
1623 croak $? if $?;
1624 if ($commit !~ /^$::sha1$/o) {
1625 die "Failed to commit, invalid sha1: $commit\n";
1626 }
1627
1628 $self->rev_db_set($log_entry->{revision}, $commit, 1);
1629
1630 $self->{last_rev} = $log_entry->{revision};
1631 $self->{last_commit} = $commit;
1632 print "r$log_entry->{revision}";
1633 if (defined $log_entry->{svm_revision}) {
1634 print " (\@$log_entry->{svm_revision})";
1635 $self->rev_db_set($log_entry->{svm_revision}, $commit,
1636 0, $self->svm_uuid);
1637 }
1638 print " = $commit ($self->{ref_id})\n";
1639 if (defined $_repack && (--$_repack_nr == 0)) {
1640 $_repack_nr = $_repack;
1641 # repack doesn't use any arguments with spaces in them, does it?
1642 print "Running git repack $_repack_flags ...\n";
1643 command_noisy('repack', split(/\s+/, $_repack_flags));
1644 print "Done repacking\n";
1645 }
1646 return $commit;
1647 }
1648
1649 sub match_paths {
1650 my ($self, $paths, $r) = @_;
1651 return 1 if $self->{path} eq '';
1652 if (my $path = $paths->{"/$self->{path}"}) {
1653 return ($path->{action} eq 'D') ? 0 : 1;
1654 }
1655 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
1656 if (grep /$self->{path_regex}/, keys %$paths) {
1657 return 1;
1658 }
1659 my $c = '';
1660 foreach (split m#/#, $self->{path}) {
1661 $c .= "/$_";
1662 next unless ($paths->{$c} &&
1663 ($paths->{$c}->{action} =~ /^[AR]$/));
1664 if ($self->ra->check_path($self->{path}, $r) ==
1665 $SVN::Node::dir) {
1666 return 1;
1667 }
1668 }
1669 return 0;
1670 }
1671
1672 sub find_parent_branch {
1673 my ($self, $paths, $rev) = @_;
1674 return undef unless $self->follow_parent;
1675 unless (defined $paths) {
1676 my $err_handler = $SVN::Error::handler;
1677 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1678 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1679 $paths =
1680 Git::SVN::Ra::dup_changed_paths($_[0]) });
1681 $SVN::Error::handler = $err_handler;
1682 }
1683 return undef unless defined $paths;
1684
1685 # look for a parent from another branch:
1686 my @b_path_components = split m#/#, $self->rel_path;
1687 my @a_path_components;
1688 my $i;
1689 while (@b_path_components) {
1690 $i = $paths->{'/'.join('/', @b_path_components)};
1691 last if $i && defined $i->{copyfrom_path};
1692 unshift(@a_path_components, pop(@b_path_components));
1693 }
1694 return undef unless defined $i && defined $i->{copyfrom_path};
1695 my $branch_from = $i->{copyfrom_path};
1696 if (@a_path_components) {
1697 print STDERR "branch_from: $branch_from => ";
1698 $branch_from .= '/'.join('/', @a_path_components);
1699 print STDERR $branch_from, "\n";
1700 }
1701 my $r = $i->{copyfrom_rev};
1702 my $repos_root = $self->ra->{repos_root};
1703 my $url = $self->ra->{url};
1704 my $new_url = $repos_root . $branch_from;
1705 print STDERR "Found possible branch point: ",
1706 "$new_url => ", $self->full_url, ", $r\n";
1707 $branch_from =~ s#^/##;
1708 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
1709 unless ($gs) {
1710 my $ref_id = $self->{ref_id};
1711 $ref_id =~ s/\@\d+$//;
1712 $ref_id .= "\@$r";
1713 # just grow a tail if we're not unique enough :x
1714 $ref_id .= '-' while find_ref($ref_id);
1715 print STDERR "Initializing parent: $ref_id\n";
1716 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1717 }
1718 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1719 if (!defined $r0 || !defined $parent) {
1720 my ($base, $head) = parse_revision_argument(0, $r);
1721 if ($base <= $r) {
1722 $gs->fetch($base, $r);
1723 }
1724 ($r0, $parent) = $gs->last_rev_commit;
1725 }
1726 if (defined $r0 && defined $parent) {
1727 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1728 my $ed;
1729 if ($self->ra->can_do_switch) {
1730 $self->assert_index_clean($parent);
1731 print STDERR "Following parent with do_switch\n";
1732 # do_switch works with svn/trunk >= r22312, but that
1733 # is not included with SVN 1.4.3 (the latest version
1734 # at the moment), so we can't rely on it
1735 $self->{last_commit} = $parent;
1736 $ed = SVN::Git::Fetcher->new($self);
1737 $gs->ra->gs_do_switch($r0, $rev, $gs,
1738 $self->full_url, $ed)
1739 or die "SVN connection failed somewhere...\n";
1740 } else {
1741 print STDERR "Following parent with do_update\n";
1742 $ed = SVN::Git::Fetcher->new($self);
1743 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1744 or die "SVN connection failed somewhere...\n";
1745 }
1746 print STDERR "Successfully followed parent\n";
1747 return $self->make_log_entry($rev, [$parent], $ed);
1748 }
1749 return undef;
1750 }
1751
1752 sub do_fetch {
1753 my ($self, $paths, $rev) = @_;
1754 my $ed;
1755 my ($last_rev, @parents);
1756 if (my $lc = $self->last_commit) {
1757 # we can have a branch that was deleted, then re-added
1758 # under the same name but copied from another path, in
1759 # which case we'll have multiple parents (we don't
1760 # want to break the original ref, nor lose copypath info):
1761 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1762 push @{$log_entry->{parents}}, $lc;
1763 return $log_entry;
1764 }
1765 $ed = SVN::Git::Fetcher->new($self);
1766 $last_rev = $self->{last_rev};
1767 $ed->{c} = $lc;
1768 @parents = ($lc);
1769 } else {
1770 $last_rev = $rev;
1771 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1772 return $log_entry;
1773 }
1774 $ed = SVN::Git::Fetcher->new($self);
1775 }
1776 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1777 die "SVN connection failed somewhere...\n";
1778 }
1779 $self->make_log_entry($rev, \@parents, $ed);
1780 }
1781
1782 sub get_untracked {
1783 my ($self, $ed) = @_;
1784 my @out;
1785 my $h = $ed->{empty};
1786 foreach (sort keys %$h) {
1787 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1788 push @out, " $act: " . uri_encode($_);
1789 warn "W: $act: $_\n";
1790 }
1791 foreach my $t (qw/dir_prop file_prop/) {
1792 $h = $ed->{$t} or next;
1793 foreach my $path (sort keys %$h) {
1794 my $ppath = $path eq '' ? '.' : $path;
1795 foreach my $prop (sort keys %{$h->{$path}}) {
1796 next if $SKIP_PROP{$prop};
1797 my $v = $h->{$path}->{$prop};
1798 my $t_ppath_prop = "$t: " .
1799 uri_encode($ppath) . ' ' .
1800 uri_encode($prop);
1801 if (defined $v) {
1802 push @out, " +$t_ppath_prop " .
1803 uri_encode($v);
1804 } else {
1805 push @out, " -$t_ppath_prop";
1806 }
1807 }
1808 }
1809 }
1810 foreach my $t (qw/absent_file absent_directory/) {
1811 $h = $ed->{$t} or next;
1812 foreach my $parent (sort keys %$h) {
1813 foreach my $path (sort @{$h->{$parent}}) {
1814 push @out, " $t: " .
1815 uri_encode("$parent/$path");
1816 warn "W: $t: $parent/$path ",
1817 "Insufficient permissions?\n";
1818 }
1819 }
1820 }
1821 \@out;
1822 }
1823
1824 sub parse_svn_date {
1825 my $date = shift || return '+0000 1970-01-01 00:00:00';
1826 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1827 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1828 croak "Unable to parse date: $date\n";
1829 "+0000 $Y-$m-$d $H:$M:$S";
1830 }
1831
1832 sub check_author {
1833 my ($author) = @_;
1834 if (!defined $author || length $author == 0) {
1835 $author = '(no author)';
1836 }
1837 if (defined $::_authors && ! defined $::users{$author}) {
1838 die "Author: $author not defined in $::_authors file\n";
1839 }
1840 $author;
1841 }
1842
1843 sub make_log_entry {
1844 my ($self, $rev, $parents, $ed) = @_;
1845 my $untracked = $self->get_untracked($ed);
1846
1847 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1848 print $un "r$rev\n" or croak $!;
1849 print $un $_, "\n" foreach @$untracked;
1850 my %log_entry = ( parents => $parents || [], revision => $rev,
1851 log => '');
1852
1853 my $headrev;
1854 my $logged = delete $self->{logged_rev_props};
1855 if (!$logged || $self->{-want_revprops}) {
1856 my $rp = $self->ra->rev_proplist($rev);
1857 foreach (sort keys %$rp) {
1858 my $v = $rp->{$_};
1859 if (/^svn:(author|date|log)$/) {
1860 $log_entry{$1} = $v;
1861 } elsif ($_ eq 'svm:headrev') {
1862 $headrev = $v;
1863 } else {
1864 print $un " rev_prop: ", uri_encode($_), ' ',
1865 uri_encode($v), "\n";
1866 }
1867 }
1868 } else {
1869 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1870 }
1871 close $un or croak $!;
1872
1873 $log_entry{date} = parse_svn_date($log_entry{date});
1874 $log_entry{log} .= "\n";
1875 my $author = $log_entry{author} = check_author($log_entry{author});
1876 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1877 : ($author, undef);
1878 if (defined $headrev && $self->use_svm_props) {
1879 if ($self->rewrite_root) {
1880 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1881 "options set!\n";
1882 }
1883 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
1884 # we don't want "SVM: initializing mirror for junk" ...
1885 return undef if $r == 0;
1886 my $svm = $self->svm;
1887 if ($uuid ne $svm->{uuid}) {
1888 die "UUID mismatch on SVM path:\n",
1889 "expected: $svm->{uuid}\n",
1890 " got: $uuid\n";
1891 }
1892 my $full_url = $self->full_url;
1893 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1894 die "Failed to replace '$svm->{replace}' with ",
1895 "'$svm->{source}' in $full_url\n";
1896 # throw away username for storing in records
1897 remove_username($full_url);
1898 $log_entry{metadata} = "$full_url\@$r $uuid";
1899 $log_entry{svm_revision} = $r;
1900 $email ||= "$author\@$uuid"
1901 } elsif ($self->use_svnsync_props) {
1902 my $full_url = $self->svnsync->{url};
1903 $full_url .= "/$self->{path}" if length $self->{path};
1904 remove_username($full_url);
1905 my $uuid = $self->svnsync->{uuid};
1906 $log_entry{metadata} = "$full_url\@$rev $uuid";
1907 $email ||= "$author\@$uuid"
1908 } else {
1909 my $url = $self->metadata_url;
1910 remove_username($url);
1911 $log_entry{metadata} = "$url\@$rev " .
1912 $self->ra->get_uuid;
1913 $email ||= "$author\@" . $self->ra->get_uuid;
1914 }
1915 $log_entry{name} = $name;
1916 $log_entry{email} = $email;
1917 \%log_entry;
1918 }
1919
1920 sub fetch {
1921 my ($self, $min_rev, $max_rev, @parents) = @_;
1922 my ($last_rev, $last_commit) = $self->last_rev_commit;
1923 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1924 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1925 }
1926
1927 sub set_tree_cb {
1928 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1929 $self->{inject_parents} = { $rev => $tree };
1930 $self->fetch(undef, undef);
1931 }
1932
1933 sub set_tree {
1934 my ($self, $tree) = (shift, shift);
1935 my $log_entry = ::get_commit_entry($tree);
1936 unless ($self->{last_rev}) {
1937 fatal("Must have an existing revision to commit\n");
1938 }
1939 my %ed_opts = ( r => $self->{last_rev},
1940 log => $log_entry->{log},
1941 ra => $self->ra,
1942 tree_a => $self->{last_commit},
1943 tree_b => $tree,
1944 editor_cb => sub {
1945 $self->set_tree_cb($log_entry, $tree, @_) },
1946 svn_path => $self->{path} );
1947 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1948 print "No changes\nr$self->{last_rev} = $tree\n";
1949 }
1950 }
1951
1952 sub rebuild {
1953 my ($self) = @_;
1954 my $db_path = $self->db_path;
1955 return if (-e $db_path && ! -z $db_path);
1956 return unless ::verify_ref($self->refname.'^0');
1957 if (-f $self->{db_root}) {
1958 rename $self->{db_root}, $db_path or die
1959 "rename $self->{db_root} => $db_path failed: $!\n";
1960 my ($dir, $base) = ($db_path =~ m#^(.*?)/?([^/]+)$#);
1961 symlink $base, $self->{db_root} or die
1962 "symlink $base => $self->{db_root} failed: $!\n";
1963 return;
1964 }
1965 print "Rebuilding $db_path ...\n";
1966 my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1967 my $latest;
1968 my $full_url = $self->full_url;
1969 remove_username($full_url);
1970 my $svn_uuid;
1971 while (<$rev_list>) {
1972 chomp;
1973 my $c = $_;
1974 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1975 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1976 remove_username($url);
1977
1978 # ignore merges (from set-tree)
1979 next if (!defined $rev || !$uuid);
1980
1981 # if we merged or otherwise started elsewhere, this is
1982 # how we break out of it
1983 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1984 ($full_url && $url && ($url ne $full_url))) {
1985 next;
1986 }
1987 $latest ||= $rev;
1988 $svn_uuid ||= $uuid;
1989
1990 $self->rev_db_set($rev, $c);
1991 print "r$rev = $c\n";
1992 }
1993 command_close_pipe($rev_list, $ctx);
1994 print "Done rebuilding $db_path\n";
1995 }
1996
1997 # rev_db:
1998 # Tie::File seems to be prone to offset errors if revisions get sparse,
1999 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2000 # one of my favorite modules is out :< Next up would be one of the DBM
2001 # modules, but I'm not sure which is most portable... So I'll just
2002 # go with something that's plain-text, but still capable of
2003 # being randomly accessed. So here's my ultra-simple fixed-width
2004 # database. All records are 40 characters + "\n", so it's easy to seek
2005 # to a revision: (41 * rev) is the byte offset.
2006 # A record of 40 0s denotes an empty revision.
2007 # And yes, it's still pretty fast (faster than Tie::File).
2008 # These files are disposable unless noMetadata or useSvmProps is set
2009
2010 sub _rev_db_set {
2011 my ($fh, $rev, $commit) = @_;
2012 my $offset = $rev * 41;
2013 # assume that append is the common case:
2014 seek $fh, 0, 2 or croak $!;
2015 my $pos = tell $fh;
2016 if ($pos < $offset) {
2017 for (1 .. (($offset - $pos) / 41)) {
2018 print $fh (('0' x 40),"\n") or croak $!;
2019 }
2020 }
2021 seek $fh, $offset, 0 or croak $!;
2022 print $fh $commit,"\n" or croak $!;
2023 }
2024
2025 sub mkfile {
2026 my ($path) = @_;
2027 unless (-e $path) {
2028 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2029 mkpath([$dir]) unless -d $dir;
2030 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2031 close $fh or die "Couldn't close (create) $path: $!\n";
2032 }
2033 }
2034
2035 sub rev_db_set {
2036 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2037 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2038 my $db = $self->db_path($uuid);
2039 my $db_lock = "$db.lock";
2040 my $sig;
2041 if ($update_ref) {
2042 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2043 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2044 }
2045 mkfile($db);
2046
2047 $LOCKFILES{$db_lock} = 1;
2048 my $sync;
2049 # both of these options make our .rev_db file very, very important
2050 # and we can't afford to lose it because rebuild() won't work
2051 if ($self->use_svm_props || $self->no_metadata) {
2052 $sync = 1;
2053 copy($db, $db_lock) or die "rev_db_set(@_): ",
2054 "Failed to copy: ",
2055 "$db => $db_lock ($!)\n";
2056 } else {
2057 rename $db, $db_lock or die "rev_db_set(@_): ",
2058 "Failed to rename: ",
2059 "$db => $db_lock ($!)\n";
2060 }
2061 open my $fh, '+<', $db_lock or die "Couldn't open $db_lock: $!\n";
2062 _rev_db_set($fh, $rev, $commit);
2063 if ($sync) {
2064 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2065 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2066 }
2067 close $fh or croak $!;
2068 if ($update_ref) {
2069 $_head = $self;
2070 command_noisy('update-ref', '-m', "r$rev",
2071 $self->refname, $commit);
2072 }
2073 rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
2074 "$db_lock => $db ($!)\n";
2075 delete $LOCKFILES{$db_lock};
2076 if ($update_ref) {
2077 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2078 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2079 kill $sig, $$ if defined $sig;
2080 }
2081 }
2082
2083 sub rev_db_max {
2084 my ($self) = @_;
2085 $self->rebuild;
2086 my $db_path = $self->db_path;
2087 my @stat = stat $db_path or return 0;
2088 ($stat[7] % 41) == 0 or die "$db_path inconsistent size: $stat[7]\n";
2089 my $max = $stat[7] / 41;
2090 (($max > 0) ? $max - 1 : 0);
2091 }
2092
2093 sub rev_db_get {
2094 my ($self, $rev, $uuid) = @_;
2095 my $ret;
2096 my $offset = $rev * 41;
2097 my $db_path = $self->db_path($uuid);
2098 return undef unless -e $db_path;
2099 open my $fh, '<', $db_path or croak $!;
2100 if (sysseek($fh, $offset, 0) == $offset) {
2101 my $read = sysread($fh, $ret, 40);
2102 $ret = undef if ($read != 40 || $ret eq ('0'x40));
2103 }
2104 close $fh or croak $!;
2105 $ret;
2106 }
2107
2108 sub find_rev_before {
2109 my ($self, $rev, $eq_ok) = @_;
2110 --$rev unless $eq_ok;
2111 while ($rev > 0) {
2112 if (my $c = $self->rev_db_get($rev)) {
2113 return ($rev, $c);
2114 }
2115 --$rev;
2116 }
2117 return (undef, undef);
2118 }
2119
2120 sub _new {
2121 my ($class, $repo_id, $ref_id, $path) = @_;
2122 unless (defined $repo_id && length $repo_id) {
2123 $repo_id = $Git::SVN::default_repo_id;
2124 }
2125 unless (defined $ref_id && length $ref_id) {
2126 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2127 }
2128 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2129 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2130 $_[3] = $path = '' unless (defined $path);
2131 mkpath(["$ENV{GIT_DIR}/svn"]);
2132 bless {
2133 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2134 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2135 db_root => "$dir/.rev_db", repo_id => $repo_id }, $class;
2136 }
2137
2138 sub db_path {
2139 my ($self, $uuid) = @_;
2140 $uuid ||= $self->ra_uuid;
2141 "$self->{db_root}.$uuid";
2142 }
2143
2144 sub uri_encode {
2145 my ($f) = @_;
2146 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2147 $f
2148 }
2149
2150 sub remove_username {
2151 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2152 }
2153
2154 package Git::SVN::Prompt;
2155 use strict;
2156 use warnings;
2157 require SVN::Core;
2158 use vars qw/$_no_auth_cache $_username/;
2159
2160 sub simple {
2161 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2162 $may_save = undef if $_no_auth_cache;
2163 $default_username = $_username if defined $_username;
2164 if (defined $default_username && length $default_username) {
2165 if (defined $realm && length $realm) {
2166 print STDERR "Authentication realm: $realm\n";
2167 STDERR->flush;
2168 }
2169 $cred->username($default_username);
2170 } else {
2171 username($cred, $realm, $may_save, $pool);
2172 }
2173 $cred->password(_read_password("Password for '" .
2174 $cred->username . "': ", $realm));
2175 $cred->may_save($may_save);
2176 $SVN::_Core::SVN_NO_ERROR;
2177 }
2178
2179 sub ssl_server_trust {
2180 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2181 $may_save = undef if $_no_auth_cache;
2182 print STDERR "Error validating server certificate for '$realm':\n";
2183 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2184 print STDERR " - The certificate is not issued by a trusted ",
2185 "authority. Use the\n",
2186 " fingerprint to validate the certificate manually!\n";
2187 }
2188 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2189 print STDERR " - The certificate hostname does not match.\n";
2190 }
2191 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2192 print STDERR " - The certificate is not yet valid.\n";
2193 }
2194 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2195 print STDERR " - The certificate has expired.\n";
2196 }
2197 if ($failures & $SVN::Auth::SSL::OTHER) {
2198 print STDERR " - The certificate has an unknown error.\n";
2199 }
2200 printf STDERR
2201 "Certificate information:\n".
2202 " - Hostname: %s\n".
2203 " - Valid: from %s until %s\n".
2204 " - Issuer: %s\n".
2205 " - Fingerprint: %s\n",
2206 map $cert_info->$_, qw(hostname valid_from valid_until
2207 issuer_dname fingerprint);
2208 my $choice;
2209 prompt:
2210 print STDERR $may_save ?
2211 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2212 "(R)eject or accept (t)emporarily? ";
2213 STDERR->flush;
2214 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2215 if ($choice =~ /^t$/i) {
2216 $cred->may_save(undef);
2217 } elsif ($choice =~ /^r$/i) {
2218 return -1;
2219 } elsif ($may_save && $choice =~ /^p$/i) {
2220 $cred->may_save($may_save);
2221 } else {
2222 goto prompt;
2223 }
2224 $cred->accepted_failures($failures);
2225 $SVN::_Core::SVN_NO_ERROR;
2226 }
2227
2228 sub ssl_client_cert {
2229 my ($cred, $realm, $may_save, $pool) = @_;
2230 $may_save = undef if $_no_auth_cache;
2231 print STDERR "Client certificate filename: ";
2232 STDERR->flush;
2233 chomp(my $filename = <STDIN>);
2234 $cred->cert_file($filename);
2235 $cred->may_save($may_save);
2236 $SVN::_Core::SVN_NO_ERROR;
2237 }
2238
2239 sub ssl_client_cert_pw {
2240 my ($cred, $realm, $may_save, $pool) = @_;
2241 $may_save = undef if $_no_auth_cache;
2242 $cred->password(_read_password("Password: ", $realm));
2243 $cred->may_save($may_save);
2244 $SVN::_Core::SVN_NO_ERROR;
2245 }
2246
2247 sub username {
2248 my ($cred, $realm, $may_save, $pool) = @_;
2249 $may_save = undef if $_no_auth_cache;
2250 if (defined $realm && length $realm) {
2251 print STDERR "Authentication realm: $realm\n";
2252 }
2253 my $username;
2254 if (defined $_username) {
2255 $username = $_username;
2256 } else {
2257 print STDERR "Username: ";
2258 STDERR->flush;
2259 chomp($username = <STDIN>);
2260 }
2261 $cred->username($username);
2262 $cred->may_save($may_save);
2263 $SVN::_Core::SVN_NO_ERROR;
2264 }
2265
2266 sub _read_password {
2267 my ($prompt, $realm) = @_;
2268 print STDERR $prompt;
2269 STDERR->flush;
2270 require Term::ReadKey;
2271 Term::ReadKey::ReadMode('noecho');
2272 my $password = '';
2273 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2274 last if $key =~ /[\012\015]/; # \n\r
2275 $password .= $key;
2276 }
2277 Term::ReadKey::ReadMode('restore');
2278 print STDERR "\n";
2279 STDERR->flush;
2280 $password;
2281 }
2282
2283 package main;
2284
2285 {
2286 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2287 $SVN::Node::dir.$SVN::Node::unknown.
2288 $SVN::Node::none.$SVN::Node::file.
2289 $SVN::Node::dir.$SVN::Node::unknown.
2290 $SVN::Auth::SSL::CNMISMATCH.
2291 $SVN::Auth::SSL::NOTYETVALID.
2292 $SVN::Auth::SSL::EXPIRED.
2293 $SVN::Auth::SSL::UNKNOWNCA.
2294 $SVN::Auth::SSL::OTHER;
2295 }
2296
2297 package SVN::Git::Fetcher;
2298 use vars qw/@ISA/;
2299 use strict;
2300 use warnings;
2301 use Carp qw/croak/;
2302 use IO::File qw//;
2303 use Digest::MD5;
2304
2305 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2306 sub new {
2307 my ($class, $git_svn) = @_;
2308 my $self = SVN::Delta::Editor->new;
2309 bless $self, $class;
2310 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2311 $self->{empty} = {};
2312 $self->{dir_prop} = {};
2313 $self->{file_prop} = {};
2314 $self->{absent_dir} = {};
2315 $self->{absent_file} = {};
2316 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2317 $self;
2318 }
2319
2320 sub set_path_strip {
2321 my ($self, $path) = @_;
2322 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2323 }
2324
2325 sub open_root {
2326 { path => '' };
2327 }
2328
2329 sub open_directory {
2330 my ($self, $path, $pb, $rev) = @_;
2331 { path => $path };
2332 }
2333
2334 sub git_path {
2335 my ($self, $path) = @_;
2336 if ($self->{path_strip}) {
2337 $path =~ s!$self->{path_strip}!! or
2338 die "Failed to strip path '$path' ($self->{path_strip})\n";
2339 }
2340 $path;
2341 }
2342
2343 sub delete_entry {
2344 my ($self, $path, $rev, $pb) = @_;
2345
2346 my $gpath = $self->git_path($path);
2347 return undef if ($gpath eq '');
2348
2349 # remove entire directories.
2350 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2351 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2352 -r --name-only -z/,
2353 $self->{c}, '--', $gpath);
2354 local $/ = "\0";
2355 while (<$ls>) {
2356 chomp;
2357 $self->{gii}->remove($_);
2358 print "\tD\t$_\n" unless $::_q;
2359 }
2360 print "\tD\t$gpath/\n" unless $::_q;
2361 command_close_pipe($ls, $ctx);
2362 $self->{empty}->{$path} = 0
2363 } else {
2364 $self->{gii}->remove($gpath);
2365 print "\tD\t$gpath\n" unless $::_q;
2366 }
2367 undef;
2368 }
2369
2370 sub open_file {
2371 my ($self, $path, $pb, $rev) = @_;
2372 my $gpath = $self->git_path($path);
2373 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
2374 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2375 unless (defined $mode && defined $blob) {
2376 die "$path was not found in commit $self->{c} (r$rev)\n";
2377 }
2378 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2379 pool => SVN::Pool->new, action => 'M' };
2380 }
2381
2382 sub add_file {
2383 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2384 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2385 delete $self->{empty}->{$dir};
2386 { path => $path, mode_a => 100644, mode_b => 100644,
2387 pool => SVN::Pool->new, action => 'A' };
2388 }
2389
2390 sub add_directory {
2391 my ($self, $path, $cp_path, $cp_rev) = @_;
2392 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2393 delete $self->{empty}->{$dir};
2394 $self->{empty}->{$path} = 1;
2395 { path => $path };
2396 }
2397
2398 sub change_dir_prop {
2399 my ($self, $db, $prop, $value) = @_;
2400 $self->{dir_prop}->{$db->{path}} ||= {};
2401 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2402 undef;
2403 }
2404
2405 sub absent_directory {
2406 my ($self, $path, $pb) = @_;
2407 $self->{absent_dir}->{$pb->{path}} ||= [];
2408 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2409 undef;
2410 }
2411
2412 sub absent_file {
2413 my ($self, $path, $pb) = @_;
2414 $self->{absent_file}->{$pb->{path}} ||= [];
2415 push @{$self->{absent_file}->{$pb->{path}}}, $path;
2416 undef;
2417 }
2418
2419 sub change_file_prop {
2420 my ($self, $fb, $prop, $value) = @_;
2421 if ($prop eq 'svn:executable') {
2422 if ($fb->{mode_b} != 120000) {
2423 $fb->{mode_b} = defined $value ? 100755 : 100644;
2424 }
2425 } elsif ($prop eq 'svn:special') {
2426 $fb->{mode_b} = defined $value ? 120000 : 100644;
2427 } else {
2428 $self->{file_prop}->{$fb->{path}} ||= {};
2429 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2430 }
2431 undef;
2432 }
2433
2434 sub apply_textdelta {
2435 my ($self, $fb, $exp) = @_;
2436 my $fh = IO::File->new_tmpfile;
2437 $fh->autoflush(1);
2438 # $fh gets auto-closed() by SVN::TxDelta::apply(),
2439 # (but $base does not,) so dup() it for reading in close_file
2440 open my $dup, '<&', $fh or croak $!;
2441 my $base = IO::File->new_tmpfile;
2442 $base->autoflush(1);
2443 if ($fb->{blob}) {
2444 defined (my $pid = fork) or croak $!;
2445 if (!$pid) {
2446 open STDOUT, '>&', $base or croak $!;
2447 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2448 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2449 }
2450 waitpid $pid, 0;
2451 croak $? if $?;
2452
2453 if (defined $exp) {
2454 seek $base, 0, 0 or croak $!;
2455 my $md5 = Digest::MD5->new;
2456 $md5->addfile($base);
2457 my $got = $md5->hexdigest;
2458 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2459 "expected: $exp\n",
2460 " got: $got\n" if ($got ne $exp);
2461 }
2462 }
2463 seek $base, 0, 0 or croak $!;
2464 $fb->{fh} = $dup;
2465 $fb->{base} = $base;
2466 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2467 }
2468
2469 sub close_file {
2470 my ($self, $fb, $exp) = @_;
2471 my $hash;
2472 my $path = $self->git_path($fb->{path});
2473 if (my $fh = $fb->{fh}) {
2474 if (defined $exp) {
2475 seek($fh, 0, 0) or croak $!;
2476 my $md5 = Digest::MD5->new;
2477 $md5->addfile($fh);
2478 my $got = $md5->hexdigest;
2479 if ($got ne $exp) {
2480 die "Checksum mismatch: $path\n",
2481 "expected: $exp\n got: $got\n";
2482 }
2483 }
2484 sysseek($fh, 0, 0) or croak $!;
2485 if ($fb->{mode_b} == 120000) {
2486 sysread($fh, my $buf, 5) == 5 or croak $!;
2487 $buf eq 'link ' or die "$path has mode 120000",
2488 "but is not a link\n";
2489 }
2490 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2491 if (!$pid) {
2492 open STDIN, '<&', $fh or croak $!;
2493 exec qw/git-hash-object -w --stdin/ or croak $!;
2494 }
2495 chomp($hash = do { local $/; <$out> });
2496 close $out or croak $!;
2497 close $fh or croak $!;
2498 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2499 close $fb->{base} or croak $!;
2500 } else {
2501 $hash = $fb->{blob} or die "no blob information\n";
2502 }
2503 $fb->{pool}->clear;
2504 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
2505 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
2506 undef;
2507 }
2508
2509 sub abort_edit {
2510 my $self = shift;
2511 $self->{nr} = $self->{gii}->{nr};
2512 delete $self->{gii};
2513 $self->SUPER::abort_edit(@_);
2514 }
2515
2516 sub close_edit {
2517 my $self = shift;
2518 $self->{git_commit_ok} = 1;
2519 $self->{nr} = $self->{gii}->{nr};
2520 delete $self->{gii};
2521 $self->SUPER::close_edit(@_);
2522 }
2523
2524 package SVN::Git::Editor;
2525 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
2526 use strict;
2527 use warnings;
2528 use Carp qw/croak/;
2529 use IO::File;
2530 use Digest::MD5;
2531
2532 sub new {
2533 my ($class, $opts) = @_;
2534 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
2535 die "$_ required!\n" unless (defined $opts->{$_});
2536 }
2537
2538 my $pool = SVN::Pool->new;
2539 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
2540 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
2541 $opts->{r}, $mods);
2542
2543 # $opts->{ra} functions should not be used after this:
2544 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
2545 $opts->{editor_cb}, $pool);
2546 my $self = SVN::Delta::Editor->new(@ce, $pool);
2547 bless $self, $class;
2548 foreach (qw/svn_path r tree_a tree_b/) {
2549 $self->{$_} = $opts->{$_};
2550 }
2551 $self->{url} = $opts->{ra}->{url};
2552 $self->{mods} = $mods;
2553 $self->{types} = $types;
2554 $self->{pool} = $pool;
2555 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2556 $self->{rm} = { };
2557 $self->{path_prefix} = length $self->{svn_path} ?
2558 "$self->{svn_path}/" : '';
2559 return $self;
2560 }
2561
2562 sub generate_diff {
2563 my ($tree_a, $tree_b) = @_;
2564 my @diff_tree = qw(diff-tree -z -r);
2565 if ($_cp_similarity) {
2566 push @diff_tree, "-C$_cp_similarity";
2567 } else {
2568 push @diff_tree, '-C';
2569 }
2570 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
2571 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
2572 push @diff_tree, $tree_a, $tree_b;
2573 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2574 local $/ = "\0";
2575 my $state = 'meta';
2576 my @mods;
2577 while (<$diff_fh>) {
2578 chomp $_; # this gets rid of the trailing "\0"
2579 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2580 $::sha1\s($::sha1)\s
2581 ([MTCRAD])\d*$/xo) {
2582 push @mods, { mode_a => $1, mode_b => $2,
2583 sha1_b => $3, chg => $4 };
2584 if ($4 =~ /^(?:C|R)$/) {
2585 $state = 'file_a';
2586 } else {
2587 $state = 'file_b';
2588 }
2589 } elsif ($state eq 'file_a') {
2590 my $x = $mods[$#mods] or croak "Empty array\n";
2591 if ($x->{chg} !~ /^(?:C|R)$/) {
2592 croak "Error parsing $_, $x->{chg}\n";
2593 }
2594 $x->{file_a} = $_;
2595 $state = 'file_b';
2596 } elsif ($state eq 'file_b') {
2597 my $x = $mods[$#mods] or croak "Empty array\n";
2598 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2599 croak "Error parsing $_, $x->{chg}\n";
2600 }
2601 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2602 croak "Error parsing $_, $x->{chg}\n";
2603 }
2604 $x->{file_b} = $_;
2605 $state = 'meta';
2606 } else {
2607 croak "Error parsing $_\n";
2608 }
2609 }
2610 command_close_pipe($diff_fh, $ctx);
2611 \@mods;
2612 }
2613
2614 sub check_diff_paths {
2615 my ($ra, $pfx, $rev, $mods) = @_;
2616 my %types;
2617 $pfx .= '/' if length $pfx;
2618
2619 sub type_diff_paths {
2620 my ($ra, $types, $path, $rev) = @_;
2621 my @p = split m#/+#, $path;
2622 my $c = shift @p;
2623 unless (defined $types->{$c}) {
2624 $types->{$c} = $ra->check_path($c, $rev);
2625 }
2626 while (@p) {
2627 $c .= '/' . shift @p;
2628 next if defined $types->{$c};
2629 $types->{$c} = $ra->check_path($c, $rev);
2630 }
2631 }
2632
2633 foreach my $m (@$mods) {
2634 foreach my $f (qw/file_a file_b/) {
2635 next unless defined $m->{$f};
2636 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
2637 if (length $pfx.$dir && ! defined $types{$dir}) {
2638 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
2639 }
2640 }
2641 }
2642 \%types;
2643 }
2644
2645 sub split_path {
2646 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2647 }
2648
2649 sub repo_path {
2650 my ($self, $path) = @_;
2651 $self->{path_prefix}.(defined $path ? $path : '');
2652 }
2653
2654 sub url_path {
2655 my ($self, $path) = @_;
2656 $self->{url} . '/' . $self->repo_path($path);
2657 }
2658
2659 sub rmdirs {
2660 my ($self) = @_;
2661 my $rm = $self->{rm};
2662 delete $rm->{''}; # we never delete the url we're tracking
2663 return unless %$rm;
2664
2665 foreach (keys %$rm) {
2666 my @d = split m#/#, $_;
2667 my $c = shift @d;
2668 $rm->{$c} = 1;
2669 while (@d) {
2670 $c .= '/' . shift @d;
2671 $rm->{$c} = 1;
2672 }
2673 }
2674 delete $rm->{$self->{svn_path}};
2675 delete $rm->{''}; # we never delete the url we're tracking
2676 return unless %$rm;
2677
2678 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2679 $self->{tree_b});
2680 local $/ = "\0";
2681 while (<$fh>) {
2682 chomp;
2683 my @dn = split m#/#, $_;
2684 while (pop @dn) {
2685 delete $rm->{join '/', @dn};
2686 }
2687 unless (%$rm) {
2688 close $fh;
2689 return;
2690 }
2691 }
2692 command_close_pipe($fh, $ctx);
2693
2694 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2695 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2696 $self->close_directory($bat->{$d}, $p);
2697 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2698 print "\tD+\t$d/\n" unless $::_q;
2699 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2700 delete $bat->{$d};
2701 }
2702 }
2703
2704 sub open_or_add_dir {
2705 my ($self, $full_path, $baton) = @_;
2706 my $t = $self->{types}->{$full_path};
2707 if (!defined $t) {
2708 die "$full_path not known in r$self->{r} or we have a bug!\n";
2709 }
2710 if ($t == $SVN::Node::none) {
2711 return $self->add_directory($full_path, $baton,
2712 undef, -1, $self->{pool});
2713 } elsif ($t == $SVN::Node::dir) {
2714 return $self->open_directory($full_path, $baton,
2715 $self->{r}, $self->{pool});
2716 }
2717 print STDERR "$full_path already exists in repository at ",
2718 "r$self->{r} and it is not a directory (",
2719 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2720 exit 1;
2721 }
2722
2723 sub ensure_path {
2724 my ($self, $path) = @_;
2725 my $bat = $self->{bat};
2726 my $repo_path = $self->repo_path($path);
2727 return $bat->{''} unless (length $repo_path);
2728 my @p = split m#/+#, $repo_path;
2729 my $c = shift @p;
2730 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2731 while (@p) {
2732 my $c0 = $c;
2733 $c .= '/' . shift @p;
2734 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2735 }
2736 return $bat->{$c};
2737 }
2738
2739 sub A {
2740 my ($self, $m) = @_;
2741 my ($dir, $file) = split_path($m->{file_b});
2742 my $pbat = $self->ensure_path($dir);
2743 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2744 undef, -1);
2745 print "\tA\t$m->{file_b}\n" unless $::_q;
2746 $self->chg_file($fbat, $m);
2747 $self->close_file($fbat,undef,$self->{pool});
2748 }
2749
2750 sub C {
2751 my ($self, $m) = @_;
2752 my ($dir, $file) = split_path($m->{file_b});
2753 my $pbat = $self->ensure_path($dir);
2754 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2755 $self->url_path($m->{file_a}), $self->{r});
2756 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2757 $self->chg_file($fbat, $m);
2758 $self->close_file($fbat,undef,$self->{pool});
2759 }
2760
2761 sub delete_entry {
2762 my ($self, $path, $pbat) = @_;
2763 my $rpath = $self->repo_path($path);
2764 my ($dir, $file) = split_path($rpath);
2765 $self->{rm}->{$dir} = 1;
2766 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2767 }
2768
2769 sub R {
2770 my ($self, $m) = @_;
2771 my ($dir, $file) = split_path($m->{file_b});
2772 my $pbat = $self->ensure_path($dir);
2773 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2774 $self->url_path($m->{file_a}), $self->{r});
2775 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2776 $self->chg_file($fbat, $m);
2777 $self->close_file($fbat,undef,$self->{pool});
2778
2779 ($dir, $file) = split_path($m->{file_a});
2780 $pbat = $self->ensure_path($dir);
2781 $self->delete_entry($m->{file_a}, $pbat);
2782 }
2783
2784 sub M {
2785 my ($self, $m) = @_;
2786 my ($dir, $file) = split_path($m->{file_b});
2787 my $pbat = $self->ensure_path($dir);
2788 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2789 $pbat,$self->{r},$self->{pool});
2790 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2791 $self->chg_file($fbat, $m);
2792 $self->close_file($fbat,undef,$self->{pool});
2793 }
2794
2795 sub T { shift->M(@_) }
2796
2797 sub change_file_prop {
2798 my ($self, $fbat, $pname, $pval) = @_;
2799 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2800 }
2801
2802 sub chg_file {
2803 my ($self, $fbat, $m) = @_;
2804 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2805 $self->change_file_prop($fbat,'svn:executable','*');
2806 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2807 $self->change_file_prop($fbat,'svn:executable',undef);
2808 }
2809 my $fh = IO::File->new_tmpfile or croak $!;
2810 if ($m->{mode_b} =~ /^120/) {
2811 print $fh 'link ' or croak $!;
2812 $self->change_file_prop($fbat,'svn:special','*');
2813 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2814 $self->change_file_prop($fbat,'svn:special',undef);
2815 }
2816 defined(my $pid = fork) or croak $!;
2817 if (!$pid) {
2818 open STDOUT, '>&', $fh or croak $!;
2819 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2820 }
2821 waitpid $pid, 0;
2822 croak $? if $?;
2823 $fh->flush == 0 or croak $!;
2824 seek $fh, 0, 0 or croak $!;
2825
2826 my $md5 = Digest::MD5->new;
2827 $md5->addfile($fh) or croak $!;
2828 seek $fh, 0, 0 or croak $!;
2829
2830 my $exp = $md5->hexdigest;
2831 my $pool = SVN::Pool->new;
2832 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2833 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2834 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2835 $pool->clear;
2836
2837 close $fh or croak $!;
2838 }
2839
2840 sub D {
2841 my ($self, $m) = @_;
2842 my ($dir, $file) = split_path($m->{file_b});
2843 my $pbat = $self->ensure_path($dir);
2844 print "\tD\t$m->{file_b}\n" unless $::_q;
2845 $self->delete_entry($m->{file_b}, $pbat);
2846 }
2847
2848 sub close_edit {
2849 my ($self) = @_;
2850 my ($p,$bat) = ($self->{pool}, $self->{bat});
2851 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2852 next if $_ eq '';
2853 $self->close_directory($bat->{$_}, $p);
2854 }
2855 $self->close_directory($bat->{''}, $p);
2856 $self->SUPER::close_edit($p);
2857 $p->clear;
2858 }
2859
2860 sub abort_edit {
2861 my ($self) = @_;
2862 $self->SUPER::abort_edit($self->{pool});
2863 }
2864
2865 sub DESTROY {
2866 my $self = shift;
2867 $self->SUPER::DESTROY(@_);
2868 $self->{pool}->clear;
2869 }
2870
2871 # this drives the editor
2872 sub apply_diff {
2873 my ($self) = @_;
2874 my $mods = $self->{mods};
2875 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2876 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2877 my $f = $m->{chg};
2878 if (defined $o{$f}) {
2879 $self->$f($m);
2880 } else {
2881 fatal("Invalid change type: $f\n");
2882 }
2883 }
2884 $self->rmdirs if $_rmdir;
2885 if (@$mods == 0) {
2886 $self->abort_edit;
2887 } else {
2888 $self->close_edit;
2889 }
2890 return scalar @$mods;
2891 }
2892
2893 package Git::SVN::Ra;
2894 use vars qw/@ISA $config_dir $_log_window_size/;
2895 use strict;
2896 use warnings;
2897 my ($can_do_switch, %ignored_err, $RA);
2898
2899 BEGIN {
2900 # enforce temporary pool usage for some simple functions
2901 my $e;
2902 foreach (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
2903 $e .= "sub $_ {
2904 my \$self = shift;
2905 my \$pool = SVN::Pool->new;
2906 my \@ret = \$self->SUPER::$_(\@_,\$pool);
2907 \$pool->clear;
2908 wantarray ? \@ret : \$ret[0]; }\n";
2909 }
2910
2911 eval "$e; 1;" or die $@;
2912 }
2913
2914 sub new {
2915 my ($class, $url) = @_;
2916 $url =~ s!/+$!!;
2917 return $RA if ($RA && $RA->{url} eq $url);
2918
2919 SVN::_Core::svn_config_ensure($config_dir, undef);
2920 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2921 SVN::Client::get_simple_provider(),
2922 SVN::Client::get_ssl_server_trust_file_provider(),
2923 SVN::Client::get_simple_prompt_provider(
2924 \&Git::SVN::Prompt::simple, 2),
2925 SVN::Client::get_ssl_client_cert_prompt_provider(
2926 \&Git::SVN::Prompt::ssl_client_cert, 2),
2927 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2928 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2929 SVN::Client::get_username_provider(),
2930 SVN::Client::get_ssl_server_trust_prompt_provider(
2931 \&Git::SVN::Prompt::ssl_server_trust),
2932 SVN::Client::get_username_prompt_provider(
2933 \&Git::SVN::Prompt::username, 2),
2934 ]);
2935 my $config = SVN::Core::config_get_config($config_dir);
2936 my $self = SVN::Ra->new(url => $url, auth => $baton,
2937 config => $config,
2938 pool => SVN::Pool->new,
2939 auth_provider_callbacks => $callbacks);
2940 $self->{svn_path} = $url;
2941 $self->{repos_root} = $self->get_repos_root;
2942 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
2943 $self->{cache} = { check_path => { r => 0, data => {} },
2944 get_dir => { r => 0, data => {} } };
2945 $RA = bless $self, $class;
2946 }
2947
2948 sub check_path {
2949 my ($self, $path, $r) = @_;
2950 my $cache = $self->{cache}->{check_path};
2951 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
2952 return $cache->{data}->{$path};
2953 }
2954 my $pool = SVN::Pool->new;
2955 my $t = $self->SUPER::check_path($path, $r, $pool);
2956 $pool->clear;
2957 if ($r != $cache->{r}) {
2958 %{$cache->{data}} = ();
2959 $cache->{r} = $r;
2960 }
2961 $cache->{data}->{$path} = $t;
2962 }
2963
2964 sub get_dir {
2965 my ($self, $dir, $r) = @_;
2966 my $cache = $self->{cache}->{get_dir};
2967 if ($r == $cache->{r}) {
2968 if (my $x = $cache->{data}->{$dir}) {
2969 return wantarray ? @$x : $x->[0];
2970 }
2971 }
2972 my $pool = SVN::Pool->new;
2973 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
2974 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
2975 $pool->clear;
2976 if ($r != $cache->{r}) {
2977 %{$cache->{data}} = ();
2978 $cache->{r} = $r;
2979 }
2980 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
2981 wantarray ? (\%dirents, $r, $props) : \%dirents;
2982 }
2983
2984 sub DESTROY {
2985 # do not call the real DESTROY since we store ourselves in $RA
2986 }
2987
2988 sub get_log {
2989 my ($self, @args) = @_;
2990 my $pool = SVN::Pool->new;
2991 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2992 my $ret = $self->SUPER::get_log(@args, $pool);
2993 $pool->clear;
2994 $ret;
2995 }
2996
2997 sub get_commit_editor {
2998 my ($self, $log, $cb, $pool) = @_;
2999 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3000 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3001 }
3002
3003 sub gs_do_update {
3004 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3005 my $new = ($rev_a == $rev_b);
3006 my $path = $gs->{path};
3007
3008 if ($new && -e $gs->{index}) {
3009 unlink $gs->{index} or die
3010 "Couldn't unlink index: $gs->{index}: $!\n";
3011 }
3012 my $pool = SVN::Pool->new;
3013 $editor->set_path_strip($path);
3014 my (@pc) = split m#/#, $path;
3015 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3016 1, $editor, $pool);
3017 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3018
3019 # Since we can't rely on svn_ra_reparent being available, we'll
3020 # just have to do some magic with set_path to make it so
3021 # we only want a partial path.
3022 my $sp = '';
3023 my $final = join('/', @pc);
3024 while (@pc) {
3025 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3026 $sp .= '/' if length $sp;
3027 $sp .= shift @pc;
3028 }
3029 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3030
3031 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3032
3033 $reporter->finish_report($pool);
3034 $pool->clear;
3035 $editor->{git_commit_ok};
3036 }
3037
3038 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3039 # svn_ra_reparent didn't work before 1.4)
3040 sub gs_do_switch {
3041 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3042 my $path = $gs->{path};
3043 my $pool = SVN::Pool->new;
3044
3045 my $full_url = $self->{url};
3046 my $old_url = $full_url;
3047 $full_url .= "/$path" if length $path;
3048 my ($ra, $reparented);
3049 if ($old_url ne $full_url) {
3050 if ($old_url !~ m#^svn(\+ssh)?://#) {
3051 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3052 $pool);
3053 $self->{url} = $full_url;
3054 $reparented = 1;
3055 } else {
3056 $ra = Git::SVN::Ra->new($full_url);
3057 }
3058 }
3059 $ra ||= $self;
3060 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3061 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3062 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3063 $reporter->finish_report($pool);
3064
3065 if ($reparented) {
3066 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3067 $self->{url} = $old_url;
3068 }
3069
3070 $pool->clear;
3071 $editor->{git_commit_ok};
3072 }
3073
3074 sub gs_fetch_loop_common {
3075 my ($self, $base, $head, $gsv, $globs) = @_;
3076 return if ($base > $head);
3077 my $inc = $_log_window_size;
3078 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3079 my %common;
3080 my $common_max = scalar @$gsv;
3081
3082 foreach my $gs (@$gsv) {
3083 my @tmp = split m#/#, $gs->{path};
3084 my $p = '';
3085 foreach (@tmp) {
3086 $p .= length($p) ? "/$_" : $_;
3087 $common{$p} ||= 0;
3088 $common{$p}++;
3089 }
3090 }
3091 $globs ||= [];
3092 $common_max += scalar @$globs;
3093 foreach my $glob (@$globs) {
3094 my @tmp = split m#/#, $glob->{path}->{left};
3095 my $p = '';
3096 foreach (@tmp) {
3097 $p .= length($p) ? "/$_" : $_;
3098 $common{$p} ||= 0;
3099 $common{$p}++;
3100 }
3101 }
3102
3103 my $longest_path = '';
3104 foreach (sort {length $b <=> length $a} keys %common) {
3105 if ($common{$_} == $common_max) {
3106 $longest_path = $_;
3107 last;
3108 }
3109 }
3110 while (1) {
3111 my %revs;
3112 my $err;
3113 my $err_handler = $SVN::Error::handler;
3114 $SVN::Error::handler = sub {
3115 ($err) = @_;
3116 skip_unknown_revs($err);
3117 };
3118 sub _cb {
3119 my ($paths, $r, $author, $date, $log) = @_;
3120 [ dup_changed_paths($paths),
3121 { author => $author, date => $date, log => $log } ];
3122 }
3123 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3124 sub { $revs{$_[1]} = _cb(@_) });
3125 if ($err && $max >= $head) {
3126 print STDERR "Path '$longest_path' ",
3127 "was probably deleted:\n",
3128 $err->expanded_message,
3129 "\nWill attempt to follow ",
3130 "revisions r$min .. r$max ",
3131 "committed before the deletion\n";
3132 my $hi = $max;
3133 while (--$hi >= $min) {
3134 my $ok;
3135 $self->get_log([$longest_path], $min, $hi,
3136 0, 1, 1, sub {
3137 $ok ||= $_[1];
3138 $revs{$_[1]} = _cb(@_) });
3139 if ($ok) {
3140 print STDERR "r$min .. r$ok OK\n";
3141 last;
3142 }
3143 }
3144 }
3145 $SVN::Error::handler = $err_handler;
3146
3147 my %exists = map { $_->{path} => $_ } @$gsv;
3148 foreach my $r (sort {$a <=> $b} keys %revs) {
3149 my ($paths, $logged) = @{$revs{$r}};
3150
3151 foreach my $gs ($self->match_globs(\%exists, $paths,
3152 $globs, $r)) {
3153 if ($gs->rev_db_max >= $r) {
3154 next;
3155 }
3156 next unless $gs->match_paths($paths, $r);
3157 $gs->{logged_rev_props} = $logged;
3158 if (my $last_commit = $gs->last_commit) {
3159 $gs->assert_index_clean($last_commit);
3160 }
3161 my $log_entry = $gs->do_fetch($paths, $r);
3162 if ($log_entry) {
3163 $gs->do_git_commit($log_entry);
3164 }
3165 }
3166 foreach my $g (@$globs) {
3167 my $k = "svn-remote.$g->{remote}." .
3168 "$g->{t}-maxRev";
3169 Git::SVN::tmp_config($k, $r);
3170 }
3171 }
3172 # pre-fill the .rev_db since it'll eventually get filled in
3173 # with '0' x40 if something new gets committed
3174 foreach my $gs (@$gsv) {
3175 next if defined $gs->rev_db_get($max);
3176 $gs->rev_db_set($max, 0 x40);
3177 }
3178 foreach my $g (@$globs) {
3179 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3180 Git::SVN::tmp_config($k, $max);
3181 }
3182 last if $max >= $head;
3183 $min = $max + 1;
3184 $max += $inc;
3185 $max = $head if ($max > $head);
3186 }
3187 }
3188
3189 sub match_globs {
3190 my ($self, $exists, $paths, $globs, $r) = @_;
3191
3192 sub get_dir_check {
3193 my ($self, $exists, $g, $r) = @_;
3194 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3195 return unless scalar @x == 3;
3196 my $dirents = $x[0];
3197 foreach my $de (keys %$dirents) {
3198 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3199 my $p = $g->{path}->full_path($de);
3200 next if $exists->{$p};
3201 next if (length $g->{path}->{right} &&
3202 ($self->check_path($p, $r) !=
3203 $SVN::Node::dir));
3204 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3205 $g->{ref}->full_path($de), 1);
3206 }
3207 }
3208 foreach my $g (@$globs) {
3209 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3210 if ($path->{action} =~ /^[AR]$/) {
3211 get_dir_check($self, $exists, $g, $r);
3212 }
3213 }
3214 foreach (keys %$paths) {
3215 if (/$g->{path}->{left_regex}/ &&
3216 !/$g->{path}->{regex}/) {
3217 next if $paths->{$_}->{action} !~ /^[AR]$/;
3218 get_dir_check($self, $exists, $g, $r);
3219 }
3220 next unless /$g->{path}->{regex}/;
3221 my $p = $1;
3222 my $pathname = $g->{path}->full_path($p);
3223 next if $exists->{$pathname};
3224 next if ($self->check_path($pathname, $r) !=
3225 $SVN::Node::dir);
3226 $exists->{$pathname} = Git::SVN->init(
3227 $self->{url}, $pathname, undef,
3228 $g->{ref}->full_path($p), 1);
3229 }
3230 my $c = '';
3231 foreach (split m#/#, $g->{path}->{left}) {
3232 $c .= "/$_";
3233 next unless ($paths->{$c} &&
3234 ($paths->{$c}->{action} =~ /^[AR]$/));
3235 get_dir_check($self, $exists, $g, $r);
3236 }
3237 }
3238 values %$exists;
3239 }
3240
3241 sub minimize_url {
3242 my ($self) = @_;
3243 return $self->{url} if ($self->{url} eq $self->{repos_root});
3244 my $url = $self->{repos_root};
3245 my @components = split(m!/!, $self->{svn_path});
3246 my $c = '';
3247 do {
3248 $url .= "/$c" if length $c;
3249 eval { (ref $self)->new($url)->get_latest_revnum };
3250 } while ($@ && ($c = shift @components));
3251 $url;
3252 }
3253
3254 sub can_do_switch {
3255 my $self = shift;
3256 unless (defined $can_do_switch) {
3257 my $pool = SVN::Pool->new;
3258 my $rep = eval {
3259 $self->do_switch(1, '', 0, $self->{url},
3260 SVN::Delta::Editor->new, $pool);
3261 };
3262 if ($@) {
3263 $can_do_switch = 0;
3264 } else {
3265 $rep->abort_report($pool);
3266 $can_do_switch = 1;
3267 }
3268 $pool->clear;
3269 }
3270 $can_do_switch;
3271 }
3272
3273 sub skip_unknown_revs {
3274 my ($err) = @_;
3275 my $errno = $err->apr_err();
3276 # Maybe the branch we're tracking didn't
3277 # exist when the repo started, so it's
3278 # not an error if it doesn't, just continue
3279 #
3280 # Wonderfully consistent library, eh?
3281 # 160013 - svn:// and file://
3282 # 175002 - http(s)://
3283 # 175007 - http(s):// (this repo required authorization, too...)
3284 # More codes may be discovered later...
3285 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3286 my $err_key = $err->expanded_message;
3287 # revision numbers change every time, filter them out
3288 $err_key =~ s/\d+/\0/g;
3289 $err_key = "$errno\0$err_key";
3290 unless ($ignored_err{$err_key}) {
3291 warn "W: Ignoring error from SVN, path probably ",
3292 "does not exist: ($errno): ",
3293 $err->expanded_message,"\n";
3294 $ignored_err{$err_key} = 1;
3295 }
3296 return;
3297 }
3298 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3299 }
3300
3301 # svn_log_changed_path_t objects passed to get_log are likely to be
3302 # overwritten even if only the refs are copied to an external variable,
3303 # so we should dup the structures in their entirety. Using an externally
3304 # passed pool (instead of our temporary and quickly cleared pool in
3305 # Git::SVN::Ra) does not help matters at all...
3306 sub dup_changed_paths {
3307 my ($paths) = @_;
3308 return undef unless $paths;
3309 my %ret;
3310 foreach my $p (keys %$paths) {
3311 my $i = $paths->{$p};
3312 my %s = map { $_ => $i->$_ }
3313 qw/copyfrom_path copyfrom_rev action/;
3314 $ret{$p} = \%s;
3315 }
3316 \%ret;
3317 }
3318
3319 package Git::SVN::Log;
3320 use strict;
3321 use warnings;
3322 use POSIX qw/strftime/;
3323 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
3324 %rusers $show_commit $incremental/;
3325 my $l_fmt;
3326
3327 sub cmt_showable {
3328 my ($c) = @_;
3329 return 1 if defined $c->{r};
3330
3331 # big commit message got truncated by the 16k pretty buffer in rev-list
3332 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
3333 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
3334 @{$c->{l}} = ();
3335 my @log = command(qw/cat-file commit/, $c->{c});
3336
3337 # shift off the headers
3338 shift @log while ($log[0] ne '');
3339 shift @log;
3340
3341 # TODO: make $c->{l} not have a trailing newline in the future
3342 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
3343
3344 (undef, $c->{r}, undef) = ::extract_metadata(
3345 (grep(/^git-svn-id: /, @log))[-1]);
3346 }
3347 return defined $c->{r};
3348 }
3349
3350 sub log_use_color {
3351 return 1 if $color;
3352 my ($dc, $dcvar);
3353 $dcvar = 'color.diff';
3354 $dc = `git-config --get $dcvar`;
3355 if ($dc eq '') {
3356 # nothing at all; fallback to "diff.color"
3357 $dcvar = 'diff.color';
3358 $dc = `git-config --get $dcvar`;
3359 }
3360 chomp($dc);
3361 if ($dc eq 'auto') {
3362 my $pc;
3363 $pc = `git-config --get color.pager`;
3364 if ($pc eq '') {
3365 # does not have it -- fallback to pager.color
3366 $pc = `git-config --bool --get pager.color`;
3367 }
3368 else {
3369 $pc = `git-config --bool --get color.pager`;
3370 if ($?) {
3371 $pc = 'false';
3372 }
3373 }
3374 chomp($pc);
3375 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
3376 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
3377 }
3378 return 0;
3379 }
3380 return 0 if $dc eq 'never';
3381 return 1 if $dc eq 'always';
3382 chomp($dc = `git-config --bool --get $dcvar`);
3383 return ($dc eq 'true');
3384 }
3385
3386 sub git_svn_log_cmd {
3387 my ($r_min, $r_max, @args) = @_;
3388 my $head = 'HEAD';
3389 foreach my $x (@args) {
3390 last if $x eq '--';
3391 next unless ::verify_ref("$x^0");
3392 $head = $x;
3393 last;
3394 }
3395
3396 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
3397 $gs ||= Git::SVN->_new;
3398 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
3399 $gs->refname);
3400 push @cmd, '-r' unless $non_recursive;
3401 push @cmd, qw/--raw --name-status/ if $verbose;
3402 push @cmd, '--color' if log_use_color();
3403 return @cmd unless defined $r_max;
3404 if ($r_max == $r_min) {
3405 push @cmd, '--max-count=1';
3406 if (my $c = $gs->rev_db_get($r_max)) {
3407 push @cmd, $c;
3408 }
3409 } else {
3410 my ($c_min, $c_max);
3411 $c_max = $gs->rev_db_get($r_max);
3412 $c_min = $gs->rev_db_get($r_min);
3413 if (defined $c_min && defined $c_max) {
3414 if ($r_max > $r_max) {
3415 push @cmd, "$c_min..$c_max";
3416 } else {
3417 push @cmd, "$c_max..$c_min";
3418 }
3419 } elsif ($r_max > $r_min) {
3420 push @cmd, $c_max;
3421 } else {
3422 push @cmd, $c_min;
3423 }
3424 }
3425 return @cmd;
3426 }
3427
3428 # adapted from pager.c
3429 sub config_pager {
3430 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
3431 if (!defined $pager) {
3432 $pager = 'less';
3433 } elsif (length $pager == 0 || $pager eq 'cat') {
3434 $pager = undef;
3435 }
3436 }
3437
3438 sub run_pager {
3439 return unless -t *STDOUT;
3440 pipe my $rfd, my $wfd or return;
3441 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
3442 if (!$pid) {
3443 open STDOUT, '>&', $wfd or
3444 ::fatal "Can't redirect to stdout: $!\n";
3445 return;
3446 }
3447 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
3448 $ENV{LESS} ||= 'FRSX';
3449 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
3450 }
3451
3452 sub tz_to_s_offset {
3453 my ($tz) = @_;
3454 $tz =~ s/(\d\d)$//;
3455 return ($1 * 60) + ($tz * 3600);
3456 }
3457
3458 sub get_author_info {
3459 my ($dest, $author, $t, $tz) = @_;
3460 $author =~ s/(?:^\s*|\s*$)//g;
3461 $dest->{a_raw} = $author;
3462 my $au;
3463 if ($::_authors) {
3464 $au = $rusers{$author} || undef;
3465 }
3466 if (!$au) {
3467 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
3468 }
3469 $dest->{t} = $t;
3470 $dest->{tz} = $tz;
3471 $dest->{a} = $au;
3472 # Date::Parse isn't in the standard Perl distro :(
3473 if ($tz =~ s/^\+//) {
3474 $t += tz_to_s_offset($tz);
3475 } elsif ($tz =~ s/^\-//) {
3476 $t -= tz_to_s_offset($tz);
3477 }
3478 $dest->{t_utc} = $t;
3479 }
3480
3481 sub process_commit {
3482 my ($c, $r_min, $r_max, $defer) = @_;
3483 if (defined $r_min && defined $r_max) {
3484 if ($r_min == $c->{r} && $r_min == $r_max) {
3485 show_commit($c);
3486 return 0;
3487 }
3488 return 1 if $r_min == $r_max;
3489 if ($r_min < $r_max) {
3490 # we need to reverse the print order
3491 return 0 if (defined $limit && --$limit < 0);
3492 push @$defer, $c;
3493 return 1;
3494 }
3495 if ($r_min != $r_max) {
3496 return 1 if ($r_min < $c->{r});
3497 return 1 if ($r_max > $c->{r});
3498 }
3499 }
3500 return 0 if (defined $limit && --$limit < 0);
3501 show_commit($c);
3502 return 1;
3503 }
3504
3505 sub show_commit {
3506 my $c = shift;
3507 if ($oneline) {
3508 my $x = "\n";
3509 if (my $l = $c->{l}) {
3510 while ($l->[0] =~ /^\s*$/) { shift @$l }
3511 $x = $l->[0];
3512 }
3513 $l_fmt ||= 'A' . length($c->{r});
3514 print 'r',pack($l_fmt, $c->{r}),' | ';
3515 print "$c->{c} | " if $show_commit;
3516 print $x;
3517 } else {
3518 show_commit_normal($c);
3519 }
3520 }
3521
3522 sub show_commit_changed_paths {
3523 my ($c) = @_;
3524 return unless $c->{changed};
3525 print "Changed paths:\n", @{$c->{changed}};
3526 }
3527
3528 sub show_commit_normal {
3529 my ($c) = @_;
3530 print '-' x72, "\nr$c->{r} | ";
3531 print "$c->{c} | " if $show_commit;
3532 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
3533 localtime($c->{t_utc})), ' | ';
3534 my $nr_line = 0;
3535
3536 if (my $l = $c->{l}) {
3537 while ($l->[$#$l] eq "\n" && $#$l > 0
3538 && $l->[($#$l - 1)] eq "\n") {
3539 pop @$l;
3540 }
3541 $nr_line = scalar @$l;
3542 if (!$nr_line) {
3543 print "1 line\n\n\n";
3544 } else {
3545 if ($nr_line == 1) {
3546 $nr_line = '1 line';
3547 } else {
3548 $nr_line .= ' lines';
3549 }
3550 print $nr_line, "\n";
3551 show_commit_changed_paths($c);
3552 print "\n";
3553 print $_ foreach @$l;
3554 }
3555 } else {
3556 print "1 line\n";
3557 show_commit_changed_paths($c);
3558 print "\n";
3559
3560 }
3561 foreach my $x (qw/raw stat diff/) {
3562 if ($c->{$x}) {
3563 print "\n";
3564 print $_ foreach @{$c->{$x}}
3565 }
3566 }
3567 }
3568
3569 sub cmd_show_log {
3570 my (@args) = @_;
3571 my ($r_min, $r_max);
3572 my $r_last = -1; # prevent dupes
3573 if (defined $TZ) {
3574 $ENV{TZ} = $TZ;
3575 } else {
3576 delete $ENV{TZ};
3577 }
3578 if (defined $::_revision) {
3579 if ($::_revision =~ /^(\d+):(\d+)$/) {
3580 ($r_min, $r_max) = ($1, $2);
3581 } elsif ($::_revision =~ /^\d+$/) {
3582 $r_min = $r_max = $::_revision;
3583 } else {
3584 ::fatal "-r$::_revision is not supported, use ",
3585 "standard \'git log\' arguments instead\n";
3586 }
3587 }
3588
3589 config_pager();
3590 @args = (git_svn_log_cmd($r_min, $r_max, @args), @args);
3591 my $log = command_output_pipe(@args);
3592 run_pager();
3593 my (@k, $c, $d, $stat);
3594 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
3595 while (<$log>) {
3596 if (/^${esc_color}commit ($::sha1_short)/o) {
3597 my $cmt = $1;
3598 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
3599 $r_last = $c->{r};
3600 process_commit($c, $r_min, $r_max, \@k) or
3601 goto out;
3602 }
3603 $d = undef;
3604 $c = { c => $cmt };
3605 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
3606 get_author_info($c, $1, $2, $3);
3607 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
3608 # ignore
3609 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
3610 push @{$c->{raw}}, $_;
3611 } elsif (/^${esc_color}[ACRMDT]\t/) {
3612 # we could add $SVN->{svn_path} here, but that requires
3613 # remote access at the moment (repo_path_split)...
3614 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
3615 push @{$c->{changed}}, $_;
3616 } elsif (/^${esc_color}diff /o) {
3617 $d = 1;
3618 push @{$c->{diff}}, $_;
3619 } elsif ($d) {
3620 push @{$c->{diff}}, $_;
3621 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
3622 $esc_color*[\+\-]*$esc_color$/x) {
3623 $stat = 1;
3624 push @{$c->{stat}}, $_;
3625 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
3626 push @{$c->{stat}}, $_;
3627 $stat = undef;
3628 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
3629 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
3630 } elsif (s/^${esc_color} //o) {
3631 push @{$c->{l}}, $_;
3632 }
3633 }
3634 if ($c && defined $c->{r} && $c->{r} != $r_last) {
3635 $r_last = $c->{r};
3636 process_commit($c, $r_min, $r_max, \@k);
3637 }
3638 if (@k) {
3639 my $swap = $r_max;
3640 $r_max = $r_min;
3641 $r_min = $swap;
3642 process_commit($_, $r_min, $r_max) foreach reverse @k;
3643 }
3644 out:
3645 close $log;
3646 print '-' x72,"\n" unless $incremental || $oneline;
3647 }
3648
3649 package Git::SVN::Migration;
3650 # these version numbers do NOT correspond to actual version numbers
3651 # of git nor git-svn. They are just relative.
3652 #
3653 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
3654 #
3655 # v1 layout: .git/$id/info/url, refs/remotes/$id
3656 #
3657 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
3658 #
3659 # v3 layout: .git/svn/$id, refs/remotes/$id
3660 # - info/url may remain for backwards compatibility
3661 # - this is what we migrate up to this layout automatically,
3662 # - this will be used by git svn init on single branches
3663 # v3.1 layout (auto migrated):
3664 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
3665 # for backwards compatibility
3666 #
3667 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
3668 # - this is only created for newly multi-init-ed
3669 # repositories. Similar in spirit to the
3670 # --use-separate-remotes option in git-clone (now default)
3671 # - we do not automatically migrate to this (following
3672 # the example set by core git)
3673 use strict;
3674 use warnings;
3675 use Carp qw/croak/;
3676 use File::Path qw/mkpath/;
3677 use File::Basename qw/dirname basename/;
3678 use vars qw/$_minimize/;
3679
3680 sub migrate_from_v0 {
3681 my $git_dir = $ENV{GIT_DIR};
3682 return undef unless -d $git_dir;
3683 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3684 my $migrated = 0;
3685 while (<$fh>) {
3686 chomp;
3687 my ($id, $orig_ref) = ($_, $_);
3688 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
3689 next unless -f "$git_dir/$id/info/url";
3690 my $new_ref = "refs/remotes/$id";
3691 if (::verify_ref("$new_ref^0")) {
3692 print STDERR "W: $orig_ref is probably an old ",
3693 "branch used by an ancient version of ",
3694 "git-svn.\n",
3695 "However, $new_ref also exists.\n",
3696 "We will not be able ",
3697 "to use this branch until this ",
3698 "ambiguity is resolved.\n";
3699 next;
3700 }
3701 print STDERR "Migrating from v0 layout...\n" if !$migrated;
3702 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
3703 command_noisy('update-ref', $new_ref, $orig_ref);
3704 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
3705 $migrated++;
3706 }
3707 command_close_pipe($fh, $ctx);
3708 print STDERR "Done migrating from v0 layout...\n" if $migrated;
3709 $migrated;
3710 }
3711
3712 sub migrate_from_v1 {
3713 my $git_dir = $ENV{GIT_DIR};
3714 my $migrated = 0;
3715 return $migrated unless -d $git_dir;
3716 my $svn_dir = "$git_dir/svn";
3717
3718 # just in case somebody used 'svn' as their $id at some point...
3719 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
3720
3721 print STDERR "Migrating from a git-svn v1 layout...\n";
3722 mkpath([$svn_dir]);
3723 print STDERR "Data from a previous version of git-svn exists, but\n\t",
3724 "$svn_dir\n\t(required for this version ",
3725 "($::VERSION) of git-svn) does not. exist\n";
3726 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3727 while (<$fh>) {
3728 my $x = $_;
3729 next unless $x =~ s#^refs/remotes/##;
3730 chomp $x;
3731 next unless -f "$git_dir/$x/info/url";
3732 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
3733 next unless $u;
3734 my $dn = dirname("$git_dir/svn/$x");
3735 mkpath([$dn]) unless -d $dn;
3736 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
3737 mkpath(["$git_dir/svn/svn"]);
3738 print STDERR " - $git_dir/$x/info => ",
3739 "$git_dir/svn/$x/info\n";
3740 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
3741 croak "$!: $x";
3742 # don't worry too much about these, they probably
3743 # don't exist with repos this old (save for index,
3744 # and we can easily regenerate that)
3745 foreach my $f (qw/unhandled.log index .rev_db/) {
3746 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
3747 }
3748 } else {
3749 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
3750 rename "$git_dir/$x", "$git_dir/svn/$x" or
3751 croak "$!: $x";
3752 }
3753 $migrated++;
3754 }
3755 command_close_pipe($fh, $ctx);
3756 print STDERR "Done migrating from a git-svn v1 layout\n";
3757 $migrated;
3758 }
3759
3760 sub read_old_urls {
3761 my ($l_map, $pfx, $path) = @_;
3762 my @dir;
3763 foreach (<$path/*>) {
3764 if (-r "$_/info/url") {
3765 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
3766 my $ref_id = $pfx . basename $_;
3767 my $url = ::file_to_s("$_/info/url");
3768 $l_map->{$ref_id} = $url;
3769 } elsif (-d $_) {
3770 push @dir, $_;
3771 }
3772 }
3773 foreach (@dir) {
3774 my $x = $_;
3775 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
3776 read_old_urls($l_map, $x, $_);
3777 }
3778 }
3779
3780 sub migrate_from_v2 {
3781 my @cfg = command(qw/config -l/);
3782 return if grep /^svn-remote\..+\.url=/, @cfg;
3783 my %l_map;
3784 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
3785 my $migrated = 0;
3786
3787 foreach my $ref_id (sort keys %l_map) {
3788 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
3789 if ($@) {
3790 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
3791 }
3792 $migrated++;
3793 }
3794 $migrated;
3795 }
3796
3797 sub minimize_connections {
3798 my $r = Git::SVN::read_all_remotes();
3799 my $new_urls = {};
3800 my $root_repos = {};
3801 foreach my $repo_id (keys %$r) {
3802 my $url = $r->{$repo_id}->{url} or next;
3803 my $fetch = $r->{$repo_id}->{fetch} or next;
3804 my $ra = Git::SVN::Ra->new($url);
3805
3806 # skip existing cases where we already connect to the root
3807 if (($ra->{url} eq $ra->{repos_root}) ||
3808 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
3809 $repo_id)) {
3810 $root_repos->{$ra->{url}} = $repo_id;
3811 next;
3812 }
3813
3814 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
3815 my $root_path = $ra->{url};
3816 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
3817 foreach my $path (keys %$fetch) {
3818 my $ref_id = $fetch->{$path};
3819 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
3820
3821 # make sure we can read when connecting to
3822 # a higher level of a repository
3823 my ($last_rev, undef) = $gs->last_rev_commit;
3824 if (!defined $last_rev) {
3825 $last_rev = eval {
3826 $root_ra->get_latest_revnum;
3827 };
3828 next if $@;
3829 }
3830 my $new = $root_path;
3831 $new .= length $path ? "/$path" : '';
3832 eval {
3833 $root_ra->get_log([$new], $last_rev, $last_rev,
3834 0, 0, 1, sub { });
3835 };
3836 next if $@;
3837 $new_urls->{$ra->{repos_root}}->{$new} =
3838 { ref_id => $ref_id,
3839 old_repo_id => $repo_id,
3840 old_path => $path };
3841 }
3842 }
3843
3844 my @emptied;
3845 foreach my $url (keys %$new_urls) {
3846 # see if we can re-use an existing [svn-remote "repo_id"]
3847 # instead of creating a(n ugly) new section:
3848 my $repo_id = $root_repos->{$url} ||
3849 Git::SVN::sanitize_remote_name($url);
3850
3851 my $fetch = $new_urls->{$url};
3852 foreach my $path (keys %$fetch) {
3853 my $x = $fetch->{$path};
3854 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
3855 my $pfx = "svn-remote.$x->{old_repo_id}";
3856
3857 my $old_fetch = quotemeta("$x->{old_path}:".
3858 "refs/remotes/$x->{ref_id}");
3859 command_noisy(qw/config --unset/,
3860 "$pfx.fetch", '^'. $old_fetch . '$');
3861 delete $r->{$x->{old_repo_id}}->
3862 {fetch}->{$x->{old_path}};
3863 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3864 command_noisy(qw/config --unset/,
3865 "$pfx.url");
3866 push @emptied, $x->{old_repo_id}
3867 }
3868 }
3869 }
3870 if (@emptied) {
3871 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3872 "$ENV{GIT_DIR}/config";
3873 print STDERR <<EOF;
3874 The following [svn-remote] sections in your config file ($file) are empty
3875 and can be safely removed:
3876 EOF
3877 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3878 }
3879 }
3880
3881 sub migration_check {
3882 migrate_from_v0();
3883 migrate_from_v1();
3884 migrate_from_v2();
3885 minimize_connections() if $_minimize;
3886 }
3887
3888 package Git::IndexInfo;
3889 use strict;
3890 use warnings;
3891 use Git qw/command_input_pipe command_close_pipe/;
3892
3893 sub new {
3894 my ($class) = @_;
3895 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
3896 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
3897 }
3898
3899 sub remove {
3900 my ($self, $path) = @_;
3901 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
3902 return ++$self->{nr};
3903 }
3904 undef;
3905 }
3906
3907 sub update {
3908 my ($self, $mode, $hash, $path) = @_;
3909 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
3910 return ++$self->{nr};
3911 }
3912 undef;
3913 }
3914
3915 sub DESTROY {
3916 my ($self) = @_;
3917 command_close_pipe($self->{gui}, $self->{ctx});
3918 }
3919
3920 package Git::SVN::GlobSpec;
3921 use strict;
3922 use warnings;
3923
3924 sub new {
3925 my ($class, $glob) = @_;
3926 my $re = $glob;
3927 $re =~ s!/+$!!g; # no need for trailing slashes
3928 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
3929 my ($left, $right) = ($1, $2);
3930 if ($nr > 1) {
3931 die "Only one '*' wildcard expansion ",
3932 "is supported (got $nr): '$glob'\n";
3933 } elsif ($nr == 0) {
3934 die "One '*' is needed for glob: '$glob'\n";
3935 }
3936 $re = quotemeta($left) . $re . quotemeta($right);
3937 if (length $left && !($left =~ s!/+$!!g)) {
3938 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
3939 }
3940 if (length $right && !($right =~ s!^/+!!g)) {
3941 die "Missing leading '/' on right side of: '$glob' ($right)\n";
3942 }
3943 my $left_re = qr/^\/\Q$left\E(\/|$)/;
3944 bless { left => $left, right => $right, left_regex => $left_re,
3945 regex => qr/$re/, glob => $glob }, $class;
3946 }
3947
3948 sub full_path {
3949 my ($self, $path) = @_;
3950 return (length $self->{left} ? "$self->{left}/" : '') .
3951 $path . (length $self->{right} ? "/$self->{right}" : '');
3952 }
3953
3954 __END__
3955
3956 Data structures:
3957
3958
3959 $remotes = { # returned by read_all_remotes()
3960 'svn' => {
3961 # svn-remote.svn.url=https://svn.musicpd.org
3962 url => 'https://svn.musicpd.org',
3963 # svn-remote.svn.fetch=mpd/trunk:trunk
3964 fetch => {
3965 'mpd/trunk' => 'trunk',
3966 },
3967 # svn-remote.svn.tags=mpd/tags/*:tags/*
3968 tags => {
3969 path => {
3970 left => 'mpd/tags',
3971 right => '',
3972 regex => qr!mpd/tags/([^/]+)$!,
3973 glob => 'tags/*',
3974 },
3975 ref => {
3976 left => 'tags',
3977 right => '',
3978 regex => qr!tags/([^/]+)$!,
3979 glob => 'tags/*',
3980 },
3981 }
3982 }
3983 };
3984
3985 $log_entry hashref as returned by libsvn_log_entry()
3986 {
3987 log => 'whitespace-formatted log entry
3988 ', # trailing newline is preserved
3989 revision => '8', # integer
3990 date => '2004-02-24T17:01:44.108345Z', # commit date
3991 author => 'committer name'
3992 };
3993
3994
3995 # this is generated by generate_diff();
3996 @mods = array of diff-index line hashes, each element represents one line
3997 of diff-index output
3998
3999 diff-index line ($m hash)
4000 {
4001 mode_a => first column of diff-index output, no leading ':',
4002 mode_b => second column of diff-index output,
4003 sha1_b => sha1sum of the final blob,
4004 chg => change type [MCRADT],
4005 file_a => original file name of a file (iff chg is 'C' or 'R')
4006 file_b => new/current file name of a file (any chg)
4007 }
4008 ;
4009
4010 # retval of read_url_paths{,_all}();
4011 $l_map = {
4012 # repository root url
4013 'https://svn.musicpd.org' => {
4014 # repository path # GIT_SVN_ID
4015 'mpd/trunk' => 'trunk',
4016 'mpd/tags/0.11.5' => 'tags/0.11.5',
4017 },
4018 }
4019
4020 Notes:
4021 I don't trust the each() function on unless I created %hash myself
4022 because the internal iterator may not have started at base.
Jonathan Nieder’s miscellaneous git branches