?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
t0021-conversion.sh: Test that the clean filter really cleans content.
[git/dkf.git] / git-svn.perl
blob2c8a1580f8495b0f158802f8513a5df50aca3a02
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
13 $ENV{GIT_DIR} ||= '.git';
14 $Git::SVN::default_repo_id = 'svn';
15 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
16 $Git::SVN::Ra::_log_window_size = 100;
17
18 $Git::SVN::Log::TZ = $ENV{TZ};
19 $ENV{TZ} = 'UTC';
20 $| = 1; # unbuffer STDOUT
21
22 sub fatal (@) { print STDERR @_; exit 1 }
23 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
24 require SVN::Ra;
25 require SVN::Delta;
26 if ($SVN::Core::VERSION lt '1.1.0') {
27 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
28 }
29 push @Git::SVN::Ra::ISA, 'SVN::Ra';
30 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
31 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
32 use Carp qw/croak/;
33 use IO::File qw//;
34 use File::Basename qw/dirname basename/;
35 use File::Path qw/mkpath/;
36 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
37 use IPC::Open3;
38 use Git;
39
40 BEGIN {
41 # import functions from Git into our packages, en masse
42 no strict 'refs';
43 foreach (qw/command command_oneline command_noisy command_output_pipe
44 command_input_pipe command_close_pipe/) {
45 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
46 Git::SVN::Migration Git::SVN::Log Git::SVN),
47 __PACKAGE__) {
48 *{"${package}::$_"} = \&{"Git::$_"};
49 }
50 }
51 }
52
53 my ($SVN);
54
55 $sha1 = qr/[a-f\d]{40}/;
56 $sha1_short = qr/[a-f\d]{4,40}/;
57 my ($_stdin, $_help, $_edit,
58 $_message, $_file,
59 $_template, $_shared,
60 $_version, $_fetch_all, $_no_rebase,
61 $_merge, $_strategy, $_dry_run, $_local,
62 $_prefix, $_no_checkout, $_verbose);
63 $Git::SVN::_follow_parent = 1;
64 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
65 'config-dir=s' => \$Git::SVN::Ra::config_dir,
66 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
67 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
68 'authors-file|A=s' => \$_authors,
69 'repack:i' => \$Git::SVN::_repack,
70 'noMetadata' => \$Git::SVN::_no_metadata,
71 'useSvmProps' => \$Git::SVN::_use_svm_props,
72 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
73 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
74 'no-checkout' => \$_no_checkout,
75 'quiet|q' => \$_q,
76 'repack-flags|repack-args|repack-opts=s' =>
77 \$Git::SVN::_repack_flags,
78 %remote_opts );
79
80 my ($_trunk, $_tags, $_branches, $_stdlayout);
81 my %icv;
82 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
83 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
84 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
85 'stdlayout|s' => \$_stdlayout,
86 'minimize-url|m' => \$Git::SVN::_minimize_url,
87 'no-metadata' => sub { $icv{noMetadata} = 1 },
88 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
89 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
90 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
91 %remote_opts );
92 my %cmt_opts = ( 'edit|e' => \$_edit,
93 'rmdir' => \$SVN::Git::Editor::_rmdir,
94 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
95 'l=i' => \$SVN::Git::Editor::_rename_limit,
96 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
97 );
98
99 my %cmd = (
100 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
101 { 'revision|r=s' => \$_revision,
102 'fetch-all|all' => \$_fetch_all,
103 %fc_opts } ],
104 clone => [ \&cmd_clone, "Initialize and fetch revisions",
105 { 'revision|r=s' => \$_revision,
106 %fc_opts, %init_opts } ],
107 init => [ \&cmd_init, "Initialize a repo for tracking" .
108 " (requires URL argument)",
109 \%init_opts ],
110 'multi-init' => [ \&cmd_multi_init,
111 "Deprecated alias for ".
112 "'$0 init -T<trunk> -b<branches> -t<tags>'",
113 \%init_opts ],
114 dcommit => [ \&cmd_dcommit,
115 'Commit several diffs to merge with upstream',
116 { 'merge|m|M' => \$_merge,
117 'strategy|s=s' => \$_strategy,
118 'verbose|v' => \$_verbose,
119 'dry-run|n' => \$_dry_run,
120 'fetch-all|all' => \$_fetch_all,
121 'no-rebase' => \$_no_rebase,
122 %cmt_opts, %fc_opts } ],
123 'set-tree' => [ \&cmd_set_tree,
124 "Set an SVN repository to a git tree-ish",
125 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
126 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
127 { 'revision|r=i' => \$_revision
128 } ],
129 'multi-fetch' => [ \&cmd_multi_fetch,
130 "Deprecated alias for $0 fetch --all",
131 { 'revision|r=s' => \$_revision, %fc_opts } ],
132 'migrate' => [ sub { },
133 # no-op, we automatically run this anyways,
134 'Migrate configuration/metadata/layout from
135 previous versions of git-svn',
136 { 'minimize' => \$Git::SVN::Migration::_minimize,
137 %remote_opts } ],
138 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
139 { 'limit=i' => \$Git::SVN::Log::limit,
140 'revision|r=s' => \$_revision,
141 'verbose|v' => \$Git::SVN::Log::verbose,
142 'incremental' => \$Git::SVN::Log::incremental,
143 'oneline' => \$Git::SVN::Log::oneline,
144 'show-commit' => \$Git::SVN::Log::show_commit,
145 'non-recursive' => \$Git::SVN::Log::non_recursive,
146 'authors-file|A=s' => \$_authors,
147 'color' => \$Git::SVN::Log::color,
148 'pager=s' => \$Git::SVN::Log::pager
149 } ],
150 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
151 {} ],
152 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
153 { 'merge|m|M' => \$_merge,
154 'verbose|v' => \$_verbose,
155 'strategy|s=s' => \$_strategy,
156 'local|l' => \$_local,
157 'fetch-all|all' => \$_fetch_all,
158 %fc_opts } ],
159 'commit-diff' => [ \&cmd_commit_diff,
160 'Commit a diff between two trees',
161 { 'message|m=s' => \$_message,
162 'file|F=s' => \$_file,
163 'revision|r=s' => \$_revision,
164 %cmt_opts } ],
165 );
166
167 my $cmd;
168 for (my $i = 0; $i < @ARGV; $i++) {
169 if (defined $cmd{$ARGV[$i]}) {
170 $cmd = $ARGV[$i];
171 splice @ARGV, $i, 1;
172 last;
173 }
174 };
175
176 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
177
178 read_repo_config(\%opts);
179 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
180 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
181 'minimize-connections' => \$Git::SVN::Migration::_minimize,
182 'id|i=s' => \$Git::SVN::default_ref_id,
183 'svn-remote|remote|R=s' => sub {
184 $Git::SVN::no_reuse_existing = 1;
185 $Git::SVN::default_repo_id = $_[1] });
186 exit 1 if (!$rv && $cmd && $cmd ne 'log');
187
188 usage(0) if $_help;
189 version() if $_version;
190 usage(1) unless defined $cmd;
191 load_authors() if $_authors;
192
193 # make sure we're always running
194 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
195 unless (-d $ENV{GIT_DIR}) {
196 if ($git_dir_user_set) {
197 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
198 "but it is not a directory\n";
199 }
200 my $git_dir = delete $ENV{GIT_DIR};
201 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
202 unless (length $cdup) {
203 die "Already at toplevel, but $git_dir ",
204 "not found '$cdup'\n";
205 }
206 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
207 unless (-d $git_dir) {
208 die "$git_dir still not found after going to ",
209 "'$cdup'\n";
210 }
211 $ENV{GIT_DIR} = $git_dir;
212 }
213 }
214 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
215 Git::SVN::Migration::migration_check();
216 }
217 Git::SVN::init_vars();
218 eval {
219 Git::SVN::verify_remotes_sanity();
220 $cmd{$cmd}->[0]->(@ARGV);
221 };
222 fatal $@ if $@;
223 post_fetch_checkout();
224 exit 0;
225
226 ####################### primary functions ######################
227 sub usage {
228 my $exit = shift || 0;
229 my $fd = $exit ? \*STDERR : \*STDOUT;
230 print $fd <<"";
231 git-svn - bidirectional operations between a single Subversion tree and git
232 Usage: $0 <command> [options] [arguments]\n
233
234 print $fd "Available commands:\n" unless $cmd;
235
236 foreach (sort keys %cmd) {
237 next if $cmd && $cmd ne $_;
238 next if /^multi-/; # don't show deprecated commands
239 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
240 foreach (keys %{$cmd{$_}->[2]}) {
241 # mixed-case options are for .git/config only
242 next if /[A-Z]/ && /^[a-z]+$/i;
243 # prints out arguments as they should be passed:
244 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
245 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
246 "--$_" : "-$_" }
247 split /\|/,$_)," $x\n";
248 }
249 }
250 print $fd <<"";
251 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
252 arbitrary identifier if you're tracking multiple SVN branches/repositories in
253 one git repository and want to keep them separate. See git-svn(1) for more
254 information.
255
256 exit $exit;
257 }
258
259 sub version {
260 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
261 exit 0;
262 }
263
264 sub do_git_init_db {
265 unless (-d $ENV{GIT_DIR}) {
266 my @init_db = ('init');
267 push @init_db, "--template=$_template" if defined $_template;
268 if (defined $_shared) {
269 if ($_shared =~ /[a-z]/) {
270 push @init_db, "--shared=$_shared";
271 } else {
272 push @init_db, "--shared";
273 }
274 }
275 command_noisy(@init_db);
276 }
277 my $set;
278 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
279 foreach my $i (keys %icv) {
280 die "'$set' and '$i' cannot both be set\n" if $set;
281 next unless defined $icv{$i};
282 command_noisy('config', "$pfx.$i", $icv{$i});
283 $set = $i;
284 }
285 }
286
287 sub init_subdir {
288 my $repo_path = shift or return;
289 mkpath([$repo_path]) unless -d $repo_path;
290 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
291 $ENV{GIT_DIR} = '.git';
292 }
293
294 sub cmd_clone {
295 my ($url, $path) = @_;
296 if (!defined $path &&
297 (defined $_trunk || defined $_branches || defined $_tags ||
298 defined $_stdlayout) &&
299 $url !~ m#^[a-z\+]+://#) {
300 $path = $url;
301 }
302 $path = basename($url) if !defined $path || !length $path;
303 cmd_init($url, $path);
304 Git::SVN::fetch_all($Git::SVN::default_repo_id);
305 }
306
307 sub cmd_init {
308 if (defined $_stdlayout) {
309 $_trunk = 'trunk' if (!defined $_trunk);
310 $_tags = 'tags' if (!defined $_tags);
311 $_branches = 'branches' if (!defined $_branches);
312 }
313 if (defined $_trunk || defined $_branches || defined $_tags) {
314 return cmd_multi_init(@_);
315 }
316 my $url = shift or die "SVN repository location required ",
317 "as a command-line argument\n";
318 init_subdir(@_);
319 do_git_init_db();
320
321 Git::SVN->init($url);
322 }
323
324 sub cmd_fetch {
325 if (grep /^\d+=./, @_) {
326 die "'<rev>=<commit>' fetch arguments are ",
327 "no longer supported.\n";
328 }
329 my ($remote) = @_;
330 if (@_ > 1) {
331 die "Usage: $0 fetch [--all] [svn-remote]\n";
332 }
333 $remote ||= $Git::SVN::default_repo_id;
334 if ($_fetch_all) {
335 cmd_multi_fetch();
336 } else {
337 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
338 }
339 }
340
341 sub cmd_set_tree {
342 my (@commits) = @_;
343 if ($_stdin || !@commits) {
344 print "Reading from stdin...\n";
345 @commits = ();
346 while (<STDIN>) {
347 if (/\b($sha1_short)\b/o) {
348 unshift @commits, $1;
349 }
350 }
351 }
352 my @revs;
353 foreach my $c (@commits) {
354 my @tmp = command('rev-parse',$c);
355 if (scalar @tmp == 1) {
356 push @revs, $tmp[0];
357 } elsif (scalar @tmp > 1) {
358 push @revs, reverse(command('rev-list',@tmp));
359 } else {
360 fatal "Failed to rev-parse $c\n";
361 }
362 }
363 my $gs = Git::SVN->new;
364 my ($r_last, $cmt_last) = $gs->last_rev_commit;
365 $gs->fetch;
366 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
367 fatal "There are new revisions that were fetched ",
368 "and need to be merged (or acknowledged) ",
369 "before committing.\nlast rev: $r_last\n",
370 " current: $gs->{last_rev}\n";
371 }
372 $gs->set_tree($_) foreach @revs;
373 print "Done committing ",scalar @revs," revisions to SVN\n";
374 }
375
376 sub cmd_dcommit {
377 my $head = shift;
378 $head ||= 'HEAD';
379 my @refs;
380 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
381 print "Committing to $url ...\n";
382 unless ($gs) {
383 die "Unable to determine upstream SVN information from ",
384 "$head history\n";
385 }
386 my $last_rev;
387 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
388 if ($_no_rebase && scalar(@$linear_refs) > 1) {
389 warn "Attempting to commit more than one change while ",
390 "--no-rebase is enabled.\n",
391 "If these changes depend on each other, re-running ",
392 "without --no-rebase will be required."
393 }
394 foreach my $d (@$linear_refs) {
395 unless (defined $last_rev) {
396 (undef, $last_rev, undef) = cmt_metadata("$d~1");
397 unless (defined $last_rev) {
398 fatal "Unable to extract revision information ",
399 "from commit $d~1\n";
400 }
401 }
402 if ($_dry_run) {
403 print "diff-tree $d~1 $d\n";
404 } else {
405 my $cmt_rev;
406 my %ed_opts = ( r => $last_rev,
407 log => get_commit_entry($d)->{log},
408 ra => Git::SVN::Ra->new($gs->full_url),
409 tree_a => "$d~1",
410 tree_b => $d,
411 editor_cb => sub {
412 print "Committed r$_[0]\n";
413 $cmt_rev = $_[0];
414 },
415 svn_path => '');
416 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
417 print "No changes\n$d~1 == $d\n";
418 } elsif ($parents->{$d} && @{$parents->{$d}}) {
419 $gs->{inject_parents_dcommit}->{$cmt_rev} =
420 $parents->{$d};
421 }
422 $_fetch_all ? $gs->fetch_all : $gs->fetch;
423 next if $_no_rebase;
424
425 # we always want to rebase against the current HEAD,
426 # not any head that was passed to us
427 my @diff = command('diff-tree', 'HEAD',
428 $gs->refname, '--');
429 my @finish;
430 if (@diff) {
431 @finish = rebase_cmd();
432 print STDERR "W: HEAD and ", $gs->refname,
433 " differ, using @finish:\n",
434 "@diff";
435 } else {
436 print "No changes between current HEAD and ",
437 $gs->refname,
438 "\nResetting to the latest ",
439 $gs->refname, "\n";
440 @finish = qw/reset --mixed/;
441 }
442 command_noisy(@finish, $gs->refname);
443 $last_rev = $cmt_rev;
444 }
445 }
446 }
447
448 sub cmd_find_rev {
449 my $revision_or_hash = shift;
450 my $result;
451 if ($revision_or_hash =~ /^r\d+$/) {
452 my $head = shift;
453 $head ||= 'HEAD';
454 my @refs;
455 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
456 unless ($gs) {
457 die "Unable to determine upstream SVN information from ",
458 "$head history\n";
459 }
460 my $desired_revision = substr($revision_or_hash, 1);
461 $result = $gs->rev_db_get($desired_revision);
462 } else {
463 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
464 $result = $rev;
465 }
466 print "$result\n" if $result;
467 }
468
469 sub cmd_rebase {
470 command_noisy(qw/update-index --refresh/);
471 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
472 unless ($gs) {
473 die "Unable to determine upstream SVN information from ",
474 "working tree history\n";
475 }
476 if (command(qw/diff-index HEAD --/)) {
477 print STDERR "Cannot rebase with uncommited changes:\n";
478 command_noisy('status');
479 exit 1;
480 }
481 unless ($_local) {
482 $_fetch_all ? $gs->fetch_all : $gs->fetch;
483 }
484 command_noisy(rebase_cmd(), $gs->refname);
485 }
486
487 sub cmd_show_ignore {
488 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
489 $gs ||= Git::SVN->new;
490 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
491 $gs->traverse_ignore(\*STDOUT, $gs->{path}, $r);
492 }
493
494 sub cmd_multi_init {
495 my $url = shift;
496 unless (defined $_trunk || defined $_branches || defined $_tags) {
497 usage(1);
498 }
499
500 # there are currently some bugs that prevent multi-init/multi-fetch
501 # setups from working well without this.
502 $Git::SVN::_minimize_url = 1;
503
504 $_prefix = '' unless defined $_prefix;
505 if (defined $url) {
506 $url =~ s#/+$##;
507 init_subdir(@_);
508 }
509 do_git_init_db();
510 if (defined $_trunk) {
511 my $trunk_ref = $_prefix . 'trunk';
512 # try both old-style and new-style lookups:
513 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
514 unless ($gs_trunk) {
515 my ($trunk_url, $trunk_path) =
516 complete_svn_url($url, $_trunk);
517 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
518 undef, $trunk_ref);
519 }
520 }
521 return unless defined $_branches || defined $_tags;
522 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
523 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
524 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
525 }
526
527 sub cmd_multi_fetch {
528 my $remotes = Git::SVN::read_all_remotes();
529 foreach my $repo_id (sort keys %$remotes) {
530 if ($remotes->{$repo_id}->{url}) {
531 Git::SVN::fetch_all($repo_id, $remotes);
532 }
533 }
534 }
535
536 # this command is special because it requires no metadata
537 sub cmd_commit_diff {
538 my ($ta, $tb, $url) = @_;
539 my $usage = "Usage: $0 commit-diff -r<revision> ".
540 "<tree-ish> <tree-ish> [<URL>]\n";
541 fatal($usage) if (!defined $ta || !defined $tb);
542 my $svn_path;
543 if (!defined $url) {
544 my $gs = eval { Git::SVN->new };
545 if (!$gs) {
546 fatal("Needed URL or usable git-svn --id in ",
547 "the command-line\n", $usage);
548 }
549 $url = $gs->{url};
550 $svn_path = $gs->{path};
551 }
552 unless (defined $_revision) {
553 fatal("-r|--revision is a required argument\n", $usage);
554 }
555 if (defined $_message && defined $_file) {
556 fatal("Both --message/-m and --file/-F specified ",
557 "for the commit message.\n",
558 "I have no idea what you mean\n");
559 }
560 if (defined $_file) {
561 $_message = file_to_s($_file);
562 } else {
563 $_message ||= get_commit_entry($tb)->{log};
564 }
565 my $ra ||= Git::SVN::Ra->new($url);
566 $svn_path ||= $ra->{svn_path};
567 my $r = $_revision;
568 if ($r eq 'HEAD') {
569 $r = $ra->get_latest_revnum;
570 } elsif ($r !~ /^\d+$/) {
571 die "revision argument: $r not understood by git-svn\n";
572 }
573 my %ed_opts = ( r => $r,
574 log => $_message,
575 ra => $ra,
576 tree_a => $ta,
577 tree_b => $tb,
578 editor_cb => sub { print "Committed r$_[0]\n" },
579 svn_path => $svn_path );
580 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
581 print "No changes\n$ta == $tb\n";
582 }
583 }
584
585 ########################### utility functions #########################
586
587 sub rebase_cmd {
588 my @cmd = qw/rebase/;
589 push @cmd, '-v' if $_verbose;
590 push @cmd, qw/--merge/ if $_merge;
591 push @cmd, "--strategy=$_strategy" if $_strategy;
592 @cmd;
593 }
594
595 sub post_fetch_checkout {
596 return if $_no_checkout;
597 my $gs = $Git::SVN::_head or return;
598 return if verify_ref('refs/heads/master^0');
599
600 my $valid_head = verify_ref('HEAD^0');
601 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
602 return if ($valid_head || !verify_ref('HEAD^0'));
603
604 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
605 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
606 return if -f $index;
607
608 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
609 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
610 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
611 print STDERR "Checked out HEAD:\n ",
612 $gs->full_url, " r", $gs->last_rev, "\n";
613 }
614
615 sub complete_svn_url {
616 my ($url, $path) = @_;
617 $path =~ s#/+$##;
618 if ($path !~ m#^[a-z\+]+://#) {
619 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
620 fatal("E: '$path' is not a complete URL ",
621 "and a separate URL is not specified\n");
622 }
623 return ($url, $path);
624 }
625 return ($path, '');
626 }
627
628 sub complete_url_ls_init {
629 my ($ra, $repo_path, $switch, $pfx) = @_;
630 unless ($repo_path) {
631 print STDERR "W: $switch not specified\n";
632 return;
633 }
634 $repo_path =~ s#/+$##;
635 if ($repo_path =~ m#^[a-z\+]+://#) {
636 $ra = Git::SVN::Ra->new($repo_path);
637 $repo_path = '';
638 } else {
639 $repo_path =~ s#^/+##;
640 unless ($ra) {
641 fatal("E: '$repo_path' is not a complete URL ",
642 "and a separate URL is not specified\n");
643 }
644 }
645 my $url = $ra->{url};
646 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
647 my $k = "svn-remote.$gs->{repo_id}.url";
648 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
649 if ($orig_url && ($orig_url ne $gs->{url})) {
650 die "$k already set: $orig_url\n",
651 "wanted to set to: $gs->{url}\n";
652 }
653 command_oneline('config', $k, $gs->{url}) unless $orig_url;
654 my $remote_path = "$ra->{svn_path}/$repo_path/*";
655 $remote_path =~ s#/+#/#g;
656 $remote_path =~ s#^/##g;
657 my ($n) = ($switch =~ /^--(\w+)/);
658 if (length $pfx && $pfx !~ m#/$#) {
659 die "--prefix='$pfx' must have a trailing slash '/'\n";
660 }
661 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
662 "$remote_path:refs/remotes/$pfx*");
663 }
664
665 sub verify_ref {
666 my ($ref) = @_;
667 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
668 { STDERR => 0 }); };
669 }
670
671 sub get_tree_from_treeish {
672 my ($treeish) = @_;
673 # $treeish can be a symbolic ref, too:
674 my $type = command_oneline(qw/cat-file -t/, $treeish);
675 my $expected;
676 while ($type eq 'tag') {
677 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
678 }
679 if ($type eq 'commit') {
680 $expected = (grep /^tree /, command(qw/cat-file commit/,
681 $treeish))[0];
682 ($expected) = ($expected =~ /^tree ($sha1)$/o);
683 die "Unable to get tree from $treeish\n" unless $expected;
684 } elsif ($type eq 'tree') {
685 $expected = $treeish;
686 } else {
687 die "$treeish is a $type, expected tree, tag or commit\n";
688 }
689 return $expected;
690 }
691
692 sub get_commit_entry {
693 my ($treeish) = shift;
694 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
695 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
696 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
697 open my $log_fh, '>', $commit_editmsg or croak $!;
698
699 my $type = command_oneline(qw/cat-file -t/, $treeish);
700 if ($type eq 'commit' || $type eq 'tag') {
701 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
702 $type, $treeish);
703 my $in_msg = 0;
704 while (<$msg_fh>) {
705 if (!$in_msg) {
706 $in_msg = 1 if (/^\s*$/);
707 } elsif (/^git-svn-id: /) {
708 # skip this for now, we regenerate the
709 # correct one on re-fetch anyways
710 # TODO: set *:merge properties or like...
711 } else {
712 print $log_fh $_ or croak $!;
713 }
714 }
715 command_close_pipe($msg_fh, $ctx);
716 }
717 close $log_fh or croak $!;
718
719 if ($_edit || ($type eq 'tree')) {
720 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
721 # TODO: strip out spaces, comments, like git-commit.sh
722 system($editor, $commit_editmsg);
723 }
724 rename $commit_editmsg, $commit_msg or croak $!;
725 open $log_fh, '<', $commit_msg or croak $!;
726 { local $/; chomp($log_entry{log} = <$log_fh>); }
727 close $log_fh or croak $!;
728 unlink $commit_msg;
729 \%log_entry;
730 }
731
732 sub s_to_file {
733 my ($str, $file, $mode) = @_;
734 open my $fd,'>',$file or croak $!;
735 print $fd $str,"\n" or croak $!;
736 close $fd or croak $!;
737 chmod ($mode &~ umask, $file) if (defined $mode);
738 }
739
740 sub file_to_s {
741 my $file = shift;
742 open my $fd,'<',$file or croak "$!: file: $file\n";
743 local $/;
744 my $ret = <$fd>;
745 close $fd or croak $!;
746 $ret =~ s/\s*$//s;
747 return $ret;
748 }
749
750 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
751 sub load_authors {
752 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
753 my $log = $cmd eq 'log';
754 while (<$authors>) {
755 chomp;
756 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
757 my ($user, $name, $email) = ($1, $2, $3);
758 if ($log) {
759 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
760 } else {
761 $users{$user} = [$name, $email];
762 }
763 }
764 close $authors or croak $!;
765 }
766
767 # convert GetOpt::Long specs for use by git-config
768 sub read_repo_config {
769 return unless -d $ENV{GIT_DIR};
770 my $opts = shift;
771 my @config_only;
772 foreach my $o (keys %$opts) {
773 # if we have mixedCase and a long option-only, then
774 # it's a config-only variable that we don't need for
775 # the command-line.
776 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
777 my $v = $opts->{$o};
778 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
779 $key =~ s/-//g;
780 my $arg = 'git-config';
781 $arg .= ' --int' if ($o =~ /[:=]i$/);
782 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
783 if (ref $v eq 'ARRAY') {
784 chomp(my @tmp = `$arg --get-all svn.$key`);
785 @$v = @tmp if @tmp;
786 } else {
787 chomp(my $tmp = `$arg --get svn.$key`);
788 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
789 $$v = $tmp;
790 }
791 }
792 }
793 delete @$opts{@config_only} if @config_only;
794 }
795
796 sub extract_metadata {
797 my $id = shift or return (undef, undef, undef);
798 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
799 \s([a-f\d\-]+)$/x);
800 if (!defined $rev || !$uuid || !$url) {
801 # some of the original repositories I made had
802 # identifiers like this:
803 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
804 }
805 return ($url, $rev, $uuid);
806 }
807
808 sub cmt_metadata {
809 return extract_metadata((grep(/^git-svn-id: /,
810 command(qw/cat-file commit/, shift)))[-1]);
811 }
812
813 sub working_head_info {
814 my ($head, $refs) = @_;
815 my @args = ('log', '--no-color', '--first-parent');
816 my ($fh, $ctx) = command_output_pipe(@args, $head);
817 my $hash;
818 my %max;
819 while (<$fh>) {
820 if ( m{^commit ($::sha1)$} ) {
821 unshift @$refs, $hash if $hash and $refs;
822 $hash = $1;
823 next;
824 }
825 next unless s{^\s*(git-svn-id:)}{$1};
826 my ($url, $rev, $uuid) = extract_metadata($_);
827 if (defined $url && defined $rev) {
828 next if $max{$url} and $max{$url} < $rev;
829 if (my $gs = Git::SVN->find_by_url($url)) {
830 my $c = $gs->rev_db_get($rev);
831 if ($c && $c eq $hash) {
832 close $fh; # break the pipe
833 return ($url, $rev, $uuid, $gs);
834 } else {
835 $max{$url} ||= $gs->rev_db_max;
836 }
837 }
838 }
839 }
840 command_close_pipe($fh, $ctx);
841 (undef, undef, undef, undef);
842 }
843
844 sub read_commit_parents {
845 my ($parents, $c) = @_;
846 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
847 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
848 @{$parents->{$c}} = split(/ /, $p);
849 }
850
851 sub linearize_history {
852 my ($gs, $refs) = @_;
853 my %parents;
854 foreach my $c (@$refs) {
855 read_commit_parents(\%parents, $c);
856 }
857
858 my @linear_refs;
859 my %skip = ();
860 my $last_svn_commit = $gs->last_commit;
861 foreach my $c (reverse @$refs) {
862 next if $c eq $last_svn_commit;
863 last if $skip{$c};
864
865 unshift @linear_refs, $c;
866 $skip{$c} = 1;
867
868 # we only want the first parent to diff against for linear
869 # history, we save the rest to inject when we finalize the
870 # svn commit
871 my $fp_a = verify_ref("$c~1");
872 my $fp_b = shift @{$parents{$c}} if $parents{$c};
873 if (!$fp_a || !$fp_b) {
874 die "Commit $c\n",
875 "has no parent commit, and therefore ",
876 "nothing to diff against.\n",
877 "You should be working from a repository ",
878 "originally created by git-svn\n";
879 }
880 if ($fp_a ne $fp_b) {
881 die "$c~1 = $fp_a, however parsing commit $c ",
882 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
883 }
884
885 foreach my $p (@{$parents{$c}}) {
886 $skip{$p} = 1;
887 }
888 }
889 (\@linear_refs, \%parents);
890 }
891
892 package Git::SVN;
893 use strict;
894 use warnings;
895 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
896 $_repack $_repack_flags $_use_svm_props $_head
897 $_use_svnsync_props $no_reuse_existing $_minimize_url/;
898 use Carp qw/croak/;
899 use File::Path qw/mkpath/;
900 use File::Copy qw/copy/;
901 use IPC::Open3;
902
903 my $_repack_nr;
904 # properties that we do not log:
905 my %SKIP_PROP;
906 BEGIN {
907 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
908 svn:special svn:executable
909 svn:entry:committed-rev
910 svn:entry:last-author
911 svn:entry:uuid
912 svn:entry:committed-date/;
913
914 # some options are read globally, but can be overridden locally
915 # per [svn-remote "..."] section. Command-line options will *NOT*
916 # override options set in an [svn-remote "..."] section
917 no strict 'refs';
918 for my $option (qw/follow_parent no_metadata use_svm_props
919 use_svnsync_props/) {
920 my $key = $option;
921 $key =~ tr/_//d;
922 my $prop = "-$option";
923 *$option = sub {
924 my ($self) = @_;
925 return $self->{$prop} if exists $self->{$prop};
926 my $k = "svn-remote.$self->{repo_id}.$key";
927 eval { command_oneline(qw/config --get/, $k) };
928 if ($@) {
929 $self->{$prop} = ${"Git::SVN::_$option"};
930 } else {
931 my $v = command_oneline(qw/config --bool/,$k);
932 $self->{$prop} = $v eq 'false' ? 0 : 1;
933 }
934 return $self->{$prop};
935 }
936 }
937 }
938
939 my %LOCKFILES;
940 END { unlink keys %LOCKFILES if %LOCKFILES }
941
942 sub resolve_local_globs {
943 my ($url, $fetch, $glob_spec) = @_;
944 return unless defined $glob_spec;
945 my $ref = $glob_spec->{ref};
946 my $path = $glob_spec->{path};
947 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
948 next unless m#^refs/remotes/$ref->{regex}$#;
949 my $p = $1;
950 my $pathname = desanitize_refname($path->full_path($p));
951 my $refname = desanitize_refname($ref->full_path($p));
952 if (my $existing = $fetch->{$pathname}) {
953 if ($existing ne $refname) {
954 die "Refspec conflict:\n",
955 "existing: refs/remotes/$existing\n",
956 " globbed: refs/remotes/$refname\n";
957 }
958 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
959 $u =~ s!^\Q$url\E(/|$)!! or die
960 "refs/remotes/$refname: '$url' not found in '$u'\n";
961 if ($pathname ne $u) {
962 warn "W: Refspec glob conflict ",
963 "(ref: refs/remotes/$refname):\n",
964 "expected path: $pathname\n",
965 " real path: $u\n",
966 "Continuing ahead with $u\n";
967 next;
968 }
969 } else {
970 $fetch->{$pathname} = $refname;
971 }
972 }
973 }
974
975 sub parse_revision_argument {
976 my ($base, $head) = @_;
977 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
978 return ($base, $head);
979 }
980 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
981 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
982 return ($head, $head) if ($::_revision eq 'HEAD');
983 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
984 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
985 die "revision argument: $::_revision not understood by git-svn\n";
986 }
987
988 sub fetch_all {
989 my ($repo_id, $remotes) = @_;
990 if (ref $repo_id) {
991 my $gs = $repo_id;
992 $repo_id = undef;
993 $repo_id = $gs->{repo_id};
994 }
995 $remotes ||= read_all_remotes();
996 my $remote = $remotes->{$repo_id} or
997 die "[svn-remote \"$repo_id\"] unknown\n";
998 my $fetch = $remote->{fetch};
999 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1000 my (@gs, @globs);
1001 my $ra = Git::SVN::Ra->new($url);
1002 my $uuid = $ra->get_uuid;
1003 my $head = $ra->get_latest_revnum;
1004 my $base = defined $fetch ? $head : 0;
1005
1006 # read the max revs for wildcard expansion (branches/*, tags/*)
1007 foreach my $t (qw/branches tags/) {
1008 defined $remote->{$t} or next;
1009 push @globs, $remote->{$t};
1010 my $max_rev = eval { tmp_config(qw/--int --get/,
1011 "svn-remote.$repo_id.${t}-maxRev") };
1012 if (defined $max_rev && ($max_rev < $base)) {
1013 $base = $max_rev;
1014 } elsif (!defined $max_rev) {
1015 $base = 0;
1016 }
1017 }
1018
1019 if ($fetch) {
1020 foreach my $p (sort keys %$fetch) {
1021 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1022 my $lr = $gs->rev_db_max;
1023 if (defined $lr) {
1024 $base = $lr if ($lr < $base);
1025 }
1026 push @gs, $gs;
1027 }
1028 }
1029
1030 ($base, $head) = parse_revision_argument($base, $head);
1031 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1032 }
1033
1034 sub read_all_remotes {
1035 my $r = {};
1036 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1037 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1038 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1039 $local_ref =~ s{^/}{};
1040 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1041 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1042 $r->{$1}->{url} = $2;
1043 } elsif (m!^(.+)\.(branches|tags)=
1044 (.*):refs/remotes/(.+)\s*$/!x) {
1045 my ($p, $g) = ($3, $4);
1046 my $rs = $r->{$1}->{$2} = {
1047 t => $2,
1048 remote => $1,
1049 path => Git::SVN::GlobSpec->new($p),
1050 ref => Git::SVN::GlobSpec->new($g) };
1051 if (length($rs->{ref}->{right}) != 0) {
1052 die "The '*' glob character must be the last ",
1053 "character of '$g'\n";
1054 }
1055 }
1056 }
1057 $r;
1058 }
1059
1060 sub init_vars {
1061 if (defined $_repack) {
1062 $_repack = 1000 if ($_repack <= 0);
1063 $_repack_nr = $_repack;
1064 $_repack_flags ||= '-d';
1065 }
1066 }
1067
1068 sub verify_remotes_sanity {
1069 return unless -d $ENV{GIT_DIR};
1070 my %seen;
1071 foreach (command(qw/config -l/)) {
1072 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1073 if ($seen{$1}) {
1074 die "Remote ref refs/remote/$1 is tracked by",
1075 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1076 "Please resolve this ambiguity in ",
1077 "your git configuration file before ",
1078 "continuing\n";
1079 }
1080 $seen{$1} = $_;
1081 }
1082 }
1083 }
1084
1085 # we allow more chars than remotes2config.sh...
1086 sub sanitize_remote_name {
1087 my ($name) = @_;
1088 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1089 $name;
1090 }
1091
1092 sub find_existing_remote {
1093 my ($url, $remotes) = @_;
1094 return undef if $no_reuse_existing;
1095 my $existing;
1096 foreach my $repo_id (keys %$remotes) {
1097 my $u = $remotes->{$repo_id}->{url} or next;
1098 next if $u ne $url;
1099 $existing = $repo_id;
1100 last;
1101 }
1102 $existing;
1103 }
1104
1105 sub init_remote_config {
1106 my ($self, $url, $no_write) = @_;
1107 $url =~ s!/+$!!; # strip trailing slash
1108 my $r = read_all_remotes();
1109 my $existing = find_existing_remote($url, $r);
1110 if ($existing) {
1111 unless ($no_write) {
1112 print STDERR "Using existing ",
1113 "[svn-remote \"$existing\"]\n";
1114 }
1115 $self->{repo_id} = $existing;
1116 } elsif ($_minimize_url) {
1117 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1118 $existing = find_existing_remote($min_url, $r);
1119 if ($existing) {
1120 unless ($no_write) {
1121 print STDERR "Using existing ",
1122 "[svn-remote \"$existing\"]\n";
1123 }
1124 $self->{repo_id} = $existing;
1125 }
1126 if ($min_url ne $url) {
1127 unless ($no_write) {
1128 print STDERR "Using higher level of URL: ",
1129 "$url => $min_url\n";
1130 }
1131 my $old_path = $self->{path};
1132 $self->{path} = $url;
1133 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1134 if (length $old_path) {
1135 $self->{path} .= "/$old_path";
1136 }
1137 $url = $min_url;
1138 }
1139 }
1140 my $orig_url;
1141 if (!$existing) {
1142 # verify that we aren't overwriting anything:
1143 $orig_url = eval {
1144 command_oneline('config', '--get',
1145 "svn-remote.$self->{repo_id}.url")
1146 };
1147 if ($orig_url && ($orig_url ne $url)) {
1148 die "svn-remote.$self->{repo_id}.url already set: ",
1149 "$orig_url\nwanted to set to: $url\n";
1150 }
1151 }
1152 my ($xrepo_id, $xpath) = find_ref($self->refname);
1153 if (defined $xpath) {
1154 die "svn-remote.$xrepo_id.fetch already set to track ",
1155 "$xpath:refs/remotes/", $self->refname, "\n";
1156 }
1157 unless ($no_write) {
1158 command_noisy('config',
1159 "svn-remote.$self->{repo_id}.url", $url);
1160 $self->{path} =~ s{^/}{};
1161 command_noisy('config', '--add',
1162 "svn-remote.$self->{repo_id}.fetch",
1163 "$self->{path}:".$self->refname);
1164 }
1165 $self->{url} = $url;
1166 }
1167
1168 sub find_by_url { # repos_root and, path are optional
1169 my ($class, $full_url, $repos_root, $path) = @_;
1170
1171 return undef unless defined $full_url;
1172 remove_username($full_url);
1173 remove_username($repos_root) if defined $repos_root;
1174 my $remotes = read_all_remotes();
1175 if (defined $full_url && defined $repos_root && !defined $path) {
1176 $path = $full_url;
1177 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1178 }
1179 foreach my $repo_id (keys %$remotes) {
1180 my $u = $remotes->{$repo_id}->{url} or next;
1181 remove_username($u);
1182 next if defined $repos_root && $repos_root ne $u;
1183
1184 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1185 foreach (qw/branches tags/) {
1186 resolve_local_globs($u, $fetch,
1187 $remotes->{$repo_id}->{$_});
1188 }
1189 my $p = $path;
1190 unless (defined $p) {
1191 $p = $full_url;
1192 $p =~ s#^\Q$u\E(?:/|$)## or next;
1193 }
1194 foreach my $f (keys %$fetch) {
1195 next if $f ne $p;
1196 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1197 }
1198 }
1199 undef;
1200 }
1201
1202 sub init {
1203 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1204 my $self = _new($class, $repo_id, $ref_id, $path);
1205 if (defined $url) {
1206 $self->init_remote_config($url, $no_write);
1207 }
1208 $self;
1209 }
1210
1211 sub find_ref {
1212 my ($ref_id) = @_;
1213 foreach (command(qw/config -l/)) {
1214 next unless m!^svn-remote\.(.+)\.fetch=
1215 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1216 my ($repo_id, $path, $ref) = ($1, $2, $3);
1217 if ($ref eq $ref_id) {
1218 $path = '' if ($path =~ m#^\./?#);
1219 return ($repo_id, $path);
1220 }
1221 }
1222 (undef, undef, undef);
1223 }
1224
1225 sub new {
1226 my ($class, $ref_id, $repo_id, $path) = @_;
1227 if (defined $ref_id && !defined $repo_id && !defined $path) {
1228 ($repo_id, $path) = find_ref($ref_id);
1229 if (!defined $repo_id) {
1230 die "Could not find a \"svn-remote.*.fetch\" key ",
1231 "in the repository configuration matching: ",
1232 "refs/remotes/$ref_id\n";
1233 }
1234 }
1235 my $self = _new($class, $repo_id, $ref_id, $path);
1236 if (!defined $self->{path} || !length $self->{path}) {
1237 my $fetch = command_oneline('config', '--get',
1238 "svn-remote.$repo_id.fetch",
1239 ":refs/remotes/$ref_id\$") or
1240 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1241 "\":refs/remotes/$ref_id\$\" in config\n";
1242 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1243 }
1244 $self->{url} = command_oneline('config', '--get',
1245 "svn-remote.$repo_id.url") or
1246 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1247 $self->rebuild;
1248 $self;
1249 }
1250
1251 sub refname {
1252 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1253
1254 # It cannot end with a slash /, we'll throw up on this because
1255 # SVN can't have directories with a slash in their name, either:
1256 if ($refname =~ m{/$}) {
1257 die "ref: '$refname' ends with a trailing slash, this is ",
1258 "not permitted by git nor Subversion\n";
1259 }
1260
1261 # It cannot have ASCII control character space, tilde ~, caret ^,
1262 # colon :, question-mark ?, asterisk *, space, or open bracket [
1263 # anywhere.
1264 #
1265 # Additionally, % must be escaped because it is used for escaping
1266 # and we want our escaped refname to be reversible
1267 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1268
1269 # no slash-separated component can begin with a dot .
1270 # /.* becomes /%2E*
1271 $refname =~ s{/\.}{/%2E}g;
1272
1273 # It cannot have two consecutive dots .. anywhere
1274 # .. becomes %2E%2E
1275 $refname =~ s{\.\.}{%2E%2E}g;
1276
1277 return $refname;
1278 }
1279
1280 sub desanitize_refname {
1281 my ($refname) = @_;
1282 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1283 return $refname;
1284 }
1285
1286 sub svm_uuid {
1287 my ($self) = @_;
1288 return $self->{svm}->{uuid} if $self->svm;
1289 $self->ra;
1290 unless ($self->{svm}) {
1291 die "SVM UUID not cached, and reading remotely failed\n";
1292 }
1293 $self->{svm}->{uuid};
1294 }
1295
1296 sub svm {
1297 my ($self) = @_;
1298 return $self->{svm} if $self->{svm};
1299 my $svm;
1300 # see if we have it in our config, first:
1301 eval {
1302 my $section = "svn-remote.$self->{repo_id}";
1303 $svm = {
1304 source => tmp_config('--get', "$section.svm-source"),
1305 uuid => tmp_config('--get', "$section.svm-uuid"),
1306 replace => tmp_config('--get', "$section.svm-replace"),
1307 }
1308 };
1309 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1310 $self->{svm} = $svm;
1311 }
1312 $self->{svm};
1313 }
1314
1315 sub _set_svm_vars {
1316 my ($self, $ra) = @_;
1317 return $ra if $self->svm;
1318
1319 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1320 "(svm:source, svm:uuid) ",
1321 "from the following URLs:\n" );
1322 sub read_svm_props {
1323 my ($self, $ra, $path, $r) = @_;
1324 my $props = ($ra->get_dir($path, $r))[2];
1325 my $src = $props->{'svm:source'};
1326 my $uuid = $props->{'svm:uuid'};
1327 return undef if (!$src || !$uuid);
1328
1329 chomp($src, $uuid);
1330
1331 $uuid =~ m{^[0-9a-f\-]{30,}$}
1332 or die "doesn't look right - svm:uuid is '$uuid'\n";
1333
1334 # the '!' is used to mark the repos_root!/relative/path
1335 $src =~ s{/?!/?}{/};
1336 $src =~ s{/+$}{}; # no trailing slashes please
1337 # username is of no interest
1338 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1339
1340 my $replace = $ra->{url};
1341 $replace .= "/$path" if length $path;
1342
1343 my $section = "svn-remote.$self->{repo_id}";
1344 tmp_config("$section.svm-source", $src);
1345 tmp_config("$section.svm-replace", $replace);
1346 tmp_config("$section.svm-uuid", $uuid);
1347 $self->{svm} = {
1348 source => $src,
1349 uuid => $uuid,
1350 replace => $replace
1351 };
1352 }
1353
1354 my $r = $ra->get_latest_revnum;
1355 my $path = $self->{path};
1356 my %tried;
1357 while (length $path) {
1358 unless ($tried{"$self->{url}/$path"}) {
1359 return $ra if $self->read_svm_props($ra, $path, $r);
1360 $tried{"$self->{url}/$path"} = 1;
1361 }
1362 $path =~ s#/?[^/]+$##;
1363 }
1364 die "Path: '$path' should be ''\n" if $path ne '';
1365 return $ra if $self->read_svm_props($ra, $path, $r);
1366 $tried{"$self->{url}/$path"} = 1;
1367
1368 if ($ra->{repos_root} eq $self->{url}) {
1369 die @err, (map { " $_\n" } keys %tried), "\n";
1370 }
1371
1372 # nope, make sure we're connected to the repository root:
1373 my $ok;
1374 my @tried_b;
1375 $path = $ra->{svn_path};
1376 $ra = Git::SVN::Ra->new($ra->{repos_root});
1377 while (length $path) {
1378 unless ($tried{"$ra->{url}/$path"}) {
1379 $ok = $self->read_svm_props($ra, $path, $r);
1380 last if $ok;
1381 $tried{"$ra->{url}/$path"} = 1;
1382 }
1383 $path =~ s#/?[^/]+$##;
1384 }
1385 die "Path: '$path' should be ''\n" if $path ne '';
1386 $ok ||= $self->read_svm_props($ra, $path, $r);
1387 $tried{"$ra->{url}/$path"} = 1;
1388 if (!$ok) {
1389 die @err, (map { " $_\n" } keys %tried), "\n";
1390 }
1391 Git::SVN::Ra->new($self->{url});
1392 }
1393
1394 sub svnsync {
1395 my ($self) = @_;
1396 return $self->{svnsync} if $self->{svnsync};
1397
1398 if ($self->no_metadata) {
1399 die "Can't have both 'noMetadata' and ",
1400 "'useSvnsyncProps' options set!\n";
1401 }
1402 if ($self->rewrite_root) {
1403 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1404 "options set!\n";
1405 }
1406
1407 my $svnsync;
1408 # see if we have it in our config, first:
1409 eval {
1410 my $section = "svn-remote.$self->{repo_id}";
1411 $svnsync = {
1412 url => tmp_config('--get', "$section.svnsync-url"),
1413 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1414 }
1415 };
1416 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1417 return $self->{svnsync} = $svnsync;
1418 }
1419
1420 my $err = "useSvnsyncProps set, but failed to read " .
1421 "svnsync property: svn:sync-from-";
1422 my $rp = $self->ra->rev_proplist(0);
1423
1424 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1425 $url =~ m{^[a-z\+]+://} or
1426 die "doesn't look right - svn:sync-from-url is '$url'\n";
1427
1428 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1429 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1430 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1431
1432 my $section = "svn-remote.$self->{repo_id}";
1433 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1434 tmp_config('--add', "$section.svnsync-url", $url);
1435 return $self->{svnsync} = { url => $url, uuid => $uuid };
1436 }
1437
1438 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1439 # remote lookup (useful for 'git svn log').
1440 sub ra_uuid {
1441 my ($self) = @_;
1442 unless ($self->{ra_uuid}) {
1443 my $key = "svn-remote.$self->{repo_id}.uuid";
1444 my $uuid = eval { tmp_config('--get', $key) };
1445 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1446 $self->{ra_uuid} = $uuid;
1447 } else {
1448 die "ra_uuid called without URL\n" unless $self->{url};
1449 $self->{ra_uuid} = $self->ra->get_uuid;
1450 tmp_config('--add', $key, $self->{ra_uuid});
1451 }
1452 }
1453 $self->{ra_uuid};
1454 }
1455
1456 sub ra {
1457 my ($self) = shift;
1458 my $ra = Git::SVN::Ra->new($self->{url});
1459 if ($self->use_svm_props && !$self->{svm}) {
1460 if ($self->no_metadata) {
1461 die "Can't have both 'noMetadata' and ",
1462 "'useSvmProps' options set!\n";
1463 } elsif ($self->use_svnsync_props) {
1464 die "Can't have both 'useSvnsyncProps' and ",
1465 "'useSvmProps' options set!\n";
1466 }
1467 $ra = $self->_set_svm_vars($ra);
1468 $self->{-want_revprops} = 1;
1469 }
1470 $ra;
1471 }
1472
1473 sub rel_path {
1474 my ($self) = @_;
1475 my $repos_root = $self->ra->{repos_root};
1476 return $self->{path} if ($self->{url} eq $repos_root);
1477 my $url = $self->{url} .
1478 (length $self->{path} ? "/$self->{path}" : $self->{path});
1479 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1480 $url;
1481 }
1482
1483 sub traverse_ignore {
1484 my ($self, $fh, $path, $r) = @_;
1485 $path =~ s#^/+##g;
1486 my $ra = $self->ra;
1487 my ($dirent, undef, $props) = $ra->get_dir($path, $r);
1488 my $p = $path;
1489 $p =~ s#^\Q$self->{path}\E(/|$)##;
1490 print $fh length $p ? "\n# $p\n" : "\n# /\n";
1491 if (my $s = $props->{'svn:ignore'}) {
1492 $s =~ s/[\r\n]+/\n/g;
1493 chomp $s;
1494 if (length $p == 0) {
1495 $s =~ s#\n#\n/$p#g;
1496 print $fh "/$s\n";
1497 } else {
1498 $s =~ s#\n#\n/$p/#g;
1499 print $fh "/$p/$s\n";
1500 }
1501 }
1502 foreach (sort keys %$dirent) {
1503 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1504 $self->traverse_ignore($fh, "$path/$_", $r);
1505 }
1506 }
1507
1508 sub last_rev { ($_[0]->last_rev_commit)[0] }
1509 sub last_commit { ($_[0]->last_rev_commit)[1] }
1510
1511 # returns the newest SVN revision number and newest commit SHA1
1512 sub last_rev_commit {
1513 my ($self) = @_;
1514 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1515 return ($self->{last_rev}, $self->{last_commit});
1516 }
1517 my $c = ::verify_ref($self->refname.'^0');
1518 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1519 my $rev = (::cmt_metadata($c))[1];
1520 if (defined $rev) {
1521 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1522 return ($rev, $c);
1523 }
1524 }
1525 my $db_path = $self->db_path;
1526 unless (-e $db_path) {
1527 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1528 return (undef, undef);
1529 }
1530 my $offset = -41; # from tail
1531 my $rl;
1532 open my $fh, '<', $db_path or croak "$db_path not readable: $!\n";
1533 sysseek($fh, $offset, 2); # don't care for errors
1534 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1535 chomp $rl;
1536 while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
1537 $offset -= 41;
1538 sysseek($fh, $offset, 2); # don't care for errors
1539 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1540 chomp $rl;
1541 }
1542 if ($c && $c ne $rl) {
1543 die "$db_path and ", $self->refname,
1544 " inconsistent!:\n$c != $rl\n";
1545 }
1546 my $rev = sysseek($fh, 0, 1) or croak $!;
1547 $rev = ($rev - 41) / 41;
1548 close $fh or croak $!;
1549 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1550 return ($rev, $c);
1551 }
1552
1553 sub get_fetch_range {
1554 my ($self, $min, $max) = @_;
1555 $max ||= $self->ra->get_latest_revnum;
1556 $min ||= $self->rev_db_max;
1557 (++$min, $max);
1558 }
1559
1560 sub tmp_config {
1561 my (@args) = @_;
1562 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1563 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1564 if (! -f $config && -f $old_def_config) {
1565 rename $old_def_config, $config or
1566 die "Failed rename $old_def_config => $config: $!\n";
1567 }
1568 my $old_config = $ENV{GIT_CONFIG};
1569 $ENV{GIT_CONFIG} = $config;
1570 $@ = undef;
1571 my @ret = eval {
1572 unless (-f $config) {
1573 mkfile($config);
1574 open my $fh, '>', $config or
1575 die "Can't open $config: $!\n";
1576 print $fh "; This file is used internally by ",
1577 "git-svn\n" or die
1578 "Couldn't write to $config: $!\n";
1579 print $fh "; You should not have to edit it\n" or
1580 die "Couldn't write to $config: $!\n";
1581 close $fh or die "Couldn't close $config: $!\n";
1582 }
1583 command('config', @args);
1584 };
1585 my $err = $@;
1586 if (defined $old_config) {
1587 $ENV{GIT_CONFIG} = $old_config;
1588 } else {
1589 delete $ENV{GIT_CONFIG};
1590 }
1591 die $err if $err;
1592 wantarray ? @ret : $ret[0];
1593 }
1594
1595 sub tmp_index_do {
1596 my ($self, $sub) = @_;
1597 my $old_index = $ENV{GIT_INDEX_FILE};
1598 $ENV{GIT_INDEX_FILE} = $self->{index};
1599 $@ = undef;
1600 my @ret = eval {
1601 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1602 mkpath([$dir]) unless -d $dir;
1603 &$sub;
1604 };
1605 my $err = $@;
1606 if (defined $old_index) {
1607 $ENV{GIT_INDEX_FILE} = $old_index;
1608 } else {
1609 delete $ENV{GIT_INDEX_FILE};
1610 }
1611 die $err if $err;
1612 wantarray ? @ret : $ret[0];
1613 }
1614
1615 sub assert_index_clean {
1616 my ($self, $treeish) = @_;
1617
1618 $self->tmp_index_do(sub {
1619 command_noisy('read-tree', $treeish) unless -e $self->{index};
1620 my $x = command_oneline('write-tree');
1621 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1622 /^tree ($::sha1)/mo);
1623 return if $y eq $x;
1624
1625 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1626 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1627 command_noisy('read-tree', $treeish);
1628 $x = command_oneline('write-tree');
1629 if ($y ne $x) {
1630 ::fatal "trees ($treeish) $y != $x\n",
1631 "Something is seriously wrong...\n";
1632 }
1633 });
1634 }
1635
1636 sub get_commit_parents {
1637 my ($self, $log_entry) = @_;
1638 my (%seen, @ret, @tmp);
1639 # legacy support for 'set-tree'; this is only used by set_tree_cb:
1640 if (my $ip = $self->{inject_parents}) {
1641 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1642 push @tmp, $commit;
1643 }
1644 }
1645 if (my $cur = ::verify_ref($self->refname.'^0')) {
1646 push @tmp, $cur;
1647 }
1648 if (my $ipd = $self->{inject_parents_dcommit}) {
1649 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
1650 push @tmp, @$commit;
1651 }
1652 }
1653 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1654 while (my $p = shift @tmp) {
1655 next if $seen{$p};
1656 $seen{$p} = 1;
1657 push @ret, $p;
1658 # MAXPARENT is defined to 16 in commit-tree.c:
1659 last if @ret >= 16;
1660 }
1661 if (@tmp) {
1662 die "r$log_entry->{revision}: No room for parents:\n\t",
1663 join("\n\t", @tmp), "\n";
1664 }
1665 @ret;
1666 }
1667
1668 sub rewrite_root {
1669 my ($self) = @_;
1670 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
1671 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
1672 my $rwr = eval { command_oneline(qw/config --get/, $k) };
1673 if ($rwr) {
1674 $rwr =~ s#/+$##;
1675 if ($rwr !~ m#^[a-z\+]+://#) {
1676 die "$rwr is not a valid URL (key: $k)\n";
1677 }
1678 }
1679 $self->{-rewrite_root} = $rwr;
1680 }
1681
1682 sub metadata_url {
1683 my ($self) = @_;
1684 ($self->rewrite_root || $self->{url}) .
1685 (length $self->{path} ? '/' . $self->{path} : '');
1686 }
1687
1688 sub full_url {
1689 my ($self) = @_;
1690 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1691 }
1692
1693 sub do_git_commit {
1694 my ($self, $log_entry) = @_;
1695 my $lr = $self->last_rev;
1696 if (defined $lr && $lr >= $log_entry->{revision}) {
1697 die "Last fetched revision of ", $self->refname,
1698 " was r$lr, but we are about to fetch: ",
1699 "r$log_entry->{revision}!\n";
1700 }
1701 if (my $c = $self->rev_db_get($log_entry->{revision})) {
1702 croak "$log_entry->{revision} = $c already exists! ",
1703 "Why are we refetching it?\n";
1704 }
1705 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $log_entry->{name};
1706 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} =
1707 $log_entry->{email};
1708 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1709
1710 my $tree = $log_entry->{tree};
1711 if (!defined $tree) {
1712 $tree = $self->tmp_index_do(sub {
1713 command_oneline('write-tree') });
1714 }
1715 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1716
1717 my @exec = ('git-commit-tree', $tree);
1718 foreach ($self->get_commit_parents($log_entry)) {
1719 push @exec, '-p', $_;
1720 }
1721 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1722 or croak $!;
1723 print $msg_fh $log_entry->{log} or croak $!;
1724 unless ($self->no_metadata) {
1725 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1726 or croak $!;
1727 }
1728 $msg_fh->flush == 0 or croak $!;
1729 close $msg_fh or croak $!;
1730 chomp(my $commit = do { local $/; <$out_fh> });
1731 close $out_fh or croak $!;
1732 waitpid $pid, 0;
1733 croak $? if $?;
1734 if ($commit !~ /^$::sha1$/o) {
1735 die "Failed to commit, invalid sha1: $commit\n";
1736 }
1737
1738 $self->rev_db_set($log_entry->{revision}, $commit, 1);
1739
1740 $self->{last_rev} = $log_entry->{revision};
1741 $self->{last_commit} = $commit;
1742 print "r$log_entry->{revision}";
1743 if (defined $log_entry->{svm_revision}) {
1744 print " (\@$log_entry->{svm_revision})";
1745 $self->rev_db_set($log_entry->{svm_revision}, $commit,
1746 0, $self->svm_uuid);
1747 }
1748 print " = $commit ($self->{ref_id})\n";
1749 if (defined $_repack && (--$_repack_nr == 0)) {
1750 $_repack_nr = $_repack;
1751 # repack doesn't use any arguments with spaces in them, does it?
1752 print "Running git repack $_repack_flags ...\n";
1753 command_noisy('repack', split(/\s+/, $_repack_flags));
1754 print "Done repacking\n";
1755 }
1756 return $commit;
1757 }
1758
1759 sub match_paths {
1760 my ($self, $paths, $r) = @_;
1761 return 1 if $self->{path} eq '';
1762 if (my $path = $paths->{"/$self->{path}"}) {
1763 return ($path->{action} eq 'D') ? 0 : 1;
1764 }
1765 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
1766 if (grep /$self->{path_regex}/, keys %$paths) {
1767 return 1;
1768 }
1769 my $c = '';
1770 foreach (split m#/#, $self->{path}) {
1771 $c .= "/$_";
1772 next unless ($paths->{$c} &&
1773 ($paths->{$c}->{action} =~ /^[AR]$/));
1774 if ($self->ra->check_path($self->{path}, $r) ==
1775 $SVN::Node::dir) {
1776 return 1;
1777 }
1778 }
1779 return 0;
1780 }
1781
1782 sub find_parent_branch {
1783 my ($self, $paths, $rev) = @_;
1784 return undef unless $self->follow_parent;
1785 unless (defined $paths) {
1786 my $err_handler = $SVN::Error::handler;
1787 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1788 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1789 $paths =
1790 Git::SVN::Ra::dup_changed_paths($_[0]) });
1791 $SVN::Error::handler = $err_handler;
1792 }
1793 return undef unless defined $paths;
1794
1795 # look for a parent from another branch:
1796 my @b_path_components = split m#/#, $self->rel_path;
1797 my @a_path_components;
1798 my $i;
1799 while (@b_path_components) {
1800 $i = $paths->{'/'.join('/', @b_path_components)};
1801 last if $i && defined $i->{copyfrom_path};
1802 unshift(@a_path_components, pop(@b_path_components));
1803 }
1804 return undef unless defined $i && defined $i->{copyfrom_path};
1805 my $branch_from = $i->{copyfrom_path};
1806 if (@a_path_components) {
1807 print STDERR "branch_from: $branch_from => ";
1808 $branch_from .= '/'.join('/', @a_path_components);
1809 print STDERR $branch_from, "\n";
1810 }
1811 my $r = $i->{copyfrom_rev};
1812 my $repos_root = $self->ra->{repos_root};
1813 my $url = $self->ra->{url};
1814 my $new_url = $repos_root . $branch_from;
1815 print STDERR "Found possible branch point: ",
1816 "$new_url => ", $self->full_url, ", $r\n";
1817 $branch_from =~ s#^/##;
1818 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
1819 unless ($gs) {
1820 my $ref_id = $self->{ref_id};
1821 $ref_id =~ s/\@\d+$//;
1822 $ref_id .= "\@$r";
1823 # just grow a tail if we're not unique enough :x
1824 $ref_id .= '-' while find_ref($ref_id);
1825 print STDERR "Initializing parent: $ref_id\n";
1826 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1827 }
1828 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1829 if (!defined $r0 || !defined $parent) {
1830 my ($base, $head) = parse_revision_argument(0, $r);
1831 if ($base <= $r) {
1832 $gs->fetch($base, $r);
1833 }
1834 ($r0, $parent) = $gs->last_rev_commit;
1835 }
1836 if (defined $r0 && defined $parent) {
1837 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1838 my $ed;
1839 if ($self->ra->can_do_switch) {
1840 $self->assert_index_clean($parent);
1841 print STDERR "Following parent with do_switch\n";
1842 # do_switch works with svn/trunk >= r22312, but that
1843 # is not included with SVN 1.4.3 (the latest version
1844 # at the moment), so we can't rely on it
1845 $self->{last_commit} = $parent;
1846 $ed = SVN::Git::Fetcher->new($self);
1847 $gs->ra->gs_do_switch($r0, $rev, $gs,
1848 $self->full_url, $ed)
1849 or die "SVN connection failed somewhere...\n";
1850 } elsif ($self->ra->trees_match($new_url, $r0,
1851 $self->full_url, $rev)) {
1852 print STDERR "Trees match:\n",
1853 " $new_url\@$r0\n",
1854 " ${\$self->full_url}\@$rev\n",
1855 "Following parent with no changes\n";
1856 $self->tmp_index_do(sub {
1857 command_noisy('read-tree', $parent);
1858 });
1859 $self->{last_commit} = $parent;
1860 } else {
1861 print STDERR "Following parent with do_update\n";
1862 $ed = SVN::Git::Fetcher->new($self);
1863 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1864 or die "SVN connection failed somewhere...\n";
1865 }
1866 print STDERR "Successfully followed parent\n";
1867 return $self->make_log_entry($rev, [$parent], $ed);
1868 }
1869 return undef;
1870 }
1871
1872 sub do_fetch {
1873 my ($self, $paths, $rev) = @_;
1874 my $ed;
1875 my ($last_rev, @parents);
1876 if (my $lc = $self->last_commit) {
1877 # we can have a branch that was deleted, then re-added
1878 # under the same name but copied from another path, in
1879 # which case we'll have multiple parents (we don't
1880 # want to break the original ref, nor lose copypath info):
1881 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1882 push @{$log_entry->{parents}}, $lc;
1883 return $log_entry;
1884 }
1885 $ed = SVN::Git::Fetcher->new($self);
1886 $last_rev = $self->{last_rev};
1887 $ed->{c} = $lc;
1888 @parents = ($lc);
1889 } else {
1890 $last_rev = $rev;
1891 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1892 return $log_entry;
1893 }
1894 $ed = SVN::Git::Fetcher->new($self);
1895 }
1896 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1897 die "SVN connection failed somewhere...\n";
1898 }
1899 $self->make_log_entry($rev, \@parents, $ed);
1900 }
1901
1902 sub get_untracked {
1903 my ($self, $ed) = @_;
1904 my @out;
1905 my $h = $ed->{empty};
1906 foreach (sort keys %$h) {
1907 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1908 push @out, " $act: " . uri_encode($_);
1909 warn "W: $act: $_\n";
1910 }
1911 foreach my $t (qw/dir_prop file_prop/) {
1912 $h = $ed->{$t} or next;
1913 foreach my $path (sort keys %$h) {
1914 my $ppath = $path eq '' ? '.' : $path;
1915 foreach my $prop (sort keys %{$h->{$path}}) {
1916 next if $SKIP_PROP{$prop};
1917 my $v = $h->{$path}->{$prop};
1918 my $t_ppath_prop = "$t: " .
1919 uri_encode($ppath) . ' ' .
1920 uri_encode($prop);
1921 if (defined $v) {
1922 push @out, " +$t_ppath_prop " .
1923 uri_encode($v);
1924 } else {
1925 push @out, " -$t_ppath_prop";
1926 }
1927 }
1928 }
1929 }
1930 foreach my $t (qw/absent_file absent_directory/) {
1931 $h = $ed->{$t} or next;
1932 foreach my $parent (sort keys %$h) {
1933 foreach my $path (sort @{$h->{$parent}}) {
1934 push @out, " $t: " .
1935 uri_encode("$parent/$path");
1936 warn "W: $t: $parent/$path ",
1937 "Insufficient permissions?\n";
1938 }
1939 }
1940 }
1941 \@out;
1942 }
1943
1944 sub parse_svn_date {
1945 my $date = shift || return '+0000 1970-01-01 00:00:00';
1946 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1947 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1948 croak "Unable to parse date: $date\n";
1949 "+0000 $Y-$m-$d $H:$M:$S";
1950 }
1951
1952 sub check_author {
1953 my ($author) = @_;
1954 if (!defined $author || length $author == 0) {
1955 $author = '(no author)';
1956 }
1957 if (defined $::_authors && ! defined $::users{$author}) {
1958 die "Author: $author not defined in $::_authors file\n";
1959 }
1960 $author;
1961 }
1962
1963 sub make_log_entry {
1964 my ($self, $rev, $parents, $ed) = @_;
1965 my $untracked = $self->get_untracked($ed);
1966
1967 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1968 print $un "r$rev\n" or croak $!;
1969 print $un $_, "\n" foreach @$untracked;
1970 my %log_entry = ( parents => $parents || [], revision => $rev,
1971 log => '');
1972
1973 my $headrev;
1974 my $logged = delete $self->{logged_rev_props};
1975 if (!$logged || $self->{-want_revprops}) {
1976 my $rp = $self->ra->rev_proplist($rev);
1977 foreach (sort keys %$rp) {
1978 my $v = $rp->{$_};
1979 if (/^svn:(author|date|log)$/) {
1980 $log_entry{$1} = $v;
1981 } elsif ($_ eq 'svm:headrev') {
1982 $headrev = $v;
1983 } else {
1984 print $un " rev_prop: ", uri_encode($_), ' ',
1985 uri_encode($v), "\n";
1986 }
1987 }
1988 } else {
1989 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1990 }
1991 close $un or croak $!;
1992
1993 $log_entry{date} = parse_svn_date($log_entry{date});
1994 $log_entry{log} .= "\n";
1995 my $author = $log_entry{author} = check_author($log_entry{author});
1996 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1997 : ($author, undef);
1998 if (defined $headrev && $self->use_svm_props) {
1999 if ($self->rewrite_root) {
2000 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2001 "options set!\n";
2002 }
2003 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2004 # we don't want "SVM: initializing mirror for junk" ...
2005 return undef if $r == 0;
2006 my $svm = $self->svm;
2007 if ($uuid ne $svm->{uuid}) {
2008 die "UUID mismatch on SVM path:\n",
2009 "expected: $svm->{uuid}\n",
2010 " got: $uuid\n";
2011 }
2012 my $full_url = $self->full_url;
2013 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2014 die "Failed to replace '$svm->{replace}' with ",
2015 "'$svm->{source}' in $full_url\n";
2016 # throw away username for storing in records
2017 remove_username($full_url);
2018 $log_entry{metadata} = "$full_url\@$r $uuid";
2019 $log_entry{svm_revision} = $r;
2020 $email ||= "$author\@$uuid"
2021 } elsif ($self->use_svnsync_props) {
2022 my $full_url = $self->svnsync->{url};
2023 $full_url .= "/$self->{path}" if length $self->{path};
2024 remove_username($full_url);
2025 my $uuid = $self->svnsync->{uuid};
2026 $log_entry{metadata} = "$full_url\@$rev $uuid";
2027 $email ||= "$author\@$uuid"
2028 } else {
2029 my $url = $self->metadata_url;
2030 remove_username($url);
2031 $log_entry{metadata} = "$url\@$rev " .
2032 $self->ra->get_uuid;
2033 $email ||= "$author\@" . $self->ra->get_uuid;
2034 }
2035 $log_entry{name} = $name;
2036 $log_entry{email} = $email;
2037 \%log_entry;
2038 }
2039
2040 sub fetch {
2041 my ($self, $min_rev, $max_rev, @parents) = @_;
2042 my ($last_rev, $last_commit) = $self->last_rev_commit;
2043 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2044 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2045 }
2046
2047 sub set_tree_cb {
2048 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2049 $self->{inject_parents} = { $rev => $tree };
2050 $self->fetch(undef, undef);
2051 }
2052
2053 sub set_tree {
2054 my ($self, $tree) = (shift, shift);
2055 my $log_entry = ::get_commit_entry($tree);
2056 unless ($self->{last_rev}) {
2057 fatal("Must have an existing revision to commit\n");
2058 }
2059 my %ed_opts = ( r => $self->{last_rev},
2060 log => $log_entry->{log},
2061 ra => $self->ra,
2062 tree_a => $self->{last_commit},
2063 tree_b => $tree,
2064 editor_cb => sub {
2065 $self->set_tree_cb($log_entry, $tree, @_) },
2066 svn_path => $self->{path} );
2067 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2068 print "No changes\nr$self->{last_rev} = $tree\n";
2069 }
2070 }
2071
2072 sub rebuild {
2073 my ($self) = @_;
2074 my $db_path = $self->db_path;
2075 return if (-e $db_path && ! -z $db_path);
2076 return unless ::verify_ref($self->refname.'^0');
2077 if (-f $self->{db_root}) {
2078 rename $self->{db_root}, $db_path or die
2079 "rename $self->{db_root} => $db_path failed: $!\n";
2080 my ($dir, $base) = ($db_path =~ m#^(.*?)/?([^/]+)$#);
2081 symlink $base, $self->{db_root} or die
2082 "symlink $base => $self->{db_root} failed: $!\n";
2083 return;
2084 }
2085 print "Rebuilding $db_path ...\n";
2086 my ($log, $ctx) = command_output_pipe("log", '--no-color', $self->refname);
2087 my $latest;
2088 my $full_url = $self->full_url;
2089 remove_username($full_url);
2090 my $svn_uuid;
2091 my $c;
2092 while (<$log>) {
2093 if ( m{^commit ($::sha1)$} ) {
2094 $c = $1;
2095 next;
2096 }
2097 next unless s{^\s*(git-svn-id:)}{$1};
2098 my ($url, $rev, $uuid) = ::extract_metadata($_);
2099 remove_username($url);
2100
2101 # ignore merges (from set-tree)
2102 next if (!defined $rev || !$uuid);
2103
2104 # if we merged or otherwise started elsewhere, this is
2105 # how we break out of it
2106 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
2107 ($full_url && $url && ($url ne $full_url))) {
2108 next;
2109 }
2110 $latest ||= $rev;
2111 $svn_uuid ||= $uuid;
2112
2113 $self->rev_db_set($rev, $c);
2114 print "r$rev = $c\n";
2115 }
2116 command_close_pipe($log, $ctx);
2117 print "Done rebuilding $db_path\n";
2118 }
2119
2120 # rev_db:
2121 # Tie::File seems to be prone to offset errors if revisions get sparse,
2122 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2123 # one of my favorite modules is out :< Next up would be one of the DBM
2124 # modules, but I'm not sure which is most portable... So I'll just
2125 # go with something that's plain-text, but still capable of
2126 # being randomly accessed. So here's my ultra-simple fixed-width
2127 # database. All records are 40 characters + "\n", so it's easy to seek
2128 # to a revision: (41 * rev) is the byte offset.
2129 # A record of 40 0s denotes an empty revision.
2130 # And yes, it's still pretty fast (faster than Tie::File).
2131 # These files are disposable unless noMetadata or useSvmProps is set
2132
2133 sub _rev_db_set {
2134 my ($fh, $rev, $commit) = @_;
2135 my $offset = $rev * 41;
2136 # assume that append is the common case:
2137 seek $fh, 0, 2 or croak $!;
2138 my $pos = tell $fh;
2139 if ($pos < $offset) {
2140 for (1 .. (($offset - $pos) / 41)) {
2141 print $fh (('0' x 40),"\n") or croak $!;
2142 }
2143 }
2144 seek $fh, $offset, 0 or croak $!;
2145 print $fh $commit,"\n" or croak $!;
2146 }
2147
2148 sub mkfile {
2149 my ($path) = @_;
2150 unless (-e $path) {
2151 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2152 mkpath([$dir]) unless -d $dir;
2153 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2154 close $fh or die "Couldn't close (create) $path: $!\n";
2155 }
2156 }
2157
2158 sub rev_db_set {
2159 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2160 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2161 my $db = $self->db_path($uuid);
2162 my $db_lock = "$db.lock";
2163 my $sig;
2164 if ($update_ref) {
2165 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2166 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2167 }
2168 mkfile($db);
2169
2170 $LOCKFILES{$db_lock} = 1;
2171 my $sync;
2172 # both of these options make our .rev_db file very, very important
2173 # and we can't afford to lose it because rebuild() won't work
2174 if ($self->use_svm_props || $self->no_metadata) {
2175 $sync = 1;
2176 copy($db, $db_lock) or die "rev_db_set(@_): ",
2177 "Failed to copy: ",
2178 "$db => $db_lock ($!)\n";
2179 } else {
2180 rename $db, $db_lock or die "rev_db_set(@_): ",
2181 "Failed to rename: ",
2182 "$db => $db_lock ($!)\n";
2183 }
2184 open my $fh, '+<', $db_lock or die "Couldn't open $db_lock: $!\n";
2185 _rev_db_set($fh, $rev, $commit);
2186 if ($sync) {
2187 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2188 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2189 }
2190 close $fh or croak $!;
2191 if ($update_ref) {
2192 $_head = $self;
2193 command_noisy('update-ref', '-m', "r$rev",
2194 $self->refname, $commit);
2195 }
2196 rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
2197 "$db_lock => $db ($!)\n";
2198 delete $LOCKFILES{$db_lock};
2199 if ($update_ref) {
2200 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2201 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2202 kill $sig, $$ if defined $sig;
2203 }
2204 }
2205
2206 sub rev_db_max {
2207 my ($self) = @_;
2208 $self->rebuild;
2209 my $db_path = $self->db_path;
2210 my @stat = stat $db_path or return 0;
2211 ($stat[7] % 41) == 0 or die "$db_path inconsistent size: $stat[7]\n";
2212 my $max = $stat[7] / 41;
2213 (($max > 0) ? $max - 1 : 0);
2214 }
2215
2216 sub rev_db_get {
2217 my ($self, $rev, $uuid) = @_;
2218 my $ret;
2219 my $offset = $rev * 41;
2220 my $db_path = $self->db_path($uuid);
2221 return undef unless -e $db_path;
2222 open my $fh, '<', $db_path or croak $!;
2223 if (sysseek($fh, $offset, 0) == $offset) {
2224 my $read = sysread($fh, $ret, 40);
2225 $ret = undef if ($read != 40 || $ret eq ('0'x40));
2226 }
2227 close $fh or croak $!;
2228 $ret;
2229 }
2230
2231 sub find_rev_before {
2232 my ($self, $rev, $eq_ok) = @_;
2233 --$rev unless $eq_ok;
2234 while ($rev > 0) {
2235 if (my $c = $self->rev_db_get($rev)) {
2236 return ($rev, $c);
2237 }
2238 --$rev;
2239 }
2240 return (undef, undef);
2241 }
2242
2243 sub _new {
2244 my ($class, $repo_id, $ref_id, $path) = @_;
2245 unless (defined $repo_id && length $repo_id) {
2246 $repo_id = $Git::SVN::default_repo_id;
2247 }
2248 unless (defined $ref_id && length $ref_id) {
2249 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2250 }
2251 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2252 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2253 $_[3] = $path = '' unless (defined $path);
2254 mkpath(["$ENV{GIT_DIR}/svn"]);
2255 bless {
2256 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2257 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2258 db_root => "$dir/.rev_db", repo_id => $repo_id }, $class;
2259 }
2260
2261 sub db_path {
2262 my ($self, $uuid) = @_;
2263 $uuid ||= $self->ra_uuid;
2264 "$self->{db_root}.$uuid";
2265 }
2266
2267 sub uri_encode {
2268 my ($f) = @_;
2269 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2270 $f
2271 }
2272
2273 sub remove_username {
2274 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2275 }
2276
2277 package Git::SVN::Prompt;
2278 use strict;
2279 use warnings;
2280 require SVN::Core;
2281 use vars qw/$_no_auth_cache $_username/;
2282
2283 sub simple {
2284 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2285 $may_save = undef if $_no_auth_cache;
2286 $default_username = $_username if defined $_username;
2287 if (defined $default_username && length $default_username) {
2288 if (defined $realm && length $realm) {
2289 print STDERR "Authentication realm: $realm\n";
2290 STDERR->flush;
2291 }
2292 $cred->username($default_username);
2293 } else {
2294 username($cred, $realm, $may_save, $pool);
2295 }
2296 $cred->password(_read_password("Password for '" .
2297 $cred->username . "': ", $realm));
2298 $cred->may_save($may_save);
2299 $SVN::_Core::SVN_NO_ERROR;
2300 }
2301
2302 sub ssl_server_trust {
2303 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2304 $may_save = undef if $_no_auth_cache;
2305 print STDERR "Error validating server certificate for '$realm':\n";
2306 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2307 print STDERR " - The certificate is not issued by a trusted ",
2308 "authority. Use the\n",
2309 " fingerprint to validate the certificate manually!\n";
2310 }
2311 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2312 print STDERR " - The certificate hostname does not match.\n";
2313 }
2314 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2315 print STDERR " - The certificate is not yet valid.\n";
2316 }
2317 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2318 print STDERR " - The certificate has expired.\n";
2319 }
2320 if ($failures & $SVN::Auth::SSL::OTHER) {
2321 print STDERR " - The certificate has an unknown error.\n";
2322 }
2323 printf STDERR
2324 "Certificate information:\n".
2325 " - Hostname: %s\n".
2326 " - Valid: from %s until %s\n".
2327 " - Issuer: %s\n".
2328 " - Fingerprint: %s\n",
2329 map $cert_info->$_, qw(hostname valid_from valid_until
2330 issuer_dname fingerprint);
2331 my $choice;
2332 prompt:
2333 print STDERR $may_save ?
2334 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2335 "(R)eject or accept (t)emporarily? ";
2336 STDERR->flush;
2337 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2338 if ($choice =~ /^t$/i) {
2339 $cred->may_save(undef);
2340 } elsif ($choice =~ /^r$/i) {
2341 return -1;
2342 } elsif ($may_save && $choice =~ /^p$/i) {
2343 $cred->may_save($may_save);
2344 } else {
2345 goto prompt;
2346 }
2347 $cred->accepted_failures($failures);
2348 $SVN::_Core::SVN_NO_ERROR;
2349 }
2350
2351 sub ssl_client_cert {
2352 my ($cred, $realm, $may_save, $pool) = @_;
2353 $may_save = undef if $_no_auth_cache;
2354 print STDERR "Client certificate filename: ";
2355 STDERR->flush;
2356 chomp(my $filename = <STDIN>);
2357 $cred->cert_file($filename);
2358 $cred->may_save($may_save);
2359 $SVN::_Core::SVN_NO_ERROR;
2360 }
2361
2362 sub ssl_client_cert_pw {
2363 my ($cred, $realm, $may_save, $pool) = @_;
2364 $may_save = undef if $_no_auth_cache;
2365 $cred->password(_read_password("Password: ", $realm));
2366 $cred->may_save($may_save);
2367 $SVN::_Core::SVN_NO_ERROR;
2368 }
2369
2370 sub username {
2371 my ($cred, $realm, $may_save, $pool) = @_;
2372 $may_save = undef if $_no_auth_cache;
2373 if (defined $realm && length $realm) {
2374 print STDERR "Authentication realm: $realm\n";
2375 }
2376 my $username;
2377 if (defined $_username) {
2378 $username = $_username;
2379 } else {
2380 print STDERR "Username: ";
2381 STDERR->flush;
2382 chomp($username = <STDIN>);
2383 }
2384 $cred->username($username);
2385 $cred->may_save($may_save);
2386 $SVN::_Core::SVN_NO_ERROR;
2387 }
2388
2389 sub _read_password {
2390 my ($prompt, $realm) = @_;
2391 print STDERR $prompt;
2392 STDERR->flush;
2393 require Term::ReadKey;
2394 Term::ReadKey::ReadMode('noecho');
2395 my $password = '';
2396 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2397 last if $key =~ /[\012\015]/; # \n\r
2398 $password .= $key;
2399 }
2400 Term::ReadKey::ReadMode('restore');
2401 print STDERR "\n";
2402 STDERR->flush;
2403 $password;
2404 }
2405
2406 package main;
2407
2408 {
2409 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2410 $SVN::Node::dir.$SVN::Node::unknown.
2411 $SVN::Node::none.$SVN::Node::file.
2412 $SVN::Node::dir.$SVN::Node::unknown.
2413 $SVN::Auth::SSL::CNMISMATCH.
2414 $SVN::Auth::SSL::NOTYETVALID.
2415 $SVN::Auth::SSL::EXPIRED.
2416 $SVN::Auth::SSL::UNKNOWNCA.
2417 $SVN::Auth::SSL::OTHER;
2418 }
2419
2420 package SVN::Git::Fetcher;
2421 use vars qw/@ISA/;
2422 use strict;
2423 use warnings;
2424 use Carp qw/croak/;
2425 use IO::File qw//;
2426 use Digest::MD5;
2427
2428 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2429 sub new {
2430 my ($class, $git_svn) = @_;
2431 my $self = SVN::Delta::Editor->new;
2432 bless $self, $class;
2433 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2434 $self->{empty} = {};
2435 $self->{dir_prop} = {};
2436 $self->{file_prop} = {};
2437 $self->{absent_dir} = {};
2438 $self->{absent_file} = {};
2439 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2440 $self;
2441 }
2442
2443 sub set_path_strip {
2444 my ($self, $path) = @_;
2445 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2446 }
2447
2448 sub open_root {
2449 { path => '' };
2450 }
2451
2452 sub open_directory {
2453 my ($self, $path, $pb, $rev) = @_;
2454 { path => $path };
2455 }
2456
2457 sub git_path {
2458 my ($self, $path) = @_;
2459 if ($self->{path_strip}) {
2460 $path =~ s!$self->{path_strip}!! or
2461 die "Failed to strip path '$path' ($self->{path_strip})\n";
2462 }
2463 $path;
2464 }
2465
2466 sub delete_entry {
2467 my ($self, $path, $rev, $pb) = @_;
2468
2469 my $gpath = $self->git_path($path);
2470 return undef if ($gpath eq '');
2471
2472 # remove entire directories.
2473 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2474 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2475 -r --name-only -z/,
2476 $self->{c}, '--', $gpath);
2477 local $/ = "\0";
2478 while (<$ls>) {
2479 chomp;
2480 $self->{gii}->remove($_);
2481 print "\tD\t$_\n" unless $::_q;
2482 }
2483 print "\tD\t$gpath/\n" unless $::_q;
2484 command_close_pipe($ls, $ctx);
2485 $self->{empty}->{$path} = 0
2486 } else {
2487 $self->{gii}->remove($gpath);
2488 print "\tD\t$gpath\n" unless $::_q;
2489 }
2490 undef;
2491 }
2492
2493 sub open_file {
2494 my ($self, $path, $pb, $rev) = @_;
2495 my $gpath = $self->git_path($path);
2496 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
2497 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2498 unless (defined $mode && defined $blob) {
2499 die "$path was not found in commit $self->{c} (r$rev)\n";
2500 }
2501 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2502 pool => SVN::Pool->new, action => 'M' };
2503 }
2504
2505 sub add_file {
2506 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2507 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2508 delete $self->{empty}->{$dir};
2509 { path => $path, mode_a => 100644, mode_b => 100644,
2510 pool => SVN::Pool->new, action => 'A' };
2511 }
2512
2513 sub add_directory {
2514 my ($self, $path, $cp_path, $cp_rev) = @_;
2515 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2516 delete $self->{empty}->{$dir};
2517 $self->{empty}->{$path} = 1;
2518 { path => $path };
2519 }
2520
2521 sub change_dir_prop {
2522 my ($self, $db, $prop, $value) = @_;
2523 $self->{dir_prop}->{$db->{path}} ||= {};
2524 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2525 undef;
2526 }
2527
2528 sub absent_directory {
2529 my ($self, $path, $pb) = @_;
2530 $self->{absent_dir}->{$pb->{path}} ||= [];
2531 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2532 undef;
2533 }
2534
2535 sub absent_file {
2536 my ($self, $path, $pb) = @_;
2537 $self->{absent_file}->{$pb->{path}} ||= [];
2538 push @{$self->{absent_file}->{$pb->{path}}}, $path;
2539 undef;
2540 }
2541
2542 sub change_file_prop {
2543 my ($self, $fb, $prop, $value) = @_;
2544 if ($prop eq 'svn:executable') {
2545 if ($fb->{mode_b} != 120000) {
2546 $fb->{mode_b} = defined $value ? 100755 : 100644;
2547 }
2548 } elsif ($prop eq 'svn:special') {
2549 $fb->{mode_b} = defined $value ? 120000 : 100644;
2550 } else {
2551 $self->{file_prop}->{$fb->{path}} ||= {};
2552 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2553 }
2554 undef;
2555 }
2556
2557 sub apply_textdelta {
2558 my ($self, $fb, $exp) = @_;
2559 my $fh = IO::File->new_tmpfile;
2560 $fh->autoflush(1);
2561 # $fh gets auto-closed() by SVN::TxDelta::apply(),
2562 # (but $base does not,) so dup() it for reading in close_file
2563 open my $dup, '<&', $fh or croak $!;
2564 my $base = IO::File->new_tmpfile;
2565 $base->autoflush(1);
2566 if ($fb->{blob}) {
2567 defined (my $pid = fork) or croak $!;
2568 if (!$pid) {
2569 open STDOUT, '>&', $base or croak $!;
2570 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2571 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2572 }
2573 waitpid $pid, 0;
2574 croak $? if $?;
2575
2576 if (defined $exp) {
2577 seek $base, 0, 0 or croak $!;
2578 my $md5 = Digest::MD5->new;
2579 $md5->addfile($base);
2580 my $got = $md5->hexdigest;
2581 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2582 "expected: $exp\n",
2583 " got: $got\n" if ($got ne $exp);
2584 }
2585 }
2586 seek $base, 0, 0 or croak $!;
2587 $fb->{fh} = $dup;
2588 $fb->{base} = $base;
2589 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2590 }
2591
2592 sub close_file {
2593 my ($self, $fb, $exp) = @_;
2594 my $hash;
2595 my $path = $self->git_path($fb->{path});
2596 if (my $fh = $fb->{fh}) {
2597 if (defined $exp) {
2598 seek($fh, 0, 0) or croak $!;
2599 my $md5 = Digest::MD5->new;
2600 $md5->addfile($fh);
2601 my $got = $md5->hexdigest;
2602 if ($got ne $exp) {
2603 die "Checksum mismatch: $path\n",
2604 "expected: $exp\n got: $got\n";
2605 }
2606 }
2607 sysseek($fh, 0, 0) or croak $!;
2608 if ($fb->{mode_b} == 120000) {
2609 sysread($fh, my $buf, 5) == 5 or croak $!;
2610 $buf eq 'link ' or die "$path has mode 120000",
2611 "but is not a link\n";
2612 }
2613 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2614 if (!$pid) {
2615 open STDIN, '<&', $fh or croak $!;
2616 exec qw/git-hash-object -w --stdin/ or croak $!;
2617 }
2618 chomp($hash = do { local $/; <$out> });
2619 close $out or croak $!;
2620 close $fh or croak $!;
2621 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2622 close $fb->{base} or croak $!;
2623 } else {
2624 $hash = $fb->{blob} or die "no blob information\n";
2625 }
2626 $fb->{pool}->clear;
2627 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
2628 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
2629 undef;
2630 }
2631
2632 sub abort_edit {
2633 my $self = shift;
2634 $self->{nr} = $self->{gii}->{nr};
2635 delete $self->{gii};
2636 $self->SUPER::abort_edit(@_);
2637 }
2638
2639 sub close_edit {
2640 my $self = shift;
2641 $self->{git_commit_ok} = 1;
2642 $self->{nr} = $self->{gii}->{nr};
2643 delete $self->{gii};
2644 $self->SUPER::close_edit(@_);
2645 }
2646
2647 package SVN::Git::Editor;
2648 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
2649 use strict;
2650 use warnings;
2651 use Carp qw/croak/;
2652 use IO::File;
2653 use Digest::MD5;
2654
2655 sub new {
2656 my ($class, $opts) = @_;
2657 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
2658 die "$_ required!\n" unless (defined $opts->{$_});
2659 }
2660
2661 my $pool = SVN::Pool->new;
2662 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
2663 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
2664 $opts->{r}, $mods);
2665
2666 # $opts->{ra} functions should not be used after this:
2667 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
2668 $opts->{editor_cb}, $pool);
2669 my $self = SVN::Delta::Editor->new(@ce, $pool);
2670 bless $self, $class;
2671 foreach (qw/svn_path r tree_a tree_b/) {
2672 $self->{$_} = $opts->{$_};
2673 }
2674 $self->{url} = $opts->{ra}->{url};
2675 $self->{mods} = $mods;
2676 $self->{types} = $types;
2677 $self->{pool} = $pool;
2678 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2679 $self->{rm} = { };
2680 $self->{path_prefix} = length $self->{svn_path} ?
2681 "$self->{svn_path}/" : '';
2682 return $self;
2683 }
2684
2685 sub generate_diff {
2686 my ($tree_a, $tree_b) = @_;
2687 my @diff_tree = qw(diff-tree -z -r);
2688 if ($_cp_similarity) {
2689 push @diff_tree, "-C$_cp_similarity";
2690 } else {
2691 push @diff_tree, '-C';
2692 }
2693 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
2694 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
2695 push @diff_tree, $tree_a, $tree_b;
2696 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2697 local $/ = "\0";
2698 my $state = 'meta';
2699 my @mods;
2700 while (<$diff_fh>) {
2701 chomp $_; # this gets rid of the trailing "\0"
2702 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2703 $::sha1\s($::sha1)\s
2704 ([MTCRAD])\d*$/xo) {
2705 push @mods, { mode_a => $1, mode_b => $2,
2706 sha1_b => $3, chg => $4 };
2707 if ($4 =~ /^(?:C|R)$/) {
2708 $state = 'file_a';
2709 } else {
2710 $state = 'file_b';
2711 }
2712 } elsif ($state eq 'file_a') {
2713 my $x = $mods[$#mods] or croak "Empty array\n";
2714 if ($x->{chg} !~ /^(?:C|R)$/) {
2715 croak "Error parsing $_, $x->{chg}\n";
2716 }
2717 $x->{file_a} = $_;
2718 $state = 'file_b';
2719 } elsif ($state eq 'file_b') {
2720 my $x = $mods[$#mods] or croak "Empty array\n";
2721 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2722 croak "Error parsing $_, $x->{chg}\n";
2723 }
2724 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2725 croak "Error parsing $_, $x->{chg}\n";
2726 }
2727 $x->{file_b} = $_;
2728 $state = 'meta';
2729 } else {
2730 croak "Error parsing $_\n";
2731 }
2732 }
2733 command_close_pipe($diff_fh, $ctx);
2734 \@mods;
2735 }
2736
2737 sub check_diff_paths {
2738 my ($ra, $pfx, $rev, $mods) = @_;
2739 my %types;
2740 $pfx .= '/' if length $pfx;
2741
2742 sub type_diff_paths {
2743 my ($ra, $types, $path, $rev) = @_;
2744 my @p = split m#/+#, $path;
2745 my $c = shift @p;
2746 unless (defined $types->{$c}) {
2747 $types->{$c} = $ra->check_path($c, $rev);
2748 }
2749 while (@p) {
2750 $c .= '/' . shift @p;
2751 next if defined $types->{$c};
2752 $types->{$c} = $ra->check_path($c, $rev);
2753 }
2754 }
2755
2756 foreach my $m (@$mods) {
2757 foreach my $f (qw/file_a file_b/) {
2758 next unless defined $m->{$f};
2759 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
2760 if (length $pfx.$dir && ! defined $types{$dir}) {
2761 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
2762 }
2763 }
2764 }
2765 \%types;
2766 }
2767
2768 sub split_path {
2769 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2770 }
2771
2772 sub repo_path {
2773 my ($self, $path) = @_;
2774 $self->{path_prefix}.(defined $path ? $path : '');
2775 }
2776
2777 sub url_path {
2778 my ($self, $path) = @_;
2779 if ($self->{url} =~ m#^https?://#) {
2780 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
2781 }
2782 $self->{url} . '/' . $self->repo_path($path);
2783 }
2784
2785 sub rmdirs {
2786 my ($self) = @_;
2787 my $rm = $self->{rm};
2788 delete $rm->{''}; # we never delete the url we're tracking
2789 return unless %$rm;
2790
2791 foreach (keys %$rm) {
2792 my @d = split m#/#, $_;
2793 my $c = shift @d;
2794 $rm->{$c} = 1;
2795 while (@d) {
2796 $c .= '/' . shift @d;
2797 $rm->{$c} = 1;
2798 }
2799 }
2800 delete $rm->{$self->{svn_path}};
2801 delete $rm->{''}; # we never delete the url we're tracking
2802 return unless %$rm;
2803
2804 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2805 $self->{tree_b});
2806 local $/ = "\0";
2807 while (<$fh>) {
2808 chomp;
2809 my @dn = split m#/#, $_;
2810 while (pop @dn) {
2811 delete $rm->{join '/', @dn};
2812 }
2813 unless (%$rm) {
2814 close $fh;
2815 return;
2816 }
2817 }
2818 command_close_pipe($fh, $ctx);
2819
2820 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2821 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2822 $self->close_directory($bat->{$d}, $p);
2823 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2824 print "\tD+\t$d/\n" unless $::_q;
2825 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2826 delete $bat->{$d};
2827 }
2828 }
2829
2830 sub open_or_add_dir {
2831 my ($self, $full_path, $baton) = @_;
2832 my $t = $self->{types}->{$full_path};
2833 if (!defined $t) {
2834 die "$full_path not known in r$self->{r} or we have a bug!\n";
2835 }
2836 if ($t == $SVN::Node::none) {
2837 return $self->add_directory($full_path, $baton,
2838 undef, -1, $self->{pool});
2839 } elsif ($t == $SVN::Node::dir) {
2840 return $self->open_directory($full_path, $baton,
2841 $self->{r}, $self->{pool});
2842 }
2843 print STDERR "$full_path already exists in repository at ",
2844 "r$self->{r} and it is not a directory (",
2845 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2846 exit 1;
2847 }
2848
2849 sub ensure_path {
2850 my ($self, $path) = @_;
2851 my $bat = $self->{bat};
2852 my $repo_path = $self->repo_path($path);
2853 return $bat->{''} unless (length $repo_path);
2854 my @p = split m#/+#, $repo_path;
2855 my $c = shift @p;
2856 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2857 while (@p) {
2858 my $c0 = $c;
2859 $c .= '/' . shift @p;
2860 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2861 }
2862 return $bat->{$c};
2863 }
2864
2865 sub A {
2866 my ($self, $m) = @_;
2867 my ($dir, $file) = split_path($m->{file_b});
2868 my $pbat = $self->ensure_path($dir);
2869 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2870 undef, -1);
2871 print "\tA\t$m->{file_b}\n" unless $::_q;
2872 $self->chg_file($fbat, $m);
2873 $self->close_file($fbat,undef,$self->{pool});
2874 }
2875
2876 sub C {
2877 my ($self, $m) = @_;
2878 my ($dir, $file) = split_path($m->{file_b});
2879 my $pbat = $self->ensure_path($dir);
2880 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2881 $self->url_path($m->{file_a}), $self->{r});
2882 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2883 $self->chg_file($fbat, $m);
2884 $self->close_file($fbat,undef,$self->{pool});
2885 }
2886
2887 sub delete_entry {
2888 my ($self, $path, $pbat) = @_;
2889 my $rpath = $self->repo_path($path);
2890 my ($dir, $file) = split_path($rpath);
2891 $self->{rm}->{$dir} = 1;
2892 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2893 }
2894
2895 sub R {
2896 my ($self, $m) = @_;
2897 my ($dir, $file) = split_path($m->{file_b});
2898 my $pbat = $self->ensure_path($dir);
2899 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2900 $self->url_path($m->{file_a}), $self->{r});
2901 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2902 $self->chg_file($fbat, $m);
2903 $self->close_file($fbat,undef,$self->{pool});
2904
2905 ($dir, $file) = split_path($m->{file_a});
2906 $pbat = $self->ensure_path($dir);
2907 $self->delete_entry($m->{file_a}, $pbat);
2908 }
2909
2910 sub M {
2911 my ($self, $m) = @_;
2912 my ($dir, $file) = split_path($m->{file_b});
2913 my $pbat = $self->ensure_path($dir);
2914 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2915 $pbat,$self->{r},$self->{pool});
2916 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2917 $self->chg_file($fbat, $m);
2918 $self->close_file($fbat,undef,$self->{pool});
2919 }
2920
2921 sub T { shift->M(@_) }
2922
2923 sub change_file_prop {
2924 my ($self, $fbat, $pname, $pval) = @_;
2925 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2926 }
2927
2928 sub chg_file {
2929 my ($self, $fbat, $m) = @_;
2930 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2931 $self->change_file_prop($fbat,'svn:executable','*');
2932 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2933 $self->change_file_prop($fbat,'svn:executable',undef);
2934 }
2935 my $fh = IO::File->new_tmpfile or croak $!;
2936 if ($m->{mode_b} =~ /^120/) {
2937 print $fh 'link ' or croak $!;
2938 $self->change_file_prop($fbat,'svn:special','*');
2939 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2940 $self->change_file_prop($fbat,'svn:special',undef);
2941 }
2942 defined(my $pid = fork) or croak $!;
2943 if (!$pid) {
2944 open STDOUT, '>&', $fh or croak $!;
2945 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2946 }
2947 waitpid $pid, 0;
2948 croak $? if $?;
2949 $fh->flush == 0 or croak $!;
2950 seek $fh, 0, 0 or croak $!;
2951
2952 my $md5 = Digest::MD5->new;
2953 $md5->addfile($fh) or croak $!;
2954 seek $fh, 0, 0 or croak $!;
2955
2956 my $exp = $md5->hexdigest;
2957 my $pool = SVN::Pool->new;
2958 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2959 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2960 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2961 $pool->clear;
2962
2963 close $fh or croak $!;
2964 }
2965
2966 sub D {
2967 my ($self, $m) = @_;
2968 my ($dir, $file) = split_path($m->{file_b});
2969 my $pbat = $self->ensure_path($dir);
2970 print "\tD\t$m->{file_b}\n" unless $::_q;
2971 $self->delete_entry($m->{file_b}, $pbat);
2972 }
2973
2974 sub close_edit {
2975 my ($self) = @_;
2976 my ($p,$bat) = ($self->{pool}, $self->{bat});
2977 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2978 next if $_ eq '';
2979 $self->close_directory($bat->{$_}, $p);
2980 }
2981 $self->close_directory($bat->{''}, $p);
2982 $self->SUPER::close_edit($p);
2983 $p->clear;
2984 }
2985
2986 sub abort_edit {
2987 my ($self) = @_;
2988 $self->SUPER::abort_edit($self->{pool});
2989 }
2990
2991 sub DESTROY {
2992 my $self = shift;
2993 $self->SUPER::DESTROY(@_);
2994 $self->{pool}->clear;
2995 }
2996
2997 # this drives the editor
2998 sub apply_diff {
2999 my ($self) = @_;
3000 my $mods = $self->{mods};
3001 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3002 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3003 my $f = $m->{chg};
3004 if (defined $o{$f}) {
3005 $self->$f($m);
3006 } else {
3007 fatal("Invalid change type: $f\n");
3008 }
3009 }
3010 $self->rmdirs if $_rmdir;
3011 if (@$mods == 0) {
3012 $self->abort_edit;
3013 } else {
3014 $self->close_edit;
3015 }
3016 return scalar @$mods;
3017 }
3018
3019 package Git::SVN::Ra;
3020 use vars qw/@ISA $config_dir $_log_window_size/;
3021 use strict;
3022 use warnings;
3023 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3024
3025 BEGIN {
3026 # enforce temporary pool usage for some simple functions
3027 no strict 'refs';
3028 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3029 my $SUPER = "SUPER::$f";
3030 *$f = sub {
3031 my $self = shift;
3032 my $pool = SVN::Pool->new;
3033 my @ret = $self->$SUPER(@_,$pool);
3034 $pool->clear;
3035 wantarray ? @ret : $ret[0];
3036 };
3037 }
3038 }
3039
3040 sub _auth_providers () {
3041 [
3042 SVN::Client::get_simple_provider(),
3043 SVN::Client::get_ssl_server_trust_file_provider(),
3044 SVN::Client::get_simple_prompt_provider(
3045 \&Git::SVN::Prompt::simple, 2),
3046 SVN::Client::get_ssl_client_cert_file_provider(),
3047 SVN::Client::get_ssl_client_cert_prompt_provider(
3048 \&Git::SVN::Prompt::ssl_client_cert, 2),
3049 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3050 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3051 SVN::Client::get_username_provider(),
3052 SVN::Client::get_ssl_server_trust_prompt_provider(
3053 \&Git::SVN::Prompt::ssl_server_trust),
3054 SVN::Client::get_username_prompt_provider(
3055 \&Git::SVN::Prompt::username, 2)
3056 ]
3057 }
3058
3059 sub new {
3060 my ($class, $url) = @_;
3061 $url =~ s!/+$!!;
3062 return $RA if ($RA && $RA->{url} eq $url);
3063
3064 SVN::_Core::svn_config_ensure($config_dir, undef);
3065 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3066 my $config = SVN::Core::config_get_config($config_dir);
3067 $RA = undef;
3068 my $dont_store_passwords = 1;
3069 my $conf_t = ${$config}{'config'};
3070 {
3071 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3072 # produces warnings that variables are used only once.
3073 # I had not found the better way to shut them up, so
3074 # warnings are disabled in this block.
3075 no warnings;
3076 if (SVN::_Core::svn_config_get_bool($conf_t,
3077 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3078 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3079 1) == 0) {
3080 SVN::_Core::svn_auth_set_parameter($baton,
3081 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3082 bless (\$dont_store_passwords, "_p_void"));
3083 }
3084 if (SVN::_Core::svn_config_get_bool($conf_t,
3085 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3086 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3087 1) == 0) {
3088 $Git::SVN::Prompt::_no_auth_cache = 1;
3089 }
3090 }
3091 my $self = SVN::Ra->new(url => $url, auth => $baton,
3092 config => $config,
3093 pool => SVN::Pool->new,
3094 auth_provider_callbacks => $callbacks);
3095 $self->{svn_path} = $url;
3096 $self->{repos_root} = $self->get_repos_root;
3097 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3098 $self->{cache} = { check_path => { r => 0, data => {} },
3099 get_dir => { r => 0, data => {} } };
3100 $RA = bless $self, $class;
3101 }
3102
3103 sub check_path {
3104 my ($self, $path, $r) = @_;
3105 my $cache = $self->{cache}->{check_path};
3106 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3107 return $cache->{data}->{$path};
3108 }
3109 my $pool = SVN::Pool->new;
3110 my $t = $self->SUPER::check_path($path, $r, $pool);
3111 $pool->clear;
3112 if ($r != $cache->{r}) {
3113 %{$cache->{data}} = ();
3114 $cache->{r} = $r;
3115 }
3116 $cache->{data}->{$path} = $t;
3117 }
3118
3119 sub get_dir {
3120 my ($self, $dir, $r) = @_;
3121 my $cache = $self->{cache}->{get_dir};
3122 if ($r == $cache->{r}) {
3123 if (my $x = $cache->{data}->{$dir}) {
3124 return wantarray ? @$x : $x->[0];
3125 }
3126 }
3127 my $pool = SVN::Pool->new;
3128 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3129 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3130 $pool->clear;
3131 if ($r != $cache->{r}) {
3132 %{$cache->{data}} = ();
3133 $cache->{r} = $r;
3134 }
3135 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3136 wantarray ? (\%dirents, $r, $props) : \%dirents;
3137 }
3138
3139 sub DESTROY {
3140 # do not call the real DESTROY since we store ourselves in $RA
3141 }
3142
3143 sub get_log {
3144 my ($self, @args) = @_;
3145 my $pool = SVN::Pool->new;
3146 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3147 my $ret = $self->SUPER::get_log(@args, $pool);
3148 $pool->clear;
3149 $ret;
3150 }
3151
3152 sub trees_match {
3153 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3154 my $ctx = SVN::Client->new(auth => _auth_providers);
3155 my $out = IO::File->new_tmpfile;
3156
3157 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3158 # $ctx->diff(), so we'll create a default one
3159 my $pool = SVN::Pool->new_default_sub;
3160
3161 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3162 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3163 $out->flush;
3164 my $ret = (($out->stat)[7] == 0);
3165 close $out or croak $!;
3166
3167 $ret;
3168 }
3169
3170 sub get_commit_editor {
3171 my ($self, $log, $cb, $pool) = @_;
3172 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3173 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3174 }
3175
3176 sub gs_do_update {
3177 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3178 my $new = ($rev_a == $rev_b);
3179 my $path = $gs->{path};
3180
3181 if ($new && -e $gs->{index}) {
3182 unlink $gs->{index} or die
3183 "Couldn't unlink index: $gs->{index}: $!\n";
3184 }
3185 my $pool = SVN::Pool->new;
3186 $editor->set_path_strip($path);
3187 my (@pc) = split m#/#, $path;
3188 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3189 1, $editor, $pool);
3190 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3191
3192 # Since we can't rely on svn_ra_reparent being available, we'll
3193 # just have to do some magic with set_path to make it so
3194 # we only want a partial path.
3195 my $sp = '';
3196 my $final = join('/', @pc);
3197 while (@pc) {
3198 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3199 $sp .= '/' if length $sp;
3200 $sp .= shift @pc;
3201 }
3202 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3203
3204 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3205
3206 $reporter->finish_report($pool);
3207 $pool->clear;
3208 $editor->{git_commit_ok};
3209 }
3210
3211 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3212 # svn_ra_reparent didn't work before 1.4)
3213 sub gs_do_switch {
3214 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3215 my $path = $gs->{path};
3216 my $pool = SVN::Pool->new;
3217
3218 my $full_url = $self->{url};
3219 my $old_url = $full_url;
3220 $full_url .= "/$path" if length $path;
3221 my ($ra, $reparented);
3222 if ($old_url ne $full_url) {
3223 if ($old_url !~ m#^svn(\+ssh)?://#) {
3224 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3225 $pool);
3226 $self->{url} = $full_url;
3227 $reparented = 1;
3228 } else {
3229 $_[0] = undef;
3230 $self = undef;
3231 $RA = undef;
3232 $ra = Git::SVN::Ra->new($full_url);
3233 $ra_invalid = 1;
3234 }
3235 }
3236 $ra ||= $self;
3237 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3238 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3239 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3240 $reporter->finish_report($pool);
3241
3242 if ($reparented) {
3243 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3244 $self->{url} = $old_url;
3245 }
3246
3247 $pool->clear;
3248 $editor->{git_commit_ok};
3249 }
3250
3251 sub longest_common_path {
3252 my ($gsv, $globs) = @_;
3253 my %common;
3254 my $common_max = scalar @$gsv;
3255
3256 foreach my $gs (@$gsv) {
3257 my @tmp = split m#/#, $gs->{path};
3258 my $p = '';
3259 foreach (@tmp) {
3260 $p .= length($p) ? "/$_" : $_;
3261 $common{$p} ||= 0;
3262 $common{$p}++;
3263 }
3264 }
3265 $globs ||= [];
3266 $common_max += scalar @$globs;
3267 foreach my $glob (@$globs) {
3268 my @tmp = split m#/#, $glob->{path}->{left};
3269 my $p = '';
3270 foreach (@tmp) {
3271 $p .= length($p) ? "/$_" : $_;
3272 $common{$p} ||= 0;
3273 $common{$p}++;
3274 }
3275 }
3276
3277 my $longest_path = '';
3278 foreach (sort {length $b <=> length $a} keys %common) {
3279 if ($common{$_} == $common_max) {
3280 $longest_path = $_;
3281 last;
3282 }
3283 }
3284 $longest_path;
3285 }
3286
3287 sub gs_fetch_loop_common {
3288 my ($self, $base, $head, $gsv, $globs) = @_;
3289 return if ($base > $head);
3290 my $inc = $_log_window_size;
3291 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3292 my $longest_path = longest_common_path($gsv, $globs);
3293 my $ra_url = $self->{url};
3294 while (1) {
3295 my %revs;
3296 my $err;
3297 my $err_handler = $SVN::Error::handler;
3298 $SVN::Error::handler = sub {
3299 ($err) = @_;
3300 skip_unknown_revs($err);
3301 };
3302 sub _cb {
3303 my ($paths, $r, $author, $date, $log) = @_;
3304 [ dup_changed_paths($paths),
3305 { author => $author, date => $date, log => $log } ];
3306 }
3307 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3308 sub { $revs{$_[1]} = _cb(@_) });
3309 if ($err && $max >= $head) {
3310 print STDERR "Path '$longest_path' ",
3311 "was probably deleted:\n",
3312 $err->expanded_message,
3313 "\nWill attempt to follow ",
3314 "revisions r$min .. r$max ",
3315 "committed before the deletion\n";
3316 my $hi = $max;
3317 while (--$hi >= $min) {
3318 my $ok;
3319 $self->get_log([$longest_path], $min, $hi,
3320 0, 1, 1, sub {
3321 $ok ||= $_[1];
3322 $revs{$_[1]} = _cb(@_) });
3323 if ($ok) {
3324 print STDERR "r$min .. r$ok OK\n";
3325 last;
3326 }
3327 }
3328 }
3329 $SVN::Error::handler = $err_handler;
3330
3331 my %exists = map { $_->{path} => $_ } @$gsv;
3332 foreach my $r (sort {$a <=> $b} keys %revs) {
3333 my ($paths, $logged) = @{$revs{$r}};
3334
3335 foreach my $gs ($self->match_globs(\%exists, $paths,
3336 $globs, $r)) {
3337 if ($gs->rev_db_max >= $r) {
3338 next;
3339 }
3340 next unless $gs->match_paths($paths, $r);
3341 $gs->{logged_rev_props} = $logged;
3342 if (my $last_commit = $gs->last_commit) {
3343 $gs->assert_index_clean($last_commit);
3344 }
3345 my $log_entry = $gs->do_fetch($paths, $r);
3346 if ($log_entry) {
3347 $gs->do_git_commit($log_entry);
3348 }
3349 }
3350 foreach my $g (@$globs) {
3351 my $k = "svn-remote.$g->{remote}." .
3352 "$g->{t}-maxRev";
3353 Git::SVN::tmp_config($k, $r);
3354 }
3355 if ($ra_invalid) {
3356 $_[0] = undef;
3357 $self = undef;
3358 $RA = undef;
3359 $self = Git::SVN::Ra->new($ra_url);
3360 $ra_invalid = undef;
3361 }
3362 }
3363 # pre-fill the .rev_db since it'll eventually get filled in
3364 # with '0' x40 if something new gets committed
3365 foreach my $gs (@$gsv) {
3366 next if defined $gs->rev_db_get($max);
3367 $gs->rev_db_set($max, 0 x40);
3368 }
3369 foreach my $g (@$globs) {
3370 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3371 Git::SVN::tmp_config($k, $max);
3372 }
3373 last if $max >= $head;
3374 $min = $max + 1;
3375 $max += $inc;
3376 $max = $head if ($max > $head);
3377 }
3378 }
3379
3380 sub match_globs {
3381 my ($self, $exists, $paths, $globs, $r) = @_;
3382
3383 sub get_dir_check {
3384 my ($self, $exists, $g, $r) = @_;
3385 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3386 return unless scalar @x == 3;
3387 my $dirents = $x[0];
3388 foreach my $de (keys %$dirents) {
3389 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3390 my $p = $g->{path}->full_path($de);
3391 next if $exists->{$p};
3392 next if (length $g->{path}->{right} &&
3393 ($self->check_path($p, $r) !=
3394 $SVN::Node::dir));
3395 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3396 $g->{ref}->full_path($de), 1);
3397 }
3398 }
3399 foreach my $g (@$globs) {
3400 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3401 if ($path->{action} =~ /^[AR]$/) {
3402 get_dir_check($self, $exists, $g, $r);
3403 }
3404 }
3405 foreach (keys %$paths) {
3406 if (/$g->{path}->{left_regex}/ &&
3407 !/$g->{path}->{regex}/) {
3408 next if $paths->{$_}->{action} !~ /^[AR]$/;
3409 get_dir_check($self, $exists, $g, $r);
3410 }
3411 next unless /$g->{path}->{regex}/;
3412 my $p = $1;
3413 my $pathname = $g->{path}->full_path($p);
3414 next if $exists->{$pathname};
3415 next if ($self->check_path($pathname, $r) !=
3416 $SVN::Node::dir);
3417 $exists->{$pathname} = Git::SVN->init(
3418 $self->{url}, $pathname, undef,
3419 $g->{ref}->full_path($p), 1);
3420 }
3421 my $c = '';
3422 foreach (split m#/#, $g->{path}->{left}) {
3423 $c .= "/$_";
3424 next unless ($paths->{$c} &&
3425 ($paths->{$c}->{action} =~ /^[AR]$/));
3426 get_dir_check($self, $exists, $g, $r);
3427 }
3428 }
3429 values %$exists;
3430 }
3431
3432 sub minimize_url {
3433 my ($self) = @_;
3434 return $self->{url} if ($self->{url} eq $self->{repos_root});
3435 my $url = $self->{repos_root};
3436 my @components = split(m!/!, $self->{svn_path});
3437 my $c = '';
3438 do {
3439 $url .= "/$c" if length $c;
3440 eval { (ref $self)->new($url)->get_latest_revnum };
3441 } while ($@ && ($c = shift @components));
3442 $url;
3443 }
3444
3445 sub can_do_switch {
3446 my $self = shift;
3447 unless (defined $can_do_switch) {
3448 my $pool = SVN::Pool->new;
3449 my $rep = eval {
3450 $self->do_switch(1, '', 0, $self->{url},
3451 SVN::Delta::Editor->new, $pool);
3452 };
3453 if ($@) {
3454 $can_do_switch = 0;
3455 } else {
3456 $rep->abort_report($pool);
3457 $can_do_switch = 1;
3458 }
3459 $pool->clear;
3460 }
3461 $can_do_switch;
3462 }
3463
3464 sub skip_unknown_revs {
3465 my ($err) = @_;
3466 my $errno = $err->apr_err();
3467 # Maybe the branch we're tracking didn't
3468 # exist when the repo started, so it's
3469 # not an error if it doesn't, just continue
3470 #
3471 # Wonderfully consistent library, eh?
3472 # 160013 - svn:// and file://
3473 # 175002 - http(s)://
3474 # 175007 - http(s):// (this repo required authorization, too...)
3475 # More codes may be discovered later...
3476 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3477 my $err_key = $err->expanded_message;
3478 # revision numbers change every time, filter them out
3479 $err_key =~ s/\d+/\0/g;
3480 $err_key = "$errno\0$err_key";
3481 unless ($ignored_err{$err_key}) {
3482 warn "W: Ignoring error from SVN, path probably ",
3483 "does not exist: ($errno): ",
3484 $err->expanded_message,"\n";
3485 $ignored_err{$err_key} = 1;
3486 }
3487 return;
3488 }
3489 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3490 }
3491
3492 # svn_log_changed_path_t objects passed to get_log are likely to be
3493 # overwritten even if only the refs are copied to an external variable,
3494 # so we should dup the structures in their entirety. Using an externally
3495 # passed pool (instead of our temporary and quickly cleared pool in
3496 # Git::SVN::Ra) does not help matters at all...
3497 sub dup_changed_paths {
3498 my ($paths) = @_;
3499 return undef unless $paths;
3500 my %ret;
3501 foreach my $p (keys %$paths) {
3502 my $i = $paths->{$p};
3503 my %s = map { $_ => $i->$_ }
3504 qw/copyfrom_path copyfrom_rev action/;
3505 $ret{$p} = \%s;
3506 }
3507 \%ret;
3508 }
3509
3510 package Git::SVN::Log;
3511 use strict;
3512 use warnings;
3513 use POSIX qw/strftime/;
3514 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
3515 %rusers $show_commit $incremental/;
3516 my $l_fmt;
3517
3518 sub cmt_showable {
3519 my ($c) = @_;
3520 return 1 if defined $c->{r};
3521
3522 # big commit message got truncated by the 16k pretty buffer in rev-list
3523 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
3524 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
3525 @{$c->{l}} = ();
3526 my @log = command(qw/cat-file commit/, $c->{c});
3527
3528 # shift off the headers
3529 shift @log while ($log[0] ne '');
3530 shift @log;
3531
3532 # TODO: make $c->{l} not have a trailing newline in the future
3533 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
3534
3535 (undef, $c->{r}, undef) = ::extract_metadata(
3536 (grep(/^git-svn-id: /, @log))[-1]);
3537 }
3538 return defined $c->{r};
3539 }
3540
3541 sub log_use_color {
3542 return 1 if $color;
3543 my ($dc, $dcvar);
3544 $dcvar = 'color.diff';
3545 $dc = `git-config --get $dcvar`;
3546 if ($dc eq '') {
3547 # nothing at all; fallback to "diff.color"
3548 $dcvar = 'diff.color';
3549 $dc = `git-config --get $dcvar`;
3550 }
3551 chomp($dc);
3552 if ($dc eq 'auto') {
3553 my $pc;
3554 $pc = `git-config --get color.pager`;
3555 if ($pc eq '') {
3556 # does not have it -- fallback to pager.color
3557 $pc = `git-config --bool --get pager.color`;
3558 }
3559 else {
3560 $pc = `git-config --bool --get color.pager`;
3561 if ($?) {
3562 $pc = 'false';
3563 }
3564 }
3565 chomp($pc);
3566 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
3567 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
3568 }
3569 return 0;
3570 }
3571 return 0 if $dc eq 'never';
3572 return 1 if $dc eq 'always';
3573 chomp($dc = `git-config --bool --get $dcvar`);
3574 return ($dc eq 'true');
3575 }
3576
3577 sub git_svn_log_cmd {
3578 my ($r_min, $r_max, @args) = @_;
3579 my $head = 'HEAD';
3580 my (@files, @log_opts);
3581 foreach my $x (@args) {
3582 if ($x eq '--' || @files) {
3583 push @files, $x;
3584 } else {
3585 if (::verify_ref("$x^0")) {
3586 $head = $x;
3587 } else {
3588 push @log_opts, $x;
3589 }
3590 }
3591 }
3592
3593 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
3594 $gs ||= Git::SVN->_new;
3595 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
3596 $gs->refname);
3597 push @cmd, '-r' unless $non_recursive;
3598 push @cmd, qw/--raw --name-status/ if $verbose;
3599 push @cmd, '--color' if log_use_color();
3600 push @cmd, @log_opts;
3601 if (defined $r_max && $r_max == $r_min) {
3602 push @cmd, '--max-count=1';
3603 if (my $c = $gs->rev_db_get($r_max)) {
3604 push @cmd, $c;
3605 }
3606 } elsif (defined $r_max) {
3607 my ($c_min, $c_max);
3608 $c_max = $gs->rev_db_get($r_max);
3609 $c_min = $gs->rev_db_get($r_min);
3610 if (defined $c_min && defined $c_max) {
3611 if ($r_max > $r_max) {
3612 push @cmd, "$c_min..$c_max";
3613 } else {
3614 push @cmd, "$c_max..$c_min";
3615 }
3616 } elsif ($r_max > $r_min) {
3617 push @cmd, $c_max;
3618 } else {
3619 push @cmd, $c_min;
3620 }
3621 }
3622 return (@cmd, @files);
3623 }
3624
3625 # adapted from pager.c
3626 sub config_pager {
3627 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
3628 if (!defined $pager) {
3629 $pager = 'less';
3630 } elsif (length $pager == 0 || $pager eq 'cat') {
3631 $pager = undef;
3632 }
3633 }
3634
3635 sub run_pager {
3636 return unless -t *STDOUT && defined $pager;
3637 pipe my $rfd, my $wfd or return;
3638 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
3639 if (!$pid) {
3640 open STDOUT, '>&', $wfd or
3641 ::fatal "Can't redirect to stdout: $!\n";
3642 return;
3643 }
3644 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
3645 $ENV{LESS} ||= 'FRSX';
3646 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
3647 }
3648
3649 sub tz_to_s_offset {
3650 my ($tz) = @_;
3651 $tz =~ s/(\d\d)$//;
3652 return ($1 * 60) + ($tz * 3600);
3653 }
3654
3655 sub get_author_info {
3656 my ($dest, $author, $t, $tz) = @_;
3657 $author =~ s/(?:^\s*|\s*$)//g;
3658 $dest->{a_raw} = $author;
3659 my $au;
3660 if ($::_authors) {
3661 $au = $rusers{$author} || undef;
3662 }
3663 if (!$au) {
3664 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
3665 }
3666 $dest->{t} = $t;
3667 $dest->{tz} = $tz;
3668 $dest->{a} = $au;
3669 # Date::Parse isn't in the standard Perl distro :(
3670 if ($tz =~ s/^\+//) {
3671 $t += tz_to_s_offset($tz);
3672 } elsif ($tz =~ s/^\-//) {
3673 $t -= tz_to_s_offset($tz);
3674 }
3675 $dest->{t_utc} = $t;
3676 }
3677
3678 sub process_commit {
3679 my ($c, $r_min, $r_max, $defer) = @_;
3680 if (defined $r_min && defined $r_max) {
3681 if ($r_min == $c->{r} && $r_min == $r_max) {
3682 show_commit($c);
3683 return 0;
3684 }
3685 return 1 if $r_min == $r_max;
3686 if ($r_min < $r_max) {
3687 # we need to reverse the print order
3688 return 0 if (defined $limit && --$limit < 0);
3689 push @$defer, $c;
3690 return 1;
3691 }
3692 if ($r_min != $r_max) {
3693 return 1 if ($r_min < $c->{r});
3694 return 1 if ($r_max > $c->{r});
3695 }
3696 }
3697 return 0 if (defined $limit && --$limit < 0);
3698 show_commit($c);
3699 return 1;
3700 }
3701
3702 sub show_commit {
3703 my $c = shift;
3704 if ($oneline) {
3705 my $x = "\n";
3706 if (my $l = $c->{l}) {
3707 while ($l->[0] =~ /^\s*$/) { shift @$l }
3708 $x = $l->[0];
3709 }
3710 $l_fmt ||= 'A' . length($c->{r});
3711 print 'r',pack($l_fmt, $c->{r}),' | ';
3712 print "$c->{c} | " if $show_commit;
3713 print $x;
3714 } else {
3715 show_commit_normal($c);
3716 }
3717 }
3718
3719 sub show_commit_changed_paths {
3720 my ($c) = @_;
3721 return unless $c->{changed};
3722 print "Changed paths:\n", @{$c->{changed}};
3723 }
3724
3725 sub show_commit_normal {
3726 my ($c) = @_;
3727 print '-' x72, "\nr$c->{r} | ";
3728 print "$c->{c} | " if $show_commit;
3729 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
3730 localtime($c->{t_utc})), ' | ';
3731 my $nr_line = 0;
3732
3733 if (my $l = $c->{l}) {
3734 while ($l->[$#$l] eq "\n" && $#$l > 0
3735 && $l->[($#$l - 1)] eq "\n") {
3736 pop @$l;
3737 }
3738 $nr_line = scalar @$l;
3739 if (!$nr_line) {
3740 print "1 line\n\n\n";
3741 } else {
3742 if ($nr_line == 1) {
3743 $nr_line = '1 line';
3744 } else {
3745 $nr_line .= ' lines';
3746 }
3747 print $nr_line, "\n";
3748 show_commit_changed_paths($c);
3749 print "\n";
3750 print $_ foreach @$l;
3751 }
3752 } else {
3753 print "1 line\n";
3754 show_commit_changed_paths($c);
3755 print "\n";
3756
3757 }
3758 foreach my $x (qw/raw stat diff/) {
3759 if ($c->{$x}) {
3760 print "\n";
3761 print $_ foreach @{$c->{$x}}
3762 }
3763 }
3764 }
3765
3766 sub cmd_show_log {
3767 my (@args) = @_;
3768 my ($r_min, $r_max);
3769 my $r_last = -1; # prevent dupes
3770 if (defined $TZ) {
3771 $ENV{TZ} = $TZ;
3772 } else {
3773 delete $ENV{TZ};
3774 }
3775 if (defined $::_revision) {
3776 if ($::_revision =~ /^(\d+):(\d+)$/) {
3777 ($r_min, $r_max) = ($1, $2);
3778 } elsif ($::_revision =~ /^\d+$/) {
3779 $r_min = $r_max = $::_revision;
3780 } else {
3781 ::fatal "-r$::_revision is not supported, use ",
3782 "standard \'git log\' arguments instead\n";
3783 }
3784 }
3785
3786 config_pager();
3787 @args = git_svn_log_cmd($r_min, $r_max, @args);
3788 my $log = command_output_pipe(@args);
3789 run_pager();
3790 my (@k, $c, $d, $stat);
3791 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
3792 while (<$log>) {
3793 if (/^${esc_color}commit ($::sha1_short)/o) {
3794 my $cmt = $1;
3795 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
3796 $r_last = $c->{r};
3797 process_commit($c, $r_min, $r_max, \@k) or
3798 goto out;
3799 }
3800 $d = undef;
3801 $c = { c => $cmt };
3802 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
3803 get_author_info($c, $1, $2, $3);
3804 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
3805 # ignore
3806 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
3807 push @{$c->{raw}}, $_;
3808 } elsif (/^${esc_color}[ACRMDT]\t/) {
3809 # we could add $SVN->{svn_path} here, but that requires
3810 # remote access at the moment (repo_path_split)...
3811 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
3812 push @{$c->{changed}}, $_;
3813 } elsif (/^${esc_color}diff /o) {
3814 $d = 1;
3815 push @{$c->{diff}}, $_;
3816 } elsif ($d) {
3817 push @{$c->{diff}}, $_;
3818 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
3819 $esc_color*[\+\-]*$esc_color$/x) {
3820 $stat = 1;
3821 push @{$c->{stat}}, $_;
3822 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
3823 push @{$c->{stat}}, $_;
3824 $stat = undef;
3825 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
3826 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
3827 } elsif (s/^${esc_color} //o) {
3828 push @{$c->{l}}, $_;
3829 }
3830 }
3831 if ($c && defined $c->{r} && $c->{r} != $r_last) {
3832 $r_last = $c->{r};
3833 process_commit($c, $r_min, $r_max, \@k);
3834 }
3835 if (@k) {
3836 my $swap = $r_max;
3837 $r_max = $r_min;
3838 $r_min = $swap;
3839 process_commit($_, $r_min, $r_max) foreach reverse @k;
3840 }
3841 out:
3842 close $log;
3843 print '-' x72,"\n" unless $incremental || $oneline;
3844 }
3845
3846 package Git::SVN::Migration;
3847 # these version numbers do NOT correspond to actual version numbers
3848 # of git nor git-svn. They are just relative.
3849 #
3850 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
3851 #
3852 # v1 layout: .git/$id/info/url, refs/remotes/$id
3853 #
3854 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
3855 #
3856 # v3 layout: .git/svn/$id, refs/remotes/$id
3857 # - info/url may remain for backwards compatibility
3858 # - this is what we migrate up to this layout automatically,
3859 # - this will be used by git svn init on single branches
3860 # v3.1 layout (auto migrated):
3861 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
3862 # for backwards compatibility
3863 #
3864 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
3865 # - this is only created for newly multi-init-ed
3866 # repositories. Similar in spirit to the
3867 # --use-separate-remotes option in git-clone (now default)
3868 # - we do not automatically migrate to this (following
3869 # the example set by core git)
3870 use strict;
3871 use warnings;
3872 use Carp qw/croak/;
3873 use File::Path qw/mkpath/;
3874 use File::Basename qw/dirname basename/;
3875 use vars qw/$_minimize/;
3876
3877 sub migrate_from_v0 {
3878 my $git_dir = $ENV{GIT_DIR};
3879 return undef unless -d $git_dir;
3880 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3881 my $migrated = 0;
3882 while (<$fh>) {
3883 chomp;
3884 my ($id, $orig_ref) = ($_, $_);
3885 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
3886 next unless -f "$git_dir/$id/info/url";
3887 my $new_ref = "refs/remotes/$id";
3888 if (::verify_ref("$new_ref^0")) {
3889 print STDERR "W: $orig_ref is probably an old ",
3890 "branch used by an ancient version of ",
3891 "git-svn.\n",
3892 "However, $new_ref also exists.\n",
3893 "We will not be able ",
3894 "to use this branch until this ",
3895 "ambiguity is resolved.\n";
3896 next;
3897 }
3898 print STDERR "Migrating from v0 layout...\n" if !$migrated;
3899 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
3900 command_noisy('update-ref', $new_ref, $orig_ref);
3901 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
3902 $migrated++;
3903 }
3904 command_close_pipe($fh, $ctx);
3905 print STDERR "Done migrating from v0 layout...\n" if $migrated;
3906 $migrated;
3907 }
3908
3909 sub migrate_from_v1 {
3910 my $git_dir = $ENV{GIT_DIR};
3911 my $migrated = 0;
3912 return $migrated unless -d $git_dir;
3913 my $svn_dir = "$git_dir/svn";
3914
3915 # just in case somebody used 'svn' as their $id at some point...
3916 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
3917
3918 print STDERR "Migrating from a git-svn v1 layout...\n";
3919 mkpath([$svn_dir]);
3920 print STDERR "Data from a previous version of git-svn exists, but\n\t",
3921 "$svn_dir\n\t(required for this version ",
3922 "($::VERSION) of git-svn) does not. exist\n";
3923 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3924 while (<$fh>) {
3925 my $x = $_;
3926 next unless $x =~ s#^refs/remotes/##;
3927 chomp $x;
3928 next unless -f "$git_dir/$x/info/url";
3929 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
3930 next unless $u;
3931 my $dn = dirname("$git_dir/svn/$x");
3932 mkpath([$dn]) unless -d $dn;
3933 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
3934 mkpath(["$git_dir/svn/svn"]);
3935 print STDERR " - $git_dir/$x/info => ",
3936 "$git_dir/svn/$x/info\n";
3937 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
3938 croak "$!: $x";
3939 # don't worry too much about these, they probably
3940 # don't exist with repos this old (save for index,
3941 # and we can easily regenerate that)
3942 foreach my $f (qw/unhandled.log index .rev_db/) {
3943 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
3944 }
3945 } else {
3946 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
3947 rename "$git_dir/$x", "$git_dir/svn/$x" or
3948 croak "$!: $x";
3949 }
3950 $migrated++;
3951 }
3952 command_close_pipe($fh, $ctx);
3953 print STDERR "Done migrating from a git-svn v1 layout\n";
3954 $migrated;
3955 }
3956
3957 sub read_old_urls {
3958 my ($l_map, $pfx, $path) = @_;
3959 my @dir;
3960 foreach (<$path/*>) {
3961 if (-r "$_/info/url") {
3962 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
3963 my $ref_id = $pfx . basename $_;
3964 my $url = ::file_to_s("$_/info/url");
3965 $l_map->{$ref_id} = $url;
3966 } elsif (-d $_) {
3967 push @dir, $_;
3968 }
3969 }
3970 foreach (@dir) {
3971 my $x = $_;
3972 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
3973 read_old_urls($l_map, $x, $_);
3974 }
3975 }
3976
3977 sub migrate_from_v2 {
3978 my @cfg = command(qw/config -l/);
3979 return if grep /^svn-remote\..+\.url=/, @cfg;
3980 my %l_map;
3981 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
3982 my $migrated = 0;
3983
3984 foreach my $ref_id (sort keys %l_map) {
3985 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
3986 if ($@) {
3987 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
3988 }
3989 $migrated++;
3990 }
3991 $migrated;
3992 }
3993
3994 sub minimize_connections {
3995 my $r = Git::SVN::read_all_remotes();
3996 my $new_urls = {};
3997 my $root_repos = {};
3998 foreach my $repo_id (keys %$r) {
3999 my $url = $r->{$repo_id}->{url} or next;
4000 my $fetch = $r->{$repo_id}->{fetch} or next;
4001 my $ra = Git::SVN::Ra->new($url);
4002
4003 # skip existing cases where we already connect to the root
4004 if (($ra->{url} eq $ra->{repos_root}) ||
4005 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4006 $repo_id)) {
4007 $root_repos->{$ra->{url}} = $repo_id;
4008 next;
4009 }
4010
4011 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4012 my $root_path = $ra->{url};
4013 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4014 foreach my $path (keys %$fetch) {
4015 my $ref_id = $fetch->{$path};
4016 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4017
4018 # make sure we can read when connecting to
4019 # a higher level of a repository
4020 my ($last_rev, undef) = $gs->last_rev_commit;
4021 if (!defined $last_rev) {
4022 $last_rev = eval {
4023 $root_ra->get_latest_revnum;
4024 };
4025 next if $@;
4026 }
4027 my $new = $root_path;
4028 $new .= length $path ? "/$path" : '';
4029 eval {
4030 $root_ra->get_log([$new], $last_rev, $last_rev,
4031 0, 0, 1, sub { });
4032 };
4033 next if $@;
4034 $new_urls->{$ra->{repos_root}}->{$new} =
4035 { ref_id => $ref_id,
4036 old_repo_id => $repo_id,
4037 old_path => $path };
4038 }
4039 }
4040
4041 my @emptied;
4042 foreach my $url (keys %$new_urls) {
4043 # see if we can re-use an existing [svn-remote "repo_id"]
4044 # instead of creating a(n ugly) new section:
4045 my $repo_id = $root_repos->{$url} ||
4046 Git::SVN::sanitize_remote_name($url);
4047
4048 my $fetch = $new_urls->{$url};
4049 foreach my $path (keys %$fetch) {
4050 my $x = $fetch->{$path};
4051 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4052 my $pfx = "svn-remote.$x->{old_repo_id}";
4053
4054 my $old_fetch = quotemeta("$x->{old_path}:".
4055 "refs/remotes/$x->{ref_id}");
4056 command_noisy(qw/config --unset/,
4057 "$pfx.fetch", '^'. $old_fetch . '$');
4058 delete $r->{$x->{old_repo_id}}->
4059 {fetch}->{$x->{old_path}};
4060 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4061 command_noisy(qw/config --unset/,
4062 "$pfx.url");
4063 push @emptied, $x->{old_repo_id}
4064 }
4065 }
4066 }
4067 if (@emptied) {
4068 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4069 "$ENV{GIT_DIR}/config";
4070 print STDERR <<EOF;
4071 The following [svn-remote] sections in your config file ($file) are empty
4072 and can be safely removed:
4073 EOF
4074 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4075 }
4076 }
4077
4078 sub migration_check {
4079 migrate_from_v0();
4080 migrate_from_v1();
4081 migrate_from_v2();
4082 minimize_connections() if $_minimize;
4083 }
4084
4085 package Git::IndexInfo;
4086 use strict;
4087 use warnings;
4088 use Git qw/command_input_pipe command_close_pipe/;
4089
4090 sub new {
4091 my ($class) = @_;
4092 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4093 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4094 }
4095
4096 sub remove {
4097 my ($self, $path) = @_;
4098 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4099 return ++$self->{nr};
4100 }
4101 undef;
4102 }
4103
4104 sub update {
4105 my ($self, $mode, $hash, $path) = @_;
4106 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4107 return ++$self->{nr};
4108 }
4109 undef;
4110 }
4111
4112 sub DESTROY {
4113 my ($self) = @_;
4114 command_close_pipe($self->{gui}, $self->{ctx});
4115 }
4116
4117 package Git::SVN::GlobSpec;
4118 use strict;
4119 use warnings;
4120
4121 sub new {
4122 my ($class, $glob) = @_;
4123 my $re = $glob;
4124 $re =~ s!/+$!!g; # no need for trailing slashes
4125 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4126 my ($left, $right) = ($1, $2);
4127 if ($nr > 1) {
4128 die "Only one '*' wildcard expansion ",
4129 "is supported (got $nr): '$glob'\n";
4130 } elsif ($nr == 0) {
4131 die "One '*' is needed for glob: '$glob'\n";
4132 }
4133 $re = quotemeta($left) . $re . quotemeta($right);
4134 if (length $left && !($left =~ s!/+$!!g)) {
4135 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4136 }
4137 if (length $right && !($right =~ s!^/+!!g)) {
4138 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4139 }
4140 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4141 bless { left => $left, right => $right, left_regex => $left_re,
4142 regex => qr/$re/, glob => $glob }, $class;
4143 }
4144
4145 sub full_path {
4146 my ($self, $path) = @_;
4147 return (length $self->{left} ? "$self->{left}/" : '') .
4148 $path . (length $self->{right} ? "/$self->{right}" : '');
4149 }
4150
4151 __END__
4152
4153 Data structures:
4154
4155
4156 $remotes = { # returned by read_all_remotes()
4157 'svn' => {
4158 # svn-remote.svn.url=https://svn.musicpd.org
4159 url => 'https://svn.musicpd.org',
4160 # svn-remote.svn.fetch=mpd/trunk:trunk
4161 fetch => {
4162 'mpd/trunk' => 'trunk',
4163 },
4164 # svn-remote.svn.tags=mpd/tags/*:tags/*
4165 tags => {
4166 path => {
4167 left => 'mpd/tags',
4168 right => '',
4169 regex => qr!mpd/tags/([^/]+)$!,
4170 glob => 'tags/*',
4171 },
4172 ref => {
4173 left => 'tags',
4174 right => '',
4175 regex => qr!tags/([^/]+)$!,
4176 glob => 'tags/*',
4177 },
4178 }
4179 }
4180 };
4181
4182 $log_entry hashref as returned by libsvn_log_entry()
4183 {
4184 log => 'whitespace-formatted log entry
4185 ', # trailing newline is preserved
4186 revision => '8', # integer
4187 date => '2004-02-24T17:01:44.108345Z', # commit date
4188 author => 'committer name'
4189 };
4190
4191
4192 # this is generated by generate_diff();
4193 @mods = array of diff-index line hashes, each element represents one line
4194 of diff-index output
4195
4196 diff-index line ($m hash)
4197 {
4198 mode_a => first column of diff-index output, no leading ':',
4199 mode_b => second column of diff-index output,
4200 sha1_b => sha1sum of the final blob,
4201 chg => change type [MCRADT],
4202 file_a => original file name of a file (iff chg is 'C' or 'R')
4203 file_b => new/current file name of a file (any chg)
4204 }
4205 ;
4206
4207 # retval of read_url_paths{,_all}();
4208 $l_map = {
4209 # repository root url
4210 'https://svn.musicpd.org' => {
4211 # repository path # GIT_SVN_ID
4212 'mpd/trunk' => 'trunk',
4213 'mpd/tags/0.11.5' => 'tags/0.11.5',
4214 },
4215 }
4216
4217 Notes:
4218 I don't trust the each() function on unless I created %hash myself
4219 because the internal iterator may not have started at base.
knittl's private git fork