perl/Git/RepoRoot.pm

   1 =head1 NAME
   2
   3 Git::RepoRoot - A factory class representing a root directory
   4 containing Git repositories.
   5
   6 =head1 DESCRIPTION
   7
   8 Git::RepoRoot is a factory class to create L<Git::Repo> instances that
   9 are located under a common root directory.  It also allows for
  10 specifying options that all Git::Repo instances will be created with.
  11
  12 Using Git::RepoRoot to create Git::Repo instances is entirely
  13 optional, but can be more convenient than instantiating them directly.
  14
  15 =cut
  16
  17
  18 use strict;
  19 use warnings;
  20
  21
  22 package Git::RepoRoot;
  23
  24 use File::Spec;
  25
  26 use Git::Repo;
  27
  28 use base qw(Exporter);
  29
  30 our @EXPORT = qw();
  31 our @EXPORT_OK = qw();
  32
  33 =head1 METHODS
  34
  35 =over
  36
  37 =item $repo_root = Git::RepoRoot->new(%opts)
  38
  39 Return a new Git::RepoRoot object.  The following options are
  40 supported:
  41
  42 =over
  43
  44 =item 'root_dir'
  45
  46 The directory holding all repositories.
  47
  48 =back
  49
  50 All other options will be passed through to Git::Repo->new.
  51
  52 Example:
  53
  54     $repo_root = Git::RepoRoot->new(root_dir => '/pub/git',
  55                                     git_binary => '/usr/bin/git');
  56
  57 =cut
  58
  59 sub new {
  60         my $class = shift;
  61         Git::Repo::_assert_opts(@_);
  62         my $self = {@_};
  63         bless $self, $class;
  64         die 'no root_dir given' unless $self->{root_dir};
  65         return $self;
  66 }
  67
  68 =item $repo_root->repo(%opts)
  69
  70 Return a new L<Git::Repo> object.  The following options are
  71 supported:
  72
  73 =over
  74
  75 =item 'root_dir'
  76
  77 The path of the repository relative to the repository root.
  78
  79 =item 'repo_class'
  80
  81 The Repo class to instantiate (default: 'Git::Repo').
  82
  83 =back
  84
  85 All other options are passed through to Git::Repo.
  86
  87 =cut
  88
  89 sub repo {
  90         my $self = shift;
  91         Git::Repo::_assert_opts(@_);
  92         my %opts = (%$self, @_);
  93         die 'no repo_dir given' unless $opts{repo_dir};
  94         # not technically necessary, but to guard against errors in the caller:
  95         die "you passed an absolute path ($opts{repo_dir})"
  96             if $opts{repo_dir} =~ m!^/!;
  97         my $repo_class = delete $opts{repo_class} || 'Git::Repo';
  98         $opts{repo_dir} = File::Spec->catfile($self->{root_dir}, $opts{repo_dir});
  99         return $repo_class->new(%opts);
 100 }
 101
 102
 103 1;