git-remote.perl

   1 #!/usr/bin/perl -w
   2
   3 use Git;
   4 my $git = Git->repository();
   5
   6 sub add_remote_config {
   7         my ($hash, $name, $what, $value) = @_;
   8         if ($what eq 'url') {
   9                 if (exists $hash->{$name}{'URL'}) {
  10                         print STDERR "Warning: more than one remote.$name.url\n";
  11                 }
  12                 $hash->{$name}{'URL'} = $value;
  13         }
  14         elsif ($what eq 'fetch') {
  15                 $hash->{$name}{'FETCH'} ||= [];
  16                 push @{$hash->{$name}{'FETCH'}}, $value;
  17         }
  18         elsif ($what eq 'push') {
  19                 $hash->{$name}{'PUSH'} ||= [];
  20                 push @{$hash->{$name}{'PUSH'}}, $value;
  21         }
  22         if (!exists $hash->{$name}{'SOURCE'}) {
  23                 $hash->{$name}{'SOURCE'} = 'config';
  24         }
  25 }
  26
  27 sub add_remote_remotes {
  28         my ($hash, $file, $name) = @_;
  29
  30         if (exists $hash->{$name}) {
  31                 $hash->{$name}{'WARNING'} = 'ignored due to config';
  32                 return;
  33         }
  34
  35         my $fh;
  36         if (!open($fh, '<', $file)) {
  37                 print STDERR "Warning: cannot open $file\n";
  38                 return;
  39         }
  40         my $it = { 'SOURCE' => 'remotes' };
  41         $hash->{$name} = $it;
  42         while (<$fh>) {
  43                 chomp;
  44                 if (/^URL:\s*(.*)$/) {
  45                         # Having more than one is Ok -- it is used for push.
  46                         if (! exists $it->{'URL'}) {
  47                                 $it->{'URL'} = $1;
  48                         }
  49                 }
  50                 elsif (/^Push:\s*(.*)$/) {
  51                         $it->{'PUSH'} ||= [];
  52                         push @{$it->{'PUSH'}}, $1;
  53                 }
  54                 elsif (/^Pull:\s*(.*)$/) {
  55                         $it->{'FETCH'} ||= [];
  56                         push @{$it->{'FETCH'}}, $1;
  57                 }
  58                 elsif (/^\#/) {
  59                         ; # ignore
  60                 }
  61                 else {
  62                         print STDERR "Warning: funny line in $file: $_\n";
  63                 }
  64         }
  65         close($fh);
  66 }
  67
  68 sub list_remote {
  69         my ($git) = @_;
  70         my %seen = ();
  71         my @remotes = eval {
  72                 $git->command(qw(config --get-regexp), '^remote\.');
  73         };
  74         for (@remotes) {
  75                 if (/^remote\.(\S+?)\.([^.\s]+)\s+(.*)$/) {
  76                         add_remote_config(\%seen, $1, $2, $3);
  77                 }
  78         }
  79
  80         my $dir = $git->repo_path() . "/remotes";
  81         if (opendir(my $dh, $dir)) {
  82                 local $_;
  83                 while ($_ = readdir($dh)) {
  84                         chomp;
  85                         next if (! -f "$dir/$_" || ! -r _);
  86                         add_remote_remotes(\%seen, "$dir/$_", $_);
  87                 }
  88         }
  89
  90         return \%seen;
  91 }
  92
  93 sub add_branch_config {
  94         my ($hash, $name, $what, $value) = @_;
  95         if ($what eq 'remote') {
  96                 if (exists $hash->{$name}{'REMOTE'}) {
  97                         print STDERR "Warning: more than one branch.$name.remote\n";
  98                 }
  99                 $hash->{$name}{'REMOTE'} = $value;
 100         }
 101         elsif ($what eq 'merge') {
 102                 $hash->{$name}{'MERGE'} ||= [];
 103                 push @{$hash->{$name}{'MERGE'}}, $value;
 104         }
 105 }
 106
 107 sub list_branch {
 108         my ($git) = @_;
 109         my %seen = ();
 110         my @branches = eval {
 111                 $git->command(qw(config --get-regexp), '^branch\.');
 112         };
 113         for (@branches) {
 114                 if (/^branch\.([^.]*)\.(\S*)\s+(.*)$/) {
 115                         add_branch_config(\%seen, $1, $2, $3);
 116                 }
 117         }
 118
 119         return \%seen;
 120 }
 121
 122 my $remote = list_remote($git);
 123 my $branch = list_branch($git);
 124
 125 sub update_ls_remote {
 126         my ($harder, $info) = @_;
 127
 128         return if (($harder == 0) ||
 129                    (($harder == 1) && exists $info->{'LS_REMOTE'}));
 130
 131         my @ref = map {
 132                 s|^[0-9a-f]{40}\s+refs/heads/||;
 133                 $_;
 134         } $git->command(qw(ls-remote --heads), $info->{'URL'});
 135         $info->{'LS_REMOTE'} = \@ref;
 136 }
 137
 138 sub list_wildcard_mapping {
 139         my ($forced, $ours, $ls) = @_;
 140         my %refs;
 141         for (@$ls) {
 142                 $refs{$_} = 01; # bit #0 to say "they have"
 143         }
 144         for ($git->command('for-each-ref', "refs/remotes/$ours")) {
 145                 chomp;
 146                 next unless (s|^[0-9a-f]{40}\s[a-z]+\srefs/remotes/$ours/||);
 147                 next if ($_ eq 'HEAD');
 148                 $refs{$_} ||= 0;
 149                 $refs{$_} |= 02; # bit #1 to say "we have"
 150         }
 151         my (@new, @stale, @tracked);
 152         for (sort keys %refs) {
 153                 my $have = $refs{$_};
 154                 if ($have == 1) {
 155                         push @new, $_;
 156                 }
 157                 elsif ($have == 2) {
 158                         push @stale, $_;
 159                 }
 160                 elsif ($have == 3) {
 161                         push @tracked, $_;
 162                 }
 163         }
 164         return \@new, \@stale, \@tracked;
 165 }
 166
 167 sub list_mapping {
 168         my ($name, $info) = @_;
 169         my $fetch = $info->{'FETCH'};
 170         my $ls = $info->{'LS_REMOTE'};
 171         my (@new, @stale, @tracked);
 172
 173         for (@$fetch) {
 174                 next unless (/(\+)?([^:]+):(.*)/);
 175                 my ($forced, $theirs, $ours) = ($1, $2, $3);
 176                 if ($theirs eq 'refs/heads/*' &&
 177                     $ours =~ /^refs\/remotes\/(.*)\/\*$/) {
 178                         # wildcard mapping
 179                         my ($w_new, $w_stale, $w_tracked)
 180                                 = list_wildcard_mapping($forced, $1, $ls);
 181                         push @new, @$w_new;
 182                         push @stale, @$w_stale;
 183                         push @tracked, @$w_tracked;
 184                 }
 185                 elsif ($theirs =~ /\*/ || $ours =~ /\*/) {
 186                         print STDERR "Warning: unrecognized mapping in remotes.$name.fetch: $_\n";
 187                 }
 188                 elsif ($theirs =~ s|^refs/heads/||) {
 189                         if (!grep { $_ eq $theirs } @$ls) {
 190                                 push @stale, $theirs;
 191                         }
 192                         elsif ($ours ne '') {
 193                                 push @tracked, $theirs;
 194                         }
 195                 }
 196         }
 197         return \@new, \@stale, \@tracked;
 198 }
 199
 200 sub show_mapping {
 201         my ($name, $info) = @_;
 202         my ($new, $stale, $tracked) = list_mapping($name, $info);
 203         if (@$new) {
 204                 print "  New remote branches (next fetch will store in remotes/$name)\n";
 205                 print "    @$new\n";
 206         }
 207         if (@$stale) {
 208                 print "  Stale tracking branches in remotes/$name (use 'git remote prune')\n";
 209                 print "    @$stale\n";
 210         }
 211         if (@$tracked) {
 212                 print "  Tracked remote branches\n";
 213                 print "    @$tracked\n";
 214         }
 215 }
 216
 217 sub prune_remote {
 218         my ($name, $ls_remote) = @_;
 219         if (!exists $remote->{$name}) {
 220                 print STDERR "No such remote $name\n";
 221                 return 1;
 222         }
 223         my $info = $remote->{$name};
 224         update_ls_remote($ls_remote, $info);
 225
 226         my ($new, $stale, $tracked) = list_mapping($name, $info);
 227         my $prefix = "refs/remotes/$name";
 228         foreach my $to_prune (@$stale) {
 229                 my @v = $git->command(qw(rev-parse --verify), "$prefix/$to_prune");
 230                 $git->command(qw(update-ref -d), "$prefix/$to_prune", $v[0]);
 231         }
 232         return 0;
 233 }
 234
 235 sub show_remote {
 236         my ($name, $ls_remote) = @_;
 237         if (!exists $remote->{$name}) {
 238                 print STDERR "No such remote $name\n";
 239                 return 1;
 240         }
 241         my $info = $remote->{$name};
 242         update_ls_remote($ls_remote, $info);
 243
 244         print "* remote $name\n";
 245         print "  URL: $info->{'URL'}\n";
 246         for my $branchname (sort keys %$branch) {
 247                 next unless (defined $branch->{$branchname}{'REMOTE'} &&
 248                              $branch->{$branchname}{'REMOTE'} eq $name);
 249                 my @merged = map {
 250                         s|^refs/heads/||;
 251                         $_;
 252                 } split(' ',"@{$branch->{$branchname}{'MERGE'}}");
 253                 next unless (@merged);
 254                 print "  Remote branch(es) merged with 'git pull' while on branch $branchname\n";
 255                 print "    @merged\n";
 256         }
 257         if ($info->{'LS_REMOTE'}) {
 258                 show_mapping($name, $info);
 259         }
 260         if ($info->{'PUSH'}) {
 261                 my @pushed = map {
 262                         s|^refs/heads/||;
 263                         s|^\+refs/heads/|+|;
 264                         s|:refs/heads/|:|;
 265                         $_;
 266                 } @{$info->{'PUSH'}};
 267                 print "  Local branch(es) pushed with 'git push'\n";
 268                 print "    @pushed\n";
 269         }
 270         return 0;
 271 }
 272
 273 sub add_remote {
 274         my ($name, $url, $opts) = @_;
 275         if (exists $remote->{$name}) {
 276                 print STDERR "remote $name already exists.\n";
 277                 exit(1);
 278         }
 279         $git->command('config', "remote.$name.url", $url);
 280         my $track = $opts->{'track'} || ["*"];
 281
 282         for (@$track) {
 283                 $git->command('config', '--add', "remote.$name.fetch",
 284                               "+refs/heads/$_:refs/remotes/$name/$_");
 285         }
 286         if ($opts->{'fetch'}) {
 287                 $git->command('fetch', $name);
 288         }
 289         if (exists $opts->{'master'}) {
 290                 $git->command('symbolic-ref', "refs/remotes/$name/HEAD",
 291                               "refs/remotes/$name/$opts->{'master'}");
 292         }
 293 }
 294
 295 sub update_remote {
 296         my ($name) = @_;
 297
 298         my $conf = $git->config("remotes." . $name);
 299         if (defined($conf)) {
 300                 @remotes = split(' ', $conf);
 301         } elsif ($name eq 'default') {
 302                 undef @remotes;
 303                 for (sort keys %$remote) {
 304                         my $do_fetch = $git->config_bool("remote." . $_ .
 305                                                     ".skipDefaultUpdate");
 306                         unless ($do_fetch) {
 307                                 push @remotes, $_;
 308                         }
 309                 }
 310         } else {
 311                 print STDERR "Remote group $name does not exists.\n";
 312                 exit(1);
 313         }
 314         for (@remotes) {
 315                 print "Updating $_\n";
 316                 $git->command('fetch', "$_");
 317         }
 318 }
 319
 320 sub add_usage {
 321         print STDERR "Usage: git remote add [-f] [-t track]* [-m master] <name> <url>\n";
 322         exit(1);
 323 }
 324
 325 local $VERBOSE = 0;
 326 @ARGV = grep {
 327         if ($_ eq '-v' or $_ eq '--verbose') {
 328                 $VERBOSE=1;
 329                 0
 330         } else {
 331                 1
 332         }
 333 } @ARGV;
 334
 335 if (!@ARGV) {
 336         for (sort keys %$remote) {
 337                 print "$_";
 338                 print "\t$remote->{$_}->{URL}" if $VERBOSE;
 339                 print "\n";
 340         }
 341 }
 342 elsif ($ARGV[0] eq 'show') {
 343         my $ls_remote = 1;
 344         my $i;
 345         for ($i = 1; $i < @ARGV; $i++) {
 346                 if ($ARGV[$i] eq '-n') {
 347                         $ls_remote = 0;
 348                 }
 349                 else {
 350                         last;
 351                 }
 352         }
 353         if ($i >= @ARGV) {
 354                 print STDERR "Usage: git remote show <remote>\n";
 355                 exit(1);
 356         }
 357         my $status = 0;
 358         for (; $i < @ARGV; $i++) {
 359                 $status |= show_remote($ARGV[$i], $ls_remote);
 360         }
 361         exit($status);
 362 }
 363 elsif ($ARGV[0] eq 'update') {
 364         if (@ARGV <= 1) {
 365                 update_remote("default");
 366                 exit(1);
 367         }
 368         for ($i = 1; $i < @ARGV; $i++) {
 369                 update_remote($ARGV[$i]);
 370         }
 371 }
 372 elsif ($ARGV[0] eq 'prune') {
 373         my $ls_remote = 1;
 374         my $i;
 375         for ($i = 1; $i < @ARGV; $i++) {
 376                 if ($ARGV[$i] eq '-n') {
 377                         $ls_remote = 0;
 378                 }
 379                 else {
 380                         last;
 381                 }
 382         }
 383         if ($i >= @ARGV) {
 384                 print STDERR "Usage: git remote prune <remote>\n";
 385                 exit(1);
 386         }
 387         my $status = 0;
 388         for (; $i < @ARGV; $i++) {
 389                 $status |= prune_remote($ARGV[$i], $ls_remote);
 390         }
 391         exit($status);
 392 }
 393 elsif ($ARGV[0] eq 'add') {
 394         my %opts = ();
 395         while (1 < @ARGV && $ARGV[1] =~ /^-/) {
 396                 my $opt = $ARGV[1];
 397                 shift @ARGV;
 398                 if ($opt eq '-f' || $opt eq '--fetch') {
 399                         $opts{'fetch'} = 1;
 400                         next;
 401                 }
 402                 if ($opt eq '-t' || $opt eq '--track') {
 403                         if (@ARGV < 1) {
 404                                 add_usage();
 405                         }
 406                         $opts{'track'} ||= [];
 407                         push @{$opts{'track'}}, $ARGV[1];
 408                         shift @ARGV;
 409                         next;
 410                 }
 411                 if ($opt eq '-m' || $opt eq '--master') {
 412                         if ((@ARGV < 1) || exists $opts{'master'}) {
 413                                 add_usage();
 414                         }
 415                         $opts{'master'} = $ARGV[1];
 416                         shift @ARGV;
 417                         next;
 418                 }
 419                 add_usage();
 420         }
 421         if (@ARGV != 3) {
 422                 add_usage();
 423         }
 424         add_remote($ARGV[1], $ARGV[2], \%opts);
 425 }
 426 else {
 427         print STDERR "Usage: git remote\n";
 428         print STDERR "       git remote add <name> <url>\n";
 429         print STDERR "       git remote show <name>\n";
 430         print STDERR "       git remote prune <name>\n";
 431         print STDERR "       git remote update [group]\n";
 432         exit(1);
 433 }