git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40        [-s subst] [-m] [-M regex] [-S regex] [CVS_module]
  41 END
  42         exit(1);
  43 }
  44
  45 sub read_author_info($) {
  46         my ($file) = @_;
  47         my $user;
  48         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50         while (<$f>) {
  51                 # Expected format is this:
  52                 #   exon=Andreas Ericsson <ae@op5.se>
  53                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                         $user = $1;
  55                         $conv_author_name{$user} = $2;
  56                         $conv_author_email{$user} = $3;
  57                 }
  58                 # However, we also read from CVSROOT/users format
  59                 # to ease migration.
  60                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                         my $mapped;
  62                         ($user, $mapped) = ($1, $3);
  63                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                 $conv_author_name{$user} = $1;
  65                                 $conv_author_email{$user} = $2;
  66                         }
  67                         elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                 $conv_author_name{$user} = $user;
  69                                 $conv_author_email{$user} = $1;
  70                         }
  71                 }
  72                 # NEEDSWORK: Maybe warn on unrecognized lines?
  73         }
  74         close ($f);
  75 }
  76
  77 sub write_author_info($) {
  78         my ($file) = @_;
  79         open my $f, '>', $file or
  80           die("Failed to open $file for writing: $!");
  81
  82         foreach (keys %conv_author_name) {
  83                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84         }
  85         close ($f);
  86 }
  87
  88 getopts("hivmkuo:d:p:C:z:s:M:P:A:S:") or usage();
  89 usage if $opt_h;
  90
  91 @ARGV <= 1 or usage();
  92
  93 if($opt_d) {
  94         $ENV{"CVSROOT"} = $opt_d;
  95 } elsif(-f 'CVS/Root') {
  96         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97         $opt_d = <$f>;
  98         chomp $opt_d;
  99         close $f;
 100         $ENV{"CVSROOT"} = $opt_d;
 101 } elsif($ENV{"CVSROOT"}) {
 102         $opt_d = $ENV{"CVSROOT"};
 103 } else {
 104         die "CVSROOT needs to be set";
 105 }
 106 $opt_o ||= "origin";
 107 $opt_s ||= "-";
 108 my $git_tree = $opt_C;
 109 $git_tree ||= ".";
 110
 111 my $cvs_tree;
 112 if ($#ARGV == 0) {
 113         $cvs_tree = $ARGV[0];
 114 } elsif (-f 'CVS/Repository') {
 115         open my $f, '<', 'CVS/Repository' or
 116             die 'Failed to open CVS/Repository';
 117         $cvs_tree = <$f>;
 118         chomp $cvs_tree;
 119         close $f;
 120 } else {
 121         usage();
 122 }
 123
 124 our @mergerx = ();
 125 if ($opt_m) {
 126         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 127 }
 128 if ($opt_M) {
 129         push (@mergerx, qr/$opt_M/);
 130 }
 131
 132 select(STDERR); $|=1; select(STDOUT);
 133
 134
 135 package CVSconn;
 136 # Basic CVS dialog.
 137 # We're only interested in connecting and downloading, so ...
 138
 139 use File::Spec;
 140 use File::Temp qw(tempfile);
 141 use POSIX qw(strftime dup2);
 142
 143 sub new {
 144         my($what,$repo,$subdir) = @_;
 145         $what=ref($what) if ref($what);
 146
 147         my $self = {};
 148         $self->{'buffer'} = "";
 149         bless($self,$what);
 150
 151         $repo =~ s#/+$##;
 152         $self->{'fullrep'} = $repo;
 153         $self->conn();
 154
 155         $self->{'subdir'} = $subdir;
 156         $self->{'lines'} = undef;
 157
 158         return $self;
 159 }
 160
 161 sub conn {
 162         my $self = shift;
 163         my $repo = $self->{'fullrep'};
 164         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 165                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 166                 $user="anonymous" unless defined $user;
 167                 my $rr2 = "-";
 168                 unless($port) {
 169                         $rr2 = ":pserver:$user\@$serv:$repo";
 170                         $port=2401;
 171                 }
 172                 my $rr = ":pserver:$user\@$serv:$port$repo";
 173
 174                 unless($pass) {
 175                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 176                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 177                                 while(<H>) {
 178                                         chomp;
 179                                         s/^\/\d+\s+//;
 180                                         my ($w,$p) = split(/\s/,$_,2);
 181                                         if($w eq $rr or $w eq $rr2) {
 182                                                 $pass = $p;
 183                                                 last;
 184                                         }
 185                                 }
 186                         };
 187                 }
 188                 $pass="A" unless $pass;
 189
 190                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 191                 die "Socket to $serv: $!\n" unless defined $s;
 192                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 193                         or die "Write to $serv: $!\n";
 194                 $s->flush();
 195
 196                 my $rep = <$s>;
 197
 198                 if($rep ne "I LOVE YOU\n") {
 199                         $rep="<unknown>" unless $rep;
 200                         die "AuthReply: $rep\n";
 201                 }
 202                 $self->{'socketo'} = $s;
 203                 $self->{'socketi'} = $s;
 204         } else { # local or ext: Fork off our own cvs server.
 205                 my $pr = IO::Pipe->new();
 206                 my $pw = IO::Pipe->new();
 207                 my $pid = fork();
 208                 die "Fork: $!\n" unless defined $pid;
 209                 my $cvs = 'cvs';
 210                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 211                 my $rsh = 'rsh';
 212                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 213
 214                 my @cvs = ($cvs, 'server');
 215                 my ($local, $user, $host);
 216                 $local = $repo =~ s/:local://;
 217                 if (!$local) {
 218                     $repo =~ s/:ext://;
 219                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 220                     ($user, $host) = ($1, $2);
 221                 }
 222                 if (!$local) {
 223                     if ($user) {
 224                         unshift @cvs, $rsh, '-l', $user, $host;
 225                     } else {
 226                         unshift @cvs, $rsh, $host;
 227                     }
 228                 }
 229
 230                 unless($pid) {
 231                         $pr->writer();
 232                         $pw->reader();
 233                         dup2($pw->fileno(),0);
 234                         dup2($pr->fileno(),1);
 235                         $pr->close();
 236                         $pw->close();
 237                         exec(@cvs);
 238                 }
 239                 $pw->writer();
 240                 $pr->reader();
 241                 $self->{'socketo'} = $pw;
 242                 $self->{'socketi'} = $pr;
 243         }
 244         $self->{'socketo'}->write("Root $repo\n");
 245
 246         # Trial and error says that this probably is the minimum set
 247         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 248
 249         $self->{'socketo'}->write("valid-requests\n");
 250         $self->{'socketo'}->flush();
 251
 252         chomp(my $rep=$self->readline());
 253         if($rep !~ s/^Valid-requests\s*//) {
 254                 $rep="<unknown>" unless $rep;
 255                 die "Expected Valid-requests from server, but got: $rep\n";
 256         }
 257         chomp(my $res=$self->readline());
 258         die "validReply: $res\n" if $res ne "ok";
 259
 260         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 261         $self->{'repo'} = $repo;
 262 }
 263
 264 sub readline {
 265         my($self) = @_;
 266         return $self->{'socketi'}->getline();
 267 }
 268
 269 sub _file {
 270         # Request a file with a given revision.
 271         # Trial and error says this is a good way to do it. :-/
 272         my($self,$fn,$rev) = @_;
 273         $self->{'socketo'}->write("Argument -N\n") or return undef;
 274         $self->{'socketo'}->write("Argument -P\n") or return undef;
 275         # -kk: Linus' version doesn't use it - defaults to off
 276         if ($opt_k) {
 277             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 278         }
 279         $self->{'socketo'}->write("Argument -r\n") or return undef;
 280         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 281         $self->{'socketo'}->write("Argument --\n") or return undef;
 282         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 283         $self->{'socketo'}->write("Directory .\n") or return undef;
 284         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 285         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 286         $self->{'socketo'}->write("co\n") or return undef;
 287         $self->{'socketo'}->flush() or return undef;
 288         $self->{'lines'} = 0;
 289         return 1;
 290 }
 291 sub _line {
 292         # Read a line from the server.
 293         # ... except that 'line' may be an entire file. ;-)
 294         my($self, $fh) = @_;
 295         die "Not in lines" unless defined $self->{'lines'};
 296
 297         my $line;
 298         my $res=0;
 299         while(defined($line = $self->readline())) {
 300                 # M U gnupg-cvs-rep/AUTHORS
 301                 # Updated gnupg-cvs-rep/
 302                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 303                 # /AUTHORS/1.1///T1.1
 304                 # u=rw,g=rw,o=rw
 305                 # 0
 306                 # ok
 307
 308                 if($line =~ s/^(?:Created|Updated) //) {
 309                         $line = $self->readline(); # path
 310                         $line = $self->readline(); # Entries line
 311                         my $mode = $self->readline(); chomp $mode;
 312                         $self->{'mode'} = $mode;
 313                         defined (my $cnt = $self->readline())
 314                                 or die "EOF from server after 'Changed'\n";
 315                         chomp $cnt;
 316                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 317                         $line="";
 318                         $res=0;
 319                         while($cnt) {
 320                                 my $buf;
 321                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 322                                 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 323                                 print $fh $buf;
 324                                 $res += $num;
 325                                 $cnt -= $num;
 326                         }
 327                 } elsif($line =~ s/^ //) {
 328                         print $fh $line;
 329                         $res += length($line);
 330                 } elsif($line =~ /^M\b/) {
 331                         # output, do nothing
 332                 } elsif($line =~ /^Mbinary\b/) {
 333                         my $cnt;
 334                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 335                         chomp $cnt;
 336                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 337                         $line="";
 338                         while($cnt) {
 339                                 my $buf;
 340                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 341                                 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 342                                 print $fh $buf;
 343                                 $res += $num;
 344                                 $cnt -= $num;
 345                         }
 346                 } else {
 347                         chomp $line;
 348                         if($line eq "ok") {
 349                                 # print STDERR "S: ok (".length($res).")\n";
 350                                 return $res;
 351                         } elsif($line =~ s/^E //) {
 352                                 # print STDERR "S: $line\n";
 353                         } elsif($line =~ /^(Remove-entry|Removed) /i) {
 354                                 $line = $self->readline(); # filename
 355                                 $line = $self->readline(); # OK
 356                                 chomp $line;
 357                                 die "Unknown: $line" if $line ne "ok";
 358                                 return -1;
 359                         } else {
 360                                 die "Unknown: $line\n";
 361                         }
 362                 }
 363         }
 364         return undef;
 365 }
 366 sub file {
 367         my($self,$fn,$rev) = @_;
 368         my $res;
 369
 370         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 371                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 372
 373         $self->_file($fn,$rev) and $res = $self->_line($fh);
 374
 375         if (!defined $res) {
 376             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 377             truncate $fh, 0;
 378             $self->conn();
 379             $self->_file($fn,$rev) or die "No file command send";
 380             $res = $self->_line($fh);
 381             die "Retry failed" unless defined $res;
 382         }
 383         close ($fh);
 384
 385         return ($name, $res);
 386 }
 387
 388
 389 package main;
 390
 391 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 392
 393
 394 sub pdate($) {
 395         my($d) = @_;
 396         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 397                 or die "Unparseable date: $d\n";
 398         my $y=$1; $y-=1900 if $y>1900;
 399         return timegm($6||0,$5,$4,$3,$2-1,$y);
 400 }
 401
 402 sub pmode($) {
 403         my($mode) = @_;
 404         my $m = 0;
 405         my $mm = 0;
 406         my $um = 0;
 407         for my $x(split(//,$mode)) {
 408                 if($x eq ",") {
 409                         $m |= $mm&$um;
 410                         $mm = 0;
 411                         $um = 0;
 412                 } elsif($x eq "u") { $um |= 0700;
 413                 } elsif($x eq "g") { $um |= 0070;
 414                 } elsif($x eq "o") { $um |= 0007;
 415                 } elsif($x eq "r") { $mm |= 0444;
 416                 } elsif($x eq "w") { $mm |= 0222;
 417                 } elsif($x eq "x") { $mm |= 0111;
 418                 } elsif($x eq "=") { # do nothing
 419                 } else { die "Unknown mode: $mode\n";
 420                 }
 421         }
 422         $m |= $mm&$um;
 423         return $m;
 424 }
 425
 426 sub getwd() {
 427         my $pwd = `pwd`;
 428         chomp $pwd;
 429         return $pwd;
 430 }
 431
 432
 433 sub get_headref($$) {
 434     my $name    = shift;
 435     my $git_dir = shift;
 436     my $sha;
 437
 438     if (open(C,"$git_dir/refs/heads/$name")) {
 439         chomp($sha = <C>);
 440         close(C);
 441         length($sha) == 40
 442             or die "Cannot get head id for $name ($sha): $!\n";
 443     }
 444     return $sha;
 445 }
 446
 447
 448 -d $git_tree
 449         or mkdir($git_tree,0777)
 450         or die "Could not create $git_tree: $!";
 451 chdir($git_tree);
 452
 453 my $last_branch = "";
 454 my $orig_branch = "";
 455 my %branch_date;
 456 my $tip_at_start = undef;
 457
 458 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 459 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 460 $ENV{"GIT_DIR"} = $git_dir;
 461 my $orig_git_index;
 462 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 463 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 464                                     DIR => File::Spec->tmpdir());
 465 close ($git_ih);
 466 $ENV{GIT_INDEX_FILE} = $git_index;
 467 unless(-d $git_dir) {
 468         system("git-init-db");
 469         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 470         system("git-read-tree");
 471         die "Cannot init an empty tree: $?\n" if $?;
 472
 473         $last_branch = $opt_o;
 474         $orig_branch = "";
 475 } else {
 476         -f "$git_dir/refs/heads/$opt_o"
 477                 or die "Branch '$opt_o' does not exist.\n".
 478                        "Either use the correct '-o branch' option,\n".
 479                        "or import to a new repository.\n";
 480
 481         open(F, "git-symbolic-ref HEAD |") or
 482                 die "Cannot run git-symbolic-ref: $!\n";
 483         chomp ($last_branch = <F>);
 484         $last_branch = basename($last_branch);
 485         close(F);
 486         unless($last_branch) {
 487                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 488                 $last_branch = "master";
 489         }
 490         $orig_branch = $last_branch;
 491         $tip_at_start = `git-rev-parse --verify HEAD`;
 492
 493         # populate index
 494         system('git-read-tree', $last_branch);
 495         die "read-tree failed: $?\n" if $?;
 496
 497         # Get the last import timestamps
 498         opendir(D,"$git_dir/refs/heads");
 499         while(defined(my $head = readdir(D))) {
 500                 next if $head =~ /^\./;
 501                 open(F,"$git_dir/refs/heads/$head")
 502                         or die "Bad head branch: $head: $!\n";
 503                 chomp(my $ftag = <F>);
 504                 close(F);
 505                 open(F,"git-cat-file commit $ftag |");
 506                 while(<F>) {
 507                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 508                         $branch_date{$head} = $1;
 509                         last;
 510                 }
 511                 close(F);
 512         }
 513         closedir(D);
 514 }
 515
 516 -d $git_dir
 517         or die "Could not create git subdir ($git_dir).\n";
 518
 519 # now we read (and possibly save) author-info as well
 520 -f "$git_dir/cvs-authors" and
 521   read_author_info("$git_dir/cvs-authors");
 522 if ($opt_A) {
 523         read_author_info($opt_A);
 524         write_author_info("$git_dir/cvs-authors");
 525 }
 526
 527 my $pid = open(CVS,"-|");
 528 die "Cannot fork: $!\n" unless defined $pid;
 529 unless($pid) {
 530         my @opt;
 531         @opt = split(/,/,$opt_p) if defined $opt_p;
 532         unshift @opt, '-z', $opt_z if defined $opt_z;
 533         unshift @opt, '-q'         unless defined $opt_v;
 534         unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 535                 push @opt, '--cvs-direct';
 536         }
 537         if ($opt_P) {
 538             exec("cat", $opt_P);
 539         } else {
 540             exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 541             die "Could not start cvsps: $!\n";
 542         }
 543 }
 544
 545
 546 ## cvsps output:
 547 #---------------------
 548 #PatchSet 314
 549 #Date: 1999/09/18 13:03:59
 550 #Author: wkoch
 551 #Branch: STABLE-BRANCH-1-0
 552 #Ancestor branch: HEAD
 553 #Tag: (none)
 554 #Log:
 555 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 556 #Members:
 557 #       README:1.57->1.57.2.1
 558 #       VERSION:1.96->1.96.2.1
 559 #
 560 #---------------------
 561
 562 my $state = 0;
 563
 564 my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 565 my(@old,@new,@skipped);
 566 my $commit = sub {
 567         my $pid;
 568         while(@old) {
 569                 my @o2;
 570                 if(@old > 55) {
 571                         @o2 = splice(@old,0,50);
 572                 } else {
 573                         @o2 = @old;
 574                         @old = ();
 575                 }
 576                 system("git-update-index","--force-remove","--",@o2);
 577                 die "Cannot remove files: $?\n" if $?;
 578         }
 579         while(@new) {
 580                 my @n2;
 581                 if(@new > 12) {
 582                         @n2 = splice(@new,0,10);
 583                 } else {
 584                         @n2 = @new;
 585                         @new = ();
 586                 }
 587                 system("git-update-index","--add",
 588                         (map { ('--cacheinfo', @$_) } @n2));
 589                 die "Cannot add files: $?\n" if $?;
 590         }
 591
 592         $pid = open(C,"-|");
 593         die "Cannot fork: $!" unless defined $pid;
 594         unless($pid) {
 595                 exec("git-write-tree");
 596                 die "Cannot exec git-write-tree: $!\n";
 597         }
 598         chomp(my $tree = <C>);
 599         length($tree) == 40
 600                 or die "Cannot get tree id ($tree): $!\n";
 601         close(C)
 602                 or die "Error running git-write-tree: $?\n";
 603         print "Tree ID $tree\n" if $opt_v;
 604
 605         my $parent = "";
 606         if(open(C,"$git_dir/refs/heads/$last_branch")) {
 607                 chomp($parent = <C>);
 608                 close(C);
 609                 length($parent) == 40
 610                         or die "Cannot get parent id ($parent): $!\n";
 611                 print "Parent ID $parent\n" if $opt_v;
 612         }
 613
 614         my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 615         my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 616         $pid = fork();
 617         die "Fork: $!\n" unless defined $pid;
 618         unless($pid) {
 619                 $pr->writer();
 620                 $pw->reader();
 621                 open(OUT,">&STDOUT");
 622                 dup2($pw->fileno(),0);
 623                 dup2($pr->fileno(),1);
 624                 $pr->close();
 625                 $pw->close();
 626
 627                 my @par = ();
 628                 @par = ("-p",$parent) if $parent;
 629
 630                 # loose detection of merges
 631                 # based on the commit msg
 632                 foreach my $rx (@mergerx) {
 633                         if ($logmsg =~ $rx) {
 634                                 my $mparent = $1;
 635                                 if ($mparent eq 'HEAD') { $mparent = $opt_o };
 636                                 if ( -e "$git_dir/refs/heads/$mparent") {
 637                                         $mparent = get_headref($mparent, $git_dir);
 638                                         push @par, '-p', $mparent;
 639                                         print OUT "Merge parent branch: $mparent\n" if $opt_v;
 640                                 }
 641                         }
 642                 }
 643
 644                 exec("env",
 645                         "GIT_AUTHOR_NAME=$author_name",
 646                         "GIT_AUTHOR_EMAIL=$author_email",
 647                         "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 648                         "GIT_COMMITTER_NAME=$author_name",
 649                         "GIT_COMMITTER_EMAIL=$author_email",
 650                         "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 651                         "git-commit-tree", $tree,@par);
 652                 die "Cannot exec git-commit-tree: $!\n";
 653
 654                 close OUT;
 655         }
 656         $pw->writer();
 657         $pr->reader();
 658
 659         # compatibility with git2cvs
 660         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 661         $logmsg =~ s/[\s\n]+\z//;
 662
 663         if (@skipped) {
 664             $logmsg .= "\n\n\nSKIPPED:\n\t";
 665             $logmsg .= join("\n\t", @skipped) . "\n";
 666             @skipped = ();
 667         }
 668
 669         print $pw "$logmsg\n"
 670                 or die "Error writing to git-commit-tree: $!\n";
 671         $pw->close();
 672
 673         print "Committed patch $patchset ($branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 674         chomp(my $cid = <$pr>);
 675         length($cid) == 40
 676                 or die "Cannot get commit id ($cid): $!\n";
 677         print "Commit ID $cid\n" if $opt_v;
 678         $pr->close();
 679
 680         waitpid($pid,0);
 681         die "Error running git-commit-tree: $?\n" if $?;
 682
 683         system("git-update-ref refs/heads/$branch $cid") == 0
 684                 or die "Cannot write branch $branch for update: $!\n";
 685
 686         if($tag) {
 687                 my($in, $out) = ('','');
 688                 my($xtag) = $tag;
 689                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 690                 $xtag =~ tr/_/\./ if ( $opt_u );
 691                 $xtag =~ s/[\/]/$opt_s/g;
 692
 693                 my $pid = open2($in, $out, 'git-mktag');
 694                 print $out "object $cid\n".
 695                     "type commit\n".
 696                     "tag $xtag\n".
 697                     "tagger $author_name <$author_email>\n"
 698                     or die "Cannot create tag object $xtag: $!\n";
 699                 close($out)
 700                     or die "Cannot create tag object $xtag: $!\n";
 701
 702                 my $tagobj = <$in>;
 703                 chomp $tagobj;
 704
 705                 if ( !close($in) or waitpid($pid, 0) != $pid or
 706                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 707                     die "Cannot create tag object $xtag: $!\n";
 708                 }
 709
 710
 711                 open(C,">$git_dir/refs/tags/$xtag")
 712                         or die "Cannot create tag $xtag: $!\n";
 713                 print C "$tagobj\n"
 714                         or die "Cannot write tag $xtag: $!\n";
 715                 close(C)
 716                         or die "Cannot write tag $xtag: $!\n";
 717
 718                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 719         }
 720 };
 721
 722 while(<CVS>) {
 723         chomp;
 724         if($state == 0 and /^-+$/) {
 725                 $state = 1;
 726         } elsif($state == 0) {
 727                 $state = 1;
 728                 redo;
 729         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 730                 $patchset = 0+$_;
 731                 $state=2;
 732         } elsif($state == 2 and s/^Date:\s+//) {
 733                 $date = pdate($_);
 734                 unless($date) {
 735                         print STDERR "Could not parse date: $_\n";
 736                         $state=0;
 737                         next;
 738                 }
 739                 $state=3;
 740         } elsif($state == 3 and s/^Author:\s+//) {
 741                 s/\s+$//;
 742                 if (/^(.*?)\s+<(.*)>/) {
 743                     ($author_name, $author_email) = ($1, $2);
 744                 } elsif ($conv_author_name{$_}) {
 745                         $author_name = $conv_author_name{$_};
 746                         $author_email = $conv_author_email{$_};
 747                 } else {
 748                     $author_name = $author_email = $_;
 749                 }
 750                 $state = 4;
 751         } elsif($state == 4 and s/^Branch:\s+//) {
 752                 s/\s+$//;
 753                 s/[\/]/$opt_s/g;
 754                 $branch = $_;
 755                 $state = 5;
 756         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 757                 s/\s+$//;
 758                 $ancestor = $_;
 759                 $ancestor = $opt_o if $ancestor eq "HEAD";
 760                 $state = 6;
 761         } elsif($state == 5) {
 762                 $ancestor = undef;
 763                 $state = 6;
 764                 redo;
 765         } elsif($state == 6 and s/^Tag:\s+//) {
 766                 s/\s+$//;
 767                 if($_ eq "(none)") {
 768                         $tag = undef;
 769                 } else {
 770                         $tag = $_;
 771                 }
 772                 $state = 7;
 773         } elsif($state == 7 and /^Log:/) {
 774                 $logmsg = "";
 775                 $state = 8;
 776         } elsif($state == 8 and /^Members:/) {
 777                 $branch = $opt_o if $branch eq "HEAD";
 778                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 779                         # skip
 780                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 781                         $state = 11;
 782                         next;
 783                 }
 784                 if($ancestor) {
 785                         if(-f "$git_dir/refs/heads/$branch") {
 786                                 print STDERR "Branch $branch already exists!\n";
 787                                 $state=11;
 788                                 next;
 789                         }
 790                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 791                                 print STDERR "Branch $ancestor does not exist!\n";
 792                                 $state=11;
 793                                 next;
 794                         }
 795                         chomp(my $id = <H>);
 796                         close(H);
 797                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 798                                 print STDERR "Could not create branch $branch: $!\n";
 799                                 $state=11;
 800                                 next;
 801                         }
 802                         print H "$id\n"
 803                                 or die "Could not write branch $branch: $!";
 804                         close(H)
 805                                 or die "Could not write branch $branch: $!";
 806                 }
 807                 if(($ancestor || $branch) ne $last_branch) {
 808                         print "Switching from $last_branch to $branch\n" if $opt_v;
 809                         system("git-read-tree", $branch);
 810                         die "read-tree failed: $?\n" if $?;
 811                 }
 812                 $last_branch = $branch if $branch ne $last_branch;
 813                 $state = 9;
 814         } elsif($state == 8) {
 815                 $logmsg .= "$_\n";
 816         } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 817 #       VERSION:1.96->1.96.2.1
 818                 my $init = ($2 eq "INITIAL");
 819                 my $fn = $1;
 820                 my $rev = $3;
 821                 $fn =~ s#^/+##;
 822                 if ($opt_S && $fn =~ m/$opt_S/) {
 823                     print "SKIPPING $fn v $rev\n";
 824                     push(@skipped, $fn);
 825                     next;
 826                 }
 827                 print "Fetching $fn   v $rev\n" if $opt_v;
 828                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 829                 if($size == -1) {
 830                         push(@old,$fn);
 831                         print "Drop $fn\n" if $opt_v;
 832                 } else {
 833                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 834                         my $pid = open(my $F, '-|');
 835                         die $! unless defined $pid;
 836                         if (!$pid) {
 837                             exec("git-hash-object", "-w", $tmpname)
 838                                 or die "Cannot create object: $!\n";
 839                         }
 840                         my $sha = <$F>;
 841                         chomp $sha;
 842                         close $F;
 843                         my $mode = pmode($cvs->{'mode'});
 844                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 845                 }
 846                 unlink($tmpname);
 847         } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 848                 my $fn = $1;
 849                 $fn =~ s#^/+##;
 850                 push(@old,$fn);
 851                 print "Delete $fn\n" if $opt_v;
 852         } elsif($state == 9 and /^\s*$/) {
 853                 $state = 10;
 854         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 855                 &$commit();
 856                 $state = 1;
 857         } elsif($state == 11 and /^-+$/) {
 858                 $state = 1;
 859         } elsif(/^-+$/) { # end of unknown-line processing
 860                 $state = 1;
 861         } elsif($state != 11) { # ignore stuff when skipping
 862                 print "* UNKNOWN LINE * $_\n";
 863         }
 864 }
 865 &$commit() if $branch and $state != 11;
 866
 867 unlink($git_index);
 868
 869 if (defined $orig_git_index) {
 870         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 871 } else {
 872         delete $ENV{GIT_INDEX_FILE};
 873 }
 874
 875 # Now switch back to the branch we were in before all of this happened
 876 if($orig_branch) {
 877         print "DONE.\n" if $opt_v;
 878         if ($opt_i) {
 879                 exit 0;
 880         }
 881         my $tip_at_end = `git-rev-parse --verify HEAD`;
 882         if ($tip_at_start ne $tip_at_end) {
 883                 for ($tip_at_start, $tip_at_end) { chomp; }
 884                 print "Fetched into the current branch.\n" if $opt_v;
 885                 system(qw(git-read-tree -u -m),
 886                        $tip_at_start, $tip_at_end);
 887                 die "Fast-forward update failed: $?\n" if $?;
 888         }
 889         else {
 890                 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 891                 die "Could not merge $opt_o into the current branch.\n" if $?;
 892         }
 893 } else {
 894         $orig_branch = "master";
 895         print "DONE; creating $orig_branch branch\n" if $opt_v;
 896         system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 897                 unless -f "$git_dir/refs/heads/master";
 898         system('git-update-ref', 'HEAD', "$orig_branch");
 899         unless ($opt_i) {
 900                 system('git checkout');
 901                 die "checkout failed: $?\n" if $?;
 902         }
 903 }