configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specied by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 # This also implies BLK_SHA1.
 245 #
 246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 247 # /foo/bar/include and /foo/bar/lib directories.
 248 AC_ARG_WITH(openssl,
 249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 250 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 251 GIT_PARSE_WITH([openssl]))
 252
 253 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 254 # able to use Perl-compatible regular expressions.
 255 #
 256 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
 257 # /foo/bar/include and /foo/bar/lib directories.
 258 #
 259 AC_ARG_WITH(libpcre,
 260 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
 261 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 262     if test "$withval" = "no"; then
 263         USE_LIBPCRE=
 264     elif test "$withval" = "yes"; then
 265         USE_LIBPCRE=YesPlease
 266     else
 267         USE_LIBPCRE=YesPlease
 268         LIBPCREDIR=$withval
 269         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 270         dnl USE_LIBPCRE can still be modified below, so don't substitute
 271         dnl it yet.
 272         GIT_CONF_SUBST([LIBPCREDIR])
 273     fi)
 274 #
 275 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 276 AC_FUNC_ALLOCA
 277 case $ac_cv_working_alloca_h in
 278     yes)    HAVE_ALLOCA_H=YesPlease;;
 279     *)      HAVE_ALLOCA_H='';;
 280 esac
 281 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 282 #
 283 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 284 # git-http-push are not built, and you cannot use http:// and https://
 285 # transports.
 286 #
 287 # Define CURLDIR=/foo/bar if your curl header and library files are in
 288 # /foo/bar/include and /foo/bar/lib directories.
 289 AC_ARG_WITH(curl,
 290 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 291 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 292 GIT_PARSE_WITH(curl))
 293 #
 294 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 295 # not built, and you cannot push using http:// and https:// transports.
 296 #
 297 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 298 # /foo/bar/include and /foo/bar/lib directories.
 299 AC_ARG_WITH(expat,
 300 AS_HELP_STRING([--with-expat],
 301 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 302 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 303 GIT_PARSE_WITH(expat))
 304 #
 305 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 306 # installed in /sw, but don't want GIT to link against any libraries
 307 # installed there.  If defined you may specify your own (or Fink's)
 308 # include directories and library directories by defining CFLAGS
 309 # and LDFLAGS appropriately.
 310 #
 311 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 312 # have DarwinPorts installed in /opt/local, but don't want GIT to
 313 # link against any libraries installed there.  If defined you may
 314 # specify your own (or DarwinPort's) include directories and
 315 # library directories by defining CFLAGS and LDFLAGS appropriately.
 316 #
 317 # Define NO_MMAP if you want to avoid mmap.
 318 #
 319 # Define NO_ICONV if your libc does not properly support iconv.
 320 AC_ARG_WITH(iconv,
 321 AS_HELP_STRING([--without-iconv],
 322 [if your architecture doesn't properly support iconv])
 323 AS_HELP_STRING([--with-iconv=PATH],
 324 [PATH is prefix for libiconv library and headers])
 325 AS_HELP_STRING([],
 326 [used only if you need linking with libiconv]),
 327 GIT_PARSE_WITH(iconv))
 328
 329 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 330 #
 331 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 332 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 333 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 334 # randomly break unless your underlying filesystem supports those sub-second
 335 # times (my ext3 doesn't).
 336 #
 337 # Define USE_STDEV below if you want git to care about the underlying device
 338 # change being considered an inode change from the update-index perspective.
 339
 340 #
 341 # Allow user to set ETC_GITCONFIG variable
 342 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 343                         Use VALUE instead of /etc/gitconfig as the
 344                         global git configuration file.
 345                         If VALUE is not fully qualified it will be interpreted
 346                         as a path relative to the computed prefix at runtime.)
 347
 348 #
 349 # Allow user to set ETC_GITATTRIBUTES variable
 350 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 351                         Use VALUE instead of /etc/gitattributes as the
 352                         global git attributes file.
 353                         If VALUE is not fully qualified it will be interpreted
 354                         as a path relative to the computed prefix at runtime.)
 355
 356 #
 357 # Allow user to set the default pager
 358 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 359                         Use VALUE as the fall-back pager instead of 'less'.
 360                         This is used by things like 'git log' when the user
 361                         does not specify a pager to use through alternate
 362                         methods. eg: /usr/bin/pager)
 363 #
 364 # Allow user to set the default editor
 365 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 366                         Use VALUE as the fall-back editor instead of 'vi'.
 367                         This is used by things like 'git commit' when the user
 368                         does not specify a preferred editor through other
 369                         methods. eg: /usr/bin/editor)
 370
 371 #
 372 # Define SHELL_PATH to provide path to shell.
 373 GIT_ARG_SET_PATH(shell)
 374 #
 375 # Define PERL_PATH to provide path to Perl.
 376 GIT_ARG_SET_PATH(perl)
 377 #
 378 # Define PYTHON_PATH to provide path to Python.
 379 GIT_ARG_SET_PATH(python, allow-without)
 380 #
 381 # Define ZLIB_PATH to provide path to zlib.
 382 GIT_ARG_SET_PATH(zlib)
 383 #
 384 # Declare the with-tcltk/without-tcltk options.
 385 AC_ARG_WITH(tcltk,
 386 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 387 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 388 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 389 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 390 GIT_PARSE_WITH(tcltk))
 391 #
 392
 393
 394 ## Checks for programs.
 395 AC_MSG_NOTICE([CHECKS for programs])
 396 #
 397 AC_PROG_CC([cc gcc])
 398 AC_C_INLINE
 399 case $ac_cv_c_inline in
 400   inline | yes | no) INLINE='';;
 401   *)                 INLINE=$ac_cv_c_inline ;;
 402 esac
 403 GIT_CONF_SUBST([INLINE])
 404
 405 # which switch to pass runtime path to dynamic libraries to the linker
 406 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 407    SAVE_LDFLAGS="${LDFLAGS}"
 408    LDFLAGS="${SAVE_LDFLAGS} -R /"
 409    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 410    LDFLAGS="${SAVE_LDFLAGS}"
 411 ])
 412 if test "$git_cv_ld_dashr" = "yes"; then
 413    CC_LD_DYNPATH=-R
 414 else
 415    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 416       SAVE_LDFLAGS="${LDFLAGS}"
 417       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 418       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 419       LDFLAGS="${SAVE_LDFLAGS}"
 420    ])
 421    if test "$git_cv_ld_wl_rpath" = "yes"; then
 422       CC_LD_DYNPATH=-Wl,-rpath,
 423    else
 424       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 425          SAVE_LDFLAGS="${LDFLAGS}"
 426          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 427          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 428          LDFLAGS="${SAVE_LDFLAGS}"
 429       ])
 430       if test "$git_cv_ld_rpath" = "yes"; then
 431          CC_LD_DYNPATH=-rpath
 432       else
 433          CC_LD_DYNPATH=
 434          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 435       fi
 436    fi
 437 fi
 438 GIT_CONF_SUBST([CC_LD_DYNPATH])
 439 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 440 AC_CHECK_TOOLS(AR, [gar ar], :)
 441 AC_CHECK_PROGS(TAR, [gtar tar])
 442 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 443 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 444 # or will be empty otherwise.
 445 if test -n "$NO_TCLTK"; then
 446   TCLTK_PATH=
 447 else
 448   if test "$with_tcltk" = ""; then
 449   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 450     TCLTK_PATH=wish
 451   elif test "$with_tcltk" = "yes"; then
 452   # Tcl/Tk check requested.
 453     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 454   else
 455     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 456     TCLTK_PATH="$with_tcltk"
 457   fi
 458 fi
 459 GIT_CONF_SUBST([TCLTK_PATH])
 460 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 461 if test -n "$ASCIIDOC"; then
 462         AC_MSG_CHECKING([for asciidoc version])
 463         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 464         case "${asciidoc_version}" in
 465         asciidoc' '8*)
 466                 AC_MSG_RESULT([${asciidoc_version}])
 467                 ;;
 468         *)
 469                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 470                 ;;
 471         esac
 472 fi
 473
 474
 475 ## Checks for libraries.
 476 AC_MSG_NOTICE([CHECKS for libraries])
 477 #
 478 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 479 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 480
 481 GIT_STASH_FLAGS($OPENSSLDIR)
 482
 483 AC_CHECK_LIB([crypto], [SHA1_Init],
 484 [NEEDS_SSL_WITH_CRYPTO=],
 485 [AC_CHECK_LIB([ssl], [SHA1_Init],
 486  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 487  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 488
 489 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 490
 491 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 492 GIT_CONF_SUBST([NO_OPENSSL])
 493
 494 #
 495 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 496 # able to use Perl-compatible regular expressions.
 497 #
 498
 499 if test -n "$USE_LIBPCRE"; then
 500
 501 GIT_STASH_FLAGS($LIBPCREDIR)
 502
 503 AC_CHECK_LIB([pcre], [pcre_version],
 504 [USE_LIBPCRE=YesPlease],
 505 [USE_LIBPCRE=])
 506
 507 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 508
 509 GIT_CONF_SUBST([USE_LIBPCRE])
 510
 511 fi
 512
 513 #
 514 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 515 # git-http-push are not built, and you cannot use http:// and https://
 516 # transports.
 517
 518 GIT_STASH_FLAGS($CURLDIR)
 519
 520 AC_CHECK_LIB([curl], [curl_global_init],
 521 [NO_CURL=],
 522 [NO_CURL=YesPlease])
 523
 524 GIT_UNSTASH_FLAGS($CURLDIR)
 525
 526 GIT_CONF_SUBST([NO_CURL])
 527
 528 if test -z "$NO_CURL"; then
 529
 530 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 531 [curl-config],
 532 [no])
 533
 534 if test $CURL_CONFIG != no; then
 535     GIT_CONF_SUBST([CURL_CONFIG])
 536 fi
 537
 538 fi
 539
 540
 541 #
 542 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 543 # not built, and you cannot push using http:// and https:// transports.
 544
 545 GIT_STASH_FLAGS($EXPATDIR)
 546
 547 AC_CHECK_LIB([expat], [XML_ParserCreate],
 548 [NO_EXPAT=],
 549 [NO_EXPAT=YesPlease])
 550
 551 GIT_UNSTASH_FLAGS($EXPATDIR)
 552
 553 GIT_CONF_SUBST([NO_EXPAT])
 554
 555 #
 556 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 557 # some Solaris installations).
 558 # Define NO_ICONV if neither libc nor libiconv support iconv.
 559
 560 if test -z "$NO_ICONV"; then
 561
 562 GIT_STASH_FLAGS($ICONVDIR)
 563
 564 AC_DEFUN([ICONVTEST_SRC],
 565 [AC_LANG_PROGRAM([#include <iconv.h>],
 566  [iconv_open("", "");])])
 567
 568 if test -n "$ICONVDIR"; then
 569    lib_order="-liconv -lc"
 570 else
 571    lib_order="-lc -liconv"
 572 fi
 573
 574 NO_ICONV=YesPlease
 575
 576 for l in $lib_order; do
 577     if test "$l" = "-liconv"; then
 578        NEEDS_LIBICONV=YesPlease
 579     else
 580        NEEDS_LIBICONV=
 581     fi
 582
 583     old_LIBS="$LIBS"
 584     LIBS="$LIBS $l"
 585     AC_MSG_CHECKING([for iconv in $l])
 586     AC_LINK_IFELSE([ICONVTEST_SRC],
 587         [AC_MSG_RESULT([yes])
 588         NO_ICONV=
 589         break],
 590         [AC_MSG_RESULT([no])])
 591     LIBS="$old_LIBS"
 592 done
 593
 594 #in case of break
 595 LIBS="$old_LIBS"
 596
 597 GIT_UNSTASH_FLAGS($ICONVDIR)
 598
 599 GIT_CONF_SUBST([NEEDS_LIBICONV])
 600 GIT_CONF_SUBST([NO_ICONV])
 601
 602 if test -n "$NO_ICONV"; then
 603     NEEDS_LIBICONV=
 604 fi
 605
 606 fi
 607
 608 #
 609 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 610
 611 GIT_STASH_FLAGS($ZLIB_PATH)
 612
 613 AC_DEFUN([ZLIBTEST_SRC], [
 614 AC_LANG_PROGRAM([#include <zlib.h>],
 615  [deflateBound(0, 0);])])
 616 AC_MSG_CHECKING([for deflateBound in -lz])
 617 old_LIBS="$LIBS"
 618 LIBS="$LIBS -lz"
 619 AC_LINK_IFELSE([ZLIBTEST_SRC],
 620         [AC_MSG_RESULT([yes])],
 621         [AC_MSG_RESULT([no])
 622         NO_DEFLATE_BOUND=yes])
 623 LIBS="$old_LIBS"
 624
 625 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 626
 627 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 628
 629 #
 630 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 631 # Patrick Mauritz).
 632 AC_CHECK_LIB([c], [socket],
 633 [NEEDS_SOCKET=],
 634 [NEEDS_SOCKET=YesPlease])
 635 GIT_CONF_SUBST([NEEDS_SOCKET])
 636 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 637
 638 #
 639 # The next few tests will define NEEDS_RESOLV if linking with
 640 # libresolv provides some of the functions we would normally get
 641 # from libc.
 642 NEEDS_RESOLV=
 643 #
 644 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 645 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 646 NO_INET_NTOP=
 647 AC_CHECK_FUNC([inet_ntop],
 648     [],
 649     [AC_CHECK_LIB([resolv], [inet_ntop],
 650         [NEEDS_RESOLV=YesPlease],
 651         [NO_INET_NTOP=YesPlease])
 652 ])
 653 GIT_CONF_SUBST([NO_INET_NTOP])
 654 #
 655 # Define NO_INET_PTON if linking with -lresolv is not enough.
 656 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 657 NO_INET_PTON=
 658 AC_CHECK_FUNC([inet_pton],
 659     [],
 660     [AC_CHECK_LIB([resolv], [inet_pton],
 661         [NEEDS_RESOLV=YesPlease],
 662         [NO_INET_PTON=YesPlease])
 663 ])
 664 GIT_CONF_SUBST([NO_INET_PTON])
 665 #
 666 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 667 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 668 NO_HSTRERROR=
 669 AC_CHECK_FUNC([hstrerror],
 670     [],
 671     [AC_CHECK_LIB([resolv], [hstrerror],
 672         [NEEDS_RESOLV=YesPlease],
 673         [NO_HSTRERROR=YesPlease])
 674 ])
 675 GIT_CONF_SUBST([NO_HSTRERROR])
 676
 677 dnl This must go after all the possible places for its initialization,
 678 dnl in the AC_CHECK_FUNC invocations above.
 679 GIT_CONF_SUBST([NEEDS_RESOLV])
 680 #
 681 # If any of the above tests determined that -lresolv is needed at
 682 # build-time, also set it here for remaining configure-time checks.
 683 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 684
 685 AC_CHECK_LIB([c], [basename],
 686 [NEEDS_LIBGEN=],
 687 [NEEDS_LIBGEN=YesPlease])
 688 GIT_CONF_SUBST([NEEDS_LIBGEN])
 689 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 690
 691 AC_CHECK_LIB([c], [gettext],
 692 [LIBC_CONTAINS_LIBINTL=YesPlease],
 693 [LIBC_CONTAINS_LIBINTL=])
 694 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 695
 696 #
 697 # Define NO_GETTEXT if you don't want Git output to be translated.
 698 # A translated Git requires GNU libintl or another gettext implementation
 699 AC_CHECK_HEADER([libintl.h],
 700 [NO_GETTEXT=],
 701 [NO_GETTEXT=YesPlease])
 702 GIT_CONF_SUBST([NO_GETTEXT])
 703
 704 if test -z "$NO_GETTEXT"; then
 705     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 706 fi
 707
 708 ## Checks for header files.
 709 AC_MSG_NOTICE([CHECKS for header files])
 710 #
 711 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 712 AC_CHECK_HEADER([sys/select.h],
 713 [NO_SYS_SELECT_H=],
 714 [NO_SYS_SELECT_H=UnfortunatelyYes])
 715 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 716 #
 717 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 718 AC_CHECK_HEADER([sys/poll.h],
 719 [NO_SYS_POLL_H=],
 720 [NO_SYS_POLL_H=UnfortunatelyYes])
 721 GIT_CONF_SUBST([NO_SYS_POLL_H])
 722 #
 723 # Define NO_INTTYPES_H if you don't have inttypes.h
 724 AC_CHECK_HEADER([inttypes.h],
 725 [NO_INTTYPES_H=],
 726 [NO_INTTYPES_H=UnfortunatelyYes])
 727 GIT_CONF_SUBST([NO_INTTYPES_H])
 728 #
 729 # Define OLD_ICONV if your library has an old iconv(), where the second
 730 # (input buffer pointer) parameter is declared with type (const char **).
 731 AC_DEFUN([OLDICONVTEST_SRC], [
 732 AC_LANG_PROGRAM([[
 733 #include <iconv.h>
 734
 735 extern size_t iconv(iconv_t cd,
 736                     char **inbuf, size_t *inbytesleft,
 737                     char **outbuf, size_t *outbytesleft);
 738 ]], [])])
 739
 740 GIT_STASH_FLAGS($ICONVDIR)
 741
 742 AC_MSG_CHECKING([for old iconv()])
 743 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 744         [AC_MSG_RESULT([no])],
 745         [AC_MSG_RESULT([yes])
 746         OLD_ICONV=UnfortunatelyYes])
 747
 748 GIT_UNSTASH_FLAGS($ICONVDIR)
 749
 750 GIT_CONF_SUBST([OLD_ICONV])
 751
 752 ## Checks for typedefs, structures, and compiler characteristics.
 753 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 754 #
 755 TYPE_SOCKLEN_T
 756 case $ac_cv_type_socklen_t in
 757   yes)  SOCKLEN_T='';;
 758   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 759 esac
 760 GIT_CONF_SUBST([SOCKLEN_T])
 761
 762 #
 763 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 764 AC_CHECK_TYPES([struct itimerval],
 765 [NO_STRUCT_ITIMERVAL=],
 766 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 767 [#include <sys/time.h>])
 768 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 769 #
 770 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 771 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 772 # stat.st_mtimespec.tv_nsec exists.
 773 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 774 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 775 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 776         USE_ST_TIMESPEC=YesPlease
 777         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 778 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 779         NO_NSEC=YesPlease
 780         GIT_CONF_SUBST([NO_NSEC])
 781 fi
 782 #
 783 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 784 AC_CHECK_MEMBER(struct dirent.d_ino,
 785 [NO_D_INO_IN_DIRENT=],
 786 [NO_D_INO_IN_DIRENT=YesPlease],
 787 [#include <dirent.h>])
 788 GIT_CONF_SUBST([NO_D_INO_IN_DIRENT])
 789 #
 790 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 791 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 792 AC_CHECK_MEMBER(struct dirent.d_type,
 793 [NO_D_TYPE_IN_DIRENT=],
 794 [NO_D_TYPE_IN_DIRENT=YesPlease],
 795 [#include <dirent.h>])
 796 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 797 #
 798 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 799 # in the C library.
 800 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 801 [NO_GECOS_IN_PWENT=],
 802 [NO_GECOS_IN_PWENT=YesPlease],
 803 [#include <pwd.h>])
 804 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 805 #
 806 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 807 # sockaddr_storage.
 808 AC_CHECK_TYPE(struct sockaddr_storage,
 809 [NO_SOCKADDR_STORAGE=],
 810 [NO_SOCKADDR_STORAGE=YesPlease],[
 811 #include <sys/types.h>
 812 #include <sys/socket.h>
 813 ])
 814 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 815 #
 816 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 817 AC_CHECK_TYPE([struct addrinfo],[
 818  GIT_CHECK_FUNC([getaddrinfo],
 819   [NO_IPV6=],
 820   [NO_IPV6=YesPlease])
 821 ],[NO_IPV6=YesPlease],[
 822 #include <sys/types.h>
 823 #include <sys/socket.h>
 824 #include <netdb.h>
 825 ])
 826 GIT_CONF_SUBST([NO_IPV6])
 827 #
 828 # Define NO_REGEX if you have no or inferior regex support in your C library.
 829 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 830  [ac_cv_c_excellent_regex], [
 831 AC_EGREP_CPP(yippeeyeswehaveit,
 832         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 833 #include <regex.h>
 834 ],
 835 [#ifdef REG_STARTEND
 836 yippeeyeswehaveit
 837 #endif
 838 ]),
 839         [ac_cv_c_excellent_regex=yes],
 840         [ac_cv_c_excellent_regex=no])
 841 ])
 842 if test $ac_cv_c_excellent_regex = yes; then
 843         NO_REGEX=
 844 else
 845         NO_REGEX=YesPlease
 846 fi
 847 GIT_CONF_SUBST([NO_REGEX])
 848 #
 849 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 850 # when attempting to read from an fopen'ed directory.
 851 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 852  [ac_cv_fread_reads_directories],
 853 [
 854 AC_RUN_IFELSE(
 855         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 856                 [[char c;
 857                 FILE *f = fopen(".", "r");
 858                 return f && fread(&c, 1, 1, f)]])],
 859         [ac_cv_fread_reads_directories=no],
 860         [ac_cv_fread_reads_directories=yes])
 861 ])
 862 if test $ac_cv_fread_reads_directories = yes; then
 863         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 864 else
 865         FREAD_READS_DIRECTORIES=
 866 fi
 867 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 868 #
 869 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 870 # or vsnprintf() return -1 instead of number of characters which would
 871 # have been written to the final string if enough space had been available.
 872 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 873  [ac_cv_snprintf_returns_bogus],
 874 [
 875 AC_RUN_IFELSE(
 876         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 877                 #include "stdarg.h"
 878
 879                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 880                 {
 881                   int ret;
 882                   va_list ap;
 883                   va_start(ap, format);
 884                   ret = vsnprintf(str, maxsize, format, ap);
 885                   va_end(ap);
 886                   return ret;
 887                 }],
 888                 [[char buf[6];
 889                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 890                       || strcmp(buf, "12")) return 1;
 891                   if (snprintf(buf, 3, "%s", "12345") != 5
 892                       || strcmp(buf, "12")) return 1]])],
 893         [ac_cv_snprintf_returns_bogus=no],
 894         [ac_cv_snprintf_returns_bogus=yes])
 895 ])
 896 if test $ac_cv_snprintf_returns_bogus = yes; then
 897         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 898 else
 899         SNPRINTF_RETURNS_BOGUS=
 900 fi
 901 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
 902 #
 903 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
 904 # bits in mode values.
 905 AC_CACHE_CHECK([whether the platform uses typical file type bits],
 906  [ac_cv_sane_mode_bits], [
 907 AC_EGREP_CPP(yippeeyeswehaveit,
 908         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 909 [#if S_IFMT == 0170000 && \
 910         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
 911         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
 912         S_IFIFO == 0010000 && S_IFSOCK == 0140000
 913 yippeeyeswehaveit
 914 #endif
 915 ]),
 916         [ac_cv_sane_mode_bits=yes],
 917         [ac_cv_sane_mode_bits=no])
 918 ])
 919 if test $ac_cv_sane_mode_bits = yes; then
 920         NEEDS_MODE_TRANSLATION=
 921 else
 922         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
 923 fi
 924 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
 925
 926
 927 ## Checks for library functions.
 928 ## (in default C library and libraries checked by AC_CHECK_LIB)
 929 AC_MSG_NOTICE([CHECKS for library functions])
 930 #
 931 # Define NO_LIBGEN_H if you don't have libgen.h.
 932 AC_CHECK_HEADER([libgen.h],
 933 [NO_LIBGEN_H=],
 934 [NO_LIBGEN_H=YesPlease])
 935 GIT_CONF_SUBST([NO_LIBGEN_H])
 936 #
 937 # Define HAVE_PATHS_H if you have paths.h.
 938 AC_CHECK_HEADER([paths.h],
 939 [HAVE_PATHS_H=YesPlease],
 940 [HAVE_PATHS_H=])
 941 GIT_CONF_SUBST([HAVE_PATHS_H])
 942 #
 943 # Define HAVE_LIBCHARSET_H if have libcharset.h
 944 AC_CHECK_HEADER([libcharset.h],
 945 [HAVE_LIBCHARSET_H=YesPlease],
 946 [HAVE_LIBCHARSET_H=])
 947 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
 948 #
 949 # Define HAVE_STRINGS_H if you have strings.h
 950 AC_CHECK_HEADER([strings.h],
 951 [HAVE_STRINGS_H=YesPlease],
 952 [HAVE_STRINGS_H=])
 953 GIT_CONF_SUBST([HAVE_STRINGS_H])
 954 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
 955 # and libcharset does
 956 CHARSET_LIB=
 957 AC_CHECK_LIB([iconv], [locale_charset],
 958        [CHARSET_LIB=-liconv],
 959        [AC_CHECK_LIB([charset], [locale_charset],
 960                      [CHARSET_LIB=-lcharset])])
 961 GIT_CONF_SUBST([CHARSET_LIB])
 962 #
 963 # Define NO_HMAC_CTX_CLEANUP=YesPlease if HMAC_CTX_cleanup is missing.
 964 AC_CHECK_LIB([crypto], [HMAC_CTX_cleanup],
 965         [], [GIT_CONF_SUBST([NO_HMAC_CTX_CLEANUP], [YesPlease])])
 966 #
 967 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
 968 GIT_CHECK_FUNC(clock_gettime,
 969         [HAVE_CLOCK_GETTIME=YesPlease],
 970         [HAVE_CLOCK_GETTIME=])
 971 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
 972
 973 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
 974 AC_LANG_PROGRAM([[
 975 #include <time.h>
 976 clockid_t id = CLOCK_MONOTONIC;
 977 ]])])
 978
 979 #
 980 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
 981 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 982 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
 983         [AC_MSG_RESULT([yes])
 984         HAVE_CLOCK_MONOTONIC=YesPlease],
 985         [AC_MSG_RESULT([no])
 986         HAVE_CLOCK_MONOTONIC=])
 987 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
 988 #
 989 # Define NO_SETITIMER if you don't have setitimer.
 990 GIT_CHECK_FUNC(setitimer,
 991 [NO_SETITIMER=],
 992 [NO_SETITIMER=YesPlease])
 993 GIT_CONF_SUBST([NO_SETITIMER])
 994 #
 995 # Define NO_STRCASESTR if you don't have strcasestr.
 996 GIT_CHECK_FUNC(strcasestr,
 997 [NO_STRCASESTR=],
 998 [NO_STRCASESTR=YesPlease])
 999 GIT_CONF_SUBST([NO_STRCASESTR])
1000 #
1001 # Define NO_MEMMEM if you don't have memmem.
1002 GIT_CHECK_FUNC(memmem,
1003 [NO_MEMMEM=],
1004 [NO_MEMMEM=YesPlease])
1005 GIT_CONF_SUBST([NO_MEMMEM])
1006 #
1007 # Define NO_STRLCPY if you don't have strlcpy.
1008 GIT_CHECK_FUNC(strlcpy,
1009 [NO_STRLCPY=],
1010 [NO_STRLCPY=YesPlease])
1011 GIT_CONF_SUBST([NO_STRLCPY])
1012 #
1013 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1014 AC_CHECK_TYPE(uintmax_t,
1015 [NO_UINTMAX_T=],
1016 [NO_UINTMAX_T=YesPlease],[
1017 #include <inttypes.h>
1018 ])
1019 GIT_CONF_SUBST([NO_UINTMAX_T])
1020 #
1021 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1022 GIT_CHECK_FUNC(strtoumax,
1023 [NO_STRTOUMAX=],
1024 [NO_STRTOUMAX=YesPlease])
1025 GIT_CONF_SUBST([NO_STRTOUMAX])
1026 #
1027 # Define NO_SETENV if you don't have setenv in the C library.
1028 GIT_CHECK_FUNC(setenv,
1029 [NO_SETENV=],
1030 [NO_SETENV=YesPlease])
1031 GIT_CONF_SUBST([NO_SETENV])
1032 #
1033 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1034 GIT_CHECK_FUNC(unsetenv,
1035 [NO_UNSETENV=],
1036 [NO_UNSETENV=YesPlease])
1037 GIT_CONF_SUBST([NO_UNSETENV])
1038 #
1039 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1040 GIT_CHECK_FUNC(mkdtemp,
1041 [NO_MKDTEMP=],
1042 [NO_MKDTEMP=YesPlease])
1043 GIT_CONF_SUBST([NO_MKDTEMP])
1044 #
1045 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
1046 GIT_CHECK_FUNC(mkstemps,
1047 [NO_MKSTEMPS=],
1048 [NO_MKSTEMPS=YesPlease])
1049 GIT_CONF_SUBST([NO_MKSTEMPS])
1050 #
1051 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1052 GIT_CHECK_FUNC(initgroups,
1053 [NO_INITGROUPS=],
1054 [NO_INITGROUPS=YesPlease])
1055 GIT_CONF_SUBST([NO_INITGROUPS])
1056 #
1057 # Define HAVE_GETDELIM if you have getdelim in the C library.
1058 GIT_CHECK_FUNC(getdelim,
1059 [HAVE_GETDELIM=YesPlease],
1060 [HAVE_GETDELIM=])
1061 GIT_CONF_SUBST([HAVE_GETDELIM])
1062 #
1063 #
1064 # Define NO_MMAP if you want to avoid mmap.
1065 #
1066 # Define NO_ICONV if your libc does not properly support iconv.
1067
1068 AC_DEFUN([BSD_SYSCTL_SRC], [
1069 AC_LANG_PROGRAM([[
1070 #include <stddef.h>
1071 #include <sys/types.h>
1072 #include <sys/sysctl.h>
1073 ]],[[
1074 int val, mib[2];
1075 size_t len;
1076 mib[0] = CTL_HW;
1077 mib[1] = 1;
1078 len = sizeof(val);
1079 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1080 ]])])
1081
1082 #
1083 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1084 AC_MSG_CHECKING([for BSD sysctl])
1085 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1086         [AC_MSG_RESULT([yes])
1087         HAVE_BSD_SYSCTL=YesPlease],
1088         [AC_MSG_RESULT([no])
1089         HAVE_BSD_SYSCTL=])
1090 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1091
1092 ## Other checks.
1093 # Define USE_PIC if you need the main git objects to be built with -fPIC
1094 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1095 #
1096 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1097 # Enable it on Windows.  By default, symrefs are still used.
1098 #
1099 # Define NO_PTHREADS if we do not have pthreads.
1100 #
1101 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1102 AC_DEFUN([PTHREADTEST_SRC], [
1103 AC_LANG_PROGRAM([[
1104 #include <pthread.h>
1105 ]], [[
1106         pthread_mutex_t test_mutex;
1107         pthread_key_t test_key;
1108         int retcode = 0;
1109         retcode |= pthread_key_create(&test_key, (void *)0);
1110         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1111         retcode |= pthread_mutex_lock(&test_mutex);
1112         retcode |= pthread_mutex_unlock(&test_mutex);
1113         return retcode;
1114 ]])])
1115
1116 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1117 dnl   [[#include <pthread.h>]],
1118 dnl   [[pthread_mutex_t test_mutex;]]
1119 dnl )])
1120
1121 NO_PTHREADS=UnfortunatelyYes
1122 PTHREAD_LIBS=
1123
1124 if test -n "$USER_NOPTHREAD"; then
1125    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1126 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1127 # -D_REENTRANT' or some such.
1128 elif test -z "$PTHREAD_CFLAGS"; then
1129   threads_found=no
1130   # Attempt to compile and link some code using pthreads to determine
1131   # required linker flags. The order is somewhat important here: We
1132   # first try it without any extra flags, to catch systems where
1133   # pthreads are part of the C library, then go on testing various other
1134   # flags. We do so to avoid false positives. For example, on Mac OS X
1135   # pthreads are part of the C library; moreover, the compiler allows us
1136   # to add "-mt" to the CFLAGS (although it will do nothing except
1137   # trigger a warning about an unused flag). Hence if we checked for
1138   # "-mt" before "" we would end up picking it. But unfortunately this
1139   # would then trigger compiler warnings on every single file we compile.
1140   for opt in "" -mt -pthread -lpthread; do
1141      old_CFLAGS="$CFLAGS"
1142      CFLAGS="$opt $CFLAGS"
1143      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1144      AC_LINK_IFELSE([PTHREADTEST_SRC],
1145         [AC_MSG_RESULT([yes])
1146                 NO_PTHREADS=
1147                 PTHREAD_LIBS="$opt"
1148                 PTHREAD_CFLAGS="$opt"
1149                 threads_found=yes
1150                 break
1151         ],
1152         [AC_MSG_RESULT([no])])
1153       CFLAGS="$old_CFLAGS"
1154   done
1155   if test $threads_found != yes; then
1156     AC_CHECK_LIB([pthread], [pthread_create],
1157         [PTHREAD_LIBS="-lpthread"],
1158         [NO_PTHREADS=UnfortunatelyYes])
1159   fi
1160 else
1161   old_CFLAGS="$CFLAGS"
1162   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1163   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1164   AC_LINK_IFELSE([PTHREADTEST_SRC],
1165         [AC_MSG_RESULT([yes])
1166                 NO_PTHREADS=
1167                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1168         ],
1169         [AC_MSG_RESULT([no])])
1170
1171   CFLAGS="$old_CFLAGS"
1172 fi
1173
1174 CFLAGS="$old_CFLAGS"
1175
1176 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1177 GIT_CONF_SUBST([PTHREAD_LIBS])
1178 GIT_CONF_SUBST([NO_PTHREADS])
1179
1180 ## Output files
1181 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1182 AC_OUTPUT