lib/choose_repository.tcl

   1 # git-gui Git repository chooser
   2 # Copyright (C) 2007 Shawn Pearce
   3
   4 class choose_repository {
   5
   6 field top
   7 field w
   8 field w_body      ; # Widget holding the center content
   9 field w_next      ; # Next button
  10 field w_quit      ; # Quit button
  11 field o_cons      ; # Console object (if active)
  12 field w_types     ; # List of type buttons in clone
  13 field w_recentlist ; # Listbox containing recent repositories
  14
  15 field done              0 ; # Finished picking the repository?
  16 field local_path       {} ; # Where this repository is locally
  17 field origin_url       {} ; # Where we are cloning from
  18 field origin_name  origin ; # What we shall call 'origin'
  19 field clone_type hardlink ; # Type of clone to construct
  20 field readtree_err        ; # Error output from read-tree (if any)
  21 field sorted_recent       ; # recent repositories (sorted)
  22
  23 constructor pick {} {
  24         global M1T M1B
  25
  26         make_toplevel top w
  27         wm title $top [mc "Git Gui"]
  28
  29         if {$top eq {.}} {
  30                 menu $w.mbar -tearoff 0
  31                 $top configure -menu $w.mbar
  32
  33                 set m_repo $w.mbar.repository
  34                 $w.mbar add cascade \
  35                         -label [mc Repository] \
  36                         -menu $m_repo
  37                 menu $m_repo
  38
  39                 if {[is_MacOSX]} {
  40                         $w.mbar add cascade -label [mc Apple] -menu .mbar.apple
  41                         menu $w.mbar.apple
  42                         $w.mbar.apple add command \
  43                                 -label [mc "About %s" [appname]] \
  44                                 -command do_about
  45                 } else {
  46                         $w.mbar add cascade -label [mc Help] -menu $w.mbar.help
  47                         menu $w.mbar.help
  48                         $w.mbar.help add command \
  49                                 -label [mc "About %s" [appname]] \
  50                                 -command do_about
  51                 }
  52
  53                 wm protocol $top WM_DELETE_WINDOW exit
  54                 bind $top <$M1B-q> exit
  55                 bind $top <$M1B-Q> exit
  56                 bind $top <Key-Escape> exit
  57         } else {
  58                 wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
  59                 bind $top <Key-Escape> [list destroy $top]
  60                 set m_repo {}
  61         }
  62
  63         pack [git_logo $w.git_logo] -side left -fill y -padx 10 -pady 10
  64
  65         set w_body $w.body
  66         set opts $w_body.options
  67         frame $w_body
  68         text $opts \
  69                 -cursor $::cursor_ptr \
  70                 -relief flat \
  71                 -background [$w_body cget -background] \
  72                 -wrap none \
  73                 -spacing1 5 \
  74                 -width 50 \
  75                 -height 3
  76         pack $opts -anchor w -fill x
  77
  78         $opts tag conf link_new -foreground blue -underline 1
  79         $opts tag bind link_new <1> [cb _next new]
  80         $opts insert end [mc "Create New Repository"] link_new
  81         $opts insert end "\n"
  82         if {$m_repo ne {}} {
  83                 $m_repo add command \
  84                         -command [cb _next new] \
  85                         -accelerator $M1T-N \
  86                         -label [mc "New..."]
  87                 bind $top <$M1B-n> [cb _next new]
  88                 bind $top <$M1B-N> [cb _next new]
  89         }
  90
  91         $opts tag conf link_clone -foreground blue -underline 1
  92         $opts tag bind link_clone <1> [cb _next clone]
  93         $opts insert end [mc "Clone Existing Repository"] link_clone
  94         $opts insert end "\n"
  95         if {$m_repo ne {}} {
  96                 $m_repo add command \
  97                         -command [cb _next clone] \
  98                         -accelerator $M1T-C \
  99                         -label [mc "Clone..."]
 100                 bind $top <$M1B-c> [cb _next clone]
 101                 bind $top <$M1B-C> [cb _next clone]
 102         }
 103
 104         $opts tag conf link_open -foreground blue -underline 1
 105         $opts tag bind link_open <1> [cb _next open]
 106         $opts insert end [mc "Open Existing Repository"] link_open
 107         $opts insert end "\n"
 108         if {$m_repo ne {}} {
 109                 $m_repo add command \
 110                         -command [cb _next open] \
 111                         -accelerator $M1T-O \
 112                         -label [mc "Open..."]
 113                 bind $top <$M1B-o> [cb _next open]
 114                 bind $top <$M1B-O> [cb _next open]
 115         }
 116
 117         $opts conf -state disabled
 118
 119         set sorted_recent [_get_recentrepos]
 120         if {[llength $sorted_recent] > 0} {
 121                 if {$m_repo ne {}} {
 122                         $m_repo add separator
 123                         $m_repo add command \
 124                                 -state disabled \
 125                                 -label [mc "Recent Repositories"]
 126                 }
 127
 128                 label $w_body.space
 129                 label $w_body.recentlabel \
 130                         -anchor w \
 131                         -text [mc "Open Recent Repository:"]
 132                 set w_recentlist $w_body.recentlist
 133                 text $w_recentlist \
 134                         -cursor $::cursor_ptr \
 135                         -relief flat \
 136                         -background [$w_body.recentlabel cget -background] \
 137                         -wrap none \
 138                         -width 50 \
 139                         -height 10
 140                 $w_recentlist tag conf link \
 141                         -foreground blue \
 142                         -underline 1
 143                 set home "[file normalize $::env(HOME)][file separator]"
 144                 set hlen [string length $home]
 145                 foreach p $sorted_recent {
 146                         set path $p
 147                         if {[string equal -length $hlen $home $p]} {
 148                                 set p "~[file separator][string range $p $hlen end]"
 149                         }
 150                         regsub -all "\n" $p "\\n" p
 151                         $w_recentlist insert end $p link
 152                         $w_recentlist insert end "\n"
 153
 154                         if {$m_repo ne {}} {
 155                                 $m_repo add command \
 156                                         -command [cb _open_recent_path $path] \
 157                                         -label "    $p"
 158                         }
 159                 }
 160                 $w_recentlist conf -state disabled
 161                 $w_recentlist tag bind link <1> [cb _open_recent %x,%y]
 162                 pack $w_body.space -anchor w -fill x
 163                 pack $w_body.recentlabel -anchor w -fill x
 164                 pack $w_recentlist -anchor w -fill x
 165         }
 166         pack $w_body -fill x -padx 10 -pady 10
 167
 168         frame $w.buttons
 169         set w_next $w.buttons.next
 170         set w_quit $w.buttons.quit
 171         button $w_quit \
 172                 -text [mc "Quit"] \
 173                 -command exit
 174         pack $w_quit -side right -padx 5
 175         pack $w.buttons -side bottom -fill x -padx 10 -pady 10
 176
 177         if {$m_repo ne {}} {
 178                 $m_repo add separator
 179                 $m_repo add command \
 180                         -label [mc Quit] \
 181                         -command exit \
 182                         -accelerator $M1T-Q
 183         }
 184
 185         bind $top <Return> [cb _invoke_next]
 186         bind $top <Visibility> "
 187                 [cb _center]
 188                 grab $top
 189                 focus $top
 190                 bind $top <Visibility> {}
 191         "
 192         wm deiconify $top
 193         tkwait variable @done
 194
 195         if {$top eq {.}} {
 196                 eval destroy [winfo children $top]
 197         }
 198 }
 199
 200 proc _home {} {
 201         if {[catch {set h $::env(HOME)}]
 202                 || ![file isdirectory $h]} {
 203                 set h .
 204         }
 205         return $h
 206 }
 207
 208 method _center {} {
 209         set nx [winfo reqwidth $top]
 210         set ny [winfo reqheight $top]
 211         set rx [expr {([winfo screenwidth  $top] - $nx) / 3}]
 212         set ry [expr {([winfo screenheight $top] - $ny) / 3}]
 213         wm geometry $top [format {+%d+%d} $rx $ry]
 214 }
 215
 216 method _invoke_next {} {
 217         if {[winfo exists $w_next]} {
 218                 uplevel #0 [$w_next cget -command]
 219         }
 220 }
 221
 222 proc _get_recentrepos {} {
 223         set recent [list]
 224         foreach p [get_config gui.recentrepo] {
 225                 if {[_is_git [file join $p .git]]} {
 226                         lappend recent $p
 227                 }
 228         }
 229         return [lsort $recent]
 230 }
 231
 232 proc _unset_recentrepo {p} {
 233         regsub -all -- {([()\[\]{}\.^$+*?\\])} $p {\\\1} p
 234         git config --global --unset gui.recentrepo "^$p\$"
 235 }
 236
 237 proc _append_recentrepos {path} {
 238         set path [file normalize $path]
 239         set recent [get_config gui.recentrepo]
 240
 241         if {[lindex $recent end] eq $path} {
 242                 return
 243         }
 244
 245         set i [lsearch $recent $path]
 246         if {$i >= 0} {
 247                 _unset_recentrepo $path
 248                 set recent [lreplace $recent $i $i]
 249         }
 250
 251         lappend recent $path
 252         git config --global --add gui.recentrepo $path
 253
 254         while {[llength $recent] > 10} {
 255                 _unset_recentrepo [lindex $recent 0]
 256                 set recent [lrange $recent 1 end]
 257         }
 258 }
 259
 260 method _open_recent {xy} {
 261         set id [lindex [split [$w_recentlist index @$xy] .] 0]
 262         set local_path [lindex $sorted_recent [expr {$id - 1}]]
 263         _do_open2 $this
 264 }
 265
 266 method _open_recent_path {p} {
 267         set local_path $p
 268         _do_open2 $this
 269 }
 270
 271 method _next {action} {
 272         destroy $w_body
 273         if {![winfo exists $w_next]} {
 274                 button $w_next -default active
 275                 pack $w_next -side right -padx 5 -before $w_quit
 276         }
 277         _do_$action $this
 278 }
 279
 280 method _write_local_path {args} {
 281         if {$local_path eq {}} {
 282                 $w_next conf -state disabled
 283         } else {
 284                 $w_next conf -state normal
 285         }
 286 }
 287
 288 method _git_init {} {
 289         if {[file exists $local_path]} {
 290                 error_popup [mc "Location %s already exists." $local_path]
 291                 return 0
 292         }
 293
 294         if {[catch {file mkdir $local_path} err]} {
 295                 error_popup [strcat \
 296                         [mc "Failed to create repository %s:" $local_path] \
 297                         "\n\n$err"]
 298                 return 0
 299         }
 300
 301         if {[catch {cd $local_path} err]} {
 302                 error_popup [strcat \
 303                         [mc "Failed to create repository %s:" $local_path] \
 304                         "\n\n$err"]
 305                 return 0
 306         }
 307
 308         if {[catch {git init} err]} {
 309                 error_popup [strcat \
 310                         [mc "Failed to create repository %s:" $local_path] \
 311                         "\n\n$err"]
 312                 return 0
 313         }
 314
 315         _append_recentrepos [pwd]
 316         set ::_gitdir .git
 317         set ::_prefix {}
 318         return 1
 319 }
 320
 321 proc _is_git {path} {
 322         if {[file exists [file join $path HEAD]]
 323          && [file exists [file join $path objects]]
 324          && [file exists [file join $path config]]} {
 325                 return 1
 326         }
 327         if {[is_Cygwin]} {
 328                 if {[file exists [file join $path HEAD]]
 329                  && [file exists [file join $path objects.lnk]]
 330                  && [file exists [file join $path config.lnk]]} {
 331                         return 1
 332                 }
 333         }
 334         return 0
 335 }
 336
 337 proc _objdir {path} {
 338         set objdir [file join $path .git objects]
 339         if {[file isdirectory $objdir]} {
 340                 return $objdir
 341         }
 342
 343         set objdir [file join $path objects]
 344         if {[file isdirectory $objdir]} {
 345                 return $objdir
 346         }
 347
 348         if {[is_Cygwin]} {
 349                 set objdir [file join $path .git objects.lnk]
 350                 if {[file isfile $objdir]} {
 351                         return [win32_read_lnk $objdir]
 352                 }
 353
 354                 set objdir [file join $path objects.lnk]
 355                 if {[file isfile $objdir]} {
 356                         return [win32_read_lnk $objdir]
 357                 }
 358         }
 359
 360         return {}
 361 }
 362
 363 ######################################################################
 364 ##
 365 ## Create New Repository
 366
 367 method _do_new {} {
 368         $w_next conf \
 369                 -state disabled \
 370                 -command [cb _do_new2] \
 371                 -text [mc "Create"]
 372
 373         frame $w_body
 374         label $w_body.h \
 375                 -font font_uibold \
 376                 -text [mc "Create New Repository"]
 377         pack $w_body.h -side top -fill x -pady 10
 378         pack $w_body -fill x -padx 10
 379
 380         frame $w_body.where
 381         label $w_body.where.l -text [mc "Directory:"]
 382         entry $w_body.where.t \
 383                 -textvariable @local_path \
 384                 -font font_diff \
 385                 -width 50
 386         button $w_body.where.b \
 387                 -text [mc "Browse"] \
 388                 -command [cb _new_local_path]
 389
 390         pack $w_body.where.b -side right
 391         pack $w_body.where.l -side left
 392         pack $w_body.where.t -fill x
 393         pack $w_body.where -fill x
 394
 395         trace add variable @local_path write [cb _write_local_path]
 396         bind $w_body.h <Destroy> [list trace remove variable @local_path write [cb _write_local_path]]
 397         update
 398         focus $w_body.where.t
 399 }
 400
 401 method _new_local_path {} {
 402         if {$local_path ne {}} {
 403                 set p [file dirname $local_path]
 404         } else {
 405                 set p [_home]
 406         }
 407
 408         set p [tk_chooseDirectory \
 409                 -initialdir $p \
 410                 -parent $top \
 411                 -title [mc "Git Repository"] \
 412                 -mustexist false]
 413         if {$p eq {}} return
 414
 415         set p [file normalize $p]
 416         if {[file isdirectory $p]} {
 417                 foreach i [glob \
 418                         -directory $p \
 419                         -tails \
 420                         -nocomplain \
 421                         * .*] {
 422                         switch -- $i {
 423                          . continue
 424                         .. continue
 425                         default {
 426                                 error_popup [mc "Directory %s already exists." $p]
 427                                 return
 428                         }
 429                         }
 430                 }
 431                 if {[catch {file delete $p} err]} {
 432                         error_popup [strcat \
 433                                 [mc "Directory %s already exists." $p] \
 434                                 "\n\n$err"]
 435                         return
 436                 }
 437         } elseif {[file exists $p]} {
 438                 error_popup [mc "File %s already exists." $p]
 439                 return
 440         }
 441         set local_path $p
 442 }
 443
 444 method _do_new2 {} {
 445         if {![_git_init $this]} {
 446                 return
 447         }
 448         set done 1
 449 }
 450
 451 ######################################################################
 452 ##
 453 ## Clone Existing Repository
 454
 455 method _do_clone {} {
 456         $w_next conf \
 457                 -state disabled \
 458                 -command [cb _do_clone2] \
 459                 -text [mc "Clone"]
 460
 461         frame $w_body
 462         label $w_body.h \
 463                 -font font_uibold \
 464                 -text [mc "Clone Existing Repository"]
 465         pack $w_body.h -side top -fill x -pady 10
 466         pack $w_body -fill x -padx 10
 467
 468         set args $w_body.args
 469         frame $w_body.args
 470         pack $args -fill both
 471
 472         label $args.origin_l -text [mc "URL:"]
 473         entry $args.origin_t \
 474                 -textvariable @origin_url \
 475                 -font font_diff \
 476                 -width 50
 477         button $args.origin_b \
 478                 -text [mc "Browse"] \
 479                 -command [cb _open_origin]
 480         grid $args.origin_l $args.origin_t $args.origin_b -sticky ew
 481
 482         label $args.where_l -text [mc "Directory:"]
 483         entry $args.where_t \
 484                 -textvariable @local_path \
 485                 -font font_diff \
 486                 -width 50
 487         button $args.where_b \
 488                 -text [mc "Browse"] \
 489                 -command [cb _new_local_path]
 490         grid $args.where_l $args.where_t $args.where_b -sticky ew
 491
 492         label $args.type_l -text [mc "Clone Type:"]
 493         frame $args.type_f
 494         set w_types [list]
 495         lappend w_types [radiobutton $args.type_f.hardlink \
 496                 -state disabled \
 497                 -anchor w \
 498                 -text [mc "Standard (Fast, Semi-Redundant, Hardlinks)"] \
 499                 -variable @clone_type \
 500                 -value hardlink]
 501         lappend w_types [radiobutton $args.type_f.full \
 502                 -state disabled \
 503                 -anchor w \
 504                 -text [mc "Full Copy (Slower, Redundant Backup)"] \
 505                 -variable @clone_type \
 506                 -value full]
 507         lappend w_types [radiobutton $args.type_f.shared \
 508                 -state disabled \
 509                 -anchor w \
 510                 -text [mc "Shared (Fastest, Not Recommended, No Backup)"] \
 511                 -variable @clone_type \
 512                 -value shared]
 513         foreach r $w_types {
 514                 pack $r -anchor w
 515         }
 516         grid $args.type_l $args.type_f -sticky new
 517
 518         grid columnconfigure $args 1 -weight 1
 519
 520         trace add variable @local_path write [cb _update_clone]
 521         trace add variable @origin_url write [cb _update_clone]
 522         bind $w_body.h <Destroy> "
 523                 [list trace remove variable @local_path write [cb _update_clone]]
 524                 [list trace remove variable @origin_url write [cb _update_clone]]
 525         "
 526         update
 527         focus $args.origin_t
 528 }
 529
 530 method _open_origin {} {
 531         if {$origin_url ne {} && [file isdirectory $origin_url]} {
 532                 set p $origin_url
 533         } else {
 534                 set p [_home]
 535         }
 536
 537         set p [tk_chooseDirectory \
 538                 -initialdir $p \
 539                 -parent $top \
 540                 -title [mc "Git Repository"] \
 541                 -mustexist true]
 542         if {$p eq {}} return
 543
 544         set p [file normalize $p]
 545         if {![_is_git [file join $p .git]] && ![_is_git $p]} {
 546                 error_popup [mc "Not a Git repository: %s" [file tail $p]]
 547                 return
 548         }
 549         set origin_url $p
 550 }
 551
 552 method _update_clone {args} {
 553         if {$local_path ne {} && $origin_url ne {}} {
 554                 $w_next conf -state normal
 555         } else {
 556                 $w_next conf -state disabled
 557         }
 558
 559         if {$origin_url ne {} &&
 560                 (  [_is_git [file join $origin_url .git]]
 561                 || [_is_git $origin_url])} {
 562                 set e normal
 563                 if {[[lindex $w_types 0] cget -state] eq {disabled}} {
 564                         set clone_type hardlink
 565                 }
 566         } else {
 567                 set e disabled
 568                 set clone_type full
 569         }
 570
 571         foreach r $w_types {
 572                 $r conf -state $e
 573         }
 574 }
 575
 576 method _do_clone2 {} {
 577         if {[file isdirectory $origin_url]} {
 578                 set origin_url [file normalize $origin_url]
 579         }
 580
 581         if {$clone_type eq {hardlink} && ![file isdirectory $origin_url]} {
 582                 error_popup [mc "Standard only available for local repository."]
 583                 return
 584         }
 585         if {$clone_type eq {shared} && ![file isdirectory $origin_url]} {
 586                 error_popup [mc "Shared only available for local repository."]
 587                 return
 588         }
 589
 590         if {$clone_type eq {hardlink} || $clone_type eq {shared}} {
 591                 set objdir [_objdir $origin_url]
 592                 if {$objdir eq {}} {
 593                         error_popup [mc "Not a Git repository: %s" [file tail $origin_url]]
 594                         return
 595                 }
 596         }
 597
 598         set giturl $origin_url
 599         if {[is_Cygwin] && [file isdirectory $giturl]} {
 600                 set giturl [exec cygpath --unix --absolute $giturl]
 601                 if {$clone_type eq {shared}} {
 602                         set objdir [exec cygpath --unix --absolute $objdir]
 603                 }
 604         }
 605
 606         if {![_git_init $this]} return
 607         set local_path [pwd]
 608
 609         if {[catch {
 610                         git config remote.$origin_name.url $giturl
 611                         git config remote.$origin_name.fetch +refs/heads/*:refs/remotes/$origin_name/*
 612                 } err]} {
 613                 error_popup [strcat [mc "Failed to configure origin"] "\n\n$err"]
 614                 return
 615         }
 616
 617         destroy $w_body $w_next
 618
 619         switch -exact -- $clone_type {
 620         hardlink {
 621                 set o_cons [status_bar::two_line $w_body]
 622                 pack $w_body -fill x -padx 10 -pady 10
 623
 624                 $o_cons start \
 625                         [mc "Counting objects"] \
 626                         [mc "buckets"]
 627                 update
 628
 629                 if {[file exists [file join $objdir info alternates]]} {
 630                         set pwd [pwd]
 631                         if {[catch {
 632                                 file mkdir [gitdir objects info]
 633                                 set f_in [open [file join $objdir info alternates] r]
 634                                 set f_cp [open [gitdir objects info alternates] w]
 635                                 fconfigure $f_in -translation binary -encoding binary
 636                                 fconfigure $f_cp -translation binary -encoding binary
 637                                 cd $objdir
 638                                 while {[gets $f_in line] >= 0} {
 639                                         if {[is_Cygwin]} {
 640                                                 puts $f_cp [exec cygpath --unix --absolute $line]
 641                                         } else {
 642                                                 puts $f_cp [file normalize $line]
 643                                         }
 644                                 }
 645                                 close $f_in
 646                                 close $f_cp
 647                                 cd $pwd
 648                         } err]} {
 649                                 catch {cd $pwd}
 650                                 _clone_failed $this [mc "Unable to copy objects/info/alternates: %s" $err]
 651                                 return
 652                         }
 653                 }
 654
 655                 set tolink  [list]
 656                 set buckets [glob \
 657                         -tails \
 658                         -nocomplain \
 659                         -directory [file join $objdir] ??]
 660                 set bcnt [expr {[llength $buckets] + 2}]
 661                 set bcur 1
 662                 $o_cons update $bcur $bcnt
 663                 update
 664
 665                 file mkdir [file join .git objects pack]
 666                 foreach i [glob -tails -nocomplain \
 667                         -directory [file join $objdir pack] *] {
 668                         lappend tolink [file join pack $i]
 669                 }
 670                 $o_cons update [incr bcur] $bcnt
 671                 update
 672
 673                 foreach i $buckets {
 674                         file mkdir [file join .git objects $i]
 675                         foreach j [glob -tails -nocomplain \
 676                                 -directory [file join $objdir $i] *] {
 677                                 lappend tolink [file join $i $j]
 678                         }
 679                         $o_cons update [incr bcur] $bcnt
 680                         update
 681                 }
 682                 $o_cons stop
 683
 684                 if {$tolink eq {}} {
 685                         info_popup [strcat \
 686                                 [mc "Nothing to clone from %s." $origin_url] \
 687                                 "\n" \
 688                                 [mc "The 'master' branch has not been initialized."] \
 689                                 ]
 690                         destroy $w_body
 691                         set done 1
 692                         return
 693                 }
 694
 695                 set i [lindex $tolink 0]
 696                 if {[catch {
 697                                 file link -hard \
 698                                         [file join .git objects $i] \
 699                                         [file join $objdir $i]
 700                         } err]} {
 701                         info_popup [mc "Hardlinks are unavailable.  Falling back to copying."]
 702                         set i [_copy_files $this $objdir $tolink]
 703                 } else {
 704                         set i [_link_files $this $objdir [lrange $tolink 1 end]]
 705                 }
 706                 if {!$i} return
 707
 708                 destroy $w_body
 709         }
 710         full {
 711                 set o_cons [console::embed \
 712                         $w_body \
 713                         [mc "Cloning from %s" $origin_url]]
 714                 pack $w_body -fill both -expand 1 -padx 10
 715                 $o_cons exec \
 716                         [list git fetch --no-tags -k $origin_name] \
 717                         [cb _do_clone_tags]
 718         }
 719         shared {
 720                 set fd [open [gitdir objects info alternates] w]
 721                 fconfigure $fd -translation binary
 722                 puts $fd $objdir
 723                 close $fd
 724         }
 725         }
 726
 727         if {$clone_type eq {hardlink} || $clone_type eq {shared}} {
 728                 if {![_clone_refs $this]} return
 729                 set pwd [pwd]
 730                 if {[catch {
 731                                 cd $origin_url
 732                                 set HEAD [git rev-parse --verify HEAD^0]
 733                         } err]} {
 734                         _clone_failed $this [mc "Not a Git repository: %s" [file tail $origin_url]]
 735                         return 0
 736                 }
 737                 cd $pwd
 738                 _do_clone_checkout $this $HEAD
 739         }
 740 }
 741
 742 method _copy_files {objdir tocopy} {
 743         $o_cons start \
 744                 [mc "Copying objects"] \
 745                 [mc "KiB"]
 746         set tot 0
 747         set cmp 0
 748         foreach p $tocopy {
 749                 incr tot [file size [file join $objdir $p]]
 750         }
 751         foreach p $tocopy {
 752                 if {[catch {
 753                                 set f_in [open [file join $objdir $p] r]
 754                                 set f_cp [open [file join .git objects $p] w]
 755                                 fconfigure $f_in -translation binary -encoding binary
 756                                 fconfigure $f_cp -translation binary -encoding binary
 757
 758                                 while {![eof $f_in]} {
 759                                         incr cmp [fcopy $f_in $f_cp -size 16384]
 760                                         $o_cons update \
 761                                                 [expr {$cmp / 1024}] \
 762                                                 [expr {$tot / 1024}]
 763                                         update
 764                                 }
 765
 766                                 close $f_in
 767                                 close $f_cp
 768                         } err]} {
 769                         _clone_failed $this [mc "Unable to copy object: %s" $err]
 770                         return 0
 771                 }
 772         }
 773         return 1
 774 }
 775
 776 method _link_files {objdir tolink} {
 777         set total [llength $tolink]
 778         $o_cons start \
 779                 [mc "Linking objects"] \
 780                 [mc "objects"]
 781         for {set i 0} {$i < $total} {} {
 782                 set p [lindex $tolink $i]
 783                 if {[catch {
 784                                 file link -hard \
 785                                         [file join .git objects $p] \
 786                                         [file join $objdir $p]
 787                         } err]} {
 788                         _clone_failed $this [mc "Unable to hardlink object: %s" $err]
 789                         return 0
 790                 }
 791
 792                 incr i
 793                 if {$i % 5 == 0} {
 794                         $o_cons update $i $total
 795                         update
 796                 }
 797         }
 798         return 1
 799 }
 800
 801 method _clone_refs {} {
 802         set pwd [pwd]
 803         if {[catch {cd $origin_url} err]} {
 804                 error_popup [mc "Not a Git repository: %s" [file tail $origin_url]]
 805                 return 0
 806         }
 807         set fd_in [git_read for-each-ref \
 808                 --tcl \
 809                 {--format=list %(refname) %(objectname) %(*objectname)}]
 810         cd $pwd
 811
 812         set fd [open [gitdir packed-refs] w]
 813         fconfigure $fd -translation binary
 814         puts $fd "# pack-refs with: peeled"
 815         while {[gets $fd_in line] >= 0} {
 816                 set line [eval $line]
 817                 set refn [lindex $line 0]
 818                 set robj [lindex $line 1]
 819                 set tobj [lindex $line 2]
 820
 821                 if {[regsub ^refs/heads/ $refn \
 822                         "refs/remotes/$origin_name/" refn]} {
 823                         puts $fd "$robj $refn"
 824                 } elseif {[string match refs/tags/* $refn]} {
 825                         puts $fd "$robj $refn"
 826                         if {$tobj ne {}} {
 827                                 puts $fd "^$tobj"
 828                         }
 829                 }
 830         }
 831         close $fd_in
 832         close $fd
 833         return 1
 834 }
 835
 836 method _do_clone_tags {ok} {
 837         if {$ok} {
 838                 $o_cons exec \
 839                         [list git fetch --tags -k $origin_name] \
 840                         [cb _do_clone_HEAD]
 841         } else {
 842                 $o_cons done $ok
 843                 _clone_failed $this [mc "Cannot fetch branches and objects.  See console output for details."]
 844         }
 845 }
 846
 847 method _do_clone_HEAD {ok} {
 848         if {$ok} {
 849                 $o_cons exec \
 850                         [list git fetch $origin_name HEAD] \
 851                         [cb _do_clone_full_end]
 852         } else {
 853                 $o_cons done $ok
 854                 _clone_failed $this [mc "Cannot fetch tags.  See console output for details."]
 855         }
 856 }
 857
 858 method _do_clone_full_end {ok} {
 859         $o_cons done $ok
 860
 861         if {$ok} {
 862                 destroy $w_body
 863
 864                 set HEAD {}
 865                 if {[file exists [gitdir FETCH_HEAD]]} {
 866                         set fd [open [gitdir FETCH_HEAD] r]
 867                         while {[gets $fd line] >= 0} {
 868                                 if {[regexp "^(.{40})\t\t" $line line HEAD]} {
 869                                         break
 870                                 }
 871                         }
 872                         close $fd
 873                 }
 874
 875                 catch {git pack-refs}
 876                 _do_clone_checkout $this $HEAD
 877         } else {
 878                 _clone_failed $this [mc "Cannot determine HEAD.  See console output for details."]
 879         }
 880 }
 881
 882 method _clone_failed {{why {}}} {
 883         if {[catch {file delete -force $local_path} err]} {
 884                 set why [strcat \
 885                         $why \
 886                         "\n\n" \
 887                         [mc "Unable to cleanup %s" $local_path] \
 888                         "\n\n" \
 889                         $err]
 890         }
 891         if {$why ne {}} {
 892                 update
 893                 error_popup [strcat [mc "Clone failed."] "\n" $why]
 894         }
 895 }
 896
 897 method _do_clone_checkout {HEAD} {
 898         if {$HEAD eq {}} {
 899                 info_popup [strcat \
 900                         [mc "No default branch obtained."] \
 901                         "\n" \
 902                         [mc "The 'master' branch has not been initialized."] \
 903                         ]
 904                 set done 1
 905                 return
 906         }
 907         if {[catch {
 908                         git update-ref HEAD $HEAD^0
 909                 } err]} {
 910                 info_popup [strcat \
 911                         [mc "Cannot resolve %s as a commit." $HEAD^0] \
 912                         "\n  $err" \
 913                         "\n" \
 914                         [mc "The 'master' branch has not been initialized."] \
 915                         ]
 916                 set done 1
 917                 return
 918         }
 919
 920         set o_cons [status_bar::two_line $w_body]
 921         pack $w_body -fill x -padx 10 -pady 10
 922         $o_cons start \
 923                 [mc "Creating working directory"] \
 924                 [mc "files"]
 925
 926         set readtree_err {}
 927         set fd [git_read --stderr read-tree \
 928                 -m \
 929                 -u \
 930                 -v \
 931                 HEAD \
 932                 HEAD \
 933                 ]
 934         fconfigure $fd -blocking 0 -translation binary
 935         fileevent $fd readable [cb _readtree_wait $fd]
 936 }
 937
 938 method _readtree_wait {fd} {
 939         set buf [read $fd]
 940         $o_cons update_meter $buf
 941         append readtree_err $buf
 942
 943         fconfigure $fd -blocking 1
 944         if {![eof $fd]} {
 945                 fconfigure $fd -blocking 0
 946                 return
 947         }
 948
 949         if {[catch {close $fd}]} {
 950                 set err $readtree_err
 951                 regsub {^fatal: } $err {} err
 952                 error_popup [strcat \
 953                         [mc "Initial file checkout failed."] \
 954                         "\n\n$err"]
 955                 return
 956         }
 957
 958         set done 1
 959 }
 960
 961 ######################################################################
 962 ##
 963 ## Open Existing Repository
 964
 965 method _do_open {} {
 966         $w_next conf \
 967                 -state disabled \
 968                 -command [cb _do_open2] \
 969                 -text [mc "Open"]
 970
 971         frame $w_body
 972         label $w_body.h \
 973                 -font font_uibold \
 974                 -text [mc "Open Existing Repository"]
 975         pack $w_body.h -side top -fill x -pady 10
 976         pack $w_body -fill x -padx 10
 977
 978         frame $w_body.where
 979         label $w_body.where.l -text [mc "Repository:"]
 980         entry $w_body.where.t \
 981                 -textvariable @local_path \
 982                 -font font_diff \
 983                 -width 50
 984         button $w_body.where.b \
 985                 -text [mc "Browse"] \
 986                 -command [cb _open_local_path]
 987
 988         pack $w_body.where.b -side right
 989         pack $w_body.where.l -side left
 990         pack $w_body.where.t -fill x
 991         pack $w_body.where -fill x
 992
 993         trace add variable @local_path write [cb _write_local_path]
 994         bind $w_body.h <Destroy> [list trace remove variable @local_path write [cb _write_local_path]]
 995         update
 996         focus $w_body.where.t
 997 }
 998
 999 method _open_local_path {} {
1000         if {$local_path ne {}} {
1001                 set p $local_path
1002         } else {
1003                 set p [_home]
1004         }
1005
1006         set p [tk_chooseDirectory \
1007                 -initialdir $p \
1008                 -parent $top \
1009                 -title [mc "Git Repository"] \
1010                 -mustexist true]
1011         if {$p eq {}} return
1012
1013         set p [file normalize $p]
1014         if {![_is_git [file join $p .git]]} {
1015                 error_popup [mc "Not a Git repository: %s" [file tail $p]]
1016                 return
1017         }
1018         set local_path $p
1019 }
1020
1021 method _do_open2 {} {
1022         if {![_is_git [file join $local_path .git]]} {
1023                 error_popup [mc "Not a Git repository: %s" [file tail $local_path]]
1024                 return
1025         }
1026
1027         if {[catch {cd $local_path} err]} {
1028                 error_popup [strcat \
1029                         [mc "Failed to open repository %s:" $local_path] \
1030                         "\n\n$err"]
1031                 return
1032         }
1033
1034         _append_recentrepos [pwd]
1035         set ::_gitdir .git
1036         set ::_prefix {}
1037         set done 1
1038 }
1039
1040 }