?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Update draft release notes to 1.6.1
[git/jnareb-git.git] / git-svn.perl
blob5702b100f17d32c4d370d2b29374390ad0f03520
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision $_repository
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose,
69 $_git_format, $_commit_url, $_tag);
70 $Git::SVN::_follow_parent = 1;
71 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
72 'config-dir=s' => \$Git::SVN::Ra::config_dir,
73 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
74 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
75 'authors-file|A=s' => \$_authors,
76 'repack:i' => \$Git::SVN::_repack,
77 'noMetadata' => \$Git::SVN::_no_metadata,
78 'useSvmProps' => \$Git::SVN::_use_svm_props,
79 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
80 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
81 'no-checkout' => \$_no_checkout,
82 'quiet|q' => \$_q,
83 'repack-flags|repack-args|repack-opts=s' =>
84 \$Git::SVN::_repack_flags,
85 'use-log-author' => \$Git::SVN::_use_log_author,
86 'add-author-from' => \$Git::SVN::_add_author_from,
87 %remote_opts );
88
89 my ($_trunk, $_tags, $_branches, $_stdlayout);
90 my %icv;
91 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
92 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
93 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
94 'stdlayout|s' => \$_stdlayout,
95 'minimize-url|m' => \$Git::SVN::_minimize_url,
96 'no-metadata' => sub { $icv{noMetadata} = 1 },
97 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
98 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
99 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
100 %remote_opts );
101 my %cmt_opts = ( 'edit|e' => \$_edit,
102 'rmdir' => \$SVN::Git::Editor::_rmdir,
103 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
104 'l=i' => \$SVN::Git::Editor::_rename_limit,
105 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
106 );
107
108 my %cmd = (
109 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
110 { 'revision|r=s' => \$_revision,
111 'fetch-all|all' => \$_fetch_all,
112 %fc_opts } ],
113 clone => [ \&cmd_clone, "Initialize and fetch revisions",
114 { 'revision|r=s' => \$_revision,
115 %fc_opts, %init_opts } ],
116 init => [ \&cmd_init, "Initialize a repo for tracking" .
117 " (requires URL argument)",
118 \%init_opts ],
119 'multi-init' => [ \&cmd_multi_init,
120 "Deprecated alias for ".
121 "'$0 init -T<trunk> -b<branches> -t<tags>'",
122 \%init_opts ],
123 dcommit => [ \&cmd_dcommit,
124 'Commit several diffs to merge with upstream',
125 { 'merge|m|M' => \$_merge,
126 'strategy|s=s' => \$_strategy,
127 'verbose|v' => \$_verbose,
128 'dry-run|n' => \$_dry_run,
129 'fetch-all|all' => \$_fetch_all,
130 'commit-url=s' => \$_commit_url,
131 'revision|r=i' => \$_revision,
132 'no-rebase' => \$_no_rebase,
133 %cmt_opts, %fc_opts } ],
134 branch => [ \&cmd_branch,
135 'Create a branch in the SVN repository',
136 { 'message|m=s' => \$_message,
137 'dry-run|n' => \$_dry_run,
138 'tag|t' => \$_tag } ],
139 tag => [ sub { $_tag = 1; cmd_branch(@_) },
140 'Create a tag in the SVN repository',
141 { 'message|m=s' => \$_message,
142 'dry-run|n' => \$_dry_run } ],
143 'set-tree' => [ \&cmd_set_tree,
144 "Set an SVN repository to a git tree-ish",
145 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
146 'create-ignore' => [ \&cmd_create_ignore,
147 'Create a .gitignore per svn:ignore',
148 { 'revision|r=i' => \$_revision
149 } ],
150 'propget' => [ \&cmd_propget,
151 'Print the value of a property on a file or directory',
152 { 'revision|r=i' => \$_revision } ],
153 'proplist' => [ \&cmd_proplist,
154 'List all properties of a file or directory',
155 { 'revision|r=i' => \$_revision } ],
156 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
157 { 'revision|r=i' => \$_revision
158 } ],
159 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
160 { 'revision|r=i' => \$_revision
161 } ],
162 'multi-fetch' => [ \&cmd_multi_fetch,
163 "Deprecated alias for $0 fetch --all",
164 { 'revision|r=s' => \$_revision, %fc_opts } ],
165 'migrate' => [ sub { },
166 # no-op, we automatically run this anyways,
167 'Migrate configuration/metadata/layout from
168 previous versions of git-svn',
169 { 'minimize' => \$Git::SVN::Migration::_minimize,
170 %remote_opts } ],
171 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
172 { 'limit=i' => \$Git::SVN::Log::limit,
173 'revision|r=s' => \$_revision,
174 'verbose|v' => \$Git::SVN::Log::verbose,
175 'incremental' => \$Git::SVN::Log::incremental,
176 'oneline' => \$Git::SVN::Log::oneline,
177 'show-commit' => \$Git::SVN::Log::show_commit,
178 'non-recursive' => \$Git::SVN::Log::non_recursive,
179 'authors-file|A=s' => \$_authors,
180 'color' => \$Git::SVN::Log::color,
181 'pager=s' => \$Git::SVN::Log::pager
182 } ],
183 'find-rev' => [ \&cmd_find_rev,
184 "Translate between SVN revision numbers and tree-ish",
185 {} ],
186 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
187 { 'merge|m|M' => \$_merge,
188 'verbose|v' => \$_verbose,
189 'strategy|s=s' => \$_strategy,
190 'local|l' => \$_local,
191 'fetch-all|all' => \$_fetch_all,
192 'dry-run|n' => \$_dry_run,
193 %fc_opts } ],
194 'commit-diff' => [ \&cmd_commit_diff,
195 'Commit a diff between two trees',
196 { 'message|m=s' => \$_message,
197 'file|F=s' => \$_file,
198 'revision|r=s' => \$_revision,
199 %cmt_opts } ],
200 'info' => [ \&cmd_info,
201 "Show info about the latest SVN revision
202 on the current branch",
203 { 'url' => \$_url, } ],
204 'blame' => [ \&Git::SVN::Log::cmd_blame,
205 "Show what revision and author last modified each line of a file",
206 { 'git-format' => \$_git_format } ],
207 );
208
209 my $cmd;
210 for (my $i = 0; $i < @ARGV; $i++) {
211 if (defined $cmd{$ARGV[$i]}) {
212 $cmd = $ARGV[$i];
213 splice @ARGV, $i, 1;
214 last;
215 }
216 };
217
218 # make sure we're always running at the top-level working directory
219 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
220 unless (-d $ENV{GIT_DIR}) {
221 if ($git_dir_user_set) {
222 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
223 "but it is not a directory\n";
224 }
225 my $git_dir = delete $ENV{GIT_DIR};
226 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
227 unless (length $cdup) {
228 die "Already at toplevel, but $git_dir ",
229 "not found '$cdup'\n";
230 }
231 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
232 unless (-d $git_dir) {
233 die "$git_dir still not found after going to ",
234 "'$cdup'\n";
235 }
236 $ENV{GIT_DIR} = $git_dir;
237 }
238 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
239 }
240
241 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
242
243 read_repo_config(\%opts);
244 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
245 Getopt::Long::Configure('pass_through');
246 }
247 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
248 'minimize-connections' => \$Git::SVN::Migration::_minimize,
249 'id|i=s' => \$Git::SVN::default_ref_id,
250 'svn-remote|remote|R=s' => sub {
251 $Git::SVN::no_reuse_existing = 1;
252 $Git::SVN::default_repo_id = $_[1] });
253 exit 1 if (!$rv && $cmd && $cmd ne 'log');
254
255 usage(0) if $_help;
256 version() if $_version;
257 usage(1) unless defined $cmd;
258 load_authors() if $_authors;
259
260 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
261 Git::SVN::Migration::migration_check();
262 }
263 Git::SVN::init_vars();
264 eval {
265 Git::SVN::verify_remotes_sanity();
266 $cmd{$cmd}->[0]->(@ARGV);
267 };
268 fatal $@ if $@;
269 post_fetch_checkout();
270 exit 0;
271
272 ####################### primary functions ######################
273 sub usage {
274 my $exit = shift || 0;
275 my $fd = $exit ? \*STDERR : \*STDOUT;
276 print $fd <<"";
277 git-svn - bidirectional operations between a single Subversion tree and git
278 Usage: git svn <command> [options] [arguments]\n
279
280 print $fd "Available commands:\n" unless $cmd;
281
282 foreach (sort keys %cmd) {
283 next if $cmd && $cmd ne $_;
284 next if /^multi-/; # don't show deprecated commands
285 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
286 foreach (sort keys %{$cmd{$_}->[2]}) {
287 # mixed-case options are for .git/config only
288 next if /[A-Z]/ && /^[a-z]+$/i;
289 # prints out arguments as they should be passed:
290 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
291 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
292 "--$_" : "-$_" }
293 split /\|/,$_)," $x\n";
294 }
295 }
296 print $fd <<"";
297 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
298 arbitrary identifier if you're tracking multiple SVN branches/repositories in
299 one git repository and want to keep them separate. See git-svn(1) for more
300 information.
301
302 exit $exit;
303 }
304
305 sub version {
306 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
307 exit 0;
308 }
309
310 sub do_git_init_db {
311 unless (-d $ENV{GIT_DIR}) {
312 my @init_db = ('init');
313 push @init_db, "--template=$_template" if defined $_template;
314 if (defined $_shared) {
315 if ($_shared =~ /[a-z]/) {
316 push @init_db, "--shared=$_shared";
317 } else {
318 push @init_db, "--shared";
319 }
320 }
321 command_noisy(@init_db);
322 $_repository = Git->repository(Repository => ".git");
323 }
324 my $set;
325 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
326 foreach my $i (keys %icv) {
327 die "'$set' and '$i' cannot both be set\n" if $set;
328 next unless defined $icv{$i};
329 command_noisy('config', "$pfx.$i", $icv{$i});
330 $set = $i;
331 }
332 }
333
334 sub init_subdir {
335 my $repo_path = shift or return;
336 mkpath([$repo_path]) unless -d $repo_path;
337 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
338 $ENV{GIT_DIR} = '.git';
339 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
340 }
341
342 sub cmd_clone {
343 my ($url, $path) = @_;
344 if (!defined $path &&
345 (defined $_trunk || defined $_branches || defined $_tags ||
346 defined $_stdlayout) &&
347 $url !~ m#^[a-z\+]+://#) {
348 $path = $url;
349 }
350 $path = basename($url) if !defined $path || !length $path;
351 cmd_init($url, $path);
352 Git::SVN::fetch_all($Git::SVN::default_repo_id);
353 }
354
355 sub cmd_init {
356 if (defined $_stdlayout) {
357 $_trunk = 'trunk' if (!defined $_trunk);
358 $_tags = 'tags' if (!defined $_tags);
359 $_branches = 'branches' if (!defined $_branches);
360 }
361 if (defined $_trunk || defined $_branches || defined $_tags) {
362 return cmd_multi_init(@_);
363 }
364 my $url = shift or die "SVN repository location required ",
365 "as a command-line argument\n";
366 init_subdir(@_);
367 do_git_init_db();
368
369 Git::SVN->init($url);
370 }
371
372 sub cmd_fetch {
373 if (grep /^\d+=./, @_) {
374 die "'<rev>=<commit>' fetch arguments are ",
375 "no longer supported.\n";
376 }
377 my ($remote) = @_;
378 if (@_ > 1) {
379 die "Usage: $0 fetch [--all] [svn-remote]\n";
380 }
381 $remote ||= $Git::SVN::default_repo_id;
382 if ($_fetch_all) {
383 cmd_multi_fetch();
384 } else {
385 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
386 }
387 }
388
389 sub cmd_set_tree {
390 my (@commits) = @_;
391 if ($_stdin || !@commits) {
392 print "Reading from stdin...\n";
393 @commits = ();
394 while (<STDIN>) {
395 if (/\b($sha1_short)\b/o) {
396 unshift @commits, $1;
397 }
398 }
399 }
400 my @revs;
401 foreach my $c (@commits) {
402 my @tmp = command('rev-parse',$c);
403 if (scalar @tmp == 1) {
404 push @revs, $tmp[0];
405 } elsif (scalar @tmp > 1) {
406 push @revs, reverse(command('rev-list',@tmp));
407 } else {
408 fatal "Failed to rev-parse $c";
409 }
410 }
411 my $gs = Git::SVN->new;
412 my ($r_last, $cmt_last) = $gs->last_rev_commit;
413 $gs->fetch;
414 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
415 fatal "There are new revisions that were fetched ",
416 "and need to be merged (or acknowledged) ",
417 "before committing.\nlast rev: $r_last\n",
418 " current: $gs->{last_rev}";
419 }
420 $gs->set_tree($_) foreach @revs;
421 print "Done committing ",scalar @revs," revisions to SVN\n";
422 unlink $gs->{index};
423 }
424
425 sub cmd_dcommit {
426 my $head = shift;
427 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
428 'Cannot dcommit with a dirty index. Commit your changes first, '
429 . "or stash them with `git stash'.\n";
430 $head ||= 'HEAD';
431 my @refs;
432 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
433 unless ($gs) {
434 die "Unable to determine upstream SVN information from ",
435 "$head history.\nPerhaps the repository is empty.";
436 }
437 $url = defined $_commit_url ? $_commit_url : $gs->full_url;
438 my $last_rev = $_revision if defined $_revision;
439 if ($url) {
440 print "Committing to $url ...\n";
441 }
442 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
443 if ($_no_rebase && scalar(@$linear_refs) > 1) {
444 warn "Attempting to commit more than one change while ",
445 "--no-rebase is enabled.\n",
446 "If these changes depend on each other, re-running ",
447 "without --no-rebase may be required."
448 }
449 my $expect_url = $url;
450 Git::SVN::remove_username($expect_url);
451 while (1) {
452 my $d = shift @$linear_refs or last;
453 unless (defined $last_rev) {
454 (undef, $last_rev, undef) = cmt_metadata("$d~1");
455 unless (defined $last_rev) {
456 fatal "Unable to extract revision information ",
457 "from commit $d~1";
458 }
459 }
460 if ($_dry_run) {
461 print "diff-tree $d~1 $d\n";
462 } else {
463 my $cmt_rev;
464 my %ed_opts = ( r => $last_rev,
465 log => get_commit_entry($d)->{log},
466 ra => Git::SVN::Ra->new($url),
467 config => SVN::Core::config_get_config(
468 $Git::SVN::Ra::config_dir
469 ),
470 tree_a => "$d~1",
471 tree_b => $d,
472 editor_cb => sub {
473 print "Committed r$_[0]\n";
474 $cmt_rev = $_[0];
475 },
476 svn_path => '');
477 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
478 print "No changes\n$d~1 == $d\n";
479 } elsif ($parents->{$d} && @{$parents->{$d}}) {
480 $gs->{inject_parents_dcommit}->{$cmt_rev} =
481 $parents->{$d};
482 }
483 $_fetch_all ? $gs->fetch_all : $gs->fetch;
484 $last_rev = $cmt_rev;
485 next if $_no_rebase;
486
487 # we always want to rebase against the current HEAD,
488 # not any head that was passed to us
489 my @diff = command('diff-tree', $d,
490 $gs->refname, '--');
491 my @finish;
492 if (@diff) {
493 @finish = rebase_cmd();
494 print STDERR "W: $d and ", $gs->refname,
495 " differ, using @finish:\n",
496 join("\n", @diff), "\n";
497 } else {
498 print "No changes between current HEAD and ",
499 $gs->refname,
500 "\nResetting to the latest ",
501 $gs->refname, "\n";
502 @finish = qw/reset --mixed/;
503 }
504 command_noisy(@finish, $gs->refname);
505 if (@diff) {
506 @refs = ();
507 my ($url_, $rev_, $uuid_, $gs_) =
508 working_head_info($head, \@refs);
509 my ($linear_refs_, $parents_) =
510 linearize_history($gs_, \@refs);
511 if (scalar(@$linear_refs) !=
512 scalar(@$linear_refs_)) {
513 fatal "# of revisions changed ",
514 "\nbefore:\n",
515 join("\n", @$linear_refs),
516 "\n\nafter:\n",
517 join("\n", @$linear_refs_), "\n",
518 'If you are attempting to commit ',
519 "merges, try running:\n\t",
520 'git rebase --interactive',
521 '--preserve-merges ',
522 $gs->refname,
523 "\nBefore dcommitting";
524 }
525 if ($url_ ne $expect_url) {
526 fatal "URL mismatch after rebase: ",
527 "$url_ != $expect_url";
528 }
529 if ($uuid_ ne $uuid) {
530 fatal "uuid mismatch after rebase: ",
531 "$uuid_ != $uuid";
532 }
533 # remap parents
534 my (%p, @l, $i);
535 for ($i = 0; $i < scalar @$linear_refs; $i++) {
536 my $new = $linear_refs_->[$i] or next;
537 $p{$new} =
538 $parents->{$linear_refs->[$i]};
539 push @l, $new;
540 }
541 $parents = \%p;
542 $linear_refs = \@l;
543 }
544 }
545 }
546 unlink $gs->{index};
547 }
548
549 sub cmd_branch {
550 my ($branch_name, $head) = @_;
551
552 unless (defined $branch_name && length $branch_name) {
553 die(($_tag ? "tag" : "branch") . " name required\n");
554 }
555 $head ||= 'HEAD';
556
557 my ($src, $rev, undef, $gs) = working_head_info($head);
558
559 my $remote = Git::SVN::read_all_remotes()->{svn};
560 my $glob = $remote->{ $_tag ? 'tags' : 'branches' };
561 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
562 my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
563
564 my $ctx = SVN::Client->new(
565 auth => Git::SVN::Ra::_auth_providers(),
566 log_msg => sub {
567 ${ $_[0] } = defined $_message
568 ? $_message
569 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
570 . $branch_name;
571 },
572 );
573
574 eval {
575 $ctx->ls($dst, 'HEAD', 0);
576 } and die "branch ${branch_name} already exists\n";
577
578 print "Copying ${src} at r${rev} to ${dst}...\n";
579 $ctx->copy($src, $rev, $dst)
580 unless $_dry_run;
581
582 $gs->fetch_all;
583 }
584
585 sub cmd_find_rev {
586 my $revision_or_hash = shift or die "SVN or git revision required ",
587 "as a command-line argument\n";
588 my $result;
589 if ($revision_or_hash =~ /^r\d+$/) {
590 my $head = shift;
591 $head ||= 'HEAD';
592 my @refs;
593 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
594 unless ($gs) {
595 die "Unable to determine upstream SVN information from ",
596 "$head history\n";
597 }
598 my $desired_revision = substr($revision_or_hash, 1);
599 $result = $gs->rev_map_get($desired_revision, $uuid);
600 } else {
601 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
602 $result = $rev;
603 }
604 print "$result\n" if $result;
605 }
606
607 sub cmd_rebase {
608 command_noisy(qw/update-index --refresh/);
609 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
610 unless ($gs) {
611 die "Unable to determine upstream SVN information from ",
612 "working tree history\n";
613 }
614 if ($_dry_run) {
615 print "Remote Branch: " . $gs->refname . "\n";
616 print "SVN URL: " . $url . "\n";
617 return;
618 }
619 if (command(qw/diff-index HEAD --/)) {
620 print STDERR "Cannot rebase with uncommited changes:\n";
621 command_noisy('status');
622 exit 1;
623 }
624 unless ($_local) {
625 # rebase will checkout for us, so no need to do it explicitly
626 $_no_checkout = 'true';
627 $_fetch_all ? $gs->fetch_all : $gs->fetch;
628 }
629 command_noisy(rebase_cmd(), $gs->refname);
630 }
631
632 sub cmd_show_ignore {
633 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
634 $gs ||= Git::SVN->new;
635 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
636 $gs->prop_walk($gs->{path}, $r, sub {
637 my ($gs, $path, $props) = @_;
638 print STDOUT "\n# $path\n";
639 my $s = $props->{'svn:ignore'} or return;
640 $s =~ s/[\r\n]+/\n/g;
641 chomp $s;
642 $s =~ s#^#$path#gm;
643 print STDOUT "$s\n";
644 });
645 }
646
647 sub cmd_show_externals {
648 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
649 $gs ||= Git::SVN->new;
650 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
651 $gs->prop_walk($gs->{path}, $r, sub {
652 my ($gs, $path, $props) = @_;
653 print STDOUT "\n# $path\n";
654 my $s = $props->{'svn:externals'} or return;
655 $s =~ s/[\r\n]+/\n/g;
656 chomp $s;
657 $s =~ s#^#$path#gm;
658 print STDOUT "$s\n";
659 });
660 }
661
662 sub cmd_create_ignore {
663 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
664 $gs ||= Git::SVN->new;
665 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
666 $gs->prop_walk($gs->{path}, $r, sub {
667 my ($gs, $path, $props) = @_;
668 # $path is of the form /path/to/dir/
669 my $ignore = '.' . $path . '.gitignore';
670 my $s = $props->{'svn:ignore'} or return;
671 open(GITIGNORE, '>', $ignore)
672 or fatal("Failed to open `$ignore' for writing: $!");
673 $s =~ s/[\r\n]+/\n/g;
674 chomp $s;
675 # Prefix all patterns so that the ignore doesn't apply
676 # to sub-directories.
677 $s =~ s#^#/#gm;
678 print GITIGNORE "$s\n";
679 close(GITIGNORE)
680 or fatal("Failed to close `$ignore': $!");
681 command_noisy('add', '-f', $ignore);
682 });
683 }
684
685 sub canonicalize_path {
686 my ($path) = @_;
687 my $dot_slash_added = 0;
688 if (substr($path, 0, 1) ne "/") {
689 $path = "./" . $path;
690 $dot_slash_added = 1;
691 }
692 # File::Spec->canonpath doesn't collapse x/../y into y (for a
693 # good reason), so let's do this manually.
694 $path =~ s#/+#/#g;
695 $path =~ s#/\.(?:/|$)#/#g;
696 $path =~ s#/[^/]+/\.\.##g;
697 $path =~ s#/$##g;
698 $path =~ s#^\./## if $dot_slash_added;
699 $path =~ s#^/##;
700 $path =~ s#^\.$##;
701 return $path;
702 }
703
704 # get_svnprops(PATH)
705 # ------------------
706 # Helper for cmd_propget and cmd_proplist below.
707 sub get_svnprops {
708 my $path = shift;
709 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
710 $gs ||= Git::SVN->new;
711
712 # prefix THE PATH by the sub-directory from which the user
713 # invoked us.
714 $path = $cmd_dir_prefix . $path;
715 fatal("No such file or directory: $path") unless -e $path;
716 my $is_dir = -d $path ? 1 : 0;
717 $path = $gs->{path} . '/' . $path;
718
719 # canonicalize the path (otherwise libsvn will abort or fail to
720 # find the file)
721 $path = canonicalize_path($path);
722
723 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
724 my $props;
725 if ($is_dir) {
726 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
727 }
728 else {
729 (undef, $props) = $gs->ra->get_file($path, $r, undef);
730 }
731 return $props;
732 }
733
734 # cmd_propget (PROP, PATH)
735 # ------------------------
736 # Print the SVN property PROP for PATH.
737 sub cmd_propget {
738 my ($prop, $path) = @_;
739 $path = '.' if not defined $path;
740 usage(1) if not defined $prop;
741 my $props = get_svnprops($path);
742 if (not defined $props->{$prop}) {
743 fatal("`$path' does not have a `$prop' SVN property.");
744 }
745 print $props->{$prop} . "\n";
746 }
747
748 # cmd_proplist (PATH)
749 # -------------------
750 # Print the list of SVN properties for PATH.
751 sub cmd_proplist {
752 my $path = shift;
753 $path = '.' if not defined $path;
754 my $props = get_svnprops($path);
755 print "Properties on '$path':\n";
756 foreach (sort keys %{$props}) {
757 print " $_\n";
758 }
759 }
760
761 sub cmd_multi_init {
762 my $url = shift;
763 unless (defined $_trunk || defined $_branches || defined $_tags) {
764 usage(1);
765 }
766
767 # there are currently some bugs that prevent multi-init/multi-fetch
768 # setups from working well without this.
769 $Git::SVN::_minimize_url = 1;
770
771 $_prefix = '' unless defined $_prefix;
772 if (defined $url) {
773 $url =~ s#/+$##;
774 init_subdir(@_);
775 }
776 do_git_init_db();
777 if (defined $_trunk) {
778 my $trunk_ref = $_prefix . 'trunk';
779 # try both old-style and new-style lookups:
780 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
781 unless ($gs_trunk) {
782 my ($trunk_url, $trunk_path) =
783 complete_svn_url($url, $_trunk);
784 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
785 undef, $trunk_ref);
786 }
787 }
788 return unless defined $_branches || defined $_tags;
789 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
790 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
791 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
792 }
793
794 sub cmd_multi_fetch {
795 my $remotes = Git::SVN::read_all_remotes();
796 foreach my $repo_id (sort keys %$remotes) {
797 if ($remotes->{$repo_id}->{url}) {
798 Git::SVN::fetch_all($repo_id, $remotes);
799 }
800 }
801 }
802
803 # this command is special because it requires no metadata
804 sub cmd_commit_diff {
805 my ($ta, $tb, $url) = @_;
806 my $usage = "Usage: $0 commit-diff -r<revision> ".
807 "<tree-ish> <tree-ish> [<URL>]";
808 fatal($usage) if (!defined $ta || !defined $tb);
809 my $svn_path = '';
810 if (!defined $url) {
811 my $gs = eval { Git::SVN->new };
812 if (!$gs) {
813 fatal("Needed URL or usable git-svn --id in ",
814 "the command-line\n", $usage);
815 }
816 $url = $gs->{url};
817 $svn_path = $gs->{path};
818 }
819 unless (defined $_revision) {
820 fatal("-r|--revision is a required argument\n", $usage);
821 }
822 if (defined $_message && defined $_file) {
823 fatal("Both --message/-m and --file/-F specified ",
824 "for the commit message.\n",
825 "I have no idea what you mean");
826 }
827 if (defined $_file) {
828 $_message = file_to_s($_file);
829 } else {
830 $_message ||= get_commit_entry($tb)->{log};
831 }
832 my $ra ||= Git::SVN::Ra->new($url);
833 my $r = $_revision;
834 if ($r eq 'HEAD') {
835 $r = $ra->get_latest_revnum;
836 } elsif ($r !~ /^\d+$/) {
837 die "revision argument: $r not understood by git-svn\n";
838 }
839 my %ed_opts = ( r => $r,
840 log => $_message,
841 ra => $ra,
842 tree_a => $ta,
843 tree_b => $tb,
844 editor_cb => sub { print "Committed r$_[0]\n" },
845 svn_path => $svn_path );
846 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
847 print "No changes\n$ta == $tb\n";
848 }
849 }
850
851 sub escape_uri_only {
852 my ($uri) = @_;
853 my @tmp;
854 foreach (split m{/}, $uri) {
855 s/([^\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
856 push @tmp, $_;
857 }
858 join('/', @tmp);
859 }
860
861 sub escape_url {
862 my ($url) = @_;
863 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
864 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
865 $url = "$scheme://$domain$uri";
866 }
867 $url;
868 }
869
870 sub cmd_info {
871 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
872 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
873 if (exists $_[1]) {
874 die "Too many arguments specified\n";
875 }
876
877 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
878
879 if (!$file_type && !$diff_status) {
880 print STDERR "svn: '$path' is not under version control\n";
881 exit 1;
882 }
883
884 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
885 unless ($gs) {
886 die "Unable to determine upstream SVN information from ",
887 "working tree history\n";
888 }
889
890 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
891 $path = "." if $path eq "";
892
893 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
894
895 if ($_url) {
896 print escape_url($full_url), "\n";
897 return;
898 }
899
900 my $result = "Path: $path\n";
901 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
902 $result .= "URL: " . escape_url($full_url) . "\n";
903
904 eval {
905 my $repos_root = $gs->repos_root;
906 Git::SVN::remove_username($repos_root);
907 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
908 };
909 if ($@) {
910 $result .= "Repository Root: (offline)\n";
911 }
912 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
913 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
914
915 $result .= "Node Kind: " .
916 ($file_type eq "dir" ? "directory" : "file") . "\n";
917
918 my $schedule = $diff_status eq "A"
919 ? "add"
920 : ($diff_status eq "D" ? "delete" : "normal");
921 $result .= "Schedule: $schedule\n";
922
923 if ($diff_status eq "A") {
924 print $result, "\n";
925 return;
926 }
927
928 my ($lc_author, $lc_rev, $lc_date_utc);
929 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
930 my $log = command_output_pipe(@args);
931 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
932 while (<$log>) {
933 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
934 $lc_author = $1;
935 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
936 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
937 (undef, $lc_rev, undef) = ::extract_metadata($1);
938 }
939 }
940 close $log;
941
942 Git::SVN::Log::set_local_timezone();
943
944 $result .= "Last Changed Author: $lc_author\n";
945 $result .= "Last Changed Rev: $lc_rev\n";
946 $result .= "Last Changed Date: " .
947 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
948
949 if ($file_type ne "dir") {
950 my $text_last_updated_date =
951 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
952 $result .=
953 "Text Last Updated: " .
954 Git::SVN::Log::format_svn_date($text_last_updated_date) .
955 "\n";
956 my $checksum;
957 if ($diff_status eq "D") {
958 my ($fh, $ctx) =
959 command_output_pipe(qw(cat-file blob), "HEAD:$path");
960 if ($file_type eq "link") {
961 my $file_name = <$fh>;
962 $checksum = md5sum("link $file_name");
963 } else {
964 $checksum = md5sum($fh);
965 }
966 command_close_pipe($fh, $ctx);
967 } elsif ($file_type eq "link") {
968 my $file_name =
969 command(qw(cat-file blob), "HEAD:$path");
970 $checksum =
971 md5sum("link " . $file_name);
972 } else {
973 open FILE, "<", $path or die $!;
974 $checksum = md5sum(\*FILE);
975 close FILE or die $!;
976 }
977 $result .= "Checksum: " . $checksum . "\n";
978 }
979
980 print $result, "\n";
981 }
982
983 ########################### utility functions #########################
984
985 sub rebase_cmd {
986 my @cmd = qw/rebase/;
987 push @cmd, '-v' if $_verbose;
988 push @cmd, qw/--merge/ if $_merge;
989 push @cmd, "--strategy=$_strategy" if $_strategy;
990 @cmd;
991 }
992
993 sub post_fetch_checkout {
994 return if $_no_checkout;
995 my $gs = $Git::SVN::_head or return;
996 return if verify_ref('refs/heads/master^0');
997
998 my $valid_head = verify_ref('HEAD^0');
999 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1000 return if ($valid_head || !verify_ref('HEAD^0'));
1001
1002 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1003 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1004 return if -f $index;
1005
1006 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1007 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1008 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1009 print STDERR "Checked out HEAD:\n ",
1010 $gs->full_url, " r", $gs->last_rev, "\n";
1011 }
1012
1013 sub complete_svn_url {
1014 my ($url, $path) = @_;
1015 $path =~ s#/+$##;
1016 if ($path !~ m#^[a-z\+]+://#) {
1017 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1018 fatal("E: '$path' is not a complete URL ",
1019 "and a separate URL is not specified");
1020 }
1021 return ($url, $path);
1022 }
1023 return ($path, '');
1024 }
1025
1026 sub complete_url_ls_init {
1027 my ($ra, $repo_path, $switch, $pfx) = @_;
1028 unless ($repo_path) {
1029 print STDERR "W: $switch not specified\n";
1030 return;
1031 }
1032 $repo_path =~ s#/+$##;
1033 if ($repo_path =~ m#^[a-z\+]+://#) {
1034 $ra = Git::SVN::Ra->new($repo_path);
1035 $repo_path = '';
1036 } else {
1037 $repo_path =~ s#^/+##;
1038 unless ($ra) {
1039 fatal("E: '$repo_path' is not a complete URL ",
1040 "and a separate URL is not specified");
1041 }
1042 }
1043 my $url = $ra->{url};
1044 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1045 my $k = "svn-remote.$gs->{repo_id}.url";
1046 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1047 if ($orig_url && ($orig_url ne $gs->{url})) {
1048 die "$k already set: $orig_url\n",
1049 "wanted to set to: $gs->{url}\n";
1050 }
1051 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1052 my $remote_path = "$ra->{svn_path}/$repo_path";
1053 $remote_path =~ s#/+#/#g;
1054 $remote_path =~ s#^/##g;
1055 $remote_path .= "/*" if $remote_path !~ /\*/;
1056 my ($n) = ($switch =~ /^--(\w+)/);
1057 if (length $pfx && $pfx !~ m#/$#) {
1058 die "--prefix='$pfx' must have a trailing slash '/'\n";
1059 }
1060 command_noisy('config',
1061 "svn-remote.$gs->{repo_id}.$n",
1062 "$remote_path:refs/remotes/$pfx*" .
1063 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1064 }
1065
1066 sub verify_ref {
1067 my ($ref) = @_;
1068 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1069 { STDERR => 0 }); };
1070 }
1071
1072 sub get_tree_from_treeish {
1073 my ($treeish) = @_;
1074 # $treeish can be a symbolic ref, too:
1075 my $type = command_oneline(qw/cat-file -t/, $treeish);
1076 my $expected;
1077 while ($type eq 'tag') {
1078 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1079 }
1080 if ($type eq 'commit') {
1081 $expected = (grep /^tree /, command(qw/cat-file commit/,
1082 $treeish))[0];
1083 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1084 die "Unable to get tree from $treeish\n" unless $expected;
1085 } elsif ($type eq 'tree') {
1086 $expected = $treeish;
1087 } else {
1088 die "$treeish is a $type, expected tree, tag or commit\n";
1089 }
1090 return $expected;
1091 }
1092
1093 sub get_commit_entry {
1094 my ($treeish) = shift;
1095 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1096 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1097 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1098 open my $log_fh, '>', $commit_editmsg or croak $!;
1099
1100 my $type = command_oneline(qw/cat-file -t/, $treeish);
1101 if ($type eq 'commit' || $type eq 'tag') {
1102 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1103 $type, $treeish);
1104 my $in_msg = 0;
1105 my $author;
1106 my $saw_from = 0;
1107 my $msgbuf = "";
1108 while (<$msg_fh>) {
1109 if (!$in_msg) {
1110 $in_msg = 1 if (/^\s*$/);
1111 $author = $1 if (/^author (.*>)/);
1112 } elsif (/^git-svn-id: /) {
1113 # skip this for now, we regenerate the
1114 # correct one on re-fetch anyways
1115 # TODO: set *:merge properties or like...
1116 } else {
1117 if (/^From:/ || /^Signed-off-by:/) {
1118 $saw_from = 1;
1119 }
1120 $msgbuf .= $_;
1121 }
1122 }
1123 $msgbuf =~ s/\s+$//s;
1124 if ($Git::SVN::_add_author_from && defined($author)
1125 && !$saw_from) {
1126 $msgbuf .= "\n\nFrom: $author";
1127 }
1128 print $log_fh $msgbuf or croak $!;
1129 command_close_pipe($msg_fh, $ctx);
1130 }
1131 close $log_fh or croak $!;
1132
1133 if ($_edit || ($type eq 'tree')) {
1134 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1135 # TODO: strip out spaces, comments, like git-commit.sh
1136 system($editor, $commit_editmsg);
1137 }
1138 rename $commit_editmsg, $commit_msg or croak $!;
1139 open $log_fh, '<', $commit_msg or croak $!;
1140 { local $/; chomp($log_entry{log} = <$log_fh>); }
1141 close $log_fh or croak $!;
1142 unlink $commit_msg;
1143 \%log_entry;
1144 }
1145
1146 sub s_to_file {
1147 my ($str, $file, $mode) = @_;
1148 open my $fd,'>',$file or croak $!;
1149 print $fd $str,"\n" or croak $!;
1150 close $fd or croak $!;
1151 chmod ($mode &~ umask, $file) if (defined $mode);
1152 }
1153
1154 sub file_to_s {
1155 my $file = shift;
1156 open my $fd,'<',$file or croak "$!: file: $file\n";
1157 local $/;
1158 my $ret = <$fd>;
1159 close $fd or croak $!;
1160 $ret =~ s/\s*$//s;
1161 return $ret;
1162 }
1163
1164 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1165 sub load_authors {
1166 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1167 my $log = $cmd eq 'log';
1168 while (<$authors>) {
1169 chomp;
1170 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1171 my ($user, $name, $email) = ($1, $2, $3);
1172 if ($log) {
1173 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1174 } else {
1175 $users{$user} = [$name, $email];
1176 }
1177 }
1178 close $authors or croak $!;
1179 }
1180
1181 # convert GetOpt::Long specs for use by git-config
1182 sub read_repo_config {
1183 return unless -d $ENV{GIT_DIR};
1184 my $opts = shift;
1185 my @config_only;
1186 foreach my $o (keys %$opts) {
1187 # if we have mixedCase and a long option-only, then
1188 # it's a config-only variable that we don't need for
1189 # the command-line.
1190 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1191 my $v = $opts->{$o};
1192 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1193 $key =~ s/-//g;
1194 my $arg = 'git config';
1195 $arg .= ' --int' if ($o =~ /[:=]i$/);
1196 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1197 if (ref $v eq 'ARRAY') {
1198 chomp(my @tmp = `$arg --get-all svn.$key`);
1199 @$v = @tmp if @tmp;
1200 } else {
1201 chomp(my $tmp = `$arg --get svn.$key`);
1202 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1203 $$v = $tmp;
1204 }
1205 }
1206 }
1207 delete @$opts{@config_only} if @config_only;
1208 }
1209
1210 sub extract_metadata {
1211 my $id = shift or return (undef, undef, undef);
1212 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1213 \s([a-f\d\-]+)$/x);
1214 if (!defined $rev || !$uuid || !$url) {
1215 # some of the original repositories I made had
1216 # identifiers like this:
1217 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1218 }
1219 return ($url, $rev, $uuid);
1220 }
1221
1222 sub cmt_metadata {
1223 return extract_metadata((grep(/^git-svn-id: /,
1224 command(qw/cat-file commit/, shift)))[-1]);
1225 }
1226
1227 sub working_head_info {
1228 my ($head, $refs) = @_;
1229 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1230 my ($fh, $ctx) = command_output_pipe(@args, $head);
1231 my $hash;
1232 my %max;
1233 while (<$fh>) {
1234 if ( m{^commit ($::sha1)$} ) {
1235 unshift @$refs, $hash if $hash and $refs;
1236 $hash = $1;
1237 next;
1238 }
1239 next unless s{^\s*(git-svn-id:)}{$1};
1240 my ($url, $rev, $uuid) = extract_metadata($_);
1241 if (defined $url && defined $rev) {
1242 next if $max{$url} and $max{$url} < $rev;
1243 if (my $gs = Git::SVN->find_by_url($url)) {
1244 my $c = $gs->rev_map_get($rev, $uuid);
1245 if ($c && $c eq $hash) {
1246 close $fh; # break the pipe
1247 return ($url, $rev, $uuid, $gs);
1248 } else {
1249 $max{$url} ||= $gs->rev_map_max;
1250 }
1251 }
1252 }
1253 }
1254 command_close_pipe($fh, $ctx);
1255 (undef, undef, undef, undef);
1256 }
1257
1258 sub read_commit_parents {
1259 my ($parents, $c) = @_;
1260 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1261 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1262 @{$parents->{$c}} = split(/ /, $p);
1263 }
1264
1265 sub linearize_history {
1266 my ($gs, $refs) = @_;
1267 my %parents;
1268 foreach my $c (@$refs) {
1269 read_commit_parents(\%parents, $c);
1270 }
1271
1272 my @linear_refs;
1273 my %skip = ();
1274 my $last_svn_commit = $gs->last_commit;
1275 foreach my $c (reverse @$refs) {
1276 next if $c eq $last_svn_commit;
1277 last if $skip{$c};
1278
1279 unshift @linear_refs, $c;
1280 $skip{$c} = 1;
1281
1282 # we only want the first parent to diff against for linear
1283 # history, we save the rest to inject when we finalize the
1284 # svn commit
1285 my $fp_a = verify_ref("$c~1");
1286 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1287 if (!$fp_a || !$fp_b) {
1288 die "Commit $c\n",
1289 "has no parent commit, and therefore ",
1290 "nothing to diff against.\n",
1291 "You should be working from a repository ",
1292 "originally created by git-svn\n";
1293 }
1294 if ($fp_a ne $fp_b) {
1295 die "$c~1 = $fp_a, however parsing commit $c ",
1296 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1297 }
1298
1299 foreach my $p (@{$parents{$c}}) {
1300 $skip{$p} = 1;
1301 }
1302 }
1303 (\@linear_refs, \%parents);
1304 }
1305
1306 sub find_file_type_and_diff_status {
1307 my ($path) = @_;
1308 return ('dir', '') if $path eq '';
1309
1310 my $diff_output =
1311 command_oneline(qw(diff --cached --name-status --), $path) || "";
1312 my $diff_status = (split(' ', $diff_output))[0] || "";
1313
1314 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1315
1316 return (undef, undef) if !$diff_status && !$ls_tree;
1317
1318 if ($diff_status eq "A") {
1319 return ("link", $diff_status) if -l $path;
1320 return ("dir", $diff_status) if -d $path;
1321 return ("file", $diff_status);
1322 }
1323
1324 my $mode = (split(' ', $ls_tree))[0] || "";
1325
1326 return ("link", $diff_status) if $mode eq "120000";
1327 return ("dir", $diff_status) if $mode eq "040000";
1328 return ("file", $diff_status);
1329 }
1330
1331 sub md5sum {
1332 my $arg = shift;
1333 my $ref = ref $arg;
1334 my $md5 = Digest::MD5->new();
1335 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1336 $md5->addfile($arg) or croak $!;
1337 } elsif ($ref eq 'SCALAR') {
1338 $md5->add($$arg) or croak $!;
1339 } elsif (!$ref) {
1340 $md5->add($arg) or croak $!;
1341 } else {
1342 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1343 }
1344 return $md5->hexdigest();
1345 }
1346
1347 package Git::SVN;
1348 use strict;
1349 use warnings;
1350 use Fcntl qw/:DEFAULT :seek/;
1351 use constant rev_map_fmt => 'NH40';
1352 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1353 $_repack $_repack_flags $_use_svm_props $_head
1354 $_use_svnsync_props $no_reuse_existing $_minimize_url
1355 $_use_log_author $_add_author_from/;
1356 use Carp qw/croak/;
1357 use File::Path qw/mkpath/;
1358 use File::Copy qw/copy/;
1359 use IPC::Open3;
1360
1361 my ($_gc_nr, $_gc_period);
1362
1363 # properties that we do not log:
1364 my %SKIP_PROP;
1365 BEGIN {
1366 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1367 svn:special svn:executable
1368 svn:entry:committed-rev
1369 svn:entry:last-author
1370 svn:entry:uuid
1371 svn:entry:committed-date/;
1372
1373 # some options are read globally, but can be overridden locally
1374 # per [svn-remote "..."] section. Command-line options will *NOT*
1375 # override options set in an [svn-remote "..."] section
1376 no strict 'refs';
1377 for my $option (qw/follow_parent no_metadata use_svm_props
1378 use_svnsync_props/) {
1379 my $key = $option;
1380 $key =~ tr/_//d;
1381 my $prop = "-$option";
1382 *$option = sub {
1383 my ($self) = @_;
1384 return $self->{$prop} if exists $self->{$prop};
1385 my $k = "svn-remote.$self->{repo_id}.$key";
1386 eval { command_oneline(qw/config --get/, $k) };
1387 if ($@) {
1388 $self->{$prop} = ${"Git::SVN::_$option"};
1389 } else {
1390 my $v = command_oneline(qw/config --bool/,$k);
1391 $self->{$prop} = $v eq 'false' ? 0 : 1;
1392 }
1393 return $self->{$prop};
1394 }
1395 }
1396 }
1397
1398
1399 my (%LOCKFILES, %INDEX_FILES);
1400 END {
1401 unlink keys %LOCKFILES if %LOCKFILES;
1402 unlink keys %INDEX_FILES if %INDEX_FILES;
1403 }
1404
1405 sub resolve_local_globs {
1406 my ($url, $fetch, $glob_spec) = @_;
1407 return unless defined $glob_spec;
1408 my $ref = $glob_spec->{ref};
1409 my $path = $glob_spec->{path};
1410 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1411 next unless m#^refs/remotes/$ref->{regex}$#;
1412 my $p = $1;
1413 my $pathname = desanitize_refname($path->full_path($p));
1414 my $refname = desanitize_refname($ref->full_path($p));
1415 if (my $existing = $fetch->{$pathname}) {
1416 if ($existing ne $refname) {
1417 die "Refspec conflict:\n",
1418 "existing: refs/remotes/$existing\n",
1419 " globbed: refs/remotes/$refname\n";
1420 }
1421 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1422 $u =~ s!^\Q$url\E(/|$)!! or die
1423 "refs/remotes/$refname: '$url' not found in '$u'\n";
1424 if ($pathname ne $u) {
1425 warn "W: Refspec glob conflict ",
1426 "(ref: refs/remotes/$refname):\n",
1427 "expected path: $pathname\n",
1428 " real path: $u\n",
1429 "Continuing ahead with $u\n";
1430 next;
1431 }
1432 } else {
1433 $fetch->{$pathname} = $refname;
1434 }
1435 }
1436 }
1437
1438 sub parse_revision_argument {
1439 my ($base, $head) = @_;
1440 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1441 return ($base, $head);
1442 }
1443 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1444 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1445 return ($head, $head) if ($::_revision eq 'HEAD');
1446 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1447 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1448 die "revision argument: $::_revision not understood by git-svn\n";
1449 }
1450
1451 sub fetch_all {
1452 my ($repo_id, $remotes) = @_;
1453 if (ref $repo_id) {
1454 my $gs = $repo_id;
1455 $repo_id = undef;
1456 $repo_id = $gs->{repo_id};
1457 }
1458 $remotes ||= read_all_remotes();
1459 my $remote = $remotes->{$repo_id} or
1460 die "[svn-remote \"$repo_id\"] unknown\n";
1461 my $fetch = $remote->{fetch};
1462 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1463 my (@gs, @globs);
1464 my $ra = Git::SVN::Ra->new($url);
1465 my $uuid = $ra->get_uuid;
1466 my $head = $ra->get_latest_revnum;
1467 my $base = defined $fetch ? $head : 0;
1468
1469 # read the max revs for wildcard expansion (branches/*, tags/*)
1470 foreach my $t (qw/branches tags/) {
1471 defined $remote->{$t} or next;
1472 push @globs, $remote->{$t};
1473 my $max_rev = eval { tmp_config(qw/--int --get/,
1474 "svn-remote.$repo_id.${t}-maxRev") };
1475 if (defined $max_rev && ($max_rev < $base)) {
1476 $base = $max_rev;
1477 } elsif (!defined $max_rev) {
1478 $base = 0;
1479 }
1480 }
1481
1482 if ($fetch) {
1483 foreach my $p (sort keys %$fetch) {
1484 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1485 my $lr = $gs->rev_map_max;
1486 if (defined $lr) {
1487 $base = $lr if ($lr < $base);
1488 }
1489 push @gs, $gs;
1490 }
1491 }
1492
1493 ($base, $head) = parse_revision_argument($base, $head);
1494 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1495 }
1496
1497 sub read_all_remotes {
1498 my $r = {};
1499 my $use_svm_props = eval { command_oneline(qw/config --bool
1500 svn.useSvmProps/) };
1501 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1502 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1503 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1504 my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1505 die("svn-remote.$remote: remote ref '$_remote_ref' "
1506 . "must start with 'refs/remotes/'\n")
1507 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1508 my $remote_ref = $1;
1509 $local_ref =~ s{^/}{};
1510 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1511 $r->{$remote}->{svm} = {} if $use_svm_props;
1512 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1513 $r->{$1}->{svm} = {};
1514 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1515 $r->{$1}->{url} = $2;
1516 } elsif (m!^(.+)\.(branches|tags)=
1517 (.*):refs/remotes/(.+)\s*$/!x) {
1518 my ($p, $g) = ($3, $4);
1519 my $rs = $r->{$1}->{$2} = {
1520 t => $2,
1521 remote => $1,
1522 path => Git::SVN::GlobSpec->new($p),
1523 ref => Git::SVN::GlobSpec->new($g) };
1524 if (length($rs->{ref}->{right}) != 0) {
1525 die "The '*' glob character must be the last ",
1526 "character of '$g'\n";
1527 }
1528 }
1529 }
1530
1531 map {
1532 if (defined $r->{$_}->{svm}) {
1533 my $svm;
1534 eval {
1535 my $section = "svn-remote.$_";
1536 $svm = {
1537 source => tmp_config('--get',
1538 "$section.svm-source"),
1539 replace => tmp_config('--get',
1540 "$section.svm-replace"),
1541 }
1542 };
1543 $r->{$_}->{svm} = $svm;
1544 }
1545 } keys %$r;
1546
1547 $r;
1548 }
1549
1550 sub init_vars {
1551 $_gc_nr = $_gc_period = 1000;
1552 if (defined $_repack || defined $_repack_flags) {
1553 warn "Repack options are obsolete; they have no effect.\n";
1554 }
1555 }
1556
1557 sub verify_remotes_sanity {
1558 return unless -d $ENV{GIT_DIR};
1559 my %seen;
1560 foreach (command(qw/config -l/)) {
1561 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1562 if ($seen{$1}) {
1563 die "Remote ref refs/remote/$1 is tracked by",
1564 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1565 "Please resolve this ambiguity in ",
1566 "your git configuration file before ",
1567 "continuing\n";
1568 }
1569 $seen{$1} = $_;
1570 }
1571 }
1572 }
1573
1574 sub find_existing_remote {
1575 my ($url, $remotes) = @_;
1576 return undef if $no_reuse_existing;
1577 my $existing;
1578 foreach my $repo_id (keys %$remotes) {
1579 my $u = $remotes->{$repo_id}->{url} or next;
1580 next if $u ne $url;
1581 $existing = $repo_id;
1582 last;
1583 }
1584 $existing;
1585 }
1586
1587 sub init_remote_config {
1588 my ($self, $url, $no_write) = @_;
1589 $url =~ s!/+$!!; # strip trailing slash
1590 my $r = read_all_remotes();
1591 my $existing = find_existing_remote($url, $r);
1592 if ($existing) {
1593 unless ($no_write) {
1594 print STDERR "Using existing ",
1595 "[svn-remote \"$existing\"]\n";
1596 }
1597 $self->{repo_id} = $existing;
1598 } elsif ($_minimize_url) {
1599 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1600 $existing = find_existing_remote($min_url, $r);
1601 if ($existing) {
1602 unless ($no_write) {
1603 print STDERR "Using existing ",
1604 "[svn-remote \"$existing\"]\n";
1605 }
1606 $self->{repo_id} = $existing;
1607 }
1608 if ($min_url ne $url) {
1609 unless ($no_write) {
1610 print STDERR "Using higher level of URL: ",
1611 "$url => $min_url\n";
1612 }
1613 my $old_path = $self->{path};
1614 $self->{path} = $url;
1615 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1616 if (length $old_path) {
1617 $self->{path} .= "/$old_path";
1618 }
1619 $url = $min_url;
1620 }
1621 }
1622 my $orig_url;
1623 if (!$existing) {
1624 # verify that we aren't overwriting anything:
1625 $orig_url = eval {
1626 command_oneline('config', '--get',
1627 "svn-remote.$self->{repo_id}.url")
1628 };
1629 if ($orig_url && ($orig_url ne $url)) {
1630 die "svn-remote.$self->{repo_id}.url already set: ",
1631 "$orig_url\nwanted to set to: $url\n";
1632 }
1633 }
1634 my ($xrepo_id, $xpath) = find_ref($self->refname);
1635 if (defined $xpath) {
1636 die "svn-remote.$xrepo_id.fetch already set to track ",
1637 "$xpath:refs/remotes/", $self->refname, "\n";
1638 }
1639 unless ($no_write) {
1640 command_noisy('config',
1641 "svn-remote.$self->{repo_id}.url", $url);
1642 $self->{path} =~ s{^/}{};
1643 command_noisy('config', '--add',
1644 "svn-remote.$self->{repo_id}.fetch",
1645 "$self->{path}:".$self->refname);
1646 }
1647 $self->{url} = $url;
1648 }
1649
1650 sub find_by_url { # repos_root and, path are optional
1651 my ($class, $full_url, $repos_root, $path) = @_;
1652
1653 return undef unless defined $full_url;
1654 remove_username($full_url);
1655 remove_username($repos_root) if defined $repos_root;
1656 my $remotes = read_all_remotes();
1657 if (defined $full_url && defined $repos_root && !defined $path) {
1658 $path = $full_url;
1659 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1660 }
1661 foreach my $repo_id (keys %$remotes) {
1662 my $u = $remotes->{$repo_id}->{url} or next;
1663 remove_username($u);
1664 next if defined $repos_root && $repos_root ne $u;
1665
1666 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1667 foreach (qw/branches tags/) {
1668 resolve_local_globs($u, $fetch,
1669 $remotes->{$repo_id}->{$_});
1670 }
1671 my $p = $path;
1672 my $rwr = rewrite_root({repo_id => $repo_id});
1673 my $svm = $remotes->{$repo_id}->{svm}
1674 if defined $remotes->{$repo_id}->{svm};
1675 unless (defined $p) {
1676 $p = $full_url;
1677 my $z = $u;
1678 my $prefix = '';
1679 if ($rwr) {
1680 $z = $rwr;
1681 } elsif (defined $svm) {
1682 $z = $svm->{source};
1683 $prefix = $svm->{replace};
1684 $prefix =~ s#^\Q$u\E(?:/|$)##;
1685 $prefix =~ s#/$##;
1686 }
1687 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1688 }
1689 foreach my $f (keys %$fetch) {
1690 next if $f ne $p;
1691 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1692 }
1693 }
1694 undef;
1695 }
1696
1697 sub init {
1698 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1699 my $self = _new($class, $repo_id, $ref_id, $path);
1700 if (defined $url) {
1701 $self->init_remote_config($url, $no_write);
1702 }
1703 $self;
1704 }
1705
1706 sub find_ref {
1707 my ($ref_id) = @_;
1708 foreach (command(qw/config -l/)) {
1709 next unless m!^svn-remote\.(.+)\.fetch=
1710 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1711 my ($repo_id, $path, $ref) = ($1, $2, $3);
1712 if ($ref eq $ref_id) {
1713 $path = '' if ($path =~ m#^\./?#);
1714 return ($repo_id, $path);
1715 }
1716 }
1717 (undef, undef, undef);
1718 }
1719
1720 sub new {
1721 my ($class, $ref_id, $repo_id, $path) = @_;
1722 if (defined $ref_id && !defined $repo_id && !defined $path) {
1723 ($repo_id, $path) = find_ref($ref_id);
1724 if (!defined $repo_id) {
1725 die "Could not find a \"svn-remote.*.fetch\" key ",
1726 "in the repository configuration matching: ",
1727 "refs/remotes/$ref_id\n";
1728 }
1729 }
1730 my $self = _new($class, $repo_id, $ref_id, $path);
1731 if (!defined $self->{path} || !length $self->{path}) {
1732 my $fetch = command_oneline('config', '--get',
1733 "svn-remote.$repo_id.fetch",
1734 ":refs/remotes/$ref_id\$") or
1735 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1736 "\":refs/remotes/$ref_id\$\" in config\n";
1737 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1738 }
1739 $self->{url} = command_oneline('config', '--get',
1740 "svn-remote.$repo_id.url") or
1741 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1742 $self->rebuild;
1743 $self;
1744 }
1745
1746 sub refname {
1747 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1748
1749 # It cannot end with a slash /, we'll throw up on this because
1750 # SVN can't have directories with a slash in their name, either:
1751 if ($refname =~ m{/$}) {
1752 die "ref: '$refname' ends with a trailing slash, this is ",
1753 "not permitted by git nor Subversion\n";
1754 }
1755
1756 # It cannot have ASCII control character space, tilde ~, caret ^,
1757 # colon :, question-mark ?, asterisk *, space, or open bracket [
1758 # anywhere.
1759 #
1760 # Additionally, % must be escaped because it is used for escaping
1761 # and we want our escaped refname to be reversible
1762 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1763
1764 # no slash-separated component can begin with a dot .
1765 # /.* becomes /%2E*
1766 $refname =~ s{/\.}{/%2E}g;
1767
1768 # It cannot have two consecutive dots .. anywhere
1769 # .. becomes %2E%2E
1770 $refname =~ s{\.\.}{%2E%2E}g;
1771
1772 return $refname;
1773 }
1774
1775 sub desanitize_refname {
1776 my ($refname) = @_;
1777 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1778 return $refname;
1779 }
1780
1781 sub svm_uuid {
1782 my ($self) = @_;
1783 return $self->{svm}->{uuid} if $self->svm;
1784 $self->ra;
1785 unless ($self->{svm}) {
1786 die "SVM UUID not cached, and reading remotely failed\n";
1787 }
1788 $self->{svm}->{uuid};
1789 }
1790
1791 sub svm {
1792 my ($self) = @_;
1793 return $self->{svm} if $self->{svm};
1794 my $svm;
1795 # see if we have it in our config, first:
1796 eval {
1797 my $section = "svn-remote.$self->{repo_id}";
1798 $svm = {
1799 source => tmp_config('--get', "$section.svm-source"),
1800 uuid => tmp_config('--get', "$section.svm-uuid"),
1801 replace => tmp_config('--get', "$section.svm-replace"),
1802 }
1803 };
1804 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1805 $self->{svm} = $svm;
1806 }
1807 $self->{svm};
1808 }
1809
1810 sub _set_svm_vars {
1811 my ($self, $ra) = @_;
1812 return $ra if $self->svm;
1813
1814 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1815 "(svm:source, svm:uuid) ",
1816 "from the following URLs:\n" );
1817 sub read_svm_props {
1818 my ($self, $ra, $path, $r) = @_;
1819 my $props = ($ra->get_dir($path, $r))[2];
1820 my $src = $props->{'svm:source'};
1821 my $uuid = $props->{'svm:uuid'};
1822 return undef if (!$src || !$uuid);
1823
1824 chomp($src, $uuid);
1825
1826 $uuid =~ m{^[0-9a-f\-]{30,}$}
1827 or die "doesn't look right - svm:uuid is '$uuid'\n";
1828
1829 # the '!' is used to mark the repos_root!/relative/path
1830 $src =~ s{/?!/?}{/};
1831 $src =~ s{/+$}{}; # no trailing slashes please
1832 # username is of no interest
1833 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1834
1835 my $replace = $ra->{url};
1836 $replace .= "/$path" if length $path;
1837
1838 my $section = "svn-remote.$self->{repo_id}";
1839 tmp_config("$section.svm-source", $src);
1840 tmp_config("$section.svm-replace", $replace);
1841 tmp_config("$section.svm-uuid", $uuid);
1842 $self->{svm} = {
1843 source => $src,
1844 uuid => $uuid,
1845 replace => $replace
1846 };
1847 }
1848
1849 my $r = $ra->get_latest_revnum;
1850 my $path = $self->{path};
1851 my %tried;
1852 while (length $path) {
1853 unless ($tried{"$self->{url}/$path"}) {
1854 return $ra if $self->read_svm_props($ra, $path, $r);
1855 $tried{"$self->{url}/$path"} = 1;
1856 }
1857 $path =~ s#/?[^/]+$##;
1858 }
1859 die "Path: '$path' should be ''\n" if $path ne '';
1860 return $ra if $self->read_svm_props($ra, $path, $r);
1861 $tried{"$self->{url}/$path"} = 1;
1862
1863 if ($ra->{repos_root} eq $self->{url}) {
1864 die @err, (map { " $_\n" } keys %tried), "\n";
1865 }
1866
1867 # nope, make sure we're connected to the repository root:
1868 my $ok;
1869 my @tried_b;
1870 $path = $ra->{svn_path};
1871 $ra = Git::SVN::Ra->new($ra->{repos_root});
1872 while (length $path) {
1873 unless ($tried{"$ra->{url}/$path"}) {
1874 $ok = $self->read_svm_props($ra, $path, $r);
1875 last if $ok;
1876 $tried{"$ra->{url}/$path"} = 1;
1877 }
1878 $path =~ s#/?[^/]+$##;
1879 }
1880 die "Path: '$path' should be ''\n" if $path ne '';
1881 $ok ||= $self->read_svm_props($ra, $path, $r);
1882 $tried{"$ra->{url}/$path"} = 1;
1883 if (!$ok) {
1884 die @err, (map { " $_\n" } keys %tried), "\n";
1885 }
1886 Git::SVN::Ra->new($self->{url});
1887 }
1888
1889 sub svnsync {
1890 my ($self) = @_;
1891 return $self->{svnsync} if $self->{svnsync};
1892
1893 if ($self->no_metadata) {
1894 die "Can't have both 'noMetadata' and ",
1895 "'useSvnsyncProps' options set!\n";
1896 }
1897 if ($self->rewrite_root) {
1898 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1899 "options set!\n";
1900 }
1901
1902 my $svnsync;
1903 # see if we have it in our config, first:
1904 eval {
1905 my $section = "svn-remote.$self->{repo_id}";
1906
1907 my $url = tmp_config('--get', "$section.svnsync-url");
1908 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1909 die "doesn't look right - svn:sync-from-url is '$url'\n";
1910
1911 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1912 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1913 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1914
1915 $svnsync = { url => $url, uuid => $uuid }
1916 };
1917 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1918 return $self->{svnsync} = $svnsync;
1919 }
1920
1921 my $err = "useSvnsyncProps set, but failed to read " .
1922 "svnsync property: svn:sync-from-";
1923 my $rp = $self->ra->rev_proplist(0);
1924
1925 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1926 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1927 die "doesn't look right - svn:sync-from-url is '$url'\n";
1928
1929 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1930 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1931 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1932
1933 my $section = "svn-remote.$self->{repo_id}";
1934 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1935 tmp_config('--add', "$section.svnsync-url", $url);
1936 return $self->{svnsync} = { url => $url, uuid => $uuid };
1937 }
1938
1939 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1940 # remote lookup (useful for 'git svn log').
1941 sub ra_uuid {
1942 my ($self) = @_;
1943 unless ($self->{ra_uuid}) {
1944 my $key = "svn-remote.$self->{repo_id}.uuid";
1945 my $uuid = eval { tmp_config('--get', $key) };
1946 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1947 $self->{ra_uuid} = $uuid;
1948 } else {
1949 die "ra_uuid called without URL\n" unless $self->{url};
1950 $self->{ra_uuid} = $self->ra->get_uuid;
1951 tmp_config('--add', $key, $self->{ra_uuid});
1952 }
1953 }
1954 $self->{ra_uuid};
1955 }
1956
1957 sub _set_repos_root {
1958 my ($self, $repos_root) = @_;
1959 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1960 $repos_root ||= $self->ra->{repos_root};
1961 tmp_config($k, $repos_root);
1962 $repos_root;
1963 }
1964
1965 sub repos_root {
1966 my ($self) = @_;
1967 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1968 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1969 }
1970
1971 sub ra {
1972 my ($self) = shift;
1973 my $ra = Git::SVN::Ra->new($self->{url});
1974 $self->_set_repos_root($ra->{repos_root});
1975 if ($self->use_svm_props && !$self->{svm}) {
1976 if ($self->no_metadata) {
1977 die "Can't have both 'noMetadata' and ",
1978 "'useSvmProps' options set!\n";
1979 } elsif ($self->use_svnsync_props) {
1980 die "Can't have both 'useSvnsyncProps' and ",
1981 "'useSvmProps' options set!\n";
1982 }
1983 $ra = $self->_set_svm_vars($ra);
1984 $self->{-want_revprops} = 1;
1985 }
1986 $ra;
1987 }
1988
1989 sub rel_path {
1990 my ($self) = @_;
1991 my $repos_root = $self->ra->{repos_root};
1992 return $self->{path} if ($self->{url} eq $repos_root);
1993 my $url = $self->{url} .
1994 (length $self->{path} ? "/$self->{path}" : $self->{path});
1995 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1996 $url;
1997 }
1998
1999 # prop_walk(PATH, REV, SUB)
2000 # -------------------------
2001 # Recursively traverse PATH at revision REV and invoke SUB for each
2002 # directory that contains a SVN property. SUB will be invoked as
2003 # follows: &SUB(gs, path, props); where `gs' is this instance of
2004 # Git::SVN, `path' the path to the directory where the properties
2005 # `props' were found. The `path' will be relative to point of checkout,
2006 # that is, if url://repo/trunk is the current Git branch, and that
2007 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2008 # as `path' (note the trailing `/').
2009 sub prop_walk {
2010 my ($self, $path, $rev, $sub) = @_;
2011
2012 $path =~ s#^/##;
2013 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2014 $path =~ s#^/*#/#g;
2015 my $p = $path;
2016 # Strip the irrelevant part of the path.
2017 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2018 # Ensure the path is terminated by a `/'.
2019 $p =~ s#/*$#/#;
2020
2021 # The properties contain all the internal SVN stuff nobody
2022 # (usually) cares about.
2023 my $interesting_props = 0;
2024 foreach (keys %{$props}) {
2025 # If it doesn't start with `svn:', it must be a
2026 # user-defined property.
2027 ++$interesting_props and next if $_ !~ /^svn:/;
2028 # FIXME: Fragile, if SVN adds new public properties,
2029 # this needs to be updated.
2030 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2031 |eol-style|mime-type
2032 |externals|needs-lock)$/x;
2033 }
2034 &$sub($self, $p, $props) if $interesting_props;
2035
2036 foreach (sort keys %$dirent) {
2037 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2038 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2039 }
2040 }
2041
2042 sub last_rev { ($_[0]->last_rev_commit)[0] }
2043 sub last_commit { ($_[0]->last_rev_commit)[1] }
2044
2045 # returns the newest SVN revision number and newest commit SHA1
2046 sub last_rev_commit {
2047 my ($self) = @_;
2048 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2049 return ($self->{last_rev}, $self->{last_commit});
2050 }
2051 my $c = ::verify_ref($self->refname.'^0');
2052 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2053 my $rev = (::cmt_metadata($c))[1];
2054 if (defined $rev) {
2055 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2056 return ($rev, $c);
2057 }
2058 }
2059 my $map_path = $self->map_path;
2060 unless (-e $map_path) {
2061 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2062 return (undef, undef);
2063 }
2064 my ($rev, $commit) = $self->rev_map_max(1);
2065 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2066 return ($rev, $commit);
2067 }
2068
2069 sub get_fetch_range {
2070 my ($self, $min, $max) = @_;
2071 $max ||= $self->ra->get_latest_revnum;
2072 $min ||= $self->rev_map_max;
2073 (++$min, $max);
2074 }
2075
2076 sub tmp_config {
2077 my (@args) = @_;
2078 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2079 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2080 if (! -f $config && -f $old_def_config) {
2081 rename $old_def_config, $config or
2082 die "Failed rename $old_def_config => $config: $!\n";
2083 }
2084 my $old_config = $ENV{GIT_CONFIG};
2085 $ENV{GIT_CONFIG} = $config;
2086 $@ = undef;
2087 my @ret = eval {
2088 unless (-f $config) {
2089 mkfile($config);
2090 open my $fh, '>', $config or
2091 die "Can't open $config: $!\n";
2092 print $fh "; This file is used internally by ",
2093 "git-svn\n" or die
2094 "Couldn't write to $config: $!\n";
2095 print $fh "; You should not have to edit it\n" or
2096 die "Couldn't write to $config: $!\n";
2097 close $fh or die "Couldn't close $config: $!\n";
2098 }
2099 command('config', @args);
2100 };
2101 my $err = $@;
2102 if (defined $old_config) {
2103 $ENV{GIT_CONFIG} = $old_config;
2104 } else {
2105 delete $ENV{GIT_CONFIG};
2106 }
2107 die $err if $err;
2108 wantarray ? @ret : $ret[0];
2109 }
2110
2111 sub tmp_index_do {
2112 my ($self, $sub) = @_;
2113 my $old_index = $ENV{GIT_INDEX_FILE};
2114 $ENV{GIT_INDEX_FILE} = $self->{index};
2115 $@ = undef;
2116 my @ret = eval {
2117 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2118 mkpath([$dir]) unless -d $dir;
2119 &$sub;
2120 };
2121 my $err = $@;
2122 if (defined $old_index) {
2123 $ENV{GIT_INDEX_FILE} = $old_index;
2124 } else {
2125 delete $ENV{GIT_INDEX_FILE};
2126 }
2127 die $err if $err;
2128 wantarray ? @ret : $ret[0];
2129 }
2130
2131 sub assert_index_clean {
2132 my ($self, $treeish) = @_;
2133
2134 $self->tmp_index_do(sub {
2135 command_noisy('read-tree', $treeish) unless -e $self->{index};
2136 my $x = command_oneline('write-tree');
2137 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2138 /^tree ($::sha1)/mo);
2139 return if $y eq $x;
2140
2141 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2142 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2143 command_noisy('read-tree', $treeish);
2144 $x = command_oneline('write-tree');
2145 if ($y ne $x) {
2146 ::fatal "trees ($treeish) $y != $x\n",
2147 "Something is seriously wrong...";
2148 }
2149 });
2150 }
2151
2152 sub get_commit_parents {
2153 my ($self, $log_entry) = @_;
2154 my (%seen, @ret, @tmp);
2155 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2156 if (my $ip = $self->{inject_parents}) {
2157 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2158 push @tmp, $commit;
2159 }
2160 }
2161 if (my $cur = ::verify_ref($self->refname.'^0')) {
2162 push @tmp, $cur;
2163 }
2164 if (my $ipd = $self->{inject_parents_dcommit}) {
2165 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2166 push @tmp, @$commit;
2167 }
2168 }
2169 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2170 while (my $p = shift @tmp) {
2171 next if $seen{$p};
2172 $seen{$p} = 1;
2173 push @ret, $p;
2174 # MAXPARENT is defined to 16 in commit-tree.c:
2175 last if @ret >= 16;
2176 }
2177 if (@tmp) {
2178 die "r$log_entry->{revision}: No room for parents:\n\t",
2179 join("\n\t", @tmp), "\n";
2180 }
2181 @ret;
2182 }
2183
2184 sub rewrite_root {
2185 my ($self) = @_;
2186 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2187 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2188 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2189 if ($rwr) {
2190 $rwr =~ s#/+$##;
2191 if ($rwr !~ m#^[a-z\+]+://#) {
2192 die "$rwr is not a valid URL (key: $k)\n";
2193 }
2194 }
2195 $self->{-rewrite_root} = $rwr;
2196 }
2197
2198 sub metadata_url {
2199 my ($self) = @_;
2200 ($self->rewrite_root || $self->{url}) .
2201 (length $self->{path} ? '/' . $self->{path} : '');
2202 }
2203
2204 sub full_url {
2205 my ($self) = @_;
2206 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2207 }
2208
2209
2210 sub set_commit_header_env {
2211 my ($log_entry) = @_;
2212 my %env;
2213 foreach my $ned (qw/NAME EMAIL DATE/) {
2214 foreach my $ac (qw/AUTHOR COMMITTER/) {
2215 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2216 }
2217 }
2218
2219 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2220 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2221 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2222
2223 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2224 ? $log_entry->{commit_name}
2225 : $log_entry->{name};
2226 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2227 ? $log_entry->{commit_email}
2228 : $log_entry->{email};
2229 \%env;
2230 }
2231
2232 sub restore_commit_header_env {
2233 my ($env) = @_;
2234 foreach my $ned (qw/NAME EMAIL DATE/) {
2235 foreach my $ac (qw/AUTHOR COMMITTER/) {
2236 my $k = "GIT_${ac}_${ned}";
2237 if (defined $env->{$k}) {
2238 $ENV{$k} = $env->{$k};
2239 } else {
2240 delete $ENV{$k};
2241 }
2242 }
2243 }
2244 }
2245
2246 sub gc {
2247 command_noisy('gc', '--auto');
2248 };
2249
2250 sub do_git_commit {
2251 my ($self, $log_entry) = @_;
2252 my $lr = $self->last_rev;
2253 if (defined $lr && $lr >= $log_entry->{revision}) {
2254 die "Last fetched revision of ", $self->refname,
2255 " was r$lr, but we are about to fetch: ",
2256 "r$log_entry->{revision}!\n";
2257 }
2258 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2259 croak "$log_entry->{revision} = $c already exists! ",
2260 "Why are we refetching it?\n";
2261 }
2262 my $old_env = set_commit_header_env($log_entry);
2263 my $tree = $log_entry->{tree};
2264 if (!defined $tree) {
2265 $tree = $self->tmp_index_do(sub {
2266 command_oneline('write-tree') });
2267 }
2268 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2269
2270 my @exec = ('git', 'commit-tree', $tree);
2271 foreach ($self->get_commit_parents($log_entry)) {
2272 push @exec, '-p', $_;
2273 }
2274 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2275 or croak $!;
2276 print $msg_fh $log_entry->{log} or croak $!;
2277 restore_commit_header_env($old_env);
2278 unless ($self->no_metadata) {
2279 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2280 or croak $!;
2281 }
2282 $msg_fh->flush == 0 or croak $!;
2283 close $msg_fh or croak $!;
2284 chomp(my $commit = do { local $/; <$out_fh> });
2285 close $out_fh or croak $!;
2286 waitpid $pid, 0;
2287 croak $? if $?;
2288 if ($commit !~ /^$::sha1$/o) {
2289 die "Failed to commit, invalid sha1: $commit\n";
2290 }
2291
2292 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2293
2294 $self->{last_rev} = $log_entry->{revision};
2295 $self->{last_commit} = $commit;
2296 print "r$log_entry->{revision}";
2297 if (defined $log_entry->{svm_revision}) {
2298 print " (\@$log_entry->{svm_revision})";
2299 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2300 0, $self->svm_uuid);
2301 }
2302 print " = $commit ($self->{ref_id})\n";
2303 if (--$_gc_nr == 0) {
2304 $_gc_nr = $_gc_period;
2305 gc();
2306 }
2307 return $commit;
2308 }
2309
2310 sub match_paths {
2311 my ($self, $paths, $r) = @_;
2312 return 1 if $self->{path} eq '';
2313 if (my $path = $paths->{"/$self->{path}"}) {
2314 return ($path->{action} eq 'D') ? 0 : 1;
2315 }
2316 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2317 if (grep /$self->{path_regex}/, keys %$paths) {
2318 return 1;
2319 }
2320 my $c = '';
2321 foreach (split m#/#, $self->{path}) {
2322 $c .= "/$_";
2323 next unless ($paths->{$c} &&
2324 ($paths->{$c}->{action} =~ /^[AR]$/));
2325 if ($self->ra->check_path($self->{path}, $r) ==
2326 $SVN::Node::dir) {
2327 return 1;
2328 }
2329 }
2330 return 0;
2331 }
2332
2333 sub find_parent_branch {
2334 my ($self, $paths, $rev) = @_;
2335 return undef unless $self->follow_parent;
2336 unless (defined $paths) {
2337 my $err_handler = $SVN::Error::handler;
2338 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2339 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2340 $paths =
2341 Git::SVN::Ra::dup_changed_paths($_[0]) });
2342 $SVN::Error::handler = $err_handler;
2343 }
2344 return undef unless defined $paths;
2345
2346 # look for a parent from another branch:
2347 my @b_path_components = split m#/#, $self->rel_path;
2348 my @a_path_components;
2349 my $i;
2350 while (@b_path_components) {
2351 $i = $paths->{'/'.join('/', @b_path_components)};
2352 last if $i && defined $i->{copyfrom_path};
2353 unshift(@a_path_components, pop(@b_path_components));
2354 }
2355 return undef unless defined $i && defined $i->{copyfrom_path};
2356 my $branch_from = $i->{copyfrom_path};
2357 if (@a_path_components) {
2358 print STDERR "branch_from: $branch_from => ";
2359 $branch_from .= '/'.join('/', @a_path_components);
2360 print STDERR $branch_from, "\n";
2361 }
2362 my $r = $i->{copyfrom_rev};
2363 my $repos_root = $self->ra->{repos_root};
2364 my $url = $self->ra->{url};
2365 my $new_url = $repos_root . $branch_from;
2366 print STDERR "Found possible branch point: ",
2367 "$new_url => ", $self->full_url, ", $r\n";
2368 $branch_from =~ s#^/##;
2369 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2370 unless ($gs) {
2371 my $ref_id = $self->{ref_id};
2372 $ref_id =~ s/\@\d+$//;
2373 $ref_id .= "\@$r";
2374 # just grow a tail if we're not unique enough :x
2375 $ref_id .= '-' while find_ref($ref_id);
2376 print STDERR "Initializing parent: $ref_id\n";
2377 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2378 if ($u =~ s#^\Q$url\E(/|$)##) {
2379 $p = $u;
2380 $u = $url;
2381 $repo_id = $self->{repo_id};
2382 }
2383 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2384 }
2385 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2386 if (!defined $r0 || !defined $parent) {
2387 my ($base, $head) = parse_revision_argument(0, $r);
2388 if ($base <= $r) {
2389 $gs->fetch($base, $r);
2390 }
2391 ($r0, $parent) = $gs->last_rev_commit;
2392 }
2393 if (defined $r0 && defined $parent) {
2394 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2395 my $ed;
2396 if ($self->ra->can_do_switch) {
2397 $self->assert_index_clean($parent);
2398 print STDERR "Following parent with do_switch\n";
2399 # do_switch works with svn/trunk >= r22312, but that
2400 # is not included with SVN 1.4.3 (the latest version
2401 # at the moment), so we can't rely on it
2402 $self->{last_commit} = $parent;
2403 $ed = SVN::Git::Fetcher->new($self);
2404 $gs->ra->gs_do_switch($r0, $rev, $gs,
2405 $self->full_url, $ed)
2406 or die "SVN connection failed somewhere...\n";
2407 } elsif ($self->ra->trees_match($new_url, $r0,
2408 $self->full_url, $rev)) {
2409 print STDERR "Trees match:\n",
2410 " $new_url\@$r0\n",
2411 " ${\$self->full_url}\@$rev\n",
2412 "Following parent with no changes\n";
2413 $self->tmp_index_do(sub {
2414 command_noisy('read-tree', $parent);
2415 });
2416 $self->{last_commit} = $parent;
2417 } else {
2418 print STDERR "Following parent with do_update\n";
2419 $ed = SVN::Git::Fetcher->new($self);
2420 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2421 or die "SVN connection failed somewhere...\n";
2422 }
2423 print STDERR "Successfully followed parent\n";
2424 return $self->make_log_entry($rev, [$parent], $ed);
2425 }
2426 return undef;
2427 }
2428
2429 sub do_fetch {
2430 my ($self, $paths, $rev) = @_;
2431 my $ed;
2432 my ($last_rev, @parents);
2433 if (my $lc = $self->last_commit) {
2434 # we can have a branch that was deleted, then re-added
2435 # under the same name but copied from another path, in
2436 # which case we'll have multiple parents (we don't
2437 # want to break the original ref, nor lose copypath info):
2438 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2439 push @{$log_entry->{parents}}, $lc;
2440 return $log_entry;
2441 }
2442 $ed = SVN::Git::Fetcher->new($self);
2443 $last_rev = $self->{last_rev};
2444 $ed->{c} = $lc;
2445 @parents = ($lc);
2446 } else {
2447 $last_rev = $rev;
2448 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2449 return $log_entry;
2450 }
2451 $ed = SVN::Git::Fetcher->new($self);
2452 }
2453 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2454 die "SVN connection failed somewhere...\n";
2455 }
2456 $self->make_log_entry($rev, \@parents, $ed);
2457 }
2458
2459 sub get_untracked {
2460 my ($self, $ed) = @_;
2461 my @out;
2462 my $h = $ed->{empty};
2463 foreach (sort keys %$h) {
2464 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2465 push @out, " $act: " . uri_encode($_);
2466 warn "W: $act: $_\n";
2467 }
2468 foreach my $t (qw/dir_prop file_prop/) {
2469 $h = $ed->{$t} or next;
2470 foreach my $path (sort keys %$h) {
2471 my $ppath = $path eq '' ? '.' : $path;
2472 foreach my $prop (sort keys %{$h->{$path}}) {
2473 next if $SKIP_PROP{$prop};
2474 my $v = $h->{$path}->{$prop};
2475 my $t_ppath_prop = "$t: " .
2476 uri_encode($ppath) . ' ' .
2477 uri_encode($prop);
2478 if (defined $v) {
2479 push @out, " +$t_ppath_prop " .
2480 uri_encode($v);
2481 } else {
2482 push @out, " -$t_ppath_prop";
2483 }
2484 }
2485 }
2486 }
2487 foreach my $t (qw/absent_file absent_directory/) {
2488 $h = $ed->{$t} or next;
2489 foreach my $parent (sort keys %$h) {
2490 foreach my $path (sort @{$h->{$parent}}) {
2491 push @out, " $t: " .
2492 uri_encode("$parent/$path");
2493 warn "W: $t: $parent/$path ",
2494 "Insufficient permissions?\n";
2495 }
2496 }
2497 }
2498 \@out;
2499 }
2500
2501 sub parse_svn_date {
2502 my $date = shift || return '+0000 1970-01-01 00:00:00';
2503 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2504 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2505 croak "Unable to parse date: $date\n";
2506 "+0000 $Y-$m-$d $H:$M:$S";
2507 }
2508
2509 sub check_author {
2510 my ($author) = @_;
2511 if (!defined $author || length $author == 0) {
2512 $author = '(no author)';
2513 } elsif (defined $::_authors && ! defined $::users{$author}) {
2514 die "Author: $author not defined in $::_authors file\n";
2515 }
2516 $author;
2517 }
2518
2519 sub make_log_entry {
2520 my ($self, $rev, $parents, $ed) = @_;
2521 my $untracked = $self->get_untracked($ed);
2522
2523 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2524 print $un "r$rev\n" or croak $!;
2525 print $un $_, "\n" foreach @$untracked;
2526 my %log_entry = ( parents => $parents || [], revision => $rev,
2527 log => '');
2528
2529 my $headrev;
2530 my $logged = delete $self->{logged_rev_props};
2531 if (!$logged || $self->{-want_revprops}) {
2532 my $rp = $self->ra->rev_proplist($rev);
2533 foreach (sort keys %$rp) {
2534 my $v = $rp->{$_};
2535 if (/^svn:(author|date|log)$/) {
2536 $log_entry{$1} = $v;
2537 } elsif ($_ eq 'svm:headrev') {
2538 $headrev = $v;
2539 } else {
2540 print $un " rev_prop: ", uri_encode($_), ' ',
2541 uri_encode($v), "\n";
2542 }
2543 }
2544 } else {
2545 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2546 }
2547 close $un or croak $!;
2548
2549 $log_entry{date} = parse_svn_date($log_entry{date});
2550 $log_entry{log} .= "\n";
2551 my $author = $log_entry{author} = check_author($log_entry{author});
2552 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2553 : ($author, undef);
2554
2555 my ($commit_name, $commit_email) = ($name, $email);
2556 if ($_use_log_author) {
2557 my $name_field;
2558 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2559 $name_field = $1;
2560 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2561 $name_field = $1;
2562 }
2563 if (!defined $name_field) {
2564 if (!defined $email) {
2565 $email = $name;
2566 }
2567 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2568 ($name, $email) = ($1, $2);
2569 } elsif ($name_field =~ /(.*)@/) {
2570 ($name, $email) = ($1, $name_field);
2571 } else {
2572 ($name, $email) = ($name_field, $name_field);
2573 }
2574 }
2575 if (defined $headrev && $self->use_svm_props) {
2576 if ($self->rewrite_root) {
2577 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2578 "options set!\n";
2579 }
2580 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2581 # we don't want "SVM: initializing mirror for junk" ...
2582 return undef if $r == 0;
2583 my $svm = $self->svm;
2584 if ($uuid ne $svm->{uuid}) {
2585 die "UUID mismatch on SVM path:\n",
2586 "expected: $svm->{uuid}\n",
2587 " got: $uuid\n";
2588 }
2589 my $full_url = $self->full_url;
2590 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2591 die "Failed to replace '$svm->{replace}' with ",
2592 "'$svm->{source}' in $full_url\n";
2593 # throw away username for storing in records
2594 remove_username($full_url);
2595 $log_entry{metadata} = "$full_url\@$r $uuid";
2596 $log_entry{svm_revision} = $r;
2597 $email ||= "$author\@$uuid";
2598 $commit_email ||= "$author\@$uuid";
2599 } elsif ($self->use_svnsync_props) {
2600 my $full_url = $self->svnsync->{url};
2601 $full_url .= "/$self->{path}" if length $self->{path};
2602 remove_username($full_url);
2603 my $uuid = $self->svnsync->{uuid};
2604 $log_entry{metadata} = "$full_url\@$rev $uuid";
2605 $email ||= "$author\@$uuid";
2606 $commit_email ||= "$author\@$uuid";
2607 } else {
2608 my $url = $self->metadata_url;
2609 remove_username($url);
2610 $log_entry{metadata} = "$url\@$rev " .
2611 $self->ra->get_uuid;
2612 $email ||= "$author\@" . $self->ra->get_uuid;
2613 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2614 }
2615 $log_entry{name} = $name;
2616 $log_entry{email} = $email;
2617 $log_entry{commit_name} = $commit_name;
2618 $log_entry{commit_email} = $commit_email;
2619 \%log_entry;
2620 }
2621
2622 sub fetch {
2623 my ($self, $min_rev, $max_rev, @parents) = @_;
2624 my ($last_rev, $last_commit) = $self->last_rev_commit;
2625 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2626 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2627 }
2628
2629 sub set_tree_cb {
2630 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2631 $self->{inject_parents} = { $rev => $tree };
2632 $self->fetch(undef, undef);
2633 }
2634
2635 sub set_tree {
2636 my ($self, $tree) = (shift, shift);
2637 my $log_entry = ::get_commit_entry($tree);
2638 unless ($self->{last_rev}) {
2639 ::fatal("Must have an existing revision to commit");
2640 }
2641 my %ed_opts = ( r => $self->{last_rev},
2642 log => $log_entry->{log},
2643 ra => $self->ra,
2644 tree_a => $self->{last_commit},
2645 tree_b => $tree,
2646 editor_cb => sub {
2647 $self->set_tree_cb($log_entry, $tree, @_) },
2648 svn_path => $self->{path} );
2649 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2650 print "No changes\nr$self->{last_rev} = $tree\n";
2651 }
2652 }
2653
2654 sub rebuild_from_rev_db {
2655 my ($self, $path) = @_;
2656 my $r = -1;
2657 open my $fh, '<', $path or croak "open: $!";
2658 binmode $fh or croak "binmode: $!";
2659 while (<$fh>) {
2660 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2661 chomp($_);
2662 ++$r;
2663 next if $_ eq ('0' x 40);
2664 $self->rev_map_set($r, $_);
2665 print "r$r = $_\n";
2666 }
2667 close $fh or croak "close: $!";
2668 unlink $path or croak "unlink: $!";
2669 }
2670
2671 sub rebuild {
2672 my ($self) = @_;
2673 my $map_path = $self->map_path;
2674 my $partial = (-e $map_path && ! -z $map_path);
2675 return unless ::verify_ref($self->refname.'^0');
2676 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2677 my $rev_db = $self->rev_db_path;
2678 $self->rebuild_from_rev_db($rev_db);
2679 if ($self->use_svm_props) {
2680 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2681 $self->rebuild_from_rev_db($svm_rev_db);
2682 }
2683 $self->unlink_rev_db_symlink;
2684 return;
2685 }
2686 print "Rebuilding $map_path ...\n" if (!$partial);
2687 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2688 (undef, undef));
2689 my ($log, $ctx) =
2690 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2691 ($head ? "$head.." : "") . $self->refname,
2692 '--');
2693 my $metadata_url = $self->metadata_url;
2694 remove_username($metadata_url);
2695 my $svn_uuid = $self->ra_uuid;
2696 my $c;
2697 while (<$log>) {
2698 if ( m{^commit ($::sha1)$} ) {
2699 $c = $1;
2700 next;
2701 }
2702 next unless s{^\s*(git-svn-id:)}{$1};
2703 my ($url, $rev, $uuid) = ::extract_metadata($_);
2704 remove_username($url);
2705
2706 # ignore merges (from set-tree)
2707 next if (!defined $rev || !$uuid);
2708
2709 # if we merged or otherwise started elsewhere, this is
2710 # how we break out of it
2711 if (($uuid ne $svn_uuid) ||
2712 ($metadata_url && $url && ($url ne $metadata_url))) {
2713 next;
2714 }
2715 if ($partial && $head) {
2716 print "Partial-rebuilding $map_path ...\n";
2717 print "Currently at $base_rev = $head\n";
2718 $head = undef;
2719 }
2720
2721 $self->rev_map_set($rev, $c);
2722 print "r$rev = $c\n";
2723 }
2724 command_close_pipe($log, $ctx);
2725 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2726 my $rev_db_path = $self->rev_db_path;
2727 if (-f $self->rev_db_path) {
2728 unlink $self->rev_db_path or croak "unlink: $!";
2729 }
2730 $self->unlink_rev_db_symlink;
2731 }
2732
2733 # rev_map:
2734 # Tie::File seems to be prone to offset errors if revisions get sparse,
2735 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2736 # one of my favorite modules is out :< Next up would be one of the DBM
2737 # modules, but I'm not sure which is most portable...
2738 #
2739 # This is the replacement for the rev_db format, which was too big
2740 # and inefficient for large repositories with a lot of sparse history
2741 # (mainly tags)
2742 #
2743 # The format is this:
2744 # - 24 bytes for every record,
2745 # * 4 bytes for the integer representing an SVN revision number
2746 # * 20 bytes representing the sha1 of a git commit
2747 # - No empty padding records like the old format
2748 # (except the last record, which can be overwritten)
2749 # - new records are written append-only since SVN revision numbers
2750 # increase monotonically
2751 # - lookups on SVN revision number are done via a binary search
2752 # - Piping the file to xxd -c24 is a good way of dumping it for
2753 # viewing or editing (piped back through xxd -r), should the need
2754 # ever arise.
2755 # - The last record can be padding revision with an all-zero sha1
2756 # This is used to optimize fetch performance when using multiple
2757 # "fetch" directives in .git/config
2758 #
2759 # These files are disposable unless noMetadata or useSvmProps is set
2760
2761 sub _rev_map_set {
2762 my ($fh, $rev, $commit) = @_;
2763
2764 binmode $fh or croak "binmode: $!";
2765 my $size = (stat($fh))[7];
2766 ($size % 24) == 0 or croak "inconsistent size: $size";
2767
2768 my $wr_offset = 0;
2769 if ($size > 0) {
2770 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2771 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2772 $read == 24 or croak "read only $read bytes (!= 24)";
2773 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2774 if ($last_commit eq ('0' x40)) {
2775 if ($size >= 48) {
2776 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2777 $read = sysread($fh, $buf, 24) or
2778 croak "read: $!";
2779 $read == 24 or
2780 croak "read only $read bytes (!= 24)";
2781 ($last_rev, $last_commit) =
2782 unpack(rev_map_fmt, $buf);
2783 if ($last_commit eq ('0' x40)) {
2784 croak "inconsistent .rev_map\n";
2785 }
2786 }
2787 if ($last_rev >= $rev) {
2788 croak "last_rev is higher!: $last_rev >= $rev";
2789 }
2790 $wr_offset = -24;
2791 }
2792 }
2793 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2794 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2795 croak "write: $!";
2796 }
2797
2798 sub mkfile {
2799 my ($path) = @_;
2800 unless (-e $path) {
2801 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2802 mkpath([$dir]) unless -d $dir;
2803 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2804 close $fh or die "Couldn't close (create) $path: $!\n";
2805 }
2806 }
2807
2808 sub rev_map_set {
2809 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2810 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2811 my $db = $self->map_path($uuid);
2812 my $db_lock = "$db.lock";
2813 my $sig;
2814 if ($update_ref) {
2815 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2816 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2817 }
2818 mkfile($db);
2819
2820 $LOCKFILES{$db_lock} = 1;
2821 my $sync;
2822 # both of these options make our .rev_db file very, very important
2823 # and we can't afford to lose it because rebuild() won't work
2824 if ($self->use_svm_props || $self->no_metadata) {
2825 $sync = 1;
2826 copy($db, $db_lock) or die "rev_map_set(@_): ",
2827 "Failed to copy: ",
2828 "$db => $db_lock ($!)\n";
2829 } else {
2830 rename $db, $db_lock or die "rev_map_set(@_): ",
2831 "Failed to rename: ",
2832 "$db => $db_lock ($!)\n";
2833 }
2834
2835 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2836 or croak "Couldn't open $db_lock: $!\n";
2837 _rev_map_set($fh, $rev, $commit);
2838 if ($sync) {
2839 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2840 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2841 }
2842 close $fh or croak $!;
2843 if ($update_ref) {
2844 $_head = $self;
2845 command_noisy('update-ref', '-m', "r$rev",
2846 $self->refname, $commit);
2847 }
2848 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2849 "$db_lock => $db ($!)\n";
2850 delete $LOCKFILES{$db_lock};
2851 if ($update_ref) {
2852 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2853 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2854 kill $sig, $$ if defined $sig;
2855 }
2856 }
2857
2858 # If want_commit, this will return an array of (rev, commit) where
2859 # commit _must_ be a valid commit in the archive.
2860 # Otherwise, it'll return the max revision (whether or not the
2861 # commit is valid or just a 0x40 placeholder).
2862 sub rev_map_max {
2863 my ($self, $want_commit) = @_;
2864 $self->rebuild;
2865 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2866 $want_commit ? ($r, $c) : $r;
2867 }
2868
2869 sub rev_map_max_norebuild {
2870 my ($self, $want_commit) = @_;
2871 my $map_path = $self->map_path;
2872 stat $map_path or return $want_commit ? (0, undef) : 0;
2873 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2874 binmode $fh or croak "binmode: $!";
2875 my $size = (stat($fh))[7];
2876 ($size % 24) == 0 or croak "inconsistent size: $size";
2877
2878 if ($size == 0) {
2879 close $fh or croak "close: $!";
2880 return $want_commit ? (0, undef) : 0;
2881 }
2882
2883 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2884 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2885 my ($r, $c) = unpack(rev_map_fmt, $buf);
2886 if ($want_commit && $c eq ('0' x40)) {
2887 if ($size < 48) {
2888 return $want_commit ? (0, undef) : 0;
2889 }
2890 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2891 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2892 ($r, $c) = unpack(rev_map_fmt, $buf);
2893 if ($c eq ('0'x40)) {
2894 croak "Penultimate record is all-zeroes in $map_path";
2895 }
2896 }
2897 close $fh or croak "close: $!";
2898 $want_commit ? ($r, $c) : $r;
2899 }
2900
2901 sub rev_map_get {
2902 my ($self, $rev, $uuid) = @_;
2903 my $map_path = $self->map_path($uuid);
2904 return undef unless -e $map_path;
2905
2906 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2907 binmode $fh or croak "binmode: $!";
2908 my $size = (stat($fh))[7];
2909 ($size % 24) == 0 or croak "inconsistent size: $size";
2910
2911 if ($size == 0) {
2912 close $fh or croak "close: $fh";
2913 return undef;
2914 }
2915
2916 my ($l, $u) = (0, $size - 24);
2917 my ($r, $c, $buf);
2918
2919 while ($l <= $u) {
2920 my $i = int(($l/24 + $u/24) / 2) * 24;
2921 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2922 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2923 my ($r, $c) = unpack('NH40', $buf);
2924
2925 if ($r < $rev) {
2926 $l = $i + 24;
2927 } elsif ($r > $rev) {
2928 $u = $i - 24;
2929 } else { # $r == $rev
2930 close($fh) or croak "close: $!";
2931 return $c eq ('0' x 40) ? undef : $c;
2932 }
2933 }
2934 close($fh) or croak "close: $!";
2935 undef;
2936 }
2937
2938 # Finds the first svn revision that exists on (if $eq_ok is true) or
2939 # before $rev for the current branch. It will not search any lower
2940 # than $min_rev. Returns the git commit hash and svn revision number
2941 # if found, else (undef, undef).
2942 sub find_rev_before {
2943 my ($self, $rev, $eq_ok, $min_rev) = @_;
2944 --$rev unless $eq_ok;
2945 $min_rev ||= 1;
2946 while ($rev >= $min_rev) {
2947 if (my $c = $self->rev_map_get($rev)) {
2948 return ($rev, $c);
2949 }
2950 --$rev;
2951 }
2952 return (undef, undef);
2953 }
2954
2955 # Finds the first svn revision that exists on (if $eq_ok is true) or
2956 # after $rev for the current branch. It will not search any higher
2957 # than $max_rev. Returns the git commit hash and svn revision number
2958 # if found, else (undef, undef).
2959 sub find_rev_after {
2960 my ($self, $rev, $eq_ok, $max_rev) = @_;
2961 ++$rev unless $eq_ok;
2962 $max_rev ||= $self->rev_map_max;
2963 while ($rev <= $max_rev) {
2964 if (my $c = $self->rev_map_get($rev)) {
2965 return ($rev, $c);
2966 }
2967 ++$rev;
2968 }
2969 return (undef, undef);
2970 }
2971
2972 sub _new {
2973 my ($class, $repo_id, $ref_id, $path) = @_;
2974 unless (defined $repo_id && length $repo_id) {
2975 $repo_id = $Git::SVN::default_repo_id;
2976 }
2977 unless (defined $ref_id && length $ref_id) {
2978 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2979 }
2980 $_[1] = $repo_id;
2981 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2982 $_[3] = $path = '' unless (defined $path);
2983 mkpath(["$ENV{GIT_DIR}/svn"]);
2984 bless {
2985 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2986 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2987 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2988 }
2989
2990 # for read-only access of old .rev_db formats
2991 sub unlink_rev_db_symlink {
2992 my ($self) = @_;
2993 my $link = $self->rev_db_path;
2994 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2995 if (-l $link) {
2996 unlink $link or croak "unlink: $link failed!";
2997 }
2998 }
2999
3000 sub rev_db_path {
3001 my ($self, $uuid) = @_;
3002 my $db_path = $self->map_path($uuid);
3003 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3004 or croak "map_path: $db_path does not contain '/.rev_map.' !";
3005 $db_path;
3006 }
3007
3008 # the new replacement for .rev_db
3009 sub map_path {
3010 my ($self, $uuid) = @_;
3011 $uuid ||= $self->ra_uuid;
3012 "$self->{map_root}.$uuid";
3013 }
3014
3015 sub uri_encode {
3016 my ($f) = @_;
3017 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3018 $f
3019 }
3020
3021 sub remove_username {
3022 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3023 }
3024
3025 package Git::SVN::Prompt;
3026 use strict;
3027 use warnings;
3028 require SVN::Core;
3029 use vars qw/$_no_auth_cache $_username/;
3030
3031 sub simple {
3032 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3033 $may_save = undef if $_no_auth_cache;
3034 $default_username = $_username if defined $_username;
3035 if (defined $default_username && length $default_username) {
3036 if (defined $realm && length $realm) {
3037 print STDERR "Authentication realm: $realm\n";
3038 STDERR->flush;
3039 }
3040 $cred->username($default_username);
3041 } else {
3042 username($cred, $realm, $may_save, $pool);
3043 }
3044 $cred->password(_read_password("Password for '" .
3045 $cred->username . "': ", $realm));
3046 $cred->may_save($may_save);
3047 $SVN::_Core::SVN_NO_ERROR;
3048 }
3049
3050 sub ssl_server_trust {
3051 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3052 $may_save = undef if $_no_auth_cache;
3053 print STDERR "Error validating server certificate for '$realm':\n";
3054 {
3055 no warnings 'once';
3056 # All variables SVN::Auth::SSL::* are used only once,
3057 # so we're shutting up Perl warnings about this.
3058 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3059 print STDERR " - The certificate is not issued ",
3060 "by a trusted authority. Use the\n",
3061 " fingerprint to validate ",
3062 "the certificate manually!\n";
3063 }
3064 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3065 print STDERR " - The certificate hostname ",
3066 "does not match.\n";
3067 }
3068 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3069 print STDERR " - The certificate is not yet valid.\n";
3070 }
3071 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3072 print STDERR " - The certificate has expired.\n";
3073 }
3074 if ($failures & $SVN::Auth::SSL::OTHER) {
3075 print STDERR " - The certificate has ",
3076 "an unknown error.\n";
3077 }
3078 } # no warnings 'once'
3079 printf STDERR
3080 "Certificate information:\n".
3081 " - Hostname: %s\n".
3082 " - Valid: from %s until %s\n".
3083 " - Issuer: %s\n".
3084 " - Fingerprint: %s\n",
3085 map $cert_info->$_, qw(hostname valid_from valid_until
3086 issuer_dname fingerprint);
3087 my $choice;
3088 prompt:
3089 print STDERR $may_save ?
3090 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3091 "(R)eject or accept (t)emporarily? ";
3092 STDERR->flush;
3093 $choice = lc(substr(<STDIN> || 'R', 0, 1));
3094 if ($choice =~ /^t$/i) {
3095 $cred->may_save(undef);
3096 } elsif ($choice =~ /^r$/i) {
3097 return -1;
3098 } elsif ($may_save && $choice =~ /^p$/i) {
3099 $cred->may_save($may_save);
3100 } else {
3101 goto prompt;
3102 }
3103 $cred->accepted_failures($failures);
3104 $SVN::_Core::SVN_NO_ERROR;
3105 }
3106
3107 sub ssl_client_cert {
3108 my ($cred, $realm, $may_save, $pool) = @_;
3109 $may_save = undef if $_no_auth_cache;
3110 print STDERR "Client certificate filename: ";
3111 STDERR->flush;
3112 chomp(my $filename = <STDIN>);
3113 $cred->cert_file($filename);
3114 $cred->may_save($may_save);
3115 $SVN::_Core::SVN_NO_ERROR;
3116 }
3117
3118 sub ssl_client_cert_pw {
3119 my ($cred, $realm, $may_save, $pool) = @_;
3120 $may_save = undef if $_no_auth_cache;
3121 $cred->password(_read_password("Password: ", $realm));
3122 $cred->may_save($may_save);
3123 $SVN::_Core::SVN_NO_ERROR;
3124 }
3125
3126 sub username {
3127 my ($cred, $realm, $may_save, $pool) = @_;
3128 $may_save = undef if $_no_auth_cache;
3129 if (defined $realm && length $realm) {
3130 print STDERR "Authentication realm: $realm\n";
3131 }
3132 my $username;
3133 if (defined $_username) {
3134 $username = $_username;
3135 } else {
3136 print STDERR "Username: ";
3137 STDERR->flush;
3138 chomp($username = <STDIN>);
3139 }
3140 $cred->username($username);
3141 $cred->may_save($may_save);
3142 $SVN::_Core::SVN_NO_ERROR;
3143 }
3144
3145 sub _read_password {
3146 my ($prompt, $realm) = @_;
3147 print STDERR $prompt;
3148 STDERR->flush;
3149 require Term::ReadKey;
3150 Term::ReadKey::ReadMode('noecho');
3151 my $password = '';
3152 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3153 last if $key =~ /[\012\015]/; # \n\r
3154 $password .= $key;
3155 }
3156 Term::ReadKey::ReadMode('restore');
3157 print STDERR "\n";
3158 STDERR->flush;
3159 $password;
3160 }
3161
3162 package SVN::Git::Fetcher;
3163 use vars qw/@ISA/;
3164 use strict;
3165 use warnings;
3166 use Carp qw/croak/;
3167 use File::Temp qw/tempfile/;
3168 use IO::File qw//;
3169
3170 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3171 sub new {
3172 my ($class, $git_svn) = @_;
3173 my $self = SVN::Delta::Editor->new;
3174 bless $self, $class;
3175 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3176 $self->{empty} = {};
3177 $self->{dir_prop} = {};
3178 $self->{file_prop} = {};
3179 $self->{absent_dir} = {};
3180 $self->{absent_file} = {};
3181 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3182 $self;
3183 }
3184
3185 sub set_path_strip {
3186 my ($self, $path) = @_;
3187 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3188 }
3189
3190 sub open_root {
3191 { path => '' };
3192 }
3193
3194 sub open_directory {
3195 my ($self, $path, $pb, $rev) = @_;
3196 { path => $path };
3197 }
3198
3199 sub git_path {
3200 my ($self, $path) = @_;
3201 if ($self->{path_strip}) {
3202 $path =~ s!$self->{path_strip}!! or
3203 die "Failed to strip path '$path' ($self->{path_strip})\n";
3204 }
3205 $path;
3206 }
3207
3208 sub delete_entry {
3209 my ($self, $path, $rev, $pb) = @_;
3210
3211 my $gpath = $self->git_path($path);
3212 return undef if ($gpath eq '');
3213
3214 # remove entire directories.
3215 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3216 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3217 -r --name-only -z/,
3218 $self->{c}, '--', $gpath);
3219 local $/ = "\0";
3220 while (<$ls>) {
3221 chomp;
3222 $self->{gii}->remove($_);
3223 print "\tD\t$_\n" unless $::_q;
3224 }
3225 print "\tD\t$gpath/\n" unless $::_q;
3226 command_close_pipe($ls, $ctx);
3227 $self->{empty}->{$path} = 0
3228 } else {
3229 $self->{gii}->remove($gpath);
3230 print "\tD\t$gpath\n" unless $::_q;
3231 }
3232 undef;
3233 }
3234
3235 sub open_file {
3236 my ($self, $path, $pb, $rev) = @_;
3237 my $gpath = $self->git_path($path);
3238 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3239 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3240 unless (defined $mode && defined $blob) {
3241 die "$path was not found in commit $self->{c} (r$rev)\n";
3242 }
3243 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3244 pool => SVN::Pool->new, action => 'M' };
3245 }
3246
3247 sub add_file {
3248 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3249 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3250 delete $self->{empty}->{$dir};
3251 { path => $path, mode_a => 100644, mode_b => 100644,
3252 pool => SVN::Pool->new, action => 'A' };
3253 }
3254
3255 sub add_directory {
3256 my ($self, $path, $cp_path, $cp_rev) = @_;
3257 my $gpath = $self->git_path($path);
3258 if ($gpath eq '') {
3259 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3260 -r --name-only -z/,
3261 $self->{c});
3262 local $/ = "\0";
3263 while (<$ls>) {
3264 chomp;
3265 $self->{gii}->remove($_);
3266 print "\tD\t$_\n" unless $::_q;
3267 }
3268 command_close_pipe($ls, $ctx);
3269 $self->{empty}->{$path} = 0;
3270 }
3271 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3272 delete $self->{empty}->{$dir};
3273 $self->{empty}->{$path} = 1;
3274 { path => $path };
3275 }
3276
3277 sub change_dir_prop {
3278 my ($self, $db, $prop, $value) = @_;
3279 $self->{dir_prop}->{$db->{path}} ||= {};
3280 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3281 undef;
3282 }
3283
3284 sub absent_directory {
3285 my ($self, $path, $pb) = @_;
3286 $self->{absent_dir}->{$pb->{path}} ||= [];
3287 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3288 undef;
3289 }
3290
3291 sub absent_file {
3292 my ($self, $path, $pb) = @_;
3293 $self->{absent_file}->{$pb->{path}} ||= [];
3294 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3295 undef;
3296 }
3297
3298 sub change_file_prop {
3299 my ($self, $fb, $prop, $value) = @_;
3300 if ($prop eq 'svn:executable') {
3301 if ($fb->{mode_b} != 120000) {
3302 $fb->{mode_b} = defined $value ? 100755 : 100644;
3303 }
3304 } elsif ($prop eq 'svn:special') {
3305 $fb->{mode_b} = defined $value ? 120000 : 100644;
3306 } else {
3307 $self->{file_prop}->{$fb->{path}} ||= {};
3308 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3309 }
3310 undef;
3311 }
3312
3313 sub apply_textdelta {
3314 my ($self, $fb, $exp) = @_;
3315 my $fh = Git::temp_acquire('svn_delta');
3316 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3317 # (but $base does not,) so dup() it for reading in close_file
3318 open my $dup, '<&', $fh or croak $!;
3319 my $base = Git::temp_acquire('git_blob');
3320 if ($fb->{blob}) {
3321 print $base 'link ' if ($fb->{mode_a} == 120000);
3322 my $size = $::_repository->cat_blob($fb->{blob}, $base);
3323 die "Failed to read object $fb->{blob}" if ($size < 0);
3324
3325 if (defined $exp) {
3326 seek $base, 0, 0 or croak $!;
3327 my $got = ::md5sum($base);
3328 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3329 "expected: $exp\n",
3330 " got: $got\n" if ($got ne $exp);
3331 }
3332 }
3333 seek $base, 0, 0 or croak $!;
3334 $fb->{fh} = $fh;
3335 $fb->{base} = $base;
3336 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3337 }
3338
3339 sub close_file {
3340 my ($self, $fb, $exp) = @_;
3341 my $hash;
3342 my $path = $self->git_path($fb->{path});
3343 if (my $fh = $fb->{fh}) {
3344 if (defined $exp) {
3345 seek($fh, 0, 0) or croak $!;
3346 my $got = ::md5sum($fh);
3347 if ($got ne $exp) {
3348 die "Checksum mismatch: $path\n",
3349 "expected: $exp\n got: $got\n";
3350 }
3351 }
3352 if ($fb->{mode_b} == 120000) {
3353 sysseek($fh, 0, 0) or croak $!;
3354 sysread($fh, my $buf, 5) == 5 or croak $!;
3355
3356 unless ($buf eq 'link ') {
3357 warn "$path has mode 120000",
3358 " but is not a link\n";
3359 } else {
3360 my $tmp_fh = Git::temp_acquire('svn_hash');
3361 my $res;
3362 while ($res = sysread($fh, my $str, 1024)) {
3363 my $out = syswrite($tmp_fh, $str, $res);
3364 defined($out) && $out == $res
3365 or croak("write ",
3366 Git::temp_path($tmp_fh),
3367 ": $!\n");
3368 }
3369 defined $res or croak $!;
3370
3371 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3372 Git::temp_release($tmp_fh, 1);
3373 }
3374 }
3375
3376 $hash = $::_repository->hash_and_insert_object(
3377 Git::temp_path($fh));
3378 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3379
3380 Git::temp_release($fb->{base}, 1);
3381 Git::temp_release($fh, 1);
3382 } else {
3383 $hash = $fb->{blob} or die "no blob information\n";
3384 }
3385 $fb->{pool}->clear;
3386 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3387 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3388 undef;
3389 }
3390
3391 sub abort_edit {
3392 my $self = shift;
3393 $self->{nr} = $self->{gii}->{nr};
3394 delete $self->{gii};
3395 $self->SUPER::abort_edit(@_);
3396 }
3397
3398 sub close_edit {
3399 my $self = shift;
3400 $self->{git_commit_ok} = 1;
3401 $self->{nr} = $self->{gii}->{nr};
3402 delete $self->{gii};
3403 $self->SUPER::close_edit(@_);
3404 }
3405
3406 package SVN::Git::Editor;
3407 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3408 use strict;
3409 use warnings;
3410 use Carp qw/croak/;
3411 use IO::File;
3412
3413 sub new {
3414 my ($class, $opts) = @_;
3415 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3416 die "$_ required!\n" unless (defined $opts->{$_});
3417 }
3418
3419 my $pool = SVN::Pool->new;
3420 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3421 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3422 $opts->{r}, $mods);
3423
3424 # $opts->{ra} functions should not be used after this:
3425 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3426 $opts->{editor_cb}, $pool);
3427 my $self = SVN::Delta::Editor->new(@ce, $pool);
3428 bless $self, $class;
3429 foreach (qw/svn_path r tree_a tree_b/) {
3430 $self->{$_} = $opts->{$_};
3431 }
3432 $self->{url} = $opts->{ra}->{url};
3433 $self->{mods} = $mods;
3434 $self->{types} = $types;
3435 $self->{pool} = $pool;
3436 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3437 $self->{rm} = { };
3438 $self->{path_prefix} = length $self->{svn_path} ?
3439 "$self->{svn_path}/" : '';
3440 $self->{config} = $opts->{config};
3441 return $self;
3442 }
3443
3444 sub generate_diff {
3445 my ($tree_a, $tree_b) = @_;
3446 my @diff_tree = qw(diff-tree -z -r);
3447 if ($_cp_similarity) {
3448 push @diff_tree, "-C$_cp_similarity";
3449 } else {
3450 push @diff_tree, '-C';
3451 }
3452 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3453 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3454 push @diff_tree, $tree_a, $tree_b;
3455 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3456 local $/ = "\0";
3457 my $state = 'meta';
3458 my @mods;
3459 while (<$diff_fh>) {
3460 chomp $_; # this gets rid of the trailing "\0"
3461 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3462 ($::sha1)\s($::sha1)\s
3463 ([MTCRAD])\d*$/xo) {
3464 push @mods, { mode_a => $1, mode_b => $2,
3465 sha1_a => $3, sha1_b => $4,
3466 chg => $5 };
3467 if ($5 =~ /^(?:C|R)$/) {
3468 $state = 'file_a';
3469 } else {
3470 $state = 'file_b';
3471 }
3472 } elsif ($state eq 'file_a') {
3473 my $x = $mods[$#mods] or croak "Empty array\n";
3474 if ($x->{chg} !~ /^(?:C|R)$/) {
3475 croak "Error parsing $_, $x->{chg}\n";
3476 }
3477 $x->{file_a} = $_;
3478 $state = 'file_b';
3479 } elsif ($state eq 'file_b') {
3480 my $x = $mods[$#mods] or croak "Empty array\n";
3481 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3482 croak "Error parsing $_, $x->{chg}\n";
3483 }
3484 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3485 croak "Error parsing $_, $x->{chg}\n";
3486 }
3487 $x->{file_b} = $_;
3488 $state = 'meta';
3489 } else {
3490 croak "Error parsing $_\n";
3491 }
3492 }
3493 command_close_pipe($diff_fh, $ctx);
3494 \@mods;
3495 }
3496
3497 sub check_diff_paths {
3498 my ($ra, $pfx, $rev, $mods) = @_;
3499 my %types;
3500 $pfx .= '/' if length $pfx;
3501
3502 sub type_diff_paths {
3503 my ($ra, $types, $path, $rev) = @_;
3504 my @p = split m#/+#, $path;
3505 my $c = shift @p;
3506 unless (defined $types->{$c}) {
3507 $types->{$c} = $ra->check_path($c, $rev);
3508 }
3509 while (@p) {
3510 $c .= '/' . shift @p;
3511 next if defined $types->{$c};
3512 $types->{$c} = $ra->check_path($c, $rev);
3513 }
3514 }
3515
3516 foreach my $m (@$mods) {
3517 foreach my $f (qw/file_a file_b/) {
3518 next unless defined $m->{$f};
3519 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3520 if (length $pfx.$dir && ! defined $types{$dir}) {
3521 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3522 }
3523 }
3524 }
3525 \%types;
3526 }
3527
3528 sub split_path {
3529 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3530 }
3531
3532 sub repo_path {
3533 my ($self, $path) = @_;
3534 $self->{path_prefix}.(defined $path ? $path : '');
3535 }
3536
3537 sub url_path {
3538 my ($self, $path) = @_;
3539 if ($self->{url} =~ m#^https?://#) {
3540 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3541 }
3542 $self->{url} . '/' . $self->repo_path($path);
3543 }
3544
3545 sub rmdirs {
3546 my ($self) = @_;
3547 my $rm = $self->{rm};
3548 delete $rm->{''}; # we never delete the url we're tracking
3549 return unless %$rm;
3550
3551 foreach (keys %$rm) {
3552 my @d = split m#/#, $_;
3553 my $c = shift @d;
3554 $rm->{$c} = 1;
3555 while (@d) {
3556 $c .= '/' . shift @d;
3557 $rm->{$c} = 1;
3558 }
3559 }
3560 delete $rm->{$self->{svn_path}};
3561 delete $rm->{''}; # we never delete the url we're tracking
3562 return unless %$rm;
3563
3564 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3565 $self->{tree_b});
3566 local $/ = "\0";
3567 while (<$fh>) {
3568 chomp;
3569 my @dn = split m#/#, $_;
3570 while (pop @dn) {
3571 delete $rm->{join '/', @dn};
3572 }
3573 unless (%$rm) {
3574 close $fh;
3575 return;
3576 }
3577 }
3578 command_close_pipe($fh, $ctx);
3579
3580 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3581 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3582 $self->close_directory($bat->{$d}, $p);
3583 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3584 print "\tD+\t$d/\n" unless $::_q;
3585 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3586 delete $bat->{$d};
3587 }
3588 }
3589
3590 sub open_or_add_dir {
3591 my ($self, $full_path, $baton) = @_;
3592 my $t = $self->{types}->{$full_path};
3593 if (!defined $t) {
3594 die "$full_path not known in r$self->{r} or we have a bug!\n";
3595 }
3596 {
3597 no warnings 'once';
3598 # SVN::Node::none and SVN::Node::file are used only once,
3599 # so we're shutting up Perl's warnings about them.
3600 if ($t == $SVN::Node::none) {
3601 return $self->add_directory($full_path, $baton,
3602 undef, -1, $self->{pool});
3603 } elsif ($t == $SVN::Node::dir) {
3604 return $self->open_directory($full_path, $baton,
3605 $self->{r}, $self->{pool});
3606 } # no warnings 'once'
3607 print STDERR "$full_path already exists in repository at ",
3608 "r$self->{r} and it is not a directory (",
3609 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3610 } # no warnings 'once'
3611 exit 1;
3612 }
3613
3614 sub ensure_path {
3615 my ($self, $path) = @_;
3616 my $bat = $self->{bat};
3617 my $repo_path = $self->repo_path($path);
3618 return $bat->{''} unless (length $repo_path);
3619 my @p = split m#/+#, $repo_path;
3620 my $c = shift @p;
3621 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3622 while (@p) {
3623 my $c0 = $c;
3624 $c .= '/' . shift @p;
3625 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3626 }
3627 return $bat->{$c};
3628 }
3629
3630 # Subroutine to convert a globbing pattern to a regular expression.
3631 # From perl cookbook.
3632 sub glob2pat {
3633 my $globstr = shift;
3634 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
3635 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
3636 return '^' . $globstr . '$';
3637 }
3638
3639 sub check_autoprop {
3640 my ($self, $pattern, $properties, $file, $fbat) = @_;
3641 # Convert the globbing pattern to a regular expression.
3642 my $regex = glob2pat($pattern);
3643 # Check if the pattern matches the file name.
3644 if($file =~ m/($regex)/) {
3645 # Parse the list of properties to set.
3646 my @props = split(/;/, $properties);
3647 foreach my $prop (@props) {
3648 # Parse 'name=value' syntax and set the property.
3649 if ($prop =~ /([^=]+)=(.*)/) {
3650 my ($n,$v) = ($1,$2);
3651 for ($n, $v) {
3652 s/^\s+//; s/\s+$//;
3653 }
3654 $self->change_file_prop($fbat, $n, $v);
3655 }
3656 }
3657 }
3658 }
3659
3660 sub apply_autoprops {
3661 my ($self, $file, $fbat) = @_;
3662 my $conf_t = ${$self->{config}}{'config'};
3663 no warnings 'once';
3664 # Check [miscellany]/enable-auto-props in svn configuration.
3665 if (SVN::_Core::svn_config_get_bool(
3666 $conf_t,
3667 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
3668 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
3669 0)) {
3670 # Auto-props are enabled. Enumerate them to look for matches.
3671 my $callback = sub {
3672 $self->check_autoprop($_[0], $_[1], $file, $fbat);
3673 };
3674 SVN::_Core::svn_config_enumerate(
3675 $conf_t,
3676 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
3677 $callback);
3678 }
3679 }
3680
3681 sub A {
3682 my ($self, $m) = @_;
3683 my ($dir, $file) = split_path($m->{file_b});
3684 my $pbat = $self->ensure_path($dir);
3685 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3686 undef, -1);
3687 print "\tA\t$m->{file_b}\n" unless $::_q;
3688 $self->apply_autoprops($file, $fbat);
3689 $self->chg_file($fbat, $m);
3690 $self->close_file($fbat,undef,$self->{pool});
3691 }
3692
3693 sub C {
3694 my ($self, $m) = @_;
3695 my ($dir, $file) = split_path($m->{file_b});
3696 my $pbat = $self->ensure_path($dir);
3697 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3698 $self->url_path($m->{file_a}), $self->{r});
3699 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3700 $self->chg_file($fbat, $m);
3701 $self->close_file($fbat,undef,$self->{pool});
3702 }
3703
3704 sub delete_entry {
3705 my ($self, $path, $pbat) = @_;
3706 my $rpath = $self->repo_path($path);
3707 my ($dir, $file) = split_path($rpath);
3708 $self->{rm}->{$dir} = 1;
3709 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3710 }
3711
3712 sub R {
3713 my ($self, $m) = @_;
3714 my ($dir, $file) = split_path($m->{file_b});
3715 my $pbat = $self->ensure_path($dir);
3716 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3717 $self->url_path($m->{file_a}), $self->{r});
3718 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3719 $self->apply_autoprops($file, $fbat);
3720 $self->chg_file($fbat, $m);
3721 $self->close_file($fbat,undef,$self->{pool});
3722
3723 ($dir, $file) = split_path($m->{file_a});
3724 $pbat = $self->ensure_path($dir);
3725 $self->delete_entry($m->{file_a}, $pbat);
3726 }
3727
3728 sub M {
3729 my ($self, $m) = @_;
3730 my ($dir, $file) = split_path($m->{file_b});
3731 my $pbat = $self->ensure_path($dir);
3732 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3733 $pbat,$self->{r},$self->{pool});
3734 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3735 $self->chg_file($fbat, $m);
3736 $self->close_file($fbat,undef,$self->{pool});
3737 }
3738
3739 sub T { shift->M(@_) }
3740
3741 sub change_file_prop {
3742 my ($self, $fbat, $pname, $pval) = @_;
3743 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3744 }
3745
3746 sub _chg_file_get_blob ($$$$) {
3747 my ($self, $fbat, $m, $which) = @_;
3748 my $fh = Git::temp_acquire("git_blob_$which");
3749 if ($m->{"mode_$which"} =~ /^120/) {
3750 print $fh 'link ' or croak $!;
3751 $self->change_file_prop($fbat,'svn:special','*');
3752 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
3753 $self->change_file_prop($fbat,'svn:special',undef);
3754 }
3755 my $blob = $m->{"sha1_$which"};
3756 return ($fh,) if ($blob =~ /^0{40}$/);
3757 my $size = $::_repository->cat_blob($blob, $fh);
3758 croak "Failed to read object $blob" if ($size < 0);
3759 $fh->flush == 0 or croak $!;
3760 seek $fh, 0, 0 or croak $!;
3761
3762 my $exp = ::md5sum($fh);
3763 seek $fh, 0, 0 or croak $!;
3764 return ($fh, $exp);
3765 }
3766
3767 sub chg_file {
3768 my ($self, $fbat, $m) = @_;
3769 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3770 $self->change_file_prop($fbat,'svn:executable','*');
3771 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3772 $self->change_file_prop($fbat,'svn:executable',undef);
3773 }
3774 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
3775 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
3776 my $pool = SVN::Pool->new;
3777 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
3778 if (-s $fh_a) {
3779 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
3780 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
3781 if (defined $res) {
3782 die "Unexpected result from send_txstream: $res\n",
3783 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
3784 }
3785 } else {
3786 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
3787 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
3788 if ($got ne $exp_b);
3789 }
3790 Git::temp_release($fh_b, 1);
3791 Git::temp_release($fh_a, 1);
3792 $pool->clear;
3793 }
3794
3795 sub D {
3796 my ($self, $m) = @_;
3797 my ($dir, $file) = split_path($m->{file_b});
3798 my $pbat = $self->ensure_path($dir);
3799 print "\tD\t$m->{file_b}\n" unless $::_q;
3800 $self->delete_entry($m->{file_b}, $pbat);
3801 }
3802
3803 sub close_edit {
3804 my ($self) = @_;
3805 my ($p,$bat) = ($self->{pool}, $self->{bat});
3806 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3807 next if $_ eq '';
3808 $self->close_directory($bat->{$_}, $p);
3809 }
3810 $self->close_directory($bat->{''}, $p);
3811 $self->SUPER::close_edit($p);
3812 $p->clear;
3813 }
3814
3815 sub abort_edit {
3816 my ($self) = @_;
3817 $self->SUPER::abort_edit($self->{pool});
3818 }
3819
3820 sub DESTROY {
3821 my $self = shift;
3822 $self->SUPER::DESTROY(@_);
3823 $self->{pool}->clear;
3824 }
3825
3826 # this drives the editor
3827 sub apply_diff {
3828 my ($self) = @_;
3829 my $mods = $self->{mods};
3830 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3831 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3832 my $f = $m->{chg};
3833 if (defined $o{$f}) {
3834 $self->$f($m);
3835 } else {
3836 fatal("Invalid change type: $f");
3837 }
3838 }
3839 $self->rmdirs if $_rmdir;
3840 if (@$mods == 0) {
3841 $self->abort_edit;
3842 } else {
3843 $self->close_edit;
3844 }
3845 return scalar @$mods;
3846 }
3847
3848 package Git::SVN::Ra;
3849 use vars qw/@ISA $config_dir $_log_window_size/;
3850 use strict;
3851 use warnings;
3852 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3853
3854 BEGIN {
3855 # enforce temporary pool usage for some simple functions
3856 no strict 'refs';
3857 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3858 my $SUPER = "SUPER::$f";
3859 *$f = sub {
3860 my $self = shift;
3861 my $pool = SVN::Pool->new;
3862 my @ret = $self->$SUPER(@_,$pool);
3863 $pool->clear;
3864 wantarray ? @ret : $ret[0];
3865 };
3866 }
3867 }
3868
3869 sub _auth_providers () {
3870 [
3871 SVN::Client::get_simple_provider(),
3872 SVN::Client::get_ssl_server_trust_file_provider(),
3873 SVN::Client::get_simple_prompt_provider(
3874 \&Git::SVN::Prompt::simple, 2),
3875 SVN::Client::get_ssl_client_cert_file_provider(),
3876 SVN::Client::get_ssl_client_cert_prompt_provider(
3877 \&Git::SVN::Prompt::ssl_client_cert, 2),
3878 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3879 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3880 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3881 SVN::Client::get_username_provider(),
3882 SVN::Client::get_ssl_server_trust_prompt_provider(
3883 \&Git::SVN::Prompt::ssl_server_trust),
3884 SVN::Client::get_username_prompt_provider(
3885 \&Git::SVN::Prompt::username, 2)
3886 ]
3887 }
3888
3889 sub escape_uri_only {
3890 my ($uri) = @_;
3891 my @tmp;
3892 foreach (split m{/}, $uri) {
3893 s/([^\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
3894 push @tmp, $_;
3895 }
3896 join('/', @tmp);
3897 }
3898
3899 sub escape_url {
3900 my ($url) = @_;
3901 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3902 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3903 $url = "$scheme://$domain$uri";
3904 }
3905 $url;
3906 }
3907
3908 sub new {
3909 my ($class, $url) = @_;
3910 $url =~ s!/+$!!;
3911 return $RA if ($RA && $RA->{url} eq $url);
3912
3913 SVN::_Core::svn_config_ensure($config_dir, undef);
3914 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3915 my $config = SVN::Core::config_get_config($config_dir);
3916 $RA = undef;
3917 my $dont_store_passwords = 1;
3918 my $conf_t = ${$config}{'config'};
3919 {
3920 no warnings 'once';
3921 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3922 # produces warnings that variables are used only once.
3923 # I had not found the better way to shut them up, so
3924 # the warnings of type 'once' are disabled in this block.
3925 if (SVN::_Core::svn_config_get_bool($conf_t,
3926 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3927 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3928 1) == 0) {
3929 SVN::_Core::svn_auth_set_parameter($baton,
3930 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3931 bless (\$dont_store_passwords, "_p_void"));
3932 }
3933 if (SVN::_Core::svn_config_get_bool($conf_t,
3934 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3935 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3936 1) == 0) {
3937 $Git::SVN::Prompt::_no_auth_cache = 1;
3938 }
3939 } # no warnings 'once'
3940 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3941 config => $config,
3942 pool => SVN::Pool->new,
3943 auth_provider_callbacks => $callbacks);
3944 $self->{url} = $url;
3945 $self->{svn_path} = $url;
3946 $self->{repos_root} = $self->get_repos_root;
3947 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3948 $self->{cache} = { check_path => { r => 0, data => {} },
3949 get_dir => { r => 0, data => {} } };
3950 $RA = bless $self, $class;
3951 }
3952
3953 sub check_path {
3954 my ($self, $path, $r) = @_;
3955 my $cache = $self->{cache}->{check_path};
3956 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3957 return $cache->{data}->{$path};
3958 }
3959 my $pool = SVN::Pool->new;
3960 my $t = $self->SUPER::check_path($path, $r, $pool);
3961 $pool->clear;
3962 if ($r != $cache->{r}) {
3963 %{$cache->{data}} = ();
3964 $cache->{r} = $r;
3965 }
3966 $cache->{data}->{$path} = $t;
3967 }
3968
3969 sub get_dir {
3970 my ($self, $dir, $r) = @_;
3971 my $cache = $self->{cache}->{get_dir};
3972 if ($r == $cache->{r}) {
3973 if (my $x = $cache->{data}->{$dir}) {
3974 return wantarray ? @$x : $x->[0];
3975 }
3976 }
3977 my $pool = SVN::Pool->new;
3978 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3979 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3980 $pool->clear;
3981 if ($r != $cache->{r}) {
3982 %{$cache->{data}} = ();
3983 $cache->{r} = $r;
3984 }
3985 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3986 wantarray ? (\%dirents, $r, $props) : \%dirents;
3987 }
3988
3989 sub DESTROY {
3990 # do not call the real DESTROY since we store ourselves in $RA
3991 }
3992
3993 sub get_log {
3994 my ($self, @args) = @_;
3995 my $pool = SVN::Pool->new;
3996 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3997 my $ret = $self->SUPER::get_log(@args, $pool);
3998 $pool->clear;
3999 $ret;
4000 }
4001
4002 sub trees_match {
4003 my ($self, $url1, $rev1, $url2, $rev2) = @_;
4004 my $ctx = SVN::Client->new(auth => _auth_providers);
4005 my $out = IO::File->new_tmpfile;
4006
4007 # older SVN (1.1.x) doesn't take $pool as the last parameter for
4008 # $ctx->diff(), so we'll create a default one
4009 my $pool = SVN::Pool->new_default_sub;
4010
4011 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4012 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4013 $out->flush;
4014 my $ret = (($out->stat)[7] == 0);
4015 close $out or croak $!;
4016
4017 $ret;
4018 }
4019
4020 sub get_commit_editor {
4021 my ($self, $log, $cb, $pool) = @_;
4022 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4023 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4024 }
4025
4026 sub gs_do_update {
4027 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4028 my $new = ($rev_a == $rev_b);
4029 my $path = $gs->{path};
4030
4031 if ($new && -e $gs->{index}) {
4032 unlink $gs->{index} or die
4033 "Couldn't unlink index: $gs->{index}: $!\n";
4034 }
4035 my $pool = SVN::Pool->new;
4036 $editor->set_path_strip($path);
4037 my (@pc) = split m#/#, $path;
4038 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4039 1, $editor, $pool);
4040 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4041
4042 # Since we can't rely on svn_ra_reparent being available, we'll
4043 # just have to do some magic with set_path to make it so
4044 # we only want a partial path.
4045 my $sp = '';
4046 my $final = join('/', @pc);
4047 while (@pc) {
4048 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4049 $sp .= '/' if length $sp;
4050 $sp .= shift @pc;
4051 }
4052 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4053
4054 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4055
4056 $reporter->finish_report($pool);
4057 $pool->clear;
4058 $editor->{git_commit_ok};
4059 }
4060
4061 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4062 # svn_ra_reparent didn't work before 1.4)
4063 sub gs_do_switch {
4064 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4065 my $path = $gs->{path};
4066 my $pool = SVN::Pool->new;
4067
4068 my $full_url = $self->{url};
4069 my $old_url = $full_url;
4070 $full_url .= '/' . escape_uri_only($path) if length $path;
4071 my ($ra, $reparented);
4072
4073 if ($old_url =~ m#^svn(\+ssh)?://#) {
4074 $_[0] = undef;
4075 $self = undef;
4076 $RA = undef;
4077 $ra = Git::SVN::Ra->new($full_url);
4078 $ra_invalid = 1;
4079 } elsif ($old_url ne $full_url) {
4080 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4081 $self->{url} = $full_url;
4082 $reparented = 1;
4083 }
4084
4085 $ra ||= $self;
4086 $url_b = escape_url($url_b);
4087 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4088 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4089 $reporter->set_path('', $rev_a, 0, @lock, $pool);
4090 $reporter->finish_report($pool);
4091
4092 if ($reparented) {
4093 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4094 $self->{url} = $old_url;
4095 }
4096
4097 $pool->clear;
4098 $editor->{git_commit_ok};
4099 }
4100
4101 sub longest_common_path {
4102 my ($gsv, $globs) = @_;
4103 my %common;
4104 my $common_max = scalar @$gsv;
4105
4106 foreach my $gs (@$gsv) {
4107 my @tmp = split m#/#, $gs->{path};
4108 my $p = '';
4109 foreach (@tmp) {
4110 $p .= length($p) ? "/$_" : $_;
4111 $common{$p} ||= 0;
4112 $common{$p}++;
4113 }
4114 }
4115 $globs ||= [];
4116 $common_max += scalar @$globs;
4117 foreach my $glob (@$globs) {
4118 my @tmp = split m#/#, $glob->{path}->{left};
4119 my $p = '';
4120 foreach (@tmp) {
4121 $p .= length($p) ? "/$_" : $_;
4122 $common{$p} ||= 0;
4123 $common{$p}++;
4124 }
4125 }
4126
4127 my $longest_path = '';
4128 foreach (sort {length $b <=> length $a} keys %common) {
4129 if ($common{$_} == $common_max) {
4130 $longest_path = $_;
4131 last;
4132 }
4133 }
4134 $longest_path;
4135 }
4136
4137 sub gs_fetch_loop_common {
4138 my ($self, $base, $head, $gsv, $globs) = @_;
4139 return if ($base > $head);
4140 my $inc = $_log_window_size;
4141 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4142 my $longest_path = longest_common_path($gsv, $globs);
4143 my $ra_url = $self->{url};
4144 while (1) {
4145 my %revs;
4146 my $err;
4147 my $err_handler = $SVN::Error::handler;
4148 $SVN::Error::handler = sub {
4149 ($err) = @_;
4150 skip_unknown_revs($err);
4151 };
4152 sub _cb {
4153 my ($paths, $r, $author, $date, $log) = @_;
4154 [ dup_changed_paths($paths),
4155 { author => $author, date => $date, log => $log } ];
4156 }
4157 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4158 sub { $revs{$_[1]} = _cb(@_) });
4159 if ($err && $max >= $head) {
4160 print STDERR "Path '$longest_path' ",
4161 "was probably deleted:\n",
4162 $err->expanded_message,
4163 "\nWill attempt to follow ",
4164 "revisions r$min .. r$max ",
4165 "committed before the deletion\n";
4166 my $hi = $max;
4167 while (--$hi >= $min) {
4168 my $ok;
4169 $self->get_log([$longest_path], $min, $hi,
4170 0, 1, 1, sub {
4171 $ok ||= $_[1];
4172 $revs{$_[1]} = _cb(@_) });
4173 if ($ok) {
4174 print STDERR "r$min .. r$ok OK\n";
4175 last;
4176 }
4177 }
4178 }
4179 $SVN::Error::handler = $err_handler;
4180
4181 my %exists = map { $_->{path} => $_ } @$gsv;
4182 foreach my $r (sort {$a <=> $b} keys %revs) {
4183 my ($paths, $logged) = @{$revs{$r}};
4184
4185 foreach my $gs ($self->match_globs(\%exists, $paths,
4186 $globs, $r)) {
4187 if ($gs->rev_map_max >= $r) {
4188 next;
4189 }
4190 next unless $gs->match_paths($paths, $r);
4191 $gs->{logged_rev_props} = $logged;
4192 if (my $last_commit = $gs->last_commit) {
4193 $gs->assert_index_clean($last_commit);
4194 }
4195 my $log_entry = $gs->do_fetch($paths, $r);
4196 if ($log_entry) {
4197 $gs->do_git_commit($log_entry);
4198 }
4199 $INDEX_FILES{$gs->{index}} = 1;
4200 }
4201 foreach my $g (@$globs) {
4202 my $k = "svn-remote.$g->{remote}." .
4203 "$g->{t}-maxRev";
4204 Git::SVN::tmp_config($k, $r);
4205 }
4206 if ($ra_invalid) {
4207 $_[0] = undef;
4208 $self = undef;
4209 $RA = undef;
4210 $self = Git::SVN::Ra->new($ra_url);
4211 $ra_invalid = undef;
4212 }
4213 }
4214 # pre-fill the .rev_db since it'll eventually get filled in
4215 # with '0' x40 if something new gets committed
4216 foreach my $gs (@$gsv) {
4217 next if $gs->rev_map_max >= $max;
4218 next if defined $gs->rev_map_get($max);
4219 $gs->rev_map_set($max, 0 x40);
4220 }
4221 foreach my $g (@$globs) {
4222 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4223 Git::SVN::tmp_config($k, $max);
4224 }
4225 last if $max >= $head;
4226 $min = $max + 1;
4227 $max += $inc;
4228 $max = $head if ($max > $head);
4229 }
4230 Git::SVN::gc();
4231 }
4232
4233 sub get_dir_globbed {
4234 my ($self, $left, $depth, $r) = @_;
4235
4236 my @x = eval { $self->get_dir($left, $r) };
4237 return unless scalar @x == 3;
4238 my $dirents = $x[0];
4239 my @finalents;
4240 foreach my $de (keys %$dirents) {
4241 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4242 if ($depth > 1) {
4243 my @args = ("$left/$de", $depth - 1, $r);
4244 foreach my $dir ($self->get_dir_globbed(@args)) {
4245 push @finalents, "$de/$dir";
4246 }
4247 } else {
4248 push @finalents, $de;
4249 }
4250 }
4251 @finalents;
4252 }
4253
4254 sub match_globs {
4255 my ($self, $exists, $paths, $globs, $r) = @_;
4256
4257 sub get_dir_check {
4258 my ($self, $exists, $g, $r) = @_;
4259
4260 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4261 $g->{path}->{depth},
4262 $r);
4263
4264 foreach my $de (@dirs) {
4265 my $p = $g->{path}->full_path($de);
4266 next if $exists->{$p};
4267 next if (length $g->{path}->{right} &&
4268 ($self->check_path($p, $r) !=
4269 $SVN::Node::dir));
4270 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4271 $g->{ref}->full_path($de), 1);
4272 }
4273 }
4274 foreach my $g (@$globs) {
4275 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4276 if ($path->{action} =~ /^[AR]$/) {
4277 get_dir_check($self, $exists, $g, $r);
4278 }
4279 }
4280 foreach (keys %$paths) {
4281 if (/$g->{path}->{left_regex}/ &&
4282 !/$g->{path}->{regex}/) {
4283 next if $paths->{$_}->{action} !~ /^[AR]$/;
4284 get_dir_check($self, $exists, $g, $r);
4285 }
4286 next unless /$g->{path}->{regex}/;
4287 my $p = $1;
4288 my $pathname = $g->{path}->full_path($p);
4289 next if $exists->{$pathname};
4290 next if ($self->check_path($pathname, $r) !=
4291 $SVN::Node::dir);
4292 $exists->{$pathname} = Git::SVN->init(
4293 $self->{url}, $pathname, undef,
4294 $g->{ref}->full_path($p), 1);
4295 }
4296 my $c = '';
4297 foreach (split m#/#, $g->{path}->{left}) {
4298 $c .= "/$_";
4299 next unless ($paths->{$c} &&
4300 ($paths->{$c}->{action} =~ /^[AR]$/));
4301 get_dir_check($self, $exists, $g, $r);
4302 }
4303 }
4304 values %$exists;
4305 }
4306
4307 sub minimize_url {
4308 my ($self) = @_;
4309 return $self->{url} if ($self->{url} eq $self->{repos_root});
4310 my $url = $self->{repos_root};
4311 my @components = split(m!/!, $self->{svn_path});
4312 my $c = '';
4313 do {
4314 $url .= "/$c" if length $c;
4315 eval { (ref $self)->new($url)->get_latest_revnum };
4316 } while ($@ && ($c = shift @components));
4317 $url;
4318 }
4319
4320 sub can_do_switch {
4321 my $self = shift;
4322 unless (defined $can_do_switch) {
4323 my $pool = SVN::Pool->new;
4324 my $rep = eval {
4325 $self->do_switch(1, '', 0, $self->{url},
4326 SVN::Delta::Editor->new, $pool);
4327 };
4328 if ($@) {
4329 $can_do_switch = 0;
4330 } else {
4331 $rep->abort_report($pool);
4332 $can_do_switch = 1;
4333 }
4334 $pool->clear;
4335 }
4336 $can_do_switch;
4337 }
4338
4339 sub skip_unknown_revs {
4340 my ($err) = @_;
4341 my $errno = $err->apr_err();
4342 # Maybe the branch we're tracking didn't
4343 # exist when the repo started, so it's
4344 # not an error if it doesn't, just continue
4345 #
4346 # Wonderfully consistent library, eh?
4347 # 160013 - svn:// and file://
4348 # 175002 - http(s)://
4349 # 175007 - http(s):// (this repo required authorization, too...)
4350 # More codes may be discovered later...
4351 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4352 my $err_key = $err->expanded_message;
4353 # revision numbers change every time, filter them out
4354 $err_key =~ s/\d+/\0/g;
4355 $err_key = "$errno\0$err_key";
4356 unless ($ignored_err{$err_key}) {
4357 warn "W: Ignoring error from SVN, path probably ",
4358 "does not exist: ($errno): ",
4359 $err->expanded_message,"\n";
4360 warn "W: Do not be alarmed at the above message ",
4361 "git-svn is just searching aggressively for ",
4362 "old history.\n",
4363 "This may take a while on large repositories\n";
4364 $ignored_err{$err_key} = 1;
4365 }
4366 return;
4367 }
4368 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4369 }
4370
4371 # svn_log_changed_path_t objects passed to get_log are likely to be
4372 # overwritten even if only the refs are copied to an external variable,
4373 # so we should dup the structures in their entirety. Using an externally
4374 # passed pool (instead of our temporary and quickly cleared pool in
4375 # Git::SVN::Ra) does not help matters at all...
4376 sub dup_changed_paths {
4377 my ($paths) = @_;
4378 return undef unless $paths;
4379 my %ret;
4380 foreach my $p (keys %$paths) {
4381 my $i = $paths->{$p};
4382 my %s = map { $_ => $i->$_ }
4383 qw/copyfrom_path copyfrom_rev action/;
4384 $ret{$p} = \%s;
4385 }
4386 \%ret;
4387 }
4388
4389 package Git::SVN::Log;
4390 use strict;
4391 use warnings;
4392 use POSIX qw/strftime/;
4393 use constant commit_log_separator => ('-' x 72) . "\n";
4394 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4395 %rusers $show_commit $incremental/;
4396 my $l_fmt;
4397
4398 sub cmt_showable {
4399 my ($c) = @_;
4400 return 1 if defined $c->{r};
4401
4402 # big commit message got truncated by the 16k pretty buffer in rev-list
4403 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4404 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4405 @{$c->{l}} = ();
4406 my @log = command(qw/cat-file commit/, $c->{c});
4407
4408 # shift off the headers
4409 shift @log while ($log[0] ne '');
4410 shift @log;
4411
4412 # TODO: make $c->{l} not have a trailing newline in the future
4413 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4414
4415 (undef, $c->{r}, undef) = ::extract_metadata(
4416 (grep(/^git-svn-id: /, @log))[-1]);
4417 }
4418 return defined $c->{r};
4419 }
4420
4421 sub log_use_color {
4422 return $color || Git->repository->get_colorbool('color.diff');
4423 }
4424
4425 sub git_svn_log_cmd {
4426 my ($r_min, $r_max, @args) = @_;
4427 my $head = 'HEAD';
4428 my (@files, @log_opts);
4429 foreach my $x (@args) {
4430 if ($x eq '--' || @files) {
4431 push @files, $x;
4432 } else {
4433 if (::verify_ref("$x^0")) {
4434 $head = $x;
4435 } else {
4436 push @log_opts, $x;
4437 }
4438 }
4439 }
4440
4441 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4442 $gs ||= Git::SVN->_new;
4443 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4444 $gs->refname);
4445 push @cmd, '-r' unless $non_recursive;
4446 push @cmd, qw/--raw --name-status/ if $verbose;
4447 push @cmd, '--color' if log_use_color();
4448 push @cmd, @log_opts;
4449 if (defined $r_max && $r_max == $r_min) {
4450 push @cmd, '--max-count=1';
4451 if (my $c = $gs->rev_map_get($r_max)) {
4452 push @cmd, $c;
4453 }
4454 } elsif (defined $r_max) {
4455 if ($r_max < $r_min) {
4456 ($r_min, $r_max) = ($r_max, $r_min);
4457 }
4458 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4459 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4460 # If there are no commits in the range, both $c_max and $c_min
4461 # will be undefined. If there is at least 1 commit in the
4462 # range, both will be defined.
4463 return () if !defined $c_min || !defined $c_max;
4464 if ($c_min eq $c_max) {
4465 push @cmd, '--max-count=1', $c_min;
4466 } else {
4467 push @cmd, '--boundary', "$c_min..$c_max";
4468 }
4469 }
4470 return (@cmd, @files);
4471 }
4472
4473 # adapted from pager.c
4474 sub config_pager {
4475 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4476 if (!defined $pager) {
4477 $pager = 'less';
4478 } elsif (length $pager == 0 || $pager eq 'cat') {
4479 $pager = undef;
4480 }
4481 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4482 }
4483
4484 sub run_pager {
4485 return unless -t *STDOUT && defined $pager;
4486 pipe my ($rfd, $wfd) or return;
4487 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4488 if (!$pid) {
4489 open STDOUT, '>&', $wfd or
4490 ::fatal "Can't redirect to stdout: $!";
4491 return;
4492 }
4493 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4494 $ENV{LESS} ||= 'FRSX';
4495 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4496 }
4497
4498 sub format_svn_date {
4499 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4500 }
4501
4502 sub parse_git_date {
4503 my ($t, $tz) = @_;
4504 # Date::Parse isn't in the standard Perl distro :(
4505 if ($tz =~ s/^\+//) {
4506 $t += tz_to_s_offset($tz);
4507 } elsif ($tz =~ s/^\-//) {
4508 $t -= tz_to_s_offset($tz);
4509 }
4510 return $t;
4511 }
4512
4513 sub set_local_timezone {
4514 if (defined $TZ) {
4515 $ENV{TZ} = $TZ;
4516 } else {
4517 delete $ENV{TZ};
4518 }
4519 }
4520
4521 sub tz_to_s_offset {
4522 my ($tz) = @_;
4523 $tz =~ s/(\d\d)$//;
4524 return ($1 * 60) + ($tz * 3600);
4525 }
4526
4527 sub get_author_info {
4528 my ($dest, $author, $t, $tz) = @_;
4529 $author =~ s/(?:^\s*|\s*$)//g;
4530 $dest->{a_raw} = $author;
4531 my $au;
4532 if ($::_authors) {
4533 $au = $rusers{$author} || undef;
4534 }
4535 if (!$au) {
4536 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4537 }
4538 $dest->{t} = $t;
4539 $dest->{tz} = $tz;
4540 $dest->{a} = $au;
4541 $dest->{t_utc} = parse_git_date($t, $tz);
4542 }
4543
4544 sub process_commit {
4545 my ($c, $r_min, $r_max, $defer) = @_;
4546 if (defined $r_min && defined $r_max) {
4547 if ($r_min == $c->{r} && $r_min == $r_max) {
4548 show_commit($c);
4549 return 0;
4550 }
4551 return 1 if $r_min == $r_max;
4552 if ($r_min < $r_max) {
4553 # we need to reverse the print order
4554 return 0 if (defined $limit && --$limit < 0);
4555 push @$defer, $c;
4556 return 1;
4557 }
4558 if ($r_min != $r_max) {
4559 return 1 if ($r_min < $c->{r});
4560 return 1 if ($r_max > $c->{r});
4561 }
4562 }
4563 return 0 if (defined $limit && --$limit < 0);
4564 show_commit($c);
4565 return 1;
4566 }
4567
4568 sub show_commit {
4569 my $c = shift;
4570 if ($oneline) {
4571 my $x = "\n";
4572 if (my $l = $c->{l}) {
4573 while ($l->[0] =~ /^\s*$/) { shift @$l }
4574 $x = $l->[0];
4575 }
4576 $l_fmt ||= 'A' . length($c->{r});
4577 print 'r',pack($l_fmt, $c->{r}),' | ';
4578 print "$c->{c} | " if $show_commit;
4579 print $x;
4580 } else {
4581 show_commit_normal($c);
4582 }
4583 }
4584
4585 sub show_commit_changed_paths {
4586 my ($c) = @_;
4587 return unless $c->{changed};
4588 print "Changed paths:\n", @{$c->{changed}};
4589 }
4590
4591 sub show_commit_normal {
4592 my ($c) = @_;
4593 print commit_log_separator, "r$c->{r} | ";
4594 print "$c->{c} | " if $show_commit;
4595 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4596 my $nr_line = 0;
4597
4598 if (my $l = $c->{l}) {
4599 while ($l->[$#$l] eq "\n" && $#$l > 0
4600 && $l->[($#$l - 1)] eq "\n") {
4601 pop @$l;
4602 }
4603 $nr_line = scalar @$l;
4604 if (!$nr_line) {
4605 print "1 line\n\n\n";
4606 } else {
4607 if ($nr_line == 1) {
4608 $nr_line = '1 line';
4609 } else {
4610 $nr_line .= ' lines';
4611 }
4612 print $nr_line, "\n";
4613 show_commit_changed_paths($c);
4614 print "\n";
4615 print $_ foreach @$l;
4616 }
4617 } else {
4618 print "1 line\n";
4619 show_commit_changed_paths($c);
4620 print "\n";
4621
4622 }
4623 foreach my $x (qw/raw stat diff/) {
4624 if ($c->{$x}) {
4625 print "\n";
4626 print $_ foreach @{$c->{$x}}
4627 }
4628 }
4629 }
4630
4631 sub cmd_show_log {
4632 my (@args) = @_;
4633 my ($r_min, $r_max);
4634 my $r_last = -1; # prevent dupes
4635 set_local_timezone();
4636 if (defined $::_revision) {
4637 if ($::_revision =~ /^(\d+):(\d+)$/) {
4638 ($r_min, $r_max) = ($1, $2);
4639 } elsif ($::_revision =~ /^\d+$/) {
4640 $r_min = $r_max = $::_revision;
4641 } else {
4642 ::fatal "-r$::_revision is not supported, use ",
4643 "standard 'git log' arguments instead";
4644 }
4645 }
4646
4647 config_pager();
4648 @args = git_svn_log_cmd($r_min, $r_max, @args);
4649 if (!@args) {
4650 print commit_log_separator unless $incremental || $oneline;
4651 return;
4652 }
4653 my $log = command_output_pipe(@args);
4654 run_pager();
4655 my (@k, $c, $d, $stat);
4656 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4657 while (<$log>) {
4658 if (/^${esc_color}commit -?($::sha1_short)/o) {
4659 my $cmt = $1;
4660 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4661 $r_last = $c->{r};
4662 process_commit($c, $r_min, $r_max, \@k) or
4663 goto out;
4664 }
4665 $d = undef;
4666 $c = { c => $cmt };
4667 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4668 get_author_info($c, $1, $2, $3);
4669 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4670 # ignore
4671 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4672 push @{$c->{raw}}, $_;
4673 } elsif (/^${esc_color}[ACRMDT]\t/) {
4674 # we could add $SVN->{svn_path} here, but that requires
4675 # remote access at the moment (repo_path_split)...
4676 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4677 push @{$c->{changed}}, $_;
4678 } elsif (/^${esc_color}diff /o) {
4679 $d = 1;
4680 push @{$c->{diff}}, $_;
4681 } elsif ($d) {
4682 push @{$c->{diff}}, $_;
4683 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4684 $esc_color*[\+\-]*$esc_color$/x) {
4685 $stat = 1;
4686 push @{$c->{stat}}, $_;
4687 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4688 push @{$c->{stat}}, $_;
4689 $stat = undef;
4690 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4691 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4692 } elsif (s/^${esc_color} //o) {
4693 push @{$c->{l}}, $_;
4694 }
4695 }
4696 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4697 $r_last = $c->{r};
4698 process_commit($c, $r_min, $r_max, \@k);
4699 }
4700 if (@k) {
4701 ($r_min, $r_max) = ($r_max, $r_min);
4702 process_commit($_, $r_min, $r_max) foreach reverse @k;
4703 }
4704 out:
4705 close $log;
4706 print commit_log_separator unless $incremental || $oneline;
4707 }
4708
4709 sub cmd_blame {
4710 my $path = pop;
4711
4712 config_pager();
4713 run_pager();
4714
4715 my ($fh, $ctx, $rev);
4716
4717 if ($_git_format) {
4718 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4719 while (my $line = <$fh>) {
4720 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4721 # Uncommitted edits show up as a rev ID of
4722 # all zeros, which we can't look up with
4723 # cmt_metadata
4724 if ($1 !~ /^0+$/) {
4725 (undef, $rev, undef) =
4726 ::cmt_metadata($1);
4727 $rev = '0' if (!$rev);
4728 } else {
4729 $rev = '0';
4730 }
4731 $rev = sprintf('%-10s', $rev);
4732 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4733 }
4734 print $line;
4735 }
4736 } else {
4737 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
4738 '--', $path);
4739 my ($sha1);
4740 my %authors;
4741 while (my $line = <$fh>) {
4742 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
4743 $sha1 = $1;
4744 (undef, $rev, undef) = ::cmt_metadata($1);
4745 $rev = '0' if (!$rev);
4746 }
4747 elsif ($line =~ /^author (.*)/) {
4748 $authors{$rev} = $1;
4749 $authors{$rev} =~ s/\s/_/g;
4750 }
4751 elsif ($line =~ /^\t(.*)$/) {
4752 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
4753 }
4754 }
4755 }
4756 command_close_pipe($fh, $ctx);
4757 }
4758
4759 package Git::SVN::Migration;
4760 # these version numbers do NOT correspond to actual version numbers
4761 # of git nor git-svn. They are just relative.
4762 #
4763 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4764 #
4765 # v1 layout: .git/$id/info/url, refs/remotes/$id
4766 #
4767 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4768 #
4769 # v3 layout: .git/svn/$id, refs/remotes/$id
4770 # - info/url may remain for backwards compatibility
4771 # - this is what we migrate up to this layout automatically,
4772 # - this will be used by git svn init on single branches
4773 # v3.1 layout (auto migrated):
4774 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4775 # for backwards compatibility
4776 #
4777 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4778 # - this is only created for newly multi-init-ed
4779 # repositories. Similar in spirit to the
4780 # --use-separate-remotes option in git-clone (now default)
4781 # - we do not automatically migrate to this (following
4782 # the example set by core git)
4783 #
4784 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4785 # - newer, more-efficient format that uses 24-bytes per record
4786 # with no filler space.
4787 # - use xxd -c24 < .rev_map.$UUID to view and debug
4788 # - This is a one-way migration, repositories updated to the
4789 # new format will not be able to use old git-svn without
4790 # rebuilding the .rev_db. Rebuilding the rev_db is not
4791 # possible if noMetadata or useSvmProps are set; but should
4792 # be no problem for users that use the (sensible) defaults.
4793 use strict;
4794 use warnings;
4795 use Carp qw/croak/;
4796 use File::Path qw/mkpath/;
4797 use File::Basename qw/dirname basename/;
4798 use vars qw/$_minimize/;
4799
4800 sub migrate_from_v0 {
4801 my $git_dir = $ENV{GIT_DIR};
4802 return undef unless -d $git_dir;
4803 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4804 my $migrated = 0;
4805 while (<$fh>) {
4806 chomp;
4807 my ($id, $orig_ref) = ($_, $_);
4808 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4809 next unless -f "$git_dir/$id/info/url";
4810 my $new_ref = "refs/remotes/$id";
4811 if (::verify_ref("$new_ref^0")) {
4812 print STDERR "W: $orig_ref is probably an old ",
4813 "branch used by an ancient version of ",
4814 "git-svn.\n",
4815 "However, $new_ref also exists.\n",
4816 "We will not be able ",
4817 "to use this branch until this ",
4818 "ambiguity is resolved.\n";
4819 next;
4820 }
4821 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4822 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4823 command_noisy('update-ref', $new_ref, $orig_ref);
4824 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4825 $migrated++;
4826 }
4827 command_close_pipe($fh, $ctx);
4828 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4829 $migrated;
4830 }
4831
4832 sub migrate_from_v1 {
4833 my $git_dir = $ENV{GIT_DIR};
4834 my $migrated = 0;
4835 return $migrated unless -d $git_dir;
4836 my $svn_dir = "$git_dir/svn";
4837
4838 # just in case somebody used 'svn' as their $id at some point...
4839 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4840
4841 print STDERR "Migrating from a git-svn v1 layout...\n";
4842 mkpath([$svn_dir]);
4843 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4844 "$svn_dir\n\t(required for this version ",
4845 "($::VERSION) of git-svn) does not exist.\n";
4846 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4847 while (<$fh>) {
4848 my $x = $_;
4849 next unless $x =~ s#^refs/remotes/##;
4850 chomp $x;
4851 next unless -f "$git_dir/$x/info/url";
4852 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4853 next unless $u;
4854 my $dn = dirname("$git_dir/svn/$x");
4855 mkpath([$dn]) unless -d $dn;
4856 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4857 mkpath(["$git_dir/svn/svn"]);
4858 print STDERR " - $git_dir/$x/info => ",
4859 "$git_dir/svn/$x/info\n";
4860 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4861 croak "$!: $x";
4862 # don't worry too much about these, they probably
4863 # don't exist with repos this old (save for index,
4864 # and we can easily regenerate that)
4865 foreach my $f (qw/unhandled.log index .rev_db/) {
4866 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4867 }
4868 } else {
4869 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4870 rename "$git_dir/$x", "$git_dir/svn/$x" or
4871 croak "$!: $x";
4872 }
4873 $migrated++;
4874 }
4875 command_close_pipe($fh, $ctx);
4876 print STDERR "Done migrating from a git-svn v1 layout\n";
4877 $migrated;
4878 }
4879
4880 sub read_old_urls {
4881 my ($l_map, $pfx, $path) = @_;
4882 my @dir;
4883 foreach (<$path/*>) {
4884 if (-r "$_/info/url") {
4885 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4886 my $ref_id = $pfx . basename $_;
4887 my $url = ::file_to_s("$_/info/url");
4888 $l_map->{$ref_id} = $url;
4889 } elsif (-d $_) {
4890 push @dir, $_;
4891 }
4892 }
4893 foreach (@dir) {
4894 my $x = $_;
4895 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4896 read_old_urls($l_map, $x, $_);
4897 }
4898 }
4899
4900 sub migrate_from_v2 {
4901 my @cfg = command(qw/config -l/);
4902 return if grep /^svn-remote\..+\.url=/, @cfg;
4903 my %l_map;
4904 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4905 my $migrated = 0;
4906
4907 foreach my $ref_id (sort keys %l_map) {
4908 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4909 if ($@) {
4910 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4911 }
4912 $migrated++;
4913 }
4914 $migrated;
4915 }
4916
4917 sub minimize_connections {
4918 my $r = Git::SVN::read_all_remotes();
4919 my $new_urls = {};
4920 my $root_repos = {};
4921 foreach my $repo_id (keys %$r) {
4922 my $url = $r->{$repo_id}->{url} or next;
4923 my $fetch = $r->{$repo_id}->{fetch} or next;
4924 my $ra = Git::SVN::Ra->new($url);
4925
4926 # skip existing cases where we already connect to the root
4927 if (($ra->{url} eq $ra->{repos_root}) ||
4928 ($ra->{repos_root} eq $repo_id)) {
4929 $root_repos->{$ra->{url}} = $repo_id;
4930 next;
4931 }
4932
4933 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4934 my $root_path = $ra->{url};
4935 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4936 foreach my $path (keys %$fetch) {
4937 my $ref_id = $fetch->{$path};
4938 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4939
4940 # make sure we can read when connecting to
4941 # a higher level of a repository
4942 my ($last_rev, undef) = $gs->last_rev_commit;
4943 if (!defined $last_rev) {
4944 $last_rev = eval {
4945 $root_ra->get_latest_revnum;
4946 };
4947 next if $@;
4948 }
4949 my $new = $root_path;
4950 $new .= length $path ? "/$path" : '';
4951 eval {
4952 $root_ra->get_log([$new], $last_rev, $last_rev,
4953 0, 0, 1, sub { });
4954 };
4955 next if $@;
4956 $new_urls->{$ra->{repos_root}}->{$new} =
4957 { ref_id => $ref_id,
4958 old_repo_id => $repo_id,
4959 old_path => $path };
4960 }
4961 }
4962
4963 my @emptied;
4964 foreach my $url (keys %$new_urls) {
4965 # see if we can re-use an existing [svn-remote "repo_id"]
4966 # instead of creating a(n ugly) new section:
4967 my $repo_id = $root_repos->{$url} || $url;
4968
4969 my $fetch = $new_urls->{$url};
4970 foreach my $path (keys %$fetch) {
4971 my $x = $fetch->{$path};
4972 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4973 my $pfx = "svn-remote.$x->{old_repo_id}";
4974
4975 my $old_fetch = quotemeta("$x->{old_path}:".
4976 "refs/remotes/$x->{ref_id}");
4977 command_noisy(qw/config --unset/,
4978 "$pfx.fetch", '^'. $old_fetch . '$');
4979 delete $r->{$x->{old_repo_id}}->
4980 {fetch}->{$x->{old_path}};
4981 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4982 command_noisy(qw/config --unset/,
4983 "$pfx.url");
4984 push @emptied, $x->{old_repo_id}
4985 }
4986 }
4987 }
4988 if (@emptied) {
4989 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4990 "$ENV{GIT_DIR}/config";
4991 print STDERR <<EOF;
4992 The following [svn-remote] sections in your config file ($file) are empty
4993 and can be safely removed:
4994 EOF
4995 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4996 }
4997 }
4998
4999 sub migration_check {
5000 migrate_from_v0();
5001 migrate_from_v1();
5002 migrate_from_v2();
5003 minimize_connections() if $_minimize;
5004 }
5005
5006 package Git::IndexInfo;
5007 use strict;
5008 use warnings;
5009 use Git qw/command_input_pipe command_close_pipe/;
5010
5011 sub new {
5012 my ($class) = @_;
5013 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5014 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5015 }
5016
5017 sub remove {
5018 my ($self, $path) = @_;
5019 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5020 return ++$self->{nr};
5021 }
5022 undef;
5023 }
5024
5025 sub update {
5026 my ($self, $mode, $hash, $path) = @_;
5027 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5028 return ++$self->{nr};
5029 }
5030 undef;
5031 }
5032
5033 sub DESTROY {
5034 my ($self) = @_;
5035 command_close_pipe($self->{gui}, $self->{ctx});
5036 }
5037
5038 package Git::SVN::GlobSpec;
5039 use strict;
5040 use warnings;
5041
5042 sub new {
5043 my ($class, $glob) = @_;
5044 my $re = $glob;
5045 $re =~ s!/+$!!g; # no need for trailing slashes
5046 $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5047 my $temp = $re;
5048 my ($left, $right) = ($1, $3);
5049 $re = $2;
5050 my $depth = $re =~ tr/*/*/;
5051 if ($depth != $temp =~ tr/*/*/) {
5052 die "Only one set of wildcard directories " .
5053 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5054 }
5055 if ($depth == 0) {
5056 die "One '*' is needed for glob: '$glob'\n";
5057 }
5058 $re =~ s!\*!\[^/\]*!g;
5059 $re = quotemeta($left) . "($re)" . quotemeta($right);
5060 if (length $left && !($left =~ s!/+$!!g)) {
5061 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5062 }
5063 if (length $right && !($right =~ s!^/+!!g)) {
5064 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5065 }
5066 my $left_re = qr/^\/\Q$left\E(\/|$)/;
5067 bless { left => $left, right => $right, left_regex => $left_re,
5068 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5069 }
5070
5071 sub full_path {
5072 my ($self, $path) = @_;
5073 return (length $self->{left} ? "$self->{left}/" : '') .
5074 $path . (length $self->{right} ? "/$self->{right}" : '');
5075 }
5076
5077 __END__
5078
5079 Data structures:
5080
5081
5082 $remotes = { # returned by read_all_remotes()
5083 'svn' => {
5084 # svn-remote.svn.url=https://svn.musicpd.org
5085 url => 'https://svn.musicpd.org',
5086 # svn-remote.svn.fetch=mpd/trunk:trunk
5087 fetch => {
5088 'mpd/trunk' => 'trunk',
5089 },
5090 # svn-remote.svn.tags=mpd/tags/*:tags/*
5091 tags => {
5092 path => {
5093 left => 'mpd/tags',
5094 right => '',
5095 regex => qr!mpd/tags/([^/]+)$!,
5096 glob => 'tags/*',
5097 },
5098 ref => {
5099 left => 'tags',
5100 right => '',
5101 regex => qr!tags/([^/]+)$!,
5102 glob => 'tags/*',
5103 },
5104 }
5105 }
5106 };
5107
5108 $log_entry hashref as returned by libsvn_log_entry()
5109 {
5110 log => 'whitespace-formatted log entry
5111 ', # trailing newline is preserved
5112 revision => '8', # integer
5113 date => '2004-02-24T17:01:44.108345Z', # commit date
5114 author => 'committer name'
5115 };
5116
5117
5118 # this is generated by generate_diff();
5119 @mods = array of diff-index line hashes, each element represents one line
5120 of diff-index output
5121
5122 diff-index line ($m hash)
5123 {
5124 mode_a => first column of diff-index output, no leading ':',
5125 mode_b => second column of diff-index output,
5126 sha1_b => sha1sum of the final blob,
5127 chg => change type [MCRADT],
5128 file_a => original file name of a file (iff chg is 'C' or 'R')
5129 file_b => new/current file name of a file (any chg)
5130 }
5131 ;
5132
5133 # retval of read_url_paths{,_all}();
5134 $l_map = {
5135 # repository root url
5136 'https://svn.musicpd.org' => {
5137 # repository path # GIT_SVN_ID
5138 'mpd/trunk' => 'trunk',
5139 'mpd/tags/0.11.5' => 'tags/0.11.5',
5140 },
5141 }
5142
5143 Notes:
5144 I don't trust the each() function on unless I created %hash myself
5145 because the internal iterator may not have started at base.
git with Jakub Narębski modifications