configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10    [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11    config_appended_defs="$config_appended_defs${newline}$1=$2"])
  12
  13 # GIT_CONF_SUBST_INIT
  14 # -------------------
  15 # Prepare shell variables and autoconf machine required by later calls
  16 # to GIT_CONF_SUBST.
  17 AC_DEFUN([GIT_CONF_SUBST_INIT],
  18     [config_appended_defs=; newline='
  19 '
  20     AC_CONFIG_COMMANDS([$config_file],
  21                        [echo "$config_appended_defs" >> "$config_file"],
  22                        [config_file=$config_file
  23                         config_appended_defs="$config_appended_defs"])])
  24
  25 # GIT_ARG_SET_PATH(PROGRAM)
  26 # -------------------------
  27 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  28 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  29 # --without-PROGRAM version used.
  30 AC_DEFUN([GIT_ARG_SET_PATH],
  31     [AC_ARG_WITH([$1],
  32         [AS_HELP_STRING([--with-$1=PATH],
  33                         [provide PATH to $1])],
  34         [GIT_CONF_APPEND_PATH([$1], [$2])],
  35         [])])
  36
  37 # GIT_CONF_APPEND_PATH(PROGRAM)
  38 # -----------------------------
  39 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  40 # Used by GIT_ARG_SET_PATH(PROGRAM)
  41 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  42 # --without-PROGRAM is used.
  43 AC_DEFUN([GIT_CONF_APPEND_PATH],
  44     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  45     if test "$withval" = "no"; then
  46         if test -n "$2"; then
  47                 GIT_UC_PROGRAM[]_PATH=$withval
  48                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  49                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  50                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  51         else
  52                 AC_MSG_ERROR([You cannot use git without $1])
  53         fi
  54     else
  55         if test "$withval" = "yes"; then
  56                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  57         else
  58                 GIT_UC_PROGRAM[]_PATH=$withval
  59                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  60                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  61         fi
  62     fi
  63     m4_popdef([GIT_UC_PROGRAM])])
  64
  65 # GIT_PARSE_WITH(PACKAGE)
  66 # -----------------------
  67 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  68 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  69 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  70 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  71 AC_DEFUN([GIT_PARSE_WITH],
  72     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  73     if test "$withval" = "no"; then
  74         NO_[]GIT_UC_PACKAGE=YesPlease
  75     elif test "$withval" = "yes"; then
  76         NO_[]GIT_UC_PACKAGE=
  77     else
  78         NO_[]GIT_UC_PACKAGE=
  79         GIT_UC_PACKAGE[]DIR=$withval
  80         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  81         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  82     fi
  83     m4_popdef([GIT_UC_PACKAGE])])
  84
  85 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  86 # -----------------------------------------------------
  87 # Set VAR to the value specied by --with-WITHNAME.
  88 # No verification of arguments is performed, but warnings are issued
  89 # if either 'yes' or 'no' is specified.
  90 # HELP_TEXT is presented when --help is called.
  91 # This is a direct way to allow setting variables in the Makefile.
  92 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  93 [AC_ARG_WITH([$1],
  94  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  95  if test -n "$withval"; then
  96   if test "$withval" = "yes" -o "$withval" = "no"; then
  97     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  98                      [a value for $1 ($2).  Maybe you do...?])
  99   fi
 100   AC_MSG_NOTICE([Setting $2 to $withval])
 101   GIT_CONF_SUBST([$2], [$withval])
 102  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 103
 104 #
 105 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 106 # -----------------------------------------
 107 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 108 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 109 # -Wall), it does not work.  By looking for function definition in
 110 # libraries, this problem can be worked around.
 111 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 112   AC_SEARCH_LIBS([$1],,
 113   [$2],[$3])
 114 ],[$3])])
 115
 116 #
 117 # GIT_STASH_FLAGS(BASEPATH_VAR)
 118 # -----------------------------
 119 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 120 # tests that may want to take user settings into account.
 121 AC_DEFUN([GIT_STASH_FLAGS],[
 122 if test -n "$1"; then
 123    old_CPPFLAGS="$CPPFLAGS"
 124    old_LDFLAGS="$LDFLAGS"
 125    CPPFLAGS="-I$1/include $CPPFLAGS"
 126    LDFLAGS="-L$1/$lib $LDFLAGS"
 127 fi
 128 ])
 129
 130 dnl
 131 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 132 dnl -----------------------------
 133 dnl Restore the stashed *FLAGS values.
 134 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 135 if test -n "$1"; then
 136    CPPFLAGS="$old_CPPFLAGS"
 137    LDFLAGS="$old_LDFLAGS"
 138 fi
 139 ])
 140
 141 ## Configure body starts here.
 142
 143 AC_PREREQ(2.59)
 144 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 145
 146 AC_CONFIG_SRCDIR([git.c])
 147
 148 config_file=config.mak.autogen
 149 config_in=config.mak.in
 150
 151 # Directories holding "saner" versions of common or POSIX binaries.
 152 AC_ARG_WITH([sane-tool-path],
 153   [AS_HELP_STRING(
 154     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 155     [Directories to prepend to PATH in build system and generated scripts])],
 156   [if test "$withval" = "no"; then
 157     withval=''
 158   else
 159     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 160   fi
 161   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 162   [# If the "--with-sane-tool-path" option was not given, don't touch
 163    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 164    # This should minimize spurious differences in the behaviour of the
 165    # Git build system when configure is used w.r.t. when it is not.
 166    :])
 167
 168 ## Site configuration related to programs (before tests)
 169 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 170 #
 171 # Set lib to alternative name of lib directory (e.g. lib64)
 172 AC_ARG_WITH([lib],
 173  [AS_HELP_STRING([--with-lib=ARG],
 174                  [ARG specifies alternative name for lib directory])],
 175  [if test "$withval" = "no" || test "$withval" = "yes"; then
 176         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 177   else
 178         lib=$withval
 179         AC_MSG_NOTICE([Setting lib to '$lib'])
 180         GIT_CONF_SUBST([lib], [$withval])
 181   fi])
 182
 183 if test -z "$lib"; then
 184    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 185    lib=lib
 186 fi
 187
 188 AC_ARG_ENABLE([pthreads],
 189  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 190   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 191   [The default if FLAGS is not specified is to try first -pthread]
 192   [and then -lpthread.]
 193   [--without-pthreads will disable threading.])],
 194 [
 195 if test "x$enableval" = "xyes"; then
 196    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 197 elif test "x$enableval" != "xno"; then
 198    PTHREAD_CFLAGS=$enableval
 199    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 200 else
 201    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 202    NO_PTHREADS=YesPlease
 203    USER_NOPTHREAD=1
 204 fi],
 205 [
 206    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 207 ])
 208
 209 # Define option to enable JavaScript minification
 210 AC_ARG_ENABLE([jsmin],
 211 [AS_HELP_STRING([--enable-jsmin=PATH],
 212   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 213 [
 214   JSMIN=$enableval;
 215   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 216   GIT_CONF_SUBST([JSMIN], [$enableval])
 217 ])
 218
 219 # Define option to enable CSS minification
 220 AC_ARG_ENABLE([cssmin],
 221 [AS_HELP_STRING([--enable-cssmin=PATH],
 222   [PATH is the name of a CSS minifier or the absolute path to one.])],
 223 [
 224   CSSMIN=$enableval;
 225   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 226   GIT_CONF_SUBST([CSSMIN], [$enableval])
 227 ])
 228
 229 ## Site configuration (override autodetection)
 230 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 231 AC_MSG_NOTICE([CHECKS for site configuration])
 232 #
 233 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 234 # tests.  These tests take up a significant amount of the total test time
 235 # but are not needed unless you plan to talk to SVN repos.
 236 #
 237 # Define PPC_SHA1 environment variable when running make to make use of
 238 # a bundled SHA1 routine optimized for PowerPC.
 239 #
 240 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 241 # This also implies BLK_SHA1.
 242 #
 243 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 244 # /foo/bar/include and /foo/bar/lib directories.
 245 AC_ARG_WITH(openssl,
 246 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 247 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 248 GIT_PARSE_WITH([openssl]))
 249
 250 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 251 # able to use Perl-compatible regular expressions.
 252 #
 253 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
 254 # /foo/bar/include and /foo/bar/lib directories.
 255 #
 256 AC_ARG_WITH(libpcre,
 257 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
 258 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 259     if test "$withval" = "no"; then
 260         USE_LIBPCRE=
 261     elif test "$withval" = "yes"; then
 262         USE_LIBPCRE=YesPlease
 263     else
 264         USE_LIBPCRE=YesPlease
 265         LIBPCREDIR=$withval
 266         AC_MSG_NOTICE([Setting LIBPCREDIR to $withval])
 267         GIT_CONF_SUBST([LIBPCREDIR], [$withval])
 268     fi)
 269 #
 270 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 271 # git-http-push are not built, and you cannot use http:// and https://
 272 # transports.
 273 #
 274 # Define CURLDIR=/foo/bar if your curl header and library files are in
 275 # /foo/bar/include and /foo/bar/lib directories.
 276 AC_ARG_WITH(curl,
 277 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 278 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 279 GIT_PARSE_WITH(curl))
 280 #
 281 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 282 # not built, and you cannot push using http:// and https:// transports.
 283 #
 284 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 285 # /foo/bar/include and /foo/bar/lib directories.
 286 AC_ARG_WITH(expat,
 287 AS_HELP_STRING([--with-expat],
 288 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 289 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 290 GIT_PARSE_WITH(expat))
 291 #
 292 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 293 # installed in /sw, but don't want GIT to link against any libraries
 294 # installed there.  If defined you may specify your own (or Fink's)
 295 # include directories and library directories by defining CFLAGS
 296 # and LDFLAGS appropriately.
 297 #
 298 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 299 # have DarwinPorts installed in /opt/local, but don't want GIT to
 300 # link against any libraries installed there.  If defined you may
 301 # specify your own (or DarwinPort's) include directories and
 302 # library directories by defining CFLAGS and LDFLAGS appropriately.
 303 #
 304 # Define NO_MMAP if you want to avoid mmap.
 305 #
 306 # Define NO_ICONV if your libc does not properly support iconv.
 307 AC_ARG_WITH(iconv,
 308 AS_HELP_STRING([--without-iconv],
 309 [if your architecture doesn't properly support iconv])
 310 AS_HELP_STRING([--with-iconv=PATH],
 311 [PATH is prefix for libiconv library and headers])
 312 AS_HELP_STRING([],
 313 [used only if you need linking with libiconv]),
 314 GIT_PARSE_WITH(iconv))
 315
 316 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 317 #
 318 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 319 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 320 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 321 # randomly break unless your underlying filesystem supports those sub-second
 322 # times (my ext3 doesn't).
 323 #
 324 # Define USE_STDEV below if you want git to care about the underlying device
 325 # change being considered an inode change from the update-index perspective.
 326
 327 #
 328 # Allow user to set ETC_GITCONFIG variable
 329 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 330                         Use VALUE instead of /etc/gitconfig as the
 331                         global git configuration file.
 332                         If VALUE is not fully qualified it will be interpreted
 333                         as a path relative to the computed prefix at runtime.)
 334
 335 #
 336 # Allow user to set ETC_GITATTRIBUTES variable
 337 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 338                         Use VALUE instead of /etc/gitattributes as the
 339                         global git attributes file.
 340                         If VALUE is not fully qualified it will be interpreted
 341                         as a path relative to the computed prefix at runtime.)
 342
 343 #
 344 # Allow user to set the default pager
 345 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 346                         Use VALUE as the fall-back pager instead of 'less'.
 347                         This is used by things like 'git log' when the user
 348                         does not specify a pager to use through alternate
 349                         methods. eg: /usr/bin/pager)
 350 #
 351 # Allow user to set the default editor
 352 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 353                         Use VALUE as the fall-back editor instead of 'vi'.
 354                         This is used by things like 'git commit' when the user
 355                         does not specify a preferred editor through other
 356                         methods. eg: /usr/bin/editor)
 357
 358 #
 359 # Define SHELL_PATH to provide path to shell.
 360 GIT_ARG_SET_PATH(shell)
 361 #
 362 # Define PERL_PATH to provide path to Perl.
 363 GIT_ARG_SET_PATH(perl)
 364 #
 365 # Define PYTHON_PATH to provide path to Python.
 366 GIT_ARG_SET_PATH(python, allow-without)
 367 #
 368 # Define ZLIB_PATH to provide path to zlib.
 369 GIT_ARG_SET_PATH(zlib)
 370 #
 371 # Declare the with-tcltk/without-tcltk options.
 372 AC_ARG_WITH(tcltk,
 373 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 374 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 375 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 376 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 377 GIT_PARSE_WITH(tcltk))
 378 #
 379
 380
 381 ## Checks for programs.
 382 AC_MSG_NOTICE([CHECKS for programs])
 383 #
 384 AC_PROG_CC([cc gcc])
 385 AC_C_INLINE
 386 case $ac_cv_c_inline in
 387   inline | yes | no)    ;;
 388   *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 389 esac
 390
 391 # which switch to pass runtime path to dynamic libraries to the linker
 392 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 393    SAVE_LDFLAGS="${LDFLAGS}"
 394    LDFLAGS="${SAVE_LDFLAGS} -R /"
 395    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 396    LDFLAGS="${SAVE_LDFLAGS}"
 397 ])
 398 if test "$git_cv_ld_dashr" = "yes"; then
 399    AC_SUBST(CC_LD_DYNPATH, [-R])
 400 else
 401    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 402       SAVE_LDFLAGS="${LDFLAGS}"
 403       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 404       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 405       LDFLAGS="${SAVE_LDFLAGS}"
 406    ])
 407    if test "$git_cv_ld_wl_rpath" = "yes"; then
 408       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 409    else
 410       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 411          SAVE_LDFLAGS="${LDFLAGS}"
 412          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 413          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 414          LDFLAGS="${SAVE_LDFLAGS}"
 415       ])
 416       if test "$git_cv_ld_rpath" = "yes"; then
 417          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 418       else
 419          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 420       fi
 421    fi
 422 fi
 423 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 424 AC_CHECK_TOOLS(AR, [gar ar], :)
 425 AC_CHECK_PROGS(TAR, [gtar tar])
 426 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 427 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 428 # or will be empty otherwise.
 429 if test -z "$NO_TCLTK"; then
 430   if test "$with_tcltk" = ""; then
 431   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 432     TCLTK_PATH=wish
 433     AC_SUBST(TCLTK_PATH)
 434   elif test "$with_tcltk" = "yes"; then
 435   # Tcl/Tk check requested.
 436     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 437   else
 438     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 439     TCLTK_PATH="$with_tcltk"
 440     AC_SUBST(TCLTK_PATH)
 441   fi
 442 fi
 443 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 444 if test -n "$ASCIIDOC"; then
 445         AC_MSG_CHECKING([for asciidoc version])
 446         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 447         case "${asciidoc_version}" in
 448         asciidoc' '8*)
 449                 AC_MSG_RESULT([${asciidoc_version}])
 450                 ;;
 451         *)
 452                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 453                 ;;
 454         esac
 455 fi
 456
 457
 458 ## Checks for libraries.
 459 AC_MSG_NOTICE([CHECKS for libraries])
 460 #
 461 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 462 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 463
 464 GIT_STASH_FLAGS($OPENSSLDIR)
 465
 466 AC_CHECK_LIB([crypto], [SHA1_Init],
 467 [NEEDS_SSL_WITH_CRYPTO=],
 468 [AC_CHECK_LIB([ssl], [SHA1_Init],
 469  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 470  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 471
 472 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 473
 474 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 475 AC_SUBST(NO_OPENSSL)
 476
 477 #
 478 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 479 # able to use Perl-compatible regular expressions.
 480 #
 481
 482 if test -n "$USE_LIBPCRE"; then
 483
 484 GIT_STASH_FLAGS($LIBPCREDIR)
 485
 486 AC_CHECK_LIB([pcre], [pcre_version],
 487 [USE_LIBPCRE=YesPlease],
 488 [USE_LIBPCRE=])
 489
 490 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 491
 492 AC_SUBST(USE_LIBPCRE)
 493
 494 fi
 495
 496 #
 497 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 498 # git-http-push are not built, and you cannot use http:// and https://
 499 # transports.
 500
 501 GIT_STASH_FLAGS($CURLDIR)
 502
 503 AC_CHECK_LIB([curl], [curl_global_init],
 504 [NO_CURL=],
 505 [NO_CURL=YesPlease])
 506
 507 GIT_UNSTASH_FLAGS($CURLDIR)
 508
 509 AC_SUBST(NO_CURL)
 510
 511 #
 512 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 513 # not built, and you cannot push using http:// and https:// transports.
 514
 515 GIT_STASH_FLAGS($EXPATDIR)
 516
 517 AC_CHECK_LIB([expat], [XML_ParserCreate],
 518 [NO_EXPAT=],
 519 [NO_EXPAT=YesPlease])
 520
 521 GIT_UNSTASH_FLAGS($EXPATDIR)
 522
 523 AC_SUBST(NO_EXPAT)
 524
 525 #
 526 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 527 # some Solaris installations).
 528 # Define NO_ICONV if neither libc nor libiconv support iconv.
 529
 530 if test -z "$NO_ICONV"; then
 531
 532 GIT_STASH_FLAGS($ICONVDIR)
 533
 534 AC_DEFUN([ICONVTEST_SRC],
 535 [AC_LANG_PROGRAM([#include <iconv.h>],
 536  [iconv_open("", "");])])
 537
 538 if test -n "$ICONVDIR"; then
 539    lib_order="-liconv -lc"
 540 else
 541    lib_order="-lc -liconv"
 542 fi
 543
 544 NO_ICONV=YesPlease
 545
 546 for l in $lib_order; do
 547     if test "$l" = "-liconv"; then
 548        NEEDS_LIBICONV=YesPlease
 549     else
 550        NEEDS_LIBICONV=
 551     fi
 552
 553     old_LIBS="$LIBS"
 554     LIBS="$LIBS $l"
 555     AC_MSG_CHECKING([for iconv in $l])
 556     AC_LINK_IFELSE([ICONVTEST_SRC],
 557         [AC_MSG_RESULT([yes])
 558         NO_ICONV=
 559         break],
 560         [AC_MSG_RESULT([no])])
 561     LIBS="$old_LIBS"
 562 done
 563
 564 #in case of break
 565 LIBS="$old_LIBS"
 566
 567 GIT_UNSTASH_FLAGS($ICONVDIR)
 568
 569 AC_SUBST(NEEDS_LIBICONV)
 570 AC_SUBST(NO_ICONV)
 571
 572 if test -n "$NO_ICONV"; then
 573     NEEDS_LIBICONV=
 574 fi
 575
 576 fi
 577
 578 #
 579 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 580
 581 GIT_STASH_FLAGS($ZLIB_PATH)
 582
 583 AC_DEFUN([ZLIBTEST_SRC], [
 584 AC_LANG_PROGRAM([#include <zlib.h>],
 585  [deflateBound(0, 0);])])
 586 AC_MSG_CHECKING([for deflateBound in -lz])
 587 old_LIBS="$LIBS"
 588 LIBS="$LIBS -lz"
 589 AC_LINK_IFELSE([ZLIBTEST_SRC],
 590         [AC_MSG_RESULT([yes])],
 591         [AC_MSG_RESULT([no])
 592         NO_DEFLATE_BOUND=yes])
 593 LIBS="$old_LIBS"
 594
 595 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 596
 597 AC_SUBST(NO_DEFLATE_BOUND)
 598
 599 #
 600 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 601 # Patrick Mauritz).
 602 AC_CHECK_LIB([c], [socket],
 603 [NEEDS_SOCKET=],
 604 [NEEDS_SOCKET=YesPlease])
 605 AC_SUBST(NEEDS_SOCKET)
 606 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 607
 608 #
 609 # The next few tests will define NEEDS_RESOLV if linking with
 610 # libresolv provides some of the functions we would normally get
 611 # from libc.
 612 NEEDS_RESOLV=
 613 AC_SUBST(NEEDS_RESOLV)
 614 #
 615 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 616 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 617 NO_INET_NTOP=
 618 AC_SUBST(NO_INET_NTOP)
 619 AC_CHECK_FUNC([inet_ntop],
 620         [],
 621     [AC_CHECK_LIB([resolv], [inet_ntop],
 622             [NEEDS_RESOLV=YesPlease],
 623         [NO_INET_NTOP=YesPlease])
 624 ])
 625 #
 626 # Define NO_INET_PTON if linking with -lresolv is not enough.
 627 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 628 NO_INET_PTON=
 629 AC_SUBST(NO_INET_PTON)
 630 AC_CHECK_FUNC([inet_pton],
 631         [],
 632     [AC_CHECK_LIB([resolv], [inet_pton],
 633             [NEEDS_RESOLV=YesPlease],
 634         [NO_INET_PTON=YesPlease])
 635 ])
 636 #
 637 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 638 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 639 NO_HSTRERROR=
 640 AC_CHECK_FUNC([hstrerror],
 641         [],
 642     [AC_CHECK_LIB([resolv], [hstrerror],
 643             [NEEDS_RESOLV=YesPlease],
 644         [NO_HSTRERROR=YesPlease])
 645 ])
 646 AC_SUBST(NO_HSTRERROR)
 647 #
 648 # If any of the above tests determined that -lresolv is needed at
 649 # build-time, also set it here for remaining configure-time checks.
 650 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 651
 652 AC_CHECK_LIB([c], [basename],
 653 [NEEDS_LIBGEN=],
 654 [NEEDS_LIBGEN=YesPlease])
 655 AC_SUBST(NEEDS_LIBGEN)
 656 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 657
 658 AC_CHECK_LIB([c], [gettext],
 659 [LIBC_CONTAINS_LIBINTL=YesPlease],
 660 [LIBC_CONTAINS_LIBINTL=])
 661 AC_SUBST(LIBC_CONTAINS_LIBINTL)
 662
 663 #
 664 # Define NO_GETTEXT if you don't want Git output to be translated.
 665 # A translated Git requires GNU libintl or another gettext implementation
 666 AC_CHECK_HEADER([libintl.h],
 667 [NO_GETTEXT=],
 668 [NO_GETTEXT=YesPlease])
 669 AC_SUBST(NO_GETTEXT)
 670
 671 if test -z "$NO_GETTEXT"; then
 672     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 673 fi
 674
 675 ## Checks for header files.
 676 AC_MSG_NOTICE([CHECKS for header files])
 677 #
 678 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 679 AC_CHECK_HEADER([sys/select.h],
 680 [NO_SYS_SELECT_H=],
 681 [NO_SYS_SELECT_H=UnfortunatelyYes])
 682 AC_SUBST(NO_SYS_SELECT_H)
 683 #
 684 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 685 AC_CHECK_HEADER([sys/poll.h],
 686 [NO_SYS_POLL_H=],
 687 [NO_SYS_POLL_H=UnfortunatelyYes])
 688 AC_SUBST(NO_SYS_POLL_H)
 689 #
 690 # Define NO_INTTYPES_H if you don't have inttypes.h
 691 AC_CHECK_HEADER([inttypes.h],
 692 [NO_INTTYPES_H=],
 693 [NO_INTTYPES_H=UnfortunatelyYes])
 694 AC_SUBST(NO_INTTYPES_H)
 695 #
 696 # Define OLD_ICONV if your library has an old iconv(), where the second
 697 # (input buffer pointer) parameter is declared with type (const char **).
 698 AC_DEFUN([OLDICONVTEST_SRC], [
 699 AC_LANG_PROGRAM([[
 700 #include <iconv.h>
 701
 702 extern size_t iconv(iconv_t cd,
 703                     char **inbuf, size_t *inbytesleft,
 704                     char **outbuf, size_t *outbytesleft);
 705 ]], [])])
 706
 707 GIT_STASH_FLAGS($ICONVDIR)
 708
 709 AC_MSG_CHECKING([for old iconv()])
 710 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 711         [AC_MSG_RESULT([no])],
 712         [AC_MSG_RESULT([yes])
 713         OLD_ICONV=UnfortunatelyYes])
 714
 715 GIT_UNSTASH_FLAGS($ICONVDIR)
 716
 717 AC_SUBST(OLD_ICONV)
 718
 719 ## Checks for typedefs, structures, and compiler characteristics.
 720 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 721 #
 722 TYPE_SOCKLEN_T
 723 case $ac_cv_type_socklen_t in
 724   yes)  ;;
 725   *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 726 esac
 727
 728 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 729 AC_CHECK_MEMBER(struct dirent.d_ino,
 730 [NO_D_INO_IN_DIRENT=],
 731 [NO_D_INO_IN_DIRENT=YesPlease],
 732 [#include <dirent.h>])
 733 AC_SUBST(NO_D_INO_IN_DIRENT)
 734 #
 735 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 736 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 737 AC_CHECK_MEMBER(struct dirent.d_type,
 738 [NO_D_TYPE_IN_DIRENT=],
 739 [NO_D_TYPE_IN_DIRENT=YesPlease],
 740 [#include <dirent.h>])
 741 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 742 #
 743 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 744 # sockaddr_storage.
 745 AC_CHECK_TYPE(struct sockaddr_storage,
 746 [NO_SOCKADDR_STORAGE=],
 747 [NO_SOCKADDR_STORAGE=YesPlease],[
 748 #include <sys/types.h>
 749 #include <sys/socket.h>
 750 ])
 751 AC_SUBST(NO_SOCKADDR_STORAGE)
 752 #
 753 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 754 AC_CHECK_TYPE([struct addrinfo],[
 755  GIT_CHECK_FUNC([getaddrinfo],
 756   [NO_IPV6=],
 757   [NO_IPV6=YesPlease])
 758 ],[NO_IPV6=YesPlease],[
 759 #include <sys/types.h>
 760 #include <sys/socket.h>
 761 #include <netdb.h>
 762 ])
 763 AC_SUBST(NO_IPV6)
 764 #
 765 # Define NO_REGEX if you have no or inferior regex support in your C library.
 766 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 767  [ac_cv_c_excellent_regex], [
 768 AC_EGREP_CPP(yippeeyeswehaveit,
 769         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 770 #include <regex.h>
 771 ],
 772 [#ifdef REG_STARTEND
 773 yippeeyeswehaveit
 774 #endif
 775 ]),
 776         [ac_cv_c_excellent_regex=yes],
 777         [ac_cv_c_excellent_regex=no])
 778 ])
 779 if test $ac_cv_c_excellent_regex = yes; then
 780         NO_REGEX=
 781 else
 782         NO_REGEX=YesPlease
 783 fi
 784 AC_SUBST(NO_REGEX)
 785 #
 786 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 787 # when attempting to read from an fopen'ed directory.
 788 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 789  [ac_cv_fread_reads_directories],
 790 [
 791 AC_RUN_IFELSE(
 792         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 793                 [[char c;
 794                 FILE *f = fopen(".", "r");
 795                 return f && fread(&c, 1, 1, f)]])],
 796         [ac_cv_fread_reads_directories=no],
 797         [ac_cv_fread_reads_directories=yes])
 798 ])
 799 if test $ac_cv_fread_reads_directories = yes; then
 800         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 801 else
 802         FREAD_READS_DIRECTORIES=
 803 fi
 804 AC_SUBST(FREAD_READS_DIRECTORIES)
 805 #
 806 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 807 # or vsnprintf() return -1 instead of number of characters which would
 808 # have been written to the final string if enough space had been available.
 809 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 810  [ac_cv_snprintf_returns_bogus],
 811 [
 812 AC_RUN_IFELSE(
 813         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 814                 #include "stdarg.h"
 815
 816                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 817                 {
 818                   int ret;
 819                   va_list ap;
 820                   va_start(ap, format);
 821                   ret = vsnprintf(str, maxsize, format, ap);
 822                   va_end(ap);
 823                   return ret;
 824                 }],
 825                 [[char buf[6];
 826                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 827                       || strcmp(buf, "12")) return 1;
 828                   if (snprintf(buf, 3, "%s", "12345") != 5
 829                       || strcmp(buf, "12")) return 1]])],
 830         [ac_cv_snprintf_returns_bogus=no],
 831         [ac_cv_snprintf_returns_bogus=yes])
 832 ])
 833 if test $ac_cv_snprintf_returns_bogus = yes; then
 834         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 835 else
 836         SNPRINTF_RETURNS_BOGUS=
 837 fi
 838 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 839
 840
 841 ## Checks for library functions.
 842 ## (in default C library and libraries checked by AC_CHECK_LIB)
 843 AC_MSG_NOTICE([CHECKS for library functions])
 844 #
 845 # Define NO_LIBGEN_H if you don't have libgen.h.
 846 AC_CHECK_HEADER([libgen.h],
 847 [NO_LIBGEN_H=],
 848 [NO_LIBGEN_H=YesPlease])
 849 AC_SUBST(NO_LIBGEN_H)
 850 #
 851 # Define HAVE_PATHS_H if you have paths.h.
 852 AC_CHECK_HEADER([paths.h],
 853 [HAVE_PATHS_H=YesPlease],
 854 [HAVE_PATHS_H=])
 855 AC_SUBST(HAVE_PATHS_H)
 856 #
 857 # Define HAVE_LIBCHARSET_H if have libcharset.h
 858 AC_CHECK_HEADER([libcharset.h],
 859 [HAVE_LIBCHARSET_H=YesPlease],
 860 [HAVE_LIBCHARSET_H=])
 861 AC_SUBST(HAVE_LIBCHARSET_H)
 862 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
 863 # and libcharset does
 864 CHARSET_LIB=
 865 AC_CHECK_LIB([iconv], [locale_charset],
 866        [],
 867        [AC_CHECK_LIB([charset], [locale_charset],
 868                      [CHARSET_LIB=-lcharset])
 869        ]
 870 )
 871 AC_SUBST(CHARSET_LIB)
 872 #
 873 # Define NO_STRCASESTR if you don't have strcasestr.
 874 GIT_CHECK_FUNC(strcasestr,
 875 [NO_STRCASESTR=],
 876 [NO_STRCASESTR=YesPlease])
 877 AC_SUBST(NO_STRCASESTR)
 878 #
 879 # Define NO_STRTOK_R if you don't have strtok_r
 880 GIT_CHECK_FUNC(strtok_r,
 881 [NO_STRTOK_R=],
 882 [NO_STRTOK_R=YesPlease])
 883 AC_SUBST(NO_STRTOK_R)
 884 #
 885 # Define NO_FNMATCH if you don't have fnmatch
 886 GIT_CHECK_FUNC(fnmatch,
 887 [NO_FNMATCH=],
 888 [NO_FNMATCH=YesPlease])
 889 AC_SUBST(NO_FNMATCH)
 890 #
 891 # Define NO_FNMATCH_CASEFOLD if your fnmatch function doesn't have the
 892 # FNM_CASEFOLD GNU extension.
 893 AC_CACHE_CHECK([whether the fnmatch function supports the FNMATCH_CASEFOLD GNU extension],
 894  [ac_cv_c_excellent_fnmatch], [
 895 AC_EGREP_CPP(yippeeyeswehaveit,
 896         AC_LANG_PROGRAM([
 897 #include <fnmatch.h>
 898 ],
 899 [#ifdef FNM_CASEFOLD
 900 yippeeyeswehaveit
 901 #endif
 902 ]),
 903         [ac_cv_c_excellent_fnmatch=yes],
 904         [ac_cv_c_excellent_fnmatch=no])
 905 ])
 906 if test $ac_cv_c_excellent_fnmatch = yes; then
 907         NO_FNMATCH_CASEFOLD=
 908 else
 909         NO_FNMATCH_CASEFOLD=YesPlease
 910 fi
 911 AC_SUBST(NO_FNMATCH_CASEFOLD)
 912 #
 913 # Define NO_MEMMEM if you don't have memmem.
 914 GIT_CHECK_FUNC(memmem,
 915 [NO_MEMMEM=],
 916 [NO_MEMMEM=YesPlease])
 917 AC_SUBST(NO_MEMMEM)
 918 #
 919 # Define NO_STRLCPY if you don't have strlcpy.
 920 GIT_CHECK_FUNC(strlcpy,
 921 [NO_STRLCPY=],
 922 [NO_STRLCPY=YesPlease])
 923 AC_SUBST(NO_STRLCPY)
 924 #
 925 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 926 AC_CHECK_TYPE(uintmax_t,
 927 [NO_UINTMAX_T=],
 928 [NO_UINTMAX_T=YesPlease],[
 929 #include <inttypes.h>
 930 ])
 931 AC_SUBST(NO_UINTMAX_T)
 932 #
 933 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 934 GIT_CHECK_FUNC(strtoumax,
 935 [NO_STRTOUMAX=],
 936 [NO_STRTOUMAX=YesPlease])
 937 AC_SUBST(NO_STRTOUMAX)
 938 #
 939 # Define NO_SETENV if you don't have setenv in the C library.
 940 GIT_CHECK_FUNC(setenv,
 941 [NO_SETENV=],
 942 [NO_SETENV=YesPlease])
 943 AC_SUBST(NO_SETENV)
 944 #
 945 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 946 GIT_CHECK_FUNC(unsetenv,
 947 [NO_UNSETENV=],
 948 [NO_UNSETENV=YesPlease])
 949 AC_SUBST(NO_UNSETENV)
 950 #
 951 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 952 GIT_CHECK_FUNC(mkdtemp,
 953 [NO_MKDTEMP=],
 954 [NO_MKDTEMP=YesPlease])
 955 AC_SUBST(NO_MKDTEMP)
 956 #
 957 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 958 GIT_CHECK_FUNC(mkstemps,
 959 [NO_MKSTEMPS=],
 960 [NO_MKSTEMPS=YesPlease])
 961 AC_SUBST(NO_MKSTEMPS)
 962 #
 963 # Define NO_INITGROUPS if you don't have initgroups in the C library.
 964 GIT_CHECK_FUNC(initgroups,
 965 [NO_INITGROUPS=],
 966 [NO_INITGROUPS=YesPlease])
 967 AC_SUBST(NO_INITGROUPS)
 968 #
 969 #
 970 # Define NO_MMAP if you want to avoid mmap.
 971 #
 972 # Define NO_ICONV if your libc does not properly support iconv.
 973
 974
 975 ## Other checks.
 976 # Define USE_PIC if you need the main git objects to be built with -fPIC
 977 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 978 #
 979 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 980 # Enable it on Windows.  By default, symrefs are still used.
 981 #
 982 # Define NO_PTHREADS if we do not have pthreads.
 983 #
 984 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
 985 AC_DEFUN([PTHREADTEST_SRC], [
 986 AC_LANG_PROGRAM([[
 987 #include <pthread.h>
 988 ]], [[
 989         pthread_mutex_t test_mutex;
 990         pthread_key_t test_key;
 991         int retcode = 0;
 992         retcode |= pthread_key_create(&test_key, (void *)0);
 993         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 994         retcode |= pthread_mutex_lock(&test_mutex);
 995         retcode |= pthread_mutex_unlock(&test_mutex);
 996         return retcode;
 997 ]])])
 998
 999 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1000 dnl   [[#include <pthread.h>]],
1001 dnl   [[pthread_mutex_t test_mutex;]]
1002 dnl )])
1003
1004 NO_PTHREADS=UnfortunatelyYes
1005 PTHREAD_LIBS=
1006
1007 if test -n "$USER_NOPTHREAD"; then
1008    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1009 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1010 # -D_REENTRANT' or some such.
1011 elif test -z "$PTHREAD_CFLAGS"; then
1012   threads_found=no
1013   for opt in -mt -pthread -lpthread; do
1014      old_CFLAGS="$CFLAGS"
1015      CFLAGS="$opt $CFLAGS"
1016      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
1017      AC_LINK_IFELSE([PTHREADTEST_SRC],
1018         [AC_MSG_RESULT([yes])
1019                 NO_PTHREADS=
1020                 PTHREAD_LIBS="$opt"
1021                 PTHREAD_CFLAGS="$opt"
1022                 threads_found=yes
1023                 break
1024         ],
1025         [AC_MSG_RESULT([no])])
1026       CFLAGS="$old_CFLAGS"
1027   done
1028   if test $threads_found != yes; then
1029     AC_CHECK_LIB([pthread], [pthread_create],
1030         [PTHREAD_LIBS="-lpthread"],
1031         [NO_PTHREADS=UnfortunatelyYes])
1032   fi
1033 else
1034   old_CFLAGS="$CFLAGS"
1035   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1036   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
1037   AC_LINK_IFELSE([PTHREADTEST_SRC],
1038         [AC_MSG_RESULT([yes])
1039                 NO_PTHREADS=
1040                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1041         ],
1042         [AC_MSG_RESULT([no])])
1043
1044   CFLAGS="$old_CFLAGS"
1045 fi
1046
1047 CFLAGS="$old_CFLAGS"
1048
1049 AC_SUBST(PTHREAD_CFLAGS)
1050 AC_SUBST(PTHREAD_LIBS)
1051 AC_SUBST(NO_PTHREADS)
1052
1053 ## Output files
1054 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1055 AC_OUTPUT