?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-cvsimport: fix merging with remote parent branch
[git/haiku.git] / git-svn.perl
blob38e1d5944d309f6b1f4b58fd5857a1bfb0545cc9
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
458
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift or die "SVN or git revision required ",
523 "as a command-line argument\n";
524 my $result;
525 if ($revision_or_hash =~ /^r\d+$/) {
526 my $head = shift;
527 $head ||= 'HEAD';
528 my @refs;
529 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
530 unless ($gs) {
531 die "Unable to determine upstream SVN information from ",
532 "$head history\n";
533 }
534 my $desired_revision = substr($revision_or_hash, 1);
535 $result = $gs->rev_map_get($desired_revision);
536 } else {
537 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
538 $result = $rev;
539 }
540 print "$result\n" if $result;
541 }
542
543 sub cmd_rebase {
544 command_noisy(qw/update-index --refresh/);
545 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
546 unless ($gs) {
547 die "Unable to determine upstream SVN information from ",
548 "working tree history\n";
549 }
550 if (command(qw/diff-index HEAD --/)) {
551 print STDERR "Cannot rebase with uncommited changes:\n";
552 command_noisy('status');
553 exit 1;
554 }
555 unless ($_local) {
556 # rebase will checkout for us, so no need to do it explicitly
557 $_no_checkout = 'true';
558 $_fetch_all ? $gs->fetch_all : $gs->fetch;
559 }
560 command_noisy(rebase_cmd(), $gs->refname);
561 }
562
563 sub cmd_show_ignore {
564 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
565 $gs ||= Git::SVN->new;
566 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
567 $gs->prop_walk($gs->{path}, $r, sub {
568 my ($gs, $path, $props) = @_;
569 print STDOUT "\n# $path\n";
570 my $s = $props->{'svn:ignore'} or return;
571 $s =~ s/[\r\n]+/\n/g;
572 chomp $s;
573 $s =~ s#^#$path#gm;
574 print STDOUT "$s\n";
575 });
576 }
577
578 sub cmd_show_externals {
579 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
580 $gs ||= Git::SVN->new;
581 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
582 $gs->prop_walk($gs->{path}, $r, sub {
583 my ($gs, $path, $props) = @_;
584 print STDOUT "\n# $path\n";
585 my $s = $props->{'svn:externals'} or return;
586 $s =~ s/[\r\n]+/\n/g;
587 chomp $s;
588 $s =~ s#^#$path#gm;
589 print STDOUT "$s\n";
590 });
591 }
592
593 sub cmd_create_ignore {
594 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
595 $gs ||= Git::SVN->new;
596 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
597 $gs->prop_walk($gs->{path}, $r, sub {
598 my ($gs, $path, $props) = @_;
599 # $path is of the form /path/to/dir/
600 my $ignore = '.' . $path . '.gitignore';
601 my $s = $props->{'svn:ignore'} or return;
602 open(GITIGNORE, '>', $ignore)
603 or fatal("Failed to open `$ignore' for writing: $!");
604 $s =~ s/[\r\n]+/\n/g;
605 chomp $s;
606 # Prefix all patterns so that the ignore doesn't apply
607 # to sub-directories.
608 $s =~ s#^#/#gm;
609 print GITIGNORE "$s\n";
610 close(GITIGNORE)
611 or fatal("Failed to close `$ignore': $!");
612 command_noisy('add', $ignore);
613 });
614 }
615
616 sub canonicalize_path {
617 my ($path) = @_;
618 my $dot_slash_added = 0;
619 if (substr($path, 0, 1) ne "/") {
620 $path = "./" . $path;
621 $dot_slash_added = 1;
622 }
623 # File::Spec->canonpath doesn't collapse x/../y into y (for a
624 # good reason), so let's do this manually.
625 $path =~ s#/+#/#g;
626 $path =~ s#/\.(?:/|$)#/#g;
627 $path =~ s#/[^/]+/\.\.##g;
628 $path =~ s#/$##g;
629 $path =~ s#^\./## if $dot_slash_added;
630 return $path;
631 }
632
633 # get_svnprops(PATH)
634 # ------------------
635 # Helper for cmd_propget and cmd_proplist below.
636 sub get_svnprops {
637 my $path = shift;
638 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
639 $gs ||= Git::SVN->new;
640
641 # prefix THE PATH by the sub-directory from which the user
642 # invoked us.
643 $path = $cmd_dir_prefix . $path;
644 fatal("No such file or directory: $path") unless -e $path;
645 my $is_dir = -d $path ? 1 : 0;
646 $path = $gs->{path} . '/' . $path;
647
648 # canonicalize the path (otherwise libsvn will abort or fail to
649 # find the file)
650 $path = canonicalize_path($path);
651
652 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
653 my $props;
654 if ($is_dir) {
655 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
656 }
657 else {
658 (undef, $props) = $gs->ra->get_file($path, $r, undef);
659 }
660 return $props;
661 }
662
663 # cmd_propget (PROP, PATH)
664 # ------------------------
665 # Print the SVN property PROP for PATH.
666 sub cmd_propget {
667 my ($prop, $path) = @_;
668 $path = '.' if not defined $path;
669 usage(1) if not defined $prop;
670 my $props = get_svnprops($path);
671 if (not defined $props->{$prop}) {
672 fatal("`$path' does not have a `$prop' SVN property.");
673 }
674 print $props->{$prop} . "\n";
675 }
676
677 # cmd_proplist (PATH)
678 # -------------------
679 # Print the list of SVN properties for PATH.
680 sub cmd_proplist {
681 my $path = shift;
682 $path = '.' if not defined $path;
683 my $props = get_svnprops($path);
684 print "Properties on '$path':\n";
685 foreach (sort keys %{$props}) {
686 print " $_\n";
687 }
688 }
689
690 sub cmd_multi_init {
691 my $url = shift;
692 unless (defined $_trunk || defined $_branches || defined $_tags) {
693 usage(1);
694 }
695
696 # there are currently some bugs that prevent multi-init/multi-fetch
697 # setups from working well without this.
698 $Git::SVN::_minimize_url = 1;
699
700 $_prefix = '' unless defined $_prefix;
701 if (defined $url) {
702 $url =~ s#/+$##;
703 init_subdir(@_);
704 }
705 do_git_init_db();
706 if (defined $_trunk) {
707 my $trunk_ref = $_prefix . 'trunk';
708 # try both old-style and new-style lookups:
709 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
710 unless ($gs_trunk) {
711 my ($trunk_url, $trunk_path) =
712 complete_svn_url($url, $_trunk);
713 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
714 undef, $trunk_ref);
715 }
716 }
717 return unless defined $_branches || defined $_tags;
718 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
719 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
720 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
721 }
722
723 sub cmd_multi_fetch {
724 my $remotes = Git::SVN::read_all_remotes();
725 foreach my $repo_id (sort keys %$remotes) {
726 if ($remotes->{$repo_id}->{url}) {
727 Git::SVN::fetch_all($repo_id, $remotes);
728 }
729 }
730 }
731
732 # this command is special because it requires no metadata
733 sub cmd_commit_diff {
734 my ($ta, $tb, $url) = @_;
735 my $usage = "Usage: $0 commit-diff -r<revision> ".
736 "<tree-ish> <tree-ish> [<URL>]";
737 fatal($usage) if (!defined $ta || !defined $tb);
738 my $svn_path;
739 if (!defined $url) {
740 my $gs = eval { Git::SVN->new };
741 if (!$gs) {
742 fatal("Needed URL or usable git-svn --id in ",
743 "the command-line\n", $usage);
744 }
745 $url = $gs->{url};
746 $svn_path = $gs->{path};
747 }
748 unless (defined $_revision) {
749 fatal("-r|--revision is a required argument\n", $usage);
750 }
751 if (defined $_message && defined $_file) {
752 fatal("Both --message/-m and --file/-F specified ",
753 "for the commit message.\n",
754 "I have no idea what you mean");
755 }
756 if (defined $_file) {
757 $_message = file_to_s($_file);
758 } else {
759 $_message ||= get_commit_entry($tb)->{log};
760 }
761 my $ra ||= Git::SVN::Ra->new($url);
762 $svn_path ||= $ra->{svn_path};
763 my $r = $_revision;
764 if ($r eq 'HEAD') {
765 $r = $ra->get_latest_revnum;
766 } elsif ($r !~ /^\d+$/) {
767 die "revision argument: $r not understood by git-svn\n";
768 }
769 my %ed_opts = ( r => $r,
770 log => $_message,
771 ra => $ra,
772 tree_a => $ta,
773 tree_b => $tb,
774 editor_cb => sub { print "Committed r$_[0]\n" },
775 svn_path => $svn_path );
776 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
777 print "No changes\n$ta == $tb\n";
778 }
779 }
780
781 sub cmd_info {
782 my $path = canonicalize_path(shift or ".");
783 unless (scalar(@_) == 0) {
784 die "Too many arguments specified\n";
785 }
786
787 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
788
789 if (!$file_type && !$diff_status) {
790 print STDERR "$path: (Not a versioned resource)\n\n";
791 return;
792 }
793
794 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
795 unless ($gs) {
796 die "Unable to determine upstream SVN information from ",
797 "working tree history\n";
798 }
799 my $full_url = $url . ($path eq "." ? "" : "/$path");
800
801 if ($_url) {
802 print $full_url, "\n";
803 return;
804 }
805
806 my $result = "Path: $path\n";
807 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
808 $result .= "URL: " . $full_url . "\n";
809
810 eval {
811 my $repos_root = $gs->repos_root;
812 Git::SVN::remove_username($repos_root);
813 $result .= "Repository Root: $repos_root\n";
814 };
815 if ($@) {
816 $result .= "Repository Root: (offline)\n";
817 }
818 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
819 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
820
821 $result .= "Node Kind: " .
822 ($file_type eq "dir" ? "directory" : "file") . "\n";
823
824 my $schedule = $diff_status eq "A"
825 ? "add"
826 : ($diff_status eq "D" ? "delete" : "normal");
827 $result .= "Schedule: $schedule\n";
828
829 if ($diff_status eq "A") {
830 print $result, "\n";
831 return;
832 }
833
834 my ($lc_author, $lc_rev, $lc_date_utc);
835 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
836 my $log = command_output_pipe(@args);
837 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
838 while (<$log>) {
839 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
840 $lc_author = $1;
841 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
842 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
843 (undef, $lc_rev, undef) = ::extract_metadata($1);
844 }
845 }
846 close $log;
847
848 Git::SVN::Log::set_local_timezone();
849
850 $result .= "Last Changed Author: $lc_author\n";
851 $result .= "Last Changed Rev: $lc_rev\n";
852 $result .= "Last Changed Date: " .
853 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
854
855 if ($file_type ne "dir") {
856 my $text_last_updated_date =
857 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
858 $result .=
859 "Text Last Updated: " .
860 Git::SVN::Log::format_svn_date($text_last_updated_date) .
861 "\n";
862 my $checksum;
863 if ($diff_status eq "D") {
864 my ($fh, $ctx) =
865 command_output_pipe(qw(cat-file blob), "HEAD:$path");
866 if ($file_type eq "link") {
867 my $file_name = <$fh>;
868 $checksum = md5sum("link $file_name");
869 } else {
870 $checksum = md5sum($fh);
871 }
872 command_close_pipe($fh, $ctx);
873 } elsif ($file_type eq "link") {
874 my $file_name =
875 command(qw(cat-file blob), "HEAD:$path");
876 $checksum =
877 md5sum("link " . $file_name);
878 } else {
879 open FILE, "<", $path or die $!;
880 $checksum = md5sum(\*FILE);
881 close FILE or die $!;
882 }
883 $result .= "Checksum: " . $checksum . "\n";
884 }
885
886 print $result, "\n";
887 }
888
889 ########################### utility functions #########################
890
891 sub rebase_cmd {
892 my @cmd = qw/rebase/;
893 push @cmd, '-v' if $_verbose;
894 push @cmd, qw/--merge/ if $_merge;
895 push @cmd, "--strategy=$_strategy" if $_strategy;
896 @cmd;
897 }
898
899 sub post_fetch_checkout {
900 return if $_no_checkout;
901 my $gs = $Git::SVN::_head or return;
902 return if verify_ref('refs/heads/master^0');
903
904 my $valid_head = verify_ref('HEAD^0');
905 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
906 return if ($valid_head || !verify_ref('HEAD^0'));
907
908 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
909 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
910 return if -f $index;
911
912 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
913 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
914 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
915 print STDERR "Checked out HEAD:\n ",
916 $gs->full_url, " r", $gs->last_rev, "\n";
917 }
918
919 sub complete_svn_url {
920 my ($url, $path) = @_;
921 $path =~ s#/+$##;
922 if ($path !~ m#^[a-z\+]+://#) {
923 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
924 fatal("E: '$path' is not a complete URL ",
925 "and a separate URL is not specified");
926 }
927 return ($url, $path);
928 }
929 return ($path, '');
930 }
931
932 sub complete_url_ls_init {
933 my ($ra, $repo_path, $switch, $pfx) = @_;
934 unless ($repo_path) {
935 print STDERR "W: $switch not specified\n";
936 return;
937 }
938 $repo_path =~ s#/+$##;
939 if ($repo_path =~ m#^[a-z\+]+://#) {
940 $ra = Git::SVN::Ra->new($repo_path);
941 $repo_path = '';
942 } else {
943 $repo_path =~ s#^/+##;
944 unless ($ra) {
945 fatal("E: '$repo_path' is not a complete URL ",
946 "and a separate URL is not specified");
947 }
948 }
949 my $url = $ra->{url};
950 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
951 my $k = "svn-remote.$gs->{repo_id}.url";
952 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
953 if ($orig_url && ($orig_url ne $gs->{url})) {
954 die "$k already set: $orig_url\n",
955 "wanted to set to: $gs->{url}\n";
956 }
957 command_oneline('config', $k, $gs->{url}) unless $orig_url;
958 my $remote_path = "$ra->{svn_path}/$repo_path/*";
959 $remote_path =~ s#/+#/#g;
960 $remote_path =~ s#^/##g;
961 my ($n) = ($switch =~ /^--(\w+)/);
962 if (length $pfx && $pfx !~ m#/$#) {
963 die "--prefix='$pfx' must have a trailing slash '/'\n";
964 }
965 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
966 "$remote_path:refs/remotes/$pfx*");
967 }
968
969 sub verify_ref {
970 my ($ref) = @_;
971 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
972 { STDERR => 0 }); };
973 }
974
975 sub get_tree_from_treeish {
976 my ($treeish) = @_;
977 # $treeish can be a symbolic ref, too:
978 my $type = command_oneline(qw/cat-file -t/, $treeish);
979 my $expected;
980 while ($type eq 'tag') {
981 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
982 }
983 if ($type eq 'commit') {
984 $expected = (grep /^tree /, command(qw/cat-file commit/,
985 $treeish))[0];
986 ($expected) = ($expected =~ /^tree ($sha1)$/o);
987 die "Unable to get tree from $treeish\n" unless $expected;
988 } elsif ($type eq 'tree') {
989 $expected = $treeish;
990 } else {
991 die "$treeish is a $type, expected tree, tag or commit\n";
992 }
993 return $expected;
994 }
995
996 sub get_commit_entry {
997 my ($treeish) = shift;
998 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
999 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1000 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1001 open my $log_fh, '>', $commit_editmsg or croak $!;
1002
1003 my $type = command_oneline(qw/cat-file -t/, $treeish);
1004 if ($type eq 'commit' || $type eq 'tag') {
1005 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1006 $type, $treeish);
1007 my $in_msg = 0;
1008 while (<$msg_fh>) {
1009 if (!$in_msg) {
1010 $in_msg = 1 if (/^\s*$/);
1011 } elsif (/^git-svn-id: /) {
1012 # skip this for now, we regenerate the
1013 # correct one on re-fetch anyways
1014 # TODO: set *:merge properties or like...
1015 } else {
1016 print $log_fh $_ or croak $!;
1017 }
1018 }
1019 command_close_pipe($msg_fh, $ctx);
1020 }
1021 close $log_fh or croak $!;
1022
1023 if ($_edit || ($type eq 'tree')) {
1024 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1025 # TODO: strip out spaces, comments, like git-commit.sh
1026 system($editor, $commit_editmsg);
1027 }
1028 rename $commit_editmsg, $commit_msg or croak $!;
1029 open $log_fh, '<', $commit_msg or croak $!;
1030 { local $/; chomp($log_entry{log} = <$log_fh>); }
1031 close $log_fh or croak $!;
1032 unlink $commit_msg;
1033 \%log_entry;
1034 }
1035
1036 sub s_to_file {
1037 my ($str, $file, $mode) = @_;
1038 open my $fd,'>',$file or croak $!;
1039 print $fd $str,"\n" or croak $!;
1040 close $fd or croak $!;
1041 chmod ($mode &~ umask, $file) if (defined $mode);
1042 }
1043
1044 sub file_to_s {
1045 my $file = shift;
1046 open my $fd,'<',$file or croak "$!: file: $file\n";
1047 local $/;
1048 my $ret = <$fd>;
1049 close $fd or croak $!;
1050 $ret =~ s/\s*$//s;
1051 return $ret;
1052 }
1053
1054 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1055 sub load_authors {
1056 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1057 my $log = $cmd eq 'log';
1058 while (<$authors>) {
1059 chomp;
1060 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1061 my ($user, $name, $email) = ($1, $2, $3);
1062 if ($log) {
1063 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1064 } else {
1065 $users{$user} = [$name, $email];
1066 }
1067 }
1068 close $authors or croak $!;
1069 }
1070
1071 # convert GetOpt::Long specs for use by git-config
1072 sub read_repo_config {
1073 return unless -d $ENV{GIT_DIR};
1074 my $opts = shift;
1075 my @config_only;
1076 foreach my $o (keys %$opts) {
1077 # if we have mixedCase and a long option-only, then
1078 # it's a config-only variable that we don't need for
1079 # the command-line.
1080 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1081 my $v = $opts->{$o};
1082 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1083 $key =~ s/-//g;
1084 my $arg = 'git-config';
1085 $arg .= ' --int' if ($o =~ /[:=]i$/);
1086 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1087 if (ref $v eq 'ARRAY') {
1088 chomp(my @tmp = `$arg --get-all svn.$key`);
1089 @$v = @tmp if @tmp;
1090 } else {
1091 chomp(my $tmp = `$arg --get svn.$key`);
1092 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1093 $$v = $tmp;
1094 }
1095 }
1096 }
1097 delete @$opts{@config_only} if @config_only;
1098 }
1099
1100 sub extract_metadata {
1101 my $id = shift or return (undef, undef, undef);
1102 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1103 \s([a-f\d\-]+)$/x);
1104 if (!defined $rev || !$uuid || !$url) {
1105 # some of the original repositories I made had
1106 # identifiers like this:
1107 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1108 }
1109 return ($url, $rev, $uuid);
1110 }
1111
1112 sub cmt_metadata {
1113 return extract_metadata((grep(/^git-svn-id: /,
1114 command(qw/cat-file commit/, shift)))[-1]);
1115 }
1116
1117 sub working_head_info {
1118 my ($head, $refs) = @_;
1119 my @args = ('log', '--no-color', '--first-parent');
1120 my ($fh, $ctx) = command_output_pipe(@args, $head);
1121 my $hash;
1122 my %max;
1123 while (<$fh>) {
1124 if ( m{^commit ($::sha1)$} ) {
1125 unshift @$refs, $hash if $hash and $refs;
1126 $hash = $1;
1127 next;
1128 }
1129 next unless s{^\s*(git-svn-id:)}{$1};
1130 my ($url, $rev, $uuid) = extract_metadata($_);
1131 if (defined $url && defined $rev) {
1132 next if $max{$url} and $max{$url} < $rev;
1133 if (my $gs = Git::SVN->find_by_url($url)) {
1134 my $c = $gs->rev_map_get($rev);
1135 if ($c && $c eq $hash) {
1136 close $fh; # break the pipe
1137 return ($url, $rev, $uuid, $gs);
1138 } else {
1139 $max{$url} ||= $gs->rev_map_max;
1140 }
1141 }
1142 }
1143 }
1144 command_close_pipe($fh, $ctx);
1145 (undef, undef, undef, undef);
1146 }
1147
1148 sub read_commit_parents {
1149 my ($parents, $c) = @_;
1150 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1151 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1152 @{$parents->{$c}} = split(/ /, $p);
1153 }
1154
1155 sub linearize_history {
1156 my ($gs, $refs) = @_;
1157 my %parents;
1158 foreach my $c (@$refs) {
1159 read_commit_parents(\%parents, $c);
1160 }
1161
1162 my @linear_refs;
1163 my %skip = ();
1164 my $last_svn_commit = $gs->last_commit;
1165 foreach my $c (reverse @$refs) {
1166 next if $c eq $last_svn_commit;
1167 last if $skip{$c};
1168
1169 unshift @linear_refs, $c;
1170 $skip{$c} = 1;
1171
1172 # we only want the first parent to diff against for linear
1173 # history, we save the rest to inject when we finalize the
1174 # svn commit
1175 my $fp_a = verify_ref("$c~1");
1176 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1177 if (!$fp_a || !$fp_b) {
1178 die "Commit $c\n",
1179 "has no parent commit, and therefore ",
1180 "nothing to diff against.\n",
1181 "You should be working from a repository ",
1182 "originally created by git-svn\n";
1183 }
1184 if ($fp_a ne $fp_b) {
1185 die "$c~1 = $fp_a, however parsing commit $c ",
1186 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1187 }
1188
1189 foreach my $p (@{$parents{$c}}) {
1190 $skip{$p} = 1;
1191 }
1192 }
1193 (\@linear_refs, \%parents);
1194 }
1195
1196 sub find_file_type_and_diff_status {
1197 my ($path) = @_;
1198 return ('dir', '') if $path eq '.';
1199
1200 my $diff_output =
1201 command_oneline(qw(diff --cached --name-status --), $path) || "";
1202 my $diff_status = (split(' ', $diff_output))[0] || "";
1203
1204 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1205
1206 return (undef, undef) if !$diff_status && !$ls_tree;
1207
1208 if ($diff_status eq "A") {
1209 return ("link", $diff_status) if -l $path;
1210 return ("dir", $diff_status) if -d $path;
1211 return ("file", $diff_status);
1212 }
1213
1214 my $mode = (split(' ', $ls_tree))[0] || "";
1215
1216 return ("link", $diff_status) if $mode eq "120000";
1217 return ("dir", $diff_status) if $mode eq "040000";
1218 return ("file", $diff_status);
1219 }
1220
1221 sub md5sum {
1222 my $arg = shift;
1223 my $ref = ref $arg;
1224 my $md5 = Digest::MD5->new();
1225 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1226 $md5->addfile($arg) or croak $!;
1227 } elsif ($ref eq 'SCALAR') {
1228 $md5->add($$arg) or croak $!;
1229 } elsif (!$ref) {
1230 $md5->add($arg) or croak $!;
1231 } else {
1232 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1233 }
1234 return $md5->hexdigest();
1235 }
1236
1237 package Git::SVN;
1238 use strict;
1239 use warnings;
1240 use Fcntl qw/:DEFAULT :seek/;
1241 use constant rev_map_fmt => 'NH40';
1242 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1243 $_repack $_repack_flags $_use_svm_props $_head
1244 $_use_svnsync_props $no_reuse_existing $_minimize_url
1245 $_use_log_author/;
1246 use Carp qw/croak/;
1247 use File::Path qw/mkpath/;
1248 use File::Copy qw/copy/;
1249 use IPC::Open3;
1250
1251 my $_repack_nr;
1252 # properties that we do not log:
1253 my %SKIP_PROP;
1254 BEGIN {
1255 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1256 svn:special svn:executable
1257 svn:entry:committed-rev
1258 svn:entry:last-author
1259 svn:entry:uuid
1260 svn:entry:committed-date/;
1261
1262 # some options are read globally, but can be overridden locally
1263 # per [svn-remote "..."] section. Command-line options will *NOT*
1264 # override options set in an [svn-remote "..."] section
1265 no strict 'refs';
1266 for my $option (qw/follow_parent no_metadata use_svm_props
1267 use_svnsync_props/) {
1268 my $key = $option;
1269 $key =~ tr/_//d;
1270 my $prop = "-$option";
1271 *$option = sub {
1272 my ($self) = @_;
1273 return $self->{$prop} if exists $self->{$prop};
1274 my $k = "svn-remote.$self->{repo_id}.$key";
1275 eval { command_oneline(qw/config --get/, $k) };
1276 if ($@) {
1277 $self->{$prop} = ${"Git::SVN::_$option"};
1278 } else {
1279 my $v = command_oneline(qw/config --bool/,$k);
1280 $self->{$prop} = $v eq 'false' ? 0 : 1;
1281 }
1282 return $self->{$prop};
1283 }
1284 }
1285 }
1286
1287 my (%LOCKFILES, %INDEX_FILES);
1288 END {
1289 unlink keys %LOCKFILES if %LOCKFILES;
1290 unlink keys %INDEX_FILES if %INDEX_FILES;
1291 }
1292
1293 sub resolve_local_globs {
1294 my ($url, $fetch, $glob_spec) = @_;
1295 return unless defined $glob_spec;
1296 my $ref = $glob_spec->{ref};
1297 my $path = $glob_spec->{path};
1298 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1299 next unless m#^refs/remotes/$ref->{regex}$#;
1300 my $p = $1;
1301 my $pathname = desanitize_refname($path->full_path($p));
1302 my $refname = desanitize_refname($ref->full_path($p));
1303 if (my $existing = $fetch->{$pathname}) {
1304 if ($existing ne $refname) {
1305 die "Refspec conflict:\n",
1306 "existing: refs/remotes/$existing\n",
1307 " globbed: refs/remotes/$refname\n";
1308 }
1309 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1310 $u =~ s!^\Q$url\E(/|$)!! or die
1311 "refs/remotes/$refname: '$url' not found in '$u'\n";
1312 if ($pathname ne $u) {
1313 warn "W: Refspec glob conflict ",
1314 "(ref: refs/remotes/$refname):\n",
1315 "expected path: $pathname\n",
1316 " real path: $u\n",
1317 "Continuing ahead with $u\n";
1318 next;
1319 }
1320 } else {
1321 $fetch->{$pathname} = $refname;
1322 }
1323 }
1324 }
1325
1326 sub parse_revision_argument {
1327 my ($base, $head) = @_;
1328 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1329 return ($base, $head);
1330 }
1331 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1332 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1333 return ($head, $head) if ($::_revision eq 'HEAD');
1334 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1335 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1336 die "revision argument: $::_revision not understood by git-svn\n";
1337 }
1338
1339 sub fetch_all {
1340 my ($repo_id, $remotes) = @_;
1341 if (ref $repo_id) {
1342 my $gs = $repo_id;
1343 $repo_id = undef;
1344 $repo_id = $gs->{repo_id};
1345 }
1346 $remotes ||= read_all_remotes();
1347 my $remote = $remotes->{$repo_id} or
1348 die "[svn-remote \"$repo_id\"] unknown\n";
1349 my $fetch = $remote->{fetch};
1350 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1351 my (@gs, @globs);
1352 my $ra = Git::SVN::Ra->new($url);
1353 my $uuid = $ra->get_uuid;
1354 my $head = $ra->get_latest_revnum;
1355 my $base = defined $fetch ? $head : 0;
1356
1357 # read the max revs for wildcard expansion (branches/*, tags/*)
1358 foreach my $t (qw/branches tags/) {
1359 defined $remote->{$t} or next;
1360 push @globs, $remote->{$t};
1361 my $max_rev = eval { tmp_config(qw/--int --get/,
1362 "svn-remote.$repo_id.${t}-maxRev") };
1363 if (defined $max_rev && ($max_rev < $base)) {
1364 $base = $max_rev;
1365 } elsif (!defined $max_rev) {
1366 $base = 0;
1367 }
1368 }
1369
1370 if ($fetch) {
1371 foreach my $p (sort keys %$fetch) {
1372 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1373 my $lr = $gs->rev_map_max;
1374 if (defined $lr) {
1375 $base = $lr if ($lr < $base);
1376 }
1377 push @gs, $gs;
1378 }
1379 }
1380
1381 ($base, $head) = parse_revision_argument($base, $head);
1382 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1383 }
1384
1385 sub read_all_remotes {
1386 my $r = {};
1387 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1388 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1389 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1390 $local_ref =~ s{^/}{};
1391 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1392 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1393 $r->{$1}->{url} = $2;
1394 } elsif (m!^(.+)\.(branches|tags)=
1395 (.*):refs/remotes/(.+)\s*$/!x) {
1396 my ($p, $g) = ($3, $4);
1397 my $rs = $r->{$1}->{$2} = {
1398 t => $2,
1399 remote => $1,
1400 path => Git::SVN::GlobSpec->new($p),
1401 ref => Git::SVN::GlobSpec->new($g) };
1402 if (length($rs->{ref}->{right}) != 0) {
1403 die "The '*' glob character must be the last ",
1404 "character of '$g'\n";
1405 }
1406 }
1407 }
1408 $r;
1409 }
1410
1411 sub init_vars {
1412 $_repack = 1000 unless (defined $_repack && $_repack > 0);
1413 $_repack_nr = $_repack;
1414 $_repack_flags ||= '-d';
1415 }
1416
1417 sub verify_remotes_sanity {
1418 return unless -d $ENV{GIT_DIR};
1419 my %seen;
1420 foreach (command(qw/config -l/)) {
1421 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1422 if ($seen{$1}) {
1423 die "Remote ref refs/remote/$1 is tracked by",
1424 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1425 "Please resolve this ambiguity in ",
1426 "your git configuration file before ",
1427 "continuing\n";
1428 }
1429 $seen{$1} = $_;
1430 }
1431 }
1432 }
1433
1434 # we allow more chars than remotes2config.sh...
1435 sub sanitize_remote_name {
1436 my ($name) = @_;
1437 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1438 $name;
1439 }
1440
1441 sub find_existing_remote {
1442 my ($url, $remotes) = @_;
1443 return undef if $no_reuse_existing;
1444 my $existing;
1445 foreach my $repo_id (keys %$remotes) {
1446 my $u = $remotes->{$repo_id}->{url} or next;
1447 next if $u ne $url;
1448 $existing = $repo_id;
1449 last;
1450 }
1451 $existing;
1452 }
1453
1454 sub init_remote_config {
1455 my ($self, $url, $no_write) = @_;
1456 $url =~ s!/+$!!; # strip trailing slash
1457 my $r = read_all_remotes();
1458 my $existing = find_existing_remote($url, $r);
1459 if ($existing) {
1460 unless ($no_write) {
1461 print STDERR "Using existing ",
1462 "[svn-remote \"$existing\"]\n";
1463 }
1464 $self->{repo_id} = $existing;
1465 } elsif ($_minimize_url) {
1466 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1467 $existing = find_existing_remote($min_url, $r);
1468 if ($existing) {
1469 unless ($no_write) {
1470 print STDERR "Using existing ",
1471 "[svn-remote \"$existing\"]\n";
1472 }
1473 $self->{repo_id} = $existing;
1474 }
1475 if ($min_url ne $url) {
1476 unless ($no_write) {
1477 print STDERR "Using higher level of URL: ",
1478 "$url => $min_url\n";
1479 }
1480 my $old_path = $self->{path};
1481 $self->{path} = $url;
1482 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1483 if (length $old_path) {
1484 $self->{path} .= "/$old_path";
1485 }
1486 $url = $min_url;
1487 }
1488 }
1489 my $orig_url;
1490 if (!$existing) {
1491 # verify that we aren't overwriting anything:
1492 $orig_url = eval {
1493 command_oneline('config', '--get',
1494 "svn-remote.$self->{repo_id}.url")
1495 };
1496 if ($orig_url && ($orig_url ne $url)) {
1497 die "svn-remote.$self->{repo_id}.url already set: ",
1498 "$orig_url\nwanted to set to: $url\n";
1499 }
1500 }
1501 my ($xrepo_id, $xpath) = find_ref($self->refname);
1502 if (defined $xpath) {
1503 die "svn-remote.$xrepo_id.fetch already set to track ",
1504 "$xpath:refs/remotes/", $self->refname, "\n";
1505 }
1506 unless ($no_write) {
1507 command_noisy('config',
1508 "svn-remote.$self->{repo_id}.url", $url);
1509 $self->{path} =~ s{^/}{};
1510 command_noisy('config', '--add',
1511 "svn-remote.$self->{repo_id}.fetch",
1512 "$self->{path}:".$self->refname);
1513 }
1514 $self->{url} = $url;
1515 }
1516
1517 sub find_by_url { # repos_root and, path are optional
1518 my ($class, $full_url, $repos_root, $path) = @_;
1519
1520 return undef unless defined $full_url;
1521 remove_username($full_url);
1522 remove_username($repos_root) if defined $repos_root;
1523 my $remotes = read_all_remotes();
1524 if (defined $full_url && defined $repos_root && !defined $path) {
1525 $path = $full_url;
1526 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1527 }
1528 foreach my $repo_id (keys %$remotes) {
1529 my $u = $remotes->{$repo_id}->{url} or next;
1530 remove_username($u);
1531 next if defined $repos_root && $repos_root ne $u;
1532
1533 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1534 foreach (qw/branches tags/) {
1535 resolve_local_globs($u, $fetch,
1536 $remotes->{$repo_id}->{$_});
1537 }
1538 my $p = $path;
1539 my $rwr = rewrite_root({repo_id => $repo_id});
1540 unless (defined $p) {
1541 $p = $full_url;
1542 my $z = $u;
1543 if ($rwr) {
1544 $z = $rwr;
1545 }
1546 $p =~ s#^\Q$z\E(?:/|$)## or next;
1547 }
1548 foreach my $f (keys %$fetch) {
1549 next if $f ne $p;
1550 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1551 }
1552 }
1553 undef;
1554 }
1555
1556 sub init {
1557 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1558 my $self = _new($class, $repo_id, $ref_id, $path);
1559 if (defined $url) {
1560 $self->init_remote_config($url, $no_write);
1561 }
1562 $self;
1563 }
1564
1565 sub find_ref {
1566 my ($ref_id) = @_;
1567 foreach (command(qw/config -l/)) {
1568 next unless m!^svn-remote\.(.+)\.fetch=
1569 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1570 my ($repo_id, $path, $ref) = ($1, $2, $3);
1571 if ($ref eq $ref_id) {
1572 $path = '' if ($path =~ m#^\./?#);
1573 return ($repo_id, $path);
1574 }
1575 }
1576 (undef, undef, undef);
1577 }
1578
1579 sub new {
1580 my ($class, $ref_id, $repo_id, $path) = @_;
1581 if (defined $ref_id && !defined $repo_id && !defined $path) {
1582 ($repo_id, $path) = find_ref($ref_id);
1583 if (!defined $repo_id) {
1584 die "Could not find a \"svn-remote.*.fetch\" key ",
1585 "in the repository configuration matching: ",
1586 "refs/remotes/$ref_id\n";
1587 }
1588 }
1589 my $self = _new($class, $repo_id, $ref_id, $path);
1590 if (!defined $self->{path} || !length $self->{path}) {
1591 my $fetch = command_oneline('config', '--get',
1592 "svn-remote.$repo_id.fetch",
1593 ":refs/remotes/$ref_id\$") or
1594 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1595 "\":refs/remotes/$ref_id\$\" in config\n";
1596 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1597 }
1598 $self->{url} = command_oneline('config', '--get',
1599 "svn-remote.$repo_id.url") or
1600 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1601 $self->rebuild;
1602 $self;
1603 }
1604
1605 sub refname {
1606 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1607
1608 # It cannot end with a slash /, we'll throw up on this because
1609 # SVN can't have directories with a slash in their name, either:
1610 if ($refname =~ m{/$}) {
1611 die "ref: '$refname' ends with a trailing slash, this is ",
1612 "not permitted by git nor Subversion\n";
1613 }
1614
1615 # It cannot have ASCII control character space, tilde ~, caret ^,
1616 # colon :, question-mark ?, asterisk *, space, or open bracket [
1617 # anywhere.
1618 #
1619 # Additionally, % must be escaped because it is used for escaping
1620 # and we want our escaped refname to be reversible
1621 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1622
1623 # no slash-separated component can begin with a dot .
1624 # /.* becomes /%2E*
1625 $refname =~ s{/\.}{/%2E}g;
1626
1627 # It cannot have two consecutive dots .. anywhere
1628 # .. becomes %2E%2E
1629 $refname =~ s{\.\.}{%2E%2E}g;
1630
1631 return $refname;
1632 }
1633
1634 sub desanitize_refname {
1635 my ($refname) = @_;
1636 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1637 return $refname;
1638 }
1639
1640 sub svm_uuid {
1641 my ($self) = @_;
1642 return $self->{svm}->{uuid} if $self->svm;
1643 $self->ra;
1644 unless ($self->{svm}) {
1645 die "SVM UUID not cached, and reading remotely failed\n";
1646 }
1647 $self->{svm}->{uuid};
1648 }
1649
1650 sub svm {
1651 my ($self) = @_;
1652 return $self->{svm} if $self->{svm};
1653 my $svm;
1654 # see if we have it in our config, first:
1655 eval {
1656 my $section = "svn-remote.$self->{repo_id}";
1657 $svm = {
1658 source => tmp_config('--get', "$section.svm-source"),
1659 uuid => tmp_config('--get', "$section.svm-uuid"),
1660 replace => tmp_config('--get', "$section.svm-replace"),
1661 }
1662 };
1663 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1664 $self->{svm} = $svm;
1665 }
1666 $self->{svm};
1667 }
1668
1669 sub _set_svm_vars {
1670 my ($self, $ra) = @_;
1671 return $ra if $self->svm;
1672
1673 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1674 "(svm:source, svm:uuid) ",
1675 "from the following URLs:\n" );
1676 sub read_svm_props {
1677 my ($self, $ra, $path, $r) = @_;
1678 my $props = ($ra->get_dir($path, $r))[2];
1679 my $src = $props->{'svm:source'};
1680 my $uuid = $props->{'svm:uuid'};
1681 return undef if (!$src || !$uuid);
1682
1683 chomp($src, $uuid);
1684
1685 $uuid =~ m{^[0-9a-f\-]{30,}$}
1686 or die "doesn't look right - svm:uuid is '$uuid'\n";
1687
1688 # the '!' is used to mark the repos_root!/relative/path
1689 $src =~ s{/?!/?}{/};
1690 $src =~ s{/+$}{}; # no trailing slashes please
1691 # username is of no interest
1692 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1693
1694 my $replace = $ra->{url};
1695 $replace .= "/$path" if length $path;
1696
1697 my $section = "svn-remote.$self->{repo_id}";
1698 tmp_config("$section.svm-source", $src);
1699 tmp_config("$section.svm-replace", $replace);
1700 tmp_config("$section.svm-uuid", $uuid);
1701 $self->{svm} = {
1702 source => $src,
1703 uuid => $uuid,
1704 replace => $replace
1705 };
1706 }
1707
1708 my $r = $ra->get_latest_revnum;
1709 my $path = $self->{path};
1710 my %tried;
1711 while (length $path) {
1712 unless ($tried{"$self->{url}/$path"}) {
1713 return $ra if $self->read_svm_props($ra, $path, $r);
1714 $tried{"$self->{url}/$path"} = 1;
1715 }
1716 $path =~ s#/?[^/]+$##;
1717 }
1718 die "Path: '$path' should be ''\n" if $path ne '';
1719 return $ra if $self->read_svm_props($ra, $path, $r);
1720 $tried{"$self->{url}/$path"} = 1;
1721
1722 if ($ra->{repos_root} eq $self->{url}) {
1723 die @err, (map { " $_\n" } keys %tried), "\n";
1724 }
1725
1726 # nope, make sure we're connected to the repository root:
1727 my $ok;
1728 my @tried_b;
1729 $path = $ra->{svn_path};
1730 $ra = Git::SVN::Ra->new($ra->{repos_root});
1731 while (length $path) {
1732 unless ($tried{"$ra->{url}/$path"}) {
1733 $ok = $self->read_svm_props($ra, $path, $r);
1734 last if $ok;
1735 $tried{"$ra->{url}/$path"} = 1;
1736 }
1737 $path =~ s#/?[^/]+$##;
1738 }
1739 die "Path: '$path' should be ''\n" if $path ne '';
1740 $ok ||= $self->read_svm_props($ra, $path, $r);
1741 $tried{"$ra->{url}/$path"} = 1;
1742 if (!$ok) {
1743 die @err, (map { " $_\n" } keys %tried), "\n";
1744 }
1745 Git::SVN::Ra->new($self->{url});
1746 }
1747
1748 sub svnsync {
1749 my ($self) = @_;
1750 return $self->{svnsync} if $self->{svnsync};
1751
1752 if ($self->no_metadata) {
1753 die "Can't have both 'noMetadata' and ",
1754 "'useSvnsyncProps' options set!\n";
1755 }
1756 if ($self->rewrite_root) {
1757 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1758 "options set!\n";
1759 }
1760
1761 my $svnsync;
1762 # see if we have it in our config, first:
1763 eval {
1764 my $section = "svn-remote.$self->{repo_id}";
1765
1766 my $url = tmp_config('--get', "$section.svnsync-url");
1767 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1768 die "doesn't look right - svn:sync-from-url is '$url'\n";
1769
1770 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1771 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1772 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1773
1774 $svnsync = { url => $url, uuid => $uuid }
1775 };
1776 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1777 return $self->{svnsync} = $svnsync;
1778 }
1779
1780 my $err = "useSvnsyncProps set, but failed to read " .
1781 "svnsync property: svn:sync-from-";
1782 my $rp = $self->ra->rev_proplist(0);
1783
1784 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1785 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1786 die "doesn't look right - svn:sync-from-url is '$url'\n";
1787
1788 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1789 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1790 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1791
1792 my $section = "svn-remote.$self->{repo_id}";
1793 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1794 tmp_config('--add', "$section.svnsync-url", $url);
1795 return $self->{svnsync} = { url => $url, uuid => $uuid };
1796 }
1797
1798 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1799 # remote lookup (useful for 'git svn log').
1800 sub ra_uuid {
1801 my ($self) = @_;
1802 unless ($self->{ra_uuid}) {
1803 my $key = "svn-remote.$self->{repo_id}.uuid";
1804 my $uuid = eval { tmp_config('--get', $key) };
1805 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1806 $self->{ra_uuid} = $uuid;
1807 } else {
1808 die "ra_uuid called without URL\n" unless $self->{url};
1809 $self->{ra_uuid} = $self->ra->get_uuid;
1810 tmp_config('--add', $key, $self->{ra_uuid});
1811 }
1812 }
1813 $self->{ra_uuid};
1814 }
1815
1816 sub _set_repos_root {
1817 my ($self, $repos_root) = @_;
1818 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1819 $repos_root ||= $self->ra->{repos_root};
1820 tmp_config($k, $repos_root);
1821 $repos_root;
1822 }
1823
1824 sub repos_root {
1825 my ($self) = @_;
1826 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1827 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1828 }
1829
1830 sub ra {
1831 my ($self) = shift;
1832 my $ra = Git::SVN::Ra->new($self->{url});
1833 $self->_set_repos_root($ra->{repos_root});
1834 if ($self->use_svm_props && !$self->{svm}) {
1835 if ($self->no_metadata) {
1836 die "Can't have both 'noMetadata' and ",
1837 "'useSvmProps' options set!\n";
1838 } elsif ($self->use_svnsync_props) {
1839 die "Can't have both 'useSvnsyncProps' and ",
1840 "'useSvmProps' options set!\n";
1841 }
1842 $ra = $self->_set_svm_vars($ra);
1843 $self->{-want_revprops} = 1;
1844 }
1845 $ra;
1846 }
1847
1848 sub rel_path {
1849 my ($self) = @_;
1850 my $repos_root = $self->ra->{repos_root};
1851 return $self->{path} if ($self->{url} eq $repos_root);
1852 my $url = $self->{url} .
1853 (length $self->{path} ? "/$self->{path}" : $self->{path});
1854 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1855 $url;
1856 }
1857
1858 # prop_walk(PATH, REV, SUB)
1859 # -------------------------
1860 # Recursively traverse PATH at revision REV and invoke SUB for each
1861 # directory that contains a SVN property. SUB will be invoked as
1862 # follows: &SUB(gs, path, props); where `gs' is this instance of
1863 # Git::SVN, `path' the path to the directory where the properties
1864 # `props' were found. The `path' will be relative to point of checkout,
1865 # that is, if url://repo/trunk is the current Git branch, and that
1866 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1867 # as `path' (note the trailing `/').
1868 sub prop_walk {
1869 my ($self, $path, $rev, $sub) = @_;
1870
1871 $path =~ s#^/##;
1872 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1873 $path =~ s#^/*#/#g;
1874 my $p = $path;
1875 # Strip the irrelevant part of the path.
1876 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1877 # Ensure the path is terminated by a `/'.
1878 $p =~ s#/*$#/#;
1879
1880 # The properties contain all the internal SVN stuff nobody
1881 # (usually) cares about.
1882 my $interesting_props = 0;
1883 foreach (keys %{$props}) {
1884 # If it doesn't start with `svn:', it must be a
1885 # user-defined property.
1886 ++$interesting_props and next if $_ !~ /^svn:/;
1887 # FIXME: Fragile, if SVN adds new public properties,
1888 # this needs to be updated.
1889 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1890 |eol-style|mime-type
1891 |externals|needs-lock)$/x;
1892 }
1893 &$sub($self, $p, $props) if $interesting_props;
1894
1895 foreach (sort keys %$dirent) {
1896 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1897 $self->prop_walk($path . '/' . $_, $rev, $sub);
1898 }
1899 }
1900
1901 sub last_rev { ($_[0]->last_rev_commit)[0] }
1902 sub last_commit { ($_[0]->last_rev_commit)[1] }
1903
1904 # returns the newest SVN revision number and newest commit SHA1
1905 sub last_rev_commit {
1906 my ($self) = @_;
1907 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1908 return ($self->{last_rev}, $self->{last_commit});
1909 }
1910 my $c = ::verify_ref($self->refname.'^0');
1911 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1912 my $rev = (::cmt_metadata($c))[1];
1913 if (defined $rev) {
1914 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1915 return ($rev, $c);
1916 }
1917 }
1918 my $map_path = $self->map_path;
1919 unless (-e $map_path) {
1920 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1921 return (undef, undef);
1922 }
1923 my ($rev, $commit) = $self->rev_map_max(1);
1924 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1925 return ($rev, $commit);
1926 }
1927
1928 sub get_fetch_range {
1929 my ($self, $min, $max) = @_;
1930 $max ||= $self->ra->get_latest_revnum;
1931 $min ||= $self->rev_map_max;
1932 (++$min, $max);
1933 }
1934
1935 sub tmp_config {
1936 my (@args) = @_;
1937 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1938 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1939 if (! -f $config && -f $old_def_config) {
1940 rename $old_def_config, $config or
1941 die "Failed rename $old_def_config => $config: $!\n";
1942 }
1943 my $old_config = $ENV{GIT_CONFIG};
1944 $ENV{GIT_CONFIG} = $config;
1945 $@ = undef;
1946 my @ret = eval {
1947 unless (-f $config) {
1948 mkfile($config);
1949 open my $fh, '>', $config or
1950 die "Can't open $config: $!\n";
1951 print $fh "; This file is used internally by ",
1952 "git-svn\n" or die
1953 "Couldn't write to $config: $!\n";
1954 print $fh "; You should not have to edit it\n" or
1955 die "Couldn't write to $config: $!\n";
1956 close $fh or die "Couldn't close $config: $!\n";
1957 }
1958 command('config', @args);
1959 };
1960 my $err = $@;
1961 if (defined $old_config) {
1962 $ENV{GIT_CONFIG} = $old_config;
1963 } else {
1964 delete $ENV{GIT_CONFIG};
1965 }
1966 die $err if $err;
1967 wantarray ? @ret : $ret[0];
1968 }
1969
1970 sub tmp_index_do {
1971 my ($self, $sub) = @_;
1972 my $old_index = $ENV{GIT_INDEX_FILE};
1973 $ENV{GIT_INDEX_FILE} = $self->{index};
1974 $@ = undef;
1975 my @ret = eval {
1976 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1977 mkpath([$dir]) unless -d $dir;
1978 &$sub;
1979 };
1980 my $err = $@;
1981 if (defined $old_index) {
1982 $ENV{GIT_INDEX_FILE} = $old_index;
1983 } else {
1984 delete $ENV{GIT_INDEX_FILE};
1985 }
1986 die $err if $err;
1987 wantarray ? @ret : $ret[0];
1988 }
1989
1990 sub assert_index_clean {
1991 my ($self, $treeish) = @_;
1992
1993 $self->tmp_index_do(sub {
1994 command_noisy('read-tree', $treeish) unless -e $self->{index};
1995 my $x = command_oneline('write-tree');
1996 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1997 /^tree ($::sha1)/mo);
1998 return if $y eq $x;
1999
2000 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2001 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2002 command_noisy('read-tree', $treeish);
2003 $x = command_oneline('write-tree');
2004 if ($y ne $x) {
2005 ::fatal "trees ($treeish) $y != $x\n",
2006 "Something is seriously wrong...";
2007 }
2008 });
2009 }
2010
2011 sub get_commit_parents {
2012 my ($self, $log_entry) = @_;
2013 my (%seen, @ret, @tmp);
2014 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2015 if (my $ip = $self->{inject_parents}) {
2016 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2017 push @tmp, $commit;
2018 }
2019 }
2020 if (my $cur = ::verify_ref($self->refname.'^0')) {
2021 push @tmp, $cur;
2022 }
2023 if (my $ipd = $self->{inject_parents_dcommit}) {
2024 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2025 push @tmp, @$commit;
2026 }
2027 }
2028 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2029 while (my $p = shift @tmp) {
2030 next if $seen{$p};
2031 $seen{$p} = 1;
2032 push @ret, $p;
2033 # MAXPARENT is defined to 16 in commit-tree.c:
2034 last if @ret >= 16;
2035 }
2036 if (@tmp) {
2037 die "r$log_entry->{revision}: No room for parents:\n\t",
2038 join("\n\t", @tmp), "\n";
2039 }
2040 @ret;
2041 }
2042
2043 sub rewrite_root {
2044 my ($self) = @_;
2045 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2046 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2047 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2048 if ($rwr) {
2049 $rwr =~ s#/+$##;
2050 if ($rwr !~ m#^[a-z\+]+://#) {
2051 die "$rwr is not a valid URL (key: $k)\n";
2052 }
2053 }
2054 $self->{-rewrite_root} = $rwr;
2055 }
2056
2057 sub metadata_url {
2058 my ($self) = @_;
2059 ($self->rewrite_root || $self->{url}) .
2060 (length $self->{path} ? '/' . $self->{path} : '');
2061 }
2062
2063 sub full_url {
2064 my ($self) = @_;
2065 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2066 }
2067
2068
2069 sub set_commit_header_env {
2070 my ($log_entry) = @_;
2071 my %env;
2072 foreach my $ned (qw/NAME EMAIL DATE/) {
2073 foreach my $ac (qw/AUTHOR COMMITTER/) {
2074 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2075 }
2076 }
2077
2078 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2079 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2080 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2081
2082 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2083 ? $log_entry->{commit_name}
2084 : $log_entry->{name};
2085 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2086 ? $log_entry->{commit_email}
2087 : $log_entry->{email};
2088 \%env;
2089 }
2090
2091 sub restore_commit_header_env {
2092 my ($env) = @_;
2093 foreach my $ned (qw/NAME EMAIL DATE/) {
2094 foreach my $ac (qw/AUTHOR COMMITTER/) {
2095 my $k = "GIT_${ac}_${ned}";
2096 if (defined $env->{$k}) {
2097 $ENV{$k} = $env->{$k};
2098 } else {
2099 delete $ENV{$k};
2100 }
2101 }
2102 }
2103 }
2104
2105 sub do_git_commit {
2106 my ($self, $log_entry) = @_;
2107 my $lr = $self->last_rev;
2108 if (defined $lr && $lr >= $log_entry->{revision}) {
2109 die "Last fetched revision of ", $self->refname,
2110 " was r$lr, but we are about to fetch: ",
2111 "r$log_entry->{revision}!\n";
2112 }
2113 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2114 croak "$log_entry->{revision} = $c already exists! ",
2115 "Why are we refetching it?\n";
2116 }
2117 my $old_env = set_commit_header_env($log_entry);
2118 my $tree = $log_entry->{tree};
2119 if (!defined $tree) {
2120 $tree = $self->tmp_index_do(sub {
2121 command_oneline('write-tree') });
2122 }
2123 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2124
2125 my @exec = ('git-commit-tree', $tree);
2126 foreach ($self->get_commit_parents($log_entry)) {
2127 push @exec, '-p', $_;
2128 }
2129 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2130 or croak $!;
2131 print $msg_fh $log_entry->{log} or croak $!;
2132 restore_commit_header_env($old_env);
2133 unless ($self->no_metadata) {
2134 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2135 or croak $!;
2136 }
2137 $msg_fh->flush == 0 or croak $!;
2138 close $msg_fh or croak $!;
2139 chomp(my $commit = do { local $/; <$out_fh> });
2140 close $out_fh or croak $!;
2141 waitpid $pid, 0;
2142 croak $? if $?;
2143 if ($commit !~ /^$::sha1$/o) {
2144 die "Failed to commit, invalid sha1: $commit\n";
2145 }
2146
2147 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2148
2149 $self->{last_rev} = $log_entry->{revision};
2150 $self->{last_commit} = $commit;
2151 print "r$log_entry->{revision}";
2152 if (defined $log_entry->{svm_revision}) {
2153 print " (\@$log_entry->{svm_revision})";
2154 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2155 0, $self->svm_uuid);
2156 }
2157 print " = $commit ($self->{ref_id})\n";
2158 if ($_repack && (--$_repack_nr == 0)) {
2159 $_repack_nr = $_repack;
2160 # repack doesn't use any arguments with spaces in them, does it?
2161 print "Running git repack $_repack_flags ...\n";
2162 command_noisy('repack', split(/\s+/, $_repack_flags));
2163 print "Done repacking\n";
2164 }
2165 return $commit;
2166 }
2167
2168 sub match_paths {
2169 my ($self, $paths, $r) = @_;
2170 return 1 if $self->{path} eq '';
2171 if (my $path = $paths->{"/$self->{path}"}) {
2172 return ($path->{action} eq 'D') ? 0 : 1;
2173 }
2174 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2175 if (grep /$self->{path_regex}/, keys %$paths) {
2176 return 1;
2177 }
2178 my $c = '';
2179 foreach (split m#/#, $self->{path}) {
2180 $c .= "/$_";
2181 next unless ($paths->{$c} &&
2182 ($paths->{$c}->{action} =~ /^[AR]$/));
2183 if ($self->ra->check_path($self->{path}, $r) ==
2184 $SVN::Node::dir) {
2185 return 1;
2186 }
2187 }
2188 return 0;
2189 }
2190
2191 sub find_parent_branch {
2192 my ($self, $paths, $rev) = @_;
2193 return undef unless $self->follow_parent;
2194 unless (defined $paths) {
2195 my $err_handler = $SVN::Error::handler;
2196 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2197 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2198 $paths =
2199 Git::SVN::Ra::dup_changed_paths($_[0]) });
2200 $SVN::Error::handler = $err_handler;
2201 }
2202 return undef unless defined $paths;
2203
2204 # look for a parent from another branch:
2205 my @b_path_components = split m#/#, $self->rel_path;
2206 my @a_path_components;
2207 my $i;
2208 while (@b_path_components) {
2209 $i = $paths->{'/'.join('/', @b_path_components)};
2210 last if $i && defined $i->{copyfrom_path};
2211 unshift(@a_path_components, pop(@b_path_components));
2212 }
2213 return undef unless defined $i && defined $i->{copyfrom_path};
2214 my $branch_from = $i->{copyfrom_path};
2215 if (@a_path_components) {
2216 print STDERR "branch_from: $branch_from => ";
2217 $branch_from .= '/'.join('/', @a_path_components);
2218 print STDERR $branch_from, "\n";
2219 }
2220 my $r = $i->{copyfrom_rev};
2221 my $repos_root = $self->ra->{repos_root};
2222 my $url = $self->ra->{url};
2223 my $new_url = $repos_root . $branch_from;
2224 print STDERR "Found possible branch point: ",
2225 "$new_url => ", $self->full_url, ", $r\n";
2226 $branch_from =~ s#^/##;
2227 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2228 unless ($gs) {
2229 my $ref_id = $self->{ref_id};
2230 $ref_id =~ s/\@\d+$//;
2231 $ref_id .= "\@$r";
2232 # just grow a tail if we're not unique enough :x
2233 $ref_id .= '-' while find_ref($ref_id);
2234 print STDERR "Initializing parent: $ref_id\n";
2235 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2236 }
2237 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2238 if (!defined $r0 || !defined $parent) {
2239 my ($base, $head) = parse_revision_argument(0, $r);
2240 if ($base <= $r) {
2241 $gs->fetch($base, $r);
2242 }
2243 ($r0, $parent) = $gs->last_rev_commit;
2244 }
2245 if (defined $r0 && defined $parent) {
2246 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2247 my $ed;
2248 if ($self->ra->can_do_switch) {
2249 $self->assert_index_clean($parent);
2250 print STDERR "Following parent with do_switch\n";
2251 # do_switch works with svn/trunk >= r22312, but that
2252 # is not included with SVN 1.4.3 (the latest version
2253 # at the moment), so we can't rely on it
2254 $self->{last_commit} = $parent;
2255 $ed = SVN::Git::Fetcher->new($self);
2256 $gs->ra->gs_do_switch($r0, $rev, $gs,
2257 $self->full_url, $ed)
2258 or die "SVN connection failed somewhere...\n";
2259 } elsif ($self->ra->trees_match($new_url, $r0,
2260 $self->full_url, $rev)) {
2261 print STDERR "Trees match:\n",
2262 " $new_url\@$r0\n",
2263 " ${\$self->full_url}\@$rev\n",
2264 "Following parent with no changes\n";
2265 $self->tmp_index_do(sub {
2266 command_noisy('read-tree', $parent);
2267 });
2268 $self->{last_commit} = $parent;
2269 } else {
2270 print STDERR "Following parent with do_update\n";
2271 $ed = SVN::Git::Fetcher->new($self);
2272 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2273 or die "SVN connection failed somewhere...\n";
2274 }
2275 print STDERR "Successfully followed parent\n";
2276 return $self->make_log_entry($rev, [$parent], $ed);
2277 }
2278 return undef;
2279 }
2280
2281 sub do_fetch {
2282 my ($self, $paths, $rev) = @_;
2283 my $ed;
2284 my ($last_rev, @parents);
2285 if (my $lc = $self->last_commit) {
2286 # we can have a branch that was deleted, then re-added
2287 # under the same name but copied from another path, in
2288 # which case we'll have multiple parents (we don't
2289 # want to break the original ref, nor lose copypath info):
2290 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2291 push @{$log_entry->{parents}}, $lc;
2292 return $log_entry;
2293 }
2294 $ed = SVN::Git::Fetcher->new($self);
2295 $last_rev = $self->{last_rev};
2296 $ed->{c} = $lc;
2297 @parents = ($lc);
2298 } else {
2299 $last_rev = $rev;
2300 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2301 return $log_entry;
2302 }
2303 $ed = SVN::Git::Fetcher->new($self);
2304 }
2305 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2306 die "SVN connection failed somewhere...\n";
2307 }
2308 $self->make_log_entry($rev, \@parents, $ed);
2309 }
2310
2311 sub get_untracked {
2312 my ($self, $ed) = @_;
2313 my @out;
2314 my $h = $ed->{empty};
2315 foreach (sort keys %$h) {
2316 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2317 push @out, " $act: " . uri_encode($_);
2318 warn "W: $act: $_\n";
2319 }
2320 foreach my $t (qw/dir_prop file_prop/) {
2321 $h = $ed->{$t} or next;
2322 foreach my $path (sort keys %$h) {
2323 my $ppath = $path eq '' ? '.' : $path;
2324 foreach my $prop (sort keys %{$h->{$path}}) {
2325 next if $SKIP_PROP{$prop};
2326 my $v = $h->{$path}->{$prop};
2327 my $t_ppath_prop = "$t: " .
2328 uri_encode($ppath) . ' ' .
2329 uri_encode($prop);
2330 if (defined $v) {
2331 push @out, " +$t_ppath_prop " .
2332 uri_encode($v);
2333 } else {
2334 push @out, " -$t_ppath_prop";
2335 }
2336 }
2337 }
2338 }
2339 foreach my $t (qw/absent_file absent_directory/) {
2340 $h = $ed->{$t} or next;
2341 foreach my $parent (sort keys %$h) {
2342 foreach my $path (sort @{$h->{$parent}}) {
2343 push @out, " $t: " .
2344 uri_encode("$parent/$path");
2345 warn "W: $t: $parent/$path ",
2346 "Insufficient permissions?\n";
2347 }
2348 }
2349 }
2350 \@out;
2351 }
2352
2353 sub parse_svn_date {
2354 my $date = shift || return '+0000 1970-01-01 00:00:00';
2355 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2356 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2357 croak "Unable to parse date: $date\n";
2358 "+0000 $Y-$m-$d $H:$M:$S";
2359 }
2360
2361 sub check_author {
2362 my ($author) = @_;
2363 if (!defined $author || length $author == 0) {
2364 $author = '(no author)';
2365 }
2366 if (defined $::_authors && ! defined $::users{$author}) {
2367 die "Author: $author not defined in $::_authors file\n";
2368 }
2369 $author;
2370 }
2371
2372 sub make_log_entry {
2373 my ($self, $rev, $parents, $ed) = @_;
2374 my $untracked = $self->get_untracked($ed);
2375
2376 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2377 print $un "r$rev\n" or croak $!;
2378 print $un $_, "\n" foreach @$untracked;
2379 my %log_entry = ( parents => $parents || [], revision => $rev,
2380 log => '');
2381
2382 my $headrev;
2383 my $logged = delete $self->{logged_rev_props};
2384 if (!$logged || $self->{-want_revprops}) {
2385 my $rp = $self->ra->rev_proplist($rev);
2386 foreach (sort keys %$rp) {
2387 my $v = $rp->{$_};
2388 if (/^svn:(author|date|log)$/) {
2389 $log_entry{$1} = $v;
2390 } elsif ($_ eq 'svm:headrev') {
2391 $headrev = $v;
2392 } else {
2393 print $un " rev_prop: ", uri_encode($_), ' ',
2394 uri_encode($v), "\n";
2395 }
2396 }
2397 } else {
2398 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2399 }
2400 close $un or croak $!;
2401
2402 $log_entry{date} = parse_svn_date($log_entry{date});
2403 $log_entry{log} .= "\n";
2404 my $author = $log_entry{author} = check_author($log_entry{author});
2405 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2406 : ($author, undef);
2407
2408 my ($commit_name, $commit_email) = ($name, $email);
2409 if ($_use_log_author) {
2410 my $name_field;
2411 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2412 $name_field = $1;
2413 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2414 $name_field = $1;
2415 }
2416 if (!defined $name_field) {
2417 #
2418 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2419 ($name, $email) = ($1, $2);
2420 } elsif ($name_field =~ /(.*)@/) {
2421 ($name, $email) = ($1, $name_field);
2422 } else {
2423 ($name, $email) = ($name_field, 'unknown');
2424 }
2425 }
2426 if (defined $headrev && $self->use_svm_props) {
2427 if ($self->rewrite_root) {
2428 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2429 "options set!\n";
2430 }
2431 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2432 # we don't want "SVM: initializing mirror for junk" ...
2433 return undef if $r == 0;
2434 my $svm = $self->svm;
2435 if ($uuid ne $svm->{uuid}) {
2436 die "UUID mismatch on SVM path:\n",
2437 "expected: $svm->{uuid}\n",
2438 " got: $uuid\n";
2439 }
2440 my $full_url = $self->full_url;
2441 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2442 die "Failed to replace '$svm->{replace}' with ",
2443 "'$svm->{source}' in $full_url\n";
2444 # throw away username for storing in records
2445 remove_username($full_url);
2446 $log_entry{metadata} = "$full_url\@$r $uuid";
2447 $log_entry{svm_revision} = $r;
2448 $email ||= "$author\@$uuid";
2449 $commit_email ||= "$author\@$uuid";
2450 } elsif ($self->use_svnsync_props) {
2451 my $full_url = $self->svnsync->{url};
2452 $full_url .= "/$self->{path}" if length $self->{path};
2453 remove_username($full_url);
2454 my $uuid = $self->svnsync->{uuid};
2455 $log_entry{metadata} = "$full_url\@$rev $uuid";
2456 $email ||= "$author\@$uuid";
2457 $commit_email ||= "$author\@$uuid";
2458 } else {
2459 my $url = $self->metadata_url;
2460 remove_username($url);
2461 $log_entry{metadata} = "$url\@$rev " .
2462 $self->ra->get_uuid;
2463 $email ||= "$author\@" . $self->ra->get_uuid;
2464 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2465 }
2466 $log_entry{name} = $name;
2467 $log_entry{email} = $email;
2468 $log_entry{commit_name} = $commit_name;
2469 $log_entry{commit_email} = $commit_email;
2470 \%log_entry;
2471 }
2472
2473 sub fetch {
2474 my ($self, $min_rev, $max_rev, @parents) = @_;
2475 my ($last_rev, $last_commit) = $self->last_rev_commit;
2476 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2477 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2478 }
2479
2480 sub set_tree_cb {
2481 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2482 $self->{inject_parents} = { $rev => $tree };
2483 $self->fetch(undef, undef);
2484 }
2485
2486 sub set_tree {
2487 my ($self, $tree) = (shift, shift);
2488 my $log_entry = ::get_commit_entry($tree);
2489 unless ($self->{last_rev}) {
2490 fatal("Must have an existing revision to commit");
2491 }
2492 my %ed_opts = ( r => $self->{last_rev},
2493 log => $log_entry->{log},
2494 ra => $self->ra,
2495 tree_a => $self->{last_commit},
2496 tree_b => $tree,
2497 editor_cb => sub {
2498 $self->set_tree_cb($log_entry, $tree, @_) },
2499 svn_path => $self->{path} );
2500 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2501 print "No changes\nr$self->{last_rev} = $tree\n";
2502 }
2503 }
2504
2505 sub rebuild_from_rev_db {
2506 my ($self, $path) = @_;
2507 my $r = -1;
2508 open my $fh, '<', $path or croak "open: $!";
2509 while (<$fh>) {
2510 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2511 chomp($_);
2512 ++$r;
2513 next if $_ eq ('0' x 40);
2514 $self->rev_map_set($r, $_);
2515 print "r$r = $_\n";
2516 }
2517 close $fh or croak "close: $!";
2518 unlink $path or croak "unlink: $!";
2519 }
2520
2521 sub rebuild {
2522 my ($self) = @_;
2523 my $map_path = $self->map_path;
2524 return if (-e $map_path && ! -z $map_path);
2525 return unless ::verify_ref($self->refname.'^0');
2526 if ($self->use_svm_props || $self->no_metadata) {
2527 my $rev_db = $self->rev_db_path;
2528 $self->rebuild_from_rev_db($rev_db);
2529 if ($self->use_svm_props) {
2530 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2531 $self->rebuild_from_rev_db($svm_rev_db);
2532 }
2533 $self->unlink_rev_db_symlink;
2534 return;
2535 }
2536 print "Rebuilding $map_path ...\n";
2537 my ($log, $ctx) =
2538 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2539 $self->refname, '--');
2540 my $full_url = $self->full_url;
2541 remove_username($full_url);
2542 my $svn_uuid = $self->ra_uuid;
2543 my $c;
2544 while (<$log>) {
2545 if ( m{^commit ($::sha1)$} ) {
2546 $c = $1;
2547 next;
2548 }
2549 next unless s{^\s*(git-svn-id:)}{$1};
2550 my ($url, $rev, $uuid) = ::extract_metadata($_);
2551 remove_username($url);
2552
2553 # ignore merges (from set-tree)
2554 next if (!defined $rev || !$uuid);
2555
2556 # if we merged or otherwise started elsewhere, this is
2557 # how we break out of it
2558 if (($uuid ne $svn_uuid) ||
2559 ($full_url && $url && ($url ne $full_url))) {
2560 next;
2561 }
2562
2563 $self->rev_map_set($rev, $c);
2564 print "r$rev = $c\n";
2565 }
2566 command_close_pipe($log, $ctx);
2567 print "Done rebuilding $map_path\n";
2568 my $rev_db_path = $self->rev_db_path;
2569 if (-f $self->rev_db_path) {
2570 unlink $self->rev_db_path or croak "unlink: $!";
2571 }
2572 $self->unlink_rev_db_symlink;
2573 }
2574
2575 # rev_map:
2576 # Tie::File seems to be prone to offset errors if revisions get sparse,
2577 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2578 # one of my favorite modules is out :< Next up would be one of the DBM
2579 # modules, but I'm not sure which is most portable...
2580 #
2581 # This is the replacement for the rev_db format, which was too big
2582 # and inefficient for large repositories with a lot of sparse history
2583 # (mainly tags)
2584 #
2585 # The format is this:
2586 # - 24 bytes for every record,
2587 # * 4 bytes for the integer representing an SVN revision number
2588 # * 20 bytes representing the sha1 of a git commit
2589 # - No empty padding records like the old format
2590 # (except the last record, which can be overwritten)
2591 # - new records are written append-only since SVN revision numbers
2592 # increase monotonically
2593 # - lookups on SVN revision number are done via a binary search
2594 # - Piping the file to xxd -c24 is a good way of dumping it for
2595 # viewing or editing (piped back through xxd -r), should the need
2596 # ever arise.
2597 # - The last record can be padding revision with an all-zero sha1
2598 # This is used to optimize fetch performance when using multiple
2599 # "fetch" directives in .git/config
2600 #
2601 # These files are disposable unless noMetadata or useSvmProps is set
2602
2603 sub _rev_map_set {
2604 my ($fh, $rev, $commit) = @_;
2605
2606 my $size = (stat($fh))[7];
2607 ($size % 24) == 0 or croak "inconsistent size: $size";
2608
2609 my $wr_offset = 0;
2610 if ($size > 0) {
2611 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2612 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2613 $read == 24 or croak "read only $read bytes (!= 24)";
2614 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2615 if ($last_commit eq ('0' x40)) {
2616 if ($size >= 48) {
2617 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2618 $read = sysread($fh, $buf, 24) or
2619 croak "read: $!";
2620 $read == 24 or
2621 croak "read only $read bytes (!= 24)";
2622 ($last_rev, $last_commit) =
2623 unpack(rev_map_fmt, $buf);
2624 if ($last_commit eq ('0' x40)) {
2625 croak "inconsistent .rev_map\n";
2626 }
2627 }
2628 if ($last_rev >= $rev) {
2629 croak "last_rev is higher!: $last_rev >= $rev";
2630 }
2631 $wr_offset = -24;
2632 }
2633 }
2634 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2635 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2636 croak "write: $!";
2637 }
2638
2639 sub mkfile {
2640 my ($path) = @_;
2641 unless (-e $path) {
2642 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2643 mkpath([$dir]) unless -d $dir;
2644 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2645 close $fh or die "Couldn't close (create) $path: $!\n";
2646 }
2647 }
2648
2649 sub rev_map_set {
2650 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2651 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2652 my $db = $self->map_path($uuid);
2653 my $db_lock = "$db.lock";
2654 my $sig;
2655 if ($update_ref) {
2656 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2657 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2658 }
2659 mkfile($db);
2660
2661 $LOCKFILES{$db_lock} = 1;
2662 my $sync;
2663 # both of these options make our .rev_db file very, very important
2664 # and we can't afford to lose it because rebuild() won't work
2665 if ($self->use_svm_props || $self->no_metadata) {
2666 $sync = 1;
2667 copy($db, $db_lock) or die "rev_map_set(@_): ",
2668 "Failed to copy: ",
2669 "$db => $db_lock ($!)\n";
2670 } else {
2671 rename $db, $db_lock or die "rev_map_set(@_): ",
2672 "Failed to rename: ",
2673 "$db => $db_lock ($!)\n";
2674 }
2675
2676 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2677 or croak "Couldn't open $db_lock: $!\n";
2678 _rev_map_set($fh, $rev, $commit);
2679 if ($sync) {
2680 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2681 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2682 }
2683 close $fh or croak $!;
2684 if ($update_ref) {
2685 $_head = $self;
2686 command_noisy('update-ref', '-m', "r$rev",
2687 $self->refname, $commit);
2688 }
2689 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2690 "$db_lock => $db ($!)\n";
2691 delete $LOCKFILES{$db_lock};
2692 if ($update_ref) {
2693 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2694 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2695 kill $sig, $$ if defined $sig;
2696 }
2697 }
2698
2699 # If want_commit, this will return an array of (rev, commit) where
2700 # commit _must_ be a valid commit in the archive.
2701 # Otherwise, it'll return the max revision (whether or not the
2702 # commit is valid or just a 0x40 placeholder).
2703 sub rev_map_max {
2704 my ($self, $want_commit) = @_;
2705 $self->rebuild;
2706 my $map_path = $self->map_path;
2707 stat $map_path or return $want_commit ? (0, undef) : 0;
2708 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2709 my $size = (stat($fh))[7];
2710 ($size % 24) == 0 or croak "inconsistent size: $size";
2711
2712 if ($size == 0) {
2713 close $fh or croak "close: $!";
2714 return $want_commit ? (0, undef) : 0;
2715 }
2716
2717 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2718 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2719 my ($r, $c) = unpack(rev_map_fmt, $buf);
2720 if ($want_commit && $c eq ('0' x40)) {
2721 if ($size < 48) {
2722 return $want_commit ? (0, undef) : 0;
2723 }
2724 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2725 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2726 ($r, $c) = unpack(rev_map_fmt, $buf);
2727 if ($c eq ('0'x40)) {
2728 croak "Penultimate record is all-zeroes in $map_path";
2729 }
2730 }
2731 close $fh or croak "close: $!";
2732 $want_commit ? ($r, $c) : $r;
2733 }
2734
2735 sub rev_map_get {
2736 my ($self, $rev, $uuid) = @_;
2737 my $map_path = $self->map_path($uuid);
2738 return undef unless -e $map_path;
2739
2740 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2741 my $size = (stat($fh))[7];
2742 ($size % 24) == 0 or croak "inconsistent size: $size";
2743
2744 if ($size == 0) {
2745 close $fh or croak "close: $fh";
2746 return undef;
2747 }
2748
2749 my ($l, $u) = (0, $size - 24);
2750 my ($r, $c, $buf);
2751
2752 while ($l <= $u) {
2753 my $i = int(($l/24 + $u/24) / 2) * 24;
2754 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2755 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2756 my ($r, $c) = unpack('NH40', $buf);
2757
2758 if ($r < $rev) {
2759 $l = $i + 24;
2760 } elsif ($r > $rev) {
2761 $u = $i - 24;
2762 } else { # $r == $rev
2763 close($fh) or croak "close: $!";
2764 return $c eq ('0' x 40) ? undef : $c;
2765 }
2766 }
2767 close($fh) or croak "close: $!";
2768 undef;
2769 }
2770
2771 # Finds the first svn revision that exists on (if $eq_ok is true) or
2772 # before $rev for the current branch. It will not search any lower
2773 # than $min_rev. Returns the git commit hash and svn revision number
2774 # if found, else (undef, undef).
2775 sub find_rev_before {
2776 my ($self, $rev, $eq_ok, $min_rev) = @_;
2777 --$rev unless $eq_ok;
2778 $min_rev ||= 1;
2779 while ($rev >= $min_rev) {
2780 if (my $c = $self->rev_map_get($rev)) {
2781 return ($rev, $c);
2782 }
2783 --$rev;
2784 }
2785 return (undef, undef);
2786 }
2787
2788 # Finds the first svn revision that exists on (if $eq_ok is true) or
2789 # after $rev for the current branch. It will not search any higher
2790 # than $max_rev. Returns the git commit hash and svn revision number
2791 # if found, else (undef, undef).
2792 sub find_rev_after {
2793 my ($self, $rev, $eq_ok, $max_rev) = @_;
2794 ++$rev unless $eq_ok;
2795 $max_rev ||= $self->rev_map_max;
2796 while ($rev <= $max_rev) {
2797 if (my $c = $self->rev_map_get($rev)) {
2798 return ($rev, $c);
2799 }
2800 ++$rev;
2801 }
2802 return (undef, undef);
2803 }
2804
2805 sub _new {
2806 my ($class, $repo_id, $ref_id, $path) = @_;
2807 unless (defined $repo_id && length $repo_id) {
2808 $repo_id = $Git::SVN::default_repo_id;
2809 }
2810 unless (defined $ref_id && length $ref_id) {
2811 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2812 }
2813 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2814 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2815 $_[3] = $path = '' unless (defined $path);
2816 mkpath(["$ENV{GIT_DIR}/svn"]);
2817 bless {
2818 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2819 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2820 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2821 }
2822
2823 # for read-only access of old .rev_db formats
2824 sub unlink_rev_db_symlink {
2825 my ($self) = @_;
2826 my $link = $self->rev_db_path;
2827 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2828 if (-l $link) {
2829 unlink $link or croak "unlink: $link failed!";
2830 }
2831 }
2832
2833 sub rev_db_path {
2834 my ($self, $uuid) = @_;
2835 my $db_path = $self->map_path($uuid);
2836 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2837 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2838 $db_path;
2839 }
2840
2841 # the new replacement for .rev_db
2842 sub map_path {
2843 my ($self, $uuid) = @_;
2844 $uuid ||= $self->ra_uuid;
2845 "$self->{map_root}.$uuid";
2846 }
2847
2848 sub uri_encode {
2849 my ($f) = @_;
2850 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2851 $f
2852 }
2853
2854 sub remove_username {
2855 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2856 }
2857
2858 package Git::SVN::Prompt;
2859 use strict;
2860 use warnings;
2861 require SVN::Core;
2862 use vars qw/$_no_auth_cache $_username/;
2863
2864 sub simple {
2865 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2866 $may_save = undef if $_no_auth_cache;
2867 $default_username = $_username if defined $_username;
2868 if (defined $default_username && length $default_username) {
2869 if (defined $realm && length $realm) {
2870 print STDERR "Authentication realm: $realm\n";
2871 STDERR->flush;
2872 }
2873 $cred->username($default_username);
2874 } else {
2875 username($cred, $realm, $may_save, $pool);
2876 }
2877 $cred->password(_read_password("Password for '" .
2878 $cred->username . "': ", $realm));
2879 $cred->may_save($may_save);
2880 $SVN::_Core::SVN_NO_ERROR;
2881 }
2882
2883 sub ssl_server_trust {
2884 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2885 $may_save = undef if $_no_auth_cache;
2886 print STDERR "Error validating server certificate for '$realm':\n";
2887 {
2888 no warnings 'once';
2889 # All variables SVN::Auth::SSL::* are used only once,
2890 # so we're shutting up Perl warnings about this.
2891 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2892 print STDERR " - The certificate is not issued ",
2893 "by a trusted authority. Use the\n",
2894 " fingerprint to validate ",
2895 "the certificate manually!\n";
2896 }
2897 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2898 print STDERR " - The certificate hostname ",
2899 "does not match.\n";
2900 }
2901 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2902 print STDERR " - The certificate is not yet valid.\n";
2903 }
2904 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2905 print STDERR " - The certificate has expired.\n";
2906 }
2907 if ($failures & $SVN::Auth::SSL::OTHER) {
2908 print STDERR " - The certificate has ",
2909 "an unknown error.\n";
2910 }
2911 } # no warnings 'once'
2912 printf STDERR
2913 "Certificate information:\n".
2914 " - Hostname: %s\n".
2915 " - Valid: from %s until %s\n".
2916 " - Issuer: %s\n".
2917 " - Fingerprint: %s\n",
2918 map $cert_info->$_, qw(hostname valid_from valid_until
2919 issuer_dname fingerprint);
2920 my $choice;
2921 prompt:
2922 print STDERR $may_save ?
2923 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2924 "(R)eject or accept (t)emporarily? ";
2925 STDERR->flush;
2926 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2927 if ($choice =~ /^t$/i) {
2928 $cred->may_save(undef);
2929 } elsif ($choice =~ /^r$/i) {
2930 return -1;
2931 } elsif ($may_save && $choice =~ /^p$/i) {
2932 $cred->may_save($may_save);
2933 } else {
2934 goto prompt;
2935 }
2936 $cred->accepted_failures($failures);
2937 $SVN::_Core::SVN_NO_ERROR;
2938 }
2939
2940 sub ssl_client_cert {
2941 my ($cred, $realm, $may_save, $pool) = @_;
2942 $may_save = undef if $_no_auth_cache;
2943 print STDERR "Client certificate filename: ";
2944 STDERR->flush;
2945 chomp(my $filename = <STDIN>);
2946 $cred->cert_file($filename);
2947 $cred->may_save($may_save);
2948 $SVN::_Core::SVN_NO_ERROR;
2949 }
2950
2951 sub ssl_client_cert_pw {
2952 my ($cred, $realm, $may_save, $pool) = @_;
2953 $may_save = undef if $_no_auth_cache;
2954 $cred->password(_read_password("Password: ", $realm));
2955 $cred->may_save($may_save);
2956 $SVN::_Core::SVN_NO_ERROR;
2957 }
2958
2959 sub username {
2960 my ($cred, $realm, $may_save, $pool) = @_;
2961 $may_save = undef if $_no_auth_cache;
2962 if (defined $realm && length $realm) {
2963 print STDERR "Authentication realm: $realm\n";
2964 }
2965 my $username;
2966 if (defined $_username) {
2967 $username = $_username;
2968 } else {
2969 print STDERR "Username: ";
2970 STDERR->flush;
2971 chomp($username = <STDIN>);
2972 }
2973 $cred->username($username);
2974 $cred->may_save($may_save);
2975 $SVN::_Core::SVN_NO_ERROR;
2976 }
2977
2978 sub _read_password {
2979 my ($prompt, $realm) = @_;
2980 print STDERR $prompt;
2981 STDERR->flush;
2982 require Term::ReadKey;
2983 Term::ReadKey::ReadMode('noecho');
2984 my $password = '';
2985 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2986 last if $key =~ /[\012\015]/; # \n\r
2987 $password .= $key;
2988 }
2989 Term::ReadKey::ReadMode('restore');
2990 print STDERR "\n";
2991 STDERR->flush;
2992 $password;
2993 }
2994
2995 package SVN::Git::Fetcher;
2996 use vars qw/@ISA/;
2997 use strict;
2998 use warnings;
2999 use Carp qw/croak/;
3000 use IO::File qw//;
3001
3002 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3003 sub new {
3004 my ($class, $git_svn) = @_;
3005 my $self = SVN::Delta::Editor->new;
3006 bless $self, $class;
3007 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3008 $self->{empty} = {};
3009 $self->{dir_prop} = {};
3010 $self->{file_prop} = {};
3011 $self->{absent_dir} = {};
3012 $self->{absent_file} = {};
3013 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3014 $self;
3015 }
3016
3017 sub set_path_strip {
3018 my ($self, $path) = @_;
3019 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3020 }
3021
3022 sub open_root {
3023 { path => '' };
3024 }
3025
3026 sub open_directory {
3027 my ($self, $path, $pb, $rev) = @_;
3028 { path => $path };
3029 }
3030
3031 sub git_path {
3032 my ($self, $path) = @_;
3033 if ($self->{path_strip}) {
3034 $path =~ s!$self->{path_strip}!! or
3035 die "Failed to strip path '$path' ($self->{path_strip})\n";
3036 }
3037 $path;
3038 }
3039
3040 sub delete_entry {
3041 my ($self, $path, $rev, $pb) = @_;
3042
3043 my $gpath = $self->git_path($path);
3044 return undef if ($gpath eq '');
3045
3046 # remove entire directories.
3047 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3048 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3049 -r --name-only -z/,
3050 $self->{c}, '--', $gpath);
3051 local $/ = "\0";
3052 while (<$ls>) {
3053 chomp;
3054 $self->{gii}->remove($_);
3055 print "\tD\t$_\n" unless $::_q;
3056 }
3057 print "\tD\t$gpath/\n" unless $::_q;
3058 command_close_pipe($ls, $ctx);
3059 $self->{empty}->{$path} = 0
3060 } else {
3061 $self->{gii}->remove($gpath);
3062 print "\tD\t$gpath\n" unless $::_q;
3063 }
3064 undef;
3065 }
3066
3067 sub open_file {
3068 my ($self, $path, $pb, $rev) = @_;
3069 my $gpath = $self->git_path($path);
3070 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3071 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3072 unless (defined $mode && defined $blob) {
3073 die "$path was not found in commit $self->{c} (r$rev)\n";
3074 }
3075 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3076 pool => SVN::Pool->new, action => 'M' };
3077 }
3078
3079 sub add_file {
3080 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3081 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3082 delete $self->{empty}->{$dir};
3083 { path => $path, mode_a => 100644, mode_b => 100644,
3084 pool => SVN::Pool->new, action => 'A' };
3085 }
3086
3087 sub add_directory {
3088 my ($self, $path, $cp_path, $cp_rev) = @_;
3089 my $gpath = $self->git_path($path);
3090 if ($gpath eq '') {
3091 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3092 -r --name-only -z/,
3093 $self->{c});
3094 local $/ = "\0";
3095 while (<$ls>) {
3096 chomp;
3097 $self->{gii}->remove($_);
3098 print "\tD\t$_\n" unless $::_q;
3099 }
3100 command_close_pipe($ls, $ctx);
3101 $self->{empty}->{$path} = 0;
3102 }
3103 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3104 delete $self->{empty}->{$dir};
3105 $self->{empty}->{$path} = 1;
3106 { path => $path };
3107 }
3108
3109 sub change_dir_prop {
3110 my ($self, $db, $prop, $value) = @_;
3111 $self->{dir_prop}->{$db->{path}} ||= {};
3112 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3113 undef;
3114 }
3115
3116 sub absent_directory {
3117 my ($self, $path, $pb) = @_;
3118 $self->{absent_dir}->{$pb->{path}} ||= [];
3119 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3120 undef;
3121 }
3122
3123 sub absent_file {
3124 my ($self, $path, $pb) = @_;
3125 $self->{absent_file}->{$pb->{path}} ||= [];
3126 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3127 undef;
3128 }
3129
3130 sub change_file_prop {
3131 my ($self, $fb, $prop, $value) = @_;
3132 if ($prop eq 'svn:executable') {
3133 if ($fb->{mode_b} != 120000) {
3134 $fb->{mode_b} = defined $value ? 100755 : 100644;
3135 }
3136 } elsif ($prop eq 'svn:special') {
3137 $fb->{mode_b} = defined $value ? 120000 : 100644;
3138 } else {
3139 $self->{file_prop}->{$fb->{path}} ||= {};
3140 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3141 }
3142 undef;
3143 }
3144
3145 sub apply_textdelta {
3146 my ($self, $fb, $exp) = @_;
3147 my $fh = IO::File->new_tmpfile;
3148 $fh->autoflush(1);
3149 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3150 # (but $base does not,) so dup() it for reading in close_file
3151 open my $dup, '<&', $fh or croak $!;
3152 my $base = IO::File->new_tmpfile;
3153 $base->autoflush(1);
3154 if ($fb->{blob}) {
3155 defined (my $pid = fork) or croak $!;
3156 if (!$pid) {
3157 open STDOUT, '>&', $base or croak $!;
3158 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3159 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3160 }
3161 waitpid $pid, 0;
3162 croak $? if $?;
3163
3164 if (defined $exp) {
3165 seek $base, 0, 0 or croak $!;
3166 my $got = ::md5sum($base);
3167 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3168 "expected: $exp\n",
3169 " got: $got\n" if ($got ne $exp);
3170 }
3171 }
3172 seek $base, 0, 0 or croak $!;
3173 $fb->{fh} = $dup;
3174 $fb->{base} = $base;
3175 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3176 }
3177
3178 sub close_file {
3179 my ($self, $fb, $exp) = @_;
3180 my $hash;
3181 my $path = $self->git_path($fb->{path});
3182 if (my $fh = $fb->{fh}) {
3183 if (defined $exp) {
3184 seek($fh, 0, 0) or croak $!;
3185 my $got = ::md5sum($fh);
3186 if ($got ne $exp) {
3187 die "Checksum mismatch: $path\n",
3188 "expected: $exp\n got: $got\n";
3189 }
3190 }
3191 sysseek($fh, 0, 0) or croak $!;
3192 if ($fb->{mode_b} == 120000) {
3193 eval {
3194 sysread($fh, my $buf, 5) == 5 or croak $!;
3195 $buf eq 'link ' or die "$path has mode 120000",
3196 " but is not a link";
3197 };
3198 if ($@) {
3199 warn "$@\n";
3200 sysseek($fh, 0, 0) or croak $!;
3201 }
3202 }
3203 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3204 if (!$pid) {
3205 open STDIN, '<&', $fh or croak $!;
3206 exec qw/git-hash-object -w --stdin/ or croak $!;
3207 }
3208 chomp($hash = do { local $/; <$out> });
3209 close $out or croak $!;
3210 close $fh or croak $!;
3211 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3212 close $fb->{base} or croak $!;
3213 } else {
3214 $hash = $fb->{blob} or die "no blob information\n";
3215 }
3216 $fb->{pool}->clear;
3217 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3218 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3219 undef;
3220 }
3221
3222 sub abort_edit {
3223 my $self = shift;
3224 $self->{nr} = $self->{gii}->{nr};
3225 delete $self->{gii};
3226 $self->SUPER::abort_edit(@_);
3227 }
3228
3229 sub close_edit {
3230 my $self = shift;
3231 $self->{git_commit_ok} = 1;
3232 $self->{nr} = $self->{gii}->{nr};
3233 delete $self->{gii};
3234 $self->SUPER::close_edit(@_);
3235 }
3236
3237 package SVN::Git::Editor;
3238 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3239 use strict;
3240 use warnings;
3241 use Carp qw/croak/;
3242 use IO::File;
3243
3244 sub new {
3245 my ($class, $opts) = @_;
3246 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3247 die "$_ required!\n" unless (defined $opts->{$_});
3248 }
3249
3250 my $pool = SVN::Pool->new;
3251 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3252 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3253 $opts->{r}, $mods);
3254
3255 # $opts->{ra} functions should not be used after this:
3256 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3257 $opts->{editor_cb}, $pool);
3258 my $self = SVN::Delta::Editor->new(@ce, $pool);
3259 bless $self, $class;
3260 foreach (qw/svn_path r tree_a tree_b/) {
3261 $self->{$_} = $opts->{$_};
3262 }
3263 $self->{url} = $opts->{ra}->{url};
3264 $self->{mods} = $mods;
3265 $self->{types} = $types;
3266 $self->{pool} = $pool;
3267 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3268 $self->{rm} = { };
3269 $self->{path_prefix} = length $self->{svn_path} ?
3270 "$self->{svn_path}/" : '';
3271 return $self;
3272 }
3273
3274 sub generate_diff {
3275 my ($tree_a, $tree_b) = @_;
3276 my @diff_tree = qw(diff-tree -z -r);
3277 if ($_cp_similarity) {
3278 push @diff_tree, "-C$_cp_similarity";
3279 } else {
3280 push @diff_tree, '-C';
3281 }
3282 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3283 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3284 push @diff_tree, $tree_a, $tree_b;
3285 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3286 local $/ = "\0";
3287 my $state = 'meta';
3288 my @mods;
3289 while (<$diff_fh>) {
3290 chomp $_; # this gets rid of the trailing "\0"
3291 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3292 $::sha1\s($::sha1)\s
3293 ([MTCRAD])\d*$/xo) {
3294 push @mods, { mode_a => $1, mode_b => $2,
3295 sha1_b => $3, chg => $4 };
3296 if ($4 =~ /^(?:C|R)$/) {
3297 $state = 'file_a';
3298 } else {
3299 $state = 'file_b';
3300 }
3301 } elsif ($state eq 'file_a') {
3302 my $x = $mods[$#mods] or croak "Empty array\n";
3303 if ($x->{chg} !~ /^(?:C|R)$/) {
3304 croak "Error parsing $_, $x->{chg}\n";
3305 }
3306 $x->{file_a} = $_;
3307 $state = 'file_b';
3308 } elsif ($state eq 'file_b') {
3309 my $x = $mods[$#mods] or croak "Empty array\n";
3310 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3311 croak "Error parsing $_, $x->{chg}\n";
3312 }
3313 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3314 croak "Error parsing $_, $x->{chg}\n";
3315 }
3316 $x->{file_b} = $_;
3317 $state = 'meta';
3318 } else {
3319 croak "Error parsing $_\n";
3320 }
3321 }
3322 command_close_pipe($diff_fh, $ctx);
3323 \@mods;
3324 }
3325
3326 sub check_diff_paths {
3327 my ($ra, $pfx, $rev, $mods) = @_;
3328 my %types;
3329 $pfx .= '/' if length $pfx;
3330
3331 sub type_diff_paths {
3332 my ($ra, $types, $path, $rev) = @_;
3333 my @p = split m#/+#, $path;
3334 my $c = shift @p;
3335 unless (defined $types->{$c}) {
3336 $types->{$c} = $ra->check_path($c, $rev);
3337 }
3338 while (@p) {
3339 $c .= '/' . shift @p;
3340 next if defined $types->{$c};
3341 $types->{$c} = $ra->check_path($c, $rev);
3342 }
3343 }
3344
3345 foreach my $m (@$mods) {
3346 foreach my $f (qw/file_a file_b/) {
3347 next unless defined $m->{$f};
3348 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3349 if (length $pfx.$dir && ! defined $types{$dir}) {
3350 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3351 }
3352 }
3353 }
3354 \%types;
3355 }
3356
3357 sub split_path {
3358 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3359 }
3360
3361 sub repo_path {
3362 my ($self, $path) = @_;
3363 $self->{path_prefix}.(defined $path ? $path : '');
3364 }
3365
3366 sub url_path {
3367 my ($self, $path) = @_;
3368 if ($self->{url} =~ m#^https?://#) {
3369 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3370 }
3371 $self->{url} . '/' . $self->repo_path($path);
3372 }
3373
3374 sub rmdirs {
3375 my ($self) = @_;
3376 my $rm = $self->{rm};
3377 delete $rm->{''}; # we never delete the url we're tracking
3378 return unless %$rm;
3379
3380 foreach (keys %$rm) {
3381 my @d = split m#/#, $_;
3382 my $c = shift @d;
3383 $rm->{$c} = 1;
3384 while (@d) {
3385 $c .= '/' . shift @d;
3386 $rm->{$c} = 1;
3387 }
3388 }
3389 delete $rm->{$self->{svn_path}};
3390 delete $rm->{''}; # we never delete the url we're tracking
3391 return unless %$rm;
3392
3393 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3394 $self->{tree_b});
3395 local $/ = "\0";
3396 while (<$fh>) {
3397 chomp;
3398 my @dn = split m#/#, $_;
3399 while (pop @dn) {
3400 delete $rm->{join '/', @dn};
3401 }
3402 unless (%$rm) {
3403 close $fh;
3404 return;
3405 }
3406 }
3407 command_close_pipe($fh, $ctx);
3408
3409 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3410 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3411 $self->close_directory($bat->{$d}, $p);
3412 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3413 print "\tD+\t$d/\n" unless $::_q;
3414 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3415 delete $bat->{$d};
3416 }
3417 }
3418
3419 sub open_or_add_dir {
3420 my ($self, $full_path, $baton) = @_;
3421 my $t = $self->{types}->{$full_path};
3422 if (!defined $t) {
3423 die "$full_path not known in r$self->{r} or we have a bug!\n";
3424 }
3425 {
3426 no warnings 'once';
3427 # SVN::Node::none and SVN::Node::file are used only once,
3428 # so we're shutting up Perl's warnings about them.
3429 if ($t == $SVN::Node::none) {
3430 return $self->add_directory($full_path, $baton,
3431 undef, -1, $self->{pool});
3432 } elsif ($t == $SVN::Node::dir) {
3433 return $self->open_directory($full_path, $baton,
3434 $self->{r}, $self->{pool});
3435 } # no warnings 'once'
3436 print STDERR "$full_path already exists in repository at ",
3437 "r$self->{r} and it is not a directory (",
3438 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3439 } # no warnings 'once'
3440 exit 1;
3441 }
3442
3443 sub ensure_path {
3444 my ($self, $path) = @_;
3445 my $bat = $self->{bat};
3446 my $repo_path = $self->repo_path($path);
3447 return $bat->{''} unless (length $repo_path);
3448 my @p = split m#/+#, $repo_path;
3449 my $c = shift @p;
3450 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3451 while (@p) {
3452 my $c0 = $c;
3453 $c .= '/' . shift @p;
3454 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3455 }
3456 return $bat->{$c};
3457 }
3458
3459 sub A {
3460 my ($self, $m) = @_;
3461 my ($dir, $file) = split_path($m->{file_b});
3462 my $pbat = $self->ensure_path($dir);
3463 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3464 undef, -1);
3465 print "\tA\t$m->{file_b}\n" unless $::_q;
3466 $self->chg_file($fbat, $m);
3467 $self->close_file($fbat,undef,$self->{pool});
3468 }
3469
3470 sub C {
3471 my ($self, $m) = @_;
3472 my ($dir, $file) = split_path($m->{file_b});
3473 my $pbat = $self->ensure_path($dir);
3474 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3475 $self->url_path($m->{file_a}), $self->{r});
3476 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3477 $self->chg_file($fbat, $m);
3478 $self->close_file($fbat,undef,$self->{pool});
3479 }
3480
3481 sub delete_entry {
3482 my ($self, $path, $pbat) = @_;
3483 my $rpath = $self->repo_path($path);
3484 my ($dir, $file) = split_path($rpath);
3485 $self->{rm}->{$dir} = 1;
3486 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3487 }
3488
3489 sub R {
3490 my ($self, $m) = @_;
3491 my ($dir, $file) = split_path($m->{file_b});
3492 my $pbat = $self->ensure_path($dir);
3493 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3494 $self->url_path($m->{file_a}), $self->{r});
3495 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3496 $self->chg_file($fbat, $m);
3497 $self->close_file($fbat,undef,$self->{pool});
3498
3499 ($dir, $file) = split_path($m->{file_a});
3500 $pbat = $self->ensure_path($dir);
3501 $self->delete_entry($m->{file_a}, $pbat);
3502 }
3503
3504 sub M {
3505 my ($self, $m) = @_;
3506 my ($dir, $file) = split_path($m->{file_b});
3507 my $pbat = $self->ensure_path($dir);
3508 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3509 $pbat,$self->{r},$self->{pool});
3510 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3511 $self->chg_file($fbat, $m);
3512 $self->close_file($fbat,undef,$self->{pool});
3513 }
3514
3515 sub T { shift->M(@_) }
3516
3517 sub change_file_prop {
3518 my ($self, $fbat, $pname, $pval) = @_;
3519 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3520 }
3521
3522 sub chg_file {
3523 my ($self, $fbat, $m) = @_;
3524 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3525 $self->change_file_prop($fbat,'svn:executable','*');
3526 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3527 $self->change_file_prop($fbat,'svn:executable',undef);
3528 }
3529 my $fh = IO::File->new_tmpfile or croak $!;
3530 if ($m->{mode_b} =~ /^120/) {
3531 print $fh 'link ' or croak $!;
3532 $self->change_file_prop($fbat,'svn:special','*');
3533 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3534 $self->change_file_prop($fbat,'svn:special',undef);
3535 }
3536 defined(my $pid = fork) or croak $!;
3537 if (!$pid) {
3538 open STDOUT, '>&', $fh or croak $!;
3539 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3540 }
3541 waitpid $pid, 0;
3542 croak $? if $?;
3543 $fh->flush == 0 or croak $!;
3544 seek $fh, 0, 0 or croak $!;
3545
3546 my $exp = ::md5sum($fh);
3547 seek $fh, 0, 0 or croak $!;
3548
3549 my $pool = SVN::Pool->new;
3550 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3551 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3552 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3553 $pool->clear;
3554
3555 close $fh or croak $!;
3556 }
3557
3558 sub D {
3559 my ($self, $m) = @_;
3560 my ($dir, $file) = split_path($m->{file_b});
3561 my $pbat = $self->ensure_path($dir);
3562 print "\tD\t$m->{file_b}\n" unless $::_q;
3563 $self->delete_entry($m->{file_b}, $pbat);
3564 }
3565
3566 sub close_edit {
3567 my ($self) = @_;
3568 my ($p,$bat) = ($self->{pool}, $self->{bat});
3569 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3570 next if $_ eq '';
3571 $self->close_directory($bat->{$_}, $p);
3572 }
3573 $self->close_directory($bat->{''}, $p);
3574 $self->SUPER::close_edit($p);
3575 $p->clear;
3576 }
3577
3578 sub abort_edit {
3579 my ($self) = @_;
3580 $self->SUPER::abort_edit($self->{pool});
3581 }
3582
3583 sub DESTROY {
3584 my $self = shift;
3585 $self->SUPER::DESTROY(@_);
3586 $self->{pool}->clear;
3587 }
3588
3589 # this drives the editor
3590 sub apply_diff {
3591 my ($self) = @_;
3592 my $mods = $self->{mods};
3593 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3594 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3595 my $f = $m->{chg};
3596 if (defined $o{$f}) {
3597 $self->$f($m);
3598 } else {
3599 fatal("Invalid change type: $f");
3600 }
3601 }
3602 $self->rmdirs if $_rmdir;
3603 if (@$mods == 0) {
3604 $self->abort_edit;
3605 } else {
3606 $self->close_edit;
3607 }
3608 return scalar @$mods;
3609 }
3610
3611 package Git::SVN::Ra;
3612 use vars qw/@ISA $config_dir $_log_window_size/;
3613 use strict;
3614 use warnings;
3615 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3616
3617 BEGIN {
3618 # enforce temporary pool usage for some simple functions
3619 no strict 'refs';
3620 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3621 my $SUPER = "SUPER::$f";
3622 *$f = sub {
3623 my $self = shift;
3624 my $pool = SVN::Pool->new;
3625 my @ret = $self->$SUPER(@_,$pool);
3626 $pool->clear;
3627 wantarray ? @ret : $ret[0];
3628 };
3629 }
3630 }
3631
3632 sub _auth_providers () {
3633 [
3634 SVN::Client::get_simple_provider(),
3635 SVN::Client::get_ssl_server_trust_file_provider(),
3636 SVN::Client::get_simple_prompt_provider(
3637 \&Git::SVN::Prompt::simple, 2),
3638 SVN::Client::get_ssl_client_cert_file_provider(),
3639 SVN::Client::get_ssl_client_cert_prompt_provider(
3640 \&Git::SVN::Prompt::ssl_client_cert, 2),
3641 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3642 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3643 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3644 SVN::Client::get_username_provider(),
3645 SVN::Client::get_ssl_server_trust_prompt_provider(
3646 \&Git::SVN::Prompt::ssl_server_trust),
3647 SVN::Client::get_username_prompt_provider(
3648 \&Git::SVN::Prompt::username, 2)
3649 ]
3650 }
3651
3652 sub escape_uri_only {
3653 my ($uri) = @_;
3654 my @tmp;
3655 foreach (split m{/}, $uri) {
3656 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3657 push @tmp, $_;
3658 }
3659 join('/', @tmp);
3660 }
3661
3662 sub escape_url {
3663 my ($url) = @_;
3664 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3665 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3666 $url = "$scheme://$domain$uri";
3667 }
3668 $url;
3669 }
3670
3671 sub new {
3672 my ($class, $url) = @_;
3673 $url =~ s!/+$!!;
3674 return $RA if ($RA && $RA->{url} eq $url);
3675
3676 SVN::_Core::svn_config_ensure($config_dir, undef);
3677 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3678 my $config = SVN::Core::config_get_config($config_dir);
3679 $RA = undef;
3680 my $dont_store_passwords = 1;
3681 my $conf_t = ${$config}{'config'};
3682 {
3683 no warnings 'once';
3684 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3685 # produces warnings that variables are used only once.
3686 # I had not found the better way to shut them up, so
3687 # the warnings of type 'once' are disabled in this block.
3688 if (SVN::_Core::svn_config_get_bool($conf_t,
3689 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3690 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3691 1) == 0) {
3692 SVN::_Core::svn_auth_set_parameter($baton,
3693 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3694 bless (\$dont_store_passwords, "_p_void"));
3695 }
3696 if (SVN::_Core::svn_config_get_bool($conf_t,
3697 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3698 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3699 1) == 0) {
3700 $Git::SVN::Prompt::_no_auth_cache = 1;
3701 }
3702 } # no warnings 'once'
3703 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3704 config => $config,
3705 pool => SVN::Pool->new,
3706 auth_provider_callbacks => $callbacks);
3707 $self->{url} = $url;
3708 $self->{svn_path} = $url;
3709 $self->{repos_root} = $self->get_repos_root;
3710 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3711 $self->{cache} = { check_path => { r => 0, data => {} },
3712 get_dir => { r => 0, data => {} } };
3713 $RA = bless $self, $class;
3714 }
3715
3716 sub check_path {
3717 my ($self, $path, $r) = @_;
3718 my $cache = $self->{cache}->{check_path};
3719 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3720 return $cache->{data}->{$path};
3721 }
3722 my $pool = SVN::Pool->new;
3723 my $t = $self->SUPER::check_path($path, $r, $pool);
3724 $pool->clear;
3725 if ($r != $cache->{r}) {
3726 %{$cache->{data}} = ();
3727 $cache->{r} = $r;
3728 }
3729 $cache->{data}->{$path} = $t;
3730 }
3731
3732 sub get_dir {
3733 my ($self, $dir, $r) = @_;
3734 my $cache = $self->{cache}->{get_dir};
3735 if ($r == $cache->{r}) {
3736 if (my $x = $cache->{data}->{$dir}) {
3737 return wantarray ? @$x : $x->[0];
3738 }
3739 }
3740 my $pool = SVN::Pool->new;
3741 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3742 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3743 $pool->clear;
3744 if ($r != $cache->{r}) {
3745 %{$cache->{data}} = ();
3746 $cache->{r} = $r;
3747 }
3748 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3749 wantarray ? (\%dirents, $r, $props) : \%dirents;
3750 }
3751
3752 sub DESTROY {
3753 # do not call the real DESTROY since we store ourselves in $RA
3754 }
3755
3756 sub get_log {
3757 my ($self, @args) = @_;
3758 my $pool = SVN::Pool->new;
3759 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3760 my $ret = $self->SUPER::get_log(@args, $pool);
3761 $pool->clear;
3762 $ret;
3763 }
3764
3765 sub trees_match {
3766 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3767 my $ctx = SVN::Client->new(auth => _auth_providers);
3768 my $out = IO::File->new_tmpfile;
3769
3770 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3771 # $ctx->diff(), so we'll create a default one
3772 my $pool = SVN::Pool->new_default_sub;
3773
3774 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3775 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3776 $out->flush;
3777 my $ret = (($out->stat)[7] == 0);
3778 close $out or croak $!;
3779
3780 $ret;
3781 }
3782
3783 sub get_commit_editor {
3784 my ($self, $log, $cb, $pool) = @_;
3785 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3786 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3787 }
3788
3789 sub gs_do_update {
3790 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3791 my $new = ($rev_a == $rev_b);
3792 my $path = $gs->{path};
3793
3794 if ($new && -e $gs->{index}) {
3795 unlink $gs->{index} or die
3796 "Couldn't unlink index: $gs->{index}: $!\n";
3797 }
3798 my $pool = SVN::Pool->new;
3799 $editor->set_path_strip($path);
3800 my (@pc) = split m#/#, $path;
3801 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3802 1, $editor, $pool);
3803 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3804
3805 # Since we can't rely on svn_ra_reparent being available, we'll
3806 # just have to do some magic with set_path to make it so
3807 # we only want a partial path.
3808 my $sp = '';
3809 my $final = join('/', @pc);
3810 while (@pc) {
3811 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3812 $sp .= '/' if length $sp;
3813 $sp .= shift @pc;
3814 }
3815 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3816
3817 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3818
3819 $reporter->finish_report($pool);
3820 $pool->clear;
3821 $editor->{git_commit_ok};
3822 }
3823
3824 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3825 # svn_ra_reparent didn't work before 1.4)
3826 sub gs_do_switch {
3827 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3828 my $path = $gs->{path};
3829 my $pool = SVN::Pool->new;
3830
3831 my $full_url = $self->{url};
3832 my $old_url = $full_url;
3833 $full_url .= '/' . escape_uri_only($path) if length $path;
3834 my ($ra, $reparented);
3835 if ($old_url ne $full_url) {
3836 if ($old_url !~ m#^svn(\+ssh)?://#) {
3837 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3838 $pool);
3839 $self->{url} = $full_url;
3840 $reparented = 1;
3841 } else {
3842 $_[0] = undef;
3843 $self = undef;
3844 $RA = undef;
3845 $ra = Git::SVN::Ra->new($full_url);
3846 $ra_invalid = 1;
3847 }
3848 }
3849 $ra ||= $self;
3850 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3851 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3852 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3853 $reporter->finish_report($pool);
3854
3855 if ($reparented) {
3856 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3857 $self->{url} = $old_url;
3858 }
3859
3860 $pool->clear;
3861 $editor->{git_commit_ok};
3862 }
3863
3864 sub longest_common_path {
3865 my ($gsv, $globs) = @_;
3866 my %common;
3867 my $common_max = scalar @$gsv;
3868
3869 foreach my $gs (@$gsv) {
3870 my @tmp = split m#/#, $gs->{path};
3871 my $p = '';
3872 foreach (@tmp) {
3873 $p .= length($p) ? "/$_" : $_;
3874 $common{$p} ||= 0;
3875 $common{$p}++;
3876 }
3877 }
3878 $globs ||= [];
3879 $common_max += scalar @$globs;
3880 foreach my $glob (@$globs) {
3881 my @tmp = split m#/#, $glob->{path}->{left};
3882 my $p = '';
3883 foreach (@tmp) {
3884 $p .= length($p) ? "/$_" : $_;
3885 $common{$p} ||= 0;
3886 $common{$p}++;
3887 }
3888 }
3889
3890 my $longest_path = '';
3891 foreach (sort {length $b <=> length $a} keys %common) {
3892 if ($common{$_} == $common_max) {
3893 $longest_path = $_;
3894 last;
3895 }
3896 }
3897 $longest_path;
3898 }
3899
3900 sub gs_fetch_loop_common {
3901 my ($self, $base, $head, $gsv, $globs) = @_;
3902 return if ($base > $head);
3903 my $inc = $_log_window_size;
3904 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3905 my $longest_path = longest_common_path($gsv, $globs);
3906 my $ra_url = $self->{url};
3907 while (1) {
3908 my %revs;
3909 my $err;
3910 my $err_handler = $SVN::Error::handler;
3911 $SVN::Error::handler = sub {
3912 ($err) = @_;
3913 skip_unknown_revs($err);
3914 };
3915 sub _cb {
3916 my ($paths, $r, $author, $date, $log) = @_;
3917 [ dup_changed_paths($paths),
3918 { author => $author, date => $date, log => $log } ];
3919 }
3920 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3921 sub { $revs{$_[1]} = _cb(@_) });
3922 if ($err && $max >= $head) {
3923 print STDERR "Path '$longest_path' ",
3924 "was probably deleted:\n",
3925 $err->expanded_message,
3926 "\nWill attempt to follow ",
3927 "revisions r$min .. r$max ",
3928 "committed before the deletion\n";
3929 my $hi = $max;
3930 while (--$hi >= $min) {
3931 my $ok;
3932 $self->get_log([$longest_path], $min, $hi,
3933 0, 1, 1, sub {
3934 $ok ||= $_[1];
3935 $revs{$_[1]} = _cb(@_) });
3936 if ($ok) {
3937 print STDERR "r$min .. r$ok OK\n";
3938 last;
3939 }
3940 }
3941 }
3942 $SVN::Error::handler = $err_handler;
3943
3944 my %exists = map { $_->{path} => $_ } @$gsv;
3945 foreach my $r (sort {$a <=> $b} keys %revs) {
3946 my ($paths, $logged) = @{$revs{$r}};
3947
3948 foreach my $gs ($self->match_globs(\%exists, $paths,
3949 $globs, $r)) {
3950 if ($gs->rev_map_max >= $r) {
3951 next;
3952 }
3953 next unless $gs->match_paths($paths, $r);
3954 $gs->{logged_rev_props} = $logged;
3955 if (my $last_commit = $gs->last_commit) {
3956 $gs->assert_index_clean($last_commit);
3957 }
3958 my $log_entry = $gs->do_fetch($paths, $r);
3959 if ($log_entry) {
3960 $gs->do_git_commit($log_entry);
3961 }
3962 $INDEX_FILES{$gs->{index}} = 1;
3963 }
3964 foreach my $g (@$globs) {
3965 my $k = "svn-remote.$g->{remote}." .
3966 "$g->{t}-maxRev";
3967 Git::SVN::tmp_config($k, $r);
3968 }
3969 if ($ra_invalid) {
3970 $_[0] = undef;
3971 $self = undef;
3972 $RA = undef;
3973 $self = Git::SVN::Ra->new($ra_url);
3974 $ra_invalid = undef;
3975 }
3976 }
3977 # pre-fill the .rev_db since it'll eventually get filled in
3978 # with '0' x40 if something new gets committed
3979 foreach my $gs (@$gsv) {
3980 next if $gs->rev_map_max >= $max;
3981 next if defined $gs->rev_map_get($max);
3982 $gs->rev_map_set($max, 0 x40);
3983 }
3984 foreach my $g (@$globs) {
3985 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3986 Git::SVN::tmp_config($k, $max);
3987 }
3988 last if $max >= $head;
3989 $min = $max + 1;
3990 $max += $inc;
3991 $max = $head if ($max > $head);
3992 }
3993 }
3994
3995 sub match_globs {
3996 my ($self, $exists, $paths, $globs, $r) = @_;
3997
3998 sub get_dir_check {
3999 my ($self, $exists, $g, $r) = @_;
4000 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4001 return unless scalar @x == 3;
4002 my $dirents = $x[0];
4003 foreach my $de (keys %$dirents) {
4004 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4005 my $p = $g->{path}->full_path($de);
4006 next if $exists->{$p};
4007 next if (length $g->{path}->{right} &&
4008 ($self->check_path($p, $r) !=
4009 $SVN::Node::dir));
4010 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4011 $g->{ref}->full_path($de), 1);
4012 }
4013 }
4014 foreach my $g (@$globs) {
4015 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4016 if ($path->{action} =~ /^[AR]$/) {
4017 get_dir_check($self, $exists, $g, $r);
4018 }
4019 }
4020 foreach (keys %$paths) {
4021 if (/$g->{path}->{left_regex}/ &&
4022 !/$g->{path}->{regex}/) {
4023 next if $paths->{$_}->{action} !~ /^[AR]$/;
4024 get_dir_check($self, $exists, $g, $r);
4025 }
4026 next unless /$g->{path}->{regex}/;
4027 my $p = $1;
4028 my $pathname = $g->{path}->full_path($p);
4029 next if $exists->{$pathname};
4030 next if ($self->check_path($pathname, $r) !=
4031 $SVN::Node::dir);
4032 $exists->{$pathname} = Git::SVN->init(
4033 $self->{url}, $pathname, undef,
4034 $g->{ref}->full_path($p), 1);
4035 }
4036 my $c = '';
4037 foreach (split m#/#, $g->{path}->{left}) {
4038 $c .= "/$_";
4039 next unless ($paths->{$c} &&
4040 ($paths->{$c}->{action} =~ /^[AR]$/));
4041 get_dir_check($self, $exists, $g, $r);
4042 }
4043 }
4044 values %$exists;
4045 }
4046
4047 sub minimize_url {
4048 my ($self) = @_;
4049 return $self->{url} if ($self->{url} eq $self->{repos_root});
4050 my $url = $self->{repos_root};
4051 my @components = split(m!/!, $self->{svn_path});
4052 my $c = '';
4053 do {
4054 $url .= "/$c" if length $c;
4055 eval { (ref $self)->new($url)->get_latest_revnum };
4056 } while ($@ && ($c = shift @components));
4057 $url;
4058 }
4059
4060 sub can_do_switch {
4061 my $self = shift;
4062 unless (defined $can_do_switch) {
4063 my $pool = SVN::Pool->new;
4064 my $rep = eval {
4065 $self->do_switch(1, '', 0, $self->{url},
4066 SVN::Delta::Editor->new, $pool);
4067 };
4068 if ($@) {
4069 $can_do_switch = 0;
4070 } else {
4071 $rep->abort_report($pool);
4072 $can_do_switch = 1;
4073 }
4074 $pool->clear;
4075 }
4076 $can_do_switch;
4077 }
4078
4079 sub skip_unknown_revs {
4080 my ($err) = @_;
4081 my $errno = $err->apr_err();
4082 # Maybe the branch we're tracking didn't
4083 # exist when the repo started, so it's
4084 # not an error if it doesn't, just continue
4085 #
4086 # Wonderfully consistent library, eh?
4087 # 160013 - svn:// and file://
4088 # 175002 - http(s)://
4089 # 175007 - http(s):// (this repo required authorization, too...)
4090 # More codes may be discovered later...
4091 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4092 my $err_key = $err->expanded_message;
4093 # revision numbers change every time, filter them out
4094 $err_key =~ s/\d+/\0/g;
4095 $err_key = "$errno\0$err_key";
4096 unless ($ignored_err{$err_key}) {
4097 warn "W: Ignoring error from SVN, path probably ",
4098 "does not exist: ($errno): ",
4099 $err->expanded_message,"\n";
4100 warn "W: Do not be alarmed at the above message ",
4101 "git-svn is just searching aggressively for ",
4102 "old history.\n",
4103 "This may take a while on large repositories\n";
4104 $ignored_err{$err_key} = 1;
4105 }
4106 return;
4107 }
4108 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4109 }
4110
4111 # svn_log_changed_path_t objects passed to get_log are likely to be
4112 # overwritten even if only the refs are copied to an external variable,
4113 # so we should dup the structures in their entirety. Using an externally
4114 # passed pool (instead of our temporary and quickly cleared pool in
4115 # Git::SVN::Ra) does not help matters at all...
4116 sub dup_changed_paths {
4117 my ($paths) = @_;
4118 return undef unless $paths;
4119 my %ret;
4120 foreach my $p (keys %$paths) {
4121 my $i = $paths->{$p};
4122 my %s = map { $_ => $i->$_ }
4123 qw/copyfrom_path copyfrom_rev action/;
4124 $ret{$p} = \%s;
4125 }
4126 \%ret;
4127 }
4128
4129 package Git::SVN::Log;
4130 use strict;
4131 use warnings;
4132 use POSIX qw/strftime/;
4133 use constant commit_log_separator => ('-' x 72) . "\n";
4134 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4135 %rusers $show_commit $incremental/;
4136 my $l_fmt;
4137
4138 sub cmt_showable {
4139 my ($c) = @_;
4140 return 1 if defined $c->{r};
4141
4142 # big commit message got truncated by the 16k pretty buffer in rev-list
4143 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4144 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4145 @{$c->{l}} = ();
4146 my @log = command(qw/cat-file commit/, $c->{c});
4147
4148 # shift off the headers
4149 shift @log while ($log[0] ne '');
4150 shift @log;
4151
4152 # TODO: make $c->{l} not have a trailing newline in the future
4153 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4154
4155 (undef, $c->{r}, undef) = ::extract_metadata(
4156 (grep(/^git-svn-id: /, @log))[-1]);
4157 }
4158 return defined $c->{r};
4159 }
4160
4161 sub log_use_color {
4162 return $color || Git->repository->get_colorbool('color.diff');
4163 }
4164
4165 sub git_svn_log_cmd {
4166 my ($r_min, $r_max, @args) = @_;
4167 my $head = 'HEAD';
4168 my (@files, @log_opts);
4169 foreach my $x (@args) {
4170 if ($x eq '--' || @files) {
4171 push @files, $x;
4172 } else {
4173 if (::verify_ref("$x^0")) {
4174 $head = $x;
4175 } else {
4176 push @log_opts, $x;
4177 }
4178 }
4179 }
4180
4181 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4182 $gs ||= Git::SVN->_new;
4183 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4184 $gs->refname);
4185 push @cmd, '-r' unless $non_recursive;
4186 push @cmd, qw/--raw --name-status/ if $verbose;
4187 push @cmd, '--color' if log_use_color();
4188 push @cmd, @log_opts;
4189 if (defined $r_max && $r_max == $r_min) {
4190 push @cmd, '--max-count=1';
4191 if (my $c = $gs->rev_map_get($r_max)) {
4192 push @cmd, $c;
4193 }
4194 } elsif (defined $r_max) {
4195 if ($r_max < $r_min) {
4196 ($r_min, $r_max) = ($r_max, $r_min);
4197 }
4198 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4199 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4200 # If there are no commits in the range, both $c_max and $c_min
4201 # will be undefined. If there is at least 1 commit in the
4202 # range, both will be defined.
4203 return () if !defined $c_min || !defined $c_max;
4204 if ($c_min eq $c_max) {
4205 push @cmd, '--max-count=1', $c_min;
4206 } else {
4207 push @cmd, '--boundary', "$c_min..$c_max";
4208 }
4209 }
4210 return (@cmd, @files);
4211 }
4212
4213 # adapted from pager.c
4214 sub config_pager {
4215 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4216 if (!defined $pager) {
4217 $pager = 'less';
4218 } elsif (length $pager == 0 || $pager eq 'cat') {
4219 $pager = undef;
4220 }
4221 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4222 }
4223
4224 sub run_pager {
4225 return unless -t *STDOUT && defined $pager;
4226 pipe my $rfd, my $wfd or return;
4227 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4228 if (!$pid) {
4229 open STDOUT, '>&', $wfd or
4230 ::fatal "Can't redirect to stdout: $!";
4231 return;
4232 }
4233 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4234 $ENV{LESS} ||= 'FRSX';
4235 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4236 }
4237
4238 sub format_svn_date {
4239 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4240 }
4241
4242 sub parse_git_date {
4243 my ($t, $tz) = @_;
4244 # Date::Parse isn't in the standard Perl distro :(
4245 if ($tz =~ s/^\+//) {
4246 $t += tz_to_s_offset($tz);
4247 } elsif ($tz =~ s/^\-//) {
4248 $t -= tz_to_s_offset($tz);
4249 }
4250 return $t;
4251 }
4252
4253 sub set_local_timezone {
4254 if (defined $TZ) {
4255 $ENV{TZ} = $TZ;
4256 } else {
4257 delete $ENV{TZ};
4258 }
4259 }
4260
4261 sub tz_to_s_offset {
4262 my ($tz) = @_;
4263 $tz =~ s/(\d\d)$//;
4264 return ($1 * 60) + ($tz * 3600);
4265 }
4266
4267 sub get_author_info {
4268 my ($dest, $author, $t, $tz) = @_;
4269 $author =~ s/(?:^\s*|\s*$)//g;
4270 $dest->{a_raw} = $author;
4271 my $au;
4272 if ($::_authors) {
4273 $au = $rusers{$author} || undef;
4274 }
4275 if (!$au) {
4276 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4277 }
4278 $dest->{t} = $t;
4279 $dest->{tz} = $tz;
4280 $dest->{a} = $au;
4281 $dest->{t_utc} = parse_git_date($t, $tz);
4282 }
4283
4284 sub process_commit {
4285 my ($c, $r_min, $r_max, $defer) = @_;
4286 if (defined $r_min && defined $r_max) {
4287 if ($r_min == $c->{r} && $r_min == $r_max) {
4288 show_commit($c);
4289 return 0;
4290 }
4291 return 1 if $r_min == $r_max;
4292 if ($r_min < $r_max) {
4293 # we need to reverse the print order
4294 return 0 if (defined $limit && --$limit < 0);
4295 push @$defer, $c;
4296 return 1;
4297 }
4298 if ($r_min != $r_max) {
4299 return 1 if ($r_min < $c->{r});
4300 return 1 if ($r_max > $c->{r});
4301 }
4302 }
4303 return 0 if (defined $limit && --$limit < 0);
4304 show_commit($c);
4305 return 1;
4306 }
4307
4308 sub show_commit {
4309 my $c = shift;
4310 if ($oneline) {
4311 my $x = "\n";
4312 if (my $l = $c->{l}) {
4313 while ($l->[0] =~ /^\s*$/) { shift @$l }
4314 $x = $l->[0];
4315 }
4316 $l_fmt ||= 'A' . length($c->{r});
4317 print 'r',pack($l_fmt, $c->{r}),' | ';
4318 print "$c->{c} | " if $show_commit;
4319 print $x;
4320 } else {
4321 show_commit_normal($c);
4322 }
4323 }
4324
4325 sub show_commit_changed_paths {
4326 my ($c) = @_;
4327 return unless $c->{changed};
4328 print "Changed paths:\n", @{$c->{changed}};
4329 }
4330
4331 sub show_commit_normal {
4332 my ($c) = @_;
4333 print commit_log_separator, "r$c->{r} | ";
4334 print "$c->{c} | " if $show_commit;
4335 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4336 my $nr_line = 0;
4337
4338 if (my $l = $c->{l}) {
4339 while ($l->[$#$l] eq "\n" && $#$l > 0
4340 && $l->[($#$l - 1)] eq "\n") {
4341 pop @$l;
4342 }
4343 $nr_line = scalar @$l;
4344 if (!$nr_line) {
4345 print "1 line\n\n\n";
4346 } else {
4347 if ($nr_line == 1) {
4348 $nr_line = '1 line';
4349 } else {
4350 $nr_line .= ' lines';
4351 }
4352 print $nr_line, "\n";
4353 show_commit_changed_paths($c);
4354 print "\n";
4355 print $_ foreach @$l;
4356 }
4357 } else {
4358 print "1 line\n";
4359 show_commit_changed_paths($c);
4360 print "\n";
4361
4362 }
4363 foreach my $x (qw/raw stat diff/) {
4364 if ($c->{$x}) {
4365 print "\n";
4366 print $_ foreach @{$c->{$x}}
4367 }
4368 }
4369 }
4370
4371 sub cmd_show_log {
4372 my (@args) = @_;
4373 my ($r_min, $r_max);
4374 my $r_last = -1; # prevent dupes
4375 set_local_timezone();
4376 if (defined $::_revision) {
4377 if ($::_revision =~ /^(\d+):(\d+)$/) {
4378 ($r_min, $r_max) = ($1, $2);
4379 } elsif ($::_revision =~ /^\d+$/) {
4380 $r_min = $r_max = $::_revision;
4381 } else {
4382 ::fatal "-r$::_revision is not supported, use ",
4383 "standard 'git log' arguments instead";
4384 }
4385 }
4386
4387 config_pager();
4388 @args = git_svn_log_cmd($r_min, $r_max, @args);
4389 if (!@args) {
4390 print commit_log_separator unless $incremental || $oneline;
4391 return;
4392 }
4393 my $log = command_output_pipe(@args);
4394 run_pager();
4395 my (@k, $c, $d, $stat);
4396 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4397 while (<$log>) {
4398 if (/^${esc_color}commit -?($::sha1_short)/o) {
4399 my $cmt = $1;
4400 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4401 $r_last = $c->{r};
4402 process_commit($c, $r_min, $r_max, \@k) or
4403 goto out;
4404 }
4405 $d = undef;
4406 $c = { c => $cmt };
4407 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4408 get_author_info($c, $1, $2, $3);
4409 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4410 # ignore
4411 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4412 push @{$c->{raw}}, $_;
4413 } elsif (/^${esc_color}[ACRMDT]\t/) {
4414 # we could add $SVN->{svn_path} here, but that requires
4415 # remote access at the moment (repo_path_split)...
4416 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4417 push @{$c->{changed}}, $_;
4418 } elsif (/^${esc_color}diff /o) {
4419 $d = 1;
4420 push @{$c->{diff}}, $_;
4421 } elsif ($d) {
4422 push @{$c->{diff}}, $_;
4423 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4424 $esc_color*[\+\-]*$esc_color$/x) {
4425 $stat = 1;
4426 push @{$c->{stat}}, $_;
4427 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4428 push @{$c->{stat}}, $_;
4429 $stat = undef;
4430 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4431 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4432 } elsif (s/^${esc_color} //o) {
4433 push @{$c->{l}}, $_;
4434 }
4435 }
4436 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4437 $r_last = $c->{r};
4438 process_commit($c, $r_min, $r_max, \@k);
4439 }
4440 if (@k) {
4441 ($r_min, $r_max) = ($r_max, $r_min);
4442 process_commit($_, $r_min, $r_max) foreach reverse @k;
4443 }
4444 out:
4445 close $log;
4446 print commit_log_separator unless $incremental || $oneline;
4447 }
4448
4449 package Git::SVN::Migration;
4450 # these version numbers do NOT correspond to actual version numbers
4451 # of git nor git-svn. They are just relative.
4452 #
4453 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4454 #
4455 # v1 layout: .git/$id/info/url, refs/remotes/$id
4456 #
4457 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4458 #
4459 # v3 layout: .git/svn/$id, refs/remotes/$id
4460 # - info/url may remain for backwards compatibility
4461 # - this is what we migrate up to this layout automatically,
4462 # - this will be used by git svn init on single branches
4463 # v3.1 layout (auto migrated):
4464 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4465 # for backwards compatibility
4466 #
4467 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4468 # - this is only created for newly multi-init-ed
4469 # repositories. Similar in spirit to the
4470 # --use-separate-remotes option in git-clone (now default)
4471 # - we do not automatically migrate to this (following
4472 # the example set by core git)
4473 #
4474 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4475 # - newer, more-efficient format that uses 24-bytes per record
4476 # with no filler space.
4477 # - use xxd -c24 < .rev_map.$UUID to view and debug
4478 # - This is a one-way migration, repositories updated to the
4479 # new format will not be able to use old git-svn without
4480 # rebuilding the .rev_db. Rebuilding the rev_db is not
4481 # possible if noMetadata or useSvmProps are set; but should
4482 # be no problem for users that use the (sensible) defaults.
4483 use strict;
4484 use warnings;
4485 use Carp qw/croak/;
4486 use File::Path qw/mkpath/;
4487 use File::Basename qw/dirname basename/;
4488 use vars qw/$_minimize/;
4489
4490 sub migrate_from_v0 {
4491 my $git_dir = $ENV{GIT_DIR};
4492 return undef unless -d $git_dir;
4493 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4494 my $migrated = 0;
4495 while (<$fh>) {
4496 chomp;
4497 my ($id, $orig_ref) = ($_, $_);
4498 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4499 next unless -f "$git_dir/$id/info/url";
4500 my $new_ref = "refs/remotes/$id";
4501 if (::verify_ref("$new_ref^0")) {
4502 print STDERR "W: $orig_ref is probably an old ",
4503 "branch used by an ancient version of ",
4504 "git-svn.\n",
4505 "However, $new_ref also exists.\n",
4506 "We will not be able ",
4507 "to use this branch until this ",
4508 "ambiguity is resolved.\n";
4509 next;
4510 }
4511 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4512 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4513 command_noisy('update-ref', $new_ref, $orig_ref);
4514 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4515 $migrated++;
4516 }
4517 command_close_pipe($fh, $ctx);
4518 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4519 $migrated;
4520 }
4521
4522 sub migrate_from_v1 {
4523 my $git_dir = $ENV{GIT_DIR};
4524 my $migrated = 0;
4525 return $migrated unless -d $git_dir;
4526 my $svn_dir = "$git_dir/svn";
4527
4528 # just in case somebody used 'svn' as their $id at some point...
4529 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4530
4531 print STDERR "Migrating from a git-svn v1 layout...\n";
4532 mkpath([$svn_dir]);
4533 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4534 "$svn_dir\n\t(required for this version ",
4535 "($::VERSION) of git-svn) does not. exist\n";
4536 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4537 while (<$fh>) {
4538 my $x = $_;
4539 next unless $x =~ s#^refs/remotes/##;
4540 chomp $x;
4541 next unless -f "$git_dir/$x/info/url";
4542 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4543 next unless $u;
4544 my $dn = dirname("$git_dir/svn/$x");
4545 mkpath([$dn]) unless -d $dn;
4546 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4547 mkpath(["$git_dir/svn/svn"]);
4548 print STDERR " - $git_dir/$x/info => ",
4549 "$git_dir/svn/$x/info\n";
4550 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4551 croak "$!: $x";
4552 # don't worry too much about these, they probably
4553 # don't exist with repos this old (save for index,
4554 # and we can easily regenerate that)
4555 foreach my $f (qw/unhandled.log index .rev_db/) {
4556 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4557 }
4558 } else {
4559 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4560 rename "$git_dir/$x", "$git_dir/svn/$x" or
4561 croak "$!: $x";
4562 }
4563 $migrated++;
4564 }
4565 command_close_pipe($fh, $ctx);
4566 print STDERR "Done migrating from a git-svn v1 layout\n";
4567 $migrated;
4568 }
4569
4570 sub read_old_urls {
4571 my ($l_map, $pfx, $path) = @_;
4572 my @dir;
4573 foreach (<$path/*>) {
4574 if (-r "$_/info/url") {
4575 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4576 my $ref_id = $pfx . basename $_;
4577 my $url = ::file_to_s("$_/info/url");
4578 $l_map->{$ref_id} = $url;
4579 } elsif (-d $_) {
4580 push @dir, $_;
4581 }
4582 }
4583 foreach (@dir) {
4584 my $x = $_;
4585 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4586 read_old_urls($l_map, $x, $_);
4587 }
4588 }
4589
4590 sub migrate_from_v2 {
4591 my @cfg = command(qw/config -l/);
4592 return if grep /^svn-remote\..+\.url=/, @cfg;
4593 my %l_map;
4594 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4595 my $migrated = 0;
4596
4597 foreach my $ref_id (sort keys %l_map) {
4598 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4599 if ($@) {
4600 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4601 }
4602 $migrated++;
4603 }
4604 $migrated;
4605 }
4606
4607 sub minimize_connections {
4608 my $r = Git::SVN::read_all_remotes();
4609 my $new_urls = {};
4610 my $root_repos = {};
4611 foreach my $repo_id (keys %$r) {
4612 my $url = $r->{$repo_id}->{url} or next;
4613 my $fetch = $r->{$repo_id}->{fetch} or next;
4614 my $ra = Git::SVN::Ra->new($url);
4615
4616 # skip existing cases where we already connect to the root
4617 if (($ra->{url} eq $ra->{repos_root}) ||
4618 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4619 $repo_id)) {
4620 $root_repos->{$ra->{url}} = $repo_id;
4621 next;
4622 }
4623
4624 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4625 my $root_path = $ra->{url};
4626 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4627 foreach my $path (keys %$fetch) {
4628 my $ref_id = $fetch->{$path};
4629 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4630
4631 # make sure we can read when connecting to
4632 # a higher level of a repository
4633 my ($last_rev, undef) = $gs->last_rev_commit;
4634 if (!defined $last_rev) {
4635 $last_rev = eval {
4636 $root_ra->get_latest_revnum;
4637 };
4638 next if $@;
4639 }
4640 my $new = $root_path;
4641 $new .= length $path ? "/$path" : '';
4642 eval {
4643 $root_ra->get_log([$new], $last_rev, $last_rev,
4644 0, 0, 1, sub { });
4645 };
4646 next if $@;
4647 $new_urls->{$ra->{repos_root}}->{$new} =
4648 { ref_id => $ref_id,
4649 old_repo_id => $repo_id,
4650 old_path => $path };
4651 }
4652 }
4653
4654 my @emptied;
4655 foreach my $url (keys %$new_urls) {
4656 # see if we can re-use an existing [svn-remote "repo_id"]
4657 # instead of creating a(n ugly) new section:
4658 my $repo_id = $root_repos->{$url} ||
4659 Git::SVN::sanitize_remote_name($url);
4660
4661 my $fetch = $new_urls->{$url};
4662 foreach my $path (keys %$fetch) {
4663 my $x = $fetch->{$path};
4664 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4665 my $pfx = "svn-remote.$x->{old_repo_id}";
4666
4667 my $old_fetch = quotemeta("$x->{old_path}:".
4668 "refs/remotes/$x->{ref_id}");
4669 command_noisy(qw/config --unset/,
4670 "$pfx.fetch", '^'. $old_fetch . '$');
4671 delete $r->{$x->{old_repo_id}}->
4672 {fetch}->{$x->{old_path}};
4673 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4674 command_noisy(qw/config --unset/,
4675 "$pfx.url");
4676 push @emptied, $x->{old_repo_id}
4677 }
4678 }
4679 }
4680 if (@emptied) {
4681 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4682 "$ENV{GIT_DIR}/config";
4683 print STDERR <<EOF;
4684 The following [svn-remote] sections in your config file ($file) are empty
4685 and can be safely removed:
4686 EOF
4687 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4688 }
4689 }
4690
4691 sub migration_check {
4692 migrate_from_v0();
4693 migrate_from_v1();
4694 migrate_from_v2();
4695 minimize_connections() if $_minimize;
4696 }
4697
4698 package Git::IndexInfo;
4699 use strict;
4700 use warnings;
4701 use Git qw/command_input_pipe command_close_pipe/;
4702
4703 sub new {
4704 my ($class) = @_;
4705 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4706 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4707 }
4708
4709 sub remove {
4710 my ($self, $path) = @_;
4711 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4712 return ++$self->{nr};
4713 }
4714 undef;
4715 }
4716
4717 sub update {
4718 my ($self, $mode, $hash, $path) = @_;
4719 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4720 return ++$self->{nr};
4721 }
4722 undef;
4723 }
4724
4725 sub DESTROY {
4726 my ($self) = @_;
4727 command_close_pipe($self->{gui}, $self->{ctx});
4728 }
4729
4730 package Git::SVN::GlobSpec;
4731 use strict;
4732 use warnings;
4733
4734 sub new {
4735 my ($class, $glob) = @_;
4736 my $re = $glob;
4737 $re =~ s!/+$!!g; # no need for trailing slashes
4738 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4739 my ($left, $right) = ($1, $2);
4740 if ($nr > 1) {
4741 die "Only one '*' wildcard expansion ",
4742 "is supported (got $nr): '$glob'\n";
4743 } elsif ($nr == 0) {
4744 die "One '*' is needed for glob: '$glob'\n";
4745 }
4746 $re = quotemeta($left) . $re . quotemeta($right);
4747 if (length $left && !($left =~ s!/+$!!g)) {
4748 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4749 }
4750 if (length $right && !($right =~ s!^/+!!g)) {
4751 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4752 }
4753 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4754 bless { left => $left, right => $right, left_regex => $left_re,
4755 regex => qr/$re/, glob => $glob }, $class;
4756 }
4757
4758 sub full_path {
4759 my ($self, $path) = @_;
4760 return (length $self->{left} ? "$self->{left}/" : '') .
4761 $path . (length $self->{right} ? "/$self->{right}" : '');
4762 }
4763
4764 __END__
4765
4766 Data structures:
4767
4768
4769 $remotes = { # returned by read_all_remotes()
4770 'svn' => {
4771 # svn-remote.svn.url=https://svn.musicpd.org
4772 url => 'https://svn.musicpd.org',
4773 # svn-remote.svn.fetch=mpd/trunk:trunk
4774 fetch => {
4775 'mpd/trunk' => 'trunk',
4776 },
4777 # svn-remote.svn.tags=mpd/tags/*:tags/*
4778 tags => {
4779 path => {
4780 left => 'mpd/tags',
4781 right => '',
4782 regex => qr!mpd/tags/([^/]+)$!,
4783 glob => 'tags/*',
4784 },
4785 ref => {
4786 left => 'tags',
4787 right => '',
4788 regex => qr!tags/([^/]+)$!,
4789 glob => 'tags/*',
4790 },
4791 }
4792 }
4793 };
4794
4795 $log_entry hashref as returned by libsvn_log_entry()
4796 {
4797 log => 'whitespace-formatted log entry
4798 ', # trailing newline is preserved
4799 revision => '8', # integer
4800 date => '2004-02-24T17:01:44.108345Z', # commit date
4801 author => 'committer name'
4802 };
4803
4804
4805 # this is generated by generate_diff();
4806 @mods = array of diff-index line hashes, each element represents one line
4807 of diff-index output
4808
4809 diff-index line ($m hash)
4810 {
4811 mode_a => first column of diff-index output, no leading ':',
4812 mode_b => second column of diff-index output,
4813 sha1_b => sha1sum of the final blob,
4814 chg => change type [MCRADT],
4815 file_a => original file name of a file (iff chg is 'C' or 'R')
4816 file_b => new/current file name of a file (any chg)
4817 }
4818 ;
4819
4820 # retval of read_url_paths{,_all}();
4821 $l_map = {
4822 # repository root url
4823 'https://svn.musicpd.org' => {
4824 # repository path # GIT_SVN_ID
4825 'mpd/trunk' => 'trunk',
4826 'mpd/tags/0.11.5' => 'tags/0.11.5',
4827 },
4828 }
4829
4830 Notes:
4831 I don't trust the each() function on unless I created %hash myself
4832 because the internal iterator may not have started at base.
Haiku port