git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc sq {value} {
 525         regsub -all ' $value "'\\''" value
 526         return "'$value'"
 527 }
 528
 529 proc load_current_branch {} {
 530         global current_branch is_detached
 531
 532         set fd [open [gitdir HEAD] r]
 533         if {[gets $fd ref] < 1} {
 534                 set ref {}
 535         }
 536         close $fd
 537
 538         set pfx {ref: refs/heads/}
 539         set len [string length $pfx]
 540         if {[string equal -length $len $pfx $ref]} {
 541                 # We're on a branch.  It might not exist.  But
 542                 # HEAD looks good enough to be a branch.
 543                 #
 544                 set current_branch [string range $ref $len end]
 545                 set is_detached 0
 546         } else {
 547                 # Assume this is a detached head.
 548                 #
 549                 set current_branch HEAD
 550                 set is_detached 1
 551         }
 552 }
 553
 554 auto_load tk_optionMenu
 555 rename tk_optionMenu real__tkOptionMenu
 556 proc tk_optionMenu {w varName args} {
 557         set m [eval real__tkOptionMenu $w $varName $args]
 558         $m configure -font font_ui
 559         $w configure -font font_ui
 560         return $m
 561 }
 562
 563 proc rmsel_tag {text} {
 564         $text tag conf sel \
 565                 -background [$text cget -background] \
 566                 -foreground [$text cget -foreground] \
 567                 -borderwidth 0
 568         $text tag conf in_sel -background lightgray
 569         bind $text <Motion> break
 570         return $text
 571 }
 572
 573 set root_exists 0
 574 bind . <Visibility> {
 575         bind . <Visibility> {}
 576         set root_exists 1
 577 }
 578
 579 if {[is_Windows]} {
 580         wm iconbitmap . -default $oguilib/git-gui.ico
 581 }
 582
 583 ######################################################################
 584 ##
 585 ## config defaults
 586
 587 set cursor_ptr arrow
 588 font create font_diff -family Courier -size 10
 589 font create font_ui
 590 catch {
 591         label .dummy
 592         eval font configure font_ui [font actual [.dummy cget -font]]
 593         destroy .dummy
 594 }
 595
 596 font create font_uiitalic
 597 font create font_uibold
 598 font create font_diffbold
 599 font create font_diffitalic
 600
 601 foreach class {Button Checkbutton Entry Label
 602                 Labelframe Listbox Menu Message
 603                 Radiobutton Spinbox Text} {
 604         option add *$class.font font_ui
 605 }
 606 unset class
 607
 608 if {[is_Windows] || [is_MacOSX]} {
 609         option add *Menu.tearOff 0
 610 }
 611
 612 if {[is_MacOSX]} {
 613         set M1B M1
 614         set M1T Cmd
 615 } else {
 616         set M1B Control
 617         set M1T Ctrl
 618 }
 619
 620 proc bind_button3 {w cmd} {
 621         bind $w <Any-Button-3> $cmd
 622         if {[is_MacOSX]} {
 623                 # Mac OS X sends Button-2 on right click through three-button mouse,
 624                 # or through trackpad right-clicking (two-finger touch + click).
 625                 bind $w <Any-Button-2> $cmd
 626                 bind $w <Control-Button-1> $cmd
 627         }
 628 }
 629
 630 proc apply_config {} {
 631         global repo_config font_descs
 632
 633         foreach option $font_descs {
 634                 set name [lindex $option 0]
 635                 set font [lindex $option 1]
 636                 if {[catch {
 637                         set need_weight 1
 638                         foreach {cn cv} $repo_config(gui.$name) {
 639                                 if {$cn eq {-weight}} {
 640                                         set need_weight 0
 641                                 }
 642                                 font configure $font $cn $cv
 643                         }
 644                         if {$need_weight} {
 645                                 font configure $font -weight normal
 646                         }
 647                         } err]} {
 648                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                 }
 650                 foreach {cn cv} [font configure $font] {
 651                         font configure ${font}bold $cn $cv
 652                         font configure ${font}italic $cn $cv
 653                 }
 654                 font configure ${font}bold -weight bold
 655                 font configure ${font}italic -slant italic
 656         }
 657 }
 658
 659 set default_config(branch.autosetupmerge) true
 660 set default_config(merge.tool) {}
 661 set default_config(merge.keepbackup) true
 662 set default_config(merge.diffstat) true
 663 set default_config(merge.summary) false
 664 set default_config(merge.verbosity) 2
 665 set default_config(user.name) {}
 666 set default_config(user.email) {}
 667
 668 set default_config(gui.matchtrackingbranch) false
 669 set default_config(gui.pruneduringfetch) false
 670 set default_config(gui.trustmtime) false
 671 set default_config(gui.fastcopyblame) false
 672 set default_config(gui.copyblamethreshold) 40
 673 set default_config(gui.blamehistoryctx) 7
 674 set default_config(gui.diffcontext) 5
 675 set default_config(gui.commitmsgwidth) 75
 676 set default_config(gui.newbranchtemplate) {}
 677 set default_config(gui.spellingdictionary) {}
 678 set default_config(gui.fontui) [font configure font_ui]
 679 set default_config(gui.fontdiff) [font configure font_diff]
 680 set font_descs {
 681         {fontui   font_ui   {mc "Main Font"}}
 682         {fontdiff font_diff {mc "Diff/Console Font"}}
 683 }
 684
 685 ######################################################################
 686 ##
 687 ## find git
 688
 689 set _git  [_which git]
 690 if {$_git eq {}} {
 691         catch {wm withdraw .}
 692         tk_messageBox \
 693                 -icon error \
 694                 -type ok \
 695                 -title [mc "git-gui: fatal error"] \
 696                 -message [mc "Cannot find git in PATH."]
 697         exit 1
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## version check
 703
 704 if {[catch {set _git_version [git --version]} err]} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message "Cannot determine Git version:
 711
 712 $err
 713
 714 [appname] requires Git 1.5.0 or later."
 715         exit 1
 716 }
 717 if {![regsub {^git version } $_git_version {} _git_version]} {
 718         catch {wm withdraw .}
 719         tk_messageBox \
 720                 -icon error \
 721                 -type ok \
 722                 -title [mc "git-gui: fatal error"] \
 723                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724         exit 1
 725 }
 726
 727 set _real_git_version $_git_version
 728 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731 regsub {\.GIT$} $_git_version {} _git_version
 732 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735         catch {wm withdraw .}
 736         if {[tk_messageBox \
 737                 -icon warning \
 738                 -type yesno \
 739                 -default no \
 740                 -title "[appname]: warning" \
 741                  -message [mc "Git version cannot be determined.
 742
 743 %s claims it is version '%s'.
 744
 745 %s requires at least Git 1.5.0 or later.
 746
 747 Assume '%s' is version 1.5.0?
 748 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                 set _git_version 1.5.0
 750         } else {
 751                 exit 1
 752         }
 753 }
 754 unset _real_git_version
 755
 756 proc git-version {args} {
 757         global _git_version
 758
 759         switch [llength $args] {
 760         0 {
 761                 return $_git_version
 762         }
 763
 764         2 {
 765                 set op [lindex $args 0]
 766                 set vr [lindex $args 1]
 767                 set cm [package vcompare $_git_version $vr]
 768                 return [expr $cm $op 0]
 769         }
 770
 771         4 {
 772                 set type [lindex $args 0]
 773                 set name [lindex $args 1]
 774                 set parm [lindex $args 2]
 775                 set body [lindex $args 3]
 776
 777                 if {($type ne {proc} && $type ne {method})} {
 778                         error "Invalid arguments to git-version"
 779                 }
 780                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                         error "Last arm of $type $name must be default"
 782                 }
 783
 784                 foreach {op vr cb} [lrange $body 0 end-2] {
 785                         if {[git-version $op $vr]} {
 786                                 return [uplevel [list $type $name $parm $cb]]
 787                         }
 788                 }
 789
 790                 return [uplevel [list $type $name $parm [lindex $body end]]]
 791         }
 792
 793         default {
 794                 error "git-version >= x"
 795         }
 796
 797         }
 798 }
 799
 800 if {[git-version < 1.5]} {
 801         catch {wm withdraw .}
 802         tk_messageBox \
 803                 -icon error \
 804                 -type ok \
 805                 -title [mc "git-gui: fatal error"] \
 806                 -message "[appname] requires Git 1.5.0 or later.
 807
 808 You are using [git-version]:
 809
 810 [git --version]"
 811         exit 1
 812 }
 813
 814 ######################################################################
 815 ##
 816 ## configure our library
 817
 818 set idx [file join $oguilib tclIndex]
 819 if {[catch {set fd [open $idx r]} err]} {
 820         catch {wm withdraw .}
 821         tk_messageBox \
 822                 -icon error \
 823                 -type ok \
 824                 -title [mc "git-gui: fatal error"] \
 825                 -message $err
 826         exit 1
 827 }
 828 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829         set idx [list]
 830         while {[gets $fd n] >= 0} {
 831                 if {$n ne {} && ![string match #* $n]} {
 832                         lappend idx $n
 833                 }
 834         }
 835 } else {
 836         set idx {}
 837 }
 838 close $fd
 839
 840 if {$idx ne {}} {
 841         set loaded [list]
 842         foreach p $idx {
 843                 if {[lsearch -exact $loaded $p] >= 0} continue
 844                 source [file join $oguilib $p]
 845                 lappend loaded $p
 846         }
 847         unset loaded p
 848 } else {
 849         set auto_path [concat [list $oguilib] $auto_path]
 850 }
 851 unset -nocomplain idx fd
 852
 853 ######################################################################
 854 ##
 855 ## config file parsing
 856
 857 git-version proc _parse_config {arr_name args} {
 858         >= 1.5.3 {
 859                 upvar $arr_name arr
 860                 array unset arr
 861                 set buf {}
 862                 catch {
 863                         set fd_rc [eval \
 864                                 [list git_read config] \
 865                                 $args \
 866                                 [list --null --list]]
 867                         fconfigure $fd_rc -translation binary
 868                         set buf [read $fd_rc]
 869                         close $fd_rc
 870                 }
 871                 foreach line [split $buf "\0"] {
 872                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                 if {[is_many_config $name]} {
 874                                         lappend arr($name) $value
 875                                 } else {
 876                                         set arr($name) $value
 877                                 }
 878                         }
 879                 }
 880         }
 881         default {
 882                 upvar $arr_name arr
 883                 array unset arr
 884                 catch {
 885                         set fd_rc [eval [list git_read config --list] $args]
 886                         while {[gets $fd_rc line] >= 0} {
 887                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                         if {[is_many_config $name]} {
 889                                                 lappend arr($name) $value
 890                                         } else {
 891                                                 set arr($name) $value
 892                                         }
 893                                 }
 894                         }
 895                         close $fd_rc
 896                 }
 897         }
 898 }
 899
 900 proc load_config {include_global} {
 901         global repo_config global_config default_config
 902
 903         if {$include_global} {
 904                 _parse_config global_config --global
 905         }
 906         _parse_config repo_config
 907
 908         foreach name [array names default_config] {
 909                 if {[catch {set v $global_config($name)}]} {
 910                         set global_config($name) $default_config($name)
 911                 }
 912                 if {[catch {set v $repo_config($name)}]} {
 913                         set repo_config($name) $default_config($name)
 914                 }
 915         }
 916 }
 917
 918 ######################################################################
 919 ##
 920 ## feature option selection
 921
 922 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923         unset _junk
 924 } else {
 925         set subcommand gui
 926 }
 927 if {$subcommand eq {gui.sh}} {
 928         set subcommand gui
 929 }
 930 if {$subcommand eq {gui} && [llength $argv] > 0} {
 931         set subcommand [lindex $argv 0]
 932         set argv [lrange $argv 1 end]
 933 }
 934
 935 enable_option multicommit
 936 enable_option branch
 937 enable_option transport
 938 disable_option bare
 939
 940 switch -- $subcommand {
 941 browser -
 942 blame {
 943         enable_option bare
 944
 945         disable_option multicommit
 946         disable_option branch
 947         disable_option transport
 948 }
 949 citool {
 950         enable_option singlecommit
 951
 952         disable_option multicommit
 953         disable_option branch
 954         disable_option transport
 955 }
 956 }
 957
 958 ######################################################################
 959 ##
 960 ## repository setup
 961
 962 if {[catch {
 963                 set _gitdir $env(GIT_DIR)
 964                 set _prefix {}
 965                 }]
 966         && [catch {
 967                 set _gitdir [git rev-parse --git-dir]
 968                 set _prefix [git rev-parse --show-prefix]
 969         } err]} {
 970         load_config 1
 971         apply_config
 972         choose_repository::pick
 973 }
 974 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 975         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 976 }
 977 if {![file isdirectory $_gitdir]} {
 978         catch {wm withdraw .}
 979         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 980         exit 1
 981 }
 982 if {$_prefix ne {}} {
 983         regsub -all {[^/]+/} $_prefix ../ cdup
 984         if {[catch {cd $cdup} err]} {
 985                 catch {wm withdraw .}
 986                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 987                 exit 1
 988         }
 989         unset cdup
 990 } elseif {![is_enabled bare]} {
 991         if {[lindex [file split $_gitdir] end] ne {.git}} {
 992                 catch {wm withdraw .}
 993                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 994                 exit 1
 995         }
 996         if {[catch {cd [file dirname $_gitdir]} err]} {
 997                 catch {wm withdraw .}
 998                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 999                 exit 1
1000         }
1001 }
1002 set _reponame [file split [file normalize $_gitdir]]
1003 if {[lindex $_reponame end] eq {.git}} {
1004         set _reponame [lindex $_reponame end-1]
1005 } else {
1006         set _reponame [lindex $_reponame end]
1007 }
1008
1009 ######################################################################
1010 ##
1011 ## global init
1012
1013 set current_diff_path {}
1014 set current_diff_side {}
1015 set diff_actions [list]
1016
1017 set HEAD {}
1018 set PARENT {}
1019 set MERGE_HEAD [list]
1020 set commit_type {}
1021 set empty_tree {}
1022 set current_branch {}
1023 set is_detached 0
1024 set current_diff_path {}
1025 set is_3way_diff 0
1026 set selected_commit_type new
1027
1028 set nullid "0000000000000000000000000000000000000000"
1029 set nullid2 "0000000000000000000000000000000000000001"
1030
1031 ######################################################################
1032 ##
1033 ## task management
1034
1035 set rescan_active 0
1036 set diff_active 0
1037 set last_clicked {}
1038
1039 set disable_on_lock [list]
1040 set index_lock_type none
1041
1042 proc lock_index {type} {
1043         global index_lock_type disable_on_lock
1044
1045         if {$index_lock_type eq {none}} {
1046                 set index_lock_type $type
1047                 foreach w $disable_on_lock {
1048                         uplevel #0 $w disabled
1049                 }
1050                 return 1
1051         } elseif {$index_lock_type eq "begin-$type"} {
1052                 set index_lock_type $type
1053                 return 1
1054         }
1055         return 0
1056 }
1057
1058 proc unlock_index {} {
1059         global index_lock_type disable_on_lock
1060
1061         set index_lock_type none
1062         foreach w $disable_on_lock {
1063                 uplevel #0 $w normal
1064         }
1065 }
1066
1067 ######################################################################
1068 ##
1069 ## status
1070
1071 proc repository_state {ctvar hdvar mhvar} {
1072         global current_branch
1073         upvar $ctvar ct $hdvar hd $mhvar mh
1074
1075         set mh [list]
1076
1077         load_current_branch
1078         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1079                 set hd {}
1080                 set ct initial
1081                 return
1082         }
1083
1084         set merge_head [gitdir MERGE_HEAD]
1085         if {[file exists $merge_head]} {
1086                 set ct merge
1087                 set fd_mh [open $merge_head r]
1088                 while {[gets $fd_mh line] >= 0} {
1089                         lappend mh $line
1090                 }
1091                 close $fd_mh
1092                 return
1093         }
1094
1095         set ct normal
1096 }
1097
1098 proc PARENT {} {
1099         global PARENT empty_tree
1100
1101         set p [lindex $PARENT 0]
1102         if {$p ne {}} {
1103                 return $p
1104         }
1105         if {$empty_tree eq {}} {
1106                 set empty_tree [git mktree << {}]
1107         }
1108         return $empty_tree
1109 }
1110
1111 proc rescan {after {honor_trustmtime 1}} {
1112         global HEAD PARENT MERGE_HEAD commit_type
1113         global ui_index ui_workdir ui_comm
1114         global rescan_active file_states
1115         global repo_config
1116
1117         if {$rescan_active > 0 || ![lock_index read]} return
1118
1119         repository_state newType newHEAD newMERGE_HEAD
1120         if {[string match amend* $commit_type]
1121                 && $newType eq {normal}
1122                 && $newHEAD eq $HEAD} {
1123         } else {
1124                 set HEAD $newHEAD
1125                 set PARENT $newHEAD
1126                 set MERGE_HEAD $newMERGE_HEAD
1127                 set commit_type $newType
1128         }
1129
1130         array unset file_states
1131
1132         if {!$::GITGUI_BCK_exists &&
1133                 (![$ui_comm edit modified]
1134                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1135                 if {[string match amend* $commit_type]} {
1136                 } elseif {[load_message GITGUI_MSG]} {
1137                 } elseif {[load_message MERGE_MSG]} {
1138                 } elseif {[load_message SQUASH_MSG]} {
1139                 }
1140                 $ui_comm edit reset
1141                 $ui_comm edit modified false
1142         }
1143
1144         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1145                 rescan_stage2 {} $after
1146         } else {
1147                 set rescan_active 1
1148                 ui_status [mc "Refreshing file status..."]
1149                 set fd_rf [git_read update-index \
1150                         -q \
1151                         --unmerged \
1152                         --ignore-missing \
1153                         --refresh \
1154                         ]
1155                 fconfigure $fd_rf -blocking 0 -translation binary
1156                 fileevent $fd_rf readable \
1157                         [list rescan_stage2 $fd_rf $after]
1158         }
1159 }
1160
1161 if {[is_Cygwin]} {
1162         set is_git_info_exclude {}
1163         proc have_info_exclude {} {
1164                 global is_git_info_exclude
1165
1166                 if {$is_git_info_exclude eq {}} {
1167                         if {[catch {exec test -f [gitdir info exclude]}]} {
1168                                 set is_git_info_exclude 0
1169                         } else {
1170                                 set is_git_info_exclude 1
1171                         }
1172                 }
1173                 return $is_git_info_exclude
1174         }
1175 } else {
1176         proc have_info_exclude {} {
1177                 return [file readable [gitdir info exclude]]
1178         }
1179 }
1180
1181 proc rescan_stage2 {fd after} {
1182         global rescan_active buf_rdi buf_rdf buf_rlo
1183
1184         if {$fd ne {}} {
1185                 read $fd
1186                 if {![eof $fd]} return
1187                 close $fd
1188         }
1189
1190         set ls_others [list --exclude-per-directory=.gitignore]
1191         if {[have_info_exclude]} {
1192                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1193         }
1194         set user_exclude [get_config core.excludesfile]
1195         if {$user_exclude ne {} && [file readable $user_exclude]} {
1196                 lappend ls_others "--exclude-from=$user_exclude"
1197         }
1198
1199         set buf_rdi {}
1200         set buf_rdf {}
1201         set buf_rlo {}
1202
1203         set rescan_active 3
1204         ui_status [mc "Scanning for modified files ..."]
1205         set fd_di [git_read diff-index --cached -z [PARENT]]
1206         set fd_df [git_read diff-files -z]
1207         set fd_lo [eval git_read ls-files --others -z $ls_others]
1208
1209         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1210         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1211         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1212         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1213         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1214         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1215 }
1216
1217 proc load_message {file} {
1218         global ui_comm
1219
1220         set f [gitdir $file]
1221         if {[file isfile $f]} {
1222                 if {[catch {set fd [open $f r]}]} {
1223                         return 0
1224                 }
1225                 fconfigure $fd -eofchar {}
1226                 set content [string trim [read $fd]]
1227                 close $fd
1228                 regsub -all -line {[ \r\t]+$} $content {} content
1229                 $ui_comm delete 0.0 end
1230                 $ui_comm insert end $content
1231                 return 1
1232         }
1233         return 0
1234 }
1235
1236 proc read_diff_index {fd after} {
1237         global buf_rdi
1238
1239         append buf_rdi [read $fd]
1240         set c 0
1241         set n [string length $buf_rdi]
1242         while {$c < $n} {
1243                 set z1 [string first "\0" $buf_rdi $c]
1244                 if {$z1 == -1} break
1245                 incr z1
1246                 set z2 [string first "\0" $buf_rdi $z1]
1247                 if {$z2 == -1} break
1248
1249                 incr c
1250                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1251                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1252                 merge_state \
1253                         [encoding convertfrom $p] \
1254                         [lindex $i 4]? \
1255                         [list [lindex $i 0] [lindex $i 2]] \
1256                         [list]
1257                 set c $z2
1258                 incr c
1259         }
1260         if {$c < $n} {
1261                 set buf_rdi [string range $buf_rdi $c end]
1262         } else {
1263                 set buf_rdi {}
1264         }
1265
1266         rescan_done $fd buf_rdi $after
1267 }
1268
1269 proc read_diff_files {fd after} {
1270         global buf_rdf
1271
1272         append buf_rdf [read $fd]
1273         set c 0
1274         set n [string length $buf_rdf]
1275         while {$c < $n} {
1276                 set z1 [string first "\0" $buf_rdf $c]
1277                 if {$z1 == -1} break
1278                 incr z1
1279                 set z2 [string first "\0" $buf_rdf $z1]
1280                 if {$z2 == -1} break
1281
1282                 incr c
1283                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1284                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1285                 merge_state \
1286                         [encoding convertfrom $p] \
1287                         ?[lindex $i 4] \
1288                         [list] \
1289                         [list [lindex $i 0] [lindex $i 2]]
1290                 set c $z2
1291                 incr c
1292         }
1293         if {$c < $n} {
1294                 set buf_rdf [string range $buf_rdf $c end]
1295         } else {
1296                 set buf_rdf {}
1297         }
1298
1299         rescan_done $fd buf_rdf $after
1300 }
1301
1302 proc read_ls_others {fd after} {
1303         global buf_rlo
1304
1305         append buf_rlo [read $fd]
1306         set pck [split $buf_rlo "\0"]
1307         set buf_rlo [lindex $pck end]
1308         foreach p [lrange $pck 0 end-1] {
1309                 set p [encoding convertfrom $p]
1310                 if {[string index $p end] eq {/}} {
1311                         set p [string range $p 0 end-1]
1312                 }
1313                 merge_state $p ?O
1314         }
1315         rescan_done $fd buf_rlo $after
1316 }
1317
1318 proc rescan_done {fd buf after} {
1319         global rescan_active current_diff_path
1320         global file_states repo_config
1321         upvar $buf to_clear
1322
1323         if {![eof $fd]} return
1324         set to_clear {}
1325         close $fd
1326         if {[incr rescan_active -1] > 0} return
1327
1328         prune_selection
1329         unlock_index
1330         display_all_files
1331         if {$current_diff_path ne {}} reshow_diff
1332         if {$current_diff_path eq {}} select_first_diff
1333
1334         uplevel #0 $after
1335 }
1336
1337 proc prune_selection {} {
1338         global file_states selected_paths
1339
1340         foreach path [array names selected_paths] {
1341                 if {[catch {set still_here $file_states($path)}]} {
1342                         unset selected_paths($path)
1343                 }
1344         }
1345 }
1346
1347 ######################################################################
1348 ##
1349 ## ui helpers
1350
1351 proc mapicon {w state path} {
1352         global all_icons
1353
1354         if {[catch {set r $all_icons($state$w)}]} {
1355                 puts "error: no icon for $w state={$state} $path"
1356                 return file_plain
1357         }
1358         return $r
1359 }
1360
1361 proc mapdesc {state path} {
1362         global all_descs
1363
1364         if {[catch {set r $all_descs($state)}]} {
1365                 puts "error: no desc for state={$state} $path"
1366                 return $state
1367         }
1368         return $r
1369 }
1370
1371 proc ui_status {msg} {
1372         global main_status
1373         if {[info exists main_status]} {
1374                 $main_status show $msg
1375         }
1376 }
1377
1378 proc ui_ready {{test {}}} {
1379         global main_status
1380         if {[info exists main_status]} {
1381                 $main_status show [mc "Ready."] $test
1382         }
1383 }
1384
1385 proc escape_path {path} {
1386         regsub -all {\\} $path "\\\\" path
1387         regsub -all "\n" $path "\\n" path
1388         return $path
1389 }
1390
1391 proc short_path {path} {
1392         return [escape_path [lindex [file split $path] end]]
1393 }
1394
1395 set next_icon_id 0
1396 set null_sha1 [string repeat 0 40]
1397
1398 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1399         global file_states next_icon_id null_sha1
1400
1401         set s0 [string index $new_state 0]
1402         set s1 [string index $new_state 1]
1403
1404         if {[catch {set info $file_states($path)}]} {
1405                 set state __
1406                 set icon n[incr next_icon_id]
1407         } else {
1408                 set state [lindex $info 0]
1409                 set icon [lindex $info 1]
1410                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1411                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1412         }
1413
1414         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1415         elseif {$s0 eq {_}} {set s0 _}
1416
1417         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1418         elseif {$s1 eq {_}} {set s1 _}
1419
1420         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1421                 set head_info [list 0 $null_sha1]
1422         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1423                 && $head_info eq {}} {
1424                 set head_info $index_info
1425         }
1426
1427         set file_states($path) [list $s0$s1 $icon \
1428                 $head_info $index_info \
1429                 ]
1430         return $state
1431 }
1432
1433 proc display_file_helper {w path icon_name old_m new_m} {
1434         global file_lists
1435
1436         if {$new_m eq {_}} {
1437                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1438                 if {$lno >= 0} {
1439                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1440                         incr lno
1441                         $w conf -state normal
1442                         $w delete $lno.0 [expr {$lno + 1}].0
1443                         $w conf -state disabled
1444                 }
1445         } elseif {$old_m eq {_} && $new_m ne {_}} {
1446                 lappend file_lists($w) $path
1447                 set file_lists($w) [lsort -unique $file_lists($w)]
1448                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1449                 incr lno
1450                 $w conf -state normal
1451                 $w image create $lno.0 \
1452                         -align center -padx 5 -pady 1 \
1453                         -name $icon_name \
1454                         -image [mapicon $w $new_m $path]
1455                 $w insert $lno.1 "[escape_path $path]\n"
1456                 $w conf -state disabled
1457         } elseif {$old_m ne $new_m} {
1458                 $w conf -state normal
1459                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1460                 $w conf -state disabled
1461         }
1462 }
1463
1464 proc display_file {path state} {
1465         global file_states selected_paths
1466         global ui_index ui_workdir
1467
1468         set old_m [merge_state $path $state]
1469         set s $file_states($path)
1470         set new_m [lindex $s 0]
1471         set icon_name [lindex $s 1]
1472
1473         set o [string index $old_m 0]
1474         set n [string index $new_m 0]
1475         if {$o eq {U}} {
1476                 set o _
1477         }
1478         if {$n eq {U}} {
1479                 set n _
1480         }
1481         display_file_helper     $ui_index $path $icon_name $o $n
1482
1483         if {[string index $old_m 0] eq {U}} {
1484                 set o U
1485         } else {
1486                 set o [string index $old_m 1]
1487         }
1488         if {[string index $new_m 0] eq {U}} {
1489                 set n U
1490         } else {
1491                 set n [string index $new_m 1]
1492         }
1493         display_file_helper     $ui_workdir $path $icon_name $o $n
1494
1495         if {$new_m eq {__}} {
1496                 unset file_states($path)
1497                 catch {unset selected_paths($path)}
1498         }
1499 }
1500
1501 proc display_all_files_helper {w path icon_name m} {
1502         global file_lists
1503
1504         lappend file_lists($w) $path
1505         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1506         $w image create end \
1507                 -align center -padx 5 -pady 1 \
1508                 -name $icon_name \
1509                 -image [mapicon $w $m $path]
1510         $w insert end "[escape_path $path]\n"
1511 }
1512
1513 proc display_all_files {} {
1514         global ui_index ui_workdir
1515         global file_states file_lists
1516         global last_clicked
1517
1518         $ui_index conf -state normal
1519         $ui_workdir conf -state normal
1520
1521         $ui_index delete 0.0 end
1522         $ui_workdir delete 0.0 end
1523         set last_clicked {}
1524
1525         set file_lists($ui_index) [list]
1526         set file_lists($ui_workdir) [list]
1527
1528         foreach path [lsort [array names file_states]] {
1529                 set s $file_states($path)
1530                 set m [lindex $s 0]
1531                 set icon_name [lindex $s 1]
1532
1533                 set s [string index $m 0]
1534                 if {$s ne {U} && $s ne {_}} {
1535                         display_all_files_helper $ui_index $path \
1536                                 $icon_name $s
1537                 }
1538
1539                 if {[string index $m 0] eq {U}} {
1540                         set s U
1541                 } else {
1542                         set s [string index $m 1]
1543                 }
1544                 if {$s ne {_}} {
1545                         display_all_files_helper $ui_workdir $path \
1546                                 $icon_name $s
1547                 }
1548         }
1549
1550         $ui_index conf -state disabled
1551         $ui_workdir conf -state disabled
1552 }
1553
1554 ######################################################################
1555 ##
1556 ## icons
1557
1558 set filemask {
1559 #define mask_width 14
1560 #define mask_height 15
1561 static unsigned char mask_bits[] = {
1562    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1563    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1564    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1565 }
1566
1567 image create bitmap file_plain -background white -foreground black -data {
1568 #define plain_width 14
1569 #define plain_height 15
1570 static unsigned char plain_bits[] = {
1571    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1572    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1573    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1574 } -maskdata $filemask
1575
1576 image create bitmap file_mod -background white -foreground blue -data {
1577 #define mod_width 14
1578 #define mod_height 15
1579 static unsigned char mod_bits[] = {
1580    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1581    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1582    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1583 } -maskdata $filemask
1584
1585 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1586 #define file_fulltick_width 14
1587 #define file_fulltick_height 15
1588 static unsigned char file_fulltick_bits[] = {
1589    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1590    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1591    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1592 } -maskdata $filemask
1593
1594 image create bitmap file_parttick -background white -foreground "#005050" -data {
1595 #define parttick_width 14
1596 #define parttick_height 15
1597 static unsigned char parttick_bits[] = {
1598    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1599    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1600    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1601 } -maskdata $filemask
1602
1603 image create bitmap file_question -background white -foreground black -data {
1604 #define file_question_width 14
1605 #define file_question_height 15
1606 static unsigned char file_question_bits[] = {
1607    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1608    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1609    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1610 } -maskdata $filemask
1611
1612 image create bitmap file_removed -background white -foreground red -data {
1613 #define file_removed_width 14
1614 #define file_removed_height 15
1615 static unsigned char file_removed_bits[] = {
1616    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1617    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1618    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1619 } -maskdata $filemask
1620
1621 image create bitmap file_merge -background white -foreground blue -data {
1622 #define file_merge_width 14
1623 #define file_merge_height 15
1624 static unsigned char file_merge_bits[] = {
1625    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1626    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1627    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1628 } -maskdata $filemask
1629
1630 image create bitmap file_statechange -background white -foreground green -data {
1631 #define file_merge_width 14
1632 #define file_merge_height 15
1633 static unsigned char file_statechange_bits[] = {
1634    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1635    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1636    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1637 } -maskdata $filemask
1638
1639 set ui_index .vpane.files.index.list
1640 set ui_workdir .vpane.files.workdir.list
1641
1642 set all_icons(_$ui_index)   file_plain
1643 set all_icons(A$ui_index)   file_fulltick
1644 set all_icons(M$ui_index)   file_fulltick
1645 set all_icons(D$ui_index)   file_removed
1646 set all_icons(U$ui_index)   file_merge
1647 set all_icons(T$ui_index)   file_statechange
1648
1649 set all_icons(_$ui_workdir) file_plain
1650 set all_icons(M$ui_workdir) file_mod
1651 set all_icons(D$ui_workdir) file_question
1652 set all_icons(U$ui_workdir) file_merge
1653 set all_icons(O$ui_workdir) file_plain
1654 set all_icons(T$ui_workdir) file_statechange
1655
1656 set max_status_desc 0
1657 foreach i {
1658                 {__ {mc "Unmodified"}}
1659
1660                 {_M {mc "Modified, not staged"}}
1661                 {M_ {mc "Staged for commit"}}
1662                 {MM {mc "Portions staged for commit"}}
1663                 {MD {mc "Staged for commit, missing"}}
1664
1665                 {_T {mc "File type changed, not staged"}}
1666                 {T_ {mc "File type changed, staged"}}
1667
1668                 {_O {mc "Untracked, not staged"}}
1669                 {A_ {mc "Staged for commit"}}
1670                 {AM {mc "Portions staged for commit"}}
1671                 {AD {mc "Staged for commit, missing"}}
1672
1673                 {_D {mc "Missing"}}
1674                 {D_ {mc "Staged for removal"}}
1675                 {DO {mc "Staged for removal, still present"}}
1676
1677                 {_U {mc "Requires merge resolution"}}
1678                 {U_ {mc "Requires merge resolution"}}
1679                 {UU {mc "Requires merge resolution"}}
1680                 {UM {mc "Requires merge resolution"}}
1681                 {UD {mc "Requires merge resolution"}}
1682                 {UT {mc "Requires merge resolution"}}
1683         } {
1684         set text [eval [lindex $i 1]]
1685         if {$max_status_desc < [string length $text]} {
1686                 set max_status_desc [string length $text]
1687         }
1688         set all_descs([lindex $i 0]) $text
1689 }
1690 unset i
1691
1692 ######################################################################
1693 ##
1694 ## util
1695
1696 proc scrollbar2many {list mode args} {
1697         foreach w $list {eval $w $mode $args}
1698 }
1699
1700 proc many2scrollbar {list mode sb top bottom} {
1701         $sb set $top $bottom
1702         foreach w $list {$w $mode moveto $top}
1703 }
1704
1705 proc incr_font_size {font {amt 1}} {
1706         set sz [font configure $font -size]
1707         incr sz $amt
1708         font configure $font -size $sz
1709         font configure ${font}bold -size $sz
1710         font configure ${font}italic -size $sz
1711 }
1712
1713 ######################################################################
1714 ##
1715 ## ui commands
1716
1717 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1718
1719 proc do_gitk {revs} {
1720         # -- Always start gitk through whatever we were loaded with.  This
1721         #    lets us bypass using shell process on Windows systems.
1722         #
1723         set exe [_which gitk -script]
1724         set cmd [list [info nameofexecutable] $exe]
1725         if {$exe eq {}} {
1726                 error_popup [mc "Couldn't find gitk in PATH"]
1727         } else {
1728                 global env
1729
1730                 if {[info exists env(GIT_DIR)]} {
1731                         set old_GIT_DIR $env(GIT_DIR)
1732                 } else {
1733                         set old_GIT_DIR {}
1734                 }
1735
1736                 set pwd [pwd]
1737                 cd [file dirname [gitdir]]
1738                 set env(GIT_DIR) [file tail [gitdir]]
1739
1740                 eval exec $cmd $revs &
1741
1742                 if {$old_GIT_DIR eq {}} {
1743                         unset env(GIT_DIR)
1744                 } else {
1745                         set env(GIT_DIR) $old_GIT_DIR
1746                 }
1747                 cd $pwd
1748
1749                 ui_status $::starting_gitk_msg
1750                 after 10000 {
1751                         ui_ready $starting_gitk_msg
1752                 }
1753         }
1754 }
1755
1756 set is_quitting 0
1757
1758 proc do_quit {} {
1759         global ui_comm is_quitting repo_config commit_type
1760         global GITGUI_BCK_exists GITGUI_BCK_i
1761         global ui_comm_spell
1762
1763         if {$is_quitting} return
1764         set is_quitting 1
1765
1766         if {[winfo exists $ui_comm]} {
1767                 # -- Stash our current commit buffer.
1768                 #
1769                 set save [gitdir GITGUI_MSG]
1770                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1771                         file rename -force [gitdir GITGUI_BCK] $save
1772                         set GITGUI_BCK_exists 0
1773                 } else {
1774                         set msg [string trim [$ui_comm get 0.0 end]]
1775                         regsub -all -line {[ \r\t]+$} $msg {} msg
1776                         if {(![string match amend* $commit_type]
1777                                 || [$ui_comm edit modified])
1778                                 && $msg ne {}} {
1779                                 catch {
1780                                         set fd [open $save w]
1781                                         puts -nonewline $fd $msg
1782                                         close $fd
1783                                 }
1784                         } else {
1785                                 catch {file delete $save}
1786                         }
1787                 }
1788
1789                 # -- Cancel our spellchecker if its running.
1790                 #
1791                 if {[info exists ui_comm_spell]} {
1792                         $ui_comm_spell stop
1793                 }
1794
1795                 # -- Remove our editor backup, its not needed.
1796                 #
1797                 after cancel $GITGUI_BCK_i
1798                 if {$GITGUI_BCK_exists} {
1799                         catch {file delete [gitdir GITGUI_BCK]}
1800                 }
1801
1802                 # -- Stash our current window geometry into this repository.
1803                 #
1804                 set cfg_geometry [list]
1805                 lappend cfg_geometry [wm geometry .]
1806                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1807                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1808                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1809                         set rc_geometry {}
1810                 }
1811                 if {$cfg_geometry ne $rc_geometry} {
1812                         catch {git config gui.geometry $cfg_geometry}
1813                 }
1814         }
1815
1816         destroy .
1817 }
1818
1819 proc do_rescan {} {
1820         rescan ui_ready
1821 }
1822
1823 proc ui_do_rescan {} {
1824         rescan {force_first_diff; ui_ready}
1825 }
1826
1827 proc do_commit {} {
1828         commit_tree
1829 }
1830
1831 proc next_diff {} {
1832         global next_diff_p next_diff_w next_diff_i
1833         show_diff $next_diff_p $next_diff_w {}
1834 }
1835
1836 proc find_anchor_pos {lst name} {
1837         set lid [lsearch -sorted -exact $lst $name]
1838
1839         if {$lid == -1} {
1840                 set lid 0
1841                 foreach lname $lst {
1842                         if {$lname >= $name} break
1843                         incr lid
1844                 }
1845         }
1846
1847         return $lid
1848 }
1849
1850 proc find_file_from {flist idx delta path mmask} {
1851         global file_states
1852
1853         set len [llength $flist]
1854         while {$idx >= 0 && $idx < $len} {
1855                 set name [lindex $flist $idx]
1856
1857                 if {$name ne $path && [info exists file_states($name)]} {
1858                         set state [lindex $file_states($name) 0]
1859
1860                         if {$mmask eq {} || [regexp $mmask $state]} {
1861                                 return $idx
1862                         }
1863                 }
1864
1865                 incr idx $delta
1866         }
1867
1868         return {}
1869 }
1870
1871 proc find_next_diff {w path {lno {}} {mmask {}}} {
1872         global next_diff_p next_diff_w next_diff_i
1873         global file_lists ui_index ui_workdir
1874
1875         set flist $file_lists($w)
1876         if {$lno eq {}} {
1877                 set lno [find_anchor_pos $flist $path]
1878         } else {
1879                 incr lno -1
1880         }
1881
1882         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
1883                 if {$w eq $ui_index} {
1884                         set mmask "^$mmask"
1885                 } else {
1886                         set mmask "$mmask\$"
1887                 }
1888         }
1889
1890         set idx [find_file_from $flist $lno 1 $path $mmask]
1891         if {$idx eq {}} {
1892                 incr lno -1
1893                 set idx [find_file_from $flist $lno -1 $path $mmask]
1894         }
1895
1896         if {$idx ne {}} {
1897                 set next_diff_w $w
1898                 set next_diff_p [lindex $flist $idx]
1899                 set next_diff_i [expr {$idx+1}]
1900                 return 1
1901         } else {
1902                 return 0
1903         }
1904 }
1905
1906 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
1907         global current_diff_path
1908
1909         if {$path ne $current_diff_path} {
1910                 return {}
1911         } elseif {[find_next_diff $w $path $lno $mmask]} {
1912                 return {next_diff;}
1913         } else {
1914                 return {reshow_diff;}
1915         }
1916 }
1917
1918 proc select_first_diff {} {
1919         global ui_workdir
1920
1921         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
1922             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
1923                 next_diff
1924         }
1925 }
1926
1927 proc force_first_diff {} {
1928         global current_diff_path
1929
1930         if {[info exists file_states($current_diff_path)]} {
1931                 set state [lindex $file_states($current_diff_path) 0]
1932
1933                 if {[string index $state 1] ne {O}} return
1934         }
1935
1936         select_first_diff
1937 }
1938
1939 proc toggle_or_diff {w x y} {
1940         global file_states file_lists current_diff_path ui_index ui_workdir
1941         global last_clicked selected_paths
1942
1943         set pos [split [$w index @$x,$y] .]
1944         set lno [lindex $pos 0]
1945         set col [lindex $pos 1]
1946         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1947         if {$path eq {}} {
1948                 set last_clicked {}
1949                 return
1950         }
1951
1952         set last_clicked [list $w $lno]
1953         array unset selected_paths
1954         $ui_index tag remove in_sel 0.0 end
1955         $ui_workdir tag remove in_sel 0.0 end
1956
1957         # Do not stage files with conflicts
1958         if {[info exists file_states($path)]} {
1959                 set state [lindex $file_states($path) 0]
1960         } else {
1961                 set state {__}
1962         }
1963
1964         if {[string first {U} $state] >= 0} {
1965                 set col 1
1966         }
1967
1968         # Restage the file, or simply show the diff
1969         if {$col == 0 && $y > 1} {
1970                 if {[string index $state 1] eq {O}} {
1971                         set mmask {}
1972                 } else {
1973                         set mmask {[^O]}
1974                 }
1975
1976                 set after [next_diff_after_action $w $path $lno $mmask]
1977
1978                 if {$w eq $ui_index} {
1979                         update_indexinfo \
1980                                 "Unstaging [short_path $path] from commit" \
1981                                 [list $path] \
1982                                 [concat $after [list ui_ready]]
1983                 } elseif {$w eq $ui_workdir} {
1984                         update_index \
1985                                 "Adding [short_path $path]" \
1986                                 [list $path] \
1987                                 [concat $after [list ui_ready]]
1988                 }
1989         } else {
1990                 show_diff $path $w $lno
1991         }
1992 }
1993
1994 proc add_one_to_selection {w x y} {
1995         global file_lists last_clicked selected_paths
1996
1997         set lno [lindex [split [$w index @$x,$y] .] 0]
1998         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1999         if {$path eq {}} {
2000                 set last_clicked {}
2001                 return
2002         }
2003
2004         if {$last_clicked ne {}
2005                 && [lindex $last_clicked 0] ne $w} {
2006                 array unset selected_paths
2007                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2008         }
2009
2010         set last_clicked [list $w $lno]
2011         if {[catch {set in_sel $selected_paths($path)}]} {
2012                 set in_sel 0
2013         }
2014         if {$in_sel} {
2015                 unset selected_paths($path)
2016                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2017         } else {
2018                 set selected_paths($path) 1
2019                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2020         }
2021 }
2022
2023 proc add_range_to_selection {w x y} {
2024         global file_lists last_clicked selected_paths
2025
2026         if {[lindex $last_clicked 0] ne $w} {
2027                 toggle_or_diff $w $x $y
2028                 return
2029         }
2030
2031         set lno [lindex [split [$w index @$x,$y] .] 0]
2032         set lc [lindex $last_clicked 1]
2033         if {$lc < $lno} {
2034                 set begin $lc
2035                 set end $lno
2036         } else {
2037                 set begin $lno
2038                 set end $lc
2039         }
2040
2041         foreach path [lrange $file_lists($w) \
2042                 [expr {$begin - 1}] \
2043                 [expr {$end - 1}]] {
2044                 set selected_paths($path) 1
2045         }
2046         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2047 }
2048
2049 proc show_more_context {} {
2050         global repo_config
2051         if {$repo_config(gui.diffcontext) < 99} {
2052                 incr repo_config(gui.diffcontext)
2053                 reshow_diff
2054         }
2055 }
2056
2057 proc show_less_context {} {
2058         global repo_config
2059         if {$repo_config(gui.diffcontext) > 1} {
2060                 incr repo_config(gui.diffcontext) -1
2061                 reshow_diff
2062         }
2063 }
2064
2065 ######################################################################
2066 ##
2067 ## ui construction
2068
2069 load_config 0
2070 apply_config
2071 set ui_comm {}
2072
2073 # -- Menu Bar
2074 #
2075 menu .mbar -tearoff 0
2076 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2077 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2078 if {[is_enabled branch]} {
2079         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2080 }
2081 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2082         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2083 }
2084 if {[is_enabled transport]} {
2085         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2086         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2087 }
2088 . configure -menu .mbar
2089
2090 # -- Repository Menu
2091 #
2092 menu .mbar.repository
2093
2094 .mbar.repository add command \
2095         -label [mc "Browse Current Branch's Files"] \
2096         -command {browser::new $current_branch}
2097 set ui_browse_current [.mbar.repository index last]
2098 .mbar.repository add command \
2099         -label [mc "Browse Branch Files..."] \
2100         -command browser_open::dialog
2101 .mbar.repository add separator
2102
2103 .mbar.repository add command \
2104         -label [mc "Visualize Current Branch's History"] \
2105         -command {do_gitk $current_branch}
2106 set ui_visualize_current [.mbar.repository index last]
2107 .mbar.repository add command \
2108         -label [mc "Visualize All Branch History"] \
2109         -command {do_gitk --all}
2110 .mbar.repository add separator
2111
2112 proc current_branch_write {args} {
2113         global current_branch
2114         .mbar.repository entryconf $::ui_browse_current \
2115                 -label [mc "Browse %s's Files" $current_branch]
2116         .mbar.repository entryconf $::ui_visualize_current \
2117                 -label [mc "Visualize %s's History" $current_branch]
2118 }
2119 trace add variable current_branch write current_branch_write
2120
2121 if {[is_enabled multicommit]} {
2122         .mbar.repository add command -label [mc "Database Statistics"] \
2123                 -command do_stats
2124
2125         .mbar.repository add command -label [mc "Compress Database"] \
2126                 -command do_gc
2127
2128         .mbar.repository add command -label [mc "Verify Database"] \
2129                 -command do_fsck_objects
2130
2131         .mbar.repository add separator
2132
2133         if {[is_Cygwin]} {
2134                 .mbar.repository add command \
2135                         -label [mc "Create Desktop Icon"] \
2136                         -command do_cygwin_shortcut
2137         } elseif {[is_Windows]} {
2138                 .mbar.repository add command \
2139                         -label [mc "Create Desktop Icon"] \
2140                         -command do_windows_shortcut
2141         } elseif {[is_MacOSX]} {
2142                 .mbar.repository add command \
2143                         -label [mc "Create Desktop Icon"] \
2144                         -command do_macosx_app
2145         }
2146 }
2147
2148 if {[is_MacOSX]} {
2149         proc ::tk::mac::Quit {args} { do_quit }
2150 } else {
2151         .mbar.repository add command -label [mc Quit] \
2152                 -command do_quit \
2153                 -accelerator $M1T-Q
2154 }
2155
2156 # -- Edit Menu
2157 #
2158 menu .mbar.edit
2159 .mbar.edit add command -label [mc Undo] \
2160         -command {catch {[focus] edit undo}} \
2161         -accelerator $M1T-Z
2162 .mbar.edit add command -label [mc Redo] \
2163         -command {catch {[focus] edit redo}} \
2164         -accelerator $M1T-Y
2165 .mbar.edit add separator
2166 .mbar.edit add command -label [mc Cut] \
2167         -command {catch {tk_textCut [focus]}} \
2168         -accelerator $M1T-X
2169 .mbar.edit add command -label [mc Copy] \
2170         -command {catch {tk_textCopy [focus]}} \
2171         -accelerator $M1T-C
2172 .mbar.edit add command -label [mc Paste] \
2173         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2174         -accelerator $M1T-V
2175 .mbar.edit add command -label [mc Delete] \
2176         -command {catch {[focus] delete sel.first sel.last}} \
2177         -accelerator Del
2178 .mbar.edit add separator
2179 .mbar.edit add command -label [mc "Select All"] \
2180         -command {catch {[focus] tag add sel 0.0 end}} \
2181         -accelerator $M1T-A
2182
2183 # -- Branch Menu
2184 #
2185 if {[is_enabled branch]} {
2186         menu .mbar.branch
2187
2188         .mbar.branch add command -label [mc "Create..."] \
2189                 -command branch_create::dialog \
2190                 -accelerator $M1T-N
2191         lappend disable_on_lock [list .mbar.branch entryconf \
2192                 [.mbar.branch index last] -state]
2193
2194         .mbar.branch add command -label [mc "Checkout..."] \
2195                 -command branch_checkout::dialog \
2196                 -accelerator $M1T-O
2197         lappend disable_on_lock [list .mbar.branch entryconf \
2198                 [.mbar.branch index last] -state]
2199
2200         .mbar.branch add command -label [mc "Rename..."] \
2201                 -command branch_rename::dialog
2202         lappend disable_on_lock [list .mbar.branch entryconf \
2203                 [.mbar.branch index last] -state]
2204
2205         .mbar.branch add command -label [mc "Delete..."] \
2206                 -command branch_delete::dialog
2207         lappend disable_on_lock [list .mbar.branch entryconf \
2208                 [.mbar.branch index last] -state]
2209
2210         .mbar.branch add command -label [mc "Reset..."] \
2211                 -command merge::reset_hard
2212         lappend disable_on_lock [list .mbar.branch entryconf \
2213                 [.mbar.branch index last] -state]
2214 }
2215
2216 # -- Commit Menu
2217 #
2218 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2219         menu .mbar.commit
2220
2221         .mbar.commit add radiobutton \
2222                 -label [mc "New Commit"] \
2223                 -command do_select_commit_type \
2224                 -variable selected_commit_type \
2225                 -value new
2226         lappend disable_on_lock \
2227                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2228
2229         .mbar.commit add radiobutton \
2230                 -label [mc "Amend Last Commit"] \
2231                 -command do_select_commit_type \
2232                 -variable selected_commit_type \
2233                 -value amend
2234         lappend disable_on_lock \
2235                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2236
2237         .mbar.commit add separator
2238
2239         .mbar.commit add command -label [mc Rescan] \
2240                 -command ui_do_rescan \
2241                 -accelerator F5
2242         lappend disable_on_lock \
2243                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2244
2245         .mbar.commit add command -label [mc "Stage To Commit"] \
2246                 -command do_add_selection \
2247                 -accelerator $M1T-T
2248         lappend disable_on_lock \
2249                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2250
2251         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2252                 -command do_add_all \
2253                 -accelerator $M1T-I
2254         lappend disable_on_lock \
2255                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2256
2257         .mbar.commit add command -label [mc "Unstage From Commit"] \
2258                 -command do_unstage_selection
2259         lappend disable_on_lock \
2260                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2261
2262         .mbar.commit add command -label [mc "Revert Changes"] \
2263                 -command do_revert_selection
2264         lappend disable_on_lock \
2265                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2266
2267         .mbar.commit add separator
2268
2269         .mbar.commit add command -label [mc "Show Less Context"] \
2270                 -command show_less_context \
2271                 -accelerator $M1T-\-
2272
2273         .mbar.commit add command -label [mc "Show More Context"] \
2274                 -command show_more_context \
2275                 -accelerator $M1T-=
2276
2277         .mbar.commit add separator
2278
2279         .mbar.commit add command -label [mc "Sign Off"] \
2280                 -command do_signoff \
2281                 -accelerator $M1T-S
2282
2283         .mbar.commit add command -label [mc Commit@@verb] \
2284                 -command do_commit \
2285                 -accelerator $M1T-Return
2286         lappend disable_on_lock \
2287                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2288 }
2289
2290 # -- Merge Menu
2291 #
2292 if {[is_enabled branch]} {
2293         menu .mbar.merge
2294         .mbar.merge add command -label [mc "Local Merge..."] \
2295                 -command merge::dialog \
2296                 -accelerator $M1T-M
2297         lappend disable_on_lock \
2298                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2299         .mbar.merge add command -label [mc "Abort Merge..."] \
2300                 -command merge::reset_hard
2301         lappend disable_on_lock \
2302                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2303 }
2304
2305 # -- Transport Menu
2306 #
2307 if {[is_enabled transport]} {
2308         menu .mbar.remote
2309
2310         .mbar.remote add command \
2311                 -label [mc "Push..."] \
2312                 -command do_push_anywhere \
2313                 -accelerator $M1T-P
2314         .mbar.remote add command \
2315                 -label [mc "Delete..."] \
2316                 -command remote_branch_delete::dialog
2317 }
2318
2319 if {[is_MacOSX]} {
2320         # -- Apple Menu (Mac OS X only)
2321         #
2322         .mbar add cascade -label Apple -menu .mbar.apple
2323         menu .mbar.apple
2324
2325         .mbar.apple add command -label [mc "About %s" [appname]] \
2326                 -command do_about
2327         .mbar.apple add separator
2328         .mbar.apple add command \
2329                 -label [mc "Preferences..."] \
2330                 -command do_options \
2331                 -accelerator $M1T-,
2332         bind . <$M1B-,> do_options
2333 } else {
2334         # -- Edit Menu
2335         #
2336         .mbar.edit add separator
2337         .mbar.edit add command -label [mc "Options..."] \
2338                 -command do_options
2339 }
2340
2341 # -- Help Menu
2342 #
2343 .mbar add cascade -label [mc Help] -menu .mbar.help
2344 menu .mbar.help
2345
2346 if {![is_MacOSX]} {
2347         .mbar.help add command -label [mc "About %s" [appname]] \
2348                 -command do_about
2349 }
2350
2351 set browser {}
2352 catch {set browser $repo_config(instaweb.browser)}
2353 set doc_path [file dirname [gitexec]]
2354 set doc_path [file join $doc_path Documentation index.html]
2355
2356 if {[is_Cygwin]} {
2357         set doc_path [exec cygpath --mixed $doc_path]
2358 }
2359
2360 if {$browser eq {}} {
2361         if {[is_MacOSX]} {
2362                 set browser open
2363         } elseif {[is_Cygwin]} {
2364                 set program_files [file dirname [exec cygpath --windir]]
2365                 set program_files [file join $program_files {Program Files}]
2366                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2367                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2368                 if {[file exists $firefox]} {
2369                         set browser $firefox
2370                 } elseif {[file exists $ie]} {
2371                         set browser $ie
2372                 }
2373                 unset program_files firefox ie
2374         }
2375 }
2376
2377 if {[file isfile $doc_path]} {
2378         set doc_url "file:$doc_path"
2379 } else {
2380         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2381 }
2382
2383 if {$browser ne {}} {
2384         .mbar.help add command -label [mc "Online Documentation"] \
2385                 -command [list exec $browser $doc_url &]
2386 }
2387 unset browser doc_path doc_url
2388
2389 # -- Standard bindings
2390 #
2391 wm protocol . WM_DELETE_WINDOW do_quit
2392 bind all <$M1B-Key-q> do_quit
2393 bind all <$M1B-Key-Q> do_quit
2394 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2395 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2396
2397 set subcommand_args {}
2398 proc usage {} {
2399         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2400         exit 1
2401 }
2402
2403 # -- Not a normal commit type invocation?  Do that instead!
2404 #
2405 switch -- $subcommand {
2406 browser -
2407 blame {
2408         if {$subcommand eq "blame"} {
2409                 set subcommand_args {[--line=<num>] rev? path}
2410         } else {
2411                 set subcommand_args {rev? path}
2412         }
2413         if {$argv eq {}} usage
2414         set head {}
2415         set path {}
2416         set jump_spec {}
2417         set is_path 0
2418         foreach a $argv {
2419                 if {$is_path || [file exists $_prefix$a]} {
2420                         if {$path ne {}} usage
2421                         set path $_prefix$a
2422                         break
2423                 } elseif {$a eq {--}} {
2424                         if {$path ne {}} {
2425                                 if {$head ne {}} usage
2426                                 set head $path
2427                                 set path {}
2428                         }
2429                         set is_path 1
2430                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2431                         if {$jump_spec ne {} || $head ne {}} usage
2432                         set jump_spec [list $lnum]
2433                 } elseif {$head eq {}} {
2434                         if {$head ne {}} usage
2435                         set head $a
2436                         set is_path 1
2437                 } else {
2438                         usage
2439                 }
2440         }
2441         unset is_path
2442
2443         if {$head ne {} && $path eq {}} {
2444                 set path $_prefix$head
2445                 set head {}
2446         }
2447
2448         if {$head eq {}} {
2449                 load_current_branch
2450         } else {
2451                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2452                         if {[catch {
2453                                         set head [git rev-parse --verify $head]
2454                                 } err]} {
2455                                 puts stderr $err
2456                                 exit 1
2457                         }
2458                 }
2459                 set current_branch $head
2460         }
2461
2462         switch -- $subcommand {
2463         browser {
2464                 if {$jump_spec ne {}} usage
2465                 if {$head eq {}} {
2466                         if {$path ne {} && [file isdirectory $path]} {
2467                                 set head $current_branch
2468                         } else {
2469                                 set head $path
2470                                 set path {}
2471                         }
2472                 }
2473                 browser::new $head $path
2474         }
2475         blame   {
2476                 if {$head eq {} && ![file exists $path]} {
2477                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2478                         exit 1
2479                 }
2480                 blame::new $head $path $jump_spec
2481         }
2482         }
2483         return
2484 }
2485 citool -
2486 gui {
2487         if {[llength $argv] != 0} {
2488                 puts -nonewline stderr "usage: $argv0"
2489                 if {$subcommand ne {gui}
2490                         && [file tail $argv0] ne "git-$subcommand"} {
2491                         puts -nonewline stderr " $subcommand"
2492                 }
2493                 puts stderr {}
2494                 exit 1
2495         }
2496         # fall through to setup UI for commits
2497 }
2498 default {
2499         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2500         exit 1
2501 }
2502 }
2503
2504 # -- Branch Control
2505 #
2506 frame .branch \
2507         -borderwidth 1 \
2508         -relief sunken
2509 label .branch.l1 \
2510         -text [mc "Current Branch:"] \
2511         -anchor w \
2512         -justify left
2513 label .branch.cb \
2514         -textvariable current_branch \
2515         -anchor w \
2516         -justify left
2517 pack .branch.l1 -side left
2518 pack .branch.cb -side left -fill x
2519 pack .branch -side top -fill x
2520
2521 # -- Main Window Layout
2522 #
2523 panedwindow .vpane -orient horizontal
2524 panedwindow .vpane.files -orient vertical
2525 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2526 pack .vpane -anchor n -side top -fill both -expand 1
2527
2528 # -- Index File List
2529 #
2530 frame .vpane.files.index -height 100 -width 200
2531 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2532         -background lightgreen -foreground black
2533 text $ui_index -background white -foreground black \
2534         -borderwidth 0 \
2535         -width 20 -height 10 \
2536         -wrap none \
2537         -cursor $cursor_ptr \
2538         -xscrollcommand {.vpane.files.index.sx set} \
2539         -yscrollcommand {.vpane.files.index.sy set} \
2540         -state disabled
2541 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2542 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2543 pack .vpane.files.index.title -side top -fill x
2544 pack .vpane.files.index.sx -side bottom -fill x
2545 pack .vpane.files.index.sy -side right -fill y
2546 pack $ui_index -side left -fill both -expand 1
2547
2548 # -- Working Directory File List
2549 #
2550 frame .vpane.files.workdir -height 100 -width 200
2551 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2552         -background lightsalmon -foreground black
2553 text $ui_workdir -background white -foreground black \
2554         -borderwidth 0 \
2555         -width 20 -height 10 \
2556         -wrap none \
2557         -cursor $cursor_ptr \
2558         -xscrollcommand {.vpane.files.workdir.sx set} \
2559         -yscrollcommand {.vpane.files.workdir.sy set} \
2560         -state disabled
2561 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2562 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2563 pack .vpane.files.workdir.title -side top -fill x
2564 pack .vpane.files.workdir.sx -side bottom -fill x
2565 pack .vpane.files.workdir.sy -side right -fill y
2566 pack $ui_workdir -side left -fill both -expand 1
2567
2568 .vpane.files add .vpane.files.workdir -sticky nsew
2569 .vpane.files add .vpane.files.index -sticky nsew
2570
2571 foreach i [list $ui_index $ui_workdir] {
2572         rmsel_tag $i
2573         $i tag conf in_diff -background [$i tag cget in_sel -background]
2574 }
2575 unset i
2576
2577 # -- Diff and Commit Area
2578 #
2579 frame .vpane.lower -height 300 -width 400
2580 frame .vpane.lower.commarea
2581 frame .vpane.lower.diff -relief sunken -borderwidth 1
2582 pack .vpane.lower.diff -fill both -expand 1
2583 pack .vpane.lower.commarea -side bottom -fill x
2584 .vpane add .vpane.lower -sticky nsew
2585
2586 # -- Commit Area Buttons
2587 #
2588 frame .vpane.lower.commarea.buttons
2589 label .vpane.lower.commarea.buttons.l -text {} \
2590         -anchor w \
2591         -justify left
2592 pack .vpane.lower.commarea.buttons.l -side top -fill x
2593 pack .vpane.lower.commarea.buttons -side left -fill y
2594
2595 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2596         -command ui_do_rescan
2597 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2598 lappend disable_on_lock \
2599         {.vpane.lower.commarea.buttons.rescan conf -state}
2600
2601 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2602         -command do_add_all
2603 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2604 lappend disable_on_lock \
2605         {.vpane.lower.commarea.buttons.incall conf -state}
2606
2607 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2608         -command do_signoff
2609 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2610
2611 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2612         -command do_commit
2613 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2614 lappend disable_on_lock \
2615         {.vpane.lower.commarea.buttons.commit conf -state}
2616
2617 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2618         -command do_push_anywhere
2619 pack .vpane.lower.commarea.buttons.push -side top -fill x
2620
2621 # -- Commit Message Buffer
2622 #
2623 frame .vpane.lower.commarea.buffer
2624 frame .vpane.lower.commarea.buffer.header
2625 set ui_comm .vpane.lower.commarea.buffer.t
2626 set ui_coml .vpane.lower.commarea.buffer.header.l
2627 radiobutton .vpane.lower.commarea.buffer.header.new \
2628         -text [mc "New Commit"] \
2629         -command do_select_commit_type \
2630         -variable selected_commit_type \
2631         -value new
2632 lappend disable_on_lock \
2633         [list .vpane.lower.commarea.buffer.header.new conf -state]
2634 radiobutton .vpane.lower.commarea.buffer.header.amend \
2635         -text [mc "Amend Last Commit"] \
2636         -command do_select_commit_type \
2637         -variable selected_commit_type \
2638         -value amend
2639 lappend disable_on_lock \
2640         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2641 label $ui_coml \
2642         -anchor w \
2643         -justify left
2644 proc trace_commit_type {varname args} {
2645         global ui_coml commit_type
2646         switch -glob -- $commit_type {
2647         initial       {set txt [mc "Initial Commit Message:"]}
2648         amend         {set txt [mc "Amended Commit Message:"]}
2649         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2650         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2651         merge         {set txt [mc "Merge Commit Message:"]}
2652         *             {set txt [mc "Commit Message:"]}
2653         }
2654         $ui_coml conf -text $txt
2655 }
2656 trace add variable commit_type write trace_commit_type
2657 pack $ui_coml -side left -fill x
2658 pack .vpane.lower.commarea.buffer.header.amend -side right
2659 pack .vpane.lower.commarea.buffer.header.new -side right
2660
2661 text $ui_comm -background white -foreground black \
2662         -borderwidth 1 \
2663         -undo true \
2664         -maxundo 20 \
2665         -autoseparators true \
2666         -relief sunken \
2667         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2668         -font font_diff \
2669         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2670 scrollbar .vpane.lower.commarea.buffer.sby \
2671         -command [list $ui_comm yview]
2672 pack .vpane.lower.commarea.buffer.header -side top -fill x
2673 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2674 pack $ui_comm -side left -fill y
2675 pack .vpane.lower.commarea.buffer -side left -fill y
2676
2677 # -- Commit Message Buffer Context Menu
2678 #
2679 set ctxm .vpane.lower.commarea.buffer.ctxm
2680 menu $ctxm -tearoff 0
2681 $ctxm add command \
2682         -label [mc Cut] \
2683         -command {tk_textCut $ui_comm}
2684 $ctxm add command \
2685         -label [mc Copy] \
2686         -command {tk_textCopy $ui_comm}
2687 $ctxm add command \
2688         -label [mc Paste] \
2689         -command {tk_textPaste $ui_comm}
2690 $ctxm add command \
2691         -label [mc Delete] \
2692         -command {$ui_comm delete sel.first sel.last}
2693 $ctxm add separator
2694 $ctxm add command \
2695         -label [mc "Select All"] \
2696         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2697 $ctxm add command \
2698         -label [mc "Copy All"] \
2699         -command {
2700                 $ui_comm tag add sel 0.0 end
2701                 tk_textCopy $ui_comm
2702                 $ui_comm tag remove sel 0.0 end
2703         }
2704 $ctxm add separator
2705 $ctxm add command \
2706         -label [mc "Sign Off"] \
2707         -command do_signoff
2708 set ui_comm_ctxm $ctxm
2709
2710 # -- Diff Header
2711 #
2712 proc trace_current_diff_path {varname args} {
2713         global current_diff_path diff_actions file_states
2714         if {$current_diff_path eq {}} {
2715                 set s {}
2716                 set f {}
2717                 set p {}
2718                 set o disabled
2719         } else {
2720                 set p $current_diff_path
2721                 set s [mapdesc [lindex $file_states($p) 0] $p]
2722                 set f [mc "File:"]
2723                 set p [escape_path $p]
2724                 set o normal
2725         }
2726
2727         .vpane.lower.diff.header.status configure -text $s
2728         .vpane.lower.diff.header.file configure -text $f
2729         .vpane.lower.diff.header.path configure -text $p
2730         foreach w $diff_actions {
2731                 uplevel #0 $w $o
2732         }
2733 }
2734 trace add variable current_diff_path write trace_current_diff_path
2735
2736 frame .vpane.lower.diff.header -background gold
2737 label .vpane.lower.diff.header.status \
2738         -background gold \
2739         -foreground black \
2740         -width $max_status_desc \
2741         -anchor w \
2742         -justify left
2743 label .vpane.lower.diff.header.file \
2744         -background gold \
2745         -foreground black \
2746         -anchor w \
2747         -justify left
2748 label .vpane.lower.diff.header.path \
2749         -background gold \
2750         -foreground black \
2751         -anchor w \
2752         -justify left
2753 pack .vpane.lower.diff.header.status -side left
2754 pack .vpane.lower.diff.header.file -side left
2755 pack .vpane.lower.diff.header.path -fill x
2756 set ctxm .vpane.lower.diff.header.ctxm
2757 menu $ctxm -tearoff 0
2758 $ctxm add command \
2759         -label [mc Copy] \
2760         -command {
2761                 clipboard clear
2762                 clipboard append \
2763                         -format STRING \
2764                         -type STRING \
2765                         -- $current_diff_path
2766         }
2767 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2768 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2769
2770 # -- Diff Body
2771 #
2772 frame .vpane.lower.diff.body
2773 set ui_diff .vpane.lower.diff.body.t
2774 text $ui_diff -background white -foreground black \
2775         -borderwidth 0 \
2776         -width 80 -height 15 -wrap none \
2777         -font font_diff \
2778         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2779         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2780         -state disabled
2781 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2782         -command [list $ui_diff xview]
2783 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2784         -command [list $ui_diff yview]
2785 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2786 pack .vpane.lower.diff.body.sby -side right -fill y
2787 pack $ui_diff -side left -fill both -expand 1
2788 pack .vpane.lower.diff.header -side top -fill x
2789 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2790
2791 $ui_diff tag conf d_cr -elide true
2792 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2793 $ui_diff tag conf d_+ -foreground {#00a000}
2794 $ui_diff tag conf d_- -foreground red
2795
2796 $ui_diff tag conf d_++ -foreground {#00a000}
2797 $ui_diff tag conf d_-- -foreground red
2798 $ui_diff tag conf d_+s \
2799         -foreground {#00a000} \
2800         -background {#e2effa}
2801 $ui_diff tag conf d_-s \
2802         -foreground red \
2803         -background {#e2effa}
2804 $ui_diff tag conf d_s+ \
2805         -foreground {#00a000} \
2806         -background ivory1
2807 $ui_diff tag conf d_s- \
2808         -foreground red \
2809         -background ivory1
2810
2811 $ui_diff tag conf d<<<<<<< \
2812         -foreground orange \
2813         -font font_diffbold
2814 $ui_diff tag conf d======= \
2815         -foreground orange \
2816         -font font_diffbold
2817 $ui_diff tag conf d>>>>>>> \
2818         -foreground orange \
2819         -font font_diffbold
2820
2821 $ui_diff tag raise sel
2822
2823 # -- Diff Body Context Menu
2824 #
2825
2826 proc create_common_diff_popup {ctxm} {
2827         $ctxm add command \
2828                 -label [mc "Show Less Context"] \
2829                 -command show_less_context
2830         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2831         $ctxm add command \
2832                 -label [mc "Show More Context"] \
2833                 -command show_more_context
2834         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2835         $ctxm add separator
2836         $ctxm add command \
2837                 -label [mc Refresh] \
2838                 -command reshow_diff
2839         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2840         $ctxm add command \
2841                 -label [mc Copy] \
2842                 -command {tk_textCopy $ui_diff}
2843         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2844         $ctxm add command \
2845                 -label [mc "Select All"] \
2846                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2847         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2848         $ctxm add command \
2849                 -label [mc "Copy All"] \
2850                 -command {
2851                         $ui_diff tag add sel 0.0 end
2852                         tk_textCopy $ui_diff
2853                         $ui_diff tag remove sel 0.0 end
2854                 }
2855         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2856         $ctxm add separator
2857         $ctxm add command \
2858                 -label [mc "Decrease Font Size"] \
2859                 -command {incr_font_size font_diff -1}
2860         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2861         $ctxm add command \
2862                 -label [mc "Increase Font Size"] \
2863                 -command {incr_font_size font_diff 1}
2864         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2865         $ctxm add separator
2866         $ctxm add command -label [mc "Options..."] \
2867                 -command do_options
2868 }
2869
2870 set ctxm .vpane.lower.diff.body.ctxm
2871 menu $ctxm -tearoff 0
2872 $ctxm add command \
2873         -label [mc "Apply/Reverse Hunk"] \
2874         -command {apply_hunk $cursorX $cursorY}
2875 set ui_diff_applyhunk [$ctxm index last]
2876 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2877 $ctxm add command \
2878         -label [mc "Apply/Reverse Line"] \
2879         -command {apply_line $cursorX $cursorY; do_rescan}
2880 set ui_diff_applyline [$ctxm index last]
2881 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2882 $ctxm add separator
2883 create_common_diff_popup $ctxm
2884
2885 set ctxmmg .vpane.lower.diff.body.ctxmmg
2886 menu $ctxmmg -tearoff 0
2887 $ctxmmg add command \
2888         -label [mc "Run Merge Tool"] \
2889         -command {merge_resolve_tool}
2890 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2891 $ctxmmg add separator
2892 $ctxmmg add command \
2893         -label [mc "Use Remote Version"] \
2894         -command {merge_resolve_one 3}
2895 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2896 $ctxmmg add command \
2897         -label [mc "Use Local Version"] \
2898         -command {merge_resolve_one 2}
2899 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2900 $ctxmmg add command \
2901         -label [mc "Revert To Base"] \
2902         -command {merge_resolve_one 1}
2903 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2904 $ctxmmg add separator
2905 $ctxmmg add command \
2906         -label [mc "Stage Working Copy"] \
2907         -command {merge_resolve_one 0}
2908 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2909 $ctxmmg add separator
2910 create_common_diff_popup $ctxmmg
2911
2912 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2913         global current_diff_path file_states
2914         set ::cursorX $x
2915         set ::cursorY $y
2916         if {[info exists file_states($current_diff_path)]} {
2917                 set state [lindex $file_states($current_diff_path) 0]
2918         } else {
2919                 set state {__}
2920         }
2921         if {[string first {U} $state] >= 0} {
2922                 tk_popup $ctxmmg $X $Y
2923         } else {
2924                 if {$::ui_index eq $::current_diff_side} {
2925                         set l [mc "Unstage Hunk From Commit"]
2926                         set t [mc "Unstage Line From Commit"]
2927                 } else {
2928                         set l [mc "Stage Hunk For Commit"]
2929                         set t [mc "Stage Line For Commit"]
2930                 }
2931                 if {$::is_3way_diff
2932                         || $current_diff_path eq {}
2933                         || {__} eq $state
2934                         || {_O} eq $state
2935                         || {_T} eq $state
2936                         || {T_} eq $state} {
2937                         set s disabled
2938                 } else {
2939                         set s normal
2940                 }
2941                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2942                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
2943                 tk_popup $ctxm $X $Y
2944         }
2945 }
2946 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
2947
2948 # -- Status Bar
2949 #
2950 set main_status [::status_bar::new .status]
2951 pack .status -anchor w -side bottom -fill x
2952 $main_status show [mc "Initializing..."]
2953
2954 # -- Load geometry
2955 #
2956 catch {
2957 set gm $repo_config(gui.geometry)
2958 wm geometry . [lindex $gm 0]
2959 .vpane sash place 0 \
2960         [lindex $gm 1] \
2961         [lindex [.vpane sash coord 0] 1]
2962 .vpane.files sash place 0 \
2963         [lindex [.vpane.files sash coord 0] 0] \
2964         [lindex $gm 2]
2965 unset gm
2966 }
2967
2968 # -- Key Bindings
2969 #
2970 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2971 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2972 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2973 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2974 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2975 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2976 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2977 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2978 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2979 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2980 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2981 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2982 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2983 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
2984 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
2985 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
2986 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
2987 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
2988
2989 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2990 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2991 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2992 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2993 bind $ui_diff <$M1B-Key-v> {break}
2994 bind $ui_diff <$M1B-Key-V> {break}
2995 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2996 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2997 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2998 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2999 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3000 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3001 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3002 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3003 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3004 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3005 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3006 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3007 bind $ui_diff <Button-1>   {focus %W}
3008
3009 if {[is_enabled branch]} {
3010         bind . <$M1B-Key-n> branch_create::dialog
3011         bind . <$M1B-Key-N> branch_create::dialog
3012         bind . <$M1B-Key-o> branch_checkout::dialog
3013         bind . <$M1B-Key-O> branch_checkout::dialog
3014         bind . <$M1B-Key-m> merge::dialog
3015         bind . <$M1B-Key-M> merge::dialog
3016 }
3017 if {[is_enabled transport]} {
3018         bind . <$M1B-Key-p> do_push_anywhere
3019         bind . <$M1B-Key-P> do_push_anywhere
3020 }
3021
3022 bind .   <Key-F5>     ui_do_rescan
3023 bind .   <$M1B-Key-r> ui_do_rescan
3024 bind .   <$M1B-Key-R> ui_do_rescan
3025 bind .   <$M1B-Key-s> do_signoff
3026 bind .   <$M1B-Key-S> do_signoff
3027 bind .   <$M1B-Key-t> do_add_selection
3028 bind .   <$M1B-Key-T> do_add_selection
3029 bind .   <$M1B-Key-i> do_add_all
3030 bind .   <$M1B-Key-I> do_add_all
3031 bind .   <$M1B-Key-minus> {show_less_context;break}
3032 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3033 bind .   <$M1B-Key-equal> {show_more_context;break}
3034 bind .   <$M1B-Key-plus> {show_more_context;break}
3035 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3036 bind .   <$M1B-Key-Return> do_commit
3037 foreach i [list $ui_index $ui_workdir] {
3038         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3039         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3040         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3041 }
3042 unset i
3043
3044 set file_lists($ui_index) [list]
3045 set file_lists($ui_workdir) [list]
3046
3047 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3048 focus -force $ui_comm
3049
3050 # -- Warn the user about environmental problems.  Cygwin's Tcl
3051 #    does *not* pass its env array onto any processes it spawns.
3052 #    This means that git processes get none of our environment.
3053 #
3054 if {[is_Cygwin]} {
3055         set ignored_env 0
3056         set suggest_user {}
3057         set msg [mc "Possible environment issues exist.
3058
3059 The following environment variables are probably
3060 going to be ignored by any Git subprocess run
3061 by %s:
3062
3063 " [appname]]
3064         foreach name [array names env] {
3065                 switch -regexp -- $name {
3066                 {^GIT_INDEX_FILE$} -
3067                 {^GIT_OBJECT_DIRECTORY$} -
3068                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3069                 {^GIT_DIFF_OPTS$} -
3070                 {^GIT_EXTERNAL_DIFF$} -
3071                 {^GIT_PAGER$} -
3072                 {^GIT_TRACE$} -
3073                 {^GIT_CONFIG$} -
3074                 {^GIT_CONFIG_LOCAL$} -
3075                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3076                         append msg " - $name\n"
3077                         incr ignored_env
3078                 }
3079                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3080                         append msg " - $name\n"
3081                         incr ignored_env
3082                         set suggest_user $name
3083                 }
3084                 }
3085         }
3086         if {$ignored_env > 0} {
3087                 append msg [mc "
3088 This is due to a known issue with the
3089 Tcl binary distributed by Cygwin."]
3090
3091                 if {$suggest_user ne {}} {
3092                         append msg [mc "
3093
3094 A good replacement for %s
3095 is placing values for the user.name and
3096 user.email settings into your personal
3097 ~/.gitconfig file.
3098 " $suggest_user]
3099                 }
3100                 warn_popup $msg
3101         }
3102         unset ignored_env msg suggest_user name
3103 }
3104
3105 # -- Only initialize complex UI if we are going to stay running.
3106 #
3107 if {[is_enabled transport]} {
3108         load_all_remotes
3109
3110         set n [.mbar.remote index end]
3111         populate_push_menu
3112         populate_fetch_menu
3113         set n [expr {[.mbar.remote index end] - $n}]
3114         if {$n > 0} {
3115                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3116                 .mbar.remote insert $n separator
3117         }
3118         unset n
3119 }
3120
3121 if {[winfo exists $ui_comm]} {
3122         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3123
3124         # -- If both our backup and message files exist use the
3125         #    newer of the two files to initialize the buffer.
3126         #
3127         if {$GITGUI_BCK_exists} {
3128                 set m [gitdir GITGUI_MSG]
3129                 if {[file isfile $m]} {
3130                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3131                                 catch {file delete [gitdir GITGUI_MSG]}
3132                         } else {
3133                                 $ui_comm delete 0.0 end
3134                                 $ui_comm edit reset
3135                                 $ui_comm edit modified false
3136                                 catch {file delete [gitdir GITGUI_BCK]}
3137                                 set GITGUI_BCK_exists 0
3138                         }
3139                 }
3140                 unset m
3141         }
3142
3143         proc backup_commit_buffer {} {
3144                 global ui_comm GITGUI_BCK_exists
3145
3146                 set m [$ui_comm edit modified]
3147                 if {$m || $GITGUI_BCK_exists} {
3148                         set msg [string trim [$ui_comm get 0.0 end]]
3149                         regsub -all -line {[ \r\t]+$} $msg {} msg
3150
3151                         if {$msg eq {}} {
3152                                 if {$GITGUI_BCK_exists} {
3153                                         catch {file delete [gitdir GITGUI_BCK]}
3154                                         set GITGUI_BCK_exists 0
3155                                 }
3156                         } elseif {$m} {
3157                                 catch {
3158                                         set fd [open [gitdir GITGUI_BCK] w]
3159                                         puts -nonewline $fd $msg
3160                                         close $fd
3161                                         set GITGUI_BCK_exists 1
3162                                 }
3163                         }
3164
3165                         $ui_comm edit modified false
3166                 }
3167
3168                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3169         }
3170
3171         backup_commit_buffer
3172
3173         # -- If the user has aspell available we can drive it
3174         #    in pipe mode to spellcheck the commit message.
3175         #
3176         set spell_cmd [list |]
3177         set spell_dict [get_config gui.spellingdictionary]
3178         lappend spell_cmd aspell
3179         if {$spell_dict ne {}} {
3180                 lappend spell_cmd --master=$spell_dict
3181         }
3182         lappend spell_cmd --mode=none
3183         lappend spell_cmd --encoding=utf-8
3184         lappend spell_cmd pipe
3185         if {$spell_dict eq {none}
3186          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3187                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3188         } else {
3189                 set ui_comm_spell [spellcheck::init \
3190                         $spell_fd \
3191                         $ui_comm \
3192                         $ui_comm_ctxm \
3193                 ]
3194         }
3195         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3196 }
3197
3198 lock_index begin-read
3199 if {![winfo ismapped .]} {
3200         wm deiconify .
3201 }
3202 after 1 do_rescan
3203 if {[is_enabled multicommit]} {
3204         after 1000 hint_gc
3205 }