git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213     "from" => \$sender,
 214 );
 215
 216 # Handle Uncouth Termination
 217 sub signal_handler {
 218
 219         # Make text normal
 220         print color("reset"), "\n";
 221
 222         # SMTP password masked
 223         system "stty echo";
 224
 225         # tmp files from --compose
 226         if (defined $compose_filename) {
 227                 if (-e $compose_filename) {
 228                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229                 }
 230                 if (-e ($compose_filename . ".final")) {
 231                         print "'$compose_filename.final' contains the composed email.\n"
 232                 }
 233         }
 234
 235         exit;
 236 };
 237
 238 $SIG{TERM} = \&signal_handler;
 239 $SIG{INT}  = \&signal_handler;
 240
 241 # Begin by accumulating all the variables (defined above), that we will end up
 242 # needing, first, from the command line:
 243
 244 my $rc = GetOptions("sender|from=s" => \$sender,
 245                     "in-reply-to=s" => \$initial_reply_to,
 246                     "subject=s" => \$initial_subject,
 247                     "to=s" => \@to,
 248                     "cc=s" => \@initial_cc,
 249                     "bcc=s" => \@bcclist,
 250                     "chain-reply-to!" => \$chain_reply_to,
 251                     "smtp-server=s" => \$smtp_server,
 252                     "smtp-server-port=s" => \$smtp_server_port,
 253                     "smtp-user=s" => \$smtp_authuser,
 254                     "smtp-pass:s" => \$smtp_authpass,
 255                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 256                     "smtp-encryption=s" => \$smtp_encryption,
 257                     "identity=s" => \$identity,
 258                     "annotate" => \$annotate,
 259                     "compose" => \$compose,
 260                     "quiet" => \$quiet,
 261                     "cc-cmd=s" => \$cc_cmd,
 262                     "suppress-from!" => \$suppress_from,
 263                     "suppress-cc=s" => \@suppress_cc,
 264                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 265                     "confirm=s" => \$confirm,
 266                     "dry-run" => \$dry_run,
 267                     "envelope-sender=s" => \$envelope_sender,
 268                     "thread!" => \$thread,
 269                     "validate!" => \$validate,
 270                     "format-patch!" => \$format_patch,
 271          );
 272
 273 unless ($rc) {
 274     usage();
 275 }
 276
 277 die "Cannot run git format-patch from outside a repository\n"
 278         if $format_patch and not $repo;
 279
 280 # Now, let's fill any that aren't set in with defaults:
 281
 282 sub read_config {
 283         my ($prefix) = @_;
 284
 285         foreach my $setting (keys %config_bool_settings) {
 286                 my $target = $config_bool_settings{$setting}->[0];
 287                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 288         }
 289
 290         foreach my $setting (keys %config_settings) {
 291                 my $target = $config_settings{$setting};
 292                 if (ref($target) eq "ARRAY") {
 293                         unless (@$target) {
 294                                 my @values = Git::config(@repo, "$prefix.$setting");
 295                                 @$target = @values if (@values && defined $values[0]);
 296                         }
 297                 }
 298                 else {
 299                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 300                 }
 301         }
 302
 303         if (!defined $smtp_encryption) {
 304                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 305                 if (defined $enc) {
 306                         $smtp_encryption = $enc;
 307                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 308                         $smtp_encryption = 'ssl';
 309                 }
 310         }
 311 }
 312
 313 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 314 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 315 read_config("sendemail.$identity") if (defined $identity);
 316 read_config("sendemail");
 317
 318 # fall back on builtin bool defaults
 319 foreach my $setting (values %config_bool_settings) {
 320         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 321 }
 322
 323 # 'default' encryption is none -- this only prevents a warning
 324 $smtp_encryption = '' unless (defined $smtp_encryption);
 325
 326 # Set CC suppressions
 327 my(%suppress_cc);
 328 if (@suppress_cc) {
 329         foreach my $entry (@suppress_cc) {
 330                 die "Unknown --suppress-cc field: '$entry'\n"
 331                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 332                 $suppress_cc{$entry} = 1;
 333         }
 334 }
 335
 336 if ($suppress_cc{'all'}) {
 337         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 338                 $suppress_cc{$entry} = 1;
 339         }
 340         delete $suppress_cc{'all'};
 341 }
 342
 343 # If explicit old-style ones are specified, they trump --suppress-cc.
 344 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 345 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 346
 347 if ($suppress_cc{'body'}) {
 348         foreach my $entry (qw (sob bodycc)) {
 349                 $suppress_cc{$entry} = 1;
 350         }
 351         delete $suppress_cc{'body'};
 352 }
 353
 354 # Set confirm's default value
 355 my $confirm_unconfigured = !defined $confirm;
 356 if ($confirm_unconfigured) {
 357         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 358 };
 359 die "Unknown --confirm setting: '$confirm'\n"
 360         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 361
 362 # Debugging, print out the suppressions.
 363 if (0) {
 364         print "suppressions:\n";
 365         foreach my $entry (keys %suppress_cc) {
 366                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 367         }
 368 }
 369
 370 my ($repoauthor, $repocommitter);
 371 ($repoauthor) = Git::ident_person(@repo, 'author');
 372 ($repocommitter) = Git::ident_person(@repo, 'committer');
 373
 374 # Verify the user input
 375
 376 foreach my $entry (@to) {
 377         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 378 }
 379
 380 foreach my $entry (@initial_cc) {
 381         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 382 }
 383
 384 foreach my $entry (@bcclist) {
 385         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 386 }
 387
 388 sub parse_address_line {
 389         if ($have_mail_address) {
 390                 return map { $_->format } Mail::Address->parse($_[0]);
 391         } else {
 392                 return split_addrs($_[0]);
 393         }
 394 }
 395
 396 sub split_addrs {
 397         return quotewords('\s*,\s*', 1, @_);
 398 }
 399
 400 my %aliases;
 401 my %parse_alias = (
 402         # multiline formats can be supported in the future
 403         mutt => sub { my $fh = shift; while (<$fh>) {
 404                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 405                         my ($alias, $addr) = ($1, $2);
 406                         $addr =~ s/#.*$//; # mutt allows # comments
 407                          # commas delimit multiple addresses
 408                         $aliases{$alias} = [ split_addrs($addr) ];
 409                 }}},
 410         mailrc => sub { my $fh = shift; while (<$fh>) {
 411                 if (/^alias\s+(\S+)\s+(.*)$/) {
 412                         # spaces delimit multiple addresses
 413                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 414                 }}},
 415         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 416                 for (my $x = ''; defined($x); $x = $_) {
 417                         chomp $x;
 418                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 419                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 420                         $aliases{$1} = [ split_addrs($2) ];
 421                 }},
 422         elm => sub  { my $fh = shift;
 423                       while (<$fh>) {
 424                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 425                               my ($alias, $addr) = ($1, $2);
 426                                $aliases{$alias} = [ split_addrs($addr) ];
 427                           }
 428                       } },
 429
 430         gnus => sub { my $fh = shift; while (<$fh>) {
 431                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 432                         $aliases{$1} = [ $2 ];
 433                 }}}
 434 );
 435
 436 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 437         foreach my $file (@alias_files) {
 438                 open my $fh, '<', $file or die "opening $file: $!\n";
 439                 $parse_alias{$aliasfiletype}->($fh);
 440                 close $fh;
 441         }
 442 }
 443
 444 ($sender) = expand_aliases($sender) if defined $sender;
 445
 446 # returns 1 if the conflict must be solved using it as a format-patch argument
 447 sub check_file_rev_conflict($) {
 448         return unless $repo;
 449         my $f = shift;
 450         try {
 451                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 452                 if (defined($format_patch)) {
 453                         return $format_patch;
 454                 }
 455                 die(<<EOF);
 456 File '$f' exists but it could also be the range of commits
 457 to produce patches for.  Please disambiguate by...
 458
 459     * Saying "./$f" if you mean a file; or
 460     * Giving --format-patch option if you mean a range.
 461 EOF
 462         } catch Git::Error::Command with {
 463                 return 0;
 464         }
 465 }
 466
 467 # Now that all the defaults are set, process the rest of the command line
 468 # arguments and collect up the files that need to be processed.
 469 my @rev_list_opts;
 470 while (defined(my $f = shift @ARGV)) {
 471         if ($f eq "--") {
 472                 push @rev_list_opts, "--", @ARGV;
 473                 @ARGV = ();
 474         } elsif (-d $f and !check_file_rev_conflict($f)) {
 475                 opendir(DH,$f)
 476                         or die "Failed to opendir $f: $!";
 477
 478                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 479                                 sort readdir(DH);
 480                 closedir(DH);
 481         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 482                 push @files, $f;
 483         } else {
 484                 push @rev_list_opts, $f;
 485         }
 486 }
 487
 488 if (@rev_list_opts) {
 489         die "Cannot run git format-patch from outside a repository\n"
 490                 unless $repo;
 491         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 492 }
 493
 494 if ($validate) {
 495         foreach my $f (@files) {
 496                 unless (-p $f) {
 497                         my $error = validate_patch($f);
 498                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 499                 }
 500         }
 501 }
 502
 503 if (@files) {
 504         unless ($quiet) {
 505                 print $_,"\n" for (@files);
 506         }
 507 } else {
 508         print STDERR "\nNo patch files specified!\n\n";
 509         usage();
 510 }
 511
 512 sub get_patch_subject($) {
 513         my $fn = shift;
 514         open (my $fh, '<', $fn);
 515         while (my $line = <$fh>) {
 516                 next unless ($line =~ /^Subject: (.*)$/);
 517                 close $fh;
 518                 return "GIT: $1\n";
 519         }
 520         close $fh;
 521         die "No subject line in $fn ?";
 522 }
 523
 524 if ($compose) {
 525         # Note that this does not need to be secure, but we will make a small
 526         # effort to have it be unique
 527         $compose_filename = ($repo ?
 528                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 530         open(C,">",$compose_filename)
 531                 or die "Failed to open for writing $compose_filename: $!";
 532
 533
 534         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 535         my $tpl_subject = $initial_subject || '';
 536         my $tpl_reply_to = $initial_reply_to || '';
 537
 538         print C <<EOT;
 539 From $tpl_sender # This line is ignored.
 540 GIT: Lines beginning in "GIT:" will be removed.
 541 GIT: Consider including an overall diffstat or table of contents
 542 GIT: for the patch you are writing.
 543 GIT:
 544 GIT: Clear the body content if you don't wish to send a summary.
 545 From: $tpl_sender
 546 Subject: $tpl_subject
 547 In-Reply-To: $tpl_reply_to
 548
 549 EOT
 550         for my $f (@files) {
 551                 print C get_patch_subject($f);
 552         }
 553         close(C);
 554
 555         if ($annotate) {
 556                 do_edit($compose_filename, @files);
 557         } else {
 558                 do_edit($compose_filename);
 559         }
 560
 561         open(C2,">",$compose_filename . ".final")
 562                 or die "Failed to open $compose_filename.final : " . $!;
 563
 564         open(C,"<",$compose_filename)
 565                 or die "Failed to open $compose_filename : " . $!;
 566
 567         my $need_8bit_cte = file_has_nonascii($compose_filename);
 568         my $in_body = 0;
 569         my $summary_empty = 1;
 570         while(<C>) {
 571                 next if m/^GIT:/;
 572                 if ($in_body) {
 573                         $summary_empty = 0 unless (/^\n$/);
 574                 } elsif (/^\n$/) {
 575                         $in_body = 1;
 576                         if ($need_8bit_cte) {
 577                                 print C2 "MIME-Version: 1.0\n",
 578                                          "Content-Type: text/plain; ",
 579                                            "charset=UTF-8\n",
 580                                          "Content-Transfer-Encoding: 8bit\n";
 581                         }
 582                 } elsif (/^MIME-Version:/i) {
 583                         $need_8bit_cte = 0;
 584                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 585                         $initial_subject = $1;
 586                         my $subject = $initial_subject;
 587                         $_ = "Subject: " .
 588                                 ($subject =~ /[^[:ascii:]]/ ?
 589                                  quote_rfc2047($subject) :
 590                                  $subject) .
 591                                 "\n";
 592                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 593                         $initial_reply_to = $1;
 594                         next;
 595                 } elsif (/^From:\s*(.+)\s*$/i) {
 596                         $sender = $1;
 597                         next;
 598                 } elsif (/^(?:To|Cc|Bcc):/i) {
 599                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 600                         next;
 601                 }
 602                 print C2 $_;
 603         }
 604         close(C);
 605         close(C2);
 606
 607         if ($summary_empty) {
 608                 print "Summary email is empty, skipping it\n";
 609                 $compose = -1;
 610         }
 611 } elsif ($annotate) {
 612         do_edit(@files);
 613 }
 614
 615 sub ask {
 616         my ($prompt, %arg) = @_;
 617         my $valid_re = $arg{valid_re};
 618         my $default = $arg{default};
 619         my $resp;
 620         my $i = 0;
 621         return defined $default ? $default : undef
 622                 unless defined $term->IN and defined fileno($term->IN) and
 623                        defined $term->OUT and defined fileno($term->OUT);
 624         while ($i++ < 10) {
 625                 $resp = $term->readline($prompt);
 626                 if (!defined $resp) { # EOF
 627                         print "\n";
 628                         return defined $default ? $default : undef;
 629                 }
 630                 if ($resp eq '' and defined $default) {
 631                         return $default;
 632                 }
 633                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 634                         return $resp;
 635                 }
 636         }
 637         return undef;
 638 }
 639
 640 my $prompting = 0;
 641 if (!defined $sender) {
 642         $sender = $repoauthor || $repocommitter || '';
 643         $sender = ask("Who should the emails appear to be from? [$sender] ",
 644                       default => $sender);
 645         print "Emails will be sent from: ", $sender, "\n";
 646         $prompting++;
 647 }
 648
 649 if (!@to) {
 650         my $to = ask("Who should the emails be sent to? ");
 651         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 652         $prompting++;
 653 }
 654
 655 sub expand_aliases {
 656         return map { expand_one_alias($_) } @_;
 657 }
 658
 659 my %EXPANDED_ALIASES;
 660 sub expand_one_alias {
 661         my $alias = shift;
 662         if ($EXPANDED_ALIASES{$alias}) {
 663                 die "fatal: alias '$alias' expands to itself\n";
 664         }
 665         local $EXPANDED_ALIASES{$alias} = 1;
 666         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 667 }
 668
 669 @to = expand_aliases(@to);
 670 @to = (map { sanitize_address($_) } @to);
 671 @initial_cc = expand_aliases(@initial_cc);
 672 @bcclist = expand_aliases(@bcclist);
 673
 674 if ($thread && !defined $initial_reply_to && $prompting) {
 675         $initial_reply_to = ask(
 676                 "Message-ID to be used as In-Reply-To for the first email? ");
 677 }
 678 if (defined $initial_reply_to) {
 679         $initial_reply_to =~ s/^\s*<?//;
 680         $initial_reply_to =~ s/>?\s*$//;
 681         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 682 }
 683
 684 if (!defined $smtp_server) {
 685         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 686                 if (-x $_) {
 687                         $smtp_server = $_;
 688                         last;
 689                 }
 690         }
 691         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 692 }
 693
 694 if ($compose && $compose > 0) {
 695         @files = ($compose_filename . ".final", @files);
 696 }
 697
 698 # Variables we set as part of the loop over files
 699 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 700         $needs_confirm, $message_num, $ask_default);
 701
 702 sub extract_valid_address {
 703         my $address = shift;
 704         my $local_part_regexp = '[^<>"\s@]+';
 705         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 706
 707         # check for a local address:
 708         return $address if ($address =~ /^($local_part_regexp)$/);
 709
 710         $address =~ s/^\s*<(.*)>\s*$/$1/;
 711         if ($have_email_valid) {
 712                 return scalar Email::Valid->address($address);
 713         } else {
 714                 # less robust/correct than the monster regexp in Email::Valid,
 715                 # but still does a 99% job, and one less dependency
 716                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 717                 return $1;
 718         }
 719 }
 720
 721 # Usually don't need to change anything below here.
 722
 723 # we make a "fake" message id by taking the current number
 724 # of seconds since the beginning of Unix time and tacking on
 725 # a random number to the end, in case we are called quicker than
 726 # 1 second since the last time we were called.
 727
 728 # We'll setup a template for the message id, using the "from" address:
 729
 730 my ($message_id_stamp, $message_id_serial);
 731 sub make_message_id
 732 {
 733         my $uniq;
 734         if (!defined $message_id_stamp) {
 735                 $message_id_stamp = sprintf("%s-%s", time, $$);
 736                 $message_id_serial = 0;
 737         }
 738         $message_id_serial++;
 739         $uniq = "$message_id_stamp-$message_id_serial";
 740
 741         my $du_part;
 742         for ($sender, $repocommitter, $repoauthor) {
 743                 $du_part = extract_valid_address(sanitize_address($_));
 744                 last if (defined $du_part and $du_part ne '');
 745         }
 746         if (not defined $du_part or $du_part eq '') {
 747                 use Sys::Hostname qw();
 748                 $du_part = 'user@' . Sys::Hostname::hostname();
 749         }
 750         my $message_id_template = "<%s-git-send-email-%s>";
 751         $message_id = sprintf($message_id_template, $uniq, $du_part);
 752         #print "new message id = $message_id\n"; # Was useful for debugging
 753 }
 754
 755
 756
 757 $time = time - scalar $#files;
 758
 759 sub unquote_rfc2047 {
 760         local ($_) = @_;
 761         my $encoding;
 762         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 763                 $encoding = $1;
 764                 s/_/ /g;
 765                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 766         }
 767         return wantarray ? ($_, $encoding) : $_;
 768 }
 769
 770 sub quote_rfc2047 {
 771         local $_ = shift;
 772         my $encoding = shift || 'UTF-8';
 773         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 774         s/(.*)/=\?$encoding\?q\?$1\?=/;
 775         return $_;
 776 }
 777
 778 sub is_rfc2047_quoted {
 779         my $s = shift;
 780         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 781         my $encoded_text = '[!->@-~]+';
 782         length($s) <= 75 &&
 783         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 784 }
 785
 786 # use the simplest quoting being able to handle the recipient
 787 sub sanitize_address
 788 {
 789         my ($recipient) = @_;
 790         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 791
 792         if (not $recipient_name) {
 793                 return "$recipient";
 794         }
 795
 796         # if recipient_name is already quoted, do nothing
 797         if (is_rfc2047_quoted($recipient_name)) {
 798                 return $recipient;
 799         }
 800
 801         # rfc2047 is needed if a non-ascii char is included
 802         if ($recipient_name =~ /[^[:ascii:]]/) {
 803                 $recipient_name =~ s/^"(.*)"$/$1/;
 804                 $recipient_name = quote_rfc2047($recipient_name);
 805         }
 806
 807         # double quotes are needed if specials or CTLs are included
 808         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 809                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 810                 $recipient_name = "\"$recipient_name\"";
 811         }
 812
 813         return "$recipient_name $recipient_addr";
 814
 815 }
 816
 817 # Returns 1 if the message was sent, and 0 otherwise.
 818 # In actuality, the whole program dies when there
 819 # is an error sending a message.
 820
 821 sub send_message
 822 {
 823         my @recipients = unique_email_list(@to);
 824         @cc = (grep { my $cc = extract_valid_address($_);
 825                       not grep { $cc eq $_ } @recipients
 826                     }
 827                map { sanitize_address($_) }
 828                @cc);
 829         my $to = join (",\n\t", @recipients);
 830         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 831         @recipients = (map { extract_valid_address($_) } @recipients);
 832         my $date = format_2822_time($time++);
 833         my $gitversion = '@@GIT_VERSION@@';
 834         if ($gitversion =~ m/..GIT_VERSION../) {
 835             $gitversion = Git::version();
 836         }
 837
 838         my $cc = join(",\n\t", unique_email_list(@cc));
 839         my $ccline = "";
 840         if ($cc ne '') {
 841                 $ccline = "\nCc: $cc";
 842         }
 843         my $sanitized_sender = sanitize_address($sender);
 844         make_message_id() unless defined($message_id);
 845
 846         my $header = "From: $sanitized_sender
 847 To: $to${ccline}
 848 Subject: $subject
 849 Date: $date
 850 Message-Id: $message_id
 851 X-Mailer: git-send-email $gitversion
 852 ";
 853         if ($reply_to) {
 854
 855                 $header .= "In-Reply-To: $reply_to\n";
 856                 $header .= "References: $references\n";
 857         }
 858         if (@xh) {
 859                 $header .= join("\n", @xh) . "\n";
 860         }
 861
 862         my @sendmail_parameters = ('-i', @recipients);
 863         my $raw_from = $sanitized_sender;
 864         $raw_from = $envelope_sender if (defined $envelope_sender);
 865         $raw_from = extract_valid_address($raw_from);
 866         unshift (@sendmail_parameters,
 867                         '-f', $raw_from) if(defined $envelope_sender);
 868
 869         if ($needs_confirm && !$dry_run) {
 870                 print "\n$header\n";
 871                 if ($needs_confirm eq "inform") {
 872                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 873                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 874                         print "    The Cc list above has been expanded by additional\n";
 875                         print "    addresses found in the patch commit message. By default\n";
 876                         print "    send-email prompts before sending whenever this occurs.\n";
 877                         print "    This behavior is controlled by the sendemail.confirm\n";
 878                         print "    configuration setting.\n";
 879                         print "\n";
 880                         print "    For additional information, run 'git send-email --help'.\n";
 881                         print "    To retain the current behavior, but squelch this message,\n";
 882                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 883                 }
 884                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 885                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 886                          default => $ask_default);
 887                 die "Send this email reply required" unless defined $_;
 888                 if (/^n/i) {
 889                         return 0;
 890                 } elsif (/^q/i) {
 891                         cleanup_compose_files();
 892                         exit(0);
 893                 } elsif (/^a/i) {
 894                         $confirm = 'never';
 895                 }
 896         }
 897
 898         if ($dry_run) {
 899                 # We don't want to send the email.
 900         } elsif ($smtp_server =~ m#^/#) {
 901                 my $pid = open my $sm, '|-';
 902                 defined $pid or die $!;
 903                 if (!$pid) {
 904                         exec($smtp_server, @sendmail_parameters) or die $!;
 905                 }
 906                 print $sm "$header\n$message";
 907                 close $sm or die $?;
 908         } else {
 909
 910                 if (!defined $smtp_server) {
 911                         die "The required SMTP server is not properly defined."
 912                 }
 913
 914                 if ($smtp_encryption eq 'ssl') {
 915                         $smtp_server_port ||= 465; # ssmtp
 916                         require Net::SMTP::SSL;
 917                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 918                 }
 919                 else {
 920                         require Net::SMTP;
 921                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 922                                                  ? "$smtp_server:$smtp_server_port"
 923                                                  : $smtp_server);
 924                         if ($smtp_encryption eq 'tls' && $smtp) {
 925                                 require Net::SMTP::SSL;
 926                                 $smtp->command('STARTTLS');
 927                                 $smtp->response();
 928                                 if ($smtp->code == 220) {
 929                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 930                                                 or die "STARTTLS failed! ".$smtp->message;
 931                                         $smtp_encryption = '';
 932                                         # Send EHLO again to receive fresh
 933                                         # supported commands
 934                                         $smtp->hello();
 935                                 } else {
 936                                         die "Server does not support STARTTLS! ".$smtp->message;
 937                                 }
 938                         }
 939                 }
 940
 941                 if (!$smtp) {
 942                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 943                 }
 944
 945                 if (defined $smtp_authuser) {
 946
 947                         if (!defined $smtp_authpass) {
 948
 949                                 system "stty -echo";
 950
 951                                 do {
 952                                         print "Password: ";
 953                                         $_ = <STDIN>;
 954                                         print "\n";
 955                                 } while (!defined $_);
 956
 957                                 chomp($smtp_authpass = $_);
 958
 959                                 system "stty echo";
 960                         }
 961
 962                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 963                 }
 964
 965                 $smtp->mail( $raw_from ) or die $smtp->message;
 966                 $smtp->to( @recipients ) or die $smtp->message;
 967                 $smtp->data or die $smtp->message;
 968                 $smtp->datasend("$header\n$message") or die $smtp->message;
 969                 $smtp->dataend() or die $smtp->message;
 970                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 971         }
 972         if ($quiet) {
 973                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 974         } else {
 975                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 976                 if ($smtp_server !~ m#^/#) {
 977                         print "Server: $smtp_server\n";
 978                         print "MAIL FROM:<$raw_from>\n";
 979                         foreach my $entry (@recipients) {
 980                             print "RCPT TO:<$entry>\n";
 981                         }
 982                 } else {
 983                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 984                 }
 985                 print $header, "\n";
 986                 if ($smtp) {
 987                         print "Result: ", $smtp->code, ' ',
 988                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 989                 } else {
 990                         print "Result: OK\n";
 991                 }
 992         }
 993
 994         return 1;
 995 }
 996
 997 $reply_to = $initial_reply_to;
 998 $references = $initial_reply_to || '';
 999 $subject = $initial_subject;
1000 $message_num = 0;
1001
1002 foreach my $t (@files) {
1003         open(F,"<",$t) or die "can't open file $t";
1004
1005         my $author = undef;
1006         my $author_encoding;
1007         my $has_content_type;
1008         my $body_encoding;
1009         @cc = ();
1010         @xh = ();
1011         my $input_format = undef;
1012         my @header = ();
1013         $message = "";
1014         $message_num++;
1015         # First unfold multiline header fields
1016         while(<F>) {
1017                 last if /^\s*$/;
1018                 if (/^\s+\S/ and @header) {
1019                         chomp($header[$#header]);
1020                         s/^\s+/ /;
1021                         $header[$#header] .= $_;
1022             } else {
1023                         push(@header, $_);
1024                 }
1025         }
1026         # Now parse the header
1027         foreach(@header) {
1028                 if (/^From /) {
1029                         $input_format = 'mbox';
1030                         next;
1031                 }
1032                 chomp;
1033                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1034                         $input_format = 'mbox';
1035                 }
1036
1037                 if (defined $input_format && $input_format eq 'mbox') {
1038                         if (/^Subject:\s+(.*)$/) {
1039                                 $subject = $1;
1040                         }
1041                         elsif (/^From:\s+(.*)$/) {
1042                                 ($author, $author_encoding) = unquote_rfc2047($1);
1043                                 next if $suppress_cc{'author'};
1044                                 next if $suppress_cc{'self'} and $author eq $sender;
1045                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1046                                         $1, $_) unless $quiet;
1047                                 push @cc, $1;
1048                         }
1049                         elsif (/^Cc:\s+(.*)$/) {
1050                                 foreach my $addr (parse_address_line($1)) {
1051                                         if (unquote_rfc2047($addr) eq $sender) {
1052                                                 next if ($suppress_cc{'self'});
1053                                         } else {
1054                                                 next if ($suppress_cc{'cc'});
1055                                         }
1056                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1057                                                 $addr, $_) unless $quiet;
1058                                         push @cc, $addr;
1059                                 }
1060                         }
1061                         elsif (/^Content-type:/i) {
1062                                 $has_content_type = 1;
1063                                 if (/charset="?([^ "]+)/) {
1064                                         $body_encoding = $1;
1065                                 }
1066                                 push @xh, $_;
1067                         }
1068                         elsif (/^Message-Id: (.*)/i) {
1069                                 $message_id = $1;
1070                         }
1071                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1072                                 push @xh, $_;
1073                         }
1074
1075                 } else {
1076                         # In the traditional
1077                         # "send lots of email" format,
1078                         # line 1 = cc
1079                         # line 2 = subject
1080                         # So let's support that, too.
1081                         $input_format = 'lots';
1082                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1083                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1084                                         $_, $_) unless $quiet;
1085                                 push @cc, $_;
1086                         } elsif (!defined $subject) {
1087                                 $subject = $_;
1088                         }
1089                 }
1090         }
1091         # Now parse the message body
1092         while(<F>) {
1093                 $message .=  $_;
1094                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1095                         chomp;
1096                         my ($what, $c) = ($1, $2);
1097                         chomp $c;
1098                         if ($c eq $sender) {
1099                                 next if ($suppress_cc{'self'});
1100                         } else {
1101                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1102                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1103                         }
1104                         push @cc, $c;
1105                         printf("(body) Adding cc: %s from line '%s'\n",
1106                                 $c, $_) unless $quiet;
1107                 }
1108         }
1109         close F;
1110
1111         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1112                 open(F, "$cc_cmd \Q$t\E |")
1113                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1114                 while(<F>) {
1115                         my $c = $_;
1116                         $c =~ s/^\s*//g;
1117                         $c =~ s/\n$//g;
1118                         next if ($c eq $sender and $suppress_from);
1119                         push @cc, $c;
1120                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1121                                 $c, $cc_cmd) unless $quiet;
1122                 }
1123                 close F
1124                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1125         }
1126
1127         if (defined $author and $author ne $sender) {
1128                 $message = "From: $author\n\n$message";
1129                 if (defined $author_encoding) {
1130                         if ($has_content_type) {
1131                                 if ($body_encoding eq $author_encoding) {
1132                                         # ok, we already have the right encoding
1133                                 }
1134                                 else {
1135                                         # uh oh, we should re-encode
1136                                 }
1137                         }
1138                         else {
1139                                 push @xh,
1140                                   'MIME-Version: 1.0',
1141                                   "Content-Type: text/plain; charset=$author_encoding",
1142                                   'Content-Transfer-Encoding: 8bit';
1143                         }
1144                 }
1145         }
1146
1147         $needs_confirm = (
1148                 $confirm eq "always" or
1149                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1150                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1151         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1152
1153         @cc = (@initial_cc, @cc);
1154
1155         my $message_was_sent = send_message();
1156
1157         # set up for the next message
1158         if ($thread && $message_was_sent &&
1159                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0)) {
1160                 $reply_to = $message_id;
1161                 if (length $references > 0) {
1162                         $references .= "\n $message_id";
1163                 } else {
1164                         $references = "$message_id";
1165                 }
1166         }
1167         $message_id = undef;
1168 }
1169
1170 cleanup_compose_files();
1171
1172 sub cleanup_compose_files() {
1173         unlink($compose_filename, $compose_filename . ".final") if $compose;
1174 }
1175
1176 $smtp->quit if $smtp;
1177
1178 sub unique_email_list(@) {
1179         my %seen;
1180         my @emails;
1181
1182         foreach my $entry (@_) {
1183                 if (my $clean = extract_valid_address($entry)) {
1184                         $seen{$clean} ||= 0;
1185                         next if $seen{$clean}++;
1186                         push @emails, $entry;
1187                 } else {
1188                         print STDERR "W: unable to extract a valid address",
1189                                         " from: $entry\n";
1190                 }
1191         }
1192         return @emails;
1193 }
1194
1195 sub validate_patch {
1196         my $fn = shift;
1197         open(my $fh, '<', $fn)
1198                 or die "unable to open $fn: $!\n";
1199         while (my $line = <$fh>) {
1200                 if (length($line) > 998) {
1201                         return "$.: patch contains a line longer than 998 characters";
1202                 }
1203         }
1204         return undef;
1205 }
1206
1207 sub file_has_nonascii {
1208         my $fn = shift;
1209         open(my $fh, '<', $fn)
1210                 or die "unable to open $fn: $!\n";
1211         while (my $line = <$fh>) {
1212                 return 1 if $line =~ /[^[:ascii:]]/;
1213         }
1214         return 0;
1215 }