git-gui/lib/browser.tcl

   1 # git-gui tree browser
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class browser {
   5
   6 image create photo ::browser::img_parent  -data {R0lGODlhEAAQAIUAAPwCBBxSHBxOHMTSzNzu3KzCtBRGHCSKFIzCjLzSxBQ2FAxGHDzCLCyeHBQ+FHSmfAwuFBxKLDSCNMzizISyjJzOnDSyLAw+FAQSDAQeDBxWJAwmDAQOBKzWrDymNAQaDAQODAwaDDyKTFSyXFTGTEy6TAQCBAQKDAwiFBQyHAwSFAwmHAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAZ1QIBwSCwaj0hiQCBICpcDQsFgGAaIguhhi0gohIsrQEDYMhiNrRfgeAQC5fMCAolIDhD2hFI5WC4YRBkaBxsOE2l/RxsHHA4dHmkfRyAbIQ4iIyQlB5NFGCAACiakpSZEJyinTgAcKSesACorgU4mJ6uxR35BACH+aENyZWF0ZWQgYnkgQk1QVG9HSUYgUHJvIHZlcnNpb24gMi41DQqpIERldmVsQ29yIDE5OTcsMTk5OC4gQWxsIHJpZ2h0cyByZXNlcnZlZC4NCmh0dHA6Ly93d3cuZGV2ZWxjb3IuY29tADs=}
   7 image create photo ::browser::img_rblob   -data {R0lGODlhEAAQAIUAAPwCBFxaXNze3Ly2rJSWjPz+/Ozq7GxqbJyanPT29HRydMzOzDQyNIyKjERCROTi3Pz69PTy7Pzy7PTu5Ozm3LyqlJyWlJSSjJSOhOzi1LyulPz27PTq3PTm1OzezLyqjIyKhJSKfOzaxPz29OzizLyidIyGdIyCdOTOpLymhOzavOTStMTCtMS+rMS6pMSynMSulLyedAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAaQQIAQECgajcNkQMBkDgKEQFK4LFgLhkMBIVUKroWEYlEgMLxbBKLQUBwc52HgAQ4LBo049atWQyIPA3pEdFcQEhMUFYNVagQWFxgZGoxfYRsTHB0eH5UJCJAYICEinUoPIxIcHCQkIiIllQYEGCEhJicoKYwPmiQeKisrKLFKLCwtLi8wHyUlMYwM0tPUDH5BACH+aENyZWF0ZWQgYnkgQk1QVG9HSUYgUHJvIHZlcnNpb24gMi41DQqpIERldmVsQ29yIDE5OTcsMTk5OC4gQWxsIHJpZ2h0cyByZXNlcnZlZC4NCmh0dHA6Ly93d3cuZGV2ZWxjb3IuY29tADs=}
   8 image create photo ::browser::img_xblob   -data {R0lGODlhEAAQAIYAAPwCBFRWVFxaXNza3OTi3Nze3Ly2tJyanPz+/Ozq7GxubNzSxMzOzMTGxHRybDQyNLy+vHRydHx6fKSipISChIyKjGxqbERCRCwuLLy6vGRiZExKTCQiJAwKDLSytLy2rJSSlHx+fDw6PKyqrBQWFPTu5Ozm3LyulLS2tCQmJAQCBPTq3Ozi1MSynCwqLAQGBOTazOzizOzezLyqjBweHNzSvOzaxKyurHRuZNzOtLymhDw+PIyCdOzWvOTOpLyidNzKtOTStLyifMTCtMS+rLyedAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAfZgACCAAEChYeGg4oCAwQFjgYBBwGKggEECJkICQoIkwADCwwNDY2mDA4Lng8QDhESsLARExQVDhYXGBkWExIaGw8cHR4SCQQfFQ8eFgUgIQEiwiMSBMYfGB4atwEXDyQd0wQlJicPKAHoFyIpJCoeDgMrLC0YKBsX6i4kL+4OMDEyZijr5oLGNxUqUCioEcPGDAwjPNyI6MEDChQjcOSwsUDHgw07RIgI4KCkAgs8cvTw8eOBogAxQtXIASTISiEuBwUYMoRIixYnZggpUgTDywdIkWJIitRPIAAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
   9 image create photo ::browser::img_tree    -data {R0lGODlhEAAQAIYAAPwCBAQCBExKTBwWHMzKzOzq7ERCRExGTCwqLARqnAQ+ZHR2dKyqrNTOzHx2fCQiJMTi9NTu9HzC3AxmnAQ+XPTm7Dy67DymzITC3IzG5AxypHRydKymrMzOzOzu7BweHByy9AyGtFyy1IzG3NTu/ARupFRSVByazBR6rAyGvFyuzJTK3MTm9BR+tAxWhHS61MTi7Pz+/IymvCxulBRelAx2rHS63Pz6/PTy9PTu9Nza3ISitBRupFSixNTS1CxqnDQyNMzGzOTi5MTCxMTGxGxubGxqbLy2vLSutGRiZLy6vLSytKyurDQuNFxaXKSipDw6PAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAfDgACCAAECg4eIAAMEBQYHCImDBgkKCwwNBQIBBw4Bhw8QERITFJYEFQUFnoIPFhcYoRkaFBscHR4Ggh8gIRciEiMQJBkltCa6JyUoKSkXKhIrLCQYuQAPLS4TEyUhKb0qLzDVAjEFMjMuNBMoNcw21QY3ODkFOjs82RM1PfDzFRU3fOggcM7Fj2pAgggRokOHDx9DhhAZUqQaISBGhjwMEvEIkiIHEgUAkgSJkiNLmFSMJChAEydPGBSBwvJQgAc0/QQCACH+aENyZWF0ZWQgYnkgQk1QVG9HSUYgUHJvIHZlcnNpb24gMi41DQqpIERldmVsQ29yIDE5OTcsMTk5OC4gQWxsIHJpZ2h0cyByZXNlcnZlZC4NCmh0dHA6Ly93d3cuZGV2ZWxjb3IuY29tADs=}
  10 image create photo ::browser::img_symlink -data {R0lGODlhEAAQAIQAAPwCBCwqLLSytLy+vERGRFRWVDQ2NKSmpAQCBKyurMTGxISChJyanHR2dIyKjGxubHRydGRmZIyOjFxeXHx6fAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAVbICACwWieY1CibCCsrBkMb0zchSEcNYskCtqBBzshFkOGQFk0IRqOxqPBODRHCMhCQKteRc9FI/KQWGOIyFYgkDC+gPR4snCcfRGKOIKIgSMQE31+f4OEYCZ+IQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
  11 image create photo ::browser::img_unknown -data {R0lGODlhEAAQAIUAAPwCBFxaXIyKjNTW1Nze3LS2tJyanER2RGS+VPz+/PTu5GxqbPz69BQ6BCxeLFSqRPT29HRydMzOzDQyNERmPKSypCRWHIyKhERCRDyGPKz2nESiLBxGHCyCHGxubPz6/PTy7Ozi1Ly2rKSipOzm3LyqlKSWhCRyFOzizLymhNTKtNzOvOzaxOTStPz27OzWvOTOpLSupLyedMS+rMS6pMSulLyqjLymfLyifAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAQABAAAAamQIAQECgajcOkYEBoDgoBQyAJOCCuiENCsWBIh9aGw9F4HCARiXciRDQoBUnlYRlcIgsMG5CxXAgMGhscBRAEBRd7AB0eBBoIgxUfICEiikSPgyMMIAokJZcBkBybJgomIaBJAZoMpyCmqkMBFCcVCrgKKAwpoSorKqchKCwtvasIFBIhLiYvLzDHsxQNMcMKLDAwMqEz3jQ1NTY3ONyrE+jp6hN+QQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
  12
  13 field w
  14 field browser_commit
  15 field browser_path
  16 field browser_files  {}
  17 field browser_status {Starting...}
  18 field browser_stack  {}
  19 field browser_busy   1
  20
  21 field ls_buf     {}; # Buffered record output from ls-tree
  22
  23 constructor new {commit {path {}}} {
  24         global cursor_ptr M1B
  25         make_toplevel top w
  26         wm title $top "[appname] ([reponame]): File Browser"
  27
  28         set browser_commit $commit
  29         set browser_path $browser_commit:$path
  30
  31         label $w.path \
  32                 -textvariable @browser_path \
  33                 -anchor w \
  34                 -justify left \
  35                 -borderwidth 1 \
  36                 -relief sunken \
  37                 -font font_uibold
  38         pack $w.path -anchor w -side top -fill x
  39
  40         frame $w.list
  41         set w_list $w.list.l
  42         text $w_list -background white -borderwidth 0 \
  43                 -cursor $cursor_ptr \
  44                 -state disabled \
  45                 -wrap none \
  46                 -height 20 \
  47                 -width 70 \
  48                 -xscrollcommand [list $w.list.sbx set] \
  49                 -yscrollcommand [list $w.list.sby set]
  50         $w_list tag conf in_sel \
  51                 -background [$w_list cget -foreground] \
  52                 -foreground [$w_list cget -background]
  53         scrollbar $w.list.sbx -orient h -command [list $w_list xview]
  54         scrollbar $w.list.sby -orient v -command [list $w_list yview]
  55         pack $w.list.sbx -side bottom -fill x
  56         pack $w.list.sby -side right -fill y
  57         pack $w_list -side left -fill both -expand 1
  58         pack $w.list -side top -fill both -expand 1
  59
  60         label $w.status \
  61                 -textvariable @browser_status \
  62                 -anchor w \
  63                 -justify left \
  64                 -borderwidth 1 \
  65                 -relief sunken
  66         pack $w.status -anchor w -side bottom -fill x
  67
  68         bind $w_list <Button-1>        "[cb _click 0 @%x,%y];break"
  69         bind $w_list <Double-Button-1> "[cb _click 1 @%x,%y];break"
  70         bind $w_list <$M1B-Up>         "[cb _parent]        ;break"
  71         bind $w_list <$M1B-Left>       "[cb _parent]        ;break"
  72         bind $w_list <Up>              "[cb _move -1]       ;break"
  73         bind $w_list <Down>            "[cb _move  1]       ;break"
  74         bind $w_list <$M1B-Right>      "[cb _enter]         ;break"
  75         bind $w_list <Return>          "[cb _enter]         ;break"
  76         bind $w_list <Prior>           "[cb _page -1]       ;break"
  77         bind $w_list <Next>            "[cb _page  1]       ;break"
  78         bind $w_list <Left>            break
  79         bind $w_list <Right>           break
  80
  81         bind $w_list <Visibility> [list focus $w_list]
  82         set w $w_list
  83         if {$path ne {}} {
  84                 _ls $this $browser_commit:$path $path
  85         } else {
  86                 _ls $this $browser_commit $path
  87         }
  88         return $this
  89 }
  90
  91 method _move {dir} {
  92         if {$browser_busy} return
  93         set lno [lindex [split [$w index in_sel.first] .] 0]
  94         incr lno $dir
  95         if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
  96                 $w tag remove in_sel 0.0 end
  97                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
  98                 $w see $lno.0
  99         }
 100 }
 101
 102 method _page {dir} {
 103         if {$browser_busy} return
 104         $w yview scroll $dir pages
 105         set lno [expr {int(
 106                   [lindex [$w yview] 0]
 107                 * [llength $browser_files]
 108                 + 1)}]
 109         if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
 110                 $w tag remove in_sel 0.0 end
 111                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
 112                 $w see $lno.0
 113         }
 114 }
 115
 116 method _parent {} {
 117         if {$browser_busy} return
 118         set info [lindex $browser_files 0]
 119         if {[lindex $info 0] eq {parent}} {
 120                 set parent [lindex $browser_stack end-1]
 121                 set browser_stack [lrange $browser_stack 0 end-2]
 122                 if {$browser_stack eq {}} {
 123                         regsub {:.*$} $browser_path {:} browser_path
 124                 } else {
 125                         regsub {/[^/]+$} $browser_path {} browser_path
 126                 }
 127                 set browser_status "Loading $browser_path..."
 128                 _ls $this [lindex $parent 0] [lindex $parent 1]
 129         }
 130 }
 131
 132 method _enter {} {
 133         if {$browser_busy} return
 134         set lno [lindex [split [$w index in_sel.first] .] 0]
 135         set info [lindex $browser_files [expr {$lno - 1}]]
 136         if {$info ne {}} {
 137                 switch -- [lindex $info 0] {
 138                 parent {
 139                         _parent $this
 140                 }
 141                 tree {
 142                         set name [lindex $info 2]
 143                         set escn [escape_path $name]
 144                         set browser_status "Loading $escn..."
 145                         append browser_path $escn
 146                         _ls $this [lindex $info 1] $name
 147                 }
 148                 blob {
 149                         set name [lindex $info 2]
 150                         set p {}
 151                         foreach n $browser_stack {
 152                                 append p [lindex $n 1]
 153                         }
 154                         append p $name
 155                         blame::new $browser_commit $p
 156                 }
 157                 }
 158         }
 159 }
 160
 161 method _click {was_double_click pos} {
 162         if {$browser_busy} return
 163         set lno [lindex [split [$w index $pos] .] 0]
 164         focus $w
 165
 166         if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
 167                 $w tag remove in_sel 0.0 end
 168                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
 169                 if {$was_double_click} {
 170                         _enter $this
 171                 }
 172         }
 173 }
 174
 175 method _ls {tree_id {name {}}} {
 176         set ls_buf {}
 177         set browser_files {}
 178         set browser_busy 1
 179
 180         $w conf -state normal
 181         $w tag remove in_sel 0.0 end
 182         $w delete 0.0 end
 183         if {$browser_stack ne {}} {
 184                 $w image create end \
 185                         -align center -padx 5 -pady 1 \
 186                         -name icon0 \
 187                         -image ::browser::img_parent
 188                 $w insert end {[Up To Parent]}
 189                 lappend browser_files parent
 190         }
 191         lappend browser_stack [list $tree_id $name]
 192         $w conf -state disabled
 193
 194         set fd [git_read ls-tree -z $tree_id]
 195         fconfigure $fd -blocking 0 -translation binary -encoding binary
 196         fileevent $fd readable [cb _read $fd]
 197 }
 198
 199 method _read {fd} {
 200         append ls_buf [read $fd]
 201         set pck [split $ls_buf "\0"]
 202         set ls_buf [lindex $pck end]
 203
 204         set n [llength $browser_files]
 205         $w conf -state normal
 206         foreach p [lrange $pck 0 end-1] {
 207                 set tab [string first "\t" $p]
 208                 if {$tab == -1} continue
 209
 210                 set info [split [string range $p 0 [expr {$tab - 1}]] { }]
 211                 set path [string range $p [expr {$tab + 1}] end]
 212                 set type   [lindex $info 1]
 213                 set object [lindex $info 2]
 214
 215                 switch -- $type {
 216                 blob {
 217                         scan [lindex $info 0] %o mode
 218                         if {$mode == 0120000} {
 219                                 set image ::browser::img_symlink
 220                         } elseif {($mode & 0100) != 0} {
 221                                 set image ::browser::img_xblob
 222                         } else {
 223                                 set image ::browser::img_rblob
 224                         }
 225                 }
 226                 tree {
 227                         set image ::browser::img_tree
 228                         append path /
 229                 }
 230                 default {
 231                         set image ::browser::img_unknown
 232                 }
 233                 }
 234
 235                 if {$n > 0} {$w insert end "\n"}
 236                 $w image create end \
 237                         -align center -padx 5 -pady 1 \
 238                         -name icon[incr n] \
 239                         -image $image
 240                 $w insert end [escape_path $path]
 241                 lappend browser_files [list $type $object $path]
 242         }
 243         $w conf -state disabled
 244
 245         if {[eof $fd]} {
 246                 close $fd
 247                 set browser_status Ready.
 248                 set browser_busy 0
 249                 set ls_buf {}
 250                 if {$n > 0} {
 251                         $w tag add in_sel 1.0 2.0
 252                         focus -force $w
 253                 }
 254         }
 255 } ifdeleted {
 256         catch {close $fd}
 257 }
 258
 259 }
 260
 261 class browser_open {
 262
 263 field w              ; # widget path
 264 field w_rev          ; # mega-widget to pick the initial revision
 265
 266 constructor dialog {} {
 267         make_toplevel top w
 268         wm title $top "[appname] ([reponame]): Browse Branch Files"
 269         if {$top ne {.}} {
 270                 wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
 271         }
 272
 273         label $w.header \
 274                 -text {Browse Branch Files} \
 275                 -font font_uibold
 276         pack $w.header -side top -fill x
 277
 278         frame $w.buttons
 279         button $w.buttons.browse -text Browse \
 280                 -default active \
 281                 -command [cb _open]
 282         pack $w.buttons.browse -side right
 283         button $w.buttons.cancel -text {Cancel} \
 284                 -command [list destroy $w]
 285         pack $w.buttons.cancel -side right -padx 5
 286         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
 287
 288         set w_rev [::choose_rev::new $w.rev {Revision}]
 289         $w_rev bind_listbox <Double-Button-1> [cb _open]
 290         pack $w.rev -anchor nw -fill both -expand 1 -pady 5 -padx 5
 291
 292         bind $w <Visibility> [cb _visible]
 293         bind $w <Key-Escape> [list destroy $w]
 294         bind $w <Key-Return> [cb _open]\;break
 295         tkwait window $w
 296 }
 297
 298 method _open {} {
 299         if {[catch {$w_rev commit_or_die} err]} {
 300                 return
 301         }
 302         set name [$w_rev get]
 303         destroy $w
 304         browser::new $name
 305 }
 306
 307 method _visible {} {
 308         grab $w
 309         $w_rev focus_filter
 310 }
 311
 312 }