?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-branch.txt: compare --contains, --merged and --no-merged
[git/gitweb.git] / git-svn.perl
blobb864b54a4440537900cab47e71ee93bd01d72d28
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 'blame' => [ \&Git::SVN::Log::cmd_blame,
190 "Show what revision and author last modified each line of a file",
191 {} ],
192 );
193
194 my $cmd;
195 for (my $i = 0; $i < @ARGV; $i++) {
196 if (defined $cmd{$ARGV[$i]}) {
197 $cmd = $ARGV[$i];
198 splice @ARGV, $i, 1;
199 last;
200 }
201 };
202
203 # make sure we're always running at the top-level working directory
204 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
205 unless (-d $ENV{GIT_DIR}) {
206 if ($git_dir_user_set) {
207 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
208 "but it is not a directory\n";
209 }
210 my $git_dir = delete $ENV{GIT_DIR};
211 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
212 unless (length $cdup) {
213 die "Already at toplevel, but $git_dir ",
214 "not found '$cdup'\n";
215 }
216 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
217 unless (-d $git_dir) {
218 die "$git_dir still not found after going to ",
219 "'$cdup'\n";
220 }
221 $ENV{GIT_DIR} = $git_dir;
222 }
223 }
224
225 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
226
227 read_repo_config(\%opts);
228 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
229 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
230 'minimize-connections' => \$Git::SVN::Migration::_minimize,
231 'id|i=s' => \$Git::SVN::default_ref_id,
232 'svn-remote|remote|R=s' => sub {
233 $Git::SVN::no_reuse_existing = 1;
234 $Git::SVN::default_repo_id = $_[1] });
235 exit 1 if (!$rv && $cmd && $cmd ne 'log');
236
237 usage(0) if $_help;
238 version() if $_version;
239 usage(1) unless defined $cmd;
240 load_authors() if $_authors;
241
242 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
243 Git::SVN::Migration::migration_check();
244 }
245 Git::SVN::init_vars();
246 eval {
247 Git::SVN::verify_remotes_sanity();
248 $cmd{$cmd}->[0]->(@ARGV);
249 };
250 fatal $@ if $@;
251 post_fetch_checkout();
252 exit 0;
253
254 ####################### primary functions ######################
255 sub usage {
256 my $exit = shift || 0;
257 my $fd = $exit ? \*STDERR : \*STDOUT;
258 print $fd <<"";
259 git-svn - bidirectional operations between a single Subversion tree and git
260 Usage: $0 <command> [options] [arguments]\n
261
262 print $fd "Available commands:\n" unless $cmd;
263
264 foreach (sort keys %cmd) {
265 next if $cmd && $cmd ne $_;
266 next if /^multi-/; # don't show deprecated commands
267 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
268 foreach (sort keys %{$cmd{$_}->[2]}) {
269 # mixed-case options are for .git/config only
270 next if /[A-Z]/ && /^[a-z]+$/i;
271 # prints out arguments as they should be passed:
272 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
273 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
274 "--$_" : "-$_" }
275 split /\|/,$_)," $x\n";
276 }
277 }
278 print $fd <<"";
279 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
280 arbitrary identifier if you're tracking multiple SVN branches/repositories in
281 one git repository and want to keep them separate. See git-svn(1) for more
282 information.
283
284 exit $exit;
285 }
286
287 sub version {
288 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
289 exit 0;
290 }
291
292 sub do_git_init_db {
293 unless (-d $ENV{GIT_DIR}) {
294 my @init_db = ('init');
295 push @init_db, "--template=$_template" if defined $_template;
296 if (defined $_shared) {
297 if ($_shared =~ /[a-z]/) {
298 push @init_db, "--shared=$_shared";
299 } else {
300 push @init_db, "--shared";
301 }
302 }
303 command_noisy(@init_db);
304 }
305 my $set;
306 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
307 foreach my $i (keys %icv) {
308 die "'$set' and '$i' cannot both be set\n" if $set;
309 next unless defined $icv{$i};
310 command_noisy('config', "$pfx.$i", $icv{$i});
311 $set = $i;
312 }
313 }
314
315 sub init_subdir {
316 my $repo_path = shift or return;
317 mkpath([$repo_path]) unless -d $repo_path;
318 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
319 $ENV{GIT_DIR} = '.git';
320 }
321
322 sub cmd_clone {
323 my ($url, $path) = @_;
324 if (!defined $path &&
325 (defined $_trunk || defined $_branches || defined $_tags ||
326 defined $_stdlayout) &&
327 $url !~ m#^[a-z\+]+://#) {
328 $path = $url;
329 }
330 $path = basename($url) if !defined $path || !length $path;
331 cmd_init($url, $path);
332 Git::SVN::fetch_all($Git::SVN::default_repo_id);
333 }
334
335 sub cmd_init {
336 if (defined $_stdlayout) {
337 $_trunk = 'trunk' if (!defined $_trunk);
338 $_tags = 'tags' if (!defined $_tags);
339 $_branches = 'branches' if (!defined $_branches);
340 }
341 if (defined $_trunk || defined $_branches || defined $_tags) {
342 return cmd_multi_init(@_);
343 }
344 my $url = shift or die "SVN repository location required ",
345 "as a command-line argument\n";
346 init_subdir(@_);
347 do_git_init_db();
348
349 Git::SVN->init($url);
350 }
351
352 sub cmd_fetch {
353 if (grep /^\d+=./, @_) {
354 die "'<rev>=<commit>' fetch arguments are ",
355 "no longer supported.\n";
356 }
357 my ($remote) = @_;
358 if (@_ > 1) {
359 die "Usage: $0 fetch [--all] [svn-remote]\n";
360 }
361 $remote ||= $Git::SVN::default_repo_id;
362 if ($_fetch_all) {
363 cmd_multi_fetch();
364 } else {
365 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
366 }
367 }
368
369 sub cmd_set_tree {
370 my (@commits) = @_;
371 if ($_stdin || !@commits) {
372 print "Reading from stdin...\n";
373 @commits = ();
374 while (<STDIN>) {
375 if (/\b($sha1_short)\b/o) {
376 unshift @commits, $1;
377 }
378 }
379 }
380 my @revs;
381 foreach my $c (@commits) {
382 my @tmp = command('rev-parse',$c);
383 if (scalar @tmp == 1) {
384 push @revs, $tmp[0];
385 } elsif (scalar @tmp > 1) {
386 push @revs, reverse(command('rev-list',@tmp));
387 } else {
388 fatal "Failed to rev-parse $c";
389 }
390 }
391 my $gs = Git::SVN->new;
392 my ($r_last, $cmt_last) = $gs->last_rev_commit;
393 $gs->fetch;
394 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
395 fatal "There are new revisions that were fetched ",
396 "and need to be merged (or acknowledged) ",
397 "before committing.\nlast rev: $r_last\n",
398 " current: $gs->{last_rev}";
399 }
400 $gs->set_tree($_) foreach @revs;
401 print "Done committing ",scalar @revs," revisions to SVN\n";
402 unlink $gs->{index};
403 }
404
405 sub cmd_dcommit {
406 my $head = shift;
407 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
408 'Cannot dcommit with a dirty index. Commit your changes first, '
409 . "or stash them with `git stash'.\n";
410 $head ||= 'HEAD';
411 my @refs;
412 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
413 print "Committing to $url ...\n";
414 unless ($gs) {
415 die "Unable to determine upstream SVN information from ",
416 "$head history\n";
417 }
418 my $last_rev;
419 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
420 if ($_no_rebase && scalar(@$linear_refs) > 1) {
421 warn "Attempting to commit more than one change while ",
422 "--no-rebase is enabled.\n",
423 "If these changes depend on each other, re-running ",
424 "without --no-rebase may be required."
425 }
426 while (1) {
427 my $d = shift @$linear_refs or last;
428 unless (defined $last_rev) {
429 (undef, $last_rev, undef) = cmt_metadata("$d~1");
430 unless (defined $last_rev) {
431 fatal "Unable to extract revision information ",
432 "from commit $d~1";
433 }
434 }
435 if ($_dry_run) {
436 print "diff-tree $d~1 $d\n";
437 } else {
438 my $cmt_rev;
439 my %ed_opts = ( r => $last_rev,
440 log => get_commit_entry($d)->{log},
441 ra => Git::SVN::Ra->new($gs->full_url),
442 config => SVN::Core::config_get_config(
443 $Git::SVN::Ra::config_dir
444 ),
445 tree_a => "$d~1",
446 tree_b => $d,
447 editor_cb => sub {
448 print "Committed r$_[0]\n";
449 $cmt_rev = $_[0];
450 },
451 svn_path => '');
452 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
453 print "No changes\n$d~1 == $d\n";
454 } elsif ($parents->{$d} && @{$parents->{$d}}) {
455 $gs->{inject_parents_dcommit}->{$cmt_rev} =
456 $parents->{$d};
457 }
458 $_fetch_all ? $gs->fetch_all : $gs->fetch;
459 $last_rev = $cmt_rev;
460 next if $_no_rebase;
461
462 # we always want to rebase against the current HEAD,
463 # not any head that was passed to us
464 my @diff = command('diff-tree', $d,
465 $gs->refname, '--');
466 my @finish;
467 if (@diff) {
468 @finish = rebase_cmd();
469 print STDERR "W: $d and ", $gs->refname,
470 " differ, using @finish:\n",
471 join("\n", @diff), "\n";
472 } else {
473 print "No changes between current HEAD and ",
474 $gs->refname,
475 "\nResetting to the latest ",
476 $gs->refname, "\n";
477 @finish = qw/reset --mixed/;
478 }
479 command_noisy(@finish, $gs->refname);
480 if (@diff) {
481 @refs = ();
482 my ($url_, $rev_, $uuid_, $gs_) =
483 working_head_info($head, \@refs);
484 my ($linear_refs_, $parents_) =
485 linearize_history($gs_, \@refs);
486 if (scalar(@$linear_refs) !=
487 scalar(@$linear_refs_)) {
488 fatal "# of revisions changed ",
489 "\nbefore:\n",
490 join("\n", @$linear_refs),
491 "\n\nafter:\n",
492 join("\n", @$linear_refs_), "\n",
493 'If you are attempting to commit ',
494 "merges, try running:\n\t",
495 'git rebase --interactive',
496 '--preserve-merges ',
497 $gs->refname,
498 "\nBefore dcommitting";
499 }
500 if ($url_ ne $url) {
501 fatal "URL mismatch after rebase: ",
502 "$url_ != $url";
503 }
504 if ($uuid_ ne $uuid) {
505 fatal "uuid mismatch after rebase: ",
506 "$uuid_ != $uuid";
507 }
508 # remap parents
509 my (%p, @l, $i);
510 for ($i = 0; $i < scalar @$linear_refs; $i++) {
511 my $new = $linear_refs_->[$i] or next;
512 $p{$new} =
513 $parents->{$linear_refs->[$i]};
514 push @l, $new;
515 }
516 $parents = \%p;
517 $linear_refs = \@l;
518 }
519 }
520 }
521 unlink $gs->{index};
522 }
523
524 sub cmd_find_rev {
525 my $revision_or_hash = shift or die "SVN or git revision required ",
526 "as a command-line argument\n";
527 my $result;
528 if ($revision_or_hash =~ /^r\d+$/) {
529 my $head = shift;
530 $head ||= 'HEAD';
531 my @refs;
532 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
533 unless ($gs) {
534 die "Unable to determine upstream SVN information from ",
535 "$head history\n";
536 }
537 my $desired_revision = substr($revision_or_hash, 1);
538 $result = $gs->rev_map_get($desired_revision);
539 } else {
540 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
541 $result = $rev;
542 }
543 print "$result\n" if $result;
544 }
545
546 sub cmd_rebase {
547 command_noisy(qw/update-index --refresh/);
548 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
549 unless ($gs) {
550 die "Unable to determine upstream SVN information from ",
551 "working tree history\n";
552 }
553 if (command(qw/diff-index HEAD --/)) {
554 print STDERR "Cannot rebase with uncommited changes:\n";
555 command_noisy('status');
556 exit 1;
557 }
558 unless ($_local) {
559 # rebase will checkout for us, so no need to do it explicitly
560 $_no_checkout = 'true';
561 $_fetch_all ? $gs->fetch_all : $gs->fetch;
562 }
563 command_noisy(rebase_cmd(), $gs->refname);
564 }
565
566 sub cmd_show_ignore {
567 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
568 $gs ||= Git::SVN->new;
569 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
570 $gs->prop_walk($gs->{path}, $r, sub {
571 my ($gs, $path, $props) = @_;
572 print STDOUT "\n# $path\n";
573 my $s = $props->{'svn:ignore'} or return;
574 $s =~ s/[\r\n]+/\n/g;
575 chomp $s;
576 $s =~ s#^#$path#gm;
577 print STDOUT "$s\n";
578 });
579 }
580
581 sub cmd_show_externals {
582 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
583 $gs ||= Git::SVN->new;
584 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
585 $gs->prop_walk($gs->{path}, $r, sub {
586 my ($gs, $path, $props) = @_;
587 print STDOUT "\n# $path\n";
588 my $s = $props->{'svn:externals'} or return;
589 $s =~ s/[\r\n]+/\n/g;
590 chomp $s;
591 $s =~ s#^#$path#gm;
592 print STDOUT "$s\n";
593 });
594 }
595
596 sub cmd_create_ignore {
597 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
598 $gs ||= Git::SVN->new;
599 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
600 $gs->prop_walk($gs->{path}, $r, sub {
601 my ($gs, $path, $props) = @_;
602 # $path is of the form /path/to/dir/
603 my $ignore = '.' . $path . '.gitignore';
604 my $s = $props->{'svn:ignore'} or return;
605 open(GITIGNORE, '>', $ignore)
606 or fatal("Failed to open `$ignore' for writing: $!");
607 $s =~ s/[\r\n]+/\n/g;
608 chomp $s;
609 # Prefix all patterns so that the ignore doesn't apply
610 # to sub-directories.
611 $s =~ s#^#/#gm;
612 print GITIGNORE "$s\n";
613 close(GITIGNORE)
614 or fatal("Failed to close `$ignore': $!");
615 command_noisy('add', $ignore);
616 });
617 }
618
619 sub canonicalize_path {
620 my ($path) = @_;
621 my $dot_slash_added = 0;
622 if (substr($path, 0, 1) ne "/") {
623 $path = "./" . $path;
624 $dot_slash_added = 1;
625 }
626 # File::Spec->canonpath doesn't collapse x/../y into y (for a
627 # good reason), so let's do this manually.
628 $path =~ s#/+#/#g;
629 $path =~ s#/\.(?:/|$)#/#g;
630 $path =~ s#/[^/]+/\.\.##g;
631 $path =~ s#/$##g;
632 $path =~ s#^\./## if $dot_slash_added;
633 return $path;
634 }
635
636 # get_svnprops(PATH)
637 # ------------------
638 # Helper for cmd_propget and cmd_proplist below.
639 sub get_svnprops {
640 my $path = shift;
641 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
642 $gs ||= Git::SVN->new;
643
644 # prefix THE PATH by the sub-directory from which the user
645 # invoked us.
646 $path = $cmd_dir_prefix . $path;
647 fatal("No such file or directory: $path") unless -e $path;
648 my $is_dir = -d $path ? 1 : 0;
649 $path = $gs->{path} . '/' . $path;
650
651 # canonicalize the path (otherwise libsvn will abort or fail to
652 # find the file)
653 $path = canonicalize_path($path);
654
655 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
656 my $props;
657 if ($is_dir) {
658 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
659 }
660 else {
661 (undef, $props) = $gs->ra->get_file($path, $r, undef);
662 }
663 return $props;
664 }
665
666 # cmd_propget (PROP, PATH)
667 # ------------------------
668 # Print the SVN property PROP for PATH.
669 sub cmd_propget {
670 my ($prop, $path) = @_;
671 $path = '.' if not defined $path;
672 usage(1) if not defined $prop;
673 my $props = get_svnprops($path);
674 if (not defined $props->{$prop}) {
675 fatal("`$path' does not have a `$prop' SVN property.");
676 }
677 print $props->{$prop} . "\n";
678 }
679
680 # cmd_proplist (PATH)
681 # -------------------
682 # Print the list of SVN properties for PATH.
683 sub cmd_proplist {
684 my $path = shift;
685 $path = '.' if not defined $path;
686 my $props = get_svnprops($path);
687 print "Properties on '$path':\n";
688 foreach (sort keys %{$props}) {
689 print " $_\n";
690 }
691 }
692
693 sub cmd_multi_init {
694 my $url = shift;
695 unless (defined $_trunk || defined $_branches || defined $_tags) {
696 usage(1);
697 }
698
699 # there are currently some bugs that prevent multi-init/multi-fetch
700 # setups from working well without this.
701 $Git::SVN::_minimize_url = 1;
702
703 $_prefix = '' unless defined $_prefix;
704 if (defined $url) {
705 $url =~ s#/+$##;
706 init_subdir(@_);
707 }
708 do_git_init_db();
709 if (defined $_trunk) {
710 my $trunk_ref = $_prefix . 'trunk';
711 # try both old-style and new-style lookups:
712 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
713 unless ($gs_trunk) {
714 my ($trunk_url, $trunk_path) =
715 complete_svn_url($url, $_trunk);
716 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
717 undef, $trunk_ref);
718 }
719 }
720 return unless defined $_branches || defined $_tags;
721 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
722 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
723 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
724 }
725
726 sub cmd_multi_fetch {
727 my $remotes = Git::SVN::read_all_remotes();
728 foreach my $repo_id (sort keys %$remotes) {
729 if ($remotes->{$repo_id}->{url}) {
730 Git::SVN::fetch_all($repo_id, $remotes);
731 }
732 }
733 }
734
735 # this command is special because it requires no metadata
736 sub cmd_commit_diff {
737 my ($ta, $tb, $url) = @_;
738 my $usage = "Usage: $0 commit-diff -r<revision> ".
739 "<tree-ish> <tree-ish> [<URL>]";
740 fatal($usage) if (!defined $ta || !defined $tb);
741 my $svn_path;
742 if (!defined $url) {
743 my $gs = eval { Git::SVN->new };
744 if (!$gs) {
745 fatal("Needed URL or usable git-svn --id in ",
746 "the command-line\n", $usage);
747 }
748 $url = $gs->{url};
749 $svn_path = $gs->{path};
750 }
751 unless (defined $_revision) {
752 fatal("-r|--revision is a required argument\n", $usage);
753 }
754 if (defined $_message && defined $_file) {
755 fatal("Both --message/-m and --file/-F specified ",
756 "for the commit message.\n",
757 "I have no idea what you mean");
758 }
759 if (defined $_file) {
760 $_message = file_to_s($_file);
761 } else {
762 $_message ||= get_commit_entry($tb)->{log};
763 }
764 my $ra ||= Git::SVN::Ra->new($url);
765 $svn_path ||= $ra->{svn_path};
766 my $r = $_revision;
767 if ($r eq 'HEAD') {
768 $r = $ra->get_latest_revnum;
769 } elsif ($r !~ /^\d+$/) {
770 die "revision argument: $r not understood by git-svn\n";
771 }
772 my %ed_opts = ( r => $r,
773 log => $_message,
774 ra => $ra,
775 tree_a => $ta,
776 tree_b => $tb,
777 editor_cb => sub { print "Committed r$_[0]\n" },
778 svn_path => $svn_path );
779 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
780 print "No changes\n$ta == $tb\n";
781 }
782 }
783
784 sub cmd_info {
785 my $path = canonicalize_path(shift or ".");
786 unless (scalar(@_) == 0) {
787 die "Too many arguments specified\n";
788 }
789
790 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
791
792 if (!$file_type && !$diff_status) {
793 print STDERR "$path: (Not a versioned resource)\n\n";
794 return;
795 }
796
797 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
798 unless ($gs) {
799 die "Unable to determine upstream SVN information from ",
800 "working tree history\n";
801 }
802 my $full_url = $url . ($path eq "." ? "" : "/$path");
803
804 if ($_url) {
805 print $full_url, "\n";
806 return;
807 }
808
809 my $result = "Path: $path\n";
810 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
811 $result .= "URL: " . $full_url . "\n";
812
813 eval {
814 my $repos_root = $gs->repos_root;
815 Git::SVN::remove_username($repos_root);
816 $result .= "Repository Root: $repos_root\n";
817 };
818 if ($@) {
819 $result .= "Repository Root: (offline)\n";
820 }
821 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
822 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
823
824 $result .= "Node Kind: " .
825 ($file_type eq "dir" ? "directory" : "file") . "\n";
826
827 my $schedule = $diff_status eq "A"
828 ? "add"
829 : ($diff_status eq "D" ? "delete" : "normal");
830 $result .= "Schedule: $schedule\n";
831
832 if ($diff_status eq "A") {
833 print $result, "\n";
834 return;
835 }
836
837 my ($lc_author, $lc_rev, $lc_date_utc);
838 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
839 my $log = command_output_pipe(@args);
840 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
841 while (<$log>) {
842 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
843 $lc_author = $1;
844 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
845 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
846 (undef, $lc_rev, undef) = ::extract_metadata($1);
847 }
848 }
849 close $log;
850
851 Git::SVN::Log::set_local_timezone();
852
853 $result .= "Last Changed Author: $lc_author\n";
854 $result .= "Last Changed Rev: $lc_rev\n";
855 $result .= "Last Changed Date: " .
856 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
857
858 if ($file_type ne "dir") {
859 my $text_last_updated_date =
860 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
861 $result .=
862 "Text Last Updated: " .
863 Git::SVN::Log::format_svn_date($text_last_updated_date) .
864 "\n";
865 my $checksum;
866 if ($diff_status eq "D") {
867 my ($fh, $ctx) =
868 command_output_pipe(qw(cat-file blob), "HEAD:$path");
869 if ($file_type eq "link") {
870 my $file_name = <$fh>;
871 $checksum = md5sum("link $file_name");
872 } else {
873 $checksum = md5sum($fh);
874 }
875 command_close_pipe($fh, $ctx);
876 } elsif ($file_type eq "link") {
877 my $file_name =
878 command(qw(cat-file blob), "HEAD:$path");
879 $checksum =
880 md5sum("link " . $file_name);
881 } else {
882 open FILE, "<", $path or die $!;
883 $checksum = md5sum(\*FILE);
884 close FILE or die $!;
885 }
886 $result .= "Checksum: " . $checksum . "\n";
887 }
888
889 print $result, "\n";
890 }
891
892 ########################### utility functions #########################
893
894 sub rebase_cmd {
895 my @cmd = qw/rebase/;
896 push @cmd, '-v' if $_verbose;
897 push @cmd, qw/--merge/ if $_merge;
898 push @cmd, "--strategy=$_strategy" if $_strategy;
899 @cmd;
900 }
901
902 sub post_fetch_checkout {
903 return if $_no_checkout;
904 my $gs = $Git::SVN::_head or return;
905 return if verify_ref('refs/heads/master^0');
906
907 my $valid_head = verify_ref('HEAD^0');
908 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
909 return if ($valid_head || !verify_ref('HEAD^0'));
910
911 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
912 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
913 return if -f $index;
914
915 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
916 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
917 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
918 print STDERR "Checked out HEAD:\n ",
919 $gs->full_url, " r", $gs->last_rev, "\n";
920 }
921
922 sub complete_svn_url {
923 my ($url, $path) = @_;
924 $path =~ s#/+$##;
925 if ($path !~ m#^[a-z\+]+://#) {
926 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
927 fatal("E: '$path' is not a complete URL ",
928 "and a separate URL is not specified");
929 }
930 return ($url, $path);
931 }
932 return ($path, '');
933 }
934
935 sub complete_url_ls_init {
936 my ($ra, $repo_path, $switch, $pfx) = @_;
937 unless ($repo_path) {
938 print STDERR "W: $switch not specified\n";
939 return;
940 }
941 $repo_path =~ s#/+$##;
942 if ($repo_path =~ m#^[a-z\+]+://#) {
943 $ra = Git::SVN::Ra->new($repo_path);
944 $repo_path = '';
945 } else {
946 $repo_path =~ s#^/+##;
947 unless ($ra) {
948 fatal("E: '$repo_path' is not a complete URL ",
949 "and a separate URL is not specified");
950 }
951 }
952 my $url = $ra->{url};
953 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
954 my $k = "svn-remote.$gs->{repo_id}.url";
955 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
956 if ($orig_url && ($orig_url ne $gs->{url})) {
957 die "$k already set: $orig_url\n",
958 "wanted to set to: $gs->{url}\n";
959 }
960 command_oneline('config', $k, $gs->{url}) unless $orig_url;
961 my $remote_path = "$ra->{svn_path}/$repo_path";
962 $remote_path =~ s#/+#/#g;
963 $remote_path =~ s#^/##g;
964 $remote_path .= "/*" if $remote_path !~ /\*/;
965 my ($n) = ($switch =~ /^--(\w+)/);
966 if (length $pfx && $pfx !~ m#/$#) {
967 die "--prefix='$pfx' must have a trailing slash '/'\n";
968 }
969 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
970 "$remote_path:refs/remotes/$pfx*");
971 }
972
973 sub verify_ref {
974 my ($ref) = @_;
975 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
976 { STDERR => 0 }); };
977 }
978
979 sub get_tree_from_treeish {
980 my ($treeish) = @_;
981 # $treeish can be a symbolic ref, too:
982 my $type = command_oneline(qw/cat-file -t/, $treeish);
983 my $expected;
984 while ($type eq 'tag') {
985 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
986 }
987 if ($type eq 'commit') {
988 $expected = (grep /^tree /, command(qw/cat-file commit/,
989 $treeish))[0];
990 ($expected) = ($expected =~ /^tree ($sha1)$/o);
991 die "Unable to get tree from $treeish\n" unless $expected;
992 } elsif ($type eq 'tree') {
993 $expected = $treeish;
994 } else {
995 die "$treeish is a $type, expected tree, tag or commit\n";
996 }
997 return $expected;
998 }
999
1000 sub get_commit_entry {
1001 my ($treeish) = shift;
1002 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1003 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1004 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1005 open my $log_fh, '>', $commit_editmsg or croak $!;
1006
1007 my $type = command_oneline(qw/cat-file -t/, $treeish);
1008 if ($type eq 'commit' || $type eq 'tag') {
1009 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1010 $type, $treeish);
1011 my $in_msg = 0;
1012 while (<$msg_fh>) {
1013 if (!$in_msg) {
1014 $in_msg = 1 if (/^\s*$/);
1015 } elsif (/^git-svn-id: /) {
1016 # skip this for now, we regenerate the
1017 # correct one on re-fetch anyways
1018 # TODO: set *:merge properties or like...
1019 } else {
1020 print $log_fh $_ or croak $!;
1021 }
1022 }
1023 command_close_pipe($msg_fh, $ctx);
1024 }
1025 close $log_fh or croak $!;
1026
1027 if ($_edit || ($type eq 'tree')) {
1028 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1029 # TODO: strip out spaces, comments, like git-commit.sh
1030 system($editor, $commit_editmsg);
1031 }
1032 rename $commit_editmsg, $commit_msg or croak $!;
1033 open $log_fh, '<', $commit_msg or croak $!;
1034 { local $/; chomp($log_entry{log} = <$log_fh>); }
1035 close $log_fh or croak $!;
1036 unlink $commit_msg;
1037 \%log_entry;
1038 }
1039
1040 sub s_to_file {
1041 my ($str, $file, $mode) = @_;
1042 open my $fd,'>',$file or croak $!;
1043 print $fd $str,"\n" or croak $!;
1044 close $fd or croak $!;
1045 chmod ($mode &~ umask, $file) if (defined $mode);
1046 }
1047
1048 sub file_to_s {
1049 my $file = shift;
1050 open my $fd,'<',$file or croak "$!: file: $file\n";
1051 local $/;
1052 my $ret = <$fd>;
1053 close $fd or croak $!;
1054 $ret =~ s/\s*$//s;
1055 return $ret;
1056 }
1057
1058 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1059 sub load_authors {
1060 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1061 my $log = $cmd eq 'log';
1062 while (<$authors>) {
1063 chomp;
1064 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1065 my ($user, $name, $email) = ($1, $2, $3);
1066 if ($log) {
1067 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1068 } else {
1069 $users{$user} = [$name, $email];
1070 }
1071 }
1072 close $authors or croak $!;
1073 }
1074
1075 # convert GetOpt::Long specs for use by git-config
1076 sub read_repo_config {
1077 return unless -d $ENV{GIT_DIR};
1078 my $opts = shift;
1079 my @config_only;
1080 foreach my $o (keys %$opts) {
1081 # if we have mixedCase and a long option-only, then
1082 # it's a config-only variable that we don't need for
1083 # the command-line.
1084 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1085 my $v = $opts->{$o};
1086 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1087 $key =~ s/-//g;
1088 my $arg = 'git-config';
1089 $arg .= ' --int' if ($o =~ /[:=]i$/);
1090 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1091 if (ref $v eq 'ARRAY') {
1092 chomp(my @tmp = `$arg --get-all svn.$key`);
1093 @$v = @tmp if @tmp;
1094 } else {
1095 chomp(my $tmp = `$arg --get svn.$key`);
1096 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1097 $$v = $tmp;
1098 }
1099 }
1100 }
1101 delete @$opts{@config_only} if @config_only;
1102 }
1103
1104 sub extract_metadata {
1105 my $id = shift or return (undef, undef, undef);
1106 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1107 \s([a-f\d\-]+)$/x);
1108 if (!defined $rev || !$uuid || !$url) {
1109 # some of the original repositories I made had
1110 # identifiers like this:
1111 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1112 }
1113 return ($url, $rev, $uuid);
1114 }
1115
1116 sub cmt_metadata {
1117 return extract_metadata((grep(/^git-svn-id: /,
1118 command(qw/cat-file commit/, shift)))[-1]);
1119 }
1120
1121 sub working_head_info {
1122 my ($head, $refs) = @_;
1123 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1124 my ($fh, $ctx) = command_output_pipe(@args, $head);
1125 my $hash;
1126 my %max;
1127 while (<$fh>) {
1128 if ( m{^commit ($::sha1)$} ) {
1129 unshift @$refs, $hash if $hash and $refs;
1130 $hash = $1;
1131 next;
1132 }
1133 next unless s{^\s*(git-svn-id:)}{$1};
1134 my ($url, $rev, $uuid) = extract_metadata($_);
1135 if (defined $url && defined $rev) {
1136 next if $max{$url} and $max{$url} < $rev;
1137 if (my $gs = Git::SVN->find_by_url($url)) {
1138 my $c = $gs->rev_map_get($rev);
1139 if ($c && $c eq $hash) {
1140 close $fh; # break the pipe
1141 return ($url, $rev, $uuid, $gs);
1142 } else {
1143 $max{$url} ||= $gs->rev_map_max;
1144 }
1145 }
1146 }
1147 }
1148 command_close_pipe($fh, $ctx);
1149 (undef, undef, undef, undef);
1150 }
1151
1152 sub read_commit_parents {
1153 my ($parents, $c) = @_;
1154 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1155 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1156 @{$parents->{$c}} = split(/ /, $p);
1157 }
1158
1159 sub linearize_history {
1160 my ($gs, $refs) = @_;
1161 my %parents;
1162 foreach my $c (@$refs) {
1163 read_commit_parents(\%parents, $c);
1164 }
1165
1166 my @linear_refs;
1167 my %skip = ();
1168 my $last_svn_commit = $gs->last_commit;
1169 foreach my $c (reverse @$refs) {
1170 next if $c eq $last_svn_commit;
1171 last if $skip{$c};
1172
1173 unshift @linear_refs, $c;
1174 $skip{$c} = 1;
1175
1176 # we only want the first parent to diff against for linear
1177 # history, we save the rest to inject when we finalize the
1178 # svn commit
1179 my $fp_a = verify_ref("$c~1");
1180 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1181 if (!$fp_a || !$fp_b) {
1182 die "Commit $c\n",
1183 "has no parent commit, and therefore ",
1184 "nothing to diff against.\n",
1185 "You should be working from a repository ",
1186 "originally created by git-svn\n";
1187 }
1188 if ($fp_a ne $fp_b) {
1189 die "$c~1 = $fp_a, however parsing commit $c ",
1190 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1191 }
1192
1193 foreach my $p (@{$parents{$c}}) {
1194 $skip{$p} = 1;
1195 }
1196 }
1197 (\@linear_refs, \%parents);
1198 }
1199
1200 sub find_file_type_and_diff_status {
1201 my ($path) = @_;
1202 return ('dir', '') if $path eq '.';
1203
1204 my $diff_output =
1205 command_oneline(qw(diff --cached --name-status --), $path) || "";
1206 my $diff_status = (split(' ', $diff_output))[0] || "";
1207
1208 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1209
1210 return (undef, undef) if !$diff_status && !$ls_tree;
1211
1212 if ($diff_status eq "A") {
1213 return ("link", $diff_status) if -l $path;
1214 return ("dir", $diff_status) if -d $path;
1215 return ("file", $diff_status);
1216 }
1217
1218 my $mode = (split(' ', $ls_tree))[0] || "";
1219
1220 return ("link", $diff_status) if $mode eq "120000";
1221 return ("dir", $diff_status) if $mode eq "040000";
1222 return ("file", $diff_status);
1223 }
1224
1225 sub md5sum {
1226 my $arg = shift;
1227 my $ref = ref $arg;
1228 my $md5 = Digest::MD5->new();
1229 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1230 $md5->addfile($arg) or croak $!;
1231 } elsif ($ref eq 'SCALAR') {
1232 $md5->add($$arg) or croak $!;
1233 } elsif (!$ref) {
1234 $md5->add($arg) or croak $!;
1235 } else {
1236 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1237 }
1238 return $md5->hexdigest();
1239 }
1240
1241 package Git::SVN;
1242 use strict;
1243 use warnings;
1244 use Fcntl qw/:DEFAULT :seek/;
1245 use constant rev_map_fmt => 'NH40';
1246 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1247 $_repack $_repack_flags $_use_svm_props $_head
1248 $_use_svnsync_props $no_reuse_existing $_minimize_url
1249 $_use_log_author/;
1250 use Carp qw/croak/;
1251 use File::Path qw/mkpath/;
1252 use File::Copy qw/copy/;
1253 use IPC::Open3;
1254
1255 my ($_gc_nr, $_gc_period);
1256
1257 # properties that we do not log:
1258 my %SKIP_PROP;
1259 BEGIN {
1260 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1261 svn:special svn:executable
1262 svn:entry:committed-rev
1263 svn:entry:last-author
1264 svn:entry:uuid
1265 svn:entry:committed-date/;
1266
1267 # some options are read globally, but can be overridden locally
1268 # per [svn-remote "..."] section. Command-line options will *NOT*
1269 # override options set in an [svn-remote "..."] section
1270 no strict 'refs';
1271 for my $option (qw/follow_parent no_metadata use_svm_props
1272 use_svnsync_props/) {
1273 my $key = $option;
1274 $key =~ tr/_//d;
1275 my $prop = "-$option";
1276 *$option = sub {
1277 my ($self) = @_;
1278 return $self->{$prop} if exists $self->{$prop};
1279 my $k = "svn-remote.$self->{repo_id}.$key";
1280 eval { command_oneline(qw/config --get/, $k) };
1281 if ($@) {
1282 $self->{$prop} = ${"Git::SVN::_$option"};
1283 } else {
1284 my $v = command_oneline(qw/config --bool/,$k);
1285 $self->{$prop} = $v eq 'false' ? 0 : 1;
1286 }
1287 return $self->{$prop};
1288 }
1289 }
1290 }
1291
1292 my (%LOCKFILES, %INDEX_FILES);
1293 END {
1294 unlink keys %LOCKFILES if %LOCKFILES;
1295 unlink keys %INDEX_FILES if %INDEX_FILES;
1296 }
1297
1298 sub resolve_local_globs {
1299 my ($url, $fetch, $glob_spec) = @_;
1300 return unless defined $glob_spec;
1301 my $ref = $glob_spec->{ref};
1302 my $path = $glob_spec->{path};
1303 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1304 next unless m#^refs/remotes/$ref->{regex}$#;
1305 my $p = $1;
1306 my $pathname = desanitize_refname($path->full_path($p));
1307 my $refname = desanitize_refname($ref->full_path($p));
1308 if (my $existing = $fetch->{$pathname}) {
1309 if ($existing ne $refname) {
1310 die "Refspec conflict:\n",
1311 "existing: refs/remotes/$existing\n",
1312 " globbed: refs/remotes/$refname\n";
1313 }
1314 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1315 $u =~ s!^\Q$url\E(/|$)!! or die
1316 "refs/remotes/$refname: '$url' not found in '$u'\n";
1317 if ($pathname ne $u) {
1318 warn "W: Refspec glob conflict ",
1319 "(ref: refs/remotes/$refname):\n",
1320 "expected path: $pathname\n",
1321 " real path: $u\n",
1322 "Continuing ahead with $u\n";
1323 next;
1324 }
1325 } else {
1326 $fetch->{$pathname} = $refname;
1327 }
1328 }
1329 }
1330
1331 sub parse_revision_argument {
1332 my ($base, $head) = @_;
1333 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1334 return ($base, $head);
1335 }
1336 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1337 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1338 return ($head, $head) if ($::_revision eq 'HEAD');
1339 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1340 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1341 die "revision argument: $::_revision not understood by git-svn\n";
1342 }
1343
1344 sub fetch_all {
1345 my ($repo_id, $remotes) = @_;
1346 if (ref $repo_id) {
1347 my $gs = $repo_id;
1348 $repo_id = undef;
1349 $repo_id = $gs->{repo_id};
1350 }
1351 $remotes ||= read_all_remotes();
1352 my $remote = $remotes->{$repo_id} or
1353 die "[svn-remote \"$repo_id\"] unknown\n";
1354 my $fetch = $remote->{fetch};
1355 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1356 my (@gs, @globs);
1357 my $ra = Git::SVN::Ra->new($url);
1358 my $uuid = $ra->get_uuid;
1359 my $head = $ra->get_latest_revnum;
1360 my $base = defined $fetch ? $head : 0;
1361
1362 # read the max revs for wildcard expansion (branches/*, tags/*)
1363 foreach my $t (qw/branches tags/) {
1364 defined $remote->{$t} or next;
1365 push @globs, $remote->{$t};
1366 my $max_rev = eval { tmp_config(qw/--int --get/,
1367 "svn-remote.$repo_id.${t}-maxRev") };
1368 if (defined $max_rev && ($max_rev < $base)) {
1369 $base = $max_rev;
1370 } elsif (!defined $max_rev) {
1371 $base = 0;
1372 }
1373 }
1374
1375 if ($fetch) {
1376 foreach my $p (sort keys %$fetch) {
1377 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1378 my $lr = $gs->rev_map_max;
1379 if (defined $lr) {
1380 $base = $lr if ($lr < $base);
1381 }
1382 push @gs, $gs;
1383 }
1384 }
1385
1386 ($base, $head) = parse_revision_argument($base, $head);
1387 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1388 }
1389
1390 sub read_all_remotes {
1391 my $r = {};
1392 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1393 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1394 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1395 $local_ref =~ s{^/}{};
1396 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1397 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1398 $r->{$1}->{url} = $2;
1399 } elsif (m!^(.+)\.(branches|tags)=
1400 (.*):refs/remotes/(.+)\s*$/!x) {
1401 my ($p, $g) = ($3, $4);
1402 my $rs = $r->{$1}->{$2} = {
1403 t => $2,
1404 remote => $1,
1405 path => Git::SVN::GlobSpec->new($p),
1406 ref => Git::SVN::GlobSpec->new($g) };
1407 if (length($rs->{ref}->{right}) != 0) {
1408 die "The '*' glob character must be the last ",
1409 "character of '$g'\n";
1410 }
1411 }
1412 }
1413 $r;
1414 }
1415
1416 sub init_vars {
1417 $_gc_nr = $_gc_period = 1000;
1418 if (defined $_repack || defined $_repack_flags) {
1419 warn "Repack options are obsolete; they have no effect.\n";
1420 }
1421 }
1422
1423 sub verify_remotes_sanity {
1424 return unless -d $ENV{GIT_DIR};
1425 my %seen;
1426 foreach (command(qw/config -l/)) {
1427 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1428 if ($seen{$1}) {
1429 die "Remote ref refs/remote/$1 is tracked by",
1430 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1431 "Please resolve this ambiguity in ",
1432 "your git configuration file before ",
1433 "continuing\n";
1434 }
1435 $seen{$1} = $_;
1436 }
1437 }
1438 }
1439
1440 # we allow more chars than remotes2config.sh...
1441 sub sanitize_remote_name {
1442 my ($name) = @_;
1443 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1444 $name;
1445 }
1446
1447 sub find_existing_remote {
1448 my ($url, $remotes) = @_;
1449 return undef if $no_reuse_existing;
1450 my $existing;
1451 foreach my $repo_id (keys %$remotes) {
1452 my $u = $remotes->{$repo_id}->{url} or next;
1453 next if $u ne $url;
1454 $existing = $repo_id;
1455 last;
1456 }
1457 $existing;
1458 }
1459
1460 sub init_remote_config {
1461 my ($self, $url, $no_write) = @_;
1462 $url =~ s!/+$!!; # strip trailing slash
1463 my $r = read_all_remotes();
1464 my $existing = find_existing_remote($url, $r);
1465 if ($existing) {
1466 unless ($no_write) {
1467 print STDERR "Using existing ",
1468 "[svn-remote \"$existing\"]\n";
1469 }
1470 $self->{repo_id} = $existing;
1471 } elsif ($_minimize_url) {
1472 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1473 $existing = find_existing_remote($min_url, $r);
1474 if ($existing) {
1475 unless ($no_write) {
1476 print STDERR "Using existing ",
1477 "[svn-remote \"$existing\"]\n";
1478 }
1479 $self->{repo_id} = $existing;
1480 }
1481 if ($min_url ne $url) {
1482 unless ($no_write) {
1483 print STDERR "Using higher level of URL: ",
1484 "$url => $min_url\n";
1485 }
1486 my $old_path = $self->{path};
1487 $self->{path} = $url;
1488 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1489 if (length $old_path) {
1490 $self->{path} .= "/$old_path";
1491 }
1492 $url = $min_url;
1493 }
1494 }
1495 my $orig_url;
1496 if (!$existing) {
1497 # verify that we aren't overwriting anything:
1498 $orig_url = eval {
1499 command_oneline('config', '--get',
1500 "svn-remote.$self->{repo_id}.url")
1501 };
1502 if ($orig_url && ($orig_url ne $url)) {
1503 die "svn-remote.$self->{repo_id}.url already set: ",
1504 "$orig_url\nwanted to set to: $url\n";
1505 }
1506 }
1507 my ($xrepo_id, $xpath) = find_ref($self->refname);
1508 if (defined $xpath) {
1509 die "svn-remote.$xrepo_id.fetch already set to track ",
1510 "$xpath:refs/remotes/", $self->refname, "\n";
1511 }
1512 unless ($no_write) {
1513 command_noisy('config',
1514 "svn-remote.$self->{repo_id}.url", $url);
1515 $self->{path} =~ s{^/}{};
1516 command_noisy('config', '--add',
1517 "svn-remote.$self->{repo_id}.fetch",
1518 "$self->{path}:".$self->refname);
1519 }
1520 $self->{url} = $url;
1521 }
1522
1523 sub find_by_url { # repos_root and, path are optional
1524 my ($class, $full_url, $repos_root, $path) = @_;
1525
1526 return undef unless defined $full_url;
1527 remove_username($full_url);
1528 remove_username($repos_root) if defined $repos_root;
1529 my $remotes = read_all_remotes();
1530 if (defined $full_url && defined $repos_root && !defined $path) {
1531 $path = $full_url;
1532 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1533 }
1534 foreach my $repo_id (keys %$remotes) {
1535 my $u = $remotes->{$repo_id}->{url} or next;
1536 remove_username($u);
1537 next if defined $repos_root && $repos_root ne $u;
1538
1539 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1540 foreach (qw/branches tags/) {
1541 resolve_local_globs($u, $fetch,
1542 $remotes->{$repo_id}->{$_});
1543 }
1544 my $p = $path;
1545 my $rwr = rewrite_root({repo_id => $repo_id});
1546 unless (defined $p) {
1547 $p = $full_url;
1548 my $z = $u;
1549 if ($rwr) {
1550 $z = $rwr;
1551 }
1552 $p =~ s#^\Q$z\E(?:/|$)## or next;
1553 }
1554 foreach my $f (keys %$fetch) {
1555 next if $f ne $p;
1556 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1557 }
1558 }
1559 undef;
1560 }
1561
1562 sub init {
1563 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1564 my $self = _new($class, $repo_id, $ref_id, $path);
1565 if (defined $url) {
1566 $self->init_remote_config($url, $no_write);
1567 }
1568 $self;
1569 }
1570
1571 sub find_ref {
1572 my ($ref_id) = @_;
1573 foreach (command(qw/config -l/)) {
1574 next unless m!^svn-remote\.(.+)\.fetch=
1575 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1576 my ($repo_id, $path, $ref) = ($1, $2, $3);
1577 if ($ref eq $ref_id) {
1578 $path = '' if ($path =~ m#^\./?#);
1579 return ($repo_id, $path);
1580 }
1581 }
1582 (undef, undef, undef);
1583 }
1584
1585 sub new {
1586 my ($class, $ref_id, $repo_id, $path) = @_;
1587 if (defined $ref_id && !defined $repo_id && !defined $path) {
1588 ($repo_id, $path) = find_ref($ref_id);
1589 if (!defined $repo_id) {
1590 die "Could not find a \"svn-remote.*.fetch\" key ",
1591 "in the repository configuration matching: ",
1592 "refs/remotes/$ref_id\n";
1593 }
1594 }
1595 my $self = _new($class, $repo_id, $ref_id, $path);
1596 if (!defined $self->{path} || !length $self->{path}) {
1597 my $fetch = command_oneline('config', '--get',
1598 "svn-remote.$repo_id.fetch",
1599 ":refs/remotes/$ref_id\$") or
1600 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1601 "\":refs/remotes/$ref_id\$\" in config\n";
1602 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1603 }
1604 $self->{url} = command_oneline('config', '--get',
1605 "svn-remote.$repo_id.url") or
1606 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1607 $self->rebuild;
1608 $self;
1609 }
1610
1611 sub refname {
1612 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1613
1614 # It cannot end with a slash /, we'll throw up on this because
1615 # SVN can't have directories with a slash in their name, either:
1616 if ($refname =~ m{/$}) {
1617 die "ref: '$refname' ends with a trailing slash, this is ",
1618 "not permitted by git nor Subversion\n";
1619 }
1620
1621 # It cannot have ASCII control character space, tilde ~, caret ^,
1622 # colon :, question-mark ?, asterisk *, space, or open bracket [
1623 # anywhere.
1624 #
1625 # Additionally, % must be escaped because it is used for escaping
1626 # and we want our escaped refname to be reversible
1627 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1628
1629 # no slash-separated component can begin with a dot .
1630 # /.* becomes /%2E*
1631 $refname =~ s{/\.}{/%2E}g;
1632
1633 # It cannot have two consecutive dots .. anywhere
1634 # .. becomes %2E%2E
1635 $refname =~ s{\.\.}{%2E%2E}g;
1636
1637 return $refname;
1638 }
1639
1640 sub desanitize_refname {
1641 my ($refname) = @_;
1642 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1643 return $refname;
1644 }
1645
1646 sub svm_uuid {
1647 my ($self) = @_;
1648 return $self->{svm}->{uuid} if $self->svm;
1649 $self->ra;
1650 unless ($self->{svm}) {
1651 die "SVM UUID not cached, and reading remotely failed\n";
1652 }
1653 $self->{svm}->{uuid};
1654 }
1655
1656 sub svm {
1657 my ($self) = @_;
1658 return $self->{svm} if $self->{svm};
1659 my $svm;
1660 # see if we have it in our config, first:
1661 eval {
1662 my $section = "svn-remote.$self->{repo_id}";
1663 $svm = {
1664 source => tmp_config('--get', "$section.svm-source"),
1665 uuid => tmp_config('--get', "$section.svm-uuid"),
1666 replace => tmp_config('--get', "$section.svm-replace"),
1667 }
1668 };
1669 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1670 $self->{svm} = $svm;
1671 }
1672 $self->{svm};
1673 }
1674
1675 sub _set_svm_vars {
1676 my ($self, $ra) = @_;
1677 return $ra if $self->svm;
1678
1679 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1680 "(svm:source, svm:uuid) ",
1681 "from the following URLs:\n" );
1682 sub read_svm_props {
1683 my ($self, $ra, $path, $r) = @_;
1684 my $props = ($ra->get_dir($path, $r))[2];
1685 my $src = $props->{'svm:source'};
1686 my $uuid = $props->{'svm:uuid'};
1687 return undef if (!$src || !$uuid);
1688
1689 chomp($src, $uuid);
1690
1691 $uuid =~ m{^[0-9a-f\-]{30,}$}
1692 or die "doesn't look right - svm:uuid is '$uuid'\n";
1693
1694 # the '!' is used to mark the repos_root!/relative/path
1695 $src =~ s{/?!/?}{/};
1696 $src =~ s{/+$}{}; # no trailing slashes please
1697 # username is of no interest
1698 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1699
1700 my $replace = $ra->{url};
1701 $replace .= "/$path" if length $path;
1702
1703 my $section = "svn-remote.$self->{repo_id}";
1704 tmp_config("$section.svm-source", $src);
1705 tmp_config("$section.svm-replace", $replace);
1706 tmp_config("$section.svm-uuid", $uuid);
1707 $self->{svm} = {
1708 source => $src,
1709 uuid => $uuid,
1710 replace => $replace
1711 };
1712 }
1713
1714 my $r = $ra->get_latest_revnum;
1715 my $path = $self->{path};
1716 my %tried;
1717 while (length $path) {
1718 unless ($tried{"$self->{url}/$path"}) {
1719 return $ra if $self->read_svm_props($ra, $path, $r);
1720 $tried{"$self->{url}/$path"} = 1;
1721 }
1722 $path =~ s#/?[^/]+$##;
1723 }
1724 die "Path: '$path' should be ''\n" if $path ne '';
1725 return $ra if $self->read_svm_props($ra, $path, $r);
1726 $tried{"$self->{url}/$path"} = 1;
1727
1728 if ($ra->{repos_root} eq $self->{url}) {
1729 die @err, (map { " $_\n" } keys %tried), "\n";
1730 }
1731
1732 # nope, make sure we're connected to the repository root:
1733 my $ok;
1734 my @tried_b;
1735 $path = $ra->{svn_path};
1736 $ra = Git::SVN::Ra->new($ra->{repos_root});
1737 while (length $path) {
1738 unless ($tried{"$ra->{url}/$path"}) {
1739 $ok = $self->read_svm_props($ra, $path, $r);
1740 last if $ok;
1741 $tried{"$ra->{url}/$path"} = 1;
1742 }
1743 $path =~ s#/?[^/]+$##;
1744 }
1745 die "Path: '$path' should be ''\n" if $path ne '';
1746 $ok ||= $self->read_svm_props($ra, $path, $r);
1747 $tried{"$ra->{url}/$path"} = 1;
1748 if (!$ok) {
1749 die @err, (map { " $_\n" } keys %tried), "\n";
1750 }
1751 Git::SVN::Ra->new($self->{url});
1752 }
1753
1754 sub svnsync {
1755 my ($self) = @_;
1756 return $self->{svnsync} if $self->{svnsync};
1757
1758 if ($self->no_metadata) {
1759 die "Can't have both 'noMetadata' and ",
1760 "'useSvnsyncProps' options set!\n";
1761 }
1762 if ($self->rewrite_root) {
1763 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1764 "options set!\n";
1765 }
1766
1767 my $svnsync;
1768 # see if we have it in our config, first:
1769 eval {
1770 my $section = "svn-remote.$self->{repo_id}";
1771
1772 my $url = tmp_config('--get', "$section.svnsync-url");
1773 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1774 die "doesn't look right - svn:sync-from-url is '$url'\n";
1775
1776 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1777 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1778 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1779
1780 $svnsync = { url => $url, uuid => $uuid }
1781 };
1782 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1783 return $self->{svnsync} = $svnsync;
1784 }
1785
1786 my $err = "useSvnsyncProps set, but failed to read " .
1787 "svnsync property: svn:sync-from-";
1788 my $rp = $self->ra->rev_proplist(0);
1789
1790 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1791 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1792 die "doesn't look right - svn:sync-from-url is '$url'\n";
1793
1794 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1795 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1796 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1797
1798 my $section = "svn-remote.$self->{repo_id}";
1799 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1800 tmp_config('--add', "$section.svnsync-url", $url);
1801 return $self->{svnsync} = { url => $url, uuid => $uuid };
1802 }
1803
1804 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1805 # remote lookup (useful for 'git svn log').
1806 sub ra_uuid {
1807 my ($self) = @_;
1808 unless ($self->{ra_uuid}) {
1809 my $key = "svn-remote.$self->{repo_id}.uuid";
1810 my $uuid = eval { tmp_config('--get', $key) };
1811 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1812 $self->{ra_uuid} = $uuid;
1813 } else {
1814 die "ra_uuid called without URL\n" unless $self->{url};
1815 $self->{ra_uuid} = $self->ra->get_uuid;
1816 tmp_config('--add', $key, $self->{ra_uuid});
1817 }
1818 }
1819 $self->{ra_uuid};
1820 }
1821
1822 sub _set_repos_root {
1823 my ($self, $repos_root) = @_;
1824 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1825 $repos_root ||= $self->ra->{repos_root};
1826 tmp_config($k, $repos_root);
1827 $repos_root;
1828 }
1829
1830 sub repos_root {
1831 my ($self) = @_;
1832 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1833 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1834 }
1835
1836 sub ra {
1837 my ($self) = shift;
1838 my $ra = Git::SVN::Ra->new($self->{url});
1839 $self->_set_repos_root($ra->{repos_root});
1840 if ($self->use_svm_props && !$self->{svm}) {
1841 if ($self->no_metadata) {
1842 die "Can't have both 'noMetadata' and ",
1843 "'useSvmProps' options set!\n";
1844 } elsif ($self->use_svnsync_props) {
1845 die "Can't have both 'useSvnsyncProps' and ",
1846 "'useSvmProps' options set!\n";
1847 }
1848 $ra = $self->_set_svm_vars($ra);
1849 $self->{-want_revprops} = 1;
1850 }
1851 $ra;
1852 }
1853
1854 sub rel_path {
1855 my ($self) = @_;
1856 my $repos_root = $self->ra->{repos_root};
1857 return $self->{path} if ($self->{url} eq $repos_root);
1858 my $url = $self->{url} .
1859 (length $self->{path} ? "/$self->{path}" : $self->{path});
1860 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1861 $url;
1862 }
1863
1864 # prop_walk(PATH, REV, SUB)
1865 # -------------------------
1866 # Recursively traverse PATH at revision REV and invoke SUB for each
1867 # directory that contains a SVN property. SUB will be invoked as
1868 # follows: &SUB(gs, path, props); where `gs' is this instance of
1869 # Git::SVN, `path' the path to the directory where the properties
1870 # `props' were found. The `path' will be relative to point of checkout,
1871 # that is, if url://repo/trunk is the current Git branch, and that
1872 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1873 # as `path' (note the trailing `/').
1874 sub prop_walk {
1875 my ($self, $path, $rev, $sub) = @_;
1876
1877 $path =~ s#^/##;
1878 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1879 $path =~ s#^/*#/#g;
1880 my $p = $path;
1881 # Strip the irrelevant part of the path.
1882 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1883 # Ensure the path is terminated by a `/'.
1884 $p =~ s#/*$#/#;
1885
1886 # The properties contain all the internal SVN stuff nobody
1887 # (usually) cares about.
1888 my $interesting_props = 0;
1889 foreach (keys %{$props}) {
1890 # If it doesn't start with `svn:', it must be a
1891 # user-defined property.
1892 ++$interesting_props and next if $_ !~ /^svn:/;
1893 # FIXME: Fragile, if SVN adds new public properties,
1894 # this needs to be updated.
1895 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1896 |eol-style|mime-type
1897 |externals|needs-lock)$/x;
1898 }
1899 &$sub($self, $p, $props) if $interesting_props;
1900
1901 foreach (sort keys %$dirent) {
1902 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1903 $self->prop_walk($p . $_, $rev, $sub);
1904 }
1905 }
1906
1907 sub last_rev { ($_[0]->last_rev_commit)[0] }
1908 sub last_commit { ($_[0]->last_rev_commit)[1] }
1909
1910 # returns the newest SVN revision number and newest commit SHA1
1911 sub last_rev_commit {
1912 my ($self) = @_;
1913 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1914 return ($self->{last_rev}, $self->{last_commit});
1915 }
1916 my $c = ::verify_ref($self->refname.'^0');
1917 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1918 my $rev = (::cmt_metadata($c))[1];
1919 if (defined $rev) {
1920 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1921 return ($rev, $c);
1922 }
1923 }
1924 my $map_path = $self->map_path;
1925 unless (-e $map_path) {
1926 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1927 return (undef, undef);
1928 }
1929 my ($rev, $commit) = $self->rev_map_max(1);
1930 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1931 return ($rev, $commit);
1932 }
1933
1934 sub get_fetch_range {
1935 my ($self, $min, $max) = @_;
1936 $max ||= $self->ra->get_latest_revnum;
1937 $min ||= $self->rev_map_max;
1938 (++$min, $max);
1939 }
1940
1941 sub tmp_config {
1942 my (@args) = @_;
1943 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1944 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1945 if (! -f $config && -f $old_def_config) {
1946 rename $old_def_config, $config or
1947 die "Failed rename $old_def_config => $config: $!\n";
1948 }
1949 my $old_config = $ENV{GIT_CONFIG};
1950 $ENV{GIT_CONFIG} = $config;
1951 $@ = undef;
1952 my @ret = eval {
1953 unless (-f $config) {
1954 mkfile($config);
1955 open my $fh, '>', $config or
1956 die "Can't open $config: $!\n";
1957 print $fh "; This file is used internally by ",
1958 "git-svn\n" or die
1959 "Couldn't write to $config: $!\n";
1960 print $fh "; You should not have to edit it\n" or
1961 die "Couldn't write to $config: $!\n";
1962 close $fh or die "Couldn't close $config: $!\n";
1963 }
1964 command('config', @args);
1965 };
1966 my $err = $@;
1967 if (defined $old_config) {
1968 $ENV{GIT_CONFIG} = $old_config;
1969 } else {
1970 delete $ENV{GIT_CONFIG};
1971 }
1972 die $err if $err;
1973 wantarray ? @ret : $ret[0];
1974 }
1975
1976 sub tmp_index_do {
1977 my ($self, $sub) = @_;
1978 my $old_index = $ENV{GIT_INDEX_FILE};
1979 $ENV{GIT_INDEX_FILE} = $self->{index};
1980 $@ = undef;
1981 my @ret = eval {
1982 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1983 mkpath([$dir]) unless -d $dir;
1984 &$sub;
1985 };
1986 my $err = $@;
1987 if (defined $old_index) {
1988 $ENV{GIT_INDEX_FILE} = $old_index;
1989 } else {
1990 delete $ENV{GIT_INDEX_FILE};
1991 }
1992 die $err if $err;
1993 wantarray ? @ret : $ret[0];
1994 }
1995
1996 sub assert_index_clean {
1997 my ($self, $treeish) = @_;
1998
1999 $self->tmp_index_do(sub {
2000 command_noisy('read-tree', $treeish) unless -e $self->{index};
2001 my $x = command_oneline('write-tree');
2002 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2003 /^tree ($::sha1)/mo);
2004 return if $y eq $x;
2005
2006 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2007 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2008 command_noisy('read-tree', $treeish);
2009 $x = command_oneline('write-tree');
2010 if ($y ne $x) {
2011 ::fatal "trees ($treeish) $y != $x\n",
2012 "Something is seriously wrong...";
2013 }
2014 });
2015 }
2016
2017 sub get_commit_parents {
2018 my ($self, $log_entry) = @_;
2019 my (%seen, @ret, @tmp);
2020 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2021 if (my $ip = $self->{inject_parents}) {
2022 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2023 push @tmp, $commit;
2024 }
2025 }
2026 if (my $cur = ::verify_ref($self->refname.'^0')) {
2027 push @tmp, $cur;
2028 }
2029 if (my $ipd = $self->{inject_parents_dcommit}) {
2030 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2031 push @tmp, @$commit;
2032 }
2033 }
2034 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2035 while (my $p = shift @tmp) {
2036 next if $seen{$p};
2037 $seen{$p} = 1;
2038 push @ret, $p;
2039 # MAXPARENT is defined to 16 in commit-tree.c:
2040 last if @ret >= 16;
2041 }
2042 if (@tmp) {
2043 die "r$log_entry->{revision}: No room for parents:\n\t",
2044 join("\n\t", @tmp), "\n";
2045 }
2046 @ret;
2047 }
2048
2049 sub rewrite_root {
2050 my ($self) = @_;
2051 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2052 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2053 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2054 if ($rwr) {
2055 $rwr =~ s#/+$##;
2056 if ($rwr !~ m#^[a-z\+]+://#) {
2057 die "$rwr is not a valid URL (key: $k)\n";
2058 }
2059 }
2060 $self->{-rewrite_root} = $rwr;
2061 }
2062
2063 sub metadata_url {
2064 my ($self) = @_;
2065 ($self->rewrite_root || $self->{url}) .
2066 (length $self->{path} ? '/' . $self->{path} : '');
2067 }
2068
2069 sub full_url {
2070 my ($self) = @_;
2071 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2072 }
2073
2074
2075 sub set_commit_header_env {
2076 my ($log_entry) = @_;
2077 my %env;
2078 foreach my $ned (qw/NAME EMAIL DATE/) {
2079 foreach my $ac (qw/AUTHOR COMMITTER/) {
2080 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2081 }
2082 }
2083
2084 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2085 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2086 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2087
2088 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2089 ? $log_entry->{commit_name}
2090 : $log_entry->{name};
2091 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2092 ? $log_entry->{commit_email}
2093 : $log_entry->{email};
2094 \%env;
2095 }
2096
2097 sub restore_commit_header_env {
2098 my ($env) = @_;
2099 foreach my $ned (qw/NAME EMAIL DATE/) {
2100 foreach my $ac (qw/AUTHOR COMMITTER/) {
2101 my $k = "GIT_${ac}_${ned}";
2102 if (defined $env->{$k}) {
2103 $ENV{$k} = $env->{$k};
2104 } else {
2105 delete $ENV{$k};
2106 }
2107 }
2108 }
2109 }
2110
2111 sub gc {
2112 command_noisy('gc', '--auto');
2113 };
2114
2115 sub do_git_commit {
2116 my ($self, $log_entry) = @_;
2117 my $lr = $self->last_rev;
2118 if (defined $lr && $lr >= $log_entry->{revision}) {
2119 die "Last fetched revision of ", $self->refname,
2120 " was r$lr, but we are about to fetch: ",
2121 "r$log_entry->{revision}!\n";
2122 }
2123 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2124 croak "$log_entry->{revision} = $c already exists! ",
2125 "Why are we refetching it?\n";
2126 }
2127 my $old_env = set_commit_header_env($log_entry);
2128 my $tree = $log_entry->{tree};
2129 if (!defined $tree) {
2130 $tree = $self->tmp_index_do(sub {
2131 command_oneline('write-tree') });
2132 }
2133 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2134
2135 my @exec = ('git-commit-tree', $tree);
2136 foreach ($self->get_commit_parents($log_entry)) {
2137 push @exec, '-p', $_;
2138 }
2139 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2140 or croak $!;
2141 print $msg_fh $log_entry->{log} or croak $!;
2142 restore_commit_header_env($old_env);
2143 unless ($self->no_metadata) {
2144 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2145 or croak $!;
2146 }
2147 $msg_fh->flush == 0 or croak $!;
2148 close $msg_fh or croak $!;
2149 chomp(my $commit = do { local $/; <$out_fh> });
2150 close $out_fh or croak $!;
2151 waitpid $pid, 0;
2152 croak $? if $?;
2153 if ($commit !~ /^$::sha1$/o) {
2154 die "Failed to commit, invalid sha1: $commit\n";
2155 }
2156
2157 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2158
2159 $self->{last_rev} = $log_entry->{revision};
2160 $self->{last_commit} = $commit;
2161 print "r$log_entry->{revision}";
2162 if (defined $log_entry->{svm_revision}) {
2163 print " (\@$log_entry->{svm_revision})";
2164 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2165 0, $self->svm_uuid);
2166 }
2167 print " = $commit ($self->{ref_id})\n";
2168 if (--$_gc_nr == 0) {
2169 $_gc_nr = $_gc_period;
2170 gc();
2171 }
2172 return $commit;
2173 }
2174
2175 sub match_paths {
2176 my ($self, $paths, $r) = @_;
2177 return 1 if $self->{path} eq '';
2178 if (my $path = $paths->{"/$self->{path}"}) {
2179 return ($path->{action} eq 'D') ? 0 : 1;
2180 }
2181 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2182 if (grep /$self->{path_regex}/, keys %$paths) {
2183 return 1;
2184 }
2185 my $c = '';
2186 foreach (split m#/#, $self->{path}) {
2187 $c .= "/$_";
2188 next unless ($paths->{$c} &&
2189 ($paths->{$c}->{action} =~ /^[AR]$/));
2190 if ($self->ra->check_path($self->{path}, $r) ==
2191 $SVN::Node::dir) {
2192 return 1;
2193 }
2194 }
2195 return 0;
2196 }
2197
2198 sub find_parent_branch {
2199 my ($self, $paths, $rev) = @_;
2200 return undef unless $self->follow_parent;
2201 unless (defined $paths) {
2202 my $err_handler = $SVN::Error::handler;
2203 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2204 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2205 $paths =
2206 Git::SVN::Ra::dup_changed_paths($_[0]) });
2207 $SVN::Error::handler = $err_handler;
2208 }
2209 return undef unless defined $paths;
2210
2211 # look for a parent from another branch:
2212 my @b_path_components = split m#/#, $self->rel_path;
2213 my @a_path_components;
2214 my $i;
2215 while (@b_path_components) {
2216 $i = $paths->{'/'.join('/', @b_path_components)};
2217 last if $i && defined $i->{copyfrom_path};
2218 unshift(@a_path_components, pop(@b_path_components));
2219 }
2220 return undef unless defined $i && defined $i->{copyfrom_path};
2221 my $branch_from = $i->{copyfrom_path};
2222 if (@a_path_components) {
2223 print STDERR "branch_from: $branch_from => ";
2224 $branch_from .= '/'.join('/', @a_path_components);
2225 print STDERR $branch_from, "\n";
2226 }
2227 my $r = $i->{copyfrom_rev};
2228 my $repos_root = $self->ra->{repos_root};
2229 my $url = $self->ra->{url};
2230 my $new_url = $repos_root . $branch_from;
2231 print STDERR "Found possible branch point: ",
2232 "$new_url => ", $self->full_url, ", $r\n";
2233 $branch_from =~ s#^/##;
2234 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2235 unless ($gs) {
2236 my $ref_id = $self->{ref_id};
2237 $ref_id =~ s/\@\d+$//;
2238 $ref_id .= "\@$r";
2239 # just grow a tail if we're not unique enough :x
2240 $ref_id .= '-' while find_ref($ref_id);
2241 print STDERR "Initializing parent: $ref_id\n";
2242 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2243 if ($u =~ s#^\Q$url\E(/|$)##) {
2244 $p = $u;
2245 $u = $url;
2246 $repo_id = $self->{repo_id};
2247 }
2248 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2249 }
2250 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2251 if (!defined $r0 || !defined $parent) {
2252 my ($base, $head) = parse_revision_argument(0, $r);
2253 if ($base <= $r) {
2254 $gs->fetch($base, $r);
2255 }
2256 ($r0, $parent) = $gs->last_rev_commit;
2257 }
2258 if (defined $r0 && defined $parent) {
2259 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2260 my $ed;
2261 if ($self->ra->can_do_switch) {
2262 $self->assert_index_clean($parent);
2263 print STDERR "Following parent with do_switch\n";
2264 # do_switch works with svn/trunk >= r22312, but that
2265 # is not included with SVN 1.4.3 (the latest version
2266 # at the moment), so we can't rely on it
2267 $self->{last_commit} = $parent;
2268 $ed = SVN::Git::Fetcher->new($self);
2269 $gs->ra->gs_do_switch($r0, $rev, $gs,
2270 $self->full_url, $ed)
2271 or die "SVN connection failed somewhere...\n";
2272 } elsif ($self->ra->trees_match($new_url, $r0,
2273 $self->full_url, $rev)) {
2274 print STDERR "Trees match:\n",
2275 " $new_url\@$r0\n",
2276 " ${\$self->full_url}\@$rev\n",
2277 "Following parent with no changes\n";
2278 $self->tmp_index_do(sub {
2279 command_noisy('read-tree', $parent);
2280 });
2281 $self->{last_commit} = $parent;
2282 } else {
2283 print STDERR "Following parent with do_update\n";
2284 $ed = SVN::Git::Fetcher->new($self);
2285 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2286 or die "SVN connection failed somewhere...\n";
2287 }
2288 print STDERR "Successfully followed parent\n";
2289 return $self->make_log_entry($rev, [$parent], $ed);
2290 }
2291 return undef;
2292 }
2293
2294 sub do_fetch {
2295 my ($self, $paths, $rev) = @_;
2296 my $ed;
2297 my ($last_rev, @parents);
2298 if (my $lc = $self->last_commit) {
2299 # we can have a branch that was deleted, then re-added
2300 # under the same name but copied from another path, in
2301 # which case we'll have multiple parents (we don't
2302 # want to break the original ref, nor lose copypath info):
2303 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2304 push @{$log_entry->{parents}}, $lc;
2305 return $log_entry;
2306 }
2307 $ed = SVN::Git::Fetcher->new($self);
2308 $last_rev = $self->{last_rev};
2309 $ed->{c} = $lc;
2310 @parents = ($lc);
2311 } else {
2312 $last_rev = $rev;
2313 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2314 return $log_entry;
2315 }
2316 $ed = SVN::Git::Fetcher->new($self);
2317 }
2318 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2319 die "SVN connection failed somewhere...\n";
2320 }
2321 $self->make_log_entry($rev, \@parents, $ed);
2322 }
2323
2324 sub get_untracked {
2325 my ($self, $ed) = @_;
2326 my @out;
2327 my $h = $ed->{empty};
2328 foreach (sort keys %$h) {
2329 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2330 push @out, " $act: " . uri_encode($_);
2331 warn "W: $act: $_\n";
2332 }
2333 foreach my $t (qw/dir_prop file_prop/) {
2334 $h = $ed->{$t} or next;
2335 foreach my $path (sort keys %$h) {
2336 my $ppath = $path eq '' ? '.' : $path;
2337 foreach my $prop (sort keys %{$h->{$path}}) {
2338 next if $SKIP_PROP{$prop};
2339 my $v = $h->{$path}->{$prop};
2340 my $t_ppath_prop = "$t: " .
2341 uri_encode($ppath) . ' ' .
2342 uri_encode($prop);
2343 if (defined $v) {
2344 push @out, " +$t_ppath_prop " .
2345 uri_encode($v);
2346 } else {
2347 push @out, " -$t_ppath_prop";
2348 }
2349 }
2350 }
2351 }
2352 foreach my $t (qw/absent_file absent_directory/) {
2353 $h = $ed->{$t} or next;
2354 foreach my $parent (sort keys %$h) {
2355 foreach my $path (sort @{$h->{$parent}}) {
2356 push @out, " $t: " .
2357 uri_encode("$parent/$path");
2358 warn "W: $t: $parent/$path ",
2359 "Insufficient permissions?\n";
2360 }
2361 }
2362 }
2363 \@out;
2364 }
2365
2366 sub parse_svn_date {
2367 my $date = shift || return '+0000 1970-01-01 00:00:00';
2368 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2369 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2370 croak "Unable to parse date: $date\n";
2371 "+0000 $Y-$m-$d $H:$M:$S";
2372 }
2373
2374 sub check_author {
2375 my ($author) = @_;
2376 if (!defined $author || length $author == 0) {
2377 $author = '(no author)';
2378 }
2379 if (defined $::_authors && ! defined $::users{$author}) {
2380 die "Author: $author not defined in $::_authors file\n";
2381 }
2382 $author;
2383 }
2384
2385 sub make_log_entry {
2386 my ($self, $rev, $parents, $ed) = @_;
2387 my $untracked = $self->get_untracked($ed);
2388
2389 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2390 print $un "r$rev\n" or croak $!;
2391 print $un $_, "\n" foreach @$untracked;
2392 my %log_entry = ( parents => $parents || [], revision => $rev,
2393 log => '');
2394
2395 my $headrev;
2396 my $logged = delete $self->{logged_rev_props};
2397 if (!$logged || $self->{-want_revprops}) {
2398 my $rp = $self->ra->rev_proplist($rev);
2399 foreach (sort keys %$rp) {
2400 my $v = $rp->{$_};
2401 if (/^svn:(author|date|log)$/) {
2402 $log_entry{$1} = $v;
2403 } elsif ($_ eq 'svm:headrev') {
2404 $headrev = $v;
2405 } else {
2406 print $un " rev_prop: ", uri_encode($_), ' ',
2407 uri_encode($v), "\n";
2408 }
2409 }
2410 } else {
2411 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2412 }
2413 close $un or croak $!;
2414
2415 $log_entry{date} = parse_svn_date($log_entry{date});
2416 $log_entry{log} .= "\n";
2417 my $author = $log_entry{author} = check_author($log_entry{author});
2418 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2419 : ($author, undef);
2420
2421 my ($commit_name, $commit_email) = ($name, $email);
2422 if ($_use_log_author) {
2423 my $name_field;
2424 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2425 $name_field = $1;
2426 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2427 $name_field = $1;
2428 }
2429 if (!defined $name_field) {
2430 #
2431 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2432 ($name, $email) = ($1, $2);
2433 } elsif ($name_field =~ /(.*)@/) {
2434 ($name, $email) = ($1, $name_field);
2435 } else {
2436 ($name, $email) = ($name_field, 'unknown');
2437 }
2438 }
2439 if (defined $headrev && $self->use_svm_props) {
2440 if ($self->rewrite_root) {
2441 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2442 "options set!\n";
2443 }
2444 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2445 # we don't want "SVM: initializing mirror for junk" ...
2446 return undef if $r == 0;
2447 my $svm = $self->svm;
2448 if ($uuid ne $svm->{uuid}) {
2449 die "UUID mismatch on SVM path:\n",
2450 "expected: $svm->{uuid}\n",
2451 " got: $uuid\n";
2452 }
2453 my $full_url = $self->full_url;
2454 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2455 die "Failed to replace '$svm->{replace}' with ",
2456 "'$svm->{source}' in $full_url\n";
2457 # throw away username for storing in records
2458 remove_username($full_url);
2459 $log_entry{metadata} = "$full_url\@$r $uuid";
2460 $log_entry{svm_revision} = $r;
2461 $email ||= "$author\@$uuid";
2462 $commit_email ||= "$author\@$uuid";
2463 } elsif ($self->use_svnsync_props) {
2464 my $full_url = $self->svnsync->{url};
2465 $full_url .= "/$self->{path}" if length $self->{path};
2466 remove_username($full_url);
2467 my $uuid = $self->svnsync->{uuid};
2468 $log_entry{metadata} = "$full_url\@$rev $uuid";
2469 $email ||= "$author\@$uuid";
2470 $commit_email ||= "$author\@$uuid";
2471 } else {
2472 my $url = $self->metadata_url;
2473 remove_username($url);
2474 $log_entry{metadata} = "$url\@$rev " .
2475 $self->ra->get_uuid;
2476 $email ||= "$author\@" . $self->ra->get_uuid;
2477 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2478 }
2479 $log_entry{name} = $name;
2480 $log_entry{email} = $email;
2481 $log_entry{commit_name} = $commit_name;
2482 $log_entry{commit_email} = $commit_email;
2483 \%log_entry;
2484 }
2485
2486 sub fetch {
2487 my ($self, $min_rev, $max_rev, @parents) = @_;
2488 my ($last_rev, $last_commit) = $self->last_rev_commit;
2489 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2490 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2491 }
2492
2493 sub set_tree_cb {
2494 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2495 $self->{inject_parents} = { $rev => $tree };
2496 $self->fetch(undef, undef);
2497 }
2498
2499 sub set_tree {
2500 my ($self, $tree) = (shift, shift);
2501 my $log_entry = ::get_commit_entry($tree);
2502 unless ($self->{last_rev}) {
2503 fatal("Must have an existing revision to commit");
2504 }
2505 my %ed_opts = ( r => $self->{last_rev},
2506 log => $log_entry->{log},
2507 ra => $self->ra,
2508 tree_a => $self->{last_commit},
2509 tree_b => $tree,
2510 editor_cb => sub {
2511 $self->set_tree_cb($log_entry, $tree, @_) },
2512 svn_path => $self->{path} );
2513 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2514 print "No changes\nr$self->{last_rev} = $tree\n";
2515 }
2516 }
2517
2518 sub rebuild_from_rev_db {
2519 my ($self, $path) = @_;
2520 my $r = -1;
2521 open my $fh, '<', $path or croak "open: $!";
2522 while (<$fh>) {
2523 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2524 chomp($_);
2525 ++$r;
2526 next if $_ eq ('0' x 40);
2527 $self->rev_map_set($r, $_);
2528 print "r$r = $_\n";
2529 }
2530 close $fh or croak "close: $!";
2531 unlink $path or croak "unlink: $!";
2532 }
2533
2534 sub rebuild {
2535 my ($self) = @_;
2536 my $map_path = $self->map_path;
2537 return if (-e $map_path && ! -z $map_path);
2538 return unless ::verify_ref($self->refname.'^0');
2539 if ($self->use_svm_props || $self->no_metadata) {
2540 my $rev_db = $self->rev_db_path;
2541 $self->rebuild_from_rev_db($rev_db);
2542 if ($self->use_svm_props) {
2543 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2544 $self->rebuild_from_rev_db($svm_rev_db);
2545 }
2546 $self->unlink_rev_db_symlink;
2547 return;
2548 }
2549 print "Rebuilding $map_path ...\n";
2550 my ($log, $ctx) =
2551 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2552 $self->refname, '--');
2553 my $full_url = $self->full_url;
2554 remove_username($full_url);
2555 my $svn_uuid = $self->ra_uuid;
2556 my $c;
2557 while (<$log>) {
2558 if ( m{^commit ($::sha1)$} ) {
2559 $c = $1;
2560 next;
2561 }
2562 next unless s{^\s*(git-svn-id:)}{$1};
2563 my ($url, $rev, $uuid) = ::extract_metadata($_);
2564 remove_username($url);
2565
2566 # ignore merges (from set-tree)
2567 next if (!defined $rev || !$uuid);
2568
2569 # if we merged or otherwise started elsewhere, this is
2570 # how we break out of it
2571 if (($uuid ne $svn_uuid) ||
2572 ($full_url && $url && ($url ne $full_url))) {
2573 next;
2574 }
2575
2576 $self->rev_map_set($rev, $c);
2577 print "r$rev = $c\n";
2578 }
2579 command_close_pipe($log, $ctx);
2580 print "Done rebuilding $map_path\n";
2581 my $rev_db_path = $self->rev_db_path;
2582 if (-f $self->rev_db_path) {
2583 unlink $self->rev_db_path or croak "unlink: $!";
2584 }
2585 $self->unlink_rev_db_symlink;
2586 }
2587
2588 # rev_map:
2589 # Tie::File seems to be prone to offset errors if revisions get sparse,
2590 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2591 # one of my favorite modules is out :< Next up would be one of the DBM
2592 # modules, but I'm not sure which is most portable...
2593 #
2594 # This is the replacement for the rev_db format, which was too big
2595 # and inefficient for large repositories with a lot of sparse history
2596 # (mainly tags)
2597 #
2598 # The format is this:
2599 # - 24 bytes for every record,
2600 # * 4 bytes for the integer representing an SVN revision number
2601 # * 20 bytes representing the sha1 of a git commit
2602 # - No empty padding records like the old format
2603 # (except the last record, which can be overwritten)
2604 # - new records are written append-only since SVN revision numbers
2605 # increase monotonically
2606 # - lookups on SVN revision number are done via a binary search
2607 # - Piping the file to xxd -c24 is a good way of dumping it for
2608 # viewing or editing (piped back through xxd -r), should the need
2609 # ever arise.
2610 # - The last record can be padding revision with an all-zero sha1
2611 # This is used to optimize fetch performance when using multiple
2612 # "fetch" directives in .git/config
2613 #
2614 # These files are disposable unless noMetadata or useSvmProps is set
2615
2616 sub _rev_map_set {
2617 my ($fh, $rev, $commit) = @_;
2618
2619 my $size = (stat($fh))[7];
2620 ($size % 24) == 0 or croak "inconsistent size: $size";
2621
2622 my $wr_offset = 0;
2623 if ($size > 0) {
2624 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2625 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2626 $read == 24 or croak "read only $read bytes (!= 24)";
2627 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2628 if ($last_commit eq ('0' x40)) {
2629 if ($size >= 48) {
2630 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2631 $read = sysread($fh, $buf, 24) or
2632 croak "read: $!";
2633 $read == 24 or
2634 croak "read only $read bytes (!= 24)";
2635 ($last_rev, $last_commit) =
2636 unpack(rev_map_fmt, $buf);
2637 if ($last_commit eq ('0' x40)) {
2638 croak "inconsistent .rev_map\n";
2639 }
2640 }
2641 if ($last_rev >= $rev) {
2642 croak "last_rev is higher!: $last_rev >= $rev";
2643 }
2644 $wr_offset = -24;
2645 }
2646 }
2647 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2648 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2649 croak "write: $!";
2650 }
2651
2652 sub mkfile {
2653 my ($path) = @_;
2654 unless (-e $path) {
2655 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2656 mkpath([$dir]) unless -d $dir;
2657 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2658 close $fh or die "Couldn't close (create) $path: $!\n";
2659 }
2660 }
2661
2662 sub rev_map_set {
2663 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2664 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2665 my $db = $self->map_path($uuid);
2666 my $db_lock = "$db.lock";
2667 my $sig;
2668 if ($update_ref) {
2669 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2670 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2671 }
2672 mkfile($db);
2673
2674 $LOCKFILES{$db_lock} = 1;
2675 my $sync;
2676 # both of these options make our .rev_db file very, very important
2677 # and we can't afford to lose it because rebuild() won't work
2678 if ($self->use_svm_props || $self->no_metadata) {
2679 $sync = 1;
2680 copy($db, $db_lock) or die "rev_map_set(@_): ",
2681 "Failed to copy: ",
2682 "$db => $db_lock ($!)\n";
2683 } else {
2684 rename $db, $db_lock or die "rev_map_set(@_): ",
2685 "Failed to rename: ",
2686 "$db => $db_lock ($!)\n";
2687 }
2688
2689 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2690 or croak "Couldn't open $db_lock: $!\n";
2691 _rev_map_set($fh, $rev, $commit);
2692 if ($sync) {
2693 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2694 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2695 }
2696 close $fh or croak $!;
2697 if ($update_ref) {
2698 $_head = $self;
2699 command_noisy('update-ref', '-m', "r$rev",
2700 $self->refname, $commit);
2701 }
2702 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2703 "$db_lock => $db ($!)\n";
2704 delete $LOCKFILES{$db_lock};
2705 if ($update_ref) {
2706 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2707 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2708 kill $sig, $$ if defined $sig;
2709 }
2710 }
2711
2712 # If want_commit, this will return an array of (rev, commit) where
2713 # commit _must_ be a valid commit in the archive.
2714 # Otherwise, it'll return the max revision (whether or not the
2715 # commit is valid or just a 0x40 placeholder).
2716 sub rev_map_max {
2717 my ($self, $want_commit) = @_;
2718 $self->rebuild;
2719 my $map_path = $self->map_path;
2720 stat $map_path or return $want_commit ? (0, undef) : 0;
2721 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2722 my $size = (stat($fh))[7];
2723 ($size % 24) == 0 or croak "inconsistent size: $size";
2724
2725 if ($size == 0) {
2726 close $fh or croak "close: $!";
2727 return $want_commit ? (0, undef) : 0;
2728 }
2729
2730 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2731 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2732 my ($r, $c) = unpack(rev_map_fmt, $buf);
2733 if ($want_commit && $c eq ('0' x40)) {
2734 if ($size < 48) {
2735 return $want_commit ? (0, undef) : 0;
2736 }
2737 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2738 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2739 ($r, $c) = unpack(rev_map_fmt, $buf);
2740 if ($c eq ('0'x40)) {
2741 croak "Penultimate record is all-zeroes in $map_path";
2742 }
2743 }
2744 close $fh or croak "close: $!";
2745 $want_commit ? ($r, $c) : $r;
2746 }
2747
2748 sub rev_map_get {
2749 my ($self, $rev, $uuid) = @_;
2750 my $map_path = $self->map_path($uuid);
2751 return undef unless -e $map_path;
2752
2753 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2754 my $size = (stat($fh))[7];
2755 ($size % 24) == 0 or croak "inconsistent size: $size";
2756
2757 if ($size == 0) {
2758 close $fh or croak "close: $fh";
2759 return undef;
2760 }
2761
2762 my ($l, $u) = (0, $size - 24);
2763 my ($r, $c, $buf);
2764
2765 while ($l <= $u) {
2766 my $i = int(($l/24 + $u/24) / 2) * 24;
2767 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2768 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2769 my ($r, $c) = unpack('NH40', $buf);
2770
2771 if ($r < $rev) {
2772 $l = $i + 24;
2773 } elsif ($r > $rev) {
2774 $u = $i - 24;
2775 } else { # $r == $rev
2776 close($fh) or croak "close: $!";
2777 return $c eq ('0' x 40) ? undef : $c;
2778 }
2779 }
2780 close($fh) or croak "close: $!";
2781 undef;
2782 }
2783
2784 # Finds the first svn revision that exists on (if $eq_ok is true) or
2785 # before $rev for the current branch. It will not search any lower
2786 # than $min_rev. Returns the git commit hash and svn revision number
2787 # if found, else (undef, undef).
2788 sub find_rev_before {
2789 my ($self, $rev, $eq_ok, $min_rev) = @_;
2790 --$rev unless $eq_ok;
2791 $min_rev ||= 1;
2792 while ($rev >= $min_rev) {
2793 if (my $c = $self->rev_map_get($rev)) {
2794 return ($rev, $c);
2795 }
2796 --$rev;
2797 }
2798 return (undef, undef);
2799 }
2800
2801 # Finds the first svn revision that exists on (if $eq_ok is true) or
2802 # after $rev for the current branch. It will not search any higher
2803 # than $max_rev. Returns the git commit hash and svn revision number
2804 # if found, else (undef, undef).
2805 sub find_rev_after {
2806 my ($self, $rev, $eq_ok, $max_rev) = @_;
2807 ++$rev unless $eq_ok;
2808 $max_rev ||= $self->rev_map_max;
2809 while ($rev <= $max_rev) {
2810 if (my $c = $self->rev_map_get($rev)) {
2811 return ($rev, $c);
2812 }
2813 ++$rev;
2814 }
2815 return (undef, undef);
2816 }
2817
2818 sub _new {
2819 my ($class, $repo_id, $ref_id, $path) = @_;
2820 unless (defined $repo_id && length $repo_id) {
2821 $repo_id = $Git::SVN::default_repo_id;
2822 }
2823 unless (defined $ref_id && length $ref_id) {
2824 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2825 }
2826 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2827 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2828 $_[3] = $path = '' unless (defined $path);
2829 mkpath(["$ENV{GIT_DIR}/svn"]);
2830 bless {
2831 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2832 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2833 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2834 }
2835
2836 # for read-only access of old .rev_db formats
2837 sub unlink_rev_db_symlink {
2838 my ($self) = @_;
2839 my $link = $self->rev_db_path;
2840 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2841 if (-l $link) {
2842 unlink $link or croak "unlink: $link failed!";
2843 }
2844 }
2845
2846 sub rev_db_path {
2847 my ($self, $uuid) = @_;
2848 my $db_path = $self->map_path($uuid);
2849 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2850 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2851 $db_path;
2852 }
2853
2854 # the new replacement for .rev_db
2855 sub map_path {
2856 my ($self, $uuid) = @_;
2857 $uuid ||= $self->ra_uuid;
2858 "$self->{map_root}.$uuid";
2859 }
2860
2861 sub uri_encode {
2862 my ($f) = @_;
2863 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2864 $f
2865 }
2866
2867 sub remove_username {
2868 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2869 }
2870
2871 package Git::SVN::Prompt;
2872 use strict;
2873 use warnings;
2874 require SVN::Core;
2875 use vars qw/$_no_auth_cache $_username/;
2876
2877 sub simple {
2878 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2879 $may_save = undef if $_no_auth_cache;
2880 $default_username = $_username if defined $_username;
2881 if (defined $default_username && length $default_username) {
2882 if (defined $realm && length $realm) {
2883 print STDERR "Authentication realm: $realm\n";
2884 STDERR->flush;
2885 }
2886 $cred->username($default_username);
2887 } else {
2888 username($cred, $realm, $may_save, $pool);
2889 }
2890 $cred->password(_read_password("Password for '" .
2891 $cred->username . "': ", $realm));
2892 $cred->may_save($may_save);
2893 $SVN::_Core::SVN_NO_ERROR;
2894 }
2895
2896 sub ssl_server_trust {
2897 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2898 $may_save = undef if $_no_auth_cache;
2899 print STDERR "Error validating server certificate for '$realm':\n";
2900 {
2901 no warnings 'once';
2902 # All variables SVN::Auth::SSL::* are used only once,
2903 # so we're shutting up Perl warnings about this.
2904 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2905 print STDERR " - The certificate is not issued ",
2906 "by a trusted authority. Use the\n",
2907 " fingerprint to validate ",
2908 "the certificate manually!\n";
2909 }
2910 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2911 print STDERR " - The certificate hostname ",
2912 "does not match.\n";
2913 }
2914 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2915 print STDERR " - The certificate is not yet valid.\n";
2916 }
2917 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2918 print STDERR " - The certificate has expired.\n";
2919 }
2920 if ($failures & $SVN::Auth::SSL::OTHER) {
2921 print STDERR " - The certificate has ",
2922 "an unknown error.\n";
2923 }
2924 } # no warnings 'once'
2925 printf STDERR
2926 "Certificate information:\n".
2927 " - Hostname: %s\n".
2928 " - Valid: from %s until %s\n".
2929 " - Issuer: %s\n".
2930 " - Fingerprint: %s\n",
2931 map $cert_info->$_, qw(hostname valid_from valid_until
2932 issuer_dname fingerprint);
2933 my $choice;
2934 prompt:
2935 print STDERR $may_save ?
2936 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2937 "(R)eject or accept (t)emporarily? ";
2938 STDERR->flush;
2939 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2940 if ($choice =~ /^t$/i) {
2941 $cred->may_save(undef);
2942 } elsif ($choice =~ /^r$/i) {
2943 return -1;
2944 } elsif ($may_save && $choice =~ /^p$/i) {
2945 $cred->may_save($may_save);
2946 } else {
2947 goto prompt;
2948 }
2949 $cred->accepted_failures($failures);
2950 $SVN::_Core::SVN_NO_ERROR;
2951 }
2952
2953 sub ssl_client_cert {
2954 my ($cred, $realm, $may_save, $pool) = @_;
2955 $may_save = undef if $_no_auth_cache;
2956 print STDERR "Client certificate filename: ";
2957 STDERR->flush;
2958 chomp(my $filename = <STDIN>);
2959 $cred->cert_file($filename);
2960 $cred->may_save($may_save);
2961 $SVN::_Core::SVN_NO_ERROR;
2962 }
2963
2964 sub ssl_client_cert_pw {
2965 my ($cred, $realm, $may_save, $pool) = @_;
2966 $may_save = undef if $_no_auth_cache;
2967 $cred->password(_read_password("Password: ", $realm));
2968 $cred->may_save($may_save);
2969 $SVN::_Core::SVN_NO_ERROR;
2970 }
2971
2972 sub username {
2973 my ($cred, $realm, $may_save, $pool) = @_;
2974 $may_save = undef if $_no_auth_cache;
2975 if (defined $realm && length $realm) {
2976 print STDERR "Authentication realm: $realm\n";
2977 }
2978 my $username;
2979 if (defined $_username) {
2980 $username = $_username;
2981 } else {
2982 print STDERR "Username: ";
2983 STDERR->flush;
2984 chomp($username = <STDIN>);
2985 }
2986 $cred->username($username);
2987 $cred->may_save($may_save);
2988 $SVN::_Core::SVN_NO_ERROR;
2989 }
2990
2991 sub _read_password {
2992 my ($prompt, $realm) = @_;
2993 print STDERR $prompt;
2994 STDERR->flush;
2995 require Term::ReadKey;
2996 Term::ReadKey::ReadMode('noecho');
2997 my $password = '';
2998 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2999 last if $key =~ /[\012\015]/; # \n\r
3000 $password .= $key;
3001 }
3002 Term::ReadKey::ReadMode('restore');
3003 print STDERR "\n";
3004 STDERR->flush;
3005 $password;
3006 }
3007
3008 package SVN::Git::Fetcher;
3009 use vars qw/@ISA/;
3010 use strict;
3011 use warnings;
3012 use Carp qw/croak/;
3013 use IO::File qw//;
3014
3015 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3016 sub new {
3017 my ($class, $git_svn) = @_;
3018 my $self = SVN::Delta::Editor->new;
3019 bless $self, $class;
3020 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3021 $self->{empty} = {};
3022 $self->{dir_prop} = {};
3023 $self->{file_prop} = {};
3024 $self->{absent_dir} = {};
3025 $self->{absent_file} = {};
3026 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3027 $self;
3028 }
3029
3030 sub set_path_strip {
3031 my ($self, $path) = @_;
3032 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3033 }
3034
3035 sub open_root {
3036 { path => '' };
3037 }
3038
3039 sub open_directory {
3040 my ($self, $path, $pb, $rev) = @_;
3041 { path => $path };
3042 }
3043
3044 sub git_path {
3045 my ($self, $path) = @_;
3046 if ($self->{path_strip}) {
3047 $path =~ s!$self->{path_strip}!! or
3048 die "Failed to strip path '$path' ($self->{path_strip})\n";
3049 }
3050 $path;
3051 }
3052
3053 sub delete_entry {
3054 my ($self, $path, $rev, $pb) = @_;
3055
3056 my $gpath = $self->git_path($path);
3057 return undef if ($gpath eq '');
3058
3059 # remove entire directories.
3060 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3061 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3062 -r --name-only -z/,
3063 $self->{c}, '--', $gpath);
3064 local $/ = "\0";
3065 while (<$ls>) {
3066 chomp;
3067 $self->{gii}->remove($_);
3068 print "\tD\t$_\n" unless $::_q;
3069 }
3070 print "\tD\t$gpath/\n" unless $::_q;
3071 command_close_pipe($ls, $ctx);
3072 $self->{empty}->{$path} = 0
3073 } else {
3074 $self->{gii}->remove($gpath);
3075 print "\tD\t$gpath\n" unless $::_q;
3076 }
3077 undef;
3078 }
3079
3080 sub open_file {
3081 my ($self, $path, $pb, $rev) = @_;
3082 my $gpath = $self->git_path($path);
3083 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3084 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3085 unless (defined $mode && defined $blob) {
3086 die "$path was not found in commit $self->{c} (r$rev)\n";
3087 }
3088 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3089 pool => SVN::Pool->new, action => 'M' };
3090 }
3091
3092 sub add_file {
3093 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3094 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3095 delete $self->{empty}->{$dir};
3096 { path => $path, mode_a => 100644, mode_b => 100644,
3097 pool => SVN::Pool->new, action => 'A' };
3098 }
3099
3100 sub add_directory {
3101 my ($self, $path, $cp_path, $cp_rev) = @_;
3102 my $gpath = $self->git_path($path);
3103 if ($gpath eq '') {
3104 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3105 -r --name-only -z/,
3106 $self->{c});
3107 local $/ = "\0";
3108 while (<$ls>) {
3109 chomp;
3110 $self->{gii}->remove($_);
3111 print "\tD\t$_\n" unless $::_q;
3112 }
3113 command_close_pipe($ls, $ctx);
3114 $self->{empty}->{$path} = 0;
3115 }
3116 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3117 delete $self->{empty}->{$dir};
3118 $self->{empty}->{$path} = 1;
3119 { path => $path };
3120 }
3121
3122 sub change_dir_prop {
3123 my ($self, $db, $prop, $value) = @_;
3124 $self->{dir_prop}->{$db->{path}} ||= {};
3125 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3126 undef;
3127 }
3128
3129 sub absent_directory {
3130 my ($self, $path, $pb) = @_;
3131 $self->{absent_dir}->{$pb->{path}} ||= [];
3132 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3133 undef;
3134 }
3135
3136 sub absent_file {
3137 my ($self, $path, $pb) = @_;
3138 $self->{absent_file}->{$pb->{path}} ||= [];
3139 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3140 undef;
3141 }
3142
3143 sub change_file_prop {
3144 my ($self, $fb, $prop, $value) = @_;
3145 if ($prop eq 'svn:executable') {
3146 if ($fb->{mode_b} != 120000) {
3147 $fb->{mode_b} = defined $value ? 100755 : 100644;
3148 }
3149 } elsif ($prop eq 'svn:special') {
3150 $fb->{mode_b} = defined $value ? 120000 : 100644;
3151 } else {
3152 $self->{file_prop}->{$fb->{path}} ||= {};
3153 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3154 }
3155 undef;
3156 }
3157
3158 sub apply_textdelta {
3159 my ($self, $fb, $exp) = @_;
3160 my $fh = IO::File->new_tmpfile;
3161 $fh->autoflush(1);
3162 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3163 # (but $base does not,) so dup() it for reading in close_file
3164 open my $dup, '<&', $fh or croak $!;
3165 my $base = IO::File->new_tmpfile;
3166 $base->autoflush(1);
3167 if ($fb->{blob}) {
3168 defined (my $pid = fork) or croak $!;
3169 if (!$pid) {
3170 open STDOUT, '>&', $base or croak $!;
3171 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3172 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3173 }
3174 waitpid $pid, 0;
3175 croak $? if $?;
3176
3177 if (defined $exp) {
3178 seek $base, 0, 0 or croak $!;
3179 my $got = ::md5sum($base);
3180 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3181 "expected: $exp\n",
3182 " got: $got\n" if ($got ne $exp);
3183 }
3184 }
3185 seek $base, 0, 0 or croak $!;
3186 $fb->{fh} = $dup;
3187 $fb->{base} = $base;
3188 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3189 }
3190
3191 sub close_file {
3192 my ($self, $fb, $exp) = @_;
3193 my $hash;
3194 my $path = $self->git_path($fb->{path});
3195 if (my $fh = $fb->{fh}) {
3196 if (defined $exp) {
3197 seek($fh, 0, 0) or croak $!;
3198 my $got = ::md5sum($fh);
3199 if ($got ne $exp) {
3200 die "Checksum mismatch: $path\n",
3201 "expected: $exp\n got: $got\n";
3202 }
3203 }
3204 sysseek($fh, 0, 0) or croak $!;
3205 if ($fb->{mode_b} == 120000) {
3206 eval {
3207 sysread($fh, my $buf, 5) == 5 or croak $!;
3208 $buf eq 'link ' or die "$path has mode 120000",
3209 " but is not a link";
3210 };
3211 if ($@) {
3212 warn "$@\n";
3213 sysseek($fh, 0, 0) or croak $!;
3214 }
3215 }
3216 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3217 if (!$pid) {
3218 open STDIN, '<&', $fh or croak $!;
3219 exec qw/git-hash-object -w --stdin/ or croak $!;
3220 }
3221 chomp($hash = do { local $/; <$out> });
3222 close $out or croak $!;
3223 close $fh or croak $!;
3224 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3225 close $fb->{base} or croak $!;
3226 } else {
3227 $hash = $fb->{blob} or die "no blob information\n";
3228 }
3229 $fb->{pool}->clear;
3230 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3231 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3232 undef;
3233 }
3234
3235 sub abort_edit {
3236 my $self = shift;
3237 $self->{nr} = $self->{gii}->{nr};
3238 delete $self->{gii};
3239 $self->SUPER::abort_edit(@_);
3240 }
3241
3242 sub close_edit {
3243 my $self = shift;
3244 $self->{git_commit_ok} = 1;
3245 $self->{nr} = $self->{gii}->{nr};
3246 delete $self->{gii};
3247 $self->SUPER::close_edit(@_);
3248 }
3249
3250 package SVN::Git::Editor;
3251 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3252 use strict;
3253 use warnings;
3254 use Carp qw/croak/;
3255 use IO::File;
3256
3257 sub new {
3258 my ($class, $opts) = @_;
3259 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3260 die "$_ required!\n" unless (defined $opts->{$_});
3261 }
3262
3263 my $pool = SVN::Pool->new;
3264 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3265 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3266 $opts->{r}, $mods);
3267
3268 # $opts->{ra} functions should not be used after this:
3269 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3270 $opts->{editor_cb}, $pool);
3271 my $self = SVN::Delta::Editor->new(@ce, $pool);
3272 bless $self, $class;
3273 foreach (qw/svn_path r tree_a tree_b/) {
3274 $self->{$_} = $opts->{$_};
3275 }
3276 $self->{url} = $opts->{ra}->{url};
3277 $self->{mods} = $mods;
3278 $self->{types} = $types;
3279 $self->{pool} = $pool;
3280 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3281 $self->{rm} = { };
3282 $self->{path_prefix} = length $self->{svn_path} ?
3283 "$self->{svn_path}/" : '';
3284 return $self;
3285 }
3286
3287 sub generate_diff {
3288 my ($tree_a, $tree_b) = @_;
3289 my @diff_tree = qw(diff-tree -z -r);
3290 if ($_cp_similarity) {
3291 push @diff_tree, "-C$_cp_similarity";
3292 } else {
3293 push @diff_tree, '-C';
3294 }
3295 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3296 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3297 push @diff_tree, $tree_a, $tree_b;
3298 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3299 local $/ = "\0";
3300 my $state = 'meta';
3301 my @mods;
3302 while (<$diff_fh>) {
3303 chomp $_; # this gets rid of the trailing "\0"
3304 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3305 $::sha1\s($::sha1)\s
3306 ([MTCRAD])\d*$/xo) {
3307 push @mods, { mode_a => $1, mode_b => $2,
3308 sha1_b => $3, chg => $4 };
3309 if ($4 =~ /^(?:C|R)$/) {
3310 $state = 'file_a';
3311 } else {
3312 $state = 'file_b';
3313 }
3314 } elsif ($state eq 'file_a') {
3315 my $x = $mods[$#mods] or croak "Empty array\n";
3316 if ($x->{chg} !~ /^(?:C|R)$/) {
3317 croak "Error parsing $_, $x->{chg}\n";
3318 }
3319 $x->{file_a} = $_;
3320 $state = 'file_b';
3321 } elsif ($state eq 'file_b') {
3322 my $x = $mods[$#mods] or croak "Empty array\n";
3323 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3324 croak "Error parsing $_, $x->{chg}\n";
3325 }
3326 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3327 croak "Error parsing $_, $x->{chg}\n";
3328 }
3329 $x->{file_b} = $_;
3330 $state = 'meta';
3331 } else {
3332 croak "Error parsing $_\n";
3333 }
3334 }
3335 command_close_pipe($diff_fh, $ctx);
3336 \@mods;
3337 }
3338
3339 sub check_diff_paths {
3340 my ($ra, $pfx, $rev, $mods) = @_;
3341 my %types;
3342 $pfx .= '/' if length $pfx;
3343
3344 sub type_diff_paths {
3345 my ($ra, $types, $path, $rev) = @_;
3346 my @p = split m#/+#, $path;
3347 my $c = shift @p;
3348 unless (defined $types->{$c}) {
3349 $types->{$c} = $ra->check_path($c, $rev);
3350 }
3351 while (@p) {
3352 $c .= '/' . shift @p;
3353 next if defined $types->{$c};
3354 $types->{$c} = $ra->check_path($c, $rev);
3355 }
3356 }
3357
3358 foreach my $m (@$mods) {
3359 foreach my $f (qw/file_a file_b/) {
3360 next unless defined $m->{$f};
3361 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3362 if (length $pfx.$dir && ! defined $types{$dir}) {
3363 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3364 }
3365 }
3366 }
3367 \%types;
3368 }
3369
3370 sub split_path {
3371 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3372 }
3373
3374 sub repo_path {
3375 my ($self, $path) = @_;
3376 $self->{path_prefix}.(defined $path ? $path : '');
3377 }
3378
3379 sub url_path {
3380 my ($self, $path) = @_;
3381 if ($self->{url} =~ m#^https?://#) {
3382 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3383 }
3384 $self->{url} . '/' . $self->repo_path($path);
3385 }
3386
3387 sub rmdirs {
3388 my ($self) = @_;
3389 my $rm = $self->{rm};
3390 delete $rm->{''}; # we never delete the url we're tracking
3391 return unless %$rm;
3392
3393 foreach (keys %$rm) {
3394 my @d = split m#/#, $_;
3395 my $c = shift @d;
3396 $rm->{$c} = 1;
3397 while (@d) {
3398 $c .= '/' . shift @d;
3399 $rm->{$c} = 1;
3400 }
3401 }
3402 delete $rm->{$self->{svn_path}};
3403 delete $rm->{''}; # we never delete the url we're tracking
3404 return unless %$rm;
3405
3406 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3407 $self->{tree_b});
3408 local $/ = "\0";
3409 while (<$fh>) {
3410 chomp;
3411 my @dn = split m#/#, $_;
3412 while (pop @dn) {
3413 delete $rm->{join '/', @dn};
3414 }
3415 unless (%$rm) {
3416 close $fh;
3417 return;
3418 }
3419 }
3420 command_close_pipe($fh, $ctx);
3421
3422 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3423 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3424 $self->close_directory($bat->{$d}, $p);
3425 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3426 print "\tD+\t$d/\n" unless $::_q;
3427 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3428 delete $bat->{$d};
3429 }
3430 }
3431
3432 sub open_or_add_dir {
3433 my ($self, $full_path, $baton) = @_;
3434 my $t = $self->{types}->{$full_path};
3435 if (!defined $t) {
3436 die "$full_path not known in r$self->{r} or we have a bug!\n";
3437 }
3438 {
3439 no warnings 'once';
3440 # SVN::Node::none and SVN::Node::file are used only once,
3441 # so we're shutting up Perl's warnings about them.
3442 if ($t == $SVN::Node::none) {
3443 return $self->add_directory($full_path, $baton,
3444 undef, -1, $self->{pool});
3445 } elsif ($t == $SVN::Node::dir) {
3446 return $self->open_directory($full_path, $baton,
3447 $self->{r}, $self->{pool});
3448 } # no warnings 'once'
3449 print STDERR "$full_path already exists in repository at ",
3450 "r$self->{r} and it is not a directory (",
3451 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3452 } # no warnings 'once'
3453 exit 1;
3454 }
3455
3456 sub ensure_path {
3457 my ($self, $path) = @_;
3458 my $bat = $self->{bat};
3459 my $repo_path = $self->repo_path($path);
3460 return $bat->{''} unless (length $repo_path);
3461 my @p = split m#/+#, $repo_path;
3462 my $c = shift @p;
3463 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3464 while (@p) {
3465 my $c0 = $c;
3466 $c .= '/' . shift @p;
3467 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3468 }
3469 return $bat->{$c};
3470 }
3471
3472 sub A {
3473 my ($self, $m) = @_;
3474 my ($dir, $file) = split_path($m->{file_b});
3475 my $pbat = $self->ensure_path($dir);
3476 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3477 undef, -1);
3478 print "\tA\t$m->{file_b}\n" unless $::_q;
3479 $self->chg_file($fbat, $m);
3480 $self->close_file($fbat,undef,$self->{pool});
3481 }
3482
3483 sub C {
3484 my ($self, $m) = @_;
3485 my ($dir, $file) = split_path($m->{file_b});
3486 my $pbat = $self->ensure_path($dir);
3487 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3488 $self->url_path($m->{file_a}), $self->{r});
3489 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3490 $self->chg_file($fbat, $m);
3491 $self->close_file($fbat,undef,$self->{pool});
3492 }
3493
3494 sub delete_entry {
3495 my ($self, $path, $pbat) = @_;
3496 my $rpath = $self->repo_path($path);
3497 my ($dir, $file) = split_path($rpath);
3498 $self->{rm}->{$dir} = 1;
3499 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3500 }
3501
3502 sub R {
3503 my ($self, $m) = @_;
3504 my ($dir, $file) = split_path($m->{file_b});
3505 my $pbat = $self->ensure_path($dir);
3506 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3507 $self->url_path($m->{file_a}), $self->{r});
3508 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3509 $self->chg_file($fbat, $m);
3510 $self->close_file($fbat,undef,$self->{pool});
3511
3512 ($dir, $file) = split_path($m->{file_a});
3513 $pbat = $self->ensure_path($dir);
3514 $self->delete_entry($m->{file_a}, $pbat);
3515 }
3516
3517 sub M {
3518 my ($self, $m) = @_;
3519 my ($dir, $file) = split_path($m->{file_b});
3520 my $pbat = $self->ensure_path($dir);
3521 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3522 $pbat,$self->{r},$self->{pool});
3523 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3524 $self->chg_file($fbat, $m);
3525 $self->close_file($fbat,undef,$self->{pool});
3526 }
3527
3528 sub T { shift->M(@_) }
3529
3530 sub change_file_prop {
3531 my ($self, $fbat, $pname, $pval) = @_;
3532 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3533 }
3534
3535 sub chg_file {
3536 my ($self, $fbat, $m) = @_;
3537 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3538 $self->change_file_prop($fbat,'svn:executable','*');
3539 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3540 $self->change_file_prop($fbat,'svn:executable',undef);
3541 }
3542 my $fh = IO::File->new_tmpfile or croak $!;
3543 if ($m->{mode_b} =~ /^120/) {
3544 print $fh 'link ' or croak $!;
3545 $self->change_file_prop($fbat,'svn:special','*');
3546 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3547 $self->change_file_prop($fbat,'svn:special',undef);
3548 }
3549 defined(my $pid = fork) or croak $!;
3550 if (!$pid) {
3551 open STDOUT, '>&', $fh or croak $!;
3552 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3553 }
3554 waitpid $pid, 0;
3555 croak $? if $?;
3556 $fh->flush == 0 or croak $!;
3557 seek $fh, 0, 0 or croak $!;
3558
3559 my $exp = ::md5sum($fh);
3560 seek $fh, 0, 0 or croak $!;
3561
3562 my $pool = SVN::Pool->new;
3563 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3564 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3565 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3566 $pool->clear;
3567
3568 close $fh or croak $!;
3569 }
3570
3571 sub D {
3572 my ($self, $m) = @_;
3573 my ($dir, $file) = split_path($m->{file_b});
3574 my $pbat = $self->ensure_path($dir);
3575 print "\tD\t$m->{file_b}\n" unless $::_q;
3576 $self->delete_entry($m->{file_b}, $pbat);
3577 }
3578
3579 sub close_edit {
3580 my ($self) = @_;
3581 my ($p,$bat) = ($self->{pool}, $self->{bat});
3582 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3583 next if $_ eq '';
3584 $self->close_directory($bat->{$_}, $p);
3585 }
3586 $self->close_directory($bat->{''}, $p);
3587 $self->SUPER::close_edit($p);
3588 $p->clear;
3589 }
3590
3591 sub abort_edit {
3592 my ($self) = @_;
3593 $self->SUPER::abort_edit($self->{pool});
3594 }
3595
3596 sub DESTROY {
3597 my $self = shift;
3598 $self->SUPER::DESTROY(@_);
3599 $self->{pool}->clear;
3600 }
3601
3602 # this drives the editor
3603 sub apply_diff {
3604 my ($self) = @_;
3605 my $mods = $self->{mods};
3606 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3607 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3608 my $f = $m->{chg};
3609 if (defined $o{$f}) {
3610 $self->$f($m);
3611 } else {
3612 fatal("Invalid change type: $f");
3613 }
3614 }
3615 $self->rmdirs if $_rmdir;
3616 if (@$mods == 0) {
3617 $self->abort_edit;
3618 } else {
3619 $self->close_edit;
3620 }
3621 return scalar @$mods;
3622 }
3623
3624 package Git::SVN::Ra;
3625 use vars qw/@ISA $config_dir $_log_window_size/;
3626 use strict;
3627 use warnings;
3628 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3629
3630 BEGIN {
3631 # enforce temporary pool usage for some simple functions
3632 no strict 'refs';
3633 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3634 my $SUPER = "SUPER::$f";
3635 *$f = sub {
3636 my $self = shift;
3637 my $pool = SVN::Pool->new;
3638 my @ret = $self->$SUPER(@_,$pool);
3639 $pool->clear;
3640 wantarray ? @ret : $ret[0];
3641 };
3642 }
3643 }
3644
3645 sub _auth_providers () {
3646 [
3647 SVN::Client::get_simple_provider(),
3648 SVN::Client::get_ssl_server_trust_file_provider(),
3649 SVN::Client::get_simple_prompt_provider(
3650 \&Git::SVN::Prompt::simple, 2),
3651 SVN::Client::get_ssl_client_cert_file_provider(),
3652 SVN::Client::get_ssl_client_cert_prompt_provider(
3653 \&Git::SVN::Prompt::ssl_client_cert, 2),
3654 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3655 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3656 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3657 SVN::Client::get_username_provider(),
3658 SVN::Client::get_ssl_server_trust_prompt_provider(
3659 \&Git::SVN::Prompt::ssl_server_trust),
3660 SVN::Client::get_username_prompt_provider(
3661 \&Git::SVN::Prompt::username, 2)
3662 ]
3663 }
3664
3665 sub escape_uri_only {
3666 my ($uri) = @_;
3667 my @tmp;
3668 foreach (split m{/}, $uri) {
3669 s/([^\w.%-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
3670 push @tmp, $_;
3671 }
3672 join('/', @tmp);
3673 }
3674
3675 sub escape_url {
3676 my ($url) = @_;
3677 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3678 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3679 $url = "$scheme://$domain$uri";
3680 }
3681 $url;
3682 }
3683
3684 sub new {
3685 my ($class, $url) = @_;
3686 $url =~ s!/+$!!;
3687 return $RA if ($RA && $RA->{url} eq $url);
3688
3689 SVN::_Core::svn_config_ensure($config_dir, undef);
3690 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3691 my $config = SVN::Core::config_get_config($config_dir);
3692 $RA = undef;
3693 my $dont_store_passwords = 1;
3694 my $conf_t = ${$config}{'config'};
3695 {
3696 no warnings 'once';
3697 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3698 # produces warnings that variables are used only once.
3699 # I had not found the better way to shut them up, so
3700 # the warnings of type 'once' are disabled in this block.
3701 if (SVN::_Core::svn_config_get_bool($conf_t,
3702 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3703 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3704 1) == 0) {
3705 SVN::_Core::svn_auth_set_parameter($baton,
3706 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3707 bless (\$dont_store_passwords, "_p_void"));
3708 }
3709 if (SVN::_Core::svn_config_get_bool($conf_t,
3710 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3711 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3712 1) == 0) {
3713 $Git::SVN::Prompt::_no_auth_cache = 1;
3714 }
3715 } # no warnings 'once'
3716 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3717 config => $config,
3718 pool => SVN::Pool->new,
3719 auth_provider_callbacks => $callbacks);
3720 $self->{url} = $url;
3721 $self->{svn_path} = $url;
3722 $self->{repos_root} = $self->get_repos_root;
3723 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3724 $self->{cache} = { check_path => { r => 0, data => {} },
3725 get_dir => { r => 0, data => {} } };
3726 $RA = bless $self, $class;
3727 }
3728
3729 sub check_path {
3730 my ($self, $path, $r) = @_;
3731 my $cache = $self->{cache}->{check_path};
3732 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3733 return $cache->{data}->{$path};
3734 }
3735 my $pool = SVN::Pool->new;
3736 my $t = $self->SUPER::check_path($path, $r, $pool);
3737 $pool->clear;
3738 if ($r != $cache->{r}) {
3739 %{$cache->{data}} = ();
3740 $cache->{r} = $r;
3741 }
3742 $cache->{data}->{$path} = $t;
3743 }
3744
3745 sub get_dir {
3746 my ($self, $dir, $r) = @_;
3747 my $cache = $self->{cache}->{get_dir};
3748 if ($r == $cache->{r}) {
3749 if (my $x = $cache->{data}->{$dir}) {
3750 return wantarray ? @$x : $x->[0];
3751 }
3752 }
3753 my $pool = SVN::Pool->new;
3754 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3755 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3756 $pool->clear;
3757 if ($r != $cache->{r}) {
3758 %{$cache->{data}} = ();
3759 $cache->{r} = $r;
3760 }
3761 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3762 wantarray ? (\%dirents, $r, $props) : \%dirents;
3763 }
3764
3765 sub DESTROY {
3766 # do not call the real DESTROY since we store ourselves in $RA
3767 }
3768
3769 sub get_log {
3770 my ($self, @args) = @_;
3771 my $pool = SVN::Pool->new;
3772 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3773 my $ret = $self->SUPER::get_log(@args, $pool);
3774 $pool->clear;
3775 $ret;
3776 }
3777
3778 sub trees_match {
3779 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3780 my $ctx = SVN::Client->new(auth => _auth_providers);
3781 my $out = IO::File->new_tmpfile;
3782
3783 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3784 # $ctx->diff(), so we'll create a default one
3785 my $pool = SVN::Pool->new_default_sub;
3786
3787 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3788 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3789 $out->flush;
3790 my $ret = (($out->stat)[7] == 0);
3791 close $out or croak $!;
3792
3793 $ret;
3794 }
3795
3796 sub get_commit_editor {
3797 my ($self, $log, $cb, $pool) = @_;
3798 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3799 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3800 }
3801
3802 sub gs_do_update {
3803 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3804 my $new = ($rev_a == $rev_b);
3805 my $path = $gs->{path};
3806
3807 if ($new && -e $gs->{index}) {
3808 unlink $gs->{index} or die
3809 "Couldn't unlink index: $gs->{index}: $!\n";
3810 }
3811 my $pool = SVN::Pool->new;
3812 $editor->set_path_strip($path);
3813 my (@pc) = split m#/#, $path;
3814 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3815 1, $editor, $pool);
3816 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3817
3818 # Since we can't rely on svn_ra_reparent being available, we'll
3819 # just have to do some magic with set_path to make it so
3820 # we only want a partial path.
3821 my $sp = '';
3822 my $final = join('/', @pc);
3823 while (@pc) {
3824 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3825 $sp .= '/' if length $sp;
3826 $sp .= shift @pc;
3827 }
3828 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3829
3830 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3831
3832 $reporter->finish_report($pool);
3833 $pool->clear;
3834 $editor->{git_commit_ok};
3835 }
3836
3837 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3838 # svn_ra_reparent didn't work before 1.4)
3839 sub gs_do_switch {
3840 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3841 my $path = $gs->{path};
3842 my $pool = SVN::Pool->new;
3843
3844 my $full_url = $self->{url};
3845 my $old_url = $full_url;
3846 $full_url .= '/' . escape_uri_only($path) if length $path;
3847 my ($ra, $reparented);
3848 if ($old_url ne $full_url) {
3849 if ($old_url !~ m#^svn(\+ssh)?://#) {
3850 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3851 $pool);
3852 $self->{url} = $full_url;
3853 $reparented = 1;
3854 } else {
3855 $_[0] = undef;
3856 $self = undef;
3857 $RA = undef;
3858 $ra = Git::SVN::Ra->new($full_url);
3859 $ra_invalid = 1;
3860 }
3861 }
3862 $ra ||= $self;
3863 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3864 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3865 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3866 $reporter->finish_report($pool);
3867
3868 if ($reparented) {
3869 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3870 $self->{url} = $old_url;
3871 }
3872
3873 $pool->clear;
3874 $editor->{git_commit_ok};
3875 }
3876
3877 sub longest_common_path {
3878 my ($gsv, $globs) = @_;
3879 my %common;
3880 my $common_max = scalar @$gsv;
3881
3882 foreach my $gs (@$gsv) {
3883 my @tmp = split m#/#, $gs->{path};
3884 my $p = '';
3885 foreach (@tmp) {
3886 $p .= length($p) ? "/$_" : $_;
3887 $common{$p} ||= 0;
3888 $common{$p}++;
3889 }
3890 }
3891 $globs ||= [];
3892 $common_max += scalar @$globs;
3893 foreach my $glob (@$globs) {
3894 my @tmp = split m#/#, $glob->{path}->{left};
3895 my $p = '';
3896 foreach (@tmp) {
3897 $p .= length($p) ? "/$_" : $_;
3898 $common{$p} ||= 0;
3899 $common{$p}++;
3900 }
3901 }
3902
3903 my $longest_path = '';
3904 foreach (sort {length $b <=> length $a} keys %common) {
3905 if ($common{$_} == $common_max) {
3906 $longest_path = $_;
3907 last;
3908 }
3909 }
3910 $longest_path;
3911 }
3912
3913 sub gs_fetch_loop_common {
3914 my ($self, $base, $head, $gsv, $globs) = @_;
3915 return if ($base > $head);
3916 my $inc = $_log_window_size;
3917 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3918 my $longest_path = longest_common_path($gsv, $globs);
3919 my $ra_url = $self->{url};
3920 while (1) {
3921 my %revs;
3922 my $err;
3923 my $err_handler = $SVN::Error::handler;
3924 $SVN::Error::handler = sub {
3925 ($err) = @_;
3926 skip_unknown_revs($err);
3927 };
3928 sub _cb {
3929 my ($paths, $r, $author, $date, $log) = @_;
3930 [ dup_changed_paths($paths),
3931 { author => $author, date => $date, log => $log } ];
3932 }
3933 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3934 sub { $revs{$_[1]} = _cb(@_) });
3935 if ($err && $max >= $head) {
3936 print STDERR "Path '$longest_path' ",
3937 "was probably deleted:\n",
3938 $err->expanded_message,
3939 "\nWill attempt to follow ",
3940 "revisions r$min .. r$max ",
3941 "committed before the deletion\n";
3942 my $hi = $max;
3943 while (--$hi >= $min) {
3944 my $ok;
3945 $self->get_log([$longest_path], $min, $hi,
3946 0, 1, 1, sub {
3947 $ok ||= $_[1];
3948 $revs{$_[1]} = _cb(@_) });
3949 if ($ok) {
3950 print STDERR "r$min .. r$ok OK\n";
3951 last;
3952 }
3953 }
3954 }
3955 $SVN::Error::handler = $err_handler;
3956
3957 my %exists = map { $_->{path} => $_ } @$gsv;
3958 foreach my $r (sort {$a <=> $b} keys %revs) {
3959 my ($paths, $logged) = @{$revs{$r}};
3960
3961 foreach my $gs ($self->match_globs(\%exists, $paths,
3962 $globs, $r)) {
3963 if ($gs->rev_map_max >= $r) {
3964 next;
3965 }
3966 next unless $gs->match_paths($paths, $r);
3967 $gs->{logged_rev_props} = $logged;
3968 if (my $last_commit = $gs->last_commit) {
3969 $gs->assert_index_clean($last_commit);
3970 }
3971 my $log_entry = $gs->do_fetch($paths, $r);
3972 if ($log_entry) {
3973 $gs->do_git_commit($log_entry);
3974 }
3975 $INDEX_FILES{$gs->{index}} = 1;
3976 }
3977 foreach my $g (@$globs) {
3978 my $k = "svn-remote.$g->{remote}." .
3979 "$g->{t}-maxRev";
3980 Git::SVN::tmp_config($k, $r);
3981 }
3982 if ($ra_invalid) {
3983 $_[0] = undef;
3984 $self = undef;
3985 $RA = undef;
3986 $self = Git::SVN::Ra->new($ra_url);
3987 $ra_invalid = undef;
3988 }
3989 }
3990 # pre-fill the .rev_db since it'll eventually get filled in
3991 # with '0' x40 if something new gets committed
3992 foreach my $gs (@$gsv) {
3993 next if $gs->rev_map_max >= $max;
3994 next if defined $gs->rev_map_get($max);
3995 $gs->rev_map_set($max, 0 x40);
3996 }
3997 foreach my $g (@$globs) {
3998 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3999 Git::SVN::tmp_config($k, $max);
4000 }
4001 last if $max >= $head;
4002 $min = $max + 1;
4003 $max += $inc;
4004 $max = $head if ($max > $head);
4005 }
4006 Git::SVN::gc();
4007 }
4008
4009 sub match_globs {
4010 my ($self, $exists, $paths, $globs, $r) = @_;
4011
4012 sub get_dir_check {
4013 my ($self, $exists, $g, $r) = @_;
4014 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4015 return unless scalar @x == 3;
4016 my $dirents = $x[0];
4017 foreach my $de (keys %$dirents) {
4018 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4019 my $p = $g->{path}->full_path($de);
4020 next if $exists->{$p};
4021 next if (length $g->{path}->{right} &&
4022 ($self->check_path($p, $r) !=
4023 $SVN::Node::dir));
4024 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4025 $g->{ref}->full_path($de), 1);
4026 }
4027 }
4028 foreach my $g (@$globs) {
4029 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4030 if ($path->{action} =~ /^[AR]$/) {
4031 get_dir_check($self, $exists, $g, $r);
4032 }
4033 }
4034 foreach (keys %$paths) {
4035 if (/$g->{path}->{left_regex}/ &&
4036 !/$g->{path}->{regex}/) {
4037 next if $paths->{$_}->{action} !~ /^[AR]$/;
4038 get_dir_check($self, $exists, $g, $r);
4039 }
4040 next unless /$g->{path}->{regex}/;
4041 my $p = $1;
4042 my $pathname = $g->{path}->full_path($p);
4043 next if $exists->{$pathname};
4044 next if ($self->check_path($pathname, $r) !=
4045 $SVN::Node::dir);
4046 $exists->{$pathname} = Git::SVN->init(
4047 $self->{url}, $pathname, undef,
4048 $g->{ref}->full_path($p), 1);
4049 }
4050 my $c = '';
4051 foreach (split m#/#, $g->{path}->{left}) {
4052 $c .= "/$_";
4053 next unless ($paths->{$c} &&
4054 ($paths->{$c}->{action} =~ /^[AR]$/));
4055 get_dir_check($self, $exists, $g, $r);
4056 }
4057 }
4058 values %$exists;
4059 }
4060
4061 sub minimize_url {
4062 my ($self) = @_;
4063 return $self->{url} if ($self->{url} eq $self->{repos_root});
4064 my $url = $self->{repos_root};
4065 my @components = split(m!/!, $self->{svn_path});
4066 my $c = '';
4067 do {
4068 $url .= "/$c" if length $c;
4069 eval { (ref $self)->new($url)->get_latest_revnum };
4070 } while ($@ && ($c = shift @components));
4071 $url;
4072 }
4073
4074 sub can_do_switch {
4075 my $self = shift;
4076 unless (defined $can_do_switch) {
4077 my $pool = SVN::Pool->new;
4078 my $rep = eval {
4079 $self->do_switch(1, '', 0, $self->{url},
4080 SVN::Delta::Editor->new, $pool);
4081 };
4082 if ($@) {
4083 $can_do_switch = 0;
4084 } else {
4085 $rep->abort_report($pool);
4086 $can_do_switch = 1;
4087 }
4088 $pool->clear;
4089 }
4090 $can_do_switch;
4091 }
4092
4093 sub skip_unknown_revs {
4094 my ($err) = @_;
4095 my $errno = $err->apr_err();
4096 # Maybe the branch we're tracking didn't
4097 # exist when the repo started, so it's
4098 # not an error if it doesn't, just continue
4099 #
4100 # Wonderfully consistent library, eh?
4101 # 160013 - svn:// and file://
4102 # 175002 - http(s)://
4103 # 175007 - http(s):// (this repo required authorization, too...)
4104 # More codes may be discovered later...
4105 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4106 my $err_key = $err->expanded_message;
4107 # revision numbers change every time, filter them out
4108 $err_key =~ s/\d+/\0/g;
4109 $err_key = "$errno\0$err_key";
4110 unless ($ignored_err{$err_key}) {
4111 warn "W: Ignoring error from SVN, path probably ",
4112 "does not exist: ($errno): ",
4113 $err->expanded_message,"\n";
4114 warn "W: Do not be alarmed at the above message ",
4115 "git-svn is just searching aggressively for ",
4116 "old history.\n",
4117 "This may take a while on large repositories\n";
4118 $ignored_err{$err_key} = 1;
4119 }
4120 return;
4121 }
4122 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4123 }
4124
4125 # svn_log_changed_path_t objects passed to get_log are likely to be
4126 # overwritten even if only the refs are copied to an external variable,
4127 # so we should dup the structures in their entirety. Using an externally
4128 # passed pool (instead of our temporary and quickly cleared pool in
4129 # Git::SVN::Ra) does not help matters at all...
4130 sub dup_changed_paths {
4131 my ($paths) = @_;
4132 return undef unless $paths;
4133 my %ret;
4134 foreach my $p (keys %$paths) {
4135 my $i = $paths->{$p};
4136 my %s = map { $_ => $i->$_ }
4137 qw/copyfrom_path copyfrom_rev action/;
4138 $ret{$p} = \%s;
4139 }
4140 \%ret;
4141 }
4142
4143 package Git::SVN::Log;
4144 use strict;
4145 use warnings;
4146 use POSIX qw/strftime/;
4147 use constant commit_log_separator => ('-' x 72) . "\n";
4148 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4149 %rusers $show_commit $incremental/;
4150 my $l_fmt;
4151
4152 sub cmt_showable {
4153 my ($c) = @_;
4154 return 1 if defined $c->{r};
4155
4156 # big commit message got truncated by the 16k pretty buffer in rev-list
4157 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4158 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4159 @{$c->{l}} = ();
4160 my @log = command(qw/cat-file commit/, $c->{c});
4161
4162 # shift off the headers
4163 shift @log while ($log[0] ne '');
4164 shift @log;
4165
4166 # TODO: make $c->{l} not have a trailing newline in the future
4167 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4168
4169 (undef, $c->{r}, undef) = ::extract_metadata(
4170 (grep(/^git-svn-id: /, @log))[-1]);
4171 }
4172 return defined $c->{r};
4173 }
4174
4175 sub log_use_color {
4176 return $color || Git->repository->get_colorbool('color.diff');
4177 }
4178
4179 sub git_svn_log_cmd {
4180 my ($r_min, $r_max, @args) = @_;
4181 my $head = 'HEAD';
4182 my (@files, @log_opts);
4183 foreach my $x (@args) {
4184 if ($x eq '--' || @files) {
4185 push @files, $x;
4186 } else {
4187 if (::verify_ref("$x^0")) {
4188 $head = $x;
4189 } else {
4190 push @log_opts, $x;
4191 }
4192 }
4193 }
4194
4195 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4196 $gs ||= Git::SVN->_new;
4197 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4198 $gs->refname);
4199 push @cmd, '-r' unless $non_recursive;
4200 push @cmd, qw/--raw --name-status/ if $verbose;
4201 push @cmd, '--color' if log_use_color();
4202 push @cmd, @log_opts;
4203 if (defined $r_max && $r_max == $r_min) {
4204 push @cmd, '--max-count=1';
4205 if (my $c = $gs->rev_map_get($r_max)) {
4206 push @cmd, $c;
4207 }
4208 } elsif (defined $r_max) {
4209 if ($r_max < $r_min) {
4210 ($r_min, $r_max) = ($r_max, $r_min);
4211 }
4212 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4213 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4214 # If there are no commits in the range, both $c_max and $c_min
4215 # will be undefined. If there is at least 1 commit in the
4216 # range, both will be defined.
4217 return () if !defined $c_min || !defined $c_max;
4218 if ($c_min eq $c_max) {
4219 push @cmd, '--max-count=1', $c_min;
4220 } else {
4221 push @cmd, '--boundary', "$c_min..$c_max";
4222 }
4223 }
4224 return (@cmd, @files);
4225 }
4226
4227 # adapted from pager.c
4228 sub config_pager {
4229 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4230 if (!defined $pager) {
4231 $pager = 'less';
4232 } elsif (length $pager == 0 || $pager eq 'cat') {
4233 $pager = undef;
4234 }
4235 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4236 }
4237
4238 sub run_pager {
4239 return unless -t *STDOUT && defined $pager;
4240 pipe my $rfd, my $wfd or return;
4241 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4242 if (!$pid) {
4243 open STDOUT, '>&', $wfd or
4244 ::fatal "Can't redirect to stdout: $!";
4245 return;
4246 }
4247 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4248 $ENV{LESS} ||= 'FRSX';
4249 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4250 }
4251
4252 sub format_svn_date {
4253 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4254 }
4255
4256 sub parse_git_date {
4257 my ($t, $tz) = @_;
4258 # Date::Parse isn't in the standard Perl distro :(
4259 if ($tz =~ s/^\+//) {
4260 $t += tz_to_s_offset($tz);
4261 } elsif ($tz =~ s/^\-//) {
4262 $t -= tz_to_s_offset($tz);
4263 }
4264 return $t;
4265 }
4266
4267 sub set_local_timezone {
4268 if (defined $TZ) {
4269 $ENV{TZ} = $TZ;
4270 } else {
4271 delete $ENV{TZ};
4272 }
4273 }
4274
4275 sub tz_to_s_offset {
4276 my ($tz) = @_;
4277 $tz =~ s/(\d\d)$//;
4278 return ($1 * 60) + ($tz * 3600);
4279 }
4280
4281 sub get_author_info {
4282 my ($dest, $author, $t, $tz) = @_;
4283 $author =~ s/(?:^\s*|\s*$)//g;
4284 $dest->{a_raw} = $author;
4285 my $au;
4286 if ($::_authors) {
4287 $au = $rusers{$author} || undef;
4288 }
4289 if (!$au) {
4290 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4291 }
4292 $dest->{t} = $t;
4293 $dest->{tz} = $tz;
4294 $dest->{a} = $au;
4295 $dest->{t_utc} = parse_git_date($t, $tz);
4296 }
4297
4298 sub process_commit {
4299 my ($c, $r_min, $r_max, $defer) = @_;
4300 if (defined $r_min && defined $r_max) {
4301 if ($r_min == $c->{r} && $r_min == $r_max) {
4302 show_commit($c);
4303 return 0;
4304 }
4305 return 1 if $r_min == $r_max;
4306 if ($r_min < $r_max) {
4307 # we need to reverse the print order
4308 return 0 if (defined $limit && --$limit < 0);
4309 push @$defer, $c;
4310 return 1;
4311 }
4312 if ($r_min != $r_max) {
4313 return 1 if ($r_min < $c->{r});
4314 return 1 if ($r_max > $c->{r});
4315 }
4316 }
4317 return 0 if (defined $limit && --$limit < 0);
4318 show_commit($c);
4319 return 1;
4320 }
4321
4322 sub show_commit {
4323 my $c = shift;
4324 if ($oneline) {
4325 my $x = "\n";
4326 if (my $l = $c->{l}) {
4327 while ($l->[0] =~ /^\s*$/) { shift @$l }
4328 $x = $l->[0];
4329 }
4330 $l_fmt ||= 'A' . length($c->{r});
4331 print 'r',pack($l_fmt, $c->{r}),' | ';
4332 print "$c->{c} | " if $show_commit;
4333 print $x;
4334 } else {
4335 show_commit_normal($c);
4336 }
4337 }
4338
4339 sub show_commit_changed_paths {
4340 my ($c) = @_;
4341 return unless $c->{changed};
4342 print "Changed paths:\n", @{$c->{changed}};
4343 }
4344
4345 sub show_commit_normal {
4346 my ($c) = @_;
4347 print commit_log_separator, "r$c->{r} | ";
4348 print "$c->{c} | " if $show_commit;
4349 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4350 my $nr_line = 0;
4351
4352 if (my $l = $c->{l}) {
4353 while ($l->[$#$l] eq "\n" && $#$l > 0
4354 && $l->[($#$l - 1)] eq "\n") {
4355 pop @$l;
4356 }
4357 $nr_line = scalar @$l;
4358 if (!$nr_line) {
4359 print "1 line\n\n\n";
4360 } else {
4361 if ($nr_line == 1) {
4362 $nr_line = '1 line';
4363 } else {
4364 $nr_line .= ' lines';
4365 }
4366 print $nr_line, "\n";
4367 show_commit_changed_paths($c);
4368 print "\n";
4369 print $_ foreach @$l;
4370 }
4371 } else {
4372 print "1 line\n";
4373 show_commit_changed_paths($c);
4374 print "\n";
4375
4376 }
4377 foreach my $x (qw/raw stat diff/) {
4378 if ($c->{$x}) {
4379 print "\n";
4380 print $_ foreach @{$c->{$x}}
4381 }
4382 }
4383 }
4384
4385 sub cmd_show_log {
4386 my (@args) = @_;
4387 my ($r_min, $r_max);
4388 my $r_last = -1; # prevent dupes
4389 set_local_timezone();
4390 if (defined $::_revision) {
4391 if ($::_revision =~ /^(\d+):(\d+)$/) {
4392 ($r_min, $r_max) = ($1, $2);
4393 } elsif ($::_revision =~ /^\d+$/) {
4394 $r_min = $r_max = $::_revision;
4395 } else {
4396 ::fatal "-r$::_revision is not supported, use ",
4397 "standard 'git log' arguments instead";
4398 }
4399 }
4400
4401 config_pager();
4402 @args = git_svn_log_cmd($r_min, $r_max, @args);
4403 if (!@args) {
4404 print commit_log_separator unless $incremental || $oneline;
4405 return;
4406 }
4407 my $log = command_output_pipe(@args);
4408 run_pager();
4409 my (@k, $c, $d, $stat);
4410 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4411 while (<$log>) {
4412 if (/^${esc_color}commit -?($::sha1_short)/o) {
4413 my $cmt = $1;
4414 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4415 $r_last = $c->{r};
4416 process_commit($c, $r_min, $r_max, \@k) or
4417 goto out;
4418 }
4419 $d = undef;
4420 $c = { c => $cmt };
4421 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4422 get_author_info($c, $1, $2, $3);
4423 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4424 # ignore
4425 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4426 push @{$c->{raw}}, $_;
4427 } elsif (/^${esc_color}[ACRMDT]\t/) {
4428 # we could add $SVN->{svn_path} here, but that requires
4429 # remote access at the moment (repo_path_split)...
4430 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4431 push @{$c->{changed}}, $_;
4432 } elsif (/^${esc_color}diff /o) {
4433 $d = 1;
4434 push @{$c->{diff}}, $_;
4435 } elsif ($d) {
4436 push @{$c->{diff}}, $_;
4437 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4438 $esc_color*[\+\-]*$esc_color$/x) {
4439 $stat = 1;
4440 push @{$c->{stat}}, $_;
4441 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4442 push @{$c->{stat}}, $_;
4443 $stat = undef;
4444 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4445 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4446 } elsif (s/^${esc_color} //o) {
4447 push @{$c->{l}}, $_;
4448 }
4449 }
4450 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4451 $r_last = $c->{r};
4452 process_commit($c, $r_min, $r_max, \@k);
4453 }
4454 if (@k) {
4455 ($r_min, $r_max) = ($r_max, $r_min);
4456 process_commit($_, $r_min, $r_max) foreach reverse @k;
4457 }
4458 out:
4459 close $log;
4460 print commit_log_separator unless $incremental || $oneline;
4461 }
4462
4463 sub cmd_blame {
4464 my $path = shift;
4465
4466 config_pager();
4467 run_pager();
4468
4469 my ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4470 while (my $line = <$fh>) {
4471 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4472 my (undef, $rev, undef) = ::cmt_metadata($1);
4473 $rev = sprintf('%-10s', $rev);
4474 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4475 }
4476 print $line;
4477 }
4478 command_close_pipe($fh, $ctx);
4479 }
4480
4481 package Git::SVN::Migration;
4482 # these version numbers do NOT correspond to actual version numbers
4483 # of git nor git-svn. They are just relative.
4484 #
4485 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4486 #
4487 # v1 layout: .git/$id/info/url, refs/remotes/$id
4488 #
4489 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4490 #
4491 # v3 layout: .git/svn/$id, refs/remotes/$id
4492 # - info/url may remain for backwards compatibility
4493 # - this is what we migrate up to this layout automatically,
4494 # - this will be used by git svn init on single branches
4495 # v3.1 layout (auto migrated):
4496 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4497 # for backwards compatibility
4498 #
4499 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4500 # - this is only created for newly multi-init-ed
4501 # repositories. Similar in spirit to the
4502 # --use-separate-remotes option in git-clone (now default)
4503 # - we do not automatically migrate to this (following
4504 # the example set by core git)
4505 #
4506 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4507 # - newer, more-efficient format that uses 24-bytes per record
4508 # with no filler space.
4509 # - use xxd -c24 < .rev_map.$UUID to view and debug
4510 # - This is a one-way migration, repositories updated to the
4511 # new format will not be able to use old git-svn without
4512 # rebuilding the .rev_db. Rebuilding the rev_db is not
4513 # possible if noMetadata or useSvmProps are set; but should
4514 # be no problem for users that use the (sensible) defaults.
4515 use strict;
4516 use warnings;
4517 use Carp qw/croak/;
4518 use File::Path qw/mkpath/;
4519 use File::Basename qw/dirname basename/;
4520 use vars qw/$_minimize/;
4521
4522 sub migrate_from_v0 {
4523 my $git_dir = $ENV{GIT_DIR};
4524 return undef unless -d $git_dir;
4525 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4526 my $migrated = 0;
4527 while (<$fh>) {
4528 chomp;
4529 my ($id, $orig_ref) = ($_, $_);
4530 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4531 next unless -f "$git_dir/$id/info/url";
4532 my $new_ref = "refs/remotes/$id";
4533 if (::verify_ref("$new_ref^0")) {
4534 print STDERR "W: $orig_ref is probably an old ",
4535 "branch used by an ancient version of ",
4536 "git-svn.\n",
4537 "However, $new_ref also exists.\n",
4538 "We will not be able ",
4539 "to use this branch until this ",
4540 "ambiguity is resolved.\n";
4541 next;
4542 }
4543 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4544 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4545 command_noisy('update-ref', $new_ref, $orig_ref);
4546 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4547 $migrated++;
4548 }
4549 command_close_pipe($fh, $ctx);
4550 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4551 $migrated;
4552 }
4553
4554 sub migrate_from_v1 {
4555 my $git_dir = $ENV{GIT_DIR};
4556 my $migrated = 0;
4557 return $migrated unless -d $git_dir;
4558 my $svn_dir = "$git_dir/svn";
4559
4560 # just in case somebody used 'svn' as their $id at some point...
4561 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4562
4563 print STDERR "Migrating from a git-svn v1 layout...\n";
4564 mkpath([$svn_dir]);
4565 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4566 "$svn_dir\n\t(required for this version ",
4567 "($::VERSION) of git-svn) does not. exist\n";
4568 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4569 while (<$fh>) {
4570 my $x = $_;
4571 next unless $x =~ s#^refs/remotes/##;
4572 chomp $x;
4573 next unless -f "$git_dir/$x/info/url";
4574 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4575 next unless $u;
4576 my $dn = dirname("$git_dir/svn/$x");
4577 mkpath([$dn]) unless -d $dn;
4578 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4579 mkpath(["$git_dir/svn/svn"]);
4580 print STDERR " - $git_dir/$x/info => ",
4581 "$git_dir/svn/$x/info\n";
4582 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4583 croak "$!: $x";
4584 # don't worry too much about these, they probably
4585 # don't exist with repos this old (save for index,
4586 # and we can easily regenerate that)
4587 foreach my $f (qw/unhandled.log index .rev_db/) {
4588 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4589 }
4590 } else {
4591 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4592 rename "$git_dir/$x", "$git_dir/svn/$x" or
4593 croak "$!: $x";
4594 }
4595 $migrated++;
4596 }
4597 command_close_pipe($fh, $ctx);
4598 print STDERR "Done migrating from a git-svn v1 layout\n";
4599 $migrated;
4600 }
4601
4602 sub read_old_urls {
4603 my ($l_map, $pfx, $path) = @_;
4604 my @dir;
4605 foreach (<$path/*>) {
4606 if (-r "$_/info/url") {
4607 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4608 my $ref_id = $pfx . basename $_;
4609 my $url = ::file_to_s("$_/info/url");
4610 $l_map->{$ref_id} = $url;
4611 } elsif (-d $_) {
4612 push @dir, $_;
4613 }
4614 }
4615 foreach (@dir) {
4616 my $x = $_;
4617 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4618 read_old_urls($l_map, $x, $_);
4619 }
4620 }
4621
4622 sub migrate_from_v2 {
4623 my @cfg = command(qw/config -l/);
4624 return if grep /^svn-remote\..+\.url=/, @cfg;
4625 my %l_map;
4626 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4627 my $migrated = 0;
4628
4629 foreach my $ref_id (sort keys %l_map) {
4630 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4631 if ($@) {
4632 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4633 }
4634 $migrated++;
4635 }
4636 $migrated;
4637 }
4638
4639 sub minimize_connections {
4640 my $r = Git::SVN::read_all_remotes();
4641 my $new_urls = {};
4642 my $root_repos = {};
4643 foreach my $repo_id (keys %$r) {
4644 my $url = $r->{$repo_id}->{url} or next;
4645 my $fetch = $r->{$repo_id}->{fetch} or next;
4646 my $ra = Git::SVN::Ra->new($url);
4647
4648 # skip existing cases where we already connect to the root
4649 if (($ra->{url} eq $ra->{repos_root}) ||
4650 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4651 $repo_id)) {
4652 $root_repos->{$ra->{url}} = $repo_id;
4653 next;
4654 }
4655
4656 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4657 my $root_path = $ra->{url};
4658 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4659 foreach my $path (keys %$fetch) {
4660 my $ref_id = $fetch->{$path};
4661 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4662
4663 # make sure we can read when connecting to
4664 # a higher level of a repository
4665 my ($last_rev, undef) = $gs->last_rev_commit;
4666 if (!defined $last_rev) {
4667 $last_rev = eval {
4668 $root_ra->get_latest_revnum;
4669 };
4670 next if $@;
4671 }
4672 my $new = $root_path;
4673 $new .= length $path ? "/$path" : '';
4674 eval {
4675 $root_ra->get_log([$new], $last_rev, $last_rev,
4676 0, 0, 1, sub { });
4677 };
4678 next if $@;
4679 $new_urls->{$ra->{repos_root}}->{$new} =
4680 { ref_id => $ref_id,
4681 old_repo_id => $repo_id,
4682 old_path => $path };
4683 }
4684 }
4685
4686 my @emptied;
4687 foreach my $url (keys %$new_urls) {
4688 # see if we can re-use an existing [svn-remote "repo_id"]
4689 # instead of creating a(n ugly) new section:
4690 my $repo_id = $root_repos->{$url} ||
4691 Git::SVN::sanitize_remote_name($url);
4692
4693 my $fetch = $new_urls->{$url};
4694 foreach my $path (keys %$fetch) {
4695 my $x = $fetch->{$path};
4696 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4697 my $pfx = "svn-remote.$x->{old_repo_id}";
4698
4699 my $old_fetch = quotemeta("$x->{old_path}:".
4700 "refs/remotes/$x->{ref_id}");
4701 command_noisy(qw/config --unset/,
4702 "$pfx.fetch", '^'. $old_fetch . '$');
4703 delete $r->{$x->{old_repo_id}}->
4704 {fetch}->{$x->{old_path}};
4705 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4706 command_noisy(qw/config --unset/,
4707 "$pfx.url");
4708 push @emptied, $x->{old_repo_id}
4709 }
4710 }
4711 }
4712 if (@emptied) {
4713 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4714 "$ENV{GIT_DIR}/config";
4715 print STDERR <<EOF;
4716 The following [svn-remote] sections in your config file ($file) are empty
4717 and can be safely removed:
4718 EOF
4719 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4720 }
4721 }
4722
4723 sub migration_check {
4724 migrate_from_v0();
4725 migrate_from_v1();
4726 migrate_from_v2();
4727 minimize_connections() if $_minimize;
4728 }
4729
4730 package Git::IndexInfo;
4731 use strict;
4732 use warnings;
4733 use Git qw/command_input_pipe command_close_pipe/;
4734
4735 sub new {
4736 my ($class) = @_;
4737 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4738 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4739 }
4740
4741 sub remove {
4742 my ($self, $path) = @_;
4743 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4744 return ++$self->{nr};
4745 }
4746 undef;
4747 }
4748
4749 sub update {
4750 my ($self, $mode, $hash, $path) = @_;
4751 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4752 return ++$self->{nr};
4753 }
4754 undef;
4755 }
4756
4757 sub DESTROY {
4758 my ($self) = @_;
4759 command_close_pipe($self->{gui}, $self->{ctx});
4760 }
4761
4762 package Git::SVN::GlobSpec;
4763 use strict;
4764 use warnings;
4765
4766 sub new {
4767 my ($class, $glob) = @_;
4768 my $re = $glob;
4769 $re =~ s!/+$!!g; # no need for trailing slashes
4770 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4771 my ($left, $right) = ($1, $2);
4772 if ($nr > 1) {
4773 die "Only one '*' wildcard expansion ",
4774 "is supported (got $nr): '$glob'\n";
4775 } elsif ($nr == 0) {
4776 die "One '*' is needed for glob: '$glob'\n";
4777 }
4778 $re = quotemeta($left) . $re . quotemeta($right);
4779 if (length $left && !($left =~ s!/+$!!g)) {
4780 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4781 }
4782 if (length $right && !($right =~ s!^/+!!g)) {
4783 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4784 }
4785 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4786 bless { left => $left, right => $right, left_regex => $left_re,
4787 regex => qr/$re/, glob => $glob }, $class;
4788 }
4789
4790 sub full_path {
4791 my ($self, $path) = @_;
4792 return (length $self->{left} ? "$self->{left}/" : '') .
4793 $path . (length $self->{right} ? "/$self->{right}" : '');
4794 }
4795
4796 __END__
4797
4798 Data structures:
4799
4800
4801 $remotes = { # returned by read_all_remotes()
4802 'svn' => {
4803 # svn-remote.svn.url=https://svn.musicpd.org
4804 url => 'https://svn.musicpd.org',
4805 # svn-remote.svn.fetch=mpd/trunk:trunk
4806 fetch => {
4807 'mpd/trunk' => 'trunk',
4808 },
4809 # svn-remote.svn.tags=mpd/tags/*:tags/*
4810 tags => {
4811 path => {
4812 left => 'mpd/tags',
4813 right => '',
4814 regex => qr!mpd/tags/([^/]+)$!,
4815 glob => 'tags/*',
4816 },
4817 ref => {
4818 left => 'tags',
4819 right => '',
4820 regex => qr!tags/([^/]+)$!,
4821 glob => 'tags/*',
4822 },
4823 }
4824 }
4825 };
4826
4827 $log_entry hashref as returned by libsvn_log_entry()
4828 {
4829 log => 'whitespace-formatted log entry
4830 ', # trailing newline is preserved
4831 revision => '8', # integer
4832 date => '2004-02-24T17:01:44.108345Z', # commit date
4833 author => 'committer name'
4834 };
4835
4836
4837 # this is generated by generate_diff();
4838 @mods = array of diff-index line hashes, each element represents one line
4839 of diff-index output
4840
4841 diff-index line ($m hash)
4842 {
4843 mode_a => first column of diff-index output, no leading ':',
4844 mode_b => second column of diff-index output,
4845 sha1_b => sha1sum of the final blob,
4846 chg => change type [MCRADT],
4847 file_a => original file name of a file (iff chg is 'C' or 'R')
4848 file_b => new/current file name of a file (any chg)
4849 }
4850 ;
4851
4852 # retval of read_url_paths{,_all}();
4853 $l_map = {
4854 # repository root url
4855 'https://svn.musicpd.org' => {
4856 # repository path # GIT_SVN_ID
4857 'mpd/trunk' => 'trunk',
4858 'mpd/tags/0.11.5' => 'tags/0.11.5',
4859 },
4860 }
4861
4862 Notes:
4863 I don't trust the each() function on unless I created %hash myself
4864 because the internal iterator may not have started at base.
Gitweb development nest