git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg {parent .}} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent $parent \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after {honor_trustmtime 1}} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
 414         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
 415         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 regsub -all -line {[ \r\t]+$} $content {} content
 432                 $ui_comm delete 0.0 end
 433                 $ui_comm insert end $content
 434                 return 1
 435         }
 436         return 0
 437 }
 438
 439 proc read_diff_index {fd after} {
 440         global buf_rdi
 441
 442         append buf_rdi [read $fd]
 443         set c 0
 444         set n [string length $buf_rdi]
 445         while {$c < $n} {
 446                 set z1 [string first "\0" $buf_rdi $c]
 447                 if {$z1 == -1} break
 448                 incr z1
 449                 set z2 [string first "\0" $buf_rdi $z1]
 450                 if {$z2 == -1} break
 451
 452                 incr c
 453                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 454                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
 455                 merge_state \
 456                         [encoding convertfrom $p] \
 457                         [lindex $i 4]? \
 458                         [list [lindex $i 0] [lindex $i 2]] \
 459                         [list]
 460                 set c $z2
 461                 incr c
 462         }
 463         if {$c < $n} {
 464                 set buf_rdi [string range $buf_rdi $c end]
 465         } else {
 466                 set buf_rdi {}
 467         }
 468
 469         rescan_done $fd buf_rdi $after
 470 }
 471
 472 proc read_diff_files {fd after} {
 473         global buf_rdf
 474
 475         append buf_rdf [read $fd]
 476         set c 0
 477         set n [string length $buf_rdf]
 478         while {$c < $n} {
 479                 set z1 [string first "\0" $buf_rdf $c]
 480                 if {$z1 == -1} break
 481                 incr z1
 482                 set z2 [string first "\0" $buf_rdf $z1]
 483                 if {$z2 == -1} break
 484
 485                 incr c
 486                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 487                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
 488                 merge_state \
 489                         [encoding convertfrom $p] \
 490                         ?[lindex $i 4] \
 491                         [list] \
 492                         [list [lindex $i 0] [lindex $i 2]]
 493                 set c $z2
 494                 incr c
 495         }
 496         if {$c < $n} {
 497                 set buf_rdf [string range $buf_rdf $c end]
 498         } else {
 499                 set buf_rdf {}
 500         }
 501
 502         rescan_done $fd buf_rdf $after
 503 }
 504
 505 proc read_ls_others {fd after} {
 506         global buf_rlo
 507
 508         append buf_rlo [read $fd]
 509         set pck [split $buf_rlo "\0"]
 510         set buf_rlo [lindex $pck end]
 511         foreach p [lrange $pck 0 end-1] {
 512                 merge_state [encoding convertfrom $p] ?O
 513         }
 514         rescan_done $fd buf_rlo $after
 515 }
 516
 517 proc rescan_done {fd buf after} {
 518         global rescan_active
 519         global file_states repo_config
 520         upvar $buf to_clear
 521
 522         if {![eof $fd]} return
 523         set to_clear {}
 524         close $fd
 525         if {[incr rescan_active -1] > 0} return
 526
 527         prune_selection
 528         unlock_index
 529         display_all_files
 530         reshow_diff
 531         uplevel #0 $after
 532 }
 533
 534 proc prune_selection {} {
 535         global file_states selected_paths
 536
 537         foreach path [array names selected_paths] {
 538                 if {[catch {set still_here $file_states($path)}]} {
 539                         unset selected_paths($path)
 540                 }
 541         }
 542 }
 543
 544 ######################################################################
 545 ##
 546 ## diff
 547
 548 proc clear_diff {} {
 549         global ui_diff current_diff_path current_diff_header
 550         global ui_index ui_workdir
 551
 552         $ui_diff conf -state normal
 553         $ui_diff delete 0.0 end
 554         $ui_diff conf -state disabled
 555
 556         set current_diff_path {}
 557         set current_diff_header {}
 558
 559         $ui_index tag remove in_diff 0.0 end
 560         $ui_workdir tag remove in_diff 0.0 end
 561 }
 562
 563 proc reshow_diff {} {
 564         global ui_status_value file_states file_lists
 565         global current_diff_path current_diff_side
 566
 567         set p $current_diff_path
 568         if {$p eq {}
 569                 || $current_diff_side eq {}
 570                 || [catch {set s $file_states($p)}]
 571                 || [lsearch -sorted -exact $file_lists($current_diff_side) $p] == -1} {
 572                 clear_diff
 573         } else {
 574                 show_diff $p $current_diff_side
 575         }
 576 }
 577
 578 proc handle_empty_diff {} {
 579         global current_diff_path file_states file_lists
 580
 581         set path $current_diff_path
 582         set s $file_states($path)
 583         if {[lindex $s 0] ne {_M}} return
 584
 585         info_popup "No differences detected.
 586
 587 [short_path $path] has no changes.
 588
 589 The modification date of this file was updated
 590 by another application, but the content within
 591 the file was not changed.
 592
 593 A rescan will be automatically started to find
 594 other files which may have the same state."
 595
 596         clear_diff
 597         display_file $path __
 598         rescan {set ui_status_value {Ready.}} 0
 599 }
 600
 601 proc show_diff {path w {lno {}}} {
 602         global file_states file_lists
 603         global is_3way_diff diff_active repo_config
 604         global ui_diff ui_status_value ui_index ui_workdir
 605         global current_diff_path current_diff_side current_diff_header
 606
 607         if {$diff_active || ![lock_index read]} return
 608
 609         clear_diff
 610         if {$lno == {}} {
 611                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 612                 if {$lno >= 0} {
 613                         incr lno
 614                 }
 615         }
 616         if {$lno >= 1} {
 617                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 618         }
 619
 620         set s $file_states($path)
 621         set m [lindex $s 0]
 622         set is_3way_diff 0
 623         set diff_active 1
 624         set current_diff_path $path
 625         set current_diff_side $w
 626         set current_diff_header {}
 627         set ui_status_value "Loading diff of [escape_path $path]..."
 628
 629         # - Git won't give us the diff, there's nothing to compare to!
 630         #
 631         if {$m eq {_O}} {
 632                 set max_sz [expr {128 * 1024}]
 633                 if {[catch {
 634                                 set fd [open $path r]
 635                                 set content [read $fd $max_sz]
 636                                 close $fd
 637                                 set sz [file size $path]
 638                         } err ]} {
 639                         set diff_active 0
 640                         unlock_index
 641                         set ui_status_value "Unable to display [escape_path $path]"
 642                         error_popup "Error loading file:\n\n$err"
 643                         return
 644                 }
 645                 $ui_diff conf -state normal
 646                 if {![catch {set type [exec file $path]}]} {
 647                         set n [string length $path]
 648                         if {[string equal -length $n $path $type]} {
 649                                 set type [string range $type $n end]
 650                                 regsub {^:?\s*} $type {} type
 651                         }
 652                         $ui_diff insert end "* $type\n" d_@
 653                 }
 654                 if {[string first "\0" $content] != -1} {
 655                         $ui_diff insert end \
 656                                 "* Binary file (not showing content)." \
 657                                 d_@
 658                 } else {
 659                         if {$sz > $max_sz} {
 660                                 $ui_diff insert end \
 661 "* Untracked file is $sz bytes.
 662 * Showing only first $max_sz bytes.
 663 " d_@
 664                         }
 665                         $ui_diff insert end $content
 666                         if {$sz > $max_sz} {
 667                                 $ui_diff insert end "
 668 * Untracked file clipped here by [appname].
 669 * To see the entire file, use an external editor.
 670 " d_@
 671                         }
 672                 }
 673                 $ui_diff conf -state disabled
 674                 set diff_active 0
 675                 unlock_index
 676                 set ui_status_value {Ready.}
 677                 return
 678         }
 679
 680         set cmd [list | git]
 681         if {$w eq $ui_index} {
 682                 lappend cmd diff-index
 683                 lappend cmd --cached
 684         } elseif {$w eq $ui_workdir} {
 685                 if {[string index $m 0] eq {U}} {
 686                         lappend cmd diff
 687                 } else {
 688                         lappend cmd diff-files
 689                 }
 690         }
 691
 692         lappend cmd -p
 693         lappend cmd --no-color
 694         if {$repo_config(gui.diffcontext) > 0} {
 695                 lappend cmd "-U$repo_config(gui.diffcontext)"
 696         }
 697         if {$w eq $ui_index} {
 698                 lappend cmd [PARENT]
 699         }
 700         lappend cmd --
 701         lappend cmd $path
 702
 703         if {[catch {set fd [open $cmd r]} err]} {
 704                 set diff_active 0
 705                 unlock_index
 706                 set ui_status_value "Unable to display [escape_path $path]"
 707                 error_popup "Error loading diff:\n\n$err"
 708                 return
 709         }
 710
 711         fconfigure $fd \
 712                 -blocking 0 \
 713                 -encoding binary \
 714                 -translation binary
 715         fileevent $fd readable [list read_diff $fd]
 716 }
 717
 718 proc read_diff {fd} {
 719         global ui_diff ui_status_value diff_active
 720         global is_3way_diff current_diff_header
 721
 722         $ui_diff conf -state normal
 723         while {[gets $fd line] >= 0} {
 724                 # -- Cleanup uninteresting diff header lines.
 725                 #
 726                 if {   [string match {diff --git *}      $line]
 727                         || [string match {diff --cc *}       $line]
 728                         || [string match {diff --combined *} $line]
 729                         || [string match {--- *}             $line]
 730                         || [string match {+++ *}             $line]} {
 731                         append current_diff_header $line "\n"
 732                         continue
 733                 }
 734                 if {[string match {index *} $line]} continue
 735                 if {$line eq {deleted file mode 120000}} {
 736                         set line "deleted symlink"
 737                 }
 738
 739                 # -- Automatically detect if this is a 3 way diff.
 740                 #
 741                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 742
 743                 if {[string match {mode *} $line]
 744                         || [string match {new file *} $line]
 745                         || [string match {deleted file *} $line]
 746                         || [string match {Binary files * and * differ} $line]
 747                         || $line eq {\ No newline at end of file}
 748                         || [regexp {^\* Unmerged path } $line]} {
 749                         set tags {}
 750                 } elseif {$is_3way_diff} {
 751                         set op [string range $line 0 1]
 752                         switch -- $op {
 753                         {  } {set tags {}}
 754                         {@@} {set tags d_@}
 755                         { +} {set tags d_s+}
 756                         { -} {set tags d_s-}
 757                         {+ } {set tags d_+s}
 758                         {- } {set tags d_-s}
 759                         {--} {set tags d_--}
 760                         {++} {
 761                                 if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
 762                                         set line [string replace $line 0 1 {  }]
 763                                         set tags d$op
 764                                 } else {
 765                                         set tags d_++
 766                                 }
 767                         }
 768                         default {
 769                                 puts "error: Unhandled 3 way diff marker: {$op}"
 770                                 set tags {}
 771                         }
 772                         }
 773                 } else {
 774                         set op [string index $line 0]
 775                         switch -- $op {
 776                         { } {set tags {}}
 777                         {@} {set tags d_@}
 778                         {-} {set tags d_-}
 779                         {+} {
 780                                 if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
 781                                         set line [string replace $line 0 0 { }]
 782                                         set tags d$op
 783                                 } else {
 784                                         set tags d_+
 785                                 }
 786                         }
 787                         default {
 788                                 puts "error: Unhandled 2 way diff marker: {$op}"
 789                                 set tags {}
 790                         }
 791                         }
 792                 }
 793                 $ui_diff insert end $line $tags
 794                 if {[string index $line end] eq "\r"} {
 795                         $ui_diff tag add d_cr {end - 2c}
 796                 }
 797                 $ui_diff insert end "\n" $tags
 798         }
 799         $ui_diff conf -state disabled
 800
 801         if {[eof $fd]} {
 802                 close $fd
 803                 set diff_active 0
 804                 unlock_index
 805                 set ui_status_value {Ready.}
 806
 807                 if {[$ui_diff index end] eq {2.0}} {
 808                         handle_empty_diff
 809                 }
 810         }
 811 }
 812
 813 proc apply_hunk {x y} {
 814         global current_diff_path current_diff_header current_diff_side
 815         global ui_diff ui_index file_states
 816
 817         if {$current_diff_path eq {} || $current_diff_header eq {}} return
 818         if {![lock_index apply_hunk]} return
 819
 820         set apply_cmd {git apply --cached --whitespace=nowarn}
 821         set mi [lindex $file_states($current_diff_path) 0]
 822         if {$current_diff_side eq $ui_index} {
 823                 set mode unstage
 824                 lappend apply_cmd --reverse
 825                 if {[string index $mi 0] ne {M}} {
 826                         unlock_index
 827                         return
 828                 }
 829         } else {
 830                 set mode stage
 831                 if {[string index $mi 1] ne {M}} {
 832                         unlock_index
 833                         return
 834                 }
 835         }
 836
 837         set s_lno [lindex [split [$ui_diff index @$x,$y] .] 0]
 838         set s_lno [$ui_diff search -backwards -regexp ^@@ $s_lno.0 0.0]
 839         if {$s_lno eq {}} {
 840                 unlock_index
 841                 return
 842         }
 843
 844         set e_lno [$ui_diff search -forwards -regexp ^@@ "$s_lno + 1 lines" end]
 845         if {$e_lno eq {}} {
 846                 set e_lno end
 847         }
 848
 849         if {[catch {
 850                 set p [open "| $apply_cmd" w]
 851                 fconfigure $p -translation binary -encoding binary
 852                 puts -nonewline $p $current_diff_header
 853                 puts -nonewline $p [$ui_diff get $s_lno $e_lno]
 854                 close $p} err]} {
 855                 error_popup "Failed to $mode selected hunk.\n\n$err"
 856                 unlock_index
 857                 return
 858         }
 859
 860         $ui_diff conf -state normal
 861         $ui_diff delete $s_lno $e_lno
 862         $ui_diff conf -state disabled
 863
 864         if {[$ui_diff get 1.0 end] eq "\n"} {
 865                 set o _
 866         } else {
 867                 set o ?
 868         }
 869
 870         if {$current_diff_side eq $ui_index} {
 871                 set mi ${o}M
 872         } elseif {[string index $mi 0] eq {_}} {
 873                 set mi M$o
 874         } else {
 875                 set mi ?$o
 876         }
 877         unlock_index
 878         display_file $current_diff_path $mi
 879         if {$o eq {_}} {
 880                 clear_diff
 881         }
 882 }
 883
 884 ######################################################################
 885 ##
 886 ## commit
 887
 888 proc load_last_commit {} {
 889         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 890         global repo_config
 891
 892         if {[llength $PARENT] == 0} {
 893                 error_popup {There is nothing to amend.
 894
 895 You are about to create the initial commit.
 896 There is no commit before this to amend.
 897 }
 898                 return
 899         }
 900
 901         repository_state curType curHEAD curMERGE_HEAD
 902         if {$curType eq {merge}} {
 903                 error_popup {Cannot amend while merging.
 904
 905 You are currently in the middle of a merge that
 906 has not been fully completed.  You cannot amend
 907 the prior commit unless you first abort the
 908 current merge activity.
 909 }
 910                 return
 911         }
 912
 913         set msg {}
 914         set parents [list]
 915         if {[catch {
 916                         set fd [open "| git cat-file commit $curHEAD" r]
 917                         fconfigure $fd -encoding binary -translation lf
 918                         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 919                                 set enc utf-8
 920                         }
 921                         while {[gets $fd line] > 0} {
 922                                 if {[string match {parent *} $line]} {
 923                                         lappend parents [string range $line 7 end]
 924                                 } elseif {[string match {encoding *} $line]} {
 925                                         set enc [string tolower [string range $line 9 end]]
 926                                 }
 927                         }
 928                         fconfigure $fd -encoding $enc
 929                         set msg [string trim [read $fd]]
 930                         close $fd
 931                 } err]} {
 932                 error_popup "Error loading commit data for amend:\n\n$err"
 933                 return
 934         }
 935
 936         set HEAD $curHEAD
 937         set PARENT $parents
 938         set MERGE_HEAD [list]
 939         switch -- [llength $parents] {
 940         0       {set commit_type amend-initial}
 941         1       {set commit_type amend}
 942         default {set commit_type amend-merge}
 943         }
 944
 945         $ui_comm delete 0.0 end
 946         $ui_comm insert end $msg
 947         $ui_comm edit reset
 948         $ui_comm edit modified false
 949         rescan {set ui_status_value {Ready.}}
 950 }
 951
 952 proc create_new_commit {} {
 953         global commit_type ui_comm
 954
 955         set commit_type normal
 956         $ui_comm delete 0.0 end
 957         $ui_comm edit reset
 958         $ui_comm edit modified false
 959         rescan {set ui_status_value {Ready.}}
 960 }
 961
 962 set GIT_COMMITTER_IDENT {}
 963
 964 proc committer_ident {} {
 965         global GIT_COMMITTER_IDENT
 966
 967         if {$GIT_COMMITTER_IDENT eq {}} {
 968                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 969                         error_popup "Unable to obtain your identity:\n\n$err"
 970                         return {}
 971                 }
 972                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 973                         $me me GIT_COMMITTER_IDENT]} {
 974                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 975                         return {}
 976                 }
 977         }
 978
 979         return $GIT_COMMITTER_IDENT
 980 }
 981
 982 proc commit_tree {} {
 983         global HEAD commit_type file_states ui_comm repo_config
 984         global ui_status_value pch_error
 985
 986         if {[committer_ident] eq {}} return
 987         if {![lock_index update]} return
 988
 989         # -- Our in memory state should match the repository.
 990         #
 991         repository_state curType curHEAD curMERGE_HEAD
 992         if {[string match amend* $commit_type]
 993                 && $curType eq {normal}
 994                 && $curHEAD eq $HEAD} {
 995         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 996                 info_popup {Last scanned state does not match repository state.
 997
 998 Another Git program has modified this repository
 999 since the last scan.  A rescan must be performed
1000 before another commit can be created.
1001
1002 The rescan will be automatically started now.
1003 }
1004                 unlock_index
1005                 rescan {set ui_status_value {Ready.}}
1006                 return
1007         }
1008
1009         # -- At least one file should differ in the index.
1010         #
1011         set files_ready 0
1012         foreach path [array names file_states] {
1013                 switch -glob -- [lindex $file_states($path) 0] {
1014                 _? {continue}
1015                 A? -
1016                 D? -
1017                 M? {set files_ready 1}
1018                 U? {
1019                         error_popup "Unmerged files cannot be committed.
1020
1021 File [short_path $path] has merge conflicts.
1022 You must resolve them and add the file before committing.
1023 "
1024                         unlock_index
1025                         return
1026                 }
1027                 default {
1028                         error_popup "Unknown file state [lindex $s 0] detected.
1029
1030 File [short_path $path] cannot be committed by this program.
1031 "
1032                 }
1033                 }
1034         }
1035         if {!$files_ready} {
1036                 info_popup {No changes to commit.
1037
1038 You must add at least 1 file before you can commit.
1039 }
1040                 unlock_index
1041                 return
1042         }
1043
1044         # -- A message is required.
1045         #
1046         set msg [string trim [$ui_comm get 1.0 end]]
1047         regsub -all -line {[ \t\r]+$} $msg {} msg
1048         if {$msg eq {}} {
1049                 error_popup {Please supply a commit message.
1050
1051 A good commit message has the following format:
1052
1053 - First line: Describe in one sentance what you did.
1054 - Second line: Blank
1055 - Remaining lines: Describe why this change is good.
1056 }
1057                 unlock_index
1058                 return
1059         }
1060
1061         # -- Run the pre-commit hook.
1062         #
1063         set pchook [gitdir hooks pre-commit]
1064
1065         # On Cygwin [file executable] might lie so we need to ask
1066         # the shell if the hook is executable.  Yes that's annoying.
1067         #
1068         if {[is_Windows] && [file isfile $pchook]} {
1069                 set pchook [list sh -c [concat \
1070                         "if test -x \"$pchook\";" \
1071                         "then exec \"$pchook\" 2>&1;" \
1072                         "fi"]]
1073         } elseif {[file executable $pchook]} {
1074                 set pchook [list $pchook |& cat]
1075         } else {
1076                 commit_writetree $curHEAD $msg
1077                 return
1078         }
1079
1080         set ui_status_value {Calling pre-commit hook...}
1081         set pch_error {}
1082         set fd_ph [open "| $pchook" r]
1083         fconfigure $fd_ph -blocking 0 -translation binary
1084         fileevent $fd_ph readable \
1085                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
1086 }
1087
1088 proc commit_prehook_wait {fd_ph curHEAD msg} {
1089         global pch_error ui_status_value
1090
1091         append pch_error [read $fd_ph]
1092         fconfigure $fd_ph -blocking 1
1093         if {[eof $fd_ph]} {
1094                 if {[catch {close $fd_ph}]} {
1095                         set ui_status_value {Commit declined by pre-commit hook.}
1096                         hook_failed_popup pre-commit $pch_error
1097                         unlock_index
1098                 } else {
1099                         commit_writetree $curHEAD $msg
1100                 }
1101                 set pch_error {}
1102                 return
1103         }
1104         fconfigure $fd_ph -blocking 0
1105 }
1106
1107 proc commit_writetree {curHEAD msg} {
1108         global ui_status_value
1109
1110         set ui_status_value {Committing changes...}
1111         set fd_wt [open "| git write-tree" r]
1112         fileevent $fd_wt readable \
1113                 [list commit_committree $fd_wt $curHEAD $msg]
1114 }
1115
1116 proc commit_committree {fd_wt curHEAD msg} {
1117         global HEAD PARENT MERGE_HEAD commit_type
1118         global single_commit all_heads current_branch
1119         global ui_status_value ui_comm selected_commit_type
1120         global file_states selected_paths rescan_active
1121         global repo_config
1122
1123         gets $fd_wt tree_id
1124         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1125                 error_popup "write-tree failed:\n\n$err"
1126                 set ui_status_value {Commit failed.}
1127                 unlock_index
1128                 return
1129         }
1130
1131         # -- Build the message.
1132         #
1133         set msg_p [gitdir COMMIT_EDITMSG]
1134         set msg_wt [open $msg_p w]
1135         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
1136                 set enc utf-8
1137         }
1138         fconfigure $msg_wt -encoding $enc -translation binary
1139         puts -nonewline $msg_wt $msg
1140         close $msg_wt
1141
1142         # -- Create the commit.
1143         #
1144         set cmd [list git commit-tree $tree_id]
1145         set parents [concat $PARENT $MERGE_HEAD]
1146         if {[llength $parents] > 0} {
1147                 foreach p $parents {
1148                         lappend cmd -p $p
1149                 }
1150         } else {
1151                 # git commit-tree writes to stderr during initial commit.
1152                 lappend cmd 2>/dev/null
1153         }
1154         lappend cmd <$msg_p
1155         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1156                 error_popup "commit-tree failed:\n\n$err"
1157                 set ui_status_value {Commit failed.}
1158                 unlock_index
1159                 return
1160         }
1161
1162         # -- Update the HEAD ref.
1163         #
1164         set reflogm commit
1165         if {$commit_type ne {normal}} {
1166                 append reflogm " ($commit_type)"
1167         }
1168         set i [string first "\n" $msg]
1169         if {$i >= 0} {
1170                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1171         } else {
1172                 append reflogm {: } $msg
1173         }
1174         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1175         if {[catch {eval exec $cmd} err]} {
1176                 error_popup "update-ref failed:\n\n$err"
1177                 set ui_status_value {Commit failed.}
1178                 unlock_index
1179                 return
1180         }
1181
1182         # -- Make sure our current branch exists.
1183         #
1184         if {$commit_type eq {initial}} {
1185                 lappend all_heads $current_branch
1186                 set all_heads [lsort -unique $all_heads]
1187                 populate_branch_menu
1188         }
1189
1190         # -- Cleanup after ourselves.
1191         #
1192         catch {file delete $msg_p}
1193         catch {file delete [gitdir MERGE_HEAD]}
1194         catch {file delete [gitdir MERGE_MSG]}
1195         catch {file delete [gitdir SQUASH_MSG]}
1196         catch {file delete [gitdir GITGUI_MSG]}
1197
1198         # -- Let rerere do its thing.
1199         #
1200         if {[file isdirectory [gitdir rr-cache]]} {
1201                 catch {exec git rerere}
1202         }
1203
1204         # -- Run the post-commit hook.
1205         #
1206         set pchook [gitdir hooks post-commit]
1207         if {[is_Windows] && [file isfile $pchook]} {
1208                 set pchook [list sh -c [concat \
1209                         "if test -x \"$pchook\";" \
1210                         "then exec \"$pchook\";" \
1211                         "fi"]]
1212         } elseif {![file executable $pchook]} {
1213                 set pchook {}
1214         }
1215         if {$pchook ne {}} {
1216                 catch {exec $pchook &}
1217         }
1218
1219         $ui_comm delete 0.0 end
1220         $ui_comm edit reset
1221         $ui_comm edit modified false
1222
1223         if {$single_commit} do_quit
1224
1225         # -- Update in memory status
1226         #
1227         set selected_commit_type new
1228         set commit_type normal
1229         set HEAD $cmt_id
1230         set PARENT $cmt_id
1231         set MERGE_HEAD [list]
1232
1233         foreach path [array names file_states] {
1234                 set s $file_states($path)
1235                 set m [lindex $s 0]
1236                 switch -glob -- $m {
1237                 _O -
1238                 _M -
1239                 _D {continue}
1240                 __ -
1241                 A_ -
1242                 M_ -
1243                 D_ {
1244                         unset file_states($path)
1245                         catch {unset selected_paths($path)}
1246                 }
1247                 DO {
1248                         set file_states($path) [list _O [lindex $s 1] {} {}]
1249                 }
1250                 AM -
1251                 AD -
1252                 MM -
1253                 MD {
1254                         set file_states($path) [list \
1255                                 _[string index $m 1] \
1256                                 [lindex $s 1] \
1257                                 [lindex $s 3] \
1258                                 {}]
1259                 }
1260                 }
1261         }
1262
1263         display_all_files
1264         unlock_index
1265         reshow_diff
1266         set ui_status_value \
1267                 "Changes committed as [string range $cmt_id 0 7]."
1268 }
1269
1270 ######################################################################
1271 ##
1272 ## fetch push
1273
1274 proc fetch_from {remote} {
1275         set w [new_console \
1276                 "fetch $remote" \
1277                 "Fetching new changes from $remote"]
1278         set cmd [list git fetch]
1279         lappend cmd $remote
1280         console_exec $w $cmd console_done
1281 }
1282
1283 proc push_to {remote} {
1284         set w [new_console \
1285                 "push $remote" \
1286                 "Pushing changes to $remote"]
1287         set cmd [list git push]
1288         lappend cmd -v
1289         lappend cmd $remote
1290         console_exec $w $cmd console_done
1291 }
1292
1293 ######################################################################
1294 ##
1295 ## ui helpers
1296
1297 proc mapicon {w state path} {
1298         global all_icons
1299
1300         if {[catch {set r $all_icons($state$w)}]} {
1301                 puts "error: no icon for $w state={$state} $path"
1302                 return file_plain
1303         }
1304         return $r
1305 }
1306
1307 proc mapdesc {state path} {
1308         global all_descs
1309
1310         if {[catch {set r $all_descs($state)}]} {
1311                 puts "error: no desc for state={$state} $path"
1312                 return $state
1313         }
1314         return $r
1315 }
1316
1317 proc escape_path {path} {
1318         regsub -all "\n" $path "\\n" path
1319         return $path
1320 }
1321
1322 proc short_path {path} {
1323         return [escape_path [lindex [file split $path] end]]
1324 }
1325
1326 set next_icon_id 0
1327 set null_sha1 [string repeat 0 40]
1328
1329 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1330         global file_states next_icon_id null_sha1
1331
1332         set s0 [string index $new_state 0]
1333         set s1 [string index $new_state 1]
1334
1335         if {[catch {set info $file_states($path)}]} {
1336                 set state __
1337                 set icon n[incr next_icon_id]
1338         } else {
1339                 set state [lindex $info 0]
1340                 set icon [lindex $info 1]
1341                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1342                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1343         }
1344
1345         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1346         elseif {$s0 eq {_}} {set s0 _}
1347
1348         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1349         elseif {$s1 eq {_}} {set s1 _}
1350
1351         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1352                 set head_info [list 0 $null_sha1]
1353         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1354                 && $head_info eq {}} {
1355                 set head_info $index_info
1356         }
1357
1358         set file_states($path) [list $s0$s1 $icon \
1359                 $head_info $index_info \
1360                 ]
1361         return $state
1362 }
1363
1364 proc display_file_helper {w path icon_name old_m new_m} {
1365         global file_lists
1366
1367         if {$new_m eq {_}} {
1368                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1369                 if {$lno >= 0} {
1370                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1371                         incr lno
1372                         $w conf -state normal
1373                         $w delete $lno.0 [expr {$lno + 1}].0
1374                         $w conf -state disabled
1375                 }
1376         } elseif {$old_m eq {_} && $new_m ne {_}} {
1377                 lappend file_lists($w) $path
1378                 set file_lists($w) [lsort -unique $file_lists($w)]
1379                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1380                 incr lno
1381                 $w conf -state normal
1382                 $w image create $lno.0 \
1383                         -align center -padx 5 -pady 1 \
1384                         -name $icon_name \
1385                         -image [mapicon $w $new_m $path]
1386                 $w insert $lno.1 "[escape_path $path]\n"
1387                 $w conf -state disabled
1388         } elseif {$old_m ne $new_m} {
1389                 $w conf -state normal
1390                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1391                 $w conf -state disabled
1392         }
1393 }
1394
1395 proc display_file {path state} {
1396         global file_states selected_paths
1397         global ui_index ui_workdir
1398
1399         set old_m [merge_state $path $state]
1400         set s $file_states($path)
1401         set new_m [lindex $s 0]
1402         set icon_name [lindex $s 1]
1403
1404         set o [string index $old_m 0]
1405         set n [string index $new_m 0]
1406         if {$o eq {U}} {
1407                 set o _
1408         }
1409         if {$n eq {U}} {
1410                 set n _
1411         }
1412         display_file_helper     $ui_index $path $icon_name $o $n
1413
1414         if {[string index $old_m 0] eq {U}} {
1415                 set o U
1416         } else {
1417                 set o [string index $old_m 1]
1418         }
1419         if {[string index $new_m 0] eq {U}} {
1420                 set n U
1421         } else {
1422                 set n [string index $new_m 1]
1423         }
1424         display_file_helper     $ui_workdir $path $icon_name $o $n
1425
1426         if {$new_m eq {__}} {
1427                 unset file_states($path)
1428                 catch {unset selected_paths($path)}
1429         }
1430 }
1431
1432 proc display_all_files_helper {w path icon_name m} {
1433         global file_lists
1434
1435         lappend file_lists($w) $path
1436         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1437         $w image create end \
1438                 -align center -padx 5 -pady 1 \
1439                 -name $icon_name \
1440                 -image [mapicon $w $m $path]
1441         $w insert end "[escape_path $path]\n"
1442 }
1443
1444 proc display_all_files {} {
1445         global ui_index ui_workdir
1446         global file_states file_lists
1447         global last_clicked
1448
1449         $ui_index conf -state normal
1450         $ui_workdir conf -state normal
1451
1452         $ui_index delete 0.0 end
1453         $ui_workdir delete 0.0 end
1454         set last_clicked {}
1455
1456         set file_lists($ui_index) [list]
1457         set file_lists($ui_workdir) [list]
1458
1459         foreach path [lsort [array names file_states]] {
1460                 set s $file_states($path)
1461                 set m [lindex $s 0]
1462                 set icon_name [lindex $s 1]
1463
1464                 set s [string index $m 0]
1465                 if {$s ne {U} && $s ne {_}} {
1466                         display_all_files_helper $ui_index $path \
1467                                 $icon_name $s
1468                 }
1469
1470                 if {[string index $m 0] eq {U}} {
1471                         set s U
1472                 } else {
1473                         set s [string index $m 1]
1474                 }
1475                 if {$s ne {_}} {
1476                         display_all_files_helper $ui_workdir $path \
1477                                 $icon_name $s
1478                 }
1479         }
1480
1481         $ui_index conf -state disabled
1482         $ui_workdir conf -state disabled
1483 }
1484
1485 proc update_indexinfo {msg pathList after} {
1486         global update_index_cp ui_status_value
1487
1488         if {![lock_index update]} return
1489
1490         set update_index_cp 0
1491         set pathList [lsort $pathList]
1492         set totalCnt [llength $pathList]
1493         set batch [expr {int($totalCnt * .01) + 1}]
1494         if {$batch > 25} {set batch 25}
1495
1496         set ui_status_value [format \
1497                 "$msg... %i/%i files (%.2f%%)" \
1498                 $update_index_cp \
1499                 $totalCnt \
1500                 0.0]
1501         set fd [open "| git update-index -z --index-info" w]
1502         fconfigure $fd \
1503                 -blocking 0 \
1504                 -buffering full \
1505                 -buffersize 512 \
1506                 -encoding binary \
1507                 -translation binary
1508         fileevent $fd writable [list \
1509                 write_update_indexinfo \
1510                 $fd \
1511                 $pathList \
1512                 $totalCnt \
1513                 $batch \
1514                 $msg \
1515                 $after \
1516                 ]
1517 }
1518
1519 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1520         global update_index_cp ui_status_value
1521         global file_states current_diff_path
1522
1523         if {$update_index_cp >= $totalCnt} {
1524                 close $fd
1525                 unlock_index
1526                 uplevel #0 $after
1527                 return
1528         }
1529
1530         for {set i $batch} \
1531                 {$update_index_cp < $totalCnt && $i > 0} \
1532                 {incr i -1} {
1533                 set path [lindex $pathList $update_index_cp]
1534                 incr update_index_cp
1535
1536                 set s $file_states($path)
1537                 switch -glob -- [lindex $s 0] {
1538                 A? {set new _O}
1539                 M? {set new _M}
1540                 D_ {set new _D}
1541                 D? {set new _?}
1542                 ?? {continue}
1543                 }
1544                 set info [lindex $s 2]
1545                 if {$info eq {}} continue
1546
1547                 puts -nonewline $fd "$info\t[encoding convertto $path]\0"
1548                 display_file $path $new
1549         }
1550
1551         set ui_status_value [format \
1552                 "$msg... %i/%i files (%.2f%%)" \
1553                 $update_index_cp \
1554                 $totalCnt \
1555                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1556 }
1557
1558 proc update_index {msg pathList after} {
1559         global update_index_cp ui_status_value
1560
1561         if {![lock_index update]} return
1562
1563         set update_index_cp 0
1564         set pathList [lsort $pathList]
1565         set totalCnt [llength $pathList]
1566         set batch [expr {int($totalCnt * .01) + 1}]
1567         if {$batch > 25} {set batch 25}
1568
1569         set ui_status_value [format \
1570                 "$msg... %i/%i files (%.2f%%)" \
1571                 $update_index_cp \
1572                 $totalCnt \
1573                 0.0]
1574         set fd [open "| git update-index --add --remove -z --stdin" w]
1575         fconfigure $fd \
1576                 -blocking 0 \
1577                 -buffering full \
1578                 -buffersize 512 \
1579                 -encoding binary \
1580                 -translation binary
1581         fileevent $fd writable [list \
1582                 write_update_index \
1583                 $fd \
1584                 $pathList \
1585                 $totalCnt \
1586                 $batch \
1587                 $msg \
1588                 $after \
1589                 ]
1590 }
1591
1592 proc write_update_index {fd pathList totalCnt batch msg after} {
1593         global update_index_cp ui_status_value
1594         global file_states current_diff_path
1595
1596         if {$update_index_cp >= $totalCnt} {
1597                 close $fd
1598                 unlock_index
1599                 uplevel #0 $after
1600                 return
1601         }
1602
1603         for {set i $batch} \
1604                 {$update_index_cp < $totalCnt && $i > 0} \
1605                 {incr i -1} {
1606                 set path [lindex $pathList $update_index_cp]
1607                 incr update_index_cp
1608
1609                 switch -glob -- [lindex $file_states($path) 0] {
1610                 AD {set new __}
1611                 ?D {set new D_}
1612                 _O -
1613                 AM {set new A_}
1614                 U? {
1615                         if {[file exists $path]} {
1616                                 set new M_
1617                         } else {
1618                                 set new D_
1619                         }
1620                 }
1621                 ?M {set new M_}
1622                 ?? {continue}
1623                 }
1624                 puts -nonewline $fd "[encoding convertto $path]\0"
1625                 display_file $path $new
1626         }
1627
1628         set ui_status_value [format \
1629                 "$msg... %i/%i files (%.2f%%)" \
1630                 $update_index_cp \
1631                 $totalCnt \
1632                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1633 }
1634
1635 proc checkout_index {msg pathList after} {
1636         global update_index_cp ui_status_value
1637
1638         if {![lock_index update]} return
1639
1640         set update_index_cp 0
1641         set pathList [lsort $pathList]
1642         set totalCnt [llength $pathList]
1643         set batch [expr {int($totalCnt * .01) + 1}]
1644         if {$batch > 25} {set batch 25}
1645
1646         set ui_status_value [format \
1647                 "$msg... %i/%i files (%.2f%%)" \
1648                 $update_index_cp \
1649                 $totalCnt \
1650                 0.0]
1651         set cmd [list git checkout-index]
1652         lappend cmd --index
1653         lappend cmd --quiet
1654         lappend cmd --force
1655         lappend cmd -z
1656         lappend cmd --stdin
1657         set fd [open "| $cmd " w]
1658         fconfigure $fd \
1659                 -blocking 0 \
1660                 -buffering full \
1661                 -buffersize 512 \
1662                 -encoding binary \
1663                 -translation binary
1664         fileevent $fd writable [list \
1665                 write_checkout_index \
1666                 $fd \
1667                 $pathList \
1668                 $totalCnt \
1669                 $batch \
1670                 $msg \
1671                 $after \
1672                 ]
1673 }
1674
1675 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1676         global update_index_cp ui_status_value
1677         global file_states current_diff_path
1678
1679         if {$update_index_cp >= $totalCnt} {
1680                 close $fd
1681                 unlock_index
1682                 uplevel #0 $after
1683                 return
1684         }
1685
1686         for {set i $batch} \
1687                 {$update_index_cp < $totalCnt && $i > 0} \
1688                 {incr i -1} {
1689                 set path [lindex $pathList $update_index_cp]
1690                 incr update_index_cp
1691                 switch -glob -- [lindex $file_states($path) 0] {
1692                 U? {continue}
1693                 ?M -
1694                 ?D {
1695                         puts -nonewline $fd "[encoding convertto $path]\0"
1696                         display_file $path ?_
1697                 }
1698                 }
1699         }
1700
1701         set ui_status_value [format \
1702                 "$msg... %i/%i files (%.2f%%)" \
1703                 $update_index_cp \
1704                 $totalCnt \
1705                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1706 }
1707
1708 ######################################################################
1709 ##
1710 ## branch management
1711
1712 proc is_tracking_branch {name} {
1713         global tracking_branches
1714
1715         if {![catch {set info $tracking_branches($name)}]} {
1716                 return 1
1717         }
1718         foreach t [array names tracking_branches] {
1719                 if {[string match {*/\*} $t] && [string match $t $name]} {
1720                         return 1
1721                 }
1722         }
1723         return 0
1724 }
1725
1726 proc load_all_heads {} {
1727         global all_heads
1728
1729         set all_heads [list]
1730         set fd [open "| git for-each-ref --format=%(refname) refs/heads" r]
1731         while {[gets $fd line] > 0} {
1732                 if {[is_tracking_branch $line]} continue
1733                 if {![regsub ^refs/heads/ $line {} name]} continue
1734                 lappend all_heads $name
1735         }
1736         close $fd
1737
1738         set all_heads [lsort $all_heads]
1739 }
1740
1741 proc populate_branch_menu {} {
1742         global all_heads disable_on_lock
1743
1744         set m .mbar.branch
1745         set last [$m index last]
1746         for {set i 0} {$i <= $last} {incr i} {
1747                 if {[$m type $i] eq {separator}} {
1748                         $m delete $i last
1749                         set new_dol [list]
1750                         foreach a $disable_on_lock {
1751                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1752                                         lappend new_dol $a
1753                                 }
1754                         }
1755                         set disable_on_lock $new_dol
1756                         break
1757                 }
1758         }
1759
1760         if {$all_heads ne {}} {
1761                 $m add separator
1762         }
1763         foreach b $all_heads {
1764                 $m add radiobutton \
1765                         -label $b \
1766                         -command [list switch_branch $b] \
1767                         -variable current_branch \
1768                         -value $b \
1769                         -font font_ui
1770                 lappend disable_on_lock \
1771                         [list $m entryconf [$m index last] -state]
1772         }
1773 }
1774
1775 proc all_tracking_branches {} {
1776         global tracking_branches
1777
1778         set all_trackings {}
1779         set cmd {}
1780         foreach name [array names tracking_branches] {
1781                 if {[regsub {/\*$} $name {} name]} {
1782                         lappend cmd $name
1783                 } else {
1784                         regsub ^refs/(heads|remotes)/ $name {} name
1785                         lappend all_trackings $name
1786                 }
1787         }
1788
1789         if {$cmd ne {}} {
1790                 set fd [open "| git for-each-ref --format=%(refname) $cmd" r]
1791                 while {[gets $fd name] > 0} {
1792                         regsub ^refs/(heads|remotes)/ $name {} name
1793                         lappend all_trackings $name
1794                 }
1795                 close $fd
1796         }
1797
1798         return [lsort -unique $all_trackings]
1799 }
1800
1801 proc do_create_branch_action {w} {
1802         global all_heads null_sha1 repo_config
1803         global create_branch_checkout create_branch_revtype
1804         global create_branch_head create_branch_trackinghead
1805         global create_branch_name create_branch_revexp
1806
1807         set newbranch $create_branch_name
1808         if {$newbranch eq {}
1809                 || $newbranch eq $repo_config(gui.newbranchtemplate)} {
1810                 tk_messageBox \
1811                         -icon error \
1812                         -type ok \
1813                         -title [wm title $w] \
1814                         -parent $w \
1815                         -message "Please supply a branch name."
1816                 focus $w.desc.name_t
1817                 return
1818         }
1819         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1820                 tk_messageBox \
1821                         -icon error \
1822                         -type ok \
1823                         -title [wm title $w] \
1824                         -parent $w \
1825                         -message "Branch '$newbranch' already exists."
1826                 focus $w.desc.name_t
1827                 return
1828         }
1829         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1830                 tk_messageBox \
1831                         -icon error \
1832                         -type ok \
1833                         -title [wm title $w] \
1834                         -parent $w \
1835                         -message "We do not like '$newbranch' as a branch name."
1836                 focus $w.desc.name_t
1837                 return
1838         }
1839
1840         set rev {}
1841         switch -- $create_branch_revtype {
1842         head {set rev $create_branch_head}
1843         tracking {set rev $create_branch_trackinghead}
1844         expression {set rev $create_branch_revexp}
1845         }
1846         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1847                 tk_messageBox \
1848                         -icon error \
1849                         -type ok \
1850                         -title [wm title $w] \
1851                         -parent $w \
1852                         -message "Invalid starting revision: $rev"
1853                 return
1854         }
1855         set cmd [list git update-ref]
1856         lappend cmd -m
1857         lappend cmd "branch: Created from $rev"
1858         lappend cmd "refs/heads/$newbranch"
1859         lappend cmd $cmt
1860         lappend cmd $null_sha1
1861         if {[catch {eval exec $cmd} err]} {
1862                 tk_messageBox \
1863                         -icon error \
1864                         -type ok \
1865                         -title [wm title $w] \
1866                         -parent $w \
1867                         -message "Failed to create '$newbranch'.\n\n$err"
1868                 return
1869         }
1870
1871         lappend all_heads $newbranch
1872         set all_heads [lsort $all_heads]
1873         populate_branch_menu
1874         destroy $w
1875         if {$create_branch_checkout} {
1876                 switch_branch $newbranch
1877         }
1878 }
1879
1880 proc radio_selector {varname value args} {
1881         upvar #0 $varname var
1882         set var $value
1883 }
1884
1885 trace add variable create_branch_head write \
1886         [list radio_selector create_branch_revtype head]
1887 trace add variable create_branch_trackinghead write \
1888         [list radio_selector create_branch_revtype tracking]
1889
1890 trace add variable delete_branch_head write \
1891         [list radio_selector delete_branch_checktype head]
1892 trace add variable delete_branch_trackinghead write \
1893         [list radio_selector delete_branch_checktype tracking]
1894
1895 proc do_create_branch {} {
1896         global all_heads current_branch repo_config
1897         global create_branch_checkout create_branch_revtype
1898         global create_branch_head create_branch_trackinghead
1899         global create_branch_name create_branch_revexp
1900
1901         set w .branch_editor
1902         toplevel $w
1903         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1904
1905         label $w.header -text {Create New Branch} \
1906                 -font font_uibold
1907         pack $w.header -side top -fill x
1908
1909         frame $w.buttons
1910         button $w.buttons.create -text Create \
1911                 -font font_ui \
1912                 -default active \
1913                 -command [list do_create_branch_action $w]
1914         pack $w.buttons.create -side right
1915         button $w.buttons.cancel -text {Cancel} \
1916                 -font font_ui \
1917                 -command [list destroy $w]
1918         pack $w.buttons.cancel -side right -padx 5
1919         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1920
1921         labelframe $w.desc \
1922                 -text {Branch Description} \
1923                 -font font_ui
1924         label $w.desc.name_l -text {Name:} -font font_ui
1925         entry $w.desc.name_t \
1926                 -borderwidth 1 \
1927                 -relief sunken \
1928                 -width 40 \
1929                 -textvariable create_branch_name \
1930                 -font font_ui \
1931                 -validate key \
1932                 -validatecommand {
1933                         if {%d == 1 && [regexp {[~^:?*\[\0- ]} %S]} {return 0}
1934                         return 1
1935                 }
1936         grid $w.desc.name_l $w.desc.name_t -sticky we -padx {0 5}
1937         grid columnconfigure $w.desc 1 -weight 1
1938         pack $w.desc -anchor nw -fill x -pady 5 -padx 5
1939
1940         labelframe $w.from \
1941                 -text {Starting Revision} \
1942                 -font font_ui
1943         radiobutton $w.from.head_r \
1944                 -text {Local Branch:} \
1945                 -value head \
1946                 -variable create_branch_revtype \
1947                 -font font_ui
1948         eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
1949         grid $w.from.head_r $w.from.head_m -sticky w
1950         set all_trackings [all_tracking_branches]
1951         if {$all_trackings ne {}} {
1952                 set create_branch_trackinghead [lindex $all_trackings 0]
1953                 radiobutton $w.from.tracking_r \
1954                         -text {Tracking Branch:} \
1955                         -value tracking \
1956                         -variable create_branch_revtype \
1957                         -font font_ui
1958                 eval tk_optionMenu $w.from.tracking_m \
1959                         create_branch_trackinghead \
1960                         $all_trackings
1961                 grid $w.from.tracking_r $w.from.tracking_m -sticky w
1962         }
1963         radiobutton $w.from.exp_r \
1964                 -text {Revision Expression:} \
1965                 -value expression \
1966                 -variable create_branch_revtype \
1967                 -font font_ui
1968         entry $w.from.exp_t \
1969                 -borderwidth 1 \
1970                 -relief sunken \
1971                 -width 50 \
1972                 -textvariable create_branch_revexp \
1973                 -font font_ui \
1974                 -validate key \
1975                 -validatecommand {
1976                         if {%d == 1 && [regexp {\s} %S]} {return 0}
1977                         if {%d == 1 && [string length %S] > 0} {
1978                                 set create_branch_revtype expression
1979                         }
1980                         return 1
1981                 }
1982         grid $w.from.exp_r $w.from.exp_t -sticky we -padx {0 5}
1983         grid columnconfigure $w.from 1 -weight 1
1984         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1985
1986         labelframe $w.postActions \
1987                 -text {Post Creation Actions} \
1988                 -font font_ui
1989         checkbutton $w.postActions.checkout \
1990                 -text {Checkout after creation} \
1991                 -variable create_branch_checkout \
1992                 -font font_ui
1993         pack $w.postActions.checkout -anchor nw
1994         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1995
1996         set create_branch_checkout 1
1997         set create_branch_head $current_branch
1998         set create_branch_revtype head
1999         set create_branch_name $repo_config(gui.newbranchtemplate)
2000         set create_branch_revexp {}
2001
2002         bind $w <Visibility> "
2003                 grab $w
2004                 $w.desc.name_t icursor end
2005                 focus $w.desc.name_t
2006         "
2007         bind $w <Key-Escape> "destroy $w"
2008         bind $w <Key-Return> "do_create_branch_action $w;break"
2009         wm title $w "[appname] ([reponame]): Create Branch"
2010         tkwait window $w
2011 }
2012
2013 proc do_delete_branch_action {w} {
2014         global all_heads
2015         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
2016
2017         set check_rev {}
2018         switch -- $delete_branch_checktype {
2019         head {set check_rev $delete_branch_head}
2020         tracking {set check_rev $delete_branch_trackinghead}
2021         always {set check_rev {:none}}
2022         }
2023         if {$check_rev eq {:none}} {
2024                 set check_cmt {}
2025         } elseif {[catch {set check_cmt [exec git rev-parse --verify "${check_rev}^0"]}]} {
2026                 tk_messageBox \
2027                         -icon error \
2028                         -type ok \
2029                         -title [wm title $w] \
2030                         -parent $w \
2031                         -message "Invalid check revision: $check_rev"
2032                 return
2033         }
2034
2035         set to_delete [list]
2036         set not_merged [list]
2037         foreach i [$w.list.l curselection] {
2038                 set b [$w.list.l get $i]
2039                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
2040                 if {$check_cmt ne {}} {
2041                         if {$b eq $check_rev} continue
2042                         if {[catch {set m [exec git merge-base $o $check_cmt]}]} continue
2043                         if {$o ne $m} {
2044                                 lappend not_merged $b
2045                                 continue
2046                         }
2047                 }
2048                 lappend to_delete [list $b $o]
2049         }
2050         if {$not_merged ne {}} {
2051                 set msg "The following branches are not completely merged into $check_rev:
2052
2053  - [join $not_merged "\n - "]"
2054                 tk_messageBox \
2055                         -icon info \
2056                         -type ok \
2057                         -title [wm title $w] \
2058                         -parent $w \
2059                         -message $msg
2060         }
2061         if {$to_delete eq {}} return
2062         if {$delete_branch_checktype eq {always}} {
2063                 set msg {Recovering deleted branches is difficult.
2064
2065 Delete the selected branches?}
2066                 if {[tk_messageBox \
2067                         -icon warning \
2068                         -type yesno \
2069                         -title [wm title $w] \
2070                         -parent $w \
2071                         -message $msg] ne yes} {
2072                         return
2073                 }
2074         }
2075
2076         set failed {}
2077         foreach i $to_delete {
2078                 set b [lindex $i 0]
2079                 set o [lindex $i 1]
2080                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
2081                         append failed " - $b: $err\n"
2082                 } else {
2083                         set x [lsearch -sorted -exact $all_heads $b]
2084                         if {$x >= 0} {
2085                                 set all_heads [lreplace $all_heads $x $x]
2086                         }
2087                 }
2088         }
2089
2090         if {$failed ne {}} {
2091                 tk_messageBox \
2092                         -icon error \
2093                         -type ok \
2094                         -title [wm title $w] \
2095                         -parent $w \
2096                         -message "Failed to delete branches:\n$failed"
2097         }
2098
2099         set all_heads [lsort $all_heads]
2100         populate_branch_menu
2101         destroy $w
2102 }
2103
2104 proc do_delete_branch {} {
2105         global all_heads tracking_branches current_branch
2106         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
2107
2108         set w .branch_editor
2109         toplevel $w
2110         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2111
2112         label $w.header -text {Delete Local Branch} \
2113                 -font font_uibold
2114         pack $w.header -side top -fill x
2115
2116         frame $w.buttons
2117         button $w.buttons.create -text Delete \
2118                 -font font_ui \
2119                 -command [list do_delete_branch_action $w]
2120         pack $w.buttons.create -side right
2121         button $w.buttons.cancel -text {Cancel} \
2122                 -font font_ui \
2123                 -command [list destroy $w]
2124         pack $w.buttons.cancel -side right -padx 5
2125         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2126
2127         labelframe $w.list \
2128                 -text {Local Branches} \
2129                 -font font_ui
2130         listbox $w.list.l \
2131                 -height 10 \
2132                 -width 50 \
2133                 -selectmode extended \
2134                 -font font_ui
2135         foreach h $all_heads {
2136                 if {$h ne $current_branch} {
2137                         $w.list.l insert end $h
2138                 }
2139         }
2140         pack $w.list.l -fill both -pady 5 -padx 5
2141         pack $w.list -fill both -pady 5 -padx 5
2142
2143         labelframe $w.validate \
2144                 -text {Delete Only If} \
2145                 -font font_ui
2146         radiobutton $w.validate.head_r \
2147                 -text {Merged Into Local Branch:} \
2148                 -value head \
2149                 -variable delete_branch_checktype \
2150                 -font font_ui
2151         eval tk_optionMenu $w.validate.head_m delete_branch_head $all_heads
2152         grid $w.validate.head_r $w.validate.head_m -sticky w
2153         set all_trackings [all_tracking_branches]
2154         if {$all_trackings ne {}} {
2155                 set delete_branch_trackinghead [lindex $all_trackings 0]
2156                 radiobutton $w.validate.tracking_r \
2157                         -text {Merged Into Tracking Branch:} \
2158                         -value tracking \
2159                         -variable delete_branch_checktype \
2160                         -font font_ui
2161                 eval tk_optionMenu $w.validate.tracking_m \
2162                         delete_branch_trackinghead \
2163                         $all_trackings
2164                 grid $w.validate.tracking_r $w.validate.tracking_m -sticky w
2165         }
2166         radiobutton $w.validate.always_r \
2167                 -text {Always (Do not perform merge checks)} \
2168                 -value always \
2169                 -variable delete_branch_checktype \
2170                 -font font_ui
2171         grid $w.validate.always_r -columnspan 2 -sticky w
2172         grid columnconfigure $w.validate 1 -weight 1
2173         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
2174
2175         set delete_branch_head $current_branch
2176         set delete_branch_checktype head
2177
2178         bind $w <Visibility> "grab $w; focus $w"
2179         bind $w <Key-Escape> "destroy $w"
2180         wm title $w "[appname] ([reponame]): Delete Branch"
2181         tkwait window $w
2182 }
2183
2184 proc switch_branch {new_branch} {
2185         global HEAD commit_type current_branch repo_config
2186
2187         if {![lock_index switch]} return
2188
2189         # -- Our in memory state should match the repository.
2190         #
2191         repository_state curType curHEAD curMERGE_HEAD
2192         if {[string match amend* $commit_type]
2193                 && $curType eq {normal}
2194                 && $curHEAD eq $HEAD} {
2195         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2196                 info_popup {Last scanned state does not match repository state.
2197
2198 Another Git program has modified this repository
2199 since the last scan.  A rescan must be performed
2200 before the current branch can be changed.
2201
2202 The rescan will be automatically started now.
2203 }
2204                 unlock_index
2205                 rescan {set ui_status_value {Ready.}}
2206                 return
2207         }
2208
2209         # -- Don't do a pointless switch.
2210         #
2211         if {$current_branch eq $new_branch} {
2212                 unlock_index
2213                 return
2214         }
2215
2216         if {$repo_config(gui.trustmtime) eq {true}} {
2217                 switch_branch_stage2 {} $new_branch
2218         } else {
2219                 set ui_status_value {Refreshing file status...}
2220                 set cmd [list git update-index]
2221                 lappend cmd -q
2222                 lappend cmd --unmerged
2223                 lappend cmd --ignore-missing
2224                 lappend cmd --refresh
2225                 set fd_rf [open "| $cmd" r]
2226                 fconfigure $fd_rf -blocking 0 -translation binary
2227                 fileevent $fd_rf readable \
2228                         [list switch_branch_stage2 $fd_rf $new_branch]
2229         }
2230 }
2231
2232 proc switch_branch_stage2 {fd_rf new_branch} {
2233         global ui_status_value HEAD
2234
2235         if {$fd_rf ne {}} {
2236                 read $fd_rf
2237                 if {![eof $fd_rf]} return
2238                 close $fd_rf
2239         }
2240
2241         set ui_status_value "Updating working directory to '$new_branch'..."
2242         set cmd [list git read-tree]
2243         lappend cmd -m
2244         lappend cmd -u
2245         lappend cmd --exclude-per-directory=.gitignore
2246         lappend cmd $HEAD
2247         lappend cmd $new_branch
2248         set fd_rt [open "| $cmd" r]
2249         fconfigure $fd_rt -blocking 0 -translation binary
2250         fileevent $fd_rt readable \
2251                 [list switch_branch_readtree_wait $fd_rt $new_branch]
2252 }
2253
2254 proc switch_branch_readtree_wait {fd_rt new_branch} {
2255         global selected_commit_type commit_type HEAD MERGE_HEAD PARENT
2256         global current_branch
2257         global ui_comm ui_status_value
2258
2259         # -- We never get interesting output on stdout; only stderr.
2260         #
2261         read $fd_rt
2262         fconfigure $fd_rt -blocking 1
2263         if {![eof $fd_rt]} {
2264                 fconfigure $fd_rt -blocking 0
2265                 return
2266         }
2267
2268         # -- The working directory wasn't in sync with the index and
2269         #    we'd have to overwrite something to make the switch. A
2270         #    merge is required.
2271         #
2272         if {[catch {close $fd_rt} err]} {
2273                 regsub {^fatal: } $err {} err
2274                 warn_popup "File level merge required.
2275
2276 $err
2277
2278 Staying on branch '$current_branch'."
2279                 set ui_status_value "Aborted checkout of '$new_branch' (file level merging is required)."
2280                 unlock_index
2281                 return
2282         }
2283
2284         # -- Update the symbolic ref.  Core git doesn't even check for failure
2285         #    here, it Just Works(tm).  If it doesn't we are in some really ugly
2286         #    state that is difficult to recover from within git-gui.
2287         #
2288         if {[catch {exec git symbolic-ref HEAD "refs/heads/$new_branch"} err]} {
2289                 error_popup "Failed to set current branch.
2290
2291 This working directory is only partially switched.
2292 We successfully updated your files, but failed to
2293 update an internal Git file.
2294
2295 This should not have occurred.  [appname] will now
2296 close and give up.
2297
2298 $err"
2299                 do_quit
2300                 return
2301         }
2302
2303         # -- Update our repository state.  If we were previously in amend mode
2304         #    we need to toss the current buffer and do a full rescan to update
2305         #    our file lists.  If we weren't in amend mode our file lists are
2306         #    accurate and we can avoid the rescan.
2307         #
2308         unlock_index
2309         set selected_commit_type new
2310         if {[string match amend* $commit_type]} {
2311                 $ui_comm delete 0.0 end
2312                 $ui_comm edit reset
2313                 $ui_comm edit modified false
2314                 rescan {set ui_status_value "Checked out branch '$current_branch'."}
2315         } else {
2316                 repository_state commit_type HEAD MERGE_HEAD
2317                 set PARENT $HEAD
2318                 set ui_status_value "Checked out branch '$current_branch'."
2319         }
2320 }
2321
2322 ######################################################################
2323 ##
2324 ## remote management
2325
2326 proc load_all_remotes {} {
2327         global repo_config
2328         global all_remotes tracking_branches
2329
2330         set all_remotes [list]
2331         array unset tracking_branches
2332
2333         set rm_dir [gitdir remotes]
2334         if {[file isdirectory $rm_dir]} {
2335                 set all_remotes [glob \
2336                         -types f \
2337                         -tails \
2338                         -nocomplain \
2339                         -directory $rm_dir *]
2340
2341                 foreach name $all_remotes {
2342                         catch {
2343                                 set fd [open [file join $rm_dir $name] r]
2344                                 while {[gets $fd line] >= 0} {
2345                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2346                                                 $line line src dst]} continue
2347                                         if {![regexp ^refs/ $dst]} {
2348                                                 set dst "refs/heads/$dst"
2349                                         }
2350                                         set tracking_branches($dst) [list $name $src]
2351                                 }
2352                                 close $fd
2353                         }
2354                 }
2355         }
2356
2357         foreach line [array names repo_config remote.*.url] {
2358                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2359                 lappend all_remotes $name
2360
2361                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2362                         set fl {}
2363                 }
2364                 foreach line $fl {
2365                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2366                         if {![regexp ^refs/ $dst]} {
2367                                 set dst "refs/heads/$dst"
2368                         }
2369                         set tracking_branches($dst) [list $name $src]
2370                 }
2371         }
2372
2373         set all_remotes [lsort -unique $all_remotes]
2374 }
2375
2376 proc populate_fetch_menu {} {
2377         global all_remotes repo_config
2378
2379         set m .mbar.fetch
2380         foreach r $all_remotes {
2381                 set enable 0
2382                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2383                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2384                                 set enable 1
2385                         }
2386                 } else {
2387                         catch {
2388                                 set fd [open [gitdir remotes $r] r]
2389                                 while {[gets $fd n] >= 0} {
2390                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2391                                                 set enable 1
2392                                                 break
2393                                         }
2394                                 }
2395                                 close $fd
2396                         }
2397                 }
2398
2399                 if {$enable} {
2400                         $m add command \
2401                                 -label "Fetch from $r..." \
2402                                 -command [list fetch_from $r] \
2403                                 -font font_ui
2404                 }
2405         }
2406 }
2407
2408 proc populate_push_menu {} {
2409         global all_remotes repo_config
2410
2411         set m .mbar.push
2412         set fast_count 0
2413         foreach r $all_remotes {
2414                 set enable 0
2415                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2416                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2417                                 set enable 1
2418                         }
2419                 } else {
2420                         catch {
2421                                 set fd [open [gitdir remotes $r] r]
2422                                 while {[gets $fd n] >= 0} {
2423                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2424                                                 set enable 1
2425                                                 break
2426                                         }
2427                                 }
2428                                 close $fd
2429                         }
2430                 }
2431
2432                 if {$enable} {
2433                         if {!$fast_count} {
2434                                 $m add separator
2435                         }
2436                         $m add command \
2437                                 -label "Push to $r..." \
2438                                 -command [list push_to $r] \
2439                                 -font font_ui
2440                         incr fast_count
2441                 }
2442         }
2443 }
2444
2445 proc start_push_anywhere_action {w} {
2446         global push_urltype push_remote push_url push_thin push_tags
2447
2448         set r_url {}
2449         switch -- $push_urltype {
2450         remote {set r_url $push_remote}
2451         url {set r_url $push_url}
2452         }
2453         if {$r_url eq {}} return
2454
2455         set cmd [list git push]
2456         lappend cmd -v
2457         if {$push_thin} {
2458                 lappend cmd --thin
2459         }
2460         if {$push_tags} {
2461                 lappend cmd --tags
2462         }
2463         lappend cmd $r_url
2464         set cnt 0
2465         foreach i [$w.source.l curselection] {
2466                 set b [$w.source.l get $i]
2467                 lappend cmd "refs/heads/$b:refs/heads/$b"
2468                 incr cnt
2469         }
2470         if {$cnt == 0} {
2471                 return
2472         } elseif {$cnt == 1} {
2473                 set unit branch
2474         } else {
2475                 set unit branches
2476         }
2477
2478         set cons [new_console "push $r_url" "Pushing $cnt $unit to $r_url"]
2479         console_exec $cons $cmd console_done
2480         destroy $w
2481 }
2482
2483 trace add variable push_remote write \
2484         [list radio_selector push_urltype remote]
2485
2486 proc do_push_anywhere {} {
2487         global all_heads all_remotes current_branch
2488         global push_urltype push_remote push_url push_thin push_tags
2489
2490         set w .push_setup
2491         toplevel $w
2492         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2493
2494         label $w.header -text {Push Branches} -font font_uibold
2495         pack $w.header -side top -fill x
2496
2497         frame $w.buttons
2498         button $w.buttons.create -text Push \
2499                 -font font_ui \
2500                 -command [list start_push_anywhere_action $w]
2501         pack $w.buttons.create -side right
2502         button $w.buttons.cancel -text {Cancel} \
2503                 -font font_ui \
2504                 -command [list destroy $w]
2505         pack $w.buttons.cancel -side right -padx 5
2506         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2507
2508         labelframe $w.source \
2509                 -text {Source Branches} \
2510                 -font font_ui
2511         listbox $w.source.l \
2512                 -height 10 \
2513                 -width 50 \
2514                 -selectmode extended \
2515                 -font font_ui
2516         foreach h $all_heads {
2517                 $w.source.l insert end $h
2518                 if {$h eq $current_branch} {
2519                         $w.source.l select set end
2520                 }
2521         }
2522         pack $w.source.l -fill both -pady 5 -padx 5
2523         pack $w.source -fill both -pady 5 -padx 5
2524
2525         labelframe $w.dest \
2526                 -text {Destination Repository} \
2527                 -font font_ui
2528         if {$all_remotes ne {}} {
2529                 radiobutton $w.dest.remote_r \
2530                         -text {Remote:} \
2531                         -value remote \
2532                         -variable push_urltype \
2533                         -font font_ui
2534                 eval tk_optionMenu $w.dest.remote_m push_remote $all_remotes
2535                 grid $w.dest.remote_r $w.dest.remote_m -sticky w
2536                 if {[lsearch -sorted -exact $all_remotes origin] != -1} {
2537                         set push_remote origin
2538                 } else {
2539                         set push_remote [lindex $all_remotes 0]
2540                 }
2541                 set push_urltype remote
2542         } else {
2543                 set push_urltype url
2544         }
2545         radiobutton $w.dest.url_r \
2546                 -text {Arbitrary URL:} \
2547                 -value url \
2548                 -variable push_urltype \
2549                 -font font_ui
2550         entry $w.dest.url_t \
2551                 -borderwidth 1 \
2552                 -relief sunken \
2553                 -width 50 \
2554                 -textvariable push_url \
2555                 -font font_ui \
2556                 -validate key \
2557                 -validatecommand {
2558                         if {%d == 1 && [regexp {\s} %S]} {return 0}
2559                         if {%d == 1 && [string length %S] > 0} {
2560                                 set push_urltype url
2561                         }
2562                         return 1
2563                 }
2564         grid $w.dest.url_r $w.dest.url_t -sticky we -padx {0 5}
2565         grid columnconfigure $w.dest 1 -weight 1
2566         pack $w.dest -anchor nw -fill x -pady 5 -padx 5
2567
2568         labelframe $w.options \
2569                 -text {Transfer Options} \
2570                 -font font_ui
2571         checkbutton $w.options.thin \
2572                 -text {Use thin pack (for slow network connections)} \
2573                 -variable push_thin \
2574                 -font font_ui
2575         grid $w.options.thin -columnspan 2 -sticky w
2576         checkbutton $w.options.tags \
2577                 -text {Include tags} \
2578                 -variable push_tags \
2579                 -font font_ui
2580         grid $w.options.tags -columnspan 2 -sticky w
2581         grid columnconfigure $w.options 1 -weight 1
2582         pack $w.options -anchor nw -fill x -pady 5 -padx 5
2583
2584         set push_url {}
2585         set push_thin 0
2586         set push_tags 0
2587
2588         bind $w <Visibility> "grab $w"
2589         bind $w <Key-Escape> "destroy $w"
2590         wm title $w "[appname] ([reponame]): Push"
2591         tkwait window $w
2592 }
2593
2594 ######################################################################
2595 ##
2596 ## merge
2597
2598 proc can_merge {} {
2599         global HEAD commit_type file_states
2600
2601         if {[string match amend* $commit_type]} {
2602                 info_popup {Cannot merge while amending.
2603
2604 You must finish amending this commit before
2605 starting any type of merge.
2606 }
2607                 return 0
2608         }
2609
2610         if {[committer_ident] eq {}} {return 0}
2611         if {![lock_index merge]} {return 0}
2612
2613         # -- Our in memory state should match the repository.
2614         #
2615         repository_state curType curHEAD curMERGE_HEAD
2616         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
2617                 info_popup {Last scanned state does not match repository state.
2618
2619 Another Git program has modified this repository
2620 since the last scan.  A rescan must be performed
2621 before a merge can be performed.
2622
2623 The rescan will be automatically started now.
2624 }
2625                 unlock_index
2626                 rescan {set ui_status_value {Ready.}}
2627                 return 0
2628         }
2629
2630         foreach path [array names file_states] {
2631                 switch -glob -- [lindex $file_states($path) 0] {
2632                 U? {
2633                         error_popup "You are in the middle of a conflicted merge.
2634
2635 File [short_path $path] has merge conflicts.
2636
2637 You must resolve them, add the file, and commit to
2638 complete the current merge.  Only then can you
2639 begin another merge.
2640 "
2641                         unlock_index
2642                         return 0
2643                 }
2644                 }
2645         }
2646
2647         return 1
2648 }
2649
2650 proc visualize_local_merge {w} {
2651         set revs {}
2652         foreach i [$w.source.l curselection] {
2653                 lappend revs [$w.source.l get $i]
2654         }
2655         if {$revs eq {}} return
2656         lappend revs --not HEAD
2657         do_gitk $revs
2658 }
2659
2660 proc start_local_merge_action {w} {
2661         global HEAD ui_status_value current_branch
2662
2663         set cmd [list git merge]
2664         set names {}
2665         set revcnt 0
2666         foreach i [$w.source.l curselection] {
2667                 set b [$w.source.l get $i]
2668                 lappend cmd $b
2669                 lappend names $b
2670                 incr revcnt
2671         }
2672
2673         if {$revcnt == 0} {
2674                 return
2675         } elseif {$revcnt == 1} {
2676                 set unit branch
2677         } elseif {$revcnt <= 15} {
2678                 set unit branches
2679         } else {
2680                 tk_messageBox \
2681                         -icon error \
2682                         -type ok \
2683                         -title [wm title $w] \
2684                         -parent $w \
2685                         -message "Too many branches selected.
2686
2687 You have requested to merge $revcnt branches
2688 in an octopus merge.  This exceeds Git's
2689 internal limit of 15 branches per merge.
2690
2691 Please select fewer branches.  To merge more
2692 than 15 branches, merge the branches in batches.
2693 "
2694                 return
2695         }
2696
2697         set msg "Merging $current_branch, [join $names {, }]"
2698         set ui_status_value "$msg..."
2699         set cons [new_console "Merge" $msg]
2700         console_exec $cons $cmd [list finish_merge $revcnt]
2701         bind $w <Destroy> {}
2702         destroy $w
2703 }
2704
2705 proc finish_merge {revcnt w ok} {
2706         console_done $w $ok
2707         if {$ok} {
2708                 set msg {Merge completed successfully.}
2709         } else {
2710                 if {$revcnt != 1} {
2711                         info_popup "Octopus merge failed.
2712
2713 Your merge of $revcnt branches has failed.
2714
2715 There are file-level conflicts between the
2716 branches which must be resolved manually.
2717
2718 The working directory will now be reset.
2719
2720 You can attempt this merge again
2721 by merging only one branch at a time." $w
2722
2723                         set fd [open "| git read-tree --reset -u HEAD" r]
2724                         fconfigure $fd -blocking 0 -translation binary
2725                         fileevent $fd readable [list reset_hard_wait $fd]
2726                         set ui_status_value {Aborting... please wait...}
2727                         return
2728                 }
2729
2730                 set msg {Merge failed.  Conflict resolution is required.}
2731         }
2732         unlock_index
2733         rescan [list set ui_status_value $msg]
2734 }
2735
2736 proc do_local_merge {} {
2737         global current_branch
2738
2739         if {![can_merge]} return
2740
2741         set w .merge_setup
2742         toplevel $w
2743         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2744
2745         label $w.header \
2746                 -text "Merge Into $current_branch" \
2747                 -font font_uibold
2748         pack $w.header -side top -fill x
2749
2750         frame $w.buttons
2751         button $w.buttons.visualize -text Visualize \
2752                 -font font_ui \
2753                 -command [list visualize_local_merge $w]
2754         pack $w.buttons.visualize -side left
2755         button $w.buttons.create -text Merge \
2756                 -font font_ui \
2757                 -command [list start_local_merge_action $w]
2758         pack $w.buttons.create -side right
2759         button $w.buttons.cancel -text {Cancel} \
2760                 -font font_ui \
2761                 -command [list destroy $w]
2762         pack $w.buttons.cancel -side right -padx 5
2763         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2764
2765         labelframe $w.source \
2766                 -text {Source Branches} \
2767                 -font font_ui
2768         listbox $w.source.l \
2769                 -height 10 \
2770                 -width 25 \
2771                 -selectmode extended \
2772                 -yscrollcommand [list $w.source.sby set] \
2773                 -font font_ui
2774         scrollbar $w.source.sby -command [list $w.source.l yview]
2775         pack $w.source.sby -side right -fill y
2776         pack $w.source.l -side left -fill both -expand 1
2777         pack $w.source -fill both -expand 1 -pady 5 -padx 5
2778
2779         set cmd [list git for-each-ref]
2780         lappend cmd {--format=%(objectname) %(refname)}
2781         lappend cmd refs/heads
2782         lappend cmd refs/remotes
2783         set fr_fd [open "| $cmd" r]
2784         fconfigure $fr_fd -translation binary
2785         while {[gets $fr_fd line] > 0} {
2786                 set line [split $line { }]
2787                 set sha1([lindex $line 0]) [lindex $line 1]
2788         }
2789         close $fr_fd
2790
2791         set to_show {}
2792         set fr_fd [open "| git rev-list --all --not HEAD"]
2793         while {[gets $fr_fd line] > 0} {
2794                 if {[catch {set ref $sha1($line)}]} continue
2795                 regsub ^refs/(heads|remotes)/ $ref {} ref
2796                 lappend to_show $ref
2797         }
2798         close $fr_fd
2799
2800         foreach ref [lsort -unique $to_show] {
2801                 $w.source.l insert end $ref
2802         }
2803
2804         bind $w <Visibility> "grab $w"
2805         bind $w <Key-Escape> "unlock_index;destroy $w"
2806         bind $w <Destroy> unlock_index
2807         wm title $w "[appname] ([reponame]): Merge"
2808         tkwait window $w
2809 }
2810
2811 proc do_reset_hard {} {
2812         global HEAD commit_type file_states
2813
2814         if {[string match amend* $commit_type]} {
2815                 info_popup {Cannot abort while amending.
2816
2817 You must finish amending this commit.
2818 }
2819                 return
2820         }
2821
2822         if {![lock_index abort]} return
2823
2824         if {[string match *merge* $commit_type]} {
2825                 set op merge
2826         } else {
2827                 set op commit
2828         }
2829
2830         if {[ask_popup "Abort $op?
2831
2832 Aborting the current $op will cause
2833 *ALL* uncommitted changes to be lost.
2834
2835 Continue with aborting the current $op?"] eq {yes}} {
2836                 set fd [open "| git read-tree --reset -u HEAD" r]
2837                 fconfigure $fd -blocking 0 -translation binary
2838                 fileevent $fd readable [list reset_hard_wait $fd]
2839                 set ui_status_value {Aborting... please wait...}
2840         } else {
2841                 unlock_index
2842         }
2843 }
2844
2845 proc reset_hard_wait {fd} {
2846         global ui_comm
2847
2848         read $fd
2849         if {[eof $fd]} {
2850                 close $fd
2851                 unlock_index
2852
2853                 $ui_comm delete 0.0 end
2854                 $ui_comm edit modified false
2855
2856                 catch {file delete [gitdir MERGE_HEAD]}
2857                 catch {file delete [gitdir rr-cache MERGE_RR]}
2858                 catch {file delete [gitdir SQUASH_MSG]}
2859                 catch {file delete [gitdir MERGE_MSG]}
2860                 catch {file delete [gitdir GITGUI_MSG]}
2861
2862                 rescan {set ui_status_value {Abort completed.  Ready.}}
2863         }
2864 }
2865
2866 ######################################################################
2867 ##
2868 ## icons
2869
2870 set filemask {
2871 #define mask_width 14
2872 #define mask_height 15
2873 static unsigned char mask_bits[] = {
2874    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2875    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2876    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2877 }
2878
2879 image create bitmap file_plain -background white -foreground black -data {
2880 #define plain_width 14
2881 #define plain_height 15
2882 static unsigned char plain_bits[] = {
2883    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2884    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2885    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2886 } -maskdata $filemask
2887
2888 image create bitmap file_mod -background white -foreground blue -data {
2889 #define mod_width 14
2890 #define mod_height 15
2891 static unsigned char mod_bits[] = {
2892    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2893    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2894    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2895 } -maskdata $filemask
2896
2897 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2898 #define file_fulltick_width 14
2899 #define file_fulltick_height 15
2900 static unsigned char file_fulltick_bits[] = {
2901    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2902    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2903    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2904 } -maskdata $filemask
2905
2906 image create bitmap file_parttick -background white -foreground "#005050" -data {
2907 #define parttick_width 14
2908 #define parttick_height 15
2909 static unsigned char parttick_bits[] = {
2910    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2911    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2912    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2913 } -maskdata $filemask
2914
2915 image create bitmap file_question -background white -foreground black -data {
2916 #define file_question_width 14
2917 #define file_question_height 15
2918 static unsigned char file_question_bits[] = {
2919    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2920    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2921    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2922 } -maskdata $filemask
2923
2924 image create bitmap file_removed -background white -foreground red -data {
2925 #define file_removed_width 14
2926 #define file_removed_height 15
2927 static unsigned char file_removed_bits[] = {
2928    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2929    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2930    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2931 } -maskdata $filemask
2932
2933 image create bitmap file_merge -background white -foreground blue -data {
2934 #define file_merge_width 14
2935 #define file_merge_height 15
2936 static unsigned char file_merge_bits[] = {
2937    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2938    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2939    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2940 } -maskdata $filemask
2941
2942 set ui_index .vpane.files.index.list
2943 set ui_workdir .vpane.files.workdir.list
2944
2945 set all_icons(_$ui_index)   file_plain
2946 set all_icons(A$ui_index)   file_fulltick
2947 set all_icons(M$ui_index)   file_fulltick
2948 set all_icons(D$ui_index)   file_removed
2949 set all_icons(U$ui_index)   file_merge
2950
2951 set all_icons(_$ui_workdir) file_plain
2952 set all_icons(M$ui_workdir) file_mod
2953 set all_icons(D$ui_workdir) file_question
2954 set all_icons(U$ui_workdir) file_merge
2955 set all_icons(O$ui_workdir) file_plain
2956
2957 set max_status_desc 0
2958 foreach i {
2959                 {__ "Unmodified"}
2960
2961                 {_M "Modified, not staged"}
2962                 {M_ "Staged for commit"}
2963                 {MM "Portions staged for commit"}
2964                 {MD "Staged for commit, missing"}
2965
2966                 {_O "Untracked, not staged"}
2967                 {A_ "Staged for commit"}
2968                 {AM "Portions staged for commit"}
2969                 {AD "Staged for commit, missing"}
2970
2971                 {_D "Missing"}
2972                 {D_ "Staged for removal"}
2973                 {DO "Staged for removal, still present"}
2974
2975                 {U_ "Requires merge resolution"}
2976                 {UU "Requires merge resolution"}
2977                 {UM "Requires merge resolution"}
2978                 {UD "Requires merge resolution"}
2979         } {
2980         if {$max_status_desc < [string length [lindex $i 1]]} {
2981                 set max_status_desc [string length [lindex $i 1]]
2982         }
2983         set all_descs([lindex $i 0]) [lindex $i 1]
2984 }
2985 unset i
2986
2987 ######################################################################
2988 ##
2989 ## util
2990
2991 proc is_MacOSX {} {
2992         global tcl_platform tk_library
2993         if {[tk windowingsystem] eq {aqua}} {
2994                 return 1
2995         }
2996         return 0
2997 }
2998
2999 proc is_Windows {} {
3000         global tcl_platform
3001         if {$tcl_platform(platform) eq {windows}} {
3002                 return 1
3003         }
3004         return 0
3005 }
3006
3007 proc bind_button3 {w cmd} {
3008         bind $w <Any-Button-3> $cmd
3009         if {[is_MacOSX]} {
3010                 bind $w <Control-Button-1> $cmd
3011         }
3012 }
3013
3014 proc incr_font_size {font {amt 1}} {
3015         set sz [font configure $font -size]
3016         incr sz $amt
3017         font configure $font -size $sz
3018         font configure ${font}bold -size $sz
3019 }
3020
3021 proc hook_failed_popup {hook msg} {
3022         set w .hookfail
3023         toplevel $w
3024
3025         frame $w.m
3026         label $w.m.l1 -text "$hook hook failed:" \
3027                 -anchor w \
3028                 -justify left \
3029                 -font font_uibold
3030         text $w.m.t \
3031                 -background white -borderwidth 1 \
3032                 -relief sunken \
3033                 -width 80 -height 10 \
3034                 -font font_diff \
3035                 -yscrollcommand [list $w.m.sby set]
3036         label $w.m.l2 \
3037                 -text {You must correct the above errors before committing.} \
3038                 -anchor w \
3039                 -justify left \
3040                 -font font_uibold
3041         scrollbar $w.m.sby -command [list $w.m.t yview]
3042         pack $w.m.l1 -side top -fill x
3043         pack $w.m.l2 -side bottom -fill x
3044         pack $w.m.sby -side right -fill y
3045         pack $w.m.t -side left -fill both -expand 1
3046         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
3047
3048         $w.m.t insert 1.0 $msg
3049         $w.m.t conf -state disabled
3050
3051         button $w.ok -text OK \
3052                 -width 15 \
3053                 -font font_ui \
3054                 -command "destroy $w"
3055         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
3056
3057         bind $w <Visibility> "grab $w; focus $w"
3058         bind $w <Key-Return> "destroy $w"
3059         wm title $w "[appname] ([reponame]): error"
3060         tkwait window $w
3061 }
3062
3063 set next_console_id 0
3064
3065 proc new_console {short_title long_title} {
3066         global next_console_id console_data
3067         set w .console[incr next_console_id]
3068         set console_data($w) [list $short_title $long_title]
3069         return [console_init $w]
3070 }
3071
3072 proc console_init {w} {
3073         global console_cr console_data M1B
3074
3075         set console_cr($w) 1.0
3076         toplevel $w
3077         frame $w.m
3078         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
3079                 -anchor w \
3080                 -justify left \
3081                 -font font_uibold
3082         text $w.m.t \
3083                 -background white -borderwidth 1 \
3084                 -relief sunken \
3085                 -width 80 -height 10 \
3086                 -font font_diff \
3087                 -state disabled \
3088                 -yscrollcommand [list $w.m.sby set]
3089         label $w.m.s -text {Working... please wait...} \
3090                 -anchor w \
3091                 -justify left \
3092                 -font font_uibold
3093         scrollbar $w.m.sby -command [list $w.m.t yview]
3094         pack $w.m.l1 -side top -fill x
3095         pack $w.m.s -side bottom -fill x
3096         pack $w.m.sby -side right -fill y
3097         pack $w.m.t -side left -fill both -expand 1
3098         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
3099
3100         menu $w.ctxm -tearoff 0
3101         $w.ctxm add command -label "Copy" \
3102                 -font font_ui \
3103                 -command "tk_textCopy $w.m.t"
3104         $w.ctxm add command -label "Select All" \
3105                 -font font_ui \
3106                 -command "focus $w.m.t;$w.m.t tag add sel 0.0 end"
3107         $w.ctxm add command -label "Copy All" \
3108                 -font font_ui \
3109                 -command "
3110                         $w.m.t tag add sel 0.0 end
3111                         tk_textCopy $w.m.t
3112                         $w.m.t tag remove sel 0.0 end
3113                 "
3114
3115         button $w.ok -text {Close} \
3116                 -font font_ui \
3117                 -state disabled \
3118                 -command "destroy $w"
3119         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
3120
3121         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
3122         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
3123         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
3124         bind $w <Visibility> "focus $w"
3125         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
3126         return $w
3127 }
3128
3129 proc console_exec {w cmd after} {
3130         # -- Windows tosses the enviroment when we exec our child.
3131         #    But most users need that so we have to relogin. :-(
3132         #
3133         if {[is_Windows]} {
3134                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
3135         }
3136
3137         # -- Tcl won't let us redirect both stdout and stderr to
3138         #    the same pipe.  So pass it through cat...
3139         #
3140         set cmd [concat | $cmd |& cat]
3141
3142         set fd_f [open $cmd r]
3143         fconfigure $fd_f -blocking 0 -translation binary
3144         fileevent $fd_f readable [list console_read $w $fd_f $after]
3145 }
3146
3147 proc console_read {w fd after} {
3148         global console_cr
3149
3150         set buf [read $fd]
3151         if {$buf ne {}} {
3152                 if {![winfo exists $w]} {console_init $w}
3153                 $w.m.t conf -state normal
3154                 set c 0
3155                 set n [string length $buf]
3156                 while {$c < $n} {
3157                         set cr [string first "\r" $buf $c]
3158                         set lf [string first "\n" $buf $c]
3159                         if {$cr < 0} {set cr [expr {$n + 1}]}
3160                         if {$lf < 0} {set lf [expr {$n + 1}]}
3161
3162                         if {$lf < $cr} {
3163                                 $w.m.t insert end [string range $buf $c $lf]
3164                                 set console_cr($w) [$w.m.t index {end -1c}]
3165                                 set c $lf
3166                                 incr c
3167                         } else {
3168                                 $w.m.t delete $console_cr($w) end
3169                                 $w.m.t insert end "\n"
3170                                 $w.m.t insert end [string range $buf $c $cr]
3171                                 set c $cr
3172                                 incr c
3173                         }
3174                 }
3175                 $w.m.t conf -state disabled
3176                 $w.m.t see end
3177         }
3178
3179         fconfigure $fd -blocking 1
3180         if {[eof $fd]} {
3181                 if {[catch {close $fd}]} {
3182                         set ok 0
3183                 } else {
3184                         set ok 1
3185                 }
3186                 uplevel #0 $after $w $ok
3187                 return
3188         }
3189         fconfigure $fd -blocking 0
3190 }
3191
3192 proc console_chain {cmdlist w {ok 1}} {
3193         if {$ok} {
3194                 if {[llength $cmdlist] == 0} {
3195                         console_done $w $ok
3196                         return
3197                 }
3198
3199                 set cmd [lindex $cmdlist 0]
3200                 set cmdlist [lrange $cmdlist 1 end]
3201
3202                 if {[lindex $cmd 0] eq {console_exec}} {
3203                         console_exec $w \
3204                                 [lindex $cmd 1] \
3205                                 [list console_chain $cmdlist]
3206                 } else {
3207                         uplevel #0 $cmd $cmdlist $w $ok
3208                 }
3209         } else {
3210                 console_done $w $ok
3211         }
3212 }
3213
3214 proc console_done {args} {
3215         global console_cr console_data
3216
3217         switch -- [llength $args] {
3218         2 {
3219                 set w [lindex $args 0]
3220                 set ok [lindex $args 1]
3221         }
3222         3 {
3223                 set w [lindex $args 1]
3224                 set ok [lindex $args 2]
3225         }
3226         default {
3227                 error "wrong number of args: console_done ?ignored? w ok"
3228         }
3229         }
3230
3231         if {$ok} {
3232                 if {[winfo exists $w]} {
3233                         $w.m.s conf -background green -text {Success}
3234                         $w.ok conf -state normal
3235                 }
3236         } else {
3237                 if {![winfo exists $w]} {
3238                         console_init $w
3239                 }
3240                 $w.m.s conf -background red -text {Error: Command Failed}
3241                 $w.ok conf -state normal
3242         }
3243
3244         array unset console_cr $w
3245         array unset console_data $w
3246 }
3247
3248 ######################################################################
3249 ##
3250 ## ui commands
3251
3252 set starting_gitk_msg {Starting gitk... please wait...}
3253
3254 proc do_gitk {revs} {
3255         global ui_status_value starting_gitk_msg
3256
3257         set cmd gitk
3258         if {$revs ne {}} {
3259                 append cmd { }
3260                 append cmd $revs
3261         }
3262         if {[is_Windows]} {
3263                 set cmd "sh -c \"exec $cmd\""
3264         }
3265         append cmd { &}
3266
3267         if {[catch {eval exec $cmd} err]} {
3268                 error_popup "Failed to start gitk:\n\n$err"
3269         } else {
3270                 set ui_status_value $starting_gitk_msg
3271                 after 10000 {
3272                         if {$ui_status_value eq $starting_gitk_msg} {
3273                                 set ui_status_value {Ready.}
3274                         }
3275                 }
3276         }
3277 }
3278
3279 proc do_stats {} {
3280         set fd [open "| git count-objects -v" r]
3281         while {[gets $fd line] > 0} {
3282                 if {[regexp {^([^:]+): (\d+)$} $line _ name value]} {
3283                         set stats($name) $value
3284                 }
3285         }
3286         close $fd
3287
3288         set packed_sz 0
3289         foreach p [glob -directory [gitdir objects pack] \
3290                 -type f \
3291                 -nocomplain -- *] {
3292                 incr packed_sz [file size $p]
3293         }
3294         if {$packed_sz > 0} {
3295                 set stats(size-pack) [expr {$packed_sz / 1024}]
3296         }
3297
3298         set w .stats_view
3299         toplevel $w
3300         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
3301
3302         label $w.header -text {Database Statistics} \
3303                 -font font_uibold
3304         pack $w.header -side top -fill x
3305
3306         frame $w.buttons -border 1
3307         button $w.buttons.close -text Close \
3308                 -font font_ui \
3309                 -command [list destroy $w]
3310         button $w.buttons.gc -text {Compress Database} \
3311                 -font font_ui \
3312                 -command "destroy $w;do_gc"
3313         pack $w.buttons.close -side right
3314         pack $w.buttons.gc -side left
3315         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
3316
3317         frame $w.stat -borderwidth 1 -relief solid
3318         foreach s {
3319                 {count           {Number of loose objects}}
3320                 {size            {Disk space used by loose objects} { KiB}}
3321                 {in-pack         {Number of packed objects}}
3322                 {packs           {Number of packs}}
3323                 {size-pack       {Disk space used by packed objects} { KiB}}
3324                 {prune-packable  {Packed objects waiting for pruning}}
3325                 {garbage         {Garbage files}}
3326                 } {
3327                 set name [lindex $s 0]
3328                 set label [lindex $s 1]
3329                 if {[catch {set value $stats($name)}]} continue
3330                 if {[llength $s] > 2} {
3331                         set value "$value[lindex $s 2]"
3332                 }
3333
3334                 label $w.stat.l_$name -text "$label:" -anchor w -font font_ui
3335                 label $w.stat.v_$name -text $value -anchor w -font font_ui
3336                 grid $w.stat.l_$name $w.stat.v_$name -sticky we -padx {0 5}
3337         }
3338         pack $w.stat -pady 10 -padx 10
3339
3340         bind $w <Visibility> "grab $w; focus $w"
3341         bind $w <Key-Escape> [list destroy $w]
3342         bind $w <Key-Return> [list destroy $w]
3343         wm title $w "[appname] ([reponame]): Database Statistics"
3344         tkwait window $w
3345 }
3346
3347 proc do_gc {} {
3348         set w [new_console {gc} {Compressing the object database}]
3349         console_chain {
3350                 {console_exec {git pack-refs --prune}}
3351                 {console_exec {git reflog expire --all}}
3352                 {console_exec {git repack -a -d -l}}
3353                 {console_exec {git rerere gc}}
3354         } $w
3355 }
3356
3357 proc do_fsck_objects {} {
3358         set w [new_console {fsck-objects} \
3359                 {Verifying the object database with fsck-objects}]
3360         set cmd [list git fsck-objects]
3361         lappend cmd --full
3362         lappend cmd --cache
3363         lappend cmd --strict
3364         console_exec $w $cmd console_done
3365 }
3366
3367 set is_quitting 0
3368
3369 proc do_quit {} {
3370         global ui_comm is_quitting repo_config commit_type
3371
3372         if {$is_quitting} return
3373         set is_quitting 1
3374
3375         # -- Stash our current commit buffer.
3376         #
3377         set save [gitdir GITGUI_MSG]
3378         set msg [string trim [$ui_comm get 0.0 end]]
3379         regsub -all -line {[ \r\t]+$} $msg {} msg
3380         if {(![string match amend* $commit_type]
3381                 || [$ui_comm edit modified])
3382                 && $msg ne {}} {
3383                 catch {
3384                         set fd [open $save w]
3385                         puts -nonewline $fd $msg
3386                         close $fd
3387                 }
3388         } else {
3389                 catch {file delete $save}
3390         }
3391
3392         # -- Stash our current window geometry into this repository.
3393         #
3394         set cfg_geometry [list]
3395         lappend cfg_geometry [wm geometry .]
3396         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
3397         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
3398         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
3399                 set rc_geometry {}
3400         }
3401         if {$cfg_geometry ne $rc_geometry} {
3402                 catch {exec git repo-config gui.geometry $cfg_geometry}
3403         }
3404
3405         destroy .
3406 }
3407
3408 proc do_rescan {} {
3409         rescan {set ui_status_value {Ready.}}
3410 }
3411
3412 proc unstage_helper {txt paths} {
3413         global file_states current_diff_path
3414
3415         if {![lock_index begin-update]} return
3416
3417         set pathList [list]
3418         set after {}
3419         foreach path $paths {
3420                 switch -glob -- [lindex $file_states($path) 0] {
3421                 A? -
3422                 M? -
3423                 D? {
3424                         lappend pathList $path
3425                         if {$path eq $current_diff_path} {
3426                                 set after {reshow_diff;}
3427                         }
3428                 }
3429                 }
3430         }
3431         if {$pathList eq {}} {
3432                 unlock_index
3433         } else {
3434                 update_indexinfo \
3435                         $txt \
3436                         $pathList \
3437                         [concat $after {set ui_status_value {Ready.}}]
3438         }
3439 }
3440
3441 proc do_unstage_selection {} {
3442         global current_diff_path selected_paths
3443
3444         if {[array size selected_paths] > 0} {
3445                 unstage_helper \
3446                         {Unstaging selected files from commit} \
3447                         [array names selected_paths]
3448         } elseif {$current_diff_path ne {}} {
3449                 unstage_helper \
3450                         "Unstaging [short_path $current_diff_path] from commit" \
3451                         [list $current_diff_path]
3452         }
3453 }
3454
3455 proc add_helper {txt paths} {
3456         global file_states current_diff_path
3457
3458         if {![lock_index begin-update]} return
3459
3460         set pathList [list]
3461         set after {}
3462         foreach path $paths {
3463                 switch -glob -- [lindex $file_states($path) 0] {
3464                 _O -
3465                 ?M -
3466                 ?D -
3467                 U? {
3468                         lappend pathList $path
3469                         if {$path eq $current_diff_path} {
3470                                 set after {reshow_diff;}
3471                         }
3472                 }
3473                 }
3474         }
3475         if {$pathList eq {}} {
3476                 unlock_index
3477         } else {
3478                 update_index \
3479                         $txt \
3480                         $pathList \
3481                         [concat $after {set ui_status_value {Ready to commit.}}]
3482         }
3483 }
3484
3485 proc do_add_selection {} {
3486         global current_diff_path selected_paths
3487
3488         if {[array size selected_paths] > 0} {
3489                 add_helper \
3490                         {Adding selected files} \
3491                         [array names selected_paths]
3492         } elseif {$current_diff_path ne {}} {
3493                 add_helper \
3494                         "Adding [short_path $current_diff_path]" \
3495                         [list $current_diff_path]
3496         }
3497 }
3498
3499 proc do_add_all {} {
3500         global file_states
3501
3502         set paths [list]
3503         foreach path [array names file_states] {
3504                 switch -glob -- [lindex $file_states($path) 0] {
3505                 U? {continue}
3506                 ?M -
3507                 ?D {lappend paths $path}
3508                 }
3509         }
3510         add_helper {Adding all changed files} $paths
3511 }
3512
3513 proc revert_helper {txt paths} {
3514         global file_states current_diff_path
3515
3516         if {![lock_index begin-update]} return
3517
3518         set pathList [list]
3519         set after {}
3520         foreach path $paths {
3521                 switch -glob -- [lindex $file_states($path) 0] {
3522                 U? {continue}
3523                 ?M -
3524                 ?D {
3525                         lappend pathList $path
3526                         if {$path eq $current_diff_path} {
3527                                 set after {reshow_diff;}
3528                         }
3529                 }
3530                 }
3531         }
3532
3533         set n [llength $pathList]
3534         if {$n == 0} {
3535                 unlock_index
3536                 return
3537         } elseif {$n == 1} {
3538                 set s "[short_path [lindex $pathList]]"
3539         } else {
3540                 set s "these $n files"
3541         }
3542
3543         set reply [tk_dialog \
3544                 .confirm_revert \
3545                 "[appname] ([reponame])" \
3546                 "Revert changes in $s?
3547
3548 Any unadded changes will be permanently lost by the revert." \
3549                 question \
3550                 1 \
3551                 {Do Nothing} \
3552                 {Revert Changes} \
3553                 ]
3554         if {$reply == 1} {
3555                 checkout_index \
3556                         $txt \
3557                         $pathList \
3558                         [concat $after {set ui_status_value {Ready.}}]
3559         } else {
3560                 unlock_index
3561         }
3562 }
3563
3564 proc do_revert_selection {} {
3565         global current_diff_path selected_paths
3566
3567         if {[array size selected_paths] > 0} {
3568                 revert_helper \
3569                         {Reverting selected files} \
3570                         [array names selected_paths]
3571         } elseif {$current_diff_path ne {}} {
3572                 revert_helper \
3573                         "Reverting [short_path $current_diff_path]" \
3574                         [list $current_diff_path]
3575         }
3576 }
3577
3578 proc do_signoff {} {
3579         global ui_comm
3580
3581         set me [committer_ident]
3582         if {$me eq {}} return
3583
3584         set sob "Signed-off-by: $me"
3585         set last [$ui_comm get {end -1c linestart} {end -1c}]
3586         if {$last ne $sob} {
3587                 $ui_comm edit separator
3588                 if {$last ne {}
3589                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
3590                         $ui_comm insert end "\n"
3591                 }
3592                 $ui_comm insert end "\n$sob"
3593                 $ui_comm edit separator
3594                 $ui_comm see end
3595         }
3596 }
3597
3598 proc do_select_commit_type {} {
3599         global commit_type selected_commit_type
3600
3601         if {$selected_commit_type eq {new}
3602                 && [string match amend* $commit_type]} {
3603                 create_new_commit
3604         } elseif {$selected_commit_type eq {amend}
3605                 && ![string match amend* $commit_type]} {
3606                 load_last_commit
3607
3608                 # The amend request was rejected...
3609                 #
3610                 if {![string match amend* $commit_type]} {
3611                         set selected_commit_type new
3612                 }
3613         }
3614 }
3615
3616 proc do_commit {} {
3617         commit_tree
3618 }
3619
3620 proc do_about {} {
3621         global appvers copyright
3622         global tcl_patchLevel tk_patchLevel
3623
3624         set w .about_dialog
3625         toplevel $w
3626         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
3627
3628         label $w.header -text "About [appname]" \
3629                 -font font_uibold
3630         pack $w.header -side top -fill x
3631
3632         frame $w.buttons
3633         button $w.buttons.close -text {Close} \
3634                 -font font_ui \
3635                 -command [list destroy $w]
3636         pack $w.buttons.close -side right
3637         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
3638
3639         label $w.desc \
3640                 -text "[appname] - a commit creation tool for Git.
3641 $copyright" \
3642                 -padx 5 -pady 5 \
3643                 -justify left \
3644                 -anchor w \
3645                 -borderwidth 1 \
3646                 -relief solid \
3647                 -font font_ui
3648         pack $w.desc -side top -fill x -padx 5 -pady 5
3649
3650         set v {}
3651         append v "[appname] version $appvers\n"
3652         append v "[exec git version]\n"
3653         append v "\n"
3654         if {$tcl_patchLevel eq $tk_patchLevel} {
3655                 append v "Tcl/Tk version $tcl_patchLevel"
3656         } else {
3657                 append v "Tcl version $tcl_patchLevel"
3658                 append v ", Tk version $tk_patchLevel"
3659         }
3660
3661         label $w.vers \
3662                 -text $v \
3663                 -padx 5 -pady 5 \
3664                 -justify left \
3665                 -anchor w \
3666                 -borderwidth 1 \
3667                 -relief solid \
3668                 -font font_ui
3669         pack $w.vers -side top -fill x -padx 5 -pady 5
3670
3671         menu $w.ctxm -tearoff 0
3672         $w.ctxm add command \
3673                 -label {Copy} \
3674                 -font font_ui \
3675                 -command "
3676                 clipboard clear
3677                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
3678         "
3679
3680         bind $w <Visibility> "grab $w; focus $w"
3681         bind $w <Key-Escape> "destroy $w"
3682         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
3683         wm title $w "About [appname]"
3684         tkwait window $w
3685 }
3686
3687 proc do_options {} {
3688         global repo_config global_config font_descs
3689         global repo_config_new global_config_new
3690
3691         array unset repo_config_new
3692         array unset global_config_new
3693         foreach name [array names repo_config] {
3694                 set repo_config_new($name) $repo_config($name)
3695         }
3696         load_config 1
3697         foreach name [array names repo_config] {
3698                 switch -- $name {
3699                 gui.diffcontext {continue}
3700                 }
3701                 set repo_config_new($name) $repo_config($name)
3702         }
3703         foreach name [array names global_config] {
3704                 set global_config_new($name) $global_config($name)
3705         }
3706
3707         set w .options_editor
3708         toplevel $w
3709         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
3710
3711         label $w.header -text "[appname] Options" \
3712                 -font font_uibold
3713         pack $w.header -side top -fill x
3714
3715         frame $w.buttons
3716         button $w.buttons.restore -text {Restore Defaults} \
3717                 -font font_ui \
3718                 -command do_restore_defaults
3719         pack $w.buttons.restore -side left
3720         button $w.buttons.save -text Save \
3721                 -font font_ui \
3722                 -command [list do_save_config $w]
3723         pack $w.buttons.save -side right
3724         button $w.buttons.cancel -text {Cancel} \
3725                 -font font_ui \
3726                 -command [list destroy $w]
3727         pack $w.buttons.cancel -side right -padx 5
3728         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
3729
3730         labelframe $w.repo -text "[reponame] Repository" \
3731                 -font font_ui
3732         labelframe $w.global -text {Global (All Repositories)} \
3733                 -font font_ui
3734         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
3735         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
3736
3737         foreach option {
3738                 {b pullsummary {Show Pull Summary}}
3739                 {b trustmtime  {Trust File Modification Timestamps}}
3740                 {i diffcontext {Number of Diff Context Lines}}
3741                 {t newbranchtemplate {New Branch Name Template}}
3742                 } {
3743                 set type [lindex $option 0]
3744                 set name [lindex $option 1]
3745                 set text [lindex $option 2]
3746                 foreach f {repo global} {
3747                         switch $type {
3748                         b {
3749                                 checkbutton $w.$f.$name -text $text \
3750                                         -variable ${f}_config_new(gui.$name) \
3751                                         -onvalue true \
3752                                         -offvalue false \
3753                                         -font font_ui
3754                                 pack $w.$f.$name -side top -anchor w
3755                         }
3756                         i {
3757                                 frame $w.$f.$name
3758                                 label $w.$f.$name.l -text "$text:" -font font_ui
3759                                 pack $w.$f.$name.l -side left -anchor w -fill x
3760                                 spinbox $w.$f.$name.v \
3761                                         -textvariable ${f}_config_new(gui.$name) \
3762                                         -from 1 -to 99 -increment 1 \
3763                                         -width 3 \
3764                                         -font font_ui
3765                                 bind $w.$f.$name.v <FocusIn> {%W selection range 0 end}
3766                                 pack $w.$f.$name.v -side right -anchor e -padx 5
3767                                 pack $w.$f.$name -side top -anchor w -fill x
3768                         }
3769                         t {
3770                                 frame $w.$f.$name
3771                                 label $w.$f.$name.l -text "$text:" -font font_ui
3772                                 entry $w.$f.$name.v \
3773                                         -borderwidth 1 \
3774                                         -relief sunken \
3775                                         -width 20 \
3776                                         -textvariable ${f}_config_new(gui.$name) \
3777                                         -font font_ui
3778                                 pack $w.$f.$name.l -side left -anchor w
3779                                 pack $w.$f.$name.v -side left -anchor w \
3780                                         -fill x -expand 1 \
3781                                         -padx 5
3782                                 pack $w.$f.$name -side top -anchor w -fill x
3783                         }
3784                         }
3785                 }
3786         }
3787
3788         set all_fonts [lsort [font families]]
3789         foreach option $font_descs {
3790                 set name [lindex $option 0]
3791                 set font [lindex $option 1]
3792                 set text [lindex $option 2]
3793
3794                 set global_config_new(gui.$font^^family) \
3795                         [font configure $font -family]
3796                 set global_config_new(gui.$font^^size) \
3797                         [font configure $font -size]
3798
3799                 frame $w.global.$name
3800                 label $w.global.$name.l -text "$text:" -font font_ui
3801                 pack $w.global.$name.l -side left -anchor w -fill x
3802                 eval tk_optionMenu $w.global.$name.family \
3803                         global_config_new(gui.$font^^family) \
3804                         $all_fonts
3805                 spinbox $w.global.$name.size \
3806                         -textvariable global_config_new(gui.$font^^size) \
3807                         -from 2 -to 80 -increment 1 \
3808                         -width 3 \
3809                         -font font_ui
3810                 bind $w.global.$name.size <FocusIn> {%W selection range 0 end}
3811                 pack $w.global.$name.size -side right -anchor e
3812                 pack $w.global.$name.family -side right -anchor e
3813                 pack $w.global.$name -side top -anchor w -fill x
3814         }
3815
3816         bind $w <Visibility> "grab $w; focus $w"
3817         bind $w <Key-Escape> "destroy $w"
3818         wm title $w "[appname] ([reponame]): Options"
3819         tkwait window $w
3820 }
3821
3822 proc do_restore_defaults {} {
3823         global font_descs default_config repo_config
3824         global repo_config_new global_config_new
3825
3826         foreach name [array names default_config] {
3827                 set repo_config_new($name) $default_config($name)
3828                 set global_config_new($name) $default_config($name)
3829         }
3830
3831         foreach option $font_descs {
3832                 set name [lindex $option 0]
3833                 set repo_config(gui.$name) $default_config(gui.$name)
3834         }
3835         apply_config
3836
3837         foreach option $font_descs {
3838                 set name [lindex $option 0]
3839                 set font [lindex $option 1]
3840                 set global_config_new(gui.$font^^family) \
3841                         [font configure $font -family]
3842                 set global_config_new(gui.$font^^size) \
3843                         [font configure $font -size]
3844         }
3845 }
3846
3847 proc do_save_config {w} {
3848         if {[catch {save_config} err]} {
3849                 error_popup "Failed to completely save options:\n\n$err"
3850         }
3851         reshow_diff
3852         destroy $w
3853 }
3854
3855 proc do_windows_shortcut {} {
3856         global argv0
3857
3858         if {[catch {
3859                 set desktop [exec cygpath \
3860                         --windows \
3861                         --absolute \
3862                         --long-name \
3863                         --desktop]
3864                 }]} {
3865                         set desktop .
3866         }
3867         set fn [tk_getSaveFile \
3868                 -parent . \
3869                 -title "[appname] ([reponame]): Create Desktop Icon" \
3870                 -initialdir $desktop \
3871                 -initialfile "Git [reponame].bat"]
3872         if {$fn != {}} {
3873                 if {[catch {
3874                                 set fd [open $fn w]
3875                                 set sh [exec cygpath \
3876                                         --windows \
3877                                         --absolute \
3878                                         /bin/sh]
3879                                 set me [exec cygpath \
3880                                         --unix \
3881                                         --absolute \
3882                                         $argv0]
3883                                 set gd [exec cygpath \
3884                                         --unix \
3885                                         --absolute \
3886                                         [gitdir]]
3887                                 set gw [exec cygpath \
3888                                         --windows \
3889                                         --absolute \
3890                                         [file dirname [gitdir]]]
3891                                 regsub -all ' $me "'\\''" me
3892                                 regsub -all ' $gd "'\\''" gd
3893                                 puts $fd "@ECHO Entering $gw"
3894                                 puts $fd "@ECHO Starting git-gui... please wait..."
3895                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3896                                 puts -nonewline $fd "GIT_DIR='$gd'"
3897                                 puts -nonewline $fd " '$me'"
3898                                 puts $fd "&\""
3899                                 close $fd
3900                         } err]} {
3901                         error_popup "Cannot write script:\n\n$err"
3902                 }
3903         }
3904 }
3905
3906 proc do_macosx_app {} {
3907         global argv0 env
3908
3909         set fn [tk_getSaveFile \
3910                 -parent . \
3911                 -title "[appname] ([reponame]): Create Desktop Icon" \
3912                 -initialdir [file join $env(HOME) Desktop] \
3913                 -initialfile "Git [reponame].app"]
3914         if {$fn != {}} {
3915                 if {[catch {
3916                                 set Contents [file join $fn Contents]
3917                                 set MacOS [file join $Contents MacOS]
3918                                 set exe [file join $MacOS git-gui]
3919
3920                                 file mkdir $MacOS
3921
3922                                 set fd [open [file join $Contents Info.plist] w]
3923                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3924 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3925 <plist version="1.0">
3926 <dict>
3927         <key>CFBundleDevelopmentRegion</key>
3928         <string>English</string>
3929         <key>CFBundleExecutable</key>
3930         <string>git-gui</string>
3931         <key>CFBundleIdentifier</key>
3932         <string>org.spearce.git-gui</string>
3933         <key>CFBundleInfoDictionaryVersion</key>
3934         <string>6.0</string>
3935         <key>CFBundlePackageType</key>
3936         <string>APPL</string>
3937         <key>CFBundleSignature</key>
3938         <string>????</string>
3939         <key>CFBundleVersion</key>
3940         <string>1.0</string>
3941         <key>NSPrincipalClass</key>
3942         <string>NSApplication</string>
3943 </dict>
3944 </plist>}
3945                                 close $fd
3946
3947                                 set fd [open $exe w]
3948                                 set gd [file normalize [gitdir]]
3949                                 set ep [file normalize [exec git --exec-path]]
3950                                 regsub -all ' $gd "'\\''" gd
3951                                 regsub -all ' $ep "'\\''" ep
3952                                 puts $fd "#!/bin/sh"
3953                                 foreach name [array names env] {
3954                                         if {[string match GIT_* $name]} {
3955                                                 regsub -all ' $env($name) "'\\''" v
3956                                                 puts $fd "export $name='$v'"
3957                                         }
3958                                 }
3959                                 puts $fd "export PATH='$ep':\$PATH"
3960                                 puts $fd "export GIT_DIR='$gd'"
3961                                 puts $fd "exec [file normalize $argv0]"
3962                                 close $fd
3963
3964                                 file attributes $exe -permissions u+x,g+x,o+x
3965                         } err]} {
3966                         error_popup "Cannot write icon:\n\n$err"
3967                 }
3968         }
3969 }
3970
3971 proc toggle_or_diff {w x y} {
3972         global file_states file_lists current_diff_path ui_index ui_workdir
3973         global last_clicked selected_paths
3974
3975         set pos [split [$w index @$x,$y] .]
3976         set lno [lindex $pos 0]
3977         set col [lindex $pos 1]
3978         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3979         if {$path eq {}} {
3980                 set last_clicked {}
3981                 return
3982         }
3983
3984         set last_clicked [list $w $lno]
3985         array unset selected_paths
3986         $ui_index tag remove in_sel 0.0 end
3987         $ui_workdir tag remove in_sel 0.0 end
3988
3989         if {$col == 0} {
3990                 if {$current_diff_path eq $path} {
3991                         set after {reshow_diff;}
3992                 } else {
3993                         set after {}
3994                 }
3995                 if {$w eq $ui_index} {
3996                         update_indexinfo \
3997                                 "Unstaging [short_path $path] from commit" \
3998                                 [list $path] \
3999                                 [concat $after {set ui_status_value {Ready.}}]
4000                 } elseif {$w eq $ui_workdir} {
4001                         update_index \
4002                                 "Adding [short_path $path]" \
4003                                 [list $path] \
4004                                 [concat $after {set ui_status_value {Ready.}}]
4005                 }
4006         } else {
4007                 show_diff $path $w $lno
4008         }
4009 }
4010
4011 proc add_one_to_selection {w x y} {
4012         global file_lists last_clicked selected_paths
4013
4014         set lno [lindex [split [$w index @$x,$y] .] 0]
4015         set path [lindex $file_lists($w) [expr {$lno - 1}]]
4016         if {$path eq {}} {
4017                 set last_clicked {}
4018                 return
4019         }
4020
4021         if {$last_clicked ne {}
4022                 && [lindex $last_clicked 0] ne $w} {
4023                 array unset selected_paths
4024                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
4025         }
4026
4027         set last_clicked [list $w $lno]
4028         if {[catch {set in_sel $selected_paths($path)}]} {
4029                 set in_sel 0
4030         }
4031         if {$in_sel} {
4032                 unset selected_paths($path)
4033                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
4034         } else {
4035                 set selected_paths($path) 1
4036                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
4037         }
4038 }
4039
4040 proc add_range_to_selection {w x y} {
4041         global file_lists last_clicked selected_paths
4042
4043         if {[lindex $last_clicked 0] ne $w} {
4044                 toggle_or_diff $w $x $y
4045                 return
4046         }
4047
4048         set lno [lindex [split [$w index @$x,$y] .] 0]
4049         set lc [lindex $last_clicked 1]
4050         if {$lc < $lno} {
4051                 set begin $lc
4052                 set end $lno
4053         } else {
4054                 set begin $lno
4055                 set end $lc
4056         }
4057
4058         foreach path [lrange $file_lists($w) \
4059                 [expr {$begin - 1}] \
4060                 [expr {$end - 1}]] {
4061                 set selected_paths($path) 1
4062         }
4063         $w tag add in_sel $begin.0 [expr {$end + 1}].0
4064 }
4065
4066 ######################################################################
4067 ##
4068 ## config defaults
4069
4070 set cursor_ptr arrow
4071 font create font_diff -family Courier -size 10
4072 font create font_ui
4073 catch {
4074         label .dummy
4075         eval font configure font_ui [font actual [.dummy cget -font]]
4076         destroy .dummy
4077 }
4078
4079 font create font_uibold
4080 font create font_diffbold
4081
4082 if {[is_Windows]} {
4083         set M1B Control
4084         set M1T Ctrl
4085 } elseif {[is_MacOSX]} {
4086         set M1B M1
4087         set M1T Cmd
4088 } else {
4089         set M1B M1
4090         set M1T M1
4091 }
4092
4093 proc apply_config {} {
4094         global repo_config font_descs
4095
4096         foreach option $font_descs {
4097                 set name [lindex $option 0]
4098                 set font [lindex $option 1]
4099                 if {[catch {
4100                         foreach {cn cv} $repo_config(gui.$name) {
4101                                 font configure $font $cn $cv
4102                         }
4103                         } err]} {
4104                         error_popup "Invalid font specified in gui.$name:\n\n$err"
4105                 }
4106                 foreach {cn cv} [font configure $font] {
4107                         font configure ${font}bold $cn $cv
4108                 }
4109                 font configure ${font}bold -weight bold
4110         }
4111 }
4112
4113 set default_config(gui.trustmtime) false
4114 set default_config(gui.pullsummary) true
4115 set default_config(gui.diffcontext) 5
4116 set default_config(gui.newbranchtemplate) {}
4117 set default_config(gui.fontui) [font configure font_ui]
4118 set default_config(gui.fontdiff) [font configure font_diff]
4119 set font_descs {
4120         {fontui   font_ui   {Main Font}}
4121         {fontdiff font_diff {Diff/Console Font}}
4122 }
4123 load_config 0
4124 apply_config
4125
4126 ######################################################################
4127 ##
4128 ## ui construction
4129
4130 # -- Menu Bar
4131 #
4132 menu .mbar -tearoff 0
4133 .mbar add cascade -label Repository -menu .mbar.repository
4134 .mbar add cascade -label Edit -menu .mbar.edit
4135 if {!$single_commit} {
4136         .mbar add cascade -label Branch -menu .mbar.branch
4137 }
4138 .mbar add cascade -label Commit -menu .mbar.commit
4139 if {!$single_commit} {
4140         .mbar add cascade -label Merge -menu .mbar.merge
4141         .mbar add cascade -label Fetch -menu .mbar.fetch
4142         .mbar add cascade -label Push -menu .mbar.push
4143 }
4144 . configure -menu .mbar
4145
4146 # -- Repository Menu
4147 #
4148 menu .mbar.repository
4149 .mbar.repository add command \
4150         -label {Visualize Current Branch} \
4151         -command {do_gitk {}} \
4152         -font font_ui
4153 .mbar.repository add command \
4154         -label {Visualize All Branches} \
4155         -command {do_gitk {--all}} \
4156         -font font_ui
4157 .mbar.repository add separator
4158
4159 if {!$single_commit} {
4160         .mbar.repository add command -label {Database Statistics} \
4161                 -command do_stats \
4162                 -font font_ui
4163
4164         .mbar.repository add command -label {Compress Database} \
4165                 -command do_gc \
4166                 -font font_ui
4167
4168         .mbar.repository add command -label {Verify Database} \
4169                 -command do_fsck_objects \
4170                 -font font_ui
4171
4172         .mbar.repository add separator
4173
4174         if {[is_Windows]} {
4175                 .mbar.repository add command \
4176                         -label {Create Desktop Icon} \
4177                         -command do_windows_shortcut \
4178                         -font font_ui
4179         } elseif {[is_MacOSX]} {
4180                 .mbar.repository add command \
4181                         -label {Create Desktop Icon} \
4182                         -command do_macosx_app \
4183                         -font font_ui
4184         }
4185 }
4186
4187 .mbar.repository add command -label Quit \
4188         -command do_quit \
4189         -accelerator $M1T-Q \
4190         -font font_ui
4191
4192 # -- Edit Menu
4193 #
4194 menu .mbar.edit
4195 .mbar.edit add command -label Undo \
4196         -command {catch {[focus] edit undo}} \
4197         -accelerator $M1T-Z \
4198         -font font_ui
4199 .mbar.edit add command -label Redo \
4200         -command {catch {[focus] edit redo}} \
4201         -accelerator $M1T-Y \
4202         -font font_ui
4203 .mbar.edit add separator
4204 .mbar.edit add command -label Cut \
4205         -command {catch {tk_textCut [focus]}} \
4206         -accelerator $M1T-X \
4207         -font font_ui
4208 .mbar.edit add command -label Copy \
4209         -command {catch {tk_textCopy [focus]}} \
4210         -accelerator $M1T-C \
4211         -font font_ui
4212 .mbar.edit add command -label Paste \
4213         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
4214         -accelerator $M1T-V \
4215         -font font_ui
4216 .mbar.edit add command -label Delete \
4217         -command {catch {[focus] delete sel.first sel.last}} \
4218         -accelerator Del \
4219         -font font_ui
4220 .mbar.edit add separator
4221 .mbar.edit add command -label {Select All} \
4222         -command {catch {[focus] tag add sel 0.0 end}} \
4223         -accelerator $M1T-A \
4224         -font font_ui
4225
4226 # -- Branch Menu
4227 #
4228 if {!$single_commit} {
4229         menu .mbar.branch
4230
4231         .mbar.branch add command -label {Create...} \
4232                 -command do_create_branch \
4233                 -accelerator $M1T-N \
4234                 -font font_ui
4235         lappend disable_on_lock [list .mbar.branch entryconf \
4236                 [.mbar.branch index last] -state]
4237
4238         .mbar.branch add command -label {Delete...} \
4239                 -command do_delete_branch \
4240                 -font font_ui
4241         lappend disable_on_lock [list .mbar.branch entryconf \
4242                 [.mbar.branch index last] -state]
4243 }
4244
4245 # -- Commit Menu
4246 #
4247 menu .mbar.commit
4248
4249 .mbar.commit add radiobutton \
4250         -label {New Commit} \
4251         -command do_select_commit_type \
4252         -variable selected_commit_type \
4253         -value new \
4254         -font font_ui
4255 lappend disable_on_lock \
4256         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4257
4258 .mbar.commit add radiobutton \
4259         -label {Amend Last Commit} \
4260         -command do_select_commit_type \
4261         -variable selected_commit_type \
4262         -value amend \
4263         -font font_ui
4264 lappend disable_on_lock \
4265         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4266
4267 .mbar.commit add separator
4268
4269 .mbar.commit add command -label Rescan \
4270         -command do_rescan \
4271         -accelerator F5 \
4272         -font font_ui
4273 lappend disable_on_lock \
4274         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4275
4276 .mbar.commit add command -label {Add To Commit} \
4277         -command do_add_selection \
4278         -font font_ui
4279 lappend disable_on_lock \
4280         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4281
4282 .mbar.commit add command -label {Add All To Commit} \
4283         -command do_add_all \
4284         -accelerator $M1T-I \
4285         -font font_ui
4286 lappend disable_on_lock \
4287         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4288
4289 .mbar.commit add command -label {Unstage From Commit} \
4290         -command do_unstage_selection \
4291         -font font_ui
4292 lappend disable_on_lock \
4293         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4294
4295 .mbar.commit add command -label {Revert Changes} \
4296         -command do_revert_selection \
4297         -font font_ui
4298 lappend disable_on_lock \
4299         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4300
4301 .mbar.commit add separator
4302
4303 .mbar.commit add command -label {Sign Off} \
4304         -command do_signoff \
4305         -accelerator $M1T-S \
4306         -font font_ui
4307
4308 .mbar.commit add command -label Commit \
4309         -command do_commit \
4310         -accelerator $M1T-Return \
4311         -font font_ui
4312 lappend disable_on_lock \
4313         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4314
4315 if {[is_MacOSX]} {
4316         # -- Apple Menu (Mac OS X only)
4317         #
4318         .mbar add cascade -label Apple -menu .mbar.apple
4319         menu .mbar.apple
4320
4321         .mbar.apple add command -label "About [appname]" \
4322                 -command do_about \
4323                 -font font_ui
4324         .mbar.apple add command -label "[appname] Options..." \
4325                 -command do_options \
4326                 -font font_ui
4327 } else {
4328         # -- Edit Menu
4329         #
4330         .mbar.edit add separator
4331         .mbar.edit add command -label {Options...} \
4332                 -command do_options \
4333                 -font font_ui
4334
4335         # -- Tools Menu
4336         #
4337         if {[file exists /usr/local/miga/lib/gui-miga]
4338                 && [file exists .pvcsrc]} {
4339         proc do_miga {} {
4340                 global ui_status_value
4341                 if {![lock_index update]} return
4342                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
4343                 set miga_fd [open "|$cmd" r]
4344                 fconfigure $miga_fd -blocking 0
4345                 fileevent $miga_fd readable [list miga_done $miga_fd]
4346                 set ui_status_value {Running miga...}
4347         }
4348         proc miga_done {fd} {
4349                 read $fd 512
4350                 if {[eof $fd]} {
4351                         close $fd
4352                         unlock_index
4353                         rescan [list set ui_status_value {Ready.}]
4354                 }
4355         }
4356         .mbar add cascade -label Tools -menu .mbar.tools
4357         menu .mbar.tools
4358         .mbar.tools add command -label "Migrate" \
4359                 -command do_miga \
4360                 -font font_ui
4361         lappend disable_on_lock \
4362                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
4363         }
4364
4365         # -- Help Menu
4366         #
4367         .mbar add cascade -label Help -menu .mbar.help
4368         menu .mbar.help
4369
4370         .mbar.help add command -label "About [appname]" \
4371                 -command do_about \
4372                 -font font_ui
4373 }
4374
4375
4376 # -- Branch Control
4377 #
4378 frame .branch \
4379         -borderwidth 1 \
4380         -relief sunken
4381 label .branch.l1 \
4382         -text {Current Branch:} \
4383         -anchor w \
4384         -justify left \
4385         -font font_ui
4386 label .branch.cb \
4387         -textvariable current_branch \
4388         -anchor w \
4389         -justify left \
4390         -font font_ui
4391 pack .branch.l1 -side left
4392 pack .branch.cb -side left -fill x
4393 pack .branch -side top -fill x
4394
4395 if {!$single_commit} {
4396         menu .mbar.merge
4397         .mbar.merge add command -label {Local Merge...} \
4398                 -command do_local_merge \
4399                 -font font_ui
4400         lappend disable_on_lock \
4401                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
4402         .mbar.merge add command -label {Abort Merge...} \
4403                 -command do_reset_hard \
4404                 -font font_ui
4405         lappend disable_on_lock \
4406                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
4407
4408
4409         menu .mbar.fetch
4410
4411         menu .mbar.push
4412         .mbar.push add command -label {Push...} \
4413                 -command do_push_anywhere \
4414                 -font font_ui
4415 }
4416
4417 # -- Main Window Layout
4418 #
4419 panedwindow .vpane -orient vertical
4420 panedwindow .vpane.files -orient horizontal
4421 .vpane add .vpane.files -sticky nsew -height 100 -width 200
4422 pack .vpane -anchor n -side top -fill both -expand 1
4423
4424 # -- Index File List
4425 #
4426 frame .vpane.files.index -height 100 -width 200
4427 label .vpane.files.index.title -text {Changes To Be Committed} \
4428         -background green \
4429         -font font_ui
4430 text $ui_index -background white -borderwidth 0 \
4431         -width 20 -height 10 \
4432         -wrap none \
4433         -font font_ui \
4434         -cursor $cursor_ptr \
4435         -xscrollcommand {.vpane.files.index.sx set} \
4436         -yscrollcommand {.vpane.files.index.sy set} \
4437         -state disabled
4438 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
4439 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
4440 pack .vpane.files.index.title -side top -fill x
4441 pack .vpane.files.index.sx -side bottom -fill x
4442 pack .vpane.files.index.sy -side right -fill y
4443 pack $ui_index -side left -fill both -expand 1
4444 .vpane.files add .vpane.files.index -sticky nsew
4445
4446 # -- Working Directory File List
4447 #
4448 frame .vpane.files.workdir -height 100 -width 200
4449 label .vpane.files.workdir.title -text {Changed But Not Updated} \
4450         -background red \
4451         -font font_ui
4452 text $ui_workdir -background white -borderwidth 0 \
4453         -width 20 -height 10 \
4454         -wrap none \
4455         -font font_ui \
4456         -cursor $cursor_ptr \
4457         -xscrollcommand {.vpane.files.workdir.sx set} \
4458         -yscrollcommand {.vpane.files.workdir.sy set} \
4459         -state disabled
4460 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
4461 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
4462 pack .vpane.files.workdir.title -side top -fill x
4463 pack .vpane.files.workdir.sx -side bottom -fill x
4464 pack .vpane.files.workdir.sy -side right -fill y
4465 pack $ui_workdir -side left -fill both -expand 1
4466 .vpane.files add .vpane.files.workdir -sticky nsew
4467
4468 foreach i [list $ui_index $ui_workdir] {
4469         $i tag conf in_diff -font font_uibold
4470         $i tag conf in_sel \
4471                 -background [$i cget -foreground] \
4472                 -foreground [$i cget -background]
4473 }
4474 unset i
4475
4476 # -- Diff and Commit Area
4477 #
4478 frame .vpane.lower -height 300 -width 400
4479 frame .vpane.lower.commarea
4480 frame .vpane.lower.diff -relief sunken -borderwidth 1
4481 pack .vpane.lower.commarea -side top -fill x
4482 pack .vpane.lower.diff -side bottom -fill both -expand 1
4483 .vpane add .vpane.lower -sticky nsew
4484
4485 # -- Commit Area Buttons
4486 #
4487 frame .vpane.lower.commarea.buttons
4488 label .vpane.lower.commarea.buttons.l -text {} \
4489         -anchor w \
4490         -justify left \
4491         -font font_ui
4492 pack .vpane.lower.commarea.buttons.l -side top -fill x
4493 pack .vpane.lower.commarea.buttons -side left -fill y
4494
4495 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
4496         -command do_rescan \
4497         -font font_ui
4498 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
4499 lappend disable_on_lock \
4500         {.vpane.lower.commarea.buttons.rescan conf -state}
4501
4502 button .vpane.lower.commarea.buttons.incall -text {Add All} \
4503         -command do_add_all \
4504         -font font_ui
4505 pack .vpane.lower.commarea.buttons.incall -side top -fill x
4506 lappend disable_on_lock \
4507         {.vpane.lower.commarea.buttons.incall conf -state}
4508
4509 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
4510         -command do_signoff \
4511         -font font_ui
4512 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
4513
4514 button .vpane.lower.commarea.buttons.commit -text {Commit} \
4515         -command do_commit \
4516         -font font_ui
4517 pack .vpane.lower.commarea.buttons.commit -side top -fill x
4518 lappend disable_on_lock \
4519         {.vpane.lower.commarea.buttons.commit conf -state}
4520
4521 # -- Commit Message Buffer
4522 #
4523 frame .vpane.lower.commarea.buffer
4524 frame .vpane.lower.commarea.buffer.header
4525 set ui_comm .vpane.lower.commarea.buffer.t
4526 set ui_coml .vpane.lower.commarea.buffer.header.l
4527 radiobutton .vpane.lower.commarea.buffer.header.new \
4528         -text {New Commit} \
4529         -command do_select_commit_type \
4530         -variable selected_commit_type \
4531         -value new \
4532         -font font_ui
4533 lappend disable_on_lock \
4534         [list .vpane.lower.commarea.buffer.header.new conf -state]
4535 radiobutton .vpane.lower.commarea.buffer.header.amend \
4536         -text {Amend Last Commit} \
4537         -command do_select_commit_type \
4538         -variable selected_commit_type \
4539         -value amend \
4540         -font font_ui
4541 lappend disable_on_lock \
4542         [list .vpane.lower.commarea.buffer.header.amend conf -state]
4543 label $ui_coml \
4544         -anchor w \
4545         -justify left \
4546         -font font_ui
4547 proc trace_commit_type {varname args} {
4548         global ui_coml commit_type
4549         switch -glob -- $commit_type {
4550         initial       {set txt {Initial Commit Message:}}
4551         amend         {set txt {Amended Commit Message:}}
4552         amend-initial {set txt {Amended Initial Commit Message:}}
4553         amend-merge   {set txt {Amended Merge Commit Message:}}
4554         merge         {set txt {Merge Commit Message:}}
4555         *             {set txt {Commit Message:}}
4556         }
4557         $ui_coml conf -text $txt
4558 }
4559 trace add variable commit_type write trace_commit_type
4560 pack $ui_coml -side left -fill x
4561 pack .vpane.lower.commarea.buffer.header.amend -side right
4562 pack .vpane.lower.commarea.buffer.header.new -side right
4563
4564 text $ui_comm -background white -borderwidth 1 \
4565         -undo true \
4566         -maxundo 20 \
4567         -autoseparators true \
4568         -relief sunken \
4569         -width 75 -height 9 -wrap none \
4570         -font font_diff \
4571         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
4572 scrollbar .vpane.lower.commarea.buffer.sby \
4573         -command [list $ui_comm yview]
4574 pack .vpane.lower.commarea.buffer.header -side top -fill x
4575 pack .vpane.lower.commarea.buffer.sby -side right -fill y
4576 pack $ui_comm -side left -fill y
4577 pack .vpane.lower.commarea.buffer -side left -fill y
4578
4579 # -- Commit Message Buffer Context Menu
4580 #
4581 set ctxm .vpane.lower.commarea.buffer.ctxm
4582 menu $ctxm -tearoff 0
4583 $ctxm add command \
4584         -label {Cut} \
4585         -font font_ui \
4586         -command {tk_textCut $ui_comm}
4587 $ctxm add command \
4588         -label {Copy} \
4589         -font font_ui \
4590         -command {tk_textCopy $ui_comm}
4591 $ctxm add command \
4592         -label {Paste} \
4593         -font font_ui \
4594         -command {tk_textPaste $ui_comm}
4595 $ctxm add command \
4596         -label {Delete} \
4597         -font font_ui \
4598         -command {$ui_comm delete sel.first sel.last}
4599 $ctxm add separator
4600 $ctxm add command \
4601         -label {Select All} \
4602         -font font_ui \
4603         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
4604 $ctxm add command \
4605         -label {Copy All} \
4606         -font font_ui \
4607         -command {
4608                 $ui_comm tag add sel 0.0 end
4609                 tk_textCopy $ui_comm
4610                 $ui_comm tag remove sel 0.0 end
4611         }
4612 $ctxm add separator
4613 $ctxm add command \
4614         -label {Sign Off} \
4615         -font font_ui \
4616         -command do_signoff
4617 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
4618
4619 # -- Diff Header
4620 #
4621 set current_diff_path {}
4622 set current_diff_side {}
4623 set diff_actions [list]
4624 proc trace_current_diff_path {varname args} {
4625         global current_diff_path diff_actions file_states
4626         if {$current_diff_path eq {}} {
4627                 set s {}
4628                 set f {}
4629                 set p {}
4630                 set o disabled
4631         } else {
4632                 set p $current_diff_path
4633                 set s [mapdesc [lindex $file_states($p) 0] $p]
4634                 set f {File:}
4635                 set p [escape_path $p]
4636                 set o normal
4637         }
4638
4639         .vpane.lower.diff.header.status configure -text $s
4640         .vpane.lower.diff.header.file configure -text $f
4641         .vpane.lower.diff.header.path configure -text $p
4642         foreach w $diff_actions {
4643                 uplevel #0 $w $o
4644         }
4645 }
4646 trace add variable current_diff_path write trace_current_diff_path
4647
4648 frame .vpane.lower.diff.header -background orange
4649 label .vpane.lower.diff.header.status \
4650         -background orange \
4651         -width $max_status_desc \
4652         -anchor w \
4653         -justify left \
4654         -font font_ui
4655 label .vpane.lower.diff.header.file \
4656         -background orange \
4657         -anchor w \
4658         -justify left \
4659         -font font_ui
4660 label .vpane.lower.diff.header.path \
4661         -background orange \
4662         -anchor w \
4663         -justify left \
4664         -font font_ui
4665 pack .vpane.lower.diff.header.status -side left
4666 pack .vpane.lower.diff.header.file -side left
4667 pack .vpane.lower.diff.header.path -fill x
4668 set ctxm .vpane.lower.diff.header.ctxm
4669 menu $ctxm -tearoff 0
4670 $ctxm add command \
4671         -label {Copy} \
4672         -font font_ui \
4673         -command {
4674                 clipboard clear
4675                 clipboard append \
4676                         -format STRING \
4677                         -type STRING \
4678                         -- $current_diff_path
4679         }
4680 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4681 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
4682
4683 # -- Diff Body
4684 #
4685 frame .vpane.lower.diff.body
4686 set ui_diff .vpane.lower.diff.body.t
4687 text $ui_diff -background white -borderwidth 0 \
4688         -width 80 -height 15 -wrap none \
4689         -font font_diff \
4690         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
4691         -yscrollcommand {.vpane.lower.diff.body.sby set} \
4692         -state disabled
4693 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
4694         -command [list $ui_diff xview]
4695 scrollbar .vpane.lower.diff.body.sby -orient vertical \
4696         -command [list $ui_diff yview]
4697 pack .vpane.lower.diff.body.sbx -side bottom -fill x
4698 pack .vpane.lower.diff.body.sby -side right -fill y
4699 pack $ui_diff -side left -fill both -expand 1
4700 pack .vpane.lower.diff.header -side top -fill x
4701 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
4702
4703 $ui_diff tag conf d_cr -elide true
4704 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
4705 $ui_diff tag conf d_+ -foreground {#00a000}
4706 $ui_diff tag conf d_- -foreground red
4707
4708 $ui_diff tag conf d_++ -foreground {#00a000}
4709 $ui_diff tag conf d_-- -foreground red
4710 $ui_diff tag conf d_+s \
4711         -foreground {#00a000} \
4712         -background {#e2effa}
4713 $ui_diff tag conf d_-s \
4714         -foreground red \
4715         -background {#e2effa}
4716 $ui_diff tag conf d_s+ \
4717         -foreground {#00a000} \
4718         -background ivory1
4719 $ui_diff tag conf d_s- \
4720         -foreground red \
4721         -background ivory1
4722
4723 $ui_diff tag conf d<<<<<<< \
4724         -foreground orange \
4725         -font font_diffbold
4726 $ui_diff tag conf d======= \
4727         -foreground orange \
4728         -font font_diffbold
4729 $ui_diff tag conf d>>>>>>> \
4730         -foreground orange \
4731         -font font_diffbold
4732
4733 $ui_diff tag raise sel
4734
4735 # -- Diff Body Context Menu
4736 #
4737 set ctxm .vpane.lower.diff.body.ctxm
4738 menu $ctxm -tearoff 0
4739 $ctxm add command \
4740         -label {Refresh} \
4741         -font font_ui \
4742         -command reshow_diff
4743 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4744 $ctxm add command \
4745         -label {Copy} \
4746         -font font_ui \
4747         -command {tk_textCopy $ui_diff}
4748 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4749 $ctxm add command \
4750         -label {Select All} \
4751         -font font_ui \
4752         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
4753 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4754 $ctxm add command \
4755         -label {Copy All} \
4756         -font font_ui \
4757         -command {
4758                 $ui_diff tag add sel 0.0 end
4759                 tk_textCopy $ui_diff
4760                 $ui_diff tag remove sel 0.0 end
4761         }
4762 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4763 $ctxm add separator
4764 $ctxm add command \
4765         -label {Apply/Reverse Hunk} \
4766         -font font_ui \
4767         -command {apply_hunk $cursorX $cursorY}
4768 set ui_diff_applyhunk [$ctxm index last]
4769 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
4770 $ctxm add separator
4771 $ctxm add command \
4772         -label {Decrease Font Size} \
4773         -font font_ui \
4774         -command {incr_font_size font_diff -1}
4775 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4776 $ctxm add command \
4777         -label {Increase Font Size} \
4778         -font font_ui \
4779         -command {incr_font_size font_diff 1}
4780 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4781 $ctxm add separator
4782 $ctxm add command \
4783         -label {Show Less Context} \
4784         -font font_ui \
4785         -command {if {$repo_config(gui.diffcontext) >= 2} {
4786                 incr repo_config(gui.diffcontext) -1
4787                 reshow_diff
4788         }}
4789 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4790 $ctxm add command \
4791         -label {Show More Context} \
4792         -font font_ui \
4793         -command {
4794                 incr repo_config(gui.diffcontext)
4795                 reshow_diff
4796         }
4797 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4798 $ctxm add separator
4799 $ctxm add command -label {Options...} \
4800         -font font_ui \
4801         -command do_options
4802 bind_button3 $ui_diff "
4803         set cursorX %x
4804         set cursorY %y
4805         if {\$ui_index eq \$current_diff_side} {
4806                 $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
4807         } else {
4808                 $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
4809         }
4810         tk_popup $ctxm %X %Y
4811 "
4812 unset ui_diff_applyhunk
4813
4814 # -- Status Bar
4815 #
4816 set ui_status_value {Initializing...}
4817 label .status -textvariable ui_status_value \
4818         -anchor w \
4819         -justify left \
4820         -borderwidth 1 \
4821         -relief sunken \
4822         -font font_ui
4823 pack .status -anchor w -side bottom -fill x
4824
4825 # -- Load geometry
4826 #
4827 catch {
4828 set gm $repo_config(gui.geometry)
4829 wm geometry . [lindex $gm 0]
4830 .vpane sash place 0 \
4831         [lindex [.vpane sash coord 0] 0] \
4832         [lindex $gm 1]
4833 .vpane.files sash place 0 \
4834         [lindex $gm 2] \
4835         [lindex [.vpane.files sash coord 0] 1]
4836 unset gm
4837 }
4838
4839 # -- Key Bindings
4840 #
4841 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
4842 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
4843 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
4844 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
4845 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
4846 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
4847 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
4848 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
4849 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
4850 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4851 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4852
4853 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
4854 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
4855 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
4856 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
4857 bind $ui_diff <$M1B-Key-v> {break}
4858 bind $ui_diff <$M1B-Key-V> {break}
4859 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4860 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4861 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
4862 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
4863 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
4864 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
4865 bind $ui_diff <Button-1>   {focus %W}
4866
4867 if {!$single_commit} {
4868         bind . <$M1B-Key-n> do_create_branch
4869         bind . <$M1B-Key-N> do_create_branch
4870 }
4871
4872 bind .   <Destroy> do_quit
4873 bind all <Key-F5> do_rescan
4874 bind all <$M1B-Key-r> do_rescan
4875 bind all <$M1B-Key-R> do_rescan
4876 bind .   <$M1B-Key-s> do_signoff
4877 bind .   <$M1B-Key-S> do_signoff
4878 bind .   <$M1B-Key-i> do_add_all
4879 bind .   <$M1B-Key-I> do_add_all
4880 bind .   <$M1B-Key-Return> do_commit
4881 bind all <$M1B-Key-q> do_quit
4882 bind all <$M1B-Key-Q> do_quit
4883 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
4884 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4885 foreach i [list $ui_index $ui_workdir] {
4886         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4887         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4888         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4889 }
4890 unset i
4891
4892 set file_lists($ui_index) [list]
4893 set file_lists($ui_workdir) [list]
4894
4895 set HEAD {}
4896 set PARENT {}
4897 set MERGE_HEAD [list]
4898 set commit_type {}
4899 set empty_tree {}
4900 set current_branch {}
4901 set current_diff_path {}
4902 set selected_commit_type new
4903
4904 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4905 focus -force $ui_comm
4906
4907 # -- Warn the user about environmental problems.  Cygwin's Tcl
4908 #    does *not* pass its env array onto any processes it spawns.
4909 #    This means that git processes get none of our environment.
4910 #
4911 if {[is_Windows]} {
4912         set ignored_env 0
4913         set suggest_user {}
4914         set msg "Possible environment issues exist.
4915
4916 The following environment variables are probably
4917 going to be ignored by any Git subprocess run
4918 by [appname]:
4919
4920 "
4921         foreach name [array names env] {
4922                 switch -regexp -- $name {
4923                 {^GIT_INDEX_FILE$} -
4924                 {^GIT_OBJECT_DIRECTORY$} -
4925                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4926                 {^GIT_DIFF_OPTS$} -
4927                 {^GIT_EXTERNAL_DIFF$} -
4928                 {^GIT_PAGER$} -
4929                 {^GIT_TRACE$} -
4930                 {^GIT_CONFIG$} -
4931                 {^GIT_CONFIG_LOCAL$} -
4932                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4933                         append msg " - $name\n"
4934                         incr ignored_env
4935                 }
4936                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4937                         append msg " - $name\n"
4938                         incr ignored_env
4939                         set suggest_user $name
4940                 }
4941                 }
4942         }
4943         if {$ignored_env > 0} {
4944                 append msg "
4945 This is due to a known issue with the
4946 Tcl binary distributed by Cygwin."
4947
4948                 if {$suggest_user ne {}} {
4949                         append msg "
4950
4951 A good replacement for $suggest_user
4952 is placing values for the user.name and
4953 user.email settings into your personal
4954 ~/.gitconfig file.
4955 "
4956                 }
4957                 warn_popup $msg
4958         }
4959         unset ignored_env msg suggest_user name
4960 }
4961
4962 # -- Only initialize complex UI if we are going to stay running.
4963 #
4964 if {!$single_commit} {
4965         load_all_remotes
4966         load_all_heads
4967
4968         populate_branch_menu
4969         populate_fetch_menu
4970         populate_push_menu
4971 }
4972
4973 # -- Only suggest a gc run if we are going to stay running.
4974 #
4975 if {!$single_commit} {
4976         set object_limit 2000
4977         if {[is_Windows]} {set object_limit 200}
4978         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4979         if {$objects_current >= $object_limit} {
4980                 if {[ask_popup \
4981                         "This repository currently has $objects_current loose objects.
4982
4983 To maintain optimal performance it is strongly
4984 recommended that you compress the database
4985 when more than $object_limit loose objects exist.
4986
4987 Compress the database now?"] eq yes} {
4988                         do_gc
4989                 }
4990         }
4991         unset object_limit _junk objects_current
4992 }
4993
4994 lock_index begin-read
4995 after 1 do_rescan