gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  24         eval 'sub CGI::multi_param { CGI::param(@_) }'
  25 }
  26
  27 our $t0 = [ gettimeofday() ];
  28 our $number_of_git_cmds = 0;
  29
  30 BEGIN {
  31         CGI->compile() if $ENV{'MOD_PERL'};
  32 }
  33
  34 our $version = "++GIT_VERSION++";
  35
  36 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  37 sub evaluate_uri {
  38         our $cgi;
  39
  40         our $my_url = $cgi->url();
  41         our $my_uri = $cgi->url(-absolute => 1);
  42
  43         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  44         # needed and used only for URLs with nonempty PATH_INFO
  45         our $base_url = $my_url;
  46
  47         # When the script is used as DirectoryIndex, the URL does not contain the name
  48         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  49         # have to do it ourselves. We make $path_info global because it's also used
  50         # later on.
  51         #
  52         # Another issue with the script being the DirectoryIndex is that the resulting
  53         # $my_url data is not the full script URL: this is good, because we want
  54         # generated links to keep implying the script name if it wasn't explicitly
  55         # indicated in the URL we're handling, but it means that $my_url cannot be used
  56         # as base URL.
  57         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  58         # to build the base URL ourselves:
  59         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  60         if ($path_info) {
  61                 # $path_info has already been URL-decoded by the web server, but
  62                 # $my_url and $my_uri have not. URL-decode them so we can properly
  63                 # strip $path_info.
  64                 $my_url = unescape($my_url);
  65                 $my_uri = unescape($my_uri);
  66                 if ($my_url =~ s,\Q$path_info\E$,, &&
  67                     $my_uri =~ s,\Q$path_info\E$,, &&
  68                     defined $ENV{'SCRIPT_NAME'}) {
  69                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  70                 }
  71         }
  72
  73         # target of the home link on top of all pages
  74         our $home_link = $my_uri || "/";
  75 }
  76
  77 # core git executable to use
  78 # this can just be "git" if your webserver has a sensible PATH
  79 our $GIT = "++GIT_BINDIR++/git";
  80
  81 # absolute fs-path which will be prepended to the project path
  82 #our $projectroot = "/pub/scm";
  83 our $projectroot = "++GITWEB_PROJECTROOT++";
  84
  85 # fs traversing limit for getting project list
  86 # the number is relative to the projectroot
  87 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  88
  89 # string of the home link on top of all pages
  90 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  91
  92 # extra breadcrumbs preceding the home link
  93 our @extra_breadcrumbs = ();
  94
  95 # name of your site or organization to appear in page titles
  96 # replace this with something more descriptive for clearer bookmarks
  97 our $site_name = "++GITWEB_SITENAME++"
  98                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  99
 100 # html snippet to include in the <head> section of each page
 101 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 102 # filename of html text to include at top of each page
 103 our $site_header = "++GITWEB_SITE_HEADER++";
 104 # html text to include at home page
 105 our $home_text = "++GITWEB_HOMETEXT++";
 106 # filename of html text to include at bottom of each page
 107 our $site_footer = "++GITWEB_SITE_FOOTER++";
 108
 109 # URI of stylesheets
 110 our @stylesheets = ("++GITWEB_CSS++");
 111 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 112 our $stylesheet = undef;
 113 # URI of GIT logo (72x27 size)
 114 our $logo = "++GITWEB_LOGO++";
 115 # URI of GIT favicon, assumed to be image/png type
 116 our $favicon = "++GITWEB_FAVICON++";
 117 # URI of gitweb.js (JavaScript code for gitweb)
 118 our $javascript = "++GITWEB_JS++";
 119
 120 # URI and label (title) of GIT logo link
 121 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 122 #our $logo_label = "git documentation";
 123 our $logo_url = "http://git-scm.com/";
 124 our $logo_label = "git homepage";
 125
 126 # source of projects list
 127 our $projects_list = "++GITWEB_LIST++";
 128
 129 # the width (in characters) of the projects list "Description" column
 130 our $projects_list_description_width = 25;
 131
 132 # group projects by category on the projects list
 133 # (enabled if this variable evaluates to true)
 134 our $projects_list_group_categories = 0;
 135
 136 # default category if none specified
 137 # (leave the empty string for no category)
 138 our $project_list_default_category = "";
 139
 140 # default order of projects list
 141 # valid values are none, project, descr, owner, and age
 142 our $default_projects_order = "project";
 143
 144 # show repository only if this file exists
 145 # (only effective if this variable evaluates to true)
 146 our $export_ok = "++GITWEB_EXPORT_OK++";
 147
 148 # don't generate age column on the projects list page
 149 our $omit_age_column = 0;
 150
 151 # don't generate information about owners of repositories
 152 our $omit_owner=0;
 153
 154 # show repository only if this subroutine returns true
 155 # when given the path to the project, for example:
 156 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 157 our $export_auth_hook = undef;
 158
 159 # only allow viewing of repositories also shown on the overview page
 160 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 161
 162 # list of git base URLs used for URL to where fetch project from,
 163 # i.e. full URL is "$git_base_url/$project"
 164 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 165
 166 # default blob_plain mimetype and default charset for text/plain blob
 167 our $default_blob_plain_mimetype = 'text/plain';
 168 our $default_text_plain_charset  = undef;
 169
 170 # file to use for guessing MIME types before trying /etc/mime.types
 171 # (relative to the current git repository)
 172 our $mimetypes_file = undef;
 173
 174 # assume this charset if line contains non-UTF-8 characters;
 175 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 176 # for which encoding all byte sequences are valid, for example
 177 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 178 # could be even 'utf-8' for the old behavior)
 179 our $fallback_encoding = 'latin1';
 180
 181 # rename detection options for git-diff and git-diff-tree
 182 # - default is '-M', with the cost proportional to
 183 #   (number of removed files) * (number of new files).
 184 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 185 #   (number of changed files + number of removed files) * (number of new files)
 186 # - even more costly is '-C', '--find-copies-harder' with cost
 187 #   (number of files in the original tree) * (number of new files)
 188 # - one might want to include '-B' option, e.g. '-B', '-M'
 189 our @diff_opts = ('-M'); # taken from git_commit
 190
 191 # Disables features that would allow repository owners to inject script into
 192 # the gitweb domain.
 193 our $prevent_xss = 0;
 194
 195 # Path to the highlight executable to use (must be the one from
 196 # http://www.andre-simon.de due to assumptions about parameters and output).
 197 # Useful if highlight is not installed on your webserver's PATH.
 198 # [Default: highlight]
 199 our $highlight_bin = "++HIGHLIGHT_BIN++";
 200
 201 # information about snapshot formats that gitweb is capable of serving
 202 our %known_snapshot_formats = (
 203         # name => {
 204         #       'display' => display name,
 205         #       'type' => mime type,
 206         #       'suffix' => filename suffix,
 207         #       'format' => --format for git-archive,
 208         #       'compressor' => [compressor command and arguments]
 209         #                       (array reference, optional)
 210         #       'disabled' => boolean (optional)}
 211         #
 212         'tgz' => {
 213                 'display' => 'tar.gz',
 214                 'type' => 'application/x-gzip',
 215                 'suffix' => '.tar.gz',
 216                 'format' => 'tar',
 217                 'compressor' => ['gzip', '-n']},
 218
 219         'tbz2' => {
 220                 'display' => 'tar.bz2',
 221                 'type' => 'application/x-bzip2',
 222                 'suffix' => '.tar.bz2',
 223                 'format' => 'tar',
 224                 'compressor' => ['bzip2']},
 225
 226         'txz' => {
 227                 'display' => 'tar.xz',
 228                 'type' => 'application/x-xz',
 229                 'suffix' => '.tar.xz',
 230                 'format' => 'tar',
 231                 'compressor' => ['xz'],
 232                 'disabled' => 1},
 233
 234         'zip' => {
 235                 'display' => 'zip',
 236                 'type' => 'application/x-zip',
 237                 'suffix' => '.zip',
 238                 'format' => 'zip'},
 239 );
 240
 241 # Aliases so we understand old gitweb.snapshot values in repository
 242 # configuration.
 243 our %known_snapshot_format_aliases = (
 244         'gzip'  => 'tgz',
 245         'bzip2' => 'tbz2',
 246         'xz'    => 'txz',
 247
 248         # backward compatibility: legacy gitweb config support
 249         'x-gzip' => undef, 'gz' => undef,
 250         'x-bzip2' => undef, 'bz2' => undef,
 251         'x-zip' => undef, '' => undef,
 252 );
 253
 254 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 255 # are changed, it may be appropriate to change these values too via
 256 # $GITWEB_CONFIG.
 257 our %avatar_size = (
 258         'default' => 16,
 259         'double'  => 32
 260 );
 261
 262 # Used to set the maximum load that we will still respond to gitweb queries.
 263 # If server load exceed this value then return "503 server busy" error.
 264 # If gitweb cannot determined server load, it is taken to be 0.
 265 # Leave it undefined (or set to 'undef') to turn off load checking.
 266 our $maxload = 300;
 267
 268 # configuration for 'highlight' (http://www.andre-simon.de/)
 269 # match by basename
 270 our %highlight_basename = (
 271         #'Program' => 'py',
 272         #'Library' => 'py',
 273         'SConstruct' => 'py', # SCons equivalent of Makefile
 274         'Makefile' => 'make',
 275 );
 276 # match by extension
 277 our %highlight_ext = (
 278         # main extensions, defining name of syntax;
 279         # see files in /usr/share/highlight/langDefs/ directory
 280         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 281         # alternate extensions, see /etc/highlight/filetypes.conf
 282         (map { $_ => 'c'   } qw(c h)),
 283         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 284         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 285         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 286         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 287         (map { $_ => 'make'} qw(make mak mk)),
 288         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 289 );
 290
 291 # You define site-wide feature defaults here; override them with
 292 # $GITWEB_CONFIG as necessary.
 293 our %feature = (
 294         # feature => {
 295         #       'sub' => feature-sub (subroutine),
 296         #       'override' => allow-override (boolean),
 297         #       'default' => [ default options...] (array reference)}
 298         #
 299         # if feature is overridable (it means that allow-override has true value),
 300         # then feature-sub will be called with default options as parameters;
 301         # return value of feature-sub indicates if to enable specified feature
 302         #
 303         # if there is no 'sub' key (no feature-sub), then feature cannot be
 304         # overridden
 305         #
 306         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 307         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 308         # is enabled
 309
 310         # Enable the 'blame' blob view, showing the last commit that modified
 311         # each line in the file. This can be very CPU-intensive.
 312
 313         # To enable system wide have in $GITWEB_CONFIG
 314         # $feature{'blame'}{'default'} = [1];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'blame'}{'override'} = 1;
 317         # and in project config gitweb.blame = 0|1;
 318         'blame' => {
 319                 'sub' => sub { feature_bool('blame', @_) },
 320                 'override' => 0,
 321                 'default' => [0]},
 322
 323         # Enable the 'snapshot' link, providing a compressed archive of any
 324         # tree. This can potentially generate high traffic if you have large
 325         # project.
 326
 327         # Value is a list of formats defined in %known_snapshot_formats that
 328         # you wish to offer.
 329         # To disable system wide have in $GITWEB_CONFIG
 330         # $feature{'snapshot'}{'default'} = [];
 331         # To have project specific config enable override in $GITWEB_CONFIG
 332         # $feature{'snapshot'}{'override'} = 1;
 333         # and in project config, a comma-separated list of formats or "none"
 334         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 335         'snapshot' => {
 336                 'sub' => \&feature_snapshot,
 337                 'override' => 0,
 338                 'default' => ['tgz']},
 339
 340         # Enable text search, which will list the commits which match author,
 341         # committer or commit text to a given string.  Enabled by default.
 342         # Project specific override is not supported.
 343         #
 344         # Note that this controls all search features, which means that if
 345         # it is disabled, then 'grep' and 'pickaxe' search would also be
 346         # disabled.
 347         'search' => {
 348                 'override' => 0,
 349                 'default' => [1]},
 350
 351         # Enable grep search, which will list the files in currently selected
 352         # tree containing the given string. Enabled by default. This can be
 353         # potentially CPU-intensive, of course.
 354         # Note that you need to have 'search' feature enabled too.
 355
 356         # To enable system wide have in $GITWEB_CONFIG
 357         # $feature{'grep'}{'default'} = [1];
 358         # To have project specific config enable override in $GITWEB_CONFIG
 359         # $feature{'grep'}{'override'} = 1;
 360         # and in project config gitweb.grep = 0|1;
 361         'grep' => {
 362                 'sub' => sub { feature_bool('grep', @_) },
 363                 'override' => 0,
 364                 'default' => [1]},
 365
 366         # Enable the pickaxe search, which will list the commits that modified
 367         # a given string in a file. This can be practical and quite faster
 368         # alternative to 'blame', but still potentially CPU-intensive.
 369         # Note that you need to have 'search' feature enabled too.
 370
 371         # To enable system wide have in $GITWEB_CONFIG
 372         # $feature{'pickaxe'}{'default'} = [1];
 373         # To have project specific config enable override in $GITWEB_CONFIG
 374         # $feature{'pickaxe'}{'override'} = 1;
 375         # and in project config gitweb.pickaxe = 0|1;
 376         'pickaxe' => {
 377                 'sub' => sub { feature_bool('pickaxe', @_) },
 378                 'override' => 0,
 379                 'default' => [1]},
 380
 381         # Enable showing size of blobs in a 'tree' view, in a separate
 382         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 383
 384         # To disable system wide have in $GITWEB_CONFIG
 385         # $feature{'show-sizes'}{'default'} = [0];
 386         # To have project specific config enable override in $GITWEB_CONFIG
 387         # $feature{'show-sizes'}{'override'} = 1;
 388         # and in project config gitweb.showsizes = 0|1;
 389         'show-sizes' => {
 390                 'sub' => sub { feature_bool('showsizes', @_) },
 391                 'override' => 0,
 392                 'default' => [1]},
 393
 394         # Make gitweb use an alternative format of the URLs which can be
 395         # more readable and natural-looking: project name is embedded
 396         # directly in the path and the query string contains other
 397         # auxiliary information. All gitweb installations recognize
 398         # URL in either format; this configures in which formats gitweb
 399         # generates links.
 400
 401         # To enable system wide have in $GITWEB_CONFIG
 402         # $feature{'pathinfo'}{'default'} = [1];
 403         # Project specific override is not supported.
 404
 405         # Note that you will need to change the default location of CSS,
 406         # favicon, logo and possibly other files to an absolute URL. Also,
 407         # if gitweb.cgi serves as your indexfile, you will need to force
 408         # $my_uri to contain the script name in your $GITWEB_CONFIG (and you
 409         # will also likely want to set $home_link if you're setting $my_uri).
 410         'pathinfo' => {
 411                 'override' => 0,
 412                 'default' => [0]},
 413
 414         # Make gitweb consider projects in project root subdirectories
 415         # to be forks of existing projects. Given project $projname.git,
 416         # projects matching $projname/*.git will not be shown in the main
 417         # projects list, instead a '+' mark will be added to $projname
 418         # there and a 'forks' view will be enabled for the project, listing
 419         # all the forks. If project list is taken from a file, forks have
 420         # to be listed after the main project.
 421
 422         # To enable system wide have in $GITWEB_CONFIG
 423         # $feature{'forks'}{'default'} = [1];
 424         # Project specific override is not supported.
 425         'forks' => {
 426                 'override' => 0,
 427                 'default' => [0]},
 428
 429         # Insert custom links to the action bar of all project pages.
 430         # This enables you mainly to link to third-party scripts integrating
 431         # into gitweb; e.g. git-browser for graphical history representation
 432         # or custom web-based repository administration interface.
 433
 434         # The 'default' value consists of a list of triplets in the form
 435         # (label, link, position) where position is the label after which
 436         # to insert the link and link is a format string where %n expands
 437         # to the project name, %f to the project path within the filesystem,
 438         # %h to the current hash (h gitweb parameter) and %b to the current
 439         # hash base (hb gitweb parameter); %% expands to %.
 440
 441         # To enable system wide have in $GITWEB_CONFIG e.g.
 442         # $feature{'actions'}{'default'} = [('graphiclog',
 443         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 444         # Project specific override is not supported.
 445         'actions' => {
 446                 'override' => 0,
 447                 'default' => []},
 448
 449         # Allow gitweb scan project content tags of project repository,
 450         # and display the popular Web 2.0-ish "tag cloud" near the projects
 451         # list.  Note that this is something COMPLETELY different from the
 452         # normal Git tags.
 453
 454         # gitweb by itself can show existing tags, but it does not handle
 455         # tagging itself; you need to do it externally, outside gitweb.
 456         # The format is described in git_get_project_ctags() subroutine.
 457         # You may want to install the HTML::TagCloud Perl module to get
 458         # a pretty tag cloud instead of just a list of tags.
 459
 460         # To enable system wide have in $GITWEB_CONFIG
 461         # $feature{'ctags'}{'default'} = [1];
 462         # Project specific override is not supported.
 463
 464         # In the future whether ctags editing is enabled might depend
 465         # on the value, but using 1 should always mean no editing of ctags.
 466         'ctags' => {
 467                 'override' => 0,
 468                 'default' => [0]},
 469
 470         # The maximum number of patches in a patchset generated in patch
 471         # view. Set this to 0 or undef to disable patch view, or to a
 472         # negative number to remove any limit.
 473
 474         # To disable system wide have in $GITWEB_CONFIG
 475         # $feature{'patches'}{'default'} = [0];
 476         # To have project specific config enable override in $GITWEB_CONFIG
 477         # $feature{'patches'}{'override'} = 1;
 478         # and in project config gitweb.patches = 0|n;
 479         # where n is the maximum number of patches allowed in a patchset.
 480         'patches' => {
 481                 'sub' => \&feature_patches,
 482                 'override' => 0,
 483                 'default' => [16]},
 484
 485         # Avatar support. When this feature is enabled, views such as
 486         # shortlog or commit will display an avatar associated with
 487         # the email of the committer(s) and/or author(s).
 488
 489         # Currently available providers are gravatar and picon.
 490         # If an unknown provider is specified, the feature is disabled.
 491
 492         # Gravatar depends on Digest::MD5.
 493         # Picon currently relies on the indiana.edu database.
 494
 495         # To enable system wide have in $GITWEB_CONFIG
 496         # $feature{'avatar'}{'default'} = ['<provider>'];
 497         # where <provider> is either gravatar or picon.
 498         # To have project specific config enable override in $GITWEB_CONFIG
 499         # $feature{'avatar'}{'override'} = 1;
 500         # and in project config gitweb.avatar = <provider>;
 501         'avatar' => {
 502                 'sub' => \&feature_avatar,
 503                 'override' => 0,
 504                 'default' => ['']},
 505
 506         # Enable displaying how much time and how many git commands
 507         # it took to generate and display page.  Disabled by default.
 508         # Project specific override is not supported.
 509         'timed' => {
 510                 'override' => 0,
 511                 'default' => [0]},
 512
 513         # Enable turning some links into links to actions which require
 514         # JavaScript to run (like 'blame_incremental').  Not enabled by
 515         # default.  Project specific override is currently not supported.
 516         'javascript-actions' => {
 517                 'override' => 0,
 518                 'default' => [0]},
 519
 520         # Enable and configure ability to change common timezone for dates
 521         # in gitweb output via JavaScript.  Enabled by default.
 522         # Project specific override is not supported.
 523         'javascript-timezone' => {
 524                 'override' => 0,
 525                 'default' => [
 526                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 527                                      # or undef to turn off this feature
 528                         'gitweb_tz', # name of cookie where to store selected timezone
 529                         'datetime',  # CSS class used to mark up dates for manipulation
 530                 ]},
 531
 532         # Syntax highlighting support. This is based on Daniel Svensson's
 533         # and Sham Chukoury's work in gitweb-xmms2.git.
 534         # It requires the 'highlight' program present in $PATH,
 535         # and therefore is disabled by default.
 536
 537         # To enable system wide have in $GITWEB_CONFIG
 538         # $feature{'highlight'}{'default'} = [1];
 539
 540         'highlight' => {
 541                 'sub' => sub { feature_bool('highlight', @_) },
 542                 'override' => 0,
 543                 'default' => [0]},
 544
 545         # Enable displaying of remote heads in the heads list
 546
 547         # To enable system wide have in $GITWEB_CONFIG
 548         # $feature{'remote_heads'}{'default'} = [1];
 549         # To have project specific config enable override in $GITWEB_CONFIG
 550         # $feature{'remote_heads'}{'override'} = 1;
 551         # and in project config gitweb.remoteheads = 0|1;
 552         'remote_heads' => {
 553                 'sub' => sub { feature_bool('remote_heads', @_) },
 554                 'override' => 0,
 555                 'default' => [0]},
 556
 557         # Enable showing branches under other refs in addition to heads
 558
 559         # To set system wide extra branch refs have in $GITWEB_CONFIG
 560         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 561         # To have project specific config enable override in $GITWEB_CONFIG
 562         # $feature{'extra-branch-refs'}{'override'} = 1;
 563         # and in project config gitweb.extrabranchrefs = dirs of choice
 564         # Every directory is separated with whitespace.
 565
 566         'extra-branch-refs' => {
 567                 'sub' => \&feature_extra_branch_refs,
 568                 'override' => 0,
 569                 'default' => []},
 570 );
 571
 572 sub gitweb_get_feature {
 573         my ($name) = @_;
 574         return unless exists $feature{$name};
 575         my ($sub, $override, @defaults) = (
 576                 $feature{$name}{'sub'},
 577                 $feature{$name}{'override'},
 578                 @{$feature{$name}{'default'}});
 579         # project specific override is possible only if we have project
 580         our $git_dir; # global variable, declared later
 581         if (!$override || !defined $git_dir) {
 582                 return @defaults;
 583         }
 584         if (!defined $sub) {
 585                 warn "feature $name is not overridable";
 586                 return @defaults;
 587         }
 588         return $sub->(@defaults);
 589 }
 590
 591 # A wrapper to check if a given feature is enabled.
 592 # With this, you can say
 593 #
 594 #   my $bool_feat = gitweb_check_feature('bool_feat');
 595 #   gitweb_check_feature('bool_feat') or somecode;
 596 #
 597 # instead of
 598 #
 599 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 600 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 601 #
 602 sub gitweb_check_feature {
 603         return (gitweb_get_feature(@_))[0];
 604 }
 605
 606
 607 sub feature_bool {
 608         my $key = shift;
 609         my ($val) = git_get_project_config($key, '--bool');
 610
 611         if (!defined $val) {
 612                 return ($_[0]);
 613         } elsif ($val eq 'true') {
 614                 return (1);
 615         } elsif ($val eq 'false') {
 616                 return (0);
 617         }
 618 }
 619
 620 sub feature_snapshot {
 621         my (@fmts) = @_;
 622
 623         my ($val) = git_get_project_config('snapshot');
 624
 625         if ($val) {
 626                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 627         }
 628
 629         return @fmts;
 630 }
 631
 632 sub feature_patches {
 633         my @val = (git_get_project_config('patches', '--int'));
 634
 635         if (@val) {
 636                 return @val;
 637         }
 638
 639         return ($_[0]);
 640 }
 641
 642 sub feature_avatar {
 643         my @val = (git_get_project_config('avatar'));
 644
 645         return @val ? @val : @_;
 646 }
 647
 648 sub feature_extra_branch_refs {
 649         my (@branch_refs) = @_;
 650         my $values = git_get_project_config('extrabranchrefs');
 651
 652         if ($values) {
 653                 $values = config_to_multi ($values);
 654                 @branch_refs = ();
 655                 foreach my $value (@{$values}) {
 656                         push @branch_refs, split /\s+/, $value;
 657                 }
 658         }
 659
 660         return @branch_refs;
 661 }
 662
 663 # checking HEAD file with -e is fragile if the repository was
 664 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 665 # and then pruned.
 666 sub check_head_link {
 667         my ($dir) = @_;
 668         my $headfile = "$dir/HEAD";
 669         return ((-e $headfile) ||
 670                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 671 }
 672
 673 sub check_export_ok {
 674         my ($dir) = @_;
 675         return (check_head_link($dir) &&
 676                 (!$export_ok || -e "$dir/$export_ok") &&
 677                 (!$export_auth_hook || $export_auth_hook->($dir)));
 678 }
 679
 680 # process alternate names for backward compatibility
 681 # filter out unsupported (unknown) snapshot formats
 682 sub filter_snapshot_fmts {
 683         my @fmts = @_;
 684
 685         @fmts = map {
 686                 exists $known_snapshot_format_aliases{$_} ?
 687                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 688         @fmts = grep {
 689                 exists $known_snapshot_formats{$_} &&
 690                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 691 }
 692
 693 sub filter_and_validate_refs {
 694         my @refs = @_;
 695         my %unique_refs = ();
 696
 697         foreach my $ref (@refs) {
 698                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 699                 # 'heads' are added implicitly in get_branch_refs().
 700                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 701         }
 702         return sort keys %unique_refs;
 703 }
 704
 705 # If it is set to code reference, it is code that it is to be run once per
 706 # request, allowing updating configurations that change with each request,
 707 # while running other code in config file only once.
 708 #
 709 # Otherwise, if it is false then gitweb would process config file only once;
 710 # if it is true then gitweb config would be run for each request.
 711 our $per_request_config = 1;
 712
 713 # If true and fileno STDIN is 0 and getsockname succeeds and getpeername fails
 714 # with ENOTCONN, then FCGI mode will be activated automatically in just the
 715 # same way as though the --fcgi option had been given instead.
 716 our $auto_fcgi = 0;
 717
 718 # read and parse gitweb config file given by its parameter.
 719 # returns true on success, false on recoverable error, allowing
 720 # to chain this subroutine, using first file that exists.
 721 # dies on errors during parsing config file, as it is unrecoverable.
 722 sub read_config_file {
 723         my $filename = shift;
 724         return unless defined $filename;
 725         # die if there are errors parsing config file
 726         if (-e $filename) {
 727                 do $filename;
 728                 die $@ if $@;
 729                 return 1;
 730         }
 731         return;
 732 }
 733
 734 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 735 sub evaluate_gitweb_config {
 736         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 737         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 738         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 739
 740         # Protect against duplications of file names, to not read config twice.
 741         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 742         # there possibility of duplication of filename there doesn't matter.
 743         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 744         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 745
 746         # Common system-wide settings for convenience.
 747         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 748         read_config_file($GITWEB_CONFIG_COMMON);
 749
 750         # Use first config file that exists.  This means use the per-instance
 751         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 752         read_config_file($GITWEB_CONFIG) and return;
 753         read_config_file($GITWEB_CONFIG_SYSTEM);
 754 }
 755
 756 # Get loadavg of system, to compare against $maxload.
 757 # Currently it requires '/proc/loadavg' present to get loadavg;
 758 # if it is not present it returns 0, which means no load checking.
 759 sub get_loadavg {
 760         if( -e '/proc/loadavg' ){
 761                 open my $fd, '<', '/proc/loadavg'
 762                         or return 0;
 763                 my @load = split(/\s+/, scalar <$fd>);
 764                 close $fd;
 765
 766                 # The first three columns measure CPU and IO utilization of the last one,
 767                 # five, and 10 minute periods.  The fourth column shows the number of
 768                 # currently running processes and the total number of processes in the m/n
 769                 # format.  The last column displays the last process ID used.
 770                 return $load[0] || 0;
 771         }
 772         # additional checks for load average should go here for things that don't export
 773         # /proc/loadavg
 774
 775         return 0;
 776 }
 777
 778 # version of the core git binary
 779 our $git_version;
 780 sub evaluate_git_version {
 781         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 782         $number_of_git_cmds++;
 783 }
 784
 785 sub check_loadavg {
 786         if (defined $maxload && get_loadavg() > $maxload) {
 787                 die_error(503, "The load average on the server is too high");
 788         }
 789 }
 790
 791 # ======================================================================
 792 # input validation and dispatch
 793
 794 # input parameters can be collected from a variety of sources (presently, CGI
 795 # and PATH_INFO), so we define an %input_params hash that collects them all
 796 # together during validation: this allows subsequent uses (e.g. href()) to be
 797 # agnostic of the parameter origin
 798
 799 our %input_params = ();
 800
 801 # input parameters are stored with the long parameter name as key. This will
 802 # also be used in the href subroutine to convert parameters to their CGI
 803 # equivalent, and since the href() usage is the most frequent one, we store
 804 # the name -> CGI key mapping here, instead of the reverse.
 805 #
 806 # XXX: Warning: If you touch this, check the search form for updating,
 807 # too.
 808
 809 our @cgi_param_mapping = (
 810         project => "p",
 811         action => "a",
 812         file_name => "f",
 813         file_parent => "fp",
 814         hash => "h",
 815         hash_parent => "hp",
 816         hash_base => "hb",
 817         hash_parent_base => "hpb",
 818         page => "pg",
 819         order => "o",
 820         searchtext => "s",
 821         searchtype => "st",
 822         snapshot_format => "sf",
 823         extra_options => "opt",
 824         search_use_regexp => "sr",
 825         ctag => "by_tag",
 826         diff_style => "ds",
 827         project_filter => "pf",
 828         # this must be last entry (for manipulation from JavaScript)
 829         javascript => "js"
 830 );
 831 our %cgi_param_mapping = @cgi_param_mapping;
 832
 833 # we will also need to know the possible actions, for validation
 834 our %actions = (
 835         "blame" => \&git_blame,
 836         "blame_incremental" => \&git_blame_incremental,
 837         "blame_data" => \&git_blame_data,
 838         "blobdiff" => \&git_blobdiff,
 839         "blobdiff_plain" => \&git_blobdiff_plain,
 840         "blob" => \&git_blob,
 841         "blob_plain" => \&git_blob_plain,
 842         "commitdiff" => \&git_commitdiff,
 843         "commitdiff_plain" => \&git_commitdiff_plain,
 844         "commit" => \&git_commit,
 845         "forks" => \&git_forks,
 846         "heads" => \&git_heads,
 847         "history" => \&git_history,
 848         "log" => \&git_log,
 849         "patch" => \&git_patch,
 850         "patches" => \&git_patches,
 851         "remotes" => \&git_remotes,
 852         "rss" => \&git_rss,
 853         "atom" => \&git_atom,
 854         "search" => \&git_search,
 855         "search_help" => \&git_search_help,
 856         "shortlog" => \&git_shortlog,
 857         "summary" => \&git_summary,
 858         "tag" => \&git_tag,
 859         "tags" => \&git_tags,
 860         "tree" => \&git_tree,
 861         "snapshot" => \&git_snapshot,
 862         "object" => \&git_object,
 863         # those below don't need $project
 864         "opml" => \&git_opml,
 865         "project_list" => \&git_project_list,
 866         "project_index" => \&git_project_index,
 867 );
 868
 869 # finally, we have the hash of allowed extra_options for the commands that
 870 # allow them
 871 our %allowed_options = (
 872         "--no-merges" => [ qw(rss atom log shortlog history) ],
 873 );
 874
 875 # fill %input_params with the CGI parameters. All values except for 'opt'
 876 # should be single values, but opt can be an array. We should probably
 877 # build an array of parameters that can be multi-valued, but since for the time
 878 # being it's only this one, we just single it out
 879 sub evaluate_query_params {
 880         our $cgi;
 881
 882         while (my ($name, $symbol) = each %cgi_param_mapping) {
 883                 if ($symbol eq 'opt') {
 884                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 885                 } else {
 886                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 887                 }
 888         }
 889 }
 890
 891 # now read PATH_INFO and update the parameter list for missing parameters
 892 sub evaluate_path_info {
 893         return if defined $input_params{'project'};
 894         return if !$path_info;
 895         $path_info =~ s,^/+,,;
 896         return if !$path_info;
 897
 898         # find which part of PATH_INFO is project
 899         my $project = $path_info;
 900         $project =~ s,/+$,,;
 901         while ($project && !check_head_link("$projectroot/$project")) {
 902                 $project =~ s,/*[^/]*$,,;
 903         }
 904         return unless $project;
 905         $input_params{'project'} = $project;
 906
 907         # do not change any parameters if an action is given using the query string
 908         return if $input_params{'action'};
 909         $path_info =~ s,^\Q$project\E/*,,;
 910
 911         # next, check if we have an action
 912         my $action = $path_info;
 913         $action =~ s,/.*$,,;
 914         if (exists $actions{$action}) {
 915                 $path_info =~ s,^$action/*,,;
 916                 $input_params{'action'} = $action;
 917         }
 918
 919         # list of actions that want hash_base instead of hash, but can have no
 920         # pathname (f) parameter
 921         my @wants_base = (
 922                 'tree',
 923                 'history',
 924         );
 925
 926         # we want to catch, among others
 927         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 928         my ($parentrefname, $parentpathname, $refname, $pathname) =
 929                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 930
 931         # first, analyze the 'current' part
 932         if (defined $pathname) {
 933                 # we got "branch:filename" or "branch:dir/"
 934                 # we could use git_get_type(branch:pathname), but:
 935                 # - it needs $git_dir
 936                 # - it does a git() call
 937                 # - the convention of terminating directories with a slash
 938                 #   makes it superfluous
 939                 # - embedding the action in the PATH_INFO would make it even
 940                 #   more superfluous
 941                 $pathname =~ s,^/+,,;
 942                 if (!$pathname || substr($pathname, -1) eq "/") {
 943                         $input_params{'action'} ||= "tree";
 944                         $pathname =~ s,/$,,;
 945                 } else {
 946                         # the default action depends on whether we had parent info
 947                         # or not
 948                         if ($parentrefname) {
 949                                 $input_params{'action'} ||= "blobdiff_plain";
 950                         } else {
 951                                 $input_params{'action'} ||= "blob_plain";
 952                         }
 953                 }
 954                 $input_params{'hash_base'} ||= $refname;
 955                 $input_params{'file_name'} ||= $pathname;
 956         } elsif (defined $refname) {
 957                 # we got "branch". In this case we have to choose if we have to
 958                 # set hash or hash_base.
 959                 #
 960                 # Most of the actions without a pathname only want hash to be
 961                 # set, except for the ones specified in @wants_base that want
 962                 # hash_base instead. It should also be noted that hand-crafted
 963                 # links having 'history' as an action and no pathname or hash
 964                 # set will fail, but that happens regardless of PATH_INFO.
 965                 if (defined $parentrefname) {
 966                         # if there is parent let the default be 'shortlog' action
 967                         # (for http://git.example.com/repo.git/A..B links); if there
 968                         # is no parent, dispatch will detect type of object and set
 969                         # action appropriately if required (if action is not set)
 970                         $input_params{'action'} ||= "shortlog";
 971                 }
 972                 if ($input_params{'action'} &&
 973                     grep { $_ eq $input_params{'action'} } @wants_base) {
 974                         $input_params{'hash_base'} ||= $refname;
 975                 } else {
 976                         $input_params{'hash'} ||= $refname;
 977                 }
 978         }
 979
 980         # next, handle the 'parent' part, if present
 981         if (defined $parentrefname) {
 982                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 983                 # someproject/blobdiff/oldrev..newrev:/filename
 984                 if ($parentpathname) {
 985                         $parentpathname =~ s,^/+,,;
 986                         $parentpathname =~ s,/$,,;
 987                         $input_params{'file_parent'} ||= $parentpathname;
 988                 } else {
 989                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 990                 }
 991                 # we assume that hash_parent_base is wanted if a path was specified,
 992                 # or if the action wants hash_base instead of hash
 993                 if (defined $input_params{'file_parent'} ||
 994                         grep { $_ eq $input_params{'action'} } @wants_base) {
 995                         $input_params{'hash_parent_base'} ||= $parentrefname;
 996                 } else {
 997                         $input_params{'hash_parent'} ||= $parentrefname;
 998                 }
 999         }
1000
1001         # for the snapshot action, we allow URLs in the form
1002         # $project/snapshot/$hash.ext
1003         # where .ext determines the snapshot and gets removed from the
1004         # passed $refname to provide the $hash.
1005         #
1006         # To be able to tell that $refname includes the format extension, we
1007         # require the following two conditions to be satisfied:
1008         # - the hash input parameter MUST have been set from the $refname part
1009         #   of the URL (i.e. they must be equal)
1010         # - the snapshot format MUST NOT have been defined already (e.g. from
1011         #   CGI parameter sf)
1012         # It's also useless to try any matching unless $refname has a dot,
1013         # so we check for that too
1014         if (defined $input_params{'action'} &&
1015                 $input_params{'action'} eq 'snapshot' &&
1016                 defined $refname && index($refname, '.') != -1 &&
1017                 $refname eq $input_params{'hash'} &&
1018                 !defined $input_params{'snapshot_format'}) {
1019                 # We loop over the known snapshot formats, checking for
1020                 # extensions. Allowed extensions are both the defined suffix
1021                 # (which includes the initial dot already) and the snapshot
1022                 # format key itself, with a prepended dot
1023                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1024                         my $hash = $refname;
1025                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1026                                 next;
1027                         }
1028                         my $sfx = $1;
1029                         # a valid suffix was found, so set the snapshot format
1030                         # and reset the hash parameter
1031                         $input_params{'snapshot_format'} = $fmt;
1032                         $input_params{'hash'} = $hash;
1033                         # we also set the format suffix to the one requested
1034                         # in the URL: this way a request for e.g. .tgz returns
1035                         # a .tgz instead of a .tar.gz
1036                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1037                         last;
1038                 }
1039         }
1040 }
1041
1042 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1043      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1044      $searchtext, $search_regexp, $project_filter);
1045 sub evaluate_and_validate_params {
1046         our $action = $input_params{'action'};
1047         if (defined $action) {
1048                 if (!is_valid_action($action)) {
1049                         die_error(400, "Invalid action parameter");
1050                 }
1051         }
1052
1053         # parameters which are pathnames
1054         our $project = $input_params{'project'};
1055         if (defined $project) {
1056                 if (!is_valid_project($project)) {
1057                         undef $project;
1058                         die_error(404, "No such project");
1059                 }
1060         }
1061
1062         our $project_filter = $input_params{'project_filter'};
1063         if (defined $project_filter) {
1064                 if (!is_valid_pathname($project_filter)) {
1065                         die_error(404, "Invalid project_filter parameter");
1066                 }
1067         }
1068
1069         our $file_name = $input_params{'file_name'};
1070         if (defined $file_name) {
1071                 if (!is_valid_pathname($file_name)) {
1072                         die_error(400, "Invalid file parameter");
1073                 }
1074         }
1075
1076         our $file_parent = $input_params{'file_parent'};
1077         if (defined $file_parent) {
1078                 if (!is_valid_pathname($file_parent)) {
1079                         die_error(400, "Invalid file parent parameter");
1080                 }
1081         }
1082
1083         # parameters which are refnames
1084         our $hash = $input_params{'hash'};
1085         if (defined $hash) {
1086                 if (!is_valid_refname($hash)) {
1087                         die_error(400, "Invalid hash parameter");
1088                 }
1089         }
1090
1091         our $hash_parent = $input_params{'hash_parent'};
1092         if (defined $hash_parent) {
1093                 if (!is_valid_refname($hash_parent)) {
1094                         die_error(400, "Invalid hash parent parameter");
1095                 }
1096         }
1097
1098         our $hash_base = $input_params{'hash_base'};
1099         if (defined $hash_base) {
1100                 if (!is_valid_refname($hash_base)) {
1101                         die_error(400, "Invalid hash base parameter");
1102                 }
1103         }
1104
1105         our @extra_options = @{$input_params{'extra_options'}};
1106         # @extra_options is always defined, since it can only be (currently) set from
1107         # CGI, and $cgi->param() returns the empty array in array context if the param
1108         # is not set
1109         foreach my $opt (@extra_options) {
1110                 if (not exists $allowed_options{$opt}) {
1111                         die_error(400, "Invalid option parameter");
1112                 }
1113                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1114                         die_error(400, "Invalid option parameter for this action");
1115                 }
1116         }
1117
1118         our $hash_parent_base = $input_params{'hash_parent_base'};
1119         if (defined $hash_parent_base) {
1120                 if (!is_valid_refname($hash_parent_base)) {
1121                         die_error(400, "Invalid hash parent base parameter");
1122                 }
1123         }
1124
1125         # other parameters
1126         our $page = $input_params{'page'};
1127         if (defined $page) {
1128                 if ($page =~ m/[^0-9]/) {
1129                         die_error(400, "Invalid page parameter");
1130                 }
1131         }
1132
1133         our $searchtype = $input_params{'searchtype'};
1134         if (defined $searchtype) {
1135                 if ($searchtype =~ m/[^a-z]/) {
1136                         die_error(400, "Invalid searchtype parameter");
1137                 }
1138         }
1139
1140         our $search_use_regexp = $input_params{'search_use_regexp'};
1141
1142         our $searchtext = $input_params{'searchtext'};
1143         our $search_regexp = undef;
1144         if (defined $searchtext) {
1145                 if (length($searchtext) < 2) {
1146                         die_error(403, "At least two characters are required for search parameter");
1147                 }
1148                 if ($search_use_regexp) {
1149                         $search_regexp = $searchtext;
1150                         if (!eval { qr/$search_regexp/; 1; }) {
1151                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1152                                 die_error(400, "Invalid search regexp '$search_regexp'",
1153                                           esc_html($error));
1154                         }
1155                 } else {
1156                         $search_regexp = quotemeta $searchtext;
1157                 }
1158         }
1159 }
1160
1161 # path to the current git repository
1162 our $git_dir;
1163 sub evaluate_git_dir {
1164         our $git_dir = "$projectroot/$project" if $project;
1165 }
1166
1167 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1168 sub configure_gitweb_features {
1169         # list of supported snapshot formats
1170         our @snapshot_fmts = gitweb_get_feature('snapshot');
1171         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1172
1173         # check that the avatar feature is set to a known provider name,
1174         # and for each provider check if the dependencies are satisfied.
1175         # if the provider name is invalid or the dependencies are not met,
1176         # reset $git_avatar to the empty string.
1177         our ($git_avatar) = gitweb_get_feature('avatar');
1178         if ($git_avatar eq 'gravatar') {
1179                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1180         } elsif ($git_avatar eq 'picon') {
1181                 # no dependencies
1182         } else {
1183                 $git_avatar = '';
1184         }
1185
1186         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1187         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1188 }
1189
1190 sub get_branch_refs {
1191         return ('heads', @extra_branch_refs);
1192 }
1193
1194 # custom error handler: 'die <message>' is Internal Server Error
1195 sub handle_errors_html {
1196         my $msg = shift; # it is already HTML escaped
1197
1198         # to avoid infinite loop where error occurs in die_error,
1199         # change handler to default handler, disabling handle_errors_html
1200         set_message("Error occurred when inside die_error:\n$msg");
1201
1202         # you cannot jump out of die_error when called as error handler;
1203         # the subroutine set via CGI::Carp::set_message is called _after_
1204         # HTTP headers are already written, so it cannot write them itself
1205         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1206 }
1207 set_message(\&handle_errors_html);
1208
1209 # dispatch
1210 sub dispatch {
1211         if (!defined $action) {
1212                 if (defined $hash) {
1213                         $action = git_get_type($hash);
1214                         $action or die_error(404, "Object does not exist");
1215                 } elsif (defined $hash_base && defined $file_name) {
1216                         $action = git_get_type("$hash_base:$file_name");
1217                         $action or die_error(404, "File or directory does not exist");
1218                 } elsif (defined $project) {
1219                         $action = 'summary';
1220                 } else {
1221                         $action = 'project_list';
1222                 }
1223         }
1224         if (!defined($actions{$action})) {
1225                 die_error(400, "Unknown action");
1226         }
1227         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1228             !$project) {
1229                 die_error(400, "Project needed");
1230         }
1231         $actions{$action}->();
1232 }
1233
1234 sub reset_timer {
1235         our $t0 = [ gettimeofday() ]
1236                 if defined $t0;
1237         our $number_of_git_cmds = 0;
1238 }
1239
1240 our $first_request = 1;
1241 our $evaluate_uri_force = undef;
1242 sub run_request {
1243         reset_timer();
1244
1245         # Only allow GET and HEAD methods
1246         if (!$ENV{'REQUEST_METHOD'} || ($ENV{'REQUEST_METHOD'} ne 'GET' && $ENV{'REQUEST_METHOD'} ne 'HEAD')) {
1247                 print <<EOT;
1248 Status: 405 Method Not Allowed
1249 Content-Type: text/plain
1250 Allow: GET,HEAD
1251
1252 405 Method Not Allowed
1253 EOT
1254                 return;
1255         }
1256
1257         evaluate_uri();
1258         &$evaluate_uri_force() if $evaluate_uri_force;
1259         if ($per_request_config) {
1260                 if (ref($per_request_config) eq 'CODE') {
1261                         $per_request_config->();
1262                 } elsif (!$first_request) {
1263                         evaluate_gitweb_config();
1264                 }
1265         }
1266         check_loadavg();
1267
1268         # $projectroot and $projects_list might be set in gitweb config file
1269         $projects_list ||= $projectroot;
1270
1271         evaluate_query_params();
1272         evaluate_path_info();
1273         evaluate_and_validate_params();
1274         evaluate_git_dir();
1275
1276         configure_gitweb_features();
1277
1278         dispatch();
1279 }
1280
1281 our $is_last_request = sub { 1 };
1282 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1283 our $CGI = 'CGI';
1284 our $cgi;
1285 our $fcgi_mode = 0;
1286 our $fcgi_nproc_active = 0;
1287 sub is_fcgi {
1288         use Errno;
1289         my $stdinfno = fileno STDIN;
1290         return 0 unless defined $stdinfno && $stdinfno == 0;
1291         return 0 unless getsockname STDIN;
1292         return 0 if getpeername STDIN;
1293         return $!{ENOTCONN}?1:0;
1294 }
1295 sub configure_as_fcgi {
1296         return if $fcgi_mode;
1297
1298         require CGI::Fast;
1299         our $CGI = 'CGI::Fast';
1300
1301         $fcgi_mode = 1;
1302         $first_request = 0;
1303         my $request_number = 0;
1304         # let each child service 100 requests
1305         our $is_last_request = sub { ++$request_number > 100 };
1306 }
1307 sub evaluate_argv {
1308         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1309         configure_as_fcgi()
1310                 if $script_name =~ /\.fcgi$/ || ($auto_fcgi && is_fcgi());
1311
1312         my $nproc_sub = sub {
1313                 my ($arg, $val) = @_;
1314                 return unless eval { require FCGI::ProcManager; 1; };
1315                 $fcgi_nproc_active = 1;
1316                 my $proc_manager = FCGI::ProcManager->new({
1317                         n_processes => $val,
1318                 });
1319                 our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1320                 our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1321                 our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1322         };
1323         if (@ARGV) {
1324                 require Getopt::Long;
1325                 Getopt::Long::GetOptions(
1326                         'fastcgi|fcgi|f' => \&configure_as_fcgi,
1327                         'nproc|n=i' => $nproc_sub,
1328                 );
1329         };
1330         if (!$fcgi_nproc_active && defined $ENV{'GITWEB_FCGI_NPROC'} && $ENV{'GITWEB_FCGI_NPROC'} =~ /^\d+$/) {
1331                 &$nproc_sub('nproc', $ENV{'GITWEB_FCGI_NPROC'});
1332         }
1333 }
1334
1335 sub run {
1336         evaluate_gitweb_config();
1337         evaluate_git_version();
1338         my ($ml, $mi, $bu, $hl, $subroutine) = ($my_url, $my_uri, $base_url, $home_link, '');
1339         $subroutine .= '$my_url = $ml;' if defined $my_url && $my_url ne '';
1340         $subroutine .= '$my_uri = $mi;' if defined $my_uri; # this one can be ""
1341         $subroutine .= '$base_url = $bu;' if defined $base_url && $base_url ne '';
1342         $subroutine .= '$home_link = $hl;' if defined $home_link && $home_link ne '';
1343         $evaluate_uri_force = eval "sub {$subroutine}" if $subroutine;
1344         $first_request = 1;
1345         evaluate_argv();
1346
1347         $pre_listen_hook->()
1348                 if $pre_listen_hook;
1349
1350  REQUEST:
1351         while ($cgi = $CGI->new()) {
1352                 $pre_dispatch_hook->()
1353                         if $pre_dispatch_hook;
1354
1355                 run_request();
1356
1357                 $post_dispatch_hook->()
1358                         if $post_dispatch_hook;
1359                 $first_request = 0;
1360
1361                 last REQUEST if ($is_last_request->());
1362         }
1363
1364  DONE_GITWEB:
1365         1;
1366 }
1367
1368 run();
1369
1370 if (defined caller) {
1371         # wrapped in a subroutine processing requests,
1372         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1373         return;
1374 } else {
1375         # pure CGI script, serving single request
1376         exit;
1377 }
1378
1379 ## ======================================================================
1380 ## action links
1381
1382 # possible values of extra options
1383 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1384 # -replay => 1      - start from a current view (replay with modifications)
1385 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1386 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1387 sub href {
1388         my %params = @_;
1389         # default is to use -absolute url() i.e. $my_uri
1390         my $href = $params{-full} ? $my_url : $my_uri;
1391
1392         # implicit -replay, must be first of implicit params
1393         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1394
1395         $params{'project'} = $project unless exists $params{'project'};
1396
1397         if ($params{-replay}) {
1398                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1399                         if (!exists $params{$name}) {
1400                                 $params{$name} = $input_params{$name};
1401                         }
1402                 }
1403         }
1404
1405         my $use_pathinfo = gitweb_check_feature('pathinfo');
1406         if (defined $params{'project'} &&
1407             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1408                 # try to put as many parameters as possible in PATH_INFO:
1409                 #   - project name
1410                 #   - action
1411                 #   - hash_parent or hash_parent_base:/file_parent
1412                 #   - hash or hash_base:/filename
1413                 #   - the snapshot_format as an appropriate suffix
1414
1415                 # When the script is the root DirectoryIndex for the domain,
1416                 # $href here would be something like http://gitweb.example.com/
1417                 # Thus, we strip any trailing / from $href, to spare us double
1418                 # slashes in the final URL
1419                 $href =~ s,/$,,;
1420
1421                 # Then add the project name, if present
1422                 $href .= "/".esc_path_info($params{'project'});
1423                 delete $params{'project'};
1424
1425                 # since we destructively absorb parameters, we keep this
1426                 # boolean that remembers if we're handling a snapshot
1427                 my $is_snapshot = $params{'action'} eq 'snapshot';
1428
1429                 # Summary just uses the project path URL, any other action is
1430                 # added to the URL
1431                 if (defined $params{'action'}) {
1432                         $href .= "/".esc_path_info($params{'action'})
1433                                 unless $params{'action'} eq 'summary';
1434                         delete $params{'action'};
1435                 }
1436
1437                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1438                 # stripping nonexistent or useless pieces
1439                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1440                         || $params{'hash_parent'} || $params{'hash'});
1441                 if (defined $params{'hash_base'}) {
1442                         if (defined $params{'hash_parent_base'}) {
1443                                 $href .= esc_path_info($params{'hash_parent_base'});
1444                                 # skip the file_parent if it's the same as the file_name
1445                                 if (defined $params{'file_parent'}) {
1446                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1447                                                 delete $params{'file_parent'};
1448                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1449                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1450                                                 delete $params{'file_parent'};
1451                                         }
1452                                 }
1453                                 $href .= "..";
1454                                 delete $params{'hash_parent'};
1455                                 delete $params{'hash_parent_base'};
1456                         } elsif (defined $params{'hash_parent'}) {
1457                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1458                                 delete $params{'hash_parent'};
1459                         }
1460
1461                         $href .= esc_path_info($params{'hash_base'});
1462                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1463                                 $href .= ":/".esc_path_info($params{'file_name'});
1464                                 delete $params{'file_name'};
1465                         }
1466                         delete $params{'hash'};
1467                         delete $params{'hash_base'};
1468                 } elsif (defined $params{'hash'}) {
1469                         $href .= esc_path_info($params{'hash'});
1470                         delete $params{'hash'};
1471                 }
1472
1473                 # If the action was a snapshot, we can absorb the
1474                 # snapshot_format parameter too
1475                 if ($is_snapshot) {
1476                         my $fmt = $params{'snapshot_format'};
1477                         # snapshot_format should always be defined when href()
1478                         # is called, but just in case some code forgets, we
1479                         # fall back to the default
1480                         $fmt ||= $snapshot_fmts[0];
1481                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1482                         delete $params{'snapshot_format'};
1483                 }
1484         }
1485
1486         # now encode the parameters explicitly
1487         my @result = ();
1488         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1489                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1490                 if (defined $params{$name}) {
1491                         if (ref($params{$name}) eq "ARRAY") {
1492                                 foreach my $par (@{$params{$name}}) {
1493                                         push @result, $symbol . "=" . esc_param($par);
1494                                 }
1495                         } else {
1496                                 push @result, $symbol . "=" . esc_param($params{$name});
1497                         }
1498                 }
1499         }
1500         $href .= "?" . join(';', @result) if scalar @result;
1501
1502         # final transformation: trailing spaces must be escaped (URI-encoded)
1503         $href =~ s/(\s+)$/CGI::escape($1)/e;
1504
1505         if ($params{-anchor}) {
1506                 $href .= "#".esc_param($params{-anchor});
1507         }
1508
1509         return $href;
1510 }
1511
1512
1513 ## ======================================================================
1514 ## validation, quoting/unquoting and escaping
1515
1516 sub is_valid_action {
1517         my $input = shift;
1518         return undef unless exists $actions{$input};
1519         return 1;
1520 }
1521
1522 sub is_valid_project {
1523         my $input = shift;
1524
1525         return unless defined $input;
1526         if (!is_valid_pathname($input) ||
1527                 !(-d "$projectroot/$input") ||
1528                 !check_export_ok("$projectroot/$input") ||
1529                 ($strict_export && !project_in_list($input))) {
1530                 return undef;
1531         } else {
1532                 return 1;
1533         }
1534 }
1535
1536 sub is_valid_pathname {
1537         my $input = shift;
1538
1539         return undef unless defined $input;
1540         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1541         # at the beginning, at the end, and between slashes.
1542         # also this catches doubled slashes
1543         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1544                 return undef;
1545         }
1546         # no null characters
1547         if ($input =~ m!\0!) {
1548                 return undef;
1549         }
1550         return 1;
1551 }
1552
1553 sub is_valid_ref_format {
1554         my $input = shift;
1555
1556         return undef unless defined $input;
1557         # restrictions on ref name according to git-check-ref-format
1558         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1559                 return undef;
1560         }
1561         return 1;
1562 }
1563
1564 sub is_valid_refname {
1565         my $input = shift;
1566
1567         return undef unless defined $input;
1568         # textual hashes are O.K.
1569         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1570                 return 1;
1571         }
1572         # it must be correct pathname
1573         is_valid_pathname($input) or return undef;
1574         # check git-check-ref-format restrictions
1575         is_valid_ref_format($input) or return undef;
1576         return 1;
1577 }
1578
1579 # decode sequences of octets in utf8 into Perl's internal form,
1580 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1581 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1582 sub to_utf8 {
1583         my $str = shift;
1584         return undef unless defined $str;
1585
1586         if (utf8::is_utf8($str) || utf8::decode($str)) {
1587                 return $str;
1588         } else {
1589                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1590         }
1591 }
1592
1593 # quote unsafe chars, but keep the slash, even when it's not
1594 # correct, but quoted slashes look too horrible in bookmarks
1595 sub esc_param {
1596         my $str = shift;
1597         return undef unless defined $str;
1598         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1599         $str =~ s/ /\+/g;
1600         return $str;
1601 }
1602
1603 # the quoting rules for path_info fragment are slightly different
1604 sub esc_path_info {
1605         my $str = shift;
1606         return undef unless defined $str;
1607
1608         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1609         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1610
1611         return $str;
1612 }
1613
1614 # quote unsafe chars in whole URL, so some characters cannot be quoted
1615 sub esc_url {
1616         my $str = shift;
1617         return undef unless defined $str;
1618         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1619         $str =~ s/ /\+/g;
1620         return $str;
1621 }
1622
1623 # quote unsafe characters in HTML attributes
1624 sub esc_attr {
1625
1626         # for XHTML conformance escaping '"' to '&quot;' is not enough
1627         return esc_html(@_);
1628 }
1629
1630 # replace invalid utf8 character with SUBSTITUTION sequence
1631 sub esc_html {
1632         my $str = shift;
1633         my %opts = @_;
1634
1635         return undef unless defined $str;
1636
1637         $str = to_utf8($str);
1638         $str = $cgi->escapeHTML($str);
1639         if ($opts{'-nbsp'}) {
1640                 $str =~ s/ /&nbsp;/g;
1641         }
1642         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1643         return $str;
1644 }
1645
1646 # quote control characters and escape filename to HTML
1647 sub esc_path {
1648         my $str = shift;
1649         my %opts = @_;
1650
1651         return undef unless defined $str;
1652
1653         $str = to_utf8($str);
1654         $str = $cgi->escapeHTML($str);
1655         if ($opts{'-nbsp'}) {
1656                 $str =~ s/ /&nbsp;/g;
1657         }
1658         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1659         return $str;
1660 }
1661
1662 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1663 sub sanitize {
1664         my $str = shift;
1665
1666         return undef unless defined $str;
1667
1668         $str = to_utf8($str);
1669         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1670         return $str;
1671 }
1672
1673 # Make control characters "printable", using character escape codes (CEC)
1674 sub quot_cec {
1675         my $cntrl = shift;
1676         my %opts = @_;
1677         my %es = ( # character escape codes, aka escape sequences
1678                 "\t" => '\t',   # tab            (HT)
1679                 "\n" => '\n',   # line feed      (LF)
1680                 "\r" => '\r',   # carrige return (CR)
1681                 "\f" => '\f',   # form feed      (FF)
1682                 "\b" => '\b',   # backspace      (BS)
1683                 "\a" => '\a',   # alarm (bell)   (BEL)
1684                 "\e" => '\e',   # escape         (ESC)
1685                 "\013" => '\v', # vertical tab   (VT)
1686                 "\000" => '\0', # nul character  (NUL)
1687         );
1688         my $chr = ( (exists $es{$cntrl})
1689                     ? $es{$cntrl}
1690                     : sprintf('\%2x', ord($cntrl)) );
1691         if ($opts{-nohtml}) {
1692                 return $chr;
1693         } else {
1694                 return "<span class=\"cntrl\">$chr</span>";
1695         }
1696 }
1697
1698 # Alternatively use unicode control pictures codepoints,
1699 # Unicode "printable representation" (PR)
1700 sub quot_upr {
1701         my $cntrl = shift;
1702         my %opts = @_;
1703
1704         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1705         if ($opts{-nohtml}) {
1706                 return $chr;
1707         } else {
1708                 return "<span class=\"cntrl\">$chr</span>";
1709         }
1710 }
1711
1712 # git may return quoted and escaped filenames
1713 sub unquote {
1714         my $str = shift;
1715
1716         sub unq {
1717                 my $seq = shift;
1718                 my %es = ( # character escape codes, aka escape sequences
1719                         't' => "\t",   # tab            (HT, TAB)
1720                         'n' => "\n",   # newline        (NL)
1721                         'r' => "\r",   # return         (CR)
1722                         'f' => "\f",   # form feed      (FF)
1723                         'b' => "\b",   # backspace      (BS)
1724                         'a' => "\a",   # alarm (bell)   (BEL)
1725                         'e' => "\e",   # escape         (ESC)
1726                         'v' => "\013", # vertical tab   (VT)
1727                 );
1728
1729                 if ($seq =~ m/^[0-7]{1,3}$/) {
1730                         # octal char sequence
1731                         return chr(oct($seq));
1732                 } elsif (exists $es{$seq}) {
1733                         # C escape sequence, aka character escape code
1734                         return $es{$seq};
1735                 }
1736                 # quoted ordinary character
1737                 return $seq;
1738         }
1739
1740         if ($str =~ m/^"(.*)"$/) {
1741                 # needs unquoting
1742                 $str = $1;
1743                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1744         }
1745         return $str;
1746 }
1747
1748 # escape tabs (convert tabs to spaces)
1749 sub untabify {
1750         my $line = shift;
1751
1752         while ((my $pos = index($line, "\t")) != -1) {
1753                 if (my $count = (8 - ($pos % 8))) {
1754                         my $spaces = ' ' x $count;
1755                         $line =~ s/\t/$spaces/;
1756                 }
1757         }
1758
1759         return $line;
1760 }
1761
1762 sub project_in_list {
1763         my $project = shift;
1764         my @list = git_get_projects_list();
1765         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1766 }
1767
1768 ## ----------------------------------------------------------------------
1769 ## HTML aware string manipulation
1770
1771 # Try to chop given string on a word boundary between position
1772 # $len and $len+$add_len. If there is no word boundary there,
1773 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1774 # (marking chopped part) would be longer than given string.
1775 sub chop_str {
1776         my $str = shift;
1777         my $len = shift;
1778         my $add_len = shift || 10;
1779         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1780
1781         # Make sure perl knows it is utf8 encoded so we don't
1782         # cut in the middle of a utf8 multibyte char.
1783         $str = to_utf8($str);
1784
1785         # allow only $len chars, but don't cut a word if it would fit in $add_len
1786         # if it doesn't fit, cut it if it's still longer than the dots we would add
1787         # remove chopped character entities entirely
1788
1789         # when chopping in the middle, distribute $len into left and right part
1790         # return early if chopping wouldn't make string shorter
1791         if ($where eq 'center') {
1792                 return $str if ($len + 5 >= length($str)); # filler is length 5
1793                 $len = int($len/2);
1794         } else {
1795                 return $str if ($len + 4 >= length($str)); # filler is length 4
1796         }
1797
1798         # regexps: ending and beginning with word part up to $add_len
1799         my $endre = qr/.{$len}\w{0,$add_len}/;
1800         my $begre = qr/\w{0,$add_len}.{$len}/;
1801
1802         if ($where eq 'left') {
1803                 $str =~ m/^(.*?)($begre)$/;
1804                 my ($lead, $body) = ($1, $2);
1805                 if (length($lead) > 4) {
1806                         $lead = " ...";
1807                 }
1808                 return "$lead$body";
1809
1810         } elsif ($where eq 'center') {
1811                 $str =~ m/^($endre)(.*)$/;
1812                 my ($left, $str)  = ($1, $2);
1813                 $str =~ m/^(.*?)($begre)$/;
1814                 my ($mid, $right) = ($1, $2);
1815                 if (length($mid) > 5) {
1816                         $mid = " ... ";
1817                 }
1818                 return "$left$mid$right";
1819
1820         } else {
1821                 $str =~ m/^($endre)(.*)$/;
1822                 my $body = $1;
1823                 my $tail = $2;
1824                 if (length($tail) > 4) {
1825                         $tail = "... ";
1826                 }
1827                 return "$body$tail";
1828         }
1829 }
1830
1831 # takes the same arguments as chop_str, but also wraps a <span> around the
1832 # result with a title attribute if it does get chopped. Additionally, the
1833 # string is HTML-escaped.
1834 sub chop_and_escape_str {
1835         my ($str) = @_;
1836
1837         my $chopped = chop_str(@_);
1838         $str = to_utf8($str);
1839         if ($chopped eq $str) {
1840                 return esc_html($chopped);
1841         } else {
1842                 $str =~ s/[[:cntrl:]]/?/g;
1843                 return $cgi->span({-title=>$str}, esc_html($chopped));
1844         }
1845 }
1846
1847 # Highlight selected fragments of string, using given CSS class,
1848 # and escape HTML.  It is assumed that fragments do not overlap.
1849 # Regions are passed as list of pairs (array references).
1850 #
1851 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1852 # '<span class="mark">foo</span>bar'
1853 sub esc_html_hl_regions {
1854         my ($str, $css_class, @sel) = @_;
1855         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1856         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1857         return esc_html($str, %opts) unless @sel;
1858
1859         my $out = '';
1860         my $pos = 0;
1861
1862         for my $s (@sel) {
1863                 my ($begin, $end) = @$s;
1864
1865                 # Don't create empty <span> elements.
1866                 next if $end <= $begin;
1867
1868                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1869                                        %opts);
1870
1871                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1872                         if ($begin - $pos > 0);
1873                 $out .= $cgi->span({-class => $css_class}, $escaped);
1874
1875                 $pos = $end;
1876         }
1877         $out .= esc_html(substr($str, $pos), %opts)
1878                 if ($pos < length($str));
1879
1880         return $out;
1881 }
1882
1883 # return positions of beginning and end of each match
1884 sub matchpos_list {
1885         my ($str, $regexp) = @_;
1886         return unless (defined $str && defined $regexp);
1887
1888         my @matches;
1889         while ($str =~ /$regexp/g) {
1890                 push @matches, [$-[0], $+[0]];
1891         }
1892         return @matches;
1893 }
1894
1895 # highlight match (if any), and escape HTML
1896 sub esc_html_match_hl {
1897         my ($str, $regexp) = @_;
1898         return esc_html($str) unless defined $regexp;
1899
1900         my @matches = matchpos_list($str, $regexp);
1901         return esc_html($str) unless @matches;
1902
1903         return esc_html_hl_regions($str, 'match', @matches);
1904 }
1905
1906
1907 # highlight match (if any) of shortened string, and escape HTML
1908 sub esc_html_match_hl_chopped {
1909         my ($str, $chopped, $regexp) = @_;
1910         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1911
1912         my @matches = matchpos_list($str, $regexp);
1913         return esc_html($chopped) unless @matches;
1914
1915         # filter matches so that we mark chopped string
1916         my $tail = "... "; # see chop_str
1917         unless ($chopped =~ s/\Q$tail\E$//) {
1918                 $tail = '';
1919         }
1920         my $chop_len = length($chopped);
1921         my $tail_len = length($tail);
1922         my @filtered;
1923
1924         for my $m (@matches) {
1925                 if ($m->[0] > $chop_len) {
1926                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1927                         last;
1928                 } elsif ($m->[1] > $chop_len) {
1929                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1930                         last;
1931                 }
1932                 push @filtered, $m;
1933         }
1934
1935         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1936 }
1937
1938 ## ----------------------------------------------------------------------
1939 ## functions returning short strings
1940
1941 # CSS class for given age value (in seconds)
1942 sub age_class {
1943         my $age = shift;
1944
1945         if (!defined $age) {
1946                 return "noage";
1947         } elsif ($age < 60*60*2) {
1948                 return "age0";
1949         } elsif ($age < 60*60*24*2) {
1950                 return "age1";
1951         } else {
1952                 return "age2";
1953         }
1954 }
1955
1956 # convert age in seconds to "nn units ago" string
1957 sub age_string {
1958         my $age = shift;
1959         my $age_str;
1960
1961         if ($age > 60*60*24*365*2) {
1962                 $age_str = (int $age/60/60/24/365);
1963                 $age_str .= " years ago";
1964         } elsif ($age > 60*60*24*(365/12)*2) {
1965                 $age_str = int $age/60/60/24/(365/12);
1966                 $age_str .= " months ago";
1967         } elsif ($age > 60*60*24*7*2) {
1968                 $age_str = int $age/60/60/24/7;
1969                 $age_str .= " weeks ago";
1970         } elsif ($age > 60*60*24*2) {
1971                 $age_str = int $age/60/60/24;
1972                 $age_str .= " days ago";
1973         } elsif ($age > 60*60*2) {
1974                 $age_str = int $age/60/60;
1975                 $age_str .= " hours ago";
1976         } elsif ($age > 60*2) {
1977                 $age_str = int $age/60;
1978                 $age_str .= " min ago";
1979         } elsif ($age > 2) {
1980                 $age_str = int $age;
1981                 $age_str .= " sec ago";
1982         } else {
1983                 $age_str .= " right now";
1984         }
1985         return $age_str;
1986 }
1987
1988 use constant {
1989         S_IFINVALID => 0030000,
1990         S_IFGITLINK => 0160000,
1991 };
1992
1993 # submodule/subproject, a commit object reference
1994 sub S_ISGITLINK {
1995         my $mode = shift;
1996
1997         return (($mode & S_IFMT) == S_IFGITLINK)
1998 }
1999
2000 # convert file mode in octal to symbolic file mode string
2001 sub mode_str {
2002         my $mode = oct shift;
2003
2004         if (S_ISGITLINK($mode)) {
2005                 return 'm---------';
2006         } elsif (S_ISDIR($mode & S_IFMT)) {
2007                 return 'drwxr-xr-x';
2008         } elsif (S_ISLNK($mode)) {
2009                 return 'lrwxrwxrwx';
2010         } elsif (S_ISREG($mode)) {
2011                 # git cares only about the executable bit
2012                 if ($mode & S_IXUSR) {
2013                         return '-rwxr-xr-x';
2014                 } else {
2015                         return '-rw-r--r--';
2016                 };
2017         } else {
2018                 return '----------';
2019         }
2020 }
2021
2022 # convert file mode in octal to file type string
2023 sub file_type {
2024         my $mode = shift;
2025
2026         if ($mode !~ m/^[0-7]+$/) {
2027                 return $mode;
2028         } else {
2029                 $mode = oct $mode;
2030         }
2031
2032         if (S_ISGITLINK($mode)) {
2033                 return "submodule";
2034         } elsif (S_ISDIR($mode & S_IFMT)) {
2035                 return "directory";
2036         } elsif (S_ISLNK($mode)) {
2037                 return "symlink";
2038         } elsif (S_ISREG($mode)) {
2039                 return "file";
2040         } else {
2041                 return "unknown";
2042         }
2043 }
2044
2045 # convert file mode in octal to file type description string
2046 sub file_type_long {
2047         my $mode = shift;
2048
2049         if ($mode !~ m/^[0-7]+$/) {
2050                 return $mode;
2051         } else {
2052                 $mode = oct $mode;
2053         }
2054
2055         if (S_ISGITLINK($mode)) {
2056                 return "submodule";
2057         } elsif (S_ISDIR($mode & S_IFMT)) {
2058                 return "directory";
2059         } elsif (S_ISLNK($mode)) {
2060                 return "symlink";
2061         } elsif (S_ISREG($mode)) {
2062                 if ($mode & S_IXUSR) {
2063                         return "executable";
2064                 } else {
2065                         return "file";
2066                 };
2067         } else {
2068                 return "unknown";
2069         }
2070 }
2071
2072
2073 ## ----------------------------------------------------------------------
2074 ## functions returning short HTML fragments, or transforming HTML fragments
2075 ## which don't belong to other sections
2076
2077 # format line of commit message.
2078 sub format_log_line_html {
2079         my $line = shift;
2080
2081         $line = esc_html($line, -nbsp=>1);
2082         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
2083                 $cgi->a({-href => href(action=>"object", hash=>$1),
2084                                         -class => "text"}, $1);
2085         }eg;
2086
2087         return $line;
2088 }
2089
2090 # format marker of refs pointing to given object
2091
2092 # the destination action is chosen based on object type and current context:
2093 # - for annotated tags, we choose the tag view unless it's the current view
2094 #   already, in which case we go to shortlog view
2095 # - for other refs, we keep the current view if we're in history, shortlog or
2096 #   log view, and select shortlog otherwise
2097 sub format_ref_marker {
2098         my ($refs, $id) = @_;
2099         my $markers = '';
2100
2101         if (defined $refs->{$id}) {
2102                 foreach my $ref (@{$refs->{$id}}) {
2103                         # this code exploits the fact that non-lightweight tags are the
2104                         # only indirect objects, and that they are the only objects for which
2105                         # we want to use tag instead of shortlog as action
2106                         my ($type, $name) = qw();
2107                         my $indirect = ($ref =~ s/\^\{\}$//);
2108                         # e.g. tags/v2.6.11 or heads/next
2109                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2110                                 $type = $1;
2111                                 $name = $2;
2112                         } else {
2113                                 $type = "ref";
2114                                 $name = $ref;
2115                         }
2116
2117                         my $class = $type;
2118                         $class .= " indirect" if $indirect;
2119
2120                         my $dest_action = "shortlog";
2121
2122                         if ($indirect) {
2123                                 $dest_action = "tag" unless $action eq "tag";
2124                         } elsif ($action =~ /^(history|(short)?log)$/) {
2125                                 $dest_action = $action;
2126                         }
2127
2128                         my $dest = "";
2129                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2130                         $dest .= $ref;
2131
2132                         my $link = $cgi->a({
2133                                 -href => href(
2134                                         action=>$dest_action,
2135                                         hash=>$dest
2136                                 )}, esc_html($name));
2137
2138                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2139                                 $link . "</span>";
2140                 }
2141         }
2142
2143         if ($markers) {
2144                 return ' <span class="refs">'. $markers . '</span>';
2145         } else {
2146                 return "";
2147         }
2148 }
2149
2150 # format, perhaps shortened and with markers, title line
2151 sub format_subject_html {
2152         my ($long, $short, $href, $extra) = @_;
2153         $extra = '' unless defined($extra);
2154
2155         if (length($short) < length($long)) {
2156                 $long =~ s/[[:cntrl:]]/?/g;
2157                 return $cgi->a({-href => $href, -class => "list subject",
2158                                 -title => to_utf8($long)},
2159                        esc_html($short)) . $extra;
2160         } else {
2161                 return $cgi->a({-href => $href, -class => "list subject"},
2162                        esc_html($long)) . $extra;
2163         }
2164 }
2165
2166 # Rather than recomputing the url for an email multiple times, we cache it
2167 # after the first hit. This gives a visible benefit in views where the avatar
2168 # for the same email is used repeatedly (e.g. shortlog).
2169 # The cache is shared by all avatar engines (currently gravatar only), which
2170 # are free to use it as preferred. Since only one avatar engine is used for any
2171 # given page, there's no risk for cache conflicts.
2172 our %avatar_cache = ();
2173
2174 # Compute the picon url for a given email, by using the picon search service over at
2175 # http://www.cs.indiana.edu/picons/search.html
2176 sub picon_url {
2177         my $email = lc shift;
2178         if (!$avatar_cache{$email}) {
2179                 my ($user, $domain) = split('@', $email);
2180                 $avatar_cache{$email} =
2181                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2182                         "$domain/$user/" .
2183                         "users+domains+unknown/up/single";
2184         }
2185         return $avatar_cache{$email};
2186 }
2187
2188 # Compute the gravatar url for a given email, if it's not in the cache already.
2189 # Gravatar stores only the part of the URL before the size, since that's the
2190 # one computationally more expensive. This also allows reuse of the cache for
2191 # different sizes (for this particular engine).
2192 sub gravatar_url {
2193         my $email = lc shift;
2194         my $size = shift;
2195         $avatar_cache{$email} ||=
2196                 "//www.gravatar.com/avatar/" .
2197                         Digest::MD5::md5_hex($email) . "?s=";
2198         return $avatar_cache{$email} . $size;
2199 }
2200
2201 # Insert an avatar for the given $email at the given $size if the feature
2202 # is enabled.
2203 sub git_get_avatar {
2204         my ($email, %opts) = @_;
2205         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2206         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2207         $opts{-size} ||= 'default';
2208         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2209         my $url = "";
2210         if ($git_avatar eq 'gravatar') {
2211                 $url = gravatar_url($email, $size);
2212         } elsif ($git_avatar eq 'picon') {
2213                 $url = picon_url($email);
2214         }
2215         # Other providers can be added by extending the if chain, defining $url
2216         # as needed. If no variant puts something in $url, we assume avatars
2217         # are completely disabled/unavailable.
2218         if ($url) {
2219                 return $pre_white .
2220                        "<img width=\"$size\" " .
2221                             "class=\"avatar\" " .
2222                             "src=\"".esc_url($url)."\" " .
2223                             "alt=\"\" " .
2224                        "/>" . $post_white;
2225         } else {
2226                 return "";
2227         }
2228 }
2229
2230 sub format_search_author {
2231         my ($author, $searchtype, $displaytext) = @_;
2232         my $have_search = gitweb_check_feature('search');
2233
2234         if ($have_search) {
2235                 my $performed = "";
2236                 if ($searchtype eq 'author') {
2237                         $performed = "authored";
2238                 } elsif ($searchtype eq 'committer') {
2239                         $performed = "committed";
2240                 }
2241
2242                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2243                                 searchtext=>$author,
2244                                 searchtype=>$searchtype), class=>"list",
2245                                 title=>"Search for commits $performed by $author"},
2246                                 $displaytext);
2247
2248         } else {
2249                 return $displaytext;
2250         }
2251 }
2252
2253 # format the author name of the given commit with the given tag
2254 # the author name is chopped and escaped according to the other
2255 # optional parameters (see chop_str).
2256 sub format_author_html {
2257         my $tag = shift;
2258         my $co = shift;
2259         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2260         return "<$tag class=\"author\">" .
2261                format_search_author($co->{'author_name'}, "author",
2262                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2263                        $author) .
2264                "</$tag>";
2265 }
2266
2267 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2268 sub format_git_diff_header_line {
2269         my $line = shift;
2270         my $diffinfo = shift;
2271         my ($from, $to) = @_;
2272
2273         if ($diffinfo->{'nparents'}) {
2274                 # combined diff
2275                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2276                 if ($to->{'href'}) {
2277                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2278                                          esc_path($to->{'file'}));
2279                 } else { # file was deleted (no href)
2280                         $line .= esc_path($to->{'file'});
2281                 }
2282         } else {
2283                 # "ordinary" diff
2284                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2285                 if ($from->{'href'}) {
2286                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2287                                          'a/' . esc_path($from->{'file'}));
2288                 } else { # file was added (no href)
2289                         $line .= 'a/' . esc_path($from->{'file'});
2290                 }
2291                 $line .= ' ';
2292                 if ($to->{'href'}) {
2293                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2294                                          'b/' . esc_path($to->{'file'}));
2295                 } else { # file was deleted
2296                         $line .= 'b/' . esc_path($to->{'file'});
2297                 }
2298         }
2299
2300         return "<div class=\"diff header\">$line</div>\n";
2301 }
2302
2303 # format extended diff header line, before patch itself
2304 sub format_extended_diff_header_line {
2305         my $line = shift;
2306         my $diffinfo = shift;
2307         my ($from, $to) = @_;
2308
2309         # match <path>
2310         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2311                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2312                                        esc_path($from->{'file'}));
2313         }
2314         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2315                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2316                                  esc_path($to->{'file'}));
2317         }
2318         # match single <mode>
2319         if ($line =~ m/\s(\d{6})$/) {
2320                 $line .= '<span class="info"> (' .
2321                          file_type_long($1) .
2322                          ')</span>';
2323         }
2324         # match <hash>
2325         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2326                 # can match only for combined diff
2327                 $line = 'index ';
2328                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2329                         if ($from->{'href'}[$i]) {
2330                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2331                                                   -class=>"hash"},
2332                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2333                         } else {
2334                                 $line .= '0' x 7;
2335                         }
2336                         # separator
2337                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2338                 }
2339                 $line .= '..';
2340                 if ($to->{'href'}) {
2341                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2342                                          substr($diffinfo->{'to_id'},0,7));
2343                 } else {
2344                         $line .= '0' x 7;
2345                 }
2346
2347         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2348                 # can match only for ordinary diff
2349                 my ($from_link, $to_link);
2350                 if ($from->{'href'}) {
2351                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2352                                              substr($diffinfo->{'from_id'},0,7));
2353                 } else {
2354                         $from_link = '0' x 7;
2355                 }
2356                 if ($to->{'href'}) {
2357                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2358                                            substr($diffinfo->{'to_id'},0,7));
2359                 } else {
2360                         $to_link = '0' x 7;
2361                 }
2362                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2363                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2364         }
2365
2366         return $line . "<br/>\n";
2367 }
2368
2369 # format from-file/to-file diff header
2370 sub format_diff_from_to_header {
2371         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2372         my $line;
2373         my $result = '';
2374
2375         $line = $from_line;
2376         #assert($line =~ m/^---/) if DEBUG;
2377         # no extra formatting for "^--- /dev/null"
2378         if (! $diffinfo->{'nparents'}) {
2379                 # ordinary (single parent) diff
2380                 if ($line =~ m!^--- "?a/!) {
2381                         if ($from->{'href'}) {
2382                                 $line = '--- a/' .
2383                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2384                                                 esc_path($from->{'file'}));
2385                         } else {
2386                                 $line = '--- a/' .
2387                                         esc_path($from->{'file'});
2388                         }
2389                 }
2390                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2391
2392         } else {
2393                 # combined diff (merge commit)
2394                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2395                         if ($from->{'href'}[$i]) {
2396                                 $line = '--- ' .
2397                                         $cgi->a({-href=>href(action=>"blobdiff",
2398                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2399                                                              hash_parent_base=>$parents[$i],
2400                                                              file_parent=>$from->{'file'}[$i],
2401                                                              hash=>$diffinfo->{'to_id'},
2402                                                              hash_base=>$hash,
2403                                                              file_name=>$to->{'file'}),
2404                                                  -class=>"path",
2405                                                  -title=>"diff" . ($i+1)},
2406                                                 $i+1) .
2407                                         '/' .
2408                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2409                                                 esc_path($from->{'file'}[$i]));
2410                         } else {
2411                                 $line = '--- /dev/null';
2412                         }
2413                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2414                 }
2415         }
2416
2417         $line = $to_line;
2418         #assert($line =~ m/^\+\+\+/) if DEBUG;
2419         # no extra formatting for "^+++ /dev/null"
2420         if ($line =~ m!^\+\+\+ "?b/!) {
2421                 if ($to->{'href'}) {
2422                         $line = '+++ b/' .
2423                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2424                                         esc_path($to->{'file'}));
2425                 } else {
2426                         $line = '+++ b/' .
2427                                 esc_path($to->{'file'});
2428                 }
2429         }
2430         $result .= qq!<div class="diff to_file">$line</div>\n!;
2431
2432         return $result;
2433 }
2434
2435 # create note for patch simplified by combined diff
2436 sub format_diff_cc_simplified {
2437         my ($diffinfo, @parents) = @_;
2438         my $result = '';
2439
2440         $result .= "<div class=\"diff header\">" .
2441                    "diff --cc ";
2442         if (!is_deleted($diffinfo)) {
2443                 $result .= $cgi->a({-href => href(action=>"blob",
2444                                                   hash_base=>$hash,
2445                                                   hash=>$diffinfo->{'to_id'},
2446                                                   file_name=>$diffinfo->{'to_file'}),
2447                                     -class => "path"},
2448                                    esc_path($diffinfo->{'to_file'}));
2449         } else {
2450                 $result .= esc_path($diffinfo->{'to_file'});
2451         }
2452         $result .= "</div>\n" . # class="diff header"
2453                    "<div class=\"diff nodifferences\">" .
2454                    "Simple merge" .
2455                    "</div>\n"; # class="diff nodifferences"
2456
2457         return $result;
2458 }
2459
2460 sub diff_line_class {
2461         my ($line, $from, $to) = @_;
2462
2463         # ordinary diff
2464         my $num_sign = 1;
2465         # combined diff
2466         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2467                 $num_sign = scalar @{$from->{'href'}};
2468         }
2469
2470         my @diff_line_classifier = (
2471                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2472                 { regexp => qr/^\\/,               class => "incomplete"  },
2473                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2474                 # classifier for context must come before classifier add/rem,
2475                 # or we would have to use more complicated regexp, for example
2476                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2477                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2478                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2479         );
2480         for my $clsfy (@diff_line_classifier) {
2481                 return $clsfy->{'class'}
2482                         if ($line =~ $clsfy->{'regexp'});
2483         }
2484
2485         # fallback
2486         return "";
2487 }
2488
2489 # assumes that $from and $to are defined and correctly filled,
2490 # and that $line holds a line of chunk header for unified diff
2491 sub format_unidiff_chunk_header {
2492         my ($line, $from, $to) = @_;
2493
2494         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2495                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2496
2497         $from_lines = 0 unless defined $from_lines;
2498         $to_lines   = 0 unless defined $to_lines;
2499
2500         if ($from->{'href'}) {
2501                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2502                                      -class=>"list"}, $from_text);
2503         }
2504         if ($to->{'href'}) {
2505                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2506                                      -class=>"list"}, $to_text);
2507         }
2508         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2509                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2510         return $line;
2511 }
2512
2513 # assumes that $from and $to are defined and correctly filled,
2514 # and that $line holds a line of chunk header for combined diff
2515 sub format_cc_diff_chunk_header {
2516         my ($line, $from, $to) = @_;
2517
2518         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2519         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2520
2521         @from_text = split(' ', $ranges);
2522         for (my $i = 0; $i < @from_text; ++$i) {
2523                 ($from_start[$i], $from_nlines[$i]) =
2524                         (split(',', substr($from_text[$i], 1)), 0);
2525         }
2526
2527         $to_text   = pop @from_text;
2528         $to_start  = pop @from_start;
2529         $to_nlines = pop @from_nlines;
2530
2531         $line = "<span class=\"chunk_info\">$prefix ";
2532         for (my $i = 0; $i < @from_text; ++$i) {
2533                 if ($from->{'href'}[$i]) {
2534                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2535                                           -class=>"list"}, $from_text[$i]);
2536                 } else {
2537                         $line .= $from_text[$i];
2538                 }
2539                 $line .= " ";
2540         }
2541         if ($to->{'href'}) {
2542                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2543                                   -class=>"list"}, $to_text);
2544         } else {
2545                 $line .= $to_text;
2546         }
2547         $line .= " $prefix</span>" .
2548                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2549         return $line;
2550 }
2551
2552 # process patch (diff) line (not to be used for diff headers),
2553 # returning HTML-formatted (but not wrapped) line.
2554 # If the line is passed as a reference, it is treated as HTML and not
2555 # esc_html()'ed.
2556 sub format_diff_line {
2557         my ($line, $diff_class, $from, $to) = @_;
2558
2559         if (ref($line)) {
2560                 $line = $$line;
2561         } else {
2562                 chomp $line;
2563                 $line = untabify($line);
2564
2565                 if ($from && $to && $line =~ m/^\@{2} /) {
2566                         $line = format_unidiff_chunk_header($line, $from, $to);
2567                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2568                         $line = format_cc_diff_chunk_header($line, $from, $to);
2569                 } else {
2570                         $line = esc_html($line, -nbsp=>1);
2571                 }
2572         }
2573
2574         my $diff_classes = "diff";
2575         $diff_classes .= " $diff_class" if ($diff_class);
2576         $line = "<div class=\"$diff_classes\">$line</div>\n";
2577
2578         return $line;
2579 }
2580
2581 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2582 # linked.  Pass the hash of the tree/commit to snapshot.
2583 sub format_snapshot_links {
2584         my ($hash) = @_;
2585         my $num_fmts = @snapshot_fmts;
2586         if ($num_fmts > 1) {
2587                 # A parenthesized list of links bearing format names.
2588                 # e.g. "snapshot (_tar.gz_ _zip_)"
2589                 return "snapshot (" . join(' ', map
2590                         $cgi->a({
2591                                 -href => href(
2592                                         action=>"snapshot",
2593                                         hash=>$hash,
2594                                         snapshot_format=>$_
2595                                 )
2596                         }, $known_snapshot_formats{$_}{'display'})
2597                 , @snapshot_fmts) . ")";
2598         } elsif ($num_fmts == 1) {
2599                 # A single "snapshot" link whose tooltip bears the format name.
2600                 # i.e. "_snapshot_"
2601                 my ($fmt) = @snapshot_fmts;
2602                 return
2603                         $cgi->a({
2604                                 -href => href(
2605                                         action=>"snapshot",
2606                                         hash=>$hash,
2607                                         snapshot_format=>$fmt
2608                                 ),
2609                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2610                         }, "snapshot");
2611         } else { # $num_fmts == 0
2612                 return undef;
2613         }
2614 }
2615
2616 ## ......................................................................
2617 ## functions returning values to be passed, perhaps after some
2618 ## transformation, to other functions; e.g. returning arguments to href()
2619
2620 # returns hash to be passed to href to generate gitweb URL
2621 # in -title key it returns description of link
2622 sub get_feed_info {
2623         my $format = shift || 'Atom';
2624         my %res = (action => lc($format));
2625         my $matched_ref = 0;
2626
2627         # feed links are possible only for project views
2628         return unless (defined $project);
2629         # some views should link to OPML, or to generic project feed,
2630         # or don't have specific feed yet (so they should use generic)
2631         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2632
2633         my $branch = undef;
2634         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2635         # (fullname) to differentiate from tag links; this also makes
2636         # possible to detect branch links
2637         for my $ref (get_branch_refs()) {
2638                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2639                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2640                         $branch = $1;
2641                         $matched_ref = $ref;
2642                         last;
2643                 }
2644         }
2645         # find log type for feed description (title)
2646         my $type = 'log';
2647         if (defined $file_name) {
2648                 $type  = "history of $file_name";
2649                 $type .= "/" if ($action eq 'tree');
2650                 $type .= " on '$branch'" if (defined $branch);
2651         } else {
2652                 $type = "log of $branch" if (defined $branch);
2653         }
2654
2655         $res{-title} = $type;
2656         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2657         $res{'file_name'} = $file_name;
2658
2659         return %res;
2660 }
2661
2662 ## ----------------------------------------------------------------------
2663 ## git utility subroutines, invoking git commands
2664
2665 # returns path to the core git executable and the --git-dir parameter as list
2666 sub git_cmd {
2667         $number_of_git_cmds++;
2668         return $GIT, '--git-dir='.$git_dir;
2669 }
2670
2671 # quote the given arguments for passing them to the shell
2672 # quote_command("command", "arg 1", "arg with ' and ! characters")
2673 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2674 # Try to avoid using this function wherever possible.
2675 sub quote_command {
2676         return join(' ',
2677                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2678 }
2679
2680 # get HEAD ref of given project as hash
2681 sub git_get_head_hash {
2682         return git_get_full_hash(shift, 'HEAD');
2683 }
2684
2685 sub git_get_full_hash {
2686         return git_get_hash(@_);
2687 }
2688
2689 sub git_get_short_hash {
2690         return git_get_hash(@_, '--short=7');
2691 }
2692
2693 sub git_get_hash {
2694         my ($project, $hash, @options) = @_;
2695         my $o_git_dir = $git_dir;
2696         my $retval = undef;
2697         $git_dir = "$projectroot/$project";
2698         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2699             '--verify', '-q', @options, $hash) {
2700                 $retval = <$fd>;
2701                 chomp $retval if defined $retval;
2702                 close $fd;
2703         }
2704         if (defined $o_git_dir) {
2705                 $git_dir = $o_git_dir;
2706         }
2707         return $retval;
2708 }
2709
2710 # get type of given object
2711 sub git_get_type {
2712         my $hash = shift;
2713
2714         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2715         my $type = <$fd>;
2716         close $fd or return;
2717         chomp $type;
2718         return $type;
2719 }
2720
2721 # repository configuration
2722 our $config_file = '';
2723 our %config;
2724
2725 # store multiple values for single key as anonymous array reference
2726 # single values stored directly in the hash, not as [ <value> ]
2727 sub hash_set_multi {
2728         my ($hash, $key, $value) = @_;
2729
2730         if (!exists $hash->{$key}) {
2731                 $hash->{$key} = $value;
2732         } elsif (!ref $hash->{$key}) {
2733                 $hash->{$key} = [ $hash->{$key}, $value ];
2734         } else {
2735                 push @{$hash->{$key}}, $value;
2736         }
2737 }
2738
2739 # return hash of git project configuration
2740 # optionally limited to some section, e.g. 'gitweb'
2741 sub git_parse_project_config {
2742         my $section_regexp = shift;
2743         my %config;
2744
2745         local $/ = "\0";
2746
2747         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2748                 or return;
2749
2750         while (my $keyval = <$fh>) {
2751                 chomp $keyval;
2752                 my ($key, $value) = split(/\n/, $keyval, 2);
2753
2754                 hash_set_multi(\%config, $key, $value)
2755                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2756         }
2757         close $fh;
2758
2759         return %config;
2760 }
2761
2762 # convert config value to boolean: 'true' or 'false'
2763 # no value, number > 0, 'true' and 'yes' values are true
2764 # rest of values are treated as false (never as error)
2765 sub config_to_bool {
2766         my $val = shift;
2767
2768         return 1 if !defined $val;             # section.key
2769
2770         # strip leading and trailing whitespace
2771         $val =~ s/^\s+//;
2772         $val =~ s/\s+$//;
2773
2774         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2775                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2776 }
2777
2778 # convert config value to simple decimal number
2779 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2780 # to be multiplied by 1024, 1048576, or 1073741824
2781 sub config_to_int {
2782         my $val = shift;
2783
2784         # strip leading and trailing whitespace
2785         $val =~ s/^\s+//;
2786         $val =~ s/\s+$//;
2787
2788         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2789                 $unit = lc($unit);
2790                 # unknown unit is treated as 1
2791                 return $num * ($unit eq 'g' ? 1073741824 :
2792                                $unit eq 'm' ?    1048576 :
2793                                $unit eq 'k' ?       1024 : 1);
2794         }
2795         return $val;
2796 }
2797
2798 # convert config value to array reference, if needed
2799 sub config_to_multi {
2800         my $val = shift;
2801
2802         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2803 }
2804
2805 sub git_get_project_config {
2806         my ($key, $type) = @_;
2807
2808         return unless defined $git_dir;
2809
2810         # key sanity check
2811         return unless ($key);
2812         # only subsection, if exists, is case sensitive,
2813         # and not lowercased by 'git config -z -l'
2814         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2815                 $lo =~ s/_//g;
2816                 $key = join(".", lc($hi), $mi, lc($lo));
2817                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2818         } else {
2819                 $key = lc($key);
2820                 $key =~ s/_//g;
2821                 return if ($key =~ /\W/);
2822         }
2823         $key =~ s/^gitweb\.//;
2824
2825         # type sanity check
2826         if (defined $type) {
2827                 $type =~ s/^--//;
2828                 $type = undef
2829                         unless ($type eq 'bool' || $type eq 'int');
2830         }
2831
2832         # get config
2833         if (!defined $config_file ||
2834             $config_file ne "$git_dir/config") {
2835                 %config = git_parse_project_config('gitweb');
2836                 $config_file = "$git_dir/config";
2837         }
2838
2839         # check if config variable (key) exists
2840         return unless exists $config{"gitweb.$key"};
2841
2842         # ensure given type
2843         if (!defined $type) {
2844                 return $config{"gitweb.$key"};
2845         } elsif ($type eq 'bool') {
2846                 # backward compatibility: 'git config --bool' returns true/false
2847                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2848         } elsif ($type eq 'int') {
2849                 return config_to_int($config{"gitweb.$key"});
2850         }
2851         return $config{"gitweb.$key"};
2852 }
2853
2854 # get hash of given path at given ref
2855 sub git_get_hash_by_path {
2856         my $base = shift;
2857         my $path = shift || return undef;
2858         my $type = shift;
2859
2860         $path =~ s,/+$,,;
2861
2862         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2863                 or die_error(500, "Open git-ls-tree failed");
2864         my $line = <$fd>;
2865         close $fd or return undef;
2866
2867         if (!defined $line) {
2868                 # there is no tree or hash given by $path at $base
2869                 return undef;
2870         }
2871
2872         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2873         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2874         if (defined $type && $type ne $2) {
2875                 # type doesn't match
2876                 return undef;
2877         }
2878         return $3;
2879 }
2880
2881 # get path of entry with given hash at given tree-ish (ref)
2882 # used to get 'from' filename for combined diff (merge commit) for renames
2883 sub git_get_path_by_hash {
2884         my $base = shift || return;
2885         my $hash = shift || return;
2886
2887         local $/ = "\0";
2888
2889         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2890                 or return undef;
2891         while (my $line = <$fd>) {
2892                 chomp $line;
2893
2894                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2895                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2896                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2897                         close $fd;
2898                         return $1;
2899                 }
2900         }
2901         close $fd;
2902         return undef;
2903 }
2904
2905 ## ......................................................................
2906 ## git utility functions, directly accessing git repository
2907
2908 # get the value of config variable either from file named as the variable
2909 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2910 # configuration variable in the repository config file.
2911 sub git_get_file_or_project_config {
2912         my ($path, $name) = @_;
2913
2914         $git_dir = "$projectroot/$path";
2915         open my $fd, '<', "$git_dir/$name"
2916                 or return git_get_project_config($name);
2917         my $conf = <$fd>;
2918         close $fd;
2919         if (defined $conf) {
2920                 chomp $conf;
2921         }
2922         return $conf;
2923 }
2924
2925 sub git_get_project_description {
2926         my $path = shift;
2927         return git_get_file_or_project_config($path, 'description');
2928 }
2929
2930 sub git_get_project_category {
2931         my $path = shift;
2932         return git_get_file_or_project_config($path, 'category');
2933 }
2934
2935
2936 # supported formats:
2937 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2938 #   - if its contents is a number, use it as tag weight,
2939 #   - otherwise add a tag with weight 1
2940 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2941 #   the same value multiple times increases tag weight
2942 # * `gitweb.ctag' multi-valued repo config variable
2943 sub git_get_project_ctags {
2944         my $project = shift;
2945         my $ctags = {};
2946
2947         $git_dir = "$projectroot/$project";
2948         if (opendir my $dh, "$git_dir/ctags") {
2949                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2950                 foreach my $tagfile (@files) {
2951                         open my $ct, '<', $tagfile
2952                                 or next;
2953                         my $val = <$ct>;
2954                         chomp $val if $val;
2955                         close $ct;
2956
2957                         (my $ctag = $tagfile) =~ s#.*/##;
2958                         if ($val =~ /^\d+$/) {
2959                                 $ctags->{$ctag} = $val;
2960                         } else {
2961                                 $ctags->{$ctag} = 1;
2962                         }
2963                 }
2964                 closedir $dh;
2965
2966         } elsif (open my $fh, '<', "$git_dir/ctags") {
2967                 while (my $line = <$fh>) {
2968                         chomp $line;
2969                         $ctags->{$line}++ if $line;
2970                 }
2971                 close $fh;
2972
2973         } else {
2974                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2975                 foreach my $tag (@$taglist) {
2976                         $ctags->{$tag}++;
2977                 }
2978         }
2979
2980         return $ctags;
2981 }
2982
2983 # return hash, where keys are content tags ('ctags'),
2984 # and values are sum of weights of given tag in every project
2985 sub git_gather_all_ctags {
2986         my $projects = shift;
2987         my $ctags = {};
2988
2989         foreach my $p (@$projects) {
2990                 foreach my $ct (keys %{$p->{'ctags'}}) {
2991                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2992                 }
2993         }
2994
2995         return $ctags;
2996 }
2997
2998 sub git_populate_project_tagcloud {
2999         my $ctags = shift;
3000
3001         # First, merge different-cased tags; tags vote on casing
3002         my %ctags_lc;
3003         foreach (keys %$ctags) {
3004                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
3005                 if (not $ctags_lc{lc $_}->{topcount}
3006                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
3007                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
3008                         $ctags_lc{lc $_}->{topname} = $_;
3009                 }
3010         }
3011
3012         my $cloud;
3013         my $matched = $input_params{'ctag'};
3014         if (eval { require HTML::TagCloud; 1; }) {
3015                 $cloud = HTML::TagCloud->new;
3016                 foreach my $ctag (sort keys %ctags_lc) {
3017                         # Pad the title with spaces so that the cloud looks
3018                         # less crammed.
3019                         my $title = esc_html($ctags_lc{$ctag}->{topname});
3020                         $title =~ s/ /&nbsp;/g;
3021                         $title =~ s/^/&nbsp;/g;
3022                         $title =~ s/$/&nbsp;/g;
3023                         if (defined $matched && $matched eq $ctag) {
3024                                 $title = qq(<span class="match">$title</span>);
3025                         }
3026                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3027                                     $ctags_lc{$ctag}->{count});
3028                 }
3029         } else {
3030                 $cloud = {};
3031                 foreach my $ctag (keys %ctags_lc) {
3032                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3033                         if (defined $matched && $matched eq $ctag) {
3034                                 $title = qq(<span class="match">$title</span>);
3035                         }
3036                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3037                         $cloud->{$ctag}{ctag} =
3038                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3039                 }
3040         }
3041         return $cloud;
3042 }
3043
3044 sub git_show_project_tagcloud {
3045         my ($cloud, $count) = @_;
3046         if (ref $cloud eq 'HTML::TagCloud') {
3047                 return $cloud->html_and_css($count);
3048         } else {
3049                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3050                 return
3051                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3052                         join (', ', map {
3053                                 $cloud->{$_}->{'ctag'}
3054                         } splice(@tags, 0, $count)) .
3055                         '</div>';
3056         }
3057 }
3058
3059 sub git_get_project_url_list {
3060         my $path = shift;
3061
3062         $git_dir = "$projectroot/$path";
3063         open my $fd, '<', "$git_dir/cloneurl"
3064                 or return wantarray ?
3065                 @{ config_to_multi(git_get_project_config('url')) } :
3066                    config_to_multi(git_get_project_config('url'));
3067         my @git_project_url_list = map { chomp; $_ } <$fd>;
3068         close $fd;
3069
3070         return wantarray ? @git_project_url_list : \@git_project_url_list;
3071 }
3072
3073 sub git_get_projects_list {
3074         my $filter = shift || '';
3075         my $paranoid = shift;
3076         my @list;
3077
3078         if (-d $projects_list) {
3079                 # search in directory
3080                 my $dir = $projects_list;
3081                 # remove the trailing "/"
3082                 $dir =~ s!/+$!!;
3083                 my $pfxlen = length("$dir");
3084                 my $pfxdepth = ($dir =~ tr!/!!);
3085                 # when filtering, search only given subdirectory
3086                 if ($filter && !$paranoid) {
3087                         $dir .= "/$filter";
3088                         $dir =~ s!/+$!!;
3089                 }
3090
3091                 File::Find::find({
3092                         follow_fast => 1, # follow symbolic links
3093                         follow_skip => 2, # ignore duplicates
3094                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3095                         wanted => sub {
3096                                 # global variables
3097                                 our $project_maxdepth;
3098                                 our $projectroot;
3099                                 # skip project-list toplevel, if we get it.
3100                                 return if (m!^[/.]$!);
3101                                 # only directories can be git repositories
3102                                 return unless (-d $_);
3103                                 # don't traverse too deep (Find is super slow on os x)
3104                                 # $project_maxdepth excludes depth of $projectroot
3105                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3106                                         $File::Find::prune = 1;
3107                                         return;
3108                                 }
3109
3110                                 my $path = substr($File::Find::name, $pfxlen + 1);
3111                                 # paranoidly only filter here
3112                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3113                                         next;
3114                                 }
3115                                 # we check related file in $projectroot
3116                                 if (check_export_ok("$projectroot/$path")) {
3117                                         push @list, { path => $path };
3118                                         $File::Find::prune = 1;
3119                                 }
3120                         },
3121                 }, "$dir");
3122
3123         } elsif (-f $projects_list) {
3124                 # read from file(url-encoded):
3125                 # 'git%2Fgit.git Linus+Torvalds'
3126                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3127                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3128                 open my $fd, '<', $projects_list or return;
3129         PROJECT:
3130                 while (my $line = <$fd>) {
3131                         chomp $line;
3132                         my ($path, $owner) = split ' ', $line;
3133                         $path = unescape($path);
3134                         $owner = unescape($owner);
3135                         if (!defined $path) {
3136                                 next;
3137                         }
3138                         # if $filter is rpovided, check if $path begins with $filter
3139                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3140                                 next;
3141                         }
3142                         if (check_export_ok("$projectroot/$path")) {
3143                                 my $pr = {
3144                                         path => $path
3145                                 };
3146                                 if ($owner) {
3147                                         $pr->{'owner'} = to_utf8($owner);
3148                                 }
3149                                 push @list, $pr;
3150                         }
3151                 }
3152                 close $fd;
3153         }
3154         return @list;
3155 }
3156
3157 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3158 # as side effects it sets 'forks' field to list of forks for forked projects
3159 sub filter_forks_from_projects_list {
3160         my $projects = shift;
3161
3162         my %trie; # prefix tree of directories (path components)
3163         # generate trie out of those directories that might contain forks
3164         foreach my $pr (@$projects) {
3165                 my $path = $pr->{'path'};
3166                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3167                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3168                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3169                 next unless (-d "$projectroot/$path"); # containing directory exists
3170                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3171
3172                 # add to trie
3173                 my @dirs = split('/', $path);
3174                 # walk the trie, until either runs out of components or out of trie
3175                 my $ref = \%trie;
3176                 while (scalar @dirs &&
3177                        exists($ref->{$dirs[0]})) {
3178                         $ref = $ref->{shift @dirs};
3179                 }
3180                 # create rest of trie structure from rest of components
3181                 foreach my $dir (@dirs) {
3182                         $ref = $ref->{$dir} = {};
3183                 }
3184                 # create end marker, store $pr as a data
3185                 $ref->{''} = $pr if (!exists $ref->{''});
3186         }
3187
3188         # filter out forks, by finding shortest prefix match for paths
3189         my @filtered;
3190  PROJECT:
3191         foreach my $pr (@$projects) {
3192                 # trie lookup
3193                 my $ref = \%trie;
3194         DIR:
3195                 foreach my $dir (split('/', $pr->{'path'})) {
3196                         if (exists $ref->{''}) {
3197                                 # found [shortest] prefix, is a fork - skip it
3198                                 push @{$ref->{''}{'forks'}}, $pr;
3199                                 next PROJECT;
3200                         }
3201                         if (!exists $ref->{$dir}) {
3202                                 # not in trie, cannot have prefix, not a fork
3203                                 push @filtered, $pr;
3204                                 next PROJECT;
3205                         }
3206                         # If the dir is there, we just walk one step down the trie.
3207                         $ref = $ref->{$dir};
3208                 }
3209                 # we ran out of trie
3210                 # (shouldn't happen: it's either no match, or end marker)
3211                 push @filtered, $pr;
3212         }
3213
3214         return @filtered;
3215 }
3216
3217 # note: fill_project_list_info must be run first,
3218 # for 'descr_long' and 'ctags' to be filled
3219 sub search_projects_list {
3220         my ($projlist, %opts) = @_;
3221         my $tagfilter  = $opts{'tagfilter'};
3222         my $search_re = $opts{'search_regexp'};
3223
3224         return @$projlist
3225                 unless ($tagfilter || $search_re);
3226
3227         # searching projects require filling to be run before it;
3228         fill_project_list_info($projlist,
3229                                $tagfilter  ? 'ctags' : (),
3230                                $search_re ? ('path', 'descr') : ());
3231         my @projects;
3232  PROJECT:
3233         foreach my $pr (@$projlist) {
3234
3235                 if ($tagfilter) {
3236                         next unless ref($pr->{'ctags'}) eq 'HASH';
3237                         next unless
3238                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3239                 }
3240
3241                 if ($search_re) {
3242                         next unless
3243                                 $pr->{'path'} =~ /$search_re/ ||
3244                                 $pr->{'descr_long'} =~ /$search_re/;
3245                 }
3246
3247                 push @projects, $pr;
3248         }
3249
3250         return @projects;
3251 }
3252
3253 our $gitweb_project_owner = undef;
3254 sub git_get_project_list_from_file {
3255
3256         return if (defined $gitweb_project_owner);
3257
3258         $gitweb_project_owner = {};
3259         # read from file (url-encoded):
3260         # 'git%2Fgit.git Linus+Torvalds'
3261         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3262         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3263         if (-f $projects_list) {
3264                 open(my $fd, '<', $projects_list);
3265                 while (my $line = <$fd>) {
3266                         chomp $line;
3267                         my ($pr, $ow) = split ' ', $line;
3268                         $pr = unescape($pr);
3269                         $ow = unescape($ow);
3270                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3271                 }
3272                 close $fd;
3273         }
3274 }
3275
3276 sub git_get_project_owner {
3277         my $project = shift;
3278         my $owner;
3279
3280         return undef unless $project;
3281         $git_dir = "$projectroot/$project";
3282
3283         if (!defined $gitweb_project_owner) {
3284                 git_get_project_list_from_file();
3285         }
3286
3287         if (exists $gitweb_project_owner->{$project}) {
3288                 $owner = $gitweb_project_owner->{$project};
3289         }
3290         if (!defined $owner){
3291                 $owner = git_get_project_config('owner');
3292         }
3293         if (!defined $owner) {
3294                 $owner = get_file_owner("$git_dir");
3295         }
3296
3297         return $owner;
3298 }
3299
3300 sub git_get_last_activity {
3301         my ($path) = @_;
3302         my $fd;
3303
3304         $git_dir = "$projectroot/$path";
3305         open($fd, "-|", git_cmd(), 'for-each-ref',
3306              '--format=%(committer)',
3307              '--sort=-committerdate',
3308              '--count=1',
3309              map { "refs/$_" } get_branch_refs ()) or return;
3310         my $most_recent = <$fd>;
3311         close $fd or return;
3312         if (defined $most_recent &&
3313             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3314                 my $timestamp = $1;
3315                 my $age = time - $timestamp;
3316                 return ($age, age_string($age));
3317         }
3318         return (undef, undef);
3319 }
3320
3321 # Implementation note: when a single remote is wanted, we cannot use 'git
3322 # remote show -n' because that command always work (assuming it's a remote URL
3323 # if it's not defined), and we cannot use 'git remote show' because that would
3324 # try to make a network roundtrip. So the only way to find if that particular
3325 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3326 # and when we find what we want.
3327 sub git_get_remotes_list {
3328         my $wanted = shift;
3329         my %remotes = ();
3330
3331         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3332         return unless $fd;
3333         while (my $remote = <$fd>) {
3334                 chomp $remote;
3335                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3336                 next if $wanted and not $remote eq $wanted;
3337                 my ($url, $key) = ($1, $2);
3338
3339                 $remotes{$remote} ||= { 'heads' => () };
3340                 $remotes{$remote}{$key} = $url;
3341         }
3342         close $fd or return;
3343         return wantarray ? %remotes : \%remotes;
3344 }
3345
3346 # Takes a hash of remotes as first parameter and fills it by adding the
3347 # available remote heads for each of the indicated remotes.
3348 sub fill_remote_heads {
3349         my $remotes = shift;
3350         my @heads = map { "remotes/$_" } keys %$remotes;
3351         my @remoteheads = git_get_heads_list(undef, @heads);
3352         foreach my $remote (keys %$remotes) {
3353                 $remotes->{$remote}{'heads'} = [ grep {
3354                         $_->{'name'} =~ s!^$remote/!!
3355                         } @remoteheads ];
3356         }
3357 }
3358
3359 sub git_get_references {
3360         my $type = shift || "";
3361         my %refs;
3362         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3363         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3364         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3365                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3366                 or return;
3367
3368         while (my $line = <$fd>) {
3369                 chomp $line;
3370                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3371                         if (defined $refs{$1}) {
3372                                 push @{$refs{$1}}, $2;
3373                         } else {
3374                                 $refs{$1} = [ $2 ];
3375                         }
3376                 }
3377         }
3378         close $fd or return;
3379         return \%refs;
3380 }
3381
3382 sub git_get_rev_name_tags {
3383         my $hash = shift || return undef;
3384
3385         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3386                 or return;
3387         my $name_rev = <$fd>;
3388         close $fd;
3389
3390         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3391                 return $1;
3392         } else {
3393                 # catches also '$hash undefined' output
3394                 return undef;
3395         }
3396 }
3397
3398 ## ----------------------------------------------------------------------
3399 ## parse to hash functions
3400
3401 sub parse_date {
3402         my $epoch = shift;
3403         my $tz = shift || "-0000";
3404
3405         my %date;
3406         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3407         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3408         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3409         $date{'hour'} = $hour;
3410         $date{'minute'} = $min;
3411         $date{'mday'} = $mday;
3412         $date{'day'} = $days[$wday];
3413         $date{'month'} = $months[$mon];
3414         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3415                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3416         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3417                              $mday, $months[$mon], $hour ,$min;
3418         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3419                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3420
3421         my ($tz_sign, $tz_hour, $tz_min) =
3422                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3423         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3424         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3425         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3426         $date{'hour_local'} = $hour;
3427         $date{'minute_local'} = $min;
3428         $date{'tz_local'} = $tz;
3429         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3430                                   1900+$year, $mon+1, $mday,
3431                                   $hour, $min, $sec, $tz);
3432         return %date;
3433 }
3434
3435 sub parse_tag {
3436         my $tag_id = shift;
3437         my %tag;
3438         my @comment;
3439
3440         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3441         $tag{'id'} = $tag_id;
3442         while (my $line = <$fd>) {
3443                 chomp $line;
3444                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3445                         $tag{'object'} = $1;
3446                 } elsif ($line =~ m/^type (.+)$/) {
3447                         $tag{'type'} = $1;
3448                 } elsif ($line =~ m/^tag (.+)$/) {
3449                         $tag{'name'} = $1;
3450                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3451                         $tag{'author'} = $1;
3452                         $tag{'author_epoch'} = $2;
3453                         $tag{'author_tz'} = $3;
3454                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3455                                 $tag{'author_name'}  = $1;
3456                                 $tag{'author_email'} = $2;
3457                         } else {
3458                                 $tag{'author_name'} = $tag{'author'};
3459                         }
3460                 } elsif ($line =~ m/--BEGIN/) {
3461                         push @comment, $line;
3462                         last;
3463                 } elsif ($line eq "") {
3464                         last;
3465                 }
3466         }
3467         push @comment, <$fd>;
3468         $tag{'comment'} = \@comment;
3469         close $fd or return;
3470         if (!defined $tag{'name'}) {
3471                 return
3472         };
3473         return %tag
3474 }
3475
3476 sub parse_commit_text {
3477         my ($commit_text, $withparents) = @_;
3478         my @commit_lines = split '\n', $commit_text;
3479         my %co;
3480
3481         pop @commit_lines; # Remove '\0'
3482
3483         if (! @commit_lines) {
3484                 return;
3485         }
3486
3487         my $header = shift @commit_lines;
3488         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3489                 return;
3490         }
3491         ($co{'id'}, my @parents) = split ' ', $header;
3492         while (my $line = shift @commit_lines) {
3493                 last if $line eq "\n";
3494                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3495                         $co{'tree'} = $1;
3496                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3497                         push @parents, $1;
3498                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3499                         $co{'author'} = to_utf8($1);
3500                         $co{'author_epoch'} = $2;
3501                         $co{'author_tz'} = $3;
3502                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3503                                 $co{'author_name'}  = $1;
3504                                 $co{'author_email'} = $2;
3505                         } else {
3506                                 $co{'author_name'} = $co{'author'};
3507                         }
3508                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3509                         $co{'committer'} = to_utf8($1);
3510                         $co{'committer_epoch'} = $2;
3511                         $co{'committer_tz'} = $3;
3512                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3513                                 $co{'committer_name'}  = $1;
3514                                 $co{'committer_email'} = $2;
3515                         } else {
3516                                 $co{'committer_name'} = $co{'committer'};
3517                         }
3518                 }
3519         }
3520         if (!defined $co{'tree'}) {
3521                 return;
3522         };
3523         $co{'parents'} = \@parents;
3524         $co{'parent'} = $parents[0];
3525
3526         foreach my $title (@commit_lines) {
3527                 $title =~ s/^    //;
3528                 if ($title ne "") {
3529                         $co{'title'} = chop_str($title, 80, 5);
3530                         # remove leading stuff of merges to make the interesting part visible
3531                         if (length($title) > 50) {
3532                                 $title =~ s/^Automatic //;
3533                                 $title =~ s/^merge (of|with) /Merge ... /i;
3534                                 if (length($title) > 50) {
3535                                         $title =~ s/(http|rsync):\/\///;
3536                                 }
3537                                 if (length($title) > 50) {
3538                                         $title =~ s/(master|www|rsync)\.//;
3539                                 }
3540                                 if (length($title) > 50) {
3541                                         $title =~ s/kernel.org:?//;
3542                                 }
3543                                 if (length($title) > 50) {
3544                                         $title =~ s/\/pub\/scm//;
3545                                 }
3546                         }
3547                         $co{'title_short'} = chop_str($title, 50, 5);
3548                         last;
3549                 }
3550         }
3551         if (! defined $co{'title'} || $co{'title'} eq "") {
3552                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3553         }
3554         # remove added spaces
3555         foreach my $line (@commit_lines) {
3556                 $line =~ s/^    //;
3557         }
3558         $co{'comment'} = \@commit_lines;
3559
3560         my $age = time - $co{'committer_epoch'};
3561         $co{'age'} = $age;
3562         $co{'age_string'} = age_string($age);
3563         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3564         if ($age > 60*60*24*7*2) {
3565                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3566                 $co{'age_string_age'} = $co{'age_string'};
3567         } else {
3568                 $co{'age_string_date'} = $co{'age_string'};
3569                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3570         }
3571         return %co;
3572 }
3573
3574 sub parse_commit {
3575         my ($commit_id) = @_;
3576         my %co;
3577
3578         local $/ = "\0";
3579
3580         open my $fd, "-|", git_cmd(), "rev-list",
3581                 "--parents",
3582                 "--header",
3583                 "--max-count=1",
3584                 $commit_id,
3585                 "--",
3586                 or die_error(500, "Open git-rev-list failed");
3587         %co = parse_commit_text(<$fd>, 1);
3588         close $fd;
3589
3590         return %co;
3591 }
3592
3593 sub parse_commits {
3594         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3595         my @cos;
3596
3597         $maxcount ||= 1;
3598         $skip ||= 0;
3599
3600         local $/ = "\0";
3601
3602         open my $fd, "-|", git_cmd(), "rev-list",
3603                 "--header",
3604                 @args,
3605                 ("--max-count=" . $maxcount),
3606                 ("--skip=" . $skip),
3607                 @extra_options,
3608                 $commit_id,
3609                 "--",
3610                 ($filename ? ($filename) : ())
3611                 or die_error(500, "Open git-rev-list failed");
3612         while (my $line = <$fd>) {
3613                 my %co = parse_commit_text($line);
3614                 push @cos, \%co;
3615         }
3616         close $fd;
3617
3618         return wantarray ? @cos : \@cos;
3619 }
3620
3621 # parse line of git-diff-tree "raw" output
3622 sub parse_difftree_raw_line {
3623         my $line = shift;
3624         my %res;
3625
3626         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3627         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3628         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3629                 $res{'from_mode'} = $1;
3630                 $res{'to_mode'} = $2;
3631                 $res{'from_id'} = $3;
3632                 $res{'to_id'} = $4;
3633                 $res{'status'} = $5;
3634                 $res{'similarity'} = $6;
3635                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3636                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3637                 } else {
3638                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3639                 }
3640         }
3641         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3642         # combined diff (for merge commit)
3643         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3644                 $res{'nparents'}  = length($1);
3645                 $res{'from_mode'} = [ split(' ', $2) ];
3646                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3647                 $res{'from_id'} = [ split(' ', $3) ];
3648                 $res{'to_id'} = pop @{$res{'from_id'}};
3649                 $res{'status'} = [ split('', $4) ];
3650                 $res{'to_file'} = unquote($5);
3651         }
3652         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3653         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3654                 $res{'commit'} = $1;
3655         }
3656
3657         return wantarray ? %res : \%res;
3658 }
3659
3660 # wrapper: return parsed line of git-diff-tree "raw" output
3661 # (the argument might be raw line, or parsed info)
3662 sub parsed_difftree_line {
3663         my $line_or_ref = shift;
3664
3665         if (ref($line_or_ref) eq "HASH") {
3666                 # pre-parsed (or generated by hand)
3667                 return $line_or_ref;
3668         } else {
3669                 return parse_difftree_raw_line($line_or_ref);
3670         }
3671 }
3672
3673 # parse line of git-ls-tree output
3674 sub parse_ls_tree_line {
3675         my $line = shift;
3676         my %opts = @_;
3677         my %res;
3678
3679         if ($opts{'-l'}) {
3680                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3681                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3682
3683                 $res{'mode'} = $1;
3684                 $res{'type'} = $2;
3685                 $res{'hash'} = $3;
3686                 $res{'size'} = $4;
3687                 if ($opts{'-z'}) {
3688                         $res{'name'} = $5;
3689                 } else {
3690                         $res{'name'} = unquote($5);
3691                 }
3692         } else {
3693                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3694                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3695
3696                 $res{'mode'} = $1;
3697                 $res{'type'} = $2;
3698                 $res{'hash'} = $3;
3699                 if ($opts{'-z'}) {
3700                         $res{'name'} = $4;
3701                 } else {
3702                         $res{'name'} = unquote($4);
3703                 }
3704         }
3705
3706         return wantarray ? %res : \%res;
3707 }
3708
3709 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3710 sub parse_from_to_diffinfo {
3711         my ($diffinfo, $from, $to, @parents) = @_;
3712
3713         if ($diffinfo->{'nparents'}) {
3714                 # combined diff
3715                 $from->{'file'} = [];
3716                 $from->{'href'} = [];
3717                 fill_from_file_info($diffinfo, @parents)
3718                         unless exists $diffinfo->{'from_file'};
3719                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3720                         $from->{'file'}[$i] =
3721                                 defined $diffinfo->{'from_file'}[$i] ?
3722                                         $diffinfo->{'from_file'}[$i] :
3723                                         $diffinfo->{'to_file'};
3724                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3725                                 $from->{'href'}[$i] = href(action=>"blob",
3726                                                            hash_base=>$parents[$i],
3727                                                            hash=>$diffinfo->{'from_id'}[$i],
3728                                                            file_name=>$from->{'file'}[$i]);
3729                         } else {
3730                                 $from->{'href'}[$i] = undef;
3731                         }
3732                 }
3733         } else {
3734                 # ordinary (not combined) diff
3735                 $from->{'file'} = $diffinfo->{'from_file'};
3736                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3737                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3738                                                hash=>$diffinfo->{'from_id'},
3739                                                file_name=>$from->{'file'});
3740                 } else {
3741                         delete $from->{'href'};
3742                 }
3743         }
3744
3745         $to->{'file'} = $diffinfo->{'to_file'};
3746         if (!is_deleted($diffinfo)) { # file exists in result
3747                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3748                                      hash=>$diffinfo->{'to_id'},
3749                                      file_name=>$to->{'file'});
3750         } else {
3751                 delete $to->{'href'};
3752         }
3753 }
3754
3755 ## ......................................................................
3756 ## parse to array of hashes functions
3757
3758 sub git_get_heads_list {
3759         my ($limit, @classes) = @_;
3760         @classes = get_branch_refs() unless @classes;
3761         my @patterns = map { "refs/$_" } @classes;
3762         my @headslist;
3763
3764         open my $fd, '-|', git_cmd(), 'for-each-ref',
3765                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3766                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3767                 @patterns
3768                 or return;
3769         while (my $line = <$fd>) {
3770                 my %ref_item;
3771
3772                 chomp $line;
3773                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3774                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3775                 my ($committer, $epoch, $tz) =
3776                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3777                 $ref_item{'fullname'}  = $name;
3778                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3779                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3780                 $ref_item{'name'} = $name;
3781                 # for refs neither in 'heads' nor 'remotes' we want to
3782                 # show their ref dir
3783                 my $ref_dir = (defined $1) ? $1 : '';
3784                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3785                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3786                 }
3787
3788                 $ref_item{'id'}    = $hash;
3789                 $ref_item{'title'} = $title || '(no commit message)';
3790                 $ref_item{'epoch'} = $epoch;
3791                 if ($epoch) {
3792                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3793                 } else {
3794                         $ref_item{'age'} = "unknown";
3795                 }
3796
3797                 push @headslist, \%ref_item;
3798         }
3799         close $fd;
3800
3801         return wantarray ? @headslist : \@headslist;
3802 }
3803
3804 sub git_get_tags_list {
3805         my $limit = shift;
3806         my @tagslist;
3807
3808         open my $fd, '-|', git_cmd(), 'for-each-ref',
3809                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3810                 '--format=%(objectname) %(objecttype) %(refname) '.
3811                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3812                 'refs/tags'
3813                 or return;
3814         while (my $line = <$fd>) {
3815                 my %ref_item;
3816
3817                 chomp $line;
3818                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3819                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3820                 my ($creator, $epoch, $tz) =
3821                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3822                 $ref_item{'fullname'} = $name;
3823                 $name =~ s!^refs/tags/!!;
3824
3825                 $ref_item{'type'} = $type;
3826                 $ref_item{'id'} = $id;
3827                 $ref_item{'name'} = $name;
3828                 if ($type eq "tag") {
3829                         $ref_item{'subject'} = $title;
3830                         $ref_item{'reftype'} = $reftype;
3831                         $ref_item{'refid'}   = $refid;
3832                 } else {
3833                         $ref_item{'reftype'} = $type;
3834                         $ref_item{'refid'}   = $id;
3835                 }
3836
3837                 if ($type eq "tag" || $type eq "commit") {
3838                         $ref_item{'epoch'} = $epoch;
3839                         if ($epoch) {
3840                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3841                         } else {
3842                                 $ref_item{'age'} = "unknown";
3843                         }
3844                 }
3845
3846                 push @tagslist, \%ref_item;
3847         }
3848         close $fd;
3849
3850         return wantarray ? @tagslist : \@tagslist;
3851 }
3852
3853 ## ----------------------------------------------------------------------
3854 ## filesystem-related functions
3855
3856 sub get_file_owner {
3857         my $path = shift;
3858
3859         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3860         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3861         if (!defined $gcos) {
3862                 return undef;
3863         }
3864         my $owner = $gcos;
3865         $owner =~ s/[,;].*$//;
3866         return to_utf8($owner);
3867 }
3868
3869 # assume that file exists
3870 sub insert_file {
3871         my $filename = shift;
3872
3873         open my $fd, '<', $filename;
3874         print map { to_utf8($_) } <$fd>;
3875         close $fd;
3876 }
3877
3878 ## ......................................................................
3879 ## mimetype related functions
3880
3881 sub mimetype_guess_file {
3882         my $filename = shift;
3883         my $mimemap = shift;
3884         -r $mimemap or return undef;
3885
3886         my %mimemap;
3887         open(my $mh, '<', $mimemap) or return undef;
3888         while (<$mh>) {
3889                 next if m/^#/; # skip comments
3890                 my ($mimetype, @exts) = split(/\s+/);
3891                 foreach my $ext (@exts) {
3892                         $mimemap{$ext} = $mimetype;
3893                 }
3894         }
3895         close($mh);
3896
3897         $filename =~ /\.([^.]*)$/;
3898         return $mimemap{$1};
3899 }
3900
3901 sub mimetype_guess {
3902         my $filename = shift;
3903         my $mime;
3904         $filename =~ /\./ or return undef;
3905
3906         if ($mimetypes_file) {
3907                 my $file = $mimetypes_file;
3908                 if ($file !~ m!^/!) { # if it is relative path
3909                         # it is relative to project
3910                         $file = "$projectroot/$project/$file";
3911                 }
3912                 $mime = mimetype_guess_file($filename, $file);
3913         }
3914         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3915         return $mime;
3916 }
3917
3918 sub blob_mimetype {
3919         my $fd = shift;
3920         my $filename = shift;
3921
3922         if ($filename) {
3923                 my $mime = mimetype_guess($filename);
3924                 $mime and return $mime;
3925         }
3926
3927         # just in case
3928         return $default_blob_plain_mimetype unless $fd;
3929
3930         if (-T $fd) {
3931                 return 'text/plain';
3932         } elsif (! $filename) {
3933                 return 'application/octet-stream';
3934         } elsif ($filename =~ m/\.png$/i) {
3935                 return 'image/png';
3936         } elsif ($filename =~ m/\.gif$/i) {
3937                 return 'image/gif';
3938         } elsif ($filename =~ m/\.jpe?g$/i) {
3939                 return 'image/jpeg';
3940         } else {
3941                 return 'application/octet-stream';
3942         }
3943 }
3944
3945 sub blob_contenttype {
3946         my ($fd, $file_name, $type) = @_;
3947
3948         $type ||= blob_mimetype($fd, $file_name);
3949         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3950                 $type .= "; charset=$default_text_plain_charset";
3951         }
3952
3953         return $type;
3954 }
3955
3956 # guess file syntax for syntax highlighting; return undef if no highlighting
3957 # the name of syntax can (in the future) depend on syntax highlighter used
3958 sub guess_file_syntax {
3959         my ($highlight, $mimetype, $file_name) = @_;
3960         return undef unless ($highlight && defined $file_name);
3961         my $basename = basename($file_name, '.in');
3962         return $highlight_basename{$basename}
3963                 if exists $highlight_basename{$basename};
3964
3965         $basename =~ /\.([^.]*)$/;
3966         my $ext = $1 or return undef;
3967         return $highlight_ext{$ext}
3968                 if exists $highlight_ext{$ext};
3969
3970         return undef;
3971 }
3972
3973 # run highlighter and return FD of its output,
3974 # or return original FD if no highlighting
3975 sub run_highlighter {
3976         my ($fd, $highlight, $syntax) = @_;
3977         return $fd unless ($highlight && defined $syntax);
3978
3979         close $fd;
3980         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3981                   quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
3982                     '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
3983                     '--', "-fe=$fallback_encoding")." | ".
3984                   quote_command($highlight_bin).
3985                   " --replace-tabs=8 --fragment --syntax $syntax |"
3986                 or die_error(500, "Couldn't open file or run syntax highlighter");
3987         return $fd;
3988 }
3989
3990 ## ======================================================================
3991 ## functions printing HTML: header, footer, error page
3992
3993 sub get_page_title {
3994         my $title = to_utf8($site_name);
3995
3996         unless (defined $project) {
3997                 if (defined $project_filter) {
3998                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3999                 }
4000                 return $title;
4001         }
4002         $title .= " - " . to_utf8($project);
4003
4004         return $title unless (defined $action);
4005         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
4006
4007         return $title unless (defined $file_name);
4008         $title .= " - " . esc_path($file_name);
4009         if ($action eq "tree" && $file_name !~ m|/$|) {
4010                 $title .= "/";
4011         }
4012
4013         return $title;
4014 }
4015
4016 sub get_content_type_html {
4017         # require explicit support from the UA if we are to send the page as
4018         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
4019         # we have to do this because MSIE sometimes globs '*/*', pretending to
4020         # support xhtml+xml but choking when it gets what it asked for.
4021         if (defined $cgi->http('HTTP_ACCEPT') &&
4022             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
4023             $cgi->Accept('application/xhtml+xml') != 0) {
4024                 return 'application/xhtml+xml';
4025         } else {
4026                 return 'text/html';
4027         }
4028 }
4029
4030 sub print_feed_meta {
4031         if (defined $project) {
4032                 my %href_params = get_feed_info();
4033                 if (!exists $href_params{'-title'}) {
4034                         $href_params{'-title'} = 'log';
4035                 }
4036
4037                 foreach my $format (qw(RSS Atom)) {
4038                         my $type = lc($format);
4039                         my %link_attr = (
4040                                 '-rel' => 'alternate',
4041                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4042                                 '-type' => "application/$type+xml"
4043                         );
4044
4045                         $href_params{'extra_options'} = undef;
4046                         $href_params{'action'} = $type;
4047                         $link_attr{'-href'} = href(%href_params);
4048                         print "<link ".
4049                               "rel=\"$link_attr{'-rel'}\" ".
4050                               "title=\"$link_attr{'-title'}\" ".
4051                               "href=\"$link_attr{'-href'}\" ".
4052                               "type=\"$link_attr{'-type'}\" ".
4053                               "/>\n";
4054
4055                         $href_params{'extra_options'} = '--no-merges';
4056                         $link_attr{'-href'} = href(%href_params);
4057                         $link_attr{'-title'} .= ' (no merges)';
4058                         print "<link ".
4059                               "rel=\"$link_attr{'-rel'}\" ".
4060                               "title=\"$link_attr{'-title'}\" ".
4061                               "href=\"$link_attr{'-href'}\" ".
4062                               "type=\"$link_attr{'-type'}\" ".
4063                               "/>\n";
4064                 }
4065
4066         } else {
4067                 printf('<link rel="alternate" title="%s projects list" '.
4068                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4069                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
4070                 printf('<link rel="alternate" title="%s projects feeds" '.
4071                        'href="%s" type="text/x-opml" />'."\n",
4072                        esc_attr($site_name), href(project=>undef, action=>"opml"));
4073         }
4074 }
4075
4076 sub print_header_links {
4077         my $status = shift;
4078
4079         # print out each stylesheet that exist, providing backwards capability
4080         # for those people who defined $stylesheet in a config file
4081         if (defined $stylesheet) {
4082                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4083         } else {
4084                 foreach my $stylesheet (@stylesheets) {
4085                         next unless $stylesheet;
4086                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4087                 }
4088         }
4089         print_feed_meta()
4090                 if ($status eq '200 OK');
4091         if (defined $favicon) {
4092                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4093         }
4094 }
4095
4096 sub print_nav_breadcrumbs_path {
4097         my $dirprefix = undef;
4098         while (my $part = shift) {
4099                 $dirprefix .= "/" if defined $dirprefix;
4100                 $dirprefix .= $part;
4101                 print $cgi->a({-href => href(project => undef,
4102                                              project_filter => $dirprefix,
4103                                              action => "project_list")},
4104                               esc_html($part)) . " / ";
4105         }
4106 }
4107
4108 sub print_nav_breadcrumbs {
4109         my %opts = @_;
4110
4111         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4112                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4113         }
4114         if (defined $project) {
4115                 my @dirname = split '/', $project;
4116                 my $projectbasename = pop @dirname;
4117                 print_nav_breadcrumbs_path(@dirname);
4118                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4119                 if (defined $action) {
4120                         my $action_print = $action ;
4121                         if (defined $opts{-action_extra}) {
4122                                 $action_print = $cgi->a({-href => href(action=>$action)},
4123                                         $action);
4124                         }
4125                         print " / $action_print";
4126                 }
4127                 if (defined $opts{-action_extra}) {
4128                         print " / $opts{-action_extra}";
4129                 }
4130                 print "\n";
4131         } elsif (defined $project_filter) {
4132                 print_nav_breadcrumbs_path(split '/', $project_filter);
4133         }
4134 }
4135
4136 sub print_search_form {
4137         if (!defined $searchtext) {
4138                 $searchtext = "";
4139         }
4140         my $search_hash;
4141         if (defined $hash_base) {
4142                 $search_hash = $hash_base;
4143         } elsif (defined $hash) {
4144                 $search_hash = $hash;
4145         } else {
4146                 $search_hash = "HEAD";
4147         }
4148         my $action = $my_uri;
4149         my $use_pathinfo = gitweb_check_feature('pathinfo');
4150         if ($use_pathinfo) {
4151                 $action .= "/".esc_url($project);
4152         }
4153         print $cgi->start_form(-method => "get", -action => $action) .
4154               "<div class=\"search\">\n" .
4155               (!$use_pathinfo &&
4156               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4157               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4158               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4159               $cgi->popup_menu(-name => 'st', -default => 'commit',
4160                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4161               " " . $cgi->a({-href => href(action=>"search_help"),
4162                              -title => "search help" }, "?") . " search:\n",
4163               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4164               "<span title=\"Extended regular expression\">" .
4165               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4166                              -checked => $search_use_regexp) .
4167               "</span>" .
4168               "</div>" .
4169               $cgi->end_form() . "\n";
4170 }
4171
4172 sub git_header_html {
4173         my $status = shift || "200 OK";
4174         my $expires = shift;
4175         my %opts = @_;
4176
4177         my $title = get_page_title();
4178         my $content_type = get_content_type_html();
4179         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4180                            -status=> $status, -expires => $expires)
4181                 unless ($opts{'-no_http_header'});
4182         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4183         print <<EOF;
4184 <?xml version="1.0" encoding="utf-8"?>
4185 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4186 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4187 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4188 <!-- git core binaries version $git_version -->
4189 <head>
4190 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4191 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4192 <meta name="robots" content="index, nofollow"/>
4193 <title>$title</title>
4194 EOF
4195         # the stylesheet, favicon etc urls won't work correctly with path_info
4196         # unless we set the appropriate base URL
4197         if ($ENV{'PATH_INFO'}) {
4198                 print "<base href=\"".esc_url($base_url)."\" />\n";
4199         }
4200         print_header_links($status);
4201
4202         if (defined $site_html_head_string) {
4203                 print to_utf8($site_html_head_string);
4204         }
4205
4206         print "</head>\n" .
4207               "<body>\n";
4208
4209         if (defined $site_header && -f $site_header) {
4210                 insert_file($site_header);
4211         }
4212
4213         print "<div class=\"page_header\">\n";
4214         if (defined $logo) {
4215                 print $cgi->a({-href => esc_url($logo_url),
4216                                -title => $logo_label},
4217                               $cgi->img({-src => esc_url($logo),
4218                                          -width => 72, -height => 27,
4219                                          -alt => "git",
4220                                          -class => "logo"}));
4221         }
4222         print_nav_breadcrumbs(%opts);
4223         print "</div>\n";
4224
4225         my $have_search = gitweb_check_feature('search');
4226         if (defined $project && $have_search) {
4227                 print_search_form();
4228         }
4229 }
4230
4231 sub git_footer_html {
4232         my $feed_class = 'rss_logo';
4233
4234         print "<div class=\"page_footer\">\n";
4235         if (defined $project) {
4236                 my $descr = git_get_project_description($project);
4237                 if (defined $descr) {
4238                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4239                 }
4240
4241                 my %href_params = get_feed_info();
4242                 if (!%href_params) {
4243                         $feed_class .= ' generic';
4244                 }
4245                 $href_params{'-title'} ||= 'log';
4246
4247                 foreach my $format (qw(RSS Atom)) {
4248                         $href_params{'action'} = lc($format);
4249                         print $cgi->a({-href => href(%href_params),
4250                                       -title => "$href_params{'-title'} $format feed",
4251                                       -class => $feed_class}, $format)."\n";
4252                 }
4253
4254         } else {
4255                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4256                                              project_filter => $project_filter),
4257                               -class => $feed_class}, "OPML") . " ";
4258                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4259                                              project_filter => $project_filter),
4260                               -class => $feed_class}, "TXT") . "\n";
4261         }
4262         print "</div>\n"; # class="page_footer"
4263
4264         if (defined $t0 && gitweb_check_feature('timed')) {
4265                 print "<div id=\"generating_info\">\n";
4266                 print 'This page took '.
4267                       '<span id="generating_time" class="time_span">'.
4268                       tv_interval($t0, [ gettimeofday() ]).
4269                       ' seconds </span>'.
4270                       ' and '.
4271                       '<span id="generating_cmd">'.
4272                       $number_of_git_cmds.
4273                       '</span> git commands '.
4274                       " to generate.\n";
4275                 print "</div>\n"; # class="page_footer"
4276         }
4277
4278         if (defined $site_footer && -f $site_footer) {
4279                 insert_file($site_footer);
4280         }
4281
4282         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4283         if (defined $action &&
4284             $action eq 'blame_incremental') {
4285                 print qq!<script type="text/javascript">\n!.
4286                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4287                       qq!           "!. href() .qq!");\n!.
4288                       qq!</script>\n!;
4289         } else {
4290                 my ($jstimezone, $tz_cookie, $datetime_class) =
4291                         gitweb_get_feature('javascript-timezone');
4292
4293                 print qq!<script type="text/javascript">\n!.
4294                       qq!window.onload = function () {\n!;
4295                 if (gitweb_check_feature('javascript-actions')) {
4296                         print qq!       fixLinks();\n!;
4297                 }
4298                 if ($jstimezone && $tz_cookie && $datetime_class) {
4299                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4300                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4301                 }
4302                 print qq!};\n!.
4303                       qq!</script>\n!;
4304         }
4305
4306         print "</body>\n" .
4307               "</html>";
4308 }
4309
4310 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4311 # Example: die_error(404, 'Hash not found')
4312 # By convention, use the following status codes (as defined in RFC 2616):
4313 # 400: Invalid or missing CGI parameters, or
4314 #      requested object exists but has wrong type.
4315 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4316 #      this server or project.
4317 # 404: Requested object/revision/project doesn't exist.
4318 # 500: The server isn't configured properly, or
4319 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4320 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4321 # 503: The server is currently unavailable (because it is overloaded,
4322 #      or down for maintenance).  Generally, this is a temporary state.
4323 sub die_error {
4324         my $status = shift || 500;
4325         my $error = esc_html(shift) || "Internal Server Error";
4326         my $extra = shift;
4327         my %opts = @_;
4328
4329         my %http_responses = (
4330                 400 => '400 Bad Request',
4331                 403 => '403 Forbidden',
4332                 404 => '404 Not Found',
4333                 500 => '500 Internal Server Error',
4334                 503 => '503 Service Unavailable',
4335         );
4336         git_header_html($http_responses{$status}, undef, %opts);
4337         print <<EOF;
4338 <div class="page_body">
4339 <br /><br />
4340 $status - $error
4341 <br />
4342 EOF
4343         if (defined $extra) {
4344                 print "<hr />\n" .
4345                       "$extra\n";
4346         }
4347         print "</div>\n";
4348
4349         git_footer_html();
4350         goto DONE_GITWEB
4351                 unless ($opts{'-error_handler'});
4352 }
4353
4354 ## ----------------------------------------------------------------------
4355 ## functions printing or outputting HTML: navigation
4356
4357 sub git_print_page_nav {
4358         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4359         $extra = '' if !defined $extra; # pager or formats
4360
4361         my @navs = qw(summary shortlog log commit commitdiff tree);
4362         if ($suppress) {
4363                 @navs = grep { $_ ne $suppress } @navs;
4364         }
4365
4366         my %arg = map { $_ => {action=>$_} } @navs;
4367         if (defined $head) {
4368                 for (qw(commit commitdiff)) {
4369                         $arg{$_}{'hash'} = $head;
4370                 }
4371                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4372                         for (qw(shortlog log)) {
4373                                 $arg{$_}{'hash'} = $head;
4374                         }
4375                 }
4376         }
4377
4378         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4379         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4380
4381         my @actions = gitweb_get_feature('actions');
4382         my %repl = (
4383                 '%' => '%',
4384                 'n' => $project,         # project name
4385                 'f' => $git_dir,         # project path within filesystem
4386                 'h' => $treehead || '',  # current hash ('h' parameter)
4387                 'b' => $treebase || '',  # hash base ('hb' parameter)
4388         );
4389         while (@actions) {
4390                 my ($label, $link, $pos) = splice(@actions,0,3);
4391                 # insert
4392                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4393                 # munch munch
4394                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4395                 $arg{$label}{'_href'} = $link;
4396         }
4397
4398         print "<div class=\"page_nav\">\n" .
4399                 (join " | ",
4400                  map { $_ eq $current ?
4401                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4402                  } @navs);
4403         print "<br/>\n$extra<br/>\n" .
4404               "</div>\n";
4405 }
4406
4407 # returns a submenu for the nagivation of the refs views (tags, heads,
4408 # remotes) with the current view disabled and the remotes view only
4409 # available if the feature is enabled
4410 sub format_ref_views {
4411         my ($current) = @_;
4412         my @ref_views = qw{tags heads};
4413         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4414         return join " | ", map {
4415                 $_ eq $current ? $_ :
4416                 $cgi->a({-href => href(action=>$_)}, $_)
4417         } @ref_views
4418 }
4419
4420 sub format_paging_nav {
4421         my ($action, $page, $has_next_link) = @_;
4422         my $paging_nav;
4423
4424
4425         if ($page > 0) {
4426                 $paging_nav .=
4427                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4428                         " &sdot; " .
4429                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4430                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4431         } else {
4432                 $paging_nav .= "first &sdot; prev";
4433         }
4434
4435         if ($has_next_link) {
4436                 $paging_nav .= " &sdot; " .
4437                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4438                                  -accesskey => "n", -title => "Alt-n"}, "next");
4439         } else {
4440                 $paging_nav .= " &sdot; next";
4441         }
4442
4443         return $paging_nav;
4444 }
4445
4446 ## ......................................................................
4447 ## functions printing or outputting HTML: div
4448
4449 sub git_print_header_div {
4450         my ($action, $title, $hash, $hash_base) = @_;
4451         my %args = ();
4452
4453         $args{'action'} = $action;
4454         $args{'hash'} = $hash if $hash;
4455         $args{'hash_base'} = $hash_base if $hash_base;
4456
4457         print "<div class=\"header\">\n" .
4458               $cgi->a({-href => href(%args), -class => "title"},
4459               $title ? $title : $action) .
4460               "\n</div>\n";
4461 }
4462
4463 sub format_repo_url {
4464         my ($name, $url) = @_;
4465         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4466 }
4467
4468 # Group output by placing it in a DIV element and adding a header.
4469 # Options for start_div() can be provided by passing a hash reference as the
4470 # first parameter to the function.
4471 # Options to git_print_header_div() can be provided by passing an array
4472 # reference. This must follow the options to start_div if they are present.
4473 # The content can be a scalar, which is output as-is, a scalar reference, which
4474 # is output after html escaping, an IO handle passed either as *handle or
4475 # *handle{IO}, or a function reference. In the latter case all following
4476 # parameters will be taken as argument to the content function call.
4477 sub git_print_section {
4478         my ($div_args, $header_args, $content);
4479         my $arg = shift;
4480         if (ref($arg) eq 'HASH') {
4481                 $div_args = $arg;
4482                 $arg = shift;
4483         }
4484         if (ref($arg) eq 'ARRAY') {
4485                 $header_args = $arg;
4486                 $arg = shift;
4487         }
4488         $content = $arg;
4489
4490         print $cgi->start_div($div_args);
4491         git_print_header_div(@$header_args);
4492
4493         if (ref($content) eq 'CODE') {
4494                 $content->(@_);
4495         } elsif (ref($content) eq 'SCALAR') {
4496                 print esc_html($$content);
4497         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4498                 print <$content>;
4499         } elsif (!ref($content) && defined($content)) {
4500                 print $content;
4501         }
4502
4503         print $cgi->end_div;
4504 }
4505
4506 sub format_timestamp_html {
4507         my $date = shift;
4508         my $strtime = $date->{'rfc2822'};
4509
4510         my (undef, undef, $datetime_class) =
4511                 gitweb_get_feature('javascript-timezone');
4512         if ($datetime_class) {
4513                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4514         }
4515
4516         my $localtime_format = '(%02d:%02d %s)';
4517         if ($date->{'hour_local'} < 6) {
4518                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4519         }
4520         $strtime .= ' ' .
4521                     sprintf($localtime_format,
4522                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4523
4524         return $strtime;
4525 }
4526
4527 # Outputs the author name and date in long form
4528 sub git_print_authorship {
4529         my $co = shift;
4530         my %opts = @_;
4531         my $tag = $opts{-tag} || 'div';
4532         my $author = $co->{'author_name'};
4533
4534         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4535         print "<$tag class=\"author_date\">" .
4536               format_search_author($author, "author", esc_html($author)) .
4537               " [".format_timestamp_html(\%ad)."]".
4538               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4539               "</$tag>\n";
4540 }
4541
4542 # Outputs table rows containing the full author or committer information,
4543 # in the format expected for 'commit' view (& similar).
4544 # Parameters are a commit hash reference, followed by the list of people
4545 # to output information for. If the list is empty it defaults to both
4546 # author and committer.
4547 sub git_print_authorship_rows {
4548         my $co = shift;
4549         # too bad we can't use @people = @_ || ('author', 'committer')
4550         my @people = @_;
4551         @people = ('author', 'committer') unless @people;
4552         foreach my $who (@people) {
4553                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4554                 print "<tr><td>$who</td><td>" .
4555                       format_search_author($co->{"${who}_name"}, $who,
4556                                            esc_html($co->{"${who}_name"})) . " " .
4557                       format_search_author($co->{"${who}_email"}, $who,
4558                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4559                       "</td><td rowspan=\"2\">" .
4560                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4561                       "</td></tr>\n" .
4562                       "<tr>" .
4563                       "<td></td><td>" .
4564                       format_timestamp_html(\%wd) .
4565                       "</td>" .
4566                       "</tr>\n";
4567         }
4568 }
4569
4570 sub git_print_page_path {
4571         my $name = shift;
4572         my $type = shift;
4573         my $hb = shift;
4574
4575
4576         print "<div class=\"page_path\">";
4577         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4578                       -title => 'tree root'}, to_utf8("[$project]"));
4579         print " / ";
4580         if (defined $name) {
4581                 my @dirname = split '/', $name;
4582                 my $basename = pop @dirname;
4583                 my $fullname = '';
4584
4585                 foreach my $dir (@dirname) {
4586                         $fullname .= ($fullname ? '/' : '') . $dir;
4587                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4588                                                      hash_base=>$hb),
4589                                       -title => $fullname}, esc_path($dir));
4590                         print " / ";
4591                 }
4592                 if (defined $type && $type eq 'blob') {
4593                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4594                                                      hash_base=>$hb),
4595                                       -title => $name}, esc_path($basename));
4596                 } elsif (defined $type && $type eq 'tree') {
4597                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4598                                                      hash_base=>$hb),
4599                                       -title => $name}, esc_path($basename));
4600                         print " / ";
4601                 } else {
4602                         print esc_path($basename);
4603                 }
4604         }
4605         print "<br/></div>\n";
4606 }
4607
4608 sub git_print_log {
4609         my $log = shift;
4610         my %opts = @_;
4611
4612         if ($opts{'-remove_title'}) {
4613                 # remove title, i.e. first line of log
4614                 shift @$log;
4615         }
4616         # remove leading empty lines
4617         while (defined $log->[0] && $log->[0] eq "") {
4618                 shift @$log;
4619         }
4620
4621         # print log
4622         my $skip_blank_line = 0;
4623         foreach my $line (@$log) {
4624                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4625                         if (! $opts{'-remove_signoff'}) {
4626                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4627                                 $skip_blank_line = 1;
4628                         }
4629                         next;
4630                 }
4631
4632                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4633                         if (! $opts{'-remove_signoff'}) {
4634                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4635                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4636                                         "</span><br/>\n";
4637                                 $skip_blank_line = 1;
4638                         }
4639                         next;
4640                 }
4641
4642                 # print only one empty line
4643                 # do not print empty line after signoff
4644                 if ($line eq "") {
4645                         next if ($skip_blank_line);
4646                         $skip_blank_line = 1;
4647                 } else {
4648                         $skip_blank_line = 0;
4649                 }
4650
4651                 print format_log_line_html($line) . "<br/>\n";
4652         }
4653
4654         if ($opts{'-final_empty_line'}) {
4655                 # end with single empty line
4656                 print "<br/>\n" unless $skip_blank_line;
4657         }
4658 }
4659
4660 # return link target (what link points to)
4661 sub git_get_link_target {
4662         my $hash = shift;
4663         my $link_target;
4664
4665         # read link
4666         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4667                 or return;
4668         {
4669                 local $/ = undef;
4670                 $link_target = <$fd>;
4671         }
4672         close $fd
4673                 or return;
4674
4675         return $link_target;
4676 }
4677
4678 # given link target, and the directory (basedir) the link is in,
4679 # return target of link relative to top directory (top tree);
4680 # return undef if it is not possible (including absolute links).
4681 sub normalize_link_target {
4682         my ($link_target, $basedir) = @_;
4683
4684         # absolute symlinks (beginning with '/') cannot be normalized
4685         return if (substr($link_target, 0, 1) eq '/');
4686
4687         # normalize link target to path from top (root) tree (dir)
4688         my $path;
4689         if ($basedir) {
4690                 $path = $basedir . '/' . $link_target;
4691         } else {
4692                 # we are in top (root) tree (dir)
4693                 $path = $link_target;
4694         }
4695
4696         # remove //, /./, and /../
4697         my @path_parts;
4698         foreach my $part (split('/', $path)) {
4699                 # discard '.' and ''
4700                 next if (!$part || $part eq '.');
4701                 # handle '..'
4702                 if ($part eq '..') {
4703                         if (@path_parts) {
4704                                 pop @path_parts;
4705                         } else {
4706                                 # link leads outside repository (outside top dir)
4707                                 return;
4708                         }
4709                 } else {
4710                         push @path_parts, $part;
4711                 }
4712         }
4713         $path = join('/', @path_parts);
4714
4715         return $path;
4716 }
4717
4718 # print tree entry (row of git_tree), but without encompassing <tr> element
4719 sub git_print_tree_entry {
4720         my ($t, $basedir, $hash_base, $have_blame) = @_;
4721
4722         my %base_key = ();
4723         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4724
4725         # The format of a table row is: mode list link.  Where mode is
4726         # the mode of the entry, list is the name of the entry, an href,
4727         # and link is the action links of the entry.
4728
4729         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4730         if (exists $t->{'size'}) {
4731                 print "<td class=\"size\">$t->{'size'}</td>\n";
4732         }
4733         if ($t->{'type'} eq "blob") {
4734                 print "<td class=\"list\">" .
4735                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4736                                                file_name=>"$basedir$t->{'name'}", %base_key),
4737                                 -class => "list"}, esc_path($t->{'name'}));
4738                 if (S_ISLNK(oct $t->{'mode'})) {
4739                         my $link_target = git_get_link_target($t->{'hash'});
4740                         if ($link_target) {
4741                                 my $norm_target = normalize_link_target($link_target, $basedir);
4742                                 if (defined $norm_target) {
4743                                         print " -> " .
4744                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4745                                                                      file_name=>$norm_target),
4746                                                        -title => $norm_target}, esc_path($link_target));
4747                                 } else {
4748                                         print " -> " . esc_path($link_target);
4749                                 }
4750                         }
4751                 }
4752                 print "</td>\n";
4753                 print "<td class=\"link\">";
4754                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4755                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4756                               "blob");
4757                 if ($have_blame) {
4758                         print " | " .
4759                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4760                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4761                                       "blame");
4762                 }
4763                 if (defined $hash_base) {
4764                         print " | " .
4765                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4766                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4767                                       "history");
4768                 }
4769                 print " | " .
4770                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4771                                                file_name=>"$basedir$t->{'name'}")},
4772                                 "raw");
4773                 print "</td>\n";
4774
4775         } elsif ($t->{'type'} eq "tree") {
4776                 print "<td class=\"list\">";
4777                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4778                                              file_name=>"$basedir$t->{'name'}",
4779                                              %base_key)},
4780                               esc_path($t->{'name'}));
4781                 print "</td>\n";
4782                 print "<td class=\"link\">";
4783                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4784                                              file_name=>"$basedir$t->{'name'}",
4785                                              %base_key)},
4786                               "tree");
4787                 if (defined $hash_base) {
4788                         print " | " .
4789                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4790                                                      file_name=>"$basedir$t->{'name'}")},
4791                                       "history");
4792                 }
4793                 print "</td>\n";
4794         } else {
4795                 # unknown object: we can only present history for it
4796                 # (this includes 'commit' object, i.e. submodule support)
4797                 print "<td class=\"list\">" .
4798                       esc_path($t->{'name'}) .
4799                       "</td>\n";
4800                 print "<td class=\"link\">";
4801                 if (defined $hash_base) {
4802                         print $cgi->a({-href => href(action=>"history",
4803                                                      hash_base=>$hash_base,
4804                                                      file_name=>"$basedir$t->{'name'}")},
4805                                       "history");
4806                 }
4807                 print "</td>\n";
4808         }
4809 }
4810
4811 ## ......................................................................
4812 ## functions printing large fragments of HTML
4813
4814 # get pre-image filenames for merge (combined) diff
4815 sub fill_from_file_info {
4816         my ($diff, @parents) = @_;
4817
4818         $diff->{'from_file'} = [ ];
4819         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4820         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4821                 if ($diff->{'status'}[$i] eq 'R' ||
4822                     $diff->{'status'}[$i] eq 'C') {
4823                         $diff->{'from_file'}[$i] =
4824                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4825                 }
4826         }
4827
4828         return $diff;
4829 }
4830
4831 # is current raw difftree line of file deletion
4832 sub is_deleted {
4833         my $diffinfo = shift;
4834
4835         return $diffinfo->{'to_id'} eq ('0' x 40);
4836 }
4837
4838 # does patch correspond to [previous] difftree raw line
4839 # $diffinfo  - hashref of parsed raw diff format
4840 # $patchinfo - hashref of parsed patch diff format
4841 #              (the same keys as in $diffinfo)
4842 sub is_patch_split {
4843         my ($diffinfo, $patchinfo) = @_;
4844
4845         return defined $diffinfo && defined $patchinfo
4846                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4847 }
4848
4849
4850 sub git_difftree_body {
4851         my ($difftree, $hash, @parents) = @_;
4852         my ($parent) = $parents[0];
4853         my $have_blame = gitweb_check_feature('blame');
4854         print "<div class=\"list_head\">\n";
4855         if ($#{$difftree} > 10) {
4856                 print(($#{$difftree} + 1) . " files changed:\n");
4857         }
4858         print "</div>\n";
4859
4860         print "<table class=\"" .
4861               (@parents > 1 ? "combined " : "") .
4862               "diff_tree\">\n";
4863
4864         # header only for combined diff in 'commitdiff' view
4865         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4866         if ($has_header) {
4867                 # table header
4868                 print "<thead><tr>\n" .
4869                        "<th></th><th></th>\n"; # filename, patchN link
4870                 for (my $i = 0; $i < @parents; $i++) {
4871                         my $par = $parents[$i];
4872                         print "<th>" .
4873                               $cgi->a({-href => href(action=>"commitdiff",
4874                                                      hash=>$hash, hash_parent=>$par),
4875                                        -title => 'commitdiff to parent number ' .
4876                                                   ($i+1) . ': ' . substr($par,0,7)},
4877                                       $i+1) .
4878                               "&nbsp;</th>\n";
4879                 }
4880                 print "</tr></thead>\n<tbody>\n";
4881         }
4882
4883         my $alternate = 1;
4884         my $patchno = 0;
4885         foreach my $line (@{$difftree}) {
4886                 my $diff = parsed_difftree_line($line);
4887
4888                 if ($alternate) {
4889                         print "<tr class=\"dark\">\n";
4890                 } else {
4891                         print "<tr class=\"light\">\n";
4892                 }
4893                 $alternate ^= 1;
4894
4895                 if (exists $diff->{'nparents'}) { # combined diff
4896
4897                         fill_from_file_info($diff, @parents)
4898                                 unless exists $diff->{'from_file'};
4899
4900                         if (!is_deleted($diff)) {
4901                                 # file exists in the result (child) commit
4902                                 print "<td>" .
4903                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4904                                                              file_name=>$diff->{'to_file'},
4905                                                              hash_base=>$hash),
4906                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4907                                       "</td>\n";
4908                         } else {
4909                                 print "<td>" .
4910                                       esc_path($diff->{'to_file'}) .
4911                                       "</td>\n";
4912                         }
4913
4914                         if ($action eq 'commitdiff') {
4915                                 # link to patch
4916                                 $patchno++;
4917                                 print "<td class=\"link\">" .
4918                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4919                                               "patch") .
4920                                       " | " .
4921                                       "</td>\n";
4922                         }
4923
4924                         my $has_history = 0;
4925                         my $not_deleted = 0;
4926                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4927                                 my $hash_parent = $parents[$i];
4928                                 my $from_hash = $diff->{'from_id'}[$i];
4929                                 my $from_path = $diff->{'from_file'}[$i];
4930                                 my $status = $diff->{'status'}[$i];
4931
4932                                 $has_history ||= ($status ne 'A');
4933                                 $not_deleted ||= ($status ne 'D');
4934
4935                                 if ($status eq 'A') {
4936                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4937                                 } elsif ($status eq 'D') {
4938                                         print "<td class=\"link\">" .
4939                                               $cgi->a({-href => href(action=>"blob",
4940                                                                      hash_base=>$hash,
4941                                                                      hash=>$from_hash,
4942                                                                      file_name=>$from_path)},
4943                                                       "blob" . ($i+1)) .
4944                                               " | </td>\n";
4945                                 } else {
4946                                         if ($diff->{'to_id'} eq $from_hash) {
4947                                                 print "<td class=\"link nochange\">";
4948                                         } else {
4949                                                 print "<td class=\"link\">";
4950                                         }
4951                                         print $cgi->a({-href => href(action=>"blobdiff",
4952                                                                      hash=>$diff->{'to_id'},
4953                                                                      hash_parent=>$from_hash,
4954                                                                      hash_base=>$hash,
4955                                                                      hash_parent_base=>$hash_parent,
4956                                                                      file_name=>$diff->{'to_file'},
4957                                                                      file_parent=>$from_path)},
4958                                                       "diff" . ($i+1)) .
4959                                               " | </td>\n";
4960                                 }
4961                         }
4962
4963                         print "<td class=\"link\">";
4964                         if ($not_deleted) {
4965                                 print $cgi->a({-href => href(action=>"blob",
4966                                                              hash=>$diff->{'to_id'},
4967                                                              file_name=>$diff->{'to_file'},
4968                                                              hash_base=>$hash)},
4969                                               "blob");
4970                                 print " | " if ($has_history);
4971                         }
4972                         if ($has_history) {
4973                                 print $cgi->a({-href => href(action=>"history",
4974                                                              file_name=>$diff->{'to_file'},
4975                                                              hash_base=>$hash)},
4976                                               "history");
4977                         }
4978                         print "</td>\n";
4979
4980                         print "</tr>\n";
4981                         next; # instead of 'else' clause, to avoid extra indent
4982                 }
4983                 # else ordinary diff
4984
4985                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4986                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4987                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4988                         $to_mode_oct = oct $diff->{'to_mode'};
4989                         if (S_ISREG($to_mode_oct)) { # only for regular file
4990                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4991                         }
4992                         $to_file_type = file_type($diff->{'to_mode'});
4993                 }
4994                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4995                         $from_mode_oct = oct $diff->{'from_mode'};
4996                         if (S_ISREG($from_mode_oct)) { # only for regular file
4997                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4998                         }
4999                         $from_file_type = file_type($diff->{'from_mode'});
5000                 }
5001
5002                 if ($diff->{'status'} eq "A") { # created
5003                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
5004                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
5005                         $mode_chng   .= "]</span>";
5006                         print "<td>";
5007                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5008                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5009                                       -class => "list"}, esc_path($diff->{'file'}));
5010                         print "</td>\n";
5011                         print "<td>$mode_chng</td>\n";
5012                         print "<td class=\"link\">";
5013                         if ($action eq 'commitdiff') {
5014                                 # link to patch
5015                                 $patchno++;
5016                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5017                                               "patch") .
5018                                       " | ";
5019                         }
5020                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5021                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5022                                       "blob");
5023                         print "</td>\n";
5024
5025                 } elsif ($diff->{'status'} eq "D") { # deleted
5026                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5027                         print "<td>";
5028                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5029                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5030                                        -class => "list"}, esc_path($diff->{'file'}));
5031                         print "</td>\n";
5032                         print "<td>$mode_chng</td>\n";
5033                         print "<td class=\"link\">";
5034                         if ($action eq 'commitdiff') {
5035                                 # link to patch
5036                                 $patchno++;
5037                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5038                                               "patch") .
5039                                       " | ";
5040                         }
5041                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5042                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5043                                       "blob") . " | ";
5044                         if ($have_blame) {
5045                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5046                                                              file_name=>$diff->{'file'})},
5047                                               "blame") . " | ";
5048                         }
5049                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5050                                                      file_name=>$diff->{'file'})},
5051                                       "history");
5052                         print "</td>\n";
5053
5054                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5055                         my $mode_chnge = "";
5056                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5057                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5058                                 if ($from_file_type ne $to_file_type) {
5059                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5060                                 }
5061                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5062                                         if ($from_mode_str && $to_mode_str) {
5063                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5064                                         } elsif ($to_mode_str) {
5065                                                 $mode_chnge .= " mode: $to_mode_str";
5066                                         }
5067                                 }
5068                                 $mode_chnge .= "]</span>\n";
5069                         }
5070                         print "<td>";
5071                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5072                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5073                                       -class => "list"}, esc_path($diff->{'file'}));
5074                         print "</td>\n";
5075                         print "<td>$mode_chnge</td>\n";
5076                         print "<td class=\"link\">";
5077                         if ($action eq 'commitdiff') {
5078                                 # link to patch
5079                                 $patchno++;
5080                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5081                                               "patch") .
5082                                       " | ";
5083                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5084                                 # "commit" view and modified file (not onlu mode changed)
5085                                 print $cgi->a({-href => href(action=>"blobdiff",
5086                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5087                                                              hash_base=>$hash, hash_parent_base=>$parent,
5088                                                              file_name=>$diff->{'file'})},
5089                                               "diff") .
5090                                       " | ";
5091                         }
5092                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5093                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5094                                        "blob") . " | ";
5095                         if ($have_blame) {
5096                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5097                                                              file_name=>$diff->{'file'})},
5098                                               "blame") . " | ";
5099                         }
5100                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5101                                                      file_name=>$diff->{'file'})},
5102                                       "history");
5103                         print "</td>\n";
5104
5105                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5106                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5107                         my $nstatus = $status_name{$diff->{'status'}};
5108                         my $mode_chng = "";
5109                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5110                                 # mode also for directories, so we cannot use $to_mode_str
5111                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5112                         }
5113                         print "<td>" .
5114                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5115                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5116                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5117                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5118                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5119                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5120                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5121                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5122                               "<td class=\"link\">";
5123                         if ($action eq 'commitdiff') {
5124                                 # link to patch
5125                                 $patchno++;
5126                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5127                                               "patch") .
5128                                       " | ";
5129                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5130                                 # "commit" view and modified file (not only pure rename or copy)
5131                                 print $cgi->a({-href => href(action=>"blobdiff",
5132                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5133                                                              hash_base=>$hash, hash_parent_base=>$parent,
5134                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5135                                               "diff") .
5136                                       " | ";
5137                         }
5138                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5139                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5140                                       "blob") . " | ";
5141                         if ($have_blame) {
5142                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5143                                                              file_name=>$diff->{'to_file'})},
5144                                               "blame") . " | ";
5145                         }
5146                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5147                                                     file_name=>$diff->{'to_file'})},
5148                                       "history");
5149                         print "</td>\n";
5150
5151                 } # we should not encounter Unmerged (U) or Unknown (X) status
5152                 print "</tr>\n";
5153         }
5154         print "</tbody>" if $has_header;
5155         print "</table>\n";
5156 }
5157
5158 # Print context lines and then rem/add lines in a side-by-side manner.
5159 sub print_sidebyside_diff_lines {
5160         my ($ctx, $rem, $add) = @_;
5161
5162         # print context block before add/rem block
5163         if (@$ctx) {
5164                 print join '',
5165                         '<div class="chunk_block ctx">',
5166                                 '<div class="old">',
5167                                 @$ctx,
5168                                 '</div>',
5169                                 '<div class="new">',
5170                                 @$ctx,
5171                                 '</div>',
5172                         '</div>';
5173         }
5174
5175         if (!@$add) {
5176                 # pure removal
5177                 print join '',
5178                         '<div class="chunk_block rem">',
5179                                 '<div class="old">',
5180                                 @$rem,
5181                                 '</div>',
5182                         '</div>';
5183         } elsif (!@$rem) {
5184                 # pure addition
5185                 print join '',
5186                         '<div class="chunk_block add">',
5187                                 '<div class="new">',
5188                                 @$add,
5189                                 '</div>',
5190                         '</div>';
5191         } else {
5192                 print join '',
5193                         '<div class="chunk_block chg">',
5194                                 '<div class="old">',
5195                                 @$rem,
5196                                 '</div>',
5197                                 '<div class="new">',
5198                                 @$add,
5199                                 '</div>',
5200                         '</div>';
5201         }
5202 }
5203
5204 # Print context lines and then rem/add lines in inline manner.
5205 sub print_inline_diff_lines {
5206         my ($ctx, $rem, $add) = @_;
5207
5208         print @$ctx, @$rem, @$add;
5209 }
5210
5211 # Format removed and added line, mark changed part and HTML-format them.
5212 # Implementation is based on contrib/diff-highlight
5213 sub format_rem_add_lines_pair {
5214         my ($rem, $add, $num_parents) = @_;
5215
5216         # We need to untabify lines before split()'ing them;
5217         # otherwise offsets would be invalid.
5218         chomp $rem;
5219         chomp $add;
5220         $rem = untabify($rem);
5221         $add = untabify($add);
5222
5223         my @rem = split(//, $rem);
5224         my @add = split(//, $add);
5225         my ($esc_rem, $esc_add);
5226         # Ignore leading +/- characters for each parent.
5227         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5228         my ($prefix_has_nonspace, $suffix_has_nonspace);
5229
5230         my $shorter = (@rem < @add) ? @rem : @add;
5231         while ($prefix_len < $shorter) {
5232                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5233
5234                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5235                 $prefix_len++;
5236         }
5237
5238         while ($prefix_len + $suffix_len < $shorter) {
5239                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5240
5241                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5242                 $suffix_len++;
5243         }
5244
5245         # Mark lines that are different from each other, but have some common
5246         # part that isn't whitespace.  If lines are completely different, don't
5247         # mark them because that would make output unreadable, especially if
5248         # diff consists of multiple lines.
5249         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5250                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5251                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5252                 $esc_add = esc_html_hl_regions($add, 'marked',
5253                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5254         } else {
5255                 $esc_rem = esc_html($rem, -nbsp=>1);
5256                 $esc_add = esc_html($add, -nbsp=>1);
5257         }
5258
5259         return format_diff_line(\$esc_rem, 'rem'),
5260                format_diff_line(\$esc_add, 'add');
5261 }
5262
5263 # HTML-format diff context, removed and added lines.
5264 sub format_ctx_rem_add_lines {
5265         my ($ctx, $rem, $add, $num_parents) = @_;
5266         my (@new_ctx, @new_rem, @new_add);
5267         my $can_highlight = 0;
5268         my $is_combined = ($num_parents > 1);
5269
5270         # Highlight if every removed line has a corresponding added line.
5271         if (@$add > 0 && @$add == @$rem) {
5272                 $can_highlight = 1;
5273
5274                 # Highlight lines in combined diff only if the chunk contains
5275                 # diff between the same version, e.g.
5276                 #
5277                 #    - a
5278                 #   -  b
5279                 #    + c
5280                 #   +  d
5281                 #
5282                 # Otherwise the highlightling would be confusing.
5283                 if ($is_combined) {
5284                         for (my $i = 0; $i < @$add; $i++) {
5285                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5286                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5287
5288                                 $prefix_rem =~ s/-/+/g;
5289
5290                                 if ($prefix_rem ne $prefix_add) {
5291                                         $can_highlight = 0;
5292                                         last;
5293                                 }
5294                         }
5295                 }
5296         }
5297
5298         if ($can_highlight) {
5299                 for (my $i = 0; $i < @$add; $i++) {
5300                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5301                                 $rem->[$i], $add->[$i], $num_parents);
5302                         push @new_rem, $line_rem;
5303                         push @new_add, $line_add;
5304                 }
5305         } else {
5306                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5307                 @new_add = map { format_diff_line($_, 'add') } @$add;
5308         }
5309
5310         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5311
5312         return (\@new_ctx, \@new_rem, \@new_add);
5313 }
5314
5315 # Print context lines and then rem/add lines.
5316 sub print_diff_lines {
5317         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5318         my $is_combined = $num_parents > 1;
5319
5320         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5321                 $num_parents);
5322
5323         if ($diff_style eq 'sidebyside' && !$is_combined) {
5324                 print_sidebyside_diff_lines($ctx, $rem, $add);
5325         } else {
5326                 # default 'inline' style and unknown styles
5327                 print_inline_diff_lines($ctx, $rem, $add);
5328         }
5329 }
5330
5331 sub print_diff_chunk {
5332         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5333         my (@ctx, @rem, @add);
5334
5335         # The class of the previous line.
5336         my $prev_class = '';
5337
5338         return unless @chunk;
5339
5340         # incomplete last line might be among removed or added lines,
5341         # or both, or among context lines: find which
5342         for (my $i = 1; $i < @chunk; $i++) {
5343                 if ($chunk[$i][0] eq 'incomplete') {
5344                         $chunk[$i][0] = $chunk[$i-1][0];
5345                 }
5346         }
5347
5348         # guardian
5349         push @chunk, ["", ""];
5350
5351         foreach my $line_info (@chunk) {
5352                 my ($class, $line) = @$line_info;
5353
5354                 # print chunk headers
5355                 if ($class && $class eq 'chunk_header') {
5356                         print format_diff_line($line, $class, $from, $to);
5357                         next;
5358                 }
5359
5360                 ## print from accumulator when have some add/rem lines or end
5361                 # of chunk (flush context lines), or when have add and rem
5362                 # lines and new block is reached (otherwise add/rem lines could
5363                 # be reordered)
5364                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5365                     (@rem && @add && $class ne $prev_class)) {
5366                         print_diff_lines(\@ctx, \@rem, \@add,
5367                                          $diff_style, $num_parents);
5368                         @ctx = @rem = @add = ();
5369                 }
5370
5371                 ## adding lines to accumulator
5372                 # guardian value
5373                 last unless $line;
5374                 # rem, add or change
5375                 if ($class eq 'rem') {
5376                         push @rem, $line;
5377                 } elsif ($class eq 'add') {
5378                         push @add, $line;
5379                 }
5380                 # context line
5381                 if ($class eq 'ctx') {
5382                         push @ctx, $line;
5383                 }
5384
5385                 $prev_class = $class;
5386         }
5387 }
5388
5389 sub git_patchset_body {
5390         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5391         my ($hash_parent) = $hash_parents[0];
5392
5393         my $is_combined = (@hash_parents > 1);
5394         my $patch_idx = 0;
5395         my $patch_number = 0;
5396         my $patch_line;
5397         my $diffinfo;
5398         my $to_name;
5399         my (%from, %to);
5400         my @chunk; # for side-by-side diff
5401
5402         print "<div class=\"patchset\">\n";
5403
5404         # skip to first patch
5405         while ($patch_line = <$fd>) {
5406                 chomp $patch_line;
5407
5408                 last if ($patch_line =~ m/^diff /);
5409         }
5410
5411  PATCH:
5412         while ($patch_line) {
5413
5414                 # parse "git diff" header line
5415                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5416                         # $1 is from_name, which we do not use
5417                         $to_name = unquote($2);
5418                         $to_name =~ s!^b/!!;
5419                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5420                         # $1 is 'cc' or 'combined', which we do not use
5421                         $to_name = unquote($2);
5422                 } else {
5423                         $to_name = undef;
5424                 }
5425
5426                 # check if current patch belong to current raw line
5427                 # and parse raw git-diff line if needed
5428                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5429                         # this is continuation of a split patch
5430                         print "<div class=\"patch cont\">\n";
5431                 } else {
5432                         # advance raw git-diff output if needed
5433                         $patch_idx++ if defined $diffinfo;
5434
5435                         # read and prepare patch information
5436                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5437
5438                         # compact combined diff output can have some patches skipped
5439                         # find which patch (using pathname of result) we are at now;
5440                         if ($is_combined) {
5441                                 while ($to_name ne $diffinfo->{'to_file'}) {
5442                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5443                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5444                                               "</div>\n";  # class="patch"
5445
5446                                         $patch_idx++;
5447                                         $patch_number++;
5448
5449                                         last if $patch_idx > $#$difftree;
5450                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5451                                 }
5452                         }
5453
5454                         # modifies %from, %to hashes
5455                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5456
5457                         # this is first patch for raw difftree line with $patch_idx index
5458                         # we index @$difftree array from 0, but number patches from 1
5459                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5460                 }
5461
5462                 # git diff header
5463                 #assert($patch_line =~ m/^diff /) if DEBUG;
5464                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5465                 $patch_number++;
5466                 # print "git diff" header
5467                 print format_git_diff_header_line($patch_line, $diffinfo,
5468                                                   \%from, \%to);
5469
5470                 # print extended diff header
5471                 print "<div class=\"diff extended_header\">\n";
5472         EXTENDED_HEADER:
5473                 while ($patch_line = <$fd>) {
5474                         chomp $patch_line;
5475
5476                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5477
5478                         print format_extended_diff_header_line($patch_line, $diffinfo,
5479                                                                \%from, \%to);
5480                 }
5481                 print "</div>\n"; # class="diff extended_header"
5482
5483                 # from-file/to-file diff header
5484                 if (! $patch_line) {
5485                         print "</div>\n"; # class="patch"
5486                         last PATCH;
5487                 }
5488                 next PATCH if ($patch_line =~ m/^diff /);
5489                 #assert($patch_line =~ m/^---/) if DEBUG;
5490
5491                 my $last_patch_line = $patch_line;
5492                 $patch_line = <$fd>;
5493                 chomp $patch_line;
5494                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5495
5496                 print format_diff_from_to_header($last_patch_line, $patch_line,
5497                                                  $diffinfo, \%from, \%to,
5498                                                  @hash_parents);
5499
5500                 # the patch itself
5501         LINE:
5502                 while ($patch_line = <$fd>) {
5503                         chomp $patch_line;
5504
5505                         next PATCH if ($patch_line =~ m/^diff /);
5506
5507                         my $class = diff_line_class($patch_line, \%from, \%to);
5508
5509                         if ($class eq 'chunk_header') {
5510                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5511                                 @chunk = ();
5512                         }
5513
5514                         push @chunk, [ $class, $patch_line ];
5515                 }
5516
5517         } continue {
5518                 if (@chunk) {
5519                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5520                         @chunk = ();
5521                 }
5522                 print "</div>\n"; # class="patch"
5523         }
5524
5525         # for compact combined (--cc) format, with chunk and patch simplification
5526         # the patchset might be empty, but there might be unprocessed raw lines
5527         for (++$patch_idx if $patch_number > 0;
5528              $patch_idx < @$difftree;
5529              ++$patch_idx) {
5530                 # read and prepare patch information
5531                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5532
5533                 # generate anchor for "patch" links in difftree / whatchanged part
5534                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5535                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5536                       "</div>\n";  # class="patch"
5537
5538                 $patch_number++;
5539         }
5540
5541         if ($patch_number == 0) {
5542                 if (@hash_parents > 1) {
5543                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5544                 } else {
5545                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5546                 }
5547         }
5548
5549         print "</div>\n"; # class="patchset"
5550 }
5551
5552 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5553
5554 sub git_project_search_form {
5555         my ($searchtext, $search_use_regexp) = @_;
5556
5557         my $limit = '';
5558         if ($project_filter) {
5559                 $limit = " in '$project_filter/'";
5560         }
5561
5562         print "<div class=\"projsearch\">\n";
5563         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5564               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5565         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5566                 if (defined $project_filter);
5567         print $cgi->textfield(-name => 's', -value => $searchtext,
5568                               -title => "Search project by name and description$limit",
5569                               -size => 60) . "\n" .
5570               "<span title=\"Extended regular expression\">" .
5571               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5572                              -checked => $search_use_regexp) .
5573               "</span>\n" .
5574               $cgi->submit(-name => 'btnS', -value => 'Search') .
5575               $cgi->end_form() . "\n" .
5576               $cgi->a({-href => href(project => undef, searchtext => undef,
5577                                      project_filter => $project_filter)},
5578                       esc_html("List all projects$limit")) . "<br />\n";
5579         print "</div>\n";
5580 }
5581
5582 # entry for given @keys needs filling if at least one of keys in list
5583 # is not present in %$project_info
5584 sub project_info_needs_filling {
5585         my ($project_info, @keys) = @_;
5586
5587         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5588         foreach my $key (@keys) {
5589                 if (!exists $project_info->{$key}) {
5590                         return 1;
5591                 }
5592         }
5593         return;
5594 }
5595
5596 # fills project list info (age, description, owner, category, forks, etc.)
5597 # for each project in the list, removing invalid projects from
5598 # returned list, or fill only specified info.
5599 #
5600 # Invalid projects are removed from the returned list if and only if you
5601 # ask 'age' or 'age_string' to be filled, because they are the only fields
5602 # that run unconditionally git command that requires repository, and
5603 # therefore do always check if project repository is invalid.
5604 #
5605 # USAGE:
5606 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5607 #   ensures that 'descr_long' and 'ctags' fields are filled
5608 # * @project_list = fill_project_list_info(\@project_list)
5609 #   ensures that all fields are filled (and invalid projects removed)
5610 #
5611 # NOTE: modifies $projlist, but does not remove entries from it
5612 sub fill_project_list_info {
5613         my ($projlist, @wanted_keys) = @_;
5614         my @projects;
5615         my $filter_set = sub { return @_; };
5616         if (@wanted_keys) {
5617                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5618                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5619         }
5620
5621         my $show_ctags = gitweb_check_feature('ctags');
5622  PROJECT:
5623         foreach my $pr (@$projlist) {
5624                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5625                         my (@activity) = git_get_last_activity($pr->{'path'});
5626                         unless (@activity) {
5627                                 next PROJECT;
5628                         }
5629                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5630                 }
5631                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5632                         my $descr = git_get_project_description($pr->{'path'}) || "";
5633                         $descr = to_utf8($descr);
5634                         $pr->{'descr_long'} = $descr;
5635                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5636                 }
5637                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5638                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5639                 }
5640                 if ($show_ctags &&
5641                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5642                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5643                 }
5644                 if ($projects_list_group_categories &&
5645                     project_info_needs_filling($pr, $filter_set->('category'))) {
5646                         my $cat = git_get_project_category($pr->{'path'}) ||
5647                                                            $project_list_default_category;
5648                         $pr->{'category'} = to_utf8($cat);
5649                 }
5650
5651                 push @projects, $pr;
5652         }
5653
5654         return @projects;
5655 }
5656
5657 sub sort_projects_list {
5658         my ($projlist, $order) = @_;
5659
5660         sub order_str {
5661                 my $key = shift;
5662                 return sub { $a->{$key} cmp $b->{$key} };
5663         }
5664
5665         sub order_num_then_undef {
5666                 my $key = shift;
5667                 return sub {
5668                         defined $a->{$key} ?
5669                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5670                                 (defined $b->{$key} ? 1 : 0)
5671                 };
5672         }
5673
5674         my %orderings = (
5675                 project => order_str('path'),
5676                 descr => order_str('descr_long'),
5677                 owner => order_str('owner'),
5678                 age => order_num_then_undef('age'),
5679         );
5680
5681         my $ordering = $orderings{$order};
5682         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5683 }
5684
5685 # returns a hash of categories, containing the list of project
5686 # belonging to each category
5687 sub build_projlist_by_category {
5688         my ($projlist, $from, $to) = @_;
5689         my %categories;
5690
5691         $from = 0 unless defined $from;
5692         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5693
5694         for (my $i = $from; $i <= $to; $i++) {
5695                 my $pr = $projlist->[$i];
5696                 push @{$categories{ $pr->{'category'} }}, $pr;
5697         }
5698
5699         return wantarray ? %categories : \%categories;
5700 }
5701
5702 # print 'sort by' <th> element, generating 'sort by $name' replay link
5703 # if that order is not selected
5704 sub print_sort_th {
5705         print format_sort_th(@_);
5706 }
5707
5708 sub format_sort_th {
5709         my ($name, $order, $header) = @_;
5710         my $sort_th = "";
5711         $header ||= ucfirst($name);
5712
5713         if ($order eq $name) {
5714                 $sort_th .= "<th>$header</th>\n";
5715         } else {
5716                 $sort_th .= "<th>" .
5717                             $cgi->a({-href => href(-replay=>1, order=>$name),
5718                                      -class => "header"}, $header) .
5719                             "</th>\n";
5720         }
5721
5722         return $sort_th;
5723 }
5724
5725 sub git_project_list_rows {
5726         my ($projlist, $from, $to, $check_forks) = @_;
5727
5728         $from = 0 unless defined $from;
5729         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5730
5731         my $alternate = 1;
5732         for (my $i = $from; $i <= $to; $i++) {
5733                 my $pr = $projlist->[$i];
5734
5735                 if ($alternate) {
5736                         print "<tr class=\"dark\">\n";
5737                 } else {
5738                         print "<tr class=\"light\">\n";
5739                 }
5740                 $alternate ^= 1;
5741
5742                 if ($check_forks) {
5743                         print "<td>";
5744                         if ($pr->{'forks'}) {
5745                                 my $nforks = scalar @{$pr->{'forks'}};
5746                                 if ($nforks > 0) {
5747                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5748                                                        -title => "$nforks forks"}, "+");
5749                                 } else {
5750                                         print $cgi->span({-title => "$nforks forks"}, "+");
5751                                 }
5752                         }
5753                         print "</td>\n";
5754                 }
5755                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5756                                         -class => "list"},
5757                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5758                       "</td>\n" .
5759                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5760                                         -class => "list",
5761                                         -title => $pr->{'descr_long'}},
5762                                         $search_regexp
5763                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5764                                                                     $pr->{'descr'}, $search_regexp)
5765                                         : esc_html($pr->{'descr'})) .
5766                       "</td>\n";
5767                 unless ($omit_owner) {
5768                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5769                 }
5770                 unless ($omit_age_column) {
5771                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5772                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5773                 }
5774                 print"<td class=\"link\">" .
5775                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5776                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5777                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5778                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5779                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5780                       "</td>\n" .
5781                       "</tr>\n";
5782         }
5783 }
5784
5785 sub git_project_list_body {
5786         # actually uses global variable $project
5787         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5788         my @projects = @$projlist;
5789
5790         my $check_forks = gitweb_check_feature('forks');
5791         my $show_ctags  = gitweb_check_feature('ctags');
5792         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5793         $check_forks = undef
5794                 if ($tagfilter || $search_regexp);
5795
5796         # filtering out forks before filling info allows to do less work
5797         @projects = filter_forks_from_projects_list(\@projects)
5798                 if ($check_forks);
5799         # search_projects_list pre-fills required info
5800         @projects = search_projects_list(\@projects,
5801                                          'search_regexp' => $search_regexp,
5802                                          'tagfilter'  => $tagfilter)
5803                 if ($tagfilter || $search_regexp);
5804         # fill the rest
5805         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5806         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5807         push @all_fields, 'owner' unless($omit_owner);
5808         @projects = fill_project_list_info(\@projects, @all_fields);
5809
5810         $order ||= $default_projects_order;
5811         $from = 0 unless defined $from;
5812         $to = $#projects if (!defined $to || $#projects < $to);
5813
5814         # short circuit
5815         if ($from > $to) {
5816                 print "<center>\n".
5817                       "<b>No such projects found</b><br />\n".
5818                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5819                       "</center>\n<br />\n";
5820                 return;
5821         }
5822
5823         @projects = sort_projects_list(\@projects, $order);
5824
5825         if ($show_ctags) {
5826                 my $ctags = git_gather_all_ctags(\@projects);
5827                 my $cloud = git_populate_project_tagcloud($ctags);
5828                 print git_show_project_tagcloud($cloud, 64);
5829         }
5830
5831         print "<table class=\"project_list\">\n";
5832         unless ($no_header) {
5833                 print "<tr>\n";
5834                 if ($check_forks) {
5835                         print "<th></th>\n";
5836                 }
5837                 print_sort_th('project', $order, 'Project');
5838                 print_sort_th('descr', $order, 'Description');
5839                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5840                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5841                 print "<th></th>\n" . # for links
5842                       "</tr>\n";
5843         }
5844
5845         if ($projects_list_group_categories) {
5846                 # only display categories with projects in the $from-$to window
5847                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5848                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5849                 foreach my $cat (sort keys %categories) {
5850                         unless ($cat eq "") {
5851                                 print "<tr>\n";
5852                                 if ($check_forks) {
5853                                         print "<td></td>\n";
5854                                 }
5855                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5856                                 print "</tr>\n";
5857                         }
5858
5859                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5860                 }
5861         } else {
5862                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5863         }
5864
5865         if (defined $extra) {
5866                 print "<tr>\n";
5867                 if ($check_forks) {
5868                         print "<td></td>\n";
5869                 }
5870                 print "<td colspan=\"5\">$extra</td>\n" .
5871                       "</tr>\n";
5872         }
5873         print "</table>\n";
5874 }
5875
5876 sub git_log_body {
5877         # uses global variable $project
5878         my ($commitlist, $from, $to, $refs, $extra) = @_;
5879
5880         $from = 0 unless defined $from;
5881         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5882
5883         for (my $i = 0; $i <= $to; $i++) {
5884                 my %co = %{$commitlist->[$i]};
5885                 next if !%co;
5886                 my $commit = $co{'id'};
5887                 my $ref = format_ref_marker($refs, $commit);
5888                 git_print_header_div('commit',
5889                                "<span class=\"age\">$co{'age_string'}</span>" .
5890                                esc_html($co{'title'}) . $ref,
5891                                $commit);
5892                 print "<div class=\"title_text\">\n" .
5893                       "<div class=\"log_link\">\n" .
5894                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5895                       " | " .
5896                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5897                       " | " .
5898                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5899                       "<br/>\n" .
5900                       "</div>\n";
5901                       git_print_authorship(\%co, -tag => 'span');
5902                       print "<br/>\n</div>\n";
5903
5904                 print "<div class=\"log_body\">\n";
5905                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5906                 print "</div>\n";
5907         }
5908         if ($extra) {
5909                 print "<div class=\"page_nav\">\n";
5910                 print "$extra\n";
5911                 print "</div>\n";
5912         }
5913 }
5914
5915 sub git_shortlog_body {
5916         # uses global variable $project
5917         my ($commitlist, $from, $to, $refs, $extra) = @_;
5918
5919         $from = 0 unless defined $from;
5920         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5921
5922         print "<table class=\"shortlog\">\n";
5923         my $alternate = 1;
5924         for (my $i = $from; $i <= $to; $i++) {
5925                 my %co = %{$commitlist->[$i]};
5926                 my $commit = $co{'id'};
5927                 my $ref = format_ref_marker($refs, $commit);
5928                 if ($alternate) {
5929                         print "<tr class=\"dark\">\n";
5930                 } else {
5931                         print "<tr class=\"light\">\n";
5932                 }
5933                 $alternate ^= 1;
5934                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5935                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5936                       format_author_html('td', \%co, 10) . "<td>";
5937                 print format_subject_html($co{'title'}, $co{'title_short'},
5938                                           href(action=>"commit", hash=>$commit), $ref);
5939                 print "</td>\n" .
5940                       "<td class=\"link\">" .
5941                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5942                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5943                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5944                 my $snapshot_links = format_snapshot_links($commit);
5945                 if (defined $snapshot_links) {
5946                         print " | " . $snapshot_links;
5947                 }
5948                 print "</td>\n" .
5949                       "</tr>\n";
5950         }
5951         if (defined $extra) {
5952                 print "<tr>\n" .
5953                       "<td colspan=\"4\">$extra</td>\n" .
5954                       "</tr>\n";
5955         }
5956         print "</table>\n";
5957 }
5958
5959 sub git_history_body {
5960         # Warning: assumes constant type (blob or tree) during history
5961         my ($commitlist, $from, $to, $refs, $extra,
5962             $file_name, $file_hash, $ftype) = @_;
5963
5964         $from = 0 unless defined $from;
5965         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5966
5967         print "<table class=\"history\">\n";
5968         my $alternate = 1;
5969         for (my $i = $from; $i <= $to; $i++) {
5970                 my %co = %{$commitlist->[$i]};
5971                 if (!%co) {
5972                         next;
5973                 }
5974                 my $commit = $co{'id'};
5975
5976                 my $ref = format_ref_marker($refs, $commit);
5977
5978                 if ($alternate) {
5979                         print "<tr class=\"dark\">\n";
5980                 } else {
5981                         print "<tr class=\"light\">\n";
5982                 }
5983                 $alternate ^= 1;
5984                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5985         # shortlog:   format_author_html('td', \%co, 10)
5986                       format_author_html('td', \%co, 15, 3) . "<td>";
5987                 # originally git_history used chop_str($co{'title'}, 50)
5988                 print format_subject_html($co{'title'}, $co{'title_short'},
5989                                           href(action=>"commit", hash=>$commit), $ref);
5990                 print "</td>\n" .
5991                       "<td class=\"link\">" .
5992                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5993                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5994
5995                 if ($ftype eq 'blob') {
5996                         my $blob_current = $file_hash;
5997                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5998                         if (defined $blob_current && defined $blob_parent &&
5999                                         $blob_current ne $blob_parent) {
6000                                 print " | " .
6001                                         $cgi->a({-href => href(action=>"blobdiff",
6002                                                                hash=>$blob_current, hash_parent=>$blob_parent,
6003                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
6004                                                                file_name=>$file_name)},
6005                                                 "diff to current");
6006                         }
6007                 }
6008                 print "</td>\n" .
6009                       "</tr>\n";
6010         }
6011         if (defined $extra) {
6012                 print "<tr>\n" .
6013                       "<td colspan=\"4\">$extra</td>\n" .
6014                       "</tr>\n";
6015         }
6016         print "</table>\n";
6017 }
6018
6019 sub git_tags_body {
6020         # uses global variable $project
6021         my ($taglist, $from, $to, $extra) = @_;
6022         $from = 0 unless defined $from;
6023         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
6024
6025         print "<table class=\"tags\">\n";
6026         my $alternate = 1;
6027         for (my $i = $from; $i <= $to; $i++) {
6028                 my $entry = $taglist->[$i];
6029                 my %tag = %$entry;
6030                 my $comment = $tag{'subject'};
6031                 my $comment_short;
6032                 if (defined $comment) {
6033                         $comment_short = chop_str($comment, 30, 5);
6034                 }
6035                 if ($alternate) {
6036                         print "<tr class=\"dark\">\n";
6037                 } else {
6038                         print "<tr class=\"light\">\n";
6039                 }
6040                 $alternate ^= 1;
6041                 if (defined $tag{'age'}) {
6042                         print "<td><i>$tag{'age'}</i></td>\n";
6043                 } else {
6044                         print "<td></td>\n";
6045                 }
6046                 print "<td>" .
6047                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6048                                -class => "list name"}, esc_html($tag{'name'})) .
6049                       "</td>\n" .
6050                       "<td>";
6051                 if (defined $comment) {
6052                         print format_subject_html($comment, $comment_short,
6053                                                   href(action=>"tag", hash=>$tag{'id'}));
6054                 }
6055                 print "</td>\n" .
6056                       "<td class=\"selflink\">";
6057                 if ($tag{'type'} eq "tag") {
6058                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6059                 } else {
6060                         print "&nbsp;";
6061                 }
6062                 print "</td>\n" .
6063                       "<td class=\"link\">" . " | " .
6064                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6065                 if ($tag{'reftype'} eq "commit") {
6066                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6067                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6068                 } elsif ($tag{'reftype'} eq "blob") {
6069                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6070                 }
6071                 print "</td>\n" .
6072                       "</tr>";
6073         }
6074         if (defined $extra) {
6075                 print "<tr>\n" .
6076                       "<td colspan=\"5\">$extra</td>\n" .
6077                       "</tr>\n";
6078         }
6079         print "</table>\n";
6080 }
6081
6082 sub git_heads_body {
6083         # uses global variable $project
6084         my ($headlist, $head_at, $from, $to, $extra) = @_;
6085         $from = 0 unless defined $from;
6086         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6087
6088         print "<table class=\"heads\">\n";
6089         my $alternate = 1;
6090         for (my $i = $from; $i <= $to; $i++) {
6091                 my $entry = $headlist->[$i];
6092                 my %ref = %$entry;
6093                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6094                 if ($alternate) {
6095                         print "<tr class=\"dark\">\n";
6096                 } else {
6097                         print "<tr class=\"light\">\n";
6098                 }
6099                 $alternate ^= 1;
6100                 print "<td><i>$ref{'age'}</i></td>\n" .
6101                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6102                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6103                                -class => "list name"},esc_html($ref{'name'})) .
6104                       "</td>\n" .
6105                       "<td class=\"link\">" .
6106                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6107                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6108                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6109                       "</td>\n" .
6110                       "</tr>";
6111         }
6112         if (defined $extra) {
6113                 print "<tr>\n" .
6114                       "<td colspan=\"3\">$extra</td>\n" .
6115                       "</tr>\n";
6116         }
6117         print "</table>\n";
6118 }
6119
6120 # Display a single remote block
6121 sub git_remote_block {
6122         my ($remote, $rdata, $limit, $head) = @_;
6123
6124         my $heads = $rdata->{'heads'};
6125         my $fetch = $rdata->{'fetch'};
6126         my $push = $rdata->{'push'};
6127
6128         my $urls_table = "<table class=\"projects_list\">\n" ;
6129
6130         if (defined $fetch) {
6131                 if ($fetch eq $push) {
6132                         $urls_table .= format_repo_url("URL", $fetch);
6133                 } else {
6134                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6135                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6136                 }
6137         } elsif (defined $push) {
6138                 $urls_table .= format_repo_url("Push URL", $push);
6139         } else {
6140                 $urls_table .= format_repo_url("", "No remote URL");
6141         }
6142
6143         $urls_table .= "</table>\n";
6144
6145         my $dots;
6146         if (defined $limit && $limit < @$heads) {
6147                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6148         }
6149
6150         print $urls_table;
6151         git_heads_body($heads, $head, 0, $limit, $dots);
6152 }
6153
6154 # Display a list of remote names with the respective fetch and push URLs
6155 sub git_remotes_list {
6156         my ($remotedata, $limit) = @_;
6157         print "<table class=\"heads\">\n";
6158         my $alternate = 1;
6159         my @remotes = sort keys %$remotedata;
6160
6161         my $limited = $limit && $limit < @remotes;
6162
6163         $#remotes = $limit - 1 if $limited;
6164
6165         while (my $remote = shift @remotes) {
6166                 my $rdata = $remotedata->{$remote};
6167                 my $fetch = $rdata->{'fetch'};
6168                 my $push = $rdata->{'push'};
6169                 if ($alternate) {
6170                         print "<tr class=\"dark\">\n";
6171                 } else {
6172                         print "<tr class=\"light\">\n";
6173                 }
6174                 $alternate ^= 1;
6175                 print "<td>" .
6176                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6177                                -class=> "list name"},esc_html($remote)) .
6178                       "</td>";
6179                 print "<td class=\"link\">" .
6180                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6181                       " | " .
6182                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6183                       "</td>";
6184
6185                 print "</tr>\n";
6186         }
6187
6188         if ($limited) {
6189                 print "<tr>\n" .
6190                       "<td colspan=\"3\">" .
6191                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6192                       "</td>\n" . "</tr>\n";
6193         }
6194
6195         print "</table>";
6196 }
6197
6198 # Display remote heads grouped by remote, unless there are too many
6199 # remotes, in which case we only display the remote names
6200 sub git_remotes_body {
6201         my ($remotedata, $limit, $head) = @_;
6202         if ($limit and $limit < keys %$remotedata) {
6203                 git_remotes_list($remotedata, $limit);
6204         } else {
6205                 fill_remote_heads($remotedata);
6206                 while (my ($remote, $rdata) = each %$remotedata) {
6207                         git_print_section({-class=>"remote", -id=>$remote},
6208                                 ["remotes", $remote, $remote], sub {
6209                                         git_remote_block($remote, $rdata, $limit, $head);
6210                                 });
6211                 }
6212         }
6213 }
6214
6215 sub git_search_message {
6216         my %co = @_;
6217
6218         my $greptype;
6219         if ($searchtype eq 'commit') {
6220                 $greptype = "--grep=";
6221         } elsif ($searchtype eq 'author') {
6222                 $greptype = "--author=";
6223         } elsif ($searchtype eq 'committer') {
6224                 $greptype = "--committer=";
6225         }
6226         $greptype .= $searchtext;
6227         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6228                                        $greptype, '--regexp-ignore-case',
6229                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6230
6231         my $paging_nav = '';
6232         if ($page > 0) {
6233                 $paging_nav .=
6234                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6235                                 "first") .
6236                         " &sdot; " .
6237                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6238                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6239         } else {
6240                 $paging_nav .= "first &sdot; prev";
6241         }
6242         my $next_link = '';
6243         if ($#commitlist >= 100) {
6244                 $next_link =
6245                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6246                                  -accesskey => "n", -title => "Alt-n"}, "next");
6247                 $paging_nav .= " &sdot; $next_link";
6248         } else {
6249                 $paging_nav .= " &sdot; next";
6250         }
6251
6252         git_header_html();
6253
6254         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6255         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6256         if ($page == 0 && !@commitlist) {
6257                 print "<p>No match.</p>\n";
6258         } else {
6259                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6260         }
6261
6262         git_footer_html();
6263 }
6264
6265 sub git_search_changes {
6266         my %co = @_;
6267
6268         local $/ = "\n";
6269         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6270                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6271                 ($search_use_regexp ? '--pickaxe-regex' : ())
6272                         or die_error(500, "Open git-log failed");
6273
6274         git_header_html();
6275
6276         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6277         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6278
6279         print "<table class=\"pickaxe search\">\n";
6280         my $alternate = 1;
6281         undef %co;
6282         my @files;
6283         while (my $line = <$fd>) {
6284                 chomp $line;
6285                 next unless $line;
6286
6287                 my %set = parse_difftree_raw_line($line);
6288                 if (defined $set{'commit'}) {
6289                         # finish previous commit
6290                         if (%co) {
6291                                 print "</td>\n" .
6292                                       "<td class=\"link\">" .
6293                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6294                                               "commit") .
6295                                       " | " .
6296                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6297                                                              hash_base=>$co{'id'})},
6298                                               "tree") .
6299                                       "</td>\n" .
6300                                       "</tr>\n";
6301                         }
6302
6303                         if ($alternate) {
6304                                 print "<tr class=\"dark\">\n";
6305                         } else {
6306                                 print "<tr class=\"light\">\n";
6307                         }
6308                         $alternate ^= 1;
6309                         %co = parse_commit($set{'commit'});
6310                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6311                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6312                               "<td><i>$author</i></td>\n" .
6313                               "<td>" .
6314                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6315                                       -class => "list subject"},
6316                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6317                 } elsif (defined $set{'to_id'}) {
6318                         next if ($set{'to_id'} =~ m/^0{40}$/);
6319
6320                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6321                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6322                                       -class => "list"},
6323                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6324                               "<br/>\n";
6325                 }
6326         }
6327         close $fd;
6328
6329         # finish last commit (warning: repetition!)
6330         if (%co) {
6331                 print "</td>\n" .
6332                       "<td class=\"link\">" .
6333                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6334                               "commit") .
6335                       " | " .
6336                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6337                                              hash_base=>$co{'id'})},
6338                               "tree") .
6339                       "</td>\n" .
6340                       "</tr>\n";
6341         }
6342
6343         print "</table>\n";
6344
6345         git_footer_html();
6346 }
6347
6348 sub git_search_files {
6349         my %co = @_;
6350
6351         local $/ = "\n";
6352         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6353                 $search_use_regexp ? ('-E', '-i') : '-F',
6354                 $searchtext, $co{'tree'}
6355                         or die_error(500, "Open git-grep failed");
6356
6357         git_header_html();
6358
6359         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6360         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6361
6362         print "<table class=\"grep_search\">\n";
6363         my $alternate = 1;
6364         my $matches = 0;
6365         my $lastfile = '';
6366         my $file_href;
6367         while (my $line = <$fd>) {
6368                 chomp $line;
6369                 my ($file, $lno, $ltext, $binary);
6370                 last if ($matches++ > 1000);
6371                 if ($line =~ /^Binary file (.+) matches$/) {
6372                         $file = $1;
6373                         $binary = 1;
6374                 } else {
6375                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6376                         $file =~ s/^$co{'tree'}://;
6377                 }
6378                 if ($file ne $lastfile) {
6379                         $lastfile and print "</td></tr>\n";
6380                         if ($alternate++) {
6381                                 print "<tr class=\"dark\">\n";
6382                         } else {
6383                                 print "<tr class=\"light\">\n";
6384                         }
6385                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6386                                           file_name=>$file);
6387                         print "<td class=\"list\">".
6388                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6389                         print "</td><td>\n";
6390                         $lastfile = $file;
6391                 }
6392                 if ($binary) {
6393                         print "<div class=\"binary\">Binary file</div>\n";
6394                 } else {
6395                         $ltext = untabify($ltext);
6396                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6397                                 $ltext = esc_html($1, -nbsp=>1);
6398                                 $ltext .= '<span class="match">';
6399                                 $ltext .= esc_html($2, -nbsp=>1);
6400                                 $ltext .= '</span>';
6401                                 $ltext .= esc_html($3, -nbsp=>1);
6402                         } else {
6403                                 $ltext = esc_html($ltext, -nbsp=>1);
6404                         }
6405                         print "<div class=\"pre\">" .
6406                                 $cgi->a({-href => $file_href.'#l'.$lno,
6407                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6408                                 ' ' .  $ltext . "</div>\n";
6409                 }
6410         }
6411         if ($lastfile) {
6412                 print "</td></tr>\n";
6413                 if ($matches > 1000) {
6414                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6415                 }
6416         } else {
6417                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6418         }
6419         close $fd;
6420
6421         print "</table>\n";
6422
6423         git_footer_html();
6424 }
6425
6426 sub git_search_grep_body {
6427         my ($commitlist, $from, $to, $extra) = @_;
6428         $from = 0 unless defined $from;
6429         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6430
6431         print "<table class=\"commit_search\">\n";
6432         my $alternate = 1;
6433         for (my $i = $from; $i <= $to; $i++) {
6434                 my %co = %{$commitlist->[$i]};
6435                 if (!%co) {
6436                         next;
6437                 }
6438                 my $commit = $co{'id'};
6439                 if ($alternate) {
6440                         print "<tr class=\"dark\">\n";
6441                 } else {
6442                         print "<tr class=\"light\">\n";
6443                 }
6444                 $alternate ^= 1;
6445                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6446                       format_author_html('td', \%co, 15, 5) .
6447                       "<td>" .
6448                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6449                                -class => "list subject"},
6450                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6451                 my $comment = $co{'comment'};
6452                 foreach my $line (@$comment) {
6453                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6454                                 my ($lead, $match, $trail) = ($1, $2, $3);
6455                                 $match = chop_str($match, 70, 5, 'center');
6456                                 my $contextlen = int((80 - length($match))/2);
6457                                 $contextlen = 30 if ($contextlen > 30);
6458                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6459                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6460
6461                                 $lead  = esc_html($lead);
6462                                 $match = esc_html($match);
6463                                 $trail = esc_html($trail);
6464
6465                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6466                         }
6467                 }
6468                 print "</td>\n" .
6469                       "<td class=\"link\">" .
6470                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6471                       " | " .
6472                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6473                       " | " .
6474                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6475                 print "</td>\n" .
6476                       "</tr>\n";
6477         }
6478         if (defined $extra) {
6479                 print "<tr>\n" .
6480                       "<td colspan=\"3\">$extra</td>\n" .
6481                       "</tr>\n";
6482         }
6483         print "</table>\n";
6484 }
6485
6486 ## ======================================================================
6487 ## ======================================================================
6488 ## actions
6489
6490 sub git_project_list {
6491         my $order = $input_params{'order'};
6492         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6493                 die_error(400, "Unknown order parameter");
6494         }
6495
6496         my @list = git_get_projects_list($project_filter, $strict_export);
6497         if (!@list) {
6498                 die_error(404, "No projects found");
6499         }
6500
6501         git_header_html();
6502         if (defined $home_text && -f $home_text) {
6503                 print "<div class=\"index_include\">\n";
6504                 insert_file($home_text);
6505                 print "</div>\n";
6506         }
6507
6508         git_project_search_form($searchtext, $search_use_regexp);
6509         git_project_list_body(\@list, $order);
6510         git_footer_html();
6511 }
6512
6513 sub git_forks {
6514         my $order = $input_params{'order'};
6515         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6516                 die_error(400, "Unknown order parameter");
6517         }
6518
6519         my $filter = $project;
6520         $filter =~ s/\.git$//;
6521         my @list = git_get_projects_list($filter);
6522         if (!@list) {
6523                 die_error(404, "No forks found");
6524         }
6525
6526         git_header_html();
6527         git_print_page_nav('','');
6528         git_print_header_div('summary', "$project forks");
6529         git_project_list_body(\@list, $order);
6530         git_footer_html();
6531 }
6532
6533 sub git_project_index {
6534         my @projects = git_get_projects_list($project_filter, $strict_export);
6535         if (!@projects) {
6536                 die_error(404, "No projects found");
6537         }
6538
6539         print $cgi->header(
6540                 -type => 'text/plain',
6541                 -charset => 'utf-8',
6542                 -content_disposition => 'inline; filename="index.aux"');
6543
6544         foreach my $pr (@projects) {
6545                 if (!exists $pr->{'owner'}) {
6546                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6547                 }
6548
6549                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6550                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6551                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6552                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6553                 $path  =~ s/ /\+/g;
6554                 $owner =~ s/ /\+/g;
6555
6556                 print "$path $owner\n";
6557         }
6558 }
6559
6560 sub git_summary {
6561         my $descr = git_get_project_description($project) || "none";
6562         my %co = parse_commit("HEAD");
6563         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6564         my $head = $co{'id'};
6565         my $remote_heads = gitweb_check_feature('remote_heads');
6566
6567         my $owner = git_get_project_owner($project);
6568
6569         my $refs = git_get_references();
6570         # These get_*_list functions return one more to allow us to see if
6571         # there are more ...
6572         my @taglist  = git_get_tags_list(16);
6573         my @headlist = git_get_heads_list(16);
6574         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6575         my @forklist;
6576         my $check_forks = gitweb_check_feature('forks');
6577
6578         if ($check_forks) {
6579                 # find forks of a project
6580                 my $filter = $project;
6581                 $filter =~ s/\.git$//;
6582                 @forklist = git_get_projects_list($filter);
6583                 # filter out forks of forks
6584                 @forklist = filter_forks_from_projects_list(\@forklist)
6585                         if (@forklist);
6586         }
6587
6588         git_header_html();
6589         git_print_page_nav('summary','', $head);
6590
6591         print "<div class=\"title\">&nbsp;</div>\n";
6592         print "<table class=\"projects_list\">\n" .
6593               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6594         if ($owner and not $omit_owner) {
6595                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6596         }
6597         if (defined $cd{'rfc2822'}) {
6598                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6599                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6600         }
6601
6602         # use per project git URL list in $projectroot/$project/cloneurl
6603         # or make project git URL from git base URL and project name
6604         my $url_tag = "URL";
6605         my @url_list = git_get_project_url_list($project);
6606         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6607         foreach my $git_url (@url_list) {
6608                 next unless $git_url;
6609                 print format_repo_url($url_tag, $git_url);
6610                 $url_tag = "";
6611         }
6612
6613         # Tag cloud
6614         my $show_ctags = gitweb_check_feature('ctags');
6615         if ($show_ctags) {
6616                 my $ctags = git_get_project_ctags($project);
6617                 if (%$ctags) {
6618                         # without ability to add tags, don't show if there are none
6619                         my $cloud = git_populate_project_tagcloud($ctags);
6620                         print "<tr id=\"metadata_ctags\">" .
6621                               "<td>content tags</td>" .
6622                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6623                               "</tr>\n";
6624                 }
6625         }
6626
6627         print "</table>\n";
6628
6629         # If XSS prevention is on, we don't include README.html.
6630         # TODO: Allow a readme in some safe format.
6631         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6632                 print "<div class=\"title\">readme</div>\n" .
6633                       "<div class=\"readme\">\n";
6634                 insert_file("$projectroot/$project/README.html");
6635                 print "\n</div>\n"; # class="readme"
6636         }
6637
6638         # we need to request one more than 16 (0..15) to check if
6639         # those 16 are all
6640         my @commitlist = $head ? parse_commits($head, 17) : ();
6641         if (@commitlist) {
6642                 git_print_header_div('shortlog');
6643                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6644                                   $#commitlist <=  15 ? undef :
6645                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6646         }
6647
6648         if (@taglist) {
6649                 git_print_header_div('tags');
6650                 git_tags_body(\@taglist, 0, 15,
6651                               $#taglist <=  15 ? undef :
6652                               $cgi->a({-href => href(action=>"tags")}, "..."));
6653         }
6654
6655         if (@headlist) {
6656                 git_print_header_div('heads');
6657                 git_heads_body(\@headlist, $head, 0, 15,
6658                                $#headlist <= 15 ? undef :
6659                                $cgi->a({-href => href(action=>"heads")}, "..."));
6660         }
6661
6662         if (%remotedata) {
6663                 git_print_header_div('remotes');
6664                 git_remotes_body(\%remotedata, 15, $head);
6665         }
6666
6667         if (@forklist) {
6668                 git_print_header_div('forks');
6669                 git_project_list_body(\@forklist, 'age', 0, 15,
6670                                       $#forklist <= 15 ? undef :
6671                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6672                                       'no_header');
6673         }
6674
6675         git_footer_html();
6676 }
6677
6678 sub git_tag {
6679         my %tag = parse_tag($hash);
6680
6681         if (! %tag) {
6682                 die_error(404, "Unknown tag object");
6683         }
6684
6685         my $head = git_get_head_hash($project);
6686         git_header_html();
6687         git_print_page_nav('','', $head,undef,$head);
6688         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6689         print "<div class=\"title_text\">\n" .
6690               "<table class=\"object_header\">\n" .
6691               "<tr>\n" .
6692               "<td>object</td>\n" .
6693               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6694                                $tag{'object'}) . "</td>\n" .
6695               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6696                                               $tag{'type'}) . "</td>\n" .
6697               "</tr>\n";
6698         if (defined($tag{'author'})) {
6699                 git_print_authorship_rows(\%tag, 'author');
6700         }
6701         print "</table>\n\n" .
6702               "</div>\n";
6703         print "<div class=\"page_body\">";
6704         my $comment = $tag{'comment'};
6705         foreach my $line (@$comment) {
6706                 chomp $line;
6707                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6708         }
6709         print "</div>\n";
6710         git_footer_html();
6711 }
6712
6713 sub git_blame_common {
6714         my $format = shift || 'porcelain';
6715         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6716                 $format = 'incremental';
6717                 $action = 'blame_incremental'; # for page title etc
6718         }
6719
6720         # permissions
6721         gitweb_check_feature('blame')
6722                 or die_error(403, "Blame view not allowed");
6723
6724         # error checking
6725         die_error(400, "No file name given") unless $file_name;
6726         $hash_base ||= git_get_head_hash($project);
6727         die_error(404, "Couldn't find base commit") unless $hash_base;
6728         my %co = parse_commit($hash_base)
6729                 or die_error(404, "Commit not found");
6730         my $ftype = "blob";
6731         if (!defined $hash) {
6732                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6733                         or die_error(404, "Error looking up file");
6734         } else {
6735                 $ftype = git_get_type($hash);
6736                 if ($ftype !~ "blob") {
6737                         die_error(400, "Object is not a blob");
6738                 }
6739         }
6740
6741         my $fd;
6742         if ($format eq 'incremental') {
6743                 # get file contents (as base)
6744                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6745                         or die_error(500, "Open git-cat-file failed");
6746         } elsif ($format eq 'data') {
6747                 # run git-blame --incremental
6748                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6749                         $hash_base, "--", $file_name
6750                         or die_error(500, "Open git-blame --incremental failed");
6751         } else {
6752                 # run git-blame --porcelain
6753                 open $fd, "-|", git_cmd(), "blame", '-p',
6754                         $hash_base, '--', $file_name
6755                         or die_error(500, "Open git-blame --porcelain failed");
6756         }
6757         binmode $fd, ':utf8';
6758
6759         # incremental blame data returns early
6760         if ($format eq 'data') {
6761                 print $cgi->header(
6762                         -type=>"text/plain", -charset => "utf-8",
6763                         -status=> "200 OK");
6764                 local $| = 1; # output autoflush
6765                 while (my $line = <$fd>) {
6766                         print to_utf8($line);
6767                 }
6768                 close $fd
6769                         or print "ERROR $!\n";
6770
6771                 print 'END';
6772                 if (defined $t0 && gitweb_check_feature('timed')) {
6773                         print ' '.
6774                               tv_interval($t0, [ gettimeofday() ]).
6775                               ' '.$number_of_git_cmds;
6776                 }
6777                 print "\n";
6778
6779                 return;
6780         }
6781
6782         # page header
6783         git_header_html();
6784         my $formats_nav =
6785                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6786                         "blob") .
6787                 " | ";
6788         if ($format eq 'incremental') {
6789                 $formats_nav .=
6790                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6791                                 "blame") . " (non-incremental)";
6792         } else {
6793                 $formats_nav .=
6794                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6795                                 "blame") . " (incremental)";
6796         }
6797         $formats_nav .=
6798                 " | " .
6799                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6800                         "history") .
6801                 " | " .
6802                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6803                         "HEAD");
6804         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6805         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6806         git_print_page_path($file_name, $ftype, $hash_base);
6807
6808         # page body
6809         if ($format eq 'incremental') {
6810                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6811                       "This page requires JavaScript to run.\n Use ".
6812                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6813                               'this page').
6814                       " instead.\n".
6815                       "</b></center></div>\n</noscript>\n";
6816
6817                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6818         }
6819
6820         print qq!<div class="page_body">\n!;
6821         print qq!<div id="progress_info">... / ...</div>\n!
6822                 if ($format eq 'incremental');
6823         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6824               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6825               qq!<thead>\n!.
6826               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6827               qq!</thead>\n!.
6828               qq!<tbody>\n!;
6829
6830         my @rev_color = qw(light dark);
6831         my $num_colors = scalar(@rev_color);
6832         my $current_color = 0;
6833
6834         if ($format eq 'incremental') {
6835                 my $color_class = $rev_color[$current_color];
6836
6837                 #contents of a file
6838                 my $linenr = 0;
6839         LINE:
6840                 while (my $line = <$fd>) {
6841                         chomp $line;
6842                         $linenr++;
6843
6844                         print qq!<tr id="l$linenr" class="$color_class">!.
6845                               qq!<td class="sha1"><a href=""> </a></td>!.
6846                               qq!<td class="linenr">!.
6847                               qq!<a class="linenr" href="">$linenr</a></td>!;
6848                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6849                         print qq!</tr>\n!;
6850                 }
6851
6852         } else { # porcelain, i.e. ordinary blame
6853                 my %metainfo = (); # saves information about commits
6854
6855                 # blame data
6856         LINE:
6857                 while (my $line = <$fd>) {
6858                         chomp $line;
6859                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6860                         # no <lines in group> for subsequent lines in group of lines
6861                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6862                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6863                         if (!exists $metainfo{$full_rev}) {
6864                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6865                         }
6866                         my $meta = $metainfo{$full_rev};
6867                         my $data;
6868                         while ($data = <$fd>) {
6869                                 chomp $data;
6870                                 last if ($data =~ s/^\t//); # contents of line
6871                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6872                                         $meta->{$1} = $2 unless exists $meta->{$1};
6873                                 }
6874                                 if ($data =~ /^previous /) {
6875                                         $meta->{'nprevious'}++;
6876                                 }
6877                         }
6878                         my $short_rev = substr($full_rev, 0, 8);
6879                         my $author = $meta->{'author'};
6880                         my %date =
6881                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6882                         my $date = $date{'iso-tz'};
6883                         if ($group_size) {
6884                                 $current_color = ($current_color + 1) % $num_colors;
6885                         }
6886                         my $tr_class = $rev_color[$current_color];
6887                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6888                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6889                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6890                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6891                         if ($group_size) {
6892                                 print "<td class=\"sha1\"";
6893                                 print " title=\"". esc_html($author) . ", $date\"";
6894                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6895                                 print ">";
6896                                 print $cgi->a({-href => href(action=>"commit",
6897                                                              hash=>$full_rev,
6898                                                              file_name=>$file_name)},
6899                                               esc_html($short_rev));
6900                                 if ($group_size >= 2) {
6901                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6902                                         if (@author_initials) {
6903                                                 print "<br />" .
6904                                                       esc_html(join('', @author_initials));
6905                                                 #           or join('.', ...)
6906                                         }
6907                                 }
6908                                 print "</td>\n";
6909                         }
6910                         # 'previous' <sha1 of parent commit> <filename at commit>
6911                         if (exists $meta->{'previous'} &&
6912                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6913                                 $meta->{'parent'} = $1;
6914                                 $meta->{'file_parent'} = unquote($2);
6915                         }
6916                         my $linenr_commit =
6917                                 exists($meta->{'parent'}) ?
6918                                 $meta->{'parent'} : $full_rev;
6919                         my $linenr_filename =
6920                                 exists($meta->{'file_parent'}) ?
6921                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6922                         my $blamed = href(action => 'blame',
6923                                           file_name => $linenr_filename,
6924                                           hash_base => $linenr_commit);
6925                         print "<td class=\"linenr\">";
6926                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6927                                         -class => "linenr" },
6928                                       esc_html($lineno));
6929                         print "</td>";
6930                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6931                         print "</tr>\n";
6932                 } # end while
6933
6934         }
6935
6936         # footer
6937         print "</tbody>\n".
6938               "</table>\n"; # class="blame"
6939         print "</div>\n";   # class="blame_body"
6940         close $fd
6941                 or print "Reading blob failed\n";
6942
6943         git_footer_html();
6944 }
6945
6946 sub git_blame {
6947         git_blame_common();
6948 }
6949
6950 sub git_blame_incremental {
6951         git_blame_common('incremental');
6952 }
6953
6954 sub git_blame_data {
6955         git_blame_common('data');
6956 }
6957
6958 sub git_tags {
6959         my $head = git_get_head_hash($project);
6960         git_header_html();
6961         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6962         git_print_header_div('summary', $project);
6963
6964         my @tagslist = git_get_tags_list();
6965         if (@tagslist) {
6966                 git_tags_body(\@tagslist);
6967         }
6968         git_footer_html();
6969 }
6970
6971 sub git_heads {
6972         my $head = git_get_head_hash($project);
6973         git_header_html();
6974         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6975         git_print_header_div('summary', $project);
6976
6977         my @headslist = git_get_heads_list();
6978         if (@headslist) {
6979                 git_heads_body(\@headslist, $head);
6980         }
6981         git_footer_html();
6982 }
6983
6984 # used both for single remote view and for list of all the remotes
6985 sub git_remotes {
6986         gitweb_check_feature('remote_heads')
6987                 or die_error(403, "Remote heads view is disabled");
6988
6989         my $head = git_get_head_hash($project);
6990         my $remote = $input_params{'hash'};
6991
6992         my $remotedata = git_get_remotes_list($remote);
6993         die_error(500, "Unable to get remote information") unless defined $remotedata;
6994
6995         unless (%$remotedata) {
6996                 die_error(404, defined $remote ?
6997                         "Remote $remote not found" :
6998                         "No remotes found");
6999         }
7000
7001         git_header_html(undef, undef, -action_extra => $remote);
7002         git_print_page_nav('', '',  $head, undef, $head,
7003                 format_ref_views($remote ? '' : 'remotes'));
7004
7005         fill_remote_heads($remotedata);
7006         if (defined $remote) {
7007                 git_print_header_div('remotes', "$remote remote for $project");
7008                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
7009         } else {
7010                 git_print_header_div('summary', "$project remotes");
7011                 git_remotes_body($remotedata, undef, $head);
7012         }
7013
7014         git_footer_html();
7015 }
7016
7017 sub git_blob_plain {
7018         my $type = shift;
7019         my $expires;
7020
7021         if (!defined $hash) {
7022                 if (defined $file_name) {
7023                         my $base = $hash_base || git_get_head_hash($project);
7024                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7025                                 or die_error(404, "Cannot find file");
7026                 } else {
7027                         die_error(400, "No file name defined");
7028                 }
7029         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7030                 # blobs defined by non-textual hash id's can be cached
7031                 $expires = "+1d";
7032         }
7033
7034         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7035                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7036
7037         # content-type (can include charset)
7038         $type = blob_contenttype($fd, $file_name, $type);
7039
7040         # "save as" filename, even when no $file_name is given
7041         my $save_as = "$hash";
7042         if (defined $file_name) {
7043                 $save_as = $file_name;
7044         } elsif ($type =~ m/^text\//) {
7045                 $save_as .= '.txt';
7046         }
7047
7048         # With XSS prevention on, blobs of all types except a few known safe
7049         # ones are served with "Content-Disposition: attachment" to make sure
7050         # they don't run in our security domain.  For certain image types,
7051         # blob view writes an <img> tag referring to blob_plain view, and we
7052         # want to be sure not to break that by serving the image as an
7053         # attachment (though Firefox 3 doesn't seem to care).
7054         my $sandbox = $prevent_xss &&
7055                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7056
7057         # serve text/* as text/plain
7058         if ($prevent_xss &&
7059             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7060              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7061                 my $rest = $1;
7062                 $rest = defined $rest ? $rest : '';
7063                 $type = "text/plain$rest";
7064         }
7065
7066         print $cgi->header(
7067                 -type => $type,
7068                 -expires => $expires,
7069                 -content_disposition =>
7070                         ($sandbox ? 'attachment' : 'inline')
7071                         . '; filename="' . $save_as . '"');
7072         local $/ = undef;
7073         binmode STDOUT, ':raw';
7074         print <$fd>;
7075         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7076         close $fd;
7077 }
7078
7079 sub git_blob {
7080         my $expires;
7081
7082         if (!defined $hash) {
7083                 if (defined $file_name) {
7084                         my $base = $hash_base || git_get_head_hash($project);
7085                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7086                                 or die_error(404, "Cannot find file");
7087                 } else {
7088                         die_error(400, "No file name defined");
7089                 }
7090         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7091                 # blobs defined by non-textual hash id's can be cached
7092                 $expires = "+1d";
7093         }
7094
7095         my $have_blame = gitweb_check_feature('blame');
7096         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7097                 or die_error(500, "Couldn't cat $file_name, $hash");
7098         my $mimetype = blob_mimetype($fd, $file_name);
7099         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7100         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7101                 close $fd;
7102                 return git_blob_plain($mimetype);
7103         }
7104         # we can have blame only for text/* mimetype
7105         $have_blame &&= ($mimetype =~ m!^text/!);
7106
7107         my $highlight = gitweb_check_feature('highlight');
7108         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
7109         $fd = run_highlighter($fd, $highlight, $syntax)
7110                 if $syntax;
7111
7112         git_header_html(undef, $expires);
7113         my $formats_nav = '';
7114         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7115                 if (defined $file_name) {
7116                         if ($have_blame) {
7117                                 $formats_nav .=
7118                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7119                                                 "blame") .
7120                                         " | ";
7121                         }
7122                         $formats_nav .=
7123                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7124                                         "history") .
7125                                 " | " .
7126                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7127                                         "raw") .
7128                                 " | " .
7129                                 $cgi->a({-href => href(action=>"blob",
7130                                                        hash_base=>"HEAD", file_name=>$file_name)},
7131                                         "HEAD");
7132                 } else {
7133                         $formats_nav .=
7134                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7135                                         "raw");
7136                 }
7137                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7138                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7139         } else {
7140                 print "<div class=\"page_nav\">\n" .
7141                       "<br/><br/></div>\n" .
7142                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7143         }
7144         git_print_page_path($file_name, "blob", $hash_base);
7145         print "<div class=\"page_body\">\n";
7146         if ($mimetype =~ m!^image/!) {
7147                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7148                 if ($file_name) {
7149                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7150                 }
7151                 print qq! src="! .
7152                       href(action=>"blob_plain", hash=>$hash,
7153                            hash_base=>$hash_base, file_name=>$file_name) .
7154                       qq!" />\n!;
7155         } else {
7156                 my $nr;
7157                 while (my $line = <$fd>) {
7158                         chomp $line;
7159                         $nr++;
7160                         $line = untabify($line);
7161                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7162                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7163                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7164                 }
7165         }
7166         close $fd
7167                 or print "Reading blob failed.\n";
7168         print "</div>";
7169         git_footer_html();
7170 }
7171
7172 sub git_tree {
7173         if (!defined $hash_base) {
7174                 $hash_base = "HEAD";
7175         }
7176         if (!defined $hash) {
7177                 if (defined $file_name) {
7178                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7179                 } else {
7180                         $hash = $hash_base;
7181                 }
7182         }
7183         die_error(404, "No such tree") unless defined($hash);
7184
7185         my $show_sizes = gitweb_check_feature('show-sizes');
7186         my $have_blame = gitweb_check_feature('blame');
7187
7188         my @entries = ();
7189         {
7190                 local $/ = "\0";
7191                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7192                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7193                         or die_error(500, "Open git-ls-tree failed");
7194                 @entries = map { chomp; $_ } <$fd>;
7195                 close $fd
7196                         or die_error(404, "Reading tree failed");
7197         }
7198
7199         my $refs = git_get_references();
7200         my $ref = format_ref_marker($refs, $hash_base);
7201         git_header_html();
7202         my $basedir = '';
7203         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7204                 my @views_nav = ();
7205                 if (defined $file_name) {
7206                         push @views_nav,
7207                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7208                                         "history"),
7209                                 $cgi->a({-href => href(action=>"tree",
7210                                                        hash_base=>"HEAD", file_name=>$file_name)},
7211                                         "HEAD"),
7212                 }
7213                 my $snapshot_links = format_snapshot_links($hash);
7214                 if (defined $snapshot_links) {
7215                         # FIXME: Should be available when we have no hash base as well.
7216                         push @views_nav, $snapshot_links;
7217                 }
7218                 git_print_page_nav('tree','', $hash_base, undef, undef,
7219                                    join(' | ', @views_nav));
7220                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7221         } else {
7222                 undef $hash_base;
7223                 print "<div class=\"page_nav\">\n";
7224                 print "<br/><br/></div>\n";
7225                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7226         }
7227         if (defined $file_name) {
7228                 $basedir = $file_name;
7229                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7230                         $basedir .= '/';
7231                 }
7232                 git_print_page_path($file_name, 'tree', $hash_base);
7233         }
7234         print "<div class=\"page_body\">\n";
7235         print "<table class=\"tree\">\n";
7236         my $alternate = 1;
7237         # '..' (top directory) link if possible
7238         if (defined $hash_base &&
7239             defined $file_name && $file_name =~ m![^/]+$!) {
7240                 if ($alternate) {
7241                         print "<tr class=\"dark\">\n";
7242                 } else {
7243                         print "<tr class=\"light\">\n";
7244                 }
7245                 $alternate ^= 1;
7246
7247                 my $up = $file_name;
7248                 $up =~ s!/?[^/]+$!!;
7249                 undef $up unless $up;
7250                 # based on git_print_tree_entry
7251                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7252                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7253                 print '<td class="list">';
7254                 print $cgi->a({-href => href(action=>"tree",
7255                                              hash_base=>$hash_base,
7256                                              file_name=>$up)},
7257                               "..");
7258                 print "</td>\n";
7259                 print "<td class=\"link\"></td>\n";
7260
7261                 print "</tr>\n";
7262         }
7263         foreach my $line (@entries) {
7264                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7265
7266                 if ($alternate) {
7267                         print "<tr class=\"dark\">\n";
7268                 } else {
7269                         print "<tr class=\"light\">\n";
7270                 }
7271                 $alternate ^= 1;
7272
7273                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7274
7275                 print "</tr>\n";
7276         }
7277         print "</table>\n" .
7278               "</div>";
7279         git_footer_html();
7280 }
7281
7282 sub sanitize_for_filename {
7283     my $name = shift;
7284
7285     $name =~ s!/!-!g;
7286     $name =~ s/[^[:alnum:]_.-]//g;
7287
7288     return $name;
7289 }
7290
7291 sub snapshot_name {
7292         my ($project, $hash) = @_;
7293
7294         # path/to/project.git  -> project
7295         # path/to/project/.git -> project
7296         my $name = to_utf8($project);
7297         $name =~ s,([^/])/*\.git$,$1,;
7298         $name = sanitize_for_filename(basename($name));
7299
7300         my $ver = $hash;
7301         if ($hash =~ /^[0-9a-fA-F]+$/) {
7302                 # shorten SHA-1 hash
7303                 my $full_hash = git_get_full_hash($project, $hash);
7304                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7305                         $ver = git_get_short_hash($project, $hash);
7306                 }
7307         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7308                 # tags don't need shortened SHA-1 hash
7309                 $ver = $1;
7310         } else {
7311                 # branches and other need shortened SHA-1 hash
7312                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7313                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7314                         my $ref_dir = (defined $1) ? $1 : '';
7315                         $ver = $2;
7316
7317                         $ref_dir = sanitize_for_filename($ref_dir);
7318                         # for refs neither in heads nor remotes we want to
7319                         # add a ref dir to archive name
7320                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7321                                 $ver = $ref_dir . '-' . $ver;
7322                         }
7323                 }
7324                 $ver .= '-' . git_get_short_hash($project, $hash);
7325         }
7326         # special case of sanitization for filename - we change
7327         # slashes to dots instead of dashes
7328         # in case of hierarchical branch names
7329         $ver =~ s!/!.!g;
7330         $ver =~ s/[^[:alnum:]_.-]//g;
7331
7332         # name = project-version_string
7333         $name = "$name-$ver";
7334
7335         return wantarray ? ($name, $name) : $name;
7336 }
7337
7338 sub exit_if_unmodified_since {
7339         my ($latest_epoch) = @_;
7340         our $cgi;
7341
7342         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7343         if (defined $if_modified) {
7344                 my $since;
7345                 if (eval { require HTTP::Date; 1; }) {
7346                         $since = HTTP::Date::str2time($if_modified);
7347                 } elsif (eval { require Time::ParseDate; 1; }) {
7348                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7349                 }
7350                 if (defined $since && $latest_epoch <= $since) {
7351                         my %latest_date = parse_date($latest_epoch);
7352                         print $cgi->header(
7353                                 -last_modified => $latest_date{'rfc2822'},
7354                                 -status => '304 Not Modified');
7355                         goto DONE_GITWEB;
7356                 }
7357         }
7358 }
7359
7360 sub git_snapshot {
7361         my $format = $input_params{'snapshot_format'};
7362         if (!@snapshot_fmts) {
7363                 die_error(403, "Snapshots not allowed");
7364         }
7365         # default to first supported snapshot format
7366         $format ||= $snapshot_fmts[0];
7367         if ($format !~ m/^[a-z0-9]+$/) {
7368                 die_error(400, "Invalid snapshot format parameter");
7369         } elsif (!exists($known_snapshot_formats{$format})) {
7370                 die_error(400, "Unknown snapshot format");
7371         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7372                 die_error(403, "Snapshot format not allowed");
7373         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7374                 die_error(403, "Unsupported snapshot format");
7375         }
7376
7377         my $type = git_get_type("$hash^{}");
7378         if (!$type) {
7379                 die_error(404, 'Object does not exist');
7380         }  elsif ($type eq 'blob') {
7381                 die_error(400, 'Object is not a tree-ish');
7382         }
7383
7384         my ($name, $prefix) = snapshot_name($project, $hash);
7385         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7386
7387         my %co = parse_commit($hash);
7388         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7389
7390         my $cmd = quote_command(
7391                 git_cmd(), 'archive',
7392                 "--format=$known_snapshot_formats{$format}{'format'}",
7393                 "--prefix=$prefix/", $hash);
7394         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7395                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7396         }
7397
7398         $filename =~ s/(["\\])/\\$1/g;
7399         my %latest_date;
7400         if (%co) {
7401                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7402         }
7403
7404         print $cgi->header(
7405                 -type => $known_snapshot_formats{$format}{'type'},
7406                 -content_disposition => 'inline; filename="' . $filename . '"',
7407                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7408                 -status => '200 OK');
7409
7410         open my $fd, "-|", $cmd
7411                 or die_error(500, "Execute git-archive failed");
7412         binmode STDOUT, ':raw';
7413         print <$fd>;
7414         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7415         close $fd;
7416 }
7417
7418 sub git_log_generic {
7419         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7420
7421         my $head = git_get_head_hash($project);
7422         if (!defined $base) {
7423                 $base = $head;
7424         }
7425         if (!defined $page) {
7426                 $page = 0;
7427         }
7428         my $refs = git_get_references();
7429
7430         my $commit_hash = $base;
7431         if (defined $parent) {
7432                 $commit_hash = "$parent..$base";
7433         }
7434         my @commitlist =
7435                 parse_commits($commit_hash, 101, (100 * $page),
7436                               defined $file_name ? ($file_name, "--full-history") : ());
7437
7438         my $ftype;
7439         if (!defined $file_hash && defined $file_name) {
7440                 # some commits could have deleted file in question,
7441                 # and not have it in tree, but one of them has to have it
7442                 for (my $i = 0; $i < @commitlist; $i++) {
7443                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7444                         last if defined $file_hash;
7445                 }
7446         }
7447         if (defined $file_hash) {
7448                 $ftype = git_get_type($file_hash);
7449         }
7450         if (defined $file_name && !defined $ftype) {
7451                 die_error(500, "Unknown type of object");
7452         }
7453         my %co;
7454         if (defined $file_name) {
7455                 %co = parse_commit($base)
7456                         or die_error(404, "Unknown commit object");
7457         }
7458
7459
7460         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7461         my $next_link = '';
7462         if ($#commitlist >= 100) {
7463                 $next_link =
7464                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7465                                  -accesskey => "n", -title => "Alt-n"}, "next");
7466         }
7467         my $patch_max = gitweb_get_feature('patches');
7468         if ($patch_max && !defined $file_name) {
7469                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7470                         $paging_nav .= " &sdot; " .
7471                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7472                                         "patches");
7473                 }
7474         }
7475
7476         git_header_html();
7477         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7478         if (defined $file_name) {
7479                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7480         } else {
7481                 git_print_header_div('summary', $project)
7482         }
7483         git_print_page_path($file_name, $ftype, $hash_base)
7484                 if (defined $file_name);
7485
7486         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7487                      $file_name, $file_hash, $ftype);
7488
7489         git_footer_html();
7490 }
7491
7492 sub git_log {
7493         git_log_generic('log', \&git_log_body,
7494                         $hash, $hash_parent);
7495 }
7496
7497 sub git_commit {
7498         $hash ||= $hash_base || "HEAD";
7499         my %co = parse_commit($hash)
7500             or die_error(404, "Unknown commit object");
7501
7502         my $parent  = $co{'parent'};
7503         my $parents = $co{'parents'}; # listref
7504
7505         # we need to prepare $formats_nav before any parameter munging
7506         my $formats_nav;
7507         if (!defined $parent) {
7508                 # --root commitdiff
7509                 $formats_nav .= '(initial)';
7510         } elsif (@$parents == 1) {
7511                 # single parent commit
7512                 $formats_nav .=
7513                         '(parent: ' .
7514                         $cgi->a({-href => href(action=>"commit",
7515                                                hash=>$parent)},
7516                                 esc_html(substr($parent, 0, 7))) .
7517                         ')';
7518         } else {
7519                 # merge commit
7520                 $formats_nav .=
7521                         '(merge: ' .
7522                         join(' ', map {
7523                                 $cgi->a({-href => href(action=>"commit",
7524                                                        hash=>$_)},
7525                                         esc_html(substr($_, 0, 7)));
7526                         } @$parents ) .
7527                         ')';
7528         }
7529         if (gitweb_check_feature('patches') && @$parents <= 1) {
7530                 $formats_nav .= " | " .
7531                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7532                                 "patch");
7533         }
7534
7535         if (!defined $parent) {
7536                 $parent = "--root";
7537         }
7538         my @difftree;
7539         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7540                 @diff_opts,
7541                 (@$parents <= 1 ? $parent : '-c'),
7542                 $hash, "--"
7543                 or die_error(500, "Open git-diff-tree failed");
7544         @difftree = map { chomp; $_ } <$fd>;
7545         close $fd or die_error(404, "Reading git-diff-tree failed");
7546
7547         # non-textual hash id's can be cached
7548         my $expires;
7549         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7550                 $expires = "+1d";
7551         }
7552         my $refs = git_get_references();
7553         my $ref = format_ref_marker($refs, $co{'id'});
7554
7555         git_header_html(undef, $expires);
7556         git_print_page_nav('commit', '',
7557                            $hash, $co{'tree'}, $hash,
7558                            $formats_nav);
7559
7560         if (defined $co{'parent'}) {
7561                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7562         } else {
7563                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7564         }
7565         print "<div class=\"title_text\">\n" .
7566               "<table class=\"object_header\">\n";
7567         git_print_authorship_rows(\%co);
7568         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7569         print "<tr>" .
7570               "<td>tree</td>" .
7571               "<td class=\"sha1\">" .
7572               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7573                        class => "list"}, $co{'tree'}) .
7574               "</td>" .
7575               "<td class=\"link\">" .
7576               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7577                       "tree");
7578         my $snapshot_links = format_snapshot_links($hash);
7579         if (defined $snapshot_links) {
7580                 print " | " . $snapshot_links;
7581         }
7582         print "</td>" .
7583               "</tr>\n";
7584
7585         foreach my $par (@$parents) {
7586                 print "<tr>" .
7587                       "<td>parent</td>" .
7588                       "<td class=\"sha1\">" .
7589                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7590                                class => "list"}, $par) .
7591                       "</td>" .
7592                       "<td class=\"link\">" .
7593                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7594                       " | " .
7595                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7596                       "</td>" .
7597                       "</tr>\n";
7598         }
7599         print "</table>".
7600               "</div>\n";
7601
7602         print "<div class=\"page_body\">\n";
7603         git_print_log($co{'comment'});
7604         print "</div>\n";
7605
7606         git_difftree_body(\@difftree, $hash, @$parents);
7607
7608         git_footer_html();
7609 }
7610
7611 sub git_object {
7612         # object is defined by:
7613         # - hash or hash_base alone
7614         # - hash_base and file_name
7615         my $type;
7616
7617         # - hash or hash_base alone
7618         if ($hash || ($hash_base && !defined $file_name)) {
7619                 my $object_id = $hash || $hash_base;
7620
7621                 open my $fd, "-|", quote_command(
7622                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7623                         or die_error(404, "Object does not exist");
7624                 $type = <$fd>;
7625                 defined $type && chomp $type;
7626                 close $fd
7627                         or die_error(404, "Object does not exist");
7628
7629         # - hash_base and file_name
7630         } elsif ($hash_base && defined $file_name) {
7631                 $file_name =~ s,/+$,,;
7632
7633                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7634                         or die_error(404, "Base object does not exist");
7635
7636                 # here errors should not happen
7637                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7638                         or die_error(500, "Open git-ls-tree failed");
7639                 my $line = <$fd>;
7640                 close $fd;
7641
7642                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7643                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7644                         die_error(404, "File or directory for given base does not exist");
7645                 }
7646                 $type = $2;
7647                 $hash = $3;
7648         } else {
7649                 die_error(400, "Not enough information to find object");
7650         }
7651
7652         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7653                                           hash=>$hash, hash_base=>$hash_base,
7654                                           file_name=>$file_name),
7655                              -status => '302 Found');
7656 }
7657
7658 sub git_blobdiff {
7659         my $format = shift || 'html';
7660         my $diff_style = $input_params{'diff_style'} || 'inline';
7661
7662         my $fd;
7663         my @difftree;
7664         my %diffinfo;
7665         my $expires;
7666
7667         # preparing $fd and %diffinfo for git_patchset_body
7668         # new style URI
7669         if (defined $hash_base && defined $hash_parent_base) {
7670                 if (defined $file_name) {
7671                         # read raw output
7672                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7673                                 $hash_parent_base, $hash_base,
7674                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7675                                 or die_error(500, "Open git-diff-tree failed");
7676                         @difftree = map { chomp; $_ } <$fd>;
7677                         close $fd
7678                                 or die_error(404, "Reading git-diff-tree failed");
7679                         @difftree
7680                                 or die_error(404, "Blob diff not found");
7681
7682                 } elsif (defined $hash &&
7683                          $hash =~ /[0-9a-fA-F]{40}/) {
7684                         # try to find filename from $hash
7685
7686                         # read filtered raw output
7687                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7688                                 $hash_parent_base, $hash_base, "--"
7689                                 or die_error(500, "Open git-diff-tree failed");
7690                         @difftree =
7691                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7692                                 # $hash == to_id
7693                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7694                                 map { chomp; $_ } <$fd>;
7695                         close $fd
7696                                 or die_error(404, "Reading git-diff-tree failed");
7697                         @difftree
7698                                 or die_error(404, "Blob diff not found");
7699
7700                 } else {
7701                         die_error(400, "Missing one of the blob diff parameters");
7702                 }
7703
7704                 if (@difftree > 1) {
7705                         die_error(400, "Ambiguous blob diff specification");
7706                 }
7707
7708                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7709                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7710                 $file_name   ||= $diffinfo{'to_file'};
7711
7712                 $hash_parent ||= $diffinfo{'from_id'};
7713                 $hash        ||= $diffinfo{'to_id'};
7714
7715                 # non-textual hash id's can be cached
7716                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7717                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7718                         $expires = '+1d';
7719                 }
7720
7721                 # open patch output
7722                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7723                         '-p', ($format eq 'html' ? "--full-index" : ()),
7724                         $hash_parent_base, $hash_base,
7725                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7726                         or die_error(500, "Open git-diff-tree failed");
7727         }
7728
7729         # old/legacy style URI -- not generated anymore since 1.4.3.
7730         if (!%diffinfo) {
7731                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7732         }
7733
7734         # header
7735         if ($format eq 'html') {
7736                 my $formats_nav =
7737                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7738                                 "raw");
7739                 $formats_nav .= diff_style_nav($diff_style);
7740                 git_header_html(undef, $expires);
7741                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7742                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7743                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7744                 } else {
7745                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7746                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7747                 }
7748                 if (defined $file_name) {
7749                         git_print_page_path($file_name, "blob", $hash_base);
7750                 } else {
7751                         print "<div class=\"page_path\"></div>\n";
7752                 }
7753
7754         } elsif ($format eq 'plain') {
7755                 print $cgi->header(
7756                         -type => 'text/plain',
7757                         -charset => 'utf-8',
7758                         -expires => $expires,
7759                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7760
7761                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7762
7763         } else {
7764                 die_error(400, "Unknown blobdiff format");
7765         }
7766
7767         # patch
7768         if ($format eq 'html') {
7769                 print "<div class=\"page_body\">\n";
7770
7771                 git_patchset_body($fd, $diff_style,
7772                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7773                 close $fd;
7774
7775                 print "</div>\n"; # class="page_body"
7776                 git_footer_html();
7777
7778         } else {
7779                 while (my $line = <$fd>) {
7780                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7781                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7782
7783                         print $line;
7784
7785                         last if $line =~ m!^\+\+\+!;
7786                 }
7787                 local $/ = undef;
7788                 print <$fd>;
7789                 close $fd;
7790         }
7791 }
7792
7793 sub git_blobdiff_plain {
7794         git_blobdiff('plain');
7795 }
7796
7797 # assumes that it is added as later part of already existing navigation,
7798 # so it returns "| foo | bar" rather than just "foo | bar"
7799 sub diff_style_nav {
7800         my ($diff_style, $is_combined) = @_;
7801         $diff_style ||= 'inline';
7802
7803         return "" if ($is_combined);
7804
7805         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7806         my %styles = @styles;
7807         @styles =
7808                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7809
7810         return join '',
7811                 map { " | ".$_ }
7812                 map {
7813                         $_ eq $diff_style ? $styles{$_} :
7814                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7815                 } @styles;
7816 }
7817
7818 sub git_commitdiff {
7819         my %params = @_;
7820         my $format = $params{-format} || 'html';
7821         my $diff_style = $input_params{'diff_style'} || 'inline';
7822
7823         my ($patch_max) = gitweb_get_feature('patches');
7824         if ($format eq 'patch') {
7825                 die_error(403, "Patch view not allowed") unless $patch_max;
7826         }
7827
7828         $hash ||= $hash_base || "HEAD";
7829         my %co = parse_commit($hash)
7830             or die_error(404, "Unknown commit object");
7831
7832         # choose format for commitdiff for merge
7833         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7834                 $hash_parent = '--cc';
7835         }
7836         # we need to prepare $formats_nav before almost any parameter munging
7837         my $formats_nav;
7838         if ($format eq 'html') {
7839                 $formats_nav =
7840                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7841                                 "raw");
7842                 if ($patch_max && @{$co{'parents'}} <= 1) {
7843                         $formats_nav .= " | " .
7844                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7845                                         "patch");
7846                 }
7847                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7848
7849                 if (defined $hash_parent &&
7850                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7851                         # commitdiff with two commits given
7852                         my $hash_parent_short = $hash_parent;
7853                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7854                                 $hash_parent_short = substr($hash_parent, 0, 7);
7855                         }
7856                         $formats_nav .=
7857                                 ' (from';
7858                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7859                                 if ($co{'parents'}[$i] eq $hash_parent) {
7860                                         $formats_nav .= ' parent ' . ($i+1);
7861                                         last;
7862                                 }
7863                         }
7864                         $formats_nav .= ': ' .
7865                                 $cgi->a({-href => href(-replay=>1,
7866                                                        hash=>$hash_parent, hash_base=>undef)},
7867                                         esc_html($hash_parent_short)) .
7868                                 ')';
7869                 } elsif (!$co{'parent'}) {
7870                         # --root commitdiff
7871                         $formats_nav .= ' (initial)';
7872                 } elsif (scalar @{$co{'parents'}} == 1) {
7873                         # single parent commit
7874                         $formats_nav .=
7875                                 ' (parent: ' .
7876                                 $cgi->a({-href => href(-replay=>1,
7877                                                        hash=>$co{'parent'}, hash_base=>undef)},
7878                                         esc_html(substr($co{'parent'}, 0, 7))) .
7879                                 ')';
7880                 } else {
7881                         # merge commit
7882                         if ($hash_parent eq '--cc') {
7883                                 $formats_nav .= ' | ' .
7884                                         $cgi->a({-href => href(-replay=>1,
7885                                                                hash=>$hash, hash_parent=>'-c')},
7886                                                 'combined');
7887                         } else { # $hash_parent eq '-c'
7888                                 $formats_nav .= ' | ' .
7889                                         $cgi->a({-href => href(-replay=>1,
7890                                                                hash=>$hash, hash_parent=>'--cc')},
7891                                                 'compact');
7892                         }
7893                         $formats_nav .=
7894                                 ' (merge: ' .
7895                                 join(' ', map {
7896                                         $cgi->a({-href => href(-replay=>1,
7897                                                                hash=>$_, hash_base=>undef)},
7898                                                 esc_html(substr($_, 0, 7)));
7899                                 } @{$co{'parents'}} ) .
7900                                 ')';
7901                 }
7902         }
7903
7904         my $hash_parent_param = $hash_parent;
7905         if (!defined $hash_parent_param) {
7906                 # --cc for multiple parents, --root for parentless
7907                 $hash_parent_param =
7908                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7909         }
7910
7911         # read commitdiff
7912         my $fd;
7913         my @difftree;
7914         if ($format eq 'html') {
7915                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7916                         "--no-commit-id", "--patch-with-raw", "--full-index",
7917                         $hash_parent_param, $hash, "--"
7918                         or die_error(500, "Open git-diff-tree failed");
7919
7920                 while (my $line = <$fd>) {
7921                         chomp $line;
7922                         # empty line ends raw part of diff-tree output
7923                         last unless $line;
7924                         push @difftree, scalar parse_difftree_raw_line($line);
7925                 }
7926
7927         } elsif ($format eq 'plain') {
7928                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7929                         '-p', $hash_parent_param, $hash, "--"
7930                         or die_error(500, "Open git-diff-tree failed");
7931         } elsif ($format eq 'patch') {
7932                 # For commit ranges, we limit the output to the number of
7933                 # patches specified in the 'patches' feature.
7934                 # For single commits, we limit the output to a single patch,
7935                 # diverging from the git-format-patch default.
7936                 my @commit_spec = ();
7937                 if ($hash_parent) {
7938                         if ($patch_max > 0) {
7939                                 push @commit_spec, "-$patch_max";
7940                         }
7941                         push @commit_spec, '-n', "$hash_parent..$hash";
7942                 } else {
7943                         if ($params{-single}) {
7944                                 push @commit_spec, '-1';
7945                         } else {
7946                                 if ($patch_max > 0) {
7947                                         push @commit_spec, "-$patch_max";
7948                                 }
7949                                 push @commit_spec, "-n";
7950                         }
7951                         push @commit_spec, '--root', $hash;
7952                 }
7953                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7954                         '--encoding=utf8', '--stdout', @commit_spec
7955                         or die_error(500, "Open git-format-patch failed");
7956         } else {
7957                 die_error(400, "Unknown commitdiff format");
7958         }
7959
7960         # non-textual hash id's can be cached
7961         my $expires;
7962         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7963                 $expires = "+1d";
7964         }
7965
7966         # write commit message
7967         if ($format eq 'html') {
7968                 my $refs = git_get_references();
7969                 my $ref = format_ref_marker($refs, $co{'id'});
7970
7971                 git_header_html(undef, $expires);
7972                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7973                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7974                 print "<div class=\"title_text\">\n" .
7975                       "<table class=\"object_header\">\n";
7976                 git_print_authorship_rows(\%co);
7977                 print "</table>".
7978                       "</div>\n";
7979                 print "<div class=\"page_body\">\n";
7980                 if (@{$co{'comment'}} > 1) {
7981                         print "<div class=\"log\">\n";
7982                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7983                         print "</div>\n"; # class="log"
7984                 }
7985
7986         } elsif ($format eq 'plain') {
7987                 my $refs = git_get_references("tags");
7988                 my $tagname = git_get_rev_name_tags($hash);
7989                 my $filename = basename($project) . "-$hash.patch";
7990
7991                 print $cgi->header(
7992                         -type => 'text/plain',
7993                         -charset => 'utf-8',
7994                         -expires => $expires,
7995                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7996                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7997                 print "From: " . to_utf8($co{'author'}) . "\n";
7998                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7999                 print "Subject: " . to_utf8($co{'title'}) . "\n";
8000
8001                 print "X-Git-Tag: $tagname\n" if $tagname;
8002                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
8003
8004                 foreach my $line (@{$co{'comment'}}) {
8005                         print to_utf8($line) . "\n";
8006                 }
8007                 print "---\n\n";
8008         } elsif ($format eq 'patch') {
8009                 my $filename = basename($project) . "-$hash.patch";
8010
8011                 print $cgi->header(
8012                         -type => 'text/plain',
8013                         -charset => 'utf-8',
8014                         -expires => $expires,
8015                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8016         }
8017
8018         # write patch
8019         if ($format eq 'html') {
8020                 my $use_parents = !defined $hash_parent ||
8021                         $hash_parent eq '-c' || $hash_parent eq '--cc';
8022                 git_difftree_body(\@difftree, $hash,
8023                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8024                 print "<br/>\n";
8025
8026                 git_patchset_body($fd, $diff_style,
8027                                   \@difftree, $hash,
8028                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8029                 close $fd;
8030                 print "</div>\n"; # class="page_body"
8031                 git_footer_html();
8032
8033         } elsif ($format eq 'plain') {
8034                 local $/ = undef;
8035                 print <$fd>;
8036                 close $fd
8037                         or print "Reading git-diff-tree failed\n";
8038         } elsif ($format eq 'patch') {
8039                 local $/ = undef;
8040                 print <$fd>;
8041                 close $fd
8042                         or print "Reading git-format-patch failed\n";
8043         }
8044 }
8045
8046 sub git_commitdiff_plain {
8047         git_commitdiff(-format => 'plain');
8048 }
8049
8050 # format-patch-style patches
8051 sub git_patch {
8052         git_commitdiff(-format => 'patch', -single => 1);
8053 }
8054
8055 sub git_patches {
8056         git_commitdiff(-format => 'patch');
8057 }
8058
8059 sub git_history {
8060         git_log_generic('history', \&git_history_body,
8061                         $hash_base, $hash_parent_base,
8062                         $file_name, $hash);
8063 }
8064
8065 sub git_search {
8066         $searchtype ||= 'commit';
8067
8068         # check if appropriate features are enabled
8069         gitweb_check_feature('search')
8070                 or die_error(403, "Search is disabled");
8071         if ($searchtype eq 'pickaxe') {
8072                 # pickaxe may take all resources of your box and run for several minutes
8073                 # with every query - so decide by yourself how public you make this feature
8074                 gitweb_check_feature('pickaxe')
8075                         or die_error(403, "Pickaxe search is disabled");
8076         }
8077         if ($searchtype eq 'grep') {
8078                 # grep search might be potentially CPU-intensive, too
8079                 gitweb_check_feature('grep')
8080                         or die_error(403, "Grep search is disabled");
8081         }
8082
8083         if (!defined $searchtext) {
8084                 die_error(400, "Text field is empty");
8085         }
8086         if (!defined $hash) {
8087                 $hash = git_get_head_hash($project);
8088         }
8089         my %co = parse_commit($hash);
8090         if (!%co) {
8091                 die_error(404, "Unknown commit object");
8092         }
8093         if (!defined $page) {
8094                 $page = 0;
8095         }
8096
8097         if ($searchtype eq 'commit' ||
8098             $searchtype eq 'author' ||
8099             $searchtype eq 'committer') {
8100                 git_search_message(%co);
8101         } elsif ($searchtype eq 'pickaxe') {
8102                 git_search_changes(%co);
8103         } elsif ($searchtype eq 'grep') {
8104                 git_search_files(%co);
8105         } else {
8106                 die_error(400, "Unknown search type");
8107         }
8108 }
8109
8110 sub git_search_help {
8111         git_header_html();
8112         git_print_page_nav('','', $hash,$hash,$hash);
8113         print <<EOT;
8114 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8115 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8116 the pattern entered is recognized as the POSIX extended
8117 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8118 insensitive).</p>
8119 <dl>
8120 <dt><b>commit</b></dt>
8121 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8122 EOT
8123         my $have_grep = gitweb_check_feature('grep');
8124         if ($have_grep) {
8125                 print <<EOT;
8126 <dt><b>grep</b></dt>
8127 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8128     a different one) are searched for the given pattern. On large trees, this search can take
8129 a while and put some strain on the server, so please use it with some consideration. Note that
8130 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8131 case-sensitive.</dd>
8132 EOT
8133         }
8134         print <<EOT;
8135 <dt><b>author</b></dt>
8136 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8137 <dt><b>committer</b></dt>
8138 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8139 EOT
8140         my $have_pickaxe = gitweb_check_feature('pickaxe');
8141         if ($have_pickaxe) {
8142                 print <<EOT;
8143 <dt><b>pickaxe</b></dt>
8144 <dd>All commits that caused the string to appear or disappear from any file (changes that
8145 added, removed or "modified" the string) will be listed. This search can take a while and
8146 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8147 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8148 EOT
8149         }
8150         print "</dl>\n";
8151         git_footer_html();
8152 }
8153
8154 sub git_shortlog {
8155         git_log_generic('shortlog', \&git_shortlog_body,
8156                         $hash, $hash_parent);
8157 }
8158
8159 ## ......................................................................
8160 ## feeds (RSS, Atom; OPML)
8161
8162 sub git_feed {
8163         my $format = shift || 'atom';
8164         my $have_blame = gitweb_check_feature('blame');
8165
8166         # Atom: http://www.atomenabled.org/developers/syndication/
8167         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8168         if ($format ne 'rss' && $format ne 'atom') {
8169                 die_error(400, "Unknown web feed format");
8170         }
8171
8172         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8173         my $head = $hash || 'HEAD';
8174         my @commitlist = parse_commits($head, 150, 0, $file_name);
8175
8176         my %latest_commit;
8177         my %latest_date;
8178         my $content_type = "application/$format+xml";
8179         if (defined $cgi->http('HTTP_ACCEPT') &&
8180                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8181                 # browser (feed reader) prefers text/xml
8182                 $content_type = 'text/xml';
8183         }
8184         if (defined($commitlist[0])) {
8185                 %latest_commit = %{$commitlist[0]};
8186                 my $latest_epoch = $latest_commit{'committer_epoch'};
8187                 exit_if_unmodified_since($latest_epoch);
8188                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8189         }
8190         print $cgi->header(
8191                 -type => $content_type,
8192                 -charset => 'utf-8',
8193                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8194                 -status => '200 OK');
8195
8196         # Optimization: skip generating the body if client asks only
8197         # for Last-Modified date.
8198         return if ($cgi->request_method() eq 'HEAD');
8199
8200         # header variables
8201         my $title = "$site_name - $project/$action";
8202         my $feed_type = 'log';
8203         if (defined $hash) {
8204                 $title .= " - '$hash'";
8205                 $feed_type = 'branch log';
8206                 if (defined $file_name) {
8207                         $title .= " :: $file_name";
8208                         $feed_type = 'history';
8209                 }
8210         } elsif (defined $file_name) {
8211                 $title .= " - $file_name";
8212                 $feed_type = 'history';
8213         }
8214         $title .= " $feed_type";
8215         $title = esc_html($title);
8216         my $descr = git_get_project_description($project);
8217         if (defined $descr) {
8218                 $descr = esc_html($descr);
8219         } else {
8220                 $descr = "$project " .
8221                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8222                          " feed";
8223         }
8224         my $owner = git_get_project_owner($project);
8225         $owner = esc_html($owner);
8226
8227         #header
8228         my $alt_url;
8229         if (defined $file_name) {
8230                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8231         } elsif (defined $hash) {
8232                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8233         } else {
8234                 $alt_url = href(-full=>1, action=>"summary");
8235         }
8236         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8237         if ($format eq 'rss') {
8238                 print <<XML;
8239 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8240 <channel>
8241 XML
8242                 print "<title>$title</title>\n" .
8243                       "<link>$alt_url</link>\n" .
8244                       "<description>$descr</description>\n" .
8245                       "<language>en</language>\n" .
8246                       # project owner is responsible for 'editorial' content
8247                       "<managingEditor>$owner</managingEditor>\n";
8248                 if (defined $logo || defined $favicon) {
8249                         # prefer the logo to the favicon, since RSS
8250                         # doesn't allow both
8251                         my $img = esc_url($logo || $favicon);
8252                         print "<image>\n" .
8253                               "<url>$img</url>\n" .
8254                               "<title>$title</title>\n" .
8255                               "<link>$alt_url</link>\n" .
8256                               "</image>\n";
8257                 }
8258                 if (%latest_date) {
8259                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8260                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8261                 }
8262                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8263         } elsif ($format eq 'atom') {
8264                 print <<XML;
8265 <feed xmlns="http://www.w3.org/2005/Atom">
8266 XML
8267                 print "<title>$title</title>\n" .
8268                       "<subtitle>$descr</subtitle>\n" .
8269                       '<link rel="alternate" type="text/html" href="' .
8270                       $alt_url . '" />' . "\n" .
8271                       '<link rel="self" type="' . $content_type . '" href="' .
8272                       $cgi->self_url() . '" />' . "\n" .
8273                       "<id>" . href(-full=>1) . "</id>\n" .
8274                       # use project owner for feed author
8275                       "<author><name>$owner</name></author>\n";
8276                 if (defined $favicon) {
8277                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8278                 }
8279                 if (defined $logo) {
8280                         # not twice as wide as tall: 72 x 27 pixels
8281                         print "<logo>" . esc_url($logo) . "</logo>\n";
8282                 }
8283                 if (! %latest_date) {
8284                         # dummy date to keep the feed valid until commits trickle in:
8285                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8286                 } else {
8287                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8288                 }
8289                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8290         }
8291
8292         # contents
8293         for (my $i = 0; $i <= $#commitlist; $i++) {
8294                 my %co = %{$commitlist[$i]};
8295                 my $commit = $co{'id'};
8296                 # we read 150, we always show 30 and the ones more recent than 48 hours
8297                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8298                         last;
8299                 }
8300                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8301
8302                 # get list of changed files
8303                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8304                         $co{'parent'} || "--root",
8305                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8306                         or next;
8307                 my @difftree = map { chomp; $_ } <$fd>;
8308                 close $fd
8309                         or next;
8310
8311                 # print element (entry, item)
8312                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8313                 if ($format eq 'rss') {
8314                         print "<item>\n" .
8315                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8316                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8317                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8318                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8319                               "<link>$co_url</link>\n" .
8320                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8321                               "<content:encoded>" .
8322                               "<![CDATA[\n";
8323                 } elsif ($format eq 'atom') {
8324                         print "<entry>\n" .
8325                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8326                               "<updated>$cd{'iso-8601'}</updated>\n" .
8327                               "<author>\n" .
8328                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8329                         if ($co{'author_email'}) {
8330                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8331                         }
8332                         print "</author>\n" .
8333                               # use committer for contributor
8334                               "<contributor>\n" .
8335                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8336                         if ($co{'committer_email'}) {
8337                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8338                         }
8339                         print "</contributor>\n" .
8340                               "<published>$cd{'iso-8601'}</published>\n" .
8341                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8342                               "<id>$co_url</id>\n" .
8343                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8344                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8345                 }
8346                 my $comment = $co{'comment'};
8347                 print "<pre>\n";
8348                 foreach my $line (@$comment) {
8349                         $line = esc_html($line);
8350                         print "$line\n";
8351                 }
8352                 print "</pre><ul>\n";
8353                 foreach my $difftree_line (@difftree) {
8354                         my %difftree = parse_difftree_raw_line($difftree_line);
8355                         next if !$difftree{'from_id'};
8356
8357                         my $file = $difftree{'file'} || $difftree{'to_file'};
8358
8359                         print "<li>" .
8360                               "[" .
8361                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8362                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8363                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8364                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8365                                       -title => "diff"}, 'D');
8366                         if ($have_blame) {
8367                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8368                                                              file_name=>$file, hash_base=>$commit),
8369                                               -title => "blame"}, 'B');
8370                         }
8371                         # if this is not a feed of a file history
8372                         if (!defined $file_name || $file_name ne $file) {
8373                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8374                                                              file_name=>$file, hash=>$commit),
8375                                               -title => "history"}, 'H');
8376                         }
8377                         $file = esc_path($file);
8378                         print "] ".
8379                               "$file</li>\n";
8380                 }
8381                 if ($format eq 'rss') {
8382                         print "</ul>]]>\n" .
8383                               "</content:encoded>\n" .
8384                               "</item>\n";
8385                 } elsif ($format eq 'atom') {
8386                         print "</ul>\n</div>\n" .
8387                               "</content>\n" .
8388                               "</entry>\n";
8389                 }
8390         }
8391
8392         # end of feed
8393         if ($format eq 'rss') {
8394                 print "</channel>\n</rss>\n";
8395         } elsif ($format eq 'atom') {
8396                 print "</feed>\n";
8397         }
8398 }
8399
8400 sub git_rss {
8401         git_feed('rss');
8402 }
8403
8404 sub git_atom {
8405         git_feed('atom');
8406 }
8407
8408 sub git_opml {
8409         my @list = git_get_projects_list($project_filter, $strict_export);
8410         if (!@list) {
8411                 die_error(404, "No projects found");
8412         }
8413
8414         print $cgi->header(
8415                 -type => 'text/xml',
8416                 -charset => 'utf-8',
8417                 -content_disposition => 'inline; filename="opml.xml"');
8418
8419         my $title = esc_html($site_name);
8420         my $filter = " within subdirectory ";
8421         if (defined $project_filter) {
8422                 $filter .= esc_html($project_filter);
8423         } else {
8424                 $filter = "";
8425         }
8426         print <<XML;
8427 <?xml version="1.0" encoding="utf-8"?>
8428 <opml version="1.0">
8429 <head>
8430   <title>$title OPML Export$filter</title>
8431 </head>
8432 <body>
8433 <outline text="git RSS feeds">
8434 XML
8435
8436         foreach my $pr (@list) {
8437                 my %proj = %$pr;
8438                 my $head = git_get_head_hash($proj{'path'});
8439                 if (!defined $head) {
8440                         next;
8441                 }
8442                 $git_dir = "$projectroot/$proj{'path'}";
8443                 my %co = parse_commit($head);
8444                 if (!%co) {
8445                         next;
8446                 }
8447
8448                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8449                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8450                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8451                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8452         }
8453         print <<XML;
8454 </outline>
8455 </body>
8456 </opml>
8457 XML
8458 }