configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Define PYTHON_PATH to provide path to Python.
  79 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
  80 AS_HELP_STRING([--without-python], [don't use python scripts])],
  81  [if test "$withval" = "no"; then \
  82     NO_PYTHON=YesPlease; \
  83   elif test "$withval" = "yes"; then \
  84     NO_PYTHON=; \
  85   else \
  86     NO_PYTHON=; \
  87     PYTHON_PATH=$withval; \
  88   fi; \
  89  ])
  90 AC_SUBST(NO_PYTHON)
  91 AC_SUBST(PYTHON_PATH)
  92
  93
  94 ## Checks for programs.
  95 AC_MSG_NOTICE([CHECKS for programs])
  96 #
  97 AC_PROG_CC([cc gcc])
  98 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  99 AC_CHECK_TOOL(AR, ar, :)
 100 AC_CHECK_PROGS(TAR, [gtar tar])
 101 #
 102 # Define PYTHON_PATH to provide path to Python.
 103 if test -z "$NO_PYTHON"; then
 104         if test -z "$PYTHON_PATH"; then
 105                 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 106         fi
 107         if test -n "$PYTHON_PATH"; then
 108                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 109                 NO_PYTHON=""
 110         fi
 111 fi
 112
 113
 114 ## Checks for libraries.
 115 AC_MSG_NOTICE([CHECKS for libraries])
 116 #
 117 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 118 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 119 AC_CHECK_LIB([crypto], [SHA1_Init],
 120 [NEEDS_SSL_WITH_CRYPTO=],
 121 [AC_CHECK_LIB([ssl], [SHA1_Init],
 122  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 123   NEEDS_SSL_WITH_CRYPTO=],
 124  [NO_OPENSSL=YesPlease])])
 125 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 126 AC_SUBST(NO_OPENSSL)
 127 #
 128 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 129 # git-http-push are not built, and you cannot use http:// and https://
 130 # transports.
 131 AC_CHECK_LIB([curl], [curl_global_init],
 132 [NO_CURL=],
 133 [NO_CURL=YesPlease])
 134 AC_SUBST(NO_CURL)
 135 #
 136 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 137 # not built, and you cannot push using http:// and https:// transports.
 138 AC_CHECK_LIB([expat], [XML_ParserCreate],
 139 [NO_EXPAT=],
 140 [NO_EXPAT=YesPlease])
 141 AC_SUBST(NO_EXPAT)
 142 #
 143 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 144 # Define NO_ICONV if neither libc nor libiconv support iconv.
 145 AC_CHECK_LIB([c], [iconv],
 146         [NEEDS_LIBICONV=],
 147         AC_CHECK_LIB([iconv], [iconv],
 148                 [NEEDS_LIBICONV=YesPlease],
 149                 [NO_ICONV=YesPlease]))
 150 AC_SUBST(NEEDS_LIBICONV)
 151 AC_SUBST(NO_ICONV)
 152 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 153 #
 154 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 155 # Patrick Mauritz).
 156 AC_CHECK_LIB([c], [socket],
 157 [NEEDS_SOCKET=],
 158 [NEEDS_SOCKET=YesPlease])
 159 AC_SUBST(NEEDS_SOCKET)
 160 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 161
 162
 163 ## Checks for header files.
 164
 165
 166 ## Checks for typedefs, structures, and compiler characteristics.
 167 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 168 #
 169 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 170 AC_CHECK_MEMBER(struct dirent.d_ino,
 171 [NO_D_INO_IN_DIRENT=],
 172 [NO_D_INO_IN_DIRENT=YesPlease],
 173 [#include <dirent.h>])
 174 AC_SUBST(NO_D_INO_IN_DIRENT)
 175 #
 176 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 177 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 178 AC_CHECK_MEMBER(struct dirent.d_type,
 179 [NO_D_TYPE_IN_DIRENT=],
 180 [NO_D_TYPE_IN_DIRENT=YesPlease],
 181 [#include <dirent.h>])
 182 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 183 #
 184 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 185 # sockaddr_storage.
 186 AC_CHECK_TYPE(struct sockaddr_storage,
 187 [NO_SOCKADDR_STORAGE=],
 188 [NO_SOCKADDR_STORAGE=YesPlease],[
 189 #include <sys/types.h>
 190 #include <sys/socket.h>
 191 ])
 192 AC_SUBST(NO_SOCKADDR_STORAGE)
 193 #
 194 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 195 AC_CHECK_TYPE([struct addrinfo],[
 196  AC_CHECK_FUNC([getaddrinfo],
 197   [NO_IPV6=],
 198   [NO_IPV6=YesPlease])
 199 ],[NO_IPV6=YesPlease],[
 200 #include <sys/types.h>
 201 #include <sys/socket.h>
 202 #include <netdb.h>
 203 ])
 204 AC_SUBST(NO_IPV6)
 205 #
 206 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 207 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 208 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 209 # some C compilers supported these specifiers prior to C99 as an extension.
 210 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 211  [ac_cv_c_c99_format],
 212 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 213 AC_RUN_IFELSE(
 214         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 215                 [[char buf[64];
 216                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 217                   exit(1);
 218                 else if (strcmp(buf, "12345"))
 219                   exit(2);]])],
 220         [ac_cv_c_c99_format=yes],
 221         [ac_cv_c_c99_format=no])
 222 ])
 223 if test $ac_cv_c_c99_format = no; then
 224         NO_C99_FORMAT=YesPlease
 225 else
 226         NO_C99_FORMAT=
 227 fi
 228 AC_SUBST(NO_C99_FORMAT)
 229
 230
 231 ## Checks for library functions.
 232 ## (in default C library and libraries checked by AC_CHECK_LIB)
 233 AC_MSG_NOTICE([CHECKS for library functions])
 234 #
 235 # Define NO_STRCASESTR if you don't have strcasestr.
 236 AC_CHECK_FUNC(strcasestr,
 237 [NO_STRCASESTR=],
 238 [NO_STRCASESTR=YesPlease])
 239 AC_SUBST(NO_STRCASESTR)
 240 #
 241 # Define NO_STRLCPY if you don't have strlcpy.
 242 AC_CHECK_FUNC(strlcpy,
 243 [NO_STRLCPY=],
 244 [NO_STRLCPY=YesPlease])
 245 AC_SUBST(NO_STRLCPY)
 246 #
 247 # Define NO_SETENV if you don't have setenv in the C library.
 248 AC_CHECK_FUNC(setenv,
 249 [NO_SETENV=],
 250 [NO_SETENV=YesPlease])
 251 AC_SUBST(NO_SETENV)
 252 #
 253 # Define NO_MMAP if you want to avoid mmap.
 254 #
 255 # Define NO_ICONV if your libc does not properly support iconv.
 256
 257
 258 ## Other checks.
 259 # Define USE_PIC if you need the main git objects to be built with -fPIC
 260 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 261 #
 262 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 263 # Enable it on Windows.  By default, symrefs are still used.
 264 #
 265 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 266 AC_CACHE_CHECK([for subprocess.py],
 267  [ac_cv_python_has_subprocess_py],
 268 [if $PYTHON_PATH -c 'import subprocess' 2>/dev/null; then
 269         ac_cv_python_has_subprocess_py=yes
 270 else
 271         ac_cv_python_has_subprocess_py=no
 272 fi])
 273 if test $ac_cv_python_has_subprocess_py != yes; then
 274         GIT_CONF_APPEND_LINE([WITH_OWN_SUBPROCESS_PY=YesPlease])
 275 fi
 276 #
 277 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 278 # a missing newline at the end of the file.
 279
 280
 281 ## Site configuration (override autodetection)
 282 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 283 AC_MSG_NOTICE([CHECKS for site configuration])
 284 #
 285 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 286 # tests.  These tests take up a significant amount of the total test time
 287 # but are not needed unless you plan to talk to SVN repos.
 288 #
 289 # Define MOZILLA_SHA1 environment variable when running make to make use of
 290 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 291 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 292 # choice) has very fast version optimized for i586.
 293 #
 294 # Define PPC_SHA1 environment variable when running make to make use of
 295 # a bundled SHA1 routine optimized for PowerPC.
 296 #
 297 # Define ARM_SHA1 environment variable when running make to make use of
 298 # a bundled SHA1 routine optimized for ARM.
 299 #
 300 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 301 # This also implies MOZILLA_SHA1.
 302 #
 303 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 304 # /foo/bar/include and /foo/bar/lib directories.
 305 AC_ARG_WITH(openssl,
 306 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 307 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 308 GIT_PARSE_WITH(openssl))
 309 #
 310 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 311 # git-http-push are not built, and you cannot use http:// and https://
 312 # transports.
 313 #
 314 # Define CURLDIR=/foo/bar if your curl header and library files are in
 315 # /foo/bar/include and /foo/bar/lib directories.
 316 AC_ARG_WITH(curl,
 317 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 318 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 319 GIT_PARSE_WITH(curl))
 320 #
 321 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 322 # not built, and you cannot push using http:// and https:// transports.
 323 #
 324 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 325 # /foo/bar/include and /foo/bar/lib directories.
 326 AC_ARG_WITH(expat,
 327 AS_HELP_STRING([--with-expat],
 328 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 329 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 330 GIT_PARSE_WITH(expat))
 331 #
 332 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 333 # installed in /sw, but don't want GIT to link against any libraries
 334 # installed there.  If defined you may specify your own (or Fink's)
 335 # include directories and library directories by defining CFLAGS
 336 # and LDFLAGS appropriately.
 337 #
 338 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 339 # have DarwinPorts installed in /opt/local, but don't want GIT to
 340 # link against any libraries installed there.  If defined you may
 341 # specify your own (or DarwinPort's) include directories and
 342 # library directories by defining CFLAGS and LDFLAGS appropriately.
 343 #
 344 # Define NO_MMAP if you want to avoid mmap.
 345 #
 346 # Define NO_ICONV if your libc does not properly support iconv.
 347 AC_ARG_WITH(iconv,
 348 AS_HELP_STRING([--without-iconv],
 349 [if your architecture doesn't properly support iconv])
 350 AS_HELP_STRING([--with-iconv=PATH],
 351 [PATH is prefix for libiconv library and headers])
 352 AS_HELP_STRING([],
 353 [used only if you need linking with libiconv]),
 354 GIT_PARSE_WITH(iconv))
 355
 356 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 357 #
 358 # Define COLLISION_CHECK below if you believe that SHA1's
 359 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 360 # sufficient guarantee that no collisions between objects will ever happen.
 361 #
 362 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 363 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 364 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 365 # randomly break unless your underlying filesystem supports those sub-second
 366 # times (my ext3 doesn't).
 367 #
 368 # Define USE_STDEV below if you want git to care about the underlying device
 369 # change being considered an inode change from the update-cache perspective.
 370
 371
 372 ## Output files
 373 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 374 AC_OUTPUT
 375
 376
 377 ## Cleanup
 378 rm -f "${config_append}"