?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-svn: use sys* IO functions for reading rev_db
[git/jnareb-git.git] / git-svn.perl
blob1e3a3c08f11372857c5152d7c20b50df8784a673
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 $ENV{GIT_DIR} ||= '.git';
13 $Git::SVN::default_repo_id = 'git-svn';
14 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
15
16 $Git::SVN::Log::TZ = $ENV{TZ};
17 $ENV{TZ} = 'UTC';
18 $| = 1; # unbuffer STDOUT
19
20 sub fatal (@) { print STDERR @_; exit 1 }
21 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
22 require SVN::Ra;
23 require SVN::Delta;
24 if ($SVN::Core::VERSION lt '1.1.0') {
25 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
26 }
27 push @Git::SVN::Ra::ISA, 'SVN::Ra';
28 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
29 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
30 use Carp qw/croak/;
31 use IO::File qw//;
32 use File::Basename qw/dirname basename/;
33 use File::Path qw/mkpath/;
34 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
35 use IPC::Open3;
36 use Git;
37
38 BEGIN {
39 my $s;
40 foreach (qw/command command_oneline command_noisy command_output_pipe
41 command_input_pipe command_close_pipe/) {
42 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
43 "*Git::SVN::Migration::$_ = ".
44 "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
45 }
46 eval $s;
47 }
48
49 my ($SVN);
50
51 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
52 $sha1 = qr/[a-f\d]{40}/;
53 $sha1_short = qr/[a-f\d]{4,40}/;
54 my ($_stdin, $_help, $_edit,
55 $_message, $_file,
56 $_template, $_shared,
57 $_version,
58 $_merge, $_strategy, $_dry_run,
59 $_prefix);
60
61 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
62 'config-dir=s' => \$Git::SVN::Ra::config_dir,
63 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
64 my %fc_opts = ( 'follow-parent|follow' => \$Git::SVN::_follow_parent,
65 'authors-file|A=s' => \$_authors,
66 'repack:i' => \$Git::SVN::_repack,
67 'no-metadata' => \$Git::SVN::_no_metadata,
68 'quiet|q' => \$_q,
69 'repack-flags|repack-args|repack-opts=s' =>
70 \$Git::SVN::_repack_flags,
71 %remote_opts );
72
73 my ($_trunk, $_tags, $_branches);
74 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
75 'tags|t=s' => \$_tags,
76 'branches|b=s' => \$_branches );
77 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
78 my %cmt_opts = ( 'edit|e' => \$_edit,
79 'rmdir' => \$SVN::Git::Editor::_rmdir,
80 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
81 'l=i' => \$SVN::Git::Editor::_rename_limit,
82 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
83 );
84
85 my %cmd = (
86 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
87 { 'revision|r=s' => \$_revision, %fc_opts } ],
88 init => [ \&cmd_init, "Initialize a repo for tracking" .
89 " (requires URL argument)",
90 \%init_opts ],
91 dcommit => [ \&cmd_dcommit,
92 'Commit several diffs to merge with upstream',
93 { 'merge|m|M' => \$_merge,
94 'strategy|s=s' => \$_strategy,
95 'dry-run|n' => \$_dry_run,
96 %cmt_opts, %fc_opts } ],
97 'set-tree' => [ \&cmd_set_tree,
98 "Set an SVN repository to a git tree-ish",
99 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
100 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
101 { 'revision|r=i' => \$_revision } ],
102 'multi-init' => [ \&cmd_multi_init,
103 'Initialize multiple trees (like git-svnimport)',
104 { %multi_opts, %init_opts, %remote_opts,
105 'revision|r=i' => \$_revision,
106 'prefix=s' => \$_prefix,
107 } ],
108 'multi-fetch' => [ \&cmd_multi_fetch,
109 'Fetch multiple trees (like git-svnimport)',
110 \%fc_opts ],
111 'migrate' => [ sub { },
112 # no-op, we automatically run this anyways,
113 'Migrate configuration/metadata/layout from
114 previous versions of git-svn',
115 \%remote_opts ],
116 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
117 { 'limit=i' => \$Git::SVN::Log::limit,
118 'revision|r=s' => \$_revision,
119 'verbose|v' => \$Git::SVN::Log::verbose,
120 'incremental' => \$Git::SVN::Log::incremental,
121 'oneline' => \$Git::SVN::Log::oneline,
122 'show-commit' => \$Git::SVN::Log::show_commit,
123 'non-recursive' => \$Git::SVN::Log::non_recursive,
124 'authors-file|A=s' => \$_authors,
125 'color' => \$Git::SVN::Log::color,
126 'pager=s' => \$Git::SVN::Log::pager,
127 } ],
128 'commit-diff' => [ \&cmd_commit_diff,
129 'Commit a diff between two trees',
130 { 'message|m=s' => \$_message,
131 'file|F=s' => \$_file,
132 'revision|r=s' => \$_revision,
133 %cmt_opts } ],
134 );
135
136 my $cmd;
137 for (my $i = 0; $i < @ARGV; $i++) {
138 if (defined $cmd{$ARGV[$i]}) {
139 $cmd = $ARGV[$i];
140 splice @ARGV, $i, 1;
141 last;
142 }
143 };
144
145 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
146
147 read_repo_config(\%opts);
148 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
149 'minimize-connections' => \$Git::SVN::Migration::_minimize,
150 'id|i=s' => \$Git::SVN::default_ref_id,
151 'svn-remote|remote|R=s' => \$Git::SVN::default_repo_id);
152 exit 1 if (!$rv && $cmd ne 'log');
153
154 usage(0) if $_help;
155 version() if $_version;
156 usage(1) unless defined $cmd;
157 load_authors() if $_authors;
158 unless ($cmd =~ /^(?:init|multi-init|commit-diff)$/) {
159 Git::SVN::Migration::migration_check();
160 }
161 Git::SVN::init_vars();
162 eval {
163 Git::SVN::verify_remotes_sanity();
164 $cmd{$cmd}->[0]->(@ARGV);
165 };
166 fatal $@ if $@;
167 exit 0;
168
169 ####################### primary functions ######################
170 sub usage {
171 my $exit = shift || 0;
172 my $fd = $exit ? \*STDERR : \*STDOUT;
173 print $fd <<"";
174 git-svn - bidirectional operations between a single Subversion tree and git
175 Usage: $0 <command> [options] [arguments]\n
176
177 print $fd "Available commands:\n" unless $cmd;
178
179 foreach (sort keys %cmd) {
180 next if $cmd && $cmd ne $_;
181 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
182 foreach (keys %{$cmd{$_}->[2]}) {
183 # prints out arguments as they should be passed:
184 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
185 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
186 "--$_" : "-$_" }
187 split /\|/,$_)," $x\n";
188 }
189 }
190 print $fd <<"";
191 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
192 arbitrary identifier if you're tracking multiple SVN branches/repositories in
193 one git repository and want to keep them separate. See git-svn(1) for more
194 information.
195
196 exit $exit;
197 }
198
199 sub version {
200 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
201 exit 0;
202 }
203
204 sub do_git_init_db {
205 unless (-d $ENV{GIT_DIR}) {
206 my @init_db = ('init');
207 push @init_db, "--template=$_template" if defined $_template;
208 push @init_db, "--shared" if defined $_shared;
209 command_noisy(@init_db);
210 }
211 }
212
213 sub cmd_init {
214 my $url = shift or die "SVN repository location required " .
215 "as a command-line argument\n";
216 if (my $repo_path = shift) {
217 unless (-d $repo_path) {
218 mkpath([$repo_path]);
219 }
220 chdir $repo_path or croak $!;
221 $ENV{GIT_DIR} = $repo_path . "/.git";
222 }
223 do_git_init_db();
224
225 Git::SVN->init($url);
226 }
227
228 sub cmd_fetch {
229 if (@_) {
230 die "Additional fetch arguments are no longer supported.\n",
231 "Use --follow-parent if you have moved/copied directories
232 instead.\n";
233 }
234 my $gs = Git::SVN->new;
235 $gs->fetch(parse_revision_argument());
236 if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
237 command_noisy(qw(update-ref refs/heads/master),
238 $gs->{last_commit});
239 }
240 }
241
242 sub cmd_set_tree {
243 my (@commits) = @_;
244 if ($_stdin || !@commits) {
245 print "Reading from stdin...\n";
246 @commits = ();
247 while (<STDIN>) {
248 if (/\b($sha1_short)\b/o) {
249 unshift @commits, $1;
250 }
251 }
252 }
253 my @revs;
254 foreach my $c (@commits) {
255 my @tmp = command('rev-parse',$c);
256 if (scalar @tmp == 1) {
257 push @revs, $tmp[0];
258 } elsif (scalar @tmp > 1) {
259 push @revs, reverse(command('rev-list',@tmp));
260 } else {
261 fatal "Failed to rev-parse $c\n";
262 }
263 }
264 my $gs = Git::SVN->new;
265 my ($r_last, $cmt_last) = $gs->last_rev_commit;
266 $gs->fetch;
267 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
268 fatal "There are new revisions that were fetched ",
269 "and need to be merged (or acknowledged) ",
270 "before committing.\nlast rev: $r_last\n",
271 " current: $gs->{last_rev}\n";
272 }
273 $gs->set_tree($_) foreach @revs;
274 print "Done committing ",scalar @revs," revisions to SVN\n";
275 }
276
277 sub cmd_dcommit {
278 my $head = shift;
279 my $gs = Git::SVN->new;
280 $head ||= 'HEAD';
281 my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
282 my $last_rev;
283 foreach my $d (reverse @refs) {
284 if (!verify_ref("$d~1")) {
285 fatal "Commit $d\n",
286 "has no parent commit, and therefore ",
287 "nothing to diff against.\n",
288 "You should be working from a repository ",
289 "originally created by git-svn\n";
290 }
291 unless (defined $last_rev) {
292 (undef, $last_rev, undef) = cmt_metadata("$d~1");
293 unless (defined $last_rev) {
294 fatal "Unable to extract revision information ",
295 "from commit $d~1\n";
296 }
297 }
298 if ($_dry_run) {
299 print "diff-tree $d~1 $d\n";
300 } else {
301 my %ed_opts = ( r => $last_rev,
302 log => get_commit_entry($d)->{log},
303 ra => $gs->ra,
304 tree_a => "$d~1",
305 tree_b => $d,
306 editor_cb => sub {
307 print "Committed r$_[0]\n";
308 $last_rev = $_[0]; },
309 svn_path => $gs->{path} );
310 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
311 print "No changes\n$d~1 == $d\n";
312 }
313 }
314 }
315 return if $_dry_run;
316 $gs->fetch;
317 # we always want to rebase against the current HEAD, not any
318 # head that was passed to us
319 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
320 my @finish;
321 if (@diff) {
322 @finish = qw/rebase/;
323 push @finish, qw/--merge/ if $_merge;
324 push @finish, "--strategy=$_strategy" if $_strategy;
325 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
326 "using @finish:\n", "@diff";
327 } else {
328 print "No changes between current HEAD and ",
329 $gs->refname, "\nResetting to the latest ",
330 $gs->refname, "\n";
331 @finish = qw/reset --mixed/;
332 }
333 command_noisy(@finish, $gs->refname);
334 }
335
336 sub cmd_show_ignore {
337 my $gs = Git::SVN->new;
338 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
339 $gs->traverse_ignore(\*STDOUT, '', $r);
340 }
341
342 sub cmd_multi_init {
343 my $url = shift;
344 unless (defined $_trunk || defined $_branches || defined $_tags) {
345 usage(1);
346 }
347 do_git_init_db();
348 $_prefix = '' unless defined $_prefix;
349 $url =~ s#/+$## if defined $url;
350 if (defined $_trunk) {
351 my $trunk_ref = $_prefix . 'trunk';
352 # try both old-style and new-style lookups:
353 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
354 unless ($gs_trunk) {
355 my ($trunk_url, $trunk_path) =
356 complete_svn_url($url, $_trunk);
357 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
358 undef, $trunk_ref);
359 }
360 }
361 return unless defined $_branches || defined $_tags;
362 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
363 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
364 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
365 }
366
367 sub cmd_multi_fetch {
368 my $remotes = Git::SVN::read_all_remotes();
369 foreach my $repo_id (sort keys %$remotes) {
370 my $url = $remotes->{$repo_id}->{url} or next;
371 my $fetch = $remotes->{$repo_id}->{fetch} or next;
372 Git::SVN::fetch_all($repo_id, $url, $fetch);
373 }
374 }
375
376 # this command is special because it requires no metadata
377 sub cmd_commit_diff {
378 my ($ta, $tb, $url) = @_;
379 my $usage = "Usage: $0 commit-diff -r<revision> ".
380 "<tree-ish> <tree-ish> [<URL>]\n";
381 fatal($usage) if (!defined $ta || !defined $tb);
382 my $svn_path;
383 if (!defined $url) {
384 my $gs = eval { Git::SVN->new };
385 if (!$gs) {
386 fatal("Needed URL or usable git-svn --id in ",
387 "the command-line\n", $usage);
388 }
389 $url = $gs->{url};
390 $svn_path = $gs->{path};
391 }
392 unless (defined $_revision) {
393 fatal("-r|--revision is a required argument\n", $usage);
394 }
395 if (defined $_message && defined $_file) {
396 fatal("Both --message/-m and --file/-F specified ",
397 "for the commit message.\n",
398 "I have no idea what you mean\n");
399 }
400 if (defined $_file) {
401 $_message = file_to_s($_file);
402 } else {
403 $_message ||= get_commit_entry($tb)->{log};
404 }
405 my $ra ||= Git::SVN::Ra->new($url);
406 $svn_path ||= $ra->{svn_path};
407 my $r = $_revision;
408 if ($r eq 'HEAD') {
409 $r = $ra->get_latest_revnum;
410 } elsif ($r !~ /^\d+$/) {
411 die "revision argument: $r not understood by git-svn\n";
412 }
413 my %ed_opts = ( r => $r,
414 log => $_message,
415 ra => $ra,
416 tree_a => $ta,
417 tree_b => $tb,
418 editor_cb => sub { print "Committed r$_[0]\n" },
419 svn_path => $svn_path );
420 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
421 print "No changes\n$ta == $tb\n";
422 }
423 }
424
425 ########################### utility functions #########################
426
427 sub parse_revision_argument {
428 if (!defined $_revision || $_revision eq 'BASE:HEAD') {
429 return (undef, undef);
430 }
431 return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
432 return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
433 return (undef, $1) if ($_revision =~ /^BASE:(\d+)$/);
434 return ($1, undef) if ($_revision =~ /^(\d+):HEAD$/);
435 die "revision argument: $_revision not understood by git-svn\n",
436 "Try using the command-line svn client instead\n";
437 }
438
439 sub complete_svn_url {
440 my ($url, $path) = @_;
441 $path =~ s#/+$##;
442 if ($path !~ m#^[a-z\+]+://#) {
443 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
444 fatal("E: '$path' is not a complete URL ",
445 "and a separate URL is not specified\n");
446 }
447 return ($url, $path);
448 }
449 return ($path, '');
450 }
451
452 sub complete_url_ls_init {
453 my ($ra, $repo_path, $switch, $pfx) = @_;
454 unless ($repo_path) {
455 print STDERR "W: $switch not specified\n";
456 return;
457 }
458 $repo_path =~ s#/+$##;
459 if ($repo_path =~ m#^[a-z\+]+://#) {
460 $ra = Git::SVN::Ra->new($repo_path);
461 $repo_path = '';
462 } else {
463 $repo_path =~ s#^/+##;
464 unless ($ra) {
465 fatal("E: '$repo_path' is not a complete URL ",
466 "and a separate URL is not specified\n");
467 }
468 }
469 my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
470 my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
471 my $url = $ra->{url};
472 foreach my $d (sort keys %$dirent) {
473 next if ($dirent->{$d}->kind != $SVN::Node::dir);
474 my $path = "$repo_path/$d";
475 my $ref = "$pfx$d";
476 my $gs = eval { Git::SVN->new($ref) };
477 # don't try to init already existing refs
478 unless ($gs) {
479 print "init $url/$path => $ref\n";
480 Git::SVN->init($url, $path, undef, $ref);
481 }
482 }
483 }
484
485 sub verify_ref {
486 my ($ref) = @_;
487 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
488 { STDERR => 0 }); };
489 }
490
491 sub get_tree_from_treeish {
492 my ($treeish) = @_;
493 # $treeish can be a symbolic ref, too:
494 my $type = command_oneline(qw/cat-file -t/, $treeish);
495 my $expected;
496 while ($type eq 'tag') {
497 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
498 }
499 if ($type eq 'commit') {
500 $expected = (grep /^tree /, command(qw/cat-file commit/,
501 $treeish))[0];
502 ($expected) = ($expected =~ /^tree ($sha1)$/o);
503 die "Unable to get tree from $treeish\n" unless $expected;
504 } elsif ($type eq 'tree') {
505 $expected = $treeish;
506 } else {
507 die "$treeish is a $type, expected tree, tag or commit\n";
508 }
509 return $expected;
510 }
511
512 sub get_commit_entry {
513 my ($treeish) = shift;
514 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
515 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
516 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
517 open my $log_fh, '>', $commit_editmsg or croak $!;
518
519 my $type = command_oneline(qw/cat-file -t/, $treeish);
520 if ($type eq 'commit' || $type eq 'tag') {
521 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
522 $type, $treeish);
523 my $in_msg = 0;
524 while (<$msg_fh>) {
525 if (!$in_msg) {
526 $in_msg = 1 if (/^\s*$/);
527 } elsif (/^git-svn-id: /) {
528 # skip this for now, we regenerate the
529 # correct one on re-fetch anyways
530 # TODO: set *:merge properties or like...
531 } else {
532 print $log_fh $_ or croak $!;
533 }
534 }
535 command_close_pipe($msg_fh, $ctx);
536 }
537 close $log_fh or croak $!;
538
539 if ($_edit || ($type eq 'tree')) {
540 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
541 # TODO: strip out spaces, comments, like git-commit.sh
542 system($editor, $commit_editmsg);
543 }
544 rename $commit_editmsg, $commit_msg or croak $!;
545 open $log_fh, '<', $commit_msg or croak $!;
546 { local $/; chomp($log_entry{log} = <$log_fh>); }
547 close $log_fh or croak $!;
548 unlink $commit_msg;
549 \%log_entry;
550 }
551
552 sub s_to_file {
553 my ($str, $file, $mode) = @_;
554 open my $fd,'>',$file or croak $!;
555 print $fd $str,"\n" or croak $!;
556 close $fd or croak $!;
557 chmod ($mode &~ umask, $file) if (defined $mode);
558 }
559
560 sub file_to_s {
561 my $file = shift;
562 open my $fd,'<',$file or croak "$!: file: $file\n";
563 local $/;
564 my $ret = <$fd>;
565 close $fd or croak $!;
566 $ret =~ s/\s*$//s;
567 return $ret;
568 }
569
570 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
571 sub load_authors {
572 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
573 my $log = $cmd eq 'log';
574 while (<$authors>) {
575 chomp;
576 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
577 my ($user, $name, $email) = ($1, $2, $3);
578 if ($log) {
579 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
580 } else {
581 $users{$user} = [$name, $email];
582 }
583 }
584 close $authors or croak $!;
585 }
586
587 # convert GetOpt::Long specs for use by git-config
588 sub read_repo_config {
589 return unless -d $ENV{GIT_DIR};
590 my $opts = shift;
591 foreach my $o (keys %$opts) {
592 my $v = $opts->{$o};
593 my ($key) = ($o =~ /^([a-z\-]+)/);
594 $key =~ s/-//g;
595 my $arg = 'git-config';
596 $arg .= ' --int' if ($o =~ /[:=]i$/);
597 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
598 if (ref $v eq 'ARRAY') {
599 chomp(my @tmp = `$arg --get-all svn.$key`);
600 @$v = @tmp if @tmp;
601 } else {
602 chomp(my $tmp = `$arg --get svn.$key`);
603 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
604 $$v = $tmp;
605 }
606 }
607 }
608 }
609
610 sub extract_metadata {
611 my $id = shift or return (undef, undef, undef);
612 my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
613 \s([a-f\d\-]+)$/x);
614 if (!defined $rev || !$uuid || !$url) {
615 # some of the original repositories I made had
616 # identifiers like this:
617 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
618 }
619 return ($url, $rev, $uuid);
620 }
621
622 sub cmt_metadata {
623 return extract_metadata((grep(/^git-svn-id: /,
624 command(qw/cat-file commit/, shift)))[-1]);
625 }
626
627 package Git::SVN;
628 use strict;
629 use warnings;
630 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
631 $_repack $_repack_flags/;
632 use Carp qw/croak/;
633 use File::Path qw/mkpath/;
634 use File::Copy qw/copy/;
635 use IPC::Open3;
636
637 my $_repack_nr;
638 # properties that we do not log:
639 my %SKIP_PROP;
640 BEGIN {
641 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
642 svn:special svn:executable
643 svn:entry:committed-rev
644 svn:entry:last-author
645 svn:entry:uuid
646 svn:entry:committed-date/;
647 }
648
649 my %LOCKFILES;
650 END { unlink keys %LOCKFILES if %LOCKFILES }
651
652 sub fetch_all {
653 my ($repo_id, $url, $fetch) = @_;
654 my @gs;
655 my $ra = Git::SVN::Ra->new($url);
656 my $head = $ra->get_latest_revnum;
657 my $base = $head;
658 foreach my $p (sort keys %$fetch) {
659 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
660 my $lr = $gs->rev_db_max;
661 if (defined $lr) {
662 $base = $lr if ($lr < $base);
663 }
664 push @gs, $gs;
665 }
666 return if (++$base > $head);
667 $ra->gs_fetch_loop_common($base, $head, @gs);
668 }
669
670 sub read_all_remotes {
671 my $r = {};
672 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
673 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
674 $r->{$1}->{fetch}->{$2} = $3;
675 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
676 $r->{$1}->{url} = $2;
677 }
678 }
679 $r;
680 }
681
682 sub init_vars {
683 if (defined $_repack) {
684 $_repack = 1000 if ($_repack <= 0);
685 $_repack_nr = $_repack;
686 $_repack_flags ||= '-d';
687 }
688 }
689
690 sub verify_remotes_sanity {
691 return unless -d $ENV{GIT_DIR};
692 my %seen;
693 foreach (command(qw/config -l/)) {
694 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
695 if ($seen{$1}) {
696 die "Remote ref refs/remote/$1 is tracked by",
697 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
698 "Please resolve this ambiguity in ",
699 "your git configuration file before ",
700 "continuing\n";
701 }
702 $seen{$1} = $_;
703 }
704 }
705 }
706
707 # we allow more chars than remotes2config.sh...
708 sub sanitize_remote_name {
709 my ($name) = @_;
710 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
711 $name;
712 }
713
714 sub find_existing_remote {
715 my ($url, $remotes) = @_;
716 my $existing;
717 foreach my $repo_id (keys %$remotes) {
718 my $u = $remotes->{$repo_id}->{url} or next;
719 next if $u ne $url;
720 $existing = $repo_id;
721 last;
722 }
723 $existing;
724 }
725
726 sub init_remote_config {
727 my ($self, $url) = @_;
728 $url =~ s!/+$!!; # strip trailing slash
729 my $r = read_all_remotes();
730 my $existing = find_existing_remote($url, $r);
731 if ($existing) {
732 print STDERR "Using existing ",
733 "[svn-remote \"$existing\"]\n";
734 $self->{repo_id} = $existing;
735 } else {
736 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
737 $existing = find_existing_remote($min_url, $r);
738 if ($existing) {
739 print STDERR "Using existing ",
740 "[svn-remote \"$existing\"]\n";
741 $self->{repo_id} = $existing;
742 }
743 if ($min_url ne $url) {
744 print STDERR "Using higher level of URL: ",
745 "$url => $min_url\n";
746 my $old_path = $self->{path};
747 $self->{path} = $url;
748 $self->{path} =~ s!^\Q$min_url\E/*!!;
749 if (length $old_path) {
750 $self->{path} .= "/$old_path";
751 }
752 $url = $min_url;
753 }
754 }
755 my $orig_url;
756 if (!$existing) {
757 # verify that we aren't overwriting anything:
758 $orig_url = eval {
759 command_oneline('config', '--get',
760 "svn-remote.$self->{repo_id}.url")
761 };
762 if ($orig_url && ($orig_url ne $url)) {
763 die "svn-remote.$self->{repo_id}.url already set: ",
764 "$orig_url\nwanted to set to: $url\n";
765 }
766 }
767 my ($xrepo_id, $xpath) = find_ref($self->refname);
768 if (defined $xpath) {
769 die "svn-remote.$xrepo_id.fetch already set to track ",
770 "$xpath:refs/remotes/", $self->refname, "\n";
771 }
772 command_noisy('config',
773 "svn-remote.$self->{repo_id}.url", $url);
774 command_noisy('config', '--add',
775 "svn-remote.$self->{repo_id}.fetch",
776 "$self->{path}:".$self->refname);
777 $self->{url} = $url;
778 }
779
780 sub init {
781 my ($class, $url, $path, $repo_id, $ref_id) = @_;
782 my $self = _new($class, $repo_id, $ref_id, $path);
783 if (defined $url) {
784 $self->init_remote_config($url);
785 }
786 $self;
787 }
788
789 sub find_ref {
790 my ($ref_id) = @_;
791 foreach (command(qw/config -l/)) {
792 next unless m!^svn-remote\.(.+)\.fetch=
793 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
794 my ($repo_id, $path, $ref) = ($1, $2, $3);
795 if ($ref eq $ref_id) {
796 $path = '' if ($path =~ m#^\./?#);
797 return ($repo_id, $path);
798 }
799 }
800 (undef, undef, undef);
801 }
802
803 sub new {
804 my ($class, $ref_id, $repo_id, $path) = @_;
805 if (defined $ref_id && !defined $repo_id && !defined $path) {
806 ($repo_id, $path) = find_ref($ref_id);
807 if (!defined $repo_id) {
808 die "Could not find a \"svn-remote.*.fetch\" key ",
809 "in the repository configuration matching: ",
810 "refs/remotes/$ref_id\n";
811 }
812 }
813 my $self = _new($class, $repo_id, $ref_id, $path);
814 if (!defined $self->{path} || !length $self->{path}) {
815 my $fetch = command_oneline('config', '--get',
816 "svn-remote.$repo_id.fetch",
817 ":refs/remotes/$ref_id\$") or
818 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
819 "\":refs/remotes/$ref_id\$\" in config\n";
820 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
821 }
822 $self->{url} = command_oneline('config', '--get',
823 "svn-remote.$repo_id.url") or
824 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
825 if (-z $self->{db_path} && ::verify_ref($self->refname.'^0')) {
826 $self->rebuild;
827 }
828 $self;
829 }
830
831 sub refname { "refs/remotes/$_[0]->{ref_id}" }
832
833 sub ra {
834 my ($self) = shift;
835 Git::SVN::Ra->new($self->{url});
836 }
837
838 sub rel_path {
839 my ($self) = @_;
840 my $repos_root = $self->ra->{repos_root};
841 return $self->{path} if ($self->{url} eq $repos_root);
842 my $url = $self->{url} .
843 (length $self->{path} ? "/$self->{path}" : $self->{path});
844 $url =~ s!^\Q$repos_root\E/*!!g;
845 $url;
846 }
847
848 sub traverse_ignore {
849 my ($self, $fh, $path, $r) = @_;
850 $path =~ s#^/+##g;
851 my $ra = $self->ra;
852 my ($dirent, undef, $props) = $ra->get_dir($path, $r);
853 my $p = $path;
854 $p =~ s#^\Q$ra->{svn_path}\E/##;
855 print $fh length $p ? "\n# $p\n" : "\n# /\n";
856 if (my $s = $props->{'svn:ignore'}) {
857 $s =~ s/[\r\n]+/\n/g;
858 chomp $s;
859 if (length $p == 0) {
860 $s =~ s#\n#\n/$p#g;
861 print $fh "/$s\n";
862 } else {
863 $s =~ s#\n#\n/$p/#g;
864 print $fh "/$p/$s\n";
865 }
866 }
867 foreach (sort keys %$dirent) {
868 next if $dirent->{$_}->kind != $SVN::Node::dir;
869 $self->traverse_ignore($fh, "$path/$_", $r);
870 }
871 }
872
873 sub last_rev { ($_[0]->last_rev_commit)[0] }
874 sub last_commit { ($_[0]->last_rev_commit)[1] }
875
876 # returns the newest SVN revision number and newest commit SHA1
877 sub last_rev_commit {
878 my ($self) = @_;
879 if (defined $self->{last_rev} && defined $self->{last_commit}) {
880 return ($self->{last_rev}, $self->{last_commit});
881 }
882 my $c = ::verify_ref($self->refname.'^0');
883 if ($c) {
884 my $rev = (::cmt_metadata($c))[1];
885 if (defined $rev) {
886 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
887 return ($rev, $c);
888 }
889 }
890 my $offset = -41; # from tail
891 my $rl;
892 open my $fh, '<', $self->{db_path} or
893 croak "$self->{db_path} not readable: $!\n";
894 sysseek($fh, $offset, 2); # don't care for errors
895 sysread($fh, $rl, 41) == 41 or return (undef, undef);
896 chomp $rl;
897 while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
898 $offset -= 41;
899 sysseek($fh, $offset, 2); # don't care for errors
900 sysread($fh, $rl, 41) == 41 or return (undef, undef);
901 chomp $rl;
902 }
903 if ($c) {
904 die "$self->{db_path} and ", $self->refname,
905 " inconsistent!:\n$c != $rl\n";
906 }
907 my $rev = sysseek($fh, 0, 1) or croak $!;
908 $rev = ($rev - 41) / 41;
909 close $fh or croak $!;
910 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
911 return ($rev, $c);
912 }
913
914 sub get_fetch_range {
915 my ($self, $min, $max) = @_;
916 $max ||= $self->ra->get_latest_revnum;
917 $min ||= $self->rev_db_max;
918 (++$min, $max);
919 }
920
921 sub tmp_index_do {
922 my ($self, $sub) = @_;
923 my $old_index = $ENV{GIT_INDEX_FILE};
924 $ENV{GIT_INDEX_FILE} = $self->{index};
925 my @ret = &$sub;
926 if ($old_index) {
927 $ENV{GIT_INDEX_FILE} = $old_index;
928 } else {
929 delete $ENV{GIT_INDEX_FILE};
930 }
931 wantarray ? @ret : $ret[0];
932 }
933
934 sub assert_index_clean {
935 my ($self, $treeish) = @_;
936
937 $self->tmp_index_do(sub {
938 command_noisy('read-tree', $treeish) unless -e $self->{index};
939 my $x = command_oneline('write-tree');
940 my ($y) = (command(qw/cat-file commit/, $treeish) =~
941 /^tree ($::sha1)/mo);
942 if ($y ne $x) {
943 unlink $self->{index} or croak $!;
944 command_noisy('read-tree', $treeish);
945 }
946 $x = command_oneline('write-tree');
947 if ($y ne $x) {
948 ::fatal "trees ($treeish) $y != $x\n",
949 "Something is seriously wrong...\n";
950 }
951 });
952 }
953
954 sub get_commit_parents {
955 my ($self, $log_entry) = @_;
956 my (%seen, @ret, @tmp);
957 # legacy support for 'set-tree'; this is only used by set_tree_cb:
958 if (my $ip = $self->{inject_parents}) {
959 if (my $commit = delete $ip->{$log_entry->{revision}}) {
960 push @tmp, $commit;
961 }
962 }
963 if (my $cur = ::verify_ref($self->refname.'^0')) {
964 push @tmp, $cur;
965 }
966 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
967 while (my $p = shift @tmp) {
968 next if $seen{$p};
969 $seen{$p} = 1;
970 push @ret, $p;
971 # MAXPARENT is defined to 16 in commit-tree.c:
972 last if @ret >= 16;
973 }
974 if (@tmp) {
975 die "r$log_entry->{revision}: No room for parents:\n\t",
976 join("\n\t", @tmp), "\n";
977 }
978 @ret;
979 }
980
981 sub full_url {
982 my ($self) = @_;
983 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
984 }
985
986 sub do_git_commit {
987 my ($self, $log_entry) = @_;
988 my $lr = $self->last_rev;
989 if (defined $lr && $lr >= $log_entry->{revision}) {
990 die "Last fetched revision of ", $self->refname,
991 " was r$lr, but we are about to fetch: ",
992 "r$log_entry->{revision}!\n";
993 }
994 if (my $c = $self->rev_db_get($log_entry->{revision})) {
995 croak "$log_entry->{revision} = $c already exists! ",
996 "Why are we refetching it?\n";
997 }
998 my $author = $log_entry->{author};
999 my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1000 : ($author, "$author\@".$self->ra->uuid));
1001 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1002 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1003 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1004
1005 my $tree = $log_entry->{tree};
1006 if (!defined $tree) {
1007 $tree = $self->tmp_index_do(sub {
1008 command_oneline('write-tree') });
1009 }
1010 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1011
1012 my @exec = ('git-commit-tree', $tree);
1013 foreach ($self->get_commit_parents($log_entry)) {
1014 push @exec, '-p', $_;
1015 }
1016 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1017 or croak $!;
1018 print $msg_fh $log_entry->{log} or croak $!;
1019 unless ($_no_metadata) {
1020 print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1021 $log_entry->{revision}, ' ',
1022 $self->ra->uuid, "\n" or croak $!;
1023 }
1024 $msg_fh->flush == 0 or croak $!;
1025 close $msg_fh or croak $!;
1026 chomp(my $commit = do { local $/; <$out_fh> });
1027 close $out_fh or croak $!;
1028 waitpid $pid, 0;
1029 croak $? if $?;
1030 if ($commit !~ /^$::sha1$/o) {
1031 die "Failed to commit, invalid sha1: $commit\n";
1032 }
1033
1034 $self->rev_db_set($log_entry->{revision}, $commit, 1);
1035
1036 $self->{last_rev} = $log_entry->{revision};
1037 $self->{last_commit} = $commit;
1038 print "r$log_entry->{revision} = $commit ($self->{ref_id})\n";
1039 if (defined $_repack && (--$_repack_nr == 0)) {
1040 $_repack_nr = $_repack;
1041 # repack doesn't use any arguments with spaces in them, does it?
1042 print "Running git repack $_repack_flags ...\n";
1043 command_noisy('repack', split(/\s+/, $_repack_flags));
1044 print "Done repacking\n";
1045 }
1046 return $commit;
1047 }
1048
1049 sub revisions_eq {
1050 my ($self, $r0, $r1) = @_;
1051 return 1 if $r0 == $r1;
1052 my $nr = 0;
1053 $self->ra->get_log([$self->{path}], $r0, $r1,
1054 0, 0, 1, sub { $nr++ });
1055 return 0 if ($nr > 1);
1056 return 1;
1057 }
1058
1059 sub find_parent_branch {
1060 my ($self, $paths, $rev) = @_;
1061 return undef unless $_follow_parent;
1062 unless (defined $paths) {
1063 my $err_handler = $SVN::Error::handler;
1064 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1065 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1066 $paths =
1067 Git::SVN::Ra::dup_changed_paths($_[0]) });
1068 $SVN::Error::handler = $err_handler;
1069 }
1070 return undef unless defined $paths;
1071
1072 # look for a parent from another branch:
1073 my @b_path_components = split m#/#, $self->rel_path;
1074 my @a_path_components;
1075 my $i;
1076 while (@b_path_components) {
1077 $i = $paths->{'/'.join('/', @b_path_components)};
1078 last if $i;
1079 unshift(@a_path_components, pop(@b_path_components));
1080 }
1081 goto not_found unless defined $i;
1082 my $branch_from = $i->{copyfrom_path} or goto not_found;
1083 if (@a_path_components) {
1084 print STDERR "branch_from: $branch_from => ";
1085 $branch_from .= '/'.join('/', @a_path_components);
1086 print STDERR $branch_from, "\n";
1087 }
1088 my $r = $i->{copyfrom_rev};
1089 my $repos_root = $self->ra->{repos_root};
1090 my $url = $self->ra->{url};
1091 my $new_url = $repos_root . $branch_from;
1092 print STDERR "Found possible branch point: ",
1093 "$new_url => ", $self->full_url, ", $r\n";
1094 $branch_from =~ s#^/##;
1095 my $remotes = read_all_remotes();
1096 my $gs;
1097 foreach my $repo_id (keys %$remotes) {
1098 my $u = $remotes->{$repo_id}->{url} or next;
1099 next if $url ne $u;
1100 my $fetch = $remotes->{$repo_id}->{fetch};
1101 foreach my $f (keys %$fetch) {
1102 next if $f ne $branch_from;
1103 $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1104 last;
1105 }
1106 last if $gs;
1107 }
1108 unless ($gs) {
1109 my $ref_id = $self->{ref_id};
1110 $ref_id =~ s/\@\d+$//;
1111 $ref_id .= "\@$r";
1112 # just grow a tail if we're not unique enough :x
1113 $ref_id .= '-' while find_ref($ref_id);
1114 print STDERR "Initializing parent: $ref_id\n";
1115 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1116 }
1117 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1118 if ($_follow_parent && (!defined $r0 || !defined $parent)) {
1119 $gs->fetch(0, $r);
1120 ($r0, $parent) = $gs->last_rev_commit;
1121 }
1122 if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1123 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1124 $self->assert_index_clean($parent);
1125 my $ed;
1126 if ($self->ra->can_do_switch) {
1127 print STDERR "Following parent with do_switch\n";
1128 # do_switch works with svn/trunk >= r22312, but that
1129 # is not included with SVN 1.4.3 (the latest version
1130 # at the moment), so we can't rely on it
1131 $self->{last_commit} = $parent;
1132 $ed = SVN::Git::Fetcher->new($self);
1133 $gs->ra->gs_do_switch($r0, $rev, $gs,
1134 $self->full_url, $ed)
1135 or die "SVN connection failed somewhere...\n";
1136 } else {
1137 print STDERR "Following parent with do_update\n";
1138 $ed = SVN::Git::Fetcher->new($self);
1139 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1140 or die "SVN connection failed somewhere...\n";
1141 }
1142 print STDERR "Successfully followed parent\n";
1143 return $self->make_log_entry($rev, [$parent], $ed);
1144 }
1145 not_found:
1146 print STDERR "Branch parent for path: '/",
1147 $self->rel_path, "' @ r$rev not found:\n";
1148 return undef unless $paths;
1149 print STDERR "Changed paths:\n";
1150 foreach my $x (sort keys %$paths) {
1151 my $p = $paths->{$x};
1152 print STDERR "\t$p->{action}\t$x";
1153 if ($p->{copyfrom_path}) {
1154 print STDERR "(from $p->{copyfrom_path}: ",
1155 "$p->{copyfrom_rev})";
1156 }
1157 print STDERR "\n";
1158 }
1159 print STDERR '-'x72, "\n";
1160 return undef;
1161 }
1162
1163 sub do_fetch {
1164 my ($self, $paths, $rev) = @_;
1165 my $ed;
1166 my ($last_rev, @parents);
1167 if ($self->{last_commit}) {
1168 $ed = SVN::Git::Fetcher->new($self);
1169 $last_rev = $self->{last_rev};
1170 $ed->{c} = $self->{last_commit};
1171 @parents = ($self->{last_commit});
1172 } else {
1173 $last_rev = $rev;
1174 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1175 return $log_entry;
1176 }
1177 $ed = SVN::Git::Fetcher->new($self);
1178 }
1179 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1180 die "SVN connection failed somewhere...\n";
1181 }
1182 $self->make_log_entry($rev, \@parents, $ed);
1183 }
1184
1185 sub get_untracked {
1186 my ($self, $ed) = @_;
1187 my @out;
1188 my $h = $ed->{empty};
1189 foreach (sort keys %$h) {
1190 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1191 push @out, " $act: " . uri_encode($_);
1192 warn "W: $act: $_\n";
1193 }
1194 foreach my $t (qw/dir_prop file_prop/) {
1195 $h = $ed->{$t} or next;
1196 foreach my $path (sort keys %$h) {
1197 my $ppath = $path eq '' ? '.' : $path;
1198 foreach my $prop (sort keys %{$h->{$path}}) {
1199 next if $SKIP_PROP{$prop};
1200 my $v = $h->{$path}->{$prop};
1201 my $t_ppath_prop = "$t: " .
1202 uri_encode($ppath) . ' ' .
1203 uri_encode($prop);
1204 if (defined $v) {
1205 push @out, " +$t_ppath_prop " .
1206 uri_encode($v);
1207 } else {
1208 push @out, " -$t_ppath_prop";
1209 }
1210 }
1211 }
1212 }
1213 foreach my $t (qw/absent_file absent_directory/) {
1214 $h = $ed->{$t} or next;
1215 foreach my $parent (sort keys %$h) {
1216 foreach my $path (sort @{$h->{$parent}}) {
1217 push @out, " $t: " .
1218 uri_encode("$parent/$path");
1219 warn "W: $t: $parent/$path ",
1220 "Insufficient permissions?\n";
1221 }
1222 }
1223 }
1224 \@out;
1225 }
1226
1227 sub parse_svn_date {
1228 my $date = shift || return '+0000 1970-01-01 00:00:00';
1229 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1230 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1231 croak "Unable to parse date: $date\n";
1232 "+0000 $Y-$m-$d $H:$M:$S";
1233 }
1234
1235 sub check_author {
1236 my ($author) = @_;
1237 if (!defined $author || length $author == 0) {
1238 $author = '(no author)';
1239 }
1240 if (defined $::_authors && ! defined $::users{$author}) {
1241 die "Author: $author not defined in $::_authors file\n";
1242 }
1243 $author;
1244 }
1245
1246 sub make_log_entry {
1247 my ($self, $rev, $parents, $ed) = @_;
1248 my $untracked = $self->get_untracked($ed);
1249
1250 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1251 print $un "r$rev\n" or croak $!;
1252 print $un $_, "\n" foreach @$untracked;
1253 my %log_entry = ( parents => $parents || [], revision => $rev,
1254 log => '');
1255 my $rp = $self->ra->rev_proplist($rev);
1256 foreach (sort keys %$rp) {
1257 my $v = $rp->{$_};
1258 if (/^svn:(author|date|log)$/) {
1259 $log_entry{$1} = $v;
1260 } else {
1261 print $un " rev_prop: ", uri_encode($_), ' ',
1262 uri_encode($v), "\n";
1263 }
1264 }
1265 close $un or croak $!;
1266
1267 $log_entry{date} = parse_svn_date($log_entry{date});
1268 $log_entry{author} = check_author($log_entry{author});
1269 $log_entry{log} .= "\n";
1270 \%log_entry;
1271 }
1272
1273 sub fetch {
1274 my ($self, $min_rev, $max_rev, @parents) = @_;
1275 my ($last_rev, $last_commit) = $self->last_rev_commit;
1276 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1277 return if ($base > $head);
1278 $self->ra->gs_fetch_loop_common($base, $head, $self);
1279 }
1280
1281 sub set_tree_cb {
1282 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1283 # TODO: enable and test optimized commits:
1284 if (0 && $rev == ($self->{last_rev} + 1)) {
1285 $log_entry->{revision} = $rev;
1286 $log_entry->{author} = $author;
1287 $self->do_git_commit($log_entry, "$rev=$tree");
1288 } else {
1289 $self->{inject_parents} = { $rev => $tree };
1290 $self->fetch(undef, undef);
1291 }
1292 }
1293
1294 sub set_tree {
1295 my ($self, $tree) = (shift, shift);
1296 my $log_entry = ::get_commit_entry($tree);
1297 unless ($self->{last_rev}) {
1298 fatal("Must have an existing revision to commit\n");
1299 }
1300 my %ed_opts = ( r => $self->{last_rev},
1301 log => $log_entry->{log},
1302 ra => $self->ra,
1303 tree_a => $self->{last_commit},
1304 tree_b => $tree,
1305 editor_cb => sub {
1306 $self->set_tree_cb($log_entry, $tree, @_) },
1307 svn_path => $self->{path} );
1308 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1309 print "No changes\nr$self->{last_rev} = $tree\n";
1310 }
1311 }
1312
1313 sub rebuild {
1314 my ($self) = @_;
1315 print "Rebuilding $self->{db_path} ...\n";
1316 my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1317 my $latest;
1318 my $full_url = $self->full_url;
1319 my $svn_uuid;
1320 while (<$rev_list>) {
1321 chomp;
1322 my $c = $_;
1323 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1324 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1325
1326 # ignore merges (from set-tree)
1327 next if (!defined $rev || !$uuid);
1328
1329 # if we merged or otherwise started elsewhere, this is
1330 # how we break out of it
1331 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1332 ($full_url && $url && ($url ne $full_url))) {
1333 next;
1334 }
1335 $latest ||= $rev;
1336 $svn_uuid ||= $uuid;
1337
1338 $self->rev_db_set($rev, $c);
1339 print "r$rev = $c\n";
1340 }
1341 command_close_pipe($rev_list, $ctx);
1342 print "Done rebuilding $self->{db_path}\n";
1343 }
1344
1345 # rev_db:
1346 # Tie::File seems to be prone to offset errors if revisions get sparse,
1347 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
1348 # one of my favorite modules is out :< Next up would be one of the DBM
1349 # modules, but I'm not sure which is most portable... So I'll just
1350 # go with something that's plain-text, but still capable of
1351 # being randomly accessed. So here's my ultra-simple fixed-width
1352 # database. All records are 40 characters + "\n", so it's easy to seek
1353 # to a revision: (41 * rev) is the byte offset.
1354 # A record of 40 0s denotes an empty revision.
1355 # And yes, it's still pretty fast (faster than Tie::File).
1356 # These files are disposable unless --no-metadata is set
1357
1358 sub rev_db_set {
1359 my ($self, $rev, $commit, $update_ref) = @_;
1360 length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1361 my ($db, $db_lock) = ($self->{db_path}, "$self->{db_path}.lock");
1362 my $sig;
1363 if ($update_ref) {
1364 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
1365 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
1366 }
1367 $LOCKFILES{$db_lock} = 1;
1368 if ($_no_metadata) {
1369 copy($db, $db_lock) or die "rev_db_set(@_): ",
1370 "Failed to copy: ",
1371 "$db => $db_lock ($!)\n";
1372 } else {
1373 rename $db, $db_lock or die "rev_db_set(@_): ",
1374 "Failed to rename: ",
1375 "$db => $db_lock ($!)\n";
1376 }
1377 open my $fh, '+<', $db_lock or croak $!;
1378 my $offset = $rev * 41;
1379 # assume that append is the common case:
1380 seek $fh, 0, 2 or croak $!;
1381 my $pos = tell $fh;
1382 if ($pos < $offset) {
1383 for (1 .. (($offset - $pos) / 41)) {
1384 print $fh (('0' x 40),"\n") or croak $!;
1385 }
1386 }
1387 seek $fh, $offset, 0 or croak $!;
1388 print $fh $commit,"\n" or croak $!;
1389 close $fh or croak $!;
1390 if ($update_ref) {
1391 command_noisy('update-ref', '-m', "r$rev",
1392 $self->refname, $commit);
1393 }
1394 rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
1395 "$db_lock => $db ($!)\n";
1396 delete $LOCKFILES{$db_lock};
1397 if ($update_ref) {
1398 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
1399 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
1400 kill $sig, $$ if defined $sig;
1401 }
1402 }
1403
1404 sub rev_db_max {
1405 my ($self) = @_;
1406 my @stat = stat $self->{db_path} or
1407 die "Couldn't stat $self->{db_path}: $!\n";
1408 ($stat[7] % 41) == 0 or
1409 die "$self->{db_path} inconsistent size:$stat[7]\n";
1410 my $max = $stat[7] / 41;
1411 (($max > 0) ? $max - 1 : 0);
1412 }
1413
1414 sub rev_db_get {
1415 my ($self, $rev) = @_;
1416 my $ret;
1417 my $offset = $rev * 41;
1418 open my $fh, '<', $self->{db_path} or croak $!;
1419 if (sysseek($fh, $offset, 0) == $offset) {
1420 my $read = sysread($fh, $ret, 40);
1421 $ret = undef if ($read != 40 || $ret eq ('0'x40));
1422 }
1423 close $fh or croak $!;
1424 $ret;
1425 }
1426
1427 sub find_rev_before {
1428 my ($self, $rev, $eq_ok) = @_;
1429 --$rev unless $eq_ok;
1430 while ($rev > 0) {
1431 if (my $c = $self->rev_db_get($rev)) {
1432 return ($rev, $c);
1433 }
1434 --$rev;
1435 }
1436 return (undef, undef);
1437 }
1438
1439 sub _new {
1440 my ($class, $repo_id, $ref_id, $path) = @_;
1441 unless (defined $repo_id && length $repo_id) {
1442 $repo_id = $Git::SVN::default_repo_id;
1443 }
1444 unless (defined $ref_id && length $ref_id) {
1445 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1446 }
1447 $_[1] = $repo_id = sanitize_remote_name($repo_id);
1448 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1449 $_[3] = $path = '' unless (defined $path);
1450 mkpath([$dir]);
1451 unless (-f "$dir/.rev_db") {
1452 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1453 close $fh or croak $!;
1454 }
1455 bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1456 path => $path,
1457 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1458 }
1459
1460 sub uri_encode {
1461 my ($f) = @_;
1462 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1463 $f
1464 }
1465
1466 package Git::SVN::Prompt;
1467 use strict;
1468 use warnings;
1469 require SVN::Core;
1470 use vars qw/$_no_auth_cache $_username/;
1471
1472 sub simple {
1473 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1474 $may_save = undef if $_no_auth_cache;
1475 $default_username = $_username if defined $_username;
1476 if (defined $default_username && length $default_username) {
1477 if (defined $realm && length $realm) {
1478 print STDERR "Authentication realm: $realm\n";
1479 STDERR->flush;
1480 }
1481 $cred->username($default_username);
1482 } else {
1483 username($cred, $realm, $may_save, $pool);
1484 }
1485 $cred->password(_read_password("Password for '" .
1486 $cred->username . "': ", $realm));
1487 $cred->may_save($may_save);
1488 $SVN::_Core::SVN_NO_ERROR;
1489 }
1490
1491 sub ssl_server_trust {
1492 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1493 $may_save = undef if $_no_auth_cache;
1494 print STDERR "Error validating server certificate for '$realm':\n";
1495 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1496 print STDERR " - The certificate is not issued by a trusted ",
1497 "authority. Use the\n",
1498 " fingerprint to validate the certificate manually!\n";
1499 }
1500 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1501 print STDERR " - The certificate hostname does not match.\n";
1502 }
1503 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1504 print STDERR " - The certificate is not yet valid.\n";
1505 }
1506 if ($failures & $SVN::Auth::SSL::EXPIRED) {
1507 print STDERR " - The certificate has expired.\n";
1508 }
1509 if ($failures & $SVN::Auth::SSL::OTHER) {
1510 print STDERR " - The certificate has an unknown error.\n";
1511 }
1512 printf STDERR
1513 "Certificate information:\n".
1514 " - Hostname: %s\n".
1515 " - Valid: from %s until %s\n".
1516 " - Issuer: %s\n".
1517 " - Fingerprint: %s\n",
1518 map $cert_info->$_, qw(hostname valid_from valid_until
1519 issuer_dname fingerprint);
1520 my $choice;
1521 prompt:
1522 print STDERR $may_save ?
1523 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1524 "(R)eject or accept (t)emporarily? ";
1525 STDERR->flush;
1526 $choice = lc(substr(<STDIN> || 'R', 0, 1));
1527 if ($choice =~ /^t$/i) {
1528 $cred->may_save(undef);
1529 } elsif ($choice =~ /^r$/i) {
1530 return -1;
1531 } elsif ($may_save && $choice =~ /^p$/i) {
1532 $cred->may_save($may_save);
1533 } else {
1534 goto prompt;
1535 }
1536 $cred->accepted_failures($failures);
1537 $SVN::_Core::SVN_NO_ERROR;
1538 }
1539
1540 sub ssl_client_cert {
1541 my ($cred, $realm, $may_save, $pool) = @_;
1542 $may_save = undef if $_no_auth_cache;
1543 print STDERR "Client certificate filename: ";
1544 STDERR->flush;
1545 chomp(my $filename = <STDIN>);
1546 $cred->cert_file($filename);
1547 $cred->may_save($may_save);
1548 $SVN::_Core::SVN_NO_ERROR;
1549 }
1550
1551 sub ssl_client_cert_pw {
1552 my ($cred, $realm, $may_save, $pool) = @_;
1553 $may_save = undef if $_no_auth_cache;
1554 $cred->password(_read_password("Password: ", $realm));
1555 $cred->may_save($may_save);
1556 $SVN::_Core::SVN_NO_ERROR;
1557 }
1558
1559 sub username {
1560 my ($cred, $realm, $may_save, $pool) = @_;
1561 $may_save = undef if $_no_auth_cache;
1562 if (defined $realm && length $realm) {
1563 print STDERR "Authentication realm: $realm\n";
1564 }
1565 my $username;
1566 if (defined $_username) {
1567 $username = $_username;
1568 } else {
1569 print STDERR "Username: ";
1570 STDERR->flush;
1571 chomp($username = <STDIN>);
1572 }
1573 $cred->username($username);
1574 $cred->may_save($may_save);
1575 $SVN::_Core::SVN_NO_ERROR;
1576 }
1577
1578 sub _read_password {
1579 my ($prompt, $realm) = @_;
1580 print STDERR $prompt;
1581 STDERR->flush;
1582 require Term::ReadKey;
1583 Term::ReadKey::ReadMode('noecho');
1584 my $password = '';
1585 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1586 last if $key =~ /[\012\015]/; # \n\r
1587 $password .= $key;
1588 }
1589 Term::ReadKey::ReadMode('restore');
1590 print STDERR "\n";
1591 STDERR->flush;
1592 $password;
1593 }
1594
1595 package main;
1596
1597 {
1598 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1599 $SVN::Node::dir.$SVN::Node::unknown.
1600 $SVN::Node::none.$SVN::Node::file.
1601 $SVN::Node::dir.$SVN::Node::unknown.
1602 $SVN::Auth::SSL::CNMISMATCH.
1603 $SVN::Auth::SSL::NOTYETVALID.
1604 $SVN::Auth::SSL::EXPIRED.
1605 $SVN::Auth::SSL::UNKNOWNCA.
1606 $SVN::Auth::SSL::OTHER;
1607 }
1608
1609 package SVN::Git::Fetcher;
1610 use vars qw/@ISA/;
1611 use strict;
1612 use warnings;
1613 use Carp qw/croak/;
1614 use IO::File qw//;
1615 use Digest::MD5;
1616
1617 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1618 sub new {
1619 my ($class, $git_svn) = @_;
1620 my $self = SVN::Delta::Editor->new;
1621 bless $self, $class;
1622 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1623 $self->{empty} = {};
1624 $self->{dir_prop} = {};
1625 $self->{file_prop} = {};
1626 $self->{absent_dir} = {};
1627 $self->{absent_file} = {};
1628 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1629 $self;
1630 }
1631
1632 sub set_path_strip {
1633 my ($self, $path) = @_;
1634 $self->{path_strip} = qr/^\Q$path\E\/?/;
1635 }
1636
1637 sub open_root {
1638 { path => '' };
1639 }
1640
1641 sub open_directory {
1642 my ($self, $path, $pb, $rev) = @_;
1643 { path => $path };
1644 }
1645
1646 sub git_path {
1647 my ($self, $path) = @_;
1648 if ($self->{path_strip}) {
1649 $path =~ s!$self->{path_strip}!! or
1650 die "Failed to strip path '$path' ($self->{path_strip})\n";
1651 }
1652 $path;
1653 }
1654
1655 sub delete_entry {
1656 my ($self, $path, $rev, $pb) = @_;
1657
1658 my $gpath = $self->git_path($path);
1659 return undef if ($gpath eq '');
1660
1661 # remove entire directories.
1662 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1663 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1664 -r --name-only -z/,
1665 $self->{c}, '--', $gpath);
1666 local $/ = "\0";
1667 while (<$ls>) {
1668 chomp;
1669 $self->{gii}->remove($_);
1670 print "\tD\t$_\n" unless $self->{q};
1671 }
1672 print "\tD\t$gpath/\n" unless $self->{q};
1673 command_close_pipe($ls, $ctx);
1674 $self->{empty}->{$path} = 0
1675 } else {
1676 $self->{gii}->remove($gpath);
1677 print "\tD\t$gpath\n" unless $self->{q};
1678 }
1679 undef;
1680 }
1681
1682 sub open_file {
1683 my ($self, $path, $pb, $rev) = @_;
1684 my $gpath = $self->git_path($path);
1685 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1686 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1687 unless (defined $mode && defined $blob) {
1688 die "$path was not found in commit $self->{c} (r$rev)\n";
1689 }
1690 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1691 pool => SVN::Pool->new, action => 'M' };
1692 }
1693
1694 sub add_file {
1695 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1696 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1697 delete $self->{empty}->{$dir};
1698 { path => $path, mode_a => 100644, mode_b => 100644,
1699 pool => SVN::Pool->new, action => 'A' };
1700 }
1701
1702 sub add_directory {
1703 my ($self, $path, $cp_path, $cp_rev) = @_;
1704 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1705 delete $self->{empty}->{$dir};
1706 $self->{empty}->{$path} = 1;
1707 { path => $path };
1708 }
1709
1710 sub change_dir_prop {
1711 my ($self, $db, $prop, $value) = @_;
1712 $self->{dir_prop}->{$db->{path}} ||= {};
1713 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1714 undef;
1715 }
1716
1717 sub absent_directory {
1718 my ($self, $path, $pb) = @_;
1719 $self->{absent_dir}->{$pb->{path}} ||= [];
1720 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1721 undef;
1722 }
1723
1724 sub absent_file {
1725 my ($self, $path, $pb) = @_;
1726 $self->{absent_file}->{$pb->{path}} ||= [];
1727 push @{$self->{absent_file}->{$pb->{path}}}, $path;
1728 undef;
1729 }
1730
1731 sub change_file_prop {
1732 my ($self, $fb, $prop, $value) = @_;
1733 if ($prop eq 'svn:executable') {
1734 if ($fb->{mode_b} != 120000) {
1735 $fb->{mode_b} = defined $value ? 100755 : 100644;
1736 }
1737 } elsif ($prop eq 'svn:special') {
1738 $fb->{mode_b} = defined $value ? 120000 : 100644;
1739 } else {
1740 $self->{file_prop}->{$fb->{path}} ||= {};
1741 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1742 }
1743 undef;
1744 }
1745
1746 sub apply_textdelta {
1747 my ($self, $fb, $exp) = @_;
1748 my $fh = IO::File->new_tmpfile;
1749 $fh->autoflush(1);
1750 # $fh gets auto-closed() by SVN::TxDelta::apply(),
1751 # (but $base does not,) so dup() it for reading in close_file
1752 open my $dup, '<&', $fh or croak $!;
1753 my $base = IO::File->new_tmpfile;
1754 $base->autoflush(1);
1755 if ($fb->{blob}) {
1756 defined (my $pid = fork) or croak $!;
1757 if (!$pid) {
1758 open STDOUT, '>&', $base or croak $!;
1759 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1760 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1761 }
1762 waitpid $pid, 0;
1763 croak $? if $?;
1764
1765 if (defined $exp) {
1766 seek $base, 0, 0 or croak $!;
1767 my $md5 = Digest::MD5->new;
1768 $md5->addfile($base);
1769 my $got = $md5->hexdigest;
1770 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1771 "expected: $exp\n",
1772 " got: $got\n" if ($got ne $exp);
1773 }
1774 }
1775 seek $base, 0, 0 or croak $!;
1776 $fb->{fh} = $dup;
1777 $fb->{base} = $base;
1778 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1779 }
1780
1781 sub close_file {
1782 my ($self, $fb, $exp) = @_;
1783 my $hash;
1784 my $path = $self->git_path($fb->{path});
1785 if (my $fh = $fb->{fh}) {
1786 seek($fh, 0, 0) or croak $!;
1787 my $md5 = Digest::MD5->new;
1788 $md5->addfile($fh);
1789 my $got = $md5->hexdigest;
1790 die "Checksum mismatch: $path\n",
1791 "expected: $exp\n got: $got\n" if ($got ne $exp);
1792 seek($fh, 0, 0) or croak $!;
1793 if ($fb->{mode_b} == 120000) {
1794 read($fh, my $buf, 5) == 5 or croak $!;
1795 $buf eq 'link ' or die "$path has mode 120000",
1796 "but is not a link\n";
1797 }
1798 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1799 if (!$pid) {
1800 open STDIN, '<&', $fh or croak $!;
1801 exec qw/git-hash-object -w --stdin/ or croak $!;
1802 }
1803 chomp($hash = do { local $/; <$out> });
1804 close $out or croak $!;
1805 close $fh or croak $!;
1806 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1807 close $fb->{base} or croak $!;
1808 } else {
1809 $hash = $fb->{blob} or die "no blob information\n";
1810 }
1811 $fb->{pool}->clear;
1812 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1813 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1814 undef;
1815 }
1816
1817 sub abort_edit {
1818 my $self = shift;
1819 $self->{nr} = $self->{gii}->{nr};
1820 delete $self->{gii};
1821 $self->SUPER::abort_edit(@_);
1822 }
1823
1824 sub close_edit {
1825 my $self = shift;
1826 $self->{git_commit_ok} = 1;
1827 $self->{nr} = $self->{gii}->{nr};
1828 delete $self->{gii};
1829 $self->SUPER::close_edit(@_);
1830 }
1831
1832 package SVN::Git::Editor;
1833 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
1834 use strict;
1835 use warnings;
1836 use Carp qw/croak/;
1837 use IO::File;
1838 use Digest::MD5;
1839
1840 sub new {
1841 my ($class, $opts) = @_;
1842 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
1843 die "$_ required!\n" unless (defined $opts->{$_});
1844 }
1845
1846 my $pool = SVN::Pool->new;
1847 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
1848 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
1849 $opts->{r}, $mods);
1850
1851 # $opts->{ra} functions should not be used after this:
1852 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
1853 $opts->{editor_cb}, $pool);
1854 my $self = SVN::Delta::Editor->new(@ce, $pool);
1855 bless $self, $class;
1856 foreach (qw/svn_path r tree_a tree_b/) {
1857 $self->{$_} = $opts->{$_};
1858 }
1859 $self->{url} = $opts->{ra}->{url};
1860 $self->{mods} = $mods;
1861 $self->{types} = $types;
1862 $self->{pool} = $pool;
1863 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1864 $self->{rm} = { };
1865 $self->{path_prefix} = length $self->{svn_path} ?
1866 "$self->{svn_path}/" : '';
1867 return $self;
1868 }
1869
1870 sub generate_diff {
1871 my ($tree_a, $tree_b) = @_;
1872 my @diff_tree = qw(diff-tree -z -r);
1873 if ($_cp_similarity) {
1874 push @diff_tree, "-C$_cp_similarity";
1875 } else {
1876 push @diff_tree, '-C';
1877 }
1878 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
1879 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
1880 push @diff_tree, $tree_a, $tree_b;
1881 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1882 local $/ = "\0";
1883 my $state = 'meta';
1884 my @mods;
1885 while (<$diff_fh>) {
1886 chomp $_; # this gets rid of the trailing "\0"
1887 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1888 $::sha1\s($::sha1)\s
1889 ([MTCRAD])\d*$/xo) {
1890 push @mods, { mode_a => $1, mode_b => $2,
1891 sha1_b => $3, chg => $4 };
1892 if ($4 =~ /^(?:C|R)$/) {
1893 $state = 'file_a';
1894 } else {
1895 $state = 'file_b';
1896 }
1897 } elsif ($state eq 'file_a') {
1898 my $x = $mods[$#mods] or croak "Empty array\n";
1899 if ($x->{chg} !~ /^(?:C|R)$/) {
1900 croak "Error parsing $_, $x->{chg}\n";
1901 }
1902 $x->{file_a} = $_;
1903 $state = 'file_b';
1904 } elsif ($state eq 'file_b') {
1905 my $x = $mods[$#mods] or croak "Empty array\n";
1906 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1907 croak "Error parsing $_, $x->{chg}\n";
1908 }
1909 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1910 croak "Error parsing $_, $x->{chg}\n";
1911 }
1912 $x->{file_b} = $_;
1913 $state = 'meta';
1914 } else {
1915 croak "Error parsing $_\n";
1916 }
1917 }
1918 command_close_pipe($diff_fh, $ctx);
1919 \@mods;
1920 }
1921
1922 sub check_diff_paths {
1923 my ($ra, $pfx, $rev, $mods) = @_;
1924 my %types;
1925 $pfx .= '/' if length $pfx;
1926
1927 sub type_diff_paths {
1928 my ($ra, $types, $path, $rev) = @_;
1929 my @p = split m#/+#, $path;
1930 my $c = shift @p;
1931 unless (defined $types->{$c}) {
1932 $types->{$c} = $ra->check_path($c, $rev);
1933 }
1934 while (@p) {
1935 $c .= '/' . shift @p;
1936 next if defined $types->{$c};
1937 $types->{$c} = $ra->check_path($c, $rev);
1938 }
1939 }
1940
1941 foreach my $m (@$mods) {
1942 foreach my $f (qw/file_a file_b/) {
1943 next unless defined $m->{$f};
1944 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
1945 if (length $pfx.$dir && ! defined $types{$dir}) {
1946 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
1947 }
1948 }
1949 }
1950 \%types;
1951 }
1952
1953 sub split_path {
1954 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1955 }
1956
1957 sub repo_path {
1958 my ($self, $path) = @_;
1959 $self->{path_prefix}.(defined $path ? $path : '');
1960 }
1961
1962 sub url_path {
1963 my ($self, $path) = @_;
1964 $self->{url} . '/' . $self->repo_path($path);
1965 }
1966
1967 sub rmdirs {
1968 my ($self) = @_;
1969 my $rm = $self->{rm};
1970 delete $rm->{''}; # we never delete the url we're tracking
1971 return unless %$rm;
1972
1973 foreach (keys %$rm) {
1974 my @d = split m#/#, $_;
1975 my $c = shift @d;
1976 $rm->{$c} = 1;
1977 while (@d) {
1978 $c .= '/' . shift @d;
1979 $rm->{$c} = 1;
1980 }
1981 }
1982 delete $rm->{$self->{svn_path}};
1983 delete $rm->{''}; # we never delete the url we're tracking
1984 return unless %$rm;
1985
1986 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
1987 $self->{tree_b});
1988 local $/ = "\0";
1989 while (<$fh>) {
1990 chomp;
1991 my @dn = split m#/#, $_;
1992 while (pop @dn) {
1993 delete $rm->{join '/', @dn};
1994 }
1995 unless (%$rm) {
1996 close $fh;
1997 return;
1998 }
1999 }
2000 command_close_pipe($fh, $ctx);
2001
2002 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2003 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2004 $self->close_directory($bat->{$d}, $p);
2005 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2006 print "\tD+\t$d/\n" unless $::_q;
2007 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2008 delete $bat->{$d};
2009 }
2010 }
2011
2012 sub open_or_add_dir {
2013 my ($self, $full_path, $baton) = @_;
2014 my $t = $self->{types}->{$full_path};
2015 if (!defined $t) {
2016 die "$full_path not known in r$self->{r} or we have a bug!\n";
2017 }
2018 if ($t == $SVN::Node::none) {
2019 return $self->add_directory($full_path, $baton,
2020 undef, -1, $self->{pool});
2021 } elsif ($t == $SVN::Node::dir) {
2022 return $self->open_directory($full_path, $baton,
2023 $self->{r}, $self->{pool});
2024 }
2025 print STDERR "$full_path already exists in repository at ",
2026 "r$self->{r} and it is not a directory (",
2027 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2028 exit 1;
2029 }
2030
2031 sub ensure_path {
2032 my ($self, $path) = @_;
2033 my $bat = $self->{bat};
2034 my $repo_path = $self->repo_path($path);
2035 return $bat->{''} unless (length $repo_path);
2036 my @p = split m#/+#, $repo_path;
2037 my $c = shift @p;
2038 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2039 while (@p) {
2040 my $c0 = $c;
2041 $c .= '/' . shift @p;
2042 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2043 }
2044 return $bat->{$c};
2045 }
2046
2047 sub A {
2048 my ($self, $m) = @_;
2049 my ($dir, $file) = split_path($m->{file_b});
2050 my $pbat = $self->ensure_path($dir);
2051 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2052 undef, -1);
2053 print "\tA\t$m->{file_b}\n" unless $::_q;
2054 $self->chg_file($fbat, $m);
2055 $self->close_file($fbat,undef,$self->{pool});
2056 }
2057
2058 sub C {
2059 my ($self, $m) = @_;
2060 my ($dir, $file) = split_path($m->{file_b});
2061 my $pbat = $self->ensure_path($dir);
2062 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2063 $self->url_path($m->{file_a}), $self->{r});
2064 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2065 $self->chg_file($fbat, $m);
2066 $self->close_file($fbat,undef,$self->{pool});
2067 }
2068
2069 sub delete_entry {
2070 my ($self, $path, $pbat) = @_;
2071 my $rpath = $self->repo_path($path);
2072 my ($dir, $file) = split_path($rpath);
2073 $self->{rm}->{$dir} = 1;
2074 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2075 }
2076
2077 sub R {
2078 my ($self, $m) = @_;
2079 my ($dir, $file) = split_path($m->{file_b});
2080 my $pbat = $self->ensure_path($dir);
2081 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2082 $self->url_path($m->{file_a}), $self->{r});
2083 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2084 $self->chg_file($fbat, $m);
2085 $self->close_file($fbat,undef,$self->{pool});
2086
2087 ($dir, $file) = split_path($m->{file_a});
2088 $pbat = $self->ensure_path($dir);
2089 $self->delete_entry($m->{file_a}, $pbat);
2090 }
2091
2092 sub M {
2093 my ($self, $m) = @_;
2094 my ($dir, $file) = split_path($m->{file_b});
2095 my $pbat = $self->ensure_path($dir);
2096 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2097 $pbat,$self->{r},$self->{pool});
2098 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2099 $self->chg_file($fbat, $m);
2100 $self->close_file($fbat,undef,$self->{pool});
2101 }
2102
2103 sub T { shift->M(@_) }
2104
2105 sub change_file_prop {
2106 my ($self, $fbat, $pname, $pval) = @_;
2107 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2108 }
2109
2110 sub chg_file {
2111 my ($self, $fbat, $m) = @_;
2112 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2113 $self->change_file_prop($fbat,'svn:executable','*');
2114 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2115 $self->change_file_prop($fbat,'svn:executable',undef);
2116 }
2117 my $fh = IO::File->new_tmpfile or croak $!;
2118 if ($m->{mode_b} =~ /^120/) {
2119 print $fh 'link ' or croak $!;
2120 $self->change_file_prop($fbat,'svn:special','*');
2121 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2122 $self->change_file_prop($fbat,'svn:special',undef);
2123 }
2124 defined(my $pid = fork) or croak $!;
2125 if (!$pid) {
2126 open STDOUT, '>&', $fh or croak $!;
2127 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2128 }
2129 waitpid $pid, 0;
2130 croak $? if $?;
2131 $fh->flush == 0 or croak $!;
2132 seek $fh, 0, 0 or croak $!;
2133
2134 my $md5 = Digest::MD5->new;
2135 $md5->addfile($fh) or croak $!;
2136 seek $fh, 0, 0 or croak $!;
2137
2138 my $exp = $md5->hexdigest;
2139 my $pool = SVN::Pool->new;
2140 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2141 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2142 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2143 $pool->clear;
2144
2145 close $fh or croak $!;
2146 }
2147
2148 sub D {
2149 my ($self, $m) = @_;
2150 my ($dir, $file) = split_path($m->{file_b});
2151 my $pbat = $self->ensure_path($dir);
2152 print "\tD\t$m->{file_b}\n" unless $::_q;
2153 $self->delete_entry($m->{file_b}, $pbat);
2154 }
2155
2156 sub close_edit {
2157 my ($self) = @_;
2158 my ($p,$bat) = ($self->{pool}, $self->{bat});
2159 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2160 $self->close_directory($bat->{$_}, $p);
2161 }
2162 $self->SUPER::close_edit($p);
2163 $p->clear;
2164 }
2165
2166 sub abort_edit {
2167 my ($self) = @_;
2168 $self->SUPER::abort_edit($self->{pool});
2169 }
2170
2171 sub DESTROY {
2172 my $self = shift;
2173 $self->SUPER::DESTROY(@_);
2174 $self->{pool}->clear;
2175 }
2176
2177 # this drives the editor
2178 sub apply_diff {
2179 my ($self) = @_;
2180 my $mods = $self->{mods};
2181 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2182 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2183 my $f = $m->{chg};
2184 if (defined $o{$f}) {
2185 $self->$f($m);
2186 } else {
2187 fatal("Invalid change type: $f\n");
2188 }
2189 }
2190 $self->rmdirs if $_rmdir;
2191 if (@$mods == 0) {
2192 $self->abort_edit;
2193 } else {
2194 $self->close_edit;
2195 }
2196 return scalar @$mods;
2197 }
2198
2199 package Git::SVN::Ra;
2200 use vars qw/@ISA $config_dir/;
2201 use strict;
2202 use warnings;
2203 my ($can_do_switch);
2204 my $RA;
2205
2206 BEGIN {
2207 # enforce temporary pool usage for some simple functions
2208 my $e;
2209 foreach (qw/get_latest_revnum rev_proplist get_file
2210 check_path get_dir get_uuid get_repos_root/) {
2211 $e .= "sub $_ {
2212 my \$self = shift;
2213 my \$pool = SVN::Pool->new;
2214 my \@ret = \$self->SUPER::$_(\@_,\$pool);
2215 \$pool->clear;
2216 wantarray ? \@ret : \$ret[0]; }\n";
2217 }
2218 eval $e;
2219 }
2220
2221 sub new {
2222 my ($class, $url) = @_;
2223 $url =~ s!/+$!!;
2224 return $RA if ($RA && $RA->{url} eq $url);
2225
2226 SVN::_Core::svn_config_ensure($config_dir, undef);
2227 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2228 SVN::Client::get_simple_provider(),
2229 SVN::Client::get_ssl_server_trust_file_provider(),
2230 SVN::Client::get_simple_prompt_provider(
2231 \&Git::SVN::Prompt::simple, 2),
2232 SVN::Client::get_ssl_client_cert_prompt_provider(
2233 \&Git::SVN::Prompt::ssl_client_cert, 2),
2234 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2235 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2236 SVN::Client::get_username_provider(),
2237 SVN::Client::get_ssl_server_trust_prompt_provider(
2238 \&Git::SVN::Prompt::ssl_server_trust),
2239 SVN::Client::get_username_prompt_provider(
2240 \&Git::SVN::Prompt::username, 2),
2241 ]);
2242 my $config = SVN::Core::config_get_config($config_dir);
2243 my $self = SVN::Ra->new(url => $url, auth => $baton,
2244 config => $config,
2245 pool => SVN::Pool->new,
2246 auth_provider_callbacks => $callbacks);
2247 $self->{svn_path} = $url;
2248 $self->{repos_root} = $self->get_repos_root;
2249 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2250 $RA = bless $self, $class;
2251 }
2252
2253 sub DESTROY {
2254 # do not call the real DESTROY since we store ourselves in $RA
2255 }
2256
2257 sub get_log {
2258 my ($self, @args) = @_;
2259 my $pool = SVN::Pool->new;
2260 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2261 my $ret = $self->SUPER::get_log(@args, $pool);
2262 $pool->clear;
2263 $ret;
2264 }
2265
2266 sub get_commit_editor {
2267 my ($self, $log, $cb, $pool) = @_;
2268 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2269 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2270 }
2271
2272 sub uuid {
2273 my ($self) = @_;
2274 $self->{uuid} ||= $self->get_uuid;
2275 }
2276
2277 sub gs_do_update {
2278 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
2279 my $new = ($rev_a == $rev_b);
2280 my $path = $gs->{path};
2281
2282 my $ta = $self->check_path($path, $rev_a);
2283 my $tb = $new ? $ta : $self->check_path($path, $rev_b);
2284 return 1 if ($tb != $SVN::Node::dir && $ta != $SVN::Node::dir);
2285 if ($ta == $SVN::Node::none) {
2286 $rev_a = $rev_b;
2287 $new = 1;
2288 }
2289
2290 my $pool = SVN::Pool->new;
2291 $editor->set_path_strip($path);
2292 my (@pc) = split m#/#, $path;
2293 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2294 1, $editor, $pool);
2295 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2296
2297 # Since we can't rely on svn_ra_reparent being available, we'll
2298 # just have to do some magic with set_path to make it so
2299 # we only want a partial path.
2300 my $sp = '';
2301 my $final = join('/', @pc);
2302 while (@pc) {
2303 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2304 $sp .= '/' if length $sp;
2305 $sp .= shift @pc;
2306 }
2307 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2308
2309 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2310
2311 $reporter->finish_report($pool);
2312 $pool->clear;
2313 $editor->{git_commit_ok};
2314 }
2315
2316 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2317 # svn_ra_reparent didn't work before 1.4)
2318 sub gs_do_switch {
2319 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
2320 my $path = $gs->{path};
2321 my $pool = SVN::Pool->new;
2322
2323 my $full_url = $self->{url};
2324 my $old_url = $full_url;
2325 $full_url .= "/$path" if length $path;
2326 my ($ra, $reparented);
2327 if ($old_url ne $full_url) {
2328 if ($old_url !~ m#^svn(\+ssh)?://#) {
2329 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
2330 $pool);
2331 $self->{url} = $full_url;
2332 $reparented = 1;
2333 } else {
2334 $ra = Git::SVN::Ra->new($full_url);
2335 }
2336 }
2337 $ra ||= $self;
2338 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
2339 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2340 $reporter->set_path('', $rev_a, 0, @lock, $pool);
2341 $reporter->finish_report($pool);
2342
2343 if ($reparented) {
2344 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
2345 $self->{url} = $old_url;
2346 }
2347
2348 $pool->clear;
2349 $editor->{git_commit_ok};
2350 }
2351
2352 sub gs_fetch_loop_common {
2353 my ($self, $base, $head, @gs) = @_;
2354 my $inc = 1000;
2355 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
2356 foreach my $gs (@gs) {
2357 if (my $last_commit = $gs->last_commit) {
2358 $gs->assert_index_clean($last_commit);
2359 }
2360 }
2361 while (1) {
2362 my %revs;
2363 my $err;
2364 my $err_handler = $SVN::Error::handler;
2365 $SVN::Error::handler = sub {
2366 ($err) = @_;
2367 skip_unknown_revs($err);
2368 };
2369 foreach my $gs (@gs) {
2370 $self->get_log([$gs->{path}], $min, $max, 0, 1, 1, sub
2371 { my ($paths, $rev) = @_;
2372 push @{$revs{$rev}},
2373 [ $gs,
2374 dup_changed_paths($paths) ] });
2375
2376 next unless ($err && $max >= $head);
2377
2378 print STDERR "Path '$gs->{path}' ",
2379 "was probably deleted:\n",
2380 $err->expanded_message,
2381 "\nWill attempt to follow ",
2382 "revisions r$min .. r$max ",
2383 "committed before the deletion\n";
2384 my $hi = $max;
2385 while (--$hi >= $min) {
2386 my $ok;
2387 $self->get_log([$gs->{path}], $min, $hi,
2388 0, 1, 1, sub {
2389 my ($paths, $rev) = @_;
2390 $ok = $rev;
2391 push @{$revs{$rev}}, [ $gs,
2392 dup_changed_paths($_[0])]});
2393 if ($ok) {
2394 print STDERR "r$min .. r$ok OK\n";
2395 last;
2396 }
2397 }
2398 }
2399 $SVN::Error::handler = $err_handler;
2400 foreach my $r (sort {$a <=> $b} keys %revs) {
2401 foreach (@{$revs{$r}}) {
2402 my ($gs, $paths) = @$_;
2403 my $lr = $gs->last_rev;
2404 next if defined $lr && $lr >= $r;
2405 next if defined $gs->rev_db_get($r);
2406 if (my $log_entry = $gs->do_fetch($paths, $r)) {
2407 $gs->do_git_commit($log_entry);
2408 }
2409 }
2410 }
2411 # pre-fill the .rev_db since it'll eventually get filled in
2412 # with '0' x40 if something new gets committed
2413 foreach my $gs (@gs) {
2414 next if defined $gs->rev_db_get($max);
2415 $gs->rev_db_set($max, 0 x40);
2416 }
2417 last if $max >= $head;
2418 $min = $max + 1;
2419 $max += $inc;
2420 $max = $head if ($max > $head);
2421 }
2422 }
2423
2424 sub minimize_url {
2425 my ($self) = @_;
2426 return $self->{url} if ($self->{url} eq $self->{repos_root});
2427 my $url = $self->{repos_root};
2428 my @components = split(m!/!, $self->{svn_path});
2429 my $c = '';
2430 do {
2431 $url .= "/$c" if length $c;
2432 eval { (ref $self)->new($url)->get_latest_revnum };
2433 } while ($@ && ($c = shift @components));
2434 $url;
2435 }
2436
2437 sub can_do_switch {
2438 my $self = shift;
2439 unless (defined $can_do_switch) {
2440 my $pool = SVN::Pool->new;
2441 my $rep = eval {
2442 $self->do_switch(1, '', 0, $self->{url},
2443 SVN::Delta::Editor->new, $pool);
2444 };
2445 if ($@) {
2446 $can_do_switch = 0;
2447 } else {
2448 $rep->abort_report($pool);
2449 $can_do_switch = 1;
2450 }
2451 $pool->clear;
2452 }
2453 $can_do_switch;
2454 }
2455
2456 sub skip_unknown_revs {
2457 my ($err) = @_;
2458 my $errno = $err->apr_err();
2459 # Maybe the branch we're tracking didn't
2460 # exist when the repo started, so it's
2461 # not an error if it doesn't, just continue
2462 #
2463 # Wonderfully consistent library, eh?
2464 # 160013 - svn:// and file://
2465 # 175002 - http(s)://
2466 # 175007 - http(s):// (this repo required authorization, too...)
2467 # More codes may be discovered later...
2468 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2469 return;
2470 }
2471 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2472 }
2473
2474 # svn_log_changed_path_t objects passed to get_log are likely to be
2475 # overwritten even if only the refs are copied to an external variable,
2476 # so we should dup the structures in their entirety. Using an externally
2477 # passed pool (instead of our temporary and quickly cleared pool in
2478 # Git::SVN::Ra) does not help matters at all...
2479 sub dup_changed_paths {
2480 my ($paths) = @_;
2481 return undef unless $paths;
2482 my %ret;
2483 foreach my $p (keys %$paths) {
2484 my $i = $paths->{$p};
2485 my %s = map { $_ => $i->$_ }
2486 qw/copyfrom_path copyfrom_rev action/;
2487 $ret{$p} = \%s;
2488 }
2489 \%ret;
2490 }
2491
2492 package Git::SVN::Log;
2493 use strict;
2494 use warnings;
2495 use POSIX qw/strftime/;
2496 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2497 %rusers $show_commit $incremental/;
2498 my $l_fmt;
2499
2500 sub cmt_showable {
2501 my ($c) = @_;
2502 return 1 if defined $c->{r};
2503 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2504 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2505 my @log = command(qw/cat-file commit/, $c->{c});
2506 shift @log while ($log[0] ne "\n");
2507 shift @log;
2508 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2509
2510 (undef, $c->{r}, undef) = ::extract_metadata(
2511 (grep(/^git-svn-id: /, @log))[-1]);
2512 }
2513 return defined $c->{r};
2514 }
2515
2516 sub log_use_color {
2517 return 1 if $color;
2518 my ($dc, $dcvar);
2519 $dcvar = 'color.diff';
2520 $dc = `git-config --get $dcvar`;
2521 if ($dc eq '') {
2522 # nothing at all; fallback to "diff.color"
2523 $dcvar = 'diff.color';
2524 $dc = `git-config --get $dcvar`;
2525 }
2526 chomp($dc);
2527 if ($dc eq 'auto') {
2528 my $pc;
2529 $pc = `git-config --get color.pager`;
2530 if ($pc eq '') {
2531 # does not have it -- fallback to pager.color
2532 $pc = `git-config --bool --get pager.color`;
2533 }
2534 else {
2535 $pc = `git-config --bool --get color.pager`;
2536 if ($?) {
2537 $pc = 'false';
2538 }
2539 }
2540 chomp($pc);
2541 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2542 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2543 }
2544 return 0;
2545 }
2546 return 0 if $dc eq 'never';
2547 return 1 if $dc eq 'always';
2548 chomp($dc = `git-config --bool --get $dcvar`);
2549 return ($dc eq 'true');
2550 }
2551
2552 sub git_svn_log_cmd {
2553 my ($r_min, $r_max) = @_;
2554 my $gs = Git::SVN->_new;
2555 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2556 $gs->refname);
2557 push @cmd, '-r' unless $non_recursive;
2558 push @cmd, qw/--raw --name-status/ if $verbose;
2559 push @cmd, '--color' if log_use_color();
2560 return @cmd unless defined $r_max;
2561 if ($r_max == $r_min) {
2562 push @cmd, '--max-count=1';
2563 if (my $c = $gs->rev_db_get($r_max)) {
2564 push @cmd, $c;
2565 }
2566 } else {
2567 my ($c_min, $c_max);
2568 $c_max = $gs->rev_db_get($r_max);
2569 $c_min = $gs->rev_db_get($r_min);
2570 if (defined $c_min && defined $c_max) {
2571 if ($r_max > $r_max) {
2572 push @cmd, "$c_min..$c_max";
2573 } else {
2574 push @cmd, "$c_max..$c_min";
2575 }
2576 } elsif ($r_max > $r_min) {
2577 push @cmd, $c_max;
2578 } else {
2579 push @cmd, $c_min;
2580 }
2581 }
2582 return @cmd;
2583 }
2584
2585 # adapted from pager.c
2586 sub config_pager {
2587 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2588 if (!defined $pager) {
2589 $pager = 'less';
2590 } elsif (length $pager == 0 || $pager eq 'cat') {
2591 $pager = undef;
2592 }
2593 }
2594
2595 sub run_pager {
2596 return unless -t *STDOUT;
2597 pipe my $rfd, my $wfd or return;
2598 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2599 if (!$pid) {
2600 open STDOUT, '>&', $wfd or
2601 ::fatal "Can't redirect to stdout: $!\n";
2602 return;
2603 }
2604 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2605 $ENV{LESS} ||= 'FRSX';
2606 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2607 }
2608
2609 sub tz_to_s_offset {
2610 my ($tz) = @_;
2611 $tz =~ s/(\d\d)$//;
2612 return ($1 * 60) + ($tz * 3600);
2613 }
2614
2615 sub get_author_info {
2616 my ($dest, $author, $t, $tz) = @_;
2617 $author =~ s/(?:^\s*|\s*$)//g;
2618 $dest->{a_raw} = $author;
2619 my $au;
2620 if ($::_authors) {
2621 $au = $rusers{$author} || undef;
2622 }
2623 if (!$au) {
2624 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2625 }
2626 $dest->{t} = $t;
2627 $dest->{tz} = $tz;
2628 $dest->{a} = $au;
2629 # Date::Parse isn't in the standard Perl distro :(
2630 if ($tz =~ s/^\+//) {
2631 $t += tz_to_s_offset($tz);
2632 } elsif ($tz =~ s/^\-//) {
2633 $t -= tz_to_s_offset($tz);
2634 }
2635 $dest->{t_utc} = $t;
2636 }
2637
2638 sub process_commit {
2639 my ($c, $r_min, $r_max, $defer) = @_;
2640 if (defined $r_min && defined $r_max) {
2641 if ($r_min == $c->{r} && $r_min == $r_max) {
2642 show_commit($c);
2643 return 0;
2644 }
2645 return 1 if $r_min == $r_max;
2646 if ($r_min < $r_max) {
2647 # we need to reverse the print order
2648 return 0 if (defined $limit && --$limit < 0);
2649 push @$defer, $c;
2650 return 1;
2651 }
2652 if ($r_min != $r_max) {
2653 return 1 if ($r_min < $c->{r});
2654 return 1 if ($r_max > $c->{r});
2655 }
2656 }
2657 return 0 if (defined $limit && --$limit < 0);
2658 show_commit($c);
2659 return 1;
2660 }
2661
2662 sub show_commit {
2663 my $c = shift;
2664 if ($oneline) {
2665 my $x = "\n";
2666 if (my $l = $c->{l}) {
2667 while ($l->[0] =~ /^\s*$/) { shift @$l }
2668 $x = $l->[0];
2669 }
2670 $l_fmt ||= 'A' . length($c->{r});
2671 print 'r',pack($l_fmt, $c->{r}),' | ';
2672 print "$c->{c} | " if $show_commit;
2673 print $x;
2674 } else {
2675 show_commit_normal($c);
2676 }
2677 }
2678
2679 sub show_commit_changed_paths {
2680 my ($c) = @_;
2681 return unless $c->{changed};
2682 print "Changed paths:\n", @{$c->{changed}};
2683 }
2684
2685 sub show_commit_normal {
2686 my ($c) = @_;
2687 print '-' x72, "\nr$c->{r} | ";
2688 print "$c->{c} | " if $show_commit;
2689 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2690 localtime($c->{t_utc})), ' | ';
2691 my $nr_line = 0;
2692
2693 if (my $l = $c->{l}) {
2694 while ($l->[$#$l] eq "\n" && $#$l > 0
2695 && $l->[($#$l - 1)] eq "\n") {
2696 pop @$l;
2697 }
2698 $nr_line = scalar @$l;
2699 if (!$nr_line) {
2700 print "1 line\n\n\n";
2701 } else {
2702 if ($nr_line == 1) {
2703 $nr_line = '1 line';
2704 } else {
2705 $nr_line .= ' lines';
2706 }
2707 print $nr_line, "\n";
2708 show_commit_changed_paths($c);
2709 print "\n";
2710 print $_ foreach @$l;
2711 }
2712 } else {
2713 print "1 line\n";
2714 show_commit_changed_paths($c);
2715 print "\n";
2716
2717 }
2718 foreach my $x (qw/raw diff/) {
2719 if ($c->{$x}) {
2720 print "\n";
2721 print $_ foreach @{$c->{$x}}
2722 }
2723 }
2724 }
2725
2726 sub cmd_show_log {
2727 my (@args) = @_;
2728 my ($r_min, $r_max);
2729 my $r_last = -1; # prevent dupes
2730 if (defined $TZ) {
2731 $ENV{TZ} = $TZ;
2732 } else {
2733 delete $ENV{TZ};
2734 }
2735 if (defined $::_revision) {
2736 if ($::_revision =~ /^(\d+):(\d+)$/) {
2737 ($r_min, $r_max) = ($1, $2);
2738 } elsif ($::_revision =~ /^\d+$/) {
2739 $r_min = $r_max = $::_revision;
2740 } else {
2741 ::fatal "-r$::_revision is not supported, use ",
2742 "standard \'git log\' arguments instead\n";
2743 }
2744 }
2745
2746 config_pager();
2747 @args = (git_svn_log_cmd($r_min, $r_max), @args);
2748 my $log = command_output_pipe(@args);
2749 run_pager();
2750 my (@k, $c, $d);
2751 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2752 while (<$log>) {
2753 if (/^${esc_color}commit ($::sha1_short)/o) {
2754 my $cmt = $1;
2755 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2756 $r_last = $c->{r};
2757 process_commit($c, $r_min, $r_max, \@k) or
2758 goto out;
2759 }
2760 $d = undef;
2761 $c = { c => $cmt };
2762 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2763 get_author_info($c, $1, $2, $3);
2764 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2765 # ignore
2766 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2767 push @{$c->{raw}}, $_;
2768 } elsif (/^${esc_color}[ACRMDT]\t/) {
2769 # we could add $SVN->{svn_path} here, but that requires
2770 # remote access at the moment (repo_path_split)...
2771 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
2772 push @{$c->{changed}}, $_;
2773 } elsif (/^${esc_color}diff /o) {
2774 $d = 1;
2775 push @{$c->{diff}}, $_;
2776 } elsif ($d) {
2777 push @{$c->{diff}}, $_;
2778 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
2779 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2780 } elsif (s/^${esc_color} //o) {
2781 push @{$c->{l}}, $_;
2782 }
2783 }
2784 if ($c && defined $c->{r} && $c->{r} != $r_last) {
2785 $r_last = $c->{r};
2786 process_commit($c, $r_min, $r_max, \@k);
2787 }
2788 if (@k) {
2789 my $swap = $r_max;
2790 $r_max = $r_min;
2791 $r_min = $swap;
2792 process_commit($_, $r_min, $r_max) foreach reverse @k;
2793 }
2794 out:
2795 close $log;
2796 print '-' x72,"\n" unless $incremental || $oneline;
2797 }
2798
2799 package Git::SVN::Migration;
2800 # these version numbers do NOT correspond to actual version numbers
2801 # of git nor git-svn. They are just relative.
2802 #
2803 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2804 #
2805 # v1 layout: .git/$id/info/url, refs/remotes/$id
2806 #
2807 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2808 #
2809 # v3 layout: .git/svn/$id, refs/remotes/$id
2810 # - info/url may remain for backwards compatibility
2811 # - this is what we migrate up to this layout automatically,
2812 # - this will be used by git svn init on single branches
2813 #
2814 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2815 # - this is only created for newly multi-init-ed
2816 # repositories. Similar in spirit to the
2817 # --use-separate-remotes option in git-clone (now default)
2818 # - we do not automatically migrate to this (following
2819 # the example set by core git)
2820 use strict;
2821 use warnings;
2822 use Carp qw/croak/;
2823 use File::Path qw/mkpath/;
2824 use File::Basename qw/dirname basename/;
2825 use vars qw/$_minimize/;
2826
2827 sub migrate_from_v0 {
2828 my $git_dir = $ENV{GIT_DIR};
2829 return undef unless -d $git_dir;
2830 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2831 my $migrated = 0;
2832 while (<$fh>) {
2833 chomp;
2834 my ($id, $orig_ref) = ($_, $_);
2835 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2836 next unless -f "$git_dir/$id/info/url";
2837 my $new_ref = "refs/remotes/$id";
2838 if (::verify_ref("$new_ref^0")) {
2839 print STDERR "W: $orig_ref is probably an old ",
2840 "branch used by an ancient version of ",
2841 "git-svn.\n",
2842 "However, $new_ref also exists.\n",
2843 "We will not be able ",
2844 "to use this branch until this ",
2845 "ambiguity is resolved.\n";
2846 next;
2847 }
2848 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2849 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2850 command_noisy('update-ref', $new_ref, $orig_ref);
2851 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2852 $migrated++;
2853 }
2854 command_close_pipe($fh, $ctx);
2855 print STDERR "Done migrating from v0 layout...\n" if $migrated;
2856 $migrated;
2857 }
2858
2859 sub migrate_from_v1 {
2860 my $git_dir = $ENV{GIT_DIR};
2861 my $migrated = 0;
2862 return $migrated unless -d $git_dir;
2863 my $svn_dir = "$git_dir/svn";
2864
2865 # just in case somebody used 'svn' as their $id at some point...
2866 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2867
2868 print STDERR "Migrating from a git-svn v1 layout...\n";
2869 mkpath([$svn_dir]);
2870 print STDERR "Data from a previous version of git-svn exists, but\n\t",
2871 "$svn_dir\n\t(required for this version ",
2872 "($::VERSION) of git-svn) does not. exist\n";
2873 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2874 while (<$fh>) {
2875 my $x = $_;
2876 next unless $x =~ s#^refs/remotes/##;
2877 chomp $x;
2878 next unless -f "$git_dir/$x/info/url";
2879 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2880 next unless $u;
2881 my $dn = dirname("$git_dir/svn/$x");
2882 mkpath([$dn]) unless -d $dn;
2883 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2884 mkpath(["$git_dir/svn/svn"]);
2885 print STDERR " - $git_dir/$x/info => ",
2886 "$git_dir/svn/$x/info\n";
2887 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2888 croak "$!: $x";
2889 # don't worry too much about these, they probably
2890 # don't exist with repos this old (save for index,
2891 # and we can easily regenerate that)
2892 foreach my $f (qw/unhandled.log index .rev_db/) {
2893 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2894 }
2895 } else {
2896 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2897 rename "$git_dir/$x", "$git_dir/svn/$x" or
2898 croak "$!: $x";
2899 }
2900 $migrated++;
2901 }
2902 command_close_pipe($fh, $ctx);
2903 print STDERR "Done migrating from a git-svn v1 layout\n";
2904 $migrated;
2905 }
2906
2907 sub read_old_urls {
2908 my ($l_map, $pfx, $path) = @_;
2909 my @dir;
2910 foreach (<$path/*>) {
2911 if (-r "$_/info/url") {
2912 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2913 my $ref_id = $pfx . basename $_;
2914 my $url = ::file_to_s("$_/info/url");
2915 $l_map->{$ref_id} = $url;
2916 } elsif (-d $_) {
2917 push @dir, $_;
2918 }
2919 }
2920 foreach (@dir) {
2921 my $x = $_;
2922 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2923 read_old_urls($l_map, $x, $_);
2924 }
2925 }
2926
2927 sub migrate_from_v2 {
2928 my @cfg = command(qw/config -l/);
2929 return if grep /^svn-remote\..+\.url=/, @cfg;
2930 my %l_map;
2931 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2932 my $migrated = 0;
2933
2934 foreach my $ref_id (sort keys %l_map) {
2935 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2936 $migrated++;
2937 }
2938 $migrated;
2939 }
2940
2941 sub minimize_connections {
2942 my $r = Git::SVN::read_all_remotes();
2943 my $new_urls = {};
2944 my $root_repos = {};
2945 foreach my $repo_id (keys %$r) {
2946 my $url = $r->{$repo_id}->{url} or next;
2947 my $fetch = $r->{$repo_id}->{fetch} or next;
2948 my $ra = Git::SVN::Ra->new($url);
2949
2950 # skip existing cases where we already connect to the root
2951 if (($ra->{url} eq $ra->{repos_root}) ||
2952 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2953 $repo_id)) {
2954 $root_repos->{$ra->{url}} = $repo_id;
2955 next;
2956 }
2957
2958 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2959 my $root_path = $ra->{url};
2960 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2961 foreach my $path (keys %$fetch) {
2962 my $ref_id = $fetch->{$path};
2963 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2964
2965 # make sure we can read when connecting to
2966 # a higher level of a repository
2967 my ($last_rev, undef) = $gs->last_rev_commit;
2968 if (!defined $last_rev) {
2969 $last_rev = eval {
2970 $root_ra->get_latest_revnum;
2971 };
2972 next if $@;
2973 }
2974 my $new = $root_path;
2975 $new .= length $path ? "/$path" : '';
2976 eval {
2977 $root_ra->get_log([$new], $last_rev, $last_rev,
2978 0, 0, 1, sub { });
2979 };
2980 next if $@;
2981 $new_urls->{$ra->{repos_root}}->{$new} =
2982 { ref_id => $ref_id,
2983 old_repo_id => $repo_id,
2984 old_path => $path };
2985 }
2986 }
2987
2988 my @emptied;
2989 foreach my $url (keys %$new_urls) {
2990 # see if we can re-use an existing [svn-remote "repo_id"]
2991 # instead of creating a(n ugly) new section:
2992 my $repo_id = $root_repos->{$url} ||
2993 Git::SVN::sanitize_remote_name($url);
2994
2995 my $fetch = $new_urls->{$url};
2996 foreach my $path (keys %$fetch) {
2997 my $x = $fetch->{$path};
2998 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2999 my $pfx = "svn-remote.$x->{old_repo_id}";
3000
3001 my $old_fetch = quotemeta("$x->{old_path}:".
3002 "refs/remotes/$x->{ref_id}");
3003 command_noisy(qw/config --unset/,
3004 "$pfx.fetch", '^'. $old_fetch . '$');
3005 delete $r->{$x->{old_repo_id}}->
3006 {fetch}->{$x->{old_path}};
3007 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3008 command_noisy(qw/config --unset/,
3009 "$pfx.url");
3010 push @emptied, $x->{old_repo_id}
3011 }
3012 }
3013 }
3014 if (@emptied) {
3015 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3016 "$ENV{GIT_DIR}/config";
3017 print STDERR <<EOF;
3018 The following [svn-remote] sections in your config file ($file) are empty
3019 and can be safely removed:
3020 EOF
3021 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3022 }
3023 }
3024
3025 sub migration_check {
3026 migrate_from_v0();
3027 migrate_from_v1();
3028 migrate_from_v2();
3029 minimize_connections() if $_minimize;
3030 }
3031
3032 package Git::IndexInfo;
3033 use strict;
3034 use warnings;
3035 use Git qw/command_input_pipe command_close_pipe/;
3036
3037 sub new {
3038 my ($class) = @_;
3039 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
3040 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
3041 }
3042
3043 sub remove {
3044 my ($self, $path) = @_;
3045 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
3046 return ++$self->{nr};
3047 }
3048 undef;
3049 }
3050
3051 sub update {
3052 my ($self, $mode, $hash, $path) = @_;
3053 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
3054 return ++$self->{nr};
3055 }
3056 undef;
3057 }
3058
3059 sub DESTROY {
3060 my ($self) = @_;
3061 command_close_pipe($self->{gui}, $self->{ctx});
3062 }
3063
3064 __END__
3065
3066 Data structures:
3067
3068 $log_entry hashref as returned by libsvn_log_entry()
3069 {
3070 log => 'whitespace-formatted log entry
3071 ', # trailing newline is preserved
3072 revision => '8', # integer
3073 date => '2004-02-24T17:01:44.108345Z', # commit date
3074 author => 'committer name'
3075 };
3076
3077
3078 # this is generated by generate_diff();
3079 @mods = array of diff-index line hashes, each element represents one line
3080 of diff-index output
3081
3082 diff-index line ($m hash)
3083 {
3084 mode_a => first column of diff-index output, no leading ':',
3085 mode_b => second column of diff-index output,
3086 sha1_b => sha1sum of the final blob,
3087 chg => change type [MCRADT],
3088 file_a => original file name of a file (iff chg is 'C' or 'R')
3089 file_b => new/current file name of a file (any chg)
3090 }
3091 ;
3092
3093 # retval of read_url_paths{,_all}();
3094 $l_map = {
3095 # repository root url
3096 'https://svn.musicpd.org' => {
3097 # repository path # GIT_SVN_ID
3098 'mpd/trunk' => 'trunk',
3099 'mpd/tags/0.11.5' => 'tags/0.11.5',
3100 },
3101 }
3102
3103 Notes:
3104 I don't trust the each() function on unless I created %hash myself
3105 because the internal iterator may not have started at base.
git with Jakub Narębski modifications