lib/blame.tcl

   1 # git-gui blame viewer
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class blame {
   5
   6 image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
   7
   8 field commit    ; # input commit to blame
   9 field path      ; # input filename to view in $commit
  10 field history {}; # viewer history: {commit path}
  11
  12 field w          ; # top window in this viewer
  13 field w_back     ; # our back button
  14 field w_path     ; # label showing the current file path
  15 field w_line     ; # text column: all line numbers
  16 field w_cgrp     ; # text column: abbreviated commit SHA-1s
  17 field w_file     ; # text column: actual file data
  18 field w_cmit     ; # pane showing commit message
  19 field status     ; # text variable bound to status bar
  20 field old_height ; # last known height of $w.file_pane
  21
  22 field current_fd       {} ; # background process running
  23 field highlight_line   -1 ; # current line selected
  24 field highlight_commit {} ; # sha1 of commit selected
  25
  26 field total_lines       0  ; # total length of file
  27 field blame_lines       0  ; # number of lines computed
  28 field commit_count      0  ; # number of commits in $commit_list
  29 field commit_list      {}  ; # list of commit sha1 in receipt order
  30 field order                ; # array commit -> receipt order
  31 field header               ; # array commit,key -> header field
  32 field line_commit          ; # array line -> sha1 commit
  33 field line_file            ; # array line -> file name
  34
  35 field r_commit      ; # commit currently being parsed
  36 field r_orig_line   ; # original line number
  37 field r_final_line  ; # final line number
  38 field r_line_count  ; # lines in this region
  39
  40 field tooltip_wm     {} ; # Current tooltip toplevel, if open
  41 field tooltip_timer  {} ; # Current timer event for our tooltip
  42 field tooltip_commit {} ; # Commit in tooltip
  43 field tooltip_text   {} ; # Text in current tooltip
  44
  45 variable active_color #98e1a0
  46 variable group_colors {
  47         #cbcbcb
  48         #e1e1e1
  49 }
  50
  51 constructor new {i_commit i_path} {
  52         variable active_color
  53         global cursor_ptr
  54
  55         set commit $i_commit
  56         set path   $i_path
  57
  58         make_toplevel top w
  59         wm title $top "[appname] ([reponame]): File Viewer"
  60
  61         frame $w.header -background orange
  62         label $w.header.commit_l \
  63                 -text {Commit:} \
  64                 -background orange \
  65                 -anchor w \
  66                 -justify left
  67         set w_back $w.header.commit_b
  68         label $w_back \
  69                 -image ::blame::img_back_arrow \
  70                 -borderwidth 0 \
  71                 -relief flat \
  72                 -state disabled \
  73                 -background orange \
  74                 -activebackground orange
  75         bind $w_back <Button-1> "
  76                 if {\[$w_back cget -state\] eq {normal}} {
  77                         [cb _history_menu]
  78                 }
  79                 "
  80         label $w.header.commit \
  81                 -textvariable @commit \
  82                 -background orange \
  83                 -anchor w \
  84                 -justify left
  85         label $w.header.path_l \
  86                 -text {File:} \
  87                 -background orange \
  88                 -anchor w \
  89                 -justify left
  90         set w_path $w.header.path
  91         label $w_path \
  92                 -background orange \
  93                 -anchor w \
  94                 -justify left
  95         pack $w.header.commit_l -side left
  96         pack $w_back -side left
  97         pack $w.header.commit -side left
  98         pack $w_path -fill x -side right
  99         pack $w.header.path_l -side right
 100
 101         panedwindow $w.file_pane -orient vertical
 102         frame $w.file_pane.out
 103         frame $w.file_pane.cm
 104         $w.file_pane add $w.file_pane.out \
 105                 -sticky nsew \
 106                 -minsize 100 \
 107                 -height 100 \
 108                 -width 100
 109         $w.file_pane add $w.file_pane.cm \
 110                 -sticky nsew \
 111                 -minsize 25 \
 112                 -height 25 \
 113                 -width 100
 114
 115         set w_line $w.file_pane.out.linenumber_t
 116         text $w_line \
 117                 -takefocus 0 \
 118                 -highlightthickness 0 \
 119                 -padx 0 -pady 0 \
 120                 -background white -borderwidth 0 \
 121                 -state disabled \
 122                 -wrap none \
 123                 -height 40 \
 124                 -width 5 \
 125                 -font font_diff
 126         $w_line tag conf linenumber -justify right -rmargin 5
 127
 128         set w_cgrp $w.file_pane.out.commit_t
 129         text $w_cgrp \
 130                 -takefocus 0 \
 131                 -highlightthickness 0 \
 132                 -padx 0 -pady 0 \
 133                 -background white -borderwidth 0 \
 134                 -state disabled \
 135                 -wrap none \
 136                 -height 40 \
 137                 -width 4 \
 138                 -font font_diff
 139         $w_cgrp tag conf curr_commit
 140         $w_cgrp tag conf prior_commit \
 141                 -foreground blue \
 142                 -underline 1
 143         $w_cgrp tag bind prior_commit \
 144                 <Button-1> \
 145                 "[cb _load_commit @%x,%y];break"
 146
 147         set w_file $w.file_pane.out.file_t
 148         text $w_file \
 149                 -takefocus 0 \
 150                 -highlightthickness 0 \
 151                 -padx 0 -pady 0 \
 152                 -background white -borderwidth 0 \
 153                 -state disabled \
 154                 -wrap none \
 155                 -height 40 \
 156                 -width 80 \
 157                 -xscrollcommand [list $w.file_pane.out.sbx set] \
 158                 -font font_diff
 159
 160         scrollbar $w.file_pane.out.sbx \
 161                 -orient h \
 162                 -command [list $w_file xview]
 163         scrollbar $w.file_pane.out.sby \
 164                 -orient v \
 165                 -command [list scrollbar2many [list \
 166                 $w_line \
 167                 $w_cgrp \
 168                 $w_file \
 169                 ] yview]
 170         grid \
 171                 $w_cgrp \
 172                 $w_line \
 173                 $w_file \
 174                 $w.file_pane.out.sby \
 175                 -sticky nsew
 176         grid conf $w.file_pane.out.sbx -column 2 -sticky we
 177         grid columnconfigure $w.file_pane.out 2 -weight 1
 178         grid rowconfigure $w.file_pane.out 0 -weight 1
 179
 180         set w_cmit $w.file_pane.cm.t
 181         text $w_cmit \
 182                 -background white -borderwidth 0 \
 183                 -state disabled \
 184                 -wrap none \
 185                 -height 10 \
 186                 -width 80 \
 187                 -xscrollcommand [list $w.file_pane.cm.sbx set] \
 188                 -yscrollcommand [list $w.file_pane.cm.sby set] \
 189                 -font font_diff
 190         $w_cmit tag conf header_key \
 191                 -tabs {3c} \
 192                 -background $active_color \
 193                 -font font_uibold
 194         $w_cmit tag conf header_val \
 195                 -background $active_color \
 196                 -font font_ui
 197         $w_cmit tag raise sel
 198         scrollbar $w.file_pane.cm.sbx \
 199                 -orient h \
 200                 -command [list $w_cmit xview]
 201         scrollbar $w.file_pane.cm.sby \
 202                 -orient v \
 203                 -command [list $w_cmit yview]
 204         pack $w.file_pane.cm.sby -side right -fill y
 205         pack $w.file_pane.cm.sbx -side bottom -fill x
 206         pack $w_cmit -expand 1 -fill both
 207
 208         frame $w.status \
 209                 -borderwidth 1 \
 210                 -relief sunken
 211         label $w.status.l \
 212                 -textvariable @status \
 213                 -anchor w \
 214                 -justify left
 215         pack $w.status.l -side left
 216
 217         menu $w.ctxm -tearoff 0
 218         $w.ctxm add command \
 219                 -label "Copy Commit" \
 220                 -command [cb _copycommit]
 221
 222         foreach i [list \
 223                 $w_cgrp \
 224                 $w_line \
 225                 $w_file] {
 226                 $i conf -cursor $cursor_ptr
 227                 $i conf -yscrollcommand \
 228                         [list many2scrollbar [list \
 229                         $w_cgrp \
 230                         $w_line \
 231                         $w_file \
 232                         ] yview $w.file_pane.out.sby]
 233                 bind $i <Button-1> "
 234                         [cb _hide_tooltip]
 235                         [cb _click $i @%x,%y]
 236                         focus $i
 237                 "
 238                 bind $i <Any-Motion>  [cb _show_tooltip $i @%x,%y]
 239                 bind $i <Any-Enter>   [cb _hide_tooltip]
 240                 bind $i <Any-Leave>   [cb _hide_tooltip]
 241                 bind_button3 $i "
 242                         [cb _hide_tooltip]
 243                         set cursorX %x
 244                         set cursorY %y
 245                         set cursorW %W
 246                         tk_popup $w.ctxm %X %Y
 247                 "
 248         }
 249
 250         foreach i [list \
 251                 $w_cgrp \
 252                 $w_line \
 253                 $w_file \
 254                 $w_cmit] {
 255                 bind $i <Key-Up>        {catch {%W yview scroll -1 units};break}
 256                 bind $i <Key-Down>      {catch {%W yview scroll  1 units};break}
 257                 bind $i <Key-Left>      {catch {%W xview scroll -1 units};break}
 258                 bind $i <Key-Right>     {catch {%W xview scroll  1 units};break}
 259                 bind $i <Key-k>         {catch {%W yview scroll -1 units};break}
 260                 bind $i <Key-j>         {catch {%W yview scroll  1 units};break}
 261                 bind $i <Key-h>         {catch {%W xview scroll -1 units};break}
 262                 bind $i <Key-l>         {catch {%W xview scroll  1 units};break}
 263                 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
 264                 bind $i <Control-Key-f> {catch {%W yview scroll  1 pages};break}
 265         }
 266
 267         bind $w_cmit <Button-1> [list focus $w_cmit]
 268         bind $top <Visibility> [list focus $top]
 269         bind $w_file <Destroy> [list delete_this $this]
 270
 271         grid configure $w.header -sticky ew
 272         grid configure $w.file_pane -sticky nsew
 273         grid configure $w.status -sticky ew
 274         grid columnconfigure $top 0 -weight 1
 275         grid rowconfigure $top 0 -weight 0
 276         grid rowconfigure $top 1 -weight 1
 277         grid rowconfigure $top 2 -weight 0
 278
 279         set req_w [winfo reqwidth  $top]
 280         set req_h [winfo reqheight $top]
 281         if {$req_w < 600} {set req_w 600}
 282         if {$req_h < 400} {set req_h 400}
 283         set g "${req_w}x${req_h}"
 284         wm geometry $top $g
 285         update
 286
 287         set old_height [winfo height $w.file_pane]
 288         $w.file_pane sash place 0 \
 289                 [lindex [$w.file_pane sash coord 0] 0] \
 290                 [expr {int($old_height * 0.70)}]
 291         bind $w.file_pane <Configure> \
 292         "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
 293
 294         _load $this
 295 }
 296
 297 method _load {} {
 298         _hide_tooltip $this
 299
 300         if {$total_lines != 0 || $current_fd ne {}} {
 301                 if {$current_fd ne {}} {
 302                         catch {close $current_fd}
 303                         set current_fd {}
 304                 }
 305
 306                 set highlight_line -1
 307                 set highlight_commit {}
 308                 set total_lines 0
 309                 set blame_lines 0
 310                 set commit_count 0
 311                 set commit_list {}
 312                 array unset order
 313                 array unset line_commit
 314                 array unset line_file
 315
 316                 $w_cgrp conf -state normal
 317                 $w_line conf -state normal
 318                 $w_file conf -state normal
 319
 320                 $w_cgrp delete 0.0 end
 321                 $w_line delete 0.0 end
 322                 $w_file delete 0.0 end
 323
 324                 $w_cgrp conf -state disabled
 325                 $w_line conf -state disabled
 326                 $w_file conf -state disabled
 327         }
 328
 329         if {[winfo exists $w.status.c]} {
 330                 $w.status.c coords bar 0 0 0 20
 331         } else {
 332                 canvas $w.status.c \
 333                         -width 100 \
 334                         -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
 335                         -borderwidth 1 \
 336                         -relief groove \
 337                         -highlightt 0
 338                 $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
 339                 pack $w.status.c -side right
 340         }
 341
 342         if {$history eq {}} {
 343                 $w_back conf -state disabled
 344         } else {
 345                 $w_back conf -state normal
 346         }
 347         lappend history [list $commit $path]
 348
 349         set status "Loading $commit:[escape_path $path]..."
 350         $w_path conf -text [escape_path $path]
 351         if {$commit eq {}} {
 352                 set fd [open $path r]
 353         } else {
 354                 set cmd [list git cat-file blob "$commit:$path"]
 355                 set fd [open "| $cmd" r]
 356         }
 357         fconfigure $fd -blocking 0 -translation lf -encoding binary
 358         fileevent $fd readable [cb _read_file $fd]
 359         set current_fd $fd
 360 }
 361
 362 method _history_menu {} {
 363         set m $w.backmenu
 364         if {[winfo exists $m]} {
 365                 $m delete 0 end
 366         } else {
 367                 menu $m -tearoff 0
 368         }
 369
 370         for {set i [expr {[llength $history] - 2}]
 371                 } {$i >= 0} {incr i -1} {
 372                 set e [lindex $history $i]
 373                 set c [lindex $e 0]
 374                 set f [lindex $e 1]
 375
 376                 if {[regexp {^[0-9a-f]{40}$} $c]} {
 377                         set t [string range $c 0 8]...
 378                 } else {
 379                         set t $c
 380                 }
 381                 if {![catch {set summary $header($c,summary)}]} {
 382                         append t " $summary"
 383                         if {[string length $t] > 70} {
 384                                 set t [string range $t 0 66]...
 385                         }
 386                 }
 387
 388                 $m add command -label $t -command [cb _goback $i $c $f]
 389         }
 390         set X [winfo rootx $w_back]
 391         set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
 392         tk_popup $m $X $Y
 393 }
 394
 395 method _goback {i c f} {
 396         set history [lrange $history 0 [expr {$i - 1}]]
 397         set commit $c
 398         set path $f
 399         _load $this
 400 }
 401
 402 method _read_file {fd} {
 403         if {$fd ne $current_fd} {
 404                 catch {close $fd}
 405                 return
 406         }
 407
 408         $w_cgrp conf -state normal
 409         $w_line conf -state normal
 410         $w_file conf -state normal
 411         while {[gets $fd line] >= 0} {
 412                 regsub "\r\$" $line {} line
 413                 incr total_lines
 414
 415                 if {$total_lines > 1} {
 416                         $w_cgrp insert end "\n"
 417                         $w_line insert end "\n"
 418                         $w_file insert end "\n"
 419                 }
 420
 421                 $w_line insert end "$total_lines" linenumber
 422                 $w_file insert end "$line"
 423         }
 424         $w_cgrp conf -state disabled
 425         $w_line conf -state disabled
 426         $w_file conf -state disabled
 427
 428         if {[eof $fd]} {
 429                 close $fd
 430                 _status $this
 431                 set cmd {nice git blame -M -C --incremental}
 432                 if {$commit eq {}} {
 433                         lappend cmd --contents $path
 434                 } else {
 435                         lappend cmd $commit
 436                 }
 437                 lappend cmd -- $path
 438                 set fd [open "| $cmd" r]
 439                 fconfigure $fd -blocking 0 -translation lf -encoding binary
 440                 fileevent $fd readable [cb _read_blame $fd]
 441                 set current_fd $fd
 442         }
 443 } ifdeleted { catch {close $fd} }
 444
 445 method _read_blame {fd} {
 446         variable group_colors
 447
 448         if {$fd ne $current_fd} {
 449                 catch {close $fd}
 450                 return
 451         }
 452
 453         $w_cgrp conf -state normal
 454         while {[gets $fd line] >= 0} {
 455                 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
 456                         cmit original_line final_line line_count]} {
 457                         set r_commit     $cmit
 458                         set r_orig_line  $original_line
 459                         set r_final_line $final_line
 460                         set r_line_count $line_count
 461
 462                         if {[catch {set g $order($cmit)}]} {
 463                                 set bg [lindex $group_colors 0]
 464                                 set group_colors [lrange $group_colors 1 end]
 465                                 lappend group_colors $bg
 466
 467                                 $w_cgrp tag conf g$cmit -background $bg
 468                                 $w_line tag conf g$cmit -background $bg
 469                                 $w_file tag conf g$cmit -background $bg
 470
 471                                 set order($cmit) $commit_count
 472                                 incr commit_count
 473                                 lappend commit_list $cmit
 474                         }
 475                 } elseif {[string match {filename *} $line]} {
 476                         set file [string range $line 9 end]
 477                         set n    $r_line_count
 478                         set lno  $r_final_line
 479                         set cmit $r_commit
 480
 481                         if {[regexp {^0{40}$} $cmit]} {
 482                                 set commit_abbr work
 483                                 set commit_type curr_commit
 484                         } elseif {$cmit eq $commit} {
 485                                 set commit_abbr this
 486                                 set commit_type curr_commit
 487                         } else {
 488                                 set commit_type prior_commit
 489                                 set commit_abbr [string range $cmit 0 4]
 490                         }
 491
 492                         set author_abbr {}
 493                         set a_name {}
 494                         catch {set a_name $header($cmit,author)}
 495                         while {$a_name ne {}} {
 496                                 if {![regexp {^([[:upper:]])} $a_name _a]} break
 497                                 append author_abbr $_a
 498                                 unset _a
 499                                 if {![regsub \
 500                                         {^[[:upper:]][^\s]*\s+} \
 501                                         $a_name {} a_name ]} break
 502                         }
 503                         if {$author_abbr eq {}} {
 504                                 set author_abbr { |}
 505                         } else {
 506                                 set author_abbr [string range $author_abbr 0 3]
 507                                 while {[string length $author_abbr] < 4} {
 508                                         set author_abbr " $author_abbr"
 509                                 }
 510                         }
 511                         unset a_name
 512
 513                         set first_lno $lno
 514                         while {
 515                            ![catch {set ncmit $line_commit([expr {$first_lno - 1}])}]
 516                         && ![catch {set nfile $line_file([expr {$first_lno - 1}])}]
 517                         && $ncmit eq $cmit
 518                         && $nfile eq $file
 519                         } {
 520                                 incr first_lno -1
 521                         }
 522
 523                         while {$n > 0} {
 524                                 set lno_e "$lno.0 lineend + 1c"
 525                                 if {![catch {set g g$line_commit($lno)}]} {
 526                                         $w_cgrp tag remove g$g $lno.0 $lno_e
 527                                         $w_line tag remove g$g $lno.0 $lno_e
 528                                         $w_file tag remove g$g $lno.0 $lno_e
 529
 530                                         $w_cgrp tag remove a$g $lno.0 $lno_e
 531                                         $w_line tag remove a$g $lno.0 $lno_e
 532                                         $w_file tag remove a$g $lno.0 $lno_e
 533                                 }
 534
 535                                 set line_commit($lno) $cmit
 536                                 set line_file($lno)   $file
 537
 538                                 $w_cgrp delete $lno.0 "$lno.0 lineend"
 539                                 if {$lno == $first_lno} {
 540                                         $w_cgrp insert $lno.0 $commit_abbr $commit_type
 541                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 542                                         $w_cgrp insert $lno.0 $author_abbr
 543                                 } else {
 544                                         $w_cgrp insert $lno.0 { |}
 545                                 }
 546
 547                                 $w_cgrp tag add g$cmit $lno.0 $lno_e
 548                                 $w_line tag add g$cmit $lno.0 $lno_e
 549                                 $w_file tag add g$cmit $lno.0 $lno_e
 550
 551                                 $w_cgrp tag add a$cmit $lno.0 $lno_e
 552                                 $w_line tag add a$cmit $lno.0 $lno_e
 553                                 $w_file tag add a$cmit $lno.0 $lno_e
 554
 555                                 if {$highlight_line == -1} {
 556                                         if {[lindex [$w_file yview] 0] == 0} {
 557                                                 $w_file see $lno.0
 558                                                 _showcommit $this $lno
 559                                         }
 560                                 } elseif {$highlight_line == $lno} {
 561                                         _showcommit $this $lno
 562                                 }
 563
 564                                 incr n -1
 565                                 incr lno
 566                                 incr blame_lines
 567                         }
 568
 569                         while {
 570                            ![catch {set ncmit $line_commit($lno)}]
 571                         && ![catch {set nfile $line_file($lno)}]
 572                         && $ncmit eq $cmit
 573                         && $nfile eq $file
 574                         } {
 575                                 $w_cgrp delete $lno.0 "$lno.0 lineend"
 576
 577                                 if {$lno == $first_lno} {
 578                                         $w_cgrp insert $lno.0 $commit_abbr $commit_type
 579                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 580                                         $w_cgrp insert $lno.0 $author_abbr
 581                                 } else {
 582                                         $w_cgrp insert $lno.0 { |}
 583                                 }
 584                                 incr lno
 585                         }
 586
 587                 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
 588                         set header($r_commit,$key) $data
 589                 }
 590         }
 591         $w_cgrp conf -state disabled
 592
 593         if {[eof $fd]} {
 594                 close $fd
 595                 set current_fd {}
 596                 set status {Annotation complete.}
 597                 destroy $w.status.c
 598         } else {
 599                 _status $this
 600         }
 601 } ifdeleted { catch {close $fd} }
 602
 603 method _status {} {
 604         set have  $blame_lines
 605         set total $total_lines
 606         set pdone 0
 607         if {$total} {set pdone [expr {100 * $have / $total}]}
 608
 609         set status [format \
 610                 "Loading annotations... %i of %i lines annotated (%2i%%)" \
 611                 $have $total $pdone]
 612         $w.status.c coords bar 0 0 $pdone 20
 613 }
 614
 615 method _click {cur_w pos} {
 616         set lno [lindex [split [$cur_w index $pos] .] 0]
 617         if {$lno eq {}} return
 618         _showcommit $this $lno
 619 }
 620
 621 method _load_commit {pos} {
 622         set lno [lindex [split [$w_cgrp index $pos] .] 0]
 623         if {[catch {set cmit $line_commit($lno)}]} return
 624         if {[catch {set file $line_file($lno)  }]} return
 625
 626         set commit $cmit
 627         set path $file
 628         _load $this
 629 }
 630
 631 method _showcommit {lno} {
 632         global repo_config
 633         variable active_color
 634
 635         if {$highlight_commit ne {}} {
 636                 set cmit $highlight_commit
 637                 $w_cgrp tag conf a$cmit -background {}
 638                 $w_line tag conf a$cmit -background {}
 639                 $w_file tag conf a$cmit -background {}
 640         }
 641
 642         $w_cmit conf -state normal
 643         $w_cmit delete 0.0 end
 644         if {[catch {set cmit $line_commit($lno)}]} {
 645                 set cmit {}
 646                 $w_cmit insert end "Loading annotation..."
 647         } else {
 648                 $w_cgrp tag conf a$cmit -background $active_color
 649                 $w_line tag conf a$cmit -background $active_color
 650                 $w_file tag conf a$cmit -background $active_color
 651
 652                 set author_name {}
 653                 set author_email {}
 654                 set author_time {}
 655                 catch {set author_name $header($cmit,author)}
 656                 catch {set author_email $header($cmit,author-mail)}
 657                 catch {set author_time [clock format \
 658                         $header($cmit,author-time) \
 659                         -format {%Y-%m-%d %H:%M:%S}
 660                 ]}
 661
 662                 set committer_name {}
 663                 set committer_email {}
 664                 set committer_time {}
 665                 catch {set committer_name $header($cmit,committer)}
 666                 catch {set committer_email $header($cmit,committer-mail)}
 667                 catch {set committer_time [clock format \
 668                         $header($cmit,committer-time) \
 669                         -format {%Y-%m-%d %H:%M:%S}
 670                 ]}
 671
 672                 if {[catch {set msg $header($cmit,message)}]} {
 673                         set msg {}
 674                         catch {
 675                                 set fd [open "| git cat-file commit $cmit" r]
 676                                 fconfigure $fd -encoding binary -translation lf
 677                                 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 678                                         set enc utf-8
 679                                 }
 680                                 while {[gets $fd line] > 0} {
 681                                         if {[string match {encoding *} $line]} {
 682                                                 set enc [string tolower [string range $line 9 end]]
 683                                         }
 684                                 }
 685                                 set msg [encoding convertfrom $enc [read $fd]]
 686                                 set msg [string trim $msg]
 687                                 close $fd
 688
 689                                 set author_name [encoding convertfrom $enc $author_name]
 690                                 set committer_name [encoding convertfrom $enc $committer_name]
 691
 692                                 set header($cmit,author) $author_name
 693                                 set header($cmit,committer) $committer_name
 694                         }
 695                         set header($cmit,message) $msg
 696                 }
 697
 698                 $w_cmit insert end "commit $cmit\n" header_key
 699                 $w_cmit insert end "Author:\t" header_key
 700                 $w_cmit insert end "$author_name $author_email" header_val
 701                 $w_cmit insert end "$author_time\n" header_val
 702
 703                 $w_cmit insert end "Committer:\t" header_key
 704                 $w_cmit insert end "$committer_name $committer_email" header_val
 705                 $w_cmit insert end "$committer_time\n" header_val
 706
 707                 if {$line_file($lno) ne $path} {
 708                         $w_cmit insert end "Original File:\t" header_key
 709                         $w_cmit insert end "[escape_path $line_file($lno)]\n" header_val
 710                 }
 711
 712                 $w_cmit insert end "\n$msg"
 713         }
 714         $w_cmit conf -state disabled
 715
 716         set highlight_line $lno
 717         set highlight_commit $cmit
 718
 719         if {$highlight_commit eq $tooltip_commit} {
 720                 _hide_tooltip $this
 721         }
 722 }
 723
 724 method _copycommit {} {
 725         set pos @$::cursorX,$::cursorY
 726         set lno [lindex [split [$::cursorW index $pos] .] 0]
 727         if {![catch {set commit $line_commit($lno)}]} {
 728                 clipboard clear
 729                 clipboard append \
 730                         -format STRING \
 731                         -type STRING \
 732                         -- $commit
 733         }
 734 }
 735
 736 method _show_tooltip {cur_w pos} {
 737         set lno [lindex [split [$cur_w index $pos] .] 0]
 738         if {[catch {set cmit $line_commit($lno)}]} {
 739                 _hide_tooltip $this
 740                 return
 741         }
 742
 743         if {$cmit eq $highlight_commit} {
 744                 _hide_tooltip $this
 745                 return
 746         }
 747
 748         if {$cmit eq $tooltip_commit} {
 749                 _position_tooltip $this
 750         } elseif {$tooltip_wm ne {}} {
 751                 _open_tooltip $this $cur_w
 752         } elseif {$tooltip_timer eq {}} {
 753                 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
 754         }
 755 }
 756
 757 method _open_tooltip {cur_w} {
 758         set tooltip_timer {}
 759         set pos_x [winfo pointerx $cur_w]
 760         set pos_y [winfo pointery $cur_w]
 761         if {[winfo containing $pos_x $pos_y] ne $cur_w} {
 762                 _hide_tooltip $this
 763                 return
 764         }
 765
 766         set pos @[join [list \
 767                 [expr {$pos_x - [winfo rootx $cur_w]}] \
 768                 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
 769         set lno [lindex [split [$cur_w index $pos] .] 0]
 770         set cmit $line_commit($lno)
 771
 772         set author_name {}
 773         set author_email {}
 774         set author_time {}
 775         catch {set author_name $header($cmit,author)}
 776         catch {set author_email $header($cmit,author-mail)}
 777         catch {set author_time [clock format \
 778                 $header($cmit,author-time) \
 779                 -format {%Y-%m-%d %H:%M:%S}
 780         ]}
 781
 782         set committer_name {}
 783         set committer_email {}
 784         set committer_time {}
 785         catch {set committer_name $header($cmit,committer)}
 786         catch {set committer_email $header($cmit,committer-mail)}
 787         catch {set committer_time [clock format \
 788                 $header($cmit,committer-time) \
 789                 -format {%Y-%m-%d %H:%M:%S}
 790         ]}
 791
 792         set summary {}
 793         catch {set summary $header($cmit,summary)}
 794
 795         set tooltip_commit $cmit
 796         set tooltip_text "commit $cmit
 797 $author_name $author_email  $author_time
 798 $summary"
 799
 800         set file $line_file($lno)
 801         if {$file ne $path} {
 802                 append tooltip_text "
 803
 804 Original File: $file"
 805         }
 806
 807         if {$tooltip_wm ne "$cur_w.tooltip"} {
 808                 _hide_tooltip $this
 809
 810                 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
 811                 wm overrideredirect $tooltip_wm 1
 812                 wm transient $tooltip_wm [winfo toplevel $cur_w]
 813                 pack [label $tooltip_wm.label \
 814                         -background lightyellow \
 815                         -foreground black \
 816                         -textvariable @tooltip_text \
 817                         -justify left]
 818         }
 819         _position_tooltip $this
 820 }
 821
 822 method _position_tooltip {} {
 823         set req_w [winfo reqwidth  $tooltip_wm.label]
 824         set req_h [winfo reqheight $tooltip_wm.label]
 825         set pos_x [expr {[winfo pointerx .] +  5}]
 826         set pos_y [expr {[winfo pointery .] + 10}]
 827
 828         set g "${req_w}x${req_h}"
 829         if {$pos_x >= 0} {append g +}
 830         append g $pos_x
 831         if {$pos_y >= 0} {append g +}
 832         append g $pos_y
 833
 834         wm geometry $tooltip_wm $g
 835         raise $tooltip_wm
 836 }
 837
 838 method _hide_tooltip {} {
 839         if {$tooltip_wm ne {}} {
 840                 destroy $tooltip_wm
 841                 set tooltip_wm {}
 842                 set tooltip_commit {}
 843         }
 844         if {$tooltip_timer ne {}} {
 845                 after cancel $tooltip_timer
 846                 set tooltip_timer {}
 847         }
 848 }
 849
 850 method _resize {new_height} {
 851         set diff [expr {$new_height - $old_height}]
 852         if {$diff == 0} return
 853
 854         set my [expr {[winfo height $w.file_pane] - 25}]
 855         set o [$w.file_pane sash coord 0]
 856         set ox [lindex $o 0]
 857         set oy [expr {[lindex $o 1] + $diff}]
 858         if {$oy < 0}   {set oy 0}
 859         if {$oy > $my} {set oy $my}
 860         $w.file_pane sash place 0 $ox $oy
 861
 862         set old_height $new_height
 863 }
 864
 865 }