configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Set lib to alternative name of lib directory (e.g. lib64)
  73 AC_ARG_WITH([lib],
  74  [AS_HELP_STRING([--with-lib=ARG],
  75                  [ARG specifies alternative name for lib directory])],
  76  [if test "$withval" = "no" || test "$withval" = "yes"; then \
  77         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
  78 else \
  79         GIT_CONF_APPEND_LINE(lib=$withval); \
  80 fi; \
  81 ],[])
  82 #
  83 # Define SHELL_PATH to provide path to shell.
  84 GIT_ARG_SET_PATH(shell)
  85 #
  86 # Define PERL_PATH to provide path to Perl.
  87 GIT_ARG_SET_PATH(perl)
  88 #
  89 # Define ZLIB_PATH to provide path to zlib.
  90 GIT_ARG_SET_PATH(zlib)
  91 #
  92 # Declare the with-tcltk/without-tcltk options.
  93 AC_ARG_WITH(tcltk,
  94 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  95 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  96 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  97 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  98 GIT_PARSE_WITH(tcltk))
  99 #
 100
 101
 102 ## Checks for programs.
 103 AC_MSG_NOTICE([CHECKS for programs])
 104 #
 105 AC_PROG_CC([cc gcc])
 106 # which switch to pass runtime path to dynamic libraries to the linker
 107 AC_CACHE_CHECK([if linker supports -R], ld_dashr, [
 108    SAVE_LDFLAGS="${LDFLAGS}"
 109    LDFLAGS="${SAVE_LDFLAGS} -R /"
 110    AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [ld_dashr=yes], [ld_dashr=no])
 111    LDFLAGS="${SAVE_LDFLAGS}"
 112 ])
 113 if test "$ld_dashr" = "yes"; then
 114    AC_SUBST(CC_LD_DYNPATH, [-R])
 115 else
 116    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], ld_wl_rpath, [
 117       SAVE_LDFLAGS="${LDFLAGS}"
 118       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 119       AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [ld_wl_rpath=yes], [ld_wl_rpath=no])
 120       LDFLAGS="${SAVE_LD_FLAGS}"
 121    ])
 122    if test "$ld_wl_rpath" = "yes"; then
 123       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 124    else
 125       AC_CACHE_CHECK([if linker supports -rpath], ld_rpath, [
 126          SAVE_LDFLAGS="${LDFLAGS}"
 127          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 128          AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [ld_rpath=yes], [ld_rpath=no])
 129          LDFLAGS="${SAVE_LD_FLAGS}"
 130       ])
 131       if test "$ld_rpath" = "yes"; then
 132          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 133       else
 134          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 135       fi
 136    fi
 137 fi
 138 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 139 AC_CHECK_TOOLS(AR, [gar ar], :)
 140 AC_CHECK_PROGS(TAR, [gtar tar])
 141 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 142 # or will be empty otherwise.
 143 if test -z "$NO_TCLTK"; then
 144   if test "$with_tcltk" = ""; then
 145   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 146     TCLTK_PATH=wish
 147     AC_SUBST(TCLTK_PATH)
 148   elif test "$with_tcltk" = "yes"; then
 149   # Tcl/Tk check requested.
 150     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 151   else
 152     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 153     TCLTK_PATH="$with_tcltk"
 154     AC_SUBST(TCLTK_PATH)
 155   fi
 156 fi
 157 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 158 if test -n "$ASCIIDOC"; then
 159         AC_MSG_CHECKING([for asciidoc version])
 160         asciidoc_version=`$ASCIIDOC --version 2>&1`
 161         case "${asciidoc_version}" in
 162         asciidoc' '8*)
 163                 ASCIIDOC8=YesPlease
 164                 AC_MSG_RESULT([${asciidoc_version} > 7])
 165                 ;;
 166         asciidoc' '7*)
 167                 ASCIIDOC8=
 168                 AC_MSG_RESULT([${asciidoc_version}])
 169                 ;;
 170         *)
 171                 ASCIIDOC8=
 172                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 173                 ;;
 174         esac
 175 fi
 176 AC_SUBST(ASCIIDOC8)
 177
 178
 179 ## Checks for libraries.
 180 AC_MSG_NOTICE([CHECKS for libraries])
 181 #
 182 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 183 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 184 AC_CHECK_LIB([crypto], [SHA1_Init],
 185 [NEEDS_SSL_WITH_CRYPTO=],
 186 [AC_CHECK_LIB([ssl], [SHA1_Init],
 187  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 188   NEEDS_SSL_WITH_CRYPTO=],
 189  [NO_OPENSSL=YesPlease])])
 190 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 191 AC_SUBST(NO_OPENSSL)
 192 #
 193 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 194 # git-http-push are not built, and you cannot use http:// and https://
 195 # transports.
 196 AC_CHECK_LIB([curl], [curl_global_init],
 197 [NO_CURL=],
 198 [NO_CURL=YesPlease])
 199 AC_SUBST(NO_CURL)
 200 #
 201 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 202 # not built, and you cannot push using http:// and https:// transports.
 203 AC_CHECK_LIB([expat], [XML_ParserCreate],
 204 [NO_EXPAT=],
 205 [NO_EXPAT=YesPlease])
 206 AC_SUBST(NO_EXPAT)
 207 #
 208 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 209 # some Solaris installations).
 210 # Define NO_ICONV if neither libc nor libiconv support iconv.
 211 AC_DEFUN([ICONVTEST_SRC], [
 212 #include <iconv.h>
 213
 214 int main(void)
 215 {
 216         iconv_open("", "");
 217         return 0;
 218 }
 219 ])
 220 AC_MSG_CHECKING([for iconv in -lc])
 221 AC_LINK_IFELSE(ICONVTEST_SRC,
 222         [AC_MSG_RESULT([yes])
 223         NEEDS_LIBICONV=],
 224         [AC_MSG_RESULT([no])
 225         old_LIBS="$LIBS"
 226         LIBS="$LIBS -liconv"
 227         AC_MSG_CHECKING([for iconv in -liconv])
 228         AC_LINK_IFELSE(ICONVTEST_SRC,
 229                 [AC_MSG_RESULT([yes])
 230                 NEEDS_LIBICONV=YesPlease],
 231                 [AC_MSG_RESULT([no])
 232                 NO_ICONV=YesPlease])
 233         LIBS="$old_LIBS"])
 234 AC_SUBST(NEEDS_LIBICONV)
 235 AC_SUBST(NO_ICONV)
 236 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 237 #
 238 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 239 AC_DEFUN([ZLIBTEST_SRC], [
 240 #include <zlib.h>
 241
 242 int main(void)
 243 {
 244         deflateBound(0, 0);
 245         return 0;
 246 }
 247 ])
 248 AC_MSG_CHECKING([for deflateBound in -lz])
 249 old_LIBS="$LIBS"
 250 LIBS="$LIBS -lz"
 251 AC_LINK_IFELSE(ZLIBTEST_SRC,
 252         [AC_MSG_RESULT([yes])],
 253         [AC_MSG_RESULT([no])
 254         NO_DEFLATE_BOUND=yes])
 255 LIBS="$old_LIBS"
 256 AC_SUBST(NO_DEFLATE_BOUND)
 257 #
 258 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 259 # Patrick Mauritz).
 260 AC_CHECK_LIB([c], [socket],
 261 [NEEDS_SOCKET=],
 262 [NEEDS_SOCKET=YesPlease])
 263 AC_SUBST(NEEDS_SOCKET)
 264 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 265
 266
 267 ## Checks for header files.
 268 AC_MSG_NOTICE([CHECKS for header files])
 269 #
 270 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 271 AC_CHECK_HEADER([sys/select.h],
 272 [NO_SYS_SELECT_H=],
 273 [NO_SYS_SELECT_H=UnfortunatelyYes])
 274 AC_SUBST(NO_SYS_SELECT_H)
 275 #
 276 # Define OLD_ICONV if your library has an old iconv(), where the second
 277 # (input buffer pointer) parameter is declared with type (const char **).
 278 AC_DEFUN([OLDICONVTEST_SRC], [[
 279 #include <iconv.h>
 280
 281 extern size_t iconv(iconv_t cd,
 282                     char **inbuf, size_t *inbytesleft,
 283                     char **outbuf, size_t *outbytesleft);
 284
 285 int main(void)
 286 {
 287         return 0;
 288 }
 289 ]])
 290 AC_MSG_CHECKING([for old iconv()])
 291 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 292         [AC_MSG_RESULT([no])],
 293         [AC_MSG_RESULT([yes])
 294         OLD_ICONV=UnfortunatelyYes])
 295 AC_SUBST(OLD_ICONV)
 296
 297
 298 ## Checks for typedefs, structures, and compiler characteristics.
 299 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 300 #
 301 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 302 AC_CHECK_MEMBER(struct dirent.d_ino,
 303 [NO_D_INO_IN_DIRENT=],
 304 [NO_D_INO_IN_DIRENT=YesPlease],
 305 [#include <dirent.h>])
 306 AC_SUBST(NO_D_INO_IN_DIRENT)
 307 #
 308 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 309 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 310 AC_CHECK_MEMBER(struct dirent.d_type,
 311 [NO_D_TYPE_IN_DIRENT=],
 312 [NO_D_TYPE_IN_DIRENT=YesPlease],
 313 [#include <dirent.h>])
 314 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 315 #
 316 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 317 # sockaddr_storage.
 318 AC_CHECK_TYPE(struct sockaddr_storage,
 319 [NO_SOCKADDR_STORAGE=],
 320 [NO_SOCKADDR_STORAGE=YesPlease],[
 321 #include <sys/types.h>
 322 #include <sys/socket.h>
 323 ])
 324 AC_SUBST(NO_SOCKADDR_STORAGE)
 325 #
 326 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 327 AC_CHECK_TYPE([struct addrinfo],[
 328  AC_CHECK_FUNC([getaddrinfo],
 329   [NO_IPV6=],
 330   [NO_IPV6=YesPlease])
 331 ],[NO_IPV6=YesPlease],[
 332 #include <sys/types.h>
 333 #include <sys/socket.h>
 334 #include <netdb.h>
 335 ])
 336 AC_SUBST(NO_IPV6)
 337 #
 338 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 339 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 340 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 341 # some C compilers supported these specifiers prior to C99 as an extension.
 342 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 343  [ac_cv_c_c99_format],
 344 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 345 AC_RUN_IFELSE(
 346         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 347                 [[char buf[64];
 348                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 349                   return 1;
 350                 else if (strcmp(buf, "12345"))
 351                   return 2;]])],
 352         [ac_cv_c_c99_format=yes],
 353         [ac_cv_c_c99_format=no])
 354 ])
 355 if test $ac_cv_c_c99_format = no; then
 356         NO_C99_FORMAT=YesPlease
 357 else
 358         NO_C99_FORMAT=
 359 fi
 360 AC_SUBST(NO_C99_FORMAT)
 361 #
 362 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 363 # when attempting to read from an fopen'ed directory.
 364 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 365  [ac_cv_fread_reads_directories],
 366 [
 367 AC_RUN_IFELSE(
 368         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 369                 [[char c;
 370                 FILE *f = fopen(".", "r");
 371                 return f && fread(&c, 1, 1, f)]])],
 372         [ac_cv_fread_reads_directories=no],
 373         [ac_cv_fread_reads_directories=yes])
 374 ])
 375 if test $ac_cv_fread_reads_directories = yes; then
 376         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 377 else
 378         FREAD_READS_DIRECTORIES=
 379 fi
 380 AC_SUBST(FREAD_READS_DIRECTORIES)
 381 #
 382 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 383 # or vsnprintf() return -1 instead of number of characters which would
 384 # have been written to the final string if enough space had been available.
 385 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 386  [ac_cv_snprintf_returns_bogus],
 387 [
 388 AC_RUN_IFELSE(
 389         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 390                 #include "stdarg.h"
 391
 392                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 393                 {
 394                   int ret;
 395                   va_list ap;
 396                   va_start(ap, format);
 397                   ret = vsnprintf(str, maxsize, format, ap);
 398                   va_end(ap);
 399                   return ret;
 400                 }],
 401                 [[char buf[6];
 402                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 403                       || strcmp(buf, "12")) return 1;
 404                   if (snprintf(buf, 3, "%s", "12345") != 5
 405                       || strcmp(buf, "12")) return 1]])],
 406         [ac_cv_snprintf_returns_bogus=no],
 407         [ac_cv_snprintf_returns_bogus=yes])
 408 ])
 409 if test $ac_cv_snprintf_returns_bogus = yes; then
 410         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 411 else
 412         SNPRINTF_RETURNS_BOGUS=
 413 fi
 414 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 415
 416
 417 ## Checks for library functions.
 418 ## (in default C library and libraries checked by AC_CHECK_LIB)
 419 AC_MSG_NOTICE([CHECKS for library functions])
 420 #
 421 # Define NO_STRCASESTR if you don't have strcasestr.
 422 AC_CHECK_FUNC(strcasestr,
 423 [NO_STRCASESTR=],
 424 [NO_STRCASESTR=YesPlease])
 425 AC_SUBST(NO_STRCASESTR)
 426 #
 427 # Define NO_MEMMEM if you don't have memmem.
 428 AC_CHECK_FUNC(memmem,
 429 [NO_MEMMEM=],
 430 [NO_MEMMEM=YesPlease])
 431 AC_SUBST(NO_MEMMEM)
 432 #
 433 # Define NO_STRLCPY if you don't have strlcpy.
 434 AC_CHECK_FUNC(strlcpy,
 435 [NO_STRLCPY=],
 436 [NO_STRLCPY=YesPlease])
 437 AC_SUBST(NO_STRLCPY)
 438 #
 439 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 440 AC_CHECK_FUNC(strtoumax,
 441 [NO_STRTOUMAX=],
 442 [NO_STRTOUMAX=YesPlease])
 443 AC_SUBST(NO_STRTOUMAX)
 444 #
 445 # Define NO_SETENV if you don't have setenv in the C library.
 446 AC_CHECK_FUNC(setenv,
 447 [NO_SETENV=],
 448 [NO_SETENV=YesPlease])
 449 AC_SUBST(NO_SETENV)
 450 #
 451 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 452 AC_CHECK_FUNC(unsetenv,
 453 [NO_UNSETENV=],
 454 [NO_UNSETENV=YesPlease])
 455 AC_SUBST(NO_UNSETENV)
 456 #
 457 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 458 AC_CHECK_FUNC(mkdtemp,
 459 [NO_MKDTEMP=],
 460 [NO_MKDTEMP=YesPlease])
 461 AC_SUBST(NO_MKDTEMP)
 462 #
 463 # Define NO_MMAP if you want to avoid mmap.
 464 #
 465 # Define NO_ICONV if your libc does not properly support iconv.
 466
 467
 468 ## Other checks.
 469 # Define USE_PIC if you need the main git objects to be built with -fPIC
 470 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 471 #
 472 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 473 # Enable it on Windows.  By default, symrefs are still used.
 474
 475 ## Site configuration (override autodetection)
 476 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 477 AC_MSG_NOTICE([CHECKS for site configuration])
 478 #
 479 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 480 # tests.  These tests take up a significant amount of the total test time
 481 # but are not needed unless you plan to talk to SVN repos.
 482 #
 483 # Define MOZILLA_SHA1 environment variable when running make to make use of
 484 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 485 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 486 # choice) has very fast version optimized for i586.
 487 #
 488 # Define PPC_SHA1 environment variable when running make to make use of
 489 # a bundled SHA1 routine optimized for PowerPC.
 490 #
 491 # Define ARM_SHA1 environment variable when running make to make use of
 492 # a bundled SHA1 routine optimized for ARM.
 493 #
 494 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 495 # This also implies MOZILLA_SHA1.
 496 #
 497 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 498 # /foo/bar/include and /foo/bar/lib directories.
 499 AC_ARG_WITH(openssl,
 500 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 501 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 502 GIT_PARSE_WITH(openssl))
 503 #
 504 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 505 # git-http-push are not built, and you cannot use http:// and https://
 506 # transports.
 507 #
 508 # Define CURLDIR=/foo/bar if your curl header and library files are in
 509 # /foo/bar/include and /foo/bar/lib directories.
 510 AC_ARG_WITH(curl,
 511 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 512 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 513 GIT_PARSE_WITH(curl))
 514 #
 515 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 516 # not built, and you cannot push using http:// and https:// transports.
 517 #
 518 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 519 # /foo/bar/include and /foo/bar/lib directories.
 520 AC_ARG_WITH(expat,
 521 AS_HELP_STRING([--with-expat],
 522 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 523 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 524 GIT_PARSE_WITH(expat))
 525 #
 526 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 527 # installed in /sw, but don't want GIT to link against any libraries
 528 # installed there.  If defined you may specify your own (or Fink's)
 529 # include directories and library directories by defining CFLAGS
 530 # and LDFLAGS appropriately.
 531 #
 532 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 533 # have DarwinPorts installed in /opt/local, but don't want GIT to
 534 # link against any libraries installed there.  If defined you may
 535 # specify your own (or DarwinPort's) include directories and
 536 # library directories by defining CFLAGS and LDFLAGS appropriately.
 537 #
 538 # Define NO_MMAP if you want to avoid mmap.
 539 #
 540 # Define NO_ICONV if your libc does not properly support iconv.
 541 AC_ARG_WITH(iconv,
 542 AS_HELP_STRING([--without-iconv],
 543 [if your architecture doesn't properly support iconv])
 544 AS_HELP_STRING([--with-iconv=PATH],
 545 [PATH is prefix for libiconv library and headers])
 546 AS_HELP_STRING([],
 547 [used only if you need linking with libiconv]),
 548 GIT_PARSE_WITH(iconv))
 549
 550 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 551 #
 552 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 553 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 554 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 555 # randomly break unless your underlying filesystem supports those sub-second
 556 # times (my ext3 doesn't).
 557 #
 558 # Define USE_STDEV below if you want git to care about the underlying device
 559 # change being considered an inode change from the update-index perspective.
 560
 561
 562 ## Output files
 563 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 564 AC_OUTPUT
 565
 566
 567 ## Cleanup
 568 rm -f "${config_append}"