gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  24         eval 'sub CGI::multi_param { CGI::param(@_) }'
  25 }
  26
  27 our $t0 = [ gettimeofday() ];
  28 our $number_of_git_cmds = 0;
  29
  30 BEGIN {
  31         CGI->compile() if $ENV{'MOD_PERL'};
  32 }
  33
  34 our $version = "++GIT_VERSION++";
  35
  36 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  37 sub evaluate_uri {
  38         our $cgi;
  39
  40         our $my_url = $cgi->url();
  41         our $my_uri = $cgi->url(-absolute => 1);
  42
  43         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  44         # needed and used only for URLs with nonempty PATH_INFO
  45         our $base_url = $my_url;
  46
  47         # When the script is used as DirectoryIndex, the URL does not contain the name
  48         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  49         # have to do it ourselves. We make $path_info global because it's also used
  50         # later on.
  51         #
  52         # Another issue with the script being the DirectoryIndex is that the resulting
  53         # $my_url data is not the full script URL: this is good, because we want
  54         # generated links to keep implying the script name if it wasn't explicitly
  55         # indicated in the URL we're handling, but it means that $my_url cannot be used
  56         # as base URL.
  57         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  58         # to build the base URL ourselves:
  59         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  60         if ($path_info) {
  61                 # $path_info has already been URL-decoded by the web server, but
  62                 # $my_url and $my_uri have not. URL-decode them so we can properly
  63                 # strip $path_info.
  64                 $my_url = unescape($my_url);
  65                 $my_uri = unescape($my_uri);
  66                 if ($my_url =~ s,\Q$path_info\E$,, &&
  67                     $my_uri =~ s,\Q$path_info\E$,, &&
  68                     defined $ENV{'SCRIPT_NAME'}) {
  69                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  70                 }
  71         }
  72
  73         # target of the home link on top of all pages
  74         our $home_link = $my_uri || "/";
  75 }
  76
  77 # core git executable to use
  78 # this can just be "git" if your webserver has a sensible PATH
  79 our $GIT = "++GIT_BINDIR++/git";
  80
  81 # absolute fs-path which will be prepended to the project path
  82 #our $projectroot = "/pub/scm";
  83 our $projectroot = "++GITWEB_PROJECTROOT++";
  84
  85 # fs traversing limit for getting project list
  86 # the number is relative to the projectroot
  87 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  88
  89 # string of the home link on top of all pages
  90 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  91
  92 # extra breadcrumbs preceding the home link
  93 our @extra_breadcrumbs = ();
  94
  95 # name of your site or organization to appear in page titles
  96 # replace this with something more descriptive for clearer bookmarks
  97 our $site_name = "++GITWEB_SITENAME++"
  98                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  99
 100 # html snippet to include in the <head> section of each page
 101 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 102 # filename of html text to include at top of each page
 103 our $site_header = "++GITWEB_SITE_HEADER++";
 104 # html text to include at home page
 105 our $home_text = "++GITWEB_HOMETEXT++";
 106 # filename of html text to include at bottom of each page
 107 our $site_footer = "++GITWEB_SITE_FOOTER++";
 108
 109 # URI of stylesheets
 110 our @stylesheets = ("++GITWEB_CSS++");
 111 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 112 our $stylesheet = undef;
 113 # URI of GIT logo (72x27 size)
 114 our $logo = "++GITWEB_LOGO++";
 115 # URI of GIT favicon, assumed to be image/png type
 116 our $favicon = "++GITWEB_FAVICON++";
 117 # URI of gitweb.js (JavaScript code for gitweb)
 118 our $javascript = "++GITWEB_JS++";
 119
 120 # URI and label (title) of GIT logo link
 121 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 122 #our $logo_label = "git documentation";
 123 our $logo_url = "http://git-scm.com/";
 124 our $logo_label = "git homepage";
 125
 126 # source of projects list
 127 our $projects_list = "++GITWEB_LIST++";
 128
 129 # the width (in characters) of the projects list "Description" column
 130 our $projects_list_description_width = 25;
 131
 132 # group projects by category on the projects list
 133 # (enabled if this variable evaluates to true)
 134 our $projects_list_group_categories = 0;
 135
 136 # default category if none specified
 137 # (leave the empty string for no category)
 138 our $project_list_default_category = "";
 139
 140 # default order of projects list
 141 # valid values are none, project, descr, owner, and age
 142 our $default_projects_order = "project";
 143
 144 # show repository only if this file exists
 145 # (only effective if this variable evaluates to true)
 146 our $export_ok = "++GITWEB_EXPORT_OK++";
 147
 148 # don't generate age column on the projects list page
 149 our $omit_age_column = 0;
 150
 151 # don't generate information about owners of repositories
 152 our $omit_owner=0;
 153
 154 # show repository only if this subroutine returns true
 155 # when given the path to the project, for example:
 156 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 157 our $export_auth_hook = undef;
 158
 159 # only allow viewing of repositories also shown on the overview page
 160 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 161
 162 # list of git base URLs used for URL to where fetch project from,
 163 # i.e. full URL is "$git_base_url/$project"
 164 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 165
 166 # default blob_plain mimetype and default charset for text/plain blob
 167 our $default_blob_plain_mimetype = 'text/plain';
 168 our $default_text_plain_charset  = undef;
 169
 170 # file to use for guessing MIME types before trying /etc/mime.types
 171 # (relative to the current git repository)
 172 our $mimetypes_file = undef;
 173
 174 # assume this charset if line contains non-UTF-8 characters;
 175 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 176 # for which encoding all byte sequences are valid, for example
 177 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 178 # could be even 'utf-8' for the old behavior)
 179 our $fallback_encoding = 'latin1';
 180
 181 # rename detection options for git-diff and git-diff-tree
 182 # - default is '-M', with the cost proportional to
 183 #   (number of removed files) * (number of new files).
 184 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 185 #   (number of changed files + number of removed files) * (number of new files)
 186 # - even more costly is '-C', '--find-copies-harder' with cost
 187 #   (number of files in the original tree) * (number of new files)
 188 # - one might want to include '-B' option, e.g. '-B', '-M'
 189 our @diff_opts = ('-M'); # taken from git_commit
 190
 191 # Disables features that would allow repository owners to inject script into
 192 # the gitweb domain.
 193 our $prevent_xss = 0;
 194
 195 # Path to the highlight executable to use (must be the one from
 196 # http://www.andre-simon.de due to assumptions about parameters and output).
 197 # Useful if highlight is not installed on your webserver's PATH.
 198 # [Default: highlight]
 199 our $highlight_bin = "++HIGHLIGHT_BIN++";
 200
 201 # information about snapshot formats that gitweb is capable of serving
 202 our %known_snapshot_formats = (
 203         # name => {
 204         #       'display' => display name,
 205         #       'type' => mime type,
 206         #       'suffix' => filename suffix,
 207         #       'format' => --format for git-archive,
 208         #       'compressor' => [compressor command and arguments]
 209         #                       (array reference, optional)
 210         #       'disabled' => boolean (optional)}
 211         #
 212         'tgz' => {
 213                 'display' => 'tar.gz',
 214                 'type' => 'application/x-gzip',
 215                 'suffix' => '.tar.gz',
 216                 'format' => 'tar',
 217                 'compressor' => ['gzip', '-n']},
 218
 219         'tbz2' => {
 220                 'display' => 'tar.bz2',
 221                 'type' => 'application/x-bzip2',
 222                 'suffix' => '.tar.bz2',
 223                 'format' => 'tar',
 224                 'compressor' => ['bzip2']},
 225
 226         'txz' => {
 227                 'display' => 'tar.xz',
 228                 'type' => 'application/x-xz',
 229                 'suffix' => '.tar.xz',
 230                 'format' => 'tar',
 231                 'compressor' => ['xz'],
 232                 'disabled' => 1},
 233
 234         'zip' => {
 235                 'display' => 'zip',
 236                 'type' => 'application/x-zip',
 237                 'suffix' => '.zip',
 238                 'format' => 'zip'},
 239 );
 240
 241 # Aliases so we understand old gitweb.snapshot values in repository
 242 # configuration.
 243 our %known_snapshot_format_aliases = (
 244         'gzip'  => 'tgz',
 245         'bzip2' => 'tbz2',
 246         'xz'    => 'txz',
 247
 248         # backward compatibility: legacy gitweb config support
 249         'x-gzip' => undef, 'gz' => undef,
 250         'x-bzip2' => undef, 'bz2' => undef,
 251         'x-zip' => undef, '' => undef,
 252 );
 253
 254 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 255 # are changed, it may be appropriate to change these values too via
 256 # $GITWEB_CONFIG.
 257 our %avatar_size = (
 258         'default' => 16,
 259         'double'  => 32
 260 );
 261
 262 # Used to set the maximum load that we will still respond to gitweb queries.
 263 # If server load exceed this value then return "503 server busy" error.
 264 # If gitweb cannot determined server load, it is taken to be 0.
 265 # Leave it undefined (or set to 'undef') to turn off load checking.
 266 our $maxload = 300;
 267
 268 # configuration for 'highlight' (http://www.andre-simon.de/)
 269 # match by basename
 270 our %highlight_basename = (
 271         #'Program' => 'py',
 272         #'Library' => 'py',
 273         'SConstruct' => 'py', # SCons equivalent of Makefile
 274         'Makefile' => 'make',
 275 );
 276 # match by extension
 277 our %highlight_ext = (
 278         # main extensions, defining name of syntax;
 279         # see files in /usr/share/highlight/langDefs/ directory
 280         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 281         # alternate extensions, see /etc/highlight/filetypes.conf
 282         (map { $_ => 'c'   } qw(c h)),
 283         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 284         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 285         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 286         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 287         (map { $_ => 'make'} qw(make mak mk)),
 288         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 289 );
 290
 291 # You define site-wide feature defaults here; override them with
 292 # $GITWEB_CONFIG as necessary.
 293 our %feature = (
 294         # feature => {
 295         #       'sub' => feature-sub (subroutine),
 296         #       'override' => allow-override (boolean),
 297         #       'default' => [ default options...] (array reference)}
 298         #
 299         # if feature is overridable (it means that allow-override has true value),
 300         # then feature-sub will be called with default options as parameters;
 301         # return value of feature-sub indicates if to enable specified feature
 302         #
 303         # if there is no 'sub' key (no feature-sub), then feature cannot be
 304         # overridden
 305         #
 306         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 307         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 308         # is enabled
 309
 310         # Enable the 'blame' blob view, showing the last commit that modified
 311         # each line in the file. This can be very CPU-intensive.
 312
 313         # To enable system wide have in $GITWEB_CONFIG
 314         # $feature{'blame'}{'default'} = [1];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'blame'}{'override'} = 1;
 317         # and in project config gitweb.blame = 0|1;
 318         'blame' => {
 319                 'sub' => sub { feature_bool('blame', @_) },
 320                 'override' => 0,
 321                 'default' => [0]},
 322
 323         # Enable the 'snapshot' link, providing a compressed archive of any
 324         # tree. This can potentially generate high traffic if you have large
 325         # project.
 326
 327         # Value is a list of formats defined in %known_snapshot_formats that
 328         # you wish to offer.
 329         # To disable system wide have in $GITWEB_CONFIG
 330         # $feature{'snapshot'}{'default'} = [];
 331         # To have project specific config enable override in $GITWEB_CONFIG
 332         # $feature{'snapshot'}{'override'} = 1;
 333         # and in project config, a comma-separated list of formats or "none"
 334         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 335         'snapshot' => {
 336                 'sub' => \&feature_snapshot,
 337                 'override' => 0,
 338                 'default' => ['tgz']},
 339
 340         # Enable text search, which will list the commits which match author,
 341         # committer or commit text to a given string.  Enabled by default.
 342         # Project specific override is not supported.
 343         #
 344         # Note that this controls all search features, which means that if
 345         # it is disabled, then 'grep' and 'pickaxe' search would also be
 346         # disabled.
 347         'search' => {
 348                 'override' => 0,
 349                 'default' => [1]},
 350
 351         # Enable grep search, which will list the files in currently selected
 352         # tree containing the given string. Enabled by default. This can be
 353         # potentially CPU-intensive, of course.
 354         # Note that you need to have 'search' feature enabled too.
 355
 356         # To enable system wide have in $GITWEB_CONFIG
 357         # $feature{'grep'}{'default'} = [1];
 358         # To have project specific config enable override in $GITWEB_CONFIG
 359         # $feature{'grep'}{'override'} = 1;
 360         # and in project config gitweb.grep = 0|1;
 361         'grep' => {
 362                 'sub' => sub { feature_bool('grep', @_) },
 363                 'override' => 0,
 364                 'default' => [1]},
 365
 366         # Enable the pickaxe search, which will list the commits that modified
 367         # a given string in a file. This can be practical and quite faster
 368         # alternative to 'blame', but still potentially CPU-intensive.
 369         # Note that you need to have 'search' feature enabled too.
 370
 371         # To enable system wide have in $GITWEB_CONFIG
 372         # $feature{'pickaxe'}{'default'} = [1];
 373         # To have project specific config enable override in $GITWEB_CONFIG
 374         # $feature{'pickaxe'}{'override'} = 1;
 375         # and in project config gitweb.pickaxe = 0|1;
 376         'pickaxe' => {
 377                 'sub' => sub { feature_bool('pickaxe', @_) },
 378                 'override' => 0,
 379                 'default' => [1]},
 380
 381         # Enable showing size of blobs in a 'tree' view, in a separate
 382         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 383
 384         # To disable system wide have in $GITWEB_CONFIG
 385         # $feature{'show-sizes'}{'default'} = [0];
 386         # To have project specific config enable override in $GITWEB_CONFIG
 387         # $feature{'show-sizes'}{'override'} = 1;
 388         # and in project config gitweb.showsizes = 0|1;
 389         'show-sizes' => {
 390                 'sub' => sub { feature_bool('showsizes', @_) },
 391                 'override' => 0,
 392                 'default' => [1]},
 393
 394         # Make gitweb use an alternative format of the URLs which can be
 395         # more readable and natural-looking: project name is embedded
 396         # directly in the path and the query string contains other
 397         # auxiliary information. All gitweb installations recognize
 398         # URL in either format; this configures in which formats gitweb
 399         # generates links.
 400
 401         # To enable system wide have in $GITWEB_CONFIG
 402         # $feature{'pathinfo'}{'default'} = [1];
 403         # Project specific override is not supported.
 404
 405         # Note that you will need to change the default location of CSS,
 406         # favicon, logo and possibly other files to an absolute URL. Also,
 407         # if gitweb.cgi serves as your indexfile, you will need to force
 408         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 409         'pathinfo' => {
 410                 'override' => 0,
 411                 'default' => [0]},
 412
 413         # Make gitweb consider projects in project root subdirectories
 414         # to be forks of existing projects. Given project $projname.git,
 415         # projects matching $projname/*.git will not be shown in the main
 416         # projects list, instead a '+' mark will be added to $projname
 417         # there and a 'forks' view will be enabled for the project, listing
 418         # all the forks. If project list is taken from a file, forks have
 419         # to be listed after the main project.
 420
 421         # To enable system wide have in $GITWEB_CONFIG
 422         # $feature{'forks'}{'default'} = [1];
 423         # Project specific override is not supported.
 424         'forks' => {
 425                 'override' => 0,
 426                 'default' => [0]},
 427
 428         # Insert custom links to the action bar of all project pages.
 429         # This enables you mainly to link to third-party scripts integrating
 430         # into gitweb; e.g. git-browser for graphical history representation
 431         # or custom web-based repository administration interface.
 432
 433         # The 'default' value consists of a list of triplets in the form
 434         # (label, link, position) where position is the label after which
 435         # to insert the link and link is a format string where %n expands
 436         # to the project name, %f to the project path within the filesystem,
 437         # %h to the current hash (h gitweb parameter) and %b to the current
 438         # hash base (hb gitweb parameter); %% expands to %.
 439
 440         # To enable system wide have in $GITWEB_CONFIG e.g.
 441         # $feature{'actions'}{'default'} = [('graphiclog',
 442         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 443         # Project specific override is not supported.
 444         'actions' => {
 445                 'override' => 0,
 446                 'default' => []},
 447
 448         # Allow gitweb scan project content tags of project repository,
 449         # and display the popular Web 2.0-ish "tag cloud" near the projects
 450         # list.  Note that this is something COMPLETELY different from the
 451         # normal Git tags.
 452
 453         # gitweb by itself can show existing tags, but it does not handle
 454         # tagging itself; you need to do it externally, outside gitweb.
 455         # The format is described in git_get_project_ctags() subroutine.
 456         # You may want to install the HTML::TagCloud Perl module to get
 457         # a pretty tag cloud instead of just a list of tags.
 458
 459         # To enable system wide have in $GITWEB_CONFIG
 460         # $feature{'ctags'}{'default'} = [1];
 461         # Project specific override is not supported.
 462
 463         # In the future whether ctags editing is enabled might depend
 464         # on the value, but using 1 should always mean no editing of ctags.
 465         'ctags' => {
 466                 'override' => 0,
 467                 'default' => [0]},
 468
 469         # The maximum number of patches in a patchset generated in patch
 470         # view. Set this to 0 or undef to disable patch view, or to a
 471         # negative number to remove any limit.
 472
 473         # To disable system wide have in $GITWEB_CONFIG
 474         # $feature{'patches'}{'default'} = [0];
 475         # To have project specific config enable override in $GITWEB_CONFIG
 476         # $feature{'patches'}{'override'} = 1;
 477         # and in project config gitweb.patches = 0|n;
 478         # where n is the maximum number of patches allowed in a patchset.
 479         'patches' => {
 480                 'sub' => \&feature_patches,
 481                 'override' => 0,
 482                 'default' => [16]},
 483
 484         # Avatar support. When this feature is enabled, views such as
 485         # shortlog or commit will display an avatar associated with
 486         # the email of the committer(s) and/or author(s).
 487
 488         # Currently available providers are gravatar and picon.
 489         # If an unknown provider is specified, the feature is disabled.
 490
 491         # Gravatar depends on Digest::MD5.
 492         # Picon currently relies on the indiana.edu database.
 493
 494         # To enable system wide have in $GITWEB_CONFIG
 495         # $feature{'avatar'}{'default'} = ['<provider>'];
 496         # where <provider> is either gravatar or picon.
 497         # To have project specific config enable override in $GITWEB_CONFIG
 498         # $feature{'avatar'}{'override'} = 1;
 499         # and in project config gitweb.avatar = <provider>;
 500         'avatar' => {
 501                 'sub' => \&feature_avatar,
 502                 'override' => 0,
 503                 'default' => ['']},
 504
 505         # Enable displaying how much time and how many git commands
 506         # it took to generate and display page.  Disabled by default.
 507         # Project specific override is not supported.
 508         'timed' => {
 509                 'override' => 0,
 510                 'default' => [0]},
 511
 512         # Enable turning some links into links to actions which require
 513         # JavaScript to run (like 'blame_incremental').  Not enabled by
 514         # default.  Project specific override is currently not supported.
 515         'javascript-actions' => {
 516                 'override' => 0,
 517                 'default' => [0]},
 518
 519         # Enable and configure ability to change common timezone for dates
 520         # in gitweb output via JavaScript.  Enabled by default.
 521         # Project specific override is not supported.
 522         'javascript-timezone' => {
 523                 'override' => 0,
 524                 'default' => [
 525                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 526                                      # or undef to turn off this feature
 527                         'gitweb_tz', # name of cookie where to store selected timezone
 528                         'datetime',  # CSS class used to mark up dates for manipulation
 529                 ]},
 530
 531         # Syntax highlighting support. This is based on Daniel Svensson's
 532         # and Sham Chukoury's work in gitweb-xmms2.git.
 533         # It requires the 'highlight' program present in $PATH,
 534         # and therefore is disabled by default.
 535
 536         # To enable system wide have in $GITWEB_CONFIG
 537         # $feature{'highlight'}{'default'} = [1];
 538
 539         'highlight' => {
 540                 'sub' => sub { feature_bool('highlight', @_) },
 541                 'override' => 0,
 542                 'default' => [0]},
 543
 544         # Enable displaying of remote heads in the heads list
 545
 546         # To enable system wide have in $GITWEB_CONFIG
 547         # $feature{'remote_heads'}{'default'} = [1];
 548         # To have project specific config enable override in $GITWEB_CONFIG
 549         # $feature{'remote_heads'}{'override'} = 1;
 550         # and in project config gitweb.remoteheads = 0|1;
 551         'remote_heads' => {
 552                 'sub' => sub { feature_bool('remote_heads', @_) },
 553                 'override' => 0,
 554                 'default' => [0]},
 555
 556         # Enable showing branches under other refs in addition to heads
 557
 558         # To set system wide extra branch refs have in $GITWEB_CONFIG
 559         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 560         # To have project specific config enable override in $GITWEB_CONFIG
 561         # $feature{'extra-branch-refs'}{'override'} = 1;
 562         # and in project config gitweb.extrabranchrefs = dirs of choice
 563         # Every directory is separated with whitespace.
 564
 565         'extra-branch-refs' => {
 566                 'sub' => \&feature_extra_branch_refs,
 567                 'override' => 0,
 568                 'default' => []},
 569 );
 570
 571 # email obfuscation
 572 our $email;
 573 if (eval { require HTML::Email::Obfuscate; 1 }) {
 574         $email = HTML::Email::Obfuscate->new(lite => 1);
 575 }
 576
 577 sub gitweb_get_feature {
 578         my ($name) = @_;
 579         return unless exists $feature{$name};
 580         my ($sub, $override, @defaults) = (
 581                 $feature{$name}{'sub'},
 582                 $feature{$name}{'override'},
 583                 @{$feature{$name}{'default'}});
 584         # project specific override is possible only if we have project
 585         our $git_dir; # global variable, declared later
 586         if (!$override || !defined $git_dir) {
 587                 return @defaults;
 588         }
 589         if (!defined $sub) {
 590                 warn "feature $name is not overridable";
 591                 return @defaults;
 592         }
 593         return $sub->(@defaults);
 594 }
 595
 596 # A wrapper to check if a given feature is enabled.
 597 # With this, you can say
 598 #
 599 #   my $bool_feat = gitweb_check_feature('bool_feat');
 600 #   gitweb_check_feature('bool_feat') or somecode;
 601 #
 602 # instead of
 603 #
 604 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 605 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 606 #
 607 sub gitweb_check_feature {
 608         return (gitweb_get_feature(@_))[0];
 609 }
 610
 611
 612 sub feature_bool {
 613         my $key = shift;
 614         my ($val) = git_get_project_config($key, '--bool');
 615
 616         if (!defined $val) {
 617                 return ($_[0]);
 618         } elsif ($val eq 'true') {
 619                 return (1);
 620         } elsif ($val eq 'false') {
 621                 return (0);
 622         }
 623 }
 624
 625 sub feature_snapshot {
 626         my (@fmts) = @_;
 627
 628         my ($val) = git_get_project_config('snapshot');
 629
 630         if ($val) {
 631                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 632         }
 633
 634         return @fmts;
 635 }
 636
 637 sub feature_patches {
 638         my @val = (git_get_project_config('patches', '--int'));
 639
 640         if (@val) {
 641                 return @val;
 642         }
 643
 644         return ($_[0]);
 645 }
 646
 647 sub feature_avatar {
 648         my @val = (git_get_project_config('avatar'));
 649
 650         return @val ? @val : @_;
 651 }
 652
 653 sub feature_extra_branch_refs {
 654         my (@branch_refs) = @_;
 655         my $values = git_get_project_config('extrabranchrefs');
 656
 657         if ($values) {
 658                 $values = config_to_multi ($values);
 659                 @branch_refs = ();
 660                 foreach my $value (@{$values}) {
 661                         push @branch_refs, split /\s+/, $value;
 662                 }
 663         }
 664
 665         return @branch_refs;
 666 }
 667
 668 # checking HEAD file with -e is fragile if the repository was
 669 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 670 # and then pruned.
 671 sub check_head_link {
 672         my ($dir) = @_;
 673         my $headfile = "$dir/HEAD";
 674         return ((-e $headfile) ||
 675                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 676 }
 677
 678 sub check_export_ok {
 679         my ($dir) = @_;
 680         return (check_head_link($dir) &&
 681                 (!$export_ok || -e "$dir/$export_ok") &&
 682                 (!$export_auth_hook || $export_auth_hook->($dir)));
 683 }
 684
 685 # process alternate names for backward compatibility
 686 # filter out unsupported (unknown) snapshot formats
 687 sub filter_snapshot_fmts {
 688         my @fmts = @_;
 689
 690         @fmts = map {
 691                 exists $known_snapshot_format_aliases{$_} ?
 692                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 693         @fmts = grep {
 694                 exists $known_snapshot_formats{$_} &&
 695                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 696 }
 697
 698 sub filter_and_validate_refs {
 699         my @refs = @_;
 700         my %unique_refs = ();
 701
 702         foreach my $ref (@refs) {
 703                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 704                 # 'heads' are added implicitly in get_branch_refs().
 705                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 706         }
 707         return sort keys %unique_refs;
 708 }
 709
 710 # If it is set to code reference, it is code that it is to be run once per
 711 # request, allowing updating configurations that change with each request,
 712 # while running other code in config file only once.
 713 #
 714 # Otherwise, if it is false then gitweb would process config file only once;
 715 # if it is true then gitweb config would be run for each request.
 716 our $per_request_config = 1;
 717
 718 # read and parse gitweb config file given by its parameter.
 719 # returns true on success, false on recoverable error, allowing
 720 # to chain this subroutine, using first file that exists.
 721 # dies on errors during parsing config file, as it is unrecoverable.
 722 sub read_config_file {
 723         my $filename = shift;
 724         return unless defined $filename;
 725         # die if there are errors parsing config file
 726         if (-e $filename) {
 727                 do $filename;
 728                 die $@ if $@;
 729                 return 1;
 730         }
 731         return;
 732 }
 733
 734 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 735 sub evaluate_gitweb_config {
 736         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 737         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 738         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 739
 740         # Protect against duplications of file names, to not read config twice.
 741         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 742         # there possibility of duplication of filename there doesn't matter.
 743         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 744         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 745
 746         # Common system-wide settings for convenience.
 747         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 748         read_config_file($GITWEB_CONFIG_COMMON);
 749
 750         # Use first config file that exists.  This means use the per-instance
 751         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 752         read_config_file($GITWEB_CONFIG) and return;
 753         read_config_file($GITWEB_CONFIG_SYSTEM);
 754 }
 755
 756 # Get loadavg of system, to compare against $maxload.
 757 # Currently it requires '/proc/loadavg' present to get loadavg;
 758 # if it is not present it returns 0, which means no load checking.
 759 sub get_loadavg {
 760         if( -e '/proc/loadavg' ){
 761                 open my $fd, '<', '/proc/loadavg'
 762                         or return 0;
 763                 my @load = split(/\s+/, scalar <$fd>);
 764                 close $fd;
 765
 766                 # The first three columns measure CPU and IO utilization of the last one,
 767                 # five, and 10 minute periods.  The fourth column shows the number of
 768                 # currently running processes and the total number of processes in the m/n
 769                 # format.  The last column displays the last process ID used.
 770                 return $load[0] || 0;
 771         }
 772         # additional checks for load average should go here for things that don't export
 773         # /proc/loadavg
 774
 775         return 0;
 776 }
 777
 778 # version of the core git binary
 779 our $git_version;
 780 sub evaluate_git_version {
 781         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 782         $number_of_git_cmds++;
 783 }
 784
 785 sub check_loadavg {
 786         if (defined $maxload && get_loadavg() > $maxload) {
 787                 die_error(503, "The load average on the server is too high");
 788         }
 789 }
 790
 791 # ======================================================================
 792 # input validation and dispatch
 793
 794 # input parameters can be collected from a variety of sources (presently, CGI
 795 # and PATH_INFO), so we define an %input_params hash that collects them all
 796 # together during validation: this allows subsequent uses (e.g. href()) to be
 797 # agnostic of the parameter origin
 798
 799 our %input_params = ();
 800
 801 # input parameters are stored with the long parameter name as key. This will
 802 # also be used in the href subroutine to convert parameters to their CGI
 803 # equivalent, and since the href() usage is the most frequent one, we store
 804 # the name -> CGI key mapping here, instead of the reverse.
 805 #
 806 # XXX: Warning: If you touch this, check the search form for updating,
 807 # too.
 808
 809 our @cgi_param_mapping = (
 810         project => "p",
 811         action => "a",
 812         file_name => "f",
 813         file_parent => "fp",
 814         hash => "h",
 815         hash_parent => "hp",
 816         hash_base => "hb",
 817         hash_parent_base => "hpb",
 818         page => "pg",
 819         order => "o",
 820         searchtext => "s",
 821         searchtype => "st",
 822         snapshot_format => "sf",
 823         extra_options => "opt",
 824         search_use_regexp => "sr",
 825         ctag => "by_tag",
 826         diff_style => "ds",
 827         project_filter => "pf",
 828         # this must be last entry (for manipulation from JavaScript)
 829         javascript => "js"
 830 );
 831 our %cgi_param_mapping = @cgi_param_mapping;
 832
 833 # we will also need to know the possible actions, for validation
 834 our %actions = (
 835         "blame" => \&git_blame,
 836         "blame_incremental" => \&git_blame_incremental,
 837         "blame_data" => \&git_blame_data,
 838         "blobdiff" => \&git_blobdiff,
 839         "blobdiff_plain" => \&git_blobdiff_plain,
 840         "blob" => \&git_blob,
 841         "blob_plain" => \&git_blob_plain,
 842         "commitdiff" => \&git_commitdiff,
 843         "commitdiff_plain" => \&git_commitdiff_plain,
 844         "commit" => \&git_commit,
 845         "forks" => \&git_forks,
 846         "heads" => \&git_heads,
 847         "history" => \&git_history,
 848         "log" => \&git_log,
 849         "patch" => \&git_patch,
 850         "patches" => \&git_patches,
 851         "remotes" => \&git_remotes,
 852         "rss" => \&git_rss,
 853         "atom" => \&git_atom,
 854         "search" => \&git_search,
 855         "search_help" => \&git_search_help,
 856         "shortlog" => \&git_shortlog,
 857         "summary" => \&git_summary,
 858         "tag" => \&git_tag,
 859         "tags" => \&git_tags,
 860         "tree" => \&git_tree,
 861         "snapshot" => \&git_snapshot,
 862         "object" => \&git_object,
 863         # those below don't need $project
 864         "opml" => \&git_opml,
 865         "project_list" => \&git_project_list,
 866         "project_index" => \&git_project_index,
 867 );
 868
 869 # finally, we have the hash of allowed extra_options for the commands that
 870 # allow them
 871 our %allowed_options = (
 872         "--no-merges" => [ qw(rss atom log shortlog history) ],
 873 );
 874
 875 # fill %input_params with the CGI parameters. All values except for 'opt'
 876 # should be single values, but opt can be an array. We should probably
 877 # build an array of parameters that can be multi-valued, but since for the time
 878 # being it's only this one, we just single it out
 879 sub evaluate_query_params {
 880         our $cgi;
 881
 882         while (my ($name, $symbol) = each %cgi_param_mapping) {
 883                 if ($symbol eq 'opt') {
 884                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 885                 } else {
 886                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 887                 }
 888         }
 889 }
 890
 891 # now read PATH_INFO and update the parameter list for missing parameters
 892 sub evaluate_path_info {
 893         return if defined $input_params{'project'};
 894         return if !$path_info;
 895         $path_info =~ s,^/+,,;
 896         return if !$path_info;
 897
 898         # find which part of PATH_INFO is project
 899         my $project = $path_info;
 900         $project =~ s,/+$,,;
 901         while ($project && !check_head_link("$projectroot/$project")) {
 902                 $project =~ s,/*[^/]*$,,;
 903         }
 904         return unless $project;
 905         $input_params{'project'} = $project;
 906
 907         # do not change any parameters if an action is given using the query string
 908         return if $input_params{'action'};
 909         $path_info =~ s,^\Q$project\E/*,,;
 910
 911         # next, check if we have an action
 912         my $action = $path_info;
 913         $action =~ s,/.*$,,;
 914         if (exists $actions{$action}) {
 915                 $path_info =~ s,^$action/*,,;
 916                 $input_params{'action'} = $action;
 917         }
 918
 919         # list of actions that want hash_base instead of hash, but can have no
 920         # pathname (f) parameter
 921         my @wants_base = (
 922                 'tree',
 923                 'history',
 924         );
 925
 926         # we want to catch, among others
 927         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 928         my ($parentrefname, $parentpathname, $refname, $pathname) =
 929                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 930
 931         # first, analyze the 'current' part
 932         if (defined $pathname) {
 933                 # we got "branch:filename" or "branch:dir/"
 934                 # we could use git_get_type(branch:pathname), but:
 935                 # - it needs $git_dir
 936                 # - it does a git() call
 937                 # - the convention of terminating directories with a slash
 938                 #   makes it superfluous
 939                 # - embedding the action in the PATH_INFO would make it even
 940                 #   more superfluous
 941                 $pathname =~ s,^/+,,;
 942                 if (!$pathname || substr($pathname, -1) eq "/") {
 943                         $input_params{'action'} ||= "tree";
 944                         $pathname =~ s,/$,,;
 945                 } else {
 946                         # the default action depends on whether we had parent info
 947                         # or not
 948                         if ($parentrefname) {
 949                                 $input_params{'action'} ||= "blobdiff_plain";
 950                         } else {
 951                                 $input_params{'action'} ||= "blob_plain";
 952                         }
 953                 }
 954                 $input_params{'hash_base'} ||= $refname;
 955                 $input_params{'file_name'} ||= $pathname;
 956         } elsif (defined $refname) {
 957                 # we got "branch". In this case we have to choose if we have to
 958                 # set hash or hash_base.
 959                 #
 960                 # Most of the actions without a pathname only want hash to be
 961                 # set, except for the ones specified in @wants_base that want
 962                 # hash_base instead. It should also be noted that hand-crafted
 963                 # links having 'history' as an action and no pathname or hash
 964                 # set will fail, but that happens regardless of PATH_INFO.
 965                 if (defined $parentrefname) {
 966                         # if there is parent let the default be 'shortlog' action
 967                         # (for http://git.example.com/repo.git/A..B links); if there
 968                         # is no parent, dispatch will detect type of object and set
 969                         # action appropriately if required (if action is not set)
 970                         $input_params{'action'} ||= "shortlog";
 971                 }
 972                 if ($input_params{'action'} &&
 973                     grep { $_ eq $input_params{'action'} } @wants_base) {
 974                         $input_params{'hash_base'} ||= $refname;
 975                 } else {
 976                         $input_params{'hash'} ||= $refname;
 977                 }
 978         }
 979
 980         # next, handle the 'parent' part, if present
 981         if (defined $parentrefname) {
 982                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 983                 # someproject/blobdiff/oldrev..newrev:/filename
 984                 if ($parentpathname) {
 985                         $parentpathname =~ s,^/+,,;
 986                         $parentpathname =~ s,/$,,;
 987                         $input_params{'file_parent'} ||= $parentpathname;
 988                 } else {
 989                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 990                 }
 991                 # we assume that hash_parent_base is wanted if a path was specified,
 992                 # or if the action wants hash_base instead of hash
 993                 if (defined $input_params{'file_parent'} ||
 994                         grep { $_ eq $input_params{'action'} } @wants_base) {
 995                         $input_params{'hash_parent_base'} ||= $parentrefname;
 996                 } else {
 997                         $input_params{'hash_parent'} ||= $parentrefname;
 998                 }
 999         }
1000
1001         # for the snapshot action, we allow URLs in the form
1002         # $project/snapshot/$hash.ext
1003         # where .ext determines the snapshot and gets removed from the
1004         # passed $refname to provide the $hash.
1005         #
1006         # To be able to tell that $refname includes the format extension, we
1007         # require the following two conditions to be satisfied:
1008         # - the hash input parameter MUST have been set from the $refname part
1009         #   of the URL (i.e. they must be equal)
1010         # - the snapshot format MUST NOT have been defined already (e.g. from
1011         #   CGI parameter sf)
1012         # It's also useless to try any matching unless $refname has a dot,
1013         # so we check for that too
1014         if (defined $input_params{'action'} &&
1015                 $input_params{'action'} eq 'snapshot' &&
1016                 defined $refname && index($refname, '.') != -1 &&
1017                 $refname eq $input_params{'hash'} &&
1018                 !defined $input_params{'snapshot_format'}) {
1019                 # We loop over the known snapshot formats, checking for
1020                 # extensions. Allowed extensions are both the defined suffix
1021                 # (which includes the initial dot already) and the snapshot
1022                 # format key itself, with a prepended dot
1023                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1024                         my $hash = $refname;
1025                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1026                                 next;
1027                         }
1028                         my $sfx = $1;
1029                         # a valid suffix was found, so set the snapshot format
1030                         # and reset the hash parameter
1031                         $input_params{'snapshot_format'} = $fmt;
1032                         $input_params{'hash'} = $hash;
1033                         # we also set the format suffix to the one requested
1034                         # in the URL: this way a request for e.g. .tgz returns
1035                         # a .tgz instead of a .tar.gz
1036                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1037                         last;
1038                 }
1039         }
1040 }
1041
1042 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1043      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1044      $searchtext, $search_regexp, $project_filter);
1045 sub evaluate_and_validate_params {
1046         our $action = $input_params{'action'};
1047         if (defined $action) {
1048                 if (!is_valid_action($action)) {
1049                         die_error(400, "Invalid action parameter");
1050                 }
1051         }
1052
1053         # parameters which are pathnames
1054         our $project = $input_params{'project'};
1055         if (defined $project) {
1056                 if (!is_valid_project($project)) {
1057                         undef $project;
1058                         die_error(404, "No such project");
1059                 }
1060         }
1061
1062         our $project_filter = $input_params{'project_filter'};
1063         if (defined $project_filter) {
1064                 if (!is_valid_pathname($project_filter)) {
1065                         die_error(404, "Invalid project_filter parameter");
1066                 }
1067         }
1068
1069         our $file_name = $input_params{'file_name'};
1070         if (defined $file_name) {
1071                 if (!is_valid_pathname($file_name)) {
1072                         die_error(400, "Invalid file parameter");
1073                 }
1074         }
1075
1076         our $file_parent = $input_params{'file_parent'};
1077         if (defined $file_parent) {
1078                 if (!is_valid_pathname($file_parent)) {
1079                         die_error(400, "Invalid file parent parameter");
1080                 }
1081         }
1082
1083         # parameters which are refnames
1084         our $hash = $input_params{'hash'};
1085         if (defined $hash) {
1086                 if (!is_valid_refname($hash)) {
1087                         die_error(400, "Invalid hash parameter");
1088                 }
1089         }
1090
1091         our $hash_parent = $input_params{'hash_parent'};
1092         if (defined $hash_parent) {
1093                 if (!is_valid_refname($hash_parent)) {
1094                         die_error(400, "Invalid hash parent parameter");
1095                 }
1096         }
1097
1098         our $hash_base = $input_params{'hash_base'};
1099         if (defined $hash_base) {
1100                 if (!is_valid_refname($hash_base)) {
1101                         die_error(400, "Invalid hash base parameter");
1102                 }
1103         }
1104
1105         our @extra_options = @{$input_params{'extra_options'}};
1106         # @extra_options is always defined, since it can only be (currently) set from
1107         # CGI, and $cgi->param() returns the empty array in array context if the param
1108         # is not set
1109         foreach my $opt (@extra_options) {
1110                 if (not exists $allowed_options{$opt}) {
1111                         die_error(400, "Invalid option parameter");
1112                 }
1113                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1114                         die_error(400, "Invalid option parameter for this action");
1115                 }
1116         }
1117
1118         our $hash_parent_base = $input_params{'hash_parent_base'};
1119         if (defined $hash_parent_base) {
1120                 if (!is_valid_refname($hash_parent_base)) {
1121                         die_error(400, "Invalid hash parent base parameter");
1122                 }
1123         }
1124
1125         # other parameters
1126         our $page = $input_params{'page'};
1127         if (defined $page) {
1128                 if ($page =~ m/[^0-9]/) {
1129                         die_error(400, "Invalid page parameter");
1130                 }
1131         }
1132
1133         our $searchtype = $input_params{'searchtype'};
1134         if (defined $searchtype) {
1135                 if ($searchtype =~ m/[^a-z]/) {
1136                         die_error(400, "Invalid searchtype parameter");
1137                 }
1138         }
1139
1140         our $search_use_regexp = $input_params{'search_use_regexp'};
1141
1142         our $searchtext = $input_params{'searchtext'};
1143         our $search_regexp = undef;
1144         if (defined $searchtext) {
1145                 if (length($searchtext) < 2) {
1146                         die_error(403, "At least two characters are required for search parameter");
1147                 }
1148                 if ($search_use_regexp) {
1149                         $search_regexp = $searchtext;
1150                         if (!eval { qr/$search_regexp/; 1; }) {
1151                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1152                                 die_error(400, "Invalid search regexp '$search_regexp'",
1153                                           esc_html($error));
1154                         }
1155                 } else {
1156                         $search_regexp = quotemeta $searchtext;
1157                 }
1158         }
1159 }
1160
1161 # path to the current git repository
1162 our $git_dir;
1163 sub evaluate_git_dir {
1164         our $git_dir = "$projectroot/$project" if $project;
1165 }
1166
1167 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1168 sub configure_gitweb_features {
1169         # list of supported snapshot formats
1170         our @snapshot_fmts = gitweb_get_feature('snapshot');
1171         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1172
1173         # check that the avatar feature is set to a known provider name,
1174         # and for each provider check if the dependencies are satisfied.
1175         # if the provider name is invalid or the dependencies are not met,
1176         # reset $git_avatar to the empty string.
1177         our ($git_avatar) = gitweb_get_feature('avatar');
1178         if ($git_avatar eq 'gravatar') {
1179                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1180         } elsif ($git_avatar eq 'picon') {
1181                 # no dependencies
1182         } else {
1183                 $git_avatar = '';
1184         }
1185
1186         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1187         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1188 }
1189
1190 sub get_branch_refs {
1191         return ('heads', @extra_branch_refs);
1192 }
1193
1194 # custom error handler: 'die <message>' is Internal Server Error
1195 sub handle_errors_html {
1196         my $msg = shift; # it is already HTML escaped
1197
1198         # to avoid infinite loop where error occurs in die_error,
1199         # change handler to default handler, disabling handle_errors_html
1200         set_message("Error occurred when inside die_error:\n$msg");
1201
1202         # you cannot jump out of die_error when called as error handler;
1203         # the subroutine set via CGI::Carp::set_message is called _after_
1204         # HTTP headers are already written, so it cannot write them itself
1205         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1206 }
1207 set_message(\&handle_errors_html);
1208
1209 # dispatch
1210 sub dispatch {
1211         if (!defined $action) {
1212                 if (defined $hash) {
1213                         $action = git_get_type($hash);
1214                         $action or die_error(404, "Object does not exist");
1215                 } elsif (defined $hash_base && defined $file_name) {
1216                         $action = git_get_type("$hash_base:$file_name");
1217                         $action or die_error(404, "File or directory does not exist");
1218                 } elsif (defined $project) {
1219                         $action = 'summary';
1220                 } else {
1221                         $action = 'project_list';
1222                 }
1223         }
1224         if (!defined($actions{$action})) {
1225                 die_error(400, "Unknown action");
1226         }
1227         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1228             !$project) {
1229                 die_error(400, "Project needed");
1230         }
1231         $actions{$action}->();
1232 }
1233
1234 sub reset_timer {
1235         our $t0 = [ gettimeofday() ]
1236                 if defined $t0;
1237         our $number_of_git_cmds = 0;
1238 }
1239
1240 our $first_request = 1;
1241 sub run_request {
1242         reset_timer();
1243
1244         evaluate_uri();
1245         if ($first_request) {
1246                 evaluate_gitweb_config();
1247                 evaluate_git_version();
1248         }
1249         if ($per_request_config) {
1250                 if (ref($per_request_config) eq 'CODE') {
1251                         $per_request_config->();
1252                 } elsif (!$first_request) {
1253                         evaluate_gitweb_config();
1254                 }
1255         }
1256         check_loadavg();
1257
1258         # $projectroot and $projects_list might be set in gitweb config file
1259         $projects_list ||= $projectroot;
1260
1261         evaluate_query_params();
1262         evaluate_path_info();
1263         evaluate_and_validate_params();
1264         evaluate_git_dir();
1265
1266         configure_gitweb_features();
1267
1268         dispatch();
1269 }
1270
1271 our $is_last_request = sub { 1 };
1272 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1273 our $CGI = 'CGI';
1274 our $cgi;
1275 sub configure_as_fcgi {
1276         require CGI::Fast;
1277         our $CGI = 'CGI::Fast';
1278
1279         my $request_number = 0;
1280         # let each child service 100 requests
1281         our $is_last_request = sub { ++$request_number > 100 };
1282 }
1283 sub evaluate_argv {
1284         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1285         configure_as_fcgi()
1286                 if $script_name =~ /\.fcgi$/;
1287
1288         return unless (@ARGV);
1289
1290         require Getopt::Long;
1291         Getopt::Long::GetOptions(
1292                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1293                 'nproc|n=i' => sub {
1294                         my ($arg, $val) = @_;
1295                         return unless eval { require FCGI::ProcManager; 1; };
1296                         my $proc_manager = FCGI::ProcManager->new({
1297                                 n_processes => $val,
1298                         });
1299                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1300                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1301                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1302                 },
1303         );
1304 }
1305
1306 sub run {
1307         evaluate_argv();
1308
1309         $first_request = 1;
1310         $pre_listen_hook->()
1311                 if $pre_listen_hook;
1312
1313  REQUEST:
1314         while ($cgi = $CGI->new()) {
1315                 $pre_dispatch_hook->()
1316                         if $pre_dispatch_hook;
1317
1318                 run_request();
1319
1320                 $post_dispatch_hook->()
1321                         if $post_dispatch_hook;
1322                 $first_request = 0;
1323
1324                 last REQUEST if ($is_last_request->());
1325         }
1326
1327  DONE_GITWEB:
1328         1;
1329 }
1330
1331 run();
1332
1333 if (defined caller) {
1334         # wrapped in a subroutine processing requests,
1335         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1336         return;
1337 } else {
1338         # pure CGI script, serving single request
1339         exit;
1340 }
1341
1342 ## ======================================================================
1343 ## action links
1344
1345 # possible values of extra options
1346 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1347 # -replay => 1      - start from a current view (replay with modifications)
1348 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1349 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1350 sub href {
1351         my %params = @_;
1352         # default is to use -absolute url() i.e. $my_uri
1353         my $href = $params{-full} ? $my_url : $my_uri;
1354
1355         # implicit -replay, must be first of implicit params
1356         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1357
1358         $params{'project'} = $project unless exists $params{'project'};
1359
1360         if ($params{-replay}) {
1361                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1362                         if (!exists $params{$name}) {
1363                                 $params{$name} = $input_params{$name};
1364                         }
1365                 }
1366         }
1367
1368         my $use_pathinfo = gitweb_check_feature('pathinfo');
1369         if (defined $params{'project'} &&
1370             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1371                 # try to put as many parameters as possible in PATH_INFO:
1372                 #   - project name
1373                 #   - action
1374                 #   - hash_parent or hash_parent_base:/file_parent
1375                 #   - hash or hash_base:/filename
1376                 #   - the snapshot_format as an appropriate suffix
1377
1378                 # When the script is the root DirectoryIndex for the domain,
1379                 # $href here would be something like http://gitweb.example.com/
1380                 # Thus, we strip any trailing / from $href, to spare us double
1381                 # slashes in the final URL
1382                 $href =~ s,/$,,;
1383
1384                 # Then add the project name, if present
1385                 $href .= "/".esc_path_info($params{'project'});
1386                 delete $params{'project'};
1387
1388                 # since we destructively absorb parameters, we keep this
1389                 # boolean that remembers if we're handling a snapshot
1390                 my $is_snapshot = $params{'action'} eq 'snapshot';
1391
1392                 # Summary just uses the project path URL, any other action is
1393                 # added to the URL
1394                 if (defined $params{'action'}) {
1395                         $href .= "/".esc_path_info($params{'action'})
1396                                 unless $params{'action'} eq 'summary';
1397                         delete $params{'action'};
1398                 }
1399
1400                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1401                 # stripping nonexistent or useless pieces
1402                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1403                         || $params{'hash_parent'} || $params{'hash'});
1404                 if (defined $params{'hash_base'}) {
1405                         if (defined $params{'hash_parent_base'}) {
1406                                 $href .= esc_path_info($params{'hash_parent_base'});
1407                                 # skip the file_parent if it's the same as the file_name
1408                                 if (defined $params{'file_parent'}) {
1409                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1410                                                 delete $params{'file_parent'};
1411                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1412                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1413                                                 delete $params{'file_parent'};
1414                                         }
1415                                 }
1416                                 $href .= "..";
1417                                 delete $params{'hash_parent'};
1418                                 delete $params{'hash_parent_base'};
1419                         } elsif (defined $params{'hash_parent'}) {
1420                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1421                                 delete $params{'hash_parent'};
1422                         }
1423
1424                         $href .= esc_path_info($params{'hash_base'});
1425                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1426                                 $href .= ":/".esc_path_info($params{'file_name'});
1427                                 delete $params{'file_name'};
1428                         }
1429                         delete $params{'hash'};
1430                         delete $params{'hash_base'};
1431                 } elsif (defined $params{'hash'}) {
1432                         $href .= esc_path_info($params{'hash'});
1433                         delete $params{'hash'};
1434                 }
1435
1436                 # If the action was a snapshot, we can absorb the
1437                 # snapshot_format parameter too
1438                 if ($is_snapshot) {
1439                         my $fmt = $params{'snapshot_format'};
1440                         # snapshot_format should always be defined when href()
1441                         # is called, but just in case some code forgets, we
1442                         # fall back to the default
1443                         $fmt ||= $snapshot_fmts[0];
1444                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1445                         delete $params{'snapshot_format'};
1446                 }
1447         }
1448
1449         # now encode the parameters explicitly
1450         my @result = ();
1451         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1452                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1453                 if (defined $params{$name}) {
1454                         if (ref($params{$name}) eq "ARRAY") {
1455                                 foreach my $par (@{$params{$name}}) {
1456                                         push @result, $symbol . "=" . esc_param($par);
1457                                 }
1458                         } else {
1459                                 push @result, $symbol . "=" . esc_param($params{$name});
1460                         }
1461                 }
1462         }
1463         $href .= "?" . join(';', @result) if scalar @result;
1464
1465         # final transformation: trailing spaces must be escaped (URI-encoded)
1466         $href =~ s/(\s+)$/CGI::escape($1)/e;
1467
1468         if ($params{-anchor}) {
1469                 $href .= "#".esc_param($params{-anchor});
1470         }
1471
1472         return $href;
1473 }
1474
1475
1476 ## ======================================================================
1477 ## validation, quoting/unquoting and escaping
1478
1479 sub is_valid_action {
1480         my $input = shift;
1481         return undef unless exists $actions{$input};
1482         return 1;
1483 }
1484
1485 sub is_valid_project {
1486         my $input = shift;
1487
1488         return unless defined $input;
1489         if (!is_valid_pathname($input) ||
1490                 !(-d "$projectroot/$input") ||
1491                 !check_export_ok("$projectroot/$input") ||
1492                 ($strict_export && !project_in_list($input))) {
1493                 return undef;
1494         } else {
1495                 return 1;
1496         }
1497 }
1498
1499 sub is_valid_pathname {
1500         my $input = shift;
1501
1502         return undef unless defined $input;
1503         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1504         # at the beginning, at the end, and between slashes.
1505         # also this catches doubled slashes
1506         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1507                 return undef;
1508         }
1509         # no null characters
1510         if ($input =~ m!\0!) {
1511                 return undef;
1512         }
1513         return 1;
1514 }
1515
1516 sub is_valid_ref_format {
1517         my $input = shift;
1518
1519         return undef unless defined $input;
1520         # restrictions on ref name according to git-check-ref-format
1521         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1522                 return undef;
1523         }
1524         return 1;
1525 }
1526
1527 sub is_valid_refname {
1528         my $input = shift;
1529
1530         return undef unless defined $input;
1531         # textual hashes are O.K.
1532         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1533                 return 1;
1534         }
1535         # it must be correct pathname
1536         is_valid_pathname($input) or return undef;
1537         # check git-check-ref-format restrictions
1538         is_valid_ref_format($input) or return undef;
1539         return 1;
1540 }
1541
1542 # decode sequences of octets in utf8 into Perl's internal form,
1543 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1544 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1545 sub to_utf8 {
1546         my $str = shift;
1547         return undef unless defined $str;
1548
1549         if (utf8::is_utf8($str) || utf8::decode($str)) {
1550                 return $str;
1551         } else {
1552                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1553         }
1554 }
1555
1556 # quote unsafe chars, but keep the slash, even when it's not
1557 # correct, but quoted slashes look too horrible in bookmarks
1558 sub esc_param {
1559         my $str = shift;
1560         return undef unless defined $str;
1561         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1562         $str =~ s/ /\+/g;
1563         return $str;
1564 }
1565
1566 # the quoting rules for path_info fragment are slightly different
1567 sub esc_path_info {
1568         my $str = shift;
1569         return undef unless defined $str;
1570
1571         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1572         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1573
1574         return $str;
1575 }
1576
1577 # quote unsafe chars in whole URL, so some characters cannot be quoted
1578 sub esc_url {
1579         my $str = shift;
1580         return undef unless defined $str;
1581         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1582         $str =~ s/ /\+/g;
1583         return $str;
1584 }
1585
1586 # quote unsafe characters in HTML attributes
1587 sub esc_attr {
1588
1589         # for XHTML conformance escaping '"' to '&quot;' is not enough
1590         return esc_html(@_);
1591 }
1592
1593 # replace invalid utf8 character with SUBSTITUTION sequence
1594 sub esc_html {
1595         my $str = shift;
1596         my %opts = @_;
1597
1598         return undef unless defined $str;
1599
1600         $str = to_utf8($str);
1601         $str = $cgi->escapeHTML($str);
1602         if ($opts{'-nbsp'}) {
1603                 $str =~ s/ /&nbsp;/g;
1604         }
1605         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1606         return $str;
1607 }
1608
1609 # quote control characters and escape filename to HTML
1610 sub esc_path {
1611         my $str = shift;
1612         my %opts = @_;
1613
1614         return undef unless defined $str;
1615
1616         $str = to_utf8($str);
1617         $str = $cgi->escapeHTML($str);
1618         if ($opts{'-nbsp'}) {
1619                 $str =~ s/ /&nbsp;/g;
1620         }
1621         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1622         return $str;
1623 }
1624
1625 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1626 sub sanitize {
1627         my $str = shift;
1628
1629         return undef unless defined $str;
1630
1631         $str = to_utf8($str);
1632         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1633         return $str;
1634 }
1635
1636 # Make control characters "printable", using character escape codes (CEC)
1637 sub quot_cec {
1638         my $cntrl = shift;
1639         my %opts = @_;
1640         my %es = ( # character escape codes, aka escape sequences
1641                 "\t" => '\t',   # tab            (HT)
1642                 "\n" => '\n',   # line feed      (LF)
1643                 "\r" => '\r',   # carrige return (CR)
1644                 "\f" => '\f',   # form feed      (FF)
1645                 "\b" => '\b',   # backspace      (BS)
1646                 "\a" => '\a',   # alarm (bell)   (BEL)
1647                 "\e" => '\e',   # escape         (ESC)
1648                 "\013" => '\v', # vertical tab   (VT)
1649                 "\000" => '\0', # nul character  (NUL)
1650         );
1651         my $chr = ( (exists $es{$cntrl})
1652                     ? $es{$cntrl}
1653                     : sprintf('\%2x', ord($cntrl)) );
1654         if ($opts{-nohtml}) {
1655                 return $chr;
1656         } else {
1657                 return "<span class=\"cntrl\">$chr</span>";
1658         }
1659 }
1660
1661 # Alternatively use unicode control pictures codepoints,
1662 # Unicode "printable representation" (PR)
1663 sub quot_upr {
1664         my $cntrl = shift;
1665         my %opts = @_;
1666
1667         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1668         if ($opts{-nohtml}) {
1669                 return $chr;
1670         } else {
1671                 return "<span class=\"cntrl\">$chr</span>";
1672         }
1673 }
1674
1675 # git may return quoted and escaped filenames
1676 sub unquote {
1677         my $str = shift;
1678
1679         sub unq {
1680                 my $seq = shift;
1681                 my %es = ( # character escape codes, aka escape sequences
1682                         't' => "\t",   # tab            (HT, TAB)
1683                         'n' => "\n",   # newline        (NL)
1684                         'r' => "\r",   # return         (CR)
1685                         'f' => "\f",   # form feed      (FF)
1686                         'b' => "\b",   # backspace      (BS)
1687                         'a' => "\a",   # alarm (bell)   (BEL)
1688                         'e' => "\e",   # escape         (ESC)
1689                         'v' => "\013", # vertical tab   (VT)
1690                 );
1691
1692                 if ($seq =~ m/^[0-7]{1,3}$/) {
1693                         # octal char sequence
1694                         return chr(oct($seq));
1695                 } elsif (exists $es{$seq}) {
1696                         # C escape sequence, aka character escape code
1697                         return $es{$seq};
1698                 }
1699                 # quoted ordinary character
1700                 return $seq;
1701         }
1702
1703         if ($str =~ m/^"(.*)"$/) {
1704                 # needs unquoting
1705                 $str = $1;
1706                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1707         }
1708         return $str;
1709 }
1710
1711 # escape tabs (convert tabs to spaces)
1712 sub untabify {
1713         my $line = shift;
1714
1715         while ((my $pos = index($line, "\t")) != -1) {
1716                 if (my $count = (8 - ($pos % 8))) {
1717                         my $spaces = ' ' x $count;
1718                         $line =~ s/\t/$spaces/;
1719                 }
1720         }
1721
1722         return $line;
1723 }
1724
1725 sub project_in_list {
1726         my $project = shift;
1727         my @list = git_get_projects_list();
1728         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1729 }
1730
1731 ## ----------------------------------------------------------------------
1732 ## HTML aware string manipulation
1733
1734 # Try to chop given string on a word boundary between position
1735 # $len and $len+$add_len. If there is no word boundary there,
1736 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1737 # (marking chopped part) would be longer than given string.
1738 sub chop_str {
1739         my $str = shift;
1740         my $len = shift;
1741         my $add_len = shift || 10;
1742         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1743
1744         # Make sure perl knows it is utf8 encoded so we don't
1745         # cut in the middle of a utf8 multibyte char.
1746         $str = to_utf8($str);
1747
1748         # allow only $len chars, but don't cut a word if it would fit in $add_len
1749         # if it doesn't fit, cut it if it's still longer than the dots we would add
1750         # remove chopped character entities entirely
1751
1752         # when chopping in the middle, distribute $len into left and right part
1753         # return early if chopping wouldn't make string shorter
1754         if ($where eq 'center') {
1755                 return $str if ($len + 5 >= length($str)); # filler is length 5
1756                 $len = int($len/2);
1757         } else {
1758                 return $str if ($len + 4 >= length($str)); # filler is length 4
1759         }
1760
1761         # regexps: ending and beginning with word part up to $add_len
1762         my $endre = qr/.{$len}\w{0,$add_len}/;
1763         my $begre = qr/\w{0,$add_len}.{$len}/;
1764
1765         if ($where eq 'left') {
1766                 $str =~ m/^(.*?)($begre)$/;
1767                 my ($lead, $body) = ($1, $2);
1768                 if (length($lead) > 4) {
1769                         $lead = " ...";
1770                 }
1771                 return "$lead$body";
1772
1773         } elsif ($where eq 'center') {
1774                 $str =~ m/^($endre)(.*)$/;
1775                 my ($left, $str)  = ($1, $2);
1776                 $str =~ m/^(.*?)($begre)$/;
1777                 my ($mid, $right) = ($1, $2);
1778                 if (length($mid) > 5) {
1779                         $mid = " ... ";
1780                 }
1781                 return "$left$mid$right";
1782
1783         } else {
1784                 $str =~ m/^($endre)(.*)$/;
1785                 my $body = $1;
1786                 my $tail = $2;
1787                 if (length($tail) > 4) {
1788                         $tail = "... ";
1789                 }
1790                 return "$body$tail";
1791         }
1792 }
1793
1794 # pass-through email filter, obfuscating it when possible
1795 sub email_obfuscate {
1796         my ($str) = @_;
1797         if ($email) {
1798                 $str = $email->escape_html($str);
1799                 # Stock HTML::Email::Obfuscate version likes to produce
1800                 # invalid XHTML...
1801                 $str =~ s#<(/?)B>#<$1b>#g;
1802                 return $str;
1803         } else {
1804                 $str = esc_html($str);
1805                 $str =~ s/@/&#x40;/;
1806                 return $str;
1807         }
1808 }
1809
1810 # takes the same arguments as chop_str, but also wraps a <span> around the
1811 # result with a title attribute if it does get chopped. Additionally, the
1812 # string is HTML-escaped.
1813 sub chop_and_escape_str {
1814         my ($str) = @_;
1815
1816         my $chopped = chop_str(@_);
1817         $str = to_utf8($str);
1818         if ($chopped eq $str) {
1819                 return email_obfuscate($chopped);
1820         } else {
1821                 $str =~ s/[[:cntrl:]]/?/g;
1822                 return $cgi->span({-title=>$str}, email_obfuscate($chopped));
1823         }
1824 }
1825
1826 # Highlight selected fragments of string, using given CSS class,
1827 # and escape HTML.  It is assumed that fragments do not overlap.
1828 # Regions are passed as list of pairs (array references).
1829 #
1830 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1831 # '<span class="mark">foo</span>bar'
1832 sub esc_html_hl_regions {
1833         my ($str, $css_class, @sel) = @_;
1834         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1835         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1836         return esc_html($str, %opts) unless @sel;
1837
1838         my $out = '';
1839         my $pos = 0;
1840
1841         for my $s (@sel) {
1842                 my ($begin, $end) = @$s;
1843
1844                 # Don't create empty <span> elements.
1845                 next if $end <= $begin;
1846
1847                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1848                                        %opts);
1849
1850                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1851                         if ($begin - $pos > 0);
1852                 $out .= $cgi->span({-class => $css_class}, $escaped);
1853
1854                 $pos = $end;
1855         }
1856         $out .= esc_html(substr($str, $pos), %opts)
1857                 if ($pos < length($str));
1858
1859         return $out;
1860 }
1861
1862 # return positions of beginning and end of each match
1863 sub matchpos_list {
1864         my ($str, $regexp) = @_;
1865         return unless (defined $str && defined $regexp);
1866
1867         my @matches;
1868         while ($str =~ /$regexp/g) {
1869                 push @matches, [$-[0], $+[0]];
1870         }
1871         return @matches;
1872 }
1873
1874 # highlight match (if any), and escape HTML
1875 sub esc_html_match_hl {
1876         my ($str, $regexp) = @_;
1877         return esc_html($str) unless defined $regexp;
1878
1879         my @matches = matchpos_list($str, $regexp);
1880         return esc_html($str) unless @matches;
1881
1882         return esc_html_hl_regions($str, 'match', @matches);
1883 }
1884
1885
1886 # highlight match (if any) of shortened string, and escape HTML
1887 sub esc_html_match_hl_chopped {
1888         my ($str, $chopped, $regexp) = @_;
1889         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1890
1891         my @matches = matchpos_list($str, $regexp);
1892         return esc_html($chopped) unless @matches;
1893
1894         # filter matches so that we mark chopped string
1895         my $tail = "... "; # see chop_str
1896         unless ($chopped =~ s/\Q$tail\E$//) {
1897                 $tail = '';
1898         }
1899         my $chop_len = length($chopped);
1900         my $tail_len = length($tail);
1901         my @filtered;
1902
1903         for my $m (@matches) {
1904                 if ($m->[0] > $chop_len) {
1905                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1906                         last;
1907                 } elsif ($m->[1] > $chop_len) {
1908                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1909                         last;
1910                 }
1911                 push @filtered, $m;
1912         }
1913
1914         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1915 }
1916
1917 ## ----------------------------------------------------------------------
1918 ## functions returning short strings
1919
1920 # CSS class for given age value (in seconds)
1921 sub age_class {
1922         my $age = shift;
1923
1924         if (!defined $age) {
1925                 return "noage";
1926         } elsif ($age < 60*60*2) {
1927                 return "age0";
1928         } elsif ($age < 60*60*24*2) {
1929                 return "age1";
1930         } else {
1931                 return "age2";
1932         }
1933 }
1934
1935 # convert age in seconds to "nn units ago" string
1936 sub age_string {
1937         my $age = shift;
1938         my $age_str;
1939
1940         if ($age > 60*60*24*365*2) {
1941                 $age_str = (int $age/60/60/24/365);
1942                 $age_str .= " years ago";
1943         } elsif ($age > 60*60*24*(365/12)*2) {
1944                 $age_str = int $age/60/60/24/(365/12);
1945                 $age_str .= " months ago";
1946         } elsif ($age > 60*60*24*7*2) {
1947                 $age_str = int $age/60/60/24/7;
1948                 $age_str .= " weeks ago";
1949         } elsif ($age > 60*60*24*2) {
1950                 $age_str = int $age/60/60/24;
1951                 $age_str .= " days ago";
1952         } elsif ($age > 60*60*2) {
1953                 $age_str = int $age/60/60;
1954                 $age_str .= " hours ago";
1955         } elsif ($age > 60*2) {
1956                 $age_str = int $age/60;
1957                 $age_str .= " min ago";
1958         } elsif ($age > 2) {
1959                 $age_str = int $age;
1960                 $age_str .= " sec ago";
1961         } else {
1962                 $age_str .= " right now";
1963         }
1964         return $age_str;
1965 }
1966
1967 use constant {
1968         S_IFINVALID => 0030000,
1969         S_IFGITLINK => 0160000,
1970 };
1971
1972 # submodule/subproject, a commit object reference
1973 sub S_ISGITLINK {
1974         my $mode = shift;
1975
1976         return (($mode & S_IFMT) == S_IFGITLINK)
1977 }
1978
1979 # convert file mode in octal to symbolic file mode string
1980 sub mode_str {
1981         my $mode = oct shift;
1982
1983         if (S_ISGITLINK($mode)) {
1984                 return 'm---------';
1985         } elsif (S_ISDIR($mode & S_IFMT)) {
1986                 return 'drwxr-xr-x';
1987         } elsif (S_ISLNK($mode)) {
1988                 return 'lrwxrwxrwx';
1989         } elsif (S_ISREG($mode)) {
1990                 # git cares only about the executable bit
1991                 if ($mode & S_IXUSR) {
1992                         return '-rwxr-xr-x';
1993                 } else {
1994                         return '-rw-r--r--';
1995                 };
1996         } else {
1997                 return '----------';
1998         }
1999 }
2000
2001 # convert file mode in octal to file type string
2002 sub file_type {
2003         my $mode = shift;
2004
2005         if ($mode !~ m/^[0-7]+$/) {
2006                 return $mode;
2007         } else {
2008                 $mode = oct $mode;
2009         }
2010
2011         if (S_ISGITLINK($mode)) {
2012                 return "submodule";
2013         } elsif (S_ISDIR($mode & S_IFMT)) {
2014                 return "directory";
2015         } elsif (S_ISLNK($mode)) {
2016                 return "symlink";
2017         } elsif (S_ISREG($mode)) {
2018                 return "file";
2019         } else {
2020                 return "unknown";
2021         }
2022 }
2023
2024 # convert file mode in octal to file type description string
2025 sub file_type_long {
2026         my $mode = shift;
2027
2028         if ($mode !~ m/^[0-7]+$/) {
2029                 return $mode;
2030         } else {
2031                 $mode = oct $mode;
2032         }
2033
2034         if (S_ISGITLINK($mode)) {
2035                 return "submodule";
2036         } elsif (S_ISDIR($mode & S_IFMT)) {
2037                 return "directory";
2038         } elsif (S_ISLNK($mode)) {
2039                 return "symlink";
2040         } elsif (S_ISREG($mode)) {
2041                 if ($mode & S_IXUSR) {
2042                         return "executable";
2043                 } else {
2044                         return "file";
2045                 };
2046         } else {
2047                 return "unknown";
2048         }
2049 }
2050
2051
2052 ## ----------------------------------------------------------------------
2053 ## functions returning short HTML fragments, or transforming HTML fragments
2054 ## which don't belong to other sections
2055
2056 # format line of commit message.
2057 sub format_log_line_html {
2058         my $line = shift;
2059
2060         $line = esc_html($line, -nbsp=>1);
2061         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
2062                 $cgi->a({-href => href(action=>"object", hash=>$1),
2063                                         -class => "text"}, $1);
2064         }eg;
2065
2066         return $line;
2067 }
2068
2069 # format marker of refs pointing to given object
2070
2071 # the destination action is chosen based on object type and current context:
2072 # - for annotated tags, we choose the tag view unless it's the current view
2073 #   already, in which case we go to shortlog view
2074 # - for other refs, we keep the current view if we're in history, shortlog or
2075 #   log view, and select shortlog otherwise
2076 sub format_ref_marker {
2077         my ($refs, $id) = @_;
2078         my $markers = '';
2079
2080         if (defined $refs->{$id}) {
2081                 foreach my $ref (@{$refs->{$id}}) {
2082                         # this code exploits the fact that non-lightweight tags are the
2083                         # only indirect objects, and that they are the only objects for which
2084                         # we want to use tag instead of shortlog as action
2085                         my ($type, $name) = qw();
2086                         my $indirect = ($ref =~ s/\^\{\}$//);
2087                         # e.g. tags/v2.6.11 or heads/next
2088                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2089                                 $type = $1;
2090                                 $name = $2;
2091                         } else {
2092                                 $type = "ref";
2093                                 $name = $ref;
2094                         }
2095
2096                         my $class = $type;
2097                         $class .= " indirect" if $indirect;
2098
2099                         my $dest_action = "shortlog";
2100
2101                         if ($indirect) {
2102                                 $dest_action = "tag" unless $action eq "tag";
2103                         } elsif ($action =~ /^(history|(short)?log)$/) {
2104                                 $dest_action = $action;
2105                         }
2106
2107                         my $dest = "";
2108                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2109                         $dest .= $ref;
2110
2111                         my $link = $cgi->a({
2112                                 -href => href(
2113                                         action=>$dest_action,
2114                                         hash=>$dest
2115                                 )}, $name);
2116
2117                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2118                                 $link . "</span>";
2119                 }
2120         }
2121
2122         if ($markers) {
2123                 return ' <span class="refs">'. $markers . '</span>';
2124         } else {
2125                 return "";
2126         }
2127 }
2128
2129 # format, perhaps shortened and with markers, title line
2130 sub format_subject_html {
2131         my ($long, $short, $href, $extra) = @_;
2132         $extra = '' unless defined($extra);
2133
2134         if (length($short) < length($long)) {
2135                 $long =~ s/[[:cntrl:]]/?/g;
2136                 return $cgi->a({-href => $href, -class => "list subject",
2137                                 -title => to_utf8($long)},
2138                        esc_html($short)) . $extra;
2139         } else {
2140                 return $cgi->a({-href => $href, -class => "list subject"},
2141                        esc_html($long)) . $extra;
2142         }
2143 }
2144
2145 # Rather than recomputing the url for an email multiple times, we cache it
2146 # after the first hit. This gives a visible benefit in views where the avatar
2147 # for the same email is used repeatedly (e.g. shortlog).
2148 # The cache is shared by all avatar engines (currently gravatar only), which
2149 # are free to use it as preferred. Since only one avatar engine is used for any
2150 # given page, there's no risk for cache conflicts.
2151 our %avatar_cache = ();
2152
2153 # Compute the picon url for a given email, by using the picon search service over at
2154 # http://www.cs.indiana.edu/picons/search.html
2155 sub picon_url {
2156         my $email = lc shift;
2157         if (!$avatar_cache{$email}) {
2158                 my ($user, $domain) = split('@', $email);
2159                 $avatar_cache{$email} =
2160                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2161                         "$domain/$user/" .
2162                         "users+domains+unknown/up/single";
2163         }
2164         return $avatar_cache{$email};
2165 }
2166
2167 # Compute the gravatar url for a given email, if it's not in the cache already.
2168 # Gravatar stores only the part of the URL before the size, since that's the
2169 # one computationally more expensive. This also allows reuse of the cache for
2170 # different sizes (for this particular engine).
2171 sub gravatar_url {
2172         my $email = lc shift;
2173         my $size = shift;
2174         $avatar_cache{$email} ||=
2175                 "//www.gravatar.com/avatar/" .
2176                         Digest::MD5::md5_hex($email) . "?s=";
2177         return $avatar_cache{$email} . $size;
2178 }
2179
2180 # Insert an avatar for the given $email at the given $size if the feature
2181 # is enabled.
2182 sub git_get_avatar {
2183         my ($email, %opts) = @_;
2184         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2185         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2186         $opts{-size} ||= 'default';
2187         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2188         my $url = "";
2189         if ($git_avatar eq 'gravatar') {
2190                 $url = gravatar_url($email, $size);
2191         } elsif ($git_avatar eq 'picon') {
2192                 $url = picon_url($email);
2193         }
2194         # Other providers can be added by extending the if chain, defining $url
2195         # as needed. If no variant puts something in $url, we assume avatars
2196         # are completely disabled/unavailable.
2197         if ($url) {
2198                 return $pre_white .
2199                        "<img width=\"$size\" " .
2200                             "class=\"avatar\" " .
2201                             "src=\"".esc_url($url)."\" " .
2202                             "alt=\"\" " .
2203                        "/>" . $post_white;
2204         } else {
2205                 return "";
2206         }
2207 }
2208
2209 sub format_search_author {
2210         my ($author, $searchtype, $displaytext) = @_;
2211         my $have_search = gitweb_check_feature('search');
2212
2213         if ($have_search) {
2214                 my $performed = "";
2215                 if ($searchtype eq 'author') {
2216                         $performed = "authored";
2217                 } elsif ($searchtype eq 'committer') {
2218                         $performed = "committed";
2219                 }
2220
2221                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2222                                 searchtext=>$author,
2223                                 searchtype=>$searchtype), class=>"list",
2224                                 title=>"Search for commits $performed by $author"},
2225                                 $displaytext);
2226
2227         } else {
2228                 return $displaytext;
2229         }
2230 }
2231
2232 # format the author name of the given commit with the given tag
2233 # the author name is chopped and escaped according to the other
2234 # optional parameters (see chop_str).
2235 sub format_author_html {
2236         my $tag = shift;
2237         my $co = shift;
2238         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2239         return "<$tag class=\"author\">" .
2240                format_search_author($co->{'author_name'}, "author",
2241                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2242                        $author) .
2243                "</$tag>";
2244 }
2245
2246 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2247 sub format_git_diff_header_line {
2248         my $line = shift;
2249         my $diffinfo = shift;
2250         my ($from, $to) = @_;
2251
2252         if ($diffinfo->{'nparents'}) {
2253                 # combined diff
2254                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2255                 if ($to->{'href'}) {
2256                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2257                                          esc_path($to->{'file'}));
2258                 } else { # file was deleted (no href)
2259                         $line .= esc_path($to->{'file'});
2260                 }
2261         } else {
2262                 # "ordinary" diff
2263                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2264                 if ($from->{'href'}) {
2265                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2266                                          'a/' . esc_path($from->{'file'}));
2267                 } else { # file was added (no href)
2268                         $line .= 'a/' . esc_path($from->{'file'});
2269                 }
2270                 $line .= ' ';
2271                 if ($to->{'href'}) {
2272                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2273                                          'b/' . esc_path($to->{'file'}));
2274                 } else { # file was deleted
2275                         $line .= 'b/' . esc_path($to->{'file'});
2276                 }
2277         }
2278
2279         return "<div class=\"diff header\">$line</div>\n";
2280 }
2281
2282 # format extended diff header line, before patch itself
2283 sub format_extended_diff_header_line {
2284         my $line = shift;
2285         my $diffinfo = shift;
2286         my ($from, $to) = @_;
2287
2288         # match <path>
2289         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2290                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2291                                        esc_path($from->{'file'}));
2292         }
2293         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2294                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2295                                  esc_path($to->{'file'}));
2296         }
2297         # match single <mode>
2298         if ($line =~ m/\s(\d{6})$/) {
2299                 $line .= '<span class="info"> (' .
2300                          file_type_long($1) .
2301                          ')</span>';
2302         }
2303         # match <hash>
2304         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2305                 # can match only for combined diff
2306                 $line = 'index ';
2307                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2308                         if ($from->{'href'}[$i]) {
2309                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2310                                                   -class=>"hash"},
2311                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2312                         } else {
2313                                 $line .= '0' x 7;
2314                         }
2315                         # separator
2316                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2317                 }
2318                 $line .= '..';
2319                 if ($to->{'href'}) {
2320                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2321                                          substr($diffinfo->{'to_id'},0,7));
2322                 } else {
2323                         $line .= '0' x 7;
2324                 }
2325
2326         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2327                 # can match only for ordinary diff
2328                 my ($from_link, $to_link);
2329                 if ($from->{'href'}) {
2330                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2331                                              substr($diffinfo->{'from_id'},0,7));
2332                 } else {
2333                         $from_link = '0' x 7;
2334                 }
2335                 if ($to->{'href'}) {
2336                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2337                                            substr($diffinfo->{'to_id'},0,7));
2338                 } else {
2339                         $to_link = '0' x 7;
2340                 }
2341                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2342                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2343         }
2344
2345         return $line . "<br/>\n";
2346 }
2347
2348 # format from-file/to-file diff header
2349 sub format_diff_from_to_header {
2350         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2351         my $line;
2352         my $result = '';
2353
2354         $line = $from_line;
2355         #assert($line =~ m/^---/) if DEBUG;
2356         # no extra formatting for "^--- /dev/null"
2357         if (! $diffinfo->{'nparents'}) {
2358                 # ordinary (single parent) diff
2359                 if ($line =~ m!^--- "?a/!) {
2360                         if ($from->{'href'}) {
2361                                 $line = '--- a/' .
2362                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2363                                                 esc_path($from->{'file'}));
2364                         } else {
2365                                 $line = '--- a/' .
2366                                         esc_path($from->{'file'});
2367                         }
2368                 }
2369                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2370
2371         } else {
2372                 # combined diff (merge commit)
2373                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2374                         if ($from->{'href'}[$i]) {
2375                                 $line = '--- ' .
2376                                         $cgi->a({-href=>href(action=>"blobdiff",
2377                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2378                                                              hash_parent_base=>$parents[$i],
2379                                                              file_parent=>$from->{'file'}[$i],
2380                                                              hash=>$diffinfo->{'to_id'},
2381                                                              hash_base=>$hash,
2382                                                              file_name=>$to->{'file'}),
2383                                                  -class=>"path",
2384                                                  -title=>"diff" . ($i+1)},
2385                                                 $i+1) .
2386                                         '/' .
2387                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2388                                                 esc_path($from->{'file'}[$i]));
2389                         } else {
2390                                 $line = '--- /dev/null';
2391                         }
2392                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2393                 }
2394         }
2395
2396         $line = $to_line;
2397         #assert($line =~ m/^\+\+\+/) if DEBUG;
2398         # no extra formatting for "^+++ /dev/null"
2399         if ($line =~ m!^\+\+\+ "?b/!) {
2400                 if ($to->{'href'}) {
2401                         $line = '+++ b/' .
2402                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2403                                         esc_path($to->{'file'}));
2404                 } else {
2405                         $line = '+++ b/' .
2406                                 esc_path($to->{'file'});
2407                 }
2408         }
2409         $result .= qq!<div class="diff to_file">$line</div>\n!;
2410
2411         return $result;
2412 }
2413
2414 # create note for patch simplified by combined diff
2415 sub format_diff_cc_simplified {
2416         my ($diffinfo, @parents) = @_;
2417         my $result = '';
2418
2419         $result .= "<div class=\"diff header\">" .
2420                    "diff --cc ";
2421         if (!is_deleted($diffinfo)) {
2422                 $result .= $cgi->a({-href => href(action=>"blob",
2423                                                   hash_base=>$hash,
2424                                                   hash=>$diffinfo->{'to_id'},
2425                                                   file_name=>$diffinfo->{'to_file'}),
2426                                     -class => "path"},
2427                                    esc_path($diffinfo->{'to_file'}));
2428         } else {
2429                 $result .= esc_path($diffinfo->{'to_file'});
2430         }
2431         $result .= "</div>\n" . # class="diff header"
2432                    "<div class=\"diff nodifferences\">" .
2433                    "Simple merge" .
2434                    "</div>\n"; # class="diff nodifferences"
2435
2436         return $result;
2437 }
2438
2439 sub diff_line_class {
2440         my ($line, $from, $to) = @_;
2441
2442         # ordinary diff
2443         my $num_sign = 1;
2444         # combined diff
2445         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2446                 $num_sign = scalar @{$from->{'href'}};
2447         }
2448
2449         my @diff_line_classifier = (
2450                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2451                 { regexp => qr/^\\/,               class => "incomplete"  },
2452                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2453                 # classifier for context must come before classifier add/rem,
2454                 # or we would have to use more complicated regexp, for example
2455                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2456                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2457                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2458         );
2459         for my $clsfy (@diff_line_classifier) {
2460                 return $clsfy->{'class'}
2461                         if ($line =~ $clsfy->{'regexp'});
2462         }
2463
2464         # fallback
2465         return "";
2466 }
2467
2468 # assumes that $from and $to are defined and correctly filled,
2469 # and that $line holds a line of chunk header for unified diff
2470 sub format_unidiff_chunk_header {
2471         my ($line, $from, $to) = @_;
2472
2473         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2474                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2475
2476         $from_lines = 0 unless defined $from_lines;
2477         $to_lines   = 0 unless defined $to_lines;
2478
2479         if ($from->{'href'}) {
2480                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2481                                      -class=>"list"}, $from_text);
2482         }
2483         if ($to->{'href'}) {
2484                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2485                                      -class=>"list"}, $to_text);
2486         }
2487         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2488                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2489         return $line;
2490 }
2491
2492 # assumes that $from and $to are defined and correctly filled,
2493 # and that $line holds a line of chunk header for combined diff
2494 sub format_cc_diff_chunk_header {
2495         my ($line, $from, $to) = @_;
2496
2497         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2498         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2499
2500         @from_text = split(' ', $ranges);
2501         for (my $i = 0; $i < @from_text; ++$i) {
2502                 ($from_start[$i], $from_nlines[$i]) =
2503                         (split(',', substr($from_text[$i], 1)), 0);
2504         }
2505
2506         $to_text   = pop @from_text;
2507         $to_start  = pop @from_start;
2508         $to_nlines = pop @from_nlines;
2509
2510         $line = "<span class=\"chunk_info\">$prefix ";
2511         for (my $i = 0; $i < @from_text; ++$i) {
2512                 if ($from->{'href'}[$i]) {
2513                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2514                                           -class=>"list"}, $from_text[$i]);
2515                 } else {
2516                         $line .= $from_text[$i];
2517                 }
2518                 $line .= " ";
2519         }
2520         if ($to->{'href'}) {
2521                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2522                                   -class=>"list"}, $to_text);
2523         } else {
2524                 $line .= $to_text;
2525         }
2526         $line .= " $prefix</span>" .
2527                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2528         return $line;
2529 }
2530
2531 # process patch (diff) line (not to be used for diff headers),
2532 # returning HTML-formatted (but not wrapped) line.
2533 # If the line is passed as a reference, it is treated as HTML and not
2534 # esc_html()'ed.
2535 sub format_diff_line {
2536         my ($line, $diff_class, $from, $to) = @_;
2537
2538         if (ref($line)) {
2539                 $line = $$line;
2540         } else {
2541                 chomp $line;
2542                 $line = untabify($line);
2543
2544                 if ($from && $to && $line =~ m/^\@{2} /) {
2545                         $line = format_unidiff_chunk_header($line, $from, $to);
2546                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2547                         $line = format_cc_diff_chunk_header($line, $from, $to);
2548                 } else {
2549                         $line = esc_html($line, -nbsp=>1);
2550                 }
2551         }
2552
2553         my $diff_classes = "diff";
2554         $diff_classes .= " $diff_class" if ($diff_class);
2555         $line = "<div class=\"$diff_classes\">$line</div>\n";
2556
2557         return $line;
2558 }
2559
2560 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2561 # linked.  Pass the hash of the tree/commit to snapshot.
2562 sub format_snapshot_links {
2563         my ($hash) = @_;
2564         my $num_fmts = @snapshot_fmts;
2565         if ($num_fmts > 1) {
2566                 # A parenthesized list of links bearing format names.
2567                 # e.g. "snapshot (_tar.gz_ _zip_)"
2568                 return "snapshot (" . join(' ', map
2569                         $cgi->a({
2570                                 -href => href(
2571                                         action=>"snapshot",
2572                                         hash=>$hash,
2573                                         snapshot_format=>$_
2574                                 )
2575                         }, $known_snapshot_formats{$_}{'display'})
2576                 , @snapshot_fmts) . ")";
2577         } elsif ($num_fmts == 1) {
2578                 # A single "snapshot" link whose tooltip bears the format name.
2579                 # i.e. "_snapshot_"
2580                 my ($fmt) = @snapshot_fmts;
2581                 return
2582                         $cgi->a({
2583                                 -href => href(
2584                                         action=>"snapshot",
2585                                         hash=>$hash,
2586                                         snapshot_format=>$fmt
2587                                 ),
2588                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2589                         }, "snapshot");
2590         } else { # $num_fmts == 0
2591                 return undef;
2592         }
2593 }
2594
2595 ## ......................................................................
2596 ## functions returning values to be passed, perhaps after some
2597 ## transformation, to other functions; e.g. returning arguments to href()
2598
2599 # returns hash to be passed to href to generate gitweb URL
2600 # in -title key it returns description of link
2601 sub get_feed_info {
2602         my $format = shift || 'Atom';
2603         my %res = (action => lc($format));
2604         my $matched_ref = 0;
2605
2606         # feed links are possible only for project views
2607         return unless (defined $project);
2608         # some views should link to OPML, or to generic project feed,
2609         # or don't have specific feed yet (so they should use generic)
2610         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2611
2612         my $branch = undef;
2613         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2614         # (fullname) to differentiate from tag links; this also makes
2615         # possible to detect branch links
2616         for my $ref (get_branch_refs()) {
2617                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2618                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2619                         $branch = $1;
2620                         $matched_ref = $ref;
2621                         last;
2622                 }
2623         }
2624         # find log type for feed description (title)
2625         my $type = 'log';
2626         if (defined $file_name) {
2627                 $type  = "history of $file_name";
2628                 $type .= "/" if ($action eq 'tree');
2629                 $type .= " on '$branch'" if (defined $branch);
2630         } else {
2631                 $type = "log of $branch" if (defined $branch);
2632         }
2633
2634         $res{-title} = $type;
2635         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2636         $res{'file_name'} = $file_name;
2637
2638         return %res;
2639 }
2640
2641 ## ----------------------------------------------------------------------
2642 ## git utility subroutines, invoking git commands
2643
2644 # returns path to the core git executable and the --git-dir parameter as list
2645 sub git_cmd {
2646         $number_of_git_cmds++;
2647         return $GIT, '--git-dir='.$git_dir;
2648 }
2649
2650 # quote the given arguments for passing them to the shell
2651 # quote_command("command", "arg 1", "arg with ' and ! characters")
2652 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2653 # Try to avoid using this function wherever possible.
2654 sub quote_command {
2655         return join(' ',
2656                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2657 }
2658
2659 # get HEAD ref of given project as hash
2660 sub git_get_head_hash {
2661         return git_get_full_hash(shift, 'HEAD');
2662 }
2663
2664 sub git_get_full_hash {
2665         return git_get_hash(@_);
2666 }
2667
2668 sub git_get_short_hash {
2669         return git_get_hash(@_, '--short=7');
2670 }
2671
2672 sub git_get_hash {
2673         my ($project, $hash, @options) = @_;
2674         my $o_git_dir = $git_dir;
2675         my $retval = undef;
2676         $git_dir = "$projectroot/$project";
2677         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2678             '--verify', '-q', @options, $hash) {
2679                 $retval = <$fd>;
2680                 chomp $retval if defined $retval;
2681                 close $fd;
2682         }
2683         if (defined $o_git_dir) {
2684                 $git_dir = $o_git_dir;
2685         }
2686         return $retval;
2687 }
2688
2689 # get type of given object
2690 sub git_get_type {
2691         my $hash = shift;
2692
2693         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2694         my $type = <$fd>;
2695         close $fd or return;
2696         chomp $type;
2697         return $type;
2698 }
2699
2700 # repository configuration
2701 our $config_file = '';
2702 our %config;
2703
2704 # store multiple values for single key as anonymous array reference
2705 # single values stored directly in the hash, not as [ <value> ]
2706 sub hash_set_multi {
2707         my ($hash, $key, $value) = @_;
2708
2709         if (!exists $hash->{$key}) {
2710                 $hash->{$key} = $value;
2711         } elsif (!ref $hash->{$key}) {
2712                 $hash->{$key} = [ $hash->{$key}, $value ];
2713         } else {
2714                 push @{$hash->{$key}}, $value;
2715         }
2716 }
2717
2718 # return hash of git project configuration
2719 # optionally limited to some section, e.g. 'gitweb'
2720 sub git_parse_project_config {
2721         my $section_regexp = shift;
2722         my %config;
2723
2724         local $/ = "\0";
2725
2726         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2727                 or return;
2728
2729         while (my $keyval = <$fh>) {
2730                 chomp $keyval;
2731                 my ($key, $value) = split(/\n/, $keyval, 2);
2732
2733                 hash_set_multi(\%config, $key, $value)
2734                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2735         }
2736         close $fh;
2737
2738         return %config;
2739 }
2740
2741 # convert config value to boolean: 'true' or 'false'
2742 # no value, number > 0, 'true' and 'yes' values are true
2743 # rest of values are treated as false (never as error)
2744 sub config_to_bool {
2745         my $val = shift;
2746
2747         return 1 if !defined $val;             # section.key
2748
2749         # strip leading and trailing whitespace
2750         $val =~ s/^\s+//;
2751         $val =~ s/\s+$//;
2752
2753         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2754                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2755 }
2756
2757 # convert config value to simple decimal number
2758 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2759 # to be multiplied by 1024, 1048576, or 1073741824
2760 sub config_to_int {
2761         my $val = shift;
2762
2763         # strip leading and trailing whitespace
2764         $val =~ s/^\s+//;
2765         $val =~ s/\s+$//;
2766
2767         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2768                 $unit = lc($unit);
2769                 # unknown unit is treated as 1
2770                 return $num * ($unit eq 'g' ? 1073741824 :
2771                                $unit eq 'm' ?    1048576 :
2772                                $unit eq 'k' ?       1024 : 1);
2773         }
2774         return $val;
2775 }
2776
2777 # convert config value to array reference, if needed
2778 sub config_to_multi {
2779         my $val = shift;
2780
2781         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2782 }
2783
2784 sub git_get_project_config {
2785         my ($key, $type) = @_;
2786
2787         return unless defined $git_dir;
2788
2789         # key sanity check
2790         return unless ($key);
2791         # only subsection, if exists, is case sensitive,
2792         # and not lowercased by 'git config -z -l'
2793         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2794                 $lo =~ s/_//g;
2795                 $key = join(".", lc($hi), $mi, lc($lo));
2796                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2797         } else {
2798                 $key = lc($key);
2799                 $key =~ s/_//g;
2800                 return if ($key =~ /\W/);
2801         }
2802         $key =~ s/^gitweb\.//;
2803
2804         # type sanity check
2805         if (defined $type) {
2806                 $type =~ s/^--//;
2807                 $type = undef
2808                         unless ($type eq 'bool' || $type eq 'int');
2809         }
2810
2811         # get config
2812         if (!defined $config_file ||
2813             $config_file ne "$git_dir/config") {
2814                 %config = git_parse_project_config('gitweb');
2815                 $config_file = "$git_dir/config";
2816         }
2817
2818         # check if config variable (key) exists
2819         return unless exists $config{"gitweb.$key"};
2820
2821         # ensure given type
2822         if (!defined $type) {
2823                 return $config{"gitweb.$key"};
2824         } elsif ($type eq 'bool') {
2825                 # backward compatibility: 'git config --bool' returns true/false
2826                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2827         } elsif ($type eq 'int') {
2828                 return config_to_int($config{"gitweb.$key"});
2829         }
2830         return $config{"gitweb.$key"};
2831 }
2832
2833 # get hash of given path at given ref
2834 sub git_get_hash_by_path {
2835         my $base = shift;
2836         my $path = shift || return undef;
2837         my $type = shift;
2838
2839         $path =~ s,/+$,,;
2840
2841         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2842                 or die_error(500, "Open git-ls-tree failed");
2843         my $line = <$fd>;
2844         close $fd or return undef;
2845
2846         if (!defined $line) {
2847                 # there is no tree or hash given by $path at $base
2848                 return undef;
2849         }
2850
2851         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2852         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2853         if (defined $type && $type ne $2) {
2854                 # type doesn't match
2855                 return undef;
2856         }
2857         return $3;
2858 }
2859
2860 # get path of entry with given hash at given tree-ish (ref)
2861 # used to get 'from' filename for combined diff (merge commit) for renames
2862 sub git_get_path_by_hash {
2863         my $base = shift || return;
2864         my $hash = shift || return;
2865
2866         local $/ = "\0";
2867
2868         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2869                 or return undef;
2870         while (my $line = <$fd>) {
2871                 chomp $line;
2872
2873                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2874                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2875                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2876                         close $fd;
2877                         return $1;
2878                 }
2879         }
2880         close $fd;
2881         return undef;
2882 }
2883
2884 ## ......................................................................
2885 ## git utility functions, directly accessing git repository
2886
2887 # get the value of config variable either from file named as the variable
2888 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2889 # configuration variable in the repository config file.
2890 sub git_get_file_or_project_config {
2891         my ($path, $name) = @_;
2892
2893         $git_dir = "$projectroot/$path";
2894         open my $fd, '<', "$git_dir/$name"
2895                 or return git_get_project_config($name);
2896         my $conf = <$fd>;
2897         close $fd;
2898         if (defined $conf) {
2899                 chomp $conf;
2900         }
2901         return $conf;
2902 }
2903
2904 sub git_get_project_description {
2905         my $path = shift;
2906         return git_get_file_or_project_config($path, 'description');
2907 }
2908
2909 sub git_get_project_category {
2910         my $path = shift;
2911         return git_get_file_or_project_config($path, 'category');
2912 }
2913
2914
2915 # supported formats:
2916 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2917 #   - if its contents is a number, use it as tag weight,
2918 #   - otherwise add a tag with weight 1
2919 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2920 #   the same value multiple times increases tag weight
2921 # * `gitweb.ctag' multi-valued repo config variable
2922 sub git_get_project_ctags {
2923         my $project = shift;
2924         my $ctags = {};
2925
2926         $git_dir = "$projectroot/$project";
2927         if (opendir my $dh, "$git_dir/ctags") {
2928                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2929                 foreach my $tagfile (@files) {
2930                         open my $ct, '<', $tagfile
2931                                 or next;
2932                         my $val = <$ct>;
2933                         chomp $val if $val;
2934                         close $ct;
2935
2936                         (my $ctag = $tagfile) =~ s#.*/##;
2937                         if ($val =~ /^\d+$/) {
2938                                 $ctags->{$ctag} = $val;
2939                         } else {
2940                                 $ctags->{$ctag} = 1;
2941                         }
2942                 }
2943                 closedir $dh;
2944
2945         } elsif (open my $fh, '<', "$git_dir/ctags") {
2946                 while (my $line = <$fh>) {
2947                         chomp $line;
2948                         $ctags->{$line}++ if $line;
2949                 }
2950                 close $fh;
2951
2952         } else {
2953                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2954                 foreach my $tag (@$taglist) {
2955                         $ctags->{$tag}++;
2956                 }
2957         }
2958
2959         return $ctags;
2960 }
2961
2962 # return hash, where keys are content tags ('ctags'),
2963 # and values are sum of weights of given tag in every project
2964 sub git_gather_all_ctags {
2965         my $projects = shift;
2966         my $ctags = {};
2967
2968         foreach my $p (@$projects) {
2969                 foreach my $ct (keys %{$p->{'ctags'}}) {
2970                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2971                 }
2972         }
2973
2974         return $ctags;
2975 }
2976
2977 sub git_populate_project_tagcloud {
2978         my $ctags = shift;
2979
2980         # First, merge different-cased tags; tags vote on casing
2981         my %ctags_lc;
2982         foreach (keys %$ctags) {
2983                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2984                 if (not $ctags_lc{lc $_}->{topcount}
2985                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2986                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2987                         $ctags_lc{lc $_}->{topname} = $_;
2988                 }
2989         }
2990
2991         my $cloud;
2992         my $matched = $input_params{'ctag'};
2993         if (eval { require HTML::TagCloud; 1; }) {
2994                 $cloud = HTML::TagCloud->new;
2995                 foreach my $ctag (sort keys %ctags_lc) {
2996                         # Pad the title with spaces so that the cloud looks
2997                         # less crammed.
2998                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2999                         $title =~ s/ /&nbsp;/g;
3000                         $title =~ s/^/&nbsp;/g;
3001                         $title =~ s/$/&nbsp;/g;
3002                         if (defined $matched && $matched eq $ctag) {
3003                                 $title = qq(<span class="match">$title</span>);
3004                         }
3005                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3006                                     $ctags_lc{$ctag}->{count});
3007                 }
3008         } else {
3009                 $cloud = {};
3010                 foreach my $ctag (keys %ctags_lc) {
3011                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3012                         if (defined $matched && $matched eq $ctag) {
3013                                 $title = qq(<span class="match">$title</span>);
3014                         }
3015                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3016                         $cloud->{$ctag}{ctag} =
3017                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3018                 }
3019         }
3020         return $cloud;
3021 }
3022
3023 sub git_show_project_tagcloud {
3024         my ($cloud, $count) = @_;
3025         if (ref $cloud eq 'HTML::TagCloud') {
3026                 return $cloud->html_and_css($count);
3027         } else {
3028                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3029                 return
3030                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3031                         join (', ', map {
3032                                 $cloud->{$_}->{'ctag'}
3033                         } splice(@tags, 0, $count)) .
3034                         '</div>';
3035         }
3036 }
3037
3038 sub git_get_project_url_list {
3039         my $path = shift;
3040
3041         $git_dir = "$projectroot/$path";
3042         open my $fd, '<', "$git_dir/cloneurl"
3043                 or return wantarray ?
3044                 @{ config_to_multi(git_get_project_config('url')) } :
3045                    config_to_multi(git_get_project_config('url'));
3046         my @git_project_url_list = map { chomp; $_ } <$fd>;
3047         close $fd;
3048
3049         return wantarray ? @git_project_url_list : \@git_project_url_list;
3050 }
3051
3052 sub git_get_projects_list {
3053         my $filter = shift || '';
3054         my $paranoid = shift;
3055         my @list;
3056
3057         if (-d $projects_list) {
3058                 # search in directory
3059                 my $dir = $projects_list;
3060                 # remove the trailing "/"
3061                 $dir =~ s!/+$!!;
3062                 my $pfxlen = length("$dir");
3063                 my $pfxdepth = ($dir =~ tr!/!!);
3064                 # when filtering, search only given subdirectory
3065                 if ($filter && !$paranoid) {
3066                         $dir .= "/$filter";
3067                         $dir =~ s!/+$!!;
3068                 }
3069
3070                 File::Find::find({
3071                         follow_fast => 1, # follow symbolic links
3072                         follow_skip => 2, # ignore duplicates
3073                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3074                         wanted => sub {
3075                                 # global variables
3076                                 our $project_maxdepth;
3077                                 our $projectroot;
3078                                 # skip project-list toplevel, if we get it.
3079                                 return if (m!^[/.]$!);
3080                                 # only directories can be git repositories
3081                                 return unless (-d $_);
3082                                 # don't traverse too deep (Find is super slow on os x)
3083                                 # $project_maxdepth excludes depth of $projectroot
3084                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3085                                         $File::Find::prune = 1;
3086                                         return;
3087                                 }
3088
3089                                 my $path = substr($File::Find::name, $pfxlen + 1);
3090                                 # paranoidly only filter here
3091                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3092                                         next;
3093                                 }
3094                                 # we check related file in $projectroot
3095                                 if (check_export_ok("$projectroot/$path")) {
3096                                         push @list, { path => $path };
3097                                         $File::Find::prune = 1;
3098                                 }
3099                         },
3100                 }, "$dir");
3101
3102         } elsif (-f $projects_list) {
3103                 # read from file(url-encoded):
3104                 # 'git%2Fgit.git Linus+Torvalds'
3105                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3106                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3107                 open my $fd, '<', $projects_list or return;
3108         PROJECT:
3109                 while (my $line = <$fd>) {
3110                         chomp $line;
3111                         my ($path, $owner) = split ' ', $line;
3112                         $path = unescape($path);
3113                         $owner = unescape($owner);
3114                         if (!defined $path) {
3115                                 next;
3116                         }
3117                         # if $filter is rpovided, check if $path begins with $filter
3118                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3119                                 next;
3120                         }
3121                         if (check_export_ok("$projectroot/$path")) {
3122                                 my $pr = {
3123                                         path => $path
3124                                 };
3125                                 if ($owner) {
3126                                         $pr->{'owner'} = to_utf8($owner);
3127                                 }
3128                                 push @list, $pr;
3129                         }
3130                 }
3131                 close $fd;
3132         }
3133         return @list;
3134 }
3135
3136 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3137 # as side effects it sets 'forks' field to list of forks for forked projects
3138 sub filter_forks_from_projects_list {
3139         my $projects = shift;
3140
3141         my %trie; # prefix tree of directories (path components)
3142         # generate trie out of those directories that might contain forks
3143         foreach my $pr (@$projects) {
3144                 my $path = $pr->{'path'};
3145                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3146                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3147                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3148                 next unless (-d "$projectroot/$path"); # containing directory exists
3149                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3150
3151                 # add to trie
3152                 my @dirs = split('/', $path);
3153                 # walk the trie, until either runs out of components or out of trie
3154                 my $ref = \%trie;
3155                 while (scalar @dirs &&
3156                        exists($ref->{$dirs[0]})) {
3157                         $ref = $ref->{shift @dirs};
3158                 }
3159                 # create rest of trie structure from rest of components
3160                 foreach my $dir (@dirs) {
3161                         $ref = $ref->{$dir} = {};
3162                 }
3163                 # create end marker, store $pr as a data
3164                 $ref->{''} = $pr if (!exists $ref->{''});
3165         }
3166
3167         # filter out forks, by finding shortest prefix match for paths
3168         my @filtered;
3169  PROJECT:
3170         foreach my $pr (@$projects) {
3171                 # trie lookup
3172                 my $ref = \%trie;
3173         DIR:
3174                 foreach my $dir (split('/', $pr->{'path'})) {
3175                         if (exists $ref->{''}) {
3176                                 # found [shortest] prefix, is a fork - skip it
3177                                 push @{$ref->{''}{'forks'}}, $pr;
3178                                 next PROJECT;
3179                         }
3180                         if (!exists $ref->{$dir}) {
3181                                 # not in trie, cannot have prefix, not a fork
3182                                 push @filtered, $pr;
3183                                 next PROJECT;
3184                         }
3185                         # If the dir is there, we just walk one step down the trie.
3186                         $ref = $ref->{$dir};
3187                 }
3188                 # we ran out of trie
3189                 # (shouldn't happen: it's either no match, or end marker)
3190                 push @filtered, $pr;
3191         }
3192
3193         return @filtered;
3194 }
3195
3196 # note: fill_project_list_info must be run first,
3197 # for 'descr_long' and 'ctags' to be filled
3198 sub search_projects_list {
3199         my ($projlist, %opts) = @_;
3200         my $tagfilter  = $opts{'tagfilter'};
3201         my $search_re = $opts{'search_regexp'};
3202
3203         return @$projlist
3204                 unless ($tagfilter || $search_re);
3205
3206         # searching projects require filling to be run before it;
3207         fill_project_list_info($projlist,
3208                                $tagfilter  ? 'ctags' : (),
3209                                $search_re ? ('path', 'descr') : ());
3210         my @projects;
3211  PROJECT:
3212         foreach my $pr (@$projlist) {
3213
3214                 if ($tagfilter) {
3215                         next unless ref($pr->{'ctags'}) eq 'HASH';
3216                         next unless
3217                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3218                 }
3219
3220                 if ($search_re) {
3221                         next unless
3222                                 $pr->{'path'} =~ /$search_re/ ||
3223                                 $pr->{'descr_long'} =~ /$search_re/;
3224                 }
3225
3226                 push @projects, $pr;
3227         }
3228
3229         return @projects;
3230 }
3231
3232 our $gitweb_project_owner = undef;
3233 sub git_get_project_list_from_file {
3234
3235         return if (defined $gitweb_project_owner);
3236
3237         $gitweb_project_owner = {};
3238         # read from file (url-encoded):
3239         # 'git%2Fgit.git Linus+Torvalds'
3240         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3241         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3242         if (-f $projects_list) {
3243                 open(my $fd, '<', $projects_list);
3244                 while (my $line = <$fd>) {
3245                         chomp $line;
3246                         my ($pr, $ow) = split ' ', $line;
3247                         $pr = unescape($pr);
3248                         $ow = unescape($ow);
3249                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3250                 }
3251                 close $fd;
3252         }
3253 }
3254
3255 sub git_get_project_owner {
3256         my $project = shift;
3257         my $owner;
3258
3259         return undef unless $project;
3260         $git_dir = "$projectroot/$project";
3261
3262         if (!defined $gitweb_project_owner) {
3263                 git_get_project_list_from_file();
3264         }
3265
3266         if (exists $gitweb_project_owner->{$project}) {
3267                 $owner = $gitweb_project_owner->{$project};
3268         }
3269         if (!defined $owner){
3270                 $owner = git_get_project_config('owner');
3271         }
3272         if (!defined $owner) {
3273                 $owner = get_file_owner("$git_dir");
3274         }
3275
3276         return $owner;
3277 }
3278
3279 sub git_get_last_activity {
3280         my ($path) = @_;
3281         my $fd;
3282
3283         $git_dir = "$projectroot/$path";
3284         open($fd, "-|", git_cmd(), 'for-each-ref',
3285              '--format=%(committer)',
3286              '--sort=-committerdate',
3287              '--count=1',
3288              map { "refs/$_" } get_branch_refs ()) or return;
3289         my $most_recent = <$fd>;
3290         close $fd or return;
3291         if (defined $most_recent &&
3292             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3293                 my $timestamp = $1;
3294                 my $age = time - $timestamp;
3295                 return ($age, age_string($age));
3296         }
3297         return (undef, undef);
3298 }
3299
3300 # Implementation note: when a single remote is wanted, we cannot use 'git
3301 # remote show -n' because that command always work (assuming it's a remote URL
3302 # if it's not defined), and we cannot use 'git remote show' because that would
3303 # try to make a network roundtrip. So the only way to find if that particular
3304 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3305 # and when we find what we want.
3306 sub git_get_remotes_list {
3307         my $wanted = shift;
3308         my %remotes = ();
3309
3310         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3311         return unless $fd;
3312         while (my $remote = <$fd>) {
3313                 chomp $remote;
3314                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3315                 next if $wanted and not $remote eq $wanted;
3316                 my ($url, $key) = ($1, $2);
3317
3318                 $remotes{$remote} ||= { 'heads' => () };
3319                 $remotes{$remote}{$key} = $url;
3320         }
3321         close $fd or return;
3322         return wantarray ? %remotes : \%remotes;
3323 }
3324
3325 # Takes a hash of remotes as first parameter and fills it by adding the
3326 # available remote heads for each of the indicated remotes.
3327 sub fill_remote_heads {
3328         my $remotes = shift;
3329         my @heads = map { "remotes/$_" } keys %$remotes;
3330         my @remoteheads = git_get_heads_list(undef, @heads);
3331         foreach my $remote (keys %$remotes) {
3332                 $remotes->{$remote}{'heads'} = [ grep {
3333                         $_->{'name'} =~ s!^$remote/!!
3334                         } @remoteheads ];
3335         }
3336 }
3337
3338 sub git_get_references {
3339         my $type = shift || "";
3340         my %refs;
3341         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3342         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3343         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3344                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3345                 or return;
3346
3347         while (my $line = <$fd>) {
3348                 chomp $line;
3349                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3350                         if (defined $refs{$1}) {
3351                                 push @{$refs{$1}}, $2;
3352                         } else {
3353                                 $refs{$1} = [ $2 ];
3354                         }
3355                 }
3356         }
3357         close $fd or return;
3358         return \%refs;
3359 }
3360
3361 sub git_get_rev_name_tags {
3362         my $hash = shift || return undef;
3363
3364         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3365                 or return;
3366         my $name_rev = <$fd>;
3367         close $fd;
3368
3369         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3370                 return $1;
3371         } else {
3372                 # catches also '$hash undefined' output
3373                 return undef;
3374         }
3375 }
3376
3377 ## ----------------------------------------------------------------------
3378 ## parse to hash functions
3379
3380 sub parse_date {
3381         my $epoch = shift;
3382         my $tz = shift || "-0000";
3383
3384         my %date;
3385         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3386         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3387         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3388         $date{'hour'} = $hour;
3389         $date{'minute'} = $min;
3390         $date{'mday'} = $mday;
3391         $date{'day'} = $days[$wday];
3392         $date{'month'} = $months[$mon];
3393         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3394                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3395         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3396                              $mday, $months[$mon], $hour ,$min;
3397         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3398                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3399
3400         my ($tz_sign, $tz_hour, $tz_min) =
3401                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3402         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3403         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3404         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3405         $date{'hour_local'} = $hour;
3406         $date{'minute_local'} = $min;
3407         $date{'tz_local'} = $tz;
3408         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3409                                   1900+$year, $mon+1, $mday,
3410                                   $hour, $min, $sec, $tz);
3411         return %date;
3412 }
3413
3414 sub parse_tag {
3415         my $tag_id = shift;
3416         my %tag;
3417         my @comment;
3418
3419         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3420         $tag{'id'} = $tag_id;
3421         while (my $line = <$fd>) {
3422                 chomp $line;
3423                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3424                         $tag{'object'} = $1;
3425                 } elsif ($line =~ m/^type (.+)$/) {
3426                         $tag{'type'} = $1;
3427                 } elsif ($line =~ m/^tag (.+)$/) {
3428                         $tag{'name'} = $1;
3429                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3430                         $tag{'author'} = $1;
3431                         $tag{'author_epoch'} = $2;
3432                         $tag{'author_tz'} = $3;
3433                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3434                                 $tag{'author_name'}  = $1;
3435                                 $tag{'author_email'} = $2;
3436                         } else {
3437                                 $tag{'author_name'} = $tag{'author'};
3438                         }
3439                 } elsif ($line =~ m/--BEGIN/) {
3440                         push @comment, $line;
3441                         last;
3442                 } elsif ($line eq "") {
3443                         last;
3444                 }
3445         }
3446         push @comment, <$fd>;
3447         $tag{'comment'} = \@comment;
3448         close $fd or return;
3449         if (!defined $tag{'name'}) {
3450                 return
3451         };
3452         return %tag
3453 }
3454
3455 sub parse_commit_text {
3456         my ($commit_text, $withparents) = @_;
3457         my @commit_lines = split '\n', $commit_text;
3458         my %co;
3459
3460         pop @commit_lines; # Remove '\0'
3461
3462         if (! @commit_lines) {
3463                 return;
3464         }
3465
3466         my $header = shift @commit_lines;
3467         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3468                 return;
3469         }
3470         ($co{'id'}, my @parents) = split ' ', $header;
3471         while (my $line = shift @commit_lines) {
3472                 last if $line eq "\n";
3473                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3474                         $co{'tree'} = $1;
3475                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3476                         push @parents, $1;
3477                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3478                         $co{'author'} = to_utf8($1);
3479                         $co{'author_epoch'} = $2;
3480                         $co{'author_tz'} = $3;
3481                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3482                                 $co{'author_name'}  = $1;
3483                                 $co{'author_email'} = $2;
3484                         } else {
3485                                 $co{'author_name'} = $co{'author'};
3486                         }
3487                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3488                         $co{'committer'} = to_utf8($1);
3489                         $co{'committer_epoch'} = $2;
3490                         $co{'committer_tz'} = $3;
3491                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3492                                 $co{'committer_name'}  = $1;
3493                                 $co{'committer_email'} = $2;
3494                         } else {
3495                                 $co{'committer_name'} = $co{'committer'};
3496                         }
3497                 }
3498         }
3499         if (!defined $co{'tree'}) {
3500                 return;
3501         };
3502         $co{'parents'} = \@parents;
3503         $co{'parent'} = $parents[0];
3504
3505         foreach my $title (@commit_lines) {
3506                 $title =~ s/^    //;
3507                 if ($title ne "") {
3508                         $co{'title'} = chop_str($title, 80, 5);
3509                         # remove leading stuff of merges to make the interesting part visible
3510                         if (length($title) > 50) {
3511                                 $title =~ s/^Automatic //;
3512                                 $title =~ s/^merge (of|with) /Merge ... /i;
3513                                 if (length($title) > 50) {
3514                                         $title =~ s/(http|rsync):\/\///;
3515                                 }
3516                                 if (length($title) > 50) {
3517                                         $title =~ s/(master|www|rsync)\.//;
3518                                 }
3519                                 if (length($title) > 50) {
3520                                         $title =~ s/kernel.org:?//;
3521                                 }
3522                                 if (length($title) > 50) {
3523                                         $title =~ s/\/pub\/scm//;
3524                                 }
3525                         }
3526                         $co{'title_short'} = chop_str($title, 50, 5);
3527                         last;
3528                 }
3529         }
3530         if (! defined $co{'title'} || $co{'title'} eq "") {
3531                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3532         }
3533         # remove added spaces
3534         foreach my $line (@commit_lines) {
3535                 $line =~ s/^    //;
3536         }
3537         $co{'comment'} = \@commit_lines;
3538
3539         my $age = time - $co{'committer_epoch'};
3540         $co{'age'} = $age;
3541         $co{'age_string'} = age_string($age);
3542         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3543         if ($age > 60*60*24*7*2) {
3544                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3545                 $co{'age_string_age'} = $co{'age_string'};
3546         } else {
3547                 $co{'age_string_date'} = $co{'age_string'};
3548                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3549         }
3550         return %co;
3551 }
3552
3553 sub parse_commit {
3554         my ($commit_id) = @_;
3555         my %co;
3556
3557         local $/ = "\0";
3558
3559         open my $fd, "-|", git_cmd(), "rev-list",
3560                 "--parents",
3561                 "--header",
3562                 "--max-count=1",
3563                 $commit_id,
3564                 "--",
3565                 or die_error(500, "Open git-rev-list failed");
3566         %co = parse_commit_text(<$fd>, 1);
3567         close $fd;
3568
3569         return %co;
3570 }
3571
3572 sub parse_commits {
3573         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3574         my @cos;
3575
3576         $maxcount ||= 1;
3577         $skip ||= 0;
3578
3579         local $/ = "\0";
3580
3581         open my $fd, "-|", git_cmd(), "rev-list",
3582                 "--header",
3583                 @args,
3584                 ("--max-count=" . $maxcount),
3585                 ("--skip=" . $skip),
3586                 @extra_options,
3587                 $commit_id,
3588                 "--",
3589                 ($filename ? ($filename) : ())
3590                 or die_error(500, "Open git-rev-list failed");
3591         while (my $line = <$fd>) {
3592                 my %co = parse_commit_text($line);
3593                 push @cos, \%co;
3594         }
3595         close $fd;
3596
3597         return wantarray ? @cos : \@cos;
3598 }
3599
3600 # parse line of git-diff-tree "raw" output
3601 sub parse_difftree_raw_line {
3602         my $line = shift;
3603         my %res;
3604
3605         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3606         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3607         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3608                 $res{'from_mode'} = $1;
3609                 $res{'to_mode'} = $2;
3610                 $res{'from_id'} = $3;
3611                 $res{'to_id'} = $4;
3612                 $res{'status'} = $5;
3613                 $res{'similarity'} = $6;
3614                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3615                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3616                 } else {
3617                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3618                 }
3619         }
3620         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3621         # combined diff (for merge commit)
3622         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3623                 $res{'nparents'}  = length($1);
3624                 $res{'from_mode'} = [ split(' ', $2) ];
3625                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3626                 $res{'from_id'} = [ split(' ', $3) ];
3627                 $res{'to_id'} = pop @{$res{'from_id'}};
3628                 $res{'status'} = [ split('', $4) ];
3629                 $res{'to_file'} = unquote($5);
3630         }
3631         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3632         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3633                 $res{'commit'} = $1;
3634         }
3635
3636         return wantarray ? %res : \%res;
3637 }
3638
3639 # wrapper: return parsed line of git-diff-tree "raw" output
3640 # (the argument might be raw line, or parsed info)
3641 sub parsed_difftree_line {
3642         my $line_or_ref = shift;
3643
3644         if (ref($line_or_ref) eq "HASH") {
3645                 # pre-parsed (or generated by hand)
3646                 return $line_or_ref;
3647         } else {
3648                 return parse_difftree_raw_line($line_or_ref);
3649         }
3650 }
3651
3652 # parse line of git-ls-tree output
3653 sub parse_ls_tree_line {
3654         my $line = shift;
3655         my %opts = @_;
3656         my %res;
3657
3658         if ($opts{'-l'}) {
3659                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3660                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3661
3662                 $res{'mode'} = $1;
3663                 $res{'type'} = $2;
3664                 $res{'hash'} = $3;
3665                 $res{'size'} = $4;
3666                 if ($opts{'-z'}) {
3667                         $res{'name'} = $5;
3668                 } else {
3669                         $res{'name'} = unquote($5);
3670                 }
3671         } else {
3672                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3673                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3674
3675                 $res{'mode'} = $1;
3676                 $res{'type'} = $2;
3677                 $res{'hash'} = $3;
3678                 if ($opts{'-z'}) {
3679                         $res{'name'} = $4;
3680                 } else {
3681                         $res{'name'} = unquote($4);
3682                 }
3683         }
3684
3685         return wantarray ? %res : \%res;
3686 }
3687
3688 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3689 sub parse_from_to_diffinfo {
3690         my ($diffinfo, $from, $to, @parents) = @_;
3691
3692         if ($diffinfo->{'nparents'}) {
3693                 # combined diff
3694                 $from->{'file'} = [];
3695                 $from->{'href'} = [];
3696                 fill_from_file_info($diffinfo, @parents)
3697                         unless exists $diffinfo->{'from_file'};
3698                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3699                         $from->{'file'}[$i] =
3700                                 defined $diffinfo->{'from_file'}[$i] ?
3701                                         $diffinfo->{'from_file'}[$i] :
3702                                         $diffinfo->{'to_file'};
3703                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3704                                 $from->{'href'}[$i] = href(action=>"blob",
3705                                                            hash_base=>$parents[$i],
3706                                                            hash=>$diffinfo->{'from_id'}[$i],
3707                                                            file_name=>$from->{'file'}[$i]);
3708                         } else {
3709                                 $from->{'href'}[$i] = undef;
3710                         }
3711                 }
3712         } else {
3713                 # ordinary (not combined) diff
3714                 $from->{'file'} = $diffinfo->{'from_file'};
3715                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3716                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3717                                                hash=>$diffinfo->{'from_id'},
3718                                                file_name=>$from->{'file'});
3719                 } else {
3720                         delete $from->{'href'};
3721                 }
3722         }
3723
3724         $to->{'file'} = $diffinfo->{'to_file'};
3725         if (!is_deleted($diffinfo)) { # file exists in result
3726                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3727                                      hash=>$diffinfo->{'to_id'},
3728                                      file_name=>$to->{'file'});
3729         } else {
3730                 delete $to->{'href'};
3731         }
3732 }
3733
3734 ## ......................................................................
3735 ## parse to array of hashes functions
3736
3737 sub git_get_heads_list {
3738         my ($limit, @classes) = @_;
3739         @classes = get_branch_refs() unless @classes;
3740         my @patterns = map { "refs/$_" } @classes;
3741         my @headslist;
3742
3743         open my $fd, '-|', git_cmd(), 'for-each-ref',
3744                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3745                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3746                 @patterns
3747                 or return;
3748         while (my $line = <$fd>) {
3749                 my %ref_item;
3750
3751                 chomp $line;
3752                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3753                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3754                 my ($committer, $epoch, $tz) =
3755                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3756                 $ref_item{'fullname'}  = $name;
3757                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3758                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3759                 $ref_item{'name'} = $name;
3760                 # for refs neither in 'heads' nor 'remotes' we want to
3761                 # show their ref dir
3762                 my $ref_dir = (defined $1) ? $1 : '';
3763                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3764                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3765                 }
3766
3767                 $ref_item{'id'}    = $hash;
3768                 $ref_item{'title'} = $title || '(no commit message)';
3769                 $ref_item{'epoch'} = $epoch;
3770                 if ($epoch) {
3771                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3772                 } else {
3773                         $ref_item{'age'} = "unknown";
3774                 }
3775
3776                 push @headslist, \%ref_item;
3777         }
3778         close $fd;
3779
3780         return wantarray ? @headslist : \@headslist;
3781 }
3782
3783 sub git_get_tags_list {
3784         my $limit = shift;
3785         my @tagslist;
3786
3787         open my $fd, '-|', git_cmd(), 'for-each-ref',
3788                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3789                 '--format=%(objectname) %(objecttype) %(refname) '.
3790                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3791                 'refs/tags'
3792                 or return;
3793         while (my $line = <$fd>) {
3794                 my %ref_item;
3795
3796                 chomp $line;
3797                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3798                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3799                 my ($creator, $epoch, $tz) =
3800                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3801                 $ref_item{'fullname'} = $name;
3802                 $name =~ s!^refs/tags/!!;
3803
3804                 $ref_item{'type'} = $type;
3805                 $ref_item{'id'} = $id;
3806                 $ref_item{'name'} = $name;
3807                 if ($type eq "tag") {
3808                         $ref_item{'subject'} = $title;
3809                         $ref_item{'reftype'} = $reftype;
3810                         $ref_item{'refid'}   = $refid;
3811                 } else {
3812                         $ref_item{'reftype'} = $type;
3813                         $ref_item{'refid'}   = $id;
3814                 }
3815
3816                 if ($type eq "tag" || $type eq "commit") {
3817                         $ref_item{'epoch'} = $epoch;
3818                         if ($epoch) {
3819                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3820                         } else {
3821                                 $ref_item{'age'} = "unknown";
3822                         }
3823                 }
3824
3825                 push @tagslist, \%ref_item;
3826         }
3827         close $fd;
3828
3829         return wantarray ? @tagslist : \@tagslist;
3830 }
3831
3832 ## ----------------------------------------------------------------------
3833 ## filesystem-related functions
3834
3835 sub get_file_owner {
3836         my $path = shift;
3837
3838         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3839         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3840         if (!defined $gcos) {
3841                 return undef;
3842         }
3843         my $owner = $gcos;
3844         $owner =~ s/[,;].*$//;
3845         return to_utf8($owner);
3846 }
3847
3848 # assume that file exists
3849 sub insert_file {
3850         my $filename = shift;
3851
3852         open my $fd, '<', $filename;
3853         print map { to_utf8($_) } <$fd>;
3854         close $fd;
3855 }
3856
3857 ## ......................................................................
3858 ## mimetype related functions
3859
3860 sub mimetype_guess_file {
3861         my $filename = shift;
3862         my $mimemap = shift;
3863         -r $mimemap or return undef;
3864
3865         my %mimemap;
3866         open(my $mh, '<', $mimemap) or return undef;
3867         while (<$mh>) {
3868                 next if m/^#/; # skip comments
3869                 my ($mimetype, @exts) = split(/\s+/);
3870                 foreach my $ext (@exts) {
3871                         $mimemap{$ext} = $mimetype;
3872                 }
3873         }
3874         close($mh);
3875
3876         $filename =~ /\.([^.]*)$/;
3877         return $mimemap{$1};
3878 }
3879
3880 sub mimetype_guess {
3881         my $filename = shift;
3882         my $mime;
3883         $filename =~ /\./ or return undef;
3884
3885         if ($mimetypes_file) {
3886                 my $file = $mimetypes_file;
3887                 if ($file !~ m!^/!) { # if it is relative path
3888                         # it is relative to project
3889                         $file = "$projectroot/$project/$file";
3890                 }
3891                 $mime = mimetype_guess_file($filename, $file);
3892         }
3893         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3894         return $mime;
3895 }
3896
3897 sub blob_mimetype {
3898         my $fd = shift;
3899         my $filename = shift;
3900
3901         if ($filename) {
3902                 my $mime = mimetype_guess($filename);
3903                 $mime and return $mime;
3904         }
3905
3906         # just in case
3907         return $default_blob_plain_mimetype unless $fd;
3908
3909         if (-T $fd) {
3910                 return 'text/plain';
3911         } elsif (! $filename) {
3912                 return 'application/octet-stream';
3913         } elsif ($filename =~ m/\.png$/i) {
3914                 return 'image/png';
3915         } elsif ($filename =~ m/\.gif$/i) {
3916                 return 'image/gif';
3917         } elsif ($filename =~ m/\.jpe?g$/i) {
3918                 return 'image/jpeg';
3919         } else {
3920                 return 'application/octet-stream';
3921         }
3922 }
3923
3924 sub blob_contenttype {
3925         my ($fd, $file_name, $type) = @_;
3926
3927         $type ||= blob_mimetype($fd, $file_name);
3928         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3929                 $type .= "; charset=$default_text_plain_charset";
3930         }
3931
3932         return $type;
3933 }
3934
3935 # guess file syntax for syntax highlighting; return undef if no highlighting
3936 # the name of syntax can (in the future) depend on syntax highlighter used
3937 sub guess_file_syntax {
3938         my ($highlight, $mimetype, $file_name) = @_;
3939         return undef unless ($highlight && defined $file_name);
3940         my $basename = basename($file_name, '.in');
3941         return $highlight_basename{$basename}
3942                 if exists $highlight_basename{$basename};
3943
3944         $basename =~ /\.([^.]*)$/;
3945         my $ext = $1 or return undef;
3946         return $highlight_ext{$ext}
3947                 if exists $highlight_ext{$ext};
3948
3949         return undef;
3950 }
3951
3952 # run highlighter and return FD of its output,
3953 # or return original FD if no highlighting
3954 sub run_highlighter {
3955         my ($fd, $highlight, $syntax) = @_;
3956         return $fd unless ($highlight && defined $syntax);
3957
3958         close $fd;
3959         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3960                   quote_command($highlight_bin).
3961                   " --replace-tabs=8 --fragment --syntax $syntax |"
3962                 or die_error(500, "Couldn't open file or run syntax highlighter");
3963         return $fd;
3964 }
3965
3966 ## ======================================================================
3967 ## functions printing HTML: header, footer, error page
3968
3969 sub get_page_title {
3970         my $title = to_utf8($site_name);
3971
3972         unless (defined $project) {
3973                 if (defined $project_filter) {
3974                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3975                 }
3976                 return $title;
3977         }
3978         $title .= " - " . to_utf8($project);
3979
3980         return $title unless (defined $action);
3981         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3982
3983         return $title unless (defined $file_name);
3984         $title .= " - " . esc_path($file_name);
3985         if ($action eq "tree" && $file_name !~ m|/$|) {
3986                 $title .= "/";
3987         }
3988
3989         return $title;
3990 }
3991
3992 sub get_content_type_html {
3993         # require explicit support from the UA if we are to send the page as
3994         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3995         # we have to do this because MSIE sometimes globs '*/*', pretending to
3996         # support xhtml+xml but choking when it gets what it asked for.
3997         if (defined $cgi->http('HTTP_ACCEPT') &&
3998             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3999             $cgi->Accept('application/xhtml+xml') != 0) {
4000                 return 'application/xhtml+xml';
4001         } else {
4002                 return 'text/html';
4003         }
4004 }
4005
4006 sub print_feed_meta {
4007         if (defined $project) {
4008                 my %href_params = get_feed_info();
4009                 if (!exists $href_params{'-title'}) {
4010                         $href_params{'-title'} = 'log';
4011                 }
4012
4013                 foreach my $format (qw(RSS Atom)) {
4014                         my $type = lc($format);
4015                         my %link_attr = (
4016                                 '-rel' => 'alternate',
4017                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4018                                 '-type' => "application/$type+xml"
4019                         );
4020
4021                         $href_params{'extra_options'} = undef;
4022                         $href_params{'action'} = $type;
4023                         $link_attr{'-href'} = href(%href_params);
4024                         print "<link ".
4025                               "rel=\"$link_attr{'-rel'}\" ".
4026                               "title=\"$link_attr{'-title'}\" ".
4027                               "href=\"$link_attr{'-href'}\" ".
4028                               "type=\"$link_attr{'-type'}\" ".
4029                               "/>\n";
4030
4031                         $href_params{'extra_options'} = '--no-merges';
4032                         $link_attr{'-href'} = href(%href_params);
4033                         $link_attr{'-title'} .= ' (no merges)';
4034                         print "<link ".
4035                               "rel=\"$link_attr{'-rel'}\" ".
4036                               "title=\"$link_attr{'-title'}\" ".
4037                               "href=\"$link_attr{'-href'}\" ".
4038                               "type=\"$link_attr{'-type'}\" ".
4039                               "/>\n";
4040                 }
4041
4042         } else {
4043                 printf('<link rel="alternate" title="%s projects list" '.
4044                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4045                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
4046                 printf('<link rel="alternate" title="%s projects feeds" '.
4047                        'href="%s" type="text/x-opml" />'."\n",
4048                        esc_attr($site_name), href(project=>undef, action=>"opml"));
4049         }
4050 }
4051
4052 sub print_header_links {
4053         my $status = shift;
4054
4055         # print out each stylesheet that exist, providing backwards capability
4056         # for those people who defined $stylesheet in a config file
4057         if (defined $stylesheet) {
4058                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4059         } else {
4060                 foreach my $stylesheet (@stylesheets) {
4061                         next unless $stylesheet;
4062                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4063                 }
4064         }
4065         print_feed_meta()
4066                 if ($status eq '200 OK');
4067         if (defined $favicon) {
4068                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4069         }
4070 }
4071
4072 sub print_nav_breadcrumbs_path {
4073         my $dirprefix = undef;
4074         while (my $part = shift) {
4075                 $dirprefix .= "/" if defined $dirprefix;
4076                 $dirprefix .= $part;
4077                 print $cgi->a({-href => href(project => undef,
4078                                              project_filter => $dirprefix,
4079                                              action => "project_list")},
4080                               esc_html($part)) . " / ";
4081         }
4082 }
4083
4084 sub print_nav_breadcrumbs {
4085         my %opts = @_;
4086
4087         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4088                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4089         }
4090         if (defined $project) {
4091                 my @dirname = split '/', $project;
4092                 my $projectbasename = pop @dirname;
4093                 print_nav_breadcrumbs_path(@dirname);
4094                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4095                 if (defined $action) {
4096                         my $action_print = $action ;
4097                         if (defined $opts{-action_extra}) {
4098                                 $action_print = $cgi->a({-href => href(action=>$action)},
4099                                         $action);
4100                         }
4101                         print " / $action_print";
4102                 }
4103                 if (defined $opts{-action_extra}) {
4104                         print " / $opts{-action_extra}";
4105                 }
4106                 print "\n";
4107         } elsif (defined $project_filter) {
4108                 print_nav_breadcrumbs_path(split '/', $project_filter);
4109         }
4110 }
4111
4112 sub print_search_form {
4113         if (!defined $searchtext) {
4114                 $searchtext = "";
4115         }
4116         my $search_hash;
4117         if (defined $hash_base) {
4118                 $search_hash = $hash_base;
4119         } elsif (defined $hash) {
4120                 $search_hash = $hash;
4121         } else {
4122                 $search_hash = "HEAD";
4123         }
4124         my $action = $my_uri;
4125         my $use_pathinfo = gitweb_check_feature('pathinfo');
4126         if ($use_pathinfo) {
4127                 $action .= "/".esc_url($project);
4128         }
4129         print $cgi->start_form(-method => "get", -action => $action) .
4130               "<div class=\"search\">\n" .
4131               (!$use_pathinfo &&
4132               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4133               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4134               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4135               $cgi->popup_menu(-name => 'st', -default => 'commit',
4136                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4137               " " . $cgi->a({-href => href(action=>"search_help"),
4138                              -title => "search help" }, "?") . " search:\n",
4139               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4140               "<span title=\"Extended regular expression\">" .
4141               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4142                              -checked => $search_use_regexp) .
4143               "</span>" .
4144               "</div>" .
4145               $cgi->end_form() . "\n";
4146 }
4147
4148 sub git_header_html {
4149         my $status = shift || "200 OK";
4150         my $expires = shift;
4151         my %opts = @_;
4152
4153         my $title = get_page_title();
4154         my $content_type = get_content_type_html();
4155         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4156                            -status=> $status, -expires => $expires)
4157                 unless ($opts{'-no_http_header'});
4158         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4159         print <<EOF;
4160 <?xml version="1.0" encoding="utf-8"?>
4161 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4162 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4163 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4164 <!-- git core binaries version $git_version -->
4165 <head>
4166 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4167 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4168 <meta name="robots" content="index, nofollow"/>
4169 <title>$title</title>
4170 EOF
4171         # the stylesheet, favicon etc urls won't work correctly with path_info
4172         # unless we set the appropriate base URL
4173         if ($ENV{'PATH_INFO'}) {
4174                 print "<base href=\"".esc_url($base_url)."\" />\n";
4175         }
4176         print_header_links($status);
4177
4178         if (defined $site_html_head_string) {
4179                 print to_utf8($site_html_head_string);
4180         }
4181
4182         print "</head>\n" .
4183               "<body>\n";
4184
4185         if (defined $site_header && -f $site_header) {
4186                 insert_file($site_header);
4187         }
4188
4189         print "<div class=\"page_header\">\n";
4190         if (defined $logo) {
4191                 print $cgi->a({-href => esc_url($logo_url),
4192                                -title => $logo_label},
4193                               $cgi->img({-src => esc_url($logo),
4194                                          -width => 72, -height => 27,
4195                                          -alt => "git",
4196                                          -class => "logo"}));
4197         }
4198         print_nav_breadcrumbs(%opts);
4199         print "</div>\n";
4200
4201         my $have_search = gitweb_check_feature('search');
4202         if (defined $project && $have_search) {
4203                 print_search_form();
4204         }
4205 }
4206
4207 sub git_footer_html {
4208         my $feed_class = 'rss_logo';
4209
4210         print "<div class=\"page_footer\">\n";
4211         if (defined $project) {
4212                 my $descr = git_get_project_description($project);
4213                 if (defined $descr) {
4214                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4215                 }
4216
4217                 my %href_params = get_feed_info();
4218                 if (!%href_params) {
4219                         $feed_class .= ' generic';
4220                 }
4221                 $href_params{'-title'} ||= 'log';
4222
4223                 foreach my $format (qw(RSS Atom)) {
4224                         $href_params{'action'} = lc($format);
4225                         print $cgi->a({-href => href(%href_params),
4226                                       -title => "$href_params{'-title'} $format feed",
4227                                       -class => $feed_class}, $format)."\n";
4228                 }
4229
4230         } else {
4231                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4232                                              project_filter => $project_filter),
4233                               -class => $feed_class}, "OPML") . " ";
4234                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4235                                              project_filter => $project_filter),
4236                               -class => $feed_class}, "TXT") . "\n";
4237         }
4238         print "</div>\n"; # class="page_footer"
4239
4240         if (defined $t0 && gitweb_check_feature('timed')) {
4241                 print "<div id=\"generating_info\">\n";
4242                 print 'This page took '.
4243                       '<span id="generating_time" class="time_span">'.
4244                       tv_interval($t0, [ gettimeofday() ]).
4245                       ' seconds </span>'.
4246                       ' and '.
4247                       '<span id="generating_cmd">'.
4248                       $number_of_git_cmds.
4249                       '</span> git commands '.
4250                       " to generate.\n";
4251                 print "</div>\n"; # class="page_footer"
4252         }
4253
4254         if (defined $site_footer && -f $site_footer) {
4255                 insert_file($site_footer);
4256         }
4257
4258         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4259         if (defined $action &&
4260             $action eq 'blame_incremental') {
4261                 print qq!<script type="text/javascript">\n!.
4262                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4263                       qq!           "!. href() .qq!");\n!.
4264                       qq!</script>\n!;
4265         } else {
4266                 my ($jstimezone, $tz_cookie, $datetime_class) =
4267                         gitweb_get_feature('javascript-timezone');
4268
4269                 print qq!<script type="text/javascript">\n!.
4270                       qq!window.onload = function () {\n!;
4271                 if (gitweb_check_feature('javascript-actions')) {
4272                         print qq!       fixLinks();\n!;
4273                 }
4274                 if ($jstimezone && $tz_cookie && $datetime_class) {
4275                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4276                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4277                 }
4278                 print qq!};\n!.
4279                       qq!</script>\n!;
4280         }
4281
4282         print "</body>\n" .
4283               "</html>";
4284 }
4285
4286 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4287 # Example: die_error(404, 'Hash not found')
4288 # By convention, use the following status codes (as defined in RFC 2616):
4289 # 400: Invalid or missing CGI parameters, or
4290 #      requested object exists but has wrong type.
4291 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4292 #      this server or project.
4293 # 404: Requested object/revision/project doesn't exist.
4294 # 500: The server isn't configured properly, or
4295 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4296 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4297 # 503: The server is currently unavailable (because it is overloaded,
4298 #      or down for maintenance).  Generally, this is a temporary state.
4299 sub die_error {
4300         my $status = shift || 500;
4301         my $error = esc_html(shift) || "Internal Server Error";
4302         my $extra = shift;
4303         my %opts = @_;
4304
4305         my %http_responses = (
4306                 400 => '400 Bad Request',
4307                 403 => '403 Forbidden',
4308                 404 => '404 Not Found',
4309                 500 => '500 Internal Server Error',
4310                 503 => '503 Service Unavailable',
4311         );
4312         git_header_html($http_responses{$status}, undef, %opts);
4313         print <<EOF;
4314 <div class="page_body">
4315 <br /><br />
4316 $status - $error
4317 <br />
4318 EOF
4319         if (defined $extra) {
4320                 print "<hr />\n" .
4321                       "$extra\n";
4322         }
4323         print "</div>\n";
4324
4325         git_footer_html();
4326         goto DONE_GITWEB
4327                 unless ($opts{'-error_handler'});
4328 }
4329
4330 ## ----------------------------------------------------------------------
4331 ## functions printing or outputting HTML: navigation
4332
4333 sub git_print_page_nav {
4334         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4335         $extra = '' if !defined $extra; # pager or formats
4336
4337         my @navs = qw(summary shortlog log commit commitdiff tree);
4338         if ($suppress) {
4339                 @navs = grep { $_ ne $suppress } @navs;
4340         }
4341
4342         my %arg = map { $_ => {action=>$_} } @navs;
4343         if (defined $head) {
4344                 for (qw(commit commitdiff)) {
4345                         $arg{$_}{'hash'} = $head;
4346                 }
4347                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4348                         for (qw(shortlog log)) {
4349                                 $arg{$_}{'hash'} = $head;
4350                         }
4351                 }
4352         }
4353
4354         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4355         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4356
4357         my @actions = gitweb_get_feature('actions');
4358         my %repl = (
4359                 '%' => '%',
4360                 'n' => $project,         # project name
4361                 'f' => $git_dir,         # project path within filesystem
4362                 'h' => $treehead || '',  # current hash ('h' parameter)
4363                 'b' => $treebase || '',  # hash base ('hb' parameter)
4364         );
4365         while (@actions) {
4366                 my ($label, $link, $pos) = splice(@actions,0,3);
4367                 # insert
4368                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4369                 # munch munch
4370                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4371                 $arg{$label}{'_href'} = $link;
4372         }
4373
4374         print "<div class=\"page_nav\">\n" .
4375                 (join " | ",
4376                  map { $_ eq $current ?
4377                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4378                  } @navs);
4379         print "<br/>\n$extra<br/>\n" .
4380               "</div>\n";
4381 }
4382
4383 # returns a submenu for the nagivation of the refs views (tags, heads,
4384 # remotes) with the current view disabled and the remotes view only
4385 # available if the feature is enabled
4386 sub format_ref_views {
4387         my ($current) = @_;
4388         my @ref_views = qw{tags heads};
4389         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4390         return join " | ", map {
4391                 $_ eq $current ? $_ :
4392                 $cgi->a({-href => href(action=>$_)}, $_)
4393         } @ref_views
4394 }
4395
4396 sub format_paging_nav {
4397         my ($action, $page, $has_next_link) = @_;
4398         my $paging_nav;
4399
4400
4401         if ($page > 0) {
4402                 $paging_nav .=
4403                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4404                         " &sdot; " .
4405                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4406                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4407         } else {
4408                 $paging_nav .= "first &sdot; prev";
4409         }
4410
4411         if ($has_next_link) {
4412                 $paging_nav .= " &sdot; " .
4413                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4414                                  -accesskey => "n", -title => "Alt-n"}, "next");
4415         } else {
4416                 $paging_nav .= " &sdot; next";
4417         }
4418
4419         return $paging_nav;
4420 }
4421
4422 ## ......................................................................
4423 ## functions printing or outputting HTML: div
4424
4425 sub git_print_header_div {
4426         my ($action, $title, $hash, $hash_base) = @_;
4427         my %args = ();
4428
4429         $args{'action'} = $action;
4430         $args{'hash'} = $hash if $hash;
4431         $args{'hash_base'} = $hash_base if $hash_base;
4432
4433         print "<div class=\"header\">\n" .
4434               $cgi->a({-href => href(%args), -class => "title"},
4435               $title ? $title : $action) .
4436               "\n</div>\n";
4437 }
4438
4439 sub format_repo_url {
4440         my ($name, $url) = @_;
4441         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4442 }
4443
4444 # Group output by placing it in a DIV element and adding a header.
4445 # Options for start_div() can be provided by passing a hash reference as the
4446 # first parameter to the function.
4447 # Options to git_print_header_div() can be provided by passing an array
4448 # reference. This must follow the options to start_div if they are present.
4449 # The content can be a scalar, which is output as-is, a scalar reference, which
4450 # is output after html escaping, an IO handle passed either as *handle or
4451 # *handle{IO}, or a function reference. In the latter case all following
4452 # parameters will be taken as argument to the content function call.
4453 sub git_print_section {
4454         my ($div_args, $header_args, $content);
4455         my $arg = shift;
4456         if (ref($arg) eq 'HASH') {
4457                 $div_args = $arg;
4458                 $arg = shift;
4459         }
4460         if (ref($arg) eq 'ARRAY') {
4461                 $header_args = $arg;
4462                 $arg = shift;
4463         }
4464         $content = $arg;
4465
4466         print $cgi->start_div($div_args);
4467         git_print_header_div(@$header_args);
4468
4469         if (ref($content) eq 'CODE') {
4470                 $content->(@_);
4471         } elsif (ref($content) eq 'SCALAR') {
4472                 print esc_html($$content);
4473         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4474                 print <$content>;
4475         } elsif (!ref($content) && defined($content)) {
4476                 print $content;
4477         }
4478
4479         print $cgi->end_div;
4480 }
4481
4482 sub format_timestamp_html {
4483         my $date = shift;
4484         my $strtime = $date->{'rfc2822'};
4485
4486         my (undef, undef, $datetime_class) =
4487                 gitweb_get_feature('javascript-timezone');
4488         if ($datetime_class) {
4489                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4490         }
4491
4492         my $localtime_format = '(%02d:%02d %s)';
4493         if ($date->{'hour_local'} < 6) {
4494                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4495         }
4496         $strtime .= ' ' .
4497                     sprintf($localtime_format,
4498                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4499
4500         return $strtime;
4501 }
4502
4503 # Outputs the author name and date in long form
4504 sub git_print_authorship {
4505         my $co = shift;
4506         my %opts = @_;
4507         my $tag = $opts{-tag} || 'div';
4508         my $author = $co->{'author_name'};
4509
4510         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4511         print "<$tag class=\"author_date\">" .
4512               format_search_author($author, "author", esc_html($author)) .
4513               " [".format_timestamp_html(\%ad)."]".
4514               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4515               "</$tag>\n";
4516 }
4517
4518 # Outputs table rows containing the full author or committer information,
4519 # in the format expected for 'commit' view (& similar).
4520 # Parameters are a commit hash reference, followed by the list of people
4521 # to output information for. If the list is empty it defaults to both
4522 # author and committer.
4523 sub git_print_authorship_rows {
4524         my $co = shift;
4525         # too bad we can't use @people = @_ || ('author', 'committer')
4526         my @people = @_;
4527         @people = ('author', 'committer') unless @people;
4528         foreach my $who (@people) {
4529                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4530                 print "<tr><td>$who</td><td>" .
4531                       format_search_author($co->{"${who}_name"}, $who,
4532                                            esc_html($co->{"${who}_name"})) . " " .
4533                       format_search_author($co->{"${who}_email"}, $who,
4534                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4535                       "</td><td rowspan=\"2\">" .
4536                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4537                       "</td></tr>\n" .
4538                       "<tr>" .
4539                       "<td></td><td>" .
4540                       format_timestamp_html(\%wd) .
4541                       "</td>" .
4542                       "</tr>\n";
4543         }
4544 }
4545
4546 sub git_print_page_path {
4547         my $name = shift;
4548         my $type = shift;
4549         my $hb = shift;
4550
4551
4552         print "<div class=\"page_path\">";
4553         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4554                       -title => 'tree root'}, to_utf8("[$project]"));
4555         print " / ";
4556         if (defined $name) {
4557                 my @dirname = split '/', $name;
4558                 my $basename = pop @dirname;
4559                 my $fullname = '';
4560
4561                 foreach my $dir (@dirname) {
4562                         $fullname .= ($fullname ? '/' : '') . $dir;
4563                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4564                                                      hash_base=>$hb),
4565                                       -title => $fullname}, esc_path($dir));
4566                         print " / ";
4567                 }
4568                 if (defined $type && $type eq 'blob') {
4569                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4570                                                      hash_base=>$hb),
4571                                       -title => $name}, esc_path($basename));
4572                 } elsif (defined $type && $type eq 'tree') {
4573                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4574                                                      hash_base=>$hb),
4575                                       -title => $name}, esc_path($basename));
4576                         print " / ";
4577                 } else {
4578                         print esc_path($basename);
4579                 }
4580         }
4581         print "<br/></div>\n";
4582 }
4583
4584 sub git_print_log {
4585         my $log = shift;
4586         my %opts = @_;
4587
4588         if ($opts{'-remove_title'}) {
4589                 # remove title, i.e. first line of log
4590                 shift @$log;
4591         }
4592         # remove leading empty lines
4593         while (defined $log->[0] && $log->[0] eq "") {
4594                 shift @$log;
4595         }
4596
4597         # print log
4598         my $skip_blank_line = 0;
4599         foreach my $line (@$log) {
4600                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4601                         if (! $opts{'-remove_signoff'}) {
4602                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4603                                 $skip_blank_line = 1;
4604                         }
4605                         next;
4606                 }
4607
4608                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4609                         if (! $opts{'-remove_signoff'}) {
4610                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4611                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4612                                         "</span><br/>\n";
4613                                 $skip_blank_line = 1;
4614                         }
4615                         next;
4616                 }
4617
4618                 # print only one empty line
4619                 # do not print empty line after signoff
4620                 if ($line eq "") {
4621                         next if ($skip_blank_line);
4622                         $skip_blank_line = 1;
4623                 } else {
4624                         $skip_blank_line = 0;
4625                 }
4626
4627                 print format_log_line_html($line) . "<br/>\n";
4628         }
4629
4630         if ($opts{'-final_empty_line'}) {
4631                 # end with single empty line
4632                 print "<br/>\n" unless $skip_blank_line;
4633         }
4634 }
4635
4636 # return link target (what link points to)
4637 sub git_get_link_target {
4638         my $hash = shift;
4639         my $link_target;
4640
4641         # read link
4642         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4643                 or return;
4644         {
4645                 local $/ = undef;
4646                 $link_target = <$fd>;
4647         }
4648         close $fd
4649                 or return;
4650
4651         return $link_target;
4652 }
4653
4654 # given link target, and the directory (basedir) the link is in,
4655 # return target of link relative to top directory (top tree);
4656 # return undef if it is not possible (including absolute links).
4657 sub normalize_link_target {
4658         my ($link_target, $basedir) = @_;
4659
4660         # absolute symlinks (beginning with '/') cannot be normalized
4661         return if (substr($link_target, 0, 1) eq '/');
4662
4663         # normalize link target to path from top (root) tree (dir)
4664         my $path;
4665         if ($basedir) {
4666                 $path = $basedir . '/' . $link_target;
4667         } else {
4668                 # we are in top (root) tree (dir)
4669                 $path = $link_target;
4670         }
4671
4672         # remove //, /./, and /../
4673         my @path_parts;
4674         foreach my $part (split('/', $path)) {
4675                 # discard '.' and ''
4676                 next if (!$part || $part eq '.');
4677                 # handle '..'
4678                 if ($part eq '..') {
4679                         if (@path_parts) {
4680                                 pop @path_parts;
4681                         } else {
4682                                 # link leads outside repository (outside top dir)
4683                                 return;
4684                         }
4685                 } else {
4686                         push @path_parts, $part;
4687                 }
4688         }
4689         $path = join('/', @path_parts);
4690
4691         return $path;
4692 }
4693
4694 # print tree entry (row of git_tree), but without encompassing <tr> element
4695 sub git_print_tree_entry {
4696         my ($t, $basedir, $hash_base, $have_blame) = @_;
4697
4698         my %base_key = ();
4699         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4700
4701         # The format of a table row is: mode list link.  Where mode is
4702         # the mode of the entry, list is the name of the entry, an href,
4703         # and link is the action links of the entry.
4704
4705         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4706         if (exists $t->{'size'}) {
4707                 print "<td class=\"size\">$t->{'size'}</td>\n";
4708         }
4709         if ($t->{'type'} eq "blob") {
4710                 print "<td class=\"list\">" .
4711                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4712                                                file_name=>"$basedir$t->{'name'}", %base_key),
4713                                 -class => "list"}, esc_path($t->{'name'}));
4714                 if (S_ISLNK(oct $t->{'mode'})) {
4715                         my $link_target = git_get_link_target($t->{'hash'});
4716                         if ($link_target) {
4717                                 my $norm_target = normalize_link_target($link_target, $basedir);
4718                                 if (defined $norm_target) {
4719                                         print " -> " .
4720                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4721                                                                      file_name=>$norm_target),
4722                                                        -title => $norm_target}, esc_path($link_target));
4723                                 } else {
4724                                         print " -> " . esc_path($link_target);
4725                                 }
4726                         }
4727                 }
4728                 print "</td>\n";
4729                 print "<td class=\"link\">";
4730                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4731                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4732                               "blob");
4733                 if ($have_blame) {
4734                         print " | " .
4735                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4736                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4737                                       "blame");
4738                 }
4739                 if (defined $hash_base) {
4740                         print " | " .
4741                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4742                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4743                                       "history");
4744                 }
4745                 print " | " .
4746                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4747                                                file_name=>"$basedir$t->{'name'}")},
4748                                 "raw");
4749                 print "</td>\n";
4750
4751         } elsif ($t->{'type'} eq "tree") {
4752                 print "<td class=\"list\">";
4753                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4754                                              file_name=>"$basedir$t->{'name'}",
4755                                              %base_key)},
4756                               esc_path($t->{'name'}));
4757                 print "</td>\n";
4758                 print "<td class=\"link\">";
4759                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4760                                              file_name=>"$basedir$t->{'name'}",
4761                                              %base_key)},
4762                               "tree");
4763                 if (defined $hash_base) {
4764                         print " | " .
4765                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4766                                                      file_name=>"$basedir$t->{'name'}")},
4767                                       "history");
4768                 }
4769                 print "</td>\n";
4770         } else {
4771                 # unknown object: we can only present history for it
4772                 # (this includes 'commit' object, i.e. submodule support)
4773                 print "<td class=\"list\">" .
4774                       esc_path($t->{'name'}) .
4775                       "</td>\n";
4776                 print "<td class=\"link\">";
4777                 if (defined $hash_base) {
4778                         print $cgi->a({-href => href(action=>"history",
4779                                                      hash_base=>$hash_base,
4780                                                      file_name=>"$basedir$t->{'name'}")},
4781                                       "history");
4782                 }
4783                 print "</td>\n";
4784         }
4785 }
4786
4787 ## ......................................................................
4788 ## functions printing large fragments of HTML
4789
4790 # get pre-image filenames for merge (combined) diff
4791 sub fill_from_file_info {
4792         my ($diff, @parents) = @_;
4793
4794         $diff->{'from_file'} = [ ];
4795         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4796         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4797                 if ($diff->{'status'}[$i] eq 'R' ||
4798                     $diff->{'status'}[$i] eq 'C') {
4799                         $diff->{'from_file'}[$i] =
4800                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4801                 }
4802         }
4803
4804         return $diff;
4805 }
4806
4807 # is current raw difftree line of file deletion
4808 sub is_deleted {
4809         my $diffinfo = shift;
4810
4811         return $diffinfo->{'to_id'} eq ('0' x 40);
4812 }
4813
4814 # does patch correspond to [previous] difftree raw line
4815 # $diffinfo  - hashref of parsed raw diff format
4816 # $patchinfo - hashref of parsed patch diff format
4817 #              (the same keys as in $diffinfo)
4818 sub is_patch_split {
4819         my ($diffinfo, $patchinfo) = @_;
4820
4821         return defined $diffinfo && defined $patchinfo
4822                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4823 }
4824
4825
4826 sub git_difftree_body {
4827         my ($difftree, $hash, @parents) = @_;
4828         my ($parent) = $parents[0];
4829         my $have_blame = gitweb_check_feature('blame');
4830         print "<div class=\"list_head\">\n";
4831         if ($#{$difftree} > 10) {
4832                 print(($#{$difftree} + 1) . " files changed:\n");
4833         }
4834         print "</div>\n";
4835
4836         print "<table class=\"" .
4837               (@parents > 1 ? "combined " : "") .
4838               "diff_tree\">\n";
4839
4840         # header only for combined diff in 'commitdiff' view
4841         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4842         if ($has_header) {
4843                 # table header
4844                 print "<thead><tr>\n" .
4845                        "<th></th><th></th>\n"; # filename, patchN link
4846                 for (my $i = 0; $i < @parents; $i++) {
4847                         my $par = $parents[$i];
4848                         print "<th>" .
4849                               $cgi->a({-href => href(action=>"commitdiff",
4850                                                      hash=>$hash, hash_parent=>$par),
4851                                        -title => 'commitdiff to parent number ' .
4852                                                   ($i+1) . ': ' . substr($par,0,7)},
4853                                       $i+1) .
4854                               "&nbsp;</th>\n";
4855                 }
4856                 print "</tr></thead>\n<tbody>\n";
4857         }
4858
4859         my $alternate = 1;
4860         my $patchno = 0;
4861         foreach my $line (@{$difftree}) {
4862                 my $diff = parsed_difftree_line($line);
4863
4864                 if ($alternate) {
4865                         print "<tr class=\"dark\">\n";
4866                 } else {
4867                         print "<tr class=\"light\">\n";
4868                 }
4869                 $alternate ^= 1;
4870
4871                 if (exists $diff->{'nparents'}) { # combined diff
4872
4873                         fill_from_file_info($diff, @parents)
4874                                 unless exists $diff->{'from_file'};
4875
4876                         if (!is_deleted($diff)) {
4877                                 # file exists in the result (child) commit
4878                                 print "<td>" .
4879                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4880                                                              file_name=>$diff->{'to_file'},
4881                                                              hash_base=>$hash),
4882                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4883                                       "</td>\n";
4884                         } else {
4885                                 print "<td>" .
4886                                       esc_path($diff->{'to_file'}) .
4887                                       "</td>\n";
4888                         }
4889
4890                         if ($action eq 'commitdiff') {
4891                                 # link to patch
4892                                 $patchno++;
4893                                 print "<td class=\"link\">" .
4894                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4895                                               "patch") .
4896                                       " | " .
4897                                       "</td>\n";
4898                         }
4899
4900                         my $has_history = 0;
4901                         my $not_deleted = 0;
4902                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4903                                 my $hash_parent = $parents[$i];
4904                                 my $from_hash = $diff->{'from_id'}[$i];
4905                                 my $from_path = $diff->{'from_file'}[$i];
4906                                 my $status = $diff->{'status'}[$i];
4907
4908                                 $has_history ||= ($status ne 'A');
4909                                 $not_deleted ||= ($status ne 'D');
4910
4911                                 if ($status eq 'A') {
4912                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4913                                 } elsif ($status eq 'D') {
4914                                         print "<td class=\"link\">" .
4915                                               $cgi->a({-href => href(action=>"blob",
4916                                                                      hash_base=>$hash,
4917                                                                      hash=>$from_hash,
4918                                                                      file_name=>$from_path)},
4919                                                       "blob" . ($i+1)) .
4920                                               " | </td>\n";
4921                                 } else {
4922                                         if ($diff->{'to_id'} eq $from_hash) {
4923                                                 print "<td class=\"link nochange\">";
4924                                         } else {
4925                                                 print "<td class=\"link\">";
4926                                         }
4927                                         print $cgi->a({-href => href(action=>"blobdiff",
4928                                                                      hash=>$diff->{'to_id'},
4929                                                                      hash_parent=>$from_hash,
4930                                                                      hash_base=>$hash,
4931                                                                      hash_parent_base=>$hash_parent,
4932                                                                      file_name=>$diff->{'to_file'},
4933                                                                      file_parent=>$from_path)},
4934                                                       "diff" . ($i+1)) .
4935                                               " | </td>\n";
4936                                 }
4937                         }
4938
4939                         print "<td class=\"link\">";
4940                         if ($not_deleted) {
4941                                 print $cgi->a({-href => href(action=>"blob",
4942                                                              hash=>$diff->{'to_id'},
4943                                                              file_name=>$diff->{'to_file'},
4944                                                              hash_base=>$hash)},
4945                                               "blob");
4946                                 print " | " if ($has_history);
4947                         }
4948                         if ($has_history) {
4949                                 print $cgi->a({-href => href(action=>"history",
4950                                                              file_name=>$diff->{'to_file'},
4951                                                              hash_base=>$hash)},
4952                                               "history");
4953                         }
4954                         print "</td>\n";
4955
4956                         print "</tr>\n";
4957                         next; # instead of 'else' clause, to avoid extra indent
4958                 }
4959                 # else ordinary diff
4960
4961                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4962                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4963                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4964                         $to_mode_oct = oct $diff->{'to_mode'};
4965                         if (S_ISREG($to_mode_oct)) { # only for regular file
4966                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4967                         }
4968                         $to_file_type = file_type($diff->{'to_mode'});
4969                 }
4970                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4971                         $from_mode_oct = oct $diff->{'from_mode'};
4972                         if (S_ISREG($from_mode_oct)) { # only for regular file
4973                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4974                         }
4975                         $from_file_type = file_type($diff->{'from_mode'});
4976                 }
4977
4978                 if ($diff->{'status'} eq "A") { # created
4979                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4980                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4981                         $mode_chng   .= "]</span>";
4982                         print "<td>";
4983                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4984                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4985                                       -class => "list"}, esc_path($diff->{'file'}));
4986                         print "</td>\n";
4987                         print "<td>$mode_chng</td>\n";
4988                         print "<td class=\"link\">";
4989                         if ($action eq 'commitdiff') {
4990                                 # link to patch
4991                                 $patchno++;
4992                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4993                                               "patch") .
4994                                       " | ";
4995                         }
4996                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4997                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4998                                       "blob");
4999                         print "</td>\n";
5000
5001                 } elsif ($diff->{'status'} eq "D") { # deleted
5002                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5003                         print "<td>";
5004                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5005                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5006                                        -class => "list"}, esc_path($diff->{'file'}));
5007                         print "</td>\n";
5008                         print "<td>$mode_chng</td>\n";
5009                         print "<td class=\"link\">";
5010                         if ($action eq 'commitdiff') {
5011                                 # link to patch
5012                                 $patchno++;
5013                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5014                                               "patch") .
5015                                       " | ";
5016                         }
5017                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5018                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5019                                       "blob") . " | ";
5020                         if ($have_blame) {
5021                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5022                                                              file_name=>$diff->{'file'})},
5023                                               "blame") . " | ";
5024                         }
5025                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5026                                                      file_name=>$diff->{'file'})},
5027                                       "history");
5028                         print "</td>\n";
5029
5030                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5031                         my $mode_chnge = "";
5032                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5033                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5034                                 if ($from_file_type ne $to_file_type) {
5035                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5036                                 }
5037                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5038                                         if ($from_mode_str && $to_mode_str) {
5039                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5040                                         } elsif ($to_mode_str) {
5041                                                 $mode_chnge .= " mode: $to_mode_str";
5042                                         }
5043                                 }
5044                                 $mode_chnge .= "]</span>\n";
5045                         }
5046                         print "<td>";
5047                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5048                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5049                                       -class => "list"}, esc_path($diff->{'file'}));
5050                         print "</td>\n";
5051                         print "<td>$mode_chnge</td>\n";
5052                         print "<td class=\"link\">";
5053                         if ($action eq 'commitdiff') {
5054                                 # link to patch
5055                                 $patchno++;
5056                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5057                                               "patch") .
5058                                       " | ";
5059                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5060                                 # "commit" view and modified file (not onlu mode changed)
5061                                 print $cgi->a({-href => href(action=>"blobdiff",
5062                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5063                                                              hash_base=>$hash, hash_parent_base=>$parent,
5064                                                              file_name=>$diff->{'file'})},
5065                                               "diff") .
5066                                       " | ";
5067                         }
5068                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5069                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5070                                        "blob") . " | ";
5071                         if ($have_blame) {
5072                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5073                                                              file_name=>$diff->{'file'})},
5074                                               "blame") . " | ";
5075                         }
5076                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5077                                                      file_name=>$diff->{'file'})},
5078                                       "history");
5079                         print "</td>\n";
5080
5081                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5082                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5083                         my $nstatus = $status_name{$diff->{'status'}};
5084                         my $mode_chng = "";
5085                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5086                                 # mode also for directories, so we cannot use $to_mode_str
5087                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5088                         }
5089                         print "<td>" .
5090                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5091                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5092                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5093                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5094                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5095                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5096                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5097                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5098                               "<td class=\"link\">";
5099                         if ($action eq 'commitdiff') {
5100                                 # link to patch
5101                                 $patchno++;
5102                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5103                                               "patch") .
5104                                       " | ";
5105                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5106                                 # "commit" view and modified file (not only pure rename or copy)
5107                                 print $cgi->a({-href => href(action=>"blobdiff",
5108                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5109                                                              hash_base=>$hash, hash_parent_base=>$parent,
5110                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5111                                               "diff") .
5112                                       " | ";
5113                         }
5114                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5115                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5116                                       "blob") . " | ";
5117                         if ($have_blame) {
5118                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5119                                                              file_name=>$diff->{'to_file'})},
5120                                               "blame") . " | ";
5121                         }
5122                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5123                                                     file_name=>$diff->{'to_file'})},
5124                                       "history");
5125                         print "</td>\n";
5126
5127                 } # we should not encounter Unmerged (U) or Unknown (X) status
5128                 print "</tr>\n";
5129         }
5130         print "</tbody>" if $has_header;
5131         print "</table>\n";
5132 }
5133
5134 # Print context lines and then rem/add lines in a side-by-side manner.
5135 sub print_sidebyside_diff_lines {
5136         my ($ctx, $rem, $add) = @_;
5137
5138         # print context block before add/rem block
5139         if (@$ctx) {
5140                 print join '',
5141                         '<div class="chunk_block ctx">',
5142                                 '<div class="old">',
5143                                 @$ctx,
5144                                 '</div>',
5145                                 '<div class="new">',
5146                                 @$ctx,
5147                                 '</div>',
5148                         '</div>';
5149         }
5150
5151         if (!@$add) {
5152                 # pure removal
5153                 print join '',
5154                         '<div class="chunk_block rem">',
5155                                 '<div class="old">',
5156                                 @$rem,
5157                                 '</div>',
5158                         '</div>';
5159         } elsif (!@$rem) {
5160                 # pure addition
5161                 print join '',
5162                         '<div class="chunk_block add">',
5163                                 '<div class="new">',
5164                                 @$add,
5165                                 '</div>',
5166                         '</div>';
5167         } else {
5168                 print join '',
5169                         '<div class="chunk_block chg">',
5170                                 '<div class="old">',
5171                                 @$rem,
5172                                 '</div>',
5173                                 '<div class="new">',
5174                                 @$add,
5175                                 '</div>',
5176                         '</div>';
5177         }
5178 }
5179
5180 # Print context lines and then rem/add lines in inline manner.
5181 sub print_inline_diff_lines {
5182         my ($ctx, $rem, $add) = @_;
5183
5184         print @$ctx, @$rem, @$add;
5185 }
5186
5187 # Format removed and added line, mark changed part and HTML-format them.
5188 # Implementation is based on contrib/diff-highlight
5189 sub format_rem_add_lines_pair {
5190         my ($rem, $add, $num_parents) = @_;
5191
5192         # We need to untabify lines before split()'ing them;
5193         # otherwise offsets would be invalid.
5194         chomp $rem;
5195         chomp $add;
5196         $rem = untabify($rem);
5197         $add = untabify($add);
5198
5199         my @rem = split(//, $rem);
5200         my @add = split(//, $add);
5201         my ($esc_rem, $esc_add);
5202         # Ignore leading +/- characters for each parent.
5203         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5204         my ($prefix_has_nonspace, $suffix_has_nonspace);
5205
5206         my $shorter = (@rem < @add) ? @rem : @add;
5207         while ($prefix_len < $shorter) {
5208                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5209
5210                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5211                 $prefix_len++;
5212         }
5213
5214         while ($prefix_len + $suffix_len < $shorter) {
5215                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5216
5217                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5218                 $suffix_len++;
5219         }
5220
5221         # Mark lines that are different from each other, but have some common
5222         # part that isn't whitespace.  If lines are completely different, don't
5223         # mark them because that would make output unreadable, especially if
5224         # diff consists of multiple lines.
5225         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5226                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5227                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5228                 $esc_add = esc_html_hl_regions($add, 'marked',
5229                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5230         } else {
5231                 $esc_rem = esc_html($rem, -nbsp=>1);
5232                 $esc_add = esc_html($add, -nbsp=>1);
5233         }
5234
5235         return format_diff_line(\$esc_rem, 'rem'),
5236                format_diff_line(\$esc_add, 'add');
5237 }
5238
5239 # HTML-format diff context, removed and added lines.
5240 sub format_ctx_rem_add_lines {
5241         my ($ctx, $rem, $add, $num_parents) = @_;
5242         my (@new_ctx, @new_rem, @new_add);
5243         my $can_highlight = 0;
5244         my $is_combined = ($num_parents > 1);
5245
5246         # Highlight if every removed line has a corresponding added line.
5247         if (@$add > 0 && @$add == @$rem) {
5248                 $can_highlight = 1;
5249
5250                 # Highlight lines in combined diff only if the chunk contains
5251                 # diff between the same version, e.g.
5252                 #
5253                 #    - a
5254                 #   -  b
5255                 #    + c
5256                 #   +  d
5257                 #
5258                 # Otherwise the highlightling would be confusing.
5259                 if ($is_combined) {
5260                         for (my $i = 0; $i < @$add; $i++) {
5261                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5262                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5263
5264                                 $prefix_rem =~ s/-/+/g;
5265
5266                                 if ($prefix_rem ne $prefix_add) {
5267                                         $can_highlight = 0;
5268                                         last;
5269                                 }
5270                         }
5271                 }
5272         }
5273
5274         if ($can_highlight) {
5275                 for (my $i = 0; $i < @$add; $i++) {
5276                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5277                                 $rem->[$i], $add->[$i], $num_parents);
5278                         push @new_rem, $line_rem;
5279                         push @new_add, $line_add;
5280                 }
5281         } else {
5282                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5283                 @new_add = map { format_diff_line($_, 'add') } @$add;
5284         }
5285
5286         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5287
5288         return (\@new_ctx, \@new_rem, \@new_add);
5289 }
5290
5291 # Print context lines and then rem/add lines.
5292 sub print_diff_lines {
5293         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5294         my $is_combined = $num_parents > 1;
5295
5296         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5297                 $num_parents);
5298
5299         if ($diff_style eq 'sidebyside' && !$is_combined) {
5300                 print_sidebyside_diff_lines($ctx, $rem, $add);
5301         } else {
5302                 # default 'inline' style and unknown styles
5303                 print_inline_diff_lines($ctx, $rem, $add);
5304         }
5305 }
5306
5307 sub print_diff_chunk {
5308         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5309         my (@ctx, @rem, @add);
5310
5311         # The class of the previous line.
5312         my $prev_class = '';
5313
5314         return unless @chunk;
5315
5316         # incomplete last line might be among removed or added lines,
5317         # or both, or among context lines: find which
5318         for (my $i = 1; $i < @chunk; $i++) {
5319                 if ($chunk[$i][0] eq 'incomplete') {
5320                         $chunk[$i][0] = $chunk[$i-1][0];
5321                 }
5322         }
5323
5324         # guardian
5325         push @chunk, ["", ""];
5326
5327         foreach my $line_info (@chunk) {
5328                 my ($class, $line) = @$line_info;
5329
5330                 # print chunk headers
5331                 if ($class && $class eq 'chunk_header') {
5332                         print format_diff_line($line, $class, $from, $to);
5333                         next;
5334                 }
5335
5336                 ## print from accumulator when have some add/rem lines or end
5337                 # of chunk (flush context lines), or when have add and rem
5338                 # lines and new block is reached (otherwise add/rem lines could
5339                 # be reordered)
5340                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5341                     (@rem && @add && $class ne $prev_class)) {
5342                         print_diff_lines(\@ctx, \@rem, \@add,
5343                                          $diff_style, $num_parents);
5344                         @ctx = @rem = @add = ();
5345                 }
5346
5347                 ## adding lines to accumulator
5348                 # guardian value
5349                 last unless $line;
5350                 # rem, add or change
5351                 if ($class eq 'rem') {
5352                         push @rem, $line;
5353                 } elsif ($class eq 'add') {
5354                         push @add, $line;
5355                 }
5356                 # context line
5357                 if ($class eq 'ctx') {
5358                         push @ctx, $line;
5359                 }
5360
5361                 $prev_class = $class;
5362         }
5363 }
5364
5365 sub git_patchset_body {
5366         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5367         my ($hash_parent) = $hash_parents[0];
5368
5369         my $is_combined = (@hash_parents > 1);
5370         my $patch_idx = 0;
5371         my $patch_number = 0;
5372         my $patch_line;
5373         my $diffinfo;
5374         my $to_name;
5375         my (%from, %to);
5376         my @chunk; # for side-by-side diff
5377
5378         print "<div class=\"patchset\">\n";
5379
5380         # skip to first patch
5381         while ($patch_line = <$fd>) {
5382                 chomp $patch_line;
5383
5384                 last if ($patch_line =~ m/^diff /);
5385         }
5386
5387  PATCH:
5388         while ($patch_line) {
5389
5390                 # parse "git diff" header line
5391                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5392                         # $1 is from_name, which we do not use
5393                         $to_name = unquote($2);
5394                         $to_name =~ s!^b/!!;
5395                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5396                         # $1 is 'cc' or 'combined', which we do not use
5397                         $to_name = unquote($2);
5398                 } else {
5399                         $to_name = undef;
5400                 }
5401
5402                 # check if current patch belong to current raw line
5403                 # and parse raw git-diff line if needed
5404                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5405                         # this is continuation of a split patch
5406                         print "<div class=\"patch cont\">\n";
5407                 } else {
5408                         # advance raw git-diff output if needed
5409                         $patch_idx++ if defined $diffinfo;
5410
5411                         # read and prepare patch information
5412                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5413
5414                         # compact combined diff output can have some patches skipped
5415                         # find which patch (using pathname of result) we are at now;
5416                         if ($is_combined) {
5417                                 while ($to_name ne $diffinfo->{'to_file'}) {
5418                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5419                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5420                                               "</div>\n";  # class="patch"
5421
5422                                         $patch_idx++;
5423                                         $patch_number++;
5424
5425                                         last if $patch_idx > $#$difftree;
5426                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5427                                 }
5428                         }
5429
5430                         # modifies %from, %to hashes
5431                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5432
5433                         # this is first patch for raw difftree line with $patch_idx index
5434                         # we index @$difftree array from 0, but number patches from 1
5435                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5436                 }
5437
5438                 # git diff header
5439                 #assert($patch_line =~ m/^diff /) if DEBUG;
5440                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5441                 $patch_number++;
5442                 # print "git diff" header
5443                 print format_git_diff_header_line($patch_line, $diffinfo,
5444                                                   \%from, \%to);
5445
5446                 # print extended diff header
5447                 print "<div class=\"diff extended_header\">\n";
5448         EXTENDED_HEADER:
5449                 while ($patch_line = <$fd>) {
5450                         chomp $patch_line;
5451
5452                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5453
5454                         print format_extended_diff_header_line($patch_line, $diffinfo,
5455                                                                \%from, \%to);
5456                 }
5457                 print "</div>\n"; # class="diff extended_header"
5458
5459                 # from-file/to-file diff header
5460                 if (! $patch_line) {
5461                         print "</div>\n"; # class="patch"
5462                         last PATCH;
5463                 }
5464                 next PATCH if ($patch_line =~ m/^diff /);
5465                 #assert($patch_line =~ m/^---/) if DEBUG;
5466
5467                 my $last_patch_line = $patch_line;
5468                 $patch_line = <$fd>;
5469                 chomp $patch_line;
5470                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5471
5472                 print format_diff_from_to_header($last_patch_line, $patch_line,
5473                                                  $diffinfo, \%from, \%to,
5474                                                  @hash_parents);
5475
5476                 # the patch itself
5477         LINE:
5478                 while ($patch_line = <$fd>) {
5479                         chomp $patch_line;
5480
5481                         next PATCH if ($patch_line =~ m/^diff /);
5482
5483                         my $class = diff_line_class($patch_line, \%from, \%to);
5484
5485                         if ($class eq 'chunk_header') {
5486                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5487                                 @chunk = ();
5488                         }
5489
5490                         push @chunk, [ $class, $patch_line ];
5491                 }
5492
5493         } continue {
5494                 if (@chunk) {
5495                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5496                         @chunk = ();
5497                 }
5498                 print "</div>\n"; # class="patch"
5499         }
5500
5501         # for compact combined (--cc) format, with chunk and patch simplification
5502         # the patchset might be empty, but there might be unprocessed raw lines
5503         for (++$patch_idx if $patch_number > 0;
5504              $patch_idx < @$difftree;
5505              ++$patch_idx) {
5506                 # read and prepare patch information
5507                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5508
5509                 # generate anchor for "patch" links in difftree / whatchanged part
5510                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5511                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5512                       "</div>\n";  # class="patch"
5513
5514                 $patch_number++;
5515         }
5516
5517         if ($patch_number == 0) {
5518                 if (@hash_parents > 1) {
5519                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5520                 } else {
5521                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5522                 }
5523         }
5524
5525         print "</div>\n"; # class="patchset"
5526 }
5527
5528 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5529
5530 sub git_project_search_form {
5531         my ($searchtext, $search_use_regexp) = @_;
5532
5533         my $limit = '';
5534         if ($project_filter) {
5535                 $limit = " in '$project_filter/'";
5536         }
5537
5538         print "<div class=\"projsearch\">\n";
5539         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5540               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5541         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5542                 if (defined $project_filter);
5543         print $cgi->textfield(-name => 's', -value => $searchtext,
5544                               -title => "Search project by name and description$limit",
5545                               -size => 60) . "\n" .
5546               "<span title=\"Extended regular expression\">" .
5547               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5548                              -checked => $search_use_regexp) .
5549               "</span>\n" .
5550               $cgi->submit(-name => 'btnS', -value => 'Search') .
5551               $cgi->end_form() . "\n" .
5552               $cgi->a({-href => href(project => undef, searchtext => undef,
5553                                      project_filter => $project_filter)},
5554                       esc_html("List all projects$limit")) . "<br />\n";
5555         print "</div>\n";
5556 }
5557
5558 # entry for given @keys needs filling if at least one of keys in list
5559 # is not present in %$project_info
5560 sub project_info_needs_filling {
5561         my ($project_info, @keys) = @_;
5562
5563         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5564         foreach my $key (@keys) {
5565                 if (!exists $project_info->{$key}) {
5566                         return 1;
5567                 }
5568         }
5569         return;
5570 }
5571
5572 # fills project list info (age, description, owner, category, forks, etc.)
5573 # for each project in the list, removing invalid projects from
5574 # returned list, or fill only specified info.
5575 #
5576 # Invalid projects are removed from the returned list if and only if you
5577 # ask 'age' or 'age_string' to be filled, because they are the only fields
5578 # that run unconditionally git command that requires repository, and
5579 # therefore do always check if project repository is invalid.
5580 #
5581 # USAGE:
5582 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5583 #   ensures that 'descr_long' and 'ctags' fields are filled
5584 # * @project_list = fill_project_list_info(\@project_list)
5585 #   ensures that all fields are filled (and invalid projects removed)
5586 #
5587 # NOTE: modifies $projlist, but does not remove entries from it
5588 sub fill_project_list_info {
5589         my ($projlist, @wanted_keys) = @_;
5590         my @projects;
5591         my $filter_set = sub { return @_; };
5592         if (@wanted_keys) {
5593                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5594                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5595         }
5596
5597         my $show_ctags = gitweb_check_feature('ctags');
5598  PROJECT:
5599         foreach my $pr (@$projlist) {
5600                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5601                         my (@activity) = git_get_last_activity($pr->{'path'});
5602                         unless (@activity) {
5603                                 next PROJECT;
5604                         }
5605                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5606                 }
5607                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5608                         my $descr = git_get_project_description($pr->{'path'}) || "";
5609                         $descr = to_utf8($descr);
5610                         $pr->{'descr_long'} = $descr;
5611                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5612                 }
5613                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5614                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5615                 }
5616                 if ($show_ctags &&
5617                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5618                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5619                 }
5620                 if ($projects_list_group_categories &&
5621                     project_info_needs_filling($pr, $filter_set->('category'))) {
5622                         my $cat = git_get_project_category($pr->{'path'}) ||
5623                                                            $project_list_default_category;
5624                         $pr->{'category'} = to_utf8($cat);
5625                 }
5626
5627                 push @projects, $pr;
5628         }
5629
5630         return @projects;
5631 }
5632
5633 sub sort_projects_list {
5634         my ($projlist, $order) = @_;
5635
5636         sub order_str {
5637                 my $key = shift;
5638                 return sub { $a->{$key} cmp $b->{$key} };
5639         }
5640
5641         sub order_num_then_undef {
5642                 my $key = shift;
5643                 return sub {
5644                         defined $a->{$key} ?
5645                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5646                                 (defined $b->{$key} ? 1 : 0)
5647                 };
5648         }
5649
5650         my %orderings = (
5651                 project => order_str('path'),
5652                 descr => order_str('descr_long'),
5653                 owner => order_str('owner'),
5654                 age => order_num_then_undef('age'),
5655         );
5656
5657         my $ordering = $orderings{$order};
5658         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5659 }
5660
5661 # returns a hash of categories, containing the list of project
5662 # belonging to each category
5663 sub build_projlist_by_category {
5664         my ($projlist, $from, $to) = @_;
5665         my %categories;
5666
5667         $from = 0 unless defined $from;
5668         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5669
5670         for (my $i = $from; $i <= $to; $i++) {
5671                 my $pr = $projlist->[$i];
5672                 push @{$categories{ $pr->{'category'} }}, $pr;
5673         }
5674
5675         return wantarray ? %categories : \%categories;
5676 }
5677
5678 # print 'sort by' <th> element, generating 'sort by $name' replay link
5679 # if that order is not selected
5680 sub print_sort_th {
5681         print format_sort_th(@_);
5682 }
5683
5684 sub format_sort_th {
5685         my ($name, $order, $header) = @_;
5686         my $sort_th = "";
5687         $header ||= ucfirst($name);
5688
5689         if ($order eq $name) {
5690                 $sort_th .= "<th>$header</th>\n";
5691         } else {
5692                 $sort_th .= "<th>" .
5693                             $cgi->a({-href => href(-replay=>1, order=>$name),
5694                                      -class => "header"}, $header) .
5695                             "</th>\n";
5696         }
5697
5698         return $sort_th;
5699 }
5700
5701 sub git_project_list_rows {
5702         my ($projlist, $from, $to, $check_forks) = @_;
5703
5704         $from = 0 unless defined $from;
5705         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5706
5707         my $alternate = 1;
5708         for (my $i = $from; $i <= $to; $i++) {
5709                 my $pr = $projlist->[$i];
5710
5711                 if ($alternate) {
5712                         print "<tr class=\"dark\">\n";
5713                 } else {
5714                         print "<tr class=\"light\">\n";
5715                 }
5716                 $alternate ^= 1;
5717
5718                 if ($check_forks) {
5719                         print "<td>";
5720                         if ($pr->{'forks'}) {
5721                                 my $nforks = scalar @{$pr->{'forks'}};
5722                                 if ($nforks > 0) {
5723                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5724                                                        -title => "$nforks forks"}, "+");
5725                                 } else {
5726                                         print $cgi->span({-title => "$nforks forks"}, "+");
5727                                 }
5728                         }
5729                         print "</td>\n";
5730                 }
5731                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5732                                         -class => "list"},
5733                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5734                       "</td>\n" .
5735                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5736                                         -class => "list",
5737                                         -title => $pr->{'descr_long'}},
5738                                         $search_regexp
5739                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5740                                                                     $pr->{'descr'}, $search_regexp)
5741                                         : esc_html($pr->{'descr'})) .
5742                       "</td>\n";
5743                 unless ($omit_owner) {
5744                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5745                 }
5746                 unless ($omit_age_column) {
5747                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5748                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5749                 }
5750                 print"<td class=\"link\">" .
5751                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5752                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5753                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5754                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5755                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5756                       "</td>\n" .
5757                       "</tr>\n";
5758         }
5759 }
5760
5761 sub git_project_list_body {
5762         # actually uses global variable $project
5763         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5764         my @projects = @$projlist;
5765
5766         my $check_forks = gitweb_check_feature('forks');
5767         my $show_ctags  = gitweb_check_feature('ctags');
5768         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5769         $check_forks = undef
5770                 if ($tagfilter || $search_regexp);
5771
5772         # filtering out forks before filling info allows to do less work
5773         @projects = filter_forks_from_projects_list(\@projects)
5774                 if ($check_forks);
5775         # search_projects_list pre-fills required info
5776         @projects = search_projects_list(\@projects,
5777                                          'search_regexp' => $search_regexp,
5778                                          'tagfilter'  => $tagfilter)
5779                 if ($tagfilter || $search_regexp);
5780         # fill the rest
5781         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5782         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5783         push @all_fields, 'owner' unless($omit_owner);
5784         @projects = fill_project_list_info(\@projects, @all_fields);
5785
5786         $order ||= $default_projects_order;
5787         $from = 0 unless defined $from;
5788         $to = $#projects if (!defined $to || $#projects < $to);
5789
5790         # short circuit
5791         if ($from > $to) {
5792                 print "<center>\n".
5793                       "<b>No such projects found</b><br />\n".
5794                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5795                       "</center>\n<br />\n";
5796                 return;
5797         }
5798
5799         @projects = sort_projects_list(\@projects, $order);
5800
5801         if ($show_ctags) {
5802                 my $ctags = git_gather_all_ctags(\@projects);
5803                 my $cloud = git_populate_project_tagcloud($ctags);
5804                 print git_show_project_tagcloud($cloud, 64);
5805         }
5806
5807         print "<table class=\"project_list\">\n";
5808         unless ($no_header) {
5809                 print "<tr>\n";
5810                 if ($check_forks) {
5811                         print "<th></th>\n";
5812                 }
5813                 print_sort_th('project', $order, 'Project');
5814                 print_sort_th('descr', $order, 'Description');
5815                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5816                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5817                 print "<th></th>\n" . # for links
5818                       "</tr>\n";
5819         }
5820
5821         if ($projects_list_group_categories) {
5822                 # only display categories with projects in the $from-$to window
5823                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5824                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5825                 foreach my $cat (sort keys %categories) {
5826                         unless ($cat eq "") {
5827                                 print "<tr>\n";
5828                                 if ($check_forks) {
5829                                         print "<td></td>\n";
5830                                 }
5831                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5832                                 print "</tr>\n";
5833                         }
5834
5835                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5836                 }
5837         } else {
5838                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5839         }
5840
5841         if (defined $extra) {
5842                 print "<tr>\n";
5843                 if ($check_forks) {
5844                         print "<td></td>\n";
5845                 }
5846                 print "<td colspan=\"5\">$extra</td>\n" .
5847                       "</tr>\n";
5848         }
5849         print "</table>\n";
5850 }
5851
5852 sub git_log_body {
5853         # uses global variable $project
5854         my ($commitlist, $from, $to, $refs, $extra) = @_;
5855
5856         $from = 0 unless defined $from;
5857         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5858
5859         for (my $i = 0; $i <= $to; $i++) {
5860                 my %co = %{$commitlist->[$i]};
5861                 next if !%co;
5862                 my $commit = $co{'id'};
5863                 my $ref = format_ref_marker($refs, $commit);
5864                 git_print_header_div('commit',
5865                                "<span class=\"age\">$co{'age_string'}</span>" .
5866                                esc_html($co{'title'}) . $ref,
5867                                $commit);
5868                 print "<div class=\"title_text\">\n" .
5869                       "<div class=\"log_link\">\n" .
5870                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5871                       " | " .
5872                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5873                       " | " .
5874                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5875                       "<br/>\n" .
5876                       "</div>\n";
5877                       git_print_authorship(\%co, -tag => 'span');
5878                       print "<br/>\n</div>\n";
5879
5880                 print "<div class=\"log_body\">\n";
5881                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5882                 print "</div>\n";
5883         }
5884         if ($extra) {
5885                 print "<div class=\"page_nav\">\n";
5886                 print "$extra\n";
5887                 print "</div>\n";
5888         }
5889 }
5890
5891 sub git_shortlog_body {
5892         # uses global variable $project
5893         my ($commitlist, $from, $to, $refs, $extra) = @_;
5894
5895         $from = 0 unless defined $from;
5896         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5897
5898         print "<table class=\"shortlog\">\n";
5899         my $alternate = 1;
5900         for (my $i = $from; $i <= $to; $i++) {
5901                 my %co = %{$commitlist->[$i]};
5902                 my $commit = $co{'id'};
5903                 my $ref = format_ref_marker($refs, $commit);
5904                 if ($alternate) {
5905                         print "<tr class=\"dark\">\n";
5906                 } else {
5907                         print "<tr class=\"light\">\n";
5908                 }
5909                 $alternate ^= 1;
5910                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5911                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5912                       format_author_html('td', \%co, 10) . "<td>";
5913                 print format_subject_html($co{'title'}, $co{'title_short'},
5914                                           href(action=>"commit", hash=>$commit), $ref);
5915                 print "</td>\n" .
5916                       "<td class=\"link\">" .
5917                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5918                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5919                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5920                 my $snapshot_links = format_snapshot_links($commit);
5921                 if (defined $snapshot_links) {
5922                         print " | " . $snapshot_links;
5923                 }
5924                 print "</td>\n" .
5925                       "</tr>\n";
5926         }
5927         if (defined $extra) {
5928                 print "<tr>\n" .
5929                       "<td colspan=\"4\">$extra</td>\n" .
5930                       "</tr>\n";
5931         }
5932         print "</table>\n";
5933 }
5934
5935 sub git_history_body {
5936         # Warning: assumes constant type (blob or tree) during history
5937         my ($commitlist, $from, $to, $refs, $extra,
5938             $file_name, $file_hash, $ftype) = @_;
5939
5940         $from = 0 unless defined $from;
5941         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5942
5943         print "<table class=\"history\">\n";
5944         my $alternate = 1;
5945         for (my $i = $from; $i <= $to; $i++) {
5946                 my %co = %{$commitlist->[$i]};
5947                 if (!%co) {
5948                         next;
5949                 }
5950                 my $commit = $co{'id'};
5951
5952                 my $ref = format_ref_marker($refs, $commit);
5953
5954                 if ($alternate) {
5955                         print "<tr class=\"dark\">\n";
5956                 } else {
5957                         print "<tr class=\"light\">\n";
5958                 }
5959                 $alternate ^= 1;
5960                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5961         # shortlog:   format_author_html('td', \%co, 10)
5962                       format_author_html('td', \%co, 15, 3) . "<td>";
5963                 # originally git_history used chop_str($co{'title'}, 50)
5964                 print format_subject_html($co{'title'}, $co{'title_short'},
5965                                           href(action=>"commit", hash=>$commit), $ref);
5966                 print "</td>\n" .
5967                       "<td class=\"link\">" .
5968                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5969                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5970
5971                 if ($ftype eq 'blob') {
5972                         my $blob_current = $file_hash;
5973                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5974                         if (defined $blob_current && defined $blob_parent &&
5975                                         $blob_current ne $blob_parent) {
5976                                 print " | " .
5977                                         $cgi->a({-href => href(action=>"blobdiff",
5978                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5979                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5980                                                                file_name=>$file_name)},
5981                                                 "diff to current");
5982                         }
5983                 }
5984                 print "</td>\n" .
5985                       "</tr>\n";
5986         }
5987         if (defined $extra) {
5988                 print "<tr>\n" .
5989                       "<td colspan=\"4\">$extra</td>\n" .
5990                       "</tr>\n";
5991         }
5992         print "</table>\n";
5993 }
5994
5995 sub git_tags_body {
5996         # uses global variable $project
5997         my ($taglist, $from, $to, $extra) = @_;
5998         $from = 0 unless defined $from;
5999         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
6000
6001         print "<table class=\"tags\">\n";
6002         my $alternate = 1;
6003         for (my $i = $from; $i <= $to; $i++) {
6004                 my $entry = $taglist->[$i];
6005                 my %tag = %$entry;
6006                 my $comment = $tag{'subject'};
6007                 my $comment_short;
6008                 if (defined $comment) {
6009                         $comment_short = chop_str($comment, 30, 5);
6010                 }
6011                 if ($alternate) {
6012                         print "<tr class=\"dark\">\n";
6013                 } else {
6014                         print "<tr class=\"light\">\n";
6015                 }
6016                 $alternate ^= 1;
6017                 if (defined $tag{'age'}) {
6018                         print "<td><i>$tag{'age'}</i></td>\n";
6019                 } else {
6020                         print "<td></td>\n";
6021                 }
6022                 print "<td>" .
6023                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6024                                -class => "list name"}, esc_html($tag{'name'})) .
6025                       "</td>\n" .
6026                       "<td>";
6027                 if (defined $comment) {
6028                         print format_subject_html($comment, $comment_short,
6029                                                   href(action=>"tag", hash=>$tag{'id'}));
6030                 }
6031                 print "</td>\n" .
6032                       "<td class=\"selflink\">";
6033                 if ($tag{'type'} eq "tag") {
6034                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6035                 } else {
6036                         print "&nbsp;";
6037                 }
6038                 print "</td>\n" .
6039                       "<td class=\"link\">" . " | " .
6040                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6041                 if ($tag{'reftype'} eq "commit") {
6042                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6043                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6044                 } elsif ($tag{'reftype'} eq "blob") {
6045                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6046                 }
6047                 print "</td>\n" .
6048                       "</tr>";
6049         }
6050         if (defined $extra) {
6051                 print "<tr>\n" .
6052                       "<td colspan=\"5\">$extra</td>\n" .
6053                       "</tr>\n";
6054         }
6055         print "</table>\n";
6056 }
6057
6058 sub git_heads_body {
6059         # uses global variable $project
6060         my ($headlist, $head_at, $from, $to, $extra) = @_;
6061         $from = 0 unless defined $from;
6062         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6063
6064         print "<table class=\"heads\">\n";
6065         my $alternate = 1;
6066         for (my $i = $from; $i <= $to; $i++) {
6067                 my $entry = $headlist->[$i];
6068                 my %ref = %$entry;
6069                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6070                 if ($alternate) {
6071                         print "<tr class=\"dark\">\n";
6072                 } else {
6073                         print "<tr class=\"light\">\n";
6074                 }
6075                 $alternate ^= 1;
6076                 print "<td><i>$ref{'age'}</i></td>\n" .
6077                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6078                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6079                                -class => "list name"},esc_html($ref{'name'})) .
6080                       "</td>\n" .
6081                       "<td class=\"link\">" .
6082                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6083                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6084                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6085                       "</td>\n" .
6086                       "</tr>";
6087         }
6088         if (defined $extra) {
6089                 print "<tr>\n" .
6090                       "<td colspan=\"3\">$extra</td>\n" .
6091                       "</tr>\n";
6092         }
6093         print "</table>\n";
6094 }
6095
6096 # Display a single remote block
6097 sub git_remote_block {
6098         my ($remote, $rdata, $limit, $head) = @_;
6099
6100         my $heads = $rdata->{'heads'};
6101         my $fetch = $rdata->{'fetch'};
6102         my $push = $rdata->{'push'};
6103
6104         my $urls_table = "<table class=\"projects_list\">\n" ;
6105
6106         if (defined $fetch) {
6107                 if ($fetch eq $push) {
6108                         $urls_table .= format_repo_url("URL", $fetch);
6109                 } else {
6110                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6111                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6112                 }
6113         } elsif (defined $push) {
6114                 $urls_table .= format_repo_url("Push URL", $push);
6115         } else {
6116                 $urls_table .= format_repo_url("", "No remote URL");
6117         }
6118
6119         $urls_table .= "</table>\n";
6120
6121         my $dots;
6122         if (defined $limit && $limit < @$heads) {
6123                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6124         }
6125
6126         print $urls_table;
6127         git_heads_body($heads, $head, 0, $limit, $dots);
6128 }
6129
6130 # Display a list of remote names with the respective fetch and push URLs
6131 sub git_remotes_list {
6132         my ($remotedata, $limit) = @_;
6133         print "<table class=\"heads\">\n";
6134         my $alternate = 1;
6135         my @remotes = sort keys %$remotedata;
6136
6137         my $limited = $limit && $limit < @remotes;
6138
6139         $#remotes = $limit - 1 if $limited;
6140
6141         while (my $remote = shift @remotes) {
6142                 my $rdata = $remotedata->{$remote};
6143                 my $fetch = $rdata->{'fetch'};
6144                 my $push = $rdata->{'push'};
6145                 if ($alternate) {
6146                         print "<tr class=\"dark\">\n";
6147                 } else {
6148                         print "<tr class=\"light\">\n";
6149                 }
6150                 $alternate ^= 1;
6151                 print "<td>" .
6152                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6153                                -class=> "list name"},esc_html($remote)) .
6154                       "</td>";
6155                 print "<td class=\"link\">" .
6156                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6157                       " | " .
6158                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6159                       "</td>";
6160
6161                 print "</tr>\n";
6162         }
6163
6164         if ($limited) {
6165                 print "<tr>\n" .
6166                       "<td colspan=\"3\">" .
6167                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6168                       "</td>\n" . "</tr>\n";
6169         }
6170
6171         print "</table>";
6172 }
6173
6174 # Display remote heads grouped by remote, unless there are too many
6175 # remotes, in which case we only display the remote names
6176 sub git_remotes_body {
6177         my ($remotedata, $limit, $head) = @_;
6178         if ($limit and $limit < keys %$remotedata) {
6179                 git_remotes_list($remotedata, $limit);
6180         } else {
6181                 fill_remote_heads($remotedata);
6182                 while (my ($remote, $rdata) = each %$remotedata) {
6183                         git_print_section({-class=>"remote", -id=>$remote},
6184                                 ["remotes", $remote, $remote], sub {
6185                                         git_remote_block($remote, $rdata, $limit, $head);
6186                                 });
6187                 }
6188         }
6189 }
6190
6191 sub git_search_message {
6192         my %co = @_;
6193
6194         my $greptype;
6195         if ($searchtype eq 'commit') {
6196                 $greptype = "--grep=";
6197         } elsif ($searchtype eq 'author') {
6198                 $greptype = "--author=";
6199         } elsif ($searchtype eq 'committer') {
6200                 $greptype = "--committer=";
6201         }
6202         $greptype .= $searchtext;
6203         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6204                                        $greptype, '--regexp-ignore-case',
6205                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6206
6207         my $paging_nav = '';
6208         if ($page > 0) {
6209                 $paging_nav .=
6210                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6211                                 "first") .
6212                         " &sdot; " .
6213                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6214                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6215         } else {
6216                 $paging_nav .= "first &sdot; prev";
6217         }
6218         my $next_link = '';
6219         if ($#commitlist >= 100) {
6220                 $next_link =
6221                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6222                                  -accesskey => "n", -title => "Alt-n"}, "next");
6223                 $paging_nav .= " &sdot; $next_link";
6224         } else {
6225                 $paging_nav .= " &sdot; next";
6226         }
6227
6228         git_header_html();
6229
6230         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6231         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6232         if ($page == 0 && !@commitlist) {
6233                 print "<p>No match.</p>\n";
6234         } else {
6235                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6236         }
6237
6238         git_footer_html();
6239 }
6240
6241 sub git_search_changes {
6242         my %co = @_;
6243
6244         local $/ = "\n";
6245         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6246                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6247                 ($search_use_regexp ? '--pickaxe-regex' : ())
6248                         or die_error(500, "Open git-log failed");
6249
6250         git_header_html();
6251
6252         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6253         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6254
6255         print "<table class=\"pickaxe search\">\n";
6256         my $alternate = 1;
6257         undef %co;
6258         my @files;
6259         while (my $line = <$fd>) {
6260                 chomp $line;
6261                 next unless $line;
6262
6263                 my %set = parse_difftree_raw_line($line);
6264                 if (defined $set{'commit'}) {
6265                         # finish previous commit
6266                         if (%co) {
6267                                 print "</td>\n" .
6268                                       "<td class=\"link\">" .
6269                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6270                                               "commit") .
6271                                       " | " .
6272                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6273                                                              hash_base=>$co{'id'})},
6274                                               "tree") .
6275                                       "</td>\n" .
6276                                       "</tr>\n";
6277                         }
6278
6279                         if ($alternate) {
6280                                 print "<tr class=\"dark\">\n";
6281                         } else {
6282                                 print "<tr class=\"light\">\n";
6283                         }
6284                         $alternate ^= 1;
6285                         %co = parse_commit($set{'commit'});
6286                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6287                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6288                               "<td><i>$author</i></td>\n" .
6289                               "<td>" .
6290                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6291                                       -class => "list subject"},
6292                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6293                 } elsif (defined $set{'to_id'}) {
6294                         next if ($set{'to_id'} =~ m/^0{40}$/);
6295
6296                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6297                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6298                                       -class => "list"},
6299                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6300                               "<br/>\n";
6301                 }
6302         }
6303         close $fd;
6304
6305         # finish last commit (warning: repetition!)
6306         if (%co) {
6307                 print "</td>\n" .
6308                       "<td class=\"link\">" .
6309                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6310                               "commit") .
6311                       " | " .
6312                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6313                                              hash_base=>$co{'id'})},
6314                               "tree") .
6315                       "</td>\n" .
6316                       "</tr>\n";
6317         }
6318
6319         print "</table>\n";
6320
6321         git_footer_html();
6322 }
6323
6324 sub git_search_files {
6325         my %co = @_;
6326
6327         local $/ = "\n";
6328         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6329                 $search_use_regexp ? ('-E', '-i') : '-F',
6330                 $searchtext, $co{'tree'}
6331                         or die_error(500, "Open git-grep failed");
6332
6333         git_header_html();
6334
6335         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6336         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6337
6338         print "<table class=\"grep_search\">\n";
6339         my $alternate = 1;
6340         my $matches = 0;
6341         my $lastfile = '';
6342         my $file_href;
6343         while (my $line = <$fd>) {
6344                 chomp $line;
6345                 my ($file, $lno, $ltext, $binary);
6346                 last if ($matches++ > 1000);
6347                 if ($line =~ /^Binary file (.+) matches$/) {
6348                         $file = $1;
6349                         $binary = 1;
6350                 } else {
6351                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6352                         $file =~ s/^$co{'tree'}://;
6353                 }
6354                 if ($file ne $lastfile) {
6355                         $lastfile and print "</td></tr>\n";
6356                         if ($alternate++) {
6357                                 print "<tr class=\"dark\">\n";
6358                         } else {
6359                                 print "<tr class=\"light\">\n";
6360                         }
6361                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6362                                           file_name=>$file);
6363                         print "<td class=\"list\">".
6364                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6365                         print "</td><td>\n";
6366                         $lastfile = $file;
6367                 }
6368                 if ($binary) {
6369                         print "<div class=\"binary\">Binary file</div>\n";
6370                 } else {
6371                         $ltext = untabify($ltext);
6372                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6373                                 $ltext = esc_html($1, -nbsp=>1);
6374                                 $ltext .= '<span class="match">';
6375                                 $ltext .= esc_html($2, -nbsp=>1);
6376                                 $ltext .= '</span>';
6377                                 $ltext .= esc_html($3, -nbsp=>1);
6378                         } else {
6379                                 $ltext = esc_html($ltext, -nbsp=>1);
6380                         }
6381                         print "<div class=\"pre\">" .
6382                                 $cgi->a({-href => $file_href.'#l'.$lno,
6383                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6384                                 ' ' .  $ltext . "</div>\n";
6385                 }
6386         }
6387         if ($lastfile) {
6388                 print "</td></tr>\n";
6389                 if ($matches > 1000) {
6390                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6391                 }
6392         } else {
6393                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6394         }
6395         close $fd;
6396
6397         print "</table>\n";
6398
6399         git_footer_html();
6400 }
6401
6402 sub git_search_grep_body {
6403         my ($commitlist, $from, $to, $extra) = @_;
6404         $from = 0 unless defined $from;
6405         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6406
6407         print "<table class=\"commit_search\">\n";
6408         my $alternate = 1;
6409         for (my $i = $from; $i <= $to; $i++) {
6410                 my %co = %{$commitlist->[$i]};
6411                 if (!%co) {
6412                         next;
6413                 }
6414                 my $commit = $co{'id'};
6415                 if ($alternate) {
6416                         print "<tr class=\"dark\">\n";
6417                 } else {
6418                         print "<tr class=\"light\">\n";
6419                 }
6420                 $alternate ^= 1;
6421                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6422                       format_author_html('td', \%co, 15, 5) .
6423                       "<td>" .
6424                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6425                                -class => "list subject"},
6426                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6427                 my $comment = $co{'comment'};
6428                 foreach my $line (@$comment) {
6429                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6430                                 my ($lead, $match, $trail) = ($1, $2, $3);
6431                                 $match = chop_str($match, 70, 5, 'center');
6432                                 my $contextlen = int((80 - length($match))/2);
6433                                 $contextlen = 30 if ($contextlen > 30);
6434                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6435                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6436
6437                                 $lead  = esc_html($lead);
6438                                 $match = esc_html($match);
6439                                 $trail = esc_html($trail);
6440
6441                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6442                         }
6443                 }
6444                 print "</td>\n" .
6445                       "<td class=\"link\">" .
6446                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6447                       " | " .
6448                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6449                       " | " .
6450                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6451                 print "</td>\n" .
6452                       "</tr>\n";
6453         }
6454         if (defined $extra) {
6455                 print "<tr>\n" .
6456                       "<td colspan=\"3\">$extra</td>\n" .
6457                       "</tr>\n";
6458         }
6459         print "</table>\n";
6460 }
6461
6462 ## ======================================================================
6463 ## ======================================================================
6464 ## actions
6465
6466 sub git_project_list {
6467         my $order = $input_params{'order'};
6468         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6469                 die_error(400, "Unknown order parameter");
6470         }
6471
6472         my @list = git_get_projects_list($project_filter, $strict_export);
6473         if (!@list) {
6474                 die_error(404, "No projects found");
6475         }
6476
6477         git_header_html();
6478         if (defined $home_text && -f $home_text) {
6479                 print "<div class=\"index_include\">\n";
6480                 insert_file($home_text);
6481                 print "</div>\n";
6482         }
6483
6484         git_project_search_form($searchtext, $search_use_regexp);
6485         git_project_list_body(\@list, $order);
6486         git_footer_html();
6487 }
6488
6489 sub git_forks {
6490         my $order = $input_params{'order'};
6491         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6492                 die_error(400, "Unknown order parameter");
6493         }
6494
6495         my $filter = $project;
6496         $filter =~ s/\.git$//;
6497         my @list = git_get_projects_list($filter);
6498         if (!@list) {
6499                 die_error(404, "No forks found");
6500         }
6501
6502         git_header_html();
6503         git_print_page_nav('','');
6504         git_print_header_div('summary', "$project forks");
6505         git_project_list_body(\@list, $order);
6506         git_footer_html();
6507 }
6508
6509 sub git_project_index {
6510         my @projects = git_get_projects_list($project_filter, $strict_export);
6511         if (!@projects) {
6512                 die_error(404, "No projects found");
6513         }
6514
6515         print $cgi->header(
6516                 -type => 'text/plain',
6517                 -charset => 'utf-8',
6518                 -content_disposition => 'inline; filename="index.aux"');
6519
6520         foreach my $pr (@projects) {
6521                 if (!exists $pr->{'owner'}) {
6522                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6523                 }
6524
6525                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6526                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6527                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6528                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6529                 $path  =~ s/ /\+/g;
6530                 $owner =~ s/ /\+/g;
6531
6532                 print "$path $owner\n";
6533         }
6534 }
6535
6536 sub git_summary {
6537         my $descr = git_get_project_description($project) || "none";
6538         my %co = parse_commit("HEAD");
6539         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6540         my $head = $co{'id'};
6541         my $remote_heads = gitweb_check_feature('remote_heads');
6542
6543         my $owner = git_get_project_owner($project);
6544
6545         my $refs = git_get_references();
6546         # These get_*_list functions return one more to allow us to see if
6547         # there are more ...
6548         my @taglist  = git_get_tags_list(16);
6549         my @headlist = git_get_heads_list(16);
6550         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6551         my @forklist;
6552         my $check_forks = gitweb_check_feature('forks');
6553
6554         if ($check_forks) {
6555                 # find forks of a project
6556                 my $filter = $project;
6557                 $filter =~ s/\.git$//;
6558                 @forklist = git_get_projects_list($filter);
6559                 # filter out forks of forks
6560                 @forklist = filter_forks_from_projects_list(\@forklist)
6561                         if (@forklist);
6562         }
6563
6564         git_header_html();
6565         git_print_page_nav('summary','', $head);
6566
6567         print "<div class=\"title\">&nbsp;</div>\n";
6568         print "<table class=\"projects_list\">\n" .
6569               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6570         if ($owner and not $omit_owner) {
6571                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . email_obfuscate($owner) . "</td></tr>\n";
6572         }
6573         if (defined $cd{'rfc2822'}) {
6574                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6575                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6576         }
6577
6578         # use per project git URL list in $projectroot/$project/cloneurl
6579         # or make project git URL from git base URL and project name
6580         my $url_tag = "URL";
6581         my @url_list = git_get_project_url_list($project);
6582         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6583         foreach my $git_url (@url_list) {
6584                 next unless $git_url;
6585                 print format_repo_url($url_tag, $git_url);
6586                 $url_tag = "";
6587         }
6588
6589         # Tag cloud
6590         my $show_ctags = gitweb_check_feature('ctags');
6591         if ($show_ctags) {
6592                 my $ctags = git_get_project_ctags($project);
6593                 if (%$ctags) {
6594                         # without ability to add tags, don't show if there are none
6595                         my $cloud = git_populate_project_tagcloud($ctags);
6596                         print "<tr id=\"metadata_ctags\">" .
6597                               "<td>content tags</td>" .
6598                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6599                               "</tr>\n";
6600                 }
6601         }
6602
6603         print "</table>\n";
6604
6605         # If XSS prevention is on, we don't include README.html.
6606         # TODO: Allow a readme in some safe format.
6607         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6608                 print "<div class=\"title\">readme</div>\n" .
6609                       "<div class=\"readme\">\n";
6610                 insert_file("$projectroot/$project/README.html");
6611                 print "\n</div>\n"; # class="readme"
6612         }
6613
6614         # we need to request one more than 16 (0..15) to check if
6615         # those 16 are all
6616         my @commitlist = $head ? parse_commits($head, 17) : ();
6617         if (@commitlist) {
6618                 git_print_header_div('shortlog');
6619                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6620                                   $#commitlist <=  15 ? undef :
6621                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6622         }
6623
6624         if (@taglist) {
6625                 git_print_header_div('tags');
6626                 git_tags_body(\@taglist, 0, 15,
6627                               $#taglist <=  15 ? undef :
6628                               $cgi->a({-href => href(action=>"tags")}, "..."));
6629         }
6630
6631         if (@headlist) {
6632                 git_print_header_div('heads');
6633                 git_heads_body(\@headlist, $head, 0, 15,
6634                                $#headlist <= 15 ? undef :
6635                                $cgi->a({-href => href(action=>"heads")}, "..."));
6636         }
6637
6638         if (%remotedata) {
6639                 git_print_header_div('remotes');
6640                 git_remotes_body(\%remotedata, 15, $head);
6641         }
6642
6643         if (@forklist) {
6644                 git_print_header_div('forks');
6645                 git_project_list_body(\@forklist, 'age', 0, 15,
6646                                       $#forklist <= 15 ? undef :
6647                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6648                                       'no_header');
6649         }
6650
6651         git_footer_html();
6652 }
6653
6654 sub git_tag {
6655         my %tag = parse_tag($hash);
6656
6657         if (! %tag) {
6658                 die_error(404, "Unknown tag object");
6659         }
6660
6661         my $head = git_get_head_hash($project);
6662         git_header_html();
6663         git_print_page_nav('','', $head,undef,$head);
6664         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6665         print "<div class=\"title_text\">\n" .
6666               "<table class=\"object_header\">\n" .
6667               "<tr>\n" .
6668               "<td>object</td>\n" .
6669               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6670                                $tag{'object'}) . "</td>\n" .
6671               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6672                                               $tag{'type'}) . "</td>\n" .
6673               "</tr>\n";
6674         if (defined($tag{'author'})) {
6675                 git_print_authorship_rows(\%tag, 'author');
6676         }
6677         print "</table>\n\n" .
6678               "</div>\n";
6679         print "<div class=\"page_body\">";
6680         my $comment = $tag{'comment'};
6681         foreach my $line (@$comment) {
6682                 chomp $line;
6683                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6684         }
6685         print "</div>\n";
6686         git_footer_html();
6687 }
6688
6689 sub git_blame_common {
6690         my $format = shift || 'porcelain';
6691         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6692                 $format = 'incremental';
6693                 $action = 'blame_incremental'; # for page title etc
6694         }
6695
6696         # permissions
6697         gitweb_check_feature('blame')
6698                 or die_error(403, "Blame view not allowed");
6699
6700         # error checking
6701         die_error(400, "No file name given") unless $file_name;
6702         $hash_base ||= git_get_head_hash($project);
6703         die_error(404, "Couldn't find base commit") unless $hash_base;
6704         my %co = parse_commit($hash_base)
6705                 or die_error(404, "Commit not found");
6706         my $ftype = "blob";
6707         if (!defined $hash) {
6708                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6709                         or die_error(404, "Error looking up file");
6710         } else {
6711                 $ftype = git_get_type($hash);
6712                 if ($ftype !~ "blob") {
6713                         die_error(400, "Object is not a blob");
6714                 }
6715         }
6716
6717         my $fd;
6718         if ($format eq 'incremental') {
6719                 # get file contents (as base)
6720                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6721                         or die_error(500, "Open git-cat-file failed");
6722         } elsif ($format eq 'data') {
6723                 # run git-blame --incremental
6724                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6725                         $hash_base, "--", $file_name
6726                         or die_error(500, "Open git-blame --incremental failed");
6727         } else {
6728                 # run git-blame --porcelain
6729                 open $fd, "-|", git_cmd(), "blame", '-p',
6730                         $hash_base, '--', $file_name
6731                         or die_error(500, "Open git-blame --porcelain failed");
6732         }
6733         binmode $fd, ':utf8';
6734
6735         # incremental blame data returns early
6736         if ($format eq 'data') {
6737                 print $cgi->header(
6738                         -type=>"text/plain", -charset => "utf-8",
6739                         -status=> "200 OK");
6740                 local $| = 1; # output autoflush
6741                 while (my $line = <$fd>) {
6742                         print to_utf8($line);
6743                 }
6744                 close $fd
6745                         or print "ERROR $!\n";
6746
6747                 print 'END';
6748                 if (defined $t0 && gitweb_check_feature('timed')) {
6749                         print ' '.
6750                               tv_interval($t0, [ gettimeofday() ]).
6751                               ' '.$number_of_git_cmds;
6752                 }
6753                 print "\n";
6754
6755                 return;
6756         }
6757
6758         # page header
6759         git_header_html();
6760         my $formats_nav =
6761                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6762                         "blob") .
6763                 " | ";
6764         if ($format eq 'incremental') {
6765                 $formats_nav .=
6766                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6767                                 "blame") . " (non-incremental)";
6768         } else {
6769                 $formats_nav .=
6770                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6771                                 "blame") . " (incremental)";
6772         }
6773         $formats_nav .=
6774                 " | " .
6775                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6776                         "history") .
6777                 " | " .
6778                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6779                         "HEAD");
6780         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6781         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6782         git_print_page_path($file_name, $ftype, $hash_base);
6783
6784         # page body
6785         if ($format eq 'incremental') {
6786                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6787                       "This page requires JavaScript to run.\n Use ".
6788                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6789                               'this page').
6790                       " instead.\n".
6791                       "</b></center></div>\n</noscript>\n";
6792
6793                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6794         }
6795
6796         print qq!<div class="page_body">\n!;
6797         print qq!<div id="progress_info">... / ...</div>\n!
6798                 if ($format eq 'incremental');
6799         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6800               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6801               qq!<thead>\n!.
6802               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6803               qq!</thead>\n!.
6804               qq!<tbody>\n!;
6805
6806         my @rev_color = qw(light dark);
6807         my $num_colors = scalar(@rev_color);
6808         my $current_color = 0;
6809
6810         if ($format eq 'incremental') {
6811                 my $color_class = $rev_color[$current_color];
6812
6813                 #contents of a file
6814                 my $linenr = 0;
6815         LINE:
6816                 while (my $line = <$fd>) {
6817                         chomp $line;
6818                         $linenr++;
6819
6820                         print qq!<tr id="l$linenr" class="$color_class">!.
6821                               qq!<td class="sha1"><a href=""> </a></td>!.
6822                               qq!<td class="linenr">!.
6823                               qq!<a class="linenr" href="">$linenr</a></td>!;
6824                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6825                         print qq!</tr>\n!;
6826                 }
6827
6828         } else { # porcelain, i.e. ordinary blame
6829                 my %metainfo = (); # saves information about commits
6830
6831                 # blame data
6832         LINE:
6833                 while (my $line = <$fd>) {
6834                         chomp $line;
6835                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6836                         # no <lines in group> for subsequent lines in group of lines
6837                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6838                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6839                         if (!exists $metainfo{$full_rev}) {
6840                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6841                         }
6842                         my $meta = $metainfo{$full_rev};
6843                         my $data;
6844                         while ($data = <$fd>) {
6845                                 chomp $data;
6846                                 last if ($data =~ s/^\t//); # contents of line
6847                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6848                                         $meta->{$1} = $2 unless exists $meta->{$1};
6849                                 }
6850                                 if ($data =~ /^previous /) {
6851                                         $meta->{'nprevious'}++;
6852                                 }
6853                         }
6854                         my $short_rev = substr($full_rev, 0, 8);
6855                         my $author = $meta->{'author'};
6856                         my %date =
6857                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6858                         my $date = $date{'iso-tz'};
6859                         if ($group_size) {
6860                                 $current_color = ($current_color + 1) % $num_colors;
6861                         }
6862                         my $tr_class = $rev_color[$current_color];
6863                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6864                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6865                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6866                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6867                         if ($group_size) {
6868                                 print "<td class=\"sha1\"";
6869                                 print " title=\"". esc_html($author) . ", $date\"";
6870                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6871                                 print ">";
6872                                 print $cgi->a({-href => href(action=>"commit",
6873                                                              hash=>$full_rev,
6874                                                              file_name=>$file_name)},
6875                                               esc_html($short_rev));
6876                                 if ($group_size >= 2) {
6877                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6878                                         if (@author_initials) {
6879                                                 print "<br />" .
6880                                                       esc_html(join('', @author_initials));
6881                                                 #           or join('.', ...)
6882                                         }
6883                                 }
6884                                 print "</td>\n";
6885                         }
6886                         # 'previous' <sha1 of parent commit> <filename at commit>
6887                         if (exists $meta->{'previous'} &&
6888                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6889                                 $meta->{'parent'} = $1;
6890                                 $meta->{'file_parent'} = unquote($2);
6891                         }
6892                         my $linenr_commit =
6893                                 exists($meta->{'parent'}) ?
6894                                 $meta->{'parent'} : $full_rev;
6895                         my $linenr_filename =
6896                                 exists($meta->{'file_parent'}) ?
6897                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6898                         my $blamed = href(action => 'blame',
6899                                           file_name => $linenr_filename,
6900                                           hash_base => $linenr_commit);
6901                         print "<td class=\"linenr\">";
6902                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6903                                         -class => "linenr" },
6904                                       esc_html($lineno));
6905                         print "</td>";
6906                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6907                         print "</tr>\n";
6908                 } # end while
6909
6910         }
6911
6912         # footer
6913         print "</tbody>\n".
6914               "</table>\n"; # class="blame"
6915         print "</div>\n";   # class="blame_body"
6916         close $fd
6917                 or print "Reading blob failed\n";
6918
6919         git_footer_html();
6920 }
6921
6922 sub git_blame {
6923         git_blame_common();
6924 }
6925
6926 sub git_blame_incremental {
6927         git_blame_common('incremental');
6928 }
6929
6930 sub git_blame_data {
6931         git_blame_common('data');
6932 }
6933
6934 sub git_tags {
6935         my $head = git_get_head_hash($project);
6936         git_header_html();
6937         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6938         git_print_header_div('summary', $project);
6939
6940         my @tagslist = git_get_tags_list();
6941         if (@tagslist) {
6942                 git_tags_body(\@tagslist);
6943         }
6944         git_footer_html();
6945 }
6946
6947 sub git_heads {
6948         my $head = git_get_head_hash($project);
6949         git_header_html();
6950         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6951         git_print_header_div('summary', $project);
6952
6953         my @headslist = git_get_heads_list();
6954         if (@headslist) {
6955                 git_heads_body(\@headslist, $head);
6956         }
6957         git_footer_html();
6958 }
6959
6960 # used both for single remote view and for list of all the remotes
6961 sub git_remotes {
6962         gitweb_check_feature('remote_heads')
6963                 or die_error(403, "Remote heads view is disabled");
6964
6965         my $head = git_get_head_hash($project);
6966         my $remote = $input_params{'hash'};
6967
6968         my $remotedata = git_get_remotes_list($remote);
6969         die_error(500, "Unable to get remote information") unless defined $remotedata;
6970
6971         unless (%$remotedata) {
6972                 die_error(404, defined $remote ?
6973                         "Remote $remote not found" :
6974                         "No remotes found");
6975         }
6976
6977         git_header_html(undef, undef, -action_extra => $remote);
6978         git_print_page_nav('', '',  $head, undef, $head,
6979                 format_ref_views($remote ? '' : 'remotes'));
6980
6981         fill_remote_heads($remotedata);
6982         if (defined $remote) {
6983                 git_print_header_div('remotes', "$remote remote for $project");
6984                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6985         } else {
6986                 git_print_header_div('summary', "$project remotes");
6987                 git_remotes_body($remotedata, undef, $head);
6988         }
6989
6990         git_footer_html();
6991 }
6992
6993 sub git_blob_plain {
6994         my $type = shift;
6995         my $expires;
6996
6997         if (!defined $hash) {
6998                 if (defined $file_name) {
6999                         my $base = $hash_base || git_get_head_hash($project);
7000                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7001                                 or die_error(404, "Cannot find file");
7002                 } else {
7003                         die_error(400, "No file name defined");
7004                 }
7005         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7006                 # blobs defined by non-textual hash id's can be cached
7007                 $expires = "+1d";
7008         }
7009
7010         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7011                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7012
7013         # content-type (can include charset)
7014         $type = blob_contenttype($fd, $file_name, $type);
7015
7016         # "save as" filename, even when no $file_name is given
7017         my $save_as = "$hash";
7018         if (defined $file_name) {
7019                 $save_as = $file_name;
7020         } elsif ($type =~ m/^text\//) {
7021                 $save_as .= '.txt';
7022         }
7023
7024         # With XSS prevention on, blobs of all types except a few known safe
7025         # ones are served with "Content-Disposition: attachment" to make sure
7026         # they don't run in our security domain.  For certain image types,
7027         # blob view writes an <img> tag referring to blob_plain view, and we
7028         # want to be sure not to break that by serving the image as an
7029         # attachment (though Firefox 3 doesn't seem to care).
7030         my $sandbox = $prevent_xss &&
7031                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7032
7033         # serve text/* as text/plain
7034         if ($prevent_xss &&
7035             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7036              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7037                 my $rest = $1;
7038                 $rest = defined $rest ? $rest : '';
7039                 $type = "text/plain$rest";
7040         }
7041
7042         print $cgi->header(
7043                 -type => $type,
7044                 -expires => $expires,
7045                 -content_disposition =>
7046                         ($sandbox ? 'attachment' : 'inline')
7047                         . '; filename="' . $save_as . '"');
7048         local $/ = undef;
7049         binmode STDOUT, ':raw';
7050         print <$fd>;
7051         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7052         close $fd;
7053 }
7054
7055 sub git_blob {
7056         my $expires;
7057
7058         if (!defined $hash) {
7059                 if (defined $file_name) {
7060                         my $base = $hash_base || git_get_head_hash($project);
7061                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7062                                 or die_error(404, "Cannot find file");
7063                 } else {
7064                         die_error(400, "No file name defined");
7065                 }
7066         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7067                 # blobs defined by non-textual hash id's can be cached
7068                 $expires = "+1d";
7069         }
7070
7071         my $have_blame = gitweb_check_feature('blame');
7072         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7073                 or die_error(500, "Couldn't cat $file_name, $hash");
7074         my $mimetype = blob_mimetype($fd, $file_name);
7075         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7076         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7077                 close $fd;
7078                 return git_blob_plain($mimetype);
7079         }
7080         # we can have blame only for text/* mimetype
7081         $have_blame &&= ($mimetype =~ m!^text/!);
7082
7083         my $highlight = gitweb_check_feature('highlight');
7084         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
7085         $fd = run_highlighter($fd, $highlight, $syntax)
7086                 if $syntax;
7087
7088         git_header_html(undef, $expires);
7089         my $formats_nav = '';
7090         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7091                 if (defined $file_name) {
7092                         if ($have_blame) {
7093                                 $formats_nav .=
7094                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7095                                                 "blame") .
7096                                         " | ";
7097                         }
7098                         $formats_nav .=
7099                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7100                                         "history") .
7101                                 " | " .
7102                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7103                                         "raw") .
7104                                 " | " .
7105                                 $cgi->a({-href => href(action=>"blob",
7106                                                        hash_base=>"HEAD", file_name=>$file_name)},
7107                                         "HEAD");
7108                 } else {
7109                         $formats_nav .=
7110                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7111                                         "raw");
7112                 }
7113                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7114                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7115         } else {
7116                 print "<div class=\"page_nav\">\n" .
7117                       "<br/><br/></div>\n" .
7118                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7119         }
7120         git_print_page_path($file_name, "blob", $hash_base);
7121         print "<div class=\"page_body\">\n";
7122         if ($mimetype =~ m!^image/!) {
7123                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7124                 if ($file_name) {
7125                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7126                 }
7127                 print qq! src="! .
7128                       href(action=>"blob_plain", hash=>$hash,
7129                            hash_base=>$hash_base, file_name=>$file_name) .
7130                       qq!" />\n!;
7131         } else {
7132                 my $nr;
7133                 while (my $line = <$fd>) {
7134                         chomp $line;
7135                         $nr++;
7136                         $line = untabify($line);
7137                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7138                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7139                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7140                 }
7141         }
7142         close $fd
7143                 or print "Reading blob failed.\n";
7144         print "</div>";
7145         git_footer_html();
7146 }
7147
7148 sub git_tree {
7149         if (!defined $hash_base) {
7150                 $hash_base = "HEAD";
7151         }
7152         if (!defined $hash) {
7153                 if (defined $file_name) {
7154                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7155                 } else {
7156                         $hash = $hash_base;
7157                 }
7158         }
7159         die_error(404, "No such tree") unless defined($hash);
7160
7161         my $show_sizes = gitweb_check_feature('show-sizes');
7162         my $have_blame = gitweb_check_feature('blame');
7163
7164         my @entries = ();
7165         {
7166                 local $/ = "\0";
7167                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7168                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7169                         or die_error(500, "Open git-ls-tree failed");
7170                 @entries = map { chomp; $_ } <$fd>;
7171                 close $fd
7172                         or die_error(404, "Reading tree failed");
7173         }
7174
7175         my $refs = git_get_references();
7176         my $ref = format_ref_marker($refs, $hash_base);
7177         git_header_html();
7178         my $basedir = '';
7179         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7180                 my @views_nav = ();
7181                 if (defined $file_name) {
7182                         push @views_nav,
7183                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7184                                         "history"),
7185                                 $cgi->a({-href => href(action=>"tree",
7186                                                        hash_base=>"HEAD", file_name=>$file_name)},
7187                                         "HEAD"),
7188                 }
7189                 my $snapshot_links = format_snapshot_links($hash);
7190                 if (defined $snapshot_links) {
7191                         # FIXME: Should be available when we have no hash base as well.
7192                         push @views_nav, $snapshot_links;
7193                 }
7194                 git_print_page_nav('tree','', $hash_base, undef, undef,
7195                                    join(' | ', @views_nav));
7196                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7197         } else {
7198                 undef $hash_base;
7199                 print "<div class=\"page_nav\">\n";
7200                 print "<br/><br/></div>\n";
7201                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7202         }
7203         if (defined $file_name) {
7204                 $basedir = $file_name;
7205                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7206                         $basedir .= '/';
7207                 }
7208                 git_print_page_path($file_name, 'tree', $hash_base);
7209         }
7210         print "<div class=\"page_body\">\n";
7211         print "<table class=\"tree\">\n";
7212         my $alternate = 1;
7213         # '..' (top directory) link if possible
7214         if (defined $hash_base &&
7215             defined $file_name && $file_name =~ m![^/]+$!) {
7216                 if ($alternate) {
7217                         print "<tr class=\"dark\">\n";
7218                 } else {
7219                         print "<tr class=\"light\">\n";
7220                 }
7221                 $alternate ^= 1;
7222
7223                 my $up = $file_name;
7224                 $up =~ s!/?[^/]+$!!;
7225                 undef $up unless $up;
7226                 # based on git_print_tree_entry
7227                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7228                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7229                 print '<td class="list">';
7230                 print $cgi->a({-href => href(action=>"tree",
7231                                              hash_base=>$hash_base,
7232                                              file_name=>$up)},
7233                               "..");
7234                 print "</td>\n";
7235                 print "<td class=\"link\"></td>\n";
7236
7237                 print "</tr>\n";
7238         }
7239         foreach my $line (@entries) {
7240                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7241
7242                 if ($alternate) {
7243                         print "<tr class=\"dark\">\n";
7244                 } else {
7245                         print "<tr class=\"light\">\n";
7246                 }
7247                 $alternate ^= 1;
7248
7249                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7250
7251                 print "</tr>\n";
7252         }
7253         print "</table>\n" .
7254               "</div>";
7255         git_footer_html();
7256 }
7257
7258 sub sanitize_for_filename {
7259     my $name = shift;
7260
7261     $name =~ s!/!-!g;
7262     $name =~ s/[^[:alnum:]_.-]//g;
7263
7264     return $name;
7265 }
7266
7267 sub snapshot_name {
7268         my ($project, $hash) = @_;
7269
7270         # path/to/project.git  -> project
7271         # path/to/project/.git -> project
7272         my $name = to_utf8($project);
7273         $name =~ s,([^/])/*\.git$,$1,;
7274         $name = sanitize_for_filename(basename($name));
7275
7276         my $ver = $hash;
7277         if ($hash =~ /^[0-9a-fA-F]+$/) {
7278                 # shorten SHA-1 hash
7279                 my $full_hash = git_get_full_hash($project, $hash);
7280                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7281                         $ver = git_get_short_hash($project, $hash);
7282                 }
7283         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7284                 # tags don't need shortened SHA-1 hash
7285                 $ver = $1;
7286         } else {
7287                 # branches and other need shortened SHA-1 hash
7288                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7289                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7290                         my $ref_dir = (defined $1) ? $1 : '';
7291                         $ver = $2;
7292
7293                         $ref_dir = sanitize_for_filename($ref_dir);
7294                         # for refs neither in heads nor remotes we want to
7295                         # add a ref dir to archive name
7296                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7297                                 $ver = $ref_dir . '-' . $ver;
7298                         }
7299                 }
7300                 $ver .= '-' . git_get_short_hash($project, $hash);
7301         }
7302         # special case of sanitization for filename - we change
7303         # slashes to dots instead of dashes
7304         # in case of hierarchical branch names
7305         $ver =~ s!/!.!g;
7306         $ver =~ s/[^[:alnum:]_.-]//g;
7307
7308         # name = project-version_string
7309         $name = "$name-$ver";
7310
7311         return wantarray ? ($name, $name) : $name;
7312 }
7313
7314 sub exit_if_unmodified_since {
7315         my ($latest_epoch) = @_;
7316         our $cgi;
7317
7318         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7319         if (defined $if_modified) {
7320                 my $since;
7321                 if (eval { require HTTP::Date; 1; }) {
7322                         $since = HTTP::Date::str2time($if_modified);
7323                 } elsif (eval { require Time::ParseDate; 1; }) {
7324                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7325                 }
7326                 if (defined $since && $latest_epoch <= $since) {
7327                         my %latest_date = parse_date($latest_epoch);
7328                         print $cgi->header(
7329                                 -last_modified => $latest_date{'rfc2822'},
7330                                 -status => '304 Not Modified');
7331                         goto DONE_GITWEB;
7332                 }
7333         }
7334 }
7335
7336 sub git_snapshot {
7337         my $format = $input_params{'snapshot_format'};
7338         if (!@snapshot_fmts) {
7339                 die_error(403, "Snapshots not allowed");
7340         }
7341         # default to first supported snapshot format
7342         $format ||= $snapshot_fmts[0];
7343         if ($format !~ m/^[a-z0-9]+$/) {
7344                 die_error(400, "Invalid snapshot format parameter");
7345         } elsif (!exists($known_snapshot_formats{$format})) {
7346                 die_error(400, "Unknown snapshot format");
7347         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7348                 die_error(403, "Snapshot format not allowed");
7349         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7350                 die_error(403, "Unsupported snapshot format");
7351         }
7352
7353         my $type = git_get_type("$hash^{}");
7354         if (!$type) {
7355                 die_error(404, 'Object does not exist');
7356         }  elsif ($type eq 'blob') {
7357                 die_error(400, 'Object is not a tree-ish');
7358         }
7359
7360         my ($name, $prefix) = snapshot_name($project, $hash);
7361         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7362
7363         my %co = parse_commit($hash);
7364         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7365
7366         my $cmd = quote_command(
7367                 git_cmd(), 'archive',
7368                 "--format=$known_snapshot_formats{$format}{'format'}",
7369                 "--prefix=$prefix/", $hash);
7370         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7371                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7372         }
7373
7374         $filename =~ s/(["\\])/\\$1/g;
7375         my %latest_date;
7376         if (%co) {
7377                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7378         }
7379
7380         print $cgi->header(
7381                 -type => $known_snapshot_formats{$format}{'type'},
7382                 -content_disposition => 'inline; filename="' . $filename . '"',
7383                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7384                 -status => '200 OK');
7385
7386         open my $fd, "-|", $cmd
7387                 or die_error(500, "Execute git-archive failed");
7388         binmode STDOUT, ':raw';
7389         print <$fd>;
7390         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7391         close $fd;
7392 }
7393
7394 sub git_log_generic {
7395         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7396
7397         my $head = git_get_head_hash($project);
7398         if (!defined $base) {
7399                 $base = $head;
7400         }
7401         if (!defined $page) {
7402                 $page = 0;
7403         }
7404         my $refs = git_get_references();
7405
7406         my $commit_hash = $base;
7407         if (defined $parent) {
7408                 $commit_hash = "$parent..$base";
7409         }
7410         my @commitlist =
7411                 parse_commits($commit_hash, 101, (100 * $page),
7412                               defined $file_name ? ($file_name, "--full-history") : ());
7413
7414         my $ftype;
7415         if (!defined $file_hash && defined $file_name) {
7416                 # some commits could have deleted file in question,
7417                 # and not have it in tree, but one of them has to have it
7418                 for (my $i = 0; $i < @commitlist; $i++) {
7419                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7420                         last if defined $file_hash;
7421                 }
7422         }
7423         if (defined $file_hash) {
7424                 $ftype = git_get_type($file_hash);
7425         }
7426         if (defined $file_name && !defined $ftype) {
7427                 die_error(500, "Unknown type of object");
7428         }
7429         my %co;
7430         if (defined $file_name) {
7431                 %co = parse_commit($base)
7432                         or die_error(404, "Unknown commit object");
7433         }
7434
7435
7436         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7437         my $next_link = '';
7438         if ($#commitlist >= 100) {
7439                 $next_link =
7440                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7441                                  -accesskey => "n", -title => "Alt-n"}, "next");
7442         }
7443         my $patch_max = gitweb_get_feature('patches');
7444         if ($patch_max && !defined $file_name) {
7445                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7446                         $paging_nav .= " &sdot; " .
7447                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7448                                         "patches");
7449                 }
7450         }
7451
7452         git_header_html();
7453         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7454         if (defined $file_name) {
7455                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7456         } else {
7457                 git_print_header_div('summary', $project)
7458         }
7459         git_print_page_path($file_name, $ftype, $hash_base)
7460                 if (defined $file_name);
7461
7462         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7463                      $file_name, $file_hash, $ftype);
7464
7465         git_footer_html();
7466 }
7467
7468 sub git_log {
7469         git_log_generic('log', \&git_log_body,
7470                         $hash, $hash_parent);
7471 }
7472
7473 sub git_commit {
7474         $hash ||= $hash_base || "HEAD";
7475         my %co = parse_commit($hash)
7476             or die_error(404, "Unknown commit object");
7477
7478         my $parent  = $co{'parent'};
7479         my $parents = $co{'parents'}; # listref
7480
7481         # we need to prepare $formats_nav before any parameter munging
7482         my $formats_nav;
7483         if (!defined $parent) {
7484                 # --root commitdiff
7485                 $formats_nav .= '(initial)';
7486         } elsif (@$parents == 1) {
7487                 # single parent commit
7488                 $formats_nav .=
7489                         '(parent: ' .
7490                         $cgi->a({-href => href(action=>"commit",
7491                                                hash=>$parent)},
7492                                 esc_html(substr($parent, 0, 7))) .
7493                         ')';
7494         } else {
7495                 # merge commit
7496                 $formats_nav .=
7497                         '(merge: ' .
7498                         join(' ', map {
7499                                 $cgi->a({-href => href(action=>"commit",
7500                                                        hash=>$_)},
7501                                         esc_html(substr($_, 0, 7)));
7502                         } @$parents ) .
7503                         ')';
7504         }
7505         if (gitweb_check_feature('patches') && @$parents <= 1) {
7506                 $formats_nav .= " | " .
7507                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7508                                 "patch");
7509         }
7510
7511         if (!defined $parent) {
7512                 $parent = "--root";
7513         }
7514         my @difftree;
7515         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7516                 @diff_opts,
7517                 (@$parents <= 1 ? $parent : '-c'),
7518                 $hash, "--"
7519                 or die_error(500, "Open git-diff-tree failed");
7520         @difftree = map { chomp; $_ } <$fd>;
7521         close $fd or die_error(404, "Reading git-diff-tree failed");
7522
7523         # non-textual hash id's can be cached
7524         my $expires;
7525         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7526                 $expires = "+1d";
7527         }
7528         my $refs = git_get_references();
7529         my $ref = format_ref_marker($refs, $co{'id'});
7530
7531         git_header_html(undef, $expires);
7532         git_print_page_nav('commit', '',
7533                            $hash, $co{'tree'}, $hash,
7534                            $formats_nav);
7535
7536         if (defined $co{'parent'}) {
7537                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7538         } else {
7539                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7540         }
7541         print "<div class=\"title_text\">\n" .
7542               "<table class=\"object_header\">\n";
7543         git_print_authorship_rows(\%co);
7544         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7545         print "<tr>" .
7546               "<td>tree</td>" .
7547               "<td class=\"sha1\">" .
7548               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7549                        class => "list"}, $co{'tree'}) .
7550               "</td>" .
7551               "<td class=\"link\">" .
7552               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7553                       "tree");
7554         my $snapshot_links = format_snapshot_links($hash);
7555         if (defined $snapshot_links) {
7556                 print " | " . $snapshot_links;
7557         }
7558         print "</td>" .
7559               "</tr>\n";
7560
7561         foreach my $par (@$parents) {
7562                 print "<tr>" .
7563                       "<td>parent</td>" .
7564                       "<td class=\"sha1\">" .
7565                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7566                                class => "list"}, $par) .
7567                       "</td>" .
7568                       "<td class=\"link\">" .
7569                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7570                       " | " .
7571                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7572                       "</td>" .
7573                       "</tr>\n";
7574         }
7575         print "</table>".
7576               "</div>\n";
7577
7578         print "<div class=\"page_body\">\n";
7579         git_print_log($co{'comment'});
7580         print "</div>\n";
7581
7582         git_difftree_body(\@difftree, $hash, @$parents);
7583
7584         git_footer_html();
7585 }
7586
7587 sub git_object {
7588         # object is defined by:
7589         # - hash or hash_base alone
7590         # - hash_base and file_name
7591         my $type;
7592
7593         # - hash or hash_base alone
7594         if ($hash || ($hash_base && !defined $file_name)) {
7595                 my $object_id = $hash || $hash_base;
7596
7597                 open my $fd, "-|", quote_command(
7598                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7599                         or die_error(404, "Object does not exist");
7600                 $type = <$fd>;
7601                 chomp $type;
7602                 close $fd
7603                         or die_error(404, "Object does not exist");
7604
7605         # - hash_base and file_name
7606         } elsif ($hash_base && defined $file_name) {
7607                 $file_name =~ s,/+$,,;
7608
7609                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7610                         or die_error(404, "Base object does not exist");
7611
7612                 # here errors should not happen
7613                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7614                         or die_error(500, "Open git-ls-tree failed");
7615                 my $line = <$fd>;
7616                 close $fd;
7617
7618                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7619                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7620                         die_error(404, "File or directory for given base does not exist");
7621                 }
7622                 $type = $2;
7623                 $hash = $3;
7624         } else {
7625                 die_error(400, "Not enough information to find object");
7626         }
7627
7628         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7629                                           hash=>$hash, hash_base=>$hash_base,
7630                                           file_name=>$file_name),
7631                              -status => '302 Found');
7632 }
7633
7634 sub git_blobdiff {
7635         my $format = shift || 'html';
7636         my $diff_style = $input_params{'diff_style'} || 'inline';
7637
7638         my $fd;
7639         my @difftree;
7640         my %diffinfo;
7641         my $expires;
7642
7643         # preparing $fd and %diffinfo for git_patchset_body
7644         # new style URI
7645         if (defined $hash_base && defined $hash_parent_base) {
7646                 if (defined $file_name) {
7647                         # read raw output
7648                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7649                                 $hash_parent_base, $hash_base,
7650                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7651                                 or die_error(500, "Open git-diff-tree failed");
7652                         @difftree = map { chomp; $_ } <$fd>;
7653                         close $fd
7654                                 or die_error(404, "Reading git-diff-tree failed");
7655                         @difftree
7656                                 or die_error(404, "Blob diff not found");
7657
7658                 } elsif (defined $hash &&
7659                          $hash =~ /[0-9a-fA-F]{40}/) {
7660                         # try to find filename from $hash
7661
7662                         # read filtered raw output
7663                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7664                                 $hash_parent_base, $hash_base, "--"
7665                                 or die_error(500, "Open git-diff-tree failed");
7666                         @difftree =
7667                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7668                                 # $hash == to_id
7669                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7670                                 map { chomp; $_ } <$fd>;
7671                         close $fd
7672                                 or die_error(404, "Reading git-diff-tree failed");
7673                         @difftree
7674                                 or die_error(404, "Blob diff not found");
7675
7676                 } else {
7677                         die_error(400, "Missing one of the blob diff parameters");
7678                 }
7679
7680                 if (@difftree > 1) {
7681                         die_error(400, "Ambiguous blob diff specification");
7682                 }
7683
7684                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7685                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7686                 $file_name   ||= $diffinfo{'to_file'};
7687
7688                 $hash_parent ||= $diffinfo{'from_id'};
7689                 $hash        ||= $diffinfo{'to_id'};
7690
7691                 # non-textual hash id's can be cached
7692                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7693                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7694                         $expires = '+1d';
7695                 }
7696
7697                 # open patch output
7698                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7699                         '-p', ($format eq 'html' ? "--full-index" : ()),
7700                         $hash_parent_base, $hash_base,
7701                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7702                         or die_error(500, "Open git-diff-tree failed");
7703         }
7704
7705         # old/legacy style URI -- not generated anymore since 1.4.3.
7706         if (!%diffinfo) {
7707                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7708         }
7709
7710         # header
7711         if ($format eq 'html') {
7712                 my $formats_nav =
7713                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7714                                 "raw");
7715                 $formats_nav .= diff_style_nav($diff_style);
7716                 git_header_html(undef, $expires);
7717                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7718                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7719                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7720                 } else {
7721                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7722                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7723                 }
7724                 if (defined $file_name) {
7725                         git_print_page_path($file_name, "blob", $hash_base);
7726                 } else {
7727                         print "<div class=\"page_path\"></div>\n";
7728                 }
7729
7730         } elsif ($format eq 'plain') {
7731                 print $cgi->header(
7732                         -type => 'text/plain',
7733                         -charset => 'utf-8',
7734                         -expires => $expires,
7735                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7736
7737                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7738
7739         } else {
7740                 die_error(400, "Unknown blobdiff format");
7741         }
7742
7743         # patch
7744         if ($format eq 'html') {
7745                 print "<div class=\"page_body\">\n";
7746
7747                 git_patchset_body($fd, $diff_style,
7748                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7749                 close $fd;
7750
7751                 print "</div>\n"; # class="page_body"
7752                 git_footer_html();
7753
7754         } else {
7755                 while (my $line = <$fd>) {
7756                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7757                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7758
7759                         print $line;
7760
7761                         last if $line =~ m!^\+\+\+!;
7762                 }
7763                 local $/ = undef;
7764                 print <$fd>;
7765                 close $fd;
7766         }
7767 }
7768
7769 sub git_blobdiff_plain {
7770         git_blobdiff('plain');
7771 }
7772
7773 # assumes that it is added as later part of already existing navigation,
7774 # so it returns "| foo | bar" rather than just "foo | bar"
7775 sub diff_style_nav {
7776         my ($diff_style, $is_combined) = @_;
7777         $diff_style ||= 'inline';
7778
7779         return "" if ($is_combined);
7780
7781         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7782         my %styles = @styles;
7783         @styles =
7784                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7785
7786         return join '',
7787                 map { " | ".$_ }
7788                 map {
7789                         $_ eq $diff_style ? $styles{$_} :
7790                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7791                 } @styles;
7792 }
7793
7794 sub git_commitdiff {
7795         my %params = @_;
7796         my $format = $params{-format} || 'html';
7797         my $diff_style = $input_params{'diff_style'} || 'inline';
7798
7799         my ($patch_max) = gitweb_get_feature('patches');
7800         if ($format eq 'patch') {
7801                 die_error(403, "Patch view not allowed") unless $patch_max;
7802         }
7803
7804         $hash ||= $hash_base || "HEAD";
7805         my %co = parse_commit($hash)
7806             or die_error(404, "Unknown commit object");
7807
7808         # choose format for commitdiff for merge
7809         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7810                 $hash_parent = '--cc';
7811         }
7812         # we need to prepare $formats_nav before almost any parameter munging
7813         my $formats_nav;
7814         if ($format eq 'html') {
7815                 $formats_nav =
7816                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7817                                 "raw");
7818                 if ($patch_max && @{$co{'parents'}} <= 1) {
7819                         $formats_nav .= " | " .
7820                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7821                                         "patch");
7822                 }
7823                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7824
7825                 if (defined $hash_parent &&
7826                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7827                         # commitdiff with two commits given
7828                         my $hash_parent_short = $hash_parent;
7829                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7830                                 $hash_parent_short = substr($hash_parent, 0, 7);
7831                         }
7832                         $formats_nav .=
7833                                 ' (from';
7834                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7835                                 if ($co{'parents'}[$i] eq $hash_parent) {
7836                                         $formats_nav .= ' parent ' . ($i+1);
7837                                         last;
7838                                 }
7839                         }
7840                         $formats_nav .= ': ' .
7841                                 $cgi->a({-href => href(-replay=>1,
7842                                                        hash=>$hash_parent, hash_base=>undef)},
7843                                         esc_html($hash_parent_short)) .
7844                                 ')';
7845                 } elsif (!$co{'parent'}) {
7846                         # --root commitdiff
7847                         $formats_nav .= ' (initial)';
7848                 } elsif (scalar @{$co{'parents'}} == 1) {
7849                         # single parent commit
7850                         $formats_nav .=
7851                                 ' (parent: ' .
7852                                 $cgi->a({-href => href(-replay=>1,
7853                                                        hash=>$co{'parent'}, hash_base=>undef)},
7854                                         esc_html(substr($co{'parent'}, 0, 7))) .
7855                                 ')';
7856                 } else {
7857                         # merge commit
7858                         if ($hash_parent eq '--cc') {
7859                                 $formats_nav .= ' | ' .
7860                                         $cgi->a({-href => href(-replay=>1,
7861                                                                hash=>$hash, hash_parent=>'-c')},
7862                                                 'combined');
7863                         } else { # $hash_parent eq '-c'
7864                                 $formats_nav .= ' | ' .
7865                                         $cgi->a({-href => href(-replay=>1,
7866                                                                hash=>$hash, hash_parent=>'--cc')},
7867                                                 'compact');
7868                         }
7869                         $formats_nav .=
7870                                 ' (merge: ' .
7871                                 join(' ', map {
7872                                         $cgi->a({-href => href(-replay=>1,
7873                                                                hash=>$_, hash_base=>undef)},
7874                                                 esc_html(substr($_, 0, 7)));
7875                                 } @{$co{'parents'}} ) .
7876                                 ')';
7877                 }
7878         }
7879
7880         my $hash_parent_param = $hash_parent;
7881         if (!defined $hash_parent_param) {
7882                 # --cc for multiple parents, --root for parentless
7883                 $hash_parent_param =
7884                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7885         }
7886
7887         # read commitdiff
7888         my $fd;
7889         my @difftree;
7890         if ($format eq 'html') {
7891                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7892                         "--no-commit-id", "--patch-with-raw", "--full-index",
7893                         $hash_parent_param, $hash, "--"
7894                         or die_error(500, "Open git-diff-tree failed");
7895
7896                 while (my $line = <$fd>) {
7897                         chomp $line;
7898                         # empty line ends raw part of diff-tree output
7899                         last unless $line;
7900                         push @difftree, scalar parse_difftree_raw_line($line);
7901                 }
7902
7903         } elsif ($format eq 'plain') {
7904                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7905                         '-p', $hash_parent_param, $hash, "--"
7906                         or die_error(500, "Open git-diff-tree failed");
7907         } elsif ($format eq 'patch') {
7908                 # For commit ranges, we limit the output to the number of
7909                 # patches specified in the 'patches' feature.
7910                 # For single commits, we limit the output to a single patch,
7911                 # diverging from the git-format-patch default.
7912                 my @commit_spec = ();
7913                 if ($hash_parent) {
7914                         if ($patch_max > 0) {
7915                                 push @commit_spec, "-$patch_max";
7916                         }
7917                         push @commit_spec, '-n', "$hash_parent..$hash";
7918                 } else {
7919                         if ($params{-single}) {
7920                                 push @commit_spec, '-1';
7921                         } else {
7922                                 if ($patch_max > 0) {
7923                                         push @commit_spec, "-$patch_max";
7924                                 }
7925                                 push @commit_spec, "-n";
7926                         }
7927                         push @commit_spec, '--root', $hash;
7928                 }
7929                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7930                         '--encoding=utf8', '--stdout', @commit_spec
7931                         or die_error(500, "Open git-format-patch failed");
7932         } else {
7933                 die_error(400, "Unknown commitdiff format");
7934         }
7935
7936         # non-textual hash id's can be cached
7937         my $expires;
7938         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7939                 $expires = "+1d";
7940         }
7941
7942         # write commit message
7943         if ($format eq 'html') {
7944                 my $refs = git_get_references();
7945                 my $ref = format_ref_marker($refs, $co{'id'});
7946
7947                 git_header_html(undef, $expires);
7948                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7949                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7950                 print "<div class=\"title_text\">\n" .
7951                       "<table class=\"object_header\">\n";
7952                 git_print_authorship_rows(\%co);
7953                 print "</table>".
7954                       "</div>\n";
7955                 print "<div class=\"page_body\">\n";
7956                 if (@{$co{'comment'}} > 1) {
7957                         print "<div class=\"log\">\n";
7958                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7959                         print "</div>\n"; # class="log"
7960                 }
7961
7962         } elsif ($format eq 'plain') {
7963                 my $refs = git_get_references("tags");
7964                 my $tagname = git_get_rev_name_tags($hash);
7965                 my $filename = basename($project) . "-$hash.patch";
7966
7967                 print $cgi->header(
7968                         -type => 'text/plain',
7969                         -charset => 'utf-8',
7970                         -expires => $expires,
7971                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7972                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7973                 print "From: " . to_utf8($co{'author'}) . "\n";
7974                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7975                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7976
7977                 print "X-Git-Tag: $tagname\n" if $tagname;
7978                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7979
7980                 foreach my $line (@{$co{'comment'}}) {
7981                         print to_utf8($line) . "\n";
7982                 }
7983                 print "---\n\n";
7984         } elsif ($format eq 'patch') {
7985                 my $filename = basename($project) . "-$hash.patch";
7986
7987                 print $cgi->header(
7988                         -type => 'text/plain',
7989                         -charset => 'utf-8',
7990                         -expires => $expires,
7991                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7992         }
7993
7994         # write patch
7995         if ($format eq 'html') {
7996                 my $use_parents = !defined $hash_parent ||
7997                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7998                 git_difftree_body(\@difftree, $hash,
7999                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8000                 print "<br/>\n";
8001
8002                 git_patchset_body($fd, $diff_style,
8003                                   \@difftree, $hash,
8004                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8005                 close $fd;
8006                 print "</div>\n"; # class="page_body"
8007                 git_footer_html();
8008
8009         } elsif ($format eq 'plain') {
8010                 local $/ = undef;
8011                 print <$fd>;
8012                 close $fd
8013                         or print "Reading git-diff-tree failed\n";
8014         } elsif ($format eq 'patch') {
8015                 local $/ = undef;
8016                 print <$fd>;
8017                 close $fd
8018                         or print "Reading git-format-patch failed\n";
8019         }
8020 }
8021
8022 sub git_commitdiff_plain {
8023         git_commitdiff(-format => 'plain');
8024 }
8025
8026 # format-patch-style patches
8027 sub git_patch {
8028         git_commitdiff(-format => 'patch', -single => 1);
8029 }
8030
8031 sub git_patches {
8032         git_commitdiff(-format => 'patch');
8033 }
8034
8035 sub git_history {
8036         git_log_generic('history', \&git_history_body,
8037                         $hash_base, $hash_parent_base,
8038                         $file_name, $hash);
8039 }
8040
8041 sub git_search {
8042         $searchtype ||= 'commit';
8043
8044         # check if appropriate features are enabled
8045         gitweb_check_feature('search')
8046                 or die_error(403, "Search is disabled");
8047         if ($searchtype eq 'pickaxe') {
8048                 # pickaxe may take all resources of your box and run for several minutes
8049                 # with every query - so decide by yourself how public you make this feature
8050                 gitweb_check_feature('pickaxe')
8051                         or die_error(403, "Pickaxe search is disabled");
8052         }
8053         if ($searchtype eq 'grep') {
8054                 # grep search might be potentially CPU-intensive, too
8055                 gitweb_check_feature('grep')
8056                         or die_error(403, "Grep search is disabled");
8057         }
8058
8059         if (!defined $searchtext) {
8060                 die_error(400, "Text field is empty");
8061         }
8062         if (!defined $hash) {
8063                 $hash = git_get_head_hash($project);
8064         }
8065         my %co = parse_commit($hash);
8066         if (!%co) {
8067                 die_error(404, "Unknown commit object");
8068         }
8069         if (!defined $page) {
8070                 $page = 0;
8071         }
8072
8073         if ($searchtype eq 'commit' ||
8074             $searchtype eq 'author' ||
8075             $searchtype eq 'committer') {
8076                 git_search_message(%co);
8077         } elsif ($searchtype eq 'pickaxe') {
8078                 git_search_changes(%co);
8079         } elsif ($searchtype eq 'grep') {
8080                 git_search_files(%co);
8081         } else {
8082                 die_error(400, "Unknown search type");
8083         }
8084 }
8085
8086 sub git_search_help {
8087         git_header_html();
8088         git_print_page_nav('','', $hash,$hash,$hash);
8089         print <<EOT;
8090 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8091 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8092 the pattern entered is recognized as the POSIX extended
8093 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8094 insensitive).</p>
8095 <dl>
8096 <dt><b>commit</b></dt>
8097 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8098 EOT
8099         my $have_grep = gitweb_check_feature('grep');
8100         if ($have_grep) {
8101                 print <<EOT;
8102 <dt><b>grep</b></dt>
8103 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8104     a different one) are searched for the given pattern. On large trees, this search can take
8105 a while and put some strain on the server, so please use it with some consideration. Note that
8106 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8107 case-sensitive.</dd>
8108 EOT
8109         }
8110         print <<EOT;
8111 <dt><b>author</b></dt>
8112 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8113 <dt><b>committer</b></dt>
8114 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8115 EOT
8116         my $have_pickaxe = gitweb_check_feature('pickaxe');
8117         if ($have_pickaxe) {
8118                 print <<EOT;
8119 <dt><b>pickaxe</b></dt>
8120 <dd>All commits that caused the string to appear or disappear from any file (changes that
8121 added, removed or "modified" the string) will be listed. This search can take a while and
8122 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8123 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8124 EOT
8125         }
8126         print "</dl>\n";
8127         git_footer_html();
8128 }
8129
8130 sub git_shortlog {
8131         git_log_generic('shortlog', \&git_shortlog_body,
8132                         $hash, $hash_parent);
8133 }
8134
8135 ## ......................................................................
8136 ## feeds (RSS, Atom; OPML)
8137
8138 sub git_feed {
8139         my $format = shift || 'atom';
8140         my $have_blame = gitweb_check_feature('blame');
8141
8142         # Atom: http://www.atomenabled.org/developers/syndication/
8143         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8144         if ($format ne 'rss' && $format ne 'atom') {
8145                 die_error(400, "Unknown web feed format");
8146         }
8147
8148         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8149         my $head = $hash || 'HEAD';
8150         my @commitlist = parse_commits($head, 150, 0, $file_name);
8151
8152         my %latest_commit;
8153         my %latest_date;
8154         my $content_type = "application/$format+xml";
8155         if (defined $cgi->http('HTTP_ACCEPT') &&
8156                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8157                 # browser (feed reader) prefers text/xml
8158                 $content_type = 'text/xml';
8159         }
8160         if (defined($commitlist[0])) {
8161                 %latest_commit = %{$commitlist[0]};
8162                 my $latest_epoch = $latest_commit{'committer_epoch'};
8163                 exit_if_unmodified_since($latest_epoch);
8164                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8165         }
8166         print $cgi->header(
8167                 -type => $content_type,
8168                 -charset => 'utf-8',
8169                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8170                 -status => '200 OK');
8171
8172         # Optimization: skip generating the body if client asks only
8173         # for Last-Modified date.
8174         return if ($cgi->request_method() eq 'HEAD');
8175
8176         # header variables
8177         my $title = "$site_name - $project/$action";
8178         my $feed_type = 'log';
8179         if (defined $hash) {
8180                 $title .= " - '$hash'";
8181                 $feed_type = 'branch log';
8182                 if (defined $file_name) {
8183                         $title .= " :: $file_name";
8184                         $feed_type = 'history';
8185                 }
8186         } elsif (defined $file_name) {
8187                 $title .= " - $file_name";
8188                 $feed_type = 'history';
8189         }
8190         $title .= " $feed_type";
8191         $title = esc_html($title);
8192         my $descr = git_get_project_description($project);
8193         if (defined $descr) {
8194                 $descr = esc_html($descr);
8195         } else {
8196                 $descr = "$project " .
8197                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8198                          " feed";
8199         }
8200         my $owner = git_get_project_owner($project);
8201         $owner = esc_html($owner);
8202
8203         #header
8204         my $alt_url;
8205         if (defined $file_name) {
8206                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8207         } elsif (defined $hash) {
8208                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8209         } else {
8210                 $alt_url = href(-full=>1, action=>"summary");
8211         }
8212         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8213         if ($format eq 'rss') {
8214                 print <<XML;
8215 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8216 <channel>
8217 XML
8218                 print "<title>$title</title>\n" .
8219                       "<link>$alt_url</link>\n" .
8220                       "<description>$descr</description>\n" .
8221                       "<language>en</language>\n" .
8222                       # project owner is responsible for 'editorial' content
8223                       "<managingEditor>$owner</managingEditor>\n";
8224                 if (defined $logo || defined $favicon) {
8225                         # prefer the logo to the favicon, since RSS
8226                         # doesn't allow both
8227                         my $img = esc_url($logo || $favicon);
8228                         print "<image>\n" .
8229                               "<url>$img</url>\n" .
8230                               "<title>$title</title>\n" .
8231                               "<link>$alt_url</link>\n" .
8232                               "</image>\n";
8233                 }
8234                 if (%latest_date) {
8235                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8236                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8237                 }
8238                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8239         } elsif ($format eq 'atom') {
8240                 print <<XML;
8241 <feed xmlns="http://www.w3.org/2005/Atom">
8242 XML
8243                 print "<title>$title</title>\n" .
8244                       "<subtitle>$descr</subtitle>\n" .
8245                       '<link rel="alternate" type="text/html" href="' .
8246                       $alt_url . '" />' . "\n" .
8247                       '<link rel="self" type="' . $content_type . '" href="' .
8248                       $cgi->self_url() . '" />' . "\n" .
8249                       "<id>" . href(-full=>1) . "</id>\n" .
8250                       # use project owner for feed author
8251                       '<author><name>'. email_obfuscate($owner) . '</name></author>\n';
8252                 if (defined $favicon) {
8253                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8254                 }
8255                 if (defined $logo) {
8256                         # not twice as wide as tall: 72 x 27 pixels
8257                         print "<logo>" . esc_url($logo) . "</logo>\n";
8258                 }
8259                 if (! %latest_date) {
8260                         # dummy date to keep the feed valid until commits trickle in:
8261                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8262                 } else {
8263                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8264                 }
8265                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8266         }
8267
8268         # contents
8269         for (my $i = 0; $i <= $#commitlist; $i++) {
8270                 my %co = %{$commitlist[$i]};
8271                 my $commit = $co{'id'};
8272                 # we read 150, we always show 30 and the ones more recent than 48 hours
8273                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8274                         last;
8275                 }
8276                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8277
8278                 # get list of changed files
8279                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8280                         $co{'parent'} || "--root",
8281                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8282                         or next;
8283                 my @difftree = map { chomp; $_ } <$fd>;
8284                 close $fd
8285                         or next;
8286
8287                 # print element (entry, item)
8288                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8289                 if ($format eq 'rss') {
8290                         print "<item>\n" .
8291                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8292                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8293                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8294                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8295                               "<link>$co_url</link>\n" .
8296                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8297                               "<content:encoded>" .
8298                               "<![CDATA[\n";
8299                 } elsif ($format eq 'atom') {
8300                         print "<entry>\n" .
8301                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8302                               "<updated>$cd{'iso-8601'}</updated>\n" .
8303                               "<author>\n" .
8304                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8305                         if ($co{'author_email'}) {
8306                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8307                         }
8308                         print "</author>\n" .
8309                               # use committer for contributor
8310                               "<contributor>\n" .
8311                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8312                         if ($co{'committer_email'}) {
8313                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8314                         }
8315                         print "</contributor>\n" .
8316                               "<published>$cd{'iso-8601'}</published>\n" .
8317                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8318                               "<id>$co_url</id>\n" .
8319                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8320                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8321                 }
8322                 my $comment = $co{'comment'};
8323                 print "<pre>\n";
8324                 foreach my $line (@$comment) {
8325                         $line = esc_html($line);
8326                         print "$line\n";
8327                 }
8328                 print "</pre><ul>\n";
8329                 foreach my $difftree_line (@difftree) {
8330                         my %difftree = parse_difftree_raw_line($difftree_line);
8331                         next if !$difftree{'from_id'};
8332
8333                         my $file = $difftree{'file'} || $difftree{'to_file'};
8334
8335                         print "<li>" .
8336                               "[" .
8337                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8338                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8339                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8340                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8341                                       -title => "diff"}, 'D');
8342                         if ($have_blame) {
8343                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8344                                                              file_name=>$file, hash_base=>$commit),
8345                                               -title => "blame"}, 'B');
8346                         }
8347                         # if this is not a feed of a file history
8348                         if (!defined $file_name || $file_name ne $file) {
8349                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8350                                                              file_name=>$file, hash=>$commit),
8351                                               -title => "history"}, 'H');
8352                         }
8353                         $file = esc_path($file);
8354                         print "] ".
8355                               "$file</li>\n";
8356                 }
8357                 if ($format eq 'rss') {
8358                         print "</ul>]]>\n" .
8359                               "</content:encoded>\n" .
8360                               "</item>\n";
8361                 } elsif ($format eq 'atom') {
8362                         print "</ul>\n</div>\n" .
8363                               "</content>\n" .
8364                               "</entry>\n";
8365                 }
8366         }
8367
8368         # end of feed
8369         if ($format eq 'rss') {
8370                 print "</channel>\n</rss>\n";
8371         } elsif ($format eq 'atom') {
8372                 print "</feed>\n";
8373         }
8374 }
8375
8376 sub git_rss {
8377         git_feed('rss');
8378 }
8379
8380 sub git_atom {
8381         git_feed('atom');
8382 }
8383
8384 sub git_opml {
8385         my @list = git_get_projects_list($project_filter, $strict_export);
8386         if (!@list) {
8387                 die_error(404, "No projects found");
8388         }
8389
8390         print $cgi->header(
8391                 -type => 'text/xml',
8392                 -charset => 'utf-8',
8393                 -content_disposition => 'inline; filename="opml.xml"');
8394
8395         my $title = esc_html($site_name);
8396         my $filter = " within subdirectory ";
8397         if (defined $project_filter) {
8398                 $filter .= esc_html($project_filter);
8399         } else {
8400                 $filter = "";
8401         }
8402         print <<XML;
8403 <?xml version="1.0" encoding="utf-8"?>
8404 <opml version="1.0">
8405 <head>
8406   <title>$title OPML Export$filter</title>
8407 </head>
8408 <body>
8409 <outline text="git RSS feeds">
8410 XML
8411
8412         foreach my $pr (@list) {
8413                 my %proj = %$pr;
8414                 my $head = git_get_head_hash($proj{'path'});
8415                 if (!defined $head) {
8416                         next;
8417                 }
8418                 $git_dir = "$projectroot/$proj{'path'}";
8419                 my %co = parse_commit($head);
8420                 if (!%co) {
8421                         next;
8422                 }
8423
8424                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8425                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8426                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8427                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8428         }
8429         print <<XML;
8430 </outline>
8431 </body>
8432 </opml>
8433 XML
8434 }