git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {$::_trace} {
 552                 puts stderr "< $result"
 553         }
 554         return $result
 555 }
 556
 557 proc _open_stdout_stderr {cmd} {
 558         _trace_exec $cmd
 559         if {[catch {
 560                         set fd [open [concat [list | ] $cmd] r]
 561                 } err]} {
 562                 if {   [lindex $cmd end] eq {2>@1}
 563                     && $err eq {can not find channel named "1"}
 564                         } {
 565                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 566                         # redirect operator.  Fallback to |& cat for those.
 567                         # The command was not actually started, so its safe
 568                         # to try to start it a second time.
 569                         #
 570                         set fd [open [concat \
 571                                 [list | ] \
 572                                 [lrange $cmd 0 end-1] \
 573                                 [list |& cat] \
 574                                 ] r]
 575                 } else {
 576                         error $err
 577                 }
 578         }
 579         fconfigure $fd -eofchar {}
 580         return $fd
 581 }
 582
 583 proc git_read {args} {
 584         set opt [list]
 585
 586         while {1} {
 587                 switch -- [lindex $args 0] {
 588                 --nice {
 589                         _lappend_nice opt
 590                 }
 591
 592                 --stderr {
 593                         lappend args 2>@1
 594                 }
 595
 596                 default {
 597                         break
 598                 }
 599
 600                 }
 601
 602                 set args [lrange $args 1 end]
 603         }
 604
 605         set cmdp [_git_cmd [lindex $args 0]]
 606         set args [lrange $args 1 end]
 607
 608         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 609 }
 610
 611 proc git_write {args} {
 612         set opt [list]
 613
 614         while {1} {
 615                 switch -- [lindex $args 0] {
 616                 --nice {
 617                         _lappend_nice opt
 618                 }
 619
 620                 default {
 621                         break
 622                 }
 623
 624                 }
 625
 626                 set args [lrange $args 1 end]
 627         }
 628
 629         set cmdp [_git_cmd [lindex $args 0]]
 630         set args [lrange $args 1 end]
 631
 632         _trace_exec [concat $opt $cmdp $args]
 633         return [open [concat [list | ] $opt $cmdp $args] w]
 634 }
 635
 636 proc githook_read {hook_name args} {
 637         set pchook [gitdir hooks $hook_name]
 638         lappend args 2>@1
 639
 640         # On Windows [file executable] might lie so we need to ask
 641         # the shell if the hook is executable.  Yes that's annoying.
 642         #
 643         if {[is_Windows]} {
 644                 upvar #0 _sh interp
 645                 if {![info exists interp]} {
 646                         set interp [_which sh]
 647                 }
 648                 if {$interp eq {}} {
 649                         error "hook execution requires sh (not in PATH)"
 650                 }
 651
 652                 set scr {if test -x "$1";then exec "$@";fi}
 653                 set sh_c [list $interp -c $scr $interp $pchook]
 654                 return [_open_stdout_stderr [concat $sh_c $args]]
 655         }
 656
 657         if {[file executable $pchook]} {
 658                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 659         }
 660
 661         return {}
 662 }
 663
 664 proc kill_file_process {fd} {
 665         set process [pid $fd]
 666
 667         catch {
 668                 if {[is_Windows]} {
 669                         # Use a Cygwin-specific flag to allow killing
 670                         # native Windows processes
 671                         exec kill -f $process
 672                 } else {
 673                         exec kill $process
 674                 }
 675         }
 676 }
 677
 678 proc gitattr {path attr default} {
 679         if {[catch {set r [git check-attr $attr -- $path]}]} {
 680                 set r unspecified
 681         } else {
 682                 set r [join [lrange [split $r :] 2 end] :]
 683                 regsub {^ } $r {} r
 684         }
 685         if {$r eq {unspecified}} {
 686                 return $default
 687         }
 688         return $r
 689 }
 690
 691 proc sq {value} {
 692         regsub -all ' $value "'\\''" value
 693         return "'$value'"
 694 }
 695
 696 proc load_current_branch {} {
 697         global current_branch is_detached
 698
 699         set fd [open [gitdir HEAD] r]
 700         if {[gets $fd ref] < 1} {
 701                 set ref {}
 702         }
 703         close $fd
 704
 705         set pfx {ref: refs/heads/}
 706         set len [string length $pfx]
 707         if {[string equal -length $len $pfx $ref]} {
 708                 # We're on a branch.  It might not exist.  But
 709                 # HEAD looks good enough to be a branch.
 710                 #
 711                 set current_branch [string range $ref $len end]
 712                 set is_detached 0
 713         } else {
 714                 # Assume this is a detached head.
 715                 #
 716                 set current_branch HEAD
 717                 set is_detached 1
 718         }
 719 }
 720
 721 auto_load tk_optionMenu
 722 rename tk_optionMenu real__tkOptionMenu
 723 proc tk_optionMenu {w varName args} {
 724         set m [eval real__tkOptionMenu $w $varName $args]
 725         $m configure -font font_ui
 726         $w configure -font font_ui
 727         return $m
 728 }
 729
 730 proc rmsel_tag {text} {
 731         $text tag conf sel \
 732                 -background [$text cget -background] \
 733                 -foreground [$text cget -foreground] \
 734                 -borderwidth 0
 735         $text tag conf in_sel -background lightgray
 736         bind $text <Motion> break
 737         return $text
 738 }
 739
 740 wm withdraw .
 741 set root_exists 0
 742 bind . <Visibility> {
 743         bind . <Visibility> {}
 744         set root_exists 1
 745 }
 746
 747 if {[is_Windows]} {
 748         wm iconbitmap . -default $oguilib/git-gui.ico
 749         set ::tk::AlwaysShowSelection 1
 750         bind . <Control-F2> {console show}
 751
 752         # Spoof an X11 display for SSH
 753         if {![info exists env(DISPLAY)]} {
 754                 set env(DISPLAY) :9999
 755         }
 756 } else {
 757         catch {
 758                 image create photo gitlogo -width 16 -height 16
 759
 760                 gitlogo put #33CC33 -to  7  0  9  2
 761                 gitlogo put #33CC33 -to  4  2 12  4
 762                 gitlogo put #33CC33 -to  7  4  9  6
 763                 gitlogo put #CC3333 -to  4  6 12  8
 764                 gitlogo put gray26  -to  4  9  6 10
 765                 gitlogo put gray26  -to  3 10  6 12
 766                 gitlogo put gray26  -to  8  9 13 11
 767                 gitlogo put gray26  -to  8 11 10 12
 768                 gitlogo put gray26  -to 11 11 13 14
 769                 gitlogo put gray26  -to  3 12  5 14
 770                 gitlogo put gray26  -to  5 13
 771                 gitlogo put gray26  -to 10 13
 772                 gitlogo put gray26  -to  4 14 12 15
 773                 gitlogo put gray26  -to  5 15 11 16
 774                 gitlogo redither
 775
 776                 image create photo gitlogo32 -width 32 -height 32
 777                 gitlogo32 copy gitlogo -zoom 2 2
 778
 779                 wm iconphoto . -default gitlogo gitlogo32
 780         }
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## config defaults
 786
 787 set cursor_ptr arrow
 788 font create font_ui
 789 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 790         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 791         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 792 } else {
 793         font create font_diff -family Courier -size 10
 794         catch {
 795                 label .dummy
 796                 eval font configure font_ui [font actual [.dummy cget -font]]
 797                 destroy .dummy
 798         }
 799 }
 800
 801 font create font_uiitalic
 802 font create font_uibold
 803 font create font_diffbold
 804 font create font_diffitalic
 805
 806 foreach class {Button Checkbutton Entry Label
 807                 Labelframe Listbox Message
 808                 Radiobutton Spinbox Text} {
 809         option add *$class.font font_ui
 810 }
 811 if {![is_MacOSX]} {
 812         option add *Menu.font font_ui
 813         option add *Entry.borderWidth 1 startupFile
 814         option add *Entry.relief sunken startupFile
 815         option add *RadioButton.anchor w startupFile
 816 }
 817 unset class
 818
 819 if {[is_Windows] || [is_MacOSX]} {
 820         option add *Menu.tearOff 0
 821 }
 822
 823 if {[is_MacOSX]} {
 824         set M1B M1
 825         set M1T Cmd
 826 } else {
 827         set M1B Control
 828         set M1T Ctrl
 829 }
 830
 831 proc bind_button3 {w cmd} {
 832         bind $w <Any-Button-3> $cmd
 833         if {[is_MacOSX]} {
 834                 # Mac OS X sends Button-2 on right click through three-button mouse,
 835                 # or through trackpad right-clicking (two-finger touch + click).
 836                 bind $w <Any-Button-2> $cmd
 837                 bind $w <Control-Button-1> $cmd
 838         }
 839 }
 840
 841 proc apply_config {} {
 842         global repo_config font_descs
 843
 844         foreach option $font_descs {
 845                 set name [lindex $option 0]
 846                 set font [lindex $option 1]
 847                 if {[catch {
 848                         set need_weight 1
 849                         foreach {cn cv} $repo_config(gui.$name) {
 850                                 if {$cn eq {-weight}} {
 851                                         set need_weight 0
 852                                 }
 853                                 font configure $font $cn $cv
 854                         }
 855                         if {$need_weight} {
 856                                 font configure $font -weight normal
 857                         }
 858                         } err]} {
 859                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 860                 }
 861                 foreach {cn cv} [font configure $font] {
 862                         font configure ${font}bold $cn $cv
 863                         font configure ${font}italic $cn $cv
 864                 }
 865                 font configure ${font}bold -weight bold
 866                 font configure ${font}italic -slant italic
 867         }
 868
 869         global use_ttk NS
 870         set use_ttk 0
 871         set NS {}
 872         if {$repo_config(gui.usettk)} {
 873                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 874                 if {$use_ttk} {
 875                         set NS ttk
 876                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 877                         pave_toplevel .
 878                 }
 879         }
 880 }
 881
 882 set default_config(branch.autosetupmerge) true
 883 set default_config(merge.tool) {}
 884 set default_config(mergetool.keepbackup) true
 885 set default_config(merge.diffstat) true
 886 set default_config(merge.summary) false
 887 set default_config(merge.verbosity) 2
 888 set default_config(user.name) {}
 889 set default_config(user.email) {}
 890
 891 set default_config(gui.encoding) [encoding system]
 892 set default_config(gui.matchtrackingbranch) false
 893 set default_config(gui.textconv) true
 894 set default_config(gui.pruneduringfetch) false
 895 set default_config(gui.trustmtime) false
 896 set default_config(gui.fastcopyblame) false
 897 set default_config(gui.maxrecentrepo) 10
 898 set default_config(gui.copyblamethreshold) 40
 899 set default_config(gui.blamehistoryctx) 7
 900 set default_config(gui.diffcontext) 5
 901 set default_config(gui.diffopts) {}
 902 set default_config(gui.commitmsgwidth) 75
 903 set default_config(gui.newbranchtemplate) {}
 904 set default_config(gui.spellingdictionary) {}
 905 set default_config(gui.fontui) [font configure font_ui]
 906 set default_config(gui.fontdiff) [font configure font_diff]
 907 # TODO: this option should be added to the git-config documentation
 908 set default_config(gui.maxfilesdisplayed) 5000
 909 set default_config(gui.usettk) 1
 910 set default_config(gui.warndetachedcommit) 1
 911 set font_descs {
 912         {fontui   font_ui   {mc "Main Font"}}
 913         {fontdiff font_diff {mc "Diff/Console Font"}}
 914 }
 915 set default_config(gui.stageuntracked) ask
 916 set default_config(gui.displayuntracked) true
 917
 918 ######################################################################
 919 ##
 920 ## find git
 921
 922 set _git  [_which git]
 923 if {$_git eq {}} {
 924         catch {wm withdraw .}
 925         tk_messageBox \
 926                 -icon error \
 927                 -type ok \
 928                 -title [mc "git-gui: fatal error"] \
 929                 -message [mc "Cannot find git in PATH."]
 930         exit 1
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## version check
 936
 937 if {[catch {set _git_version [git --version]} err]} {
 938         catch {wm withdraw .}
 939         tk_messageBox \
 940                 -icon error \
 941                 -type ok \
 942                 -title [mc "git-gui: fatal error"] \
 943                 -message "Cannot determine Git version:
 944
 945 $err
 946
 947 [appname] requires Git 1.5.0 or later."
 948         exit 1
 949 }
 950 if {![regsub {^git version } $_git_version {} _git_version]} {
 951         catch {wm withdraw .}
 952         tk_messageBox \
 953                 -icon error \
 954                 -type ok \
 955                 -title [mc "git-gui: fatal error"] \
 956                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 957         exit 1
 958 }
 959
 960 proc get_trimmed_version {s} {
 961     set r {}
 962     foreach x [split $s -._] {
 963         if {[string is integer -strict $x]} {
 964             lappend r $x
 965         } else {
 966             break
 967         }
 968     }
 969     return [join $r .]
 970 }
 971 set _real_git_version $_git_version
 972 set _git_version [get_trimmed_version $_git_version]
 973
 974 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 975         catch {wm withdraw .}
 976         if {[tk_messageBox \
 977                 -icon warning \
 978                 -type yesno \
 979                 -default no \
 980                 -title "[appname]: warning" \
 981                  -message [mc "Git version cannot be determined.
 982
 983 %s claims it is version '%s'.
 984
 985 %s requires at least Git 1.5.0 or later.
 986
 987 Assume '%s' is version 1.5.0?
 988 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 989                 set _git_version 1.5.0
 990         } else {
 991                 exit 1
 992         }
 993 }
 994 unset _real_git_version
 995
 996 proc git-version {args} {
 997         global _git_version
 998
 999         switch [llength $args] {
1000         0 {
1001                 return $_git_version
1002         }
1003
1004         2 {
1005                 set op [lindex $args 0]
1006                 set vr [lindex $args 1]
1007                 set cm [package vcompare $_git_version $vr]
1008                 return [expr $cm $op 0]
1009         }
1010
1011         4 {
1012                 set type [lindex $args 0]
1013                 set name [lindex $args 1]
1014                 set parm [lindex $args 2]
1015                 set body [lindex $args 3]
1016
1017                 if {($type ne {proc} && $type ne {method})} {
1018                         error "Invalid arguments to git-version"
1019                 }
1020                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1021                         error "Last arm of $type $name must be default"
1022                 }
1023
1024                 foreach {op vr cb} [lrange $body 0 end-2] {
1025                         if {[git-version $op $vr]} {
1026                                 return [uplevel [list $type $name $parm $cb]]
1027                         }
1028                 }
1029
1030                 return [uplevel [list $type $name $parm [lindex $body end]]]
1031         }
1032
1033         default {
1034                 error "git-version >= x"
1035         }
1036
1037         }
1038 }
1039
1040 if {[git-version < 1.5]} {
1041         catch {wm withdraw .}
1042         tk_messageBox \
1043                 -icon error \
1044                 -type ok \
1045                 -title [mc "git-gui: fatal error"] \
1046                 -message "[appname] requires Git 1.5.0 or later.
1047
1048 You are using [git-version]:
1049
1050 [git --version]"
1051         exit 1
1052 }
1053
1054 ######################################################################
1055 ##
1056 ## configure our library
1057
1058 set idx [file join $oguilib tclIndex]
1059 if {[catch {set fd [open $idx r]} err]} {
1060         catch {wm withdraw .}
1061         tk_messageBox \
1062                 -icon error \
1063                 -type ok \
1064                 -title [mc "git-gui: fatal error"] \
1065                 -message $err
1066         exit 1
1067 }
1068 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1069         set idx [list]
1070         while {[gets $fd n] >= 0} {
1071                 if {$n ne {} && ![string match #* $n]} {
1072                         lappend idx $n
1073                 }
1074         }
1075 } else {
1076         set idx {}
1077 }
1078 close $fd
1079
1080 if {$idx ne {}} {
1081         set loaded [list]
1082         foreach p $idx {
1083                 if {[lsearch -exact $loaded $p] >= 0} continue
1084                 source [file join $oguilib $p]
1085                 lappend loaded $p
1086         }
1087         unset loaded p
1088 } else {
1089         set auto_path [concat [list $oguilib] $auto_path]
1090 }
1091 unset -nocomplain idx fd
1092
1093 ######################################################################
1094 ##
1095 ## config file parsing
1096
1097 git-version proc _parse_config {arr_name args} {
1098         >= 1.5.3 {
1099                 upvar $arr_name arr
1100                 array unset arr
1101                 set buf {}
1102                 catch {
1103                         set fd_rc [eval \
1104                                 [list git_read config] \
1105                                 $args \
1106                                 [list --null --list]]
1107                         fconfigure $fd_rc -translation binary
1108                         set buf [read $fd_rc]
1109                         close $fd_rc
1110                 }
1111                 foreach line [split $buf "\0"] {
1112                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1113                                 if {[is_many_config $name]} {
1114                                         lappend arr($name) $value
1115                                 } else {
1116                                         set arr($name) $value
1117                                 }
1118                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1119                                 # no value given, but interpreting them as
1120                                 # boolean will be handled as true
1121                                 set arr($name) {}
1122                         }
1123                 }
1124         }
1125         default {
1126                 upvar $arr_name arr
1127                 array unset arr
1128                 catch {
1129                         set fd_rc [eval [list git_read config --list] $args]
1130                         while {[gets $fd_rc line] >= 0} {
1131                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1132                                         if {[is_many_config $name]} {
1133                                                 lappend arr($name) $value
1134                                         } else {
1135                                                 set arr($name) $value
1136                                         }
1137                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1138                                         # no value given, but interpreting them as
1139                                         # boolean will be handled as true
1140                                         set arr($name) {}
1141                                 }
1142                         }
1143                         close $fd_rc
1144                 }
1145         }
1146 }
1147
1148 proc load_config {include_global} {
1149         global repo_config global_config system_config default_config
1150
1151         if {$include_global} {
1152                 _parse_config system_config --system
1153                 _parse_config global_config --global
1154         }
1155         _parse_config repo_config
1156
1157         foreach name [array names default_config] {
1158                 if {[catch {set v $system_config($name)}]} {
1159                         set system_config($name) $default_config($name)
1160                 }
1161         }
1162         foreach name [array names system_config] {
1163                 if {[catch {set v $global_config($name)}]} {
1164                         set global_config($name) $system_config($name)
1165                 }
1166                 if {[catch {set v $repo_config($name)}]} {
1167                         set repo_config($name) $system_config($name)
1168                 }
1169         }
1170 }
1171
1172 ######################################################################
1173 ##
1174 ## feature option selection
1175
1176 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1177         unset _junk
1178 } else {
1179         set subcommand gui
1180 }
1181 if {$subcommand eq {gui.sh}} {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui} && [llength $argv] > 0} {
1185         set subcommand [lindex $argv 0]
1186         set argv [lrange $argv 1 end]
1187 }
1188
1189 enable_option multicommit
1190 enable_option branch
1191 enable_option transport
1192 disable_option bare
1193
1194 switch -- $subcommand {
1195 browser -
1196 blame {
1197         enable_option bare
1198
1199         disable_option multicommit
1200         disable_option branch
1201         disable_option transport
1202 }
1203 citool {
1204         enable_option singlecommit
1205         enable_option retcode
1206
1207         disable_option multicommit
1208         disable_option branch
1209         disable_option transport
1210
1211         while {[llength $argv] > 0} {
1212                 set a [lindex $argv 0]
1213                 switch -- $a {
1214                 --amend {
1215                         enable_option initialamend
1216                 }
1217                 --nocommit {
1218                         enable_option nocommit
1219                         enable_option nocommitmsg
1220                 }
1221                 --commitmsg {
1222                         disable_option nocommitmsg
1223                 }
1224                 default {
1225                         break
1226                 }
1227                 }
1228
1229                 set argv [lrange $argv 1 end]
1230         }
1231 }
1232 }
1233
1234 ######################################################################
1235 ##
1236 ## execution environment
1237
1238 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1239
1240 # Suggest our implementation of askpass, if none is set
1241 if {![info exists env(SSH_ASKPASS)]} {
1242         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1243 }
1244
1245 ######################################################################
1246 ##
1247 ## repository setup
1248
1249 set picked 0
1250 if {[catch {
1251                 set _gitdir $env(GIT_DIR)
1252                 set _prefix {}
1253                 }]
1254         && [catch {
1255                 # beware that from the .git dir this sets _gitdir to .
1256                 # and _prefix to the empty string
1257                 set _gitdir [git rev-parse --git-dir]
1258                 set _prefix [git rev-parse --show-prefix]
1259         } err]} {
1260         load_config 1
1261         apply_config
1262         choose_repository::pick
1263         set picked 1
1264 }
1265
1266 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1267 # run from the .git dir itself) lest the routines to find the worktree
1268 # get confused
1269 if {$_gitdir eq "."} {
1270         set _gitdir [pwd]
1271 }
1272
1273 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1274         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1275 }
1276 if {![file isdirectory $_gitdir]} {
1277         catch {wm withdraw .}
1278         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1279         exit 1
1280 }
1281 # _gitdir exists, so try loading the config
1282 load_config 0
1283 apply_config
1284
1285 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1286 if {[package vsatisfies $_git_version 1.7.0]} {
1287         if { [is_Cygwin] } {
1288                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1289         } else {
1290                 set _gitworktree [git rev-parse --show-toplevel]
1291         }
1292 } else {
1293         # try to set work tree from environment, core.worktree or use
1294         # cdup to obtain a relative path to the top of the worktree. If
1295         # run from the top, the ./ prefix ensures normalize expands pwd.
1296         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1297                 set _gitworktree [get_config core.worktree]
1298                 if {$_gitworktree eq ""} {
1299                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1300                 }
1301         }
1302 }
1303
1304 if {$_prefix ne {}} {
1305         if {$_gitworktree eq {}} {
1306                 regsub -all {[^/]+/} $_prefix ../ cdup
1307         } else {
1308                 set cdup $_gitworktree
1309         }
1310         if {[catch {cd $cdup} err]} {
1311                 catch {wm withdraw .}
1312                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1313                 exit 1
1314         }
1315         set _gitworktree [pwd]
1316         unset cdup
1317 } elseif {![is_enabled bare]} {
1318         if {[is_bare]} {
1319                 catch {wm withdraw .}
1320                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1321                 exit 1
1322         }
1323         if {$_gitworktree eq {}} {
1324                 set _gitworktree [file dirname $_gitdir]
1325         }
1326         if {[catch {cd $_gitworktree} err]} {
1327                 catch {wm withdraw .}
1328                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1329                 exit 1
1330         }
1331         set _gitworktree [pwd]
1332 }
1333 set _reponame [file split [file normalize $_gitdir]]
1334 if {[lindex $_reponame end] eq {.git}} {
1335         set _reponame [lindex $_reponame end-1]
1336 } else {
1337         set _reponame [lindex $_reponame end]
1338 }
1339
1340 set env(GIT_DIR) $_gitdir
1341 set env(GIT_WORK_TREE) $_gitworktree
1342
1343 ######################################################################
1344 ##
1345 ## global init
1346
1347 set current_diff_path {}
1348 set current_diff_side {}
1349 set diff_actions [list]
1350
1351 set HEAD {}
1352 set PARENT {}
1353 set MERGE_HEAD [list]
1354 set commit_type {}
1355 set empty_tree {}
1356 set current_branch {}
1357 set is_detached 0
1358 set current_diff_path {}
1359 set is_3way_diff 0
1360 set is_submodule_diff 0
1361 set is_conflict_diff 0
1362 set selected_commit_type new
1363 set diff_empty_count 0
1364
1365 set nullid "0000000000000000000000000000000000000000"
1366 set nullid2 "0000000000000000000000000000000000000001"
1367
1368 ######################################################################
1369 ##
1370 ## task management
1371
1372 set rescan_active 0
1373 set diff_active 0
1374 set last_clicked {}
1375
1376 set disable_on_lock [list]
1377 set index_lock_type none
1378
1379 proc lock_index {type} {
1380         global index_lock_type disable_on_lock
1381
1382         if {$index_lock_type eq {none}} {
1383                 set index_lock_type $type
1384                 foreach w $disable_on_lock {
1385                         uplevel #0 $w disabled
1386                 }
1387                 return 1
1388         } elseif {$index_lock_type eq "begin-$type"} {
1389                 set index_lock_type $type
1390                 return 1
1391         }
1392         return 0
1393 }
1394
1395 proc unlock_index {} {
1396         global index_lock_type disable_on_lock
1397
1398         set index_lock_type none
1399         foreach w $disable_on_lock {
1400                 uplevel #0 $w normal
1401         }
1402 }
1403
1404 ######################################################################
1405 ##
1406 ## status
1407
1408 proc repository_state {ctvar hdvar mhvar} {
1409         global current_branch
1410         upvar $ctvar ct $hdvar hd $mhvar mh
1411
1412         set mh [list]
1413
1414         load_current_branch
1415         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1416                 set hd {}
1417                 set ct initial
1418                 return
1419         }
1420
1421         set merge_head [gitdir MERGE_HEAD]
1422         if {[file exists $merge_head]} {
1423                 set ct merge
1424                 set fd_mh [open $merge_head r]
1425                 while {[gets $fd_mh line] >= 0} {
1426                         lappend mh $line
1427                 }
1428                 close $fd_mh
1429                 return
1430         }
1431
1432         set ct normal
1433 }
1434
1435 proc PARENT {} {
1436         global PARENT empty_tree
1437
1438         set p [lindex $PARENT 0]
1439         if {$p ne {}} {
1440                 return $p
1441         }
1442         if {$empty_tree eq {}} {
1443                 set empty_tree [git mktree << {}]
1444         }
1445         return $empty_tree
1446 }
1447
1448 proc force_amend {} {
1449         global selected_commit_type
1450         global HEAD PARENT MERGE_HEAD commit_type
1451
1452         repository_state newType newHEAD newMERGE_HEAD
1453         set HEAD $newHEAD
1454         set PARENT $newHEAD
1455         set MERGE_HEAD $newMERGE_HEAD
1456         set commit_type $newType
1457
1458         set selected_commit_type amend
1459         do_select_commit_type
1460 }
1461
1462 proc rescan {after {honor_trustmtime 1}} {
1463         global HEAD PARENT MERGE_HEAD commit_type
1464         global ui_index ui_workdir ui_comm
1465         global rescan_active file_states
1466         global repo_config
1467
1468         if {$rescan_active > 0 || ![lock_index read]} return
1469
1470         repository_state newType newHEAD newMERGE_HEAD
1471         if {[string match amend* $commit_type]
1472                 && $newType eq {normal}
1473                 && $newHEAD eq $HEAD} {
1474         } else {
1475                 set HEAD $newHEAD
1476                 set PARENT $newHEAD
1477                 set MERGE_HEAD $newMERGE_HEAD
1478                 set commit_type $newType
1479         }
1480
1481         array unset file_states
1482
1483         if {!$::GITGUI_BCK_exists &&
1484                 (![$ui_comm edit modified]
1485                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1486                 if {[string match amend* $commit_type]} {
1487                 } elseif {[load_message GITGUI_MSG utf-8]} {
1488                 } elseif {[run_prepare_commit_msg_hook]} {
1489                 } elseif {[load_message MERGE_MSG]} {
1490                 } elseif {[load_message SQUASH_MSG]} {
1491                 }
1492                 $ui_comm edit reset
1493                 $ui_comm edit modified false
1494         }
1495
1496         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1497                 rescan_stage2 {} $after
1498         } else {
1499                 set rescan_active 1
1500                 ui_status [mc "Refreshing file status..."]
1501                 set fd_rf [git_read update-index \
1502                         -q \
1503                         --unmerged \
1504                         --ignore-missing \
1505                         --refresh \
1506                         ]
1507                 fconfigure $fd_rf -blocking 0 -translation binary
1508                 fileevent $fd_rf readable \
1509                         [list rescan_stage2 $fd_rf $after]
1510         }
1511 }
1512
1513 if {[is_Cygwin]} {
1514         set is_git_info_exclude {}
1515         proc have_info_exclude {} {
1516                 global is_git_info_exclude
1517
1518                 if {$is_git_info_exclude eq {}} {
1519                         if {[catch {exec test -f [gitdir info exclude]}]} {
1520                                 set is_git_info_exclude 0
1521                         } else {
1522                                 set is_git_info_exclude 1
1523                         }
1524                 }
1525                 return $is_git_info_exclude
1526         }
1527 } else {
1528         proc have_info_exclude {} {
1529                 return [file readable [gitdir info exclude]]
1530         }
1531 }
1532
1533 proc rescan_stage2 {fd after} {
1534         global rescan_active buf_rdi buf_rdf buf_rlo
1535
1536         if {$fd ne {}} {
1537                 read $fd
1538                 if {![eof $fd]} return
1539                 close $fd
1540         }
1541
1542         if {[package vsatisfies $::_git_version 1.6.3]} {
1543                 set ls_others [list --exclude-standard]
1544         } else {
1545                 set ls_others [list --exclude-per-directory=.gitignore]
1546                 if {[have_info_exclude]} {
1547                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1548                 }
1549                 set user_exclude [get_config core.excludesfile]
1550                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1551                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1552                 }
1553         }
1554
1555         set buf_rdi {}
1556         set buf_rdf {}
1557         set buf_rlo {}
1558
1559         set rescan_active 2
1560         ui_status [mc "Scanning for modified files ..."]
1561         set fd_di [git_read diff-index --cached -z [PARENT]]
1562         set fd_df [git_read diff-files -z]
1563
1564         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1565         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1566
1567         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1568         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1569
1570         if {[is_config_true gui.displayuntracked]} {
1571                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1572                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1573                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1574                 incr rescan_active
1575         }
1576 }
1577
1578 proc load_message {file {encoding {}}} {
1579         global ui_comm
1580
1581         set f [gitdir $file]
1582         if {[file isfile $f]} {
1583                 if {[catch {set fd [open $f r]}]} {
1584                         return 0
1585                 }
1586                 fconfigure $fd -eofchar {}
1587                 if {$encoding ne {}} {
1588                         fconfigure $fd -encoding $encoding
1589                 }
1590                 set content [string trim [read $fd]]
1591                 close $fd
1592                 regsub -all -line {[ \r\t]+$} $content {} content
1593                 $ui_comm delete 0.0 end
1594                 $ui_comm insert end $content
1595                 return 1
1596         }
1597         return 0
1598 }
1599
1600 proc run_prepare_commit_msg_hook {} {
1601         global pch_error
1602
1603         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1604         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1605         # empty file but existent file.
1606
1607         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1608
1609         if {[file isfile [gitdir MERGE_MSG]]} {
1610                 set pcm_source "merge"
1611                 set fd_mm [open [gitdir MERGE_MSG] r]
1612                 puts -nonewline $fd_pcm [read $fd_mm]
1613                 close $fd_mm
1614         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1615                 set pcm_source "squash"
1616                 set fd_sm [open [gitdir SQUASH_MSG] r]
1617                 puts -nonewline $fd_pcm [read $fd_sm]
1618                 close $fd_sm
1619         } else {
1620                 set pcm_source ""
1621         }
1622
1623         close $fd_pcm
1624
1625         set fd_ph [githook_read prepare-commit-msg \
1626                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1627         if {$fd_ph eq {}} {
1628                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1629                 return 0;
1630         }
1631
1632         ui_status [mc "Calling prepare-commit-msg hook..."]
1633         set pch_error {}
1634
1635         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1636         fileevent $fd_ph readable \
1637                 [list prepare_commit_msg_hook_wait $fd_ph]
1638
1639         return 1;
1640 }
1641
1642 proc prepare_commit_msg_hook_wait {fd_ph} {
1643         global pch_error
1644
1645         append pch_error [read $fd_ph]
1646         fconfigure $fd_ph -blocking 1
1647         if {[eof $fd_ph]} {
1648                 if {[catch {close $fd_ph}]} {
1649                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1650                         hook_failed_popup prepare-commit-msg $pch_error
1651                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1652                         exit 1
1653                 } else {
1654                         load_message PREPARE_COMMIT_MSG
1655                 }
1656                 set pch_error {}
1657                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1658                 return
1659         }
1660         fconfigure $fd_ph -blocking 0
1661         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1662 }
1663
1664 proc read_diff_index {fd after} {
1665         global buf_rdi
1666
1667         append buf_rdi [read $fd]
1668         set c 0
1669         set n [string length $buf_rdi]
1670         while {$c < $n} {
1671                 set z1 [string first "\0" $buf_rdi $c]
1672                 if {$z1 == -1} break
1673                 incr z1
1674                 set z2 [string first "\0" $buf_rdi $z1]
1675                 if {$z2 == -1} break
1676
1677                 incr c
1678                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1679                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1680                 merge_state \
1681                         [encoding convertfrom $p] \
1682                         [lindex $i 4]? \
1683                         [list [lindex $i 0] [lindex $i 2]] \
1684                         [list]
1685                 set c $z2
1686                 incr c
1687         }
1688         if {$c < $n} {
1689                 set buf_rdi [string range $buf_rdi $c end]
1690         } else {
1691                 set buf_rdi {}
1692         }
1693
1694         rescan_done $fd buf_rdi $after
1695 }
1696
1697 proc read_diff_files {fd after} {
1698         global buf_rdf
1699
1700         append buf_rdf [read $fd]
1701         set c 0
1702         set n [string length $buf_rdf]
1703         while {$c < $n} {
1704                 set z1 [string first "\0" $buf_rdf $c]
1705                 if {$z1 == -1} break
1706                 incr z1
1707                 set z2 [string first "\0" $buf_rdf $z1]
1708                 if {$z2 == -1} break
1709
1710                 incr c
1711                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1712                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1713                 merge_state \
1714                         [encoding convertfrom $p] \
1715                         ?[lindex $i 4] \
1716                         [list] \
1717                         [list [lindex $i 0] [lindex $i 2]]
1718                 set c $z2
1719                 incr c
1720         }
1721         if {$c < $n} {
1722                 set buf_rdf [string range $buf_rdf $c end]
1723         } else {
1724                 set buf_rdf {}
1725         }
1726
1727         rescan_done $fd buf_rdf $after
1728 }
1729
1730 proc read_ls_others {fd after} {
1731         global buf_rlo
1732
1733         append buf_rlo [read $fd]
1734         set pck [split $buf_rlo "\0"]
1735         set buf_rlo [lindex $pck end]
1736         foreach p [lrange $pck 0 end-1] {
1737                 set p [encoding convertfrom $p]
1738                 if {[string index $p end] eq {/}} {
1739                         set p [string range $p 0 end-1]
1740                 }
1741                 merge_state $p ?O
1742         }
1743         rescan_done $fd buf_rlo $after
1744 }
1745
1746 proc rescan_done {fd buf after} {
1747         global rescan_active current_diff_path
1748         global file_states repo_config
1749         upvar $buf to_clear
1750
1751         if {![eof $fd]} return
1752         set to_clear {}
1753         close $fd
1754         if {[incr rescan_active -1] > 0} return
1755
1756         prune_selection
1757         unlock_index
1758         display_all_files
1759         if {$current_diff_path ne {}} { reshow_diff $after }
1760         if {$current_diff_path eq {}} { select_first_diff $after }
1761 }
1762
1763 proc prune_selection {} {
1764         global file_states selected_paths
1765
1766         foreach path [array names selected_paths] {
1767                 if {[catch {set still_here $file_states($path)}]} {
1768                         unset selected_paths($path)
1769                 }
1770         }
1771 }
1772
1773 ######################################################################
1774 ##
1775 ## ui helpers
1776
1777 proc mapicon {w state path} {
1778         global all_icons
1779
1780         if {[catch {set r $all_icons($state$w)}]} {
1781                 puts "error: no icon for $w state={$state} $path"
1782                 return file_plain
1783         }
1784         return $r
1785 }
1786
1787 proc mapdesc {state path} {
1788         global all_descs
1789
1790         if {[catch {set r $all_descs($state)}]} {
1791                 puts "error: no desc for state={$state} $path"
1792                 return $state
1793         }
1794         return $r
1795 }
1796
1797 proc ui_status {msg} {
1798         global main_status
1799         if {[info exists main_status]} {
1800                 $main_status show $msg
1801         }
1802 }
1803
1804 proc ui_ready {{test {}}} {
1805         global main_status
1806         if {[info exists main_status]} {
1807                 $main_status show [mc "Ready."] $test
1808         }
1809 }
1810
1811 proc escape_path {path} {
1812         regsub -all {\\} $path "\\\\" path
1813         regsub -all "\n" $path "\\n" path
1814         return $path
1815 }
1816
1817 proc short_path {path} {
1818         return [escape_path [lindex [file split $path] end]]
1819 }
1820
1821 set next_icon_id 0
1822 set null_sha1 [string repeat 0 40]
1823
1824 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1825         global file_states next_icon_id null_sha1
1826
1827         set s0 [string index $new_state 0]
1828         set s1 [string index $new_state 1]
1829
1830         if {[catch {set info $file_states($path)}]} {
1831                 set state __
1832                 set icon n[incr next_icon_id]
1833         } else {
1834                 set state [lindex $info 0]
1835                 set icon [lindex $info 1]
1836                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1837                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1838         }
1839
1840         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1841         elseif {$s0 eq {_}} {set s0 _}
1842
1843         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1844         elseif {$s1 eq {_}} {set s1 _}
1845
1846         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1847                 set head_info [list 0 $null_sha1]
1848         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1849                 && $head_info eq {}} {
1850                 set head_info $index_info
1851         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1852                 set index_info $head_info
1853                 set head_info {}
1854         }
1855
1856         set file_states($path) [list $s0$s1 $icon \
1857                 $head_info $index_info \
1858                 ]
1859         return $state
1860 }
1861
1862 proc display_file_helper {w path icon_name old_m new_m} {
1863         global file_lists
1864
1865         if {$new_m eq {_}} {
1866                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1867                 if {$lno >= 0} {
1868                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1869                         incr lno
1870                         $w conf -state normal
1871                         $w delete $lno.0 [expr {$lno + 1}].0
1872                         $w conf -state disabled
1873                 }
1874         } elseif {$old_m eq {_} && $new_m ne {_}} {
1875                 lappend file_lists($w) $path
1876                 set file_lists($w) [lsort -unique $file_lists($w)]
1877                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1878                 incr lno
1879                 $w conf -state normal
1880                 $w image create $lno.0 \
1881                         -align center -padx 5 -pady 1 \
1882                         -name $icon_name \
1883                         -image [mapicon $w $new_m $path]
1884                 $w insert $lno.1 "[escape_path $path]\n"
1885                 $w conf -state disabled
1886         } elseif {$old_m ne $new_m} {
1887                 $w conf -state normal
1888                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1889                 $w conf -state disabled
1890         }
1891 }
1892
1893 proc display_file {path state} {
1894         global file_states selected_paths
1895         global ui_index ui_workdir
1896
1897         set old_m [merge_state $path $state]
1898         set s $file_states($path)
1899         set new_m [lindex $s 0]
1900         set icon_name [lindex $s 1]
1901
1902         set o [string index $old_m 0]
1903         set n [string index $new_m 0]
1904         if {$o eq {U}} {
1905                 set o _
1906         }
1907         if {$n eq {U}} {
1908                 set n _
1909         }
1910         display_file_helper     $ui_index $path $icon_name $o $n
1911
1912         if {[string index $old_m 0] eq {U}} {
1913                 set o U
1914         } else {
1915                 set o [string index $old_m 1]
1916         }
1917         if {[string index $new_m 0] eq {U}} {
1918                 set n U
1919         } else {
1920                 set n [string index $new_m 1]
1921         }
1922         display_file_helper     $ui_workdir $path $icon_name $o $n
1923
1924         if {$new_m eq {__}} {
1925                 unset file_states($path)
1926                 catch {unset selected_paths($path)}
1927         }
1928 }
1929
1930 proc display_all_files_helper {w path icon_name m} {
1931         global file_lists
1932
1933         lappend file_lists($w) $path
1934         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1935         $w image create end \
1936                 -align center -padx 5 -pady 1 \
1937                 -name $icon_name \
1938                 -image [mapicon $w $m $path]
1939         $w insert end "[escape_path $path]\n"
1940 }
1941
1942 set files_warning 0
1943 proc display_all_files {} {
1944         global ui_index ui_workdir
1945         global file_states file_lists
1946         global last_clicked
1947         global files_warning
1948
1949         $ui_index conf -state normal
1950         $ui_workdir conf -state normal
1951
1952         $ui_index delete 0.0 end
1953         $ui_workdir delete 0.0 end
1954         set last_clicked {}
1955
1956         set file_lists($ui_index) [list]
1957         set file_lists($ui_workdir) [list]
1958
1959         set to_display [lsort [array names file_states]]
1960         set display_limit [get_config gui.maxfilesdisplayed]
1961         if {[llength $to_display] > $display_limit} {
1962                 if {!$files_warning} {
1963                         # do not repeatedly warn:
1964                         set files_warning 1
1965                         info_popup [mc "Displaying only %s of %s files." \
1966                                 $display_limit [llength $to_display]]
1967                 }
1968                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1969         }
1970         foreach path $to_display {
1971                 set s $file_states($path)
1972                 set m [lindex $s 0]
1973                 set icon_name [lindex $s 1]
1974
1975                 set s [string index $m 0]
1976                 if {$s ne {U} && $s ne {_}} {
1977                         display_all_files_helper $ui_index $path \
1978                                 $icon_name $s
1979                 }
1980
1981                 if {[string index $m 0] eq {U}} {
1982                         set s U
1983                 } else {
1984                         set s [string index $m 1]
1985                 }
1986                 if {$s ne {_}} {
1987                         display_all_files_helper $ui_workdir $path \
1988                                 $icon_name $s
1989                 }
1990         }
1991
1992         $ui_index conf -state disabled
1993         $ui_workdir conf -state disabled
1994 }
1995
1996 ######################################################################
1997 ##
1998 ## icons
1999
2000 set filemask {
2001 #define mask_width 14
2002 #define mask_height 15
2003 static unsigned char mask_bits[] = {
2004    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2005    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2006    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2007 }
2008
2009 image create bitmap file_plain -background white -foreground black -data {
2010 #define plain_width 14
2011 #define plain_height 15
2012 static unsigned char plain_bits[] = {
2013    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2014    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2015    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2016 } -maskdata $filemask
2017
2018 image create bitmap file_mod -background white -foreground blue -data {
2019 #define mod_width 14
2020 #define mod_height 15
2021 static unsigned char mod_bits[] = {
2022    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2023    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2024    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2025 } -maskdata $filemask
2026
2027 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2028 #define file_fulltick_width 14
2029 #define file_fulltick_height 15
2030 static unsigned char file_fulltick_bits[] = {
2031    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2032    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2033    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2034 } -maskdata $filemask
2035
2036 image create bitmap file_question -background white -foreground black -data {
2037 #define file_question_width 14
2038 #define file_question_height 15
2039 static unsigned char file_question_bits[] = {
2040    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2041    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2042    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2043 } -maskdata $filemask
2044
2045 image create bitmap file_removed -background white -foreground red -data {
2046 #define file_removed_width 14
2047 #define file_removed_height 15
2048 static unsigned char file_removed_bits[] = {
2049    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2050    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2051    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2052 } -maskdata $filemask
2053
2054 image create bitmap file_merge -background white -foreground blue -data {
2055 #define file_merge_width 14
2056 #define file_merge_height 15
2057 static unsigned char file_merge_bits[] = {
2058    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2059    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2060    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2061 } -maskdata $filemask
2062
2063 image create bitmap file_statechange -background white -foreground green -data {
2064 #define file_statechange_width 14
2065 #define file_statechange_height 15
2066 static unsigned char file_statechange_bits[] = {
2067    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2068    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2069    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2070 } -maskdata $filemask
2071
2072 set ui_index .vpane.files.index.list
2073 set ui_workdir .vpane.files.workdir.list
2074
2075 set all_icons(_$ui_index)   file_plain
2076 set all_icons(A$ui_index)   file_plain
2077 set all_icons(M$ui_index)   file_fulltick
2078 set all_icons(D$ui_index)   file_removed
2079 set all_icons(U$ui_index)   file_merge
2080 set all_icons(T$ui_index)   file_statechange
2081
2082 set all_icons(_$ui_workdir) file_plain
2083 set all_icons(M$ui_workdir) file_mod
2084 set all_icons(D$ui_workdir) file_question
2085 set all_icons(U$ui_workdir) file_merge
2086 set all_icons(O$ui_workdir) file_plain
2087 set all_icons(T$ui_workdir) file_statechange
2088
2089 set max_status_desc 0
2090 foreach i {
2091                 {__ {mc "Unmodified"}}
2092
2093                 {_M {mc "Modified, not staged"}}
2094                 {M_ {mc "Staged for commit"}}
2095                 {MM {mc "Portions staged for commit"}}
2096                 {MD {mc "Staged for commit, missing"}}
2097
2098                 {_T {mc "File type changed, not staged"}}
2099                 {MT {mc "File type changed, old type staged for commit"}}
2100                 {AT {mc "File type changed, old type staged for commit"}}
2101                 {T_ {mc "File type changed, staged"}}
2102                 {TM {mc "File type change staged, modification not staged"}}
2103                 {TD {mc "File type change staged, file missing"}}
2104
2105                 {_O {mc "Untracked, not staged"}}
2106                 {A_ {mc "Staged for commit"}}
2107                 {AM {mc "Portions staged for commit"}}
2108                 {AD {mc "Staged for commit, missing"}}
2109
2110                 {_D {mc "Missing"}}
2111                 {D_ {mc "Staged for removal"}}
2112                 {DO {mc "Staged for removal, still present"}}
2113
2114                 {_U {mc "Requires merge resolution"}}
2115                 {U_ {mc "Requires merge resolution"}}
2116                 {UU {mc "Requires merge resolution"}}
2117                 {UM {mc "Requires merge resolution"}}
2118                 {UD {mc "Requires merge resolution"}}
2119                 {UT {mc "Requires merge resolution"}}
2120         } {
2121         set text [eval [lindex $i 1]]
2122         if {$max_status_desc < [string length $text]} {
2123                 set max_status_desc [string length $text]
2124         }
2125         set all_descs([lindex $i 0]) $text
2126 }
2127 unset i
2128
2129 ######################################################################
2130 ##
2131 ## util
2132
2133 proc scrollbar2many {list mode args} {
2134         foreach w $list {eval $w $mode $args}
2135 }
2136
2137 proc many2scrollbar {list mode sb top bottom} {
2138         $sb set $top $bottom
2139         foreach w $list {$w $mode moveto $top}
2140 }
2141
2142 proc incr_font_size {font {amt 1}} {
2143         set sz [font configure $font -size]
2144         incr sz $amt
2145         font configure $font -size $sz
2146         font configure ${font}bold -size $sz
2147         font configure ${font}italic -size $sz
2148 }
2149
2150 ######################################################################
2151 ##
2152 ## ui commands
2153
2154 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2155
2156 proc do_gitk {revs {is_submodule false}} {
2157         global current_diff_path file_states current_diff_side ui_index
2158         global _gitdir _gitworktree
2159
2160         # -- Always start gitk through whatever we were loaded with.  This
2161         #    lets us bypass using shell process on Windows systems.
2162         #
2163         set exe [_which gitk -script]
2164         set cmd [list [info nameofexecutable] $exe]
2165         if {$exe eq {}} {
2166                 error_popup [mc "Couldn't find gitk in PATH"]
2167         } else {
2168                 global env
2169
2170                 set pwd [pwd]
2171
2172                 if {!$is_submodule} {
2173                         if {![is_bare]} {
2174                                 cd $_gitworktree
2175                         }
2176                 } else {
2177                         cd $current_diff_path
2178                         if {$revs eq {--}} {
2179                                 set s $file_states($current_diff_path)
2180                                 set old_sha1 {}
2181                                 set new_sha1 {}
2182                                 switch -glob -- [lindex $s 0] {
2183                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2184                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2185                                 MM {
2186                                         if {$current_diff_side eq $ui_index} {
2187                                                 set old_sha1 [lindex [lindex $s 2] 1]
2188                                                 set new_sha1 [lindex [lindex $s 3] 1]
2189                                         } else {
2190                                                 set old_sha1 [lindex [lindex $s 3] 1]
2191                                         }
2192                                 }
2193                                 }
2194                                 set revs $old_sha1...$new_sha1
2195                         }
2196                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2197                         # we've been using for the main repository, so unset them.
2198                         # TODO we could make life easier (start up faster?) for gitk
2199                         # by setting these to the appropriate values to allow gitk
2200                         # to skip the heuristics to find their proper value
2201                         unset env(GIT_DIR)
2202                         unset env(GIT_WORK_TREE)
2203                 }
2204                 eval exec $cmd $revs "--" "--" &
2205
2206                 set env(GIT_DIR) $_gitdir
2207                 set env(GIT_WORK_TREE) $_gitworktree
2208                 cd $pwd
2209
2210                 ui_status $::starting_gitk_msg
2211                 after 10000 {
2212                         ui_ready $starting_gitk_msg
2213                 }
2214         }
2215 }
2216
2217 proc do_git_gui {} {
2218         global current_diff_path
2219
2220         # -- Always start git gui through whatever we were loaded with.  This
2221         #    lets us bypass using shell process on Windows systems.
2222         #
2223         set exe [list [_which git]]
2224         if {$exe eq {}} {
2225                 error_popup [mc "Couldn't find git gui in PATH"]
2226         } else {
2227                 global env
2228                 global _gitdir _gitworktree
2229
2230                 # see note in do_gitk about unsetting these vars when
2231                 # running tools in a submodule
2232                 unset env(GIT_DIR)
2233                 unset env(GIT_WORK_TREE)
2234
2235                 set pwd [pwd]
2236                 cd $current_diff_path
2237
2238                 eval exec $exe gui &
2239
2240                 set env(GIT_DIR) $_gitdir
2241                 set env(GIT_WORK_TREE) $_gitworktree
2242                 cd $pwd
2243
2244                 ui_status $::starting_gitk_msg
2245                 after 10000 {
2246                         ui_ready $starting_gitk_msg
2247                 }
2248         }
2249 }
2250
2251 proc do_explore {} {
2252         global _gitworktree
2253         set explorer {}
2254         if {[is_Cygwin] || [is_Windows]} {
2255                 set explorer "explorer.exe"
2256         } elseif {[is_MacOSX]} {
2257                 set explorer "open"
2258         } else {
2259                 # freedesktop.org-conforming system is our best shot
2260                 set explorer "xdg-open"
2261         }
2262         eval exec $explorer [list [file nativename $_gitworktree]] &
2263 }
2264
2265 set is_quitting 0
2266 set ret_code    1
2267
2268 proc terminate_me {win} {
2269         global ret_code
2270         if {$win ne {.}} return
2271         exit $ret_code
2272 }
2273
2274 proc do_quit {{rc {1}}} {
2275         global ui_comm is_quitting repo_config commit_type
2276         global GITGUI_BCK_exists GITGUI_BCK_i
2277         global ui_comm_spell
2278         global ret_code use_ttk
2279
2280         if {$is_quitting} return
2281         set is_quitting 1
2282
2283         if {[winfo exists $ui_comm]} {
2284                 # -- Stash our current commit buffer.
2285                 #
2286                 set save [gitdir GITGUI_MSG]
2287                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2288                         file rename -force [gitdir GITGUI_BCK] $save
2289                         set GITGUI_BCK_exists 0
2290                 } else {
2291                         set msg [string trim [$ui_comm get 0.0 end]]
2292                         regsub -all -line {[ \r\t]+$} $msg {} msg
2293                         if {(![string match amend* $commit_type]
2294                                 || [$ui_comm edit modified])
2295                                 && $msg ne {}} {
2296                                 catch {
2297                                         set fd [open $save w]
2298                                         fconfigure $fd -encoding utf-8
2299                                         puts -nonewline $fd $msg
2300                                         close $fd
2301                                 }
2302                         } else {
2303                                 catch {file delete $save}
2304                         }
2305                 }
2306
2307                 # -- Cancel our spellchecker if its running.
2308                 #
2309                 if {[info exists ui_comm_spell]} {
2310                         $ui_comm_spell stop
2311                 }
2312
2313                 # -- Remove our editor backup, its not needed.
2314                 #
2315                 after cancel $GITGUI_BCK_i
2316                 if {$GITGUI_BCK_exists} {
2317                         catch {file delete [gitdir GITGUI_BCK]}
2318                 }
2319
2320                 # -- Stash our current window geometry into this repository.
2321                 #
2322                 set cfg_wmstate [wm state .]
2323                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2324                         set rc_wmstate {}
2325                 }
2326                 if {$cfg_wmstate ne $rc_wmstate} {
2327                         catch {git config gui.wmstate $cfg_wmstate}
2328                 }
2329                 if {$cfg_wmstate eq {zoomed}} {
2330                         # on Windows wm geometry will lie about window
2331                         # position (but not size) when window is zoomed
2332                         # restore the window before querying wm geometry
2333                         wm state . normal
2334                 }
2335                 set cfg_geometry [list]
2336                 lappend cfg_geometry [wm geometry .]
2337                 if {$use_ttk} {
2338                         lappend cfg_geometry [.vpane sashpos 0]
2339                         lappend cfg_geometry [.vpane.files sashpos 0]
2340                 } else {
2341                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2342                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2343                 }
2344                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2345                         set rc_geometry {}
2346                 }
2347                 if {$cfg_geometry ne $rc_geometry} {
2348                         catch {git config gui.geometry $cfg_geometry}
2349                 }
2350         }
2351
2352         set ret_code $rc
2353
2354         # Briefly enable send again, working around Tk bug
2355         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2356         tk appname [appname]
2357
2358         destroy .
2359 }
2360
2361 proc do_rescan {} {
2362         rescan ui_ready
2363 }
2364
2365 proc ui_do_rescan {} {
2366         rescan {force_first_diff ui_ready}
2367 }
2368
2369 proc do_commit {} {
2370         commit_tree
2371 }
2372
2373 proc next_diff {{after {}}} {
2374         global next_diff_p next_diff_w next_diff_i
2375         show_diff $next_diff_p $next_diff_w {} {} $after
2376 }
2377
2378 proc find_anchor_pos {lst name} {
2379         set lid [lsearch -sorted -exact $lst $name]
2380
2381         if {$lid == -1} {
2382                 set lid 0
2383                 foreach lname $lst {
2384                         if {$lname >= $name} break
2385                         incr lid
2386                 }
2387         }
2388
2389         return $lid
2390 }
2391
2392 proc find_file_from {flist idx delta path mmask} {
2393         global file_states
2394
2395         set len [llength $flist]
2396         while {$idx >= 0 && $idx < $len} {
2397                 set name [lindex $flist $idx]
2398
2399                 if {$name ne $path && [info exists file_states($name)]} {
2400                         set state [lindex $file_states($name) 0]
2401
2402                         if {$mmask eq {} || [regexp $mmask $state]} {
2403                                 return $idx
2404                         }
2405                 }
2406
2407                 incr idx $delta
2408         }
2409
2410         return {}
2411 }
2412
2413 proc find_next_diff {w path {lno {}} {mmask {}}} {
2414         global next_diff_p next_diff_w next_diff_i
2415         global file_lists ui_index ui_workdir
2416
2417         set flist $file_lists($w)
2418         if {$lno eq {}} {
2419                 set lno [find_anchor_pos $flist $path]
2420         } else {
2421                 incr lno -1
2422         }
2423
2424         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2425                 if {$w eq $ui_index} {
2426                         set mmask "^$mmask"
2427                 } else {
2428                         set mmask "$mmask\$"
2429                 }
2430         }
2431
2432         set idx [find_file_from $flist $lno 1 $path $mmask]
2433         if {$idx eq {}} {
2434                 incr lno -1
2435                 set idx [find_file_from $flist $lno -1 $path $mmask]
2436         }
2437
2438         if {$idx ne {}} {
2439                 set next_diff_w $w
2440                 set next_diff_p [lindex $flist $idx]
2441                 set next_diff_i [expr {$idx+1}]
2442                 return 1
2443         } else {
2444                 return 0
2445         }
2446 }
2447
2448 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2449         global current_diff_path
2450
2451         if {$path ne $current_diff_path} {
2452                 return {}
2453         } elseif {[find_next_diff $w $path $lno $mmask]} {
2454                 return {next_diff;}
2455         } else {
2456                 return {reshow_diff;}
2457         }
2458 }
2459
2460 proc select_first_diff {after} {
2461         global ui_workdir
2462
2463         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2464             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2465                 next_diff $after
2466         } else {
2467                 uplevel #0 $after
2468         }
2469 }
2470
2471 proc force_first_diff {after} {
2472         global ui_workdir current_diff_path file_states
2473
2474         if {[info exists file_states($current_diff_path)]} {
2475                 set state [lindex $file_states($current_diff_path) 0]
2476         } else {
2477                 set state {OO}
2478         }
2479
2480         set reselect 0
2481         if {[string first {U} $state] >= 0} {
2482                 # Already a conflict, do nothing
2483         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2484                 set reselect 1
2485         } elseif {[string index $state 1] ne {O}} {
2486                 # Already a diff & no conflicts, do nothing
2487         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2488                 set reselect 1
2489         }
2490
2491         if {$reselect} {
2492                 next_diff $after
2493         } else {
2494                 uplevel #0 $after
2495         }
2496 }
2497
2498 proc toggle_or_diff {w x y} {
2499         global file_states file_lists current_diff_path ui_index ui_workdir
2500         global last_clicked selected_paths
2501
2502         set pos [split [$w index @$x,$y] .]
2503         set lno [lindex $pos 0]
2504         set col [lindex $pos 1]
2505         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2506         if {$path eq {}} {
2507                 set last_clicked {}
2508                 return
2509         }
2510
2511         set last_clicked [list $w $lno]
2512         array unset selected_paths
2513         $ui_index tag remove in_sel 0.0 end
2514         $ui_workdir tag remove in_sel 0.0 end
2515
2516         # Determine the state of the file
2517         if {[info exists file_states($path)]} {
2518                 set state [lindex $file_states($path) 0]
2519         } else {
2520                 set state {__}
2521         }
2522
2523         # Restage the file, or simply show the diff
2524         if {$col == 0 && $y > 1} {
2525                 # Conflicts need special handling
2526                 if {[string first {U} $state] >= 0} {
2527                         # $w must always be $ui_workdir, but...
2528                         if {$w ne $ui_workdir} { set lno {} }
2529                         merge_stage_workdir $path $lno
2530                         return
2531                 }
2532
2533                 if {[string index $state 1] eq {O}} {
2534                         set mmask {}
2535                 } else {
2536                         set mmask {[^O]}
2537                 }
2538
2539                 set after [next_diff_after_action $w $path $lno $mmask]
2540
2541                 if {$w eq $ui_index} {
2542                         update_indexinfo \
2543                                 "Unstaging [short_path $path] from commit" \
2544                                 [list $path] \
2545                                 [concat $after [list ui_ready]]
2546                 } elseif {$w eq $ui_workdir} {
2547                         update_index \
2548                                 "Adding [short_path $path]" \
2549                                 [list $path] \
2550                                 [concat $after [list ui_ready]]
2551                 }
2552         } else {
2553                 set selected_paths($path) 1
2554                 show_diff $path $w $lno
2555         }
2556 }
2557
2558 proc add_one_to_selection {w x y} {
2559         global file_lists last_clicked selected_paths
2560
2561         set lno [lindex [split [$w index @$x,$y] .] 0]
2562         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2563         if {$path eq {}} {
2564                 set last_clicked {}
2565                 return
2566         }
2567
2568         if {$last_clicked ne {}
2569                 && [lindex $last_clicked 0] ne $w} {
2570                 array unset selected_paths
2571                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2572         }
2573
2574         set last_clicked [list $w $lno]
2575         if {[catch {set in_sel $selected_paths($path)}]} {
2576                 set in_sel 0
2577         }
2578         if {$in_sel} {
2579                 unset selected_paths($path)
2580                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2581         } else {
2582                 set selected_paths($path) 1
2583                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2584         }
2585 }
2586
2587 proc add_range_to_selection {w x y} {
2588         global file_lists last_clicked selected_paths
2589
2590         if {[lindex $last_clicked 0] ne $w} {
2591                 toggle_or_diff $w $x $y
2592                 return
2593         }
2594
2595         set lno [lindex [split [$w index @$x,$y] .] 0]
2596         set lc [lindex $last_clicked 1]
2597         if {$lc < $lno} {
2598                 set begin $lc
2599                 set end $lno
2600         } else {
2601                 set begin $lno
2602                 set end $lc
2603         }
2604
2605         foreach path [lrange $file_lists($w) \
2606                 [expr {$begin - 1}] \
2607                 [expr {$end - 1}]] {
2608                 set selected_paths($path) 1
2609         }
2610         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2611 }
2612
2613 proc show_more_context {} {
2614         global repo_config
2615         if {$repo_config(gui.diffcontext) < 99} {
2616                 incr repo_config(gui.diffcontext)
2617                 reshow_diff
2618         }
2619 }
2620
2621 proc show_less_context {} {
2622         global repo_config
2623         if {$repo_config(gui.diffcontext) > 1} {
2624                 incr repo_config(gui.diffcontext) -1
2625                 reshow_diff
2626         }
2627 }
2628
2629 ######################################################################
2630 ##
2631 ## ui construction
2632
2633 set ui_comm {}
2634
2635 # -- Menu Bar
2636 #
2637 menu .mbar -tearoff 0
2638 if {[is_MacOSX]} {
2639         # -- Apple Menu (Mac OS X only)
2640         #
2641         .mbar add cascade -label Apple -menu .mbar.apple
2642         menu .mbar.apple
2643 }
2644 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2645 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2646 if {[is_enabled branch]} {
2647         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2648 }
2649 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2650         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2651 }
2652 if {[is_enabled transport]} {
2653         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2654         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2655 }
2656 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2657         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2658 }
2659
2660 # -- Repository Menu
2661 #
2662 menu .mbar.repository
2663
2664 if {![is_bare]} {
2665         .mbar.repository add command \
2666                 -label [mc "Explore Working Copy"] \
2667                 -command {do_explore}
2668         .mbar.repository add separator
2669 }
2670
2671 .mbar.repository add command \
2672         -label [mc "Browse Current Branch's Files"] \
2673         -command {browser::new $current_branch}
2674 set ui_browse_current [.mbar.repository index last]
2675 .mbar.repository add command \
2676         -label [mc "Browse Branch Files..."] \
2677         -command browser_open::dialog
2678 .mbar.repository add separator
2679
2680 .mbar.repository add command \
2681         -label [mc "Visualize Current Branch's History"] \
2682         -command {do_gitk $current_branch}
2683 set ui_visualize_current [.mbar.repository index last]
2684 .mbar.repository add command \
2685         -label [mc "Visualize All Branch History"] \
2686         -command {do_gitk --all}
2687 .mbar.repository add separator
2688
2689 proc current_branch_write {args} {
2690         global current_branch
2691         .mbar.repository entryconf $::ui_browse_current \
2692                 -label [mc "Browse %s's Files" $current_branch]
2693         .mbar.repository entryconf $::ui_visualize_current \
2694                 -label [mc "Visualize %s's History" $current_branch]
2695 }
2696 trace add variable current_branch write current_branch_write
2697
2698 if {[is_enabled multicommit]} {
2699         .mbar.repository add command -label [mc "Database Statistics"] \
2700                 -command do_stats
2701
2702         .mbar.repository add command -label [mc "Compress Database"] \
2703                 -command do_gc
2704
2705         .mbar.repository add command -label [mc "Verify Database"] \
2706                 -command do_fsck_objects
2707
2708         .mbar.repository add separator
2709
2710         if {[is_Cygwin]} {
2711                 .mbar.repository add command \
2712                         -label [mc "Create Desktop Icon"] \
2713                         -command do_cygwin_shortcut
2714         } elseif {[is_Windows]} {
2715                 .mbar.repository add command \
2716                         -label [mc "Create Desktop Icon"] \
2717                         -command do_windows_shortcut
2718         } elseif {[is_MacOSX]} {
2719                 .mbar.repository add command \
2720                         -label [mc "Create Desktop Icon"] \
2721                         -command do_macosx_app
2722         }
2723 }
2724
2725 if {[is_MacOSX]} {
2726         proc ::tk::mac::Quit {args} { do_quit }
2727 } else {
2728         .mbar.repository add command -label [mc Quit] \
2729                 -command do_quit \
2730                 -accelerator $M1T-Q
2731 }
2732
2733 # -- Edit Menu
2734 #
2735 menu .mbar.edit
2736 .mbar.edit add command -label [mc Undo] \
2737         -command {catch {[focus] edit undo}} \
2738         -accelerator $M1T-Z
2739 .mbar.edit add command -label [mc Redo] \
2740         -command {catch {[focus] edit redo}} \
2741         -accelerator $M1T-Y
2742 .mbar.edit add separator
2743 .mbar.edit add command -label [mc Cut] \
2744         -command {catch {tk_textCut [focus]}} \
2745         -accelerator $M1T-X
2746 .mbar.edit add command -label [mc Copy] \
2747         -command {catch {tk_textCopy [focus]}} \
2748         -accelerator $M1T-C
2749 .mbar.edit add command -label [mc Paste] \
2750         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2751         -accelerator $M1T-V
2752 .mbar.edit add command -label [mc Delete] \
2753         -command {catch {[focus] delete sel.first sel.last}} \
2754         -accelerator Del
2755 .mbar.edit add separator
2756 .mbar.edit add command -label [mc "Select All"] \
2757         -command {catch {[focus] tag add sel 0.0 end}} \
2758         -accelerator $M1T-A
2759
2760 # -- Branch Menu
2761 #
2762 if {[is_enabled branch]} {
2763         menu .mbar.branch
2764
2765         .mbar.branch add command -label [mc "Create..."] \
2766                 -command branch_create::dialog \
2767                 -accelerator $M1T-N
2768         lappend disable_on_lock [list .mbar.branch entryconf \
2769                 [.mbar.branch index last] -state]
2770
2771         .mbar.branch add command -label [mc "Checkout..."] \
2772                 -command branch_checkout::dialog \
2773                 -accelerator $M1T-O
2774         lappend disable_on_lock [list .mbar.branch entryconf \
2775                 [.mbar.branch index last] -state]
2776
2777         .mbar.branch add command -label [mc "Rename..."] \
2778                 -command branch_rename::dialog
2779         lappend disable_on_lock [list .mbar.branch entryconf \
2780                 [.mbar.branch index last] -state]
2781
2782         .mbar.branch add command -label [mc "Delete..."] \
2783                 -command branch_delete::dialog
2784         lappend disable_on_lock [list .mbar.branch entryconf \
2785                 [.mbar.branch index last] -state]
2786
2787         .mbar.branch add command -label [mc "Reset..."] \
2788                 -command merge::reset_hard
2789         lappend disable_on_lock [list .mbar.branch entryconf \
2790                 [.mbar.branch index last] -state]
2791 }
2792
2793 # -- Commit Menu
2794 #
2795 proc commit_btn_caption {} {
2796         if {[is_enabled nocommit]} {
2797                 return [mc "Done"]
2798         } else {
2799                 return [mc Commit@@verb]
2800         }
2801 }
2802
2803 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2804         menu .mbar.commit
2805
2806         if {![is_enabled nocommit]} {
2807                 .mbar.commit add radiobutton \
2808                         -label [mc "New Commit"] \
2809                         -command do_select_commit_type \
2810                         -variable selected_commit_type \
2811                         -value new
2812                 lappend disable_on_lock \
2813                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2814
2815                 .mbar.commit add radiobutton \
2816                         -label [mc "Amend Last Commit"] \
2817                         -command do_select_commit_type \
2818                         -variable selected_commit_type \
2819                         -value amend
2820                 lappend disable_on_lock \
2821                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2822
2823                 .mbar.commit add separator
2824         }
2825
2826         .mbar.commit add command -label [mc Rescan] \
2827                 -command ui_do_rescan \
2828                 -accelerator F5
2829         lappend disable_on_lock \
2830                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2831
2832         .mbar.commit add command -label [mc "Stage To Commit"] \
2833                 -command do_add_selection \
2834                 -accelerator $M1T-T
2835         lappend disable_on_lock \
2836                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2837
2838         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2839                 -command do_add_all \
2840                 -accelerator $M1T-I
2841         lappend disable_on_lock \
2842                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2843
2844         .mbar.commit add command -label [mc "Unstage From Commit"] \
2845                 -command do_unstage_selection \
2846                 -accelerator $M1T-U
2847         lappend disable_on_lock \
2848                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2849
2850         .mbar.commit add command -label [mc "Revert Changes"] \
2851                 -command do_revert_selection \
2852                 -accelerator $M1T-J
2853         lappend disable_on_lock \
2854                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2855
2856         .mbar.commit add separator
2857
2858         .mbar.commit add command -label [mc "Show Less Context"] \
2859                 -command show_less_context \
2860                 -accelerator $M1T-\-
2861
2862         .mbar.commit add command -label [mc "Show More Context"] \
2863                 -command show_more_context \
2864                 -accelerator $M1T-=
2865
2866         .mbar.commit add separator
2867
2868         if {![is_enabled nocommitmsg]} {
2869                 .mbar.commit add command -label [mc "Sign Off"] \
2870                         -command do_signoff \
2871                         -accelerator $M1T-S
2872         }
2873
2874         .mbar.commit add command -label [commit_btn_caption] \
2875                 -command do_commit \
2876                 -accelerator $M1T-Return
2877         lappend disable_on_lock \
2878                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2879 }
2880
2881 # -- Merge Menu
2882 #
2883 if {[is_enabled branch]} {
2884         menu .mbar.merge
2885         .mbar.merge add command -label [mc "Local Merge..."] \
2886                 -command merge::dialog \
2887                 -accelerator $M1T-M
2888         lappend disable_on_lock \
2889                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2890         .mbar.merge add command -label [mc "Abort Merge..."] \
2891                 -command merge::reset_hard
2892         lappend disable_on_lock \
2893                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2894 }
2895
2896 # -- Transport Menu
2897 #
2898 if {[is_enabled transport]} {
2899         menu .mbar.remote
2900
2901         .mbar.remote add command \
2902                 -label [mc "Add..."] \
2903                 -command remote_add::dialog \
2904                 -accelerator $M1T-A
2905         .mbar.remote add command \
2906                 -label [mc "Push..."] \
2907                 -command do_push_anywhere \
2908                 -accelerator $M1T-P
2909         .mbar.remote add command \
2910                 -label [mc "Delete Branch..."] \
2911                 -command remote_branch_delete::dialog
2912 }
2913
2914 if {[is_MacOSX]} {
2915         proc ::tk::mac::ShowPreferences {} {do_options}
2916 } else {
2917         # -- Edit Menu
2918         #
2919         .mbar.edit add separator
2920         .mbar.edit add command -label [mc "Options..."] \
2921                 -command do_options
2922 }
2923
2924 # -- Tools Menu
2925 #
2926 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2927         set tools_menubar .mbar.tools
2928         menu $tools_menubar
2929         $tools_menubar add separator
2930         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2931         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2932         set tools_tailcnt 3
2933         if {[array names repo_config guitool.*.cmd] ne {}} {
2934                 tools_populate_all
2935         }
2936 }
2937
2938 # -- Help Menu
2939 #
2940 .mbar add cascade -label [mc Help] -menu .mbar.help
2941 menu .mbar.help
2942
2943 if {[is_MacOSX]} {
2944         .mbar.apple add command -label [mc "About %s" [appname]] \
2945                 -command do_about
2946         .mbar.apple add separator
2947 } else {
2948         .mbar.help add command -label [mc "About %s" [appname]] \
2949                 -command do_about
2950 }
2951 . configure -menu .mbar
2952
2953 set doc_path [githtmldir]
2954 if {$doc_path ne {}} {
2955         set doc_path [file join $doc_path index.html]
2956
2957         if {[is_Cygwin]} {
2958                 set doc_path [exec cygpath --mixed $doc_path]
2959         }
2960 }
2961
2962 if {[file isfile $doc_path]} {
2963         set doc_url "file:$doc_path"
2964 } else {
2965         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2966 }
2967
2968 proc start_browser {url} {
2969         git "web--browse" $url
2970 }
2971
2972 .mbar.help add command -label [mc "Online Documentation"] \
2973         -command [list start_browser $doc_url]
2974
2975 .mbar.help add command -label [mc "Show SSH Key"] \
2976         -command do_ssh_key
2977
2978 unset doc_path doc_url
2979
2980 # -- Standard bindings
2981 #
2982 wm protocol . WM_DELETE_WINDOW do_quit
2983 bind all <$M1B-Key-q> do_quit
2984 bind all <$M1B-Key-Q> do_quit
2985 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2986 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2987
2988 set subcommand_args {}
2989 proc usage {} {
2990         set s "usage: $::argv0 $::subcommand $::subcommand_args"
2991         if {[tk windowingsystem] eq "win32"} {
2992                 wm withdraw .
2993                 tk_messageBox -icon info -message $s \
2994                         -title [mc "Usage"]
2995         } else {
2996                 puts stderr $s
2997         }
2998         exit 1
2999 }
3000
3001 proc normalize_relpath {path} {
3002         set elements {}
3003         foreach item [file split $path] {
3004                 if {$item eq {.}} continue
3005                 if {$item eq {..} && [llength $elements] > 0
3006                     && [lindex $elements end] ne {..}} {
3007                         set elements [lrange $elements 0 end-1]
3008                         continue
3009                 }
3010                 lappend elements $item
3011         }
3012         return [eval file join $elements]
3013 }
3014
3015 # -- Not a normal commit type invocation?  Do that instead!
3016 #
3017 switch -- $subcommand {
3018 browser -
3019 blame {
3020         if {$subcommand eq "blame"} {
3021                 set subcommand_args {[--line=<num>] rev? path}
3022         } else {
3023                 set subcommand_args {rev? path}
3024         }
3025         if {$argv eq {}} usage
3026         set head {}
3027         set path {}
3028         set jump_spec {}
3029         set is_path 0
3030         foreach a $argv {
3031                 set p [file join $_prefix $a]
3032
3033                 if {$is_path || [file exists $p]} {
3034                         if {$path ne {}} usage
3035                         set path [normalize_relpath $p]
3036                         break
3037                 } elseif {$a eq {--}} {
3038                         if {$path ne {}} {
3039                                 if {$head ne {}} usage
3040                                 set head $path
3041                                 set path {}
3042                         }
3043                         set is_path 1
3044                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3045                         if {$jump_spec ne {} || $head ne {}} usage
3046                         set jump_spec [list $lnum]
3047                 } elseif {$head eq {}} {
3048                         if {$head ne {}} usage
3049                         set head $a
3050                         set is_path 1
3051                 } else {
3052                         usage
3053                 }
3054         }
3055         unset is_path
3056
3057         if {$head ne {} && $path eq {}} {
3058                 if {[string index $head 0] eq {/}} {
3059                         set path [normalize_relpath $head]
3060                         set head {}
3061                 } else {
3062                         set path [normalize_relpath $_prefix$head]
3063                         set head {}
3064                 }
3065         }
3066
3067         if {$head eq {}} {
3068                 load_current_branch
3069         } else {
3070                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3071                         if {[catch {
3072                                         set head [git rev-parse --verify $head]
3073                                 } err]} {
3074                                 if {[tk windowingsystem] eq "win32"} {
3075                                         tk_messageBox -icon error -title [mc Error] -message $err
3076                                 } else {
3077                                         puts stderr $err
3078                                 }
3079                                 exit 1
3080                         }
3081                 }
3082                 set current_branch $head
3083         }
3084
3085         wm deiconify .
3086         switch -- $subcommand {
3087         browser {
3088                 if {$jump_spec ne {}} usage
3089                 if {$head eq {}} {
3090                         if {$path ne {} && [file isdirectory $path]} {
3091                                 set head $current_branch
3092                         } else {
3093                                 set head $path
3094                                 set path {}
3095                         }
3096                 }
3097                 browser::new $head $path
3098         }
3099         blame   {
3100                 if {$head eq {} && ![file exists $path]} {
3101                         catch {wm withdraw .}
3102                         tk_messageBox \
3103                                 -icon error \
3104                                 -type ok \
3105                                 -title [mc "git-gui: fatal error"] \
3106                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3107                         exit 1
3108                 }
3109                 blame::new $head $path $jump_spec
3110         }
3111         }
3112         return
3113 }
3114 citool -
3115 gui {
3116         if {[llength $argv] != 0} {
3117                 usage
3118         }
3119         # fall through to setup UI for commits
3120 }
3121 default {
3122         set err "usage: $argv0 \[{blame|browser|citool}\]"
3123         if {[tk windowingsystem] eq "win32"} {
3124                 wm withdraw .
3125                 tk_messageBox -icon error -message $err \
3126                         -title [mc "Usage"]
3127         } else {
3128                 puts stderr $err
3129         }
3130         exit 1
3131 }
3132 }
3133
3134 # -- Branch Control
3135 #
3136 ${NS}::frame .branch
3137 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3138 ${NS}::label .branch.l1 \
3139         -text [mc "Current Branch:"] \
3140         -anchor w \
3141         -justify left
3142 ${NS}::label .branch.cb \
3143         -textvariable current_branch \
3144         -anchor w \
3145         -justify left
3146 pack .branch.l1 -side left
3147 pack .branch.cb -side left -fill x
3148 pack .branch -side top -fill x
3149
3150 # -- Main Window Layout
3151 #
3152 ${NS}::panedwindow .vpane -orient horizontal
3153 ${NS}::panedwindow .vpane.files -orient vertical
3154 if {$use_ttk} {
3155         .vpane add .vpane.files
3156 } else {
3157         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3158 }
3159 pack .vpane -anchor n -side top -fill both -expand 1
3160
3161 # -- Index File List
3162 #
3163 ${NS}::frame .vpane.files.index -height 100 -width 200
3164 tlabel .vpane.files.index.title \
3165         -text [mc "Staged Changes (Will Commit)"] \
3166         -background lightgreen -foreground black
3167 text $ui_index -background white -foreground black \
3168         -borderwidth 0 \
3169         -width 20 -height 10 \
3170         -wrap none \
3171         -cursor $cursor_ptr \
3172         -xscrollcommand {.vpane.files.index.sx set} \
3173         -yscrollcommand {.vpane.files.index.sy set} \
3174         -state disabled
3175 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3176 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3177 pack .vpane.files.index.title -side top -fill x
3178 pack .vpane.files.index.sx -side bottom -fill x
3179 pack .vpane.files.index.sy -side right -fill y
3180 pack $ui_index -side left -fill both -expand 1
3181
3182 # -- Working Directory File List
3183 #
3184 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3185 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3186         -background lightsalmon -foreground black
3187 text $ui_workdir -background white -foreground black \
3188         -borderwidth 0 \
3189         -width 20 -height 10 \
3190         -wrap none \
3191         -cursor $cursor_ptr \
3192         -xscrollcommand {.vpane.files.workdir.sx set} \
3193         -yscrollcommand {.vpane.files.workdir.sy set} \
3194         -state disabled
3195 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3196 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3197 pack .vpane.files.workdir.title -side top -fill x
3198 pack .vpane.files.workdir.sx -side bottom -fill x
3199 pack .vpane.files.workdir.sy -side right -fill y
3200 pack $ui_workdir -side left -fill both -expand 1
3201
3202 .vpane.files add .vpane.files.workdir
3203 .vpane.files add .vpane.files.index
3204 if {!$use_ttk} {
3205         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3206         .vpane.files paneconfigure .vpane.files.index -sticky news
3207 }
3208
3209 foreach i [list $ui_index $ui_workdir] {
3210         rmsel_tag $i
3211         $i tag conf in_diff -background [$i tag cget in_sel -background]
3212 }
3213 unset i
3214
3215 # -- Diff and Commit Area
3216 #
3217 ${NS}::panedwindow .vpane.lower -orient vertical
3218 ${NS}::frame .vpane.lower.commarea
3219 ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3220 .vpane.lower add .vpane.lower.diff
3221 .vpane.lower add .vpane.lower.commarea
3222 .vpane add .vpane.lower
3223 if {$use_ttk} {
3224         .vpane.lower pane .vpane.lower.diff -weight 1
3225         .vpane.lower pane .vpane.lower.commarea -weight 0
3226 } else {
3227         .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3228         .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3229 }
3230
3231 # -- Commit Area Buttons
3232 #
3233 ${NS}::frame .vpane.lower.commarea.buttons
3234 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3235         -anchor w \
3236         -justify left
3237 pack .vpane.lower.commarea.buttons.l -side top -fill x
3238 pack .vpane.lower.commarea.buttons -side left -fill y
3239
3240 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3241         -command ui_do_rescan
3242 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3243 lappend disable_on_lock \
3244         {.vpane.lower.commarea.buttons.rescan conf -state}
3245
3246 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3247         -command do_add_all
3248 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3249 lappend disable_on_lock \
3250         {.vpane.lower.commarea.buttons.incall conf -state}
3251
3252 if {![is_enabled nocommitmsg]} {
3253         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3254                 -command do_signoff
3255         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3256 }
3257
3258 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3259         -command do_commit
3260 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3261 lappend disable_on_lock \
3262         {.vpane.lower.commarea.buttons.commit conf -state}
3263
3264 if {![is_enabled nocommit]} {
3265         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3266                 -command do_push_anywhere
3267         pack .vpane.lower.commarea.buttons.push -side top -fill x
3268 }
3269
3270 # -- Commit Message Buffer
3271 #
3272 ${NS}::frame .vpane.lower.commarea.buffer
3273 ${NS}::frame .vpane.lower.commarea.buffer.header
3274 set ui_comm .vpane.lower.commarea.buffer.t
3275 set ui_coml .vpane.lower.commarea.buffer.header.l
3276
3277 if {![is_enabled nocommit]} {
3278         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3279                 -text [mc "New Commit"] \
3280                 -command do_select_commit_type \
3281                 -variable selected_commit_type \
3282                 -value new
3283         lappend disable_on_lock \
3284                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3285         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3286                 -text [mc "Amend Last Commit"] \
3287                 -command do_select_commit_type \
3288                 -variable selected_commit_type \
3289                 -value amend
3290         lappend disable_on_lock \
3291                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3292 }
3293
3294 ${NS}::label $ui_coml \
3295         -anchor w \
3296         -justify left
3297 proc trace_commit_type {varname args} {
3298         global ui_coml commit_type
3299         switch -glob -- $commit_type {
3300         initial       {set txt [mc "Initial Commit Message:"]}
3301         amend         {set txt [mc "Amended Commit Message:"]}
3302         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3303         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3304         merge         {set txt [mc "Merge Commit Message:"]}
3305         *             {set txt [mc "Commit Message:"]}
3306         }
3307         $ui_coml conf -text $txt
3308 }
3309 trace add variable commit_type write trace_commit_type
3310 pack $ui_coml -side left -fill x
3311
3312 if {![is_enabled nocommit]} {
3313         pack .vpane.lower.commarea.buffer.header.amend -side right
3314         pack .vpane.lower.commarea.buffer.header.new -side right
3315 }
3316
3317 text $ui_comm -background white -foreground black \
3318         -borderwidth 1 \
3319         -undo true \
3320         -maxundo 20 \
3321         -autoseparators true \
3322         -relief sunken \
3323         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3324         -font font_diff \
3325         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3326 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3327         -command [list $ui_comm yview]
3328 pack .vpane.lower.commarea.buffer.header -side top -fill x
3329 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3330 pack $ui_comm -side left -fill y
3331 pack .vpane.lower.commarea.buffer -side left -fill y
3332
3333 # -- Commit Message Buffer Context Menu
3334 #
3335 set ctxm .vpane.lower.commarea.buffer.ctxm
3336 menu $ctxm -tearoff 0
3337 $ctxm add command \
3338         -label [mc Cut] \
3339         -command {tk_textCut $ui_comm}
3340 $ctxm add command \
3341         -label [mc Copy] \
3342         -command {tk_textCopy $ui_comm}
3343 $ctxm add command \
3344         -label [mc Paste] \
3345         -command {tk_textPaste $ui_comm}
3346 $ctxm add command \
3347         -label [mc Delete] \
3348         -command {catch {$ui_comm delete sel.first sel.last}}
3349 $ctxm add separator
3350 $ctxm add command \
3351         -label [mc "Select All"] \
3352         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3353 $ctxm add command \
3354         -label [mc "Copy All"] \
3355         -command {
3356                 $ui_comm tag add sel 0.0 end
3357                 tk_textCopy $ui_comm
3358                 $ui_comm tag remove sel 0.0 end
3359         }
3360 $ctxm add separator
3361 $ctxm add command \
3362         -label [mc "Sign Off"] \
3363         -command do_signoff
3364 set ui_comm_ctxm $ctxm
3365
3366 # -- Diff Header
3367 #
3368 proc trace_current_diff_path {varname args} {
3369         global current_diff_path diff_actions file_states
3370         if {$current_diff_path eq {}} {
3371                 set s {}
3372                 set f {}
3373                 set p {}
3374                 set o disabled
3375         } else {
3376                 set p $current_diff_path
3377                 set s [mapdesc [lindex $file_states($p) 0] $p]
3378                 set f [mc "File:"]
3379                 set p [escape_path $p]
3380                 set o normal
3381         }
3382
3383         .vpane.lower.diff.header.status configure -text $s
3384         .vpane.lower.diff.header.file configure -text $f
3385         .vpane.lower.diff.header.path configure -text $p
3386         foreach w $diff_actions {
3387                 uplevel #0 $w $o
3388         }
3389 }
3390 trace add variable current_diff_path write trace_current_diff_path
3391
3392 gold_frame .vpane.lower.diff.header
3393 tlabel .vpane.lower.diff.header.status \
3394         -background gold \
3395         -foreground black \
3396         -width $max_status_desc \
3397         -anchor w \
3398         -justify left
3399 tlabel .vpane.lower.diff.header.file \
3400         -background gold \
3401         -foreground black \
3402         -anchor w \
3403         -justify left
3404 tlabel .vpane.lower.diff.header.path \
3405         -background gold \
3406         -foreground black \
3407         -anchor w \
3408         -justify left
3409 pack .vpane.lower.diff.header.status -side left
3410 pack .vpane.lower.diff.header.file -side left
3411 pack .vpane.lower.diff.header.path -fill x
3412 set ctxm .vpane.lower.diff.header.ctxm
3413 menu $ctxm -tearoff 0
3414 $ctxm add command \
3415         -label [mc Copy] \
3416         -command {
3417                 clipboard clear
3418                 clipboard append \
3419                         -format STRING \
3420                         -type STRING \
3421                         -- $current_diff_path
3422         }
3423 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3424 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3425
3426 # -- Diff Body
3427 #
3428 ${NS}::frame .vpane.lower.diff.body
3429 set ui_diff .vpane.lower.diff.body.t
3430 text $ui_diff -background white -foreground black \
3431         -borderwidth 0 \
3432         -width 80 -height 5 -wrap none \
3433         -font font_diff \
3434         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3435         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3436         -state disabled
3437 catch {$ui_diff configure -tabstyle wordprocessor}
3438 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3439         -command [list $ui_diff xview]
3440 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3441         -command [list $ui_diff yview]
3442 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3443 pack .vpane.lower.diff.body.sby -side right -fill y
3444 pack $ui_diff -side left -fill both -expand 1
3445 pack .vpane.lower.diff.header -side top -fill x
3446 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3447
3448 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3449         $ui_diff tag configure clr4$n -background $c
3450         $ui_diff tag configure clri4$n -foreground $c
3451         $ui_diff tag configure clr3$n -foreground $c
3452         $ui_diff tag configure clri3$n -background $c
3453 }
3454 $ui_diff tag configure clr1 -font font_diffbold
3455 $ui_diff tag configure clr4 -underline 1
3456
3457 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3458
3459 $ui_diff tag conf d_cr -elide true
3460 $ui_diff tag conf d_@ -font font_diffbold
3461 $ui_diff tag conf d_+ -foreground {#00a000}
3462 $ui_diff tag conf d_- -foreground red
3463
3464 $ui_diff tag conf d_++ -foreground {#00a000}
3465 $ui_diff tag conf d_-- -foreground red
3466 $ui_diff tag conf d_+s \
3467         -foreground {#00a000} \
3468         -background {#e2effa}
3469 $ui_diff tag conf d_-s \
3470         -foreground red \
3471         -background {#e2effa}
3472 $ui_diff tag conf d_s+ \
3473         -foreground {#00a000} \
3474         -background ivory1
3475 $ui_diff tag conf d_s- \
3476         -foreground red \
3477         -background ivory1
3478
3479 $ui_diff tag conf d< \
3480         -foreground orange \
3481         -font font_diffbold
3482 $ui_diff tag conf d= \
3483         -foreground orange \
3484         -font font_diffbold
3485 $ui_diff tag conf d> \
3486         -foreground orange \
3487         -font font_diffbold
3488
3489 $ui_diff tag raise sel
3490
3491 # -- Diff Body Context Menu
3492 #
3493
3494 proc create_common_diff_popup {ctxm} {
3495         $ctxm add command \
3496                 -label [mc Refresh] \
3497                 -command reshow_diff
3498         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3499         $ctxm add command \
3500                 -label [mc Copy] \
3501                 -command {tk_textCopy $ui_diff}
3502         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3503         $ctxm add command \
3504                 -label [mc "Select All"] \
3505                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3506         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3507         $ctxm add command \
3508                 -label [mc "Copy All"] \
3509                 -command {
3510                         $ui_diff tag add sel 0.0 end
3511                         tk_textCopy $ui_diff
3512                         $ui_diff tag remove sel 0.0 end
3513                 }
3514         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3515         $ctxm add separator
3516         $ctxm add command \
3517                 -label [mc "Decrease Font Size"] \
3518                 -command {incr_font_size font_diff -1}
3519         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3520         $ctxm add command \
3521                 -label [mc "Increase Font Size"] \
3522                 -command {incr_font_size font_diff 1}
3523         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3524         $ctxm add separator
3525         set emenu $ctxm.enc
3526         menu $emenu
3527         build_encoding_menu $emenu [list force_diff_encoding]
3528         $ctxm add cascade \
3529                 -label [mc "Encoding"] \
3530                 -menu $emenu
3531         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3532         $ctxm add separator
3533         $ctxm add command -label [mc "Options..."] \
3534                 -command do_options
3535 }
3536
3537 set ctxm .vpane.lower.diff.body.ctxm
3538 menu $ctxm -tearoff 0
3539 $ctxm add command \
3540         -label [mc "Apply/Reverse Hunk"] \
3541         -command {apply_hunk $cursorX $cursorY}
3542 set ui_diff_applyhunk [$ctxm index last]
3543 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3544 $ctxm add command \
3545         -label [mc "Apply/Reverse Line"] \
3546         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3547 set ui_diff_applyline [$ctxm index last]
3548 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3549 $ctxm add separator
3550 $ctxm add command \
3551         -label [mc "Show Less Context"] \
3552         -command show_less_context
3553 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3554 $ctxm add command \
3555         -label [mc "Show More Context"] \
3556         -command show_more_context
3557 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3558 $ctxm add separator
3559 create_common_diff_popup $ctxm
3560
3561 set ctxmmg .vpane.lower.diff.body.ctxmmg
3562 menu $ctxmmg -tearoff 0
3563 $ctxmmg add command \
3564         -label [mc "Run Merge Tool"] \
3565         -command {merge_resolve_tool}
3566 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3567 $ctxmmg add separator
3568 $ctxmmg add command \
3569         -label [mc "Use Remote Version"] \
3570         -command {merge_resolve_one 3}
3571 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3572 $ctxmmg add command \
3573         -label [mc "Use Local Version"] \
3574         -command {merge_resolve_one 2}
3575 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3576 $ctxmmg add command \
3577         -label [mc "Revert To Base"] \
3578         -command {merge_resolve_one 1}
3579 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3580 $ctxmmg add separator
3581 $ctxmmg add command \
3582         -label [mc "Show Less Context"] \
3583         -command show_less_context
3584 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3585 $ctxmmg add command \
3586         -label [mc "Show More Context"] \
3587         -command show_more_context
3588 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3589 $ctxmmg add separator
3590 create_common_diff_popup $ctxmmg
3591
3592 set ctxmsm .vpane.lower.diff.body.ctxmsm
3593 menu $ctxmsm -tearoff 0
3594 $ctxmsm add command \
3595         -label [mc "Visualize These Changes In The Submodule"] \
3596         -command {do_gitk -- true}
3597 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3598 $ctxmsm add command \
3599         -label [mc "Visualize Current Branch History In The Submodule"] \
3600         -command {do_gitk {} true}
3601 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3602 $ctxmsm add command \
3603         -label [mc "Visualize All Branch History In The Submodule"] \
3604         -command {do_gitk --all true}
3605 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3606 $ctxmsm add separator
3607 $ctxmsm add command \
3608         -label [mc "Start git gui In The Submodule"] \
3609         -command {do_git_gui}
3610 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3611 $ctxmsm add separator
3612 create_common_diff_popup $ctxmsm
3613
3614 proc has_textconv {path} {
3615         if {[is_config_false gui.textconv]} {
3616                 return 0
3617         }
3618         set filter [gitattr $path diff set]
3619         set textconv [get_config [join [list diff $filter textconv] .]]
3620         if {$filter ne {set} && $textconv ne {}} {
3621                 return 1
3622         } else {
3623                 return 0
3624         }
3625 }
3626
3627 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3628         global current_diff_path file_states
3629         set ::cursorX $x
3630         set ::cursorY $y
3631         if {[info exists file_states($current_diff_path)]} {
3632                 set state [lindex $file_states($current_diff_path) 0]
3633         } else {
3634                 set state {__}
3635         }
3636         if {[string first {U} $state] >= 0} {
3637                 tk_popup $ctxmmg $X $Y
3638         } elseif {$::is_submodule_diff} {
3639                 tk_popup $ctxmsm $X $Y
3640         } else {
3641                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3642                 if {$::ui_index eq $::current_diff_side} {
3643                         set l [mc "Unstage Hunk From Commit"]
3644                         if {$has_range} {
3645                                 set t [mc "Unstage Lines From Commit"]
3646                         } else {
3647                                 set t [mc "Unstage Line From Commit"]
3648                         }
3649                 } else {
3650                         set l [mc "Stage Hunk For Commit"]
3651                         if {$has_range} {
3652                                 set t [mc "Stage Lines For Commit"]
3653                         } else {
3654                                 set t [mc "Stage Line For Commit"]
3655                         }
3656                 }
3657                 if {$::is_3way_diff
3658                         || $current_diff_path eq {}
3659                         || {__} eq $state
3660                         || {_O} eq $state
3661                         || [string match {?T} $state]
3662                         || [string match {T?} $state]
3663                         || [has_textconv $current_diff_path]} {
3664                         set s disabled
3665                 } else {
3666                         set s normal
3667                 }
3668                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3669                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3670                 tk_popup $ctxm $X $Y
3671         }
3672 }
3673 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3674
3675 # -- Status Bar
3676 #
3677 set main_status [::status_bar::new .status]
3678 pack .status -anchor w -side bottom -fill x
3679 $main_status show [mc "Initializing..."]
3680
3681 # -- Load geometry
3682 #
3683 proc on_ttk_pane_mapped {w pane pos} {
3684         bind $w <Map> {}
3685         after 0 [list after idle [list $w sashpos $pane $pos]]
3686 }
3687 proc on_tk_pane_mapped {w pane x y} {
3688         bind $w <Map> {}
3689         after 0 [list after idle [list $w sash place $pane $x $y]]
3690 }
3691 proc on_application_mapped {} {
3692         global repo_config use_ttk
3693         bind . <Map> {}
3694         set gm $repo_config(gui.geometry)
3695         if {$use_ttk} {
3696                 bind .vpane <Map> \
3697                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3698                 bind .vpane.files <Map> \
3699                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3700         } else {
3701                 bind .vpane <Map> \
3702                     [list on_tk_pane_mapped %W 0 \
3703                          [lindex $gm 1] \
3704                          [lindex [.vpane sash coord 0] 1]]
3705                 bind .vpane.files <Map> \
3706                     [list on_tk_pane_mapped %W 0 \
3707                          [lindex [.vpane.files sash coord 0] 0] \
3708                          [lindex $gm 2]]
3709         }
3710         wm geometry . [lindex $gm 0]
3711 }
3712 if {[info exists repo_config(gui.geometry)]} {
3713         bind . <Map> [list on_application_mapped]
3714         wm geometry . [lindex $repo_config(gui.geometry) 0]
3715 }
3716
3717 # -- Load window state
3718 #
3719 if {[info exists repo_config(gui.wmstate)]} {
3720         catch {wm state . $repo_config(gui.wmstate)}
3721 }
3722
3723 # -- Key Bindings
3724 #
3725 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3726 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3727 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3728 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3729 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3730 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3731 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3732 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3733 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3734 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3735 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3736 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3737 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3738 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3739 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3740 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3741 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3742 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3743 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3744 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3745 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3746 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3747
3748 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3749 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3750 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3751 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3752 bind $ui_diff <$M1B-Key-v> {break}
3753 bind $ui_diff <$M1B-Key-V> {break}
3754 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3755 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3756 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3757 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3758 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3759 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3760 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3761 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3762 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3763 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3764 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3765 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3766 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3767 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3768 bind $ui_diff <Button-1>   {focus %W}
3769
3770 if {[is_enabled branch]} {
3771         bind . <$M1B-Key-n> branch_create::dialog
3772         bind . <$M1B-Key-N> branch_create::dialog
3773         bind . <$M1B-Key-o> branch_checkout::dialog
3774         bind . <$M1B-Key-O> branch_checkout::dialog
3775         bind . <$M1B-Key-m> merge::dialog
3776         bind . <$M1B-Key-M> merge::dialog
3777 }
3778 if {[is_enabled transport]} {
3779         bind . <$M1B-Key-p> do_push_anywhere
3780         bind . <$M1B-Key-P> do_push_anywhere
3781 }
3782
3783 bind .   <Key-F5>     ui_do_rescan
3784 bind .   <$M1B-Key-r> ui_do_rescan
3785 bind .   <$M1B-Key-R> ui_do_rescan
3786 bind .   <$M1B-Key-s> do_signoff
3787 bind .   <$M1B-Key-S> do_signoff
3788 bind .   <$M1B-Key-t> do_add_selection
3789 bind .   <$M1B-Key-T> do_add_selection
3790 bind .   <$M1B-Key-u> do_unstage_selection
3791 bind .   <$M1B-Key-U> do_unstage_selection
3792 bind .   <$M1B-Key-j> do_revert_selection
3793 bind .   <$M1B-Key-J> do_revert_selection
3794 bind .   <$M1B-Key-i> do_add_all
3795 bind .   <$M1B-Key-I> do_add_all
3796 bind .   <$M1B-Key-minus> {show_less_context;break}
3797 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3798 bind .   <$M1B-Key-equal> {show_more_context;break}
3799 bind .   <$M1B-Key-plus> {show_more_context;break}
3800 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3801 bind .   <$M1B-Key-Return> do_commit
3802 foreach i [list $ui_index $ui_workdir] {
3803         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3804         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3805         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3806 }
3807 unset i
3808
3809 set file_lists($ui_index) [list]
3810 set file_lists($ui_workdir) [list]
3811
3812 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3813 focus -force $ui_comm
3814
3815 # -- Warn the user about environmental problems.  Cygwin's Tcl
3816 #    does *not* pass its env array onto any processes it spawns.
3817 #    This means that git processes get none of our environment.
3818 #
3819 if {[is_Cygwin]} {
3820         set ignored_env 0
3821         set suggest_user {}
3822         set msg [mc "Possible environment issues exist.
3823
3824 The following environment variables are probably
3825 going to be ignored by any Git subprocess run
3826 by %s:
3827
3828 " [appname]]
3829         foreach name [array names env] {
3830                 switch -regexp -- $name {
3831                 {^GIT_INDEX_FILE$} -
3832                 {^GIT_OBJECT_DIRECTORY$} -
3833                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3834                 {^GIT_DIFF_OPTS$} -
3835                 {^GIT_EXTERNAL_DIFF$} -
3836                 {^GIT_PAGER$} -
3837                 {^GIT_TRACE$} -
3838                 {^GIT_CONFIG$} -
3839                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3840                         append msg " - $name\n"
3841                         incr ignored_env
3842                 }
3843                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3844                         append msg " - $name\n"
3845                         incr ignored_env
3846                         set suggest_user $name
3847                 }
3848                 }
3849         }
3850         if {$ignored_env > 0} {
3851                 append msg [mc "
3852 This is due to a known issue with the
3853 Tcl binary distributed by Cygwin."]
3854
3855                 if {$suggest_user ne {}} {
3856                         append msg [mc "
3857
3858 A good replacement for %s
3859 is placing values for the user.name and
3860 user.email settings into your personal
3861 ~/.gitconfig file.
3862 " $suggest_user]
3863                 }
3864                 warn_popup $msg
3865         }
3866         unset ignored_env msg suggest_user name
3867 }
3868
3869 # -- Only initialize complex UI if we are going to stay running.
3870 #
3871 if {[is_enabled transport]} {
3872         load_all_remotes
3873
3874         set n [.mbar.remote index end]
3875         populate_remotes_menu
3876         set n [expr {[.mbar.remote index end] - $n}]
3877         if {$n > 0} {
3878                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3879                 .mbar.remote insert $n separator
3880         }
3881         unset n
3882 }
3883
3884 if {[winfo exists $ui_comm]} {
3885         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3886
3887         # -- If both our backup and message files exist use the
3888         #    newer of the two files to initialize the buffer.
3889         #
3890         if {$GITGUI_BCK_exists} {
3891                 set m [gitdir GITGUI_MSG]
3892                 if {[file isfile $m]} {
3893                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3894                                 catch {file delete [gitdir GITGUI_MSG]}
3895                         } else {
3896                                 $ui_comm delete 0.0 end
3897                                 $ui_comm edit reset
3898                                 $ui_comm edit modified false
3899                                 catch {file delete [gitdir GITGUI_BCK]}
3900                                 set GITGUI_BCK_exists 0
3901                         }
3902                 }
3903                 unset m
3904         }
3905
3906         proc backup_commit_buffer {} {
3907                 global ui_comm GITGUI_BCK_exists
3908
3909                 set m [$ui_comm edit modified]
3910                 if {$m || $GITGUI_BCK_exists} {
3911                         set msg [string trim [$ui_comm get 0.0 end]]
3912                         regsub -all -line {[ \r\t]+$} $msg {} msg
3913
3914                         if {$msg eq {}} {
3915                                 if {$GITGUI_BCK_exists} {
3916                                         catch {file delete [gitdir GITGUI_BCK]}
3917                                         set GITGUI_BCK_exists 0
3918                                 }
3919                         } elseif {$m} {
3920                                 catch {
3921                                         set fd [open [gitdir GITGUI_BCK] w]
3922                                         fconfigure $fd -encoding utf-8
3923                                         puts -nonewline $fd $msg
3924                                         close $fd
3925                                         set GITGUI_BCK_exists 1
3926                                 }
3927                         }
3928
3929                         $ui_comm edit modified false
3930                 }
3931
3932                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3933         }
3934
3935         backup_commit_buffer
3936
3937         # -- If the user has aspell available we can drive it
3938         #    in pipe mode to spellcheck the commit message.
3939         #
3940         set spell_cmd [list |]
3941         set spell_dict [get_config gui.spellingdictionary]
3942         lappend spell_cmd aspell
3943         if {$spell_dict ne {}} {
3944                 lappend spell_cmd --master=$spell_dict
3945         }
3946         lappend spell_cmd --mode=none
3947         lappend spell_cmd --encoding=utf-8
3948         lappend spell_cmd pipe
3949         if {$spell_dict eq {none}
3950          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3951                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3952         } else {
3953                 set ui_comm_spell [spellcheck::init \
3954                         $spell_fd \
3955                         $ui_comm \
3956                         $ui_comm_ctxm \
3957                 ]
3958         }
3959         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3960 }
3961
3962 lock_index begin-read
3963 if {![winfo ismapped .]} {
3964         wm deiconify .
3965 }
3966 after 1 {
3967         if {[is_enabled initialamend]} {
3968                 force_amend
3969         } else {
3970                 do_rescan
3971         }
3972
3973         if {[is_enabled nocommitmsg]} {
3974                 $ui_comm configure -state disabled -background gray
3975         }
3976 }
3977 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
3978         after 1000 hint_gc
3979 }
3980 if {[is_enabled retcode]} {
3981         bind . <Destroy> {+terminate_me %W}
3982 }
3983 if {$picked && [is_config_true gui.autoexplore]} {
3984         do_explore
3985 }
3986
3987 # Local variables:
3988 # mode: tcl
3989 # indent-tabs-mode: t
3990 # tab-width: 4
3991 # End: