configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specied by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--without-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 # This also implies BLK_SHA1.
 245 #
 246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 247 # /foo/bar/include and /foo/bar/lib directories.
 248 AC_ARG_WITH(openssl,
 249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 250 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 251 GIT_PARSE_WITH([openssl]))
 252
 253 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 254 # able to use Perl-compatible regular expressions.
 255 #
 256 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
 257 # /foo/bar/include and /foo/bar/lib directories.
 258 #
 259 AC_ARG_WITH(libpcre,
 260 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
 261 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 262     if test "$withval" = "no"; then
 263         USE_LIBPCRE=
 264     elif test "$withval" = "yes"; then
 265         USE_LIBPCRE=YesPlease
 266     else
 267         USE_LIBPCRE=YesPlease
 268         LIBPCREDIR=$withval
 269         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 270         GIT_CONF_SUBST([LIBPCREDIR])
 271     fi)
 272 #
 273 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 274 # git-http-push are not built, and you cannot use http:// and https://
 275 # transports.
 276 #
 277 # Define CURLDIR=/foo/bar if your curl header and library files are in
 278 # /foo/bar/include and /foo/bar/lib directories.
 279 AC_ARG_WITH(curl,
 280 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 281 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 282 GIT_PARSE_WITH(curl))
 283 #
 284 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 285 # not built, and you cannot push using http:// and https:// transports.
 286 #
 287 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 288 # /foo/bar/include and /foo/bar/lib directories.
 289 AC_ARG_WITH(expat,
 290 AS_HELP_STRING([--with-expat],
 291 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 292 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 293 GIT_PARSE_WITH(expat))
 294 #
 295 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 296 # installed in /sw, but don't want GIT to link against any libraries
 297 # installed there.  If defined you may specify your own (or Fink's)
 298 # include directories and library directories by defining CFLAGS
 299 # and LDFLAGS appropriately.
 300 #
 301 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 302 # have DarwinPorts installed in /opt/local, but don't want GIT to
 303 # link against any libraries installed there.  If defined you may
 304 # specify your own (or DarwinPort's) include directories and
 305 # library directories by defining CFLAGS and LDFLAGS appropriately.
 306 #
 307 # Define NO_MMAP if you want to avoid mmap.
 308 #
 309 # Define NO_ICONV if your libc does not properly support iconv.
 310 AC_ARG_WITH(iconv,
 311 AS_HELP_STRING([--without-iconv],
 312 [if your architecture doesn't properly support iconv])
 313 AS_HELP_STRING([--with-iconv=PATH],
 314 [PATH is prefix for libiconv library and headers])
 315 AS_HELP_STRING([],
 316 [used only if you need linking with libiconv]),
 317 GIT_PARSE_WITH(iconv))
 318
 319 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 320 #
 321 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 322 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 323 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 324 # randomly break unless your underlying filesystem supports those sub-second
 325 # times (my ext3 doesn't).
 326 #
 327 # Define USE_STDEV below if you want git to care about the underlying device
 328 # change being considered an inode change from the update-index perspective.
 329
 330 #
 331 # Allow user to set ETC_GITCONFIG variable
 332 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 333                         Use VALUE instead of /etc/gitconfig as the
 334                         global git configuration file.
 335                         If VALUE is not fully qualified it will be interpreted
 336                         as a path relative to the computed prefix at runtime.)
 337
 338 #
 339 # Allow user to set ETC_GITATTRIBUTES variable
 340 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 341                         Use VALUE instead of /etc/gitattributes as the
 342                         global git attributes file.
 343                         If VALUE is not fully qualified it will be interpreted
 344                         as a path relative to the computed prefix at runtime.)
 345
 346 #
 347 # Allow user to set the default pager
 348 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 349                         Use VALUE as the fall-back pager instead of 'less'.
 350                         This is used by things like 'git log' when the user
 351                         does not specify a pager to use through alternate
 352                         methods. eg: /usr/bin/pager)
 353 #
 354 # Allow user to set the default editor
 355 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 356                         Use VALUE as the fall-back editor instead of 'vi'.
 357                         This is used by things like 'git commit' when the user
 358                         does not specify a preferred editor through other
 359                         methods. eg: /usr/bin/editor)
 360
 361 #
 362 # Define SHELL_PATH to provide path to shell.
 363 GIT_ARG_SET_PATH(shell)
 364 #
 365 # Define PERL_PATH to provide path to Perl.
 366 GIT_ARG_SET_PATH(perl)
 367 #
 368 # Define PYTHON_PATH to provide path to Python.
 369 GIT_ARG_SET_PATH(python, allow-without)
 370 #
 371 # Define ZLIB_PATH to provide path to zlib.
 372 GIT_ARG_SET_PATH(zlib)
 373 #
 374 # Declare the with-tcltk/without-tcltk options.
 375 AC_ARG_WITH(tcltk,
 376 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 377 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 378 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 379 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 380 GIT_PARSE_WITH(tcltk))
 381 #
 382
 383
 384 ## Checks for programs.
 385 AC_MSG_NOTICE([CHECKS for programs])
 386 #
 387 AC_PROG_CC([cc gcc])
 388 AC_C_INLINE
 389 case $ac_cv_c_inline in
 390   inline | yes | no)    ;;
 391   *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 392 esac
 393
 394 # which switch to pass runtime path to dynamic libraries to the linker
 395 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 396    SAVE_LDFLAGS="${LDFLAGS}"
 397    LDFLAGS="${SAVE_LDFLAGS} -R /"
 398    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 399    LDFLAGS="${SAVE_LDFLAGS}"
 400 ])
 401 if test "$git_cv_ld_dashr" = "yes"; then
 402    AC_SUBST(CC_LD_DYNPATH, [-R])
 403 else
 404    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 405       SAVE_LDFLAGS="${LDFLAGS}"
 406       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 407       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 408       LDFLAGS="${SAVE_LDFLAGS}"
 409    ])
 410    if test "$git_cv_ld_wl_rpath" = "yes"; then
 411       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 412    else
 413       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 414          SAVE_LDFLAGS="${LDFLAGS}"
 415          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 416          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 417          LDFLAGS="${SAVE_LDFLAGS}"
 418       ])
 419       if test "$git_cv_ld_rpath" = "yes"; then
 420          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 421       else
 422          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 423       fi
 424    fi
 425 fi
 426 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 427 AC_CHECK_TOOLS(AR, [gar ar], :)
 428 AC_CHECK_PROGS(TAR, [gtar tar])
 429 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 430 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 431 # or will be empty otherwise.
 432 if test -z "$NO_TCLTK"; then
 433   if test "$with_tcltk" = ""; then
 434   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 435     TCLTK_PATH=wish
 436     AC_SUBST(TCLTK_PATH)
 437   elif test "$with_tcltk" = "yes"; then
 438   # Tcl/Tk check requested.
 439     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 440   else
 441     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 442     TCLTK_PATH="$with_tcltk"
 443     AC_SUBST(TCLTK_PATH)
 444   fi
 445 fi
 446 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 447 if test -n "$ASCIIDOC"; then
 448         AC_MSG_CHECKING([for asciidoc version])
 449         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 450         case "${asciidoc_version}" in
 451         asciidoc' '8*)
 452                 AC_MSG_RESULT([${asciidoc_version}])
 453                 ;;
 454         *)
 455                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 456                 ;;
 457         esac
 458 fi
 459
 460
 461 ## Checks for libraries.
 462 AC_MSG_NOTICE([CHECKS for libraries])
 463 #
 464 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 465 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 466
 467 GIT_STASH_FLAGS($OPENSSLDIR)
 468
 469 AC_CHECK_LIB([crypto], [SHA1_Init],
 470 [NEEDS_SSL_WITH_CRYPTO=],
 471 [AC_CHECK_LIB([ssl], [SHA1_Init],
 472  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 473  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 474
 475 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 476
 477 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 478 AC_SUBST(NO_OPENSSL)
 479
 480 #
 481 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 482 # able to use Perl-compatible regular expressions.
 483 #
 484
 485 if test -n "$USE_LIBPCRE"; then
 486
 487 GIT_STASH_FLAGS($LIBPCREDIR)
 488
 489 AC_CHECK_LIB([pcre], [pcre_version],
 490 [USE_LIBPCRE=YesPlease],
 491 [USE_LIBPCRE=])
 492
 493 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 494
 495 AC_SUBST(USE_LIBPCRE)
 496
 497 fi
 498
 499 #
 500 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 501 # git-http-push are not built, and you cannot use http:// and https://
 502 # transports.
 503
 504 GIT_STASH_FLAGS($CURLDIR)
 505
 506 AC_CHECK_LIB([curl], [curl_global_init],
 507 [NO_CURL=],
 508 [NO_CURL=YesPlease])
 509
 510 GIT_UNSTASH_FLAGS($CURLDIR)
 511
 512 AC_SUBST(NO_CURL)
 513
 514 #
 515 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 516 # not built, and you cannot push using http:// and https:// transports.
 517
 518 GIT_STASH_FLAGS($EXPATDIR)
 519
 520 AC_CHECK_LIB([expat], [XML_ParserCreate],
 521 [NO_EXPAT=],
 522 [NO_EXPAT=YesPlease])
 523
 524 GIT_UNSTASH_FLAGS($EXPATDIR)
 525
 526 AC_SUBST(NO_EXPAT)
 527
 528 #
 529 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 530 # some Solaris installations).
 531 # Define NO_ICONV if neither libc nor libiconv support iconv.
 532
 533 if test -z "$NO_ICONV"; then
 534
 535 GIT_STASH_FLAGS($ICONVDIR)
 536
 537 AC_DEFUN([ICONVTEST_SRC],
 538 [AC_LANG_PROGRAM([#include <iconv.h>],
 539  [iconv_open("", "");])])
 540
 541 if test -n "$ICONVDIR"; then
 542    lib_order="-liconv -lc"
 543 else
 544    lib_order="-lc -liconv"
 545 fi
 546
 547 NO_ICONV=YesPlease
 548
 549 for l in $lib_order; do
 550     if test "$l" = "-liconv"; then
 551        NEEDS_LIBICONV=YesPlease
 552     else
 553        NEEDS_LIBICONV=
 554     fi
 555
 556     old_LIBS="$LIBS"
 557     LIBS="$LIBS $l"
 558     AC_MSG_CHECKING([for iconv in $l])
 559     AC_LINK_IFELSE([ICONVTEST_SRC],
 560         [AC_MSG_RESULT([yes])
 561         NO_ICONV=
 562         break],
 563         [AC_MSG_RESULT([no])])
 564     LIBS="$old_LIBS"
 565 done
 566
 567 #in case of break
 568 LIBS="$old_LIBS"
 569
 570 GIT_UNSTASH_FLAGS($ICONVDIR)
 571
 572 AC_SUBST(NEEDS_LIBICONV)
 573 AC_SUBST(NO_ICONV)
 574
 575 if test -n "$NO_ICONV"; then
 576     NEEDS_LIBICONV=
 577 fi
 578
 579 fi
 580
 581 #
 582 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 583
 584 GIT_STASH_FLAGS($ZLIB_PATH)
 585
 586 AC_DEFUN([ZLIBTEST_SRC], [
 587 AC_LANG_PROGRAM([#include <zlib.h>],
 588  [deflateBound(0, 0);])])
 589 AC_MSG_CHECKING([for deflateBound in -lz])
 590 old_LIBS="$LIBS"
 591 LIBS="$LIBS -lz"
 592 AC_LINK_IFELSE([ZLIBTEST_SRC],
 593         [AC_MSG_RESULT([yes])],
 594         [AC_MSG_RESULT([no])
 595         NO_DEFLATE_BOUND=yes])
 596 LIBS="$old_LIBS"
 597
 598 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 599
 600 AC_SUBST(NO_DEFLATE_BOUND)
 601
 602 #
 603 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 604 # Patrick Mauritz).
 605 AC_CHECK_LIB([c], [socket],
 606 [NEEDS_SOCKET=],
 607 [NEEDS_SOCKET=YesPlease])
 608 AC_SUBST(NEEDS_SOCKET)
 609 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 610
 611 #
 612 # The next few tests will define NEEDS_RESOLV if linking with
 613 # libresolv provides some of the functions we would normally get
 614 # from libc.
 615 NEEDS_RESOLV=
 616 AC_SUBST(NEEDS_RESOLV)
 617 #
 618 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 619 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 620 NO_INET_NTOP=
 621 AC_SUBST(NO_INET_NTOP)
 622 AC_CHECK_FUNC([inet_ntop],
 623         [],
 624     [AC_CHECK_LIB([resolv], [inet_ntop],
 625             [NEEDS_RESOLV=YesPlease],
 626         [NO_INET_NTOP=YesPlease])
 627 ])
 628 #
 629 # Define NO_INET_PTON if linking with -lresolv is not enough.
 630 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 631 NO_INET_PTON=
 632 AC_SUBST(NO_INET_PTON)
 633 AC_CHECK_FUNC([inet_pton],
 634         [],
 635     [AC_CHECK_LIB([resolv], [inet_pton],
 636             [NEEDS_RESOLV=YesPlease],
 637         [NO_INET_PTON=YesPlease])
 638 ])
 639 #
 640 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 641 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 642 NO_HSTRERROR=
 643 AC_CHECK_FUNC([hstrerror],
 644         [],
 645     [AC_CHECK_LIB([resolv], [hstrerror],
 646             [NEEDS_RESOLV=YesPlease],
 647         [NO_HSTRERROR=YesPlease])
 648 ])
 649 AC_SUBST(NO_HSTRERROR)
 650 #
 651 # If any of the above tests determined that -lresolv is needed at
 652 # build-time, also set it here for remaining configure-time checks.
 653 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 654
 655 AC_CHECK_LIB([c], [basename],
 656 [NEEDS_LIBGEN=],
 657 [NEEDS_LIBGEN=YesPlease])
 658 AC_SUBST(NEEDS_LIBGEN)
 659 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 660
 661 AC_CHECK_LIB([c], [gettext],
 662 [LIBC_CONTAINS_LIBINTL=YesPlease],
 663 [LIBC_CONTAINS_LIBINTL=])
 664 AC_SUBST(LIBC_CONTAINS_LIBINTL)
 665
 666 #
 667 # Define NO_GETTEXT if you don't want Git output to be translated.
 668 # A translated Git requires GNU libintl or another gettext implementation
 669 AC_CHECK_HEADER([libintl.h],
 670 [NO_GETTEXT=],
 671 [NO_GETTEXT=YesPlease])
 672 AC_SUBST(NO_GETTEXT)
 673
 674 if test -z "$NO_GETTEXT"; then
 675     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 676 fi
 677
 678 ## Checks for header files.
 679 AC_MSG_NOTICE([CHECKS for header files])
 680 #
 681 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 682 AC_CHECK_HEADER([sys/select.h],
 683 [NO_SYS_SELECT_H=],
 684 [NO_SYS_SELECT_H=UnfortunatelyYes])
 685 AC_SUBST(NO_SYS_SELECT_H)
 686 #
 687 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 688 AC_CHECK_HEADER([sys/poll.h],
 689 [NO_SYS_POLL_H=],
 690 [NO_SYS_POLL_H=UnfortunatelyYes])
 691 AC_SUBST(NO_SYS_POLL_H)
 692 #
 693 # Define NO_INTTYPES_H if you don't have inttypes.h
 694 AC_CHECK_HEADER([inttypes.h],
 695 [NO_INTTYPES_H=],
 696 [NO_INTTYPES_H=UnfortunatelyYes])
 697 AC_SUBST(NO_INTTYPES_H)
 698 #
 699 # Define OLD_ICONV if your library has an old iconv(), where the second
 700 # (input buffer pointer) parameter is declared with type (const char **).
 701 AC_DEFUN([OLDICONVTEST_SRC], [
 702 AC_LANG_PROGRAM([[
 703 #include <iconv.h>
 704
 705 extern size_t iconv(iconv_t cd,
 706                     char **inbuf, size_t *inbytesleft,
 707                     char **outbuf, size_t *outbytesleft);
 708 ]], [])])
 709
 710 GIT_STASH_FLAGS($ICONVDIR)
 711
 712 AC_MSG_CHECKING([for old iconv()])
 713 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 714         [AC_MSG_RESULT([no])],
 715         [AC_MSG_RESULT([yes])
 716         OLD_ICONV=UnfortunatelyYes])
 717
 718 GIT_UNSTASH_FLAGS($ICONVDIR)
 719
 720 AC_SUBST(OLD_ICONV)
 721
 722 ## Checks for typedefs, structures, and compiler characteristics.
 723 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 724 #
 725 TYPE_SOCKLEN_T
 726 case $ac_cv_type_socklen_t in
 727   yes)  ;;
 728   *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 729 esac
 730
 731 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 732 AC_CHECK_MEMBER(struct dirent.d_ino,
 733 [NO_D_INO_IN_DIRENT=],
 734 [NO_D_INO_IN_DIRENT=YesPlease],
 735 [#include <dirent.h>])
 736 AC_SUBST(NO_D_INO_IN_DIRENT)
 737 #
 738 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 739 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 740 AC_CHECK_MEMBER(struct dirent.d_type,
 741 [NO_D_TYPE_IN_DIRENT=],
 742 [NO_D_TYPE_IN_DIRENT=YesPlease],
 743 [#include <dirent.h>])
 744 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 745 #
 746 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 747 # sockaddr_storage.
 748 AC_CHECK_TYPE(struct sockaddr_storage,
 749 [NO_SOCKADDR_STORAGE=],
 750 [NO_SOCKADDR_STORAGE=YesPlease],[
 751 #include <sys/types.h>
 752 #include <sys/socket.h>
 753 ])
 754 AC_SUBST(NO_SOCKADDR_STORAGE)
 755 #
 756 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 757 AC_CHECK_TYPE([struct addrinfo],[
 758  GIT_CHECK_FUNC([getaddrinfo],
 759   [NO_IPV6=],
 760   [NO_IPV6=YesPlease])
 761 ],[NO_IPV6=YesPlease],[
 762 #include <sys/types.h>
 763 #include <sys/socket.h>
 764 #include <netdb.h>
 765 ])
 766 AC_SUBST(NO_IPV6)
 767 #
 768 # Define NO_REGEX if you have no or inferior regex support in your C library.
 769 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 770  [ac_cv_c_excellent_regex], [
 771 AC_EGREP_CPP(yippeeyeswehaveit,
 772         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 773 #include <regex.h>
 774 ],
 775 [#ifdef REG_STARTEND
 776 yippeeyeswehaveit
 777 #endif
 778 ]),
 779         [ac_cv_c_excellent_regex=yes],
 780         [ac_cv_c_excellent_regex=no])
 781 ])
 782 if test $ac_cv_c_excellent_regex = yes; then
 783         NO_REGEX=
 784 else
 785         NO_REGEX=YesPlease
 786 fi
 787 AC_SUBST(NO_REGEX)
 788 #
 789 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 790 # when attempting to read from an fopen'ed directory.
 791 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 792  [ac_cv_fread_reads_directories],
 793 [
 794 AC_RUN_IFELSE(
 795         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 796                 [[char c;
 797                 FILE *f = fopen(".", "r");
 798                 return f && fread(&c, 1, 1, f)]])],
 799         [ac_cv_fread_reads_directories=no],
 800         [ac_cv_fread_reads_directories=yes])
 801 ])
 802 if test $ac_cv_fread_reads_directories = yes; then
 803         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 804 else
 805         FREAD_READS_DIRECTORIES=
 806 fi
 807 AC_SUBST(FREAD_READS_DIRECTORIES)
 808 #
 809 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 810 # or vsnprintf() return -1 instead of number of characters which would
 811 # have been written to the final string if enough space had been available.
 812 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 813  [ac_cv_snprintf_returns_bogus],
 814 [
 815 AC_RUN_IFELSE(
 816         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 817                 #include "stdarg.h"
 818
 819                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 820                 {
 821                   int ret;
 822                   va_list ap;
 823                   va_start(ap, format);
 824                   ret = vsnprintf(str, maxsize, format, ap);
 825                   va_end(ap);
 826                   return ret;
 827                 }],
 828                 [[char buf[6];
 829                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 830                       || strcmp(buf, "12")) return 1;
 831                   if (snprintf(buf, 3, "%s", "12345") != 5
 832                       || strcmp(buf, "12")) return 1]])],
 833         [ac_cv_snprintf_returns_bogus=no],
 834         [ac_cv_snprintf_returns_bogus=yes])
 835 ])
 836 if test $ac_cv_snprintf_returns_bogus = yes; then
 837         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 838 else
 839         SNPRINTF_RETURNS_BOGUS=
 840 fi
 841 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 842
 843
 844 ## Checks for library functions.
 845 ## (in default C library and libraries checked by AC_CHECK_LIB)
 846 AC_MSG_NOTICE([CHECKS for library functions])
 847 #
 848 # Define NO_LIBGEN_H if you don't have libgen.h.
 849 AC_CHECK_HEADER([libgen.h],
 850 [NO_LIBGEN_H=],
 851 [NO_LIBGEN_H=YesPlease])
 852 AC_SUBST(NO_LIBGEN_H)
 853 #
 854 # Define HAVE_PATHS_H if you have paths.h.
 855 AC_CHECK_HEADER([paths.h],
 856 [HAVE_PATHS_H=YesPlease],
 857 [HAVE_PATHS_H=])
 858 AC_SUBST(HAVE_PATHS_H)
 859 #
 860 # Define HAVE_LIBCHARSET_H if have libcharset.h
 861 AC_CHECK_HEADER([libcharset.h],
 862 [HAVE_LIBCHARSET_H=YesPlease],
 863 [HAVE_LIBCHARSET_H=])
 864 AC_SUBST(HAVE_LIBCHARSET_H)
 865 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
 866 # and libcharset does
 867 CHARSET_LIB=
 868 AC_CHECK_LIB([iconv], [locale_charset],
 869        [],
 870        [AC_CHECK_LIB([charset], [locale_charset],
 871                      [CHARSET_LIB=-lcharset])
 872        ]
 873 )
 874 AC_SUBST(CHARSET_LIB)
 875 #
 876 # Define NO_STRCASESTR if you don't have strcasestr.
 877 GIT_CHECK_FUNC(strcasestr,
 878 [NO_STRCASESTR=],
 879 [NO_STRCASESTR=YesPlease])
 880 AC_SUBST(NO_STRCASESTR)
 881 #
 882 # Define NO_STRTOK_R if you don't have strtok_r
 883 GIT_CHECK_FUNC(strtok_r,
 884 [NO_STRTOK_R=],
 885 [NO_STRTOK_R=YesPlease])
 886 AC_SUBST(NO_STRTOK_R)
 887 #
 888 # Define NO_FNMATCH if you don't have fnmatch
 889 GIT_CHECK_FUNC(fnmatch,
 890 [NO_FNMATCH=],
 891 [NO_FNMATCH=YesPlease])
 892 AC_SUBST(NO_FNMATCH)
 893 #
 894 # Define NO_FNMATCH_CASEFOLD if your fnmatch function doesn't have the
 895 # FNM_CASEFOLD GNU extension.
 896 AC_CACHE_CHECK([whether the fnmatch function supports the FNMATCH_CASEFOLD GNU extension],
 897  [ac_cv_c_excellent_fnmatch], [
 898 AC_EGREP_CPP(yippeeyeswehaveit,
 899         AC_LANG_PROGRAM([
 900 #include <fnmatch.h>
 901 ],
 902 [#ifdef FNM_CASEFOLD
 903 yippeeyeswehaveit
 904 #endif
 905 ]),
 906         [ac_cv_c_excellent_fnmatch=yes],
 907         [ac_cv_c_excellent_fnmatch=no])
 908 ])
 909 if test $ac_cv_c_excellent_fnmatch = yes; then
 910         NO_FNMATCH_CASEFOLD=
 911 else
 912         NO_FNMATCH_CASEFOLD=YesPlease
 913 fi
 914 AC_SUBST(NO_FNMATCH_CASEFOLD)
 915 #
 916 # Define NO_MEMMEM if you don't have memmem.
 917 GIT_CHECK_FUNC(memmem,
 918 [NO_MEMMEM=],
 919 [NO_MEMMEM=YesPlease])
 920 AC_SUBST(NO_MEMMEM)
 921 #
 922 # Define NO_STRLCPY if you don't have strlcpy.
 923 GIT_CHECK_FUNC(strlcpy,
 924 [NO_STRLCPY=],
 925 [NO_STRLCPY=YesPlease])
 926 AC_SUBST(NO_STRLCPY)
 927 #
 928 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 929 AC_CHECK_TYPE(uintmax_t,
 930 [NO_UINTMAX_T=],
 931 [NO_UINTMAX_T=YesPlease],[
 932 #include <inttypes.h>
 933 ])
 934 AC_SUBST(NO_UINTMAX_T)
 935 #
 936 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 937 GIT_CHECK_FUNC(strtoumax,
 938 [NO_STRTOUMAX=],
 939 [NO_STRTOUMAX=YesPlease])
 940 AC_SUBST(NO_STRTOUMAX)
 941 #
 942 # Define NO_SETENV if you don't have setenv in the C library.
 943 GIT_CHECK_FUNC(setenv,
 944 [NO_SETENV=],
 945 [NO_SETENV=YesPlease])
 946 AC_SUBST(NO_SETENV)
 947 #
 948 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 949 GIT_CHECK_FUNC(unsetenv,
 950 [NO_UNSETENV=],
 951 [NO_UNSETENV=YesPlease])
 952 AC_SUBST(NO_UNSETENV)
 953 #
 954 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 955 GIT_CHECK_FUNC(mkdtemp,
 956 [NO_MKDTEMP=],
 957 [NO_MKDTEMP=YesPlease])
 958 AC_SUBST(NO_MKDTEMP)
 959 #
 960 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 961 GIT_CHECK_FUNC(mkstemps,
 962 [NO_MKSTEMPS=],
 963 [NO_MKSTEMPS=YesPlease])
 964 AC_SUBST(NO_MKSTEMPS)
 965 #
 966 # Define NO_INITGROUPS if you don't have initgroups in the C library.
 967 GIT_CHECK_FUNC(initgroups,
 968 [NO_INITGROUPS=],
 969 [NO_INITGROUPS=YesPlease])
 970 AC_SUBST(NO_INITGROUPS)
 971 #
 972 #
 973 # Define NO_MMAP if you want to avoid mmap.
 974 #
 975 # Define NO_ICONV if your libc does not properly support iconv.
 976
 977
 978 ## Other checks.
 979 # Define USE_PIC if you need the main git objects to be built with -fPIC
 980 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 981 #
 982 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 983 # Enable it on Windows.  By default, symrefs are still used.
 984 #
 985 # Define NO_PTHREADS if we do not have pthreads.
 986 #
 987 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
 988 AC_DEFUN([PTHREADTEST_SRC], [
 989 AC_LANG_PROGRAM([[
 990 #include <pthread.h>
 991 ]], [[
 992         pthread_mutex_t test_mutex;
 993         pthread_key_t test_key;
 994         int retcode = 0;
 995         retcode |= pthread_key_create(&test_key, (void *)0);
 996         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 997         retcode |= pthread_mutex_lock(&test_mutex);
 998         retcode |= pthread_mutex_unlock(&test_mutex);
 999         return retcode;
1000 ]])])
1001
1002 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1003 dnl   [[#include <pthread.h>]],
1004 dnl   [[pthread_mutex_t test_mutex;]]
1005 dnl )])
1006
1007 NO_PTHREADS=UnfortunatelyYes
1008 PTHREAD_LIBS=
1009
1010 if test -n "$USER_NOPTHREAD"; then
1011    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1012 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1013 # -D_REENTRANT' or some such.
1014 elif test -z "$PTHREAD_CFLAGS"; then
1015   threads_found=no
1016   for opt in -mt -pthread -lpthread; do
1017      old_CFLAGS="$CFLAGS"
1018      CFLAGS="$opt $CFLAGS"
1019      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
1020      AC_LINK_IFELSE([PTHREADTEST_SRC],
1021         [AC_MSG_RESULT([yes])
1022                 NO_PTHREADS=
1023                 PTHREAD_LIBS="$opt"
1024                 PTHREAD_CFLAGS="$opt"
1025                 threads_found=yes
1026                 break
1027         ],
1028         [AC_MSG_RESULT([no])])
1029       CFLAGS="$old_CFLAGS"
1030   done
1031   if test $threads_found != yes; then
1032     AC_CHECK_LIB([pthread], [pthread_create],
1033         [PTHREAD_LIBS="-lpthread"],
1034         [NO_PTHREADS=UnfortunatelyYes])
1035   fi
1036 else
1037   old_CFLAGS="$CFLAGS"
1038   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1039   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
1040   AC_LINK_IFELSE([PTHREADTEST_SRC],
1041         [AC_MSG_RESULT([yes])
1042                 NO_PTHREADS=
1043                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1044         ],
1045         [AC_MSG_RESULT([no])])
1046
1047   CFLAGS="$old_CFLAGS"
1048 fi
1049
1050 CFLAGS="$old_CFLAGS"
1051
1052 AC_SUBST(PTHREAD_CFLAGS)
1053 AC_SUBST(PTHREAD_LIBS)
1054 AC_SUBST(NO_PTHREADS)
1055
1056 ## Output files
1057 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1058 AC_OUTPUT