contrib/buildsystems/CMakeLists.txt

   1 #
   2 #       Copyright (c) 2020 Sibi Siddharthan
   3 #
   4
   5 #[[
   6
   7 Instructions how to use this in Visual Studio:
   8
   9 Open the worktree as a folder. Visual Studio 2019 and later will detect
  10 the CMake configuration automatically and set everything up for you,
  11 ready to build. You can then run the tests in `t/` via a regular Git Bash.
  12
  13 Note: Visual Studio also has the option of opening `CMakeLists.txt`
  14 directly; Using this option, Visual Studio will not find the source code,
  15 though, therefore the `File>Open>Folder...` option is preferred.
  16
  17 Instructions to run CMake manually:
  18
  19     mkdir -p contrib/buildsystems/out
  20     cd contrib/buildsystems/out
  21     cmake ../ -DCMAKE_BUILD_TYPE=Release
  22
  23 This will build the git binaries in contrib/buildsystems/out
  24 directory (our top-level .gitignore file knows to ignore contents of
  25 this directory).
  26
  27 Possible build configurations(-DCMAKE_BUILD_TYPE) with corresponding
  28 compiler flags
  29 Debug : -g
  30 Release: -O3
  31 RelWithDebInfo : -O2 -g
  32 MinSizeRel : -Os
  33 empty(default) :
  34
  35 NOTE: -DCMAKE_BUILD_TYPE is optional. For multi-config generators like Visual Studio
  36 this option is ignored
  37
  38 This process generates a Makefile(Linux/*BSD/MacOS) , Visual Studio solution(Windows) by default.
  39 Run `make` to build Git on Linux/*BSD/MacOS.
  40 Open git.sln on Windows and build Git.
  41
  42 NOTE: By default CMake uses Makefile as the build tool on Linux and Visual Studio in Windows,
  43 to use another tool say `ninja` add this to the command line when configuring.
  44 `-G Ninja`
  45
  46 NOTE: By default CMake will install vcpkg locally to your source tree on configuration,
  47 to avoid this, add `-DNO_VCPKG=TRUE` to the command line when configuring.
  48
  49 ]]
  50 cmake_minimum_required(VERSION 3.14)
  51
  52 #set the source directory to root of git
  53 set(CMAKE_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/../..)
  54
  55 option(USE_VCPKG "Whether or not to use vcpkg for obtaining dependencies.  Only applicable to Windows platforms" ON)
  56 if(NOT WIN32)
  57         set(USE_VCPKG OFF CACHE BOOL FORCE)
  58 endif()
  59
  60 if(NOT DEFINED CMAKE_EXPORT_COMPILE_COMMANDS)
  61         set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
  62 endif()
  63
  64 if(USE_VCPKG)
  65         set(VCPKG_DIR "${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg")
  66         if(NOT EXISTS ${VCPKG_DIR})
  67                 message("Initializing vcpkg and building the Git's dependencies (this will take a while...)")
  68                 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg_install.bat)
  69         endif()
  70         list(APPEND CMAKE_PREFIX_PATH "${VCPKG_DIR}/installed/x64-windows")
  71
  72         # In the vcpkg edition, we need this to be able to link to libcurl
  73         set(CURL_NO_CURL_CMAKE ON)
  74
  75         # Copy the necessary vcpkg DLLs (like iconv) to the install dir
  76         set(X_VCPKG_APPLOCAL_DEPS_INSTALL ON)
  77         set(CMAKE_TOOLCHAIN_FILE ${VCPKG_DIR}/scripts/buildsystems/vcpkg.cmake CACHE STRING "Vcpkg toolchain file")
  78 endif()
  79
  80 find_program(SH_EXE sh PATHS "C:/Program Files/Git/bin")
  81 if(NOT SH_EXE)
  82         message(FATAL_ERROR "sh: shell interpreter was not found in your path, please install one."
  83                         "On Windows, you can get it as part of 'Git for Windows' install at https://gitforwindows.org/")
  84 endif()
  85
  86 #Create GIT-VERSION-FILE using GIT-VERSION-GEN
  87 if(NOT EXISTS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE)
  88         message("Generating GIT-VERSION-FILE")
  89         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/GIT-VERSION-GEN
  90                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  91 endif()
  92
  93 #Parse GIT-VERSION-FILE to get the version
  94 file(STRINGS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE git_version REGEX "GIT_VERSION = (.*)")
  95 string(REPLACE "GIT_VERSION = " "" git_version ${git_version})
  96 string(FIND ${git_version} "GIT" location)
  97 if(location EQUAL -1)
  98         string(REGEX MATCH "[0-9]*\\.[0-9]*\\.[0-9]*" git_version ${git_version})
  99 else()
 100         string(REGEX MATCH "[0-9]*\\.[0-9]*" git_version ${git_version})
 101         string(APPEND git_version ".0") #for building from a snapshot
 102 endif()
 103
 104 project(git
 105         VERSION ${git_version}
 106         LANGUAGES C)
 107
 108
 109 #TODO gitk git-gui gitweb
 110 #TODO Enable NLS on windows natively
 111 #TODO Add pcre support
 112
 113 #macros for parsing the Makefile for sources and scripts
 114 macro(parse_makefile_for_sources list_var regex)
 115         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 116         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 117         string(REPLACE "$(COMPAT_OBJS)" "" ${list_var} ${${list_var}}) #remove "$(COMPAT_OBJS)" This is only for libgit.
 118         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 119         string(REPLACE ".o" ".c;" ${list_var} ${${list_var}}) #change .o to .c, ; is for converting the string into a list
 120         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 121         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 122 endmacro()
 123
 124 macro(parse_makefile_for_scripts list_var regex lang)
 125         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 126         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 127         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 128         string(REPLACE " " ";" ${list_var} ${${list_var}}) #convert string to a list
 129         if(NOT ${lang}) #exclude for SCRIPT_LIB
 130                 list(TRANSFORM ${list_var} REPLACE "${lang}" "") #do the replacement
 131         endif()
 132 endmacro()
 133
 134 macro(parse_makefile_for_executables list_var regex)
 135         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+= git-(.*)")
 136         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 137         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 138         string(REPLACE "git-" "" ${list_var} ${${list_var}}) #strip `git-` prefix
 139         string(REPLACE "\$X" ";" ${list_var} ${${list_var}}) #strip $X, ; is for converting the string into a list
 140         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 141         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 142 endmacro()
 143
 144 include(CheckTypeSize)
 145 include(CheckCSourceRuns)
 146 include(CheckCSourceCompiles)
 147 include(CheckIncludeFile)
 148 include(CheckFunctionExists)
 149 include(CheckSymbolExists)
 150 include(CheckStructHasMember)
 151 include(CTest)
 152
 153 find_package(ZLIB REQUIRED)
 154 find_package(CURL)
 155 find_package(EXPAT)
 156 find_package(Iconv)
 157
 158 #Don't use libintl on Windows Visual Studio and Clang builds
 159 if(NOT (WIN32 AND (CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")))
 160         find_package(Intl)
 161 endif()
 162
 163 if(NOT Intl_FOUND)
 164         add_compile_definitions(NO_GETTEXT)
 165         if(NOT Iconv_FOUND)
 166                 add_compile_definitions(NO_ICONV)
 167         endif()
 168 endif()
 169
 170 include_directories(SYSTEM ${ZLIB_INCLUDE_DIRS})
 171 if(CURL_FOUND)
 172         include_directories(SYSTEM ${CURL_INCLUDE_DIRS})
 173 endif()
 174 if(EXPAT_FOUND)
 175         include_directories(SYSTEM ${EXPAT_INCLUDE_DIRS})
 176 endif()
 177 if(Iconv_FOUND)
 178         include_directories(SYSTEM ${Iconv_INCLUDE_DIRS})
 179 endif()
 180 if(Intl_FOUND)
 181         include_directories(SYSTEM ${Intl_INCLUDE_DIRS})
 182 endif()
 183
 184
 185 if(WIN32 AND NOT MSVC)#not required for visual studio builds
 186         find_program(WINDRES_EXE windres)
 187         if(NOT WINDRES_EXE)
 188                 message(FATAL_ERROR "Install windres on Windows for resource files")
 189         endif()
 190 endif()
 191
 192 if(NO_GETTEXT)
 193         message(STATUS "msgfmt not used under NO_GETTEXT")
 194 else()
 195         find_program(MSGFMT_EXE msgfmt)
 196         if(NOT MSGFMT_EXE)
 197                 if(USE_VCPKG)
 198                         set(MSGFMT_EXE ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg/downloads/tools/msys2/msys64/usr/bin/msgfmt.exe)
 199                 endif()
 200                 if(NOT EXISTS ${MSGFMT_EXE})
 201                         message(WARNING "Text Translations won't be built")
 202                         unset(MSGFMT_EXE)
 203                 endif()
 204         endif()
 205 endif()
 206
 207 #Force all visual studio outputs to CMAKE_BINARY_DIR
 208 if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 209         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR})
 210         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR})
 211         add_compile_options(/MP /std:c11)
 212 endif()
 213
 214 #default behaviour
 215 include_directories(${CMAKE_SOURCE_DIR})
 216 add_compile_definitions(GIT_HOST_CPU="${CMAKE_SYSTEM_PROCESSOR}")
 217 add_compile_definitions(SHA256_BLK INTERNAL_QSORT RUNTIME_PREFIX)
 218 add_compile_definitions(NO_OPENSSL SHA1_DC SHA1DC_NO_STANDARD_INCLUDES
 219                         SHA1DC_INIT_SAFE_HASH_DEFAULT=0
 220                         SHA1DC_CUSTOM_INCLUDE_SHA1_C="cache.h"
 221                         SHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C="git-compat-util.h" )
 222 list(APPEND compat_SOURCES sha1dc_git.c sha1dc/sha1.c sha1dc/ubc_check.c block-sha1/sha1.c sha256/block/sha256.c compat/qsort_s.c)
 223
 224
 225 add_compile_definitions(PAGER_ENV="LESS=FRX LV=-c"
 226                         GIT_EXEC_PATH="libexec/git-core"
 227                         GIT_LOCALE_PATH="share/locale"
 228                         GIT_MAN_PATH="share/man"
 229                         GIT_INFO_PATH="share/info"
 230                         GIT_HTML_PATH="share/doc/git-doc"
 231                         DEFAULT_HELP_FORMAT="html"
 232                         DEFAULT_GIT_TEMPLATE_DIR="share/git-core/templates"
 233                         GIT_VERSION="${PROJECT_VERSION}.GIT"
 234                         GIT_USER_AGENT="git/${PROJECT_VERSION}.GIT"
 235                         BINDIR="bin"
 236                         GIT_BUILT_FROM_COMMIT="")
 237
 238 if(WIN32)
 239         set(FALLBACK_RUNTIME_PREFIX /mingw64)
 240         # Move system config into top-level /etc/
 241         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 242                 ETC_GITATTRIBUTES="../etc/gitattributes"
 243                 ETC_GITCONFIG="../etc/gitconfig")
 244 else()
 245         set(FALLBACK_RUNTIME_PREFIX /home/$ENV{USER})
 246         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 247                 ETC_GITATTRIBUTES="etc/gitattributes"
 248                 ETC_GITCONFIG="etc/gitconfig")
 249 endif()
 250
 251
 252 #Platform Specific
 253 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 254         if(CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")
 255                 include_directories(${CMAKE_SOURCE_DIR}/compat/vcbuild/include)
 256                 add_compile_definitions(_CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 257         endif()
 258         include_directories(${CMAKE_SOURCE_DIR}/compat/win32)
 259         add_compile_definitions(HAVE_ALLOCA_H NO_POSIX_GOODIES NATIVE_CRLF NO_UNIX_SOCKETS WIN32
 260                                 _CONSOLE DETECT_MSYS_TTY STRIP_EXTENSION=".exe"  NO_SYMLINK_HEAD UNRELIABLE_FSTAT
 261                                 NOGDI OBJECT_CREATION_MODE=1 __USE_MINGW_ANSI_STDIO=0
 262                                 USE_NED_ALLOCATOR OVERRIDE_STRDUP MMAP_PREVENTS_DELETE USE_WIN32_MMAP
 263                                 UNICODE _UNICODE HAVE_WPGMPTR ENSURE_MSYSTEM_IS_SET HAVE_RTLGENRANDOM)
 264         list(APPEND compat_SOURCES compat/mingw.c compat/winansi.c compat/win32/path-utils.c
 265                 compat/win32/pthread.c compat/win32mmap.c compat/win32/syslog.c
 266                 compat/win32/trace2_win32_process_info.c compat/win32/dirent.c
 267                 compat/nedmalloc/nedmalloc.c compat/strdup.c)
 268         set(NO_UNIX_SOCKETS 1)
 269
 270 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 271         add_compile_definitions(PROCFS_EXECUTABLE_PATH="/proc/self/exe" HAVE_DEV_TTY )
 272         list(APPEND compat_SOURCES unix-socket.c unix-stream-server.c)
 273 endif()
 274
 275 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 276         list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-win32.c)
 277         add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 278         set(SUPPORTS_SIMPLE_IPC 1)
 279 else()
 280         # Simple IPC requires both Unix sockets and pthreads on Unix-based systems.
 281         if(NOT NO_UNIX_SOCKETS AND NOT NO_PTHREADS)
 282                 list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-unix-socket.c)
 283                 add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 284                 set(SUPPORTS_SIMPLE_IPC 1)
 285         endif()
 286 endif()
 287
 288 if(SUPPORTS_SIMPLE_IPC)
 289         if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 290                 add_compile_definitions(HAVE_FSMONITOR_DAEMON_BACKEND)
 291                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-listen-win32.c)
 292         elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 293                 add_compile_definitions(HAVE_FSMONITOR_DAEMON_BACKEND)
 294                 list(APPEND compat_SOURCES compat/fsmonitor/fsm-listen-darwin.c)
 295         endif()
 296 endif()
 297
 298 set(EXE_EXTENSION ${CMAKE_EXECUTABLE_SUFFIX})
 299
 300 #header checks
 301 check_include_file(libgen.h HAVE_LIBGEN_H)
 302 if(NOT HAVE_LIBGEN_H)
 303         add_compile_definitions(NO_LIBGEN_H)
 304         list(APPEND compat_SOURCES compat/basename.c)
 305 endif()
 306
 307 check_include_file(sys/sysinfo.h HAVE_SYSINFO)
 308 if(HAVE_SYSINFO)
 309         add_compile_definitions(HAVE_SYSINFO)
 310 endif()
 311
 312 check_c_source_compiles("
 313 #include <alloca.h>
 314
 315 int main(void)
 316 {
 317         char *p = (char *) alloca(2 * sizeof(int));
 318
 319         if (p)
 320                 return 0;
 321         return 0;
 322 }"
 323 HAVE_ALLOCA_H)
 324 if(HAVE_ALLOCA_H)
 325         add_compile_definitions(HAVE_ALLOCA_H)
 326 endif()
 327
 328 check_include_file(strings.h HAVE_STRINGS_H)
 329 if(HAVE_STRINGS_H)
 330         add_compile_definitions(HAVE_STRINGS_H)
 331 endif()
 332
 333 check_include_file(sys/select.h HAVE_SYS_SELECT_H)
 334 if(NOT HAVE_SYS_SELECT_H)
 335         add_compile_definitions(NO_SYS_SELECT_H)
 336 endif()
 337
 338 check_include_file(sys/poll.h HAVE_SYS_POLL_H)
 339 if(NOT HAVE_SYS_POLL_H)
 340         add_compile_definitions(NO_SYS_POLL_H)
 341 endif()
 342
 343 check_include_file(poll.h HAVE_POLL_H)
 344 if(NOT HAVE_POLL_H)
 345         add_compile_definitions(NO_POLL_H)
 346 endif()
 347
 348 check_include_file(inttypes.h HAVE_INTTYPES_H)
 349 if(NOT HAVE_INTTYPES_H)
 350         add_compile_definitions(NO_INTTYPES_H)
 351 endif()
 352
 353 check_include_file(paths.h HAVE_PATHS_H)
 354 if(HAVE_PATHS_H)
 355         add_compile_definitions(HAVE_PATHS_H)
 356 endif()
 357
 358 #function checks
 359 set(function_checks
 360         strcasestr memmem strlcpy strtoimax strtoumax strtoull
 361         setenv mkdtemp poll pread memmem)
 362
 363 #unsetenv,hstrerror are incompatible with windows build
 364 if(NOT WIN32)
 365         list(APPEND function_checks unsetenv hstrerror)
 366 endif()
 367
 368 foreach(f ${function_checks})
 369         string(TOUPPER ${f} uf)
 370         check_function_exists(${f} HAVE_${uf})
 371         if(NOT HAVE_${uf})
 372                 add_compile_definitions(NO_${uf})
 373         endif()
 374 endforeach()
 375
 376 if(NOT HAVE_POLL_H OR NOT HAVE_SYS_POLL_H OR NOT HAVE_POLL)
 377         include_directories(${CMAKE_SOURCE_DIR}/compat/poll)
 378         add_compile_definitions(NO_POLL)
 379         list(APPEND compat_SOURCES compat/poll/poll.c)
 380 endif()
 381
 382 if(NOT HAVE_STRCASESTR)
 383         list(APPEND compat_SOURCES compat/strcasestr.c)
 384 endif()
 385
 386 if(NOT HAVE_STRLCPY)
 387         list(APPEND compat_SOURCES compat/strlcpy.c)
 388 endif()
 389
 390 if(NOT HAVE_STRTOUMAX)
 391         list(APPEND compat_SOURCES compat/strtoumax.c compat/strtoimax.c)
 392 endif()
 393
 394 if(NOT HAVE_SETENV)
 395         list(APPEND compat_SOURCES compat/setenv.c)
 396 endif()
 397
 398 if(NOT HAVE_MKDTEMP)
 399         list(APPEND compat_SOURCES compat/mkdtemp.c)
 400 endif()
 401
 402 if(NOT HAVE_PREAD)
 403         list(APPEND compat_SOURCES compat/pread.c)
 404 endif()
 405
 406 if(NOT HAVE_MEMMEM)
 407         list(APPEND compat_SOURCES compat/memmem.c)
 408 endif()
 409
 410 if(NOT WIN32)
 411         if(NOT HAVE_UNSETENV)
 412                 list(APPEND compat_SOURCES compat/unsetenv.c)
 413         endif()
 414
 415         if(NOT HAVE_HSTRERROR)
 416                 list(APPEND compat_SOURCES compat/hstrerror.c)
 417         endif()
 418 endif()
 419
 420 check_function_exists(getdelim HAVE_GETDELIM)
 421 if(HAVE_GETDELIM)
 422         add_compile_definitions(HAVE_GETDELIM)
 423 endif()
 424
 425 check_function_exists(clock_gettime HAVE_CLOCK_GETTIME)
 426 check_symbol_exists(CLOCK_MONOTONIC "time.h" HAVE_CLOCK_MONOTONIC)
 427 if(HAVE_CLOCK_GETTIME)
 428         add_compile_definitions(HAVE_CLOCK_GETTIME)
 429 endif()
 430 if(HAVE_CLOCK_MONOTONIC)
 431         add_compile_definitions(HAVE_CLOCK_MONOTONIC)
 432 endif()
 433
 434 #check for st_blocks in struct stat
 435 check_struct_has_member("struct stat" st_blocks "sys/stat.h" STRUCT_STAT_HAS_ST_BLOCKS)
 436 if(NOT STRUCT_STAT_HAS_ST_BLOCKS)
 437         add_compile_definitions(NO_ST_BLOCKS_IN_STRUCT_STAT)
 438 endif()
 439
 440 #compile checks
 441 check_c_source_runs("
 442 #include<stdio.h>
 443 #include<stdarg.h>
 444 #include<string.h>
 445 #include<stdlib.h>
 446
 447 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 448 {
 449         int ret;
 450         va_list ap;
 451
 452         va_start(ap, format);
 453         ret = vsnprintf(str, maxsize, format, ap);
 454         va_end(ap);
 455         return ret;
 456 }
 457
 458 int main(void)
 459 {
 460         char buf[6];
 461
 462         if (test_vsnprintf(buf, 3, \"%s\", \"12345\") != 5
 463                 || strcmp(buf, \"12\"))
 464                         return 1;
 465         if (snprintf(buf, 3, \"%s\", \"12345\") != 5
 466                 || strcmp(buf, \"12\"))
 467                         return 1;
 468         return 0;
 469 }"
 470 SNPRINTF_OK)
 471 if(NOT SNPRINTF_OK)
 472         add_compile_definitions(SNPRINTF_RETURNS_BOGUS)
 473         list(APPEND compat_SOURCES compat/snprintf.c)
 474 endif()
 475
 476 check_c_source_runs("
 477 #include<stdio.h>
 478
 479 int main(void)
 480 {
 481         FILE *f = fopen(\".\", \"r\");
 482
 483         return f != NULL;
 484 }"
 485 FREAD_READS_DIRECTORIES_NO)
 486 if(NOT FREAD_READS_DIRECTORIES_NO)
 487         add_compile_definitions(FREAD_READS_DIRECTORIES)
 488         list(APPEND compat_SOURCES compat/fopen.c)
 489 endif()
 490
 491 check_c_source_compiles("
 492 #include <regex.h>
 493 #ifndef REG_STARTEND
 494 #error oops we dont have it
 495 #endif
 496
 497 int main(void)
 498 {
 499         return 0;
 500 }"
 501 HAVE_REGEX)
 502 if(NOT HAVE_REGEX)
 503         include_directories(${CMAKE_SOURCE_DIR}/compat/regex)
 504         list(APPEND compat_SOURCES compat/regex/regex.c )
 505         add_compile_definitions(NO_REGEX NO_MBSUPPORT GAWK)
 506 endif()
 507
 508
 509 check_c_source_compiles("
 510 #include <stddef.h>
 511 #include <sys/types.h>
 512 #include <sys/sysctl.h>
 513
 514 int main(void)
 515 {
 516         int val, mib[2];
 517         size_t len;
 518
 519         mib[0] = CTL_HW;
 520         mib[1] = 1;
 521         len = sizeof(val);
 522         return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
 523 }"
 524 HAVE_BSD_SYSCTL)
 525 if(HAVE_BSD_SYSCTL)
 526         add_compile_definitions(HAVE_BSD_SYSCTL)
 527 endif()
 528
 529 set(CMAKE_REQUIRED_LIBRARIES ${Iconv_LIBRARIES})
 530 set(CMAKE_REQUIRED_INCLUDES ${Iconv_INCLUDE_DIRS})
 531
 532 check_c_source_compiles("
 533 #include <iconv.h>
 534
 535 extern size_t iconv(iconv_t cd,
 536                 char **inbuf, size_t *inbytesleft,
 537                 char **outbuf, size_t *outbytesleft);
 538
 539 int main(void)
 540 {
 541         return 0;
 542 }"
 543 HAVE_NEW_ICONV)
 544 if(HAVE_NEW_ICONV)
 545         set(HAVE_OLD_ICONV 0)
 546 else()
 547         set(HAVE_OLD_ICONV 1)
 548 endif()
 549
 550 check_c_source_runs("
 551 #include <iconv.h>
 552 #if ${HAVE_OLD_ICONV}
 553 typedef const char *iconv_ibp;
 554 #else
 555 typedef char *iconv_ibp;
 556 #endif
 557
 558 int main(void)
 559 {
 560         int v;
 561         iconv_t conv;
 562         char in[] = \"a\";
 563         iconv_ibp pin = in;
 564         char out[20] = \"\";
 565         char *pout = out;
 566         size_t isz = sizeof(in);
 567         size_t osz = sizeof(out);
 568
 569         conv = iconv_open(\"UTF-16\", \"UTF-8\");
 570         iconv(conv, &pin, &isz, &pout, &osz);
 571         iconv_close(conv);
 572         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 573         return v != 0xfe + 0xff;
 574 }"
 575 ICONV_DOESNOT_OMIT_BOM)
 576 if(NOT ICONV_DOESNOT_OMIT_BOM)
 577         add_compile_definitions(ICONV_OMITS_BOM)
 578 endif()
 579
 580 unset(CMAKE_REQUIRED_LIBRARIES)
 581 unset(CMAKE_REQUIRED_INCLUDES)
 582
 583
 584 #programs
 585 set(PROGRAMS_BUILT
 586         git git-daemon git-http-backend git-sh-i18n--envsubst
 587         git-shell)
 588
 589 if(NOT CURL_FOUND)
 590         list(APPEND excluded_progs git-http-fetch git-http-push)
 591         add_compile_definitions(NO_CURL)
 592         message(WARNING "git-http-push and git-http-fetch will not be built")
 593 else()
 594         list(APPEND PROGRAMS_BUILT git-http-fetch git-http-push git-imap-send git-remote-http)
 595         if(CURL_VERSION_STRING VERSION_GREATER_EQUAL 7.34.0)
 596                 add_compile_definitions(USE_CURL_FOR_IMAP_SEND)
 597         endif()
 598 endif()
 599
 600 if(NOT EXPAT_FOUND)
 601         list(APPEND excluded_progs git-http-push)
 602         add_compile_definitions(NO_EXPAT)
 603 else()
 604         list(APPEND PROGRAMS_BUILT git-http-push)
 605         if(EXPAT_VERSION_STRING VERSION_LESS_EQUAL 1.2)
 606                 add_compile_definitions(EXPAT_NEEDS_XMLPARSE_H)
 607         endif()
 608 endif()
 609
 610 list(REMOVE_DUPLICATES excluded_progs)
 611 list(REMOVE_DUPLICATES PROGRAMS_BUILT)
 612
 613
 614 foreach(p ${excluded_progs})
 615         list(APPEND EXCLUSION_PROGS --exclude-program ${p} )
 616 endforeach()
 617
 618 #for comparing null values
 619 list(APPEND EXCLUSION_PROGS empty)
 620 set(EXCLUSION_PROGS_CACHE ${EXCLUSION_PROGS} CACHE STRING "Programs not built" FORCE)
 621
 622 if(NOT EXISTS ${CMAKE_BINARY_DIR}/command-list.h OR NOT EXCLUSION_PROGS_CACHE STREQUAL EXCLUSION_PROGS)
 623         list(REMOVE_ITEM EXCLUSION_PROGS empty)
 624         message("Generating command-list.h")
 625         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-cmdlist.sh ${EXCLUSION_PROGS} command-list.txt
 626                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 627                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/command-list.h)
 628 endif()
 629
 630 if(NOT EXISTS ${CMAKE_BINARY_DIR}/config-list.h)
 631         message("Generating config-list.h")
 632         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-configlist.sh
 633                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 634                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/config-list.h)
 635 endif()
 636
 637 if(NOT EXISTS ${CMAKE_BINARY_DIR}/hook-list.h)
 638         message("Generating hook-list.h")
 639         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-hooklist.sh
 640                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 641                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/hook-list.h)
 642 endif()
 643
 644 include_directories(${CMAKE_BINARY_DIR})
 645
 646 #build
 647 #libgit
 648 parse_makefile_for_sources(libgit_SOURCES "LIB_OBJS")
 649
 650 list(TRANSFORM libgit_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 651 list(TRANSFORM compat_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 652 add_library(libgit ${libgit_SOURCES} ${compat_SOURCES})
 653
 654 #libxdiff
 655 parse_makefile_for_sources(libxdiff_SOURCES "XDIFF_OBJS")
 656
 657 list(TRANSFORM libxdiff_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 658 add_library(xdiff STATIC ${libxdiff_SOURCES})
 659
 660 #reftable
 661 parse_makefile_for_sources(reftable_SOURCES "REFTABLE_OBJS")
 662
 663 list(TRANSFORM reftable_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 664 add_library(reftable STATIC ${reftable_SOURCES})
 665
 666 if(WIN32)
 667         if(NOT MSVC)#use windres when compiling with gcc and clang
 668                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 669                                 COMMAND ${WINDRES_EXE} -O coff -DMAJOR=${PROJECT_VERSION_MAJOR} -DMINOR=${PROJECT_VERSION_MINOR}
 670                                         -DMICRO=${PROJECT_VERSION_PATCH} -DPATCHLEVEL=0 -DGIT_VERSION="\\\"${PROJECT_VERSION}.GIT\\\""
 671                                         -i ${CMAKE_SOURCE_DIR}/git.rc -o ${CMAKE_BINARY_DIR}/git.res
 672                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 673                                 VERBATIM)
 674         else()#MSVC use rc
 675                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 676                                 COMMAND ${CMAKE_RC_COMPILER} /d MAJOR=${PROJECT_VERSION_MAJOR} /d MINOR=${PROJECT_VERSION_MINOR}
 677                                         /d MICRO=${PROJECT_VERSION_PATCH} /d PATCHLEVEL=0 /d GIT_VERSION="${PROJECT_VERSION}.GIT"
 678                                         /fo ${CMAKE_BINARY_DIR}/git.res ${CMAKE_SOURCE_DIR}/git.rc
 679                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 680                                 VERBATIM)
 681         endif()
 682         add_custom_target(git-rc DEPENDS ${CMAKE_BINARY_DIR}/git.res)
 683 endif()
 684
 685 #link all required libraries to common-main
 686 add_library(common-main OBJECT ${CMAKE_SOURCE_DIR}/common-main.c)
 687
 688 target_link_libraries(common-main libgit xdiff reftable ${ZLIB_LIBRARIES})
 689 if(Intl_FOUND)
 690         target_link_libraries(common-main ${Intl_LIBRARIES})
 691 endif()
 692 if(Iconv_FOUND)
 693         target_link_libraries(common-main ${Iconv_LIBRARIES})
 694 endif()
 695 if(WIN32)
 696         target_link_libraries(common-main ws2_32 ntdll ${CMAKE_BINARY_DIR}/git.res)
 697         add_dependencies(common-main git-rc)
 698         if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 699                 target_link_options(common-main PUBLIC -municode -Wl,--nxcompat -Wl,--dynamicbase -Wl,--pic-executable,-e,mainCRTStartup)
 700         elseif(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 701                 target_link_options(common-main PUBLIC -municode -Wl,-nxcompat -Wl,-dynamicbase -Wl,-entry:wmainCRTStartup -Wl,invalidcontinue.obj)
 702         elseif(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 703                 target_link_options(common-main PUBLIC /IGNORE:4217 /IGNORE:4049 /NOLOGO /ENTRY:wmainCRTStartup /SUBSYSTEM:CONSOLE invalidcontinue.obj)
 704         else()
 705                 message(FATAL_ERROR "Unhandled compiler: ${CMAKE_C_COMPILER_ID}")
 706         endif()
 707 elseif(UNIX)
 708         target_link_libraries(common-main pthread rt)
 709 endif()
 710
 711 #git
 712 parse_makefile_for_sources(git_SOURCES "BUILTIN_OBJS")
 713
 714 list(TRANSFORM git_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 715 add_executable(git ${CMAKE_SOURCE_DIR}/git.c ${git_SOURCES})
 716 target_link_libraries(git common-main)
 717
 718 add_executable(git-daemon ${CMAKE_SOURCE_DIR}/daemon.c)
 719 target_link_libraries(git-daemon common-main)
 720
 721 add_executable(git-http-backend ${CMAKE_SOURCE_DIR}/http-backend.c)
 722 target_link_libraries(git-http-backend common-main)
 723
 724 add_executable(git-sh-i18n--envsubst ${CMAKE_SOURCE_DIR}/sh-i18n--envsubst.c)
 725 target_link_libraries(git-sh-i18n--envsubst common-main)
 726
 727 add_executable(git-shell ${CMAKE_SOURCE_DIR}/shell.c)
 728 target_link_libraries(git-shell common-main)
 729
 730 if(CURL_FOUND)
 731         add_library(http_obj OBJECT ${CMAKE_SOURCE_DIR}/http.c)
 732
 733         add_executable(git-imap-send ${CMAKE_SOURCE_DIR}/imap-send.c)
 734         target_link_libraries(git-imap-send http_obj common-main ${CURL_LIBRARIES})
 735
 736         add_executable(git-http-fetch ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/http-fetch.c)
 737         target_link_libraries(git-http-fetch http_obj common-main ${CURL_LIBRARIES})
 738
 739         add_executable(git-remote-http ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/remote-curl.c)
 740         target_link_libraries(git-remote-http http_obj common-main ${CURL_LIBRARIES} )
 741
 742         if(EXPAT_FOUND)
 743                 add_executable(git-http-push ${CMAKE_SOURCE_DIR}/http-push.c)
 744                 target_link_libraries(git-http-push http_obj common-main ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 745         endif()
 746 endif()
 747
 748 parse_makefile_for_executables(git_builtin_extra "BUILT_INS")
 749
 750 option(SKIP_DASHED_BUILT_INS "Skip hardlinking the dashed versions of the built-ins")
 751
 752 #Creating hardlinks
 753 if(NOT SKIP_DASHED_BUILT_INS)
 754 foreach(s ${git_SOURCES} ${git_builtin_extra})
 755         string(REPLACE "${CMAKE_SOURCE_DIR}/builtin/" "" s ${s})
 756         string(REPLACE ".c" "" s ${s})
 757         file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git${EXE_EXTENSION} git-${s}${EXE_EXTENSION})\n")
 758         list(APPEND git_links ${CMAKE_BINARY_DIR}/git-${s}${EXE_EXTENSION})
 759 endforeach()
 760 endif()
 761
 762 if(CURL_FOUND)
 763         set(remote_exes
 764                 git-remote-https git-remote-ftp git-remote-ftps)
 765         foreach(s ${remote_exes})
 766                 file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git-remote-http${EXE_EXTENSION} ${s}${EXE_EXTENSION})\n")
 767                 list(APPEND git_http_links ${CMAKE_BINARY_DIR}/${s}${EXE_EXTENSION})
 768         endforeach()
 769 endif()
 770
 771 add_custom_command(OUTPUT ${git_links} ${git_http_links}
 772                 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/CreateLinks.cmake
 773                 DEPENDS git git-remote-http)
 774 add_custom_target(git-links ALL DEPENDS ${git_links} ${git_http_links})
 775
 776
 777 #creating required scripts
 778 set(SHELL_PATH /bin/sh)
 779 set(PERL_PATH /usr/bin/perl)
 780 set(LOCALEDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 781 set(GITWEBDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 782 set(INSTLIBDIR ${FALLBACK_RUNTIME_PREFIX}/share/perl5)
 783
 784 #shell scripts
 785 parse_makefile_for_scripts(git_sh_scripts "SCRIPT_SH" ".sh")
 786 parse_makefile_for_scripts(git_shlib_scripts "SCRIPT_LIB" "")
 787 set(git_shell_scripts
 788         ${git_sh_scripts} ${git_shlib_scripts} git-instaweb)
 789
 790 foreach(script ${git_shell_scripts})
 791         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.sh content NEWLINE_CONSUME)
 792         string(REPLACE "@SHELL_PATH@" "${SHELL_PATH}" content "${content}")
 793         string(REPLACE "@@DIFF@@" "diff" content "${content}")
 794         string(REPLACE "@LOCALEDIR@" "${LOCALEDIR}" content "${content}")
 795         string(REPLACE "@GITWEBDIR@" "${GITWEBDIR}" content "${content}")
 796         string(REPLACE "@@NO_CURL@@" "" content "${content}")
 797         string(REPLACE "@@USE_GETTEXT_SCHEME@@" "" content "${content}")
 798         string(REPLACE "# @@BROKEN_PATH_FIX@@" "" content "${content}")
 799         string(REPLACE "@@PERL@@" "${PERL_PATH}" content "${content}")
 800         string(REPLACE "@@PAGER_ENV@@" "LESS=FRX LV=-c" content "${content}")
 801         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 802 endforeach()
 803
 804 #perl scripts
 805 parse_makefile_for_scripts(git_perl_scripts "SCRIPT_PERL" ".perl")
 806
 807 #create perl header
 808 file(STRINGS ${CMAKE_SOURCE_DIR}/perl/header_templates/fixed_prefix.template.pl perl_header )
 809 string(REPLACE "@@PATHSEP@@" ":" perl_header "${perl_header}")
 810 string(REPLACE "@@INSTLIBDIR@@" "${INSTLIBDIR}" perl_header "${perl_header}")
 811
 812 foreach(script ${git_perl_scripts})
 813         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.perl content NEWLINE_CONSUME)
 814         string(REPLACE "#!/usr/bin/perl" "#!/usr/bin/perl\n${perl_header}\n" content "${content}")
 815         string(REPLACE "@@GIT_VERSION@@" "${PROJECT_VERSION}" content "${content}")
 816         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 817 endforeach()
 818
 819 #python script
 820 file(STRINGS ${CMAKE_SOURCE_DIR}/git-p4.py content NEWLINE_CONSUME)
 821 string(REPLACE "#!/usr/bin/env python" "#!/usr/bin/python" content "${content}")
 822 file(WRITE ${CMAKE_BINARY_DIR}/git-p4 ${content})
 823
 824 #perl modules
 825 file(GLOB_RECURSE perl_modules "${CMAKE_SOURCE_DIR}/perl/*.pm")
 826
 827 foreach(pm ${perl_modules})
 828         string(REPLACE "${CMAKE_SOURCE_DIR}/perl/" "" file_path ${pm})
 829         file(STRINGS ${pm} content NEWLINE_CONSUME)
 830         string(REPLACE "@@LOCALEDIR@@" "${LOCALEDIR}" content "${content}")
 831         string(REPLACE "@@NO_PERL_CPAN_FALLBACKS@@" "" content "${content}")
 832         file(WRITE ${CMAKE_BINARY_DIR}/perl/build/lib/${file_path} ${content})
 833 #test-lib.sh requires perl/build/lib to be the build directory of perl modules
 834 endforeach()
 835
 836
 837 #templates
 838 file(GLOB templates "${CMAKE_SOURCE_DIR}/templates/*")
 839 list(TRANSFORM templates REPLACE "${CMAKE_SOURCE_DIR}/templates/" "")
 840 list(REMOVE_ITEM templates ".gitignore")
 841 list(REMOVE_ITEM templates "Makefile")
 842 list(REMOVE_ITEM templates "blt")# Prevents an error when reconfiguring for in source builds
 843
 844 list(REMOVE_ITEM templates "branches--")
 845 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/branches) #create branches
 846
 847 #templates have @.*@ replacement so use configure_file instead
 848 foreach(tm ${templates})
 849         string(REPLACE "--" "/" blt_tm ${tm})
 850         string(REPLACE "this" "" blt_tm ${blt_tm})# for this--
 851         configure_file(${CMAKE_SOURCE_DIR}/templates/${tm} ${CMAKE_BINARY_DIR}/templates/blt/${blt_tm} @ONLY)
 852 endforeach()
 853
 854
 855 #translations
 856 if(MSGFMT_EXE)
 857         file(GLOB po_files "${CMAKE_SOURCE_DIR}/po/*.po")
 858         list(TRANSFORM po_files REPLACE "${CMAKE_SOURCE_DIR}/po/" "")
 859         list(TRANSFORM po_files REPLACE ".po" "")
 860         foreach(po ${po_files})
 861                 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES)
 862                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo
 863                                 COMMAND ${MSGFMT_EXE} --check --statistics -o ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo ${CMAKE_SOURCE_DIR}/po/${po}.po)
 864                 list(APPEND po_gen ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo)
 865         endforeach()
 866         add_custom_target(po-gen ALL DEPENDS ${po_gen})
 867 endif()
 868
 869
 870 #to help with the install
 871 list(TRANSFORM git_shell_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 872 list(TRANSFORM git_perl_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 873
 874 #install
 875 foreach(program ${PROGRAMS_BUILT})
 876 if(program STREQUAL "git" OR program STREQUAL "git-shell")
 877 install(TARGETS ${program}
 878         RUNTIME DESTINATION bin)
 879 else()
 880 install(TARGETS ${program}
 881         RUNTIME DESTINATION libexec/git-core)
 882 endif()
 883 endforeach()
 884
 885 install(PROGRAMS ${CMAKE_BINARY_DIR}/git-cvsserver
 886         DESTINATION bin)
 887
 888 set(bin_links
 889         git-receive-pack git-upload-archive git-upload-pack)
 890
 891 foreach(b ${bin_links})
 892 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/bin/${b}${EXE_EXTENSION})")
 893 endforeach()
 894
 895 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git${EXE_EXTENSION})")
 896 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git-shell${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-shell${EXE_EXTENSION})")
 897
 898 foreach(b ${git_links})
 899         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 900         install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 901 endforeach()
 902
 903 foreach(b ${git_http_links})
 904         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 905         install(CODE "file(CREATE_LINK  ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-remote-http${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 906 endforeach()
 907
 908 install(PROGRAMS ${git_shell_scripts} ${git_perl_scripts} ${CMAKE_BINARY_DIR}/git-p4
 909         DESTINATION libexec/git-core)
 910
 911 install(DIRECTORY ${CMAKE_SOURCE_DIR}/mergetools DESTINATION libexec/git-core)
 912 install(DIRECTORY ${CMAKE_BINARY_DIR}/perl/build/lib/ DESTINATION share/perl5
 913         FILES_MATCHING PATTERN "*.pm")
 914 install(DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/ DESTINATION share/git-core/templates)
 915
 916 if(MSGFMT_EXE)
 917         install(DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale DESTINATION share)
 918 endif()
 919
 920
 921 if(BUILD_TESTING)
 922
 923 #tests-helpers
 924 add_executable(test-fake-ssh ${CMAKE_SOURCE_DIR}/t/helper/test-fake-ssh.c)
 925 target_link_libraries(test-fake-ssh common-main)
 926
 927 #reftable-tests
 928 parse_makefile_for_sources(test-reftable_SOURCES "REFTABLE_TEST_OBJS")
 929 list(TRANSFORM test-reftable_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 930
 931 #test-tool
 932 parse_makefile_for_sources(test-tool_SOURCES "TEST_BUILTINS_OBJS")
 933
 934 list(TRANSFORM test-tool_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/t/helper/")
 935 add_executable(test-tool ${CMAKE_SOURCE_DIR}/t/helper/test-tool.c ${test-tool_SOURCES} ${test-reftable_SOURCES})
 936 target_link_libraries(test-tool common-main)
 937
 938 set_target_properties(test-fake-ssh test-tool
 939                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/t/helper)
 940
 941 if(MSVC)
 942         set_target_properties(test-fake-ssh test-tool
 943                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR}/t/helper)
 944         set_target_properties(test-fake-ssh test-tool
 945                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR}/t/helper)
 946 endif()
 947
 948 #wrapper scripts
 949 set(wrapper_scripts
 950         git git-upload-pack git-receive-pack git-upload-archive git-shell git-remote-ext)
 951
 952 set(wrapper_test_scripts
 953         test-fake-ssh test-tool)
 954
 955
 956 foreach(script ${wrapper_scripts})
 957         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 958         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 959         string(REPLACE "@@PROG@@" "${script}${EXE_EXTENSION}" content "${content}")
 960         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 961 endforeach()
 962
 963 foreach(script ${wrapper_test_scripts})
 964         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 965         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 966         string(REPLACE "@@PROG@@" "t/helper/${script}${EXE_EXTENSION}" content "${content}")
 967         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 968 endforeach()
 969
 970 file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 971 string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 972 string(REPLACE "@@PROG@@" "git-cvsserver" content "${content}")
 973 file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/git-cvsserver ${content})
 974
 975 #options for configuring test options
 976 option(PERL_TESTS "Perform tests that use perl" ON)
 977 option(PYTHON_TESTS "Perform tests that use python" ON)
 978
 979 #GIT-BUILD-OPTIONS
 980 set(TEST_SHELL_PATH ${SHELL_PATH})
 981 set(DIFF diff)
 982 set(PYTHON_PATH /usr/bin/python)
 983 set(TAR tar)
 984 set(NO_CURL )
 985 set(NO_EXPAT )
 986 set(USE_LIBPCRE2 )
 987 set(NO_PERL )
 988 set(NO_PTHREADS )
 989 set(NO_PYTHON )
 990 set(PAGER_ENV "LESS=FRX LV=-c")
 991 set(DC_SHA1 YesPlease)
 992 set(RUNTIME_PREFIX true)
 993 set(NO_GETTEXT )
 994
 995 if(NOT CURL_FOUND)
 996         set(NO_CURL 1)
 997 endif()
 998
 999 if(NOT EXPAT_FOUND)
1000         set(NO_EXPAT 1)
1001 endif()
1002
1003 if(NOT Intl_FOUND)
1004         set(NO_GETTEXT 1)
1005 endif()
1006
1007 if(NOT PERL_TESTS)
1008         set(NO_PERL 1)
1009 endif()
1010
1011 if(NOT PYTHON_TESTS)
1012         set(NO_PYTHON 1)
1013 endif()
1014
1015 file(WRITE ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SHELL_PATH='${SHELL_PATH}'\n")
1016 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TEST_SHELL_PATH='${TEST_SHELL_PATH}'\n")
1017 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PERL_PATH='${PERL_PATH}'\n")
1018 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DIFF='${DIFF}'\n")
1019 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PYTHON_PATH='${PYTHON_PATH}'\n")
1020 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TAR='${TAR}'\n")
1021 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_CURL='${NO_CURL}'\n")
1022 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_EXPAT='${NO_EXPAT}'\n")
1023 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PERL='${NO_PERL}'\n")
1024 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PTHREADS='${NO_PTHREADS}'\n")
1025 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_UNIX_SOCKETS='${NO_UNIX_SOCKETS}'\n")
1026 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PAGER_ENV='${PAGER_ENV}'\n")
1027 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DC_SHA1='${DC_SHA1}'\n")
1028 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "X='${EXE_EXTENSION}'\n")
1029 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_GETTEXT='${NO_GETTEXT}'\n")
1030 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "RUNTIME_PREFIX='${RUNTIME_PREFIX}'\n")
1031 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PYTHON='${NO_PYTHON}'\n")
1032 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SUPPORTS_SIMPLE_IPC='${SUPPORTS_SIMPLE_IPC}'\n")
1033 if(USE_VCPKG)
1034         file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PATH=\"$PATH:$TEST_DIRECTORY/../compat/vcbuild/vcpkg/installed/x64-windows/bin\"\n")
1035 endif()
1036
1037 #Make the tests work when building out of the source tree
1038 get_filename_component(CACHE_PATH ${CMAKE_CURRENT_LIST_DIR}/../../CMakeCache.txt ABSOLUTE)
1039 if(NOT ${CMAKE_BINARY_DIR}/CMakeCache.txt STREQUAL ${CACHE_PATH})
1040         file(RELATIVE_PATH BUILD_DIR_RELATIVE ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/CMakeCache.txt)
1041         string(REPLACE "/CMakeCache.txt" "" BUILD_DIR_RELATIVE ${BUILD_DIR_RELATIVE})
1042         #Setting the build directory in test-lib.sh before running tests
1043         file(WRITE ${CMAKE_BINARY_DIR}/CTestCustom.cmake
1044                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh GIT_BUILD_DIR_REPL REGEX \"GIT_BUILD_DIR=(.*)\")\n"
1045                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh content NEWLINE_CONSUME)\n"
1046                 "string(REPLACE \"\${GIT_BUILD_DIR_REPL}\" \"GIT_BUILD_DIR=\\\"$TEST_DIRECTORY/../${BUILD_DIR_RELATIVE}\\\"\" content \"\${content}\")\n"
1047                 "file(WRITE ${CMAKE_SOURCE_DIR}/t/test-lib.sh \${content})")
1048         #misc copies
1049         file(COPY ${CMAKE_SOURCE_DIR}/t/chainlint.sed DESTINATION ${CMAKE_BINARY_DIR}/t/)
1050         file(COPY ${CMAKE_SOURCE_DIR}/po/is.po DESTINATION ${CMAKE_BINARY_DIR}/po/)
1051         file(COPY ${CMAKE_SOURCE_DIR}/mergetools/tkdiff DESTINATION ${CMAKE_BINARY_DIR}/mergetools/)
1052         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-prompt.sh DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1053         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-completion.bash DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1054 endif()
1055
1056 file(GLOB test_scipts "${CMAKE_SOURCE_DIR}/t/t[0-9]*.sh")
1057
1058 #test
1059 foreach(tsh ${test_scipts})
1060         add_test(NAME ${tsh}
1061                 COMMAND ${SH_EXE} ${tsh}
1062                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/t)
1063 endforeach()
1064
1065 endif()#BUILD_TESTING