gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 our $cgi = new CGI;
  22 our $version = "++GIT_VERSION++";
  23 our $my_url = $cgi->url();
  24 our $my_uri = $cgi->url(-absolute => 1);
  25
  26 # core git executable to use
  27 # this can just be "git" if your webserver has a sensible PATH
  28 our $GIT = "++GIT_BINDIR++/git";
  29
  30 # absolute fs-path which will be prepended to the project path
  31 #our $projectroot = "/pub/scm";
  32 our $projectroot = "++GITWEB_PROJECTROOT++";
  33
  34 # target of the home link on top of all pages
  35 our $home_link = $my_uri || "/";
  36
  37 # string of the home link on top of all pages
  38 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  39
  40 # name of your site or organization to appear in page titles
  41 # replace this with something more descriptive for clearer bookmarks
  42 our $site_name = "++GITWEB_SITENAME++"
  43                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  44
  45 # filename of html text to include at top of each page
  46 our $site_header = "++GITWEB_SITE_HEADER++";
  47 # html text to include at home page
  48 our $home_text = "++GITWEB_HOMETEXT++";
  49 # filename of html text to include at bottom of each page
  50 our $site_footer = "++GITWEB_SITE_FOOTER++";
  51
  52 # URI of stylesheets
  53 our @stylesheets = ("++GITWEB_CSS++");
  54 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  55 our $stylesheet = undef;
  56 # URI of GIT logo (72x27 size)
  57 our $logo = "++GITWEB_LOGO++";
  58 # URI of GIT favicon, assumed to be image/png type
  59 our $favicon = "++GITWEB_FAVICON++";
  60
  61 # URI and label (title) of GIT logo link
  62 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
  63 #our $logo_label = "git documentation";
  64 our $logo_url = "http://git.or.cz/";
  65 our $logo_label = "git homepage";
  66
  67 # source of projects list
  68 our $projects_list = "++GITWEB_LIST++";
  69
  70 # show repository only if this file exists
  71 # (only effective if this variable evaluates to true)
  72 our $export_ok = "++GITWEB_EXPORT_OK++";
  73
  74 # only allow viewing of repositories also shown on the overview page
  75 our $strict_export = "++GITWEB_STRICT_EXPORT++";
  76
  77 # list of git base URLs used for URL to where fetch project from,
  78 # i.e. full URL is "$git_base_url/$project"
  79 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
  80
  81 # default blob_plain mimetype and default charset for text/plain blob
  82 our $default_blob_plain_mimetype = 'text/plain';
  83 our $default_text_plain_charset  = undef;
  84
  85 # file to use for guessing MIME types before trying /etc/mime.types
  86 # (relative to the current git repository)
  87 our $mimetypes_file = undef;
  88
  89 # You define site-wide feature defaults here; override them with
  90 # $GITWEB_CONFIG as necessary.
  91 our %feature = (
  92         # feature => {
  93         #       'sub' => feature-sub (subroutine),
  94         #       'override' => allow-override (boolean),
  95         #       'default' => [ default options...] (array reference)}
  96         #
  97         # if feature is overridable (it means that allow-override has true value,
  98         # then feature-sub will be called with default options as parameters;
  99         # return value of feature-sub indicates if to enable specified feature
 100         #
 101         # use gitweb_check_feature(<feature>) to check if <feature> is enabled
 102
 103         # Enable the 'blame' blob view, showing the last commit that modified
 104         # each line in the file. This can be very CPU-intensive.
 105
 106         # To enable system wide have in $GITWEB_CONFIG
 107         # $feature{'blame'}{'default'} = [1];
 108         # To have project specific config enable override in $GITWEB_CONFIG
 109         # $feature{'blame'}{'override'} = 1;
 110         # and in project config gitweb.blame = 0|1;
 111         'blame' => {
 112                 'sub' => \&feature_blame,
 113                 'override' => 0,
 114                 'default' => [0]},
 115
 116         # Enable the 'snapshot' link, providing a compressed tarball of any
 117         # tree. This can potentially generate high traffic if you have large
 118         # project.
 119
 120         # To disable system wide have in $GITWEB_CONFIG
 121         # $feature{'snapshot'}{'default'} = [undef];
 122         # To have project specific config enable override in $GITWEB_CONFIG
 123         # $feature{'blame'}{'override'} = 1;
 124         # and in project config gitweb.snapshot = none|gzip|bzip2;
 125         'snapshot' => {
 126                 'sub' => \&feature_snapshot,
 127                 'override' => 0,
 128                 #         => [content-encoding, suffix, program]
 129                 'default' => ['x-gzip', 'gz', 'gzip']},
 130
 131         # Enable the pickaxe search, which will list the commits that modified
 132         # a given string in a file. This can be practical and quite faster
 133         # alternative to 'blame', but still potentially CPU-intensive.
 134
 135         # To enable system wide have in $GITWEB_CONFIG
 136         # $feature{'pickaxe'}{'default'} = [1];
 137         # To have project specific config enable override in $GITWEB_CONFIG
 138         # $feature{'pickaxe'}{'override'} = 1;
 139         # and in project config gitweb.pickaxe = 0|1;
 140         'pickaxe' => {
 141                 'sub' => \&feature_pickaxe,
 142                 'override' => 0,
 143                 'default' => [1]},
 144
 145         # Make gitweb use an alternative format of the URLs which can be
 146         # more readable and natural-looking: project name is embedded
 147         # directly in the path and the query string contains other
 148         # auxiliary information. All gitweb installations recognize
 149         # URL in either format; this configures in which formats gitweb
 150         # generates links.
 151
 152         # To enable system wide have in $GITWEB_CONFIG
 153         # $feature{'pathinfo'}{'default'} = [1];
 154         # Project specific override is not supported.
 155
 156         # Note that you will need to change the default location of CSS,
 157         # favicon, logo and possibly other files to an absolute URL. Also,
 158         # if gitweb.cgi serves as your indexfile, you will need to force
 159         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 160         'pathinfo' => {
 161                 'override' => 0,
 162                 'default' => [0]},
 163
 164         # Make gitweb consider projects in project root subdirectories
 165         # to be forks of existing projects. Given project $projname.git,
 166         # projects matching $projname/*.git will not be shown in the main
 167         # projects list, instead a '+' mark will be added to $projname
 168         # there and a 'forks' view will be enabled for the project, listing
 169         # all the forks. This feature is supported only if project list
 170         # is taken from a directory, not file.
 171
 172         # To enable system wide have in $GITWEB_CONFIG
 173         # $feature{'forks'}{'default'} = [1];
 174         # Project specific override is not supported.
 175         'forks' => {
 176                 'override' => 0,
 177                 'default' => [0]},
 178 );
 179
 180 sub gitweb_check_feature {
 181         my ($name) = @_;
 182         return unless exists $feature{$name};
 183         my ($sub, $override, @defaults) = (
 184                 $feature{$name}{'sub'},
 185                 $feature{$name}{'override'},
 186                 @{$feature{$name}{'default'}});
 187         if (!$override) { return @defaults; }
 188         if (!defined $sub) {
 189                 warn "feature $name is not overrideable";
 190                 return @defaults;
 191         }
 192         return $sub->(@defaults);
 193 }
 194
 195 sub feature_blame {
 196         my ($val) = git_get_project_config('blame', '--bool');
 197
 198         if ($val eq 'true') {
 199                 return 1;
 200         } elsif ($val eq 'false') {
 201                 return 0;
 202         }
 203
 204         return $_[0];
 205 }
 206
 207 sub feature_snapshot {
 208         my ($ctype, $suffix, $command) = @_;
 209
 210         my ($val) = git_get_project_config('snapshot');
 211
 212         if ($val eq 'gzip') {
 213                 return ('x-gzip', 'gz', 'gzip');
 214         } elsif ($val eq 'bzip2') {
 215                 return ('x-bzip2', 'bz2', 'bzip2');
 216         } elsif ($val eq 'none') {
 217                 return ();
 218         }
 219
 220         return ($ctype, $suffix, $command);
 221 }
 222
 223 sub gitweb_have_snapshot {
 224         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
 225         my $have_snapshot = (defined $ctype && defined $suffix);
 226
 227         return $have_snapshot;
 228 }
 229
 230 sub feature_pickaxe {
 231         my ($val) = git_get_project_config('pickaxe', '--bool');
 232
 233         if ($val eq 'true') {
 234                 return (1);
 235         } elsif ($val eq 'false') {
 236                 return (0);
 237         }
 238
 239         return ($_[0]);
 240 }
 241
 242 # checking HEAD file with -e is fragile if the repository was
 243 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 244 # and then pruned.
 245 sub check_head_link {
 246         my ($dir) = @_;
 247         my $headfile = "$dir/HEAD";
 248         return ((-e $headfile) ||
 249                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 250 }
 251
 252 sub check_export_ok {
 253         my ($dir) = @_;
 254         return (check_head_link($dir) &&
 255                 (!$export_ok || -e "$dir/$export_ok"));
 256 }
 257
 258 # rename detection options for git-diff and git-diff-tree
 259 # - default is '-M', with the cost proportional to
 260 #   (number of removed files) * (number of new files).
 261 # - more costly is '-C' (or '-C', '-M'), with the cost proportional to
 262 #   (number of changed files + number of removed files) * (number of new files)
 263 # - even more costly is '-C', '--find-copies-harder' with cost
 264 #   (number of files in the original tree) * (number of new files)
 265 # - one might want to include '-B' option, e.g. '-B', '-M'
 266 our @diff_opts = ('-M'); # taken from git_commit
 267
 268 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 269 do $GITWEB_CONFIG if -e $GITWEB_CONFIG;
 270
 271 # version of the core git binary
 272 our $git_version = qx($GIT --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 273
 274 $projects_list ||= $projectroot;
 275
 276 # ======================================================================
 277 # input validation and dispatch
 278 our $action = $cgi->param('a');
 279 if (defined $action) {
 280         if ($action =~ m/[^0-9a-zA-Z\.\-_]/) {
 281                 die_error(undef, "Invalid action parameter");
 282         }
 283 }
 284
 285 # parameters which are pathnames
 286 our $project = $cgi->param('p');
 287 if (defined $project) {
 288         if (!validate_pathname($project) ||
 289             !(-d "$projectroot/$project") ||
 290             !check_head_link("$projectroot/$project") ||
 291             ($export_ok && !(-e "$projectroot/$project/$export_ok")) ||
 292             ($strict_export && !project_in_list($project))) {
 293                 undef $project;
 294                 die_error(undef, "No such project");
 295         }
 296 }
 297
 298 our $file_name = $cgi->param('f');
 299 if (defined $file_name) {
 300         if (!validate_pathname($file_name)) {
 301                 die_error(undef, "Invalid file parameter");
 302         }
 303 }
 304
 305 our $file_parent = $cgi->param('fp');
 306 if (defined $file_parent) {
 307         if (!validate_pathname($file_parent)) {
 308                 die_error(undef, "Invalid file parent parameter");
 309         }
 310 }
 311
 312 # parameters which are refnames
 313 our $hash = $cgi->param('h');
 314 if (defined $hash) {
 315         if (!validate_refname($hash)) {
 316                 die_error(undef, "Invalid hash parameter");
 317         }
 318 }
 319
 320 our $hash_parent = $cgi->param('hp');
 321 if (defined $hash_parent) {
 322         if (!validate_refname($hash_parent)) {
 323                 die_error(undef, "Invalid hash parent parameter");
 324         }
 325 }
 326
 327 our $hash_base = $cgi->param('hb');
 328 if (defined $hash_base) {
 329         if (!validate_refname($hash_base)) {
 330                 die_error(undef, "Invalid hash base parameter");
 331         }
 332 }
 333
 334 our $hash_parent_base = $cgi->param('hpb');
 335 if (defined $hash_parent_base) {
 336         if (!validate_refname($hash_parent_base)) {
 337                 die_error(undef, "Invalid hash parent base parameter");
 338         }
 339 }
 340
 341 # other parameters
 342 our $page = $cgi->param('pg');
 343 if (defined $page) {
 344         if ($page =~ m/[^0-9]/) {
 345                 die_error(undef, "Invalid page parameter");
 346         }
 347 }
 348
 349 our $searchtext = $cgi->param('s');
 350 if (defined $searchtext) {
 351         if ($searchtext =~ m/[^a-zA-Z0-9_\.\/\-\+\:\@ ]/) {
 352                 die_error(undef, "Invalid search parameter");
 353         }
 354         $searchtext = quotemeta $searchtext;
 355 }
 356
 357 our $searchtype = $cgi->param('st');
 358 if (defined $searchtype) {
 359         if ($searchtype =~ m/[^a-z]/) {
 360                 die_error(undef, "Invalid searchtype parameter");
 361         }
 362 }
 363
 364 # now read PATH_INFO and use it as alternative to parameters
 365 sub evaluate_path_info {
 366         return if defined $project;
 367         my $path_info = $ENV{"PATH_INFO"};
 368         return if !$path_info;
 369         $path_info =~ s,^/+,,;
 370         return if !$path_info;
 371         # find which part of PATH_INFO is project
 372         $project = $path_info;
 373         $project =~ s,/+$,,;
 374         while ($project && !check_head_link("$projectroot/$project")) {
 375                 $project =~ s,/*[^/]*$,,;
 376         }
 377         # validate project
 378         $project = validate_pathname($project);
 379         if (!$project ||
 380             ($export_ok && !-e "$projectroot/$project/$export_ok") ||
 381             ($strict_export && !project_in_list($project))) {
 382                 undef $project;
 383                 return;
 384         }
 385         # do not change any parameters if an action is given using the query string
 386         return if $action;
 387         $path_info =~ s,^$project/*,,;
 388         my ($refname, $pathname) = split(/:/, $path_info, 2);
 389         if (defined $pathname) {
 390                 # we got "project.git/branch:filename" or "project.git/branch:dir/"
 391                 # we could use git_get_type(branch:pathname), but it needs $git_dir
 392                 $pathname =~ s,^/+,,;
 393                 if (!$pathname || substr($pathname, -1) eq "/") {
 394                         $action  ||= "tree";
 395                         $pathname =~ s,/$,,;
 396                 } else {
 397                         $action  ||= "blob_plain";
 398                 }
 399                 $hash_base ||= validate_refname($refname);
 400                 $file_name ||= validate_pathname($pathname);
 401         } elsif (defined $refname) {
 402                 # we got "project.git/branch"
 403                 $action ||= "shortlog";
 404                 $hash   ||= validate_refname($refname);
 405         }
 406 }
 407 evaluate_path_info();
 408
 409 # path to the current git repository
 410 our $git_dir;
 411 $git_dir = "$projectroot/$project" if $project;
 412
 413 # dispatch
 414 my %actions = (
 415         "blame" => \&git_blame2,
 416         "blobdiff" => \&git_blobdiff,
 417         "blobdiff_plain" => \&git_blobdiff_plain,
 418         "blob" => \&git_blob,
 419         "blob_plain" => \&git_blob_plain,
 420         "commitdiff" => \&git_commitdiff,
 421         "commitdiff_plain" => \&git_commitdiff_plain,
 422         "commit" => \&git_commit,
 423         "forks" => \&git_forks,
 424         "heads" => \&git_heads,
 425         "history" => \&git_history,
 426         "log" => \&git_log,
 427         "rss" => \&git_rss,
 428         "search" => \&git_search,
 429         "search_help" => \&git_search_help,
 430         "shortlog" => \&git_shortlog,
 431         "summary" => \&git_summary,
 432         "tag" => \&git_tag,
 433         "tags" => \&git_tags,
 434         "tree" => \&git_tree,
 435         "snapshot" => \&git_snapshot,
 436         # those below don't need $project
 437         "opml" => \&git_opml,
 438         "project_list" => \&git_project_list,
 439         "project_index" => \&git_project_index,
 440 );
 441
 442 if (defined $project) {
 443         $action ||= 'summary';
 444 } else {
 445         $action ||= 'project_list';
 446 }
 447 if (!defined($actions{$action})) {
 448         die_error(undef, "Unknown action");
 449 }
 450 if ($action !~ m/^(opml|project_list|project_index)$/ &&
 451     !$project) {
 452         die_error(undef, "Project needed");
 453 }
 454 $actions{$action}->();
 455 exit;
 456
 457 ## ======================================================================
 458 ## action links
 459
 460 sub href(%) {
 461         my %params = @_;
 462         my $href = $my_uri;
 463
 464         # XXX: Warning: If you touch this, check the search form for updating,
 465         # too.
 466
 467         my @mapping = (
 468                 project => "p",
 469                 action => "a",
 470                 file_name => "f",
 471                 file_parent => "fp",
 472                 hash => "h",
 473                 hash_parent => "hp",
 474                 hash_base => "hb",
 475                 hash_parent_base => "hpb",
 476                 page => "pg",
 477                 order => "o",
 478                 searchtext => "s",
 479                 searchtype => "st",
 480         );
 481         my %mapping = @mapping;
 482
 483         $params{'project'} = $project unless exists $params{'project'};
 484
 485         my ($use_pathinfo) = gitweb_check_feature('pathinfo');
 486         if ($use_pathinfo) {
 487                 # use PATH_INFO for project name
 488                 $href .= "/$params{'project'}" if defined $params{'project'};
 489                 delete $params{'project'};
 490
 491                 # Summary just uses the project path URL
 492                 if (defined $params{'action'} && $params{'action'} eq 'summary') {
 493                         delete $params{'action'};
 494                 }
 495         }
 496
 497         # now encode the parameters explicitly
 498         my @result = ();
 499         for (my $i = 0; $i < @mapping; $i += 2) {
 500                 my ($name, $symbol) = ($mapping[$i], $mapping[$i+1]);
 501                 if (defined $params{$name}) {
 502                         push @result, $symbol . "=" . esc_param($params{$name});
 503                 }
 504         }
 505         $href .= "?" . join(';', @result) if scalar @result;
 506
 507         return $href;
 508 }
 509
 510
 511 ## ======================================================================
 512 ## validation, quoting/unquoting and escaping
 513
 514 sub validate_pathname {
 515         my $input = shift || return undef;
 516
 517         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
 518         # at the beginning, at the end, and between slashes.
 519         # also this catches doubled slashes
 520         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
 521                 return undef;
 522         }
 523         # no null characters
 524         if ($input =~ m!\0!) {
 525                 return undef;
 526         }
 527         return $input;
 528 }
 529
 530 sub validate_refname {
 531         my $input = shift || return undef;
 532
 533         # textual hashes are O.K.
 534         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
 535                 return $input;
 536         }
 537         # it must be correct pathname
 538         $input = validate_pathname($input)
 539                 or return undef;
 540         # restrictions on ref name according to git-check-ref-format
 541         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
 542                 return undef;
 543         }
 544         return $input;
 545 }
 546
 547 # very thin wrapper for decode("utf8", $str, Encode::FB_DEFAULT);
 548 sub to_utf8 {
 549         my $str = shift;
 550         return decode("utf8", $str, Encode::FB_DEFAULT);
 551 }
 552
 553 # quote unsafe chars, but keep the slash, even when it's not
 554 # correct, but quoted slashes look too horrible in bookmarks
 555 sub esc_param {
 556         my $str = shift;
 557         $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
 558         $str =~ s/\+/%2B/g;
 559         $str =~ s/ /\+/g;
 560         return $str;
 561 }
 562
 563 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
 564 sub esc_url {
 565         my $str = shift;
 566         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
 567         $str =~ s/\+/%2B/g;
 568         $str =~ s/ /\+/g;
 569         return $str;
 570 }
 571
 572 # replace invalid utf8 character with SUBSTITUTION sequence
 573 sub esc_html ($;%) {
 574         my $str = shift;
 575         my %opts = @_;
 576
 577         $str = to_utf8($str);
 578         $str = escapeHTML($str);
 579         $str =~ s/\014/^L/g; # escape FORM FEED (FF) character (e.g. in COPYING file)
 580         $str =~ s/\033/^[/g; # "escape" ESCAPE (\e) character (e.g. commit 20a3847d8a5032ce41f90dcc68abfb36e6fee9b1)
 581         if ($opts{'-nbsp'}) {
 582                 $str =~ s/ /&nbsp;/g;
 583         }
 584         return $str;
 585 }
 586
 587 # git may return quoted and escaped filenames
 588 sub unquote {
 589         my $str = shift;
 590         if ($str =~ m/^"(.*)"$/) {
 591                 $str = $1;
 592                 $str =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 593         }
 594         return $str;
 595 }
 596
 597 # escape tabs (convert tabs to spaces)
 598 sub untabify {
 599         my $line = shift;
 600
 601         while ((my $pos = index($line, "\t")) != -1) {
 602                 if (my $count = (8 - ($pos % 8))) {
 603                         my $spaces = ' ' x $count;
 604                         $line =~ s/\t/$spaces/;
 605                 }
 606         }
 607
 608         return $line;
 609 }
 610
 611 sub project_in_list {
 612         my $project = shift;
 613         my @list = git_get_projects_list();
 614         return @list && scalar(grep { $_->{'path'} eq $project } @list);
 615 }
 616
 617 ## ----------------------------------------------------------------------
 618 ## HTML aware string manipulation
 619
 620 sub chop_str {
 621         my $str = shift;
 622         my $len = shift;
 623         my $add_len = shift || 10;
 624
 625         # allow only $len chars, but don't cut a word if it would fit in $add_len
 626         # if it doesn't fit, cut it if it's still longer than the dots we would add
 627         $str =~ m/^(.{0,$len}[^ \/\-_:\.@]{0,$add_len})(.*)/;
 628         my $body = $1;
 629         my $tail = $2;
 630         if (length($tail) > 4) {
 631                 $tail = " ...";
 632                 $body =~ s/&[^;]*$//; # remove chopped character entities
 633         }
 634         return "$body$tail";
 635 }
 636
 637 ## ----------------------------------------------------------------------
 638 ## functions returning short strings
 639
 640 # CSS class for given age value (in seconds)
 641 sub age_class {
 642         my $age = shift;
 643
 644         if ($age < 60*60*2) {
 645                 return "age0";
 646         } elsif ($age < 60*60*24*2) {
 647                 return "age1";
 648         } else {
 649                 return "age2";
 650         }
 651 }
 652
 653 # convert age in seconds to "nn units ago" string
 654 sub age_string {
 655         my $age = shift;
 656         my $age_str;
 657
 658         if ($age > 60*60*24*365*2) {
 659                 $age_str = (int $age/60/60/24/365);
 660                 $age_str .= " years ago";
 661         } elsif ($age > 60*60*24*(365/12)*2) {
 662                 $age_str = int $age/60/60/24/(365/12);
 663                 $age_str .= " months ago";
 664         } elsif ($age > 60*60*24*7*2) {
 665                 $age_str = int $age/60/60/24/7;
 666                 $age_str .= " weeks ago";
 667         } elsif ($age > 60*60*24*2) {
 668                 $age_str = int $age/60/60/24;
 669                 $age_str .= " days ago";
 670         } elsif ($age > 60*60*2) {
 671                 $age_str = int $age/60/60;
 672                 $age_str .= " hours ago";
 673         } elsif ($age > 60*2) {
 674                 $age_str = int $age/60;
 675                 $age_str .= " min ago";
 676         } elsif ($age > 2) {
 677                 $age_str = int $age;
 678                 $age_str .= " sec ago";
 679         } else {
 680                 $age_str .= " right now";
 681         }
 682         return $age_str;
 683 }
 684
 685 # convert file mode in octal to symbolic file mode string
 686 sub mode_str {
 687         my $mode = oct shift;
 688
 689         if (S_ISDIR($mode & S_IFMT)) {
 690                 return 'drwxr-xr-x';
 691         } elsif (S_ISLNK($mode)) {
 692                 return 'lrwxrwxrwx';
 693         } elsif (S_ISREG($mode)) {
 694                 # git cares only about the executable bit
 695                 if ($mode & S_IXUSR) {
 696                         return '-rwxr-xr-x';
 697                 } else {
 698                         return '-rw-r--r--';
 699                 };
 700         } else {
 701                 return '----------';
 702         }
 703 }
 704
 705 # convert file mode in octal to file type string
 706 sub file_type {
 707         my $mode = shift;
 708
 709         if ($mode !~ m/^[0-7]+$/) {
 710                 return $mode;
 711         } else {
 712                 $mode = oct $mode;
 713         }
 714
 715         if (S_ISDIR($mode & S_IFMT)) {
 716                 return "directory";
 717         } elsif (S_ISLNK($mode)) {
 718                 return "symlink";
 719         } elsif (S_ISREG($mode)) {
 720                 return "file";
 721         } else {
 722                 return "unknown";
 723         }
 724 }
 725
 726 ## ----------------------------------------------------------------------
 727 ## functions returning short HTML fragments, or transforming HTML fragments
 728 ## which don't beling to other sections
 729
 730 # format line of commit message or tag comment
 731 sub format_log_line_html {
 732         my $line = shift;
 733
 734         $line = esc_html($line);
 735         $line =~ s/ /&nbsp;/g;
 736         if ($line =~ m/([0-9a-fA-F]{40})/) {
 737                 my $hash_text = $1;
 738                 if (git_get_type($hash_text) eq "commit") {
 739                         my $link =
 740                                 $cgi->a({-href => href(action=>"commit", hash=>$hash_text),
 741                                         -class => "text"}, $hash_text);
 742                         $line =~ s/$hash_text/$link/;
 743                 }
 744         }
 745         return $line;
 746 }
 747
 748 # format marker of refs pointing to given object
 749 sub format_ref_marker {
 750         my ($refs, $id) = @_;
 751         my $markers = '';
 752
 753         if (defined $refs->{$id}) {
 754                 foreach my $ref (@{$refs->{$id}}) {
 755                         my ($type, $name) = qw();
 756                         # e.g. tags/v2.6.11 or heads/next
 757                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
 758                                 $type = $1;
 759                                 $name = $2;
 760                         } else {
 761                                 $type = "ref";
 762                                 $name = $ref;
 763                         }
 764
 765                         $markers .= " <span class=\"$type\">" . esc_html($name) . "</span>";
 766                 }
 767         }
 768
 769         if ($markers) {
 770                 return ' <span class="refs">'. $markers . '</span>';
 771         } else {
 772                 return "";
 773         }
 774 }
 775
 776 # format, perhaps shortened and with markers, title line
 777 sub format_subject_html {
 778         my ($long, $short, $href, $extra) = @_;
 779         $extra = '' unless defined($extra);
 780
 781         if (length($short) < length($long)) {
 782                 return $cgi->a({-href => $href, -class => "list subject",
 783                                 -title => to_utf8($long)},
 784                        esc_html($short) . $extra);
 785         } else {
 786                 return $cgi->a({-href => $href, -class => "list subject"},
 787                        esc_html($long)  . $extra);
 788         }
 789 }
 790
 791 sub format_diff_line {
 792         my $line = shift;
 793         my $char = substr($line, 0, 1);
 794         my $diff_class = "";
 795
 796         chomp $line;
 797
 798         if ($char eq '+') {
 799                 $diff_class = " add";
 800         } elsif ($char eq "-") {
 801                 $diff_class = " rem";
 802         } elsif ($char eq "@") {
 803                 $diff_class = " chunk_header";
 804         } elsif ($char eq "\\") {
 805                 $diff_class = " incomplete";
 806         }
 807         $line = untabify($line);
 808         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
 809 }
 810
 811 ## ----------------------------------------------------------------------
 812 ## git utility subroutines, invoking git commands
 813
 814 # returns path to the core git executable and the --git-dir parameter as list
 815 sub git_cmd {
 816         return $GIT, '--git-dir='.$git_dir;
 817 }
 818
 819 # returns path to the core git executable and the --git-dir parameter as string
 820 sub git_cmd_str {
 821         return join(' ', git_cmd());
 822 }
 823
 824 # get HEAD ref of given project as hash
 825 sub git_get_head_hash {
 826         my $project = shift;
 827         my $o_git_dir = $git_dir;
 828         my $retval = undef;
 829         $git_dir = "$projectroot/$project";
 830         if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
 831                 my $head = <$fd>;
 832                 close $fd;
 833                 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
 834                         $retval = $1;
 835                 }
 836         }
 837         if (defined $o_git_dir) {
 838                 $git_dir = $o_git_dir;
 839         }
 840         return $retval;
 841 }
 842
 843 # get type of given object
 844 sub git_get_type {
 845         my $hash = shift;
 846
 847         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
 848         my $type = <$fd>;
 849         close $fd or return;
 850         chomp $type;
 851         return $type;
 852 }
 853
 854 sub git_get_project_config {
 855         my ($key, $type) = @_;
 856
 857         return unless ($key);
 858         $key =~ s/^gitweb\.//;
 859         return if ($key =~ m/\W/);
 860
 861         my @x = (git_cmd(), 'repo-config');
 862         if (defined $type) { push @x, $type; }
 863         push @x, "--get";
 864         push @x, "gitweb.$key";
 865         my $val = qx(@x);
 866         chomp $val;
 867         return ($val);
 868 }
 869
 870 # get hash of given path at given ref
 871 sub git_get_hash_by_path {
 872         my $base = shift;
 873         my $path = shift || return undef;
 874         my $type = shift;
 875
 876         $path =~ s,/+$,,;
 877
 878         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
 879                 or die_error(undef, "Open git-ls-tree failed");
 880         my $line = <$fd>;
 881         close $fd or return undef;
 882
 883         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 884         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
 885         if (defined $type && $type ne $2) {
 886                 # type doesn't match
 887                 return undef;
 888         }
 889         return $3;
 890 }
 891
 892 ## ......................................................................
 893 ## git utility functions, directly accessing git repository
 894
 895 sub git_get_project_description {
 896         my $path = shift;
 897
 898         open my $fd, "$projectroot/$path/description" or return undef;
 899         my $descr = <$fd>;
 900         close $fd;
 901         chomp $descr;
 902         return $descr;
 903 }
 904
 905 sub git_get_project_url_list {
 906         my $path = shift;
 907
 908         open my $fd, "$projectroot/$path/cloneurl" or return;
 909         my @git_project_url_list = map { chomp; $_ } <$fd>;
 910         close $fd;
 911
 912         return wantarray ? @git_project_url_list : \@git_project_url_list;
 913 }
 914
 915 sub git_get_projects_list {
 916         my ($filter) = @_;
 917         my @list;
 918
 919         $filter ||= '';
 920         $filter =~ s/\.git$//;
 921
 922         if (-d $projects_list) {
 923                 # search in directory
 924                 my $dir = $projects_list . ($filter ? "/$filter" : '');
 925                 # remove the trailing "/"
 926                 $dir =~ s!/+$!!;
 927                 my $pfxlen = length("$dir");
 928
 929                 my $check_forks = gitweb_check_feature('forks');
 930
 931                 File::Find::find({
 932                         follow_fast => 1, # follow symbolic links
 933                         dangling_symlinks => 0, # ignore dangling symlinks, silently
 934                         wanted => sub {
 935                                 # skip project-list toplevel, if we get it.
 936                                 return if (m!^[/.]$!);
 937                                 # only directories can be git repositories
 938                                 return unless (-d $_);
 939
 940                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
 941                                 # we check related file in $projectroot
 942                                 if ($check_forks and $subdir =~ m#/.#) {
 943                                         $File::Find::prune = 1;
 944                                 } elsif (check_export_ok("$projectroot/$filter/$subdir")) {
 945                                         push @list, { path => ($filter ? "$filter/" : '') . $subdir };
 946                                         $File::Find::prune = 1;
 947                                 }
 948                         },
 949                 }, "$dir");
 950
 951         } elsif (-f $projects_list) {
 952                 # read from file(url-encoded):
 953                 # 'git%2Fgit.git Linus+Torvalds'
 954                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
 955                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
 956                 open my ($fd), $projects_list or return;
 957                 while (my $line = <$fd>) {
 958                         chomp $line;
 959                         my ($path, $owner) = split ' ', $line;
 960                         $path = unescape($path);
 961                         $owner = unescape($owner);
 962                         if (!defined $path) {
 963                                 next;
 964                         }
 965                         if (check_export_ok("$projectroot/$path")) {
 966                                 my $pr = {
 967                                         path => $path,
 968                                         owner => to_utf8($owner),
 969                                 };
 970                                 push @list, $pr
 971                         }
 972                 }
 973                 close $fd;
 974         }
 975         @list = sort {$a->{'path'} cmp $b->{'path'}} @list;
 976         return @list;
 977 }
 978
 979 sub git_get_project_owner {
 980         my $project = shift;
 981         my $owner;
 982
 983         return undef unless $project;
 984
 985         # read from file (url-encoded):
 986         # 'git%2Fgit.git Linus+Torvalds'
 987         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
 988         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
 989         if (-f $projects_list) {
 990                 open (my $fd , $projects_list);
 991                 while (my $line = <$fd>) {
 992                         chomp $line;
 993                         my ($pr, $ow) = split ' ', $line;
 994                         $pr = unescape($pr);
 995                         $ow = unescape($ow);
 996                         if ($pr eq $project) {
 997                                 $owner = to_utf8($ow);
 998                                 last;
 999                         }
1000                 }
1001                 close $fd;
1002         }
1003         if (!defined $owner) {
1004                 $owner = get_file_owner("$projectroot/$project");
1005         }
1006
1007         return $owner;
1008 }
1009
1010 sub git_get_last_activity {
1011         my ($path) = @_;
1012         my $fd;
1013
1014         $git_dir = "$projectroot/$path";
1015         open($fd, "-|", git_cmd(), 'for-each-ref',
1016              '--format=%(refname) %(committer)',
1017              '--sort=-committerdate',
1018              'refs/heads') or return;
1019         my $most_recent = <$fd>;
1020         close $fd or return;
1021         if ($most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
1022                 my $timestamp = $1;
1023                 my $age = time - $timestamp;
1024                 return ($age, age_string($age));
1025         }
1026 }
1027
1028 sub git_get_references {
1029         my $type = shift || "";
1030         my %refs;
1031         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c      refs/tags/v2.6.11
1032         # c39ae07f393806ccf406ef966e9a15afc43cc36a      refs/tags/v2.6.11^{}
1033         open my $fd, "-|", $GIT, "peek-remote", "$projectroot/$project/"
1034                 or return;
1035
1036         while (my $line = <$fd>) {
1037                 chomp $line;
1038                 if ($line =~ m/^([0-9a-fA-F]{40})\trefs\/($type\/?[^\^]+)/) {
1039                         if (defined $refs{$1}) {
1040                                 push @{$refs{$1}}, $2;
1041                         } else {
1042                                 $refs{$1} = [ $2 ];
1043                         }
1044                 }
1045         }
1046         close $fd or return;
1047         return \%refs;
1048 }
1049
1050 sub git_get_rev_name_tags {
1051         my $hash = shift || return undef;
1052
1053         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
1054                 or return;
1055         my $name_rev = <$fd>;
1056         close $fd;
1057
1058         if ($name_rev =~ m|^$hash tags/(.*)$|) {
1059                 return $1;
1060         } else {
1061                 # catches also '$hash undefined' output
1062                 return undef;
1063         }
1064 }
1065
1066 ## ----------------------------------------------------------------------
1067 ## parse to hash functions
1068
1069 sub parse_date {
1070         my $epoch = shift;
1071         my $tz = shift || "-0000";
1072
1073         my %date;
1074         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
1075         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
1076         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
1077         $date{'hour'} = $hour;
1078         $date{'minute'} = $min;
1079         $date{'mday'} = $mday;
1080         $date{'day'} = $days[$wday];
1081         $date{'month'} = $months[$mon];
1082         $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
1083                            $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
1084         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
1085                              $mday, $months[$mon], $hour ,$min;
1086
1087         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
1088         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
1089         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
1090         $date{'hour_local'} = $hour;
1091         $date{'minute_local'} = $min;
1092         $date{'tz_local'} = $tz;
1093         $date{'iso-tz'} = sprintf ("%04d-%02d-%02d %02d:%02d:%02d %s",
1094                                    1900+$year, $mon+1, $mday,
1095                                    $hour, $min, $sec, $tz);
1096         return %date;
1097 }
1098
1099 sub parse_tag {
1100         my $tag_id = shift;
1101         my %tag;
1102         my @comment;
1103
1104         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
1105         $tag{'id'} = $tag_id;
1106         while (my $line = <$fd>) {
1107                 chomp $line;
1108                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
1109                         $tag{'object'} = $1;
1110                 } elsif ($line =~ m/^type (.+)$/) {
1111                         $tag{'type'} = $1;
1112                 } elsif ($line =~ m/^tag (.+)$/) {
1113                         $tag{'name'} = $1;
1114                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
1115                         $tag{'author'} = $1;
1116                         $tag{'epoch'} = $2;
1117                         $tag{'tz'} = $3;
1118                 } elsif ($line =~ m/--BEGIN/) {
1119                         push @comment, $line;
1120                         last;
1121                 } elsif ($line eq "") {
1122                         last;
1123                 }
1124         }
1125         push @comment, <$fd>;
1126         $tag{'comment'} = \@comment;
1127         close $fd or return;
1128         if (!defined $tag{'name'}) {
1129                 return
1130         };
1131         return %tag
1132 }
1133
1134 sub parse_commit {
1135         my $commit_id = shift;
1136         my $commit_text = shift;
1137
1138         my @commit_lines;
1139         my %co;
1140
1141         if (defined $commit_text) {
1142                 @commit_lines = @$commit_text;
1143         } else {
1144                 local $/ = "\0";
1145                 open my $fd, "-|", git_cmd(), "rev-list",
1146                         "--header", "--parents", "--max-count=1",
1147                         $commit_id, "--"
1148                         or return;
1149                 @commit_lines = split '\n', <$fd>;
1150                 close $fd or return;
1151                 pop @commit_lines;
1152         }
1153         my $header = shift @commit_lines;
1154         if (!($header =~ m/^[0-9a-fA-F]{40}/)) {
1155                 return;
1156         }
1157         ($co{'id'}, my @parents) = split ' ', $header;
1158         $co{'parents'} = \@parents;
1159         $co{'parent'} = $parents[0];
1160         while (my $line = shift @commit_lines) {
1161                 last if $line eq "\n";
1162                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
1163                         $co{'tree'} = $1;
1164                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
1165                         $co{'author'} = $1;
1166                         $co{'author_epoch'} = $2;
1167                         $co{'author_tz'} = $3;
1168                         if ($co{'author'} =~ m/^([^<]+) </) {
1169                                 $co{'author_name'} = $1;
1170                         } else {
1171                                 $co{'author_name'} = $co{'author'};
1172                         }
1173                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
1174                         $co{'committer'} = $1;
1175                         $co{'committer_epoch'} = $2;
1176                         $co{'committer_tz'} = $3;
1177                         $co{'committer_name'} = $co{'committer'};
1178                         $co{'committer_name'} =~ s/ <.*//;
1179                 }
1180         }
1181         if (!defined $co{'tree'}) {
1182                 return;
1183         };
1184
1185         foreach my $title (@commit_lines) {
1186                 $title =~ s/^    //;
1187                 if ($title ne "") {
1188                         $co{'title'} = chop_str($title, 80, 5);
1189                         # remove leading stuff of merges to make the interesting part visible
1190                         if (length($title) > 50) {
1191                                 $title =~ s/^Automatic //;
1192                                 $title =~ s/^merge (of|with) /Merge ... /i;
1193                                 if (length($title) > 50) {
1194                                         $title =~ s/(http|rsync):\/\///;
1195                                 }
1196                                 if (length($title) > 50) {
1197                                         $title =~ s/(master|www|rsync)\.//;
1198                                 }
1199                                 if (length($title) > 50) {
1200                                         $title =~ s/kernel.org:?//;
1201                                 }
1202                                 if (length($title) > 50) {
1203                                         $title =~ s/\/pub\/scm//;
1204                                 }
1205                         }
1206                         $co{'title_short'} = chop_str($title, 50, 5);
1207                         last;
1208                 }
1209         }
1210         if ($co{'title'} eq "") {
1211                 $co{'title'} = $co{'title_short'} = '(no commit message)';
1212         }
1213         # remove added spaces
1214         foreach my $line (@commit_lines) {
1215                 $line =~ s/^    //;
1216         }
1217         $co{'comment'} = \@commit_lines;
1218
1219         my $age = time - $co{'committer_epoch'};
1220         $co{'age'} = $age;
1221         $co{'age_string'} = age_string($age);
1222         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
1223         if ($age > 60*60*24*7*2) {
1224                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1225                 $co{'age_string_age'} = $co{'age_string'};
1226         } else {
1227                 $co{'age_string_date'} = $co{'age_string'};
1228                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1229         }
1230         return %co;
1231 }
1232
1233 # parse ref from ref_file, given by ref_id, with given type
1234 sub parse_ref {
1235         my $ref_file = shift;
1236         my $ref_id = shift;
1237         my $type = shift || git_get_type($ref_id);
1238         my %ref_item;
1239
1240         $ref_item{'type'} = $type;
1241         $ref_item{'id'} = $ref_id;
1242         $ref_item{'epoch'} = 0;
1243         $ref_item{'age'} = "unknown";
1244         if ($type eq "tag") {
1245                 my %tag = parse_tag($ref_id);
1246                 $ref_item{'comment'} = $tag{'comment'};
1247                 if ($tag{'type'} eq "commit") {
1248                         my %co = parse_commit($tag{'object'});
1249                         $ref_item{'epoch'} = $co{'committer_epoch'};
1250                         $ref_item{'age'} = $co{'age_string'};
1251                 } elsif (defined($tag{'epoch'})) {
1252                         my $age = time - $tag{'epoch'};
1253                         $ref_item{'epoch'} = $tag{'epoch'};
1254                         $ref_item{'age'} = age_string($age);
1255                 }
1256                 $ref_item{'reftype'} = $tag{'type'};
1257                 $ref_item{'name'} = $tag{'name'};
1258                 $ref_item{'refid'} = $tag{'object'};
1259         } elsif ($type eq "commit"){
1260                 my %co = parse_commit($ref_id);
1261                 $ref_item{'reftype'} = "commit";
1262                 $ref_item{'name'} = $ref_file;
1263                 $ref_item{'title'} = $co{'title'};
1264                 $ref_item{'refid'} = $ref_id;
1265                 $ref_item{'epoch'} = $co{'committer_epoch'};
1266                 $ref_item{'age'} = $co{'age_string'};
1267         } else {
1268                 $ref_item{'reftype'} = $type;
1269                 $ref_item{'name'} = $ref_file;
1270                 $ref_item{'refid'} = $ref_id;
1271         }
1272
1273         return %ref_item;
1274 }
1275
1276 # parse line of git-diff-tree "raw" output
1277 sub parse_difftree_raw_line {
1278         my $line = shift;
1279         my %res;
1280
1281         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
1282         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
1283         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
1284                 $res{'from_mode'} = $1;
1285                 $res{'to_mode'} = $2;
1286                 $res{'from_id'} = $3;
1287                 $res{'to_id'} = $4;
1288                 $res{'status'} = $5;
1289                 $res{'similarity'} = $6;
1290                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
1291                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
1292                 } else {
1293                         $res{'file'} = unquote($7);
1294                 }
1295         }
1296         # 'c512b523472485aef4fff9e57b229d9d243c967f'
1297         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
1298                 $res{'commit'} = $1;
1299         }
1300
1301         return wantarray ? %res : \%res;
1302 }
1303
1304 # parse line of git-ls-tree output
1305 sub parse_ls_tree_line ($;%) {
1306         my $line = shift;
1307         my %opts = @_;
1308         my %res;
1309
1310         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1311         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
1312
1313         $res{'mode'} = $1;
1314         $res{'type'} = $2;
1315         $res{'hash'} = $3;
1316         if ($opts{'-z'}) {
1317                 $res{'name'} = $4;
1318         } else {
1319                 $res{'name'} = unquote($4);
1320         }
1321
1322         return wantarray ? %res : \%res;
1323 }
1324
1325 ## ......................................................................
1326 ## parse to array of hashes functions
1327
1328 sub git_get_heads_list {
1329         my $limit = shift;
1330         my @headslist;
1331
1332         open my $fd, '-|', git_cmd(), 'for-each-ref',
1333                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
1334                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
1335                 'refs/heads'
1336                 or return;
1337         while (my $line = <$fd>) {
1338                 my %ref_item;
1339
1340                 chomp $line;
1341                 my ($refinfo, $committerinfo) = split(/\0/, $line);
1342                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
1343                 my ($committer, $epoch, $tz) =
1344                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
1345                 $name =~ s!^refs/heads/!!;
1346
1347                 $ref_item{'name'}  = $name;
1348                 $ref_item{'id'}    = $hash;
1349                 $ref_item{'title'} = $title || '(no commit message)';
1350                 $ref_item{'epoch'} = $epoch;
1351                 if ($epoch) {
1352                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1353                 } else {
1354                         $ref_item{'age'} = "unknown";
1355                 }
1356
1357                 push @headslist, \%ref_item;
1358         }
1359         close $fd;
1360
1361         return wantarray ? @headslist : \@headslist;
1362 }
1363
1364 sub git_get_tags_list {
1365         my $limit = shift;
1366         my @tagslist;
1367
1368         open my $fd, '-|', git_cmd(), 'for-each-ref',
1369                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
1370                 '--format=%(objectname) %(objecttype) %(refname) '.
1371                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
1372                 'refs/tags'
1373                 or return;
1374         while (my $line = <$fd>) {
1375                 my %ref_item;
1376
1377                 chomp $line;
1378                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
1379                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
1380                 my ($creator, $epoch, $tz) =
1381                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
1382                 $name =~ s!^refs/tags/!!;
1383
1384                 $ref_item{'type'} = $type;
1385                 $ref_item{'id'} = $id;
1386                 $ref_item{'name'} = $name;
1387                 if ($type eq "tag") {
1388                         $ref_item{'subject'} = $title;
1389                         $ref_item{'reftype'} = $reftype;
1390                         $ref_item{'refid'}   = $refid;
1391                 } else {
1392                         $ref_item{'reftype'} = $type;
1393                         $ref_item{'refid'}   = $id;
1394                 }
1395
1396                 if ($type eq "tag" || $type eq "commit") {
1397                         $ref_item{'epoch'} = $epoch;
1398                         if ($epoch) {
1399                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1400                         } else {
1401                                 $ref_item{'age'} = "unknown";
1402                         }
1403                 }
1404
1405                 push @tagslist, \%ref_item;
1406         }
1407         close $fd;
1408
1409         return wantarray ? @tagslist : \@tagslist;
1410 }
1411
1412 ## ----------------------------------------------------------------------
1413 ## filesystem-related functions
1414
1415 sub get_file_owner {
1416         my $path = shift;
1417
1418         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
1419         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
1420         if (!defined $gcos) {
1421                 return undef;
1422         }
1423         my $owner = $gcos;
1424         $owner =~ s/[,;].*$//;
1425         return to_utf8($owner);
1426 }
1427
1428 ## ......................................................................
1429 ## mimetype related functions
1430
1431 sub mimetype_guess_file {
1432         my $filename = shift;
1433         my $mimemap = shift;
1434         -r $mimemap or return undef;
1435
1436         my %mimemap;
1437         open(MIME, $mimemap) or return undef;
1438         while (<MIME>) {
1439                 next if m/^#/; # skip comments
1440                 my ($mime, $exts) = split(/\t+/);
1441                 if (defined $exts) {
1442                         my @exts = split(/\s+/, $exts);
1443                         foreach my $ext (@exts) {
1444                                 $mimemap{$ext} = $mime;
1445                         }
1446                 }
1447         }
1448         close(MIME);
1449
1450         $filename =~ /\.([^.]*)$/;
1451         return $mimemap{$1};
1452 }
1453
1454 sub mimetype_guess {
1455         my $filename = shift;
1456         my $mime;
1457         $filename =~ /\./ or return undef;
1458
1459         if ($mimetypes_file) {
1460                 my $file = $mimetypes_file;
1461                 if ($file !~ m!^/!) { # if it is relative path
1462                         # it is relative to project
1463                         $file = "$projectroot/$project/$file";
1464                 }
1465                 $mime = mimetype_guess_file($filename, $file);
1466         }
1467         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
1468         return $mime;
1469 }
1470
1471 sub blob_mimetype {
1472         my $fd = shift;
1473         my $filename = shift;
1474
1475         if ($filename) {
1476                 my $mime = mimetype_guess($filename);
1477                 $mime and return $mime;
1478         }
1479
1480         # just in case
1481         return $default_blob_plain_mimetype unless $fd;
1482
1483         if (-T $fd) {
1484                 return 'text/plain' .
1485                        ($default_text_plain_charset ? '; charset='.$default_text_plain_charset : '');
1486         } elsif (! $filename) {
1487                 return 'application/octet-stream';
1488         } elsif ($filename =~ m/\.png$/i) {
1489                 return 'image/png';
1490         } elsif ($filename =~ m/\.gif$/i) {
1491                 return 'image/gif';
1492         } elsif ($filename =~ m/\.jpe?g$/i) {
1493                 return 'image/jpeg';
1494         } else {
1495                 return 'application/octet-stream';
1496         }
1497 }
1498
1499 ## ======================================================================
1500 ## functions printing HTML: header, footer, error page
1501
1502 sub git_header_html {
1503         my $status = shift || "200 OK";
1504         my $expires = shift;
1505
1506         my $title = "$site_name";
1507         if (defined $project) {
1508                 $title .= " - $project";
1509                 if (defined $action) {
1510                         $title .= "/$action";
1511                         if (defined $file_name) {
1512                                 $title .= " - " . esc_html($file_name);
1513                                 if ($action eq "tree" && $file_name !~ m|/$|) {
1514                                         $title .= "/";
1515                                 }
1516                         }
1517                 }
1518         }
1519         my $content_type;
1520         # require explicit support from the UA if we are to send the page as
1521         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
1522         # we have to do this because MSIE sometimes globs '*/*', pretending to
1523         # support xhtml+xml but choking when it gets what it asked for.
1524         if (defined $cgi->http('HTTP_ACCEPT') &&
1525             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
1526             $cgi->Accept('application/xhtml+xml') != 0) {
1527                 $content_type = 'application/xhtml+xml';
1528         } else {
1529                 $content_type = 'text/html';
1530         }
1531         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
1532                            -status=> $status, -expires => $expires);
1533         print <<EOF;
1534 <?xml version="1.0" encoding="utf-8"?>
1535 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1536 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
1537 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
1538 <!-- git core binaries version $git_version -->
1539 <head>
1540 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
1541 <meta name="generator" content="gitweb/$version git/$git_version"/>
1542 <meta name="robots" content="index, nofollow"/>
1543 <title>$title</title>
1544 EOF
1545 # print out each stylesheet that exist
1546         if (defined $stylesheet) {
1547 #provides backwards capability for those people who define style sheet in a config file
1548                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1549         } else {
1550                 foreach my $stylesheet (@stylesheets) {
1551                         next unless $stylesheet;
1552                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1553                 }
1554         }
1555         if (defined $project) {
1556                 printf('<link rel="alternate" title="%s log" '.
1557                        'href="%s" type="application/rss+xml"/>'."\n",
1558                        esc_param($project), href(action=>"rss"));
1559         } else {
1560                 printf('<link rel="alternate" title="%s projects list" '.
1561                        'href="%s" type="text/plain; charset=utf-8"/>'."\n",
1562                        $site_name, href(project=>undef, action=>"project_index"));
1563                 printf('<link rel="alternate" title="%s projects logs" '.
1564                        'href="%s" type="text/x-opml"/>'."\n",
1565                        $site_name, href(project=>undef, action=>"opml"));
1566         }
1567         if (defined $favicon) {
1568                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png"/>\n);
1569         }
1570
1571         print "</head>\n" .
1572               "<body>\n";
1573
1574         if (-f $site_header) {
1575                 open (my $fd, $site_header);
1576                 print <$fd>;
1577                 close $fd;
1578         }
1579
1580         print "<div class=\"page_header\">\n" .
1581               $cgi->a({-href => esc_url($logo_url),
1582                        -title => $logo_label},
1583                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
1584         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
1585         if (defined $project) {
1586                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
1587                 if (defined $action) {
1588                         print " / $action";
1589                 }
1590                 print "\n";
1591                 if (!defined $searchtext) {
1592                         $searchtext = "";
1593                 }
1594                 my $search_hash;
1595                 if (defined $hash_base) {
1596                         $search_hash = $hash_base;
1597                 } elsif (defined $hash) {
1598                         $search_hash = $hash;
1599                 } else {
1600                         $search_hash = "HEAD";
1601                 }
1602                 $cgi->param("a", "search");
1603                 $cgi->param("h", $search_hash);
1604                 $cgi->param("p", $project);
1605                 print $cgi->startform(-method => "get", -action => $my_uri) .
1606                       "<div class=\"search\">\n" .
1607                       $cgi->hidden(-name => "p") . "\n" .
1608                       $cgi->hidden(-name => "a") . "\n" .
1609                       $cgi->hidden(-name => "h") . "\n" .
1610                       $cgi->popup_menu(-name => 'st', -default => 'commit',
1611                                        -values => ['commit', 'author', 'committer', 'pickaxe']) .
1612                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
1613                       " search:\n",
1614                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
1615                       "</div>" .
1616                       $cgi->end_form() . "\n";
1617         }
1618         print "</div>\n";
1619 }
1620
1621 sub git_footer_html {
1622         print "<div class=\"page_footer\">\n";
1623         if (defined $project) {
1624                 my $descr = git_get_project_description($project);
1625                 if (defined $descr) {
1626                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
1627                 }
1628                 print $cgi->a({-href => href(action=>"rss"),
1629                               -class => "rss_logo"}, "RSS") . "\n";
1630         } else {
1631                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
1632                               -class => "rss_logo"}, "OPML") . " ";
1633                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
1634                               -class => "rss_logo"}, "TXT") . "\n";
1635         }
1636         print "</div>\n" ;
1637
1638         if (-f $site_footer) {
1639                 open (my $fd, $site_footer);
1640                 print <$fd>;
1641                 close $fd;
1642         }
1643
1644         print "</body>\n" .
1645               "</html>";
1646 }
1647
1648 sub die_error {
1649         my $status = shift || "403 Forbidden";
1650         my $error = shift || "Malformed query, file missing or permission denied";
1651
1652         git_header_html($status);
1653         print <<EOF;
1654 <div class="page_body">
1655 <br /><br />
1656 $status - $error
1657 <br />
1658 </div>
1659 EOF
1660         git_footer_html();
1661         exit;
1662 }
1663
1664 ## ----------------------------------------------------------------------
1665 ## functions printing or outputting HTML: navigation
1666
1667 sub git_print_page_nav {
1668         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
1669         $extra = '' if !defined $extra; # pager or formats
1670
1671         my @navs = qw(summary shortlog log commit commitdiff tree);
1672         if ($suppress) {
1673                 @navs = grep { $_ ne $suppress } @navs;
1674         }
1675
1676         my %arg = map { $_ => {action=>$_} } @navs;
1677         if (defined $head) {
1678                 for (qw(commit commitdiff)) {
1679                         $arg{$_}{hash} = $head;
1680                 }
1681                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
1682                         for (qw(shortlog log)) {
1683                                 $arg{$_}{hash} = $head;
1684                         }
1685                 }
1686         }
1687         $arg{tree}{hash} = $treehead if defined $treehead;
1688         $arg{tree}{hash_base} = $treebase if defined $treebase;
1689
1690         print "<div class=\"page_nav\">\n" .
1691                 (join " | ",
1692                  map { $_ eq $current ?
1693                        $_ : $cgi->a({-href => href(%{$arg{$_}})}, "$_")
1694                  } @navs);
1695         print "<br/>\n$extra<br/>\n" .
1696               "</div>\n";
1697 }
1698
1699 sub format_paging_nav {
1700         my ($action, $hash, $head, $page, $nrevs) = @_;
1701         my $paging_nav;
1702
1703
1704         if ($hash ne $head || $page) {
1705                 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
1706         } else {
1707                 $paging_nav .= "HEAD";
1708         }
1709
1710         if ($page > 0) {
1711                 $paging_nav .= " &sdot; " .
1712                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page-1),
1713                                  -accesskey => "p", -title => "Alt-p"}, "prev");
1714         } else {
1715                 $paging_nav .= " &sdot; prev";
1716         }
1717
1718         if ($nrevs >= (100 * ($page+1)-1)) {
1719                 $paging_nav .= " &sdot; " .
1720                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page+1),
1721                                  -accesskey => "n", -title => "Alt-n"}, "next");
1722         } else {
1723                 $paging_nav .= " &sdot; next";
1724         }
1725
1726         return $paging_nav;
1727 }
1728
1729 ## ......................................................................
1730 ## functions printing or outputting HTML: div
1731
1732 sub git_print_header_div {
1733         my ($action, $title, $hash, $hash_base) = @_;
1734         my %args = ();
1735
1736         $args{action} = $action;
1737         $args{hash} = $hash if $hash;
1738         $args{hash_base} = $hash_base if $hash_base;
1739
1740         print "<div class=\"header\">\n" .
1741               $cgi->a({-href => href(%args), -class => "title"},
1742               $title ? $title : $action) .
1743               "\n</div>\n";
1744 }
1745
1746 #sub git_print_authorship (\%) {
1747 sub git_print_authorship {
1748         my $co = shift;
1749
1750         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
1751         print "<div class=\"author_date\">" .
1752               esc_html($co->{'author_name'}) .
1753               " [$ad{'rfc2822'}";
1754         if ($ad{'hour_local'} < 6) {
1755                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
1756                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1757         } else {
1758                 printf(" (%02d:%02d %s)",
1759                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1760         }
1761         print "]</div>\n";
1762 }
1763
1764 sub git_print_page_path {
1765         my $name = shift;
1766         my $type = shift;
1767         my $hb = shift;
1768
1769
1770         print "<div class=\"page_path\">";
1771         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
1772                       -title => 'tree root'}, "[$project]");
1773         print " / ";
1774         if (defined $name) {
1775                 my @dirname = split '/', $name;
1776                 my $basename = pop @dirname;
1777                 my $fullname = '';
1778
1779                 foreach my $dir (@dirname) {
1780                         $fullname .= ($fullname ? '/' : '') . $dir;
1781                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
1782                                                      hash_base=>$hb),
1783                                       -title => $fullname}, esc_html($dir));
1784                         print " / ";
1785                 }
1786                 if (defined $type && $type eq 'blob') {
1787                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
1788                                                      hash_base=>$hb),
1789                                       -title => $name}, esc_html($basename));
1790                 } elsif (defined $type && $type eq 'tree') {
1791                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
1792                                                      hash_base=>$hb),
1793                                       -title => $name}, esc_html($basename));
1794                         print " / ";
1795                 } else {
1796                         print esc_html($basename);
1797                 }
1798         }
1799         print "<br/></div>\n";
1800 }
1801
1802 # sub git_print_log (\@;%) {
1803 sub git_print_log ($;%) {
1804         my $log = shift;
1805         my %opts = @_;
1806
1807         if ($opts{'-remove_title'}) {
1808                 # remove title, i.e. first line of log
1809                 shift @$log;
1810         }
1811         # remove leading empty lines
1812         while (defined $log->[0] && $log->[0] eq "") {
1813                 shift @$log;
1814         }
1815
1816         # print log
1817         my $signoff = 0;
1818         my $empty = 0;
1819         foreach my $line (@$log) {
1820                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
1821                         $signoff = 1;
1822                         $empty = 0;
1823                         if (! $opts{'-remove_signoff'}) {
1824                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
1825                                 next;
1826                         } else {
1827                                 # remove signoff lines
1828                                 next;
1829                         }
1830                 } else {
1831                         $signoff = 0;
1832                 }
1833
1834                 # print only one empty line
1835                 # do not print empty line after signoff
1836                 if ($line eq "") {
1837                         next if ($empty || $signoff);
1838                         $empty = 1;
1839                 } else {
1840                         $empty = 0;
1841                 }
1842
1843                 print format_log_line_html($line) . "<br/>\n";
1844         }
1845
1846         if ($opts{'-final_empty_line'}) {
1847                 # end with single empty line
1848                 print "<br/>\n" unless $empty;
1849         }
1850 }
1851
1852 # print tree entry (row of git_tree), but without encompassing <tr> element
1853 sub git_print_tree_entry {
1854         my ($t, $basedir, $hash_base, $have_blame) = @_;
1855
1856         my %base_key = ();
1857         $base_key{hash_base} = $hash_base if defined $hash_base;
1858
1859         # The format of a table row is: mode list link.  Where mode is
1860         # the mode of the entry, list is the name of the entry, an href,
1861         # and link is the action links of the entry.
1862
1863         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
1864         if ($t->{'type'} eq "blob") {
1865                 print "<td class=\"list\">" .
1866                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
1867                                                file_name=>"$basedir$t->{'name'}", %base_key),
1868                                 -class => "list"}, esc_html($t->{'name'})) . "</td>\n";
1869                 print "<td class=\"link\">";
1870                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
1871                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1872                               "blob");
1873                 if ($have_blame) {
1874                         print " | " .
1875                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
1876                                                            file_name=>"$basedir$t->{'name'}", %base_key)},
1877                                             "blame");
1878                 }
1879                 if (defined $hash_base) {
1880                         print " | " .
1881                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
1882                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
1883                                       "history");
1884                 }
1885                 print " | " .
1886                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
1887                                                file_name=>"$basedir$t->{'name'}")},
1888                                 "raw");
1889                 print "</td>\n";
1890
1891         } elsif ($t->{'type'} eq "tree") {
1892                 print "<td class=\"list\">";
1893                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
1894                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1895                               esc_html($t->{'name'}));
1896                 print "</td>\n";
1897                 print "<td class=\"link\">";
1898                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
1899                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1900                               "tree");
1901                 if (defined $hash_base) {
1902                         print " | " .
1903                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
1904                                                      file_name=>"$basedir$t->{'name'}")},
1905                                       "history");
1906                 }
1907                 print "</td>\n";
1908         }
1909 }
1910
1911 ## ......................................................................
1912 ## functions printing large fragments of HTML
1913
1914 sub git_difftree_body {
1915         my ($difftree, $hash, $parent) = @_;
1916
1917         print "<div class=\"list_head\">\n";
1918         if ($#{$difftree} > 10) {
1919                 print(($#{$difftree} + 1) . " files changed:\n");
1920         }
1921         print "</div>\n";
1922
1923         print "<table class=\"diff_tree\">\n";
1924         my $alternate = 1;
1925         my $patchno = 0;
1926         foreach my $line (@{$difftree}) {
1927                 my %diff = parse_difftree_raw_line($line);
1928
1929                 if ($alternate) {
1930                         print "<tr class=\"dark\">\n";
1931                 } else {
1932                         print "<tr class=\"light\">\n";
1933                 }
1934                 $alternate ^= 1;
1935
1936                 my ($to_mode_oct, $to_mode_str, $to_file_type);
1937                 my ($from_mode_oct, $from_mode_str, $from_file_type);
1938                 if ($diff{'to_mode'} ne ('0' x 6)) {
1939                         $to_mode_oct = oct $diff{'to_mode'};
1940                         if (S_ISREG($to_mode_oct)) { # only for regular file
1941                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
1942                         }
1943                         $to_file_type = file_type($diff{'to_mode'});
1944                 }
1945                 if ($diff{'from_mode'} ne ('0' x 6)) {
1946                         $from_mode_oct = oct $diff{'from_mode'};
1947                         if (S_ISREG($to_mode_oct)) { # only for regular file
1948                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
1949                         }
1950                         $from_file_type = file_type($diff{'from_mode'});
1951                 }
1952
1953                 if ($diff{'status'} eq "A") { # created
1954                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
1955                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
1956                         $mode_chng   .= "]</span>";
1957                         print "<td>";
1958                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
1959                                                      hash_base=>$hash, file_name=>$diff{'file'}),
1960                                       -class => "list"}, esc_html($diff{'file'}));
1961                         print "</td>\n";
1962                         print "<td>$mode_chng</td>\n";
1963                         print "<td class=\"link\">";
1964                         if ($action eq 'commitdiff') {
1965                                 # link to patch
1966                                 $patchno++;
1967                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
1968                         }
1969                         print "</td>\n";
1970
1971                 } elsif ($diff{'status'} eq "D") { # deleted
1972                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
1973                         print "<td>";
1974                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
1975                                                      hash_base=>$parent, file_name=>$diff{'file'}),
1976                                        -class => "list"}, esc_html($diff{'file'}));
1977                         print "</td>\n";
1978                         print "<td>$mode_chng</td>\n";
1979                         print "<td class=\"link\">";
1980                         if ($action eq 'commitdiff') {
1981                                 # link to patch
1982                                 $patchno++;
1983                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
1984                                 print " | ";
1985                         }
1986                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
1987                                                      hash_base=>$parent, file_name=>$diff{'file'})},
1988                                       "blob") . " | ";
1989                         print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
1990                                                      file_name=>$diff{'file'})},
1991                                       "blame") . " | ";
1992                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
1993                                                      file_name=>$diff{'file'})},
1994                                       "history");
1995                         print "</td>\n";
1996
1997                 } elsif ($diff{'status'} eq "M" || $diff{'status'} eq "T") { # modified, or type changed
1998                         my $mode_chnge = "";
1999                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2000                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
2001                                 if ($from_file_type != $to_file_type) {
2002                                         $mode_chnge .= " from $from_file_type to $to_file_type";
2003                                 }
2004                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
2005                                         if ($from_mode_str && $to_mode_str) {
2006                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
2007                                         } elsif ($to_mode_str) {
2008                                                 $mode_chnge .= " mode: $to_mode_str";
2009                                         }
2010                                 }
2011                                 $mode_chnge .= "]</span>\n";
2012                         }
2013                         print "<td>";
2014                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2015                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2016                                       -class => "list"}, esc_html($diff{'file'}));
2017                         print "</td>\n";
2018                         print "<td>$mode_chnge</td>\n";
2019                         print "<td class=\"link\">";
2020                         if ($action eq 'commitdiff') {
2021                                 # link to patch
2022                                 $patchno++;
2023                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2024                                       " | ";
2025                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2026                                 # "commit" view and modified file (not onlu mode changed)
2027                                 print $cgi->a({-href => href(action=>"blobdiff",
2028                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2029                                                              hash_base=>$hash, hash_parent_base=>$parent,
2030                                                              file_name=>$diff{'file'})},
2031                                               "diff") .
2032                                       " | ";
2033                         }
2034                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2035                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2036                                       "blob") . " | ";
2037                         print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
2038                                                      file_name=>$diff{'file'})},
2039                                       "blame") . " | ";
2040                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2041                                                      file_name=>$diff{'file'})},
2042                                       "history");
2043                         print "</td>\n";
2044
2045                 } elsif ($diff{'status'} eq "R" || $diff{'status'} eq "C") { # renamed or copied
2046                         my %status_name = ('R' => 'moved', 'C' => 'copied');
2047                         my $nstatus = $status_name{$diff{'status'}};
2048                         my $mode_chng = "";
2049                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2050                                 # mode also for directories, so we cannot use $to_mode_str
2051                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
2052                         }
2053                         print "<td>" .
2054                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2055                                                      hash=>$diff{'to_id'}, file_name=>$diff{'to_file'}),
2056                                       -class => "list"}, esc_html($diff{'to_file'})) . "</td>\n" .
2057                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
2058                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
2059                                                      hash=>$diff{'from_id'}, file_name=>$diff{'from_file'}),
2060                                       -class => "list"}, esc_html($diff{'from_file'})) .
2061                               " with " . (int $diff{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
2062                               "<td class=\"link\">";
2063                         if ($action eq 'commitdiff') {
2064                                 # link to patch
2065                                 $patchno++;
2066                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2067                                       " | ";
2068                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2069                                 # "commit" view and modified file (not only pure rename or copy)
2070                                 print $cgi->a({-href => href(action=>"blobdiff",
2071                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2072                                                              hash_base=>$hash, hash_parent_base=>$parent,
2073                                                              file_name=>$diff{'to_file'}, file_parent=>$diff{'from_file'})},
2074                                               "diff") .
2075                                       " | ";
2076                         }
2077                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2078                                                      hash_base=>$parent, file_name=>$diff{'from_file'})},
2079                                       "blob") . " | ";
2080                         print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
2081                                                      file_name=>$diff{'from_file'})},
2082                                       "blame") . " | ";
2083                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
2084                                                     file_name=>$diff{'from_file'})},
2085                                       "history");
2086                         print "</td>\n";
2087
2088                 } # we should not encounter Unmerged (U) or Unknown (X) status
2089                 print "</tr>\n";
2090         }
2091         print "</table>\n";
2092 }
2093
2094 sub git_patchset_body {
2095         my ($fd, $difftree, $hash, $hash_parent) = @_;
2096
2097         my $patch_idx = 0;
2098         my $in_header = 0;
2099         my $patch_found = 0;
2100         my $diffinfo;
2101
2102         print "<div class=\"patchset\">\n";
2103
2104         LINE:
2105         while (my $patch_line = <$fd>) {
2106                 chomp $patch_line;
2107
2108                 if ($patch_line =~ m/^diff /) { # "git diff" header
2109                         # beginning of patch (in patchset)
2110                         if ($patch_found) {
2111                                 # close previous patch
2112                                 print "</div>\n"; # class="patch"
2113                         } else {
2114                                 # first patch in patchset
2115                                 $patch_found = 1;
2116                         }
2117                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
2118
2119                         if (ref($difftree->[$patch_idx]) eq "HASH") {
2120                                 $diffinfo = $difftree->[$patch_idx];
2121                         } else {
2122                                 $diffinfo = parse_difftree_raw_line($difftree->[$patch_idx]);
2123                         }
2124                         $patch_idx++;
2125
2126                         if ($diffinfo->{'status'} eq "A") { # added
2127                                 print "<div class=\"diff_info\">" . file_type($diffinfo->{'to_mode'}) . ":" .
2128                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2129                                                              hash=>$diffinfo->{'to_id'}, file_name=>$diffinfo->{'file'})},
2130                                               $diffinfo->{'to_id'}) . " (new)" .
2131                                       "</div>\n"; # class="diff_info"
2132
2133                         } elsif ($diffinfo->{'status'} eq "D") { # deleted
2134                                 print "<div class=\"diff_info\">" . file_type($diffinfo->{'from_mode'}) . ":" .
2135                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash_parent,
2136                                                              hash=>$diffinfo->{'from_id'}, file_name=>$diffinfo->{'file'})},
2137                                               $diffinfo->{'from_id'}) . " (deleted)" .
2138                                       "</div>\n"; # class="diff_info"
2139
2140                         } elsif ($diffinfo->{'status'} eq "R" || # renamed
2141                                  $diffinfo->{'status'} eq "C" || # copied
2142                                  $diffinfo->{'status'} eq "2") { # with two filenames (from git_blobdiff)
2143                                 print "<div class=\"diff_info\">" .
2144                                       file_type($diffinfo->{'from_mode'}) . ":" .
2145                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash_parent,
2146                                                              hash=>$diffinfo->{'from_id'}, file_name=>$diffinfo->{'from_file'})},
2147                                               $diffinfo->{'from_id'}) .
2148                                       " -> " .
2149                                       file_type($diffinfo->{'to_mode'}) . ":" .
2150                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2151                                                              hash=>$diffinfo->{'to_id'}, file_name=>$diffinfo->{'to_file'})},
2152                                               $diffinfo->{'to_id'});
2153                                 print "</div>\n"; # class="diff_info"
2154
2155                         } else { # modified, mode changed, ...
2156                                 print "<div class=\"diff_info\">" .
2157                                       file_type($diffinfo->{'from_mode'}) . ":" .
2158                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash_parent,
2159                                                              hash=>$diffinfo->{'from_id'}, file_name=>$diffinfo->{'file'})},
2160                                               $diffinfo->{'from_id'}) .
2161                                       " -> " .
2162                                       file_type($diffinfo->{'to_mode'}) . ":" .
2163                                       $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2164                                                              hash=>$diffinfo->{'to_id'}, file_name=>$diffinfo->{'file'})},
2165                                               $diffinfo->{'to_id'});
2166                                 print "</div>\n"; # class="diff_info"
2167                         }
2168
2169                         #print "<div class=\"diff extended_header\">\n";
2170                         $in_header = 1;
2171                         next LINE;
2172                 } # start of patch in patchset
2173
2174
2175                 if ($in_header && $patch_line =~ m/^---/) {
2176                         #print "</div>\n"; # class="diff extended_header"
2177                         $in_header = 0;
2178
2179                         my $file = $diffinfo->{'from_file'};
2180                         $file  ||= $diffinfo->{'file'};
2181                         $file = $cgi->a({-href => href(action=>"blob", hash_base=>$hash_parent,
2182                                                        hash=>$diffinfo->{'from_id'}, file_name=>$file),
2183                                         -class => "list"}, esc_html($file));
2184                         $patch_line =~ s|a/.*$|a/$file|g;
2185                         print "<div class=\"diff from_file\">$patch_line</div>\n";
2186
2187                         $patch_line = <$fd>;
2188                         chomp $patch_line;
2189
2190                         #$patch_line =~ m/^+++/;
2191                         $file    = $diffinfo->{'to_file'};
2192                         $file  ||= $diffinfo->{'file'};
2193                         $file = $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2194                                                        hash=>$diffinfo->{'to_id'}, file_name=>$file),
2195                                         -class => "list"}, esc_html($file));
2196                         $patch_line =~ s|b/.*|b/$file|g;
2197                         print "<div class=\"diff to_file\">$patch_line</div>\n";
2198
2199                         next LINE;
2200                 }
2201                 next LINE if $in_header;
2202
2203                 print format_diff_line($patch_line);
2204         }
2205         print "</div>\n" if $patch_found; # class="patch"
2206
2207         print "</div>\n"; # class="patchset"
2208 }
2209
2210 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
2211
2212 sub git_project_list_body {
2213         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
2214
2215         my $check_forks = gitweb_check_feature('forks');
2216
2217         my @projects;
2218         foreach my $pr (@$projlist) {
2219                 my (@aa) = git_get_last_activity($pr->{'path'});
2220                 unless (@aa) {
2221                         next;
2222                 }
2223                 ($pr->{'age'}, $pr->{'age_string'}) = @aa;
2224                 if (!defined $pr->{'descr'}) {
2225                         my $descr = git_get_project_description($pr->{'path'}) || "";
2226                         $pr->{'descr'} = chop_str($descr, 25, 5);
2227                 }
2228                 if (!defined $pr->{'owner'}) {
2229                         $pr->{'owner'} = get_file_owner("$projectroot/$pr->{'path'}") || "";
2230                 }
2231                 if ($check_forks) {
2232                         my $pname = $pr->{'path'};
2233                         $pname =~ s/\.git$//;
2234                         $pr->{'forks'} = -d "$projectroot/$pname";
2235                 }
2236                 push @projects, $pr;
2237         }
2238
2239         $order ||= "project";
2240         $from = 0 unless defined $from;
2241         $to = $#projects if (!defined $to || $#projects < $to);
2242
2243         print "<table class=\"project_list\">\n";
2244         unless ($no_header) {
2245                 print "<tr>\n";
2246                 if ($check_forks) {
2247                         print "<th></th>\n";
2248                 }
2249                 if ($order eq "project") {
2250                         @projects = sort {$a->{'path'} cmp $b->{'path'}} @projects;
2251                         print "<th>Project</th>\n";
2252                 } else {
2253                         print "<th>" .
2254                               $cgi->a({-href => href(project=>undef, order=>'project'),
2255                                        -class => "header"}, "Project") .
2256                               "</th>\n";
2257                 }
2258                 if ($order eq "descr") {
2259                         @projects = sort {$a->{'descr'} cmp $b->{'descr'}} @projects;
2260                         print "<th>Description</th>\n";
2261                 } else {
2262                         print "<th>" .
2263                               $cgi->a({-href => href(project=>undef, order=>'descr'),
2264                                        -class => "header"}, "Description") .
2265                               "</th>\n";
2266                 }
2267                 if ($order eq "owner") {
2268                         @projects = sort {$a->{'owner'} cmp $b->{'owner'}} @projects;
2269                         print "<th>Owner</th>\n";
2270                 } else {
2271                         print "<th>" .
2272                               $cgi->a({-href => href(project=>undef, order=>'owner'),
2273                                        -class => "header"}, "Owner") .
2274                               "</th>\n";
2275                 }
2276                 if ($order eq "age") {
2277                         @projects = sort {$a->{'age'} <=> $b->{'age'}} @projects;
2278                         print "<th>Last Change</th>\n";
2279                 } else {
2280                         print "<th>" .
2281                               $cgi->a({-href => href(project=>undef, order=>'age'),
2282                                        -class => "header"}, "Last Change") .
2283                               "</th>\n";
2284                 }
2285                 print "<th></th>\n" .
2286                       "</tr>\n";
2287         }
2288         my $alternate = 1;
2289         for (my $i = $from; $i <= $to; $i++) {
2290                 my $pr = $projects[$i];
2291                 if ($alternate) {
2292                         print "<tr class=\"dark\">\n";
2293                 } else {
2294                         print "<tr class=\"light\">\n";
2295                 }
2296                 $alternate ^= 1;
2297                 if ($check_forks) {
2298                         print "<td>";
2299                         if ($pr->{'forks'}) {
2300                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
2301                         }
2302                         print "</td>\n";
2303                 }
2304                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
2305                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
2306                       "<td>" . esc_html($pr->{'descr'}) . "</td>\n" .
2307                       "<td><i>" . chop_str($pr->{'owner'}, 15) . "</i></td>\n";
2308                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
2309                       $pr->{'age_string'} . "</td>\n" .
2310                       "<td class=\"link\">" .
2311                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
2312                       $cgi->a({-href => '/git-browser/by-commit.html?r='.$pr->{'path'}}, "graphiclog") . " | " .
2313                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
2314                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
2315                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
2316                       "</td>\n" .
2317                       "</tr>\n";
2318         }
2319         if (defined $extra) {
2320                 print "<tr>\n";
2321                 if ($check_forks) {
2322                         print "<td></td>\n";
2323                 }
2324                 print "<td colspan=\"5\">$extra</td>\n" .
2325                       "</tr>\n";
2326         }
2327         print "</table>\n";
2328 }
2329
2330 sub git_shortlog_body {
2331         # uses global variable $project
2332         my ($revlist, $from, $to, $refs, $extra) = @_;
2333
2334         $from = 0 unless defined $from;
2335         $to = $#{$revlist} if (!defined $to || $#{$revlist} < $to);
2336
2337         print "<table class=\"shortlog\" cellspacing=\"0\">\n";
2338         my $alternate = 1;
2339         for (my $i = $from; $i <= $to; $i++) {
2340                 my $commit = $revlist->[$i];
2341                 #my $ref = defined $refs ? format_ref_marker($refs, $commit) : '';
2342                 my $ref = format_ref_marker($refs, $commit);
2343                 my %co = parse_commit($commit);
2344                 if ($alternate) {
2345                         print "<tr class=\"dark\">\n";
2346                 } else {
2347                         print "<tr class=\"light\">\n";
2348                 }
2349                 $alternate ^= 1;
2350                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
2351                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2352                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 10)) . "</i></td>\n" .
2353                       "<td>";
2354                 print format_subject_html($co{'title'}, $co{'title_short'},
2355                                           href(action=>"commit", hash=>$commit), $ref);
2356                 print "</td>\n" .
2357                       "<td class=\"link\">" .
2358                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
2359                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
2360                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
2361                 if (gitweb_have_snapshot()) {
2362                         print " | " . $cgi->a({-href => href(action=>"snapshot", hash=>$commit)}, "snapshot");
2363                 }
2364                 print "</td>\n" .
2365                       "</tr>\n";
2366         }
2367         if (defined $extra) {
2368                 print "<tr>\n" .
2369                       "<td colspan=\"4\">$extra</td>\n" .
2370                       "</tr>\n";
2371         }
2372         print "</table>\n";
2373 }
2374
2375 sub git_history_body {
2376         # Warning: assumes constant type (blob or tree) during history
2377         my ($revlist, $from, $to, $refs, $hash_base, $ftype, $extra) = @_;
2378
2379         $from = 0 unless defined $from;
2380         $to = $#{$revlist} unless (defined $to && $to <= $#{$revlist});
2381
2382         print "<table class=\"history\" cellspacing=\"0\">\n";
2383         my $alternate = 1;
2384         for (my $i = $from; $i <= $to; $i++) {
2385                 if ($revlist->[$i] !~ m/^([0-9a-fA-F]{40})/) {
2386                         next;
2387                 }
2388
2389                 my $commit = $1;
2390                 my %co = parse_commit($commit);
2391                 if (!%co) {
2392                         next;
2393                 }
2394
2395                 my $ref = format_ref_marker($refs, $commit);
2396
2397                 if ($alternate) {
2398                         print "<tr class=\"dark\">\n";
2399                 } else {
2400                         print "<tr class=\"light\">\n";
2401                 }
2402                 $alternate ^= 1;
2403                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2404                       # shortlog uses      chop_str($co{'author_name'}, 10)
2405                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 3)) . "</i></td>\n" .
2406                       "<td>";
2407                 # originally git_history used chop_str($co{'title'}, 50)
2408                 print format_subject_html($co{'title'}, $co{'title_short'},
2409                                           href(action=>"commit", hash=>$commit), $ref);
2410                 print "</td>\n" .
2411                       "<td class=\"link\">" .
2412                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
2413                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
2414
2415                 if ($ftype eq 'blob') {
2416                         my $blob_current = git_get_hash_by_path($hash_base, $file_name);
2417                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
2418                         if (defined $blob_current && defined $blob_parent &&
2419                                         $blob_current ne $blob_parent) {
2420                                 print " | " .
2421                                         $cgi->a({-href => href(action=>"blobdiff",
2422                                                                hash=>$blob_current, hash_parent=>$blob_parent,
2423                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
2424                                                                file_name=>$file_name)},
2425                                                 "diff to current");
2426                         }
2427                 }
2428                 print "</td>\n" .
2429                       "</tr>\n";
2430         }
2431         if (defined $extra) {
2432                 print "<tr>\n" .
2433                       "<td colspan=\"4\">$extra</td>\n" .
2434                       "</tr>\n";
2435         }
2436         print "</table>\n";
2437 }
2438
2439 sub git_tags_body {
2440         # uses global variable $project
2441         my ($taglist, $from, $to, $extra) = @_;
2442         $from = 0 unless defined $from;
2443         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
2444
2445         print "<table class=\"tags\" cellspacing=\"0\">\n";
2446         my $alternate = 1;
2447         for (my $i = $from; $i <= $to; $i++) {
2448                 my $entry = $taglist->[$i];
2449                 my %tag = %$entry;
2450                 my $comment = $tag{'subject'};
2451                 my $comment_short;
2452                 if (defined $comment) {
2453                         $comment_short = chop_str($comment, 30, 5);
2454                 }
2455                 if ($alternate) {
2456                         print "<tr class=\"dark\">\n";
2457                 } else {
2458                         print "<tr class=\"light\">\n";
2459                 }
2460                 $alternate ^= 1;
2461                 print "<td><i>$tag{'age'}</i></td>\n" .
2462                       "<td>" .
2463                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
2464                                -class => "list name"}, esc_html($tag{'name'})) .
2465                       "</td>\n" .
2466                       "<td>";
2467                 if (defined $comment) {
2468                         print format_subject_html($comment, $comment_short,
2469                                                   href(action=>"tag", hash=>$tag{'id'}));
2470                 }
2471                 print "</td>\n" .
2472                       "<td class=\"selflink\">";
2473                 if ($tag{'type'} eq "tag") {
2474                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
2475                 } else {
2476                         print "&nbsp;";
2477                 }
2478                 print "</td>\n" .
2479                       "<td class=\"link\">" . " | " .
2480                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
2481                 if ($tag{'reftype'} eq "commit") {
2482                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'name'})}, "shortlog") .
2483                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'name'})}, "log");
2484                 } elsif ($tag{'reftype'} eq "blob") {
2485                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
2486                 }
2487                 print "</td>\n" .
2488                       "</tr>";
2489         }
2490         if (defined $extra) {
2491                 print "<tr>\n" .
2492                       "<td colspan=\"5\">$extra</td>\n" .
2493                       "</tr>\n";
2494         }
2495         print "</table>\n";
2496 }
2497
2498 sub git_heads_body {
2499         # uses global variable $project
2500         my ($headlist, $head, $from, $to, $extra) = @_;
2501         $from = 0 unless defined $from;
2502         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
2503
2504         print "<table class=\"heads\" cellspacing=\"0\">\n";
2505         my $alternate = 1;
2506         for (my $i = $from; $i <= $to; $i++) {
2507                 my $entry = $headlist->[$i];
2508                 my %ref = %$entry;
2509                 my $curr = $ref{'id'} eq $head;
2510                 if ($alternate) {
2511                         print "<tr class=\"dark\">\n";
2512                 } else {
2513                         print "<tr class=\"light\">\n";
2514                 }
2515                 $alternate ^= 1;
2516                 print "<td><i>$ref{'age'}</i></td>\n" .
2517                       ($curr ? "<td class=\"current_head\">" : "<td>") .
2518                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'}),
2519                                -class => "list name"},esc_html($ref{'name'})) .
2520                       "</td>\n" .
2521                       "<td class=\"link\">" .
2522                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'})}, "shortlog") . " | " .
2523                       $cgi->a({-href => href(action=>"log", hash=>$ref{'name'})}, "log") . " | " .
2524                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'name'}, hash_base=>$ref{'name'})}, "tree") .
2525                       "</td>\n" .
2526                       "</tr>";
2527         }
2528         if (defined $extra) {
2529                 print "<tr>\n" .
2530                       "<td colspan=\"3\">$extra</td>\n" .
2531                       "</tr>\n";
2532         }
2533         print "</table>\n";
2534 }
2535
2536 ## ======================================================================
2537 ## ======================================================================
2538 ## actions
2539
2540 sub git_project_list {
2541         my $order = $cgi->param('o');
2542         if (defined $order && $order !~ m/project|descr|owner|age/) {
2543                 die_error(undef, "Unknown order parameter");
2544         }
2545
2546         my @list = git_get_projects_list();
2547         if (!@list) {
2548                 die_error(undef, "No projects found");
2549         }
2550
2551         git_header_html();
2552         if (-f $home_text) {
2553                 print "<div class=\"index_include\">\n";
2554                 open (my $fd, $home_text);
2555                 print <$fd>;
2556                 close $fd;
2557                 print "</div>\n";
2558         }
2559         git_project_list_body(\@list, $order);
2560         git_footer_html();
2561 }
2562
2563 sub git_forks {
2564         my $order = $cgi->param('o');
2565         if (defined $order && $order !~ m/project|descr|owner|age/) {
2566                 die_error(undef, "Unknown order parameter");
2567         }
2568
2569         my @list = git_get_projects_list($project);
2570         if (!@list) {
2571                 die_error(undef, "No forks found");
2572         }
2573
2574         git_header_html();
2575         git_print_page_nav('','');
2576         git_print_header_div('summary', "$project forks");
2577         git_project_list_body(\@list, $order);
2578         git_footer_html();
2579 }
2580
2581 sub git_project_index {
2582         my @projects = git_get_projects_list($project);
2583
2584         print $cgi->header(
2585                 -type => 'text/plain',
2586                 -charset => 'utf-8',
2587                 -content_disposition => 'inline; filename="index.aux"');
2588
2589         foreach my $pr (@projects) {
2590                 if (!exists $pr->{'owner'}) {
2591                         $pr->{'owner'} = get_file_owner("$projectroot/$project");
2592                 }
2593
2594                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
2595                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
2596                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2597                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2598                 $path  =~ s/ /\+/g;
2599                 $owner =~ s/ /\+/g;
2600
2601                 print "$path $owner\n";
2602         }
2603 }
2604
2605 sub git_summary {
2606         my $descr = git_get_project_description($project) || "none";
2607         my $head = git_get_head_hash($project);
2608         my %co = parse_commit($head);
2609         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
2610
2611         my $owner = git_get_project_owner($project);
2612
2613         my $refs = git_get_references();
2614         my @taglist  = git_get_tags_list(15);
2615         my @headlist = git_get_heads_list(15);
2616         my @forklist;
2617         if (gitweb_check_feature('forks')) {
2618                 @forklist = git_get_projects_list($project);
2619         }
2620
2621         git_header_html();
2622         git_print_page_nav('summary','', $head);
2623
2624         print "<div class=\"title\">&nbsp;</div>\n";
2625         print "<table cellspacing=\"0\">\n" .
2626               "<tr><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
2627               "<tr><td>owner</td><td>$owner</td></tr>\n" .
2628               "<tr><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
2629         # use per project git URL list in $projectroot/$project/cloneurl
2630         # or make project git URL from git base URL and project name
2631         my $url_tag = "URL";
2632         my @url_list = git_get_project_url_list($project);
2633         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
2634         foreach my $git_url (@url_list) {
2635                 next unless $git_url;
2636                 print "<tr><td>$url_tag</td><td>$git_url</td></tr>\n";
2637                 $url_tag = "";
2638         }
2639         print "</table>\n";
2640
2641         if (-s "$projectroot/$project/README.html") {
2642                 if (open my $fd, "$projectroot/$project/README.html") {
2643                         print "<div class=\"title\">readme</div>\n";
2644                         print $_ while (<$fd>);
2645                         close $fd;
2646                 }
2647         }
2648
2649         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=17",
2650                 git_get_head_hash($project), "--"
2651                 or die_error(undef, "Open git-rev-list failed");
2652         my @revlist = map { chomp; $_ } <$fd>;
2653         close $fd;
2654         git_print_header_div('shortlog');
2655         git_shortlog_body(\@revlist, 0, 15, $refs,
2656                           $cgi->a({-href => href(action=>"shortlog")}, "..."));
2657
2658         if (@taglist) {
2659                 git_print_header_div('tags');
2660                 git_tags_body(\@taglist, 0, 15,
2661                               $cgi->a({-href => href(action=>"tags")}, "..."));
2662         }
2663
2664         if (@headlist) {
2665                 git_print_header_div('heads');
2666                 git_heads_body(\@headlist, $head, 0, 15,
2667                                $cgi->a({-href => href(action=>"heads")}, "..."));
2668         }
2669
2670         if (@forklist) {
2671                 git_print_header_div('forks');
2672                 git_project_list_body(\@forklist, undef, 0, 15,
2673                                       $cgi->a({-href => href(action=>"forks")}, "..."),
2674                                       'noheader');
2675         }
2676
2677         git_footer_html();
2678 }
2679
2680 sub git_tag {
2681         my $head = git_get_head_hash($project);
2682         git_header_html();
2683         git_print_page_nav('','', $head,undef,$head);
2684         my %tag = parse_tag($hash);
2685         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
2686         print "<div class=\"title_text\">\n" .
2687               "<table cellspacing=\"0\">\n" .
2688               "<tr>\n" .
2689               "<td>object</td>\n" .
2690               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2691                                $tag{'object'}) . "</td>\n" .
2692               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2693                                               $tag{'type'}) . "</td>\n" .
2694               "</tr>\n";
2695         if (defined($tag{'author'})) {
2696                 my %ad = parse_date($tag{'epoch'}, $tag{'tz'});
2697                 print "<tr><td>author</td><td>" . esc_html($tag{'author'}) . "</td></tr>\n";
2698                 print "<tr><td></td><td>" . $ad{'rfc2822'} .
2699                         sprintf(" (%02d:%02d %s)", $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'}) .
2700                         "</td></tr>\n";
2701         }
2702         print "</table>\n\n" .
2703               "</div>\n";
2704         print "<div class=\"page_body\">";
2705         my $comment = $tag{'comment'};
2706         foreach my $line (@$comment) {
2707                 print esc_html($line) . "<br/>\n";
2708         }
2709         print "</div>\n";
2710         git_footer_html();
2711 }
2712
2713 sub git_blame2 {
2714         my $fd;
2715         my $ftype;
2716
2717         my ($have_blame) = gitweb_check_feature('blame');
2718         if (!$have_blame) {
2719                 die_error('403 Permission denied', "Permission denied");
2720         }
2721         die_error('404 Not Found', "File name not defined") if (!$file_name);
2722         $hash_base ||= git_get_head_hash($project);
2723         die_error(undef, "Couldn't find base commit") unless ($hash_base);
2724         my %co = parse_commit($hash_base)
2725                 or die_error(undef, "Reading commit failed");
2726         if (!defined $hash) {
2727                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
2728                         or die_error(undef, "Error looking up file");
2729         }
2730         $ftype = git_get_type($hash);
2731         if ($ftype !~ "blob") {
2732                 die_error("400 Bad Request", "Object is not a blob");
2733         }
2734         open ($fd, "-|", git_cmd(), "blame", '-p', '--',
2735               $file_name, $hash_base)
2736                 or die_error(undef, "Open git-blame failed");
2737         git_header_html();
2738         my $formats_nav =
2739                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2740                         "blob") .
2741                 " | " .
2742                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2743                         "history") .
2744                 " | " .
2745                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
2746                         "HEAD");
2747         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
2748         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
2749         git_print_page_path($file_name, $ftype, $hash_base);
2750         my @rev_color = (qw(light2 dark2));
2751         my $num_colors = scalar(@rev_color);
2752         my $current_color = 0;
2753         my $last_rev;
2754         print <<HTML;
2755 <div class="page_body">
2756 <table class="blame">
2757 <tr><th>Commit</th><th>Line</th><th>Data</th></tr>
2758 HTML
2759         my %metainfo = ();
2760         while (1) {
2761                 $_ = <$fd>;
2762                 last unless defined $_;
2763                 my ($full_rev, $orig_lineno, $lineno, $group_size) =
2764                     /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/;
2765                 if (!exists $metainfo{$full_rev}) {
2766                         $metainfo{$full_rev} = {};
2767                 }
2768                 my $meta = $metainfo{$full_rev};
2769                 while (<$fd>) {
2770                         last if (s/^\t//);
2771                         if (/^(\S+) (.*)$/) {
2772                                 $meta->{$1} = $2;
2773                         }
2774                 }
2775                 my $data = $_;
2776                 my $rev = substr($full_rev, 0, 8);
2777                 my $author = $meta->{'author'};
2778                 my %date = parse_date($meta->{'author-time'},
2779                                       $meta->{'author-tz'});
2780                 my $date = $date{'iso-tz'};
2781                 if ($group_size) {
2782                         $current_color = ++$current_color % $num_colors;
2783                 }
2784                 print "<tr class=\"$rev_color[$current_color]\">\n";
2785                 if ($group_size) {
2786                         print "<td class=\"sha1\"";
2787                         print " title=\"". esc_html($author) . ", $date\"";
2788                         print " rowspan=\"$group_size\"" if ($group_size > 1);
2789                         print ">";
2790                         print $cgi->a({-href => href(action=>"commit",
2791                                                      hash=>$full_rev,
2792                                                      file_name=>$file_name)},
2793                                       esc_html($rev));
2794                         print "</td>\n";
2795                 }
2796                 my $blamed = href(action => 'blame',
2797                                   file_name => $meta->{'filename'},
2798                                   hash_base => $full_rev);
2799                 print "<td class=\"linenr\">";
2800                 print $cgi->a({ -href => "$blamed#l$orig_lineno",
2801                                 -id => "l$lineno",
2802                                 -class => "linenr" },
2803                               esc_html($lineno));
2804                 print "</td>";
2805                 print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
2806                 print "</tr>\n";
2807         }
2808         print "</table>\n";
2809         print "</div>";
2810         close $fd
2811                 or print "Reading blob failed\n";
2812         git_footer_html();
2813 }
2814
2815 sub git_blame {
2816         my $fd;
2817
2818         my ($have_blame) = gitweb_check_feature('blame');
2819         if (!$have_blame) {
2820                 die_error('403 Permission denied', "Permission denied");
2821         }
2822         die_error('404 Not Found', "File name not defined") if (!$file_name);
2823         $hash_base ||= git_get_head_hash($project);
2824         die_error(undef, "Couldn't find base commit") unless ($hash_base);
2825         my %co = parse_commit($hash_base)
2826                 or die_error(undef, "Reading commit failed");
2827         if (!defined $hash) {
2828                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
2829                         or die_error(undef, "Error lookup file");
2830         }
2831         open ($fd, "-|", git_cmd(), "annotate", '-l', '-t', '-r', $file_name, $hash_base)
2832                 or die_error(undef, "Open git-annotate failed");
2833         git_header_html();
2834         my $formats_nav =
2835                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2836                         "blob") .
2837                 " | " .
2838                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2839                         "history") .
2840                 " | " .
2841                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
2842                         "HEAD");
2843         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
2844         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
2845         git_print_page_path($file_name, 'blob', $hash_base);
2846         print "<div class=\"page_body\">\n";
2847         print <<HTML;
2848 <table class="blame">
2849   <tr>
2850     <th>Commit</th>
2851     <th>Age</th>
2852     <th>Author</th>
2853     <th>Line</th>
2854     <th>Data</th>
2855   </tr>
2856 HTML
2857         my @line_class = (qw(light dark));
2858         my $line_class_len = scalar (@line_class);
2859         my $line_class_num = $#line_class;
2860         while (my $line = <$fd>) {
2861                 my $long_rev;
2862                 my $short_rev;
2863                 my $author;
2864                 my $time;
2865                 my $lineno;
2866                 my $data;
2867                 my $age;
2868                 my $age_str;
2869                 my $age_class;
2870
2871                 chomp $line;
2872                 $line_class_num = ($line_class_num + 1) % $line_class_len;
2873
2874                 if ($line =~ m/^([0-9a-fA-F]{40})\t\(\s*([^\t]+)\t(\d+) [+-]\d\d\d\d\t(\d+)\)(.*)$/) {
2875                         $long_rev = $1;
2876                         $author   = $2;
2877                         $time     = $3;
2878                         $lineno   = $4;
2879                         $data     = $5;
2880                 } else {
2881                         print qq(  <tr><td colspan="5" class="error">Unable to parse: $line</td></tr>\n);
2882                         next;
2883                 }
2884                 $short_rev  = substr ($long_rev, 0, 8);
2885                 $age        = time () - $time;
2886                 $age_str    = age_string ($age);
2887                 $age_str    =~ s/ /&nbsp;/g;
2888                 $age_class  = age_class($age);
2889                 $author     = esc_html ($author);
2890                 $author     =~ s/ /&nbsp;/g;
2891
2892                 $data = untabify($data);
2893                 $data = esc_html ($data);
2894
2895                 print <<HTML;
2896   <tr class="$line_class[$line_class_num]">
2897     <td class="sha1"><a href="${\href (action=>"commit", hash=>$long_rev)}" class="text">$short_rev..</a></td>
2898     <td class="$age_class">$age_str</td>
2899     <td>$author</td>
2900     <td class="linenr"><a id="$lineno" href="#$lineno" class="linenr">$lineno</a></td>
2901     <td class="pre">$data</td>
2902   </tr>
2903 HTML
2904         } # while (my $line = <$fd>)
2905         print "</table>\n\n";
2906         close $fd
2907                 or print "Reading blob failed.\n";
2908         print "</div>";
2909         git_footer_html();
2910 }
2911
2912 sub git_tags {
2913         my $head = git_get_head_hash($project);
2914         git_header_html();
2915         git_print_page_nav('','', $head,undef,$head);
2916         git_print_header_div('summary', $project);
2917
2918         my @tagslist = git_get_tags_list();
2919         if (@tagslist) {
2920                 git_tags_body(\@tagslist);
2921         }
2922         git_footer_html();
2923 }
2924
2925 sub git_heads {
2926         my $head = git_get_head_hash($project);
2927         git_header_html();
2928         git_print_page_nav('','', $head,undef,$head);
2929         git_print_header_div('summary', $project);
2930
2931         my @headslist = git_get_heads_list();
2932         if (@headslist) {
2933                 git_heads_body(\@headslist, $head);
2934         }
2935         git_footer_html();
2936 }
2937
2938 sub git_blob_plain {
2939         my $expires;
2940
2941         if (!defined $hash) {
2942                 if (defined $file_name) {
2943                         my $base = $hash_base || git_get_head_hash($project);
2944                         $hash = git_get_hash_by_path($base, $file_name, "blob")
2945                                 or die_error(undef, "Error lookup file");
2946                 } else {
2947                         die_error(undef, "No file name defined");
2948                 }
2949         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
2950                 # blobs defined by non-textual hash id's can be cached
2951                 $expires = "+1d";
2952         }
2953
2954         my $type = shift;
2955         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
2956                 or die_error(undef, "Couldn't cat $file_name, $hash");
2957
2958         $type ||= blob_mimetype($fd, $file_name);
2959
2960         # save as filename, even when no $file_name is given
2961         my $save_as = "$hash";
2962         if (defined $file_name) {
2963                 $save_as = $file_name;
2964         } elsif ($type =~ m/^text\//) {
2965                 $save_as .= '.txt';
2966         }
2967
2968         print $cgi->header(
2969                 -type => "$type",
2970                 -expires=>$expires,
2971                 -content_disposition => 'inline; filename="' . "$save_as" . '"');
2972         undef $/;
2973         binmode STDOUT, ':raw';
2974         print <$fd>;
2975         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
2976         $/ = "\n";
2977         close $fd;
2978 }
2979
2980 sub git_blob {
2981         my $expires;
2982
2983         if (!defined $hash) {
2984                 if (defined $file_name) {
2985                         my $base = $hash_base || git_get_head_hash($project);
2986                         $hash = git_get_hash_by_path($base, $file_name, "blob")
2987                                 or die_error(undef, "Error lookup file");
2988                 } else {
2989                         die_error(undef, "No file name defined");
2990                 }
2991         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
2992                 # blobs defined by non-textual hash id's can be cached
2993                 $expires = "+1d";
2994         }
2995
2996         my ($have_blame) = gitweb_check_feature('blame');
2997         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
2998                 or die_error(undef, "Couldn't cat $file_name, $hash");
2999         my $mimetype = blob_mimetype($fd, $file_name);
3000         if ($mimetype !~ m/^text\//) {
3001                 close $fd;
3002                 return git_blob_plain($mimetype);
3003         }
3004         git_header_html(undef, $expires);
3005         my $formats_nav = '';
3006         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3007                 if (defined $file_name) {
3008                         if ($have_blame) {
3009                                 $formats_nav .=
3010                                         $cgi->a({-href => href(action=>"blame", hash_base=>$hash_base,
3011                                                                hash=>$hash, file_name=>$file_name)},
3012                                                 "blame") .
3013                                         " | ";
3014                         }
3015                         $formats_nav .=
3016                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3017                                                        hash=>$hash, file_name=>$file_name)},
3018                                         "history") .
3019                                 " | " .
3020                                 $cgi->a({-href => href(action=>"blob_plain",
3021                                                        hash=>$hash, file_name=>$file_name)},
3022                                         "raw") .
3023                                 " | " .
3024                                 $cgi->a({-href => href(action=>"blob",
3025                                                        hash_base=>"HEAD", file_name=>$file_name)},
3026                                         "HEAD");
3027                 } else {
3028                         $formats_nav .=
3029                                 $cgi->a({-href => href(action=>"blob_plain", hash=>$hash)}, "raw");
3030                 }
3031                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3032                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3033         } else {
3034                 print "<div class=\"page_nav\">\n" .
3035                       "<br/><br/></div>\n" .
3036                       "<div class=\"title\">$hash</div>\n";
3037         }
3038         git_print_page_path($file_name, "blob", $hash_base);
3039         print "<div class=\"page_body\">\n";
3040         my $nr;
3041         while (my $line = <$fd>) {
3042                 chomp $line;
3043                 $nr++;
3044                 $line = untabify($line);
3045                 printf "<div class=\"pre\"><a id=\"l%i\" href=\"#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
3046                        $nr, $nr, $nr, esc_html($line, -nbsp=>1);
3047         }
3048         close $fd
3049                 or print "Reading blob failed.\n";
3050         print "</div>";
3051         git_footer_html();
3052 }
3053
3054 sub git_tree {
3055         my $have_snapshot = gitweb_have_snapshot();
3056
3057         if (!defined $hash_base) {
3058                 $hash_base = "HEAD";
3059         }
3060         if (!defined $hash) {
3061                 if (defined $file_name) {
3062                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
3063                 } else {
3064                         $hash = $hash_base;
3065                 }
3066         }
3067         $/ = "\0";
3068         open my $fd, "-|", git_cmd(), "ls-tree", '-z', $hash
3069                 or die_error(undef, "Open git-ls-tree failed");
3070         my @entries = map { chomp; $_ } <$fd>;
3071         close $fd or die_error(undef, "Reading tree failed");
3072         $/ = "\n";
3073
3074         my $refs = git_get_references();
3075         my $ref = format_ref_marker($refs, $hash_base);
3076         git_header_html();
3077         my $basedir = '';
3078         my ($have_blame) = gitweb_check_feature('blame');
3079         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3080                 my @views_nav = ();
3081                 if (defined $file_name) {
3082                         push @views_nav,
3083                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3084                                                        hash=>$hash, file_name=>$file_name)},
3085                                         "history"),
3086                                 $cgi->a({-href => href(action=>"tree",
3087                                                        hash_base=>"HEAD", file_name=>$file_name)},
3088                                         "HEAD"),
3089                 }
3090                 if ($have_snapshot) {
3091                         # FIXME: Should be available when we have no hash base as well.
3092                         push @views_nav,
3093                                 $cgi->a({-href => href(action=>"snapshot", hash=>$hash)},
3094                                         "snapshot");
3095                 }
3096                 git_print_page_nav('tree','', $hash_base, undef, undef, join(' | ', @views_nav));
3097                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
3098         } else {
3099                 undef $hash_base;
3100                 print "<div class=\"page_nav\">\n";
3101                 print "<br/><br/></div>\n";
3102                 print "<div class=\"title\">$hash</div>\n";
3103         }
3104         if (defined $file_name) {
3105                 $basedir = $file_name;
3106                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
3107                         $basedir .= '/';
3108                 }
3109         }
3110         git_print_page_path($file_name, 'tree', $hash_base);
3111         print "<div class=\"page_body\">\n";
3112         print "<table cellspacing=\"0\">\n";
3113         my $alternate = 1;
3114         # '..' (top directory) link if possible
3115         if (defined $hash_base &&
3116             defined $file_name && $file_name =~ m![^/]+$!) {
3117                 if ($alternate) {
3118                         print "<tr class=\"dark\">\n";
3119                 } else {
3120                         print "<tr class=\"light\">\n";
3121                 }
3122                 $alternate ^= 1;
3123
3124                 my $up = $file_name;
3125                 $up =~ s!/?[^/]+$!!;
3126                 undef $up unless $up;
3127                 # based on git_print_tree_entry
3128                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
3129                 print '<td class="list">';
3130                 print $cgi->a({-href => href(action=>"tree", hash_base=>$hash_base,
3131                                              file_name=>$up)},
3132                               "..");
3133                 print "</td>\n";
3134                 print "<td class=\"link\"></td>\n";
3135
3136                 print "</tr>\n";
3137         }
3138         foreach my $line (@entries) {
3139                 my %t = parse_ls_tree_line($line, -z => 1);
3140
3141                 if ($alternate) {
3142                         print "<tr class=\"dark\">\n";
3143                 } else {
3144                         print "<tr class=\"light\">\n";
3145                 }
3146                 $alternate ^= 1;
3147
3148                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
3149
3150                 print "</tr>\n";
3151         }
3152         print "</table>\n" .
3153               "</div>";
3154         git_footer_html();
3155 }
3156
3157 sub git_snapshot {
3158         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
3159         my $have_snapshot = (defined $ctype && defined $suffix);
3160         if (!$have_snapshot) {
3161                 die_error('403 Permission denied', "Permission denied");
3162         }
3163
3164         if (!defined $hash) {
3165                 $hash = git_get_head_hash($project);
3166         }
3167
3168         my $filename = basename($project) . "-$hash.tar.$suffix";
3169
3170         print $cgi->header(
3171                 -type => 'application/x-tar',
3172                 -content_encoding => $ctype,
3173                 -content_disposition => 'inline; filename="' . "$filename" . '"',
3174                 -status => '200 OK');
3175
3176         my $git = git_cmd_str();
3177         my $name = $project;
3178         $name =~ s/\047/\047\\\047\047/g;
3179         open my $fd, "-|",
3180         "$git archive --format=tar --prefix=\'$name\'/ $hash | $command"
3181                 or die_error(undef, "Execute git-tar-tree failed.");
3182         binmode STDOUT, ':raw';
3183         print <$fd>;
3184         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3185         close $fd;
3186
3187 }
3188
3189 sub git_log {
3190         my $head = git_get_head_hash($project);
3191         if (!defined $hash) {
3192                 $hash = $head;
3193         }
3194         if (!defined $page) {
3195                 $page = 0;
3196         }
3197         my $refs = git_get_references();
3198
3199         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3200         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
3201                 or die_error(undef, "Open git-rev-list failed");
3202         my @revlist = map { chomp; $_ } <$fd>;
3203         close $fd;
3204
3205         my $paging_nav = format_paging_nav('log', $hash, $head, $page, $#revlist);
3206
3207         git_header_html();
3208         git_print_page_nav('log','', $hash,undef,undef, $paging_nav);
3209
3210         if (!@revlist) {
3211                 my %co = parse_commit($hash);
3212
3213                 git_print_header_div('summary', $project);
3214                 print "<div class=\"page_body\"> Last change $co{'age_string'}.<br/><br/></div>\n";
3215         }
3216         for (my $i = ($page * 100); $i <= $#revlist; $i++) {
3217                 my $commit = $revlist[$i];
3218                 my $ref = format_ref_marker($refs, $commit);
3219                 my %co = parse_commit($commit);
3220                 next if !%co;
3221                 my %ad = parse_date($co{'author_epoch'});
3222                 git_print_header_div('commit',
3223                                "<span class=\"age\">$co{'age_string'}</span>" .
3224                                esc_html($co{'title'}) . $ref,
3225                                $commit);
3226                 print "<div class=\"title_text\">\n" .
3227                       "<div class=\"log_link\">\n" .
3228                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
3229                       " | " .
3230                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
3231                       " | " .
3232                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
3233                       "<br/>\n" .
3234                       "</div>\n" .
3235                       "<i>" . esc_html($co{'author_name'}) .  " [$ad{'rfc2822'}]</i><br/>\n" .
3236                       "</div>\n";
3237
3238                 print "<div class=\"log_body\">\n";
3239                 git_print_log($co{'comment'}, -final_empty_line=> 1);
3240                 print "</div>\n";
3241         }
3242         git_footer_html();
3243 }
3244
3245 sub git_commit {
3246         my %co = parse_commit($hash);
3247         if (!%co) {
3248                 die_error(undef, "Unknown commit object");
3249         }
3250         my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3251         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
3252
3253         my $parent = $co{'parent'};
3254         if (!defined $parent) {
3255                 $parent = "--root";
3256         }
3257         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
3258                 @diff_opts, $parent, $hash, "--"
3259                 or die_error(undef, "Open git-diff-tree failed");
3260         my @difftree = map { chomp; $_ } <$fd>;
3261         close $fd or die_error(undef, "Reading git-diff-tree failed");
3262
3263         # non-textual hash id's can be cached
3264         my $expires;
3265         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3266                 $expires = "+1d";
3267         }
3268         my $refs = git_get_references();
3269         my $ref = format_ref_marker($refs, $co{'id'});
3270
3271         my $have_snapshot = gitweb_have_snapshot();
3272
3273         my @views_nav = ();
3274         if (defined $file_name && defined $co{'parent'}) {
3275                 push @views_nav,
3276                         $cgi->a({-href => href(action=>"blame", hash_parent=>$parent, file_name=>$file_name)},
3277                                 "blame");
3278         }
3279         git_header_html(undef, $expires);
3280         git_print_page_nav('commit', '',
3281                            $hash, $co{'tree'}, $hash,
3282                            join (' | ', @views_nav));
3283
3284         if (defined $co{'parent'}) {
3285                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
3286         } else {
3287                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
3288         }
3289         print "<div class=\"title_text\">\n" .
3290               "<table cellspacing=\"0\">\n";
3291         print "<tr><td>author</td><td>" . esc_html($co{'author'}) . "</td></tr>\n".
3292               "<tr>" .
3293               "<td></td><td> $ad{'rfc2822'}";
3294         if ($ad{'hour_local'} < 6) {
3295                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3296                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3297         } else {
3298                 printf(" (%02d:%02d %s)",
3299                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3300         }
3301         print "</td>" .
3302               "</tr>\n";
3303         print "<tr><td>committer</td><td>" . esc_html($co{'committer'}) . "</td></tr>\n";
3304         print "<tr><td></td><td> $cd{'rfc2822'}" .
3305               sprintf(" (%02d:%02d %s)", $cd{'hour_local'}, $cd{'minute_local'}, $cd{'tz_local'}) .
3306               "</td></tr>\n";
3307         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
3308         print "<tr>" .
3309               "<td>tree</td>" .
3310               "<td class=\"sha1\">" .
3311               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
3312                        class => "list"}, $co{'tree'}) .
3313               "</td>" .
3314               "<td class=\"link\">" .
3315               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
3316                       "tree");
3317         if ($have_snapshot) {
3318                 print " | " .
3319                       $cgi->a({-href => href(action=>"snapshot", hash=>$hash)}, "snapshot");
3320         }
3321         print "</td>" .
3322               "</tr>\n";
3323         my $parents = $co{'parents'};
3324         foreach my $par (@$parents) {
3325                 print "<tr>" .
3326                       "<td>parent</td>" .
3327                       "<td class=\"sha1\">" .
3328                       $cgi->a({-href => href(action=>"commit", hash=>$par),
3329                                class => "list"}, $par) .
3330                       "</td>" .
3331                       "<td class=\"link\">" .
3332                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
3333                       " | " .
3334                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
3335                       "</td>" .
3336                       "</tr>\n";
3337         }
3338         print "</table>".
3339               "</div>\n";
3340
3341         print "<div class=\"page_body\">\n";
3342         git_print_log($co{'comment'});
3343         print "</div>\n";
3344
3345         git_difftree_body(\@difftree, $hash, $parent);
3346
3347         git_footer_html();
3348 }
3349
3350 sub git_blobdiff {
3351         my $format = shift || 'html';
3352
3353         my $fd;
3354         my @difftree;
3355         my %diffinfo;
3356         my $expires;
3357
3358         # preparing $fd and %diffinfo for git_patchset_body
3359         # new style URI
3360         if (defined $hash_base && defined $hash_parent_base) {
3361                 if (defined $file_name) {
3362                         # read raw output
3363                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3364                                 $hash_parent_base, $hash_base,
3365                                 "--", $file_name
3366                                 or die_error(undef, "Open git-diff-tree failed");
3367                         @difftree = map { chomp; $_ } <$fd>;
3368                         close $fd
3369                                 or die_error(undef, "Reading git-diff-tree failed");
3370                         @difftree
3371                                 or die_error('404 Not Found', "Blob diff not found");
3372
3373                 } elsif (defined $hash &&
3374                          $hash =~ /[0-9a-fA-F]{40}/) {
3375                         # try to find filename from $hash
3376
3377                         # read filtered raw output
3378                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3379                                 $hash_parent_base, $hash_base, "--"
3380                                 or die_error(undef, "Open git-diff-tree failed");
3381                         @difftree =
3382                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
3383                                 # $hash == to_id
3384                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
3385                                 map { chomp; $_ } <$fd>;
3386                         close $fd
3387                                 or die_error(undef, "Reading git-diff-tree failed");
3388                         @difftree
3389                                 or die_error('404 Not Found', "Blob diff not found");
3390
3391                 } else {
3392                         die_error('404 Not Found', "Missing one of the blob diff parameters");
3393                 }
3394
3395                 if (@difftree > 1) {
3396                         die_error('404 Not Found', "Ambiguous blob diff specification");
3397                 }
3398
3399                 %diffinfo = parse_difftree_raw_line($difftree[0]);
3400                 $file_parent ||= $diffinfo{'from_file'} || $file_name || $diffinfo{'file'};
3401                 $file_name   ||= $diffinfo{'to_file'}   || $diffinfo{'file'};
3402
3403                 $hash_parent ||= $diffinfo{'from_id'};
3404                 $hash        ||= $diffinfo{'to_id'};
3405
3406                 # non-textual hash id's can be cached
3407                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
3408                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
3409                         $expires = '+1d';
3410                 }
3411
3412                 # open patch output
3413                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3414                         '-p', $hash_parent_base, $hash_base,
3415                         "--", $file_name
3416                         or die_error(undef, "Open git-diff-tree failed");
3417         }
3418
3419         # old/legacy style URI
3420         if (!%diffinfo && # if new style URI failed
3421             defined $hash && defined $hash_parent) {
3422                 # fake git-diff-tree raw output
3423                 $diffinfo{'from_mode'} = $diffinfo{'to_mode'} = "blob";
3424                 $diffinfo{'from_id'} = $hash_parent;
3425                 $diffinfo{'to_id'}   = $hash;
3426                 if (defined $file_name) {
3427                         if (defined $file_parent) {
3428                                 $diffinfo{'status'} = '2';
3429                                 $diffinfo{'from_file'} = $file_parent;
3430                                 $diffinfo{'to_file'}   = $file_name;
3431                         } else { # assume not renamed
3432                                 $diffinfo{'status'} = '1';
3433                                 $diffinfo{'from_file'} = $file_name;
3434                                 $diffinfo{'to_file'}   = $file_name;
3435                         }
3436                 } else { # no filename given
3437                         $diffinfo{'status'} = '2';
3438                         $diffinfo{'from_file'} = $hash_parent;
3439                         $diffinfo{'to_file'}   = $hash;
3440                 }
3441
3442                 # non-textual hash id's can be cached
3443                 if ($hash =~ m/^[0-9a-fA-F]{40}$/ &&
3444                     $hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3445                         $expires = '+1d';
3446                 }
3447
3448                 # open patch output
3449                 open $fd, "-|", git_cmd(), "diff", '-p', @diff_opts,
3450                         $hash_parent, $hash, "--"
3451                         or die_error(undef, "Open git-diff failed");
3452         } else  {
3453                 die_error('404 Not Found', "Missing one of the blob diff parameters")
3454                         unless %diffinfo;
3455         }
3456
3457         # header
3458         if ($format eq 'html') {
3459                 my $formats_nav =
3460                         $cgi->a({-href => href(action=>"blobdiff_plain",
3461                                                hash=>$hash, hash_parent=>$hash_parent,
3462                                                hash_base=>$hash_base, hash_parent_base=>$hash_parent_base,
3463                                                file_name=>$file_name, file_parent=>$file_parent)},
3464                                 "raw");
3465                 git_header_html(undef, $expires);
3466                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3467                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3468                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3469                 } else {
3470                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
3471                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
3472                 }
3473                 if (defined $file_name) {
3474                         git_print_page_path($file_name, "blob", $hash_base);
3475                 } else {
3476                         print "<div class=\"page_path\"></div>\n";
3477                 }
3478
3479         } elsif ($format eq 'plain') {
3480                 print $cgi->header(
3481                         -type => 'text/plain',
3482                         -charset => 'utf-8',
3483                         -expires => $expires,
3484                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
3485
3486                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3487
3488         } else {
3489                 die_error(undef, "Unknown blobdiff format");
3490         }
3491
3492         # patch
3493         if ($format eq 'html') {
3494                 print "<div class=\"page_body\">\n";
3495
3496                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
3497                 close $fd;
3498
3499                 print "</div>\n"; # class="page_body"
3500                 git_footer_html();
3501
3502         } else {
3503                 while (my $line = <$fd>) {
3504                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_html($diffinfo{'from_file'})!eg;
3505                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_html($diffinfo{'to_file'})!eg;
3506
3507                         print $line;
3508
3509                         last if $line =~ m!^\+\+\+!;
3510                 }
3511                 local $/ = undef;
3512                 print <$fd>;
3513                 close $fd;
3514         }
3515 }
3516
3517 sub git_blobdiff_plain {
3518         git_blobdiff('plain');
3519 }
3520
3521 sub git_commitdiff {
3522         my $format = shift || 'html';
3523         my %co = parse_commit($hash);
3524         if (!%co) {
3525                 die_error(undef, "Unknown commit object");
3526         }
3527
3528         # we need to prepare $formats_nav before any parameter munging
3529         my $formats_nav;
3530         if ($format eq 'html') {
3531                 $formats_nav =
3532                         $cgi->a({-href => href(action=>"commitdiff_plain",
3533                                                hash=>$hash, hash_parent=>$hash_parent)},
3534                                 "raw");
3535
3536                 if (defined $hash_parent) {
3537                         # commitdiff with two commits given
3538                         my $hash_parent_short = $hash_parent;
3539                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3540                                 $hash_parent_short = substr($hash_parent, 0, 7);
3541                         }
3542                         $formats_nav .=
3543                                 ' (from: ' .
3544                                 $cgi->a({-href => href(action=>"commitdiff",
3545                                                        hash=>$hash_parent)},
3546                                         esc_html($hash_parent_short)) .
3547                                 ')';
3548                 } elsif (!$co{'parent'}) {
3549                         # --root commitdiff
3550                         $formats_nav .= ' (initial)';
3551                 } elsif (scalar @{$co{'parents'}} == 1) {
3552                         # single parent commit
3553                         $formats_nav .=
3554                                 ' (parent: ' .
3555                                 $cgi->a({-href => href(action=>"commitdiff",
3556                                                        hash=>$co{'parent'})},
3557                                         esc_html(substr($co{'parent'}, 0, 7))) .
3558                                 ')';
3559                 } else {
3560                         # merge commit
3561                         $formats_nav .=
3562                                 ' (merge: ' .
3563                                 join(' ', map {
3564                                         $cgi->a({-href => href(action=>"commitdiff",
3565                                                                hash=>$_)},
3566                                                 esc_html(substr($_, 0, 7)));
3567                                 } @{$co{'parents'}} ) .
3568                                 ')';
3569                 }
3570         }
3571
3572         if (!defined $hash_parent) {
3573                 $hash_parent = $co{'parent'} || '--root';
3574         }
3575
3576         # read commitdiff
3577         my $fd;
3578         my @difftree;
3579         if ($format eq 'html') {
3580                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3581                         "--no-commit-id", "--patch-with-raw", "--full-index",
3582                         $hash_parent, $hash, "--"
3583                         or die_error(undef, "Open git-diff-tree failed");
3584
3585                 while (chomp(my $line = <$fd>)) {
3586                         # empty line ends raw part of diff-tree output
3587                         last unless $line;
3588                         push @difftree, $line;
3589                 }
3590
3591         } elsif ($format eq 'plain') {
3592                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3593                         '-p', $hash_parent, $hash, "--"
3594                         or die_error(undef, "Open git-diff-tree failed");
3595
3596         } else {
3597                 die_error(undef, "Unknown commitdiff format");
3598         }
3599
3600         # non-textual hash id's can be cached
3601         my $expires;
3602         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3603                 $expires = "+1d";
3604         }
3605
3606         # write commit message
3607         if ($format eq 'html') {
3608                 my $refs = git_get_references();
3609                 my $ref = format_ref_marker($refs, $co{'id'});
3610
3611                 git_header_html(undef, $expires);
3612                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
3613                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
3614                 git_print_authorship(\%co);
3615                 print "<div class=\"page_body\">\n";
3616                 if (@{$co{'comment'}} > 1) {
3617                         print "<div class=\"log\">\n";
3618                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
3619                         print "</div>\n"; # class="log"
3620                 }
3621
3622         } elsif ($format eq 'plain') {
3623                 my $refs = git_get_references("tags");
3624                 my $tagname = git_get_rev_name_tags($hash);
3625                 my $filename = basename($project) . "-$hash.patch";
3626
3627                 print $cgi->header(
3628                         -type => 'text/plain',
3629                         -charset => 'utf-8',
3630                         -expires => $expires,
3631                         -content_disposition => 'inline; filename="' . "$filename" . '"');
3632                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3633                 print <<TEXT;
3634 From: $co{'author'}
3635 Date: $ad{'rfc2822'} ($ad{'tz_local'})
3636 Subject: $co{'title'}
3637 TEXT
3638                 print "X-Git-Tag: $tagname\n" if $tagname;
3639                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3640
3641                 foreach my $line (@{$co{'comment'}}) {
3642                         print "$line\n";
3643                 }
3644                 print "---\n\n";
3645         }
3646
3647         # write patch
3648         if ($format eq 'html') {
3649                 git_difftree_body(\@difftree, $hash, $hash_parent);
3650                 print "<br/>\n";
3651
3652                 git_patchset_body($fd, \@difftree, $hash, $hash_parent);
3653                 close $fd;
3654                 print "</div>\n"; # class="page_body"
3655                 git_footer_html();
3656
3657         } elsif ($format eq 'plain') {
3658                 local $/ = undef;
3659                 print <$fd>;
3660                 close $fd
3661                         or print "Reading git-diff-tree failed\n";
3662         }
3663 }
3664
3665 sub git_commitdiff_plain {
3666         git_commitdiff('plain');
3667 }
3668
3669 sub git_history {
3670         if (!defined $hash_base) {
3671                 $hash_base = git_get_head_hash($project);
3672         }
3673         if (!defined $page) {
3674                 $page = 0;
3675         }
3676         my $ftype;
3677         my %co = parse_commit($hash_base);
3678         if (!%co) {
3679                 die_error(undef, "Unknown commit object");
3680         }
3681
3682         my $refs = git_get_references();
3683         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3684
3685         if (!defined $hash && defined $file_name) {
3686                 $hash = git_get_hash_by_path($hash_base, $file_name);
3687         }
3688         if (defined $hash) {
3689                 $ftype = git_get_type($hash);
3690         }
3691
3692         open my $fd, "-|",
3693                 git_cmd(), "rev-list", $limit, "--full-history", $hash_base, "--", $file_name
3694                         or die_error(undef, "Open git-rev-list-failed");
3695         my @revlist = map { chomp; $_ } <$fd>;
3696         close $fd
3697                 or die_error(undef, "Reading git-rev-list failed");
3698
3699         my $paging_nav = '';
3700         if ($page > 0) {
3701                 $paging_nav .=
3702                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3703                                                file_name=>$file_name)},
3704                                 "first");
3705                 $paging_nav .= " &sdot; " .
3706                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3707                                                file_name=>$file_name, page=>$page-1),
3708                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3709         } else {
3710                 $paging_nav .= "first";
3711                 $paging_nav .= " &sdot; prev";
3712         }
3713         if ($#revlist >= (100 * ($page+1)-1)) {
3714                 $paging_nav .= " &sdot; " .
3715                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3716                                                file_name=>$file_name, page=>$page+1),
3717                                  -accesskey => "n", -title => "Alt-n"}, "next");
3718         } else {
3719                 $paging_nav .= " &sdot; next";
3720         }
3721         my $next_link = '';
3722         if ($#revlist >= (100 * ($page+1)-1)) {
3723                 $next_link =
3724                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3725                                                file_name=>$file_name, page=>$page+1),
3726                                  -title => "Alt-n"}, "next");
3727         }
3728
3729         git_header_html();
3730         git_print_page_nav('history','', $hash_base,$co{'tree'},$hash_base, $paging_nav);
3731         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3732         git_print_page_path($file_name, $ftype, $hash_base);
3733
3734         git_history_body(\@revlist, ($page * 100), $#revlist,
3735                          $refs, $hash_base, $ftype, $next_link);
3736
3737         git_footer_html();
3738 }
3739
3740 sub git_search {
3741         if (!defined $searchtext) {
3742                 die_error(undef, "Text field empty");
3743         }
3744         if (!defined $hash) {
3745                 $hash = git_get_head_hash($project);
3746         }
3747         my %co = parse_commit($hash);
3748         if (!%co) {
3749                 die_error(undef, "Unknown commit object");
3750         }
3751
3752         $searchtype ||= 'commit';
3753         if ($searchtype eq 'pickaxe') {
3754                 # pickaxe may take all resources of your box and run for several minutes
3755                 # with every query - so decide by yourself how public you make this feature
3756                 my ($have_pickaxe) = gitweb_check_feature('pickaxe');
3757                 if (!$have_pickaxe) {
3758                         die_error('403 Permission denied', "Permission denied");
3759                 }
3760         }
3761
3762         git_header_html();
3763         git_print_page_nav('','', $hash,$co{'tree'},$hash);
3764         git_print_header_div('commit', esc_html($co{'title'}), $hash);
3765
3766         print "<table cellspacing=\"0\">\n";
3767         my $alternate = 1;
3768         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
3769                 $/ = "\0";
3770                 open my $fd, "-|", git_cmd(), "rev-list",
3771                         "--header", "--parents", $hash, "--"
3772                         or next;
3773                 while (my $commit_text = <$fd>) {
3774                         if (!grep m/$searchtext/i, $commit_text) {
3775                                 next;
3776                         }
3777                         if ($searchtype eq 'author' && !grep m/\nauthor .*$searchtext/i, $commit_text) {
3778                                 next;
3779                         }
3780                         if ($searchtype eq 'committer' && !grep m/\ncommitter .*$searchtext/i, $commit_text) {
3781                                 next;
3782                         }
3783                         my @commit_lines = split "\n", $commit_text;
3784                         my %co = parse_commit(undef, \@commit_lines);
3785                         if (!%co) {
3786                                 next;
3787                         }
3788                         if ($alternate) {
3789                                 print "<tr class=\"dark\">\n";
3790                         } else {
3791                                 print "<tr class=\"light\">\n";
3792                         }
3793                         $alternate ^= 1;
3794                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
3795                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
3796                               "<td>" .
3797                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}), -class => "list subject"},
3798                                        esc_html(chop_str($co{'title'}, 50)) . "<br/>");
3799                         my $comment = $co{'comment'};
3800                         foreach my $line (@$comment) {
3801                                 if ($line =~ m/^(.*)($searchtext)(.*)$/i) {
3802                                         my $lead = esc_html($1) || "";
3803                                         $lead = chop_str($lead, 30, 10);
3804                                         my $match = esc_html($2) || "";
3805                                         my $trail = esc_html($3) || "";
3806                                         $trail = chop_str($trail, 30, 10);
3807                                         my $text = "$lead<span class=\"match\">$match</span>$trail";
3808                                         print chop_str($text, 80, 5) . "<br/>\n";
3809                                 }
3810                         }
3811                         print "</td>\n" .
3812                               "<td class=\"link\">" .
3813                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
3814                               " | " .
3815                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
3816                         print "</td>\n" .
3817                               "</tr>\n";
3818                 }
3819                 close $fd;
3820         }
3821
3822         if ($searchtype eq 'pickaxe') {
3823                 $/ = "\n";
3824                 my $git_command = git_cmd_str();
3825                 open my $fd, "-|", "$git_command rev-list $hash | " .
3826                         "$git_command diff-tree -r --stdin -S\'$searchtext\'";
3827                 undef %co;
3828                 my @files;
3829                 while (my $line = <$fd>) {
3830                         if (%co && $line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)\t(.*)$/) {
3831                                 my %set;
3832                                 $set{'file'} = $6;
3833                                 $set{'from_id'} = $3;
3834                                 $set{'to_id'} = $4;
3835                                 $set{'id'} = $set{'to_id'};
3836                                 if ($set{'id'} =~ m/0{40}/) {
3837                                         $set{'id'} = $set{'from_id'};
3838                                 }
3839                                 if ($set{'id'} =~ m/0{40}/) {
3840                                         next;
3841                                 }
3842                                 push @files, \%set;
3843                         } elsif ($line =~ m/^([0-9a-fA-F]{40})$/){
3844                                 if (%co) {
3845                                         if ($alternate) {
3846                                                 print "<tr class=\"dark\">\n";
3847                                         } else {
3848                                                 print "<tr class=\"light\">\n";
3849                                         }
3850                                         $alternate ^= 1;
3851                                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
3852                                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
3853                                               "<td>" .
3854                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
3855                                                       -class => "list subject"},
3856                                                       esc_html(chop_str($co{'title'}, 50)) . "<br/>");
3857                                         while (my $setref = shift @files) {
3858                                                 my %set = %$setref;
3859                                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
3860                                                                              hash=>$set{'id'}, file_name=>$set{'file'}),
3861                                                               -class => "list"},
3862                                                               "<span class=\"match\">" . esc_html($set{'file'}) . "</span>") .
3863                                                       "<br/>\n";
3864                                         }
3865                                         print "</td>\n" .
3866                                               "<td class=\"link\">" .
3867                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
3868                                               " | " .
3869                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
3870                                         print "</td>\n" .
3871                                               "</tr>\n";
3872                                 }
3873                                 %co = parse_commit($1);
3874                         }
3875                 }
3876                 close $fd;
3877         }
3878         print "</table>\n";
3879         git_footer_html();
3880 }
3881
3882 sub git_search_help {
3883         git_header_html();
3884         git_print_page_nav('','', $hash,$hash,$hash);
3885         print <<EOT;
3886 <dl>
3887 <dt><b>commit</b></dt>
3888 <dd>The commit messages and authorship information will be scanned for the given string.</dd>
3889 <dt><b>author</b></dt>
3890 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given string.</dd>
3891 <dt><b>committer</b></dt>
3892 <dd>Name and e-mail of the committer and date of commit will be scanned for the given string.</dd>
3893 EOT
3894         my ($have_pickaxe) = gitweb_check_feature('pickaxe');
3895         if ($have_pickaxe) {
3896                 print <<EOT;
3897 <dt><b>pickaxe</b></dt>
3898 <dd>All commits that caused the string to appear or disappear from any file (changes that
3899 added, removed or "modified" the string) will be listed. This search can take a while and
3900 takes a lot of strain on the server, so please use it wisely.</dd>
3901 EOT
3902         }
3903         print "</dl>\n";
3904         git_footer_html();
3905 }
3906
3907 sub git_shortlog {
3908         my $head = git_get_head_hash($project);
3909         if (!defined $hash) {
3910                 $hash = $head;
3911         }
3912         if (!defined $page) {
3913                 $page = 0;
3914         }
3915         my $refs = git_get_references();
3916
3917         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3918         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
3919                 or die_error(undef, "Open git-rev-list failed");
3920         my @revlist = map { chomp; $_ } <$fd>;
3921         close $fd;
3922
3923         my $paging_nav = format_paging_nav('shortlog', $hash, $head, $page, $#revlist);
3924         my $next_link = '';
3925         if ($#revlist >= (100 * ($page+1)-1)) {
3926                 $next_link =
3927                         $cgi->a({-href => href(action=>"shortlog", hash=>$hash, page=>$page+1),
3928                                  -title => "Alt-n"}, "next");
3929         }
3930
3931
3932         git_header_html();
3933         git_print_page_nav('shortlog','', $hash,$hash,$hash, $paging_nav);
3934         git_print_header_div('summary', $project);
3935
3936         git_shortlog_body(\@revlist, ($page * 100), $#revlist, $refs, $next_link);
3937
3938         git_footer_html();
3939 }
3940
3941 ## ......................................................................
3942 ## feeds (RSS, OPML)
3943
3944 sub git_rss {
3945         # http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
3946         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=150",
3947                 git_get_head_hash($project), "--"
3948                 or die_error(undef, "Open git-rev-list failed");
3949         my @revlist = map { chomp; $_ } <$fd>;
3950         close $fd or die_error(undef, "Reading git-rev-list failed");
3951         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
3952         print <<XML;
3953 <?xml version="1.0" encoding="utf-8"?>
3954 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
3955 <channel>
3956 <title>$project $my_uri $my_url</title>
3957 <link>${\esc_html("$my_url?p=$project;a=summary")}</link>
3958 <description>$project log</description>
3959 <language>en</language>
3960 XML
3961
3962         for (my $i = 0; $i <= $#revlist; $i++) {
3963                 my $commit = $revlist[$i];
3964                 my %co = parse_commit($commit);
3965                 # we read 150, we always show 30 and the ones more recent than 48 hours
3966                 if (($i >= 20) && ((time - $co{'committer_epoch'}) > 48*60*60)) {
3967                         last;
3968                 }
3969                 my %cd = parse_date($co{'committer_epoch'});
3970                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3971                         $co{'parent'}, $co{'id'}, "--"
3972                         or next;
3973                 my @difftree = map { chomp; $_ } <$fd>;
3974                 close $fd
3975                         or next;
3976                 print "<item>\n" .
3977                       "<title>" .
3978                       sprintf("%d %s %02d:%02d", $cd{'mday'}, $cd{'month'}, $cd{'hour'}, $cd{'minute'}) . " - " . esc_html($co{'title'}) .
3979                       "</title>\n" .
3980                       "<author>" . esc_html($co{'author'}) . "</author>\n" .
3981                       "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
3982                       "<guid isPermaLink=\"true\">" . esc_html("$my_url?p=$project;a=commit;h=$commit") . "</guid>\n" .
3983                       "<link>" . esc_html("$my_url?p=$project;a=commit;h=$commit") . "</link>\n" .
3984                       "<description>" . esc_html($co{'title'}) . "</description>\n" .
3985                       "<content:encoded>" .
3986                       "<![CDATA[\n";
3987                 my $comment = $co{'comment'};
3988                 foreach my $line (@$comment) {
3989                         $line = to_utf8($line);
3990                         print "$line<br/>\n";
3991                 }
3992                 print "<br/>\n";
3993                 foreach my $line (@difftree) {
3994                         if (!($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/)) {
3995                                 next;
3996                         }
3997                         my $file = esc_html(unquote($7));
3998                         $file = to_utf8($file);
3999                         print "$file<br/>\n";
4000                 }
4001                 print "]]>\n" .
4002                       "</content:encoded>\n" .
4003                       "</item>\n";
4004         }
4005         print "</channel></rss>";
4006 }
4007
4008 sub git_opml {
4009         my @list = git_get_projects_list();
4010
4011         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
4012         print <<XML;
4013 <?xml version="1.0" encoding="utf-8"?>
4014 <opml version="1.0">
4015 <head>
4016   <title>$site_name OPML Export</title>
4017 </head>
4018 <body>
4019 <outline text="git RSS feeds">
4020 XML
4021
4022         foreach my $pr (@list) {
4023                 my %proj = %$pr;
4024                 my $head = git_get_head_hash($proj{'path'});
4025                 if (!defined $head) {
4026                         next;
4027                 }
4028                 $git_dir = "$projectroot/$proj{'path'}";
4029                 my %co = parse_commit($head);
4030                 if (!%co) {
4031                         next;
4032                 }
4033
4034                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
4035                 my $rss  = "$my_url?p=$proj{'path'};a=rss";
4036                 my $html = "$my_url?p=$proj{'path'};a=summary";
4037                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
4038         }
4039         print <<XML;
4040 </outline>
4041 </body>
4042 </opml>
4043 XML
4044 }