configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  79 # Define PYTHON_PATH to provide path to Python.
  80 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
  81 AS_HELP_STRING([--without-python], [don't use python scripts])],
  82  [if test "$withval" = "no"; then \
  83     NO_PYTHON=YesPlease; \
  84   elif test "$withval" = "yes"; then \
  85     NO_PYTHON=; \
  86   else \
  87     NO_PYTHON=; \
  88     PYTHON_PATH=$withval; \
  89   fi; \
  90  ])
  91 AC_SUBST(NO_PYTHON)
  92 AC_SUBST(PYTHON_PATH)
  93
  94
  95 ## Checks for programs.
  96 AC_MSG_NOTICE([CHECKS for programs])
  97 #
  98 AC_PROG_CC
  99 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 100 AC_CHECK_TOOL(AR, ar, :)
 101 AC_CHECK_PROGS(TAR, [gtar tar])
 102 #
 103 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 104 # Define PYTHON_PATH to provide path to Python.
 105 if test -z "$NO_PYTHON"; then
 106         if test -z "$PYTHON_PATH"; then
 107                 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 108         fi
 109         if test -n "$PYTHON_PATH"; then
 110                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 111                 NO_PYTHON=""
 112         fi
 113 fi
 114
 115
 116 ## Checks for libraries.
 117 AC_MSG_NOTICE([CHECKS for libraries])
 118 #
 119 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 120 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 121 AC_CHECK_LIB([crypto], [SHA1_Init],
 122 [NEEDS_SSL_WITH_CRYPTO=],
 123 [AC_CHECK_LIB([ssl], [SHA1_Init],
 124  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 125   NEEDS_SSL_WITH_CRYPTO=],
 126  [NO_OPENSSL=YesPlease])])
 127 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 128 AC_SUBST(NO_OPENSSL)
 129 #
 130 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 131 # git-http-push are not built, and you cannot use http:// and https://
 132 # transports.
 133 AC_CHECK_LIB([curl], [curl_global_init],
 134 [NO_CURL=],
 135 [NO_CURL=YesPlease])
 136 AC_SUBST(NO_CURL)
 137 #
 138 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 139 # not built, and you cannot push using http:// and https:// transports.
 140 AC_CHECK_LIB([expat], [XML_ParserCreate],
 141 [NO_EXPAT=],
 142 [NO_EXPAT=YesPlease])
 143 AC_SUBST(NO_EXPAT)
 144 #
 145 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 146 AC_CHECK_LIB([c], [iconv],
 147 [NEEDS_LIBICONV=],
 148 [NEEDS_LIBICONV=YesPlease])
 149 AC_SUBST(NEEDS_LIBICONV)
 150 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 151 #
 152 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 153 # Patrick Mauritz).
 154 AC_CHECK_LIB([c], [socket],
 155 [NEEDS_SOCKET=],
 156 [NEEDS_SOCKET=YesPlease])
 157 AC_SUBST(NEEDS_SOCKET)
 158 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 159
 160
 161 ## Checks for header files.
 162
 163
 164 ## Checks for typedefs, structures, and compiler characteristics.
 165 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 166 #
 167 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 168 AC_CHECK_MEMBER(struct dirent.d_ino,
 169 [NO_D_INO_IN_DIRENT=],
 170 [NO_D_INO_IN_DIRENT=YesPlease],
 171 [#include <dirent.h>])
 172 AC_SUBST(NO_D_INO_IN_DIRENT)
 173 #
 174 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 175 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 176 AC_CHECK_MEMBER(struct dirent.d_type,
 177 [NO_D_TYPE_IN_DIRENT=],
 178 [NO_D_TYPE_IN_DIRENT=YesPlease],
 179 [#include <dirent.h>])
 180 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 181 #
 182 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 183 # sockaddr_storage.
 184 AC_CHECK_TYPE(struct sockaddr_storage,
 185 [NO_SOCKADDR_STORAGE=],
 186 [NO_SOCKADDR_STORAGE=YesPlease],[
 187 #include <sys/types.h>
 188 #include <sys/socket.h>
 189 ])
 190 AC_SUBST(NO_SOCKADDR_STORAGE)
 191 #
 192 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 193 AC_CHECK_TYPE([struct addrinfo],[
 194  AC_CHECK_FUNC([getaddrinfo],
 195   [NO_IPV6=],
 196   [NO_IPV6=YesPlease])
 197 ],[NO_IPV6=YesPlease],[
 198 #include <sys/types.h>
 199 #include <sys/socket.h>
 200 #include <netdb.h>
 201 ])
 202 AC_SUBST(NO_IPV6)
 203 #
 204 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 205 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 206 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 207 # some C compilers supported these specifiers prior to C99 as an extension.
 208 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 209  [ac_cv_c_c99_format],
 210 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 211 AC_RUN_IFELSE(
 212         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 213                 [[char buf[64];
 214                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 215                   exit(1);
 216                 else if (strcmp(buf, "12345"))
 217                   exit(2);]])],
 218         [ac_cv_c_c99_format=yes],
 219         [ac_cv_c_c99_format=no])
 220 ])
 221 if test $ac_cv_c_c99_format = no; then
 222         NO_C99_FORMAT=YesPlease
 223 else
 224         NO_C99_FORMAT=
 225 fi
 226 AC_SUBST(NO_C99_FORMAT)
 227
 228
 229 ## Checks for library functions.
 230 ## (in default C library and libraries checked by AC_CHECK_LIB)
 231 AC_MSG_NOTICE([CHECKS for library functions])
 232 #
 233 # Define NO_STRCASESTR if you don't have strcasestr.
 234 AC_CHECK_FUNC(strcasestr,
 235 [NO_STRCASESTR=],
 236 [NO_STRCASESTR=YesPlease])
 237 AC_SUBST(NO_STRCASESTR)
 238 #
 239 # Define NO_STRLCPY if you don't have strlcpy.
 240 AC_CHECK_FUNC(strlcpy,
 241 [NO_STRLCPY=],
 242 [NO_STRLCPY=YesPlease])
 243 AC_SUBST(NO_STRLCPY)
 244 #
 245 # Define NO_SETENV if you don't have setenv in the C library.
 246 AC_CHECK_FUNC(setenv,
 247 [NO_SETENV=],
 248 [NO_SETENV=YesPlease])
 249 AC_SUBST(NO_SETENV)
 250 #
 251 # Define NO_MMAP if you want to avoid mmap.
 252 #
 253 # Define NO_ICONV if your libc does not properly support iconv.
 254
 255
 256 ## Other checks.
 257 # Define USE_PIC if you need the main git objects to be built with -fPIC
 258 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 259 #
 260 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 261 # Enable it on Windows.  By default, symrefs are still used.
 262 #
 263 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 264 AC_CACHE_CHECK([for subprocess.py],
 265  [ac_cv_python_has_subprocess_py],
 266 [if $PYTHON_PATH -c 'import subprocess' 2>/dev/null; then
 267         ac_cv_python_has_subprocess_py=yes
 268 else
 269         ac_cv_python_has_subprocess_py=no
 270 fi])
 271 if test $ac_cv_python_has_subprocess_py != yes; then
 272         GIT_CONF_APPEND_LINE([WITH_OWN_SUBPROCESS_PY=YesPlease])
 273 fi
 274 #
 275 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 276 # a missing newline at the end of the file.
 277
 278
 279 ## Site configuration (override autodetection)
 280 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 281 AC_MSG_NOTICE([CHECKS for site configuration])
 282 #
 283 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 284 # tests.  These tests take up a significant amount of the total test time
 285 # but are not needed unless you plan to talk to SVN repos.
 286 #
 287 # Define MOZILLA_SHA1 environment variable when running make to make use of
 288 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 289 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 290 # choice) has very fast version optimized for i586.
 291 #
 292 # Define PPC_SHA1 environment variable when running make to make use of
 293 # a bundled SHA1 routine optimized for PowerPC.
 294 #
 295 # Define ARM_SHA1 environment variable when running make to make use of
 296 # a bundled SHA1 routine optimized for ARM.
 297 #
 298 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 299 # This also implies MOZILLA_SHA1.
 300 #
 301 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 302 # /foo/bar/include and /foo/bar/lib directories.
 303 AC_ARG_WITH(openssl,
 304 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 305 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 306 GIT_PARSE_WITH(openssl))
 307 #
 308 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 309 # git-http-push are not built, and you cannot use http:// and https://
 310 # transports.
 311 #
 312 # Define CURLDIR=/foo/bar if your curl header and library files are in
 313 # /foo/bar/include and /foo/bar/lib directories.
 314 AC_ARG_WITH(curl,
 315 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 316 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 317 GIT_PARSE_WITH(curl))
 318 #
 319 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 320 # not built, and you cannot push using http:// and https:// transports.
 321 #
 322 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 323 # /foo/bar/include and /foo/bar/lib directories.
 324 AC_ARG_WITH(expat,
 325 AS_HELP_STRING([--with-expat],
 326 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 327 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 328 GIT_PARSE_WITH(expat))
 329 #
 330 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 331 # installed in /sw, but don't want GIT to link against any libraries
 332 # installed there.  If defined you may specify your own (or Fink's)
 333 # include directories and library directories by defining CFLAGS
 334 # and LDFLAGS appropriately.
 335 #
 336 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 337 # have DarwinPorts installed in /opt/local, but don't want GIT to
 338 # link against any libraries installed there.  If defined you may
 339 # specify your own (or DarwinPort's) include directories and
 340 # library directories by defining CFLAGS and LDFLAGS appropriately.
 341 #
 342 # Define NO_MMAP if you want to avoid mmap.
 343
 344 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 345 #
 346 # Define COLLISION_CHECK below if you believe that SHA1's
 347 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 348 # sufficient guarantee that no collisions between objects will ever happen.
 349 #
 350 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 351 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 352 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 353 # randomly break unless your underlying filesystem supports those sub-second
 354 # times (my ext3 doesn't).
 355 #
 356 # Define USE_STDEV below if you want git to care about the underlying device
 357 # change being considered an inode change from the update-cache perspective.
 358
 359
 360 ## Output files
 361 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 362 AC_OUTPUT
 363
 364
 365 ## Cleanup
 366 rm -f "${config_append}"