?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Ensure git ls-tree exits with a non-zero exit code if read_tree_recursive fails.
[git/gitweb.git] / git-svn.perl
blob7849cfc141d384bc28479c2f37fd128c77fe0fbe
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use 5.008;
5 use warnings;
6 use strict;
7 use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11 $VERSION = '@@GIT_VERSION@@';
12
13 # From which subdir have we been invoked?
14 my $cmd_dir_prefix = eval {
15 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
16 } || '';
17
18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
19 $ENV{GIT_DIR} ||= '.git';
20 $Git::SVN::default_repo_id = 'svn';
21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
22 $Git::SVN::Ra::_log_window_size = 100;
23 $Git::SVN::_minimize_url = 'unset';
24
25 if (! exists $ENV{SVN_SSH}) {
26 if (exists $ENV{GIT_SSH}) {
27 $ENV{SVN_SSH} = $ENV{GIT_SSH};
28 if ($^O eq 'msys') {
29 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
30 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
31 }
32 }
33 }
34
35 $Git::SVN::Log::TZ = $ENV{TZ};
36 $ENV{TZ} = 'UTC';
37 $| = 1; # unbuffer STDOUT
38
39 sub fatal (@) { print STDERR "@_\n"; exit 1 }
40 sub _req_svn {
41 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
42 require SVN::Ra;
43 require SVN::Delta;
44 if ($SVN::Core::VERSION lt '1.1.0') {
45 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
46 }
47 }
48 my $can_compress = eval { require Compress::Zlib; 1};
49 push @Git::SVN::Ra::ISA, 'SVN::Ra';
50 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
51 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
52 use Carp qw/croak/;
53 use Digest::MD5;
54 use IO::File qw//;
55 use File::Basename qw/dirname basename/;
56 use File::Path qw/mkpath/;
57 use File::Spec;
58 use File::Find;
59 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
60 use IPC::Open3;
61 use Git;
62 use Memoize; # core since 5.8.0, Jul 2002
63
64 BEGIN {
65 # import functions from Git into our packages, en masse
66 no strict 'refs';
67 foreach (qw/command command_oneline command_noisy command_output_pipe
68 command_input_pipe command_close_pipe
69 command_bidi_pipe command_close_bidi_pipe/) {
70 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
71 Git::SVN::Migration Git::SVN::Log Git::SVN),
72 __PACKAGE__) {
73 *{"${package}::$_"} = \&{"Git::$_"};
74 }
75 }
76 Memoize::memoize 'Git::config';
77 Memoize::memoize 'Git::config_bool';
78 }
79
80 my ($SVN);
81
82 $sha1 = qr/[a-f\d]{40}/;
83 $sha1_short = qr/[a-f\d]{4,40}/;
84 my ($_stdin, $_help, $_edit,
85 $_message, $_file, $_branch_dest,
86 $_template, $_shared,
87 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
88 $_merge, $_strategy, $_dry_run, $_local,
89 $_prefix, $_no_checkout, $_url, $_verbose,
90 $_git_format, $_commit_url, $_tag, $_merge_info);
91 $Git::SVN::_follow_parent = 1;
92 $_q ||= 0;
93 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
94 'config-dir=s' => \$Git::SVN::Ra::config_dir,
95 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
96 'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
97 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
98 'authors-file|A=s' => \$_authors,
99 'authors-prog=s' => \$_authors_prog,
100 'repack:i' => \$Git::SVN::_repack,
101 'noMetadata' => \$Git::SVN::_no_metadata,
102 'useSvmProps' => \$Git::SVN::_use_svm_props,
103 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
104 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
105 'no-checkout' => \$_no_checkout,
106 'quiet|q+' => \$_q,
107 'repack-flags|repack-args|repack-opts=s' =>
108 \$Git::SVN::_repack_flags,
109 'use-log-author' => \$Git::SVN::_use_log_author,
110 'add-author-from' => \$Git::SVN::_add_author_from,
111 'localtime' => \$Git::SVN::_localtime,
112 %remote_opts );
113
114 my ($_trunk, @_tags, @_branches, $_stdlayout);
115 my %icv;
116 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
117 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
118 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
119 'stdlayout|s' => \$_stdlayout,
120 'minimize-url|m!' => \$Git::SVN::_minimize_url,
121 'no-metadata' => sub { $icv{noMetadata} = 1 },
122 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
123 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
124 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
125 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
126 %remote_opts );
127 my %cmt_opts = ( 'edit|e' => \$_edit,
128 'rmdir' => \$SVN::Git::Editor::_rmdir,
129 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
130 'l=i' => \$SVN::Git::Editor::_rename_limit,
131 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
132 );
133
134 my %cmd = (
135 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
136 { 'revision|r=s' => \$_revision,
137 'fetch-all|all' => \$_fetch_all,
138 'parent|p' => \$_fetch_parent,
139 %fc_opts } ],
140 clone => [ \&cmd_clone, "Initialize and fetch revisions",
141 { 'revision|r=s' => \$_revision,
142 %fc_opts, %init_opts } ],
143 init => [ \&cmd_init, "Initialize a repo for tracking" .
144 " (requires URL argument)",
145 \%init_opts ],
146 'multi-init' => [ \&cmd_multi_init,
147 "Deprecated alias for ".
148 "'$0 init -T<trunk> -b<branches> -t<tags>'",
149 \%init_opts ],
150 dcommit => [ \&cmd_dcommit,
151 'Commit several diffs to merge with upstream',
152 { 'merge|m|M' => \$_merge,
153 'strategy|s=s' => \$_strategy,
154 'verbose|v' => \$_verbose,
155 'dry-run|n' => \$_dry_run,
156 'fetch-all|all' => \$_fetch_all,
157 'commit-url=s' => \$_commit_url,
158 'revision|r=i' => \$_revision,
159 'no-rebase' => \$_no_rebase,
160 'mergeinfo=s' => \$_merge_info,
161 %cmt_opts, %fc_opts } ],
162 branch => [ \&cmd_branch,
163 'Create a branch in the SVN repository',
164 { 'message|m=s' => \$_message,
165 'destination|d=s' => \$_branch_dest,
166 'dry-run|n' => \$_dry_run,
167 'tag|t' => \$_tag,
168 'username=s' => \$Git::SVN::Prompt::_username,
169 'commit-url=s' => \$_commit_url } ],
170 tag => [ sub { $_tag = 1; cmd_branch(@_) },
171 'Create a tag in the SVN repository',
172 { 'message|m=s' => \$_message,
173 'destination|d=s' => \$_branch_dest,
174 'dry-run|n' => \$_dry_run,
175 'username=s' => \$Git::SVN::Prompt::_username,
176 'commit-url=s' => \$_commit_url } ],
177 'set-tree' => [ \&cmd_set_tree,
178 "Set an SVN repository to a git tree-ish",
179 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
180 'create-ignore' => [ \&cmd_create_ignore,
181 'Create a .gitignore per svn:ignore',
182 { 'revision|r=i' => \$_revision
183 } ],
184 'mkdirs' => [ \&cmd_mkdirs ,
185 "recreate empty directories after a checkout",
186 { 'revision|r=i' => \$_revision } ],
187 'propget' => [ \&cmd_propget,
188 'Print the value of a property on a file or directory',
189 { 'revision|r=i' => \$_revision } ],
190 'proplist' => [ \&cmd_proplist,
191 'List all properties of a file or directory',
192 { 'revision|r=i' => \$_revision } ],
193 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
194 { 'revision|r=i' => \$_revision
195 } ],
196 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
197 { 'revision|r=i' => \$_revision
198 } ],
199 'multi-fetch' => [ \&cmd_multi_fetch,
200 "Deprecated alias for $0 fetch --all",
201 { 'revision|r=s' => \$_revision, %fc_opts } ],
202 'migrate' => [ sub { },
203 # no-op, we automatically run this anyways,
204 'Migrate configuration/metadata/layout from
205 previous versions of git-svn',
206 { 'minimize' => \$Git::SVN::Migration::_minimize,
207 %remote_opts } ],
208 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
209 { 'limit=i' => \$Git::SVN::Log::limit,
210 'revision|r=s' => \$_revision,
211 'verbose|v' => \$Git::SVN::Log::verbose,
212 'incremental' => \$Git::SVN::Log::incremental,
213 'oneline' => \$Git::SVN::Log::oneline,
214 'show-commit' => \$Git::SVN::Log::show_commit,
215 'non-recursive' => \$Git::SVN::Log::non_recursive,
216 'authors-file|A=s' => \$_authors,
217 'color' => \$Git::SVN::Log::color,
218 'pager=s' => \$Git::SVN::Log::pager
219 } ],
220 'find-rev' => [ \&cmd_find_rev,
221 "Translate between SVN revision numbers and tree-ish",
222 {} ],
223 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
224 { 'merge|m|M' => \$_merge,
225 'verbose|v' => \$_verbose,
226 'strategy|s=s' => \$_strategy,
227 'local|l' => \$_local,
228 'fetch-all|all' => \$_fetch_all,
229 'dry-run|n' => \$_dry_run,
230 %fc_opts } ],
231 'commit-diff' => [ \&cmd_commit_diff,
232 'Commit a diff between two trees',
233 { 'message|m=s' => \$_message,
234 'file|F=s' => \$_file,
235 'revision|r=s' => \$_revision,
236 %cmt_opts } ],
237 'info' => [ \&cmd_info,
238 "Show info about the latest SVN revision
239 on the current branch",
240 { 'url' => \$_url, } ],
241 'blame' => [ \&Git::SVN::Log::cmd_blame,
242 "Show what revision and author last modified each line of a file",
243 { 'git-format' => \$_git_format } ],
244 'reset' => [ \&cmd_reset,
245 "Undo fetches back to the specified SVN revision",
246 { 'revision|r=s' => \$_revision,
247 'parent|p' => \$_fetch_parent } ],
248 'gc' => [ \&cmd_gc,
249 "Compress unhandled.log files in .git/svn and remove " .
250 "index files in .git/svn",
251 {} ],
252 );
253
254 my $cmd;
255 for (my $i = 0; $i < @ARGV; $i++) {
256 if (defined $cmd{$ARGV[$i]}) {
257 $cmd = $ARGV[$i];
258 splice @ARGV, $i, 1;
259 last;
260 } elsif ($ARGV[$i] eq 'help') {
261 $cmd = $ARGV[$i+1];
262 usage(0);
263 }
264 };
265
266 # make sure we're always running at the top-level working directory
267 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
268 unless (-d $ENV{GIT_DIR}) {
269 if ($git_dir_user_set) {
270 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
271 "but it is not a directory\n";
272 }
273 my $git_dir = delete $ENV{GIT_DIR};
274 my $cdup = undef;
275 git_cmd_try {
276 $cdup = command_oneline(qw/rev-parse --show-cdup/);
277 $git_dir = '.' unless ($cdup);
278 chomp $cdup if ($cdup);
279 $cdup = "." unless ($cdup && length $cdup);
280 } "Already at toplevel, but $git_dir not found\n";
281 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
282 unless (-d $git_dir) {
283 die "$git_dir still not found after going to ",
284 "'$cdup'\n";
285 }
286 $ENV{GIT_DIR} = $git_dir;
287 }
288 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
289 }
290
291 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
292
293 read_git_config(\%opts);
294 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
295 Getopt::Long::Configure('pass_through');
296 }
297 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
298 'minimize-connections' => \$Git::SVN::Migration::_minimize,
299 'id|i=s' => \$Git::SVN::default_ref_id,
300 'svn-remote|remote|R=s' => sub {
301 $Git::SVN::no_reuse_existing = 1;
302 $Git::SVN::default_repo_id = $_[1] });
303 exit 1 if (!$rv && $cmd && $cmd ne 'log');
304
305 usage(0) if $_help;
306 version() if $_version;
307 usage(1) unless defined $cmd;
308 load_authors() if $_authors;
309 if (defined $_authors_prog) {
310 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
311 }
312
313 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
314 Git::SVN::Migration::migration_check();
315 }
316 Git::SVN::init_vars();
317 eval {
318 Git::SVN::verify_remotes_sanity();
319 $cmd{$cmd}->[0]->(@ARGV);
320 };
321 fatal $@ if $@;
322 post_fetch_checkout();
323 exit 0;
324
325 ####################### primary functions ######################
326 sub usage {
327 my $exit = shift || 0;
328 my $fd = $exit ? \*STDERR : \*STDOUT;
329 print $fd <<"";
330 git-svn - bidirectional operations between a single Subversion tree and git
331 Usage: git svn <command> [options] [arguments]\n
332
333 print $fd "Available commands:\n" unless $cmd;
334
335 foreach (sort keys %cmd) {
336 next if $cmd && $cmd ne $_;
337 next if /^multi-/; # don't show deprecated commands
338 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
339 foreach (sort keys %{$cmd{$_}->[2]}) {
340 # mixed-case options are for .git/config only
341 next if /[A-Z]/ && /^[a-z]+$/i;
342 # prints out arguments as they should be passed:
343 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
344 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
345 "--$_" : "-$_" }
346 split /\|/,$_)," $x\n";
347 }
348 }
349 print $fd <<"";
350 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
351 arbitrary identifier if you're tracking multiple SVN branches/repositories in
352 one git repository and want to keep them separate. See git-svn(1) for more
353 information.
354
355 exit $exit;
356 }
357
358 sub version {
359 ::_req_svn();
360 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
361 exit 0;
362 }
363
364 sub do_git_init_db {
365 unless (-d $ENV{GIT_DIR}) {
366 my @init_db = ('init');
367 push @init_db, "--template=$_template" if defined $_template;
368 if (defined $_shared) {
369 if ($_shared =~ /[a-z]/) {
370 push @init_db, "--shared=$_shared";
371 } else {
372 push @init_db, "--shared";
373 }
374 }
375 command_noisy(@init_db);
376 $_repository = Git->repository(Repository => ".git");
377 }
378 my $set;
379 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
380 foreach my $i (keys %icv) {
381 die "'$set' and '$i' cannot both be set\n" if $set;
382 next unless defined $icv{$i};
383 command_noisy('config', "$pfx.$i", $icv{$i});
384 $set = $i;
385 }
386 my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
387 command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
388 if defined $$ignore_regex;
389 }
390
391 sub init_subdir {
392 my $repo_path = shift or return;
393 mkpath([$repo_path]) unless -d $repo_path;
394 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
395 $ENV{GIT_DIR} = '.git';
396 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
397 }
398
399 sub cmd_clone {
400 my ($url, $path) = @_;
401 if (!defined $path &&
402 (defined $_trunk || @_branches || @_tags ||
403 defined $_stdlayout) &&
404 $url !~ m#^[a-z\+]+://#) {
405 $path = $url;
406 }
407 $path = basename($url) if !defined $path || !length $path;
408 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
409 cmd_init($url, $path);
410 command_oneline('config', 'svn.authorsfile', $authors_absolute)
411 if $_authors;
412 Git::SVN::fetch_all($Git::SVN::default_repo_id);
413 }
414
415 sub cmd_init {
416 if (defined $_stdlayout) {
417 $_trunk = 'trunk' if (!defined $_trunk);
418 @_tags = 'tags' if (! @_tags);
419 @_branches = 'branches' if (! @_branches);
420 }
421 if (defined $_trunk || @_branches || @_tags) {
422 return cmd_multi_init(@_);
423 }
424 my $url = shift or die "SVN repository location required ",
425 "as a command-line argument\n";
426 $url = canonicalize_url($url);
427 init_subdir(@_);
428 do_git_init_db();
429
430 if ($Git::SVN::_minimize_url eq 'unset') {
431 $Git::SVN::_minimize_url = 0;
432 }
433
434 Git::SVN->init($url);
435 }
436
437 sub cmd_fetch {
438 if (grep /^\d+=./, @_) {
439 die "'<rev>=<commit>' fetch arguments are ",
440 "no longer supported.\n";
441 }
442 my ($remote) = @_;
443 if (@_ > 1) {
444 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
445 }
446 $Git::SVN::no_reuse_existing = undef;
447 if ($_fetch_parent) {
448 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
449 unless ($gs) {
450 die "Unable to determine upstream SVN information from ",
451 "working tree history\n";
452 }
453 # just fetch, don't checkout.
454 $_no_checkout = 'true';
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 } elsif ($_fetch_all) {
457 cmd_multi_fetch();
458 } else {
459 $remote ||= $Git::SVN::default_repo_id;
460 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
461 }
462 }
463
464 sub cmd_set_tree {
465 my (@commits) = @_;
466 if ($_stdin || !@commits) {
467 print "Reading from stdin...\n";
468 @commits = ();
469 while (<STDIN>) {
470 if (/\b($sha1_short)\b/o) {
471 unshift @commits, $1;
472 }
473 }
474 }
475 my @revs;
476 foreach my $c (@commits) {
477 my @tmp = command('rev-parse',$c);
478 if (scalar @tmp == 1) {
479 push @revs, $tmp[0];
480 } elsif (scalar @tmp > 1) {
481 push @revs, reverse(command('rev-list',@tmp));
482 } else {
483 fatal "Failed to rev-parse $c";
484 }
485 }
486 my $gs = Git::SVN->new;
487 my ($r_last, $cmt_last) = $gs->last_rev_commit;
488 $gs->fetch;
489 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
490 fatal "There are new revisions that were fetched ",
491 "and need to be merged (or acknowledged) ",
492 "before committing.\nlast rev: $r_last\n",
493 " current: $gs->{last_rev}";
494 }
495 $gs->set_tree($_) foreach @revs;
496 print "Done committing ",scalar @revs," revisions to SVN\n";
497 unlink $gs->{index};
498 }
499
500 sub cmd_dcommit {
501 my $head = shift;
502 command_noisy(qw/update-index --refresh/);
503 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
504 'Cannot dcommit with a dirty index. Commit your changes first, '
505 . "or stash them with `git stash'.\n";
506 $head ||= 'HEAD';
507
508 my $old_head;
509 if ($head ne 'HEAD') {
510 $old_head = eval {
511 command_oneline([qw/symbolic-ref -q HEAD/])
512 };
513 if ($old_head) {
514 $old_head =~ s{^refs/heads/}{};
515 } else {
516 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
517 }
518 command(['checkout', $head], STDERR => 0);
519 }
520
521 my @refs;
522 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
523 unless ($gs) {
524 die "Unable to determine upstream SVN information from ",
525 "$head history.\nPerhaps the repository is empty.";
526 }
527
528 if (defined $_commit_url) {
529 $url = $_commit_url;
530 } else {
531 $url = eval { command_oneline('config', '--get',
532 "svn-remote.$gs->{repo_id}.commiturl") };
533 if (!$url) {
534 $url = $gs->full_pushurl
535 }
536 }
537
538 my $last_rev = $_revision if defined $_revision;
539 if ($url) {
540 print "Committing to $url ...\n";
541 }
542 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
543 if ($_no_rebase && scalar(@$linear_refs) > 1) {
544 warn "Attempting to commit more than one change while ",
545 "--no-rebase is enabled.\n",
546 "If these changes depend on each other, re-running ",
547 "without --no-rebase may be required."
548 }
549 my $expect_url = $url;
550 Git::SVN::remove_username($expect_url);
551 while (1) {
552 my $d = shift @$linear_refs or last;
553 unless (defined $last_rev) {
554 (undef, $last_rev, undef) = cmt_metadata("$d~1");
555 unless (defined $last_rev) {
556 fatal "Unable to extract revision information ",
557 "from commit $d~1";
558 }
559 }
560 if ($_dry_run) {
561 print "diff-tree $d~1 $d\n";
562 } else {
563 my $cmt_rev;
564 my %ed_opts = ( r => $last_rev,
565 log => get_commit_entry($d)->{log},
566 ra => Git::SVN::Ra->new($url),
567 config => SVN::Core::config_get_config(
568 $Git::SVN::Ra::config_dir
569 ),
570 tree_a => "$d~1",
571 tree_b => $d,
572 editor_cb => sub {
573 print "Committed r$_[0]\n";
574 $cmt_rev = $_[0];
575 },
576 mergeinfo => $_merge_info,
577 svn_path => '');
578 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
579 print "No changes\n$d~1 == $d\n";
580 } elsif ($parents->{$d} && @{$parents->{$d}}) {
581 $gs->{inject_parents_dcommit}->{$cmt_rev} =
582 $parents->{$d};
583 }
584 $_fetch_all ? $gs->fetch_all : $gs->fetch;
585 $last_rev = $cmt_rev;
586 next if $_no_rebase;
587
588 # we always want to rebase against the current HEAD,
589 # not any head that was passed to us
590 my @diff = command('diff-tree', $d,
591 $gs->refname, '--');
592 my @finish;
593 if (@diff) {
594 @finish = rebase_cmd();
595 print STDERR "W: $d and ", $gs->refname,
596 " differ, using @finish:\n",
597 join("\n", @diff), "\n";
598 } else {
599 print "No changes between current HEAD and ",
600 $gs->refname,
601 "\nResetting to the latest ",
602 $gs->refname, "\n";
603 @finish = qw/reset --mixed/;
604 }
605 command_noisy(@finish, $gs->refname);
606 if (@diff) {
607 @refs = ();
608 my ($url_, $rev_, $uuid_, $gs_) =
609 working_head_info('HEAD', \@refs);
610 my ($linear_refs_, $parents_) =
611 linearize_history($gs_, \@refs);
612 if (scalar(@$linear_refs) !=
613 scalar(@$linear_refs_)) {
614 fatal "# of revisions changed ",
615 "\nbefore:\n",
616 join("\n", @$linear_refs),
617 "\n\nafter:\n",
618 join("\n", @$linear_refs_), "\n",
619 'If you are attempting to commit ',
620 "merges, try running:\n\t",
621 'git rebase --interactive',
622 '--preserve-merges ',
623 $gs->refname,
624 "\nBefore dcommitting";
625 }
626 if ($url_ ne $expect_url) {
627 if ($url_ eq $gs->metadata_url) {
628 print
629 "Accepting rewritten URL:",
630 " $url_\n";
631 } else {
632 fatal
633 "URL mismatch after rebase:",
634 " $url_ != $expect_url";
635 }
636 }
637 if ($uuid_ ne $uuid) {
638 fatal "uuid mismatch after rebase: ",
639 "$uuid_ != $uuid";
640 }
641 # remap parents
642 my (%p, @l, $i);
643 for ($i = 0; $i < scalar @$linear_refs; $i++) {
644 my $new = $linear_refs_->[$i] or next;
645 $p{$new} =
646 $parents->{$linear_refs->[$i]};
647 push @l, $new;
648 }
649 $parents = \%p;
650 $linear_refs = \@l;
651 }
652 }
653 }
654
655 if ($old_head) {
656 my $new_head = command_oneline(qw/rev-parse HEAD/);
657 my $new_is_symbolic = eval {
658 command_oneline(qw/symbolic-ref -q HEAD/);
659 };
660 if ($new_is_symbolic) {
661 print "dcommitted the branch ", $head, "\n";
662 } else {
663 print "dcommitted on a detached HEAD because you gave ",
664 "a revision argument.\n",
665 "The rewritten commit is: ", $new_head, "\n";
666 }
667 command(['checkout', $old_head], STDERR => 0);
668 }
669
670 unlink $gs->{index};
671 }
672
673 sub cmd_branch {
674 my ($branch_name, $head) = @_;
675
676 unless (defined $branch_name && length $branch_name) {
677 die(($_tag ? "tag" : "branch") . " name required\n");
678 }
679 $head ||= 'HEAD';
680
681 my (undef, $rev, undef, $gs) = working_head_info($head);
682 my $src = $gs->full_pushurl;
683
684 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
685 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
686 my $glob;
687 if ($#{$allglobs} == 0) {
688 $glob = $allglobs->[0];
689 } else {
690 unless(defined $_branch_dest) {
691 die "Multiple ",
692 $_tag ? "tag" : "branch",
693 " paths defined for Subversion repository.\n",
694 "You must specify where you want to create the ",
695 $_tag ? "tag" : "branch",
696 " with the --destination argument.\n";
697 }
698 foreach my $g (@{$allglobs}) {
699 # SVN::Git::Editor could probably be moved to Git.pm..
700 my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
701 if ($_branch_dest =~ /$re/) {
702 $glob = $g;
703 last;
704 }
705 }
706 unless (defined $glob) {
707 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
708 foreach my $g (@{$allglobs}) {
709 $g->{path}->{left} =~ /$dest_re/ or next;
710 if (defined $glob) {
711 die "Ambiguous destination: ",
712 $_branch_dest, "\nmatches both '",
713 $glob->{path}->{left}, "' and '",
714 $g->{path}->{left}, "'\n";
715 }
716 $glob = $g;
717 }
718 unless (defined $glob) {
719 die "Unknown ",
720 $_tag ? "tag" : "branch",
721 " destination $_branch_dest\n";
722 }
723 }
724 }
725 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
726 my $url;
727 if (defined $_commit_url) {
728 $url = $_commit_url;
729 } else {
730 $url = eval { command_oneline('config', '--get',
731 "svn-remote.$gs->{repo_id}.commiturl") };
732 if (!$url) {
733 $url = $remote->{pushurl} || $remote->{url};
734 }
735 }
736 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
737
738 if ($dst =~ /^https:/ && $src =~ /^http:/) {
739 $src=~s/^http:/https:/;
740 }
741
742 ::_req_svn();
743
744 my $ctx = SVN::Client->new(
745 auth => Git::SVN::Ra::_auth_providers(),
746 log_msg => sub {
747 ${ $_[0] } = defined $_message
748 ? $_message
749 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
750 . $branch_name;
751 },
752 );
753
754 eval {
755 $ctx->ls($dst, 'HEAD', 0);
756 } and die "branch ${branch_name} already exists\n";
757
758 print "Copying ${src} at r${rev} to ${dst}...\n";
759 $ctx->copy($src, $rev, $dst)
760 unless $_dry_run;
761
762 $gs->fetch_all;
763 }
764
765 sub cmd_find_rev {
766 my $revision_or_hash = shift or die "SVN or git revision required ",
767 "as a command-line argument\n";
768 my $result;
769 if ($revision_or_hash =~ /^r\d+$/) {
770 my $head = shift;
771 $head ||= 'HEAD';
772 my @refs;
773 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
774 unless ($gs) {
775 die "Unable to determine upstream SVN information from ",
776 "$head history\n";
777 }
778 my $desired_revision = substr($revision_or_hash, 1);
779 $result = $gs->rev_map_get($desired_revision, $uuid);
780 } else {
781 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
782 $result = $rev;
783 }
784 print "$result\n" if $result;
785 }
786
787 sub auto_create_empty_directories {
788 my ($gs) = @_;
789 my $var = eval { command_oneline('config', '--get', '--bool',
790 "svn-remote.$gs->{repo_id}.automkdirs") };
791 # By default, create empty directories by consulting the unhandled log,
792 # but allow setting it to 'false' to skip it.
793 return !($var && $var eq 'false');
794 }
795
796 sub cmd_rebase {
797 command_noisy(qw/update-index --refresh/);
798 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
799 unless ($gs) {
800 die "Unable to determine upstream SVN information from ",
801 "working tree history\n";
802 }
803 if ($_dry_run) {
804 print "Remote Branch: " . $gs->refname . "\n";
805 print "SVN URL: " . $url . "\n";
806 return;
807 }
808 if (command(qw/diff-index HEAD --/)) {
809 print STDERR "Cannot rebase with uncommited changes:\n";
810 command_noisy('status');
811 exit 1;
812 }
813 unless ($_local) {
814 # rebase will checkout for us, so no need to do it explicitly
815 $_no_checkout = 'true';
816 $_fetch_all ? $gs->fetch_all : $gs->fetch;
817 }
818 command_noisy(rebase_cmd(), $gs->refname);
819 if (auto_create_empty_directories($gs)) {
820 $gs->mkemptydirs;
821 }
822 }
823
824 sub cmd_show_ignore {
825 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
826 $gs ||= Git::SVN->new;
827 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
828 $gs->prop_walk($gs->{path}, $r, sub {
829 my ($gs, $path, $props) = @_;
830 print STDOUT "\n# $path\n";
831 my $s = $props->{'svn:ignore'} or return;
832 $s =~ s/[\r\n]+/\n/g;
833 $s =~ s/^\n+//;
834 chomp $s;
835 $s =~ s#^#$path#gm;
836 print STDOUT "$s\n";
837 });
838 }
839
840 sub cmd_show_externals {
841 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
842 $gs ||= Git::SVN->new;
843 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
844 $gs->prop_walk($gs->{path}, $r, sub {
845 my ($gs, $path, $props) = @_;
846 print STDOUT "\n# $path\n";
847 my $s = $props->{'svn:externals'} or return;
848 $s =~ s/[\r\n]+/\n/g;
849 chomp $s;
850 $s =~ s#^#$path#gm;
851 print STDOUT "$s\n";
852 });
853 }
854
855 sub cmd_create_ignore {
856 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
857 $gs ||= Git::SVN->new;
858 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
859 $gs->prop_walk($gs->{path}, $r, sub {
860 my ($gs, $path, $props) = @_;
861 # $path is of the form /path/to/dir/
862 $path = '.' . $path;
863 # SVN can have attributes on empty directories,
864 # which git won't track
865 mkpath([$path]) unless -d $path;
866 my $ignore = $path . '.gitignore';
867 my $s = $props->{'svn:ignore'} or return;
868 open(GITIGNORE, '>', $ignore)
869 or fatal("Failed to open `$ignore' for writing: $!");
870 $s =~ s/[\r\n]+/\n/g;
871 $s =~ s/^\n+//;
872 chomp $s;
873 # Prefix all patterns so that the ignore doesn't apply
874 # to sub-directories.
875 $s =~ s#^#/#gm;
876 print GITIGNORE "$s\n";
877 close(GITIGNORE)
878 or fatal("Failed to close `$ignore': $!");
879 command_noisy('add', '-f', $ignore);
880 });
881 }
882
883 sub cmd_mkdirs {
884 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
885 $gs ||= Git::SVN->new;
886 $gs->mkemptydirs($_revision);
887 }
888
889 sub canonicalize_path {
890 my ($path) = @_;
891 my $dot_slash_added = 0;
892 if (substr($path, 0, 1) ne "/") {
893 $path = "./" . $path;
894 $dot_slash_added = 1;
895 }
896 # File::Spec->canonpath doesn't collapse x/../y into y (for a
897 # good reason), so let's do this manually.
898 $path =~ s#/+#/#g;
899 $path =~ s#/\.(?:/|$)#/#g;
900 $path =~ s#/[^/]+/\.\.##g;
901 $path =~ s#/$##g;
902 $path =~ s#^\./## if $dot_slash_added;
903 $path =~ s#^/##;
904 $path =~ s#^\.$##;
905 return $path;
906 }
907
908 sub canonicalize_url {
909 my ($url) = @_;
910 $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
911 return $url;
912 }
913
914 # get_svnprops(PATH)
915 # ------------------
916 # Helper for cmd_propget and cmd_proplist below.
917 sub get_svnprops {
918 my $path = shift;
919 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
920 $gs ||= Git::SVN->new;
921
922 # prefix THE PATH by the sub-directory from which the user
923 # invoked us.
924 $path = $cmd_dir_prefix . $path;
925 fatal("No such file or directory: $path") unless -e $path;
926 my $is_dir = -d $path ? 1 : 0;
927 $path = $gs->{path} . '/' . $path;
928
929 # canonicalize the path (otherwise libsvn will abort or fail to
930 # find the file)
931 $path = canonicalize_path($path);
932
933 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
934 my $props;
935 if ($is_dir) {
936 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
937 }
938 else {
939 (undef, $props) = $gs->ra->get_file($path, $r, undef);
940 }
941 return $props;
942 }
943
944 # cmd_propget (PROP, PATH)
945 # ------------------------
946 # Print the SVN property PROP for PATH.
947 sub cmd_propget {
948 my ($prop, $path) = @_;
949 $path = '.' if not defined $path;
950 usage(1) if not defined $prop;
951 my $props = get_svnprops($path);
952 if (not defined $props->{$prop}) {
953 fatal("`$path' does not have a `$prop' SVN property.");
954 }
955 print $props->{$prop} . "\n";
956 }
957
958 # cmd_proplist (PATH)
959 # -------------------
960 # Print the list of SVN properties for PATH.
961 sub cmd_proplist {
962 my $path = shift;
963 $path = '.' if not defined $path;
964 my $props = get_svnprops($path);
965 print "Properties on '$path':\n";
966 foreach (sort keys %{$props}) {
967 print " $_\n";
968 }
969 }
970
971 sub cmd_multi_init {
972 my $url = shift;
973 unless (defined $_trunk || @_branches || @_tags) {
974 usage(1);
975 }
976
977 $_prefix = '' unless defined $_prefix;
978 if (defined $url) {
979 $url = canonicalize_url($url);
980 init_subdir(@_);
981 }
982 do_git_init_db();
983 if (defined $_trunk) {
984 $_trunk =~ s#^/+##;
985 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
986 # try both old-style and new-style lookups:
987 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
988 unless ($gs_trunk) {
989 my ($trunk_url, $trunk_path) =
990 complete_svn_url($url, $_trunk);
991 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
992 undef, $trunk_ref);
993 }
994 }
995 return unless @_branches || @_tags;
996 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
997 foreach my $path (@_branches) {
998 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
999 }
1000 foreach my $path (@_tags) {
1001 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1002 }
1003 }
1004
1005 sub cmd_multi_fetch {
1006 $Git::SVN::no_reuse_existing = undef;
1007 my $remotes = Git::SVN::read_all_remotes();
1008 foreach my $repo_id (sort keys %$remotes) {
1009 if ($remotes->{$repo_id}->{url}) {
1010 Git::SVN::fetch_all($repo_id, $remotes);
1011 }
1012 }
1013 }
1014
1015 # this command is special because it requires no metadata
1016 sub cmd_commit_diff {
1017 my ($ta, $tb, $url) = @_;
1018 my $usage = "Usage: $0 commit-diff -r<revision> ".
1019 "<tree-ish> <tree-ish> [<URL>]";
1020 fatal($usage) if (!defined $ta || !defined $tb);
1021 my $svn_path = '';
1022 if (!defined $url) {
1023 my $gs = eval { Git::SVN->new };
1024 if (!$gs) {
1025 fatal("Needed URL or usable git-svn --id in ",
1026 "the command-line\n", $usage);
1027 }
1028 $url = $gs->{url};
1029 $svn_path = $gs->{path};
1030 }
1031 unless (defined $_revision) {
1032 fatal("-r|--revision is a required argument\n", $usage);
1033 }
1034 if (defined $_message && defined $_file) {
1035 fatal("Both --message/-m and --file/-F specified ",
1036 "for the commit message.\n",
1037 "I have no idea what you mean");
1038 }
1039 if (defined $_file) {
1040 $_message = file_to_s($_file);
1041 } else {
1042 $_message ||= get_commit_entry($tb)->{log};
1043 }
1044 my $ra ||= Git::SVN::Ra->new($url);
1045 my $r = $_revision;
1046 if ($r eq 'HEAD') {
1047 $r = $ra->get_latest_revnum;
1048 } elsif ($r !~ /^\d+$/) {
1049 die "revision argument: $r not understood by git-svn\n";
1050 }
1051 my %ed_opts = ( r => $r,
1052 log => $_message,
1053 ra => $ra,
1054 tree_a => $ta,
1055 tree_b => $tb,
1056 editor_cb => sub { print "Committed r$_[0]\n" },
1057 svn_path => $svn_path );
1058 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1059 print "No changes\n$ta == $tb\n";
1060 }
1061 }
1062
1063 sub escape_uri_only {
1064 my ($uri) = @_;
1065 my @tmp;
1066 foreach (split m{/}, $uri) {
1067 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1068 push @tmp, $_;
1069 }
1070 join('/', @tmp);
1071 }
1072
1073 sub escape_url {
1074 my ($url) = @_;
1075 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1076 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1077 $url = "$scheme://$domain$uri";
1078 }
1079 $url;
1080 }
1081
1082 sub cmd_info {
1083 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1084 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1085 if (exists $_[1]) {
1086 die "Too many arguments specified\n";
1087 }
1088
1089 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1090
1091 if (!$file_type && !$diff_status) {
1092 print STDERR "svn: '$path' is not under version control\n";
1093 exit 1;
1094 }
1095
1096 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1097 unless ($gs) {
1098 die "Unable to determine upstream SVN information from ",
1099 "working tree history\n";
1100 }
1101
1102 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1103 $path = "." if $path eq "";
1104
1105 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1106
1107 if ($_url) {
1108 print escape_url($full_url), "\n";
1109 return;
1110 }
1111
1112 my $result = "Path: $path\n";
1113 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1114 $result .= "URL: " . escape_url($full_url) . "\n";
1115
1116 eval {
1117 my $repos_root = $gs->repos_root;
1118 Git::SVN::remove_username($repos_root);
1119 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1120 };
1121 if ($@) {
1122 $result .= "Repository Root: (offline)\n";
1123 }
1124 ::_req_svn();
1125 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1126 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1127 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1128
1129 $result .= "Node Kind: " .
1130 ($file_type eq "dir" ? "directory" : "file") . "\n";
1131
1132 my $schedule = $diff_status eq "A"
1133 ? "add"
1134 : ($diff_status eq "D" ? "delete" : "normal");
1135 $result .= "Schedule: $schedule\n";
1136
1137 if ($diff_status eq "A") {
1138 print $result, "\n";
1139 return;
1140 }
1141
1142 my ($lc_author, $lc_rev, $lc_date_utc);
1143 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1144 my $log = command_output_pipe(@args);
1145 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1146 while (<$log>) {
1147 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1148 $lc_author = $1;
1149 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1150 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1151 (undef, $lc_rev, undef) = ::extract_metadata($1);
1152 }
1153 }
1154 close $log;
1155
1156 Git::SVN::Log::set_local_timezone();
1157
1158 $result .= "Last Changed Author: $lc_author\n";
1159 $result .= "Last Changed Rev: $lc_rev\n";
1160 $result .= "Last Changed Date: " .
1161 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1162
1163 if ($file_type ne "dir") {
1164 my $text_last_updated_date =
1165 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1166 $result .=
1167 "Text Last Updated: " .
1168 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1169 "\n";
1170 my $checksum;
1171 if ($diff_status eq "D") {
1172 my ($fh, $ctx) =
1173 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1174 if ($file_type eq "link") {
1175 my $file_name = <$fh>;
1176 $checksum = md5sum("link $file_name");
1177 } else {
1178 $checksum = md5sum($fh);
1179 }
1180 command_close_pipe($fh, $ctx);
1181 } elsif ($file_type eq "link") {
1182 my $file_name =
1183 command(qw(cat-file blob), "HEAD:$path");
1184 $checksum =
1185 md5sum("link " . $file_name);
1186 } else {
1187 open FILE, "<", $path or die $!;
1188 $checksum = md5sum(\*FILE);
1189 close FILE or die $!;
1190 }
1191 $result .= "Checksum: " . $checksum . "\n";
1192 }
1193
1194 print $result, "\n";
1195 }
1196
1197 sub cmd_reset {
1198 my $target = shift || $_revision or die "SVN revision required\n";
1199 $target = $1 if $target =~ /^r(\d+)$/;
1200 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1201 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1202 unless ($gs) {
1203 die "Unable to determine upstream SVN information from ".
1204 "history\n";
1205 }
1206 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1207 die "Cannot find SVN revision $target\n" unless defined($c);
1208 $gs->rev_map_set($r, $c, 'reset', $uuid);
1209 print "r$r = $c ($gs->{ref_id})\n";
1210 }
1211
1212 sub cmd_gc {
1213 if (!$can_compress) {
1214 warn "Compress::Zlib could not be found; unhandled.log " .
1215 "files will not be compressed.\n";
1216 }
1217 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1218 }
1219
1220 ########################### utility functions #########################
1221
1222 sub rebase_cmd {
1223 my @cmd = qw/rebase/;
1224 push @cmd, '-v' if $_verbose;
1225 push @cmd, qw/--merge/ if $_merge;
1226 push @cmd, "--strategy=$_strategy" if $_strategy;
1227 @cmd;
1228 }
1229
1230 sub post_fetch_checkout {
1231 return if $_no_checkout;
1232 my $gs = $Git::SVN::_head or return;
1233 return if verify_ref('refs/heads/master^0');
1234
1235 # look for "trunk" ref if it exists
1236 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1237 my $fetch = $remote->{fetch};
1238 if ($fetch) {
1239 foreach my $p (keys %$fetch) {
1240 basename($fetch->{$p}) eq 'trunk' or next;
1241 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1242 last;
1243 }
1244 }
1245
1246 my $valid_head = verify_ref('HEAD^0');
1247 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1248 return if ($valid_head || !verify_ref('HEAD^0'));
1249
1250 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1251 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1252 return if -f $index;
1253
1254 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1255 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1256 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1257 print STDERR "Checked out HEAD:\n ",
1258 $gs->full_url, " r", $gs->last_rev, "\n";
1259 if (auto_create_empty_directories($gs)) {
1260 $gs->mkemptydirs($gs->last_rev);
1261 }
1262 }
1263
1264 sub complete_svn_url {
1265 my ($url, $path) = @_;
1266 $path =~ s#/+$##;
1267 if ($path !~ m#^[a-z\+]+://#) {
1268 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1269 fatal("E: '$path' is not a complete URL ",
1270 "and a separate URL is not specified");
1271 }
1272 return ($url, $path);
1273 }
1274 return ($path, '');
1275 }
1276
1277 sub complete_url_ls_init {
1278 my ($ra, $repo_path, $switch, $pfx) = @_;
1279 unless ($repo_path) {
1280 print STDERR "W: $switch not specified\n";
1281 return;
1282 }
1283 $repo_path =~ s#/+$##;
1284 if ($repo_path =~ m#^[a-z\+]+://#) {
1285 $ra = Git::SVN::Ra->new($repo_path);
1286 $repo_path = '';
1287 } else {
1288 $repo_path =~ s#^/+##;
1289 unless ($ra) {
1290 fatal("E: '$repo_path' is not a complete URL ",
1291 "and a separate URL is not specified");
1292 }
1293 }
1294 my $url = $ra->{url};
1295 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1296 my $k = "svn-remote.$gs->{repo_id}.url";
1297 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1298 if ($orig_url && ($orig_url ne $gs->{url})) {
1299 die "$k already set: $orig_url\n",
1300 "wanted to set to: $gs->{url}\n";
1301 }
1302 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1303 my $remote_path = "$gs->{path}/$repo_path";
1304 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1305 $remote_path =~ s#/+#/#g;
1306 $remote_path =~ s#^/##g;
1307 $remote_path .= "/*" if $remote_path !~ /\*/;
1308 my ($n) = ($switch =~ /^--(\w+)/);
1309 if (length $pfx && $pfx !~ m#/$#) {
1310 die "--prefix='$pfx' must have a trailing slash '/'\n";
1311 }
1312 command_noisy('config',
1313 '--add',
1314 "svn-remote.$gs->{repo_id}.$n",
1315 "$remote_path:refs/remotes/$pfx*" .
1316 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1317 }
1318
1319 sub verify_ref {
1320 my ($ref) = @_;
1321 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1322 { STDERR => 0 }); };
1323 }
1324
1325 sub get_tree_from_treeish {
1326 my ($treeish) = @_;
1327 # $treeish can be a symbolic ref, too:
1328 my $type = command_oneline(qw/cat-file -t/, $treeish);
1329 my $expected;
1330 while ($type eq 'tag') {
1331 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1332 }
1333 if ($type eq 'commit') {
1334 $expected = (grep /^tree /, command(qw/cat-file commit/,
1335 $treeish))[0];
1336 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1337 die "Unable to get tree from $treeish\n" unless $expected;
1338 } elsif ($type eq 'tree') {
1339 $expected = $treeish;
1340 } else {
1341 die "$treeish is a $type, expected tree, tag or commit\n";
1342 }
1343 return $expected;
1344 }
1345
1346 sub get_commit_entry {
1347 my ($treeish) = shift;
1348 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1349 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1350 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1351 open my $log_fh, '>', $commit_editmsg or croak $!;
1352
1353 my $type = command_oneline(qw/cat-file -t/, $treeish);
1354 if ($type eq 'commit' || $type eq 'tag') {
1355 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1356 $type, $treeish);
1357 my $in_msg = 0;
1358 my $author;
1359 my $saw_from = 0;
1360 my $msgbuf = "";
1361 while (<$msg_fh>) {
1362 if (!$in_msg) {
1363 $in_msg = 1 if (/^\s*$/);
1364 $author = $1 if (/^author (.*>)/);
1365 } elsif (/^git-svn-id: /) {
1366 # skip this for now, we regenerate the
1367 # correct one on re-fetch anyways
1368 # TODO: set *:merge properties or like...
1369 } else {
1370 if (/^From:/ || /^Signed-off-by:/) {
1371 $saw_from = 1;
1372 }
1373 $msgbuf .= $_;
1374 }
1375 }
1376 $msgbuf =~ s/\s+$//s;
1377 if ($Git::SVN::_add_author_from && defined($author)
1378 && !$saw_from) {
1379 $msgbuf .= "\n\nFrom: $author";
1380 }
1381 print $log_fh $msgbuf or croak $!;
1382 command_close_pipe($msg_fh, $ctx);
1383 }
1384 close $log_fh or croak $!;
1385
1386 if ($_edit || ($type eq 'tree')) {
1387 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1388 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1389 }
1390 rename $commit_editmsg, $commit_msg or croak $!;
1391 {
1392 require Encode;
1393 # SVN requires messages to be UTF-8 when entering the repo
1394 local $/;
1395 open $log_fh, '<', $commit_msg or croak $!;
1396 binmode $log_fh;
1397 chomp($log_entry{log} = <$log_fh>);
1398
1399 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1400 my $msg = $log_entry{log};
1401
1402 eval { $msg = Encode::decode($enc, $msg, 1) };
1403 if ($@) {
1404 die "Could not decode as $enc:\n", $msg,
1405 "\nPerhaps you need to set i18n.commitencoding\n";
1406 }
1407
1408 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1409 die "Could not encode as UTF-8:\n$msg\n" if $@;
1410
1411 $log_entry{log} = $msg;
1412
1413 close $log_fh or croak $!;
1414 }
1415 unlink $commit_msg;
1416 \%log_entry;
1417 }
1418
1419 sub s_to_file {
1420 my ($str, $file, $mode) = @_;
1421 open my $fd,'>',$file or croak $!;
1422 print $fd $str,"\n" or croak $!;
1423 close $fd or croak $!;
1424 chmod ($mode &~ umask, $file) if (defined $mode);
1425 }
1426
1427 sub file_to_s {
1428 my $file = shift;
1429 open my $fd,'<',$file or croak "$!: file: $file\n";
1430 local $/;
1431 my $ret = <$fd>;
1432 close $fd or croak $!;
1433 $ret =~ s/\s*$//s;
1434 return $ret;
1435 }
1436
1437 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1438 sub load_authors {
1439 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1440 my $log = $cmd eq 'log';
1441 while (<$authors>) {
1442 chomp;
1443 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1444 my ($user, $name, $email) = ($1, $2, $3);
1445 if ($log) {
1446 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1447 } else {
1448 $users{$user} = [$name, $email];
1449 }
1450 }
1451 close $authors or croak $!;
1452 }
1453
1454 # convert GetOpt::Long specs for use by git-config
1455 sub read_git_config {
1456 my $opts = shift;
1457 my @config_only;
1458 foreach my $o (keys %$opts) {
1459 # if we have mixedCase and a long option-only, then
1460 # it's a config-only variable that we don't need for
1461 # the command-line.
1462 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1463 my $v = $opts->{$o};
1464 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1465 $key =~ s/-//g;
1466 my $arg = 'git config';
1467 $arg .= ' --int' if ($o =~ /[:=]i$/);
1468 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1469 if (ref $v eq 'ARRAY') {
1470 chomp(my @tmp = `$arg --get-all svn.$key`);
1471 @$v = @tmp if @tmp;
1472 } else {
1473 chomp(my $tmp = `$arg --get svn.$key`);
1474 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1475 $$v = $tmp;
1476 }
1477 }
1478 }
1479 delete @$opts{@config_only} if @config_only;
1480 }
1481
1482 sub extract_metadata {
1483 my $id = shift or return (undef, undef, undef);
1484 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1485 \s([a-f\d\-]+)$/ix);
1486 if (!defined $rev || !$uuid || !$url) {
1487 # some of the original repositories I made had
1488 # identifiers like this:
1489 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1490 }
1491 return ($url, $rev, $uuid);
1492 }
1493
1494 sub cmt_metadata {
1495 return extract_metadata((grep(/^git-svn-id: /,
1496 command(qw/cat-file commit/, shift)))[-1]);
1497 }
1498
1499 sub cmt_sha2rev_batch {
1500 my %s2r;
1501 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1502 my $list = shift;
1503
1504 foreach my $sha (@{$list}) {
1505 my $first = 1;
1506 my $size = 0;
1507 print $out $sha, "\n";
1508
1509 while (my $line = <$in>) {
1510 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1511 last;
1512 } elsif ($first &&
1513 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1514 $first = 0;
1515 $size = $1;
1516 next;
1517 } elsif ($line =~ /^(git-svn-id: )/) {
1518 my (undef, $rev, undef) =
1519 extract_metadata($line);
1520 $s2r{$sha} = $rev;
1521 }
1522
1523 $size -= length($line);
1524 last if ($size == 0);
1525 }
1526 }
1527
1528 command_close_bidi_pipe($pid, $in, $out, $ctx);
1529
1530 return \%s2r;
1531 }
1532
1533 sub working_head_info {
1534 my ($head, $refs) = @_;
1535 my @args = qw/log --no-color --no-decorate --first-parent
1536 --pretty=medium/;
1537 my ($fh, $ctx) = command_output_pipe(@args, $head);
1538 my $hash;
1539 my %max;
1540 while (<$fh>) {
1541 if ( m{^commit ($::sha1)$} ) {
1542 unshift @$refs, $hash if $hash and $refs;
1543 $hash = $1;
1544 next;
1545 }
1546 next unless s{^\s*(git-svn-id:)}{$1};
1547 my ($url, $rev, $uuid) = extract_metadata($_);
1548 if (defined $url && defined $rev) {
1549 next if $max{$url} and $max{$url} < $rev;
1550 if (my $gs = Git::SVN->find_by_url($url)) {
1551 my $c = $gs->rev_map_get($rev, $uuid);
1552 if ($c && $c eq $hash) {
1553 close $fh; # break the pipe
1554 return ($url, $rev, $uuid, $gs);
1555 } else {
1556 $max{$url} ||= $gs->rev_map_max;
1557 }
1558 }
1559 }
1560 }
1561 command_close_pipe($fh, $ctx);
1562 (undef, undef, undef, undef);
1563 }
1564
1565 sub read_commit_parents {
1566 my ($parents, $c) = @_;
1567 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1568 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1569 @{$parents->{$c}} = split(/ /, $p);
1570 }
1571
1572 sub linearize_history {
1573 my ($gs, $refs) = @_;
1574 my %parents;
1575 foreach my $c (@$refs) {
1576 read_commit_parents(\%parents, $c);
1577 }
1578
1579 my @linear_refs;
1580 my %skip = ();
1581 my $last_svn_commit = $gs->last_commit;
1582 foreach my $c (reverse @$refs) {
1583 next if $c eq $last_svn_commit;
1584 last if $skip{$c};
1585
1586 unshift @linear_refs, $c;
1587 $skip{$c} = 1;
1588
1589 # we only want the first parent to diff against for linear
1590 # history, we save the rest to inject when we finalize the
1591 # svn commit
1592 my $fp_a = verify_ref("$c~1");
1593 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1594 if (!$fp_a || !$fp_b) {
1595 die "Commit $c\n",
1596 "has no parent commit, and therefore ",
1597 "nothing to diff against.\n",
1598 "You should be working from a repository ",
1599 "originally created by git-svn\n";
1600 }
1601 if ($fp_a ne $fp_b) {
1602 die "$c~1 = $fp_a, however parsing commit $c ",
1603 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1604 }
1605
1606 foreach my $p (@{$parents{$c}}) {
1607 $skip{$p} = 1;
1608 }
1609 }
1610 (\@linear_refs, \%parents);
1611 }
1612
1613 sub find_file_type_and_diff_status {
1614 my ($path) = @_;
1615 return ('dir', '') if $path eq '';
1616
1617 my $diff_output =
1618 command_oneline(qw(diff --cached --name-status --), $path) || "";
1619 my $diff_status = (split(' ', $diff_output))[0] || "";
1620
1621 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1622
1623 return (undef, undef) if !$diff_status && !$ls_tree;
1624
1625 if ($diff_status eq "A") {
1626 return ("link", $diff_status) if -l $path;
1627 return ("dir", $diff_status) if -d $path;
1628 return ("file", $diff_status);
1629 }
1630
1631 my $mode = (split(' ', $ls_tree))[0] || "";
1632
1633 return ("link", $diff_status) if $mode eq "120000";
1634 return ("dir", $diff_status) if $mode eq "040000";
1635 return ("file", $diff_status);
1636 }
1637
1638 sub md5sum {
1639 my $arg = shift;
1640 my $ref = ref $arg;
1641 my $md5 = Digest::MD5->new();
1642 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1643 $md5->addfile($arg) or croak $!;
1644 } elsif ($ref eq 'SCALAR') {
1645 $md5->add($$arg) or croak $!;
1646 } elsif (!$ref) {
1647 $md5->add($arg) or croak $!;
1648 } else {
1649 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1650 }
1651 return $md5->hexdigest();
1652 }
1653
1654 sub gc_directory {
1655 if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1656 my $out_filename = $_ . ".gz";
1657 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1658 binmode $in_fh;
1659 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1660 die "Unable to open $out_filename: $!\n";
1661
1662 my $res;
1663 while ($res = sysread($in_fh, my $str, 1024)) {
1664 $gz->gzwrite($str) or
1665 die "Unable to write: ".$gz->gzerror()."!\n";
1666 }
1667 unlink $_ or die "unlink $File::Find::name: $!\n";
1668 } elsif (-f $_ && basename($_) eq "index") {
1669 unlink $_ or die "unlink $_: $!\n";
1670 }
1671 }
1672
1673 package Git::SVN;
1674 use strict;
1675 use warnings;
1676 use Fcntl qw/:DEFAULT :seek/;
1677 use constant rev_map_fmt => 'NH40';
1678 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1679 $_repack $_repack_flags $_use_svm_props $_head
1680 $_use_svnsync_props $no_reuse_existing $_minimize_url
1681 $_use_log_author $_add_author_from $_localtime/;
1682 use Carp qw/croak/;
1683 use File::Path qw/mkpath/;
1684 use File::Copy qw/copy/;
1685 use IPC::Open3;
1686 use Memoize; # core since 5.8.0, Jul 2002
1687 use Memoize::Storable;
1688
1689 my ($_gc_nr, $_gc_period);
1690
1691 # properties that we do not log:
1692 my %SKIP_PROP;
1693 BEGIN {
1694 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1695 svn:special svn:executable
1696 svn:entry:committed-rev
1697 svn:entry:last-author
1698 svn:entry:uuid
1699 svn:entry:committed-date/;
1700
1701 # some options are read globally, but can be overridden locally
1702 # per [svn-remote "..."] section. Command-line options will *NOT*
1703 # override options set in an [svn-remote "..."] section
1704 no strict 'refs';
1705 for my $option (qw/follow_parent no_metadata use_svm_props
1706 use_svnsync_props/) {
1707 my $key = $option;
1708 $key =~ tr/_//d;
1709 my $prop = "-$option";
1710 *$option = sub {
1711 my ($self) = @_;
1712 return $self->{$prop} if exists $self->{$prop};
1713 my $k = "svn-remote.$self->{repo_id}.$key";
1714 eval { command_oneline(qw/config --get/, $k) };
1715 if ($@) {
1716 $self->{$prop} = ${"Git::SVN::_$option"};
1717 } else {
1718 my $v = command_oneline(qw/config --bool/,$k);
1719 $self->{$prop} = $v eq 'false' ? 0 : 1;
1720 }
1721 return $self->{$prop};
1722 }
1723 }
1724 }
1725
1726
1727 my (%LOCKFILES, %INDEX_FILES);
1728 END {
1729 unlink keys %LOCKFILES if %LOCKFILES;
1730 unlink keys %INDEX_FILES if %INDEX_FILES;
1731 }
1732
1733 sub resolve_local_globs {
1734 my ($url, $fetch, $glob_spec) = @_;
1735 return unless defined $glob_spec;
1736 my $ref = $glob_spec->{ref};
1737 my $path = $glob_spec->{path};
1738 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1739 next unless m#^$ref->{regex}$#;
1740 my $p = $1;
1741 my $pathname = desanitize_refname($path->full_path($p));
1742 my $refname = desanitize_refname($ref->full_path($p));
1743 if (my $existing = $fetch->{$pathname}) {
1744 if ($existing ne $refname) {
1745 die "Refspec conflict:\n",
1746 "existing: $existing\n",
1747 " globbed: $refname\n";
1748 }
1749 my $u = (::cmt_metadata("$refname"))[0];
1750 $u =~ s!^\Q$url\E(/|$)!! or die
1751 "$refname: '$url' not found in '$u'\n";
1752 if ($pathname ne $u) {
1753 warn "W: Refspec glob conflict ",
1754 "(ref: $refname):\n",
1755 "expected path: $pathname\n",
1756 " real path: $u\n",
1757 "Continuing ahead with $u\n";
1758 next;
1759 }
1760 } else {
1761 $fetch->{$pathname} = $refname;
1762 }
1763 }
1764 }
1765
1766 sub parse_revision_argument {
1767 my ($base, $head) = @_;
1768 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1769 return ($base, $head);
1770 }
1771 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1772 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1773 return ($head, $head) if ($::_revision eq 'HEAD');
1774 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1775 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1776 die "revision argument: $::_revision not understood by git-svn\n";
1777 }
1778
1779 sub fetch_all {
1780 my ($repo_id, $remotes) = @_;
1781 if (ref $repo_id) {
1782 my $gs = $repo_id;
1783 $repo_id = undef;
1784 $repo_id = $gs->{repo_id};
1785 }
1786 $remotes ||= read_all_remotes();
1787 my $remote = $remotes->{$repo_id} or
1788 die "[svn-remote \"$repo_id\"] unknown\n";
1789 my $fetch = $remote->{fetch};
1790 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1791 my (@gs, @globs);
1792 my $ra = Git::SVN::Ra->new($url);
1793 my $uuid = $ra->get_uuid;
1794 my $head = $ra->get_latest_revnum;
1795
1796 # ignore errors, $head revision may not even exist anymore
1797 eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1798 warn "W: $@\n" if $@;
1799
1800 my $base = defined $fetch ? $head : 0;
1801
1802 # read the max revs for wildcard expansion (branches/*, tags/*)
1803 foreach my $t (qw/branches tags/) {
1804 defined $remote->{$t} or next;
1805 push @globs, @{$remote->{$t}};
1806
1807 my $max_rev = eval { tmp_config(qw/--int --get/,
1808 "svn-remote.$repo_id.${t}-maxRev") };
1809 if (defined $max_rev && ($max_rev < $base)) {
1810 $base = $max_rev;
1811 } elsif (!defined $max_rev) {
1812 $base = 0;
1813 }
1814 }
1815
1816 if ($fetch) {
1817 foreach my $p (sort keys %$fetch) {
1818 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1819 my $lr = $gs->rev_map_max;
1820 if (defined $lr) {
1821 $base = $lr if ($lr < $base);
1822 }
1823 push @gs, $gs;
1824 }
1825 }
1826
1827 ($base, $head) = parse_revision_argument($base, $head);
1828 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1829 }
1830
1831 sub read_all_remotes {
1832 my $r = {};
1833 my $use_svm_props = eval { command_oneline(qw/config --bool
1834 svn.useSvmProps/) };
1835 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1836 my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1837 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1838 if (m!^(.+)\.fetch=$svn_refspec$!) {
1839 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1840 die("svn-remote.$remote: remote ref '$remote_ref' "
1841 . "must start with 'refs/'\n")
1842 unless $remote_ref =~ m{^refs/};
1843 $local_ref = uri_decode($local_ref);
1844 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1845 $r->{$remote}->{svm} = {} if $use_svm_props;
1846 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1847 $r->{$1}->{svm} = {};
1848 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1849 $r->{$1}->{url} = $2;
1850 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
1851 $r->{$1}->{pushurl} = $2;
1852 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1853 my ($remote, $t, $local_ref, $remote_ref) =
1854 ($1, $2, $3, $4);
1855 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1856 . "must start with 'refs/'\n")
1857 unless $remote_ref =~ m{^refs/};
1858 $local_ref = uri_decode($local_ref);
1859 my $rs = {
1860 t => $t,
1861 remote => $remote,
1862 path => Git::SVN::GlobSpec->new($local_ref, 1),
1863 ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1864 if (length($rs->{ref}->{right}) != 0) {
1865 die "The '*' glob character must be the last ",
1866 "character of '$remote_ref'\n";
1867 }
1868 push @{ $r->{$remote}->{$t} }, $rs;
1869 }
1870 }
1871
1872 map {
1873 if (defined $r->{$_}->{svm}) {
1874 my $svm;
1875 eval {
1876 my $section = "svn-remote.$_";
1877 $svm = {
1878 source => tmp_config('--get',
1879 "$section.svm-source"),
1880 replace => tmp_config('--get',
1881 "$section.svm-replace"),
1882 }
1883 };
1884 $r->{$_}->{svm} = $svm;
1885 }
1886 } keys %$r;
1887
1888 $r;
1889 }
1890
1891 sub init_vars {
1892 $_gc_nr = $_gc_period = 1000;
1893 if (defined $_repack || defined $_repack_flags) {
1894 warn "Repack options are obsolete; they have no effect.\n";
1895 }
1896 }
1897
1898 sub verify_remotes_sanity {
1899 return unless -d $ENV{GIT_DIR};
1900 my %seen;
1901 foreach (command(qw/config -l/)) {
1902 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1903 if ($seen{$1}) {
1904 die "Remote ref refs/remote/$1 is tracked by",
1905 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1906 "Please resolve this ambiguity in ",
1907 "your git configuration file before ",
1908 "continuing\n";
1909 }
1910 $seen{$1} = $_;
1911 }
1912 }
1913 }
1914
1915 sub find_existing_remote {
1916 my ($url, $remotes) = @_;
1917 return undef if $no_reuse_existing;
1918 my $existing;
1919 foreach my $repo_id (keys %$remotes) {
1920 my $u = $remotes->{$repo_id}->{url} or next;
1921 next if $u ne $url;
1922 $existing = $repo_id;
1923 last;
1924 }
1925 $existing;
1926 }
1927
1928 sub init_remote_config {
1929 my ($self, $url, $no_write) = @_;
1930 $url =~ s!/+$!!; # strip trailing slash
1931 my $r = read_all_remotes();
1932 my $existing = find_existing_remote($url, $r);
1933 if ($existing) {
1934 unless ($no_write) {
1935 print STDERR "Using existing ",
1936 "[svn-remote \"$existing\"]\n";
1937 }
1938 $self->{repo_id} = $existing;
1939 } elsif ($_minimize_url) {
1940 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1941 $existing = find_existing_remote($min_url, $r);
1942 if ($existing) {
1943 unless ($no_write) {
1944 print STDERR "Using existing ",
1945 "[svn-remote \"$existing\"]\n";
1946 }
1947 $self->{repo_id} = $existing;
1948 }
1949 if ($min_url ne $url) {
1950 unless ($no_write) {
1951 print STDERR "Using higher level of URL: ",
1952 "$url => $min_url\n";
1953 }
1954 my $old_path = $self->{path};
1955 $self->{path} = $url;
1956 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1957 if (length $old_path) {
1958 $self->{path} .= "/$old_path";
1959 }
1960 $url = $min_url;
1961 }
1962 }
1963 my $orig_url;
1964 if (!$existing) {
1965 # verify that we aren't overwriting anything:
1966 $orig_url = eval {
1967 command_oneline('config', '--get',
1968 "svn-remote.$self->{repo_id}.url")
1969 };
1970 if ($orig_url && ($orig_url ne $url)) {
1971 die "svn-remote.$self->{repo_id}.url already set: ",
1972 "$orig_url\nwanted to set to: $url\n";
1973 }
1974 }
1975 my ($xrepo_id, $xpath) = find_ref($self->refname);
1976 if (!$no_write && defined $xpath) {
1977 die "svn-remote.$xrepo_id.fetch already set to track ",
1978 "$xpath:", $self->refname, "\n";
1979 }
1980 unless ($no_write) {
1981 command_noisy('config',
1982 "svn-remote.$self->{repo_id}.url", $url);
1983 $self->{path} =~ s{^/}{};
1984 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1985 command_noisy('config', '--add',
1986 "svn-remote.$self->{repo_id}.fetch",
1987 "$self->{path}:".$self->refname);
1988 }
1989 $self->{url} = $url;
1990 }
1991
1992 sub find_by_url { # repos_root and, path are optional
1993 my ($class, $full_url, $repos_root, $path) = @_;
1994
1995 return undef unless defined $full_url;
1996 remove_username($full_url);
1997 remove_username($repos_root) if defined $repos_root;
1998 my $remotes = read_all_remotes();
1999 if (defined $full_url && defined $repos_root && !defined $path) {
2000 $path = $full_url;
2001 $path =~ s#^\Q$repos_root\E(?:/|$)##;
2002 }
2003 foreach my $repo_id (keys %$remotes) {
2004 my $u = $remotes->{$repo_id}->{url} or next;
2005 remove_username($u);
2006 next if defined $repos_root && $repos_root ne $u;
2007
2008 my $fetch = $remotes->{$repo_id}->{fetch} || {};
2009 foreach my $t (qw/branches tags/) {
2010 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
2011 resolve_local_globs($u, $fetch, $globspec);
2012 }
2013 }
2014 my $p = $path;
2015 my $rwr = rewrite_root({repo_id => $repo_id});
2016 my $svm = $remotes->{$repo_id}->{svm}
2017 if defined $remotes->{$repo_id}->{svm};
2018 unless (defined $p) {
2019 $p = $full_url;
2020 my $z = $u;
2021 my $prefix = '';
2022 if ($rwr) {
2023 $z = $rwr;
2024 remove_username($z);
2025 } elsif (defined $svm) {
2026 $z = $svm->{source};
2027 $prefix = $svm->{replace};
2028 $prefix =~ s#^\Q$u\E(?:/|$)##;
2029 $prefix =~ s#/$##;
2030 }
2031 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2032 }
2033 foreach my $f (keys %$fetch) {
2034 next if $f ne $p;
2035 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2036 }
2037 }
2038 undef;
2039 }
2040
2041 sub init {
2042 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2043 my $self = _new($class, $repo_id, $ref_id, $path);
2044 if (defined $url) {
2045 $self->init_remote_config($url, $no_write);
2046 }
2047 $self;
2048 }
2049
2050 sub find_ref {
2051 my ($ref_id) = @_;
2052 foreach (command(qw/config -l/)) {
2053 next unless m!^svn-remote\.(.+)\.fetch=
2054 \s*(.*?)\s*:\s*(.+?)\s*$!x;
2055 my ($repo_id, $path, $ref) = ($1, $2, $3);
2056 if ($ref eq $ref_id) {
2057 $path = '' if ($path =~ m#^\./?#);
2058 return ($repo_id, $path);
2059 }
2060 }
2061 (undef, undef, undef);
2062 }
2063
2064 sub new {
2065 my ($class, $ref_id, $repo_id, $path) = @_;
2066 if (defined $ref_id && !defined $repo_id && !defined $path) {
2067 ($repo_id, $path) = find_ref($ref_id);
2068 if (!defined $repo_id) {
2069 die "Could not find a \"svn-remote.*.fetch\" key ",
2070 "in the repository configuration matching: ",
2071 "$ref_id\n";
2072 }
2073 }
2074 my $self = _new($class, $repo_id, $ref_id, $path);
2075 if (!defined $self->{path} || !length $self->{path}) {
2076 my $fetch = command_oneline('config', '--get',
2077 "svn-remote.$repo_id.fetch",
2078 ":$ref_id\$") or
2079 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2080 "\":$ref_id\$\" in config\n";
2081 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2082 }
2083 $self->{path} =~ s{/+}{/}g;
2084 $self->{path} =~ s{\A/}{};
2085 $self->{path} =~ s{/\z}{};
2086 $self->{url} = command_oneline('config', '--get',
2087 "svn-remote.$repo_id.url") or
2088 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2089 $self->{pushurl} = eval { command_oneline('config', '--get',
2090 "svn-remote.$repo_id.pushurl") };
2091 $self->rebuild;
2092 $self;
2093 }
2094
2095 sub refname {
2096 my ($refname) = $_[0]->{ref_id} ;
2097
2098 # It cannot end with a slash /, we'll throw up on this because
2099 # SVN can't have directories with a slash in their name, either:
2100 if ($refname =~ m{/$}) {
2101 die "ref: '$refname' ends with a trailing slash, this is ",
2102 "not permitted by git nor Subversion\n";
2103 }
2104
2105 # It cannot have ASCII control character space, tilde ~, caret ^,
2106 # colon :, question-mark ?, asterisk *, space, or open bracket [
2107 # anywhere.
2108 #
2109 # Additionally, % must be escaped because it is used for escaping
2110 # and we want our escaped refname to be reversible
2111 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2112
2113 # no slash-separated component can begin with a dot .
2114 # /.* becomes /%2E*
2115 $refname =~ s{/\.}{/%2E}g;
2116
2117 # It cannot have two consecutive dots .. anywhere
2118 # .. becomes %2E%2E
2119 $refname =~ s{\.\.}{%2E%2E}g;
2120
2121 # trailing dots and .lock are not allowed
2122 # .$ becomes %2E and .lock becomes %2Elock
2123 $refname =~ s{\.(?=$|lock$)}{%2E};
2124
2125 # the sequence @{ is used to access the reflog
2126 # @{ becomes %40{
2127 $refname =~ s{\@\{}{%40\{}g;
2128
2129 return $refname;
2130 }
2131
2132 sub desanitize_refname {
2133 my ($refname) = @_;
2134 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2135 return $refname;
2136 }
2137
2138 sub svm_uuid {
2139 my ($self) = @_;
2140 return $self->{svm}->{uuid} if $self->svm;
2141 $self->ra;
2142 unless ($self->{svm}) {
2143 die "SVM UUID not cached, and reading remotely failed\n";
2144 }
2145 $self->{svm}->{uuid};
2146 }
2147
2148 sub svm {
2149 my ($self) = @_;
2150 return $self->{svm} if $self->{svm};
2151 my $svm;
2152 # see if we have it in our config, first:
2153 eval {
2154 my $section = "svn-remote.$self->{repo_id}";
2155 $svm = {
2156 source => tmp_config('--get', "$section.svm-source"),
2157 uuid => tmp_config('--get', "$section.svm-uuid"),
2158 replace => tmp_config('--get', "$section.svm-replace"),
2159 }
2160 };
2161 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2162 $self->{svm} = $svm;
2163 }
2164 $self->{svm};
2165 }
2166
2167 sub _set_svm_vars {
2168 my ($self, $ra) = @_;
2169 return $ra if $self->svm;
2170
2171 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2172 "(svm:source, svm:uuid) ",
2173 "from the following URLs:\n" );
2174 sub read_svm_props {
2175 my ($self, $ra, $path, $r) = @_;
2176 my $props = ($ra->get_dir($path, $r))[2];
2177 my $src = $props->{'svm:source'};
2178 my $uuid = $props->{'svm:uuid'};
2179 return undef if (!$src || !$uuid);
2180
2181 chomp($src, $uuid);
2182
2183 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2184 or die "doesn't look right - svm:uuid is '$uuid'\n";
2185
2186 # the '!' is used to mark the repos_root!/relative/path
2187 $src =~ s{/?!/?}{/};
2188 $src =~ s{/+$}{}; # no trailing slashes please
2189 # username is of no interest
2190 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2191
2192 my $replace = $ra->{url};
2193 $replace .= "/$path" if length $path;
2194
2195 my $section = "svn-remote.$self->{repo_id}";
2196 tmp_config("$section.svm-source", $src);
2197 tmp_config("$section.svm-replace", $replace);
2198 tmp_config("$section.svm-uuid", $uuid);
2199 $self->{svm} = {
2200 source => $src,
2201 uuid => $uuid,
2202 replace => $replace
2203 };
2204 }
2205
2206 my $r = $ra->get_latest_revnum;
2207 my $path = $self->{path};
2208 my %tried;
2209 while (length $path) {
2210 unless ($tried{"$self->{url}/$path"}) {
2211 return $ra if $self->read_svm_props($ra, $path, $r);
2212 $tried{"$self->{url}/$path"} = 1;
2213 }
2214 $path =~ s#/?[^/]+$##;
2215 }
2216 die "Path: '$path' should be ''\n" if $path ne '';
2217 return $ra if $self->read_svm_props($ra, $path, $r);
2218 $tried{"$self->{url}/$path"} = 1;
2219
2220 if ($ra->{repos_root} eq $self->{url}) {
2221 die @err, (map { " $_\n" } keys %tried), "\n";
2222 }
2223
2224 # nope, make sure we're connected to the repository root:
2225 my $ok;
2226 my @tried_b;
2227 $path = $ra->{svn_path};
2228 $ra = Git::SVN::Ra->new($ra->{repos_root});
2229 while (length $path) {
2230 unless ($tried{"$ra->{url}/$path"}) {
2231 $ok = $self->read_svm_props($ra, $path, $r);
2232 last if $ok;
2233 $tried{"$ra->{url}/$path"} = 1;
2234 }
2235 $path =~ s#/?[^/]+$##;
2236 }
2237 die "Path: '$path' should be ''\n" if $path ne '';
2238 $ok ||= $self->read_svm_props($ra, $path, $r);
2239 $tried{"$ra->{url}/$path"} = 1;
2240 if (!$ok) {
2241 die @err, (map { " $_\n" } keys %tried), "\n";
2242 }
2243 Git::SVN::Ra->new($self->{url});
2244 }
2245
2246 sub svnsync {
2247 my ($self) = @_;
2248 return $self->{svnsync} if $self->{svnsync};
2249
2250 if ($self->no_metadata) {
2251 die "Can't have both 'noMetadata' and ",
2252 "'useSvnsyncProps' options set!\n";
2253 }
2254 if ($self->rewrite_root) {
2255 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2256 "options set!\n";
2257 }
2258 if ($self->rewrite_uuid) {
2259 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2260 "options set!\n";
2261 }
2262
2263 my $svnsync;
2264 # see if we have it in our config, first:
2265 eval {
2266 my $section = "svn-remote.$self->{repo_id}";
2267
2268 my $url = tmp_config('--get', "$section.svnsync-url");
2269 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2270 die "doesn't look right - svn:sync-from-url is '$url'\n";
2271
2272 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2273 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2274 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2275
2276 $svnsync = { url => $url, uuid => $uuid }
2277 };
2278 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2279 return $self->{svnsync} = $svnsync;
2280 }
2281
2282 my $err = "useSvnsyncProps set, but failed to read " .
2283 "svnsync property: svn:sync-from-";
2284 my $rp = $self->ra->rev_proplist(0);
2285
2286 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2287 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2288 die "doesn't look right - svn:sync-from-url is '$url'\n";
2289
2290 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2291 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2292 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2293
2294 my $section = "svn-remote.$self->{repo_id}";
2295 tmp_config('--add', "$section.svnsync-uuid", $uuid);
2296 tmp_config('--add', "$section.svnsync-url", $url);
2297 return $self->{svnsync} = { url => $url, uuid => $uuid };
2298 }
2299
2300 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2301 # remote lookup (useful for 'git svn log').
2302 sub ra_uuid {
2303 my ($self) = @_;
2304 unless ($self->{ra_uuid}) {
2305 my $key = "svn-remote.$self->{repo_id}.uuid";
2306 my $uuid = eval { tmp_config('--get', $key) };
2307 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2308 $self->{ra_uuid} = $uuid;
2309 } else {
2310 die "ra_uuid called without URL\n" unless $self->{url};
2311 $self->{ra_uuid} = $self->ra->get_uuid;
2312 tmp_config('--add', $key, $self->{ra_uuid});
2313 }
2314 }
2315 $self->{ra_uuid};
2316 }
2317
2318 sub _set_repos_root {
2319 my ($self, $repos_root) = @_;
2320 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2321 $repos_root ||= $self->ra->{repos_root};
2322 tmp_config($k, $repos_root);
2323 $repos_root;
2324 }
2325
2326 sub repos_root {
2327 my ($self) = @_;
2328 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2329 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2330 }
2331
2332 sub ra {
2333 my ($self) = shift;
2334 my $ra = Git::SVN::Ra->new($self->{url});
2335 $self->_set_repos_root($ra->{repos_root});
2336 if ($self->use_svm_props && !$self->{svm}) {
2337 if ($self->no_metadata) {
2338 die "Can't have both 'noMetadata' and ",
2339 "'useSvmProps' options set!\n";
2340 } elsif ($self->use_svnsync_props) {
2341 die "Can't have both 'useSvnsyncProps' and ",
2342 "'useSvmProps' options set!\n";
2343 }
2344 $ra = $self->_set_svm_vars($ra);
2345 $self->{-want_revprops} = 1;
2346 }
2347 $ra;
2348 }
2349
2350 # prop_walk(PATH, REV, SUB)
2351 # -------------------------
2352 # Recursively traverse PATH at revision REV and invoke SUB for each
2353 # directory that contains a SVN property. SUB will be invoked as
2354 # follows: &SUB(gs, path, props); where `gs' is this instance of
2355 # Git::SVN, `path' the path to the directory where the properties
2356 # `props' were found. The `path' will be relative to point of checkout,
2357 # that is, if url://repo/trunk is the current Git branch, and that
2358 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2359 # as `path' (note the trailing `/').
2360 sub prop_walk {
2361 my ($self, $path, $rev, $sub) = @_;
2362
2363 $path =~ s#^/##;
2364 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2365 $path =~ s#^/*#/#g;
2366 my $p = $path;
2367 # Strip the irrelevant part of the path.
2368 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2369 # Ensure the path is terminated by a `/'.
2370 $p =~ s#/*$#/#;
2371
2372 # The properties contain all the internal SVN stuff nobody
2373 # (usually) cares about.
2374 my $interesting_props = 0;
2375 foreach (keys %{$props}) {
2376 # If it doesn't start with `svn:', it must be a
2377 # user-defined property.
2378 ++$interesting_props and next if $_ !~ /^svn:/;
2379 # FIXME: Fragile, if SVN adds new public properties,
2380 # this needs to be updated.
2381 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2382 |eol-style|mime-type
2383 |externals|needs-lock)$/x;
2384 }
2385 &$sub($self, $p, $props) if $interesting_props;
2386
2387 foreach (sort keys %$dirent) {
2388 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2389 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2390 }
2391 }
2392
2393 sub last_rev { ($_[0]->last_rev_commit)[0] }
2394 sub last_commit { ($_[0]->last_rev_commit)[1] }
2395
2396 # returns the newest SVN revision number and newest commit SHA1
2397 sub last_rev_commit {
2398 my ($self) = @_;
2399 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2400 return ($self->{last_rev}, $self->{last_commit});
2401 }
2402 my $c = ::verify_ref($self->refname.'^0');
2403 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2404 my $rev = (::cmt_metadata($c))[1];
2405 if (defined $rev) {
2406 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2407 return ($rev, $c);
2408 }
2409 }
2410 my $map_path = $self->map_path;
2411 unless (-e $map_path) {
2412 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2413 return (undef, undef);
2414 }
2415 my ($rev, $commit) = $self->rev_map_max(1);
2416 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2417 return ($rev, $commit);
2418 }
2419
2420 sub get_fetch_range {
2421 my ($self, $min, $max) = @_;
2422 $max ||= $self->ra->get_latest_revnum;
2423 $min ||= $self->rev_map_max;
2424 (++$min, $max);
2425 }
2426
2427 sub tmp_config {
2428 my (@args) = @_;
2429 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2430 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2431 if (! -f $config && -f $old_def_config) {
2432 rename $old_def_config, $config or
2433 die "Failed rename $old_def_config => $config: $!\n";
2434 }
2435 my $old_config = $ENV{GIT_CONFIG};
2436 $ENV{GIT_CONFIG} = $config;
2437 $@ = undef;
2438 my @ret = eval {
2439 unless (-f $config) {
2440 mkfile($config);
2441 open my $fh, '>', $config or
2442 die "Can't open $config: $!\n";
2443 print $fh "; This file is used internally by ",
2444 "git-svn\n" or die
2445 "Couldn't write to $config: $!\n";
2446 print $fh "; You should not have to edit it\n" or
2447 die "Couldn't write to $config: $!\n";
2448 close $fh or die "Couldn't close $config: $!\n";
2449 }
2450 command('config', @args);
2451 };
2452 my $err = $@;
2453 if (defined $old_config) {
2454 $ENV{GIT_CONFIG} = $old_config;
2455 } else {
2456 delete $ENV{GIT_CONFIG};
2457 }
2458 die $err if $err;
2459 wantarray ? @ret : $ret[0];
2460 }
2461
2462 sub tmp_index_do {
2463 my ($self, $sub) = @_;
2464 my $old_index = $ENV{GIT_INDEX_FILE};
2465 $ENV{GIT_INDEX_FILE} = $self->{index};
2466 $@ = undef;
2467 my @ret = eval {
2468 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2469 mkpath([$dir]) unless -d $dir;
2470 &$sub;
2471 };
2472 my $err = $@;
2473 if (defined $old_index) {
2474 $ENV{GIT_INDEX_FILE} = $old_index;
2475 } else {
2476 delete $ENV{GIT_INDEX_FILE};
2477 }
2478 die $err if $err;
2479 wantarray ? @ret : $ret[0];
2480 }
2481
2482 sub assert_index_clean {
2483 my ($self, $treeish) = @_;
2484
2485 $self->tmp_index_do(sub {
2486 command_noisy('read-tree', $treeish) unless -e $self->{index};
2487 my $x = command_oneline('write-tree');
2488 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2489 /^tree ($::sha1)/mo);
2490 return if $y eq $x;
2491
2492 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2493 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2494 command_noisy('read-tree', $treeish);
2495 $x = command_oneline('write-tree');
2496 if ($y ne $x) {
2497 ::fatal "trees ($treeish) $y != $x\n",
2498 "Something is seriously wrong...";
2499 }
2500 });
2501 }
2502
2503 sub get_commit_parents {
2504 my ($self, $log_entry) = @_;
2505 my (%seen, @ret, @tmp);
2506 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2507 if (my $ip = $self->{inject_parents}) {
2508 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2509 push @tmp, $commit;
2510 }
2511 }
2512 if (my $cur = ::verify_ref($self->refname.'^0')) {
2513 push @tmp, $cur;
2514 }
2515 if (my $ipd = $self->{inject_parents_dcommit}) {
2516 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2517 push @tmp, @$commit;
2518 }
2519 }
2520 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2521 while (my $p = shift @tmp) {
2522 next if $seen{$p};
2523 $seen{$p} = 1;
2524 push @ret, $p;
2525 }
2526 @ret;
2527 }
2528
2529 sub rewrite_root {
2530 my ($self) = @_;
2531 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2532 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2533 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2534 if ($rwr) {
2535 $rwr =~ s#/+$##;
2536 if ($rwr !~ m#^[a-z\+]+://#) {
2537 die "$rwr is not a valid URL (key: $k)\n";
2538 }
2539 }
2540 $self->{-rewrite_root} = $rwr;
2541 }
2542
2543 sub rewrite_uuid {
2544 my ($self) = @_;
2545 return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2546 my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2547 my $rwid = eval { command_oneline(qw/config --get/, $k) };
2548 if ($rwid) {
2549 $rwid =~ s#/+$##;
2550 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2551 die "$rwid is not a valid UUID (key: $k)\n";
2552 }
2553 }
2554 $self->{-rewrite_uuid} = $rwid;
2555 }
2556
2557 sub metadata_url {
2558 my ($self) = @_;
2559 ($self->rewrite_root || $self->{url}) .
2560 (length $self->{path} ? '/' . $self->{path} : '');
2561 }
2562
2563 sub full_url {
2564 my ($self) = @_;
2565 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2566 }
2567
2568 sub full_pushurl {
2569 my ($self) = @_;
2570 if ($self->{pushurl}) {
2571 return $self->{pushurl} . (length $self->{path} ? '/' .
2572 $self->{path} : '');
2573 } else {
2574 return $self->full_url;
2575 }
2576 }
2577
2578 sub set_commit_header_env {
2579 my ($log_entry) = @_;
2580 my %env;
2581 foreach my $ned (qw/NAME EMAIL DATE/) {
2582 foreach my $ac (qw/AUTHOR COMMITTER/) {
2583 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2584 }
2585 }
2586
2587 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2588 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2589 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2590
2591 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2592 ? $log_entry->{commit_name}
2593 : $log_entry->{name};
2594 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2595 ? $log_entry->{commit_email}
2596 : $log_entry->{email};
2597 \%env;
2598 }
2599
2600 sub restore_commit_header_env {
2601 my ($env) = @_;
2602 foreach my $ned (qw/NAME EMAIL DATE/) {
2603 foreach my $ac (qw/AUTHOR COMMITTER/) {
2604 my $k = "GIT_${ac}_${ned}";
2605 if (defined $env->{$k}) {
2606 $ENV{$k} = $env->{$k};
2607 } else {
2608 delete $ENV{$k};
2609 }
2610 }
2611 }
2612 }
2613
2614 sub gc {
2615 command_noisy('gc', '--auto');
2616 };
2617
2618 sub do_git_commit {
2619 my ($self, $log_entry) = @_;
2620 my $lr = $self->last_rev;
2621 if (defined $lr && $lr >= $log_entry->{revision}) {
2622 die "Last fetched revision of ", $self->refname,
2623 " was r$lr, but we are about to fetch: ",
2624 "r$log_entry->{revision}!\n";
2625 }
2626 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2627 croak "$log_entry->{revision} = $c already exists! ",
2628 "Why are we refetching it?\n";
2629 }
2630 my $old_env = set_commit_header_env($log_entry);
2631 my $tree = $log_entry->{tree};
2632 if (!defined $tree) {
2633 $tree = $self->tmp_index_do(sub {
2634 command_oneline('write-tree') });
2635 }
2636 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2637
2638 my @exec = ('git', 'commit-tree', $tree);
2639 foreach ($self->get_commit_parents($log_entry)) {
2640 push @exec, '-p', $_;
2641 }
2642 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2643 or croak $!;
2644 binmode $msg_fh;
2645
2646 # we always get UTF-8 from SVN, but we may want our commits in
2647 # a different encoding.
2648 if (my $enc = Git::config('i18n.commitencoding')) {
2649 require Encode;
2650 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2651 }
2652 print $msg_fh $log_entry->{log} or croak $!;
2653 restore_commit_header_env($old_env);
2654 unless ($self->no_metadata) {
2655 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2656 or croak $!;
2657 }
2658 $msg_fh->flush == 0 or croak $!;
2659 close $msg_fh or croak $!;
2660 chomp(my $commit = do { local $/; <$out_fh> });
2661 close $out_fh or croak $!;
2662 waitpid $pid, 0;
2663 croak $? if $?;
2664 if ($commit !~ /^$::sha1$/o) {
2665 die "Failed to commit, invalid sha1: $commit\n";
2666 }
2667
2668 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2669
2670 $self->{last_rev} = $log_entry->{revision};
2671 $self->{last_commit} = $commit;
2672 print "r$log_entry->{revision}" unless $::_q > 1;
2673 if (defined $log_entry->{svm_revision}) {
2674 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2675 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2676 0, $self->svm_uuid);
2677 }
2678 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2679 if (--$_gc_nr == 0) {
2680 $_gc_nr = $_gc_period;
2681 gc();
2682 }
2683 return $commit;
2684 }
2685
2686 sub match_paths {
2687 my ($self, $paths, $r) = @_;
2688 return 1 if $self->{path} eq '';
2689 if (my $path = $paths->{"/$self->{path}"}) {
2690 return ($path->{action} eq 'D') ? 0 : 1;
2691 }
2692 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2693 if (grep /$self->{path_regex}/, keys %$paths) {
2694 return 1;
2695 }
2696 my $c = '';
2697 foreach (split m#/#, $self->{path}) {
2698 $c .= "/$_";
2699 next unless ($paths->{$c} &&
2700 ($paths->{$c}->{action} =~ /^[AR]$/));
2701 if ($self->ra->check_path($self->{path}, $r) ==
2702 $SVN::Node::dir) {
2703 return 1;
2704 }
2705 }
2706 return 0;
2707 }
2708
2709 sub find_parent_branch {
2710 my ($self, $paths, $rev) = @_;
2711 return undef unless $self->follow_parent;
2712 unless (defined $paths) {
2713 my $err_handler = $SVN::Error::handler;
2714 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2715 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2716 sub { $paths = $_[0] });
2717 $SVN::Error::handler = $err_handler;
2718 }
2719 return undef unless defined $paths;
2720
2721 # look for a parent from another branch:
2722 my @b_path_components = split m#/#, $self->{path};
2723 my @a_path_components;
2724 my $i;
2725 while (@b_path_components) {
2726 $i = $paths->{'/'.join('/', @b_path_components)};
2727 last if $i && defined $i->{copyfrom_path};
2728 unshift(@a_path_components, pop(@b_path_components));
2729 }
2730 return undef unless defined $i && defined $i->{copyfrom_path};
2731 my $branch_from = $i->{copyfrom_path};
2732 if (@a_path_components) {
2733 print STDERR "branch_from: $branch_from => ";
2734 $branch_from .= '/'.join('/', @a_path_components);
2735 print STDERR $branch_from, "\n";
2736 }
2737 my $r = $i->{copyfrom_rev};
2738 my $repos_root = $self->ra->{repos_root};
2739 my $url = $self->ra->{url};
2740 my $new_url = $url . $branch_from;
2741 print STDERR "Found possible branch point: ",
2742 "$new_url => ", $self->full_url, ", $r\n"
2743 unless $::_q > 1;
2744 $branch_from =~ s#^/##;
2745 my $gs = $self->other_gs($new_url, $url,
2746 $branch_from, $r, $self->{ref_id});
2747 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2748 {
2749 my ($base, $head);
2750 if (!defined $r0 || !defined $parent) {
2751 ($base, $head) = parse_revision_argument(0, $r);
2752 } else {
2753 if ($r0 < $r) {
2754 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2755 0, 1, sub { $base = $_[1] - 1 });
2756 }
2757 }
2758 if (defined $base && $base <= $r) {
2759 $gs->fetch($base, $r);
2760 }
2761 ($r0, $parent) = $gs->find_rev_before($r, 1);
2762 }
2763 if (defined $r0 && defined $parent) {
2764 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2765 unless $::_q > 1;
2766 my $ed;
2767 if ($self->ra->can_do_switch) {
2768 $self->assert_index_clean($parent);
2769 print STDERR "Following parent with do_switch\n"
2770 unless $::_q > 1;
2771 # do_switch works with svn/trunk >= r22312, but that
2772 # is not included with SVN 1.4.3 (the latest version
2773 # at the moment), so we can't rely on it
2774 $self->{last_rev} = $r0;
2775 $self->{last_commit} = $parent;
2776 $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2777 $gs->ra->gs_do_switch($r0, $rev, $gs,
2778 $self->full_url, $ed)
2779 or die "SVN connection failed somewhere...\n";
2780 } elsif ($self->ra->trees_match($new_url, $r0,
2781 $self->full_url, $rev)) {
2782 print STDERR "Trees match:\n",
2783 " $new_url\@$r0\n",
2784 " ${\$self->full_url}\@$rev\n",
2785 "Following parent with no changes\n"
2786 unless $::_q > 1;
2787 $self->tmp_index_do(sub {
2788 command_noisy('read-tree', $parent);
2789 });
2790 $self->{last_commit} = $parent;
2791 } else {
2792 print STDERR "Following parent with do_update\n"
2793 unless $::_q > 1;
2794 $ed = SVN::Git::Fetcher->new($self);
2795 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2796 or die "SVN connection failed somewhere...\n";
2797 }
2798 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2799 return $self->make_log_entry($rev, [$parent], $ed);
2800 }
2801 return undef;
2802 }
2803
2804 sub do_fetch {
2805 my ($self, $paths, $rev) = @_;
2806 my $ed;
2807 my ($last_rev, @parents);
2808 if (my $lc = $self->last_commit) {
2809 # we can have a branch that was deleted, then re-added
2810 # under the same name but copied from another path, in
2811 # which case we'll have multiple parents (we don't
2812 # want to break the original ref, nor lose copypath info):
2813 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2814 push @{$log_entry->{parents}}, $lc;
2815 return $log_entry;
2816 }
2817 $ed = SVN::Git::Fetcher->new($self);
2818 $last_rev = $self->{last_rev};
2819 $ed->{c} = $lc;
2820 @parents = ($lc);
2821 } else {
2822 $last_rev = $rev;
2823 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2824 return $log_entry;
2825 }
2826 $ed = SVN::Git::Fetcher->new($self);
2827 }
2828 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2829 die "SVN connection failed somewhere...\n";
2830 }
2831 $self->make_log_entry($rev, \@parents, $ed);
2832 }
2833
2834 sub mkemptydirs {
2835 my ($self, $r) = @_;
2836
2837 sub scan {
2838 my ($r, $empty_dirs, $line) = @_;
2839 if (defined $r && $line =~ /^r(\d+)$/) {
2840 return 0 if $1 > $r;
2841 } elsif ($line =~ /^ \+empty_dir: (.+)$/) {
2842 $empty_dirs->{$1} = 1;
2843 } elsif ($line =~ /^ \-empty_dir: (.+)$/) {
2844 my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2845 delete @$empty_dirs{@d};
2846 }
2847 1; # continue
2848 };
2849
2850 my %empty_dirs = ();
2851 my $gz_file = "$self->{dir}/unhandled.log.gz";
2852 if (-f $gz_file) {
2853 if (!$can_compress) {
2854 warn "Compress::Zlib could not be found; ",
2855 "empty directories in $gz_file will not be read\n";
2856 } else {
2857 my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2858 die "Unable to open $gz_file: $!\n";
2859 my $line;
2860 while ($gz->gzreadline($line) > 0) {
2861 scan($r, \%empty_dirs, $line) or last;
2862 }
2863 $gz->gzclose;
2864 }
2865 }
2866
2867 if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2868 binmode $fh or croak "binmode: $!";
2869 while (<$fh>) {
2870 scan($r, \%empty_dirs, $_) or last;
2871 }
2872 close $fh;
2873 }
2874
2875 my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2876 foreach my $d (sort keys %empty_dirs) {
2877 $d = uri_decode($d);
2878 $d =~ s/$strip//;
2879 next unless length($d);
2880 next if -d $d;
2881 if (-e $d) {
2882 warn "$d exists but is not a directory\n";
2883 } else {
2884 print "creating empty directory: $d\n";
2885 mkpath([$d]);
2886 }
2887 }
2888 }
2889
2890 sub get_untracked {
2891 my ($self, $ed) = @_;
2892 my @out;
2893 my $h = $ed->{empty};
2894 foreach (sort keys %$h) {
2895 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2896 push @out, " $act: " . uri_encode($_);
2897 warn "W: $act: $_\n";
2898 }
2899 foreach my $t (qw/dir_prop file_prop/) {
2900 $h = $ed->{$t} or next;
2901 foreach my $path (sort keys %$h) {
2902 my $ppath = $path eq '' ? '.' : $path;
2903 foreach my $prop (sort keys %{$h->{$path}}) {
2904 next if $SKIP_PROP{$prop};
2905 my $v = $h->{$path}->{$prop};
2906 my $t_ppath_prop = "$t: " .
2907 uri_encode($ppath) . ' ' .
2908 uri_encode($prop);
2909 if (defined $v) {
2910 push @out, " +$t_ppath_prop " .
2911 uri_encode($v);
2912 } else {
2913 push @out, " -$t_ppath_prop";
2914 }
2915 }
2916 }
2917 }
2918 foreach my $t (qw/absent_file absent_directory/) {
2919 $h = $ed->{$t} or next;
2920 foreach my $parent (sort keys %$h) {
2921 foreach my $path (sort @{$h->{$parent}}) {
2922 push @out, " $t: " .
2923 uri_encode("$parent/$path");
2924 warn "W: $t: $parent/$path ",
2925 "Insufficient permissions?\n";
2926 }
2927 }
2928 }
2929 \@out;
2930 }
2931
2932 # parse_svn_date(DATE)
2933 # --------------------
2934 # Given a date (in UTC) from Subversion, return a string in the format
2935 # "<TZ Offset> <local date/time>" that Git will use.
2936 #
2937 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2938 # is true we'll convert it to the local timezone instead.
2939 sub parse_svn_date {
2940 my $date = shift || return '+0000 1970-01-01 00:00:00';
2941 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2942 (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2943 croak "Unable to parse date: $date\n";
2944 my $parsed_date; # Set next.
2945
2946 if ($Git::SVN::_localtime) {
2947 # Translate the Subversion datetime to an epoch time.
2948 # Begin by switching ourselves to $date's timezone, UTC.
2949 my $old_env_TZ = $ENV{TZ};
2950 $ENV{TZ} = 'UTC';
2951
2952 my $epoch_in_UTC =
2953 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2954
2955 # Determine our local timezone (including DST) at the
2956 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
2957 # value of TZ, if any, at the time we were run.
2958 if (defined $Git::SVN::Log::TZ) {
2959 $ENV{TZ} = $Git::SVN::Log::TZ;
2960 } else {
2961 delete $ENV{TZ};
2962 }
2963
2964 my $our_TZ =
2965 POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2966
2967 # This converts $epoch_in_UTC into our local timezone.
2968 my ($sec, $min, $hour, $mday, $mon, $year,
2969 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2970
2971 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2972 $our_TZ, $year + 1900, $mon + 1,
2973 $mday, $hour, $min, $sec);
2974
2975 # Reset us to the timezone in effect when we entered
2976 # this routine.
2977 if (defined $old_env_TZ) {
2978 $ENV{TZ} = $old_env_TZ;
2979 } else {
2980 delete $ENV{TZ};
2981 }
2982 } else {
2983 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2984 }
2985
2986 return $parsed_date;
2987 }
2988
2989 sub other_gs {
2990 my ($self, $new_url, $url,
2991 $branch_from, $r, $old_ref_id) = @_;
2992 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2993 unless ($gs) {
2994 my $ref_id = $old_ref_id;
2995 $ref_id =~ s/\@\d+-*$//;
2996 $ref_id .= "\@$r";
2997 # just grow a tail if we're not unique enough :x
2998 $ref_id .= '-' while find_ref($ref_id);
2999 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
3000 if ($u =~ s#^\Q$url\E(/|$)##) {
3001 $p = $u;
3002 $u = $url;
3003 $repo_id = $self->{repo_id};
3004 }
3005 while (1) {
3006 # It is possible to tag two different subdirectories at
3007 # the same revision. If the url for an existing ref
3008 # does not match, we must either find a ref with a
3009 # matching url or create a new ref by growing a tail.
3010 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
3011 my (undef, $max_commit) = $gs->rev_map_max(1);
3012 last if (!$max_commit);
3013 my ($url) = ::cmt_metadata($max_commit);
3014 last if ($url eq $gs->full_url);
3015 $ref_id .= '-';
3016 }
3017 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
3018 }
3019 $gs
3020 }
3021
3022 sub call_authors_prog {
3023 my ($orig_author) = @_;
3024 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
3025 my $author = `$::_authors_prog $orig_author`;
3026 if ($? != 0) {
3027 die "$::_authors_prog failed with exit code $?\n"
3028 }
3029 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
3030 my ($name, $email) = ($1, $2);
3031 $email = undef if length $2 == 0;
3032 return [$name, $email];
3033 } else {
3034 die "Author: $orig_author: $::_authors_prog returned "
3035 . "invalid author format: $author\n";
3036 }
3037 }
3038
3039 sub check_author {
3040 my ($author) = @_;
3041 if (!defined $author || length $author == 0) {
3042 $author = '(no author)';
3043 }
3044 if (!defined $::users{$author}) {
3045 if (defined $::_authors_prog) {
3046 $::users{$author} = call_authors_prog($author);
3047 } elsif (defined $::_authors) {
3048 die "Author: $author not defined in $::_authors file\n";
3049 }
3050 }
3051 $author;
3052 }
3053
3054 sub find_extra_svk_parents {
3055 my ($self, $ed, $tickets, $parents) = @_;
3056 # aha! svk:merge property changed...
3057 my @tickets = split "\n", $tickets;
3058 my @known_parents;
3059 for my $ticket ( @tickets ) {
3060 my ($uuid, $path, $rev) = split /:/, $ticket;
3061 if ( $uuid eq $self->ra_uuid ) {
3062 my $url = $self->{url};
3063 my $repos_root = $url;
3064 my $branch_from = $path;
3065 $branch_from =~ s{^/}{};
3066 my $gs = $self->other_gs($repos_root."/".$branch_from,
3067 $url,
3068 $branch_from,
3069 $rev,
3070 $self->{ref_id});
3071 if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3072 # wahey! we found it, but it might be
3073 # an old one (!)
3074 push @known_parents, [ $rev, $commit ];
3075 }
3076 }
3077 }
3078 # Ordering matters; highest-numbered commit merge tickets
3079 # first, as they may account for later merge ticket additions
3080 # or changes.
3081 @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3082 for my $parent ( @known_parents ) {
3083 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3084 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3085 my $new;
3086 while ( <$msg_fh> ) {
3087 $new=1;last;
3088 }
3089 command_close_pipe($msg_fh, $ctx);
3090 if ( $new ) {
3091 print STDERR
3092 "Found merge parent (svk:merge ticket): $parent\n";
3093 push @$parents, $parent;
3094 }
3095 }
3096 }
3097
3098 sub lookup_svn_merge {
3099 my $uuid = shift;
3100 my $url = shift;
3101 my $merge = shift;
3102
3103 my ($source, $revs) = split ":", $merge;
3104 my $path = $source;
3105 $path =~ s{^/}{};
3106 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3107 if ( !$gs ) {
3108 warn "Couldn't find revmap for $url$source\n";
3109 return;
3110 }
3111 my @ranges = split ",", $revs;
3112 my ($tip, $tip_commit);
3113 my @merged_commit_ranges;
3114 # find the tip
3115 for my $range ( @ranges ) {
3116 my ($bottom, $top) = split "-", $range;
3117 $top ||= $bottom;
3118 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3119 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3120
3121 unless ($top_commit and $bottom_commit) {
3122 warn "W:unknown path/rev in svn:mergeinfo "
3123 ."dirprop: $source:$range\n";
3124 next;
3125 }
3126
3127 push @merged_commit_ranges,
3128 "$bottom_commit^..$top_commit";
3129
3130 if ( !defined $tip or $top > $tip ) {
3131 $tip = $top;
3132 $tip_commit = $top_commit;
3133 }
3134 }
3135 return ($tip_commit, @merged_commit_ranges);
3136 }
3137
3138 sub _rev_list {
3139 my ($msg_fh, $ctx) = command_output_pipe(
3140 "rev-list", @_,
3141 );
3142 my @rv;
3143 while ( <$msg_fh> ) {
3144 chomp;
3145 push @rv, $_;
3146 }
3147 command_close_pipe($msg_fh, $ctx);
3148 @rv;
3149 }
3150
3151 sub check_cherry_pick {
3152 my $base = shift;
3153 my $tip = shift;
3154 my $parents = shift;
3155 my @ranges = @_;
3156 my %commits = map { $_ => 1 }
3157 _rev_list("--no-merges", $tip, "--not", $base, @$parents);
3158 for my $range ( @ranges ) {
3159 delete @commits{_rev_list($range)};
3160 }
3161 for my $commit (keys %commits) {
3162 if (has_no_changes($commit)) {
3163 delete $commits{$commit};
3164 }
3165 }
3166 return (keys %commits);
3167 }
3168
3169 sub has_no_changes {
3170 my $commit = shift;
3171
3172 my @revs = split / /, command_oneline(
3173 qw(rev-list --parents -1 -m), $commit);
3174
3175 # Commits with no parents, e.g. the start of a partial branch,
3176 # have changes by definition.
3177 return 1 if (@revs < 2);
3178
3179 # Commits with multiple parents, e.g a merge, have no changes
3180 # by definition.
3181 return 0 if (@revs > 2);
3182
3183 return (command_oneline("rev-parse", "$commit^{tree}") eq
3184 command_oneline("rev-parse", "$commit~1^{tree}"));
3185 }
3186
3187 # The GIT_DIR environment variable is not always set until after the command
3188 # line arguments are processed, so we can't memoize in a BEGIN block.
3189 {
3190 my $memoized = 0;
3191
3192 sub memoize_svn_mergeinfo_functions {
3193 return if $memoized;
3194 $memoized = 1;
3195
3196 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3197 mkpath([$cache_path]) unless -d $cache_path;
3198
3199 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3200 "$cache_path/lookup_svn_merge.db", 'nstore';
3201 memoize 'lookup_svn_merge',
3202 SCALAR_CACHE => 'FAULT',
3203 LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3204 ;
3205
3206 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3207 "$cache_path/check_cherry_pick.db", 'nstore';
3208 memoize 'check_cherry_pick',
3209 SCALAR_CACHE => 'FAULT',
3210 LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3211 ;
3212
3213 tie my %has_no_changes_cache => 'Memoize::Storable',
3214 "$cache_path/has_no_changes.db", 'nstore';
3215 memoize 'has_no_changes',
3216 SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3217 LIST_CACHE => 'FAULT',
3218 ;
3219 }
3220
3221 sub unmemoize_svn_mergeinfo_functions {
3222 return if not $memoized;
3223 $memoized = 0;
3224
3225 Memoize::unmemoize 'lookup_svn_merge';
3226 Memoize::unmemoize 'check_cherry_pick';
3227 Memoize::unmemoize 'has_no_changes';
3228 }
3229
3230 Memoize::memoize 'Git::SVN::repos_root';
3231 }
3232
3233 END {
3234 # Force cache writeout explicitly instead of waiting for
3235 # global destruction to avoid segfault in Storable:
3236 # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3237 unmemoize_svn_mergeinfo_functions();
3238 }
3239
3240 sub parents_exclude {
3241 my $parents = shift;
3242 my @commits = @_;
3243 return unless @commits;
3244
3245 my @excluded;
3246 my $excluded;
3247 do {
3248 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3249 $excluded = command_oneline(@cmd);
3250 if ( $excluded ) {
3251 my @new;
3252 my $found;
3253 for my $commit ( @commits ) {
3254 if ( $commit eq $excluded ) {
3255 push @excluded, $commit;
3256 $found++;
3257 last;
3258 }
3259 else {
3260 push @new, $commit;
3261 }
3262 }
3263 die "saw commit '$excluded' in rev-list output, "
3264 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3265 unless $found;
3266 @commits = @new;
3267 }
3268 }
3269 while ($excluded and @commits);
3270
3271 return @excluded;
3272 }
3273
3274
3275 # note: this function should only be called if the various dirprops
3276 # have actually changed
3277 sub find_extra_svn_parents {
3278 my ($self, $ed, $mergeinfo, $parents) = @_;
3279 # aha! svk:merge property changed...
3280
3281 memoize_svn_mergeinfo_functions();
3282
3283 # We first search for merged tips which are not in our
3284 # history. Then, we figure out which git revisions are in
3285 # that tip, but not this revision. If all of those revisions
3286 # are now marked as merge, we can add the tip as a parent.
3287 my @merges = split "\n", $mergeinfo;
3288 my @merge_tips;
3289 my $url = $self->{url};
3290 my $uuid = $self->ra_uuid;
3291 my %ranges;
3292 for my $merge ( @merges ) {
3293 my ($tip_commit, @ranges) =
3294 lookup_svn_merge( $uuid, $url, $merge );
3295 unless (!$tip_commit or
3296 grep { $_ eq $tip_commit } @$parents ) {
3297 push @merge_tips, $tip_commit;
3298 $ranges{$tip_commit} = \@ranges;
3299 } else {
3300 push @merge_tips, undef;
3301 }
3302 }
3303
3304 my %excluded = map { $_ => 1 }
3305 parents_exclude($parents, grep { defined } @merge_tips);
3306
3307 # check merge tips for new parents
3308 my @new_parents;
3309 for my $merge_tip ( @merge_tips ) {
3310 my $spec = shift @merges;
3311 next unless $merge_tip and $excluded{$merge_tip};
3312
3313 my $ranges = $ranges{$merge_tip};
3314
3315 # check out 'new' tips
3316 my $merge_base;
3317 eval {
3318 $merge_base = command_oneline(
3319 "merge-base",
3320 @$parents, $merge_tip,
3321 );
3322 };
3323 if ($@) {
3324 die "An error occurred during merge-base"
3325 unless $@->isa("Git::Error::Command");
3326
3327 warn "W: Cannot find common ancestor between ".
3328 "@$parents and $merge_tip. Ignoring merge info.\n";
3329 next;
3330 }
3331
3332 # double check that there are no missing non-merge commits
3333 my (@incomplete) = check_cherry_pick(
3334 $merge_base, $merge_tip,
3335 $parents,
3336 @$ranges,
3337 );
3338
3339 if ( @incomplete ) {
3340 warn "W:svn cherry-pick ignored ($spec) - missing "
3341 .@incomplete." commit(s) (eg $incomplete[0])\n";
3342 } else {
3343 warn
3344 "Found merge parent (svn:mergeinfo prop): ",
3345 $merge_tip, "\n";
3346 push @new_parents, $merge_tip;
3347 }
3348 }
3349
3350 # cater for merges which merge commits from multiple branches
3351 if ( @new_parents > 1 ) {
3352 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3353 for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3354 next if $i == $j;
3355 next unless $new_parents[$i];
3356 next unless $new_parents[$j];
3357 my $revs = command_oneline(
3358 "rev-list", "-1",
3359 "$new_parents[$i]..$new_parents[$j]",
3360 );
3361 if ( !$revs ) {
3362 undef($new_parents[$j]);
3363 }
3364 }
3365 }
3366 }
3367 push @$parents, grep { defined } @new_parents;
3368 }
3369
3370 sub make_log_entry {
3371 my ($self, $rev, $parents, $ed) = @_;
3372 my $untracked = $self->get_untracked($ed);
3373
3374 my @parents = @$parents;
3375 my $ps = $ed->{path_strip} || "";
3376 for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3377 my $props = $ed->{dir_prop}{$path};
3378 if ( $props->{"svk:merge"} ) {
3379 $self->find_extra_svk_parents
3380 ($ed, $props->{"svk:merge"}, \@parents);
3381 }
3382 if ( $props->{"svn:mergeinfo"} ) {
3383 $self->find_extra_svn_parents
3384 ($ed,
3385 $props->{"svn:mergeinfo"},
3386 \@parents);
3387 }
3388 }
3389
3390 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3391 print $un "r$rev\n" or croak $!;
3392 print $un $_, "\n" foreach @$untracked;
3393 my %log_entry = ( parents => \@parents, revision => $rev,
3394 log => '');
3395
3396 my $headrev;
3397 my $logged = delete $self->{logged_rev_props};
3398 if (!$logged || $self->{-want_revprops}) {
3399 my $rp = $self->ra->rev_proplist($rev);
3400 foreach (sort keys %$rp) {
3401 my $v = $rp->{$_};
3402 if (/^svn:(author|date|log)$/) {
3403 $log_entry{$1} = $v;
3404 } elsif ($_ eq 'svm:headrev') {
3405 $headrev = $v;
3406 } else {
3407 print $un " rev_prop: ", uri_encode($_), ' ',
3408 uri_encode($v), "\n";
3409 }
3410 }
3411 } else {
3412 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3413 }
3414 close $un or croak $!;
3415
3416 $log_entry{date} = parse_svn_date($log_entry{date});
3417 $log_entry{log} .= "\n";
3418 my $author = $log_entry{author} = check_author($log_entry{author});
3419 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3420 : ($author, undef);
3421
3422 my ($commit_name, $commit_email) = ($name, $email);
3423 if ($_use_log_author) {
3424 my $name_field;
3425 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3426 $name_field = $1;
3427 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3428 $name_field = $1;
3429 }
3430 if (!defined $name_field) {
3431 if (!defined $email) {
3432 $email = $name;
3433 }
3434 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3435 ($name, $email) = ($1, $2);
3436 } elsif ($name_field =~ /(.*)@/) {
3437 ($name, $email) = ($1, $name_field);
3438 } else {
3439 ($name, $email) = ($name_field, $name_field);
3440 }
3441 }
3442 if (defined $headrev && $self->use_svm_props) {
3443 if ($self->rewrite_root) {
3444 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3445 "options set!\n";
3446 }
3447 if ($self->rewrite_uuid) {
3448 die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3449 "options set!\n";
3450 }
3451 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3452 # we don't want "SVM: initializing mirror for junk" ...
3453 return undef if $r == 0;
3454 my $svm = $self->svm;
3455 if ($uuid ne $svm->{uuid}) {
3456 die "UUID mismatch on SVM path:\n",
3457 "expected: $svm->{uuid}\n",
3458 " got: $uuid\n";
3459 }
3460 my $full_url = $self->full_url;
3461 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3462 die "Failed to replace '$svm->{replace}' with ",
3463 "'$svm->{source}' in $full_url\n";
3464 # throw away username for storing in records
3465 remove_username($full_url);
3466 $log_entry{metadata} = "$full_url\@$r $uuid";
3467 $log_entry{svm_revision} = $r;
3468 $email ||= "$author\@$uuid";
3469 $commit_email ||= "$author\@$uuid";
3470 } elsif ($self->use_svnsync_props) {
3471 my $full_url = $self->svnsync->{url};
3472 $full_url .= "/$self->{path}" if length $self->{path};
3473 remove_username($full_url);
3474 my $uuid = $self->svnsync->{uuid};
3475 $log_entry{metadata} = "$full_url\@$rev $uuid";
3476 $email ||= "$author\@$uuid";
3477 $commit_email ||= "$author\@$uuid";
3478 } else {
3479 my $url = $self->metadata_url;
3480 remove_username($url);
3481 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3482 $log_entry{metadata} = "$url\@$rev " . $uuid;
3483 $email ||= "$author\@" . $uuid;
3484 $commit_email ||= "$author\@" . $uuid;
3485 }
3486 $log_entry{name} = $name;
3487 $log_entry{email} = $email;
3488 $log_entry{commit_name} = $commit_name;
3489 $log_entry{commit_email} = $commit_email;
3490 \%log_entry;
3491 }
3492
3493 sub fetch {
3494 my ($self, $min_rev, $max_rev, @parents) = @_;
3495 my ($last_rev, $last_commit) = $self->last_rev_commit;
3496 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3497 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3498 }
3499
3500 sub set_tree_cb {
3501 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3502 $self->{inject_parents} = { $rev => $tree };
3503 $self->fetch(undef, undef);
3504 }
3505
3506 sub set_tree {
3507 my ($self, $tree) = (shift, shift);
3508 my $log_entry = ::get_commit_entry($tree);
3509 unless ($self->{last_rev}) {
3510 ::fatal("Must have an existing revision to commit");
3511 }
3512 my %ed_opts = ( r => $self->{last_rev},
3513 log => $log_entry->{log},
3514 ra => $self->ra,
3515 tree_a => $self->{last_commit},
3516 tree_b => $tree,
3517 editor_cb => sub {
3518 $self->set_tree_cb($log_entry, $tree, @_) },
3519 svn_path => $self->{path} );
3520 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3521 print "No changes\nr$self->{last_rev} = $tree\n";
3522 }
3523 }
3524
3525 sub rebuild_from_rev_db {
3526 my ($self, $path) = @_;
3527 my $r = -1;
3528 open my $fh, '<', $path or croak "open: $!";
3529 binmode $fh or croak "binmode: $!";
3530 while (<$fh>) {
3531 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3532 chomp($_);
3533 ++$r;
3534 next if $_ eq ('0' x 40);
3535 $self->rev_map_set($r, $_);
3536 print "r$r = $_\n";
3537 }
3538 close $fh or croak "close: $!";
3539 unlink $path or croak "unlink: $!";
3540 }
3541
3542 sub rebuild {
3543 my ($self) = @_;
3544 my $map_path = $self->map_path;
3545 my $partial = (-e $map_path && ! -z $map_path);
3546 return unless ::verify_ref($self->refname.'^0');
3547 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3548 my $rev_db = $self->rev_db_path;
3549 $self->rebuild_from_rev_db($rev_db);
3550 if ($self->use_svm_props) {
3551 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3552 $self->rebuild_from_rev_db($svm_rev_db);
3553 }
3554 $self->unlink_rev_db_symlink;
3555 return;
3556 }
3557 print "Rebuilding $map_path ...\n" if (!$partial);
3558 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3559 (undef, undef));
3560 my ($log, $ctx) =
3561 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3562 ($head ? "$head.." : "") . $self->refname,
3563 '--');
3564 my $metadata_url = $self->metadata_url;
3565 remove_username($metadata_url);
3566 my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3567 my $c;
3568 while (<$log>) {
3569 if ( m{^commit ($::sha1)$} ) {
3570 $c = $1;
3571 next;
3572 }
3573 next unless s{^\s*(git-svn-id:)}{$1};
3574 my ($url, $rev, $uuid) = ::extract_metadata($_);
3575 remove_username($url);
3576
3577 # ignore merges (from set-tree)
3578 next if (!defined $rev || !$uuid);
3579
3580 # if we merged or otherwise started elsewhere, this is
3581 # how we break out of it
3582 if (($uuid ne $svn_uuid) ||
3583 ($metadata_url && $url && ($url ne $metadata_url))) {
3584 next;
3585 }
3586 if ($partial && $head) {
3587 print "Partial-rebuilding $map_path ...\n";
3588 print "Currently at $base_rev = $head\n";
3589 $head = undef;
3590 }
3591
3592 $self->rev_map_set($rev, $c);
3593 print "r$rev = $c\n";
3594 }
3595 command_close_pipe($log, $ctx);
3596 print "Done rebuilding $map_path\n" if (!$partial || !$head);
3597 my $rev_db_path = $self->rev_db_path;
3598 if (-f $self->rev_db_path) {
3599 unlink $self->rev_db_path or croak "unlink: $!";
3600 }
3601 $self->unlink_rev_db_symlink;
3602 }
3603
3604 # rev_map:
3605 # Tie::File seems to be prone to offset errors if revisions get sparse,
3606 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3607 # one of my favorite modules is out :< Next up would be one of the DBM
3608 # modules, but I'm not sure which is most portable...
3609 #
3610 # This is the replacement for the rev_db format, which was too big
3611 # and inefficient for large repositories with a lot of sparse history
3612 # (mainly tags)
3613 #
3614 # The format is this:
3615 # - 24 bytes for every record,
3616 # * 4 bytes for the integer representing an SVN revision number
3617 # * 20 bytes representing the sha1 of a git commit
3618 # - No empty padding records like the old format
3619 # (except the last record, which can be overwritten)
3620 # - new records are written append-only since SVN revision numbers
3621 # increase monotonically
3622 # - lookups on SVN revision number are done via a binary search
3623 # - Piping the file to xxd -c24 is a good way of dumping it for
3624 # viewing or editing (piped back through xxd -r), should the need
3625 # ever arise.
3626 # - The last record can be padding revision with an all-zero sha1
3627 # This is used to optimize fetch performance when using multiple
3628 # "fetch" directives in .git/config
3629 #
3630 # These files are disposable unless noMetadata or useSvmProps is set
3631
3632 sub _rev_map_set {
3633 my ($fh, $rev, $commit) = @_;
3634
3635 binmode $fh or croak "binmode: $!";
3636 my $size = (stat($fh))[7];
3637 ($size % 24) == 0 or croak "inconsistent size: $size";
3638
3639 my $wr_offset = 0;
3640 if ($size > 0) {
3641 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3642 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3643 $read == 24 or croak "read only $read bytes (!= 24)";
3644 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3645 if ($last_commit eq ('0' x40)) {
3646 if ($size >= 48) {
3647 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3648 $read = sysread($fh, $buf, 24) or
3649 croak "read: $!";
3650 $read == 24 or
3651 croak "read only $read bytes (!= 24)";
3652 ($last_rev, $last_commit) =
3653 unpack(rev_map_fmt, $buf);
3654 if ($last_commit eq ('0' x40)) {
3655 croak "inconsistent .rev_map\n";
3656 }
3657 }
3658 if ($last_rev >= $rev) {
3659 croak "last_rev is higher!: $last_rev >= $rev";
3660 }
3661 $wr_offset = -24;
3662 }
3663 }
3664 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3665 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3666 croak "write: $!";
3667 }
3668
3669 sub _rev_map_reset {
3670 my ($fh, $rev, $commit) = @_;
3671 my $c = _rev_map_get($fh, $rev);
3672 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3673 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3674 truncate $fh, $offset or croak "truncate: $!";
3675 }
3676
3677 sub mkfile {
3678 my ($path) = @_;
3679 unless (-e $path) {
3680 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3681 mkpath([$dir]) unless -d $dir;
3682 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3683 close $fh or die "Couldn't close (create) $path: $!\n";
3684 }
3685 }
3686
3687 sub rev_map_set {
3688 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3689 defined $commit or die "missing arg3\n";
3690 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3691 my $db = $self->map_path($uuid);
3692 my $db_lock = "$db.lock";
3693 my $sig;
3694 $update_ref ||= 0;
3695 if ($update_ref) {
3696 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3697 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3698 }
3699 mkfile($db);
3700
3701 $LOCKFILES{$db_lock} = 1;
3702 my $sync;
3703 # both of these options make our .rev_db file very, very important
3704 # and we can't afford to lose it because rebuild() won't work
3705 if ($self->use_svm_props || $self->no_metadata) {
3706 $sync = 1;
3707 copy($db, $db_lock) or die "rev_map_set(@_): ",
3708 "Failed to copy: ",
3709 "$db => $db_lock ($!)\n";
3710 } else {
3711 rename $db, $db_lock or die "rev_map_set(@_): ",
3712 "Failed to rename: ",
3713 "$db => $db_lock ($!)\n";
3714 }
3715
3716 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3717 or croak "Couldn't open $db_lock: $!\n";
3718 $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3719 _rev_map_set($fh, $rev, $commit);
3720 if ($sync) {
3721 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3722 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3723 }
3724 close $fh or croak $!;
3725 if ($update_ref) {
3726 $_head = $self;
3727 my $note = "";
3728 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3729 command_noisy('update-ref', '-m', "r$rev$note",
3730 $self->refname, $commit);
3731 }
3732 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3733 "$db_lock => $db ($!)\n";
3734 delete $LOCKFILES{$db_lock};
3735 if ($update_ref) {
3736 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3737 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3738 kill $sig, $$ if defined $sig;
3739 }
3740 }
3741
3742 # If want_commit, this will return an array of (rev, commit) where
3743 # commit _must_ be a valid commit in the archive.
3744 # Otherwise, it'll return the max revision (whether or not the
3745 # commit is valid or just a 0x40 placeholder).
3746 sub rev_map_max {
3747 my ($self, $want_commit) = @_;
3748 $self->rebuild;
3749 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3750 $want_commit ? ($r, $c) : $r;
3751 }
3752
3753 sub rev_map_max_norebuild {
3754 my ($self, $want_commit) = @_;
3755 my $map_path = $self->map_path;
3756 stat $map_path or return $want_commit ? (0, undef) : 0;
3757 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3758 binmode $fh or croak "binmode: $!";
3759 my $size = (stat($fh))[7];
3760 ($size % 24) == 0 or croak "inconsistent size: $size";
3761
3762 if ($size == 0) {
3763 close $fh or croak "close: $!";
3764 return $want_commit ? (0, undef) : 0;
3765 }
3766
3767 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3768 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3769 my ($r, $c) = unpack(rev_map_fmt, $buf);
3770 if ($want_commit && $c eq ('0' x40)) {
3771 if ($size < 48) {
3772 return $want_commit ? (0, undef) : 0;
3773 }
3774 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3775 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3776 ($r, $c) = unpack(rev_map_fmt, $buf);
3777 if ($c eq ('0'x40)) {
3778 croak "Penultimate record is all-zeroes in $map_path";
3779 }
3780 }
3781 close $fh or croak "close: $!";
3782 $want_commit ? ($r, $c) : $r;
3783 }
3784
3785 sub rev_map_get {
3786 my ($self, $rev, $uuid) = @_;
3787 my $map_path = $self->map_path($uuid);
3788 return undef unless -e $map_path;
3789
3790 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3791 my $c = _rev_map_get($fh, $rev);
3792 close($fh) or croak "close: $!";
3793 $c
3794 }
3795
3796 sub _rev_map_get {
3797 my ($fh, $rev) = @_;
3798
3799 binmode $fh or croak "binmode: $!";
3800 my $size = (stat($fh))[7];
3801 ($size % 24) == 0 or croak "inconsistent size: $size";
3802
3803 if ($size == 0) {
3804 return undef;
3805 }
3806
3807 my ($l, $u) = (0, $size - 24);
3808 my ($r, $c, $buf);
3809
3810 while ($l <= $u) {
3811 my $i = int(($l/24 + $u/24) / 2) * 24;
3812 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3813 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3814 my ($r, $c) = unpack(rev_map_fmt, $buf);
3815
3816 if ($r < $rev) {
3817 $l = $i + 24;
3818 } elsif ($r > $rev) {
3819 $u = $i - 24;
3820 } else { # $r == $rev
3821 return $c eq ('0' x 40) ? undef : $c;
3822 }
3823 }
3824 undef;
3825 }
3826
3827 # Finds the first svn revision that exists on (if $eq_ok is true) or
3828 # before $rev for the current branch. It will not search any lower
3829 # than $min_rev. Returns the git commit hash and svn revision number
3830 # if found, else (undef, undef).
3831 sub find_rev_before {
3832 my ($self, $rev, $eq_ok, $min_rev) = @_;
3833 --$rev unless $eq_ok;
3834 $min_rev ||= 1;
3835 my $max_rev = $self->rev_map_max;
3836 $rev = $max_rev if ($rev > $max_rev);
3837 while ($rev >= $min_rev) {
3838 if (my $c = $self->rev_map_get($rev)) {
3839 return ($rev, $c);
3840 }
3841 --$rev;
3842 }
3843 return (undef, undef);
3844 }
3845
3846 # Finds the first svn revision that exists on (if $eq_ok is true) or
3847 # after $rev for the current branch. It will not search any higher
3848 # than $max_rev. Returns the git commit hash and svn revision number
3849 # if found, else (undef, undef).
3850 sub find_rev_after {
3851 my ($self, $rev, $eq_ok, $max_rev) = @_;
3852 ++$rev unless $eq_ok;
3853 $max_rev ||= $self->rev_map_max;
3854 while ($rev <= $max_rev) {
3855 if (my $c = $self->rev_map_get($rev)) {
3856 return ($rev, $c);
3857 }
3858 ++$rev;
3859 }
3860 return (undef, undef);
3861 }
3862
3863 sub _new {
3864 my ($class, $repo_id, $ref_id, $path) = @_;
3865 unless (defined $repo_id && length $repo_id) {
3866 $repo_id = $Git::SVN::default_repo_id;
3867 }
3868 unless (defined $ref_id && length $ref_id) {
3869 $_prefix = '' unless defined($_prefix);
3870 $_[2] = $ref_id =
3871 "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3872 }
3873 $_[1] = $repo_id;
3874 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3875
3876 # Older repos imported by us used $GIT_DIR/svn/foo instead of
3877 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3878 if ($ref_id =~ m{^refs/remotes/(.*)}) {
3879 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3880 if (-d $old_dir && ! -d $dir) {
3881 $dir = $old_dir;
3882 }
3883 }
3884
3885 $_[3] = $path = '' unless (defined $path);
3886 mkpath([$dir]);
3887 bless {
3888 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3889 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3890 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3891 }
3892
3893 # for read-only access of old .rev_db formats
3894 sub unlink_rev_db_symlink {
3895 my ($self) = @_;
3896 my $link = $self->rev_db_path;
3897 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3898 if (-l $link) {
3899 unlink $link or croak "unlink: $link failed!";
3900 }
3901 }
3902
3903 sub rev_db_path {
3904 my ($self, $uuid) = @_;
3905 my $db_path = $self->map_path($uuid);
3906 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3907 or croak "map_path: $db_path does not contain '/.rev_map.' !";
3908 $db_path;
3909 }
3910
3911 # the new replacement for .rev_db
3912 sub map_path {
3913 my ($self, $uuid) = @_;
3914 $uuid ||= $self->ra_uuid;
3915 "$self->{map_root}.$uuid";
3916 }
3917
3918 sub uri_encode {
3919 my ($f) = @_;
3920 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3921 $f
3922 }
3923
3924 sub uri_decode {
3925 my ($f) = @_;
3926 $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3927 $f
3928 }
3929
3930 sub remove_username {
3931 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3932 }
3933
3934 package Git::SVN::Prompt;
3935 use strict;
3936 use warnings;
3937 require SVN::Core;
3938 use vars qw/$_no_auth_cache $_username/;
3939
3940 sub simple {
3941 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3942 $may_save = undef if $_no_auth_cache;
3943 $default_username = $_username if defined $_username;
3944 if (defined $default_username && length $default_username) {
3945 if (defined $realm && length $realm) {
3946 print STDERR "Authentication realm: $realm\n";
3947 STDERR->flush;
3948 }
3949 $cred->username($default_username);
3950 } else {
3951 username($cred, $realm, $may_save, $pool);
3952 }
3953 $cred->password(_read_password("Password for '" .
3954 $cred->username . "': ", $realm));
3955 $cred->may_save($may_save);
3956 $SVN::_Core::SVN_NO_ERROR;
3957 }
3958
3959 sub ssl_server_trust {
3960 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3961 $may_save = undef if $_no_auth_cache;
3962 print STDERR "Error validating server certificate for '$realm':\n";
3963 {
3964 no warnings 'once';
3965 # All variables SVN::Auth::SSL::* are used only once,
3966 # so we're shutting up Perl warnings about this.
3967 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3968 print STDERR " - The certificate is not issued ",
3969 "by a trusted authority. Use the\n",
3970 " fingerprint to validate ",
3971 "the certificate manually!\n";
3972 }
3973 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3974 print STDERR " - The certificate hostname ",
3975 "does not match.\n";
3976 }
3977 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3978 print STDERR " - The certificate is not yet valid.\n";
3979 }
3980 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3981 print STDERR " - The certificate has expired.\n";
3982 }
3983 if ($failures & $SVN::Auth::SSL::OTHER) {
3984 print STDERR " - The certificate has ",
3985 "an unknown error.\n";
3986 }
3987 } # no warnings 'once'
3988 printf STDERR
3989 "Certificate information:\n".
3990 " - Hostname: %s\n".
3991 " - Valid: from %s until %s\n".
3992 " - Issuer: %s\n".
3993 " - Fingerprint: %s\n",
3994 map $cert_info->$_, qw(hostname valid_from valid_until
3995 issuer_dname fingerprint);
3996 my $choice;
3997 prompt:
3998 print STDERR $may_save ?
3999 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
4000 "(R)eject or accept (t)emporarily? ";
4001 STDERR->flush;
4002 $choice = lc(substr(<STDIN> || 'R', 0, 1));
4003 if ($choice =~ /^t$/i) {
4004 $cred->may_save(undef);
4005 } elsif ($choice =~ /^r$/i) {
4006 return -1;
4007 } elsif ($may_save && $choice =~ /^p$/i) {
4008 $cred->may_save($may_save);
4009 } else {
4010 goto prompt;
4011 }
4012 $cred->accepted_failures($failures);
4013 $SVN::_Core::SVN_NO_ERROR;
4014 }
4015
4016 sub ssl_client_cert {
4017 my ($cred, $realm, $may_save, $pool) = @_;
4018 $may_save = undef if $_no_auth_cache;
4019 print STDERR "Client certificate filename: ";
4020 STDERR->flush;
4021 chomp(my $filename = <STDIN>);
4022 $cred->cert_file($filename);
4023 $cred->may_save($may_save);
4024 $SVN::_Core::SVN_NO_ERROR;
4025 }
4026
4027 sub ssl_client_cert_pw {
4028 my ($cred, $realm, $may_save, $pool) = @_;
4029 $may_save = undef if $_no_auth_cache;
4030 $cred->password(_read_password("Password: ", $realm));
4031 $cred->may_save($may_save);
4032 $SVN::_Core::SVN_NO_ERROR;
4033 }
4034
4035 sub username {
4036 my ($cred, $realm, $may_save, $pool) = @_;
4037 $may_save = undef if $_no_auth_cache;
4038 if (defined $realm && length $realm) {
4039 print STDERR "Authentication realm: $realm\n";
4040 }
4041 my $username;
4042 if (defined $_username) {
4043 $username = $_username;
4044 } else {
4045 print STDERR "Username: ";
4046 STDERR->flush;
4047 chomp($username = <STDIN>);
4048 }
4049 $cred->username($username);
4050 $cred->may_save($may_save);
4051 $SVN::_Core::SVN_NO_ERROR;
4052 }
4053
4054 sub _read_password {
4055 my ($prompt, $realm) = @_;
4056 my $password = '';
4057 if (exists $ENV{GIT_ASKPASS}) {
4058 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4059 $password = <PH>;
4060 $password =~ s/[\012\015]//; # \n\r
4061 close(PH);
4062 } else {
4063 print STDERR $prompt;
4064 STDERR->flush;
4065 require Term::ReadKey;
4066 Term::ReadKey::ReadMode('noecho');
4067 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4068 last if $key =~ /[\012\015]/; # \n\r
4069 $password .= $key;
4070 }
4071 Term::ReadKey::ReadMode('restore');
4072 print STDERR "\n";
4073 STDERR->flush;
4074 }
4075 $password;
4076 }
4077
4078 package SVN::Git::Fetcher;
4079 use vars qw/@ISA/;
4080 use strict;
4081 use warnings;
4082 use Carp qw/croak/;
4083 use IO::File qw//;
4084 use vars qw/$_ignore_regex/;
4085
4086 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4087 sub new {
4088 my ($class, $git_svn, $switch_path) = @_;
4089 my $self = SVN::Delta::Editor->new;
4090 bless $self, $class;
4091 if (exists $git_svn->{last_commit}) {
4092 $self->{c} = $git_svn->{last_commit};
4093 $self->{empty_symlinks} =
4094 _mark_empty_symlinks($git_svn, $switch_path);
4095 }
4096 $self->{ignore_regex} = eval { command_oneline('config', '--get',
4097 "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4098 $self->{empty} = {};
4099 $self->{dir_prop} = {};
4100 $self->{file_prop} = {};
4101 $self->{absent_dir} = {};
4102 $self->{absent_file} = {};
4103 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4104 $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4105 $self;
4106 }
4107
4108 # this uses the Ra object, so it must be called before do_{switch,update},
4109 # not inside them (when the Git::SVN::Fetcher object is passed) to
4110 # do_{switch,update}
4111 sub _mark_empty_symlinks {
4112 my ($git_svn, $switch_path) = @_;
4113 my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4114 return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4115
4116 my %ret;
4117 my ($rev, $cmt) = $git_svn->last_rev_commit;
4118 return {} unless ($rev && $cmt);
4119
4120 # allow the warning to be printed for each revision we fetch to
4121 # ensure the user sees it. The user can also disable the workaround
4122 # on the repository even while git svn is running and the next
4123 # revision fetched will skip this expensive function.
4124 my $printed_warning;
4125 chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4126 my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4127 local $/ = "\0";
4128 my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4129 $pfx .= '/' if length($pfx);
4130 while (<$ls>) {
4131 chomp;
4132 s/\A100644 blob $empty_blob\t//o or next;
4133 unless ($printed_warning) {
4134 print STDERR "Scanning for empty symlinks, ",
4135 "this may take a while if you have ",
4136 "many empty files\n",
4137 "You may disable this with `",
4138 "git config svn.brokenSymlinkWorkaround ",
4139 "false'.\n",
4140 "This may be done in a different ",
4141 "terminal without restarting ",
4142 "git svn\n";
4143 $printed_warning = 1;
4144 }
4145 my $path = $_;
4146 my (undef, $props) =
4147 $git_svn->ra->get_file($pfx.$path, $rev, undef);
4148 if ($props->{'svn:special'}) {
4149 $ret{$path} = 1;
4150 }
4151 }
4152 command_close_pipe($ls, $ctx);
4153 \%ret;
4154 }
4155
4156 # returns true if a given path is inside a ".git" directory
4157 sub in_dot_git {
4158 $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4159 }
4160
4161 # return value: 0 -- don't ignore, 1 -- ignore
4162 sub is_path_ignored {
4163 my ($self, $path) = @_;
4164 return 1 if in_dot_git($path);
4165 return 1 if defined($self->{ignore_regex}) &&
4166 $path =~ m!$self->{ignore_regex}!;
4167 return 0 unless defined($_ignore_regex);
4168 return 1 if $path =~ m!$_ignore_regex!o;
4169 return 0;
4170 }
4171
4172 sub set_path_strip {
4173 my ($self, $path) = @_;
4174 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4175 }
4176
4177 sub open_root {
4178 { path => '' };
4179 }
4180
4181 sub open_directory {
4182 my ($self, $path, $pb, $rev) = @_;
4183 { path => $path };
4184 }
4185
4186 sub git_path {
4187 my ($self, $path) = @_;
4188 if (my $enc = $self->{pathnameencoding}) {
4189 require Encode;
4190 Encode::from_to($path, 'UTF-8', $enc);
4191 }
4192 if ($self->{path_strip}) {
4193 $path =~ s!$self->{path_strip}!! or
4194 die "Failed to strip path '$path' ($self->{path_strip})\n";
4195 }
4196 $path;
4197 }
4198
4199 sub delete_entry {
4200 my ($self, $path, $rev, $pb) = @_;
4201 return undef if $self->is_path_ignored($path);
4202
4203 my $gpath = $self->git_path($path);
4204 return undef if ($gpath eq '');
4205
4206 # remove entire directories.
4207 my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4208 =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4209 if ($tree) {
4210 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4211 -r --name-only -z/,
4212 $tree);
4213 local $/ = "\0";
4214 while (<$ls>) {
4215 chomp;
4216 my $rmpath = "$gpath/$_";
4217 $self->{gii}->remove($rmpath);
4218 print "\tD\t$rmpath\n" unless $::_q;
4219 }
4220 print "\tD\t$gpath/\n" unless $::_q;
4221 command_close_pipe($ls, $ctx);
4222 } else {
4223 $self->{gii}->remove($gpath);
4224 print "\tD\t$gpath\n" unless $::_q;
4225 }
4226 $self->{empty}->{$path} = 0;
4227 undef;
4228 }
4229
4230 sub open_file {
4231 my ($self, $path, $pb, $rev) = @_;
4232 my ($mode, $blob);
4233
4234 goto out if $self->is_path_ignored($path);
4235
4236 my $gpath = $self->git_path($path);
4237 ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4238 =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4239 unless (defined $mode && defined $blob) {
4240 die "$path was not found in commit $self->{c} (r$rev)\n";
4241 }
4242 if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4243 $mode = '120000';
4244 }
4245 out:
4246 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4247 pool => SVN::Pool->new, action => 'M' };
4248 }
4249
4250 sub add_file {
4251 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4252 my $mode;
4253
4254 if (!$self->is_path_ignored($path)) {
4255 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4256 delete $self->{empty}->{$dir};
4257 $mode = '100644';
4258 }
4259 { path => $path, mode_a => $mode, mode_b => $mode,
4260 pool => SVN::Pool->new, action => 'A' };
4261 }
4262
4263 sub add_directory {
4264 my ($self, $path, $cp_path, $cp_rev) = @_;
4265 goto out if $self->is_path_ignored($path);
4266 my $gpath = $self->git_path($path);
4267 if ($gpath eq '') {
4268 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4269 -r --name-only -z/,
4270 $self->{c});
4271 local $/ = "\0";
4272 while (<$ls>) {
4273 chomp;
4274 $self->{gii}->remove($_);
4275 print "\tD\t$_\n" unless $::_q;
4276 }
4277 command_close_pipe($ls, $ctx);
4278 $self->{empty}->{$path} = 0;
4279 }
4280 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4281 delete $self->{empty}->{$dir};
4282 $self->{empty}->{$path} = 1;
4283 out:
4284 { path => $path };
4285 }
4286
4287 sub change_dir_prop {
4288 my ($self, $db, $prop, $value) = @_;
4289 return undef if $self->is_path_ignored($db->{path});
4290 $self->{dir_prop}->{$db->{path}} ||= {};
4291 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4292 undef;
4293 }
4294
4295 sub absent_directory {
4296 my ($self, $path, $pb) = @_;
4297 return undef if $self->is_path_ignored($path);
4298 $self->{absent_dir}->{$pb->{path}} ||= [];
4299 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4300 undef;
4301 }
4302
4303 sub absent_file {
4304 my ($self, $path, $pb) = @_;
4305 return undef if $self->is_path_ignored($path);
4306 $self->{absent_file}->{$pb->{path}} ||= [];
4307 push @{$self->{absent_file}->{$pb->{path}}}, $path;
4308 undef;
4309 }
4310
4311 sub change_file_prop {
4312 my ($self, $fb, $prop, $value) = @_;
4313 return undef if $self->is_path_ignored($fb->{path});
4314 if ($prop eq 'svn:executable') {
4315 if ($fb->{mode_b} != 120000) {
4316 $fb->{mode_b} = defined $value ? 100755 : 100644;
4317 }
4318 } elsif ($prop eq 'svn:special') {
4319 $fb->{mode_b} = defined $value ? 120000 : 100644;
4320 } else {
4321 $self->{file_prop}->{$fb->{path}} ||= {};
4322 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4323 }
4324 undef;
4325 }
4326
4327 sub apply_textdelta {
4328 my ($self, $fb, $exp) = @_;
4329 return undef if $self->is_path_ignored($fb->{path});
4330 my $fh = $::_repository->temp_acquire('svn_delta');
4331 # $fh gets auto-closed() by SVN::TxDelta::apply(),
4332 # (but $base does not,) so dup() it for reading in close_file
4333 open my $dup, '<&', $fh or croak $!;
4334 my $base = $::_repository->temp_acquire('git_blob');
4335
4336 if ($fb->{blob}) {
4337 my ($base_is_link, $size);
4338
4339 if ($fb->{mode_a} eq '120000' &&
4340 ! $self->{empty_symlinks}->{$fb->{path}}) {
4341 print $base 'link ' or die "print $!\n";
4342 $base_is_link = 1;
4343 }
4344 retry:
4345 $size = $::_repository->cat_blob($fb->{blob}, $base);
4346 die "Failed to read object $fb->{blob}" if ($size < 0);
4347
4348 if (defined $exp) {
4349 seek $base, 0, 0 or croak $!;
4350 my $got = ::md5sum($base);
4351 if ($got ne $exp) {
4352 my $err = "Checksum mismatch: ".
4353 "$fb->{path} $fb->{blob}\n" .
4354 "expected: $exp\n" .
4355 " got: $got\n";
4356 if ($base_is_link) {
4357 warn $err,
4358 "Retrying... (possibly ",
4359 "a bad symlink from SVN)\n";
4360 $::_repository->temp_reset($base);
4361 $base_is_link = 0;
4362 goto retry;
4363 }
4364 die $err;
4365 }
4366 }
4367 }
4368 seek $base, 0, 0 or croak $!;
4369 $fb->{fh} = $fh;
4370 $fb->{base} = $base;
4371 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4372 }
4373
4374 sub close_file {
4375 my ($self, $fb, $exp) = @_;
4376 return undef if $self->is_path_ignored($fb->{path});
4377
4378 my $hash;
4379 my $path = $self->git_path($fb->{path});
4380 if (my $fh = $fb->{fh}) {
4381 if (defined $exp) {
4382 seek($fh, 0, 0) or croak $!;
4383 my $got = ::md5sum($fh);
4384 if ($got ne $exp) {
4385 die "Checksum mismatch: $path\n",
4386 "expected: $exp\n got: $got\n";
4387 }
4388 }
4389 if ($fb->{mode_b} == 120000) {
4390 sysseek($fh, 0, 0) or croak $!;
4391 my $rd = sysread($fh, my $buf, 5);
4392
4393 if (!defined $rd) {
4394 croak "sysread: $!\n";
4395 } elsif ($rd == 0) {
4396 warn "$path has mode 120000",
4397 " but it points to nothing\n",
4398 "converting to an empty file with mode",
4399 " 100644\n";
4400 $fb->{mode_b} = '100644';
4401 } elsif ($buf ne 'link ') {
4402 warn "$path has mode 120000",
4403 " but is not a link\n";
4404 } else {
4405 my $tmp_fh = $::_repository->temp_acquire(
4406 'svn_hash');
4407 my $res;
4408 while ($res = sysread($fh, my $str, 1024)) {
4409 my $out = syswrite($tmp_fh, $str, $res);
4410 defined($out) && $out == $res
4411 or croak("write ",
4412 Git::temp_path($tmp_fh),
4413 ": $!\n");
4414 }
4415 defined $res or croak $!;
4416
4417 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4418 Git::temp_release($tmp_fh, 1);
4419 }
4420 }
4421
4422 $hash = $::_repository->hash_and_insert_object(
4423 Git::temp_path($fh));
4424 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4425
4426 Git::temp_release($fb->{base}, 1);
4427 Git::temp_release($fh, 1);
4428 } else {
4429 $hash = $fb->{blob} or die "no blob information\n";
4430 }
4431 $fb->{pool}->clear;
4432 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4433 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4434 undef;
4435 }
4436
4437 sub abort_edit {
4438 my $self = shift;
4439 $self->{nr} = $self->{gii}->{nr};
4440 delete $self->{gii};
4441 $self->SUPER::abort_edit(@_);
4442 }
4443
4444 sub close_edit {
4445 my $self = shift;
4446 $self->{git_commit_ok} = 1;
4447 $self->{nr} = $self->{gii}->{nr};
4448 delete $self->{gii};
4449 $self->SUPER::close_edit(@_);
4450 }
4451
4452 package SVN::Git::Editor;
4453 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4454 use strict;
4455 use warnings;
4456 use Carp qw/croak/;
4457 use IO::File;
4458
4459 sub new {
4460 my ($class, $opts) = @_;
4461 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4462 die "$_ required!\n" unless (defined $opts->{$_});
4463 }
4464
4465 my $pool = SVN::Pool->new;
4466 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4467 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4468 $opts->{r}, $mods);
4469
4470 # $opts->{ra} functions should not be used after this:
4471 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
4472 $opts->{editor_cb}, $pool);
4473 my $self = SVN::Delta::Editor->new(@ce, $pool);
4474 bless $self, $class;
4475 foreach (qw/svn_path r tree_a tree_b/) {
4476 $self->{$_} = $opts->{$_};
4477 }
4478 $self->{url} = $opts->{ra}->{url};
4479 $self->{mods} = $mods;
4480 $self->{types} = $types;
4481 $self->{pool} = $pool;
4482 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4483 $self->{rm} = { };
4484 $self->{path_prefix} = length $self->{svn_path} ?
4485 "$self->{svn_path}/" : '';
4486 $self->{config} = $opts->{config};
4487 $self->{mergeinfo} = $opts->{mergeinfo};
4488 return $self;
4489 }
4490
4491 sub generate_diff {
4492 my ($tree_a, $tree_b) = @_;
4493 my @diff_tree = qw(diff-tree -z -r);
4494 if ($_cp_similarity) {
4495 push @diff_tree, "-C$_cp_similarity";
4496 } else {
4497 push @diff_tree, '-C';
4498 }
4499 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4500 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4501 push @diff_tree, $tree_a, $tree_b;
4502 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4503 local $/ = "\0";
4504 my $state = 'meta';
4505 my @mods;
4506 while (<$diff_fh>) {
4507 chomp $_; # this gets rid of the trailing "\0"
4508 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4509 ($::sha1)\s($::sha1)\s
4510 ([MTCRAD])\d*$/xo) {
4511 push @mods, { mode_a => $1, mode_b => $2,
4512 sha1_a => $3, sha1_b => $4,
4513 chg => $5 };
4514 if ($5 =~ /^(?:C|R)$/) {
4515 $state = 'file_a';
4516 } else {
4517 $state = 'file_b';
4518 }
4519 } elsif ($state eq 'file_a') {
4520 my $x = $mods[$#mods] or croak "Empty array\n";
4521 if ($x->{chg} !~ /^(?:C|R)$/) {
4522 croak "Error parsing $_, $x->{chg}\n";
4523 }
4524 $x->{file_a} = $_;
4525 $state = 'file_b';
4526 } elsif ($state eq 'file_b') {
4527 my $x = $mods[$#mods] or croak "Empty array\n";
4528 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4529 croak "Error parsing $_, $x->{chg}\n";
4530 }
4531 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4532 croak "Error parsing $_, $x->{chg}\n";
4533 }
4534 $x->{file_b} = $_;
4535 $state = 'meta';
4536 } else {
4537 croak "Error parsing $_\n";
4538 }
4539 }
4540 command_close_pipe($diff_fh, $ctx);
4541 \@mods;
4542 }
4543
4544 sub check_diff_paths {
4545 my ($ra, $pfx, $rev, $mods) = @_;
4546 my %types;
4547 $pfx .= '/' if length $pfx;
4548
4549 sub type_diff_paths {
4550 my ($ra, $types, $path, $rev) = @_;
4551 my @p = split m#/+#, $path;
4552 my $c = shift @p;
4553 unless (defined $types->{$c}) {
4554 $types->{$c} = $ra->check_path($c, $rev);
4555 }
4556 while (@p) {
4557 $c .= '/' . shift @p;
4558 next if defined $types->{$c};
4559 $types->{$c} = $ra->check_path($c, $rev);
4560 }
4561 }
4562
4563 foreach my $m (@$mods) {
4564 foreach my $f (qw/file_a file_b/) {
4565 next unless defined $m->{$f};
4566 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4567 if (length $pfx.$dir && ! defined $types{$dir}) {
4568 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4569 }
4570 }
4571 }
4572 \%types;
4573 }
4574
4575 sub split_path {
4576 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4577 }
4578
4579 sub repo_path {
4580 my ($self, $path) = @_;
4581 if (my $enc = $self->{pathnameencoding}) {
4582 require Encode;
4583 Encode::from_to($path, $enc, 'UTF-8');
4584 }
4585 $self->{path_prefix}.(defined $path ? $path : '');
4586 }
4587
4588 sub url_path {
4589 my ($self, $path) = @_;
4590 if ($self->{url} =~ m#^https?://#) {
4591 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4592 }
4593 $self->{url} . '/' . $self->repo_path($path);
4594 }
4595
4596 sub rmdirs {
4597 my ($self) = @_;
4598 my $rm = $self->{rm};
4599 delete $rm->{''}; # we never delete the url we're tracking
4600 return unless %$rm;
4601
4602 foreach (keys %$rm) {
4603 my @d = split m#/#, $_;
4604 my $c = shift @d;
4605 $rm->{$c} = 1;
4606 while (@d) {
4607 $c .= '/' . shift @d;
4608 $rm->{$c} = 1;
4609 }
4610 }
4611 delete $rm->{$self->{svn_path}};
4612 delete $rm->{''}; # we never delete the url we're tracking
4613 return unless %$rm;
4614
4615 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4616 $self->{tree_b});
4617 local $/ = "\0";
4618 while (<$fh>) {
4619 chomp;
4620 my @dn = split m#/#, $_;
4621 while (pop @dn) {
4622 delete $rm->{join '/', @dn};
4623 }
4624 unless (%$rm) {
4625 close $fh;
4626 return;
4627 }
4628 }
4629 command_close_pipe($fh, $ctx);
4630
4631 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4632 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4633 $self->close_directory($bat->{$d}, $p);
4634 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4635 print "\tD+\t$d/\n" unless $::_q;
4636 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4637 delete $bat->{$d};
4638 }
4639 }
4640
4641 sub open_or_add_dir {
4642 my ($self, $full_path, $baton) = @_;
4643 my $t = $self->{types}->{$full_path};
4644 if (!defined $t) {
4645 die "$full_path not known in r$self->{r} or we have a bug!\n";
4646 }
4647 {
4648 no warnings 'once';
4649 # SVN::Node::none and SVN::Node::file are used only once,
4650 # so we're shutting up Perl's warnings about them.
4651 if ($t == $SVN::Node::none) {
4652 return $self->add_directory($full_path, $baton,
4653 undef, -1, $self->{pool});
4654 } elsif ($t == $SVN::Node::dir) {
4655 return $self->open_directory($full_path, $baton,
4656 $self->{r}, $self->{pool});
4657 } # no warnings 'once'
4658 print STDERR "$full_path already exists in repository at ",
4659 "r$self->{r} and it is not a directory (",
4660 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4661 } # no warnings 'once'
4662 exit 1;
4663 }
4664
4665 sub ensure_path {
4666 my ($self, $path) = @_;
4667 my $bat = $self->{bat};
4668 my $repo_path = $self->repo_path($path);
4669 return $bat->{''} unless (length $repo_path);
4670 my @p = split m#/+#, $repo_path;
4671 my $c = shift @p;
4672 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4673 while (@p) {
4674 my $c0 = $c;
4675 $c .= '/' . shift @p;
4676 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4677 }
4678 return $bat->{$c};
4679 }
4680
4681 # Subroutine to convert a globbing pattern to a regular expression.
4682 # From perl cookbook.
4683 sub glob2pat {
4684 my $globstr = shift;
4685 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4686 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4687 return '^' . $globstr . '$';
4688 }
4689
4690 sub check_autoprop {
4691 my ($self, $pattern, $properties, $file, $fbat) = @_;
4692 # Convert the globbing pattern to a regular expression.
4693 my $regex = glob2pat($pattern);
4694 # Check if the pattern matches the file name.
4695 if($file =~ m/($regex)/) {
4696 # Parse the list of properties to set.
4697 my @props = split(/;/, $properties);
4698 foreach my $prop (@props) {
4699 # Parse 'name=value' syntax and set the property.
4700 if ($prop =~ /([^=]+)=(.*)/) {
4701 my ($n,$v) = ($1,$2);
4702 for ($n, $v) {
4703 s/^\s+//; s/\s+$//;
4704 }
4705 $self->change_file_prop($fbat, $n, $v);
4706 }
4707 }
4708 }
4709 }
4710
4711 sub apply_autoprops {
4712 my ($self, $file, $fbat) = @_;
4713 my $conf_t = ${$self->{config}}{'config'};
4714 no warnings 'once';
4715 # Check [miscellany]/enable-auto-props in svn configuration.
4716 if (SVN::_Core::svn_config_get_bool(
4717 $conf_t,
4718 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4719 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4720 0)) {
4721 # Auto-props are enabled. Enumerate them to look for matches.
4722 my $callback = sub {
4723 $self->check_autoprop($_[0], $_[1], $file, $fbat);
4724 };
4725 SVN::_Core::svn_config_enumerate(
4726 $conf_t,
4727 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4728 $callback);
4729 }
4730 }
4731
4732 sub A {
4733 my ($self, $m) = @_;
4734 my ($dir, $file) = split_path($m->{file_b});
4735 my $pbat = $self->ensure_path($dir);
4736 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4737 undef, -1);
4738 print "\tA\t$m->{file_b}\n" unless $::_q;
4739 $self->apply_autoprops($file, $fbat);
4740 $self->chg_file($fbat, $m);
4741 $self->close_file($fbat,undef,$self->{pool});
4742 }
4743
4744 sub C {
4745 my ($self, $m) = @_;
4746 my ($dir, $file) = split_path($m->{file_b});
4747 my $pbat = $self->ensure_path($dir);
4748 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4749 $self->url_path($m->{file_a}), $self->{r});
4750 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4751 $self->chg_file($fbat, $m);
4752 $self->close_file($fbat,undef,$self->{pool});
4753 }
4754
4755 sub delete_entry {
4756 my ($self, $path, $pbat) = @_;
4757 my $rpath = $self->repo_path($path);
4758 my ($dir, $file) = split_path($rpath);
4759 $self->{rm}->{$dir} = 1;
4760 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4761 }
4762
4763 sub R {
4764 my ($self, $m) = @_;
4765 my ($dir, $file) = split_path($m->{file_b});
4766 my $pbat = $self->ensure_path($dir);
4767 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4768 $self->url_path($m->{file_a}), $self->{r});
4769 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4770 $self->apply_autoprops($file, $fbat);
4771 $self->chg_file($fbat, $m);
4772 $self->close_file($fbat,undef,$self->{pool});
4773
4774 ($dir, $file) = split_path($m->{file_a});
4775 $pbat = $self->ensure_path($dir);
4776 $self->delete_entry($m->{file_a}, $pbat);
4777 }
4778
4779 sub M {
4780 my ($self, $m) = @_;
4781 my ($dir, $file) = split_path($m->{file_b});
4782 my $pbat = $self->ensure_path($dir);
4783 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4784 $pbat,$self->{r},$self->{pool});
4785 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4786 $self->chg_file($fbat, $m);
4787 $self->close_file($fbat,undef,$self->{pool});
4788 }
4789
4790 sub T { shift->M(@_) }
4791
4792 sub change_file_prop {
4793 my ($self, $fbat, $pname, $pval) = @_;
4794 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4795 }
4796
4797 sub change_dir_prop {
4798 my ($self, $pbat, $pname, $pval) = @_;
4799 $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
4800 }
4801
4802 sub _chg_file_get_blob ($$$$) {
4803 my ($self, $fbat, $m, $which) = @_;
4804 my $fh = $::_repository->temp_acquire("git_blob_$which");
4805 if ($m->{"mode_$which"} =~ /^120/) {
4806 print $fh 'link ' or croak $!;
4807 $self->change_file_prop($fbat,'svn:special','*');
4808 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4809 $self->change_file_prop($fbat,'svn:special',undef);
4810 }
4811 my $blob = $m->{"sha1_$which"};
4812 return ($fh,) if ($blob =~ /^0{40}$/);
4813 my $size = $::_repository->cat_blob($blob, $fh);
4814 croak "Failed to read object $blob" if ($size < 0);
4815 $fh->flush == 0 or croak $!;
4816 seek $fh, 0, 0 or croak $!;
4817
4818 my $exp = ::md5sum($fh);
4819 seek $fh, 0, 0 or croak $!;
4820 return ($fh, $exp);
4821 }
4822
4823 sub chg_file {
4824 my ($self, $fbat, $m) = @_;
4825 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4826 $self->change_file_prop($fbat,'svn:executable','*');
4827 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4828 $self->change_file_prop($fbat,'svn:executable',undef);
4829 }
4830 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4831 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4832 my $pool = SVN::Pool->new;
4833 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4834 if (-s $fh_a) {
4835 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4836 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4837 if (defined $res) {
4838 die "Unexpected result from send_txstream: $res\n",
4839 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4840 }
4841 } else {
4842 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4843 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4844 if ($got ne $exp_b);
4845 }
4846 Git::temp_release($fh_b, 1);
4847 Git::temp_release($fh_a, 1);
4848 $pool->clear;
4849 }
4850
4851 sub D {
4852 my ($self, $m) = @_;
4853 my ($dir, $file) = split_path($m->{file_b});
4854 my $pbat = $self->ensure_path($dir);
4855 print "\tD\t$m->{file_b}\n" unless $::_q;
4856 $self->delete_entry($m->{file_b}, $pbat);
4857 }
4858
4859 sub close_edit {
4860 my ($self) = @_;
4861 my ($p,$bat) = ($self->{pool}, $self->{bat});
4862 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4863 next if $_ eq '';
4864 $self->close_directory($bat->{$_}, $p);
4865 }
4866 $self->close_directory($bat->{''}, $p);
4867 $self->SUPER::close_edit($p);
4868 $p->clear;
4869 }
4870
4871 sub abort_edit {
4872 my ($self) = @_;
4873 $self->SUPER::abort_edit($self->{pool});
4874 }
4875
4876 sub DESTROY {
4877 my $self = shift;
4878 $self->SUPER::DESTROY(@_);
4879 $self->{pool}->clear;
4880 }
4881
4882 # this drives the editor
4883 sub apply_diff {
4884 my ($self) = @_;
4885 my $mods = $self->{mods};
4886 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4887 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4888 my $f = $m->{chg};
4889 if (defined $o{$f}) {
4890 $self->$f($m);
4891 } else {
4892 fatal("Invalid change type: $f");
4893 }
4894 }
4895
4896 if (defined($self->{mergeinfo})) {
4897 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
4898 $self->{mergeinfo});
4899 }
4900 $self->rmdirs if $_rmdir;
4901 if (@$mods == 0) {
4902 $self->abort_edit;
4903 } else {
4904 $self->close_edit;
4905 }
4906 return scalar @$mods;
4907 }
4908
4909 package Git::SVN::Ra;
4910 use vars qw/@ISA $config_dir $_log_window_size/;
4911 use strict;
4912 use warnings;
4913 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4914
4915 BEGIN {
4916 # enforce temporary pool usage for some simple functions
4917 no strict 'refs';
4918 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4919 get_file/) {
4920 my $SUPER = "SUPER::$f";
4921 *$f = sub {
4922 my $self = shift;
4923 my $pool = SVN::Pool->new;
4924 my @ret = $self->$SUPER(@_,$pool);
4925 $pool->clear;
4926 wantarray ? @ret : $ret[0];
4927 };
4928 }
4929 }
4930
4931 sub _auth_providers () {
4932 [
4933 SVN::Client::get_simple_provider(),
4934 SVN::Client::get_ssl_server_trust_file_provider(),
4935 SVN::Client::get_simple_prompt_provider(
4936 \&Git::SVN::Prompt::simple, 2),
4937 SVN::Client::get_ssl_client_cert_file_provider(),
4938 SVN::Client::get_ssl_client_cert_prompt_provider(
4939 \&Git::SVN::Prompt::ssl_client_cert, 2),
4940 SVN::Client::get_ssl_client_cert_pw_file_provider(),
4941 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4942 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4943 SVN::Client::get_username_provider(),
4944 SVN::Client::get_ssl_server_trust_prompt_provider(
4945 \&Git::SVN::Prompt::ssl_server_trust),
4946 SVN::Client::get_username_prompt_provider(
4947 \&Git::SVN::Prompt::username, 2)
4948 ]
4949 }
4950
4951 sub escape_uri_only {
4952 my ($uri) = @_;
4953 my @tmp;
4954 foreach (split m{/}, $uri) {
4955 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4956 push @tmp, $_;
4957 }
4958 join('/', @tmp);
4959 }
4960
4961 sub escape_url {
4962 my ($url) = @_;
4963 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4964 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4965 $url = "$scheme://$domain$uri";
4966 }
4967 $url;
4968 }
4969
4970 sub new {
4971 my ($class, $url) = @_;
4972 $url =~ s!/+$!!;
4973 return $RA if ($RA && $RA->{url} eq $url);
4974
4975 ::_req_svn();
4976
4977 SVN::_Core::svn_config_ensure($config_dir, undef);
4978 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4979 my $config = SVN::Core::config_get_config($config_dir);
4980 $RA = undef;
4981 my $dont_store_passwords = 1;
4982 my $conf_t = ${$config}{'config'};
4983 {
4984 no warnings 'once';
4985 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4986 # produces warnings that variables are used only once.
4987 # I had not found the better way to shut them up, so
4988 # the warnings of type 'once' are disabled in this block.
4989 if (SVN::_Core::svn_config_get_bool($conf_t,
4990 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4991 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4992 1) == 0) {
4993 SVN::_Core::svn_auth_set_parameter($baton,
4994 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4995 bless (\$dont_store_passwords, "_p_void"));
4996 }
4997 if (SVN::_Core::svn_config_get_bool($conf_t,
4998 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4999 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
5000 1) == 0) {
5001 $Git::SVN::Prompt::_no_auth_cache = 1;
5002 }
5003 } # no warnings 'once'
5004 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
5005 config => $config,
5006 pool => SVN::Pool->new,
5007 auth_provider_callbacks => $callbacks);
5008 $self->{url} = $url;
5009 $self->{svn_path} = $url;
5010 $self->{repos_root} = $self->get_repos_root;
5011 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
5012 $self->{cache} = { check_path => { r => 0, data => {} },
5013 get_dir => { r => 0, data => {} } };
5014 $RA = bless $self, $class;
5015 }
5016
5017 sub check_path {
5018 my ($self, $path, $r) = @_;
5019 my $cache = $self->{cache}->{check_path};
5020 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
5021 return $cache->{data}->{$path};
5022 }
5023 my $pool = SVN::Pool->new;
5024 my $t = $self->SUPER::check_path($path, $r, $pool);
5025 $pool->clear;
5026 if ($r != $cache->{r}) {
5027 %{$cache->{data}} = ();
5028 $cache->{r} = $r;
5029 }
5030 $cache->{data}->{$path} = $t;
5031 }
5032
5033 sub get_dir {
5034 my ($self, $dir, $r) = @_;
5035 my $cache = $self->{cache}->{get_dir};
5036 if ($r == $cache->{r}) {
5037 if (my $x = $cache->{data}->{$dir}) {
5038 return wantarray ? @$x : $x->[0];
5039 }
5040 }
5041 my $pool = SVN::Pool->new;
5042 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
5043 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
5044 $pool->clear;
5045 if ($r != $cache->{r}) {
5046 %{$cache->{data}} = ();
5047 $cache->{r} = $r;
5048 }
5049 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5050 wantarray ? (\%dirents, $r, $props) : \%dirents;
5051 }
5052
5053 sub DESTROY {
5054 # do not call the real DESTROY since we store ourselves in $RA
5055 }
5056
5057 # get_log(paths, start, end, limit,
5058 # discover_changed_paths, strict_node_history, receiver)
5059 sub get_log {
5060 my ($self, @args) = @_;
5061 my $pool = SVN::Pool->new;
5062
5063 # svn_log_changed_path_t objects passed to get_log are likely to be
5064 # overwritten even if only the refs are copied to an external variable,
5065 # so we should dup the structures in their entirety. Using an
5066 # externally passed pool (instead of our temporary and quickly cleared
5067 # pool in Git::SVN::Ra) does not help matters at all...
5068 my $receiver = pop @args;
5069 my $prefix = "/".$self->{svn_path};
5070 $prefix =~ s#/+($)##;
5071 my $prefix_regex = qr#^\Q$prefix\E#;
5072 push(@args, sub {
5073 my ($paths) = $_[0];
5074 return &$receiver(@_) unless $paths;
5075 $_[0] = ();
5076 foreach my $p (keys %$paths) {
5077 my $i = $paths->{$p};
5078 # Make path relative to our url, not repos_root
5079 $p =~ s/$prefix_regex//;
5080 my %s = map { $_ => $i->$_; }
5081 qw/copyfrom_path copyfrom_rev action/;
5082 if ($s{'copyfrom_path'}) {
5083 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5084 }
5085 $_[0]{$p} = \%s;
5086 }
5087 &$receiver(@_);
5088 });
5089
5090
5091 # the limit parameter was not supported in SVN 1.1.x, so we
5092 # drop it. Therefore, the receiver callback passed to it
5093 # is made aware of this limitation by being wrapped if
5094 # the limit passed to is being wrapped.
5095 if ($SVN::Core::VERSION le '1.2.0') {
5096 my $limit = splice(@args, 3, 1);
5097 if ($limit > 0) {
5098 my $receiver = pop @args;
5099 push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5100 }
5101 }
5102 my $ret = $self->SUPER::get_log(@args, $pool);
5103 $pool->clear;
5104 $ret;
5105 }
5106
5107 sub trees_match {
5108 my ($self, $url1, $rev1, $url2, $rev2) = @_;
5109 my $ctx = SVN::Client->new(auth => _auth_providers);
5110 my $out = IO::File->new_tmpfile;
5111
5112 # older SVN (1.1.x) doesn't take $pool as the last parameter for
5113 # $ctx->diff(), so we'll create a default one
5114 my $pool = SVN::Pool->new_default_sub;
5115
5116 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5117 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5118 $out->flush;
5119 my $ret = (($out->stat)[7] == 0);
5120 close $out or croak $!;
5121
5122 $ret;
5123 }
5124
5125 sub get_commit_editor {
5126 my ($self, $log, $cb, $pool) = @_;
5127 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5128 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5129 }
5130
5131 sub gs_do_update {
5132 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5133 my $new = ($rev_a == $rev_b);
5134 my $path = $gs->{path};
5135
5136 if ($new && -e $gs->{index}) {
5137 unlink $gs->{index} or die
5138 "Couldn't unlink index: $gs->{index}: $!\n";
5139 }
5140 my $pool = SVN::Pool->new;
5141 $editor->set_path_strip($path);
5142 my (@pc) = split m#/#, $path;
5143 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5144 1, $editor, $pool);
5145 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5146
5147 # Since we can't rely on svn_ra_reparent being available, we'll
5148 # just have to do some magic with set_path to make it so
5149 # we only want a partial path.
5150 my $sp = '';
5151 my $final = join('/', @pc);
5152 while (@pc) {
5153 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5154 $sp .= '/' if length $sp;
5155 $sp .= shift @pc;
5156 }
5157 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5158
5159 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5160
5161 $reporter->finish_report($pool);
5162 $pool->clear;
5163 $editor->{git_commit_ok};
5164 }
5165
5166 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5167 # svn_ra_reparent didn't work before 1.4)
5168 sub gs_do_switch {
5169 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5170 my $path = $gs->{path};
5171 my $pool = SVN::Pool->new;
5172
5173 my $full_url = $self->{url};
5174 my $old_url = $full_url;
5175 $full_url .= '/' . $path if length $path;
5176 my ($ra, $reparented);
5177
5178 if ($old_url =~ m#^svn(\+ssh)?://# ||
5179 ($full_url =~ m#^https?://# &&
5180 escape_url($full_url) ne $full_url)) {
5181 $_[0] = undef;
5182 $self = undef;
5183 $RA = undef;
5184 $ra = Git::SVN::Ra->new($full_url);
5185 $ra_invalid = 1;
5186 } elsif ($old_url ne $full_url) {
5187 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5188 $self->{url} = $full_url;
5189 $reparented = 1;
5190 }
5191
5192 $ra ||= $self;
5193 $url_b = escape_url($url_b);
5194 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5195 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5196 $reporter->set_path('', $rev_a, 0, @lock, $pool);
5197 $reporter->finish_report($pool);
5198
5199 if ($reparented) {
5200 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5201 $self->{url} = $old_url;
5202 }
5203
5204 $pool->clear;
5205 $editor->{git_commit_ok};
5206 }
5207
5208 sub longest_common_path {
5209 my ($gsv, $globs) = @_;
5210 my %common;
5211 my $common_max = scalar @$gsv;
5212
5213 foreach my $gs (@$gsv) {
5214 my @tmp = split m#/#, $gs->{path};
5215 my $p = '';
5216 foreach (@tmp) {
5217 $p .= length($p) ? "/$_" : $_;
5218 $common{$p} ||= 0;
5219 $common{$p}++;
5220 }
5221 }
5222 $globs ||= [];
5223 $common_max += scalar @$globs;
5224 foreach my $glob (@$globs) {
5225 my @tmp = split m#/#, $glob->{path}->{left};
5226 my $p = '';
5227 foreach (@tmp) {
5228 $p .= length($p) ? "/$_" : $_;
5229 $common{$p} ||= 0;
5230 $common{$p}++;
5231 }
5232 }
5233
5234 my $longest_path = '';
5235 foreach (sort {length $b <=> length $a} keys %common) {
5236 if ($common{$_} == $common_max) {
5237 $longest_path = $_;
5238 last;
5239 }
5240 }
5241 $longest_path;
5242 }
5243
5244 sub gs_fetch_loop_common {
5245 my ($self, $base, $head, $gsv, $globs) = @_;
5246 return if ($base > $head);
5247 my $inc = $_log_window_size;
5248 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5249 my $longest_path = longest_common_path($gsv, $globs);
5250 my $ra_url = $self->{url};
5251 my $find_trailing_edge;
5252 while (1) {
5253 my %revs;
5254 my $err;
5255 my $err_handler = $SVN::Error::handler;
5256 $SVN::Error::handler = sub {
5257 ($err) = @_;
5258 skip_unknown_revs($err);
5259 };
5260 sub _cb {
5261 my ($paths, $r, $author, $date, $log) = @_;
5262 [ $paths,
5263 { author => $author, date => $date, log => $log } ];
5264 }
5265 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5266 sub { $revs{$_[1]} = _cb(@_) });
5267 if ($err) {
5268 print "Checked through r$max\r";
5269 } else {
5270 $find_trailing_edge = 1;
5271 }
5272 if ($err and $find_trailing_edge) {
5273 print STDERR "Path '$longest_path' ",
5274 "was probably deleted:\n",
5275 $err->expanded_message,
5276 "\nWill attempt to follow ",
5277 "revisions r$min .. r$max ",
5278 "committed before the deletion\n";
5279 my $hi = $max;
5280 while (--$hi >= $min) {
5281 my $ok;
5282 $self->get_log([$longest_path], $min, $hi,
5283 0, 1, 1, sub {
5284 $ok = $_[1];
5285 $revs{$_[1]} = _cb(@_) });
5286 if ($ok) {
5287 print STDERR "r$min .. r$ok OK\n";
5288 last;
5289 }
5290 }
5291 $find_trailing_edge = 0;
5292 }
5293 $SVN::Error::handler = $err_handler;
5294
5295 my %exists = map { $_->{path} => $_ } @$gsv;
5296 foreach my $r (sort {$a <=> $b} keys %revs) {
5297 my ($paths, $logged) = @{$revs{$r}};
5298
5299 foreach my $gs ($self->match_globs(\%exists, $paths,
5300 $globs, $r)) {
5301 if ($gs->rev_map_max >= $r) {
5302 next;
5303 }
5304 next unless $gs->match_paths($paths, $r);
5305 $gs->{logged_rev_props} = $logged;
5306 if (my $last_commit = $gs->last_commit) {
5307 $gs->assert_index_clean($last_commit);
5308 }
5309 my $log_entry = $gs->do_fetch($paths, $r);
5310 if ($log_entry) {
5311 $gs->do_git_commit($log_entry);
5312 }
5313 $INDEX_FILES{$gs->{index}} = 1;
5314 }
5315 foreach my $g (@$globs) {
5316 my $k = "svn-remote.$g->{remote}." .
5317 "$g->{t}-maxRev";
5318 Git::SVN::tmp_config($k, $r);
5319 }
5320 if ($ra_invalid) {
5321 $_[0] = undef;
5322 $self = undef;
5323 $RA = undef;
5324 $self = Git::SVN::Ra->new($ra_url);
5325 $ra_invalid = undef;
5326 }
5327 }
5328 # pre-fill the .rev_db since it'll eventually get filled in
5329 # with '0' x40 if something new gets committed
5330 foreach my $gs (@$gsv) {
5331 next if $gs->rev_map_max >= $max;
5332 next if defined $gs->rev_map_get($max);
5333 $gs->rev_map_set($max, 0 x40);
5334 }
5335 foreach my $g (@$globs) {
5336 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5337 Git::SVN::tmp_config($k, $max);
5338 }
5339 last if $max >= $head;
5340 $min = $max + 1;
5341 $max += $inc;
5342 $max = $head if ($max > $head);
5343 }
5344 Git::SVN::gc();
5345 }
5346
5347 sub get_dir_globbed {
5348 my ($self, $left, $depth, $r) = @_;
5349
5350 my @x = eval { $self->get_dir($left, $r) };
5351 return unless scalar @x == 3;
5352 my $dirents = $x[0];
5353 my @finalents;
5354 foreach my $de (keys %$dirents) {
5355 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5356 if ($depth > 1) {
5357 my @args = ("$left/$de", $depth - 1, $r);
5358 foreach my $dir ($self->get_dir_globbed(@args)) {
5359 push @finalents, "$de/$dir";
5360 }
5361 } else {
5362 push @finalents, $de;
5363 }
5364 }
5365 @finalents;
5366 }
5367
5368 sub match_globs {
5369 my ($self, $exists, $paths, $globs, $r) = @_;
5370
5371 sub get_dir_check {
5372 my ($self, $exists, $g, $r) = @_;
5373
5374 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5375 $g->{path}->{depth},
5376 $r);
5377
5378 foreach my $de (@dirs) {
5379 my $p = $g->{path}->full_path($de);
5380 next if $exists->{$p};
5381 next if (length $g->{path}->{right} &&
5382 ($self->check_path($p, $r) !=
5383 $SVN::Node::dir));
5384 next unless $p =~ /$g->{path}->{regex}/;
5385 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5386 $g->{ref}->full_path($de), 1);
5387 }
5388 }
5389 foreach my $g (@$globs) {
5390 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5391 if ($path->{action} =~ /^[AR]$/) {
5392 get_dir_check($self, $exists, $g, $r);
5393 }
5394 }
5395 foreach (keys %$paths) {
5396 if (/$g->{path}->{left_regex}/ &&
5397 !/$g->{path}->{regex}/) {
5398 next if $paths->{$_}->{action} !~ /^[AR]$/;
5399 get_dir_check($self, $exists, $g, $r);
5400 }
5401 next unless /$g->{path}->{regex}/;
5402 my $p = $1;
5403 my $pathname = $g->{path}->full_path($p);
5404 next if $exists->{$pathname};
5405 next if ($self->check_path($pathname, $r) !=
5406 $SVN::Node::dir);
5407 $exists->{$pathname} = Git::SVN->init(
5408 $self->{url}, $pathname, undef,
5409 $g->{ref}->full_path($p), 1);
5410 }
5411 my $c = '';
5412 foreach (split m#/#, $g->{path}->{left}) {
5413 $c .= "/$_";
5414 next unless ($paths->{$c} &&
5415 ($paths->{$c}->{action} =~ /^[AR]$/));
5416 get_dir_check($self, $exists, $g, $r);
5417 }
5418 }
5419 values %$exists;
5420 }
5421
5422 sub minimize_url {
5423 my ($self) = @_;
5424 return $self->{url} if ($self->{url} eq $self->{repos_root});
5425 my $url = $self->{repos_root};
5426 my @components = split(m!/!, $self->{svn_path});
5427 my $c = '';
5428 do {
5429 $url .= "/$c" if length $c;
5430 eval {
5431 my $ra = (ref $self)->new($url);
5432 my $latest = $ra->get_latest_revnum;
5433 $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5434 };
5435 } while ($@ && ($c = shift @components));
5436 $url;
5437 }
5438
5439 sub can_do_switch {
5440 my $self = shift;
5441 unless (defined $can_do_switch) {
5442 my $pool = SVN::Pool->new;
5443 my $rep = eval {
5444 $self->do_switch(1, '', 0, $self->{url},
5445 SVN::Delta::Editor->new, $pool);
5446 };
5447 if ($@) {
5448 $can_do_switch = 0;
5449 } else {
5450 $rep->abort_report($pool);
5451 $can_do_switch = 1;
5452 }
5453 $pool->clear;
5454 }
5455 $can_do_switch;
5456 }
5457
5458 sub skip_unknown_revs {
5459 my ($err) = @_;
5460 my $errno = $err->apr_err();
5461 # Maybe the branch we're tracking didn't
5462 # exist when the repo started, so it's
5463 # not an error if it doesn't, just continue
5464 #
5465 # Wonderfully consistent library, eh?
5466 # 160013 - svn:// and file://
5467 # 175002 - http(s)://
5468 # 175007 - http(s):// (this repo required authorization, too...)
5469 # More codes may be discovered later...
5470 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5471 my $err_key = $err->expanded_message;
5472 # revision numbers change every time, filter them out
5473 $err_key =~ s/\d+/\0/g;
5474 $err_key = "$errno\0$err_key";
5475 unless ($ignored_err{$err_key}) {
5476 warn "W: Ignoring error from SVN, path probably ",
5477 "does not exist: ($errno): ",
5478 $err->expanded_message,"\n";
5479 warn "W: Do not be alarmed at the above message ",
5480 "git-svn is just searching aggressively for ",
5481 "old history.\n",
5482 "This may take a while on large repositories\n";
5483 $ignored_err{$err_key} = 1;
5484 }
5485 return;
5486 }
5487 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5488 }
5489
5490 package Git::SVN::Log;
5491 use strict;
5492 use warnings;
5493 use POSIX qw/strftime/;
5494 use Time::Local;
5495 use constant commit_log_separator => ('-' x 72) . "\n";
5496 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5497 %rusers $show_commit $incremental/;
5498 my $l_fmt;
5499
5500 sub cmt_showable {
5501 my ($c) = @_;
5502 return 1 if defined $c->{r};
5503
5504 # big commit message got truncated by the 16k pretty buffer in rev-list
5505 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5506 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5507 @{$c->{l}} = ();
5508 my @log = command(qw/cat-file commit/, $c->{c});
5509
5510 # shift off the headers
5511 shift @log while ($log[0] ne '');
5512 shift @log;
5513
5514 # TODO: make $c->{l} not have a trailing newline in the future
5515 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5516
5517 (undef, $c->{r}, undef) = ::extract_metadata(
5518 (grep(/^git-svn-id: /, @log))[-1]);
5519 }
5520 return defined $c->{r};
5521 }
5522
5523 sub log_use_color {
5524 return $color || Git->repository->get_colorbool('color.diff');
5525 }
5526
5527 sub git_svn_log_cmd {
5528 my ($r_min, $r_max, @args) = @_;
5529 my $head = 'HEAD';
5530 my (@files, @log_opts);
5531 foreach my $x (@args) {
5532 if ($x eq '--' || @files) {
5533 push @files, $x;
5534 } else {
5535 if (::verify_ref("$x^0")) {
5536 $head = $x;
5537 } else {
5538 push @log_opts, $x;
5539 }
5540 }
5541 }
5542
5543 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5544 $gs ||= Git::SVN->_new;
5545 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5546 $gs->refname);
5547 push @cmd, '-r' unless $non_recursive;
5548 push @cmd, qw/--raw --name-status/ if $verbose;
5549 push @cmd, '--color' if log_use_color();
5550 push @cmd, @log_opts;
5551 if (defined $r_max && $r_max == $r_min) {
5552 push @cmd, '--max-count=1';
5553 if (my $c = $gs->rev_map_get($r_max)) {
5554 push @cmd, $c;
5555 }
5556 } elsif (defined $r_max) {
5557 if ($r_max < $r_min) {
5558 ($r_min, $r_max) = ($r_max, $r_min);
5559 }
5560 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5561 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5562 # If there are no commits in the range, both $c_max and $c_min
5563 # will be undefined. If there is at least 1 commit in the
5564 # range, both will be defined.
5565 return () if !defined $c_min || !defined $c_max;
5566 if ($c_min eq $c_max) {
5567 push @cmd, '--max-count=1', $c_min;
5568 } else {
5569 push @cmd, '--boundary', "$c_min..$c_max";
5570 }
5571 }
5572 return (@cmd, @files);
5573 }
5574
5575 # adapted from pager.c
5576 sub config_pager {
5577 if (! -t *STDOUT) {
5578 $ENV{GIT_PAGER_IN_USE} = 'false';
5579 $pager = undef;
5580 return;
5581 }
5582 chomp($pager = command_oneline(qw(var GIT_PAGER)));
5583 if ($pager eq 'cat') {
5584 $pager = undef;
5585 }
5586 $ENV{GIT_PAGER_IN_USE} = defined($pager);
5587 }
5588
5589 sub run_pager {
5590 return unless defined $pager;
5591 pipe my ($rfd, $wfd) or return;
5592 defined(my $pid = fork) or ::fatal "Can't fork: $!";
5593 if (!$pid) {
5594 open STDOUT, '>&', $wfd or
5595 ::fatal "Can't redirect to stdout: $!";
5596 return;
5597 }
5598 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5599 $ENV{LESS} ||= 'FRSX';
5600 exec $pager or ::fatal "Can't run pager: $! ($pager)";
5601 }
5602
5603 sub format_svn_date {
5604 # some systmes don't handle or mishandle %z, so be creative.
5605 my $t = shift || time;
5606 my $gm = timelocal(gmtime($t));
5607 my $sign = qw( + + - )[ $t <=> $gm ];
5608 my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5609 return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5610 }
5611
5612 sub parse_git_date {
5613 my ($t, $tz) = @_;
5614 # Date::Parse isn't in the standard Perl distro :(
5615 if ($tz =~ s/^\+//) {
5616 $t += tz_to_s_offset($tz);
5617 } elsif ($tz =~ s/^\-//) {
5618 $t -= tz_to_s_offset($tz);
5619 }
5620 return $t;
5621 }
5622
5623 sub set_local_timezone {
5624 if (defined $TZ) {
5625 $ENV{TZ} = $TZ;
5626 } else {
5627 delete $ENV{TZ};
5628 }
5629 }
5630
5631 sub tz_to_s_offset {
5632 my ($tz) = @_;
5633 $tz =~ s/(\d\d)$//;
5634 return ($1 * 60) + ($tz * 3600);
5635 }
5636
5637 sub get_author_info {
5638 my ($dest, $author, $t, $tz) = @_;
5639 $author =~ s/(?:^\s*|\s*$)//g;
5640 $dest->{a_raw} = $author;
5641 my $au;
5642 if ($::_authors) {
5643 $au = $rusers{$author} || undef;
5644 }
5645 if (!$au) {
5646 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5647 }
5648 $dest->{t} = $t;
5649 $dest->{tz} = $tz;
5650 $dest->{a} = $au;
5651 $dest->{t_utc} = parse_git_date($t, $tz);
5652 }
5653
5654 sub process_commit {
5655 my ($c, $r_min, $r_max, $defer) = @_;
5656 if (defined $r_min && defined $r_max) {
5657 if ($r_min == $c->{r} && $r_min == $r_max) {
5658 show_commit($c);
5659 return 0;
5660 }
5661 return 1 if $r_min == $r_max;
5662 if ($r_min < $r_max) {
5663 # we need to reverse the print order
5664 return 0 if (defined $limit && --$limit < 0);
5665 push @$defer, $c;
5666 return 1;
5667 }
5668 if ($r_min != $r_max) {
5669 return 1 if ($r_min < $c->{r});
5670 return 1 if ($r_max > $c->{r});
5671 }
5672 }
5673 return 0 if (defined $limit && --$limit < 0);
5674 show_commit($c);
5675 return 1;
5676 }
5677
5678 sub show_commit {
5679 my $c = shift;
5680 if ($oneline) {
5681 my $x = "\n";
5682 if (my $l = $c->{l}) {
5683 while ($l->[0] =~ /^\s*$/) { shift @$l }
5684 $x = $l->[0];
5685 }
5686 $l_fmt ||= 'A' . length($c->{r});
5687 print 'r',pack($l_fmt, $c->{r}),' | ';
5688 print "$c->{c} | " if $show_commit;
5689 print $x;
5690 } else {
5691 show_commit_normal($c);
5692 }
5693 }
5694
5695 sub show_commit_changed_paths {
5696 my ($c) = @_;
5697 return unless $c->{changed};
5698 print "Changed paths:\n", @{$c->{changed}};
5699 }
5700
5701 sub show_commit_normal {
5702 my ($c) = @_;
5703 print commit_log_separator, "r$c->{r} | ";
5704 print "$c->{c} | " if $show_commit;
5705 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5706 my $nr_line = 0;
5707
5708 if (my $l = $c->{l}) {
5709 while ($l->[$#$l] eq "\n" && $#$l > 0
5710 && $l->[($#$l - 1)] eq "\n") {
5711 pop @$l;
5712 }
5713 $nr_line = scalar @$l;
5714 if (!$nr_line) {
5715 print "1 line\n\n\n";
5716 } else {
5717 if ($nr_line == 1) {
5718 $nr_line = '1 line';
5719 } else {
5720 $nr_line .= ' lines';
5721 }
5722 print $nr_line, "\n";
5723 show_commit_changed_paths($c);
5724 print "\n";
5725 print $_ foreach @$l;
5726 }
5727 } else {
5728 print "1 line\n";
5729 show_commit_changed_paths($c);
5730 print "\n";
5731
5732 }
5733 foreach my $x (qw/raw stat diff/) {
5734 if ($c->{$x}) {
5735 print "\n";
5736 print $_ foreach @{$c->{$x}}
5737 }
5738 }
5739 }
5740
5741 sub cmd_show_log {
5742 my (@args) = @_;
5743 my ($r_min, $r_max);
5744 my $r_last = -1; # prevent dupes
5745 set_local_timezone();
5746 if (defined $::_revision) {
5747 if ($::_revision =~ /^(\d+):(\d+)$/) {
5748 ($r_min, $r_max) = ($1, $2);
5749 } elsif ($::_revision =~ /^\d+$/) {
5750 $r_min = $r_max = $::_revision;
5751 } else {
5752 ::fatal "-r$::_revision is not supported, use ",
5753 "standard 'git log' arguments instead";
5754 }
5755 }
5756
5757 config_pager();
5758 @args = git_svn_log_cmd($r_min, $r_max, @args);
5759 if (!@args) {
5760 print commit_log_separator unless $incremental || $oneline;
5761 return;
5762 }
5763 my $log = command_output_pipe(@args);
5764 run_pager();
5765 my (@k, $c, $d, $stat);
5766 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5767 while (<$log>) {
5768 if (/^${esc_color}commit (?:- )?($::sha1_short)/o) {
5769 my $cmt = $1;
5770 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5771 $r_last = $c->{r};
5772 process_commit($c, $r_min, $r_max, \@k) or
5773 goto out;
5774 }
5775 $d = undef;
5776 $c = { c => $cmt };
5777 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5778 get_author_info($c, $1, $2, $3);
5779 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5780 # ignore
5781 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5782 push @{$c->{raw}}, $_;
5783 } elsif (/^${esc_color}[ACRMDT]\t/) {
5784 # we could add $SVN->{svn_path} here, but that requires
5785 # remote access at the moment (repo_path_split)...
5786 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
5787 push @{$c->{changed}}, $_;
5788 } elsif (/^${esc_color}diff /o) {
5789 $d = 1;
5790 push @{$c->{diff}}, $_;
5791 } elsif ($d) {
5792 push @{$c->{diff}}, $_;
5793 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5794 $esc_color*[\+\-]*$esc_color$/x) {
5795 $stat = 1;
5796 push @{$c->{stat}}, $_;
5797 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5798 push @{$c->{stat}}, $_;
5799 $stat = undef;
5800 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
5801 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5802 } elsif (s/^${esc_color} //o) {
5803 push @{$c->{l}}, $_;
5804 }
5805 }
5806 if ($c && defined $c->{r} && $c->{r} != $r_last) {
5807 $r_last = $c->{r};
5808 process_commit($c, $r_min, $r_max, \@k);
5809 }
5810 if (@k) {
5811 ($r_min, $r_max) = ($r_max, $r_min);
5812 process_commit($_, $r_min, $r_max) foreach reverse @k;
5813 }
5814 out:
5815 close $log;
5816 print commit_log_separator unless $incremental || $oneline;
5817 }
5818
5819 sub cmd_blame {
5820 my $path = pop;
5821
5822 config_pager();
5823 run_pager();
5824
5825 my ($fh, $ctx, $rev);
5826
5827 if ($_git_format) {
5828 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5829 while (my $line = <$fh>) {
5830 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5831 # Uncommitted edits show up as a rev ID of
5832 # all zeros, which we can't look up with
5833 # cmt_metadata
5834 if ($1 !~ /^0+$/) {
5835 (undef, $rev, undef) =
5836 ::cmt_metadata($1);
5837 $rev = '0' if (!$rev);
5838 } else {
5839 $rev = '0';
5840 }
5841 $rev = sprintf('%-10s', $rev);
5842 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5843 }
5844 print $line;
5845 }
5846 } else {
5847 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5848 '--', $path);
5849 my ($sha1);
5850 my %authors;
5851 my @buffer;
5852 my %dsha; #distinct sha keys
5853
5854 while (my $line = <$fh>) {
5855 push @buffer, $line;
5856 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5857 $dsha{$1} = 1;
5858 }
5859 }
5860
5861 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5862
5863 foreach my $line (@buffer) {
5864 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5865 $rev = $s2r->{$1};
5866 $rev = '0' if (!$rev)
5867 }
5868 elsif ($line =~ /^author (.*)/) {
5869 $authors{$rev} = $1;
5870 $authors{$rev} =~ s/\s/_/g;
5871 }
5872 elsif ($line =~ /^\t(.*)$/) {
5873 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5874 }
5875 }
5876 }
5877 command_close_pipe($fh, $ctx);
5878 }
5879
5880 package Git::SVN::Migration;
5881 # these version numbers do NOT correspond to actual version numbers
5882 # of git nor git-svn. They are just relative.
5883 #
5884 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5885 #
5886 # v1 layout: .git/$id/info/url, refs/remotes/$id
5887 #
5888 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5889 #
5890 # v3 layout: .git/svn/$id, refs/remotes/$id
5891 # - info/url may remain for backwards compatibility
5892 # - this is what we migrate up to this layout automatically,
5893 # - this will be used by git svn init on single branches
5894 # v3.1 layout (auto migrated):
5895 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5896 # for backwards compatibility
5897 #
5898 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5899 # - this is only created for newly multi-init-ed
5900 # repositories. Similar in spirit to the
5901 # --use-separate-remotes option in git-clone (now default)
5902 # - we do not automatically migrate to this (following
5903 # the example set by core git)
5904 #
5905 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5906 # - newer, more-efficient format that uses 24-bytes per record
5907 # with no filler space.
5908 # - use xxd -c24 < .rev_map.$UUID to view and debug
5909 # - This is a one-way migration, repositories updated to the
5910 # new format will not be able to use old git-svn without
5911 # rebuilding the .rev_db. Rebuilding the rev_db is not
5912 # possible if noMetadata or useSvmProps are set; but should
5913 # be no problem for users that use the (sensible) defaults.
5914 use strict;
5915 use warnings;
5916 use Carp qw/croak/;
5917 use File::Path qw/mkpath/;
5918 use File::Basename qw/dirname basename/;
5919 use vars qw/$_minimize/;
5920
5921 sub migrate_from_v0 {
5922 my $git_dir = $ENV{GIT_DIR};
5923 return undef unless -d $git_dir;
5924 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5925 my $migrated = 0;
5926 while (<$fh>) {
5927 chomp;
5928 my ($id, $orig_ref) = ($_, $_);
5929 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5930 next unless -f "$git_dir/$id/info/url";
5931 my $new_ref = "refs/remotes/$id";
5932 if (::verify_ref("$new_ref^0")) {
5933 print STDERR "W: $orig_ref is probably an old ",
5934 "branch used by an ancient version of ",
5935 "git-svn.\n",
5936 "However, $new_ref also exists.\n",
5937 "We will not be able ",
5938 "to use this branch until this ",
5939 "ambiguity is resolved.\n";
5940 next;
5941 }
5942 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5943 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5944 command_noisy('update-ref', $new_ref, $orig_ref);
5945 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5946 $migrated++;
5947 }
5948 command_close_pipe($fh, $ctx);
5949 print STDERR "Done migrating from v0 layout...\n" if $migrated;
5950 $migrated;
5951 }
5952
5953 sub migrate_from_v1 {
5954 my $git_dir = $ENV{GIT_DIR};
5955 my $migrated = 0;
5956 return $migrated unless -d $git_dir;
5957 my $svn_dir = "$git_dir/svn";
5958
5959 # just in case somebody used 'svn' as their $id at some point...
5960 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5961
5962 print STDERR "Migrating from a git-svn v1 layout...\n";
5963 mkpath([$svn_dir]);
5964 print STDERR "Data from a previous version of git-svn exists, but\n\t",
5965 "$svn_dir\n\t(required for this version ",
5966 "($::VERSION) of git-svn) does not exist.\n";
5967 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5968 while (<$fh>) {
5969 my $x = $_;
5970 next unless $x =~ s#^refs/remotes/##;
5971 chomp $x;
5972 next unless -f "$git_dir/$x/info/url";
5973 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5974 next unless $u;
5975 my $dn = dirname("$git_dir/svn/$x");
5976 mkpath([$dn]) unless -d $dn;
5977 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5978 mkpath(["$git_dir/svn/svn"]);
5979 print STDERR " - $git_dir/$x/info => ",
5980 "$git_dir/svn/$x/info\n";
5981 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5982 croak "$!: $x";
5983 # don't worry too much about these, they probably
5984 # don't exist with repos this old (save for index,
5985 # and we can easily regenerate that)
5986 foreach my $f (qw/unhandled.log index .rev_db/) {
5987 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5988 }
5989 } else {
5990 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5991 rename "$git_dir/$x", "$git_dir/svn/$x" or
5992 croak "$!: $x";
5993 }
5994 $migrated++;
5995 }
5996 command_close_pipe($fh, $ctx);
5997 print STDERR "Done migrating from a git-svn v1 layout\n";
5998 $migrated;
5999 }
6000
6001 sub read_old_urls {
6002 my ($l_map, $pfx, $path) = @_;
6003 my @dir;
6004 foreach (<$path/*>) {
6005 if (-r "$_/info/url") {
6006 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
6007 my $ref_id = $pfx . basename $_;
6008 my $url = ::file_to_s("$_/info/url");
6009 $l_map->{$ref_id} = $url;
6010 } elsif (-d $_) {
6011 push @dir, $_;
6012 }
6013 }
6014 foreach (@dir) {
6015 my $x = $_;
6016 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
6017 read_old_urls($l_map, $x, $_);
6018 }
6019 }
6020
6021 sub migrate_from_v2 {
6022 my @cfg = command(qw/config -l/);
6023 return if grep /^svn-remote\..+\.url=/, @cfg;
6024 my %l_map;
6025 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
6026 my $migrated = 0;
6027
6028 foreach my $ref_id (sort keys %l_map) {
6029 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
6030 if ($@) {
6031 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
6032 }
6033 $migrated++;
6034 }
6035 $migrated;
6036 }
6037
6038 sub minimize_connections {
6039 my $r = Git::SVN::read_all_remotes();
6040 my $new_urls = {};
6041 my $root_repos = {};
6042 foreach my $repo_id (keys %$r) {
6043 my $url = $r->{$repo_id}->{url} or next;
6044 my $fetch = $r->{$repo_id}->{fetch} or next;
6045 my $ra = Git::SVN::Ra->new($url);
6046
6047 # skip existing cases where we already connect to the root
6048 if (($ra->{url} eq $ra->{repos_root}) ||
6049 ($ra->{repos_root} eq $repo_id)) {
6050 $root_repos->{$ra->{url}} = $repo_id;
6051 next;
6052 }
6053
6054 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6055 my $root_path = $ra->{url};
6056 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6057 foreach my $path (keys %$fetch) {
6058 my $ref_id = $fetch->{$path};
6059 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6060
6061 # make sure we can read when connecting to
6062 # a higher level of a repository
6063 my ($last_rev, undef) = $gs->last_rev_commit;
6064 if (!defined $last_rev) {
6065 $last_rev = eval {
6066 $root_ra->get_latest_revnum;
6067 };
6068 next if $@;
6069 }
6070 my $new = $root_path;
6071 $new .= length $path ? "/$path" : '';
6072 eval {
6073 $root_ra->get_log([$new], $last_rev, $last_rev,
6074 0, 0, 1, sub { });
6075 };
6076 next if $@;
6077 $new_urls->{$ra->{repos_root}}->{$new} =
6078 { ref_id => $ref_id,
6079 old_repo_id => $repo_id,
6080 old_path => $path };
6081 }
6082 }
6083
6084 my @emptied;
6085 foreach my $url (keys %$new_urls) {
6086 # see if we can re-use an existing [svn-remote "repo_id"]
6087 # instead of creating a(n ugly) new section:
6088 my $repo_id = $root_repos->{$url} || $url;
6089
6090 my $fetch = $new_urls->{$url};
6091 foreach my $path (keys %$fetch) {
6092 my $x = $fetch->{$path};
6093 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6094 my $pfx = "svn-remote.$x->{old_repo_id}";
6095
6096 my $old_fetch = quotemeta("$x->{old_path}:".
6097 "$x->{ref_id}");
6098 command_noisy(qw/config --unset/,
6099 "$pfx.fetch", '^'. $old_fetch . '$');
6100 delete $r->{$x->{old_repo_id}}->
6101 {fetch}->{$x->{old_path}};
6102 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6103 command_noisy(qw/config --unset/,
6104 "$pfx.url");
6105 push @emptied, $x->{old_repo_id}
6106 }
6107 }
6108 }
6109 if (@emptied) {
6110 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6111 print STDERR <<EOF;
6112 The following [svn-remote] sections in your config file ($file) are empty
6113 and can be safely removed:
6114 EOF
6115 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6116 }
6117 }
6118
6119 sub migration_check {
6120 migrate_from_v0();
6121 migrate_from_v1();
6122 migrate_from_v2();
6123 minimize_connections() if $_minimize;
6124 }
6125
6126 package Git::IndexInfo;
6127 use strict;
6128 use warnings;
6129 use Git qw/command_input_pipe command_close_pipe/;
6130
6131 sub new {
6132 my ($class) = @_;
6133 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6134 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6135 }
6136
6137 sub remove {
6138 my ($self, $path) = @_;
6139 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6140 return ++$self->{nr};
6141 }
6142 undef;
6143 }
6144
6145 sub update {
6146 my ($self, $mode, $hash, $path) = @_;
6147 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6148 return ++$self->{nr};
6149 }
6150 undef;
6151 }
6152
6153 sub DESTROY {
6154 my ($self) = @_;
6155 command_close_pipe($self->{gui}, $self->{ctx});
6156 }
6157
6158 package Git::SVN::GlobSpec;
6159 use strict;
6160 use warnings;
6161
6162 sub new {
6163 my ($class, $glob, $pattern_ok) = @_;
6164 my $re = $glob;
6165 $re =~ s!/+$!!g; # no need for trailing slashes
6166 my (@left, @right, @patterns);
6167 my $state = "left";
6168 my $die_msg = "Only one set of wildcard directories " .
6169 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6170 for my $part (split(m|/|, $glob)) {
6171 if ($part =~ /\*/ && $part ne "*") {
6172 die "Invalid pattern in '$glob': $part\n";
6173 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6174 $part !~ /^\{[^{}]+\}/) {
6175 die "Invalid pattern in '$glob': $part\n";
6176 }
6177 if ($part eq "*") {
6178 die $die_msg if $state eq "right";
6179 $state = "pattern";
6180 push(@patterns, "[^/]*");
6181 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6182 die $die_msg if $state eq "right";
6183 $state = "pattern";
6184 my $p = quotemeta($1);
6185 $p =~ s/\\,/|/g;
6186 push(@patterns, "(?:$p)");
6187 } else {
6188 if ($state eq "left") {
6189 push(@left, $part);
6190 } else {
6191 push(@right, $part);
6192 $state = "right";
6193 }
6194 }
6195 }
6196 my $depth = @patterns;
6197 if ($depth == 0) {
6198 die "One '*' is needed in glob: '$glob'\n";
6199 }
6200 my $left = join('/', @left);
6201 my $right = join('/', @right);
6202 $re = join('/', @patterns);
6203 $re = join('\/',
6204 grep(length, quotemeta($left), "($re)", quotemeta($right)));
6205 my $left_re = qr/^\/\Q$left\E(\/|$)/;
6206 bless { left => $left, right => $right, left_regex => $left_re,
6207 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6208 }
6209
6210 sub full_path {
6211 my ($self, $path) = @_;
6212 return (length $self->{left} ? "$self->{left}/" : '') .
6213 $path . (length $self->{right} ? "/$self->{right}" : '');
6214 }
6215
6216 __END__
6217
6218 Data structures:
6219
6220
6221 $remotes = { # returned by read_all_remotes()
6222 'svn' => {
6223 # svn-remote.svn.url=https://svn.musicpd.org
6224 url => 'https://svn.musicpd.org',
6225 # svn-remote.svn.fetch=mpd/trunk:trunk
6226 fetch => {
6227 'mpd/trunk' => 'trunk',
6228 },
6229 # svn-remote.svn.tags=mpd/tags/*:tags/*
6230 tags => {
6231 path => {
6232 left => 'mpd/tags',
6233 right => '',
6234 regex => qr!mpd/tags/([^/]+)$!,
6235 glob => 'tags/*',
6236 },
6237 ref => {
6238 left => 'tags',
6239 right => '',
6240 regex => qr!tags/([^/]+)$!,
6241 glob => 'tags/*',
6242 },
6243 }
6244 }
6245 };
6246
6247 $log_entry hashref as returned by libsvn_log_entry()
6248 {
6249 log => 'whitespace-formatted log entry
6250 ', # trailing newline is preserved
6251 revision => '8', # integer
6252 date => '2004-02-24T17:01:44.108345Z', # commit date
6253 author => 'committer name'
6254 };
6255
6256
6257 # this is generated by generate_diff();
6258 @mods = array of diff-index line hashes, each element represents one line
6259 of diff-index output
6260
6261 diff-index line ($m hash)
6262 {
6263 mode_a => first column of diff-index output, no leading ':',
6264 mode_b => second column of diff-index output,
6265 sha1_b => sha1sum of the final blob,
6266 chg => change type [MCRADT],
6267 file_a => original file name of a file (iff chg is 'C' or 'R')
6268 file_b => new/current file name of a file (any chg)
6269 }
6270 ;
6271
6272 # retval of read_url_paths{,_all}();
6273 $l_map = {
6274 # repository root url
6275 'https://svn.musicpd.org' => {
6276 # repository path # GIT_SVN_ID
6277 'mpd/trunk' => 'trunk',
6278 'mpd/tags/0.11.5' => 'tags/0.11.5',
6279 },
6280 }
6281
6282 Notes:
6283 I don't trust the each() function on unless I created %hash myself
6284 because the internal iterator may not have started at base.
Gitweb development nest