git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42
  43   Composing:
  44     --from                  <str>  * Email From:
  45     --to                    <str>  * Email To:
  46     --cc                    <str>  * Email Cc:
  47     --bcc                   <str>  * Email Bcc:
  48     --subject               <str>  * Email "Subject:"
  49     --in-reply-to           <str>  * Email "In-Reply-To:"
  50     --compose                      * Open an editor for introduction.
  51
  52   Sending:
  53     --envelope-sender       <str>  * Email envelope sender.
  54     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  55                                      is optional. Default 'localhost'.
  56     --smtp-server-port      <int>  * Outgoing SMTP server port.
  57     --smtp-user             <str>  * Username for SMTP-AUTH.
  58     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  59     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  60     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  61
  62   Automating:
  63     --identity              <str>  * Use the sendemail.<id> options.
  64     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  65     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  66     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  67                                      addresses. Default on.
  68     --[no-]suppress-from           * Send to self. Default off.
  69     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  70     --[no-]thread                  * Use In-Reply-To: field. Default on.
  71
  72   Administering:
  73     --quiet                        * Output one line of info per email.
  74     --dry-run                      * Don't actually send the emails.
  75     --[no-]validate                * Perform patch sanity checks. Default on.
  76
  77 EOT
  78         exit(1);
  79 }
  80
  81 # most mail servers generate the Date: header, but not all...
  82 sub format_2822_time {
  83         my ($time) = @_;
  84         my @localtm = localtime($time);
  85         my @gmttm = gmtime($time);
  86         my $localmin = $localtm[1] + $localtm[2] * 60;
  87         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  88         if ($localtm[0] != $gmttm[0]) {
  89                 die "local zone differs from GMT by a non-minute interval\n";
  90         }
  91         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
  92                 $localmin += 1440;
  93         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
  94                 $localmin -= 1440;
  95         } elsif ($gmttm[6] != $localtm[6]) {
  96                 die "local time offset greater than or equal to 24 hours\n";
  97         }
  98         my $offset = $localmin - $gmtmin;
  99         my $offhour = $offset / 60;
 100         my $offmin = abs($offset % 60);
 101         if (abs($offhour) >= 24) {
 102                 die ("local time offset greater than or equal to 24 hours\n");
 103         }
 104
 105         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 106                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 107                        $localtm[3],
 108                        qw(Jan Feb Mar Apr May Jun
 109                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 110                        $localtm[5]+1900,
 111                        $localtm[2],
 112                        $localtm[1],
 113                        $localtm[0],
 114                        ($offset >= 0) ? '+' : '-',
 115                        abs($offhour),
 116                        $offmin,
 117                        );
 118 }
 119
 120 my $have_email_valid = eval { require Email::Valid; 1 };
 121 my $smtp;
 122 my $auth;
 123
 124 sub unique_email_list(@);
 125 sub cleanup_compose_files();
 126
 127 # Constants (essentially)
 128 my $compose_filename = ".msg.$$";
 129
 130 # Variables we fill in automatically, or via prompting:
 131 my (@to,@cc,@initial_cc,@bcclist,@xh,
 132         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 133
 134 my $envelope_sender;
 135
 136 # Example reply to:
 137 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 138
 139 my $repo = eval { Git->repository() };
 140 my @repo = $repo ? ($repo) : ();
 141 my $term = eval {
 142         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 143                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 144                 : new Term::ReadLine 'git-send-email';
 145 };
 146 if ($@) {
 147         $term = new FakeTerm "$@: going non-interactive";
 148 }
 149
 150 # Behavior modification variables
 151 my ($quiet, $dry_run) = (0, 0);
 152
 153 # Variables with corresponding config settings
 154 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 155 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 156 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 157 my ($validate);
 158 my (@suppress_cc);
 159
 160 my %config_bool_settings = (
 161     "thread" => [\$thread, 1],
 162     "chainreplyto" => [\$chain_reply_to, 1],
 163     "suppressfrom" => [\$suppress_from, undef],
 164     "signedoffbycc" => [\$signed_off_by_cc, undef],
 165     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 166     "validate" => [\$validate, 1],
 167 );
 168
 169 my %config_settings = (
 170     "smtpserver" => \$smtp_server,
 171     "smtpserverport" => \$smtp_server_port,
 172     "smtpuser" => \$smtp_authuser,
 173     "smtppass" => \$smtp_authpass,
 174     "to" => \@to,
 175     "cc" => \@initial_cc,
 176     "cccmd" => \$cc_cmd,
 177     "aliasfiletype" => \$aliasfiletype,
 178     "bcc" => \@bcclist,
 179     "aliasesfile" => \@alias_files,
 180     "suppresscc" => \@suppress_cc,
 181     "envelopesender" => \$envelope_sender,
 182 );
 183
 184 # Handle Uncouth Termination
 185 sub signal_handler {
 186
 187         # Make text normal
 188         print color("reset"), "\n";
 189
 190         # SMTP password masked
 191         system "stty echo";
 192
 193         # tmp files from --compose
 194         if (-e $compose_filename) {
 195                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 196         }
 197         if (-e ($compose_filename . ".final")) {
 198                 print "'$compose_filename.final' contains the composed email.\n"
 199         }
 200
 201         exit;
 202 };
 203
 204 $SIG{TERM} = \&signal_handler;
 205 $SIG{INT}  = \&signal_handler;
 206
 207 # Begin by accumulating all the variables (defined above), that we will end up
 208 # needing, first, from the command line:
 209
 210 my $rc = GetOptions("sender|from=s" => \$sender,
 211                     "in-reply-to=s" => \$initial_reply_to,
 212                     "subject=s" => \$initial_subject,
 213                     "to=s" => \@to,
 214                     "cc=s" => \@initial_cc,
 215                     "bcc=s" => \@bcclist,
 216                     "chain-reply-to!" => \$chain_reply_to,
 217                     "smtp-server=s" => \$smtp_server,
 218                     "smtp-server-port=s" => \$smtp_server_port,
 219                     "smtp-user=s" => \$smtp_authuser,
 220                     "smtp-pass:s" => \$smtp_authpass,
 221                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 222                     "smtp-encryption=s" => \$smtp_encryption,
 223                     "identity=s" => \$identity,
 224                     "compose" => \$compose,
 225                     "quiet" => \$quiet,
 226                     "cc-cmd=s" => \$cc_cmd,
 227                     "suppress-from!" => \$suppress_from,
 228                     "suppress-cc=s" => \@suppress_cc,
 229                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 230                     "dry-run" => \$dry_run,
 231                     "envelope-sender=s" => \$envelope_sender,
 232                     "thread!" => \$thread,
 233                     "validate!" => \$validate,
 234          );
 235
 236 unless ($rc) {
 237     usage();
 238 }
 239
 240 # Now, let's fill any that aren't set in with defaults:
 241
 242 sub read_config {
 243         my ($prefix) = @_;
 244
 245         foreach my $setting (keys %config_bool_settings) {
 246                 my $target = $config_bool_settings{$setting}->[0];
 247                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 248         }
 249
 250         foreach my $setting (keys %config_settings) {
 251                 my $target = $config_settings{$setting};
 252                 if (ref($target) eq "ARRAY") {
 253                         unless (@$target) {
 254                                 my @values = Git::config(@repo, "$prefix.$setting");
 255                                 @$target = @values if (@values && defined $values[0]);
 256                         }
 257                 }
 258                 else {
 259                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 260                 }
 261         }
 262
 263         if (!defined $smtp_encryption) {
 264                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 265                 if (defined $enc) {
 266                         $smtp_encryption = $enc;
 267                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 268                         $smtp_encryption = 'ssl';
 269                 }
 270         }
 271 }
 272
 273 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 274 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 275 read_config("sendemail.$identity") if (defined $identity);
 276 read_config("sendemail");
 277
 278 # fall back on builtin bool defaults
 279 foreach my $setting (values %config_bool_settings) {
 280         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 281 }
 282
 283 # 'default' encryption is none -- this only prevents a warning
 284 $smtp_encryption = '' unless (defined $smtp_encryption);
 285
 286 # Set CC suppressions
 287 my(%suppress_cc);
 288 if (@suppress_cc) {
 289         foreach my $entry (@suppress_cc) {
 290                 die "Unknown --suppress-cc field: '$entry'\n"
 291                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 292                 $suppress_cc{$entry} = 1;
 293         }
 294 }
 295
 296 if ($suppress_cc{'all'}) {
 297         foreach my $entry (qw (ccmd cc author self sob)) {
 298                 $suppress_cc{$entry} = 1;
 299         }
 300         delete $suppress_cc{'all'};
 301 }
 302
 303 # If explicit old-style ones are specified, they trump --suppress-cc.
 304 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 305 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 306
 307 # Debugging, print out the suppressions.
 308 if (0) {
 309         print "suppressions:\n";
 310         foreach my $entry (keys %suppress_cc) {
 311                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 312         }
 313 }
 314
 315 my ($repoauthor, $repocommitter);
 316 ($repoauthor) = Git::ident_person(@repo, 'author');
 317 ($repocommitter) = Git::ident_person(@repo, 'committer');
 318
 319 # Verify the user input
 320
 321 foreach my $entry (@to) {
 322         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 323 }
 324
 325 foreach my $entry (@initial_cc) {
 326         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 327 }
 328
 329 foreach my $entry (@bcclist) {
 330         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 331 }
 332
 333 my %aliases;
 334 my %parse_alias = (
 335         # multiline formats can be supported in the future
 336         mutt => sub { my $fh = shift; while (<$fh>) {
 337                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 338                         my ($alias, $addr) = ($1, $2);
 339                         $addr =~ s/#.*$//; # mutt allows # comments
 340                          # commas delimit multiple addresses
 341                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 342                 }}},
 343         mailrc => sub { my $fh = shift; while (<$fh>) {
 344                 if (/^alias\s+(\S+)\s+(.*)$/) {
 345                         # spaces delimit multiple addresses
 346                         $aliases{$1} = [ split(/\s+/, $2) ];
 347                 }}},
 348         pine => sub { my $fh = shift; while (<$fh>) {
 349                 if (/^(\S+)\t.*\t(.*)$/) {
 350                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 351                 }}},
 352         gnus => sub { my $fh = shift; while (<$fh>) {
 353                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 354                         $aliases{$1} = [ $2 ];
 355                 }}}
 356 );
 357
 358 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 359         foreach my $file (@alias_files) {
 360                 open my $fh, '<', $file or die "opening $file: $!\n";
 361                 $parse_alias{$aliasfiletype}->($fh);
 362                 close $fh;
 363         }
 364 }
 365
 366 ($sender) = expand_aliases($sender) if defined $sender;
 367
 368 # Now that all the defaults are set, process the rest of the command line
 369 # arguments and collect up the files that need to be processed.
 370 for my $f (@ARGV) {
 371         if (-d $f) {
 372                 opendir(DH,$f)
 373                         or die "Failed to opendir $f: $!";
 374
 375                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 376                                 sort readdir(DH);
 377                 closedir(DH);
 378         } elsif (-f $f or -p $f) {
 379                 push @files, $f;
 380         } else {
 381                 print STDERR "Skipping $f - not found.\n";
 382         }
 383 }
 384
 385 if ($validate) {
 386         foreach my $f (@files) {
 387                 unless (-p $f) {
 388                         my $error = validate_patch($f);
 389                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 390                 }
 391         }
 392 }
 393
 394 if (@files) {
 395         unless ($quiet) {
 396                 print $_,"\n" for (@files);
 397         }
 398 } else {
 399         print STDERR "\nNo patch files specified!\n\n";
 400         usage();
 401 }
 402
 403 my $prompting = 0;
 404 if (!defined $sender) {
 405         $sender = $repoauthor || $repocommitter || '';
 406
 407         while (1) {
 408                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 409                 last if defined $_;
 410                 print "\n";
 411         }
 412
 413         $sender = $_ if ($_);
 414         print "Emails will be sent from: ", $sender, "\n";
 415         $prompting++;
 416 }
 417
 418 if (!@to) {
 419
 420
 421         while (1) {
 422                 $_ = $term->readline("Who should the emails be sent to? ", "");
 423                 last if defined $_;
 424                 print "\n";
 425         }
 426
 427         my $to = $_;
 428         push @to, split /,\s*/, $to;
 429         $prompting++;
 430 }
 431
 432 sub expand_aliases {
 433         my @cur = @_;
 434         my @last;
 435         do {
 436                 @last = @cur;
 437                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 438         } while (join(',',@cur) ne join(',',@last));
 439         return @cur;
 440 }
 441
 442 @to = expand_aliases(@to);
 443 @to = (map { sanitize_address($_) } @to);
 444 @initial_cc = expand_aliases(@initial_cc);
 445 @bcclist = expand_aliases(@bcclist);
 446
 447 if (!defined $initial_subject && $compose) {
 448         while (1) {
 449                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 450                 last if defined $_;
 451                 print "\n";
 452         }
 453
 454         $initial_subject = $_;
 455         $prompting++;
 456 }
 457
 458 if ($thread && !defined $initial_reply_to && $prompting) {
 459         while (1) {
 460                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 461                 last if defined $_;
 462                 print "\n";
 463         }
 464
 465         $initial_reply_to = $_;
 466 }
 467 if (defined $initial_reply_to) {
 468         $initial_reply_to =~ s/^\s*<?//;
 469         $initial_reply_to =~ s/>?\s*$//;
 470         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 471 }
 472
 473 if (!defined $smtp_server) {
 474         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 475                 if (-x $_) {
 476                         $smtp_server = $_;
 477                         last;
 478                 }
 479         }
 480         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 481 }
 482
 483 if ($compose) {
 484         # Note that this does not need to be secure, but we will make a small
 485         # effort to have it be unique
 486         open(C,">",$compose_filename)
 487                 or die "Failed to open for writing $compose_filename: $!";
 488         print C "From $sender # This line is ignored.\n";
 489         printf C "Subject: %s\n\n", $initial_subject;
 490         printf C <<EOT;
 491 GIT: Please enter your email below.
 492 GIT: Lines beginning in "GIT: " will be removed.
 493 GIT: Consider including an overall diffstat or table of contents
 494 GIT: for the patch you are writing.
 495
 496 EOT
 497         close(C);
 498
 499         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 500         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 501
 502         open(C2,">",$compose_filename . ".final")
 503                 or die "Failed to open $compose_filename.final : " . $!;
 504
 505         open(C,"<",$compose_filename)
 506                 or die "Failed to open $compose_filename : " . $!;
 507
 508         my $need_8bit_cte = file_has_nonascii($compose_filename);
 509         my $in_body = 0;
 510         while(<C>) {
 511                 next if m/^GIT: /;
 512                 if (!$in_body && /^\n$/) {
 513                         $in_body = 1;
 514                         if ($need_8bit_cte) {
 515                                 print C2 "MIME-Version: 1.0\n",
 516                                          "Content-Type: text/plain; ",
 517                                            "charset=utf-8\n",
 518                                          "Content-Transfer-Encoding: 8bit\n";
 519                         }
 520                 }
 521                 if (!$in_body && /^MIME-Version:/i) {
 522                         $need_8bit_cte = 0;
 523                 }
 524                 if (!$in_body && /^Subject: ?(.*)/i) {
 525                         my $subject = $1;
 526                         $_ = "Subject: " .
 527                                 ($subject =~ /[^[:ascii:]]/ ?
 528                                  quote_rfc2047($subject) :
 529                                  $subject) .
 530                                 "\n";
 531                 }
 532                 print C2 $_;
 533         }
 534         close(C);
 535         close(C2);
 536
 537         while (1) {
 538                 $_ = $term->readline("Send this email? (y|n) ");
 539                 last if defined $_;
 540                 print "\n";
 541         }
 542
 543         if (uc substr($_,0,1) ne 'Y') {
 544                 cleanup_compose_files();
 545                 exit(0);
 546         }
 547
 548         @files = ($compose_filename . ".final", @files);
 549 }
 550
 551 # Variables we set as part of the loop over files
 552 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 553
 554 sub extract_valid_address {
 555         my $address = shift;
 556         my $local_part_regexp = '[^<>"\s@]+';
 557         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 558
 559         # check for a local address:
 560         return $address if ($address =~ /^($local_part_regexp)$/);
 561
 562         $address =~ s/^\s*<(.*)>\s*$/$1/;
 563         if ($have_email_valid) {
 564                 return scalar Email::Valid->address($address);
 565         } else {
 566                 # less robust/correct than the monster regexp in Email::Valid,
 567                 # but still does a 99% job, and one less dependency
 568                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 569                 return $1;
 570         }
 571 }
 572
 573 # Usually don't need to change anything below here.
 574
 575 # we make a "fake" message id by taking the current number
 576 # of seconds since the beginning of Unix time and tacking on
 577 # a random number to the end, in case we are called quicker than
 578 # 1 second since the last time we were called.
 579
 580 # We'll setup a template for the message id, using the "from" address:
 581
 582 my ($message_id_stamp, $message_id_serial);
 583 sub make_message_id
 584 {
 585         my $uniq;
 586         if (!defined $message_id_stamp) {
 587                 $message_id_stamp = sprintf("%s-%s", time, $$);
 588                 $message_id_serial = 0;
 589         }
 590         $message_id_serial++;
 591         $uniq = "$message_id_stamp-$message_id_serial";
 592
 593         my $du_part;
 594         for ($sender, $repocommitter, $repoauthor) {
 595                 $du_part = extract_valid_address(sanitize_address($_));
 596                 last if (defined $du_part and $du_part ne '');
 597         }
 598         if (not defined $du_part or $du_part eq '') {
 599                 use Sys::Hostname qw();
 600                 $du_part = 'user@' . Sys::Hostname::hostname();
 601         }
 602         my $message_id_template = "<%s-git-send-email-%s>";
 603         $message_id = sprintf($message_id_template, $uniq, $du_part);
 604         #print "new message id = $message_id\n"; # Was useful for debugging
 605 }
 606
 607
 608
 609 $time = time - scalar $#files;
 610
 611 sub unquote_rfc2047 {
 612         local ($_) = @_;
 613         my $encoding;
 614         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 615                 $encoding = $1;
 616                 s/_/ /g;
 617                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 618         }
 619         return wantarray ? ($_, $encoding) : $_;
 620 }
 621
 622 sub quote_rfc2047 {
 623         local $_ = shift;
 624         my $encoding = shift || 'utf-8';
 625         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 626         s/(.*)/=\?$encoding\?q\?$1\?=/;
 627         return $_;
 628 }
 629
 630 # use the simplest quoting being able to handle the recipient
 631 sub sanitize_address
 632 {
 633         my ($recipient) = @_;
 634         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 635
 636         if (not $recipient_name) {
 637                 return "$recipient";
 638         }
 639
 640         # if recipient_name is already quoted, do nothing
 641         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 642                 return $recipient;
 643         }
 644
 645         # rfc2047 is needed if a non-ascii char is included
 646         if ($recipient_name =~ /[^[:ascii:]]/) {
 647                 $recipient_name = quote_rfc2047($recipient_name);
 648         }
 649
 650         # double quotes are needed if specials or CTLs are included
 651         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 652                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 653                 $recipient_name = "\"$recipient_name\"";
 654         }
 655
 656         return "$recipient_name $recipient_addr";
 657
 658 }
 659
 660 sub send_message
 661 {
 662         my @recipients = unique_email_list(@to);
 663         @cc = (grep { my $cc = extract_valid_address($_);
 664                       not grep { $cc eq $_ } @recipients
 665                     }
 666                map { sanitize_address($_) }
 667                @cc);
 668         my $to = join (",\n\t", @recipients);
 669         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 670         @recipients = (map { extract_valid_address($_) } @recipients);
 671         my $date = format_2822_time($time++);
 672         my $gitversion = '@@GIT_VERSION@@';
 673         if ($gitversion =~ m/..GIT_VERSION../) {
 674             $gitversion = Git::version();
 675         }
 676
 677         my $cc = join(", ", unique_email_list(@cc));
 678         my $ccline = "";
 679         if ($cc ne '') {
 680                 $ccline = "\nCc: $cc";
 681         }
 682         my $sanitized_sender = sanitize_address($sender);
 683         make_message_id() unless defined($message_id);
 684
 685         my $header = "From: $sanitized_sender
 686 To: $to${ccline}
 687 Subject: $subject
 688 Date: $date
 689 Message-Id: $message_id
 690 X-Mailer: git-send-email $gitversion
 691 ";
 692         if ($thread && $reply_to) {
 693
 694                 $header .= "In-Reply-To: $reply_to\n";
 695                 $header .= "References: $references\n";
 696         }
 697         if (@xh) {
 698                 $header .= join("\n", @xh) . "\n";
 699         }
 700
 701         my @sendmail_parameters = ('-i', @recipients);
 702         my $raw_from = $sanitized_sender;
 703         $raw_from = $envelope_sender if (defined $envelope_sender);
 704         $raw_from = extract_valid_address($raw_from);
 705         unshift (@sendmail_parameters,
 706                         '-f', $raw_from) if(defined $envelope_sender);
 707
 708         if ($dry_run) {
 709                 # We don't want to send the email.
 710         } elsif ($smtp_server =~ m#^/#) {
 711                 my $pid = open my $sm, '|-';
 712                 defined $pid or die $!;
 713                 if (!$pid) {
 714                         exec($smtp_server, @sendmail_parameters) or die $!;
 715                 }
 716                 print $sm "$header\n$message";
 717                 close $sm or die $?;
 718         } else {
 719
 720                 if (!defined $smtp_server) {
 721                         die "The required SMTP server is not properly defined."
 722                 }
 723
 724                 if ($smtp_encryption eq 'ssl') {
 725                         $smtp_server_port ||= 465; # ssmtp
 726                         require Net::SMTP::SSL;
 727                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 728                 }
 729                 else {
 730                         require Net::SMTP;
 731                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 732                                                  ? "$smtp_server:$smtp_server_port"
 733                                                  : $smtp_server);
 734                         if ($smtp_encryption eq 'tls') {
 735                                 require Net::SMTP::SSL;
 736                                 $smtp->command('STARTTLS');
 737                                 $smtp->response();
 738                                 if ($smtp->code == 220) {
 739                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 740                                                 or die "STARTTLS failed! ".$smtp->message;
 741                                         $smtp_encryption = '';
 742                                         # Send EHLO again to receive fresh
 743                                         # supported commands
 744                                         $smtp->hello();
 745                                 } else {
 746                                         die "Server does not support STARTTLS! ".$smtp->message;
 747                                 }
 748                         }
 749                 }
 750
 751                 if (!$smtp) {
 752                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 753                 }
 754
 755                 if (defined $smtp_authuser) {
 756
 757                         if (!defined $smtp_authpass) {
 758
 759                                 system "stty -echo";
 760
 761                                 do {
 762                                         print "Password: ";
 763                                         $_ = <STDIN>;
 764                                         print "\n";
 765                                 } while (!defined $_);
 766
 767                                 chomp($smtp_authpass = $_);
 768
 769                                 system "stty echo";
 770                         }
 771
 772                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 773                 }
 774
 775                 $smtp->mail( $raw_from ) or die $smtp->message;
 776                 $smtp->to( @recipients ) or die $smtp->message;
 777                 $smtp->data or die $smtp->message;
 778                 $smtp->datasend("$header\n$message") or die $smtp->message;
 779                 $smtp->dataend() or die $smtp->message;
 780                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 781         }
 782         if ($quiet) {
 783                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 784         } else {
 785                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 786                 if ($smtp_server !~ m#^/#) {
 787                         print "Server: $smtp_server\n";
 788                         print "MAIL FROM:<$raw_from>\n";
 789                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 790                 } else {
 791                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 792                 }
 793                 print $header, "\n";
 794                 if ($smtp) {
 795                         print "Result: ", $smtp->code, ' ',
 796                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 797                 } else {
 798                         print "Result: OK\n";
 799                 }
 800         }
 801 }
 802
 803 $reply_to = $initial_reply_to;
 804 $references = $initial_reply_to || '';
 805 $subject = $initial_subject;
 806
 807 foreach my $t (@files) {
 808         open(F,"<",$t) or die "can't open file $t";
 809
 810         my $author = undef;
 811         my $author_encoding;
 812         my $has_content_type;
 813         my $body_encoding;
 814         @cc = @initial_cc;
 815         @xh = ();
 816         my $input_format = undef;
 817         my $header_done = 0;
 818         $message = "";
 819         while(<F>) {
 820                 if (!$header_done) {
 821                         if (/^From /) {
 822                                 $input_format = 'mbox';
 823                                 next;
 824                         }
 825                         chomp;
 826                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 827                                 $input_format = 'mbox';
 828                         }
 829
 830                         if (defined $input_format && $input_format eq 'mbox') {
 831                                 if (/^Subject:\s+(.*)$/) {
 832                                         $subject = $1;
 833
 834                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 835                                         if (unquote_rfc2047($2) eq $sender) {
 836                                                 next if ($suppress_cc{'self'});
 837                                         }
 838                                         elsif ($1 eq 'From') {
 839                                                 ($author, $author_encoding)
 840                                                   = unquote_rfc2047($2);
 841                                                 next if ($suppress_cc{'author'});
 842                                         } else {
 843                                                 next if ($suppress_cc{'cc'});
 844                                         }
 845                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 846                                                 $2, $_) unless $quiet;
 847                                         push @cc, $2;
 848                                 }
 849                                 elsif (/^Content-type:/i) {
 850                                         $has_content_type = 1;
 851                                         if (/charset="?([^ "]+)/) {
 852                                                 $body_encoding = $1;
 853                                         }
 854                                         push @xh, $_;
 855                                 }
 856                                 elsif (/^Message-Id: (.*)/i) {
 857                                         $message_id = $1;
 858                                 }
 859                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 860                                         push @xh, $_;
 861                                 }
 862
 863                         } else {
 864                                 # In the traditional
 865                                 # "send lots of email" format,
 866                                 # line 1 = cc
 867                                 # line 2 = subject
 868                                 # So let's support that, too.
 869                                 $input_format = 'lots';
 870                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 871                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 872                                                 $_, $_) unless $quiet;
 873
 874                                         push @cc, $_;
 875
 876                                 } elsif (!defined $subject) {
 877                                         $subject = $_;
 878                                 }
 879                         }
 880
 881                         # A whitespace line will terminate the headers
 882                         if (m/^\s*$/) {
 883                                 $header_done = 1;
 884                         }
 885                 } else {
 886                         $message .=  $_;
 887                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 888                                 next if ($suppress_cc{'sob'});
 889                                 chomp;
 890                                 my $c = $2;
 891                                 chomp $c;
 892                                 next if ($c eq $sender and $suppress_cc{'self'});
 893                                 push @cc, $c;
 894                                 printf("(sob) Adding cc: %s from line '%s'\n",
 895                                         $c, $_) unless $quiet;
 896                         }
 897                 }
 898         }
 899         close F;
 900
 901         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 902                 open(F, "$cc_cmd $t |")
 903                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 904                 while(<F>) {
 905                         my $c = $_;
 906                         $c =~ s/^\s*//g;
 907                         $c =~ s/\n$//g;
 908                         next if ($c eq $sender and $suppress_from);
 909                         push @cc, $c;
 910                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 911                                 $c, $cc_cmd) unless $quiet;
 912                 }
 913                 close F
 914                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 915         }
 916
 917         if (defined $author) {
 918                 $message = "From: $author\n\n$message";
 919                 if (defined $author_encoding) {
 920                         if ($has_content_type) {
 921                                 if ($body_encoding eq $author_encoding) {
 922                                         # ok, we already have the right encoding
 923                                 }
 924                                 else {
 925                                         # uh oh, we should re-encode
 926                                 }
 927                         }
 928                         else {
 929                                 push @xh,
 930                                   'MIME-Version: 1.0',
 931                                   "Content-Type: text/plain; charset=$author_encoding",
 932                                   'Content-Transfer-Encoding: 8bit';
 933                         }
 934                 }
 935         }
 936
 937         send_message();
 938
 939         # set up for the next message
 940         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 941                 $reply_to = $message_id;
 942                 if (length $references > 0) {
 943                         $references .= "\n $message_id";
 944                 } else {
 945                         $references = "$message_id";
 946                 }
 947         }
 948         $message_id = undef;
 949 }
 950
 951 if ($compose) {
 952         cleanup_compose_files();
 953 }
 954
 955 sub cleanup_compose_files() {
 956         unlink($compose_filename, $compose_filename . ".final");
 957
 958 }
 959
 960 $smtp->quit if $smtp;
 961
 962 sub unique_email_list(@) {
 963         my %seen;
 964         my @emails;
 965
 966         foreach my $entry (@_) {
 967                 if (my $clean = extract_valid_address($entry)) {
 968                         $seen{$clean} ||= 0;
 969                         next if $seen{$clean}++;
 970                         push @emails, $entry;
 971                 } else {
 972                         print STDERR "W: unable to extract a valid address",
 973                                         " from: $entry\n";
 974                 }
 975         }
 976         return @emails;
 977 }
 978
 979 sub validate_patch {
 980         my $fn = shift;
 981         open(my $fh, '<', $fn)
 982                 or die "unable to open $fn: $!\n";
 983         while (my $line = <$fh>) {
 984                 if (length($line) > 998) {
 985                         return "$.: patch contains a line longer than 998 characters";
 986                 }
 987         }
 988         return undef;
 989 }
 990
 991 sub file_has_nonascii {
 992         my $fn = shift;
 993         open(my $fh, '<', $fn)
 994                 or die "unable to open $fn: $!\n";
 995         while (my $line = <$fh>) {
 996                 return 1 if $line =~ /[^[:ascii:]]/;
 997         }
 998         return 0;
 999 }