share/vim/vim73/ftplugin/xhtml.vim

   1 " Vim filetype plugin file
   2 " Language:     xhtml
   3 " Maintainer:   Dan Sharp <dwsharp at users dot sourceforge dot net>
   4 " Last Changed: 20 Jan 2009
   5 " URL:          http://dwsharp.users.sourceforge.net/vim/ftplugin
   6
   7 if exists("b:did_ftplugin") | finish | endif
   8
   9 " Make sure the continuation lines below do not cause problems in
  10 " compatibility mode.
  11 let s:save_cpo = &cpo
  12 set cpo-=C
  13
  14 " Define some defaults in case the included ftplugins don't set them.
  15 let s:undo_ftplugin = ""
  16 let s:browsefilter = "HTML Files (*.html, *.htm)\t*.html;*.htm\n" .
  17             \        "XML Files (*.xml)\t*.xml\n" .
  18             \        "All Files (*.*)\t*.*\n"
  19 let s:match_words = ""
  20
  21 runtime! ftplugin/xml.vim ftplugin/xml_*.vim ftplugin/xml/*.vim
  22 unlet b:did_ftplugin
  23
  24 " Override our defaults if these were set by an included ftplugin.
  25 if exists("b:undo_ftplugin")
  26     let s:undo_ftplugin = b:undo_ftplugin
  27     unlet b:undo_ftplugin
  28 endif
  29 if exists("b:browsefilter")
  30     let s:browsefilter = b:browsefilter
  31     unlet b:browsefilter
  32 endif
  33 if exists("b:match_words")
  34     let s:match_words = b:match_words
  35     unlet b:match_words
  36 endif
  37
  38 runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
  39 let b:did_ftplugin = 1
  40
  41 " Combine the new set of values with those previously included.
  42 if exists("b:undo_ftplugin")
  43     let s:undo_ftplugin = b:undo_ftplugin . " | " . s:undo_ftplugin
  44 endif
  45 if exists("b:browsefilter")
  46     let s:browsefilter = b:browsefilter . s:browsefilter
  47 endif
  48 if exists("b:match_words")
  49     let s:match_words = b:match_words . "," . s:match_words
  50 endif
  51
  52 " Load the combined list of match_words for matchit.vim
  53 if exists("loaded_matchit")
  54     let b:match_words = s:match_words
  55 endif
  56
  57 " Change the :browse e filter to primarily show tcsh-related files.
  58 if has("gui_win32")
  59     let  b:browsefilter="XHTML files (*.xhtml, *.xhtm)\t*.xhtml;*.xhtm\n" . s:browsefilter
  60 endif
  61
  62 " Undo the stuff we changed.
  63 let b:undo_ftplugin = "unlet! b:browsefilter b:match_words | " . s:undo_ftplugin
  64
  65 " Restore the saved compatibility options.
  66 let &cpo = s:save_cpo